This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Teach B::Concise about OPpFT_STACKING
[perl5.git] / ext / B / B / Concise.pm
1 package B::Concise;
2 # Copyright (C) 2000-2003 Stephen McCamant. All rights reserved.
3 # This program is free software; you can redistribute and/or modify it
4 # under the same terms as Perl itself.
5
6 # Note: we need to keep track of how many use declarations/BEGIN
7 # blocks this module uses, so we can avoid printing them when user
8 # asks for the BEGIN blocks in her program. Update the comments and
9 # the count in concise_specials if you add or delete one. The
10 # -MO=Concise counts as use #1.
11
12 use strict; # use #2
13 use warnings; # uses #3 and #4, since warnings uses Carp
14
15 use Exporter (); # use #5
16
17 our $VERSION   = "0.86";
18 our @ISA       = qw(Exporter);
19 our @EXPORT_OK = qw( set_style set_style_standard add_callback
20                      concise_subref concise_cv concise_main
21                      add_style walk_output compile reset_sequence );
22 our %EXPORT_TAGS =
23     ( io        => [qw( walk_output compile reset_sequence )],
24       style     => [qw( add_style set_style_standard )],
25       cb        => [qw( add_callback )],
26       mech      => [qw( concise_subref concise_cv concise_main )],  );
27
28 # use #6
29 use B qw(class ppname main_start main_root main_cv cstring svref_2object
30          SVf_IOK SVf_NOK SVf_POK SVf_IVisUV SVf_FAKE OPf_KIDS OPf_SPECIAL
31          CVf_ANON PAD_FAKELEX_ANON PAD_FAKELEX_MULTI SVf_ROK);
32
33 my %style =
34   ("terse" =>
35    ["(?(#label =>\n)?)(*(    )*)#class (#addr) #name (?([#targ])?) "
36     . "#svclass~(?((#svaddr))?)~#svval~(?(label \"#coplabel\")?)\n",
37     "(*(    )*)goto #class (#addr)\n",
38     "#class pp_#name"],
39    "concise" =>
40    ["#hyphseq2 (*(   (x( ;)x))*)<#classsym> #exname#arg(?([#targarglife])?)"
41     . "~#flags(?(/#private)?)(?(:#hints)?)(x(;~->#next)x)\n"
42     , "  (*(    )*)     goto #seq\n",
43     "(?(<#seq>)?)#exname#arg(?([#targarglife])?)"],
44    "linenoise" =>
45    ["(x(;(*( )*))x)#noise#arg(?([#targarg])?)(x( ;\n)x)",
46     "gt_#seq ",
47     "(?(#seq)?)#noise#arg(?([#targarg])?)"],
48    "debug" =>
49    ["#class (#addr)\n\top_next\t\t#nextaddr\n\top_sibling\t#sibaddr\n\t"
50     . "op_ppaddr\tPL_ppaddr[OP_#NAME]\n\top_type\t\t#typenum\n" .
51     ($] > 5.009 ? '' : "\top_seq\t\t#seqnum\n")
52     . "\top_flags\t#flagval\n\top_private\t#privval\t#hintsval\n"
53     . "(?(\top_first\t#firstaddr\n)?)(?(\top_last\t\t#lastaddr\n)?)"
54     . "(?(\top_sv\t\t#svaddr\n)?)",
55     "    GOTO #addr\n",
56     "#addr"],
57    "env" => [$ENV{B_CONCISE_FORMAT}, $ENV{B_CONCISE_GOTO_FORMAT},
58              $ENV{B_CONCISE_TREE_FORMAT}],
59   );
60
61 # Renderings, ie how Concise prints, is controlled by these vars
62 # primary:
63 our $stylename;         # selects current style from %style
64 my $order = "basic";    # how optree is walked & printed: basic, exec, tree
65
66 # rendering mechanics:
67 # these 'formats' are the line-rendering templates
68 # they're updated from %style when $stylename changes
69 my ($format, $gotofmt, $treefmt);
70
71 # lesser players:
72 my $base = 36;          # how <sequence#> is displayed
73 my $big_endian = 1;     # more <sequence#> display
74 my $tree_style = 0;     # tree-order details
75 my $banner = 1;         # print banner before optree is traversed
76 my $do_main = 0;        # force printing of main routine
77 my $show_src;           # show source code
78
79 # another factor: can affect all styles!
80 our @callbacks;         # allow external management
81
82 set_style_standard("concise");
83
84 my $curcv;
85 my $cop_seq_base;
86
87 sub set_style {
88     ($format, $gotofmt, $treefmt) = @_;
89     #warn "set_style: deprecated, use set_style_standard instead\n"; # someday
90     die "expecting 3 style-format args\n" unless @_ == 3;
91 }
92
93 sub add_style {
94     my ($newstyle,@args) = @_;
95     die "style '$newstyle' already exists, choose a new name\n"
96         if exists $style{$newstyle};
97     die "expecting 3 style-format args\n" unless @args == 3;
98     $style{$newstyle} = [@args];
99     $stylename = $newstyle; # update rendering state
100 }
101
102 sub set_style_standard {
103     ($stylename) = @_; # update rendering state
104     die "err: style '$stylename' unknown\n" unless exists $style{$stylename};
105     set_style(@{$style{$stylename}});
106 }
107
108 sub add_callback {
109     push @callbacks, @_;
110 }
111
112 # output handle, used with all Concise-output printing
113 our $walkHandle;        # public for your convenience
114 BEGIN { $walkHandle = \*STDOUT }
115
116 sub walk_output { # updates $walkHandle
117     my $handle = shift;
118     return $walkHandle unless $handle; # allow use as accessor
119
120     if (ref $handle eq 'SCALAR') {
121         require Config;
122         die "no perlio in this build, can't call walk_output (\\\$scalar)\n"
123             unless $Config::Config{useperlio};
124         # in 5.8+, open(FILEHANDLE,MODE,REFERENCE) writes to string
125         open my $tmp, '>', $handle;     # but cant re-set existing STDOUT
126         $walkHandle = $tmp;             # so use my $tmp as intermediate var
127         return $walkHandle;
128     }
129     my $iotype = ref $handle;
130     die "expecting argument/object that can print\n"
131         unless $iotype eq 'GLOB' or $iotype and $handle->can('print');
132     $walkHandle = $handle;
133 }
134
135 sub concise_subref {
136     my($order, $coderef, $name) = @_;
137     my $codeobj = svref_2object($coderef);
138
139     return concise_stashref(@_)
140         unless ref $codeobj eq 'B::CV';
141     concise_cv_obj($order, $codeobj, $name);
142 }
143
144 sub concise_stashref {
145     my($order, $h) = @_;
146     local *s;
147     foreach my $k (sort keys %$h) {
148         next unless defined $h->{$k};
149         *s = $h->{$k};
150         my $coderef = *s{CODE} or next;
151         reset_sequence();
152         print "FUNC: ", *s, "\n";
153         my $codeobj = svref_2object($coderef);
154         next unless ref $codeobj eq 'B::CV';
155         eval { concise_cv_obj($order, $codeobj, $k) };
156         warn "err $@ on $codeobj" if $@;
157     }
158 }
159
160 # This should have been called concise_subref, but it was exported
161 # under this name in versions before 0.56
162 *concise_cv = \&concise_subref;
163
164 sub concise_cv_obj {
165     my ($order, $cv, $name) = @_;
166     # name is either a string, or a CODE ref (copy of $cv arg??)
167
168     $curcv = $cv;
169
170     if (ref($cv->XSUBANY) =~ /B::(\w+)/) {
171         print $walkHandle "$name is a constant sub, optimized to a $1\n";
172         return;
173     }
174     if ($cv->XSUB) {
175         print $walkHandle "$name is XS code\n";
176         return;
177     }
178     if (class($cv->START) eq "NULL") {
179         no strict 'refs';
180         if (ref $name eq 'CODE') {
181             print $walkHandle "coderef $name has no START\n";
182         }
183         elsif (exists &$name) {
184             print $walkHandle "$name exists in stash, but has no START\n";
185         }
186         else {
187             print $walkHandle "$name not in symbol table\n";
188         }
189         return;
190     }
191     sequence($cv->START);
192     if ($order eq "exec") {
193         walk_exec($cv->START);
194     }
195     elsif ($order eq "basic") {
196         # walk_topdown($cv->ROOT, sub { $_[0]->concise($_[1]) }, 0);
197         my $root = $cv->ROOT;
198         unless (ref $root eq 'B::NULL') {
199             walk_topdown($root, sub { $_[0]->concise($_[1]) }, 0);
200         } else {
201             print $walkHandle "B::NULL encountered doing ROOT on $cv. avoiding disaster\n";
202         }
203     } else {
204         print $walkHandle tree($cv->ROOT, 0);
205     }
206 }
207
208 sub concise_main {
209     my($order) = @_;
210     sequence(main_start);
211     $curcv = main_cv;
212     if ($order eq "exec") {
213         return if class(main_start) eq "NULL";
214         walk_exec(main_start);
215     } elsif ($order eq "tree") {
216         return if class(main_root) eq "NULL";
217         print $walkHandle tree(main_root, 0);
218     } elsif ($order eq "basic") {
219         return if class(main_root) eq "NULL";
220         walk_topdown(main_root,
221                      sub { $_[0]->concise($_[1]) }, 0);
222     }
223 }
224
225 sub concise_specials {
226     my($name, $order, @cv_s) = @_;
227     my $i = 1;
228     if ($name eq "BEGIN") {
229         splice(@cv_s, 0, 8); # skip 7 BEGIN blocks in this file. NOW 8 ??
230     } elsif ($name eq "CHECK") {
231         pop @cv_s; # skip the CHECK block that calls us
232     }
233     for my $cv (@cv_s) {
234         print $walkHandle "$name $i:\n";
235         $i++;
236         concise_cv_obj($order, $cv, $name);
237     }
238 }
239
240 my $start_sym = "\e(0"; # "\cN" sometimes also works
241 my $end_sym   = "\e(B"; # "\cO" respectively
242
243 my @tree_decorations =
244   (["  ", "--", "+-", "|-", "| ", "`-", "-", 1],
245    [" ", "-", "+", "+", "|", "`", "", 0],
246    ["  ", map("$start_sym$_$end_sym", "qq", "wq", "tq", "x ", "mq", "q"), 1],
247    [" ", map("$start_sym$_$end_sym", "q", "w", "t", "x", "m"), "", 0],
248   );
249
250 my @render_packs; # collect -stash=<packages>
251
252 sub compileOpts {
253     # set rendering state from options and args
254     my (@options,@args);
255     if (@_) {
256         @options = grep(/^-/, @_);
257         @args = grep(!/^-/, @_);
258     }
259     for my $o (@options) {
260         # mode/order
261         if ($o eq "-basic") {
262             $order = "basic";
263         } elsif ($o eq "-exec") {
264             $order = "exec";
265         } elsif ($o eq "-tree") {
266             $order = "tree";
267         }
268         # tree-specific
269         elsif ($o eq "-compact") {
270             $tree_style |= 1;
271         } elsif ($o eq "-loose") {
272             $tree_style &= ~1;
273         } elsif ($o eq "-vt") {
274             $tree_style |= 2;
275         } elsif ($o eq "-ascii") {
276             $tree_style &= ~2;
277         }
278         # sequence numbering
279         elsif ($o =~ /^-base(\d+)$/) {
280             $base = $1;
281         } elsif ($o eq "-bigendian") {
282             $big_endian = 1;
283         } elsif ($o eq "-littleendian") {
284             $big_endian = 0;
285         }
286         # miscellaneous, presentation
287         elsif ($o eq "-nobanner") {
288             $banner = 0;
289         } elsif ($o eq "-banner") {
290             $banner = 1;
291         }
292         elsif ($o eq "-main") {
293             $do_main = 1;
294         } elsif ($o eq "-nomain") {
295             $do_main = 0;
296         } elsif ($o eq "-src") {
297             $show_src = 1;
298         }
299         elsif ($o =~ /^-stash=(.*)/) {
300             my $pkg = $1;
301             no strict 'refs';
302             if (! %{$pkg.'::'}) {
303                 eval "require $pkg";
304             } else {
305                 require Config;
306                 if (!$Config::Config{usedl}
307                     && keys %{$pkg.'::'} == 1
308                     && $pkg->can('bootstrap')) {
309                     # It is something that we're statically linked to, but hasn't
310                     # yet been used.
311                     eval "require $pkg";
312                 }
313             }
314             push @render_packs, $pkg;
315         }
316         # line-style options
317         elsif (exists $style{substr($o, 1)}) {
318             $stylename = substr($o, 1);
319             set_style_standard($stylename);
320         } else {
321             warn "Option $o unrecognized";
322         }
323     }
324     return (@args);
325 }
326
327 sub compile {
328     my (@args) = compileOpts(@_);
329     return sub {
330         my @newargs = compileOpts(@_); # accept new rendering options
331         warn "disregarding non-options: @newargs\n" if @newargs;
332
333         for my $objname (@args) {
334             next unless $objname; # skip null args to avoid noisy responses
335
336             if ($objname eq "BEGIN") {
337                 concise_specials("BEGIN", $order,
338                                  B::begin_av->isa("B::AV") ?
339                                  B::begin_av->ARRAY : ());
340             } elsif ($objname eq "INIT") {
341                 concise_specials("INIT", $order,
342                                  B::init_av->isa("B::AV") ?
343                                  B::init_av->ARRAY : ());
344             } elsif ($objname eq "CHECK") {
345                 concise_specials("CHECK", $order,
346                                  B::check_av->isa("B::AV") ?
347                                  B::check_av->ARRAY : ());
348             } elsif ($objname eq "UNITCHECK") {
349                 concise_specials("UNITCHECK", $order,
350                                  B::unitcheck_av->isa("B::AV") ?
351                                  B::unitcheck_av->ARRAY : ());
352             } elsif ($objname eq "END") {
353                 concise_specials("END", $order,
354                                  B::end_av->isa("B::AV") ?
355                                  B::end_av->ARRAY : ());
356             }
357             else {
358                 # convert function names to subrefs
359                 my $objref;
360                 if (ref $objname) {
361                     print $walkHandle "B::Concise::compile($objname)\n"
362                         if $banner;
363                     $objref = $objname;
364                 } else {
365                     $objname = "main::" . $objname unless $objname =~ /::/;
366                     print $walkHandle "$objname:\n";
367                     no strict 'refs';
368                     unless (exists &$objname) {
369                         print $walkHandle "err: unknown function ($objname)\n";
370                         return;
371                     }
372                     $objref = \&$objname;
373                 }
374                 concise_subref($order, $objref, $objname);
375             }
376         }
377         for my $pkg (@render_packs) {
378             no strict 'refs';
379             concise_stashref($order, \%{$pkg.'::'});
380         }
381
382         if (!@args or $do_main or @render_packs) {
383             print $walkHandle "main program:\n" if $do_main;
384             concise_main($order);
385         }
386         return @args;   # something
387     }
388 }
389
390 my %labels;
391 my $lastnext;   # remembers op-chain, used to insert gotos
392
393 my %opclass = ('OP' => "0", 'UNOP' => "1", 'BINOP' => "2", 'LOGOP' => "|",
394                'LISTOP' => "@", 'PMOP' => "/", 'SVOP' => "\$", 'GVOP' => "*",
395                'PVOP' => '"', 'LOOP' => "{", 'COP' => ";", 'PADOP' => "#");
396
397 no warnings 'qw'; # "Possible attempt to put comments..."; use #7
398 my @linenoise =
399   qw'#  () sc (  @? 1  $* gv *{ m$ m@ m% m? p/ *$ $  $# & a& pt \\ s\\ rf bl
400      `  *? <> ?? ?/ r/ c/ // qr s/ /c y/ =  @= C  sC Cp sp df un BM po +1 +I
401      -1 -I 1+ I+ 1- I- ** *  i* /  i/ %$ i% x  +  i+ -  i- .  "  << >> <  i<
402      >  i> <= i, >= i. == i= != i! <? i? s< s> s, s. s= s! s? b& b^ b| -0 -i
403      !  ~  a2 si cs rd sr e^ lg sq in %x %o ab le ss ve ix ri sf FL od ch cy
404      uf lf uc lc qm @  [f [  @[ eh vl ky dl ex %  ${ @{ uk pk st jn )  )[ a@
405      a% sl +] -] [- [+ so rv GS GW MS MW .. f. .f && || ^^ ?: &= |= -> s{ s}
406      v} ca wa di rs ;; ;  ;d }{ {  }  {} f{ it {l l} rt }l }n }r dm }g }e ^o
407      ^c ^| ^# um bm t~ u~ ~d DB db ^s se ^g ^r {w }w pf pr ^O ^K ^R ^W ^d ^v
408      ^e ^t ^k t. fc ic fl .s .p .b .c .l .a .h g1 s1 g2 s2 ?. l? -R -W -X -r
409      -w -x -e -o -O -z -s -M -A -C -S -c -b -f -d -p -l -u -g -k -t -T -B cd
410      co cr u. cm ut r. l@ s@ r@ mD uD oD rD tD sD wD cD f$ w$ p$ sh e$ k$ g3
411      g4 s4 g5 s5 T@ C@ L@ G@ A@ S@ Hg Hc Hr Hw Mg Mc Ms Mr Sg Sc So rq do {e
412      e} {t t} g6 G6 6e g7 G7 7e g8 G8 8e g9 G9 9e 6s 7s 8s 9s 6E 7E 8E 9E Pn
413      Pu GP SP EP Gn Gg GG SG EG g0 c$ lk t$ ;s n> // /= CO';
414
415 my $chars = "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ";
416
417 sub op_flags { # common flags (see BASOP.op_flags in op.h)
418     my($x) = @_;
419     my(@v);
420     push @v, "v" if ($x & 3) == 1;
421     push @v, "s" if ($x & 3) == 2;
422     push @v, "l" if ($x & 3) == 3;
423     push @v, "K" if $x & 4;
424     push @v, "P" if $x & 8;
425     push @v, "R" if $x & 16;
426     push @v, "M" if $x & 32;
427     push @v, "S" if $x & 64;
428     push @v, "*" if $x & 128;
429     return join("", @v);
430 }
431
432 sub base_n {
433     my $x = shift;
434     return "-" . base_n(-$x) if $x < 0;
435     my $str = "";
436     do { $str .= substr($chars, $x % $base, 1) } while $x = int($x / $base);
437     $str = reverse $str if $big_endian;
438     return $str;
439 }
440
441 my %sequence_num;
442 my $seq_max = 1;
443
444 sub reset_sequence {
445     # reset the sequence
446     %sequence_num = ();
447     $seq_max = 1;
448     $lastnext = 0;
449 }
450
451 sub seq {
452     my($op) = @_;
453     return "-" if not exists $sequence_num{$$op};
454     return base_n($sequence_num{$$op});
455 }
456
457 sub walk_topdown {
458     my($op, $sub, $level) = @_;
459     $sub->($op, $level);
460     if ($op->flags & OPf_KIDS) {
461         for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
462             walk_topdown($kid, $sub, $level + 1);
463         }
464     }
465     if (class($op) eq "PMOP") {
466         my $maybe_root = $op->pmreplroot;
467         if (ref($maybe_root) and $maybe_root->isa("B::OP")) {
468             # It really is the root of the replacement, not something
469             # else stored here for lack of space elsewhere
470             walk_topdown($maybe_root, $sub, $level + 1);
471         }
472     }
473 }
474
475 sub walklines {
476     my($ar, $level) = @_;
477     for my $l (@$ar) {
478         if (ref($l) eq "ARRAY") {
479             walklines($l, $level + 1);
480         } else {
481             $l->concise($level);
482         }
483     }
484 }
485
486 sub walk_exec {
487     my($top, $level) = @_;
488     my %opsseen;
489     my @lines;
490     my @todo = ([$top, \@lines]);
491     while (@todo and my($op, $targ) = @{shift @todo}) {
492         for (; $$op; $op = $op->next) {
493             last if $opsseen{$$op}++;
494             push @$targ, $op;
495             my $name = $op->name;
496             if (class($op) eq "LOGOP") {
497                 my $ar = [];
498                 push @$targ, $ar;
499                 push @todo, [$op->other, $ar];
500             } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
501                 my $ar = [];
502                 push @$targ, $ar;
503                 push @todo, [$op->pmreplstart, $ar];
504             } elsif ($name =~ /^enter(loop|iter)$/) {
505                 if ($] > 5.009) {
506                     $labels{${$op->nextop}} = "NEXT";
507                     $labels{${$op->lastop}} = "LAST";
508                     $labels{${$op->redoop}} = "REDO";
509                 } else {
510                     $labels{$op->nextop->seq} = "NEXT";
511                     $labels{$op->lastop->seq} = "LAST";
512                     $labels{$op->redoop->seq} = "REDO";         
513                 }
514             }
515         }
516     }
517     walklines(\@lines, 0);
518 }
519
520 # The structure of this routine is purposely modeled after op.c's peep()
521 sub sequence {
522     my($op) = @_;
523     my $oldop = 0;
524     return if class($op) eq "NULL" or exists $sequence_num{$$op};
525     for (; $$op; $op = $op->next) {
526         last if exists $sequence_num{$$op};
527         my $name = $op->name;
528         if ($name =~ /^(null|scalar|lineseq|scope)$/) {
529             next if $oldop and $ {$op->next};
530         } else {
531             $sequence_num{$$op} = $seq_max++;
532             if (class($op) eq "LOGOP") {
533                 my $other = $op->other;
534                 $other = $other->next while $other->name eq "null";
535                 sequence($other);
536             } elsif (class($op) eq "LOOP") {
537                 my $redoop = $op->redoop;
538                 $redoop = $redoop->next while $redoop->name eq "null";
539                 sequence($redoop);
540                 my $nextop = $op->nextop;
541                 $nextop = $nextop->next while $nextop->name eq "null";
542                 sequence($nextop);
543                 my $lastop = $op->lastop;
544                 $lastop = $lastop->next while $lastop->name eq "null";
545                 sequence($lastop);
546             } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
547                 my $replstart = $op->pmreplstart;
548                 $replstart = $replstart->next while $replstart->name eq "null";
549                 sequence($replstart);
550             }
551         }
552         $oldop = $op;
553     }
554 }
555
556 sub fmt_line {    # generate text-line for op.
557     my($hr, $op, $text, $level) = @_;
558
559     $_->($hr, $op, \$text, \$level, $stylename) for @callbacks;
560
561     return '' if $hr->{SKIP};   # suppress line if a callback said so
562     return '' if $hr->{goto} and $hr->{goto} eq '-';    # no goto nowhere
563
564     # spec: (?(text1#varText2)?)
565     $text =~ s/\(\?\(([^\#]*?)\#(\w+)([^\#]*?)\)\?\)/
566         $hr->{$2} ? $1.$hr->{$2}.$3 : ""/eg;
567
568     # spec: (x(exec_text;basic_text)x)
569     $text =~ s/\(x\((.*?);(.*?)\)x\)/$order eq "exec" ? $1 : $2/egs;
570
571     # spec: (*(text)*)
572     $text =~ s/\(\*\(([^;]*?)\)\*\)/$1 x $level/egs;
573
574     # spec: (*(text1;text2)*)
575     $text =~ s/\(\*\((.*?);(.*?)\)\*\)/$1 x ($level - 1) . $2 x ($level>0)/egs;
576
577     # convert #Var to tag=>val form: Var\t#var
578     $text =~ s/\#([A-Z][a-z]+)(\d+)?/\t\u$1\t\L#$1$2/gs;
579
580     # spec: #varN
581     $text =~ s/\#([a-zA-Z]+)(\d+)/sprintf("%-$2s", $hr->{$1})/eg;
582
583     $text =~ s/\#([a-zA-Z]+)/$hr->{$1}/eg;      # populate #var's
584     $text =~ s/[ \t]*~+[ \t]*/ /g;              # squeeze tildes
585
586     $text = "# $hr->{src}\n$text" if $show_src and $hr->{src};
587
588     chomp $text;
589     return "$text\n" if $text ne "" and $order ne "tree";
590     return $text; # suppress empty lines
591 }
592
593 our %priv; # used to display each opcode's BASEOP.op_private values
594
595 $priv{$_}{128} = "LVINTRO"
596   for ("pos", "substr", "vec", "threadsv", "gvsv", "rv2sv", "rv2hv", "rv2gv",
597        "rv2av", "rv2arylen", "aelem", "helem", "aslice", "hslice", "padsv",
598        "padav", "padhv", "enteriter", "entersub");
599 $priv{$_}{64} = "REFC" for ("leave", "leavesub", "leavesublv", "leavewrite");
600 $priv{"aassign"}{64} = "COMMON";
601 $priv{"aassign"}{32} = $] < 5.009 ? "PHASH" : "STATE";
602 $priv{"sassign"}{32} = "STATE";
603 $priv{"sassign"}{64} = "BKWARD";
604 $priv{"sassign"}{128}= "CV2GV";
605 $priv{$_}{64} = "RTIME" for ("match", "subst", "substcont", "qr");
606 @{$priv{"trans"}}{1,2,4,8,16,64} = ("<UTF", ">UTF", "IDENT", "SQUASH", "DEL",
607                                     "COMPL", "GROWS");
608 $priv{transr} = $priv{trans};
609 $priv{"repeat"}{64} = "DOLIST";
610 $priv{"leaveloop"}{64} = "CONT";
611 $priv{$_}{4} = "DREFed" for (qw(rv2sv rv2av rv2hv));
612 @{$priv{$_}}{32,64,96} = ("DREFAV", "DREFHV", "DREFSV")
613   for (qw(rv2gv rv2sv padsv aelem helem));
614 $priv{$_}{16} = "STATE" for ("padav", "padhv", "padsv");
615 $priv{rv2gv}{4} = "NOINIT";
616 @{$priv{"entersub"}}{1,4,16,32,64} = qw( INARGS TARG DBG DEREF );
617 @{$priv{rv2cv}}{1,8,128} = ("CONST","AMPER","NO()");
618 $priv{"gv"}{32} = "EARLYCV";
619 $priv{"aelem"}{16} = $priv{"helem"}{16} = "LVDEFER";
620 $priv{$_}{16} = "OURINTR" for ("gvsv", "rv2sv", "rv2av", "rv2hv", "r2gv",
621         "enteriter");
622 $priv{$_}{8} = 'LVSUB' for qw(rv2av rv2gv rv2hv padav padhv aelem helem
623                         aslice hslice av2arylen keys rkeys substr pos vec);
624 $priv{$_}{16} = "TARGMY"
625   for (map(($_,"s$_"),"chop", "chomp"),
626        map(($_,"i_$_"), "postinc", "postdec", "multiply", "divide", "modulo",
627            "add", "subtract", "negate"), "pow", "concat", "stringify",
628        "left_shift", "right_shift", "bit_and", "bit_xor", "bit_or",
629        "complement", "atan2", "sin", "cos", "rand", "exp", "log", "sqrt",
630        "int", "hex", "oct", "abs", "length", "index", "rindex", "sprintf",
631        "ord", "chr", "crypt", "quotemeta", "join", "push", "unshift", "flock",
632        "chdir", "chown", "chroot", "unlink", "chmod", "utime", "rename",
633        "link", "symlink", "mkdir", "rmdir", "wait", "waitpid", "system",
634        "exec", "kill", "getppid", "getpgrp", "setpgrp", "getpriority",
635        "setpriority", "time", "sleep");
636 $priv{$_}{4} = "REVERSED" for ("enteriter", "iter");
637 @{$priv{"const"}}{4,8,16,64,128} = ("SHORT","STRICT","ENTERED","BARE","WARN");
638 $priv{"flip"}{64} = $priv{"flop"}{64} = "LINENUM";
639 $priv{"list"}{64} = "GUESSED";
640 $priv{"delete"}{64} = "SLICE";
641 $priv{"exists"}{64} = "SUB";
642 @{$priv{"sort"}}{1,2,4,8,16,32,64} = ("NUM", "INT", "REV", "INPLACE","DESC","QSORT","STABLE");
643 $priv{"reverse"}{8} = "INPLACE";
644 $priv{"threadsv"}{64} = "SVREFd";
645 @{$priv{$_}}{16,32,64,128} = ("INBIN","INCR","OUTBIN","OUTCR")
646   for ("open", "backtick");
647 $priv{"exit"}{128} = "VMS";
648 $priv{$_}{2} = "FTACCESS"
649   for ("ftrread", "ftrwrite", "ftrexec", "fteread", "ftewrite", "fteexec");
650 $priv{"entereval"}{2} = "HAS_HH";
651 if ($] >= 5.009) {
652   # Stacked filetests are post 5.8.x
653   @{$priv{$_}}{4,8} = ("FTSTACKED","FTSTACKING")
654     for ("ftrread", "ftrwrite", "ftrexec", "fteread", "ftewrite", "fteexec",
655          "ftis", "fteowned", "ftrowned", "ftzero", "ftsize", "ftmtime",
656          "ftatime", "ftctime", "ftsock", "ftchr", "ftblk", "ftfile", "ftdir",
657          "ftpipe", "ftlink", "ftsuid", "ftsgid", "ftsvtx", "fttty", "fttext",
658          "ftbinary");
659   # Lexical $_ is post 5.8.x
660   $priv{$_}{2} = "GREPLEX"
661     for ("mapwhile", "mapstart", "grepwhile", "grepstart");
662 }
663 $priv{$_}{128} = '+1' for qw "caller wantarray";
664 @{$priv{coreargs}}{1,2,64,128} = ('DREF1','DREF2','$MOD','MARK');
665
666 our %hints; # used to display each COP's op_hints values
667
668 # strict refs, subs, vars
669 @hints{2,512,1024} = ('$', '&', '*');
670 # integers, locale, bytes
671 @hints{1,4,8,16} = ('i', 'l', 'b');
672 # block scope, localise %^H, $^OPEN (in), $^OPEN (out)
673 @hints{256,131072,262144,524288} = ('{','%','<','>');
674 # overload new integer, float, binary, string, re
675 @hints{4096,8192,16384,32768,65536} = ('I', 'F', 'B', 'S', 'R');
676 # taint and eval
677 @hints{1048576,2097152} = ('T', 'E');
678 # filetest access, UTF-8
679 @hints{4194304,8388608} = ('X', 'U');
680
681 sub _flags {
682     my($hash, $x) = @_;
683     my @s;
684     for my $flag (sort {$b <=> $a} keys %$hash) {
685         if ($hash->{$flag} and $x & $flag and $x >= $flag) {
686             $x -= $flag;
687             push @s, $hash->{$flag};
688         }
689     }
690     push @s, $x if $x;
691     return join(",", @s);
692 }
693
694 sub private_flags {
695     my($name, $x) = @_;
696     _flags($priv{$name}, $x);
697 }
698
699 sub hints_flags {
700     my($x) = @_;
701     _flags(\%hints, $x);
702 }
703
704 sub concise_sv {
705     my($sv, $hr, $preferpv) = @_;
706     $hr->{svclass} = class($sv);
707     $hr->{svclass} = "UV"
708       if $hr->{svclass} eq "IV" and $sv->FLAGS & SVf_IVisUV;
709     Carp::cluck("bad concise_sv: $sv") unless $sv and $$sv;
710     $hr->{svaddr} = sprintf("%#x", $$sv);
711     if ($hr->{svclass} eq "GV" && $sv->isGV_with_GP()) {
712         my $gv = $sv;
713         my $stash = $gv->STASH->NAME; if ($stash eq "main") {
714             $stash = "";
715         } else {
716             $stash = $stash . "::";
717         }
718         $hr->{svval} = "*$stash" . $gv->SAFENAME;
719         return "*$stash" . $gv->SAFENAME;
720     } else {
721         if ($] >= 5.011) {
722             while (class($sv) eq "IV" && $sv->FLAGS & SVf_ROK) {
723                 $hr->{svval} .= "\\";
724                 $sv = $sv->RV;
725             }
726         } else {
727             while (class($sv) eq "RV") {
728                 $hr->{svval} .= "\\";
729                 $sv = $sv->RV;
730             }
731         }
732         if (class($sv) eq "SPECIAL") {
733             $hr->{svval} .= ["Null", "sv_undef", "sv_yes", "sv_no"]->[$$sv];
734         } elsif ($preferpv && $sv->FLAGS & SVf_POK) {
735             $hr->{svval} .= cstring($sv->PV);
736         } elsif ($sv->FLAGS & SVf_NOK) {
737             $hr->{svval} .= $sv->NV;
738         } elsif ($sv->FLAGS & SVf_IOK) {
739             $hr->{svval} .= $sv->int_value;
740         } elsif ($sv->FLAGS & SVf_POK) {
741             $hr->{svval} .= cstring($sv->PV);
742         } elsif (class($sv) eq "HV") {
743             $hr->{svval} .= 'HASH';
744         }
745
746         $hr->{svval} = 'undef' unless defined $hr->{svval};
747         my $out = $hr->{svclass};
748         return $out .= " $hr->{svval}" ; 
749     }
750 }
751
752 my %srclines;
753
754 sub fill_srclines {
755     my $fullnm = shift;
756     if ($fullnm eq '-e') {
757         $srclines{$fullnm} = [ $fullnm, "-src not supported for -e" ];
758         return;
759     }
760     open (my $fh, '<', $fullnm)
761         or warn "# $fullnm: $!, (chdirs not supported by this feature yet)\n"
762         and return;
763     my @l = <$fh>;
764     chomp @l;
765     unshift @l, $fullnm; # like @{_<$fullnm} in debug, array starts at 1
766     $srclines{$fullnm} = \@l;
767 }
768
769 sub concise_op {
770     my ($op, $level, $format) = @_;
771     my %h;
772     $h{exname} = $h{name} = $op->name;
773     $h{NAME} = uc $h{name};
774     $h{class} = class($op);
775     $h{extarg} = $h{targ} = $op->targ;
776     $h{extarg} = "" unless $h{extarg};
777     if ($h{name} eq "null" and $h{targ}) {
778         # targ holds the old type
779         $h{exname} = "ex-" . substr(ppname($h{targ}), 3);
780         $h{extarg} = "";
781     } elsif ($op->name =~ /^leave(sub(lv)?|write)?$/) {
782         # targ potentially holds a reference count
783         if ($op->private & 64) {
784             my $refs = "ref" . ($h{targ} != 1 ? "s" : "");
785             $h{targarglife} = $h{targarg} = "$h{targ} $refs";
786         }
787     } elsif ($h{targ}) {
788         my $padname = (($curcv->PADLIST->ARRAY)[0]->ARRAY)[$h{targ}];
789         if (defined $padname and class($padname) ne "SPECIAL") {
790             $h{targarg}  = $padname->PVX;
791             if ($padname->FLAGS & SVf_FAKE) {
792                 if ($] < 5.009) {
793                     $h{targarglife} = "$h{targarg}:FAKE";
794                 } else {
795                     # These changes relate to the jumbo closure fix.
796                     # See changes 19939 and 20005
797                     my $fake = '';
798                     $fake .= 'a'
799                         if $padname->PARENT_FAKELEX_FLAGS & PAD_FAKELEX_ANON;
800                     $fake .= 'm'
801                         if $padname->PARENT_FAKELEX_FLAGS & PAD_FAKELEX_MULTI;
802                     $fake .= ':' . $padname->PARENT_PAD_INDEX
803                         if $curcv->CvFLAGS & CVf_ANON;
804                     $h{targarglife} = "$h{targarg}:FAKE:$fake";
805                 }
806             }
807             else {
808                 my $intro = $padname->COP_SEQ_RANGE_LOW - $cop_seq_base;
809                 my $finish = int($padname->COP_SEQ_RANGE_HIGH) - $cop_seq_base;
810                 $finish = "end" if $finish == 999999999 - $cop_seq_base;
811                 $h{targarglife} = "$h{targarg}:$intro,$finish";
812             }
813         } else {
814             $h{targarglife} = $h{targarg} = "t" . $h{targ};
815         }
816     }
817     $h{arg} = "";
818     $h{svclass} = $h{svaddr} = $h{svval} = "";
819     if ($h{class} eq "PMOP") {
820         my $precomp = $op->precomp;
821         if (defined $precomp) {
822             $precomp = cstring($precomp); # Escape literal control sequences
823             $precomp = "/$precomp/";
824         } else {
825             $precomp = "";
826         }
827         my $pmreplroot = $op->pmreplroot;
828         my $pmreplstart;
829         if (ref($pmreplroot) eq "B::GV") {
830             # with C<@stash_array = split(/pat/, str);>,
831             #  *stash_array is stored in /pat/'s pmreplroot.
832             $h{arg} = "($precomp => \@" . $pmreplroot->NAME . ")";
833         } elsif (!ref($pmreplroot) and $pmreplroot) {
834             # same as the last case, except the value is actually a
835             # pad offset for where the GV is kept (this happens under
836             # ithreads)
837             my $gv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$pmreplroot];
838             $h{arg} = "($precomp => \@" . $gv->NAME . ")";
839         } elsif ($ {$op->pmreplstart}) {
840             undef $lastnext;
841             $pmreplstart = "replstart->" . seq($op->pmreplstart);
842             $h{arg} = "(" . join(" ", $precomp, $pmreplstart) . ")";
843         } else {
844             $h{arg} = "($precomp)";
845         }
846     } elsif ($h{class} eq "PVOP" and $h{name} !~ '^transr?\z') {
847         $h{arg} = '("' . $op->pv . '")';
848         $h{svval} = '"' . $op->pv . '"';
849     } elsif ($h{class} eq "COP") {
850         my $label = $op->label;
851         $h{coplabel} = $label;
852         $label = $label ? "$label: " : "";
853         my $loc = $op->file;
854         my $pathnm = $loc;
855         $loc =~ s[.*/][];
856         my $ln = $op->line;
857         $loc .= ":$ln";
858         my($stash, $cseq) = ($op->stash->NAME, $op->cop_seq - $cop_seq_base);
859         $h{arg} = "($label$stash $cseq $loc)";
860         if ($show_src) {
861             fill_srclines($pathnm) unless exists $srclines{$pathnm};
862             # Would love to retain Jim's use of // but this code needs to be
863             # portable to 5.8.x
864             my $line = $srclines{$pathnm}[$ln];
865             $line = "-src unavailable under -e" unless defined $line;
866             $h{src} = "$ln: $line";
867         }
868     } elsif ($h{class} eq "LOOP") {
869         $h{arg} = "(next->" . seq($op->nextop) . " last->" . seq($op->lastop)
870           . " redo->" . seq($op->redoop) . ")";
871     } elsif ($h{class} eq "LOGOP") {
872         undef $lastnext;
873         $h{arg} = "(other->" . seq($op->other) . ")";
874     }
875     elsif ($h{class} eq "SVOP" or $h{class} eq "PADOP") {
876         unless ($h{name} eq 'aelemfast' and $op->flags & OPf_SPECIAL) {
877             my $idx = ($h{class} eq "SVOP") ? $op->targ : $op->padix;
878             my $preferpv = $h{name} eq "method_named";
879             if ($h{class} eq "PADOP" or !${$op->sv}) {
880                 my $sv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$idx];
881                 $h{arg} = "[" . concise_sv($sv, \%h, $preferpv) . "]";
882                 $h{targarglife} = $h{targarg} = "";
883             } else {
884                 $h{arg} = "(" . concise_sv($op->sv, \%h, $preferpv) . ")";
885             }
886         }
887     }
888     $h{seq} = $h{hyphseq} = seq($op);
889     $h{seq} = "" if $h{seq} eq "-";
890     if ($] > 5.009) {
891         $h{opt} = $op->opt;
892         $h{label} = $labels{$$op};
893     } else {
894         $h{seqnum} = $op->seq;
895         $h{label} = $labels{$op->seq};
896     }
897     $h{next} = $op->next;
898     $h{next} = (class($h{next}) eq "NULL") ? "(end)" : seq($h{next});
899     $h{nextaddr} = sprintf("%#x", $ {$op->next});
900     $h{sibaddr} = sprintf("%#x", $ {$op->sibling});
901     $h{firstaddr} = sprintf("%#x", $ {$op->first}) if $op->can("first");
902     $h{lastaddr} = sprintf("%#x", $ {$op->last}) if $op->can("last");
903
904     $h{classsym} = $opclass{$h{class}};
905     $h{flagval} = $op->flags;
906     $h{flags} = op_flags($op->flags);
907     $h{privval} = $op->private;
908     $h{private} = private_flags($h{name}, $op->private);
909     if ($op->can("hints")) {
910       $h{hintsval} = $op->hints;
911       $h{hints} = hints_flags($h{hintsval});
912     } else {
913       $h{hintsval} = $h{hints} = '';
914     }
915     $h{addr} = sprintf("%#x", $$op);
916     $h{typenum} = $op->type;
917     $h{noise} = $linenoise[$op->type];
918
919     return fmt_line(\%h, $op, $format, $level);
920 }
921
922 sub B::OP::concise {
923     my($op, $level) = @_;
924     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
925         # insert a 'goto' line
926         my $synth = {"seq" => seq($lastnext), "class" => class($lastnext),
927                      "addr" => sprintf("%#x", $$lastnext),
928                      "goto" => seq($lastnext), # simplify goto '-' removal
929              };
930         print $walkHandle fmt_line($synth, $op, $gotofmt, $level+1);
931     }
932     $lastnext = $op->next;
933     print $walkHandle concise_op($op, $level, $format);
934 }
935
936 # B::OP::terse (see Terse.pm) now just calls this
937 sub b_terse {
938     my($op, $level) = @_;
939
940     # This isn't necessarily right, but there's no easy way to get
941     # from an OP to the right CV. This is a limitation of the
942     # ->terse() interface style, and there isn't much to do about
943     # it. In particular, we can die in concise_op if the main pad
944     # isn't long enough, or has the wrong kind of entries, compared to
945     # the pad a sub was compiled with. The fix for that would be to
946     # make a backwards compatible "terse" format that never even
947     # looked at the pad, just like the old B::Terse. I don't think
948     # that's worth the effort, though.
949     $curcv = main_cv unless $curcv;
950
951     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
952         # insert a 'goto'
953         my $h = {"seq" => seq($lastnext), "class" => class($lastnext),
954                  "addr" => sprintf("%#x", $$lastnext)};
955         print # $walkHandle
956             fmt_line($h, $op, $style{"terse"}[1], $level+1);
957     }
958     $lastnext = $op->next;
959     print # $walkHandle 
960         concise_op($op, $level, $style{"terse"}[0]);
961 }
962
963 sub tree {
964     my $op = shift;
965     my $level = shift;
966     my $style = $tree_decorations[$tree_style];
967     my($space, $single, $kids, $kid, $nokid, $last, $lead, $size) = @$style;
968     my $name = concise_op($op, $level, $treefmt);
969     if (not $op->flags & OPf_KIDS) {
970         return $name . "\n";
971     }
972     my @lines;
973     for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
974         push @lines, tree($kid, $level+1);
975     }
976     my $i;
977     for ($i = $#lines; substr($lines[$i], 0, 1) eq " "; $i--) {
978         $lines[$i] = $space . $lines[$i];
979     }
980     if ($i > 0) {
981         $lines[$i] = $last . $lines[$i];
982         while ($i-- > 1) {
983             if (substr($lines[$i], 0, 1) eq " ") {
984                 $lines[$i] = $nokid . $lines[$i];
985             } else {
986                 $lines[$i] = $kid . $lines[$i];
987             }
988         }
989         $lines[$i] = $kids . $lines[$i];
990     } else {
991         $lines[0] = $single . $lines[0];
992     }
993     return("$name$lead" . shift @lines,
994            map(" " x (length($name)+$size) . $_, @lines));
995 }
996
997 # *** Warning: fragile kludge ahead ***
998 # Because the B::* modules run in the same interpreter as the code
999 # they're compiling, their presence tends to distort the view we have of
1000 # the code we're looking at. In particular, perl gives sequence numbers
1001 # to COPs. If the program we're looking at were run on its own, this
1002 # would start at 1. Because all of B::Concise and all the modules it
1003 # uses are compiled first, though, by the time we get to the user's
1004 # program the sequence number is already pretty high, which could be
1005 # distracting if you're trying to tell OPs apart. Therefore we'd like to
1006 # subtract an offset from all the sequence numbers we display, to
1007 # restore the simpler view of the world. The trick is to know what that
1008 # offset will be, when we're still compiling B::Concise!  If we
1009 # hardcoded a value, it would have to change every time B::Concise or
1010 # other modules we use do. To help a little, what we do here is compile
1011 # a little code at the end of the module, and compute the base sequence
1012 # number for the user's program as being a small offset later, so all we
1013 # have to worry about are changes in the offset.
1014
1015 # [For 5.8.x and earlier perl is generating sequence numbers for all ops,
1016 #  and using them to reference labels]
1017
1018
1019 # When you say "perl -MO=Concise -e '$a'", the output should look like:
1020
1021 # 4  <@> leave[t1] vKP/REFC ->(end)
1022 # 1     <0> enter ->2
1023  #^ smallest OP sequence number should be 1
1024 # 2     <;> nextstate(main 1 -e:1) v ->3
1025  #                         ^ smallest COP sequence number should be 1
1026 # -     <1> ex-rv2sv vK/1 ->4
1027 # 3        <$> gvsv(*a) s ->4
1028
1029 # If the second of the marked numbers there isn't 1, it means you need
1030 # to update the corresponding magic number in the next line.
1031 # Remember, this needs to stay the last things in the module.
1032
1033 # Why is this different for MacOS?  Does it matter?
1034 my $cop_seq_mnum = $^O eq 'MacOS' ? 12 : 11;
1035 $cop_seq_base = svref_2object(eval 'sub{0;}')->START->cop_seq + $cop_seq_mnum;
1036
1037 1;
1038
1039 __END__
1040
1041 =head1 NAME
1042
1043 B::Concise - Walk Perl syntax tree, printing concise info about ops
1044
1045 =head1 SYNOPSIS
1046
1047     perl -MO=Concise[,OPTIONS] foo.pl
1048
1049     use B::Concise qw(set_style add_callback);
1050
1051 =head1 DESCRIPTION
1052
1053 This compiler backend prints the internal OPs of a Perl program's syntax
1054 tree in one of several space-efficient text formats suitable for debugging
1055 the inner workings of perl or other compiler backends. It can print OPs in
1056 the order they appear in the OP tree, in the order they will execute, or
1057 in a text approximation to their tree structure, and the format of the
1058 information displayed is customizable. Its function is similar to that of
1059 perl's B<-Dx> debugging flag or the B<B::Terse> module, but it is more
1060 sophisticated and flexible.
1061
1062 =head1 EXAMPLE
1063
1064 Here's two outputs (or 'renderings'), using the -exec and -basic
1065 (i.e. default) formatting conventions on the same code snippet.
1066
1067     % perl -MO=Concise,-exec -e '$a = $b + 42'
1068     1  <0> enter
1069     2  <;> nextstate(main 1 -e:1) v
1070     3  <#> gvsv[*b] s
1071     4  <$> const[IV 42] s
1072  *  5  <2> add[t3] sK/2
1073     6  <#> gvsv[*a] s
1074     7  <2> sassign vKS/2
1075     8  <@> leave[1 ref] vKP/REFC
1076
1077 In this -exec rendering, each opcode is executed in the order shown.
1078 The add opcode, marked with '*', is discussed in more detail.
1079
1080 The 1st column is the op's sequence number, starting at 1, and is
1081 displayed in base 36 by default.  Here they're purely linear; the
1082 sequences are very helpful when looking at code with loops and
1083 branches.
1084
1085 The symbol between angle brackets indicates the op's type, for
1086 example; <2> is a BINOP, <@> a LISTOP, and <#> is a PADOP, which is
1087 used in threaded perls. (see L</"OP class abbreviations">).
1088
1089 The opname, as in B<'add[t1]'>, may be followed by op-specific
1090 information in parentheses or brackets (ex B<'[t1]'>).
1091
1092 The op-flags (ex B<'sK/2'>) are described in (L</"OP flags
1093 abbreviations">).
1094
1095     % perl -MO=Concise -e '$a = $b + 42'
1096     8  <@> leave[1 ref] vKP/REFC ->(end)
1097     1     <0> enter ->2
1098     2     <;> nextstate(main 1 -e:1) v ->3
1099     7     <2> sassign vKS/2 ->8
1100  *  5        <2> add[t1] sK/2 ->6
1101     -           <1> ex-rv2sv sK/1 ->4
1102     3              <$> gvsv(*b) s ->4
1103     4           <$> const(IV 42) s ->5
1104     -        <1> ex-rv2sv sKRM*/1 ->7
1105     6           <$> gvsv(*a) s ->7
1106
1107 The default rendering is top-down, so they're not in execution order.
1108 This form reflects the way the stack is used to parse and evaluate
1109 expressions; the add operates on the two terms below it in the tree.
1110
1111 Nullops appear as C<ex-opname>, where I<opname> is an op that has been
1112 optimized away by perl.  They're displayed with a sequence-number of
1113 '-', because they are not executed (they don't appear in previous
1114 example), they're printed here because they reflect the parse.
1115
1116 The arrow points to the sequence number of the next op; they're not
1117 displayed in -exec mode, for obvious reasons.
1118
1119 Note that because this rendering was done on a non-threaded perl, the
1120 PADOPs in the previous examples are now SVOPs, and some (but not all)
1121 of the square brackets have been replaced by round ones.  This is a
1122 subtle feature to provide some visual distinction between renderings
1123 on threaded and un-threaded perls.
1124
1125
1126 =head1 OPTIONS
1127
1128 Arguments that don't start with a hyphen are taken to be the names of
1129 subroutines to render; if no such functions are specified, the main
1130 body of the program (outside any subroutines, and not including use'd
1131 or require'd files) is rendered.  Passing C<BEGIN>, C<UNITCHECK>,
1132 C<CHECK>, C<INIT>, or C<END> will cause all of the corresponding
1133 special blocks to be printed.  Arguments must follow options.
1134
1135 Options affect how things are rendered (ie printed).  They're presented
1136 here by their visual effect, 1st being strongest.  They're grouped
1137 according to how they interrelate; within each group the options are
1138 mutually exclusive (unless otherwise stated).
1139
1140 =head2 Options for Opcode Ordering
1141
1142 These options control the 'vertical display' of opcodes.  The display
1143 'order' is also called 'mode' elsewhere in this document.
1144
1145 =over 4
1146
1147 =item B<-basic>
1148
1149 Print OPs in the order they appear in the OP tree (a preorder
1150 traversal, starting at the root). The indentation of each OP shows its
1151 level in the tree, and the '->' at the end of the line indicates the
1152 next opcode in execution order.  This mode is the default, so the flag
1153 is included simply for completeness.
1154
1155 =item B<-exec>
1156
1157 Print OPs in the order they would normally execute (for the majority
1158 of constructs this is a postorder traversal of the tree, ending at the
1159 root). In most cases the OP that usually follows a given OP will
1160 appear directly below it; alternate paths are shown by indentation. In
1161 cases like loops when control jumps out of a linear path, a 'goto'
1162 line is generated.
1163
1164 =item B<-tree>
1165
1166 Print OPs in a text approximation of a tree, with the root of the tree
1167 at the left and 'left-to-right' order of children transformed into
1168 'top-to-bottom'. Because this mode grows both to the right and down,
1169 it isn't suitable for large programs (unless you have a very wide
1170 terminal).
1171
1172 =back
1173
1174 =head2 Options for Line-Style
1175
1176 These options select the line-style (or just style) used to render
1177 each opcode, and dictates what info is actually printed into each line.
1178
1179 =over 4
1180
1181 =item B<-concise>
1182
1183 Use the author's favorite set of formatting conventions. This is the
1184 default, of course.
1185
1186 =item B<-terse>
1187
1188 Use formatting conventions that emulate the output of B<B::Terse>. The
1189 basic mode is almost indistinguishable from the real B<B::Terse>, and the
1190 exec mode looks very similar, but is in a more logical order and lacks
1191 curly brackets. B<B::Terse> doesn't have a tree mode, so the tree mode
1192 is only vaguely reminiscent of B<B::Terse>.
1193
1194 =item B<-linenoise>
1195
1196 Use formatting conventions in which the name of each OP, rather than being
1197 written out in full, is represented by a one- or two-character abbreviation.
1198 This is mainly a joke.
1199
1200 =item B<-debug>
1201
1202 Use formatting conventions reminiscent of B<B::Debug>; these aren't
1203 very concise at all.
1204
1205 =item B<-env>
1206
1207 Use formatting conventions read from the environment variables
1208 C<B_CONCISE_FORMAT>, C<B_CONCISE_GOTO_FORMAT>, and C<B_CONCISE_TREE_FORMAT>.
1209
1210 =back
1211
1212 =head2 Options for tree-specific formatting
1213
1214 =over 4
1215
1216 =item B<-compact>
1217
1218 Use a tree format in which the minimum amount of space is used for the
1219 lines connecting nodes (one character in most cases). This squeezes out
1220 a few precious columns of screen real estate.
1221
1222 =item B<-loose>
1223
1224 Use a tree format that uses longer edges to separate OP nodes. This format
1225 tends to look better than the compact one, especially in ASCII, and is
1226 the default.
1227
1228 =item B<-vt>
1229
1230 Use tree connecting characters drawn from the VT100 line-drawing set.
1231 This looks better if your terminal supports it.
1232
1233 =item B<-ascii>
1234
1235 Draw the tree with standard ASCII characters like C<+> and C<|>. These don't
1236 look as clean as the VT100 characters, but they'll work with almost any
1237 terminal (or the horizontal scrolling mode of less(1)) and are suitable
1238 for text documentation or email. This is the default.
1239
1240 =back
1241
1242 These are pairwise exclusive, i.e. compact or loose, vt or ascii.
1243
1244 =head2 Options controlling sequence numbering
1245
1246 =over 4
1247
1248 =item B<-base>I<n>
1249
1250 Print OP sequence numbers in base I<n>. If I<n> is greater than 10, the
1251 digit for 11 will be 'a', and so on. If I<n> is greater than 36, the digit
1252 for 37 will be 'A', and so on until 62. Values greater than 62 are not
1253 currently supported. The default is 36.
1254
1255 =item B<-bigendian>
1256
1257 Print sequence numbers with the most significant digit first. This is the
1258 usual convention for Arabic numerals, and the default.
1259
1260 =item B<-littleendian>
1261
1262 Print sequence numbers with the least significant digit first.  This is
1263 obviously mutually exclusive with bigendian.
1264
1265 =back
1266
1267 =head2 Other options
1268
1269 =over 4
1270
1271 =item B<-src>
1272
1273 With this option, the rendering of each statement (starting with the
1274 nextstate OP) will be preceded by the 1st line of source code that
1275 generates it.  For example:
1276
1277     1  <0> enter
1278     # 1: my $i;
1279     2  <;> nextstate(main 1 junk.pl:1) v:{
1280     3  <0> padsv[$i:1,10] vM/LVINTRO
1281     # 3: for $i (0..9) {
1282     4  <;> nextstate(main 3 junk.pl:3) v:{
1283     5  <0> pushmark s
1284     6  <$> const[IV 0] s
1285     7  <$> const[IV 9] s
1286     8  <{> enteriter(next->j last->m redo->9)[$i:1,10] lKS
1287     k  <0> iter s
1288     l  <|> and(other->9) vK/1
1289     # 4:     print "line ";
1290     9      <;> nextstate(main 2 junk.pl:4) v
1291     a      <0> pushmark s
1292     b      <$> const[PV "line "] s
1293     c      <@> print vK
1294     # 5:     print "$i\n";
1295     ...
1296
1297 =item B<-stash="somepackage">
1298
1299 With this, "somepackage" will be required, then the stash is
1300 inspected, and each function is rendered.
1301
1302 =back
1303
1304 The following options are pairwise exclusive.
1305
1306 =over 4
1307
1308 =item B<-main>
1309
1310 Include the main program in the output, even if subroutines were also
1311 specified.  This rendering is normally suppressed when a subroutine
1312 name or reference is given.
1313
1314 =item B<-nomain>
1315
1316 This restores the default behavior after you've changed it with '-main'
1317 (it's not normally needed).  If no subroutine name/ref is given, main is
1318 rendered, regardless of this flag.
1319
1320 =item B<-nobanner>
1321
1322 Renderings usually include a banner line identifying the function name
1323 or stringified subref.  This suppresses the printing of the banner.
1324
1325 TBC: Remove the stringified coderef; while it provides a 'cookie' for
1326 each function rendered, the cookies used should be 1,2,3.. not a
1327 random hex-address.  It also complicates string comparison of two
1328 different trees.
1329
1330 =item B<-banner>
1331
1332 restores default banner behavior.
1333
1334 =item B<-banneris> => subref
1335
1336 TBC: a hookpoint (and an option to set it) for a user-supplied
1337 function to produce a banner appropriate for users needs.  It's not
1338 ideal, because the rendering-state variables, which are a natural
1339 candidate for use in concise.t, are unavailable to the user.
1340
1341 =back
1342
1343 =head2 Option Stickiness
1344
1345 If you invoke Concise more than once in a program, you should know that
1346 the options are 'sticky'.  This means that the options you provide in
1347 the first call will be remembered for the 2nd call, unless you
1348 re-specify or change them.
1349
1350 =head1 ABBREVIATIONS
1351
1352 The concise style uses symbols to convey maximum info with minimal
1353 clutter (like hex addresses).  With just a little practice, you can
1354 start to see the flowers, not just the branches, in the trees.
1355
1356 =head2 OP class abbreviations
1357
1358 These symbols appear before the op-name, and indicate the
1359 B:: namespace that represents the ops in your Perl code.
1360
1361     0      OP (aka BASEOP)  An OP with no children
1362     1      UNOP             An OP with one child
1363     2      BINOP            An OP with two children
1364     |      LOGOP            A control branch OP
1365     @      LISTOP           An OP that could have lots of children
1366     /      PMOP             An OP with a regular expression
1367     $      SVOP             An OP with an SV
1368     "      PVOP             An OP with a string
1369     {      LOOP             An OP that holds pointers for a loop
1370     ;      COP              An OP that marks the start of a statement
1371     #      PADOP            An OP with a GV on the pad
1372
1373 =head2 OP flags abbreviations
1374
1375 OP flags are either public or private.  The public flags alter the
1376 behavior of each opcode in consistent ways, and are represented by 0
1377 or more single characters.
1378
1379     v      OPf_WANT_VOID    Want nothing (void context)
1380     s      OPf_WANT_SCALAR  Want single value (scalar context)
1381     l      OPf_WANT_LIST    Want list of any length (list context)
1382                             Want is unknown
1383     K      OPf_KIDS         There is a firstborn child.
1384     P      OPf_PARENS       This operator was parenthesized.
1385                              (Or block needs explicit scope entry.)
1386     R      OPf_REF          Certified reference.
1387                              (Return container, not containee).
1388     M      OPf_MOD          Will modify (lvalue).
1389     S      OPf_STACKED      Some arg is arriving on the stack.
1390     *      OPf_SPECIAL      Do something weird for this op (see op.h)
1391
1392 Private flags, if any are set for an opcode, are displayed after a '/'
1393
1394     8  <@> leave[1 ref] vKP/REFC ->(end)
1395     7     <2> sassign vKS/2 ->8
1396
1397 They're opcode specific, and occur less often than the public ones, so
1398 they're represented by short mnemonics instead of single-chars; see
1399 F<op.h> for gory details, or try this quick 2-liner:
1400
1401   $> perl -MB::Concise -de 1
1402   DB<1> |x \%B::Concise::priv
1403
1404 =head1 FORMATTING SPECIFICATIONS
1405
1406 For each line-style ('concise', 'terse', 'linenoise', etc.) there are
1407 3 format-specs which control how OPs are rendered.
1408
1409 The first is the 'default' format, which is used in both basic and exec
1410 modes to print all opcodes.  The 2nd, goto-format, is used in exec
1411 mode when branches are encountered.  They're not real opcodes, and are
1412 inserted to look like a closing curly brace.  The tree-format is tree
1413 specific.
1414
1415 When a line is rendered, the correct format-spec is copied and scanned
1416 for the following items; data is substituted in, and other
1417 manipulations like basic indenting are done, for each opcode rendered.
1418
1419 There are 3 kinds of items that may be populated; special patterns,
1420 #vars, and literal text, which is copied verbatim.  (Yes, it's a set
1421 of s///g steps.)
1422
1423 =head2 Special Patterns
1424
1425 These items are the primitives used to perform indenting, and to
1426 select text from amongst alternatives.
1427
1428 =over 4
1429
1430 =item B<(x(>I<exec_text>B<;>I<basic_text>B<)x)>
1431
1432 Generates I<exec_text> in exec mode, or I<basic_text> in basic mode.
1433
1434 =item B<(*(>I<text>B<)*)>
1435
1436 Generates one copy of I<text> for each indentation level.
1437
1438 =item B<(*(>I<text1>B<;>I<text2>B<)*)>
1439
1440 Generates one fewer copies of I<text1> than the indentation level, followed
1441 by one copy of I<text2> if the indentation level is more than 0.
1442
1443 =item B<(?(>I<text1>B<#>I<var>I<Text2>B<)?)>
1444
1445 If the value of I<var> is true (not empty or zero), generates the
1446 value of I<var> surrounded by I<text1> and I<Text2>, otherwise
1447 nothing.
1448
1449 =item B<~>
1450
1451 Any number of tildes and surrounding whitespace will be collapsed to
1452 a single space.
1453
1454 =back
1455
1456 =head2 # Variables
1457
1458 These #vars represent opcode properties that you may want as part of
1459 your rendering.  The '#' is intended as a private sigil; a #var's
1460 value is interpolated into the style-line, much like "read $this".
1461
1462 These vars take 3 forms:
1463
1464 =over 4
1465
1466 =item B<#>I<var>
1467
1468 A property named 'var' is assumed to exist for the opcodes, and is
1469 interpolated into the rendering.
1470
1471 =item B<#>I<var>I<N>
1472
1473 Generates the value of I<var>, left justified to fill I<N> spaces.
1474 Note that this means while you can have properties 'foo' and 'foo2',
1475 you cannot render 'foo2', but you could with 'foo2a'.  You would be
1476 wise not to rely on this behavior going forward ;-)
1477
1478 =item B<#>I<Var>
1479
1480 This ucfirst form of #var generates a tag-value form of itself for
1481 display; it converts '#Var' into a 'Var => #var' style, which is then
1482 handled as described above.  (Imp-note: #Vars cannot be used for
1483 conditional-fills, because the => #var transform is done after the check
1484 for #Var's value).
1485
1486 =back
1487
1488 The following variables are 'defined' by B::Concise; when they are
1489 used in a style, their respective values are plugged into the
1490 rendering of each opcode.
1491
1492 Only some of these are used by the standard styles, the others are
1493 provided for you to delve into optree mechanics, should you wish to
1494 add a new style (see L</add_style> below) that uses them.  You can
1495 also add new ones using L</add_callback>.
1496
1497 =over 4
1498
1499 =item B<#addr>
1500
1501 The address of the OP, in hexadecimal.
1502
1503 =item B<#arg>
1504
1505 The OP-specific information of the OP (such as the SV for an SVOP, the
1506 non-local exit pointers for a LOOP, etc.) enclosed in parentheses.
1507
1508 =item B<#class>
1509
1510 The B-determined class of the OP, in all caps.
1511
1512 =item B<#classsym>
1513
1514 A single symbol abbreviating the class of the OP.
1515
1516 =item B<#coplabel>
1517
1518 The label of the statement or block the OP is the start of, if any.
1519
1520 =item B<#exname>
1521
1522 The name of the OP, or 'ex-foo' if the OP is a null that used to be a foo.
1523
1524 =item B<#extarg>
1525
1526 The target of the OP, or nothing for a nulled OP.
1527
1528 =item B<#firstaddr>
1529
1530 The address of the OP's first child, in hexadecimal.
1531
1532 =item B<#flags>
1533
1534 The OP's flags, abbreviated as a series of symbols.
1535
1536 =item B<#flagval>
1537
1538 The numeric value of the OP's flags.
1539
1540 =item B<#hints>
1541
1542 The COP's hint flags, rendered with abbreviated names if possible. An empty
1543 string if this is not a COP. Here are the symbols used:
1544
1545     $ strict refs
1546     & strict subs
1547     * strict vars
1548     i integers
1549     l locale
1550     b bytes
1551     { block scope
1552     % localise %^H
1553     < open in
1554     > open out
1555     I overload int
1556     F overload float
1557     B overload binary
1558     S overload string
1559     R overload re
1560     T taint
1561     E eval
1562     X filetest access
1563     U utf-8
1564
1565 =item B<#hintsval>
1566
1567 The numeric value of the COP's hint flags, or an empty string if this is not
1568 a COP.
1569
1570 =item B<#hyphseq>
1571
1572 The sequence number of the OP, or a hyphen if it doesn't have one.
1573
1574 =item B<#label>
1575
1576 'NEXT', 'LAST', or 'REDO' if the OP is a target of one of those in exec
1577 mode, or empty otherwise.
1578
1579 =item B<#lastaddr>
1580
1581 The address of the OP's last child, in hexadecimal.
1582
1583 =item B<#name>
1584
1585 The OP's name.
1586
1587 =item B<#NAME>
1588
1589 The OP's name, in all caps.
1590
1591 =item B<#next>
1592
1593 The sequence number of the OP's next OP.
1594
1595 =item B<#nextaddr>
1596
1597 The address of the OP's next OP, in hexadecimal.
1598
1599 =item B<#noise>
1600
1601 A one- or two-character abbreviation for the OP's name.
1602
1603 =item B<#private>
1604
1605 The OP's private flags, rendered with abbreviated names if possible.
1606
1607 =item B<#privval>
1608
1609 The numeric value of the OP's private flags.
1610
1611 =item B<#seq>
1612
1613 The sequence number of the OP. Note that this is a sequence number
1614 generated by B::Concise.
1615
1616 =item B<#seqnum>
1617
1618 5.8.x and earlier only. 5.9 and later do not provide this.
1619
1620 The real sequence number of the OP, as a regular number and not adjusted
1621 to be relative to the start of the real program. (This will generally be
1622 a fairly large number because all of B<B::Concise> is compiled before
1623 your program is).
1624
1625 =item B<#opt>
1626
1627 Whether or not the op has been optimised by the peephole optimiser.
1628
1629 Only available in 5.9 and later.
1630
1631 =item B<#sibaddr>
1632
1633 The address of the OP's next youngest sibling, in hexadecimal.
1634
1635 =item B<#svaddr>
1636
1637 The address of the OP's SV, if it has an SV, in hexadecimal.
1638
1639 =item B<#svclass>
1640
1641 The class of the OP's SV, if it has one, in all caps (e.g., 'IV').
1642
1643 =item B<#svval>
1644
1645 The value of the OP's SV, if it has one, in a short human-readable format.
1646
1647 =item B<#targ>
1648
1649 The numeric value of the OP's targ.
1650
1651 =item B<#targarg>
1652
1653 The name of the variable the OP's targ refers to, if any, otherwise the
1654 letter t followed by the OP's targ in decimal.
1655
1656 =item B<#targarglife>
1657
1658 Same as B<#targarg>, but followed by the COP sequence numbers that delimit
1659 the variable's lifetime (or 'end' for a variable in an open scope) for a
1660 variable.
1661
1662 =item B<#typenum>
1663
1664 The numeric value of the OP's type, in decimal.
1665
1666 =back
1667
1668 =head1 One-Liner Command tips
1669
1670 =over 4
1671
1672 =item perl -MO=Concise,bar foo.pl
1673
1674 Renders only bar() from foo.pl.  To see main, drop the ',bar'.  To see
1675 both, add ',-main'
1676
1677 =item perl -MDigest::MD5=md5 -MO=Concise,md5 -e1
1678
1679 Identifies md5 as an XS function.  The export is needed so that BC can
1680 find it in main.
1681
1682 =item perl -MPOSIX -MO=Concise,_POSIX_ARG_MAX -e1
1683
1684 Identifies _POSIX_ARG_MAX as a constant sub, optimized to an IV.
1685 Although POSIX isn't entirely consistent across platforms, this is
1686 likely to be present in virtually all of them.
1687
1688 =item perl -MPOSIX -MO=Concise,a -e 'print _POSIX_SAVED_IDS'
1689
1690 This renders a print statement, which includes a call to the function.
1691 It's identical to rendering a file with a use call and that single
1692 statement, except for the filename which appears in the nextstate ops.
1693
1694 =item perl -MPOSIX -MO=Concise,a -e 'sub a{_POSIX_SAVED_IDS}'
1695
1696 This is B<very> similar to previous, only the first two ops differ.  This
1697 subroutine rendering is more representative, insofar as a single main
1698 program will have many subs.
1699
1700 =item perl -MB::Concise -e 'B::Concise::compile("-exec","-src", \%B::Concise::)->()'
1701
1702 This renders all functions in the B::Concise package with the source
1703 lines.  It eschews the O framework so that the stashref can be passed
1704 directly to B::Concise::compile().  See -stash option for a more
1705 convenient way to render a package.
1706
1707 =back
1708
1709 =head1 Using B::Concise outside of the O framework
1710
1711 The common (and original) usage of B::Concise was for command-line
1712 renderings of simple code, as given in EXAMPLE.  But you can also use
1713 B<B::Concise> from your code, and call compile() directly, and
1714 repeatedly.  By doing so, you can avoid the compile-time only
1715 operation of O.pm, and even use the debugger to step through
1716 B::Concise::compile() itself.
1717
1718 Once you're doing this, you may alter Concise output by adding new
1719 rendering styles, and by optionally adding callback routines which
1720 populate new variables, if such were referenced from those (just
1721 added) styles.  
1722
1723 =head2 Example: Altering Concise Renderings
1724
1725     use B::Concise qw(set_style add_callback);
1726     add_style($yourStyleName => $defaultfmt, $gotofmt, $treefmt);
1727     add_callback
1728       ( sub {
1729             my ($h, $op, $format, $level, $stylename) = @_;
1730             $h->{variable} = some_func($op);
1731         });
1732     $walker = B::Concise::compile(@options,@subnames,@subrefs);
1733     $walker->();
1734
1735 =head2 set_style()
1736
1737 B<set_style> accepts 3 arguments, and updates the three format-specs
1738 comprising a line-style (basic-exec, goto, tree).  It has one minor
1739 drawback though; it doesn't register the style under a new name.  This
1740 can become an issue if you render more than once and switch styles.
1741 Thus you may prefer to use add_style() and/or set_style_standard()
1742 instead.
1743
1744 =head2 set_style_standard($name)
1745
1746 This restores one of the standard line-styles: C<terse>, C<concise>,
1747 C<linenoise>, C<debug>, C<env>, into effect.  It also accepts style
1748 names previously defined with add_style().
1749
1750 =head2 add_style ()
1751
1752 This subroutine accepts a new style name and three style arguments as
1753 above, and creates, registers, and selects the newly named style.  It is
1754 an error to re-add a style; call set_style_standard() to switch between
1755 several styles.
1756
1757 =head2 add_callback ()
1758
1759 If your newly minted styles refer to any new #variables, you'll need
1760 to define a callback subroutine that will populate (or modify) those
1761 variables.  They are then available for use in the style you've
1762 chosen.
1763
1764 The callbacks are called for each opcode visited by Concise, in the
1765 same order as they are added.  Each subroutine is passed five
1766 parameters.
1767
1768   1. A hashref, containing the variable names and values which are
1769      populated into the report-line for the op
1770   2. the op, as a B<B::OP> object
1771   3. a reference to the format string
1772   4. the formatting (indent) level
1773   5. the selected stylename
1774
1775 To define your own variables, simply add them to the hash, or change
1776 existing values if you need to.  The level and format are passed in as
1777 references to scalars, but it is unlikely that they will need to be
1778 changed or even used.
1779
1780 =head2 Running B::Concise::compile()
1781
1782 B<compile> accepts options as described above in L</OPTIONS>, and
1783 arguments, which are either coderefs, or subroutine names.
1784
1785 It constructs and returns a $treewalker coderef, which when invoked,
1786 traverses, or walks, and renders the optrees of the given arguments to
1787 STDOUT.  You can reuse this, and can change the rendering style used
1788 each time; thereafter the coderef renders in the new style.
1789
1790 B<walk_output> lets you change the print destination from STDOUT to
1791 another open filehandle, or into a string passed as a ref (unless
1792 you've built perl with -Uuseperlio).
1793
1794     my $walker = B::Concise::compile('-terse','aFuncName', \&aSubRef);  # 1
1795     walk_output(\my $buf);
1796     $walker->();                        # 1 renders -terse
1797     set_style_standard('concise');      # 2
1798     $walker->();                        # 2 renders -concise
1799     $walker->(@new);                    # 3 renders whatever
1800     print "3 different renderings: terse, concise, and @new: $buf\n";
1801
1802 When $walker is called, it traverses the subroutines supplied when it
1803 was created, and renders them using the current style.  You can change
1804 the style afterwards in several different ways:
1805
1806   1. call C<compile>, altering style or mode/order
1807   2. call C<set_style_standard>
1808   3. call $walker, passing @new options
1809
1810 Passing new options to the $walker is the easiest way to change
1811 amongst any pre-defined styles (the ones you add are automatically
1812 recognized as options), and is the only way to alter rendering order
1813 without calling compile again.  Note however that rendering state is
1814 still shared amongst multiple $walker objects, so they must still be
1815 used in a coordinated manner.
1816
1817 =head2 B::Concise::reset_sequence()
1818
1819 This function (not exported) lets you reset the sequence numbers (note
1820 that they're numbered arbitrarily, their goal being to be human
1821 readable).  Its purpose is mostly to support testing, i.e. to compare
1822 the concise output from two identical anonymous subroutines (but
1823 different instances).  Without the reset, B::Concise, seeing that
1824 they're separate optrees, generates different sequence numbers in
1825 the output.
1826
1827 =head2 Errors
1828
1829 Errors in rendering (non-existent function-name, non-existent coderef)
1830 are written to the STDOUT, or wherever you've set it via
1831 walk_output().
1832
1833 Errors using the various *style* calls, and bad args to walk_output(),
1834 result in die().  Use an eval if you wish to catch these errors and
1835 continue processing.
1836
1837 =head1 AUTHOR
1838
1839 Stephen McCamant, E<lt>smcc@CSUA.Berkeley.EDUE<gt>.
1840
1841 =cut