This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
3257a47ace9ac4d84daabfaac781c04099ef9a73
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25
26 require 5.010_001;
27 use strict;
28 use warnings;
29 use Carp;
30 use Config;
31 use File::Find;
32 use File::Path;
33 use File::Spec;
34 use Text::Tabs;
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 ##########################################################################
40 #
41 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
42 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
43 # a pod file and a .t file
44 #
45 # The structure of this file is:
46 #   First these introductory comments; then
47 #   code needed for everywhere, such as debugging stuff; then
48 #   code to handle input parameters; then
49 #   data structures likely to be of external interest (some of which depend on
50 #       the input parameters, so follows them; then
51 #   more data structures and subroutine and package (class) definitions; then
52 #   the small actual loop to process the input files and finish up; then
53 #   a __DATA__ section, for the .t tests
54 #
55 # This program works on all releases of Unicode through at least 6.0.  The
56 # outputs have been scrutinized most intently for release 5.1.  The others
57 # have been checked for somewhat more than just sanity.  It can handle all
58 # existing Unicode character properties in those releases.
59 #
60 # This program is mostly about Unicode character (or code point) properties.
61 # A property describes some attribute or quality of a code point, like if it
62 # is lowercase or not, its name, what version of Unicode it was first defined
63 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
64 # possibilities by making all properties into mappings from each code point
65 # into some corresponding value.  In the case of it being lowercase or not,
66 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
67 # property maps each Unicode code point to a single value, called a "property
68 # value".  (Hence each Unicode property is a true mathematical function with
69 # exactly one value per code point.)
70 #
71 # When using a property in a regular expression, what is desired isn't the
72 # mapping of the code point to its property's value, but the reverse (or the
73 # mathematical "inverse relation"): starting with the property value, "Does a
74 # code point map to it?"  These are written in a "compound" form:
75 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
76 # files containing the lists of code points that map to each such regular
77 # expression property value, one file per list
78 #
79 # There is also a single form shortcut that Perl adds for many of the commonly
80 # used properties.  This happens for all binary properties, plus script,
81 # general_category, and block properties.
82 #
83 # Thus the outputs of this program are files.  There are map files, mostly in
84 # the 'To' directory; and there are list files for use in regular expression
85 # matching, all in subdirectories of the 'lib' directory, with each
86 # subdirectory being named for the property that the lists in it are for.
87 # Bookkeeping, test, and documentation files are also generated.
88
89 my $matches_directory = 'lib';   # Where match (\p{}) files go.
90 my $map_directory = 'To';        # Where map files go.
91
92 # DATA STRUCTURES
93 #
94 # The major data structures of this program are Property, of course, but also
95 # Table.  There are two kinds of tables, very similar to each other.
96 # "Match_Table" is the data structure giving the list of code points that have
97 # a particular property value, mentioned above.  There is also a "Map_Table"
98 # data structure which gives the property's mapping from code point to value.
99 # There are two structures because the match tables need to be combined in
100 # various ways, such as constructing unions, intersections, complements, etc.,
101 # and the map ones don't.  And there would be problems, perhaps subtle, if
102 # a map table were inadvertently operated on in some of those ways.
103 # The use of separate classes with operations defined on one but not the other
104 # prevents accidentally confusing the two.
105 #
106 # At the heart of each table's data structure is a "Range_List", which is just
107 # an ordered list of "Ranges", plus ancillary information, and methods to
108 # operate on them.  A Range is a compact way to store property information.
109 # Each range has a starting code point, an ending code point, and a value that
110 # is meant to apply to all the code points between the two end points,
111 # inclusive.  For a map table, this value is the property value for those
112 # code points.  Two such ranges could be written like this:
113 #   0x41 .. 0x5A, 'Upper',
114 #   0x61 .. 0x7A, 'Lower'
115 #
116 # Each range also has a type used as a convenience to classify the values.
117 # Most ranges in this program will be Type 0, or normal, but there are some
118 # ranges that have a non-zero type.  These are used only in map tables, and
119 # are for mappings that don't fit into the normal scheme of things.  Mappings
120 # that require a hash entry to communicate with utf8.c are one example;
121 # another example is mappings for charnames.pm to use which indicate a name
122 # that is algorithmically determinable from its code point (and vice-versa).
123 # These are used to significantly compact these tables, instead of listing
124 # each one of the tens of thousands individually.
125 #
126 # In a match table, the value of a range is irrelevant (and hence the type as
127 # well, which will always be 0), and arbitrarily set to the null string.
128 # Using the example above, there would be two match tables for those two
129 # entries, one named Upper would contain the 0x41..0x5A range, and the other
130 # named Lower would contain 0x61..0x7A.
131 #
132 # Actually, there are two types of range lists, "Range_Map" is the one
133 # associated with map tables, and "Range_List" with match tables.
134 # Again, this is so that methods can be defined on one and not the other so as
135 # to prevent operating on them in incorrect ways.
136 #
137 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
138 # in the perl core.  All tables could in theory be written, but some are
139 # suppressed because there is no current practical use for them.  It is easy
140 # to change which get written by changing various lists that are near the top
141 # of the actual code in this file.  The table data structures contain enough
142 # ancillary information to allow them to be treated as separate entities for
143 # writing, such as the path to each one's file.  There is a heading in each
144 # map table that gives the format of its entries, and what the map is for all
145 # the code points missing from it.  (This allows tables to be more compact.)
146 #
147 # The Property data structure contains one or more tables.  All properties
148 # contain a map table (except the $perl property which is a
149 # pseudo-property containing only match tables), and any properties that
150 # are usable in regular expression matches also contain various matching
151 # tables, one for each value the property can have.  A binary property can
152 # have two values, True and False (or Y and N, which are preferred by Unicode
153 # terminology).  Thus each of these properties will have a map table that
154 # takes every code point and maps it to Y or N (but having ranges cuts the
155 # number of entries in that table way down), and two match tables, one
156 # which has a list of all the code points that map to Y, and one for all the
157 # code points that map to N.  (For each of these, a third table is also
158 # generated for the pseudo Perl property.  It contains the identical code
159 # points as the Y table, but can be written, not in the compound form, but in
160 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
161 # properties have several possible values, some have many, and properties like
162 # Name have a different value for every named code point.  Those will not,
163 # unless the controlling lists are changed, have their match tables written
164 # out.  But all the ones which can be used in regular expression \p{} and \P{}
165 # constructs will.  Generally a property will have either its map table or its
166 # match tables written but not both.  Again, what gets written is controlled
167 # by lists which can easily be changed.  Properties have a 'Type', like
168 # binary, or string, or enum depending on how many match tables there are and
169 # the content of the maps.  This 'Type' is different than a range 'Type', so
170 # don't get confused by the two concepts having the same name.
171 #
172 # For information about the Unicode properties, see Unicode's UAX44 document:
173
174 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
175
176 # As stated earlier, this program will work on any release of Unicode so far.
177 # Most obvious problems in earlier data have NOT been corrected except when
178 # necessary to make Perl or this program work reasonably.  For example, no
179 # folding information was given in early releases, so this program uses the
180 # substitute of lower case, just so that a regular expression with the /i
181 # option will do something that actually gives the right results in many
182 # cases.  There are also a couple other corrections for version 1.1.5,
183 # commented at the point they are made.  As an example of corrections that
184 # weren't made (but could be) is this statement from DerivedAge.txt: "The
185 # supplementary private use code points and the non-character code points were
186 # assigned in version 2.0, but not specifically listed in the UCD until
187 # versions 3.0 and 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0)
188 # More information on Unicode version glitches is further down in these
189 # introductory comments.
190 #
191 # This program works on all non-provisional properties as of 6.0, though the
192 # files for some are suppressed from apparent lack of demand for them.  You
193 # can change which are output by changing lists in this program.
194 #
195 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
196 # loose matchings rules (from Unicode TR18):
197 #
198 #    The recommended names for UCD properties and property values are in
199 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
200 #    [PropValue]. There are both abbreviated names and longer, more
201 #    descriptive names. It is strongly recommended that both names be
202 #    recognized, and that loose matching of property names be used,
203 #    whereby the case distinctions, whitespace, hyphens, and underbar
204 #    are ignored.
205 # The program still allows Fuzzy to override its determination of if loose
206 # matching should be used, but it isn't currently used, as it is no longer
207 # needed; the calculations it makes are good enough.
208 #
209 # SUMMARY OF HOW IT WORKS:
210 #
211 #   Process arguments
212 #
213 #   A list is constructed containing each input file that is to be processed
214 #
215 #   Each file on the list is processed in a loop, using the associated handler
216 #   code for each:
217 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
218 #            first.  These files name the properties and property values.
219 #            Objects are created of all the property and property value names
220 #            that the rest of the input should expect, including all synonyms.
221 #        The other input files give mappings from properties to property
222 #           values.  That is, they list code points and say what the mapping
223 #           is under the given property.  Some files give the mappings for
224 #           just one property; and some for many.  This program goes through
225 #           each file and populates the properties from them.  Some properties
226 #           are listed in more than one file, and Unicode has set up a
227 #           precedence as to which has priority if there is a conflict.  Thus
228 #           the order of processing matters, and this program handles the
229 #           conflict possibility by processing the overriding input files
230 #           last, so that if necessary they replace earlier values.
231 #        After this is all done, the program creates the property mappings not
232 #            furnished by Unicode, but derivable from what it does give.
233 #        The tables of code points that match each property value in each
234 #            property that is accessible by regular expressions are created.
235 #        The Perl-defined properties are created and populated.  Many of these
236 #            require data determined from the earlier steps
237 #        Any Perl-defined synonyms are created, and name clashes between Perl
238 #            and Unicode are reconciled and warned about.
239 #        All the properties are written to files
240 #        Any other files are written, and final warnings issued.
241 #
242 # For clarity, a number of operators have been overloaded to work on tables:
243 #   ~ means invert (take all characters not in the set).  The more
244 #       conventional '!' is not used because of the possibility of confusing
245 #       it with the actual boolean operation.
246 #   + means union
247 #   - means subtraction
248 #   & means intersection
249 # The precedence of these is the order listed.  Parentheses should be
250 # copiously used.  These are not a general scheme.  The operations aren't
251 # defined for a number of things, deliberately, to avoid getting into trouble.
252 # Operations are done on references and affect the underlying structures, so
253 # that the copy constructors for them have been overloaded to not return a new
254 # clone, but the input object itself.
255 #
256 # The bool operator is deliberately not overloaded to avoid confusion with
257 # "should it mean if the object merely exists, or also is non-empty?".
258 #
259 # WHY CERTAIN DESIGN DECISIONS WERE MADE
260 #
261 # This program needs to be able to run under miniperl.  Therefore, it uses a
262 # minimum of other modules, and hence implements some things itself that could
263 # be gotten from CPAN
264 #
265 # This program uses inputs published by the Unicode Consortium.  These can
266 # change incompatibly between releases without the Perl maintainers realizing
267 # it.  Therefore this program is now designed to try to flag these.  It looks
268 # at the directories where the inputs are, and flags any unrecognized files.
269 # It keeps track of all the properties in the files it handles, and flags any
270 # that it doesn't know how to handle.  It also flags any input lines that
271 # don't match the expected syntax, among other checks.
272 #
273 # It is also designed so if a new input file matches one of the known
274 # templates, one hopefully just needs to add it to a list to have it
275 # processed.
276 #
277 # As mentioned earlier, some properties are given in more than one file.  In
278 # particular, the files in the extracted directory are supposedly just
279 # reformattings of the others.  But they contain information not easily
280 # derivable from the other files, including results for Unihan, which this
281 # program doesn't ordinarily look at, and for unassigned code points.  They
282 # also have historically had errors or been incomplete.  In an attempt to
283 # create the best possible data, this program thus processes them first to
284 # glean information missing from the other files; then processes those other
285 # files to override any errors in the extracted ones.  Much of the design was
286 # driven by this need to store things and then possibly override them.
287 #
288 # It tries to keep fatal errors to a minimum, to generate something usable for
289 # testing purposes.  It always looks for files that could be inputs, and will
290 # warn about any that it doesn't know how to handle (the -q option suppresses
291 # the warning).
292 #
293 # Why have files written out for binary 'N' matches?
294 #   For binary properties, if you know the mapping for either Y or N; the
295 #   other is trivial to construct, so could be done at Perl run-time by just
296 #   complementing the result, instead of having a file for it.  That is, if
297 #   someone types in \p{foo: N}, Perl could translate that to \P{foo: Y} and
298 #   not need a file.   The problem is communicating to Perl that a given
299 #   property is binary.  Perl can't figure it out from looking at the N (or
300 #   No), as some non-binary properties have these as property values.  So
301 #   rather than inventing a way to communicate this info back to the core,
302 #   which would have required changes there as well, it was simpler just to
303 #   add the extra tables.
304 #
305 # Why is there more than one type of range?
306 #   This simplified things.  There are some very specialized code points that
307 #   have to be handled specially for output, such as Hangul syllable names.
308 #   By creating a range type (done late in the development process), it
309 #   allowed this to be stored with the range, and overridden by other input.
310 #   Originally these were stored in another data structure, and it became a
311 #   mess trying to decide if a second file that was for the same property was
312 #   overriding the earlier one or not.
313 #
314 # Why are there two kinds of tables, match and map?
315 #   (And there is a base class shared by the two as well.)  As stated above,
316 #   they actually are for different things.  Development proceeded much more
317 #   smoothly when I (khw) realized the distinction.  Map tables are used to
318 #   give the property value for every code point (actually every code point
319 #   that doesn't map to a default value).  Match tables are used for regular
320 #   expression matches, and are essentially the inverse mapping.  Separating
321 #   the two allows more specialized methods, and error checks so that one
322 #   can't just take the intersection of two map tables, for example, as that
323 #   is nonsensical.
324 #
325 # There are no match tables generated for matches of the null string.  These
326 # would look like qr/\p{JSN=}/ currently without modifying the regex code.
327 # Perhaps something like them could be added if necessary.  The JSN does have
328 # a real code point U+110B that maps to the null string, but it is a
329 # contributory property, and therefore not output by default.  And it's easily
330 # handled so far by making the null string the default where it is a
331 # possibility.
332 #
333 # DEBUGGING
334 #
335 # This program is written so it will run under miniperl.  Occasionally changes
336 # will cause an error where the backtrace doesn't work well under miniperl.
337 # To diagnose the problem, you can instead run it under regular perl, if you
338 # have one compiled.
339 #
340 # There is a good trace facility.  To enable it, first sub DEBUG must be set
341 # to return true.  Then a line like
342 #
343 # local $to_trace = 1 if main::DEBUG;
344 #
345 # can be added to enable tracing in its lexical scope or until you insert
346 # another line:
347 #
348 # local $to_trace = 0 if main::DEBUG;
349 #
350 # then use a line like "trace $a, @b, %c, ...;
351 #
352 # Some of the more complex subroutines already have trace statements in them.
353 # Permanent trace statements should be like:
354 #
355 # trace ... if main::DEBUG && $to_trace;
356 #
357 # If there is just one or a few files that you're debugging, you can easily
358 # cause most everything else to be skipped.  Change the line
359 #
360 # my $debug_skip = 0;
361 #
362 # to 1, and every file whose object is in @input_file_objects and doesn't have
363 # a, 'non_skip => 1,' in its constructor will be skipped.
364 #
365 # To compare the output tables, it may be useful to specify the -annotate
366 # flag.  This causes the tables to expand so there is one entry for each
367 # non-algorithmically named code point giving, currently its name, and its
368 # graphic representation if printable (and you have a font that knows about
369 # it).  This makes it easier to see what the particular code points are in
370 # each output table.  The tables are usable, but because they don't have
371 # ranges (for the most part), a Perl using them will run slower.  Non-named
372 # code points are annotated with a description of their status, and contiguous
373 # ones with the same description will be output as a range rather than
374 # individually.  Algorithmically named characters are also output as ranges,
375 # except when there are just a few contiguous ones.
376 #
377 # FUTURE ISSUES
378 #
379 # The program would break if Unicode were to change its names so that
380 # interior white space, underscores, or dashes differences were significant
381 # within property and property value names.
382 #
383 # It might be easier to use the xml versions of the UCD if this program ever
384 # would need heavy revision, and the ability to handle old versions was not
385 # required.
386 #
387 # There is the potential for name collisions, in that Perl has chosen names
388 # that Unicode could decide it also likes.  There have been such collisions in
389 # the past, with mostly Perl deciding to adopt the Unicode definition of the
390 # name.  However in the 5.2 Unicode beta testing, there were a number of such
391 # collisions, which were withdrawn before the final release, because of Perl's
392 # and other's protests.  These all involved new properties which began with
393 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
394 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
395 # Unicode document, so they are unlikely to be used by Unicode for another
396 # purpose.  However, they might try something beginning with 'In', or use any
397 # of the other Perl-defined properties.  This program will warn you of name
398 # collisions, and refuse to generate tables with them, but manual intervention
399 # will be required in this event.  One scheme that could be implemented, if
400 # necessary, would be to have this program generate another file, or add a
401 # field to mktables.lst that gives the date of first definition of a property.
402 # Each new release of Unicode would use that file as a basis for the next
403 # iteration.  And the Perl synonym addition code could sort based on the age
404 # of the property, so older properties get priority, and newer ones that clash
405 # would be refused; hence existing code would not be impacted, and some other
406 # synonym would have to be used for the new property.  This is ugly, and
407 # manual intervention would certainly be easier to do in the short run; lets
408 # hope it never comes to this.
409 #
410 # A NOTE ON UNIHAN
411 #
412 # This program can generate tables from the Unihan database.  But it doesn't
413 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
414 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
415 # database was split into 8 different files, all beginning with the letters
416 # 'Unihan'.  This program will read those file(s) if present, but it needs to
417 # know which of the many properties in the file(s) should have tables created
418 # for them.  It will create tables for any properties listed in
419 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
420 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
421 # property you want is not in those files of the release you are building
422 # against, you must add it to those two arrays.  Starting in 4.0, the
423 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
424 # is present in the directory, a table will be generated for that property.
425 # In 5.2, several more properties were added.  For your convenience, the two
426 # arrays are initialized with all the 6.0 listed properties that are also in
427 # earlier releases.  But these are commented out.  You can just uncomment the
428 # ones you want, or use them as a template for adding entries for other
429 # properties.
430 #
431 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
432 # and filter_unihan_line() are the functions where this is done.  This program
433 # already does some adjusting to make the lines look more like the rest of the
434 # Unicode DB;  You can see what that is in filter_unihan_line()
435 #
436 # There is a bug in the 3.2 data file in which some values for the
437 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
438 # could be added for these; or for a particular installation, the Unihan.txt
439 # file could be edited to fix them.
440 #
441 # HOW TO ADD A FILE TO BE PROCESSED
442 #
443 # A new file from Unicode needs to have an object constructed for it in
444 # @input_file_objects, probably at the end or at the end of the extracted
445 # ones.  The program should warn you if its name will clash with others on
446 # restrictive file systems, like DOS.  If so, figure out a better name, and
447 # add lines to the README.perl file giving that.  If the file is a character
448 # property, it should be in the format that Unicode has by default
449 # standardized for such files for the more recently introduced ones.
450 # If so, the Input_file constructor for @input_file_objects can just be the
451 # file name and release it first appeared in.  If not, then it should be
452 # possible to construct an each_line_handler() to massage the line into the
453 # standardized form.
454 #
455 # For non-character properties, more code will be needed.  You can look at
456 # the existing entries for clues.
457 #
458 # UNICODE VERSIONS NOTES
459 #
460 # The Unicode UCD has had a number of errors in it over the versions.  And
461 # these remain, by policy, in the standard for that version.  Therefore it is
462 # risky to correct them, because code may be expecting the error.  So this
463 # program doesn't generally make changes, unless the error breaks the Perl
464 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
465 # for U+1105, which causes real problems for the algorithms for Jamo
466 # calculations, so it is changed here.
467 #
468 # But it isn't so clear cut as to what to do about concepts that are
469 # introduced in a later release; should they extend back to earlier releases
470 # where the concept just didn't exist?  It was easier to do this than to not,
471 # so that's what was done.  For example, the default value for code points not
472 # in the files for various properties was probably undefined until changed by
473 # some version.  No_Block for blocks is such an example.  This program will
474 # assign No_Block even in Unicode versions that didn't have it.  This has the
475 # benefit that code being written doesn't have to special case earlier
476 # versions; and the detriment that it doesn't match the Standard precisely for
477 # the affected versions.
478 #
479 # Here are some observations about some of the issues in early versions:
480 #
481 # The number of code points in \p{alpha} halved in 2.1.9.  It turns out that
482 # the reason is that the CJK block starting at 4E00 was removed from PropList,
483 # and was not put back in until 3.1.0
484 #
485 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
486 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
487 # reason is that 3.2 introduced U+205F=medium math space, which was not
488 # classed as white space, but Perl figured out that it should have been. 4.0
489 # reclassified it correctly.
490 #
491 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
492 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
493 # was left with no code points, as all the ones that mapped to 202 stayed
494 # mapped to 202.  Thus if your program used the numeric name for the class,
495 # it would not have been affected, but if it used the mnemonic, it would have
496 # been.
497 #
498 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
499 # points which eventually came to have this script property value, instead
500 # mapped to "Unknown".  But in the next release all these code points were
501 # moved to \p{sc=common} instead.
502 #
503 # The default for missing code points for BidiClass is complicated.  Starting
504 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
505 # tries to do the best it can for earlier releases.  It is done in
506 # process_PropertyAliases()
507 #
508 ##############################################################################
509
510 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
511                         # and errors
512 my $MAX_LINE_WIDTH = 78;
513
514 # Debugging aid to skip most files so as to not be distracted by them when
515 # concentrating on the ones being debugged.  Add
516 # non_skip => 1,
517 # to the constructor for those files you want processed when you set this.
518 # Files with a first version number of 0 are special: they are always
519 # processed regardless of the state of this flag.
520 my $debug_skip = 0;
521
522 # Set to 1 to enable tracing.
523 our $to_trace = 0;
524
525 { # Closure for trace: debugging aid
526     my $print_caller = 1;        # ? Include calling subroutine name
527     my $main_with_colon = 'main::';
528     my $main_colon_length = length($main_with_colon);
529
530     sub trace {
531         return unless $to_trace;        # Do nothing if global flag not set
532
533         my @input = @_;
534
535         local $DB::trace = 0;
536         $DB::trace = 0;          # Quiet 'used only once' message
537
538         my $line_number;
539
540         # Loop looking up the stack to get the first non-trace caller
541         my $caller_line;
542         my $caller_name;
543         my $i = 0;
544         do {
545             $line_number = $caller_line;
546             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
547             $caller = $main_with_colon unless defined $caller;
548
549             $caller_name = $caller;
550
551             # get rid of pkg
552             $caller_name =~ s/.*:://;
553             if (substr($caller_name, 0, $main_colon_length)
554                 eq $main_with_colon)
555             {
556                 $caller_name = substr($caller_name, $main_colon_length);
557             }
558
559         } until ($caller_name ne 'trace');
560
561         # If the stack was empty, we were called from the top level
562         $caller_name = 'main' if ($caller_name eq ""
563                                     || $caller_name eq 'trace');
564
565         my $output = "";
566         foreach my $string (@input) {
567             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
568             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
569                 $output .= simple_dumper($string);
570             }
571             else {
572                 $string = "$string" if ref $string;
573                 $string = $UNDEF unless defined $string;
574                 chomp $string;
575                 $string = '""' if $string eq "";
576                 $output .= " " if $output ne ""
577                                 && $string ne ""
578                                 && substr($output, -1, 1) ne " "
579                                 && substr($string, 0, 1) ne " ";
580                 $output .= $string;
581             }
582         }
583
584         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
585         print STDERR "$caller_name: " if $print_caller;
586         print STDERR $output, "\n";
587         return;
588     }
589 }
590
591 # This is for a rarely used development feature that allows you to compare two
592 # versions of the Unicode standard without having to deal with changes caused
593 # by the code points introduced in the later version.  Change the 0 to a SINGLE
594 # dotted Unicode release number (e.g. 2.1).  Only code points introduced in
595 # that release and earlier will be used; later ones are thrown away.  You use
596 # the version number of the earliest one you want to compare; then run this
597 # program on directory structures containing each release, and compare the
598 # outputs.  These outputs will therefore include only the code points common
599 # to both releases, and you can see the changes caused just by the underlying
600 # release semantic changes.  For versions earlier than 3.2, you must copy a
601 # version of DAge.txt into the directory.
602 my $string_compare_versions = DEBUG && 0; #  e.g., v2.1;
603 my $compare_versions = DEBUG
604                        && $string_compare_versions
605                        && pack "C*", split /\./, $string_compare_versions;
606
607 sub uniques {
608     # Returns non-duplicated input values.  From "Perl Best Practices:
609     # Encapsulated Cleverness".  p. 455 in first edition.
610
611     my %seen;
612     # Arguably this breaks encapsulation, if the goal is to permit multiple
613     # distinct objects to stringify to the same value, and be interchangeable.
614     # However, for this program, no two objects stringify identically, and all
615     # lists passed to this function are either objects or strings. So this
616     # doesn't affect correctness, but it does give a couple of percent speedup.
617     no overloading;
618     return grep { ! $seen{$_}++ } @_;
619 }
620
621 $0 = File::Spec->canonpath($0);
622
623 my $make_test_script = 0;      # ? Should we output a test script
624 my $write_unchanged_files = 0; # ? Should we update the output files even if
625                                #    we don't think they have changed
626 my $use_directory = "";        # ? Should we chdir somewhere.
627 my $pod_directory;             # input directory to store the pod file.
628 my $pod_file = 'perluniprops';
629 my $t_path;                     # Path to the .t test file
630 my $file_list = 'mktables.lst'; # File to store input and output file names.
631                                # This is used to speed up the build, by not
632                                # executing the main body of the program if
633                                # nothing on the list has changed since the
634                                # previous build
635 my $make_list = 1;             # ? Should we write $file_list.  Set to always
636                                # make a list so that when the pumpking is
637                                # preparing a release, s/he won't have to do
638                                # special things
639 my $glob_list = 0;             # ? Should we try to include unknown .txt files
640                                # in the input.
641 my $output_range_counts = $debugging_build;   # ? Should we include the number
642                                               # of code points in ranges in
643                                               # the output
644 my $annotate = 0;              # ? Should character names be in the output
645
646 # Verbosity levels; 0 is quiet
647 my $NORMAL_VERBOSITY = 1;
648 my $PROGRESS = 2;
649 my $VERBOSE = 3;
650
651 my $verbosity = $NORMAL_VERBOSITY;
652
653 # Process arguments
654 while (@ARGV) {
655     my $arg = shift @ARGV;
656     if ($arg eq '-v') {
657         $verbosity = $VERBOSE;
658     }
659     elsif ($arg eq '-p') {
660         $verbosity = $PROGRESS;
661         $| = 1;     # Flush buffers as we go.
662     }
663     elsif ($arg eq '-q') {
664         $verbosity = 0;
665     }
666     elsif ($arg eq '-w') {
667         $write_unchanged_files = 1; # update the files even if havent changed
668     }
669     elsif ($arg eq '-check') {
670         my $this = shift @ARGV;
671         my $ok = shift @ARGV;
672         if ($this ne $ok) {
673             print "Skipping as check params are not the same.\n";
674             exit(0);
675         }
676     }
677     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
678         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
679     }
680     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
681     {
682         $make_test_script = 1;
683     }
684     elsif ($arg eq '-makelist') {
685         $make_list = 1;
686     }
687     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
688         -d $use_directory or croak "Unknown directory '$use_directory'";
689     }
690     elsif ($arg eq '-L') {
691
692         # Existence not tested until have chdir'd
693         $file_list = shift;
694     }
695     elsif ($arg eq '-globlist') {
696         $glob_list = 1;
697     }
698     elsif ($arg eq '-c') {
699         $output_range_counts = ! $output_range_counts
700     }
701     elsif ($arg eq '-annotate') {
702         $annotate = 1;
703         $debugging_build = 1;
704         $output_range_counts = 1;
705     }
706     else {
707         my $with_c = 'with';
708         $with_c .= 'out' if $output_range_counts;   # Complements the state
709         croak <<END;
710 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
711           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
712           [-check A B ]
713   -c          : Output comments $with_c number of code points in ranges
714   -q          : Quiet Mode: Only output serious warnings.
715   -p          : Set verbosity level to normal plus show progress.
716   -v          : Set Verbosity level high:  Show progress and non-serious
717                 warnings
718   -w          : Write files regardless
719   -C dir      : Change to this directory before proceeding. All relative paths
720                 except those specified by the -P and -T options will be done
721                 with respect to this directory.
722   -P dir      : Output $pod_file file to directory 'dir'.
723   -T path     : Create a test script as 'path'; overrides -maketest
724   -L filelist : Use alternate 'filelist' instead of standard one
725   -globlist   : Take as input all non-Test *.txt files in current and sub
726                 directories
727   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
728                 overrides -T
729   -makelist   : Rewrite the file list $file_list based on current setup
730   -annotate   : Output an annotation for each character in the table files;
731                 useful for debugging mktables, looking at diffs; but is slow,
732                 memory intensive; resulting tables are usable but slow and
733                 very large.
734   -check A B  : Executes $0 only if A and B are the same
735 END
736     }
737 }
738
739 # Stores the most-recently changed file.  If none have changed, can skip the
740 # build
741 my $most_recent = (stat $0)[9];   # Do this before the chdir!
742
743 # Change directories now, because need to read 'version' early.
744 if ($use_directory) {
745     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
746         $pod_directory = File::Spec->rel2abs($pod_directory);
747     }
748     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
749         $t_path = File::Spec->rel2abs($t_path);
750     }
751     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
752     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
753         $pod_directory = File::Spec->abs2rel($pod_directory);
754     }
755     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
756         $t_path = File::Spec->abs2rel($t_path);
757     }
758 }
759
760 # Get Unicode version into regular and v-string.  This is done now because
761 # various tables below get populated based on it.  These tables are populated
762 # here to be near the top of the file, and so easily seeable by those needing
763 # to modify things.
764 open my $VERSION, "<", "version"
765                     or croak "$0: can't open required file 'version': $!\n";
766 my $string_version = <$VERSION>;
767 close $VERSION;
768 chomp $string_version;
769 my $v_version = pack "C*", split /\./, $string_version;        # v string
770
771 # The following are the complete names of properties with property values that
772 # are known to not match any code points in some versions of Unicode, but that
773 # may change in the future so they should be matchable, hence an empty file is
774 # generated for them.
775 my @tables_that_may_be_empty = (
776                                 'Joining_Type=Left_Joining',
777                                 );
778 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
779 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
780 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
781                                                     if $v_version ge v4.1.0;
782
783 # The lists below are hashes, so the key is the item in the list, and the
784 # value is the reason why it is in the list.  This makes generation of
785 # documentation easier.
786
787 my %why_suppressed;  # No file generated for these.
788
789 # Files aren't generated for empty extraneous properties.  This is arguable.
790 # Extraneous properties generally come about because a property is no longer
791 # used in a newer version of Unicode.  If we generated a file without code
792 # points, programs that used to work on that property will still execute
793 # without errors.  It just won't ever match (or will always match, with \P{}).
794 # This means that the logic is now likely wrong.  I (khw) think its better to
795 # find this out by getting an error message.  Just move them to the table
796 # above to change this behavior
797 my %why_suppress_if_empty_warn_if_not = (
798
799    # It is the only property that has ever officially been removed from the
800    # Standard.  The database never contained any code points for it.
801    'Special_Case_Condition' => 'Obsolete',
802
803    # Apparently never official, but there were code points in some versions of
804    # old-style PropList.txt
805    'Non_Break' => 'Obsolete',
806 );
807
808 # These would normally go in the warn table just above, but they were changed
809 # a long time before this program was written, so warnings about them are
810 # moot.
811 if ($v_version gt v3.2.0) {
812     push @tables_that_may_be_empty,
813                                 'Canonical_Combining_Class=Attached_Below_Left'
814 }
815
816 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
817 # unless explicitly added.
818 if ($v_version ge v5.2.0) {
819     my $unihan = 'Unihan; remove from list if using Unihan';
820     foreach my $table (qw (
821                            kAccountingNumeric
822                            kOtherNumeric
823                            kPrimaryNumeric
824                            kCompatibilityVariant
825                            kIICore
826                            kIRG_GSource
827                            kIRG_HSource
828                            kIRG_JSource
829                            kIRG_KPSource
830                            kIRG_MSource
831                            kIRG_KSource
832                            kIRG_TSource
833                            kIRG_USource
834                            kIRG_VSource
835                            kRSUnicode
836                         ))
837     {
838         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
839     }
840 }
841
842 # Enum values for to_output_map() method in the Map_Table package.
843 my $EXTERNAL_MAP = 1;
844 my $INTERNAL_MAP = 2;
845
846 # To override computed values for writing the map tables for these properties.
847 # The default for enum map tables is to write them out, so that the Unicode
848 # .txt files can be removed, but all the data to compute any property value
849 # for any code point is available in a more compact form.
850 my %global_to_output_map = (
851     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
852     # get stuck supporting it if things change.  Sinc it is a STRING property,
853     # it normally would be listed in the pod, but INTERNAL_MAP suppresses
854     # that.
855     Unicode_1_Name => $INTERNAL_MAP,
856
857     Present_In => 0,                # Suppress, as easily computed from Age
858     Canonical_Combining_Class => 0, # Duplicate of CombiningClass.pl
859     Block => 0,                     # Suppress, as Blocks.txt is retained.
860 );
861
862 # Properties that this program ignores.
863 my @unimplemented_properties = (
864 'Unicode_Radical_Stroke'    # Remove if changing to handle this one.
865 );
866
867 # There are several types of obsolete properties defined by Unicode.  These
868 # must be hand-edited for every new Unicode release.
869 my %why_deprecated;  # Generates a deprecated warning message if used.
870 my %why_stabilized;  # Documentation only
871 my %why_obsolete;    # Documentation only
872
873 {   # Closure
874     my $simple = 'Perl uses the more complete version of this property';
875     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
876
877     my $other_properties = 'other properties';
878     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
879     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
880
881     %why_deprecated = (
882         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
883         'Jamo_Short_Name' => $contributory,
884         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
885         'Other_Alphabetic' => $contributory,
886         'Other_Default_Ignorable_Code_Point' => $contributory,
887         'Other_Grapheme_Extend' => $contributory,
888         'Other_ID_Continue' => $contributory,
889         'Other_ID_Start' => $contributory,
890         'Other_Lowercase' => $contributory,
891         'Other_Math' => $contributory,
892         'Other_Uppercase' => $contributory,
893     );
894
895     %why_suppressed = (
896         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
897         # contains the same information, but without the algorithmically
898         # determinable Hangul syllables'.  This file is not published, so it's
899         # existence is not noted in the comment.
900         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize',
901
902         'ISO_Comment' => 'Apparently no demand for it, but can access it through Unicode::UCD::charinfo.  Obsoleted, and code points for it removed in Unicode 5.2',
903
904         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold",
905         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
906         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
907         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
908
909         'Name' => "Accessible via 'use charnames;'",
910         'Name_Alias' => "Accessible via 'use charnames;'",
911
912         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
913         Expands_On_NFC => $why_no_expand,
914         Expands_On_NFD => $why_no_expand,
915         Expands_On_NFKC => $why_no_expand,
916         Expands_On_NFKD => $why_no_expand,
917     );
918
919     # The following are suppressed because they were made contributory or
920     # deprecated by Unicode before Perl ever thought about supporting them.
921     foreach my $property ('Jamo_Short_Name', 'Grapheme_Link') {
922         $why_suppressed{$property} = $why_deprecated{$property};
923     }
924
925     # Customize the message for all the 'Other_' properties
926     foreach my $property (keys %why_deprecated) {
927         next if (my $main_property = $property) !~ s/^Other_//;
928         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
929     }
930 }
931
932 if ($v_version ge 4.0.0) {
933     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
934     if ($v_version ge 6.0.0) {
935         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
936     }
937 }
938 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
939     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
940     if ($v_version ge 6.0.0) {
941         $why_deprecated{'ISO_Comment'} = 'No longer needed for chart generation; otherwise not useful, and code points for it have been removed';
942     }
943 }
944
945 # Probably obsolete forever
946 if ($v_version ge v4.1.0) {
947     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common"';
948 }
949
950 # This program can create files for enumerated-like properties, such as
951 # 'Numeric_Type'.  This file would be the same format as for a string
952 # property, with a mapping from code point to its value, so you could look up,
953 # for example, the script a code point is in.  But no one so far wants this
954 # mapping, or they have found another way to get it since this is a new
955 # feature.  So no file is generated except if it is in this list.
956 my @output_mapped_properties = split "\n", <<END;
957 END
958
959 # If you are using the Unihan database, you need to add the properties that
960 # you want to extract from it to this table.  For your convenience, the
961 # properties in the 6.0 PropertyAliases.txt file are listed, commented out
962 my @cjk_properties = split "\n", <<'END';
963 #cjkAccountingNumeric; kAccountingNumeric
964 #cjkOtherNumeric; kOtherNumeric
965 #cjkPrimaryNumeric; kPrimaryNumeric
966 #cjkCompatibilityVariant; kCompatibilityVariant
967 #cjkIICore ; kIICore
968 #cjkIRG_GSource; kIRG_GSource
969 #cjkIRG_HSource; kIRG_HSource
970 #cjkIRG_JSource; kIRG_JSource
971 #cjkIRG_KPSource; kIRG_KPSource
972 #cjkIRG_KSource; kIRG_KSource
973 #cjkIRG_TSource; kIRG_TSource
974 #cjkIRG_USource; kIRG_USource
975 #cjkIRG_VSource; kIRG_VSource
976 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
977 END
978
979 # Similarly for the property values.  For your convenience, the lines in the
980 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
981 # '#' marks
982 my @cjk_property_values = split "\n", <<'END';
983 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
984 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
985 ## @missing: 0000..10FFFF; cjkIICore; <none>
986 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
987 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
988 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
989 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
990 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
991 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
992 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
993 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
994 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
995 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
996 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
997 END
998
999 # The input files don't list every code point.  Those not listed are to be
1000 # defaulted to some value.  Below are hard-coded what those values are for
1001 # non-binary properties as of 5.1.  Starting in 5.0, there are
1002 # machine-parsable comment lines in the files the give the defaults; so this
1003 # list shouldn't have to be extended.  The claim is that all missing entries
1004 # for binary properties will default to 'N'.  Unicode tried to change that in
1005 # 5.2, but the beta period produced enough protest that they backed off.
1006 #
1007 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1008 # be in the form that it expects.  The others may be synonyms.
1009 my $CODE_POINT = '<code point>';
1010 my %default_mapping = (
1011     Age => "Unassigned",
1012     # Bidi_Class => Complicated; set in code
1013     Bidi_Mirroring_Glyph => "",
1014     Block => 'No_Block',
1015     Canonical_Combining_Class => 0,
1016     Case_Folding => $CODE_POINT,
1017     Decomposition_Mapping => $CODE_POINT,
1018     Decomposition_Type => 'None',
1019     East_Asian_Width => "Neutral",
1020     FC_NFKC_Closure => $CODE_POINT,
1021     General_Category => 'Cn',
1022     Grapheme_Cluster_Break => 'Other',
1023     Hangul_Syllable_Type => 'NA',
1024     ISO_Comment => "",
1025     Jamo_Short_Name => "",
1026     Joining_Group => "No_Joining_Group",
1027     # Joining_Type => Complicated; set in code
1028     kIICore => 'N',   #                       Is converted to binary
1029     #Line_Break => Complicated; set in code
1030     Lowercase_Mapping => $CODE_POINT,
1031     Name => "",
1032     Name_Alias => "",
1033     NFC_QC => 'Yes',
1034     NFD_QC => 'Yes',
1035     NFKC_QC => 'Yes',
1036     NFKD_QC => 'Yes',
1037     Numeric_Type => 'None',
1038     Numeric_Value => 'NaN',
1039     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1040     Sentence_Break => 'Other',
1041     Simple_Case_Folding => $CODE_POINT,
1042     Simple_Lowercase_Mapping => $CODE_POINT,
1043     Simple_Titlecase_Mapping => $CODE_POINT,
1044     Simple_Uppercase_Mapping => $CODE_POINT,
1045     Titlecase_Mapping => $CODE_POINT,
1046     Unicode_1_Name => "",
1047     Unicode_Radical_Stroke => "",
1048     Uppercase_Mapping => $CODE_POINT,
1049     Word_Break => 'Other',
1050 );
1051
1052 # Below are files that Unicode furnishes, but this program ignores, and why
1053 my %ignored_files = (
1054     'CJKRadicals.txt' => 'Unihan data',
1055     'Index.txt' => 'An index, not actual data',
1056     'NamedSqProv.txt' => 'Not officially part of the Unicode standard; Append it to NamedSequences.txt if you want to process the contents.',
1057     'NamesList.txt' => 'Just adds commentary',
1058     'NormalizationCorrections.txt' => 'Data is already in other files.',
1059     'Props.txt' => 'Adds nothing to PropList.txt; only in very early releases',
1060     'ReadMe.txt' => 'Just comments',
1061     'README.TXT' => 'Just comments',
1062     'StandardizedVariants.txt' => 'Only for glyph changes, not a Unicode character property.  Does not fit into current scheme where one code point is mapped',
1063     'EmojiSources.txt' => 'Not of general utility: for Japanese legacy cell-phone applications',
1064     'IndicMatraCategory.txt' => 'Provisional',
1065     'IndicSyllabicCategory.txt' => 'Provisional',
1066     'ScriptExtensions.txt' => 'Provisional',
1067 );
1068
1069 ### End of externally interesting definitions, except for @input_file_objects
1070
1071 my $HEADER=<<"EOF";
1072 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1073 # This file is machine-generated by $0 from the Unicode
1074 # database, Version $string_version.  Any changes made here will be lost!
1075 EOF
1076
1077 my $INTERNAL_ONLY=<<"EOF";
1078
1079 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1080 # This file is for internal use by the Perl program only.  The format and even
1081 # the name or existence of this file are subject to change without notice.
1082 # Don't use it directly.
1083 EOF
1084
1085 my $DEVELOPMENT_ONLY=<<"EOF";
1086 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1087 # This file contains information artificially constrained to code points
1088 # present in Unicode release $string_compare_versions.
1089 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1090 # not be used for production.
1091
1092 EOF
1093
1094 my $LAST_UNICODE_CODEPOINT_STRING = "10FFFF";
1095 my $LAST_UNICODE_CODEPOINT = hex $LAST_UNICODE_CODEPOINT_STRING;
1096 my $MAX_UNICODE_CODEPOINTS = $LAST_UNICODE_CODEPOINT + 1;
1097
1098 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1099 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1100 # to decrease backtracking.  The first one allows the code point to be at the
1101 # end of a word, but to work properly, the word shouldn't end with a valid hex
1102 # character.  The second one won't match a code point at the end of a word,
1103 # and doesn't have the run-on issue
1104 my $run_on_code_point_re =
1105             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1106 my $code_point_re = qr/\b$run_on_code_point_re/;
1107
1108 # This matches the beginning of the line in the Unicode db files that give the
1109 # defaults for code points not listed (i.e., missing) in the file.  The code
1110 # depends on this ending with a semi-colon, so it can assume it is a valid
1111 # field when the line is split() by semi-colons
1112 my $missing_defaults_prefix =
1113             qr/^#\s+\@missing:\s+0000\.\.$LAST_UNICODE_CODEPOINT_STRING\s*;/;
1114
1115 # Property types.  Unicode has more types, but these are sufficient for our
1116 # purposes.
1117 my $UNKNOWN = -1;   # initialized to illegal value
1118 my $NON_STRING = 1; # Either binary or enum
1119 my $BINARY = 2;
1120 my $ENUM = 3;       # Include catalog
1121 my $STRING = 4;     # Anything else: string or misc
1122
1123 # Some input files have lines that give default values for code points not
1124 # contained in the file.  Sometimes these should be ignored.
1125 my $NO_DEFAULTS = 0;        # Must evaluate to false
1126 my $NOT_IGNORED = 1;
1127 my $IGNORED = 2;
1128
1129 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1130 # and will appear in the main body of the tables in the output files, but
1131 # there are other types of ranges as well, listed below, that are specially
1132 # handled.   There are pseudo-types as well that will never be stored as a
1133 # type, but will affect the calculation of the type.
1134
1135 # 0 is for normal, non-specials
1136 my $MULTI_CP = 1;           # Sequence of more than code point
1137 my $HANGUL_SYLLABLE = 2;
1138 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1139 my $NULL = 4;               # The map is to the null string; utf8.c can't
1140                             # handle these, nor is there an accepted syntax
1141                             # for them in \p{} constructs
1142 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1143                              # otherwise be $MULTI_CP type are instead type 0
1144
1145 # process_generic_property_file() can accept certain overrides in its input.
1146 # Each of these must begin AND end with $CMD_DELIM.
1147 my $CMD_DELIM = "\a";
1148 my $REPLACE_CMD = 'replace';    # Override the Replace
1149 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1150
1151 my $NO = 0;
1152 my $YES = 1;
1153
1154 # Values for the Replace argument to add_range.
1155 # $NO                      # Don't replace; add only the code points not
1156                            # already present.
1157 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1158                            # the comments at the subroutine definition.
1159 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1160 my $MULTIPLE = 4;          # Don't replace, but add a duplicate record if
1161                            # already there
1162 my $CROAK = 5;             # Die with an error if is already there
1163
1164 # Flags to give property statuses.  The phrases are to remind maintainers that
1165 # if the flag is changed, the indefinite article referring to it in the
1166 # documentation may need to be as well.
1167 my $NORMAL = "";
1168 my $SUPPRESSED = 'z';   # The character should never actually be seen, since
1169                         # it is suppressed
1170 my $PLACEHOLDER = 'P';  # Implies no pod entry generated
1171 my $DEPRECATED = 'D';
1172 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1173 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1174 my $DISCOURAGED = 'X';
1175 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1176 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1177 my $STRICTER = 'T';
1178 my $a_bold_stricter = "a 'B<$STRICTER>'";
1179 my $A_bold_stricter = "A 'B<$STRICTER>'";
1180 my $STABILIZED = 'S';
1181 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1182 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1183 my $OBSOLETE = 'O';
1184 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1185 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1186
1187 my %status_past_participles = (
1188     $DISCOURAGED => 'discouraged',
1189     $SUPPRESSED => 'should never be generated',
1190     $STABILIZED => 'stabilized',
1191     $OBSOLETE => 'obsolete',
1192     $DEPRECATED => 'deprecated',
1193 );
1194
1195 # The format of the values of the tables:
1196 my $EMPTY_FORMAT = "";
1197 my $BINARY_FORMAT = 'b';
1198 my $DECIMAL_FORMAT = 'd';
1199 my $FLOAT_FORMAT = 'f';
1200 my $INTEGER_FORMAT = 'i';
1201 my $HEX_FORMAT = 'x';
1202 my $RATIONAL_FORMAT = 'r';
1203 my $STRING_FORMAT = 's';
1204 my $DECOMP_STRING_FORMAT = 'c';
1205
1206 my %map_table_formats = (
1207     $BINARY_FORMAT => 'binary',
1208     $DECIMAL_FORMAT => 'single decimal digit',
1209     $FLOAT_FORMAT => 'floating point number',
1210     $INTEGER_FORMAT => 'integer',
1211     $HEX_FORMAT => 'positive hex whole number; a code point',
1212     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1213     $STRING_FORMAT => 'string',
1214     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1215 );
1216
1217 # Unicode didn't put such derived files in a separate directory at first.
1218 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1219 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1220 my $AUXILIARY = 'auxiliary';
1221
1222 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1223 my %loose_to_file_of;       # loosely maps table names to their respective
1224                             # files
1225 my %stricter_to_file_of;    # same; but for stricter mapping.
1226 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1227                              # their rational equivalent
1228 my %loose_property_name_of; # Loosely maps property names to standard form
1229
1230 # Most properties are immune to caseless matching, otherwise you would get
1231 # nonsensical results, as properties are a function of a code point, not
1232 # everything that is caselessly equivalent to that code point.  For example,
1233 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1234 # be true because 's' and 'S' are equivalent caselessly.  However,
1235 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1236 # extend that concept to those very few properties that are like this.  Each
1237 # such property will match the full range caselessly.  They are hard-coded in
1238 # the program; it's not worth trying to make it general as it's extremely
1239 # unlikely that they will ever change.
1240 my %caseless_equivalent_to;
1241
1242 # These constants names and values were taken from the Unicode standard,
1243 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1244 # syllables.  The '_string' versions are so generated tables can retain the
1245 # hex format, which is the more familiar value
1246 my $SBase_string = "0xAC00";
1247 my $SBase = CORE::hex $SBase_string;
1248 my $LBase_string = "0x1100";
1249 my $LBase = CORE::hex $LBase_string;
1250 my $VBase_string = "0x1161";
1251 my $VBase = CORE::hex $VBase_string;
1252 my $TBase_string = "0x11A7";
1253 my $TBase = CORE::hex $TBase_string;
1254 my $SCount = 11172;
1255 my $LCount = 19;
1256 my $VCount = 21;
1257 my $TCount = 28;
1258 my $NCount = $VCount * $TCount;
1259
1260 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1261 # with the above published constants.
1262 my %Jamo;
1263 my %Jamo_L;     # Leading consonants
1264 my %Jamo_V;     # Vowels
1265 my %Jamo_T;     # Trailing consonants
1266
1267 my @backslash_X_tests;     # List of tests read in for testing \X
1268 my @unhandled_properties;  # Will contain a list of properties found in
1269                            # the input that we didn't process.
1270 my @match_properties;      # Properties that have match tables, to be
1271                            # listed in the pod
1272 my @map_properties;        # Properties that get map files written
1273 my @named_sequences;       # NamedSequences.txt contents.
1274 my %potential_files;       # Generated list of all .txt files in the directory
1275                            # structure so we can warn if something is being
1276                            # ignored.
1277 my @files_actually_output; # List of files we generated.
1278 my @more_Names;            # Some code point names are compound; this is used
1279                            # to store the extra components of them.
1280 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1281                            # the minimum before we consider it equivalent to a
1282                            # candidate rational
1283 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1284
1285 # These store references to certain commonly used property objects
1286 my $gc;
1287 my $perl;
1288 my $block;
1289 my $perl_charname;
1290 my $print;
1291 my $Any;
1292
1293 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1294 my $has_In_conflicts = 0;
1295 my $has_Is_conflicts = 0;
1296
1297 sub internal_file_to_platform ($) {
1298     # Convert our file paths which have '/' separators to those of the
1299     # platform.
1300
1301     my $file = shift;
1302     return undef unless defined $file;
1303
1304     return File::Spec->join(split '/', $file);
1305 }
1306
1307 sub file_exists ($) {   # platform independent '-e'.  This program internally
1308                         # uses slash as a path separator.
1309     my $file = shift;
1310     return 0 if ! defined $file;
1311     return -e internal_file_to_platform($file);
1312 }
1313
1314 sub objaddr($) {
1315     # Returns the address of the blessed input object.
1316     # It doesn't check for blessedness because that would do a string eval
1317     # every call, and the program is structured so that this is never called
1318     # for a non-blessed object.
1319
1320     no overloading; # If overloaded, numifying below won't work.
1321
1322     # Numifying a ref gives its address.
1323     return pack 'J', $_[0];
1324 }
1325
1326 # These are used only if $annotate is true.
1327 # The entire range of Unicode characters is examined to populate these
1328 # after all the input has been processed.  But most can be skipped, as they
1329 # have the same descriptive phrases, such as being unassigned
1330 my @viacode;            # Contains the 1 million character names
1331 my @printable;          # boolean: And are those characters printable?
1332 my @annotate_char_type; # Contains a type of those characters, specifically
1333                         # for the purposes of annotation.
1334 my $annotate_ranges;    # A map of ranges of code points that have the same
1335                         # name for the purposes of annotation.  They map to the
1336                         # upper edge of the range, so that the end point can
1337                         # be immediately found.  This is used to skip ahead to
1338                         # the end of a range, and avoid processing each
1339                         # individual code point in it.
1340 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1341                                    # characters, but excluding those which are
1342                                    # also noncharacter code points
1343
1344 # The annotation types are an extension of the regular range types, though
1345 # some of the latter are folded into one.  Make the new types negative to
1346 # avoid conflicting with the regular types
1347 my $SURROGATE_TYPE = -1;
1348 my $UNASSIGNED_TYPE = -2;
1349 my $PRIVATE_USE_TYPE = -3;
1350 my $NONCHARACTER_TYPE = -4;
1351 my $CONTROL_TYPE = -5;
1352 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1353
1354 sub populate_char_info ($) {
1355     # Used only with the $annotate option.  Populates the arrays with the
1356     # input code point's info that are needed for outputting more detailed
1357     # comments.  If calling context wants a return, it is the end point of
1358     # any contiguous range of characters that share essentially the same info
1359
1360     my $i = shift;
1361     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1362
1363     $viacode[$i] = $perl_charname->value_of($i) || "";
1364
1365     # A character is generally printable if Unicode says it is,
1366     # but below we make sure that most Unicode general category 'C' types
1367     # aren't.
1368     $printable[$i] = $print->contains($i);
1369
1370     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1371
1372     # Only these two regular types are treated specially for annotations
1373     # purposes
1374     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1375                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1376
1377     # Give a generic name to all code points that don't have a real name.
1378     # We output ranges, if applicable, for these.  Also calculate the end
1379     # point of the range.
1380     my $end;
1381     if (! $viacode[$i]) {
1382         if ($gc-> table('Surrogate')->contains($i)) {
1383             $viacode[$i] = 'Surrogate';
1384             $annotate_char_type[$i] = $SURROGATE_TYPE;
1385             $printable[$i] = 0;
1386             $end = $gc->table('Surrogate')->containing_range($i)->end;
1387         }
1388         elsif ($gc-> table('Private_use')->contains($i)) {
1389             $viacode[$i] = 'Private Use';
1390             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1391             $printable[$i] = 0;
1392             $end = $gc->table('Private_Use')->containing_range($i)->end;
1393         }
1394         elsif (Property::property_ref('Noncharacter_Code_Point')-> table('Y')->
1395                                                                 contains($i))
1396         {
1397             $viacode[$i] = 'Noncharacter';
1398             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1399             $printable[$i] = 0;
1400             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1401                                                     containing_range($i)->end;
1402         }
1403         elsif ($gc-> table('Control')->contains($i)) {
1404             $viacode[$i] = 'Control';
1405             $annotate_char_type[$i] = $CONTROL_TYPE;
1406             $printable[$i] = 0;
1407             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1408         }
1409         elsif ($gc-> table('Unassigned')->contains($i)) {
1410             $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1411             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1412             $printable[$i] = 0;
1413
1414             # Because we name the unassigned by the blocks they are in, it
1415             # can't go past the end of that block, and it also can't go past
1416             # the unassigned range it is in.  The special table makes sure
1417             # that the non-characters, which are unassigned, are separated
1418             # out.
1419             $end = min($block->containing_range($i)->end,
1420                        $unassigned_sans_noncharacters-> containing_range($i)->
1421                                                                          end);
1422         }
1423         else {
1424             Carp::my_carp_bug("Can't figure out how to annotate "
1425                               . sprintf("U+%04X", $i)
1426                               . ".  Proceeding anyway.");
1427             $viacode[$i] = 'UNKNOWN';
1428             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1429             $printable[$i] = 0;
1430         }
1431     }
1432
1433     # Here, has a name, but if it's one in which the code point number is
1434     # appended to the name, do that.
1435     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1436         $viacode[$i] .= sprintf("-%04X", $i);
1437         $end = $perl_charname->containing_range($i)->end;
1438     }
1439
1440     # And here, has a name, but if it's a hangul syllable one, replace it with
1441     # the correct name from the Unicode algorithm
1442     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1443         use integer;
1444         my $SIndex = $i - $SBase;
1445         my $L = $LBase + $SIndex / $NCount;
1446         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1447         my $T = $TBase + $SIndex % $TCount;
1448         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1449         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1450         $end = $perl_charname->containing_range($i)->end;
1451     }
1452
1453     return if ! defined wantarray;
1454     return $i if ! defined $end;    # If not a range, return the input
1455
1456     # Save this whole range so can find the end point quickly
1457     $annotate_ranges->add_map($i, $end, $end);
1458
1459     return $end;
1460 }
1461
1462 # Commented code below should work on Perl 5.8.
1463 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1464 ## the native perl version of it (which is what would operate under miniperl)
1465 ## is extremely slow, as it does a string eval every call.
1466 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1467 #                            && defined eval "require Scalar::Util";
1468 #
1469 #sub objaddr($) {
1470 #    # Returns the address of the blessed input object.  Uses the XS version if
1471 #    # available.  It doesn't check for blessedness because that would do a
1472 #    # string eval every call, and the program is structured so that this is
1473 #    # never called for a non-blessed object.
1474 #
1475 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1476 #
1477 #    # Check at least that is a ref.
1478 #    my $pkg = ref($_[0]) or return undef;
1479 #
1480 #    # Change to a fake package to defeat any overloaded stringify
1481 #    bless $_[0], 'main::Fake';
1482 #
1483 #    # Numifying a ref gives its address.
1484 #    my $addr = pack 'J', $_[0];
1485 #
1486 #    # Return to original class
1487 #    bless $_[0], $pkg;
1488 #    return $addr;
1489 #}
1490
1491 sub max ($$) {
1492     my $a = shift;
1493     my $b = shift;
1494     return $a if $a >= $b;
1495     return $b;
1496 }
1497
1498 sub min ($$) {
1499     my $a = shift;
1500     my $b = shift;
1501     return $a if $a <= $b;
1502     return $b;
1503 }
1504
1505 sub clarify_number ($) {
1506     # This returns the input number with underscores inserted every 3 digits
1507     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1508     # checked.
1509
1510     my $number = shift;
1511     my $pos = length($number) - 3;
1512     return $number if $pos <= 1;
1513     while ($pos > 0) {
1514         substr($number, $pos, 0) = '_';
1515         $pos -= 3;
1516     }
1517     return $number;
1518 }
1519
1520
1521 package Carp;
1522
1523 # These routines give a uniform treatment of messages in this program.  They
1524 # are placed in the Carp package to cause the stack trace to not include them,
1525 # although an alternative would be to use another package and set @CARP_NOT
1526 # for it.
1527
1528 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1529
1530 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1531 # and overload trying to load Scalar:Util under miniperl.  See
1532 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1533 undef $overload::VERSION;
1534
1535 sub my_carp {
1536     my $message = shift || "";
1537     my $nofold = shift || 0;
1538
1539     if ($message) {
1540         $message = main::join_lines($message);
1541         $message =~ s/^$0: *//;     # Remove initial program name
1542         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1543         $message = "\n$0: $message;";
1544
1545         # Fold the message with program name, semi-colon end punctuation
1546         # (which looks good with the message that carp appends to it), and a
1547         # hanging indent for continuation lines.
1548         $message = main::simple_fold($message, "", 4) unless $nofold;
1549         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1550                                     # appends is to the same line
1551     }
1552
1553     return $message if defined wantarray;   # If a caller just wants the msg
1554
1555     carp $message;
1556     return;
1557 }
1558
1559 sub my_carp_bug {
1560     # This is called when it is clear that the problem is caused by a bug in
1561     # this program.
1562
1563     my $message = shift;
1564     $message =~ s/^$0: *//;
1565     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1566     carp $message;
1567     return;
1568 }
1569
1570 sub carp_too_few_args {
1571     if (@_ != 2) {
1572         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1573         return;
1574     }
1575
1576     my $args_ref = shift;
1577     my $count = shift;
1578
1579     my_carp_bug("Need at least $count arguments to "
1580         . (caller 1)[3]
1581         . ".  Instead got: '"
1582         . join ', ', @$args_ref
1583         . "'.  No action taken.");
1584     return;
1585 }
1586
1587 sub carp_extra_args {
1588     my $args_ref = shift;
1589     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1590
1591     unless (ref $args_ref) {
1592         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1593         return;
1594     }
1595     my ($package, $file, $line) = caller;
1596     my $subroutine = (caller 1)[3];
1597
1598     my $list;
1599     if (ref $args_ref eq 'HASH') {
1600         foreach my $key (keys %$args_ref) {
1601             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1602         }
1603         $list = join ', ', each %{$args_ref};
1604     }
1605     elsif (ref $args_ref eq 'ARRAY') {
1606         foreach my $arg (@$args_ref) {
1607             $arg = $UNDEF unless defined $arg;
1608         }
1609         $list = join ', ', @$args_ref;
1610     }
1611     else {
1612         my_carp_bug("Can't cope with ref "
1613                 . ref($args_ref)
1614                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1615         return;
1616     }
1617
1618     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1619     return;
1620 }
1621
1622 package main;
1623
1624 { # Closure
1625
1626     # This program uses the inside-out method for objects, as recommended in
1627     # "Perl Best Practices".  This closure aids in generating those.  There
1628     # are two routines.  setup_package() is called once per package to set
1629     # things up, and then set_access() is called for each hash representing a
1630     # field in the object.  These routines arrange for the object to be
1631     # properly destroyed when no longer used, and for standard accessor
1632     # functions to be generated.  If you need more complex accessors, just
1633     # write your own and leave those accesses out of the call to set_access().
1634     # More details below.
1635
1636     my %constructor_fields; # fields that are to be used in constructors; see
1637                             # below
1638
1639     # The values of this hash will be the package names as keys to other
1640     # hashes containing the name of each field in the package as keys, and
1641     # references to their respective hashes as values.
1642     my %package_fields;
1643
1644     sub setup_package {
1645         # Sets up the package, creating standard DESTROY and dump methods
1646         # (unless already defined).  The dump method is used in debugging by
1647         # simple_dumper().
1648         # The optional parameters are:
1649         #   a)  a reference to a hash, that gets populated by later
1650         #       set_access() calls with one of the accesses being
1651         #       'constructor'.  The caller can then refer to this, but it is
1652         #       not otherwise used by these two routines.
1653         #   b)  a reference to a callback routine to call during destruction
1654         #       of the object, before any fields are actually destroyed
1655
1656         my %args = @_;
1657         my $constructor_ref = delete $args{'Constructor_Fields'};
1658         my $destroy_callback = delete $args{'Destroy_Callback'};
1659         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1660
1661         my %fields;
1662         my $package = (caller)[0];
1663
1664         $package_fields{$package} = \%fields;
1665         $constructor_fields{$package} = $constructor_ref;
1666
1667         unless ($package->can('DESTROY')) {
1668             my $destroy_name = "${package}::DESTROY";
1669             no strict "refs";
1670
1671             # Use typeglob to give the anonymous subroutine the name we want
1672             *$destroy_name = sub {
1673                 my $self = shift;
1674                 my $addr = do { no overloading; pack 'J', $self; };
1675
1676                 $self->$destroy_callback if $destroy_callback;
1677                 foreach my $field (keys %{$package_fields{$package}}) {
1678                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1679                     delete $package_fields{$package}{$field}{$addr};
1680                 }
1681                 return;
1682             }
1683         }
1684
1685         unless ($package->can('dump')) {
1686             my $dump_name = "${package}::dump";
1687             no strict "refs";
1688             *$dump_name = sub {
1689                 my $self = shift;
1690                 return dump_inside_out($self, $package_fields{$package}, @_);
1691             }
1692         }
1693         return;
1694     }
1695
1696     sub set_access {
1697         # Arrange for the input field to be garbage collected when no longer
1698         # needed.  Also, creates standard accessor functions for the field
1699         # based on the optional parameters-- none if none of these parameters:
1700         #   'addable'    creates an 'add_NAME()' accessor function.
1701         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1702         #                function.
1703         #   'settable'   creates a 'set_NAME()' accessor function.
1704         #   'constructor' doesn't create an accessor function, but adds the
1705         #                field to the hash that was previously passed to
1706         #                setup_package();
1707         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1708         # 'add' etc. all mean 'addable'.
1709         # The read accessor function will work on both array and scalar
1710         # values.  If another accessor in the parameter list is 'a', the read
1711         # access assumes an array.  You can also force it to be array access
1712         # by specifying 'readable_array' instead of 'readable'
1713         #
1714         # A sort-of 'protected' access can be set-up by preceding the addable,
1715         # readable or settable with some initial portion of 'protected_' (but,
1716         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1717         # "protection" is only by convention.  All that happens is that the
1718         # accessor functions' names begin with an underscore.  So instead of
1719         # calling set_foo, the call is _set_foo.  (Real protection could be
1720         # accomplished by having a new subroutine, end_package, called at the
1721         # end of each package, and then storing the __LINE__ ranges and
1722         # checking them on every accessor.  But that is way overkill.)
1723
1724         # We create anonymous subroutines as the accessors and then use
1725         # typeglobs to assign them to the proper package and name
1726
1727         my $name = shift;   # Name of the field
1728         my $field = shift;  # Reference to the inside-out hash containing the
1729                             # field
1730
1731         my $package = (caller)[0];
1732
1733         if (! exists $package_fields{$package}) {
1734             croak "$0: Must call 'setup_package' before 'set_access'";
1735         }
1736
1737         # Stash the field so DESTROY can get it.
1738         $package_fields{$package}{$name} = $field;
1739
1740         # Remaining arguments are the accessors.  For each...
1741         foreach my $access (@_) {
1742             my $access = lc $access;
1743
1744             my $protected = "";
1745
1746             # Match the input as far as it goes.
1747             if ($access =~ /^(p[^_]*)_/) {
1748                 $protected = $1;
1749                 if (substr('protected_', 0, length $protected)
1750                     eq $protected)
1751                 {
1752
1753                     # Add 1 for the underscore not included in $protected
1754                     $access = substr($access, length($protected) + 1);
1755                     $protected = '_';
1756                 }
1757                 else {
1758                     $protected = "";
1759                 }
1760             }
1761
1762             if (substr('addable', 0, length $access) eq $access) {
1763                 my $subname = "${package}::${protected}add_$name";
1764                 no strict "refs";
1765
1766                 # add_ accessor.  Don't add if already there, which we
1767                 # determine using 'eq' for scalars and '==' otherwise.
1768                 *$subname = sub {
1769                     use strict "refs";
1770                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1771                     my $self = shift;
1772                     my $value = shift;
1773                     my $addr = do { no overloading; pack 'J', $self; };
1774                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1775                     if (ref $value) {
1776                         return if grep { $value == $_ } @{$field->{$addr}};
1777                     }
1778                     else {
1779                         return if grep { $value eq $_ } @{$field->{$addr}};
1780                     }
1781                     push @{$field->{$addr}}, $value;
1782                     return;
1783                 }
1784             }
1785             elsif (substr('constructor', 0, length $access) eq $access) {
1786                 if ($protected) {
1787                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1788                 }
1789                 else {
1790                     $constructor_fields{$package}{$name} = $field;
1791                 }
1792             }
1793             elsif (substr('readable_array', 0, length $access) eq $access) {
1794
1795                 # Here has read access.  If one of the other parameters for
1796                 # access is array, or this one specifies array (by being more
1797                 # than just 'readable_'), then create a subroutine that
1798                 # assumes the data is an array.  Otherwise just a scalar
1799                 my $subname = "${package}::${protected}$name";
1800                 if (grep { /^a/i } @_
1801                     or length($access) > length('readable_'))
1802                 {
1803                     no strict "refs";
1804                     *$subname = sub {
1805                         use strict "refs";
1806                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1807                         my $addr = do { no overloading; pack 'J', $_[0]; };
1808                         if (ref $field->{$addr} ne 'ARRAY') {
1809                             my $type = ref $field->{$addr};
1810                             $type = 'scalar' unless $type;
1811                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1812                             return;
1813                         }
1814                         return scalar @{$field->{$addr}} unless wantarray;
1815
1816                         # Make a copy; had problems with caller modifying the
1817                         # original otherwise
1818                         my @return = @{$field->{$addr}};
1819                         return @return;
1820                     }
1821                 }
1822                 else {
1823
1824                     # Here not an array value, a simpler function.
1825                     no strict "refs";
1826                     *$subname = sub {
1827                         use strict "refs";
1828                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1829                         no overloading;
1830                         return $field->{pack 'J', $_[0]};
1831                     }
1832                 }
1833             }
1834             elsif (substr('settable', 0, length $access) eq $access) {
1835                 my $subname = "${package}::${protected}set_$name";
1836                 no strict "refs";
1837                 *$subname = sub {
1838                     use strict "refs";
1839                     if (main::DEBUG) {
1840                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1841                         Carp::carp_extra_args(\@_) if @_ > 2;
1842                     }
1843                     # $self is $_[0]; $value is $_[1]
1844                     no overloading;
1845                     $field->{pack 'J', $_[0]} = $_[1];
1846                     return;
1847                 }
1848             }
1849             else {
1850                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1851             }
1852         }
1853         return;
1854     }
1855 }
1856
1857 package Input_file;
1858
1859 # All input files use this object, which stores various attributes about them,
1860 # and provides for convenient, uniform handling.  The run method wraps the
1861 # processing.  It handles all the bookkeeping of opening, reading, and closing
1862 # the file, returning only significant input lines.
1863 #
1864 # Each object gets a handler which processes the body of the file, and is
1865 # called by run().  Most should use the generic, default handler, which has
1866 # code scrubbed to handle things you might not expect.  A handler should
1867 # basically be a while(next_line()) {...} loop.
1868 #
1869 # You can also set up handlers to
1870 #   1) call before the first line is read for pre processing
1871 #   2) call to adjust each line of the input before the main handler gets them
1872 #   3) call upon EOF before the main handler exits its loop
1873 #   4) call at the end for post processing
1874 #
1875 # $_ is used to store the input line, and is to be filtered by the
1876 # each_line_handler()s.  So, if the format of the line is not in the desired
1877 # format for the main handler, these are used to do that adjusting.  They can
1878 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1879 # so the $_ output of one is used as the input to the next.  None of the other
1880 # handlers are stackable, but could easily be changed to be so.
1881 #
1882 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1883 # which insert the parameters as lines to be processed before the next input
1884 # file line is read.  This allows the EOF handler to flush buffers, for
1885 # example.  The difference between the two routines is that the lines inserted
1886 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1887 # called it from such a handler, you would get infinite recursion.)  Lines
1888 # inserted by insert_adjusted_lines() go directly to the main handler without
1889 # any adjustments.  If the  post-processing handler calls any of these, there
1890 # will be no effect.  Some error checking for these conditions could be added,
1891 # but it hasn't been done.
1892 #
1893 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1894 # to prevent further processing of the line.  This routine will output the
1895 # message as a warning once, and then keep a count of the lines that have the
1896 # same message, and output that count at the end of the file's processing.
1897 # This keeps the number of messages down to a manageable amount.
1898 #
1899 # get_missings() should be called to retrieve any @missing input lines.
1900 # Messages will be raised if this isn't done if the options aren't to ignore
1901 # missings.
1902
1903 sub trace { return main::trace(@_); }
1904
1905 { # Closure
1906     # Keep track of fields that are to be put into the constructor.
1907     my %constructor_fields;
1908
1909     main::setup_package(Constructor_Fields => \%constructor_fields);
1910
1911     my %file; # Input file name, required
1912     main::set_access('file', \%file, qw{ c r });
1913
1914     my %first_released; # Unicode version file was first released in, required
1915     main::set_access('first_released', \%first_released, qw{ c r });
1916
1917     my %handler;    # Subroutine to process the input file, defaults to
1918                     # 'process_generic_property_file'
1919     main::set_access('handler', \%handler, qw{ c });
1920
1921     my %property;
1922     # name of property this file is for.  defaults to none, meaning not
1923     # applicable, or is otherwise determinable, for example, from each line.
1924     main::set_access('property', \%property, qw{ c });
1925
1926     my %optional;
1927     # If this is true, the file is optional.  If not present, no warning is
1928     # output.  If it is present, the string given by this parameter is
1929     # evaluated, and if false the file is not processed.
1930     main::set_access('optional', \%optional, 'c', 'r');
1931
1932     my %non_skip;
1933     # This is used for debugging, to skip processing of all but a few input
1934     # files.  Add 'non_skip => 1' to the constructor for those files you want
1935     # processed when you set the $debug_skip global.
1936     main::set_access('non_skip', \%non_skip, 'c');
1937
1938     my %skip;
1939     # This is used to skip processing of this input file semi-permanently.
1940     # It is used for files that we aren't planning to process anytime soon,
1941     # but want to allow to be in the directory and not raise a message that we
1942     # are not handling.  Mostly for test files.  This is in contrast to the
1943     # non_skip element, which is supposed to be used very temporarily for
1944     # debugging.  Sets 'optional' to 1
1945     main::set_access('skip', \%skip, 'c');
1946
1947     my %each_line_handler;
1948     # list of subroutines to look at and filter each non-comment line in the
1949     # file.  defaults to none.  The subroutines are called in order, each is
1950     # to adjust $_ for the next one, and the final one adjusts it for
1951     # 'handler'
1952     main::set_access('each_line_handler', \%each_line_handler, 'c');
1953
1954     my %has_missings_defaults;
1955     # ? Are there lines in the file giving default values for code points
1956     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
1957     # the norm, but IGNORED means it has such lines, but the handler doesn't
1958     # use them.  Having these three states allows us to catch changes to the
1959     # UCD that this program should track
1960     main::set_access('has_missings_defaults',
1961                                         \%has_missings_defaults, qw{ c r });
1962
1963     my %pre_handler;
1964     # Subroutine to call before doing anything else in the file.  If undef, no
1965     # such handler is called.
1966     main::set_access('pre_handler', \%pre_handler, qw{ c });
1967
1968     my %eof_handler;
1969     # Subroutine to call upon getting an EOF on the input file, but before
1970     # that is returned to the main handler.  This is to allow buffers to be
1971     # flushed.  The handler is expected to call insert_lines() or
1972     # insert_adjusted() with the buffered material
1973     main::set_access('eof_handler', \%eof_handler, qw{ c r });
1974
1975     my %post_handler;
1976     # Subroutine to call after all the lines of the file are read in and
1977     # processed.  If undef, no such handler is called.
1978     main::set_access('post_handler', \%post_handler, qw{ c });
1979
1980     my %progress_message;
1981     # Message to print to display progress in lieu of the standard one
1982     main::set_access('progress_message', \%progress_message, qw{ c });
1983
1984     my %handle;
1985     # cache open file handle, internal.  Is undef if file hasn't been
1986     # processed at all, empty if has;
1987     main::set_access('handle', \%handle);
1988
1989     my %added_lines;
1990     # cache of lines added virtually to the file, internal
1991     main::set_access('added_lines', \%added_lines);
1992
1993     my %errors;
1994     # cache of errors found, internal
1995     main::set_access('errors', \%errors);
1996
1997     my %missings;
1998     # storage of '@missing' defaults lines
1999     main::set_access('missings', \%missings);
2000
2001     sub new {
2002         my $class = shift;
2003
2004         my $self = bless \do{ my $anonymous_scalar }, $class;
2005         my $addr = do { no overloading; pack 'J', $self; };
2006
2007         # Set defaults
2008         $handler{$addr} = \&main::process_generic_property_file;
2009         $non_skip{$addr} = 0;
2010         $skip{$addr} = 0;
2011         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2012         $handle{$addr} = undef;
2013         $added_lines{$addr} = [ ];
2014         $each_line_handler{$addr} = [ ];
2015         $errors{$addr} = { };
2016         $missings{$addr} = [ ];
2017
2018         # Two positional parameters.
2019         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2020         $file{$addr} = main::internal_file_to_platform(shift);
2021         $first_released{$addr} = shift;
2022
2023         # The rest of the arguments are key => value pairs
2024         # %constructor_fields has been set up earlier to list all possible
2025         # ones.  Either set or push, depending on how the default has been set
2026         # up just above.
2027         my %args = @_;
2028         foreach my $key (keys %args) {
2029             my $argument = $args{$key};
2030
2031             # Note that the fields are the lower case of the constructor keys
2032             my $hash = $constructor_fields{lc $key};
2033             if (! defined $hash) {
2034                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2035                 next;
2036             }
2037             if (ref $hash->{$addr} eq 'ARRAY') {
2038                 if (ref $argument eq 'ARRAY') {
2039                     foreach my $argument (@{$argument}) {
2040                         next if ! defined $argument;
2041                         push @{$hash->{$addr}}, $argument;
2042                     }
2043                 }
2044                 else {
2045                     push @{$hash->{$addr}}, $argument if defined $argument;
2046                 }
2047             }
2048             else {
2049                 $hash->{$addr} = $argument;
2050             }
2051             delete $args{$key};
2052         };
2053
2054         # If the file has a property for it, it means that the property is not
2055         # listed in the file's entries.  So add a handler to the list of line
2056         # handlers to insert the property name into the lines, to provide a
2057         # uniform interface to the final processing subroutine.
2058         # the final code doesn't have to worry about that.
2059         if ($property{$addr}) {
2060             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2061         }
2062
2063         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2064             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2065         }
2066
2067         $optional{$addr} = 1 if $skip{$addr};
2068
2069         return $self;
2070     }
2071
2072
2073     use overload
2074         fallback => 0,
2075         qw("") => "_operator_stringify",
2076         "." => \&main::_operator_dot,
2077     ;
2078
2079     sub _operator_stringify {
2080         my $self = shift;
2081
2082         return __PACKAGE__ . " object for " . $self->file;
2083     }
2084
2085     # flag to make sure extracted files are processed early
2086     my $seen_non_extracted_non_age = 0;
2087
2088     sub run {
2089         # Process the input object $self.  This opens and closes the file and
2090         # calls all the handlers for it.  Currently,  this can only be called
2091         # once per file, as it destroy's the EOF handler
2092
2093         my $self = shift;
2094         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2095
2096         my $addr = do { no overloading; pack 'J', $self; };
2097
2098         my $file = $file{$addr};
2099
2100         # Don't process if not expecting this file (because released later
2101         # than this Unicode version), and isn't there.  This means if someone
2102         # copies it into an earlier version's directory, we will go ahead and
2103         # process it.
2104         return if $first_released{$addr} gt $v_version && ! -e $file;
2105
2106         # If in debugging mode and this file doesn't have the non-skip
2107         # flag set, and isn't one of the critical files, skip it.
2108         if ($debug_skip
2109             && $first_released{$addr} ne v0
2110             && ! $non_skip{$addr})
2111         {
2112             print "Skipping $file in debugging\n" if $verbosity;
2113             return;
2114         }
2115
2116         # File could be optional
2117         if ($optional{$addr}) {
2118             return unless -e $file;
2119             my $result = eval $optional{$addr};
2120             if (! defined $result) {
2121                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2122                 return;
2123             }
2124             if (! $result) {
2125                 if ($verbosity) {
2126                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2127                 }
2128                 return;
2129             }
2130         }
2131
2132         if (! defined $file || ! -e $file) {
2133
2134             # If the file doesn't exist, see if have internal data for it
2135             # (based on first_released being 0).
2136             if ($first_released{$addr} eq v0) {
2137                 $handle{$addr} = 'pretend_is_open';
2138             }
2139             else {
2140                 if (! $optional{$addr}  # File could be optional
2141                     && $v_version ge $first_released{$addr})
2142                 {
2143                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2144                 }
2145                 return;
2146             }
2147         }
2148         else {
2149
2150             # Here, the file exists.  Some platforms may change the case of
2151             # its name
2152             if ($seen_non_extracted_non_age) {
2153                 if ($file =~ /$EXTRACTED/i) {
2154                     Carp::my_carp_bug(join_lines(<<END
2155 $file should be processed just after the 'Prop...Alias' files, and before
2156 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2157 have subtle problems
2158 END
2159                     ));
2160                 }
2161             }
2162             elsif ($EXTRACTED_DIR
2163                     && $first_released{$addr} ne v0
2164                     && $file !~ /$EXTRACTED/i
2165                     && lc($file) ne 'dage.txt')
2166             {
2167                 # We don't set this (by the 'if' above) if we have no
2168                 # extracted directory, so if running on an early version,
2169                 # this test won't work.  Not worth worrying about.
2170                 $seen_non_extracted_non_age = 1;
2171             }
2172
2173             # And mark the file as having being processed, and warn if it
2174             # isn't a file we are expecting.  As we process the files,
2175             # they are deleted from the hash, so any that remain at the
2176             # end of the program are files that we didn't process.
2177             my $fkey = File::Spec->rel2abs($file);
2178             my $expecting = delete $potential_files{$fkey};
2179             $expecting = delete $potential_files{lc($fkey)} unless defined $expecting;
2180             Carp::my_carp("Was not expecting '$file'.") if
2181                     ! $expecting
2182                     && ! defined $handle{$addr};
2183
2184             # Having deleted from expected files, we can quit if not to do
2185             # anything.  Don't print progress unless really want verbosity
2186             if ($skip{$addr}) {
2187                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2188                 return;
2189             }
2190
2191             # Open the file, converting the slashes used in this program
2192             # into the proper form for the OS
2193             my $file_handle;
2194             if (not open $file_handle, "<", $file) {
2195                 Carp::my_carp("Can't open $file.  Skipping: $!");
2196                 return 0;
2197             }
2198             $handle{$addr} = $file_handle; # Cache the open file handle
2199         }
2200
2201         if ($verbosity >= $PROGRESS) {
2202             if ($progress_message{$addr}) {
2203                 print "$progress_message{$addr}\n";
2204             }
2205             else {
2206                 # If using a virtual file, say so.
2207                 print "Processing ", (-e $file)
2208                                        ? $file
2209                                        : "substitute $file",
2210                                      "\n";
2211             }
2212         }
2213
2214
2215         # Call any special handler for before the file.
2216         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2217
2218         # Then the main handler
2219         &{$handler{$addr}}($self);
2220
2221         # Then any special post-file handler.
2222         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2223
2224         # If any errors have been accumulated, output the counts (as the first
2225         # error message in each class was output when it was encountered).
2226         if ($errors{$addr}) {
2227             my $total = 0;
2228             my $types = 0;
2229             foreach my $error (keys %{$errors{$addr}}) {
2230                 $total += $errors{$addr}->{$error};
2231                 delete $errors{$addr}->{$error};
2232                 $types++;
2233             }
2234             if ($total > 1) {
2235                 my $message
2236                         = "A total of $total lines had errors in $file.  ";
2237
2238                 $message .= ($types == 1)
2239                             ? '(Only the first one was displayed.)'
2240                             : '(Only the first of each type was displayed.)';
2241                 Carp::my_carp($message);
2242             }
2243         }
2244
2245         if (@{$missings{$addr}}) {
2246             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2247         }
2248
2249         # If a real file handle, close it.
2250         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2251                                                         ref $handle{$addr};
2252         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2253                                # the file, as opposed to undef
2254         return;
2255     }
2256
2257     sub next_line {
2258         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2259         # if such a line exists.  'logical' means that any lines that have
2260         # been added via insert_lines() will be returned in $_ before the file
2261         # is read again.
2262
2263         my $self = shift;
2264         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2265
2266         my $addr = do { no overloading; pack 'J', $self; };
2267
2268         # Here the file is open (or if the handle is not a ref, is an open
2269         # 'virtual' file).  Get the next line; any inserted lines get priority
2270         # over the file itself.
2271         my $adjusted;
2272
2273         LINE:
2274         while (1) { # Loop until find non-comment, non-empty line
2275             #local $to_trace = 1 if main::DEBUG;
2276             my $inserted_ref = shift @{$added_lines{$addr}};
2277             if (defined $inserted_ref) {
2278                 ($adjusted, $_) = @{$inserted_ref};
2279                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2280                 return 1 if $adjusted;
2281             }
2282             else {
2283                 last if ! ref $handle{$addr}; # Don't read unless is real file
2284                 last if ! defined ($_ = readline $handle{$addr});
2285             }
2286             chomp;
2287             trace $_ if main::DEBUG && $to_trace;
2288
2289             # See if this line is the comment line that defines what property
2290             # value that code points that are not listed in the file should
2291             # have.  The format or existence of these lines is not guaranteed
2292             # by Unicode since they are comments, but the documentation says
2293             # that this was added for machine-readability, so probably won't
2294             # change.  This works starting in Unicode Version 5.0.  They look
2295             # like:
2296             #
2297             # @missing: 0000..10FFFF; Not_Reordered
2298             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2299             # @missing: 0000..10FFFF; ; NaN
2300             #
2301             # Save the line for a later get_missings() call.
2302             if (/$missing_defaults_prefix/) {
2303                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2304                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2305                 }
2306                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2307                     my @defaults = split /\s* ; \s*/x, $_;
2308
2309                     # The first field is the @missing, which ends in a
2310                     # semi-colon, so can safely shift.
2311                     shift @defaults;
2312
2313                     # Some of these lines may have empty field placeholders
2314                     # which get in the way.  An example is:
2315                     # @missing: 0000..10FFFF; ; NaN
2316                     # Remove them.  Process starting from the top so the
2317                     # splice doesn't affect things still to be looked at.
2318                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2319                         next if $defaults[$i] ne "";
2320                         splice @defaults, $i, 1;
2321                     }
2322
2323                     # What's left should be just the property (maybe) and the
2324                     # default.  Having only one element means it doesn't have
2325                     # the property.
2326                     my $default;
2327                     my $property;
2328                     if (@defaults >= 1) {
2329                         if (@defaults == 1) {
2330                             $default = $defaults[0];
2331                         }
2332                         else {
2333                             $property = $defaults[0];
2334                             $default = $defaults[1];
2335                         }
2336                     }
2337
2338                     if (@defaults < 1
2339                         || @defaults > 2
2340                         || ($default =~ /^</
2341                             && $default !~ /^<code *point>$/i
2342                             && $default !~ /^<none>$/i))
2343                     {
2344                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2345                     }
2346                     else {
2347
2348                         # If the property is missing from the line, it should
2349                         # be the one for the whole file
2350                         $property = $property{$addr} if ! defined $property;
2351
2352                         # Change <none> to the null string, which is what it
2353                         # really means.  If the default is the code point
2354                         # itself, set it to <code point>, which is what
2355                         # Unicode uses (but sometimes they've forgotten the
2356                         # space)
2357                         if ($default =~ /^<none>$/i) {
2358                             $default = "";
2359                         }
2360                         elsif ($default =~ /^<code *point>$/i) {
2361                             $default = $CODE_POINT;
2362                         }
2363
2364                         # Store them as a sub-arrays with both components.
2365                         push @{$missings{$addr}}, [ $default, $property ];
2366                     }
2367                 }
2368
2369                 # There is nothing for the caller to process on this comment
2370                 # line.
2371                 next;
2372             }
2373
2374             # Remove comments and trailing space, and skip this line if the
2375             # result is empty
2376             s/#.*//;
2377             s/\s+$//;
2378             next if /^$/;
2379
2380             # Call any handlers for this line, and skip further processing of
2381             # the line if the handler sets the line to null.
2382             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2383                 &{$sub_ref}($self);
2384                 next LINE if /^$/;
2385             }
2386
2387             # Here the line is ok.  return success.
2388             return 1;
2389         } # End of looping through lines.
2390
2391         # If there is an EOF handler, call it (only once) and if it generates
2392         # more lines to process go back in the loop to handle them.
2393         if ($eof_handler{$addr}) {
2394             &{$eof_handler{$addr}}($self);
2395             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2396             goto LINE if $added_lines{$addr};
2397         }
2398
2399         # Return failure -- no more lines.
2400         return 0;
2401
2402     }
2403
2404 #   Not currently used, not fully tested.
2405 #    sub peek {
2406 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2407 #        # record.  Not callable from an each_line_handler(), nor does it call
2408 #        # an each_line_handler() on the line.
2409 #
2410 #        my $self = shift;
2411 #        my $addr = do { no overloading; pack 'J', $self; };
2412 #
2413 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2414 #            my ($adjusted, $line) = @{$inserted_ref};
2415 #            next if $adjusted;
2416 #
2417 #            # Remove comments and trailing space, and return a non-empty
2418 #            # resulting line
2419 #            $line =~ s/#.*//;
2420 #            $line =~ s/\s+$//;
2421 #            return $line if $line ne "";
2422 #        }
2423 #
2424 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2425 #        while (1) { # Loop until find non-comment, non-empty line
2426 #            local $to_trace = 1 if main::DEBUG;
2427 #            trace $_ if main::DEBUG && $to_trace;
2428 #            return if ! defined (my $line = readline $handle{$addr});
2429 #            chomp $line;
2430 #            push @{$added_lines{$addr}}, [ 0, $line ];
2431 #
2432 #            $line =~ s/#.*//;
2433 #            $line =~ s/\s+$//;
2434 #            return $line if $line ne "";
2435 #        }
2436 #
2437 #        return;
2438 #    }
2439
2440
2441     sub insert_lines {
2442         # Lines can be inserted so that it looks like they were in the input
2443         # file at the place it was when this routine is called.  See also
2444         # insert_adjusted_lines().  Lines inserted via this routine go through
2445         # any each_line_handler()
2446
2447         my $self = shift;
2448
2449         # Each inserted line is an array, with the first element being 0 to
2450         # indicate that this line hasn't been adjusted, and needs to be
2451         # processed.
2452         no overloading;
2453         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2454         return;
2455     }
2456
2457     sub insert_adjusted_lines {
2458         # Lines can be inserted so that it looks like they were in the input
2459         # file at the place it was when this routine is called.  See also
2460         # insert_lines().  Lines inserted via this routine are already fully
2461         # adjusted, ready to be processed; each_line_handler()s handlers will
2462         # not be called.  This means this is not a completely general
2463         # facility, as only the last each_line_handler on the stack should
2464         # call this.  It could be made more general, by passing to each of the
2465         # line_handlers their position on the stack, which they would pass on
2466         # to this routine, and that would replace the boolean first element in
2467         # the anonymous array pushed here, so that the next_line routine could
2468         # use that to call only those handlers whose index is after it on the
2469         # stack.  But this is overkill for what is needed now.
2470
2471         my $self = shift;
2472         trace $_[0] if main::DEBUG && $to_trace;
2473
2474         # Each inserted line is an array, with the first element being 1 to
2475         # indicate that this line has been adjusted
2476         no overloading;
2477         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2478         return;
2479     }
2480
2481     sub get_missings {
2482         # Returns the stored up @missings lines' values, and clears the list.
2483         # The values are in an array, consisting of the default in the first
2484         # element, and the property in the 2nd.  However, since these lines
2485         # can be stacked up, the return is an array of all these arrays.
2486
2487         my $self = shift;
2488         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2489
2490         my $addr = do { no overloading; pack 'J', $self; };
2491
2492         # If not accepting a list return, just return the first one.
2493         return shift @{$missings{$addr}} unless wantarray;
2494
2495         my @return = @{$missings{$addr}};
2496         undef @{$missings{$addr}};
2497         return @return;
2498     }
2499
2500     sub _insert_property_into_line {
2501         # Add a property field to $_, if this file requires it.
2502
2503         my $self = shift;
2504         my $addr = do { no overloading; pack 'J', $self; };
2505         my $property = $property{$addr};
2506         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2507
2508         $_ =~ s/(;|$)/; $property$1/;
2509         return;
2510     }
2511
2512     sub carp_bad_line {
2513         # Output consistent error messages, using either a generic one, or the
2514         # one given by the optional parameter.  To avoid gazillions of the
2515         # same message in case the syntax of a  file is way off, this routine
2516         # only outputs the first instance of each message, incrementing a
2517         # count so the totals can be output at the end of the file.
2518
2519         my $self = shift;
2520         my $message = shift;
2521         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2522
2523         my $addr = do { no overloading; pack 'J', $self; };
2524
2525         $message = 'Unexpected line' unless $message;
2526
2527         # No trailing punctuation so as to fit with our addenda.
2528         $message =~ s/[.:;,]$//;
2529
2530         # If haven't seen this exact message before, output it now.  Otherwise
2531         # increment the count of how many times it has occurred
2532         unless ($errors{$addr}->{$message}) {
2533             Carp::my_carp("$message in '$_' in "
2534                             . $file{$addr}
2535                             . " at line $..  Skipping this line;");
2536             $errors{$addr}->{$message} = 1;
2537         }
2538         else {
2539             $errors{$addr}->{$message}++;
2540         }
2541
2542         # Clear the line to prevent any further (meaningful) processing of it.
2543         $_ = "";
2544
2545         return;
2546     }
2547 } # End closure
2548
2549 package Multi_Default;
2550
2551 # Certain properties in early versions of Unicode had more than one possible
2552 # default for code points missing from the files.  In these cases, one
2553 # default applies to everything left over after all the others are applied,
2554 # and for each of the others, there is a description of which class of code
2555 # points applies to it.  This object helps implement this by storing the
2556 # defaults, and for all but that final default, an eval string that generates
2557 # the class that it applies to.
2558
2559
2560 {   # Closure
2561
2562     main::setup_package();
2563
2564     my %class_defaults;
2565     # The defaults structure for the classes
2566     main::set_access('class_defaults', \%class_defaults);
2567
2568     my %other_default;
2569     # The default that applies to everything left over.
2570     main::set_access('other_default', \%other_default, 'r');
2571
2572
2573     sub new {
2574         # The constructor is called with default => eval pairs, terminated by
2575         # the left-over default. e.g.
2576         # Multi_Default->new(
2577         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2578         #               -  0x200D',
2579         #        'R' => 'some other expression that evaluates to code points',
2580         #        .
2581         #        .
2582         #        .
2583         #        'U'));
2584
2585         my $class = shift;
2586
2587         my $self = bless \do{my $anonymous_scalar}, $class;
2588         my $addr = do { no overloading; pack 'J', $self; };
2589
2590         while (@_ > 1) {
2591             my $default = shift;
2592             my $eval = shift;
2593             $class_defaults{$addr}->{$default} = $eval;
2594         }
2595
2596         $other_default{$addr} = shift;
2597
2598         return $self;
2599     }
2600
2601     sub get_next_defaults {
2602         # Iterates and returns the next class of defaults.
2603         my $self = shift;
2604         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2605
2606         my $addr = do { no overloading; pack 'J', $self; };
2607
2608         return each %{$class_defaults{$addr}};
2609     }
2610 }
2611
2612 package Alias;
2613
2614 # An alias is one of the names that a table goes by.  This class defines them
2615 # including some attributes.  Everything is currently setup in the
2616 # constructor.
2617
2618
2619 {   # Closure
2620
2621     main::setup_package();
2622
2623     my %name;
2624     main::set_access('name', \%name, 'r');
2625
2626     my %loose_match;
2627     # Determined by the constructor code if this name should match loosely or
2628     # not.  The constructor parameters can override this, but it isn't fully
2629     # implemented, as should have ability to override Unicode one's via
2630     # something like a set_loose_match()
2631     main::set_access('loose_match', \%loose_match, 'r');
2632
2633     my %make_pod_entry;
2634     # Some aliases should not get their own entries because they are covered
2635     # by a wild-card, and some we want to discourage use of.  Binary
2636     main::set_access('make_pod_entry', \%make_pod_entry, 'r');
2637
2638     my %status;
2639     # Aliases have a status, like deprecated, or even suppressed (which means
2640     # they don't appear in documentation).  Enum
2641     main::set_access('status', \%status, 'r');
2642
2643     my %externally_ok;
2644     # Similarly, some aliases should not be considered as usable ones for
2645     # external use, such as file names, or we don't want documentation to
2646     # recommend them.  Boolean
2647     main::set_access('externally_ok', \%externally_ok, 'r');
2648
2649     sub new {
2650         my $class = shift;
2651
2652         my $self = bless \do { my $anonymous_scalar }, $class;
2653         my $addr = do { no overloading; pack 'J', $self; };
2654
2655         $name{$addr} = shift;
2656         $loose_match{$addr} = shift;
2657         $make_pod_entry{$addr} = shift;
2658         $externally_ok{$addr} = shift;
2659         $status{$addr} = shift;
2660
2661         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2662
2663         # Null names are never ok externally
2664         $externally_ok{$addr} = 0 if $name{$addr} eq "";
2665
2666         return $self;
2667     }
2668 }
2669
2670 package Range;
2671
2672 # A range is the basic unit for storing code points, and is described in the
2673 # comments at the beginning of the program.  Each range has a starting code
2674 # point; an ending code point (not less than the starting one); a value
2675 # that applies to every code point in between the two end-points, inclusive;
2676 # and an enum type that applies to the value.  The type is for the user's
2677 # convenience, and has no meaning here, except that a non-zero type is
2678 # considered to not obey the normal Unicode rules for having standard forms.
2679 #
2680 # The same structure is used for both map and match tables, even though in the
2681 # latter, the value (and hence type) is irrelevant and could be used as a
2682 # comment.  In map tables, the value is what all the code points in the range
2683 # map to.  Type 0 values have the standardized version of the value stored as
2684 # well, so as to not have to recalculate it a lot.
2685
2686 sub trace { return main::trace(@_); }
2687
2688 {   # Closure
2689
2690     main::setup_package();
2691
2692     my %start;
2693     main::set_access('start', \%start, 'r', 's');
2694
2695     my %end;
2696     main::set_access('end', \%end, 'r', 's');
2697
2698     my %value;
2699     main::set_access('value', \%value, 'r');
2700
2701     my %type;
2702     main::set_access('type', \%type, 'r');
2703
2704     my %standard_form;
2705     # The value in internal standard form.  Defined only if the type is 0.
2706     main::set_access('standard_form', \%standard_form);
2707
2708     # Note that if these fields change, the dump() method should as well
2709
2710     sub new {
2711         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2712         my $class = shift;
2713
2714         my $self = bless \do { my $anonymous_scalar }, $class;
2715         my $addr = do { no overloading; pack 'J', $self; };
2716
2717         $start{$addr} = shift;
2718         $end{$addr} = shift;
2719
2720         my %args = @_;
2721
2722         my $value = delete $args{'Value'};  # Can be 0
2723         $value = "" unless defined $value;
2724         $value{$addr} = $value;
2725
2726         $type{$addr} = delete $args{'Type'} || 0;
2727
2728         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2729
2730         if (! $type{$addr}) {
2731             $standard_form{$addr} = main::standardize($value);
2732         }
2733
2734         return $self;
2735     }
2736
2737     use overload
2738         fallback => 0,
2739         qw("") => "_operator_stringify",
2740         "." => \&main::_operator_dot,
2741     ;
2742
2743     sub _operator_stringify {
2744         my $self = shift;
2745         my $addr = do { no overloading; pack 'J', $self; };
2746
2747         # Output it like '0041..0065 (value)'
2748         my $return = sprintf("%04X", $start{$addr})
2749                         .  '..'
2750                         . sprintf("%04X", $end{$addr});
2751         my $value = $value{$addr};
2752         my $type = $type{$addr};
2753         $return .= ' (';
2754         $return .= "$value";
2755         $return .= ", Type=$type" if $type != 0;
2756         $return .= ')';
2757
2758         return $return;
2759     }
2760
2761     sub standard_form {
2762         # The standard form is the value itself if the standard form is
2763         # undefined (that is if the value is special)
2764
2765         my $self = shift;
2766         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2767
2768         my $addr = do { no overloading; pack 'J', $self; };
2769
2770         return $standard_form{$addr} if defined $standard_form{$addr};
2771         return $value{$addr};
2772     }
2773
2774     sub dump {
2775         # Human, not machine readable.  For machine readable, comment out this
2776         # entire routine and let the standard one take effect.
2777         my $self = shift;
2778         my $indent = shift;
2779         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2780
2781         my $addr = do { no overloading; pack 'J', $self; };
2782
2783         my $return = $indent
2784                     . sprintf("%04X", $start{$addr})
2785                     . '..'
2786                     . sprintf("%04X", $end{$addr})
2787                     . " '$value{$addr}';";
2788         if (! defined $standard_form{$addr}) {
2789             $return .= "(type=$type{$addr})";
2790         }
2791         elsif ($standard_form{$addr} ne $value{$addr}) {
2792             $return .= "(standard '$standard_form{$addr}')";
2793         }
2794         return $return;
2795     }
2796 } # End closure
2797
2798 package _Range_List_Base;
2799
2800 # Base class for range lists.  A range list is simply an ordered list of
2801 # ranges, so that the ranges with the lowest starting numbers are first in it.
2802 #
2803 # When a new range is added that is adjacent to an existing range that has the
2804 # same value and type, it merges with it to form a larger range.
2805 #
2806 # Ranges generally do not overlap, except that there can be multiple entries
2807 # of single code point ranges.  This is because of NameAliases.txt.
2808 #
2809 # In this program, there is a standard value such that if two different
2810 # values, have the same standard value, they are considered equivalent.  This
2811 # value was chosen so that it gives correct results on Unicode data
2812
2813 # There are a number of methods to manipulate range lists, and some operators
2814 # are overloaded to handle them.
2815
2816 sub trace { return main::trace(@_); }
2817
2818 { # Closure
2819
2820     our $addr;
2821
2822     main::setup_package();
2823
2824     my %ranges;
2825     # The list of ranges
2826     main::set_access('ranges', \%ranges, 'readable_array');
2827
2828     my %max;
2829     # The highest code point in the list.  This was originally a method, but
2830     # actual measurements said it was used a lot.
2831     main::set_access('max', \%max, 'r');
2832
2833     my %each_range_iterator;
2834     # Iterator position for each_range()
2835     main::set_access('each_range_iterator', \%each_range_iterator);
2836
2837     my %owner_name_of;
2838     # Name of parent this is attached to, if any.  Solely for better error
2839     # messages.
2840     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2841
2842     my %_search_ranges_cache;
2843     # A cache of the previous result from _search_ranges(), for better
2844     # performance
2845     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2846
2847     sub new {
2848         my $class = shift;
2849         my %args = @_;
2850
2851         # Optional initialization data for the range list.
2852         my $initialize = delete $args{'Initialize'};
2853
2854         my $self;
2855
2856         # Use _union() to initialize.  _union() returns an object of this
2857         # class, which means that it will call this constructor recursively.
2858         # But it won't have this $initialize parameter so that it won't
2859         # infinitely loop on this.
2860         return _union($class, $initialize, %args) if defined $initialize;
2861
2862         $self = bless \do { my $anonymous_scalar }, $class;
2863         my $addr = do { no overloading; pack 'J', $self; };
2864
2865         # Optional parent object, only for debug info.
2866         $owner_name_of{$addr} = delete $args{'Owner'};
2867         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2868
2869         # Stringify, in case it is an object.
2870         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2871
2872         # This is used only for error messages, and so a colon is added
2873         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2874
2875         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2876
2877         # Max is initialized to a negative value that isn't adjacent to 0,
2878         # for simpler tests
2879         $max{$addr} = -2;
2880
2881         $_search_ranges_cache{$addr} = 0;
2882         $ranges{$addr} = [];
2883
2884         return $self;
2885     }
2886
2887     use overload
2888         fallback => 0,
2889         qw("") => "_operator_stringify",
2890         "." => \&main::_operator_dot,
2891     ;
2892
2893     sub _operator_stringify {
2894         my $self = shift;
2895         my $addr = do { no overloading; pack 'J', $self; };
2896
2897         return "Range_List attached to '$owner_name_of{$addr}'"
2898                                                 if $owner_name_of{$addr};
2899         return "anonymous Range_List " . \$self;
2900     }
2901
2902     sub _union {
2903         # Returns the union of the input code points.  It can be called as
2904         # either a constructor or a method.  If called as a method, the result
2905         # will be a new() instance of the calling object, containing the union
2906         # of that object with the other parameter's code points;  if called as
2907         # a constructor, the first parameter gives the class the new object
2908         # should be, and the second parameter gives the code points to go into
2909         # it.
2910         # In either case, there are two parameters looked at by this routine;
2911         # any additional parameters are passed to the new() constructor.
2912         #
2913         # The code points can come in the form of some object that contains
2914         # ranges, and has a conventionally named method to access them; or
2915         # they can be an array of individual code points (as integers); or
2916         # just a single code point.
2917         #
2918         # If they are ranges, this routine doesn't make any effort to preserve
2919         # the range values of one input over the other.  Therefore this base
2920         # class should not allow _union to be called from other than
2921         # initialization code, so as to prevent two tables from being added
2922         # together where the range values matter.  The general form of this
2923         # routine therefore belongs in a derived class, but it was moved here
2924         # to avoid duplication of code.  The failure to overload this in this
2925         # class keeps it safe.
2926         #
2927
2928         my $self;
2929         my @args;   # Arguments to pass to the constructor
2930
2931         my $class = shift;
2932
2933         # If a method call, will start the union with the object itself, and
2934         # the class of the new object will be the same as self.
2935         if (ref $class) {
2936             $self = $class;
2937             $class = ref $self;
2938             push @args, $self;
2939         }
2940
2941         # Add the other required parameter.
2942         push @args, shift;
2943         # Rest of parameters are passed on to the constructor
2944
2945         # Accumulate all records from both lists.
2946         my @records;
2947         for my $arg (@args) {
2948             #local $to_trace = 0 if main::DEBUG;
2949             trace "argument = $arg" if main::DEBUG && $to_trace;
2950             if (! defined $arg) {
2951                 my $message = "";
2952                 if (defined $self) {
2953                     no overloading;
2954                     $message .= $owner_name_of{pack 'J', $self};
2955                 }
2956                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
2957                 return;
2958             }
2959             $arg = [ $arg ] if ! ref $arg;
2960             my $type = ref $arg;
2961             if ($type eq 'ARRAY') {
2962                 foreach my $element (@$arg) {
2963                     push @records, Range->new($element, $element);
2964                 }
2965             }
2966             elsif ($arg->isa('Range')) {
2967                 push @records, $arg;
2968             }
2969             elsif ($arg->can('ranges')) {
2970                 push @records, $arg->ranges;
2971             }
2972             else {
2973                 my $message = "";
2974                 if (defined $self) {
2975                     no overloading;
2976                     $message .= $owner_name_of{pack 'J', $self};
2977                 }
2978                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
2979                 return;
2980             }
2981         }
2982
2983         # Sort with the range containing the lowest ordinal first, but if
2984         # two ranges start at the same code point, sort with the bigger range
2985         # of the two first, because it takes fewer cycles.
2986         @records = sort { ($a->start <=> $b->start)
2987                                       or
2988                                     # if b is shorter than a, b->end will be
2989                                     # less than a->end, and we want to select
2990                                     # a, so want to return -1
2991                                     ($b->end <=> $a->end)
2992                                    } @records;
2993
2994         my $new = $class->new(@_);
2995
2996         # Fold in records so long as they add new information.
2997         for my $set (@records) {
2998             my $start = $set->start;
2999             my $end   = $set->end;
3000             my $value   = $set->value;
3001             if ($start > $new->max) {
3002                 $new->_add_delete('+', $start, $end, $value);
3003             }
3004             elsif ($end > $new->max) {
3005                 $new->_add_delete('+', $new->max +1, $end, $value);
3006             }
3007         }
3008
3009         return $new;
3010     }
3011
3012     sub range_count {        # Return the number of ranges in the range list
3013         my $self = shift;
3014         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3015
3016         no overloading;
3017         return scalar @{$ranges{pack 'J', $self}};
3018     }
3019
3020     sub min {
3021         # Returns the minimum code point currently in the range list, or if
3022         # the range list is empty, 2 beyond the max possible.  This is a
3023         # method because used so rarely, that not worth saving between calls,
3024         # and having to worry about changing it as ranges are added and
3025         # deleted.
3026
3027         my $self = shift;
3028         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3029
3030         my $addr = do { no overloading; pack 'J', $self; };
3031
3032         # If the range list is empty, return a large value that isn't adjacent
3033         # to any that could be in the range list, for simpler tests
3034         return $LAST_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3035         return $ranges{$addr}->[0]->start;
3036     }
3037
3038     sub contains {
3039         # Boolean: Is argument in the range list?  If so returns $i such that:
3040         #   range[$i]->end < $codepoint <= range[$i+1]->end
3041         # which is one beyond what you want; this is so that the 0th range
3042         # doesn't return false
3043         my $self = shift;
3044         my $codepoint = shift;
3045         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3046
3047         my $i = $self->_search_ranges($codepoint);
3048         return 0 unless defined $i;
3049
3050         # The search returns $i, such that
3051         #   range[$i-1]->end < $codepoint <= range[$i]->end
3052         # So is in the table if and only iff it is at least the start position
3053         # of range $i.
3054         no overloading;
3055         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3056         return $i + 1;
3057     }
3058
3059     sub containing_range {
3060         # Returns the range object that contains the code point, undef if none
3061
3062         my $self = shift;
3063         my $codepoint = shift;
3064         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3065
3066         my $i = $self->contains($codepoint);
3067         return unless $i;
3068
3069         # contains() returns 1 beyond where we should look
3070         no overloading;
3071         return $ranges{pack 'J', $self}->[$i-1];
3072     }
3073
3074     sub value_of {
3075         # Returns the value associated with the code point, undef if none
3076
3077         my $self = shift;
3078         my $codepoint = shift;
3079         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3080
3081         my $range = $self->containing_range($codepoint);
3082         return unless defined $range;
3083
3084         return $range->value;
3085     }
3086
3087     sub type_of {
3088         # Returns the type of the range containing the code point, undef if
3089         # the code point is not in the table
3090
3091         my $self = shift;
3092         my $codepoint = shift;
3093         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3094
3095         my $range = $self->containing_range($codepoint);
3096         return unless defined $range;
3097
3098         return $range->type;
3099     }
3100
3101     sub _search_ranges {
3102         # Find the range in the list which contains a code point, or where it
3103         # should go if were to add it.  That is, it returns $i, such that:
3104         #   range[$i-1]->end < $codepoint <= range[$i]->end
3105         # Returns undef if no such $i is possible (e.g. at end of table), or
3106         # if there is an error.
3107
3108         my $self = shift;
3109         my $code_point = shift;
3110         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3111
3112         my $addr = do { no overloading; pack 'J', $self; };
3113
3114         return if $code_point > $max{$addr};
3115         my $r = $ranges{$addr};                # The current list of ranges
3116         my $range_list_size = scalar @$r;
3117         my $i;
3118
3119         use integer;        # want integer division
3120
3121         # Use the cached result as the starting guess for this one, because,
3122         # an experiment on 5.1 showed that 90% of the time the cache was the
3123         # same as the result on the next call (and 7% it was one less).
3124         $i = $_search_ranges_cache{$addr};
3125         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3126                                             # from an intervening deletion
3127         #local $to_trace = 1 if main::DEBUG;
3128         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3129         return $i if $code_point <= $r->[$i]->end
3130                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3131
3132         # Here the cache doesn't yield the correct $i.  Try adding 1.
3133         if ($i < $range_list_size - 1
3134             && $r->[$i]->end < $code_point &&
3135             $code_point <= $r->[$i+1]->end)
3136         {
3137             $i++;
3138             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3139             $_search_ranges_cache{$addr} = $i;
3140             return $i;
3141         }
3142
3143         # Here, adding 1 also didn't work.  We do a binary search to
3144         # find the correct position, starting with current $i
3145         my $lower = 0;
3146         my $upper = $range_list_size - 1;
3147         while (1) {
3148             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3149
3150             if ($code_point <= $r->[$i]->end) {
3151
3152                 # Here we have met the upper constraint.  We can quit if we
3153                 # also meet the lower one.
3154                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3155
3156                 $upper = $i;        # Still too high.
3157
3158             }
3159             else {
3160
3161                 # Here, $r[$i]->end < $code_point, so look higher up.
3162                 $lower = $i;
3163             }
3164
3165             # Split search domain in half to try again.
3166             my $temp = ($upper + $lower) / 2;
3167
3168             # No point in continuing unless $i changes for next time
3169             # in the loop.
3170             if ($temp == $i) {
3171
3172                 # We can't reach the highest element because of the averaging.
3173                 # So if one below the upper edge, force it there and try one
3174                 # more time.
3175                 if ($i == $range_list_size - 2) {
3176
3177                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3178                     $i = $range_list_size - 1;
3179
3180                     # Change $lower as well so if fails next time through,
3181                     # taking the average will yield the same $i, and we will
3182                     # quit with the error message just below.
3183                     $lower = $i;
3184                     next;
3185                 }
3186                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3187                 return;
3188             }
3189             $i = $temp;
3190         } # End of while loop
3191
3192         if (main::DEBUG && $to_trace) {
3193             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3194             trace "i=  [ $i ]", $r->[$i];
3195             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3196         }
3197
3198         # Here we have found the offset.  Cache it as a starting point for the
3199         # next call.
3200         $_search_ranges_cache{$addr} = $i;
3201         return $i;
3202     }
3203
3204     sub _add_delete {
3205         # Add, replace or delete ranges to or from a list.  The $type
3206         # parameter gives which:
3207         #   '+' => insert or replace a range, returning a list of any changed
3208         #          ranges.
3209         #   '-' => delete a range, returning a list of any deleted ranges.
3210         #
3211         # The next three parameters give respectively the start, end, and
3212         # value associated with the range.  'value' should be null unless the
3213         # operation is '+';
3214         #
3215         # The range list is kept sorted so that the range with the lowest
3216         # starting position is first in the list, and generally, adjacent
3217         # ranges with the same values are merged into a single larger one (see
3218         # exceptions below).
3219         #
3220         # There are more parameters; all are key => value pairs:
3221         #   Type    gives the type of the value.  It is only valid for '+'.
3222         #           All ranges have types; if this parameter is omitted, 0 is
3223         #           assumed.  Ranges with type 0 are assumed to obey the
3224         #           Unicode rules for casing, etc; ranges with other types are
3225         #           not.  Otherwise, the type is arbitrary, for the caller's
3226         #           convenience, and looked at only by this routine to keep
3227         #           adjacent ranges of different types from being merged into
3228         #           a single larger range, and when Replace =>
3229         #           $IF_NOT_EQUIVALENT is specified (see just below).
3230         #   Replace  determines what to do if the range list already contains
3231         #            ranges which coincide with all or portions of the input
3232         #            range.  It is only valid for '+':
3233         #       => $NO            means that the new value is not to replace
3234         #                         any existing ones, but any empty gaps of the
3235         #                         range list coinciding with the input range
3236         #                         will be filled in with the new value.
3237         #       => $UNCONDITIONALLY  means to replace the existing values with
3238         #                         this one unconditionally.  However, if the
3239         #                         new and old values are identical, the
3240         #                         replacement is skipped to save cycles
3241         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3242         #                         with this one if they are not equivalent.
3243         #                         Ranges are equivalent if their types are the
3244         #                         same, and they are the same string; or if
3245         #                         both are type 0 ranges, if their Unicode
3246         #                         standard forms are identical.  In this last
3247         #                         case, the routine chooses the more "modern"
3248         #                         one to use.  This is because some of the
3249         #                         older files are formatted with values that
3250         #                         are, for example, ALL CAPs, whereas the
3251         #                         derived files have a more modern style,
3252         #                         which looks better.  By looking for this
3253         #                         style when the pre-existing and replacement
3254         #                         standard forms are the same, we can move to
3255         #                         the modern style
3256         #       => $MULTIPLE      means that if this range duplicates an
3257         #                         existing one, but has a different value,
3258         #                         don't replace the existing one, but insert
3259         #                         this, one so that the same range can occur
3260         #                         multiple times.  They are stored LIFO, so
3261         #                         that the final one inserted is the first one
3262         #                         returned in an ordered search of the table.
3263         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3264         #
3265         # "same value" means identical for non-type-0 ranges, and it means
3266         # having the same standard forms for type-0 ranges.
3267
3268         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3269
3270         my $self = shift;
3271         my $operation = shift;   # '+' for add/replace; '-' for delete;
3272         my $start = shift;
3273         my $end   = shift;
3274         my $value = shift;
3275
3276         my %args = @_;
3277
3278         $value = "" if not defined $value;        # warning: $value can be "0"
3279
3280         my $replace = delete $args{'Replace'};
3281         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3282
3283         my $type = delete $args{'Type'};
3284         $type = 0 unless defined $type;
3285
3286         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3287
3288         my $addr = do { no overloading; pack 'J', $self; };
3289
3290         if ($operation ne '+' && $operation ne '-') {
3291             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3292             return;
3293         }
3294         unless (defined $start && defined $end) {
3295             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3296             return;
3297         }
3298         unless ($end >= $start) {
3299             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3300             return;
3301         }
3302         #local $to_trace = 1 if main::DEBUG;
3303
3304         if ($operation eq '-') {
3305             if ($replace != $IF_NOT_EQUIVALENT) {
3306                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3307                 $replace = $IF_NOT_EQUIVALENT;
3308             }
3309             if ($type) {
3310                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3311                 $type = 0;
3312             }
3313             if ($value ne "") {
3314                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3315                 $value = "";
3316             }
3317         }
3318
3319         my $r = $ranges{$addr};               # The current list of ranges
3320         my $range_list_size = scalar @$r;     # And its size
3321         my $max = $max{$addr};                # The current high code point in
3322                                               # the list of ranges
3323
3324         # Do a special case requiring fewer machine cycles when the new range
3325         # starts after the current highest point.  The Unicode input data is
3326         # structured so this is common.
3327         if ($start > $max) {
3328
3329             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3330             return if $operation eq '-'; # Deleting a non-existing range is a
3331                                          # no-op
3332
3333             # If the new range doesn't logically extend the current final one
3334             # in the range list, create a new range at the end of the range
3335             # list.  (max cleverly is initialized to a negative number not
3336             # adjacent to 0 if the range list is empty, so even adding a range
3337             # to an empty range list starting at 0 will have this 'if'
3338             # succeed.)
3339             if ($start > $max + 1        # non-adjacent means can't extend.
3340                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3341                 || @{$r}[-1]->type != $type # types differ, can't extend.
3342             ) {
3343                 push @$r, Range->new($start, $end,
3344                                      Value => $value,
3345                                      Type => $type);
3346             }
3347             else {
3348
3349                 # Here, the new range starts just after the current highest in
3350                 # the range list, and they have the same type and value.
3351                 # Extend the current range to incorporate the new one.
3352                 @{$r}[-1]->set_end($end);
3353             }
3354
3355             # This becomes the new maximum.
3356             $max{$addr} = $end;
3357
3358             return;
3359         }
3360         #local $to_trace = 0 if main::DEBUG;
3361
3362         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3363
3364         # Here, the input range isn't after the whole rest of the range list.
3365         # Most likely 'splice' will be needed.  The rest of the routine finds
3366         # the needed splice parameters, and if necessary, does the splice.
3367         # First, find the offset parameter needed by the splice function for
3368         # the input range.  Note that the input range may span multiple
3369         # existing ones, but we'll worry about that later.  For now, just find
3370         # the beginning.  If the input range is to be inserted starting in a
3371         # position not currently in the range list, it must (obviously) come
3372         # just after the range below it, and just before the range above it.
3373         # Slightly less obviously, it will occupy the position currently
3374         # occupied by the range that is to come after it.  More formally, we
3375         # are looking for the position, $i, in the array of ranges, such that:
3376         #
3377         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3378         #
3379         # (The ordered relationships within existing ranges are also shown in
3380         # the equation above).  However, if the start of the input range is
3381         # within an existing range, the splice offset should point to that
3382         # existing range's position in the list; that is $i satisfies a
3383         # somewhat different equation, namely:
3384         #
3385         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3386         #
3387         # More briefly, $start can come before or after r[$i]->start, and at
3388         # this point, we don't know which it will be.  However, these
3389         # two equations share these constraints:
3390         #
3391         #   r[$i-1]->end < $start <= r[$i]->end
3392         #
3393         # And that is good enough to find $i.
3394
3395         my $i = $self->_search_ranges($start);
3396         if (! defined $i) {
3397             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3398             return;
3399         }
3400
3401         # The search function returns $i such that:
3402         #
3403         # r[$i-1]->end < $start <= r[$i]->end
3404         #
3405         # That means that $i points to the first range in the range list
3406         # that could possibly be affected by this operation.  We still don't
3407         # know if the start of the input range is within r[$i], or if it
3408         # points to empty space between r[$i-1] and r[$i].
3409         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3410
3411         # Special case the insertion of data that is not to replace any
3412         # existing data.
3413         if ($replace == $NO) {  # If $NO, has to be operation '+'
3414             #local $to_trace = 1 if main::DEBUG;
3415             trace "Doesn't replace" if main::DEBUG && $to_trace;
3416
3417             # Here, the new range is to take effect only on those code points
3418             # that aren't already in an existing range.  This can be done by
3419             # looking through the existing range list and finding the gaps in
3420             # the ranges that this new range affects, and then calling this
3421             # function recursively on each of those gaps, leaving untouched
3422             # anything already in the list.  Gather up a list of the changed
3423             # gaps first so that changes to the internal state as new ranges
3424             # are added won't be a problem.
3425             my @gap_list;
3426
3427             # First, if the starting point of the input range is outside an
3428             # existing one, there is a gap from there to the beginning of the
3429             # existing range -- add a span to fill the part that this new
3430             # range occupies
3431             if ($start < $r->[$i]->start) {
3432                 push @gap_list, Range->new($start,
3433                                            main::min($end,
3434                                                      $r->[$i]->start - 1),
3435                                            Type => $type);
3436                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3437             }
3438
3439             # Then look through the range list for other gaps until we reach
3440             # the highest range affected by the input one.
3441             my $j;
3442             for ($j = $i+1; $j < $range_list_size; $j++) {
3443                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3444                 last if $end < $r->[$j]->start;
3445
3446                 # If there is a gap between when this range starts and the
3447                 # previous one ends, add a span to fill it.  Note that just
3448                 # because there are two ranges doesn't mean there is a
3449                 # non-zero gap between them.  It could be that they have
3450                 # different values or types
3451                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3452                     push @gap_list,
3453                         Range->new($r->[$j-1]->end + 1,
3454                                    $r->[$j]->start - 1,
3455                                    Type => $type);
3456                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3457                 }
3458             }
3459
3460             # Here, we have either found an existing range in the range list,
3461             # beyond the area affected by the input one, or we fell off the
3462             # end of the loop because the input range affects the whole rest
3463             # of the range list.  In either case, $j is 1 higher than the
3464             # highest affected range.  If $j == $i, it means that there are no
3465             # affected ranges, that the entire insertion is in the gap between
3466             # r[$i-1], and r[$i], which we already have taken care of before
3467             # the loop.
3468             # On the other hand, if there are affected ranges, it might be
3469             # that there is a gap that needs filling after the final such
3470             # range to the end of the input range
3471             if ($r->[$j-1]->end < $end) {
3472                     push @gap_list, Range->new(main::max($start,
3473                                                          $r->[$j-1]->end + 1),
3474                                                $end,
3475                                                Type => $type);
3476                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3477             }
3478
3479             # Call recursively to fill in all the gaps.
3480             foreach my $gap (@gap_list) {
3481                 $self->_add_delete($operation,
3482                                    $gap->start,
3483                                    $gap->end,
3484                                    $value,
3485                                    Type => $type);
3486             }
3487
3488             return;
3489         }
3490
3491         # Here, we have taken care of the case where $replace is $NO.
3492         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3493         # If inserting a multiple record, this is where it goes, before the
3494         # first (if any) existing one.  This implies an insertion, and no
3495         # change to any existing ranges.  Note that $i can be -1 if this new
3496         # range doesn't actually duplicate any existing, and comes at the
3497         # beginning of the list.
3498         if ($replace == $MULTIPLE) {
3499
3500             if ($start != $end) {
3501                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3502                 return;
3503             }
3504
3505             # Don't add an exact duplicate, as it isn't really a multiple
3506             if ($end >= $r->[$i]->start) {
3507                 if ($r->[$i]->start != $r->[$i]->end) {
3508                     Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the other range ($r->[$i]) contains more than one code point.  No action taken.");
3509                     return;
3510                 }
3511                 return if $value eq $r->[$i]->value && $type eq $r->[$i]->type;
3512             }
3513
3514             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3515             my @return = splice @$r,
3516                                 $i,
3517                                 0,
3518                                 Range->new($start,
3519                                            $end,
3520                                            Value => $value,
3521                                            Type => $type);
3522             if (main::DEBUG && $to_trace) {
3523                 trace "After splice:";
3524                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3525                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3526                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3527                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3528                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3529                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3530             }
3531             return @return;
3532         }
3533
3534         # Here, we have taken care of $NO and $MULTIPLE replaces.  This leaves
3535         # delete, insert, and replace either unconditionally or if not
3536         # equivalent.  $i still points to the first potential affected range.
3537         # Now find the highest range affected, which will determine the length
3538         # parameter to splice.  (The input range can span multiple existing
3539         # ones.)  If this isn't a deletion, while we are looking through the
3540         # range list, see also if this is a replacement rather than a clean
3541         # insertion; that is if it will change the values of at least one
3542         # existing range.  Start off assuming it is an insert, until find it
3543         # isn't.
3544         my $clean_insert = $operation eq '+';
3545         my $j;        # This will point to the highest affected range
3546
3547         # For non-zero types, the standard form is the value itself;
3548         my $standard_form = ($type) ? $value : main::standardize($value);
3549
3550         for ($j = $i; $j < $range_list_size; $j++) {
3551             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3552
3553             # If find a range that it doesn't overlap into, we can stop
3554             # searching
3555             last if $end < $r->[$j]->start;
3556
3557             # Here, overlaps the range at $j.  If the values don't match,
3558             # and so far we think this is a clean insertion, it becomes a
3559             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3560             if ($clean_insert) {
3561                 if ($r->[$j]->standard_form ne $standard_form) {
3562                     $clean_insert = 0;
3563                     if ($replace == $CROAK) {
3564                         main::croak("The range to add "
3565                         . sprintf("%04X", $start)
3566                         . '-'
3567                         . sprintf("%04X", $end)
3568                         . " with value '$value' overlaps an existing range $r->[$j]");
3569                     }
3570                 }
3571                 else {
3572
3573                     # Here, the two values are essentially the same.  If the
3574                     # two are actually identical, replacing wouldn't change
3575                     # anything so skip it.
3576                     my $pre_existing = $r->[$j]->value;
3577                     if ($pre_existing ne $value) {
3578
3579                         # Here the new and old standardized values are the
3580                         # same, but the non-standardized values aren't.  If
3581                         # replacing unconditionally, then replace
3582                         if( $replace == $UNCONDITIONALLY) {
3583                             $clean_insert = 0;
3584                         }
3585                         else {
3586
3587                             # Here, are replacing conditionally.  Decide to
3588                             # replace or not based on which appears to look
3589                             # the "nicest".  If one is mixed case and the
3590                             # other isn't, choose the mixed case one.
3591                             my $new_mixed = $value =~ /[A-Z]/
3592                                             && $value =~ /[a-z]/;
3593                             my $old_mixed = $pre_existing =~ /[A-Z]/
3594                                             && $pre_existing =~ /[a-z]/;
3595
3596                             if ($old_mixed != $new_mixed) {
3597                                 $clean_insert = 0 if $new_mixed;
3598                                 if (main::DEBUG && $to_trace) {
3599                                     if ($clean_insert) {
3600                                         trace "Retaining $pre_existing over $value";
3601                                     }
3602                                     else {
3603                                         trace "Replacing $pre_existing with $value";
3604                                     }
3605                                 }
3606                             }
3607                             else {
3608
3609                                 # Here casing wasn't different between the two.
3610                                 # If one has hyphens or underscores and the
3611                                 # other doesn't, choose the one with the
3612                                 # punctuation.
3613                                 my $new_punct = $value =~ /[-_]/;
3614                                 my $old_punct = $pre_existing =~ /[-_]/;
3615
3616                                 if ($old_punct != $new_punct) {
3617                                     $clean_insert = 0 if $new_punct;
3618                                     if (main::DEBUG && $to_trace) {
3619                                         if ($clean_insert) {
3620                                             trace "Retaining $pre_existing over $value";
3621                                         }
3622                                         else {
3623                                             trace "Replacing $pre_existing with $value";
3624                                         }
3625                                     }
3626                                 }   # else existing one is just as "good";
3627                                     # retain it to save cycles.
3628                             }
3629                         }
3630                     }
3631                 }
3632             }
3633         } # End of loop looking for highest affected range.
3634
3635         # Here, $j points to one beyond the highest range that this insertion
3636         # affects (hence to beyond the range list if that range is the final
3637         # one in the range list).
3638
3639         # The splice length is all the affected ranges.  Get it before
3640         # subtracting, for efficiency, so we don't have to later add 1.
3641         my $length = $j - $i;
3642
3643         $j--;        # $j now points to the highest affected range.
3644         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3645
3646         # Here, have taken care of $NO and $MULTIPLE replaces.
3647         # $j points to the highest affected range.  But it can be < $i or even
3648         # -1.  These happen only if the insertion is entirely in the gap
3649         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3650         # above exited first time through with $end < $r->[$i]->start.  (And
3651         # then we subtracted one from j)  This implies also that $start <
3652         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3653         # $start, so the entire input range is in the gap.
3654         if ($j < $i) {
3655
3656             # Here the entire input range is in the gap before $i.
3657
3658             if (main::DEBUG && $to_trace) {
3659                 if ($i) {
3660                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3661                 }
3662                 else {
3663                     trace "Entire range is before $r->[$i]";
3664                 }
3665             }
3666             return if $operation ne '+'; # Deletion of a non-existent range is
3667                                          # a no-op
3668         }
3669         else {
3670
3671             # Here part of the input range is not in the gap before $i.  Thus,
3672             # there is at least one affected one, and $j points to the highest
3673             # such one.
3674
3675             # At this point, here is the situation:
3676             # This is not an insertion of a multiple, nor of tentative ($NO)
3677             # data.
3678             #   $i  points to the first element in the current range list that
3679             #            may be affected by this operation.  In fact, we know
3680             #            that the range at $i is affected because we are in
3681             #            the else branch of this 'if'
3682             #   $j  points to the highest affected range.
3683             # In other words,
3684             #   r[$i-1]->end < $start <= r[$i]->end
3685             # And:
3686             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3687             #
3688             # Also:
3689             #   $clean_insert is a boolean which is set true if and only if
3690             #        this is a "clean insertion", i.e., not a change nor a
3691             #        deletion (multiple was handled above).
3692
3693             # We now have enough information to decide if this call is a no-op
3694             # or not.  It is a no-op if this is an insertion of already
3695             # existing data.
3696
3697             if (main::DEBUG && $to_trace && $clean_insert
3698                                          && $i == $j
3699                                          && $start >= $r->[$i]->start)
3700             {
3701                     trace "no-op";
3702             }
3703             return if $clean_insert
3704                       && $i == $j # more than one affected range => not no-op
3705
3706                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3707                       # Further, $start and/or $end is >= r[$i]->start
3708                       # The test below hence guarantees that
3709                       #     r[$i]->start < $start <= $end <= r[$i]->end
3710                       # This means the input range is contained entirely in
3711                       # the one at $i, so is a no-op
3712                       && $start >= $r->[$i]->start;
3713         }
3714
3715         # Here, we know that some action will have to be taken.  We have
3716         # calculated the offset and length (though adjustments may be needed)
3717         # for the splice.  Now start constructing the replacement list.
3718         my @replacement;
3719         my $splice_start = $i;
3720
3721         my $extends_below;
3722         my $extends_above;
3723
3724         # See if should extend any adjacent ranges.
3725         if ($operation eq '-') { # Don't extend deletions
3726             $extends_below = $extends_above = 0;
3727         }
3728         else {  # Here, should extend any adjacent ranges.  See if there are
3729                 # any.
3730             $extends_below = ($i > 0
3731                             # can't extend unless adjacent
3732                             && $r->[$i-1]->end == $start -1
3733                             # can't extend unless are same standard value
3734                             && $r->[$i-1]->standard_form eq $standard_form
3735                             # can't extend unless share type
3736                             && $r->[$i-1]->type == $type);
3737             $extends_above = ($j+1 < $range_list_size
3738                             && $r->[$j+1]->start == $end +1
3739                             && $r->[$j+1]->standard_form eq $standard_form
3740                             && $r->[$j+1]->type == $type);
3741         }
3742         if ($extends_below && $extends_above) { # Adds to both
3743             $splice_start--;     # start replace at element below
3744             $length += 2;        # will replace on both sides
3745             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3746
3747             # The result will fill in any gap, replacing both sides, and
3748             # create one large range.
3749             @replacement = Range->new($r->[$i-1]->start,
3750                                       $r->[$j+1]->end,
3751                                       Value => $value,
3752                                       Type => $type);
3753         }
3754         else {
3755
3756             # Here we know that the result won't just be the conglomeration of
3757             # a new range with both its adjacent neighbors.  But it could
3758             # extend one of them.
3759
3760             if ($extends_below) {
3761
3762                 # Here the new element adds to the one below, but not to the
3763                 # one above.  If inserting, and only to that one range,  can
3764                 # just change its ending to include the new one.
3765                 if ($length == 0 && $clean_insert) {
3766                     $r->[$i-1]->set_end($end);
3767                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3768                     return;
3769                 }
3770                 else {
3771                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3772                     $splice_start--;        # start replace at element below
3773                     $length++;              # will replace the element below
3774                     $start = $r->[$i-1]->start;
3775                 }
3776             }
3777             elsif ($extends_above) {
3778
3779                 # Here the new element adds to the one above, but not below.
3780                 # Mirror the code above
3781                 if ($length == 0 && $clean_insert) {
3782                     $r->[$j+1]->set_start($start);
3783                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3784                     return;
3785                 }
3786                 else {
3787                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3788                     $length++;        # will replace the element above
3789                     $end = $r->[$j+1]->end;
3790                 }
3791             }
3792
3793             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3794
3795             # Finally, here we know there will have to be a splice.
3796             # If the change or delete affects only the highest portion of the
3797             # first affected range, the range will have to be split.  The
3798             # splice will remove the whole range, but will replace it by a new
3799             # range containing just the unaffected part.  So, in this case,
3800             # add to the replacement list just this unaffected portion.
3801             if (! $extends_below
3802                 && $start > $r->[$i]->start && $start <= $r->[$i]->end)
3803             {
3804                 push @replacement,
3805                     Range->new($r->[$i]->start,
3806                                $start - 1,
3807                                Value => $r->[$i]->value,
3808                                Type => $r->[$i]->type);
3809             }
3810
3811             # In the case of an insert or change, but not a delete, we have to
3812             # put in the new stuff;  this comes next.
3813             if ($operation eq '+') {
3814                 push @replacement, Range->new($start,
3815                                               $end,
3816                                               Value => $value,
3817                                               Type => $type);
3818             }
3819
3820             trace "Range at $j is $r->[$j]" if main::DEBUG && $to_trace && $j != $i;
3821             #trace "$end >=", $r->[$j]->start, " && $end <", $r->[$j]->end if main::DEBUG && $to_trace;
3822
3823             # And finally, if we're changing or deleting only a portion of the
3824             # highest affected range, it must be split, as the lowest one was.
3825             if (! $extends_above
3826                 && $j >= 0  # Remember that j can be -1 if before first
3827                             # current element
3828                 && $end >= $r->[$j]->start
3829                 && $end < $r->[$j]->end)
3830             {
3831                 push @replacement,
3832                     Range->new($end + 1,
3833                                $r->[$j]->end,
3834                                Value => $r->[$j]->value,
3835                                Type => $r->[$j]->type);
3836             }
3837         }
3838
3839         # And do the splice, as calculated above
3840         if (main::DEBUG && $to_trace) {
3841             trace "replacing $length element(s) at $i with ";
3842             foreach my $replacement (@replacement) {
3843                 trace "    $replacement";
3844             }
3845             trace "Before splice:";
3846             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3847             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3848             trace "i  =[", $i, "]", $r->[$i];
3849             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3850             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3851         }
3852
3853         my @return = splice @$r, $splice_start, $length, @replacement;
3854
3855         if (main::DEBUG && $to_trace) {
3856             trace "After splice:";
3857             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3858             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3859             trace "i  =[", $i, "]", $r->[$i];
3860             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3861             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3862             trace "removed ", @return if @return;
3863         }
3864
3865         # An actual deletion could have changed the maximum in the list.
3866         # There was no deletion if the splice didn't return something, but
3867         # otherwise recalculate it.  This is done too rarely to worry about
3868         # performance.
3869         if ($operation eq '-' && @return) {
3870             $max{$addr} = $r->[-1]->end;
3871         }
3872         return @return;
3873     }
3874
3875     sub reset_each_range {  # reset the iterator for each_range();
3876         my $self = shift;
3877         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3878
3879         no overloading;
3880         undef $each_range_iterator{pack 'J', $self};
3881         return;
3882     }
3883
3884     sub each_range {
3885         # Iterate over each range in a range list.  Results are undefined if
3886         # the range list is changed during the iteration.
3887
3888         my $self = shift;
3889         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3890
3891         my $addr = do { no overloading; pack 'J', $self; };
3892
3893         return if $self->is_empty;
3894
3895         $each_range_iterator{$addr} = -1
3896                                 if ! defined $each_range_iterator{$addr};
3897         $each_range_iterator{$addr}++;
3898         return $ranges{$addr}->[$each_range_iterator{$addr}]
3899                         if $each_range_iterator{$addr} < @{$ranges{$addr}};
3900         undef $each_range_iterator{$addr};
3901         return;
3902     }
3903
3904     sub count {        # Returns count of code points in range list
3905         my $self = shift;
3906         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3907
3908         my $addr = do { no overloading; pack 'J', $self; };
3909
3910         my $count = 0;
3911         foreach my $range (@{$ranges{$addr}}) {
3912             $count += $range->end - $range->start + 1;
3913         }
3914         return $count;
3915     }
3916
3917     sub delete_range {    # Delete a range
3918         my $self = shift;
3919         my $start = shift;
3920         my $end = shift;
3921
3922         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3923
3924         return $self->_add_delete('-', $start, $end, "");
3925     }
3926
3927     sub is_empty { # Returns boolean as to if a range list is empty
3928         my $self = shift;
3929         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3930
3931         no overloading;
3932         return scalar @{$ranges{pack 'J', $self}} == 0;
3933     }
3934
3935     sub hash {
3936         # Quickly returns a scalar suitable for separating tables into
3937         # buckets, i.e. it is a hash function of the contents of a table, so
3938         # there are relatively few conflicts.
3939
3940         my $self = shift;
3941         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3942
3943         my $addr = do { no overloading; pack 'J', $self; };
3944
3945         # These are quickly computable.  Return looks like 'min..max;count'
3946         return $self->min . "..$max{$addr};" . scalar @{$ranges{$addr}};
3947     }
3948 } # End closure for _Range_List_Base
3949
3950 package Range_List;
3951 use base '_Range_List_Base';
3952
3953 # A Range_List is a range list for match tables; i.e. the range values are
3954 # not significant.  Thus a number of operations can be safely added to it,
3955 # such as inversion, intersection.  Note that union is also an unsafe
3956 # operation when range values are cared about, and that method is in the base
3957 # class, not here.  But things are set up so that that method is callable only
3958 # during initialization.  Only in this derived class, is there an operation
3959 # that combines two tables.  A Range_Map can thus be used to initialize a
3960 # Range_List, and its mappings will be in the list, but are not significant to
3961 # this class.
3962
3963 sub trace { return main::trace(@_); }
3964
3965 { # Closure
3966
3967     use overload
3968         fallback => 0,
3969         '+' => sub { my $self = shift;
3970                     my $other = shift;
3971
3972                     return $self->_union($other)
3973                 },
3974         '&' => sub { my $self = shift;
3975                     my $other = shift;
3976
3977                     return $self->_intersect($other, 0);
3978                 },
3979         '~' => "_invert",
3980         '-' => "_subtract",
3981     ;
3982
3983     sub _invert {
3984         # Returns a new Range_List that gives all code points not in $self.</