This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perllocale: Nits
[perl5.git] / pod / perllocale.pod
1 =encoding utf8
2
3 =head1 NAME
4
5 perllocale - Perl locale handling (internationalization and localization)
6
7 =head1 DESCRIPTION
8
9 In the beginning there was ASCII, the "American Standard Code for
10 Information Interchange", which works quite well for Americans with
11 their English alphabet and dollar-denominated currency.  But it doesn't
12 work so well even for other English speakers, who may use different
13 currencies, such as the pound sterling (as the symbol for that currency
14 is not in ASCII); and it's hopelessly inadequate for many of the
15 thousands of the world's other languages.
16
17 To address these deficiencies, the concept of locales was invented
18 (formally the ISO C, XPG4, POSIX 1.c "locale system").  And applications
19 were and are being written that use the locale mechanism.  The process of
20 making such an application take account of its users' preferences in
21 these kinds of matters is called B<internationalization> (often
22 abbreviated as B<i18n>); telling such an application about a particular
23 set of preferences is known as B<localization> (B<l10n>).
24
25 Perl has been extended to support the locale system.  This
26 is controlled per application by using one pragma, one function call,
27 and several environment variables.
28
29 Unfortunately, there are quite a few deficiencies with the design (and
30 often, the implementations) of locales, and their use for character sets
31 has mostly been supplanted by Unicode (see L<perlunitut> for an
32 introduction to that, and keep on reading here for how Unicode interacts
33 with locales in Perl).
34
35 Perl continues to support the old locale system, and starting in v5.16,
36 provides a hybrid way to use the Unicode character set, along with the
37 other portions of locales that may not be so problematic.
38 (Unicode is also creating C<CLDR>, the "Common Locale Data Repository",
39 L<http://cldr.unicode.org/> which includes more types of information than
40 are available in the POSIX locale system.  At the time of this writing,
41 there was no CPAN module that provides access to this XML-encoded data.
42 However, many of its locales have the POSIX-only data extracted, and are
43 available at L<http://unicode.org/Public/cldr/latest/>.)
44
45 =head1 WHAT IS A LOCALE
46
47 A locale is a set of data that describes various aspects of how various
48 communities in the world categorize their world.  These categories are
49 broken down into the following types (some of which include a brief
50 note here):
51
52 =over
53
54 =item Category LC_NUMERIC: Numeric formatting
55
56 This indicates how numbers should be formatted for human readability,
57 for example the character used as the decimal point.
58
59 =item Category LC_MONETARY: Formatting of monetary amounts
60
61 =for comment
62 The nbsp below makes this look better
63
64 E<160>
65
66 =item Category LC_TIME: Date/Time formatting
67
68 =for comment
69 The nbsp below makes this look better
70
71 E<160>
72
73 =item Category LC_MESSAGES: Error and other messages
74
75 This for the most part is beyond the scope of Perl
76
77 =item Category LC_COLLATE: Collation
78
79 This indicates the ordering of letters for comparison and sorting.
80 In Latin alphabets, for example, "b", generally follows "a".
81
82 =item Category LC_CTYPE: Character Types
83
84 This indicates, for example if a character is an uppercase letter.
85
86 =back
87
88 More details on the categories are given below in L</LOCALE CATEGORIES>.
89
90 Together, these categories go a long way towards being able to customize
91 a single program to run in many different locations.  But there are
92 deficiencies, so keep reading.
93
94 =head1 PREPARING TO USE LOCALES
95
96 Perl will not use locales unless specifically requested to (see L</NOTES> below
97 for the partial exception of C<write()>).  But even if there is such a
98 request, B<all> of the following must be true for it to work properly:
99
100 =over 4
101
102 =item *
103
104 B<Your operating system must support the locale system>.  If it does,
105 you should find that the C<setlocale()> function is a documented part of
106 its C library.
107
108 =item *
109
110 B<Definitions for locales that you use must be installed>.  You, or
111 your system administrator, must make sure that this is the case. The
112 available locales, the location in which they are kept, and the manner
113 in which they are installed all vary from system to system.  Some systems
114 provide only a few, hard-wired locales and do not allow more to be
115 added.  Others allow you to add "canned" locales provided by the system
116 supplier.  Still others allow you or the system administrator to define
117 and add arbitrary locales.  (You may have to ask your supplier to
118 provide canned locales that are not delivered with your operating
119 system.)  Read your system documentation for further illumination.
120
121 =item *
122
123 B<Perl must believe that the locale system is supported>.  If it does,
124 C<perl -V:d_setlocale> will say that the value for C<d_setlocale> is
125 C<define>.
126
127 =back
128
129 If you want a Perl application to process and present your data
130 according to a particular locale, the application code should include
131 the S<C<use locale>> pragma (see L<The use locale pragma>) where
132 appropriate, and B<at least one> of the following must be true:
133
134 =over 4
135
136 =item 1
137
138 B<The locale-determining environment variables (see L</"ENVIRONMENT">)
139 must be correctly set up> at the time the application is started, either
140 by yourself or by whomever set up your system account; or
141
142 =item 2
143
144 B<The application must set its own locale> using the method described in
145 L<The setlocale function>.
146
147 =back
148
149 =head1 USING LOCALES
150
151 =head2 The use locale pragma
152
153 By default, Perl ignores the current locale.  The S<C<use locale>>
154 pragma tells Perl to use the current locale for some operations.
155 Starting in v5.16, there is an optional parameter to this pragma:
156
157     use locale ':not_characters';
158
159 This parameter allows better mixing of locales and Unicode, and is
160 described fully in L</Unicode and UTF-8>, but briefly, it tells Perl to
161 not use the character portions of the locale definition, that is
162 the C<LC_CTYPE> and C<LC_COLLATE> categories.  Instead it will use the
163 native (extended by Unicode) character set.  When using this parameter,
164 you are responsible for getting the external character set translated
165 into the native/Unicode one (which it already will be if it is one of
166 the increasingly popular UTF-8 locales).  There are convenient ways of
167 doing this, as described in L</Unicode and UTF-8>.
168
169 The current locale is set at execution time by
170 L<setlocale()|/The setlocale function> described below.  If that function
171 hasn't yet been called in the course of the program's execution, the
172 current locale is that which was determined by the L</"ENVIRONMENT"> in
173 effect at the start of the program, except that
174 C<L<LC_NUMERIC|/Category LC_NUMERIC: Numeric Formatting>> is always
175 initialized to the C locale (mentioned under L<Finding locales>).
176 If there is no valid environment, the current locale is undefined.  It
177 is likely, but not necessarily, the "C" locale.
178
179 The operations that are affected by locale are:
180
181 =over 4
182
183 =item B<Under C<use locale ':not_characters';>>
184
185 =over 4
186
187 =item *
188
189 B<Format declarations> (C<format()>) use C<LC_NUMERIC>
190
191 =item *
192
193 B<The POSIX date formatting function> (C<strftime()>) uses C<LC_TIME>.
194
195 =back
196
197 =for comment
198 The nbsp below makes this look better
199
200 E<160>
201
202 =item B<Under just plain C<use locale;>>
203
204 The above operations are affected, as well as the following:
205
206 =over 4
207
208 =item *
209
210 B<The comparison operators> (C<lt>, C<le>, C<cmp>, C<ge>, and C<gt>) and
211 the POSIX string collation functions C<strcoll()> and C<strxfrm()> use
212 C<LC_COLLATE>.  C<sort()> is also affected if used without an
213 explicit comparison function, because it uses C<cmp> by default.
214
215 B<Note:> C<eq> and C<ne> are unaffected by locale: they always
216 perform a char-by-char comparison of their scalar operands.  What's
217 more, if C<cmp> finds that its operands are equal according to the
218 collation sequence specified by the current locale, it goes on to
219 perform a char-by-char comparison, and only returns I<0> (equal) if the
220 operands are char-for-char identical.  If you really want to know whether
221 two strings--which C<eq> and C<cmp> may consider different--are equal
222 as far as collation in the locale is concerned, see the discussion in
223 L<Category LC_COLLATE: Collation>.
224
225 =item *
226
227 B<Regular expressions and case-modification functions> (C<uc()>, C<lc()>,
228 C<ucfirst()>, and C<lcfirst()>) use C<LC_CTYPE>
229
230 =back
231
232 =back
233
234 The default behavior is restored with the S<C<no locale>> pragma, or
235 upon reaching the end of the block enclosing C<use locale>.
236 Note that C<use locale> and C<use locale ':not_characters'> may be
237 nested, and that what is in effect within an inner scope will revert to
238 the outer scope's rules at the end of the inner scope.
239
240 The string result of any operation that uses locale
241 information is tainted, as it is possible for a locale to be
242 untrustworthy.  See L<"SECURITY">.
243
244 =head2 The setlocale function
245
246 You can switch locales as often as you wish at run time with the
247 C<POSIX::setlocale()> function:
248
249         # Import locale-handling tool set from POSIX module.
250         # This example uses: setlocale -- the function call
251         #                    LC_CTYPE -- explained below
252         use POSIX qw(locale_h);
253
254         # query and save the old locale
255         $old_locale = setlocale(LC_CTYPE);
256
257         setlocale(LC_CTYPE, "fr_CA.ISO8859-1");
258         # LC_CTYPE now in locale "French, Canada, codeset ISO 8859-1"
259
260         setlocale(LC_CTYPE, "");
261         # LC_CTYPE now reset to default defined by LC_ALL/LC_CTYPE/LANG
262         # environment variables.  See below for documentation.
263
264         # restore the old locale
265         setlocale(LC_CTYPE, $old_locale);
266
267 The first argument of C<setlocale()> gives the B<category>, the second the
268 B<locale>.  The category tells in what aspect of data processing you
269 want to apply locale-specific rules.  Category names are discussed in
270 L</LOCALE CATEGORIES> and L</"ENVIRONMENT">.  The locale is the name of a
271 collection of customization information corresponding to a particular
272 combination of language, country or territory, and codeset.  Read on for
273 hints on the naming of locales: not all systems name locales as in the
274 example.
275
276 If no second argument is provided and the category is something other
277 than LC_ALL, the function returns a string naming the current locale
278 for the category.  You can use this value as the second argument in a
279 subsequent call to C<setlocale()>.
280
281 If no second argument is provided and the category is LC_ALL, the
282 result is implementation-dependent.  It may be a string of
283 concatenated locale names (separator also implementation-dependent)
284 or a single locale name.  Please consult your L<setlocale(3)> man page for
285 details.
286
287 If a second argument is given and it corresponds to a valid locale,
288 the locale for the category is set to that value, and the function
289 returns the now-current locale value.  You can then use this in yet
290 another call to C<setlocale()>.  (In some implementations, the return
291 value may sometimes differ from the value you gave as the second
292 argument--think of it as an alias for the value you gave.)
293
294 As the example shows, if the second argument is an empty string, the
295 category's locale is returned to the default specified by the
296 corresponding environment variables.  Generally, this results in a
297 return to the default that was in force when Perl started up: changes
298 to the environment made by the application after startup may or may not
299 be noticed, depending on your system's C library.
300
301 If the second argument does not correspond to a valid locale, the locale
302 for the category is not changed, and the function returns C<undef>.
303
304 Note that Perl ignores the current C<LC_CTYPE> and C<LC_COLLATE> locales
305 within the scope of a C<use locale ':not_characters'>.
306
307 For further information about the categories, consult L<setlocale(3)>.
308
309 =head2 Finding locales
310
311 For locales available in your system, consult also L<setlocale(3)> to
312 see whether it leads to the list of available locales (search for the
313 I<SEE ALSO> section).  If that fails, try the following command lines:
314
315         locale -a
316
317         nlsinfo
318
319         ls /usr/lib/nls/loc
320
321         ls /usr/lib/locale
322
323         ls /usr/lib/nls
324
325         ls /usr/share/locale
326
327 and see whether they list something resembling these
328
329         en_US.ISO8859-1     de_DE.ISO8859-1     ru_RU.ISO8859-5
330         en_US.iso88591      de_DE.iso88591      ru_RU.iso88595
331         en_US               de_DE               ru_RU
332         en                  de                  ru
333         english             german              russian
334         english.iso88591    german.iso88591     russian.iso88595
335         english.roman8                          russian.koi8r
336
337 Sadly, even though the calling interface for C<setlocale()> has been
338 standardized, names of locales and the directories where the
339 configuration resides have not been.  The basic form of the name is
340 I<language_territory>B<.>I<codeset>, but the latter parts after
341 I<language> are not always present.  The I<language> and I<country>
342 are usually from the standards B<ISO 3166> and B<ISO 639>, the
343 two-letter abbreviations for the countries and the languages of the
344 world, respectively.  The I<codeset> part often mentions some B<ISO
345 8859> character set, the Latin codesets.  For example, C<ISO 8859-1>
346 is the so-called "Western European codeset" that can be used to encode
347 most Western European languages adequately.  Again, there are several
348 ways to write even the name of that one standard.  Lamentably.
349
350 Two special locales are worth particular mention: "C" and "POSIX".
351 Currently these are effectively the same locale: the difference is
352 mainly that the first one is defined by the C standard, the second by
353 the POSIX standard.  They define the B<default locale> in which
354 every program starts in the absence of locale information in its
355 environment.  (The I<default> default locale, if you will.)  Its language
356 is (American) English and its character codeset ASCII or, rarely, a
357 superset thereof (such as the "DEC Multinational Character Set
358 (DEC-MCS)").  B<Warning>. The C locale delivered by some vendors
359 may not actually exactly match what the C standard calls for.  So
360 beware.
361
362 B<NOTE>: Not all systems have the "POSIX" locale (not all systems are
363 POSIX-conformant), so use "C" when you need explicitly to specify this
364 default locale.
365
366 =head2 LOCALE PROBLEMS
367
368 You may encounter the following warning message at Perl startup:
369
370         perl: warning: Setting locale failed.
371         perl: warning: Please check that your locale settings:
372                 LC_ALL = "En_US",
373                 LANG = (unset)
374             are supported and installed on your system.
375         perl: warning: Falling back to the standard locale ("C").
376
377 This means that your locale settings had LC_ALL set to "En_US" and
378 LANG exists but has no value.  Perl tried to believe you but could not.
379 Instead, Perl gave up and fell back to the "C" locale, the default locale
380 that is supposed to work no matter what.  This usually means your locale
381 settings were wrong, they mention locales your system has never heard
382 of, or the locale installation in your system has problems (for example,
383 some system files are broken or missing).  There are quick and temporary
384 fixes to these problems, as well as more thorough and lasting fixes.
385
386 =head2 Temporarily fixing locale problems
387
388 The two quickest fixes are either to render Perl silent about any
389 locale inconsistencies or to run Perl under the default locale "C".
390
391 Perl's moaning about locale problems can be silenced by setting the
392 environment variable PERL_BADLANG to a zero value, for example "0".
393 This method really just sweeps the problem under the carpet: you tell
394 Perl to shut up even when Perl sees that something is wrong.  Do not
395 be surprised if later something locale-dependent misbehaves.
396
397 Perl can be run under the "C" locale by setting the environment
398 variable LC_ALL to "C".  This method is perhaps a bit more civilized
399 than the PERL_BADLANG approach, but setting LC_ALL (or
400 other locale variables) may affect other programs as well, not just
401 Perl.  In particular, external programs run from within Perl will see
402 these changes.  If you make the new settings permanent (read on), all
403 programs you run see the changes.  See L<"ENVIRONMENT"> for
404 the full list of relevant environment variables and L<USING LOCALES>
405 for their effects in Perl.  Effects in other programs are
406 easily deducible.  For example, the variable LC_COLLATE may well affect
407 your B<sort> program (or whatever the program that arranges "records"
408 alphabetically in your system is called).
409
410 You can test out changing these variables temporarily, and if the
411 new settings seem to help, put those settings into your shell startup
412 files.  Consult your local documentation for the exact details.  For in
413 Bourne-like shells (B<sh>, B<ksh>, B<bash>, B<zsh>):
414
415         LC_ALL=en_US.ISO8859-1
416         export LC_ALL
417
418 This assumes that we saw the locale "en_US.ISO8859-1" using the commands
419 discussed above.  We decided to try that instead of the above faulty
420 locale "En_US"--and in Cshish shells (B<csh>, B<tcsh>)
421
422         setenv LC_ALL en_US.ISO8859-1
423
424 or if you have the "env" application you can do in any shell
425
426         env LC_ALL=en_US.ISO8859-1 perl ...
427
428 If you do not know what shell you have, consult your local
429 helpdesk or the equivalent.
430
431 =head2 Permanently fixing locale problems
432
433 The slower but superior fixes are when you may be able to yourself
434 fix the misconfiguration of your own environment variables.  The
435 mis(sing)configuration of the whole system's locales usually requires
436 the help of your friendly system administrator.
437
438 First, see earlier in this document about L<Finding locales>.  That tells
439 how to find which locales are really supported--and more importantly,
440 installed--on your system.  In our example error message, environment
441 variables affecting the locale are listed in the order of decreasing
442 importance (and unset variables do not matter).  Therefore, having
443 LC_ALL set to "En_US" must have been the bad choice, as shown by the
444 error message.  First try fixing locale settings listed first.
445
446 Second, if using the listed commands you see something B<exactly>
447 (prefix matches do not count and case usually counts) like "En_US"
448 without the quotes, then you should be okay because you are using a
449 locale name that should be installed and available in your system.
450 In this case, see L<Permanently fixing your system's locale configuration>.
451
452 =head2 Permanently fixing your system's locale configuration
453
454 This is when you see something like:
455
456         perl: warning: Please check that your locale settings:
457                 LC_ALL = "En_US",
458                 LANG = (unset)
459             are supported and installed on your system.
460
461 but then cannot see that "En_US" listed by the above-mentioned
462 commands.  You may see things like "en_US.ISO8859-1", but that isn't
463 the same.  In this case, try running under a locale
464 that you can list and which somehow matches what you tried.  The
465 rules for matching locale names are a bit vague because
466 standardization is weak in this area.  See again the
467 L<Finding locales> about general rules.
468
469 =head2 Fixing system locale configuration
470
471 Contact a system administrator (preferably your own) and report the exact
472 error message you get, and ask them to read this same documentation you
473 are now reading.  They should be able to check whether there is something
474 wrong with the locale configuration of the system.  The L<Finding locales>
475 section is unfortunately a bit vague about the exact commands and places
476 because these things are not that standardized.
477
478 =head2 The localeconv function
479
480 The C<POSIX::localeconv()> function allows you to get particulars of the
481 locale-dependent numeric formatting information specified by the current
482 C<LC_NUMERIC> and C<LC_MONETARY> locales.  (If you just want the name of
483 the current locale for a particular category, use C<POSIX::setlocale()>
484 with a single parameter--see L<The setlocale function>.)
485
486         use POSIX qw(locale_h);
487
488         # Get a reference to a hash of locale-dependent info
489         $locale_values = localeconv();
490
491         # Output sorted list of the values
492         for (sort keys %$locale_values) {
493             printf "%-20s = %s\n", $_, $locale_values->{$_}
494         }
495
496 C<localeconv()> takes no arguments, and returns B<a reference to> a hash.
497 The keys of this hash are variable names for formatting, such as
498 C<decimal_point> and C<thousands_sep>.  The values are the
499 corresponding, er, values.  See L<POSIX/localeconv> for a longer
500 example listing the categories an implementation might be expected to
501 provide; some provide more and others fewer.  You don't need an
502 explicit C<use locale>, because C<localeconv()> always observes the
503 current locale.
504
505 Here's a simple-minded example program that rewrites its command-line
506 parameters as integers correctly formatted in the current locale:
507
508     use POSIX qw(locale_h);
509
510     # Get some of locale's numeric formatting parameters
511     my ($thousands_sep, $grouping) =
512             @{localeconv()}{'thousands_sep', 'grouping'};
513
514     # Apply defaults if values are missing
515     $thousands_sep = ',' unless $thousands_sep;
516
517     # grouping and mon_grouping are packed lists
518     # of small integers (characters) telling the
519     # grouping (thousand_seps and mon_thousand_seps
520     # being the group dividers) of numbers and
521     # monetary quantities.  The integers' meanings:
522     # 255 means no more grouping, 0 means repeat
523     # the previous grouping, 1-254 means use that
524     # as the current grouping.  Grouping goes from
525     # right to left (low to high digits).  In the
526     # below we cheat slightly by never using anything
527     # else than the first grouping (whatever that is).
528     if ($grouping) {
529         @grouping = unpack("C*", $grouping);
530     } else {
531         @grouping = (3);
532     }
533
534     # Format command line params for current locale
535     for (@ARGV) {
536         $_ = int;    # Chop non-integer part
537         1 while
538         s/(\d)(\d{$grouping[0]}($|$thousands_sep))/$1$thousands_sep$2/;
539         print "$_";
540     }
541     print "\n";
542
543 =head2 I18N::Langinfo
544
545 Another interface for querying locale-dependent information is the
546 C<I18N::Langinfo::langinfo()> function, available at least in Unix-like
547 systems and VMS.
548
549 The following example will import the C<langinfo()> function itself and
550 three constants to be used as arguments to C<langinfo()>: a constant for
551 the abbreviated first day of the week (the numbering starts from
552 Sunday = 1) and two more constants for the affirmative and negative
553 answers for a yes/no question in the current locale.
554
555     use I18N::Langinfo qw(langinfo ABDAY_1 YESSTR NOSTR);
556
557     my ($abday_1, $yesstr, $nostr)
558                 = map { langinfo } qw(ABDAY_1 YESSTR NOSTR);
559
560     print "$abday_1? [$yesstr/$nostr] ";
561
562 In other words, in the "C" (or English) locale the above will probably
563 print something like:
564
565     Sun? [yes/no]
566
567 See L<I18N::Langinfo> for more information.
568
569 =head1 LOCALE CATEGORIES
570
571 The following subsections describe basic locale categories.  Beyond these,
572 some combination categories allow manipulation of more than one
573 basic category at a time.  See L<"ENVIRONMENT"> for a discussion of these.
574
575 =head2 Category LC_COLLATE: Collation
576
577 In the scope of S<C<use locale>> (but not a
578 C<use locale ':not_characters'>), Perl looks to the C<LC_COLLATE>
579 environment variable to determine the application's notions on collation
580 (ordering) of characters.  For example, "b" follows "a" in Latin
581 alphabets, but where do "E<aacute>" and "E<aring>" belong?  And while
582 "color" follows "chocolate" in English, what about in traditional Spanish?
583
584 The following collations all make sense and you may meet any of them
585 if you "use locale".
586
587         A B C D E a b c d e
588         A a B b C c D d E e
589         a A b B c C d D e E
590         a b c d e A B C D E
591
592 Here is a code snippet to tell what "word"
593 characters are in the current locale, in that locale's order:
594
595         use locale;
596         print +(sort grep /\w/, map { chr } 0..255), "\n";
597
598 Compare this with the characters that you see and their order if you
599 state explicitly that the locale should be ignored:
600
601         no locale;
602         print +(sort grep /\w/, map { chr } 0..255), "\n";
603
604 This machine-native collation (which is what you get unless S<C<use
605 locale>> has appeared earlier in the same block) must be used for
606 sorting raw binary data, whereas the locale-dependent collation of the
607 first example is useful for natural text.
608
609 As noted in L<USING LOCALES>, C<cmp> compares according to the current
610 collation locale when C<use locale> is in effect, but falls back to a
611 char-by-char comparison for strings that the locale says are equal. You
612 can use C<POSIX::strcoll()> if you don't want this fall-back:
613
614         use POSIX qw(strcoll);
615         $equal_in_locale =
616             !strcoll("space and case ignored", "SpaceAndCaseIgnored");
617
618 C<$equal_in_locale> will be true if the collation locale specifies a
619 dictionary-like ordering that ignores space characters completely and
620 which folds case.
621
622 If you have a single string that you want to check for "equality in
623 locale" against several others, you might think you could gain a little
624 efficiency by using C<POSIX::strxfrm()> in conjunction with C<eq>:
625
626         use POSIX qw(strxfrm);
627         $xfrm_string = strxfrm("Mixed-case string");
628         print "locale collation ignores spaces\n"
629             if $xfrm_string eq strxfrm("Mixed-casestring");
630         print "locale collation ignores hyphens\n"
631             if $xfrm_string eq strxfrm("Mixedcase string");
632         print "locale collation ignores case\n"
633             if $xfrm_string eq strxfrm("mixed-case string");
634
635 C<strxfrm()> takes a string and maps it into a transformed string for use
636 in char-by-char comparisons against other transformed strings during
637 collation.  "Under the hood", locale-affected Perl comparison operators
638 call C<strxfrm()> for both operands, then do a char-by-char
639 comparison of the transformed strings.  By calling C<strxfrm()> explicitly
640 and using a non locale-affected comparison, the example attempts to save
641 a couple of transformations.  But in fact, it doesn't save anything: Perl
642 magic (see L<perlguts/Magic Variables>) creates the transformed version of a
643 string the first time it's needed in a comparison, then keeps this version around
644 in case it's needed again.  An example rewritten the easy way with
645 C<cmp> runs just about as fast.  It also copes with null characters
646 embedded in strings; if you call C<strxfrm()> directly, it treats the first
647 null it finds as a terminator.  don't expect the transformed strings
648 it produces to be portable across systems--or even from one revision
649 of your operating system to the next.  In short, don't call C<strxfrm()>
650 directly: let Perl do it for you.
651
652 Note: C<use locale> isn't shown in some of these examples because it isn't
653 needed: C<strcoll()> and C<strxfrm()> exist only to generate locale-dependent
654 results, and so always obey the current C<LC_COLLATE> locale.
655
656 =head2 Category LC_CTYPE: Character Types
657
658 In the scope of S<C<use locale>> (but not a
659 C<use locale ':not_characters'>), Perl obeys the C<LC_CTYPE> locale
660 setting.  This controls the application's notion of which characters are
661 alphabetic.  This affects Perl's C<\w> regular expression metanotation,
662 which stands for alphanumeric characters--that is, alphabetic,
663 numeric, and including other special characters such as the underscore or
664 hyphen.  (Consult L<perlre> for more information about
665 regular expressions.)  Thanks to C<LC_CTYPE>, depending on your locale
666 setting, characters like "E<aelig>", "E<eth>", "E<szlig>", and
667 "E<oslash>" may be understood as C<\w> characters.
668
669 The C<LC_CTYPE> locale also provides the map used in transliterating
670 characters between lower and uppercase.  This affects the case-mapping
671 functions--C<fc()>, C<lc()>, C<lcfirst()>, C<uc()>, and C<ucfirst()>; case-mapping
672 interpolation with C<\F>, C<\l>, C<\L>, C<\u>, or C<\U> in double-quoted
673 strings and C<s///> substitutions; and case-independent regular expression
674 pattern matching using the C<i> modifier.
675
676 Finally, C<LC_CTYPE> affects the POSIX character-class test
677 functions--C<isalpha()>, C<islower()>, and so on.  For example, if you move
678 from the "C" locale to a 7-bit Scandinavian one, you may find--possibly
679 to your surprise--that "|" moves from the C<ispunct()> class to C<isalpha()>.
680 Unfortunately, this creates big problems for regular expressions. "|" still
681 means alternation even though it matches C<\w>.
682
683 Note that there are quite a few things that are unaffected by the
684 current locale.  All the escape sequences for particular characters,
685 C<\n> for example, always mean the platform's native one.  This means,
686 for example, that C<\N> in regular expressions (every character
687 but new-line) work on the platform character set.
688
689 B<Note:> A broken or malicious C<LC_CTYPE> locale definition may result
690 in clearly ineligible characters being considered to be alphanumeric by
691 your application.  For strict matching of (mundane) ASCII letters and
692 digits--for example, in command strings--locale-aware applications
693 should use C<\w> with the C</a> regular expression modifier.  See L<"SECURITY">.
694
695 =head2 Category LC_NUMERIC: Numeric Formatting
696
697 After a proper C<POSIX::setlocale()> call, Perl obeys the C<LC_NUMERIC>
698 locale information, which controls an application's idea of how numbers
699 should be formatted for human readability by the C<printf()>, C<sprintf()>, and
700 C<write()> functions. String-to-numeric conversion by the C<POSIX::strtod()>
701 function is also affected.  In most implementations the only effect is to
702 change the character used for the decimal point--perhaps from "."  to ",".
703 These functions aren't aware of such niceties as thousands separation and
704 so on. (See L<The localeconv function> if you care about these things.)
705
706 Output produced by print() is also affected by the current locale: it
707 corresponds to what you'd get from printf() in the "C" locale.  The
708 same is true for Perl's internal conversions between numeric and
709 string formats:
710
711         use POSIX qw(strtod setlocale LC_NUMERIC);
712
713         setlocale LC_NUMERIC, "";
714
715         $n = 5/2;   # Assign numeric 2.5 to $n
716
717         $a = " $n"; # Locale-dependent conversion to string
718
719         print "half five is $n\n";       # Locale-dependent output
720
721         printf "half five is %g\n", $n;  # Locale-dependent output
722
723         print "DECIMAL POINT IS COMMA\n"
724             if $n == (strtod("2,5"))[0]; # Locale-dependent conversion
725
726 See also L<I18N::Langinfo> and C<RADIXCHAR>.
727
728 =head2 Category LC_MONETARY: Formatting of monetary amounts
729
730 The C standard defines the C<LC_MONETARY> category, but not a function
731 that is affected by its contents.  (Those with experience of standards
732 committees will recognize that the working group decided to punt on the
733 issue.)  Consequently, Perl takes no notice of it.  If you really want
734 to use C<LC_MONETARY>, you can query its contents--see
735 L<The localeconv function>--and use the information that it returns in your
736 application's own formatting of currency amounts.  However, you may well
737 find that the information, voluminous and complex though it may be, still
738 does not quite meet your requirements: currency formatting is a hard nut
739 to crack.
740
741 See also L<I18N::Langinfo> and C<CRNCYSTR>.
742
743 =head2 LC_TIME
744
745 Output produced by C<POSIX::strftime()>, which builds a formatted
746 human-readable date/time string, is affected by the current C<LC_TIME>
747 locale.  Thus, in a French locale, the output produced by the C<%B>
748 format element (full month name) for the first month of the year would
749 be "janvier".  Here's how to get a list of long month names in the
750 current locale:
751
752         use POSIX qw(strftime);
753         for (0..11) {
754             $long_month_name[$_] =
755                 strftime("%B", 0, 0, 0, 1, $_, 96);
756         }
757
758 Note: C<use locale> isn't needed in this example: as a function that
759 exists only to generate locale-dependent results, C<strftime()> always
760 obeys the current C<LC_TIME> locale.
761
762 See also L<I18N::Langinfo> and C<ABDAY_1>..C<ABDAY_7>, C<DAY_1>..C<DAY_7>,
763 C<ABMON_1>..C<ABMON_12>, and C<ABMON_1>..C<ABMON_12>.
764
765 =head2 Other categories
766
767 The remaining locale category, C<LC_MESSAGES> (possibly supplemented
768 by others in particular implementations) is not currently used by
769 Perl--except possibly to affect the behavior of library functions
770 called by extensions outside the standard Perl distribution and by the
771 operating system and its utilities.  Note especially that the string
772 value of C<$!> and the error messages given by external utilities may
773 be changed by C<LC_MESSAGES>.  If you want to have portable error
774 codes, use C<%!>.  See L<Errno>.
775
776 =head1 SECURITY
777
778 Although the main discussion of Perl security issues can be found in
779 L<perlsec>, a discussion of Perl's locale handling would be incomplete
780 if it did not draw your attention to locale-dependent security issues.
781 Locales--particularly on systems that allow unprivileged users to
782 build their own locales--are untrustworthy.  A malicious (or just plain
783 broken) locale can make a locale-aware application give unexpected
784 results.  Here are a few possibilities:
785
786 =over 4
787
788 =item *
789
790 Regular expression checks for safe file names or mail addresses using
791 C<\w> may be spoofed by an C<LC_CTYPE> locale that claims that
792 characters such as "E<gt>" and "|" are alphanumeric.
793
794 =item *
795
796 String interpolation with case-mapping, as in, say, C<$dest =
797 "C:\U$name.$ext">, may produce dangerous results if a bogus LC_CTYPE
798 case-mapping table is in effect.
799
800 =item *
801
802 A sneaky C<LC_COLLATE> locale could result in the names of students with
803 "D" grades appearing ahead of those with "A"s.
804
805 =item *
806
807 An application that takes the trouble to use information in
808 C<LC_MONETARY> may format debits as if they were credits and vice versa
809 if that locale has been subverted.  Or it might make payments in US
810 dollars instead of Hong Kong dollars.
811
812 =item *
813
814 The date and day names in dates formatted by C<strftime()> could be
815 manipulated to advantage by a malicious user able to subvert the
816 C<LC_DATE> locale.  ("Look--it says I wasn't in the building on
817 Sunday.")
818
819 =back
820
821 Such dangers are not peculiar to the locale system: any aspect of an
822 application's environment which may be modified maliciously presents
823 similar challenges.  Similarly, they are not specific to Perl: any
824 programming language that allows you to write programs that take
825 account of their environment exposes you to these issues.
826
827 Perl cannot protect you from all possibilities shown in the
828 examples--there is no substitute for your own vigilance--but, when
829 C<use locale> is in effect, Perl uses the tainting mechanism (see
830 L<perlsec>) to mark string results that become locale-dependent, and
831 which may be untrustworthy in consequence.  Here is a summary of the
832 tainting behavior of operators and functions that may be affected by
833 the locale:
834
835 =over 4
836
837 =item  *
838
839 B<Comparison operators> (C<lt>, C<le>, C<ge>, C<gt> and C<cmp>):
840
841 Scalar true/false (or less/equal/greater) result is never tainted.
842
843 =item  *
844
845 B<Case-mapping interpolation> (with C<\l>, C<\L>, C<\u> or C<\U>)
846
847 Result string containing interpolated material is tainted if
848 C<use locale> (but not S<C<use locale ':not_characters'>>) is in effect.
849
850 =item  *
851
852 B<Matching operator> (C<m//>):
853
854 Scalar true/false result never tainted.
855
856 Subpatterns, either delivered as a list-context result or as $1 etc.
857 are tainted if C<use locale> (but not S<C<use locale ':not_characters'>>)
858 is in effect, and the subpattern regular
859 expression contains C<\w> (to match an alphanumeric character), C<\W>
860 (non-alphanumeric character), C<\s> (whitespace character), or C<\S>
861 (non whitespace character).  The matched-pattern variable, $&, $`
862 (pre-match), $' (post-match), and $+ (last match) are also tainted if
863 C<use locale> is in effect and the regular expression contains C<\w>,
864 C<\W>, C<\s>, or C<\S>.
865
866 =item  *
867
868 B<Substitution operator> (C<s///>):
869
870 Has the same behavior as the match operator.  Also, the left
871 operand of C<=~> becomes tainted when C<use locale>
872 (but not S<C<use locale ':not_characters'>>) is in effect if modified as
873 a result of a substitution based on a regular
874 expression match involving C<\w>, C<\W>, C<\s>, or C<\S>; or of
875 case-mapping with C<\l>, C<\L>,C<\u> or C<\U>.
876
877 =item *
878
879 B<Output formatting functions> (C<printf()> and C<write()>):
880
881 Results are never tainted because otherwise even output from print,
882 for example C<print(1/7)>, should be tainted if C<use locale> is in
883 effect.
884
885 =item *
886
887 B<Case-mapping functions> (C<lc()>, C<lcfirst()>, C<uc()>, C<ucfirst()>):
888
889 Results are tainted if C<use locale> (but not
890 S<C<use locale ':not_characters'>>) is in effect.
891
892 =item *
893
894 B<POSIX locale-dependent functions> (C<localeconv()>, C<strcoll()>,
895 C<strftime()>, C<strxfrm()>):
896
897 Results are never tainted.
898
899 =item *
900
901 B<POSIX character class tests> (C<isalnum()>, C<isalpha()>, C<isdigit()>,
902 C<isgraph()>, C<islower()>, C<isprint()>, C<ispunct()>, C<isspace()>, C<isupper()>,
903 C<isxdigit()>):
904
905 True/false results are never tainted.
906
907 =back
908
909 Three examples illustrate locale-dependent tainting.
910 The first program, which ignores its locale, won't run: a value taken
911 directly from the command line may not be used to name an output file
912 when taint checks are enabled.
913
914         #/usr/local/bin/perl -T
915         # Run with taint checking
916
917         # Command line sanity check omitted...
918         $tainted_output_file = shift;
919
920         open(F, ">$tainted_output_file")
921             or warn "Open of $tainted_output_file failed: $!\n";
922
923 The program can be made to run by "laundering" the tainted value through
924 a regular expression: the second example--which still ignores locale
925 information--runs, creating the file named on its command line
926 if it can.
927
928         #/usr/local/bin/perl -T
929
930         $tainted_output_file = shift;
931         $tainted_output_file =~ m%[\w/]+%;
932         $untainted_output_file = $&;
933
934         open(F, ">$untainted_output_file")
935             or warn "Open of $untainted_output_file failed: $!\n";
936
937 Compare this with a similar but locale-aware program:
938
939         #/usr/local/bin/perl -T
940
941         $tainted_output_file = shift;
942         use locale;
943         $tainted_output_file =~ m%[\w/]+%;
944         $localized_output_file = $&;
945
946         open(F, ">$localized_output_file")
947             or warn "Open of $localized_output_file failed: $!\n";
948
949 This third program fails to run because $& is tainted: it is the result
950 of a match involving C<\w> while C<use locale> is in effect.
951
952 =head1 ENVIRONMENT
953
954 =over 12
955
956 =item PERL_BADLANG
957
958 A string that can suppress Perl's warning about failed locale settings
959 at startup.  Failure can occur if the locale support in the operating
960 system is lacking (broken) in some way--or if you mistyped the name of
961 a locale when you set up your environment.  If this environment
962 variable is absent, or has a value that does not evaluate to integer
963 zero--that is, "0" or ""-- Perl will complain about locale setting
964 failures.
965
966 B<NOTE>: PERL_BADLANG only gives you a way to hide the warning message.
967 The message tells about some problem in your system's locale support,
968 and you should investigate what the problem is.
969
970 =back
971
972 The following environment variables are not specific to Perl: They are
973 part of the standardized (ISO C, XPG4, POSIX 1.c) C<setlocale()> method
974 for controlling an application's opinion on data.
975
976 =over 12
977
978 =item LC_ALL
979
980 C<LC_ALL> is the "override-all" locale environment variable. If
981 set, it overrides all the rest of the locale environment variables.
982
983 =item LANGUAGE
984
985 B<NOTE>: C<LANGUAGE> is a GNU extension, it affects you only if you
986 are using the GNU libc.  This is the case if you are using e.g. Linux.
987 If you are using "commercial" Unixes you are most probably I<not>
988 using GNU libc and you can ignore C<LANGUAGE>.
989
990 However, in the case you are using C<LANGUAGE>: it affects the
991 language of informational, warning, and error messages output by
992 commands (in other words, it's like C<LC_MESSAGES>) but it has higher
993 priority than C<LC_ALL>.  Moreover, it's not a single value but
994 instead a "path" (":"-separated list) of I<languages> (not locales).
995 See the GNU C<gettext> library documentation for more information.
996
997 =item LC_CTYPE
998
999 In the absence of C<LC_ALL>, C<LC_CTYPE> chooses the character type
1000 locale.  In the absence of both C<LC_ALL> and C<LC_CTYPE>, C<LANG>
1001 chooses the character type locale.
1002
1003 =item LC_COLLATE
1004
1005 In the absence of C<LC_ALL>, C<LC_COLLATE> chooses the collation
1006 (sorting) locale.  In the absence of both C<LC_ALL> and C<LC_COLLATE>,
1007 C<LANG> chooses the collation locale.
1008
1009 =item LC_MONETARY
1010
1011 In the absence of C<LC_ALL>, C<LC_MONETARY> chooses the monetary
1012 formatting locale.  In the absence of both C<LC_ALL> and C<LC_MONETARY>,
1013 C<LANG> chooses the monetary formatting locale.
1014
1015 =item LC_NUMERIC
1016
1017 In the absence of C<LC_ALL>, C<LC_NUMERIC> chooses the numeric format
1018 locale.  In the absence of both C<LC_ALL> and C<LC_NUMERIC>, C<LANG>
1019 chooses the numeric format.
1020
1021 =item LC_TIME
1022
1023 In the absence of C<LC_ALL>, C<LC_TIME> chooses the date and time
1024 formatting locale.  In the absence of both C<LC_ALL> and C<LC_TIME>,
1025 C<LANG> chooses the date and time formatting locale.
1026
1027 =item LANG
1028
1029 C<LANG> is the "catch-all" locale environment variable. If it is set, it
1030 is used as the last resort after the overall C<LC_ALL> and the
1031 category-specific C<LC_...>.
1032
1033 =back
1034
1035 =head2 Examples
1036
1037 The LC_NUMERIC controls the numeric output:
1038
1039    use locale;
1040    use POSIX qw(locale_h); # Imports setlocale() and the LC_ constants.
1041    setlocale(LC_NUMERIC, "fr_FR") or die "Pardon";
1042    printf "%g\n", 1.23; # If the "fr_FR" succeeded, probably shows 1,23.
1043
1044 and also how strings are parsed by C<POSIX::strtod()> as numbers:
1045
1046    use locale;
1047    use POSIX qw(locale_h strtod);
1048    setlocale(LC_NUMERIC, "de_DE") or die "Entschuldigung";
1049    my $x = strtod("2,34") + 5;
1050    print $x, "\n"; # Probably shows 7,34.
1051
1052 =head1 NOTES
1053
1054 =head2 Backward compatibility
1055
1056 Versions of Perl prior to 5.004 B<mostly> ignored locale information,
1057 generally behaving as if something similar to the C<"C"> locale were
1058 always in force, even if the program environment suggested otherwise
1059 (see L<The setlocale function>).  By default, Perl still behaves this
1060 way for backward compatibility.  If you want a Perl application to pay
1061 attention to locale information, you B<must> use the S<C<use locale>>
1062 pragma (see L<The use locale pragma>) or, in the unlikely event
1063 that you want to do so for just pattern matching, the
1064 C</l> regular expression modifier (see L<perlre/Character set
1065 modifiers>) to instruct it to do so.
1066
1067 Versions of Perl from 5.002 to 5.003 did use the C<LC_CTYPE>
1068 information if available; that is, C<\w> did understand what
1069 were the letters according to the locale environment variables.
1070 The problem was that the user had no control over the feature:
1071 if the C library supported locales, Perl used them.
1072
1073 =head2 I18N:Collate obsolete
1074
1075 In versions of Perl prior to 5.004, per-locale collation was possible
1076 using the C<I18N::Collate> library module.  This module is now mildly
1077 obsolete and should be avoided in new applications.  The C<LC_COLLATE>
1078 functionality is now integrated into the Perl core language: One can
1079 use locale-specific scalar data completely normally with C<use locale>,
1080 so there is no longer any need to juggle with the scalar references of
1081 C<I18N::Collate>.
1082
1083 =head2 Sort speed and memory use impacts
1084
1085 Comparing and sorting by locale is usually slower than the default
1086 sorting; slow-downs of two to four times have been observed.  It will
1087 also consume more memory: once a Perl scalar variable has participated
1088 in any string comparison or sorting operation obeying the locale
1089 collation rules, it will take 3-15 times more memory than before.  (The
1090 exact multiplier depends on the string's contents, the operating system
1091 and the locale.) These downsides are dictated more by the operating
1092 system's implementation of the locale system than by Perl.
1093
1094 =head2 C<write()> and C<LC_NUMERIC>
1095
1096 If a program's environment specifies an LC_NUMERIC locale and C<use
1097 locale> is in effect when the format is declared, the locale is used
1098 to specify the decimal point character in formatted output.  Formatted
1099 output cannot be controlled by C<use locale> at the time when C<write()>
1100 is called.
1101
1102 =head2 Freely available locale definitions
1103
1104 The Unicode CLDR project extracts the POSIX portion of many of its
1105 locales, available at
1106
1107   http://unicode.org/Public/cldr/latest/
1108
1109 There is a large collection of locale definitions at:
1110
1111   http://std.dkuug.dk/i18n/WG15-collection/locales/
1112
1113 You should be aware that it is
1114 unsupported, and is not claimed to be fit for any purpose.  If your
1115 system allows installation of arbitrary locales, you may find the
1116 definitions useful as they are, or as a basis for the development of
1117 your own locales.
1118
1119 =head2 I18n and l10n
1120
1121 "Internationalization" is often abbreviated as B<i18n> because its first
1122 and last letters are separated by eighteen others.  (You may guess why
1123 the internalin ... internaliti ... i18n tends to get abbreviated.)  In
1124 the same way, "localization" is often abbreviated to B<l10n>.
1125
1126 =head2 An imperfect standard
1127
1128 Internationalization, as defined in the C and POSIX standards, can be
1129 criticized as incomplete, ungainly, and having too large a granularity.
1130 (Locales apply to a whole process, when it would arguably be more useful
1131 to have them apply to a single thread, window group, or whatever.)  They
1132 also have a tendency, like standards groups, to divide the world into
1133 nations, when we all know that the world can equally well be divided
1134 into bankers, bikers, gamers, and so on.
1135
1136 =head1 Unicode and UTF-8
1137
1138 The support of Unicode is new starting from Perl version v5.6, and more fully
1139 implemented in version v5.8 and later.  See L<perluniintro>.  It is
1140 strongly recommended that when combining Unicode and locale (starting in
1141 v5.16), you use
1142
1143     use locale ':not_characters';
1144
1145 When this form of the pragma is used, only the non-character portions of
1146 locales are used by Perl, for example C<LC_NUMERIC>.  Perl assumes that
1147 you have translated all the characters it is to operate on into Unicode
1148 (actually the platform's native character set (ASCII or EBCDIC) plus
1149 Unicode).  For data in files, this can conveniently be done by also
1150 specifying
1151
1152     use open ':locale';
1153
1154 This pragma arranges for all inputs from files to be translated into
1155 Unicode from the current locale as specified in the environment (see
1156 L</ENVIRONMENT>), and all outputs to files to be translated back
1157 into the locale.  (See L<open>).  On a per-filehandle basis, you can
1158 instead use the L<PerlIO::locale> module, or the L<Encode::Locale>
1159 module, both available from CPAN.  The latter module also has methods to
1160 ease the handling of C<ARGV> and environment variables, and can be used
1161 on individual strings.  Also, if you know that all your locales will be
1162 UTF-8, as many are these days, you can use the L<B<-C>|perlrun/-C>
1163 command line switch.
1164
1165 This form of the pragma allows essentially seamless handling of locales
1166 with Unicode.  The collation order will be Unicode's.  It is strongly
1167 recommended that when you need to order and sort strings that you use
1168 the standard module L<Unicode::Collate> which gives much better results
1169 in many instances than you can get with the old-style locale handling.
1170
1171 For pre-v5.16 Perls, or if you use the locale pragma without the
1172 C<:not_characters> parameter, Perl tries to work with both Unicode and
1173 locales--but there are problems.
1174
1175 Perl does not handle multi-byte locales in this case, such as have been
1176 used for various
1177 Asian languages, such as Big5 or Shift JIS.  However, the increasingly
1178 common multi-byte UTF-8 locales, if properly implemented, may work
1179 reasonably well (depending on your C library implementation) in this
1180 form of the locale pragma, simply because both
1181 they and Perl store characters that take up multiple bytes the same way.
1182 However, some, if not most, C library implementations may not process
1183 the characters in the upper half of the Latin-1 range (128 - 255)
1184 properly under LC_CTYPE.  To see if a character is a particular type
1185 under a locale, Perl uses the functions like C<isalnum()>.  Your C
1186 library may not work for UTF-8 locales with those functions, instead
1187 only working under the newer wide library functions like C<iswalnum()>.
1188
1189 Perl generally takes the tack to use locale rules on code points that can fit
1190 in a single byte, and Unicode rules for those that can't (though this
1191 isn't uniformly applied, see the note at the end of this section).  This
1192 prevents many problems in locales that aren't UTF-8.  Suppose the locale
1193 is ISO8859-7, Greek.  The character at 0xD7 there is a capital Chi. But
1194 in the ISO8859-1 locale, Latin1, it is a multiplication sign.  The POSIX
1195 regular expression character class C<[[:alpha:]]> will magically match
1196 0xD7 in the Greek locale but not in the Latin one.
1197
1198 However, there are places where this breaks down.  Certain constructs are
1199 for Unicode only, such as C<\p{Alpha}>.  They assume that 0xD7 always has its
1200 Unicode meaning (or the equivalent on EBCDIC platforms).  Since Latin1 is a
1201 subset of Unicode and 0xD7 is the multiplication sign in both Latin1 and
1202 Unicode, C<\p{Alpha}> will never match it, regardless of locale.  A similar
1203 issue occurs with C<\N{...}>.  It is therefore a bad idea to use C<\p{}> or
1204 C<\N{}> under plain C<use locale>--I<unless> you can guarantee that the
1205 locale will be a ISO8859-1.  Use POSIX character classes instead.
1206
1207 Another problem with this approach is that operations that cross the
1208 single byte/multiple byte boundary are not well-defined, and so are
1209 disallowed.  (This boundary is between the codepoints at 255/256.).
1210 For example, lower casing LATIN CAPITAL LETTER Y WITH DIAERESIS (U+0178)
1211 should return LATIN SMALL LETTER Y WITH DIAERESIS (U+00FF).  But in the
1212 Greek locale, for example, there is no character at 0xFF, and Perl
1213 has no way of knowing what the character at 0xFF is really supposed to
1214 represent.  Thus it disallows the operation.  In this mode, the
1215 lowercase of U+0178 is itself.
1216
1217 The same problems ensue if you enable automatic UTF-8-ification of your
1218 standard file handles, default C<open()> layer, and C<@ARGV> on non-ISO8859-1,
1219 non-UTF-8 locales (by using either the B<-C> command line switch or the
1220 C<PERL_UNICODE> environment variable; see L<perlrun>).
1221 Things are read in as UTF-8, which would normally imply a Unicode
1222 interpretation, but the presence of a locale causes them to be interpreted
1223 in that locale instead.  For example, a 0xD7 code point in the Unicode
1224 input, which should mean the multiplication sign, won't be interpreted by
1225 Perl that way under the Greek locale.  This is not a problem
1226 I<provided> you make certain that all locales will always and only be either
1227 an ISO8859-1, or, if you don't have a deficient C library, a UTF-8 locale.
1228
1229 Vendor locales are notoriously buggy, and it is difficult for Perl to test
1230 its locale-handling code because this interacts with code that Perl has no
1231 control over; therefore the locale-handling code in Perl may be buggy as
1232 well.  (However, the Unicode-supplied locales should be better, and
1233 there is a feed back mechanism to correct any problems.  See
1234 L</Freely available locale definitions>.)
1235
1236 If you have Perl v5.16, the problems mentioned above go away if you use
1237 the C<:not_characters> parameter to the locale pragma (except for vendor
1238 bugs in the non-character portions).  If you don't have v5.16, and you
1239 I<do> have locales that work, using them may be worthwhile for certain
1240 specific purposes, as long as you keep in mind the gotchas already
1241 mentioned.  For example, if the collation for your locales works, it
1242 runs faster under locales than under L<Unicode::Collate>; and you gain
1243 access to such things as the local currency symbol and the names of the
1244 months and days of the week.  (But to hammer home the point, in v5.16,
1245 you get this access without the downsides of locales by using the
1246 C<:not_characters> form of the pragma.)
1247
1248 Note: The policy of using locale rules for code points that can fit in a
1249 byte, and Unicode rules for those that can't is not uniformly applied.
1250 Pre-v5.12, it was somewhat haphazard; in v5.12 it was applied fairly
1251 consistently to regular expression matching except for bracketed
1252 character classes; in v5.14 it was extended to all regex matches; and in
1253 v5.16 to the casing operations such as C<"\L"> and C<uc()>.  For
1254 collation, in all releases, the system's C<strxfrm()> function is called,
1255 and whatever it does is what you get.
1256
1257 =head1 BUGS
1258
1259 =head2 Broken systems
1260
1261 In certain systems, the operating system's locale support
1262 is broken and cannot be fixed or used by Perl.  Such deficiencies can
1263 and will result in mysterious hangs and/or Perl core dumps when
1264 C<use locale> is in effect.  When confronted with such a system,
1265 please report in excruciating detail to <F<perlbug@perl.org>>, and
1266 also contact your vendor: bug fixes may exist for these problems
1267 in your operating system.  Sometimes such bug fixes are called an
1268 operating system upgrade.
1269
1270 =head1 SEE ALSO
1271
1272 L<I18N::Langinfo>, L<perluniintro>, L<perlunicode>, L<open>,
1273 L<POSIX/isalnum>, L<POSIX/isalpha>,
1274 L<POSIX/isdigit>, L<POSIX/isgraph>, L<POSIX/islower>,
1275 L<POSIX/isprint>, L<POSIX/ispunct>, L<POSIX/isspace>,
1276 L<POSIX/isupper>, L<POSIX/isxdigit>, L<POSIX/localeconv>,
1277 L<POSIX/setlocale>, L<POSIX/strcoll>, L<POSIX/strftime>,
1278 L<POSIX/strtod>, L<POSIX/strxfrm>.
1279
1280 =head1 HISTORY
1281
1282 Jarkko Hietaniemi's original F<perli18n.pod> heavily hacked by Dominic
1283 Dunlop, assisted by the perl5-porters.  Prose worked over a bit by
1284 Tom Christiansen, and updated by Perl 5 porters.