This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Revamp the section on local() in perlsub.
[perl5.git] / pod / perlsub.pod
1 =head1 NAME
2
3 perlsub - Perl subroutines
4
5 =head1 SYNOPSIS
6
7 To declare subroutines:
8
9     sub NAME;                     # A "forward" declaration.
10     sub NAME(PROTO);              #  ditto, but with prototypes
11     sub NAME : ATTRS;             #  with attributes
12     sub NAME(PROTO) : ATTRS;      #  with attributes and prototypes
13
14     sub NAME BLOCK                # A declaration and a definition.
15     sub NAME(PROTO) BLOCK         #  ditto, but with prototypes
16     sub NAME : ATTRS BLOCK        #  with attributes
17     sub NAME(PROTO) : ATTRS BLOCK #  with prototypes and attributes
18
19 To define an anonymous subroutine at runtime:
20
21     $subref = sub BLOCK;                 # no proto
22     $subref = sub (PROTO) BLOCK;         # with proto
23     $subref = sub : ATTRS BLOCK;         # with attributes
24     $subref = sub (PROTO) : ATTRS BLOCK; # with proto and attributes
25
26 To import subroutines:
27
28     use MODULE qw(NAME1 NAME2 NAME3);
29
30 To call subroutines:
31
32     NAME(LIST);    # & is optional with parentheses.
33     NAME LIST;     # Parentheses optional if predeclared/imported.
34     &NAME(LIST);   # Circumvent prototypes.
35     &NAME;         # Makes current @_ visible to called subroutine.
36
37 =head1 DESCRIPTION
38
39 Like many languages, Perl provides for user-defined subroutines.
40 These may be located anywhere in the main program, loaded in from
41 other files via the C<do>, C<require>, or C<use> keywords, or
42 generated on the fly using C<eval> or anonymous subroutines.
43 You can even call a function indirectly using a variable containing
44 its name or a CODE reference.
45
46 The Perl model for function call and return values is simple: all
47 functions are passed as parameters one single flat list of scalars, and
48 all functions likewise return to their caller one single flat list of
49 scalars.  Any arrays or hashes in these call and return lists will
50 collapse, losing their identities--but you may always use
51 pass-by-reference instead to avoid this.  Both call and return lists may
52 contain as many or as few scalar elements as you'd like.  (Often a
53 function without an explicit return statement is called a subroutine, but
54 there's really no difference from Perl's perspective.)
55
56 Any arguments passed in show up in the array C<@_>.  Therefore, if
57 you called a function with two arguments, those would be stored in
58 C<$_[0]> and C<$_[1]>.  The array C<@_> is a local array, but its
59 elements are aliases for the actual scalar parameters.  In particular,
60 if an element C<$_[0]> is updated, the corresponding argument is
61 updated (or an error occurs if it is not updatable).  If an argument
62 is an array or hash element which did not exist when the function
63 was called, that element is created only when (and if) it is modified
64 or a reference to it is taken.  (Some earlier versions of Perl
65 created the element whether or not the element was assigned to.)
66 Assigning to the whole array C<@_> removes that aliasing, and does
67 not update any arguments.
68
69 The return value of a subroutine is the value of the last expression
70 evaluated.  More explicitly, a C<return> statement may be used to exit the
71 subroutine, optionally specifying the returned value, which will be
72 evaluated in the appropriate context (list, scalar, or void) depending
73 on the context of the subroutine call.  If you specify no return value,
74 the subroutine returns an empty list in list context, the undefined
75 value in scalar context, or nothing in void context.  If you return
76 one or more aggregates (arrays and hashes), these will be flattened
77 together into one large indistinguishable list.
78
79 Perl does not have named formal parameters.  In practice all you
80 do is assign to a C<my()> list of these.  Variables that aren't
81 declared to be private are global variables.  For gory details
82 on creating private variables, see L<"Private Variables via my()">
83 and L<"Temporary Values via local()">.  To create protected
84 environments for a set of functions in a separate package (and
85 probably a separate file), see L<perlmod/"Packages">.
86
87 Example:
88
89     sub max {
90         my $max = shift(@_);
91         foreach $foo (@_) {
92             $max = $foo if $max < $foo;
93         }
94         return $max;
95     }
96     $bestday = max($mon,$tue,$wed,$thu,$fri);
97
98 Example:
99
100     # get a line, combining continuation lines
101     #  that start with whitespace
102
103     sub get_line {
104         $thisline = $lookahead;  # global variables!
105         LINE: while (defined($lookahead = <STDIN>)) {
106             if ($lookahead =~ /^[ \t]/) {
107                 $thisline .= $lookahead;
108             }
109             else {
110                 last LINE;
111             }
112         }
113         return $thisline;
114     }
115
116     $lookahead = <STDIN>;       # get first line
117     while (defined($line = get_line())) {
118         ...
119     }
120
121 Assigning to a list of private variables to name your arguments:
122
123     sub maybeset {
124         my($key, $value) = @_;
125         $Foo{$key} = $value unless $Foo{$key};
126     }
127
128 Because the assignment copies the values, this also has the effect
129 of turning call-by-reference into call-by-value.  Otherwise a
130 function is free to do in-place modifications of C<@_> and change
131 its caller's values.
132
133     upcase_in($v1, $v2);  # this changes $v1 and $v2
134     sub upcase_in {
135         for (@_) { tr/a-z/A-Z/ }
136     }
137
138 You aren't allowed to modify constants in this way, of course.  If an
139 argument were actually literal and you tried to change it, you'd take a
140 (presumably fatal) exception.   For example, this won't work:
141
142     upcase_in("frederick");
143
144 It would be much safer if the C<upcase_in()> function
145 were written to return a copy of its parameters instead
146 of changing them in place:
147
148     ($v3, $v4) = upcase($v1, $v2);  # this doesn't change $v1 and $v2
149     sub upcase {
150         return unless defined wantarray;  # void context, do nothing
151         my @parms = @_;
152         for (@parms) { tr/a-z/A-Z/ }
153         return wantarray ? @parms : $parms[0];
154     }
155
156 Notice how this (unprototyped) function doesn't care whether it was
157 passed real scalars or arrays.  Perl sees all arguments as one big,
158 long, flat parameter list in C<@_>.  This is one area where
159 Perl's simple argument-passing style shines.  The C<upcase()>
160 function would work perfectly well without changing the C<upcase()>
161 definition even if we fed it things like this:
162
163     @newlist   = upcase(@list1, @list2);
164     @newlist   = upcase( split /:/, $var );
165
166 Do not, however, be tempted to do this:
167
168     (@a, @b)   = upcase(@list1, @list2);
169
170 Like the flattened incoming parameter list, the return list is also
171 flattened on return.  So all you have managed to do here is stored
172 everything in C<@a> and made C<@b> empty.  See 
173 L<Pass by Reference> for alternatives.
174
175 A subroutine may be called using an explicit C<&> prefix.  The
176 C<&> is optional in modern Perl, as are parentheses if the
177 subroutine has been predeclared.  The C<&> is I<not> optional
178 when just naming the subroutine, such as when it's used as
179 an argument to defined() or undef().  Nor is it optional when you
180 want to do an indirect subroutine call with a subroutine name or
181 reference using the C<&$subref()> or C<&{$subref}()> constructs,
182 although the C<< $subref->() >> notation solves that problem.
183 See L<perlref> for more about all that.
184
185 Subroutines may be called recursively.  If a subroutine is called
186 using the C<&> form, the argument list is optional, and if omitted,
187 no C<@_> array is set up for the subroutine: the C<@_> array at the
188 time of the call is visible to subroutine instead.  This is an
189 efficiency mechanism that new users may wish to avoid.
190
191     &foo(1,2,3);        # pass three arguments
192     foo(1,2,3);         # the same
193
194     foo();              # pass a null list
195     &foo();             # the same
196
197     &foo;               # foo() get current args, like foo(@_) !!
198     foo;                # like foo() IFF sub foo predeclared, else "foo"
199
200 Not only does the C<&> form make the argument list optional, it also
201 disables any prototype checking on arguments you do provide.  This
202 is partly for historical reasons, and partly for having a convenient way
203 to cheat if you know what you're doing.  See L<Prototypes> below.
204
205 Functions whose names are in all upper case are reserved to the Perl
206 core, as are modules whose names are in all lower case.  A
207 function in all capitals is a loosely-held convention meaning it
208 will be called indirectly by the run-time system itself, usually
209 due to a triggered event.  Functions that do special, pre-defined
210 things include C<BEGIN>, C<CHECK>, C<INIT>, C<END>, C<AUTOLOAD>,
211 C<CLONE> and C<DESTROY>--plus all functions mentioned in L<perltie>.
212
213 =head2 Private Variables via my()
214
215 Synopsis:
216
217     my $foo;            # declare $foo lexically local
218     my (@wid, %get);    # declare list of variables local
219     my $foo = "flurp";  # declare $foo lexical, and init it
220     my @oof = @bar;     # declare @oof lexical, and init it
221     my $x : Foo = $y;   # similar, with an attribute applied
222
223 B<WARNING>: The use of attribute lists on C<my> declarations is still
224 evolving.  The current semantics and interface are subject to change.
225 See L<attributes> and L<Attribute::Handlers>.
226
227 The C<my> operator declares the listed variables to be lexically
228 confined to the enclosing block, conditional (C<if/unless/elsif/else>),
229 loop (C<for/foreach/while/until/continue>), subroutine, C<eval>,
230 or C<do/require/use>'d file.  If more than one value is listed, the
231 list must be placed in parentheses.  All listed elements must be
232 legal lvalues.  Only alphanumeric identifiers may be lexically
233 scoped--magical built-ins like C<$/> must currently be C<local>ized
234 with C<local> instead.
235
236 Unlike dynamic variables created by the C<local> operator, lexical
237 variables declared with C<my> are totally hidden from the outside
238 world, including any called subroutines.  This is true if it's the
239 same subroutine called from itself or elsewhere--every call gets
240 its own copy.
241
242 This doesn't mean that a C<my> variable declared in a statically
243 enclosing lexical scope would be invisible.  Only dynamic scopes
244 are cut off.   For example, the C<bumpx()> function below has access
245 to the lexical $x variable because both the C<my> and the C<sub>
246 occurred at the same scope, presumably file scope.
247
248     my $x = 10;
249     sub bumpx { $x++ } 
250
251 An C<eval()>, however, can see lexical variables of the scope it is
252 being evaluated in, so long as the names aren't hidden by declarations within
253 the C<eval()> itself.  See L<perlref>.
254
255 The parameter list to my() may be assigned to if desired, which allows you
256 to initialize your variables.  (If no initializer is given for a
257 particular variable, it is created with the undefined value.)  Commonly
258 this is used to name input parameters to a subroutine.  Examples:
259
260     $arg = "fred";        # "global" variable
261     $n = cube_root(27);
262     print "$arg thinks the root is $n\n";
263  fred thinks the root is 3
264
265     sub cube_root {
266         my $arg = shift;  # name doesn't matter
267         $arg **= 1/3;
268         return $arg;
269     }
270
271 The C<my> is simply a modifier on something you might assign to.  So when
272 you do assign to variables in its argument list, C<my> doesn't
273 change whether those variables are viewed as a scalar or an array.  So
274
275     my ($foo) = <STDIN>;                # WRONG?
276     my @FOO = <STDIN>;
277
278 both supply a list context to the right-hand side, while
279
280     my $foo = <STDIN>;
281
282 supplies a scalar context.  But the following declares only one variable:
283
284     my $foo, $bar = 1;                  # WRONG
285
286 That has the same effect as
287
288     my $foo;
289     $bar = 1;
290
291 The declared variable is not introduced (is not visible) until after
292 the current statement.  Thus,
293
294     my $x = $x;
295
296 can be used to initialize a new $x with the value of the old $x, and
297 the expression
298
299     my $x = 123 and $x == 123
300
301 is false unless the old $x happened to have the value C<123>.
302
303 Lexical scopes of control structures are not bounded precisely by the
304 braces that delimit their controlled blocks; control expressions are
305 part of that scope, too.  Thus in the loop
306
307     while (my $line = <>) {
308         $line = lc $line;
309     } continue {
310         print $line;
311     }
312
313 the scope of $line extends from its declaration throughout the rest of
314 the loop construct (including the C<continue> clause), but not beyond
315 it.  Similarly, in the conditional
316
317     if ((my $answer = <STDIN>) =~ /^yes$/i) {
318         user_agrees();
319     } elsif ($answer =~ /^no$/i) {
320         user_disagrees();
321     } else {
322         chomp $answer;
323         die "'$answer' is neither 'yes' nor 'no'";
324     }
325
326 the scope of $answer extends from its declaration through the rest
327 of that conditional, including any C<elsif> and C<else> clauses, 
328 but not beyond it.  See L<perlsyn/"Simple statements"> for information
329 on the scope of variables in statements with modifiers.
330
331 The C<foreach> loop defaults to scoping its index variable dynamically
332 in the manner of C<local>.  However, if the index variable is
333 prefixed with the keyword C<my>, or if there is already a lexical
334 by that name in scope, then a new lexical is created instead.  Thus
335 in the loop
336
337     for my $i (1, 2, 3) {
338         some_function();
339     }
340
341 the scope of $i extends to the end of the loop, but not beyond it,
342 rendering the value of $i inaccessible within C<some_function()>.
343
344 Some users may wish to encourage the use of lexically scoped variables.
345 As an aid to catching implicit uses to package variables,
346 which are always global, if you say
347
348     use strict 'vars';
349
350 then any variable mentioned from there to the end of the enclosing
351 block must either refer to a lexical variable, be predeclared via
352 C<our> or C<use vars>, or else must be fully qualified with the package name.
353 A compilation error results otherwise.  An inner block may countermand
354 this with C<no strict 'vars'>.
355
356 A C<my> has both a compile-time and a run-time effect.  At compile
357 time, the compiler takes notice of it.  The principal usefulness
358 of this is to quiet C<use strict 'vars'>, but it is also essential
359 for generation of closures as detailed in L<perlref>.  Actual
360 initialization is delayed until run time, though, so it gets executed
361 at the appropriate time, such as each time through a loop, for
362 example.
363
364 Variables declared with C<my> are not part of any package and are therefore
365 never fully qualified with the package name.  In particular, you're not
366 allowed to try to make a package variable (or other global) lexical:
367
368     my $pack::var;      # ERROR!  Illegal syntax
369     my $_;              # also illegal (currently)
370
371 In fact, a dynamic variable (also known as package or global variables)
372 are still accessible using the fully qualified C<::> notation even while a
373 lexical of the same name is also visible:
374
375     package main;
376     local $x = 10;
377     my    $x = 20;
378     print "$x and $::x\n";
379
380 That will print out C<20> and C<10>.
381
382 You may declare C<my> variables at the outermost scope of a file
383 to hide any such identifiers from the world outside that file.  This
384 is similar in spirit to C's static variables when they are used at
385 the file level.  To do this with a subroutine requires the use of
386 a closure (an anonymous function that accesses enclosing lexicals).
387 If you want to create a private subroutine that cannot be called
388 from outside that block, it can declare a lexical variable containing
389 an anonymous sub reference:
390
391     my $secret_version = '1.001-beta';
392     my $secret_sub = sub { print $secret_version };
393     &$secret_sub();
394
395 As long as the reference is never returned by any function within the
396 module, no outside module can see the subroutine, because its name is not in
397 any package's symbol table.  Remember that it's not I<REALLY> called
398 C<$some_pack::secret_version> or anything; it's just $secret_version,
399 unqualified and unqualifiable.
400
401 This does not work with object methods, however; all object methods
402 have to be in the symbol table of some package to be found.  See
403 L<perlref/"Function Templates"> for something of a work-around to
404 this.
405
406 =head2 Persistent Private Variables
407
408 Just because a lexical variable is lexically (also called statically)
409 scoped to its enclosing block, C<eval>, or C<do> FILE, this doesn't mean that
410 within a function it works like a C static.  It normally works more
411 like a C auto, but with implicit garbage collection.  
412
413 Unlike local variables in C or C++, Perl's lexical variables don't
414 necessarily get recycled just because their scope has exited.
415 If something more permanent is still aware of the lexical, it will
416 stick around.  So long as something else references a lexical, that
417 lexical won't be freed--which is as it should be.  You wouldn't want
418 memory being free until you were done using it, or kept around once you
419 were done.  Automatic garbage collection takes care of this for you.
420
421 This means that you can pass back or save away references to lexical
422 variables, whereas to return a pointer to a C auto is a grave error.
423 It also gives us a way to simulate C's function statics.  Here's a
424 mechanism for giving a function private variables with both lexical
425 scoping and a static lifetime.  If you do want to create something like
426 C's static variables, just enclose the whole function in an extra block,
427 and put the static variable outside the function but in the block.
428
429     {
430         my $secret_val = 0;
431         sub gimme_another {
432             return ++$secret_val;
433         }
434     }
435     # $secret_val now becomes unreachable by the outside
436     # world, but retains its value between calls to gimme_another
437
438 If this function is being sourced in from a separate file
439 via C<require> or C<use>, then this is probably just fine.  If it's
440 all in the main program, you'll need to arrange for the C<my>
441 to be executed early, either by putting the whole block above
442 your main program, or more likely, placing merely a C<BEGIN>
443 sub around it to make sure it gets executed before your program
444 starts to run:
445
446     sub BEGIN {
447         my $secret_val = 0;
448         sub gimme_another {
449             return ++$secret_val;
450         }
451     }
452
453 See L<perlmod/"Package Constructors and Destructors"> about the
454 special triggered functions, C<BEGIN>, C<CHECK>, C<INIT> and C<END>.
455
456 If declared at the outermost scope (the file scope), then lexicals
457 work somewhat like C's file statics.  They are available to all
458 functions in that same file declared below them, but are inaccessible
459 from outside that file.  This strategy is sometimes used in modules
460 to create private variables that the whole module can see.
461
462 =head2 Temporary Values via local()
463
464 B<WARNING>: In general, you should be using C<my> instead of C<local>, because
465 it's faster and safer.  Exceptions to this include the global punctuation
466 variables, global filehandles and formats, and direct manipulation of the
467 Perl symbol table itself.  C<local> is mostly used when the current value
468 of a variable must be visible to called subroutines.
469
470 Synopsis:
471
472     # localization of values
473
474     local $foo;                 # make $foo dynamically local
475     local (@wid, %get);         # make list of variables local
476     local $foo = "flurp";       # make $foo dynamic, and init it
477     local @oof = @bar;          # make @oof dynamic, and init it
478
479     local $hash{key} = "val";   # sets a local value for this hash entry
480     local ($cond ? $v1 : $v2);  # several types of lvalues support
481                                 # localization
482
483     # localization of symbols
484
485     local *FH;                  # localize $FH, @FH, %FH, &FH  ...
486     local *merlyn = *randal;    # now $merlyn is really $randal, plus
487                                 #     @merlyn is really @randal, etc
488     local *merlyn = 'randal';   # SAME THING: promote 'randal' to *randal
489     local *merlyn = \$randal;   # just alias $merlyn, not @merlyn etc
490
491 A C<local> modifies its listed variables to be "local" to the
492 enclosing block, C<eval>, or C<do FILE>--and to I<any subroutine
493 called from within that block>.  A C<local> just gives temporary
494 values to global (meaning package) variables.  It does I<not> create
495 a local variable.  This is known as dynamic scoping.  Lexical scoping
496 is done with C<my>, which works more like C's auto declarations.
497
498 Some types of lvalues can be localized as well : hash and array elements
499 and slices, conditionals (provided that their result is always
500 localizable), and symbolic references.  As for simple variables, this
501 creates new, dynamically scoped values.
502
503 If more than one variable or expression is given to C<local>, they must be
504 placed in parentheses.  This operator works
505 by saving the current values of those variables in its argument list on a
506 hidden stack and restoring them upon exiting the block, subroutine, or
507 eval.  This means that called subroutines can also reference the local
508 variable, but not the global one.  The argument list may be assigned to if
509 desired, which allows you to initialize your local variables.  (If no
510 initializer is given for a particular variable, it is created with an
511 undefined value.)
512
513 Because C<local> is a run-time operator, it gets executed each time
514 through a loop.  Consequently, it's more efficient to localize your
515 variables outside the loop.
516
517 =head3 Grammatical note on local()
518
519 A C<local> is simply a modifier on an lvalue expression.  When you assign to
520 a C<local>ized variable, the C<local> doesn't change whether its list is viewed
521 as a scalar or an array.  So
522
523     local($foo) = <STDIN>;
524     local @FOO = <STDIN>;
525
526 both supply a list context to the right-hand side, while
527
528     local $foo = <STDIN>;
529
530 supplies a scalar context.
531
532 =head3 Localization of special variables
533
534 If you localize a special variable, you'll be giving a new value to it,
535 but its magic won't go away.  That means that all side-effects related
536 to this magic still work with the localized value.
537
538 This feature allows code like this to work :
539
540     # Read the whole contents of FILE in $slurp
541     { local $/ = undef; $slurp = <FILE>; }
542
543 Note, however, that this restricts localization of some values ; for
544 example, the following statement dies, as of perl 5.9.0, with an error
545 I<Modification of a read-only value attempted>, because the $1 variable is
546 magical and read-only :
547
548     local $1 = 2;
549
550 Similarly, but in a way more difficult to spot, the following snippet will
551 die in perl 5.9.0 :
552
553     sub f { local $_ = "foo"; print }
554     for ($1) {
555         # now $_ is aliased to $1, thus is magic and readonly
556         f();
557     }
558
559 See next section for an alternative to this situation.
560
561 B<WARNING>: Localization of tied arrays and hashes does not currently
562 work as described.
563 This will be fixed in a future release of Perl; in the meantime, avoid
564 code that relies on any particular behaviour of localising tied arrays
565 or hashes (localising individual elements is still okay).
566 See L<perl58delta/"Localising Tied Arrays and Hashes Is Broken"> for more
567 details.
568
569 =head3 Localization of globs
570
571 The construct
572
573     local *name;
574
575 creates a whole new symbol table entry for the glob C<name> in the
576 current package.  That means that all variables in its glob slot ($name,
577 @name, %name, &name, and the C<name> filehandle) are dynamically reset.
578
579 This implies, among other things, that any magic eventually carried by
580 those variables is locally lost.  In other words, saying C<local */>
581 will not have any effect on the internal value of the input record
582 separator.
583
584 Notably, if you want to work with a brand new value of the default scalar
585 $_, and avoid the potential problem listed above about $_ previously
586 carrying a magic value, you should use C<local *_> instead of C<local $_>.
587
588 =head3 Localization of elements of composite types
589
590 It's also worth taking a moment to explain what happens when you
591 C<local>ize a member of a composite type (i.e. an array or hash element).
592 In this case, the element is C<local>ized I<by name>. This means that
593 when the scope of the C<local()> ends, the saved value will be
594 restored to the hash element whose key was named in the C<local()>, or
595 the array element whose index was named in the C<local()>.  If that
596 element was deleted while the C<local()> was in effect (e.g. by a
597 C<delete()> from a hash or a C<shift()> of an array), it will spring
598 back into existence, possibly extending an array and filling in the
599 skipped elements with C<undef>.  For instance, if you say
600
601     %hash = ( 'This' => 'is', 'a' => 'test' );
602     @ary  = ( 0..5 );
603     {
604          local($ary[5]) = 6;
605          local($hash{'a'}) = 'drill';
606          while (my $e = pop(@ary)) {
607              print "$e . . .\n";
608              last unless $e > 3;
609          }
610          if (@ary) {
611              $hash{'only a'} = 'test';
612              delete $hash{'a'};
613          }
614     }
615     print join(' ', map { "$_ $hash{$_}" } sort keys %hash),".\n";
616     print "The array has ",scalar(@ary)," elements: ",
617           join(', ', map { defined $_ ? $_ : 'undef' } @ary),"\n";
618
619 Perl will print
620
621     6 . . .
622     4 . . .
623     3 . . .
624     This is a test only a test.
625     The array has 6 elements: 0, 1, 2, undef, undef, 5
626
627 The behavior of local() on non-existent members of composite
628 types is subject to change in future.
629
630 =head2 Lvalue subroutines
631
632 B<WARNING>: Lvalue subroutines are still experimental and the
633 implementation may change in future versions of Perl.
634
635 It is possible to return a modifiable value from a subroutine.
636 To do this, you have to declare the subroutine to return an lvalue.
637
638     my $val;
639     sub canmod : lvalue {
640         # return $val; this doesn't work, don't say "return"
641         $val;
642     }
643     sub nomod {
644         $val;
645     }
646
647     canmod() = 5;   # assigns to $val
648     nomod()  = 5;   # ERROR
649
650 The scalar/list context for the subroutine and for the right-hand
651 side of assignment is determined as if the subroutine call is replaced
652 by a scalar. For example, consider:
653
654     data(2,3) = get_data(3,4);
655
656 Both subroutines here are called in a scalar context, while in:
657
658     (data(2,3)) = get_data(3,4);
659
660 and in:
661
662     (data(2),data(3)) = get_data(3,4);
663
664 all the subroutines are called in a list context.
665
666 =over 4
667
668 =item Lvalue subroutines are EXPERIMENTAL
669
670 They appear to be convenient, but there are several reasons to be
671 circumspect.
672
673 You can't use the return keyword, you must pass out the value before
674 falling out of subroutine scope. (see comment in example above).  This
675 is usually not a problem, but it disallows an explicit return out of a
676 deeply nested loop, which is sometimes a nice way out.
677
678 They violate encapsulation.  A normal mutator can check the supplied
679 argument before setting the attribute it is protecting, an lvalue
680 subroutine never gets that chance.  Consider;
681
682     my $some_array_ref = [];    # protected by mutators ??
683
684     sub set_arr {               # normal mutator
685         my $val = shift;
686         die("expected array, you supplied ", ref $val)
687            unless ref $val eq 'ARRAY';
688         $some_array_ref = $val;
689     }
690     sub set_arr_lv : lvalue {   # lvalue mutator
691         $some_array_ref;
692     }
693
694     # set_arr_lv cannot stop this !
695     set_arr_lv() = { a => 1 };
696
697 =back
698
699 =head2 Passing Symbol Table Entries (typeglobs)
700
701 B<WARNING>: The mechanism described in this section was originally
702 the only way to simulate pass-by-reference in older versions of
703 Perl.  While it still works fine in modern versions, the new reference
704 mechanism is generally easier to work with.  See below.
705
706 Sometimes you don't want to pass the value of an array to a subroutine
707 but rather the name of it, so that the subroutine can modify the global
708 copy of it rather than working with a local copy.  In perl you can
709 refer to all objects of a particular name by prefixing the name
710 with a star: C<*foo>.  This is often known as a "typeglob", because the
711 star on the front can be thought of as a wildcard match for all the
712 funny prefix characters on variables and subroutines and such.
713
714 When evaluated, the typeglob produces a scalar value that represents
715 all the objects of that name, including any filehandle, format, or
716 subroutine.  When assigned to, it causes the name mentioned to refer to
717 whatever C<*> value was assigned to it.  Example:
718
719     sub doubleary {
720         local(*someary) = @_;
721         foreach $elem (@someary) {
722             $elem *= 2;
723         }
724     }
725     doubleary(*foo);
726     doubleary(*bar);
727
728 Scalars are already passed by reference, so you can modify
729 scalar arguments without using this mechanism by referring explicitly
730 to C<$_[0]> etc.  You can modify all the elements of an array by passing
731 all the elements as scalars, but you have to use the C<*> mechanism (or
732 the equivalent reference mechanism) to C<push>, C<pop>, or change the size of
733 an array.  It will certainly be faster to pass the typeglob (or reference).
734
735 Even if you don't want to modify an array, this mechanism is useful for
736 passing multiple arrays in a single LIST, because normally the LIST
737 mechanism will merge all the array values so that you can't extract out
738 the individual arrays.  For more on typeglobs, see
739 L<perldata/"Typeglobs and Filehandles">.
740
741 =head2 When to Still Use local()
742
743 Despite the existence of C<my>, there are still three places where the
744 C<local> operator still shines.  In fact, in these three places, you
745 I<must> use C<local> instead of C<my>.
746
747 =over 4
748
749 =item 1.
750
751 You need to give a global variable a temporary value, especially $_.
752
753 The global variables, like C<@ARGV> or the punctuation variables, must be 
754 C<local>ized with C<local()>.  This block reads in F</etc/motd>, and splits
755 it up into chunks separated by lines of equal signs, which are placed
756 in C<@Fields>.
757
758     {
759         local @ARGV = ("/etc/motd");
760         local $/ = undef;
761         local $_ = <>;  
762         @Fields = split /^\s*=+\s*$/;
763     } 
764
765 It particular, it's important to C<local>ize $_ in any routine that assigns
766 to it.  Look out for implicit assignments in C<while> conditionals.
767
768 =item 2.
769
770 You need to create a local file or directory handle or a local function.
771
772 A function that needs a filehandle of its own must use
773 C<local()> on a complete typeglob.   This can be used to create new symbol
774 table entries:
775
776     sub ioqueue {
777         local  (*READER, *WRITER);    # not my!
778         pipe    (READER,  WRITER)     or die "pipe: $!";
779         return (*READER, *WRITER);
780     }
781     ($head, $tail) = ioqueue();
782
783 See the Symbol module for a way to create anonymous symbol table
784 entries.
785
786 Because assignment of a reference to a typeglob creates an alias, this
787 can be used to create what is effectively a local function, or at least,
788 a local alias.
789
790     {
791         local *grow = \&shrink; # only until this block exists
792         grow();                 # really calls shrink()
793         move();                 # if move() grow()s, it shrink()s too
794     }
795     grow();                     # get the real grow() again
796
797 See L<perlref/"Function Templates"> for more about manipulating
798 functions by name in this way.
799
800 =item 3.
801
802 You want to temporarily change just one element of an array or hash.
803
804 You can C<local>ize just one element of an aggregate.  Usually this
805 is done on dynamics:
806
807     {
808         local $SIG{INT} = 'IGNORE';
809         funct();                            # uninterruptible
810     } 
811     # interruptibility automatically restored here
812
813 But it also works on lexically declared aggregates.  Prior to 5.005,
814 this operation could on occasion misbehave.
815
816 =back
817
818 =head2 Pass by Reference
819
820 If you want to pass more than one array or hash into a function--or
821 return them from it--and have them maintain their integrity, then
822 you're going to have to use an explicit pass-by-reference.  Before you
823 do that, you need to understand references as detailed in L<perlref>.
824 This section may not make much sense to you otherwise.
825
826 Here are a few simple examples.  First, let's pass in several arrays
827 to a function and have it C<pop> all of then, returning a new list
828 of all their former last elements:
829
830     @tailings = popmany ( \@a, \@b, \@c, \@d );
831
832     sub popmany {
833         my $aref;
834         my @retlist = ();
835         foreach $aref ( @_ ) {
836             push @retlist, pop @$aref;
837         }
838         return @retlist;
839     }
840
841 Here's how you might write a function that returns a
842 list of keys occurring in all the hashes passed to it:
843
844     @common = inter( \%foo, \%bar, \%joe );
845     sub inter {
846         my ($k, $href, %seen); # locals
847         foreach $href (@_) {
848             while ( $k = each %$href ) {
849                 $seen{$k}++;
850             }
851         }
852         return grep { $seen{$_} == @_ } keys %seen;
853     }
854
855 So far, we're using just the normal list return mechanism.
856 What happens if you want to pass or return a hash?  Well,
857 if you're using only one of them, or you don't mind them
858 concatenating, then the normal calling convention is ok, although
859 a little expensive.
860
861 Where people get into trouble is here:
862
863     (@a, @b) = func(@c, @d);
864 or
865     (%a, %b) = func(%c, %d);
866
867 That syntax simply won't work.  It sets just C<@a> or C<%a> and
868 clears the C<@b> or C<%b>.  Plus the function didn't get passed
869 into two separate arrays or hashes: it got one long list in C<@_>,
870 as always.
871
872 If you can arrange for everyone to deal with this through references, it's
873 cleaner code, although not so nice to look at.  Here's a function that
874 takes two array references as arguments, returning the two array elements
875 in order of how many elements they have in them:
876
877     ($aref, $bref) = func(\@c, \@d);
878     print "@$aref has more than @$bref\n";
879     sub func {
880         my ($cref, $dref) = @_;
881         if (@$cref > @$dref) {
882             return ($cref, $dref);
883         } else {
884             return ($dref, $cref);
885         }
886     }
887
888 It turns out that you can actually do this also:
889
890     (*a, *b) = func(\@c, \@d);
891     print "@a has more than @b\n";
892     sub func {
893         local (*c, *d) = @_;
894         if (@c > @d) {
895             return (\@c, \@d);
896         } else {
897             return (\@d, \@c);
898         }
899     }
900
901 Here we're using the typeglobs to do symbol table aliasing.  It's
902 a tad subtle, though, and also won't work if you're using C<my>
903 variables, because only globals (even in disguise as C<local>s)
904 are in the symbol table.
905
906 If you're passing around filehandles, you could usually just use the bare
907 typeglob, like C<*STDOUT>, but typeglobs references work, too.
908 For example:
909
910     splutter(\*STDOUT);
911     sub splutter {
912         my $fh = shift;
913         print $fh "her um well a hmmm\n";
914     }
915
916     $rec = get_rec(\*STDIN);
917     sub get_rec {
918         my $fh = shift;
919         return scalar <$fh>;
920     }
921
922 If you're planning on generating new filehandles, you could do this.
923 Notice to pass back just the bare *FH, not its reference.
924
925     sub openit {
926         my $path = shift;
927         local *FH;
928         return open (FH, $path) ? *FH : undef;
929     }
930
931 =head2 Prototypes
932
933 Perl supports a very limited kind of compile-time argument checking
934 using function prototyping.  If you declare
935
936     sub mypush (\@@)
937
938 then C<mypush()> takes arguments exactly like C<push()> does.  The
939 function declaration must be visible at compile time.  The prototype
940 affects only interpretation of new-style calls to the function,
941 where new-style is defined as not using the C<&> character.  In
942 other words, if you call it like a built-in function, then it behaves
943 like a built-in function.  If you call it like an old-fashioned
944 subroutine, then it behaves like an old-fashioned subroutine.  It
945 naturally falls out from this rule that prototypes have no influence
946 on subroutine references like C<\&foo> or on indirect subroutine
947 calls like C<&{$subref}> or C<< $subref->() >>.
948
949 Method calls are not influenced by prototypes either, because the
950 function to be called is indeterminate at compile time, since
951 the exact code called depends on inheritance.
952
953 Because the intent of this feature is primarily to let you define
954 subroutines that work like built-in functions, here are prototypes
955 for some other functions that parse almost exactly like the
956 corresponding built-in.
957
958     Declared as                 Called as
959
960     sub mylink ($$)          mylink $old, $new
961     sub myvec ($$$)          myvec $var, $offset, 1
962     sub myindex ($$;$)       myindex &getstring, "substr"
963     sub mysyswrite ($$$;$)   mysyswrite $buf, 0, length($buf) - $off, $off
964     sub myreverse (@)        myreverse $a, $b, $c
965     sub myjoin ($@)          myjoin ":", $a, $b, $c
966     sub mypop (\@)           mypop @array
967     sub mysplice (\@$$@)     mysplice @array, @array, 0, @pushme
968     sub mykeys (\%)          mykeys %{$hashref}
969     sub myopen (*;$)         myopen HANDLE, $name
970     sub mypipe (**)          mypipe READHANDLE, WRITEHANDLE
971     sub mygrep (&@)          mygrep { /foo/ } $a, $b, $c
972     sub myrand ($)           myrand 42
973     sub mytime ()            mytime
974
975 Any backslashed prototype character represents an actual argument
976 that absolutely must start with that character.  The value passed
977 as part of C<@_> will be a reference to the actual argument given
978 in the subroutine call, obtained by applying C<\> to that argument.
979
980 You can also backslash several argument types simultaneously by using
981 the C<\[]> notation:
982
983     sub myref (\[$@%&*])
984
985 will allow calling myref() as
986
987     myref $var
988     myref @array
989     myref %hash
990     myref &sub
991     myref *glob
992
993 and the first argument of myref() will be a reference to
994 a scalar, an array, a hash, a code, or a glob.
995
996 Unbackslashed prototype characters have special meanings.  Any
997 unbackslashed C<@> or C<%> eats all remaining arguments, and forces
998 list context.  An argument represented by C<$> forces scalar context.  An
999 C<&> requires an anonymous subroutine, which, if passed as the first
1000 argument, does not require the C<sub> keyword or a subsequent comma.
1001
1002 A C<*> allows the subroutine to accept a bareword, constant, scalar expression,
1003 typeglob, or a reference to a typeglob in that slot.  The value will be
1004 available to the subroutine either as a simple scalar, or (in the latter
1005 two cases) as a reference to the typeglob.  If you wish to always convert
1006 such arguments to a typeglob reference, use Symbol::qualify_to_ref() as
1007 follows:
1008
1009     use Symbol 'qualify_to_ref';
1010
1011     sub foo (*) {
1012         my $fh = qualify_to_ref(shift, caller);
1013         ...
1014     }
1015
1016 A semicolon separates mandatory arguments from optional arguments.
1017 It is redundant before C<@> or C<%>, which gobble up everything else.
1018
1019 Note how the last three examples in the table above are treated
1020 specially by the parser.  C<mygrep()> is parsed as a true list
1021 operator, C<myrand()> is parsed as a true unary operator with unary
1022 precedence the same as C<rand()>, and C<mytime()> is truly without
1023 arguments, just like C<time()>.  That is, if you say
1024
1025     mytime +2;
1026
1027 you'll get C<mytime() + 2>, not C<mytime(2)>, which is how it would be parsed
1028 without a prototype.
1029
1030 The interesting thing about C<&> is that you can generate new syntax with it,
1031 provided it's in the initial position:
1032
1033     sub try (&@) {
1034         my($try,$catch) = @_;
1035         eval { &$try };
1036         if ($@) {
1037             local $_ = $@;
1038             &$catch;
1039         }
1040     }
1041     sub catch (&) { $_[0] }
1042
1043     try {
1044         die "phooey";
1045     } catch {
1046         /phooey/ and print "unphooey\n";
1047     };
1048
1049 That prints C<"unphooey">.  (Yes, there are still unresolved
1050 issues having to do with visibility of C<@_>.  I'm ignoring that
1051 question for the moment.  (But note that if we make C<@_> lexically
1052 scoped, those anonymous subroutines can act like closures... (Gee,
1053 is this sounding a little Lispish?  (Never mind.))))
1054
1055 And here's a reimplementation of the Perl C<grep> operator:
1056
1057     sub mygrep (&@) {
1058         my $code = shift;
1059         my @result;
1060         foreach $_ (@_) {
1061             push(@result, $_) if &$code;
1062         }
1063         @result;
1064     }
1065
1066 Some folks would prefer full alphanumeric prototypes.  Alphanumerics have
1067 been intentionally left out of prototypes for the express purpose of
1068 someday in the future adding named, formal parameters.  The current
1069 mechanism's main goal is to let module writers provide better diagnostics
1070 for module users.  Larry feels the notation quite understandable to Perl
1071 programmers, and that it will not intrude greatly upon the meat of the
1072 module, nor make it harder to read.  The line noise is visually
1073 encapsulated into a small pill that's easy to swallow.
1074
1075 If you try to use an alphanumeric sequence in a prototype you will
1076 generate an optional warning - "Illegal character in prototype...".
1077 Unfortunately earlier versions of Perl allowed the prototype to be
1078 used as long as its prefix was a valid prototype.  The warning may be
1079 upgraded to a fatal error in a future version of Perl once the
1080 majority of offending code is fixed.
1081
1082 It's probably best to prototype new functions, not retrofit prototyping
1083 into older ones.  That's because you must be especially careful about
1084 silent impositions of differing list versus scalar contexts.  For example,
1085 if you decide that a function should take just one parameter, like this:
1086
1087     sub func ($) {
1088         my $n = shift;
1089         print "you gave me $n\n";
1090     }
1091
1092 and someone has been calling it with an array or expression
1093 returning a list:
1094
1095     func(@foo);
1096     func( split /:/ );
1097
1098 Then you've just supplied an automatic C<scalar> in front of their
1099 argument, which can be more than a bit surprising.  The old C<@foo>
1100 which used to hold one thing doesn't get passed in.  Instead,
1101 C<func()> now gets passed in a C<1>; that is, the number of elements
1102 in C<@foo>.  And the C<split> gets called in scalar context so it
1103 starts scribbling on your C<@_> parameter list.  Ouch!
1104
1105 This is all very powerful, of course, and should be used only in moderation
1106 to make the world a better place.
1107
1108 =head2 Constant Functions
1109
1110 Functions with a prototype of C<()> are potential candidates for
1111 inlining.  If the result after optimization and constant folding
1112 is either a constant or a lexically-scoped scalar which has no other
1113 references, then it will be used in place of function calls made
1114 without C<&>.  Calls made using C<&> are never inlined.  (See
1115 F<constant.pm> for an easy way to declare most constants.)
1116
1117 The following functions would all be inlined:
1118
1119     sub pi ()           { 3.14159 }             # Not exact, but close.
1120     sub PI ()           { 4 * atan2 1, 1 }      # As good as it gets,
1121                                                 # and it's inlined, too!
1122     sub ST_DEV ()       { 0 }
1123     sub ST_INO ()       { 1 }
1124
1125     sub FLAG_FOO ()     { 1 << 8 }
1126     sub FLAG_BAR ()     { 1 << 9 }
1127     sub FLAG_MASK ()    { FLAG_FOO | FLAG_BAR }
1128
1129     sub OPT_BAZ ()      { not (0x1B58 & FLAG_MASK) }
1130     sub BAZ_VAL () {
1131         if (OPT_BAZ) {
1132             return 23;
1133         }
1134         else {
1135             return 42;
1136         }
1137     }
1138
1139     sub N () { int(BAZ_VAL) / 3 }
1140     BEGIN {
1141         my $prod = 1;
1142         for (1..N) { $prod *= $_ }
1143         sub N_FACTORIAL () { $prod }
1144     }
1145
1146 If you redefine a subroutine that was eligible for inlining, you'll get
1147 a mandatory warning.  (You can use this warning to tell whether or not a
1148 particular subroutine is considered constant.)  The warning is
1149 considered severe enough not to be optional because previously compiled
1150 invocations of the function will still be using the old value of the
1151 function.  If you need to be able to redefine the subroutine, you need to
1152 ensure that it isn't inlined, either by dropping the C<()> prototype
1153 (which changes calling semantics, so beware) or by thwarting the
1154 inlining mechanism in some other way, such as
1155
1156     sub not_inlined () {
1157         23 if $];
1158     }
1159
1160 =head2 Overriding Built-in Functions
1161
1162 Many built-in functions may be overridden, though this should be tried
1163 only occasionally and for good reason.  Typically this might be
1164 done by a package attempting to emulate missing built-in functionality
1165 on a non-Unix system.
1166
1167 Overriding may be done only by importing the name from a module at
1168 compile time--ordinary predeclaration isn't good enough.  However, the
1169 C<use subs> pragma lets you, in effect, predeclare subs
1170 via the import syntax, and these names may then override built-in ones:
1171
1172     use subs 'chdir', 'chroot', 'chmod', 'chown';
1173     chdir $somewhere;
1174     sub chdir { ... }
1175
1176 To unambiguously refer to the built-in form, precede the
1177 built-in name with the special package qualifier C<CORE::>.  For example,
1178 saying C<CORE::open()> always refers to the built-in C<open()>, even
1179 if the current package has imported some other subroutine called
1180 C<&open()> from elsewhere.  Even though it looks like a regular
1181 function call, it isn't: you can't take a reference to it, such as
1182 the incorrect C<\&CORE::open> might appear to produce.
1183
1184 Library modules should not in general export built-in names like C<open>
1185 or C<chdir> as part of their default C<@EXPORT> list, because these may
1186 sneak into someone else's namespace and change the semantics unexpectedly.
1187 Instead, if the module adds that name to C<@EXPORT_OK>, then it's
1188 possible for a user to import the name explicitly, but not implicitly.
1189 That is, they could say
1190
1191     use Module 'open';
1192
1193 and it would import the C<open> override.  But if they said
1194
1195     use Module;
1196
1197 they would get the default imports without overrides.
1198
1199 The foregoing mechanism for overriding built-in is restricted, quite
1200 deliberately, to the package that requests the import.  There is a second
1201 method that is sometimes applicable when you wish to override a built-in
1202 everywhere, without regard to namespace boundaries.  This is achieved by
1203 importing a sub into the special namespace C<CORE::GLOBAL::>.  Here is an
1204 example that quite brazenly replaces the C<glob> operator with something
1205 that understands regular expressions.
1206
1207     package REGlob;
1208     require Exporter;
1209     @ISA = 'Exporter';
1210     @EXPORT_OK = 'glob';
1211
1212     sub import {
1213         my $pkg = shift;
1214         return unless @_;
1215         my $sym = shift;
1216         my $where = ($sym =~ s/^GLOBAL_// ? 'CORE::GLOBAL' : caller(0));
1217         $pkg->export($where, $sym, @_);
1218     }
1219
1220     sub glob {
1221         my $pat = shift;
1222         my @got;
1223         local *D;
1224         if (opendir D, '.') { 
1225             @got = grep /$pat/, readdir D; 
1226             closedir D;   
1227         }
1228         return @got;
1229     }
1230     1;
1231
1232 And here's how it could be (ab)used:
1233
1234     #use REGlob 'GLOBAL_glob';      # override glob() in ALL namespaces
1235     package Foo;
1236     use REGlob 'glob';              # override glob() in Foo:: only
1237     print for <^[a-z_]+\.pm\$>;     # show all pragmatic modules
1238
1239 The initial comment shows a contrived, even dangerous example.
1240 By overriding C<glob> globally, you would be forcing the new (and
1241 subversive) behavior for the C<glob> operator for I<every> namespace,
1242 without the complete cognizance or cooperation of the modules that own
1243 those namespaces.  Naturally, this should be done with extreme caution--if
1244 it must be done at all.
1245
1246 The C<REGlob> example above does not implement all the support needed to
1247 cleanly override perl's C<glob> operator.  The built-in C<glob> has
1248 different behaviors depending on whether it appears in a scalar or list
1249 context, but our C<REGlob> doesn't.  Indeed, many perl built-in have such
1250 context sensitive behaviors, and these must be adequately supported by
1251 a properly written override.  For a fully functional example of overriding
1252 C<glob>, study the implementation of C<File::DosGlob> in the standard
1253 library.
1254
1255 When you override a built-in, your replacement should be consistent (if
1256 possible) with the built-in native syntax.  You can achieve this by using
1257 a suitable prototype.  To get the prototype of an overridable built-in,
1258 use the C<prototype> function with an argument of C<"CORE::builtin_name">
1259 (see L<perlfunc/prototype>).
1260
1261 Note however that some built-ins can't have their syntax expressed by a
1262 prototype (such as C<system> or C<chomp>).  If you override them you won't
1263 be able to fully mimic their original syntax.
1264
1265 The built-ins C<do>, C<require> and C<glob> can also be overridden, but due
1266 to special magic, their original syntax is preserved, and you don't have
1267 to define a prototype for their replacements.  (You can't override the
1268 C<do BLOCK> syntax, though).
1269
1270 C<require> has special additional dark magic: if you invoke your
1271 C<require> replacement as C<require Foo::Bar>, it will actually receive
1272 the argument C<"Foo/Bar.pm"> in @_.  See L<perlfunc/require>.
1273
1274 And, as you'll have noticed from the previous example, if you override
1275 C<glob>, the C<< <*> >> glob operator is overridden as well.
1276
1277 In a similar fashion, overriding the C<readline> function also overrides
1278 the equivalent I/O operator C<< <FILEHANDLE> >>.
1279
1280 Finally, some built-ins (e.g. C<exists> or C<grep>) can't be overridden.
1281
1282 =head2 Autoloading
1283
1284 If you call a subroutine that is undefined, you would ordinarily
1285 get an immediate, fatal error complaining that the subroutine doesn't
1286 exist.  (Likewise for subroutines being used as methods, when the
1287 method doesn't exist in any base class of the class's package.)
1288 However, if an C<AUTOLOAD> subroutine is defined in the package or
1289 packages used to locate the original subroutine, then that
1290 C<AUTOLOAD> subroutine is called with the arguments that would have
1291 been passed to the original subroutine.  The fully qualified name
1292 of the original subroutine magically appears in the global $AUTOLOAD
1293 variable of the same package as the C<AUTOLOAD> routine.  The name
1294 is not passed as an ordinary argument because, er, well, just
1295 because, that's why.  (As an exception, a method call to a nonexistent
1296 C<import> or C<unimport> method is just skipped instead.)
1297
1298 Many C<AUTOLOAD> routines load in a definition for the requested
1299 subroutine using eval(), then execute that subroutine using a special
1300 form of goto() that erases the stack frame of the C<AUTOLOAD> routine
1301 without a trace.  (See the source to the standard module documented
1302 in L<AutoLoader>, for example.)  But an C<AUTOLOAD> routine can
1303 also just emulate the routine and never define it.   For example,
1304 let's pretend that a function that wasn't defined should just invoke
1305 C<system> with those arguments.  All you'd do is:
1306
1307     sub AUTOLOAD {
1308         my $program = $AUTOLOAD;
1309         $program =~ s/.*:://;
1310         system($program, @_);
1311     }
1312     date();
1313     who('am', 'i');
1314     ls('-l');
1315
1316 In fact, if you predeclare functions you want to call that way, you don't
1317 even need parentheses:
1318
1319     use subs qw(date who ls);
1320     date;
1321     who "am", "i";
1322     ls '-l';
1323
1324 A more complete example of this is the standard Shell module, which
1325 can treat undefined subroutine calls as calls to external programs.
1326
1327 Mechanisms are available to help modules writers split their modules
1328 into autoloadable files.  See the standard AutoLoader module
1329 described in L<AutoLoader> and in L<AutoSplit>, the standard
1330 SelfLoader modules in L<SelfLoader>, and the document on adding C
1331 functions to Perl code in L<perlxs>.
1332
1333 =head2 Subroutine Attributes
1334
1335 A subroutine declaration or definition may have a list of attributes
1336 associated with it.  If such an attribute list is present, it is
1337 broken up at space or colon boundaries and treated as though a
1338 C<use attributes> had been seen.  See L<attributes> for details
1339 about what attributes are currently supported.
1340 Unlike the limitation with the obsolescent C<use attrs>, the
1341 C<sub : ATTRLIST> syntax works to associate the attributes with
1342 a pre-declaration, and not just with a subroutine definition.
1343
1344 The attributes must be valid as simple identifier names (without any
1345 punctuation other than the '_' character).  They may have a parameter
1346 list appended, which is only checked for whether its parentheses ('(',')')
1347 nest properly.
1348
1349 Examples of valid syntax (even though the attributes are unknown):
1350
1351     sub fnord (&\%) : switch(10,foo(7,3))  :  expensive ;
1352     sub plugh () : Ugly('\(") :Bad ;
1353     sub xyzzy : _5x5 { ... }
1354
1355 Examples of invalid syntax:
1356
1357     sub fnord : switch(10,foo() ; # ()-string not balanced
1358     sub snoid : Ugly('(') ;       # ()-string not balanced
1359     sub xyzzy : 5x5 ;             # "5x5" not a valid identifier
1360     sub plugh : Y2::north ;       # "Y2::north" not a simple identifier
1361     sub snurt : foo + bar ;       # "+" not a colon or space
1362
1363 The attribute list is passed as a list of constant strings to the code
1364 which associates them with the subroutine.  In particular, the second example
1365 of valid syntax above currently looks like this in terms of how it's
1366 parsed and invoked:
1367
1368     use attributes __PACKAGE__, \&plugh, q[Ugly('\(")], 'Bad';
1369
1370 For further details on attribute lists and their manipulation,
1371 see L<attributes> and L<Attribute::Handlers>.
1372
1373 =head1 SEE ALSO
1374
1375 See L<perlref/"Function Templates"> for more about references and closures.
1376 See L<perlxs> if you'd like to learn about calling C subroutines from Perl.  
1377 See L<perlembed> if you'd like to learn about calling Perl subroutines from C.  
1378 See L<perlmod> to learn about bundling up your functions in separate files.
1379 See L<perlmodlib> to learn what library modules come standard on your system.
1380 See L<perltoot> to learn how to make object method calls.