This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Update Socket to CPAN version 1.97
[perl5.git] / cpan / Socket / Socket.pm
1 package Socket;
2
3 use strict;
4
5 our $VERSION = '1.97';
6
7 =head1 NAME
8
9 C<Socket> - networking constants and support functions
10
11 =head1 SYNOPSIS
12
13 C<Socket> a low-level module used by, among other things, the L<IO::Socket>
14 family of modules. The following examples demonstrate some low-level uses but
15 a practical program would likely use the higher-level API provided by
16 C<IO::Socket> or similar instead.
17
18  use Socket qw(PF_INET SOCK_STREAM pack_sockaddr_in inet_aton);
19
20  socket(my $socket, PF_INET, SOCK_STREAM, 0)
21      or die "socket: $!";
22
23  my $port = getservbyname "echo", "tcp";
24  connect($socket, pack_sockaddr_in($port, inet_aton("localhost")))
25      or die "connect: $!";
26
27  print $socket "Hello, world!\n";
28  print <$socket>;
29
30 See also the L</EXAMPLES> section.
31
32 =head1 DESCRIPTION
33
34 This module provides a variety of constants, structure manipulators and other
35 functions related to socket-based networking. The values and functions
36 provided are useful when used in conjunction with Perl core functions such as
37 socket(), setsockopt() and bind(). It also provides several other support
38 functions, mostly for dealing with conversions of network addresses between
39 human-readable and native binary forms, and for hostname resolver operations.
40
41 Some constants and functions are exported by default by this module; but for
42 backward-compatibility any recently-added symbols are not exported by default
43 and must be requested explicitly. When an import list is provided to the
44 C<use Socket> line, the default exports are not automatically imported. It is
45 therefore best practice to always to explicitly list all the symbols required.
46
47 Also, some common socket "newline" constants are provided: the constants
48 C<CR>, C<LF>, and C<CRLF>, as well as C<$CR>, C<$LF>, and C<$CRLF>, which map
49 to C<\015>, C<\012>, and C<\015\012>. If you do not want to use the literal
50 characters in your programs, then use the constants provided here. They are
51 not exported by default, but can be imported individually, and with the
52 C<:crlf> export tag:
53
54  use Socket qw(:DEFAULT :crlf);
55
56  $sock->print("GET / HTTP/1.0$CRLF");
57
58 The entire getaddrinfo() subsystem can be exported using the tag C<:addrinfo>;
59 this exports the getaddrinfo() and getnameinfo() functions, and all the
60 C<AI_*>, C<NI_*>, C<NIx_*> and C<EAI_*> constants.
61
62 =cut
63
64 =head1 CONSTANTS
65
66 In each of the following groups, there may be many more constants provided
67 than just the ones given as examples in the section heading. If the heading
68 ends C<...> then this means there are likely more; the exact constants
69 provided will depend on the OS and headers found at compile-time.
70
71 =cut
72
73 =head2 PF_INET, PF_INET6, PF_UNIX, ...
74
75 Protocol family constants to use as the first argument to socket() or the
76 value of the C<SO_FAMILY> socket option.
77
78 =head2 AF_INET, AF_INET6, AF_UNIX, ...
79
80 Address family constants used by the socket address structures, to pass to
81 such functions as inet_pton() or getaddrinfo(), or are returned by such
82 functions as sockaddr_family().
83
84 =head2 SOCK_STREAM, SOCK_DGRAM, SOCK_RAW, ...
85
86 Socket type constants to use as the second argument to socket(), or the value
87 of the C<SO_TYPE> socket option.
88
89 =head2 SOL_SOCKET
90
91 Socket option level constant for setsockopt() and getsockopt().
92
93 =head2 SO_ACCEPTCONN, SO_BROADCAST, SO_ERROR, ...
94
95 Socket option name constants for setsockopt() and getsockopt() at the
96 C<SOL_SOCKET> level.
97
98 =head2 IP_OPTIONS, IP_TOS, IP_TTL, ...
99
100 Socket option name constants for IPv4 socket options at the C<IPPROTO_IP>
101 level.
102
103 =head2 MSG_BCAST, MSG_OOB, MSG_TRUNC, ...
104
105 Message flag constants for send() and recv().
106
107 =head2 SHUT_RD, SHUT_RDWR, SHUT_WR
108
109 Direction constants for shutdown().
110
111 =head2 INADDR_ANY, INADDR_BROADCAST, INADDR_LOOPBACK, INADDR_NONE
112
113 Constants giving the special C<AF_INET> addresses for wildcard, broadcast,
114 local loopback, and invalid addresses.
115
116 Normally equivalent to inet_aton('0.0.0.0'), inet_aton('255.255.255.255'),
117 inet_aton('localhost') and inet_aton('255.255.255.255') respectively.
118
119 =head2 IPPROTO_IP, IPPROTO_IPV6, IPPROTO_TCP, ...
120
121 IP protocol constants to use as the third argument to socket(), the level
122 argument to getsockopt() or setsockopt(), or the value of the C<SO_PROTOCOL>
123 socket option.
124
125 =head2 TCP_CORK, TCP_KEEPALIVE, TCP_NODELAY, ...
126
127 Socket option name constants for TCP socket options at the C<IPPROTO_TCP>
128 level.
129
130 =head2 IN6ADDR_ANY, IN6ADDR_LOOPBACK
131
132 Constants giving the special C<AF_INET6> addresses for wildcard and local
133 loopback.
134
135 Normally equivalent to inet_pton(AF_INET6, "::") and
136 inet_pton(AF_INET6, "::1") respectively.
137
138 =head2 IPV6_ADD_MEMBERSHIP, IPV6_MTU, IPV6_V6ONLY, ...
139
140 Socket option name constants for IPv6 socket options at the C<IPPROTO_IPV6>
141 level.
142
143 =cut
144
145 # Still undocumented: SCM_*, SOMAXCONN, IOV_MAX, UIO_MAXIOV
146
147 =head1 STRUCTURE MANIPULATORS
148
149 The following functions convert between lists of Perl values and packed binary
150 strings representing structures.
151
152 =cut
153
154 =head2 $family = sockaddr_family $sockaddr
155
156 Takes a packed socket address (as returned by pack_sockaddr_in(),
157 pack_sockaddr_un() or the perl builtin functions getsockname() and
158 getpeername()). Returns the address family tag. This will be one of the
159 C<AF_*> constants, such as C<AF_INET> for a C<sockaddr_in> addresses or
160 C<AF_UNIX> for a C<sockaddr_un>. It can be used to figure out what unpack to
161 use for a sockaddr of unknown type.
162
163 =head2 $sockaddr = pack_sockaddr_in $port, $ip_address
164
165 Takes two arguments, a port number and an opaque string (as returned by
166 inet_aton(), or a v-string). Returns the C<sockaddr_in> structure with those
167 arguments packed in and C<AF_INET> filled in. For Internet domain sockets,
168 this structure is normally what you need for the arguments in bind(),
169 connect(), and send().
170
171 =head2 ($port, $ip_address) = unpack_sockaddr_in $sockaddr
172
173 Takes a C<sockaddr_in> structure (as returned by pack_sockaddr_in(),
174 getpeername() or recv()). Returns a list of two elements: the port and an
175 opaque string representing the IP address (you can use inet_ntoa() to convert
176 the address to the four-dotted numeric format). Will croak if the structure
177 does not represent an C<AF_INET> address.
178
179 =head2 $sockaddr = sockaddr_in $port, $ip_address
180
181 =head2 ($port, $ip_address) = sockaddr_in $sockaddr
182
183 A wrapper of pack_sockaddr_in() or unpack_sockaddr_in(). In list context,
184 unpacks its argument and returns a list consisting of the port and IP address.
185 In scalar context, packs its port and IP address arguments as a C<sockaddr_in>
186 and returns it.
187
188 Provided largely for legacy compatibility; it is better to use
189 pack_sockaddr_in() or unpack_sockaddr_in() explicitly.
190
191 =head2 $sockaddr = pack_sockaddr_in6 $port, $ip6_address, [$scope_id, [$flowinfo]]
192
193 Takes two to four arguments, a port number, an opaque string (as returned by
194 inet_pton()), optionally a scope ID number, and optionally a flow label
195 number. Returns the C<sockaddr_in6> structure with those arguments packed in
196 and C<AF_INET6> filled in. IPv6 equivalent of pack_sockaddr_in().
197
198 =head2 ($port, $ip6_address, $scope_id, $flowinfo) = unpack_sockaddr_in6 $sockaddr
199
200 Takes a C<sockaddr_in6> structure. Returns a list of four elements: the port
201 number, an opaque string representing the IPv6 address, the scope ID, and the
202 flow label. (You can use inet_ntop() to convert the address to the usual
203 string format). Will croak if the structure does not represent an C<AF_INET6>
204 address.
205
206 =head2 $sockaddr = sockaddr_in6 $port, $ip6_address, [$scope_id, [$flowinfo]]
207
208 =head2 ($port, $ip6_address, $scope_id, $flowinfo) = sockaddr_in6 $sockaddr
209
210 A wrapper of pack_sockaddr_in6() or unpack_sockaddr_in6(). In list context,
211 unpacks its argument according to unpack_sockaddr_in6(). In scalar context,
212 packs its arguments according to pack_sockaddr_in6().
213
214 Provided largely for legacy compatibility; it is better to use
215 pack_sockaddr_in6() or unpack_sockaddr_in6() explicitly.
216
217 =head2 $sockaddr = pack_sockaddr_un $path
218
219 Takes one argument, a pathname. Returns the C<sockaddr_un> structure with that
220 path packed in with C<AF_UNIX> filled in. For C<PF_UNIX> sockets, this
221 structure is normally what you need for the arguments in bind(), connect(),
222 and send().
223
224 =head2 ($path) = unpack_sockaddr_un $sockaddr
225
226 Takes a C<sockaddr_un> structure (as returned by pack_sockaddr_un(),
227 getpeername() or recv()). Returns a list of one element: the pathname. Will
228 croak if the structure does not represent an C<AF_UNIX> address.
229
230 =head2 $sockaddr = sockaddr_un $path
231
232 =head2 ($path) = sockaddr_un $sockaddr
233
234 A wrapper of pack_sockaddr_un() or unpack_sockaddr_un(). In a list context,
235 unpacks its argument and returns a list consisting of the pathname. In a
236 scalar context, packs its pathname as a C<sockaddr_un> and returns it.
237
238 Provided largely for legacy compatibility; it is better to use
239 pack_sockaddr_un() or unpack_sockaddr_un() explicitly.
240
241 These are only supported if your system has E<lt>F<sys/un.h>E<gt>.
242
243 =head2 $ipv6_mreq = pack_ipv6_mreq $ip6_address, $ifindex
244
245 Takes an IPv6 address and an interface number. Returns the C<ipv6_mreq>
246 structure with those arguments packed in. Suitable for use with the
247 C<IPV6_ADD_MEMBERSHIP> and C<IPV6_DROP_MEMBERSHIP> sockopts.
248
249 =head2 ($ip6_address, $ifindex) = unpack_ipv6_mreq $ipv6_mreq
250
251 Takes an C<ipv6_mreq> structure. Returns a list of two elements; the IPv6
252 address and an interface number.
253
254 =cut
255
256 =head1 FUNCTIONS
257
258 =cut
259
260 =head2 $ip_address = inet_aton $string
261
262 Takes a string giving the name of a host, or a textual representation of an IP
263 address and translates that to an packed binary address structure suitable to
264 pass to pack_sockaddr_in(). If passed a hostname that cannot be resolved,
265 returns C<undef>. For multi-homed hosts (hosts with more than one address),
266 the first address found is returned.
267
268 For portability do not assume that the result of inet_aton() is 32 bits wide,
269 in other words, that it would contain only the IPv4 address in network order.
270
271 This IPv4-only function is provided largely for legacy reasons. Newly-written
272 code should use getaddrinfo() or inet_pton() instead for IPv6 support.
273
274 =head2 $string = inet_ntoa $ip_address
275
276 Takes a packed binary address structure such as returned by
277 unpack_sockaddr_in() (or a v-string representing the four octets of the IPv4
278 address in network order) and translates it into a string of the form
279 C<d.d.d.d> where the C<d>s are numbers less than 256 (the normal
280 human-readable four dotted number notation for Internet addresses).
281
282 This IPv4-only function is provided largely for legacy reasons. Newly-written
283 code should use getnameinfo() or inet_ntop() instead for IPv6 support.
284
285 =head2 $address = inet_pton $family, $string
286
287 Takes an address family (such as C<AF_INET> or C<AF_INET6>) and a string
288 giving the name of a host, or a textual representation of an IP address and
289 translates that to an packed binary address structure.
290
291 See also getaddrinfo() for a more powerful and flexible function to look up
292 socket addresses given hostnames or textual addresses.
293
294 =head2 $string = inet_ntop $family, $address
295
296 Takes an address family and a packed binary address structure and translates
297 it into a human-readable textual representation of the address; typically in
298 C<d.d.d.d> form for C<AF_INET> or C<hhhh:hhhh::hhhh> form for C<AF_INET6>.
299
300 See also getnameinfo() for a more powerful and flexible function to turn
301 socket addresses into human-readable textual representations.
302
303 =head2 ($err, @result) = getaddrinfo $host, $service, [$hints]
304
305 Given both a hostname and service name, this function attempts to resolve the
306 host name into a list of network addresses, and the service name into a
307 protocol and port number, and then returns a list of address structures
308 suitable to connect() to it.
309
310 Given just a host name, this function attempts to resolve it to a list of
311 network addresses, and then returns a list of address structures giving these
312 addresses.
313
314 Given just a service name, this function attempts to resolve it to a protocol
315 and port number, and then returns a list of address structures that represent
316 it suitable to bind() to. This use should be combined with the C<AI_PASSIVE>
317 flag; see below.
318
319 Given neither name, it generates an error.
320
321 If present, $hints should be a reference to a hash, where the following keys
322 are recognised:
323
324 =over 4
325
326 =item flags => INT
327
328 A bitfield containing C<AI_*> constants; see below.
329
330 =item family => INT
331
332 Restrict to only generating addresses in this address family
333
334 =item socktype => INT
335
336 Restrict to only generating addresses of this socket type
337
338 =item protocol => INT
339
340 Restrict to only generating addresses for this protocol
341
342 =back
343
344 The return value will be a list; the first value being an error indication,
345 followed by a list of address structures (if no error occurred).
346
347 The error value will be a dualvar; comparable to the C<EI_*> error constants,
348 or printable as a human-readable error message string. If no error occurred it
349 will be zero numerically and an empty string.
350
351 Each value in the results list will be a hash reference containing the following
352 fields:
353
354 =over 4
355
356 =item family => INT
357
358 The address family (e.g. C<AF_INET>)
359
360 =item socktype => INT
361
362 The socket type (e.g. C<SOCK_STREAM>)
363
364 =item protocol => INT
365
366 The protocol (e.g. C<IPPROTO_TCP>)
367
368 =item addr => STRING
369
370 The address in a packed string (such as would be returned by
371 pack_sockaddr_in())
372
373 =item canonname => STRING
374
375 The canonical name for the host if the C<AI_CANONNAME> flag was provided, or
376 C<undef> otherwise. This field will only be present on the first returned
377 address.
378
379 =back
380
381 The following flag constants are recognised in the $hints hash. Other flag
382 constants may exist as provided by the OS.
383
384 =over 4
385
386 =item AI_PASSIVE
387
388 Indicates that this resolution is for a local bind() for a passive (i.e.
389 listening) socket, rather than an active (i.e. connecting) socket.
390
391 =item AI_CANONNAME
392
393 Indicates that the caller wishes the canonical hostname (C<canonname>) field
394 of the result to be filled in.
395
396 =item AI_NUMERICHOST
397
398 Indicates that the caller will pass a numeric address, rather than a hostname,
399 and that getaddrinfo() must not perform a resolve operation on this name. This
400 flag will prevent a possibly-slow network lookup operation, and instead return
401 an error if a hostname is passed.
402
403 =back
404
405 =head2 ($err, $hostname, $servicename) = getnameinfo $sockaddr, [$flags, [$xflags]]
406
407 Given a packed socket address (such as from getsockname(), getpeername(), or
408 returned by getaddrinfo() in a C<addr> field), returns the hostname and
409 symbolic service name it represents. $flags may be a bitmask of C<NI_*>
410 constants, or defaults to 0 if unspecified.
411
412 The return value will be a list; the first value being an error condition,
413 followed by the hostname and service name.
414
415 The error value will be a dualvar; comparable to the C<EI_*> error constants,
416 or printable as a human-readable error message string. The host and service
417 names will be plain strings.
418
419 The following flag constants are recognised as $flags. Other flag constants may
420 exist as provided by the OS.
421
422 =over 4
423
424 =item NI_NUMERICHOST
425
426 Requests that a human-readable string representation of the numeric address be
427 returned directly, rather than performing a name resolve operation that may
428 convert it into a hostname. This will also avoid potentially-blocking network
429 IO.
430
431 =item NI_NUMERICSERV
432
433 Requests that the port number be returned directly as a number representation
434 rather than performing a name resolve operation that may convert it into a
435 service name.
436
437 =item NI_NAMEREQD
438
439 If a name resolve operation fails to provide a name, then this flag will cause
440 getnameinfo() to indicate an error, rather than returning the numeric
441 representation as a human-readable string.
442
443 =item NI_DGRAM
444
445 Indicates that the socket address relates to a C<SOCK_DGRAM> socket, for the
446 services whose name differs between TCP and UDP protocols.
447
448 =back
449
450 The following constants may be supplied as $xflags.
451
452 =over 4
453
454 =item NIx_NOHOST
455
456 Indicates that the caller is not interested in the hostname of the result, so
457 it does not have to be converted. C<undef> will be returned as the hostname.
458
459 =item NIx_NOSERV
460
461 Indicates that the caller is not interested in the service name of the result,
462 so it does not have to be converted. C<undef> will be returned as the service
463 name.
464
465 =back
466
467 =head1 getaddrinfo() / getnameinfo() ERROR CONSTANTS
468
469 The following constants may be returned by getaddrinfo() or getnameinfo().
470 Others may be provided by the OS.
471
472 =over 4
473
474 =item EAI_AGAIN
475
476 A temporary failure occurred during name resolution. The operation may be
477 successful if it is retried later.
478
479 =item EAI_BADFLAGS
480
481 The value of the C<flags> hint to getaddrinfo(), or the $flags parameter to
482 getnameinfo() contains unrecognised flags.
483
484 =item EAI_FAMILY
485
486 The C<family> hint to getaddrinfo(), or the family of the socket address
487 passed to getnameinfo() is not supported.
488
489 =item EAI_NODATA
490
491 The host name supplied to getaddrinfo() did not provide any usable address
492 data.
493
494 =item EAI_NONAME
495
496 The host name supplied to getaddrinfo() does not exist, or the address
497 supplied to getnameinfo() is not associated with a host name and the
498 C<NI_NAMEREQD> flag was supplied.
499
500 =item EAI_SERVICE
501
502 The service name supplied to getaddrinfo() is not available for the socket
503 type given in the $hints.
504
505 =back
506
507 =cut
508
509 =head1 EXAMPLES
510
511 =head2 Lookup for connect()
512
513 The getaddrinfo() function converts a hostname and a service name into a list
514 of structures, each containing a potential way to connect() to the named
515 service on the named host.
516
517  use IO::Socket;
518  use Socket qw(SOCK_STREAM getaddrinfo);
519
520  my %hints = (socktype => SOCK_STREAM);
521  my ($err, @res) = getaddrinfo("localhost", "echo", \%hints);
522  die "Cannot getaddrinfo - $err" if $err;
523
524  my $sock;
525
526  foreach my $ai (@res) {
527      my $candidate = IO::Socket->new();
528
529      $candidate->socket($ai->{family}, $ai->{socktype}, $ai->{protocol})
530          or next;
531
532      $candidate->connect($ai->{addr})
533          or next;
534
535      $sock = $candidate;
536      last;
537  }
538
539  die "Cannot connect to localhost:echo" unless $sock;
540
541  $sock->print("Hello, world!\n");
542  print <$sock>;
543
544 Because a list of potential candidates is returned, the C<while> loop tries
545 each in turn until it it finds one that succeeds both the socket() and
546 connect() calls.
547
548 This function performs the work of the legacy functions gethostbyname(),
549 getservbyname(), inet_aton() and pack_sockaddr_in().
550
551 In practice this logic is better performed by L<IO::Socket::IP>.
552
553 =head2 Making a human-readable string out of an address
554
555 The getnameinfo() function converts a socket address, such as returned by
556 getsockname() or getpeername(), into a pair of human-readable strings
557 representing the address and service name.
558
559  use IO::Socket::IP;
560  use Socket qw(getnameinfo);
561
562  my $server = IO::Socket::IP->new(LocalPort => 12345, Listen => 1) or
563      die "Cannot listen - $@";
564
565  my $socket = $server->accept or die "accept: $!";
566
567  my ($err, $hostname, $servicename) = getnameinfo($socket->peername);
568  die "Cannot getnameinfo - $err" if $err;
569
570  print "The peer is connected from $hostname\n";
571
572 Since in this example only the hostname was used, the redundant conversion of
573 the port number into a service name may be omitted by passing the
574 C<NIx_NOSERV> flag.
575
576  use Socket qw(getnameinfo NIx_NOSERV);
577
578  my ($err, $hostname) = getnameinfo($socket->peername, 0, NIx_NOSERV);
579
580 This function performs the work of the legacy functions unpack_sockaddr_in(),
581 inet_ntoa(), gethostbyaddr() and getservbyport().
582
583 In practice this logic is better performed by L<IO::Socket::IP>.
584
585 =head2 Resolving hostnames into IP addresses
586
587 To turn a hostname into a human-readable plain IP address use getaddrinfo()
588 to turn the hostname into a list of socket structures, then getnameinfo() on
589 each one to make it a readable IP address again.
590
591  use Socket qw(:addrinfo SOCK_RAW);
592
593  my ($err, @res) = getaddrinfo($hostname, "", {socktype => SOCK_RAW});
594  die "Cannot getaddrinfo - $err" if $err;
595
596  while( my $ai = shift @res ) {
597      my ($err, $ipaddr) = getnameinfo($ai->{addr}, NI_NUMERICHOST, NIx_NOSERV);
598      die "Cannot getnameinfo - $err" if $err;
599
600      print "$ipaddr\n";
601  }
602
603 The C<socktype> hint to getaddrinfo() filters the results to only include one
604 socket type and protocol. Without this most OSes return three combinations,
605 for C<SOCK_STREAM>, C<SOCK_DGRAM> and C<SOCK_RAW>, resulting in triplicate
606 output of addresses. The C<NI_NUMERICHOST> flag to getnameinfo() causes it to
607 return a string-formatted plain IP address, rather than reverse resolving it
608 back into a hostname.
609
610 This combination performs the work of the legacy functions gethostbyname()
611 and inet_ntoa().
612
613 =head2 Accessing socket options
614
615 The many C<SO_*> and other constants provide the socket option names for
616 getsockopt() and setsockopt().
617
618  use IO::Socket::INET;
619  use Socket qw(SOL_SOCKET SO_RCVBUF IPPROTO_IP IP_TTL);
620
621  my $socket = IO::Socket::INET->new(LocalPort => 0, Proto => 'udp')
622      or die "Cannot create socket: $@";
623
624  $socket->setsockopt(SOL_SOCKET, SO_RCVBUF, 64*1024) or
625      die "setsockopt: $!";
626
627  print "Receive buffer is ", $socket->getsockopt(SOL_SOCKET, SO_RCVBUF),
628      " bytes\n";
629
630  print "IP TTL is ", $socket->getsockopt(IPPROTO_IP, IP_TTL), "\n";
631
632 As a convenience, L<IO::Socket>'s setsockopt() method will convert a number
633 into a packed byte buffer, and getsockopt() will unpack a byte buffer of the
634 correct size back into a number.
635
636 =cut
637
638 =head1 AUTHOR
639
640 This module was originally maintained in Perl core by the Perl 5 Porters.
641
642 It was extracted to dual-life on CPAN at version 1.95 by
643 Paul Evans <leonerd@leonerd.org.uk>
644
645 =cut
646
647 use Carp;
648 use warnings::register;
649
650 require Exporter;
651 require XSLoader;
652 our @ISA = qw(Exporter);
653
654 # <@Nicholas> you can't change @EXPORT without breaking the implicit API
655 # Please put any new constants in @EXPORT_OK!
656
657 # List re-ordered to match documentation above. Try to keep the ordering
658 # consistent so it's easier to see which ones are or aren't documented.
659 our @EXPORT = qw(
660         PF_802 PF_AAL PF_APPLETALK PF_CCITT PF_CHAOS PF_CTF PF_DATAKIT
661         PF_DECnet PF_DLI PF_ECMA PF_GOSIP PF_HYLINK PF_IMPLINK PF_INET PF_INET6
662         PF_ISO PF_KEY PF_LAST PF_LAT PF_LINK PF_MAX PF_NBS PF_NIT PF_NS PF_OSI
663         PF_OSINET PF_PUP PF_ROUTE PF_SNA PF_UNIX PF_UNSPEC PF_USER PF_WAN
664         PF_X25
665
666         AF_802 AF_AAL AF_APPLETALK AF_CCITT AF_CHAOS AF_CTF AF_DATAKIT
667         AF_DECnet AF_DLI AF_ECMA AF_GOSIP AF_HYLINK AF_IMPLINK AF_INET AF_INET6
668         AF_ISO AF_KEY AF_LAST AF_LAT AF_LINK AF_MAX AF_NBS AF_NIT AF_NS AF_OSI
669         AF_OSINET AF_PUP AF_ROUTE AF_SNA AF_UNIX AF_UNSPEC AF_USER AF_WAN
670         AF_X25
671
672         SOCK_DGRAM SOCK_RAW SOCK_RDM SOCK_SEQPACKET SOCK_STREAM
673
674         SOL_SOCKET
675
676         SO_ACCEPTCONN SO_ATTACH_FILTER SO_BACKLOG SO_BROADCAST SO_CHAMELEON
677         SO_DEBUG SO_DETACH_FILTER SO_DGRAM_ERRIND SO_DONTLINGER SO_DONTROUTE
678         SO_ERROR SO_FAMILY SO_KEEPALIVE SO_LINGER SO_OOBINLINE SO_PASSCRED
679         SO_PASSIFNAME SO_PEERCRED SO_PROTOCOL SO_PROTOTYPE SO_RCVBUF
680         SO_RCVLOWAT SO_RCVTIMEO SO_REUSEADDR SO_REUSEPORT
681         SO_SECURITY_AUTHENTICATION SO_SECURITY_ENCRYPTION_NETWORK
682         SO_SECURITY_ENCRYPTION_TRANSPORT SO_SNDBUF SO_SNDLOWAT SO_SNDTIMEO
683         SO_STATE SO_TYPE SO_USELOOPBACK SO_XOPEN SO_XSE
684
685         IP_OPTIONS IP_HDRINCL IP_TOS IP_TTL IP_RECVOPTS IP_RECVRETOPTS
686         IP_RETOPTS
687
688         MSG_BCAST MSG_BTAG MSG_CTLFLAGS MSG_CTLIGNORE MSG_CTRUNC MSG_DONTROUTE
689         MSG_DONTWAIT MSG_EOF MSG_EOR MSG_ERRQUEUE MSG_ETAG MSG_FIN
690         MSG_MAXIOVLEN MSG_MCAST MSG_NOSIGNAL MSG_OOB MSG_PEEK MSG_PROXY MSG_RST
691         MSG_SYN MSG_TRUNC MSG_URG MSG_WAITALL MSG_WIRE
692
693         SHUT_RD SHUT_RDWR SHUT_WR
694
695         INADDR_ANY INADDR_BROADCAST INADDR_LOOPBACK INADDR_NONE
696
697         SCM_CONNECT SCM_CREDENTIALS SCM_CREDS SCM_RIGHTS SCM_TIMESTAMP
698
699         SOMAXCONN
700
701         IOV_MAX
702         UIO_MAXIOV
703
704         sockaddr_family
705         pack_sockaddr_in  unpack_sockaddr_in  sockaddr_in
706         pack_sockaddr_in6 unpack_sockaddr_in6 sockaddr_in6
707         pack_sockaddr_un  unpack_sockaddr_un  sockaddr_un 
708
709         inet_aton inet_ntoa
710 );
711
712 # List re-ordered to match documentation above. Try to keep the ordering
713 # consistent so it's easier to see which ones are or aren't documented.
714 our @EXPORT_OK = qw(
715         CR LF CRLF $CR $LF $CRLF
716
717         IPPROTO_IP IPPROTO_IPV6 IPPROTO_RAW IPPROTO_ICMP IPPROTO_TCP
718         IPPROTO_UDP
719
720         TCP_CONGESTION TCP_CORK TCP_DEFER_ACCEPT TCP_INFO TCP_KEEPALIVE
721         TCP_KEEPCNT TCP_KEEPIDLE TCP_KEEPINTVL TCP_LINGER2 TCP_MAXRT TCP_MAXSEG
722         TCP_MD5SIG TCP_NODELAY TCP_QUICKACK TCP_STDURG TCP_SYNCNT
723         TCP_WINDOW_CLAMP 
724
725         IN6ADDR_ANY IN6ADDR_LOOPBACK
726
727         IPV6_ADD_MEMBERSHIP IPV6_DROP_MEMBERSHIP IPV6_MTU IPV6_MTU_DISCOVER
728         IPV6_MULTICAST_HOPS IPV6_MULTICAST_IF IPV6_MULTICAST_LOOP
729         IPV6_UNICAST_HOPS IPV6_V6ONLY
730
731         pack_ipv6_mreq unpack_ipv6_mreq
732
733         inet_pton inet_ntop
734
735         getaddrinfo getnameinfo
736
737         AI_ADDRCONFIG AI_ALL AI_CANONIDN AI_CANONNAME AI_IDN
738         AI_IDN_ALLOW_UNASSIGNED AI_IDN_USE_STD3_ASCII_RULES AI_NUMERICHOST
739         AI_NUMERICSERV AI_PASSIVE AI_V4MAPPED
740
741         NI_DGRAM NI_IDN NI_IDN_ALLOW_UNASSIGNED NI_IDN_USE_STD3_ASCII_RULES
742         NI_NAMEREQD NI_NOFQDN NI_NUMERICHOST NI_NUMERICSERV
743
744         NIx_NOHOST NIx_NOSERV
745
746         EAI_ADDRFAMILY EAI_AGAIN EAI_BADFLAGS EAI_BADHINTS EAI_FAIL EAI_FAMILY
747         EAI_NODATA EAI_NONAME EAI_PROTOCOL EAI_SERVICE EAI_SOCKTYPE EAI_SYSTEM
748 );
749
750 our %EXPORT_TAGS = (
751     crlf     => [qw(CR LF CRLF $CR $LF $CRLF)],
752     addrinfo => [qw(getaddrinfo getnameinfo), grep m/^(?:AI|NI|NIx|EAI)_/, @EXPORT_OK],
753     all      => [@EXPORT, @EXPORT_OK],
754 );
755
756 BEGIN {
757     sub CR   () {"\015"}
758     sub LF   () {"\012"}
759     sub CRLF () {"\015\012"}
760
761     # These are not gni() constants; they're extensions for the perl API
762     # The definitions in Socket.pm and Socket.xs must match
763     sub NIx_NOHOST() {1 << 0}
764     sub NIx_NOSERV() {1 << 1}
765 }
766
767 *CR   = \CR();
768 *LF   = \LF();
769 *CRLF = \CRLF();
770
771 sub sockaddr_in {
772     if (@_ == 6 && !wantarray) { # perl5.001m compat; use this && die
773         my($af, $port, @quad) = @_;
774         warnings::warn "6-ARG sockaddr_in call is deprecated" 
775             if warnings::enabled();
776         pack_sockaddr_in($port, inet_aton(join('.', @quad)));
777     } elsif (wantarray) {
778         croak "usage:   (port,iaddr) = sockaddr_in(sin_sv)" unless @_ == 1;
779         unpack_sockaddr_in(@_);
780     } else {
781         croak "usage:   sin_sv = sockaddr_in(port,iaddr))" unless @_ == 2;
782         pack_sockaddr_in(@_);
783     }
784 }
785
786 sub sockaddr_in6 {
787     if (wantarray) {
788         croak "usage:   (port,in6addr,scope_id,flowinfo) = sockaddr_in6(sin6_sv)" unless @_ == 1;
789         unpack_sockaddr_in6(@_);
790     }
791     else {
792         croak "usage:   sin6_sv = sockaddr_in6(port,in6addr,[scope_id,[flowinfo]])" unless @_ >= 2 and @_ <= 4;
793         pack_sockaddr_in6(@_);
794     }
795 }
796
797 sub sockaddr_un {
798     if (wantarray) {
799         croak "usage:   (filename) = sockaddr_un(sun_sv)" unless @_ == 1;
800         unpack_sockaddr_un(@_);
801     } else {
802         croak "usage:   sun_sv = sockaddr_un(filename)" unless @_ == 1;
803         pack_sockaddr_un(@_);
804     }
805 }
806
807 XSLoader::load(__PACKAGE__, $VERSION);
808
809 my %errstr;
810
811 if( defined &getaddrinfo ) {
812     # These are not part of the API, nothing uses them, and deleting them
813     # reduces the size of %Socket:: by about 12K
814     delete $Socket::{fake_getaddrinfo};
815     delete $Socket::{fake_getnameinfo};
816 } else {
817     require Scalar::Util;
818
819     *getaddrinfo = \&fake_getaddrinfo;
820     *getnameinfo = \&fake_getnameinfo;
821
822     # These numbers borrowed from GNU libc's implementation, but since
823     # they're only used by our emulation, it doesn't matter if the real
824     # platform's values differ
825     my %constants = (
826         AI_PASSIVE     => 1,
827         AI_CANONNAME   => 2,
828         AI_NUMERICHOST => 4,
829         AI_V4MAPPED    => 8,
830         AI_ALL         => 16,
831         AI_ADDRCONFIG  => 32,
832         # RFC 2553 doesn't define this but Linux does - lets be nice and
833         # provide it since we can
834         AI_NUMERICSERV => 1024,
835
836         EAI_BADFLAGS   => -1,
837         EAI_NONAME     => -2,
838         EAI_NODATA     => -5,
839         EAI_FAMILY     => -6,
840         EAI_SERVICE    => -8,
841
842         NI_NUMERICHOST => 1,
843         NI_NUMERICSERV => 2,
844         NI_NOFQDN      => 4,
845         NI_NAMEREQD    => 8,
846         NI_DGRAM       => 16,
847
848         # Constants we don't support. Export them, but croak if anyone tries to
849         # use them
850         AI_IDN                      => 64,
851         AI_CANONIDN                 => 128,
852         AI_IDN_ALLOW_UNASSIGNED     => 256,
853         AI_IDN_USE_STD3_ASCII_RULES => 512,
854         NI_IDN                      => 32,
855         NI_IDN_ALLOW_UNASSIGNED     => 64,
856         NI_IDN_USE_STD3_ASCII_RULES => 128,
857
858         # Error constants we'll never return, so it doesn't matter what value
859         # these have, nor that we don't provide strings for them
860         EAI_SYSTEM   => -11,
861         EAI_BADHINTS => -1000,
862         EAI_PROTOCOL => -1001
863     );
864
865     foreach my $name ( keys %constants ) {
866         my $value = $constants{$name};
867
868         no strict 'refs';
869         defined &$name or *$name = sub () { $value };
870     }
871
872     %errstr = (
873         # These strings from RFC 2553
874         EAI_BADFLAGS()   => "invalid value for ai_flags",
875         EAI_NONAME()     => "nodename nor servname provided, or not known",
876         EAI_NODATA()     => "no address associated with nodename",
877         EAI_FAMILY()     => "ai_family not supported",
878         EAI_SERVICE()    => "servname not supported for ai_socktype",
879     );
880 }
881
882 # The following functions are used if the system does not have a
883 # getaddrinfo(3) function in libc; and are used to emulate it for the AF_INET
884 # family
885
886 # Borrowed from Regexp::Common::net
887 my $REGEXP_IPv4_DECIMAL = qr/25[0-5]|2[0-4][0-9]|1?[0-9][0-9]{1,2}/;
888 my $REGEXP_IPv4_DOTTEDQUAD = qr/$REGEXP_IPv4_DECIMAL\.$REGEXP_IPv4_DECIMAL\.$REGEXP_IPv4_DECIMAL\.$REGEXP_IPv4_DECIMAL/;
889
890 sub fake_makeerr
891 {
892     my ( $errno ) = @_;
893     my $errstr = $errno == 0 ? "" : ( $errstr{$errno} || $errno );
894     return Scalar::Util::dualvar( $errno, $errstr );
895 }
896
897 sub fake_getaddrinfo
898 {
899     my ( $node, $service, $hints ) = @_;
900
901     $node = "" unless defined $node;
902
903     $service = "" unless defined $service;
904
905     my ( $family, $socktype, $protocol, $flags ) = @$hints{qw( family socktype protocol flags )};
906
907     $family ||= Socket::AF_INET(); # 0 == AF_UNSPEC, which we want too
908     $family == Socket::AF_INET() or return fake_makeerr( EAI_FAMILY() );
909
910     $socktype ||= 0;
911
912     $protocol ||= 0;
913
914     $flags ||= 0;
915
916     my $flag_passive     = $flags & AI_PASSIVE();     $flags &= ~AI_PASSIVE();
917     my $flag_canonname   = $flags & AI_CANONNAME();   $flags &= ~AI_CANONNAME();
918     my $flag_numerichost = $flags & AI_NUMERICHOST(); $flags &= ~AI_NUMERICHOST();
919     my $flag_numericserv = $flags & AI_NUMERICSERV(); $flags &= ~AI_NUMERICSERV();
920
921     # These constants don't apply to AF_INET-only lookups, so we might as well
922     # just ignore them. For AI_ADDRCONFIG we just presume the host has ability
923     # to talk AF_INET. If not we'd have to return no addresses at all. :)
924     $flags &= ~(AI_V4MAPPED()|AI_ALL()|AI_ADDRCONFIG());
925
926     $flags & (AI_IDN()|AI_CANONIDN()|AI_IDN_ALLOW_UNASSIGNED()|AI_IDN_USE_STD3_ASCII_RULES()) and
927         croak "Socket::getaddrinfo() does not support IDN";
928
929     $flags == 0 or return fake_makeerr( EAI_BADFLAGS() );
930
931     $node eq "" and $service eq "" and return fake_makeerr( EAI_NONAME() );
932
933     my $canonname;
934     my @addrs;
935     if( $node ne "" ) {
936         return fake_makeerr( EAI_NONAME() ) if( $flag_numerichost and $node !~ m/^$REGEXP_IPv4_DOTTEDQUAD$/ );
937         ( $canonname, undef, undef, undef, @addrs ) = gethostbyname( $node );
938         defined $canonname or return fake_makeerr( EAI_NONAME() );
939
940         undef $canonname unless $flag_canonname;
941     }
942     else {
943         $addrs[0] = $flag_passive ? Socket::inet_aton( "0.0.0.0" )
944                                   : Socket::inet_aton( "127.0.0.1" );
945     }
946
947     my @ports; # Actually ARRAYrefs of [ socktype, protocol, port ]
948     my $protname = "";
949     if( $protocol ) {
950         $protname = getprotobynumber( $protocol );
951     }
952
953     if( $service ne "" and $service !~ m/^\d+$/ ) {
954         return fake_makeerr( EAI_NONAME() ) if( $flag_numericserv );
955         getservbyname( $service, $protname ) or return fake_makeerr( EAI_SERVICE() );
956     }
957
958     foreach my $this_socktype ( Socket::SOCK_STREAM(), Socket::SOCK_DGRAM(), Socket::SOCK_RAW() ) {
959         next if $socktype and $this_socktype != $socktype;
960
961         my $this_protname = "raw";
962         $this_socktype == Socket::SOCK_STREAM() and $this_protname = "tcp";
963         $this_socktype == Socket::SOCK_DGRAM()  and $this_protname = "udp";
964
965         next if $protname and $this_protname ne $protname;
966
967         my $port;
968         if( $service ne "" ) {
969             if( $service =~ m/^\d+$/ ) {
970                 $port = "$service";
971             }
972             else {
973                 ( undef, undef, $port, $this_protname ) = getservbyname( $service, $this_protname );
974                 next unless defined $port;
975             }
976         }
977         else {
978             $port = 0;
979         }
980
981         push @ports, [ $this_socktype, scalar getprotobyname( $this_protname ) || 0, $port ];
982     }
983
984     my @ret;
985     foreach my $addr ( @addrs ) {
986         foreach my $portspec ( @ports ) {
987             my ( $socktype, $protocol, $port ) = @$portspec;
988             push @ret, {
989                 family    => $family,
990                 socktype  => $socktype,
991                 protocol  => $protocol,
992                 addr      => Socket::pack_sockaddr_in( $port, $addr ),
993                 canonname => undef,
994             };
995         }
996     }
997
998     # Only supply canonname for the first result
999     if( defined $canonname ) {
1000         $ret[0]->{canonname} = $canonname;
1001     }
1002
1003     return ( fake_makeerr( 0 ), @ret );
1004 }
1005
1006 sub fake_getnameinfo
1007 {
1008     my ( $addr, $flags, $xflags ) = @_;
1009
1010     my ( $port, $inetaddr );
1011     eval { ( $port, $inetaddr ) = Socket::unpack_sockaddr_in( $addr ) }
1012         or return fake_makeerr( EAI_FAMILY() );
1013
1014     my $family = Socket::AF_INET();
1015
1016     $flags ||= 0;
1017
1018     my $flag_numerichost = $flags & NI_NUMERICHOST(); $flags &= ~NI_NUMERICHOST();
1019     my $flag_numericserv = $flags & NI_NUMERICSERV(); $flags &= ~NI_NUMERICSERV();
1020     my $flag_nofqdn      = $flags & NI_NOFQDN();      $flags &= ~NI_NOFQDN();
1021     my $flag_namereqd    = $flags & NI_NAMEREQD();    $flags &= ~NI_NAMEREQD();
1022     my $flag_dgram       = $flags & NI_DGRAM()   ;    $flags &= ~NI_DGRAM();
1023
1024     $flags & (NI_IDN()|NI_IDN_ALLOW_UNASSIGNED()|NI_IDN_USE_STD3_ASCII_RULES()) and
1025         croak "Socket::getnameinfo() does not support IDN";
1026
1027     $flags == 0 or return fake_makeerr( EAI_BADFLAGS() );
1028
1029     $xflags ||= 0;
1030
1031     my $node;
1032     if( $xflags & NIx_NOHOST ) {
1033         $node = undef;
1034     }
1035     elsif( $flag_numerichost ) {
1036         $node = Socket::inet_ntoa( $inetaddr );
1037     }
1038     else {
1039         $node = gethostbyaddr( $inetaddr, $family );
1040         if( !defined $node ) {
1041             return fake_makeerr( EAI_NONAME() ) if $flag_namereqd;
1042             $node = Socket::inet_ntoa( $inetaddr );
1043         }
1044         elsif( $flag_nofqdn ) {
1045             my ( $shortname ) = split m/\./, $node;
1046             my ( $fqdn ) = gethostbyname $shortname;
1047             $node = $shortname if defined $fqdn and $fqdn eq $node;
1048         }
1049     }
1050
1051     my $service;
1052     if( $xflags & NIx_NOSERV ) {
1053         $service = undef;
1054     }
1055     elsif( $flag_numericserv ) {
1056         $service = "$port";
1057     }
1058     else {
1059         my $protname = $flag_dgram ? "udp" : "";
1060         $service = getservbyport( $port, $protname );
1061         if( !defined $service ) {
1062             $service = "$port";
1063         }
1064     }
1065
1066     return ( fake_makeerr( 0 ), $node, $service );
1067 }
1068
1069 1;