This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
368794dcc7dbbcc99dbe14b4564fc3e08866e605
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # There was an attempt when this was first rewritten to make it 5.8
8 # compatible, but that has now been abandoned, and newer constructs are used
9 # as convenient.
10
11 # NOTE: this script can run quite slowly in older/slower systems.
12 # It can also consume a lot of memory (128 MB or more), you may need
13 # to raise your process resource limits (e.g. in bash, "ulimit -a"
14 # to inspect, and "ulimit -d ..." or "ulimit -m ..." to set)
15
16 my $start_time;
17 BEGIN { # Get the time the script started running; do it at compilation to
18         # get it as close as possible
19     $start_time= time;
20 }
21
22 require 5.010_001;
23 use strict;
24 use warnings;
25 use Carp;
26 use Config;
27 use File::Find;
28 use File::Path;
29 use File::Spec;
30 use Text::Tabs;
31 use re "/aa";
32 use feature 'state';
33
34 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
35 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
36
37 sub NON_ASCII_PLATFORM { ord("A") != 65 }
38
39 # When a new version of Unicode is published, unfortunately the algorithms for
40 # dealing with various bounds, like \b{gcb}, \b{lb} may have to be updated
41 # manually.  The changes may or may not be backward compatible with older
42 # releases.  The code is in regen/mk_invlist.pl and regexec.c.  Make the
43 # changes, then come back here and set the variable below to what version the
44 # code is expecting.  If a newer version of Unicode is being compiled than
45 # expected, a warning will be generated.  If an older version is being
46 # compiled, any bounds tests that fail in the generated test file (-maketest
47 # option) will be marked as TODO.
48 my $version_of_mk_invlist_bounds = v12.1.0;
49
50 ##########################################################################
51 #
52 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
53 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
54 # a pod file and .t files, depending on option parameters.
55 #
56 # The structure of this file is:
57 #   First these introductory comments; then
58 #   code needed for everywhere, such as debugging stuff; then
59 #   code to handle input parameters; then
60 #   data structures likely to be of external interest (some of which depend on
61 #       the input parameters, so follows them; then
62 #   more data structures and subroutine and package (class) definitions; then
63 #   the small actual loop to process the input files and finish up; then
64 #   a __DATA__ section, for the .t tests
65 #
66 # This program works on all releases of Unicode so far.  The outputs have been
67 # scrutinized most intently for release 5.1.  The others have been checked for
68 # somewhat more than just sanity.  It can handle all non-provisional Unicode
69 # character properties in those releases.
70 #
71 # This program is mostly about Unicode character (or code point) properties.
72 # A property describes some attribute or quality of a code point, like if it
73 # is lowercase or not, its name, what version of Unicode it was first defined
74 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
75 # possibilities by making all properties into mappings from each code point
76 # into some corresponding value.  In the case of it being lowercase or not,
77 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
78 # property maps each Unicode code point to a single value, called a "property
79 # value".  (Some more recently defined properties, map a code point to a set
80 # of values.)
81 #
82 # When using a property in a regular expression, what is desired isn't the
83 # mapping of the code point to its property's value, but the reverse (or the
84 # mathematical "inverse relation"): starting with the property value, "Does a
85 # code point map to it?"  These are written in a "compound" form:
86 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
87 # files containing the lists of code points that map to each such regular
88 # expression property value, one file per list
89 #
90 # There is also a single form shortcut that Perl adds for many of the commonly
91 # used properties.  This happens for all binary properties, plus script,
92 # general_category, and block properties.
93 #
94 # Thus the outputs of this program are files.  There are map files, mostly in
95 # the 'To' directory; and there are list files for use in regular expression
96 # matching, all in subdirectories of the 'lib' directory, with each
97 # subdirectory being named for the property that the lists in it are for.
98 # Bookkeeping, test, and documentation files are also generated.
99
100 my $matches_directory = 'lib';   # Where match (\p{}) files go.
101 my $map_directory = 'To';        # Where map files go.
102
103 # DATA STRUCTURES
104 #
105 # The major data structures of this program are Property, of course, but also
106 # Table.  There are two kinds of tables, very similar to each other.
107 # "Match_Table" is the data structure giving the list of code points that have
108 # a particular property value, mentioned above.  There is also a "Map_Table"
109 # data structure which gives the property's mapping from code point to value.
110 # There are two structures because the match tables need to be combined in
111 # various ways, such as constructing unions, intersections, complements, etc.,
112 # and the map ones don't.  And there would be problems, perhaps subtle, if
113 # a map table were inadvertently operated on in some of those ways.
114 # The use of separate classes with operations defined on one but not the other
115 # prevents accidentally confusing the two.
116 #
117 # At the heart of each table's data structure is a "Range_List", which is just
118 # an ordered list of "Ranges", plus ancillary information, and methods to
119 # operate on them.  A Range is a compact way to store property information.
120 # Each range has a starting code point, an ending code point, and a value that
121 # is meant to apply to all the code points between the two end points,
122 # inclusive.  For a map table, this value is the property value for those
123 # code points.  Two such ranges could be written like this:
124 #   0x41 .. 0x5A, 'Upper',
125 #   0x61 .. 0x7A, 'Lower'
126 #
127 # Each range also has a type used as a convenience to classify the values.
128 # Most ranges in this program will be Type 0, or normal, but there are some
129 # ranges that have a non-zero type.  These are used only in map tables, and
130 # are for mappings that don't fit into the normal scheme of things.  Mappings
131 # that require a hash entry to communicate with utf8.c are one example;
132 # another example is mappings for charnames.pm to use which indicate a name
133 # that is algorithmically determinable from its code point (and the reverse).
134 # These are used to significantly compact these tables, instead of listing
135 # each one of the tens of thousands individually.
136 #
137 # In a match table, the value of a range is irrelevant (and hence the type as
138 # well, which will always be 0), and arbitrarily set to the empty string.
139 # Using the example above, there would be two match tables for those two
140 # entries, one named Upper would contain the 0x41..0x5A range, and the other
141 # named Lower would contain 0x61..0x7A.
142 #
143 # Actually, there are two types of range lists, "Range_Map" is the one
144 # associated with map tables, and "Range_List" with match tables.
145 # Again, this is so that methods can be defined on one and not the others so
146 # as to prevent operating on them in incorrect ways.
147 #
148 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
149 # in the perl core.  All tables could in theory be written, but some are
150 # suppressed because there is no current practical use for them.  It is easy
151 # to change which get written by changing various lists that are near the top
152 # of the actual code in this file.  The table data structures contain enough
153 # ancillary information to allow them to be treated as separate entities for
154 # writing, such as the path to each one's file.  There is a heading in each
155 # map table that gives the format of its entries, and what the map is for all
156 # the code points missing from it.  (This allows tables to be more compact.)
157 #
158 # The Property data structure contains one or more tables.  All properties
159 # contain a map table (except the $perl property which is a
160 # pseudo-property containing only match tables), and any properties that
161 # are usable in regular expression matches also contain various matching
162 # tables, one for each value the property can have.  A binary property can
163 # have two values, True and False (or Y and N, which are preferred by Unicode
164 # terminology).  Thus each of these properties will have a map table that
165 # takes every code point and maps it to Y or N (but having ranges cuts the
166 # number of entries in that table way down), and two match tables, one
167 # which has a list of all the code points that map to Y, and one for all the
168 # code points that map to N.  (For each binary property, a third table is also
169 # generated for the pseudo Perl property.  It contains the identical code
170 # points as the Y table, but can be written in regular expressions, not in the
171 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
172 # properties are binary, but some properties have several possible values,
173 # some have many, and properties like Name have a different value for every
174 # named code point.  Those will not, unless the controlling lists are changed,
175 # have their match tables written out.  But all the ones which can be used in
176 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
177 # a property would have either its map table or its match tables written but
178 # not both.  Again, what gets written is controlled by lists which can easily
179 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
180 # tables needed to reconstruct the Unicode db are now written out, while
181 # suppressing the Unicode .txt files that contain the data.  Our tables are
182 # much more compact than the .txt files, so a significant space savings was
183 # achieved.  Also, tables are not written out that are trivially derivable
184 # from tables that do get written.  So, there typically is no file containing
185 # the code points not matched by a binary property (the table for \P{} versus
186 # lowercase \p{}), since you just need to invert the True table to get the
187 # False table.
188
189 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
190 # how many match tables there are and the content of the maps.  This 'Type' is
191 # different than a range 'Type', so don't get confused by the two concepts
192 # having the same name.
193 #
194 # For information about the Unicode properties, see Unicode's UAX44 document:
195
196 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
197
198 # As stated earlier, this program will work on any release of Unicode so far.
199 # Most obvious problems in earlier data have NOT been corrected except when
200 # necessary to make Perl or this program work reasonably, and to keep out
201 # potential security issues.  For example, no folding information was given in
202 # early releases, so this program substitutes lower case instead, just so that
203 # a regular expression with the /i option will do something that actually
204 # gives the right results in many cases.  There are also a couple other
205 # corrections for version 1.1.5, commented at the point they are made.  As an
206 # example of corrections that weren't made (but could be) is this statement
207 # from DerivedAge.txt: "The supplementary private use code points and the
208 # non-character code points were assigned in version 2.0, but not specifically
209 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
210 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
211 # further down in these introductory comments.
212 #
213 # This program works on all non-provisional properties as of the current
214 # Unicode release, though the files for some are suppressed for various
215 # reasons.  You can change which are output by changing lists in this program.
216 #
217 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
218 # loose matchings rules (from Unicode TR18):
219 #
220 #    The recommended names for UCD properties and property values are in
221 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
222 #    [PropValue]. There are both abbreviated names and longer, more
223 #    descriptive names. It is strongly recommended that both names be
224 #    recognized, and that loose matching of property names be used,
225 #    whereby the case distinctions, whitespace, hyphens, and underbar
226 #    are ignored.
227 #
228 # The program still allows Fuzzy to override its determination of if loose
229 # matching should be used, but it isn't currently used, as it is no longer
230 # needed; the calculations it makes are good enough.
231 #
232 # SUMMARY OF HOW IT WORKS:
233 #
234 #   Process arguments
235 #
236 #   A list is constructed containing each input file that is to be processed
237 #
238 #   Each file on the list is processed in a loop, using the associated handler
239 #   code for each:
240 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
241 #            first.  These files name the properties and property values.
242 #            Objects are created of all the property and property value names
243 #            that the rest of the input should expect, including all synonyms.
244 #        The other input files give mappings from properties to property
245 #           values.  That is, they list code points and say what the mapping
246 #           is under the given property.  Some files give the mappings for
247 #           just one property; and some for many.  This program goes through
248 #           each file and populates the properties and their map tables from
249 #           them.  Some properties are listed in more than one file, and
250 #           Unicode has set up a precedence as to which has priority if there
251 #           is a conflict.  Thus the order of processing matters, and this
252 #           program handles the conflict possibility by processing the
253 #           overriding input files last, so that if necessary they replace
254 #           earlier values.
255 #        After this is all done, the program creates the property mappings not
256 #            furnished by Unicode, but derivable from what it does give.
257 #        The tables of code points that match each property value in each
258 #            property that is accessible by regular expressions are created.
259 #        The Perl-defined properties are created and populated.  Many of these
260 #            require data determined from the earlier steps
261 #        Any Perl-defined synonyms are created, and name clashes between Perl
262 #            and Unicode are reconciled and warned about.
263 #        All the properties are written to files
264 #        Any other files are written, and final warnings issued.
265 #
266 # For clarity, a number of operators have been overloaded to work on tables:
267 #   ~ means invert (take all characters not in the set).  The more
268 #       conventional '!' is not used because of the possibility of confusing
269 #       it with the actual boolean operation.
270 #   + means union
271 #   - means subtraction
272 #   & means intersection
273 # The precedence of these is the order listed.  Parentheses should be
274 # copiously used.  These are not a general scheme.  The operations aren't
275 # defined for a number of things, deliberately, to avoid getting into trouble.
276 # Operations are done on references and affect the underlying structures, so
277 # that the copy constructors for them have been overloaded to not return a new
278 # clone, but the input object itself.
279 #
280 # The bool operator is deliberately not overloaded to avoid confusion with
281 # "should it mean if the object merely exists, or also is non-empty?".
282 #
283 # WHY CERTAIN DESIGN DECISIONS WERE MADE
284 #
285 # This program needs to be able to run under miniperl.  Therefore, it uses a
286 # minimum of other modules, and hence implements some things itself that could
287 # be gotten from CPAN
288 #
289 # This program uses inputs published by the Unicode Consortium.  These can
290 # change incompatibly between releases without the Perl maintainers realizing
291 # it.  Therefore this program is now designed to try to flag these.  It looks
292 # at the directories where the inputs are, and flags any unrecognized files.
293 # It keeps track of all the properties in the files it handles, and flags any
294 # that it doesn't know how to handle.  It also flags any input lines that
295 # don't match the expected syntax, among other checks.
296 #
297 # It is also designed so if a new input file matches one of the known
298 # templates, one hopefully just needs to add it to a list to have it
299 # processed.
300 #
301 # As mentioned earlier, some properties are given in more than one file.  In
302 # particular, the files in the extracted directory are supposedly just
303 # reformattings of the others.  But they contain information not easily
304 # derivable from the other files, including results for Unihan (which isn't
305 # usually available to this program) and for unassigned code points.  They
306 # also have historically had errors or been incomplete.  In an attempt to
307 # create the best possible data, this program thus processes them first to
308 # glean information missing from the other files; then processes those other
309 # files to override any errors in the extracted ones.  Much of the design was
310 # driven by this need to store things and then possibly override them.
311 #
312 # It tries to keep fatal errors to a minimum, to generate something usable for
313 # testing purposes.  It always looks for files that could be inputs, and will
314 # warn about any that it doesn't know how to handle (the -q option suppresses
315 # the warning).
316 #
317 # Why is there more than one type of range?
318 #   This simplified things.  There are some very specialized code points that
319 #   have to be handled specially for output, such as Hangul syllable names.
320 #   By creating a range type (done late in the development process), it
321 #   allowed this to be stored with the range, and overridden by other input.
322 #   Originally these were stored in another data structure, and it became a
323 #   mess trying to decide if a second file that was for the same property was
324 #   overriding the earlier one or not.
325 #
326 # Why are there two kinds of tables, match and map?
327 #   (And there is a base class shared by the two as well.)  As stated above,
328 #   they actually are for different things.  Development proceeded much more
329 #   smoothly when I (khw) realized the distinction.  Map tables are used to
330 #   give the property value for every code point (actually every code point
331 #   that doesn't map to a default value).  Match tables are used for regular
332 #   expression matches, and are essentially the inverse mapping.  Separating
333 #   the two allows more specialized methods, and error checks so that one
334 #   can't just take the intersection of two map tables, for example, as that
335 #   is nonsensical.
336 #
337 # What about 'fate' and 'status'.  The concept of a table's fate was created
338 #   late when it became clear that something more was needed.  The difference
339 #   between this and 'status' is unclean, and could be improved if someone
340 #   wanted to spend the effort.
341 #
342 # DEBUGGING
343 #
344 # This program is written so it will run under miniperl.  Occasionally changes
345 # will cause an error where the backtrace doesn't work well under miniperl.
346 # To diagnose the problem, you can instead run it under regular perl, if you
347 # have one compiled.
348 #
349 # There is a good trace facility.  To enable it, first sub DEBUG must be set
350 # to return true.  Then a line like
351 #
352 # local $to_trace = 1 if main::DEBUG;
353 #
354 # can be added to enable tracing in its lexical scope (plus dynamic) or until
355 # you insert another line:
356 #
357 # local $to_trace = 0 if main::DEBUG;
358 #
359 # To actually trace, use a line like "trace $a, @b, %c, ...;
360 #
361 # Some of the more complex subroutines already have trace statements in them.
362 # Permanent trace statements should be like:
363 #
364 # trace ... if main::DEBUG && $to_trace;
365 #
366 # main::stack_trace() will display what its name implies
367 #
368 # If there is just one or a few files that you're debugging, you can easily
369 # cause most everything else to be skipped.  Change the line
370 #
371 # my $debug_skip = 0;
372 #
373 # to 1, and every file whose object is in @input_file_objects and doesn't have
374 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
375 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
376 #
377 # To compare the output tables, it may be useful to specify the -annotate
378 # flag.  (As of this writing, this can't be done on a clean workspace, due to
379 # requirements in Text::Tabs used in this option; so first run mktables
380 # without this option.)  This option adds comment lines to each table, one for
381 # each non-algorithmically named character giving, currently its code point,
382 # name, and graphic representation if printable (and you have a font that
383 # knows about it).  This makes it easier to see what the particular code
384 # points are in each output table.  Non-named code points are annotated with a
385 # description of their status, and contiguous ones with the same description
386 # will be output as a range rather than individually.  Algorithmically named
387 # characters are also output as ranges, except when there are just a few
388 # contiguous ones.
389 #
390 # FUTURE ISSUES
391 #
392 # The program would break if Unicode were to change its names so that
393 # interior white space, underscores, or dashes differences were significant
394 # within property and property value names.
395 #
396 # It might be easier to use the xml versions of the UCD if this program ever
397 # would need heavy revision, and the ability to handle old versions was not
398 # required.
399 #
400 # There is the potential for name collisions, in that Perl has chosen names
401 # that Unicode could decide it also likes.  There have been such collisions in
402 # the past, with mostly Perl deciding to adopt the Unicode definition of the
403 # name.  However in the 5.2 Unicode beta testing, there were a number of such
404 # collisions, which were withdrawn before the final release, because of Perl's
405 # and other's protests.  These all involved new properties which began with
406 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
407 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
408 # Unicode document, so they are unlikely to be used by Unicode for another
409 # purpose.  However, they might try something beginning with 'In', or use any
410 # of the other Perl-defined properties.  This program will warn you of name
411 # collisions, and refuse to generate tables with them, but manual intervention
412 # will be required in this event.  One scheme that could be implemented, if
413 # necessary, would be to have this program generate another file, or add a
414 # field to mktables.lst that gives the date of first definition of a property.
415 # Each new release of Unicode would use that file as a basis for the next
416 # iteration.  And the Perl synonym addition code could sort based on the age
417 # of the property, so older properties get priority, and newer ones that clash
418 # would be refused; hence existing code would not be impacted, and some other
419 # synonym would have to be used for the new property.  This is ugly, and
420 # manual intervention would certainly be easier to do in the short run; lets
421 # hope it never comes to this.
422 #
423 # A NOTE ON UNIHAN
424 #
425 # This program can generate tables from the Unihan database.  But that DB
426 # isn't normally available, so it is marked as optional.  Prior to version
427 # 5.2, this database was in a single file, Unihan.txt.  In 5.2 the database
428 # was split into 8 different files, all beginning with the letters 'Unihan'.
429 # If you plunk those files down into the directory mktables ($0) is in, this
430 # program will read them and automatically create tables for the properties
431 # from it that are listed in PropertyAliases.txt and PropValueAliases.txt,
432 # plus any you add to the @cjk_properties array and the @cjk_property_values
433 # array, being sure to add necessary '# @missings' lines to the latter.  For
434 # Unicode versions earlier than 5.2, most of the Unihan properties are not
435 # listed at all in PropertyAliases nor PropValueAliases.  This program assumes
436 # for these early releases that you want the properties that are specified in
437 # the 5.2 release.
438 #
439 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
440 # and filter_unihan_line() are the functions where this is done.  This program
441 # already does some adjusting to make the lines look more like the rest of the
442 # Unicode DB;  You can see what that is in filter_unihan_line()
443 #
444 # There is a bug in the 3.2 data file in which some values for the
445 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
446 # could be added to correct these; or for a particular installation, the
447 # Unihan.txt file could be edited to fix them.
448 #
449 # HOW TO ADD A FILE TO BE PROCESSED
450 #
451 # A new file from Unicode needs to have an object constructed for it in
452 # @input_file_objects, probably at the end or at the end of the extracted
453 # ones.  The program should warn you if its name will clash with others on
454 # restrictive file systems, like DOS.  If so, figure out a better name, and
455 # add lines to the README.perl file giving that.  If the file is a character
456 # property, it should be in the format that Unicode has implicitly
457 # standardized for such files for the more recently introduced ones.
458 # If so, the Input_file constructor for @input_file_objects can just be the
459 # file name and release it first appeared in.  If not, then it should be
460 # possible to construct an each_line_handler() to massage the line into the
461 # standardized form.
462 #
463 # For non-character properties, more code will be needed.  You can look at
464 # the existing entries for clues.
465 #
466 # UNICODE VERSIONS NOTES
467 #
468 # The Unicode UCD has had a number of errors in it over the versions.  And
469 # these remain, by policy, in the standard for that version.  Therefore it is
470 # risky to correct them, because code may be expecting the error.  So this
471 # program doesn't generally make changes, unless the error breaks the Perl
472 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
473 # for U+1105, which causes real problems for the algorithms for Jamo
474 # calculations, so it is changed here.
475 #
476 # But it isn't so clear cut as to what to do about concepts that are
477 # introduced in a later release; should they extend back to earlier releases
478 # where the concept just didn't exist?  It was easier to do this than to not,
479 # so that's what was done.  For example, the default value for code points not
480 # in the files for various properties was probably undefined until changed by
481 # some version.  No_Block for blocks is such an example.  This program will
482 # assign No_Block even in Unicode versions that didn't have it.  This has the
483 # benefit that code being written doesn't have to special case earlier
484 # versions; and the detriment that it doesn't match the Standard precisely for
485 # the affected versions.
486 #
487 # Here are some observations about some of the issues in early versions:
488 #
489 # Prior to version 3.0, there were 3 character decompositions.  These are not
490 # handled by Unicode::Normalize, nor will it compile when presented a version
491 # that has them.  However, you can trivially get it to compile by simply
492 # ignoring those decompositions, by changing the croak to a carp.  At the time
493 # of this writing, the line (in dist/Unicode-Normalize/Normalize.pm or
494 # dist/Unicode-Normalize/mkheader) reads
495 #
496 #   croak("Weird Canonical Decomposition of U+$h");
497 #
498 # Simply comment it out.  It will compile, but will not know about any three
499 # character decompositions.
500
501 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
502 # that the reason is that the CJK block starting at 4E00 was removed from
503 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
504 # single property name \p{alpha}) has the correct values.  But the compound
505 # form is simply not generated until 3.1, as it can be argued that prior to
506 # this release, this was not an official property.  The comments for
507 # filter_old_style_proplist() give more details.
508 #
509 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
510 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
511 # reason is that 3.2 introduced U+205F=medium math space, which was not
512 # classed as white space, but Perl figured out that it should have been. 4.0
513 # reclassified it correctly.
514 #
515 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
516 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
517 # became 202, and ATBL was left with no code points, as all the ones that
518 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
519 # name for the class, it would not have been affected, but if it used the
520 # mnemonic, it would have been.
521 #
522 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that, code
523 # points which eventually came to have this script property value, instead
524 # mapped to "Unknown".  But in the next release all these code points were
525 # moved to \p{sc=common} instead.
526
527 # The tests furnished  by Unicode for testing WordBreak and SentenceBreak
528 # generate errors in 5.0 and earlier.
529 #
530 # The default for missing code points for BidiClass is complicated.  Starting
531 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
532 # tries to do the best it can for earlier releases.  It is done in
533 # process_PropertyAliases()
534 #
535 # In version 2.1.2, the entry in UnicodeData.txt:
536 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
537 # should instead be
538 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
539 # Without this change, there are casing problems for this character.
540 #
541 # Search for $string_compare_versions to see how to compare changes to
542 # properties between Unicode versions
543 #
544 ##############################################################################
545
546 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
547                         # and errors
548 my $MAX_LINE_WIDTH = 78;
549
550 # Debugging aid to skip most files so as to not be distracted by them when
551 # concentrating on the ones being debugged.  Add
552 # non_skip => 1,
553 # to the constructor for those files you want processed when you set this.
554 # Files with a first version number of 0 are special: they are always
555 # processed regardless of the state of this flag.  Generally, Jamo.txt and
556 # UnicodeData.txt must not be skipped if you want this program to not die
557 # before normal completion.
558 my $debug_skip = 0;
559
560
561 # Normally these are suppressed.
562 my $write_Unicode_deprecated_tables = 0;
563
564 # Set to 1 to enable tracing.
565 our $to_trace = 0;
566
567 { # Closure for trace: debugging aid
568     my $print_caller = 1;        # ? Include calling subroutine name
569     my $main_with_colon = 'main::';
570     my $main_colon_length = length($main_with_colon);
571
572     sub trace {
573         return unless $to_trace;        # Do nothing if global flag not set
574
575         my @input = @_;
576
577         local $DB::trace = 0;
578         $DB::trace = 0;          # Quiet 'used only once' message
579
580         my $line_number;
581
582         # Loop looking up the stack to get the first non-trace caller
583         my $caller_line;
584         my $caller_name;
585         my $i = 0;
586         do {
587             $line_number = $caller_line;
588             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
589             $caller = $main_with_colon unless defined $caller;
590
591             $caller_name = $caller;
592
593             # get rid of pkg
594             $caller_name =~ s/.*:://;
595             if (substr($caller_name, 0, $main_colon_length)
596                 eq $main_with_colon)
597             {
598                 $caller_name = substr($caller_name, $main_colon_length);
599             }
600
601         } until ($caller_name ne 'trace');
602
603         # If the stack was empty, we were called from the top level
604         $caller_name = 'main' if ($caller_name eq ""
605                                     || $caller_name eq 'trace');
606
607         my $output = "";
608         #print STDERR __LINE__, ": ", join ", ", @input, "\n";
609         foreach my $string (@input) {
610             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
611                 $output .= simple_dumper($string);
612             }
613             else {
614                 $string = "$string" if ref $string;
615                 $string = $UNDEF unless defined $string;
616                 chomp $string;
617                 $string = '""' if $string eq "";
618                 $output .= " " if $output ne ""
619                                 && $string ne ""
620                                 && substr($output, -1, 1) ne " "
621                                 && substr($string, 0, 1) ne " ";
622                 $output .= $string;
623             }
624         }
625
626         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
627         print STDERR "$caller_name: " if $print_caller;
628         print STDERR $output, "\n";
629         return;
630     }
631 }
632
633 sub stack_trace() {
634     local $to_trace = 1 if main::DEBUG;
635     my $line = (caller(0))[2];
636     my $i = 1;
637
638     # Accumulate the stack trace
639     while (1) {
640         my ($pkg, $file, $caller_line, $caller) = caller $i++;
641
642         last unless defined $caller;
643
644         trace "called from $caller() at line $line";
645         $line = $caller_line;
646     }
647 }
648
649 # This is for a rarely used development feature that allows you to compare two
650 # versions of the Unicode standard without having to deal with changes caused
651 # by the code points introduced in the later version.  You probably also want
652 # to use the -annotate option when using this.  Run this program on a unicore
653 # containing the starting release you want to compare.  Save that output
654 # structure.  Then, switching to a unicore with the ending release, change the
655 # "" in the $string_compare_versions definition just below to a string
656 # containing a SINGLE dotted Unicode release number (e.g. "2.1") corresponding
657 # to the starting release.  This program will then compile, but throw away all
658 # code points introduced after the starting release.  Finally use a diff tool
659 # to compare the two directory structures.  They include only the code points
660 # common to both releases, and you can see the changes caused just by the
661 # underlying release semantic changes.  For versions earlier than 3.2, you
662 # must copy a version of DAge.txt into the directory.
663 my $string_compare_versions = DEBUG && "";
664 my $compare_versions = DEBUG
665                        && $string_compare_versions
666                        && pack "C*", split /\./, $string_compare_versions;
667
668 sub uniques {
669     # Returns non-duplicated input values.  From "Perl Best Practices:
670     # Encapsulated Cleverness".  p. 455 in first edition.
671
672     my %seen;
673     # Arguably this breaks encapsulation, if the goal is to permit multiple
674     # distinct objects to stringify to the same value, and be interchangeable.
675     # However, for this program, no two objects stringify identically, and all
676     # lists passed to this function are either objects or strings. So this
677     # doesn't affect correctness, but it does give a couple of percent speedup.
678     no overloading;
679     return grep { ! $seen{$_}++ } @_;
680 }
681
682 $0 = File::Spec->canonpath($0);
683
684 my $make_test_script = 0;      # ? Should we output a test script
685 my $make_norm_test_script = 0; # ? Should we output a normalization test script
686 my $write_unchanged_files = 0; # ? Should we update the output files even if
687                                #    we don't think they have changed
688 my $use_directory = "";        # ? Should we chdir somewhere.
689 my $pod_directory;             # input directory to store the pod file.
690 my $pod_file = 'perluniprops';
691 my $t_path;                     # Path to the .t test file
692 my $file_list = 'mktables.lst'; # File to store input and output file names.
693                                # This is used to speed up the build, by not
694                                # executing the main body of the program if
695                                # nothing on the list has changed since the
696                                # previous build
697 my $make_list = 1;             # ? Should we write $file_list.  Set to always
698                                # make a list so that when the pumpking is
699                                # preparing a release, s/he won't have to do
700                                # special things
701 my $glob_list = 0;             # ? Should we try to include unknown .txt files
702                                # in the input.
703 my $output_range_counts = $debugging_build;   # ? Should we include the number
704                                               # of code points in ranges in
705                                               # the output
706 my $annotate = 0;              # ? Should character names be in the output
707
708 # Verbosity levels; 0 is quiet
709 my $NORMAL_VERBOSITY = 1;
710 my $PROGRESS = 2;
711 my $VERBOSE = 3;
712
713 my $verbosity = $NORMAL_VERBOSITY;
714
715 # Stored in mktables.lst so that if this program is called with different
716 # options, will regenerate even if the files otherwise look like they're
717 # up-to-date.
718 my $command_line_arguments = join " ", @ARGV;
719
720 # Process arguments
721 while (@ARGV) {
722     my $arg = shift @ARGV;
723     if ($arg eq '-v') {
724         $verbosity = $VERBOSE;
725     }
726     elsif ($arg eq '-p') {
727         $verbosity = $PROGRESS;
728         $| = 1;     # Flush buffers as we go.
729     }
730     elsif ($arg eq '-q') {
731         $verbosity = 0;
732     }
733     elsif ($arg eq '-w') {
734         # update the files even if they haven't changed
735         $write_unchanged_files = 1;
736     }
737     elsif ($arg eq '-check') {
738         my $this = shift @ARGV;
739         my $ok = shift @ARGV;
740         if ($this ne $ok) {
741             print "Skipping as check params are not the same.\n";
742             exit(0);
743         }
744     }
745     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
746         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
747     }
748     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
749     {
750         $make_test_script = 1;
751     }
752     elsif ($arg eq '-makenormtest')
753     {
754         $make_norm_test_script = 1;
755     }
756     elsif ($arg eq '-makelist') {
757         $make_list = 1;
758     }
759     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
760         -d $use_directory or croak "Unknown directory '$use_directory'";
761     }
762     elsif ($arg eq '-L') {
763
764         # Existence not tested until have chdir'd
765         $file_list = shift;
766     }
767     elsif ($arg eq '-globlist') {
768         $glob_list = 1;
769     }
770     elsif ($arg eq '-c') {
771         $output_range_counts = ! $output_range_counts
772     }
773     elsif ($arg eq '-annotate') {
774         $annotate = 1;
775         $debugging_build = 1;
776         $output_range_counts = 1;
777     }
778     else {
779         my $with_c = 'with';
780         $with_c .= 'out' if $output_range_counts;   # Complements the state
781         croak <<END;
782 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
783           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
784           [-check A B ]
785   -c          : Output comments $with_c number of code points in ranges
786   -q          : Quiet Mode: Only output serious warnings.
787   -p          : Set verbosity level to normal plus show progress.
788   -v          : Set Verbosity level high:  Show progress and non-serious
789                 warnings
790   -w          : Write files regardless
791   -C dir      : Change to this directory before proceeding. All relative paths
792                 except those specified by the -P and -T options will be done
793                 with respect to this directory.
794   -P dir      : Output $pod_file file to directory 'dir'.
795   -T path     : Create a test script as 'path'; overrides -maketest
796   -L filelist : Use alternate 'filelist' instead of standard one
797   -globlist   : Take as input all non-Test *.txt files in current and sub
798                 directories
799   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
800                 overrides -T
801   -makelist   : Rewrite the file list $file_list based on current setup
802   -annotate   : Output an annotation for each character in the table files;
803                 useful for debugging mktables, looking at diffs; but is slow
804                 and memory intensive
805   -check A B  : Executes $0 only if A and B are the same
806 END
807     }
808 }
809
810 # Stores the most-recently changed file.  If none have changed, can skip the
811 # build
812 my $most_recent = (stat $0)[9];   # Do this before the chdir!
813
814 # Change directories now, because need to read 'version' early.
815 if ($use_directory) {
816     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
817         $pod_directory = File::Spec->rel2abs($pod_directory);
818     }
819     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
820         $t_path = File::Spec->rel2abs($t_path);
821     }
822     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
823     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
824         $pod_directory = File::Spec->abs2rel($pod_directory);
825     }
826     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
827         $t_path = File::Spec->abs2rel($t_path);
828     }
829 }
830
831 # Get Unicode version into regular and v-string.  This is done now because
832 # various tables below get populated based on it.  These tables are populated
833 # here to be near the top of the file, and so easily seeable by those needing
834 # to modify things.
835 open my $VERSION, "<", "version"
836                     or croak "$0: can't open required file 'version': $!\n";
837 my $string_version = <$VERSION>;
838 close $VERSION;
839 chomp $string_version;
840 my $v_version = pack "C*", split /\./, $string_version;        # v string
841
842 my $unicode_version = ($compare_versions)
843                       ? (  "$string_compare_versions (using "
844                          . "$string_version rules)")
845                       : $string_version;
846
847 # The following are the complete names of properties with property values that
848 # are known to not match any code points in some versions of Unicode, but that
849 # may change in the future so they should be matchable, hence an empty file is
850 # generated for them.
851 my @tables_that_may_be_empty;
852 push @tables_that_may_be_empty, 'Joining_Type=Left_Joining'
853                                                     if $v_version lt v6.3.0;
854 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
855 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
856 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
857                                                     if $v_version ge v4.1.0;
858 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
859                                                     if $v_version ge v6.0.0;
860 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
861                                                     if $v_version ge v6.1.0;
862 push @tables_that_may_be_empty, 'Canonical_Combining_Class=CCC133'
863                                                     if $v_version ge v6.2.0;
864
865 # The lists below are hashes, so the key is the item in the list, and the
866 # value is the reason why it is in the list.  This makes generation of
867 # documentation easier.
868
869 my %why_suppressed;  # No file generated for these.
870
871 # Files aren't generated for empty extraneous properties.  This is arguable.
872 # Extraneous properties generally come about because a property is no longer
873 # used in a newer version of Unicode.  If we generated a file without code
874 # points, programs that used to work on that property will still execute
875 # without errors.  It just won't ever match (or will always match, with \P{}).
876 # This means that the logic is now likely wrong.  I (khw) think its better to
877 # find this out by getting an error message.  Just move them to the table
878 # above to change this behavior
879 my %why_suppress_if_empty_warn_if_not = (
880
881    # It is the only property that has ever officially been removed from the
882    # Standard.  The database never contained any code points for it.
883    'Special_Case_Condition' => 'Obsolete',
884
885    # Apparently never official, but there were code points in some versions of
886    # old-style PropList.txt
887    'Non_Break' => 'Obsolete',
888 );
889
890 # These would normally go in the warn table just above, but they were changed
891 # a long time before this program was written, so warnings about them are
892 # moot.
893 if ($v_version gt v3.2.0) {
894     push @tables_that_may_be_empty,
895                                 'Canonical_Combining_Class=Attached_Below_Left'
896 }
897
898 # Obsoleted
899 if ($v_version ge v11.0.0) {
900     push @tables_that_may_be_empty, qw(
901                                        Grapheme_Cluster_Break=E_Base
902                                        Grapheme_Cluster_Break=E_Base_GAZ
903                                        Grapheme_Cluster_Break=E_Modifier
904                                        Grapheme_Cluster_Break=Glue_After_Zwj
905                                        Word_Break=E_Base
906                                        Word_Break=E_Base_GAZ
907                                        Word_Break=E_Modifier
908                                        Word_Break=Glue_After_Zwj);
909 }
910
911 # Enum values for to_output_map() method in the Map_Table package. (0 is don't
912 # output)
913 my $EXTERNAL_MAP = 1;
914 my $INTERNAL_MAP = 2;
915 my $OUTPUT_ADJUSTED = 3;
916
917 # To override computed values for writing the map tables for these properties.
918 # The default for enum map tables is to write them out, so that the Unicode
919 # .txt files can be removed, but all the data to compute any property value
920 # for any code point is available in a more compact form.
921 my %global_to_output_map = (
922     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
923     # get stuck supporting it if things change.  Since it is a STRING
924     # property, it normally would be listed in the pod, but INTERNAL_MAP
925     # suppresses that.
926     Unicode_1_Name => $INTERNAL_MAP,
927
928     Present_In => 0,                # Suppress, as easily computed from Age
929     Block => (NON_ASCII_PLATFORM) ? 1 : 0,  # Suppress, as Blocks.txt is
930                                             # retained, but needed for
931                                             # non-ASCII
932
933     # Suppress, as mapping can be found instead from the
934     # Perl_Decomposition_Mapping file
935     Decomposition_Type => 0,
936 );
937
938 # There are several types of obsolete properties defined by Unicode.  These
939 # must be hand-edited for every new Unicode release.
940 my %why_deprecated;  # Generates a deprecated warning message if used.
941 my %why_stabilized;  # Documentation only
942 my %why_obsolete;    # Documentation only
943
944 {   # Closure
945     my $simple = 'Perl uses the more complete version';
946     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
947
948     my $other_properties = 'other properties';
949     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
950     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
951
952     %why_deprecated = (
953         'Grapheme_Link' => 'Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
954         'Jamo_Short_Name' => $contributory,
955         'Line_Break=Surrogate' => 'Surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
956         'Other_Alphabetic' => $contributory,
957         'Other_Default_Ignorable_Code_Point' => $contributory,
958         'Other_Grapheme_Extend' => $contributory,
959         'Other_ID_Continue' => $contributory,
960         'Other_ID_Start' => $contributory,
961         'Other_Lowercase' => $contributory,
962         'Other_Math' => $contributory,
963         'Other_Uppercase' => $contributory,
964         'Expands_On_NFC' => $why_no_expand,
965         'Expands_On_NFD' => $why_no_expand,
966         'Expands_On_NFKC' => $why_no_expand,
967         'Expands_On_NFKD' => $why_no_expand,
968     );
969
970     %why_suppressed = (
971         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
972         # contains the same information, but without the algorithmically
973         # determinable Hangul syllables'.  This file is not published, so it's
974         # existence is not noted in the comment.
975         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or prop_invmap() or charprop() in Unicode::UCD::',
976
977         # Don't suppress ISO_Comment, as otherwise special handling is needed
978         # to differentiate between it and gc=c, which can be written as 'isc',
979         # which is the same characters as ISO_Comment's short name.
980
981         'Name' => "Accessible via \\N{...} or 'use charnames;' or charprop() or prop_invmap() in Unicode::UCD::",
982
983         'Simple_Case_Folding' => "$simple.  Can access this through casefold(), charprop(), or prop_invmap() in Unicode::UCD",
984         'Simple_Lowercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
985         'Simple_Titlecase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
986         'Simple_Uppercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
987
988         FC_NFKC_Closure => 'Deprecated by Unicode, and supplanted in usage by NFKC_Casefold; otherwise not useful',
989     );
990
991     foreach my $property (
992
993             # The following are suppressed because they were made contributory
994             # or deprecated by Unicode before Perl ever thought about
995             # supporting them.
996             'Jamo_Short_Name',
997             'Grapheme_Link',
998             'Expands_On_NFC',
999             'Expands_On_NFD',
1000             'Expands_On_NFKC',
1001             'Expands_On_NFKD',
1002
1003             # The following are suppressed because they have been marked
1004             # as deprecated for a sufficient amount of time
1005             'Other_Alphabetic',
1006             'Other_Default_Ignorable_Code_Point',
1007             'Other_Grapheme_Extend',
1008             'Other_ID_Continue',
1009             'Other_ID_Start',
1010             'Other_Lowercase',
1011             'Other_Math',
1012             'Other_Uppercase',
1013     ) {
1014         $why_suppressed{$property} = $why_deprecated{$property};
1015     }
1016
1017     # Customize the message for all the 'Other_' properties
1018     foreach my $property (keys %why_deprecated) {
1019         next if (my $main_property = $property) !~ s/^Other_//;
1020         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
1021     }
1022 }
1023
1024 if ($write_Unicode_deprecated_tables) {
1025     foreach my $property (keys %why_suppressed) {
1026         delete $why_suppressed{$property} if $property =~
1027                                                     / ^ Other | Grapheme /x;
1028     }
1029 }
1030
1031 if ($v_version ge 4.0.0) {
1032     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
1033     if ($v_version ge 6.0.0) {
1034         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
1035     }
1036 }
1037 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
1038     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
1039     if ($v_version ge 6.0.0) {
1040         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
1041     }
1042 }
1043
1044 # Probably obsolete forever
1045 if ($v_version ge v4.1.0) {
1046     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
1047 }
1048 if ($v_version ge v6.0.0) {
1049     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana" (or both)';
1050     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
1051 }
1052
1053 # This program can create files for enumerated-like properties, such as
1054 # 'Numeric_Type'.  This file would be the same format as for a string
1055 # property, with a mapping from code point to its value, so you could look up,
1056 # for example, the script a code point is in.  But no one so far wants this
1057 # mapping, or they have found another way to get it since this is a new
1058 # feature.  So no file is generated except if it is in this list.
1059 my @output_mapped_properties = split "\n", <<END;
1060 END
1061
1062 # If you want more Unihan properties than the default, you need to add them to
1063 # these arrays.  Depending on the property type, @missing lines might have to
1064 # be added to the second array.  A sample entry would be (including the '#'):
1065 # @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1066 my @cjk_properties = split "\n", <<'END';
1067 END
1068 my @cjk_property_values = split "\n", <<'END';
1069 END
1070
1071 # The input files don't list every code point.  Those not listed are to be
1072 # defaulted to some value.  Below are hard-coded what those values are for
1073 # non-binary properties as of 5.1.  Starting in 5.0, there are
1074 # machine-parsable comment lines in the files that give the defaults; so this
1075 # list shouldn't have to be extended.  The claim is that all missing entries
1076 # for binary properties will default to 'N'.  Unicode tried to change that in
1077 # 5.2, but the beta period produced enough protest that they backed off.
1078 #
1079 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1080 # be in the form that it expects.  The others may be synonyms.
1081 my $CODE_POINT = '<code point>';
1082 my %default_mapping = (
1083     Age => "Unassigned",
1084     # Bidi_Class => Complicated; set in code
1085     Bidi_Mirroring_Glyph => "",
1086     Block => 'No_Block',
1087     Canonical_Combining_Class => 0,
1088     Case_Folding => $CODE_POINT,
1089     Decomposition_Mapping => $CODE_POINT,
1090     Decomposition_Type => 'None',
1091     East_Asian_Width => "Neutral",
1092     FC_NFKC_Closure => $CODE_POINT,
1093     General_Category => ($v_version le 6.3.0) ? 'Cn' : 'Unassigned',
1094     Grapheme_Cluster_Break => 'Other',
1095     Hangul_Syllable_Type => 'NA',
1096     ISO_Comment => "",
1097     Jamo_Short_Name => "",
1098     Joining_Group => "No_Joining_Group",
1099     # Joining_Type => Complicated; set in code
1100     kIICore => 'N',   #                       Is converted to binary
1101     #Line_Break => Complicated; set in code
1102     Lowercase_Mapping => $CODE_POINT,
1103     Name => "",
1104     Name_Alias => "",
1105     NFC_QC => 'Yes',
1106     NFD_QC => 'Yes',
1107     NFKC_QC => 'Yes',
1108     NFKD_QC => 'Yes',
1109     Numeric_Type => 'None',
1110     Numeric_Value => 'NaN',
1111     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1112     Sentence_Break => 'Other',
1113     Simple_Case_Folding => $CODE_POINT,
1114     Simple_Lowercase_Mapping => $CODE_POINT,
1115     Simple_Titlecase_Mapping => $CODE_POINT,
1116     Simple_Uppercase_Mapping => $CODE_POINT,
1117     Titlecase_Mapping => $CODE_POINT,
1118     Unicode_1_Name => "",
1119     Unicode_Radical_Stroke => "",
1120     Uppercase_Mapping => $CODE_POINT,
1121     Word_Break => 'Other',
1122 );
1123
1124 ### End of externally interesting definitions, except for @input_file_objects
1125
1126 my $HEADER=<<"EOF";
1127 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1128 # This file is machine-generated by $0 from the Unicode
1129 # database, Version $unicode_version.  Any changes made here will be lost!
1130 EOF
1131
1132 my $INTERNAL_ONLY_HEADER = <<"EOF";
1133
1134 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1135 # This file is for internal use by core Perl only.  The format and even the
1136 # name or existence of this file are subject to change without notice.  Don't
1137 # use it directly.  Use Unicode::UCD to access the Unicode character data
1138 # base.
1139 EOF
1140
1141 my $DEVELOPMENT_ONLY=<<"EOF";
1142 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1143 # This file contains information artificially constrained to code points
1144 # present in Unicode release $string_compare_versions.
1145 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1146 # not be used for production.
1147
1148 EOF
1149
1150 my $MAX_UNICODE_CODEPOINT_STRING = ($v_version ge v2.0.0)
1151                                    ? "10FFFF"
1152                                    : "FFFF";
1153 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1154 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1155
1156 # We work with above-Unicode code points, up to IV_MAX, but we may want to use
1157 # sentinels above that number.  Therefore for internal use, we use a much
1158 # smaller number, translating it to IV_MAX only for output.  The exact number
1159 # is immaterial (all above-Unicode code points are treated exactly the same),
1160 # but the algorithm requires it to be at least
1161 # 2 * $MAX_UNICODE_CODEPOINTS + 1
1162 my $MAX_WORKING_CODEPOINTS= $MAX_UNICODE_CODEPOINT * 8;
1163 my $MAX_WORKING_CODEPOINT = $MAX_WORKING_CODEPOINTS - 1;
1164 my $MAX_WORKING_CODEPOINT_STRING = sprintf("%X", $MAX_WORKING_CODEPOINT);
1165
1166 my $MAX_PLATFORM_CODEPOINT = ~0 >> 1;
1167
1168 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1169 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1170 # to decrease backtracking.  The first regex allows the code point to be at
1171 # the end of a word, but to work properly, the word shouldn't end with a valid
1172 # hex character.  The second one won't match a code point at the end of a
1173 # word, and doesn't have the run-on issue
1174 my $run_on_code_point_re =
1175             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1176 my $code_point_re = qr/\b$run_on_code_point_re/;
1177
1178 # This matches the beginning of the line in the Unicode DB files that give the
1179 # defaults for code points not listed (i.e., missing) in the file.  The code
1180 # depends on this ending with a semi-colon, so it can assume it is a valid
1181 # field when the line is split() by semi-colons
1182 my $missing_defaults_prefix = qr/^#\s+\@missing:\s+0000\.\.10FFFF\s*;/;
1183
1184 # Property types.  Unicode has more types, but these are sufficient for our
1185 # purposes.
1186 my $UNKNOWN = -1;   # initialized to illegal value
1187 my $NON_STRING = 1; # Either binary or enum
1188 my $BINARY = 2;
1189 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1190                        # tables, additional true and false tables are
1191                        # generated so that false is anything matching the
1192                        # default value, and true is everything else.
1193 my $ENUM = 4;       # Include catalog
1194 my $STRING = 5;     # Anything else: string or misc
1195
1196 # Some input files have lines that give default values for code points not
1197 # contained in the file.  Sometimes these should be ignored.
1198 my $NO_DEFAULTS = 0;        # Must evaluate to false
1199 my $NOT_IGNORED = 1;
1200 my $IGNORED = 2;
1201
1202 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1203 # and will appear in the main body of the tables in the output files, but
1204 # there are other types of ranges as well, listed below, that are specially
1205 # handled.   There are pseudo-types as well that will never be stored as a
1206 # type, but will affect the calculation of the type.
1207
1208 # 0 is for normal, non-specials
1209 my $MULTI_CP = 1;           # Sequence of more than code point
1210 my $HANGUL_SYLLABLE = 2;
1211 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1212 my $NULL = 4;               # The map is to the null string; utf8.c can't
1213                             # handle these, nor is there an accepted syntax
1214                             # for them in \p{} constructs
1215 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1216                              # otherwise be $MULTI_CP type are instead type 0
1217
1218 # process_generic_property_file() can accept certain overrides in its input.
1219 # Each of these must begin AND end with $CMD_DELIM.
1220 my $CMD_DELIM = "\a";
1221 my $REPLACE_CMD = 'replace';    # Override the Replace
1222 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1223
1224 my $NO = 0;
1225 my $YES = 1;
1226
1227 # Values for the Replace argument to add_range.
1228 # $NO                      # Don't replace; add only the code points not
1229                            # already present.
1230 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1231                            # the comments at the subroutine definition.
1232 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1233 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1234                            # already there
1235 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1236                            # already there
1237 my $CROAK = 6;             # Die with an error if is already there
1238
1239 # Flags to give property statuses.  The phrases are to remind maintainers that
1240 # if the flag is changed, the indefinite article referring to it in the
1241 # documentation may need to be as well.
1242 my $NORMAL = "";
1243 my $DEPRECATED = 'D';
1244 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1245 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1246 my $DISCOURAGED = 'X';
1247 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1248 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1249 my $STRICTER = 'T';
1250 my $a_bold_stricter = "a 'B<$STRICTER>'";
1251 my $A_bold_stricter = "A 'B<$STRICTER>'";
1252 my $STABILIZED = 'S';
1253 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1254 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1255 my $OBSOLETE = 'O';
1256 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1257 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1258
1259 # Aliases can also have an extra status:
1260 my $INTERNAL_ALIAS = 'P';
1261
1262 my %status_past_participles = (
1263     $DISCOURAGED => 'discouraged',
1264     $STABILIZED => 'stabilized',
1265     $OBSOLETE => 'obsolete',
1266     $DEPRECATED => 'deprecated',
1267     $INTERNAL_ALIAS => 'reserved for Perl core internal use only',
1268 );
1269
1270 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1271 # externally documented.
1272 my $ORDINARY = 0;       # The normal fate.
1273 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1274                         # but there is a file written that can be used to
1275                         # reconstruct this table
1276 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1277                         # for Perl's internal use only
1278 my $LEGACY_ONLY = 3;    # Like $INTERNAL_ONLY, but not actually used by Perl.
1279                         # Is for backwards compatibility for applications that
1280                         # read the file directly, so it's format is
1281                         # unchangeable.
1282 my $SUPPRESSED = 4;     # The file for this table is not written out, and as a
1283                         # result, we don't bother to do many computations on
1284                         # it.
1285 my $PLACEHOLDER = 5;    # Like $SUPPRESSED, but we go through all the
1286                         # computations anyway, as the values are needed for
1287                         # things to work.  This happens when we have Perl
1288                         # extensions that depend on Unicode tables that
1289                         # wouldn't normally be in a given Unicode version.
1290
1291 # The format of the values of the tables:
1292 my $EMPTY_FORMAT = "";
1293 my $BINARY_FORMAT = 'b';
1294 my $DECIMAL_FORMAT = 'd';
1295 my $FLOAT_FORMAT = 'f';
1296 my $INTEGER_FORMAT = 'i';
1297 my $HEX_FORMAT = 'x';
1298 my $RATIONAL_FORMAT = 'r';
1299 my $STRING_FORMAT = 's';
1300 my $ADJUST_FORMAT = 'a';
1301 my $HEX_ADJUST_FORMAT = 'ax';
1302 my $DECOMP_STRING_FORMAT = 'c';
1303 my $STRING_WHITE_SPACE_LIST = 'sw';
1304
1305 my %map_table_formats = (
1306     $BINARY_FORMAT => 'binary',
1307     $DECIMAL_FORMAT => 'single decimal digit',
1308     $FLOAT_FORMAT => 'floating point number',
1309     $INTEGER_FORMAT => 'integer',
1310     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1311     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1312     $STRING_FORMAT => 'string',
1313     $ADJUST_FORMAT => 'some entries need adjustment',
1314     $HEX_ADJUST_FORMAT => 'mapped value in hex; some entries need adjustment',
1315     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1316     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1317 );
1318
1319 # Unicode didn't put such derived files in a separate directory at first.
1320 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1321 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1322 my $AUXILIARY = 'auxiliary';
1323
1324 # Hashes and arrays that will eventually go into Heavy.pl for the use of
1325 # utf8_heavy.pl and into UCD.pl for the use of UCD.pm
1326 my %loose_to_file_of;       # loosely maps table names to their respective
1327                             # files
1328 my %stricter_to_file_of;    # same; but for stricter mapping.
1329 my %loose_property_to_file_of; # Maps a loose property name to its map file
1330 my %strict_property_to_file_of; # Same, but strict
1331 my @inline_definitions = "V0"; # Each element gives a definition of a unique
1332                             # inversion list.  When a definition is inlined,
1333                             # its value in the hash it's in (one of the two
1334                             # defined just above) will include an index into
1335                             # this array.  The 0th element is initialized to
1336                             # the definition for a zero length inversion list
1337 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1338                             # in the hash %utf8::SwashInfo
1339 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1340                              # their rational equivalent
1341 my %loose_property_name_of; # Loosely maps (non_string) property names to
1342                             # standard form
1343 my %strict_property_name_of; # Strictly maps (non_string) property names to
1344                             # standard form
1345 my %string_property_loose_to_name; # Same, for string properties.
1346 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1347                             # the property name in standard loose form, and
1348                             # 'value' is the default value for that property,
1349                             # also in standard loose form.
1350 my %loose_to_standard_value; # loosely maps table names to the canonical
1351                             # alias for them
1352 my %ambiguous_names;        # keys are alias names (in standard form) that
1353                             # have more than one possible meaning.
1354 my %combination_property;   # keys are alias names (in standard form) that
1355                             # have both a map table, and a binary one that
1356                             # yields true for all non-null maps.
1357 my %prop_aliases;           # Keys are standard property name; values are each
1358                             # one's aliases
1359 my %prop_value_aliases;     # Keys of top level are standard property name;
1360                             # values are keys to another hash,  Each one is
1361                             # one of the property's values, in standard form.
1362                             # The values are that prop-val's aliases.
1363 my %skipped_files;          # List of files that we skip
1364 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1365
1366 # Most properties are immune to caseless matching, otherwise you would get
1367 # nonsensical results, as properties are a function of a code point, not
1368 # everything that is caselessly equivalent to that code point.  For example,
1369 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1370 # be true because 's' and 'S' are equivalent caselessly.  However,
1371 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1372 # extend that concept to those very few properties that are like this.  Each
1373 # such property will match the full range caselessly.  They are hard-coded in
1374 # the program; it's not worth trying to make it general as it's extremely
1375 # unlikely that they will ever change.
1376 my %caseless_equivalent_to;
1377
1378 # This is the range of characters that were in Release 1 of Unicode, and
1379 # removed in Release 2 (replaced with the current Hangul syllables starting at
1380 # U+AC00).  The range was reused starting in Release 3 for other purposes.
1381 my $FIRST_REMOVED_HANGUL_SYLLABLE = 0x3400;
1382 my $FINAL_REMOVED_HANGUL_SYLLABLE = 0x4DFF;
1383
1384 # These constants names and values were taken from the Unicode standard,
1385 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1386 # syllables.  The '_string' versions are so generated tables can retain the
1387 # hex format, which is the more familiar value
1388 my $SBase_string = "0xAC00";
1389 my $SBase = CORE::hex $SBase_string;
1390 my $LBase_string = "0x1100";
1391 my $LBase = CORE::hex $LBase_string;
1392 my $VBase_string = "0x1161";
1393 my $VBase = CORE::hex $VBase_string;
1394 my $TBase_string = "0x11A7";
1395 my $TBase = CORE::hex $TBase_string;
1396 my $SCount = 11172;
1397 my $LCount = 19;
1398 my $VCount = 21;
1399 my $TCount = 28;
1400 my $NCount = $VCount * $TCount;
1401
1402 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1403 # with the above published constants.
1404 my %Jamo;
1405 my %Jamo_L;     # Leading consonants
1406 my %Jamo_V;     # Vowels
1407 my %Jamo_T;     # Trailing consonants
1408
1409 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1410 # The key is the base name of the code point, and the value is an
1411 # array giving all the ranges that use this base name.  Each range
1412 # is actually a hash giving the 'low' and 'high' values of it.
1413 my %names_ending_in_code_point;
1414 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1415                                         # removed from the names
1416 # Inverse mapping.  The list of ranges that have these kinds of
1417 # names.  Each element contains the low, high, and base names in an
1418 # anonymous hash.
1419 my @code_points_ending_in_code_point;
1420
1421 # To hold Unicode's normalization test suite
1422 my @normalization_tests;
1423
1424 # Boolean: does this Unicode version have the hangul syllables, and are we
1425 # writing out a table for them?
1426 my $has_hangul_syllables = 0;
1427
1428 # Does this Unicode version have code points whose names end in their
1429 # respective code points, and are we writing out a table for them?  0 for no;
1430 # otherwise points to first property that a table is needed for them, so that
1431 # if multiple tables are needed, we don't create duplicates
1432 my $needing_code_points_ending_in_code_point = 0;
1433
1434 my @backslash_X_tests;     # List of tests read in for testing \X
1435 my @LB_tests;              # List of tests read in for testing \b{lb}
1436 my @SB_tests;              # List of tests read in for testing \b{sb}
1437 my @WB_tests;              # List of tests read in for testing \b{wb}
1438 my @unhandled_properties;  # Will contain a list of properties found in
1439                            # the input that we didn't process.
1440 my @match_properties;      # Properties that have match tables, to be
1441                            # listed in the pod
1442 my @map_properties;        # Properties that get map files written
1443 my @named_sequences;       # NamedSequences.txt contents.
1444 my %potential_files;       # Generated list of all .txt files in the directory
1445                            # structure so we can warn if something is being
1446                            # ignored.
1447 my @missing_early_files;   # Generated list of absent files that we need to
1448                            # proceed in compiling this early Unicode version
1449 my @files_actually_output; # List of files we generated.
1450 my @more_Names;            # Some code point names are compound; this is used
1451                            # to store the extra components of them.
1452 my $E_FLOAT_PRECISION = 2; # The minimum number of digits after the decimal
1453                            # point of a normalized floating point number
1454                            # needed to match before we consider it equivalent
1455                            # to a candidate rational
1456
1457 # These store references to certain commonly used property objects
1458 my $age;
1459 my $ccc;
1460 my $gc;
1461 my $perl;
1462 my $block;
1463 my $perl_charname;
1464 my $print;
1465 my $All;
1466 my $Assigned;   # All assigned characters in this Unicode release
1467 my $DI;         # Default_Ignorable_Code_Point property
1468 my $NChar;      # Noncharacter_Code_Point property
1469 my $script;
1470 my $scx;        # Script_Extensions property
1471
1472 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1473 my $has_In_conflicts = 0;
1474 my $has_Is_conflicts = 0;
1475
1476 sub internal_file_to_platform ($) {
1477     # Convert our file paths which have '/' separators to those of the
1478     # platform.
1479
1480     my $file = shift;
1481     return undef unless defined $file;
1482
1483     return File::Spec->join(split '/', $file);
1484 }
1485
1486 sub file_exists ($) {   # platform independent '-e'.  This program internally
1487                         # uses slash as a path separator.
1488     my $file = shift;
1489     return 0 if ! defined $file;
1490     return -e internal_file_to_platform($file);
1491 }
1492
1493 sub objaddr($) {
1494     # Returns the address of the blessed input object.
1495     # It doesn't check for blessedness because that would do a string eval
1496     # every call, and the program is structured so that this is never called
1497     # for a non-blessed object.
1498
1499     no overloading; # If overloaded, numifying below won't work.
1500
1501     # Numifying a ref gives its address.
1502     return pack 'J', $_[0];
1503 }
1504
1505 # These are used only if $annotate is true.
1506 # The entire range of Unicode characters is examined to populate these
1507 # after all the input has been processed.  But most can be skipped, as they
1508 # have the same descriptive phrases, such as being unassigned
1509 my @viacode;            # Contains the 1 million character names
1510 my @age;                # And their ages ("" if none)
1511 my @printable;          # boolean: And are those characters printable?
1512 my @annotate_char_type; # Contains a type of those characters, specifically
1513                         # for the purposes of annotation.
1514 my $annotate_ranges;    # A map of ranges of code points that have the same
1515                         # name for the purposes of annotation.  They map to the
1516                         # upper edge of the range, so that the end point can
1517                         # be immediately found.  This is used to skip ahead to
1518                         # the end of a range, and avoid processing each
1519                         # individual code point in it.
1520 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1521                                    # characters, but excluding those which are
1522                                    # also noncharacter code points
1523
1524 # The annotation types are an extension of the regular range types, though
1525 # some of the latter are folded into one.  Make the new types negative to
1526 # avoid conflicting with the regular types
1527 my $SURROGATE_TYPE = -1;
1528 my $UNASSIGNED_TYPE = -2;
1529 my $PRIVATE_USE_TYPE = -3;
1530 my $NONCHARACTER_TYPE = -4;
1531 my $CONTROL_TYPE = -5;
1532 my $ABOVE_UNICODE_TYPE = -6;
1533 my $UNKNOWN_TYPE = -7;  # Used only if there is a bug in this program
1534
1535 sub populate_char_info ($) {
1536     # Used only with the $annotate option.  Populates the arrays with the
1537     # input code point's info that are needed for outputting more detailed
1538     # comments.  If calling context wants a return, it is the end point of
1539     # any contiguous range of characters that share essentially the same info
1540
1541     my $i = shift;
1542     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1543
1544     $viacode[$i] = $perl_charname->value_of($i) || "";
1545     $age[$i] = (defined $age)
1546                ? (($age->value_of($i) =~ / ^ \d+ \. \d+ $ /x)
1547                   ? $age->value_of($i)
1548                   : "")
1549                : "";
1550
1551     # A character is generally printable if Unicode says it is,
1552     # but below we make sure that most Unicode general category 'C' types
1553     # aren't.
1554     $printable[$i] = $print->contains($i);
1555
1556     # But the characters in this range were removed in v2.0 and replaced by
1557     # different ones later.  Modern fonts will be for the replacement
1558     # characters, so suppress printing them.
1559     if (($v_version lt v2.0
1560          || ($compare_versions && $compare_versions lt v2.0))
1561         && (   $i >= $FIRST_REMOVED_HANGUL_SYLLABLE
1562             && $i <= $FINAL_REMOVED_HANGUL_SYLLABLE))
1563     {
1564         $printable[$i] = 0;
1565     }
1566
1567     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1568
1569     # Only these two regular types are treated specially for annotations
1570     # purposes
1571     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1572                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1573
1574     # Give a generic name to all code points that don't have a real name.
1575     # We output ranges, if applicable, for these.  Also calculate the end
1576     # point of the range.
1577     my $end;
1578     if (! $viacode[$i]) {
1579         if ($i > $MAX_UNICODE_CODEPOINT) {
1580             $viacode[$i] = 'Above-Unicode';
1581             $annotate_char_type[$i] = $ABOVE_UNICODE_TYPE;
1582             $printable[$i] = 0;
1583             $end = $MAX_WORKING_CODEPOINT;
1584         }
1585         elsif ($gc-> table('Private_use')->contains($i)) {
1586             $viacode[$i] = 'Private Use';
1587             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1588             $printable[$i] = 0;
1589             $end = $gc->table('Private_Use')->containing_range($i)->end;
1590         }
1591         elsif ($NChar->contains($i)) {
1592             $viacode[$i] = 'Noncharacter';
1593             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1594             $printable[$i] = 0;
1595             $end = $NChar->containing_range($i)->end;
1596         }
1597         elsif ($gc-> table('Control')->contains($i)) {
1598             my $name_ref = property_ref('Name_Alias');
1599             $name_ref = property_ref('Unicode_1_Name') if ! defined $name_ref;
1600             $viacode[$i] = (defined $name_ref)
1601                            ? $name_ref->value_of($i)
1602                            : 'Control';
1603             $annotate_char_type[$i] = $CONTROL_TYPE;
1604             $printable[$i] = 0;
1605         }
1606         elsif ($gc-> table('Unassigned')->contains($i)) {
1607             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1608             $printable[$i] = 0;
1609             $viacode[$i] = 'Unassigned';
1610
1611             if (defined $block) { # No blocks in earliest releases
1612                 $viacode[$i] .= ', block=' . $block-> value_of($i);
1613                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1614
1615                 # Because we name the unassigned by the blocks they are in, it
1616                 # can't go past the end of that block, and it also can't go
1617                 # past the unassigned range it is in.  The special table makes
1618                 # sure that the non-characters, which are unassigned, are
1619                 # separated out.
1620                 $end = min($block->containing_range($i)->end,
1621                            $unassigned_sans_noncharacters->
1622                                                     containing_range($i)->end);
1623             }
1624             else {
1625                 $end = $i + 1;
1626                 while ($unassigned_sans_noncharacters->contains($end)) {
1627                     $end++;
1628                 }
1629                 $end--;
1630             }
1631         }
1632         elsif ($perl->table('_Perl_Surrogate')->contains($i)) {
1633             $viacode[$i] = 'Surrogate';
1634             $annotate_char_type[$i] = $SURROGATE_TYPE;
1635             $printable[$i] = 0;
1636             $end = $gc->table('Surrogate')->containing_range($i)->end;
1637         }
1638         else {
1639             Carp::my_carp_bug("Can't figure out how to annotate "
1640                               . sprintf("U+%04X", $i)
1641                               . ".  Proceeding anyway.");
1642             $viacode[$i] = 'UNKNOWN';
1643             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1644             $printable[$i] = 0;
1645         }
1646     }
1647
1648     # Here, has a name, but if it's one in which the code point number is
1649     # appended to the name, do that.
1650     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1651         $viacode[$i] .= sprintf("-%04X", $i);
1652
1653         my $limit = $perl_charname->containing_range($i)->end;
1654         if (defined $age) {
1655             # Do all these as groups of the same age, instead of individually,
1656             # because their names are so meaningless, and there are typically
1657             # large quantities of them.
1658             $end = $i + 1;
1659             while ($end <= $limit && $age->value_of($end) == $age[$i]) {
1660                 $end++;
1661             }
1662             $end--;
1663         }
1664         else {
1665             $end = $limit;
1666         }
1667     }
1668
1669     # And here, has a name, but if it's a hangul syllable one, replace it with
1670     # the correct name from the Unicode algorithm
1671     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1672         use integer;
1673         my $SIndex = $i - $SBase;
1674         my $L = $LBase + $SIndex / $NCount;
1675         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1676         my $T = $TBase + $SIndex % $TCount;
1677         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1678         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1679         $end = $perl_charname->containing_range($i)->end;
1680     }
1681
1682     return if ! defined wantarray;
1683     return $i if ! defined $end;    # If not a range, return the input
1684
1685     # Save this whole range so can find the end point quickly
1686     $annotate_ranges->add_map($i, $end, $end);
1687
1688     return $end;
1689 }
1690
1691 # Commented code below should work on Perl 5.8.
1692 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1693 ## the native perl version of it (which is what would operate under miniperl)
1694 ## is extremely slow, as it does a string eval every call.
1695 #my $has_fast_scalar_util = $^X !~ /miniperl/
1696 #                            && defined eval "require Scalar::Util";
1697 #
1698 #sub objaddr($) {
1699 #    # Returns the address of the blessed input object.  Uses the XS version if
1700 #    # available.  It doesn't check for blessedness because that would do a
1701 #    # string eval every call, and the program is structured so that this is
1702 #    # never called for a non-blessed object.
1703 #
1704 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1705 #
1706 #    # Check at least that is a ref.
1707 #    my $pkg = ref($_[0]) or return undef;
1708 #
1709 #    # Change to a fake package to defeat any overloaded stringify
1710 #    bless $_[0], 'main::Fake';
1711 #
1712 #    # Numifying a ref gives its address.
1713 #    my $addr = pack 'J', $_[0];
1714 #
1715 #    # Return to original class
1716 #    bless $_[0], $pkg;
1717 #    return $addr;
1718 #}
1719
1720 sub max ($$) {
1721     my $a = shift;
1722     my $b = shift;
1723     return $a if $a >= $b;
1724     return $b;
1725 }
1726
1727 sub min ($$) {
1728     my $a = shift;
1729     my $b = shift;
1730     return $a if $a <= $b;
1731     return $b;
1732 }
1733
1734 sub clarify_number ($) {
1735     # This returns the input number with underscores inserted every 3 digits
1736     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1737     # checked.
1738
1739     my $number = shift;
1740     my $pos = length($number) - 3;
1741     return $number if $pos <= 1;
1742     while ($pos > 0) {
1743         substr($number, $pos, 0) = '_';
1744         $pos -= 3;
1745     }
1746     return $number;
1747 }
1748
1749 sub clarify_code_point_count ($) {
1750     # This is like clarify_number(), but the input is assumed to be a count of
1751     # code points, rather than a generic number.
1752
1753     my $append = "";
1754
1755     my $number = shift;
1756     if ($number > $MAX_UNICODE_CODEPOINTS) {
1757         $number -= ($MAX_WORKING_CODEPOINTS - $MAX_UNICODE_CODEPOINTS);
1758         return "All above-Unicode code points" if $number == 0;
1759         $append = " + all above-Unicode code points";
1760     }
1761     return clarify_number($number) . $append;
1762 }
1763
1764 package Carp;
1765
1766 # These routines give a uniform treatment of messages in this program.  They
1767 # are placed in the Carp package to cause the stack trace to not include them,
1768 # although an alternative would be to use another package and set @CARP_NOT
1769 # for it.
1770
1771 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1772
1773 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1774 # and overload trying to load Scalar:Util under miniperl.  See
1775 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1776 undef $overload::VERSION;
1777
1778 sub my_carp {
1779     my $message = shift || "";
1780     my $nofold = shift || 0;
1781
1782     if ($message) {
1783         $message = main::join_lines($message);
1784         $message =~ s/^$0: *//;     # Remove initial program name
1785         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1786         $message = "\n$0: $message;";
1787
1788         # Fold the message with program name, semi-colon end punctuation
1789         # (which looks good with the message that carp appends to it), and a
1790         # hanging indent for continuation lines.
1791         $message = main::simple_fold($message, "", 4) unless $nofold;
1792         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1793                                     # appends is to the same line
1794     }
1795
1796     return $message if defined wantarray;   # If a caller just wants the msg
1797
1798     carp $message;
1799     return;
1800 }
1801
1802 sub my_carp_bug {
1803     # This is called when it is clear that the problem is caused by a bug in
1804     # this program.
1805
1806     my $message = shift;
1807     $message =~ s/^$0: *//;
1808     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1809     carp $message;
1810     return;
1811 }
1812
1813 sub carp_too_few_args {
1814     if (@_ != 2) {
1815         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1816         return;
1817     }
1818
1819     my $args_ref = shift;
1820     my $count = shift;
1821
1822     my_carp_bug("Need at least $count arguments to "
1823         . (caller 1)[3]
1824         . ".  Instead got: '"
1825         . join ', ', @$args_ref
1826         . "'.  No action taken.");
1827     return;
1828 }
1829
1830 sub carp_extra_args {
1831     my $args_ref = shift;
1832     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1833
1834     unless (ref $args_ref) {
1835         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1836         return;
1837     }
1838     my ($package, $file, $line) = caller;
1839     my $subroutine = (caller 1)[3];
1840
1841     my $list;
1842     if (ref $args_ref eq 'HASH') {
1843         foreach my $key (keys %$args_ref) {
1844             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1845         }
1846         $list = join ', ', each %{$args_ref};
1847     }
1848     elsif (ref $args_ref eq 'ARRAY') {
1849         foreach my $arg (@$args_ref) {
1850             $arg = $UNDEF unless defined $arg;
1851         }
1852         $list = join ', ', @$args_ref;
1853     }
1854     else {
1855         my_carp_bug("Can't cope with ref "
1856                 . ref($args_ref)
1857                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1858         return;
1859     }
1860
1861     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1862     return;
1863 }
1864
1865 package main;
1866
1867 { # Closure
1868
1869     # This program uses the inside-out method for objects, as recommended in
1870     # "Perl Best Practices".  (This is the best solution still, since this has
1871     # to run under miniperl.)  This closure aids in generating those.  There
1872     # are two routines.  setup_package() is called once per package to set
1873     # things up, and then set_access() is called for each hash representing a
1874     # field in the object.  These routines arrange for the object to be
1875     # properly destroyed when no longer used, and for standard accessor
1876     # functions to be generated.  If you need more complex accessors, just
1877     # write your own and leave those accesses out of the call to set_access().
1878     # More details below.
1879
1880     my %constructor_fields; # fields that are to be used in constructors; see
1881                             # below
1882
1883     # The values of this hash will be the package names as keys to other
1884     # hashes containing the name of each field in the package as keys, and
1885     # references to their respective hashes as values.
1886     my %package_fields;
1887
1888     sub setup_package {
1889         # Sets up the package, creating standard DESTROY and dump methods
1890         # (unless already defined).  The dump method is used in debugging by
1891         # simple_dumper().
1892         # The optional parameters are:
1893         #   a)  a reference to a hash, that gets populated by later
1894         #       set_access() calls with one of the accesses being
1895         #       'constructor'.  The caller can then refer to this, but it is
1896         #       not otherwise used by these two routines.
1897         #   b)  a reference to a callback routine to call during destruction
1898         #       of the object, before any fields are actually destroyed
1899
1900         my %args = @_;
1901         my $constructor_ref = delete $args{'Constructor_Fields'};
1902         my $destroy_callback = delete $args{'Destroy_Callback'};
1903         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1904
1905         my %fields;
1906         my $package = (caller)[0];
1907
1908         $package_fields{$package} = \%fields;
1909         $constructor_fields{$package} = $constructor_ref;
1910
1911         unless ($package->can('DESTROY')) {
1912             my $destroy_name = "${package}::DESTROY";
1913             no strict "refs";
1914
1915             # Use typeglob to give the anonymous subroutine the name we want
1916             *$destroy_name = sub {
1917                 my $self = shift;
1918                 my $addr = do { no overloading; pack 'J', $self; };
1919
1920                 $self->$destroy_callback if $destroy_callback;
1921                 foreach my $field (keys %{$package_fields{$package}}) {
1922                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1923                     delete $package_fields{$package}{$field}{$addr};
1924                 }
1925                 return;
1926             }
1927         }
1928
1929         unless ($package->can('dump')) {
1930             my $dump_name = "${package}::dump";
1931             no strict "refs";
1932             *$dump_name = sub {
1933                 my $self = shift;
1934                 return dump_inside_out($self, $package_fields{$package}, @_);
1935             }
1936         }
1937         return;
1938     }
1939
1940     sub set_access {
1941         # Arrange for the input field to be garbage collected when no longer
1942         # needed.  Also, creates standard accessor functions for the field
1943         # based on the optional parameters-- none if none of these parameters:
1944         #   'addable'    creates an 'add_NAME()' accessor function.
1945         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1946         #                function.
1947         #   'settable'   creates a 'set_NAME()' accessor function.
1948         #   'constructor' doesn't create an accessor function, but adds the
1949         #                field to the hash that was previously passed to
1950         #                setup_package();
1951         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1952         # 'add' etc. all mean 'addable'.
1953         # The read accessor function will work on both array and scalar
1954         # values.  If another accessor in the parameter list is 'a', the read
1955         # access assumes an array.  You can also force it to be array access
1956         # by specifying 'readable_array' instead of 'readable'
1957         #
1958         # A sort-of 'protected' access can be set-up by preceding the addable,
1959         # readable or settable with some initial portion of 'protected_' (but,
1960         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1961         # "protection" is only by convention.  All that happens is that the
1962         # accessor functions' names begin with an underscore.  So instead of
1963         # calling set_foo, the call is _set_foo.  (Real protection could be
1964         # accomplished by having a new subroutine, end_package, called at the
1965         # end of each package, and then storing the __LINE__ ranges and
1966         # checking them on every accessor.  But that is way overkill.)
1967
1968         # We create anonymous subroutines as the accessors and then use
1969         # typeglobs to assign them to the proper package and name
1970
1971         my $name = shift;   # Name of the field
1972         my $field = shift;  # Reference to the inside-out hash containing the
1973                             # field
1974
1975         my $package = (caller)[0];
1976
1977         if (! exists $package_fields{$package}) {
1978             croak "$0: Must call 'setup_package' before 'set_access'";
1979         }
1980
1981         # Stash the field so DESTROY can get it.
1982         $package_fields{$package}{$name} = $field;
1983
1984         # Remaining arguments are the accessors.  For each...
1985         foreach my $access (@_) {
1986             my $access = lc $access;
1987
1988             my $protected = "";
1989
1990             # Match the input as far as it goes.
1991             if ($access =~ /^(p[^_]*)_/) {
1992                 $protected = $1;
1993                 if (substr('protected_', 0, length $protected)
1994                     eq $protected)
1995                 {
1996
1997                     # Add 1 for the underscore not included in $protected
1998                     $access = substr($access, length($protected) + 1);
1999                     $protected = '_';
2000                 }
2001                 else {
2002                     $protected = "";
2003                 }
2004             }
2005
2006             if (substr('addable', 0, length $access) eq $access) {
2007                 my $subname = "${package}::${protected}add_$name";
2008                 no strict "refs";
2009
2010                 # add_ accessor.  Don't add if already there, which we
2011                 # determine using 'eq' for scalars and '==' otherwise.
2012                 *$subname = sub {
2013                     use strict "refs";
2014                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2015                     my $self = shift;
2016                     my $value = shift;
2017                     my $addr = do { no overloading; pack 'J', $self; };
2018                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2019                     if (ref $value) {
2020                         return if grep { $value == $_ } @{$field->{$addr}};
2021                     }
2022                     else {
2023                         return if grep { $value eq $_ } @{$field->{$addr}};
2024                     }
2025                     push @{$field->{$addr}}, $value;
2026                     return;
2027                 }
2028             }
2029             elsif (substr('constructor', 0, length $access) eq $access) {
2030                 if ($protected) {
2031                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
2032                 }
2033                 else {
2034                     $constructor_fields{$package}{$name} = $field;
2035                 }
2036             }
2037             elsif (substr('readable_array', 0, length $access) eq $access) {
2038
2039                 # Here has read access.  If one of the other parameters for
2040                 # access is array, or this one specifies array (by being more
2041                 # than just 'readable_'), then create a subroutine that
2042                 # assumes the data is an array.  Otherwise just a scalar
2043                 my $subname = "${package}::${protected}$name";
2044                 if (grep { /^a/i } @_
2045                     or length($access) > length('readable_'))
2046                 {
2047                     no strict "refs";
2048                     *$subname = sub {
2049                         use strict "refs";
2050                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2051                         my $addr = do { no overloading; pack 'J', $_[0]; };
2052                         if (ref $field->{$addr} ne 'ARRAY') {
2053                             my $type = ref $field->{$addr};
2054                             $type = 'scalar' unless $type;
2055                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
2056                             return;
2057                         }
2058                         return scalar @{$field->{$addr}} unless wantarray;
2059
2060                         # Make a copy; had problems with caller modifying the
2061                         # original otherwise
2062                         my @return = @{$field->{$addr}};
2063                         return @return;
2064                     }
2065                 }
2066                 else {
2067
2068                     # Here not an array value, a simpler function.
2069                     no strict "refs";
2070                     *$subname = sub {
2071                         use strict "refs";
2072                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2073                         no overloading;
2074                         return $field->{pack 'J', $_[0]};
2075                     }
2076                 }
2077             }
2078             elsif (substr('settable', 0, length $access) eq $access) {
2079                 my $subname = "${package}::${protected}set_$name";
2080                 no strict "refs";
2081                 *$subname = sub {
2082                     use strict "refs";
2083                     if (main::DEBUG) {
2084                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
2085                         Carp::carp_extra_args(\@_) if @_ > 2;
2086                     }
2087                     # $self is $_[0]; $value is $_[1]
2088                     no overloading;
2089                     $field->{pack 'J', $_[0]} = $_[1];
2090                     return;
2091                 }
2092             }
2093             else {
2094                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
2095             }
2096         }
2097         return;
2098     }
2099 }
2100
2101 package Input_file;
2102
2103 # All input files use this object, which stores various attributes about them,
2104 # and provides for convenient, uniform handling.  The run method wraps the
2105 # processing.  It handles all the bookkeeping of opening, reading, and closing
2106 # the file, returning only significant input lines.
2107 #
2108 # Each object gets a handler which processes the body of the file, and is
2109 # called by run().  All character property files must use the generic,
2110 # default handler, which has code scrubbed to handle things you might not
2111 # expect, including automatic EBCDIC handling.  For files that don't deal with
2112 # mapping code points to a property value, such as test files,
2113 # PropertyAliases, PropValueAliases, and named sequences, you can override the
2114 # handler to be a custom one.  Such a handler should basically be a
2115 # while(next_line()) {...} loop.
2116 #
2117 # You can also set up handlers to
2118 #   0) call during object construction time, after everything else is done
2119 #   1) call before the first line is read, for pre processing
2120 #   2) call to adjust each line of the input before the main handler gets
2121 #      them.  This can be automatically generated, if appropriately simple
2122 #      enough, by specifying a Properties parameter in the constructor.
2123 #   3) call upon EOF before the main handler exits its loop
2124 #   4) call at the end, for post processing
2125 #
2126 # $_ is used to store the input line, and is to be filtered by the
2127 # each_line_handler()s.  So, if the format of the line is not in the desired
2128 # format for the main handler, these are used to do that adjusting.  They can
2129 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2130 # so the $_ output of one is used as the input to the next.  The EOF handler
2131 # is also stackable, but none of the others are, but could easily be changed
2132 # to be so.
2133 #
2134 # Some properties are used by the Perl core but aren't defined until later
2135 # Unicode releases.  The perl interpreter would have problems working when
2136 # compiled with an earlier Unicode version that doesn't have them, so we need
2137 # to define them somehow for those releases.  The 'Early' constructor
2138 # parameter can be used to automatically handle this.  It is essentially
2139 # ignored if the Unicode version being compiled has a data file for this
2140 # property.  Either code to execute or a file to read can be specified.
2141 # Details are at the %early definition.
2142 #
2143 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2144 # which insert the parameters as lines to be processed before the next input
2145 # file line is read.  This allows the EOF handler(s) to flush buffers, for
2146 # example.  The difference between the two routines is that the lines inserted
2147 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2148 # called it from such a handler, you would get infinite recursion without some
2149 # mechanism to prevent that.)  Lines inserted by insert_adjusted_lines() go
2150 # directly to the main handler without any adjustments.  If the
2151 # post-processing handler calls any of these, there will be no effect.  Some
2152 # error checking for these conditions could be added, but it hasn't been done.
2153 #
2154 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2155 # to prevent further processing of the line.  This routine will output the
2156 # message as a warning once, and then keep a count of the lines that have the
2157 # same message, and output that count at the end of the file's processing.
2158 # This keeps the number of messages down to a manageable amount.
2159 #
2160 # get_missings() should be called to retrieve any @missing input lines.
2161 # Messages will be raised if this isn't done if the options aren't to ignore
2162 # missings.
2163
2164 sub trace { return main::trace(@_); }
2165
2166 { # Closure
2167     # Keep track of fields that are to be put into the constructor.
2168     my %constructor_fields;
2169
2170     main::setup_package(Constructor_Fields => \%constructor_fields);
2171
2172     my %file; # Input file name, required
2173     main::set_access('file', \%file, qw{ c r });
2174
2175     my %first_released; # Unicode version file was first released in, required
2176     main::set_access('first_released', \%first_released, qw{ c r });
2177
2178     my %handler;    # Subroutine to process the input file, defaults to
2179                     # 'process_generic_property_file'
2180     main::set_access('handler', \%handler, qw{ c });
2181
2182     my %property;
2183     # name of property this file is for.  defaults to none, meaning not
2184     # applicable, or is otherwise determinable, for example, from each line.
2185     main::set_access('property', \%property, qw{ c r });
2186
2187     my %optional;
2188     # This is either an unsigned number, or a list of property names.  In the
2189     # former case, if it is non-zero, it means the file is optional, so if the
2190     # file is absent, no warning about that is output.  In the latter case, it
2191     # is a list of properties that the file (exclusively) defines.  If the
2192     # file is present, tables for those properties will be produced; if
2193     # absent, none will, even if they are listed elsewhere (namely
2194     # PropertyAliases.txt and PropValueAliases.txt) as being in this release,
2195     # and no warnings will be raised about them not being available.  (And no
2196     # warning about the file itself will be raised.)
2197     main::set_access('optional', \%optional, qw{ c readable_array } );
2198
2199     my %non_skip;
2200     # This is used for debugging, to skip processing of all but a few input
2201     # files.  Add 'non_skip => 1' to the constructor for those files you want
2202     # processed when you set the $debug_skip global.
2203     main::set_access('non_skip', \%non_skip, 'c');
2204
2205     my %skip;
2206     # This is used to skip processing of this input file (semi-) permanently.
2207     # The value should be the reason the file is being skipped.  It is used
2208     # for files that we aren't planning to process anytime soon, but want to
2209     # allow to be in the directory and be checked for their names not
2210     # conflicting with any other files on a DOS 8.3 name filesystem, but to
2211     # not otherwise be processed, and to not raise a warning about not being
2212     # handled.  In the constructor call, any value that evaluates to a numeric
2213     # 0 or undef means don't skip.  Any other value is a string giving the
2214     # reason it is being skipped, and this will appear in generated pod.
2215     # However, an empty string reason will suppress the pod entry.
2216     # Internally, calls that evaluate to numeric 0 are changed into undef to
2217     # distinguish them from an empty string call.
2218     main::set_access('skip', \%skip, 'c', 'r');
2219
2220     my %each_line_handler;
2221     # list of subroutines to look at and filter each non-comment line in the
2222     # file.  defaults to none.  The subroutines are called in order, each is
2223     # to adjust $_ for the next one, and the final one adjusts it for
2224     # 'handler'
2225     main::set_access('each_line_handler', \%each_line_handler, 'c');
2226
2227     my %retain_trailing_comments;
2228     # This is used to not discard the comments that end data lines.  This
2229     # would be used only for files with non-typical syntax, and most code here
2230     # assumes that comments have been stripped, so special handlers would have
2231     # to be written.  It is assumed that the code will use these in
2232     # single-quoted contexts, and so any "'" marks in the comment will be
2233     # prefixed by a backslash.
2234     main::set_access('retain_trailing_comments', \%retain_trailing_comments, 'c');
2235
2236     my %properties; # Optional ordered list of the properties that occur in each
2237     # meaningful line of the input file.  If present, an appropriate
2238     # each_line_handler() is automatically generated and pushed onto the stack
2239     # of such handlers.  This is useful when a file contains multiple
2240     # properties per line, but no other special considerations are necessary.
2241     # The special value "<ignored>" means to discard the corresponding input
2242     # field.
2243     # Any @missing lines in the file should also match this syntax; no such
2244     # files exist as of 6.3.  But if it happens in a future release, the code
2245     # could be expanded to properly parse them.
2246     main::set_access('properties', \%properties, qw{ c r });
2247
2248     my %has_missings_defaults;
2249     # ? Are there lines in the file giving default values for code points
2250     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2251     # the norm, but IGNORED means it has such lines, but the handler doesn't
2252     # use them.  Having these three states allows us to catch changes to the
2253     # UCD that this program should track.  XXX This could be expanded to
2254     # specify the syntax for such lines, like %properties above.
2255     main::set_access('has_missings_defaults',
2256                                         \%has_missings_defaults, qw{ c r });
2257
2258     my %construction_time_handler;
2259     # Subroutine to call at the end of the new method.  If undef, no such
2260     # handler is called.
2261     main::set_access('construction_time_handler',
2262                                         \%construction_time_handler, qw{ c });
2263
2264     my %pre_handler;
2265     # Subroutine to call before doing anything else in the file.  If undef, no
2266     # such handler is called.
2267     main::set_access('pre_handler', \%pre_handler, qw{ c });
2268
2269     my %eof_handler;
2270     # Subroutines to call upon getting an EOF on the input file, but before
2271     # that is returned to the main handler.  This is to allow buffers to be
2272     # flushed.  The handler is expected to call insert_lines() or
2273     # insert_adjusted() with the buffered material
2274     main::set_access('eof_handler', \%eof_handler, qw{ c });
2275
2276     my %post_handler;
2277     # Subroutine to call after all the lines of the file are read in and
2278     # processed.  If undef, no such handler is called.  Note that this cannot
2279     # add lines to be processed; instead use eof_handler
2280     main::set_access('post_handler', \%post_handler, qw{ c });
2281
2282     my %progress_message;
2283     # Message to print to display progress in lieu of the standard one
2284     main::set_access('progress_message', \%progress_message, qw{ c });
2285
2286     my %handle;
2287     # cache open file handle, internal.  Is undef if file hasn't been
2288     # processed at all, empty if has;
2289     main::set_access('handle', \%handle);
2290
2291     my %added_lines;
2292     # cache of lines added virtually to the file, internal
2293     main::set_access('added_lines', \%added_lines);
2294
2295     my %remapped_lines;
2296     # cache of lines added virtually to the file, internal
2297     main::set_access('remapped_lines', \%remapped_lines);
2298
2299     my %errors;
2300     # cache of errors found, internal
2301     main::set_access('errors', \%errors);
2302
2303     my %missings;
2304     # storage of '@missing' defaults lines
2305     main::set_access('missings', \%missings);
2306
2307     my %early;
2308     # Used for properties that must be defined (for Perl's purposes) on
2309     # versions of Unicode earlier than Unicode itself defines them.  The
2310     # parameter is an array (it would be better to be a hash, but not worth
2311     # bothering about due to its rare use).
2312     #
2313     # The first element is either a code reference to call when in a release
2314     # earlier than the Unicode file is available in, or it is an alternate
2315     # file to use instead of the non-existent one.  This file must have been
2316     # plunked down in the same directory as mktables.  Should you be compiling
2317     # on a release that needs such a file, mktables will abort the
2318     # compilation, and tell you where to get the necessary file(s), and what
2319     # name(s) to use to store them as.
2320     # In the case of specifying an alternate file, the array must contain two
2321     # further elements:
2322     #
2323     # [1] is the name of the property that will be generated by this file.
2324     # The class automatically takes the input file and excludes any code
2325     # points in it that were not assigned in the Unicode version being
2326     # compiled.  It then uses this result to define the property in the given
2327     # version.  Since the property doesn't actually exist in the Unicode
2328     # version being compiled, this should be a name accessible only by core
2329     # perl.  If it is the same name as the regular property, the constructor
2330     # will mark the output table as a $PLACEHOLDER so that it doesn't actually
2331     # get output, and so will be unusable by non-core code.  Otherwise it gets
2332     # marked as $INTERNAL_ONLY.
2333     #
2334     # [2] is a property value to assign (only when compiling Unicode 1.1.5) to
2335     # the Hangul syllables in that release (which were ripped out in version
2336     # 2) for the given property .  (Hence it is ignored except when compiling
2337     # version 1.  You only get one value that applies to all of them, which
2338     # may not be the actual reality, but probably nobody cares anyway for
2339     # these obsolete characters.)
2340     #
2341     # [3] if present is the default value for the property to assign for code
2342     # points not given in the input.  If not present, the default from the
2343     # normal property is used
2344     #
2345     # [-1] If there is an extra final element that is the string 'ONLY_EARLY'.
2346     # it means to not add the name in [1] as an alias to the property name
2347     # used for these.  Normally, when compiling Unicode versions that don't
2348     # invoke the early handling, the name is added as a synonym.
2349     #
2350     # Not all files can be handled in the above way, and so the code ref
2351     # alternative is available.  It can do whatever it needs to.  The other
2352     # array elements are optional in this case, and the code is free to use or
2353     # ignore them if they are present.
2354     #
2355     # Internally, the constructor unshifts a 0 or 1 onto this array to
2356     # indicate if an early alternative is actually being used or not.  This
2357     # makes for easier testing later on.
2358     main::set_access('early', \%early, 'c');
2359
2360     my %only_early;
2361     main::set_access('only_early', \%only_early, 'c');
2362
2363     my %required_even_in_debug_skip;
2364     # debug_skip is used to speed up compilation during debugging by skipping
2365     # processing files that are not needed for the task at hand.  However,
2366     # some files pretty much can never be skipped, and this is used to specify
2367     # that this is one of them.  In order to skip this file, the call to the
2368     # constructor must be edited to comment out this parameter.
2369     main::set_access('required_even_in_debug_skip',
2370                      \%required_even_in_debug_skip, 'c');
2371
2372     my %withdrawn;
2373     # Some files get removed from the Unicode DB.  This is a version object
2374     # giving the first release without this file.
2375     main::set_access('withdrawn', \%withdrawn, 'c');
2376
2377     my %in_this_release;
2378     # Calculated value from %first_released and %withdrawn.  Are we compiling
2379     # a Unicode release which includes this file?
2380     main::set_access('in_this_release', \%in_this_release);
2381
2382     sub _next_line;
2383     sub _next_line_with_remapped_range;
2384
2385     sub new {
2386         my $class = shift;
2387
2388         my $self = bless \do{ my $anonymous_scalar }, $class;
2389         my $addr = do { no overloading; pack 'J', $self; };
2390
2391         # Set defaults
2392         $handler{$addr} = \&main::process_generic_property_file;
2393         $retain_trailing_comments{$addr} = 0;
2394         $non_skip{$addr} = 0;
2395         $skip{$addr} = undef;
2396         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2397         $handle{$addr} = undef;
2398         $added_lines{$addr} = [ ];
2399         $remapped_lines{$addr} = [ ];
2400         $each_line_handler{$addr} = [ ];
2401         $eof_handler{$addr} = [ ];
2402         $errors{$addr} = { };
2403         $missings{$addr} = [ ];
2404         $early{$addr} = [ ];
2405         $optional{$addr} = [ ];
2406
2407         # Two positional parameters.
2408         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2409         $file{$addr} = main::internal_file_to_platform(shift);
2410         $first_released{$addr} = shift;
2411
2412         # The rest of the arguments are key => value pairs
2413         # %constructor_fields has been set up earlier to list all possible
2414         # ones.  Either set or push, depending on how the default has been set
2415         # up just above.
2416         my %args = @_;
2417         foreach my $key (keys %args) {
2418             my $argument = $args{$key};
2419
2420             # Note that the fields are the lower case of the constructor keys
2421             my $hash = $constructor_fields{lc $key};
2422             if (! defined $hash) {
2423                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2424                 next;
2425             }
2426             if (ref $hash->{$addr} eq 'ARRAY') {
2427                 if (ref $argument eq 'ARRAY') {
2428                     foreach my $argument (@{$argument}) {
2429                         next if ! defined $argument;
2430                         push @{$hash->{$addr}}, $argument;
2431                     }
2432                 }
2433                 else {
2434                     push @{$hash->{$addr}}, $argument if defined $argument;
2435                 }
2436             }
2437             else {
2438                 $hash->{$addr} = $argument;
2439             }
2440             delete $args{$key};
2441         };
2442
2443         $non_skip{$addr} = 1 if $required_even_in_debug_skip{$addr};
2444
2445         # Convert 0 (meaning don't skip) to undef
2446         undef $skip{$addr} unless $skip{$addr};
2447
2448         # Handle the case where this file is optional
2449         my $pod_message_for_non_existent_optional = "";
2450         if ($optional{$addr}->@*) {
2451
2452             # First element is the pod message
2453             $pod_message_for_non_existent_optional
2454                                                 = shift $optional{$addr}->@*;
2455             # Convert a 0 'Optional' argument to an empty list to make later
2456             # code more concise.
2457             if (   $optional{$addr}->@*
2458                 && $optional{$addr}->@* == 1
2459                 && $optional{$addr}[0] ne ""
2460                 && $optional{$addr}[0] !~ /\D/
2461                 && $optional{$addr}[0] == 0)
2462             {
2463                 $optional{$addr} = [ ];
2464             }
2465             else {  # But if the only element doesn't evaluate to 0, make sure
2466                     # that this file is indeed considered optional below.
2467                 unshift $optional{$addr}->@*, 1;
2468             }
2469         }
2470
2471         my $progress;
2472         my $function_instead_of_file = 0;
2473
2474         if ($early{$addr}->@* && $early{$addr}[-1] eq 'ONLY_EARLY') {
2475             $only_early{$addr} = 1;
2476             pop $early{$addr}->@*;
2477         }
2478
2479         # If we are compiling a Unicode release earlier than the file became
2480         # available, the constructor may have supplied a substitute
2481         if ($first_released{$addr} gt $v_version && $early{$addr}->@*) {
2482
2483             # Yes, we have a substitute, that we will use; mark it so
2484             unshift $early{$addr}->@*, 1;
2485
2486             # See the definition of %early for what the array elements mean.
2487             # Note that we have just unshifted onto the array, so the numbers
2488             # below are +1 of those in the %early description.
2489             # If we have a property this defines, create a table and default
2490             # map for it now (at essentially compile time), so that it will be
2491             # available for the whole of run time.  (We will want to add this
2492             # name as an alias when we are using the official property name;
2493             # but this must be deferred until run(), because at construction
2494             # time the official names have yet to be defined.)
2495             if ($early{$addr}[2]) {
2496                 my $fate = ($property{$addr}
2497                             && $property{$addr} eq $early{$addr}[2])
2498                           ? $PLACEHOLDER
2499                           : $INTERNAL_ONLY;
2500                 my $prop_object = Property->new($early{$addr}[2],
2501                                                 Fate => $fate,
2502                                                 Perl_Extension => 1,
2503                                                 );
2504
2505                 # If not specified by the constructor, use the default mapping
2506                 # for the regular property for this substitute one.
2507                 if ($early{$addr}[4]) {
2508                     $prop_object->set_default_map($early{$addr}[4]);
2509                 }
2510                 elsif (    defined $property{$addr}
2511                        &&  defined $default_mapping{$property{$addr}})
2512                 {
2513                     $prop_object
2514                         ->set_default_map($default_mapping{$property{$addr}});
2515                 }
2516             }
2517
2518             if (ref $early{$addr}[1] eq 'CODE') {
2519                 $function_instead_of_file = 1;
2520
2521                 # If the first element of the array is a code ref, the others
2522                 # are optional.
2523                 $handler{$addr} = $early{$addr}[1];
2524                 $property{$addr} = $early{$addr}[2]
2525                                                 if defined $early{$addr}[2];
2526                 $progress = "substitute $file{$addr}";
2527
2528                 undef $file{$addr};
2529             }
2530             else {  # Specifying a substitute file
2531
2532                 if (! main::file_exists($early{$addr}[1])) {
2533
2534                     # If we don't see the substitute file, generate an error
2535                     # message giving the needed things, and add it to the list
2536                     # of such to output before actual processing happens
2537                     # (hence the user finds out all of them in one run).
2538                     # Instead of creating a general method for NameAliases,
2539                     # hard-code it here, as there is unlikely to ever be a
2540                     # second one which needs special handling.
2541                     my $string_version = ($file{$addr} eq "NameAliases.txt")
2542                                     ? 'at least 6.1 (the later, the better)'
2543                                     : sprintf "%vd", $first_released{$addr};
2544                     push @missing_early_files, <<END;
2545 '$file{$addr}' version $string_version should be copied to '$early{$addr}[1]'.
2546 END
2547                     ;
2548                     return;
2549                 }
2550                 $progress = $early{$addr}[1];
2551                 $progress .= ", substituting for $file{$addr}" if $file{$addr};
2552                 $file{$addr} = $early{$addr}[1];
2553                 $property{$addr} = $early{$addr}[2];
2554
2555                 # Ignore code points not in the version being compiled
2556                 push $each_line_handler{$addr}->@*, \&_exclude_unassigned;
2557
2558                 if (   $v_version lt v2.0        # Hanguls in this release ...
2559                     && defined $early{$addr}[3]) # ... need special treatment
2560                 {
2561                     push $eof_handler{$addr}->@*, \&_fixup_obsolete_hanguls;
2562                 }
2563             }
2564
2565             # And this substitute is valid for all releases.
2566             $first_released{$addr} = v0;
2567         }
2568         else {  # Normal behavior
2569             $progress = $file{$addr};
2570             unshift $early{$addr}->@*, 0; # No substitute
2571         }
2572
2573         my $file = $file{$addr};
2574         $progress_message{$addr} = "Processing $progress"
2575                                             unless $progress_message{$addr};
2576
2577         # A file should be there if it is within the window of versions for
2578         # which Unicode supplies it
2579         if ($withdrawn{$addr} && $withdrawn{$addr} le $v_version) {
2580             $in_this_release{$addr} = 0;
2581             $skip{$addr} = "";
2582         }
2583         else {
2584             $in_this_release{$addr} = $first_released{$addr} le $v_version;
2585
2586             # Check that the file for this object (possibly using a substitute
2587             # for early releases) exists or we have a function alternative
2588             if (   ! $function_instead_of_file
2589                 && ! main::file_exists($file))
2590             {
2591                 # Here there is nothing available for this release.  This is
2592                 # fine if we aren't expecting anything in this release.
2593                 if (! $in_this_release{$addr}) {
2594                     $skip{$addr} = "";  # Don't remark since we expected
2595                                         # nothing and got nothing
2596                 }
2597                 elsif ($optional{$addr}->@*) {
2598
2599                     # Here the file is optional in this release; Use the
2600                     # passed in text to document this case in the pod.
2601                     $skip{$addr} = $pod_message_for_non_existent_optional;
2602                 }
2603                 elsif (   $in_this_release{$addr}
2604                        && ! defined $skip{$addr}
2605                        && defined $file)
2606                 { # Doesn't exist but should.
2607                     $skip{$addr} = "'$file' not found.  Possibly Big problems";
2608                     Carp::my_carp($skip{$addr});
2609                 }
2610             }
2611             elsif ($debug_skip && ! defined $skip{$addr} && ! $non_skip{$addr})
2612             {
2613
2614                 # The file exists; if not skipped for another reason, and we are
2615                 # skipping most everything during debugging builds, use that as
2616                 # the skip reason.
2617                 $skip{$addr} = '$debug_skip is on'
2618             }
2619         }
2620
2621         if (   ! $debug_skip
2622             && $non_skip{$addr}
2623             && ! $required_even_in_debug_skip{$addr}
2624             && $verbosity)
2625         {
2626             print "Warning: " . __PACKAGE__ . " constructor for $file has useless 'non_skip' in it\n";
2627         }
2628
2629         # Here, we have figured out if we will be skipping this file or not.
2630         # If so, we add any single property it defines to any passed in
2631         # optional property list.  These will be dealt with at run time.
2632         if (defined $skip{$addr}) {
2633             if ($property{$addr}) {
2634                 push $optional{$addr}->@*, $property{$addr};
2635             }
2636         } # Otherwise, are going to process the file.
2637         elsif ($property{$addr}) {
2638
2639             # If the file has a property defined in the constructor for it, it
2640             # means that the property is not listed in the file's entries.  So
2641             # add a handler (to the list of line handlers) to insert the
2642             # property name into the lines, to provide a uniform interface to
2643             # the final processing subroutine.
2644             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2645         }
2646         elsif ($properties{$addr}) {
2647
2648             # Similarly, there may be more than one property represented on
2649             # each line, with no clue but the constructor input what those
2650             # might be.  Add a handler for each line in the input so that it
2651             # creates a separate input line for each property in those input
2652             # lines, thus making them suitable to handle generically.
2653
2654             push @{$each_line_handler{$addr}},
2655                  sub {
2656                     my $file = shift;
2657                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2658
2659                     my @fields = split /\s*;\s*/, $_, -1;
2660
2661                     if (@fields - 1 > @{$properties{$addr}}) {
2662                         $file->carp_bad_line('Extra fields');
2663                         $_ = "";
2664                         return;
2665                     }
2666                     my $range = shift @fields;  # 0th element is always the
2667                                                 # range
2668
2669                     # The next fields in the input line correspond
2670                     # respectively to the stored properties.
2671                     for my $i (0 ..  @{$properties{$addr}} - 1) {
2672                         my $property_name = $properties{$addr}[$i];
2673                         next if $property_name eq '<ignored>';
2674                         $file->insert_adjusted_lines(
2675                               "$range; $property_name; $fields[$i]");
2676                     }
2677                     $_ = "";
2678
2679                     return;
2680                 };
2681         }
2682
2683         {   # On non-ascii platforms, we use a special pre-handler
2684             no strict;
2685             no warnings 'once';
2686             *next_line = (main::NON_ASCII_PLATFORM)
2687                          ? *_next_line_with_remapped_range
2688                          : *_next_line;
2689         }
2690
2691         &{$construction_time_handler{$addr}}($self)
2692                                         if $construction_time_handler{$addr};
2693
2694         return $self;
2695     }
2696
2697
2698     use overload
2699         fallback => 0,
2700         qw("") => "_operator_stringify",
2701         "." => \&main::_operator_dot,
2702         ".=" => \&main::_operator_dot_equal,
2703     ;
2704
2705     sub _operator_stringify {
2706         my $self = shift;
2707
2708         return __PACKAGE__ . " object for " . $self->file;
2709     }
2710
2711     sub run {
2712         # Process the input object $self.  This opens and closes the file and
2713         # calls all the handlers for it.  Currently,  this can only be called
2714         # once per file, as it destroy's the EOF handlers
2715
2716         # flag to make sure extracted files are processed early
2717         state $seen_non_extracted = 0;
2718
2719         my $self = shift;
2720         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2721
2722         my $addr = do { no overloading; pack 'J', $self; };
2723
2724         my $file = $file{$addr};
2725
2726         if (! $file) {
2727             $handle{$addr} = 'pretend_is_open';
2728         }
2729         else {
2730             if ($seen_non_extracted) {
2731                 if ($file =~ /$EXTRACTED/i) # Some platforms may change the
2732                                             # case of the file's name
2733                 {
2734                     Carp::my_carp_bug(main::join_lines(<<END
2735 $file should be processed just after the 'Prop...Alias' files, and before
2736 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2737 have subtle problems
2738 END
2739                     ));
2740                 }
2741             }
2742             elsif ($EXTRACTED_DIR
2743
2744                     # We only do this check for generic property files
2745                     && $handler{$addr} == \&main::process_generic_property_file
2746
2747                     && $file !~ /$EXTRACTED/i)
2748             {
2749                 # We don't set this (by the 'if' above) if we have no
2750                 # extracted directory, so if running on an early version,
2751                 # this test won't work.  Not worth worrying about.
2752                 $seen_non_extracted = 1;
2753             }
2754
2755             # Mark the file as having being processed, and warn if it
2756             # isn't a file we are expecting.  As we process the files,
2757             # they are deleted from the hash, so any that remain at the
2758             # end of the program are files that we didn't process.
2759             my $fkey = File::Spec->rel2abs($file);
2760             my $exists = delete $potential_files{lc($fkey)};
2761
2762             Carp::my_carp("Was not expecting '$file'.")
2763                                     if $exists && ! $in_this_release{$addr};
2764
2765             # If there is special handling for compiling Unicode releases
2766             # earlier than the first one in which Unicode defines this
2767             # property ...
2768             if ($early{$addr}->@* > 1) {
2769
2770                 # Mark as processed any substitute file that would be used in
2771                 # such a release
2772                 $fkey = File::Spec->rel2abs($early{$addr}[1]);
2773                 delete $potential_files{lc($fkey)};
2774
2775                 # As commented in the constructor code, when using the
2776                 # official property, we still have to allow the publicly
2777                 # inaccessible early name so that the core code which uses it
2778                 # will work regardless.
2779                 if (   ! $only_early{$addr}
2780                     && ! $early{$addr}[0]
2781                     && $early{$addr}->@* > 2)
2782                 {
2783                     my $early_property_name = $early{$addr}[2];
2784                     if ($property{$addr} ne $early_property_name) {
2785                         main::property_ref($property{$addr})
2786                                             ->add_alias($early_property_name);
2787                     }
2788                 }
2789             }
2790
2791             # We may be skipping this file ...
2792             if (defined $skip{$addr}) {
2793
2794                 # If the file isn't supposed to be in this release, there is
2795                 # nothing to do
2796                 if ($in_this_release{$addr}) {
2797
2798                     # But otherwise, we may print a message
2799                     if ($debug_skip) {
2800                         print STDERR "Skipping input file '$file'",
2801                                      " because '$skip{$addr}'\n";
2802                     }
2803
2804                     # And add it to the list of skipped files, which is later
2805                     # used to make the pod
2806                     $skipped_files{$file} = $skip{$addr};
2807
2808                     # The 'optional' list contains properties that are also to
2809                     # be skipped along with the file.  (There may also be
2810                     # digits which are just placeholders to make sure it isn't
2811                     # an empty list
2812                     foreach my $property ($optional{$addr}->@*) {
2813                         next unless $property =~ /\D/;
2814                         my $prop_object = main::property_ref($property);
2815                         next unless defined $prop_object;
2816                         $prop_object->set_fate($SUPPRESSED, $skip{$addr});
2817                     }
2818                 }
2819
2820                 return;
2821             }
2822
2823             # Here, we are going to process the file.  Open it, converting the
2824             # slashes used in this program into the proper form for the OS
2825             my $file_handle;
2826             if (not open $file_handle, "<", $file) {
2827                 Carp::my_carp("Can't open $file.  Skipping: $!");
2828                 return;
2829             }
2830             $handle{$addr} = $file_handle; # Cache the open file handle
2831
2832             # If possible, make sure that the file is the correct version.
2833             # (This data isn't available on early Unicode releases or in
2834             # UnicodeData.txt.)  We don't do this check if we are using a
2835             # substitute file instead of the official one (though the code
2836             # could be extended to do so).
2837             if ($in_this_release{$addr}
2838                 && ! $early{$addr}[0]
2839                 && lc($file) ne 'unicodedata.txt')
2840             {
2841                 if ($file !~ /^Unihan/i) {
2842
2843                     # The non-Unihan files started getting version numbers in
2844                     # 3.2, but some files in 4.0 are unchanged from 3.2, and
2845                     # marked as 3.2.  4.0.1 is the first version where there
2846                     # are no files marked as being from less than 4.0, though
2847                     # some are marked as 4.0.  In versions after that, the
2848                     # numbers are correct.
2849                     if ($v_version ge v4.0.1) {
2850                         $_ = <$file_handle>;    # The version number is in the
2851                                                 # very first line
2852                         if ($_ !~ / - $string_version \. /x) {
2853                             chomp;
2854                             $_ =~ s/^#\s*//;
2855
2856                             # 4.0.1 had some valid files that weren't updated.
2857                             if (! ($v_version eq v4.0.1 && $_ =~ /4\.0\.0/)) {
2858                                 die Carp::my_carp("File '$file' is version "
2859                                                 . "'$_'.  It should be "
2860                                                 . "version $string_version");
2861                             }
2862                         }
2863                     }
2864                 }
2865                 elsif ($v_version ge v6.0.0) { # Unihan
2866
2867                     # Unihan files didn't get accurate version numbers until
2868                     # 6.0.  The version is somewhere in the first comment
2869                     # block
2870                     while (<$file_handle>) {
2871                         if ($_ !~ /^#/) {
2872                             Carp::my_carp_bug("Could not find the expected "
2873                                             . "version info in file '$file'");
2874                             last;
2875                         }
2876                         chomp;
2877                         $_ =~ s/^#\s*//;
2878                         next if $_ !~ / version: /x;
2879                         last if $_ =~ /$string_version/;
2880                         die Carp::my_carp("File '$file' is version "
2881                                         . "'$_'.  It should be "
2882                                         . "version $string_version");
2883                     }
2884                 }
2885             }
2886         }
2887
2888         print "$progress_message{$addr}\n" if $verbosity >= $PROGRESS;
2889
2890         # Call any special handler for before the file.
2891         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2892
2893         # Then the main handler
2894         &{$handler{$addr}}($self);
2895
2896         # Then any special post-file handler.
2897         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2898
2899         # If any errors have been accumulated, output the counts (as the first
2900         # error message in each class was output when it was encountered).
2901         if ($errors{$addr}) {
2902             my $total = 0;
2903             my $types = 0;
2904             foreach my $error (keys %{$errors{$addr}}) {
2905                 $total += $errors{$addr}->{$error};
2906                 delete $errors{$addr}->{$error};
2907                 $types++;
2908             }
2909             if ($total > 1) {
2910                 my $message
2911                         = "A total of $total lines had errors in $file.  ";
2912
2913                 $message .= ($types == 1)
2914                             ? '(Only the first one was displayed.)'
2915                             : '(Only the first of each type was displayed.)';
2916                 Carp::my_carp($message);
2917             }
2918         }
2919
2920         if (@{$missings{$addr}}) {
2921             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2922         }
2923
2924         # If a real file handle, close it.
2925         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2926                                                         ref $handle{$addr};
2927         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2928                                # the file, as opposed to undef
2929         return;
2930     }
2931
2932     sub _next_line {
2933         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2934         # if such a line exists.  'logical' means that any lines that have
2935         # been added via insert_lines() will be returned in $_ before the file
2936         # is read again.
2937
2938         my $self = shift;
2939         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2940
2941         my $addr = do { no overloading; pack 'J', $self; };
2942
2943         # Here the file is open (or if the handle is not a ref, is an open
2944         # 'virtual' file).  Get the next line; any inserted lines get priority
2945         # over the file itself.
2946         my $adjusted;
2947
2948         LINE:
2949         while (1) { # Loop until find non-comment, non-empty line
2950             #local $to_trace = 1 if main::DEBUG;
2951             my $inserted_ref = shift @{$added_lines{$addr}};
2952             if (defined $inserted_ref) {
2953                 ($adjusted, $_) = @{$inserted_ref};
2954                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2955                 return 1 if $adjusted;
2956             }
2957             else {
2958                 last if ! ref $handle{$addr}; # Don't read unless is real file
2959                 last if ! defined ($_ = readline $handle{$addr});
2960             }
2961             chomp;
2962             trace $_ if main::DEBUG && $to_trace;
2963
2964             # See if this line is the comment line that defines what property
2965             # value that code points that are not listed in the file should
2966             # have.  The format or existence of these lines is not guaranteed
2967             # by Unicode since they are comments, but the documentation says
2968             # that this was added for machine-readability, so probably won't
2969             # change.  This works starting in Unicode Version 5.0.  They look
2970             # like:
2971             #
2972             # @missing: 0000..10FFFF; Not_Reordered
2973             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2974             # @missing: 0000..10FFFF; ; NaN
2975             #
2976             # Save the line for a later get_missings() call.
2977             if (/$missing_defaults_prefix/) {
2978                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2979                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2980                 }
2981                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2982                     my @defaults = split /\s* ; \s*/x, $_;
2983
2984                     # The first field is the @missing, which ends in a
2985                     # semi-colon, so can safely shift.
2986                     shift @defaults;
2987
2988                     # Some of these lines may have empty field placeholders
2989                     # which get in the way.  An example is:
2990                     # @missing: 0000..10FFFF; ; NaN
2991                     # Remove them.  Process starting from the top so the
2992                     # splice doesn't affect things still to be looked at.
2993                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2994                         next if $defaults[$i] ne "";
2995                         splice @defaults, $i, 1;
2996                     }
2997
2998                     # What's left should be just the property (maybe) and the
2999                     # default.  Having only one element means it doesn't have
3000                     # the property.
3001                     my $default;
3002                     my $property;
3003                     if (@defaults >= 1) {
3004                         if (@defaults == 1) {
3005                             $default = $defaults[0];
3006                         }
3007                         else {
3008                             $property = $defaults[0];
3009                             $default = $defaults[1];
3010                         }
3011                     }
3012
3013                     if (@defaults < 1
3014                         || @defaults > 2
3015                         || ($default =~ /^</
3016                             && $default !~ /^<code *point>$/i
3017                             && $default !~ /^<none>$/i
3018                             && $default !~ /^<script>$/i))
3019                     {
3020                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
3021                     }
3022                     else {
3023
3024                         # If the property is missing from the line, it should
3025                         # be the one for the whole file
3026                         $property = $property{$addr} if ! defined $property;
3027
3028                         # Change <none> to the null string, which is what it
3029                         # really means.  If the default is the code point
3030                         # itself, set it to <code point>, which is what
3031                         # Unicode uses (but sometimes they've forgotten the
3032                         # space)
3033                         if ($default =~ /^<none>$/i) {
3034                             $default = "";
3035                         }
3036                         elsif ($default =~ /^<code *point>$/i) {
3037                             $default = $CODE_POINT;
3038                         }
3039                         elsif ($default =~ /^<script>$/i) {
3040
3041                             # Special case this one.  Currently is from
3042                             # ScriptExtensions.txt, and means for all unlisted
3043                             # code points, use their Script property values.
3044                             # For the code points not listed in that file, the
3045                             # default value is 'Unknown'.
3046                             $default = "Unknown";
3047                         }
3048
3049                         # Store them as a sub-arrays with both components.
3050                         push @{$missings{$addr}}, [ $default, $property ];
3051                     }
3052                 }
3053
3054                 # There is nothing for the caller to process on this comment
3055                 # line.
3056                 next;
3057             }
3058
3059             # Unless to keep, remove comments.  If to keep, ignore
3060             # comment-only lines
3061             if ($retain_trailing_comments{$addr}) {
3062                 next if / ^ \s* \# /x;
3063
3064                 # But escape any single quotes (done in both the comment and
3065                 # non-comment portion; this could be a bug someday, but not
3066                 # likely)
3067                 s/'/\\'/g;
3068             }
3069             else {
3070                 s/#.*//;
3071             }
3072
3073             # Remove trailing space, and skip this line if the result is empty
3074             s/\s+$//;
3075             next if /^$/;
3076
3077             # Call any handlers for this line, and skip further processing of
3078             # the line if the handler sets the line to null.
3079             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
3080                 &{$sub_ref}($self);
3081                 next LINE if /^$/;
3082             }
3083
3084             # Here the line is ok.  return success.
3085             return 1;
3086         } # End of looping through lines.
3087
3088         # If there are EOF handlers, call each (only once) and if it generates
3089         # more lines to process go back in the loop to handle them.
3090         while ($eof_handler{$addr}->@*) {
3091             &{$eof_handler{$addr}[0]}($self);
3092             shift $eof_handler{$addr}->@*;   # Currently only get one shot at it.
3093             goto LINE if $added_lines{$addr};
3094         }
3095
3096         # Return failure -- no more lines.
3097         return 0;
3098
3099     }
3100
3101     sub _next_line_with_remapped_range {
3102         my $self = shift;
3103         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3104
3105         # like _next_line(), but for use on non-ASCII platforms.  It sets $_
3106         # to be the next logical input line, if any.  Returns non-zero if such
3107         # a line exists.  'logical' means that any lines that have been added
3108         # via insert_lines() will be returned in $_ before the file is read
3109         # again.
3110         #
3111         # The difference from _next_line() is that this remaps the Unicode
3112         # code points in the input to those of the native platform.  Each
3113         # input line contains a single code point, or a single contiguous
3114         # range of them  This routine splits each range into its individual
3115         # code points and caches them.  It returns the cached values,
3116         # translated into their native equivalents, one at a time, for each
3117         # call, before reading the next line.  Since native values can only be
3118         # a single byte wide, no translation is needed for code points above
3119         # 0xFF, and ranges that are entirely above that number are not split.
3120         # If an input line contains the range 254-1000, it would be split into
3121         # three elements: 254, 255, and 256-1000.  (The downstream table
3122         # insertion code will sort and coalesce the individual code points
3123         # into appropriate ranges.)
3124
3125         my $addr = do { no overloading; pack 'J', $self; };
3126
3127         while (1) {
3128
3129             # Look in cache before reading the next line.  Return any cached
3130             # value, translated
3131             my $inserted = shift @{$remapped_lines{$addr}};
3132             if (defined $inserted) {
3133                 trace $inserted if main::DEBUG && $to_trace;
3134                 $_ = $inserted =~ s/^ ( \d+ ) /sprintf("%04X", utf8::unicode_to_native($1))/xer;
3135                 trace $_ if main::DEBUG && $to_trace;
3136                 return 1;
3137             }
3138
3139             # Get the next line.
3140             return 0 unless _next_line($self);
3141
3142             # If there is a special handler for it, return the line,
3143             # untranslated.  This should happen only for files that are
3144             # special, not being code-point related, such as property names.
3145             return 1 if $handler{$addr}
3146                                     != \&main::process_generic_property_file;
3147
3148             my ($range, $property_name, $map, @remainder)
3149                 = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
3150
3151             if (@remainder
3152                 || ! defined $property_name
3153                 || $range !~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
3154             {
3155                 Carp::my_carp_bug("Unrecognized input line '$_'.  Ignored");
3156             }
3157
3158             my $low = hex $1;
3159             my $high = (defined $2) ? hex $2 : $low;
3160
3161             # If the input maps the range to another code point, remap the
3162             # target if it is between 0 and 255.
3163             my $tail;
3164             if (defined $map) {
3165                 $map =~ s/\b 00 ( [0-9A-F]{2} ) \b/sprintf("%04X", utf8::unicode_to_native(hex $1))/gxe;
3166                 $tail = "$property_name; $map";
3167                 $_ = "$range; $tail";
3168             }
3169             else {
3170                 $tail = $property_name;
3171             }
3172
3173             # If entire range is above 255, just return it, unchanged (except
3174             # any mapped-to code point, already changed above)
3175             return 1 if $low > 255;
3176
3177             # Cache an entry for every code point < 255.  For those in the
3178             # range above 255, return a dummy entry for just that portion of
3179             # the range.  Note that this will be out-of-order, but that is not
3180             # a problem.
3181             foreach my $code_point ($low .. $high) {
3182                 if ($code_point > 255) {
3183                     $_ = sprintf "%04X..%04X; $tail", $code_point, $high;
3184                     return 1;
3185                 }
3186                 push @{$remapped_lines{$addr}}, "$code_point; $tail";
3187             }
3188         } # End of looping through lines.
3189
3190         # NOTREACHED
3191     }
3192
3193 #   Not currently used, not fully tested.
3194 #    sub peek {
3195 #        # Non-destructive lookahead one non-adjusted, non-comment, non-blank
3196 #        # record.  Not callable from an each_line_handler(), nor does it call
3197 #        # an each_line_handler() on the line.
3198 #
3199 #        my $self = shift;
3200 #        my $addr = do { no overloading; pack 'J', $self; };
3201 #
3202 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
3203 #            my ($adjusted, $line) = @{$inserted_ref};
3204 #            next if $adjusted;
3205 #
3206 #            # Remove comments and trailing space, and return a non-empty
3207 #            # resulting line
3208 #            $line =~ s/#.*//;
3209 #            $line =~ s/\s+$//;
3210 #            return $line if $line ne "";
3211 #        }
3212 #
3213 #        return if ! ref $handle{$addr}; # Don't read unless is real file
3214 #        while (1) { # Loop until find non-comment, non-empty line
3215 #            local $to_trace = 1 if main::DEBUG;
3216 #            trace $_ if main::DEBUG && $to_trace;
3217 #            return if ! defined (my $line = readline $handle{$addr});
3218 #            chomp $line;
3219 #            push @{$added_lines{$addr}}, [ 0, $line ];
3220 #
3221 #            $line =~ s/#.*//;
3222 #            $line =~ s/\s+$//;
3223 #            return $line if $line ne "";
3224 #        }
3225 #
3226 #        return;
3227 #    }
3228
3229
3230     sub insert_lines {
3231         # Lines can be inserted so that it looks like they were in the input
3232         # file at the place it was when this routine is called.  See also
3233         # insert_adjusted_lines().  Lines inserted via this routine go through
3234         # any each_line_handler()
3235
3236         my $self = shift;
3237
3238         # Each inserted line is an array, with the first element being 0 to
3239         # indicate that this line hasn't been adjusted, and needs to be
3240         # processed.
3241         no overloading;
3242         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
3243         return;
3244     }
3245
3246     sub insert_adjusted_lines {
3247         # Lines can be inserted so that it looks like they were in the input
3248         # file at the place it was when this routine is called.  See also
3249         # insert_lines().  Lines inserted via this routine are already fully
3250         # adjusted, ready to be processed; each_line_handler()s handlers will
3251         # not be called.  This means this is not a completely general
3252         # facility, as only the last each_line_handler on the stack should
3253         # call this.  It could be made more general, by passing to each of the
3254         # line_handlers their position on the stack, which they would pass on
3255         # to this routine, and that would replace the boolean first element in
3256         # the anonymous array pushed here, so that the next_line routine could
3257         # use that to call only those handlers whose index is after it on the
3258         # stack.  But this is overkill for what is needed now.
3259
3260         my $self = shift;
3261         trace $_[0] if main::DEBUG && $to_trace;
3262
3263         # Each inserted line is an array, with the first element being 1 to
3264         # indicate that this line has been adjusted
3265         no overloading;
3266         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
3267         return;
3268     }
3269
3270     sub get_missings {
3271         # Returns the stored up @missings lines' values, and clears the list.
3272         # The values are in an array, consisting of the default in the first
3273         # element, and the property in the 2nd.  However, since these lines
3274         # can be stacked up, the return is an array of all these arrays.
3275
3276         my $self = shift;
3277         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3278
3279         my $addr = do { no overloading; pack 'J', $self; };
3280
3281         # If not accepting a list return, just return the first one.
3282         return shift @{$missings{$addr}} unless wantarray;
3283
3284         my @return = @{$missings{$addr}};
3285         undef @{$missings{$addr}};
3286         return @return;
3287     }
3288
3289     sub _exclude_unassigned {
3290
3291         # Takes the range in $_ and excludes code points that aren't assigned
3292         # in this release
3293
3294         state $skip_inserted_count = 0;
3295
3296         # Ignore recursive calls.
3297         if ($skip_inserted_count) {
3298             $skip_inserted_count--;
3299             return;
3300         }
3301
3302         # Find what code points are assigned in this release
3303         main::calculate_Assigned() if ! defined $Assigned;
3304
3305         my $self = shift;
3306         my $addr = do { no overloading; pack 'J', $self; };
3307         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3308
3309         my ($range, @remainder)
3310             = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
3311
3312         # Examine the range.
3313         if ($range =~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
3314         {
3315             my $low = hex $1;
3316             my $high = (defined $2) ? hex $2 : $low;
3317
3318             # Split the range into subranges of just those code points in it
3319             # that are assigned.
3320             my @ranges = (Range_List->new(Initialize
3321                               => Range->new($low, $high)) & $Assigned)->ranges;
3322
3323             # Do nothing if nothing in the original range is assigned in this
3324             # release; handle normally if everything is in this release.
3325             if (! @ranges) {
3326                 $_ = "";
3327             }
3328             elsif (@ranges != 1) {
3329
3330                 # Here, some code points in the original range aren't in this
3331                 # release; @ranges gives the ones that are.  Create fake input
3332                 # lines for each of the ranges, and set things up so that when
3333                 # this routine is called on that fake input, it will do
3334                 # nothing.
3335                 $skip_inserted_count = @ranges;
3336                 my $remainder = join ";", @remainder;
3337                 for my $range (@ranges) {
3338                     $self->insert_lines(sprintf("%04X..%04X;%s",
3339                                     $range->start, $range->end, $remainder));
3340                 }
3341                 $_ = "";    # The original range is now defunct.
3342             }
3343         }
3344
3345         return;
3346     }
3347
3348     sub _fixup_obsolete_hanguls {
3349
3350         # This is called only when compiling Unicode version 1.  All Unicode
3351         # data for subsequent releases assumes that the code points that were
3352         # Hangul syllables in this release only are something else, so if
3353         # using such data, we have to override it
3354
3355         my $self = shift;
3356         my $addr = do { no overloading; pack 'J', $self; };
3357         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3358
3359         my $object = main::property_ref($property{$addr});
3360         $object->add_map($FIRST_REMOVED_HANGUL_SYLLABLE,
3361                          $FINAL_REMOVED_HANGUL_SYLLABLE,
3362                          $early{$addr}[3],  # Passed-in value for these
3363                          Replace => $UNCONDITIONALLY);
3364     }
3365
3366     sub _insert_property_into_line {
3367         # Add a property field to $_, if this file requires it.
3368
3369         my $self = shift;
3370         my $addr = do { no overloading; pack 'J', $self; };
3371         my $property = $property{$addr};
3372         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3373
3374         $_ =~ s/(;|$)/; $property$1/;
3375         return;
3376     }
3377
3378     sub carp_bad_line {
3379         # Output consistent error messages, using either a generic one, or the
3380         # one given by the optional parameter.  To avoid gazillions of the
3381         # same message in case the syntax of a  file is way off, this routine
3382         # only outputs the first instance of each message, incrementing a
3383         # count so the totals can be output at the end of the file.
3384
3385         my $self = shift;
3386         my $message = shift;
3387         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3388
3389         my $addr = do { no overloading; pack 'J', $self; };
3390
3391         $message = 'Unexpected line' unless $message;
3392
3393         # No trailing punctuation so as to fit with our addenda.
3394         $message =~ s/[.:;,]$//;
3395
3396         # If haven't seen this exact message before, output it now.  Otherwise
3397         # increment the count of how many times it has occurred
3398         unless ($errors{$addr}->{$message}) {
3399             Carp::my_carp("$message in '$_' in "
3400                             . $file{$addr}
3401                             . " at line $..  Skipping this line;");
3402             $errors{$addr}->{$message} = 1;
3403         }
3404         else {
3405             $errors{$addr}->{$message}++;
3406         }
3407
3408         # Clear the line to prevent any further (meaningful) processing of it.
3409         $_ = "";
3410
3411         return;
3412     }
3413 } # End closure
3414
3415 package Multi_Default;
3416
3417 # Certain properties in early versions of Unicode had more than one possible
3418 # default for code points missing from the files.  In these cases, one
3419 # default applies to everything left over after all the others are applied,
3420 # and for each of the others, there is a description of which class of code
3421 # points applies to it.  This object helps implement this by storing the
3422 # defaults, and for all but that final default, an eval string that generates
3423 # the class that it applies to.
3424
3425
3426 {   # Closure
3427
3428     main::setup_package();
3429
3430     my %class_defaults;
3431     # The defaults structure for the classes
3432     main::set_access('class_defaults', \%class_defaults);
3433
3434     my %other_default;
3435     # The default that applies to everything left over.
3436     main::set_access('other_default', \%other_default, 'r');
3437
3438
3439     sub new {
3440         # The constructor is called with default => eval pairs, terminated by
3441         # the left-over default. e.g.
3442         # Multi_Default->new(
3443         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
3444         #               -  0x200D',
3445         #        'R' => 'some other expression that evaluates to code points',
3446         #        .
3447         #        .
3448         #        .
3449         #        'U'));
3450         # It is best to leave the final value be the one that matches the
3451         # above-Unicode code points.
3452
3453         my $class = shift;
3454
3455         my $self = bless \do{my $anonymous_scalar}, $class;
3456         my $addr = do { no overloading; pack 'J', $self; };
3457
3458         while (@_ > 1) {
3459             my $default = shift;
3460             my $eval = shift;
3461             $class_defaults{$addr}->{$default} = $eval;
3462         }
3463
3464         $other_default{$addr} = shift;
3465
3466         return $self;
3467     }
3468
3469     sub get_next_defaults {
3470         # Iterates and returns the next class of defaults.
3471         my $self = shift;
3472         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3473
3474         my $addr = do { no overloading; pack 'J', $self; };
3475
3476         return each %{$class_defaults{$addr}};
3477     }
3478 }
3479
3480 package Alias;
3481
3482 # An alias is one of the names that a table goes by.  This class defines them
3483 # including some attributes.  Everything is currently setup in the
3484 # constructor.
3485
3486
3487 {   # Closure
3488
3489     main::setup_package();
3490
3491     my %name;
3492     main::set_access('name', \%name, 'r');
3493
3494     my %loose_match;
3495     # Should this name match loosely or not.
3496     main::set_access('loose_match', \%loose_match, 'r');
3497
3498     my %make_re_pod_entry;
3499     # Some aliases should not get their own entries in the re section of the
3500     # pod, because they are covered by a wild-card, and some we want to
3501     # discourage use of.  Binary
3502     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
3503
3504     my %ucd;
3505     # Is this documented to be accessible via Unicode::UCD
3506     main::set_access('ucd', \%ucd, 'r', 's');
3507
3508     my %status;
3509     # Aliases have a status, like deprecated, or even suppressed (which means
3510     # they don't appear in documentation).  Enum
3511     main::set_access('status', \%status, 'r');
3512
3513     my %ok_as_filename;
3514     # Similarly, some aliases should not be considered as usable ones for
3515     # external use, such as file names, or we don't want documentation to
3516     # recommend them.  Boolean
3517     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
3518
3519     sub new {
3520         my $class = shift;
3521
3522         my $self = bless \do { my $anonymous_scalar }, $class;
3523         my $addr = do { no overloading; pack 'J', $self; };
3524
3525         $name{$addr} = shift;
3526         $loose_match{$addr} = shift;
3527         $make_re_pod_entry{$addr} = shift;
3528         $ok_as_filename{$addr} = shift;
3529         $status{$addr} = shift;
3530         $ucd{$addr} = shift;
3531
3532         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3533
3534         # Null names are never ok externally
3535         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
3536
3537         return $self;
3538     }
3539 }
3540
3541 package Range;
3542
3543 # A range is the basic unit for storing code points, and is described in the
3544 # comments at the beginning of the program.  Each range has a starting code
3545 # point; an ending code point (not less than the starting one); a value
3546 # that applies to every code point in between the two end-points, inclusive;
3547 # and an enum type that applies to the value.  The type is for the user's
3548 # convenience, and has no meaning here, except that a non-zero type is
3549 # considered to not obey the normal Unicode rules for having standard forms.
3550 #
3551 # The same structure is used for both map and match tables, even though in the
3552 # latter, the value (and hence type) is irrelevant and could be used as a
3553 # comment.  In map tables, the value is what all the code points in the range
3554 # map to.  Type 0 values have the standardized version of the value stored as
3555 # well, so as to not have to recalculate it a lot.
3556
3557 sub trace { return main::trace(@_); }
3558
3559 {   # Closure
3560
3561     main::setup_package();
3562
3563     my %start;
3564     main::set_access('start', \%start, 'r', 's');
3565
3566     my %end;
3567     main::set_access('end', \%end, 'r', 's');
3568
3569     my %value;
3570     main::set_access('value', \%value, 'r', 's');
3571
3572     my %type;
3573     main::set_access('type', \%type, 'r');
3574
3575     my %standard_form;
3576     # The value in internal standard form.  Defined only if the type is 0.
3577     main::set_access('standard_form', \%standard_form);
3578
3579     # Note that if these fields change, the dump() method should as well
3580
3581     sub new {
3582         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
3583         my $class = shift;
3584
3585         my $self = bless \do { my $anonymous_scalar }, $class;
3586         my $addr = do { no overloading; pack 'J', $self; };
3587
3588         $start{$addr} = shift;
3589         $end{$addr} = shift;
3590
3591         my %args = @_;
3592
3593         my $value = delete $args{'Value'};  # Can be 0
3594         $value = "" unless defined $value;
3595         $value{$addr} = $value;
3596
3597         $type{$addr} = delete $args{'Type'} || 0;
3598
3599         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3600
3601         return $self;
3602     }
3603
3604     use overload
3605         fallback => 0,
3606         qw("") => "_operator_stringify",
3607         "." => \&main::_operator_dot,
3608         ".=" => \&main::_operator_dot_equal,
3609     ;
3610
3611     sub _operator_stringify {
3612         my $self = shift;
3613         my $addr = do { no overloading; pack 'J', $self; };
3614
3615         # Output it like '0041..0065 (value)'
3616         my $return = sprintf("%04X", $start{$addr})
3617                         .  '..'
3618                         . sprintf("%04X", $end{$addr});
3619         my $value = $value{$addr};
3620         my $type = $type{$addr};
3621         $return .= ' (';
3622         $return .= "$value";
3623         $return .= ", Type=$type" if $type != 0;
3624         $return .= ')';
3625
3626         return $return;
3627     }
3628
3629     sub standard_form {
3630         # Calculate the standard form only if needed, and cache the result.
3631         # The standard form is the value itself if the type is special.
3632         # This represents a considerable CPU and memory saving - at the time
3633         # of writing there are 368676 non-special objects, but the standard
3634         # form is only requested for 22047 of them - ie about 6%.
3635
3636         my $self = shift;
3637         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3638
3639         my $addr = do { no overloading; pack 'J', $self; };
3640
3641         return $standard_form{$addr} if defined $standard_form{$addr};
3642
3643         my $value = $value{$addr};
3644         return $value if $type{$addr};
3645         return $standard_form{$addr} = main::standardize($value);
3646     }
3647
3648     sub dump {
3649         # Human, not machine readable.  For machine readable, comment out this
3650         # entire routine and let the standard one take effect.
3651         my $self = shift;
3652         my $indent = shift;
3653         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3654
3655         my $addr = do { no overloading; pack 'J', $self; };
3656
3657         my $return = $indent
3658                     . sprintf("%04X", $start{$addr})
3659                     . '..'
3660                     . sprintf("%04X", $end{$addr})
3661                     . " '$value{$addr}';";
3662         if (! defined $standard_form{$addr}) {
3663             $return .= "(type=$type{$addr})";
3664         }
3665         elsif ($standard_form{$addr} ne $value{$addr}) {
3666             $return .= "(standard '$standard_form{$addr}')";
3667         }
3668         return $return;
3669     }
3670 } # End closure
3671
3672 package _Range_List_Base;
3673
3674 # Base class for range lists.  A range list is simply an ordered list of
3675 # ranges, so that the ranges with the lowest starting numbers are first in it.
3676 #
3677 # When a new range is added that is adjacent to an existing range that has the
3678 # same value and type, it merges with it to form a larger range.
3679 #
3680 # Ranges generally do not overlap, except that there can be multiple entries
3681 # of single code point ranges.  This is because of NameAliases.txt.
3682 #
3683 # In this program, there is a standard value such that if two different
3684 # values, have the same standard value, they are considered equivalent.  This
3685 # value was chosen so that it gives correct results on Unicode data
3686
3687 # There are a number of methods to manipulate range lists, and some operators
3688 # are overloaded to handle them.
3689
3690 sub trace { return main::trace(@_); }
3691
3692 { # Closure
3693
3694     our $addr;
3695
3696     # Max is initialized to a negative value that isn't adjacent to 0, for
3697     # simpler tests
3698     my $max_init = -2;
3699
3700     main::setup_package();
3701
3702     my %ranges;
3703     # The list of ranges
3704     main::set_access('ranges', \%ranges, 'readable_array');
3705
3706     my %max;
3707     # The highest code point in the list.  This was originally a method, but
3708     # actual measurements said it was used a lot.
3709     main::set_access('max', \%max, 'r');
3710
3711     my %each_range_iterator;
3712     # Iterator position for each_range()
3713     main::set_access('each_range_iterator', \%each_range_iterator);
3714
3715     my %owner_name_of;
3716     # Name of parent this is attached to, if any.  Solely for better error
3717     # messages.
3718     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3719
3720     my %_search_ranges_cache;
3721     # A cache of the previous result from _search_ranges(), for better
3722     # performance
3723     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3724
3725     sub new {
3726         my $class = shift;
3727         my %args = @_;
3728
3729         # Optional initialization data for the range list.
3730         my $initialize = delete $args{'Initialize'};
3731
3732         my $self;
3733
3734         # Use _union() to initialize.  _union() returns an object of this
3735         # class, which means that it will call this constructor recursively.
3736         # But it won't have this $initialize parameter so that it won't
3737         # infinitely loop on this.
3738         return _union($class, $initialize, %args) if defined $initialize;
3739
3740         $self = bless \do { my $anonymous_scalar }, $class;
3741         my $addr = do { no overloading; pack 'J', $self; };
3742
3743         # Optional parent object, only for debug info.
3744         $owner_name_of{$addr} = delete $args{'Owner'};
3745         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3746
3747         # Stringify, in case it is an object.
3748         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3749
3750         # This is used only for error messages, and so a colon is added
3751         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3752
3753         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3754
3755         $max{$addr} = $max_init;
3756
3757         $_search_ranges_cache{$addr} = 0;
3758         $ranges{$addr} = [];
3759
3760         return $self;
3761     }
3762
3763     use overload
3764         fallback => 0,
3765         qw("") => "_operator_stringify",
3766         "." => \&main::_operator_dot,
3767         ".=" => \&main::_operator_dot_equal,
3768     ;
3769
3770     sub _operator_stringify {
3771         my $self = shift;
3772         my $addr = do { no overloading; pack 'J', $self; };
3773
3774         return "Range_List attached to '$owner_name_of{$addr}'"
3775                                                 if $owner_name_of{$addr};
3776         return "anonymous Range_List " . \$self;
3777     }
3778
3779     sub _union {
3780         # Returns the union of the input code points.  It can be called as
3781         # either a constructor or a method.  If called as a method, the result
3782         # will be a new() instance of the calling object, containing the union
3783         # of that object with the other parameter's code points;  if called as
3784         # a constructor, the first parameter gives the class that the new object
3785         # should be, and the second parameter gives the code points to go into
3786         # it.
3787         # In either case, there are two parameters looked at by this routine;
3788         # any additional parameters are passed to the new() constructor.
3789         #
3790         # The code points can come in the form of some object that contains
3791         # ranges, and has a conventionally named method to access them; or
3792         # they can be an array of individual code points (as integers); or
3793         # just a single code point.
3794         #
3795         # If they are ranges, this routine doesn't make any effort to preserve
3796         # the range values and types of one input over the other.  Therefore
3797         # this base class should not allow _union to be called from other than
3798         # initialization code, so as to prevent two tables from being added
3799         # together where the range values matter.  The general form of this
3800         # routine therefore belongs in a derived class, but it was moved here
3801         # to avoid duplication of code.  The failure to overload this in this
3802         # class keeps it safe.
3803         #
3804         # It does make the effort during initialization to accept tables with
3805         # multiple values for the same code point, and to preserve the order
3806         # of these.  If there is only one input range or range set, it doesn't
3807         # sort (as it should already be sorted to the desired order), and will
3808         # accept multiple values per code point.  Otherwise it will merge
3809         # multiple values into a single one.
3810
3811         my $self;
3812         my @args;   # Arguments to pass to the constructor
3813
3814         my $class = shift;
3815
3816         # If a method call, will start the union with the object itself, and
3817         # the class of the new object will be the same as self.
3818         if (ref $class) {
3819             $self = $class;
3820             $class = ref $self;
3821             push @args, $self;
3822         }
3823
3824         # Add the other required parameter.
3825         push @args, shift;
3826         # Rest of parameters are passed on to the constructor
3827
3828         # Accumulate all records from both lists.
3829         my @records;
3830         my $input_count = 0;
3831         for my $arg (@args) {
3832             #local $to_trace = 0 if main::DEBUG;
3833             trace "argument = $arg" if main::DEBUG && $to_trace;
3834             if (! defined $arg) {
3835                 my $message = "";
3836                 if (defined $self) {
3837                     no overloading;
3838                     $message .= $owner_name_of{pack 'J', $self};
3839                 }
3840                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3841                 return;
3842             }
3843
3844             $arg = [ $arg ] if ! ref $arg;
3845             my $type = ref $arg;
3846             if ($type eq 'ARRAY') {
3847                 foreach my $element (@$arg) {
3848                     push @records, Range->new($element, $element);
3849                     $input_count++;
3850                 }
3851             }
3852             elsif ($arg->isa('Range')) {
3853                 push @records, $arg;
3854                 $input_count++;
3855             }
3856             elsif ($arg->can('ranges')) {
3857                 push @records, $arg->ranges;
3858                 $input_count++;
3859             }
3860             else {
3861                 my $message = "";
3862                 if (defined $self) {
3863                     no overloading;
3864                     $message .= $owner_name_of{pack 'J', $self};
3865                 }
3866                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3867                 return;
3868             }
3869         }
3870
3871         # Sort with the range containing the lowest ordinal first, but if
3872         # two ranges start at the same code point, sort with the bigger range
3873         # of the two first, because it takes fewer cycles.
3874         if ($input_count > 1) {
3875             @records = sort { ($a->start <=> $b->start)
3876                                       or
3877                                     # if b is shorter than a, b->end will be
3878                                     # less than a->end, and we want to select
3879                                     # a, so want to return -1
3880                                     ($b->end <=> $a->end)
3881                                    } @records;
3882         }
3883
3884         my $new = $class->new(@_);
3885
3886         # Fold in records so long as they add new information.
3887         for my $set (@records) {
3888             my $start = $set->start;
3889             my $end   = $set->end;
3890             my $value = $set->value;
3891             my $type  = $set->type;
3892             if ($start > $new->max) {
3893                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3894             }
3895             elsif ($end > $new->max) {
3896                 $new->_add_delete('+', $new->max +1, $end, $value,
3897                                                                 Type => $type);
3898             }
3899             elsif ($input_count == 1) {
3900                 # Here, overlaps existing range, but is from a single input,
3901                 # so preserve the multiple values from that input.
3902                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3903                                                 Replace => $MULTIPLE_AFTER);
3904             }
3905         }
3906
3907         return $new;
3908     }
3909
3910     sub range_count {        # Return the number of ranges in the range list
3911         my $self = shift;
3912         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3913
3914         no overloading;
3915         return scalar @{$ranges{pack 'J', $self}};
3916     }
3917
3918     sub min {
3919         # Returns the minimum code point currently in the range list, or if
3920         # the range list is empty, 2 beyond the max possible.  This is a
3921         # method because used so rarely, that not worth saving between calls,
3922         # and having to worry about changing it as ranges are added and
3923         # deleted.
3924
3925         my $self = shift;
3926         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3927
3928         my $addr = do { no overloading; pack 'J', $self; };
3929
3930         # If the range list is empty, return a large value that isn't adjacent
3931         # to any that could be in the range list, for simpler tests
3932         return $MAX_WORKING_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3933         return $ranges{$addr}->[0]->start;
3934     }
3935
3936     sub contains {
3937         # Boolean: Is argument in the range list?  If so returns $i such that:
3938         #   range[$i]->end < $codepoint <= range[$i+1]->end
3939         # which is one beyond what you want; this is so that the 0th range
3940         # doesn't return false
3941         my $self = shift;
3942         my $codepoint = shift;
3943         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3944
3945         my $i = $self->_search_ranges($codepoint);
3946         return 0 unless defined $i;
3947
3948         # The search returns $i, such that
3949         #   range[$i-1]->end < $codepoint <= range[$i]->end
3950         # So is in the table if and only iff it is at least the start position
3951         # of range $i.
3952         no overloading;
3953         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3954         return $i + 1;
3955     }
3956
3957     sub containing_range {
3958         # Returns the range object that contains the code point, undef if none
3959
3960         my $self = shift;
3961         my $codepoint = shift;
3962         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3963
3964         my $i = $self->contains($codepoint);
3965         return unless $i;
3966
3967         # contains() returns 1 beyond where we should look
3968         no overloading;
3969         return $ranges{pack 'J', $self}->[$i-1];
3970     }
3971
3972     sub value_of {
3973         # Returns the value associated with the code point, undef if none
3974
3975         my $self = shift;
3976         my $codepoint = shift;
3977         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3978
3979         my $range = $self->containing_range($codepoint);
3980         return unless defined $range;
3981
3982         return $range->value;
3983     }
3984
3985     sub type_of {
3986         # Returns the type of the range containing the code point, undef if
3987         # the code point is not in the table
3988
3989         my $self = shift;
3990         my $codepoint = shift;
3991         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3992
3993         my $range = $self->containing_range($codepoint);
3994         return unless defined $range;
3995
3996         return $range->type;
3997     }
3998
3999     sub _search_ranges {
4000         # Find the range in the list which contains a code point, or where it
4001         # should go if were to add it.  That is, it returns $i, such that:
4002         #   range[$i-1]->end < $codepoint <= range[$i]->end
4003         # Returns undef if no such $i is possible (e.g. at end of table), or
4004         # if there is an error.
4005
4006         my $self = shift;
4007         my $code_point = shift;
4008         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
4009
4010         my $addr = do { no overloading; pack 'J', $self; };
4011
4012         return if $code_point > $max{$addr};
4013         my $r = $ranges{$addr};                # The current list of ranges
4014         my $range_list_size = scalar @$r;
4015         my $i;
4016
4017         use integer;        # want integer division
4018
4019         # Use the cached result as the starting guess for this one, because,
4020         # an experiment on 5.1 showed that 90% of the time the cache was the
4021         # same as the result on the next call (and 7% it was one less).
4022         $i = $_search_ranges_cache{$addr};
4023         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
4024                                             # from an intervening deletion
4025         #local $to_trace =