regen/regen_lib.pl

   1 #!/usr/bin/perl -w
   2 use strict;
   3 use vars qw($Needs_Write $Verbose @Changed $TAP);
   4 use File::Compare;
   5 use Symbol;
   6 use Text::Wrap;
   7
   8 # Common functions needed by the regen scripts
   9
  10 $Needs_Write = $^O eq 'cygwin' || $^O eq 'os2' || $^O eq 'MSWin32';
  11
  12 $Verbose = 0;
  13 @ARGV = grep { not($_ eq '-q' and $Verbose = -1) }
  14   grep { not($_ eq '--tap' and $TAP = 1) }
  15   grep { not($_ eq '-v' and $Verbose = 1) } @ARGV;
  16
  17 END {
  18   print STDOUT "Changed: @Changed\n" if @Changed;
  19 }
  20
  21 sub safer_unlink {
  22   my @names = @_;
  23   my $cnt = 0;
  24
  25   my $name;
  26   foreach $name (@names) {
  27     next unless -e $name;
  28     chmod 0777, $name if $Needs_Write;
  29     ( CORE::unlink($name) and ++$cnt
  30       or warn "Couldn't unlink $name: $!\n" );
  31   }
  32   return $cnt;
  33 }
  34
  35 sub safer_rename_silent {
  36   my ($from, $to) = @_;
  37
  38   # Some dosish systems can't rename over an existing file:
  39   safer_unlink $to;
  40   chmod 0600, $from if $Needs_Write;
  41   rename $from, $to;
  42 }
  43
  44 sub rename_if_different {
  45   my ($from, $to) = @_;
  46
  47   if ($TAP) {
  48       my $not = compare($from, $to) ? 'not ' : '';
  49       print STDOUT $not . "ok - $0 $to\n";
  50       safer_unlink($from);
  51       return;
  52   }
  53   if (compare($from, $to) == 0) {
  54       warn "no changes between '$from' & '$to'\n" if $Verbose > 0;
  55       safer_unlink($from);
  56       return;
  57   }
  58   warn "changed '$from' to '$to'\n" if $Verbose > 0;
  59   push @Changed, $to unless $Verbose < 0;
  60   safer_rename_silent($from, $to) or die "renaming $from to $to: $!";
  61 }
  62
  63 # Saf*er*, but not totally safe. And assumes always open for output.
  64 sub safer_open {
  65     my $name = shift;
  66     if (-f $name) {
  67         unlink $name or die "$name exists but can't unlink: $!";
  68     }
  69     my $fh = gensym;
  70     open $fh, ">$name" or die "Can't create $name: $!";
  71     *{$fh}->{name} = $name;
  72     binmode $fh;
  73     $fh;
  74 }
  75
  76 sub safer_close {
  77     my $fh = shift;
  78     close $fh or die 'Error closing ' . *{$fh}->{name} . ": $!";
  79 }
  80
  81 sub read_only_top {
  82     my %args = @_;
  83     die "Missing language argument" unless defined $args{lang};
  84     die "Unknown language argument '$args{lang}'"
  85         unless $args{lang} eq 'Perl' or $args{lang} eq 'C';
  86     my $style = $args{style} ? " $args{style} " : '   ';
  87
  88     my $raw = "-*- buffer-read-only: t -*-\n";
  89
  90     if ($args{file}) {
  91         $raw .= "\n   $args{file}\n";
  92     }
  93     if ($args{copyright}) {
  94         local $" = ', ';
  95         local $Text::Wrap::columns = 75;
  96         $raw .= wrap('   ', '   ', <<"EOM") . "\n";
  97
  98 Copyright (C) @{$args{copyright}} by\0Larry\0Wall\0and\0others
  99
 100 You may distribute under the terms of either the GNU General Public
 101 License or the Artistic License, as specified in the README file.
 102 EOM
 103     }
 104
 105     $raw .= "!!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!\n";
 106
 107     if ($args{by}) {
 108         $raw .= "This file is built by $args{by}";
 109         if ($args{from}) {
 110             my @from = ref $args{from} eq 'ARRAY' ? @{$args{from}} : $args{from};
 111             my $last = pop @from;
 112             if (@from) {
 113                 $raw .= ' from ' . join (', ', @from) . " and $last";
 114             } else {
 115                 $raw .= " from $last";
 116             }
 117         }
 118         $raw .= ".\n";
 119     }
 120     $raw .= "Any changes made here will be lost!\n";
 121     $raw .= $args{final} if $args{final};
 122
 123     local $Text::Wrap::columns = 78;
 124     my $cooked = $args{lang} eq 'Perl'
 125         ? wrap('# ', '# ', $raw) . "\n" : wrap('/* ', $style, $raw) . " */\n\n";
 126     $cooked =~ tr/\0/ /; # Don't break Larry's name etc
 127     $cooked =~ s/ +$//mg; # Remove all trailing spaces
 128     return $cooked;
 129 }
 130
 131 1;