This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
34e0c9066634d47e2c228cfea52843c416624f3b
[perl5.git] / cpan / HTTP-Tiny / t / 110_mirror.t
1 #!perl
2 #
3 # This file is part of HTTP-Tiny
4 #
5 # This software is copyright (c) 2011 by Christian Hansen.
6 #
7 # This is free software; you can redistribute it and/or modify it under
8 # the same terms as the Perl 5 programming language system itself.
9 #
10
11 use strict;
12 use warnings;
13
14 use File::Basename;
15 use Test::More 0.88;
16 use t::Util    qw[tmpfile rewind slurp monkey_patch dir_list parse_case
17                   set_socket_source sort_headers $CRLF $LF];
18 use HTTP::Tiny;
19 use File::Temp qw/tempdir/;
20
21 BEGIN { monkey_patch() }
22
23 my $tempdir = tempdir( TMPDIR => 1, CLEANUP => 1 );
24 my $tempfile = $tempdir . "/tempfile.txt";
25
26 my $known_epoch = 760233600;
27 my $day = 24*3600;
28
29 my %timestamp = (
30   'modified.txt'      => $known_epoch - 2 * $day,
31   'not-modified.txt'  => $known_epoch - 2 * $day,
32 );
33
34 for my $file ( dir_list("t/cases", qr/^mirror/ ) ) {
35   unlink $tempfile;
36   my $data = do { local (@ARGV,$/) = $file; <> };
37   my ($params, $expect_req, $give_res) = split /--+\n/, $data;
38   # cleanup source data
39   my $version = HTTP::Tiny->VERSION || 0;
40   $expect_req =~ s{VERSION}{$version};
41   s{\n}{$CRLF}g for ($expect_req, $give_res);
42
43   # figure out what request to make
44   my $case = parse_case($params);
45   my $url = $case->{url}->[0];
46   my %options;
47
48   my %headers;
49   for my $line ( @{ $case->{headers} } ) {
50     my ($k,$v) = ($line =~ m{^([^:]+): (.*)$}g);
51     $headers{$k} = $v;
52   }
53   $options{headers} = \%headers if %headers;
54
55   # maybe create a file
56   (my $url_basename = $url) =~ s{.*/}{};
57   if ( my $mtime = $timestamp{$url_basename} ) {
58     open my $fh, ">", $tempfile;
59     close $fh;
60     utime $mtime, $mtime, $tempfile;
61   }
62
63   # setup mocking and test
64   my $res_fh = tmpfile($give_res);
65   my $req_fh = tmpfile();
66
67   my $http = HTTP::Tiny->new;
68   set_socket_source($req_fh, $res_fh);
69
70   my @call_args = %options ? ($url, $tempfile, \%options) : ($url, $tempfile);
71   my $response  = $http->mirror(@call_args);
72
73   my $got_req = slurp($req_fh);
74
75   my $label = basename($file);
76
77   is( sort_headers($got_req), sort_headers($expect_req), "$label request" );
78
79   my ($rc) = $give_res =~ m{\S+\s+(\d+)}g;
80   is( $response->{status}, $rc, "$label response code $rc" )
81     or diag $response->{content};
82
83   if ( substr($rc,0,1) eq '2' ) {
84     ok( $response->{success}, "$label success flag true" );
85     ok( -e $tempfile, "$label file created" );
86   }
87   elsif ( $rc eq '304' ) {
88     ok( $response->{success}, "$label success flag true" );
89     is( (stat($tempfile))[9], $timestamp{$url_basename},
90       "$label file not overwritten" );
91   }
92   else {
93     ok( ! $response->{success}, "$label success flag false" );
94     ok( ! -e $tempfile, "$label file not created" );
95   }
96 }
97
98 done_testing;