This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Integrate mainline
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2
3 perlop - Perl operators and precedence
4
5 =head1 SYNOPSIS
6
7 Perl operators have the following associativity and precedence,
8 listed from highest precedence to lowest.  Operators borrowed from
9 C keep the same precedence relationship with each other, even where
10 C's precedence is slightly screwy.  (This makes learning Perl easier
11 for C folks.)  With very few exceptions, these all operate on scalar
12 values only, not array values.
13
14     left        terms and list operators (leftward)
15     left        ->
16     nonassoc    ++ --
17     right       **
18     right       ! ~ \ and unary + and -
19     left        =~ !~
20     left        * / % x
21     left        + - .
22     left        << >>
23     nonassoc    named unary operators
24     nonassoc    < > <= >= lt gt le ge
25     nonassoc    == != <=> eq ne cmp
26     left        &
27     left        | ^
28     left        &&
29     left        ||
30     nonassoc    ..  ...
31     right       ?:
32     right       = += -= *= etc.
33     left        , =>
34     nonassoc    list operators (rightward)
35     right       not
36     left        and
37     left        or xor
38
39 In the following sections, these operators are covered in precedence order.
40
41 Many operators can be overloaded for objects.  See L<overload>.
42
43 =head1 DESCRIPTION
44
45 =head2 Terms and List Operators (Leftward)
46
47 A TERM has the highest precedence in Perl.  They include variables,
48 quote and quote-like operators, any expression in parentheses,
49 and any function whose arguments are parenthesized.  Actually, there
50 aren't really functions in this sense, just list operators and unary
51 operators behaving as functions because you put parentheses around
52 the arguments.  These are all documented in L<perlfunc>.
53
54 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
55 is followed by a left parenthesis as the next token, the operator and
56 arguments within parentheses are taken to be of highest precedence,
57 just like a normal function call.
58
59 In the absence of parentheses, the precedence of list operators such as
60 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
61 whether you are looking at the left side or the right side of the operator.
62 For example, in
63
64     @ary = (1, 3, sort 4, 2);
65     print @ary;         # prints 1324
66
67 the commas on the right of the sort are evaluated before the sort,
68 but the commas on the left are evaluated after.  In other words,
69 list operators tend to gobble up all arguments that follow, and
70 then act like a simple TERM with regard to the preceding expression.
71 Be careful with parentheses:
72
73     # These evaluate exit before doing the print:
74     print($foo, exit);  # Obviously not what you want.
75     print $foo, exit;   # Nor is this.
76
77     # These do the print before evaluating exit:
78     (print $foo), exit; # This is what you want.
79     print($foo), exit;  # Or this.
80     print ($foo), exit; # Or even this.
81
82 Also note that
83
84     print ($foo & 255) + 1, "\n";
85
86 probably doesn't do what you expect at first glance.  See
87 L<Named Unary Operators> for more discussion of this.
88
89 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
90 well as subroutine and method calls, and the anonymous
91 constructors C<[]> and C<{}>.
92
93 See also L<Quote and Quote-like Operators> toward the end of this section,
94 as well as L<"I/O Operators">.
95
96 =head2 The Arrow Operator
97
98 "C<< -> >>" is an infix dereference operator, just as it is in C
99 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
100 C<(...)> subscript, then the left side must be either a hard or
101 symbolic reference to an array, a hash, or a subroutine respectively.
102 (Or technically speaking, a location capable of holding a hard
103 reference, if it's an array or hash reference being used for
104 assignment.)  See L<perlreftut> and L<perlref>.
105
106 Otherwise, the right side is a method name or a simple scalar
107 variable containing either the method name or a subroutine reference,
108 and the left side must be either an object (a blessed reference)
109 or a class name (that is, a package name).  See L<perlobj>.
110
111 =head2 Auto-increment and Auto-decrement
112
113 "++" and "--" work as in C.  That is, if placed before a variable, they
114 increment or decrement the variable before returning the value, and if
115 placed after, increment or decrement the variable after returning the value.
116
117 The auto-increment operator has a little extra builtin magic to it.  If
118 you increment a variable that is numeric, or that has ever been used in
119 a numeric context, you get a normal increment.  If, however, the
120 variable has been used in only string contexts since it was set, and
121 has a value that is not the empty string and matches the pattern
122 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
123 character within its range, with carry:
124
125     print ++($foo = '99');      # prints '100'
126     print ++($foo = 'a0');      # prints 'a1'
127     print ++($foo = 'Az');      # prints 'Ba'
128     print ++($foo = 'zz');      # prints 'aaa'
129
130 The auto-decrement operator is not magical.
131
132 =head2 Exponentiation
133
134 Binary "**" is the exponentiation operator.  It binds even more
135 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
136 implemented using C's pow(3) function, which actually works on doubles
137 internally.)
138
139 =head2 Symbolic Unary Operators
140
141 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
142 precedence version of this.
143
144 Unary "-" performs arithmetic negation if the operand is numeric.  If
145 the operand is an identifier, a string consisting of a minus sign
146 concatenated with the identifier is returned.  Otherwise, if the string
147 starts with a plus or minus, a string starting with the opposite sign
148 is returned.  One effect of these rules is that C<-bareword> is equivalent
149 to C<"-bareword">.
150
151 Unary "~" performs bitwise negation, i.e., 1's complement.  For
152 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
153 L<Bitwise String Operators>.)  Note that the width of the result is
154 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
155 bits wide on a 64-bit platform, so if you are expecting a certain bit
156 width, remember use the & operator to mask off the excess bits.
157
158 Unary "+" has no effect whatsoever, even on strings.  It is useful
159 syntactically for separating a function name from a parenthesized expression
160 that would otherwise be interpreted as the complete list of function
161 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
162
163 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
164 and L<perlref>.  Do not confuse this behavior with the behavior of
165 backslash within a string, although both forms do convey the notion
166 of protecting the next thing from interpolation.
167
168 =head2 Binding Operators
169
170 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
171 search or modify the string $_ by default.  This operator makes that kind
172 of operation work on some other string.  The right argument is a search
173 pattern, substitution, or transliteration.  The left argument is what is
174 supposed to be searched, substituted, or transliterated instead of the default
175 $_.  When used in scalar context, the return value generally indicates the
176 success of the operation.  Behavior in list context depends on the particular
177 operator.  See L</"Regexp Quote-Like Operators"> for details.
178
179 If the right argument is an expression rather than a search pattern,
180 substitution, or transliteration, it is interpreted as a search pattern at run
181 time.  This can be less efficient than an explicit search, because the
182 pattern must be compiled every time the expression is evaluated.
183
184 Binary "!~" is just like "=~" except the return value is negated in
185 the logical sense.
186
187 =head2 Multiplicative Operators
188
189 Binary "*" multiplies two numbers.
190
191 Binary "/" divides two numbers.
192
193 Binary "%" computes the modulus of two numbers.  Given integer
194 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
195 C<$a> minus the largest multiple of C<$b> that is not greater than
196 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
197 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
198 result will be less than or equal to zero). 
199 Note than when C<use integer> is in scope, "%" gives you direct access
200 to the modulus operator as implemented by your C compiler.  This
201 operator is not as well defined for negative operands, but it will
202 execute faster.
203
204 Binary "x" is the repetition operator.  In scalar context or if the left
205 operand is not enclosed in parentheses, it returns a string consisting
206 of the left operand repeated the number of times specified by the right
207 operand.  In list context, if the left operand is enclosed in
208 parentheses, it repeats the list.
209
210     print '-' x 80;             # print row of dashes
211
212     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
213
214     @ones = (1) x 80;           # a list of 80 1's
215     @ones = (5) x @ones;        # set all elements to 5
216
217
218 =head2 Additive Operators
219
220 Binary "+" returns the sum of two numbers.
221
222 Binary "-" returns the difference of two numbers.
223
224 Binary "." concatenates two strings.
225
226 =head2 Shift Operators
227
228 Binary "<<" returns the value of its left argument shifted left by the
229 number of bits specified by the right argument.  Arguments should be
230 integers.  (See also L<Integer Arithmetic>.)
231
232 Binary ">>" returns the value of its left argument shifted right by
233 the number of bits specified by the right argument.  Arguments should
234 be integers.  (See also L<Integer Arithmetic>.)
235
236 =head2 Named Unary Operators
237
238 The various named unary operators are treated as functions with one
239 argument, with optional parentheses.  These include the filetest
240 operators, like C<-f>, C<-M>, etc.  See L<perlfunc>.
241
242 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
243 is followed by a left parenthesis as the next token, the operator and
244 arguments within parentheses are taken to be of highest precedence,
245 just like a normal function call.  Examples:
246
247     chdir $foo    || die;       # (chdir $foo) || die
248     chdir($foo)   || die;       # (chdir $foo) || die
249     chdir ($foo)  || die;       # (chdir $foo) || die
250     chdir +($foo) || die;       # (chdir $foo) || die
251
252 but, because * is higher precedence than ||:
253
254     chdir $foo * 20;    # chdir ($foo * 20)
255     chdir($foo) * 20;   # (chdir $foo) * 20
256     chdir ($foo) * 20;  # (chdir $foo) * 20
257     chdir +($foo) * 20; # chdir ($foo * 20)
258
259     rand 10 * 20;       # rand (10 * 20)
260     rand(10) * 20;      # (rand 10) * 20
261     rand (10) * 20;     # (rand 10) * 20
262     rand +(10) * 20;    # rand (10 * 20)
263
264 See also L<"Terms and List Operators (Leftward)">.
265
266 =head2 Relational Operators
267
268 Binary "<" returns true if the left argument is numerically less than
269 the right argument.
270
271 Binary ">" returns true if the left argument is numerically greater
272 than the right argument.
273
274 Binary "<=" returns true if the left argument is numerically less than
275 or equal to the right argument.
276
277 Binary ">=" returns true if the left argument is numerically greater
278 than or equal to the right argument.
279
280 Binary "lt" returns true if the left argument is stringwise less than
281 the right argument.
282
283 Binary "gt" returns true if the left argument is stringwise greater
284 than the right argument.
285
286 Binary "le" returns true if the left argument is stringwise less than
287 or equal to the right argument.
288
289 Binary "ge" returns true if the left argument is stringwise greater
290 than or equal to the right argument.
291
292 =head2 Equality Operators
293
294 Binary "==" returns true if the left argument is numerically equal to
295 the right argument.
296
297 Binary "!=" returns true if the left argument is numerically not equal
298 to the right argument.
299
300 Binary "<=>" returns -1, 0, or 1 depending on whether the left
301 argument is numerically less than, equal to, or greater than the right
302 argument.  If your platform supports NaNs (not-a-numbers) as numeric
303 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
304 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
305 returns true, as does NaN != anything else. If your platform doesn't
306 support NaNs then NaN is just a string with numeric value 0.
307
308     perl -le '$a = NaN; print "No NaN support here" if $a == $a'
309     perl -le '$a = NaN; print "NaN support here" if $a != $a'
310
311 Binary "eq" returns true if the left argument is stringwise equal to
312 the right argument.
313
314 Binary "ne" returns true if the left argument is stringwise not equal
315 to the right argument.
316
317 Binary "cmp" returns -1, 0, or 1 depending on whether the left
318 argument is stringwise less than, equal to, or greater than the right
319 argument.
320
321 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
322 by the current locale if C<use locale> is in effect.  See L<perllocale>.
323
324 =head2 Bitwise And
325
326 Binary "&" returns its operators ANDed together bit by bit.
327 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
328
329 =head2 Bitwise Or and Exclusive Or
330
331 Binary "|" returns its operators ORed together bit by bit.
332 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
333
334 Binary "^" returns its operators XORed together bit by bit.
335 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
336
337 =head2 C-style Logical And
338
339 Binary "&&" performs a short-circuit logical AND operation.  That is,
340 if the left operand is false, the right operand is not even evaluated.
341 Scalar or list context propagates down to the right operand if it
342 is evaluated.
343
344 =head2 C-style Logical Or
345
346 Binary "||" performs a short-circuit logical OR operation.  That is,
347 if the left operand is true, the right operand is not even evaluated.
348 Scalar or list context propagates down to the right operand if it
349 is evaluated.
350
351 The C<||> and C<&&> operators differ from C's in that, rather than returning
352 0 or 1, they return the last value evaluated.  Thus, a reasonably portable
353 way to find out the home directory (assuming it's not "0") might be:
354
355     $home = $ENV{'HOME'} || $ENV{'LOGDIR'} ||
356         (getpwuid($<))[7] || die "You're homeless!\n";
357
358 In particular, this means that you shouldn't use this
359 for selecting between two aggregates for assignment:
360
361     @a = @b || @c;              # this is wrong
362     @a = scalar(@b) || @c;      # really meant this
363     @a = @b ? @b : @c;          # this works fine, though
364
365 As more readable alternatives to C<&&> and C<||> when used for
366 control flow, Perl provides C<and> and C<or> operators (see below).
367 The short-circuit behavior is identical.  The precedence of "and" and
368 "or" is much lower, however, so that you can safely use them after a
369 list operator without the need for parentheses:
370
371     unlink "alpha", "beta", "gamma"
372             or gripe(), next LINE;
373
374 With the C-style operators that would have been written like this:
375
376     unlink("alpha", "beta", "gamma")
377             || (gripe(), next LINE);
378
379 Using "or" for assignment is unlikely to do what you want; see below.
380
381 =head2 Range Operators
382
383 Binary ".." is the range operator, which is really two different
384 operators depending on the context.  In list context, it returns an
385 array of values counting (up by ones) from the left value to the right
386 value.  If the left value is greater than the right value then it
387 returns the empty array.  The range operator is useful for writing
388 C<foreach (1..10)> loops and for doing slice operations on arrays.  In
389 the current implementation, no temporary array is created when the
390 range operator is used as the expression in C<foreach> loops, but older
391 versions of Perl might burn a lot of memory when you write something
392 like this:
393
394     for (1 .. 1_000_000) {
395         # code
396     }
397
398 In scalar context, ".." returns a boolean value.  The operator is
399 bistable, like a flip-flop, and emulates the line-range (comma) operator
400 of B<sed>, B<awk>, and various editors.  Each ".." operator maintains its
401 own boolean state.  It is false as long as its left operand is false.
402 Once the left operand is true, the range operator stays true until the
403 right operand is true, I<AFTER> which the range operator becomes false
404 again.  It doesn't become false till the next time the range operator is
405 evaluated.  It can test the right operand and become false on the same
406 evaluation it became true (as in B<awk>), but it still returns true once.
407 If you don't want it to test the right operand till the next
408 evaluation, as in B<sed>, just use three dots ("...") instead of
409 two.  In all other regards, "..." behaves just like ".." does.
410
411 The right operand is not evaluated while the operator is in the
412 "false" state, and the left operand is not evaluated while the
413 operator is in the "true" state.  The precedence is a little lower
414 than || and &&.  The value returned is either the empty string for
415 false, or a sequence number (beginning with 1) for true.  The
416 sequence number is reset for each range encountered.  The final
417 sequence number in a range has the string "E0" appended to it, which
418 doesn't affect its numeric value, but gives you something to search
419 for if you want to exclude the endpoint.  You can exclude the
420 beginning point by waiting for the sequence number to be greater
421 than 1.  If either operand of scalar ".." is a constant expression,
422 that operand is implicitly compared to the C<$.> variable, the
423 current line number.  Examples:
424
425 As a scalar operator:
426
427     if (101 .. 200) { print; }  # print 2nd hundred lines
428     next line if (1 .. /^$/);   # skip header lines
429     s/^/> / if (/^$/ .. eof()); # quote body
430
431     # parse mail messages
432     while (<>) {
433         $in_header =   1  .. /^$/;
434         $in_body   = /^$/ .. eof();
435         # do something based on those
436     } continue {
437         close ARGV if eof;              # reset $. each file
438     }
439
440 As a list operator:
441
442     for (101 .. 200) { print; } # print $_ 100 times
443     @foo = @foo[0 .. $#foo];    # an expensive no-op
444     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
445
446 The range operator (in list context) makes use of the magical
447 auto-increment algorithm if the operands are strings.  You
448 can say
449
450     @alphabet = ('A' .. 'Z');
451
452 to get all normal letters of the alphabet, or
453
454     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
455
456 to get a hexadecimal digit, or
457
458     @z2 = ('01' .. '31');  print $z2[$mday];
459
460 to get dates with leading zeros.  If the final value specified is not
461 in the sequence that the magical increment would produce, the sequence
462 goes until the next value would be longer than the final value
463 specified.
464
465 =head2 Conditional Operator
466
467 Ternary "?:" is the conditional operator, just as in C.  It works much
468 like an if-then-else.  If the argument before the ? is true, the
469 argument before the : is returned, otherwise the argument after the :
470 is returned.  For example:
471
472     printf "I have %d dog%s.\n", $n,
473             ($n == 1) ? '' : "s";
474
475 Scalar or list context propagates downward into the 2nd
476 or 3rd argument, whichever is selected.
477
478     $a = $ok ? $b : $c;  # get a scalar
479     @a = $ok ? @b : @c;  # get an array
480     $a = $ok ? @b : @c;  # oops, that's just a count!
481
482 The operator may be assigned to if both the 2nd and 3rd arguments are
483 legal lvalues (meaning that you can assign to them):
484
485     ($a_or_b ? $a : $b) = $c;
486
487 Because this operator produces an assignable result, using assignments
488 without parentheses will get you in trouble.  For example, this:
489
490     $a % 2 ? $a += 10 : $a += 2
491
492 Really means this:
493
494     (($a % 2) ? ($a += 10) : $a) += 2
495
496 Rather than this:
497
498     ($a % 2) ? ($a += 10) : ($a += 2)
499
500 That should probably be written more simply as:
501
502     $a += ($a % 2) ? 10 : 2;
503
504 =head2 Assignment Operators
505
506 "=" is the ordinary assignment operator.
507
508 Assignment operators work as in C.  That is,
509
510     $a += 2;
511
512 is equivalent to
513
514     $a = $a + 2;
515
516 although without duplicating any side effects that dereferencing the lvalue
517 might trigger, such as from tie().  Other assignment operators work similarly.
518 The following are recognized:
519
520     **=    +=    *=    &=    <<=    &&=
521            -=    /=    |=    >>=    ||=
522            .=    %=    ^=
523                  x=
524
525 Although these are grouped by family, they all have the precedence
526 of assignment.
527
528 Unlike in C, the scalar assignment operator produces a valid lvalue.
529 Modifying an assignment is equivalent to doing the assignment and
530 then modifying the variable that was assigned to.  This is useful
531 for modifying a copy of something, like this:
532
533     ($tmp = $global) =~ tr [A-Z] [a-z];
534
535 Likewise,
536
537     ($a += 2) *= 3;
538
539 is equivalent to
540
541     $a += 2;
542     $a *= 3;
543
544 Similarly, a list assignment in list context produces the list of
545 lvalues assigned to, and a list assignment in scalar context returns
546 the number of elements produced by the expression on the right hand
547 side of the assignment.
548
549 =head2 Comma Operator
550
551 Binary "," is the comma operator.  In scalar context it evaluates
552 its left argument, throws that value away, then evaluates its right
553 argument and returns that value.  This is just like C's comma operator.
554
555 In list context, it's just the list argument separator, and inserts
556 both its arguments into the list.
557
558 The => digraph is mostly just a synonym for the comma operator.  It's useful for
559 documenting arguments that come in pairs.  As of release 5.001, it also forces
560 any word to the left of it to be interpreted as a string.
561
562 =head2 List Operators (Rightward)
563
564 On the right side of a list operator, it has very low precedence,
565 such that it controls all comma-separated expressions found there.
566 The only operators with lower precedence are the logical operators
567 "and", "or", and "not", which may be used to evaluate calls to list
568 operators without the need for extra parentheses:
569
570     open HANDLE, "filename"
571         or die "Can't open: $!\n";
572
573 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
574
575 =head2 Logical Not
576
577 Unary "not" returns the logical negation of the expression to its right.
578 It's the equivalent of "!" except for the very low precedence.
579
580 =head2 Logical And
581
582 Binary "and" returns the logical conjunction of the two surrounding
583 expressions.  It's equivalent to && except for the very low
584 precedence.  This means that it short-circuits: i.e., the right
585 expression is evaluated only if the left expression is true.
586
587 =head2 Logical or and Exclusive Or
588
589 Binary "or" returns the logical disjunction of the two surrounding
590 expressions.  It's equivalent to || except for the very low precedence.
591 This makes it useful for control flow
592
593     print FH $data              or die "Can't write to FH: $!";
594
595 This means that it short-circuits: i.e., the right expression is evaluated
596 only if the left expression is false.  Due to its precedence, you should
597 probably avoid using this for assignment, only for control flow.
598
599     $a = $b or $c;              # bug: this is wrong
600     ($a = $b) or $c;            # really means this
601     $a = $b || $c;              # better written this way
602
603 However, when it's a list-context assignment and you're trying to use
604 "||" for control flow, you probably need "or" so that the assignment
605 takes higher precedence.
606
607     @info = stat($file) || die;     # oops, scalar sense of stat!
608     @info = stat($file) or die;     # better, now @info gets its due
609
610 Then again, you could always use parentheses. 
611
612 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
613 It cannot short circuit, of course.
614
615 =head2 C Operators Missing From Perl
616
617 Here is what C has that Perl doesn't:
618
619 =over 8
620
621 =item unary &
622
623 Address-of operator.  (But see the "\" operator for taking a reference.)
624
625 =item unary *
626
627 Dereference-address operator. (Perl's prefix dereferencing
628 operators are typed: $, @, %, and &.)
629
630 =item (TYPE)
631
632 Type-casting operator.
633
634 =back
635
636 =head2 Quote and Quote-like Operators
637
638 While we usually think of quotes as literal values, in Perl they
639 function as operators, providing various kinds of interpolating and
640 pattern matching capabilities.  Perl provides customary quote characters
641 for these behaviors, but also provides a way for you to choose your
642 quote character for any of them.  In the following table, a C<{}> represents
643 any pair of delimiters you choose.  
644
645     Customary  Generic        Meaning        Interpolates
646         ''       q{}          Literal             no
647         ""      qq{}          Literal             yes
648         ``      qx{}          Command             yes (unless '' is delimiter)
649                 qw{}         Word list            no
650         //       m{}       Pattern match          yes (unless '' is delimiter)
651                 qr{}          Pattern             yes (unless '' is delimiter)
652                  s{}{}      Substitution          yes (unless '' is delimiter)
653                 tr{}{}    Transliteration         no (but see below)
654
655 Non-bracketing delimiters use the same character fore and aft, but the four
656 sorts of brackets (round, angle, square, curly) will all nest, which means
657 that 
658
659         q{foo{bar}baz} 
660
661 is the same as 
662
663         'foo{bar}baz'
664
665 Note, however, that this does not always work for quoting Perl code:
666
667         $s = q{ if($a eq "}") ... }; # WRONG
668
669 is a syntax error. The C<Text::Balanced> module on CPAN is able to do this
670 properly.
671
672 There can be whitespace between the operator and the quoting
673 characters, except when C<#> is being used as the quoting character.
674 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
675 operator C<q> followed by a comment.  Its argument will be taken
676 from the next line.  This allows you to write:
677
678     s {foo}  # Replace foo
679       {bar}  # with bar.
680
681 For constructs that do interpolate, variables beginning with "C<$>"
682 or "C<@>" are interpolated, as are the following escape sequences.  Within
683 a transliteration, the first eleven of these sequences may be used.
684
685     \t          tab             (HT, TAB)
686     \n          newline         (NL)
687     \r          return          (CR)
688     \f          form feed       (FF)
689     \b          backspace       (BS)
690     \a          alarm (bell)    (BEL)
691     \e          escape          (ESC)
692     \033        octal char      (ESC)
693     \x1b        hex char        (ESC)
694     \x{263a}    wide hex char   (SMILEY)
695     \c[         control char    (ESC)
696     \N{name}    named char
697
698     \l          lowercase next char
699     \u          uppercase next char
700     \L          lowercase till \E
701     \U          uppercase till \E
702     \E          end case modification
703     \Q          quote non-word characters till \E
704
705 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
706 and C<\U> is taken from the current locale.  See L<perllocale>.  For
707 documentation of C<\N{name}>, see L<charnames>.
708
709 All systems use the virtual C<"\n"> to represent a line terminator,
710 called a "newline".  There is no such thing as an unvarying, physical
711 newline character.  It is only an illusion that the operating system,
712 device drivers, C libraries, and Perl all conspire to preserve.  Not all
713 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
714 on a Mac, these are reversed, and on systems without line terminator,
715 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
716 you mean a "newline" for your system, but use the literal ASCII when you
717 need an exact character.  For example, most networking protocols expect
718 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
719 and although they often accept just C<"\012">, they seldom tolerate just
720 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
721 you may be burned some day.
722
723 You cannot include a literal C<$> or C<@> within a C<\Q> sequence. 
724 An unescaped C<$> or C<@> interpolates the corresponding variable, 
725 while escaping will cause the literal string C<\$> to be inserted.
726 You'll need to write something like C<m/\Quser\E\@\Qhost/>. 
727
728 Patterns are subject to an additional level of interpretation as a
729 regular expression.  This is done as a second pass, after variables are
730 interpolated, so that regular expressions may be incorporated into the
731 pattern from the variables.  If this is not what you want, use C<\Q> to
732 interpolate a variable literally.
733
734 Apart from the behavior described above, Perl does not expand
735 multiple levels of interpolation.  In particular, contrary to the
736 expectations of shell programmers, back-quotes do I<NOT> interpolate
737 within double quotes, nor do single quotes impede evaluation of
738 variables when used within double quotes.
739
740 =head2 Regexp Quote-Like Operators
741
742 Here are the quote-like operators that apply to pattern
743 matching and related activities.
744
745 =over 8
746
747 =item ?PATTERN?
748
749 This is just like the C</pattern/> search, except that it matches only
750 once between calls to the reset() operator.  This is a useful
751 optimization when you want to see only the first occurrence of
752 something in each file of a set of files, for instance.  Only C<??>
753 patterns local to the current package are reset.
754
755     while (<>) {
756         if (?^$?) {
757                             # blank line between header and body
758         }
759     } continue {
760         reset if eof;       # clear ?? status for next file
761     }
762
763 This usage is vaguely depreciated, which means it just might possibly
764 be removed in some distant future version of Perl, perhaps somewhere
765 around the year 2168.
766
767 =item m/PATTERN/cgimosx
768
769 =item /PATTERN/cgimosx
770
771 Searches a string for a pattern match, and in scalar context returns
772 true if it succeeds, false if it fails.  If no string is specified
773 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
774 string specified with C<=~> need not be an lvalue--it may be the
775 result of an expression evaluation, but remember the C<=~> binds
776 rather tightly.)  See also L<perlre>.  See L<perllocale> for
777 discussion of additional considerations that apply when C<use locale>
778 is in effect.
779
780 Options are:
781
782     c   Do not reset search position on a failed match when /g is in effect.
783     g   Match globally, i.e., find all occurrences.
784     i   Do case-insensitive pattern matching.
785     m   Treat string as multiple lines.
786     o   Compile pattern only once.
787     s   Treat string as single line.
788     x   Use extended regular expressions.
789
790 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
791 you can use any pair of non-alphanumeric, non-whitespace characters 
792 as delimiters.  This is particularly useful for matching path names
793 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
794 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
795 If "'" is the delimiter, no interpolation is performed on the PATTERN.
796
797 PATTERN may contain variables, which will be interpolated (and the
798 pattern recompiled) every time the pattern search is evaluated, except
799 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
800 C<$|> are not interpolated because they look like end-of-string tests.)
801 If you want such a pattern to be compiled only once, add a C</o> after
802 the trailing delimiter.  This avoids expensive run-time recompilations,
803 and is useful when the value you are interpolating won't change over
804 the life of the script.  However, mentioning C</o> constitutes a promise
805 that you won't change the variables in the pattern.  If you change them,
806 Perl won't even notice.  See also L<"qr/STRING/imosx">.
807
808 If the PATTERN evaluates to the empty string, the last
809 I<successfully> matched regular expression is used instead.
810
811 If the C</g> option is not used, C<m//> in list context returns a
812 list consisting of the subexpressions matched by the parentheses in the
813 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
814 also set, and that this differs from Perl 4's behavior.)  When there are
815 no parentheses in the pattern, the return value is the list C<(1)> for
816 success.  With or without parentheses, an empty list is returned upon
817 failure.
818
819 Examples:
820
821     open(TTY, '/dev/tty');
822     <TTY> =~ /^y/i && foo();    # do foo if desired
823
824     if (/Version: *([0-9.]*)/) { $version = $1; }
825
826     next if m#^/usr/spool/uucp#;
827
828     # poor man's grep
829     $arg = shift;
830     while (<>) {
831         print if /$arg/o;       # compile only once
832     }
833
834     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
835
836 This last example splits $foo into the first two words and the
837 remainder of the line, and assigns those three fields to $F1, $F2, and
838 $Etc.  The conditional is true if any variables were assigned, i.e., if
839 the pattern matched.
840
841 The C</g> modifier specifies global pattern matching--that is,
842 matching as many times as possible within the string.  How it behaves
843 depends on the context.  In list context, it returns a list of the
844 substrings matched by any capturing parentheses in the regular
845 expression.  If there are no parentheses, it returns a list of all
846 the matched strings, as if there were parentheses around the whole
847 pattern.
848
849 In scalar context, each execution of C<m//g> finds the next match,
850 returning true if it matches, and false if there is no further match.
851 The position after the last match can be read or set using the pos()
852 function; see L<perlfunc/pos>.   A failed match normally resets the
853 search position to the beginning of the string, but you can avoid that
854 by adding the C</c> modifier (e.g. C<m//gc>).  Modifying the target
855 string also resets the search position.
856
857 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
858 zero-width assertion that matches the exact position where the previous
859 C<m//g>, if any, left off.  Without the C</g> modifier, the C<\G> assertion
860 still anchors at pos(), but the match is of course only attempted once.
861 Using C<\G> without C</g> on a target string that has not previously had a
862 C</g> match applied to it is the same as using the C<\A> assertion to match
863 the beginning of the string.
864
865 Examples:
866
867     # list context
868     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
869
870     # scalar context
871     $/ = "";
872     while (defined($paragraph = <>)) {
873         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
874             $sentences++;
875         }
876     }
877     print "$sentences\n";
878
879     # using m//gc with \G
880     $_ = "ppooqppqq";
881     while ($i++ < 2) {
882         print "1: '";
883         print $1 while /(o)/gc; print "', pos=", pos, "\n";
884         print "2: '";
885         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
886         print "3: '";
887         print $1 while /(p)/gc; print "', pos=", pos, "\n";
888     }
889     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
890
891 The last example should print:
892
893     1: 'oo', pos=4
894     2: 'q', pos=5
895     3: 'pp', pos=7
896     1: '', pos=7
897     2: 'q', pos=8
898     3: '', pos=8
899     Final: 'q', pos=8
900
901 Notice that the final match matched C<q> instead of C<p>, which a match
902 without the C<\G> anchor would have done. Also note that the final match
903 did not update C<pos> -- C<pos> is only updated on a C</g> match. If the
904 final match did indeed match C<p>, it's a good bet that you're running an
905 older (pre-5.6.0) Perl.
906
907 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
908 combine several regexps like this to process a string part-by-part,
909 doing different actions depending on which regexp matched.  Each
910 regexp tries to match where the previous one leaves off.
911
912  $_ = <<'EOL';
913       $url = new URI::URL "http://www/";   die if $url eq "xXx";
914  EOL
915  LOOP:
916     {
917       print(" digits"),         redo LOOP if /\G\d+\b[,.;]?\s*/gc;
918       print(" lowercase"),      redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
919       print(" UPPERCASE"),      redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
920       print(" Capitalized"),    redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
921       print(" MiXeD"),          redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
922       print(" alphanumeric"),   redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
923       print(" line-noise"),     redo LOOP if /\G[^A-Za-z0-9]+/gc;
924       print ". That's all!\n";
925     }
926
927 Here is the output (split into several lines):
928
929  line-noise lowercase line-noise lowercase UPPERCASE line-noise
930  UPPERCASE line-noise lowercase line-noise lowercase line-noise
931  lowercase lowercase line-noise lowercase lowercase line-noise
932  MiXeD line-noise. That's all!
933
934 =item q/STRING/
935
936 =item C<'STRING'>
937
938 A single-quoted, literal string.  A backslash represents a backslash
939 unless followed by the delimiter or another backslash, in which case
940 the delimiter or backslash is interpolated.
941
942     $foo = q!I said, "You said, 'She said it.'"!;
943     $bar = q('This is it.');
944     $baz = '\n';                # a two-character string
945
946 =item qq/STRING/
947
948 =item "STRING"
949
950 A double-quoted, interpolated string.
951
952     $_ .= qq
953      (*** The previous line contains the naughty word "$1".\n)
954                 if /\b(tcl|java|python)\b/i;      # :-)
955     $baz = "\n";                # a one-character string
956
957 =item qr/STRING/imosx
958
959 This operator quotes (and possibly compiles) its I<STRING> as a regular
960 expression.  I<STRING> is interpolated the same way as I<PATTERN>
961 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
962 is done.  Returns a Perl value which may be used instead of the
963 corresponding C</STRING/imosx> expression.
964
965 For example,
966
967     $rex = qr/my.STRING/is;
968     s/$rex/foo/;
969
970 is equivalent to
971
972     s/my.STRING/foo/is;
973
974 The result may be used as a subpattern in a match:
975
976     $re = qr/$pattern/;
977     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
978     $string =~ $re;             # or used standalone
979     $string =~ /$re/;           # or this way
980
981 Since Perl may compile the pattern at the moment of execution of qr()
982 operator, using qr() may have speed advantages in some situations,
983 notably if the result of qr() is used standalone:
984
985     sub match {
986         my $patterns = shift;
987         my @compiled = map qr/$_/i, @$patterns;
988         grep {
989             my $success = 0;
990             foreach my $pat (@compiled) {
991                 $success = 1, last if /$pat/;
992             }
993             $success;
994         } @_;
995     }
996
997 Precompilation of the pattern into an internal representation at
998 the moment of qr() avoids a need to recompile the pattern every
999 time a match C</$pat/> is attempted.  (Perl has many other internal
1000 optimizations, but none would be triggered in the above example if
1001 we did not use qr() operator.)
1002
1003 Options are:
1004
1005     i   Do case-insensitive pattern matching.
1006     m   Treat string as multiple lines.
1007     o   Compile pattern only once.
1008     s   Treat string as single line.
1009     x   Use extended regular expressions.
1010
1011 See L<perlre> for additional information on valid syntax for STRING, and
1012 for a detailed look at the semantics of regular expressions.
1013
1014 =item qx/STRING/
1015
1016 =item `STRING`
1017
1018 A string which is (possibly) interpolated and then executed as a
1019 system command with C</bin/sh> or its equivalent.  Shell wildcards,
1020 pipes, and redirections will be honored.  The collected standard
1021 output of the command is returned; standard error is unaffected.  In
1022 scalar context, it comes back as a single (potentially multi-line)
1023 string, or undef if the command failed.  In list context, returns a
1024 list of lines (however you've defined lines with $/ or
1025 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
1026
1027 Because backticks do not affect standard error, use shell file descriptor
1028 syntax (assuming the shell supports this) if you care to address this.
1029 To capture a command's STDERR and STDOUT together:
1030
1031     $output = `cmd 2>&1`;
1032
1033 To capture a command's STDOUT but discard its STDERR:
1034
1035     $output = `cmd 2>/dev/null`;
1036
1037 To capture a command's STDERR but discard its STDOUT (ordering is
1038 important here):
1039
1040     $output = `cmd 2>&1 1>/dev/null`;
1041
1042 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1043 but leave its STDOUT to come out the old STDERR:
1044
1045     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1046
1047 To read both a command's STDOUT and its STDERR separately, it's easiest
1048 and safest to redirect them separately to files, and then read from those
1049 files when the program is done:
1050
1051     system("program args 1>/tmp/program.stdout 2>/tmp/program.stderr");
1052
1053 Using single-quote as a delimiter protects the command from Perl's
1054 double-quote interpolation, passing it on to the shell instead:
1055
1056     $perl_info  = qx(ps $$);            # that's Perl's $$
1057     $shell_info = qx'ps $$';            # that's the new shell's $$
1058
1059 How that string gets evaluated is entirely subject to the command
1060 interpreter on your system.  On most platforms, you will have to protect
1061 shell metacharacters if you want them treated literally.  This is in
1062 practice difficult to do, as it's unclear how to escape which characters.
1063 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1064 to emulate backticks safely.
1065
1066 On some platforms (notably DOS-like ones), the shell may not be
1067 capable of dealing with multiline commands, so putting newlines in
1068 the string may not get you what you want.  You may be able to evaluate
1069 multiple commands in a single line by separating them with the command
1070 separator character, if your shell supports that (e.g. C<;> on many Unix
1071 shells; C<&> on the Windows NT C<cmd> shell).
1072
1073 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1074 output before starting the child process, but this may not be supported
1075 on some platforms (see L<perlport>).  To be safe, you may need to set
1076 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1077 C<IO::Handle> on any open handles.
1078
1079 Beware that some command shells may place restrictions on the length
1080 of the command line.  You must ensure your strings don't exceed this
1081 limit after any necessary interpolations.  See the platform-specific
1082 release notes for more details about your particular environment.
1083
1084 Using this operator can lead to programs that are difficult to port,
1085 because the shell commands called vary between systems, and may in
1086 fact not be present at all.  As one example, the C<type> command under
1087 the POSIX shell is very different from the C<type> command under DOS.
1088 That doesn't mean you should go out of your way to avoid backticks
1089 when they're the right way to get something done.  Perl was made to be
1090 a glue language, and one of the things it glues together is commands.
1091 Just understand what you're getting yourself into.
1092
1093 See L<"I/O Operators"> for more discussion.
1094
1095 =item qw/STRING/
1096
1097 Evaluates to a list of the words extracted out of STRING, using embedded
1098 whitespace as the word delimiters.  It can be understood as being roughly
1099 equivalent to:
1100
1101     split(' ', q/STRING/);
1102
1103 the difference being that it generates a real list at compile time.  So
1104 this expression:
1105
1106     qw(foo bar baz)
1107
1108 is semantically equivalent to the list:
1109
1110     'foo', 'bar', 'baz'
1111
1112 Some frequently seen examples:
1113
1114     use POSIX qw( setlocale localeconv )
1115     @EXPORT = qw( foo bar baz );
1116
1117 A common mistake is to try to separate the words with comma or to
1118 put comments into a multi-line C<qw>-string.  For this reason, the
1119 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable) 
1120 produces warnings if the STRING contains the "," or the "#" character.
1121
1122 =item s/PATTERN/REPLACEMENT/egimosx
1123
1124 Searches a string for a pattern, and if found, replaces that pattern
1125 with the replacement text and returns the number of substitutions
1126 made.  Otherwise it returns false (specifically, the empty string).
1127
1128 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1129 variable is searched and modified.  (The string specified with C<=~> must
1130 be scalar variable, an array element, a hash element, or an assignment
1131 to one of those, i.e., an lvalue.)
1132
1133 If the delimiter chosen is a single quote, no interpolation is
1134 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1135 PATTERN contains a $ that looks like a variable rather than an
1136 end-of-string test, the variable will be interpolated into the pattern
1137 at run-time.  If you want the pattern compiled only once the first time
1138 the variable is interpolated, use the C</o> option.  If the pattern
1139 evaluates to the empty string, the last successfully executed regular
1140 expression is used instead.  See L<perlre> for further explanation on these.
1141 See L<perllocale> for discussion of additional considerations that apply
1142 when C<use locale> is in effect.
1143
1144 Options are:
1145
1146     e   Evaluate the right side as an expression.
1147     g   Replace globally, i.e., all occurrences.
1148     i   Do case-insensitive pattern matching.
1149     m   Treat string as multiple lines.
1150     o   Compile pattern only once.
1151     s   Treat string as single line.
1152     x   Use extended regular expressions.
1153
1154 Any non-alphanumeric, non-whitespace delimiter may replace the
1155 slashes.  If single quotes are used, no interpretation is done on the
1156 replacement string (the C</e> modifier overrides this, however).  Unlike
1157 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
1158 text is not evaluated as a command.  If the
1159 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
1160 pair of quotes, which may or may not be bracketing quotes, e.g.,
1161 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
1162 replacement portion to be treated as a full-fledged Perl expression
1163 and evaluated right then and there.  It is, however, syntax checked at
1164 compile-time. A second C<e> modifier will cause the replacement portion
1165 to be C<eval>ed before being run as a Perl expression.
1166
1167 Examples:
1168
1169     s/\bgreen\b/mauve/g;                # don't change wintergreen
1170
1171     $path =~ s|/usr/bin|/usr/local/bin|;
1172
1173     s/Login: $foo/Login: $bar/; # run-time pattern
1174
1175     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1176
1177     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1178
1179     $_ = 'abc123xyz';
1180     s/\d+/$&*2/e;               # yields 'abc246xyz'
1181     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1182     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1183
1184     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1185     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1186     s/^=(\w+)/&pod($1)/ge;      # use function call
1187
1188     # expand variables in $_, but dynamics only, using
1189     # symbolic dereferencing
1190     s/\$(\w+)/${$1}/g;
1191
1192     # Add one to the value of any numbers in the string
1193     s/(\d+)/1 + $1/eg;
1194
1195     # This will expand any embedded scalar variable
1196     # (including lexicals) in $_ : First $1 is interpolated
1197     # to the variable name, and then evaluated
1198     s/(\$\w+)/$1/eeg;
1199
1200     # Delete (most) C comments.
1201     $program =~ s {
1202         /\*     # Match the opening delimiter.
1203         .*?     # Match a minimal number of characters.
1204         \*/     # Match the closing delimiter.
1205     } []gsx;
1206
1207     s/^\s*(.*?)\s*$/$1/;        # trim white space in $_, expensively
1208
1209     for ($variable) {           # trim white space in $variable, cheap
1210         s/^\s+//;
1211         s/\s+$//;
1212     }
1213
1214     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1215
1216 Note the use of $ instead of \ in the last example.  Unlike
1217 B<sed>, we use the \<I<digit>> form in only the left hand side.
1218 Anywhere else it's $<I<digit>>.
1219
1220 Occasionally, you can't use just a C</g> to get all the changes
1221 to occur that you might want.  Here are two common cases:
1222
1223     # put commas in the right places in an integer
1224     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;  
1225
1226     # expand tabs to 8-column spacing
1227     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1228
1229 =item tr/SEARCHLIST/REPLACEMENTLIST/cds
1230
1231 =item y/SEARCHLIST/REPLACEMENTLIST/cds
1232
1233 Transliterates all occurrences of the characters found in the search list
1234 with the corresponding character in the replacement list.  It returns
1235 the number of characters replaced or deleted.  If no string is
1236 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1237 string specified with =~ must be a scalar variable, an array element, a
1238 hash element, or an assignment to one of those, i.e., an lvalue.)
1239
1240 A character range may be specified with a hyphen, so C<tr/A-J/0-9/> 
1241 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1242 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1243 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1244 its own pair of quotes, which may or may not be bracketing quotes,
1245 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1246
1247 Note that C<tr> does B<not> do regular expression character classes
1248 such as C<\d> or C<[:lower:]>.  The <tr> operator is not equivalent to
1249 the tr(1) utility.  If you want to map strings between lower/upper
1250 cases, see L<perlfunc/lc> and L<perlfunc/uc>, and in general consider
1251 using the C<s> operator if you need regular expressions.
1252
1253 Note also that the whole range idea is rather unportable between
1254 character sets--and even within character sets they may cause results
1255 you probably didn't expect.  A sound principle is to use only ranges
1256 that begin from and end at either alphabets of equal case (a-e, A-E),
1257 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1258 character sets in full.
1259
1260 Options:
1261
1262     c   Complement the SEARCHLIST.
1263     d   Delete found but unreplaced characters.
1264     s   Squash duplicate replaced characters.
1265
1266 If the C</c> modifier is specified, the SEARCHLIST character set
1267 is complemented.  If the C</d> modifier is specified, any characters
1268 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1269 (Note that this is slightly more flexible than the behavior of some
1270 B<tr> programs, which delete anything they find in the SEARCHLIST,
1271 period.) If the C</s> modifier is specified, sequences of characters
1272 that were transliterated to the same character are squashed down
1273 to a single instance of the character.
1274
1275 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1276 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1277 than the SEARCHLIST, the final character is replicated till it is long
1278 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1279 This latter is useful for counting characters in a class or for
1280 squashing character sequences in a class.
1281
1282 Examples:
1283
1284     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1285
1286     $cnt = tr/*/*/;             # count the stars in $_
1287
1288     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1289
1290     $cnt = tr/0-9//;            # count the digits in $_
1291
1292     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1293
1294     ($HOST = $host) =~ tr/a-z/A-Z/;
1295
1296     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1297
1298     tr [\200-\377]
1299        [\000-\177];             # delete 8th bit
1300
1301 If multiple transliterations are given for a character, only the
1302 first one is used:
1303
1304     tr/AAA/XYZ/
1305
1306 will transliterate any A to X.
1307
1308 Because the transliteration table is built at compile time, neither
1309 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1310 interpolation.  That means that if you want to use variables, you
1311 must use an eval():
1312
1313     eval "tr/$oldlist/$newlist/";
1314     die $@ if $@;
1315
1316     eval "tr/$oldlist/$newlist/, 1" or die $@;
1317
1318 =back
1319
1320 =head2 Gory details of parsing quoted constructs
1321
1322 When presented with something that might have several different
1323 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
1324 principle to pick the most probable interpretation.  This strategy
1325 is so successful that Perl programmers often do not suspect the
1326 ambivalence of what they write.  But from time to time, Perl's
1327 notions differ substantially from what the author honestly meant.
1328
1329 This section hopes to clarify how Perl handles quoted constructs.
1330 Although the most common reason to learn this is to unravel labyrinthine
1331 regular expressions, because the initial steps of parsing are the
1332 same for all quoting operators, they are all discussed together.
1333
1334 The most important Perl parsing rule is the first one discussed
1335 below: when processing a quoted construct, Perl first finds the end
1336 of that construct, then interprets its contents.  If you understand
1337 this rule, you may skip the rest of this section on the first
1338 reading.  The other rules are likely to contradict the user's
1339 expectations much less frequently than this first one.
1340
1341 Some passes discussed below are performed concurrently, but because
1342 their results are the same, we consider them individually.  For different
1343 quoting constructs, Perl performs different numbers of passes, from
1344 one to five, but these passes are always performed in the same order.
1345
1346 =over 4
1347
1348 =item Finding the end
1349
1350 The first pass is finding the end of the quoted construct, whether
1351 it be a multicharacter delimiter C<"\nEOF\n"> in the C<<<EOF>
1352 construct, a C</> that terminates a C<qq//> construct, a C<]> which
1353 terminates C<qq[]> construct, or a C<< > >> which terminates a
1354 fileglob started with C<< < >>.
1355
1356 When searching for single-character non-pairing delimiters, such
1357 as C</>, combinations of C<\\> and C<\/> are skipped.  However,
1358 when searching for single-character pairing delimiter like C<[>,
1359 combinations of C<\\>, C<\]>, and C<\[> are all skipped, and nested
1360 C<[>, C<]> are skipped as well.  When searching for multicharacter
1361 delimiters, nothing is skipped.
1362
1363 For constructs with three-part delimiters (C<s///>, C<y///>, and
1364 C<tr///>), the search is repeated once more.
1365
1366 During this search no attention is paid to the semantics of the construct.
1367 Thus:
1368
1369     "$hash{"$foo/$bar"}"
1370
1371 or:
1372
1373     m/ 
1374       bar       # NOT a comment, this slash / terminated m//!
1375      /x
1376
1377 do not form legal quoted expressions.   The quoted part ends on the
1378 first C<"> and C</>, and the rest happens to be a syntax error.
1379 Because the slash that terminated C<m//> was followed by a C<SPACE>,
1380 the example above is not C<m//x>, but rather C<m//> with no C</x>
1381 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
1382
1383 =item Removal of backslashes before delimiters
1384
1385 During the second pass, text between the starting and ending
1386 delimiters is copied to a safe location, and the C<\> is removed
1387 from combinations consisting of C<\> and delimiter--or delimiters,
1388 meaning both starting and ending delimiters will should these differ.
1389 This removal does not happen for multi-character delimiters.
1390 Note that the combination C<\\> is left intact, just as it was.
1391
1392 Starting from this step no information about the delimiters is
1393 used in parsing.
1394
1395 =item Interpolation
1396
1397 The next step is interpolation in the text obtained, which is now
1398 delimiter-independent.  There are four different cases.
1399
1400 =over 4
1401
1402 =item C<<<'EOF'>, C<m''>, C<s'''>, C<tr///>, C<y///>
1403
1404 No interpolation is performed.
1405
1406 =item C<''>, C<q//>
1407
1408 The only interpolation is removal of C<\> from pairs C<\\>.
1409
1410 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>
1411
1412 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
1413 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
1414 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
1415 The other combinations are replaced with appropriate expansions.
1416
1417 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
1418 is interpolated in the usual way.  Something like C<"\Q\\E"> has
1419 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
1420 result is the same as for C<"\\\\E">.  As a general rule, backslashes
1421 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
1422 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
1423 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
1424
1425   $str = '\t';
1426   return "\Q$str";
1427
1428 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
1429
1430 Interpolated scalars and arrays are converted internally to the C<join> and
1431 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
1432
1433   $foo . " XXX '" . (join $", @arr) . "'";
1434
1435 All operations above are performed simultaneously, left to right.
1436
1437 Because the result of C<"\Q STRING \E"> has all metacharacters
1438 quoted, there is no way to insert a literal C<$> or C<@> inside a
1439 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
1440 C<"\\\$">; if not, it is interpreted as the start of an interpolated
1441 scalar.
1442
1443 Note also that the interpolation code needs to make a decision on
1444 where the interpolated scalar ends.  For instance, whether 
1445 C<< "a $b -> {c}" >> really means:
1446
1447   "a " . $b . " -> {c}";
1448
1449 or:
1450
1451   "a " . $b -> {c};
1452
1453 Most of the time, the longest possible text that does not include
1454 spaces between components and which contains matching braces or
1455 brackets.  because the outcome may be determined by voting based
1456 on heuristic estimators, the result is not strictly predictable.
1457 Fortunately, it's usually correct for ambiguous cases.
1458
1459 =item C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>, 
1460
1461 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
1462 happens (almost) as with C<qq//> constructs, but the substitution
1463 of C<\> followed by RE-special chars (including C<\>) is not
1464 performed.  Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
1465 a C<#>-comment in a C<//x>-regular expression, no processing is
1466 performed whatsoever.  This is the first step at which the presence
1467 of the C<//x> modifier is relevant.
1468
1469 Interpolation has several quirks: C<$|>, C<$(>, and C<$)> are not
1470 interpolated, and constructs C<$var[SOMETHING]> are voted (by several
1471 different estimators) to be either an array element or C<$var>
1472 followed by an RE alternative.  This is where the notation
1473 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
1474 array element C<-9>, not as a regular expression from the variable
1475 C<$arr> followed by a digit, which would be the interpretation of
1476 C</$arr[0-9]/>.  Since voting among different estimators may occur,
1477 the result is not predictable.
1478
1479 It is at this step that C<\1> is begrudgingly converted to C<$1> in
1480 the replacement text of C<s///> to correct the incorrigible
1481 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
1482 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
1483 (that is, the C<$^W> variable) was set.
1484
1485 The lack of processing of C<\\> creates specific restrictions on
1486 the post-processed text.  If the delimiter is C</>, one cannot get
1487 the combination C<\/> into the result of this step.  C</> will
1488 finish the regular expression, C<\/> will be stripped to C</> on
1489 the previous step, and C<\\/> will be left as is.  Because C</> is
1490 equivalent to C<\/> inside a regular expression, this does not
1491 matter unless the delimiter happens to be character special to the
1492 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
1493 alphanumeric char, as in:
1494
1495   m m ^ a \s* b mmx;
1496
1497 In the RE above, which is intentionally obfuscated for illustration, the
1498 delimiter is C<m>, the modifier is C<mx>, and after backslash-removal the
1499 RE is the same as for C<m/ ^ a s* b /mx>).  There's more than one 
1500 reason you're encouraged to restrict your delimiters to non-alphanumeric,
1501 non-whitespace choices.
1502
1503 =back
1504
1505 This step is the last one for all constructs except regular expressions,
1506 which are processed further.
1507
1508 =item Interpolation of regular expressions
1509
1510 Previous steps were performed during the compilation of Perl code,
1511 but this one happens at run time--although it may be optimized to
1512 be calculated at compile time if appropriate.  After preprocessing
1513 described above, and possibly after evaluation if catenation,
1514 joining, casing translation, or metaquoting are involved, the
1515 resulting I<string> is passed to the RE engine for compilation.
1516
1517 Whatever happens in the RE engine might be better discussed in L<perlre>,
1518 but for the sake of continuity, we shall do so here.
1519
1520 This is another step where the presence of the C<//x> modifier is
1521 relevant.  The RE engine scans the string from left to right and
1522 converts it to a finite automaton.
1523
1524 Backslashed characters are either replaced with corresponding
1525 literal strings (as with C<\{>), or else they generate special nodes
1526 in the finite automaton (as with C<\b>).  Characters special to the
1527 RE engine (such as C<|>) generate corresponding nodes or groups of
1528 nodes.  C<(?#...)> comments are ignored.  All the rest is either
1529 converted to literal strings to match, or else is ignored (as is
1530 whitespace and C<#>-style comments if C<//x> is present).
1531
1532 Parsing of the bracketed character class construct, C<[...]>, is
1533 rather different than the rule used for the rest of the pattern.
1534 The terminator of this construct is found using the same rules as
1535 for finding the terminator of a C<{}>-delimited construct, the only
1536 exception being that C<]> immediately following C<[> is treated as
1537 though preceded by a backslash.  Similarly, the terminator of
1538 C<(?{...})> is found using the same rules as for finding the
1539 terminator of a C<{}>-delimited construct.
1540
1541 It is possible to inspect both the string given to RE engine and the
1542 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
1543 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
1544 switch documented in L<perlrun/"Command Switches">.
1545
1546 =item Optimization of regular expressions
1547
1548 This step is listed for completeness only.  Since it does not change
1549 semantics, details of this step are not documented and are subject
1550 to change without notice.  This step is performed over the finite
1551 automaton that was generated during the previous pass.
1552
1553 It is at this stage that C<split()> silently optimizes C</^/> to
1554 mean C</^/m>.
1555
1556 =back
1557
1558 =head2 I/O Operators
1559
1560 There are several I/O operators you should know about.
1561
1562 A string enclosed by backticks (grave accents) first undergoes
1563 double-quote interpolation.  It is then interpreted as an external
1564 command, and the output of that command is the value of the
1565 pseudo-literal, j
1566 string consisting of all output is returned.  In list context, a
1567 list of values is returned, one per line of output.  (You can set
1568 C<$/> to use a different line terminator.)  The command is executed
1569 each time the pseudo-literal is evaluated.  The status value of the
1570 command is returned in C<$?> (see L<perlvar> for the interpretation
1571 of C<$?>).  Unlike in B<csh>, no translation is done on the return
1572 data--newlines remain newlines.  Unlike in any of the shells, single
1573 quotes do not hide variable names in the command from interpretation.
1574 To pass a literal dollar-sign through to the shell you need to hide
1575 it with a backslash.  The generalized form of backticks is C<qx//>.
1576 (Because backticks always undergo shell expansion as well, see
1577 L<perlsec> for security concerns.)
1578
1579 In scalar context, evaluating a filehandle in angle brackets yields
1580 the next line from that file (the newline, if any, included), or
1581 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
1582 (sometimes known as file-slurp mode) and the file is empty, it
1583 returns C<''> the first time, followed by C<undef> subsequently.
1584
1585 Ordinarily you must assign the returned value to a variable, but
1586 there is one situation where an automatic assignment happens.  If
1587 and only if the input symbol is the only thing inside the conditional
1588 of a C<while> statement (even if disguised as a C<for(;;)> loop),
1589 the value is automatically assigned to the global variable $_,
1590 destroying whatever was there previously.  (This may seem like an
1591 odd thing to you, but you'll use the construct in almost every Perl
1592 script you write.)  The $_ variables is not implicitly localized.
1593 You'll have to put a C<local $_;> before the loop if you want that
1594 to happen.
1595
1596 The following lines are equivalent:
1597
1598     while (defined($_ = <STDIN>)) { print; }
1599     while ($_ = <STDIN>) { print; }
1600     while (<STDIN>) { print; }
1601     for (;<STDIN>;) { print; }
1602     print while defined($_ = <STDIN>);
1603     print while ($_ = <STDIN>);
1604     print while <STDIN>;
1605
1606 This also behaves similarly, but avoids $_ :
1607
1608     while (my $line = <STDIN>) { print $line }    
1609
1610 In these loop constructs, the assigned value (whether assignment
1611 is automatic or explicit) is then tested to see whether it is
1612 defined.  The defined test avoids problems where line has a string
1613 value that would be treated as false by Perl, for example a "" or
1614 a "0" with no trailing newline.  If you really mean for such values
1615 to terminate the loop, they should be tested for explicitly:
1616
1617     while (($_ = <STDIN>) ne '0') { ... }
1618     while (<STDIN>) { last unless $_; ... }
1619
1620 In other boolean contexts, C<< <I<filehandle>> >> without an
1621 explicit C<defined> test or comparison elicit a warning if the 
1622 C<use warnings> pragma or the B<-w>
1623 command-line switch (the C<$^W> variable) is in effect.
1624
1625 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
1626 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
1627 in packages, where they would be interpreted as local identifiers
1628 rather than global.)  Additional filehandles may be created with
1629 the open() function, amongst others.  See L<perlopentut> and
1630 L<perlfunc/open> for details on this.
1631
1632 If a <FILEHANDLE> is used in a context that is looking for
1633 a list, a list comprising all input lines is returned, one line per
1634 list element.  It's easy to grow to a rather large data space this
1635 way, so use with care.
1636
1637 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
1638 See L<perlfunc/readline>.
1639
1640 The null filehandle <> is special: it can be used to emulate the
1641 behavior of B<sed> and B<awk>.  Input from <> comes either from
1642 standard input, or from each file listed on the command line.  Here's
1643 how it works: the first time <> is evaluated, the @ARGV array is
1644 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
1645 gives you standard input.  The @ARGV array is then processed as a list
1646 of filenames.  The loop
1647
1648     while (<>) {
1649         ...                     # code for each line
1650     }
1651
1652 is equivalent to the following Perl-like pseudo code:
1653
1654     unshift(@ARGV, '-') unless @ARGV;
1655     while ($ARGV = shift) {
1656         open(ARGV, $ARGV);
1657         while (<ARGV>) {
1658             ...         # code for each line
1659         }
1660     }
1661
1662 except that it isn't so cumbersome to say, and will actually work.
1663 It really does shift the @ARGV array and put the current filename
1664 into the $ARGV variable.  It also uses filehandle I<ARGV>
1665 internally--<> is just a synonym for <ARGV>, which
1666 is magical.  (The pseudo code above doesn't work because it treats
1667 <ARGV> as non-magical.)
1668
1669 You can modify @ARGV before the first <> as long as the array ends up
1670 containing the list of filenames you really want.  Line numbers (C<$.>)
1671 continue as though the input were one big happy file.  See the example
1672 in L<perlfunc/eof> for how to reset line numbers on each file.
1673
1674 If you want to set @ARGV to your own list of files, go right ahead.  
1675 This sets @ARGV to all plain text files if no @ARGV was given:
1676
1677     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
1678
1679 You can even set them to pipe commands.  For example, this automatically
1680 filters compressed arguments through B<gzip>:
1681
1682     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
1683
1684 If you want to pass switches into your script, you can use one of the
1685 Getopts modules or put a loop on the front like this:
1686
1687     while ($_ = $ARGV[0], /^-/) {
1688         shift;
1689         last if /^--$/;
1690         if (/^-D(.*)/) { $debug = $1 }
1691         if (/^-v/)     { $verbose++  }
1692         # ...           # other switches
1693     }
1694
1695     while (<>) {
1696         # ...           # code for each line
1697     }
1698
1699 The <> symbol will return C<undef> for end-of-file only once.  
1700 If you call it again after this, it will assume you are processing another 
1701 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
1702
1703 If angle brackets contain is a simple scalar variable (e.g.,
1704 <$foo>), then that variable contains the name of the
1705 filehandle to input from, or its typeglob, or a reference to the
1706 same.  For example:
1707
1708     $fh = \*STDIN;
1709     $line = <$fh>;
1710
1711 If what's within the angle brackets is neither a filehandle nor a simple
1712 scalar variable containing a filehandle name, typeglob, or typeglob
1713 reference, it is interpreted as a filename pattern to be globbed, and
1714 either a list of filenames or the next filename in the list is returned,
1715 depending on context.  This distinction is determined on syntactic
1716 grounds alone.  That means C<< <$x> >> is always a readline() from
1717 an indirect handle, but C<< <$hash{key}> >> is always a glob().
1718 That's because $x is a simple scalar variable, but C<$hash{key}> is
1719 not--it's a hash element.
1720
1721 One level of double-quote interpretation is done first, but you can't
1722 say C<< <$foo> >> because that's an indirect filehandle as explained
1723 in the previous paragraph.  (In older versions of Perl, programmers
1724 would insert curly brackets to force interpretation as a filename glob:
1725 C<< <${foo}> >>.  These days, it's considered cleaner to call the
1726 internal function directly as C<glob($foo)>, which is probably the right
1727 way to have done it in the first place.)  For example:
1728
1729     while (<*.c>) {
1730         chmod 0644, $_;
1731     }
1732
1733 is roughly equivalent to:
1734
1735     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
1736     while (<FOO>) {
1737         chop;
1738         chmod 0644, $_;
1739     }
1740
1741 except that the globbing is actually done internally using the standard
1742 C<File::Glob> extension.  Of course, the shortest way to do the above is:
1743
1744     chmod 0644, <*.c>;
1745
1746 A (file)glob evaluates its (embedded) argument only when it is
1747 starting a new list.  All values must be read before it will start
1748 over.  In list context, this isn't important because you automatically
1749 get them all anyway.  However, in scalar context the operator returns
1750 the next value each time it's called, or C<undef> when the list has
1751 run out.  As with filehandle reads, an automatic C<defined> is
1752 generated when the glob occurs in the test part of a C<while>,
1753 because legal glob returns (e.g. a file called F<0>) would otherwise
1754 terminate the loop.  Again, C<undef> is returned only once.  So if
1755 you're expecting a single value from a glob, it is much better to
1756 say
1757
1758     ($file) = <blurch*>;
1759
1760 than
1761
1762     $file = <blurch*>;
1763
1764 because the latter will alternate between returning a filename and
1765 returning false.
1766
1767 It you're trying to do variable interpolation, it's definitely better
1768 to use the glob() function, because the older notation can cause people
1769 to become confused with the indirect filehandle notation.
1770
1771     @files = glob("$dir/*.[ch]");
1772     @files = glob($files[$i]);
1773
1774 =head2 Constant Folding
1775
1776 Like C, Perl does a certain amount of expression evaluation at
1777 compile time whenever it determines that all arguments to an
1778 operator are static and have no side effects.  In particular, string
1779 concatenation happens at compile time between literals that don't do
1780 variable substitution.  Backslash interpolation also happens at
1781 compile time.  You can say
1782
1783     'Now is the time for all' . "\n" .
1784         'good men to come to.'
1785
1786 and this all reduces to one string internally.  Likewise, if
1787 you say
1788
1789     foreach $file (@filenames) {
1790         if (-s $file > 5 + 100 * 2**16) {  }
1791     }
1792
1793 the compiler will precompute the number which that expression
1794 represents so that the interpreter won't have to.
1795
1796 =head2 Bitwise String Operators
1797
1798 Bitstrings of any size may be manipulated by the bitwise operators
1799 (C<~ | & ^>).
1800
1801 If the operands to a binary bitwise op are strings of different
1802 sizes, B<|> and B<^> ops act as though the shorter operand had
1803 additional zero bits on the right, while the B<&> op acts as though
1804 the longer operand were truncated to the length of the shorter.
1805 The granularity for such extension or truncation is one or more
1806 bytes.
1807
1808     # ASCII-based examples 
1809     print "j p \n" ^ " a h";            # prints "JAPH\n"
1810     print "JA" | "  ph\n";              # prints "japh\n"
1811     print "japh\nJunk" & '_____';       # prints "JAPH\n";
1812     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
1813
1814 If you are intending to manipulate bitstrings, be certain that
1815 you're supplying bitstrings: If an operand is a number, that will imply
1816 a B<numeric> bitwise operation.  You may explicitly show which type of
1817 operation you intend by using C<""> or C<0+>, as in the examples below.
1818
1819     $foo =  150  |  105 ;       # yields 255  (0x96 | 0x69 is 0xFF)
1820     $foo = '150' |  105 ;       # yields 255
1821     $foo =  150  | '105';       # yields 255
1822     $foo = '150' | '105';       # yields string '155' (under ASCII)
1823
1824     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
1825     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
1826
1827 See L<perlfunc/vec> for information on how to manipulate individual bits
1828 in a bit vector.
1829
1830 =head2 Integer Arithmetic
1831
1832 By default, Perl assumes that it must do most of its arithmetic in
1833 floating point.  But by saying
1834
1835     use integer;
1836
1837 you may tell the compiler that it's okay to use integer operations
1838 (if it feels like it) from here to the end of the enclosing BLOCK.
1839 An inner BLOCK may countermand this by saying
1840
1841     no integer;
1842
1843 which lasts until the end of that BLOCK.  Note that this doesn't
1844 mean everything is only an integer, merely that Perl may use integer
1845 operations if it is so inclined.  For example, even under C<use
1846 integer>, if you take the C<sqrt(2)>, you'll still get C<1.4142135623731>
1847 or so.
1848
1849 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
1850 and ">>") always produce integral results.  (But see also 
1851 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
1852 them.  By default, their results are interpreted as unsigned integers, but
1853 if C<use integer> is in effect, their results are interpreted
1854 as signed integers.  For example, C<~0> usually evaluates to a large
1855 integral value.  However, C<use integer; ~0> is C<-1> on twos-complement
1856 machines.
1857
1858 =head2 Floating-point Arithmetic
1859
1860 While C<use integer> provides integer-only arithmetic, there is no
1861 analogous mechanism to provide automatic rounding or truncation to a
1862 certain number of decimal places.  For rounding to a certain number
1863 of digits, sprintf() or printf() is usually the easiest route.
1864 See L<perlfaq4>.
1865
1866 Floating-point numbers are only approximations to what a mathematician
1867 would call real numbers.  There are infinitely more reals than floats,
1868 so some corners must be cut.  For example:
1869
1870     printf "%.20g\n", 123456789123456789;
1871     #        produces 123456789123456784
1872
1873 Testing for exact equality of floating-point equality or inequality is
1874 not a good idea.  Here's a (relatively expensive) work-around to compare
1875 whether two floating-point numbers are equal to a particular number of
1876 decimal places.  See Knuth, volume II, for a more robust treatment of
1877 this topic.
1878
1879     sub fp_equal {
1880         my ($X, $Y, $POINTS) = @_;
1881         my ($tX, $tY);
1882         $tX = sprintf("%.${POINTS}g", $X);
1883         $tY = sprintf("%.${POINTS}g", $Y);
1884         return $tX eq $tY;
1885     }
1886
1887 The POSIX module (part of the standard perl distribution) implements
1888 ceil(), floor(), and other mathematical and trigonometric functions.
1889 The Math::Complex module (part of the standard perl distribution)
1890 defines mathematical functions that work on both the reals and the
1891 imaginary numbers.  Math::Complex not as efficient as POSIX, but
1892 POSIX can't work with complex numbers.
1893
1894 Rounding in financial applications can have serious implications, and
1895 the rounding method used should be specified precisely.  In these
1896 cases, it probably pays not to trust whichever system rounding is
1897 being used by Perl, but to instead implement the rounding function you
1898 need yourself.
1899
1900 =head2 Bigger Numbers
1901
1902 The standard Math::BigInt and Math::BigFloat modules provide
1903 variable-precision arithmetic and overloaded operators, although
1904 they're currently pretty slow.  At the cost of some space and
1905 considerable speed, they avoid the normal pitfalls associated with
1906 limited-precision representations.
1907
1908     use Math::BigInt;
1909     $x = Math::BigInt->new('123456789123456789');
1910     print $x * $x;
1911
1912     # prints +15241578780673678515622620750190521
1913
1914 The non-standard modules SSLeay::BN and Math::Pari provide
1915 equivalent functionality (and much more) with a substantial
1916 performance savings.
1917
1918 =cut