This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
document context provided by refgen
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 In Perl, the operator determines what operation is performed,
9 independent of the type of the operands.  For example S<C<$x + $y>>
10 is always a numeric addition, and if C<$x> or C<$y> do not contain
11 numbers, an attempt is made to convert them to numbers first.
12
13 This is in contrast to many other dynamic languages, where the
14 operation is determined by the type of the first argument.  It also
15 means that Perl has two versions of some operators, one for numeric
16 and one for string comparison.  For example S<C<$x == $y>> compares
17 two numbers for equality, and S<C<$x eq $y>> compares two strings.
18
19 There are a few exceptions though: C<x> can be either string
20 repetition or list repetition, depending on the type of the left
21 operand, and C<&>, C<|>, C<^> and C<~> can be either string or numeric bit
22 operations.
23
24 =head2 Operator Precedence and Associativity
25 X<operator, precedence> X<precedence> X<associativity>
26
27 Operator precedence and associativity work in Perl more or less like
28 they do in mathematics.
29
30 I<Operator precedence> means some operators are evaluated before
31 others.  For example, in S<C<2 + 4 * 5>>, the multiplication has higher
32 precedence so S<C<4 * 5>> is evaluated first yielding S<C<2 + 20 ==
33 22>> and not S<C<6 * 5 == 30>>.
34
35 I<Operator associativity> defines what happens if a sequence of the
36 same operators is used one after another: whether the evaluator will
37 evaluate the left operations first, or the right first.  For example, in
38 S<C<8 - 4 - 2>>, subtraction is left associative so Perl evaluates the
39 expression left to right.  S<C<8 - 4>> is evaluated first making the
40 expression S<C<4 - 2 == 2>> and not S<C<8 - 2 == 6>>.
41
42 Perl operators have the following associativity and precedence,
43 listed from highest precedence to lowest.  Operators borrowed from
44 C keep the same precedence relationship with each other, even where
45 C's precedence is slightly screwy.  (This makes learning Perl easier
46 for C folks.)  With very few exceptions, these all operate on scalar
47 values only, not array values.
48
49     left        terms and list operators (leftward)
50     left        ->
51     nonassoc    ++ --
52     right       **
53     right       ! ~ \ and unary + and -
54     left        =~ !~
55     left        * / % x
56     left        + - .
57     left        << >>
58     nonassoc    named unary operators
59     nonassoc    < > <= >= lt gt le ge
60     nonassoc    == != <=> eq ne cmp ~~
61     left        &
62     left        | ^
63     left        &&
64     left        || //
65     nonassoc    ..  ...
66     right       ?:
67     right       = += -= *= etc. goto last next redo dump
68     left        , =>
69     nonassoc    list operators (rightward)
70     right       not
71     left        and
72     left        or xor
73
74 In the following sections, these operators are covered in detail, in the
75 same order in which they appear in the table above.
76
77 Many operators can be overloaded for objects.  See L<overload>.
78
79 =head2 Terms and List Operators (Leftward)
80 X<list operator> X<operator, list> X<term>
81
82 A TERM has the highest precedence in Perl.  They include variables,
83 quote and quote-like operators, any expression in parentheses,
84 and any function whose arguments are parenthesized.  Actually, there
85 aren't really functions in this sense, just list operators and unary
86 operators behaving as functions because you put parentheses around
87 the arguments.  These are all documented in L<perlfunc>.
88
89 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
90 is followed by a left parenthesis as the next token, the operator and
91 arguments within parentheses are taken to be of highest precedence,
92 just like a normal function call.
93
94 In the absence of parentheses, the precedence of list operators such as
95 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
96 whether you are looking at the left side or the right side of the operator.
97 For example, in
98
99     @ary = (1, 3, sort 4, 2);
100     print @ary;         # prints 1324
101
102 the commas on the right of the C<sort> are evaluated before the C<sort>,
103 but the commas on the left are evaluated after.  In other words,
104 list operators tend to gobble up all arguments that follow, and
105 then act like a simple TERM with regard to the preceding expression.
106 Be careful with parentheses:
107
108     # These evaluate exit before doing the print:
109     print($foo, exit);  # Obviously not what you want.
110     print $foo, exit;   # Nor is this.
111
112     # These do the print before evaluating exit:
113     (print $foo), exit; # This is what you want.
114     print($foo), exit;  # Or this.
115     print ($foo), exit; # Or even this.
116
117 Also note that
118
119     print ($foo & 255) + 1, "\n";
120
121 probably doesn't do what you expect at first glance.  The parentheses
122 enclose the argument list for C<print> which is evaluated (printing
123 the result of S<C<$foo & 255>>).  Then one is added to the return value
124 of C<print> (usually 1).  The result is something like this:
125
126     1 + 1, "\n";    # Obviously not what you meant.
127
128 To do what you meant properly, you must write:
129
130     print(($foo & 255) + 1, "\n");
131
132 See L</Named Unary Operators> for more discussion of this.
133
134 Also parsed as terms are the S<C<do {}>> and S<C<eval {}>> constructs, as
135 well as subroutine and method calls, and the anonymous
136 constructors C<[]> and C<{}>.
137
138 See also L</Quote and Quote-like Operators> toward the end of this section,
139 as well as L</"I/O Operators">.
140
141 =head2 The Arrow Operator
142 X<arrow> X<dereference> X<< -> >>
143
144 "C<< -> >>" is an infix dereference operator, just as it is in C
145 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
146 C<(...)> subscript, then the left side must be either a hard or
147 symbolic reference to an array, a hash, or a subroutine respectively.
148 (Or technically speaking, a location capable of holding a hard
149 reference, if it's an array or hash reference being used for
150 assignment.)  See L<perlreftut> and L<perlref>.
151
152 Otherwise, the right side is a method name or a simple scalar
153 variable containing either the method name or a subroutine reference,
154 and the left side must be either an object (a blessed reference)
155 or a class name (that is, a package name).  See L<perlobj>.
156
157 The dereferencing cases (as opposed to method-calling cases) are
158 somewhat extended by the C<postderef> feature.  For the
159 details of that feature, consult L<perlref/Postfix Dereference Syntax>.
160
161 =head2 Auto-increment and Auto-decrement
162 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
163
164 C<"++"> and C<"--"> work as in C.  That is, if placed before a variable,
165 they increment or decrement the variable by one before returning the
166 value, and if placed after, increment or decrement after returning the
167 value.
168
169     $i = 0;  $j = 0;
170     print $i++;  # prints 0
171     print ++$j;  # prints 1
172
173 Note that just as in C, Perl doesn't define B<when> the variable is
174 incremented or decremented.  You just know it will be done sometime
175 before or after the value is returned.  This also means that modifying
176 a variable twice in the same statement will lead to undefined behavior.
177 Avoid statements like:
178
179     $i = $i ++;
180     print ++ $i + $i ++;
181
182 Perl will not guarantee what the result of the above statements is.
183
184 The auto-increment operator has a little extra builtin magic to it.  If
185 you increment a variable that is numeric, or that has ever been used in
186 a numeric context, you get a normal increment.  If, however, the
187 variable has been used in only string contexts since it was set, and
188 has a value that is not the empty string and matches the pattern
189 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
190 character within its range, with carry:
191
192     print ++($foo = "99");      # prints "100"
193     print ++($foo = "a0");      # prints "a1"
194     print ++($foo = "Az");      # prints "Ba"
195     print ++($foo = "zz");      # prints "aaa"
196
197 C<undef> is always treated as numeric, and in particular is changed
198 to C<0> before incrementing (so that a post-increment of an undef value
199 will return C<0> rather than C<undef>).
200
201 The auto-decrement operator is not magical.
202
203 =head2 Exponentiation
204 X<**> X<exponentiation> X<power>
205
206 Binary C<"**"> is the exponentiation operator.  It binds even more
207 tightly than unary minus, so C<-2**4> is C<-(2**4)>, not C<(-2)**4>.
208 (This is
209 implemented using C's C<pow(3)> function, which actually works on doubles
210 internally.)
211
212 Note that certain exponentiation expressions are ill-defined:
213 these include C<0**0>, C<1**Inf>, and C<Inf**0>.  Do not expect
214 any particular results from these special cases, the results
215 are platform-dependent.
216
217 =head2 Symbolic Unary Operators
218 X<unary operator> X<operator, unary>
219
220 Unary C<"!"> performs logical negation, that is, "not".  See also
221 L<C<not>|/Logical Not> for a lower precedence version of this.
222 X<!>
223
224 Unary C<"-"> performs arithmetic negation if the operand is numeric,
225 including any string that looks like a number.  If the operand is
226 an identifier, a string consisting of a minus sign concatenated
227 with the identifier is returned.  Otherwise, if the string starts
228 with a plus or minus, a string starting with the opposite sign is
229 returned.  One effect of these rules is that C<-bareword> is equivalent
230 to the string C<"-bareword">.  If, however, the string begins with a
231 non-alphabetic character (excluding C<"+"> or C<"-">), Perl will attempt
232 to convert
233 the string to a numeric, and the arithmetic negation is performed.  If the
234 string cannot be cleanly converted to a numeric, Perl will give the warning
235 B<Argument "the string" isn't numeric in negation (-) at ...>.
236 X<-> X<negation, arithmetic>
237
238 Unary C<"~"> performs bitwise negation, that is, 1's complement.  For
239 example, S<C<0666 & ~027>> is 0640.  (See also L</Integer Arithmetic> and
240 L</Bitwise String Operators>.)  Note that the width of the result is
241 platform-dependent: C<~0> is 32 bits wide on a 32-bit platform, but 64
242 bits wide on a 64-bit platform, so if you are expecting a certain bit
243 width, remember to use the C<"&"> operator to mask off the excess bits.
244 X<~> X<negation, binary>
245
246 Starting in Perl 5.28, it is a fatal error to try to complement a string
247 containing a character with an ordinal value above 255.
248
249 If the experimental "bitwise" feature is enabled via S<C<use feature
250 'bitwise'>>, then unary C<"~"> always treats its argument as a number, and an
251 alternate form of the operator, C<"~.">, always treats its argument as a
252 string.  So C<~0> and C<~"0"> will both give 2**32-1 on 32-bit platforms,
253 whereas C<~.0> and C<~."0"> will both yield C<"\xff">.  This feature
254 produces a warning unless you use S<C<no warnings 'experimental::bitwise'>>.
255
256 Unary C<"+"> has no effect whatsoever, even on strings.  It is useful
257 syntactically for separating a function name from a parenthesized expression
258 that would otherwise be interpreted as the complete list of function
259 arguments.  (See examples above under L</Terms and List Operators (Leftward)>.)
260 X<+>
261
262 Unary C<"\"> creates references.  If its operand is a single sigilled
263 thing, it creates a reference to that object.  If its operand is a
264 parenthesised list, then it creates references to the things mentioned
265 in the list.  Otherwise it puts its operand in list context, and creates
266 a list of references to the scalars in the list provided by the operand.
267 See L<perlreftut>
268 and L<perlref>.  Do not confuse this behavior with the behavior of
269 backslash within a string, although both forms do convey the notion
270 of protecting the next thing from interpolation.
271 X<\> X<reference> X<backslash>
272
273 =head2 Binding Operators
274 X<binding> X<operator, binding> X<=~> X<!~>
275
276 Binary C<"=~"> binds a scalar expression to a pattern match.  Certain operations
277 search or modify the string C<$_> by default.  This operator makes that kind
278 of operation work on some other string.  The right argument is a search
279 pattern, substitution, or transliteration.  The left argument is what is
280 supposed to be searched, substituted, or transliterated instead of the default
281 C<$_>.  When used in scalar context, the return value generally indicates the
282 success of the operation.  The exceptions are substitution (C<s///>)
283 and transliteration (C<y///>) with the C</r> (non-destructive) option,
284 which cause the B<r>eturn value to be the result of the substitution.
285 Behavior in list context depends on the particular operator.
286 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
287 examples using these operators.
288
289 If the right argument is an expression rather than a search pattern,
290 substitution, or transliteration, it is interpreted as a search pattern at run
291 time.  Note that this means that its
292 contents will be interpolated twice, so
293
294     '\\' =~ q'\\';
295
296 is not ok, as the regex engine will end up trying to compile the
297 pattern C<\>, which it will consider a syntax error.
298
299 Binary C<"!~"> is just like C<"=~"> except the return value is negated in
300 the logical sense.
301
302 Binary C<"!~"> with a non-destructive substitution (C<s///r>) or transliteration
303 (C<y///r>) is a syntax error.
304
305 =head2 Multiplicative Operators
306 X<operator, multiplicative>
307
308 Binary C<"*"> multiplies two numbers.
309 X<*>
310
311 Binary C<"/"> divides two numbers.
312 X</> X<slash>
313
314 Binary C<"%"> is the modulo operator, which computes the division
315 remainder of its first argument with respect to its second argument.
316 Given integer
317 operands C<$m> and C<$n>: If C<$n> is positive, then S<C<$m % $n>> is
318 C<$m> minus the largest multiple of C<$n> less than or equal to
319 C<$m>.  If C<$n> is negative, then S<C<$m % $n>> is C<$m> minus the
320 smallest multiple of C<$n> that is not less than C<$m> (that is, the
321 result will be less than or equal to zero).  If the operands
322 C<$m> and C<$n> are floating point values and the absolute value of
323 C<$n> (that is C<abs($n)>) is less than S<C<(UV_MAX + 1)>>, only
324 the integer portion of C<$m> and C<$n> will be used in the operation
325 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
326 If the absolute value of the right operand (C<abs($n)>) is greater than
327 or equal to S<C<(UV_MAX + 1)>>, C<"%"> computes the floating-point remainder
328 C<$r> in the equation S<C<($r = $m - $i*$n)>> where C<$i> is a certain
329 integer that makes C<$r> have the same sign as the right operand
330 C<$n> (B<not> as the left operand C<$m> like C function C<fmod()>)
331 and the absolute value less than that of C<$n>.
332 Note that when S<C<use integer>> is in scope, C<"%"> gives you direct access
333 to the modulo operator as implemented by your C compiler.  This
334 operator is not as well defined for negative operands, but it will
335 execute faster.
336 X<%> X<remainder> X<modulo> X<mod>
337
338 Binary C<x> is the repetition operator.  In scalar context, or if the
339 left operand is neither enclosed in parentheses nor a C<qw//> list,
340 it performs a string repetition.  In that case it supplies scalar
341 context to the left operand, and returns a string consisting of the
342 left operand string repeated the number of times specified by the right
343 operand.  If the C<x> is in list context, and the left operand is either
344 enclosed in parentheses or a C<qw//> list, it performs a list repetition.
345 In that case it supplies list context to the left operand, and returns
346 a list consisting of the left operand list repeated the number of times
347 specified by the right operand.
348 If the right operand is zero or negative (raising a warning on
349 negative), it returns an empty string
350 or an empty list, depending on the context.
351 X<x>
352
353     print '-' x 80;             # print row of dashes
354
355     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
356
357     @ones = (1) x 80;           # a list of 80 1's
358     @ones = (5) x @ones;        # set all elements to 5
359
360
361 =head2 Additive Operators
362 X<operator, additive>
363
364 Binary C<"+"> returns the sum of two numbers.
365 X<+>
366
367 Binary C<"-"> returns the difference of two numbers.
368 X<->
369
370 Binary C<"."> concatenates two strings.
371 X<string, concatenation> X<concatenation>
372 X<cat> X<concat> X<concatenate> X<.>
373
374 =head2 Shift Operators
375 X<shift operator> X<operator, shift> X<<< << >>>
376 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
377 X<shl> X<shr> X<shift, right> X<shift, left>
378
379 Binary C<<< "<<" >>> returns the value of its left argument shifted left by the
380 number of bits specified by the right argument.  Arguments should be
381 integers.  (See also L</Integer Arithmetic>.)
382
383 Binary C<<< ">>" >>> returns the value of its left argument shifted right by
384 the number of bits specified by the right argument.  Arguments should
385 be integers.  (See also L</Integer Arithmetic>.)
386
387 If S<C<use integer>> (see L</Integer Arithmetic>) is in force then
388 signed C integers are used (I<arithmetic shift>), otherwise unsigned C
389 integers are used (I<logical shift>), even for negative shiftees.
390 In arithmetic right shift the sign bit is replicated on the left,
391 in logical shift zero bits come in from the left.
392
393 Either way, the implementation isn't going to generate results larger
394 than the size of the integer type Perl was built with (32 bits or 64 bits).
395
396 Shifting by negative number of bits means the reverse shift: left
397 shift becomes right shift, right shift becomes left shift.  This is
398 unlike in C, where negative shift is undefined.
399
400 Shifting by more bits than the size of the integers means most of the
401 time zero (all bits fall off), except that under S<C<use integer>>
402 right overshifting a negative shiftee results in -1.  This is unlike
403 in C, where shifting by too many bits is undefined.  A common C
404 behavior is "shift by modulo wordbits", so that for example
405
406     1 >> 64 == 1 >> (64 % 64) == 1 >> 0 == 1  # Common C behavior.
407
408 but that is completely accidental.
409
410 If you get tired of being subject to your platform's native integers,
411 the S<C<use bigint>> pragma neatly sidesteps the issue altogether:
412
413     print 20 << 20;  # 20971520
414     print 20 << 40;  # 5120 on 32-bit machines,
415                      # 21990232555520 on 64-bit machines
416     use bigint;
417     print 20 << 100; # 25353012004564588029934064107520
418
419 =head2 Named Unary Operators
420 X<operator, named unary>
421
422 The various named unary operators are treated as functions with one
423 argument, with optional parentheses.
424
425 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
426 is followed by a left parenthesis as the next token, the operator and
427 arguments within parentheses are taken to be of highest precedence,
428 just like a normal function call.  For example,
429 because named unary operators are higher precedence than C<||>:
430
431     chdir $foo    || die;       # (chdir $foo) || die
432     chdir($foo)   || die;       # (chdir $foo) || die
433     chdir ($foo)  || die;       # (chdir $foo) || die
434     chdir +($foo) || die;       # (chdir $foo) || die
435
436 but, because C<"*"> is higher precedence than named operators:
437
438     chdir $foo * 20;    # chdir ($foo * 20)
439     chdir($foo) * 20;   # (chdir $foo) * 20
440     chdir ($foo) * 20;  # (chdir $foo) * 20
441     chdir +($foo) * 20; # chdir ($foo * 20)
442
443     rand 10 * 20;       # rand (10 * 20)
444     rand(10) * 20;      # (rand 10) * 20
445     rand (10) * 20;     # (rand 10) * 20
446     rand +(10) * 20;    # rand (10 * 20)
447
448 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
449 treated like named unary operators, but they don't follow this functional
450 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
451 equivalent to S<C<-f "$file.bak">>.
452 X<-X> X<filetest> X<operator, filetest>
453
454 See also L</"Terms and List Operators (Leftward)">.
455
456 =head2 Relational Operators
457 X<relational operator> X<operator, relational>
458
459 Perl operators that return true or false generally return values
460 that can be safely used as numbers.  For example, the relational
461 operators in this section and the equality operators in the next
462 one return C<1> for true and a special version of the defined empty
463 string, C<"">, which counts as a zero but is exempt from warnings
464 about improper numeric conversions, just as S<C<"0 but true">> is.
465
466 Binary C<< "<" >> returns true if the left argument is numerically less than
467 the right argument.
468 X<< < >>
469
470 Binary C<< ">" >> returns true if the left argument is numerically greater
471 than the right argument.
472 X<< > >>
473
474 Binary C<< "<=" >> returns true if the left argument is numerically less than
475 or equal to the right argument.
476 X<< <= >>
477
478 Binary C<< ">=" >> returns true if the left argument is numerically greater
479 than or equal to the right argument.
480 X<< >= >>
481
482 Binary C<"lt"> returns true if the left argument is stringwise less than
483 the right argument.
484 X<< lt >>
485
486 Binary C<"gt"> returns true if the left argument is stringwise greater
487 than the right argument.
488 X<< gt >>
489
490 Binary C<"le"> returns true if the left argument is stringwise less than
491 or equal to the right argument.
492 X<< le >>
493
494 Binary C<"ge"> returns true if the left argument is stringwise greater
495 than or equal to the right argument.
496 X<< ge >>
497
498 =head2 Equality Operators
499 X<equality> X<equal> X<equals> X<operator, equality>
500
501 Binary C<< "==" >> returns true if the left argument is numerically equal to
502 the right argument.
503 X<==>
504
505 Binary C<< "!=" >> returns true if the left argument is numerically not equal
506 to the right argument.
507 X<!=>
508
509 Binary C<< "<=>" >> returns -1, 0, or 1 depending on whether the left
510 argument is numerically less than, equal to, or greater than the right
511 argument.  If your platform supports C<NaN>'s (not-a-numbers) as numeric
512 values, using them with C<< "<=>" >> returns undef.  C<NaN> is not
513 C<< "<" >>, C<< "==" >>, C<< ">" >>, C<< "<=" >> or C<< ">=" >> anything
514 (even C<NaN>), so those 5 return false.  S<C<< NaN != NaN >>> returns
515 true, as does S<C<NaN !=> I<anything else>>.  If your platform doesn't
516 support C<NaN>'s then C<NaN> is just a string with numeric value 0.
517 X<< <=> >>
518 X<spaceship>
519
520     $ perl -le '$x = "NaN"; print "No NaN support here" if $x == $x'
521     $ perl -le '$x = "NaN"; print "NaN support here" if $x != $x'
522
523 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all
524 support C<"NaN">.)
525
526 Binary C<"eq"> returns true if the left argument is stringwise equal to
527 the right argument.
528 X<eq>
529
530 Binary C<"ne"> returns true if the left argument is stringwise not equal
531 to the right argument.
532 X<ne>
533
534 Binary C<"cmp"> returns -1, 0, or 1 depending on whether the left
535 argument is stringwise less than, equal to, or greater than the right
536 argument.
537 X<cmp>
538
539 Binary C<"~~"> does a smartmatch between its arguments.  Smart matching
540 is described in the next section.
541 X<~~>
542
543 C<"lt">, C<"le">, C<"ge">, C<"gt"> and C<"cmp"> use the collation (sort)
544 order specified by the current C<LC_COLLATE> locale if a S<C<use
545 locale>> form that includes collation is in effect.  See L<perllocale>.
546 Do not mix these with Unicode,
547 only use them with legacy 8-bit locale encodings.
548 The standard C<L<Unicode::Collate>> and
549 C<L<Unicode::Collate::Locale>> modules offer much more powerful
550 solutions to collation issues.
551
552 For case-insensitive comparisions, look at the L<perlfunc/fc> case-folding
553 function, available in Perl v5.16 or later:
554
555     if ( fc($x) eq fc($y) ) { ... }
556
557 =head2 Smartmatch Operator
558
559 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
560 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
561 used implicitly in the C<when> construct described in L<perlsyn>, although
562 not all C<when> clauses call the smartmatch operator.  Unique among all of
563 Perl's operators, the smartmatch operator can recurse.  The smartmatch
564 operator is L<experimental|perlpolicy/experimental> and its behavior is
565 subject to change.
566
567 It is also unique in that all other Perl operators impose a context
568 (usually string or numeric context) on their operands, autoconverting
569 those operands to those imposed contexts.  In contrast, smartmatch
570 I<infers> contexts from the actual types of its operands and uses that
571 type information to select a suitable comparison mechanism.
572
573 The C<~~> operator compares its operands "polymorphically", determining how
574 to compare them according to their actual types (numeric, string, array,
575 hash, etc.)  Like the equality operators with which it shares the same
576 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
577 read aloud as "in", "inside of", or "is contained in", because the left
578 operand is often looked for I<inside> the right operand.  That makes the
579 order of the operands to the smartmatch operand often opposite that of
580 the regular match operator.  In other words, the "smaller" thing is usually
581 placed in the left operand and the larger one in the right.
582
583 The behavior of a smartmatch depends on what type of things its arguments
584 are, as determined by the following table.  The first row of the table
585 whose types apply determines the smartmatch behavior.  Because what
586 actually happens is mostly determined by the type of the second operand,
587 the table is sorted on the right operand instead of on the left.
588
589  Left      Right      Description and pseudocode
590  ===============================================================
591  Any       undef      check whether Any is undefined
592                 like: !defined Any
593
594  Any       Object     invoke ~~ overloading on Object, or die
595
596  Right operand is an ARRAY:
597
598  Left      Right      Description and pseudocode
599  ===============================================================
600  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
601                 like: (ARRAY1[0] ~~ ARRAY2[0])
602                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
603  HASH      ARRAY      any ARRAY elements exist as HASH keys
604                 like: grep { exists HASH->{$_} } ARRAY
605  Regexp    ARRAY      any ARRAY elements pattern match Regexp
606                 like: grep { /Regexp/ } ARRAY
607  undef     ARRAY      undef in ARRAY
608                 like: grep { !defined } ARRAY
609  Any       ARRAY      smartmatch each ARRAY element[3]
610                 like: grep { Any ~~ $_ } ARRAY
611
612  Right operand is a HASH:
613
614  Left      Right      Description and pseudocode
615  ===============================================================
616  HASH1     HASH2      all same keys in both HASHes
617                 like: keys HASH1 ==
618                          grep { exists HASH2->{$_} } keys HASH1
619  ARRAY     HASH       any ARRAY elements exist as HASH keys
620                 like: grep { exists HASH->{$_} } ARRAY
621  Regexp    HASH       any HASH keys pattern match Regexp
622                 like: grep { /Regexp/ } keys HASH
623  undef     HASH       always false (undef can't be a key)
624                 like: 0 == 1
625  Any       HASH       HASH key existence
626                 like: exists HASH->{Any}
627
628  Right operand is CODE:
629
630  Left      Right      Description and pseudocode
631  ===============================================================
632  ARRAY     CODE       sub returns true on all ARRAY elements[1]
633                 like: !grep { !CODE->($_) } ARRAY
634  HASH      CODE       sub returns true on all HASH keys[1]
635                 like: !grep { !CODE->($_) } keys HASH
636  Any       CODE       sub passed Any returns true
637                 like: CODE->(Any)
638
639 Right operand is a Regexp:
640
641  Left      Right      Description and pseudocode
642  ===============================================================
643  ARRAY     Regexp     any ARRAY elements match Regexp
644                 like: grep { /Regexp/ } ARRAY
645  HASH      Regexp     any HASH keys match Regexp
646                 like: grep { /Regexp/ } keys HASH
647  Any       Regexp     pattern match
648                 like: Any =~ /Regexp/
649
650  Other:
651
652  Left      Right      Description and pseudocode
653  ===============================================================
654  Object    Any        invoke ~~ overloading on Object,
655                       or fall back to...
656
657  Any       Num        numeric equality
658                  like: Any == Num
659  Num       nummy[4]    numeric equality
660                  like: Num == nummy
661  undef     Any        check whether undefined
662                  like: !defined(Any)
663  Any       Any        string equality
664                  like: Any eq Any
665
666
667 Notes:
668
669 =over
670
671 =item 1.
672 Empty hashes or arrays match.
673
674 =item 2.
675 That is, each element smartmatches the element of the same index in the other array.[3]
676
677 =item 3.
678 If a circular reference is found, fall back to referential equality.
679
680 =item 4.
681 Either an actual number, or a string that looks like one.
682
683 =back
684
685 The smartmatch implicitly dereferences any non-blessed hash or array
686 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
687 For blessed references, the C<I<Object>> entries apply.  Smartmatches
688 involving hashes only consider hash keys, never hash values.
689
690 The "like" code entry is not always an exact rendition.  For example, the
691 smartmatch operator short-circuits whenever possible, but C<grep> does
692 not.  Also, C<grep> in scalar context returns the number of matches, but
693 C<~~> returns only true or false.
694
695 Unlike most operators, the smartmatch operator knows to treat C<undef>
696 specially:
697
698     use v5.10.1;
699     @array = (1, 2, 3, undef, 4, 5);
700     say "some elements undefined" if undef ~~ @array;
701
702 Each operand is considered in a modified scalar context, the modification
703 being that array and hash variables are passed by reference to the
704 operator, which implicitly dereferences them.  Both elements
705 of each pair are the same:
706
707     use v5.10.1;
708
709     my %hash = (red    => 1, blue   => 2, green  => 3,
710                 orange => 4, yellow => 5, purple => 6,
711                 black  => 7, grey   => 8, white  => 9);
712
713     my @array = qw(red blue green);
714
715     say "some array elements in hash keys" if  @array ~~  %hash;
716     say "some array elements in hash keys" if \@array ~~ \%hash;
717
718     say "red in array" if "red" ~~  @array;
719     say "red in array" if "red" ~~ \@array;
720
721     say "some keys end in e" if /e$/ ~~  %hash;
722     say "some keys end in e" if /e$/ ~~ \%hash;
723
724 Two arrays smartmatch if each element in the first array smartmatches
725 (that is, is "in") the corresponding element in the second array,
726 recursively.
727
728     use v5.10.1;
729     my @little = qw(red blue green);
730     my @bigger = ("red", "blue", [ "orange", "green" ] );
731     if (@little ~~ @bigger) {  # true!
732         say "little is contained in bigger";
733     }
734
735 Because the smartmatch operator recurses on nested arrays, this
736 will still report that "red" is in the array.
737
738     use v5.10.1;
739     my @array = qw(red blue green);
740     my $nested_array = [[[[[[[ @array ]]]]]]];
741     say "red in array" if "red" ~~ $nested_array;
742
743 If two arrays smartmatch each other, then they are deep
744 copies of each others' values, as this example reports:
745
746     use v5.12.0;
747     my @a = (0, 1, 2, [3, [4, 5], 6], 7);
748     my @b = (0, 1, 2, [3, [4, 5], 6], 7);
749
750     if (@a ~~ @b && @b ~~ @a) {
751         say "a and b are deep copies of each other";
752     }
753     elsif (@a ~~ @b) {
754         say "a smartmatches in b";
755     }
756     elsif (@b ~~ @a) {
757         say "b smartmatches in a";
758     }
759     else {
760         say "a and b don't smartmatch each other at all";
761     }
762
763
764 If you were to set S<C<$b[3] = 4>>, then instead of reporting that "a and b
765 are deep copies of each other", it now reports that C<"b smartmatches in a">.
766 That's because the corresponding position in C<@a> contains an array that
767 (eventually) has a 4 in it.
768
769 Smartmatching one hash against another reports whether both contain the
770 same keys, no more and no less.  This could be used to see whether two
771 records have the same field names, without caring what values those fields
772 might have.  For example:
773
774     use v5.10.1;
775     sub make_dogtag {
776         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
777
778         my ($class, $init_fields) = @_;
779
780         die "Must supply (only) name, rank, and serial number"
781             unless $init_fields ~~ $REQUIRED_FIELDS;
782
783         ...
784     }
785
786 However, this only does what you mean if C<$init_fields> is indeed a hash
787 reference. The condition C<$init_fields ~~ $REQUIRED_FIELDS> also allows the
788 strings C<"name">, C<"rank">, C<"serial_num"> as well as any array reference
789 that contains C<"name"> or C<"rank"> or C<"serial_num"> anywhere to pass
790 through.
791
792 The smartmatch operator is most often used as the implicit operator of a
793 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
794
795 =head3 Smartmatching of Objects
796
797 To avoid relying on an object's underlying representation, if the
798 smartmatch's right operand is an object that doesn't overload C<~~>,
799 it raises the exception "C<Smartmatching a non-overloaded object
800 breaks encapsulation>".  That's because one has no business digging
801 around to see whether something is "in" an object.  These are all
802 illegal on objects without a C<~~> overload:
803
804     %hash ~~ $object
805        42 ~~ $object
806    "fred" ~~ $object
807
808 However, you can change the way an object is smartmatched by overloading
809 the C<~~> operator.  This is allowed to
810 extend the usual smartmatch semantics.
811 For objects that do have an C<~~> overload, see L<overload>.
812
813 Using an object as the left operand is allowed, although not very useful.
814 Smartmatching rules take precedence over overloading, so even if the
815 object in the left operand has smartmatch overloading, this will be
816 ignored.  A left operand that is a non-overloaded object falls back on a
817 string or numeric comparison of whatever the C<ref> operator returns.  That
818 means that
819
820     $object ~~ X
821
822 does I<not> invoke the overload method with C<I<X>> as an argument.
823 Instead the above table is consulted as normal, and based on the type of
824 C<I<X>>, overloading may or may not be invoked.  For simple strings or
825 numbers, "in" becomes equivalent to this:
826
827     $object ~~ $number          ref($object) == $number
828     $object ~~ $string          ref($object) eq $string
829
830 For example, this reports that the handle smells IOish
831 (but please don't really do this!):
832
833     use IO::Handle;
834     my $fh = IO::Handle->new();
835     if ($fh ~~ /\bIO\b/) {
836         say "handle smells IOish";
837     }
838
839 That's because it treats C<$fh> as a string like
840 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
841
842 =head2 Bitwise And
843 X<operator, bitwise, and> X<bitwise and> X<&>
844
845 Binary C<"&"> returns its operands ANDed together bit by bit.  Although no
846 warning is currently raised, the result is not well defined when this operation
847 is performed on operands that aren't either numbers (see
848 L</Integer Arithmetic>) nor bitstrings (see L</Bitwise String Operators>).
849
850 Note that C<"&"> has lower priority than relational operators, so for example
851 the parentheses are essential in a test like
852
853     print "Even\n" if ($x & 1) == 0;
854
855 If the experimental "bitwise" feature is enabled via S<C<use feature
856 'bitwise'>>, then this operator always treats its operand as numbers.  This
857 feature produces a warning unless you also use C<S<no warnings
858 'experimental::bitwise'>>.
859
860 =head2 Bitwise Or and Exclusive Or
861 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
862 X<bitwise xor> X<^>
863
864 Binary C<"|"> returns its operands ORed together bit by bit.
865
866 Binary C<"^"> returns its operands XORed together bit by bit.
867
868 Although no warning is currently raised, the results are not well
869 defined when these operations are performed on operands that aren't either
870 numbers (see L</Integer Arithmetic>) nor bitstrings (see L</Bitwise String
871 Operators>).
872
873 Note that C<"|"> and C<"^"> have lower priority than relational operators, so
874 for example the parentheses are essential in a test like
875
876     print "false\n" if (8 | 2) != 10;
877
878 If the experimental "bitwise" feature is enabled via S<C<use feature
879 'bitwise'>>, then this operator always treats its operand as numbers.  This
880 feature produces a warning unless you also use S<C<no warnings
881 'experimental::bitwise'>>.
882
883 =head2 C-style Logical And
884 X<&&> X<logical and> X<operator, logical, and>
885
886 Binary C<"&&"> performs a short-circuit logical AND operation.  That is,
887 if the left operand is false, the right operand is not even evaluated.
888 Scalar or list context propagates down to the right operand if it
889 is evaluated.
890
891 =head2 C-style Logical Or
892 X<||> X<operator, logical, or>
893
894 Binary C<"||"> performs a short-circuit logical OR operation.  That is,
895 if the left operand is true, the right operand is not even evaluated.
896 Scalar or list context propagates down to the right operand if it
897 is evaluated.
898
899 =head2 Logical Defined-Or
900 X<//> X<operator, logical, defined-or>
901
902 Although it has no direct equivalent in C, Perl's C<//> operator is related
903 to its C-style "or".  In fact, it's exactly the same as C<||>, except that it
904 tests the left hand side's definedness instead of its truth.  Thus,
905 S<C<< EXPR1 // EXPR2 >>> returns the value of C<< EXPR1 >> if it's defined,
906 otherwise, the value of C<< EXPR2 >> is returned.
907 (C<< EXPR1 >> is evaluated in scalar context, C<< EXPR2 >>
908 in the context of C<< // >> itself).  Usually,
909 this is the same result as S<C<< defined(EXPR1) ? EXPR1 : EXPR2 >>> (except that
910 the ternary-operator form can be used as a lvalue, while S<C<< EXPR1 // EXPR2 >>>
911 cannot).  This is very useful for
912 providing default values for variables.  If you actually want to test if
913 at least one of C<$x> and C<$y> is defined, use S<C<defined($x // $y)>>.
914
915 The C<||>, C<//> and C<&&> operators return the last value evaluated
916 (unlike C's C<||> and C<&&>, which return 0 or 1).  Thus, a reasonably
917 portable way to find out the home directory might be:
918
919     $home =  $ENV{HOME}
920           // $ENV{LOGDIR}
921           // (getpwuid($<))[7]
922           // die "You're homeless!\n";
923
924 In particular, this means that you shouldn't use this
925 for selecting between two aggregates for assignment:
926
927     @a = @b || @c;            # This doesn't do the right thing
928     @a = scalar(@b) || @c;    # because it really means this.
929     @a = @b ? @b : @c;        # This works fine, though.
930
931 As alternatives to C<&&> and C<||> when used for
932 control flow, Perl provides the C<and> and C<or> operators (see below).
933 The short-circuit behavior is identical.  The precedence of C<"and">
934 and C<"or"> is much lower, however, so that you can safely use them after a
935 list operator without the need for parentheses:
936
937     unlink "alpha", "beta", "gamma"
938             or gripe(), next LINE;
939
940 With the C-style operators that would have been written like this:
941
942     unlink("alpha", "beta", "gamma")
943             || (gripe(), next LINE);
944
945 It would be even more readable to write that this way:
946
947     unless(unlink("alpha", "beta", "gamma")) {
948         gripe();
949         next LINE;
950     }
951
952 Using C<"or"> for assignment is unlikely to do what you want; see below.
953
954 =head2 Range Operators
955 X<operator, range> X<range> X<..> X<...>
956
957 Binary C<".."> is the range operator, which is really two different
958 operators depending on the context.  In list context, it returns a
959 list of values counting (up by ones) from the left value to the right
960 value.  If the left value is greater than the right value then it
961 returns the empty list.  The range operator is useful for writing
962 S<C<foreach (1..10)>> loops and for doing slice operations on arrays.  In
963 the current implementation, no temporary array is created when the
964 range operator is used as the expression in C<foreach> loops, but older
965 versions of Perl might burn a lot of memory when you write something
966 like this:
967
968     for (1 .. 1_000_000) {
969         # code
970     }
971
972 The range operator also works on strings, using the magical
973 auto-increment, see below.
974
975 In scalar context, C<".."> returns a boolean value.  The operator is
976 bistable, like a flip-flop, and emulates the line-range (comma)
977 operator of B<sed>, B<awk>, and various editors.  Each C<".."> operator
978 maintains its own boolean state, even across calls to a subroutine
979 that contains it.  It is false as long as its left operand is false.
980 Once the left operand is true, the range operator stays true until the
981 right operand is true, I<AFTER> which the range operator becomes false
982 again.  It doesn't become false till the next time the range operator
983 is evaluated.  It can test the right operand and become false on the
984 same evaluation it became true (as in B<awk>), but it still returns
985 true once.  If you don't want it to test the right operand until the
986 next evaluation, as in B<sed>, just use three dots (C<"...">) instead of
987 two.  In all other regards, C<"..."> behaves just like C<".."> does.
988
989 The right operand is not evaluated while the operator is in the
990 "false" state, and the left operand is not evaluated while the
991 operator is in the "true" state.  The precedence is a little lower
992 than || and &&.  The value returned is either the empty string for
993 false, or a sequence number (beginning with 1) for true.  The sequence
994 number is reset for each range encountered.  The final sequence number
995 in a range has the string C<"E0"> appended to it, which doesn't affect
996 its numeric value, but gives you something to search for if you want
997 to exclude the endpoint.  You can exclude the beginning point by
998 waiting for the sequence number to be greater than 1.
999
1000 If either operand of scalar C<".."> is a constant expression,
1001 that operand is considered true if it is equal (C<==>) to the current
1002 input line number (the C<$.> variable).
1003
1004 To be pedantic, the comparison is actually S<C<int(EXPR) == int(EXPR)>>,
1005 but that is only an issue if you use a floating point expression; when
1006 implicitly using C<$.> as described in the previous paragraph, the
1007 comparison is S<C<int(EXPR) == int($.)>> which is only an issue when C<$.>
1008 is set to a floating point value and you are not reading from a file.
1009 Furthermore, S<C<"span" .. "spat">> or S<C<2.18 .. 3.14>> will not do what
1010 you want in scalar context because each of the operands are evaluated
1011 using their integer representation.
1012
1013 Examples:
1014
1015 As a scalar operator:
1016
1017     if (101 .. 200) { print; } # print 2nd hundred lines, short for
1018                                #  if ($. == 101 .. $. == 200) { print; }
1019
1020     next LINE if (1 .. /^$/);  # skip header lines, short for
1021                                #   next LINE if ($. == 1 .. /^$/);
1022                                # (typically in a loop labeled LINE)
1023
1024     s/^/> / if (/^$/ .. eof());  # quote body
1025
1026     # parse mail messages
1027     while (<>) {
1028         $in_header =   1  .. /^$/;
1029         $in_body   = /^$/ .. eof;
1030         if ($in_header) {
1031             # do something
1032         } else { # in body
1033             # do something else
1034         }
1035     } continue {
1036         close ARGV if eof;             # reset $. each file
1037     }
1038
1039 Here's a simple example to illustrate the difference between
1040 the two range operators:
1041
1042     @lines = ("   - Foo",
1043               "01 - Bar",
1044               "1  - Baz",
1045               "   - Quux");
1046
1047     foreach (@lines) {
1048         if (/0/ .. /1/) {
1049             print "$_\n";
1050         }
1051     }
1052
1053 This program will print only the line containing "Bar".  If
1054 the range operator is changed to C<...>, it will also print the
1055 "Baz" line.
1056
1057 And now some examples as a list operator:
1058
1059     for (101 .. 200) { print }      # print $_ 100 times
1060     @foo = @foo[0 .. $#foo];        # an expensive no-op
1061     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
1062
1063 The range operator (in list context) makes use of the magical
1064 auto-increment algorithm if the operands are strings.  You
1065 can say
1066
1067     @alphabet = ("A" .. "Z");
1068
1069 to get all normal letters of the English alphabet, or
1070
1071     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
1072
1073 to get a hexadecimal digit, or
1074
1075     @z2 = ("01" .. "31");
1076     print $z2[$mday];
1077
1078 to get dates with leading zeros.
1079
1080 If the final value specified is not in the sequence that the magical
1081 increment would produce, the sequence goes until the next value would
1082 be longer than the final value specified.
1083
1084 As of Perl 5.26, the list-context range operator on strings works as expected
1085 in the scope of L<< S<C<"use feature 'unicode_strings">>|feature/The
1086 'unicode_strings' feature >>. In previous versions, and outside the scope of
1087 that feature, it exhibits L<perlunicode/The "Unicode Bug">: its behavior
1088 depends on the internal encoding of the range endpoint.
1089
1090 If the initial value specified isn't part of a magical increment
1091 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1092 only the initial value will be returned.  So the following will only
1093 return an alpha:
1094
1095     use charnames "greek";
1096     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1097
1098 To get the 25 traditional lowercase Greek letters, including both sigmas,
1099 you could use this instead:
1100
1101     use charnames "greek";
1102     my @greek_small =  map { chr } ( ord("\N{alpha}")
1103                                         ..
1104                                      ord("\N{omega}")
1105                                    );
1106
1107 However, because there are I<many> other lowercase Greek characters than
1108 just those, to match lowercase Greek characters in a regular expression,
1109 you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the
1110 L<experimental feature|perlrecharclass/Extended Bracketed Character
1111 Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>).
1112
1113 Because each operand is evaluated in integer form, S<C<2.18 .. 3.14>> will
1114 return two elements in list context.
1115
1116     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1117
1118 =head2 Conditional Operator
1119 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1120
1121 Ternary C<"?:"> is the conditional operator, just as in C.  It works much
1122 like an if-then-else.  If the argument before the C<?> is true, the
1123 argument before the C<:> is returned, otherwise the argument after the
1124 C<:> is returned.  For example:
1125
1126     printf "I have %d dog%s.\n", $n,
1127             ($n == 1) ? "" : "s";
1128
1129 Scalar or list context propagates downward into the 2nd
1130 or 3rd argument, whichever is selected.
1131
1132     $x = $ok ? $y : $z;  # get a scalar
1133     @x = $ok ? @y : @z;  # get an array
1134     $x = $ok ? @y : @z;  # oops, that's just a count!
1135
1136 The operator may be assigned to if both the 2nd and 3rd arguments are
1137 legal lvalues (meaning that you can assign to them):
1138
1139     ($x_or_y ? $x : $y) = $z;
1140
1141 Because this operator produces an assignable result, using assignments
1142 without parentheses will get you in trouble.  For example, this:
1143
1144     $x % 2 ? $x += 10 : $x += 2
1145
1146 Really means this:
1147
1148     (($x % 2) ? ($x += 10) : $x) += 2
1149
1150 Rather than this:
1151
1152     ($x % 2) ? ($x += 10) : ($x += 2)
1153
1154 That should probably be written more simply as:
1155
1156     $x += ($x % 2) ? 10 : 2;
1157
1158 =head2 Assignment Operators
1159 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1160 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1161 X<%=> X<^=> X<x=> X<&.=> X<|.=> X<^.=>
1162
1163 C<"="> is the ordinary assignment operator.
1164
1165 Assignment operators work as in C.  That is,
1166
1167     $x += 2;
1168
1169 is equivalent to
1170
1171     $x = $x + 2;
1172
1173 although without duplicating any side effects that dereferencing the lvalue
1174 might trigger, such as from C<tie()>.  Other assignment operators work similarly.
1175 The following are recognized:
1176
1177     **=    +=    *=    &=    &.=    <<=    &&=
1178            -=    /=    |=    |.=    >>=    ||=
1179            .=    %=    ^=    ^.=           //=
1180                  x=
1181
1182 Although these are grouped by family, they all have the precedence
1183 of assignment.  These combined assignment operators can only operate on
1184 scalars, whereas the ordinary assignment operator can assign to arrays,
1185 hashes, lists and even references.  (See L<"Context"|perldata/Context>
1186 and L<perldata/List value constructors>, and L<perlref/Assigning to
1187 References>.)
1188
1189 Unlike in C, the scalar assignment operator produces a valid lvalue.
1190 Modifying an assignment is equivalent to doing the assignment and
1191 then modifying the variable that was assigned to.  This is useful
1192 for modifying a copy of something, like this:
1193
1194     ($tmp = $global) =~ tr/13579/24680/;
1195
1196 Although as of 5.14, that can be also be accomplished this way:
1197
1198     use v5.14;
1199     $tmp = ($global =~  tr/13579/24680/r);
1200
1201 Likewise,
1202
1203     ($x += 2) *= 3;
1204
1205 is equivalent to
1206
1207     $x += 2;
1208     $x *= 3;
1209
1210 Similarly, a list assignment in list context produces the list of
1211 lvalues assigned to, and a list assignment in scalar context returns
1212 the number of elements produced by the expression on the right hand
1213 side of the assignment.
1214
1215 The three dotted bitwise assignment operators (C<&.=> C<|.=> C<^.=>) are new in
1216 Perl 5.22 and experimental.  See L</Bitwise String Operators>.
1217
1218 =head2 Comma Operator
1219 X<comma> X<operator, comma> X<,>
1220
1221 Binary C<","> is the comma operator.  In scalar context it evaluates
1222 its left argument, throws that value away, then evaluates its right
1223 argument and returns that value.  This is just like C's comma operator.
1224
1225 In list context, it's just the list argument separator, and inserts
1226 both its arguments into the list.  These arguments are also evaluated
1227 from left to right.
1228
1229 The C<< => >> operator (sometimes pronounced "fat comma") is a synonym
1230 for the comma except that it causes a
1231 word on its left to be interpreted as a string if it begins with a letter
1232 or underscore and is composed only of letters, digits and underscores.
1233 This includes operands that might otherwise be interpreted as operators,
1234 constants, single number v-strings or function calls.  If in doubt about
1235 this behavior, the left operand can be quoted explicitly.
1236
1237 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1238 or list argument separator, according to context.
1239
1240 For example:
1241
1242     use constant FOO => "something";
1243
1244     my %h = ( FOO => 23 );
1245
1246 is equivalent to:
1247
1248     my %h = ("FOO", 23);
1249
1250 It is I<NOT>:
1251
1252     my %h = ("something", 23);
1253
1254 The C<< => >> operator is helpful in documenting the correspondence
1255 between keys and values in hashes, and other paired elements in lists.
1256
1257     %hash = ( $key => $value );
1258     login( $username => $password );
1259
1260 The special quoting behavior ignores precedence, and hence may apply to
1261 I<part> of the left operand:
1262
1263     print time.shift => "bbb";
1264
1265 That example prints something like C<"1314363215shiftbbb">, because the
1266 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1267 the fact that C<time.shift> is the entire left operand.
1268
1269 =head2 List Operators (Rightward)
1270 X<operator, list, rightward> X<list operator>
1271
1272 On the right side of a list operator, the comma has very low precedence,
1273 such that it controls all comma-separated expressions found there.
1274 The only operators with lower precedence are the logical operators
1275 C<"and">, C<"or">, and C<"not">, which may be used to evaluate calls to list
1276 operators without the need for parentheses:
1277
1278     open HANDLE, "< :encoding(UTF-8)", "filename"
1279         or die "Can't open: $!\n";
1280
1281 However, some people find that code harder to read than writing
1282 it with parentheses:
1283
1284     open(HANDLE, "< :encoding(UTF-8)", "filename")
1285         or die "Can't open: $!\n";
1286
1287 in which case you might as well just use the more customary C<"||"> operator:
1288
1289     open(HANDLE, "< :encoding(UTF-8)", "filename")
1290         || die "Can't open: $!\n";
1291
1292 See also discussion of list operators in L</Terms and List Operators (Leftward)>.
1293
1294 =head2 Logical Not
1295 X<operator, logical, not> X<not>
1296
1297 Unary C<"not"> returns the logical negation of the expression to its right.
1298 It's the equivalent of C<"!"> except for the very low precedence.
1299
1300 =head2 Logical And
1301 X<operator, logical, and> X<and>
1302
1303 Binary C<"and"> returns the logical conjunction of the two surrounding
1304 expressions.  It's equivalent to C<&&> except for the very low
1305 precedence.  This means that it short-circuits: the right
1306 expression is evaluated only if the left expression is true.
1307
1308 =head2 Logical or and Exclusive Or
1309 X<operator, logical, or> X<operator, logical, xor>
1310 X<operator, logical, exclusive or>
1311 X<or> X<xor>
1312
1313 Binary C<"or"> returns the logical disjunction of the two surrounding
1314 expressions.  It's equivalent to C<||> except for the very low precedence.
1315 This makes it useful for control flow:
1316
1317     print FH $data              or die "Can't write to FH: $!";
1318
1319 This means that it short-circuits: the right expression is evaluated
1320 only if the left expression is false.  Due to its precedence, you must
1321 be careful to avoid using it as replacement for the C<||> operator.
1322 It usually works out better for flow control than in assignments:
1323
1324     $x = $y or $z;              # bug: this is wrong
1325     ($x = $y) or $z;            # really means this
1326     $x = $y || $z;              # better written this way
1327
1328 However, when it's a list-context assignment and you're trying to use
1329 C<||> for control flow, you probably need C<"or"> so that the assignment
1330 takes higher precedence.
1331
1332     @info = stat($file) || die;     # oops, scalar sense of stat!
1333     @info = stat($file) or die;     # better, now @info gets its due
1334
1335 Then again, you could always use parentheses.
1336
1337 Binary C<"xor"> returns the exclusive-OR of the two surrounding expressions.
1338 It cannot short-circuit (of course).
1339
1340 There is no low precedence operator for defined-OR.
1341
1342 =head2 C Operators Missing From Perl
1343 X<operator, missing from perl> X<&> X<*>
1344 X<typecasting> X<(TYPE)>
1345
1346 Here is what C has that Perl doesn't:
1347
1348 =over 8
1349
1350 =item unary &
1351
1352 Address-of operator.  (But see the C<"\"> operator for taking a reference.)
1353
1354 =item unary *
1355
1356 Dereference-address operator.  (Perl's prefix dereferencing
1357 operators are typed: C<$>, C<@>, C<%>, and C<&>.)
1358
1359 =item (TYPE)
1360
1361 Type-casting operator.
1362
1363 =back
1364
1365 =head2 Quote and Quote-like Operators
1366 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1367 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1368 X<escape sequence> X<escape>
1369
1370 While we usually think of quotes as literal values, in Perl they
1371 function as operators, providing various kinds of interpolating and
1372 pattern matching capabilities.  Perl provides customary quote characters
1373 for these behaviors, but also provides a way for you to choose your
1374 quote character for any of them.  In the following table, a C<{}> represents
1375 any pair of delimiters you choose.
1376
1377     Customary  Generic        Meaning        Interpolates
1378         ''       q{}          Literal             no
1379         ""      qq{}          Literal             yes
1380         ``      qx{}          Command             yes*
1381                 qw{}         Word list            no
1382         //       m{}       Pattern match          yes*
1383                 qr{}          Pattern             yes*
1384                  s{}{}      Substitution          yes*
1385                 tr{}{}    Transliteration         no (but see below)
1386                  y{}{}    Transliteration         no (but see below)
1387         <<EOF                 here-doc            yes*
1388
1389         * unless the delimiter is ''.
1390
1391 Non-bracketing delimiters use the same character fore and aft, but the four
1392 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1393 that
1394
1395     q{foo{bar}baz}
1396
1397 is the same as
1398
1399     'foo{bar}baz'
1400
1401 Note, however, that this does not always work for quoting Perl code:
1402
1403     $s = q{ if($x eq "}") ... }; # WRONG
1404
1405 is a syntax error.  The C<L<Text::Balanced>> module (standard as of v5.8,
1406 and from CPAN before then) is able to do this properly.
1407
1408 There can (and in some cases, must) be whitespace between the operator
1409 and the quoting
1410 characters, except when C<#> is being used as the quoting character.
1411 C<q#foo#> is parsed as the string C<foo>, while S<C<q #foo#>> is the
1412 operator C<q> followed by a comment.  Its argument will be taken
1413 from the next line.  This allows you to write:
1414
1415     s {foo}  # Replace foo
1416       {bar}  # with bar.
1417
1418 The cases where whitespace must be used are when the quoting character
1419 is a word character (meaning it matches C</\w/>):
1420
1421     q XfooX # Works: means the string 'foo'
1422     qXfooX  # WRONG!
1423
1424 The following escape sequences are available in constructs that interpolate,
1425 and in transliterations:
1426 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1427 X<\o{}>
1428
1429     Sequence     Note  Description
1430     \t                  tab               (HT, TAB)
1431     \n                  newline           (NL)
1432     \r                  return            (CR)
1433     \f                  form feed         (FF)
1434     \b                  backspace         (BS)
1435     \a                  alarm (bell)      (BEL)
1436     \e                  escape            (ESC)
1437     \x{263A}     [1,8]  hex char          (example: SMILEY)
1438     \x1b         [2,8]  restricted range hex char (example: ESC)
1439     \N{name}     [3]    named Unicode character or character sequence
1440     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1441     \c[          [5]    control char      (example: chr(27))
1442     \o{23072}    [6,8]  octal char        (example: SMILEY)
1443     \033         [7,8]  restricted range octal char  (example: ESC)
1444
1445 =over 4
1446
1447 =item [1]
1448
1449 The result is the character specified by the hexadecimal number between
1450 the braces.  See L</[8]> below for details on which character.
1451
1452 Only hexadecimal digits are valid between the braces.  If an invalid
1453 character is encountered, a warning will be issued and the invalid
1454 character and all subsequent characters (valid or invalid) within the
1455 braces will be discarded.
1456
1457 If there are no valid digits between the braces, the generated character is
1458 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1459 will not cause a warning (currently).
1460
1461 =item [2]
1462
1463 The result is the character specified by the hexadecimal number in the range
1464 0x00 to 0xFF.  See L</[8]> below for details on which character.
1465
1466 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1467 by fewer than two valid digits, any valid digits will be zero-padded.  This
1468 means that C<\x7> will be interpreted as C<\x07>, and a lone C<"\x"> will be
1469 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1470 two valid digits will result in a warning.  Note that although the warning
1471 says the illegal character is ignored, it is only ignored as part of the
1472 escape and will still be used as the subsequent character in the string.
1473 For example:
1474
1475   Original    Result    Warns?
1476   "\x7"       "\x07"    no
1477   "\x"        "\x00"    no
1478   "\x7q"      "\x07q"   yes
1479   "\xq"       "\x00q"   yes
1480
1481 =item [3]
1482
1483 The result is the Unicode character or character sequence given by I<name>.
1484 See L<charnames>.
1485
1486 =item [4]
1487
1488 S<C<\N{U+I<hexadecimal number>}>> means the Unicode character whose Unicode code
1489 point is I<hexadecimal number>.
1490
1491 =item [5]
1492
1493 The character following C<\c> is mapped to some other character as shown in the
1494 table:
1495
1496  Sequence   Value
1497    \c@      chr(0)
1498    \cA      chr(1)
1499    \ca      chr(1)
1500    \cB      chr(2)
1501    \cb      chr(2)
1502    ...
1503    \cZ      chr(26)
1504    \cz      chr(26)
1505    \c[      chr(27)
1506                      # See below for chr(28)
1507    \c]      chr(29)
1508    \c^      chr(30)
1509    \c_      chr(31)
1510    \c?      chr(127) # (on ASCII platforms; see below for link to
1511                      #  EBCDIC discussion)
1512
1513 In other words, it's the character whose code point has had 64 xor'd with
1514 its uppercase.  C<\c?> is DELETE on ASCII platforms because
1515 S<C<ord("?") ^ 64>> is 127, and
1516 C<\c@> is NULL because the ord of C<"@"> is 64, so xor'ing 64 itself produces 0.
1517
1518 Also, C<\c\I<X>> yields S<C< chr(28) . "I<X>">> for any I<X>, but cannot come at the
1519 end of a string, because the backslash would be parsed as escaping the end
1520 quote.
1521
1522 On ASCII platforms, the resulting characters from the list above are the
1523 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1524 L<perlebcdic/OPERATOR DIFFERENCES> for a full discussion of the
1525 differences between these for ASCII versus EBCDIC platforms.
1526
1527 Use of any other character following the C<"c"> besides those listed above is
1528 discouraged, and as of Perl v5.20, the only characters actually allowed
1529 are the printable ASCII ones, minus the left brace C<"{">.  What happens
1530 for any of the allowed other characters is that the value is derived by
1531 xor'ing with the seventh bit, which is 64, and a warning raised if
1532 enabled.  Using the non-allowed characters generates a fatal error.
1533
1534 To get platform independent controls, you can use C<\N{...}>.
1535
1536 =item [6]
1537
1538 The result is the character specified by the octal number between the braces.
1539 See L</[8]> below for details on which character.
1540
1541 If a character that isn't an octal digit is encountered, a warning is raised,
1542 and the value is based on the octal digits before it, discarding it and all
1543 following characters up to the closing brace.  It is a fatal error if there are
1544 no octal digits at all.
1545
1546 =item [7]
1547
1548 The result is the character specified by the three-digit octal number in the
1549 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1550 L</[8]> below for details on which character.
1551
1552 Some contexts allow 2 or even 1 digit, but any usage without exactly
1553 three digits, the first being a zero, may give unintended results.  (For
1554 example, in a regular expression it may be confused with a backreference;
1555 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1556 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1557 use this construct only for ordinals C<\077> and below, remembering to pad to
1558 the left with zeros to make three digits.  For larger ordinals, either use
1559 C<\o{}>, or convert to something else, such as to hex and use C<\N{U+}>
1560 (which is portable between platforms with different character sets) or
1561 C<\x{}> instead.
1562
1563 =item [8]
1564
1565 Several constructs above specify a character by a number.  That number
1566 gives the character's position in the character set encoding (indexed from 0).
1567 This is called synonymously its ordinal, code position, or code point.  Perl
1568 works on platforms that have a native encoding currently of either ASCII/Latin1
1569 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1570 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1571 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1572 it as a Unicode code point and the result is the corresponding Unicode
1573 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1574 decimal, which is less than 256, so the number is interpreted in the native
1575 character set encoding.  In ASCII the character in the 80th position (indexed
1576 from 0) is the letter C<"P">, and in EBCDIC it is the ampersand symbol C<"&">.
1577 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1578 as a Unicode code point no matter what the native encoding is.  The name of the
1579 character in the 256th position (indexed by 0) in Unicode is
1580 C<LATIN CAPITAL LETTER A WITH MACRON>.
1581
1582 An exception to the above rule is that S<C<\N{U+I<hex number>}>> is
1583 always interpreted as a Unicode code point, so that C<\N{U+0050}> is C<"P"> even
1584 on EBCDIC platforms.
1585
1586 =back
1587
1588 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1589 the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may
1590 use C<\N{VT}>, C<\ck>, C<\N{U+0b}>, or C<\x0b>.  (C<\v>
1591 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1592
1593 The following escape sequences are available in constructs that interpolate,
1594 but not in transliterations.
1595 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1596
1597     \l          lowercase next character only
1598     \u          titlecase (not uppercase!) next character only
1599     \L          lowercase all characters till \E or end of string
1600     \U          uppercase all characters till \E or end of string
1601     \F          foldcase all characters till \E or end of string
1602     \Q          quote (disable) pattern metacharacters till \E or
1603                 end of string
1604     \E          end either case modification or quoted section
1605                 (whichever was last seen)
1606
1607 See L<perlfunc/quotemeta> for the exact definition of characters that
1608 are quoted by C<\Q>.
1609
1610 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1611 C<\E> for each.  For example:
1612
1613  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1614  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1615
1616 If a S<C<use locale>> form that includes C<LC_CTYPE> is in effect (see
1617 L<perllocale>), the case map used by C<\l>, C<\L>, C<\u>, and C<\U> is
1618 taken from the current locale.  If Unicode (for example, C<\N{}> or code
1619 points of 0x100 or beyond) is being used, the case map used by C<\l>,
1620 C<\L>, C<\u>, and C<\U> is as defined by Unicode.  That means that
1621 case-mapping a single character can sometimes produce a sequence of
1622 several characters.
1623 Under S<C<use locale>>, C<\F> produces the same results as C<\L>
1624 for all locales but a UTF-8 one, where it instead uses the Unicode
1625 definition.
1626
1627 All systems use the virtual C<"\n"> to represent a line terminator,
1628 called a "newline".  There is no such thing as an unvarying, physical
1629 newline character.  It is only an illusion that the operating system,
1630 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1631 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1632 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1633 and on systems without a line terminator,
1634 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1635 you mean a "newline" for your system, but use the literal ASCII when you
1636 need an exact character.  For example, most networking protocols expect
1637 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1638 and although they often accept just C<"\012">, they seldom tolerate just
1639 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1640 you may be burned some day.
1641 X<newline> X<line terminator> X<eol> X<end of line>
1642 X<\n> X<\r> X<\r\n>
1643
1644 For constructs that do interpolate, variables beginning with "C<$>"
1645 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1646 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1647 But method calls such as C<< $obj->meth >> are not.
1648
1649 Interpolating an array or slice interpolates the elements in order,
1650 separated by the value of C<$">, so is equivalent to interpolating
1651 S<C<join $", @array>>.  "Punctuation" arrays such as C<@*> are usually
1652 interpolated only if the name is enclosed in braces C<@{*}>, but the
1653 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1654
1655 For double-quoted strings, the quoting from C<\Q> is applied after
1656 interpolation and escapes are processed.
1657
1658     "abc\Qfoo\tbar$s\Exyz"
1659
1660 is equivalent to
1661
1662     "abc" . quotemeta("foo\tbar$s") . "xyz"
1663
1664 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1665 the quoting from C<\Q> is applied after interpolation is processed,
1666 but before escapes are processed.  This allows the pattern to match
1667 literally (except for C<$> and C<@>).  For example, the following matches:
1668
1669     '\s\t' =~ /\Q\s\t/
1670
1671 Because C<$> or C<@> trigger interpolation, you'll need to use something
1672 like C</\Quser\E\@\Qhost/> to match them literally.
1673
1674 Patterns are subject to an additional level of interpretation as a
1675 regular expression.  This is done as a second pass, after variables are
1676 interpolated, so that regular expressions may be incorporated into the
1677 pattern from the variables.  If this is not what you want, use C<\Q> to
1678 interpolate a variable literally.
1679
1680 Apart from the behavior described above, Perl does not expand
1681 multiple levels of interpolation.  In particular, contrary to the
1682 expectations of shell programmers, back-quotes do I<NOT> interpolate
1683 within double quotes, nor do single quotes impede evaluation of
1684 variables when used within double quotes.
1685
1686 =head2 Regexp Quote-Like Operators
1687 X<operator, regexp>
1688
1689 Here are the quote-like operators that apply to pattern
1690 matching and related activities.
1691
1692 =over 8
1693
1694 =item C<qr/I<STRING>/msixpodualn>
1695 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1696
1697 This operator quotes (and possibly compiles) its I<STRING> as a regular
1698 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1699 in C<m/I<PATTERN>/>.  If C<"'"> is used as the delimiter, no variable
1700 interpolation is done.  Returns a Perl value which may be used instead of the
1701 corresponding C</I<STRING>/msixpodualn> expression.  The returned value is a
1702 normalized version of the original pattern.  It magically differs from
1703 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1704 however, dereferencing it is not well defined (you currently get the
1705 normalized version of the original pattern, but this may change).
1706
1707
1708 For example,
1709
1710     $rex = qr/my.STRING/is;
1711     print $rex;                 # prints (?si-xm:my.STRING)
1712     s/$rex/foo/;
1713
1714 is equivalent to
1715
1716     s/my.STRING/foo/is;
1717
1718 The result may be used as a subpattern in a match:
1719
1720     $re = qr/$pattern/;
1721     $string =~ /foo${re}bar/;   # can be interpolated in other
1722                                 # patterns
1723     $string =~ $re;             # or used standalone
1724     $string =~ /$re/;           # or this way
1725
1726 Since Perl may compile the pattern at the moment of execution of the C<qr()>
1727 operator, using C<qr()> may have speed advantages in some situations,
1728 notably if the result of C<qr()> is used standalone:
1729
1730     sub match {
1731         my $patterns = shift;
1732         my @compiled = map qr/$_/i, @$patterns;
1733         grep {
1734             my $success = 0;
1735             foreach my $pat (@compiled) {
1736                 $success = 1, last if /$pat/;
1737             }
1738             $success;
1739         } @_;
1740     }
1741
1742 Precompilation of the pattern into an internal representation at
1743 the moment of C<qr()> avoids the need to recompile the pattern every
1744 time a match C</$pat/> is attempted.  (Perl has many other internal
1745 optimizations, but none would be triggered in the above example if
1746 we did not use C<qr()> operator.)
1747
1748 Options (specified by the following modifiers) are:
1749
1750     m   Treat string as multiple lines.
1751     s   Treat string as single line. (Make . match a newline)
1752     i   Do case-insensitive pattern matching.
1753     x   Use extended regular expressions; specifying two
1754         x's means \t and the SPACE character are ignored within
1755         square-bracketed character classes
1756     p   When matching preserve a copy of the matched string so
1757         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be
1758         defined (ignored starting in v5.20) as these are always
1759         defined starting in that release
1760     o   Compile pattern only once.
1761     a   ASCII-restrict: Use ASCII for \d, \s, \w and [[:posix:]]
1762         character classes; specifying two a's adds the further
1763         restriction that no ASCII character will match a
1764         non-ASCII one under /i.
1765     l   Use the current run-time locale's rules.
1766     u   Use Unicode rules.
1767     d   Use Unicode or native charset, as in 5.12 and earlier.
1768     n   Non-capture mode. Don't let () fill in $1, $2, etc...
1769
1770 If a precompiled pattern is embedded in a larger pattern then the effect
1771 of C<"msixpluadn"> will be propagated appropriately.  The effect that the
1772 C</o> modifier has is not propagated, being restricted to those patterns
1773 explicitly using it.
1774
1775 The last four modifiers listed above, added in Perl 5.14,
1776 control the character set rules, but C</a> is the only one you are likely
1777 to want to specify explicitly; the other three are selected
1778 automatically by various pragmas.
1779
1780 See L<perlre> for additional information on valid syntax for I<STRING>, and
1781 for a detailed look at the semantics of regular expressions.  In
1782 particular, all modifiers except the largely obsolete C</o> are further
1783 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1784
1785 =item C<m/I<PATTERN>/msixpodualngc>
1786 X<m> X<operator, match>
1787 X<regexp, options> X<regexp> X<regex, options> X<regex>
1788 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1789
1790 =item C</I<PATTERN>/msixpodualngc>
1791
1792 Searches a string for a pattern match, and in scalar context returns
1793 true if it succeeds, false if it fails.  If no string is specified
1794 via the C<=~> or C<!~> operator, the C<$_> string is searched.  (The
1795 string specified with C<=~> need not be an lvalue--it may be the
1796 result of an expression evaluation, but remember the C<=~> binds
1797 rather tightly.)  See also L<perlre>.
1798
1799 Options are as described in C<qr//> above; in addition, the following match
1800 process modifiers are available:
1801
1802  g  Match globally, i.e., find all occurrences.
1803  c  Do not reset search position on a failed match when /g is
1804     in effect.
1805
1806 If C<"/"> is the delimiter then the initial C<m> is optional.  With the C<m>
1807 you can use any pair of non-whitespace (ASCII) characters
1808 as delimiters.  This is particularly useful for matching path names
1809 that contain C<"/">, to avoid LTS (leaning toothpick syndrome).  If C<"?"> is
1810 the delimiter, then a match-only-once rule applies,
1811 described in C<m?I<PATTERN>?> below.  If C<"'"> (single quote) is the delimiter,
1812 no variable interpolation is performed on the I<PATTERN>.
1813 When using a delimiter character valid in an identifier, whitespace is required
1814 after the C<m>.
1815
1816 I<PATTERN> may contain variables, which will be interpolated
1817 every time the pattern search is evaluated, except
1818 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1819 C<$|> are not interpolated because they look like end-of-string tests.)
1820 Perl will not recompile the pattern unless an interpolated
1821 variable that it contains changes.  You can force Perl to skip the
1822 test and never recompile by adding a C</o> (which stands for "once")
1823 after the trailing delimiter.
1824 Once upon a time, Perl would recompile regular expressions
1825 unnecessarily, and this modifier was useful to tell it not to do so, in the
1826 interests of speed.  But now, the only reasons to use C</o> are one of:
1827
1828 =over
1829
1830 =item 1
1831
1832 The variables are thousands of characters long and you know that they
1833 don't change, and you need to wring out the last little bit of speed by
1834 having Perl skip testing for that.  (There is a maintenance penalty for
1835 doing this, as mentioning C</o> constitutes a promise that you won't
1836 change the variables in the pattern.  If you do change them, Perl won't
1837 even notice.)
1838
1839 =item 2
1840
1841 you want the pattern to use the initial values of the variables
1842 regardless of whether they change or not.  (But there are saner ways
1843 of accomplishing this than using C</o>.)
1844
1845 =item 3
1846
1847 If the pattern contains embedded code, such as
1848
1849     use re 'eval';
1850     $code = 'foo(?{ $x })';
1851     /$code/
1852
1853 then perl will recompile each time, even though the pattern string hasn't
1854 changed, to ensure that the current value of C<$x> is seen each time.
1855 Use C</o> if you want to avoid this.
1856
1857 =back
1858
1859 The bottom line is that using C</o> is almost never a good idea.
1860
1861 =item The empty pattern C<//>
1862
1863 If the I<PATTERN> evaluates to the empty string, the last
1864 I<successfully> matched regular expression is used instead.  In this
1865 case, only the C<g> and C<c> flags on the empty pattern are honored;
1866 the other flags are taken from the original pattern.  If no match has
1867 previously succeeded, this will (silently) act instead as a genuine
1868 empty pattern (which will always match).
1869
1870 Note that it's possible to confuse Perl into thinking C<//> (the empty
1871 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1872 good about this, but some pathological cases might trigger this, such as
1873 C<$x///> (is that S<C<($x) / (//)>> or S<C<$x // />>?) and S<C<print $fh //>>
1874 (S<C<print $fh(//>> or S<C<print($fh //>>?).  In all of these examples, Perl
1875 will assume you meant defined-or.  If you meant the empty regex, just
1876 use parentheses or spaces to disambiguate, or even prefix the empty
1877 regex with an C<m> (so C<//> becomes C<m//>).
1878
1879 =item Matching in list context
1880
1881 If the C</g> option is not used, C<m//> in list context returns a
1882 list consisting of the subexpressions matched by the parentheses in the
1883 pattern, that is, (C<$1>, C<$2>, C<$3>...)  (Note that here C<$1> etc. are
1884 also set).  When there are no parentheses in the pattern, the return
1885 value is the list C<(1)> for success.
1886 With or without parentheses, an empty list is returned upon failure.
1887
1888 Examples:
1889
1890  open(TTY, "+</dev/tty")
1891     || die "can't access /dev/tty: $!";
1892
1893  <TTY> =~ /^y/i && foo();       # do foo if desired
1894
1895  if (/Version: *([0-9.]*)/) { $version = $1; }
1896
1897  next if m#^/usr/spool/uucp#;
1898
1899  # poor man's grep
1900  $arg = shift;
1901  while (<>) {
1902     print if /$arg/o; # compile only once (no longer needed!)
1903  }
1904
1905  if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1906
1907 This last example splits C<$foo> into the first two words and the
1908 remainder of the line, and assigns those three fields to C<$F1>, C<$F2>, and
1909 C<$Etc>.  The conditional is true if any variables were assigned; that is,
1910 if the pattern matched.
1911
1912 The C</g> modifier specifies global pattern matching--that is,
1913 matching as many times as possible within the string.  How it behaves
1914 depends on the context.  In list context, it returns a list of the
1915 substrings matched by any capturing parentheses in the regular
1916 expression.  If there are no parentheses, it returns a list of all
1917 the matched strings, as if there were parentheses around the whole
1918 pattern.
1919
1920 In scalar context, each execution of C<m//g> finds the next match,
1921 returning true if it matches, and false if there is no further match.
1922 The position after the last match can be read or set using the C<pos()>
1923 function; see L<perlfunc/pos>.  A failed match normally resets the
1924 search position to the beginning of the string, but you can avoid that
1925 by adding the C</c> modifier (for example, C<m//gc>).  Modifying the target
1926 string also resets the search position.
1927
1928 =item C<\G I<assertion>>
1929
1930 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1931 zero-width assertion that matches the exact position where the
1932 previous C<m//g>, if any, left off.  Without the C</g> modifier, the
1933 C<\G> assertion still anchors at C<pos()> as it was at the start of
1934 the operation (see L<perlfunc/pos>), but the match is of course only
1935 attempted once.  Using C<\G> without C</g> on a target string that has
1936 not previously had a C</g> match applied to it is the same as using
1937 the C<\A> assertion to match the beginning of the string.  Note also
1938 that, currently, C<\G> is only properly supported when anchored at the
1939 very beginning of the pattern.
1940
1941 Examples:
1942
1943     # list context
1944     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1945
1946     # scalar context
1947     local $/ = "";
1948     while ($paragraph = <>) {
1949         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1950             $sentences++;
1951         }
1952     }
1953     say $sentences;
1954
1955 Here's another way to check for sentences in a paragraph:
1956
1957  my $sentence_rx = qr{
1958     (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or
1959                                 # whitespace
1960     \p{Lu}                      # capital letter
1961     .*?                         # a bunch of anything
1962     (?<= \S )                   # that ends in non-
1963                                 # whitespace
1964     (?<! \b [DMS]r  )           # but isn't a common abbr.
1965     (?<! \b Mrs )
1966     (?<! \b Sra )
1967     (?<! \b St  )
1968     [.?!]                       # followed by a sentence
1969                                 # ender
1970     (?= $ | \s )                # in front of end-of-string
1971                                 # or whitespace
1972  }sx;
1973  local $/ = "";
1974  while (my $paragraph = <>) {
1975     say "NEW PARAGRAPH";
1976     my $count = 0;
1977     while ($paragraph =~ /($sentence_rx)/g) {
1978         printf "\tgot sentence %d: <%s>\n", ++$count, $1;
1979     }
1980  }
1981
1982 Here's how to use C<m//gc> with C<\G>:
1983
1984     $_ = "ppooqppqq";
1985     while ($i++ < 2) {
1986         print "1: '";
1987         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1988         print "2: '";
1989         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1990         print "3: '";
1991         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1992     }
1993     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1994
1995 The last example should print:
1996
1997     1: 'oo', pos=4
1998     2: 'q', pos=5
1999     3: 'pp', pos=7
2000     1: '', pos=7
2001     2: 'q', pos=8
2002     3: '', pos=8
2003     Final: 'q', pos=8
2004
2005 Notice that the final match matched C<q> instead of C<p>, which a match
2006 without the C<\G> anchor would have done.  Also note that the final match
2007 did not update C<pos>.  C<pos> is only updated on a C</g> match.  If the
2008 final match did indeed match C<p>, it's a good bet that you're running a
2009 very old (pre-5.6.0) version of Perl.
2010
2011 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
2012 combine several regexps like this to process a string part-by-part,
2013 doing different actions depending on which regexp matched.  Each
2014 regexp tries to match where the previous one leaves off.
2015
2016  $_ = <<'EOL';
2017     $url = URI::URL->new( "http://example.com/" );
2018     die if $url eq "xXx";
2019  EOL
2020
2021  LOOP: {
2022      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
2023      print(" lowercase"),    redo LOOP
2024                                     if /\G\p{Ll}+\b[,.;]?\s*/gc;
2025      print(" UPPERCASE"),    redo LOOP
2026                                     if /\G\p{Lu}+\b[,.;]?\s*/gc;
2027      print(" Capitalized"),  redo LOOP
2028                               if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
2029      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
2030      print(" alphanumeric"), redo LOOP
2031                             if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
2032      print(" line-noise"),   redo LOOP if /\G\W+/gc;
2033      print ". That's all!\n";
2034  }
2035
2036 Here is the output (split into several lines):
2037
2038  line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
2039  line-noise lowercase line-noise lowercase line-noise lowercase
2040  lowercase line-noise lowercase lowercase line-noise lowercase
2041  lowercase line-noise MiXeD line-noise. That's all!
2042
2043 =item C<m?I<PATTERN>?msixpodualngc>
2044 X<?> X<operator, match-once>
2045
2046 This is just like the C<m/I<PATTERN>/> search, except that it matches
2047 only once between calls to the C<reset()> operator.  This is a useful
2048 optimization when you want to see only the first occurrence of
2049 something in each file of a set of files, for instance.  Only C<m??>
2050 patterns local to the current package are reset.
2051
2052     while (<>) {
2053         if (m?^$?) {
2054                             # blank line between header and body
2055         }
2056     } continue {
2057         reset if eof;       # clear m?? status for next file
2058     }
2059
2060 Another example switched the first "latin1" encoding it finds
2061 to "utf8" in a pod file:
2062
2063     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
2064
2065 The match-once behavior is controlled by the match delimiter being
2066 C<?>; with any other delimiter this is the normal C<m//> operator.
2067
2068 In the past, the leading C<m> in C<m?I<PATTERN>?> was optional, but omitting it
2069 would produce a deprecation warning.  As of v5.22.0, omitting it produces a
2070 syntax error.  If you encounter this construct in older code, you can just add
2071 C<m>.
2072
2073 =item C<s/I<PATTERN>/I<REPLACEMENT>/msixpodualngcer>
2074 X<s> X<substitute> X<substitution> X<replace> X<regexp, replace>
2075 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
2076
2077 Searches a string for a pattern, and if found, replaces that pattern
2078 with the replacement text and returns the number of substitutions
2079 made.  Otherwise it returns false (a value that is both an empty string (C<"">)
2080 and numeric zero (C<0>) as described in L</Relational Operators>).
2081
2082 If the C</r> (non-destructive) option is used then it runs the
2083 substitution on a copy of the string and instead of returning the
2084 number of substitutions, it returns the copy whether or not a
2085 substitution occurred.  The original string is never changed when
2086 C</r> is used.  The copy will always be a plain string, even if the
2087 input is an object or a tied variable.
2088
2089 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
2090 variable is searched and modified.  Unless the C</r> option is used,
2091 the string specified must be a scalar variable, an array element, a
2092 hash element, or an assignment to one of those; that is, some sort of
2093 scalar lvalue.
2094
2095 If the delimiter chosen is a single quote, no variable interpolation is
2096 done on either the I<PATTERN> or the I<REPLACEMENT>.  Otherwise, if the
2097 I<PATTERN> contains a C<$> that looks like a variable rather than an
2098 end-of-string test, the variable will be interpolated into the pattern
2099 at run-time.  If you want the pattern compiled only once the first time
2100 the variable is interpolated, use the C</o> option.  If the pattern
2101 evaluates to the empty string, the last successfully executed regular
2102 expression is used instead.  See L<perlre> for further explanation on these.
2103
2104 Options are as with C<m//> with the addition of the following replacement
2105 specific options:
2106
2107     e   Evaluate the right side as an expression.
2108     ee  Evaluate the right side as a string then eval the
2109         result.
2110     r   Return substitution and leave the original string
2111         untouched.
2112
2113 Any non-whitespace delimiter may replace the slashes.  Add space after
2114 the C<s> when using a character allowed in identifiers.  If single quotes
2115 are used, no interpretation is done on the replacement string (the C</e>
2116 modifier overrides this, however).  Note that Perl treats backticks
2117 as normal delimiters; the replacement text is not evaluated as a command.
2118 If the I<PATTERN> is delimited by bracketing quotes, the I<REPLACEMENT> has
2119 its own pair of quotes, which may or may not be bracketing quotes, for example,
2120 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2121 replacement portion to be treated as a full-fledged Perl expression
2122 and evaluated right then and there.  It is, however, syntax checked at
2123 compile-time.  A second C<e> modifier will cause the replacement portion
2124 to be C<eval>ed before being run as a Perl expression.
2125
2126 Examples:
2127
2128     s/\bgreen\b/mauve/g;              # don't change wintergreen
2129
2130     $path =~ s|/usr/bin|/usr/local/bin|;
2131
2132     s/Login: $foo/Login: $bar/; # run-time pattern
2133
2134     ($foo = $bar) =~ s/this/that/;      # copy first, then
2135                                         # change
2136     ($foo = "$bar") =~ s/this/that/;    # convert to string,
2137                                         # copy, then change
2138     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2139     $foo = $bar =~ s/this/that/r
2140                 =~ s/that/the other/r;  # Chained substitutes
2141                                         # using /r
2142     @foo = map { s/this/that/r } @bar   # /r is very useful in
2143                                         # maps
2144
2145     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-cnt
2146
2147     $_ = 'abc123xyz';
2148     s/\d+/$&*2/e;               # yields 'abc246xyz'
2149     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2150     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2151
2152     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2153     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2154     s/^=(\w+)/pod($1)/ge;       # use function call
2155
2156     $_ = 'abc123xyz';
2157     $x = s/abc/def/r;           # $x is 'def123xyz' and
2158                                 # $_ remains 'abc123xyz'.
2159
2160     # expand variables in $_, but dynamics only, using
2161     # symbolic dereferencing
2162     s/\$(\w+)/${$1}/g;
2163
2164     # Add one to the value of any numbers in the string
2165     s/(\d+)/1 + $1/eg;
2166
2167     # Titlecase words in the last 30 characters only
2168     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2169
2170     # This will expand any embedded scalar variable
2171     # (including lexicals) in $_ : First $1 is interpolated
2172     # to the variable name, and then evaluated
2173     s/(\$\w+)/$1/eeg;
2174
2175     # Delete (most) C comments.
2176     $program =~ s {
2177         /\*     # Match the opening delimiter.
2178         .*?     # Match a minimal number of characters.
2179         \*/     # Match the closing delimiter.
2180     } []gsx;
2181
2182     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_,
2183                                 # expensively
2184
2185     for ($variable) {           # trim whitespace in $variable,
2186                                 # cheap
2187         s/^\s+//;
2188         s/\s+$//;
2189     }
2190
2191     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2192
2193 Note the use of C<$> instead of C<\> in the last example.  Unlike
2194 B<sed>, we use the \<I<digit>> form only in the left hand side.
2195 Anywhere else it's $<I<digit>>.
2196
2197 Occasionally, you can't use just a C</g> to get all the changes
2198 to occur that you might want.  Here are two common cases:
2199
2200     # put commas in the right places in an integer
2201     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2202
2203     # expand tabs to 8-column spacing
2204     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2205
2206 =back
2207
2208 =head2 Quote-Like Operators
2209 X<operator, quote-like>
2210
2211 =over 4
2212
2213 =item C<q/I<STRING>/>
2214 X<q> X<quote, single> X<'> X<''>
2215
2216 =item C<'I<STRING>'>
2217
2218 A single-quoted, literal string.  A backslash represents a backslash
2219 unless followed by the delimiter or another backslash, in which case
2220 the delimiter or backslash is interpolated.
2221
2222     $foo = q!I said, "You said, 'She said it.'"!;
2223     $bar = q('This is it.');
2224     $baz = '\n';                # a two-character string
2225
2226 =item C<qq/I<STRING>/>
2227 X<qq> X<quote, double> X<"> X<"">
2228
2229 =item "I<STRING>"
2230
2231 A double-quoted, interpolated string.
2232
2233     $_ .= qq
2234      (*** The previous line contains the naughty word "$1".\n)
2235                 if /\b(tcl|java|python)\b/i;      # :-)
2236     $baz = "\n";                # a one-character string
2237
2238 =item C<qx/I<STRING>/>
2239 X<qx> X<`> X<``> X<backtick>
2240
2241 =item C<`I<STRING>`>
2242
2243 A string which is (possibly) interpolated and then executed as a
2244 system command with F</bin/sh> or its equivalent.  Shell wildcards,
2245 pipes, and redirections will be honored.  The collected standard
2246 output of the command is returned; standard error is unaffected.  In
2247 scalar context, it comes back as a single (potentially multi-line)
2248 string, or C<undef> if the command failed.  In list context, returns a
2249 list of lines (however you've defined lines with C<$/> or
2250 C<$INPUT_RECORD_SEPARATOR>), or an empty list if the command failed.
2251
2252 Because backticks do not affect standard error, use shell file descriptor
2253 syntax (assuming the shell supports this) if you care to address this.
2254 To capture a command's STDERR and STDOUT together:
2255
2256     $output = `cmd 2>&1`;
2257
2258 To capture a command's STDOUT but discard its STDERR:
2259
2260     $output = `cmd 2>/dev/null`;
2261
2262 To capture a command's STDERR but discard its STDOUT (ordering is
2263 important here):
2264
2265     $output = `cmd 2>&1 1>/dev/null`;
2266
2267 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2268 but leave its STDOUT to come out the old STDERR:
2269
2270     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2271
2272 To read both a command's STDOUT and its STDERR separately, it's easiest
2273 to redirect them separately to files, and then read from those files
2274 when the program is done:
2275
2276     system("program args 1>program.stdout 2>program.stderr");
2277
2278 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2279 For example:
2280
2281     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2282     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2283     print STDOUT `sort`;
2284
2285 will print the sorted contents of the file named F<"stuff">.
2286
2287 Using single-quote as a delimiter protects the command from Perl's
2288 double-quote interpolation, passing it on to the shell instead:
2289
2290     $perl_info  = qx(ps $$);            # that's Perl's $$
2291     $shell_info = qx'ps $$';            # that's the new shell's $$
2292
2293 How that string gets evaluated is entirely subject to the command
2294 interpreter on your system.  On most platforms, you will have to protect
2295 shell metacharacters if you want them treated literally.  This is in
2296 practice difficult to do, as it's unclear how to escape which characters.
2297 See L<perlsec> for a clean and safe example of a manual C<fork()> and C<exec()>
2298 to emulate backticks safely.
2299
2300 On some platforms (notably DOS-like ones), the shell may not be
2301 capable of dealing with multiline commands, so putting newlines in
2302 the string may not get you what you want.  You may be able to evaluate
2303 multiple commands in a single line by separating them with the command
2304 separator character, if your shell supports that (for example, C<;> on
2305 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2306
2307 Perl will attempt to flush all files opened for
2308 output before starting the child process, but this may not be supported
2309 on some platforms (see L<perlport>).  To be safe, you may need to set
2310 C<$|> (C<$AUTOFLUSH> in C<L<English>>) or call the C<autoflush()> method of
2311 C<L<IO::Handle>> on any open handles.
2312
2313 Beware that some command shells may place restrictions on the length
2314 of the command line.  You must ensure your strings don't exceed this
2315 limit after any necessary interpolations.  See the platform-specific
2316 release notes for more details about your particular environment.
2317
2318 Using this operator can lead to programs that are difficult to port,
2319 because the shell commands called vary between systems, and may in
2320 fact not be present at all.  As one example, the C<type> command under
2321 the POSIX shell is very different from the C<type> command under DOS.
2322 That doesn't mean you should go out of your way to avoid backticks
2323 when they're the right way to get something done.  Perl was made to be
2324 a glue language, and one of the things it glues together is commands.
2325 Just understand what you're getting yourself into.
2326
2327 Like C<system>, backticks put the child process exit code in C<$?>.
2328 If you'd like to manually inspect failure, you can check all possible
2329 failure modes by inspecting C<$?> like this:
2330
2331     if ($? == -1) {
2332         print "failed to execute: $!\n";
2333     }
2334     elsif ($? & 127) {
2335         printf "child died with signal %d, %s coredump\n",
2336             ($? & 127),  ($? & 128) ? 'with' : 'without';
2337     }
2338     else {
2339         printf "child exited with value %d\n", $? >> 8;
2340     }
2341
2342 Use the L<open> pragma to control the I/O layers used when reading the
2343 output of the command, for example:
2344
2345   use open IN => ":encoding(UTF-8)";
2346   my $x = `cmd-producing-utf-8`;
2347
2348 See L</"I/O Operators"> for more discussion.
2349
2350 =item C<qw/I<STRING>/>
2351 X<qw> X<quote, list> X<quote, words>
2352
2353 Evaluates to a list of the words extracted out of I<STRING>, using embedded
2354 whitespace as the word delimiters.  It can be understood as being roughly
2355 equivalent to:
2356
2357     split(" ", q/STRING/);
2358
2359 the differences being that it only splits on ASCII whitespace,
2360 generates a real list at compile time, and
2361 in scalar context it returns the last element in the list.  So
2362 this expression:
2363
2364     qw(foo bar baz)
2365
2366 is semantically equivalent to the list:
2367
2368     "foo", "bar", "baz"
2369
2370 Some frequently seen examples:
2371
2372     use POSIX qw( setlocale localeconv )
2373     @EXPORT = qw( foo bar baz );
2374
2375 A common mistake is to try to separate the words with commas or to
2376 put comments into a multi-line C<qw>-string.  For this reason, the
2377 S<C<use warnings>> pragma and the B<-w> switch (that is, the C<$^W> variable)
2378 produces warnings if the I<STRING> contains the C<","> or the C<"#"> character.
2379
2380 =item C<tr/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2381 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2382
2383 =item C<y/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2384
2385 Transliterates all occurrences of the characters found in the search list
2386 with the corresponding character in the replacement list.  It returns
2387 the number of characters replaced or deleted.  If no string is
2388 specified via the C<=~> or C<!~> operator, the C<$_> string is transliterated.
2389
2390 If the C</r> (non-destructive) option is present, a new copy of the string
2391 is made and its characters transliterated, and this copy is returned no
2392 matter whether it was modified or not: the original string is always
2393 left unchanged.  The new copy is always a plain string, even if the input
2394 string is an object or a tied variable.
2395
2396 Unless the C</r> option is used, the string specified with C<=~> must be a
2397 scalar variable, an array element, a hash element, or an assignment to one
2398 of those; in other words, an lvalue.
2399
2400 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
2401 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
2402 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
2403 I<SEARCHLIST> is delimited by bracketing quotes, the I<REPLACEMENTLIST>
2404 must have its own pair of quotes, which may or may not be bracketing
2405 quotes; for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>.
2406
2407 Characters may be literals or any of the escape sequences accepted in
2408 double-quoted strings.  But there is no variable interpolation, so C<"$">
2409 and C<"@"> are treated as literals.  A hyphen at the beginning or end, or
2410 preceded by a backslash is considered a literal.  Escape sequence
2411 details are in L<the table near the beginning of this section|/Quote and
2412 Quote-like Operators>.
2413
2414 Note that C<tr> does B<not> do regular expression character classes such as
2415 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the C<L<tr(1)>>
2416 utility.  C<tr[a-z][A-Z]> will uppercase the 26 letters "a" through "z",
2417 but for case changing not confined to ASCII, use
2418 L<C<lc>|perlfunc/lc>, L<C<uc>|perlfunc/uc>,
2419 L<C<lcfirst>|perlfunc/lcfirst>, L<C<ucfirst>|perlfunc/ucfirst>
2420 (all documented in L<perlfunc>), or the
2421 L<substitution operator C<sE<sol>I<PATTERN>E<sol>I<REPLACEMENT>E<sol>>|/sE<sol>PATTERNE<sol>REPLACEMENTE<sol>msixpodualngcer>
2422 (with C<\U>, C<\u>, C<\L>, and C<\l> string-interpolation escapes in the
2423 I<REPLACEMENT> portion).
2424
2425 Most ranges are unportable between character sets, but certain ones
2426 signal Perl to do special handling to make them portable.  There are two
2427 classes of portable ranges.  The first are any subsets of the ranges
2428 C<A-Z>, C<a-z>, and C<0-9>, when expressed as literal characters.
2429
2430   tr/h-k/H-K/
2431
2432 capitalizes the letters C<"h">, C<"i">, C<"j">, and C<"k"> and nothing
2433 else, no matter what the platform's character set is.  In contrast, all
2434 of
2435
2436   tr/\x68-\x6B/\x48-\x4B/
2437   tr/h-\x6B/H-\x4B/
2438   tr/\x68-k/\x48-K/
2439
2440 do the same capitalizations as the previous example when run on ASCII
2441 platforms, but something completely different on EBCDIC ones.
2442
2443 The second class of portable ranges is invoked when one or both of the
2444 range's end points are expressed as C<\N{...}>
2445
2446  $string =~ tr/\N{U+20}-\N{U+7E}//d;
2447
2448 removes from C<$string> all the platform's characters which are
2449 equivalent to any of Unicode U+0020, U+0021, ... U+007D, U+007E.  This
2450 is a portable range, and has the same effect on every platform it is
2451 run on.  It turns out that in this example, these are the ASCII
2452 printable characters.  So after this is run, C<$string> has only
2453 controls and characters which have no ASCII equivalents.
2454
2455 But, even for portable ranges, it is not generally obvious what is
2456 included without having to look things up.  A sound principle is to use
2457 only ranges that begin from and end at either ASCII alphabetics of equal
2458 case (C<b-e>, C<B-E>), or digits (C<1-4>).  Anything else is unclear
2459 (and unportable unless C<\N{...}> is used).  If in doubt, spell out the
2460 character sets in full.
2461
2462 Options:
2463
2464     c   Complement the SEARCHLIST.
2465     d   Delete found but unreplaced characters.
2466     s   Squash duplicate replaced characters.
2467     r   Return the modified string and leave the original string
2468         untouched.
2469
2470 If the C</c> modifier is specified, the I<SEARCHLIST> character set
2471 is complemented.  If the C</d> modifier is specified, any characters
2472 specified by I<SEARCHLIST> not found in I<REPLACEMENTLIST> are deleted.
2473 (Note that this is slightly more flexible than the behavior of some
2474 B<tr> programs, which delete anything they find in the I<SEARCHLIST>,
2475 period.)  If the C</s> modifier is specified, sequences of characters
2476 that were transliterated to the same character are squashed down
2477 to a single instance of the character.
2478
2479 If the C</d> modifier is used, the I<REPLACEMENTLIST> is always interpreted
2480 exactly as specified.  Otherwise, if the I<REPLACEMENTLIST> is shorter
2481 than the I<SEARCHLIST>, the final character is replicated till it is long
2482 enough.  If the I<REPLACEMENTLIST> is empty, the I<SEARCHLIST> is replicated.
2483 This latter is useful for counting characters in a class or for
2484 squashing character sequences in a class.
2485
2486 Examples:
2487
2488     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2489
2490     $cnt = tr/*/*/;             # count the stars in $_
2491
2492     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2493
2494     $cnt = tr/0-9//;            # count the digits in $_
2495
2496     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2497
2498     ($HOST = $host) =~ tr/a-z/A-Z/;
2499      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2500
2501     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2502                   =~ s/:/ -p/r;
2503
2504     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2505
2506     @stripped = map tr/a-zA-Z/ /csr, @original;
2507                                 # /r with map
2508
2509     tr [\200-\377]
2510        [\000-\177];             # wickedly delete 8th bit
2511
2512 If multiple transliterations are given for a character, only the
2513 first one is used:
2514
2515     tr/AAA/XYZ/
2516
2517 will transliterate any A to X.
2518
2519 Because the transliteration table is built at compile time, neither
2520 the I<SEARCHLIST> nor the I<REPLACEMENTLIST> are subjected to double quote
2521 interpolation.  That means that if you want to use variables, you
2522 must use an C<eval()>:
2523
2524     eval "tr/$oldlist/$newlist/";
2525     die $@ if $@;
2526
2527     eval "tr/$oldlist/$newlist/, 1" or die $@;
2528
2529 =item C<< <<I<EOF> >>
2530 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2531
2532 A line-oriented form of quoting is based on the shell "here-document"
2533 syntax.  Following a C<< << >> you specify a string to terminate
2534 the quoted material, and all lines following the current line down to
2535 the terminating string are the value of the item.
2536
2537 Prefixing the terminating string with a C<~> specifies that you
2538 want to use L</Indented Here-docs> (see below).
2539
2540 The terminating string may be either an identifier (a word), or some
2541 quoted text.  An unquoted identifier works like double quotes.
2542 There may not be a space between the C<< << >> and the identifier,
2543 unless the identifier is explicitly quoted.  (If you put a space it
2544 will be treated as a null identifier, which is valid, and matches the
2545 first empty line.)  The terminating string must appear by itself
2546 (unquoted and with no surrounding whitespace) on the terminating line.
2547
2548 If the terminating string is quoted, the type of quotes used determine
2549 the treatment of the text.
2550
2551 =over 4
2552
2553 =item Double Quotes
2554
2555 Double quotes indicate that the text will be interpolated using exactly
2556 the same rules as normal double quoted strings.
2557
2558        print <<EOF;
2559     The price is $Price.
2560     EOF
2561
2562        print << "EOF"; # same as above
2563     The price is $Price.
2564     EOF
2565
2566
2567 =item Single Quotes
2568
2569 Single quotes indicate the text is to be treated literally with no
2570 interpolation of its content.  This is similar to single quoted
2571 strings except that backslashes have no special meaning, with C<\\>
2572 being treated as two backslashes and not one as they would in every
2573 other quoting construct.
2574
2575 Just as in the shell, a backslashed bareword following the C<<< << >>>
2576 means the same thing as a single-quoted string does:
2577
2578         $cost = <<'VISTA';  # hasta la ...
2579     That'll be $10 please, ma'am.
2580     VISTA
2581
2582         $cost = <<\VISTA;   # Same thing!
2583     That'll be $10 please, ma'am.
2584     VISTA
2585
2586 This is the only form of quoting in perl where there is no need
2587 to worry about escaping content, something that code generators
2588 can and do make good use of.
2589
2590 =item Backticks
2591
2592 The content of the here doc is treated just as it would be if the
2593 string were embedded in backticks.  Thus the content is interpolated
2594 as though it were double quoted and then executed via the shell, with
2595 the results of the execution returned.
2596
2597        print << `EOC`; # execute command and get results
2598     echo hi there
2599     EOC
2600
2601 =back
2602
2603 =over 4
2604
2605 =item Indented Here-docs
2606
2607 The here-doc modifier C<~> allows you to indent your here-docs to make
2608 the code more readable:
2609
2610     if ($some_var) {
2611       print <<~EOF;
2612         This is a here-doc
2613         EOF
2614     }
2615
2616 This will print...
2617
2618     This is a here-doc
2619
2620 ...with no leading whitespace.
2621
2622 The delimiter is used to determine the B<exact> whitespace to
2623 remove from the beginning of each line.  All lines B<must> have
2624 at least the same starting whitespace (except lines only
2625 containing a newline) or perl will croak.  Tabs and spaces can
2626 be mixed, but are matched exactly.  One tab will not be equal to
2627 8 spaces!
2628
2629 Additional beginning whitespace (beyond what preceded the
2630 delimiter) will be preserved:
2631
2632     print <<~EOF;
2633       This text is not indented
2634         This text is indented with two spaces
2635                 This text is indented with two tabs
2636       EOF
2637
2638 Finally, the modifier may be used with all of the forms
2639 mentioned above:
2640
2641     <<~\EOF;
2642     <<~'EOF'
2643     <<~"EOF"
2644     <<~`EOF`
2645
2646 And whitespace may be used between the C<~> and quoted delimiters:
2647
2648     <<~ 'EOF'; # ... "EOF", `EOF`
2649
2650 =back
2651
2652 It is possible to stack multiple here-docs in a row:
2653
2654        print <<"foo", <<"bar"; # you can stack them
2655     I said foo.
2656     foo
2657     I said bar.
2658     bar
2659
2660        myfunc(<< "THIS", 23, <<'THAT');
2661     Here's a line
2662     or two.
2663     THIS
2664     and here's another.
2665     THAT
2666
2667 Just don't forget that you have to put a semicolon on the end
2668 to finish the statement, as Perl doesn't know you're not going to
2669 try to do this:
2670
2671        print <<ABC
2672     179231
2673     ABC
2674        + 20;
2675
2676 If you want to remove the line terminator from your here-docs,
2677 use C<chomp()>.
2678
2679     chomp($string = <<'END');
2680     This is a string.
2681     END
2682
2683 If you want your here-docs to be indented with the rest of the code,
2684 use the C<<< <<~FOO >>> construct described under L</Indented Here-docs>:
2685
2686     $quote = <<~'FINIS';
2687        The Road goes ever on and on,
2688        down from the door where it began.
2689        FINIS
2690
2691 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2692 the quoted material must still come on the line following the
2693 C<<< <<FOO >>> marker, which means it may be inside the delimited
2694 construct:
2695
2696     s/this/<<E . 'that'
2697     the other
2698     E
2699      . 'more '/eg;
2700
2701 It works this way as of Perl 5.18.  Historically, it was inconsistent, and
2702 you would have to write
2703
2704     s/this/<<E . 'that'
2705      . 'more '/eg;
2706     the other
2707     E
2708
2709 outside of string evals.
2710
2711 Additionally, quoting rules for the end-of-string identifier are
2712 unrelated to Perl's quoting rules.  C<q()>, C<qq()>, and the like are not
2713 supported in place of C<''> and C<"">, and the only interpolation is for
2714 backslashing the quoting character:
2715
2716     print << "abc\"def";
2717     testing...
2718     abc"def
2719
2720 Finally, quoted strings cannot span multiple lines.  The general rule is
2721 that the identifier must be a string literal.  Stick with that, and you
2722 should be safe.
2723
2724 =back
2725
2726 =head2 Gory details of parsing quoted constructs
2727 X<quote, gory details>
2728
2729 When presented with something that might have several different
2730 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2731 principle to pick the most probable interpretation.  This strategy
2732 is so successful that Perl programmers often do not suspect the
2733 ambivalence of what they write.  But from time to time, Perl's
2734 notions differ substantially from what the author honestly meant.
2735
2736 This section hopes to clarify how Perl handles quoted constructs.
2737 Although the most common reason to learn this is to unravel labyrinthine
2738 regular expressions, because the initial steps of parsing are the
2739 same for all quoting operators, they are all discussed together.
2740
2741 The most important Perl parsing rule is the first one discussed
2742 below: when processing a quoted construct, Perl first finds the end
2743 of that construct, then interprets its contents.  If you understand
2744 this rule, you may skip the rest of this section on the first
2745 reading.  The other rules are likely to contradict the user's
2746 expectations much less frequently than this first one.
2747
2748 Some passes discussed below are performed concurrently, but because
2749 their results are the same, we consider them individually.  For different
2750 quoting constructs, Perl performs different numbers of passes, from
2751 one to four, but these passes are always performed in the same order.
2752
2753 =over 4
2754
2755 =item Finding the end
2756
2757 The first pass is finding the end of the quoted construct.  This results
2758 in saving to a safe location a copy of the text (between the starting
2759 and ending delimiters), normalized as necessary to avoid needing to know
2760 what the original delimiters were.
2761
2762 If the construct is a here-doc, the ending delimiter is a line
2763 that has a terminating string as the content.  Therefore C<<<EOF> is
2764 terminated by C<EOF> immediately followed by C<"\n"> and starting
2765 from the first column of the terminating line.
2766 When searching for the terminating line of a here-doc, nothing
2767 is skipped.  In other words, lines after the here-doc syntax
2768 are compared with the terminating string line by line.
2769
2770 For the constructs except here-docs, single characters are used as starting
2771 and ending delimiters.  If the starting delimiter is an opening punctuation
2772 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2773 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2774 If the starting delimiter is an unpaired character like C</> or a closing
2775 punctuation, the ending delimiter is the same as the starting delimiter.
2776 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2777 both C<qq[]> and C<qq]]> constructs.
2778
2779 When searching for single-character delimiters, escaped delimiters
2780 and C<\\> are skipped.  For example, while searching for terminating C</>,
2781 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2782 bracketing, nested pairs are also skipped.  For example, while searching
2783 for a closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2784 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2785 However, when backslashes are used as the delimiters (like C<qq\\> and
2786 C<tr\\\>), nothing is skipped.
2787 During the search for the end, backslashes that escape delimiters or
2788 other backslashes are removed (exactly speaking, they are not copied to the
2789 safe location).
2790
2791 For constructs with three-part delimiters (C<s///>, C<y///>, and
2792 C<tr///>), the search is repeated once more.
2793 If the first delimiter is not an opening punctuation, the three delimiters must
2794 be the same, such as C<s!!!> and C<tr)))>,
2795 in which case the second delimiter
2796 terminates the left part and starts the right part at once.
2797 If the left part is delimited by bracketing punctuation (that is C<()>,
2798 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2799 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2800 and comments are allowed between the two parts, although the comment must follow
2801 at least one whitespace character; otherwise a character expected as the
2802 start of the comment may be regarded as the starting delimiter of the right part.
2803
2804 During this search no attention is paid to the semantics of the construct.
2805 Thus:
2806
2807     "$hash{"$foo/$bar"}"
2808
2809 or:
2810
2811     m/
2812       bar       # NOT a comment, this slash / terminated m//!
2813      /x
2814
2815 do not form legal quoted expressions.   The quoted part ends on the
2816 first C<"> and C</>, and the rest happens to be a syntax error.
2817 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2818 the example above is not C<m//x>, but rather C<m//> with no C</x>
2819 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2820
2821 Also no attention is paid to C<\c\> (multichar control char syntax) during
2822 this search.  Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2823 of C<\/>, and the following C</> is not recognized as a delimiter.
2824 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2825
2826 =item Interpolation
2827 X<interpolation>
2828
2829 The next step is interpolation in the text obtained, which is now
2830 delimiter-independent.  There are multiple cases.
2831
2832 =over 4
2833
2834 =item C<<<'EOF'>
2835
2836 No interpolation is performed.
2837 Note that the combination C<\\> is left intact, since escaped delimiters
2838 are not available for here-docs.
2839
2840 =item  C<m''>, the pattern of C<s'''>
2841
2842 No interpolation is performed at this stage.
2843 Any backslashed sequences including C<\\> are treated at the stage
2844 to L</"parsing regular expressions">.
2845
2846 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2847
2848 The only interpolation is removal of C<\> from pairs of C<\\>.
2849 Therefore C<"-"> in C<tr'''> and C<y'''> is treated literally
2850 as a hyphen and no character range is available.
2851 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2852
2853 =item C<tr///>, C<y///>
2854
2855 No variable interpolation occurs.  String modifying combinations for
2856 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2857 The other escape sequences such as C<\200> and C<\t> and backslashed
2858 characters such as C<\\> and C<\-> are converted to appropriate literals.
2859 The character C<"-"> is treated specially and therefore C<\-> is treated
2860 as a literal C<"-">.
2861
2862 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2863
2864 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
2865 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2866 is converted to S<C<$foo . (quotemeta("baz" . $bar))>> internally.
2867 The other escape sequences such as C<\200> and C<\t> and backslashed
2868 characters such as C<\\> and C<\-> are replaced with appropriate
2869 expansions.
2870
2871 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2872 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2873 no C<\E> inside.  Instead, it has C<\Q>, C<\\>, and C<E>, so the
2874 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2875 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2876 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2877 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2878
2879   $str = '\t';
2880   return "\Q$str";
2881
2882 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2883
2884 Interpolated scalars and arrays are converted internally to the C<join> and
2885 C<"."> catenation operations.  Thus, S<C<"$foo XXX '@arr'">> becomes:
2886
2887   $foo . " XXX '" . (join $", @arr) . "'";
2888
2889 All operations above are performed simultaneously, left to right.
2890
2891 Because the result of S<C<"\Q I<STRING> \E">> has all metacharacters
2892 quoted, there is no way to insert a literal C<$> or C<@> inside a
2893 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to become
2894 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2895 scalar.
2896
2897 Note also that the interpolation code needs to make a decision on
2898 where the interpolated scalar ends.  For instance, whether
2899 S<C<< "a $x -> {c}" >>> really means:
2900
2901   "a " . $x . " -> {c}";
2902
2903 or:
2904
2905   "a " . $x -> {c};
2906
2907 Most of the time, the longest possible text that does not include
2908 spaces between components and which contains matching braces or
2909 brackets.  because the outcome may be determined by voting based
2910 on heuristic estimators, the result is not strictly predictable.
2911 Fortunately, it's usually correct for ambiguous cases.
2912
2913 =item the replacement of C<s///>
2914
2915 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
2916 happens as with C<qq//> constructs.
2917
2918 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2919 the replacement text of C<s///>, in order to correct the incorrigible
2920 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2921 is emitted if the S<C<use warnings>> pragma or the B<-w> command-line flag
2922 (that is, the C<$^W> variable) was set.
2923
2924 =item C<RE> in C<m?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2925
2926 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
2927 and interpolation happens (almost) as with C<qq//> constructs.
2928
2929 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2930 form for the regex compiler.  (This is because, as mentioned below, the regex
2931 compilation may be done at execution time, and C<\N{...}> is a compile-time
2932 construct.)
2933
2934 However any other combinations of C<\> followed by a character
2935 are not substituted but only skipped, in order to parse them
2936 as regular expressions at the following step.
2937 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2938 treated as an array symbol (for example C<@foo>),
2939 even though the same text in C<qq//> gives interpolation of C<\c@>.
2940
2941 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
2942 back to the perl parser, in a similar way that an interpolated array
2943 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
2944
2945 Moreover, inside C<(?{BLOCK})>, S<C<(?# comment )>>, and
2946 a C<#>-comment in a C</x>-regular expression, no processing is
2947 performed whatsoever.  This is the first step at which the presence
2948 of the C</x> modifier is relevant.
2949
2950 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2951 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2952 voted (by several different estimators) to be either an array element
2953 or C<$var> followed by an RE alternative.  This is where the notation
2954 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2955 array element C<-9>, not as a regular expression from the variable
2956 C<$arr> followed by a digit, which would be the interpretation of
2957 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2958 the result is not predictable.
2959
2960 The lack of processing of C<\\> creates specific restrictions on
2961 the post-processed text.  If the delimiter is C</>, one cannot get
2962 the combination C<\/> into the result of this step.  C</> will
2963 finish the regular expression, C<\/> will be stripped to C</> on
2964 the previous step, and C<\\/> will be left as is.  Because C</> is
2965 equivalent to C<\/> inside a regular expression, this does not
2966 matter unless the delimiter happens to be character special to the
2967 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<m?foo?>; or an
2968 alphanumeric char, as in:
2969
2970   m m ^ a \s* b mmx;
2971
2972 In the RE above, which is intentionally obfuscated for illustration, the
2973 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2974 RE is the same as for S<C<m/ ^ a \s* b /mx>>.  There's more than one
2975 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2976 non-whitespace choices.
2977
2978 =back
2979
2980 This step is the last one for all constructs except regular expressions,
2981 which are processed further.
2982
2983 =item parsing regular expressions
2984 X<regexp, parse>
2985
2986 Previous steps were performed during the compilation of Perl code,
2987 but this one happens at run time, although it may be optimized to
2988 be calculated at compile time if appropriate.  After preprocessing
2989 described above, and possibly after evaluation if concatenation,
2990 joining, casing translation, or metaquoting are involved, the
2991 resulting I<string> is passed to the RE engine for compilation.
2992
2993 Whatever happens in the RE engine might be better discussed in L<perlre>,
2994 but for the sake of continuity, we shall do so here.
2995
2996 This is another step where the presence of the C</x> modifier is
2997 relevant.  The RE engine scans the string from left to right and
2998 converts it into a finite automaton.
2999
3000 Backslashed characters are either replaced with corresponding
3001 literal strings (as with C<\{>), or else they generate special nodes
3002 in the finite automaton (as with C<\b>).  Characters special to the
3003 RE engine (such as C<|>) generate corresponding nodes or groups of
3004 nodes.  C<(?#...)> comments are ignored.  All the rest is either
3005 converted to literal strings to match, or else is ignored (as is
3006 whitespace and C<#>-style comments if C</x> is present).
3007
3008 Parsing of the bracketed character class construct, C<[...]>, is
3009 rather different than the rule used for the rest of the pattern.
3010 The terminator of this construct is found using the same rules as
3011 for finding the terminator of a C<{}>-delimited construct, the only
3012 exception being that C<]> immediately following C<[> is treated as
3013 though preceded by a backslash.
3014
3015 The terminator of runtime C<(?{...})> is found by temporarily switching
3016 control to the perl parser, which should stop at the point where the
3017 logically balancing terminating C<}> is found.
3018
3019 It is possible to inspect both the string given to RE engine and the
3020 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
3021 in the S<C<use L<re>>> pragma, as well as Perl's B<-Dr> command-line
3022 switch documented in L<perlrun/"Command Switches">.
3023
3024 =item Optimization of regular expressions
3025 X<regexp, optimization>
3026
3027 This step is listed for completeness only.  Since it does not change
3028 semantics, details of this step are not documented and are subject
3029 to change without notice.  This step is performed over the finite
3030 automaton that was generated during the previous pass.
3031
3032 It is at this stage that C<split()> silently optimizes C</^/> to
3033 mean C</^/m>.
3034
3035 =back
3036
3037 =head2 I/O Operators
3038 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
3039 X<< <> >> X<< <<>> >> X<@ARGV>
3040
3041 There are several I/O operators you should know about.
3042
3043 A string enclosed by backticks (grave accents) first undergoes
3044 double-quote interpolation.  It is then interpreted as an external
3045 command, and the output of that command is the value of the
3046 backtick string, like in a shell.  In scalar context, a single string
3047 consisting of all output is returned.  In list context, a list of
3048 values is returned, one per line of output.  (You can set C<$/> to use
3049 a different line terminator.)  The command is executed each time the
3050 pseudo-literal is evaluated.  The status value of the command is
3051 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
3052 Unlike in B<csh>, no translation is done on the return data--newlines
3053 remain newlines.  Unlike in any of the shells, single quotes do not
3054 hide variable names in the command from interpretation.  To pass a
3055 literal dollar-sign through to the shell you need to hide it with a
3056 backslash.  The generalized form of backticks is C<qx//>.  (Because
3057 backticks always undergo shell expansion as well, see L<perlsec> for
3058 security concerns.)
3059 X<qx> X<`> X<``> X<backtick> X<glob>
3060
3061 In scalar context, evaluating a filehandle in angle brackets yields
3062 the next line from that file (the newline, if any, included), or
3063 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
3064 (sometimes known as file-slurp mode) and the file is empty, it
3065 returns C<''> the first time, followed by C<undef> subsequently.
3066
3067 Ordinarily you must assign the returned value to a variable, but
3068 there is one situation where an automatic assignment happens.  If
3069 and only if the input symbol is the only thing inside the conditional
3070 of a C<while> statement (even if disguised as a C<for(;;)> loop),
3071 the value is automatically assigned to the global variable C<$_>,
3072 destroying whatever was there previously.  (This may seem like an
3073 odd thing to you, but you'll use the construct in almost every Perl
3074 script you write.)  The C<$_> variable is not implicitly localized.
3075 You'll have to put a S<C<local $_;>> before the loop if you want that
3076 to happen.
3077
3078 The following lines are equivalent:
3079
3080     while (defined($_ = <STDIN>)) { print; }
3081     while ($_ = <STDIN>) { print; }
3082     while (<STDIN>) { print; }
3083     for (;<STDIN>;) { print; }
3084     print while defined($_ = <STDIN>);
3085     print while ($_ = <STDIN>);
3086     print while <STDIN>;
3087
3088 This also behaves similarly, but assigns to a lexical variable
3089 instead of to C<$_>:
3090
3091     while (my $line = <STDIN>) { print $line }
3092
3093 In these loop constructs, the assigned value (whether assignment
3094 is automatic or explicit) is then tested to see whether it is
3095 defined.  The defined test avoids problems where the line has a string
3096 value that would be treated as false by Perl; for example a "" or
3097 a C<"0"> with no trailing newline.  If you really mean for such values
3098 to terminate the loop, they should be tested for explicitly:
3099
3100     while (($_ = <STDIN>) ne '0') { ... }
3101     while (<STDIN>) { last unless $_; ... }
3102
3103 In other boolean contexts, C<< <I<FILEHANDLE>> >> without an
3104 explicit C<defined> test or comparison elicits a warning if the
3105 S<C<use warnings>> pragma or the B<-w>
3106 command-line switch (the C<$^W> variable) is in effect.
3107
3108 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
3109 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
3110 in packages, where they would be interpreted as local identifiers
3111 rather than global.)  Additional filehandles may be created with
3112 the C<open()> function, amongst others.  See L<perlopentut> and
3113 L<perlfunc/open> for details on this.
3114 X<stdin> X<stdout> X<sterr>
3115
3116 If a C<< <I<FILEHANDLE>> >> is used in a context that is looking for
3117 a list, a list comprising all input lines is returned, one line per
3118 list element.  It's easy to grow to a rather large data space this
3119 way, so use with care.
3120
3121 C<< <I<FILEHANDLE>> >>  may also be spelled C<readline(*I<FILEHANDLE>)>.
3122 See L<perlfunc/readline>.
3123
3124 The null filehandle C<< <> >> is special: it can be used to emulate the
3125 behavior of B<sed> and B<awk>, and any other Unix filter program
3126 that takes a list of filenames, doing the same to each line
3127 of input from all of them.  Input from C<< <> >> comes either from
3128 standard input, or from each file listed on the command line.  Here's
3129 how it works: the first time C<< <> >> is evaluated, the C<@ARGV> array is
3130 checked, and if it is empty, C<$ARGV[0]> is set to C<"-">, which when opened
3131 gives you standard input.  The C<@ARGV> array is then processed as a list
3132 of filenames.  The loop
3133
3134     while (<>) {
3135         ...                     # code for each line
3136     }
3137
3138 is equivalent to the following Perl-like pseudo code:
3139
3140     unshift(@ARGV, '-') unless @ARGV;
3141     while ($ARGV = shift) {
3142         open(ARGV, $ARGV);
3143         while (<ARGV>) {
3144             ...         # code for each line
3145         }
3146     }
3147
3148 except that it isn't so cumbersome to say, and will actually work.
3149 It really does shift the C<@ARGV> array and put the current filename
3150 into the C<$ARGV> variable.  It also uses filehandle I<ARGV>
3151 internally.  C<< <> >> is just a synonym for C<< <ARGV> >>, which
3152 is magical.  (The pseudo code above doesn't work because it treats
3153 C<< <ARGV> >> as non-magical.)
3154
3155 Since the null filehandle uses the two argument form of L<perlfunc/open>
3156 it interprets special characters, so if you have a script like this:
3157
3158     while (<>) {
3159         print;
3160     }
3161
3162 and call it with S<C<perl dangerous.pl 'rm -rfv *|'>>, it actually opens a
3163 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
3164 If you want all items in C<@ARGV> to be interpreted as file names, you
3165 can use the module C<ARGV::readonly> from CPAN, or use the double bracket:
3166
3167     while (<<>>) {
3168         print;
3169     }
3170
3171 Using double angle brackets inside of a while causes the open to use the
3172 three argument form (with the second argument being C<< < >>), so all
3173 arguments in C<ARGV> are treated as literal filenames (including C<"-">).
3174 (Note that for convenience, if you use C<< <<>> >> and if C<@ARGV> is
3175 empty, it will still read from the standard input.)
3176
3177 You can modify C<@ARGV> before the first C<< <> >> as long as the array ends up
3178 containing the list of filenames you really want.  Line numbers (C<$.>)
3179 continue as though the input were one big happy file.  See the example
3180 in L<perlfunc/eof> for how to reset line numbers on each file.
3181
3182 If you want to set C<@ARGV> to your own list of files, go right ahead.
3183 This sets C<@ARGV> to all plain text files if no C<@ARGV> was given:
3184
3185     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
3186
3187 You can even set them to pipe commands.  For example, this automatically
3188 filters compressed arguments through B<gzip>:
3189
3190     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
3191
3192 If you want to pass switches into your script, you can use one of the
3193 C<Getopts> modules or put a loop on the front like this:
3194
3195     while ($_ = $ARGV[0], /^-/) {
3196         shift;
3197         last if /^--$/;
3198         if (/^-D(.*)/) { $debug = $1 }
3199         if (/^-v/)     { $verbose++  }
3200         # ...           # other switches
3201     }
3202
3203     while (<>) {
3204         # ...           # code for each line
3205     }
3206
3207 The C<< <> >> symbol will return C<undef> for end-of-file only once.
3208 If you call it again after this, it will assume you are processing another
3209 C<@ARGV> list, and if you haven't set C<@ARGV>, will read input from STDIN.
3210
3211 If what the angle brackets contain is a simple scalar variable (for example,
3212 C<$foo>), then that variable contains the name of the
3213 filehandle to input from, or its typeglob, or a reference to the
3214 same.  For example:
3215
3216     $fh = \*STDIN;
3217     $line = <$fh>;
3218
3219 If what's within the angle brackets is neither a filehandle nor a simple
3220 scalar variable containing a filehandle name, typeglob, or typeglob
3221 reference, it is interpreted as a filename pattern to be globbed, and
3222 either a list of filenames or the next filename in the list is returned,
3223 depending on context.  This distinction is determined on syntactic
3224 grounds alone.  That means C<< <$x> >> is always a C<readline()> from
3225 an indirect handle, but C<< <$hash{key}> >> is always a C<glob()>.
3226 That's because C<$x> is a simple scalar variable, but C<$hash{key}> is
3227 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
3228 is treated as C<glob("$x ")>, not C<readline($x)>.
3229
3230 One level of double-quote interpretation is done first, but you can't
3231 say C<< <$foo> >> because that's an indirect filehandle as explained
3232 in the previous paragraph.  (In older versions of Perl, programmers
3233 would insert curly brackets to force interpretation as a filename glob:
3234 C<< <${foo}> >>.  These days, it's considered cleaner to call the
3235 internal function directly as C<glob($foo)>, which is probably the right
3236 way to have done it in the first place.)  For example:
3237
3238     while (<*.c>) {
3239         chmod 0644, $_;
3240     }
3241
3242 is roughly equivalent to:
3243
3244     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
3245     while (<FOO>) {
3246         chomp;
3247         chmod 0644, $_;
3248     }
3249
3250 except that the globbing is actually done internally using the standard
3251 C<L<File::Glob>> extension.  Of course, the shortest way to do the above is:
3252
3253     chmod 0644, <*.c>;
3254
3255 A (file)glob evaluates its (embedded) argument only when it is
3256 starting a new list.  All values must be read before it will start
3257 over.  In list context, this isn't important because you automatically
3258 get them all anyway.  However, in scalar context the operator returns
3259 the next value each time it's called, or C<undef> when the list has
3260 run out.  As with filehandle reads, an automatic C<defined> is
3261 generated when the glob occurs in the test part of a C<while>,
3262 because legal glob returns (for example,
3263 a file called F<0>) would otherwise
3264 terminate the loop.  Again, C<undef> is returned only once.  So if
3265 you're expecting a single value from a glob, it is much better to
3266 say
3267
3268     ($file) = <blurch*>;
3269
3270 than
3271
3272     $file = <blurch*>;
3273
3274 because the latter will alternate between returning a filename and
3275 returning false.
3276
3277 If you're trying to do variable interpolation, it's definitely better
3278 to use the C<glob()> function, because the older notation can cause people
3279 to become confused with the indirect filehandle notation.
3280
3281     @files = glob("$dir/*.[ch]");
3282     @files = glob($files[$i]);
3283
3284 =head2 Constant Folding
3285 X<constant folding> X<folding>
3286
3287 Like C, Perl does a certain amount of expression evaluation at
3288 compile time whenever it determines that all arguments to an
3289 operator are static and have no side effects.  In particular, string
3290 concatenation happens at compile time between literals that don't do
3291 variable substitution.  Backslash interpolation also happens at
3292 compile time.  You can say
3293
3294       'Now is the time for all'
3295     . "\n"
3296     .  'good men to come to.'
3297
3298 and this all reduces to one string internally.  Likewise, if
3299 you say
3300
3301     foreach $file (@filenames) {
3302         if (-s $file > 5 + 100 * 2**16) {  }
3303     }
3304
3305 the compiler precomputes the number which that expression
3306 represents so that the interpreter won't have to.
3307
3308 =head2 No-ops
3309 X<no-op> X<nop>
3310
3311 Perl doesn't officially have a no-op operator, but the bare constants
3312 C<0> and C<1> are special-cased not to produce a warning in void
3313 context, so you can for example safely do
3314
3315     1 while foo();
3316
3317 =head2 Bitwise String Operators
3318 X<operator, bitwise, string> X<&.> X<|.> X<^.> X<~.>
3319
3320 Bitstrings of any size may be manipulated by the bitwise operators
3321 (C<~ | & ^>).
3322
3323 If the operands to a binary bitwise op are strings of different
3324 sizes, B<|> and B<^> ops act as though the shorter operand had
3325 additional zero bits on the right, while the B<&> op acts as though
3326 the longer operand were truncated to the length of the shorter.
3327 The granularity for such extension or truncation is one or more
3328 bytes.
3329
3330     # ASCII-based examples
3331     print "j p \n" ^ " a h";            # prints "JAPH\n"
3332     print "JA" | "  ph\n";              # prints "japh\n"
3333     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3334     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3335
3336 If you are intending to manipulate bitstrings, be certain that
3337 you're supplying bitstrings: If an operand is a number, that will imply
3338 a B<numeric> bitwise operation.  You may explicitly show which type of
3339 operation you intend by using C<""> or C<0+>, as in the examples below.
3340
3341     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3342     $foo = '150' |  105;        # yields 255
3343     $foo =  150  | '105';       # yields 255
3344     $foo = '150' | '105';       # yields string '155' (under ASCII)
3345
3346     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3347     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3348
3349 This somewhat unpredictable behavior can be avoided with the experimental
3350 "bitwise" feature, new in Perl 5.22.  You can enable it via S<C<use feature
3351 'bitwise'>>.  By default, it will warn unless the C<"experimental::bitwise">
3352 warnings category has been disabled.  (S<C<use experimental 'bitwise'>> will
3353 enable the feature and disable the warning.)  Under this feature, the four
3354 standard bitwise operators (C<~ | & ^>) are always numeric.  Adding a dot
3355 after each operator (C<~. |. &. ^.>) forces it to treat its operands as
3356 strings:
3357
3358     use experimental "bitwise";
3359     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3360     $foo = '150' |  105;        # yields 255
3361     $foo =  150  | '105';       # yields 255
3362     $foo = '150' | '105';       # yields 255
3363     $foo =  150  |. 105;        # yields string '155'
3364     $foo = '150' |. 105;        # yields string '155'
3365     $foo =  150  |.'105';       # yields string '155'
3366     $foo = '150' |.'105';       # yields string '155'
3367
3368     $baz = $foo &  $bar;        # both operands numeric
3369     $biz = $foo ^. $bar;        # both operands stringy
3370
3371 The assignment variants of these operators (C<&= |= ^= &.= |.= ^.=>)
3372 behave likewise under the feature.
3373
3374 It is a fatal error if an operand contains a character whose ordinal
3375 value is above 0xFF, and hence not expressible except in UTF-8.  The
3376 operation is performed on a non-UTF-8 copy for other operands encoded in
3377 UTF-8.  See L<perlunicode/Byte and Character Semantics>.
3378
3379 See L<perlfunc/vec> for information on how to manipulate individual bits
3380 in a bit vector.
3381
3382 =head2 Integer Arithmetic
3383 X<integer>
3384
3385 By default, Perl assumes that it must do most of its arithmetic in
3386 floating point.  But by saying
3387
3388     use integer;
3389
3390 you may tell the compiler to use integer operations
3391 (see L<integer> for a detailed explanation) from here to the end of
3392 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3393
3394     no integer;
3395
3396 which lasts until the end of that BLOCK.  Note that this doesn't
3397 mean everything is an integer, merely that Perl will use integer
3398 operations for arithmetic, comparison, and bitwise operators.  For
3399 example, even under S<C<use integer>>, if you take the C<sqrt(2)>, you'll
3400 still get C<1.4142135623731> or so.
3401
3402 Used on numbers, the bitwise operators (C<&> C<|> C<^> C<~> C<< << >>
3403 C<< >> >>) always produce integral results.  (But see also
3404 L</Bitwise String Operators>.)  However, S<C<use integer>> still has meaning for
3405 them.  By default, their results are interpreted as unsigned integers, but
3406 if S<C<use integer>> is in effect, their results are interpreted
3407 as signed integers.  For example, C<~0> usually evaluates to a large
3408 integral value.  However, S<C<use integer; ~0>> is C<-1> on two's-complement
3409 machines.
3410
3411 =head2 Floating-point Arithmetic
3412
3413 X<floating-point> X<floating point> X<float> X<real>
3414
3415 While S<C<use integer>> provides integer-only arithmetic, there is no
3416 analogous mechanism to provide automatic rounding or truncation to a
3417 certain number of decimal places.  For rounding to a certain number
3418 of digits, C<sprintf()> or C<printf()> is usually the easiest route.
3419 See L<perlfaq4>.
3420
3421 Floating-point numbers are only approximations to what a mathematician
3422 would call real numbers.  There are infinitely more reals than floats,
3423 so some corners must be cut.  For example:
3424
3425     printf "%.20g\n", 123456789123456789;
3426     #        produces 123456789123456784
3427
3428 Testing for exact floating-point equality or inequality is not a
3429 good idea.  Here's a (relatively expensive) work-around to compare
3430 whether two floating-point numbers are equal to a particular number of
3431 decimal places.  See Knuth, volume II, for a more robust treatment of
3432 this topic.
3433
3434     sub fp_equal {
3435         my ($X, $Y, $POINTS) = @_;
3436         my ($tX, $tY);
3437         $tX = sprintf("%.${POINTS}g", $X);
3438         $tY = sprintf("%.${POINTS}g", $Y);
3439         return $tX eq $tY;
3440     }
3441
3442 The POSIX module (part of the standard perl distribution) implements
3443 C<ceil()>, C<floor()>, and other mathematical and trigonometric functions.
3444 The C<L<Math::Complex>> module (part of the standard perl distribution)
3445 defines mathematical functions that work on both the reals and the
3446 imaginary numbers.  C<Math::Complex> is not as efficient as POSIX, but
3447 POSIX can't work with complex numbers.
3448
3449 Rounding in financial applications can have serious implications, and
3450 the rounding method used should be specified precisely.  In these
3451 cases, it probably pays not to trust whichever system rounding is
3452 being used by Perl, but to instead implement the rounding function you
3453 need yourself.
3454
3455 =head2 Bigger Numbers
3456 X<number, arbitrary precision>
3457
3458 The standard C<L<Math::BigInt>>, C<L<Math::BigRat>>, and
3459 C<L<Math::BigFloat>> modules,
3460 along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide
3461 variable-precision arithmetic and overloaded operators, although
3462 they're currently pretty slow.  At the cost of some space and
3463 considerable speed, they avoid the normal pitfalls associated with
3464 limited-precision representations.
3465
3466         use 5.010;
3467         use bigint;  # easy interface to Math::BigInt
3468         $x = 123456789123456789;
3469         say $x * $x;
3470     +15241578780673678515622620750190521
3471
3472 Or with rationals:
3473
3474         use 5.010;
3475         use bigrat;
3476         $x = 3/22;
3477         $y = 4/6;
3478         say "x/y is ", $x/$y;
3479         say "x*y is ", $x*$y;
3480         x/y is 9/44
3481         x*y is 1/11
3482
3483 Several modules let you calculate with unlimited or fixed precision
3484 (bound only by memory and CPU time).  There
3485 are also some non-standard modules that
3486 provide faster implementations via external C libraries.
3487
3488 Here is a short, but incomplete summary:
3489
3490   Math::String           treat string sequences like numbers
3491   Math::FixedPrecision   calculate with a fixed precision
3492   Math::Currency         for currency calculations
3493   Bit::Vector            manipulate bit vectors fast (uses C)
3494   Math::BigIntFast       Bit::Vector wrapper for big numbers
3495   Math::Pari             provides access to the Pari C library
3496   Math::Cephes           uses the external Cephes C library (no
3497                          big numbers)
3498   Math::Cephes::Fraction fractions via the Cephes library
3499   Math::GMP              another one using an external C library
3500   Math::GMPz             an alternative interface to libgmp's big ints
3501   Math::GMPq             an interface to libgmp's fraction numbers
3502   Math::GMPf             an interface to libgmp's floating point numbers
3503
3504 Choose wisely.
3505
3506 =cut