lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.39_01';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     @cmdfhs
 631     $CommandSet
 632     $CreateTTY
 633     $DBGR
 634     @dbline
 635     $dbline
 636     %dbline
 637     $dieLevel
 638     $evalarg
 639     $filename
 640     $frame
 641     $hist
 642     $histfile
 643     $histsize
 644     $ImmediateStop
 645     $IN
 646     $inhibit_exit
 647     @ini_INC
 648     $ini_warn
 649     $line
 650     $maxtrace
 651     $od
 652     $onetimeDump
 653     $onetimedumpDepth
 654     %option
 655     @options
 656     $osingle
 657     $otrace
 658     $OUT
 659     $packname
 660     $pager
 661     $post
 662     %postponed
 663     $prc
 664     $pre
 665     $pretype
 666     $psh
 667     @RememberOnROptions
 668     $remoteport
 669     @res
 670     $rl
 671     @saved
 672     $signal
 673     $signalLevel
 674     $single
 675     $start
 676     $sub
 677     %sub
 678     $subname
 679     $term
 680     $trace
 681     $usercontext
 682     $warnLevel
 683     $window
 684 );
 685
 686 # Used to save @ARGV and extract any debugger-related flags.
 687 use vars qw(@ARGS);
 688
 689 # Used to prevent multiple entries to diesignal()
 690 # (if for instance diesignal() itself dies)
 691 use vars qw($panic);
 692
 693 # Used to prevent the debugger from running nonstop
 694 # after a restart
 695 use vars qw($second_time);
 696
 697 sub _calc_usercontext {
 698     my ($package) = @_;
 699
 700     # Cancel strict completely for the evaluated code, so the code
 701     # the user evaluates won't be affected by it. (Shlomi Fish)
 702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
 703     . "package $package;";    # this won't let them modify, alas
 704 }
 705
 706 sub eval {
 707
 708     # 'my' would make it visible from user code
 709     #    but so does local! --tchrist
 710     # Remember: this localizes @DB::res, not @main::res.
 711     local @res;
 712     {
 713
 714         # Try to keep the user code from messing  with us. Save these so that
 715         # even if the eval'ed code changes them, we can put them back again.
 716         # Needed because the user could refer directly to the debugger's
 717         # package globals (and any 'my' variables in this containing scope)
 718         # inside the eval(), and we want to try to stay safe.
 719         local $otrace  = $trace;
 720         local $osingle = $single;
 721         local $od      = $^D;
 722
 723         # Untaint the incoming eval() argument.
 724         { ($evalarg) = $evalarg =~ /(.*)/s; }
 725
 726         # $usercontext built in DB::DB near the comment
 727         # "set up the context for DB::eval ..."
 728         # Evaluate and save any results.
 729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 730
 731         # Restore those old values.
 732         $trace  = $otrace;
 733         $single = $osingle;
 734         $^D     = $od;
 735     }
 736
 737     # Save the current value of $@, and preserve it in the debugger's copy
 738     # of the saved precious globals.
 739     my $at = $@;
 740
 741     # Since we're only saving $@, we only have to localize the array element
 742     # that it will be stored in.
 743     local $saved[0];    # Preserve the old value of $@
 744     eval { &DB::save };
 745
 746     # Now see whether we need to report an error back to the user.
 747     if ($at) {
 748         local $\ = '';
 749         print $OUT $at;
 750     }
 751
 752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 753     # are package globals.
 754     elsif ($onetimeDump) {
 755         if ( $onetimeDump eq 'dump' ) {
 756             local $option{dumpDepth} = $onetimedumpDepth
 757               if defined $onetimedumpDepth;
 758             dumpit( $OUT, \@res );
 759         }
 760         elsif ( $onetimeDump eq 'methods' ) {
 761             methods( $res[0] );
 762         }
 763     } ## end elsif ($onetimeDump)
 764     @res;
 765 } ## end sub eval
 766
 767 ############################################## End lexical danger zone
 768
 769 # After this point it is safe to introduce lexicals.
 770 # The code being debugged will be executing in its own context, and
 771 # can't see the inside of the debugger.
 772 #
 773 # However, one should not overdo it: leave as much control from outside as
 774 # possible. If you make something a lexical, it's not going to be addressable
 775 # from outside the debugger even if you know its name.
 776
 777 # This file is automatically included if you do perl -d.
 778 # It's probably not useful to include this yourself.
 779 #
 780 # Before venturing further into these twisty passages, it is
 781 # wise to read the perldebguts man page or risk the ire of dragons.
 782 #
 783 # (It should be noted that perldebguts will tell you a lot about
 784 # the underlying mechanics of how the debugger interfaces into the
 785 # Perl interpreter, but not a lot about the debugger itself. The new
 786 # comments in this code try to address this problem.)
 787
 788 # Note that no subroutine call is possible until &DB::sub is defined
 789 # (for subroutines defined outside of the package DB). In fact the same is
 790 # true if $deep is not defined.
 791
 792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 793
 794 # modified Perl debugger, to be run from Emacs in perldb-mode
 795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 796 # Johan Vromans -- upgrade to 4.0 pl 10
 797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 798 ########################################################################
 799
 800 =head1 DEBUGGER INITIALIZATION
 801
 802 The debugger starts up in phases.
 803
 804 =head2 BASIC SETUP
 805
 806 First, it initializes the environment it wants to run in: turning off
 807 warnings during its own compilation, defining variables which it will need
 808 to avoid warnings later, setting itself up to not exit when the program
 809 terminates, and defaulting to printing return values for the C<r> command.
 810
 811 =cut
 812
 813 # Needed for the statement after exec():
 814 #
 815 # This BEGIN block is simply used to switch off warnings during debugger
 816 # compilation. Probably it would be better practice to fix the warnings,
 817 # but this is how it's done at the moment.
 818
 819 BEGIN {
 820     $ini_warn = $^W;
 821     $^W       = 0;
 822 }    # Switch compilation warnings off until another BEGIN.
 823
 824 local ($^W) = 0;    # Switch run-time warnings off during init.
 825
 826 =head2 THREADS SUPPORT
 827
 828 If we are running under a threaded Perl, we require threads and threads::shared
 829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 830 threaded debugger control.  C<-dt> can also be used to set this.
 831
 832 Each new thread will be announced and the debugger prompt will always inform
 833 you of each new thread created.  It will also indicate the thread id in which
 834 we are currently running within the prompt like this:
 835
 836         [tid] DB<$i>
 837
 838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 839 command prompt.  The prompt will show: C<[0]> when running under threads, but
 840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 841
 842 While running under threads, when you set or delete a breakpoint (etc.), this
 843 will apply to all threads, not just the currently running one.  When you are
 844 in a currently executing thread, you will stay there until it completes.  With
 845 the current implementation it is not currently possible to hop from one thread
 846 to another.
 847
 848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 849
 850 Note that threading support was built into the debugger as of Perl version
 851 C<5.8.6> and debugger version C<1.2.8>.
 852
 853 =cut
 854
 855 BEGIN {
 856   # ensure we can share our non-threaded variables or no-op
 857   if ($ENV{PERL5DB_THREADED}) {
 858         require threads;
 859         require threads::shared;
 860         import threads::shared qw(share);
 861         $DBGR;
 862         share(\$DBGR);
 863         lock($DBGR);
 864         print "Threads support enabled\n";
 865   } else {
 866         *lock  = sub(*) {};
 867         *share = sub(*) {};
 868   }
 869 }
 870
 871 # This would probably be better done with "use vars", but that wasn't around
 872 # when this code was originally written. (Neither was "use strict".) And on
 873 # the principle of not fiddling with something that was working, this was
 874 # left alone.
 875 warn(               # Do not ;-)
 876     # These variables control the execution of 'dumpvar.pl'.
 877     $dumpvar::hashDepth,
 878     $dumpvar::arrayDepth,
 879     $dumpvar::dumpDBFiles,
 880     $dumpvar::dumpPackages,
 881     $dumpvar::quoteHighBit,
 882     $dumpvar::printUndef,
 883     $dumpvar::globPrint,
 884     $dumpvar::usageOnly,
 885
 886     # used to control die() reporting in diesignal()
 887     $Carp::CarpLevel,
 888
 889
 890   )
 891   if 0;
 892
 893 # without threads, $filename is not defined until DB::DB is called
 894 foreach my $k (keys (%INC)) {
 895         &share(\$main::{'_<'.$filename}) if defined $filename;
 896 };
 897
 898 # Command-line + PERLLIB:
 899 # Save the contents of @INC before they are modified elsewhere.
 900 @ini_INC = @INC;
 901
 902 # This was an attempt to clear out the previous values of various
 903 # trapped errors. Apparently it didn't help. XXX More info needed!
 904 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 905
 906 # We set these variables to safe values. We don't want to blindly turn
 907 # off warnings, because other packages may still want them.
 908 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 909                                    # (local $^W cannot help - other packages!).
 910
 911 # Default to not exiting when program finishes; print the return
 912 # value when the 'r' command is used to return from a subroutine.
 913 $inhibit_exit = $option{PrintRet} = 1;
 914
 915 use vars qw($trace_to_depth);
 916
 917 # Default to 1 so the prompt will display the first line.
 918 $trace_to_depth = 1;
 919
 920 =head1 OPTION PROCESSING
 921
 922 The debugger's options are actually spread out over the debugger itself and
 923 C<dumpvar.pl>; some of these are variables to be set, while others are
 924 subs to be called with a value. To try to make this a little easier to
 925 manage, the debugger uses a few data structures to define what options
 926 are legal and how they are to be processed.
 927
 928 First, the C<@options> array defines the I<names> of all the options that
 929 are to be accepted.
 930
 931 =cut
 932
 933 @options = qw(
 934   CommandSet   HistFile      HistSize
 935   hashDepth    arrayDepth    dumpDepth
 936   DumpDBFiles  DumpPackages  DumpReused
 937   compactDump  veryCompact   quote
 938   HighBit      undefPrint    globPrint
 939   PrintRet     UsageOnly     frame
 940   AutoTrace    TTY           noTTY
 941   ReadLine     NonStop       LineInfo
 942   maxTraceLen  recallCommand ShellBang
 943   pager        tkRunning     ornaments
 944   signalLevel  warnLevel     dieLevel
 945   inhibit_exit ImmediateStop bareStringify
 946   CreateTTY    RemotePort    windowSize
 947   DollarCaretP
 948 );
 949
 950 @RememberOnROptions = qw(DollarCaretP);
 951
 952 =pod
 953
 954 Second, C<optionVars> lists the variables that each option uses to save its
 955 state.
 956
 957 =cut
 958
 959 use vars qw(%optionVars);
 960
 961 %optionVars = (
 962     hashDepth     => \$dumpvar::hashDepth,
 963     arrayDepth    => \$dumpvar::arrayDepth,
 964     CommandSet    => \$CommandSet,
 965     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 966     DumpPackages  => \$dumpvar::dumpPackages,
 967     DumpReused    => \$dumpvar::dumpReused,
 968     HighBit       => \$dumpvar::quoteHighBit,
 969     undefPrint    => \$dumpvar::printUndef,
 970     globPrint     => \$dumpvar::globPrint,
 971     UsageOnly     => \$dumpvar::usageOnly,
 972     CreateTTY     => \$CreateTTY,
 973     bareStringify => \$dumpvar::bareStringify,
 974     frame         => \$frame,
 975     AutoTrace     => \$trace,
 976     inhibit_exit  => \$inhibit_exit,
 977     maxTraceLen   => \$maxtrace,
 978     ImmediateStop => \$ImmediateStop,
 979     RemotePort    => \$remoteport,
 980     windowSize    => \$window,
 981     HistFile      => \$histfile,
 982     HistSize      => \$histsize,
 983 );
 984
 985 =pod
 986
 987 Third, C<%optionAction> defines the subroutine to be called to process each
 988 option.
 989
 990 =cut
 991
 992 use vars qw(%optionAction);
 993
 994 %optionAction = (
 995     compactDump   => \&dumpvar::compactDump,
 996     veryCompact   => \&dumpvar::veryCompact,
 997     quote         => \&dumpvar::quote,
 998     TTY           => \&TTY,
 999     noTTY         => \&noTTY,
1000     ReadLine      => \&ReadLine,
1001     NonStop       => \&NonStop,
1002     LineInfo      => \&LineInfo,
1003     recallCommand => \&recallCommand,
1004     ShellBang     => \&shellBang,
1005     pager         => \&pager,
1006     signalLevel   => \&signalLevel,
1007     warnLevel     => \&warnLevel,
1008     dieLevel      => \&dieLevel,
1009     tkRunning     => \&tkRunning,
1010     ornaments     => \&ornaments,
1011     RemotePort    => \&RemotePort,
1012     DollarCaretP  => \&DollarCaretP,
1013 );
1014
1015 =pod
1016
1017 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1018 option is used.
1019
1020 =cut
1021
1022 # Note that this list is not complete: several options not listed here
1023 # actually require that dumpvar.pl be loaded for them to work, but are
1024 # not in the table. A subsequent patch will correct this problem; for
1025 # the moment, we're just recommenting, and we are NOT going to change
1026 # function.
1027 use vars qw(%optionRequire);
1028
1029 %optionRequire = (
1030     compactDump => 'dumpvar.pl',
1031     veryCompact => 'dumpvar.pl',
1032     quote       => 'dumpvar.pl',
1033 );
1034
1035 =pod
1036
1037 There are a number of initialization-related variables which can be set
1038 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1039 variable. These are:
1040
1041 =over 4
1042
1043 =item C<$rl> - readline control XXX needs more explanation
1044
1045 =item C<$warnLevel> - whether or not debugger takes over warning handling
1046
1047 =item C<$dieLevel> - whether or not debugger takes over die handling
1048
1049 =item C<$signalLevel> - whether or not debugger takes over signal handling
1050
1051 =item C<$pre> - preprompt actions (array reference)
1052
1053 =item C<$post> - postprompt actions (array reference)
1054
1055 =item C<$pretype>
1056
1057 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1058
1059 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1060
1061 =back
1062
1063 =cut
1064
1065 # These guys may be defined in $ENV{PERL5DB} :
1066 $rl          = 1     unless defined $rl;
1067 $warnLevel   = 1     unless defined $warnLevel;
1068 $dieLevel    = 1     unless defined $dieLevel;
1069 $signalLevel = 1     unless defined $signalLevel;
1070 $pre         = []    unless defined $pre;
1071 $post        = []    unless defined $post;
1072 $pretype     = []    unless defined $pretype;
1073 $CreateTTY   = 3     unless defined $CreateTTY;
1074 $CommandSet  = '580' unless defined $CommandSet;
1075
1076 share($rl);
1077 share($warnLevel);
1078 share($dieLevel);
1079 share($signalLevel);
1080 share($pre);
1081 share($post);
1082 share($pretype);
1083 share($rl);
1084 share($CreateTTY);
1085 share($CommandSet);
1086
1087 =pod
1088
1089 The default C<die>, C<warn>, and C<signal> handlers are set up.
1090
1091 =cut
1092
1093 warnLevel($warnLevel);
1094 dieLevel($dieLevel);
1095 signalLevel($signalLevel);
1096
1097 =pod
1098
1099 The pager to be used is needed next. We try to get it from the
1100 environment first.  If it's not defined there, we try to find it in
1101 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1102 then call the C<pager()> function to save the pager name.
1103
1104 =cut
1105
1106 # This routine makes sure $pager is set up so that '|' can use it.
1107 pager(
1108
1109     # If PAGER is defined in the environment, use it.
1110     defined $ENV{PAGER}
1111     ? $ENV{PAGER}
1112
1113       # If not, see if Config.pm defines it.
1114     : eval { require Config }
1115       && defined $Config::Config{pager}
1116     ? $Config::Config{pager}
1117
1118       # If not, fall back to 'more'.
1119     : 'more'
1120   )
1121   unless defined $pager;
1122
1123 =pod
1124
1125 We set up the command to be used to access the man pages, the command
1126 recall character (C<!> unless otherwise defined) and the shell escape
1127 character (C<!> unless otherwise defined). Yes, these do conflict, and
1128 neither works in the debugger at the moment.
1129
1130 =cut
1131
1132 setman();
1133
1134 # Set up defaults for command recall and shell escape (note:
1135 # these currently don't work in linemode debugging).
1136 &recallCommand("!") unless defined $prc;
1137 &shellBang("!")     unless defined $psh;
1138
1139 =pod
1140
1141 We then set up the gigantic string containing the debugger help.
1142 We also set the limit on the number of arguments we'll display during a
1143 trace.
1144
1145 =cut
1146
1147 sethelp();
1148
1149 # If we didn't get a default for the length of eval/stack trace args,
1150 # set it here.
1151 $maxtrace = 400 unless defined $maxtrace;
1152
1153 =head2 SETTING UP THE DEBUGGER GREETING
1154
1155 The debugger I<greeting> helps to inform the user how many debuggers are
1156 running, and whether the current debugger is the primary or a child.
1157
1158 If we are the primary, we just hang onto our pid so we'll have it when
1159 or if we start a child debugger. If we are a child, we'll set things up
1160 so we'll have a unique greeting and so the parent will give us our own
1161 TTY later.
1162
1163 We save the current contents of the C<PERLDB_PIDS> environment variable
1164 because we mess around with it. We'll also need to hang onto it because
1165 we'll need it if we restart.
1166
1167 Child debuggers make a label out of the current PID structure recorded in
1168 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1169 yet so the parent will give them one later via C<resetterm()>.
1170
1171 =cut
1172
1173 # Save the current contents of the environment; we're about to
1174 # much with it. We'll need this if we have to restart.
1175 use vars qw($ini_pids);
1176 $ini_pids = $ENV{PERLDB_PIDS};
1177
1178 use vars qw ($pids $term_pid);
1179
1180 if ( defined $ENV{PERLDB_PIDS} ) {
1181
1182     # We're a child. Make us a label out of the current PID structure
1183     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1184     # a term yet so the parent will give us one later via resetterm().
1185
1186     my $env_pids = $ENV{PERLDB_PIDS};
1187     $pids = "[$env_pids]";
1188
1189     # Unless we are on OpenVMS, all programs under the DCL shell run under
1190     # the same PID.
1191
1192     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1193         $term_pid         = $$;
1194     }
1195     else {
1196         $ENV{PERLDB_PIDS} .= "->$$";
1197         $term_pid = -1;
1198     }
1199
1200 } ## end if (defined $ENV{PERLDB_PIDS...
1201 else {
1202
1203     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1204     # child debugger, and mark us as the parent, so we'll know to set up
1205     # more TTY's is we have to.
1206     $ENV{PERLDB_PIDS} = "$$";
1207     $pids             = "[pid=$$]";
1208     $term_pid         = $$;
1209 }
1210
1211 use vars qw($pidprompt);
1212 $pidprompt = '';
1213
1214 # Sets up $emacs as a synonym for $slave_editor.
1215 use vars qw($slave_editor);
1216 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1217
1218 =head2 READING THE RC FILE
1219
1220 The debugger will read a file of initialization options if supplied. If
1221 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1222
1223 =cut
1224
1225 # As noted, this test really doesn't check accurately that the debugger
1226 # is running at a terminal or not.
1227
1228 my $dev_tty = '/dev/tty';
1229    $dev_tty = 'TT:' if ($^O eq 'VMS');
1230 use vars qw($rcfile);
1231 if ( -e $dev_tty ) {                      # this is the wrong metric!
1232     $rcfile = ".perldb";
1233 }
1234 else {
1235     $rcfile = "perldb.ini";
1236 }
1237
1238 =pod
1239
1240 The debugger does a safety test of the file to be read. It must be owned
1241 either by the current user or root, and must only be writable by the owner.
1242
1243 =cut
1244
1245 # This wraps a safety test around "do" to read and evaluate the init file.
1246 #
1247 # This isn't really safe, because there's a race
1248 # between checking and opening.  The solution is to
1249 # open and fstat the handle, but then you have to read and
1250 # eval the contents.  But then the silly thing gets
1251 # your lexical scope, which is unfortunate at best.
1252 sub safe_do {
1253     my $file = shift;
1254
1255     # Just exactly what part of the word "CORE::" don't you understand?
1256     local $SIG{__WARN__};
1257     local $SIG{__DIE__};
1258
1259     unless ( is_safe_file($file) ) {
1260         CORE::warn <<EO_GRIPE;
1261 perldb: Must not source insecure rcfile $file.
1262         You or the superuser must be the owner, and it must not
1263         be writable by anyone but its owner.
1264 EO_GRIPE
1265         return;
1266     } ## end unless (is_safe_file($file...
1267
1268     do $file;
1269     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1270 } ## end sub safe_do
1271
1272 # This is the safety test itself.
1273 #
1274 # Verifies that owner is either real user or superuser and that no
1275 # one but owner may write to it.  This function is of limited use
1276 # when called on a path instead of upon a handle, because there are
1277 # no guarantees that filename (by dirent) whose file (by ino) is
1278 # eventually accessed is the same as the one tested.
1279 # Assumes that the file's existence is not in doubt.
1280 sub is_safe_file {
1281     my $path = shift;
1282     stat($path) || return;    # mysteriously vaporized
1283     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1284
1285     return 0 if $uid != 0 && $uid != $<;
1286     return 0 if $mode & 022;
1287     return 1;
1288 } ## end sub is_safe_file
1289
1290 # If the rcfile (whichever one we decided was the right one to read)
1291 # exists, we safely do it.
1292 if ( -f $rcfile ) {
1293     safe_do("./$rcfile");
1294 }
1295
1296 # If there isn't one here, try the user's home directory.
1297 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1298     safe_do("$ENV{HOME}/$rcfile");
1299 }
1300
1301 # Else try the login directory.
1302 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1303     safe_do("$ENV{LOGDIR}/$rcfile");
1304 }
1305
1306 # If the PERLDB_OPTS variable has options in it, parse those out next.
1307 if ( defined $ENV{PERLDB_OPTS} ) {
1308     parse_options( $ENV{PERLDB_OPTS} );
1309 }
1310
1311 =pod
1312
1313 The last thing we do during initialization is determine which subroutine is
1314 to be used to obtain a new terminal when a new debugger is started. Right now,
1315 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1316 (darwin).
1317
1318 =cut
1319
1320 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1321 # Works if you're running an xterm or xterm-like window, or you're on
1322 # OS/2, or on Mac OS X. This may need some expansion.
1323
1324 if (not defined &get_fork_TTY)       # only if no routine exists
1325 {
1326     if ( defined $remoteport ) {
1327                                                  # Expect an inetd-like server
1328         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1329     }
1330     elsif (defined $ENV{TERM}                    # If we know what kind
1331                                                  # of terminal this is,
1332         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1333         and defined $ENV{DISPLAY}                # and what display it's on,
1334       )
1335     {
1336         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1337     }
1338     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1339         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1340     }
1341     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1342             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1343             and $ENV{TERM_PROGRAM}
1344                 eq 'Apple_Terminal'              # Terminal.app
1345             )
1346     {
1347         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1348     }
1349 } ## end if (not defined &get_fork_TTY...
1350
1351 # untaint $^O, which may have been tainted by the last statement.
1352 # see bug [perl #24674]
1353 $^O =~ m/^(.*)\z/;
1354 $^O = $1;
1355
1356 # Here begin the unreadable code.  It needs fixing.
1357
1358 =head2 RESTART PROCESSING
1359
1360 This section handles the restart command. When the C<R> command is invoked, it
1361 tries to capture all of the state it can into environment variables, and
1362 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1363 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1364 the R command stuffed into the environment variables.
1365
1366   PERLDB_RESTART   - flag only, contains no restart data itself.
1367   PERLDB_HIST      - command history, if it's available
1368   PERLDB_ON_LOAD   - breakpoints set by the rc file
1369   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1370   PERLDB_VISITED   - files that had breakpoints
1371   PERLDB_FILE_...  - breakpoints for a file
1372   PERLDB_OPT       - active options
1373   PERLDB_INC       - the original @INC
1374   PERLDB_PRETYPE   - preprompt debugger actions
1375   PERLDB_PRE       - preprompt Perl code
1376   PERLDB_POST      - post-prompt Perl code
1377   PERLDB_TYPEAHEAD - typeahead captured by readline()
1378
1379 We chug through all these variables and plug the values saved in them
1380 back into the appropriate spots in the debugger.
1381
1382 =cut
1383
1384 use vars qw(@hist @truehist %postponed_file @typeahead);
1385
1386 if ( exists $ENV{PERLDB_RESTART} ) {
1387
1388     # We're restarting, so we don't need the flag that says to restart anymore.
1389     delete $ENV{PERLDB_RESTART};
1390
1391     # $restart = 1;
1392     @hist          = get_list('PERLDB_HIST');
1393     %break_on_load = get_list("PERLDB_ON_LOAD");
1394     %postponed     = get_list("PERLDB_POSTPONE");
1395
1396         share(@hist);
1397         share(@truehist);
1398         share(%break_on_load);
1399         share(%postponed);
1400
1401     # restore breakpoints/actions
1402     my @had_breakpoints = get_list("PERLDB_VISITED");
1403     for my $file_idx ( 0 .. $#had_breakpoints ) {
1404         my $filename = $had_breakpoints[$file_idx];
1405         my %pf = get_list("PERLDB_FILE_$file_idx");
1406         $postponed_file{ $filename } = \%pf if %pf;
1407         my @lines = sort {$a <=> $b} keys(%pf);
1408         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1409         for my $line_idx (0 .. $#lines) {
1410             _set_breakpoint_enabled_status(
1411                 $filename,
1412                 $lines[$line_idx],
1413                 ($enabled_statuses[$line_idx] ? 1 : ''),
1414             );
1415         }
1416     }
1417
1418     # restore options
1419     my %opt = get_list("PERLDB_OPT");
1420     my ( $opt, $val );
1421     while ( ( $opt, $val ) = each %opt ) {
1422         $val =~ s/[\\\']/\\$1/g;
1423         parse_options("$opt'$val'");
1424     }
1425
1426     # restore original @INC
1427     @INC     = get_list("PERLDB_INC");
1428     @ini_INC = @INC;
1429
1430     # return pre/postprompt actions and typeahead buffer
1431     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1432     $pre       = [ get_list("PERLDB_PRE") ];
1433     $post      = [ get_list("PERLDB_POST") ];
1434     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1435 } ## end if (exists $ENV{PERLDB_RESTART...
1436
1437 =head2 SETTING UP THE TERMINAL
1438
1439 Now, we'll decide how the debugger is going to interact with the user.
1440 If there's no TTY, we set the debugger to run non-stop; there's not going
1441 to be anyone there to enter commands.
1442
1443 =cut
1444
1445 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1446 use vars qw($lineinfo $doccmd);
1447
1448 if ($notty) {
1449     $runnonstop = 1;
1450         share($runnonstop);
1451 }
1452
1453 =pod
1454
1455 If there is a TTY, we have to determine who it belongs to before we can
1456 proceed. If this is a slave editor or graphical debugger (denoted by
1457 the first command-line switch being '-emacs'), we shift this off and
1458 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1459
1460 =cut
1461
1462 else {
1463
1464     # Is Perl being run from a slave editor or graphical debugger?
1465     # If so, don't use readline, and set $slave_editor = 1.
1466     $slave_editor =
1467       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1468     $rl = 0, shift(@main::ARGV) if $slave_editor;
1469
1470     #require Term::ReadLine;
1471
1472 =pod
1473
1474 We then determine what the console should be on various systems:
1475
1476 =over 4
1477
1478 =item * Cygwin - We use C<stdin> instead of a separate device.
1479
1480 =cut
1481
1482     if ( $^O eq 'cygwin' ) {
1483
1484         # /dev/tty is binary. use stdin for textmode
1485         undef $console;
1486     }
1487
1488 =item * Unix - use C</dev/tty>.
1489
1490 =cut
1491
1492     elsif ( -e "/dev/tty" ) {
1493         $console = "/dev/tty";
1494     }
1495
1496 =item * Windows or MSDOS - use C<con>.
1497
1498 =cut
1499
1500     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1501         $console = "con";
1502     }
1503
1504 =item * VMS - use C<sys$command>.
1505
1506 =cut
1507
1508     else {
1509
1510         # everything else is ...
1511         $console = "sys\$command";
1512     }
1513
1514 =pod
1515
1516 =back
1517
1518 Several other systems don't use a specific console. We C<undef $console>
1519 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1520 with a slave editor, Epoc).
1521
1522 =cut
1523
1524     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1525
1526         # /dev/tty is binary. use stdin for textmode
1527         $console = undef;
1528     }
1529
1530     if ( $^O eq 'NetWare' ) {
1531
1532         # /dev/tty is binary. use stdin for textmode
1533         $console = undef;
1534     }
1535
1536     # In OS/2, we need to use STDIN to get textmode too, even though
1537     # it pretty much looks like Unix otherwise.
1538     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1539     {    # In OS/2
1540         $console = undef;
1541     }
1542
1543     # EPOC also falls into the 'got to use STDIN' camp.
1544     if ( $^O eq 'epoc' ) {
1545         $console = undef;
1546     }
1547
1548 =pod
1549
1550 If there is a TTY hanging around from a parent, we use that as the console.
1551
1552 =cut
1553
1554     $console = $tty if defined $tty;
1555
1556 =head2 SOCKET HANDLING
1557
1558 The debugger is capable of opening a socket and carrying out a debugging
1559 session over the socket.
1560
1561 If C<RemotePort> was defined in the options, the debugger assumes that it
1562 should try to start a debugging session on that port. It builds the socket
1563 and then tries to connect the input and output filehandles to it.
1564
1565 =cut
1566
1567     # Handle socket stuff.
1568
1569     if ( defined $remoteport ) {
1570
1571         # If RemotePort was defined in the options, connect input and output
1572         # to the socket.
1573         $IN = $OUT = connect_remoteport();
1574     } ## end if (defined $remoteport)
1575
1576 =pod
1577
1578 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1579 this is probably a situation where multiple debuggers are running (for example,
1580 a backticked command that starts up another debugger). We create a new IN and
1581 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1582 and if we can.
1583
1584 =cut
1585
1586     # Non-socket.
1587     else {
1588
1589         # Two debuggers running (probably a system or a backtick that invokes
1590         # the debugger itself under the running one). create a new IN and OUT
1591         # filehandle, and do the necessary mojo to create a new tty if we
1592         # know how, and we can.
1593         create_IN_OUT(4) if $CreateTTY & 4;
1594         if ($console) {
1595
1596             # If we have a console, check to see if there are separate ins and
1597             # outs to open. (They are assumed identical if not.)
1598
1599             my ( $i, $o ) = split /,/, $console;
1600             $o = $i unless defined $o;
1601
1602             # read/write on in, or just read, or read on STDIN.
1603             open( IN,      "+<$i" )
1604               || open( IN, "<$i" )
1605               || open( IN, "<&STDIN" );
1606
1607             # read/write/create/clobber out, or write/create/clobber out,
1608             # or merge with STDERR, or merge with STDOUT.
1609                  open( OUT, "+>$o" )
1610               || open( OUT, ">$o" )
1611               || open( OUT, ">&STDERR" )
1612               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1613
1614         } ## end if ($console)
1615         elsif ( not defined $console ) {
1616
1617             # No console. Open STDIN.
1618             open( IN, "<&STDIN" );
1619
1620             # merge with STDERR, or with STDOUT.
1621             open( OUT,      ">&STDERR" )
1622               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1623             $console = 'STDIN/OUT';
1624         } ## end elsif (not defined $console)
1625
1626         # Keep copies of the filehandles so that when the pager runs, it
1627         # can close standard input without clobbering ours.
1628         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1629     } ## end elsif (from if(defined $remoteport))
1630
1631     # Unbuffer DB::OUT. We need to see responses right away.
1632     my $previous = select($OUT);
1633     $| = 1;                                  # for DB::OUT
1634     select($previous);
1635
1636     # Line info goes to debugger output unless pointed elsewhere.
1637     # Pointing elsewhere makes it possible for slave editors to
1638     # keep track of file and position. We have both a filehandle
1639     # and a I/O description to keep track of.
1640     $LINEINFO = $OUT     unless defined $LINEINFO;
1641     $lineinfo = $console unless defined $lineinfo;
1642         # share($LINEINFO); # <- unable to share globs
1643         share($lineinfo);   #
1644
1645 =pod
1646
1647 To finish initialization, we show the debugger greeting,
1648 and then call the C<afterinit()> subroutine if there is one.
1649
1650 =cut
1651
1652     # Show the debugger greeting.
1653     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1654     unless ($runnonstop) {
1655         local $\ = '';
1656         local $, = '';
1657         if ( $term_pid eq '-1' ) {
1658             print $OUT "\nDaughter DB session started...\n";
1659         }
1660         else {
1661             print $OUT "\nLoading DB routines from $header\n";
1662             print $OUT (
1663                 "Editor support ",
1664                 $slave_editor ? "enabled" : "available", ".\n"
1665             );
1666             print $OUT
1667 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1668         } ## end else [ if ($term_pid eq '-1')
1669     } ## end unless ($runnonstop)
1670 } ## end else [ if ($notty)
1671
1672 # XXX This looks like a bug to me.
1673 # Why copy to @ARGS and then futz with @args?
1674 @ARGS = @ARGV;
1675 # for (@args) {
1676     # Make sure backslashes before single quotes are stripped out, and
1677     # keep args unless they are numeric (XXX why?)
1678     # s/\'/\\\'/g;                      # removed while not justified understandably
1679     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1680 # }
1681
1682 # If there was an afterinit() sub defined, call it. It will get
1683 # executed in our scope, so it can fiddle with debugger globals.
1684 if ( defined &afterinit ) {    # May be defined in $rcfile
1685     &afterinit();
1686 }
1687
1688 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1689 use vars qw($I_m_init);
1690
1691 $I_m_init = 1;
1692
1693 ############################################################ Subroutines
1694
1695 =head1 SUBROUTINES
1696
1697 =head2 DB
1698
1699 This gigantic subroutine is the heart of the debugger. Called before every
1700 statement, its job is to determine if a breakpoint has been reached, and
1701 stop if so; read commands from the user, parse them, and execute
1702 them, and then send execution off to the next statement.
1703
1704 Note that the order in which the commands are processed is very important;
1705 some commands earlier in the loop will actually alter the C<$cmd> variable
1706 to create other commands to be executed later. This is all highly I<optimized>
1707 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1708 see what's happening in any given command.
1709
1710 =cut
1711
1712 use vars qw(
1713     $action
1714     %alias
1715     $cmd
1716     $doret
1717     $fall_off_end
1718     $file
1719     $filename_ini
1720     $finished
1721     %had_breakpoints
1722     $incr
1723     $laststep
1724     $level
1725     $max
1726     @old_watch
1727     $package
1728     $rc
1729     $sh
1730     @stack
1731     $stack_depth
1732     @to_watch
1733     $try
1734 );
1735
1736 sub DB {
1737
1738     # lock the debugger and get the thread id for the prompt
1739         lock($DBGR);
1740         my $tid;
1741         my $position;
1742         my ($prefix, $after, $infix);
1743         my $pat;
1744         my $end;
1745
1746         if ($ENV{PERL5DB_THREADED}) {
1747                 $tid = eval { "[".threads->tid."]" };
1748         }
1749
1750     # Check for whether we should be running continuously or not.
1751     # _After_ the perl program is compiled, $single is set to 1:
1752     if ( $single and not $second_time++ ) {
1753
1754         # Options say run non-stop. Run until we get an interrupt.
1755         if ($runnonstop) {    # Disable until signal
1756                 # If there's any call stack in place, turn off single
1757                 # stepping into subs throughout the stack.
1758             for ( my $i = 0 ; $i <= $stack_depth ; ) {
1759                 $stack[ $i++ ] &= ~1;
1760             }
1761
1762             # And we are now no longer in single-step mode.
1763             $single = 0;
1764
1765             # If we simply returned at this point, we wouldn't get
1766             # the trace info. Fall on through.
1767             # return;
1768         } ## end if ($runnonstop)
1769
1770         elsif ($ImmediateStop) {
1771
1772             # We are supposed to stop here; XXX probably a break.
1773             $ImmediateStop = 0;    # We've processed it; turn it off
1774             $signal        = 1;    # Simulate an interrupt to force
1775                                    # us into the command loop
1776         }
1777     } ## end if ($single and not $second_time...
1778
1779     # If we're in single-step mode, or an interrupt (real or fake)
1780     # has occurred, turn off non-stop mode.
1781     $runnonstop = 0 if $single or $signal;
1782
1783     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1784     # The code being debugged may have altered them.
1785     &save;
1786
1787     # Since DB::DB gets called after every line, we can use caller() to
1788     # figure out where we last were executing. Sneaky, eh? This works because
1789     # caller is returning all the extra information when called from the
1790     # debugger.
1791     local ( $package, $filename, $line ) = caller;
1792     $filename_ini = $filename;
1793
1794     # set up the context for DB::eval, so it can properly execute
1795     # code on behalf of the user. We add the package in so that the
1796     # code is eval'ed in the proper package (not in the debugger!).
1797     local $usercontext = _calc_usercontext($package);
1798
1799     # Create an alias to the active file magical array to simplify
1800     # the code here.
1801     local (*dbline) = $main::{ '_<' . $filename };
1802
1803     # Last line in the program.
1804     my $max = $#dbline;
1805
1806     # if we have something here, see if we should break.
1807     if ( $dbline{$line}
1808         && _is_breakpoint_enabled($filename, $line)
1809         && ( my ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1810     {
1811
1812         # Stop if the stop criterion says to just stop.
1813         if ( $stop eq '1' ) {
1814             $signal |= 1;
1815         }
1816
1817         # It's a conditional stop; eval it in the user's context and
1818         # see if we should stop. If so, remove the one-time sigil.
1819         elsif ($stop) {
1820             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1821             &eval;
1822             # If the breakpoint is temporary, then delete its enabled status.
1823             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1824                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1825             }
1826         }
1827     } ## end if ($dbline{$line} && ...
1828
1829     # Preserve the current stop-or-not, and see if any of the W
1830     # (watch expressions) has changed.
1831     my $was_signal = $signal;
1832
1833     # If we have any watch expressions ...
1834     if ( $trace & 2 ) {
1835         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1836             $evalarg = $to_watch[$n];
1837             local $onetimeDump;    # Tell DB::eval() to not output results
1838
1839             # Fix context DB::eval() wants to return an array, but
1840             # we need a scalar here.
1841             my ($val) = join( "', '", &eval );
1842             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1843
1844             # Did it change?
1845             if ( $val ne $old_watch[$n] ) {
1846
1847                 # Yep! Show the difference, and fake an interrupt.
1848                 $signal = 1;
1849                 print $OUT <<EOP;
1850 Watchpoint $n:\t$to_watch[$n] changed:
1851     old value:\t$old_watch[$n]
1852     new value:\t$val
1853 EOP
1854                 $old_watch[$n] = $val;
1855             } ## end if ($val ne $old_watch...
1856         } ## end for (my $n = 0 ; $n <= ...
1857     } ## end if ($trace & 2)
1858
1859 =head2 C<watchfunction()>
1860
1861 C<watchfunction()> is a function that can be defined by the user; it is a
1862 function which will be run on each entry to C<DB::DB>; it gets the
1863 current package, filename, and line as its parameters.
1864
1865 The watchfunction can do anything it likes; it is executing in the
1866 debugger's context, so it has access to all of the debugger's internal
1867 data structures and functions.
1868
1869 C<watchfunction()> can control the debugger's actions. Any of the following
1870 will cause the debugger to return control to the user's program after
1871 C<watchfunction()> executes:
1872
1873 =over 4
1874
1875 =item *
1876
1877 Returning a false value from the C<watchfunction()> itself.
1878
1879 =item *
1880
1881 Altering C<$single> to a false value.
1882
1883 =item *
1884
1885 Altering C<$signal> to a false value.
1886
1887 =item *
1888
1889 Turning off the C<4> bit in C<$trace> (this also disables the
1890 check for C<watchfunction()>. This can be done with
1891
1892     $trace &= ~4;
1893
1894 =back
1895
1896 =cut
1897
1898     # If there's a user-defined DB::watchfunction, call it with the
1899     # current package, filename, and line. The function executes in
1900     # the DB:: package.
1901     if ( $trace & 4 ) {    # User-installed watch
1902         return
1903           if watchfunction( $package, $filename, $line )
1904           and not $single
1905           and not $was_signal
1906           and not( $trace & ~4 );
1907     } ## end if ($trace & 4)
1908
1909     # Pick up any alteration to $signal in the watchfunction, and
1910     # turn off the signal now.
1911     $was_signal = $signal;
1912     $signal     = 0;
1913
1914 =head2 GETTING READY TO EXECUTE COMMANDS
1915
1916 The debugger decides to take control if single-step mode is on, the
1917 C<t> command was entered, or the user generated a signal. If the program
1918 has fallen off the end, we set things up so that entering further commands
1919 won't cause trouble, and we say that the program is over.
1920
1921 =cut
1922
1923     # Make sure that we always print if asked for explicitly regardless
1924     # of $trace_to_depth .
1925     my $explicit_stop = ($single || $was_signal);
1926
1927     # Check to see if we should grab control ($single true,
1928     # trace set appropriately, or we got a signal).
1929     if ( $explicit_stop || ( $trace & 1 ) ) {
1930
1931         # Yes, grab control.
1932         if ($slave_editor) {
1933
1934             # Tell the editor to update its position.
1935             $position = "\032\032$filename:$line:0\n";
1936             print_lineinfo($position);
1937         }
1938
1939 =pod
1940
1941 Special check: if we're in package C<DB::fake>, we've gone through the
1942 C<END> block at least once. We set up everything so that we can continue
1943 to enter commands and have a valid context to be in.
1944
1945 =cut
1946
1947         elsif ( $package eq 'DB::fake' ) {
1948
1949             # Fallen off the end already.
1950             $term || &setterm;
1951             print_help(<<EOP);
1952 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1953   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1954   B<h q>, B<h R> or B<h o> to get additional info.
1955 EOP
1956
1957             # Set the DB::eval context appropriately.
1958             $package     = 'main';
1959             $usercontext = _calc_usercontext($package);
1960         } ## end elsif ($package eq 'DB::fake')
1961
1962 =pod
1963
1964 If the program hasn't finished executing, we scan forward to the
1965 next executable line, print that out, build the prompt from the file and line
1966 number information, and print that.
1967
1968 =cut
1969
1970         else {
1971
1972
1973             # Still somewhere in the midst of execution. Set up the
1974             #  debugger prompt.
1975             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
1976                                  # Perl 5 ones (sorry, we don't print Klingon
1977                                  #module names)
1978
1979             $prefix = $sub =~ /::/ ? "" : ($package . '::');
1980             $prefix .= "$sub($filename:";
1981             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
1982
1983             # Break up the prompt if it's really long.
1984             if ( length($prefix) > 30 ) {
1985                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
1986                 $prefix   = "";
1987                 $infix    = ":\t";
1988             }
1989             else {
1990                 $infix    = "):\t";
1991                 $position = "$prefix$line$infix$dbline[$line]$after";
1992             }
1993
1994             # Print current line info, indenting if necessary.
1995             if ($frame) {
1996                 print_lineinfo( ' ' x $stack_depth,
1997                     "$line:\t$dbline[$line]$after" );
1998             }
1999             else {
2000                 depth_print_lineinfo($explicit_stop, $position);
2001             }
2002
2003             # Scan forward, stopping at either the end or the next
2004             # unbreakable line.
2005             for ( my $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2006             {    #{ vi
2007
2008                 # Drop out on null statements, block closers, and comments.
2009                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2010
2011                 # Drop out if the user interrupted us.
2012                 last if $signal;
2013
2014                 # Append a newline if the line doesn't have one. Can happen
2015                 # in eval'ed text, for instance.
2016                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2017
2018                 # Next executable line.
2019                 my $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2020                 $position .= $incr_pos;
2021                 if ($frame) {
2022
2023                     # Print it indented if tracing is on.
2024                     print_lineinfo( ' ' x $stack_depth,
2025                         "$i:\t$dbline[$i]$after" );
2026                 }
2027                 else {
2028                     depth_print_lineinfo($explicit_stop, $incr_pos);
2029                 }
2030             } ## end for ($i = $line + 1 ; $i...
2031         } ## end else [ if ($slave_editor)
2032     } ## end if ($single || ($trace...
2033
2034 =pod
2035
2036 If there's an action to be executed for the line we stopped at, execute it.
2037 If there are any preprompt actions, execute those as well.
2038
2039 =cut
2040
2041     # If there's an action, do it now.
2042     $evalarg = $action, &eval if $action;
2043
2044     # Are we nested another level (e.g., did we evaluate a function
2045     # that had a breakpoint in it at the debugger prompt)?
2046     if ( $single || $was_signal ) {
2047
2048         # Yes, go down a level.
2049         local $level = $level + 1;
2050
2051         # Do any pre-prompt actions.
2052         foreach $evalarg (@$pre) {
2053             &eval;
2054         }
2055
2056         # Complain about too much recursion if we passed the limit.
2057         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2058           if $single & 4;
2059
2060         # The line we're currently on. Set $incr to -1 to stay here
2061         # until we get a command that tells us to advance.
2062         $start = $line;
2063         $incr  = -1;      # for backward motion.
2064
2065         # Tack preprompt debugger actions ahead of any actual input.
2066         @typeahead = ( @$pretype, @typeahead );
2067
2068 =head2 WHERE ARE WE?
2069
2070 XXX Relocate this section?
2071
2072 The debugger normally shows the line corresponding to the current line of
2073 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2074 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2075
2076 C<$incr> controls by how many lines the I<current> line should move forward
2077 after a command is executed. If set to -1, this indicates that the I<current>
2078 line shouldn't change.
2079
2080 C<$start> is the I<current> line. It is used for things like knowing where to
2081 move forwards or backwards from when doing an C<L> or C<-> command.
2082
2083 C<$max> tells the debugger where the last line of the current file is. It's
2084 used to terminate loops most often.
2085
2086 =head2 THE COMMAND LOOP
2087
2088 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2089 in two parts:
2090
2091 =over 4
2092
2093 =item *
2094
2095 The outer part of the loop, starting at the C<CMD> label. This loop
2096 reads a command and then executes it.
2097
2098 =item *
2099
2100 The inner part of the loop, starting at the C<PIPE> label. This part
2101 is wholly contained inside the C<CMD> block and only executes a command.
2102 Used to handle commands running inside a pager.
2103
2104 =back
2105
2106 So why have two labels to restart the loop? Because sometimes, it's easier to
2107 have a command I<generate> another command and then re-execute the loop to do
2108 the new command. This is faster, but perhaps a bit more convoluted.
2109
2110 =cut
2111
2112         # The big command dispatch loop. It keeps running until the
2113         # user yields up control again.
2114         #
2115         # If we have a terminal for input, and we get something back
2116         # from readline(), keep on processing.
2117         my $piped;
2118         my $selected;
2119
2120       CMD:
2121         while (
2122
2123             # We have a terminal, or can get one ...
2124             ( $term || &setterm ),
2125
2126             # ... and it belogs to this PID or we get one for this PID ...
2127             ( $term_pid == $$ or resetterm(1) ),
2128
2129             # ... and we got a line of command input ...
2130             defined(
2131                 $cmd = &readline(
2132                         "$pidprompt $tid DB"
2133                       . ( '<' x $level )
2134                       . ( $#hist + 1 )
2135                       . ( '>' x $level ) . " "
2136                 )
2137             )
2138           )
2139         {
2140
2141                         share($cmd);
2142             # ... try to execute the input as debugger commands.
2143
2144             # Don't stop running.
2145             $single = 0;
2146
2147             # No signal is active.
2148             $signal = 0;
2149
2150             # Handle continued commands (ending with \):
2151             $cmd =~ s/\\$/\n/ && do {
2152                 $cmd .= &readline("  cont: ");
2153                 redo CMD;
2154             };
2155
2156 =head4 The null command
2157
2158 A newline entered by itself means I<re-execute the last command>. We grab the
2159 command out of C<$laststep> (where it was recorded previously), and copy it
2160 back into C<$cmd> to be executed below. If there wasn't any previous command,
2161 we'll do nothing below (no command will match). If there was, we also save it
2162 in the command history and fall through to allow the command parsing to pick
2163 it up.
2164
2165 =cut
2166
2167             # Empty input means repeat the last command.
2168             $cmd =~ /^$/ && ( $cmd = $laststep );
2169             chomp($cmd);    # get rid of the annoying extra newline
2170             push( @hist, $cmd ) if length($cmd) > 1;
2171             push( @truehist, $cmd );
2172                         share(@hist);
2173                         share(@truehist);
2174
2175             # This is a restart point for commands that didn't arrive
2176             # via direct user input. It allows us to 'redo PIPE' to
2177             # re-execute command processing without reading a new command.
2178           PIPE: {
2179                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2180                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2181                 my ($i) = split( /\s+/, $cmd );
2182
2183 =head3 COMMAND ALIASES
2184
2185 The debugger can create aliases for commands (these are stored in the
2186 C<%alias> hash). Before a command is executed, the command loop looks it up
2187 in the alias hash and substitutes the contents of the alias for the command,
2188 completely replacing it.
2189
2190 =cut
2191
2192                 # See if there's an alias for the command, and set it up if so.
2193                 if ( $alias{$i} ) {
2194
2195                     # Squelch signal handling; we want to keep control here
2196                     # if something goes loco during the alias eval.
2197                     local $SIG{__DIE__};
2198                     local $SIG{__WARN__};
2199
2200                     # This is a command, so we eval it in the DEBUGGER's
2201                     # scope! Otherwise, we can't see the special debugger
2202                     # variables, or get to the debugger's subs. (Well, we
2203                     # _could_, but why make it even more complicated?)
2204                     eval "\$cmd =~ $alias{$i}";
2205                     if ($@) {
2206                         local $\ = '';
2207                         print $OUT "Couldn't evaluate '$i' alias: $@";
2208                         next CMD;
2209                     }
2210                 } ## end if ($alias{$i})
2211
2212 =head3 MAIN-LINE COMMANDS
2213
2214 All of these commands work up to and after the program being debugged has
2215 terminated.
2216
2217 =head4 C<q> - quit
2218
2219 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2220 try to execute further, cleaning any restart-related stuff out of the
2221 environment, and executing with the last value of C<$?>.
2222
2223 =cut
2224
2225                 $cmd =~ /^q$/ && do {
2226                     $fall_off_end = 1;
2227                     clean_ENV();
2228                     exit $?;
2229                 };
2230
2231 =head4 C<t> - trace [n]
2232
2233 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2234 If level is specified, set C<$trace_to_depth>.
2235
2236 =cut
2237
2238                 $cmd =~ /^t(?:\s+(\d+))?$/ && do {
2239                     my $levels = $1;
2240                     $trace ^= 1;
2241                     local $\ = '';
2242                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2243                     print $OUT "Trace = "
2244                       . ( ( $trace & 1 )
2245                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2246                       : "off" ) . "\n";
2247                     next CMD;
2248                 };
2249
2250 =head4 C<S> - list subroutines matching/not matching a pattern
2251
2252 Walks through C<%sub>, checking to see whether or not to print the name.
2253
2254 =cut
2255
2256                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2257
2258                     my $Srev     = defined $2;     # Reverse scan?
2259                     my $Spatt    = $3;             # The pattern (if any) to use.
2260                     my $Snocheck = !defined $1;    # No args - print all subs.
2261
2262                     # Need to make these sane here.
2263                     local $\ = '';
2264                     local $, = '';
2265
2266                     # Search through the debugger's magical hash of subs.
2267                     # If $nocheck is true, just print the sub name.
2268                     # Otherwise, check it against the pattern. We then use
2269                     # the XOR trick to reverse the condition as required.
2270                     foreach $subname ( sort( keys %sub ) ) {
2271                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2272                             print $OUT $subname, "\n";
2273                         }
2274                     }
2275                     next CMD;
2276                 };
2277
2278 =head4 C<X> - list variables in current package
2279
2280 Since the C<V> command actually processes this, just change this to the
2281 appropriate C<V> command and fall through.
2282
2283 =cut
2284
2285                 $cmd =~ s/^X\b/V $package/;
2286
2287 =head4 C<V> - list variables
2288
2289 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2290
2291 =cut
2292
2293                 # Bare V commands get the currently-being-debugged package
2294                 # added.
2295                 $cmd =~ /^V$/ && do {
2296                     $cmd = "V $package";
2297                 };
2298
2299                 # V - show variables in package.
2300                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2301
2302                     # Save the currently selected filehandle and
2303                     # force output to debugger's filehandle (dumpvar
2304                     # just does "print" for output).
2305                     my $savout = select($OUT);
2306
2307                     # Grab package name and variables to dump.
2308                     $packname = $1;
2309                     my @vars     = split( ' ', $2 );
2310
2311                     # If main::dumpvar isn't here, get it.
2312                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2313                     if ( defined &main::dumpvar ) {
2314
2315                         # We got it. Turn off subroutine entry/exit messages
2316                         # for the moment, along with return values.
2317                         local $frame = 0;
2318                         local $doret = -2;
2319
2320                         # must detect sigpipe failures  - not catching
2321                         # then will cause the debugger to die.
2322                         eval {
2323                             &main::dumpvar(
2324                                 $packname,
2325                                 defined $option{dumpDepth}
2326                                 ? $option{dumpDepth}
2327                                 : -1,    # assume -1 unless specified
2328                                 @vars
2329                             );
2330                         };
2331
2332                         # The die doesn't need to include the $@, because
2333                         # it will automatically get propagated for us.
2334                         if ($@) {
2335                             die unless $@ =~ /dumpvar print failed/;
2336                         }
2337                     } ## end if (defined &main::dumpvar)
2338                     else {
2339
2340                         # Couldn't load dumpvar.
2341                         print $OUT "dumpvar.pl not available.\n";
2342                     }
2343
2344                     # Restore the output filehandle, and go round again.
2345                     select($savout);
2346                     next CMD;
2347                 };
2348
2349 =head4 C<x> - evaluate and print an expression
2350
2351 Hands the expression off to C<DB::eval>, setting it up to print the value
2352 via C<dumpvar.pl> instead of just printing it directly.
2353
2354 =cut
2355
2356                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2357                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2358
2359                     # handle special  "x 3 blah" syntax XXX propagate
2360                     # doc back to special variables.
2361                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2362                         $onetimedumpDepth = $1;
2363                     }
2364                 };
2365
2366 =head4 C<m> - print methods
2367
2368 Just uses C<DB::methods> to determine what methods are available.
2369
2370 =cut
2371
2372                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2373                     methods($1);
2374                     next CMD;
2375                 };
2376
2377                 # m expr - set up DB::eval to do the work
2378                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2379                     $onetimeDump = 'methods';   #  method output gets used there
2380                 };
2381
2382 =head4 C<f> - switch files
2383
2384 =cut
2385
2386                 $cmd =~ /^f\b\s*(.*)/ && do {
2387                     $file = $1;
2388                     $file =~ s/\s+$//;
2389
2390                     # help for no arguments (old-style was return from sub).
2391                     if ( !$file ) {
2392                         print $OUT
2393                           "The old f command is now the r command.\n";    # hint
2394                         print $OUT "The new f command switches filenames.\n";
2395                         next CMD;
2396                     } ## end if (!$file)
2397
2398                     # if not in magic file list, try a close match.
2399                     if ( !defined $main::{ '_<' . $file } ) {
2400                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2401                             {
2402                                 $try = substr( $try, 2 );
2403                                 print $OUT "Choosing $try matching '$file':\n";
2404                                 $file = $try;
2405                             }
2406                         } ## end if (($try) = grep(m#^_<.*$file#...
2407                     } ## end if (!defined $main::{ ...
2408
2409                     # If not successfully switched now, we failed.
2410                     if ( !defined $main::{ '_<' . $file } ) {
2411                         print $OUT "No file matching '$file' is loaded.\n";
2412                         next CMD;
2413                     }
2414
2415                     # We switched, so switch the debugger internals around.
2416                     elsif ( $file ne $filename ) {
2417                         *dbline   = $main::{ '_<' . $file };
2418                         $max      = $#dbline;
2419                         $filename = $file;
2420                         $start    = 1;
2421                         $cmd      = "l";
2422                     } ## end elsif ($file ne $filename)
2423
2424                     # We didn't switch; say we didn't.
2425                     else {
2426                         print $OUT "Already in $file.\n";
2427                         next CMD;
2428                     }
2429                 };
2430
2431 =head4 C<.> - return to last-executed line.
2432
2433 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2434 and then we look up the line in the magical C<%dbline> hash.
2435
2436 =cut
2437
2438                 # . command.
2439                 $cmd =~ /^\.$/ && do {
2440                     $incr = -1;    # stay at current line
2441
2442                     # Reset everything to the old location.
2443                     $start    = $line;
2444                     $filename = $filename_ini;
2445                     *dbline   = $main::{ '_<' . $filename };
2446                     $max      = $#dbline;
2447
2448                     # Now where are we?
2449                     print_lineinfo($position);
2450                     next CMD;
2451                 };
2452
2453 =head4 C<-> - back one window
2454
2455 We change C<$start> to be one window back; if we go back past the first line,
2456 we set it to be the first line. We ser C<$incr> to put us back at the
2457 currently-executing line, and then put a C<l $start +> (list one window from
2458 C<$start>) in C<$cmd> to be executed later.
2459
2460 =cut
2461
2462                 # - - back a window.
2463                 $cmd =~ /^-$/ && do {
2464
2465                     # back up by a window; go to 1 if back too far.
2466                     $start -= $incr + $window + 1;
2467                     $start = 1 if $start <= 0;
2468                     $incr  = $window - 1;
2469
2470                     # Generate and execute a "l +" command (handled below).
2471                     $cmd = 'l ' . ($start) . '+';
2472                 };
2473
2474 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2475
2476 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2477 problems, most notably that the default case of several commands destroying
2478 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2479 retain the old commands for those who were used to using them or who preferred
2480 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2481 deal with them instead of processing them in-line.
2482
2483 =cut
2484
2485                 # All of these commands were remapped in perl 5.8.0;
2486                 # we send them off to the secondary dispatcher (see below).
2487                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2488                     &cmd_wrapper( $1, $2, $line );
2489                     next CMD;
2490                 };
2491
2492 =head4 C<y> - List lexicals in higher scope
2493
2494 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2495 above the current one and then displays then using C<dumpvar.pl>.
2496
2497 =cut
2498
2499                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2500
2501                     # See if we've got the necessary support.
2502                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2503                       or &warn(
2504                         $@ =~ /locate/
2505                         ? "PadWalker module not found - please install\n"
2506                         : $@
2507                       )
2508                       and next CMD;
2509
2510                     # Load up dumpvar if we don't have it. If we can, that is.
2511                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2512                     defined &main::dumpvar
2513                       or print $OUT "dumpvar.pl not available.\n"
2514                       and next CMD;
2515
2516                     # Got all the modules we need. Find them and print them.
2517                     my @vars = split( ' ', $2 || '' );
2518
2519                     # Find the pad.
2520                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2521
2522                     # Oops. Can't find it.
2523                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2524
2525                     # Show the desired vars with dumplex().
2526                     my $savout = select($OUT);
2527
2528                     # Have dumplex dump the lexicals.
2529                     dumpvar::dumplex( $_, $h->{$_},
2530                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2531                         @vars )
2532                       for sort keys %$h;
2533                     select($savout);
2534                     next CMD;
2535                 };
2536
2537 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2538
2539 All of the commands below this point don't work after the program being
2540 debugged has ended. All of them check to see if the program has ended; this
2541 allows the commands to be relocated without worrying about a 'line of
2542 demarcation' above which commands can be entered anytime, and below which
2543 they can't.
2544
2545 =head4 C<n> - single step, but don't trace down into subs
2546
2547 Done by setting C<$single> to 2, which forces subs to execute straight through
2548 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2549 so a null command knows what to re-execute.
2550
2551 =cut
2552
2553                 # n - next
2554                 $cmd =~ /^n$/ && do {
2555                     end_report(), next CMD if $finished and $level <= 1;
2556
2557                     # Single step, but don't enter subs.
2558                     $single = 2;
2559
2560                     # Save for empty command (repeat last).
2561                     $laststep = $cmd;
2562                     last CMD;
2563                 };
2564
2565 =head4 C<s> - single-step, entering subs
2566
2567 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2568 subs. Also saves C<s> as C<$lastcmd>.
2569
2570 =cut
2571
2572                 # s - single step.
2573                 $cmd =~ /^s$/ && do {
2574
2575                     # Get out and restart the command loop if program
2576                     # has finished.
2577                     end_report(), next CMD if $finished and $level <= 1;
2578
2579                     # Single step should enter subs.
2580                     $single = 1;
2581
2582                     # Save for empty command (repeat last).
2583                     $laststep = $cmd;
2584                     last CMD;
2585                 };
2586
2587 =head4 C<c> - run continuously, setting an optional breakpoint
2588
2589 Most of the code for this command is taken up with locating the optional
2590 breakpoint, which is either a subroutine name or a line number. We set
2591 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2592 in this and all call levels above this one.
2593
2594 =cut
2595
2596                 # c - start continuous execution.
2597                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2598
2599                     # Hey, show's over. The debugged program finished
2600                     # executing already.
2601                     end_report(), next CMD if $finished and $level <= 1;
2602
2603                     # Capture the place to put a one-time break.
2604                     $subname = $i = $1;
2605
2606                     #  Probably not needed, since we finish an interactive
2607                     #  sub-session anyway...
2608                     # local $filename = $filename;
2609                     # local *dbline = *dbline; # XXX Would this work?!
2610                     #
2611                     # The above question wonders if localizing the alias
2612                     # to the magic array works or not. Since it's commented
2613                     # out, we'll just leave that to speculation for now.
2614
2615                     # If the "subname" isn't all digits, we'll assume it
2616                     # is a subroutine name, and try to find it.
2617                     if ( $subname =~ /\D/ ) {    # subroutine name
2618                             # Qualify it to the current package unless it's
2619                             # already qualified.
2620                         $subname = $package . "::" . $subname
2621                           unless $subname =~ /::/;
2622
2623                         # find_sub will return "file:line_number" corresponding
2624                         # to where the subroutine is defined; we call find_sub,
2625                         # break up the return value, and assign it in one
2626                         # operation.
2627                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2628
2629                         # Force the line number to be numeric.
2630                         $i += 0;
2631
2632                         # If we got a line number, we found the sub.
2633                         if ($i) {
2634
2635                             # Switch all the debugger's internals around so
2636                             # we're actually working with that file.
2637                             $filename = $file;
2638                             *dbline   = $main::{ '_<' . $filename };
2639
2640                             # Mark that there's a breakpoint in this file.
2641                             $had_breakpoints{$filename} |= 1;
2642
2643                             # Scan forward to the first executable line
2644                             # after the 'sub whatever' line.
2645                             $max = $#dbline;
2646                             ++$i while $dbline[$i] == 0 && $i < $max;
2647                         } ## end if ($i)
2648
2649                         # We didn't find a sub by that name.
2650                         else {
2651                             print $OUT "Subroutine $subname not found.\n";
2652                             next CMD;
2653                         }
2654                     } ## end if ($subname =~ /\D/)
2655
2656                     # At this point, either the subname was all digits (an
2657                     # absolute line-break request) or we've scanned through
2658                     # the code following the definition of the sub, looking
2659                     # for an executable, which we may or may not have found.
2660                     #
2661                     # If $i (which we set $subname from) is non-zero, we
2662                     # got a request to break at some line somewhere. On
2663                     # one hand, if there wasn't any real subroutine name
2664                     # involved, this will be a request to break in the current
2665                     # file at the specified line, so we have to check to make
2666                     # sure that the line specified really is breakable.
2667                     #
2668                     # On the other hand, if there was a subname supplied, the
2669                     # preceding block has moved us to the proper file and
2670                     # location within that file, and then scanned forward
2671                     # looking for the next executable line. We have to make
2672                     # sure that one was found.
2673                     #
2674                     # On the gripping hand, we can't do anything unless the
2675                     # current value of $i points to a valid breakable line.
2676                     # Check that.
2677                     if ($i) {
2678
2679                         # Breakable?
2680                         if ( $dbline[$i] == 0 ) {
2681                             print $OUT "Line $i not breakable.\n";
2682                             next CMD;
2683                         }
2684
2685                         # Yes. Set up the one-time-break sigil.
2686                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2687                         _enable_breakpoint_temp_enabled_status($filename, $i);
2688                     } ## end if ($i)
2689
2690                     # Turn off stack tracing from here up.
2691                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2692                         $stack[ $i++ ] &= ~1;
2693                     }
2694                     last CMD;
2695                 };
2696
2697 =head4 C<r> - return from a subroutine
2698
2699 For C<r> to work properly, the debugger has to stop execution again
2700 immediately after the return is executed. This is done by forcing
2701 single-stepping to be on in the call level above the current one. If
2702 we are printing return values when a C<r> is executed, set C<$doret>
2703 appropriately, and force us out of the command loop.
2704
2705 =cut
2706
2707                 # r - return from the current subroutine.
2708                 $cmd =~ /^r$/ && do {
2709
2710                     # Can't do anything if the program's over.
2711                     end_report(), next CMD if $finished and $level <= 1;
2712
2713                     # Turn on stack trace.
2714                     $stack[$stack_depth] |= 1;
2715
2716                     # Print return value unless the stack is empty.
2717                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2718                     last CMD;
2719                 };
2720
2721 =head4 C<T> - stack trace
2722
2723 Just calls C<DB::print_trace>.
2724
2725 =cut
2726
2727                 $cmd =~ /^T$/ && do {
2728                     print_trace( $OUT, 1 );    # skip DB
2729                     next CMD;
2730                 };
2731
2732 =head4 C<w> - List window around current line.
2733
2734 Just calls C<DB::cmd_w>.
2735
2736 =cut
2737
2738                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2739
2740 =head4 C<W> - watch-expression processing.
2741
2742 Just calls C<DB::cmd_W>.
2743
2744 =cut
2745
2746                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2747
2748 =head4 C</> - search forward for a string in the source
2749
2750 We take the argument and treat it as a pattern. If it turns out to be a
2751 bad one, we return the error we got from trying to C<eval> it and exit.
2752 If not, we create some code to do the search and C<eval> it so it can't
2753 mess us up.
2754
2755 =cut
2756
2757                 $cmd =~ /^\/(.*)$/ && do {
2758
2759                     # The pattern as a string.
2760                     my $inpat = $1;
2761
2762                     # Remove the final slash.
2763                     $inpat =~ s:([^\\])/$:$1:;
2764
2765                     # If the pattern isn't null ...
2766                     if ( $inpat ne "" ) {
2767
2768                         # Turn of warn and die procesing for a bit.
2769                         local $SIG{__DIE__};
2770                         local $SIG{__WARN__};
2771
2772                         # Create the pattern.
2773                         eval '$inpat =~ m' . "\a$inpat\a";
2774                         if ( $@ ne "" ) {
2775
2776                             # Oops. Bad pattern. No biscuit.
2777                             # Print the eval error and go back for more
2778                             # commands.
2779                             print $OUT "$@";
2780                             next CMD;
2781                         }
2782                         $pat = $inpat;
2783                     } ## end if ($inpat ne "")
2784
2785                     # Set up to stop on wrap-around.
2786                     $end = $start;
2787
2788                     # Don't move off the current line.
2789                     $incr = -1;
2790
2791                     # Done in eval so nothing breaks if the pattern
2792                     # does something weird.
2793                     eval '
2794                         for (;;) {
2795                             # Move ahead one line.
2796                             ++$start;
2797
2798                             # Wrap if we pass the last line.
2799                             $start = 1 if ($start > $max);
2800
2801                             # Stop if we have gotten back to this line again,
2802                             last if ($start == $end);
2803
2804                             # A hit! (Note, though, that we are doing
2805                             # case-insensitive matching. Maybe a qr//
2806                             # expression would be better, so the user could
2807                             # do case-sensitive matching if desired.
2808                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2809                                 if ($slave_editor) {
2810                                     # Handle proper escaping in the slave.
2811                                     print $OUT "\032\032$filename:$start:0\n";
2812                                 }
2813                                 else {
2814                                     # Just print the line normally.
2815                                     print $OUT "$start:\t",$dbline[$start],"\n";
2816                                 }
2817                                 # And quit since we found something.
2818                                 last;
2819                             }
2820                          } ';
2821
2822                     # If we wrapped, there never was a match.
2823                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2824                     next CMD;
2825                 };
2826
2827 =head4 C<?> - search backward for a string in the source
2828
2829 Same as for C</>, except the loop runs backwards.
2830
2831 =cut
2832
2833                 # ? - backward pattern search.
2834                 $cmd =~ /^\?(.*)$/ && do {
2835
2836                     # Get the pattern, remove trailing question mark.
2837                     my $inpat = $1;
2838                     $inpat =~ s:([^\\])\?$:$1:;
2839
2840                     # If we've got one ...
2841                     if ( $inpat ne "" ) {
2842
2843                         # Turn off die & warn handlers.
2844                         local $SIG{__DIE__};
2845                         local $SIG{__WARN__};
2846                         eval '$inpat =~ m' . "\a$inpat\a";
2847
2848                         if ( $@ ne "" ) {
2849
2850                             # Ouch. Not good. Print the error.
2851                             print $OUT $@;
2852                             next CMD;
2853                         }
2854                         $pat = $inpat;
2855                     } ## end if ($inpat ne "")
2856
2857                     # Where we are now is where to stop after wraparound.
2858                     $end = $start;
2859
2860                     # Don't move away from this line.
2861                     $incr = -1;
2862
2863                     # Search inside the eval to prevent pattern badness
2864                     # from killing us.
2865                     eval '
2866                         for (;;) {
2867                             # Back up a line.
2868                             --$start;
2869
2870                             # Wrap if we pass the first line.
2871
2872                             $start = $max if ($start <= 0);
2873
2874                             # Quit if we get back where we started,
2875                             last if ($start == $end);
2876
2877                             # Match?
2878                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2879                                 if ($slave_editor) {
2880                                     # Yep, follow slave editor requirements.
2881                                     print $OUT "\032\032$filename:$start:0\n";
2882                                 }
2883                                 else {
2884                                     # Yep, just print normally.
2885                                     print $OUT "$start:\t",$dbline[$start],"\n";
2886                                 }
2887
2888                                 # Found, so done.
2889                                 last;
2890                             }
2891                         } ';
2892
2893                     # Say we failed if the loop never found anything,
2894                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2895                     next CMD;
2896                 };
2897
2898 =head4 C<$rc> - Recall command
2899
2900 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2901 that the terminal supports history). It find the the command required, puts it
2902 into C<$cmd>, and redoes the loop to execute it.
2903
2904 =cut
2905
2906                 # $rc - recall command.
2907                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
2908
2909                     # No arguments, take one thing off history.
2910                     pop(@hist) if length($cmd) > 1;
2911
2912                     # Relative (- found)?
2913                     #  Y - index back from most recent (by 1 if bare minus)
2914                     #  N - go to that particular command slot or the last
2915                     #      thing if nothing following.
2916                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
2917
2918                     # Pick out the command desired.
2919                     $cmd = $hist[$i];
2920
2921                     # Print the command to be executed and restart the loop
2922                     # with that command in the buffer.
2923                     print $OUT $cmd, "\n";
2924                     redo CMD;
2925                 };
2926
2927 =head4 C<$sh$sh> - C<system()> command
2928
2929 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2930 C<STDOUT> from getting messed up.
2931
2932 =cut
2933
2934                 # $sh$sh - run a shell command (if it's all ASCII).
2935                 # Can't run shell commands with Unicode in the debugger, hmm.
2936                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
2937
2938                     # System it.
2939                     &system($1);
2940                     next CMD;
2941                 };
2942
2943 =head4 C<$rc I<pattern> $rc> - Search command history
2944
2945 Another command to manipulate C<@hist>: this one searches it with a pattern.
2946 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2947
2948 =cut
2949
2950                 # $rc pattern $rc - find a command in the history.
2951                 $cmd =~ /^$rc([^$rc].*)$/ && do {
2952
2953                     # Create the pattern to use.
2954                     $pat = "^$1";
2955
2956                     # Toss off last entry if length is >1 (and it always is).
2957                     pop(@hist) if length($cmd) > 1;
2958
2959                     # Look backward through the history.
2960                     for ( $i = $#hist ; $i ; --$i ) {
2961
2962                         # Stop if we find it.
2963                         last if $hist[$i] =~ /$pat/;
2964                     }
2965
2966                     if ( !$i ) {
2967
2968                         # Never found it.
2969                         print $OUT "No such command!\n\n";
2970                         next CMD;
2971                     }
2972
2973                     # Found it. Put it in the buffer, print it, and process it.
2974                     $cmd = $hist[$i];
2975                     print $OUT $cmd, "\n";
2976                     redo CMD;
2977                 };
2978
2979 =head4 C<$sh> - Invoke a shell
2980
2981 Uses C<DB::system> to invoke a shell.
2982
2983 =cut
2984
2985                 # $sh - start a shell.
2986                 $cmd =~ /^$sh$/ && do {
2987
2988                     # Run the user's shell. If none defined, run Bourne.
2989                     # We resume execution when the shell terminates.
2990                     &system( $ENV{SHELL} || "/bin/sh" );
2991                     next CMD;
2992                 };
2993
2994 =head4 C<$sh I<command>> - Force execution of a command in a shell
2995
2996 Like the above, but the command is passed to the shell. Again, we use
2997 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2998
2999 =cut
3000
3001                 # $sh command - start a shell and run a command in it.
3002                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3003
3004                     # XXX: using csh or tcsh destroys sigint retvals!
3005                     #&system($1);  # use this instead
3006
3007                     # use the user's shell, or Bourne if none defined.
3008                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3009                     next CMD;
3010                 };
3011
3012 =head4 C<H> - display commands in history
3013
3014 Prints the contents of C<@hist> (if any).
3015
3016 =cut
3017
3018                 $cmd =~ /^H\b\s*\*/ && do {
3019                     @hist = @truehist = ();
3020                     print $OUT "History cleansed\n";
3021                     next CMD;
3022                 };
3023
3024                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3025
3026                     # Anything other than negative numbers is ignored by
3027                     # the (incorrect) pattern, so this test does nothing.
3028                     $end = $2 ? ( $#hist - $2 ) : 0;
3029
3030                     # Set to the minimum if less than zero.
3031                     $hist = 0 if $hist < 0;
3032
3033                     # Start at the end of the array.
3034                     # Stay in while we're still above the ending value.
3035                     # Tick back by one each time around the loop.
3036                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3037
3038                         # Print the command  unless it has no arguments.
3039                         print $OUT "$i: ", $hist[$i], "\n"
3040                           unless $hist[$i] =~ /^.?$/;
3041                     }
3042                     next CMD;
3043                 };
3044
3045 =head4 C<man, doc, perldoc> - look up documentation
3046
3047 Just calls C<runman()> to print the appropriate document.
3048
3049 =cut
3050
3051                 # man, perldoc, doc - show manual pages.
3052                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3053                     runman($1);
3054                     next CMD;
3055                 };
3056
3057 =head4 C<p> - print
3058
3059 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3060 the bottom of the loop.
3061
3062 =cut
3063
3064                 # p - print (no args): print $_.
3065                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3066
3067                 # p - print the given expression.
3068                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3069
3070 =head4 C<=> - define command alias
3071
3072 Manipulates C<%alias> to add or list command aliases.
3073
3074 =cut
3075
3076                 # = - set up a command alias.
3077                 $cmd =~ s/^=\s*// && do {
3078                     my @keys;
3079                     if ( length $cmd == 0 ) {
3080
3081                         # No args, get current aliases.
3082                         @keys = sort keys %alias;
3083                     }
3084                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3085
3086                         # Creating a new alias. $k is alias name, $v is
3087                         # alias value.
3088
3089                         # can't use $_ or kill //g state
3090                         for my $x ( $k, $v ) {
3091
3092                             # Escape "alarm" characters.
3093                             $x =~ s/\a/\\a/g;
3094                         }
3095
3096                         # Substitute key for value, using alarm chars
3097                         # as separators (which is why we escaped them in
3098                         # the command).
3099                         $alias{$k} = "s\a$k\a$v\a";
3100
3101                         # Turn off standard warn and die behavior.
3102                         local $SIG{__DIE__};
3103                         local $SIG{__WARN__};
3104
3105                         # Is it valid Perl?
3106                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3107
3108                             # Nope. Bad alias. Say so and get out.
3109                             print $OUT "Can't alias $k to $v: $@\n";
3110                             delete $alias{$k};
3111                             next CMD;
3112                         }
3113
3114                         # We'll only list the new one.
3115                         @keys = ($k);
3116                     } ## end elsif (my ($k, $v) = ($cmd...
3117
3118                     # The argument is the alias to list.
3119                     else {
3120                         @keys = ($cmd);
3121                     }
3122
3123                     # List aliases.
3124                     for my $k (@keys) {
3125
3126                         # Messy metaquoting: Trim the substitution code off.
3127                         # We use control-G as the delimiter because it's not
3128                         # likely to appear in the alias.
3129                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3130
3131                             # Print the alias.
3132                             print $OUT "$k\t= $1\n";
3133                         }
3134                         elsif ( defined $alias{$k} ) {
3135
3136                             # Couldn't trim it off; just print the alias code.
3137                             print $OUT "$k\t$alias{$k}\n";
3138                         }
3139                         else {
3140
3141                             # No such, dude.
3142                             print "No alias for $k\n";
3143                         }
3144                     } ## end for my $k (@keys)
3145                     next CMD;
3146                 };
3147
3148 =head4 C<source> - read commands from a file.
3149
3150 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3151 pick it up.
3152
3153 =cut
3154
3155                 # source - read commands from a file (or pipe!) and execute.
3156                 $cmd =~ /^source\s+(.*\S)/ && do {
3157                     if ( open my $fh, $1 ) {
3158
3159                         # Opened OK; stick it in the list of file handles.
3160                         push @cmdfhs, $fh;
3161                     }
3162                     else {
3163
3164                         # Couldn't open it.
3165                         &warn("Can't execute '$1': $!\n");
3166                     }
3167                     next CMD;
3168                 };
3169
3170                 $cmd =~ /^(enable|disable)\s+(\S+)\s*$/ && do {
3171                     my ($cmd, $position) = ($1, $2);
3172
3173                     my ($fn, $line_num);
3174                     if ($position =~ m{\A\d+\z})
3175                     {
3176                         $fn = $filename;
3177                         $line_num = $position;
3178                     }
3179                     elsif ($position =~ m{\A(.*):(\d+)\z})
3180                     {
3181                         ($fn, $line_num) = ($1, $2);
3182                     }
3183                     else
3184                     {
3185                         &warn("Wrong spec for enable/disable argument.\n");
3186                     }
3187
3188                     if (defined($fn)) {
3189                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3190                             _set_breakpoint_enabled_status($fn, $line_num,
3191                                 ($cmd eq 'enable' ? 1 : '')
3192                             );
3193                         }
3194                         else {
3195                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3196                         }
3197                     }
3198
3199                     next CMD;
3200                 };
3201
3202 =head4 C<save> - send current history to a file
3203
3204 Takes the complete history, (not the shrunken version you see with C<H>),
3205 and saves it to the given filename, so it can be replayed using C<source>.
3206
3207 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3208
3209 =cut
3210
3211                 # save source - write commands to a file for later use
3212                 $cmd =~ /^save\s*(.*)$/ && do {
3213                     my $file = $1 || '.perl5dbrc';    # default?
3214                     if ( open my $fh, "> $file" ) {
3215
3216                        # chomp to remove extraneous newlines from source'd files
3217                         chomp( my @truelist =
3218                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3219                               @truehist );
3220                         print $fh join( "\n", @truelist );
3221                         print "commands saved in $file\n";
3222                     }
3223                     else {
3224                         &warn("Can't save debugger commands in '$1': $!\n");
3225                     }
3226                     next CMD;
3227                 };
3228
3229 =head4 C<R> - restart
3230
3231 Restart the debugger session.
3232
3233 =head4 C<rerun> - rerun the current session
3234
3235 Return to any given position in the B<true>-history list
3236
3237 =cut
3238
3239                 # R - restart execution.
3240                 # rerun - controlled restart execution.
3241                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3242                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3243
3244                     # Close all non-system fds for a clean restart.  A more
3245                     # correct method would be to close all fds that were not
3246                     # open when the process started, but this seems to be
3247                     # hard.  See "debugger 'R'estart and open database
3248                     # connections" on p5p.
3249
3250                     my $max_fd = 1024; # default if POSIX can't be loaded
3251                     if (eval { require POSIX }) {
3252                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3253                     }
3254
3255                     if (defined $max_fd) {
3256                         foreach ($^F+1 .. $max_fd-1) {
3257                             next unless open FD_TO_CLOSE, "<&=$_";
3258                             close(FD_TO_CLOSE);
3259                         }
3260                     }
3261
3262                     # And run Perl again.  We use exec() to keep the
3263                     # PID stable (and that way $ini_pids is still valid).
3264                     exec(@args) || print $OUT "exec failed: $!\n";
3265
3266                     last CMD;
3267                 };
3268
3269 =head4 C<|, ||> - pipe output through the pager.
3270
3271 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3272 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3273 pipe to the pager (restoring the output filehandles if this fails). If this
3274 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3275 set C<$signal>, sending us back into the debugger.
3276
3277 We then trim off the pipe symbols and C<redo> the command loop at the
3278 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3279 reading another.
3280
3281 =cut
3282
3283                 # || - run command in the pager, with output to DB::OUT.
3284                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3285                     if ( $pager =~ /^\|/ ) {
3286
3287                         # Default pager is into a pipe. Redirect I/O.
3288                         open( SAVEOUT, ">&STDOUT" )
3289                           || &warn("Can't save STDOUT");
3290                         open( STDOUT, ">&OUT" )
3291                           || &warn("Can't redirect STDOUT");
3292                     } ## end if ($pager =~ /^\|/)
3293                     else {
3294
3295                         # Not into a pipe. STDOUT is safe.
3296                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3297                     }
3298
3299                     # Fix up environment to record we have less if so.
3300                     fix_less();
3301
3302                     unless ( $piped = open( OUT, $pager ) ) {
3303
3304                         # Couldn't open pipe to pager.
3305                         &warn("Can't pipe output to '$pager'");
3306                         if ( $pager =~ /^\|/ ) {
3307
3308                             # Redirect I/O back again.
3309                             open( OUT, ">&STDOUT" )    # XXX: lost message
3310                               || &warn("Can't restore DB::OUT");
3311                             open( STDOUT, ">&SAVEOUT" )
3312                               || &warn("Can't restore STDOUT");
3313                             close(SAVEOUT);
3314                         } ## end if ($pager =~ /^\|/)
3315                         else {
3316
3317                             # Redirect I/O. STDOUT already safe.
3318                             open( OUT, ">&STDOUT" )    # XXX: lost message
3319                               || &warn("Can't restore DB::OUT");
3320                         }
3321                         next CMD;
3322                     } ## end unless ($piped = open(OUT,...
3323
3324                     # Set up broken-pipe handler if necessary.
3325                     $SIG{PIPE} = \&DB::catch
3326                       if $pager =~ /^\|/
3327                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3328
3329                     # Save current filehandle, unbuffer out, and put it back.
3330                     $selected = select(OUT);
3331                     $|        = 1;
3332
3333                     # Don't put it back if pager was a pipe.
3334                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3335
3336                     # Trim off the pipe symbols and run the command now.
3337                     $cmd =~ s/^\|+\s*//;
3338                     redo PIPE;
3339                 };
3340
3341 =head3 END OF COMMAND PARSING
3342
3343 Anything left in C<$cmd> at this point is a Perl expression that we want to
3344 evaluate. We'll always evaluate in the user's context, and fully qualify
3345 any variables we might want to address in the C<DB> package.
3346
3347 =cut
3348
3349                 # t - turn trace on.
3350                 $cmd =~ s/^t\s+(\d+)?/\$DB::trace |= 1;\n/ && do {
3351                     $trace_to_depth = $1 ? $stack_depth||0 + $1 : 1E9;
3352                 };
3353
3354                 # s - single-step. Remember the last command was 's'.
3355                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3356
3357                 # n - single-step, but not into subs. Remember last command
3358                 # was 'n'.
3359                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3360
3361             }    # PIPE:
3362
3363             # Make sure the flag that says "the debugger's running" is
3364             # still on, to make sure we get control again.
3365             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3366
3367             # Run *our* eval that executes in the caller's context.
3368             &eval;
3369
3370             # Turn off the one-time-dump stuff now.
3371             if ($onetimeDump) {
3372                 $onetimeDump      = undef;
3373                 $onetimedumpDepth = undef;
3374             }
3375             elsif ( $term_pid == $$ ) {
3376                 eval {          # May run under miniperl, when not available...
3377                     STDOUT->flush();
3378                     STDERR->flush();
3379                 };
3380
3381                 # XXX If this is the master pid, print a newline.
3382                 print $OUT "\n";
3383             }
3384         } ## end while (($term || &setterm...
3385
3386 =head3 POST-COMMAND PROCESSING
3387
3388 After each command, we check to see if the command output was piped anywhere.
3389 If so, we go through the necessary code to unhook the pipe and go back to
3390 our standard filehandles for input and output.
3391
3392 =cut
3393
3394         continue {    # CMD:
3395
3396             # At the end of every command:
3397             if ($piped) {
3398
3399                 # Unhook the pipe mechanism now.
3400                 if ( $pager =~ /^\|/ ) {
3401
3402                     # No error from the child.
3403                     $? = 0;
3404
3405                     # we cannot warn here: the handle is missing --tchrist
3406                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3407
3408                     # most of the $? crud was coping with broken cshisms
3409                     # $? is explicitly set to 0, so this never runs.
3410                     if ($?) {
3411                         print SAVEOUT "Pager '$pager' failed: ";
3412                         if ( $? == -1 ) {
3413                             print SAVEOUT "shell returned -1\n";
3414                         }
3415                         elsif ( $? >> 8 ) {
3416                             print SAVEOUT ( $? & 127 )
3417                               ? " (SIG#" . ( $? & 127 ) . ")"
3418                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3419                         }
3420                         else {
3421                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3422                         }
3423                     } ## end if ($?)
3424
3425                     # Reopen filehandle for our output (if we can) and
3426                     # restore STDOUT (if we can).
3427                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3428                     open( STDOUT, ">&SAVEOUT" )
3429                       || &warn("Can't restore STDOUT");
3430
3431                     # Turn off pipe exception handler if necessary.
3432                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3433
3434                     # Will stop ignoring SIGPIPE if done like nohup(1)
3435                     # does SIGINT but Perl doesn't give us a choice.
3436                 } ## end if ($pager =~ /^\|/)
3437                 else {
3438
3439                     # Non-piped "pager". Just restore STDOUT.
3440                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3441                 }
3442
3443                 # Close filehandle pager was using, restore the normal one
3444                 # if necessary,
3445                 close(SAVEOUT);
3446                 select($selected), $selected = "" unless $selected eq "";
3447
3448                 # No pipes now.
3449                 $piped = "";
3450             } ## end if ($piped)
3451         }    # CMD:
3452
3453 =head3 COMMAND LOOP TERMINATION
3454
3455 When commands have finished executing, we come here. If the user closed the
3456 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3457 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3458 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3459 The interpreter will then execute the next line and then return control to us
3460 again.
3461
3462 =cut
3463
3464         # No more commands? Quit.
3465         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3466
3467         # Evaluate post-prompt commands.
3468         foreach $evalarg (@$post) {
3469             &eval;
3470         }
3471     }    # if ($single || $signal)
3472
3473     # Put the user's globals back where you found them.
3474     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3475     ();
3476 } ## end sub DB
3477
3478 # The following code may be executed now:
3479 # BEGIN {warn 4}
3480
3481 =head2 sub
3482
3483 C<sub> is called whenever a subroutine call happens in the program being
3484 debugged. The variable C<$DB::sub> contains the name of the subroutine
3485 being called.
3486
3487 The core function of this subroutine is to actually call the sub in the proper
3488 context, capturing its output. This of course causes C<DB::DB> to get called
3489 again, repeating until the subroutine ends and returns control to C<DB::sub>
3490 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3491 return value, and returns its captured copy of the return value as its own
3492 return value. The value then feeds back into the program being debugged as if
3493 C<DB::sub> hadn't been there at all.
3494
3495 C<sub> does all the work of printing the subroutine entry and exit messages
3496 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3497 and also prints the return value if needed (for the C<r> command and if
3498 the 16 bit is set in C<$frame>).
3499
3500 It also tracks the subroutine call depth by saving the current setting of
3501 C<$single> in the C<@stack> package global; if this exceeds the value in
3502 C<$deep>, C<sub> automatically turns on printing of the current depth by
3503 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3504 of stop/don't stop on entry to subs set as it currently is set.
3505
3506 =head3 C<caller()> support
3507
3508 If C<caller()> is called from the package C<DB>, it provides some
3509 additional data, in the following order:
3510
3511 =over 4
3512
3513 =item * C<$package>
3514
3515 The package name the sub was in
3516
3517 =item * C<$filename>
3518
3519 The filename it was defined in
3520
3521 =item * C<$line>
3522
3523 The line number it was defined on
3524
3525 =item * C<$subroutine>
3526
3527 The subroutine name; C<(eval)> if an C<eval>().
3528
3529 =item * C<$hasargs>
3530
3531 1 if it has arguments, 0 if not
3532
3533 =item * C<$wantarray>
3534
3535 1 if array context, 0 if scalar context
3536
3537 =item * C<$evaltext>
3538
3539 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3540
3541 =item * C<$is_require>
3542
3543 frame was created by a C<use> or C<require> statement
3544
3545 =item * C<$hints>
3546
3547 pragma information; subject to change between versions
3548
3549 =item * C<$bitmask>
3550
3551 pragma information; subject to change between versions
3552
3553 =item * C<@DB::args>
3554
3555 arguments with which the subroutine was invoked
3556
3557 =back
3558
3559 =cut
3560
3561 use vars qw($deep);
3562
3563 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3564 # happy. -- Shlomi Fish
3565 sub DB::sub {
3566         # Do not use a regex in this subroutine -> results in corrupted memory
3567         # See: [perl #66110]
3568
3569         # lock ourselves under threads
3570         lock($DBGR);
3571
3572     # Whether or not the autoloader was running, a scalar to put the
3573     # sub's return value in (if needed), and an array to put the sub's
3574     # return value in (if needed).
3575     my ( $al, $ret, @ret ) = "";
3576         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3577                 print "creating new thread\n";
3578         }
3579
3580     # If the last ten characters are '::AUTOLOAD', note we've traced
3581     # into AUTOLOAD for $sub.
3582     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3583         no strict 'refs';
3584         $al = " for $$sub" if defined $$sub;
3585     }
3586
3587     # We stack the stack pointer and then increment it to protect us
3588     # from a situation that might unwind a whole bunch of call frames
3589     # at once. Localizing the stack pointer means that it will automatically
3590     # unwind the same amount when multiple stack frames are unwound.
3591     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3592
3593     # Expand @stack.
3594     $#stack = $stack_depth;
3595
3596     # Save current single-step setting.
3597     $stack[-1] = $single;
3598
3599     # Turn off all flags except single-stepping.
3600     $single &= 1;
3601
3602     # If we've gotten really deeply recursed, turn on the flag that will
3603     # make us stop with the 'deep recursion' message.
3604     $single |= 4 if $stack_depth == $deep;
3605
3606     # If frame messages are on ...
3607     (
3608         $frame & 4    # Extended frame entry message
3609         ? (
3610             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3611
3612             # Why -1? But it works! :-(
3613             # Because print_trace will call add 1 to it and then call
3614             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3615             # in dump_trace.
3616             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3617           )
3618         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3619
3620           # standard frame entry message
3621       )
3622       if $frame;
3623
3624     # Determine the sub's return type, and capture appropriately.
3625     if (wantarray) {
3626
3627         # Called in array context. call sub and capture output.
3628         # DB::DB will recursively get control again if appropriate; we'll come
3629         # back here when the sub is finished.
3630         {
3631             no strict 'refs';
3632             @ret = &$sub;
3633         }
3634
3635         # Pop the single-step value back off the stack.
3636         $single |= $stack[ $stack_depth-- ];
3637
3638         # Check for exit trace messages...
3639         (
3640             $frame & 4    # Extended exit message
3641             ? (
3642                 print_lineinfo( ' ' x $stack_depth, "out " ),
3643                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3644               )
3645             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3646
3647               # Standard exit message
3648           )
3649           if $frame & 2;
3650
3651         # Print the return info if we need to.
3652         if ( $doret eq $stack_depth or $frame & 16 ) {
3653
3654             # Turn off output record separator.
3655             local $\ = '';
3656             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3657
3658             # Indent if we're printing because of $frame tracing.
3659             print $fh ' ' x $stack_depth if $frame & 16;
3660
3661             # Print the return value.
3662             print $fh "list context return from $sub:\n";
3663             dumpit( $fh, \@ret );
3664
3665             # And don't print it again.
3666             $doret = -2;
3667         } ## end if ($doret eq $stack_depth...
3668             # And we have to return the return value now.
3669         @ret;
3670     } ## end if (wantarray)
3671
3672     # Scalar context.
3673     else {
3674         if ( defined wantarray ) {
3675         no strict 'refs';
3676             # Save the value if it's wanted at all.
3677             $ret = &$sub;
3678         }
3679         else {
3680         no strict 'refs';
3681             # Void return, explicitly.
3682             &$sub;
3683             undef $ret;
3684         }
3685
3686         # Pop the single-step value off the stack.
3687         $single |= $stack[ $stack_depth-- ];
3688
3689         # If we're doing exit messages...
3690         (
3691             $frame & 4    # Extended messages
3692             ? (
3693                 print_lineinfo( ' ' x $stack_depth, "out " ),
3694                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3695               )
3696             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3697
3698               # Standard messages
3699           )
3700           if $frame & 2;
3701
3702         # If we are supposed to show the return value... same as before.
3703         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3704             local $\ = '';
3705             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3706             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3707             print $fh (
3708                 defined wantarray
3709                 ? "scalar context return from $sub: "
3710                 : "void context return from $sub\n"
3711             );
3712             dumpit( $fh, $ret ) if defined wantarray;
3713             $doret = -2;
3714         } ## end if ($doret eq $stack_depth...
3715
3716         # Return the appropriate scalar value.
3717         $ret;
3718     } ## end else [ if (wantarray)
3719 } ## end sub _sub
3720
3721 sub lsub : lvalue {
3722
3723     no strict 'refs';
3724
3725         # lock ourselves under threads
3726         lock($DBGR);
3727
3728     # Whether or not the autoloader was running, a scalar to put the
3729     # sub's return value in (if needed), and an array to put the sub's
3730     # return value in (if needed).
3731     my ( $al, $ret, @ret ) = "";
3732         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3733                 print "creating new thread\n";
3734         }
3735
3736     # If the last ten characters are C'::AUTOLOAD', note we've traced
3737     # into AUTOLOAD for $sub.
3738     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3739         $al = " for $$sub";
3740     }
3741
3742     # We stack the stack pointer and then increment it to protect us
3743     # from a situation that might unwind a whole bunch of call frames
3744     # at once. Localizing the stack pointer means that it will automatically
3745     # unwind the same amount when multiple stack frames are unwound.
3746     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3747
3748     # Expand @stack.
3749     $#stack = $stack_depth;
3750
3751     # Save current single-step setting.
3752     $stack[-1] = $single;
3753
3754     # Turn off all flags except single-stepping.
3755     $single &= 1;
3756
3757     # If we've gotten really deeply recursed, turn on the flag that will
3758     # make us stop with the 'deep recursion' message.
3759     $single |= 4 if $stack_depth == $deep;
3760
3761     # If frame messages are on ...
3762     (
3763         $frame & 4    # Extended frame entry message
3764         ? (
3765             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3766
3767             # Why -1? But it works! :-(
3768             # Because print_trace will call add 1 to it and then call
3769             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3770             # in dump_trace.
3771             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3772           )
3773         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3774
3775           # standard frame entry message
3776       )
3777       if $frame;
3778
3779     # Pop the single-step value back off the stack.
3780     $single |= $stack[ $stack_depth-- ];
3781
3782     # call the original lvalue sub.
3783     &$sub;
3784 }
3785
3786 # Abstracting common code from multiple places elsewhere:
3787 sub depth_print_lineinfo {
3788     my $always_print = shift;
3789
3790     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3791 }
3792
3793 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3794
3795 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3796 Most of the changes were to systematize the command structure and to eliminate
3797 commands that threw away user input without checking.
3798
3799 The following sections describe the code added to make it easy to support
3800 multiple command sets with conflicting command names. This section is a start
3801 at unifying all command processing to make it simpler to develop commands.
3802
3803 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3804 number, and C<$dbline> (the current line) as arguments.
3805
3806 Support functions in this section which have multiple modes of failure C<die>
3807 on error; the rest simply return a false value.
3808
3809 The user-interface functions (all of the C<cmd_*> functions) just output
3810 error messages.
3811
3812 =head2 C<%set>
3813
3814 The C<%set> hash defines the mapping from command letter to subroutine
3815 name suffix.
3816
3817 C<%set> is a two-level hash, indexed by set name and then by command name.
3818 Note that trying to set the CommandSet to C<foobar> simply results in the
3819 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3820
3821 =cut
3822
3823 ### The API section
3824
3825 my %set = (    #
3826     'pre580' => {
3827         'a' => 'pre580_a',
3828         'A' => 'pre580_null',
3829         'b' => 'pre580_b',
3830         'B' => 'pre580_null',
3831         'd' => 'pre580_null',
3832         'D' => 'pre580_D',
3833         'h' => 'pre580_h',
3834         'M' => 'pre580_null',
3835         'O' => 'o',
3836         'o' => 'pre580_null',
3837         'v' => 'M',
3838         'w' => 'v',
3839         'W' => 'pre580_W',
3840     },
3841     'pre590' => {
3842         '<'  => 'pre590_prepost',
3843         '<<' => 'pre590_prepost',
3844         '>'  => 'pre590_prepost',
3845         '>>' => 'pre590_prepost',
3846         '{'  => 'pre590_prepost',
3847         '{{' => 'pre590_prepost',
3848     },
3849 );
3850
3851 my %breakpoints_data;
3852
3853 sub _has_breakpoint_data_ref {
3854     my ($filename, $line) = @_;
3855
3856     return (
3857         exists( $breakpoints_data{$filename} )
3858             and
3859         exists( $breakpoints_data{$filename}{$line} )
3860     );
3861 }
3862
3863 sub _get_breakpoint_data_ref {
3864     my ($filename, $line) = @_;
3865
3866     return ($breakpoints_data{$filename}{$line} ||= +{});
3867 }
3868
3869 sub _delete_breakpoint_data_ref {
3870     my ($filename, $line) = @_;
3871
3872     delete($breakpoints_data{$filename}{$line});
3873     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3874         delete($breakpoints_data{$filename});
3875     }
3876
3877     return;
3878 }
3879
3880 sub _set_breakpoint_enabled_status {
3881     my ($filename, $line, $status) = @_;
3882
3883     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3884         ($status ? 1 : '')
3885         ;
3886
3887     return;
3888 }
3889
3890 sub _enable_breakpoint_temp_enabled_status {
3891     my ($filename, $line) = @_;
3892
3893     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3894
3895     return;
3896 }
3897
3898 sub _cancel_breakpoint_temp_enabled_status {
3899     my ($filename, $line) = @_;
3900
3901     my $ref = _get_breakpoint_data_ref($filename, $line);
3902
3903     delete ($ref->{'temp_enabled'});
3904
3905     if (! %$ref) {
3906         _delete_breakpoint_data_ref($filename, $line);
3907     }
3908
3909     return;
3910 }
3911
3912 sub _is_breakpoint_enabled {
3913     my ($filename, $line) = @_;
3914
3915     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3916     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3917 }
3918
3919 =head2 C<cmd_wrapper()> (API)
3920
3921 C<cmd_wrapper()> allows the debugger to switch command sets
3922 depending on the value of the C<CommandSet> option.
3923
3924 It tries to look up the command in the C<%set> package-level I<lexical>
3925 (which means external entities can't fiddle with it) and create the name of
3926 the sub to call based on the value found in the hash (if it's there). I<All>
3927 of the commands to be handled in a set have to be added to C<%set>; if they
3928 aren't found, the 5.8.0 equivalent is called (if there is one).
3929
3930 This code uses symbolic references.
3931
3932 =cut
3933
3934 sub cmd_wrapper {
3935     my $cmd      = shift;
3936     my $line     = shift;
3937     my $dblineno = shift;
3938
3939     # Assemble the command subroutine's name by looking up the
3940     # command set and command name in %set. If we can't find it,
3941     # default to the older version of the command.
3942     my $call = 'cmd_'
3943       . ( $set{$CommandSet}{$cmd}
3944           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3945
3946     # Call the command subroutine, call it by name.
3947     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
3948 } ## end sub cmd_wrapper
3949
3950 =head3 C<cmd_a> (command)
3951
3952 The C<a> command handles pre-execution actions. These are associated with a
3953 particular line, so they're stored in C<%dbline>. We default to the current
3954 line if none is specified.
3955
3956 =cut
3957
3958 sub cmd_a {
3959     my $cmd    = shift;
3960     my $line   = shift || '';    # [.|line] expr
3961     my $dbline = shift;
3962
3963     # If it's dot (here), or not all digits,  use the current line.
3964     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3965
3966     # Should be a line number followed by an expression.
3967     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3968         my ( $lineno, $expr ) = ( $1, $2 );
3969
3970         # If we have an expression ...
3971         if ( length $expr ) {
3972
3973             # ... but the line isn't breakable, complain.
3974             if ( $dbline[$lineno] == 0 ) {
3975                 print $OUT
3976                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3977             }
3978             else {
3979
3980                 # It's executable. Record that the line has an action.
3981                 $had_breakpoints{$filename} |= 2;
3982
3983                 # Remove any action, temp breakpoint, etc.
3984                 $dbline{$lineno} =~ s/\0[^\0]*//;
3985
3986                 # Add the action to the line.
3987                 $dbline{$lineno} .= "\0" . action($expr);
3988             }
3989         } ## end if (length $expr)
3990     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3991     else {
3992
3993         # Syntax wrong.
3994         print $OUT
3995           "Adding an action requires an optional lineno and an expression\n"
3996           ;    # hint
3997     }
3998 } ## end sub cmd_a
3999
4000 =head3 C<cmd_A> (command)
4001
4002 Delete actions. Similar to above, except the delete code is in a separate
4003 subroutine, C<delete_action>.
4004
4005 =cut
4006
4007 sub cmd_A {
4008     my $cmd    = shift;
4009     my $line   = shift || '';
4010     my $dbline = shift;
4011
4012     # Dot is this line.
4013     $line =~ s/^\./$dbline/;
4014
4015     # Call delete_action with a null param to delete them all.
4016     # The '1' forces the eval to be true. It'll be false only
4017     # if delete_action blows up for some reason, in which case
4018     # we print $@ and get out.
4019     if ( $line eq '*' ) {
4020         eval { &delete_action(); 1 } or print $OUT $@ and return;
4021     }
4022
4023     # There's a real line  number. Pass it to delete_action.
4024     # Error trapping is as above.
4025     elsif ( $line =~ /^(\S.*)/ ) {
4026         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4027     }
4028
4029     # Swing and a miss. Bad syntax.
4030     else {
4031         print $OUT
4032           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4033     }
4034 } ## end sub cmd_A
4035
4036 =head3 C<delete_action> (API)
4037
4038 C<delete_action> accepts either a line number or C<undef>. If a line number
4039 is specified, we check for the line being executable (if it's not, it
4040 couldn't have had an  action). If it is, we just take the action off (this
4041 will get any kind of an action, including breakpoints).
4042
4043 =cut
4044
4045 sub delete_action {
4046     my $i = shift;
4047     if ( defined($i) ) {
4048
4049         # Can there be one?
4050         die "Line $i has no action .\n" if $dbline[$i] == 0;
4051
4052         # Nuke whatever's there.
4053         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4054         delete $dbline{$i} if $dbline{$i} eq '';
4055     }
4056     else {
4057         print $OUT "Deleting all actions...\n";
4058         for my $file ( keys %had_breakpoints ) {
4059             local *dbline = $main::{ '_<' . $file };
4060             my $max = $#dbline;
4061             my $was;
4062             for ( $i = 1 ; $i <= $max ; $i++ ) {
4063                 if ( defined $dbline{$i} ) {
4064                     $dbline{$i} =~ s/\0[^\0]*//;
4065                     delete $dbline{$i} if $dbline{$i} eq '';
4066                 }
4067                 unless ( $had_breakpoints{$file} &= ~2 ) {
4068                     delete $had_breakpoints{$file};
4069                 }
4070             } ## end for ($i = 1 ; $i <= $max...
4071         } ## end for my $file (keys %had_breakpoints)
4072     } ## end else [ if (defined($i))
4073 } ## end sub delete_action
4074
4075 =head3 C<cmd_b> (command)
4076
4077 Set breakpoints. Since breakpoints can be set in so many places, in so many
4078 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4079 we try to parse the command type, and then shuttle it off to an appropriate
4080 subroutine to actually do the work of setting the breakpoint in the right
4081 place.
4082
4083 =cut
4084
4085 sub cmd_b {
4086     my $cmd    = shift;
4087     my $line   = shift;    # [.|line] [cond]
4088     my $dbline = shift;
4089
4090     # Make . the current line number if it's there..
4091     $line =~ s/^\.(\s|\z)/$dbline$1/;
4092
4093     # No line number, no condition. Simple break on current line.
4094     if ( $line =~ /^\s*$/ ) {
4095         &cmd_b_line( $dbline, 1 );
4096     }
4097
4098     # Break on load for a file.
4099     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4100         my $file = $1;
4101         $file =~ s/\s+$//;
4102         &cmd_b_load($file);
4103     }
4104
4105     # b compile|postpone <some sub> [<condition>]
4106     # The interpreter actually traps this one for us; we just put the
4107     # necessary condition in the %postponed hash.
4108     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4109
4110         # Capture the condition if there is one. Make it true if none.
4111         my $cond = length $3 ? $3 : '1';
4112
4113         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4114         # if it was 'compile'.
4115         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4116
4117         # De-Perl4-ify the name - ' separators to ::.
4118         $subname =~ s/\'/::/g;
4119
4120         # Qualify it into the current package unless it's already qualified.
4121         $subname = "${package}::" . $subname unless $subname =~ /::/;
4122
4123         # Add main if it starts with ::.
4124         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4125
4126         # Save the break type for this sub.
4127         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4128     } ## end elsif ($line =~ ...
4129     # b <filename>:<line> [<condition>]
4130     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4131         my ($filename, $line_num, $cond) = ($1, $2, $3);
4132         cmd_b_filename_line(
4133             $filename,
4134             $line_num,
4135             (length($cond) ? $cond : '1'),
4136         );
4137     }
4138     # b <sub name> [<condition>]
4139     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4140
4141         #
4142         $subname = $1;
4143         my $cond = length $2 ? $2 : '1';
4144         &cmd_b_sub( $subname, $cond );
4145     }
4146
4147     # b <line> [<condition>].
4148     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4149
4150         # Capture the line. If none, it's the current line.
4151         $line = $1 || $dbline;
4152
4153         # If there's no condition, make it '1'.
4154         my $cond = length $2 ? $2 : '1';
4155
4156         # Break on line.
4157         &cmd_b_line( $line, $cond );
4158     }
4159
4160     # Line didn't make sense.
4161     else {
4162         print "confused by line($line)?\n";
4163     }
4164 } ## end sub cmd_b
4165
4166 =head3 C<break_on_load> (API)
4167
4168 We want to break when this file is loaded. Mark this file in the
4169 C<%break_on_load> hash, and note that it has a breakpoint in
4170 C<%had_breakpoints>.
4171
4172 =cut
4173
4174 sub break_on_load {
4175     my $file = shift;
4176     $break_on_load{$file} = 1;
4177     $had_breakpoints{$file} |= 1;
4178 }
4179
4180 =head3 C<report_break_on_load> (API)
4181
4182 Gives us an array of filenames that are set to break on load. Note that
4183 only files with break-on-load are in here, so simply showing the keys
4184 suffices.
4185
4186 =cut
4187
4188 sub report_break_on_load {
4189     sort keys %break_on_load;
4190 }
4191
4192 =head3 C<cmd_b_load> (command)
4193
4194 We take the file passed in and try to find it in C<%INC> (which maps modules
4195 to files they came from). We mark those files for break-on-load via
4196 C<break_on_load> and then report that it was done.
4197
4198 =cut
4199
4200 sub cmd_b_load {
4201     my $file = shift;
4202     my @files;
4203
4204     # This is a block because that way we can use a redo inside it
4205     # even without there being any looping structure at all outside it.
4206     {
4207
4208         # Save short name and full path if found.
4209         push @files, $file;
4210         push @files, $::INC{$file} if $::INC{$file};
4211
4212         # Tack on .pm and do it again unless there was a '.' in the name
4213         # already.
4214         $file .= '.pm', redo unless $file =~ /\./;
4215     }
4216
4217     # Do the real work here.
4218     break_on_load($_) for @files;
4219
4220     # All the files that have break-on-load breakpoints.
4221     @files = report_break_on_load;
4222
4223     # Normalize for the purposes of our printing this.
4224     local $\ = '';
4225     local $" = ' ';
4226     print $OUT "Will stop on load of '@files'.\n";
4227 } ## end sub cmd_b_load
4228
4229 =head3 C<$filename_error> (API package global)
4230
4231 Several of the functions we need to implement in the API need to work both
4232 on the current file and on other files. We don't want to duplicate code, so
4233 C<$filename_error> is used to contain the name of the file that's being
4234 worked on (if it's not the current one).
4235
4236 We can now build functions in pairs: the basic function works on the current
4237 file, and uses C<$filename_error> as part of its error message. Since this is
4238 initialized to C<"">, no filename will appear when we are working on the
4239 current file.
4240
4241 The second function is a wrapper which does the following:
4242
4243 =over 4
4244
4245 =item *
4246
4247 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4248
4249 =item *
4250
4251 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4252
4253 =item *
4254
4255 Calls the first function.
4256
4257 The first function works on the I<current> file (i.e., the one we changed to),
4258 and prints C<$filename_error> in the error message (the name of the other file)
4259 if it needs to. When the functions return, C<*dbline> is restored to point
4260 to the actual current file (the one we're executing in) and
4261 C<$filename_error> is restored to C<"">. This restores everything to
4262 the way it was before the second function was called at all.
4263
4264 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4265 details.
4266
4267 =back
4268
4269 =cut
4270
4271 use vars qw($filename_error);
4272 $filename_error = '';
4273
4274 =head3 breakable_line(from, to) (API)
4275
4276 The subroutine decides whether or not a line in the current file is breakable.
4277 It walks through C<@dbline> within the range of lines specified, looking for
4278 the first line that is breakable.
4279
4280 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4281 first line I<after> C<$to> that's breakable, if there is one.
4282
4283 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4284 first line I<before> C<$to> that's breakable, if there is one.
4285
4286 =cut
4287
4288 sub breakable_line {
4289
4290     my ( $from, $to ) = @_;
4291
4292     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4293     my $i = $from;
4294
4295     # If there are at least 2 arguments, we're trying to search a range.
4296     if ( @_ >= 2 ) {
4297
4298         # $delta is positive for a forward search, negative for a backward one.
4299         my $delta = $from < $to ? +1 : -1;
4300
4301         # Keep us from running off the ends of the file.
4302         my $limit = $delta > 0 ? $#dbline : 1;
4303
4304         # Clever test. If you're a mathematician, it's obvious why this
4305         # test works. If not:
4306         # If $delta is positive (going forward), $limit will be $#dbline.
4307         #    If $to is less than $limit, ($limit - $to) will be positive, times
4308         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4309         #    as the stopping point.
4310         #
4311         #    If $to is greater than $limit, ($limit - $to) is negative,
4312         #    times $delta of 1 (positive), so the result is < 0 and we should
4313         #    use $limit ($#dbline) as the stopping point.
4314         #
4315         # If $delta is negative (going backward), $limit will be 1.
4316         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4317         #    (negative) so the result is > 0, and we use $to as the stopping
4318         #    point.
4319         #
4320         #    If $to is less than zero, ($limit - $to) will be positive,
4321         #    times $delta of -1 (negative), so the result is not > 0, and
4322         #    we use $limit (1) as the stopping point.
4323         #
4324         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4325         #    (negative), still giving zero; the result is not > 0, and
4326         #    we use $limit (1) as the stopping point.
4327         #
4328         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4329         #    (negative), giving a positive (>0) value, so we'll set $limit to
4330         #    $to.
4331
4332         $limit = $to if ( $limit - $to ) * $delta > 0;
4333
4334         # The real search loop.
4335         # $i starts at $from (the point we want to start searching from).
4336         # We move through @dbline in the appropriate direction (determined
4337         # by $delta: either -1 (back) or +1 (ahead).
4338         # We stay in as long as we haven't hit an executable line
4339         # ($dbline[$i] == 0 means not executable) and we haven't reached
4340         # the limit yet (test similar to the above).
4341         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4342
4343     } ## end if (@_ >= 2)
4344
4345     # If $i points to a line that is executable, return that.
4346     return $i unless $dbline[$i] == 0;
4347
4348     # Format the message and print it: no breakable lines in range.
4349     my ( $pl, $upto ) = ( '', '' );
4350     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4351
4352     # If there's a filename in filename_error, we'll see it.
4353     # If not, not.
4354     die "Line$pl $from$upto$filename_error not breakable\n";
4355 } ## end sub breakable_line
4356
4357 =head3 breakable_line_in_filename(file, from, to) (API)
4358
4359 Like C<breakable_line>, but look in another file.
4360
4361 =cut
4362
4363 sub breakable_line_in_filename {
4364
4365     # Capture the file name.
4366     my ($f) = shift;
4367
4368     # Swap the magic line array over there temporarily.
4369     local *dbline = $main::{ '_<' . $f };
4370
4371     # If there's an error, it's in this other file.
4372     local $filename_error = " of '$f'";
4373
4374     # Find the breakable line.
4375     breakable_line(@_);
4376
4377     # *dbline and $filename_error get restored when this block ends.
4378
4379 } ## end sub breakable_line_in_filename
4380
4381 =head3 break_on_line(lineno, [condition]) (API)
4382
4383 Adds a breakpoint with the specified condition (or 1 if no condition was
4384 specified) to the specified line. Dies if it can't.
4385
4386 =cut
4387
4388 sub break_on_line {
4389     my ( $i, $cond ) = @_;
4390
4391     # Always true if no condition supplied.
4392     $cond = 1 unless @_ >= 2;
4393
4394     my $inii  = $i;
4395     my $after = '';
4396     my $pl    = '';
4397
4398     # Woops, not a breakable line. $filename_error allows us to say
4399     # if it was in a different file.
4400     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4401
4402     # Mark this file as having breakpoints in it.
4403     $had_breakpoints{$filename} |= 1;
4404
4405     # If there is an action or condition here already ...
4406     if ( $dbline{$i} ) {
4407
4408         # ... swap this condition for the existing one.
4409         $dbline{$i} =~ s/^[^\0]*/$cond/;
4410     }
4411     else {
4412
4413         # Nothing here - just add the condition.
4414         $dbline{$i} = $cond;
4415
4416         _set_breakpoint_enabled_status($filename, $i, 1);
4417     }
4418 } ## end sub break_on_line
4419
4420 =head3 cmd_b_line(line, [condition]) (command)
4421
4422 Wrapper for C<break_on_line>. Prints the failure message if it
4423 doesn't work.
4424
4425 =cut
4426
4427 sub cmd_b_line {
4428     eval { break_on_line(@_); 1 } or do {
4429         local $\ = '';
4430         print $OUT $@ and return;
4431     };
4432 } ## end sub cmd_b_line
4433
4434 =head3 cmd_b_filename_line(line, [condition]) (command)
4435
4436 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4437 doesn't work.
4438
4439 =cut
4440
4441 sub cmd_b_filename_line {
4442     eval { break_on_filename_line(@_); 1 } or do {
4443         local $\ = '';
4444         print $OUT $@ and return;
4445     };
4446 }
4447
4448 =head3 break_on_filename_line(file, line, [condition]) (API)
4449
4450 Switches to the file specified and then calls C<break_on_line> to set
4451 the breakpoint.
4452
4453 =cut
4454
4455 sub break_on_filename_line {
4456     my ( $f, $i, $cond ) = @_;
4457
4458     # Always true if condition left off.
4459     $cond = 1 unless @_ >= 3;
4460
4461     # Switch the magical hash temporarily.
4462     local *dbline = $main::{ '_<' . $f };
4463
4464     # Localize the variables that break_on_line uses to make its message.
4465     local $filename_error = " of '$f'";
4466     local $filename       = $f;
4467
4468     # Add the breakpoint.
4469     break_on_line( $i, $cond );
4470 } ## end sub break_on_filename_line
4471
4472 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4473
4474 Switch to another file, search the range of lines specified for an
4475 executable one, and put a breakpoint on the first one you find.
4476
4477 =cut
4478
4479 sub break_on_filename_line_range {
4480     my ( $f, $from, $to, $cond ) = @_;
4481
4482     # Find a breakable line if there is one.
4483     my $i = breakable_line_in_filename( $f, $from, $to );
4484
4485     # Always true if missing.
4486     $cond = 1 unless @_ >= 3;
4487
4488     # Add the breakpoint.
4489     break_on_filename_line( $f, $i, $cond );
4490 } ## end sub break_on_filename_line_range
4491
4492 =head3 subroutine_filename_lines(subname, [condition]) (API)
4493
4494 Search for a subroutine within a given file. The condition is ignored.
4495 Uses C<find_sub> to locate the desired subroutine.
4496
4497 =cut
4498
4499 sub subroutine_filename_lines {
4500     my ( $subname, $cond ) = @_;
4501
4502     # Returned value from find_sub() is fullpathname:startline-endline.
4503     # The match creates the list (fullpathname, start, end). Falling off
4504     # the end of the subroutine returns this implicitly.
4505     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4506 } ## end sub subroutine_filename_lines
4507
4508 =head3 break_subroutine(subname) (API)
4509
4510 Places a break on the first line possible in the specified subroutine. Uses
4511 C<subroutine_filename_lines> to find the subroutine, and
4512 C<break_on_filename_line_range> to place the break.
4513
4514 =cut
4515
4516 sub break_subroutine {
4517     my $subname = shift;
4518
4519     # Get filename, start, and end.
4520     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4521       or die "Subroutine $subname not found.\n";
4522
4523
4524     # Null condition changes to '1' (always true).
4525     my $cond = @_ ? shift(@_) : 1;
4526
4527     # Put a break the first place possible in the range of lines
4528     # that make up this subroutine.
4529     break_on_filename_line_range( $file, $s, $e, $cond );
4530 } ## end sub break_subroutine
4531
4532 =head3 cmd_b_sub(subname, [condition]) (command)
4533
4534 We take the incoming subroutine name and fully-qualify it as best we can.
4535
4536 =over 4
4537
4538 =item 1. If it's already fully-qualified, leave it alone.
4539
4540 =item 2. Try putting it in the current package.
4541
4542 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4543
4544 =item 4. If it starts with '::', put it in 'main::'.
4545
4546 =back
4547
4548 After all this cleanup, we call C<break_subroutine> to try to set the
4549 breakpoint.
4550
4551 =cut
4552
4553 sub cmd_b_sub {
4554     my ( $subname, $cond ) = @_;
4555
4556     # Add always-true condition if we have none.
4557     $cond = 1 unless @_ >= 2;
4558
4559     # If the subname isn't a code reference, qualify it so that
4560     # break_subroutine() will work right.
4561     unless ( ref $subname eq 'CODE' ) {
4562
4563         # Not Perl4.
4564         $subname =~ s/\'/::/g;
4565         my $s = $subname;
4566
4567         # Put it in this package unless it's already qualified.
4568         $subname = "${package}::" . $subname
4569           unless $subname =~ /::/;
4570
4571         # Requalify it into CORE::GLOBAL if qualifying it into this
4572         # package resulted in its not being defined, but only do so
4573         # if it really is in CORE::GLOBAL.
4574         $subname = "CORE::GLOBAL::$s"
4575           if not defined &$subname
4576           and $s !~ /::/
4577           and defined &{"CORE::GLOBAL::$s"};
4578
4579         # Put it in package 'main' if it has a leading ::.
4580         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4581
4582     } ## end unless (ref $subname eq 'CODE')
4583
4584     # Try to set the breakpoint.
4585     eval { break_subroutine( $subname, $cond ); 1 } or do {
4586         local $\ = '';
4587         print $OUT $@ and return;
4588       }
4589 } ## end sub cmd_b_sub
4590
4591 =head3 C<cmd_B> - delete breakpoint(s) (command)
4592
4593 The command mostly parses the command line and tries to turn the argument
4594 into a line spec. If it can't, it uses the current line. It then calls
4595 C<delete_breakpoint> to actually do the work.
4596
4597 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4598 thereby deleting all the breakpoints.
4599
4600 =cut
4601
4602 sub cmd_B {
4603     my $cmd = shift;
4604
4605     # No line spec? Use dbline.
4606     # If there is one, use it if it's non-zero, or wipe it out if it is.
4607     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4608     my $dbline = shift;
4609
4610     # If the line was dot, make the line the current one.
4611     $line =~ s/^\./$dbline/;
4612
4613     # If it's * we're deleting all the breakpoints.
4614     if ( $line eq '*' ) {
4615         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4616     }
4617
4618     # If there is a line spec, delete the breakpoint on that line.
4619     elsif ( $line =~ /^(\S.*)/ ) {
4620         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4621             local $\ = '';
4622             print $OUT $@ and return;
4623         };
4624     } ## end elsif ($line =~ /^(\S.*)/)
4625
4626     # No line spec.
4627     else {
4628         print $OUT
4629           "Deleting a breakpoint requires a line number, or '*' for all\n"
4630           ;    # hint
4631     }
4632 } ## end sub cmd_B
4633
4634 =head3 delete_breakpoint([line]) (API)
4635
4636 This actually does the work of deleting either a single breakpoint, or all
4637 of them.
4638
4639 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4640 just drop out with a message saying so. If it is, we remove the condition
4641 part of the 'condition\0action' that says there's a breakpoint here. If,
4642 after we've done that, there's nothing left, we delete the corresponding
4643 line in C<%dbline> to signal that no action needs to be taken for this line.
4644
4645 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4646 which lists all currently-loaded files which have breakpoints. We then look
4647 at each line in each of these files, temporarily switching the C<%dbline>
4648 and C<@dbline> structures to point to the files in question, and do what
4649 we did in the single line case: delete the condition in C<@dbline>, and
4650 delete the key in C<%dbline> if nothing's left.
4651
4652 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4653 C<%break_on_load>, because these structures contain breakpoints for files
4654 and code that haven't been loaded yet. We can just kill these off because there
4655 are no magical debugger structures associated with them.
4656
4657 =cut
4658
4659 sub delete_breakpoint {
4660     my $i = shift;
4661
4662     my $fn = $filename;
4663
4664     # If we got a line, delete just that one.
4665     if ( defined($i) ) {
4666
4667         # Woops. This line wasn't breakable at all.
4668         die "Line $i not breakable.\n" if $dbline[$i] == 0;
4669
4670         # Kill the condition, but leave any action.
4671         $dbline{$i} =~ s/^[^\0]*//;
4672
4673         # Remove the entry entirely if there's no action left.
4674         if ($dbline{$i} eq '') {
4675             delete $dbline{$i};
4676             _delete_breakpoint_data_ref($fn, $i);
4677         }
4678     }
4679
4680     # No line; delete them all.
4681     else {
4682         print $OUT "Deleting all breakpoints...\n";
4683
4684         # %had_breakpoints lists every file that had at least one
4685         # breakpoint in it.
4686         for my $file ( keys %had_breakpoints ) {
4687
4688             # Switch to the desired file temporarily.
4689             local *dbline = $main::{ '_<' . $file };
4690
4691             my $max = $#dbline;
4692             my $was;
4693
4694             # For all lines in this file ...
4695             for ( $i = 1 ; $i <= $max ; $i++ ) {
4696
4697                 # If there's a breakpoint or action on this line ...
4698                 if ( defined $dbline{$i} ) {
4699
4700                     # ... remove the breakpoint.
4701                     $dbline{$i} =~ s/^[^\0]+//;
4702                     if ( $dbline{$i} =~ s/^\0?$// ) {
4703
4704                         # Remove the entry altogether if no action is there.
4705                         delete $dbline{$i};
4706                         _delete_breakpoint_data_ref($file, $i);
4707                     }
4708                 } ## end if (defined $dbline{$i...
4709             } ## end for ($i = 1 ; $i <= $max...
4710
4711             # If, after we turn off the "there were breakpoints in this file"
4712             # bit, the entry in %had_breakpoints for this file is zero,
4713             # we should remove this file from the hash.
4714             if ( not $had_breakpoints{$file} &= ~1 ) {
4715                 delete $had_breakpoints{$file};
4716             }
4717         } ## end for my $file (keys %had_breakpoints)
4718
4719         # Kill off all the other breakpoints that are waiting for files that
4720         # haven't been loaded yet.
4721         undef %postponed;
4722         undef %postponed_file;
4723         undef %break_on_load;
4724     } ## end else [ if (defined($i))
4725 } ## end sub delete_breakpoint
4726
4727 =head3 cmd_stop (command)
4728
4729 This is meant to be part of the new command API, but it isn't called or used
4730 anywhere else in the debugger. XXX It is probably meant for use in development
4731 of new commands.
4732
4733 =cut
4734
4735 sub cmd_stop {    # As on ^C, but not signal-safy.
4736     $signal = 1;
4737 }
4738
4739 =head3 C<cmd_e> - threads
4740
4741 Display the current thread id:
4742
4743         e
4744
4745 This could be how (when implemented) to send commands to this thread id (e cmd)
4746 or that thread id (e tid cmd).
4747
4748 =cut
4749
4750 sub cmd_e {
4751     my $cmd  = shift;
4752     my $line = shift;
4753         unless (exists($INC{'threads.pm'})) {
4754                 print "threads not loaded($ENV{PERL5DB_THREADED})
4755                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4756         } else {
4757                 my $tid = threads->tid;
4758                 print "thread id: $tid\n";
4759         }
4760 } ## end sub cmd_e
4761
4762 =head3 C<cmd_E> - list of thread ids
4763
4764 Display the list of available thread ids:
4765
4766         E
4767
4768 This could be used (when implemented) to send commands to all threads (E cmd).
4769
4770 =cut
4771
4772 sub cmd_E {
4773     my $cmd  = shift;
4774     my $line = shift;
4775         unless (exists($INC{'threads.pm'})) {
4776                 print "threads not loaded($ENV{PERL5DB_THREADED})
4777                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4778         } else {
4779                 my $tid = threads->tid;
4780                 print "thread ids: ".join(', ',
4781                         map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
4782                 )."\n";
4783         }
4784 } ## end sub cmd_E
4785
4786 =head3 C<cmd_h> - help command (command)
4787
4788 Does the work of either
4789
4790 =over 4
4791
4792 =item *
4793
4794 Showing all the debugger help
4795
4796 =item *
4797
4798 Showing help for a specific command
4799
4800 =back
4801
4802 =cut
4803
4804 use vars qw($help);
4805 use vars qw($summary);
4806
4807 sub cmd_h {
4808     my $cmd = shift;
4809
4810     # If we have no operand, assume null.
4811     my $line = shift || '';
4812
4813     # 'h h'. Print the long-format help.
4814     if ( $line =~ /^h\s*/ ) {
4815         print_help($help);
4816     }
4817
4818     # 'h <something>'. Search for the command and print only its help.
4819     elsif ( $line =~ /^(\S.*)$/ ) {
4820
4821         # support long commands; otherwise bogus errors
4822         # happen when you ask for h on <CR> for example
4823         my $asked = $1;    # the command requested
4824                            # (for proper error message)
4825
4826         my $qasked = quotemeta($asked);    # for searching; we don't
4827                                            # want to use it as a pattern.
4828                                            # XXX: finds CR but not <CR>
4829
4830         # Search the help string for the command.
4831         if (
4832             $help =~ /^                    # Start of a line
4833                       <?                   # Optional '<'
4834                       (?:[IB]<)            # Optional markup
4835                       $qasked              # The requested command
4836                      /mx
4837           )
4838         {
4839
4840             # It's there; pull it out and print it.
4841             while (
4842                 $help =~ /^
4843                               (<?            # Optional '<'
4844                                  (?:[IB]<)   # Optional markup
4845                                  $qasked     # The command
4846                                  ([\s\S]*?)  # Description line(s)
4847                               \n)            # End of last description line
4848                               (?!\s)         # Next line not starting with
4849                                              # whitespace
4850                              /mgx
4851               )
4852             {
4853                 print_help($1);
4854             }
4855         }
4856
4857         # Not found; not a debugger command.
4858         else {
4859             print_help("B<$asked> is not a debugger command.\n");
4860         }
4861     } ## end elsif ($line =~ /^(\S.*)$/)
4862
4863     # 'h' - print the summary help.
4864     else {
4865         print_help($summary);
4866     }
4867 } ## end sub cmd_h
4868
4869 =head3 C<cmd_i> - inheritance display
4870
4871 Display the (nested) parentage of the module or object given.
4872
4873 =cut
4874
4875 sub cmd_i {
4876     my $cmd  = shift;
4877     my $line = shift;
4878     foreach my $isa ( split( /\s+/, $line ) ) {
4879         $evalarg = $isa;
4880         ($isa) = &eval;
4881         no strict 'refs';
4882         print join(
4883             ', ',
4884             map {
4885                 "$_"
4886                   . (
4887                     defined( ${"$_\::VERSION"} )
4888                     ? ' ' . ${"$_\::VERSION"}
4889                     : undef )
4890               } @{mro::get_linear_isa(ref($isa) || $isa)}
4891         );
4892         print "\n";
4893     }
4894 } ## end sub cmd_i
4895
4896 =head3 C<cmd_l> - list lines (command)
4897
4898 Most of the command is taken up with transforming all the different line
4899 specification syntaxes into 'start-stop'. After that is done, the command
4900 runs a loop over C<@dbline> for the specified range of lines. It handles
4901 the printing of each line and any markers (C<==E<gt>> for current line,
4902 C<b> for break on this line, C<a> for action on this line, C<:> for this
4903 line breakable).
4904
4905 We save the last line listed in the C<$start> global for further listing
4906 later.
4907
4908 =cut
4909
4910 sub cmd_l {
4911     my $current_line = $line;
4912     my $cmd  = shift;
4913     my $line = shift;
4914
4915     # If this is '-something', delete any spaces after the dash.
4916     $line =~ s/^-\s*$/-/;
4917
4918     # If the line is '$something', assume this is a scalar containing a
4919     # line number.
4920     if ( $line =~ /^(\$.*)/s ) {
4921
4922         # Set up for DB::eval() - evaluate in *user* context.
4923         $evalarg = $1;
4924         # $evalarg = $2;
4925         my ($s) = &eval;
4926
4927         # Ooops. Bad scalar.
4928         print( $OUT "Error: $@\n" ), next CMD if $@;
4929
4930         # Good scalar. If it's a reference, find what it points to.
4931         $s = CvGV_name($s);
4932         print( $OUT "Interpreted as: $1 $s\n" );
4933         $line = "$1 $s";
4934
4935         # Call self recursively to really do the command.
4936         &cmd_l( 'l', $s );
4937     } ## end if ($line =~ /^(\$.*)/s)
4938
4939     # l name. Try to find a sub by that name.
4940     elsif ( $line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s ) {
4941         my $s = $subname = $1;
4942
4943         # De-Perl4.
4944         $subname =~ s/\'/::/;
4945
4946         # Put it in this package unless it starts with ::.
4947         $subname = $package . "::" . $subname unless $subname =~ /::/;
4948
4949         # Put it in CORE::GLOBAL if t doesn't start with :: and
4950         # it doesn't live in this package and it lives in CORE::GLOBAL.
4951         $subname = "CORE::GLOBAL::$s"
4952           if not defined &$subname
4953           and $s !~ /::/
4954           and defined &{"CORE::GLOBAL::$s"};
4955
4956         # Put leading '::' names into 'main::'.
4957         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4958
4959         # Get name:start-stop from find_sub, and break this up at
4960         # colons.
4961         my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
4962
4963         # Pull off start-stop.
4964         my $subrange = pop @pieces;
4965
4966         # If the name contained colons, the split broke it up.
4967         # Put it back together.
4968         $file = join( ':', @pieces );
4969
4970         # If we're not in that file, switch over to it.
4971         if ( $file ne $filename ) {
4972             print $OUT "Switching to file '$file'.\n"
4973               unless $slave_editor;
4974
4975             # Switch debugger's magic structures.
4976             *dbline   = $main::{ '_<' . $file };
4977             $max      = $#dbline;
4978             $filename = $file;
4979         } ## end if ($file ne $filename)
4980
4981         # Subrange is 'start-stop'. If this is less than a window full,
4982         # swap it to 'start+', which will list a window from the start point.
4983         if ($subrange) {
4984             if ( eval($subrange) < -$window ) {
4985                 $subrange =~ s/-.*/+/;
4986             }
4987
4988             # Call self recursively to list the range.
4989             $line = $subrange;
4990             &cmd_l( 'l', $subrange );
4991         } ## end if ($subrange)
4992
4993         # Couldn't find it.
4994         else {
4995             print $OUT "Subroutine $subname not found.\n";
4996         }
4997     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
4998
4999     # Bare 'l' command.
5000     elsif ( $line =~ /^\s*$/ ) {
5001
5002         # Compute new range to list.
5003         $incr = $window - 1;
5004         $line = $start . '-' . ( $start + $incr );
5005
5006         # Recurse to do it.
5007         &cmd_l( 'l', $line );
5008     }
5009
5010     # l [start]+number_of_lines
5011     elsif ( $line =~ /^(\d*)\+(\d*)$/ ) {
5012
5013         # Don't reset start for 'l +nnn'.
5014         $start = $1 if $1;
5015
5016         # Increment for list. Use window size if not specified.
5017         # (Allows 'l +' to work.)
5018         $incr = $2;
5019         $incr = $window - 1 unless $incr;
5020
5021         # Create a line range we'll understand, and recurse to do it.
5022         $line = $start . '-' . ( $start + $incr );
5023         &cmd_l( 'l', $line );
5024     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
5025
5026     # l start-stop or l start,stop
5027     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
5028
5029         # Determine end point; use end of file if not specified.
5030         my $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
5031
5032         # Go on to the end, and then stop.
5033         $end = $max if $end > $max;
5034
5035         # Determine start line.
5036         my $i    = $2;
5037         $i    = $line if $i eq '.';
5038         $i    = 1 if $i < 1;
5039         $incr = $end - $i;
5040
5041         # If we're running under a slave editor, force it to show the lines.
5042         if ($slave_editor) {
5043             print $OUT "\032\032$filename:$i:0\n";
5044             $i = $end;
5045         }
5046
5047         # We're doing it ourselves. We want to show the line and special
5048         # markers for:
5049         # - the current line in execution
5050         # - whether a line is breakable or not
5051         # - whether a line has a break or not
5052         # - whether a line has an action or not
5053         else {
5054             for ( ; $i <= $end ; $i++ ) {
5055
5056                 # Check for breakpoints and actions.
5057                 my ( $stop, $action );
5058                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
5059                   if $dbline{$i};
5060
5061                 # ==> if this is the current line in execution,
5062                 # : if it's breakable.
5063                 my $arrow =
5064                   ( $i == $current_line and $filename eq $filename_ini )
5065                   ? '==>'
5066                   : ( $dbline[$i] + 0 ? ':' : ' ' );
5067
5068                 # Add break and action indicators.
5069                 $arrow .= 'b' if $stop;
5070                 $arrow .= 'a' if $action;
5071
5072                 # Print the line.
5073                 print $OUT "$i$arrow\t", $dbline[$i];
5074
5075                 # Move on to the next line. Drop out on an interrupt.
5076                 $i++, last if $signal;
5077             } ## end for (; $i <= $end ; $i++)
5078
5079             # Line the prompt up; print a newline if the last line listed
5080             # didn't have a newline.
5081             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5082         } ## end else [ if ($slave_editor)
5083
5084         # Save the point we last listed to in case another relative 'l'
5085         # command is desired. Don't let it run off the end.
5086         $start = $i;
5087         $start = $max if $start > $max;
5088     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5089 } ## end sub cmd_l
5090
5091 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5092
5093 To list breakpoints, the command has to look determine where all of them are
5094 first. It starts a C<%had_breakpoints>, which tells us what all files have
5095 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5096 magic source and breakpoint data structures) to the file, and then look
5097 through C<%dbline> for lines with breakpoints and/or actions, listing them
5098 out. We look through C<%postponed> not-yet-compiled subroutines that have
5099 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5100 that have breakpoints.
5101
5102 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5103
5104 =cut
5105
5106 sub cmd_L {
5107     my $cmd = shift;
5108
5109     # If no argument, list everything. Pre-5.8.0 version always lists
5110     # everything
5111     my $arg = shift || 'abw';
5112     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5113
5114     # See what is wanted.
5115     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5116     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5117     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5118
5119     # Breaks and actions are found together, so we look in the same place
5120     # for both.
5121     if ( $break_wanted or $action_wanted ) {
5122
5123         # Look in all the files with breakpoints...
5124         for my $file ( keys %had_breakpoints ) {
5125
5126             # Temporary switch to this file.
5127             local *dbline = $main::{ '_<' . $file };
5128
5129             # Set up to look through the whole file.
5130             my $max = $#dbline;
5131             my $was;    # Flag: did we print something
5132                         # in this file?
5133
5134             # For each line in the file ...
5135             for ( my $i = 1 ; $i <= $max ; $i++ ) {
5136
5137                 # We've got something on this line.
5138                 if ( defined $dbline{$i} ) {
5139
5140                     # Print the header if we haven't.
5141                     print $OUT "$file:\n" unless $was++;
5142
5143                     # Print the line.
5144                     print $OUT " $i:\t", $dbline[$i];
5145
5146                     # Pull out the condition and the action.
5147                     my ( $stop, $action ) = split( /\0/, $dbline{$i} );
5148
5149                     # Print the break if there is one and it's wanted.
5150                     print $OUT "   break if (", $stop, ")\n"
5151                       if $stop
5152                       and $break_wanted;
5153
5154                     # Print the action if there is one and it's wanted.
5155                     print $OUT "   action:  ", $action, "\n"
5156                       if $action
5157                       and $action_wanted;
5158
5159                     # Quit if the user hit interrupt.
5160                     last if $signal;
5161                 } ## end if (defined $dbline{$i...
5162             } ## end for ($i = 1 ; $i <= $max...
5163         } ## end for my $file (keys %had_breakpoints)
5164     } ## end if ($break_wanted or $action_wanted)
5165
5166     # Look for breaks in not-yet-compiled subs:
5167     if ( %postponed and $break_wanted ) {
5168         print $OUT "Postponed breakpoints in subroutines:\n";
5169         my $subname;
5170         for $subname ( keys %postponed ) {
5171             print $OUT " $subname\t$postponed{$subname}\n";
5172             last if $signal;
5173         }
5174     } ## end if (%postponed and $break_wanted)
5175
5176     # Find files that have not-yet-loaded breaks:
5177     my @have = map {    # Combined keys
5178         keys %{ $postponed_file{$_} }
5179     } keys %postponed_file;
5180
5181     # If there are any, list them.
5182     if ( @have and ( $break_wanted or $action_wanted ) ) {
5183         print $OUT "Postponed breakpoints in files:\n";
5184         my ( $file, $line );
5185
5186         for $file ( keys %postponed_file ) {
5187             my $db = $postponed_file{$file};
5188             print $OUT " $file:\n";
5189             for $line ( sort { $a <=> $b } keys %$db ) {
5190                 print $OUT "  $line:\n";
5191                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5192                 print $OUT "    break if (", $stop, ")\n"
5193                   if $stop
5194                   and $break_wanted;
5195                 print $OUT "    action:  ", $action, "\n"
5196                   if $action
5197                   and $action_wanted;
5198                 last if $signal;
5199             } ## end for $line (sort { $a <=>...
5200             last if $signal;
5201         } ## end for $file (keys %postponed_file)
5202     } ## end if (@have and ($break_wanted...
5203     if ( %break_on_load and $break_wanted ) {
5204         print $OUT "Breakpoints on load:\n";
5205         my $file;
5206         for $file ( keys %break_on_load ) {
5207             print $OUT " $file\n";
5208             last if $signal;
5209         }
5210     } ## end if (%break_on_load and...
5211     if ($watch_wanted) {
5212         if ( $trace & 2 ) {
5213             print $OUT "Watch-expressions:\n" if @to_watch;
5214             for my $expr (@to_watch) {
5215                 print $OUT " $expr\n";
5216                 last if $signal;
5217             }
5218         } ## end if ($trace & 2)
5219     } ## end if ($watch_wanted)
5220 } ## end sub cmd_L
5221
5222 =head3 C<cmd_M> - list modules (command)
5223
5224 Just call C<list_modules>.
5225
5226 =cut
5227
5228 sub cmd_M {
5229     &list_modules();
5230 }
5231
5232 =head3 C<cmd_o> - options (command)
5233
5234 If this is just C<o> by itself, we list the current settings via
5235 C<dump_option>. If there's a nonblank value following it, we pass that on to
5236 C<parse_options> for processing.
5237
5238 =cut
5239
5240 sub cmd_o {
5241     my $cmd = shift;
5242     my $opt = shift || '';    # opt[=val]
5243
5244     # Nonblank. Try to parse and process.
5245     if ( $opt =~ /^(\S.*)/ ) {
5246         &parse_options($1);
5247     }
5248
5249     # Blank. List the current option settings.
5250     else {
5251         for (@options) {
5252             &dump_option($_);
5253         }
5254     }
5255 } ## end sub cmd_o
5256
5257 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5258
5259 Advises the user that the O command has been renamed.
5260
5261 =cut
5262
5263 sub cmd_O {
5264     print $OUT "The old O command is now the o command.\n";             # hint
5265     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5266     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5267 }
5268
5269 =head3 C<cmd_v> - view window (command)
5270
5271 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5272 move back a few lines to list the selected line in context. Uses C<cmd_l>
5273 to do the actual listing after figuring out the range of line to request.
5274
5275 =cut
5276
5277 use vars qw($preview);
5278
5279 sub cmd_v {
5280     my $cmd  = shift;
5281     my $line = shift;
5282
5283     # Extract the line to list around. (Astute readers will have noted that
5284     # this pattern will match whether or not a numeric line is specified,
5285     # which means that we'll always enter this loop (though a non-numeric
5286     # argument results in no action at all)).
5287     if ( $line =~ /^(\d*)$/ ) {
5288
5289         # Total number of lines to list (a windowful).
5290         $incr = $window - 1;
5291
5292         # Set the start to the argument given (if there was one).
5293         $start = $1 if $1;
5294
5295         # Back up by the context amount.
5296         $start -= $preview;
5297
5298         # Put together a linespec that cmd_l will like.
5299         $line = $start . '-' . ( $start + $incr );
5300
5301         # List the lines.
5302         &cmd_l( 'l', $line );
5303     } ## end if ($line =~ /^(\d*)$/)
5304 } ## end sub cmd_v
5305
5306 =head3 C<cmd_w> - add a watch expression (command)
5307
5308 The 5.8 version of this command adds a watch expression if one is specified;
5309 it does nothing if entered with no operands.
5310
5311 We extract the expression, save it, evaluate it in the user's context, and
5312 save the value. We'll re-evaluate it each time the debugger passes a line,
5313 and will stop (see the code at the top of the command loop) if the value
5314 of any of the expressions changes.
5315
5316 =cut
5317
5318 sub cmd_w {
5319     my $cmd = shift;
5320
5321     # Null expression if no arguments.
5322     my $expr = shift || '';
5323
5324     # If expression is not null ...
5325     if ( $expr =~ /^(\S.*)/ ) {
5326
5327         # ... save it.
5328         push @to_watch, $expr;
5329
5330         # Parameterize DB::eval and call it to get the expression's value
5331         # in the user's context. This version can handle expressions which
5332         # return a list value.
5333         $evalarg = $expr;
5334         my ($val) = join( ' ', &eval );
5335         $val = ( defined $val ) ? "'$val'" : 'undef';
5336
5337         # Save the current value of the expression.
5338         push @old_watch, $val;
5339
5340         # We are now watching expressions.
5341         $trace |= 2;
5342     } ## end if ($expr =~ /^(\S.*)/)
5343
5344     # You have to give one to get one.
5345     else {
5346         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5347     }
5348 } ## end sub cmd_w
5349
5350 =head3 C<cmd_W> - delete watch expressions (command)
5351
5352 This command accepts either a watch expression to be removed from the list
5353 of watch expressions, or C<*> to delete them all.
5354
5355 If C<*> is specified, we simply empty the watch expression list and the
5356 watch expression value list. We also turn off the bit that says we've got
5357 watch expressions.
5358
5359 If an expression (or partial expression) is specified, we pattern-match
5360 through the expressions and remove the ones that match. We also discard
5361 the corresponding values. If no watch expressions are left, we turn off
5362 the I<watching expressions> bit.
5363
5364 =cut
5365
5366 sub cmd_W {
5367     my $cmd  = shift;
5368     my $expr = shift || '';
5369
5370     # Delete them all.
5371     if ( $expr eq '*' ) {
5372
5373         # Not watching now.
5374         $trace &= ~2;
5375
5376         print $OUT "Deleting all watch expressions ...\n";
5377
5378         # And all gone.
5379         @to_watch = @old_watch = ();
5380     }
5381
5382     # Delete one of them.
5383     elsif ( $expr =~ /^(\S.*)/ ) {
5384
5385         # Where we are in the list.
5386         my $i_cnt = 0;
5387
5388         # For each expression ...
5389         foreach (@to_watch) {
5390             my $val = $to_watch[$i_cnt];
5391
5392             # Does this one match the command argument?
5393             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5394                                       # Yes. Turn it off, and its value too.
5395                 splice( @to_watch,  $i_cnt, 1 );
5396                 splice( @old_watch, $i_cnt, 1 );
5397             }
5398             $i_cnt++;
5399         } ## end foreach (@to_watch)
5400
5401         # We don't bother to turn watching off because
5402         #  a) we don't want to stop calling watchfunction() it it exists
5403         #  b) foreach over a null list doesn't do anything anyway
5404
5405     } ## end elsif ($expr =~ /^(\S.*)/)
5406
5407     # No command arguments entered.
5408     else {
5409         print $OUT
5410           "Deleting a watch-expression requires an expression, or '*' for all\n"
5411           ;    # hint
5412     }
5413 } ## end sub cmd_W
5414
5415 ### END of the API section
5416
5417 =head1 SUPPORT ROUTINES
5418
5419 These are general support routines that are used in a number of places
5420 throughout the debugger.
5421
5422 =head2 save
5423
5424 save() saves the user's versions of globals that would mess us up in C<@saved>,
5425 and installs the versions we like better.
5426
5427 =cut
5428
5429 sub save {
5430
5431     # Save eval failure, command failure, extended OS error, output field
5432     # separator, input record separator, output record separator and
5433     # the warning setting.
5434     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5435
5436     $,  = "";      # output field separator is null string
5437     $/  = "\n";    # input record separator is newline
5438     $\  = "";      # output record separator is null string
5439     $^W = 0;       # warnings are off
5440 } ## end sub save
5441
5442 =head2 C<print_lineinfo> - show where we are now
5443
5444 print_lineinfo prints whatever it is that it is handed; it prints it to the
5445 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5446 us to feed line information to a slave editor without messing up the
5447 debugger output.
5448
5449 =cut
5450
5451 sub print_lineinfo {
5452
5453     # Make the terminal sensible if we're not the primary debugger.
5454     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5455     local $\ = '';
5456     local $, = '';
5457     print $LINEINFO @_;
5458 } ## end sub print_lineinfo
5459
5460 =head2 C<postponed_sub>
5461
5462 Handles setting postponed breakpoints in subroutines once they're compiled.
5463 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5464 range for the subroutine, then mark the file as having a breakpoint,
5465 temporarily switch the C<*dbline> glob over to the source file, and then
5466 search the given range of lines to find a breakable line. If we find one,
5467 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5468
5469 =cut
5470
5471 # The following takes its argument via $evalarg to preserve current @_
5472
5473 sub postponed_sub {
5474
5475     # Get the subroutine name.
5476     my $subname = shift;
5477
5478     # If this is a 'break +<n> if <condition>' ...
5479     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5480
5481         # If there's no offset, use '+0'.
5482         my $offset = $1 || 0;
5483
5484         # find_sub's value is 'fullpath-filename:start-stop'. It's
5485         # possible that the filename might have colons in it too.
5486         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5487         if ($i) {
5488
5489             # We got the start line. Add the offset '+<n>' from
5490             # $postponed{subname}.
5491             $i += $offset;
5492
5493             # Switch to the file this sub is in, temporarily.
5494             local *dbline = $main::{ '_<' . $file };
5495
5496             # No warnings, please.
5497             local $^W = 0;    # != 0 is magical below
5498
5499             # This file's got a breakpoint in it.
5500             $had_breakpoints{$file} |= 1;
5501
5502             # Last line in file.
5503             my $max = $#dbline;
5504
5505             # Search forward until we hit a breakable line or get to
5506             # the end of the file.
5507             ++$i until $dbline[$i] != 0 or $i >= $max;
5508
5509             # Copy the breakpoint in and delete it from %postponed.
5510             $dbline{$i} = delete $postponed{$subname};
5511         } ## end if ($i)
5512
5513         # find_sub didn't find the sub.
5514         else {
5515             local $\ = '';
5516             print $OUT "Subroutine $subname not found.\n";
5517         }
5518         return;
5519     } ## end if ($postponed{$subname...
5520     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5521
5522     #print $OUT "In postponed_sub for '$subname'.\n";
5523 } ## end sub postponed_sub
5524
5525 =head2 C<postponed>
5526
5527 Called after each required file is compiled, but before it is executed;
5528 also called if the name of a just-compiled subroutine is a key of
5529 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5530 etc.) into the just-compiled code.
5531
5532 If this is a C<require>'d file, the incoming parameter is the glob
5533 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5534
5535 If it's a subroutine, the incoming parameter is the subroutine name.
5536
5537 =cut
5538
5539 sub postponed {
5540
5541     # If there's a break, process it.
5542     if ($ImmediateStop) {
5543
5544         # Right, we've stopped. Turn it off.
5545         $ImmediateStop = 0;
5546
5547         # Enter the command loop when DB::DB gets called.
5548         $signal = 1;
5549     }
5550
5551     # If this is a subroutine, let postponed_sub() deal with it.
5552     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5553
5554     # Not a subroutine. Deal with the file.
5555     local *dbline = shift;
5556     my $filename = $dbline;
5557     $filename =~ s/^_<//;
5558     local $\ = '';
5559     $signal = 1, print $OUT "'$filename' loaded...\n"
5560       if $break_on_load{$filename};
5561     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5562
5563     # Do we have any breakpoints to put in this file?
5564     return unless $postponed_file{$filename};
5565
5566     # Yes. Mark this file as having breakpoints.
5567     $had_breakpoints{$filename} |= 1;
5568
5569     # "Cannot be done: insufficient magic" - we can't just put the
5570     # breakpoints saved in %postponed_file into %dbline by assigning
5571     # the whole hash; we have to do it one item at a time for the
5572     # breakpoints to be set properly.
5573     #%dbline = %{$postponed_file{$filename}};
5574
5575     # Set the breakpoints, one at a time.
5576     my $key;
5577
5578     for $key ( keys %{ $postponed_file{$filename} } ) {
5579
5580         # Stash the saved breakpoint into the current file's magic line array.
5581         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5582     }
5583
5584     # This file's been compiled; discard the stored breakpoints.
5585     delete $postponed_file{$filename};
5586
5587 } ## end sub postponed
5588
5589 =head2 C<dumpit>
5590
5591 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5592
5593 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5594 a reference to a variable (the thing to be dumped) as its input.
5595
5596 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5597 the currently-selected filehandle, thank you very much). The current
5598 values of the package globals C<$single> and C<$trace> are backed up in
5599 lexicals, and they are turned off (this keeps the debugger from trying
5600 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5601 preserve its current value and it is set to zero to prevent entry/exit
5602 messages from printing, and C<$doret> is localized as well and set to -2 to
5603 prevent return values from being shown.
5604
5605 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5606 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5607 installed version in C<@INC>, yours will be used instead. Possible security
5608 problem?).
5609
5610 It then checks to see if the subroutine C<main::dumpValue> is now defined
5611 (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5612 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5613 is called, and picks up the variable to be dumped from the parameter list.
5614
5615 It checks the package global C<%options> to see if there's a C<dumpDepth>
5616 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5617 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5618 structure: -1 means dump everything.
5619
5620 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5621 warning.
5622
5623 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5624 and we then return to the caller.
5625
5626 =cut
5627
5628 sub dumpit {
5629
5630     # Save the current output filehandle and switch to the one
5631     # passed in as the first parameter.
5632     my $savout = select(shift);
5633
5634     # Save current settings of $single and $trace, and then turn them off.
5635     my $osingle = $single;
5636     my $otrace  = $trace;
5637     $single = $trace = 0;
5638
5639     # XXX Okay, what do $frame and $doret do, again?
5640     local $frame = 0;
5641     local $doret = -2;
5642
5643     # Load dumpvar.pl unless we've already got the sub we need from it.
5644     unless ( defined &main::dumpValue ) {
5645         do 'dumpvar.pl' or die $@;
5646     }
5647
5648     # If the load succeeded (or we already had dumpvalue()), go ahead
5649     # and dump things.
5650     if ( defined &main::dumpValue ) {
5651         local $\ = '';
5652         local $, = '';
5653         local $" = ' ';
5654         my $v = shift;
5655         my $maxdepth = shift || $option{dumpDepth};
5656         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5657         &main::dumpValue( $v, $maxdepth );
5658     } ## end if (defined &main::dumpValue)
5659
5660     # Oops, couldn't load dumpvar.pl.
5661     else {
5662         local $\ = '';
5663         print $OUT "dumpvar.pl not available.\n";
5664     }
5665
5666     # Reset $single and $trace to their old values.
5667     $single = $osingle;
5668     $trace  = $otrace;
5669
5670     # Restore the old filehandle.
5671     select($savout);
5672 } ## end sub dumpit
5673
5674 =head2 C<print_trace>
5675
5676 C<print_trace>'s job is to print a stack trace. It does this via the
5677 C<dump_trace> routine, which actually does all the ferreting-out of the
5678 stack trace data. C<print_trace> takes care of formatting it nicely and
5679 printing it to the proper filehandle.
5680
5681 Parameters:
5682
5683 =over 4
5684
5685 =item *
5686
5687 The filehandle to print to.
5688
5689 =item *
5690
5691 How many frames to skip before starting trace.
5692
5693 =item *
5694
5695 How many frames to print.
5696
5697 =item *
5698
5699 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5700
5701 =back
5702
5703 The original comment below seems to be noting that the traceback may not be
5704 correct if this routine is called in a tied method.
5705
5706 =cut
5707
5708 # Tied method do not create a context, so may get wrong message:
5709
5710 sub print_trace {
5711     local $\ = '';
5712     my $fh = shift;
5713
5714     # If this is going to a slave editor, but we're not the primary
5715     # debugger, reset it first.
5716     resetterm(1)
5717       if $fh        eq $LINEINFO    # slave editor
5718       and $LINEINFO eq $OUT         # normal output
5719       and $term_pid != $$;          # not the primary
5720
5721     # Collect the actual trace information to be formatted.
5722     # This is an array of hashes of subroutine call info.
5723     my @sub = dump_trace( $_[0] + 1, $_[1] );
5724
5725     # Grab the "short report" flag from @_.
5726     my $short = $_[2];              # Print short report, next one for sub name
5727
5728     # Run through the traceback info, format it, and print it.
5729     my $s;
5730     for ( my $i = 0 ; $i <= $#sub ; $i++ ) {
5731
5732         # Drop out if the user has lost interest and hit control-C.
5733         last if $signal;
5734
5735         # Set the separator so arrys print nice.
5736         local $" = ', ';
5737
5738         # Grab and stringify the arguments if they are there.
5739         my $args =
5740           defined $sub[$i]{args}
5741           ? "(@{ $sub[$i]{args} })"
5742           : '';
5743
5744         # Shorten them up if $maxtrace says they're too long.
5745         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5746           if length $args > $maxtrace;
5747
5748         # Get the file name.
5749         my $file = $sub[$i]{file};
5750
5751         # Put in a filename header if short is off.
5752         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
5753
5754         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5755         $s = $sub[$i]{sub};
5756         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5757
5758         # Short report uses trimmed file and sub names.
5759         if ($short) {
5760             my $sub = @_ >= 4 ? $_[3] : $s;
5761             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5762         } ## end if ($short)
5763
5764         # Non-short report includes full names.
5765         else {
5766             print $fh "$sub[$i]{context} = $s$args"
5767               . " called from $file"
5768               . " line $sub[$i]{line}\n";
5769         }
5770     } ## end for ($i = 0 ; $i <= $#sub...
5771 } ## end sub print_trace
5772
5773 =head2 dump_trace(skip[,count])
5774
5775 Actually collect the traceback information available via C<caller()>. It does
5776 some filtering and cleanup of the data, but mostly it just collects it to
5777 make C<print_trace()>'s job easier.
5778
5779 C<skip> defines the number of stack frames to be skipped, working backwards
5780 from the most current. C<count> determines the total number of frames to
5781 be returned; all of them (well, the first 10^9) are returned if C<count>
5782 is omitted.
5783
5784 This routine returns a list of hashes, from most-recent to least-recent
5785 stack frame. Each has the following keys and values:
5786
5787 =over 4
5788
5789 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5790
5791 =item * C<sub> - subroutine name, or C<eval> information
5792
5793 =item * C<args> - undef, or a reference to an array of arguments
5794
5795 =item * C<file> - the file in which this item was defined (if any)
5796
5797 =item * C<line> - the line on which it was defined
5798
5799 =back
5800
5801 =cut
5802
5803 sub dump_trace {
5804
5805     # How many levels to skip.
5806     my $skip = shift;
5807
5808     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5809     # it's unlikely that we'll have more than a billion stack frames. If you
5810     # do, you've got an awfully big machine...)
5811     my $count = shift || 1e9;
5812
5813     # We increment skip because caller(1) is the first level *back* from
5814     # the current one.  Add $skip to the count of frames so we have a
5815     # simple stop criterion, counting from $skip to $count+$skip.
5816     $skip++;
5817     $count += $skip;
5818
5819     # These variables are used to capture output from caller();
5820     my ( $p, $file, $line, $sub, $h, $context );
5821
5822     my ( $e, $r, @a, @sub, $args );
5823
5824     # XXX Okay... why'd we do that?
5825     my $nothard = not $frame & 8;
5826     local $frame = 0;
5827
5828     # Do not want to trace this.
5829     my $otrace = $trace;
5830     $trace = 0;
5831
5832     # Start out at the skip count.
5833     # If we haven't reached the number of frames requested, and caller() is
5834     # still returning something, stay in the loop. (If we pass the requested
5835     # number of stack frames, or we run out - caller() returns nothing - we
5836     # quit.
5837     # Up the stack frame index to go back one more level each time.
5838     for (
5839         my $i = $skip ;
5840         $i < $count
5841         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5842         $i++
5843       )
5844     {
5845
5846         # Go through the arguments and save them for later.
5847         @a = ();
5848         for my $arg (@args) {
5849             my $type;
5850             if ( not defined $arg ) {    # undefined parameter
5851                 push @a, "undef";
5852             }
5853
5854             elsif ( $nothard and tied $arg ) {    # tied parameter
5855                 push @a, "tied";
5856             }
5857             elsif ( $nothard and $type = ref $arg ) {    # reference
5858                 push @a, "ref($type)";
5859             }
5860             else {                                       # can be stringified
5861                 local $_ =
5862                   "$arg";    # Safe to stringify now - should not call f().
5863
5864                 # Backslash any single-quotes or backslashes.
5865                 s/([\'\\])/\\$1/g;
5866
5867                 # Single-quote it unless it's a number or a colon-separated
5868                 # name.
5869                 s/(.*)/'$1'/s
5870                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5871
5872                 # Turn high-bit characters into meta-whatever.
5873                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5874
5875                 # Turn control characters into ^-whatever.
5876                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5877
5878                 push( @a, $_ );
5879             } ## end else [ if (not defined $arg)
5880         } ## end for $arg (@args)
5881
5882         # If context is true, this is array (@)context.
5883         # If context is false, this is scalar ($) context.
5884         # If neither, context isn't defined. (This is apparently a 'can't
5885         # happen' trap.)
5886         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5887
5888         # if the sub has args ($h true), make an anonymous array of the
5889         # dumped args.
5890         $args = $h ? [@a] : undef;
5891
5892         # remove trailing newline-whitespace-semicolon-end of line sequence
5893         # from the eval text, if any.
5894         $e =~ s/\n\s*\;\s*\Z// if $e;
5895
5896         # Escape backslashed single-quotes again if necessary.
5897         $e =~ s/([\\\'])/\\$1/g if $e;
5898
5899         # if the require flag is true, the eval text is from a require.
5900         if ($r) {
5901             $sub = "require '$e'";
5902         }
5903
5904         # if it's false, the eval text is really from an eval.
5905         elsif ( defined $r ) {
5906             $sub = "eval '$e'";
5907         }
5908
5909         # If the sub is '(eval)', this is a block eval, meaning we don't
5910         # know what the eval'ed text actually was.
5911         elsif ( $sub eq '(eval)' ) {
5912             $sub = "eval {...}";
5913         }
5914
5915         # Stick the collected information into @sub as an anonymous hash.
5916         push(
5917             @sub,
5918             {
5919                 context => $context,
5920                 sub     => $sub,
5921                 args    => $args,
5922                 file    => $file,
5923                 line    => $line
5924             }
5925         );
5926
5927         # Stop processing frames if the user hit control-C.
5928         last if $signal;
5929     } ## end for ($i = $skip ; $i < ...
5930
5931     # Restore the trace value again.
5932     $trace = $otrace;
5933     @sub;
5934 } ## end sub dump_trace
5935
5936 =head2 C<action()>
5937
5938 C<action()> takes input provided as the argument to an add-action command,
5939 either pre- or post-, and makes sure it's a complete command. It doesn't do
5940 any fancy parsing; it just keeps reading input until it gets a string
5941 without a trailing backslash.
5942
5943 =cut
5944
5945 sub action {
5946     my $action = shift;
5947
5948     while ( $action =~ s/\\$// ) {
5949
5950         # We have a backslash on the end. Read more.
5951         $action .= &gets;
5952     } ## end while ($action =~ s/\\$//)
5953
5954     # Return the assembled action.
5955     $action;
5956 } ## end sub action
5957
5958 =head2 unbalanced
5959
5960 This routine mostly just packages up a regular expression to be used
5961 to check that the thing it's being matched against has properly-matched
5962 curly braces.
5963
5964 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
5965 speeds things up by only creating the qr//'ed expression once; if it's
5966 already defined, we don't try to define it again. A speed hack.
5967
5968 =cut
5969
5970 use vars qw($balanced_brace_re);
5971
5972 sub unbalanced {
5973
5974     # I hate using globals!
5975     $balanced_brace_re ||= qr{
5976         ^ \{
5977              (?:
5978                  (?> [^{}] + )              # Non-parens without backtracking
5979                 |
5980                  (??{ $balanced_brace_re }) # Group with matching parens
5981               ) *
5982           \} $
5983    }x;
5984     return $_[0] !~ m/$balanced_brace_re/;
5985 } ## end sub unbalanced
5986
5987 =head2 C<gets()>
5988
5989 C<gets()> is a primitive (very primitive) routine to read continuations.
5990 It was devised for reading continuations for actions.
5991 it just reads more input with C<readline()> and returns it.
5992
5993 =cut
5994
5995 sub gets {
5996     &readline("cont: ");
5997 }
5998
5999 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
6000
6001 The C<system()> function assumes that it can just go ahead and use STDIN and
6002 STDOUT, but under the debugger, we want it to use the debugger's input and
6003 outout filehandles.
6004
6005 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
6006 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6007 and then puts everything back again.
6008
6009 =cut
6010
6011 sub system {
6012
6013     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6014     # some non-Unix systems can do system() but have problems with fork().
6015     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
6016     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
6017     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
6018     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
6019
6020     # XXX: using csh or tcsh destroys sigint retvals!
6021     system(@_);
6022     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
6023     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
6024     close(SAVEIN);
6025     close(SAVEOUT);
6026
6027     # most of the $? crud was coping with broken cshisms
6028     if ( $? >> 8 ) {
6029         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6030     }
6031     elsif ($?) {
6032         &warn(
6033             "(Command died of SIG#",
6034             ( $? & 127 ),
6035             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6036             ")", "\n"
6037         );
6038     } ## end elsif ($?)
6039
6040     return $?;
6041
6042 } ## end sub system
6043
6044 =head1 TTY MANAGEMENT
6045
6046 The subs here do some of the terminal management for multiple debuggers.
6047
6048 =head2 setterm
6049
6050 Top-level function called when we want to set up a new terminal for use
6051 by the debugger.
6052
6053 If the C<noTTY> debugger option was set, we'll either use the terminal
6054 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6055 to find one. If we're a forked debugger, we call C<resetterm> to try to
6056 get a whole new terminal if we can.
6057
6058 In either case, we set up the terminal next. If the C<ReadLine> option was
6059 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6060 the appropriate attributes. We then
6061
6062 =cut
6063
6064 use vars qw($ornaments);
6065 use vars qw($rl_attribs);
6066
6067 sub setterm {
6068
6069     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6070     local $frame = 0;
6071     local $doret = -2;
6072     require Term::ReadLine;
6073
6074     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6075     if ($notty) {
6076         if ($tty) {
6077             my ( $i, $o ) = split $tty, /,/;
6078             $o = $i unless defined $o;
6079             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6080             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6081             $IN  = \*IN;
6082             $OUT = \*OUT;
6083             my $sel = select($OUT);
6084             $| = 1;
6085             select($sel);
6086         } ## end if ($tty)
6087
6088         # We don't have a TTY - try to find one via Term::Rendezvous.
6089         else {
6090             require Term::Rendezvous;
6091
6092             # See if we have anything to pass to Term::Rendezvous.
6093             # Use $HOME/.perldbtty$$ if not.
6094             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6095
6096             # Rendezvous and get the filehandles.
6097             my $term_rv = Term::Rendezvous->new( $rv );
6098             $IN  = $term_rv->IN;
6099             $OUT = $term_rv->OUT;
6100         } ## end else [ if ($tty)
6101     } ## end if ($notty)
6102
6103     # We're a daughter debugger. Try to fork off another TTY.
6104     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6105         resetterm(2);
6106     }
6107
6108     # If we shouldn't use Term::ReadLine, don't.
6109     if ( !$rl ) {
6110         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6111     }
6112
6113     # We're using Term::ReadLine. Get all the attributes for this terminal.
6114     else {
6115         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6116
6117         $rl_attribs = $term->Attribs;
6118         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6119           if defined $rl_attribs->{basic_word_break_characters}
6120           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6121         $rl_attribs->{special_prefixes} = '$@&%';
6122         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6123         $rl_attribs->{completion_function} = \&db_complete;
6124     } ## end else [ if (!$rl)
6125
6126     # Set up the LINEINFO filehandle.
6127     $LINEINFO = $OUT     unless defined $LINEINFO;
6128     $lineinfo = $console unless defined $lineinfo;
6129
6130     $term->MinLine(2);
6131
6132     &load_hist();
6133
6134     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6135         $term->SetHistory(@hist);
6136     }
6137
6138     # XXX Ornaments are turned on unconditionally, which is not
6139     # always a good thing.
6140     ornaments($ornaments) if defined $ornaments;
6141     $term_pid = $$;
6142 } ## end sub setterm
6143
6144 sub load_hist {
6145     $histfile //= option_val("HistFile", undef);
6146     return unless defined $histfile;
6147     open my $fh, "<", $histfile or return;
6148     local $/ = "\n";
6149     @hist = ();
6150     while (<$fh>) {
6151         chomp;
6152         push @hist, $_;
6153     }
6154     close $fh;
6155 }
6156
6157 sub save_hist {
6158     return unless defined $histfile;
6159     eval { require File::Path } or return;
6160     eval { require File::Basename } or return;
6161     File::Path::mkpath(File::Basename::dirname($histfile));
6162     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6163     $histsize //= option_val("HistSize",100);
6164     my @copy = grep { $_ ne '?' } @hist;
6165     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6166     for ($start .. $#copy) {
6167         print $fh "$copy[$_]\n";
6168     }
6169     close $fh or die "Could not write '$histfile': $!";
6170 }
6171
6172 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6173
6174 When the process being debugged forks, or the process invokes a command
6175 via C<system()> which starts a new debugger, we need to be able to get a new
6176 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6177 fight over the terminal, and you can never quite be sure who's going to get the
6178 input you're typing.
6179
6180 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6181 is tasked with doing all the necessary operating system mojo to get a new
6182 TTY (and probably another window) and to direct the new debugger to read and
6183 write there.
6184
6185 The debugger provides C<get_fork_TTY> functions which work for TCP
6186 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6187 supported. You are encouraged to write C<get_fork_TTY> functions which
6188 work for I<your> platform and contribute them.
6189
6190 =head3 C<socket_get_fork_TTY>
6191
6192 =cut
6193
6194 sub connect_remoteport {
6195     require IO::Socket;
6196
6197     my $socket = IO::Socket::INET->new(
6198         Timeout  => '10',
6199         PeerAddr => $remoteport,
6200         Proto    => 'tcp',
6201     );
6202     if ( ! $socket ) {
6203         die "Unable to connect to remote host: $remoteport\n";
6204     }
6205     return $socket;
6206 }
6207
6208 sub socket_get_fork_TTY {
6209     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6210
6211     # Do I need to worry about setting $term?
6212
6213     reset_IN_OUT( $IN, $OUT );
6214     return '';
6215 }
6216
6217 =head3 C<xterm_get_fork_TTY>
6218
6219 This function provides the C<get_fork_TTY> function for X11. If a
6220 program running under the debugger forks, a new <xterm> window is opened and
6221 the subsidiary debugger is directed there.
6222
6223 The C<open()> call is of particular note here. We have the new C<xterm>
6224 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6225 command (which prints the device name of the TTY we'll want to use for input
6226 and output to STDOUT, then C<sleep> for a very long time, routing this output
6227 to file number 3. This way we can simply read from the <XT> filehandle (which
6228 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6229
6230 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6231 properly set up.
6232
6233 =cut
6234
6235 sub xterm_get_fork_TTY {
6236     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6237     open XT,
6238 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6239  sleep 10000000' |];
6240
6241     # Get the output from 'tty' and clean it up a little.
6242     my $tty = <XT>;
6243     chomp $tty;
6244
6245     $pidprompt = '';    # Shown anyway in titlebar
6246
6247     # We need $term defined or we can not switch to the newly created xterm
6248     if ($tty ne '' && !defined $term) {
6249         require Term::ReadLine;
6250         if ( !$rl ) {
6251             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6252         }
6253         else {
6254             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6255         }
6256     }
6257     # There's our new TTY.
6258     return $tty;
6259 } ## end sub xterm_get_fork_TTY
6260
6261 =head3 C<os2_get_fork_TTY>
6262
6263 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6264
6265 =cut
6266
6267 # This example function resets $IN, $OUT itself
6268 my $c_pipe = 0;
6269 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6270     local $\  = '';
6271     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6272     my %opt = ( title => "Daughter Perl debugger $pids $name",
6273                 ($rl ? (read_by_key => 1) : ()) );
6274     require OS2::Process;
6275     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6276       or return;
6277     $pidprompt = '';    # Shown anyway in titlebar
6278     reset_IN_OUT($in, $out);
6279     $tty = '*reset*';
6280     return '';          # Indicate that reset_IN_OUT is called
6281 } ## end sub os2_get_fork_TTY
6282
6283 =head3 C<macosx_get_fork_TTY>
6284
6285 The Mac OS X version uses AppleScript to tell Terminal.app to create
6286 a new window.
6287
6288 =cut
6289
6290 # Notes about Terminal.app's AppleScript support,
6291 # (aka things that might break in future OS versions).
6292 #
6293 # The "do script" command doesn't return a reference to the new window
6294 # it creates, but since it appears frontmost and windows are enumerated
6295 # front to back, we can use "first window" === "window 1".
6296 #
6297 # Since "do script" is implemented by supplying the argument (plus a
6298 # return character) as terminal input, there's a potential race condition
6299 # where the debugger could beat the shell to reading the command.
6300 # To prevent this, we wait for the screen to clear before proceeding.
6301 #
6302 # 10.3 and 10.4:
6303 # There's no direct accessor for the tty device name, so we fiddle
6304 # with the window title options until it says what we want.
6305 #
6306 # 10.5:
6307 # There _is_ a direct accessor for the tty device name, _and_ there's
6308 # a new possible component of the window title (the name of the settings
6309 # set).  A separate version is needed.
6310
6311 my @script_versions=
6312
6313     ([237, <<'__LEOPARD__'],
6314 tell application "Terminal"
6315     do script "clear;exec sleep 100000"
6316     tell first tab of first window
6317         copy tty to thetty
6318         set custom title to "forked perl debugger"
6319         set title displays custom title to true
6320         repeat while (length of first paragraph of (get contents)) > 0
6321             delay 0.1
6322         end repeat
6323     end tell
6324 end tell
6325 thetty
6326 __LEOPARD__
6327
6328      [100, <<'__JAGUAR_TIGER__'],
6329 tell application "Terminal"
6330     do script "clear;exec sleep 100000"
6331     tell first window
6332         set title displays shell path to false
6333         set title displays window size to false
6334         set title displays file name to false
6335         set title displays device name to true
6336         set title displays custom title to true
6337         set custom title to ""
6338         copy "/dev/" & name to thetty
6339         set custom title to "forked perl debugger"
6340         repeat while (length of first paragraph of (get contents)) > 0
6341             delay 0.1
6342         end repeat
6343     end tell
6344 end tell
6345 thetty
6346 __JAGUAR_TIGER__
6347
6348 );
6349
6350 sub macosx_get_fork_TTY
6351 {
6352     my($version,$script,$pipe,$tty);
6353
6354     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6355     foreach my $entry (@script_versions) {
6356         if ($version>=$entry->[0]) {
6357             $script=$entry->[1];
6358             last;
6359         }
6360     }
6361     return unless defined($script);
6362     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6363     $tty=readline($pipe);
6364     close($pipe);
6365     return unless defined($tty) && $tty =~ m(^/dev/);
6366     chomp $tty;
6367     return $tty;
6368 }
6369
6370 =head2 C<create_IN_OUT($flags)>
6371
6372 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6373 try to diagnose why.
6374
6375 Flags are:
6376
6377 =over 4
6378
6379 =item * 1 - Don't know how to create a new TTY.
6380
6381 =item * 2 - Debugger has forked, but we can't get a new TTY.
6382
6383 =item * 4 - standard debugger startup is happening.
6384
6385 =back
6386
6387 =cut
6388
6389 use vars qw($fork_TTY);
6390
6391 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6392
6393     # If we know how to get a new TTY, do it! $in will have
6394     # the TTY name if get_fork_TTY works.
6395     my $in = &get_fork_TTY if defined &get_fork_TTY;
6396
6397     # It used to be that
6398     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6399
6400     if ( not defined $in ) {
6401         my $why = shift;
6402
6403         # We don't know how.
6404         print_help(<<EOP) if $why == 1;
6405 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6406 EOP
6407
6408         # Forked debugger.
6409         print_help(<<EOP) if $why == 2;
6410 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6411   This may be an asynchronous session, so the parent debugger may be active.
6412 EOP
6413
6414         # Note that both debuggers are fighting over the same input.
6415         print_help(<<EOP) if $why != 4;
6416   Since two debuggers fight for the same TTY, input is severely entangled.
6417
6418 EOP
6419         print_help(<<EOP);
6420   I know how to switch the output to a different window in xterms, OS/2
6421   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6422   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6423   B<DB::get_fork_TTY()> returning this.
6424
6425   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6426   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6427
6428 EOP
6429     } ## end if (not defined $in)
6430     elsif ( $in ne '' ) {
6431         TTY($in);
6432     }
6433     else {
6434         $console = '';    # Indicate no need to open-from-the-console
6435     }
6436     undef $fork_TTY;
6437 } ## end sub create_IN_OUT
6438
6439 =head2 C<resetterm>
6440
6441 Handles rejiggering the prompt when we've forked off a new debugger.
6442
6443 If the new debugger happened because of a C<system()> that invoked a
6444 program under the debugger, the arrow between the old pid and the new
6445 in the prompt has I<two> dashes instead of one.
6446
6447 We take the current list of pids and add this one to the end. If there
6448 isn't any list yet, we make one up out of the initial pid associated with
6449 the terminal and our new pid, sticking an arrow (either one-dashed or
6450 two dashed) in between them.
6451
6452 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6453 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6454 and try to do that.
6455
6456 =cut
6457
6458 sub resetterm {    # We forked, so we need a different TTY
6459
6460     # Needs to be passed to create_IN_OUT() as well.
6461     my $in = shift;
6462
6463     # resetterm(2): got in here because of a system() starting a debugger.
6464     # resetterm(1): just forked.
6465     my $systemed = $in > 1 ? '-' : '';
6466
6467     # If there's already a list of pids, add this to the end.
6468     if ($pids) {
6469         $pids =~ s/\]/$systemed->$$]/;
6470     }
6471
6472     # No pid list. Time to make one.
6473     else {
6474         $pids = "[$term_pid->$$]";
6475     }
6476
6477     # The prompt we're going to be using for this debugger.
6478     $pidprompt = $pids;
6479
6480     # We now 0wnz this terminal.
6481     $term_pid = $$;
6482
6483     # Just return if we're not supposed to try to create a new TTY.
6484     return unless $CreateTTY & $in;
6485
6486     # Try to create a new IN/OUT pair.
6487     create_IN_OUT($in);
6488 } ## end sub resetterm
6489
6490 =head2 C<readline>
6491
6492 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6493 the next line, print a message saying we got it, add it to the terminal
6494 history (if possible), and return it.
6495
6496 If there's nothing in the typeahead buffer, check the command filehandle stack.
6497 If there are any filehandles there, read from the last one, and return the line
6498 if we got one. If not, we pop the filehandle off and close it, and try the
6499 next one up the stack.
6500
6501 If we've emptied the filehandle stack, we check to see if we've got a socket
6502 open, and we read that and return it if we do. If we don't, we just call the
6503 core C<readline()> and return its value.
6504
6505 =cut
6506
6507 sub readline {
6508
6509     # Localize to prevent it from being smashed in the program being debugged.
6510     local $.;
6511
6512     # Pull a line out of the typeahead if there's stuff there.
6513     if (@typeahead) {
6514
6515         # How many lines left.
6516         my $left = @typeahead;
6517
6518         # Get the next line.
6519         my $got = shift @typeahead;
6520
6521         # Print a message saying we got input from the typeahead.
6522         local $\ = '';
6523         print $OUT "auto(-$left)", shift, $got, "\n";
6524
6525         # Add it to the terminal history (if possible).
6526         $term->AddHistory($got)
6527           if length($got) > 1
6528           and defined $term->Features->{addHistory};
6529         return $got;
6530     } ## end if (@typeahead)
6531
6532     # We really need to read some input. Turn off entry/exit trace and
6533     # return value printing.
6534     local $frame = 0;
6535     local $doret = -2;
6536
6537     # If there are stacked filehandles to read from ...
6538     while (@cmdfhs) {
6539
6540         # Read from the last one in the stack.
6541         my $line = CORE::readline( $cmdfhs[-1] );
6542
6543         # If we got a line ...
6544         defined $line
6545           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6546           : close pop @cmdfhs;                            # Pop and close
6547     } ## end while (@cmdfhs)
6548
6549     # Nothing on the filehandle stack. Socket?
6550     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6551
6552         # Send anything we have to send.
6553         $OUT->write( join( '', @_ ) );
6554
6555         # Receive anything there is to receive.
6556         my $stuff = '';
6557         my $buf;
6558         do {
6559             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6560                                             # XXX Don't know. You tell me.
6561         } while length $buf and ($stuff .= $buf) !~ /\n/;
6562
6563         # What we got.
6564         $stuff;
6565     } ## end if (ref $OUT and UNIVERSAL::isa...
6566
6567     # No socket. Just read from the terminal.
6568     else {
6569         $term->readline(@_);
6570     }
6571 } ## end sub readline
6572
6573 =head1 OPTIONS SUPPORT ROUTINES
6574
6575 These routines handle listing and setting option values.
6576
6577 =head2 C<dump_option> - list the current value of an option setting
6578
6579 This routine uses C<option_val> to look up the value for an option.
6580 It cleans up escaped single-quotes and then displays the option and
6581 its value.
6582
6583 =cut
6584
6585 sub dump_option {
6586     my ( $opt, $val ) = @_;
6587     $val = option_val( $opt, 'N/A' );
6588     $val =~ s/([\\\'])/\\$1/g;
6589     printf $OUT "%20s = '%s'\n", $opt, $val;
6590 } ## end sub dump_option
6591
6592 sub options2remember {
6593     foreach my $k (@RememberOnROptions) {
6594         $option{$k} = option_val( $k, 'N/A' );
6595     }
6596     return %option;
6597 }
6598
6599 =head2 C<option_val> - find the current value of an option
6600
6601 This can't just be a simple hash lookup because of the indirect way that
6602 the option values are stored. Some are retrieved by calling a subroutine,
6603 some are just variables.
6604
6605 You must supply a default value to be used in case the option isn't set.
6606
6607 =cut
6608
6609 sub option_val {
6610     my ( $opt, $default ) = @_;
6611     my $val;
6612
6613     # Does this option exist, and is it a variable?
6614     # If so, retrieve the value via the value in %optionVars.
6615     if (    defined $optionVars{$opt}
6616         and defined ${ $optionVars{$opt} } )
6617     {
6618         $val = ${ $optionVars{$opt} };
6619     }
6620
6621     # Does this option exist, and it's a subroutine?
6622     # If so, call the subroutine via the ref in %optionAction
6623     # and capture the value.
6624     elsif ( defined $optionAction{$opt}
6625         and defined &{ $optionAction{$opt} } )
6626     {
6627         $val = &{ $optionAction{$opt} }();
6628     }
6629
6630     # If there's an action or variable for the supplied option,
6631     # but no value was set, use the default.
6632     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6633         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6634     {
6635         $val = $default;
6636     }
6637
6638     # Otherwise, do the simple hash lookup.
6639     else {
6640         $val = $option{$opt};
6641     }
6642
6643     # If the value isn't defined, use the default.
6644     # Then return whatever the value is.
6645     $val = $default unless defined $val;
6646     $val;
6647 } ## end sub option_val
6648
6649 =head2 C<parse_options>
6650
6651 Handles the parsing and execution of option setting/displaying commands.
6652
6653 An option entered by itself is assumed to be I<set me to 1> (the default value)
6654 if the option is a boolean one. If not, the user is prompted to enter a valid
6655 value or to query the current value (via C<option? >).
6656
6657 If C<option=value> is entered, we try to extract a quoted string from the
6658 value (if it is quoted). If it's not, we just use the whole value as-is.
6659
6660 We load any modules required to service this option, and then we set it: if
6661 it just gets stuck in a variable, we do that; if there's a subroutine to
6662 handle setting the option, we call that.
6663
6664 Finally, if we're running in interactive mode, we display the effect of the
6665 user's command back to the terminal, skipping this if we're setting things
6666 during initialization.
6667
6668 =cut
6669
6670 sub parse_options {
6671     local ($_) = @_;
6672     local $\ = '';
6673
6674     my $option;
6675
6676     # These options need a value. Don't allow them to be clobbered by accident.
6677     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6678       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6679       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6680     };
6681
6682     while (length) {
6683         my $val_defaulted;
6684
6685         # Clean off excess leading whitespace.
6686         s/^\s+// && next;
6687
6688         # Options are always all word characters, followed by a non-word
6689         # separator.
6690         s/^(\w+)(\W?)// or print( $OUT "Invalid option '$_'\n" ), last;
6691         my ( $opt, $sep ) = ( $1, $2 );
6692
6693         # Make sure that such an option exists.
6694         my $matches = grep( /^\Q$opt/ && ( $option = $_ ), @options )
6695           || grep( /^\Q$opt/i && ( $option = $_ ), @options );
6696
6697         print( $OUT "Unknown option '$opt'\n" ), next unless $matches;
6698         print( $OUT "Ambiguous option '$opt'\n" ), next if $matches > 1;
6699         my $val;
6700
6701         # '?' as separator means query, but must have whitespace after it.
6702         if ( "?" eq $sep ) {
6703             print( $OUT "Option query '$opt?' followed by non-space '$_'\n" ),
6704               last
6705               if /^\S/;
6706
6707             #&dump_option($opt);
6708         } ## end if ("?" eq $sep)
6709
6710         # Separator is whitespace (or just a carriage return).
6711         # They're going for a default, which we assume is 1.
6712         elsif ( $sep !~ /\S/ ) {
6713             $val_defaulted = 1;
6714             $val           = "1";   #  this is an evil default; make 'em set it!
6715         }
6716
6717         # Separator is =. Trying to set a value.
6718         elsif ( $sep eq "=" ) {
6719
6720             # If quoted, extract a quoted string.
6721             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6722                 my $quote = $1;
6723                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6724             }
6725
6726             # Not quoted. Use the whole thing. Warn about 'option='.
6727             else {
6728                 s/^(\S*)//;
6729                 $val = $1;
6730                 print OUT qq(Option better cleared using $opt=""\n)
6731                   unless length $val;
6732             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6733
6734         } ## end elsif ($sep eq "=")
6735
6736         # "Quoted" with [], <>, or {}.
6737         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6738             my ($end) =
6739               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6740             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6741               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
6742             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6743         } ## end else [ if ("?" eq $sep)
6744
6745         # Exclude non-booleans from getting set to 1 by default.
6746         if ( $opt_needs_val{$option} && $val_defaulted ) {
6747             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6748             print $OUT
6749 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
6750             next;
6751         } ## end if ($opt_needs_val{$option...
6752
6753         # Save the option value.
6754         $option{$option} = $val if defined $val;
6755
6756         # Load any module that this option requires.
6757         eval qq{
6758                 local \$frame = 0;
6759                 local \$doret = -2;
6760                 require '$optionRequire{$option}';
6761                 1;
6762                } || die $@   # XXX: shouldn't happen
6763           if defined $optionRequire{$option}
6764           && defined $val;
6765
6766         # Set it.
6767         # Stick it in the proper variable if it goes in a variable.
6768         ${ $optionVars{$option} } = $val
6769           if defined $optionVars{$option}
6770           && defined $val;
6771
6772         # Call the appropriate sub if it gets set via sub.
6773         &{ $optionAction{$option} }($val)
6774           if defined $optionAction{$option}
6775           && defined &{ $optionAction{$option} }
6776           && defined $val;
6777
6778         # Not initialization - echo the value we set it to.
6779         dump_option($option) unless $OUT eq \*STDERR;
6780     } ## end while (length)
6781 } ## end sub parse_options
6782
6783 =head1 RESTART SUPPORT
6784
6785 These routines are used to store (and restore) lists of items in environment
6786 variables during a restart.
6787
6788 =head2 set_list
6789
6790 Set_list packages up items to be stored in a set of environment variables
6791 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6792 the values). Values outside the standard ASCII charset are stored by encoding
6793 then as hexadecimal values.
6794
6795 =cut
6796
6797 sub set_list {
6798     my ( $stem, @list ) = @_;
6799     my $val;
6800
6801     # VAR_n: how many we have. Scalar assignment gets the number of items.
6802     $ENV{"${stem}_n"} = @list;
6803
6804     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6805     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6806     for my $i ( 0 .. $#list ) {
6807         $val = $list[$i];
6808         $val =~ s/\\/\\\\/g;
6809         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6810         $ENV{"${stem}_$i"} = $val;
6811     } ## end for $i (0 .. $#list)
6812 } ## end sub set_list
6813
6814 =head2 get_list
6815
6816 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6817 back, and then pull VAR_0, VAR_1. etc. back out.
6818
6819 =cut
6820
6821 sub get_list {
6822     my $stem = shift;
6823     my @list;
6824     my $n = delete $ENV{"${stem}_n"};
6825     my $val;
6826     for my $i ( 0 .. $n - 1 ) {
6827         $val = delete $ENV{"${stem}_$i"};
6828         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6829         push @list, $val;
6830     }
6831     @list;
6832 } ## end sub get_list
6833
6834 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6835
6836 =head2 catch()
6837
6838 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6839 set an already-existing global scalar variable to a constant value. This
6840 avoids allocating any memory possibly in the middle of something that will
6841 get all confused if we do, particularly under I<unsafe signals>.
6842
6843 =cut
6844
6845 sub catch {
6846     $signal = 1;
6847     return;    # Put nothing on the stack - malloc/free land!
6848 }
6849
6850 =head2 C<warn()>
6851
6852 C<warn> emits a warning, by joining together its arguments and printing
6853 them, with couple of fillips.
6854
6855 If the composited message I<doesn't> end with a newline, we automatically
6856 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6857 to be set to the filehandle to be used to output warnings; it makes no
6858 assumptions about what filehandles are available.
6859
6860 =cut
6861
6862 sub warn {
6863     my ($msg) = join( "", @_ );
6864     $msg .= ": $!\n" unless $msg =~ /\n$/;
6865     local $\ = '';
6866     print $OUT $msg;
6867 } ## end sub warn
6868
6869 =head1 INITIALIZATION TTY SUPPORT
6870
6871 =head2 C<reset_IN_OUT>
6872
6873 This routine handles restoring the debugger's input and output filehandles
6874 after we've tried and failed to move them elsewhere.  In addition, it assigns
6875 the debugger's output filehandle to $LINEINFO if it was already open there.
6876
6877 =cut
6878
6879 sub reset_IN_OUT {
6880     my $switch_li = $LINEINFO eq $OUT;
6881
6882     # If there's a term and it's able to get a new tty, try to get one.
6883     if ( $term and $term->Features->{newTTY} ) {
6884         ( $IN, $OUT ) = ( shift, shift );
6885         $term->newTTY( $IN, $OUT );
6886     }
6887
6888     # This term can't get a new tty now. Better luck later.
6889     elsif ($term) {
6890         &warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
6891     }
6892
6893     # Set the filehndles up as they were.
6894     else {
6895         ( $IN, $OUT ) = ( shift, shift );
6896     }
6897
6898     # Unbuffer the output filehandle.
6899     my $o = select $OUT;
6900     $| = 1;
6901     select $o;
6902
6903     # Point LINEINFO to the same output filehandle if it was there before.
6904     $LINEINFO = $OUT if $switch_li;
6905 } ## end sub reset_IN_OUT
6906
6907 =head1 OPTION SUPPORT ROUTINES
6908
6909 The following routines are used to process some of the more complicated
6910 debugger options.
6911
6912 =head2 C<TTY>
6913
6914 Sets the input and output filehandles to the specified files or pipes.
6915 If the terminal supports switching, we go ahead and do it. If not, and
6916 there's already a terminal in place, we save the information to take effect
6917 on restart.
6918
6919 If there's no terminal yet (for instance, during debugger initialization),
6920 we go ahead and set C<$console> and C<$tty> to the file indicated.
6921
6922 =cut
6923
6924 sub TTY {
6925
6926     if ( @_ and $term and $term->Features->{newTTY} ) {
6927
6928         # This terminal supports switching to a new TTY.
6929         # Can be a list of two files, or on string containing both names,
6930         # comma-separated.
6931         # XXX Should this perhaps be an assignment from @_?
6932         my ( $in, $out ) = shift;
6933         if ( $in =~ /,/ ) {
6934
6935             # Split list apart if supplied.
6936             ( $in, $out ) = split /,/, $in, 2;
6937         }
6938         else {
6939
6940             # Use the same file for both input and output.
6941             $out = $in;
6942         }
6943
6944         # Open file onto the debugger's filehandles, if you can.
6945         open IN,  $in     or die "cannot open '$in' for read: $!";
6946         open OUT, ">$out" or die "cannot open '$out' for write: $!";
6947
6948         # Swap to the new filehandles.
6949         reset_IN_OUT( \*IN, \*OUT );
6950
6951         # Save the setting for later.
6952         return $tty = $in;
6953     } ## end if (@_ and $term and $term...
6954
6955     # Terminal doesn't support new TTY, or doesn't support readline.
6956     # Can't do it now, try restarting.
6957     &warn("Too late to set TTY, enabled on next 'R'!\n") if $term and @_;
6958
6959     # Useful if done through PERLDB_OPTS:
6960     $console = $tty = shift if @_;
6961
6962     # Return whatever the TTY is.
6963     $tty or $console;
6964 } ## end sub TTY
6965
6966 =head2 C<noTTY>
6967
6968 Sets the C<$notty> global, controlling whether or not the debugger tries to
6969 get a terminal to read from. If called after a terminal is already in place,
6970 we save the value to use it if we're restarted.
6971
6972 =cut
6973
6974 sub noTTY {
6975     if ($term) {
6976         &warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
6977     }
6978     $notty = shift if @_;
6979     $notty;
6980 } ## end sub noTTY
6981
6982 =head2 C<ReadLine>
6983
6984 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
6985 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
6986 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
6987 the value in case a restart is done so we can change it then.
6988
6989 =cut
6990
6991 sub ReadLine {
6992     if ($term) {
6993         &warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
6994     }
6995     $rl = shift if @_;
6996     $rl;
6997 } ## end sub ReadLine
6998
6999 =head2 C<RemotePort>
7000
7001 Sets the port that the debugger will try to connect to when starting up.
7002 If the terminal's already been set up, we can't do it, but we remember the
7003 setting in case the user does a restart.
7004
7005 =cut
7006
7007 sub RemotePort {
7008     if ($term) {
7009         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7010     }
7011     $remoteport = shift if @_;
7012     $remoteport;
7013 } ## end sub RemotePort
7014
7015 =head2 C<tkRunning>
7016
7017 Checks with the terminal to see if C<Tk> is running, and returns true or
7018 false. Returns false if the current terminal doesn't support C<readline>.
7019
7020 =cut
7021
7022 sub tkRunning {
7023     if ( ${ $term->Features }{tkRunning} ) {
7024         return $term->tkRunning(@_);
7025     }
7026     else {
7027         local $\ = '';
7028         print $OUT "tkRunning not supported by current ReadLine package.\n";
7029         0;
7030     }
7031 } ## end sub tkRunning
7032
7033 =head2 C<NonStop>
7034
7035 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7036 debugger remembers the setting in case you restart, though.
7037
7038 =cut
7039
7040 sub NonStop {
7041     if ($term) {
7042         &warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7043           if @_;
7044     }
7045     $runnonstop = shift if @_;
7046     $runnonstop;
7047 } ## end sub NonStop
7048
7049 sub DollarCaretP {
7050     if ($term) {
7051         &warn("Some flag changes could not take effect until next 'R'!\n")
7052           if @_;
7053     }
7054     $^P = parse_DollarCaretP_flags(shift) if @_;
7055     expand_DollarCaretP_flags($^P);
7056 }
7057
7058 =head2 C<pager>
7059
7060 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7061 there already.
7062
7063 =cut
7064
7065 sub pager {
7066     if (@_) {
7067         $pager = shift;
7068         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7069     }
7070     $pager;
7071 } ## end sub pager
7072
7073 =head2 C<shellBang>
7074
7075 Sets the shell escape command, and generates a printable copy to be used
7076 in the help.
7077
7078 =cut
7079
7080 sub shellBang {
7081
7082     # If we got an argument, meta-quote it, and add '\b' if it
7083     # ends in a word character.
7084     if (@_) {
7085         $sh = quotemeta shift;
7086         $sh .= "\\b" if $sh =~ /\w$/;
7087     }
7088
7089     # Generate the printable version for the help:
7090     $psh = $sh;    # copy it
7091     $psh =~ s/\\b$//;        # Take off trailing \b if any
7092     $psh =~ s/\\(.)/$1/g;    # De-escape
7093     $psh;                    # return the printable version
7094 } ## end sub shellBang
7095
7096 =head2 C<ornaments>
7097
7098 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7099 was passed as the argument. (This means you can't override the terminal's
7100 ornaments.)
7101
7102 =cut
7103
7104 sub ornaments {
7105     if ( defined $term ) {
7106
7107         # We don't want to show warning backtraces, but we do want die() ones.
7108         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
7109
7110         # No ornaments if the terminal doesn't support them.
7111         return '' unless $term->Features->{ornaments};
7112         eval { $term->ornaments(@_) } || '';
7113     }
7114
7115     # Use what was passed in if we can't determine it ourselves.
7116     else {
7117         $ornaments = shift;
7118     }
7119 } ## end sub ornaments
7120
7121 =head2 C<recallCommand>
7122
7123 Sets the recall command, and builds a printable version which will appear in
7124 the help text.
7125
7126 =cut
7127
7128 sub recallCommand {
7129
7130     # If there is input, metaquote it. Add '\b' if it ends with a word
7131     # character.
7132     if (@_) {
7133         $rc = quotemeta shift;
7134         $rc .= "\\b" if $rc =~ /\w$/;
7135     }
7136
7137     # Build it into a printable version.
7138     $prc = $rc;    # Copy it
7139     $prc =~ s/\\b$//;        # Remove trailing \b
7140     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7141     $prc;                    # Return the printable version
7142 } ## end sub recallCommand
7143
7144 =head2 C<LineInfo> - where the line number information goes
7145
7146 Called with no arguments, returns the file or pipe that line info should go to.
7147
7148 Called with an argument (a file or a pipe), it opens that onto the
7149 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7150 file or pipe again to the caller.
7151
7152 =cut
7153
7154 sub LineInfo {
7155     return $lineinfo unless @_;
7156     $lineinfo = shift;
7157
7158     #  If this is a valid "thing to be opened for output", tack a
7159     # '>' onto the front.
7160     my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7161
7162     # If this is a pipe, the stream points to a slave editor.
7163     $slave_editor = ( $stream =~ /^\|/ );
7164
7165     # Open it up and unbuffer it.
7166     open( LINEINFO, "$stream" ) || &warn("Cannot open '$stream' for write");
7167     $LINEINFO = \*LINEINFO;
7168     my $save = select($LINEINFO);
7169     $| = 1;
7170     select($save);
7171
7172     # Hand the file or pipe back again.
7173     $lineinfo;
7174 } ## end sub LineInfo
7175
7176 =head1 COMMAND SUPPORT ROUTINES
7177
7178 These subroutines provide functionality for various commands.
7179
7180 =head2 C<list_modules>
7181
7182 For the C<M> command: list modules loaded and their versions.
7183 Essentially just runs through the keys in %INC, picks each package's
7184 C<$VERSION> variable, gets the file name, and formats the information
7185 for output.
7186
7187 =cut
7188
7189 sub list_modules {    # versions
7190     my %version;
7191     my $file;
7192
7193     # keys are the "as-loaded" name, values are the fully-qualified path
7194     # to the file itself.
7195     for ( keys %INC ) {
7196         $file = $_;                                # get the module name
7197         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7198         s,/,::,g;                                  # change '/' to '::'
7199         s/^perl5db$/DB/;                           # Special case: debugger
7200                                                    # moves to package DB
7201         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7202
7203         # If the package has a $VERSION package global (as all good packages
7204         # should!) decode it and save as partial message.
7205         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
7206         if ( defined $pkg_version ) {
7207             $version{$file} = "$pkg_version from ";
7208         }
7209
7210         # Finish up the message with the file the package came from.
7211         $version{$file} .= $INC{$file};
7212     } ## end for (keys %INC)
7213
7214     # Hey, dumpit() formats a hash nicely, so why not use it?
7215     dumpit( $OUT, \%version );
7216 } ## end sub list_modules
7217
7218 =head2 C<sethelp()>
7219
7220 Sets up the monster string used to format and print the help.
7221
7222 =head3 HELP MESSAGE FORMAT
7223
7224 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7225 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7226 easy to parse and portable, but which still allows the help to be a little
7227 nicer than just plain text.
7228
7229 Essentially, you define the command name (usually marked up with C<< B<> >>
7230 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7231 newline. The descriptive text can also be marked up in the same way. If you
7232 need to continue the descriptive text to another line, start that line with
7233 just tabs and then enter the marked-up text.
7234
7235 If you are modifying the help text, I<be careful>. The help-string parser is
7236 not very sophisticated, and if you don't follow these rules it will mangle the
7237 help beyond hope until you fix the string.
7238
7239 =cut
7240
7241 use vars qw($pre580_help);
7242 use vars qw($pre580_summary);
7243
7244 sub sethelp {
7245
7246     # XXX: make sure there are tabs between the command and explanation,
7247     #      or print_help will screw up your formatting if you have
7248     #      eeevil ornaments enabled.  This is an insane mess.
7249
7250     $help = "
7251 Help is currently only available for the new 5.8 command set.
7252 No help is available for the old command set.
7253 We assume you know what you're doing if you switch to it.
7254
7255 B<T>        Stack trace.
7256 B<s> [I<expr>]    Single step [in I<expr>].
7257 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7258 <B<CR>>        Repeat last B<n> or B<s> command.
7259 B<r>        Return from current subroutine.
7260 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7261         at the specified position.
7262 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7263 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7264 B<l> I<line>        List single I<line>.
7265 B<l> I<subname>    List first window of lines from subroutine.
7266 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7267 B<l>        List next window of lines.
7268 B<->        List previous window of lines.
7269 B<v> [I<line>]    View window around I<line>.
7270 B<.>        Return to the executed line.
7271 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7272         I<filename> may be either the full name of the file, or a regular
7273         expression matching the full file name:
7274         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7275         Evals (with saved bodies) are considered to be filenames:
7276         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7277         (in the order of execution).
7278 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7279 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7280 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7281 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7282 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
7283 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7284 B<b>        Sets breakpoint on current line)
7285 B<b> [I<line>] [I<condition>]
7286         Set breakpoint; I<line> defaults to the current execution line;
7287         I<condition> breaks if it evaluates to true, defaults to '1'.
7288 B<b> I<subname> [I<condition>]
7289         Set breakpoint at first line of subroutine.
7290 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7291 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7292 B<b> B<postpone> I<subname> [I<condition>]
7293         Set breakpoint at first line of subroutine after
7294         it is compiled.
7295 B<b> B<compile> I<subname>
7296         Stop after the subroutine is compiled.
7297 B<B> [I<line>]    Delete the breakpoint for I<line>.
7298 B<B> I<*>             Delete all breakpoints.
7299 B<a> [I<line>] I<command>
7300         Set an action to be done before the I<line> is executed;
7301         I<line> defaults to the current execution line.
7302         Sequence is: check for breakpoint/watchpoint, print line
7303         if necessary, do action, prompt user if necessary,
7304         execute line.
7305 B<a>        Does nothing
7306 B<A> [I<line>]    Delete the action for I<line>.
7307 B<A> I<*>             Delete all actions.
7308 B<w> I<expr>        Add a global watch-expression.
7309 B<w>             Does nothing
7310 B<W> I<expr>        Delete a global watch-expression.
7311 B<W> I<*>             Delete all watch-expressions.
7312 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7313         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7314 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7315 B<x> I<expr>        Evals expression in list context, dumps the result.
7316 B<m> I<expr>        Evals expression in list context, prints methods callable
7317         on the first element of the result.
7318 B<m> I<class>        Prints methods callable via the given class.
7319 B<M>        Show versions of loaded modules.
7320 B<i> I<class>       Prints nested parents of given class.
7321 B<e>         Display current thread id.
7322 B<E>         Display all thread ids the current one will be identified: <n>.
7323 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7324
7325 B<<> ?            List Perl commands to run before each prompt.
7326 B<<> I<expr>        Define Perl command to run before each prompt.
7327 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7328 B<< *>                Delete the list of perl commands to run before each prompt.
7329 B<>> ?            List Perl commands to run after each prompt.
7330 B<>> I<expr>        Define Perl command to run after each prompt.
7331 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7332 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7333 B<{> I<db_command>    Define debugger command to run before each prompt.
7334 B<{> ?            List debugger commands to run before each prompt.
7335 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7336 B<{ *>             Delete the list of debugger commands to run before each prompt.
7337 B<$prc> I<number>    Redo a previous command (default previous command).
7338 B<$prc> I<-number>    Redo number'th-to-last command.
7339 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7340         See 'B<O> I<recallCommand>' too.
7341 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7342       . (
7343         $rc eq $sh
7344         ? ""
7345         : "
7346 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7347       ) . "
7348         See 'B<O> I<shellBang>' too.
7349 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7350 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7351 B<rerun>           Rerun session to current position.
7352 B<rerun> I<n>         Rerun session to numbered command.
7353 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7354 B<H> I<-number>    Display last number commands (default all).
7355 B<H> I<*>          Delete complete history.
7356 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7357 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7358 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
7359 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7360 I<command>        Execute as a perl statement in current package.
7361 B<R>        Pure-man-restart of debugger, some of debugger state
7362         and command-line options may be lost.
7363         Currently the following settings are preserved:
7364         history, breakpoints and actions, debugger B<O>ptions
7365         and the following command-line options: I<-w>, I<-I>, I<-e>.
7366
7367 B<o> [I<opt>] ...    Set boolean option to true
7368 B<o> [I<opt>B<?>]    Query options
7369 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7370         Set options.  Use quotes if spaces in value.
7371     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7372     I<pager>            program for output of \"|cmd\";
7373     I<tkRunning>            run Tk while prompting (with ReadLine);
7374     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7375     I<inhibit_exit>        Allows stepping off the end of the script.
7376     I<ImmediateStop>        Debugger should stop as early as possible.
7377     I<RemotePort>            Remote hostname:port for remote debugging
7378   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7379     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7380     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7381     I<globPrint>             whether to print contents of globs;
7382     I<DumpDBFiles>         dump arrays holding debugged files;
7383     I<DumpPackages>         dump symbol tables of packages;
7384     I<DumpReused>             dump contents of \"reused\" addresses;
7385     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7386     I<bareStringify>         Do not print the overload-stringified value;
7387   Other options include:
7388     I<PrintRet>        affects printing of return value after B<r> command,
7389     I<frame>        affects printing messages on subroutine entry/exit.
7390     I<AutoTrace>    affects printing messages on possible breaking points.
7391     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7392     I<ornaments>     affects screen appearance of the command line.
7393     I<CreateTTY>     bits control attempts to create a new TTY on events:
7394             1: on fork()    2: debugger is started inside debugger
7395             4: on startup
7396     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7397     You can put additional initialization options I<TTY>, I<noTTY>,
7398     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7399     B<R> after you set them).
7400
7401 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7402 B<h>        Summary of debugger commands.
7403 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7404 B<h h>        Long help for debugger commands
7405 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7406         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7407         Set B<\$DB::doccmd> to change viewer.
7408
7409 Type '|h h' for a paged display if this was too hard to read.
7410
7411 ";    # Fix balance of vi % matching: }}}}
7412
7413     #  note: tabs in the following section are not-so-helpful
7414     $summary = <<"END_SUM";
7415 I<List/search source lines:>               I<Control script execution:>
7416   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7417   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7418   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7419   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7420   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7421   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7422 I<Debugger controls:>                        B<L>           List break/watch/actions
7423   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
7424   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7425   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7426   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7427   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7428   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7429   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7430   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7431   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7432 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7433   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7434   B<p> I<expr>         Print expression (uses script's current package).
7435   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7436   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7437   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7438   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7439   B<e>     Display thread id     B<E> Display all thread ids.
7440 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7441 END_SUM
7442
7443     # ')}}; # Fix balance of vi % matching
7444
7445     # and this is really numb...
7446     $pre580_help = "
7447 B<T>        Stack trace.
7448 B<s> [I<expr>]    Single step [in I<expr>].
7449 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7450 B<CR>>        Repeat last B<n> or B<s> command.
7451 B<r>        Return from current subroutine.
7452 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7453         at the specified position.
7454 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7455 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7456 B<l> I<line>        List single I<line>.
7457 B<l> I<subname>    List first window of lines from subroutine.
7458 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7459 B<l>        List next window of lines.
7460 B<->        List previous window of lines.
7461 B<w> [I<line>]    List window around I<line>.
7462 B<.>        Return to the executed line.
7463 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7464         I<filename> may be either the full name of the file, or a regular
7465         expression matching the full file name:
7466         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7467         Evals (with saved bodies) are considered to be filenames:
7468         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7469         (in the order of execution).
7470 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7471 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7472 B<L>        List all breakpoints and actions.
7473 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7474 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
7475 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7476 B<b> [I<line>] [I<condition>]
7477         Set breakpoint; I<line> defaults to the current execution line;
7478         I<condition> breaks if it evaluates to true, defaults to '1'.
7479 B<b> I<subname> [I<condition>]
7480         Set breakpoint at first line of subroutine.
7481 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7482 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7483 B<b> B<postpone> I<subname> [I<condition>]
7484         Set breakpoint at first line of subroutine after
7485         it is compiled.
7486 B<b> B<compile> I<subname>
7487         Stop after the subroutine is compiled.
7488 B<d> [I<line>]    Delete the breakpoint for I<line>.
7489 B<D>        Delete all breakpoints.
7490 B<a> [I<line>] I<command>
7491         Set an action to be done before the I<line> is executed;
7492         I<line> defaults to the current execution line.
7493         Sequence is: check for breakpoint/watchpoint, print line
7494         if necessary, do action, prompt user if necessary,
7495         execute line.
7496 B<a> [I<line>]    Delete the action for I<line>.
7497 B<A>        Delete all actions.
7498 B<W> I<expr>        Add a global watch-expression.
7499 B<W>        Delete all watch-expressions.
7500 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7501         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7502 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7503 B<x> I<expr>        Evals expression in list context, dumps the result.
7504 B<m> I<expr>        Evals expression in list context, prints methods callable
7505         on the first element of the result.
7506 B<m> I<class>        Prints methods callable via the given class.
7507
7508 B<<> ?            List Perl commands to run before each prompt.
7509 B<<> I<expr>        Define Perl command to run before each prompt.
7510 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7511 B<>> ?            List Perl commands to run after each prompt.
7512 B<>> I<expr>        Define Perl command to run after each prompt.
7513 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7514 B<{> I<db_command>    Define debugger command to run before each prompt.
7515 B<{> ?            List debugger commands to run before each prompt.
7516 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7517 B<$prc> I<number>    Redo a previous command (default previous command).
7518 B<$prc> I<-number>    Redo number'th-to-last command.
7519 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7520         See 'B<O> I<recallCommand>' too.
7521 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7522       . (
7523         $rc eq $sh
7524         ? ""
7525         : "
7526 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7527       ) . "
7528         See 'B<O> I<shellBang>' too.
7529 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7530 B<H> I<-number>    Display last number commands (default all).
7531 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7532 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7533 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7534 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7535 I<command>        Execute as a perl statement in current package.
7536 B<v>        Show versions of loaded modules.
7537 B<R>        Pure-man-restart of debugger, some of debugger state
7538         and command-line options may be lost.
7539         Currently the following settings are preserved:
7540         history, breakpoints and actions, debugger B<O>ptions
7541         and the following command-line options: I<-w>, I<-I>, I<-e>.
7542
7543 B<O> [I<opt>] ...    Set boolean option to true
7544 B<O> [I<opt>B<?>]    Query options
7545 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7546         Set options.  Use quotes if spaces in value.
7547     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7548     I<pager>            program for output of \"|cmd\";
7549     I<tkRunning>            run Tk while prompting (with ReadLine);
7550     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7551     I<inhibit_exit>        Allows stepping off the end of the script.
7552     I<ImmediateStop>        Debugger should stop as early as possible.
7553     I<RemotePort>            Remote hostname:port for remote debugging
7554   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7555     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7556     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7557     I<globPrint>             whether to print contents of globs;
7558     I<DumpDBFiles>         dump arrays holding debugged files;
7559     I<DumpPackages>         dump symbol tables of packages;
7560     I<DumpReused>             dump contents of \"reused\" addresses;
7561     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7562     I<bareStringify>         Do not print the overload-stringified value;
7563   Other options include:
7564     I<PrintRet>        affects printing of return value after B<r> command,
7565     I<frame>        affects printing messages on subroutine entry/exit.
7566     I<AutoTrace>    affects printing messages on possible breaking points.
7567     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7568     I<ornaments>     affects screen appearance of the command line.
7569     I<CreateTTY>     bits control attempts to create a new TTY on events:
7570             1: on fork()    2: debugger is started inside debugger
7571             4: on startup
7572     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7573     You can put additional initialization options I<TTY>, I<noTTY>,
7574     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7575     B<R> after you set them).
7576
7577 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7578 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7579 B<h h>        Summary of debugger commands.
7580 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7581         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7582         Set B<\$DB::doccmd> to change viewer.
7583
7584 Type '|h' for a paged display if this was too hard to read.
7585
7586 ";    # Fix balance of vi % matching: }}}}
7587
7588     #  note: tabs in the following section are not-so-helpful
7589     $pre580_summary = <<"END_SUM";
7590 I<List/search source lines:>               I<Control script execution:>
7591   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7592   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7593   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7594   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7595   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7596   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7597 I<Debugger controls:>                        B<L>           List break/watch/actions
7598   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7599   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7600   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7601   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7602   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7603   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7604   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7605   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7606 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7607   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7608   B<p> I<expr>         Print expression (uses script's current package).
7609   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7610   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7611   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7612   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7613 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7614 END_SUM
7615
7616     # ')}}; # Fix balance of vi % matching
7617
7618 } ## end sub sethelp
7619
7620 =head2 C<print_help()>
7621
7622 Most of what C<print_help> does is just text formatting. It finds the
7623 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7624 terminal control characters to simulate them (courtesy of
7625 C<Term::ReadLine::TermCap>).
7626
7627 =cut
7628
7629 sub print_help {
7630     local $_ = shift;
7631
7632     # Restore proper alignment destroyed by eeevil I<> and B<>
7633     # ornaments: A pox on both their houses!
7634     #
7635     # A help command will have everything up to and including
7636     # the first tab sequence padded into a field 16 (or if indented 20)
7637     # wide.  If it's wider than that, an extra space will be added.
7638     s{
7639         ^                       # only matters at start of line
7640           ( \040{4} | \t )*     # some subcommands are indented
7641           ( < ?                 # so <CR> works
7642             [BI] < [^\t\n] + )  # find an eeevil ornament
7643           ( \t+ )               # original separation, discarded
7644           ( .* )                # this will now start (no earlier) than
7645                                 # column 16
7646     } {
7647         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7648         my $clean = $command;
7649         $clean =~ s/[BI]<([^>]*)>/$1/g;
7650
7651         # replace with this whole string:
7652         ($leadwhite ? " " x 4 : "")
7653       . $command
7654       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7655       . $text;
7656
7657     }mgex;
7658
7659     s{                          # handle bold ornaments
7660        B < ( [^>] + | > ) >
7661     } {
7662           $Term::ReadLine::TermCap::rl_term_set[2]
7663         . $1
7664         . $Term::ReadLine::TermCap::rl_term_set[3]
7665     }gex;
7666
7667     s{                         # handle italic ornaments
7668        I < ( [^>] + | > ) >
7669     } {
7670           $Term::ReadLine::TermCap::rl_term_set[0]
7671         . $1
7672         . $Term::ReadLine::TermCap::rl_term_set[1]
7673     }gex;
7674
7675     local $\ = '';
7676     print $OUT $_;
7677 } ## end sub print_help
7678
7679 =head2 C<fix_less>
7680
7681 This routine does a lot of gyrations to be sure that the pager is C<less>.
7682 It checks for C<less> masquerading as C<more> and records the result in
7683 C<$fixed_less> so we don't have to go through doing the stats again.
7684
7685 =cut
7686
7687 use vars qw($fixed_less);
7688
7689 sub fix_less {
7690
7691     # We already know if this is set.
7692     return if $fixed_less;
7693
7694     # Pager is less for sure.
7695     my $is_less = $pager =~ /\bless\b/;
7696     if ( $pager =~ /\bmore\b/ ) {
7697
7698         # Nope, set to more. See what's out there.
7699         my @st_more = stat('/usr/bin/more');
7700         my @st_less = stat('/usr/bin/less');
7701
7702         # is it really less, pretending to be more?
7703              $is_less = @st_more
7704           && @st_less
7705           && $st_more[0] == $st_less[0]
7706           && $st_more[1] == $st_less[1];
7707     } ## end if ($pager =~ /\bmore\b/)
7708
7709     # changes environment!
7710     # 'r' added so we don't do (slow) stats again.
7711     $fixed_less = 1 if $is_less;
7712 } ## end sub fix_less
7713
7714 =head1 DIE AND WARN MANAGEMENT
7715
7716 =head2 C<diesignal>
7717
7718 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7719 to debug a debugger problem.
7720
7721 It does its best to report the error that occurred, and then forces the
7722 program, debugger, and everything to die.
7723
7724 =cut
7725
7726 sub diesignal {
7727
7728     # No entry/exit messages.
7729     local $frame = 0;
7730
7731     # No return value prints.
7732     local $doret = -2;
7733
7734     # set the abort signal handling to the default (just terminate).
7735     $SIG{'ABRT'} = 'DEFAULT';
7736
7737     # If we enter the signal handler recursively, kill myself with an
7738     # abort signal (so we just terminate).
7739     kill 'ABRT', $$ if $panic++;
7740
7741     # If we can show detailed info, do so.
7742     if ( defined &Carp::longmess ) {
7743
7744         # Don't recursively enter the warn handler, since we're carping.
7745         local $SIG{__WARN__} = '';
7746
7747         # Skip two levels before reporting traceback: we're skipping
7748         # mydie and confess.
7749         local $Carp::CarpLevel = 2;    # mydie + confess
7750
7751         # Tell us all about it.
7752         &warn( Carp::longmess("Signal @_") );
7753     }
7754
7755     # No Carp. Tell us about the signal as best we can.
7756     else {
7757         local $\ = '';
7758         print $DB::OUT "Got signal @_\n";
7759     }
7760
7761     # Drop dead.
7762     kill 'ABRT', $$;
7763 } ## end sub diesignal
7764
7765 =head2 C<dbwarn>
7766
7767 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7768 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7769
7770 =cut
7771
7772 sub dbwarn {
7773
7774     # No entry/exit trace.
7775     local $frame = 0;
7776
7777     # No return value printing.
7778     local $doret = -2;
7779
7780     # Turn off warn and die handling to prevent recursive entries to this
7781     # routine.
7782     local $SIG{__WARN__} = '';
7783     local $SIG{__DIE__}  = '';
7784
7785     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7786     # done yet), we may not be able to do a require.
7787     eval { require Carp }
7788       if defined $^S;    # If error/warning during compilation,
7789                          # require may be broken.
7790
7791     # Use the core warn() unless Carp loaded OK.
7792     CORE::warn( @_,
7793         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7794       return
7795       unless defined &Carp::longmess;
7796
7797     # Save the current values of $single and $trace, and then turn them off.
7798     my ( $mysingle, $mytrace ) = ( $single, $trace );
7799     $single = 0;
7800     $trace  = 0;
7801
7802     # We can call Carp::longmess without its being "debugged" (which we
7803     # don't want - we just want to use it!). Capture this for later.
7804     my $mess = Carp::longmess(@_);
7805
7806     # Restore $single and $trace to their original values.
7807     ( $single, $trace ) = ( $mysingle, $mytrace );
7808
7809     # Use the debugger's own special way of printing warnings to print
7810     # the stack trace message.
7811     &warn($mess);
7812 } ## end sub dbwarn
7813
7814 =head2 C<dbdie>
7815
7816 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7817 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7818 single stepping and tracing during the call to C<Carp::longmess> to avoid
7819 debugging it - we just want to use it.
7820
7821 If C<dieLevel> is zero, we let the program being debugged handle the
7822 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7823 the debugger takes over all exception handling, printing a backtrace and
7824 displaying the exception via its C<dbwarn()> routine.
7825
7826 =cut
7827
7828 sub dbdie {
7829     local $frame         = 0;
7830     local $doret         = -2;
7831     local $SIG{__DIE__}  = '';
7832     local $SIG{__WARN__} = '';
7833     my $i      = 0;
7834     my $ineval = 0;
7835     my $sub;
7836     if ( $dieLevel > 2 ) {
7837         local $SIG{__WARN__} = \&dbwarn;
7838         &warn(@_);    # Yell no matter what
7839         return;
7840     }
7841     if ( $dieLevel < 2 ) {
7842         die @_ if $^S;    # in eval propagate
7843     }
7844
7845     # The code used to check $^S to see if compilation of the current thing
7846     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7847     eval { require Carp };
7848
7849     die( @_,
7850         "\nCannot print stack trace, load with -MCarp option to see stack" )
7851       unless defined &Carp::longmess;
7852
7853     # We do not want to debug this chunk (automatic disabling works
7854     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7855     # get the stack trace from Carp::longmess (if possible), restore $signal
7856     # and $trace, and then die with the stack trace.
7857     my ( $mysingle, $mytrace ) = ( $single, $trace );
7858     $single = 0;
7859     $trace  = 0;
7860     my $mess = "@_";
7861     {
7862
7863         package Carp;    # Do not include us in the list
7864         eval { $mess = Carp::longmess(@_); };
7865     }
7866     ( $single, $trace ) = ( $mysingle, $mytrace );
7867     die $mess;
7868 } ## end sub dbdie
7869
7870 =head2 C<warnlevel()>
7871
7872 Set the C<$DB::warnLevel> variable that stores the value of the
7873 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7874 results in the debugger taking over all warning handlers. Setting
7875 C<warnLevel> to zero leaves any warning handlers set up by the program
7876 being debugged in place.
7877
7878 =cut
7879
7880 sub warnLevel {
7881     if (@_) {
7882         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
7883         $warnLevel = shift;
7884         if ($warnLevel) {
7885             $SIG{__WARN__} = \&DB::dbwarn;
7886         }
7887         elsif ($prevwarn) {
7888             $SIG{__WARN__} = $prevwarn;
7889         } else {
7890             undef $SIG{__WARN__};
7891         }
7892     } ## end if (@_)
7893     $warnLevel;
7894 } ## end sub warnLevel
7895
7896 =head2 C<dielevel>
7897
7898 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7899 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7900 zero lets you use your own C<die()> handler.
7901
7902 =cut
7903
7904 sub dieLevel {
7905     local $\ = '';
7906     if (@_) {
7907         my $prevdie = $SIG{__DIE__} unless $dieLevel;
7908         $dieLevel = shift;
7909         if ($dieLevel) {
7910
7911             # Always set it to dbdie() for non-zero values.
7912             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
7913
7914             # No longer exists, so don't try  to use it.
7915             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
7916
7917             # If we've finished initialization, mention that stack dumps
7918             # are enabled, If dieLevel is 1, we won't stack dump if we die
7919             # in an eval().
7920             print $OUT "Stack dump during die enabled",
7921               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
7922               if $I_m_init;
7923
7924             # XXX This is probably obsolete, given that diehard() is gone.
7925             print $OUT "Dump printed too.\n" if $dieLevel > 2;
7926         } ## end if ($dieLevel)
7927
7928         # Put the old one back if there was one.
7929         elsif ($prevdie) {
7930             $SIG{__DIE__} = $prevdie;
7931             print $OUT "Default die handler restored.\n";
7932         } else {
7933             undef $SIG{__DIE__};
7934             print $OUT "Die handler removed.\n";
7935         }
7936     } ## end if (@_)
7937     $dieLevel;
7938 } ## end sub dieLevel
7939
7940 =head2 C<signalLevel>
7941
7942 Number three in a series: set C<signalLevel> to zero to keep your own
7943 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
7944 takes over and handles them with C<DB::diesignal()>.
7945
7946 =cut
7947
7948 sub signalLevel {
7949     if (@_) {
7950         my $prevsegv = $SIG{SEGV} unless $signalLevel;
7951         my $prevbus  = $SIG{BUS}  unless $signalLevel;
7952         $signalLevel = shift;
7953         if ($signalLevel) {
7954             $SIG{SEGV} = \&DB::diesignal;
7955             $SIG{BUS}  = \&DB::diesignal;
7956         }
7957         else {
7958             $SIG{SEGV} = $prevsegv;
7959             $SIG{BUS}  = $prevbus;
7960         }
7961     } ## end if (@_)
7962     $signalLevel;
7963 } ## end sub signalLevel
7964
7965 =head1 SUBROUTINE DECODING SUPPORT
7966
7967 These subroutines are used during the C<x> and C<X> commands to try to
7968 produce as much information as possible about a code reference. They use
7969 L<Devel::Peek> to try to find the glob in which this code reference lives
7970 (if it does) - this allows us to actually code references which correspond
7971 to named subroutines (including those aliased via glob assignment).
7972
7973 =head2 C<CvGV_name()>
7974
7975 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
7976 via that routine. If this fails, return the reference again (when the
7977 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
7978
7979 =cut
7980
7981 sub CvGV_name {
7982     my $in   = shift;
7983     my $name = CvGV_name_or_bust($in);
7984     defined $name ? $name : $in;
7985 }
7986
7987 =head2 C<CvGV_name_or_bust> I<coderef>
7988
7989 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
7990 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
7991 find a glob for this ref.
7992
7993 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
7994
7995 =cut
7996
7997 use vars qw($skipCvGV);
7998
7999 sub CvGV_name_or_bust {
8000     my $in = shift;
8001     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8002     return unless ref $in;
8003     $in = \&$in;            # Hard reference...
8004     eval { require Devel::Peek; 1 } or return;
8005     my $gv = Devel::Peek::CvGV($in) or return;
8006     *$gv{PACKAGE} . '::' . *$gv{NAME};
8007 } ## end sub CvGV_name_or_bust
8008
8009 =head2 C<find_sub>
8010
8011 A utility routine used in various places; finds the file where a subroutine
8012 was defined, and returns that filename and a line-number range.
8013
8014 Tries to use C<@sub> first; if it can't find it there, it tries building a
8015 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8016 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8017 this way, it brute-force searches C<%sub>, checking for identical references.
8018
8019 =cut
8020
8021 sub find_sub {
8022     my $subr = shift;
8023     $sub{$subr} or do {
8024         return unless defined &$subr;
8025         my $name = CvGV_name_or_bust($subr);
8026         my $data;
8027         $data = $sub{$name} if defined $name;
8028         return $data if defined $data;
8029
8030         # Old stupid way...
8031         $subr = \&$subr;    # Hard reference
8032         my $s;
8033         for ( keys %sub ) {
8034             $s = $_, last if $subr eq \&$_;
8035         }
8036         $sub{$s} if $s;
8037       } ## end do
8038 } ## end sub find_sub
8039
8040 =head2 C<methods>
8041
8042 A subroutine that uses the utility function C<methods_via> to find all the
8043 methods in the class corresponding to the current reference and in
8044 C<UNIVERSAL>.
8045
8046 =cut
8047
8048 use vars qw(%seen);
8049
8050 sub methods {
8051
8052     # Figure out the class - either this is the class or it's a reference
8053     # to something blessed into that class.
8054     my $class = shift;
8055     $class = ref $class if ref $class;
8056
8057     local %seen;
8058
8059     # Show the methods that this class has.
8060     methods_via( $class, '', 1 );
8061
8062     # Show the methods that UNIVERSAL has.
8063     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8064 } ## end sub methods
8065
8066 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8067
8068 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8069 all the parent class methods. C<$class> is the name of the next class to
8070 try; C<$prefix> is the message prefix, which gets built up as we go up the
8071 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8072 higher in the C<@ISA> tree, 0 if we should stop.
8073
8074 =cut
8075
8076 sub methods_via {
8077
8078     # If we've processed this class already, just quit.
8079     my $class = shift;
8080     return if $seen{$class}++;
8081
8082     # This is a package that is contributing the methods we're about to print.
8083     my $prefix  = shift;
8084     my $prepend = $prefix ? "via $prefix: " : '';
8085     my @to_print;
8086
8087     # Extract from all the symbols in this class.
8088     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8089     while (my ($name, $glob) = each %$class_ref) {
8090         # references directly in the symbol table are Proxy Constant
8091         # Subroutines, and are by their very nature defined
8092         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8093         # to a subroutine reference, which can be tested by defined.
8094         # $glob might also be the value -1  (from sub foo;)
8095         # or (say) '$$' (from sub foo ($$);)
8096         # \$glob will be SCALAR in both cases.
8097         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8098             && !$seen{$name}++) {
8099             push @to_print, "$prepend$name\n";
8100         }
8101     }
8102
8103     {
8104         local $\ = '';
8105         local $, = '';
8106         print $DB::OUT $_ foreach sort @to_print;
8107     }
8108
8109     # If the $crawl_upward argument is false, just quit here.
8110     return unless shift;
8111
8112     # $crawl_upward true: keep going up the tree.
8113     # Find all the classes this one is a subclass of.
8114     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8115     for my $name ( @$class_ISA_ref ) {
8116
8117         # Set up the new prefix.
8118         $prepend = $prefix ? $prefix . " -> $name" : $name;
8119
8120         # Crawl up the tree and keep trying to crawl up.
8121         methods_via( $name, $prepend, 1 );
8122     }
8123 } ## end sub methods_via
8124
8125 =head2 C<setman> - figure out which command to use to show documentation
8126
8127 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8128
8129 =cut
8130
8131 sub setman {
8132     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8133       ? "man"         # O Happy Day!
8134       : "perldoc";    # Alas, poor unfortunates
8135 } ## end sub setman
8136
8137 =head2 C<runman> - run the appropriate command to show documentation
8138
8139 Accepts a man page name; runs the appropriate command to display it (set up
8140 during debugger initialization). Uses C<DB::system> to avoid mucking up the
8141 program's STDIN and STDOUT.
8142
8143 =cut
8144
8145 sub runman {
8146     my $page = shift;
8147     unless ($page) {
8148         &system("$doccmd $doccmd");
8149         return;
8150     }
8151
8152     # this way user can override, like with $doccmd="man -Mwhatever"
8153     # or even just "man " to disable the path check.
8154     unless ( $doccmd eq 'man' ) {
8155         &system("$doccmd $page");
8156         return;
8157     }
8158
8159     $page = 'perl' if lc($page) eq 'help';
8160
8161     require Config;
8162     my $man1dir = $Config::Config{'man1dir'};
8163     my $man3dir = $Config::Config{'man3dir'};
8164     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8165     my $manpath = '';
8166     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8167     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8168     chop $manpath if $manpath;
8169
8170     # harmless if missing, I figure
8171     my $oldpath = $ENV{MANPATH};
8172     $ENV{MANPATH} = $manpath if $manpath;
8173     my $nopathopt = $^O =~ /dunno what goes here/;
8174     if (
8175         CORE::system(
8176             $doccmd,
8177
8178             # I just *know* there are men without -M
8179             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8180             split ' ', $page
8181         )
8182       )
8183     {
8184         unless ( $page =~ /^perl\w/ ) {
8185 # do it this way because its easier to slurp in to keep up to date - clunky though.
8186 my @pods = qw(
8187     5004delta
8188     5005delta
8189     561delta
8190     56delta
8191     570delta
8192     571delta
8193     572delta
8194     573delta
8195     58delta
8196     581delta
8197     582delta
8198     583delta
8199     584delta
8200     590delta
8201     591delta
8202     592delta
8203     aix
8204     amiga
8205     apio
8206     api
8207     artistic
8208     beos
8209     book
8210     boot
8211     bot
8212     bs2000
8213     call
8214     ce
8215     cheat
8216     clib
8217     cn
8218     compile
8219     cygwin
8220     data
8221     dbmfilter
8222     debguts
8223     debtut
8224     debug
8225     delta
8226     dgux
8227     diag
8228     doc
8229     dos
8230     dsc
8231     ebcdic
8232     embed
8233     epoc
8234     faq1
8235     faq2
8236     faq3
8237     faq4
8238     faq5
8239     faq6
8240     faq7
8241     faq8
8242     faq9
8243     faq
8244     filter
8245     fork
8246     form
8247     freebsd
8248     func
8249     gpl
8250     guts
8251     hack
8252     hist
8253     hpux
8254     hurd
8255     intern
8256     intro
8257     iol
8258     ipc
8259     irix
8260     jp
8261     ko
8262     lexwarn
8263     locale
8264     lol
8265     macos
8266     macosx
8267     modinstall
8268     modlib
8269     mod
8270     modstyle
8271     mpeix
8272     netware
8273     newmod
8274     number
8275     obj
8276     opentut
8277     op
8278     os2
8279     os390
8280     os400
8281     packtut
8282     plan9
8283     pod
8284     podspec
8285     port
8286     qnx
8287     ref
8288     reftut
8289     re
8290     requick
8291     reref
8292     retut
8293     run
8294     sec
8295     solaris
8296     style
8297     sub
8298     syn
8299     thrtut
8300     tie
8301     toc
8302     todo
8303     tooc
8304     toot
8305     trap
8306     tru64
8307     tw
8308     unicode
8309     uniintro
8310     util
8311     uts
8312     var
8313     vmesa
8314     vms
8315     vos
8316     win32
8317     xs
8318     xstut
8319 );
8320             if (grep { $page eq $_ } @pods) {
8321                 $page =~ s/^/perl/;
8322                 CORE::system( $doccmd,
8323                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8324                     $page );
8325             } ## end if (grep { $page eq $_...
8326         } ## end unless ($page =~ /^perl\w/)
8327     } ## end if (CORE::system($doccmd...
8328     if ( defined $oldpath ) {
8329         $ENV{MANPATH} = $manpath;
8330     }
8331     else {
8332         delete $ENV{MANPATH};
8333     }
8334 } ## end sub runman
8335
8336 #use Carp;                          # This did break, left for debugging
8337
8338 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8339
8340 Because of the way the debugger interface to the Perl core is designed, any
8341 debugger package globals that C<DB::sub()> requires have to be defined before
8342 any subroutines can be called. These are defined in the second C<BEGIN> block.
8343
8344 This block sets things up so that (basically) the world is sane
8345 before the debugger starts executing. We set up various variables that the
8346 debugger has to have set up before the Perl core starts running:
8347
8348 =over 4
8349
8350 =item *
8351
8352 The debugger's own filehandles (copies of STD and STDOUT for now).
8353
8354 =item *
8355
8356 Characters for shell escapes, the recall command, and the history command.
8357
8358 =item *
8359
8360 The maximum recursion depth.
8361
8362 =item *
8363
8364 The size of a C<w> command's window.
8365
8366 =item *
8367
8368 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8369
8370 =item *
8371
8372 The fact that we're not in a sub at all right now.
8373
8374 =item *
8375
8376 The default SIGINT handler for the debugger.
8377
8378 =item *
8379
8380 The appropriate value of the flag in C<$^D> that says the debugger is running
8381
8382 =item *
8383
8384 The current debugger recursion level
8385
8386 =item *
8387
8388 The list of postponed items and the C<$single> stack (XXX define this)
8389
8390 =item *
8391
8392 That we want no return values and no subroutine entry/exit trace.
8393
8394 =back
8395
8396 =cut
8397
8398 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8399
8400 use vars qw($db_stop);
8401
8402 BEGIN {    # This does not compile, alas. (XXX eh?)
8403     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8404     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8405
8406     # Define characters used by command parsing.
8407     $sh       = '!';      # Shell escape (does not work)
8408     $rc       = ',';      # Recall command (does not work)
8409     @hist     = ('?');    # Show history (does not work)
8410     @truehist = ();       # Can be saved for replay (per session)
8411
8412     # This defines the point at which you get the 'deep recursion'
8413     # warning. It MUST be defined or the debugger will not load.
8414     $deep = 100;
8415
8416     # Number of lines around the current one that are shown in the
8417     # 'w' command.
8418     $window = 10;
8419
8420     # How much before-the-current-line context the 'v' command should
8421     # use in calculating the start of the window it will display.
8422     $preview = 3;
8423
8424     # We're not in any sub yet, but we need this to be a defined value.
8425     $sub = '';
8426
8427     # Set up the debugger's interrupt handler. It simply sets a flag
8428     # ($signal) that DB::DB() will check before each command is executed.
8429     $SIG{INT} = \&DB::catch;
8430
8431     # The following lines supposedly, if uncommented, allow the debugger to
8432     # debug itself. Perhaps we can try that someday.
8433     # This may be enabled to debug debugger:
8434     #$warnLevel = 1 unless defined $warnLevel;
8435     #$dieLevel = 1 unless defined $dieLevel;
8436     #$signalLevel = 1 unless defined $signalLevel;
8437
8438     # This is the flag that says "a debugger is running, please call
8439     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8440     # execute anything in the user's context, because we always want to
8441     # get control back.
8442     $db_stop = 0;          # Compiler warning ...
8443     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8444
8445     # This variable records how many levels we're nested in debugging. Used
8446     # Used in the debugger prompt, and in determining whether it's all over or
8447     # not.
8448     $level = 0;            # Level of recursive debugging
8449
8450     # "Triggers bug (?) in perl if we postpone this until runtime."
8451     # XXX No details on this yet, or whether we should fix the bug instead
8452     # of work around it. Stay tuned.
8453     @stack = (0);
8454
8455     # Used to track the current stack depth using the auto-stacked-variable
8456     # trick.
8457     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8458
8459     # Don't print return values on exiting a subroutine.
8460     $doret = -2;
8461
8462     # No extry/exit tracing.
8463     $frame = 0;
8464
8465 } ## end BEGIN
8466
8467 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8468
8469 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8470
8471 =head2 db_complete
8472
8473 C<readline> support - adds command completion to basic C<readline>.
8474
8475 Returns a list of possible completions to C<readline> when invoked. C<readline>
8476 will print the longest common substring following the text already entered.
8477
8478 If there is only a single possible completion, C<readline> will use it in full.
8479
8480 This code uses C<map> and C<grep> heavily to create lists of possible
8481 completion. Think LISP in this section.
8482
8483 =cut
8484
8485 sub db_complete {
8486
8487     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8488     # $text is the text to be completed.
8489     # $line is the incoming line typed by the user.
8490     # $start is the start of the text to be completed in the incoming line.
8491     my ( $text, $line, $start ) = @_;
8492
8493     # Save the initial text.
8494     # The search pattern is current package, ::, extract the next qualifier
8495     # Prefix and pack are set to undef.
8496     my ( $itext, $search, $prefix, $pack ) =
8497       ( $text, "^\Q${package}::\E([^:]+)\$" );
8498
8499 =head3 C<b postpone|compile>
8500
8501 =over 4
8502
8503 =item *
8504
8505 Find all the subroutines that might match in this package
8506
8507 =item *
8508
8509 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8510
8511 =item *
8512
8513 Include all the rest of the subs that are known
8514
8515 =item *
8516
8517 C<grep> out the ones that match the text we have so far
8518
8519 =item *
8520
8521 Return this as the list of possible completions
8522
8523 =back
8524
8525 =cut
8526
8527     return sort grep /^\Q$text/, ( keys %sub ),
8528       qw(postpone load compile),    # subroutines
8529       ( map { /$search/ ? ($1) : () } keys %sub )
8530       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8531
8532 =head3 C<b load>
8533
8534 Get all the possible files from C<@INC> as it currently stands and
8535 select the ones that match the text so far.
8536
8537 =cut
8538
8539     return sort grep /^\Q$text/, values %INC    # files
8540       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8541
8542 =head3  C<V> (list variable) and C<m> (list modules)
8543
8544 There are two entry points for these commands:
8545
8546 =head4 Unqualified package names
8547
8548 Get the top-level packages and grab everything that matches the text
8549 so far. For each match, recursively complete the partial packages to
8550 get all possible matching packages. Return this sorted list.
8551
8552 =cut
8553
8554     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8555       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8556       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8557
8558 =head4 Qualified package names
8559
8560 Take a partially-qualified package and find all subpackages for it
8561 by getting all the subpackages for the package so far, matching all
8562 the subpackages against the text, and discarding all of them which
8563 start with 'main::'. Return this list.
8564
8565 =cut
8566
8567     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8568       grep !/^main::/, grep /^\Q$text/,
8569       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
8570       do { no strict 'refs'; keys %{ $prefix . '::' } }
8571       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8572       and $text =~ /^(.*[^:])::?(\w*)$/
8573       and $prefix = $1;
8574
8575 =head3 C<f> - switch files
8576
8577 Here, we want to get a fully-qualified filename for the C<f> command.
8578 Possibilities are:
8579
8580 =over 4
8581
8582 =item 1. The original source file itself
8583
8584 =item 2. A file from C<@INC>
8585
8586 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8587
8588 =back
8589
8590 =cut
8591
8592     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8593            # We might possibly want to switch to an eval (which has a "filename"
8594            # like '(eval 9)'), so we may need to clean up the completion text
8595            # before proceeding.
8596         $prefix = length($1) - length($text);
8597         $text   = $1;
8598
8599 =pod
8600
8601 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8602 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8603 out of C<%main::>, add the initial source file, and extract the ones that
8604 match the completion text so far.
8605
8606 =cut
8607
8608         return sort
8609           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8610           $0;
8611     } ## end if ($line =~ /^\|*f\s+(.*)/)
8612
8613 =head3 Subroutine name completion
8614
8615 We look through all of the defined subs (the keys of C<%sub>) and
8616 return both all the possible matches to the subroutine name plus
8617 all the matches qualified to the current package.
8618
8619 =cut
8620
8621     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8622         $text = substr $text, 1;
8623         $prefix = "&";
8624         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8625           (
8626             map { /$search/ ? ($1) : () }
8627               keys %sub
8628           );
8629     } ## end if ((substr $text, 0, ...
8630
8631 =head3  Scalar, array, and hash completion: partially qualified package
8632
8633 Much like the above, except we have to do a little more cleanup:
8634
8635 =cut
8636
8637     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8638
8639 =pod
8640
8641 =over 4
8642
8643 =item *
8644
8645 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8646
8647 =cut
8648
8649         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8650
8651 =pod
8652
8653 =item *
8654
8655 Figure out the prefix vs. what needs completing.
8656
8657 =cut
8658
8659         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8660         $text   = $2;
8661
8662 =pod
8663
8664 =item *
8665
8666 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8667
8668 =cut
8669
8670         my @out = map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8671           keys %$pack;
8672
8673 =pod
8674
8675 =item *
8676
8677 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8678
8679 =cut
8680
8681         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8682             return db_complete( $out[0], $line, $start );
8683         }
8684
8685         # Return the list of possibles.
8686         return sort @out;
8687
8688     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8689
8690 =pod
8691
8692 =back
8693
8694 =head3 Symbol completion: current package or package C<main>.
8695
8696 =cut
8697
8698     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8699 =pod
8700
8701 =over 4
8702
8703 =item *
8704
8705 If it's C<main>, delete main to just get C<::> leading.
8706
8707 =cut
8708
8709         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8710
8711 =pod
8712
8713 =item *
8714
8715 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8716
8717 =cut
8718
8719         $prefix = substr $text, 0, 1;
8720         $text   = substr $text, 1;
8721
8722         my @out;
8723
8724 =pod
8725
8726 =item *
8727
8728 We look for the lexical scope above DB::DB and auto-complete lexical variables
8729 if PadWalker could be loaded.
8730
8731 =cut
8732
8733         if (not $text =~ /::/ and eval { require PadWalker } ) {
8734             my $level = 1;
8735             while (1) {
8736                 my @info = caller($level);
8737                 $level++;
8738                 $level = -1, last
8739                   if not @info;
8740                 last if $info[3] eq 'DB::DB';
8741             }
8742             if ($level > 0) {
8743                 my $lexicals = PadWalker::peek_my($level);
8744                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
8745             }
8746         }
8747
8748 =pod
8749
8750 =item *
8751
8752 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8753
8754 =cut
8755
8756         push @out, map "$prefix$_", grep /^\Q$text/,
8757           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8758           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8759
8760 =item *
8761
8762 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8763
8764 =back
8765
8766 =cut
8767
8768         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8769             return db_complete( $out[0], $line, $start );
8770         }
8771
8772         # Return the list of possibles.
8773         return sort @out;
8774     } ## end if ($text =~ /^[\$@%]/)
8775
8776 =head3 Options
8777
8778 We use C<option_val()> to look up the current value of the option. If there's
8779 only a single value, we complete the command in such a way that it is a
8780 complete command for setting the option in question. If there are multiple
8781 possible values, we generate a command consisting of the option plus a trailing
8782 question mark, which, if executed, will list the current value of the option.
8783
8784 =cut
8785
8786     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8787     {    # Options after space
8788            # We look for the text to be matched in the list of possible options,
8789            # and fetch the current value.
8790         my @out = grep /^\Q$text/, @options;
8791         my $val = option_val( $out[0], undef );
8792
8793         # Set up a 'query option's value' command.
8794         my $out = '? ';
8795         if ( not defined $val or $val =~ /[\n\r]/ ) {
8796
8797             # There's really nothing else we can do.
8798         }
8799
8800         # We have a value. Create a proper option-setting command.
8801         elsif ( $val =~ /\s/ ) {
8802
8803             # XXX This may be an extraneous variable.
8804             my $found;
8805
8806             # We'll want to quote the string (because of the embedded
8807             # whtespace), but we want to make sure we don't end up with
8808             # mismatched quote characters. We try several possibilities.
8809             foreach my $l ( split //, qq/\"\'\#\|/ ) {
8810
8811                 # If we didn't find this quote character in the value,
8812                 # quote it using this quote character.
8813                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8814             }
8815         } ## end elsif ($val =~ /\s/)
8816
8817         # Don't need any quotes.
8818         else {
8819             $out = "=$val ";
8820         }
8821
8822         # If there were multiple possible values, return '? ', which
8823         # makes the command into a query command. If there was just one,
8824         # have readline append that.
8825         $rl_attribs->{completer_terminator_character} =
8826           ( @out == 1 ? $out : '? ' );
8827
8828         # Return list of possibilities.
8829         return sort @out;
8830     } ## end if ((substr $line, 0, ...
8831
8832 =head3 Filename completion
8833
8834 For entering filenames. We simply call C<readline>'s C<filename_list()>
8835 method with the completion text to get the possible completions.
8836
8837 =cut
8838
8839     return $term->filename_list($text);    # filenames
8840
8841 } ## end sub db_complete
8842
8843 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8844
8845 Functions that possibly ought to be somewhere else.
8846
8847 =head2 end_report
8848
8849 Say we're done.
8850
8851 =cut
8852
8853 sub end_report {
8854     local $\ = '';
8855     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
8856 }
8857
8858 =head2 clean_ENV
8859
8860 If we have $ini_pids, save it in the environment; else remove it from the
8861 environment. Used by the C<R> (restart) command.
8862
8863 =cut
8864
8865 sub clean_ENV {
8866     if ( defined($ini_pids) ) {
8867         $ENV{PERLDB_PIDS} = $ini_pids;
8868     }
8869     else {
8870         delete( $ENV{PERLDB_PIDS} );
8871     }
8872 } ## end sub clean_ENV
8873
8874 # PERLDBf_... flag names from perl.h
8875 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8876
8877 BEGIN {
8878     %DollarCaretP_flags = (
8879         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8880         PERLDBf_LINE      => 0x02,     # Keep line #
8881         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8882         PERLDBf_INTER     => 0x08,     # Preserve more data
8883         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8884         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8885         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8886         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8887         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8888         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8889         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
8890         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
8891     );
8892     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
8893     # doesn't need to set it. It's provided for the benefit of profilers and
8894     # other code analysers.
8895
8896     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8897 }
8898
8899 sub parse_DollarCaretP_flags {
8900     my $flags = shift;
8901     $flags =~ s/^\s+//;
8902     $flags =~ s/\s+$//;
8903     my $acu = 0;
8904     foreach my $f ( split /\s*\|\s*/, $flags ) {
8905         my $value;
8906         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8907             $value = hex $1;
8908         }
8909         elsif ( $f =~ /^(\d+)$/ ) {
8910             $value = int $1;
8911         }
8912         elsif ( $f =~ /^DEFAULT$/i ) {
8913             $value = $DollarCaretP_flags{PERLDB_ALL};
8914         }
8915         else {
8916             $f =~ /^(?:PERLDBf_)?(.*)$/i;
8917             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
8918             unless ( defined $value ) {
8919                 print $OUT (
8920                     "Unrecognized \$^P flag '$f'!\n",
8921                     "Acceptable flags are: "
8922                       . join( ', ', sort keys %DollarCaretP_flags ),
8923                     ", and hexadecimal and decimal numbers.\n"
8924                 );
8925                 return undef;
8926             }
8927         }
8928         $acu |= $value;
8929     }
8930     $acu;
8931 }
8932
8933 sub expand_DollarCaretP_flags {
8934     my $DollarCaretP = shift;
8935     my @bits         = (
8936         map {
8937             my $n = ( 1 << $_ );
8938             ( $DollarCaretP & $n )
8939               ? ( $DollarCaretP_flags_r{$n}
8940                   || sprintf( '0x%x', $n ) )
8941               : ()
8942           } 0 .. 31
8943     );
8944     return @bits ? join( '|', @bits ) : 0;
8945 }
8946
8947 =over 4
8948
8949 =item rerun
8950
8951 Rerun the current session to:
8952
8953     rerun        current position
8954
8955     rerun 4      command number 4
8956
8957     rerun -4     current command minus 4 (go back 4 steps)
8958
8959 Whether this always makes sense, in the current context is unknowable, and is
8960 in part left as a useful exercise for the reader.  This sub returns the
8961 appropriate arguments to rerun the current session.
8962
8963 =cut
8964
8965 sub rerun {
8966     my $i = shift;
8967     my @args;
8968     pop(@truehist);                      # strim
8969     unless (defined $truehist[$i]) {
8970         print "Unable to return to non-existent command: $i\n";
8971     } else {
8972         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
8973         my @temp = @truehist;            # store
8974         push(@DB::typeahead, @truehist); # saved
8975         @truehist = @hist = ();          # flush
8976         @args = &restart();              # setup
8977         &get_list("PERLDB_HIST");        # clean
8978         &set_list("PERLDB_HIST", @temp); # reset
8979     }
8980     return @args;
8981 }
8982
8983 =item restart
8984
8985 Restarting the debugger is a complex operation that occurs in several phases.
8986 First, we try to reconstruct the command line that was used to invoke Perl
8987 and the debugger.
8988
8989 =cut
8990
8991 sub restart {
8992     # I may not be able to resurrect you, but here goes ...
8993     print $OUT
8994 "Warning: some settings and command-line options may be lost!\n";
8995     my ( @script, @flags, $cl );
8996
8997     # If warn was on before, turn it on again.
8998     push @flags, '-w' if $ini_warn;
8999
9000     # Rebuild the -I flags that were on the initial
9001     # command line.
9002     for (@ini_INC) {
9003         push @flags, '-I', $_;
9004     }
9005
9006     # Turn on taint if it was on before.
9007     push @flags, '-T' if ${^TAINT};
9008
9009     # Arrange for setting the old INC:
9010     # Save the current @init_INC in the environment.
9011     set_list( "PERLDB_INC", @ini_INC );
9012
9013     # If this was a perl one-liner, go to the "file"
9014     # corresponding to the one-liner read all the lines
9015     # out of it (except for the first one, which is going
9016     # to be added back on again when 'perl -d' runs: that's
9017     # the 'require perl5db.pl;' line), and add them back on
9018     # to the command line to be executed.
9019     if ( $0 eq '-e' ) {
9020         my $lines = *{$main::{'_<-e'}}{ARRAY};
9021         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9022             chomp( $cl = $lines->[$_] );
9023             push @script, '-e', $cl;
9024         }
9025     } ## end if ($0 eq '-e')
9026
9027     # Otherwise we just reuse the original name we had
9028     # before.
9029     else {
9030         @script = $0;
9031     }
9032
9033 =pod
9034
9035 After the command line  has been reconstructed, the next step is to save
9036 the debugger's status in environment variables. The C<DB::set_list> routine
9037 is used to save aggregate variables (both hashes and arrays); scalars are
9038 just popped into environment variables directly.
9039
9040 =cut
9041
9042     # If the terminal supported history, grab it and
9043     # save that in the environment.
9044     set_list( "PERLDB_HIST",
9045           $term->Features->{getHistory}
9046         ? $term->GetHistory
9047         : @hist );
9048
9049     # Find all the files that were visited during this
9050     # session (i.e., the debugger had magic hashes
9051     # corresponding to them) and stick them in the environment.
9052     my @had_breakpoints = keys %had_breakpoints;
9053     set_list( "PERLDB_VISITED", @had_breakpoints );
9054
9055     # Save the debugger options we chose.
9056     set_list( "PERLDB_OPT", %option );
9057     # set_list( "PERLDB_OPT", options2remember() );
9058
9059     # Save the break-on-loads.
9060     set_list( "PERLDB_ON_LOAD", %break_on_load );
9061
9062 =pod
9063
9064 The most complex part of this is the saving of all of the breakpoints. They
9065 can live in an awful lot of places, and we have to go through all of them,
9066 find the breakpoints, and then save them in the appropriate environment
9067 variable via C<DB::set_list>.
9068
9069 =cut
9070
9071     # Go through all the breakpoints and make sure they're
9072     # still valid.
9073     my @hard;
9074     for ( 0 .. $#had_breakpoints ) {
9075
9076         # We were in this file.
9077         my $file = $had_breakpoints[$_];
9078
9079         # Grab that file's magic line hash.
9080         *dbline = $main::{ '_<' . $file };
9081
9082         # Skip out if it doesn't exist, or if the breakpoint
9083         # is in a postponed file (we'll do postponed ones
9084         # later).
9085         next unless %dbline or $postponed_file{$file};
9086
9087         # In an eval. This is a little harder, so we'll
9088         # do more processing on that below.
9089         ( push @hard, $file ), next
9090           if $file =~ /^\(\w*eval/;
9091
9092         # XXX I have no idea what this is doing. Yet.
9093         my @add;
9094         @add = %{ $postponed_file{$file} }
9095           if $postponed_file{$file};
9096
9097         # Save the list of all the breakpoints for this file.
9098         set_list( "PERLDB_FILE_$_", %dbline, @add );
9099
9100         # Serialize the extra data %breakpoints_data hash.
9101         # That's a bug fix.
9102         set_list( "PERLDB_FILE_ENABLED_$_",
9103             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9104             sort { $a <=> $b } keys(%dbline)
9105         )
9106     } ## end for (0 .. $#had_breakpoints)
9107
9108     # The breakpoint was inside an eval. This is a little
9109     # more difficult. XXX and I don't understand it.
9110     for (@hard) {
9111         # Get over to the eval in question.
9112         *dbline = $main::{ '_<' . $_ };
9113         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
9114         for $sub ( keys %sub ) {
9115             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
9116             $subs{$sub} = [ $1, $2 ];
9117         }
9118         unless (%subs) {
9119             print $OUT
9120               "No subroutines in $_, ignoring breakpoints.\n";
9121             next;
9122         }
9123       LINES: for $line ( keys %dbline ) {
9124
9125             # One breakpoint per sub only:
9126             my ( $offset, $sub, $found );
9127           SUBS: for $sub ( keys %subs ) {
9128                 if (
9129                     $subs{$sub}->[1] >=
9130                     $line    # Not after the subroutine
9131                     and (
9132                         not defined $offset    # Not caught
9133                         or $offset < 0
9134                     )
9135                   )
9136                 {                              # or badly caught
9137                     $found  = $sub;
9138                     $offset = $line - $subs{$sub}->[0];
9139                     $offset = "+$offset", last SUBS
9140                       if $offset >= 0;
9141                 } ## end if ($subs{$sub}->[1] >=...
9142             } ## end for $sub (keys %subs)
9143             if ( defined $offset ) {
9144                 $postponed{$found} =
9145                   "break $offset if $dbline{$line}";
9146             }
9147             else {
9148                 print $OUT
9149 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9150             }
9151         } ## end for $line (keys %dbline)
9152     } ## end for (@hard)
9153
9154     # Save the other things that don't need to be
9155     # processed.
9156     set_list( "PERLDB_POSTPONE",  %postponed );
9157     set_list( "PERLDB_PRETYPE",   @$pretype );
9158     set_list( "PERLDB_PRE",       @$pre );
9159     set_list( "PERLDB_POST",      @$post );
9160     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9161
9162     # We are officially restarting.
9163     $ENV{PERLDB_RESTART} = 1;
9164
9165     # We are junking all child debuggers.
9166     delete $ENV{PERLDB_PIDS};    # Restore ini state
9167
9168     # Set this back to the initial pid.
9169     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9170
9171 =pod
9172
9173 After all the debugger status has been saved, we take the command we built up
9174 and then return it, so we can C<exec()> it. The debugger will spot the
9175 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9176 from the environment.
9177
9178 =cut
9179
9180     # And run Perl again. Add the "-d" flag, all the
9181     # flags we built up, the script (whether a one-liner
9182     # or a file), add on the -emacs flag for a slave editor,
9183     # and then the old arguments.
9184
9185     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9186
9187 };  # end restart
9188
9189 =back
9190
9191 =head1 END PROCESSING - THE C<END> BLOCK
9192
9193 Come here at the very end of processing. We want to go into a
9194 loop where we allow the user to enter commands and interact with the
9195 debugger, but we don't want anything else to execute.
9196
9197 First we set the C<$finished> variable, so that some commands that
9198 shouldn't be run after the end of program quit working.
9199
9200 We then figure out whether we're truly done (as in the user entered a C<q>
9201 command, or we finished execution while running nonstop). If we aren't,
9202 we set C<$single> to 1 (causing the debugger to get control again).
9203
9204 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9205 message and returns control to the debugger. Repeat.
9206
9207 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9208 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9209 break, run to completion.).
9210
9211 =cut
9212
9213 END {
9214     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9215     $fall_off_end = 1 unless $inhibit_exit;
9216
9217     # Do not stop in at_exit() and destructors on exit:
9218     if ($fall_off_end or $runnonstop) {
9219         &save_hist();
9220     } else {
9221         $DB::single = 1;
9222         DB::fake::at_exit();
9223     }
9224 } ## end END
9225
9226 =head1 PRE-5.8 COMMANDS
9227
9228 Some of the commands changed function quite a bit in the 5.8 command
9229 realignment, so much so that the old code had to be replaced completely.
9230 Because we wanted to retain the option of being able to go back to the
9231 former command set, we moved the old code off to this section.
9232
9233 There's an awful lot of duplicated code here. We've duplicated the
9234 comments to keep things clear.
9235
9236 =head2 Null command
9237
9238 Does nothing. Used to I<turn off> commands.
9239
9240 =cut
9241
9242 sub cmd_pre580_null {
9243
9244     # do nothing...
9245 }
9246
9247 =head2 Old C<a> command.
9248
9249 This version added actions if you supplied them, and deleted them
9250 if you didn't.
9251
9252 =cut
9253
9254 sub cmd_pre580_a {
9255     my $xcmd = shift;
9256     my $cmd  = shift;
9257
9258     # Argument supplied. Add the action.
9259     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9260
9261         # If the line isn't there, use the current line.
9262         my $i = $1 || $line;
9263         my $j = $2;
9264
9265         # If there is an action ...
9266         if ( length $j ) {
9267
9268             # ... but the line isn't breakable, skip it.
9269             if ( $dbline[$i] == 0 ) {
9270                 print $OUT "Line $i may not have an action.\n";
9271             }
9272             else {
9273
9274                 # ... and the line is breakable:
9275                 # Mark that there's an action in this file.
9276                 $had_breakpoints{$filename} |= 2;
9277
9278                 # Delete any current action.
9279                 $dbline{$i} =~ s/\0[^\0]*//;
9280
9281                 # Add the new action, continuing the line as needed.
9282                 $dbline{$i} .= "\0" . action($j);
9283             }
9284         } ## end if (length $j)
9285
9286         # No action supplied.
9287         else {
9288
9289             # Delete the action.
9290             $dbline{$i} =~ s/\0[^\0]*//;
9291
9292             # Mark as having no break or action if nothing's left.
9293             delete $dbline{$i} if $dbline{$i} eq '';
9294         }
9295     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9296 } ## end sub cmd_pre580_a
9297
9298 =head2 Old C<b> command
9299
9300 Add breakpoints.
9301
9302 =cut
9303
9304 sub cmd_pre580_b {
9305     my $xcmd   = shift;
9306     my $cmd    = shift;
9307     my $dbline = shift;
9308
9309     # Break on load.
9310     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9311         my $file = $1;
9312         $file =~ s/\s+$//;
9313         &cmd_b_load($file);
9314     }
9315
9316     # b compile|postpone <some sub> [<condition>]
9317     # The interpreter actually traps this one for us; we just put the
9318     # necessary condition in the %postponed hash.
9319     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9320
9321         # Capture the condition if there is one. Make it true if none.
9322         my $cond = length $3 ? $3 : '1';
9323
9324         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9325         # if it was 'compile'.
9326         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9327
9328         # De-Perl4-ify the name - ' separators to ::.
9329         $subname =~ s/\'/::/g;
9330
9331         # Qualify it into the current package unless it's already qualified.
9332         $subname = "${package}::" . $subname
9333           unless $subname =~ /::/;
9334
9335         # Add main if it starts with ::.
9336         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9337
9338         # Save the break type for this sub.
9339         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9340     } ## end elsif ($cmd =~ ...
9341
9342     # b <sub name> [<condition>]
9343     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9344         my $subname = $1;
9345         my $cond = length $2 ? $2 : '1';
9346         &cmd_b_sub( $subname, $cond );
9347     }
9348     # b <line> [<condition>].
9349     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9350         my $i = $1 || $dbline;
9351         my $cond = length $2 ? $2 : '1';
9352         &cmd_b_line( $i, $cond );
9353     }
9354 } ## end sub cmd_pre580_b
9355
9356 =head2 Old C<D> command.
9357
9358 Delete all breakpoints unconditionally.
9359
9360 =cut
9361
9362 sub cmd_pre580_D {
9363     my $xcmd = shift;
9364     my $cmd  = shift;
9365     if ( $cmd =~ /^\s*$/ ) {
9366         print $OUT "Deleting all breakpoints...\n";
9367
9368         # %had_breakpoints lists every file that had at least one
9369         # breakpoint in it.
9370         my $file;
9371         for $file ( keys %had_breakpoints ) {
9372
9373             # Switch to the desired file temporarily.
9374             local *dbline = $main::{ '_<' . $file };
9375
9376             my $max = $#dbline;
9377             my $was;
9378
9379             # For all lines in this file ...
9380             for ( my $i = 1 ; $i <= $max ; $i++ ) {
9381
9382                 # If there's a breakpoint or action on this line ...
9383                 if ( defined $dbline{$i} ) {
9384
9385                     # ... remove the breakpoint.
9386                     $dbline{$i} =~ s/^[^\0]+//;
9387                     if ( $dbline{$i} =~ s/^\0?$// ) {
9388
9389                         # Remove the entry altogether if no action is there.
9390                         delete $dbline{$i};
9391                     }
9392                 } ## end if (defined $dbline{$i...
9393             } ## end for ($i = 1 ; $i <= $max...
9394
9395             # If, after we turn off the "there were breakpoints in this file"
9396             # bit, the entry in %had_breakpoints for this file is zero,
9397             # we should remove this file from the hash.
9398             if ( not $had_breakpoints{$file} &= ~1 ) {
9399                 delete $had_breakpoints{$file};
9400             }
9401         } ## end for $file (keys %had_breakpoints)
9402
9403         # Kill off all the other breakpoints that are waiting for files that
9404         # haven't been loaded yet.
9405         undef %postponed;
9406         undef %postponed_file;
9407         undef %break_on_load;
9408     } ## end if ($cmd =~ /^\s*$/)
9409 } ## end sub cmd_pre580_D
9410
9411 =head2 Old C<h> command
9412
9413 Print help. Defaults to printing the long-form help; the 5.8 version
9414 prints the summary by default.
9415
9416 =cut
9417
9418 sub cmd_pre580_h {
9419     my $xcmd = shift;
9420     my $cmd  = shift;
9421
9422     # Print the *right* help, long format.
9423     if ( $cmd =~ /^\s*$/ ) {
9424         print_help($pre580_help);
9425     }
9426
9427     # 'h h' - explicitly-requested summary.
9428     elsif ( $cmd =~ /^h\s*/ ) {
9429         print_help($pre580_summary);
9430     }
9431
9432     # Find and print a command's help.
9433     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9434         my $asked  = $1;                   # for proper errmsg
9435         my $qasked = quotemeta($asked);    # for searching
9436                                            # XXX: finds CR but not <CR>
9437         if (
9438             $pre580_help =~ /^
9439                               <?           # Optional '<'
9440                               (?:[IB]<)    # Optional markup
9441                               $qasked      # The command name
9442                             /mx
9443           )
9444         {
9445
9446             while (
9447                 $pre580_help =~ /^
9448                                   (             # The command help:
9449                                    <?           # Optional '<'
9450                                    (?:[IB]<)    # Optional markup
9451                                    $qasked      # The command name
9452                                    ([\s\S]*?)   # Lines starting with tabs
9453                                    \n           # Final newline
9454                                   )
9455                                   (?!\s)/mgx
9456               )    # Line not starting with space
9457                    # (Next command's help)
9458             {
9459                 print_help($1);
9460             }
9461         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9462
9463         # Help not found.
9464         else {
9465             print_help("B<$asked> is not a debugger command.\n");
9466         }
9467     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9468 } ## end sub cmd_pre580_h
9469
9470 =head2 Old C<W> command
9471
9472 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9473
9474 =cut
9475
9476 sub cmd_pre580_W {
9477     my $xcmd = shift;
9478     my $cmd  = shift;
9479
9480     # Delete all watch expressions.
9481     if ( $cmd =~ /^$/ ) {
9482
9483         # No watching is going on.
9484         $trace &= ~2;
9485
9486         # Kill all the watch expressions and values.
9487         @to_watch = @old_watch = ();
9488     }
9489
9490     # Add a watch expression.
9491     elsif ( $cmd =~ /^(.*)/s ) {
9492
9493         # add it to the list to be watched.
9494         push @to_watch, $1;
9495
9496         # Get the current value of the expression.
9497         # Doesn't handle expressions returning list values!
9498         $evalarg = $1;
9499         my ($val) = &eval;
9500         $val = ( defined $val ) ? "'$val'" : 'undef';
9501
9502         # Save it.
9503         push @old_watch, $val;
9504
9505         # We're watching stuff.
9506         $trace |= 2;
9507
9508     } ## end elsif ($cmd =~ /^(.*)/s)
9509 } ## end sub cmd_pre580_W
9510
9511 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9512
9513 The debugger used to have a bunch of nearly-identical code to handle
9514 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9515 C<cmd_prepost> unify all this into one set of code to handle the
9516 appropriate actions.
9517
9518 =head2 C<cmd_pre590_prepost>
9519
9520 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9521 do something destructive. In pre 5.8 debuggers, the default action was to
9522 delete all the actions.
9523
9524 =cut
9525
9526 sub cmd_pre590_prepost {
9527     my $cmd    = shift;
9528     my $line   = shift || '*';
9529     my $dbline = shift;
9530
9531     return &cmd_prepost( $cmd, $line, $dbline );
9532 } ## end sub cmd_pre590_prepost
9533
9534 =head2 C<cmd_prepost>
9535
9536 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9537 Since the lists of actions are all held in arrays that are pointed to by
9538 references anyway, all we have to do is pick the right array reference and
9539 then use generic code to all, delete, or list actions.
9540
9541 =cut
9542
9543 sub cmd_prepost {
9544     my $cmd = shift;
9545
9546     # No action supplied defaults to 'list'.
9547     my $line = shift || '?';
9548
9549     # Figure out what to put in the prompt.
9550     my $which = '';
9551
9552     # Make sure we have some array or another to address later.
9553     # This means that if ssome reason the tests fail, we won't be
9554     # trying to stash actions or delete them from the wrong place.
9555     my $aref = [];
9556
9557     # < - Perl code to run before prompt.
9558     if ( $cmd =~ /^\</o ) {
9559         $which = 'pre-perl';
9560         $aref  = $pre;
9561     }
9562
9563     # > - Perl code to run after prompt.
9564     elsif ( $cmd =~ /^\>/o ) {
9565         $which = 'post-perl';
9566         $aref  = $post;
9567     }
9568
9569     # { - first check for properly-balanced braces.
9570     elsif ( $cmd =~ /^\{/o ) {
9571         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9572             print $OUT
9573 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
9574         }
9575
9576         # Properly balanced. Pre-prompt debugger actions.
9577         else {
9578             $which = 'pre-debugger';
9579             $aref  = $pretype;
9580         }
9581     } ## end elsif ( $cmd =~ /^\{/o )
9582
9583     # Did we find something that makes sense?
9584     unless ($which) {
9585         print $OUT "Confused by command: $cmd\n";
9586     }
9587
9588     # Yes.
9589     else {
9590
9591         # List actions.
9592         if ( $line =~ /^\s*\?\s*$/o ) {
9593             unless (@$aref) {
9594
9595                 # Nothing there. Complain.
9596                 print $OUT "No $which actions.\n";
9597             }
9598             else {
9599
9600                 # List the actions in the selected list.
9601                 print $OUT "$which commands:\n";
9602                 foreach my $action (@$aref) {
9603                     print $OUT "\t$cmd -- $action\n";
9604                 }
9605             } ## end else
9606         } ## end if ( $line =~ /^\s*\?\s*$/o)
9607
9608         # Might be a delete.
9609         else {
9610             if ( length($cmd) == 1 ) {
9611                 if ( $line =~ /^\s*\*\s*$/o ) {
9612
9613                     # It's a delete. Get rid of the old actions in the
9614                     # selected list..
9615                     @$aref = ();
9616                     print $OUT "All $cmd actions cleared.\n";
9617                 }
9618                 else {
9619
9620                     # Replace all the actions. (This is a <, >, or {).
9621                     @$aref = action($line);
9622                 }
9623             } ## end if ( length($cmd) == 1)
9624             elsif ( length($cmd) == 2 ) {
9625
9626                 # Add the action to the line. (This is a <<, >>, or {{).
9627                 push @$aref, action($line);
9628             }
9629             else {
9630
9631                 # <<<, >>>>, {{{{{{ ... something not a command.
9632                 print $OUT
9633                   "Confused by strange length of $which command($cmd)...\n";
9634             }
9635         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9636     } ## end else
9637 } ## end sub cmd_prepost
9638
9639 =head1 C<DB::fake>
9640
9641 Contains the C<at_exit> routine that the debugger uses to issue the
9642 C<Debugged program terminated ...> message after the program completes. See
9643 the C<END> block documentation for more details.
9644
9645 =cut
9646
9647 package DB::fake;
9648
9649 sub at_exit {
9650     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
9651 }
9652
9653 package DB;    # Do not trace this 1; below!
9654
9655 1;
9656
9657