This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
39840fc8c7c6d07f98977c343754b56ae0da98dd
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  See below.
83
84 The C</x> modifier itself needs a little more explanation.  It tells
85 the regular expression parser to ignore most whitespace that is neither
86 backslashed nor within a character class.  You can use this to break up
87 your regular expression into (slightly) more readable parts.  The C<#>
88 character is also treated as a metacharacter introducing a comment,
89 just as in ordinary Perl code.  This also means that if you want real
90 whitespace or C<#> characters in the pattern (outside a character
91 class, where they are unaffected by C</x>), then you'll either have to
92 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
93 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
94 making Perl's regular expressions more readable.  Note that you have to
95 be careful not to include the pattern delimiter in the comment--perl has
96 no way of knowing you did not intend to close the pattern early.  See
97 the C-comment deletion code in L<perlop>.  Also note that anything inside
98 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
99 whether space interpretation within a single multi-character construct.  For
100 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
101 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
102 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
103 but can between the C<(> and C<?>.  Within any delimiters for such a
104 construct, allowed spaces are not affected by C</x>, and depend on the
105 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
106 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
107 in C<\p{...}>  there can be spaces that follow the Unicode rules, for which see
108 L<perluniprops/Properties accessible through \p{} and \P{}>.
109 X</x>
110
111 =head2 Regular Expressions
112
113 =head3 Metacharacters
114
115 The patterns used in Perl pattern matching evolved from those supplied in
116 the Version 8 regex routines.  (The routines are derived
117 (distantly) from Henry Spencer's freely redistributable reimplementation
118 of the V8 routines.)  See L<Version 8 Regular Expressions> for
119 details.
120
121 In particular the following metacharacters have their standard I<egrep>-ish
122 meanings:
123 X<metacharacter>
124 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
125
126
127     \        Quote the next metacharacter
128     ^        Match the beginning of the line
129     .        Match any character (except newline)
130     $        Match the end of the line (or before newline at the end)
131     |        Alternation
132     ()       Grouping
133     []       Bracketed Character class
134
135 By default, the "^" character is guaranteed to match only the
136 beginning of the string, the "$" character only the end (or before the
137 newline at the end), and Perl does certain optimizations with the
138 assumption that the string contains only one line.  Embedded newlines
139 will not be matched by "^" or "$".  You may, however, wish to treat a
140 string as a multi-line buffer, such that the "^" will match after any
141 newline within the string (except if the newline is the last character in
142 the string), and "$" will match before any newline.  At the
143 cost of a little more overhead, you can do this by using the /m modifier
144 on the pattern match operator.  (Older programs did this by setting C<$*>,
145 but this practice has been removed in perl 5.9.)
146 X<^> X<$> X</m>
147
148 To simplify multi-line substitutions, the "." character never matches a
149 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
150 the string is a single line--even if it isn't.
151 X<.> X</s>
152
153 =head3 Quantifiers
154
155 The following standard quantifiers are recognized:
156 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
157
158     *           Match 0 or more times
159     +           Match 1 or more times
160     ?           Match 1 or 0 times
161     {n}         Match exactly n times
162     {n,}        Match at least n times
163     {n,m}       Match at least n but not more than m times
164
165 (If a curly bracket occurs in any other context, it is treated
166 as a regular character.  In particular, the lower bound
167 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
168 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
169 to non-negative integral values less than a preset limit defined when perl is built.
170 This is usually 32766 on the most common platforms.  The actual limit can
171 be seen in the error message generated by code such as this:
172
173     $_ **= $_ , / {$_} / for 2 .. 42;
174
175 By default, a quantified subpattern is "greedy", that is, it will match as
176 many times as possible (given a particular starting location) while still
177 allowing the rest of the pattern to match.  If you want it to match the
178 minimum number of times possible, follow the quantifier with a "?".  Note
179 that the meanings don't change, just the "greediness":
180 X<metacharacter> X<greedy> X<greediness>
181 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
182
183     *?        Match 0 or more times, not greedily
184     +?        Match 1 or more times, not greedily
185     ??        Match 0 or 1 time, not greedily
186     {n}?      Match exactly n times, not greedily
187     {n,}?     Match at least n times, not greedily
188     {n,m}?    Match at least n but not more than m times, not greedily
189
190 By default, when a quantified subpattern does not allow the rest of the
191 overall pattern to match, Perl will backtrack. However, this behaviour is
192 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
193 as well.
194
195  *+     Match 0 or more times and give nothing back
196  ++     Match 1 or more times and give nothing back
197  ?+     Match 0 or 1 time and give nothing back
198  {n}+   Match exactly n times and give nothing back (redundant)
199  {n,}+  Match at least n times and give nothing back
200  {n,m}+ Match at least n but not more than m times and give nothing back
201
202 For instance,
203
204    'aaaa' =~ /a++a/
205
206 will never match, as the C<a++> will gobble up all the C<a>'s in the
207 string and won't leave any for the remaining part of the pattern. This
208 feature can be extremely useful to give perl hints about where it
209 shouldn't backtrack. For instance, the typical "match a double-quoted
210 string" problem can be most efficiently performed when written as:
211
212    /"(?:[^"\\]++|\\.)*+"/
213
214 as we know that if the final quote does not match, backtracking will not
215 help. See the independent subexpression C<< (?>...) >> for more details;
216 possessive quantifiers are just syntactic sugar for that construct. For
217 instance the above example could also be written as follows:
218
219    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
220
221 =head3 Escape sequences
222
223 Because patterns are processed as double quoted strings, the following
224 also work:
225
226  \t          tab                   (HT, TAB)
227  \n          newline               (LF, NL)
228  \r          return                (CR)
229  \f          form feed             (FF)
230  \a          alarm (bell)          (BEL)
231  \e          escape (think troff)  (ESC)
232  \cK         control char          (example: VT)
233  \x{}, \x00  character whose ordinal is the given hexadecimal number
234  \N{name}    named Unicode character or character sequence
235  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
236  \o{}, \000  character whose ordinal is the given octal number
237  \l          lowercase next char (think vi)
238  \u          uppercase next char (think vi)
239  \L          lowercase till \E (think vi)
240  \U          uppercase till \E (think vi)
241  \Q          quote (disable) pattern metacharacters till \E
242  \E          end either case modification or quoted section, think vi
243
244 Details are in L<perlop/Quote and Quote-like Operators>.
245
246 =head3 Character Classes and other Special Escapes
247
248 In addition, Perl defines the following:
249 X<\g> X<\k> X<\K> X<backreference>
250
251  Sequence   Note    Description
252   [...]     [1]  Match a character according to the rules of the
253                    bracketed character class defined by the "...".
254                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
255   [[:...:]] [2]  Match a character according to the rules of the POSIX
256                    character class "..." within the outer bracketed
257                    character class.  Example: [[:upper:]] matches any
258                    uppercase character.
259   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
260                    other connector punctuation chars plus Unicode
261                    marks
262   \W        [3]  Match a non-"word" character
263   \s        [3]  Match a whitespace character
264   \S        [3]  Match a non-whitespace character
265   \d        [3]  Match a decimal digit character
266   \D        [3]  Match a non-digit character
267   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
268   \PP       [3]  Match non-P
269   \X        [4]  Match Unicode "eXtended grapheme cluster"
270   \C             Match a single C-language char (octet) even if that is
271                    part of a larger UTF-8 character.  Thus it breaks up
272                    characters into their UTF-8 bytes, so you may end up
273                    with malformed pieces of UTF-8.  Unsupported in
274                    lookbehind.
275   \1        [5]  Backreference to a specific capture group or buffer.
276                    '1' may actually be any positive integer.
277   \g1       [5]  Backreference to a specific or previous group,
278   \g{-1}    [5]  The number may be negative indicating a relative
279                    previous group and may optionally be wrapped in
280                    curly brackets for safer parsing.
281   \g{name}  [5]  Named backreference
282   \k<name>  [5]  Named backreference
283   \K        [6]  Keep the stuff left of the \K, don't include it in $&
284   \N        [7]  Any character but \n (experimental).  Not affected by
285                    /s modifier
286   \v        [3]  Vertical whitespace
287   \V        [3]  Not vertical whitespace
288   \h        [3]  Horizontal whitespace
289   \H        [3]  Not horizontal whitespace
290   \R        [4]  Linebreak
291
292 =over 4
293
294 =item [1]
295
296 See L<perlrecharclass/Bracketed Character Classes> for details.
297
298 =item [2]
299
300 See L<perlrecharclass/POSIX Character Classes> for details.
301
302 =item [3]
303
304 See L<perlrecharclass/Backslash sequences> for details.
305
306 =item [4]
307
308 See L<perlrebackslash/Misc> for details.
309
310 =item [5]
311
312 See L</Capture groups> below for details.
313
314 =item [6]
315
316 See L</Extended Patterns> below for details.
317
318 =item [7]
319
320 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
321 character or character sequence whose name is C<NAME>; and similarly
322 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
323 code point is I<hex>.  Otherwise it matches any character but C<\n>.
324
325 =back
326
327 =head3 Assertions
328
329 Perl defines the following zero-width assertions:
330 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
331 X<regexp, zero-width assertion>
332 X<regular expression, zero-width assertion>
333 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
334
335     \b  Match a word boundary
336     \B  Match except at a word boundary
337     \A  Match only at beginning of string
338     \Z  Match only at end of string, or before newline at the end
339     \z  Match only at end of string
340     \G  Match only at pos() (e.g. at the end-of-match position
341         of prior m//g)
342
343 A word boundary (C<\b>) is a spot between two characters
344 that has a C<\w> on one side of it and a C<\W> on the other side
345 of it (in either order), counting the imaginary characters off the
346 beginning and end of the string as matching a C<\W>.  (Within
347 character classes C<\b> represents backspace rather than a word
348 boundary, just as it normally does in any double-quoted string.)
349 The C<\A> and C<\Z> are just like "^" and "$", except that they
350 won't match multiple times when the C</m> modifier is used, while
351 "^" and "$" will match at every internal line boundary.  To match
352 the actual end of the string and not ignore an optional trailing
353 newline, use C<\z>.
354 X<\b> X<\A> X<\Z> X<\z> X</m>
355
356 The C<\G> assertion can be used to chain global matches (using
357 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
358 It is also useful when writing C<lex>-like scanners, when you have
359 several patterns that you want to match against consequent substrings
360 of your string, see the previous reference.  The actual location
361 where C<\G> will match can also be influenced by using C<pos()> as
362 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
363 matches is modified somewhat, in that contents to the left of C<\G> is
364 not counted when determining the length of the match. Thus the following
365 will not match forever:
366 X<\G>
367
368      my $string = 'ABC';
369      pos($string) = 1;
370      while ($string =~ /(.\G)/g) {
371          print $1;
372      }
373
374 It will print 'A' and then terminate, as it considers the match to
375 be zero-width, and thus will not match at the same position twice in a
376 row.
377
378 It is worth noting that C<\G> improperly used can result in an infinite
379 loop. Take care when using patterns that include C<\G> in an alternation.
380
381 =head3 Capture groups
382
383 The bracketing construct C<( ... )> creates capture groups (also referred to as
384 capture buffers). To refer to the current contents of a group later on, within
385 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
386 for the second, and so on.
387 This is called a I<backreference>.
388 X<regex, capture buffer> X<regexp, capture buffer>
389 X<regex, capture group> X<regexp, capture group>
390 X<regular expression, capture buffer> X<backreference>
391 X<regular expression, capture group> X<backreference>
392 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
393 X<named capture buffer> X<regular expression, named capture buffer>
394 X<named capture group> X<regular expression, named capture group>
395 X<%+> X<$+{name}> X<< \k<name> >>
396 There is no limit to the number of captured substrings that you may use.
397 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
398 a group did not match, the associated backreference won't match either. (This
399 can happen if the group is optional, or in a different branch of an
400 alternation.)
401 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
402 this form, described below.
403
404 You can also refer to capture groups relatively, by using a negative number, so
405 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
406 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
407 example:
408
409         /
410          (Y)            # group 1
411          (              # group 2
412             (X)         # group 3
413             \g{-1}      # backref to group 3
414             \g{-3}      # backref to group 1
415          )
416         /x
417
418 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
419 interpolate regexes into larger regexes and not have to worry about the
420 capture groups being renumbered.
421
422 You can dispense with numbers altogether and create named capture groups.
423 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
424 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
425 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
426 I<name> must not begin with a number, nor contain hyphens.
427 When different groups within the same pattern have the same name, any reference
428 to that name assumes the leftmost defined group.  Named groups count in
429 absolute and relative numbering, and so can also be referred to by those
430 numbers.
431 (It's possible to do things with named capture groups that would otherwise
432 require C<(??{})>.)
433
434 Capture group contents are dynamically scoped and available to you outside the
435 pattern until the end of the enclosing block or until the next successful
436 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
437 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
438 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
439
440 Braces are required in referring to named capture groups, but are optional for
441 absolute or relative numbered ones.  Braces are safer when creating a regex by
442 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
443 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
444 is probably not what you intended.
445
446 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
447 there were no named nor relative numbered capture groups.  Absolute numbered
448 groups were referred to using C<\1>, C<\2>, etc, and this notation is still
449 accepted (and likely always will be).  But it leads to some ambiguities if
450 there are more than 9 capture groups, as C<\10> could mean either the tenth
451 capture group, or the character whose ordinal in octal is 010 (a backspace in
452 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
453 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
454 a backreference only if at least 11 left parentheses have opened before it.
455 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
456 There are several examples below that illustrate these perils.  You can avoid
457 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
458 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
459 digits padded with leading zeros, since a leading zero implies an octal
460 constant.
461
462 The C<\I<digit>> notation also works in certain circumstances outside
463 the pattern.  See L</Warning on \1 Instead of $1> below for details.)
464
465 Examples:
466
467     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
468
469     /(.)\g1/                        # find first doubled char
470          and print "'$1' is the first doubled character\n";
471
472     /(?<char>.)\k<char>/            # ... a different way
473          and print "'$+{char}' is the first doubled character\n";
474
475     /(?'char'.)\g1/                 # ... mix and match
476          and print "'$1' is the first doubled character\n";
477
478     if (/Time: (..):(..):(..)/) {   # parse out values
479         $hours = $1;
480         $minutes = $2;
481         $seconds = $3;
482     }
483
484     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
485     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
486     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
487     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
488
489     $a = '(.)\1';        # Creates problems when concatenated.
490     $b = '(.)\g{1}';     # Avoids the problems.
491     "aa" =~ /${a}/;      # True
492     "aa" =~ /${b}/;      # True
493     "aa0" =~ /${a}0/;    # False!
494     "aa0" =~ /${b}0/;    # True
495     "aa\x08" =~ /${a}0/;  # True!
496     "aa\x08" =~ /${b}0/;  # False
497
498 Several special variables also refer back to portions of the previous
499 match.  C<$+> returns whatever the last bracket match matched.
500 C<$&> returns the entire matched string.  (At one point C<$0> did
501 also, but now it returns the name of the program.)  C<$`> returns
502 everything before the matched string.  C<$'> returns everything
503 after the matched string. And C<$^N> contains whatever was matched by
504 the most-recently closed group (submatch). C<$^N> can be used in
505 extended patterns (see below), for example to assign a submatch to a
506 variable.
507 X<$+> X<$^N> X<$&> X<$`> X<$'>
508
509 These special variables, like the C<%+> hash and the numbered match variables
510 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
511 until the end of the enclosing block or until the next successful
512 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
513 X<$+> X<$^N> X<$&> X<$`> X<$'>
514 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
515
516 B<NOTE>: Failed matches in Perl do not reset the match variables,
517 which makes it easier to write code that tests for a series of more
518 specific cases and remembers the best match.
519
520 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
521 C<$'> anywhere in the program, it has to provide them for every
522 pattern match.  This may substantially slow your program.  Perl
523 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
524 price for each pattern that contains capturing parentheses.  (To
525 avoid this cost while retaining the grouping behaviour, use the
526 extended regular expression C<(?: ... )> instead.)  But if you never
527 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
528 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
529 if you can, but if you can't (and some algorithms really appreciate
530 them), once you've used them once, use them at will, because you've
531 already paid the price.  As of 5.005, C<$&> is not so costly as the
532 other two.
533 X<$&> X<$`> X<$'>
534
535 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
536 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
537 and C<$'>, B<except> that they are only guaranteed to be defined after a
538 successful match that was executed with the C</p> (preserve) modifier.
539 The use of these variables incurs no global performance penalty, unlike
540 their punctuation char equivalents, however at the trade-off that you
541 have to tell perl when you want to use them.
542 X</p> X<p modifier>
543
544 =head2 Quoting metacharacters
545
546 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
547 C<\w>, C<\n>.  Unlike some other regular expression languages, there
548 are no backslashed symbols that aren't alphanumeric.  So anything
549 that looks like \\, \(, \), \<, \>, \{, or \} is always
550 interpreted as a literal character, not a metacharacter.  This was
551 once used in a common idiom to disable or quote the special meanings
552 of regular expression metacharacters in a string that you want to
553 use for a pattern. Simply quote all non-"word" characters:
554
555     $pattern =~ s/(\W)/\\$1/g;
556
557 (If C<use locale> is set, then this depends on the current locale.)
558 Today it is more common to use the quotemeta() function or the C<\Q>
559 metaquoting escape sequence to disable all metacharacters' special
560 meanings like this:
561
562     /$unquoted\Q$quoted\E$unquoted/
563
564 Beware that if you put literal backslashes (those not inside
565 interpolated variables) between C<\Q> and C<\E>, double-quotish
566 backslash interpolation may lead to confusing results.  If you
567 I<need> to use literal backslashes within C<\Q...\E>,
568 consult L<perlop/"Gory details of parsing quoted constructs">.
569
570 =head2 Extended Patterns
571
572 Perl also defines a consistent extension syntax for features not
573 found in standard tools like B<awk> and B<lex>.  The syntax is a
574 pair of parentheses with a question mark as the first thing within
575 the parentheses.  The character after the question mark indicates
576 the extension.
577
578 The stability of these extensions varies widely.  Some have been
579 part of the core language for many years.  Others are experimental
580 and may change without warning or be completely removed.  Check
581 the documentation on an individual feature to verify its current
582 status.
583
584 A question mark was chosen for this and for the minimal-matching
585 construct because 1) question marks are rare in older regular
586 expressions, and 2) whenever you see one, you should stop and
587 "question" exactly what is going on.  That's psychology...
588
589 =over 10
590
591 =item C<(?#text)>
592 X<(?#)>
593
594 A comment.  The text is ignored.  If the C</x> modifier enables
595 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
596 the comment as soon as it sees a C<)>, so there is no way to put a literal
597 C<)> in the comment.
598
599 =item C<(?adlupimsx-imsx)>
600
601 =item C<(?^alupimsx)>
602 X<(?)> X<(?^)>
603
604 One or more embedded pattern-match modifiers, to be turned on (or
605 turned off, if preceded by C<->) for the remainder of the pattern or
606 the remainder of the enclosing pattern group (if any).
607
608 This is particularly useful for dynamic patterns, such as those read in from a
609 configuration file, taken from an argument, or specified in a table
610 somewhere.  Consider the case where some patterns want to be case
611 sensitive and some do not:  The case insensitive ones merely need to
612 include C<(?i)> at the front of the pattern.  For example:
613
614     $pattern = "foobar";
615     if ( /$pattern/i ) { }
616
617     # more flexible:
618
619     $pattern = "(?i)foobar";
620     if ( /$pattern/ ) { }
621
622 These modifiers are restored at the end of the enclosing group. For example,
623
624     ( (?i) blah ) \s+ \g1
625
626 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
627 repetition of the previous word, assuming the C</x> modifier, and no C</i>
628 modifier outside this group.
629
630 These modifiers do not carry over into named subpatterns called in the
631 enclosing group. In other words, a pattern such as C<((?i)(&NAME))> does not
632 change the case-sensitivity of the "NAME" pattern.
633
634 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
635 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
636 C<"d">) may follow the caret to override it.
637 But a minus sign is not legal with it.
638
639 Also, starting in Perl 5.14, are modifiers C<"a">, C<"d">, C<"l">, and
640 C<"u">, which for 5.14 may not be used as suffix modifiers.
641
642 C<"l"> means to use a locale (see L<perllocale>) when pattern matching.
643 The locale used will be the one in effect at the time of execution of
644 the pattern match.  This may not be the same as the compilation-time
645 locale, and can differ from one match to another if there is an
646 intervening call of the
647 L<setlocale() function|perllocale/The setlocale function>.
648 This modifier is automatically set if the regular expression is compiled
649 within the scope of a C<"use locale"> pragma.  Results are not
650 well-defined when using this and matching against a utf8-encoded string.
651
652 C<"u"> means to use Unicode semantics when pattern matching.  It is
653 automatically set if the regular expression is encoded in utf8, or is
654 compiled within the scope of a
655 L<C<"use feature 'unicode_strings">|feature> pragma (and isn't also in
656 the scope of L<C<"use locale">|locale> nor L<C<"use bytes">|bytes>
657 pragmas.  On ASCII platforms, the code points between 128 and 255 take on their
658 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's), whereas
659 in strict ASCII their meanings are undefined.  Thus the platform
660 effectively becomes a Unicode platform.  The ASCII characters remain as
661 ASCII characters (since ASCII is a subset of Latin-1 and Unicode).  For
662 example, when this option is XXX not on, on a non-utf8 string, C<"\w">
663 matches precisely C<[A-Za-z0-9_]>.  When the option is on, it matches
664 not just those, but all the Latin-1 word characters (such as an "n" with
665 a tilde).  On EBCDIC platforms, which already are equivalent to Latin-1,
666 this modifier changes behavior only when the C<"/i"> modifier is also
667 specified, and affects only two characters, giving them full Unicode
668 semantics: the C<MICRO SIGN> will match the Greek capital and
669 small letters C<MU>; otherwise not; and the C<LATIN CAPITAL LETTER SHARP
670 S> will match any of C<SS>, C<Ss>, C<sS>, and C<ss>, otherwise not.
671 (This last case is buggy, however.)
672
673 C<"a"> is the same as C<"u">, but C<\d>, C<\s>, C<\w>, and the Posix
674 character classes are restricted to matching in the ASCII range only.
675 That is, with this modifier, C<\d> always means precisely the digits
676 C<"0"> to C<"9">; C<\s> means the five characters C<[ \f\n\r\t]>;
677 C<\w> means the 53 characters C<[A-Za-z0-9_]>; and likewise, all the
678 Posix classes such as C<[[:print:]]> match only the appropriate
679 ASCII-range characters.  As you would expect, this modifier causes, for
680 example, C<\D> to mean the same thing as C<[^0-9]>.  C<"a"> behaves the
681 same as C<"u"> with regards to case-insensitive matches.  XXX
682
683 C<"d"> means to use the traditional Perl pattern matching behavior.
684 This is dualistic (hence the name C<"d">, which also could stand for
685 "depends").  When this is in effect, Perl matches utf8-encoded strings
686 using Unicode rules, and matches non-utf8-encoded strings using the
687 platform's native character set rules.  (If the regular expression
688 itself is encoded in utf8, Unicode rules are used regardless of the
689 target string's encoding.)
690 See L<perlunicode/The "Unicode Bug">.  It is automatically selected by
691 default if the regular expression is compiled neither within the scope
692 of a C<"use locale"> pragma nor a <C<"use feature 'unicode_strings">
693 pragma.
694
695 Note that the C<d>, C<l>, C<p>, and C<u> modifiers are special in that
696 they can only be enabled, not disabled, and the C<d>, C<l>, and C<u>
697 modifiers are mutually exclusive: specifying one de-specifies the
698 others, and a maximum of one may appear in the construct.  Thus, for
699 example, C<(?-p)>, C<(?-d:...)>, and C<(?dl:...)> will warn when
700 compiled under C<use warnings>.
701
702 Note also that the C<p> modifier is special in that its presence
703 anywhere in a pattern has a global effect.
704
705 =item C<(?:pattern)>
706 X<(?:)>
707
708 =item C<(?adluimsx-imsx:pattern)>
709
710 =item C<(?^aluimsx:pattern)>
711 X<(?^:)>
712
713 This is for clustering, not capturing; it groups subexpressions like
714 "()", but doesn't make backreferences as "()" does.  So
715
716     @fields = split(/\b(?:a|b|c)\b/)
717
718 is like
719
720     @fields = split(/\b(a|b|c)\b/)
721
722 but doesn't spit out extra fields.  It's also cheaper not to capture
723 characters if you don't need to.
724
725 Any letters between C<?> and C<:> act as flags modifiers as with
726 C<(?adluimsx-imsx)>.  For example,
727
728     /(?s-i:more.*than).*million/i
729
730 is equivalent to the more verbose
731
732     /(?:(?s-i)more.*than).*million/i
733
734 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
735 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
736 flags (except C<"d">) may follow the caret, so
737
738     (?^x:foo)
739
740 is equivalent to
741
742     (?x-ims:foo)
743
744 The caret tells Perl that this cluster doesn't inherit the flags of any
745 surrounding pattern, but to go back to the system defaults (C<d-imsx>),
746 modified by any flags specified.
747
748 The caret allows for simpler stringification of compiled regular
749 expressions.  These look like
750
751     (?^:pattern)
752
753 with any non-default flags appearing between the caret and the colon.
754 A test that looks at such stringification thus doesn't need to have the
755 system default flags hard-coded in it, just the caret.  If new flags are
756 added to Perl, the meaning of the caret's expansion will change to include
757 the default for those flags, so the test will still work, unchanged.
758
759 Specifying a negative flag after the caret is an error, as the flag is
760 redundant.
761
762 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
763 to match at the beginning.
764
765 =item C<(?|pattern)>
766 X<(?|)> X<Branch reset>
767
768 This is the "branch reset" pattern, which has the special property
769 that the capture groups are numbered from the same starting point
770 in each alternation branch. It is available starting from perl 5.10.0.
771
772 Capture groups are numbered from left to right, but inside this
773 construct the numbering is restarted for each branch.
774
775 The numbering within each branch will be as normal, and any groups
776 following this construct will be numbered as though the construct
777 contained only one branch, that being the one with the most capture
778 groups in it.
779
780 This construct will be useful when you want to capture one of a
781 number of alternative matches.
782
783 Consider the following pattern.  The numbers underneath show in
784 which group the captured content will be stored.
785
786
787     # before  ---------------branch-reset----------- after        
788     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
789     # 1            2         2  3        2     3     4  
790
791 Be careful when using the branch reset pattern in combination with 
792 named captures. Named captures are implemented as being aliases to 
793 numbered groups holding the captures, and that interferes with the
794 implementation of the branch reset pattern. If you are using named
795 captures in a branch reset pattern, it's best to use the same names,
796 in the same order, in each of the alternations:
797
798    /(?|  (?<a> x ) (?<b> y )
799       |  (?<a> z ) (?<b> w )) /x
800
801 Not doing so may lead to surprises:
802
803   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
804   say $+ {a};   # Prints '12'
805   say $+ {b};   # *Also* prints '12'.
806
807 The problem here is that both the group named C<< a >> and the group
808 named C<< b >> are aliases for the group belonging to C<< $1 >>.
809
810 =item Look-Around Assertions
811 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
812
813 Look-around assertions are zero width patterns which match a specific
814 pattern without including it in C<$&>. Positive assertions match when
815 their subpattern matches, negative assertions match when their subpattern
816 fails. Look-behind matches text up to the current match position,
817 look-ahead matches text following the current match position.
818
819 =over 4
820
821 =item C<(?=pattern)>
822 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
823
824 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
825 matches a word followed by a tab, without including the tab in C<$&>.
826
827 =item C<(?!pattern)>
828 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
829
830 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
831 matches any occurrence of "foo" that isn't followed by "bar".  Note
832 however that look-ahead and look-behind are NOT the same thing.  You cannot
833 use this for look-behind.
834
835 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
836 will not do what you want.  That's because the C<(?!foo)> is just saying that
837 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
838 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
839 say "like" because there's the case of your "bar" not having three characters
840 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
841 Sometimes it's still easier just to say:
842
843     if (/bar/ && $` !~ /foo$/)
844
845 For look-behind see below.
846
847 =item C<(?<=pattern)> C<\K>
848 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
849
850 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
851 matches a word that follows a tab, without including the tab in C<$&>.
852 Works only for fixed-width look-behind.
853
854 There is a special form of this construct, called C<\K>, which causes the
855 regex engine to "keep" everything it had matched prior to the C<\K> and
856 not include it in C<$&>. This effectively provides variable length
857 look-behind. The use of C<\K> inside of another look-around assertion
858 is allowed, but the behaviour is currently not well defined.
859
860 For various reasons C<\K> may be significantly more efficient than the
861 equivalent C<< (?<=...) >> construct, and it is especially useful in
862 situations where you want to efficiently remove something following
863 something else in a string. For instance
864
865   s/(foo)bar/$1/g;
866
867 can be rewritten as the much more efficient
868
869   s/foo\Kbar//g;
870
871 =item C<(?<!pattern)>
872 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
873
874 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
875 matches any occurrence of "foo" that does not follow "bar".  Works
876 only for fixed-width look-behind.
877
878 =back
879
880 =item C<(?'NAME'pattern)>
881
882 =item C<< (?<NAME>pattern) >>
883 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
884
885 A named capture group. Identical in every respect to normal capturing
886 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
887 used after a successful match to refer to a named group. See C<perlvar>
888 for more details on the C<%+> and C<%-> hashes.
889
890 If multiple distinct capture groups have the same name then the
891 $+{NAME} will refer to the leftmost defined group in the match.
892
893 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
894
895 B<NOTE:> While the notation of this construct is the same as the similar
896 function in .NET regexes, the behavior is not. In Perl the groups are
897 numbered sequentially regardless of being named or not. Thus in the
898 pattern
899
900   /(x)(?<foo>y)(z)/
901
902 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
903 the opposite which is what a .NET regex hacker might expect.
904
905 Currently NAME is restricted to simple identifiers only.
906 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
907 its Unicode extension (see L<utf8>),
908 though it isn't extended by the locale (see L<perllocale>).
909
910 B<NOTE:> In order to make things easier for programmers with experience
911 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
912 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
913 support the use of single quotes as a delimiter for the name.
914
915 =item C<< \k<NAME> >>
916
917 =item C<< \k'NAME' >>
918
919 Named backreference. Similar to numeric backreferences, except that
920 the group is designated by name and not number. If multiple groups
921 have the same name then it refers to the leftmost defined group in
922 the current match.
923
924 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
925 earlier in the pattern.
926
927 Both forms are equivalent.
928
929 B<NOTE:> In order to make things easier for programmers with experience
930 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
931 may be used instead of C<< \k<NAME> >>.
932
933 =item C<(?{ code })>
934 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
935
936 B<WARNING>: This extended regular expression feature is considered
937 experimental, and may be changed without notice. Code executed that
938 has side effects may not perform identically from version to version
939 due to the effect of future optimisations in the regex engine.
940
941 This zero-width assertion evaluates any embedded Perl code.  It
942 always succeeds, and its C<code> is not interpolated.  Currently,
943 the rules to determine where the C<code> ends are somewhat convoluted.
944
945 This feature can be used together with the special variable C<$^N> to
946 capture the results of submatches in variables without having to keep
947 track of the number of nested parentheses. For example:
948
949   $_ = "The brown fox jumps over the lazy dog";
950   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
951   print "color = $color, animal = $animal\n";
952
953 Inside the C<(?{...})> block, C<$_> refers to the string the regular
954 expression is matching against. You can also use C<pos()> to know what is
955 the current position of matching within this string.
956
957 The C<code> is properly scoped in the following sense: If the assertion
958 is backtracked (compare L<"Backtracking">), all changes introduced after
959 C<local>ization are undone, so that
960
961   $_ = 'a' x 8;
962   m<
963      (?{ $cnt = 0 })                   # Initialize $cnt.
964      (
965        a
966        (?{
967            local $cnt = $cnt + 1;      # Update $cnt, backtracking-safe.
968        })
969      )*
970      aaaa
971      (?{ $res = $cnt })                # On success copy to
972                                        # non-localized location.
973    >x;
974
975 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
976 introduced value, because the scopes that restrict C<local> operators
977 are unwound.
978
979 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
980 switch.  If I<not> used in this way, the result of evaluation of
981 C<code> is put into the special variable C<$^R>.  This happens
982 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
983 inside the same regular expression.
984
985 The assignment to C<$^R> above is properly localized, so the old
986 value of C<$^R> is restored if the assertion is backtracked; compare
987 L<"Backtracking">.
988
989 For reasons of security, this construct is forbidden if the regular
990 expression involves run-time interpolation of variables, unless the
991 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
992 variables contain results of C<qr//> operator (see
993 L<perlop/"qr/STRINGE<sol>msixpo">).
994
995 This restriction is due to the wide-spread and remarkably convenient
996 custom of using run-time determined strings as patterns.  For example:
997
998     $re = <>;
999     chomp $re;
1000     $string =~ /$re/;
1001
1002 Before Perl knew how to execute interpolated code within a pattern,
1003 this operation was completely safe from a security point of view,
1004 although it could raise an exception from an illegal pattern.  If
1005 you turn on the C<use re 'eval'>, though, it is no longer secure,
1006 so you should only do so if you are also using taint checking.
1007 Better yet, use the carefully constrained evaluation within a Safe
1008 compartment.  See L<perlsec> for details about both these mechanisms.
1009
1010 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
1011 broken. The result is unpredictable and will make perl unstable. The
1012 workaround is to use global (C<our>) variables.
1013
1014 B<WARNING>: In perl 5.12.x and earlier, the regex engine
1015 was not re-entrant, so interpolated code could not
1016 safely invoke the regex engine either directly with
1017 C<m//> or C<s///>), or indirectly with functions such as
1018 C<split>. Invoking the regex engine in these blocks would make perl
1019 unstable.
1020
1021 =item C<(??{ code })>
1022 X<(??{})>
1023 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1024
1025 B<WARNING>: This extended regular expression feature is considered
1026 experimental, and may be changed without notice. Code executed that
1027 has side effects may not perform identically from version to version
1028 due to the effect of future optimisations in the regex engine.
1029
1030 This is a "postponed" regular subexpression.  The C<code> is evaluated
1031 at run time, at the moment this subexpression may match.  The result
1032 of evaluation is considered as a regular expression and matched as
1033 if it were inserted instead of this construct.  Note that this means
1034 that the contents of capture groups defined inside an eval'ed pattern
1035 are not available outside of the pattern, and vice versa, there is no
1036 way for the inner pattern to refer to a capture group defined outside.
1037 Thus,
1038
1039     ('a' x 100)=~/(??{'(.)' x 100})/
1040
1041 B<will> match, it will B<not> set $1.
1042
1043 The C<code> is not interpolated.  As before, the rules to determine
1044 where the C<code> ends are currently somewhat convoluted.
1045
1046 The following pattern matches a parenthesized group:
1047
1048   $re = qr{
1049              \(
1050              (?:
1051                 (?> [^()]+ )       # Non-parens without backtracking
1052               |
1053                 (??{ $re })        # Group with matching parens
1054              )*
1055              \)
1056           }x;
1057
1058 See also C<(?PARNO)> for a different, more efficient way to accomplish
1059 the same task.
1060
1061 For reasons of security, this construct is forbidden if the regular
1062 expression involves run-time interpolation of variables, unless the
1063 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1064 variables contain results of C<qr//> operator (see
1065 L<perlop/"qrE<sol>STRINGE<sol>msixpo">).
1066
1067 In perl 5.12.x and earlier, because the regex engine was not re-entrant,
1068 delayed code could not safely invoke the regex engine either directly with
1069 C<m//> or C<s///>), or indirectly with functions such as C<split>.
1070
1071 Recursing deeper than 50 times without consuming any input string will
1072 result in a fatal error.  The maximum depth is compiled into perl, so
1073 changing it requires a custom build.
1074
1075 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1076 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1077 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1078 X<regex, relative recursion>
1079
1080 Similar to C<(??{ code })> except it does not involve compiling any code,
1081 instead it treats the contents of a capture group as an independent
1082 pattern that must match at the current position.  Capture groups
1083 contained by the pattern will have the value as determined by the
1084 outermost recursion.
1085
1086 PARNO is a sequence of digits (not starting with 0) whose value reflects
1087 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1088 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1089 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1090 to be relative, with negative numbers indicating preceding capture groups
1091 and positive ones following. Thus C<(?-1)> refers to the most recently
1092 declared group, and C<(?+1)> indicates the next group to be declared.
1093 Note that the counting for relative recursion differs from that of
1094 relative backreferences, in that with recursion unclosed groups B<are>
1095 included.
1096
1097 The following pattern matches a function foo() which may contain
1098 balanced parentheses as the argument.
1099
1100   $re = qr{ (                    # paren group 1 (full function)
1101               foo
1102               (                  # paren group 2 (parens)
1103                 \(
1104                   (              # paren group 3 (contents of parens)
1105                   (?:
1106                    (?> [^()]+ )  # Non-parens without backtracking
1107                   |
1108                    (?2)          # Recurse to start of paren group 2
1109                   )*
1110                   )
1111                 \)
1112               )
1113             )
1114           }x;
1115
1116 If the pattern was used as follows
1117
1118     'foo(bar(baz)+baz(bop))'=~/$re/
1119         and print "\$1 = $1\n",
1120                   "\$2 = $2\n",
1121                   "\$3 = $3\n";
1122
1123 the output produced should be the following:
1124
1125     $1 = foo(bar(baz)+baz(bop))
1126     $2 = (bar(baz)+baz(bop))
1127     $3 = bar(baz)+baz(bop)
1128
1129 If there is no corresponding capture group defined, then it is a
1130 fatal error.  Recursing deeper than 50 times without consuming any input
1131 string will also result in a fatal error.  The maximum depth is compiled
1132 into perl, so changing it requires a custom build.
1133
1134 The following shows how using negative indexing can make it
1135 easier to embed recursive patterns inside of a C<qr//> construct
1136 for later use:
1137
1138     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1139     if (/foo $parens \s+ + \s+ bar $parens/x) {
1140        # do something here...
1141     }
1142
1143 B<Note> that this pattern does not behave the same way as the equivalent
1144 PCRE or Python construct of the same form. In Perl you can backtrack into
1145 a recursed group, in PCRE and Python the recursed into group is treated
1146 as atomic. Also, modifiers are resolved at compile time, so constructs
1147 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1148 be processed.
1149
1150 =item C<(?&NAME)>
1151 X<(?&NAME)>
1152
1153 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1154 parenthesis to recurse to is determined by name. If multiple parentheses have
1155 the same name, then it recurses to the leftmost.
1156
1157 It is an error to refer to a name that is not declared somewhere in the
1158 pattern.
1159
1160 B<NOTE:> In order to make things easier for programmers with experience
1161 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1162 may be used instead of C<< (?&NAME) >>.
1163
1164 =item C<(?(condition)yes-pattern|no-pattern)>
1165 X<(?()>
1166
1167 =item C<(?(condition)yes-pattern)>
1168
1169 Conditional expression.  C<(condition)> should be either an integer in
1170 parentheses (which is valid if the corresponding pair of parentheses
1171 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1172 name in angle brackets or single quotes (which is valid if a group
1173 with the given name matched), or the special symbol (R) (true when
1174 evaluated inside of recursion or eval). Additionally the R may be
1175 followed by a number, (which will be true when evaluated when recursing
1176 inside of the appropriate group), or by C<&NAME>, in which case it will
1177 be true only when evaluated during recursion in the named group.
1178
1179 Here's a summary of the possible predicates:
1180
1181 =over 4
1182
1183 =item (1) (2) ...
1184
1185 Checks if the numbered capturing group has matched something.
1186
1187 =item (<NAME>) ('NAME')
1188
1189 Checks if a group with the given name has matched something.
1190
1191 =item (?{ CODE })
1192
1193 Treats the code block as the condition.
1194
1195 =item (R)
1196
1197 Checks if the expression has been evaluated inside of recursion.
1198
1199 =item (R1) (R2) ...
1200
1201 Checks if the expression has been evaluated while executing directly
1202 inside of the n-th capture group. This check is the regex equivalent of
1203
1204   if ((caller(0))[3] eq 'subname') { ... }
1205
1206 In other words, it does not check the full recursion stack.
1207
1208 =item (R&NAME)
1209
1210 Similar to C<(R1)>, this predicate checks to see if we're executing
1211 directly inside of the leftmost group with a given name (this is the same
1212 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1213 stack, but only the name of the innermost active recursion.
1214
1215 =item (DEFINE)
1216
1217 In this case, the yes-pattern is never directly executed, and no
1218 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1219 See below for details.
1220
1221 =back
1222
1223 For example:
1224
1225     m{ ( \( )?
1226        [^()]+
1227        (?(1) \) )
1228      }x
1229
1230 matches a chunk of non-parentheses, possibly included in parentheses
1231 themselves.
1232
1233 A special form is the C<(DEFINE)> predicate, which never executes directly
1234 its yes-pattern, and does not allow a no-pattern. This allows to define
1235 subpatterns which will be executed only by using the recursion mechanism.
1236 This way, you can define a set of regular expression rules that can be
1237 bundled into any pattern you choose.
1238
1239 It is recommended that for this usage you put the DEFINE block at the
1240 end of the pattern, and that you name any subpatterns defined within it.
1241
1242 Also, it's worth noting that patterns defined this way probably will
1243 not be as efficient, as the optimiser is not very clever about
1244 handling them.
1245
1246 An example of how this might be used is as follows:
1247
1248   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1249    (?(DEFINE)
1250      (?<NAME_PAT>....)
1251      (?<ADRESS_PAT>....)
1252    )/x
1253
1254 Note that capture groups matched inside of recursion are not accessible
1255 after the recursion returns, so the extra layer of capturing groups is
1256 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1257 C<$+{NAME}> would be.
1258
1259 =item C<< (?>pattern) >>
1260 X<backtrack> X<backtracking> X<atomic> X<possessive>
1261
1262 An "independent" subexpression, one which matches the substring
1263 that a I<standalone> C<pattern> would match if anchored at the given
1264 position, and it matches I<nothing other than this substring>.  This
1265 construct is useful for optimizations of what would otherwise be
1266 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1267 It may also be useful in places where the "grab all you can, and do not
1268 give anything back" semantic is desirable.
1269
1270 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1271 (anchored at the beginning of string, as above) will match I<all>
1272 characters C<a> at the beginning of string, leaving no C<a> for
1273 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1274 since the match of the subgroup C<a*> is influenced by the following
1275 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1276 C<a*ab> will match fewer characters than a standalone C<a*>, since
1277 this makes the tail match.
1278
1279 An effect similar to C<< (?>pattern) >> may be achieved by writing
1280 C<(?=(pattern))\g1>.  This matches the same substring as a standalone
1281 C<a+>, and the following C<\g1> eats the matched string; it therefore
1282 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1283 (The difference between these two constructs is that the second one
1284 uses a capturing group, thus shifting ordinals of backreferences
1285 in the rest of a regular expression.)
1286
1287 Consider this pattern:
1288
1289     m{ \(
1290           (
1291             [^()]+           # x+
1292           |
1293             \( [^()]* \)
1294           )+
1295        \)
1296      }x
1297
1298 That will efficiently match a nonempty group with matching parentheses
1299 two levels deep or less.  However, if there is no such group, it
1300 will take virtually forever on a long string.  That's because there
1301 are so many different ways to split a long string into several
1302 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1303 to a subpattern of the above pattern.  Consider how the pattern
1304 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1305 seconds, but that each extra letter doubles this time.  This
1306 exponential performance will make it appear that your program has
1307 hung.  However, a tiny change to this pattern
1308
1309     m{ \(
1310           (
1311             (?> [^()]+ )        # change x+ above to (?> x+ )
1312           |
1313             \( [^()]* \)
1314           )+
1315        \)
1316      }x
1317
1318 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1319 this yourself would be a productive exercise), but finishes in a fourth
1320 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1321 however, that this pattern currently triggers a warning message under
1322 the C<use warnings> pragma or B<-w> switch saying it
1323 C<"matches null string many times in regex">.
1324
1325 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1326 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1327 This was only 4 times slower on a string with 1000000 C<a>s.
1328
1329 The "grab all you can, and do not give anything back" semantic is desirable
1330 in many situations where on the first sight a simple C<()*> looks like
1331 the correct solution.  Suppose we parse text with comments being delimited
1332 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1333 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1334 the comment delimiter, because it may "give up" some whitespace if
1335 the remainder of the pattern can be made to match that way.  The correct
1336 answer is either one of these:
1337
1338     (?>#[ \t]*)
1339     #[ \t]*(?![ \t])
1340
1341 For example, to grab non-empty comments into $1, one should use either
1342 one of these:
1343
1344     / (?> \# [ \t]* ) (        .+ ) /x;
1345     /     \# [ \t]*   ( [^ \t] .* ) /x;
1346
1347 Which one you pick depends on which of these expressions better reflects
1348 the above specification of comments.
1349
1350 In some literature this construct is called "atomic matching" or
1351 "possessive matching".
1352
1353 Possessive quantifiers are equivalent to putting the item they are applied
1354 to inside of one of these constructs. The following equivalences apply:
1355
1356     Quantifier Form     Bracketing Form
1357     ---------------     ---------------
1358     PAT*+               (?>PAT*)
1359     PAT++               (?>PAT+)
1360     PAT?+               (?>PAT?)
1361     PAT{min,max}+       (?>PAT{min,max})
1362
1363 =back
1364
1365 =head2 Special Backtracking Control Verbs
1366
1367 B<WARNING:> These patterns are experimental and subject to change or
1368 removal in a future version of Perl. Their usage in production code should
1369 be noted to avoid problems during upgrades.
1370
1371 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1372 otherwise stated the ARG argument is optional; in some cases, it is
1373 forbidden.
1374
1375 Any pattern containing a special backtracking verb that allows an argument
1376 has the special behaviour that when executed it sets the current package's
1377 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1378 rules apply:
1379
1380 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1381 verb pattern, if the verb was involved in the failure of the match. If the
1382 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1383 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1384 none. Also, the C<$REGMARK> variable will be set to FALSE.
1385
1386 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1387 the C<$REGMARK> variable will be set to the name of the last
1388 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1389 C<(*MARK:NAME)> verb below for more details.
1390
1391 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1392 and most other regex related variables. They are not local to a scope, nor
1393 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1394 Use C<local> to localize changes to them to a specific scope if necessary.
1395
1396 If a pattern does not contain a special backtracking verb that allows an
1397 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1398
1399 =over 4
1400
1401 =item Verbs that take an argument
1402
1403 =over 4
1404
1405 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1406 X<(*PRUNE)> X<(*PRUNE:NAME)>
1407
1408 This zero-width pattern prunes the backtracking tree at the current point
1409 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1410 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1411 A may backtrack as necessary to match. Once it is reached, matching
1412 continues in B, which may also backtrack as necessary; however, should B
1413 not match, then no further backtracking will take place, and the pattern
1414 will fail outright at the current starting position.
1415
1416 The following example counts all the possible matching strings in a
1417 pattern (without actually matching any of them).
1418
1419     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1420     print "Count=$count\n";
1421
1422 which produces:
1423
1424     aaab
1425     aaa
1426     aa
1427     a
1428     aab
1429     aa
1430     a
1431     ab
1432     a
1433     Count=9
1434
1435 If we add a C<(*PRUNE)> before the count like the following
1436
1437     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1438     print "Count=$count\n";
1439
1440 we prevent backtracking and find the count of the longest matching
1441 at each matching starting point like so:
1442
1443     aaab
1444     aab
1445     ab
1446     Count=3
1447
1448 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1449
1450 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1451 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1452 replaced with a C<< (?>pattern) >> with no functional difference; however,
1453 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1454 C<< (?>pattern) >> alone.
1455
1456
1457 =item C<(*SKIP)> C<(*SKIP:NAME)>
1458 X<(*SKIP)>
1459
1460 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1461 failure it also signifies that whatever text that was matched leading up
1462 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1463 of this pattern. This effectively means that the regex engine "skips" forward
1464 to this position on failure and tries to match again, (assuming that
1465 there is sufficient room to match).
1466
1467 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1468 C<(*MARK:NAME)> was encountered while matching, then it is that position
1469 which is used as the "skip point". If no C<(*MARK)> of that name was
1470 encountered, then the C<(*SKIP)> operator has no effect. When used
1471 without a name the "skip point" is where the match point was when
1472 executing the (*SKIP) pattern.
1473
1474 Compare the following to the examples in C<(*PRUNE)>, note the string
1475 is twice as long:
1476
1477     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1478     print "Count=$count\n";
1479
1480 outputs
1481
1482     aaab
1483     aaab
1484     Count=2
1485
1486 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1487 executed, the next starting point will be where the cursor was when the
1488 C<(*SKIP)> was executed.
1489
1490 =item C<(*MARK:NAME)> C<(*:NAME)>
1491 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1492
1493 This zero-width pattern can be used to mark the point reached in a string
1494 when a certain part of the pattern has been successfully matched. This
1495 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1496 forward to that point if backtracked into on failure. Any number of
1497 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1498
1499 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1500 can be used to "label" a pattern branch, so that after matching, the
1501 program can determine which branches of the pattern were involved in the
1502 match.
1503
1504 When a match is successful, the C<$REGMARK> variable will be set to the
1505 name of the most recently executed C<(*MARK:NAME)> that was involved
1506 in the match.
1507
1508 This can be used to determine which branch of a pattern was matched
1509 without using a separate capture group for each branch, which in turn
1510 can result in a performance improvement, as perl cannot optimize
1511 C</(?:(x)|(y)|(z))/> as efficiently as something like
1512 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1513
1514 When a match has failed, and unless another verb has been involved in
1515 failing the match and has provided its own name to use, the C<$REGERROR>
1516 variable will be set to the name of the most recently executed
1517 C<(*MARK:NAME)>.
1518
1519 See C<(*SKIP)> for more details.
1520
1521 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1522
1523 =item C<(*THEN)> C<(*THEN:NAME)>
1524
1525 This is similar to the "cut group" operator C<::> from Perl 6. Like
1526 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1527 failure, it causes the regex engine to try the next alternation in the
1528 innermost enclosing group (capturing or otherwise).
1529
1530 Its name comes from the observation that this operation combined with the
1531 alternation operator (C<|>) can be used to create what is essentially a
1532 pattern-based if/then/else block:
1533
1534   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1535
1536 Note that if this operator is used and NOT inside of an alternation then
1537 it acts exactly like the C<(*PRUNE)> operator.
1538
1539   / A (*PRUNE) B /
1540
1541 is the same as
1542
1543   / A (*THEN) B /
1544
1545 but
1546
1547   / ( A (*THEN) B | C (*THEN) D ) /
1548
1549 is not the same as
1550
1551   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1552
1553 as after matching the A but failing on the B the C<(*THEN)> verb will
1554 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1555
1556 =item C<(*COMMIT)>
1557 X<(*COMMIT)>
1558
1559 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1560 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1561 into on failure it causes the match to fail outright. No further attempts
1562 to find a valid match by advancing the start pointer will occur again.
1563 For example,
1564
1565     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1566     print "Count=$count\n";
1567
1568 outputs
1569
1570     aaab
1571     Count=1
1572
1573 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1574 does not match, the regex engine will not try any further matching on the
1575 rest of the string.
1576
1577 =back
1578
1579 =item Verbs without an argument
1580
1581 =over 4
1582
1583 =item C<(*FAIL)> C<(*F)>
1584 X<(*FAIL)> X<(*F)>
1585
1586 This pattern matches nothing and always fails. It can be used to force the
1587 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1588 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1589
1590 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1591
1592 =item C<(*ACCEPT)>
1593 X<(*ACCEPT)>
1594
1595 B<WARNING:> This feature is highly experimental. It is not recommended
1596 for production code.
1597
1598 This pattern matches nothing and causes the end of successful matching at
1599 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1600 whether there is actually more to match in the string. When inside of a
1601 nested pattern, such as recursion, or in a subpattern dynamically generated
1602 via C<(??{})>, only the innermost pattern is ended immediately.
1603
1604 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1605 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1606 For instance:
1607
1608   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1609
1610 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1611 be set. If another branch in the inner parentheses were matched, such as in the
1612 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1613
1614 =back
1615
1616 =back
1617
1618 =head2 Backtracking
1619 X<backtrack> X<backtracking>
1620
1621 NOTE: This section presents an abstract approximation of regular
1622 expression behavior.  For a more rigorous (and complicated) view of
1623 the rules involved in selecting a match among possible alternatives,
1624 see L<Combining RE Pieces>.
1625
1626 A fundamental feature of regular expression matching involves the
1627 notion called I<backtracking>, which is currently used (when needed)
1628 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1629 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1630 internally, but the general principle outlined here is valid.
1631
1632 For a regular expression to match, the I<entire> regular expression must
1633 match, not just part of it.  So if the beginning of a pattern containing a
1634 quantifier succeeds in a way that causes later parts in the pattern to
1635 fail, the matching engine backs up and recalculates the beginning
1636 part--that's why it's called backtracking.
1637
1638 Here is an example of backtracking:  Let's say you want to find the
1639 word following "foo" in the string "Food is on the foo table.":
1640
1641     $_ = "Food is on the foo table.";
1642     if ( /\b(foo)\s+(\w+)/i ) {
1643         print "$2 follows $1.\n";
1644     }
1645
1646 When the match runs, the first part of the regular expression (C<\b(foo)>)
1647 finds a possible match right at the beginning of the string, and loads up
1648 $1 with "Foo".  However, as soon as the matching engine sees that there's
1649 no whitespace following the "Foo" that it had saved in $1, it realizes its
1650 mistake and starts over again one character after where it had the
1651 tentative match.  This time it goes all the way until the next occurrence
1652 of "foo". The complete regular expression matches this time, and you get
1653 the expected output of "table follows foo."
1654
1655 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1656 everything between "foo" and "bar".  Initially, you write something
1657 like this:
1658
1659     $_ =  "The food is under the bar in the barn.";
1660     if ( /foo(.*)bar/ ) {
1661         print "got <$1>\n";
1662     }
1663
1664 Which perhaps unexpectedly yields:
1665
1666   got <d is under the bar in the >
1667
1668 That's because C<.*> was greedy, so you get everything between the
1669 I<first> "foo" and the I<last> "bar".  Here it's more effective
1670 to use minimal matching to make sure you get the text between a "foo"
1671 and the first "bar" thereafter.
1672
1673     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1674   got <d is under the >
1675
1676 Here's another example. Let's say you'd like to match a number at the end
1677 of a string, and you also want to keep the preceding part of the match.
1678 So you write this:
1679
1680     $_ = "I have 2 numbers: 53147";
1681     if ( /(.*)(\d*)/ ) {                                # Wrong!
1682         print "Beginning is <$1>, number is <$2>.\n";
1683     }
1684
1685 That won't work at all, because C<.*> was greedy and gobbled up the
1686 whole string. As C<\d*> can match on an empty string the complete
1687 regular expression matched successfully.
1688
1689     Beginning is <I have 2 numbers: 53147>, number is <>.
1690
1691 Here are some variants, most of which don't work:
1692
1693     $_ = "I have 2 numbers: 53147";
1694     @pats = qw{
1695         (.*)(\d*)
1696         (.*)(\d+)
1697         (.*?)(\d*)
1698         (.*?)(\d+)
1699         (.*)(\d+)$
1700         (.*?)(\d+)$
1701         (.*)\b(\d+)$
1702         (.*\D)(\d+)$
1703     };
1704
1705     for $pat (@pats) {
1706         printf "%-12s ", $pat;
1707         if ( /$pat/ ) {
1708             print "<$1> <$2>\n";
1709         } else {
1710             print "FAIL\n";
1711         }
1712     }
1713
1714 That will print out:
1715
1716     (.*)(\d*)    <I have 2 numbers: 53147> <>
1717     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1718     (.*?)(\d*)   <> <>
1719     (.*?)(\d+)   <I have > <2>
1720     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1721     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1722     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1723     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1724
1725 As you see, this can be a bit tricky.  It's important to realize that a
1726 regular expression is merely a set of assertions that gives a definition
1727 of success.  There may be 0, 1, or several different ways that the
1728 definition might succeed against a particular string.  And if there are
1729 multiple ways it might succeed, you need to understand backtracking to
1730 know which variety of success you will achieve.
1731
1732 When using look-ahead assertions and negations, this can all get even
1733 trickier.  Imagine you'd like to find a sequence of non-digits not
1734 followed by "123".  You might try to write that as
1735
1736     $_ = "ABC123";
1737     if ( /^\D*(?!123)/ ) {                # Wrong!
1738         print "Yup, no 123 in $_\n";
1739     }
1740
1741 But that isn't going to match; at least, not the way you're hoping.  It
1742 claims that there is no 123 in the string.  Here's a clearer picture of
1743 why that pattern matches, contrary to popular expectations:
1744
1745     $x = 'ABC123';
1746     $y = 'ABC445';
1747
1748     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1749     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1750
1751     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1752     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1753
1754 This prints
1755
1756     2: got ABC
1757     3: got AB
1758     4: got ABC
1759
1760 You might have expected test 3 to fail because it seems to a more
1761 general purpose version of test 1.  The important difference between
1762 them is that test 3 contains a quantifier (C<\D*>) and so can use
1763 backtracking, whereas test 1 will not.  What's happening is
1764 that you've asked "Is it true that at the start of $x, following 0 or more
1765 non-digits, you have something that's not 123?"  If the pattern matcher had
1766 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1767 fail.
1768
1769 The search engine will initially match C<\D*> with "ABC".  Then it will
1770 try to match C<(?!123> with "123", which fails.  But because
1771 a quantifier (C<\D*>) has been used in the regular expression, the
1772 search engine can backtrack and retry the match differently
1773 in the hope of matching the complete regular expression.
1774
1775 The pattern really, I<really> wants to succeed, so it uses the
1776 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1777 time.  Now there's indeed something following "AB" that is not
1778 "123".  It's "C123", which suffices.
1779
1780 We can deal with this by using both an assertion and a negation.
1781 We'll say that the first part in $1 must be followed both by a digit
1782 and by something that's not "123".  Remember that the look-aheads
1783 are zero-width expressions--they only look, but don't consume any
1784 of the string in their match.  So rewriting this way produces what
1785 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1786
1787     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1788     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1789
1790     6: got ABC
1791
1792 In other words, the two zero-width assertions next to each other work as though
1793 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1794 matches only if you're at the beginning of the line AND the end of the
1795 line simultaneously.  The deeper underlying truth is that juxtaposition in
1796 regular expressions always means AND, except when you write an explicit OR
1797 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1798 although the attempted matches are made at different positions because "a"
1799 is not a zero-width assertion, but a one-width assertion.
1800
1801 B<WARNING>: Particularly complicated regular expressions can take
1802 exponential time to solve because of the immense number of possible
1803 ways they can use backtracking to try for a match.  For example, without
1804 internal optimizations done by the regular expression engine, this will
1805 take a painfully long time to run:
1806
1807     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1808
1809 And if you used C<*>'s in the internal groups instead of limiting them
1810 to 0 through 5 matches, then it would take forever--or until you ran
1811 out of stack space.  Moreover, these internal optimizations are not
1812 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1813 on the external group, no current optimization is applicable, and the
1814 match takes a long time to finish.
1815
1816 A powerful tool for optimizing such beasts is what is known as an
1817 "independent group",
1818 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1819 zero-length look-ahead/look-behind assertions will not backtrack to make
1820 the tail match, since they are in "logical" context: only
1821 whether they match is considered relevant.  For an example
1822 where side-effects of look-ahead I<might> have influenced the
1823 following match, see L<C<< (?>pattern) >>>.
1824
1825 =head2 Version 8 Regular Expressions
1826 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1827
1828 In case you're not familiar with the "regular" Version 8 regex
1829 routines, here are the pattern-matching rules not described above.
1830
1831 Any single character matches itself, unless it is a I<metacharacter>
1832 with a special meaning described here or above.  You can cause
1833 characters that normally function as metacharacters to be interpreted
1834 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1835 character; "\\" matches a "\"). This escape mechanism is also required
1836 for the character used as the pattern delimiter.
1837
1838 A series of characters matches that series of characters in the target
1839 string, so the pattern  C<blurfl> would match "blurfl" in the target
1840 string.
1841
1842 You can specify a character class, by enclosing a list of characters
1843 in C<[]>, which will match any character from the list.  If the
1844 first character after the "[" is "^", the class matches any character not
1845 in the list.  Within a list, the "-" character specifies a
1846 range, so that C<a-z> represents all characters between "a" and "z",
1847 inclusive.  If you want either "-" or "]" itself to be a member of a
1848 class, put it at the start of the list (possibly after a "^"), or
1849 escape it with a backslash.  "-" is also taken literally when it is
1850 at the end of the list, just before the closing "]".  (The
1851 following all specify the same class of three characters: C<[-az]>,
1852 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1853 specifies a class containing twenty-six characters, even on EBCDIC-based
1854 character sets.)  Also, if you try to use the character
1855 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1856 a range, the "-" is understood literally.
1857
1858 Note also that the whole range idea is rather unportable between
1859 character sets--and even within character sets they may cause results
1860 you probably didn't expect.  A sound principle is to use only ranges
1861 that begin from and end at either alphabetics of equal case ([a-e],
1862 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1863 spell out the character sets in full.
1864
1865 Characters may be specified using a metacharacter syntax much like that
1866 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1867 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1868 of three octal digits, matches the character whose coded character set value
1869 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1870 matches the character whose ordinal is I<nn>. The expression \cI<x>
1871 matches the character control-I<x>.  Finally, the "." metacharacter
1872 matches any character except "\n" (unless you use C</s>).
1873
1874 You can specify a series of alternatives for a pattern using "|" to
1875 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1876 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1877 first alternative includes everything from the last pattern delimiter
1878 ("(", "[", or the beginning of the pattern) up to the first "|", and
1879 the last alternative contains everything from the last "|" to the next
1880 pattern delimiter.  That's why it's common practice to include
1881 alternatives in parentheses: to minimize confusion about where they
1882 start and end.
1883
1884 Alternatives are tried from left to right, so the first
1885 alternative found for which the entire expression matches, is the one that
1886 is chosen. This means that alternatives are not necessarily greedy. For
1887 example: when matching C<foo|foot> against "barefoot", only the "foo"
1888 part will match, as that is the first alternative tried, and it successfully
1889 matches the target string. (This might not seem important, but it is
1890 important when you are capturing matched text using parentheses.)
1891
1892 Also remember that "|" is interpreted as a literal within square brackets,
1893 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1894
1895 Within a pattern, you may designate subpatterns for later reference
1896 by enclosing them in parentheses, and you may refer back to the
1897 I<n>th subpattern later in the pattern using the metacharacter
1898 \I<n>.  Subpatterns are numbered based on the left to right order
1899 of their opening parenthesis.  A backreference matches whatever
1900 actually matched the subpattern in the string being examined, not
1901 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
1902 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1903 1 matched "0x", even though the rule C<0|0x> could potentially match
1904 the leading 0 in the second number.
1905
1906 =head2 Warning on \1 Instead of $1
1907
1908 Some people get too used to writing things like:
1909
1910     $pattern =~ s/(\W)/\\\1/g;
1911
1912 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
1913 shocking the
1914 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1915 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1916 the usual double-quoted string means a control-A.  The customary Unix
1917 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1918 of doing that, you get yourself into trouble if you then add an C</e>
1919 modifier.
1920
1921     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
1922
1923 Or if you try to do
1924
1925     s/(\d+)/\1000/;
1926
1927 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1928 C<${1}000>.  The operation of interpolation should not be confused
1929 with the operation of matching a backreference.  Certainly they mean two
1930 different things on the I<left> side of the C<s///>.
1931
1932 =head2 Repeated Patterns Matching a Zero-length Substring
1933
1934 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1935
1936 Regular expressions provide a terse and powerful programming language.  As
1937 with most other power tools, power comes together with the ability
1938 to wreak havoc.
1939
1940 A common abuse of this power stems from the ability to make infinite
1941 loops using regular expressions, with something as innocuous as:
1942
1943     'foo' =~ m{ ( o? )* }x;
1944
1945 The C<o?> matches at the beginning of C<'foo'>, and since the position
1946 in the string is not moved by the match, C<o?> would match again and again
1947 because of the C<*> quantifier.  Another common way to create a similar cycle
1948 is with the looping modifier C<//g>:
1949
1950     @matches = ( 'foo' =~ m{ o? }xg );
1951
1952 or
1953
1954     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1955
1956 or the loop implied by split().
1957
1958 However, long experience has shown that many programming tasks may
1959 be significantly simplified by using repeated subexpressions that
1960 may match zero-length substrings.  Here's a simple example being:
1961
1962     @chars = split //, $string;                  # // is not magic in split
1963     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1964
1965 Thus Perl allows such constructs, by I<forcefully breaking
1966 the infinite loop>.  The rules for this are different for lower-level
1967 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1968 ones like the C</g> modifier or split() operator.
1969
1970 The lower-level loops are I<interrupted> (that is, the loop is
1971 broken) when Perl detects that a repeated expression matched a
1972 zero-length substring.   Thus
1973
1974    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1975
1976 is made equivalent to
1977
1978    m{   (?: NON_ZERO_LENGTH )*
1979       |
1980         (?: ZERO_LENGTH )?
1981     }x;
1982
1983 The higher level-loops preserve an additional state between iterations:
1984 whether the last match was zero-length.  To break the loop, the following
1985 match after a zero-length match is prohibited to have a length of zero.
1986 This prohibition interacts with backtracking (see L<"Backtracking">),
1987 and so the I<second best> match is chosen if the I<best> match is of
1988 zero length.
1989
1990 For example:
1991
1992     $_ = 'bar';
1993     s/\w??/<$&>/g;
1994
1995 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1996 match given by non-greedy C<??> is the zero-length match, and the I<second
1997 best> match is what is matched by C<\w>.  Thus zero-length matches
1998 alternate with one-character-long matches.
1999
2000 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2001 position one notch further in the string.
2002
2003 The additional state of being I<matched with zero-length> is associated with
2004 the matched string, and is reset by each assignment to pos().
2005 Zero-length matches at the end of the previous match are ignored
2006 during C<split>.
2007
2008 =head2 Combining RE Pieces
2009
2010 Each of the elementary pieces of regular expressions which were described
2011 before (such as C<ab> or C<\Z>) could match at most one substring
2012 at the given position of the input string.  However, in a typical regular
2013 expression these elementary pieces are combined into more complicated
2014 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
2015 (in these examples C<S> and C<T> are regular subexpressions).
2016
2017 Such combinations can include alternatives, leading to a problem of choice:
2018 if we match a regular expression C<a|ab> against C<"abc">, will it match
2019 substring C<"a"> or C<"ab">?  One way to describe which substring is
2020 actually matched is the concept of backtracking (see L<"Backtracking">).
2021 However, this description is too low-level and makes you think
2022 in terms of a particular implementation.
2023
2024 Another description starts with notions of "better"/"worse".  All the
2025 substrings which may be matched by the given regular expression can be
2026 sorted from the "best" match to the "worst" match, and it is the "best"
2027 match which is chosen.  This substitutes the question of "what is chosen?"
2028 by the question of "which matches are better, and which are worse?".
2029
2030 Again, for elementary pieces there is no such question, since at most
2031 one match at a given position is possible.  This section describes the
2032 notion of better/worse for combining operators.  In the description
2033 below C<S> and C<T> are regular subexpressions.
2034
2035 =over 4
2036
2037 =item C<ST>
2038
2039 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2040 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2041 which can be matched by C<T>.
2042
2043 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
2044 match than C<A'B'>.
2045
2046 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2047 C<B> is better match for C<T> than C<B'>.
2048
2049 =item C<S|T>
2050
2051 When C<S> can match, it is a better match than when only C<T> can match.
2052
2053 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2054 two matches for C<T>.
2055
2056 =item C<S{REPEAT_COUNT}>
2057
2058 Matches as C<SSS...S> (repeated as many times as necessary).
2059
2060 =item C<S{min,max}>
2061
2062 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2063
2064 =item C<S{min,max}?>
2065
2066 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2067
2068 =item C<S?>, C<S*>, C<S+>
2069
2070 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2071
2072 =item C<S??>, C<S*?>, C<S+?>
2073
2074 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2075
2076 =item C<< (?>S) >>
2077
2078 Matches the best match for C<S> and only that.
2079
2080 =item C<(?=S)>, C<(?<=S)>
2081
2082 Only the best match for C<S> is considered.  (This is important only if
2083 C<S> has capturing parentheses, and backreferences are used somewhere
2084 else in the whole regular expression.)
2085
2086 =item C<(?!S)>, C<(?<!S)>
2087
2088 For this grouping operator there is no need to describe the ordering, since
2089 only whether or not C<S> can match is important.
2090
2091 =item C<(??{ EXPR })>, C<(?PARNO)>
2092
2093 The ordering is the same as for the regular expression which is
2094 the result of EXPR, or the pattern contained by capture group PARNO.
2095
2096 =item C<(?(condition)yes-pattern|no-pattern)>
2097
2098 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2099 already determined.  The ordering of the matches is the same as for the
2100 chosen subexpression.
2101
2102 =back
2103
2104 The above recipes describe the ordering of matches I<at a given position>.
2105 One more rule is needed to understand how a match is determined for the
2106 whole regular expression: a match at an earlier position is always better
2107 than a match at a later position.
2108
2109 =head2 Creating Custom RE Engines
2110
2111 Overloaded constants (see L<overload>) provide a simple way to extend
2112 the functionality of the RE engine.
2113
2114 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2115 matches at a boundary between whitespace characters and non-whitespace
2116 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2117 at these positions, so we want to have each C<\Y|> in the place of the
2118 more complicated version.  We can create a module C<customre> to do
2119 this:
2120
2121     package customre;
2122     use overload;
2123
2124     sub import {
2125       shift;
2126       die "No argument to customre::import allowed" if @_;
2127       overload::constant 'qr' => \&convert;
2128     }
2129
2130     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2131
2132     # We must also take care of not escaping the legitimate \\Y|
2133     # sequence, hence the presence of '\\' in the conversion rules.
2134     my %rules = ( '\\' => '\\\\',
2135                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2136     sub convert {
2137       my $re = shift;
2138       $re =~ s{
2139                 \\ ( \\ | Y . )
2140               }
2141               { $rules{$1} or invalid($re,$1) }sgex;
2142       return $re;
2143     }
2144
2145 Now C<use customre> enables the new escape in constant regular
2146 expressions, i.e., those without any runtime variable interpolations.
2147 As documented in L<overload>, this conversion will work only over
2148 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2149 part of this regular expression needs to be converted explicitly
2150 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2151
2152     use customre;
2153     $re = <>;
2154     chomp $re;
2155     $re = customre::convert $re;
2156     /\Y|$re\Y|/;
2157
2158 =head1 PCRE/Python Support
2159
2160 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2161 to the regex syntax. While Perl programmers are encouraged to use the
2162 Perl specific syntax, the following are also accepted:
2163
2164 =over 4
2165
2166 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2167
2168 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2169
2170 =item C<< (?P=NAME) >>
2171
2172 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2173
2174 =item C<< (?P>NAME) >>
2175
2176 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2177
2178 =back
2179
2180 =head1 BUGS
2181
2182 There are numerous problems with case insensitive matching of characters
2183 outside the ASCII range, especially with those whose folds are multiple
2184 characters, such as ligatures like C<LATIN SMALL LIGATURE FF>.
2185
2186 In a bracketed character class with case insensitive matching, ranges only work
2187 for ASCII characters.  For example,
2188 C<m/[\N{CYRILLIC CAPITAL LETTER A}-\N{CYRILLIC CAPITAL LETTER YA}]/i>
2189 doesn't match all the Russian upper and lower case letters.
2190
2191 Many regular expression constructs don't work on EBCDIC platforms.
2192
2193 This document varies from difficult to understand to completely
2194 and utterly opaque.  The wandering prose riddled with jargon is
2195 hard to fathom in several places.
2196
2197 This document needs a rewrite that separates the tutorial content
2198 from the reference content.
2199
2200 =head1 SEE ALSO
2201
2202 L<perlrequick>.
2203
2204 L<perlretut>.
2205
2206 L<perlop/"Regexp Quote-Like Operators">.
2207
2208 L<perlop/"Gory details of parsing quoted constructs">.
2209
2210 L<perlfaq6>.
2211
2212 L<perlfunc/pos>.
2213
2214 L<perllocale>.
2215
2216 L<perlebcdic>.
2217
2218 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2219 by O'Reilly and Associates.