This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
3358a39f1bfc0f877696e14095ed66fd01ff02cc
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<fc>, C<hex>, C<index>, C<lc>,
111 C<lcfirst>, C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 =item Regular expressions and pattern matching
115 X<regular expression> X<regex> X<regexp>
116
117 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
118
119 =item Numeric functions
120 X<numeric> X<number> X<trigonometric> X<trigonometry>
121
122 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
123 C<sin>, C<sqrt>, C<srand>
124
125 =item Functions for real @ARRAYs
126 X<array>
127
128 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
129
130 =item Functions for list data
131 X<list>
132
133 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
134
135 =item Functions for real %HASHes
136 X<hash>
137
138 C<delete>, C<each>, C<exists>, C<keys>, C<values>
139
140 =item Input and output functions
141 X<I/O> X<input> X<output> X<dbm>
142
143 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
144 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
145 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
146 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
147 C<warn>, C<write>
148
149 =item Functions for fixed-length data or records
150
151 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
152
153 =item Functions for filehandles, files, or directories
154 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
155
156 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
157 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
158 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
159 C<umask>, C<unlink>, C<utime>
160
161 =item Keywords related to the control flow of your Perl program
162 X<control flow>
163
164 C<caller>, C<continue>, C<die>, C<do>,
165 C<dump>, C<eval>, C<evalbytes> C<exit>,
166 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
167 C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
168
169 C<__SUB__> is only available with a C<use v5.16> (or higher) declaration or
170 with the C<"current_sub"> feature (see L<feature>).
171
172 =item Keywords related to the switch feature
173
174 C<break>, C<continue>, C<default>, C<given>, C<when>
175
176 Except for C<continue>, these are available only if you enable the
177 C<"switch"> feature or use the C<CORE::> prefix.
178 See L<feature> and L<perlsyn/"Switch Statements">.  
179 Alternately, include a C<use v5.10> or later to the current scope.  In Perl
180 5.14 and earlier, C<continue> required the C<"switch"> feature, like the
181 other keywords.
182
183 =item Keywords related to scoping
184
185 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
186
187 C<state> is available only if the C<"state"> feature
188 is enabled or if it is prefixed with C<CORE::>.  See
189 L<feature>.  Alternately, include a C<use v5.10> or later to the current scope.
190
191 =item Miscellaneous functions
192
193 C<defined>, C<dump>, C<eval>, C<evalbytes>,
194 C<formline>, C<local>, C<my>, C<our>,
195 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
196
197 =item Functions for processes and process groups
198 X<process> X<pid> X<process id>
199
200 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
201 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
202 C<setpriority>, C<sleep>, C<system>,
203 C<times>, C<wait>, C<waitpid>
204
205 =item Keywords related to Perl modules
206 X<module>
207
208 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
209
210 =item Keywords related to classes and object-orientation
211 X<object> X<class> X<package>
212
213 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
214 C<untie>, C<use>
215
216 =item Low-level socket functions
217 X<socket> X<sock>
218
219 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
220 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
221 C<socket>, C<socketpair>
222
223 =item System V interprocess communication functions
224 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
225
226 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
227 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
228
229 =item Fetching user and group info
230 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
231
232 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
233 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
234 C<getpwuid>, C<setgrent>, C<setpwent>
235
236 =item Fetching network info
237 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
238
239 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
240 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
241 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
242 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
243 C<setnetent>, C<setprotoent>, C<setservent>
244
245 =item Time-related functions
246 X<time> X<date>
247
248 C<gmtime>, C<localtime>, C<time>, C<times>
249
250 =item Functions new in perl5
251 X<perl5>
252
253 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
254 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
255 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
256 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
257 C<ucfirst>, C<untie>, C<use>, C<when>
258
259 * C<sub> was a keyword in Perl 4, but in Perl 5 it is an
260 operator, which can be used in expressions.
261
262 =item Functions obsoleted in perl5
263
264 C<dbmclose>, C<dbmopen>
265
266 =back
267
268 =head2 Portability
269 X<portability> X<Unix> X<portable>
270
271 Perl was born in Unix and can therefore access all common Unix
272 system calls.  In non-Unix environments, the functionality of some
273 Unix system calls may not be available or details of the available
274 functionality may differ slightly.  The Perl functions affected
275 by this are:
276
277 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
278 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
279 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
280 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
281 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
282 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
283 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
284 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
285 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
286 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
287 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
288 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
289 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
290 C<shmwrite>, C<socket>, C<socketpair>,
291 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
292 C<times>, C<truncate>, C<umask>, C<unlink>,
293 C<utime>, C<wait>, C<waitpid>
294
295 For more information about the portability of these functions, see
296 L<perlport> and other available platform-specific documentation.
297
298 =head2 Alphabetical Listing of Perl Functions
299
300 =over 
301
302 =item -X FILEHANDLE
303 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
304 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
305
306 =item -X EXPR
307
308 =item -X DIRHANDLE
309
310 =item -X
311
312 A file test, where X is one of the letters listed below.  This unary
313 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
314 and tests the associated file to see if something is true about it.  If the
315 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
316 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
317 the undefined value if the file doesn't exist.  Despite the funny
318 names, precedence is the same as any other named unary operator.  The
319 operator may be any of:
320
321     -r  File is readable by effective uid/gid.
322     -w  File is writable by effective uid/gid.
323     -x  File is executable by effective uid/gid.
324     -o  File is owned by effective uid.
325
326     -R  File is readable by real uid/gid.
327     -W  File is writable by real uid/gid.
328     -X  File is executable by real uid/gid.
329     -O  File is owned by real uid.
330
331     -e  File exists.
332     -z  File has zero size (is empty).
333     -s  File has nonzero size (returns size in bytes).
334
335     -f  File is a plain file.
336     -d  File is a directory.
337     -l  File is a symbolic link.
338     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
339     -S  File is a socket.
340     -b  File is a block special file.
341     -c  File is a character special file.
342     -t  Filehandle is opened to a tty.
343
344     -u  File has setuid bit set.
345     -g  File has setgid bit set.
346     -k  File has sticky bit set.
347
348     -T  File is an ASCII text file (heuristic guess).
349     -B  File is a "binary" file (opposite of -T).
350
351     -M  Script start time minus file modification time, in days.
352     -A  Same for access time.
353     -C  Same for inode change time (Unix, may differ for other platforms)
354
355 Example:
356
357     while (<>) {
358         chomp;
359         next unless -f $_;  # ignore specials
360         #...
361     }
362
363 Note that C<-s/a/b/> does not do a negated substitution.  Saying
364 C<-exp($foo)> still works as expected, however: only single letters
365 following a minus are interpreted as file tests.
366
367 These operators are exempt from the "looks like a function rule" described
368 above.  That is, an opening parenthesis after the operator does not affect
369 how much of the following code constitutes the argument.  Put the opening
370 parentheses before the operator to separate it from code that follows (this
371 applies only to operators with higher precedence than unary operators, of
372 course):
373
374     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
375     (-s $file) + 1024  # correct
376
377 The interpretation of the file permission operators C<-r>, C<-R>,
378 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
379 of the file and the uids and gids of the user.  There may be other
380 reasons you can't actually read, write, or execute the file: for
381 example network filesystem access controls, ACLs (access control lists),
382 read-only filesystems, and unrecognized executable formats.  Note
383 that the use of these six specific operators to verify if some operation
384 is possible is usually a mistake, because it may be open to race
385 conditions.
386
387 Also note that, for the superuser on the local filesystems, the C<-r>,
388 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
389 if any execute bit is set in the mode.  Scripts run by the superuser
390 may thus need to do a stat() to determine the actual mode of the file,
391 or temporarily set their effective uid to something else.
392
393 If you are using ACLs, there is a pragma called C<filetest> that may
394 produce more accurate results than the bare stat() mode bits.
395 When under C<use filetest 'access'> the above-mentioned filetests
396 test whether the permission can(not) be granted using the
397 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
398 under this pragma return true even if there are no execute permission
399 bits set (nor any extra execute permission ACLs).  This strangeness is
400 due to the underlying system calls' definitions.  Note also that, due to
401 the implementation of C<use filetest 'access'>, the C<_> special
402 filehandle won't cache the results of the file tests when this pragma is
403 in effect.  Read the documentation for the C<filetest> pragma for more
404 information.
405
406 The C<-T> and C<-B> switches work as follows.  The first block or so of the
407 file is examined for odd characters such as strange control codes or
408 characters with the high bit set.  If too many strange characters (>30%)
409 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
410 containing a zero byte in the first block is considered a binary file.  If C<-T>
411 or C<-B> is used on a filehandle, the current IO buffer is examined
412 rather than the first block.  Both C<-T> and C<-B> return true on an empty
413 file, or a file at EOF when testing a filehandle.  Because you have to
414 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
415 against the file first, as in C<next unless -f $file && -T $file>.
416
417 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
418 the special filehandle consisting of a solitary underline, then the stat
419 structure of the previous file test (or stat operator) is used, saving
420 a system call.  (This doesn't work with C<-t>, and you need to remember
421 that lstat() and C<-l> leave values in the stat structure for the
422 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
423 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
424 Example:
425
426     print "Can do.\n" if -r $a || -w _ || -x _;
427
428     stat($filename);
429     print "Readable\n" if -r _;
430     print "Writable\n" if -w _;
431     print "Executable\n" if -x _;
432     print "Setuid\n" if -u _;
433     print "Setgid\n" if -g _;
434     print "Sticky\n" if -k _;
435     print "Text\n" if -T _;
436     print "Binary\n" if -B _;
437
438 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
439 test operators, in a way that C<-f -w -x $file> is equivalent to
440 C<-x $file && -w _ && -f _>.  (This is only fancy fancy: if you use
441 the return value of C<-f $file> as an argument to another filetest
442 operator, no special magic will happen.)
443
444 Portability issues: L<perlport/-X>.
445
446 To avoid confusing would-be users of your code with mysterious
447 syntax errors, put something like this at the top of your script:
448
449     use 5.010;  # so filetest ops can stack
450
451 =item abs VALUE
452 X<abs> X<absolute>
453
454 =item abs
455
456 Returns the absolute value of its argument.
457 If VALUE is omitted, uses C<$_>.
458
459 =item accept NEWSOCKET,GENERICSOCKET
460 X<accept>
461
462 Accepts an incoming socket connect, just as accept(2) 
463 does.  Returns the packed address if it succeeded, false otherwise.
464 See the example in L<perlipc/"Sockets: Client/Server Communication">.
465
466 On systems that support a close-on-exec flag on files, the flag will
467 be set for the newly opened file descriptor, as determined by the
468 value of $^F.  See L<perlvar/$^F>.
469
470 =item alarm SECONDS
471 X<alarm>
472 X<SIGALRM>
473 X<timer>
474
475 =item alarm
476
477 Arranges to have a SIGALRM delivered to this process after the
478 specified number of wallclock seconds has elapsed.  If SECONDS is not
479 specified, the value stored in C<$_> is used.  (On some machines,
480 unfortunately, the elapsed time may be up to one second less or more
481 than you specified because of how seconds are counted, and process
482 scheduling may delay the delivery of the signal even further.)
483
484 Only one timer may be counting at once.  Each call disables the
485 previous timer, and an argument of C<0> may be supplied to cancel the
486 previous timer without starting a new one.  The returned value is the
487 amount of time remaining on the previous timer.
488
489 For delays of finer granularity than one second, the Time::HiRes module
490 (from CPAN, and starting from Perl 5.8 part of the standard
491 distribution) provides ualarm().  You may also use Perl's four-argument
492 version of select() leaving the first three arguments undefined, or you
493 might be able to use the C<syscall> interface to access setitimer(2) if
494 your system supports it.  See L<perlfaq8> for details.
495
496 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
497 C<sleep> may be internally implemented on your system with C<alarm>.
498
499 If you want to use C<alarm> to time out a system call you need to use an
500 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
501 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
502 restart system calls on some systems.  Using C<eval>/C<die> always works,
503 modulo the caveats given in L<perlipc/"Signals">.
504
505     eval {
506         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
507         alarm $timeout;
508         $nread = sysread SOCKET, $buffer, $size;
509         alarm 0;
510     };
511     if ($@) {
512         die unless $@ eq "alarm\n";   # propagate unexpected errors
513         # timed out
514     }
515     else {
516         # didn't
517     }
518
519 For more information see L<perlipc>.
520
521 Portability issues: L<perlport/alarm>.
522
523 =item atan2 Y,X
524 X<atan2> X<arctangent> X<tan> X<tangent>
525
526 Returns the arctangent of Y/X in the range -PI to PI.
527
528 For the tangent operation, you may use the C<Math::Trig::tan>
529 function, or use the familiar relation:
530
531     sub tan { sin($_[0]) / cos($_[0])  }
532
533 The return value for C<atan2(0,0)> is implementation-defined; consult
534 your atan2(3) manpage for more information.
535
536 Portability issues: L<perlport/atan2>.
537
538 =item bind SOCKET,NAME
539 X<bind>
540
541 Binds a network address to a socket, just as bind(2)
542 does.  Returns true if it succeeded, false otherwise.  NAME should be a
543 packed address of the appropriate type for the socket.  See the examples in
544 L<perlipc/"Sockets: Client/Server Communication">.
545
546 =item binmode FILEHANDLE, LAYER
547 X<binmode> X<binary> X<text> X<DOS> X<Windows>
548
549 =item binmode FILEHANDLE
550
551 Arranges for FILEHANDLE to be read or written in "binary" or "text"
552 mode on systems where the run-time libraries distinguish between
553 binary and text files.  If FILEHANDLE is an expression, the value is
554 taken as the name of the filehandle.  Returns true on success,
555 otherwise it returns C<undef> and sets C<$!> (errno).
556
557 On some systems (in general, DOS- and Windows-based systems) binmode()
558 is necessary when you're not working with a text file.  For the sake
559 of portability it is a good idea always to use it when appropriate,
560 and never to use it when it isn't appropriate.  Also, people can
561 set their I/O to be by default UTF8-encoded Unicode, not bytes.
562
563 In other words: regardless of platform, use binmode() on binary data,
564 like images, for example.
565
566 If LAYER is present it is a single string, but may contain multiple
567 directives.  The directives alter the behaviour of the filehandle.
568 When LAYER is present, using binmode on a text file makes sense.
569
570 If LAYER is omitted or specified as C<:raw> the filehandle is made
571 suitable for passing binary data.  This includes turning off possible CRLF
572 translation and marking it as bytes (as opposed to Unicode characters).
573 Note that, despite what may be implied in I<"Programming Perl"> (the
574 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
575 Other layers that would affect the binary nature of the stream are
576 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
577 PERLIO environment variable.
578
579 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
580 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
581 establish default I/O layers.  See L<open>.
582
583 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
584 in "Programming Perl, 3rd Edition".  However, since the publishing of this
585 book, by many known as "Camel III", the consensus of the naming of this
586 functionality has moved from "discipline" to "layer".  All documentation
587 of this version of Perl therefore refers to "layers" rather than to
588 "disciplines".  Now back to the regularly scheduled documentation...>
589
590 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
591 C<:utf8> just marks the data as UTF-8 without further checking,
592 while C<:encoding(UTF-8)> checks the data for actually being valid
593 UTF-8.  More details can be found in L<PerlIO::encoding>.
594
595 In general, binmode() should be called after open() but before any I/O
596 is done on the filehandle.  Calling binmode() normally flushes any
597 pending buffered output data (and perhaps pending input data) on the
598 handle.  An exception to this is the C<:encoding> layer that
599 changes the default character encoding of the handle; see L</open>.
600 The C<:encoding> layer sometimes needs to be called in
601 mid-stream, and it doesn't flush the stream.  The C<:encoding>
602 also implicitly pushes on top of itself the C<:utf8> layer because
603 internally Perl operates on UTF8-encoded Unicode characters.
604
605 The operating system, device drivers, C libraries, and Perl run-time
606 system all conspire to let the programmer treat a single
607 character (C<\n>) as the line terminator, irrespective of external
608 representation.  On many operating systems, the native text file
609 representation matches the internal representation, but on some
610 platforms the external representation of C<\n> is made up of more than
611 one character.
612
613 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
614 a single character to end each line in the external representation of text
615 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
616 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
617 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
618 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
619 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
620 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
621 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
622 output.  This is what you want for text files, but it can be disastrous for
623 binary files.
624
625 Another consequence of using binmode() (on some systems) is that
626 special end-of-file markers will be seen as part of the data stream.
627 For systems from the Microsoft family this means that, if your binary
628 data contain C<\cZ>, the I/O subsystem will regard it as the end of
629 the file, unless you use binmode().
630
631 binmode() is important not only for readline() and print() operations,
632 but also when using read(), seek(), sysread(), syswrite() and tell()
633 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
634 in L<perlvar> for how to manually set your input and output
635 line-termination sequences.
636
637 Portability issues: L<perlport/binmode>.
638
639 =item bless REF,CLASSNAME
640 X<bless>
641
642 =item bless REF
643
644 This function tells the thingy referenced by REF that it is now an object
645 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
646 is used.  Because a C<bless> is often the last thing in a constructor,
647 it returns the reference for convenience.  Always use the two-argument
648 version if a derived class might inherit the function doing the blessing.
649 SeeL<perlobj> for more about the blessing (and blessings) of objects.
650
651 Consider always blessing objects in CLASSNAMEs that are mixed case.
652 Namespaces with all lowercase names are considered reserved for
653 Perl pragmata.  Builtin types have all uppercase names.  To prevent
654 confusion, you may wish to avoid such package names as well.  Make sure
655 that CLASSNAME is a true value.
656
657 See L<perlmod/"Perl Modules">.
658
659 =item break
660
661 Break out of a C<given()> block.
662
663 This keyword is enabled by the C<"switch"> feature: see
664 L<feature> for more information.  You can also access it by
665 prefixing it with C<CORE::>.  Alternately, include a C<use
666 v5.10> or later to the current scope.
667
668 =item caller EXPR
669 X<caller> X<call stack> X<stack> X<stack trace>
670
671 =item caller
672
673 Returns the context of the current subroutine call.  In scalar context,
674 returns the caller's package name if there I<is> a caller (that is, if
675 we're in a subroutine or C<eval> or C<require>) and the undefined value
676 otherwise.  In list context, returns
677
678     # 0         1          2
679     ($package, $filename, $line) = caller;
680
681 With EXPR, it returns some extra information that the debugger uses to
682 print a stack trace.  The value of EXPR indicates how many call frames
683 to go back before the current one.
684
685     #  0         1          2      3            4
686     ($package, $filename, $line, $subroutine, $hasargs,
687
688     #  5          6          7            8       9         10
689     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
690      = caller($i);
691
692 Here $subroutine may be C<(eval)> if the frame is not a subroutine
693 call, but an C<eval>.  In such a case additional elements $evaltext and
694 C<$is_require> are set: C<$is_require> is true if the frame is created by a
695 C<require> or C<use> statement, $evaltext contains the text of the
696 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
697 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
698 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
699 frame.)  $subroutine may also be C<(unknown)> if this particular
700 subroutine happens to have been deleted from the symbol table.
701 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
702 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
703 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
704 between versions of Perl, and are not meant for external use.
705
706 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
707 caller was compiled, or C<undef> if C<%^H> was empty.  Do not modify the values
708 of this hash, as they are the actual values stored in the optree.
709
710 Furthermore, when called from within the DB package in
711 list context, and with an argument, caller returns more
712 detailed information: it sets the list variable C<@DB::args> to be the
713 arguments with which the subroutine was invoked.
714
715 Be aware that the optimizer might have optimized call frames away before
716 C<caller> had a chance to get the information.  That means that C<caller(N)>
717 might not return information about the call frame you expect it to, for
718 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
719 previous time C<caller> was called.
720
721 Be aware that setting C<@DB::args> is I<best effort>, intended for
722 debugging or generating backtraces, and should not be relied upon.  In
723 particular, as C<@_> contains aliases to the caller's arguments, Perl does
724 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
725 subroutine makes to C<@_> or its contents, not the original values at call
726 time.  C<@DB::args>, like C<@_>, does not hold explicit references to its
727 elements, so under certain cases its elements may have become freed and
728 reallocated for other variables or temporary values.  Finally, a side effect
729 of the current implementation is that the effects of C<shift @_> can
730 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
731 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
732 elements), so C<@DB::args> is actually a hybrid of the current state and
733 initial state of C<@_>.  Buyer beware.
734
735 =item chdir EXPR
736 X<chdir>
737 X<cd>
738 X<directory, change>
739
740 =item chdir FILEHANDLE
741
742 =item chdir DIRHANDLE
743
744 =item chdir
745
746 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
747 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
748 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
749 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.)  If
750 neither is set, C<chdir> does nothing.  It returns true on success,
751 false otherwise.  See the example under C<die>.
752
753 On systems that support fchdir(2), you may pass a filehandle or
754 directory handle as the argument.  On systems that don't support fchdir(2),
755 passing handles raises an exception.
756
757 =item chmod LIST
758 X<chmod> X<permission> X<mode>
759
760 Changes the permissions of a list of files.  The first element of the
761 list must be the numeric mode, which should probably be an octal
762 number, and which definitely should I<not> be a string of octal digits:
763 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
764 successfully changed.  See also L</oct> if all you have is a string.
765
766     $cnt = chmod 0755, "foo", "bar";
767     chmod 0755, @executables;
768     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
769                                              # --w----r-T
770     $mode = "0644"; chmod oct($mode), "foo"; # this is better
771     $mode = 0644;   chmod $mode, "foo";      # this is best
772
773 On systems that support fchmod(2), you may pass filehandles among the
774 files.  On systems that don't support fchmod(2), passing filehandles raises
775 an exception.  Filehandles must be passed as globs or glob references to be
776 recognized; barewords are considered filenames.
777
778     open(my $fh, "<", "foo");
779     my $perm = (stat $fh)[2] & 07777;
780     chmod($perm | 0600, $fh);
781
782 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
783 module:
784
785     use Fcntl qw( :mode );
786     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
787     # Identical to the chmod 0755 of the example above.
788
789 Portability issues: L<perlport/chmod>.
790
791 =item chomp VARIABLE
792 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
793
794 =item chomp( LIST )
795
796 =item chomp
797
798 This safer version of L</chop> removes any trailing string
799 that corresponds to the current value of C<$/> (also known as
800 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
801 number of characters removed from all its arguments.  It's often used to
802 remove the newline from the end of an input record when you're worried
803 that the final record may be missing its newline.  When in paragraph
804 mode (C<$/ = "">), it removes all trailing newlines from the string.
805 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
806 a reference to an integer or the like; see L<perlvar>) chomp() won't
807 remove anything.
808 If VARIABLE is omitted, it chomps C<$_>.  Example:
809
810     while (<>) {
811         chomp;  # avoid \n on last field
812         @array = split(/:/);
813         # ...
814     }
815
816 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
817
818 You can actually chomp anything that's an lvalue, including an assignment:
819
820     chomp($cwd = `pwd`);
821     chomp($answer = <STDIN>);
822
823 If you chomp a list, each element is chomped, and the total number of
824 characters removed is returned.
825
826 Note that parentheses are necessary when you're chomping anything
827 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
828 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
829 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
830 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
831 as C<chomp($a, $b)>.
832
833 =item chop VARIABLE
834 X<chop>
835
836 =item chop( LIST )
837
838 =item chop
839
840 Chops off the last character of a string and returns the character
841 chopped.  It is much more efficient than C<s/.$//s> because it neither
842 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
843 If VARIABLE is a hash, it chops the hash's values, but not its keys.
844
845 You can actually chop anything that's an lvalue, including an assignment.
846
847 If you chop a list, each element is chopped.  Only the value of the
848 last C<chop> is returned.
849
850 Note that C<chop> returns the last character.  To return all but the last
851 character, use C<substr($string, 0, -1)>.
852
853 See also L</chomp>.
854
855 =item chown LIST
856 X<chown> X<owner> X<user> X<group>
857
858 Changes the owner (and group) of a list of files.  The first two
859 elements of the list must be the I<numeric> uid and gid, in that
860 order.  A value of -1 in either position is interpreted by most
861 systems to leave that value unchanged.  Returns the number of files
862 successfully changed.
863
864     $cnt = chown $uid, $gid, 'foo', 'bar';
865     chown $uid, $gid, @filenames;
866
867 On systems that support fchown(2), you may pass filehandles among the
868 files.  On systems that don't support fchown(2), passing filehandles raises
869 an exception.  Filehandles must be passed as globs or glob references to be
870 recognized; barewords are considered filenames.
871
872 Here's an example that looks up nonnumeric uids in the passwd file:
873
874     print "User: ";
875     chomp($user = <STDIN>);
876     print "Files: ";
877     chomp($pattern = <STDIN>);
878
879     ($login,$pass,$uid,$gid) = getpwnam($user)
880         or die "$user not in passwd file";
881
882     @ary = glob($pattern);  # expand filenames
883     chown $uid, $gid, @ary;
884
885 On most systems, you are not allowed to change the ownership of the
886 file unless you're the superuser, although you should be able to change
887 the group to any of your secondary groups.  On insecure systems, these
888 restrictions may be relaxed, but this is not a portable assumption.
889 On POSIX systems, you can detect this condition this way:
890
891     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
892     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
893
894 Portability issues: L<perlport/chmod>.
895
896 =item chr NUMBER
897 X<chr> X<character> X<ASCII> X<Unicode>
898
899 =item chr
900
901 Returns the character represented by that NUMBER in the character set.
902 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
903 chr(0x263a) is a Unicode smiley face.  
904
905 Negative values give the Unicode replacement character (chr(0xfffd)),
906 except under the L<bytes> pragma, where the low eight bits of the value
907 (truncated to an integer) are used.
908
909 If NUMBER is omitted, uses C<$_>.
910
911 For the reverse, use L</ord>.
912
913 Note that characters from 128 to 255 (inclusive) are by default
914 internally not encoded as UTF-8 for backward compatibility reasons.
915
916 See L<perlunicode> for more about Unicode.
917
918 =item chroot FILENAME
919 X<chroot> X<root>
920
921 =item chroot
922
923 This function works like the system call by the same name: it makes the
924 named directory the new root directory for all further pathnames that
925 begin with a C</> by your process and all its children.  (It doesn't
926 change your current working directory, which is unaffected.)  For security
927 reasons, this call is restricted to the superuser.  If FILENAME is
928 omitted, does a C<chroot> to C<$_>.
929
930 Portability issues: L<perlport/chroot>.
931
932 =item close FILEHANDLE
933 X<close>
934
935 =item close
936
937 Closes the file or pipe associated with the filehandle, flushes the IO
938 buffers, and closes the system file descriptor.  Returns true if those
939 operations succeed and if no error was reported by any PerlIO
940 layer.  Closes the currently selected filehandle if the argument is
941 omitted.
942
943 You don't have to close FILEHANDLE if you are immediately going to do
944 another C<open> on it, because C<open> closes it for you.  (See
945 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
946 counter (C<$.>), while the implicit close done by C<open> does not.
947
948 If the filehandle came from a piped open, C<close> returns false if one of
949 the other syscalls involved fails or if its program exits with non-zero
950 status.  If the only problem was that the program exited non-zero, C<$!>
951 will be set to C<0>.  Closing a pipe also waits for the process executing
952 on the pipe to exit--in case you wish to look at the output of the pipe
953 afterwards--and implicitly puts the exit status value of that command into
954 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
955
956 If there are multiple threads running, C<close> on a filehandle from a
957 piped open returns true without waiting for the child process to terminate,
958 if the filehandle is still open in another thread.
959
960 Closing the read end of a pipe before the process writing to it at the
961 other end is done writing results in the writer receiving a SIGPIPE.  If
962 the other end can't handle that, be sure to read all the data before
963 closing the pipe.
964
965 Example:
966
967     open(OUTPUT, '|sort >foo')  # pipe to sort
968         or die "Can't start sort: $!";
969     #...                        # print stuff to output
970     close OUTPUT                # wait for sort to finish
971         or warn $! ? "Error closing sort pipe: $!"
972                    : "Exit status $? from sort";
973     open(INPUT, 'foo')          # get sort's results
974         or die "Can't open 'foo' for input: $!";
975
976 FILEHANDLE may be an expression whose value can be used as an indirect
977 filehandle, usually the real filehandle name or an autovivified handle.
978
979 =item closedir DIRHANDLE
980 X<closedir>
981
982 Closes a directory opened by C<opendir> and returns the success of that
983 system call.
984
985 =item connect SOCKET,NAME
986 X<connect>
987
988 Attempts to connect to a remote socket, just like connect(2).
989 Returns true if it succeeded, false otherwise.  NAME should be a
990 packed address of the appropriate type for the socket.  See the examples in
991 L<perlipc/"Sockets: Client/Server Communication">.
992
993 =item continue BLOCK
994 X<continue>
995
996 =item continue
997
998 When followed by a BLOCK, C<continue> is actually a
999 flow control statement rather than a function.  If
1000 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
1001 C<foreach>), it is always executed just before the conditional is about to
1002 be evaluated again, just like the third part of a C<for> loop in C.  Thus
1003 it can be used to increment a loop variable, even when the loop has been
1004 continued via the C<next> statement (which is similar to the C C<continue>
1005 statement).
1006
1007 C<last>, C<next>, or C<redo> may appear within a C<continue>
1008 block; C<last> and C<redo> behave as if they had been executed within
1009 the main block.  So will C<next>, but since it will execute a C<continue>
1010 block, it may be more entertaining.
1011
1012     while (EXPR) {
1013         ### redo always comes here
1014         do_something;
1015     } continue {
1016         ### next always comes here
1017         do_something_else;
1018         # then back the top to re-check EXPR
1019     }
1020     ### last always comes here
1021
1022 Omitting the C<continue> section is equivalent to using an
1023 empty one, logically enough, so C<next> goes directly back
1024 to check the condition at the top of the loop.
1025
1026 When there is no BLOCK, C<continue> is a function that
1027 falls through the current C<when> or C<default> block instead of iterating
1028 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1029 In Perl 5.14 and earlier, this form of C<continue> was
1030 only available when the C<"switch"> feature was enabled.
1031 See L<feature> and L<perlsyn/"Switch Statements"> for more
1032 information.
1033
1034 =item cos EXPR
1035 X<cos> X<cosine> X<acos> X<arccosine>
1036
1037 =item cos
1038
1039 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1040 takes the cosine of C<$_>.
1041
1042 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1043 function, or use this relation:
1044
1045     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1046
1047 =item crypt PLAINTEXT,SALT
1048 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1049 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1050
1051 Creates a digest string exactly like the crypt(3) function in the C
1052 library (assuming that you actually have a version there that has not
1053 been extirpated as a potential munition).
1054
1055 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1056 into a short string, called a digest, which is returned.  The same
1057 PLAINTEXT and SALT will always return the same string, but there is no
1058 (known) way to get the original PLAINTEXT from the hash.  Small
1059 changes in the PLAINTEXT or SALT will result in large changes in the
1060 digest.
1061
1062 There is no decrypt function.  This function isn't all that useful for
1063 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1064 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1065 primarily used to check if two pieces of text are the same without
1066 having to transmit or store the text itself.  An example is checking
1067 if a correct password is given.  The digest of the password is stored,
1068 not the password itself.  The user types in a password that is
1069 crypt()'d with the same salt as the stored digest.  If the two digests
1070 match, the password is correct.
1071
1072 When verifying an existing digest string you should use the digest as
1073 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1074 to create the digest is visible as part of the digest.  This ensures
1075 crypt() will hash the new string with the same salt as the digest.
1076 This allows your code to work with the standard L<crypt|/crypt> and
1077 with more exotic implementations.  In other words, assume
1078 nothing about the returned string itself nor about how many bytes 
1079 of SALT may matter.
1080
1081 Traditionally the result is a string of 13 bytes: two first bytes of
1082 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1083 the first eight bytes of PLAINTEXT mattered.  But alternative
1084 hashing schemes (like MD5), higher level security schemes (like C2),
1085 and implementations on non-Unix platforms may produce different
1086 strings.
1087
1088 When choosing a new salt create a random two character string whose
1089 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1090 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1091 characters is just a recommendation; the characters allowed in
1092 the salt depend solely on your system's crypt library, and Perl can't
1093 restrict what salts C<crypt()> accepts.
1094
1095 Here's an example that makes sure that whoever runs this program knows
1096 their password:
1097
1098     $pwd = (getpwuid($<))[1];
1099
1100     system "stty -echo";
1101     print "Password: ";
1102     chomp($word = <STDIN>);
1103     print "\n";
1104     system "stty echo";
1105
1106     if (crypt($word, $pwd) ne $pwd) {
1107         die "Sorry...\n";
1108     } else {
1109         print "ok\n";
1110     }
1111
1112 Of course, typing in your own password to whoever asks you
1113 for it is unwise.
1114
1115 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1116 of data, not least of all because you can't get the information
1117 back.  Look at the L<Digest> module for more robust algorithms.
1118
1119 If using crypt() on a Unicode string (which I<potentially> has
1120 characters with codepoints above 255), Perl tries to make sense
1121 of the situation by trying to downgrade (a copy of)
1122 the string back to an eight-bit byte string before calling crypt()
1123 (on that copy).  If that works, good.  If not, crypt() dies with
1124 C<Wide character in crypt>.
1125
1126 Portability issues: L<perlport/crypt>.
1127
1128 =item dbmclose HASH
1129 X<dbmclose>
1130
1131 [This function has been largely superseded by the C<untie> function.]
1132
1133 Breaks the binding between a DBM file and a hash.
1134
1135 Portability issues: L<perlport/dbmclose>.
1136
1137 =item dbmopen HASH,DBNAME,MASK
1138 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1139
1140 [This function has been largely superseded by the
1141 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1142
1143 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1144 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1145 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1146 is the name of the database (without the F<.dir> or F<.pag> extension if
1147 any).  If the database does not exist, it is created with protection
1148 specified by MASK (as modified by the C<umask>).  To prevent creation of
1149 the database if it doesn't exist, you may specify a MODE
1150 of 0, and the function will return a false value if it
1151 can't find an existing database.  If your system supports
1152 only the older DBM functions, you may make only one C<dbmopen> call in your
1153 program.  In older versions of Perl, if your system had neither DBM nor
1154 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1155 sdbm(3).
1156
1157 If you don't have write access to the DBM file, you can only read hash
1158 variables, not set them.  If you want to test whether you can write,
1159 either use file tests or try setting a dummy hash entry inside an C<eval> 
1160 to trap the error.
1161
1162 Note that functions such as C<keys> and C<values> may return huge lists
1163 when used on large DBM files.  You may prefer to use the C<each>
1164 function to iterate over large DBM files.  Example:
1165
1166     # print out history file offsets
1167     dbmopen(%HIST,'/usr/lib/news/history',0666);
1168     while (($key,$val) = each %HIST) {
1169         print $key, ' = ', unpack('L',$val), "\n";
1170     }
1171     dbmclose(%HIST);
1172
1173 See also L<AnyDBM_File> for a more general description of the pros and
1174 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1175 rich implementation.
1176
1177 You can control which DBM library you use by loading that library
1178 before you call dbmopen():
1179
1180     use DB_File;
1181     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1182         or die "Can't open netscape history file: $!";
1183
1184 Portability issues: L<perlport/dbmopen>.
1185
1186 =item default BLOCK
1187
1188 Within a C<foreach> or a C<given>, a C<default> BLOCK acts like a C<when>
1189 that's always true.  Only available after Perl 5.10, and only if the
1190 C<switch> feature has been requested or if the keyword is prefixed with
1191 C<CORE::>.  See L</when>.
1192
1193 =item defined EXPR
1194 X<defined> X<undef> X<undefined>
1195
1196 =item defined
1197
1198 Returns a Boolean value telling whether EXPR has a value other than
1199 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1200 checked.
1201
1202 Many operations return C<undef> to indicate failure, end of file,
1203 system error, uninitialized variable, and other exceptional
1204 conditions.  This function allows you to distinguish C<undef> from
1205 other values.  (A simple Boolean test will not distinguish among
1206 C<undef>, zero, the empty string, and C<"0">, which are all equally
1207 false.)  Note that since C<undef> is a valid scalar, its presence
1208 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1209 returns C<undef> when its argument is an empty array, I<or> when the
1210 element to return happens to be C<undef>.
1211
1212 You may also use C<defined(&func)> to check whether subroutine C<&func>
1213 has ever been defined.  The return value is unaffected by any forward
1214 declarations of C<&func>.  A subroutine that is not defined
1215 may still be callable: its package may have an C<AUTOLOAD> method that
1216 makes it spring into existence the first time that it is called; see
1217 L<perlsub>.
1218
1219 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1220 used to report whether memory for that aggregate had ever been
1221 allocated.  This behavior may disappear in future versions of Perl.
1222 You should instead use a simple test for size:
1223
1224     if (@an_array) { print "has array elements\n" }
1225     if (%a_hash)   { print "has hash members\n"   }
1226
1227 When used on a hash element, it tells you whether the value is defined,
1228 not whether the key exists in the hash.  Use L</exists> for the latter
1229 purpose.
1230
1231 Examples:
1232
1233     print if defined $switch{D};
1234     print "$val\n" while defined($val = pop(@ary));
1235     die "Can't readlink $sym: $!"
1236         unless defined($value = readlink $sym);
1237     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1238     $debugging = 0 unless defined $debugging;
1239
1240 Note:  Many folks tend to overuse C<defined> and are then surprised to
1241 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1242 defined values.  For example, if you say
1243
1244     "ab" =~ /a(.*)b/;
1245
1246 The pattern match succeeds and C<$1> is defined, although it
1247 matched "nothing".  It didn't really fail to match anything.  Rather, it
1248 matched something that happened to be zero characters long.  This is all
1249 very above-board and honest.  When a function returns an undefined value,
1250 it's an admission that it couldn't give you an honest answer.  So you
1251 should use C<defined> only when questioning the integrity of what
1252 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1253 what you want.
1254
1255 See also L</undef>, L</exists>, L</ref>.
1256
1257 =item delete EXPR
1258 X<delete>
1259
1260 Given an expression that specifies an element or slice of a hash, C<delete>
1261 deletes the specified elements from that hash so that exists() on that element
1262 no longer returns true.  Setting a hash element to the undefined value does
1263 not remove its key, but deleting it does; see L</exists>.
1264
1265 In list context, returns the value or values deleted, or the last such
1266 element in scalar context.  The return list's length always matches that of
1267 the argument list: deleting non-existent elements returns the undefined value
1268 in their corresponding positions.
1269
1270 delete() may also be used on arrays and array slices, but its behavior is less
1271 straightforward.  Although exists() will return false for deleted entries,
1272 deleting array elements never changes indices of existing values; use shift()
1273 or splice() for that.  However, if all deleted elements fall at the end of an
1274 array, the array's size shrinks to the position of the highest element that
1275 still tests true for exists(), or to 0 if none do.
1276
1277 B<WARNING:> Calling delete on array values is deprecated and likely to
1278 be removed in a future version of Perl.
1279
1280 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1281 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1282 or array may not necessarily return anything; it depends on the implementation
1283 of the C<tied> package's DELETE method, which may do whatever it pleases.
1284
1285 The C<delete local EXPR> construct localizes the deletion to the current
1286 block at run time.  Until the block exits, elements locally deleted
1287 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1288 of composite types">.
1289
1290     %hash = (foo => 11, bar => 22, baz => 33);
1291     $scalar = delete $hash{foo};             # $scalar is 11
1292     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1293     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1294
1295 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1296
1297     foreach $key (keys %HASH) {
1298         delete $HASH{$key};
1299     }
1300
1301     foreach $index (0 .. $#ARRAY) {
1302         delete $ARRAY[$index];
1303     }
1304
1305 And so do these:
1306
1307     delete @HASH{keys %HASH};
1308
1309     delete @ARRAY[0 .. $#ARRAY];
1310
1311 But both are slower than assigning the empty list
1312 or undefining %HASH or @ARRAY, which is the customary 
1313 way to empty out an aggregate:
1314
1315     %HASH = ();     # completely empty %HASH
1316     undef %HASH;    # forget %HASH ever existed
1317
1318     @ARRAY = ();    # completely empty @ARRAY
1319     undef @ARRAY;   # forget @ARRAY ever existed
1320
1321 The EXPR can be arbitrarily complicated provided its
1322 final operation is an element or slice of an aggregate:
1323
1324     delete $ref->[$x][$y]{$key};
1325     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1326
1327     delete $ref->[$x][$y][$index];
1328     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1329
1330 =item die LIST
1331 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1332
1333 C<die> raises an exception.  Inside an C<eval> the error message is stuffed
1334 into C<$@> and the C<eval> is terminated with the undefined value.
1335 If the exception is outside of all enclosing C<eval>s, then the uncaught
1336 exception prints LIST to C<STDERR> and exits with a non-zero value.  If you
1337 need to exit the process with a specific exit code, see L</exit>.
1338
1339 Equivalent examples:
1340
1341     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1342     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1343
1344 If the last element of LIST does not end in a newline, the current
1345 script line number and input line number (if any) are also printed,
1346 and a newline is supplied.  Note that the "input line number" (also
1347 known as "chunk") is subject to whatever notion of "line" happens to
1348 be currently in effect, and is also available as the special variable
1349 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1350
1351 Hint: sometimes appending C<", stopped"> to your message will cause it
1352 to make better sense when the string C<"at foo line 123"> is appended.
1353 Suppose you are running script "canasta".
1354
1355     die "/etc/games is no good";
1356     die "/etc/games is no good, stopped";
1357
1358 produce, respectively
1359
1360     /etc/games is no good at canasta line 123.
1361     /etc/games is no good, stopped at canasta line 123.
1362
1363 If the output is empty and C<$@> already contains a value (typically from a
1364 previous eval) that value is reused after appending C<"\t...propagated">.
1365 This is useful for propagating exceptions:
1366
1367     eval { ... };
1368     die unless $@ =~ /Expected exception/;
1369
1370 If the output is empty and C<$@> contains an object reference that has a
1371 C<PROPAGATE> method, that method will be called with additional file
1372 and line number parameters.  The return value replaces the value in
1373 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1374 were called.
1375
1376 If C<$@> is empty then the string C<"Died"> is used.
1377
1378 If an uncaught exception results in interpreter exit, the exit code is
1379 determined from the values of C<$!> and C<$?> with this pseudocode:
1380
1381     exit $! if $!;              # errno
1382     exit $? >> 8 if $? >> 8;    # child exit status
1383     exit 255;                   # last resort
1384
1385 The intent is to squeeze as much possible information about the likely cause
1386 into the limited space of the system exit
1387 code.  However, as C<$!> is the value
1388 of C's C<errno>, which can be set by any system call, this means that the value
1389 of the exit code used by C<die> can be non-predictable, so should not be relied
1390 upon, other than to be non-zero.
1391
1392 You can also call C<die> with a reference argument, and if this is trapped
1393 within an C<eval>, C<$@> contains that reference.  This permits more
1394 elaborate exception handling using objects that maintain arbitrary state
1395 about the exception.  Such a scheme is sometimes preferable to matching
1396 particular string values of C<$@> with regular expressions.  Because C<$@> 
1397 is a global variable and C<eval> may be used within object implementations,
1398 be careful that analyzing the error object doesn't replace the reference in
1399 the global variable.  It's easiest to make a local copy of the reference
1400 before any manipulations.  Here's an example:
1401
1402     use Scalar::Util "blessed";
1403
1404     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1405     if (my $ev_err = $@) {
1406         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1407             # handle Some::Module::Exception
1408         }
1409         else {
1410             # handle all other possible exceptions
1411         }
1412     }
1413
1414 Because Perl stringifies uncaught exception messages before display,
1415 you'll probably want to overload stringification operations on
1416 exception objects.  See L<overload> for details about that.
1417
1418 You can arrange for a callback to be run just before the C<die>
1419 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1420 handler is called with the error text and can change the error
1421 message, if it sees fit, by calling C<die> again.  See
1422 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1423 L<"eval BLOCK"> for some examples.  Although this feature was 
1424 to be run only right before your program was to exit, this is not
1425 currently so: the C<$SIG{__DIE__}> hook is currently called
1426 even inside eval()ed blocks/strings!  If one wants the hook to do
1427 nothing in such situations, put
1428
1429     die @_ if $^S;
1430
1431 as the first line of the handler (see L<perlvar/$^S>).  Because
1432 this promotes strange action at a distance, this counterintuitive
1433 behavior may be fixed in a future release.
1434
1435 See also exit(), warn(), and the Carp module.
1436
1437 =item do BLOCK
1438 X<do> X<block>
1439
1440 Not really a function.  Returns the value of the last command in the
1441 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1442 C<until> loop modifier, executes the BLOCK once before testing the loop
1443 condition.  (On other statements the loop modifiers test the conditional
1444 first.)
1445
1446 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1447 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1448 See L<perlsyn> for alternative strategies.
1449
1450 =item do SUBROUTINE(LIST)
1451 X<do>
1452
1453 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword,
1454 a scalar variable or a subroutine beginning with C<&>.
1455
1456 =item do EXPR
1457 X<do>
1458
1459 Uses the value of EXPR as a filename and executes the contents of the
1460 file as a Perl script.
1461
1462     do 'stat.pl';
1463
1464 is just like
1465
1466     eval `cat stat.pl`;
1467
1468 except that it's more efficient and concise, keeps track of the current
1469 filename for error messages, searches the C<@INC> directories, and updates
1470 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1471 these variables.  It also differs in that code evaluated with C<do FILENAME>
1472 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1473 same, however, in that it does reparse the file every time you call it,
1474 so you probably don't want to do this inside a loop.
1475
1476 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1477 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1478 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1479 could fail in a way that also sets C<$!>.  If the file is successfully
1480 compiled, C<do> returns the value of the last expression evaluated.
1481
1482 Inclusion of library modules is better done with the
1483 C<use> and C<require> operators, which also do automatic error checking
1484 and raise an exception if there's a problem.
1485
1486 You might like to use C<do> to read in a program configuration
1487 file.  Manual error checking can be done this way:
1488
1489     # read in config files: system first, then user
1490     for $file ("/share/prog/defaults.rc",
1491                "$ENV{HOME}/.someprogrc")
1492     {
1493         unless ($return = do $file) {
1494             warn "couldn't parse $file: $@" if $@;
1495             warn "couldn't do $file: $!"    unless defined $return;
1496             warn "couldn't run $file"       unless $return;
1497         }
1498     }
1499
1500 =item dump LABEL
1501 X<dump> X<core> X<undump>
1502
1503 =item dump
1504
1505 This function causes an immediate core dump.  See also the B<-u>
1506 command-line switch in L<perlrun>, which does the same thing.
1507 Primarily this is so that you can use the B<undump> program (not
1508 supplied) to turn your core dump into an executable binary after
1509 having initialized all your variables at the beginning of the
1510 program.  When the new binary is executed it will begin by executing
1511 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1512 Think of it as a goto with an intervening core dump and reincarnation.
1513 If C<LABEL> is omitted, restarts the program from the top.
1514
1515 B<WARNING>: Any files opened at the time of the dump will I<not>
1516 be open any more when the program is reincarnated, with possible
1517 resulting confusion by Perl.
1518
1519 This function is now largely obsolete, mostly because it's very hard to
1520 convert a core file into an executable.  That's why you should now invoke
1521 it as C<CORE::dump()>, if you don't want to be warned against a possible
1522 typo.
1523
1524 Portability issues: L<perlport/dump>.
1525
1526 =item each HASH
1527 X<each> X<hash, iterator>
1528
1529 =item each ARRAY
1530 X<array, iterator>
1531
1532 =item each EXPR
1533
1534 When called on a hash in list context, returns a 2-element list
1535 consisting of the key and value for the next element of a hash.  In Perl
1536 5.12 and later only, it will also return the index and value for the next
1537 element of an array so that you can iterate over it; older Perls consider
1538 this a syntax error.  When called in scalar context, returns only the key
1539 (not the value) in a hash, or the index in an array.
1540
1541 Hash entries are returned in an apparently random order.  The actual random
1542 order is subject to change in future versions of Perl, but it is
1543 guaranteed to be in the same order as either the C<keys> or C<values>
1544 function would produce on the same (unmodified) hash.  Since Perl
1545 5.8.2 the ordering can be different even between different runs of Perl
1546 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1547
1548 After C<each> has returned all entries from the hash or array, the next
1549 call to C<each> returns the empty list in list context and C<undef> in
1550 scalar context; the next call following I<that> one restarts iteration.
1551 Each hash or array has its own internal iterator, accessed by C<each>,
1552 C<keys>, and C<values>.  The iterator is implicitly reset when C<each> has
1553 reached the end as just described; it can be explicitly reset by calling
1554 C<keys> or C<values> on the hash or array.  If you add or delete a hash's
1555 elements while iterating over it, entries may be skipped or duplicated--so
1556 don't do that.  Exception: In the current implementation, it is always safe
1557 to delete the item most recently returned by C<each()>, so the following
1558 code works properly:
1559
1560         while (($key, $value) = each %hash) {
1561           print $key, "\n";
1562           delete $hash{$key};   # This is safe
1563         }
1564
1565 This prints out your environment like the printenv(1) program,
1566 but in a different order:
1567
1568     while (($key,$value) = each %ENV) {
1569         print "$key=$value\n";
1570     }
1571
1572 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1573 reference to an unblessed hash or array.  The argument will be dereferenced
1574 automatically.  This aspect of C<each> is considered highly experimental.
1575 The exact behaviour may change in a future version of Perl.
1576
1577     while (($key,$value) = each $hashref) { ... }
1578
1579 To avoid confusing would-be users of your code who are running earlier
1580 versions of Perl with mysterious syntax errors, put this sort of thing at
1581 the top of your file to signal that your code will work I<only> on Perls of
1582 a recent vintage:
1583
1584     use 5.012;  # so keys/values/each work on arrays
1585     use 5.014;  # so keys/values/each work on scalars (experimental)
1586
1587 See also C<keys>, C<values>, and C<sort>.
1588
1589 =item eof FILEHANDLE
1590 X<eof>
1591 X<end of file>
1592 X<end-of-file>
1593
1594 =item eof ()
1595
1596 =item eof
1597
1598 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1599 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1600 gives the real filehandle.  (Note that this function actually
1601 reads a character and then C<ungetc>s it, so isn't useful in an
1602 interactive context.)  Do not read from a terminal file (or call
1603 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1604 as terminals may lose the end-of-file condition if you do.
1605
1606 An C<eof> without an argument uses the last file read.  Using C<eof()>
1607 with empty parentheses is different.  It refers to the pseudo file
1608 formed from the files listed on the command line and accessed via the
1609 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1610 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1611 used will cause C<@ARGV> to be examined to determine if input is
1612 available.   Similarly, an C<eof()> after C<< <> >> has returned
1613 end-of-file will assume you are processing another C<@ARGV> list,
1614 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1615 see L<perlop/"I/O Operators">.
1616
1617 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1618 detect the end of each file, whereas C<eof()> will detect the end 
1619 of the very last file only.  Examples:
1620
1621     # reset line numbering on each input file
1622     while (<>) {
1623         next if /^\s*#/;  # skip comments
1624         print "$.\t$_";
1625     } continue {
1626         close ARGV if eof;  # Not eof()!
1627     }
1628
1629     # insert dashes just before last line of last file
1630     while (<>) {
1631         if (eof()) {  # check for end of last file
1632             print "--------------\n";
1633         }
1634         print;
1635         last if eof();      # needed if we're reading from a terminal
1636     }
1637
1638 Practical hint: you almost never need to use C<eof> in Perl, because the
1639 input operators typically return C<undef> when they run out of data or 
1640 encounter an error.
1641
1642 =item eval EXPR
1643 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1644 X<error, handling> X<exception, handling>
1645
1646 =item eval BLOCK
1647
1648 =item eval
1649
1650 In the first form, the return value of EXPR is parsed and executed as if it
1651 were a little Perl program.  The value of the expression (which is itself
1652 determined within scalar context) is first parsed, and if there were no
1653 errors, executed as a block within the lexical context of the current Perl
1654 program.  This means, that in particular, any outer lexical variables are
1655 visible to it, and any package variable settings or subroutine and format
1656 definitions remain afterwards.
1657
1658 Note that the value is parsed every time the C<eval> executes.
1659 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1660 delay parsing and subsequent execution of the text of EXPR until run time.
1661
1662 If the C<unicode_eval> feature is enabled (which is the default under a
1663 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1664 characters, so C<use utf8> declarations have no effect, and source filters
1665 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1666 will sometimes be treated as characters and sometimes as bytes, depending
1667 on the internal encoding, and source filters activated within the C<eval>
1668 exhibit the erratic, but historical, behaviour of affecting some outer file
1669 scope that is still compiling.  See also the L</evalbytes> keyword, which
1670 always treats its input as a byte stream and works properly with source
1671 filters, and the L<feature> pragma.
1672
1673 In the second form, the code within the BLOCK is parsed only once--at the
1674 same time the code surrounding the C<eval> itself was parsed--and executed
1675 within the context of the current Perl program.  This form is typically
1676 used to trap exceptions more efficiently than the first (see below), while
1677 also providing the benefit of checking the code within BLOCK at compile
1678 time.
1679
1680 The final semicolon, if any, may be omitted from the value of EXPR or within
1681 the BLOCK.
1682
1683 In both forms, the value returned is the value of the last expression
1684 evaluated inside the mini-program; a return statement may be also used, just
1685 as with subroutines.  The expression providing the return value is evaluated
1686 in void, scalar, or list context, depending on the context of the C<eval> 
1687 itself.  See L</wantarray> for more on how the evaluation context can be 
1688 determined.
1689
1690 If there is a syntax error or runtime error, or a C<die> statement is
1691 executed, C<eval> returns C<undef> in scalar context
1692 or an empty list in list context, and C<$@> is set to the error
1693 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1694 in list context for syntax errors, but not for runtime errors.)
1695 If there was no error, C<$@> is set to the empty string.  A
1696 control flow operator like C<last> or C<goto> can bypass the setting of
1697 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1698 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1699 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1700 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1701 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1702
1703 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1704 determining whether a particular feature (such as C<socket> or C<symlink>)
1705 is implemented.  It is also Perl's exception-trapping mechanism, where
1706 the die operator is used to raise exceptions.
1707
1708 If you want to trap errors when loading an XS module, some problems with
1709 the binary interface (such as Perl version skew) may be fatal even with
1710 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1711
1712 If the code to be executed doesn't vary, you may use the eval-BLOCK
1713 form to trap run-time errors without incurring the penalty of
1714 recompiling each time.  The error, if any, is still returned in C<$@>.
1715 Examples:
1716
1717     # make divide-by-zero nonfatal
1718     eval { $answer = $a / $b; }; warn $@ if $@;
1719
1720     # same thing, but less efficient
1721     eval '$answer = $a / $b'; warn $@ if $@;
1722
1723     # a compile-time error
1724     eval { $answer = }; # WRONG
1725
1726     # a run-time error
1727     eval '$answer =';   # sets $@
1728
1729 Using the C<eval{}> form as an exception trap in libraries does have some
1730 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1731 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1732 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1733 as this example shows:
1734
1735     # a private exception trap for divide-by-zero
1736     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1737     warn $@ if $@;
1738
1739 This is especially significant, given that C<__DIE__> hooks can call
1740 C<die> again, which has the effect of changing their error messages:
1741
1742     # __DIE__ hooks may modify error messages
1743     {
1744        local $SIG{'__DIE__'} =
1745               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1746        eval { die "foo lives here" };
1747        print $@ if $@;                # prints "bar lives here"
1748     }
1749
1750 Because this promotes action at a distance, this counterintuitive behavior
1751 may be fixed in a future release.
1752
1753 With an C<eval>, you should be especially careful to remember what's
1754 being looked at when:
1755
1756     eval $x;        # CASE 1
1757     eval "$x";      # CASE 2
1758
1759     eval '$x';      # CASE 3
1760     eval { $x };    # CASE 4
1761
1762     eval "\$$x++";  # CASE 5
1763     $$x++;          # CASE 6
1764
1765 Cases 1 and 2 above behave identically: they run the code contained in
1766 the variable $x.  (Although case 2 has misleading double quotes making
1767 the reader wonder what else might be happening (nothing is).)  Cases 3
1768 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1769 does nothing but return the value of $x.  (Case 4 is preferred for
1770 purely visual reasons, but it also has the advantage of compiling at
1771 compile-time instead of at run-time.)  Case 5 is a place where
1772 normally you I<would> like to use double quotes, except that in this
1773 particular situation, you can just use symbolic references instead, as
1774 in case 6.
1775
1776 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1777 of localized variables, which means that for your code to run on older
1778 versions, a temporary is required if you want to mask some but not all
1779 errors:
1780
1781     # alter $@ on nefarious repugnancy only
1782     {
1783        my $e;
1784        {
1785           local $@; # protect existing $@
1786           eval { test_repugnancy() };
1787           # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1788           $@ =~ /nefarious/ and $e = $@;
1789        }
1790        die $e if defined $e
1791     }
1792
1793 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1794 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1795
1796 An C<eval ''> executed within the C<DB> package doesn't see the usual
1797 surrounding lexical scope, but rather the scope of the first non-DB piece
1798 of code that called it.  You don't normally need to worry about this unless
1799 you are writing a Perl debugger.
1800
1801 =item evalbytes EXPR
1802 X<evalbytes>
1803
1804 =item evalbytes
1805
1806 This function is like L</eval> with a string argument, except it always
1807 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1808 string containing characters whose ordinal value exceeds 255 results in an
1809 error.  Source filters activated within the evaluated code apply to the
1810 code itself.
1811
1812 This function is only available under the C<evalbytes> feature, a
1813 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1814 L<feature> for more information.
1815
1816 =item exec LIST
1817 X<exec> X<execute>
1818
1819 =item exec PROGRAM LIST
1820
1821 The C<exec> function executes a system command I<and never returns>;
1822 use C<system> instead of C<exec> if you want it to return.  It fails and
1823 returns false only if the command does not exist I<and> it is executed
1824 directly instead of via your system's command shell (see below).
1825
1826 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1827 warns you if there is a following statement that isn't C<die>, C<warn>,
1828 or C<exit> (if C<-w> is set--but you always do that, right?).   If you
1829 I<really> want to follow an C<exec> with some other statement, you
1830 can use one of these styles to avoid the warning:
1831
1832     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1833     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1834
1835 If there is more than one argument in LIST, or if LIST is an array
1836 with more than one value, calls execvp(3) with the arguments in LIST.
1837 If there is only one scalar argument or an array with one element in it,
1838 the argument is checked for shell metacharacters, and if there are any,
1839 the entire argument is passed to the system's command shell for parsing
1840 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1841 If there are no shell metacharacters in the argument, it is split into
1842 words and passed directly to C<execvp>, which is more efficient.
1843 Examples:
1844
1845     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1846     exec "sort $outfile | uniq";
1847
1848 If you don't really want to execute the first argument, but want to lie
1849 to the program you are executing about its own name, you can specify
1850 the program you actually want to run as an "indirect object" (without a
1851 comma) in front of the LIST.  (This always forces interpretation of the
1852 LIST as a multivalued list, even if there is only a single scalar in
1853 the list.)  Example:
1854
1855     $shell = '/bin/csh';
1856     exec $shell '-sh';    # pretend it's a login shell
1857
1858 or, more directly,
1859
1860     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1861
1862 When the arguments get executed via the system shell, results are
1863 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1864 for details.
1865
1866 Using an indirect object with C<exec> or C<system> is also more
1867 secure.  This usage (which also works fine with system()) forces
1868 interpretation of the arguments as a multivalued list, even if the
1869 list had just one argument.  That way you're safe from the shell
1870 expanding wildcards or splitting up words with whitespace in them.
1871
1872     @args = ( "echo surprise" );
1873
1874     exec @args;               # subject to shell escapes
1875                                 # if @args == 1
1876     exec { $args[0] } @args;  # safe even with one-arg list
1877
1878 The first version, the one without the indirect object, ran the I<echo>
1879 program, passing it C<"surprise"> an argument.  The second version didn't;
1880 it tried to run a program named I<"echo surprise">, didn't find it, and set
1881 C<$?> to a non-zero value indicating failure.
1882
1883 Beginning with v5.6.0, Perl attempts to flush all files opened for
1884 output before the exec, but this may not be supported on some platforms
1885 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1886 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1887 open handles to avoid lost output.
1888
1889 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1890 C<DESTROY> methods on your objects.
1891
1892 Portability issues: L<perlport/exec>.
1893
1894 =item exists EXPR
1895 X<exists> X<autovivification>
1896
1897 Given an expression that specifies an element of a hash, returns true if the
1898 specified element in the hash has ever been initialized, even if the
1899 corresponding value is undefined.
1900
1901     print "Exists\n"    if exists $hash{$key};
1902     print "Defined\n"   if defined $hash{$key};
1903     print "True\n"      if $hash{$key};
1904
1905 exists may also be called on array elements, but its behavior is much less
1906 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
1907 that calling exists on array values is deprecated and likely to be removed in
1908 a future version of Perl.
1909
1910     print "Exists\n"    if exists $array[$index];
1911     print "Defined\n"   if defined $array[$index];
1912     print "True\n"      if $array[$index];
1913
1914 A hash or array element can be true only if it's defined and defined only if
1915 it exists, but the reverse doesn't necessarily hold true.
1916
1917 Given an expression that specifies the name of a subroutine,
1918 returns true if the specified subroutine has ever been declared, even
1919 if it is undefined.  Mentioning a subroutine name for exists or defined
1920 does not count as declaring it.  Note that a subroutine that does not
1921 exist may still be callable: its package may have an C<AUTOLOAD>
1922 method that makes it spring into existence the first time that it is
1923 called; see L<perlsub>.
1924
1925     print "Exists\n"  if exists &subroutine;
1926     print "Defined\n" if defined &subroutine;
1927
1928 Note that the EXPR can be arbitrarily complicated as long as the final
1929 operation is a hash or array key lookup or subroutine name:
1930
1931     if (exists $ref->{A}->{B}->{$key})  { }
1932     if (exists $hash{A}{B}{$key})       { }
1933
1934     if (exists $ref->{A}->{B}->[$ix])   { }
1935     if (exists $hash{A}{B}[$ix])        { }
1936
1937     if (exists &{$ref->{A}{B}{$key}})   { }
1938
1939 Although the mostly deeply nested array or hash will not spring into
1940 existence just because its existence was tested, any intervening ones will.
1941 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1942 into existence due to the existence test for the $key element above.
1943 This happens anywhere the arrow operator is used, including even here:
1944
1945     undef $ref;
1946     if (exists $ref->{"Some key"})    { }
1947     print $ref;  # prints HASH(0x80d3d5c)
1948
1949 This surprising autovivification in what does not at first--or even
1950 second--glance appear to be an lvalue context may be fixed in a future
1951 release.
1952
1953 Use of a subroutine call, rather than a subroutine name, as an argument
1954 to exists() is an error.
1955
1956     exists &sub;    # OK
1957     exists &sub();  # Error
1958
1959 =item exit EXPR
1960 X<exit> X<terminate> X<abort>
1961
1962 =item exit
1963
1964 Evaluates EXPR and exits immediately with that value.    Example:
1965
1966     $ans = <STDIN>;
1967     exit 0 if $ans =~ /^[Xx]/;
1968
1969 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1970 universally recognized values for EXPR are C<0> for success and C<1>
1971 for error; other values are subject to interpretation depending on the
1972 environment in which the Perl program is running.  For example, exiting
1973 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1974 the mailer to return the item undelivered, but that's not true everywhere.
1975
1976 Don't use C<exit> to abort a subroutine if there's any chance that
1977 someone might want to trap whatever error happened.  Use C<die> instead,
1978 which can be trapped by an C<eval>.
1979
1980 The exit() function does not always exit immediately.  It calls any
1981 defined C<END> routines first, but these C<END> routines may not
1982 themselves abort the exit.  Likewise any object destructors that need to
1983 be called are called before the real exit.  C<END> routines and destructors
1984 can change the exit status by modifying C<$?>.  If this is a problem, you
1985 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1986 See L<perlmod> for details.
1987
1988 Portability issues: L<perlport/exit>.
1989
1990 =item exp EXPR
1991 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1992
1993 =item exp
1994
1995 Returns I<e> (the natural logarithm base) to the power of EXPR.
1996 If EXPR is omitted, gives C<exp($_)>.
1997
1998 =item fc EXPR
1999 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2000
2001 =item fc
2002
2003 Returns the casefolded version of EXPR.  This is the internal function
2004 implementing the C<\F> escape in double-quoted strings.
2005
2006 Casefolding is the process of mapping strings to a form where case
2007 differences are erased; comparing two strings in their casefolded
2008 form is effectively a way of asking if two strings are equal,
2009 regardless of case.
2010
2011 Roughly, if you ever found yourself writing this
2012
2013     lc($this) eq lc($that)  # Wrong!
2014         # or
2015     uc($this) eq uc($that)  # Also wrong!
2016         # or
2017     $this =~ /\Q$that/i     # Right!
2018
2019 Now you can write
2020
2021     fc($this) eq fc($that)
2022
2023 And get the correct results.
2024
2025 Perl only implements the full form of casefolding.
2026 For further information on casefolding, refer to
2027 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2028 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2029 available at L<http://www.unicode.org/versions/latest/>, as well as the
2030 Case Charts available at L<http://www.unicode.org/charts/case/>.
2031
2032 If EXPR is omitted, uses C<$_>.
2033
2034 This function behaves the same way under various pragma, such as in a locale,
2035 as L</lc> does.
2036
2037 While the Unicode Standard defines two additional forms of casefolding,
2038 one for Turkic languages and one that never maps one character into multiple
2039 characters, these are not provided by the Perl core; However, the CPAN module
2040 C<Unicode::Casing> may be used to provide an implementation.
2041
2042 This keyword is available only when the C<"fc"> feature is enabled,
2043 or when prefixed with C<CORE::>; See L<feature>. Alternately,
2044 include a C<use v5.16> or later to the current scope.
2045
2046 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2047 X<fcntl>
2048
2049 Implements the fcntl(2) function.  You'll probably have to say
2050
2051     use Fcntl;
2052
2053 first to get the correct constant definitions.  Argument processing and
2054 value returned work just like C<ioctl> below.
2055 For example:
2056
2057     use Fcntl;
2058     fcntl($filehandle, F_GETFL, $packed_return_buffer)
2059         or die "can't fcntl F_GETFL: $!";
2060
2061 You don't have to check for C<defined> on the return from C<fcntl>.
2062 Like C<ioctl>, it maps a C<0> return from the system call into
2063 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
2064 in numeric context.  It is also exempt from the normal B<-w> warnings
2065 on improper numeric conversions.
2066
2067 Note that C<fcntl> raises an exception if used on a machine that
2068 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2069 manpage to learn what functions are available on your system.
2070
2071 Here's an example of setting a filehandle named C<REMOTE> to be
2072 non-blocking at the system level.  You'll have to negotiate C<$|>
2073 on your own, though.
2074
2075     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2076
2077     $flags = fcntl(REMOTE, F_GETFL, 0)
2078                 or die "Can't get flags for the socket: $!\n";
2079
2080     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2081                 or die "Can't set flags for the socket: $!\n";
2082
2083 Portability issues: L<perlport/fcntl>.
2084
2085 =item __FILE__
2086 X<__FILE__>
2087
2088 A special token that returns the name of the file in which it occurs.
2089
2090 =item fileno FILEHANDLE
2091 X<fileno>
2092
2093 Returns the file descriptor for a filehandle, or undefined if the
2094 filehandle is not open.  If there is no real file descriptor at the OS
2095 level, as can happen with filehandles connected to memory objects via
2096 C<open> with a reference for the third argument, -1 is returned.
2097
2098 This is mainly useful for constructing
2099 bitmaps for C<select> and low-level POSIX tty-handling operations.
2100 If FILEHANDLE is an expression, the value is taken as an indirect
2101 filehandle, generally its name.
2102
2103 You can use this to find out whether two handles refer to the
2104 same underlying descriptor:
2105
2106     if (fileno(THIS) == fileno(THAT)) {
2107         print "THIS and THAT are dups\n";
2108     }
2109
2110 =item flock FILEHANDLE,OPERATION
2111 X<flock> X<lock> X<locking>
2112
2113 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2114 for success, false on failure.  Produces a fatal error if used on a
2115 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2116 C<flock> is Perl's portable file-locking interface, although it locks
2117 entire files only, not records.
2118
2119 Two potentially non-obvious but traditional C<flock> semantics are
2120 that it waits indefinitely until the lock is granted, and that its locks
2121 are B<merely advisory>.  Such discretionary locks are more flexible, but
2122 offer fewer guarantees.  This means that programs that do not also use
2123 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2124 your port's specific documentation, and your system-specific local manpages
2125 for details.  It's best to assume traditional behavior if you're writing
2126 portable programs.  (But if you're not, you should as always feel perfectly
2127 free to write for your own system's idiosyncrasies (sometimes called
2128 "features").  Slavish adherence to portability concerns shouldn't get
2129 in the way of your getting your job done.)
2130
2131 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2132 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2133 you can use the symbolic names if you import them from the L<Fcntl> module,
2134 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2135 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2136 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2137 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2138 waiting for the lock; check the return status to see if you got it.
2139
2140 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2141 before locking or unlocking it.
2142
2143 Note that the emulation built with lockf(3) doesn't provide shared
2144 locks, and it requires that FILEHANDLE be open with write intent.  These
2145 are the semantics that lockf(3) implements.  Most if not all systems
2146 implement lockf(3) in terms of fcntl(2) locking, though, so the
2147 differing semantics shouldn't bite too many people.
2148
2149 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2150 be open with read intent to use LOCK_SH and requires that it be open
2151 with write intent to use LOCK_EX.
2152
2153 Note also that some versions of C<flock> cannot lock things over the
2154 network; you would need to use the more system-specific C<fcntl> for
2155 that.  If you like you can force Perl to ignore your system's flock(2)
2156 function, and so provide its own fcntl(2)-based emulation, by passing
2157 the switch C<-Ud_flock> to the F<Configure> program when you configure
2158 and build a new Perl.
2159
2160 Here's a mailbox appender for BSD systems.
2161
2162     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
2163
2164     sub lock {
2165         my ($fh) = @_;
2166         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2167
2168         # and, in case someone appended while we were waiting...
2169         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2170     }
2171
2172     sub unlock {
2173         my ($fh) = @_;
2174         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2175     }
2176
2177     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2178         or die "Can't open mailbox: $!";
2179
2180     lock($mbox);
2181     print $mbox $msg,"\n\n";
2182     unlock($mbox);
2183
2184 On systems that support a real flock(2), locks are inherited across fork()
2185 calls, whereas those that must resort to the more capricious fcntl(2)
2186 function lose their locks, making it seriously harder to write servers.
2187
2188 See also L<DB_File> for other flock() examples.
2189
2190 Portability issues: L<perlport/flock>.
2191
2192 =item fork
2193 X<fork> X<child> X<parent>
2194
2195 Does a fork(2) system call to create a new process running the
2196 same program at the same point.  It returns the child pid to the
2197 parent process, C<0> to the child process, or C<undef> if the fork is
2198 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2199 are shared, while everything else is copied.  On most systems supporting
2200 fork(), great care has gone into making it extremely efficient (for
2201 example, using copy-on-write technology on data pages), making it the
2202 dominant paradigm for multitasking over the last few decades.
2203
2204 Beginning with v5.6.0, Perl attempts to flush all files opened for
2205 output before forking the child process, but this may not be supported
2206 on some platforms (see L<perlport>).  To be safe, you may need to set
2207 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2208 C<IO::Handle> on any open handles to avoid duplicate output.
2209
2210 If you C<fork> without ever waiting on your children, you will
2211 accumulate zombies.  On some systems, you can avoid this by setting
2212 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2213 forking and reaping moribund children.
2214
2215 Note that if your forked child inherits system file descriptors like
2216 STDIN and STDOUT that are actually connected by a pipe or socket, even
2217 if you exit, then the remote server (such as, say, a CGI script or a
2218 backgrounded job launched from a remote shell) won't think you're done.
2219 You should reopen those to F</dev/null> if it's any issue.
2220
2221 On some platforms such as Windows, where the fork() system call is not available,
2222 Perl can be built to emulate fork() in the Perl interpreter.
2223 The emulation is designed, at the level of the Perl program,
2224 to be as compatible as possible with the "Unix" fork().
2225 However it has limitations that have to be considered in code intended to be portable.
2226 See L<perlfork> for more details.
2227
2228 Portability issues: L<perlport/fork>.
2229
2230 =item format
2231 X<format>
2232
2233 Declare a picture format for use by the C<write> function.  For
2234 example:
2235
2236     format Something =
2237         Test: @<<<<<<<< @||||| @>>>>>
2238               $str,     $%,    '$' . int($num)
2239     .
2240
2241     $str = "widget";
2242     $num = $cost/$quantity;
2243     $~ = 'Something';
2244     write;
2245
2246 See L<perlform> for many details and examples.
2247
2248 =item formline PICTURE,LIST
2249 X<formline>
2250
2251 This is an internal function used by C<format>s, though you may call it,
2252 too.  It formats (see L<perlform>) a list of values according to the
2253 contents of PICTURE, placing the output into the format output
2254 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2255 Eventually, when a C<write> is done, the contents of
2256 C<$^A> are written to some filehandle.  You could also read C<$^A>
2257 and then set C<$^A> back to C<"">.  Note that a format typically
2258 does one C<formline> per line of form, but the C<formline> function itself
2259 doesn't care how many newlines are embedded in the PICTURE.  This means
2260 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2261 You may therefore need to use multiple formlines to implement a single
2262 record format, just like the C<format> compiler.
2263
2264 Be careful if you put double quotes around the picture, because an C<@>
2265 character may be taken to mean the beginning of an array name.
2266 C<formline> always returns true.  See L<perlform> for other examples.
2267
2268 If you are trying to use this instead of C<write> to capture the output,
2269 you may find it easier to open a filehandle to a scalar
2270 (C<< open $fh, ">", \$output >>) and write to that instead.
2271
2272 =item getc FILEHANDLE
2273 X<getc> X<getchar> X<character> X<file, read>
2274
2275 =item getc
2276
2277 Returns the next character from the input file attached to FILEHANDLE,
2278 or the undefined value at end of file or if there was an error (in
2279 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2280 STDIN.  This is not particularly efficient.  However, it cannot be
2281 used by itself to fetch single characters without waiting for the user
2282 to hit enter.  For that, try something more like:
2283
2284     if ($BSD_STYLE) {
2285         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2286     }
2287     else {
2288         system "stty", '-icanon', 'eol', "\001";
2289     }
2290
2291     $key = getc(STDIN);
2292
2293     if ($BSD_STYLE) {
2294         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2295     }
2296     else {
2297         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2298     }
2299     print "\n";
2300
2301 Determination of whether $BSD_STYLE should be set
2302 is left as an exercise to the reader.
2303
2304 The C<POSIX::getattr> function can do this more portably on
2305 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2306 module from your nearest CPAN site; details on CPAN can be found under
2307 L<perlmodlib/CPAN>.
2308
2309 =item getlogin
2310 X<getlogin> X<login>
2311
2312 This implements the C library function of the same name, which on most
2313 systems returns the current login from F</etc/utmp>, if any.  If it
2314 returns the empty string, use C<getpwuid>.
2315
2316     $login = getlogin || getpwuid($<) || "Kilroy";
2317
2318 Do not consider C<getlogin> for authentication: it is not as
2319 secure as C<getpwuid>.
2320
2321 Portability issues: L<perlport/getlogin>.
2322
2323 =item getpeername SOCKET
2324 X<getpeername> X<peer>
2325
2326 Returns the packed sockaddr address of the other end of the SOCKET
2327 connection.
2328
2329     use Socket;
2330     $hersockaddr    = getpeername(SOCK);
2331     ($port, $iaddr) = sockaddr_in($hersockaddr);
2332     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2333     $herstraddr     = inet_ntoa($iaddr);
2334
2335 =item getpgrp PID
2336 X<getpgrp> X<group>
2337
2338 Returns the current process group for the specified PID.  Use
2339 a PID of C<0> to get the current process group for the
2340 current process.  Will raise an exception if used on a machine that
2341 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2342 group of the current process.  Note that the POSIX version of C<getpgrp>
2343 does not accept a PID argument, so only C<PID==0> is truly portable.
2344
2345 Portability issues: L<perlport/getpgrp>.
2346
2347 =item getppid
2348 X<getppid> X<parent> X<pid>
2349
2350 Returns the process id of the parent process.
2351
2352 Note for Linux users: on Linux, the C functions C<getpid()> and
2353 C<getppid()> return different values from different threads.  In order to
2354 be portable, this behavior is not reflected by the Perl-level function
2355 C<getppid()>, that returns a consistent value across threads.  If you want
2356 to call the underlying C<getppid()>, you may use the CPAN module
2357 C<Linux::Pid>.
2358
2359 Portability issues: L<perlport/getppid>.
2360
2361 =item getpriority WHICH,WHO
2362 X<getpriority> X<priority> X<nice>
2363
2364 Returns the current priority for a process, a process group, or a user.
2365 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2366 machine that doesn't implement getpriority(2).
2367
2368 Portability issues: L<perlport/getpriority>.
2369
2370 =item getpwnam NAME
2371 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2372 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2373 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2374 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2375 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2376 X<endnetent> X<endprotoent> X<endservent> 
2377
2378 =item getgrnam NAME
2379
2380 =item gethostbyname NAME
2381
2382 =item getnetbyname NAME
2383
2384 =item getprotobyname NAME
2385
2386 =item getpwuid UID
2387
2388 =item getgrgid GID
2389
2390 =item getservbyname NAME,PROTO
2391
2392 =item gethostbyaddr ADDR,ADDRTYPE
2393
2394 =item getnetbyaddr ADDR,ADDRTYPE
2395
2396 =item getprotobynumber NUMBER
2397
2398 =item getservbyport PORT,PROTO
2399
2400 =item getpwent
2401
2402 =item getgrent
2403
2404 =item gethostent
2405
2406 =item getnetent
2407
2408 =item getprotoent
2409
2410 =item getservent
2411
2412 =item setpwent
2413
2414 =item setgrent
2415
2416 =item sethostent STAYOPEN
2417
2418 =item setnetent STAYOPEN
2419
2420 =item setprotoent STAYOPEN
2421
2422 =item setservent STAYOPEN
2423
2424 =item endpwent
2425
2426 =item endgrent
2427
2428 =item endhostent
2429
2430 =item endnetent
2431
2432 =item endprotoent
2433
2434 =item endservent
2435
2436 These routines are the same as their counterparts in the
2437 system C library.  In list context, the return values from the
2438 various get routines are as follows:
2439
2440     ($name,$passwd,$uid,$gid,
2441        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2442     ($name,$passwd,$gid,$members) = getgr*
2443     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2444     ($name,$aliases,$addrtype,$net) = getnet*
2445     ($name,$aliases,$proto) = getproto*
2446     ($name,$aliases,$port,$proto) = getserv*
2447
2448 (If the entry doesn't exist you get an empty list.)
2449
2450 The exact meaning of the $gcos field varies but it usually contains
2451 the real name of the user (as opposed to the login name) and other
2452 information pertaining to the user.  Beware, however, that in many
2453 system users are able to change this information and therefore it
2454 cannot be trusted and therefore the $gcos is tainted (see
2455 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2456 login shell, are also tainted, for the same reason.
2457
2458 In scalar context, you get the name, unless the function was a
2459 lookup by name, in which case you get the other thing, whatever it is.
2460 (If the entry doesn't exist you get the undefined value.)  For example:
2461
2462     $uid   = getpwnam($name);
2463     $name  = getpwuid($num);
2464     $name  = getpwent();
2465     $gid   = getgrnam($name);
2466     $name  = getgrgid($num);
2467     $name  = getgrent();
2468     #etc.
2469
2470 In I<getpw*()> the fields $quota, $comment, and $expire are special
2471 in that they are unsupported on many systems.  If the
2472 $quota is unsupported, it is an empty scalar.  If it is supported, it
2473 usually encodes the disk quota.  If the $comment field is unsupported,
2474 it is an empty scalar.  If it is supported it usually encodes some
2475 administrative comment about the user.  In some systems the $quota
2476 field may be $change or $age, fields that have to do with password
2477 aging.  In some systems the $comment field may be $class.  The $expire
2478 field, if present, encodes the expiration period of the account or the
2479 password.  For the availability and the exact meaning of these fields
2480 in your system, please consult getpwnam(3) and your system's 
2481 F<pwd.h> file.  You can also find out from within Perl what your
2482 $quota and $comment fields mean and whether you have the $expire field
2483 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2484 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2485 files are supported only if your vendor has implemented them in the
2486 intuitive fashion that calling the regular C library routines gets the
2487 shadow versions if you're running under privilege or if there exists
2488 the shadow(3) functions as found in System V (this includes Solaris
2489 and Linux).  Those systems that implement a proprietary shadow password
2490 facility are unlikely to be supported.
2491
2492 The $members value returned by I<getgr*()> is a space-separated list of
2493 the login names of the members of the group.
2494
2495 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2496 C, it will be returned to you via C<$?> if the function call fails.  The
2497 C<@addrs> value returned by a successful call is a list of raw
2498 addresses returned by the corresponding library call.  In the
2499 Internet domain, each address is four bytes long; you can unpack it
2500 by saying something like:
2501
2502     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2503
2504 The Socket library makes this slightly easier:
2505
2506     use Socket;
2507     $iaddr = inet_aton("127.1"); # or whatever address
2508     $name  = gethostbyaddr($iaddr, AF_INET);
2509
2510     # or going the other way
2511     $straddr = inet_ntoa($iaddr);
2512
2513 In the opposite way, to resolve a hostname to the IP address
2514 you can write this:
2515
2516     use Socket;
2517     $packed_ip = gethostbyname("www.perl.org");
2518     if (defined $packed_ip) {
2519         $ip_address = inet_ntoa($packed_ip);
2520     }
2521
2522 Make sure C<gethostbyname()> is called in SCALAR context and that
2523 its return value is checked for definedness.
2524
2525 The C<getprotobynumber> function, even though it only takes one argument,
2526 has the precedence of a list operator, so beware:
2527
2528     getprotobynumber $number eq 'icmp'   # WRONG
2529     getprotobynumber($number eq 'icmp')  # actually means this
2530     getprotobynumber($number) eq 'icmp'  # better this way
2531
2532 If you get tired of remembering which element of the return list
2533 contains which return value, by-name interfaces are provided
2534 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2535 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2536 and C<User::grent>.  These override the normal built-ins, supplying
2537 versions that return objects with the appropriate names
2538 for each field.  For example:
2539
2540    use File::stat;
2541    use User::pwent;
2542    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2543
2544 Even though it looks as though they're the same method calls (uid),
2545 they aren't, because a C<File::stat> object is different from
2546 a C<User::pwent> object.
2547
2548 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2549
2550 =item getsockname SOCKET
2551 X<getsockname>
2552
2553 Returns the packed sockaddr address of this end of the SOCKET connection,
2554 in case you don't know the address because you have several different
2555 IPs that the connection might have come in on.
2556
2557     use Socket;
2558     $mysockaddr = getsockname(SOCK);
2559     ($port, $myaddr) = sockaddr_in($mysockaddr);
2560     printf "Connect to %s [%s]\n",
2561        scalar gethostbyaddr($myaddr, AF_INET),
2562        inet_ntoa($myaddr);
2563
2564 =item getsockopt SOCKET,LEVEL,OPTNAME
2565 X<getsockopt>
2566
2567 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2568 Options may exist at multiple protocol levels depending on the socket
2569 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2570 C<Socket> module) will exist.  To query options at another level the
2571 protocol number of the appropriate protocol controlling the option
2572 should be supplied.  For example, to indicate that an option is to be
2573 interpreted by the TCP protocol, LEVEL should be set to the protocol
2574 number of TCP, which you can get using C<getprotobyname>.
2575
2576 The function returns a packed string representing the requested socket
2577 option, or C<undef> on error, with the reason for the error placed in
2578 C<$!>.  Just what is in the packed string depends on LEVEL and OPTNAME;
2579 consult getsockopt(2) for details.  A common case is that the option is an
2580 integer, in which case the result is a packed integer, which you can decode
2581 using C<unpack> with the C<i> (or C<I>) format.
2582
2583 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2584
2585     use Socket qw(:all);
2586
2587     defined(my $tcp = getprotobyname("tcp"))
2588         or die "Could not determine the protocol number for tcp";
2589     # my $tcp = IPPROTO_TCP; # Alternative
2590     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2591         or die "getsockopt TCP_NODELAY: $!";
2592     my $nodelay = unpack("I", $packed);
2593     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2594
2595 Portability issues: L<perlport/getsockopt>.
2596
2597 =item given EXPR BLOCK
2598 X<given>
2599
2600 =item given BLOCK
2601
2602 C<given> is analogous to the C<switch>
2603 keyword in other languages.  C<given>
2604 and C<when> are used in Perl to implement C<switch>/C<case> like statements.
2605 Only available after Perl 5.10.  For example:
2606
2607     use v5.10;
2608     given ($fruit) {
2609         when (/apples?/) {
2610             print "I like apples."
2611         }
2612         when (/oranges?/) {
2613             print "I don't like oranges."
2614         }
2615         default {
2616             print "I don't like anything"
2617         }
2618     }
2619
2620 See L<perlsyn/"Switch Statements"> for detailed information.
2621
2622 =item glob EXPR
2623 X<glob> X<wildcard> X<filename, expansion> X<expand>
2624
2625 =item glob
2626
2627 In list context, returns a (possibly empty) list of filename expansions on
2628 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
2629 scalar context, glob iterates through such filename expansions, returning
2630 undef when the list is exhausted.  This is the internal function
2631 implementing the C<< <*.c> >> operator, but you can use it directly.  If
2632 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2633 more detail in L<perlop/"I/O Operators">.
2634
2635 Note that C<glob> splits its arguments on whitespace and treats
2636 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2637 matches all files with a F<.c> or F<.h> extension.  The expression
2638 C<glob(".* *")> matches all files in the current working directory.
2639 If you want to glob filenames that might contain whitespace, you'll
2640 have to use extra quotes around the spacey filename to protect it.
2641 For example, to glob filenames that have an C<e> followed by a space
2642 followed by an C<f>, use either of:
2643
2644     @spacies = <"*e f*">;
2645     @spacies = glob '"*e f*"';
2646     @spacies = glob q("*e f*");
2647
2648 If you had to get a variable through, you could do this:
2649
2650     @spacies = glob "'*${var}e f*'";
2651     @spacies = glob qq("*${var}e f*");
2652
2653 If non-empty braces are the only wildcard characters used in the
2654 C<glob>, no filenames are matched, but potentially many strings
2655 are returned.  For example, this produces nine strings, one for
2656 each pairing of fruits and colors:
2657
2658     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2659
2660 Beginning with v5.6.0, this operator is implemented using the standard
2661 C<File::Glob> extension.  See L<File::Glob> for details, including
2662 C<bsd_glob> which does not treat whitespace as a pattern separator.
2663
2664 Portability issues: L<perlport/glob>.
2665
2666 =item gmtime EXPR
2667 X<gmtime> X<UTC> X<Greenwich>
2668
2669 =item gmtime
2670
2671 Works just like L</localtime> but the returned values are
2672 localized for the standard Greenwich time zone.
2673
2674 Note: When called in list context, $isdst, the last value
2675 returned by gmtime, is always C<0>.  There is no
2676 Daylight Saving Time in GMT.
2677
2678 Portability issues: L<perlport/gmtime>.
2679
2680 =item goto LABEL
2681 X<goto> X<jump> X<jmp>
2682
2683 =item goto EXPR
2684
2685 =item goto &NAME
2686
2687 The C<goto-LABEL> form finds the statement labeled with LABEL and
2688 resumes execution there.  It can't be used to get out of a block or
2689 subroutine given to C<sort>.  It can be used to go almost anywhere
2690 else within the dynamic scope, including out of subroutines, but it's
2691 usually better to use some other construct such as C<last> or C<die>.
2692 The author of Perl has never felt the need to use this form of C<goto>
2693 (in Perl, that is; C is another matter).  (The difference is that C
2694 does not offer named loops combined with loop control.  Perl does, and
2695 this replaces most structured uses of C<goto> in other languages.)
2696
2697 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2698 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2699 necessarily recommended if you're optimizing for maintainability:
2700
2701     goto ("FOO", "BAR", "GLARCH")[$i];
2702
2703 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2704 function" rule.  A pair of parentheses following it does not (necessarily)
2705 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2706
2707 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2708 deprecated and will issue a warning.  Even then, it may not be used to
2709 go into any construct that requires initialization, such as a
2710 subroutine or a C<foreach> loop.  It also can't be used to go into a
2711 construct that is optimized away.
2712
2713 The C<goto-&NAME> form is quite different from the other forms of
2714 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2715 doesn't have the stigma associated with other gotos.  Instead, it
2716 exits the current subroutine (losing any changes set by local()) and
2717 immediately calls in its place the named subroutine using the current
2718 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2719 load another subroutine and then pretend that the other subroutine had
2720 been called in the first place (except that any modifications to C<@_>
2721 in the current subroutine are propagated to the other subroutine.)
2722 After the C<goto>, not even C<caller> will be able to tell that this
2723 routine was called first.
2724
2725 NAME needn't be the name of a subroutine; it can be a scalar variable
2726 containing a code reference or a block that evaluates to a code
2727 reference.
2728
2729 =item grep BLOCK LIST
2730 X<grep>
2731
2732 =item grep EXPR,LIST
2733
2734 This is similar in spirit to, but not the same as, grep(1) and its
2735 relatives.  In particular, it is not limited to using regular expressions.
2736
2737 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2738 C<$_> to each element) and returns the list value consisting of those
2739 elements for which the expression evaluated to true.  In scalar
2740 context, returns the number of times the expression was true.
2741
2742     @foo = grep(!/^#/, @bar);    # weed out comments
2743
2744 or equivalently,
2745
2746     @foo = grep {!/^#/} @bar;    # weed out comments
2747
2748 Note that C<$_> is an alias to the list value, so it can be used to
2749 modify the elements of the LIST.  While this is useful and supported,
2750 it can cause bizarre results if the elements of LIST are not variables.
2751 Similarly, grep returns aliases into the original list, much as a for
2752 loop's index variable aliases the list elements.  That is, modifying an
2753 element of a list returned by grep (for example, in a C<foreach>, C<map>
2754 or another C<grep>) actually modifies the element in the original list.
2755 This is usually something to be avoided when writing clear code.
2756
2757 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2758 been declared with C<my $_>) then, in addition to being locally aliased to
2759 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2760 can't be seen from the outside, avoiding any potential side-effects.
2761
2762 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2763
2764 =item hex EXPR
2765 X<hex> X<hexadecimal>
2766
2767 =item hex
2768
2769 Interprets EXPR as a hex string and returns the corresponding value.
2770 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2771 L</oct>.)  If EXPR is omitted, uses C<$_>.
2772
2773     print hex '0xAf'; # prints '175'
2774     print hex 'aF';   # same
2775
2776 Hex strings may only represent integers.  Strings that would cause
2777 integer overflow trigger a warning.  Leading whitespace is not stripped,
2778 unlike oct().  To present something as hex, look into L</printf>,
2779 L</sprintf>, and L</unpack>.
2780
2781 =item import LIST
2782 X<import>
2783
2784 There is no builtin C<import> function.  It is just an ordinary
2785 method (subroutine) defined (or inherited) by modules that wish to export
2786 names to another module.  The C<use> function calls the C<import> method
2787 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2788
2789 =item index STR,SUBSTR,POSITION
2790 X<index> X<indexOf> X<InStr>
2791
2792 =item index STR,SUBSTR
2793
2794 The index function searches for one string within another, but without
2795 the wildcard-like behavior of a full regular-expression pattern match.
2796 It returns the position of the first occurrence of SUBSTR in STR at
2797 or after POSITION.  If POSITION is omitted, starts searching from the
2798 beginning of the string.  POSITION before the beginning of the string
2799 or after its end is treated as if it were the beginning or the end,
2800 respectively.  POSITION and the return value are based at zero.
2801 If the substring is not found, C<index> returns -1.
2802
2803 =item int EXPR
2804 X<int> X<integer> X<truncate> X<trunc> X<floor>
2805
2806 =item int
2807
2808 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2809 You should not use this function for rounding: one because it truncates
2810 towards C<0>, and two because machine representations of floating-point
2811 numbers can sometimes produce counterintuitive results.  For example,
2812 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2813 because it's really more like -268.99999999999994315658 instead.  Usually,
2814 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2815 functions will serve you better than will int().
2816
2817 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2818 X<ioctl>
2819
2820 Implements the ioctl(2) function.  You'll probably first have to say
2821
2822     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2823
2824 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2825 exist or doesn't have the correct definitions you'll have to roll your
2826 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2827 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2828 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2829 written depending on the FUNCTION; a C pointer to the string value of SCALAR
2830 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2831 has no string value but does have a numeric value, that value will be
2832 passed rather than a pointer to the string value.  To guarantee this to be
2833 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2834 functions may be needed to manipulate the values of structures used by
2835 C<ioctl>.
2836
2837 The return value of C<ioctl> (and C<fcntl>) is as follows:
2838
2839     if OS returns:      then Perl returns:
2840         -1               undefined value
2841          0              string "0 but true"
2842     anything else           that number
2843
2844 Thus Perl returns true on success and false on failure, yet you can
2845 still easily determine the actual value returned by the operating
2846 system:
2847
2848     $retval = ioctl(...) || -1;
2849     printf "System returned %d\n", $retval;
2850
2851 The special string C<"0 but true"> is exempt from B<-w> complaints
2852 about improper numeric conversions.
2853
2854 Portability issues: L<perlport/ioctl>.
2855
2856 =item join EXPR,LIST
2857 X<join>
2858
2859 Joins the separate strings of LIST into a single string with fields
2860 separated by the value of EXPR, and returns that new string.  Example:
2861
2862     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2863
2864 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2865 first argument.  Compare L</split>.
2866
2867 =item keys HASH
2868 X<keys> X<key>
2869
2870 =item keys ARRAY
2871
2872 =item keys EXPR
2873
2874 Called in list context, returns a list consisting of all the keys of the
2875 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
2876 releases prior to 5.12 will produce a syntax error if you try to use an
2877 array argument.  In scalar context, returns the number of keys or indices.
2878
2879 The keys of a hash are returned in an apparently random order.  The actual
2880 random order is subject to change in future versions of Perl, but it
2881 is guaranteed to be the same order as either the C<values> or C<each>
2882 function produces (given that the hash has not been modified).  Since
2883 Perl 5.8.1 the ordering can be different even between different runs of
2884 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2885 Attacks">).
2886
2887 As a side effect, calling keys() resets the internal interator of the HASH or ARRAY
2888 (see L</each>).  In particular, calling keys() in void context resets
2889 the iterator with no other overhead.
2890
2891 Here is yet another way to print your environment:
2892
2893     @keys = keys %ENV;
2894     @values = values %ENV;
2895     while (@keys) {
2896         print pop(@keys), '=', pop(@values), "\n";
2897     }
2898
2899 or how about sorted by key:
2900
2901     foreach $key (sort(keys %ENV)) {
2902         print $key, '=', $ENV{$key}, "\n";
2903     }
2904
2905 The returned values are copies of the original keys in the hash, so
2906 modifying them will not affect the original hash.  Compare L</values>.
2907
2908 To sort a hash by value, you'll need to use a C<sort> function.
2909 Here's a descending numeric sort of a hash by its values:
2910
2911     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2912         printf "%4d %s\n", $hash{$key}, $key;
2913     }
2914
2915 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
2916 allocated for the given hash.  This can gain you a measure of efficiency if
2917 you know the hash is going to get big.  (This is similar to pre-extending
2918 an array by assigning a larger number to $#array.)  If you say
2919
2920     keys %hash = 200;
2921
2922 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2923 in fact, since it rounds up to the next power of two.  These
2924 buckets will be retained even if you do C<%hash = ()>, use C<undef
2925 %hash> if you want to free the storage while C<%hash> is still in scope.
2926 You can't shrink the number of buckets allocated for the hash using
2927 C<keys> in this way (but you needn't worry about doing this by accident,
2928 as trying has no effect).  C<keys @array> in an lvalue context is a syntax
2929 error.
2930
2931 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
2932 a reference to an unblessed hash or array.  The argument will be
2933 dereferenced automatically.  This aspect of C<keys> is considered highly
2934 experimental.  The exact behaviour may change in a future version of Perl.
2935
2936     for (keys $hashref) { ... }
2937     for (keys $obj->get_arrayref) { ... }
2938
2939 To avoid confusing would-be users of your code who are running earlier
2940 versions of Perl with mysterious syntax errors, put this sort of thing at
2941 the top of your file to signal that your code will work I<only> on Perls of
2942 a recent vintage:
2943
2944     use 5.012;  # so keys/values/each work on arrays
2945     use 5.014;  # so keys/values/each work on scalars (experimental)
2946
2947 See also C<each>, C<values>, and C<sort>.
2948
2949 =item kill SIGNAL, LIST
2950
2951 =item kill SIGNAL
2952 X<kill> X<signal>
2953
2954 Sends a signal to a list of processes.  Returns the number of
2955 processes successfully signaled (which is not necessarily the
2956 same as the number actually killed).
2957
2958     $cnt = kill 1, $child1, $child2;
2959     kill 9, @goners;
2960
2961 If SIGNAL is zero, no signal is sent to the process, but C<kill>
2962 checks whether it's I<possible> to send a signal to it (that
2963 means, to be brief, that the process is owned by the same user, or we are
2964 the super-user).  This is useful to check that a child process is still
2965 alive (even if only as a zombie) and hasn't changed its UID.  See
2966 L<perlport> for notes on the portability of this construct.
2967
2968 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2969 of processes.  That means you usually
2970 want to use positive not negative signals.
2971 You may also use a signal name in quotes.
2972
2973 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2974 the operating system.  For example, on POSIX-conforming systems, zero will
2975 signal the current process group and -1 will signal all processes.
2976
2977 See L<perlipc/"Signals"> for more details.
2978
2979 On some platforms such as Windows where the fork() system call is not available.
2980 Perl can be built to emulate fork() at the interpreter level.
2981 This emulation has limitations related to kill that have to be considered,
2982 for code running on Windows and in code intended to be portable.
2983
2984 See L<perlfork> for more details.
2985
2986 If there is no I<LIST> of processes, no signal is sent, and the return
2987 value is 0.  This form is sometimes used, however, because it causes
2988 tainting checks to be run.  But see
2989 L<perlsec/Laundering and Detecting Tainted Data>.
2990
2991 Portability issues: L<perlport/kill>.
2992
2993 =item last LABEL
2994 X<last> X<break>
2995
2996 =item last
2997
2998 The C<last> command is like the C<break> statement in C (as used in
2999 loops); it immediately exits the loop in question.  If the LABEL is
3000 omitted, the command refers to the innermost enclosing loop.  The
3001 C<continue> block, if any, is not executed:
3002
3003     LINE: while (<STDIN>) {
3004         last LINE if /^$/;  # exit when done with header
3005         #...
3006     }
3007
3008 C<last> cannot be used to exit a block that returns a value such as
3009 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3010 a grep() or map() operation.
3011
3012 Note that a block by itself is semantically identical to a loop
3013 that executes once.  Thus C<last> can be used to effect an early
3014 exit out of such a block.
3015
3016 See also L</continue> for an illustration of how C<last>, C<next>, and
3017 C<redo> work.
3018
3019 =item lc EXPR
3020 X<lc> X<lowercase>
3021
3022 =item lc
3023
3024 Returns a lowercased version of EXPR.  This is the internal function
3025 implementing the C<\L> escape in double-quoted strings.
3026
3027 If EXPR is omitted, uses C<$_>.
3028
3029 What gets returned depends on several factors:
3030
3031 =over
3032
3033 =item If C<use bytes> is in effect:
3034
3035 =over
3036
3037 =item On EBCDIC platforms
3038
3039 The results are what the C language system call C<tolower()> returns.
3040
3041 =item On ASCII platforms
3042
3043 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
3044 respectively.
3045
3046 =back
3047
3048 =item Otherwise, if C<use locale> (but not C<use locale ':not_characters'>) is in effect:
3049
3050 Respects current LC_CTYPE locale for code points < 256; and uses Unicode
3051 semantics for the remaining code points (this last can only happen if
3052 the UTF8 flag is also set).  See L<perllocale>.
3053
3054 A deficiency in this is that case changes that cross the 255/256
3055 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3056 LETTER SHARP S (U+1E9E) in Unicode semantics is U+00DF (on ASCII
3057 platforms).   But under C<use locale>, the lower case of U+1E9E is
3058 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3059 current locale, and Perl has no way of knowing if that character even
3060 exists in the locale, much less what code point it is.  Perl returns
3061 the input character unchanged, for all instances (and there aren't
3062 many) where the 255/256 boundary would otherwise be crossed.
3063
3064 =item Otherwise, If EXPR has the UTF8 flag set:
3065
3066 Unicode semantics are used for the case change.
3067
3068 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'>) is in effect:
3069
3070 Unicode semantics are used for the case change.
3071
3072 =item Otherwise:
3073
3074 =over
3075
3076 =item On EBCDIC platforms
3077
3078 The results are what the C language system call C<tolower()> returns.
3079
3080 =item On ASCII platforms
3081
3082 ASCII semantics are used for the case change.  The lowercase of any character
3083 outside the ASCII range is the character itself.
3084
3085 =back
3086
3087 =back
3088
3089 =item lcfirst EXPR
3090 X<lcfirst> X<lowercase>
3091
3092 =item lcfirst
3093
3094 Returns the value of EXPR with the first character lowercased.  This
3095 is the internal function implementing the C<\l> escape in
3096 double-quoted strings.
3097
3098 If EXPR is omitted, uses C<$_>.
3099
3100 This function behaves the same way under various pragmata, such as in a locale,
3101 as L</lc> does.
3102
3103 =item length EXPR
3104 X<length> X<size>
3105
3106 =item length
3107
3108 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3109 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3110 C<undef>.
3111
3112 This function cannot be used on an entire array or hash to find out how
3113 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3114 %hash>, respectively.
3115
3116 Like all Perl character operations, length() normally deals in logical
3117 characters, not physical bytes.  For how many bytes a string encoded as
3118 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3119 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3120
3121 =item __LINE__
3122 X<__LINE__>
3123
3124 A special token that compiles to the current line number.
3125
3126 =item link OLDFILE,NEWFILE
3127 X<link>
3128
3129 Creates a new filename linked to the old filename.  Returns true for
3130 success, false otherwise.
3131
3132 Portability issues: L<perlport/link>.
3133
3134 =item listen SOCKET,QUEUESIZE
3135 X<listen>
3136
3137 Does the same thing that the listen(2) system call does.  Returns true if
3138 it succeeded, false otherwise.  See the example in
3139 L<perlipc/"Sockets: Client/Server Communication">.
3140
3141 =item local EXPR
3142 X<local>
3143
3144 You really probably want to be using C<my> instead, because C<local> isn't
3145 what most people think of as "local".  See
3146 L<perlsub/"Private Variables via my()"> for details.
3147
3148 A local modifies the listed variables to be local to the enclosing
3149 block, file, or eval.  If more than one value is listed, the list must
3150 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3151 for details, including issues with tied arrays and hashes.
3152
3153 The C<delete local EXPR> construct can also be used to localize the deletion
3154 of array/hash elements to the current block.
3155 See L<perlsub/"Localized deletion of elements of composite types">.
3156
3157 =item localtime EXPR
3158 X<localtime> X<ctime>
3159
3160 =item localtime
3161
3162 Converts a time as returned by the time function to a 9-element list
3163 with the time analyzed for the local time zone.  Typically used as
3164 follows:
3165
3166     #  0    1    2     3     4    5     6     7     8
3167     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3168                                                 localtime(time);
3169
3170 All list elements are numeric and come straight out of the C `struct
3171 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3172 of the specified time.
3173
3174 C<$mday> is the day of the month and C<$mon> the month in
3175 the range C<0..11>, with 0 indicating January and 11 indicating December.
3176 This makes it easy to get a month name from a list:
3177
3178     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
3179     print "$abbr[$mon] $mday";
3180     # $mon=9, $mday=18 gives "Oct 18"
3181
3182 C<$year> contains the number of years since 1900.  To get a 4-digit
3183 year write:
3184
3185     $year += 1900;
3186
3187 To get the last two digits of the year (e.g., "01" in 2001) do:
3188
3189     $year = sprintf("%02d", $year % 100);
3190
3191 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3192 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3193 (or C<0..365> in leap years.)
3194
3195 C<$isdst> is true if the specified time occurs during Daylight Saving
3196 Time, false otherwise.
3197
3198 If EXPR is omitted, C<localtime()> uses the current time (as returned
3199 by time(3)).
3200
3201 In scalar context, C<localtime()> returns the ctime(3) value:
3202
3203     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3204
3205 The format of this scalar value is B<not> locale-dependent
3206 but built into Perl.  For GMT instead of local
3207 time use the L</gmtime> builtin.  See also the
3208 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3209 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3210 and mktime(3) functions.
3211
3212 To get somewhat similar but locale-dependent date strings, set up your
3213 locale environment variables appropriately (please see L<perllocale>) and
3214 try for example:
3215
3216     use POSIX qw(strftime);
3217     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3218     # or for GMT formatted appropriately for your locale:
3219     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3220
3221 Note that the C<%a> and C<%b>, the short forms of the day of the week
3222 and the month of the year, may not necessarily be three characters wide.
3223
3224 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3225 by-name access mechanism to the gmtime() and localtime() functions,
3226 respectively.
3227
3228 For a comprehensive date and time representation look at the
3229 L<DateTime> module on CPAN.
3230
3231 Portability issues: L<perlport/localtime>.
3232
3233 =item lock THING
3234 X<lock>
3235
3236 This function places an advisory lock on a shared variable or referenced
3237 object contained in I<THING> until the lock goes out of scope.
3238
3239 The value returned is the scalar itself, if the argument is a scalar, or a
3240 reference, if the argument is a hash, array or subroutine.
3241
3242 lock() is a "weak keyword" : this means that if you've defined a function
3243 by this name (before any calls to it), that function will be called
3244 instead.  If you are not under C<use threads::shared> this does nothing.
3245 See L<threads::shared>.
3246
3247 =item log EXPR
3248 X<log> X<logarithm> X<e> X<ln> X<base>
3249
3250 =item log
3251
3252 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3253 returns the log of C<$_>.  To get the
3254 log of another base, use basic algebra:
3255 The base-N log of a number is equal to the natural log of that number
3256 divided by the natural log of N.  For example:
3257
3258     sub log10 {
3259         my $n = shift;
3260         return log($n)/log(10);
3261     }
3262
3263 See also L</exp> for the inverse operation.
3264
3265 =item lstat FILEHANDLE
3266 X<lstat>
3267
3268 =item lstat EXPR
3269
3270 =item lstat DIRHANDLE
3271
3272 =item lstat
3273
3274 Does the same thing as the C<stat> function (including setting the
3275 special C<_> filehandle) but stats a symbolic link instead of the file
3276 the symbolic link points to.  If symbolic links are unimplemented on
3277 your system, a normal C<stat> is done.  For much more detailed
3278 information, please see the documentation for C<stat>.
3279
3280 If EXPR is omitted, stats C<$_>.
3281
3282 Portability issues: L<perlport/lstat>.
3283
3284 =item m//
3285
3286 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3287
3288 =item map BLOCK LIST
3289 X<map>
3290
3291 =item map EXPR,LIST
3292
3293 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3294 C<$_> to each element) and returns the list value composed of the
3295 results of each such evaluation.  In scalar context, returns the
3296 total number of elements so generated.  Evaluates BLOCK or EXPR in
3297 list context, so each element of LIST may produce zero, one, or
3298 more elements in the returned value.
3299
3300     @chars = map(chr, @numbers);
3301
3302 translates a list of numbers to the corresponding characters.
3303
3304     my @squares = map { $_ * $_ } @numbers;
3305
3306 translates a list of numbers to their squared values.
3307
3308     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3309
3310 shows that number of returned elements can differ from the number of
3311 input elements.  To omit an element, return an empty list ().
3312 This could also be achieved by writing
3313
3314     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3315
3316 which makes the intention more clear.
3317
3318 Map always returns a list, which can be
3319 assigned to a hash such that the elements
3320 become key/value pairs.  See L<perldata> for more details.
3321
3322     %hash = map { get_a_key_for($_) => $_ } @array;
3323
3324 is just a funny way to write
3325
3326     %hash = ();
3327     foreach (@array) {
3328         $hash{get_a_key_for($_)} = $_;
3329     }
3330
3331 Note that C<$_> is an alias to the list value, so it can be used to
3332 modify the elements of the LIST.  While this is useful and supported,
3333 it can cause bizarre results if the elements of LIST are not variables.
3334 Using a regular C<foreach> loop for this purpose would be clearer in
3335 most cases.  See also L</grep> for an array composed of those items of
3336 the original list for which the BLOCK or EXPR evaluates to true.
3337
3338 If C<$_> is lexical in the scope where the C<map> appears (because it has
3339 been declared with C<my $_>), then, in addition to being locally aliased to
3340 the list elements, C<$_> keeps being lexical inside the block; that is, it
3341 can't be seen from the outside, avoiding any potential side-effects.
3342
3343 C<{> starts both hash references and blocks, so C<map { ...> could be either
3344 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
3345 ahead for the closing C<}> it has to take a guess at which it's dealing with
3346 based on what it finds just after the
3347 C<{>.  Usually it gets it right, but if it
3348 doesn't it won't realize something is wrong until it gets to the C<}> and
3349 encounters the missing (or unexpected) comma.  The syntax error will be
3350 reported close to the C<}>, but you'll need to change something near the C<{>
3351 such as using a unary C<+> to give Perl some help:
3352
3353     %hash = map {  "\L$_" => 1  } @array  # perl guesses EXPR.  wrong
3354     %hash = map { +"\L$_" => 1  } @array  # perl guesses BLOCK. right
3355     %hash = map { ("\L$_" => 1) } @array  # this also works
3356     %hash = map {  lc($_) => 1  } @array  # as does this.
3357     %hash = map +( lc($_) => 1 ), @array  # this is EXPR and works!
3358
3359     %hash = map  ( lc($_), 1 ),   @array  # evaluates to (1, @array)
3360
3361 or to force an anon hash constructor use C<+{>:
3362
3363    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end
3364
3365 to get a list of anonymous hashes each with only one entry apiece.
3366
3367 =item mkdir FILENAME,MASK
3368 X<mkdir> X<md> X<directory, create>
3369
3370 =item mkdir FILENAME
3371
3372 =item mkdir
3373
3374 Creates the directory specified by FILENAME, with permissions
3375 specified by MASK (as modified by C<umask>).  If it succeeds it
3376 returns true; otherwise it returns false and sets C<$!> (errno).
3377 MASK defaults to 0777 if omitted, and FILENAME defaults
3378 to C<$_> if omitted.
3379
3380 In general, it is better to create directories with a permissive MASK
3381 and let the user modify that with their C<umask> than it is to supply
3382 a restrictive MASK and give the user no way to be more permissive.
3383 The exceptions to this rule are when the file or directory should be
3384 kept private (mail files, for instance).  The perlfunc(1) entry on
3385 C<umask> discusses the choice of MASK in more detail.
3386
3387 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3388 number of trailing slashes.  Some operating and filesystems do not get
3389 this right, so Perl automatically removes all trailing slashes to keep
3390 everyone happy.
3391
3392 To recursively create a directory structure, look at
3393 the C<mkpath> function of the L<File::Path> module.
3394
3395 =item msgctl ID,CMD,ARG
3396 X<msgctl>
3397
3398 Calls the System V IPC function msgctl(2).  You'll probably have to say
3399
3400     use IPC::SysV;
3401
3402 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3403 then ARG must be a variable that will hold the returned C<msqid_ds>
3404 structure.  Returns like C<ioctl>: the undefined value for error,
3405 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3406 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3407 C<IPC::Semaphore>.
3408
3409 Portability issues: L<perlport/msgctl>.
3410
3411 =item msgget KEY,FLAGS
3412 X<msgget>
3413
3414 Calls the System V IPC function msgget(2).  Returns the message queue
3415 id, or C<undef> on error.  See also
3416 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3417 C<IPC::Msg>.
3418
3419 Portability issues: L<perlport/msgget>.
3420
3421 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3422 X<msgrcv>
3423
3424 Calls the System V IPC function msgrcv to receive a message from
3425 message queue ID into variable VAR with a maximum message size of
3426 SIZE.  Note that when a message is received, the message type as a
3427 native long integer will be the first thing in VAR, followed by the
3428 actual message.  This packing may be opened with C<unpack("l! a*")>.
3429 Taints the variable.  Returns true if successful, false 
3430 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3431 C<IPC::SysV> and C<IPC::SysV::Msg>.
3432
3433 Portability issues: L<perlport/msgrcv>.
3434
3435 =item msgsnd ID,MSG,FLAGS
3436 X<msgsnd>
3437
3438 Calls the System V IPC function msgsnd to send the message MSG to the
3439 message queue ID.  MSG must begin with the native long integer message
3440 type, be followed by the length of the actual message, and then finally
3441 the message itself.  This kind of packing can be achieved with
3442 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3443 false on error.  See also the C<IPC::SysV>
3444 and C<IPC::SysV::Msg> documentation.
3445
3446 Portability issues: L<perlport/msgsnd>.
3447
3448 =item my EXPR
3449 X<my>
3450
3451 =item my TYPE EXPR
3452
3453 =item my EXPR : ATTRS
3454
3455 =item my TYPE EXPR : ATTRS
3456
3457 A C<my> declares the listed variables to be local (lexically) to the
3458 enclosing block, file, or C<eval>.  If more than one value is listed,
3459 the list must be placed in parentheses.
3460
3461 The exact semantics and interface of TYPE and ATTRS are still
3462 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3463 and attributes are handled using the C<attributes> pragma, or starting
3464 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3465 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3466 L<attributes>, and L<Attribute::Handlers>.
3467
3468 =item next LABEL
3469 X<next> X<continue>
3470
3471 =item next
3472
3473 The C<next> command is like the C<continue> statement in C; it starts
3474 the next iteration of the loop:
3475
3476     LINE: while (<STDIN>) {
3477         next LINE if /^#/;  # discard comments
3478         #...
3479     }
3480
3481 Note that if there were a C<continue> block on the above, it would get
3482 executed even on discarded lines.  If LABEL is omitted, the command
3483 refers to the innermost enclosing loop.
3484
3485 C<next> cannot be used to exit a block which returns a value such as
3486 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3487 a grep() or map() operation.
3488
3489 Note that a block by itself is semantically identical to a loop
3490 that executes once.  Thus C<next> will exit such a block early.
3491
3492 See also L</continue> for an illustration of how C<last>, C<next>, and
3493 C<redo> work.
3494
3495 =item no MODULE VERSION LIST
3496 X<no declarations>
3497 X<unimporting>
3498
3499 =item no MODULE VERSION
3500
3501 =item no MODULE LIST
3502
3503 =item no MODULE
3504
3505 =item no VERSION
3506
3507 See the C<use> function, of which C<no> is the opposite.
3508
3509 =item oct EXPR
3510 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3511
3512 =item oct
3513
3514 Interprets EXPR as an octal string and returns the corresponding
3515 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3516 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3517 binary string.  Leading whitespace is ignored in all three cases.)
3518 The following will handle decimal, binary, octal, and hex in standard
3519 Perl notation:
3520
3521     $val = oct($val) if $val =~ /^0/;
3522
3523 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3524 in octal), use sprintf() or printf():
3525
3526     $dec_perms = (stat("filename"))[2] & 07777;
3527     $oct_perm_str = sprintf "%o", $perms;
3528
3529 The oct() function is commonly used when a string such as C<644> needs
3530 to be converted into a file mode, for example.  Although Perl 
3531 automatically converts strings into numbers as needed, this automatic
3532 conversion assumes base 10.
3533
3534 Leading white space is ignored without warning, as too are any trailing 
3535 non-digits, such as a decimal point (C<oct> only handles non-negative
3536 integers, not negative integers or floating point).
3537
3538 =item open FILEHANDLE,EXPR
3539 X<open> X<pipe> X<file, open> X<fopen>
3540
3541 =item open FILEHANDLE,MODE,EXPR
3542
3543 =item open FILEHANDLE,MODE,EXPR,LIST
3544
3545 =item open FILEHANDLE,MODE,REFERENCE
3546
3547 =item open FILEHANDLE
3548
3549 Opens the file whose filename is given by EXPR, and associates it with
3550 FILEHANDLE.
3551
3552 Simple examples to open a file for reading:
3553
3554     open(my $fh, "<", "input.txt") 
3555         or die "cannot open < input.txt: $!";
3556
3557 and for writing:
3558
3559     open(my $fh, ">", "output.txt") 
3560         or die "cannot open > output.txt: $!";
3561
3562 (The following is a comprehensive reference to open(): for a gentler
3563 introduction you may consider L<perlopentut>.)
3564
3565 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3566 new filehandle is autovivified, meaning that the variable is assigned a
3567 reference to a newly allocated anonymous filehandle.  Otherwise if
3568 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3569 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3570 in effect.)
3571
3572 If EXPR is omitted, the global (package) scalar variable of the same
3573 name as the FILEHANDLE contains the filename.  (Note that lexical 
3574 variables--those declared with C<my> or C<state>--will not work for this
3575 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3576 call to open.)
3577
3578 If three (or more) arguments are specified, the open mode (including
3579 optional encoding) in the second argument are distinct from the filename in
3580 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3581 If MODE is C<< > >>, the file is opened for output, with existing files
3582 first being truncated ("clobbered") and nonexisting files newly created.
3583 If MODE is C<<< >> >>>, the file is opened for appending, again being
3584 created if necessary.
3585
3586 You can put a C<+> in front of the C<< > >> or C<< < >> to
3587 indicate that you want both read and write access to the file; thus
3588 C<< +< >> is almost always preferred for read/write updates--the 
3589 C<< +> >> mode would clobber the file first.  You can't usually use
3590 either read-write mode for updating textfiles, since they have
3591 variable-length records.  See the B<-i> switch in L<perlrun> for a
3592 better approach.  The file is created with permissions of C<0666>
3593 modified by the process's C<umask> value.
3594
3595 These various prefixes correspond to the fopen(3) modes of C<r>,
3596 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3597
3598 In the one- and two-argument forms of the call, the mode and filename
3599 should be concatenated (in that order), preferably separated by white
3600 space.  You can--but shouldn't--omit the mode in these forms when that mode
3601 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3602 the filename argument is a known literal.
3603
3604 For three or more arguments if MODE is C<|->, the filename is
3605 interpreted as a command to which output is to be piped, and if MODE
3606 is C<-|>, the filename is interpreted as a command that pipes
3607 output to us.  In the two-argument (and one-argument) form, one should
3608 replace dash (C<->) with the command.
3609 See L<perlipc/"Using open() for IPC"> for more examples of this.
3610 (You are not allowed to C<open> to a command that pipes both in I<and>
3611 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3612 L<perlipc/"Bidirectional Communication with Another Process"> for
3613 alternatives.)
3614
3615 In the form of pipe opens taking three or more arguments, if LIST is specified
3616 (extra arguments after the command name) then LIST becomes arguments
3617 to the command invoked if the platform supports it.  The meaning of
3618 C<open> with more than three arguments for non-pipe modes is not yet
3619 defined, but experimental "layers" may give extra LIST arguments
3620 meaning.
3621
3622 In the two-argument (and one-argument) form, opening C<< <- >> 
3623 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3624
3625 You may (and usually should) use the three-argument form of open to specify
3626 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3627 that affect how the input and output are processed (see L<open> and
3628 L<PerlIO> for more details).  For example:
3629
3630   open(my $fh, "<:encoding(UTF-8)", "filename")
3631     || die "can't open UTF-8 encoded filename: $!";
3632
3633 opens the UTF8-encoded file containing Unicode characters;
3634 see L<perluniintro>.  Note that if layers are specified in the
3635 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3636 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3637 Those layers will also be ignored if you specifying a colon with no name
3638 following it.  In that case the default layer for the operating system
3639 (:raw on Unix, :crlf on Windows) is used.
3640
3641 Open returns nonzero on success, the undefined value otherwise.  If
3642 the C<open> involved a pipe, the return value happens to be the pid of
3643 the subprocess.
3644
3645 If you're running Perl on a system that distinguishes between text
3646 files and binary files, then you should check out L</binmode> for tips
3647 for dealing with this.  The key distinction between systems that need
3648 C<binmode> and those that don't is their text file formats.  Systems
3649 like Unix, Mac OS, and Plan 9, that end lines with a single
3650 character and encode that character in C as C<"\n"> do not
3651 need C<binmode>.  The rest need it.
3652
3653 When opening a file, it's seldom a good idea to continue 
3654 if the request failed, so C<open> is frequently used with
3655 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3656 where you want to format a suitable error message (but there are
3657 modules that can help with that problem)) always check
3658 the return value from opening a file.  
3659
3660 As a special case the three-argument form with a read/write mode and the third
3661 argument being C<undef>:
3662
3663     open(my $tmp, "+>", undef) or die ...
3664
3665 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3666 works for symmetry, but you really should consider writing something
3667 to the temporary file first.  You will need to seek() to do the
3668 reading.
3669
3670 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3671 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3672 open filehandles directly to Perl scalars via:
3673
3674     open($fh, ">", \$variable) || ..
3675
3676 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3677
3678     close STDOUT;
3679     open(STDOUT, ">", \$variable)
3680         or die "Can't open STDOUT: $!";
3681
3682 General examples:
3683
3684     $ARTICLE = 100;
3685     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3686     while (<ARTICLE>) {...
3687
3688     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3689     # if the open fails, output is discarded
3690
3691     open(my $dbase, "+<", "dbase.mine")      # open for update
3692         or die "Can't open 'dbase.mine' for update: $!";
3693
3694     open(my $dbase, "+<dbase.mine")          # ditto
3695         or die "Can't open 'dbase.mine' for update: $!";
3696
3697     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
3698         or die "Can't start caesar: $!";
3699
3700     open(ARTICLE, "caesar <$article |")      # ditto
3701         or die "Can't start caesar: $!";
3702
3703     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3704         or die "Can't start sort: $!";
3705
3706     # in-memory files
3707     open(MEMORY, ">", \$var)
3708         or die "Can't open memory file: $!";
3709     print MEMORY "foo!\n";                   # output will appear in $var
3710
3711     # process argument list of files along with any includes
3712
3713     foreach $file (@ARGV) {
3714         process($file, "fh00");
3715     }
3716
3717     sub process {
3718         my($filename, $input) = @_;
3719         $input++;    # this is a string increment
3720         unless (open($input, "<", $filename)) {
3721             print STDERR "Can't open $filename: $!\n";
3722             return;
3723         }
3724
3725         local $_;
3726         while (<$input>) {    # note use of indirection
3727             if (/^#include "(.*)"/) {
3728                 process($1, $input);
3729                 next;
3730             }
3731             #...          # whatever
3732         }
3733     }
3734
3735 See L<perliol> for detailed info on PerlIO.
3736
3737 You may also, in the Bourne shell tradition, specify an EXPR beginning
3738 with C<< >& >>, in which case the rest of the string is interpreted
3739 as the name of a filehandle (or file descriptor, if numeric) to be
3740 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3741 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3742 The mode you specify should match the mode of the original filehandle.
3743 (Duping a filehandle does not take into account any existing contents
3744 of IO buffers.)  If you use the three-argument
3745 form, then you can pass either a
3746 number, the name of a filehandle, or the normal "reference to a glob".
3747
3748 Here is a script that saves, redirects, and restores C<STDOUT> and
3749 C<STDERR> using various methods:
3750
3751     #!/usr/bin/perl
3752     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3753     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
3754
3755     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
3756     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3757
3758     select STDERR; $| = 1;  # make unbuffered
3759     select STDOUT; $| = 1;  # make unbuffered
3760
3761     print STDOUT "stdout 1\n";  # this works for
3762     print STDERR "stderr 1\n";  # subprocesses too
3763
3764     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
3765     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
3766
3767     print STDOUT "stdout 2\n";
3768     print STDERR "stderr 2\n";
3769
3770 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3771 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3772 that file descriptor (and not call C<dup(2)>); this is more
3773 parsimonious of file descriptors.  For example:
3774
3775     # open for input, reusing the fileno of $fd
3776     open(FILEHANDLE, "<&=$fd")
3777
3778 or
3779
3780     open(FILEHANDLE, "<&=", $fd)
3781
3782 or
3783
3784     # open for append, using the fileno of OLDFH
3785     open(FH, ">>&=", OLDFH)
3786
3787 or
3788
3789     open(FH, ">>&=OLDFH")
3790
3791 Being parsimonious on filehandles is also useful (besides being
3792 parsimonious) for example when something is dependent on file
3793 descriptors, like for example locking using flock().  If you do just
3794 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
3795 descriptor as B, and therefore flock(A) will not flock(B) nor vice
3796 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
3797 the same underlying system file descriptor.
3798
3799 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
3800 fdopen() to implement the C<=> functionality.  On many Unix systems,
3801 fdopen() fails when file descriptors exceed a certain value, typically 255.
3802 For Perls 5.8.0 and later, PerlIO is (most often) the default.
3803
3804 You can see whether your Perl was built with PerlIO by running C<perl -V>
3805 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
3806 have PerlIO; otherwise you don't.
3807
3808 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
3809 with the one- or two-argument forms of C<open>), 
3810 an implicit C<fork> is done, so C<open> returns twice: in the parent
3811 process it returns the pid
3812 of the child process, and in the child process it returns (a defined) C<0>.
3813 Use C<defined($pid)> or C<//> to determine whether the open was successful.
3814
3815 For example, use either
3816
3817     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
3818
3819 or
3820     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
3821
3822 followed by 
3823
3824     if ($child_pid) {
3825         # am the parent:
3826         # either write TO_KID or else read FROM_KID
3827         ...
3828         wait $child_pid;
3829     } else {
3830         # am the child; use STDIN/STDOUT normally
3831         ...
3832         exit;
3833     } 
3834
3835 The filehandle behaves normally for the parent, but I/O to that
3836 filehandle is piped from/to the STDOUT/STDIN of the child process.
3837 In the child process, the filehandle isn't opened--I/O happens from/to
3838 the new STDOUT/STDIN.  Typically this is used like the normal
3839 piped open when you want to exercise more control over just how the
3840 pipe command gets executed, such as when running setuid and
3841 you don't want to have to scan shell commands for metacharacters.
3842
3843 The following blocks are more or less equivalent:
3844
3845     open(FOO, "|tr '[a-z]' '[A-Z]'");
3846     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
3847     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
3848     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
3849
3850     open(FOO, "cat -n '$file'|");
3851     open(FOO, "-|", "cat -n '$file'");
3852     open(FOO, "-|") || exec "cat", "-n", $file;
3853     open(FOO, "-|", "cat", "-n", $file);
3854
3855 The last two examples in each block show the pipe as "list form", which is
3856 not yet supported on all platforms.  A good rule of thumb is that if
3857 your platform has a real C<fork()> (in other words, if your platform is
3858 Unix, including Linux and MacOS X), you can use the list form.  You would 
3859 want to use the list form of the pipe so you can pass literal arguments
3860 to the command without risk of the shell interpreting any shell metacharacters
3861 in them.  However, this also bars you from opening pipes to commands
3862 that intentionally contain shell metacharacters, such as:
3863
3864     open(FOO, "|cat -n | expand -4 | lpr")
3865         // die "Can't open pipeline to lpr: $!";
3866
3867 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3868
3869 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3870 output before any operation that may do a fork, but this may not be
3871 supported on some platforms (see L<perlport>).  To be safe, you may need
3872 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3873 of C<IO::Handle> on any open handles.
3874
3875 On systems that support a close-on-exec flag on files, the flag will
3876 be set for the newly opened file descriptor as determined by the value
3877 of C<$^F>.  See L<perlvar/$^F>.
3878
3879 Closing any piped filehandle causes the parent process to wait for the
3880 child to finish, then returns the status value in C<$?> and
3881 C<${^CHILD_ERROR_NATIVE}>.
3882
3883 The filename passed to the one- and two-argument forms of open() will
3884 have leading and trailing whitespace deleted and normal
3885 redirection characters honored.  This property, known as "magic open",
3886 can often be used to good effect.  A user could specify a filename of
3887 F<"rsh cat file |">, or you could change certain filenames as needed:
3888
3889     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3890     open(FH, $filename) or die "Can't open $filename: $!";
3891
3892 Use the three-argument form to open a file with arbitrary weird characters in it,
3893
3894     open(FOO, "<", $file)
3895         || die "can't open < $file: $!";
3896
3897 otherwise it's necessary to protect any leading and trailing whitespace:
3898
3899     $file =~ s#^(\s)#./$1#;
3900     open(FOO, "< $file\0")
3901         || die "open failed: $!";
3902
3903 (this may not work on some bizarre filesystems).  One should
3904 conscientiously choose between the I<magic> and I<three-argument> form
3905 of open():
3906
3907     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
3908
3909 will allow the user to specify an argument of the form C<"rsh cat file |">,
3910 but will not work on a filename that happens to have a trailing space, while
3911
3912     open(IN, "<", $ARGV[0])
3913         || die "can't open < $ARGV[0]: $!";
3914
3915 will have exactly the opposite restrictions.
3916
3917 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3918 should use the C<sysopen> function, which involves no such magic (but may
3919 use subtly different filemodes than Perl open(), which is mapped to C
3920 fopen()).  This is another way to protect your filenames from
3921 interpretation.  For example:
3922
3923     use IO::Handle;
3924     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3925         or die "sysopen $path: $!";
3926     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3927     print HANDLE "stuff $$\n";
3928     seek(HANDLE, 0, 0);
3929     print "File contains: ", <HANDLE>;
3930
3931 Using the constructor from the C<IO::Handle> package (or one of its
3932 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3933 filehandles that have the scope of the variables used to hold them, then
3934 automatically (but silently) close once their reference counts become
3935 zero, typically at scope exit:
3936
3937     use IO::File;
3938     #...
3939     sub read_myfile_munged {
3940         my $ALL = shift;
3941         # or just leave it undef to autoviv
3942         my $handle = IO::File->new;
3943         open($handle, "<", "myfile") or die "myfile: $!";
3944         $first = <$handle>
3945             or return ();     # Automatically closed here.
3946         mung($first) or die "mung failed";  # Or here.
3947         return (first, <$handle>) if $ALL;  # Or here.
3948         return $first;                      # Or here.
3949     }
3950
3951 B<WARNING:> The previous example has a bug because the automatic
3952 close that happens when the refcount on C<handle> does not
3953 properly detect and report failures.  I<Always> close the handle
3954 yourself and inspect the return value.
3955
3956     close($handle) 
3957         || warn "close failed: $!";
3958
3959 See L</seek> for some details about mixing reading and writing.
3960
3961 Portability issues: L<perlport/open>.
3962
3963 =item opendir DIRHANDLE,EXPR
3964 X<opendir>
3965
3966 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3967 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3968 DIRHANDLE may be an expression whose value can be used as an indirect
3969 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3970 scalar variable (or array or hash element), the variable is assigned a
3971 reference to a new anonymous dirhandle; that is, it's autovivified.
3972 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3973
3974 See the example at C<readdir>.
3975
3976 =item ord EXPR
3977 X<ord> X<encoding>
3978
3979 =item ord
3980
3981 Returns the numeric value of the first character of EXPR.
3982 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
3983 (Note I<character>, not byte.)
3984
3985 For the reverse, see L</chr>.
3986 See L<perlunicode> for more about Unicode.
3987
3988 =item our EXPR
3989 X<our> X<global>
3990
3991 =item our TYPE EXPR
3992
3993 =item our EXPR : ATTRS
3994
3995 =item our TYPE EXPR : ATTRS
3996
3997 C<our> associates a simple name with a package variable in the current
3998 package for use within the current scope.  When C<use strict 'vars'> is in
3999 effect, C<our> lets you use declared global variables without qualifying
4000 them with package names, within the lexical scope of the C<our> declaration.
4001 In this way C<our> differs from C<use vars>, which is package-scoped.
4002
4003 Unlike C<my> or C<state>, which allocates storage for a variable and
4004 associates a simple name with that storage for use within the current
4005 scope, C<our> associates a simple name with a package (read: global)
4006 variable in the current package, for use within the current lexical scope.
4007 In other words, C<our> has the same scoping rules as C<my> or C<state>, but
4008 does not necessarily create a variable.
4009
4010 If more than one value is listed, the list must be placed
4011 in parentheses.
4012
4013     our $foo;
4014     our($bar, $baz);
4015
4016 An C<our> declaration declares a global variable that will be visible
4017 across its entire lexical scope, even across package boundaries.  The
4018 package in which the variable is entered is determined at the point
4019 of the declaration, not at the point of use.  This means the following
4020 behavior holds:
4021
4022     package Foo;
4023     our $bar;      # declares $Foo::bar for rest of lexical scope
4024     $bar = 20;
4025
4026     package Bar;
4027     print $bar;    # prints 20, as it refers to $Foo::bar
4028
4029 Multiple C<our> declarations with the same name in the same lexical
4030 scope are allowed if they are in different packages.  If they happen
4031 to be in the same package, Perl will emit warnings if you have asked
4032 for them, just like multiple C<my> declarations.  Unlike a second
4033 C<my> declaration, which will bind the name to a fresh variable, a
4034 second C<our> declaration in the same package, in the same scope, is
4035 merely redundant.
4036
4037     use warnings;
4038     package Foo;
4039     our $bar;      # declares $Foo::bar for rest of lexical scope
4040     $bar = 20;
4041
4042     package Bar;
4043     our $bar = 30; # declares $Bar::bar for rest of lexical scope
4044     print $bar;    # prints 30
4045
4046     our $bar;      # emits warning but has no other effect
4047     print $bar;    # still prints 30
4048
4049 An C<our> declaration may also have a list of attributes associated
4050 with it.
4051
4052 The exact semantics and interface of TYPE and ATTRS are still
4053 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
4054 and attributes are handled using the C<attributes> pragma, or, starting
4055 from Perl 5.8.0, also via the C<Attribute::Handlers> module.  See
4056 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
4057 L<attributes>, and L<Attribute::Handlers>.
4058
4059 =item pack TEMPLATE,LIST
4060 X<pack>
4061
4062 Takes a LIST of values and converts it into a string using the rules
4063 given by the TEMPLATE.  The resulting string is the concatenation of
4064 the converted values.  Typically, each converted value looks
4065 like its machine-level representation.  For example, on 32-bit machines
4066 an integer may be represented by a sequence of 4 bytes, which  will in
4067 Perl be presented as a string that's 4 characters long. 
4068
4069 See L<perlpacktut> for an introduction to this function.
4070
4071 The TEMPLATE is a sequence of characters that give the order and type
4072 of values, as follows:
4073
4074     a  A string with arbitrary binary data, will be null padded.
4075     A  A text (ASCII) string, will be space padded.
4076     Z  A null-terminated (ASCIZ) string, will be null padded.
4077
4078     b  A bit string (ascending bit order inside each byte,
4079        like vec()).
4080     B  A bit string (descending bit order inside each byte).
4081     h  A hex string (low nybble first).
4082     H  A hex string (high nybble first).
4083
4084     c  A signed char (8-bit) value.
4085     C  An unsigned char (octet) value.
4086     W  An unsigned char value (can be greater than 255).
4087
4088     s  A signed short (16-bit) value.
4089     S  An unsigned short value.
4090
4091     l  A signed long (32-bit) value.
4092     L  An unsigned long value.
4093
4094     q  A signed quad (64-bit) value.
4095     Q  An unsigned quad value.
4096          (Quads are available only if your system supports 64-bit
4097           integer values _and_ if Perl has been compiled to support
4098           those.  Raises an exception otherwise.)
4099
4100     i  A signed integer value.
4101     I  A unsigned integer value.
4102          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4103           size depends on what a local C compiler calls 'int'.)
4104
4105     n  An unsigned short (16-bit) in "network" (big-endian) order.
4106     N  An unsigned long (32-bit) in "network" (big-endian) order.
4107     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4108     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4109
4110     j  A Perl internal signed integer value (IV).
4111     J  A Perl internal unsigned integer value (UV).
4112
4113     f  A single-precision float in native format.
4114     d  A double-precision float in native format.
4115
4116     F  A Perl internal floating-point value (NV) in native format
4117     D  A float of long-double precision in native format.
4118          (Long doubles are available only if your system supports
4119           long double values _and_ if Perl has been compiled to
4120           support those.  Raises an exception otherwise.)
4121
4122     p  A pointer to a null-terminated string.
4123     P  A pointer to a structure (fixed-length string).
4124
4125     u  A uuencoded string.
4126     U  A Unicode character number.  Encodes to a character in char-
4127        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4128        byte mode.
4129
4130     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4131        for details).  Its bytes represent an unsigned integer in
4132        base 128, most significant digit first, with as few digits
4133        as possible.  Bit eight (the high bit) is set on each byte
4134        except the last.
4135
4136     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4137     X  Back up a byte.
4138     @  Null-fill or truncate to absolute position, counted from the
4139        start of the innermost ()-group.
4140     .  Null-fill or truncate to absolute position specified by
4141        the value.
4142     (  Start of a ()-group.
4143
4144 One or more modifiers below may optionally follow certain letters in the
4145 TEMPLATE (the second column lists letters for which the modifier is valid):
4146
4147     !   sSlLiI     Forces native (short, long, int) sizes instead
4148                    of fixed (16-/32-bit) sizes.
4149
4150         xX         Make x and X act as alignment commands.
4151
4152         nNvV       Treat integers as signed instead of unsigned.
4153
4154         @.         Specify position as byte offset in the internal
4155                    representation of the packed string.  Efficient
4156                    but dangerous.
4157
4158     >   sSiIlLqQ   Force big-endian byte-order on the type.
4159         jJfFdDpP   (The "big end" touches the construct.)
4160
4161     <   sSiIlLqQ   Force little-endian byte-order on the type.
4162         jJfFdDpP   (The "little end" touches the construct.)
4163
4164 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4165 to force a particular byte-order on all components in that group, 
4166 including all its subgroups.
4167
4168 The following rules apply:
4169
4170 =over 
4171
4172 =item *
4173
4174 Each letter may optionally be followed by a number indicating the repeat
4175 count.  A numeric repeat count may optionally be enclosed in brackets, as
4176 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4177 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4178 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4179 something else, described below.  Supplying a C<*> for the repeat count
4180 instead of a number means to use however many items are left, except for:
4181
4182 =over 
4183
4184 =item * 
4185
4186 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4187
4188 =item * 
4189
4190 <.>, where it means relative to the start of the string.
4191
4192 =item * 
4193
4194 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4195
4196 =back 
4197
4198 One can replace a numeric repeat count with a template letter enclosed in
4199 brackets to use the packed byte length of the bracketed template for the
4200 repeat count.
4201
4202 For example, the template C<x[L]> skips as many bytes as in a packed long,
4203 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4204 variable-expanded) unpacks.  If the template in brackets contains alignment
4205 commands (such as C<x![d]>), its packed length is calculated as if the
4206 start of the template had the maximal possible alignment.
4207
4208 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4209 trailing null byte, so the resulting string is always one byte longer than
4210 the byte length of the item itself.
4211
4212 When used with C<@>, the repeat count represents an offset from the start
4213 of the innermost C<()> group.
4214
4215 When used with C<.>, the repeat count determines the starting position to
4216 calculate the value offset as follows:
4217
4218 =over 
4219
4220 =item *
4221
4222 If the repeat count is C<0>, it's relative to the current position.
4223
4224 =item *
4225
4226 If the repeat count is C<*>, the offset is relative to the start of the
4227 packed string.
4228
4229 =item *
4230
4231 And if it's an integer I<n>, the offset is relative to the start of the
4232 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4233 bigger then the group level.
4234
4235 =back
4236
4237 The repeat count for C<u> is interpreted as the maximal number of bytes
4238 to encode per line of output, with 0, 1 and 2 replaced by 45.  The repeat 
4239 count should not be more than 65.
4240
4241 =item *
4242
4243 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4244 string of length count, padding with nulls or spaces as needed.  When
4245 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4246 after the first null, and C<a> returns data with no stripping at all.
4247
4248 If the value to pack is too long, the result is truncated.  If it's too
4249 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4250 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4251 when the count is 0.
4252
4253 =item *
4254
4255 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4256 Each such format generates 1 bit of the result.  These are typically followed
4257 by a repeat count like C<B8> or C<B64>.
4258
4259 Each result bit is based on the least-significant bit of the corresponding
4260 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4261 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4262
4263 Starting from the beginning of the input string, each 8-tuple
4264 of characters is converted to 1 character of output.  With format C<b>,
4265 the first character of the 8-tuple determines the least-significant bit of a
4266 character; with format C<B>, it determines the most-significant bit of
4267 a character.
4268
4269 If the length of the input string is not evenly divisible by 8, the
4270 remainder is packed as if the input string were padded by null characters
4271 at the end.  Similarly during unpacking, "extra" bits are ignored.
4272
4273 If the input string is longer than needed, remaining characters are ignored.
4274
4275 A C<*> for the repeat count uses all characters of the input field.  
4276 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4277
4278 =item *
4279
4280 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4281 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4282
4283 For each such format, pack() generates 4 bits of result.
4284 With non-alphabetical characters, the result is based on the 4 least-significant
4285 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4286 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4287 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4288 is compatible with the usual hexadecimal digits, so that C<"a"> and
4289 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4290 characters with this format.
4291
4292 Starting from the beginning of the template to pack(), each pair
4293 of characters is converted to 1 character of output.  With format C<h>, the
4294 first character of the pair determines the least-significant nybble of the
4295 output character; with format C<H>, it determines the most-significant
4296 nybble.
4297
4298 If the length of the input string is not even, it behaves as if padded by
4299 a null character at the end.  Similarly, "extra" nybbles are ignored during
4300 unpacking.
4301
4302 If the input string is longer than needed, extra characters are ignored.
4303
4304 A C<*> for the repeat count uses all characters of the input field.  For
4305 unpack(), nybbles are converted to a string of hexadecimal digits.
4306
4307 =item *
4308
4309 The C<p> format packs a pointer to a null-terminated string.  You are
4310 responsible for ensuring that the string is not a temporary value, as that
4311 could potentially get deallocated before you got around to using the packed
4312 result.  The C<P> format packs a pointer to a structure of the size indicated
4313 by the length.  A null pointer is created if the corresponding value for
4314 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4315 unpacks into C<undef>.
4316
4317 If your system has a strange pointer size--meaning a pointer is neither as
4318 big as an int nor as big as a long--it may not be possible to pack or
4319 unpack pointers in big- or little-endian byte order.  Attempting to do
4320 so raises an exception.
4321
4322 =item *
4323
4324 The C</> template character allows packing and unpacking of a sequence of
4325 items where the packed structure contains a packed item count followed by
4326 the packed items themselves.  This is useful when the structure you're
4327 unpacking has encoded the sizes or repeat counts for some of its fields
4328 within the structure itself as separate fields.
4329
4330 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4331 I<length-item> describes how the length value is packed.  Formats likely
4332 to be of most use are integer-packing ones like C<n> for Java strings,
4333 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4334
4335 For C<pack>, I<sequence-item> may have a repeat count, in which case
4336 the minimum of that and the number of available items is used as the argument
4337 for I<length-item>.  If it has no repeat count or uses a '*', the number
4338 of available items is used.
4339
4340 For C<unpack>, an internal stack of integer arguments unpacked so far is
4341 used.  You write C</>I<sequence-item> and the repeat count is obtained by
4342 popping off the last element from the stack.  The I<sequence-item> must not
4343 have a repeat count.
4344
4345 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4346 the I<length-item> is the string length, not the number of strings.  With
4347 an explicit repeat count for pack, the packed string is adjusted to that
4348 length.  For example:
4349
4350  This code:                              gives this result:
4351  
4352   unpack("W/a", "\004Gurusamy")          ("Guru")
4353   unpack("a3/A A*", "007 Bond  J ")      (" Bond", "J")
4354   unpack("a3 x2 /A A*", "007: Bond, J.") ("Bond, J", ".")
4355
4356   pack("n/a* w/a","hello,","world")     "\000\006hello,\005world"
4357   pack("a/W2", ord("a") .. ord("z"))    "2ab"
4358
4359 The I<length-item> is not returned explicitly from C<unpack>.
4360
4361 Supplying a count to the I<length-item> format letter is only useful with
4362 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
4363 introduce C<"\000"> characters, which Perl does not regard as legal in
4364 numeric strings.
4365
4366 =item *
4367
4368 The integer types C<s>, C<S>, C<l>, and C<L> may be
4369 followed by a C<!> modifier to specify native shorts or
4370 longs.  As shown in the example above, a bare C<l> means
4371 exactly 32 bits, although the native C<long> as seen by the local C compiler
4372 may be larger.  This is mainly an issue on 64-bit platforms.  You can
4373 see whether using C<!> makes any difference this way:
4374
4375     printf "format s is %d, s! is %d\n", 
4376         length pack("s"), length pack("s!");
4377
4378     printf "format l is %d, l! is %d\n", 
4379         length pack("l"), length pack("l!");
4380
4381
4382 C<i!> and C<I!> are also allowed, but only for completeness' sake:
4383 they are identical to C<i> and C<I>.
4384
4385 The actual sizes (in bytes) of native shorts, ints, longs, and long
4386 longs on the platform where Perl was built are also available from
4387 the command line:
4388
4389     $ perl -V:{short,int,long{,long}}size
4390     shortsize='2';
4391     intsize='4';
4392     longsize='4';
4393     longlongsize='8';
4394
4395 or programmatically via the C<Config> module:
4396
4397        use Config;
4398        print $Config{shortsize},    "\n";
4399        print $Config{intsize},      "\n";
4400        print $Config{longsize},     "\n";
4401        print $Config{longlongsize}, "\n";
4402
4403 C<$Config{longlongsize}> is undefined on systems without 
4404 long long support.
4405
4406 =item *
4407
4408 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
4409 inherently non-portable between processors and operating systems because
4410 they obey native byteorder and endianness.  For example, a 4-byte integer
4411 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
4412 handled by the CPU registers) into bytes as
4413
4414     0x12 0x34 0x56 0x78  # big-endian
4415     0x78 0x56 0x34 0x12  # little-endian
4416
4417 Basically, Intel and VAX CPUs are little-endian, while everybody else,
4418 including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are
4419 big-endian.  Alpha and MIPS can be either: Digital/Compaq uses (well, used) 
4420 them in little-endian mode, but SGI/Cray uses them in big-endian mode.
4421
4422 The names I<big-endian> and I<little-endian> are comic references to the
4423 egg-eating habits of the little-endian Lilliputians and the big-endian
4424 Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>.
4425 This entered computer lingo via the paper "On Holy Wars and a Plea for
4426 Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980.
4427
4428 Some systems may have even weirder byte orders such as
4429
4430    0x56 0x78 0x12 0x34
4431    0x34 0x12 0x78 0x56
4432
4433 You can determine your system endianness with this incantation:
4434
4435    printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); 
4436
4437 The byteorder on the platform where Perl was built is also available
4438 via L<Config>:
4439
4440     use Config;
4441     print "$Config{byteorder}\n";
4442
4443 or from the command line:
4444
4445     $ perl -V:byteorder
4446
4447 Byteorders C<"1234"> and C<"12345678"> are little-endian; C<"4321">
4448 and C<"87654321"> are big-endian.
4449
4450 For portably packed integers, either use the formats C<n>, C<N>, C<v>, 
4451 and C<V> or else use the C<< > >> and C<< < >> modifiers described
4452 immediately below.  See also L<perlport>.
4453
4454 =item *
4455
4456 Starting with Perl 5.9.2, integer and floating-point formats, along with
4457 the C<p> and C<P> formats and C<()> groups, may all be followed by the 
4458 C<< > >> or C<< < >> endianness modifiers to respectively enforce big-
4459 or little-endian byte-order.  These modifiers are especially useful 
4460 given how C<n>, C<N>, C<v>, and C<V> don't cover signed integers, 
4461 64-bit integers, or floating-point values.
4462
4463 Here are some concerns to keep in mind when using an endianness modifier:
4464
4465 =over
4466
4467 =item * 
4468
4469 Exchanging signed integers between different platforms works only 
4470 when all platforms store them in the same format.  Most platforms store
4471 signed integers in two's-complement notation, so usually this is not an issue.
4472
4473 =item * 
4474
4475 The C<< > >> or C<< < >> modifiers can only be used on floating-point
4476 formats on big- or little-endian machines.  Otherwise, attempting to
4477 use them raises an exception.
4478
4479 =item * 
4480
4481 Forcing big- or little-endian byte-order on floating-point values for
4482 data exchange can work only if all platforms use the same
4483 binary representation such as IEEE floating-point.  Even if all
4484 platforms are using IEEE, there may still be subtle differences.  Being able
4485 to use C<< > >> or C<< < >> on floating-point values can be useful,
4486 but also dangerous if you don't know exactly what you're doing.
4487 It is not a general way to portably store floating-point values.
4488
4489 =item * 
4490
4491 When using C<< > >> or C<< < >> on a C<()> group, this affects
4492 all types inside the group that accept byte-order modifiers,
4493 including all subgroups.  It is silently ignored for all other
4494 types.  You are not allowed to override the byte-order within a group
4495 that already has a byte-order modifier suffix.
4496
4497 =back
4498
4499 =item *
4500
4501 Real numbers (floats and doubles) are in native machine format only.
4502 Due to the multiplicity of floating-point formats and the lack of a
4503 standard "network" representation for them, no facility for interchange has been
4504 made.  This means that packed floating-point data written on one machine
4505 may not be readable on another, even if both use IEEE floating-point
4506 arithmetic (because the endianness of the memory representation is not part
4507 of the IEEE spec).  See also L<perlport>.
4508
4509 If you know I<exactly> what you're doing, you can use the C<< > >> or C<< < >>
4510 modifiers to force big- or little-endian byte-order on floating-point values.
4511
4512 Because Perl uses doubles (or long doubles, if configured) internally for
4513 all numeric calculation, converting from double into float and thence 
4514 to double again loses precision, so C<unpack("f", pack("f", $foo)>)
4515 will not in general equal $foo.
4516
4517 =item *
4518
4519 Pack and unpack can operate in two modes: character mode (C<C0> mode) where
4520 the packed string is processed per character, and UTF-8 mode (C<U0> mode)
4521 where the packed string is processed in its UTF-8-encoded Unicode form on
4522 a byte-by-byte basis.  Character mode is the default
4523 unless the format string starts with C<U>.  You
4524 can always switch mode mid-format with an explicit 
4525 C<C0> or C<U0> in the format.  This mode remains in effect until the next 
4526 mode change, or until the end of the C<()> group it (directly) applies to.
4527
4528 Using C<C0> to get Unicode characters while using C<U0> to get I<non>-Unicode 
4529 bytes is not necessarily obvious.   Probably only the first of these
4530 is what you want:
4531
4532     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4533       perl -CS -ne 'printf "%v04X\n", $_ for unpack("C0A*", $_)'
4534     03B1.03C9
4535     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4536       perl -CS -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4537     CE.B1.CF.89
4538     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4539       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("C0A*", $_)'
4540     CE.B1.CF.89
4541     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4542       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4543     C3.8E.C2.B1.C3.8F.C2.89
4544
4545 Those examples also illustrate that you should not try to use
4546 C<pack>/C<unpack> as a substitute for the L<Encode> module.
4547
4548 =item *
4549
4550 You must yourself do any alignment or padding by inserting, for example,
4551 enough C<"x">es while packing.  There is no way for pack() and unpack()
4552 to know where characters are going to or coming from, so they 
4553 handle their output and input as flat sequences of characters.
4554
4555 =item *
4556
4557 A C<()> group is a sub-TEMPLATE enclosed in parentheses.  A group may
4558 take a repeat count either as postfix, or for unpack(), also via the C</>
4559 template character.  Within each repetition of a group, positioning with
4560 C<@> starts over at 0.  Therefore, the result of
4561
4562     pack("@1A((@2A)@3A)", qw[X Y Z])
4563
4564 is the string C<"\0X\0\0YZ">.
4565
4566 =item *
4567
4568 C<x> and C<X> accept the C<!> modifier to act as alignment commands: they
4569 jump forward or back to the closest position aligned at a multiple of C<count>
4570 characters.  For example, to pack() or unpack() a C structure like
4571
4572     struct {
4573         char   c;    /* one signed, 8-bit character */
4574         double d; 
4575         char   cc[2];
4576     }
4577
4578 one may need to use the template C<c x![d] d c[2]>.  This assumes that
4579 doubles must be aligned to the size of double.
4580
4581 For alignment commands, a C<count> of 0 is equivalent to a C<count> of 1;
4582 both are no-ops.
4583
4584 =item *
4585
4586 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier to
4587 represent signed 16-/32-bit integers in big-/little-endian order.
4588 This is portable only when all platforms sharing packed data use the
4589 same binary representation for signed integers; for example, when all
4590 platforms use two's-complement representation.
4591
4592 =item *
4593
4594 Comments can be embedded in a TEMPLATE using C<#> through the end of line.
4595 White space can separate pack codes from each other, but modifiers and
4596 repeat counts must follow immediately.  Breaking complex templates into
4597 individual line-by-line components, suitably annotated, can do as much to
4598 improve legibility and maintainability of pack/unpack formats as C</x> can
4599 for complicated pattern matches.
4600
4601 =item *
4602
4603 If TEMPLATE requires more arguments than pack() is given, pack()
4604 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4605 than given, extra arguments are ignored.
4606
4607 =back
4608
4609 Examples:
4610
4611     $foo = pack("WWWW",65,66,67,68);
4612     # foo eq "ABCD"
4613     $foo = pack("W4",65,66,67,68);
4614     # same thing
4615     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4616     # same thing with Unicode circled letters.
4617     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4618     # same thing with Unicode circled letters.  You don't get the
4619     # UTF-8 bytes because the U at the start of the format caused
4620     # a switch to U0-mode, so the UTF-8 bytes get joined into
4621     # characters
4622     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4623     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4624     # This is the UTF-8 encoding of the string in the
4625     # previous example
4626
4627     $foo = pack("ccxxcc",65,66,67,68);
4628     # foo eq "AB\0\0CD"
4629
4630     # NOTE: The examples above featuring "W" and "c" are true
4631     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4632     # and UTF-8.  On EBCDIC systems, the first example would be
4633     #      $foo = pack("WWWW",193,194,195,196);
4634
4635     $foo = pack("s2",1,2);
4636     # "\001\000\002\000" on little-endian
4637     # "\000\001\000\002" on big-endian
4638
4639     $foo = pack("a4","abcd","x","y","z");
4640     # "abcd"
4641
4642     $foo = pack("aaaa","abcd","x","y","z");
4643     # "axyz"
4644
4645     $foo = pack("a14","abcdefg");
4646     # "abcdefg\0\0\0\0\0\0\0"
4647
4648     $foo = pack("i9pl", gmtime);
4649     # a real struct tm (on my system anyway)
4650
4651     $utmp_template = "Z8 Z8 Z16 L";
4652     $utmp = pack($utmp_template, @utmp1);
4653     # a struct utmp (BSDish)
4654
4655     @utmp2 = unpack($utmp_template, $utmp);
4656     # "@utmp1" eq "@utmp2"
4657