cpan/File-Path/lib/File/Path.pm

   1 package File::Path;
   2
   3 use 5.005_04;
   4 use strict;
   5
   6 use Cwd 'getcwd';
   7 use File::Basename ();
   8 use File::Spec     ();
   9
  10 BEGIN {
  11     if ($] < 5.006) {
  12         # can't say 'opendir my $dh, $dirname'
  13         # need to initialise $dh
  14         eval "use Symbol";
  15     }
  16 }
  17
  18 use Exporter ();
  19 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK);
  20 $VERSION   = '2.08';
  21 @ISA       = qw(Exporter);
  22 @EXPORT    = qw(mkpath rmtree);
  23 @EXPORT_OK = qw(make_path remove_tree);
  24
  25 my $Is_VMS     = $^O eq 'VMS';
  26 my $Is_MacOS   = $^O eq 'MacOS';
  27
  28 # These OSes complain if you want to remove a file that you have no
  29 # write permission to:
  30 my $Force_Writeable = grep {$^O eq $_} qw(amigaos dos epoc MSWin32 MacOS os2);
  31
  32 # Unix-like systems need to stat each directory in order to detect
  33 # race condition. MS-Windows is immune to this particular attack.
  34 my $Need_Stat_Check = !($^O eq 'MSWin32');
  35
  36 sub _carp {
  37     require Carp;
  38     goto &Carp::carp;
  39 }
  40
  41 sub _croak {
  42     require Carp;
  43     goto &Carp::croak;
  44 }
  45
  46 sub _error {
  47     my $arg     = shift;
  48     my $message = shift;
  49     my $object  = shift;
  50
  51     if ($arg->{error}) {
  52         $object = '' unless defined $object;
  53         $message .= ": $!" if $!;
  54         push @{${$arg->{error}}}, {$object => $message};
  55     }
  56     else {
  57         _carp(defined($object) ? "$message for $object: $!" : "$message: $!");
  58     }
  59 }
  60
  61 sub make_path {
  62     push @_, {} unless @_ and UNIVERSAL::isa($_[-1],'HASH');
  63     goto &mkpath;
  64 }
  65
  66 sub mkpath {
  67     my $old_style = !(@_ and UNIVERSAL::isa($_[-1],'HASH'));
  68
  69     my $arg;
  70     my $paths;
  71
  72     if ($old_style) {
  73         my ($verbose, $mode);
  74         ($paths, $verbose, $mode) = @_;
  75         $paths = [$paths] unless UNIVERSAL::isa($paths,'ARRAY');
  76         $arg->{verbose} = $verbose;
  77         $arg->{mode}    = defined $mode ? $mode : 0777;
  78     }
  79     else {
  80         $arg = pop @_;
  81         $arg->{mode}      = delete $arg->{mask} if exists $arg->{mask};
  82         $arg->{mode}      = 0777 unless exists $arg->{mode};
  83         ${$arg->{error}}  = [] if exists $arg->{error};
  84         $arg->{owner}     = delete $arg->{user} if exists $arg->{user};
  85         $arg->{owner}     = delete $arg->{uid}  if exists $arg->{uid};
  86         if (exists $arg->{owner} and $arg->{owner} =~ /\D/) {
  87             my $uid = (getpwnam $arg->{owner})[2];
  88             if (defined $uid) {
  89                 $arg->{owner} = $uid;
  90             }
  91             else {
  92                 _error($arg, "unable to map $arg->{owner} to a uid, ownership not changed");
  93                 delete $arg->{owner};
  94             }
  95         }
  96         if (exists $arg->{group} and $arg->{group} =~ /\D/) {
  97             my $gid = (getgrnam $arg->{group})[2];
  98             if (defined $gid) {
  99                 $arg->{group} = $gid;
 100             }
 101             else {
 102                 _error($arg, "unable to map $arg->{group} to a gid, group ownership not changed");
 103                 delete $arg->{group};
 104             }
 105         }
 106         if (exists $arg->{owner} and not exists $arg->{group}) {
 107             $arg->{group} = -1; # chown will leave group unchanged
 108         }
 109         if (exists $arg->{group} and not exists $arg->{owner}) {
 110             $arg->{owner} = -1; # chown will leave owner unchanged
 111         }
 112         $paths = [@_];
 113     }
 114     return _mkpath($arg, $paths);
 115 }
 116
 117 sub _mkpath {
 118     my $arg   = shift;
 119     my $paths = shift;
 120
 121     my(@created,$path);
 122     foreach $path (@$paths) {
 123         next unless defined($path) and length($path);
 124         $path .= '/' if $^O eq 'os2' and $path =~ /^\w:\z/s; # feature of CRT
 125         # Logic wants Unix paths, so go with the flow.
 126         if ($Is_VMS) {
 127             next if $path eq '/';
 128             $path = VMS::Filespec::unixify($path);
 129         }
 130         next if -d $path;
 131         my $parent = File::Basename::dirname($path);
 132         unless (-d $parent or $path eq $parent) {
 133             push(@created,_mkpath($arg, [$parent]));
 134         }
 135         print "mkdir $path\n" if $arg->{verbose};
 136         if (mkdir($path,$arg->{mode})) {
 137             push(@created, $path);
 138             if (exists $arg->{owner}) {
 139                                 # NB: $arg->{group} guaranteed to be set during initialisation
 140                 if (!chown $arg->{owner}, $arg->{group}, $path) {
 141                     _error($arg, "Cannot change ownership of $path to $arg->{owner}:$arg->{group}");
 142                 }
 143             }
 144         }
 145         else {
 146             my $save_bang = $!;
 147             my ($e, $e1) = ($save_bang, $^E);
 148             $e .= "; $e1" if $e ne $e1;
 149             # allow for another process to have created it meanwhile
 150             if (!-d $path) {
 151                 $! = $save_bang;
 152                 if ($arg->{error}) {
 153                     push @{${$arg->{error}}}, {$path => $e};
 154                 }
 155                 else {
 156                     _croak("mkdir $path: $e");
 157                 }
 158             }
 159         }
 160     }
 161     return @created;
 162 }
 163
 164 sub remove_tree {
 165     push @_, {} unless @_ and UNIVERSAL::isa($_[-1],'HASH');
 166     goto &rmtree;
 167 }
 168
 169 sub _is_subdir {
 170     my($dir, $test) = @_;
 171
 172     my($dv, $dd) = File::Spec->splitpath($dir, 1);
 173     my($tv, $td) = File::Spec->splitpath($test, 1);
 174
 175     # not on same volume
 176     return 0 if $dv ne $tv;
 177
 178     my @d = File::Spec->splitdir($dd);
 179     my @t = File::Spec->splitdir($td);
 180
 181     # @t can't be a subdir if it's shorter than @d
 182     return 0 if @t < @d;
 183
 184     return join('/', @d) eq join('/', splice @t, 0, +@d);
 185 }
 186
 187 sub rmtree {
 188     my $old_style = !(@_ and UNIVERSAL::isa($_[-1],'HASH'));
 189
 190     my $arg;
 191     my $paths;
 192
 193     if ($old_style) {
 194         my ($verbose, $safe);
 195         ($paths, $verbose, $safe) = @_;
 196         $arg->{verbose} = $verbose;
 197         $arg->{safe}    = defined $safe    ? $safe    : 0;
 198
 199         if (defined($paths) and length($paths)) {
 200             $paths = [$paths] unless UNIVERSAL::isa($paths,'ARRAY');
 201         }
 202         else {
 203             _carp ("No root path(s) specified\n");
 204             return 0;
 205         }
 206     }
 207     else {
 208         $arg = pop @_;
 209         ${$arg->{error}}  = [] if exists $arg->{error};
 210         ${$arg->{result}} = [] if exists $arg->{result};
 211         $paths = [@_];
 212     }
 213
 214     $arg->{prefix} = '';
 215     $arg->{depth}  = 0;
 216
 217     my @clean_path;
 218     $arg->{cwd} = getcwd() or do {
 219         _error($arg, "cannot fetch initial working directory");
 220         return 0;
 221     };
 222     for ($arg->{cwd}) { /\A(.*)\Z/; $_ = $1 } # untaint
 223
 224     for my $p (@$paths) {
 225         # need to fixup case and map \ to / on Windows
 226         my $ortho_root = $^O eq 'MSWin32' ? _slash_lc($p)          : $p;
 227         my $ortho_cwd  = $^O eq 'MSWin32' ? _slash_lc($arg->{cwd}) : $arg->{cwd};
 228         my $ortho_root_length = length($ortho_root);
 229         $ortho_root_length-- if $^O eq 'VMS'; # don't compare '.' with ']'
 230         if ($ortho_root_length && _is_subdir($ortho_root, $ortho_cwd)) {
 231             local $! = 0;
 232             _error($arg, "cannot remove path when cwd is $arg->{cwd}", $p);
 233             next;
 234         }
 235
 236         if ($Is_MacOS) {
 237             $p  = ":$p" unless $p =~ /:/;
 238             $p .= ":"   unless $p =~ /:\z/;
 239         }
 240         elsif ($^O eq 'MSWin32') {
 241             $p =~ s{[/\\]\z}{};
 242         }
 243         else {
 244             $p =~ s{/\z}{};
 245         }
 246         push @clean_path, $p;
 247     }
 248
 249     @{$arg}{qw(device inode perm)} = (lstat $arg->{cwd})[0,1] or do {
 250         _error($arg, "cannot stat initial working directory", $arg->{cwd});
 251         return 0;
 252     };
 253
 254     return _rmtree($arg, \@clean_path);
 255 }
 256
 257 sub _rmtree {
 258     my $arg   = shift;
 259     my $paths = shift;
 260
 261     my $count  = 0;
 262     my $curdir = File::Spec->curdir();
 263     my $updir  = File::Spec->updir();
 264
 265     my (@files, $root);
 266     ROOT_DIR:
 267     foreach $root (@$paths) {
 268         # since we chdir into each directory, it may not be obvious
 269         # to figure out where we are if we generate a message about
 270         # a file name. We therefore construct a semi-canonical
 271         # filename, anchored from the directory being unlinked (as
 272         # opposed to being truly canonical, anchored from the root (/).
 273
 274         my $canon = $arg->{prefix}
 275             ? File::Spec->catfile($arg->{prefix}, $root)
 276             : $root
 277         ;
 278
 279         my ($ldev, $lino, $perm) = (lstat $root)[0,1,2] or next ROOT_DIR;
 280
 281         if ( -d _ ) {
 282             $root = VMS::Filespec::pathify($root) if $Is_VMS;
 283
 284             if (!chdir($root)) {
 285                 # see if we can escalate privileges to get in
 286                 # (e.g. funny protection mask such as -w- instead of rwx)
 287                 $perm &= 07777;
 288                 my $nperm = $perm | 0700;
 289                 if (!($arg->{safe} or $nperm == $perm or chmod($nperm, $root))) {
 290                     _error($arg, "cannot make child directory read-write-exec", $canon);
 291                     next ROOT_DIR;
 292                 }
 293                 elsif (!chdir($root)) {
 294                     _error($arg, "cannot chdir to child", $canon);
 295                     next ROOT_DIR;
 296                 }
 297             }
 298
 299             my ($cur_dev, $cur_inode, $perm) = (stat $curdir)[0,1,2] or do {
 300                 _error($arg, "cannot stat current working directory", $canon);
 301                 next ROOT_DIR;
 302             };
 303
 304             if ($Need_Stat_Check) {
 305                 ($ldev eq $cur_dev and $lino eq $cur_inode)
 306                     or _croak("directory $canon changed before chdir, expected dev=$ldev ino=$lino, actual dev=$cur_dev ino=$cur_inode, aborting.");
 307             }
 308
 309             $perm &= 07777; # don't forget setuid, setgid, sticky bits
 310             my $nperm = $perm | 0700;
 311
 312             # notabene: 0700 is for making readable in the first place,
 313             # it's also intended to change it to writable in case we have
 314             # to recurse in which case we are better than rm -rf for
 315             # subtrees with strange permissions
 316
 317             if (!($arg->{safe} or $nperm == $perm or chmod($nperm, $curdir))) {
 318                 _error($arg, "cannot make directory read+writeable", $canon);
 319                 $nperm = $perm;
 320             }
 321
 322             my $d;
 323             $d = gensym() if $] < 5.006;
 324             if (!opendir $d, $curdir) {
 325                 _error($arg, "cannot opendir", $canon);
 326                 @files = ();
 327             }
 328             else {
 329                 no strict 'refs';
 330                 if (!defined ${"\cTAINT"} or ${"\cTAINT"}) {
 331                     # Blindly untaint dir names if taint mode is
 332                     # active, or any perl < 5.006
 333                     @files = map { /\A(.*)\z/s; $1 } readdir $d;
 334                 }
 335                 else {
 336                     @files = readdir $d;
 337                 }
 338                 closedir $d;
 339             }
 340
 341             if ($Is_VMS) {
 342                 # Deleting large numbers of files from VMS Files-11
 343                 # filesystems is faster if done in reverse ASCIIbetical order.
 344                 # include '.' to '.;' from blead patch #31775
 345                 @files = map {$_ eq '.' ? '.;' : $_} reverse @files;
 346                 ($root = VMS::Filespec::unixify($root)) =~ s/\.dir\z//;
 347             }
 348
 349             @files = grep {$_ ne $updir and $_ ne $curdir} @files;
 350
 351             if (@files) {
 352                 # remove the contained files before the directory itself
 353                 my $narg = {%$arg};
 354                 @{$narg}{qw(device inode cwd prefix depth)}
 355                     = ($cur_dev, $cur_inode, $updir, $canon, $arg->{depth}+1);
 356                 $count += _rmtree($narg, \@files);
 357             }
 358
 359             # restore directory permissions of required now (in case the rmdir
 360             # below fails), while we are still in the directory and may do so
 361             # without a race via '.'
 362             if ($nperm != $perm and not chmod($perm, $curdir)) {
 363                 _error($arg, "cannot reset chmod", $canon);
 364             }
 365
 366             # don't leave the client code in an unexpected directory
 367             chdir($arg->{cwd})
 368                 or _croak("cannot chdir to $arg->{cwd} from $canon: $!, aborting.");
 369
 370             # ensure that a chdir upwards didn't take us somewhere other
 371             # than we expected (see CVE-2002-0435)
 372             ($cur_dev, $cur_inode) = (stat $curdir)[0,1]
 373                 or _croak("cannot stat prior working directory $arg->{cwd}: $!, aborting.");
 374
 375             if ($Need_Stat_Check) {
 376                 ($arg->{device} eq $cur_dev and $arg->{inode} eq $cur_inode)
 377                     or _croak("previous directory $arg->{cwd} changed before entering $canon, expected dev=$ldev ino=$lino, actual dev=$cur_dev ino=$cur_inode, aborting.");
 378             }
 379
 380             if ($arg->{depth} or !$arg->{keep_root}) {
 381                 if ($arg->{safe} &&
 382                     ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 383                     print "skipped $root\n" if $arg->{verbose};
 384                     next ROOT_DIR;
 385                 }
 386                 if ($Force_Writeable and !chmod $perm | 0700, $root) {
 387                     _error($arg, "cannot make directory writeable", $canon);
 388                 }
 389                 print "rmdir $root\n" if $arg->{verbose};
 390                 if (rmdir $root) {
 391                     push @{${$arg->{result}}}, $root if $arg->{result};
 392                     ++$count;
 393                 }
 394                 else {
 395                     _error($arg, "cannot remove directory", $canon);
 396                     if ($Force_Writeable && !chmod($perm, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 397                     ) {
 398                         _error($arg, sprintf("cannot restore permissions to 0%o",$perm), $canon);
 399                     }
 400                 }
 401             }
 402         }
 403         else {
 404             # not a directory
 405             $root = VMS::Filespec::vmsify("./$root")
 406                 if $Is_VMS
 407                    && !File::Spec->file_name_is_absolute($root)
 408                    && ($root !~ m/(?<!\^)[\]>]+/);  # not already in VMS syntax
 409
 410             if ($arg->{safe} &&
 411                 ($Is_VMS ? !&VMS::Filespec::candelete($root)
 412                          : !(-l $root || -w $root)))
 413             {
 414                 print "skipped $root\n" if $arg->{verbose};
 415                 next ROOT_DIR;
 416             }
 417
 418             my $nperm = $perm & 07777 | 0600;
 419             if ($Force_Writeable and $nperm != $perm and not chmod $nperm, $root) {
 420                 _error($arg, "cannot make file writeable", $canon);
 421             }
 422             print "unlink $canon\n" if $arg->{verbose};
 423             # delete all versions under VMS
 424             for (;;) {
 425                 if (unlink $root) {
 426                     push @{${$arg->{result}}}, $root if $arg->{result};
 427                 }
 428                 else {
 429                     _error($arg, "cannot unlink file", $canon);
 430                     $Force_Writeable and chmod($perm, $root) or
 431                         _error($arg, sprintf("cannot restore permissions to 0%o",$perm), $canon);
 432                     last;
 433                 }
 434                 ++$count;
 435                 last unless $Is_VMS && lstat $root;
 436             }
 437         }
 438     }
 439     return $count;
 440 }
 441
 442 sub _slash_lc {
 443     # fix up slashes and case on MSWin32 so that we can determine that
 444     # c:\path\to\dir is underneath C:/Path/To
 445     my $path = shift;
 446     $path =~ tr{\\}{/};
 447     return lc($path);
 448 }
 449
 450 1;
 451 __END__
 452
 453 =head1 NAME
 454
 455 File::Path - Create or remove directory trees
 456
 457 =head1 VERSION
 458
 459 This document describes version 2.08 of File::Path, released
 460 2009-10-04.
 461
 462 =head1 SYNOPSIS
 463
 464   use File::Path qw(make_path remove_tree);
 465
 466   make_path('foo/bar/baz', '/zug/zwang');
 467   make_path('foo/bar/baz', '/zug/zwang', {
 468       verbose => 1,
 469       mode => 0711,
 470   });
 471
 472   remove_tree('foo/bar/baz', '/zug/zwang');
 473   remove_tree('foo/bar/baz', '/zug/zwang', {
 474       verbose => 1,
 475       error  => \my $err_list,
 476   });
 477
 478   # legacy (interface promoted before v2.00)
 479   mkpath('/foo/bar/baz');
 480   mkpath('/foo/bar/baz', 1, 0711);
 481   mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);
 482   rmtree('foo/bar/baz', 1, 1);
 483   rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);
 484
 485   # legacy (interface promoted before v2.06)
 486   mkpath('foo/bar/baz', '/zug/zwang', { verbose => 1, mode => 0711 });
 487   rmtree('foo/bar/baz', '/zug/zwang', { verbose => 1, mode => 0711 });
 488
 489 =head1 DESCRIPTION
 490
 491 This module provide a convenient way to create directories of
 492 arbitrary depth and to delete an entire directory subtree from the
 493 filesystem.
 494
 495 The following functions are provided:
 496
 497 =over
 498
 499 =item make_path( $dir1, $dir2, .... )
 500
 501 =item make_path( $dir1, $dir2, ...., \%opts )
 502
 503 The C<make_path> function creates the given directories if they don't
 504 exists before, much like the Unix command C<mkdir -p>.
 505
 506 The function accepts a list of directories to be created. Its
 507 behaviour may be tuned by an optional hashref appearing as the last
 508 parameter on the call.
 509
 510 The function returns the list of directories actually created during
 511 the call; in scalar context the number of directories created.
 512
 513 The following keys are recognised in the option hash:
 514
 515 =over
 516
 517 =item mode => $num
 518
 519 The numeric permissions mode to apply to each created directory
 520 (defaults to 0777), to be modified by the current C<umask>. If the
 521 directory already exists (and thus does not need to be created),
 522 the permissions will not be modified.
 523
 524 C<mask> is recognised as an alias for this parameter.
 525
 526 =item verbose => $bool
 527
 528 If present, will cause C<make_path> to print the name of each directory
 529 as it is created. By default nothing is printed.
 530
 531 =item error => \$err
 532
 533 If present, it should be a reference to a scalar.
 534 This scalar will be made to reference an array, which will
 535 be used to store any errors that are encountered.  See the L</"ERROR
 536 HANDLING"> section for more information.
 537
 538 If this parameter is not used, certain error conditions may raise
 539 a fatal error that will cause the program will halt, unless trapped
 540 in an C<eval> block.
 541
 542 =item owner => $owner
 543
 544 =item user => $owner
 545
 546 =item uid => $owner
 547
 548 If present, will cause any created directory to be owned by C<$owner>.
 549 If the value is numeric, it will be interpreted as a uid, otherwise
 550 as username is assumed. An error will be issued if the username cannot be
 551 mapped to a uid, or the uid does not exist, or the process lacks the
 552 privileges to change ownership.
 553
 554 Ownwership of directories that already exist will not be changed.
 555
 556 C<user> and C<uid> are aliases of C<owner>.
 557
 558 =item group => $group
 559
 560 If present, will cause any created directory to be owned by the group C<$group>.
 561 If the value is numeric, it will be interpreted as a gid, otherwise
 562 as group name is assumed. An error will be issued if the group name cannot be
 563 mapped to a gid, or the gid does not exist, or the process lacks the
 564 privileges to change group ownership.
 565
 566 Group ownwership of directories that already exist will not be changed.
 567
 568     make_path '/var/tmp/webcache', {owner=>'nobody', group=>'nogroup'};
 569
 570 =back
 571
 572 =item mkpath( $dir )
 573
 574 =item mkpath( $dir, $verbose, $mode )
 575
 576 =item mkpath( [$dir1, $dir2,...], $verbose, $mode )
 577
 578 =item mkpath( $dir1, $dir2,..., \%opt )
 579
 580 The mkpath() function provide the legacy interface of make_path() with
 581 a different interpretation of the arguments passed.  The behaviour and
 582 return value of the function is otherwise identical to make_path().
 583
 584 =item remove_tree( $dir1, $dir2, .... )
 585
 586 =item remove_tree( $dir1, $dir2, ...., \%opts )
 587
 588 The C<remove_tree> function deletes the given directories and any
 589 files and subdirectories they might contain, much like the Unix
 590 command C<rm -r> or C<del /s> on Windows.
 591
 592 The function accepts a list of directories to be
 593 removed. Its behaviour may be tuned by an optional hashref
 594 appearing as the last parameter on the call.
 595
 596 The functions returns the number of files successfully deleted.
 597
 598 The following keys are recognised in the option hash:
 599
 600 =over
 601
 602 =item verbose => $bool
 603
 604 If present, will cause C<remove_tree> to print the name of each file as
 605 it is unlinked. By default nothing is printed.
 606
 607 =item safe => $bool
 608
 609 When set to a true value, will cause C<remove_tree> to skip the files
 610 for which the process lacks the required privileges needed to delete
 611 files, such as delete privileges on VMS. In other words, the code
 612 will make no attempt to alter file permissions. Thus, if the process
 613 is interrupted, no filesystem object will be left in a more
 614 permissive mode.
 615
 616 =item keep_root => $bool
 617
 618 When set to a true value, will cause all files and subdirectories
 619 to be removed, except the initially specified directories. This comes
 620 in handy when cleaning out an application's scratch directory.
 621
 622   remove_tree( '/tmp', {keep_root => 1} );
 623
 624 =item result => \$res
 625
 626 If present, it should be a reference to a scalar.
 627 This scalar will be made to reference an array, which will
 628 be used to store all files and directories unlinked
 629 during the call. If nothing is unlinked, the array will be empty.
 630
 631   remove_tree( '/tmp', {result => \my $list} );
 632   print "unlinked $_\n" for @$list;
 633
 634 This is a useful alternative to the C<verbose> key.
 635
 636 =item error => \$err
 637
 638 If present, it should be a reference to a scalar.
 639 This scalar will be made to reference an array, which will
 640 be used to store any errors that are encountered.  See the L</"ERROR
 641 HANDLING"> section for more information.
 642
 643 Removing things is a much more dangerous proposition than
 644 creating things. As such, there are certain conditions that
 645 C<remove_tree> may encounter that are so dangerous that the only
 646 sane action left is to kill the program.
 647
 648 Use C<error> to trap all that is reasonable (problems with
 649 permissions and the like), and let it die if things get out
 650 of hand. This is the safest course of action.
 651
 652 =back
 653
 654 =item rmtree( $dir )
 655
 656 =item rmtree( $dir, $verbose, $safe )
 657
 658 =item rmtree( [$dir1, $dir2,...], $verbose, $safe )
 659
 660 =item rmtree( $dir1, $dir2,..., \%opt )
 661
 662 The rmtree() function provide the legacy interface of remove_tree()
 663 with a different interpretation of the arguments passed. The behaviour
 664 and return value of the function is otherwise identical to
 665 remove_tree().
 666
 667 =back
 668
 669 =head2 ERROR HANDLING
 670
 671 =over 4
 672
 673 =item B<NOTE:>
 674
 675 The following error handling mechanism is considered
 676 experimental and is subject to change pending feedback from
 677 users.
 678
 679 =back
 680
 681 If C<make_path> or C<remove_tree> encounter an error, a diagnostic
 682 message will be printed to C<STDERR> via C<carp> (for non-fatal
 683 errors), or via C<croak> (for fatal errors).
 684
 685 If this behaviour is not desirable, the C<error> attribute may be
 686 used to hold a reference to a variable, which will be used to store
 687 the diagnostics. The variable is made a reference to an array of hash
 688 references.  Each hash contain a single key/value pair where the key
 689 is the name of the file, and the value is the error message (including
 690 the contents of C<$!> when appropriate).  If a general error is
 691 encountered the diagnostic key will be empty.
 692
 693 An example usage looks like:
 694
 695   remove_tree( 'foo/bar', 'bar/rat', {error => \my $err} );
 696   if (@$err) {
 697       for my $diag (@$err) {
 698           my ($file, $message) = %$diag;
 699           if ($file eq '') {
 700               print "general error: $message\n";
 701           }
 702           else {
 703               print "problem unlinking $file: $message\n";
 704           }
 705       }
 706   }
 707   else {
 708       print "No error encountered\n";
 709   }
 710
 711 Note that if no errors are encountered, C<$err> will reference an
 712 empty array.  This means that C<$err> will always end up TRUE; so you
 713 need to test C<@$err> to determine if errors occured.
 714
 715 =head2 NOTES
 716
 717 C<File::Path> blindly exports C<mkpath> and C<rmtree> into the
 718 current namespace. These days, this is considered bad style, but
 719 to change it now would break too much code. Nonetheless, you are
 720 invited to specify what it is you are expecting to use:
 721
 722   use File::Path 'rmtree';
 723
 724 The routines C<make_path> and C<remove_tree> are B<not> exported
 725 by default. You must specify which ones you want to use.
 726
 727   use File::Path 'remove_tree';
 728
 729 Note that a side-effect of the above is that C<mkpath> and C<rmtree>
 730 are no longer exported at all. This is due to the way the C<Exporter>
 731 module works. If you are migrating a codebase to use the new
 732 interface, you will have to list everything explicitly. But that's
 733 just good practice anyway.
 734
 735   use File::Path qw(remove_tree rmtree);
 736
 737 =head3 API CHANGES
 738
 739 The API was changed in the 2.0 branch. For a time, C<mkpath> and
 740 C<rmtree> tried, unsuccessfully, to deal with the two different
 741 calling mechanisms. This approach was considered a failure.
 742
 743 The new semantics are now only available with C<make_path> and
 744 C<remove_tree>. The old semantics are only available through
 745 C<mkpath> and C<rmtree>. Users are strongly encouraged to upgrade
 746 to at least 2.08 in order to avoid surprises.
 747
 748 =head3 SECURITY CONSIDERATIONS
 749
 750 There were race conditions 1.x implementations of File::Path's
 751 C<rmtree> function (although sometimes patched depending on the OS
 752 distribution or platform). The 2.0 version contains code to avoid the
 753 problem mentioned in CVE-2002-0435.
 754
 755 See the following pages for more information:
 756
 757   http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=286905
 758   http://www.nntp.perl.org/group/perl.perl5.porters/2005/01/msg97623.html
 759   http://www.debian.org/security/2005/dsa-696
 760
 761 Additionally, unless the C<safe> parameter is set (or the
 762 third parameter in the traditional interface is TRUE), should a
 763 C<remove_tree> be interrupted, files that were originally in read-only
 764 mode may now have their permissions set to a read-write (or "delete
 765 OK") mode.
 766
 767 =head1 DIAGNOSTICS
 768
 769 FATAL errors will cause the program to halt (C<croak>), since the
 770 problem is so severe that it would be dangerous to continue. (This
 771 can always be trapped with C<eval>, but it's not a good idea. Under
 772 the circumstances, dying is the best thing to do).
 773
 774 SEVERE errors may be trapped using the modern interface. If the
 775 they are not trapped, or the old interface is used, such an error
 776 will cause the program will halt.
 777
 778 All other errors may be trapped using the modern interface, otherwise
 779 they will be C<carp>ed about. Program execution will not be halted.
 780
 781 =over 4
 782
 783 =item mkdir [path]: [errmsg] (SEVERE)
 784
 785 C<make_path> was unable to create the path. Probably some sort of
 786 permissions error at the point of departure, or insufficient resources
 787 (such as free inodes on Unix).
 788
 789 =item No root path(s) specified
 790
 791 C<make_path> was not given any paths to create. This message is only
 792 emitted if the routine is called with the traditional interface.
 793 The modern interface will remain silent if given nothing to do.
 794
 795 =item No such file or directory
 796
 797 On Windows, if C<make_path> gives you this warning, it may mean that
 798 you have exceeded your filesystem's maximum path length.
 799
 800 =item cannot fetch initial working directory: [errmsg]
 801
 802 C<remove_tree> attempted to determine the initial directory by calling
 803 C<Cwd::getcwd>, but the call failed for some reason. No attempt
 804 will be made to delete anything.
 805
 806 =item cannot stat initial working directory: [errmsg]
 807
 808 C<remove_tree> attempted to stat the initial directory (after having
 809 successfully obtained its name via C<getcwd>), however, the call
 810 failed for some reason. No attempt will be made to delete anything.
 811
 812 =item cannot chdir to [dir]: [errmsg]
 813
 814 C<remove_tree> attempted to set the working directory in order to
 815 begin deleting the objects therein, but was unsuccessful. This is
 816 usually a permissions issue. The routine will continue to delete
 817 other things, but this directory will be left intact.
 818
 819 =item directory [dir] changed before chdir, expected dev=[n] ino=[n], actual dev=[n] ino=[n], aborting. (FATAL)
 820
 821 C<remove_tree> recorded the device and inode of a directory, and then
 822 moved into it. It then performed a C<stat> on the current directory
 823 and detected that the device and inode were no longer the same. As
 824 this is at the heart of the race condition problem, the program
 825 will die at this point.
 826
 827 =item cannot make directory [dir] read+writeable: [errmsg]
 828
 829 C<remove_tree> attempted to change the permissions on the current directory
 830 to ensure that subsequent unlinkings would not run into problems,
 831 but was unable to do so. The permissions remain as they were, and
 832 the program will carry on, doing the best it can.
 833
 834 =item cannot read [dir]: [errmsg]
 835
 836 C<remove_tree> tried to read the contents of the directory in order
 837 to acquire the names of the directory entries to be unlinked, but
 838 was unsuccessful. This is usually a permissions issue. The
 839 program will continue, but the files in this directory will remain
 840 after the call.
 841
 842 =item cannot reset chmod [dir]: [errmsg]
 843
 844 C<remove_tree>, after having deleted everything in a directory, attempted
 845 to restore its permissions to the original state but failed. The
 846 directory may wind up being left behind.
 847
 848 =item cannot remove [dir] when cwd is [dir]
 849
 850 The current working directory of the program is F</some/path/to/here>
 851 and you are attempting to remove an ancestor, such as F</some/path>.
 852 The directory tree is left untouched.
 853
 854 The solution is to C<chdir> out of the child directory to a place
 855 outside the directory tree to be removed.
 856
 857 =item cannot chdir to [parent-dir] from [child-dir]: [errmsg], aborting. (FATAL)
 858
 859 C<remove_tree>, after having deleted everything and restored the permissions
 860 of a directory, was unable to chdir back to the parent. The program
 861 halts to avoid a race condition from occurring.
 862
 863 =item cannot stat prior working directory [dir]: [errmsg], aborting. (FATAL)
 864
 865 C<remove_tree> was unable to stat the parent directory after have returned
 866 from the child. Since there is no way of knowing if we returned to
 867 where we think we should be (by comparing device and inode) the only
 868 way out is to C<croak>.
 869
 870 =item previous directory [parent-dir] changed before entering [child-dir], expected dev=[n] ino=[n], actual dev=[n] ino=[n], aborting. (FATAL)
 871
 872 When C<remove_tree> returned from deleting files in a child directory, a
 873 check revealed that the parent directory it returned to wasn't the one
 874 it started out from. This is considered a sign of malicious activity.
 875
 876 =item cannot make directory [dir] writeable: [errmsg]
 877
 878 Just before removing a directory (after having successfully removed
 879 everything it contained), C<remove_tree> attempted to set the permissions
 880 on the directory to ensure it could be removed and failed. Program
 881 execution continues, but the directory may possibly not be deleted.
 882
 883 =item cannot remove directory [dir]: [errmsg]
 884
 885 C<remove_tree> attempted to remove a directory, but failed. This may because
 886 some objects that were unable to be removed remain in the directory, or
 887 a permissions issue. The directory will be left behind.
 888
 889 =item cannot restore permissions of [dir] to [0nnn]: [errmsg]
 890
 891 After having failed to remove a directory, C<remove_tree> was unable to
 892 restore its permissions from a permissive state back to a possibly
 893 more restrictive setting. (Permissions given in octal).
 894
 895 =item cannot make file [file] writeable: [errmsg]
 896
 897 C<remove_tree> attempted to force the permissions of a file to ensure it
 898 could be deleted, but failed to do so. It will, however, still attempt
 899 to unlink the file.
 900
 901 =item cannot unlink file [file]: [errmsg]
 902
 903 C<remove_tree> failed to remove a file. Probably a permissions issue.
 904
 905 =item cannot restore permissions of [file] to [0nnn]: [errmsg]
 906
 907 After having failed to remove a file, C<remove_tree> was also unable
 908 to restore the permissions on the file to a possibly less permissive
 909 setting. (Permissions given in octal).
 910
 911 =item unable to map [owner] to a uid, ownership not changed");
 912
 913 C<make_path> was instructed to give the ownership of created
 914 directories to the symbolic name [owner], but C<getpwnam> did
 915 not return the corresponding numeric uid. The directory will
 916 be created, but ownership will not be changed.
 917
 918 =item unable to map [group] to a gid, group ownership not changed
 919
 920 C<make_path> was instructed to give the group ownership of created
 921 directories to the symbolic name [group], but C<getgrnam> did
 922 not return the corresponding numeric gid. The directory will
 923 be created, but group ownership will not be changed.
 924
 925 =back
 926
 927 =head1 SEE ALSO
 928
 929 =over 4
 930
 931 =item *
 932
 933 L<File::Remove>
 934
 935 Allows files and directories to be moved to the Trashcan/Recycle
 936 Bin (where they may later be restored if necessary) if the operating
 937 system supports such functionality. This feature may one day be
 938 made available directly in C<File::Path>.
 939
 940 =item *
 941
 942 L<File::Find::Rule>
 943
 944 When removing directory trees, if you want to examine each file to
 945 decide whether to delete it (and possibly leaving large swathes
 946 alone), F<File::Find::Rule> offers a convenient and flexible approach
 947 to examining directory trees.
 948
 949 =back
 950
 951 =head1 BUGS
 952
 953 Please report all bugs on the RT queue:
 954
 955 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=File-Path>
 956
 957 =head1 ACKNOWLEDGEMENTS
 958
 959 Paul Szabo identified the race condition originally, and Brendan
 960 O'Dea wrote an implementation for Debian that addressed the problem.
 961 That code was used as a basis for the current code. Their efforts
 962 are greatly appreciated.
 963
 964 Gisle Aas made a number of improvements to the documentation for
 965 2.07 and his advice and assistance is also greatly appreciated.
 966
 967 =head1 AUTHORS
 968
 969 Tim Bunce and Charles Bailey. Currently maintained by David Landgren
 970 <F<david@landgren.net>>.
 971
 972 =head1 COPYRIGHT
 973
 974 This module is copyright (C) Charles Bailey, Tim Bunce and
 975 David Landgren 1995-2009. All rights reserved.
 976
 977 =head1 LICENSE
 978
 979 This library is free software; you can redistribute it and/or modify
 980 it under the same terms as Perl itself.
 981
 982 =cut