This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
370353bb2ae3044989ac73ce86d0b7e9590e2262
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar and list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one list argument.)  For instance, splice() has three scalar
19 arguments followed by a list.
20
21 In the syntax descriptions that follow, list operators that expect a
22 list (and provide list context for the elements of the list) are shown
23 with LIST as an argument.  Such a list may consist of any combination
24 of scalar arguments or list values; the list values will be included
25 in the list as if each individual element were interpolated at that
26 point in the list, forming a longer single-dimensional list value.
27 Elements of the LIST should be separated by commas.
28
29 Any function in the list below may be used either with or without
30 parentheses around its arguments.  (The syntax descriptions omit the
31 parentheses.)  If you use the parentheses, the simple (but occasionally
32 surprising) rule is this: It I<LOOKS> like a function, therefore it I<IS> a
33 function, and precedence doesn't matter.  Otherwise it's a list
34 operator or unary operator, and precedence does matter.  And whitespace
35 between the function and left parenthesis doesn't count--so you need to
36 be careful sometimes:
37
38     print 1+2+4;        # Prints 7.
39     print(1+2) + 4;     # Prints 3.
40     print (1+2)+4;      # Also prints 3!
41     print +(1+2)+4;     # Prints 7.
42     print ((1+2)+4);    # Prints 7.
43
44 If you run Perl with the B<-w> switch it can warn you about this.  For
45 example, the third line above produces:
46
47     print (...) interpreted as function at - line 1.
48     Useless use of integer addition in void context at - line 1.
49
50 For functions that can be used in either a scalar or list context,
51 nonabortive failure is generally indicated in a scalar context by
52 returning the undefined value, and in a list context by returning the
53 null list.
54
55 Remember the following important rule: There is B<no rule> that relates
56 the behavior of an expression in list context to its behavior in scalar
57 context, or vice versa.  It might do two totally different things.
58 Each operator and function decides which sort of value it would be most
59 appropriate to return in a scalar context.  Some operators return the
60 length of the list that would have been returned in list context.  Some
61 operators return the first value in the list.  Some operators return the
62 last value in the list.  Some operators return a count of successful
63 operations.  In general, they do what you want, unless you want
64 consistency.
65
66 An named array in scalar context is quite different from what would at
67 first glance appear to be a list in scalar context.  You can't get a list
68 like C<(1,2,3)> into being in scalar context, because the compiler knows
69 the context at compile time.  It would generate the scalar comma operator
70 there, not the list construction version of the comma.  That means it
71 was never a list to start with.
72
73 In general, functions in Perl that serve as wrappers for system calls
74 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
75 true when they succeed and C<undef> otherwise, as is usually mentioned
76 in the descriptions below.  This is different from the C interfaces,
77 which return C<-1> on failure.  Exceptions to this rule are C<wait()>,
78 C<waitpid()>, and C<syscall()>.  System calls also set the special C<$!>
79 variable on failure.  Other functions do not, except accidentally.
80
81 =head2 Perl Functions by Category
82
83 Here are Perl's functions (including things that look like
84 functions, like some keywords and named operators)
85 arranged by category.  Some functions appear in more
86 than one place.
87
88 =over
89
90 =item Functions for SCALARs or strings
91
92 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
93 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
94 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
95
96 =item Regular expressions and pattern matching
97
98 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
99
100 =item Numeric functions
101
102 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
103 C<sin>, C<sqrt>, C<srand>
104
105 =item Functions for real @ARRAYs
106
107 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
108
109 =item Functions for list data
110
111 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
112
113 =item Functions for real %HASHes
114
115 C<delete>, C<each>, C<exists>, C<keys>, C<values>
116
117 =item Input and output functions
118
119 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
120 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
121 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
122 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
123 C<warn>, C<write>
124
125 =item Functions for fixed length data or records
126
127 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
128
129 =item Functions for filehandles, files, or directories
130
131 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
132 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
133 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
134 C<unlink>, C<utime>
135
136 =item Keywords related to the control flow of your perl program
137
138 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<else>, C<elsif>,
139 C<eval>, C<exit>, C<for>, C<foreach>, C<goto>, C<if>, C<last>,
140 C<next>, C<redo>, C<return>, C<sub>, C<unless>, C<wantarray>,
141 C<while>, C<until>
142
143 =item Keywords related to scoping
144
145 C<caller>, C<import>, C<local>, C<my>, C<package>, C<use>
146
147 =item Miscellaneous functions
148
149 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<reset>,
150 C<scalar>, C<undef>, C<wantarray>
151
152 =item Functions for processes and process groups
153
154 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
155 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
156 C<times>, C<wait>, C<waitpid>
157
158 =item Keywords related to perl modules
159
160 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
161
162 =item Keywords related to classes and object-orientedness
163
164 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
165 C<untie>, C<use>
166
167 =item Low-level socket functions
168
169 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
170 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
171 C<socket>, C<socketpair>
172
173 =item System V interprocess communication functions
174
175 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
176 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
177
178 =item Fetching user and group info
179
180 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
181 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
182 C<getpwuid>, C<setgrent>, C<setpwent>
183
184 =item Fetching network info
185
186 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
187 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
188 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
189 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
190 C<setnetent>, C<setprotoent>, C<setservent>
191
192 =item Time-related functions
193
194 C<gmtime>, C<localtime>, C<time>, C<times>
195
196 =item Functions new in perl5
197
198 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
199 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<prototype>, C<qx>,
200 C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
201 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
202
203 * - C<sub> was a keyword in perl4, but in perl5 it is an
204 operator, which can be used in expressions.
205
206 =item Functions obsoleted in perl5
207
208 C<dbmclose>, C<dbmopen>
209
210 =back
211
212 =head2 Portability
213
214 Perl was born in UNIX and therefore it can access all the common UNIX
215 system calls.  In non-UNIX environments the functionality of many
216 UNIX system calls may not be available or the details of the available
217 functionality may be slightly different.  The Perl functions affected
218 by this are:
219
220 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
221 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
222 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
223 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
224 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
225 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
226 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
227 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
228 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
229 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<select>, C<semctl>,
230 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
231 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
232 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
233 C<shmwrite>, C<socketpair>, C<stat>, C<symlink>, C<syscall>,
234 C<sysopen>, C<system>, C<times>, C<truncate>, C<umask>, C<utime>,
235 C<wait>, C<waitpid>
236
237 For more information about the portability of these functions, see
238 L<perlport> and other available platform-specific documentation.
239
240 =head2 Alphabetical Listing of Perl Functions
241
242 =over 8
243
244 =item I<-X> FILEHANDLE
245
246 =item I<-X> EXPR
247
248 =item I<-X>
249
250 A file test, where X is one of the letters listed below.  This unary
251 operator takes one argument, either a filename or a filehandle, and
252 tests the associated file to see if something is true about it.  If the
253 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
254 Unless otherwise documented, it returns C<1> for TRUE and C<''> for FALSE, or
255 the undefined value if the file doesn't exist.  Despite the funny
256 names, precedence is the same as any other named unary operator, and
257 the argument may be parenthesized like any other unary operator.  The
258 operator may be any of:
259 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
260 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
261
262     -r  File is readable by effective uid/gid.
263     -w  File is writable by effective uid/gid.
264     -x  File is executable by effective uid/gid.
265     -o  File is owned by effective uid.
266
267     -R  File is readable by real uid/gid.
268     -W  File is writable by real uid/gid.
269     -X  File is executable by real uid/gid.
270     -O  File is owned by real uid.
271
272     -e  File exists.
273     -z  File has zero size.
274     -s  File has nonzero size (returns size).
275
276     -f  File is a plain file.
277     -d  File is a directory.
278     -l  File is a symbolic link.
279     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
280     -S  File is a socket.
281     -b  File is a block special file.
282     -c  File is a character special file.
283     -t  Filehandle is opened to a tty.
284
285     -u  File has setuid bit set.
286     -g  File has setgid bit set.
287     -k  File has sticky bit set.
288
289     -T  File is a text file.
290     -B  File is a binary file (opposite of -T).
291
292     -M  Age of file in days when script started.
293     -A  Same for access time.
294     -C  Same for inode change time.
295
296 Example:
297
298     while (<>) {
299         chop;
300         next unless -f $_;      # ignore specials
301         #...
302     }
303
304 The interpretation of the file permission operators C<-r>, C<-R>,
305 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
306 of the file and the uids and gids of the user.  There may be other
307 reasons you can't actually read, write, or execute the file.  Such
308 reasons may be for example network filesystem access controls, ACLs
309 (access control lists), read-only filesystems, and unrecognized
310 executable formats.
311
312 Also note that, for the superuser on the local filesystems, C<-r>,
313 C<-R>, C<-w>, and C<-W> always return 1, and C<-x> and C<-X> return 1
314 if any execute bit is set in the mode.  Scripts run by the superuser
315 may thus need to do a stat() to determine the actual mode of the file,
316 or temporarily set the uid to something else.
317
318 If you are using ACLs, there is a pragma called C<filetest> that may
319 produce more accurate results than the bare stat() mode bits.
320
321 When under the C<use filetest 'access'> the above-mentioned filetests
322 will test whether the permission can (not) be granted using the
323 access() family of system calls.  Also note that the C<-x> and C<-X> may
324 under this pragma return true even if there are no execute permission
325 bits set (nor any extra execute permission ACLs).  This strangeness is
326 due to the underlying system calls' definitions.  Read the
327 documentation for the C<filetest> pragma for more information.
328
329 Note that C<-s/a/b/> does not do a negated substitution.  Saying
330 C<-exp($foo)> still works as expected, however--only single letters
331 following a minus are interpreted as file tests.
332
333 The C<-T> and C<-B> switches work as follows.  The first block or so of the
334 file is examined for odd characters such as strange control codes or
335 characters with the high bit set.  If too many strange characters (E<gt>30%)
336 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
337 containing null in the first block is considered a binary file.  If C<-T>
338 or C<-B> is used on a filehandle, the current stdio buffer is examined
339 rather than the first block.  Both C<-T> and C<-B> return TRUE on a null
340 file, or a file at EOF when testing a filehandle.  Because you have to
341 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
342 against the file first, as in C<next unless -f $file && -T $file>.
343
344 If any of the file tests (or either the C<stat()> or C<lstat()> operators) are given
345 the special filehandle consisting of a solitary underline, then the stat
346 structure of the previous file test (or stat operator) is used, saving
347 a system call.  (This doesn't work with C<-t>, and you need to remember
348 that lstat() and C<-l> will leave values in the stat structure for the
349 symbolic link, not the real file.)  Example:
350
351     print "Can do.\n" if -r $a || -w _ || -x _;
352
353     stat($filename);
354     print "Readable\n" if -r _;
355     print "Writable\n" if -w _;
356     print "Executable\n" if -x _;
357     print "Setuid\n" if -u _;
358     print "Setgid\n" if -g _;
359     print "Sticky\n" if -k _;
360     print "Text\n" if -T _;
361     print "Binary\n" if -B _;
362
363 =item abs VALUE
364
365 =item abs
366
367 Returns the absolute value of its argument.
368 If VALUE is omitted, uses C<$_>.
369
370 =item accept NEWSOCKET,GENERICSOCKET
371
372 Accepts an incoming socket connect, just as the accept(2) system call
373 does.  Returns the packed address if it succeeded, FALSE otherwise.
374 See example in L<perlipc/"Sockets: Client/Server Communication">.
375
376 =item alarm SECONDS
377
378 =item alarm
379
380 Arranges to have a SIGALRM delivered to this process after the
381 specified number of seconds have elapsed.  If SECONDS is not specified,
382 the value stored in C<$_> is used. (On some machines,
383 unfortunately, the elapsed time may be up to one second less than you
384 specified because of how seconds are counted.)  Only one timer may be
385 counting at once.  Each call disables the previous timer, and an
386 argument of C<0> may be supplied to cancel the previous timer without
387 starting a new one.  The returned value is the amount of time remaining
388 on the previous timer.
389
390 For delays of finer granularity than one second, you may use Perl's
391 C<syscall()> interface to access setitimer(2) if your system supports it,
392 or else see L</select()>.  It is usually a mistake to intermix C<alarm()>
393 and C<sleep()> calls.
394
395 If you want to use C<alarm()> to time out a system call you need to use an
396 C<eval()>/C<die()> pair.  You can't rely on the alarm causing the system call to
397 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
398 restart system calls on some systems.  Using C<eval()>/C<die()> always works,
399 modulo the caveats given in L<perlipc/"Signals">.
400
401     eval {
402         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
403         alarm $timeout;
404         $nread = sysread SOCKET, $buffer, $size;
405         alarm 0;
406     };
407     if ($@) {
408         die unless $@ eq "alarm\n";   # propagate unexpected errors
409         # timed out
410     }
411     else {
412         # didn't
413     }
414
415 =item atan2 Y,X
416
417 Returns the arctangent of Y/X in the range -PI to PI.
418
419 For the tangent operation, you may use the C<POSIX::tan()>
420 function, or use the familiar relation:
421
422     sub tan { sin($_[0]) / cos($_[0])  }
423
424 =item bind SOCKET,NAME
425
426 Binds a network address to a socket, just as the bind system call
427 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
428 packed address of the appropriate type for the socket.  See the examples in
429 L<perlipc/"Sockets: Client/Server Communication">.
430
431 =item binmode FILEHANDLE
432
433 Arranges for the file to be read or written in "binary" mode in operating
434 systems that distinguish between binary and text files.  Files that are
435 not in binary mode have CR LF sequences translated to LF on input and LF
436 translated to CR LF on output.  Binmode has no effect under Unix; in MS-DOS
437 and similarly archaic systems, it may be imperative--otherwise your
438 MS-DOS-damaged C library may mangle your file.  The key distinction between
439 systems that need C<binmode()> and those that don't is their text file
440 formats.  Systems like Unix, MacOS, and Plan9 that delimit lines with a single
441 character, and that encode that character in C as C<"\n">, do not need
442 C<binmode()>.  The rest need it.  If FILEHANDLE is an expression, the value
443 is taken as the name of the filehandle.
444
445 =item bless REF,CLASSNAME
446
447 =item bless REF
448
449 This function tells the thingy referenced by REF that it is now
450 an object in the CLASSNAME package--or the current package if no CLASSNAME
451 is specified, which is often the case.  It returns the reference for
452 convenience, because a C<bless()> is often the last thing in a constructor.
453 Always use the two-argument version if the function doing the blessing
454 might be inherited by a derived class.  See L<perltoot> and L<perlobj>
455 for more about the blessing (and blessings) of objects.
456
457 Creating objects in lowercased CLASSNAMEs should be avoided.  Such 
458 namespaces should be considered reserved for Perl pragmata and objects
459 that may be created to implement internal operations.
460
461 See L<perlmod/"Perl Modules">.
462
463 =item caller EXPR
464
465 =item caller
466
467 Returns the context of the current subroutine call.  In scalar context,
468 returns the caller's package name if there is a caller, that is, if
469 we're in a subroutine or C<eval()> or C<require()>, and the undefined value
470 otherwise.  In list context, returns
471
472     ($package, $filename, $line) = caller;
473
474 With EXPR, it returns some extra information that the debugger uses to
475 print a stack trace.  The value of EXPR indicates how many call frames
476 to go back before the current one.
477
478     ($package, $filename, $line, $subroutine,
479      $hasargs, $wantarray, $evaltext, $is_require) = caller($i);
480
481 Here C<$subroutine> may be C<"(eval)"> if the frame is not a subroutine
482 call, but an C<eval()>.  In such a case additional elements C<$evaltext> and
483 C<$is_require> are set: C<$is_require> is true if the frame is created by a
484 C<require> or C<use> statement, C<$evaltext> contains the text of the
485 C<eval EXPR> statement.  In particular, for a C<eval BLOCK> statement,
486 C<$filename> is C<"(eval)">, but C<$evaltext> is undefined.  (Note also that
487 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
488 frame.
489
490 Furthermore, when called from within the DB package, caller returns more
491 detailed information: it sets the list variable C<@DB::args> to be the
492 arguments with which the subroutine was invoked.
493
494 Be aware that the optimizer might have optimized call frames away before
495 C<caller()> had a chance to get the information. That means that C<caller(N)>
496 might not return information about the call frame you expect it do, for
497 C<N E<gt> 1>. In particular, C<@DB::args> might have information from the 
498 previous time C<caller()> was called.
499
500 =item chdir EXPR
501
502 Changes the working directory to EXPR, if possible.  If EXPR is
503 omitted, changes to home directory.  Returns TRUE upon success, FALSE
504 otherwise.  See example under C<die()>.
505
506 =item chmod LIST
507
508 Changes the permissions of a list of files.  The first element of the
509 list must be the numerical mode, which should probably be an octal
510 number, and which definitely should I<not> a string of octal digits:
511 C<0644> is okay, C<'0644'> is not.  Returns the number of files
512 successfully changed.  See also L</oct>, if all you have is a string.
513
514     $cnt = chmod 0755, 'foo', 'bar';
515     chmod 0755, @executables;
516     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
517                                              # --w----r-T
518     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
519     $mode = 0644;   chmod $mode, 'foo';      # this is best
520
521 =item chomp VARIABLE
522
523 =item chomp LIST
524
525 =item chomp
526
527 This is a slightly safer version of L</chop>.  It removes any
528 line ending that corresponds to the current value of C<$/> (also known as
529 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
530 number of characters removed from all its arguments.  It's often used to
531 remove the newline from the end of an input record when you're worried
532 that the final record may be missing its newline.  When in paragraph mode
533 (C<$/ = "">), it removes all trailing newlines from the string.  If
534 VARIABLE is omitted, it chomps C<$_>.  Example:
535
536     while (<>) {
537         chomp;  # avoid \n on last field
538         @array = split(/:/);
539         # ...
540     }
541
542 You can actually chomp anything that's an lvalue, including an assignment:
543
544     chomp($cwd = `pwd`);
545     chomp($answer = <STDIN>);
546
547 If you chomp a list, each element is chomped, and the total number of
548 characters removed is returned.
549
550 =item chop VARIABLE
551
552 =item chop LIST
553
554 =item chop
555
556 Chops off the last character of a string and returns the character
557 chopped.  It's used primarily to remove the newline from the end of an
558 input record, but is much more efficient than C<s/\n//> because it neither
559 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
560 Example:
561
562     while (<>) {
563         chop;   # avoid \n on last field
564         @array = split(/:/);
565         #...
566     }
567
568 You can actually chop anything that's an lvalue, including an assignment:
569
570     chop($cwd = `pwd`);
571     chop($answer = <STDIN>);
572
573 If you chop a list, each element is chopped.  Only the value of the
574 last C<chop()> is returned.
575
576 Note that C<chop()> returns the last character.  To return all but the last
577 character, use C<substr($string, 0, -1)>.
578
579 =item chown LIST
580
581 Changes the owner (and group) of a list of files.  The first two
582 elements of the list must be the I<NUMERICAL> uid and gid, in that order.
583 Returns the number of files successfully changed.
584
585     $cnt = chown $uid, $gid, 'foo', 'bar';
586     chown $uid, $gid, @filenames;
587
588 Here's an example that looks up nonnumeric uids in the passwd file:
589
590     print "User: ";
591     chop($user = <STDIN>);
592     print "Files: ";
593     chop($pattern = <STDIN>);
594
595     ($login,$pass,$uid,$gid) = getpwnam($user)
596         or die "$user not in passwd file";
597
598     @ary = glob($pattern);      # expand filenames
599     chown $uid, $gid, @ary;
600
601 On most systems, you are not allowed to change the ownership of the
602 file unless you're the superuser, although you should be able to change
603 the group to any of your secondary groups.  On insecure systems, these
604 restrictions may be relaxed, but this is not a portable assumption.
605
606 =item chr NUMBER
607
608 =item chr
609
610 Returns the character represented by that NUMBER in the character set.
611 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
612 chr(0x263a) is a Unicode smiley face (but only within the scope of a
613 C<use utf8>).  For the reverse, use L</ord>.
614
615 If NUMBER is omitted, uses C<$_>.
616
617 =item chroot FILENAME
618
619 =item chroot
620
621 This function works like the system call by the same name: it makes the
622 named directory the new root directory for all further pathnames that
623 begin with a C<"/"> by your process and all its children.  (It doesn't
624 change your current working directory, which is unaffected.)  For security
625 reasons, this call is restricted to the superuser.  If FILENAME is
626 omitted, does a C<chroot()> to C<$_>.
627
628 =item close FILEHANDLE
629
630 =item close
631
632 Closes the file or pipe associated with the file handle, returning TRUE
633 only if stdio successfully flushes buffers and closes the system file
634 descriptor. Closes the currently selected filehandle if the argument
635 is omitted.
636
637 You don't have to close FILEHANDLE if you are immediately going to do
638 another C<open()> on it, because C<open()> will close it for you.  (See
639 C<open()>.)  However, an explicit C<close()> on an input file resets the line
640 counter (C<$.>), while the implicit close done by C<open()> does not.
641
642 If the file handle came from a piped open C<close()> will additionally
643 return FALSE if one of the other system calls involved fails or if the
644 program exits with non-zero status.  (If the only problem was that the
645 program exited non-zero C<$!> will be set to C<0>.)  Also, closing a pipe 
646 waits for the process executing on the pipe to complete, in case you
647 want to look at the output of the pipe afterwards.  Closing a pipe
648 explicitly also puts the exit status value of the command into C<$?>.
649
650 Example:
651
652     open(OUTPUT, '|sort >foo')  # pipe to sort
653         or die "Can't start sort: $!";
654     #...                        # print stuff to output
655     close OUTPUT                # wait for sort to finish
656         or warn $! ? "Error closing sort pipe: $!"
657                    : "Exit status $? from sort";
658     open(INPUT, 'foo')          # get sort's results
659         or die "Can't open 'foo' for input: $!";
660
661 FILEHANDLE may be an expression whose value can be used as an indirect
662 filehandle, usually the real filehandle name.
663
664 =item closedir DIRHANDLE
665
666 Closes a directory opened by C<opendir()> and returns the success of that
667 system call.
668
669 DIRHANDLE may be an expression whose value can be used as an indirect
670 dirhandle, usually the real dirhandle name.
671
672 =item connect SOCKET,NAME
673
674 Attempts to connect to a remote socket, just as the connect system call
675 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
676 packed address of the appropriate type for the socket.  See the examples in
677 L<perlipc/"Sockets: Client/Server Communication">.
678
679 =item continue BLOCK
680
681 Actually a flow control statement rather than a function.  If there is a
682 C<continue> BLOCK attached to a BLOCK (typically in a L</while> or
683 L</foreach>), it is always executed just before the conditional is about to
684 be evaluated again, just like the third part of a L</for> loop in C.  Thus
685 it can be used to increment a loop variable, even when the loop has been
686 continued via the C<next> statement (which is similar to the C C<continue>
687 statement).
688
689 L</last>, L</next>, or L</redo> may appear within a C<continue>
690 block. C<last> and C<redo> will behave as if they had been executed within
691 the main block. So will C<next>, but since it will execute a C<continue>
692 block, it may be more entertaining.
693
694     while (EXPR) {
695         ### redo always comes here
696         do_something;
697     } continue {
698         ### next always comes here
699         do_something_else;
700         # then back the top to re-check EXPR
701     }
702     ### last always comes here
703
704 Omitting the C<continue> section is semantically equivalent to using an
705 empty one, logically enough. In that case, C<next> goes directly back
706 to check the condition at the top of the loop.
707
708 See also L<perlsyn>.
709
710 =item cos EXPR
711
712 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
713 takes cosine of C<$_>.
714
715 For the inverse cosine operation, you may use the C<POSIX::acos()>
716 function, or use this relation:
717
718     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
719
720 =item crypt PLAINTEXT,SALT
721
722 Encrypts a string exactly like the crypt(3) function in the C library
723 (assuming that you actually have a version there that has not been
724 extirpated as a potential munition).  This can prove useful for checking
725 the password file for lousy passwords, amongst other things.  Only the
726 guys wearing white hats should do this.
727
728 Note that C<crypt()> is intended to be a one-way function, much like breaking
729 eggs to make an omelette.  There is no (known) corresponding decrypt
730 function.  As a result, this function isn't all that useful for
731 cryptography.  (For that, see your nearby CPAN mirror.)
732
733 When verifying an existing encrypted string you should use the encrypted
734 text as the salt (like C<crypt($plain, $crypted) eq $crypted>).  This
735 allows your code to work with the standard C<crypt()> and with more
736 exotic implementations.  When choosing a new salt create a random two
737 character string whose characters come from the set C<[./0-9A-Za-z]>
738 (like C<join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
739
740 Here's an example that makes sure that whoever runs this program knows
741 their own password:
742
743     $pwd = (getpwuid($<))[1];
744
745     system "stty -echo";
746     print "Password: ";
747     chomp($word = <STDIN>);
748     print "\n";
749     system "stty echo";
750
751     if (crypt($word, $pwd) ne $pwd) {
752         die "Sorry...\n";
753     } else {
754         print "ok\n";
755     }
756
757 Of course, typing in your own password to whoever asks you
758 for it is unwise.
759
760 =item dbmclose HASH
761
762 [This function has been superseded by the C<untie()> function.]
763
764 Breaks the binding between a DBM file and a hash.
765
766 =item dbmopen HASH,DBNAME,MODE
767
768 [This function has been superseded by the C<tie()> function.]
769
770 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
771 hash.  HASH is the name of the hash.  (Unlike normal C<open()>, the first
772 argument is I<NOT> a filehandle, even though it looks like one).  DBNAME
773 is the name of the database (without the F<.dir> or F<.pag> extension if
774 any).  If the database does not exist, it is created with protection
775 specified by MODE (as modified by the C<umask()>).  If your system supports
776 only the older DBM functions, you may perform only one C<dbmopen()> in your
777 program.  In older versions of Perl, if your system had neither DBM nor
778 ndbm, calling C<dbmopen()> produced a fatal error; it now falls back to
779 sdbm(3).
780
781 If you don't have write access to the DBM file, you can only read hash
782 variables, not set them.  If you want to test whether you can write,
783 either use file tests or try setting a dummy hash entry inside an C<eval()>,
784 which will trap the error.
785
786 Note that functions such as C<keys()> and C<values()> may return huge lists
787 when used on large DBM files.  You may prefer to use the C<each()>
788 function to iterate over large DBM files.  Example:
789
790     # print out history file offsets
791     dbmopen(%HIST,'/usr/lib/news/history',0666);
792     while (($key,$val) = each %HIST) {
793         print $key, ' = ', unpack('L',$val), "\n";
794     }
795     dbmclose(%HIST);
796
797 See also L<AnyDBM_File> for a more general description of the pros and
798 cons of the various dbm approaches, as well as L<DB_File> for a particularly
799 rich implementation.
800
801 =item defined EXPR
802
803 =item defined
804
805 Returns a Boolean value telling whether EXPR has a value other than
806 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
807 checked.
808
809 Many operations return C<undef> to indicate failure, end of file,
810 system error, uninitialized variable, and other exceptional
811 conditions.  This function allows you to distinguish C<undef> from
812 other values.  (A simple Boolean test will not distinguish among
813 C<undef>, zero, the empty string, and C<"0">, which are all equally
814 false.)  Note that since C<undef> is a valid scalar, its presence
815 doesn't I<necessarily> indicate an exceptional condition: C<pop()>
816 returns C<undef> when its argument is an empty array, I<or> when the
817 element to return happens to be C<undef>.
818
819 You may also use C<defined()> to check whether a subroutine exists, by
820 saying C<defined &func> without parentheses.  On the other hand, use
821 of C<defined()> upon aggregates (hashes and arrays) is not guaranteed to
822 produce intuitive results, and should probably be avoided.
823
824 When used on a hash element, it tells you whether the value is defined,
825 not whether the key exists in the hash.  Use L</exists> for the latter
826 purpose.
827
828 Examples:
829
830     print if defined $switch{'D'};
831     print "$val\n" while defined($val = pop(@ary));
832     die "Can't readlink $sym: $!"
833         unless defined($value = readlink $sym);
834     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
835     $debugging = 0 unless defined $debugging;
836
837 Note:  Many folks tend to overuse C<defined()>, and then are surprised to
838 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
839 defined values.  For example, if you say
840
841     "ab" =~ /a(.*)b/;
842
843 The pattern match succeeds, and C<$1> is defined, despite the fact that it
844 matched "nothing".  But it didn't really match nothing--rather, it
845 matched something that happened to be C<0> characters long.  This is all
846 very above-board and honest.  When a function returns an undefined value,
847 it's an admission that it couldn't give you an honest answer.  So you
848 should use C<defined()> only when you're questioning the integrity of what
849 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
850 what you want.
851
852 Currently, using C<defined()> on an entire array or hash reports whether
853 memory for that aggregate has ever been allocated.  So an array you set
854 to the empty list appears undefined initially, and one that once was full
855 and that you then set to the empty list still appears defined.  You
856 should instead use a simple test for size:
857
858     if (@an_array) { print "has array elements\n" }
859     if (%a_hash)   { print "has hash members\n"   }
860
861 Using C<undef()> on these, however, does clear their memory and then report
862 them as not defined anymore, but you shouldn't do that unless you don't
863 plan to use them again, because it saves time when you load them up
864 again to have memory already ready to be filled.  The normal way to 
865 free up space used by an aggregate is to assign the empty list.
866
867 This counterintuitive behavior of C<defined()> on aggregates may be
868 changed, fixed, or broken in a future release of Perl.
869
870 See also L</undef>, L</exists>, L</ref>.
871
872 =item delete EXPR
873
874 Deletes the specified key(s) and their associated values from a hash.
875 For each key, returns the deleted value associated with that key, or
876 the undefined value if there was no such key.  Deleting from C<$ENV{}>
877 modifies the environment.  Deleting from a hash tied to a DBM file
878 deletes the entry from the DBM file.  (But deleting from a C<tie()>d hash
879 doesn't necessarily return anything.)
880
881 The following deletes all the values of a hash:
882
883     foreach $key (keys %HASH) {
884         delete $HASH{$key};
885     }
886
887 And so does this:
888
889     delete @HASH{keys %HASH}
890
891 (But both of these are slower than just assigning the empty list, or
892 using C<undef()>.)  Note that the EXPR can be arbitrarily complicated as
893 long as the final operation is a hash element lookup or hash slice:
894
895     delete $ref->[$x][$y]{$key};
896     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
897
898 =item die LIST
899
900 Outside an C<eval()>, prints the value of LIST to C<STDERR> and exits with
901 the current value of C<$!> (errno).  If C<$!> is C<0>, exits with the value of
902 C<($? E<gt>E<gt> 8)> (backtick `command` status).  If C<($? E<gt>E<gt> 8)>
903 is C<0>, exits with C<255>.  Inside an C<eval(),> the error message is stuffed into
904 C<$@> and the C<eval()> is terminated with the undefined value.  This makes
905 C<die()> the way to raise an exception.
906
907 Equivalent examples:
908
909     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
910     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
911
912 If the value of EXPR does not end in a newline, the current script line
913 number and input line number (if any) are also printed, and a newline
914 is supplied.  Hint: sometimes appending C<", stopped"> to your message
915 will cause it to make better sense when the string C<"at foo line 123"> is
916 appended.  Suppose you are running script "canasta".
917
918     die "/etc/games is no good";
919     die "/etc/games is no good, stopped";
920
921 produce, respectively
922
923     /etc/games is no good at canasta line 123.
924     /etc/games is no good, stopped at canasta line 123.
925
926 See also C<exit()> and C<warn()>.
927
928 If LIST is empty and C<$@> already contains a value (typically from a
929 previous eval) that value is reused after appending C<"\t...propagated">.
930 This is useful for propagating exceptions:
931
932     eval { ... };
933     die unless $@ =~ /Expected exception/;
934
935 If C<$@> is empty then the string C<"Died"> is used.
936
937 You can arrange for a callback to be run just before the C<die()> does
938 its deed, by setting the C<$SIG{__DIE__}> hook.  The associated handler
939 will be called with the error text and can change the error message, if
940 it sees fit, by calling C<die()> again.  See L<perlvar/$SIG{expr}> for details on
941 setting C<%SIG> entries, and L<"eval BLOCK"> for some examples.
942
943 Note that the C<$SIG{__DIE__}> hook is called even inside eval()ed
944 blocks/strings.  If one wants the hook to do nothing in such
945 situations, put
946
947         die @_ if $^S;
948
949 as the first line of the handler (see L<perlvar/$^S>).
950
951 =item do BLOCK
952
953 Not really a function.  Returns the value of the last command in the
954 sequence of commands indicated by BLOCK.  When modified by a loop
955 modifier such as L</while> or L</until>, executes the BLOCK once
956 before testing the loop condition.  (On other statements the loop
957 modifiers test the conditional first.)
958
959 C<do BLOCK> does I<not> count as a loop, so the loop control statements
960 L</next>, L</last> or L</redo> cannot be used to leave or restart the block.
961
962 =item do SUBROUTINE(LIST)
963
964 A deprecated form of subroutine call.  See L<perlsub>.
965
966 =item do EXPR
967
968 Uses the value of EXPR as a filename and executes the contents of the
969 file as a Perl script.  Its primary use is to include subroutines
970 from a Perl subroutine library.
971
972     do 'stat.pl';
973
974 is just like
975
976     scalar eval `cat stat.pl`;
977
978 except that it's more efficient and concise, keeps track of the
979 current filename for error messages, and searches all the B<-I>
980 libraries if the file isn't in the current directory (see also the @INC
981 array in L<perlvar/Predefined Names>).  It is also different in how
982 code evaluated with C<do FILENAME> doesn't see lexicals in the enclosing
983 scope like C<eval STRING> does.  It's the same, however, in that it does
984 reparse the file every time you call it, so you probably don't want to
985 do this inside a loop.
986
987 If C<do> cannot read the file, it returns undef and sets C<$!> to the
988 error.    If C<do> can read the file but cannot compile it, it
989 returns undef and sets an error message in C<$@>.   If the file is
990 successfully compiled, C<do> returns the value of the last expression
991 evaluated.
992
993 Note that inclusion of library modules is better done with the
994 C<use()> and C<require()> operators, which also do automatic error checking
995 and raise an exception if there's a problem.
996
997 You might like to use C<do> to read in a program configuration
998 file.  Manual error checking can be done this way:
999
1000     # read in config files: system first, then user 
1001     for $file ("/share/prog/defaults.rc",
1002                "$ENV{HOME}/.someprogrc") {
1003         unless ($return = do $file) {
1004             warn "couldn't parse $file: $@" if $@;
1005             warn "couldn't do $file: $!"    unless defined $return;
1006             warn "couldn't run $file"       unless $return;
1007         }
1008     }
1009
1010 =item dump LABEL
1011
1012 This causes an immediate core dump.  Primarily this is so that you can
1013 use the B<undump> program to turn your core dump into an executable binary
1014 after having initialized all your variables at the beginning of the
1015 program.  When the new binary is executed it will begin by executing a
1016 C<goto LABEL> (with all the restrictions that C<goto> suffers).  Think of
1017 it as a goto with an intervening core dump and reincarnation.  If C<LABEL>
1018 is omitted, restarts the program from the top.  WARNING: Any files
1019 opened at the time of the dump will NOT be open any more when the
1020 program is reincarnated, with possible resulting confusion on the part
1021 of Perl.  See also B<-u> option in L<perlrun>.
1022
1023 Example:
1024
1025     #!/usr/bin/perl
1026     require 'getopt.pl';
1027     require 'stat.pl';
1028     %days = (
1029         'Sun' => 1,
1030         'Mon' => 2,
1031         'Tue' => 3,
1032         'Wed' => 4,
1033         'Thu' => 5,
1034         'Fri' => 6,
1035         'Sat' => 7,
1036     );
1037
1038     dump QUICKSTART if $ARGV[0] eq '-d';
1039
1040     QUICKSTART:
1041     Getopt('f');
1042
1043 This operator is largely obsolete, partly because it's very hard to 
1044 convert a core file into an executable, and because the real perl-to-C
1045 compiler has superseded it.
1046
1047 =item each HASH
1048
1049 When called in list context, returns a 2-element list consisting of the
1050 key and value for the next element of a hash, so that you can iterate over
1051 it.  When called in scalar context, returns the key for only the "next"
1052 element in the hash.  (Note: Keys may be C<"0"> or C<"">, which are logically
1053 false; you may wish to avoid constructs like C<while ($k = each %foo) {}>
1054 for this reason.)
1055
1056 Entries are returned in an apparently random order.  The actual random
1057 order is subject to change in future versions of perl, but it is guaranteed
1058 to be in the same order as either the C<keys()> or C<values()> function
1059 would produce on the same (unmodified) hash.
1060
1061 When the hash is entirely read, a null array is returned in list context
1062 (which when assigned produces a FALSE (C<0>) value), and C<undef> in
1063 scalar context.  The next call to C<each()> after that will start iterating
1064 again.  There is a single iterator for each hash, shared by all C<each()>,
1065 C<keys()>, and C<values()> function calls in the program; it can be reset by
1066 reading all the elements from the hash, or by evaluating C<keys HASH> or
1067 C<values HASH>.  If you add or delete elements of a hash while you're
1068 iterating over it, you may get entries skipped or duplicated, so don't.
1069
1070 The following prints out your environment like the printenv(1) program,
1071 only in a different order:
1072
1073     while (($key,$value) = each %ENV) {
1074         print "$key=$value\n";
1075     }
1076
1077 See also C<keys()>, C<values()> and C<sort()>.
1078
1079 =item else BLOCK
1080
1081 =item elsif (EXPR) BLOCK
1082
1083 See L</if>.
1084
1085 =item eof FILEHANDLE
1086
1087 =item eof ()
1088
1089 =item eof
1090
1091 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1092 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1093 gives the real filehandle.  (Note that this function actually
1094 reads a character and then C<ungetc()>s it, so isn't very useful in an
1095 interactive context.)  Do not read from a terminal file (or call
1096 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  Filetypes such
1097 as terminals may lose the end-of-file condition if you do.
1098
1099 An C<eof> without an argument uses the last file read as argument.
1100 Using C<eof()> with empty parentheses is very different.  It indicates the pseudo file formed of
1101 the files listed on the command line, i.e., C<eof()> is reasonable to
1102 use inside a C<while (E<lt>E<gt>)> loop to detect the end of only the
1103 last file.  Use C<eof(ARGV)> or eof without the parentheses to test
1104 I<EACH> file in a while (E<lt>E<gt>) loop.  Examples:
1105
1106     # reset line numbering on each input file
1107     while (<>) {
1108         next if /^\s*#/;        # skip comments 
1109         print "$.\t$_";
1110     } continue {
1111         close ARGV  if eof;     # Not eof()!
1112     }
1113
1114     # insert dashes just before last line of last file
1115     while (<>) {
1116         if (eof()) {            # check for end of current file
1117             print "--------------\n";
1118             close(ARGV);        # close or break; is needed if we
1119                                 # are reading from the terminal
1120         }
1121         print;
1122     }
1123
1124 Practical hint: you almost never need to use C<eof> in Perl, because the
1125 input operators return false values when they run out of data, or if there
1126 was an error.
1127
1128 =item eval EXPR
1129
1130 =item eval BLOCK
1131
1132 In the first form, the return value of EXPR is parsed and executed as if it
1133 were a little Perl program.  The value of the expression (which is itself
1134 determined within scalar context) is first parsed, and if there weren't any
1135 errors, executed in the context of the current Perl program, so that any
1136 variable settings or subroutine and format definitions remain afterwards.
1137 Note that the value is parsed every time the eval executes.  If EXPR is
1138 omitted, evaluates C<$_>.  This form is typically used to delay parsing
1139 and subsequent execution of the text of EXPR until run time.
1140
1141 In the second form, the code within the BLOCK is parsed only once--at the
1142 same time the code surrounding the eval itself was parsed--and executed
1143 within the context of the current Perl program.  This form is typically
1144 used to trap exceptions more efficiently than the first (see below), while
1145 also providing the benefit of checking the code within BLOCK at compile
1146 time.
1147
1148 The final semicolon, if any, may be omitted from the value of EXPR or within
1149 the BLOCK.
1150
1151 In both forms, the value returned is the value of the last expression
1152 evaluated inside the mini-program; a return statement may be also used, just
1153 as with subroutines.  The expression providing the return value is evaluated
1154 in void, scalar, or list context, depending on the context of the eval itself.
1155 See L</wantarray> for more on how the evaluation context can be determined.
1156
1157 If there is a syntax error or runtime error, or a C<die()> statement is
1158 executed, an undefined value is returned by C<eval()>, and C<$@> is set to the
1159 error message.  If there was no error, C<$@> is guaranteed to be a null
1160 string.  Beware that using C<eval()> neither silences perl from printing
1161 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1162 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1163 L</warn> and L<perlvar>.
1164
1165 Note that, because C<eval()> traps otherwise-fatal errors, it is useful for
1166 determining whether a particular feature (such as C<socket()> or C<symlink()>)
1167 is implemented.  It is also Perl's exception trapping mechanism, where
1168 the die operator is used to raise exceptions.
1169
1170 If the code to be executed doesn't vary, you may use the eval-BLOCK
1171 form to trap run-time errors without incurring the penalty of
1172 recompiling each time.  The error, if any, is still returned in C<$@>.
1173 Examples:
1174
1175     # make divide-by-zero nonfatal
1176     eval { $answer = $a / $b; }; warn $@ if $@;
1177
1178     # same thing, but less efficient
1179     eval '$answer = $a / $b'; warn $@ if $@;
1180
1181     # a compile-time error
1182     eval { $answer = };                 # WRONG
1183
1184     # a run-time error
1185     eval '$answer =';   # sets $@
1186
1187 When using the C<eval{}> form as an exception trap in libraries, you may
1188 wish not to trigger any C<__DIE__> hooks that user code may have
1189 installed.  You can use the C<local $SIG{__DIE__}> construct for this
1190 purpose, as shown in this example:
1191
1192     # a very private exception trap for divide-by-zero
1193     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1194     warn $@ if $@;
1195
1196 This is especially significant, given that C<__DIE__> hooks can call
1197 C<die()> again, which has the effect of changing their error messages:
1198
1199     # __DIE__ hooks may modify error messages
1200     {
1201        local $SIG{'__DIE__'} =
1202               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1203        eval { die "foo lives here" };
1204        print $@ if $@;                # prints "bar lives here"
1205     }
1206
1207 With an C<eval()>, you should be especially careful to remember what's
1208 being looked at when:
1209
1210     eval $x;            # CASE 1
1211     eval "$x";          # CASE 2
1212
1213     eval '$x';          # CASE 3
1214     eval { $x };        # CASE 4
1215
1216     eval "\$$x++";      # CASE 5
1217     $$x++;              # CASE 6
1218
1219 Cases 1 and 2 above behave identically: they run the code contained in
1220 the variable C<$x>.  (Although case 2 has misleading double quotes making
1221 the reader wonder what else might be happening (nothing is).)  Cases 3
1222 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1223 does nothing but return the value of C<$x>.  (Case 4 is preferred for
1224 purely visual reasons, but it also has the advantage of compiling at
1225 compile-time instead of at run-time.)  Case 5 is a place where
1226 normally you I<WOULD> like to use double quotes, except that in this
1227 particular situation, you can just use symbolic references instead, as
1228 in case 6.
1229
1230 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1231 C<next>, C<last> or C<redo> cannot be used to leave or restart the block.
1232
1233
1234 =item exec LIST
1235
1236 =item exec PROGRAM LIST
1237
1238 The C<exec()> function executes a system command I<AND NEVER RETURNS> -
1239 use C<system()> instead of C<exec()> if you want it to return. It fails and
1240 returns FALSE only if the command does not exist I<and> it is executed
1241 directly instead of via your system's command shell (see below).
1242
1243 Since it's a common mistake to use C<exec()> instead of C<system()>, Perl
1244 warns you if there is a following statement which isn't C<die()>, C<warn()>,
1245 or C<exit()> (if C<-w> is set  -  but you always do that).   If you
1246 I<really> want to follow an C<exec()> with some other statement, you
1247 can use one of these styles to avoid the warning:
1248
1249     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1250     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1251
1252 If there is more than one argument in LIST, or if LIST is an array
1253 with more than one value, calls execvp(3) with the arguments in LIST.
1254 If there is only one scalar argument or an array with one element in it,
1255 the argument is checked for shell metacharacters, and if there are any,
1256 the entire argument is passed to the system's command shell for parsing
1257 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1258 If there are no shell metacharacters in the argument, it is split into
1259 words and passed directly to C<execvp()>, which is more efficient.  Note:
1260 C<exec()> and C<system()> do not flush your output buffer, so you may need to
1261 set C<$|> to avoid lost output.  Examples:
1262
1263     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1264     exec "sort $outfile | uniq";
1265
1266 If you don't really want to execute the first argument, but want to lie
1267 to the program you are executing about its own name, you can specify
1268 the program you actually want to run as an "indirect object" (without a
1269 comma) in front of the LIST.  (This always forces interpretation of the
1270 LIST as a multivalued list, even if there is only a single scalar in
1271 the list.)  Example:
1272
1273     $shell = '/bin/csh';
1274     exec $shell '-sh';          # pretend it's a login shell
1275
1276 or, more directly,
1277
1278     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1279
1280 When the arguments get executed via the system shell, results will
1281 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1282 for details.
1283
1284 Using an indirect object with C<exec()> or C<system()> is also more secure.
1285 This usage forces interpretation of the arguments as a multivalued list,
1286 even if the list had just one argument.  That way you're safe from the
1287 shell expanding wildcards or splitting up words with whitespace in them.
1288
1289     @args = ( "echo surprise" );
1290
1291     system @args;               # subject to shell escapes
1292                                 # if @args == 1
1293     system { $args[0] } @args;  # safe even with one-arg list
1294
1295 The first version, the one without the indirect object, ran the I<echo>
1296 program, passing it C<"surprise"> an argument.  The second version
1297 didn't--it tried to run a program literally called I<"echo surprise">,
1298 didn't find it, and set C<$?> to a non-zero value indicating failure.
1299
1300 Note that C<exec()> will not call your C<END> blocks, nor will it call
1301 any C<DESTROY> methods in your objects.
1302
1303 =item exists EXPR
1304
1305 Returns TRUE if the specified hash key exists in its hash array, even
1306 if the corresponding value is undefined.
1307
1308     print "Exists\n" if exists $array{$key};
1309     print "Defined\n" if defined $array{$key};
1310     print "True\n" if $array{$key};
1311
1312 A hash element can be TRUE only if it's defined, and defined if
1313 it exists, but the reverse doesn't necessarily hold true.
1314
1315 Note that the EXPR can be arbitrarily complicated as long as the final
1316 operation is a hash key lookup:
1317
1318     if (exists $ref->{"A"}{"B"}{$key}) { ... }
1319
1320 Although the last element will not spring into existence just because its
1321 existence was tested, intervening ones will.  Thus C<$ref-E<gt>{"A"}>
1322 C<$ref-E<gt>{"B"}> will spring into existence due to the existence
1323 test for a $key element.  This autovivification may be fixed in a later
1324 release.
1325
1326 =item exit EXPR
1327
1328 Evaluates EXPR and exits immediately with that value.  (Actually, it
1329 calls any defined C<END> routines first, but the C<END> routines may not
1330 abort the exit.  Likewise any object destructors that need to be called
1331 are called before exit.)  Example:
1332
1333     $ans = <STDIN>;
1334     exit 0 if $ans =~ /^[Xx]/;
1335
1336 See also C<die()>.  If EXPR is omitted, exits with C<0> status.  The only
1337 universally portable values for EXPR are C<0> for success and C<1> for error;
1338 all other values are subject to unpredictable interpretation depending
1339 on the environment in which the Perl program is running.
1340
1341 You shouldn't use C<exit()> to abort a subroutine if there's any chance that
1342 someone might want to trap whatever error happened.  Use C<die()> instead,
1343 which can be trapped by an C<eval()>.
1344
1345 All C<END{}> blocks are run at exit time.  See L<perlsub> for details.
1346
1347 =item exp EXPR
1348
1349 =item exp
1350
1351 Returns I<e> (the natural logarithm base) to the power of EXPR.
1352 If EXPR is omitted, gives C<exp($_)>.
1353
1354 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1355
1356 Implements the fcntl(2) function.  You'll probably have to say
1357
1358     use Fcntl;
1359
1360 first to get the correct constant definitions.  Argument processing and
1361 value return works just like C<ioctl()> below.  
1362 For example:
1363
1364     use Fcntl;
1365     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1366         or die "can't fcntl F_GETFL: $!";
1367
1368 You don't have to check for C<defined()> on the return from 
1369 C<fnctl()>.  Like C<ioctl()>, it maps a C<0> return from the system
1370 call into "C<0> but true" in Perl.  This string is true in 
1371 boolean context and C<0> in numeric context.  It is also 
1372 exempt from the normal B<-w> warnings on improper numeric
1373 conversions.
1374
1375 Note that C<fcntl()> will produce a fatal error if used on a machine that
1376 doesn't implement fcntl(2).
1377
1378 =item fileno FILEHANDLE
1379
1380 Returns the file descriptor for a filehandle.  This is useful for
1381 constructing bitmaps for C<select()> and low-level POSIX tty-handling
1382 operations.  If FILEHANDLE is an expression, the value is taken as 
1383 an indirect filehandle, generally its name. 
1384
1385 You can use this to find out whether two handles refer to the 
1386 same underlying descriptor:
1387
1388     if (fileno(THIS) == fileno(THAT)) {
1389         print "THIS and THAT are dups\n";
1390     } 
1391
1392 =item flock FILEHANDLE,OPERATION
1393
1394 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns TRUE for
1395 success, FALSE on failure.  Produces a fatal error if used on a machine
1396 that doesn't implement flock(2), fcntl(2) locking, or lockf(3).  C<flock()>
1397 is Perl's portable file locking interface, although it locks only entire
1398 files, not records.
1399
1400 On many platforms (including most versions or clones of Unix), locks
1401 established by C<flock()> are B<merely advisory>.  Such discretionary locks
1402 are more flexible, but offer fewer guarantees.  This means that files
1403 locked with C<flock()> may be modified by programs that do not also use
1404 C<flock()>.  Windows NT and OS/2 are among the platforms which
1405 enforce mandatory locking.  See your local documentation for details.
1406
1407 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1408 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1409 you can use the symbolic names if import them from the Fcntl module,
1410 either individually, or as a group using the ':flock' tag.  LOCK_SH
1411 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1412 releases a previously requested lock.  If LOCK_NB is added to LOCK_SH or
1413 LOCK_EX then C<flock()> will return immediately rather than blocking
1414 waiting for the lock (check the return status to see if you got it).
1415
1416 To avoid the possibility of mis-coordination, Perl flushes FILEHANDLE
1417 before (un)locking it.
1418
1419 Note that the emulation built with lockf(3) doesn't provide shared
1420 locks, and it requires that FILEHANDLE be open with write intent.  These
1421 are the semantics that lockf(3) implements.  Most (all?) systems
1422 implement lockf(3) in terms of fcntl(2) locking, though, so the
1423 differing semantics shouldn't bite too many people.
1424
1425 Note also that some versions of C<flock()> cannot lock things over the
1426 network; you would need to use the more system-specific C<fcntl()> for
1427 that.  If you like you can force Perl to ignore your system's flock(2)
1428 function, and so provide its own fcntl(2)-based emulation, by passing
1429 the switch C<-Ud_flock> to the F<Configure> program when you configure
1430 perl.
1431
1432 Here's a mailbox appender for BSD systems.
1433
1434     use Fcntl ':flock'; # import LOCK_* constants
1435
1436     sub lock {
1437         flock(MBOX,LOCK_EX);
1438         # and, in case someone appended
1439         # while we were waiting...
1440         seek(MBOX, 0, 2);
1441     }
1442
1443     sub unlock {
1444         flock(MBOX,LOCK_UN);
1445     }
1446
1447     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1448             or die "Can't open mailbox: $!";
1449
1450     lock();
1451     print MBOX $msg,"\n\n";
1452     unlock();
1453
1454 See also L<DB_File> for other flock() examples.
1455
1456 =item for (INITIAL; WHILE; EACH) BLOCK
1457
1458 Do INITIAL, enter BLOCK while EXPR is true, at the end of each round
1459 do EACH. For example:
1460
1461         for ($i = 0, $j = 0; $i < 10; $i++) {
1462                 if ($i % 3 == 0) { $j++ }
1463                 print "i = $i, j = $j\n";
1464         }
1465
1466 See L<perlsyn> for more details.  See also L</foreach>, a twin of
1467 C<for>, L</while> and L</until>, close cousins of L<for>, and
1468 L</last>, L</next>, and L</redo> for additional control flow.
1469
1470 =item foreach LOOPVAR (LIST) BLOCK
1471
1472 Enter BLOCK as LOOPVAR set in turn to each element of LIST.
1473 For example:
1474
1475         foreach $rolling (@stones) { print "rolling $stone\n" }
1476
1477         foreach my $file (@files)  { print "file $file\n" }
1478
1479 The LOOPVAR is optional and defaults to C<$_>.  If the elements are
1480 modifiable (as opposed to constants or tied variables) you can modify them.
1481
1482         foreach (@words) { tr/abc/xyz/ }
1483
1484 See L<perlsyn> for more details.  See also L</for>, a twin of
1485 C<foreach>, L</while> and L</until>, close cousins of L<for>, and
1486 L</last>, L</next>, and L</redo> for additional control flow.
1487
1488 =item fork
1489
1490 Does a fork(2) system call.  Returns the child pid to the parent process,
1491 C<0> to the child process, or C<undef> if the fork is unsuccessful.
1492
1493 Note: unflushed buffers remain unflushed in both processes, which means
1494 you may need to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()>
1495 method of C<IO::Handle> to avoid duplicate output.
1496
1497 If you C<fork()> without ever waiting on your children, you will accumulate
1498 zombies:
1499
1500     $SIG{CHLD} = sub { wait };
1501
1502 There's also the double-fork trick (error checking on
1503 C<fork()> returns omitted);
1504
1505     unless ($pid = fork) {
1506         unless (fork) {
1507             exec "what you really wanna do";
1508             die "no exec";
1509             # ... or ...
1510             ## (some_perl_code_here)
1511             exit 0;
1512         }
1513         exit 0;
1514     }
1515     waitpid($pid,0);
1516
1517 See also L<perlipc> for more examples of forking and reaping
1518 moribund children.
1519
1520 Note that if your forked child inherits system file descriptors like
1521 STDIN and STDOUT that are actually connected by a pipe or socket, even
1522 if you exit, then the remote server (such as, say, httpd or rsh) won't think
1523 you're done.  You should reopen those to F</dev/null> if it's any issue.
1524
1525 =item format
1526
1527 Declare a picture format for use by the C<write()> function.  For
1528 example:
1529
1530     format Something =
1531         Test: @<<<<<<<< @||||| @>>>>>
1532               $str,     $%,    '$' . int($num)
1533     .
1534
1535     $str = "widget";
1536     $num = $cost/$quantity;
1537     $~ = 'Something';
1538     write;
1539
1540 See L<perlform> for many details and examples.
1541
1542 =item formline PICTURE,LIST
1543
1544 This is an internal function used by C<format>s, though you may call it,
1545 too.  It formats (see L<perlform>) a list of values according to the
1546 contents of PICTURE, placing the output into the format output
1547 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1548 Eventually, when a C<write()> is done, the contents of
1549 C<$^A> are written to some filehandle, but you could also read C<$^A>
1550 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1551 does one C<formline()> per line of form, but the C<formline()> function itself
1552 doesn't care how many newlines are embedded in the PICTURE.  This means
1553 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1554 You may therefore need to use multiple formlines to implement a single
1555 record format, just like the format compiler.
1556
1557 Be careful if you put double quotes around the picture, because an "C<@>"
1558 character may be taken to mean the beginning of an array name.
1559 C<formline()> always returns TRUE.  See L<perlform> for other examples.
1560
1561 =item getc FILEHANDLE
1562
1563 =item getc
1564
1565 Returns the next character from the input file attached to FILEHANDLE,
1566 or the undefined value at end of file, or if there was an error.  If
1567 FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1568 efficient.  It cannot be used to get unbuffered single-characters,
1569 however.  For that, try something more like:
1570
1571     if ($BSD_STYLE) {
1572         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1573     }
1574     else {
1575         system "stty", '-icanon', 'eol', "\001";
1576     }
1577
1578     $key = getc(STDIN);
1579
1580     if ($BSD_STYLE) {
1581         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1582     }
1583     else {
1584         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1585     }
1586     print "\n";
1587
1588 Determination of whether $BSD_STYLE should be set
1589 is left as an exercise to the reader.
1590
1591 The C<POSIX::getattr()> function can do this more portably on systems
1592 purporting POSIX compliance.
1593 See also the C<Term::ReadKey> module from your nearest CPAN site;
1594 details on CPAN can be found on L<perlmod/CPAN>.
1595
1596 =item getlogin
1597
1598 Implements the C library function of the same name, which on most
1599 systems returns the current login from F</etc/utmp>, if any.  If null,
1600 use C<getpwuid()>.
1601
1602     $login = getlogin || getpwuid($<) || "Kilroy";
1603
1604 Do not consider C<getlogin()> for authentication: it is not as
1605 secure as C<getpwuid()>.
1606
1607 =item getpeername SOCKET
1608
1609 Returns the packed sockaddr address of other end of the SOCKET connection.
1610
1611     use Socket;
1612     $hersockaddr    = getpeername(SOCK);
1613     ($port, $iaddr) = unpack_sockaddr_in($hersockaddr);
1614     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1615     $herstraddr     = inet_ntoa($iaddr);
1616
1617 =item getpgrp PID
1618
1619 Returns the current process group for the specified PID.  Use
1620 a PID of C<0> to get the current process group for the
1621 current process.  Will raise an exception if used on a machine that
1622 doesn't implement getpgrp(2).  If PID is omitted, returns process
1623 group of current process.  Note that the POSIX version of C<getpgrp()>
1624 does not accept a PID argument, so only C<PID==0> is truly portable.
1625
1626 =item getppid
1627
1628 Returns the process id of the parent process.
1629
1630 =item getpriority WHICH,WHO
1631
1632 Returns the current priority for a process, a process group, or a user.
1633 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1634 machine that doesn't implement getpriority(2).
1635
1636 =item getpwnam NAME
1637
1638 =item getgrnam NAME
1639
1640 =item gethostbyname NAME
1641
1642 =item getnetbyname NAME
1643
1644 =item getprotobyname NAME
1645
1646 =item getpwuid UID
1647
1648 =item getgrgid GID
1649
1650 =item getservbyname NAME,PROTO
1651
1652 =item gethostbyaddr ADDR,ADDRTYPE
1653
1654 =item getnetbyaddr ADDR,ADDRTYPE
1655
1656 =item getprotobynumber NUMBER
1657
1658 =item getservbyport PORT,PROTO
1659
1660 =item getpwent
1661
1662 =item getgrent
1663
1664 =item gethostent
1665
1666 =item getnetent
1667
1668 =item getprotoent
1669
1670 =item getservent
1671
1672 =item setpwent
1673
1674 =item setgrent
1675
1676 =item sethostent STAYOPEN
1677
1678 =item setnetent STAYOPEN
1679
1680 =item setprotoent STAYOPEN
1681
1682 =item setservent STAYOPEN
1683
1684 =item endpwent
1685
1686 =item endgrent
1687
1688 =item endhostent
1689
1690 =item endnetent
1691
1692 =item endprotoent
1693
1694 =item endservent
1695
1696 These routines perform the same functions as their counterparts in the
1697 system library.  In list context, the return values from the
1698 various get routines are as follows:
1699
1700     ($name,$passwd,$uid,$gid,
1701        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1702     ($name,$passwd,$gid,$members) = getgr*
1703     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1704     ($name,$aliases,$addrtype,$net) = getnet*
1705     ($name,$aliases,$proto) = getproto*
1706     ($name,$aliases,$port,$proto) = getserv*
1707
1708 (If the entry doesn't exist you get a null list.)
1709
1710 In scalar context, you get the name, unless the function was a
1711 lookup by name, in which case you get the other thing, whatever it is.
1712 (If the entry doesn't exist you get the undefined value.)  For example:
1713
1714     $uid   = getpwnam($name);
1715     $name  = getpwuid($num);
1716     $name  = getpwent();
1717     $gid   = getgrnam($name);
1718     $name  = getgrgid($num;
1719     $name  = getgrent();
1720     #etc.
1721
1722 In I<getpw*()> the fields C<$quota>, C<$comment>, and C<$expire> are special
1723 cases in the sense that in many systems they are unsupported.  If the
1724 C<$quota> is unsupported, it is an empty scalar.  If it is supported, it
1725 usually encodes the disk quota.  If the C<$comment> field is unsupported,
1726 it is an empty scalar.  If it is supported it usually encodes some
1727 administrative comment about the user.  In some systems the $quota
1728 field may be C<$change> or C<$age>, fields that have to do with password
1729 aging.  In some systems the C<$comment> field may be C<$class>.  The C<$expire>
1730 field, if present, encodes the expiration period of the account or the
1731 password.  For the availability and the exact meaning of these fields
1732 in your system, please consult your getpwnam(3) documentation and your
1733 F<pwd.h> file.  You can also find out from within Perl which meaning
1734 your C<$quota> and C<$comment> fields have and whether you have the C<$expire>
1735 field by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1736 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.
1737
1738 The C<$members> value returned by I<getgr*()> is a space separated list of
1739 the login names of the members of the group.
1740
1741 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1742 C, it will be returned to you via C<$?> if the function call fails.  The
1743 C<@addrs> value returned by a successful call is a list of the raw
1744 addresses returned by the corresponding system library call.  In the
1745 Internet domain, each address is four bytes long and you can unpack it
1746 by saying something like:
1747
1748     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1749
1750 If you get tired of remembering which element of the return list contains
1751 which return value, by-name interfaces are also provided in modules:
1752 C<File::stat>, C<Net::hostent>, C<Net::netent>, C<Net::protoent>, C<Net::servent>,
1753 C<Time::gmtime>, C<Time::localtime>, and C<User::grent>.  These override the
1754 normal built-in, replacing them with versions that return objects with
1755 the appropriate names for each field.  For example:
1756
1757    use File::stat;
1758    use User::pwent;
1759    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1760
1761 Even though it looks like they're the same method calls (uid), 
1762 they aren't, because a C<File::stat> object is different from a C<User::pwent> object.
1763
1764 =item getsockname SOCKET
1765
1766 Returns the packed sockaddr address of this end of the SOCKET connection.
1767
1768     use Socket;
1769     $mysockaddr = getsockname(SOCK);
1770     ($port, $myaddr) = unpack_sockaddr_in($mysockaddr);
1771
1772 =item getsockopt SOCKET,LEVEL,OPTNAME
1773
1774 Returns the socket option requested, or undef if there is an error.
1775
1776 =item glob EXPR
1777
1778 =item glob
1779
1780 Returns the value of EXPR with filename expansions such as the standard Unix shell F</bin/sh> would
1781 do.  This is the internal function implementing the C<E<lt>*.cE<gt>>
1782 operator, but you can use it directly.  If EXPR is omitted, C<$_> is used.
1783 The C<E<lt>*.cE<gt>> operator is discussed in more detail in
1784 L<perlop/"I/O Operators">.
1785
1786 =item gmtime EXPR
1787
1788 Converts a time as returned by the time function to a 9-element array
1789 with the time localized for the standard Greenwich time zone.
1790 Typically used as follows:
1791
1792     #  0    1    2     3     4    5     6     7     8
1793     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1794                                             gmtime(time);
1795
1796 All array elements are numeric, and come straight out of a struct tm.
1797 In particular this means that C<$mon> has the range C<0..11> and C<$wday> has
1798 the range C<0..6> with sunday as day C<0>.  Also, C<$year> is the number of
1799 years since 1900, that is, C<$year> is C<123> in year 2023, I<not> simply the last two digits of the year.
1800
1801 If EXPR is omitted, does C<gmtime(time())>.
1802
1803 In scalar context, returns the ctime(3) value:
1804
1805     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1806
1807 Also see the C<timegm()> function provided by the C<Time::Local> module,
1808 and the strftime(3) function available via the POSIX module.
1809
1810 This scalar value is B<not> locale dependent, see L<perllocale>, but
1811 instead a Perl builtin.  Also see the C<Time::Local> module, and the
1812 strftime(3) and mktime(3) function available via the POSIX module.  To
1813 get somewhat similar but locale dependent date strings, set up your
1814 locale environment variables appropriately (please see L<perllocale>)
1815 and try for example:
1816
1817     use POSIX qw(strftime);
1818         $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
1819
1820 Note that the C<%a> and C<%b>, the short forms of the day of the week
1821 and the month of the year, may not necessarily be three characters wide.
1822
1823 =item goto LABEL
1824
1825 =item goto EXPR
1826
1827 =item goto &NAME
1828
1829 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
1830 execution there.  It may not be used to go into any construct that
1831 requires initialization, such as a subroutine or a C<foreach> loop.  It
1832 also can't be used to go into a construct that is optimized away,
1833 or to get out of a block or subroutine given to C<sort()>.
1834 It can be used to go almost anywhere else within the dynamic scope,
1835 including out of subroutines, but it's usually better to use some other
1836 construct such as C<last> or C<die()>.  The author of Perl has never felt the
1837 need to use this form of C<goto> (in Perl, that is--C is another matter).
1838
1839 The C<goto-EXPR> form expects a label name, whose scope will be resolved
1840 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
1841 necessarily recommended if you're optimizing for maintainability:
1842
1843     goto ("FOO", "BAR", "GLARCH")[$i];
1844
1845 The C<goto-&NAME> form is highly magical, and substitutes a call to the
1846 named subroutine for the currently running subroutine.  This is used by
1847 C<AUTOLOAD> subroutines that wish to load another subroutine and then
1848 pretend that the other subroutine had been called in the first place
1849 (except that any modifications to C<@_> in the current subroutine are
1850 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
1851 will be able to tell that this routine was called first.
1852
1853 =item grep BLOCK LIST
1854
1855 =item grep EXPR,LIST
1856
1857 This is similar in spirit to, but not the same as, grep(1)
1858 and its relatives.  In particular, it is not limited to using
1859 regular expressions.
1860
1861 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1862 C<$_> to each element) and returns the list value consisting of those
1863 elements for which the expression evaluated to TRUE.  In a scalar
1864 context, returns the number of times the expression was TRUE.
1865
1866     @foo = grep(!/^#/, @bar);    # weed out comments
1867
1868 or equivalently,
1869
1870     @foo = grep {!/^#/} @bar;    # weed out comments
1871
1872 Note that, because C<$_> is a reference into the list value, it can be used
1873 to modify the elements of the array.  While this is useful and
1874 supported, it can cause bizarre results if the LIST is not a named
1875 array.  Similarly, grep returns aliases into the original list,
1876 much like the way that a for loop's index variable aliases the list
1877 elements.  That is, modifying an element of a list returned by grep
1878 (for example, in a C<foreach>, C<map()> or another C<grep()>)
1879 actually modifies the element in the original list.
1880
1881 See also L</map> for an array composed of the results of the BLOCK or EXPR.
1882
1883 =item hex EXPR
1884
1885 =item hex
1886
1887 Interprets EXPR as a hex string and returns the corresponding
1888 value.  (To convert strings that might start with either 0 or 0x
1889 see L</oct>.)  If EXPR is omitted, uses C<$_>.
1890
1891     print hex '0xAf'; # prints '175'
1892     print hex 'aF';   # same
1893
1894 =item if (EXPR) BLOCK
1895
1896 =item if (EXPR) BLOCK else BLOCK2
1897
1898 =item if (EXPR) BLOCK elsif (EXPR2) BLOCK2
1899
1900 Enter BLOCKs conditionally.  The first EXPR to return true
1901 causes the corresponding BLOCK to be entered, or, in the case
1902 of C<else>, the fall-through default BLOCK.
1903
1904 Take notice: Perl wants BLOCKS, expressions (like e.g. in C, C++, or
1905 Pascal) won't do.
1906
1907 See L<perlsyn> for more details.  See also C<unless>.
1908
1909 =item import
1910
1911 There is no builtin C<import()> function.  It is just an ordinary
1912 method (subroutine) defined (or inherited) by modules that wish to export
1913 names to another module.  The C<use()> function calls the C<import()> method
1914 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
1915
1916 =item index STR,SUBSTR,POSITION
1917
1918 =item index STR,SUBSTR
1919
1920 Returns the position of the first occurrence of SUBSTR in STR at or after
1921 POSITION.  If POSITION is omitted, starts searching from the beginning of
1922 the string.  The return value is based at C<0> (or whatever you've set the C<$[>
1923 variable to--but don't do that).  If the substring is not found, returns
1924 one less than the base, ordinarily C<-1>.
1925
1926 =item int EXPR
1927
1928 =item int
1929
1930 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
1931 You should not use this for rounding, because it truncates
1932 towards C<0>, and because machine representations of floating point
1933 numbers can sometimes produce counterintuitive results.  Usually C<sprintf()> or C<printf()>,
1934 or the C<POSIX::floor> or C<POSIX::ceil> functions, would serve you better.
1935
1936 =item ioctl FILEHANDLE,FUNCTION,SCALAR
1937
1938 Implements the ioctl(2) function.  You'll probably have to say
1939
1940     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
1941
1942 first to get the correct function definitions.  If F<ioctl.ph> doesn't
1943 exist or doesn't have the correct definitions you'll have to roll your
1944 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
1945 (There is a Perl script called B<h2ph> that comes with the Perl kit that
1946 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
1947 written depending on the FUNCTION--a pointer to the string value of SCALAR
1948 will be passed as the third argument of the actual C<ioctl()> call.  (If SCALAR
1949 has no string value but does have a numeric value, that value will be
1950 passed rather than a pointer to the string value.  To guarantee this to be
1951 TRUE, add a C<0> to the scalar before using it.)  The C<pack()> and C<unpack()>
1952 functions are useful for manipulating the values of structures used by
1953 C<ioctl()>.  The following example sets the erase character to DEL.
1954
1955     require 'ioctl.ph';
1956     $getp = &TIOCGETP;
1957     die "NO TIOCGETP" if $@ || !$getp;
1958     $sgttyb_t = "ccccs";                # 4 chars and a short
1959     if (ioctl(STDIN,$getp,$sgttyb)) {
1960         @ary = unpack($sgttyb_t,$sgttyb);
1961         $ary[2] = 127;
1962         $sgttyb = pack($sgttyb_t,@ary);
1963         ioctl(STDIN,&TIOCSETP,$sgttyb)
1964             || die "Can't ioctl: $!";
1965     }
1966
1967 The return value of C<ioctl()> (and C<fcntl()>) is as follows:
1968
1969         if OS returns:          then Perl returns:
1970             -1                    undefined value
1971              0                  string "0 but true"
1972         anything else               that number
1973
1974 Thus Perl returns TRUE on success and FALSE on failure, yet you can
1975 still easily determine the actual value returned by the operating
1976 system:
1977
1978     ($retval = ioctl(...)) || ($retval = -1);
1979     printf "System returned %d\n", $retval;
1980
1981 The special string "C<0> but true" is excempt from B<-w> complaints
1982 about improper numeric conversions.
1983
1984 =item join EXPR,LIST
1985
1986 Joins the separate strings of LIST into a single string with
1987 fields separated by the value of EXPR, and returns the string.
1988 Example:
1989
1990     $_ = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
1991
1992 See L</split>.
1993
1994 =item keys HASH
1995
1996 Returns a list consisting of all the keys of the named hash.  (In a
1997 scalar context, returns the number of keys.)  The keys are returned in
1998 an apparently random order.  The actual random order is subject to
1999 change in future versions of perl, but it is guaranteed to be the same
2000 order as either the C<values()> or C<each()> function produces (given
2001 that the hash has not been modified).  As a side effect, it resets
2002 HASH's iterator.
2003
2004 Here is yet another way to print your environment:
2005
2006     @keys = keys %ENV;
2007     @values = values %ENV;
2008     while ($#keys >= 0) {
2009         print pop(@keys), '=', pop(@values), "\n";
2010     }
2011
2012 or how about sorted by key:
2013
2014     foreach $key (sort(keys %ENV)) {
2015         print $key, '=', $ENV{$key}, "\n";
2016     }
2017
2018 To sort a hash by value, you'll need to use a C<sort()> function.
2019 Here's a descending numeric sort of a hash by its values:
2020
2021     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2022         printf "%4d %s\n", $hash{$key}, $key;
2023     }
2024
2025 As an lvalue C<keys()> allows you to increase the number of hash buckets
2026 allocated for the given hash.  This can gain you a measure of efficiency if
2027 you know the hash is going to get big.  (This is similar to pre-extending
2028 an array by assigning a larger number to $#array.)  If you say
2029
2030     keys %hash = 200;
2031
2032 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2033 in fact, since it rounds up to the next power of two.  These
2034 buckets will be retained even if you do C<%hash = ()>, use C<undef
2035 %hash> if you want to free the storage while C<%hash> is still in scope.
2036 You can't shrink the number of buckets allocated for the hash using
2037 C<keys()> in this way (but you needn't worry about doing this by accident,
2038 as trying has no effect).
2039
2040 See also C<each()>, C<values()> and C<sort()>.
2041
2042 =item kill LIST
2043
2044 Sends a signal to a list of processes.  The first element of
2045 the list must be the signal to send.  Returns the number of
2046 processes successfully signaled.
2047
2048     $cnt = kill 1, $child1, $child2;
2049     kill 9, @goners;
2050
2051 Unlike in the shell, in Perl if the I<SIGNAL> is negative, it kills
2052 process groups instead of processes.  (On System V, a negative I<PROCESS>
2053 number will also kill process groups, but that's not portable.)  That
2054 means you usually want to use positive not negative signals.  You may also
2055 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2056
2057 =item last LABEL
2058
2059 =item last
2060
2061 The C<last> command is like the C<break> statement in C (as used in
2062 loops); it immediately exits the loop in question.  If the LABEL is
2063 omitted, the command refers to the innermost enclosing loop.  The
2064 C<continue> block, if any, is not executed:
2065
2066     LINE: while (<STDIN>) {
2067         last LINE if /^$/;      # exit when done with header
2068         #...
2069     }
2070
2071 C<last> cannot be used to exit a block which returns a value such as
2072 C<eval {}>, C<sub {}> or C<do {}>.
2073
2074 See also L</continue> for an illustration of how C<last>, L</next>, and
2075 L</redo> work.
2076
2077 See also L<perlsyn>.
2078
2079 =item lc EXPR
2080
2081 =item lc
2082
2083 Returns an lowercased version of EXPR.  This is the internal function
2084 implementing the C<\L> escape in double-quoted strings.
2085 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
2086
2087 If EXPR is omitted, uses C<$_>.
2088
2089 =item lcfirst EXPR
2090
2091 =item lcfirst
2092
2093 Returns the value of EXPR with the first character lowercased.  This is
2094 the internal function implementing the C<\l> escape in double-quoted strings.
2095 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
2096
2097 If EXPR is omitted, uses C<$_>.
2098
2099 =item length EXPR
2100
2101 =item length
2102
2103 Returns the length in characters of the value of EXPR.  If EXPR is
2104 omitted, returns length of C<$_>.
2105
2106 =item link OLDFILE,NEWFILE
2107
2108 Creates a new filename linked to the old filename.  Returns TRUE for
2109 success, FALSE otherwise.
2110
2111 =item listen SOCKET,QUEUESIZE
2112
2113 Does the same thing that the listen system call does.  Returns TRUE if
2114 it succeeded, FALSE otherwise.  See example in L<perlipc/"Sockets: Client/Server Communication">.
2115
2116 =item local EXPR
2117
2118 A local modifies the listed variables to be local to the enclosing
2119 block, file, or eval.  If more than one value is listed, the list must
2120 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2121 for details, including issues with tied arrays and hashes.
2122
2123 You really probably want to be using C<my()> instead, because C<local()> isn't
2124 what most people think of as "local".  See L<perlsub/"Private Variables
2125 via my()"> for details.
2126
2127 =item localtime EXPR
2128
2129 Converts a time as returned by the time function to a 9-element array
2130 with the time analyzed for the local time zone.  Typically used as
2131 follows:
2132
2133     #  0    1    2     3     4    5     6     7     8
2134     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2135                                                 localtime(time);
2136
2137 All array elements are numeric, and come straight out of a struct tm.
2138 In particular this means that C<$mon> has the range C<0..11> and C<$wday> has
2139 the range C<0..6> with sunday as day C<0>.  Also, C<$year> is the number of
2140 years since 1900, that is, C<$year> is C<123> in year 2023, and I<not> simply the last two digits of the year.
2141
2142 If EXPR is omitted, uses the current time (C<localtime(time)>).
2143
2144 In scalar context, returns the ctime(3) value:
2145
2146     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2147
2148 This scalar value is B<not> locale dependent, see L<perllocale>, but
2149 instead a Perl builtin.  Also see the C<Time::Local> module, and the
2150 strftime(3) and mktime(3) function available via the POSIX module.  To
2151 get somewhat similar but locale dependent date strings, set up your
2152 locale environment variables appropriately (please see L<perllocale>)
2153 and try for example:
2154
2155     use POSIX qw(strftime);
2156         $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2157
2158 Note that the C<%a> and C<%b>, the short forms of the day of the week
2159 and the month of the year, may not necessarily be three characters wide.
2160
2161 =item log EXPR
2162
2163 =item log
2164
2165 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted, returns log
2166 of C<$_>.
2167
2168 =item lstat FILEHANDLE
2169
2170 =item lstat EXPR
2171
2172 =item lstat
2173
2174 Does the same thing as the C<stat()> function (including setting the
2175 special C<_> filehandle) but stats a symbolic link instead of the file
2176 the symbolic link points to.  If symbolic links are unimplemented on
2177 your system, a normal C<stat()> is done.
2178
2179 If EXPR is omitted, stats C<$_>.
2180
2181 =item m//
2182
2183 The match operator.  See L<perlop>.
2184
2185 =item map BLOCK LIST
2186
2187 =item map EXPR,LIST
2188
2189 Evaluates the BLOCK or EXPR for each element of LIST (locally setting C<$_> to each
2190 element) and returns the list value composed of the results of each such
2191 evaluation.  Evaluates BLOCK or EXPR in a list context, so each element of LIST
2192 may produce zero, one, or more elements in the returned value.
2193
2194     @chars = map(chr, @nums);
2195
2196 translates a list of numbers to the corresponding characters.  And
2197
2198     %hash = map { getkey($_) => $_ } @array;
2199
2200 is just a funny way to write
2201
2202     %hash = ();
2203     foreach $_ (@array) {
2204         $hash{getkey($_)} = $_;
2205     }
2206
2207 Note that, because C<$_> is a reference into the list value, it can be used
2208 to modify the elements of the array.  While this is useful and
2209 supported, it can cause bizarre results if the LIST is not a named
2210 array.  See also L</grep> for an array composed of those items of the 
2211 original list for which the BLOCK or EXPR evaluates to true.
2212
2213 =item mkdir FILENAME,MODE
2214
2215 Creates the directory specified by FILENAME, with permissions
2216 specified by MODE (as modified by C<umask>).  If it succeeds it
2217 returns TRUE, otherwise it returns FALSE and sets C<$!> (errno).
2218
2219 In general, it is better to create directories with permissive MODEs,
2220 and let the user modify that with their C<umask>, than it is to supply
2221 a restrictive MODE and give the user no way to be more permissive.
2222 The exceptions to this rule are when the file or directory should be
2223 kept private (mail files, for instance).  The perlfunc(1) entry on
2224 C<umask> discusses the choice of MODE in more detail.
2225
2226 =item msgctl ID,CMD,ARG
2227
2228 Calls the System V IPC function msgctl(2).  You'll probably have to say
2229
2230     use IPC::SysV;
2231
2232 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2233 then ARG must be a variable which will hold the returned C<msqid_ds>
2234 structure.  Returns like C<ioctl()>: the undefined value for error, "C<0> but
2235 true" for zero, or the actual return value otherwise.  See also
2236 C<IPC::SysV> and C<IPC::Semaphore::Msg> documentation.
2237
2238 =item msgget KEY,FLAGS
2239
2240 Calls the System V IPC function msgget(2).  Returns the message queue
2241 id, or the undefined value if there is an error.  See also C<IPC::SysV>
2242 and C<IPC::SysV::Msg> documentation.
2243
2244 =item msgsnd ID,MSG,FLAGS
2245
2246 Calls the System V IPC function msgsnd to send the message MSG to the
2247 message queue ID.  MSG must begin with the long integer message type,
2248 which may be created with C<pack("l", $type)>.  Returns TRUE if
2249 successful, or FALSE if there is an error.  See also C<IPC::SysV>
2250 and C<IPC::SysV::Msg> documentation.
2251
2252 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2253
2254 Calls the System V IPC function msgrcv to receive a message from
2255 message queue ID into variable VAR with a maximum message size of
2256 SIZE.  Note that if a message is received, the message type will be
2257 the first thing in VAR, and the maximum length of VAR is SIZE plus the
2258 size of the message type.  Returns TRUE if successful, or FALSE if
2259 there is an error.  See also C<IPC::SysV> and C<IPC::SysV::Msg> documentation.
2260
2261 =item my EXPR
2262
2263 A C<my()> declares the listed variables to be local (lexically) to the
2264 enclosing block, file, or C<eval()>.  If
2265 more than one value is listed, the list must be placed in parentheses.  See
2266 L<perlsub/"Private Variables via my()"> for details.
2267
2268 =item next LABEL
2269
2270 =item next
2271
2272 The C<next> command is like the C<continue> statement in C; it starts
2273 the next iteration of the loop:
2274
2275     LINE: while (<STDIN>) {
2276         next LINE if /^#/;      # discard comments
2277         #...
2278     }
2279
2280 Note that if there were a C<continue> block on the above, it would get
2281 executed even on discarded lines.  If the LABEL is omitted, the command
2282 refers to the innermost enclosing loop.
2283
2284 C<next> cannot be used to exit a block which returns a value such as
2285 C<eval {}>, C<sub {}> or C<do {}>.
2286
2287 See also L</continue> for an illustration of how L</last>, C<next>, and
2288 L</redo> work.
2289
2290 See also L<perlsyn>.
2291
2292 =item no Module LIST
2293
2294 See the L</use> function, which C<no> is the opposite of.
2295
2296 =item oct EXPR
2297
2298 =item oct
2299
2300 Interprets EXPR as an octal string and returns the corresponding
2301 value.  (If EXPR happens to start off with C<0x>, interprets it as
2302 a hex string instead.)  The following will handle decimal, octal, and
2303 hex in the standard Perl or C notation:
2304
2305     $val = oct($val) if $val =~ /^0/;
2306
2307 If EXPR is omitted, uses C<$_>.  This function is commonly used when
2308 a string such as C<644> needs to be converted into a file mode, for
2309 example. (Although perl will automatically convert strings into
2310 numbers as needed, this automatic conversion assumes base 10.)
2311
2312 =item open FILEHANDLE,EXPR
2313
2314 =item open FILEHANDLE
2315
2316 Opens the file whose filename is given by EXPR, and associates it with
2317 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
2318 name of the real filehandle wanted.  If EXPR is omitted, the scalar
2319 variable of the same name as the FILEHANDLE contains the filename.
2320 (Note that lexical variables--those declared with C<my()>--will not work
2321 for this purpose; so if you're using C<my()>, specify EXPR in your call
2322 to open.)
2323
2324 If the filename begins with C<'E<lt>'> or nothing, the file is opened for input.
2325 If the filename begins with C<'E<gt>'>, the file is truncated and opened for
2326 output, being created if necessary. If the filename begins with C<'E<gt>E<gt>'>,
2327 the file is opened for appending, again being created if necessary. 
2328 You can put a C<'+'> in front of the C<'E<gt>'> or C<'E<lt>'> to indicate that
2329 you want both read and write access to the file; thus C<'+E<lt>'> is almost
2330 always preferred for read/write updates--the C<'+E<gt>'> mode would clobber the
2331 file first.  You can't usually use either read-write mode for updating
2332 textfiles, since they have variable length records.  See the B<-i>
2333 switch in L<perlrun> for a better approach.  The file is created with
2334 permissions of C<0666> modified by the process' C<umask> value.
2335
2336 The prefix and the filename may be separated with spaces.
2337 These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>, C<'w'>,
2338 C<'w+'>, C<'a'>, and C<'a+'>.
2339
2340 If the filename begins with C<'|'>, the filename is interpreted as a
2341 command to which output is to be piped, and if the filename ends with a
2342 C<'|'>, the filename is interpreted See L<perlipc/"Using open() for IPC">
2343 for more examples of this.  (You are not allowed to C<open()> to a command
2344 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2345 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2346
2347 Opening C<'-'> opens STDIN and opening C<'E<gt>-'> opens STDOUT.  Open returns
2348 nonzero upon success, the undefined value otherwise.  If the C<open()>
2349 involved a pipe, the return value happens to be the pid of the
2350 subprocess.
2351
2352 If you're unfortunate enough to be running Perl on a system that
2353 distinguishes between text files and binary files (modern operating
2354 systems don't care), then you should check out L</binmode> for tips for
2355 dealing with this.  The key distinction between systems that need C<binmode()>
2356 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2357 Plan9, which delimit lines with a single character, and which encode that
2358 character in C as C<"\n">, do not need C<binmode()>.  The rest need it.
2359
2360 When opening a file, it's usually a bad idea to continue normal execution
2361 if the request failed, so C<open()> is frequently used in connection with
2362 C<die()>. Even if C<die()> won't do what you want (say, in a CGI script,
2363 where you want to make a nicely formatted error message (but there are
2364 modules that can help with that problem)) you should always check
2365 the return value from opening a file. The infrequent exception is when
2366 working with an unopened filehandle is actually what you want to do.
2367
2368 Examples:
2369
2370     $ARTICLE = 100;
2371     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2372     while (<ARTICLE>) {...
2373
2374     open(LOG, '>>/usr/spool/news/twitlog'); # (log is reserved)
2375     # if the open fails, output is discarded
2376
2377     open(DBASE, '+<dbase.mine')             # open for update
2378         or die "Can't open 'dbase.mine' for update: $!";
2379
2380     open(ARTICLE, "caesar <$article |")     # decrypt article
2381         or die "Can't start caesar: $!";
2382
2383     open(EXTRACT, "|sort >/tmp/Tmp$$")      # $$ is our process id
2384         or die "Can't start sort: $!";
2385
2386     # process argument list of files along with any includes
2387
2388     foreach $file (@ARGV) {
2389         process($file, 'fh00');
2390     }
2391
2392     sub process {
2393         my($filename, $input) = @_;
2394         $input++;               # this is a string increment
2395         unless (open($input, $filename)) {
2396             print STDERR "Can't open $filename: $!\n";
2397             return;
2398         }
2399
2400         local $_;
2401         while (<$input>) {              # note use of indirection
2402             if (/^#include "(.*)"/) {
2403                 process($1, $input);
2404                 next;
2405             }
2406             #...                # whatever
2407         }
2408     }
2409
2410 You may also, in the Bourne shell tradition, specify an EXPR beginning
2411 with C<'E<gt>&'>, in which case the rest of the string is interpreted as the
2412 name of a filehandle (or file descriptor, if numeric) to be
2413 duped and opened.  You may use C<&> after C<E<gt>>, C<E<gt>E<gt>>, C<E<lt>>, C<+E<gt>>,
2414 C<+E<gt>E<gt>>, and C<+E<lt>>.  The
2415 mode you specify should match the mode of the original filehandle.
2416 (Duping a filehandle does not take into account any existing contents of
2417 stdio buffers.)
2418 Here is a script that saves, redirects, and restores STDOUT and
2419 STDERR:
2420
2421     #!/usr/bin/perl
2422     open(OLDOUT, ">&STDOUT");
2423     open(OLDERR, ">&STDERR");
2424
2425     open(STDOUT, ">foo.out") || die "Can't redirect stdout";
2426     open(STDERR, ">&STDOUT") || die "Can't dup stdout";
2427
2428     select(STDERR); $| = 1;     # make unbuffered
2429     select(STDOUT); $| = 1;     # make unbuffered
2430
2431     print STDOUT "stdout 1\n";  # this works for
2432     print STDERR "stderr 1\n";  # subprocesses too
2433
2434     close(STDOUT);
2435     close(STDERR);
2436
2437     open(STDOUT, ">&OLDOUT");
2438     open(STDERR, ">&OLDERR");
2439
2440     print STDOUT "stdout 2\n";
2441     print STDERR "stderr 2\n";
2442
2443
2444 If you specify C<'E<lt>&=N'>, where C<N> is a number, then Perl will do an
2445 equivalent of C's C<fdopen()> of that file descriptor; this is more
2446 parsimonious of file descriptors.  For example:
2447
2448     open(FILEHANDLE, "<&=$fd")
2449
2450 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>, then
2451 there is an implicit fork done, and the return value of open is the pid
2452 of the child within the parent process, and C<0> within the child
2453 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2454 The filehandle behaves normally for the parent, but i/o to that
2455 filehandle is piped from/to the STDOUT/STDIN of the child process.
2456 In the child process the filehandle isn't opened--i/o happens from/to
2457 the new STDOUT or STDIN.  Typically this is used like the normal
2458 piped open when you want to exercise more control over just how the
2459 pipe command gets executed, such as when you are running setuid, and
2460 don't want to have to scan shell commands for metacharacters.
2461 The following pairs are more or less equivalent:
2462
2463     open(FOO, "|tr '[a-z]' '[A-Z]'");
2464     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
2465
2466     open(FOO, "cat -n '$file'|");
2467     open(FOO, "-|") || exec 'cat', '-n', $file;
2468
2469 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2470
2471 NOTE: On any operation that may do a fork, any unflushed buffers remain
2472 unflushed in both processes, which means you may need to set C<$|> to
2473 avoid duplicate output.  On systems that support a close-on-exec flag on
2474 files, the flag will be set for the newly opened file descriptor as
2475 determined by the value of $^F.  See L<perlvar/$^F>.
2476
2477 Closing any piped filehandle causes the parent process to wait for the
2478 child to finish, and returns the status value in C<$?>.
2479
2480 The filename passed to open will have leading and trailing
2481 whitespace deleted, and the normal redirection characters
2482 honored.  This property, known as "magic open", 
2483 can often be used to good effect.  A user could specify a filename of
2484 F<"rsh cat file |">, or you could change certain filenames as needed:
2485
2486     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2487     open(FH, $filename) or die "Can't open $filename: $!";
2488
2489 However, to open a file with arbitrary weird characters in it, it's
2490 necessary to protect any leading and trailing whitespace:
2491
2492     $file =~ s#^(\s)#./$1#;
2493     open(FOO, "< $file\0");
2494
2495 If you want a "real" C C<open()> (see L<open(2)> on your system), then you
2496 should use the C<sysopen()> function, which involves no such magic.  This is
2497 another way to protect your filenames from interpretation.  For example:
2498
2499     use IO::Handle;
2500     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2501         or die "sysopen $path: $!";
2502     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2503     print HANDLE "stuff $$\n");
2504     seek(HANDLE, 0, 0);
2505     print "File contains: ", <HANDLE>;
2506
2507 Using the constructor from the C<IO::Handle> package (or one of its
2508 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2509 filehandles that have the scope of whatever variables hold references to
2510 them, and automatically close whenever and however you leave that scope:
2511
2512     use IO::File;
2513     #...
2514     sub read_myfile_munged {
2515         my $ALL = shift;
2516         my $handle = new IO::File;
2517         open($handle, "myfile") or die "myfile: $!";
2518         $first = <$handle>
2519             or return ();     # Automatically closed here.
2520         mung $first or die "mung failed";       # Or here.
2521         return $first, <$handle> if $ALL;       # Or here.
2522         $first;                                 # Or here.
2523     }
2524
2525 See L</seek()> for some details about mixing reading and writing.
2526
2527 =item opendir DIRHANDLE,EXPR
2528
2529 Opens a directory named EXPR for processing by C<readdir()>, C<telldir()>,
2530 C<seekdir()>, C<rewinddir()>, and C<closedir()>.  Returns TRUE if successful.
2531 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2532
2533 =item ord EXPR
2534
2535 =item ord
2536
2537 Returns the numeric (ASCII or Unicode) value of the first character of EXPR.  If
2538 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2539
2540 =item pack TEMPLATE,LIST
2541
2542 Takes an array or list of values and packs it into a binary structure,
2543 returning the string containing the structure.  The TEMPLATE is a
2544 sequence of characters that give the order and type of values, as
2545 follows:
2546
2547     A   An ascii string, will be space padded.
2548     a   An ascii string, will be null padded.
2549     b   A bit string (ascending bit order, like vec()).
2550     B   A bit string (descending bit order).
2551     h   A hex string (low nybble first).
2552     H   A hex string (high nybble first).
2553
2554     c   A signed char value.
2555     C   An unsigned char value.  Only does bytes.  See U for Unicode.
2556
2557     s   A signed short value.
2558     S   An unsigned short value.
2559           (This 'short' is _exactly_ 16 bits, which may differ from
2560            what a local C compiler calls 'short'.)
2561
2562     i   A signed integer value.
2563     I   An unsigned integer value.
2564           (This 'integer' is _at_least_ 32 bits wide.  Its exact
2565            size depends on what a local C compiler calls 'int',
2566            and may even be larger than the 'long' described in
2567            the next item.)
2568
2569     l   A signed long value.
2570     L   An unsigned long value.
2571           (This 'long' is _exactly_ 32 bits, which may differ from
2572            what a local C compiler calls 'long'.)
2573
2574     n   A short in "network" (big-endian) order.
2575     N   A long in "network" (big-endian) order.
2576     v   A short in "VAX" (little-endian) order.
2577     V   A long in "VAX" (little-endian) order.
2578           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2579            _exactly_ 32 bits, respectively.)
2580
2581     q   A signed quad (64-bit) value.
2582     Q   An unsigned quad value.
2583           (Available only if your system supports 64-bit integer values
2584            _and_ if Perl has been compiled to support those.
2585            Causes a fatal error otherwise.)
2586
2587     f   A single-precision float in the native format.
2588     d   A double-precision float in the native format.
2589
2590     p   A pointer to a null-terminated string.
2591     P   A pointer to a structure (fixed-length string).
2592
2593     u   A uuencoded string.
2594     U   A Unicode character number.  Encodes to UTF-8 internally.
2595         Works even if C<use utf8> is not in effect.
2596
2597     w   A BER compressed integer.  Its bytes represent an unsigned
2598         integer in base 128, most significant digit first, with as
2599         few digits as possible.  Bit eight (the high bit) is set
2600         on each byte except the last.
2601
2602     x   A null byte.
2603     X   Back up a byte.
2604     @   Null fill to absolute position.
2605
2606 Each letter may optionally be followed by a number giving a repeat
2607 count.  With all types except C<"a">, C<"A">, C<"b">, C<"B">, C<"h">, C<"H">, and C<"P"> the
2608 pack function will gobble up that many values from the LIST.  A C<*> for the
2609 repeat count means to use however many items are left.  The C<"a"> and C<"A">
2610 types gobble just one value, but pack it as a string of length count,
2611 padding with nulls or spaces as necessary.  (When unpacking, C<"A"> strips
2612 trailing spaces and nulls, but C<"a"> does not.)  Likewise, the C<"b"> and C<"B">
2613 fields pack a string that many bits long.  The C<"h"> and C<"H"> fields pack a
2614 string that many nybbles long.  The C<"p"> type packs a pointer to a null-
2615 terminated string.  You are responsible for ensuring the string is not a
2616 temporary value (which can potentially get deallocated before you get
2617 around to using the packed result).  The C<"P"> packs a pointer to a structure
2618 of the size indicated by the length. A NULL pointer is created if the 
2619 corresponding value for C<"p"> or C<"P"> is C<undef>.
2620 Real numbers (floats and doubles) are
2621 in the native machine format only; due to the multiplicity of floating
2622 formats around, and the lack of a standard "network" representation, no
2623 facility for interchange has been made.  This means that packed floating
2624 point data written on one machine may not be readable on another - even if
2625 both use IEEE floating point arithmetic (as the endian-ness of the memory
2626 representation is not part of the IEEE spec).  Note that Perl uses doubles
2627 internally for all numeric calculation, and converting from double into
2628 float and thence back to double again will lose precision (i.e.,
2629 C<unpack("f", pack("f", $foo)>) will not in general equal C<$foo>).
2630
2631 Examples:
2632
2633     $foo = pack("CCCC",65,66,67,68);
2634     # foo eq "ABCD"
2635     $foo = pack("C4",65,66,67,68);
2636     # same thing
2637     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
2638     # same thing with Unicode circled letters
2639
2640     $foo = pack("ccxxcc",65,66,67,68);
2641     # foo eq "AB\0\0CD"
2642
2643     $foo = pack("s2",1,2);
2644     # "\1\0\2\0" on little-endian
2645     # "\0\1\0\2" on big-endian
2646
2647     $foo = pack("a4","abcd","x","y","z");
2648     # "abcd"
2649
2650     $foo = pack("aaaa","abcd","x","y","z");
2651     # "axyz"
2652
2653     $foo = pack("a14","abcdefg");
2654     # "abcdefg\0\0\0\0\0\0\0"
2655
2656     $foo = pack("i9pl", gmtime);
2657     # a real struct tm (on my system anyway)
2658
2659     sub bintodec {
2660         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
2661     }
2662
2663 The same template may generally also be used in the unpack function.
2664
2665 =item package 
2666
2667 =item package NAMESPACE
2668
2669 Declares the compilation unit as being in the given namespace.  The scope
2670 of the package declaration is from the declaration itself through the end of
2671 the enclosing block (the same scope as the C<local()> operator).  All further
2672 unqualified dynamic identifiers will be in this namespace.  A package
2673 statement affects only dynamic variables--including those you've used
2674 C<local()> on--but I<not> lexical variables created with C<my()>.  Typically it
2675 would be the first declaration in a file to be included by the C<require>
2676 or C<use> operator.  You can switch into a package in more than one place;
2677 it merely influences which symbol table is used by the compiler for the
2678 rest of that block.  You can refer to variables and filehandles in other
2679 packages by prefixing the identifier with the package name and a double
2680 colon:  C<$Package::Variable>.  If the package name is null, the C<main>
2681 package as assumed.  That is, C<$::sail> is equivalent to C<$main::sail>.
2682
2683 If NAMESPACE is omitted, then there is no current package, and all
2684 identifiers must be fully qualified or lexicals.  This is stricter
2685 than C<use strict>, since it also extends to function names.
2686
2687 See L<perlmod/"Packages"> for more information about packages, modules,
2688 and classes.  See L<perlsub> for other scoping issues.
2689
2690 =item pipe READHANDLE,WRITEHANDLE
2691
2692 Opens a pair of connected pipes like the corresponding system call.
2693 Note that if you set up a loop of piped processes, deadlock can occur
2694 unless you are very careful.  In addition, note that Perl's pipes use
2695 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
2696 after each command, depending on the application.
2697
2698 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
2699 for examples of such things.
2700
2701 On systems that support a close-on-exec flag on files, the flag will be set
2702 for the newly opened file descriptors as determined by the value of $^F.
2703 See L<perlvar/$^F>.
2704
2705 =item pop ARRAY
2706
2707 =item pop
2708
2709 Pops and returns the last value of the array, shortening the array by
2710 1.  Has a similar effect to
2711
2712     $tmp = $ARRAY[$#ARRAY--];
2713
2714 If there are no elements in the array, returns the undefined value.
2715 If ARRAY is omitted, pops the
2716 C<@ARGV> array in the main program, and the C<@_> array in subroutines, just
2717 like C<shift()>.
2718
2719 =item pos SCALAR
2720
2721 =item pos
2722
2723 Returns the offset of where the last C<m//g> search left off for the variable
2724 is in question (C<$_> is used when the variable is not specified).  May be
2725 modified to change that offset.  Such modification will also influence
2726 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
2727 L<perlop>.
2728
2729 =item print FILEHANDLE LIST
2730
2731 =item print LIST
2732
2733 =item print
2734
2735 Prints a string or a comma-separated list of strings.  Returns TRUE
2736 if successful.  FILEHANDLE may be a scalar variable name, in which case
2737 the variable contains the name of or a reference to the filehandle, thus introducing one
2738 level of indirection.  (NOTE: If FILEHANDLE is a variable and the next
2739 token is a term, it may be misinterpreted as an operator unless you
2740 interpose a C<+> or put parentheses around the arguments.)  If FILEHANDLE is
2741 omitted, prints by default to standard output (or to the last selected
2742 output channel--see L</select>).  If LIST is also omitted, prints C<$_> to
2743 the currently selected output channel.  To set the default output channel to something other than
2744 STDOUT use the select operation.  Note that, because print takes a
2745 LIST, anything in the LIST is evaluated in list context, and any
2746 subroutine that you call will have one or more of its expressions
2747 evaluated in list context.  Also be careful not to follow the print
2748 keyword with a left parenthesis unless you want the corresponding right
2749 parenthesis to terminate the arguments to the print--interpose a C<+> or
2750 put parentheses around all the arguments.
2751
2752 Note that if you're storing FILEHANDLES in an array or other expression,
2753 you will have to use a block returning its value instead:
2754
2755     print { $files[$i] } "stuff\n";
2756     print { $OK ? STDOUT : STDERR } "stuff\n";
2757
2758 =item printf FILEHANDLE FORMAT, LIST
2759
2760 =item printf FORMAT, LIST
2761
2762 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
2763 (the output record separator) is not appended.  The first argument
2764 of the list will be interpreted as the C<printf()> format.  If C<use locale> is
2765 in effect, the character used for the decimal point in formatted real numbers
2766 is affected by the LC_NUMERIC locale.  See L<perllocale>.
2767
2768 Don't fall into the trap of using a C<printf()> when a simple
2769 C<print()> would do.  The C<print()> is more efficient and less
2770 error prone.
2771
2772 =item prototype FUNCTION
2773
2774 Returns the prototype of a function as a string (or C<undef> if the
2775 function has no prototype).  FUNCTION is a reference to, or the name of,
2776 the function whose prototype you want to retrieve.
2777
2778 If FUNCTION is a string starting with C<CORE::>, the rest is taken as
2779 a name for Perl builtin.  If builtin is not I<overridable> (such as
2780 C<qw//>) or its arguments cannot be expressed by a prototype (such as
2781 C<system()>) - in other words, the builtin does not behave like a Perl
2782 function - returns C<undef>.  Otherwise, the string describing the
2783 equivalent prototype is returned.
2784
2785 =item push ARRAY,LIST
2786
2787 Treats ARRAY as a stack, and pushes the values of LIST
2788 onto the end of ARRAY.  The length of ARRAY increases by the length of
2789 LIST.  Has the same effect as
2790
2791     for $value (LIST) {
2792         $ARRAY[++$#ARRAY] = $value;
2793     }
2794
2795 but is more efficient.  Returns the new number of elements in the array.
2796
2797 =item q/STRING/
2798
2799 =item qq/STRING/
2800
2801 =item qr/STRING/
2802
2803 =item qx/STRING/
2804
2805 =item qw/STRING/
2806
2807 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
2808
2809 =item quotemeta EXPR
2810
2811 =item quotemeta
2812
2813 Returns the value of EXPR with all non-alphanumeric
2814 characters backslashed.  (That is, all characters not matching
2815 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
2816 returned string, regardless of any locale settings.)
2817 This is the internal function implementing
2818 the C<\Q> escape in double-quoted strings.
2819
2820 If EXPR is omitted, uses C<$_>.
2821
2822 =item rand EXPR
2823
2824 =item rand
2825
2826 Returns a random fractional number greater than or equal to C<0> and less
2827 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
2828 omitted, the value C<1> is used.  Automatically calls C<srand()> unless
2829 C<srand()> has already been called.  See also C<srand()>.
2830
2831 (Note: If your rand function consistently returns numbers that are too
2832 large or too small, then your version of Perl was probably compiled
2833 with the wrong number of RANDBITS.)
2834
2835 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
2836
2837 =item read FILEHANDLE,SCALAR,LENGTH
2838
2839 Attempts to read LENGTH bytes of data into variable SCALAR from the
2840 specified FILEHANDLE.  Returns the number of bytes actually read,
2841 C<0> at end of file, or undef if there was an error.  SCALAR will be grown
2842 or shrunk to the length actually read.  An OFFSET may be specified to
2843 place the read data at some other place than the beginning of the
2844 string.  This call is actually implemented in terms of stdio's fread(3)
2845 call.  To get a true read(2) system call, see C<sysread()>.
2846
2847 =item readdir DIRHANDLE
2848
2849 Returns the next directory entry for a directory opened by C<opendir()>.
2850 If used in list context, returns all the rest of the entries in the
2851 directory.  If there are no more entries, returns an undefined value in
2852 scalar context or a null list in list context.
2853
2854 If you're planning to filetest the return values out of a C<readdir()>, you'd
2855 better prepend the directory in question.  Otherwise, because we didn't
2856 C<chdir()> there, it would have been testing the wrong file.
2857
2858     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
2859     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
2860     closedir DIR;
2861
2862 =item readline EXPR
2863
2864 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar context, a single line
2865 is read and returned.  In list context, reads until end-of-file is
2866 reached and returns a list of lines (however you've defined lines
2867 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
2868 This is the internal function implementing the C<E<lt>EXPRE<gt>>
2869 operator, but you can use it directly.  The C<E<lt>EXPRE<gt>>
2870 operator is discussed in more detail in L<perlop/"I/O Operators">.
2871
2872     $line = <STDIN>;
2873     $line = readline(*STDIN);           # same thing
2874
2875 =item readlink EXPR
2876
2877 =item readlink
2878
2879 Returns the value of a symbolic link, if symbolic links are
2880 implemented.  If not, gives a fatal error.  If there is some system
2881 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
2882 omitted, uses C<$_>.
2883
2884 =item readpipe EXPR
2885
2886 EXPR is executed as a system command.
2887 The collected standard output of the command is returned.
2888 In scalar context, it comes back as a single (potentially
2889 multi-line) string.  In list context, returns a list of lines
2890 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
2891 This is the internal function implementing the C<qx/EXPR/>
2892 operator, but you can use it directly.  The C<qx/EXPR/>
2893 operator is discussed in more detail in L<perlop/"I/O Operators">.
2894
2895 =item recv SOCKET,SCALAR,LEN,FLAGS
2896
2897 Receives a message on a socket.  Attempts to receive LENGTH bytes of
2898 data into variable SCALAR from the specified SOCKET filehandle.
2899 Actually does a C C<recvfrom()>, so that it can return the address of the
2900 sender.  Returns the undefined value if there's an error.  SCALAR will
2901 be grown or shrunk to the length actually read.  Takes the same flags
2902 as the system call of the same name.
2903 See L<perlipc/"UDP: Message Passing"> for examples.
2904
2905 =item redo LABEL
2906
2907 =item redo
2908
2909 The C<redo> command restarts the loop block without evaluating the
2910 conditional again.  The L</continue> block, if any, is not executed.  If
2911 the LABEL is omitted, the command refers to the innermost enclosing
2912 loop.  This command is normally used by programs that want to lie to
2913 themselves about what was just input:
2914
2915     # a simpleminded Pascal comment stripper
2916     # (warning: assumes no { or } in strings)
2917     LINE: while (<STDIN>) {
2918         while (s|({.*}.*){.*}|$1 |) {}
2919         s|{.*}| |;
2920         if (s|{.*| |) {
2921             $front = $_;
2922             while (<STDIN>) {
2923                 if (/}/) {      # end of comment?
2924                     s|^|$front\{|;
2925                     redo LINE;
2926                 }
2927             }
2928         }
2929         print;
2930     }
2931
2932 C<redo> cannot be used to retry a block which returns a value such as
2933 C<eval {}>, C<sub {}> or C<do {}>.
2934
2935 See also L</continue> for an illustration of how L</last>, L</next>, and
2936 C<redo> work.
2937
2938 See also L<perlsyn>.
2939
2940 =item ref EXPR
2941
2942 =item ref
2943
2944 Returns a TRUE value if EXPR is a reference, FALSE otherwise.  If EXPR
2945 is not specified, C<$_> will be used.  The value returned depends on the
2946 type of thing the reference is a reference to.
2947 Builtin types include:
2948
2949     REF
2950     SCALAR
2951     ARRAY
2952     HASH
2953     CODE
2954     GLOB
2955
2956 If the referenced object has been blessed into a package, then that package
2957 name is returned instead.  You can think of C<ref()> as a C<typeof()> operator.
2958
2959     if (ref($r) eq "HASH") {
2960         print "r is a reference to a hash.\n";
2961     }
2962     if (!ref($r)) {
2963         print "r is not a reference at all.\n";
2964     }
2965
2966 See also L<perlref>.
2967
2968 =item rename OLDNAME,NEWNAME
2969
2970 Changes the name of a file.  Returns C<1> for success, C<0> otherwise.  Will
2971 not work across file system boundaries.
2972
2973 =item require EXPR
2974
2975 =item require
2976
2977 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
2978 supplied.  If EXPR is numeric, demands that the current version of Perl
2979 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
2980
2981 Otherwise, demands that a library file be included if it hasn't already
2982 been included.  The file is included via the do-FILE mechanism, which is
2983 essentially just a variety of C<eval()>.  Has semantics similar to the following
2984 subroutine:
2985
2986     sub require {
2987         my($filename) = @_;
2988         return 1 if $INC{$filename};
2989         my($realfilename,$result);
2990         ITER: {
2991             foreach $prefix (@INC) {
2992                 $realfilename = "$prefix/$filename";
2993                 if (-f $realfilename) {
2994                     $result = do $realfilename;
2995                     last ITER;
2996                 }
2997             }
2998             die "Can't find $filename in \@INC";
2999         }
3000         die $@ if $@;
3001         die "$filename did not return true value" unless $result;
3002         $INC{$filename} = $realfilename;
3003         return $result;
3004     }
3005
3006 Note that the file will not be included twice under the same specified
3007 name.  The file must return TRUE as the last statement to indicate
3008 successful execution of any initialization code, so it's customary to
3009 end such a file with "C<1;>" unless you're sure it'll return TRUE
3010 otherwise.  But it's better just to put the "C<1;>", in case you add more
3011 statements.
3012
3013 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3014 replaces "F<::>" with "F</>" in the filename for you,
3015 to make it easy to load standard modules.  This form of loading of
3016 modules does not risk altering your namespace.
3017
3018 In other words, if you try this:
3019
3020         require Foo::Bar;    # a splendid bareword 
3021
3022 The require function will actually look for the "F<Foo/Bar.pm>" file in the 
3023 directories specified in the C<@INC> array.
3024
3025 But if you try this:
3026
3027         $class = 'Foo::Bar';
3028         require $class;      # $class is not a bareword
3029     #or
3030         require "Foo::Bar";  # not a bareword because of the ""
3031
3032 The require function will look for the "F<Foo::Bar>" file in the @INC array and 
3033 will complain about not finding "F<Foo::Bar>" there. In this case you can do:
3034
3035         eval "require $class";
3036
3037 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3038
3039 =item reset EXPR
3040
3041 =item reset
3042
3043 Generally used in a C<continue> block at the end of a loop to clear
3044 variables and reset C<??> searches so that they work again.  The
3045 expression is interpreted as a list of single characters (hyphens
3046 allowed for ranges).  All variables and arrays beginning with one of
3047 those letters are reset to their pristine state.  If the expression is
3048 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3049 only variables or searches in the current package.  Always returns
3050 1.  Examples:
3051
3052     reset 'X';          # reset all X variables
3053     reset 'a-z';        # reset lower case variables
3054     reset;              # just reset ?? searches
3055
3056 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3057 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package variables--lexical variables
3058 are unaffected, but they clean themselves up on scope exit anyway,
3059 so you'll probably want to use them instead.  See L</my>.
3060
3061 =item return EXPR
3062
3063 =item return
3064
3065 Returns from a subroutine, C<eval()>, or C<do FILE> with the value 
3066 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3067 context, depending on how the return value will be used, and the context
3068 may vary from one execution to the next (see C<wantarray()>).  If no EXPR
3069 is given, returns an empty list in list context, an undefined value in
3070 scalar context, or nothing in a void context.
3071
3072 (Note that in the absence of a return, a subroutine, eval, or do FILE
3073 will automatically return the value of the last expression evaluated.)
3074
3075 =item reverse LIST
3076
3077 In list context, returns a list value consisting of the elements
3078 of LIST in the opposite order.  In scalar context, concatenates the
3079 elements of LIST, and returns a string value with all the characters
3080 in the opposite order.
3081
3082     print reverse <>;           # line tac, last line first
3083
3084     undef $/;                   # for efficiency of <>
3085     print scalar reverse <>;    # character tac, last line tsrif
3086
3087 This operator is also handy for inverting a hash, although there are some
3088 caveats.  If a value is duplicated in the original hash, only one of those
3089 can be represented as a key in the inverted hash.  Also, this has to
3090 unwind one hash and build a whole new one, which may take some time
3091 on a large hash.
3092
3093     %by_name = reverse %by_address;     # Invert the hash
3094
3095 =item rewinddir DIRHANDLE
3096
3097 Sets the current position to the beginning of the directory for the
3098 C<readdir()> routine on DIRHANDLE.
3099
3100 =item rindex STR,SUBSTR,POSITION
3101
3102 =item rindex STR,SUBSTR
3103
3104 Works just like index except that it returns the position of the LAST
3105 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
3106 last occurrence at or before that position.
3107
3108 =item rmdir FILENAME
3109
3110 =item rmdir
3111
3112 Deletes the directory specified by FILENAME if that directory is empty.  If it
3113 succeeds it returns TRUE, otherwise it returns FALSE and sets C<$!> (errno).  If
3114 FILENAME is omitted, uses C<$_>.
3115
3116 =item s///
3117
3118 The substitution operator.  See L<perlop>.
3119
3120 =item scalar EXPR
3121
3122 Forces EXPR to be interpreted in scalar context and returns the value
3123 of EXPR.
3124
3125     @counts = ( scalar @a, scalar @b, scalar @c );
3126
3127 There is no equivalent operator to force an expression to
3128 be interpolated in list context because it's in practice never
3129 needed.  If you really wanted to do so, however, you could use
3130 the construction C<@{[ (some expression) ]}>, but usually a simple
3131 C<(some expression)> suffices.
3132
3133 =item seek FILEHANDLE,POSITION,WHENCE
3134
3135 Sets FILEHANDLE's position, just like the C<fseek()> call of C<stdio()>.
3136 FILEHANDLE may be an expression whose value gives the name of the
3137 filehandle.  The values for WHENCE are C<0> to set the new position to
3138 POSITION, C<1> to set it to the current position plus POSITION, and C<2> to
3139 set it to EOF plus POSITION (typically negative).  For WHENCE you may
3140 use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END> from either the
3141 C<IO::Seekable> or the POSIX module.  Returns C<1> upon success, C<0> otherwise.
3142
3143 If you want to position file for C<sysread()> or C<syswrite()>, don't use
3144 C<seek()> -- buffering makes its effect on the file's system position
3145 unpredictable and non-portable.  Use C<sysseek()> instead.
3146
3147 On some systems you have to do a seek whenever you switch between reading
3148 and writing.  Amongst other things, this may have the effect of calling
3149 stdio's clearerr(3).  A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving
3150 the file position:
3151
3152     seek(TEST,0,1);
3153
3154 This is also useful for applications emulating C<tail -f>.  Once you hit
3155 EOF on your read, and then sleep for a while, you might have to stick in a
3156 seek() to reset things.  The C<seek()> doesn't change the current position,
3157 but it I<does> clear the end-of-file condition on the handle, so that the
3158 next C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
3159
3160 If that doesn't work (some stdios are particularly cantankerous), then
3161 you may need something more like this:
3162
3163     for (;;) {
3164         for ($curpos = tell(FILE); $_ = <FILE>;
3165              $curpos = tell(FILE)) {
3166             # search for some stuff and put it into files
3167         }
3168         sleep($for_a_while);
3169         seek(FILE, $curpos, 0);
3170     }
3171
3172 =item seekdir DIRHANDLE,POS
3173
3174 Sets the current position for the C<readdir()> routine on DIRHANDLE.  POS
3175 must be a value returned by C<telldir()>.  Has the same caveats about
3176 possible directory compaction as the corresponding system library
3177 routine.
3178
3179 =item select FILEHANDLE
3180
3181 =item select
3182
3183 Returns the currently selected filehandle.  Sets the current default
3184 filehandle for output, if FILEHANDLE is supplied.  This has two
3185 effects: first, a C<write()> or a C<print()> without a filehandle will
3186 default to this FILEHANDLE.  Second, references to variables related to
3187 output will refer to this output channel.  For example, if you have to
3188 set the top of form format for more than one output channel, you might
3189 do the following:
3190
3191     select(REPORT1);
3192     $^ = 'report1_top';
3193     select(REPORT2);
3194     $^ = 'report2_top';
3195
3196 FILEHANDLE may be an expression whose value gives the name of the
3197 actual filehandle.  Thus:
3198
3199     $oldfh = select(STDERR); $| = 1; select($oldfh);
3200
3201 Some programmers may prefer to think of filehandles as objects with
3202 methods, preferring to write the last example as:
3203
3204     use IO::Handle;
3205     STDERR->autoflush(1);
3206
3207 =item select RBITS,WBITS,EBITS,TIMEOUT
3208
3209 This calls the select(2) system call with the bit masks specified, which
3210 can be constructed using C<fileno()> and C<vec()>, along these lines:
3211
3212     $rin = $win = $ein = '';
3213     vec($rin,fileno(STDIN),1) = 1;
3214     vec($win,fileno(STDOUT),1) = 1;
3215     $ein = $rin | $win;
3216
3217 If you want to select on many filehandles you might wish to write a
3218 subroutine:
3219
3220     sub fhbits {
3221         my(@fhlist) = split(' ',$_[0]);
3222         my($bits);
3223         for (@fhlist) {
3224             vec($bits,fileno($_),1) = 1;
3225         }
3226         $bits;
3227     }
3228     $rin = fhbits('STDIN TTY SOCK');
3229
3230 The usual idiom is:
3231
3232     ($nfound,$timeleft) =
3233       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
3234
3235 or to block until something becomes ready just do this
3236
3237     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
3238
3239 Most systems do not bother to return anything useful in C<$timeleft>, so
3240 calling select() in scalar context just returns C<$nfound>.
3241
3242 Any of the bit masks can also be undef.  The timeout, if specified, is
3243 in seconds, which may be fractional.  Note: not all implementations are
3244 capable of returning theC<$timeleft>.  If not, they always return
3245 C<$timeleft> equal to the supplied C<$timeout>.
3246
3247 You can effect a sleep of 250 milliseconds this way:
3248
3249     select(undef, undef, undef, 0.25);
3250
3251 B<WARNING>: One should not attempt to mix buffered I/O (like C<read()>
3252 or E<lt>FHE<gt>) with C<select()>, except as permitted by POSIX, and even
3253 then only on POSIX systems.  You have to use C<sysread()> instead.
3254
3255 =item semctl ID,SEMNUM,CMD,ARG
3256
3257 Calls the System V IPC function C<semctl()>.  You'll probably have to say
3258
3259     use IPC::SysV;
3260
3261 first to get the correct constant definitions.  If CMD is IPC_STAT or
3262 GETALL, then ARG must be a variable which will hold the returned
3263 semid_ds structure or semaphore value array.  Returns like C<ioctl()>: the
3264 undefined value for error, "C<0> but true" for zero, or the actual return
3265 value otherwise.  See also C<IPC::SysV> and C<IPC::Semaphore> documentation.
3266
3267 =item semget KEY,NSEMS,FLAGS
3268
3269 Calls the System V IPC function semget.  Returns the semaphore id, or
3270 the undefined value if there is an error.  See also C<IPC::SysV> and
3271 C<IPC::SysV::Semaphore> documentation.
3272
3273 =item semop KEY,OPSTRING
3274
3275 Calls the System V IPC function semop to perform semaphore operations
3276 such as signaling and waiting.  OPSTRING must be a packed array of
3277 semop structures.  Each semop structure can be generated with
3278 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
3279 operations is implied by the length of OPSTRING.  Returns TRUE if
3280 successful, or FALSE if there is an error.  As an example, the
3281 following code waits on semaphore C<$semnum> of semaphore id C<$semid>:
3282
3283     $semop = pack("sss", $semnum, -1, 0);
3284     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
3285
3286 To signal the semaphore, replace C<-1> with C<1>.  See also C<IPC::SysV>
3287 and C<IPC::SysV::Semaphore> documentation.
3288
3289 =item send SOCKET,MSG,FLAGS,TO
3290
3291 =item send SOCKET,MSG,FLAGS
3292
3293 Sends a message on a socket.  Takes the same flags as the system call
3294 of the same name.  On unconnected sockets you must specify a
3295 destination to send TO, in which case it does a C C<sendto()>.  Returns
3296 the number of characters sent, or the undefined value if there is an
3297 error.
3298 See L<perlipc/"UDP: Message Passing"> for examples.
3299
3300 =item setpgrp PID,PGRP
3301
3302 Sets the current process group for the specified PID, C<0> for the current
3303 process.  Will produce a fatal error if used on a machine that doesn't
3304 implement setpgrp(2).  If the arguments are omitted, it defaults to
3305 C<0,0>.  Note that the POSIX version of C<setpgrp()> does not accept any
3306 arguments, so only setpgrp C<0,0> is portable.
3307
3308 =item setpriority WHICH,WHO,PRIORITY
3309
3310 Sets the current priority for a process, a process group, or a user.
3311 (See setpriority(2).)  Will produce a fatal error if used on a machine
3312 that doesn't implement setpriority(2).
3313
3314 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
3315
3316 Sets the socket option requested.  Returns undefined if there is an
3317 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
3318 argument.
3319
3320 =item shift ARRAY
3321
3322 =item shift
3323
3324 Shifts the first value of the array off and returns it, shortening the
3325 array by 1 and moving everything down.  If there are no elements in the
3326 array, returns the undefined value.  If ARRAY is omitted, shifts the
3327 C<@_> array within the lexical scope of subroutines and formats, and the
3328 C<@ARGV> array at file scopes or within the lexical scopes established by
3329 the C<eval ''>, C<BEGIN {}>, C<END {}>, and C<INIT {}> constructs.
3330 See also C<unshift()>, C<push()>, and C<pop()>.  C<Shift()> and C<unshift()> do the
3331 same thing to the left end of an array that C<pop()> and C<push()> do to the
3332 right end.
3333
3334 =item shmctl ID,CMD,ARG
3335
3336 Calls the System V IPC function shmctl.  You'll probably have to say
3337
3338     use IPC::SysV;
3339
3340 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3341 then ARG must be a variable which will hold the returned C<shmid_ds>
3342 structure.  Returns like ioctl: the undefined value for error, "C<0> but
3343 true" for zero, or the actual return value otherwise.
3344 See also C<IPC::SysV> documentation.
3345
3346 =item shmget KEY,SIZE,FLAGS
3347
3348 Calls the System V IPC function shmget.  Returns the shared memory
3349 segment id, or the undefined value if there is an error.
3350 See also C<IPC::SysV> documentation.
3351
3352 =item shmread ID,VAR,POS,SIZE
3353
3354 =item shmwrite ID,STRING,POS,SIZE
3355
3356 Reads or writes the System V shared memory segment ID starting at
3357 position POS for size SIZE by attaching to it, copying in/out, and
3358 detaching from it.  When reading, VAR must be a variable that will
3359 hold the data read.  When writing, if STRING is too long, only SIZE
3360 bytes are used; if STRING is too short, nulls are written to fill out
3361 SIZE bytes.  Return TRUE if successful, or FALSE if there is an error.
3362 See also C<IPC::SysV> documentation.
3363
3364 =item shutdown SOCKET,HOW
3365
3366 Shuts down a socket connection in the manner indicated by HOW, which
3367 has the same interpretation as in the system call of the same name.
3368
3369     shutdown(SOCKET, 0);    # I/we have stopped reading data
3370     shutdown(SOCKET, 1);    # I/we have stopped writing data
3371     shutdown(SOCKET, 2);    # I/we have stopped using this socket
3372
3373 This is useful with sockets when you want to tell the other
3374 side you're done writing but not done reading, or vice versa.
3375 It's also a more insistent form of close because it also 
3376 disables the filedescriptor in any forked copies in other
3377 processes.
3378
3379 =item sin EXPR
3380
3381 =item sin
3382
3383 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
3384 returns sine of C<$_>.
3385
3386 For the inverse sine operation, you may use the C<POSIX::asin()>
3387 function, or use this relation:
3388
3389     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
3390
3391 =item sleep EXPR
3392
3393 =item sleep
3394
3395 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
3396 May be interrupted if the process receives a signal such as C<SIGALRM>.
3397 Returns the number of seconds actually slept.  You probably cannot
3398 mix C<alarm()> and C<sleep()> calls, because C<sleep()> is often implemented
3399 using C<alarm()>.
3400
3401 On some older systems, it may sleep up to a full second less than what
3402 you requested, depending on how it counts seconds.  Most modern systems
3403 always sleep the full amount.  They may appear to sleep longer than that,
3404 however, because your process might not be scheduled right away in a
3405 busy multitasking system.
3406
3407 For delays of finer granularity than one second, you may use Perl's
3408 C<syscall()> interface to access setitimer(2) if your system supports it,
3409 or else see L</select()> above.
3410
3411 See also the POSIX module's C<sigpause()> function.
3412
3413 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
3414
3415 Opens a socket of the specified kind and attaches it to filehandle
3416 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for the
3417 system call of the same name.  You should "C<use Socket;>" first to get
3418 the proper definitions imported.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
3419
3420 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
3421
3422 Creates an unnamed pair of sockets in the specified domain, of the
3423 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
3424 for the system call of the same name.  If unimplemented, yields a fatal
3425 error.  Returns TRUE if successful.
3426
3427 Some systems defined C<pipe()> in terms of C<socketpair()>, in which a call
3428 to C<pipe(Rdr, Wtr)> is essentially:
3429
3430     use Socket;
3431     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
3432     shutdown(Rdr, 1);        # no more writing for reader
3433     shutdown(Wtr, 0);        # no more reading for writer
3434
3435 See L<perlipc> for an example of socketpair use.
3436
3437 =item sort SUBNAME LIST
3438
3439 =item sort BLOCK LIST
3440
3441 =item sort LIST
3442
3443 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
3444 is omitted, C<sort()>s in standard string comparison order.  If SUBNAME is
3445 specified, it gives the name of a subroutine that returns an integer
3446 less than, equal to, or greater than C<0>, depending on how the elements
3447 of the array are to be ordered.  (The C<E<lt>=E<gt>> and C<cmp>
3448 operators are extremely useful in such routines.)  SUBNAME may be a
3449 scalar variable name (unsubscripted), in which case the value provides
3450 the name of (or a reference to) the actual subroutine to use.  In place
3451 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
3452 subroutine.
3453
3454 In the interests of efficiency the normal calling code for subroutines is
3455 bypassed, with the following effects: the subroutine may not be a
3456 recursive subroutine, and the two elements to be compared are passed into
3457 the subroutine not via C<@_> but as the package global variables C<$a> and
3458 C<$b> (see example below).  They are passed by reference, so don't
3459 modify C<$a> and C<$b>.  And don't try to declare them as lexicals either.
3460
3461 You also cannot exit out of the sort block or subroutine using any of the
3462 loop control operators described in L<perlsyn> or with C<goto()>.
3463
3464 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
3465 current collation locale.  See L<perllocale>.
3466
3467 Examples:
3468
3469     # sort lexically
3470     @articles = sort @files;
3471
3472     # same thing, but with explicit sort routine
3473     @articles = sort {$a cmp $b} @files;
3474
3475     # now case-insensitively
3476     @articles = sort {uc($a) cmp uc($b)} @files;
3477
3478     # same thing in reversed order
3479     @articles = sort {$b cmp $a} @files;
3480
3481     # sort numerically ascending
3482     @articles = sort {$a <=> $b} @files;
3483
3484     # sort numerically descending
3485     @articles = sort {$b <=> $a} @files;
3486
3487     # sort using explicit subroutine name
3488     sub byage {
3489         $age{$a} <=> $age{$b};  # presuming numeric
3490     }
3491     @sortedclass = sort byage @class;
3492
3493     # this sorts the %age hash by value instead of key
3494     # using an in-line function
3495     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
3496
3497     sub backwards { $b cmp $a; }
3498     @harry = ('dog','cat','x','Cain','Abel');
3499     @george = ('gone','chased','yz','Punished','Axed');
3500     print sort @harry;
3501             # prints AbelCaincatdogx
3502     print sort backwards @harry;
3503             # prints xdogcatCainAbel
3504     print sort @george, 'to', @harry;
3505             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
3506
3507     # inefficiently sort by descending numeric compare using
3508     # the first integer after the first = sign, or the
3509     # whole record case-insensitively otherwise
3510
3511     @new = sort {
3512         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
3513                             ||
3514                     uc($a)  cmp  uc($b)
3515     } @old;
3516
3517     # same thing, but much more efficiently;
3518     # we'll build auxiliary indices instead
3519     # for speed
3520     @nums = @caps = ();
3521     for (@old) {
3522         push @nums, /=(\d+)/;
3523         push @caps, uc($_);
3524     }
3525
3526     @new = @old[ sort {
3527                         $nums[$b] <=> $nums[$a]
3528                                  ||
3529                         $caps[$a] cmp $caps[$b]
3530                        } 0..$#old
3531                ];
3532
3533     # same thing using a Schwartzian Transform (no temps)
3534     @new = map { $_->[0] }
3535         sort { $b->[1] <=> $a->[1]
3536                         ||
3537                $a->[2] cmp $b->[2]
3538         } map { [$_, /=(\d+)/, uc($_)] } @old;
3539
3540 If you're using strict, you I<MUST NOT> declare C<$a>
3541 and C<$b> as lexicals.  They are package globals.  That means
3542 if you're in the C<main> package, it's
3543
3544     @articles = sort {$main::b <=> $main::a} @files;
3545
3546 or just
3547
3548     @articles = sort {$::b <=> $::a} @files;
3549
3550 but if you're in the C<FooPack> package, it's
3551
3552     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
3553
3554 The comparison function is required to behave.  If it returns
3555 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
3556 sometimes saying the opposite, for example) the results are not
3557 well-defined.
3558
3559 =item splice ARRAY,OFFSET,LENGTH,LIST
3560
3561 =item splice ARRAY,OFFSET,LENGTH
3562
3563 =item splice ARRAY,OFFSET
3564
3565 Removes the elements designated by OFFSET and LENGTH from an array, and
3566 replaces them with the elements of LIST, if any.  In list context,
3567 returns the elements removed from the array.  In scalar context,
3568 returns the last element removed, or C<undef> if no elements are
3569 removed.  The array grows or shrinks as necessary.
3570 If OFFSET is negative then it start that far from the end of the array.
3571 If LENGTH is omitted, removes everything from OFFSET onward.
3572 If LENGTH is negative, leave that many elements off the end of the array.
3573 The following equivalences hold (assuming C<$[ == 0>):
3574
3575     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
3576     pop(@a)             splice(@a,-1)
3577     shift(@a)           splice(@a,0,1)
3578     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
3579     $a[$x] = $y         splice(@a,$x,1,$y)
3580
3581 Example, assuming array lengths are passed before arrays:
3582
3583     sub aeq {   # compare two list values
3584         my(@a) = splice(@_,0,shift);
3585         my(@b) = splice(@_,0,shift);
3586         return 0 unless @a == @b;       # same len?
3587         while (@a) {
3588             return 0 if pop(@a) ne pop(@b);
3589         }
3590         return 1;
3591     }
3592     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
3593
3594 =item split /PATTERN/,EXPR,LIMIT
3595
3596 =item split /PATTERN/,EXPR
3597
3598 =item split /PATTERN/
3599
3600 =item split
3601
3602 Splits a string into an array of strings, and returns it.  By default,
3603 empty leading fields are preserved, and empty trailing ones are deleted.
3604
3605 If not in list context, returns the number of fields found and splits into
3606 the C<@_> array.  (In list context, you can force the split into C<@_> by
3607 using C<??> as the pattern delimiters, but it still returns the list
3608 value.)  The use of implicit split to C<@_> is deprecated, however, because
3609 it clobbers your subroutine arguments.
3610
3611 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
3612 splits on whitespace (after skipping any leading whitespace).  Anything
3613 matching PATTERN is taken to be a delimiter separating the fields.  (Note
3614 that the delimiter may be longer than one character.)
3615
3616 If LIMIT is specified and positive, splits into no more than that
3617 many fields (though it may split into fewer).  If LIMIT is unspecified
3618 or zero, trailing null fields are stripped (which potential users
3619 of C<pop()> would do well to remember).  If LIMIT is negative, it is
3620 treated as if an arbitrarily large LIMIT had been specified.
3621
3622 A pattern matching the null string (not to be confused with
3623 a null pattern C<//>, which is just one member of the set of patterns
3624 matching a null string) will split the value of EXPR into separate
3625 characters at each point it matches that way.  For example:
3626
3627     print join(':', split(/ */, 'hi there'));
3628
3629 produces the output 'h:i:t:h:e:r:e'.
3630
3631 The LIMIT parameter can be used to split a line partially
3632
3633     ($login, $passwd, $remainder) = split(/:/, $_, 3);
3634
3635 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
3636 one larger than the number of variables in the list, to avoid
3637 unnecessary work.  For the list above LIMIT would have been 4 by
3638 default.  In time critical applications it behooves you not to split
3639 into more fields than you really need.
3640
3641 If the PATTERN contains parentheses, additional array elements are
3642 created from each matching substring in the delimiter.
3643
3644     split(/([,-])/, "1-10,20", 3);
3645
3646 produces the list value
3647
3648     (1, '-', 10, ',', 20)
3649
3650 If you had the entire header of a normal Unix email message in C<$header>,
3651 you could split it up into fields and their values this way:
3652
3653     $header =~ s/\n\s+/ /g;  # fix continuation lines
3654     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
3655
3656 The pattern C</PATTERN/> may be replaced with an expression to specify
3657 patterns that vary at runtime.  (To do runtime compilation only once,
3658 use C</$variable/o>.)
3659
3660 As a special case, specifying a PATTERN of space (C<' '>) will split on
3661 white space just as C<split()> with no arguments does.  Thus, C<split(' ')> can
3662 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
3663 will give you as many null initial fields as there are leading spaces.
3664 A C<split()> on C</\s+/> is like a C<split(' ')> except that any leading
3665 whitespace produces a null first field.  A C<split()> with no arguments
3666 really does a C<split(' ', $_)> internally.
3667
3668 Example:
3669
3670     open(PASSWD, '/etc/passwd');
3671     while (<PASSWD>) {
3672         ($login, $passwd, $uid, $gid,
3673          $gcos, $home, $shell) = split(/:/);
3674         #...
3675     }
3676
3677 (Note that C<$shell> above will still have a newline on it.  See L</chop>,
3678 L</chomp>, and L</join>.)
3679
3680 =item sprintf FORMAT, LIST
3681
3682 Returns a string formatted by the usual C<printf()> conventions of the
3683 C library function C<sprintf()>.  See L<sprintf(3)> or L<printf(3)>
3684 on your system for an explanation of the general principles.
3685
3686 Perl does its own C<sprintf()> formatting -- it emulates the C
3687 function C<sprintf()>, but it doesn't use it (except for floating-point
3688 numbers, and even then only the standard modifiers are allowed).  As a
3689 result, any non-standard extensions in your local C<sprintf()> are not
3690 available from Perl.
3691
3692 Perl's C<sprintf()> permits the following universally-known conversions:
3693
3694    %%   a percent sign
3695    %c   a character with the given number
3696    %s   a string
3697    %d   a signed integer, in decimal
3698    %u   an unsigned integer, in decimal
3699    %o   an unsigned integer, in octal
3700    %x   an unsigned integer, in hexadecimal
3701    %e   a floating-point number, in scientific notation
3702    %f   a floating-point number, in fixed decimal notation
3703    %g   a floating-point number, in %e or %f notation
3704
3705 In addition, Perl permits the following widely-supported conversions:
3706
3707    %X   like %x, but using upper-case letters
3708    %E   like %e, but using an upper-case "E"
3709    %G   like %g, but with an upper-case "E" (if applicable)
3710    %p   a pointer (outputs the Perl value's address in hexadecimal)
3711    %n   special: *stores* the number of characters output so far
3712         into the next variable in the parameter list 
3713
3714 Finally, for backward (and we do mean "backward") compatibility, Perl
3715 permits these unnecessary but widely-supported conversions:
3716
3717    %i   a synonym for %d
3718    %D   a synonym for %ld
3719    %U   a synonym for %lu
3720    %O   a synonym for %lo
3721    %F   a synonym for %f
3722
3723 Perl permits the following universally-known flags between the C<%>
3724 and the conversion letter:
3725
3726    space   prefix positive number with a space
3727    +       prefix positive number with a plus sign
3728    -       left-justify within the field
3729    0       use zeros, not spaces, to right-justify
3730    #       prefix non-zero octal with "0", non-zero hex with "0x"
3731    number  minimum field width
3732    .number "precision": digits after decimal point for
3733            floating-point, max length for string, minimum length
3734            for integer
3735    l       interpret integer as C type "long" or "unsigned long"
3736    h       interpret integer as C type "short" or "unsigned short"
3737
3738 There is also one Perl-specific flag:
3739
3740    V       interpret integer as Perl's standard integer type
3741
3742 Where a number would appear in the flags, an asterisk ("C<*>") may be
3743 used instead, in which case Perl uses the next item in the parameter
3744 list as the given number (that is, as the field width or precision).
3745 If a field width obtained through "C<*>" is negative, it has the same
3746 effect as the "C<->" flag: left-justification.
3747
3748 If C<use locale> is in effect, the character used for the decimal
3749 point in formatted real numbers is affected by the LC_NUMERIC locale.
3750 See L<perllocale>.
3751
3752 =item sqrt EXPR
3753
3754 =item sqrt
3755
3756 Return the square root of EXPR.  If EXPR is omitted, returns square
3757 root of C<$_>.
3758
3759 =item srand EXPR
3760
3761 =item srand
3762
3763 Sets the random number seed for the C<rand()> operator.  If EXPR is
3764 omitted, uses a semi-random value supplied by the kernel (if it supports
3765 the F</dev/urandom> device) or based on the current time and process
3766 ID, among other things.  In versions of Perl prior to 5.004 the default
3767 seed was just the current C<time()>.  This isn't a particularly good seed,
3768 so many old programs supply their own seed value (often C<time ^ $$> or
3769 C<time ^ ($$ + ($$ E<lt>E<lt> 15))>), but that isn't necessary any more.
3770
3771 In fact, it's usually not necessary to call C<srand()> at all, because if
3772 it is not called explicitly, it is called implicitly at the first use of
3773 the C<rand()> operator.  However, this was not the case in version of Perl
3774 before 5.004, so if your script will run under older Perl versions, it
3775 should call C<srand()>.
3776
3777 Note that you need something much more random than the default seed for
3778 cryptographic purposes.  Checksumming the compressed output of one or more
3779 rapidly changing operating system status programs is the usual method.  For
3780 example:
3781
3782     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
3783
3784 If you're particularly concerned with this, see the C<Math::TrulyRandom>
3785 module in CPAN.
3786
3787 Do I<not> call C<srand()> multiple times in your program unless you know
3788 exactly what you're doing and why you're doing it.  The point of the
3789 function is to "seed" the C<rand()> function so that C<rand()> can produce
3790 a different sequence each time you run your program.  Just do it once at the
3791 top of your program, or you I<won't> get random numbers out of C<rand()>!
3792
3793 Frequently called programs (like CGI scripts) that simply use
3794
3795     time ^ $$
3796
3797 for a seed can fall prey to the mathematical property that
3798
3799     a^b == (a+1)^(b+1)
3800
3801 one-third of the time.  So don't do that.
3802
3803 =item stat FILEHANDLE
3804
3805 =item stat EXPR
3806
3807 =item stat
3808
3809 Returns a 13-element list giving the status info for a file, either
3810 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
3811 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
3812 as follows:
3813
3814     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
3815        $atime,$mtime,$ctime,$blksize,$blocks)
3816            = stat($filename);
3817
3818 Not all fields are supported on all filesystem types.  Here are the
3819 meaning of the fields:
3820
3821   0 dev      device number of filesystem
3822   1 ino      inode number
3823   2 mode     file mode  (type and permissions)
3824   3 nlink    number of (hard) links to the file
3825   4 uid      numeric user ID of file's owner
3826   5 gid      numeric group ID of file's owner
3827   6 rdev     the device identifier (special files only)
3828   7 size     total size of file, in bytes
3829   8 atime    last access time since the epoch
3830   9 mtime    last modify time since the epoch
3831  10 ctime    inode change time (NOT creation time!) since the epoch
3832  11 blksize  preferred block size for file system I/O
3833  12 blocks   actual number of blocks allocated
3834
3835 (The epoch was at 00:00 January 1, 1970 GMT.)
3836
3837 If stat is passed the special filehandle consisting of an underline, no
3838 stat is done, but the current contents of the stat structure from the
3839 last stat or filetest are returned.  Example:
3840
3841     if (-x $file && (($d) = stat(_)) && $d < 0) {
3842         print "$file is executable NFS file\n";
3843     }
3844
3845 (This works on machines only for which the device number is negative under NFS.)
3846
3847 In scalar context, C<stat()> returns a boolean value indicating success
3848 or failure, and, if successful, sets the information associated with
3849 the special filehandle C<_>.
3850
3851 =item study SCALAR
3852
3853 =item study
3854
3855 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
3856 doing many pattern matches on the string before it is next modified.
3857 This may or may not save time, depending on the nature and number of
3858 patterns you are searching on, and on the distribution of character
3859 frequencies in the string to be searched -- you probably want to compare
3860 run times with and without it to see which runs faster.  Those loops
3861 which scan for many short constant strings (including the constant
3862 parts of more complex patterns) will benefit most.  You may have only
3863 one C<study()> active at a time -- if you study a different scalar the first
3864 is "unstudied".  (The way C<study()> works is this: a linked list of every
3865 character in the string to be searched is made, so we know, for
3866 example, where all the C<'k'> characters are.  From each search string,
3867 the rarest character is selected, based on some static frequency tables
3868 constructed from some C programs and English text.  Only those places
3869 that contain this "rarest" character are examined.)
3870
3871 For example, here is a loop that inserts index producing entries
3872 before any line containing a certain pattern:
3873
3874     while (<>) {
3875         study;
3876         print ".IX foo\n" if /\bfoo\b/;
3877         print ".IX bar\n" if /\bbar\b/;
3878         print ".IX blurfl\n" if /\bblurfl\b/;
3879         # ...
3880         print;
3881     }
3882
3883 In searching for C</\bfoo\b/>, only those locations in C<$_> that contain C<"f">
3884 will be looked at, because C<"f"> is rarer than C<"o">.  In general, this is
3885 a big win except in pathological cases.  The only question is whether
3886 it saves you more time than it took to build the linked list in the
3887 first place.
3888
3889 Note that if you have to look for strings that you don't know till
3890 runtime, you can build an entire loop as a string and C<eval()> that to
3891 avoid recompiling all your patterns all the time.  Together with
3892 undefining C<$/> to input entire files as one record, this can be very
3893 fast, often faster than specialized programs like fgrep(1).  The following
3894 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
3895 out the names of those files that contain a match:
3896
3897     $search = 'while (<>) { study;';
3898     foreach $word (@words) {
3899         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
3900     }
3901     $search .= "}";
3902     @ARGV = @files;
3903     undef $/;
3904     eval $search;               # this screams
3905     $/ = "\n";          # put back to normal input delimiter
3906     foreach $file (sort keys(%seen)) {
3907         print $file, "\n";
3908     }
3909
3910 =item sub BLOCK
3911
3912 =item sub NAME
3913
3914 =item sub NAME BLOCK
3915
3916 This is subroutine definition, not a real function I<per se>.  With just a
3917 NAME (and possibly prototypes), it's just a forward declaration.  Without
3918 a NAME, it's an anonymous function declaration, and does actually return a
3919 value: the CODE ref of the closure you just created.  See L<perlsub> and
3920 L<perlref> for details.
3921
3922 =item substr EXPR,OFFSET,LEN,REPLACEMENT
3923
3924 =item substr EXPR,OFFSET,LEN
3925
3926 =item substr EXPR,OFFSET
3927
3928 Extracts a substring out of EXPR and returns it.  First character is at
3929 offset C<0>, or whatever you've set C<$[> to (but don't do that).
3930 If OFFSET is negative (or more precisely, less than C<$[>), starts
3931 that far from the end of the string.  If LEN is omitted, returns
3932 everything to the end of the string.  If LEN is negative, leaves that
3933 many characters off the end of the string.
3934
3935 If you specify a substring that is partly outside the string, the part
3936 within the string is returned.    If the substring is totally outside
3937 the string a warning is produced.
3938
3939 You can use the C<substr()> function
3940 as an lvalue, in which case EXPR must be an lvalue.  If you assign
3941 something shorter than LEN, the string will shrink, and if you assign
3942 something longer than LEN, the string will grow to accommodate it.  To
3943 keep the string the same length you may need to pad or chop your value
3944 using C<sprintf()>.
3945
3946 An alternative to using C<substr()> as an lvalue is to specify the
3947 replacement string as the 4th argument.  This allows you to replace
3948 parts of the EXPR and return what was there before in one operation.
3949
3950 =item symlink OLDFILE,NEWFILE
3951
3952 Creates a new filename symbolically linked to the old filename.
3953 Returns C<1> for success, C<0> otherwise.  On systems that don't support
3954 symbolic links, produces a fatal error at run time.  To check for that,
3955 use eval:
3956
3957     $symlink_exists =  eval { symlink("",""); 1 };
3958
3959 =item syscall LIST
3960
3961 Calls the system call specified as the first element of the list,
3962 passing the remaining elements as arguments to the system call.  If
3963 unimplemented, produces a fatal error.  The arguments are interpreted
3964 as follows: if a given argument is numeric, the argument is passed as
3965 an int.  If not, the pointer to the string value is passed.  You are
3966 responsible to make sure a string is pre-extended long enough to
3967 receive any result that might be written into a string.  You can't use a
3968 string literal (or other read-only string) as an argument to C<syscall()>
3969 because Perl has to assume that any string pointer might be written
3970 through.  If your
3971 integer arguments are not literals and have never been interpreted in a
3972 numeric context, you may need to add C<0> to them to force them to look
3973 like numbers.  This emulates the C<syswrite()> function (or vice versa):
3974
3975     require 'syscall.ph';               # may need to run h2ph
3976     $s = "hi there\n";
3977     syscall(&SYS_write, fileno(STDOUT), $s, length $s);
3978
3979 Note that Perl supports passing of up to only 14 arguments to your system call,
3980 which in practice should usually suffice.
3981
3982 Syscall returns whatever value returned by the system call it calls.
3983 If the system call fails, C<syscall()> returns C<-1> and sets C<$!> (errno).
3984 Note that some system calls can legitimately return C<-1>.  The proper
3985 way to handle such calls is to assign C<$!=0;> before the call and
3986 check the value of C<$!> if syscall returns C<-1>.
3987
3988 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
3989 number of the read end of the pipe it creates.  There is no way
3990 to retrieve the file number of the other end.  You can avoid this 
3991 problem by using C<pipe()> instead.
3992
3993 =item sysopen FILEHANDLE,FILENAME,MODE
3994
3995 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
3996
3997 Opens the file whose filename is given by FILENAME, and associates it
3998 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
3999 the name of the real filehandle wanted.  This function calls the
4000 underlying operating system's C<open()> function with the parameters
4001 FILENAME, MODE, PERMS.
4002
4003 The possible values and flag bits of the MODE parameter are
4004 system-dependent; they are available via the standard module C<Fcntl>.
4005 For historical reasons, some values work on almost every system
4006 supported by perl: zero means read-only, one means write-only, and two
4007 means read/write.  We know that these values do I<not> work under
4008 OS/390 & VM/ESA Unix and on the Macintosh; you probably don't want to
4009 use them in new code.
4010
4011 If the file named by FILENAME does not exist and the C<open()> call creates
4012 it (typically because MODE includes the C<O_CREAT> flag), then the value of
4013 PERMS specifies the permissions of the newly created file.  If you omit
4014 the PERMS argument to C<sysopen()>, Perl uses the octal value C<0666>.
4015 These permission values need to be in octal, and are modified by your
4016 process's current C<umask>.
4017
4018 Seldom if ever use C<0644> as argument to C<sysopen()> because that
4019 takes away the user's option to have a more permissive umask.  Better
4020 to omit it.  See the perlfunc(1) entry on C<umask> for more on this.
4021
4022 The C<IO::File> module provides a more object-oriented approach, if you're
4023 into that kind of thing.
4024
4025 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
4026
4027 =item sysread FILEHANDLE,SCALAR,LENGTH
4028
4029 Attempts to read LENGTH bytes of data into variable SCALAR from the
4030 specified FILEHANDLE, using the system call read(2).  It bypasses stdio,
4031 so mixing this with other kinds of reads, C<print()>, C<write()>,
4032 C<seek()>, C<tell()>, or C<eof()> can cause confusion because stdio
4033 usually buffers data.  Returns the number of bytes actually read, C<0>
4034 at end of file, or undef if there was an error.  SCALAR will be grown or
4035 shrunk so that the last byte actually read is the last byte of the
4036 scalar after the read.
4037
4038 An OFFSET may be specified to place the read data at some place in the
4039 string other than the beginning.  A negative OFFSET specifies
4040 placement at that many bytes counting backwards from the end of the
4041 string.  A positive OFFSET greater than the length of SCALAR results
4042 in the string being padded to the required size with C<"\0"> bytes before
4043 the result of the read is appended.
4044
4045 =item sysseek FILEHANDLE,POSITION,WHENCE
4046
4047 Sets FILEHANDLE's system position using the system call lseek(2).  It
4048 bypasses stdio, so mixing this with reads (other than C<sysread()>),
4049 C<print()>, C<write()>, C<seek()>, C<tell()>, or C<eof()> may cause
4050 confusion.  FILEHANDLE may be an expression whose value gives the name
4051 of the filehandle.  The values for WHENCE are C<0> to set the new
4052 position to POSITION, C<1> to set the it to the current position plus
4053 POSITION, and C<2> to set it to EOF plus POSITION (typically negative).
4054 For WHENCE, you may use the constants C<SEEK_SET>, C<SEEK_CUR>, and
4055 C<SEEK_END> from either the C<IO::Seekable> or the POSIX module.
4056
4057 Returns the new position, or the undefined value on failure.  A position
4058 of zero is returned as the string "C<0> but true"; thus C<sysseek()> returns
4059 TRUE on success and FALSE on failure, yet you can still easily determine
4060 the new position.
4061
4062 =item system LIST
4063
4064 =item system PROGRAM LIST
4065
4066 Does exactly the same thing as "C<exec LIST>" except that a fork is done
4067 first, and the parent process waits for the child process to complete.
4068 Note that argument processing varies depending on the number of
4069 arguments.  If there is more than one argument in LIST, or if LIST is
4070 an array with more than one value, starts the program given by the
4071 first element of the list with arguments given by the rest of the list.
4072 If there is only one scalar argument, the argument is
4073 checked for shell metacharacters, and if there are any, the entire
4074 argument is passed to the system's command shell for parsing (this is
4075 C</bin/sh -c> on Unix platforms, but varies on other platforms).  If
4076 there are no shell metacharacters in the argument, it is split into
4077 words and passed directly to C<execvp()>, which is more efficient.
4078
4079 The return value is the exit status of the program as
4080 returned by the C<wait()> call.  To get the actual exit value divide by
4081 256.  See also L</exec>.  This is I<NOT> what you want to use to capture
4082 the output from a command, for that you should use merely backticks or
4083 C<qx//>, as described in L<perlop/"`STRING`">.
4084
4085 Like C<exec()>, C<system()> allows you to lie to a program about its name if
4086 you use the "C<system PROGRAM LIST>" syntax.  Again, see L</exec>.
4087
4088 Because C<system()> and backticks block C<SIGINT> and C<SIGQUIT>, killing the
4089 program they're running doesn't actually interrupt your program.
4090
4091     @args = ("command", "arg1", "arg2");
4092     system(@args) == 0
4093          or die "system @args failed: $?"
4094
4095 You can check all the failure possibilities by inspecting
4096 C<$?> like this:
4097
4098     $exit_value  = $? >> 8;
4099     $signal_num  = $? & 127;
4100     $dumped_core = $? & 128;
4101
4102 When the arguments get executed via the system shell, results
4103 and return codes will be subject to its quirks and capabilities.
4104 See L<perlop/"`STRING`"> and L</exec> for details.
4105
4106 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
4107
4108 =item syswrite FILEHANDLE,SCALAR,LENGTH
4109
4110 =item syswrite FILEHANDLE,SCALAR
4111
4112 Attempts to write LENGTH bytes of data from variable SCALAR to the
4113 specified FILEHANDLE, using the system call write(2).  If LENGTH is
4114 not specified, writes whole SCALAR. It bypasses
4115 stdio, so mixing this with reads (other than C<sysread())>, C<print()>,
4116 C<write()>, C<seek()>, C<tell()>, or C<eof()> may cause confusion
4117 because stdio usually buffers data.  Returns the number of bytes
4118 actually written, or C<undef> if there was an error.  If the LENGTH is
4119 greater than the available data in the SCALAR after the OFFSET, only as
4120 much data as is available will be written.
4121
4122 An OFFSET may be specified to write the data from some part of the
4123 string other than the beginning.  A negative OFFSET specifies writing
4124 that many bytes counting backwards from the end of the string.  In the
4125 case the SCALAR is empty you can use OFFSET but only zero offset.
4126
4127 =item tell FILEHANDLE
4128
4129 =item tell
4130
4131 Returns the current position for FILEHANDLE.  FILEHANDLE may be an
4132 expression whose value gives the name of the actual filehandle.  If
4133 FILEHANDLE is omitted, assumes the file last read.
4134
4135 =item telldir DIRHANDLE
4136
4137 Returns the current position of the C<readdir()> routines on DIRHANDLE.
4138 Value may be given to C<seekdir()> to access a particular location in a
4139 directory.  Has the same caveats about possible directory compaction as
4140 the corresponding system library routine.
4141
4142 =item tie VARIABLE,CLASSNAME,LIST
4143
4144 This function binds a variable to a package class that will provide the
4145 implementation for the variable.  VARIABLE is the name of the variable
4146 to be enchanted.  CLASSNAME is the name of a class implementing objects
4147 of correct type.  Any additional arguments are passed to the "C<new()>"
4148 method of the class (meaning C<TIESCALAR>, C<TIEHANDLE>, C<TIEARRAY>,
4149 or C<TIEHASH>).  Typically these are arguments such as might be passed
4150 to the C<dbm_open()> function of C.  The object returned by the "C<new()>"
4151 method is also returned by the C<tie()> function, which would be useful
4152 if you want to access other methods in CLASSNAME.
4153
4154 Note that functions such as C<keys()> and C<values()> may return huge lists
4155 when used on large objects, like DBM files.  You may prefer to use the
4156 C<each()> function to iterate over such.  Example:
4157
4158     # print out history file offsets
4159     use NDBM_File;
4160     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
4161     while (($key,$val) = each %HIST) {
4162         print $key, ' = ', unpack('L',$val), "\n";
4163     }
4164     untie(%HIST);
4165
4166 A class implementing a hash should have the following methods:
4167
4168     TIEHASH classname, LIST
4169     FETCH this, key
4170     STORE this, key, value
4171     DELETE this, key
4172     CLEAR this
4173     EXISTS this, key
4174     FIRSTKEY this
4175     NEXTKEY this, lastkey
4176     DESTROY this
4177
4178 A class implementing an ordinary array should have the following methods:
4179
4180     TIEARRAY classname, LIST
4181     FETCH this, key
4182     STORE this, key, value
4183     FETCHSIZE this
4184     STORESIZE this, count
4185     CLEAR this
4186     PUSH this, LIST
4187     POP this
4188     SHIFT this
4189     UNSHIFT this, LIST
4190     SPLICE this, offset, length, LIST
4191     EXTEND this, count
4192     DESTROY this
4193
4194 A class implementing a file handle should have the following methods:
4195
4196     TIEHANDLE classname, LIST
4197     READ this, scalar, length, offset
4198     READLINE this
4199     GETC this
4200     WRITE this, scalar, length, offset
4201     PRINT this, LIST
4202     PRINTF this, format, LIST
4203     CLOSE this
4204     DESTROY this
4205
4206 A class implementing a scalar should have the following methods:
4207
4208     TIESCALAR classname, LIST
4209     FETCH this,
4210     STORE this, value
4211     DESTROY this
4212
4213 Not all methods indicated above need be implemented.  See L<perltie>,
4214 L<Tie::Hash>, L<Tie::Array>, L<Tie::Scalar> and L<Tie::Handle>.
4215
4216 Unlike C<dbmopen()>, the C<tie()> function will not use or require a module
4217 for you--you need to do that explicitly yourself.  See L<DB_File>
4218 or the F<Config> module for interesting C<tie()> implementations.
4219
4220 For further details see L<perltie>, L<tied VARIABLE>.
4221
4222 =item tied VARIABLE
4223
4224 Returns a reference to the object underlying VARIABLE (the same value
4225 that was originally returned by the C<tie()> call that bound the variable
4226 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
4227 package.
4228
4229 =item time
4230
4231 Returns the number of non-leap seconds since whatever time the system
4232 considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS,
4233 and 00:00:00 UTC, January 1, 1970 for most other systems).
4234 Suitable for feeding to C<gmtime()> and C<localtime()>.
4235
4236 =item times
4237
4238 Returns a four-element list giving the user and system times, in
4239 seconds, for this process and the children of this process.
4240
4241     ($user,$system,$cuser,$csystem) = times;
4242
4243 =item tr///
4244
4245 The transliteration operator.  Same as C<y///>. See L<perlop>.
4246
4247 =item truncate FILEHANDLE,LENGTH
4248
4249 =item truncate EXPR,LENGTH
4250
4251 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
4252 specified length.  Produces a fatal error if truncate isn't implemented
4253 on your system.  Returns TRUE if successful, the undefined value
4254 otherwise.
4255
4256 =item uc EXPR
4257
4258 =item uc
4259
4260 Returns an uppercased version of EXPR.  This is the internal function
4261 implementing the C<\U> escape in double-quoted strings.
4262 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
4263 Under Unicode (C<use utf8>) it uses the standard Unicode uppercase mappings.  (It
4264 does not attempt to do titlecase mapping on initial letters.  See C<ucfirst()> for that.)
4265
4266 If EXPR is omitted, uses C<$_>.
4267
4268 =item ucfirst EXPR
4269
4270 =item ucfirst
4271
4272 Returns the value of EXPR with the first character
4273 in uppercase (titlecase in Unicode).  This is
4274 the internal function implementing the C<\u> escape in double-quoted strings.
4275 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
4276
4277 If EXPR is omitted, uses C<$_>.
4278
4279 =item umask EXPR
4280
4281 =item umask
4282
4283 Sets the umask for the process to EXPR and returns the previous value.
4284 If EXPR is omitted, merely returns the current umask.
4285
4286 The Unix permission C<rwxr-x---> is represented as three sets of three
4287 bits, or three octal digits: C<0750> (the leading 0 indicates octal
4288 and isn't one of the the digits).  The C<umask> value is such a number
4289 representing disabled permissions bits.  The permission (or "mode")
4290 values you pass C<mkdir> or C<sysopen> are modified by your umask, so
4291 even if you tell C<sysopen> to create a file with permissions C<0777>,
4292 if your umask is C<0022> then the file will actually be created with
4293 permissions C<0755>.  If your C<umask> were C<0027> (group can't
4294 write; others can't read, write, or execute), then passing
4295 C<sysopen()> C<0666> would create a file with mode C<0640> (C<0666 &~
4296 027> is C<0640>).
4297
4298 Here's some advice: supply a creation mode of C<0666> for regular
4299 files (in C<sysopen()>) and one of C<0777> for directories (in
4300 C<mkdir()>) and executable files.  This gives users the freedom of
4301 choice: if they want protected files, they might choose process umasks
4302 of C<022>, C<027>, or even the particularly antisocial mask of C<077>.
4303 Programs should rarely if ever make policy decisions better left to
4304 the user.  The exception to this is when writing files that should be
4305 kept private: mail files, web browser cookies, I<.rhosts> files, and
4306 so on.
4307
4308 If umask(2) is not implemented on your system and you are trying to
4309 restrict access for I<yourself> (i.e., (EXPR & 0700) > 0), produces a
4310 fatal error at run time.  If umask(2) is not implemented and you are
4311 not trying to restrict access for yourself, returns C<undef>.
4312
4313 Remember that a umask is a number, usually given in octal; it is I<not> a
4314 string of octal digits.  See also L</oct>, if all you have is a string.
4315
4316 =item undef EXPR
4317
4318 =item undef
4319
4320 Undefines the value of EXPR, which must be an lvalue.  Use only on a
4321 scalar value, an array (using "C<@>"), a hash (using "C<%>"), a subroutine
4322 (using "C<&>"), or a typeglob (using "<*>").  (Saying C<undef $hash{$key}>
4323 will probably not do what you expect on most predefined variables or
4324 DBM list values, so don't do that; see L<delete>.)  Always returns the
4325 undefined value.  You can omit the EXPR, in which case nothing is
4326 undefined, but you still get an undefined value that you could, for
4327 instance, return from a subroutine, assign to a variable or pass as a
4328 parameter.  Examples:
4329
4330     undef $foo;
4331     undef $bar{'blurfl'};      # Compare to: delete $bar{'blurfl'};
4332     undef @ary;
4333     undef %hash;
4334     undef &mysub;
4335     undef *xyz;       # destroys $xyz, @xyz, %xyz, &xyz, etc.
4336     return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it;
4337     select undef, undef, undef, 0.25;
4338     ($a, $b, undef, $c) = &foo;       # Ignore third value returned
4339
4340 Note that this is a unary operator, not a list operator.
4341
4342 =item unless (EXPR) BLOCK
4343
4344 The negative counterpart of L</if>.  If the EXPR returns false the
4345 BLOCK is entered.
4346
4347 See also L<perlsyn>.
4348
4349 =item unlink LIST
4350
4351 =item unlink
4352
4353 Deletes a list of files.  Returns the number of files successfully
4354 deleted.
4355
4356     $cnt = unlink 'a', 'b', 'c';
4357     unlink @goners;
4358     unlink <*.bak>;
4359
4360 Note: C<unlink()> will not delete directories unless you are superuser and
4361 the B<-U> flag is supplied to Perl.  Even if these conditions are
4362 met, be warned that unlinking a directory can inflict damage on your
4363 filesystem.  Use C<rmdir()> instead.
4364
4365 If LIST is omitted, uses C<$_>.
4366
4367 =item unpack TEMPLATE,EXPR
4368
4369 C<Unpack()> does the reverse of C<pack()>: it takes a string representing a
4370 structure and expands it out into a list value, returning the array
4371 value.  (In scalar context, it returns merely the first value
4372 produced.)  The TEMPLATE has the same format as in the C<pack()> function.
4373 Here's a subroutine that does substring:
4374
4375     sub substr {
4376         my($what,$where,$howmuch) = @_;
4377         unpack("x$where a$howmuch", $what);
4378     }
4379
4380 and then there's
4381
4382     sub ordinal { unpack("c",$_[0]); } # same as ord()
4383
4384 In addition, you may prefix a field with a %E<lt>numberE<gt> to indicate that
4385 you want a E<lt>numberE<gt>-bit checksum of the items instead of the items
4386 themselves.  Default is a 16-bit checksum.  For example, the following
4387 computes the same number as the System V sum program:
4388
4389     while (<>) {
4390         $checksum += unpack("%16C*", $_);
4391     }
4392     $checksum %= 65536;
4393
4394 The following efficiently counts the number of set bits in a bit vector:
4395
4396     $setbits = unpack("%32b*", $selectmask);
4397
4398 =item unshift ARRAY,LIST
4399
4400 Does the opposite of a C<shift()>.  Or the opposite of a C<push()>,
4401 depending on how you look at it.  Prepends list to the front of the
4402 array, and returns the new number of elements in the array.
4403
4404     unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/;
4405
4406 Note the LIST is prepended whole, not one element at a time, so the
4407 prepended elements stay in the same order.  Use C<reverse()> to do the
4408 reverse.
4409
4410 =item until (EXPR) BLOCK
4411
4412 =item do BLOCK until (EXPR)
4413
4414 Enter BLOCK until EXPR returns false.  The first form may avoid entering
4415 the BLOCK, the second form enters the BLOCK at least once.
4416
4417 See L</do>, L</while>, and L</for>.
4418
4419 See also L<perlsyn>.
4420
4421 =item untie VARIABLE
4422
4423 Breaks the binding between a variable and a package.  (See C<tie()>.)
4424
4425 =item use Module LIST
4426
4427 =item use Module
4428
4429 =item use Module VERSION LIST
4430
4431 =item use VERSION
4432
4433 Imports some semantics into the current package from the named module,
4434 generally by aliasing certain subroutine or variable names into your
4435 package.  It is exactly equivalent to
4436
4437     BEGIN { require Module; import Module LIST; }
4438
4439 except that Module I<must> be a bareword.
4440
4441 If the first argument to C<use> is a number, it is treated as a version
4442 number instead of a module name.  If the version of the Perl interpreter
4443 is less than VERSION, then an error message is printed and Perl exits
4444 immediately.  This is often useful if you need to check the current
4445 Perl version before C<use>ing library modules that have changed in
4446 incompatible ways from older versions of Perl.  (We try not to do
4447 this more than we have to.)
4448
4449 The C<BEGIN> forces the C<require> and C<import()> to happen at compile time.  The
4450 C<require> makes sure the module is loaded into memory if it hasn't been
4451 yet.  The C<import()> is not a builtin--it's just an ordinary static method
4452 call into the "C<Module>" package to tell the module to import the list of
4453 features back into the current package.  The module can implement its
4454 C<import()> method any way it likes, though most modules just choose to
4455 derive their C<import()> method via inheritance from the C<Exporter> class that
4456 is defined in the C<Exporter> module.  See L<Exporter>.  If no C<import()>
4457 method can be found then the error is currently silently ignored.  This
4458 may change to a fatal error in a future version.
4459
4460 If you don't want your namespace altered, explicitly supply an empty list:
4461
4462     use Module ();
4463
4464 That is exactly equivalent to
4465
4466     BEGIN { require Module }
4467
4468 If the VERSION argument is present between Module and LIST, then the
4469 C<use> will call the VERSION method in class Module with the given
4470 version as an argument.  The default VERSION method, inherited from
4471 the Universal class, croaks if the given version is larger than the
4472 value of the variable C<$Module::VERSION>.  (Note that there is not a
4473 comma after VERSION!)
4474
4475 Because this is a wide-open interface, pragmas (compiler directives)
4476 are also implemented this way.  Currently implemented pragmas are:
4477
4478     use integer;
4479     use diagnostics;
4480     use sigtrap qw(SEGV BUS);
4481     use strict  qw(subs vars refs);
4482     use subs    qw(afunc blurfl);
4483
4484 Some of these these pseudo-modules import semantics into the current
4485 block scope (like C<strict> or C<integer>, unlike ordinary modules,
4486 which import symbols into the current package (which are effective
4487 through the end of the file).
4488
4489 There's a corresponding "C<no>" command that unimports meanings imported
4490 by C<use>, i.e., it calls C<unimport Module LIST> instead of C<import()>.
4491
4492     no integer;
4493     no strict 'refs';
4494
4495 If no C<unimport()> method can be found the call fails with a fatal error.
4496
4497 See L<perlmod> for a list of standard modules and pragmas.
4498
4499 =item utime LIST
4500
4501 Changes the access and modification times on each file of a list of
4502 files.  The first two elements of the list must be the NUMERICAL access
4503 and modification times, in that order.  Returns the number of files
4504 successfully changed.  The inode modification time of each file is set
4505 to the current time.  This code has the same effect as the "C<touch>"
4506 command if the files already exist:
4507
4508     #!/usr/bin/perl
4509     $now = time;
4510     utime $now, $now, @ARGV;
4511
4512 =item values HASH
4513
4514 Returns a list consisting of all the values of the named hash.  (In a
4515 scalar context, returns the number of values.)  The values are
4516 returned in an apparently random order.  The actual random order is
4517 subject to change in future versions of perl, but it is guaranteed to
4518 be the same order as either the C<keys()> or C<each()> function would
4519 produce on the same (unmodified) hash.
4520
4521 As a side effect, it resets HASH's iterator.  See also C<keys()>, C<each()>,
4522 and C<sort()>.
4523
4524 =item vec EXPR,OFFSET,BITS
4525
4526 Treats the string in EXPR as a vector of unsigned integers, and
4527 returns the value of the bit field specified by OFFSET.  BITS specifies
4528 the number of bits that are reserved for each entry in the bit
4529 vector.  This must be a power of two from 1 to 32. C<vec()> may also be
4530 assigned to, in which case parentheses are needed to give the expression
4531 the correct precedence as in
4532
4533     vec($image, $max_x * $x + $y, 8) = 3;
4534
4535 Vectors created with C<vec()> can also be manipulated with the logical
4536 operators C<|>, C<&>, and C<^>, which will assume a bit vector operation is
4537 desired when both operands are strings.
4538
4539 The following code will build up an ASCII string saying C<'PerlPerlPerl'>.
4540 The comments show the string after each step. Note that this code works
4541 in the same way on big-endian or little-endian machines.
4542
4543     my $foo = '';
4544     vec($foo,  0, 32) = 0x5065726C;     # 'Perl'
4545     vec($foo,  2, 16) = 0x5065;         # 'PerlPe'
4546     vec($foo,  3, 16) = 0x726C;         # 'PerlPerl'
4547     vec($foo,  8,  8) = 0x50;           # 'PerlPerlP'
4548     vec($foo,  9,  8) = 0x65;           # 'PerlPerlPe'
4549     vec($foo, 20,  4) = 2;              # 'PerlPerlPe'   . "\x02"
4550     vec($foo, 21,  4) = 7;              # 'PerlPerlPer'
4551                                         # 'r' is "\x72"
4552     vec($foo, 45,  2) = 3;              # 'PerlPerlPer'  . "\x0c"
4553     vec($foo, 93,  1) = 1;              # 'PerlPerlPer'  . "\x2c"
4554     vec($foo, 94,  1) = 1;              # 'PerlPerlPerl'
4555                                         # 'l' is "\x6c"
4556
4557 To transform a bit vector into a string or array of 0's and 1's, use these:
4558
4559     $bits = unpack("b*", $vector);
4560     @bits = split(//, unpack("b*", $vector));
4561
4562 If you know the exact length in bits, it can be used in place of the C<*>.
4563
4564 =item wait
4565
4566 Waits for a child process to terminate and returns the pid of the
4567 deceased process, or C<-1> if there are no child processes.  The status is
4568 returned in C<$?>.  Note that a return value of C<-1> could mean that
4569 child processes are being automatically reaped, as described in L<perlipc>.
4570
4571 =item waitpid PID,FLAGS
4572
4573 Waits for a particular child process to terminate and returns the pid
4574 of the deceased process, or C<-1> if there is no such child process.  The
4575 status is returned in C<$?>.  If you say
4576
4577     use POSIX ":sys_wait_h";
4578     #...
4579     waitpid(-1,&WNOHANG);
4580
4581 then you can do a non-blocking wait for any process.  Non-blocking wait
4582 is available on machines supporting either the waitpid(2) or
4583 wait4(2) system calls.  However, waiting for a particular pid with
4584 FLAGS of C<0> is implemented everywhere.  (Perl emulates the system call
4585 by remembering the status values of processes that have exited but have
4586 not been harvested by the Perl script yet.)
4587
4588 Note that a return value of C<-1> could mean that child processes are being
4589 automatically reaped.  See L<perlipc> for details, and for other examples.
4590
4591 =item wantarray
4592
4593 Returns TRUE if the context of the currently executing subroutine is
4594 looking for a list value.  Returns FALSE if the context is looking
4595 for a scalar.  Returns the undefined value if the context is looking
4596 for no value (void context).
4597
4598     return unless defined wantarray;    # don't bother doing more
4599     my @a = complex_calculation();
4600     return wantarray ? @a : "@a";
4601
4602 =item warn LIST
4603
4604 Produces a message on STDERR just like C<die()>, but doesn't exit or throw
4605 an exception.
4606
4607 If LIST is empty and C<$@> already contains a value (typically from a
4608 previous eval) that value is used after appending C<"\t...caught">
4609 to C<$@>. This is useful for staying almost, but not entirely similar to
4610 C<die()>.
4611
4612 If C<$@> is empty then the string C<"Warning: Something's wrong"> is used.
4613
4614 No message is printed if there is a C<$SIG{__WARN__}> handler
4615 installed.  It is the handler's responsibility to deal with the message
4616 as it sees fit (like, for instance, converting it into a C<die()>).  Most
4617 handlers must therefore make arrangements to actually display the
4618 warnings that they are not prepared to deal with, by calling C<warn()>
4619 again in the handler.  Note that this is quite safe and will not
4620 produce an endless loop, since C<__WARN__> hooks are not called from
4621 inside one.
4622
4623 You will find this behavior is slightly different from that of
4624 C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can
4625 instead call C<die()> again to change it).
4626
4627 Using a C<__WARN__> handler provides a powerful way to silence all
4628 warnings (even the so-called mandatory ones).  An example:
4629
4630     # wipe out *all* compile-time warnings
4631     BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
4632     my $foo = 10;
4633     my $foo = 20;          # no warning about duplicate my $foo,
4634                            # but hey, you asked for it!
4635     # no compile-time or run-time warnings before here
4636     $DOWARN = 1;
4637
4638     # run-time warnings enabled after here
4639     warn "\$foo is alive and $foo!";     # does show up
4640
4641 See L<perlvar> for details on setting C<%SIG> entries, and for more
4642 examples.
4643
4644 =item while (EXPR) BLOCK
4645
4646 =item do BLOCK while (EXPR)
4647
4648 Enter BLOCK while EXPR is true.  The first form may avoid entering the
4649 BLOCK, the second form enters the BLOCK at least once.
4650
4651 See also L<perlsyn>, L</for>, L</until>, and L</continue>.
4652
4653 =item write FILEHANDLE
4654
4655 =item write EXPR
4656
4657 =item write
4658
4659 Writes a formatted record (possibly multi-line) to the specified FILEHANDLE,
4660 using the format associated with that file.  By default the format for
4661 a file is the one having the same name as the filehandle, but the
4662 format for the current output channel (see the C<select()> function) may be set
4663 explicitly by assigning the name of the format to&nbs