This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Only load Maintainers.pm if cmpVERSION.pl is invoked with -x
[perl5.git] / Porting / cmpVERSION.pl
1 #!/usr/bin/perl -w
2
3 #
4 # cmpVERSION - compare the current Perl source tree and a given tag
5 # for modules that have identical version numbers but different contents.
6 #
7 # with -d option, output the diffs too
8 # with -x option, exclude dual-life modules (after all, there are tools
9 #                 like core-cpan-diff that can already deal with them)
10 #                 With this option, one of the directories must be '.'.
11 #
12 # Original by slaven@rezic.de, modified by jhi and matt.w.johnson@gmail.com.
13 #
14
15 use strict;
16
17 use ExtUtils::MakeMaker;
18 use File::Compare;
19 use File::Find;
20 use File::Spec::Functions qw(rel2abs abs2rel catfile catdir curdir);
21 use Getopt::Std;
22
23 sub usage {
24 die <<"EOF";
25 usage: $0 [ -d -x ] source_dir tag_to_compare
26 EOF
27 }
28
29 my %opts;
30 getopts('dx', \%opts) or usage;
31 @ARGV == 2 or usage;
32
33 my ($source_dir, $tag_to_compare) = @ARGV[0,1];
34 die "$0: '$source_dir' does not look like a Perl directory\n"
35     unless -f catfile($source_dir, "perl.h") && -d catdir($source_dir, "Porting");
36 die "$0: '$source_dir' is a Perl directory but does not look like Git working directory\n"
37     unless -d catdir($source_dir, ".git");
38
39 my $null = $^O eq 'MSWin32' ? 'nul' : '/dev/null';
40
41 my $tag_exists = `git --no-pager tag -l $tag_to_compare 2>$null`;
42 chomp $tag_exists;
43
44 die "$0: '$tag_to_compare' is not a known Git tag\n"
45     unless $tag_exists eq $tag_to_compare;
46
47 my %dual_files;
48 if ($opts{x}) {
49     die "With -x, the directory must be '.'\n"
50         unless $source_dir eq '.';
51
52     unshift @INC, 'Porting';
53     require Maintainers;
54
55     for my $m (grep $Maintainers::Modules{$_}{CPAN},
56                                 keys %Maintainers::Modules) {
57         $dual_files{$_} = 1 for Maintainers::get_module_files($m);
58     }
59 } else {
60     chdir $source_dir or die "$0: chdir '$source_dir' failed: $!\n";
61 }
62
63 # Files to skip from the check for one reason or another,
64 # usually because they pull in their version from some other file.
65 my %skip;
66 @skip{
67     'lib/Carp/Heavy.pm',
68     'lib/Config.pm',            # no version number but contents will vary
69     'lib/Exporter/Heavy.pm',
70     'win32/FindExt.pm',
71 } = ();
72 my $skip_dirs = qr|^t/lib|;
73
74 my @all_diffs = `git --no-pager diff --name-only $tag_to_compare`;
75 chomp @all_diffs;
76
77 my @module_diffs = grep {
78     my $this_dir;
79     $this_dir = $1 if m/^(.*)\//;
80     /\.pm$/ &&
81     (!defined($this_dir) || ($this_dir !~ $skip_dirs)) &&
82     !exists $skip{$_} &&
83     !exists $dual_files{$_}
84 } @all_diffs;
85
86 my (@output_files, @output_diffs);
87
88 foreach my $pm_file (@module_diffs) {
89     (my $xs_file = $pm_file) =~ s/\.pm$/.xs/;
90     my $pm_eq = compare_git_file($pm_file, $tag_to_compare);
91     next unless defined $pm_eq;
92     my $xs_eq = 1;
93     if (-e $xs_file) {
94         $xs_eq = compare_git_file($xs_file, $tag_to_compare);
95         next unless defined $xs_eq;
96     }
97     next if ($pm_eq && $xs_eq);
98     my $pm_version = eval {MM->parse_version($pm_file)};
99     my $orig_pm_content = get_file_from_git($pm_file, $tag_to_compare);
100     my $orig_pm_version = eval {MM->parse_version(\$orig_pm_content)};
101     next if ( ! defined $pm_version || ! defined $orig_pm_version );
102     next if ( $pm_version eq 'undef' || $orig_pm_version eq 'undef' ); # sigh
103     next if $pm_version ne $orig_pm_version;
104     push @output_files, $pm_file;
105     push @output_diffs, $pm_file unless $pm_eq;
106     push @output_diffs, $xs_file unless $xs_eq;
107 }
108
109 sub compare_git_file {
110     my ($file, $tag) = @_;
111     open(my $orig_fh, "-|", "git --no-pager show $tag:$file 2>$null");
112     return undef if eof($orig_fh);
113     my $is_eq = compare($file, $orig_fh) == 0;
114     close($orig_fh);
115     return $is_eq;
116 }
117
118 sub get_file_from_git {
119     my ($file, $tag) = @_;
120     local $/ = undef;
121     my $file_content = `git --no-pager show $tag:$file 2>$null`;
122     return $file_content;
123 }
124
125 for (sort @output_files) {
126     print "$_\n";
127 }
128
129 exit unless $opts{d};
130
131 for (sort @output_diffs) {
132     print "\n";
133     system "git --no-pager diff $tag_to_compare '$_'";
134 }
135