This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlop: Note that negative rep now warns
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 In Perl, the operator determines what operation is performed,
9 independent of the type of the operands. For example C<$a + $b>
10 is always a numeric addition, and if C<$a> or C<$b> do not contain
11 numbers, an attempt is made to convert them to numbers first.
12
13 This is in contrast to many other dynamic languages, where the
14 operation is determined by the type of the first argument. It also
15 means that Perl has two versions of some operators, one for numeric
16 and one for string comparison. For example C<$a == $b> compares
17 two numbers for equality, and C<$a eq $b> compares two strings.
18
19 There are a few exceptions though: C<x> can be either string
20 repetition or list repetition, depending on the type of the left
21 operand, and C<&>, C<|> and C<^> can be either string or numeric bit
22 operations.
23
24 =head2 Operator Precedence and Associativity
25 X<operator, precedence> X<precedence> X<associativity>
26
27 Operator precedence and associativity work in Perl more or less like
28 they do in mathematics.
29
30 I<Operator precedence> means some operators are evaluated before
31 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
32 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
33 22> and not C<6 * 5 == 30>.
34
35 I<Operator associativity> defines what happens if a sequence of the
36 same operators is used one after another: whether the evaluator will
37 evaluate the left operations first or the right.  For example, in C<8
38 - 4 - 2>, subtraction is left associative so Perl evaluates the
39 expression left to right.  C<8 - 4> is evaluated first making the
40 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
41
42 Perl operators have the following associativity and precedence,
43 listed from highest precedence to lowest.  Operators borrowed from
44 C keep the same precedence relationship with each other, even where
45 C's precedence is slightly screwy.  (This makes learning Perl easier
46 for C folks.)  With very few exceptions, these all operate on scalar
47 values only, not array values.
48
49     left        terms and list operators (leftward)
50     left        ->
51     nonassoc    ++ --
52     right       **
53     right       ! ~ \ and unary + and -
54     left        =~ !~
55     left        * / % x
56     left        + - .
57     left        << >>
58     nonassoc    named unary operators
59     nonassoc    < > <= >= lt gt le ge
60     nonassoc    == != <=> eq ne cmp ~~
61     left        &
62     left        | ^
63     left        &&
64     left        || //
65     nonassoc    ..  ...
66     right       ?:
67     right       = += -= *= etc. goto last next redo dump
68     left        , =>
69     nonassoc    list operators (rightward)
70     right       not
71     left        and
72     left        or xor
73
74 In the following sections, these operators are covered in precedence order.
75
76 Many operators can be overloaded for objects.  See L<overload>.
77
78 =head2 Terms and List Operators (Leftward)
79 X<list operator> X<operator, list> X<term>
80
81 A TERM has the highest precedence in Perl.  They include variables,
82 quote and quote-like operators, any expression in parentheses,
83 and any function whose arguments are parenthesized.  Actually, there
84 aren't really functions in this sense, just list operators and unary
85 operators behaving as functions because you put parentheses around
86 the arguments.  These are all documented in L<perlfunc>.
87
88 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
89 is followed by a left parenthesis as the next token, the operator and
90 arguments within parentheses are taken to be of highest precedence,
91 just like a normal function call.
92
93 In the absence of parentheses, the precedence of list operators such as
94 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
95 whether you are looking at the left side or the right side of the operator.
96 For example, in
97
98     @ary = (1, 3, sort 4, 2);
99     print @ary;         # prints 1324
100
101 the commas on the right of the sort are evaluated before the sort,
102 but the commas on the left are evaluated after.  In other words,
103 list operators tend to gobble up all arguments that follow, and
104 then act like a simple TERM with regard to the preceding expression.
105 Be careful with parentheses:
106
107     # These evaluate exit before doing the print:
108     print($foo, exit);  # Obviously not what you want.
109     print $foo, exit;   # Nor is this.
110
111     # These do the print before evaluating exit:
112     (print $foo), exit; # This is what you want.
113     print($foo), exit;  # Or this.
114     print ($foo), exit; # Or even this.
115
116 Also note that
117
118     print ($foo & 255) + 1, "\n";
119
120 probably doesn't do what you expect at first glance.  The parentheses
121 enclose the argument list for C<print> which is evaluated (printing
122 the result of C<$foo & 255>).  Then one is added to the return value
123 of C<print> (usually 1).  The result is something like this:
124
125     1 + 1, "\n";    # Obviously not what you meant.
126
127 To do what you meant properly, you must write:
128
129     print(($foo & 255) + 1, "\n");
130
131 See L<Named Unary Operators> for more discussion of this.
132
133 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
134 well as subroutine and method calls, and the anonymous
135 constructors C<[]> and C<{}>.
136
137 See also L<Quote and Quote-like Operators> toward the end of this section,
138 as well as L</"I/O Operators">.
139
140 =head2 The Arrow Operator
141 X<arrow> X<dereference> X<< -> >>
142
143 "C<< -> >>" is an infix dereference operator, just as it is in C
144 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
145 C<(...)> subscript, then the left side must be either a hard or
146 symbolic reference to an array, a hash, or a subroutine respectively.
147 (Or technically speaking, a location capable of holding a hard
148 reference, if it's an array or hash reference being used for
149 assignment.)  See L<perlreftut> and L<perlref>.
150
151 Otherwise, the right side is a method name or a simple scalar
152 variable containing either the method name or a subroutine reference,
153 and the left side must be either an object (a blessed reference)
154 or a class name (that is, a package name).  See L<perlobj>.
155
156 The dereferencing cases (as opposed to method-calling cases) are
157 somewhat extended by the experimental C<postderef> feature.  For the
158 details of that feature, consult L<perlref/Postfix Dereference Syntax>.
159
160 =head2 Auto-increment and Auto-decrement
161 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
162
163 "++" and "--" work as in C.  That is, if placed before a variable,
164 they increment or decrement the variable by one before returning the
165 value, and if placed after, increment or decrement after returning the
166 value.
167
168     $i = 0;  $j = 0;
169     print $i++;  # prints 0
170     print ++$j;  # prints 1
171
172 Note that just as in C, Perl doesn't define B<when> the variable is
173 incremented or decremented. You just know it will be done sometime
174 before or after the value is returned. This also means that modifying
175 a variable twice in the same statement will lead to undefined behavior.
176 Avoid statements like:
177
178     $i = $i ++;
179     print ++ $i + $i ++;
180
181 Perl will not guarantee what the result of the above statements is.
182
183 The auto-increment operator has a little extra builtin magic to it.  If
184 you increment a variable that is numeric, or that has ever been used in
185 a numeric context, you get a normal increment.  If, however, the
186 variable has been used in only string contexts since it was set, and
187 has a value that is not the empty string and matches the pattern
188 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
189 character within its range, with carry:
190
191     print ++($foo = "99");      # prints "100"
192     print ++($foo = "a0");      # prints "a1"
193     print ++($foo = "Az");      # prints "Ba"
194     print ++($foo = "zz");      # prints "aaa"
195
196 C<undef> is always treated as numeric, and in particular is changed
197 to C<0> before incrementing (so that a post-increment of an undef value
198 will return C<0> rather than C<undef>).
199
200 The auto-decrement operator is not magical.
201
202 =head2 Exponentiation
203 X<**> X<exponentiation> X<power>
204
205 Binary "**" is the exponentiation operator.  It binds even more
206 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
207 implemented using C's pow(3) function, which actually works on doubles
208 internally.)
209
210 =head2 Symbolic Unary Operators
211 X<unary operator> X<operator, unary>
212
213 Unary "!" performs logical negation, that is, "not".  See also C<not> for a lower
214 precedence version of this.
215 X<!>
216
217 Unary "-" performs arithmetic negation if the operand is numeric,
218 including any string that looks like a number.  If the operand is
219 an identifier, a string consisting of a minus sign concatenated
220 with the identifier is returned.  Otherwise, if the string starts
221 with a plus or minus, a string starting with the opposite sign is
222 returned.  One effect of these rules is that -bareword is equivalent
223 to the string "-bareword".  If, however, the string begins with a
224 non-alphabetic character (excluding "+" or "-"), Perl will attempt to convert
225 the string to a numeric and the arithmetic negation is performed. If the
226 string cannot be cleanly converted to a numeric, Perl will give the warning
227 B<Argument "the string" isn't numeric in negation (-) at ...>.
228 X<-> X<negation, arithmetic>
229
230 Unary "~" performs bitwise negation, that is, 1's complement.  For
231 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
232 L<Bitwise String Operators>.)  Note that the width of the result is
233 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
234 bits wide on a 64-bit platform, so if you are expecting a certain bit
235 width, remember to use the "&" operator to mask off the excess bits.
236 X<~> X<negation, binary>
237
238 When complementing strings, if all characters have ordinal values under
239 256, then their complements will, also.  But if they do not, all
240 characters will be in either 32- or 64-bit complements, depending on your
241 architecture.  So for example, C<~"\x{3B1}"> is C<"\x{FFFF_FC4E}"> on
242 32-bit machines and C<"\x{FFFF_FFFF_FFFF_FC4E}"> on 64-bit machines.
243
244 Unary "+" has no effect whatsoever, even on strings.  It is useful
245 syntactically for separating a function name from a parenthesized expression
246 that would otherwise be interpreted as the complete list of function
247 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
248 X<+>
249
250 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
251 and L<perlref>.  Do not confuse this behavior with the behavior of
252 backslash within a string, although both forms do convey the notion
253 of protecting the next thing from interpolation.
254 X<\> X<reference> X<backslash>
255
256 =head2 Binding Operators
257 X<binding> X<operator, binding> X<=~> X<!~>
258
259 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
260 search or modify the string $_ by default.  This operator makes that kind
261 of operation work on some other string.  The right argument is a search
262 pattern, substitution, or transliteration.  The left argument is what is
263 supposed to be searched, substituted, or transliterated instead of the default
264 $_.  When used in scalar context, the return value generally indicates the
265 success of the operation.  The exceptions are substitution (s///)
266 and transliteration (y///) with the C</r> (non-destructive) option,
267 which cause the B<r>eturn value to be the result of the substitution.
268 Behavior in list context depends on the particular operator.
269 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
270 examples using these operators.
271
272 If the right argument is an expression rather than a search pattern,
273 substitution, or transliteration, it is interpreted as a search pattern at run
274 time. Note that this means that its contents will be interpolated twice, so
275
276     '\\' =~ q'\\';
277
278 is not ok, as the regex engine will end up trying to compile the
279 pattern C<\>, which it will consider a syntax error.
280
281 Binary "!~" is just like "=~" except the return value is negated in
282 the logical sense.
283
284 Binary "!~" with a non-destructive substitution (s///r) or transliteration
285 (y///r) is a syntax error.
286
287 =head2 Multiplicative Operators
288 X<operator, multiplicative>
289
290 Binary "*" multiplies two numbers.
291 X<*>
292
293 Binary "/" divides two numbers.
294 X</> X<slash>
295
296 Binary "%" is the modulo operator, which computes the division
297 remainder of its first argument with respect to its second argument.
298 Given integer
299 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
300 C<$a> minus the largest multiple of C<$b> less than or equal to
301 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
302 smallest multiple of C<$b> that is not less than C<$a> (that is, the
303 result will be less than or equal to zero).  If the operands
304 C<$a> and C<$b> are floating point values and the absolute value of
305 C<$b> (that is C<abs($b)>) is less than C<(UV_MAX + 1)>, only
306 the integer portion of C<$a> and C<$b> will be used in the operation
307 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
308 If the absolute value of the right operand (C<abs($b)>) is greater than
309 or equal to C<(UV_MAX + 1)>, "%" computes the floating-point remainder
310 C<$r> in the equation C<($r = $a - $i*$b)> where C<$i> is a certain
311 integer that makes C<$r> have the same sign as the right operand
312 C<$b> (B<not> as the left operand C<$a> like C function C<fmod()>)
313 and the absolute value less than that of C<$b>.
314 Note that when C<use integer> is in scope, "%" gives you direct access
315 to the modulo operator as implemented by your C compiler.  This
316 operator is not as well defined for negative operands, but it will
317 execute faster.
318 X<%> X<remainder> X<modulo> X<mod>
319
320 Binary "x" is the repetition operator.  In scalar context or if the left
321 operand is not enclosed in parentheses, it returns a string consisting
322 of the left operand repeated the number of times specified by the right
323 operand.  In list context, if the left operand is enclosed in
324 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
325 If the right operand is zero or negative (raising a warning on
326 negative), it returns an empty string
327 or an empty list, depending on the context.
328 X<x>
329
330     print '-' x 80;             # print row of dashes
331
332     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
333
334     @ones = (1) x 80;           # a list of 80 1's
335     @ones = (5) x @ones;        # set all elements to 5
336
337
338 =head2 Additive Operators
339 X<operator, additive>
340
341 Binary C<+> returns the sum of two numbers.
342 X<+>
343
344 Binary C<-> returns the difference of two numbers.
345 X<->
346
347 Binary C<.> concatenates two strings.
348 X<string, concatenation> X<concatenation>
349 X<cat> X<concat> X<concatenate> X<.>
350
351 =head2 Shift Operators
352 X<shift operator> X<operator, shift> X<<< << >>>
353 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
354 X<shl> X<shr> X<shift, right> X<shift, left>
355
356 Binary C<<< << >>> returns the value of its left argument shifted left by the
357 number of bits specified by the right argument.  Arguments should be
358 integers.  (See also L<Integer Arithmetic>.)
359
360 Binary C<<< >> >>> returns the value of its left argument shifted right by
361 the number of bits specified by the right argument.  Arguments should
362 be integers.  (See also L<Integer Arithmetic>.)
363
364 Note that both C<<< << >>> and C<<< >> >>> in Perl are implemented directly using
365 C<<< << >>> and C<<< >> >>>  in C.  If C<use integer> (see L<Integer Arithmetic>) is
366 in force then signed C integers are used, else unsigned C integers are
367 used.  Either way, the implementation isn't going to generate results
368 larger than the size of the integer type Perl was built with (32 bits
369 or 64 bits).
370
371 The result of overflowing the range of the integers is undefined
372 because it is undefined also in C.  In other words, using 32-bit
373 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
374 of bits is also undefined.
375
376 If you get tired of being subject to your platform's native integers,
377 the C<use bigint> pragma neatly sidesteps the issue altogether:
378
379     print 20 << 20;  # 20971520
380     print 20 << 40;  # 5120 on 32-bit machines, 
381                      # 21990232555520 on 64-bit machines
382     use bigint;
383     print 20 << 100; # 25353012004564588029934064107520
384
385 =head2 Named Unary Operators
386 X<operator, named unary>
387
388 The various named unary operators are treated as functions with one
389 argument, with optional parentheses.
390
391 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
392 is followed by a left parenthesis as the next token, the operator and
393 arguments within parentheses are taken to be of highest precedence,
394 just like a normal function call.  For example,
395 because named unary operators are higher precedence than C<||>:
396
397     chdir $foo    || die;       # (chdir $foo) || die
398     chdir($foo)   || die;       # (chdir $foo) || die
399     chdir ($foo)  || die;       # (chdir $foo) || die
400     chdir +($foo) || die;       # (chdir $foo) || die
401
402 but, because * is higher precedence than named operators:
403
404     chdir $foo * 20;    # chdir ($foo * 20)
405     chdir($foo) * 20;   # (chdir $foo) * 20
406     chdir ($foo) * 20;  # (chdir $foo) * 20
407     chdir +($foo) * 20; # chdir ($foo * 20)
408
409     rand 10 * 20;       # rand (10 * 20)
410     rand(10) * 20;      # (rand 10) * 20
411     rand (10) * 20;     # (rand 10) * 20
412     rand +(10) * 20;    # rand (10 * 20)
413
414 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
415 treated like named unary operators, but they don't follow this functional
416 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
417 equivalent to C<-f "$file.bak">.
418 X<-X> X<filetest> X<operator, filetest>
419
420 See also L<"Terms and List Operators (Leftward)">.
421
422 =head2 Relational Operators
423 X<relational operator> X<operator, relational>
424
425 Perl operators that return true or false generally return values 
426 that can be safely used as numbers.  For example, the relational
427 operators in this section and the equality operators in the next
428 one return C<1> for true and a special version of the defined empty
429 string, C<"">, which counts as a zero but is exempt from warnings
430 about improper numeric conversions, just as C<"0 but true"> is.
431
432 Binary "<" returns true if the left argument is numerically less than
433 the right argument.
434 X<< < >>
435
436 Binary ">" returns true if the left argument is numerically greater
437 than the right argument.
438 X<< > >>
439
440 Binary "<=" returns true if the left argument is numerically less than
441 or equal to the right argument.
442 X<< <= >>
443
444 Binary ">=" returns true if the left argument is numerically greater
445 than or equal to the right argument.
446 X<< >= >>
447
448 Binary "lt" returns true if the left argument is stringwise less than
449 the right argument.
450 X<< lt >>
451
452 Binary "gt" returns true if the left argument is stringwise greater
453 than the right argument.
454 X<< gt >>
455
456 Binary "le" returns true if the left argument is stringwise less than
457 or equal to the right argument.
458 X<< le >>
459
460 Binary "ge" returns true if the left argument is stringwise greater
461 than or equal to the right argument.
462 X<< ge >>
463
464 =head2 Equality Operators
465 X<equality> X<equal> X<equals> X<operator, equality>
466
467 Binary "==" returns true if the left argument is numerically equal to
468 the right argument.
469 X<==>
470
471 Binary "!=" returns true if the left argument is numerically not equal
472 to the right argument.
473 X<!=>
474
475 Binary "<=>" returns -1, 0, or 1 depending on whether the left
476 argument is numerically less than, equal to, or greater than the right
477 argument.  If your platform supports NaNs (not-a-numbers) as numeric
478 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
479 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
480 returns true, as does NaN != anything else. If your platform doesn't
481 support NaNs then NaN is just a string with numeric value 0.
482 X<< <=> >> X<spaceship>
483
484     $ perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
485     $ perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
486
487 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all 
488 support "NaN".)
489
490 Binary "eq" returns true if the left argument is stringwise equal to
491 the right argument.
492 X<eq>
493
494 Binary "ne" returns true if the left argument is stringwise not equal
495 to the right argument.
496 X<ne>
497
498 Binary "cmp" returns -1, 0, or 1 depending on whether the left
499 argument is stringwise less than, equal to, or greater than the right
500 argument.
501 X<cmp>
502
503 Binary "~~" does a smartmatch between its arguments.  Smart matching
504 is described in the next section.
505 X<~~>
506
507 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
508 by the current locale if a legacy C<use locale> (but not
509 C<use locale ':not_characters'>) is in effect.  See
510 L<perllocale>.  Do not mix these with Unicode, only with legacy binary
511 encodings.  The standard L<Unicode::Collate> and
512 L<Unicode::Collate::Locale> modules offer much more powerful solutions to
513 collation issues.
514
515 =head2 Smartmatch Operator
516
517 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
518 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
519 used implicitly in the C<when> construct described in L<perlsyn>, although
520 not all C<when> clauses call the smartmatch operator.  Unique among all of
521 Perl's operators, the smartmatch operator can recurse.  The smartmatch
522 operator is L<experimental|perlpolicy/experimental> and its behavior is
523 subject to change.
524
525 It is also unique in that all other Perl operators impose a context
526 (usually string or numeric context) on their operands, autoconverting
527 those operands to those imposed contexts.  In contrast, smartmatch
528 I<infers> contexts from the actual types of its operands and uses that
529 type information to select a suitable comparison mechanism.
530
531 The C<~~> operator compares its operands "polymorphically", determining how
532 to compare them according to their actual types (numeric, string, array,
533 hash, etc.)  Like the equality operators with which it shares the same
534 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
535 read aloud as "in", "inside of", or "is contained in", because the left
536 operand is often looked for I<inside> the right operand.  That makes the
537 order of the operands to the smartmatch operand often opposite that of
538 the regular match operator.  In other words, the "smaller" thing is usually
539 placed in the left operand and the larger one in the right.
540
541 The behavior of a smartmatch depends on what type of things its arguments
542 are, as determined by the following table.  The first row of the table
543 whose types apply determines the smartmatch behavior.  Because what
544 actually happens is mostly determined by the type of the second operand,
545 the table is sorted on the right operand instead of on the left.
546
547  Left      Right      Description and pseudocode                               
548  ===============================================================
549  Any       undef      check whether Any is undefined                    
550                 like: !defined Any
551
552  Any       Object     invoke ~~ overloading on Object, or die
553
554  Right operand is an ARRAY:
555
556  Left      Right      Description and pseudocode                               
557  ===============================================================
558  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
559                 like: (ARRAY1[0] ~~ ARRAY2[0])
560                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
561  HASH      ARRAY      any ARRAY elements exist as HASH keys             
562                 like: grep { exists HASH->{$_} } ARRAY
563  Regexp    ARRAY      any ARRAY elements pattern match Regexp
564                 like: grep { /Regexp/ } ARRAY
565  undef     ARRAY      undef in ARRAY                                    
566                 like: grep { !defined } ARRAY
567  Any       ARRAY      smartmatch each ARRAY element[3]                   
568                 like: grep { Any ~~ $_ } ARRAY
569
570  Right operand is a HASH:
571
572  Left      Right      Description and pseudocode                               
573  ===============================================================
574  HASH1     HASH2      all same keys in both HASHes                      
575                 like: keys HASH1 ==
576                          grep { exists HASH2->{$_} } keys HASH1
577  ARRAY     HASH       any ARRAY elements exist as HASH keys             
578                 like: grep { exists HASH->{$_} } ARRAY
579  Regexp    HASH       any HASH keys pattern match Regexp                
580                 like: grep { /Regexp/ } keys HASH
581  undef     HASH       always false (undef can't be a key)               
582                 like: 0 == 1
583  Any       HASH       HASH key existence                                
584                 like: exists HASH->{Any}
585
586  Right operand is CODE:
587
588  Left      Right      Description and pseudocode                               
589  ===============================================================
590  ARRAY     CODE       sub returns true on all ARRAY elements[1]
591                 like: !grep { !CODE->($_) } ARRAY
592  HASH      CODE       sub returns true on all HASH keys[1]
593                 like: !grep { !CODE->($_) } keys HASH
594  Any       CODE       sub passed Any returns true              
595                 like: CODE->(Any)
596
597 Right operand is a Regexp:
598
599  Left      Right      Description and pseudocode                               
600  ===============================================================
601  ARRAY     Regexp     any ARRAY elements match Regexp                   
602                 like: grep { /Regexp/ } ARRAY
603  HASH      Regexp     any HASH keys match Regexp                        
604                 like: grep { /Regexp/ } keys HASH
605  Any       Regexp     pattern match                                     
606                 like: Any =~ /Regexp/
607
608  Other:
609
610  Left      Right      Description and pseudocode                               
611  ===============================================================
612  Object    Any        invoke ~~ overloading on Object,
613                       or fall back to...
614
615  Any       Num        numeric equality                                  
616                  like: Any == Num
617  Num       nummy[4]    numeric equality
618                  like: Num == nummy
619  undef     Any        check whether undefined
620                  like: !defined(Any)
621  Any       Any        string equality                                   
622                  like: Any eq Any
623
624
625 Notes:
626
627 =over
628
629 =item 1.
630 Empty hashes or arrays match. 
631
632 =item 2.
633 That is, each element smartmatches the element of the same index in the other array.[3]
634
635 =item 3.
636 If a circular reference is found, fall back to referential equality. 
637
638 =item 4.
639 Either an actual number, or a string that looks like one.
640
641 =back
642
643 The smartmatch implicitly dereferences any non-blessed hash or array
644 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
645 For blessed references, the C<I<Object>> entries apply.  Smartmatches
646 involving hashes only consider hash keys, never hash values.
647
648 The "like" code entry is not always an exact rendition.  For example, the
649 smartmatch operator short-circuits whenever possible, but C<grep> does
650 not.  Also, C<grep> in scalar context returns the number of matches, but
651 C<~~> returns only true or false.
652
653 Unlike most operators, the smartmatch operator knows to treat C<undef>
654 specially:
655
656     use v5.10.1;
657     @array = (1, 2, 3, undef, 4, 5);
658     say "some elements undefined" if undef ~~ @array;
659
660 Each operand is considered in a modified scalar context, the modification
661 being that array and hash variables are passed by reference to the
662 operator, which implicitly dereferences them.  Both elements
663 of each pair are the same:
664
665     use v5.10.1;
666
667     my %hash = (red    => 1, blue   => 2, green  => 3,
668                 orange => 4, yellow => 5, purple => 6,
669                 black  => 7, grey   => 8, white  => 9);
670
671     my @array = qw(red blue green);
672
673     say "some array elements in hash keys" if  @array ~~  %hash;
674     say "some array elements in hash keys" if \@array ~~ \%hash;
675
676     say "red in array" if "red" ~~  @array;
677     say "red in array" if "red" ~~ \@array;
678
679     say "some keys end in e" if /e$/ ~~  %hash;
680     say "some keys end in e" if /e$/ ~~ \%hash;
681
682 Two arrays smartmatch if each element in the first array smartmatches
683 (that is, is "in") the corresponding element in the second array,
684 recursively.
685
686     use v5.10.1;
687     my @little = qw(red blue green);
688     my @bigger = ("red", "blue", [ "orange", "green" ] );
689     if (@little ~~ @bigger) {  # true!
690         say "little is contained in bigger";
691     } 
692
693 Because the smartmatch operator recurses on nested arrays, this
694 will still report that "red" is in the array.
695
696     use v5.10.1;
697     my @array = qw(red blue green);
698     my $nested_array = [[[[[[[ @array ]]]]]]];
699     say "red in array" if "red" ~~ $nested_array;
700
701 If two arrays smartmatch each other, then they are deep
702 copies of each others' values, as this example reports:
703
704     use v5.12.0;
705     my @a = (0, 1, 2, [3, [4, 5], 6], 7); 
706     my @b = (0, 1, 2, [3, [4, 5], 6], 7); 
707
708     if (@a ~~ @b && @b ~~ @a) {
709         say "a and b are deep copies of each other";
710     } 
711     elsif (@a ~~ @b) {
712         say "a smartmatches in b";
713     } 
714     elsif (@b ~~ @a) {
715         say "b smartmatches in a";
716     } 
717     else {
718         say "a and b don't smartmatch each other at all";
719     } 
720
721
722 If you were to set C<$b[3] = 4>, then instead of reporting that "a and b
723 are deep copies of each other", it now reports that "b smartmatches in a".
724 That because the corresponding position in C<@a> contains an array that
725 (eventually) has a 4 in it.
726
727 Smartmatching one hash against another reports whether both contain the
728 same keys, no more and no less. This could be used to see whether two
729 records have the same field names, without caring what values those fields
730 might have.  For example:
731
732     use v5.10.1;
733     sub make_dogtag {
734         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
735
736         my ($class, $init_fields) = @_;
737
738         die "Must supply (only) name, rank, and serial number"
739             unless $init_fields ~~ $REQUIRED_FIELDS;
740
741         ...
742     }
743
744 or, if other non-required fields are allowed, use ARRAY ~~ HASH:
745
746     use v5.10.1;
747     sub make_dogtag {
748         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
749
750         my ($class, $init_fields) = @_;
751
752         die "Must supply (at least) name, rank, and serial number"
753             unless [keys %{$init_fields}] ~~ $REQUIRED_FIELDS;
754
755         ...
756     }
757
758 The smartmatch operator is most often used as the implicit operator of a
759 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
760
761 =head3 Smartmatching of Objects
762
763 To avoid relying on an object's underlying representation, if the
764 smartmatch's right operand is an object that doesn't overload C<~~>,
765 it raises the exception "C<Smartmatching a non-overloaded object
766 breaks encapsulation>". That's because one has no business digging
767 around to see whether something is "in" an object. These are all
768 illegal on objects without a C<~~> overload:
769
770     %hash ~~ $object
771        42 ~~ $object
772    "fred" ~~ $object
773
774 However, you can change the way an object is smartmatched by overloading
775 the C<~~> operator. This is allowed to extend the usual smartmatch semantics.
776 For objects that do have an C<~~> overload, see L<overload>.
777
778 Using an object as the left operand is allowed, although not very useful.
779 Smartmatching rules take precedence over overloading, so even if the
780 object in the left operand has smartmatch overloading, this will be
781 ignored.  A left operand that is a non-overloaded object falls back on a
782 string or numeric comparison of whatever the C<ref> operator returns.  That
783 means that
784
785     $object ~~ X
786
787 does I<not> invoke the overload method with C<I<X>> as an argument.
788 Instead the above table is consulted as normal, and based on the type of
789 C<I<X>>, overloading may or may not be invoked.  For simple strings or
790 numbers, in becomes equivalent to this:
791
792     $object ~~ $number          ref($object) == $number
793     $object ~~ $string          ref($object) eq $string 
794
795 For example, this reports that the handle smells IOish
796 (but please don't really do this!):
797
798     use IO::Handle;
799     my $fh = IO::Handle->new();
800     if ($fh ~~ /\bIO\b/) {
801         say "handle smells IOish";
802     } 
803
804 That's because it treats C<$fh> as a string like
805 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
806
807 =head2 Bitwise And
808 X<operator, bitwise, and> X<bitwise and> X<&>
809
810 Binary "&" returns its operands ANDed together bit by bit.  Although no
811 warning is currently raised, the result is not well defined when this operation
812 is performed on operands that aren't either numbers (see
813 L<Integer Arithmetic>) or bitstrings (see L<Bitwise String Operators>).
814
815 Note that "&" has lower priority than relational operators, so for example
816 the parentheses are essential in a test like
817
818     print "Even\n" if ($x & 1) == 0;
819
820 =head2 Bitwise Or and Exclusive Or
821 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
822 X<bitwise xor> X<^>
823
824 Binary "|" returns its operands ORed together bit by bit.
825
826 Binary "^" returns its operands XORed together bit by bit.
827
828 Although no warning is currently raised, the results are not well
829 defined when these operations are performed on operands that aren't either
830 numbers (see L<Integer Arithmetic>) or bitstrings (see L<Bitwise String
831 Operators>).
832
833 Note that "|" and "^" have lower priority than relational operators, so
834 for example the brackets are essential in a test like
835
836     print "false\n" if (8 | 2) != 10;
837
838 =head2 C-style Logical And
839 X<&&> X<logical and> X<operator, logical, and>
840
841 Binary "&&" performs a short-circuit logical AND operation.  That is,
842 if the left operand is false, the right operand is not even evaluated.
843 Scalar or list context propagates down to the right operand if it
844 is evaluated.
845
846 =head2 C-style Logical Or
847 X<||> X<operator, logical, or>
848
849 Binary "||" performs a short-circuit logical OR operation.  That is,
850 if the left operand is true, the right operand is not even evaluated.
851 Scalar or list context propagates down to the right operand if it
852 is evaluated.
853
854 =head2 Logical Defined-Or
855 X<//> X<operator, logical, defined-or>
856
857 Although it has no direct equivalent in C, Perl's C<//> operator is related
858 to its C-style or.  In fact, it's exactly the same as C<||>, except that it
859 tests the left hand side's definedness instead of its truth.  Thus,
860 C<< EXPR1 // EXPR2 >> returns the value of C<< EXPR1 >> if it's defined,
861 otherwise, the value of C<< EXPR2 >> is returned. (C<< EXPR1 >> is evaluated
862 in scalar context, C<< EXPR2 >> in the context of C<< // >> itself). Usually,
863 this is the same result as C<< defined(EXPR1) ? EXPR1 : EXPR2 >> (except that
864 the ternary-operator form can be used as a lvalue, while C<< EXPR1 // EXPR2 >>
865 cannot). This is very useful for
866 providing default values for variables.  If you actually want to test if
867 at least one of C<$a> and C<$b> is defined, use C<defined($a // $b)>.
868
869 The C<||>, C<//> and C<&&> operators return the last value evaluated
870 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
871 portable way to find out the home directory might be:
872
873     $home =  $ENV{HOME}
874           // $ENV{LOGDIR}
875           // (getpwuid($<))[7]
876           // die "You're homeless!\n";
877
878 In particular, this means that you shouldn't use this
879 for selecting between two aggregates for assignment:
880
881     @a = @b || @c;              # this is wrong
882     @a = scalar(@b) || @c;      # really meant this
883     @a = @b ? @b : @c;          # this works fine, though
884
885 As alternatives to C<&&> and C<||> when used for
886 control flow, Perl provides the C<and> and C<or> operators (see below).
887 The short-circuit behavior is identical.  The precedence of "and"
888 and "or" is much lower, however, so that you can safely use them after a
889 list operator without the need for parentheses:
890
891     unlink "alpha", "beta", "gamma"
892             or gripe(), next LINE;
893
894 With the C-style operators that would have been written like this:
895
896     unlink("alpha", "beta", "gamma")
897             || (gripe(), next LINE);
898
899 It would be even more readable to write that this way:
900
901     unless(unlink("alpha", "beta", "gamma")) {
902         gripe();
903         next LINE;
904     } 
905
906 Using "or" for assignment is unlikely to do what you want; see below.
907
908 =head2 Range Operators
909 X<operator, range> X<range> X<..> X<...>
910
911 Binary ".." is the range operator, which is really two different
912 operators depending on the context.  In list context, it returns a
913 list of values counting (up by ones) from the left value to the right
914 value.  If the left value is greater than the right value then it
915 returns the empty list.  The range operator is useful for writing
916 C<foreach (1..10)> loops and for doing slice operations on arrays. In
917 the current implementation, no temporary array is created when the
918 range operator is used as the expression in C<foreach> loops, but older
919 versions of Perl might burn a lot of memory when you write something
920 like this:
921
922     for (1 .. 1_000_000) {
923         # code
924     }
925
926 The range operator also works on strings, using the magical
927 auto-increment, see below.
928
929 In scalar context, ".." returns a boolean value.  The operator is
930 bistable, like a flip-flop, and emulates the line-range (comma)
931 operator of B<sed>, B<awk>, and various editors. Each ".." operator
932 maintains its own boolean state, even across calls to a subroutine
933 that contains it. It is false as long as its left operand is false.
934 Once the left operand is true, the range operator stays true until the
935 right operand is true, I<AFTER> which the range operator becomes false
936 again.  It doesn't become false till the next time the range operator
937 is evaluated.  It can test the right operand and become false on the
938 same evaluation it became true (as in B<awk>), but it still returns
939 true once. If you don't want it to test the right operand until the
940 next evaluation, as in B<sed>, just use three dots ("...") instead of
941 two.  In all other regards, "..." behaves just like ".." does.
942
943 The right operand is not evaluated while the operator is in the
944 "false" state, and the left operand is not evaluated while the
945 operator is in the "true" state.  The precedence is a little lower
946 than || and &&.  The value returned is either the empty string for
947 false, or a sequence number (beginning with 1) for true.  The sequence
948 number is reset for each range encountered.  The final sequence number
949 in a range has the string "E0" appended to it, which doesn't affect
950 its numeric value, but gives you something to search for if you want
951 to exclude the endpoint.  You can exclude the beginning point by
952 waiting for the sequence number to be greater than 1.
953
954 If either operand of scalar ".." is a constant expression,
955 that operand is considered true if it is equal (C<==>) to the current
956 input line number (the C<$.> variable).
957
958 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
959 but that is only an issue if you use a floating point expression; when
960 implicitly using C<$.> as described in the previous paragraph, the
961 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
962 is set to a floating point value and you are not reading from a file.
963 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
964 you want in scalar context because each of the operands are evaluated
965 using their integer representation.
966
967 Examples:
968
969 As a scalar operator:
970
971     if (101 .. 200) { print; } # print 2nd hundred lines, short for
972                                #  if ($. == 101 .. $. == 200) { print; }
973
974     next LINE if (1 .. /^$/);  # skip header lines, short for
975                                #   next LINE if ($. == 1 .. /^$/);
976                                # (typically in a loop labeled LINE)
977
978     s/^/> / if (/^$/ .. eof());  # quote body
979
980     # parse mail messages
981     while (<>) {
982         $in_header =   1  .. /^$/;
983         $in_body   = /^$/ .. eof;
984         if ($in_header) {
985             # do something
986         } else { # in body
987             # do something else
988         }
989     } continue {
990         close ARGV if eof;             # reset $. each file
991     }
992
993 Here's a simple example to illustrate the difference between
994 the two range operators:
995
996     @lines = ("   - Foo",
997               "01 - Bar",
998               "1  - Baz",
999               "   - Quux");
1000
1001     foreach (@lines) {
1002         if (/0/ .. /1/) {
1003             print "$_\n";
1004         }
1005     }
1006
1007 This program will print only the line containing "Bar". If
1008 the range operator is changed to C<...>, it will also print the
1009 "Baz" line.
1010
1011 And now some examples as a list operator:
1012
1013     for (101 .. 200) { print }      # print $_ 100 times
1014     @foo = @foo[0 .. $#foo];        # an expensive no-op
1015     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
1016
1017 The range operator (in list context) makes use of the magical
1018 auto-increment algorithm if the operands are strings.  You
1019 can say
1020
1021     @alphabet = ("A" .. "Z");
1022
1023 to get all normal letters of the English alphabet, or
1024
1025     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
1026
1027 to get a hexadecimal digit, or
1028
1029     @z2 = ("01" .. "31");
1030     print $z2[$mday];
1031
1032 to get dates with leading zeros.
1033
1034 If the final value specified is not in the sequence that the magical
1035 increment would produce, the sequence goes until the next value would
1036 be longer than the final value specified.
1037
1038 If the initial value specified isn't part of a magical increment
1039 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1040 only the initial value will be returned.  So the following will only
1041 return an alpha:
1042
1043     use charnames "greek";
1044     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1045
1046 To get the 25 traditional lowercase Greek letters, including both sigmas,
1047 you could use this instead:
1048
1049     use charnames "greek";
1050     my @greek_small =  map { chr } ( ord("\N{alpha}") 
1051                                         ..
1052                                      ord("\N{omega}") 
1053                                    );
1054
1055 However, because there are I<many> other lowercase Greek characters than
1056 just those, to match lowercase Greek characters in a regular expression,
1057 you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the
1058 L<experimental feature|perlrecharclass/Extended Bracketed Character
1059 Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>).
1060
1061 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
1062 return two elements in list context.
1063
1064     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1065
1066 =head2 Conditional Operator
1067 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1068
1069 Ternary "?:" is the conditional operator, just as in C.  It works much
1070 like an if-then-else.  If the argument before the ? is true, the
1071 argument before the : is returned, otherwise the argument after the :
1072 is returned.  For example:
1073
1074     printf "I have %d dog%s.\n", $n,
1075             ($n == 1) ? "" : "s";
1076
1077 Scalar or list context propagates downward into the 2nd
1078 or 3rd argument, whichever is selected.
1079
1080     $a = $ok ? $b : $c;  # get a scalar
1081     @a = $ok ? @b : @c;  # get an array
1082     $a = $ok ? @b : @c;  # oops, that's just a count!
1083
1084 The operator may be assigned to if both the 2nd and 3rd arguments are
1085 legal lvalues (meaning that you can assign to them):
1086
1087     ($a_or_b ? $a : $b) = $c;
1088
1089 Because this operator produces an assignable result, using assignments
1090 without parentheses will get you in trouble.  For example, this:
1091
1092     $a % 2 ? $a += 10 : $a += 2
1093
1094 Really means this:
1095
1096     (($a % 2) ? ($a += 10) : $a) += 2
1097
1098 Rather than this:
1099
1100     ($a % 2) ? ($a += 10) : ($a += 2)
1101
1102 That should probably be written more simply as:
1103
1104     $a += ($a % 2) ? 10 : 2;
1105
1106 =head2 Assignment Operators
1107 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1108 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1109 X<%=> X<^=> X<x=>
1110
1111 "=" is the ordinary assignment operator.
1112
1113 Assignment operators work as in C.  That is,
1114
1115     $a += 2;
1116
1117 is equivalent to
1118
1119     $a = $a + 2;
1120
1121 although without duplicating any side effects that dereferencing the lvalue
1122 might trigger, such as from tie().  Other assignment operators work similarly.
1123 The following are recognized:
1124
1125     **=    +=    *=    &=    <<=    &&=
1126            -=    /=    |=    >>=    ||=
1127            .=    %=    ^=           //=
1128                  x=
1129
1130 Although these are grouped by family, they all have the precedence
1131 of assignment.
1132
1133 Unlike in C, the scalar assignment operator produces a valid lvalue.
1134 Modifying an assignment is equivalent to doing the assignment and
1135 then modifying the variable that was assigned to.  This is useful
1136 for modifying a copy of something, like this:
1137
1138     ($tmp = $global) =~ tr/13579/24680/;
1139
1140 Although as of 5.14, that can be also be accomplished this way:
1141
1142     use v5.14;
1143     $tmp = ($global =~  tr/13579/24680/r);
1144
1145 Likewise,
1146
1147     ($a += 2) *= 3;
1148
1149 is equivalent to
1150
1151     $a += 2;
1152     $a *= 3;
1153
1154 Similarly, a list assignment in list context produces the list of
1155 lvalues assigned to, and a list assignment in scalar context returns
1156 the number of elements produced by the expression on the right hand
1157 side of the assignment.
1158
1159 =head2 Comma Operator
1160 X<comma> X<operator, comma> X<,>
1161
1162 Binary "," is the comma operator.  In scalar context it evaluates
1163 its left argument, throws that value away, then evaluates its right
1164 argument and returns that value.  This is just like C's comma operator.
1165
1166 In list context, it's just the list argument separator, and inserts
1167 both its arguments into the list.  These arguments are also evaluated
1168 from left to right.
1169
1170 The C<< => >> operator is a synonym for the comma except that it causes a
1171 word on its left to be interpreted as a string if it begins with a letter
1172 or underscore and is composed only of letters, digits and underscores.
1173 This includes operands that might otherwise be interpreted as operators,
1174 constants, single number v-strings or function calls. If in doubt about
1175 this behavior, the left operand can be quoted explicitly.
1176
1177 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1178 or list argument separator, according to context.
1179
1180 For example:
1181
1182     use constant FOO => "something";
1183
1184     my %h = ( FOO => 23 );
1185
1186 is equivalent to:
1187
1188     my %h = ("FOO", 23);
1189
1190 It is I<NOT>:
1191
1192     my %h = ("something", 23);
1193
1194 The C<< => >> operator is helpful in documenting the correspondence
1195 between keys and values in hashes, and other paired elements in lists.
1196
1197     %hash = ( $key => $value );
1198     login( $username => $password );
1199
1200 The special quoting behavior ignores precedence, and hence may apply to
1201 I<part> of the left operand:
1202
1203     print time.shift => "bbb";
1204
1205 That example prints something like "1314363215shiftbbb", because the
1206 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1207 the fact that C<time.shift> is the entire left operand.
1208
1209 =head2 List Operators (Rightward)
1210 X<operator, list, rightward> X<list operator>
1211
1212 On the right side of a list operator, the comma has very low precedence,
1213 such that it controls all comma-separated expressions found there.
1214 The only operators with lower precedence are the logical operators
1215 "and", "or", and "not", which may be used to evaluate calls to list
1216 operators without the need for parentheses:
1217
1218     open HANDLE, "< :utf8", "filename" or die "Can't open: $!\n";
1219
1220 However, some people find that code harder to read than writing
1221 it with parentheses:
1222
1223     open(HANDLE, "< :utf8", "filename") or die "Can't open: $!\n";
1224
1225 in which case you might as well just use the more customary "||" operator:
1226
1227     open(HANDLE, "< :utf8", "filename") || die "Can't open: $!\n";
1228
1229 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
1230
1231 =head2 Logical Not
1232 X<operator, logical, not> X<not>
1233
1234 Unary "not" returns the logical negation of the expression to its right.
1235 It's the equivalent of "!" except for the very low precedence.
1236
1237 =head2 Logical And
1238 X<operator, logical, and> X<and>
1239
1240 Binary "and" returns the logical conjunction of the two surrounding
1241 expressions.  It's equivalent to C<&&> except for the very low
1242 precedence.  This means that it short-circuits: the right
1243 expression is evaluated only if the left expression is true.
1244
1245 =head2 Logical or and Exclusive Or
1246 X<operator, logical, or> X<operator, logical, xor>
1247 X<operator, logical, exclusive or>
1248 X<or> X<xor>
1249
1250 Binary "or" returns the logical disjunction of the two surrounding
1251 expressions.  It's equivalent to C<||> except for the very low precedence.
1252 This makes it useful for control flow:
1253
1254     print FH $data              or die "Can't write to FH: $!";
1255
1256 This means that it short-circuits: the right expression is evaluated
1257 only if the left expression is false.  Due to its precedence, you must
1258 be careful to avoid using it as replacement for the C<||> operator.
1259 It usually works out better for flow control than in assignments:
1260
1261     $a = $b or $c;              # bug: this is wrong
1262     ($a = $b) or $c;            # really means this
1263     $a = $b || $c;              # better written this way
1264
1265 However, when it's a list-context assignment and you're trying to use
1266 C<||> for control flow, you probably need "or" so that the assignment
1267 takes higher precedence.
1268
1269     @info = stat($file) || die;     # oops, scalar sense of stat!
1270     @info = stat($file) or die;     # better, now @info gets its due
1271
1272 Then again, you could always use parentheses.
1273
1274 Binary C<xor> returns the exclusive-OR of the two surrounding expressions.
1275 It cannot short-circuit (of course).
1276
1277 There is no low precedence operator for defined-OR.
1278
1279 =head2 C Operators Missing From Perl
1280 X<operator, missing from perl> X<&> X<*>
1281 X<typecasting> X<(TYPE)>
1282
1283 Here is what C has that Perl doesn't:
1284
1285 =over 8
1286
1287 =item unary &
1288
1289 Address-of operator.  (But see the "\" operator for taking a reference.)
1290
1291 =item unary *
1292
1293 Dereference-address operator. (Perl's prefix dereferencing
1294 operators are typed: $, @, %, and &.)
1295
1296 =item (TYPE)
1297
1298 Type-casting operator.
1299
1300 =back
1301
1302 =head2 Quote and Quote-like Operators
1303 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1304 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1305 X<escape sequence> X<escape>
1306
1307 While we usually think of quotes as literal values, in Perl they
1308 function as operators, providing various kinds of interpolating and
1309 pattern matching capabilities.  Perl provides customary quote characters
1310 for these behaviors, but also provides a way for you to choose your
1311 quote character for any of them.  In the following table, a C<{}> represents
1312 any pair of delimiters you choose.
1313
1314     Customary  Generic        Meaning        Interpolates
1315         ''       q{}          Literal             no
1316         ""      qq{}          Literal             yes
1317         ``      qx{}          Command             yes*
1318                 qw{}         Word list            no
1319         //       m{}       Pattern match          yes*
1320                 qr{}          Pattern             yes*
1321                  s{}{}      Substitution          yes*
1322                 tr{}{}    Transliteration         no (but see below)
1323                  y{}{}    Transliteration         no (but see below)
1324         <<EOF                 here-doc            yes*
1325
1326         * unless the delimiter is ''.
1327
1328 Non-bracketing delimiters use the same character fore and aft, but the four
1329 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1330 that
1331
1332     q{foo{bar}baz}
1333
1334 is the same as
1335
1336     'foo{bar}baz'
1337
1338 Note, however, that this does not always work for quoting Perl code:
1339
1340     $s = q{ if($a eq "}") ... }; # WRONG
1341
1342 is a syntax error. The C<Text::Balanced> module (standard as of v5.8,
1343 and from CPAN before then) is able to do this properly.
1344
1345 There can be whitespace between the operator and the quoting
1346 characters, except when C<#> is being used as the quoting character.
1347 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
1348 operator C<q> followed by a comment.  Its argument will be taken
1349 from the next line.  This allows you to write:
1350
1351     s {foo}  # Replace foo
1352       {bar}  # with bar.
1353
1354 The following escape sequences are available in constructs that interpolate,
1355 and in transliterations:
1356 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1357 X<\o{}>
1358
1359     Sequence     Note  Description
1360     \t                  tab               (HT, TAB)
1361     \n                  newline           (NL)
1362     \r                  return            (CR)
1363     \f                  form feed         (FF)
1364     \b                  backspace         (BS)
1365     \a                  alarm (bell)      (BEL)
1366     \e                  escape            (ESC)
1367     \x{263A}     [1,8]  hex char          (example: SMILEY)
1368     \x1b         [2,8]  restricted range hex char (example: ESC)
1369     \N{name}     [3]    named Unicode character or character sequence
1370     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1371     \c[          [5]    control char      (example: chr(27))
1372     \o{23072}    [6,8]  octal char        (example: SMILEY)
1373     \033         [7,8]  restricted range octal char  (example: ESC)
1374
1375 =over 4
1376
1377 =item [1]
1378
1379 The result is the character specified by the hexadecimal number between
1380 the braces.  See L</[8]> below for details on which character.
1381
1382 Only hexadecimal digits are valid between the braces. If an invalid
1383 character is encountered, a warning will be issued and the invalid
1384 character and all subsequent characters (valid or invalid) within the
1385 braces will be discarded.
1386
1387 If there are no valid digits between the braces, the generated character is
1388 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1389 will not cause a warning (currently).
1390
1391 =item [2]
1392
1393 The result is the character specified by the hexadecimal number in the range
1394 0x00 to 0xFF.  See L</[8]> below for details on which character.
1395
1396 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1397 by fewer than two valid digits, any valid digits will be zero-padded.  This
1398 means that C<\x7> will be interpreted as C<\x07>, and a lone <\x> will be
1399 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1400 two valid digits will result in a warning.  Note that although the warning
1401 says the illegal character is ignored, it is only ignored as part of the
1402 escape and will still be used as the subsequent character in the string.
1403 For example:
1404
1405   Original    Result    Warns?
1406   "\x7"       "\x07"    no
1407   "\x"        "\x00"    no
1408   "\x7q"      "\x07q"   yes
1409   "\xq"       "\x00q"   yes
1410
1411 =item [3]
1412
1413 The result is the Unicode character or character sequence given by I<name>.
1414 See L<charnames>.
1415
1416 =item [4]
1417
1418 C<\N{U+I<hexadecimal number>}> means the Unicode character whose Unicode code
1419 point is I<hexadecimal number>.
1420
1421 =item [5]
1422
1423 The character following C<\c> is mapped to some other character as shown in the
1424 table:
1425
1426  Sequence   Value
1427    \c@      chr(0)
1428    \cA      chr(1)
1429    \ca      chr(1)
1430    \cB      chr(2)
1431    \cb      chr(2)
1432    ...
1433    \cZ      chr(26)
1434    \cz      chr(26)
1435    \c[      chr(27)
1436    \c]      chr(29)
1437    \c^      chr(30)
1438    \c_      chr(31)
1439    \c?      chr(127) # (on ASCII platforms)
1440
1441 In other words, it's the character whose code point has had 64 xor'd with
1442 its uppercase.  C<\c?> is DELETE on ASCII platforms because
1443 S<C<ord("?") ^ 64>> is 127, and
1444 C<\c@> is NULL because the ord of "@" is 64, so xor'ing 64 itself produces 0.
1445
1446 Also, C<\c\I<X>> yields C< chr(28) . "I<X>"> for any I<X>, but cannot come at the
1447 end of a string, because the backslash would be parsed as escaping the end
1448 quote.
1449
1450 On ASCII platforms, the resulting characters from the list above are the
1451 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1452 L<perlebcdic/OPERATOR DIFFERENCES> for a full discussion of the
1453 differences between these for ASCII versus EBCDIC platforms.
1454
1455 Use of any other character following the C<"c"> besides those listed above is
1456 discouraged, and as of Perl v5.20, the only characters actually allowed
1457 are the printable ASCII ones, minus the left brace C<"{">.  What happens
1458 for any of the allowed other characters is that the value is derived by
1459 xor'ing with the seventh bit, which is 64, and a warning raised if
1460 enabled.  Using the non-allowed characters generates a fatal error.
1461
1462 To get platform independent controls, you can use C<\N{...}>.
1463
1464 =item [6]
1465
1466 The result is the character specified by the octal number between the braces.
1467 See L</[8]> below for details on which character.
1468
1469 If a character that isn't an octal digit is encountered, a warning is raised,
1470 and the value is based on the octal digits before it, discarding it and all
1471 following characters up to the closing brace.  It is a fatal error if there are
1472 no octal digits at all.
1473
1474 =item [7]
1475
1476 The result is the character specified by the three-digit octal number in the
1477 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1478 L</[8]> below for details on which character.
1479
1480 Some contexts allow 2 or even 1 digit, but any usage without exactly
1481 three digits, the first being a zero, may give unintended results.  (For
1482 example, in a regular expression it may be confused with a backreference;
1483 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1484 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1485 use this construct only for ordinals C<\077> and below, remembering to pad to
1486 the left with zeros to make three digits.  For larger ordinals, either use
1487 C<\o{}>, or convert to something else, such as to hex and use C<\x{}>
1488 instead.
1489
1490 =item [8]
1491
1492 Several constructs above specify a character by a number.  That number
1493 gives the character's position in the character set encoding (indexed from 0).
1494 This is called synonymously its ordinal, code position, or code point.  Perl
1495 works on platforms that have a native encoding currently of either ASCII/Latin1
1496 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1497 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1498 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1499 it as a Unicode code point and the result is the corresponding Unicode
1500 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1501 decimal, which is less than 256, so the number is interpreted in the native
1502 character set encoding.  In ASCII the character in the 80th position (indexed
1503 from 0) is the letter "P", and in EBCDIC it is the ampersand symbol "&".
1504 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1505 as a Unicode code point no matter what the native encoding is.  The name of the
1506 character in the 256th position (indexed by 0) in Unicode is
1507 C<LATIN CAPITAL LETTER A WITH MACRON>.
1508
1509 There are a couple of exceptions to the above rule.  S<C<\N{U+I<hex number>}>> is
1510 always interpreted as a Unicode code point, so that C<\N{U+0050}> is "P" even
1511 on EBCDIC platforms.  And if L<C<S<use encoding>>|encoding> is in effect, the
1512 number is considered to be in that encoding, and is translated from that into
1513 the platform's native encoding if there is a corresponding native character;
1514 otherwise to Unicode.
1515
1516 =back
1517
1518 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1519 the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may
1520 use C<\ck> or
1521 C<\x0b>.  (C<\v>
1522 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1523
1524 The following escape sequences are available in constructs that interpolate,
1525 but not in transliterations.
1526 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1527
1528     \l          lowercase next character only
1529     \u          titlecase (not uppercase!) next character only
1530     \L          lowercase all characters till \E or end of string
1531     \U          uppercase all characters till \E or end of string
1532     \F          foldcase all characters till \E or end of string
1533     \Q          quote (disable) pattern metacharacters till \E or
1534                 end of string
1535     \E          end either case modification or quoted section
1536                 (whichever was last seen)
1537
1538 See L<perlfunc/quotemeta> for the exact definition of characters that
1539 are quoted by C<\Q>.
1540
1541 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1542 C<\E> for each.  For example:
1543
1544  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1545  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1546
1547 If C<use locale> is in effect (but not C<use locale ':not_characters'>),
1548 the case map used by C<\l>, C<\L>,
1549 C<\u>, and C<\U> is taken from the current locale.  See L<perllocale>.
1550 If Unicode (for example, C<\N{}> or code points of 0x100 or
1551 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u>, and
1552 C<\U> is as defined by Unicode.  That means that case-mapping
1553 a single character can sometimes produce several characters.
1554 Under C<use locale>, C<\F> produces the same results as C<\L>
1555 for all locales but a UTF-8 one, where it instead uses the Unicode
1556 definition.
1557
1558 All systems use the virtual C<"\n"> to represent a line terminator,
1559 called a "newline".  There is no such thing as an unvarying, physical
1560 newline character.  It is only an illusion that the operating system,
1561 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1562 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1563 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1564 and on systems without line terminator,
1565 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1566 you mean a "newline" for your system, but use the literal ASCII when you
1567 need an exact character.  For example, most networking protocols expect
1568 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1569 and although they often accept just C<"\012">, they seldom tolerate just
1570 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1571 you may be burned some day.
1572 X<newline> X<line terminator> X<eol> X<end of line>
1573 X<\n> X<\r> X<\r\n>
1574
1575 For constructs that do interpolate, variables beginning with "C<$>"
1576 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1577 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1578 But method calls such as C<< $obj->meth >> are not.
1579
1580 Interpolating an array or slice interpolates the elements in order,
1581 separated by the value of C<$">, so is equivalent to interpolating
1582 C<join $", @array>.  "Punctuation" arrays such as C<@*> are usually
1583 interpolated only if the name is enclosed in braces C<@{*}>, but the
1584 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1585
1586 For double-quoted strings, the quoting from C<\Q> is applied after
1587 interpolation and escapes are processed.
1588
1589     "abc\Qfoo\tbar$s\Exyz"
1590
1591 is equivalent to
1592
1593     "abc" . quotemeta("foo\tbar$s") . "xyz"
1594
1595 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1596 the quoting from C<\Q> is applied after interpolation is processed,
1597 but before escapes are processed. This allows the pattern to match
1598 literally (except for C<$> and C<@>). For example, the following matches:
1599
1600     '\s\t' =~ /\Q\s\t/
1601
1602 Because C<$> or C<@> trigger interpolation, you'll need to use something
1603 like C</\Quser\E\@\Qhost/> to match them literally.
1604
1605 Patterns are subject to an additional level of interpretation as a
1606 regular expression.  This is done as a second pass, after variables are
1607 interpolated, so that regular expressions may be incorporated into the
1608 pattern from the variables.  If this is not what you want, use C<\Q> to
1609 interpolate a variable literally.
1610
1611 Apart from the behavior described above, Perl does not expand
1612 multiple levels of interpolation.  In particular, contrary to the
1613 expectations of shell programmers, back-quotes do I<NOT> interpolate
1614 within double quotes, nor do single quotes impede evaluation of
1615 variables when used within double quotes.
1616
1617 =head2 Regexp Quote-Like Operators
1618 X<operator, regexp>
1619
1620 Here are the quote-like operators that apply to pattern
1621 matching and related activities.
1622
1623 =over 8
1624
1625 =item qr/STRING/msixpodual
1626 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1627
1628 This operator quotes (and possibly compiles) its I<STRING> as a regular
1629 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1630 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1631 is done.  Returns a Perl value which may be used instead of the
1632 corresponding C</STRING/msixpodual> expression. The returned value is a
1633 normalized version of the original pattern. It magically differs from
1634 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1635 however, dereferencing it is not well defined (you currently get the 
1636 normalized version of the original pattern, but this may change).
1637
1638
1639 For example,
1640
1641     $rex = qr/my.STRING/is;
1642     print $rex;                 # prints (?si-xm:my.STRING)
1643     s/$rex/foo/;
1644
1645 is equivalent to
1646
1647     s/my.STRING/foo/is;
1648
1649 The result may be used as a subpattern in a match:
1650
1651     $re = qr/$pattern/;
1652     $string =~ /foo${re}bar/;   # can be interpolated in other
1653                                 # patterns
1654     $string =~ $re;             # or used standalone
1655     $string =~ /$re/;           # or this way
1656
1657 Since Perl may compile the pattern at the moment of execution of the qr()
1658 operator, using qr() may have speed advantages in some situations,
1659 notably if the result of qr() is used standalone:
1660
1661     sub match {
1662         my $patterns = shift;
1663         my @compiled = map qr/$_/i, @$patterns;
1664         grep {
1665             my $success = 0;
1666             foreach my $pat (@compiled) {
1667                 $success = 1, last if /$pat/;
1668             }
1669             $success;
1670         } @_;
1671     }
1672
1673 Precompilation of the pattern into an internal representation at
1674 the moment of qr() avoids a need to recompile the pattern every
1675 time a match C</$pat/> is attempted.  (Perl has many other internal
1676 optimizations, but none would be triggered in the above example if
1677 we did not use qr() operator.)
1678
1679 Options (specified by the following modifiers) are:
1680
1681     m   Treat string as multiple lines.
1682     s   Treat string as single line. (Make . match a newline)
1683     i   Do case-insensitive pattern matching.
1684     x   Use extended regular expressions.
1685     p   When matching preserve a copy of the matched string so
1686         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be
1687         defined.
1688     o   Compile pattern only once.
1689     a   ASCII-restrict: Use ASCII for \d, \s, \w; specifying two
1690         a's further restricts /i matching so that no ASCII
1691         character will match a non-ASCII one.
1692     l   Use the locale.
1693     u   Use Unicode rules.
1694     d   Use Unicode or native charset, as in 5.12 and earlier.
1695
1696 If a precompiled pattern is embedded in a larger pattern then the effect
1697 of "msixpluad" will be propagated appropriately.  The effect the "o"
1698 modifier has is not propagated, being restricted to those patterns
1699 explicitly using it.
1700
1701 The last four modifiers listed above, added in Perl 5.14,
1702 control the character set rules, but C</a> is the only one you are likely
1703 to want to specify explicitly; the other three are selected
1704 automatically by various pragmas.
1705
1706 See L<perlre> for additional information on valid syntax for STRING, and
1707 for a detailed look at the semantics of regular expressions.  In
1708 particular, all modifiers except the largely obsolete C</o> are further
1709 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1710
1711 =item m/PATTERN/msixpodualgc
1712 X<m> X<operator, match>
1713 X<regexp, options> X<regexp> X<regex, options> X<regex>
1714 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1715
1716 =item /PATTERN/msixpodualgc
1717
1718 Searches a string for a pattern match, and in scalar context returns
1719 true if it succeeds, false if it fails.  If no string is specified
1720 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1721 string specified with C<=~> need not be an lvalue--it may be the
1722 result of an expression evaluation, but remember the C<=~> binds
1723 rather tightly.)  See also L<perlre>.
1724
1725 Options are as described in C<qr//> above; in addition, the following match
1726 process modifiers are available:
1727
1728  g  Match globally, i.e., find all occurrences.
1729  c  Do not reset search position on a failed match when /g is
1730     in effect.
1731
1732 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1733 you can use any pair of non-whitespace (ASCII) characters
1734 as delimiters.  This is particularly useful for matching path names
1735 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1736 the delimiter, then a match-only-once rule applies,
1737 described in C<m?PATTERN?> below. If "'" (single quote) is the delimiter,
1738 no interpolation is performed on the PATTERN.
1739 When using a character valid in an identifier, whitespace is required
1740 after the C<m>.
1741
1742 PATTERN may contain variables, which will be interpolated
1743 every time the pattern search is evaluated, except
1744 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1745 C<$|> are not interpolated because they look like end-of-string tests.)
1746 Perl will not recompile the pattern unless an interpolated
1747 variable that it contains changes.  You can force Perl to skip the
1748 test and never recompile by adding a C</o> (which stands for "once")
1749 after the trailing delimiter.
1750 Once upon a time, Perl would recompile regular expressions
1751 unnecessarily, and this modifier was useful to tell it not to do so, in the
1752 interests of speed.  But now, the only reasons to use C</o> are one of:
1753
1754 =over
1755
1756 =item 1
1757
1758 The variables are thousands of characters long and you know that they
1759 don't change, and you need to wring out the last little bit of speed by
1760 having Perl skip testing for that.  (There is a maintenance penalty for
1761 doing this, as mentioning C</o> constitutes a promise that you won't
1762 change the variables in the pattern.  If you do change them, Perl won't
1763 even notice.)
1764
1765 =item 2
1766
1767 you want the pattern to use the initial values of the variables
1768 regardless of whether they change or not.  (But there are saner ways
1769 of accomplishing this than using C</o>.)
1770
1771 =item 3
1772
1773 If the pattern contains embedded code, such as
1774
1775     use re 'eval';
1776     $code = 'foo(?{ $x })';
1777     /$code/
1778
1779 then perl will recompile each time, even though the pattern string hasn't
1780 changed, to ensure that the current value of C<$x> is seen each time.
1781 Use C</o> if you want to avoid this.
1782
1783 =back
1784
1785 The bottom line is that using C</o> is almost never a good idea.
1786
1787 =item The empty pattern //
1788
1789 If the PATTERN evaluates to the empty string, the last
1790 I<successfully> matched regular expression is used instead. In this
1791 case, only the C<g> and C<c> flags on the empty pattern are honored;
1792 the other flags are taken from the original pattern. If no match has
1793 previously succeeded, this will (silently) act instead as a genuine
1794 empty pattern (which will always match).
1795
1796 Note that it's possible to confuse Perl into thinking C<//> (the empty
1797 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1798 good about this, but some pathological cases might trigger this, such as
1799 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //>
1800 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl
1801 will assume you meant defined-or.  If you meant the empty regex, just
1802 use parentheses or spaces to disambiguate, or even prefix the empty
1803 regex with an C<m> (so C<//> becomes C<m//>).
1804
1805 =item Matching in list context
1806
1807 If the C</g> option is not used, C<m//> in list context returns a
1808 list consisting of the subexpressions matched by the parentheses in the
1809 pattern, that is, (C<$1>, C<$2>, C<$3>...)  (Note that here C<$1> etc. are
1810 also set).  When there are no parentheses in the pattern, the return
1811 value is the list C<(1)> for success.  
1812 With or without parentheses, an empty list is returned upon failure.
1813
1814 Examples:
1815
1816  open(TTY, "+</dev/tty")
1817     || die "can't access /dev/tty: $!";
1818
1819  <TTY> =~ /^y/i && foo();       # do foo if desired
1820
1821  if (/Version: *([0-9.]*)/) { $version = $1; }
1822
1823  next if m#^/usr/spool/uucp#;
1824
1825  # poor man's grep
1826  $arg = shift;
1827  while (<>) {
1828     print if /$arg/o; # compile only once (no longer needed!)
1829  }
1830
1831  if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1832
1833 This last example splits $foo into the first two words and the
1834 remainder of the line, and assigns those three fields to $F1, $F2, and
1835 $Etc.  The conditional is true if any variables were assigned; that is,
1836 if the pattern matched.
1837
1838 The C</g> modifier specifies global pattern matching--that is,
1839 matching as many times as possible within the string. How it behaves
1840 depends on the context. In list context, it returns a list of the
1841 substrings matched by any capturing parentheses in the regular
1842 expression. If there are no parentheses, it returns a list of all
1843 the matched strings, as if there were parentheses around the whole
1844 pattern.
1845
1846 In scalar context, each execution of C<m//g> finds the next match,
1847 returning true if it matches, and false if there is no further match.
1848 The position after the last match can be read or set using the C<pos()>
1849 function; see L<perlfunc/pos>. A failed match normally resets the
1850 search position to the beginning of the string, but you can avoid that
1851 by adding the C</c> modifier (for example, C<m//gc>). Modifying the target
1852 string also resets the search position.
1853
1854 =item \G assertion
1855
1856 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1857 zero-width assertion that matches the exact position where the
1858 previous C<m//g>, if any, left off. Without the C</g> modifier, the
1859 C<\G> assertion still anchors at C<pos()> as it was at the start of
1860 the operation (see L<perlfunc/pos>), but the match is of course only
1861 attempted once. Using C<\G> without C</g> on a target string that has
1862 not previously had a C</g> match applied to it is the same as using
1863 the C<\A> assertion to match the beginning of the string.  Note also
1864 that, currently, C<\G> is only properly supported when anchored at the
1865 very beginning of the pattern.
1866
1867 Examples:
1868
1869     # list context
1870     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1871
1872     # scalar context
1873     local $/ = "";
1874     while ($paragraph = <>) {
1875         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1876             $sentences++;
1877         }
1878     }
1879     say $sentences;
1880
1881 Here's another way to check for sentences in a paragraph:
1882
1883  my $sentence_rx = qr{
1884     (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or
1885                                 # whitespace
1886     \p{Lu}                      # capital letter
1887     .*?                         # a bunch of anything
1888     (?<= \S )                   # that ends in non-
1889                                 # whitespace
1890     (?<! \b [DMS]r  )           # but isn't a common abbr.
1891     (?<! \b Mrs )
1892     (?<! \b Sra )
1893     (?<! \b St  )
1894     [.?!]                       # followed by a sentence
1895                                 # ender
1896     (?= $ | \s )                # in front of end-of-string
1897                                 # or whitespace
1898  }sx;
1899  local $/ = "";
1900  while (my $paragraph = <>) {
1901     say "NEW PARAGRAPH";
1902     my $count = 0;
1903     while ($paragraph =~ /($sentence_rx)/g) {
1904         printf "\tgot sentence %d: <%s>\n", ++$count, $1;
1905     }
1906  }
1907
1908 Here's how to use C<m//gc> with C<\G>:
1909
1910     $_ = "ppooqppqq";
1911     while ($i++ < 2) {
1912         print "1: '";
1913         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1914         print "2: '";
1915         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1916         print "3: '";
1917         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1918     }
1919     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1920
1921 The last example should print:
1922
1923     1: 'oo', pos=4
1924     2: 'q', pos=5
1925     3: 'pp', pos=7
1926     1: '', pos=7
1927     2: 'q', pos=8
1928     3: '', pos=8
1929     Final: 'q', pos=8
1930
1931 Notice that the final match matched C<q> instead of C<p>, which a match
1932 without the C<\G> anchor would have done. Also note that the final match
1933 did not update C<pos>. C<pos> is only updated on a C</g> match. If the
1934 final match did indeed match C<p>, it's a good bet that you're running a
1935 very old (pre-5.6.0) version of Perl.
1936
1937 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1938 combine several regexps like this to process a string part-by-part,
1939 doing different actions depending on which regexp matched.  Each
1940 regexp tries to match where the previous one leaves off.
1941
1942  $_ = <<'EOL';
1943     $url = URI::URL->new( "http://example.com/" );
1944     die if $url eq "xXx";
1945  EOL
1946
1947  LOOP: {
1948      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1949      print(" lowercase"),    redo LOOP
1950                                     if /\G\p{Ll}+\b[,.;]?\s*/gc;
1951      print(" UPPERCASE"),    redo LOOP
1952                                     if /\G\p{Lu}+\b[,.;]?\s*/gc;
1953      print(" Capitalized"),  redo LOOP
1954                               if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
1955      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
1956      print(" alphanumeric"), redo LOOP
1957                             if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
1958      print(" line-noise"),   redo LOOP if /\G\W+/gc;
1959      print ". That's all!\n";
1960  }
1961
1962 Here is the output (split into several lines):
1963
1964  line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
1965  line-noise lowercase line-noise lowercase line-noise lowercase
1966  lowercase line-noise lowercase lowercase line-noise lowercase
1967  lowercase line-noise MiXeD line-noise. That's all!
1968
1969 =item m?PATTERN?msixpodualgc
1970 X<?> X<operator, match-once>
1971
1972 =item ?PATTERN?msixpodualgc
1973
1974 This is just like the C<m/PATTERN/> search, except that it matches
1975 only once between calls to the reset() operator.  This is a useful
1976 optimization when you want to see only the first occurrence of
1977 something in each file of a set of files, for instance.  Only C<m??>
1978 patterns local to the current package are reset.
1979
1980     while (<>) {
1981         if (m?^$?) {
1982                             # blank line between header and body
1983         }
1984     } continue {
1985         reset if eof;       # clear m?? status for next file
1986     }
1987
1988 Another example switched the first "latin1" encoding it finds
1989 to "utf8" in a pod file:
1990
1991     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
1992
1993 The match-once behavior is controlled by the match delimiter being
1994 C<?>; with any other delimiter this is the normal C<m//> operator.  
1995
1996 For historical reasons, the leading C<m> in C<m?PATTERN?> is optional,
1997 but the resulting C<?PATTERN?> syntax is deprecated, will warn on
1998 usage and might be removed from a future stable release of Perl (without
1999 further notice!).
2000
2001 =item s/PATTERN/REPLACEMENT/msixpodualgcer
2002 X<substitute> X<substitution> X<replace> X<regexp, replace>
2003 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
2004
2005 Searches a string for a pattern, and if found, replaces that pattern
2006 with the replacement text and returns the number of substitutions
2007 made.  Otherwise it returns false (specifically, the empty string).
2008
2009 If the C</r> (non-destructive) option is used then it runs the
2010 substitution on a copy of the string and instead of returning the
2011 number of substitutions, it returns the copy whether or not a
2012 substitution occurred.  The original string is never changed when
2013 C</r> is used.  The copy will always be a plain string, even if the
2014 input is an object or a tied variable.
2015
2016 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
2017 variable is searched and modified.  Unless the C</r> option is used,
2018 the string specified must be a scalar variable, an array element, a
2019 hash element, or an assignment to one of those; that is, some sort of
2020 scalar lvalue.
2021
2022 If the delimiter chosen is a single quote, no interpolation is
2023 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
2024 PATTERN contains a $ that looks like a variable rather than an
2025 end-of-string test, the variable will be interpolated into the pattern
2026 at run-time.  If you want the pattern compiled only once the first time
2027 the variable is interpolated, use the C</o> option.  If the pattern
2028 evaluates to the empty string, the last successfully executed regular
2029 expression is used instead.  See L<perlre> for further explanation on these.
2030
2031 Options are as with m// with the addition of the following replacement
2032 specific options:
2033
2034     e   Evaluate the right side as an expression.
2035     ee  Evaluate the right side as a string then eval the
2036         result.
2037     r   Return substitution and leave the original string
2038         untouched.
2039
2040 Any non-whitespace delimiter may replace the slashes.  Add space after
2041 the C<s> when using a character allowed in identifiers.  If single quotes
2042 are used, no interpretation is done on the replacement string (the C</e>
2043 modifier overrides this, however).  Note that Perl treats backticks
2044 as normal delimiters; the replacement text is not evaluated as a command.
2045 If the PATTERN is delimited by bracketing quotes, the REPLACEMENT has
2046 its own pair of quotes, which may or may not be bracketing quotes, for example,
2047 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2048 replacement portion to be treated as a full-fledged Perl expression
2049 and evaluated right then and there.  It is, however, syntax checked at
2050 compile-time. A second C<e> modifier will cause the replacement portion
2051 to be C<eval>ed before being run as a Perl expression.
2052
2053 Examples:
2054
2055     s/\bgreen\b/mauve/g;              # don't change wintergreen
2056
2057     $path =~ s|/usr/bin|/usr/local/bin|;
2058
2059     s/Login: $foo/Login: $bar/; # run-time pattern
2060
2061     ($foo = $bar) =~ s/this/that/;      # copy first, then
2062                                         # change
2063     ($foo = "$bar") =~ s/this/that/;    # convert to string,
2064                                         # copy, then change
2065     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2066     $foo = $bar =~ s/this/that/r
2067                 =~ s/that/the other/r;  # Chained substitutes
2068                                         # using /r
2069     @foo = map { s/this/that/r } @bar   # /r is very useful in
2070                                         # maps
2071
2072     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-cnt
2073
2074     $_ = 'abc123xyz';
2075     s/\d+/$&*2/e;               # yields 'abc246xyz'
2076     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2077     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2078
2079     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2080     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2081     s/^=(\w+)/pod($1)/ge;       # use function call
2082
2083     $_ = 'abc123xyz';
2084     $a = s/abc/def/r;           # $a is 'def123xyz' and
2085                                 # $_ remains 'abc123xyz'.
2086
2087     # expand variables in $_, but dynamics only, using
2088     # symbolic dereferencing
2089     s/\$(\w+)/${$1}/g;
2090
2091     # Add one to the value of any numbers in the string
2092     s/(\d+)/1 + $1/eg;
2093
2094     # Titlecase words in the last 30 characters only
2095     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2096
2097     # This will expand any embedded scalar variable
2098     # (including lexicals) in $_ : First $1 is interpolated
2099     # to the variable name, and then evaluated
2100     s/(\$\w+)/$1/eeg;
2101
2102     # Delete (most) C comments.
2103     $program =~ s {
2104         /\*     # Match the opening delimiter.
2105         .*?     # Match a minimal number of characters.
2106         \*/     # Match the closing delimiter.
2107     } []gsx;
2108
2109     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_,
2110                                 # expensively
2111
2112     for ($variable) {           # trim whitespace in $variable,
2113                                 # cheap
2114         s/^\s+//;
2115         s/\s+$//;
2116     }
2117
2118     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2119
2120 Note the use of $ instead of \ in the last example.  Unlike
2121 B<sed>, we use the \<I<digit>> form in only the left hand side.
2122 Anywhere else it's $<I<digit>>.
2123
2124 Occasionally, you can't use just a C</g> to get all the changes
2125 to occur that you might want.  Here are two common cases:
2126
2127     # put commas in the right places in an integer
2128     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2129
2130     # expand tabs to 8-column spacing
2131     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2132
2133 =back
2134
2135 =head2 Quote-Like Operators
2136 X<operator, quote-like>
2137
2138 =over 4
2139
2140 =item q/STRING/
2141 X<q> X<quote, single> X<'> X<''>
2142
2143 =item 'STRING'
2144
2145 A single-quoted, literal string.  A backslash represents a backslash
2146 unless followed by the delimiter or another backslash, in which case
2147 the delimiter or backslash is interpolated.
2148
2149     $foo = q!I said, "You said, 'She said it.'"!;
2150     $bar = q('This is it.');
2151     $baz = '\n';                # a two-character string
2152
2153 =item qq/STRING/
2154 X<qq> X<quote, double> X<"> X<"">
2155
2156 =item "STRING"
2157
2158 A double-quoted, interpolated string.
2159
2160     $_ .= qq
2161      (*** The previous line contains the naughty word "$1".\n)
2162                 if /\b(tcl|java|python)\b/i;      # :-)
2163     $baz = "\n";                # a one-character string
2164
2165 =item qx/STRING/
2166 X<qx> X<`> X<``> X<backtick>
2167
2168 =item `STRING`
2169
2170 A string which is (possibly) interpolated and then executed as a
2171 system command with F</bin/sh> or its equivalent.  Shell wildcards,
2172 pipes, and redirections will be honored.  The collected standard
2173 output of the command is returned; standard error is unaffected.  In
2174 scalar context, it comes back as a single (potentially multi-line)
2175 string, or undef if the command failed.  In list context, returns a
2176 list of lines (however you've defined lines with $/ or
2177 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
2178
2179 Because backticks do not affect standard error, use shell file descriptor
2180 syntax (assuming the shell supports this) if you care to address this.
2181 To capture a command's STDERR and STDOUT together:
2182
2183     $output = `cmd 2>&1`;
2184
2185 To capture a command's STDOUT but discard its STDERR:
2186
2187     $output = `cmd 2>/dev/null`;
2188
2189 To capture a command's STDERR but discard its STDOUT (ordering is
2190 important here):
2191
2192     $output = `cmd 2>&1 1>/dev/null`;
2193
2194 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2195 but leave its STDOUT to come out the old STDERR:
2196
2197     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2198
2199 To read both a command's STDOUT and its STDERR separately, it's easiest
2200 to redirect them separately to files, and then read from those files
2201 when the program is done:
2202
2203     system("program args 1>program.stdout 2>program.stderr");
2204
2205 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2206 For example:
2207
2208     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2209     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2210     print STDOUT `sort`;
2211
2212 will print the sorted contents of the file named F<"stuff">.
2213
2214 Using single-quote as a delimiter protects the command from Perl's
2215 double-quote interpolation, passing it on to the shell instead:
2216
2217     $perl_info  = qx(ps $$);            # that's Perl's $$
2218     $shell_info = qx'ps $$';            # that's the new shell's $$
2219
2220 How that string gets evaluated is entirely subject to the command
2221 interpreter on your system.  On most platforms, you will have to protect
2222 shell metacharacters if you want them treated literally.  This is in
2223 practice difficult to do, as it's unclear how to escape which characters.
2224 See L<perlsec> for a clean and safe example of a manual fork() and exec()
2225 to emulate backticks safely.
2226
2227 On some platforms (notably DOS-like ones), the shell may not be
2228 capable of dealing with multiline commands, so putting newlines in
2229 the string may not get you what you want.  You may be able to evaluate
2230 multiple commands in a single line by separating them with the command
2231 separator character, if your shell supports that (for example, C<;> on 
2232 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2233
2234 Perl will attempt to flush all files opened for
2235 output before starting the child process, but this may not be supported
2236 on some platforms (see L<perlport>).  To be safe, you may need to set
2237 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2238 C<IO::Handle> on any open handles.
2239
2240 Beware that some command shells may place restrictions on the length
2241 of the command line.  You must ensure your strings don't exceed this
2242 limit after any necessary interpolations.  See the platform-specific
2243 release notes for more details about your particular environment.
2244
2245 Using this operator can lead to programs that are difficult to port,
2246 because the shell commands called vary between systems, and may in
2247 fact not be present at all.  As one example, the C<type> command under
2248 the POSIX shell is very different from the C<type> command under DOS.
2249 That doesn't mean you should go out of your way to avoid backticks
2250 when they're the right way to get something done.  Perl was made to be
2251 a glue language, and one of the things it glues together is commands.
2252 Just understand what you're getting yourself into.
2253
2254 See L</"I/O Operators"> for more discussion.
2255
2256 =item qw/STRING/
2257 X<qw> X<quote, list> X<quote, words>
2258
2259 Evaluates to a list of the words extracted out of STRING, using embedded
2260 whitespace as the word delimiters.  It can be understood as being roughly
2261 equivalent to:
2262
2263     split(" ", q/STRING/);
2264
2265 the differences being that it generates a real list at compile time, and
2266 in scalar context it returns the last element in the list.  So
2267 this expression:
2268
2269     qw(foo bar baz)
2270
2271 is semantically equivalent to the list:
2272
2273     "foo", "bar", "baz"
2274
2275 Some frequently seen examples:
2276
2277     use POSIX qw( setlocale localeconv )
2278     @EXPORT = qw( foo bar baz );
2279
2280 A common mistake is to try to separate the words with comma or to
2281 put comments into a multi-line C<qw>-string.  For this reason, the
2282 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
2283 produces warnings if the STRING contains the "," or the "#" character.
2284
2285 =item tr/SEARCHLIST/REPLACEMENTLIST/cdsr
2286 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2287
2288 =item y/SEARCHLIST/REPLACEMENTLIST/cdsr
2289
2290 Transliterates all occurrences of the characters found in the search list
2291 with the corresponding character in the replacement list.  It returns
2292 the number of characters replaced or deleted.  If no string is
2293 specified via the C<=~> or C<!~> operator, the $_ string is transliterated.
2294
2295 If the C</r> (non-destructive) option is present, a new copy of the string
2296 is made and its characters transliterated, and this copy is returned no
2297 matter whether it was modified or not: the original string is always
2298 left unchanged.  The new copy is always a plain string, even if the input
2299 string is an object or a tied variable.
2300
2301 Unless the C</r> option is used, the string specified with C<=~> must be a
2302 scalar variable, an array element, a hash element, or an assignment to one
2303 of those; in other words, an lvalue.
2304
2305 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
2306 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
2307 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
2308 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
2309 its own pair of quotes, which may or may not be bracketing quotes;
2310 for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>.
2311
2312 Note that C<tr> does B<not> do regular expression character classes such as
2313 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the tr(1)
2314 utility.  If you want to map strings between lower/upper cases, see
2315 L<perlfunc/lc> and L<perlfunc/uc>, and in general consider using the C<s>
2316 operator if you need regular expressions.  The C<\U>, C<\u>, C<\L>, and
2317 C<\l> string-interpolation escapes on the right side of a substitution
2318 operator will perform correct case-mappings, but C<tr[a-z][A-Z]> will not
2319 (except sometimes on legacy 7-bit data).
2320
2321 Note also that the whole range idea is rather unportable between
2322 character sets--and even within character sets they may cause results
2323 you probably didn't expect.  A sound principle is to use only ranges
2324 that begin from and end at either alphabets of equal case (a-e, A-E),
2325 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
2326 character sets in full.
2327
2328 Options:
2329
2330     c   Complement the SEARCHLIST.
2331     d   Delete found but unreplaced characters.
2332     s   Squash duplicate replaced characters.
2333     r   Return the modified string and leave the original string
2334         untouched.
2335
2336 If the C</c> modifier is specified, the SEARCHLIST character set
2337 is complemented.  If the C</d> modifier is specified, any characters
2338 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
2339 (Note that this is slightly more flexible than the behavior of some
2340 B<tr> programs, which delete anything they find in the SEARCHLIST,
2341 period.) If the C</s> modifier is specified, sequences of characters
2342 that were transliterated to the same character are squashed down
2343 to a single instance of the character.
2344
2345 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
2346 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
2347 than the SEARCHLIST, the final character is replicated till it is long
2348 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
2349 This latter is useful for counting characters in a class or for
2350 squashing character sequences in a class.
2351
2352 Examples:
2353
2354     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2355
2356     $cnt = tr/*/*/;             # count the stars in $_
2357
2358     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2359
2360     $cnt = tr/0-9//;            # count the digits in $_
2361
2362     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2363
2364     ($HOST = $host) =~ tr/a-z/A-Z/;
2365      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2366
2367     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2368                   =~ s/:/ -p/r;
2369
2370     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2371
2372     @stripped = map tr/a-zA-Z/ /csr, @original;
2373                                 # /r with map
2374
2375     tr [\200-\377]
2376        [\000-\177];             # wickedly delete 8th bit
2377
2378 If multiple transliterations are given for a character, only the
2379 first one is used:
2380
2381     tr/AAA/XYZ/
2382
2383 will transliterate any A to X.
2384
2385 Because the transliteration table is built at compile time, neither
2386 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
2387 interpolation.  That means that if you want to use variables, you
2388 must use an eval():
2389
2390     eval "tr/$oldlist/$newlist/";
2391     die $@ if $@;
2392
2393     eval "tr/$oldlist/$newlist/, 1" or die $@;
2394
2395 =item <<EOF
2396 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2397
2398 A line-oriented form of quoting is based on the shell "here-document"
2399 syntax.  Following a C<< << >> you specify a string to terminate
2400 the quoted material, and all lines following the current line down to
2401 the terminating string are the value of the item.
2402
2403 The terminating string may be either an identifier (a word), or some
2404 quoted text.  An unquoted identifier works like double quotes.
2405 There may not be a space between the C<< << >> and the identifier,
2406 unless the identifier is explicitly quoted.  (If you put a space it
2407 will be treated as a null identifier, which is valid, and matches the
2408 first empty line.)  The terminating string must appear by itself
2409 (unquoted and with no surrounding whitespace) on the terminating line.
2410
2411 If the terminating string is quoted, the type of quotes used determine
2412 the treatment of the text.
2413
2414 =over 4
2415
2416 =item Double Quotes
2417
2418 Double quotes indicate that the text will be interpolated using exactly
2419 the same rules as normal double quoted strings.
2420
2421        print <<EOF;
2422     The price is $Price.
2423     EOF
2424
2425        print << "EOF"; # same as above
2426     The price is $Price.
2427     EOF
2428
2429
2430 =item Single Quotes
2431
2432 Single quotes indicate the text is to be treated literally with no
2433 interpolation of its content. This is similar to single quoted
2434 strings except that backslashes have no special meaning, with C<\\>
2435 being treated as two backslashes and not one as they would in every
2436 other quoting construct.
2437
2438 Just as in the shell, a backslashed bareword following the C<<< << >>>
2439 means the same thing as a single-quoted string does:
2440
2441         $cost = <<'VISTA';  # hasta la ...
2442     That'll be $10 please, ma'am.
2443     VISTA
2444
2445         $cost = <<\VISTA;   # Same thing!
2446     That'll be $10 please, ma'am.
2447     VISTA
2448
2449 This is the only form of quoting in perl where there is no need
2450 to worry about escaping content, something that code generators
2451 can and do make good use of.
2452
2453 =item Backticks
2454
2455 The content of the here doc is treated just as it would be if the
2456 string were embedded in backticks. Thus the content is interpolated
2457 as though it were double quoted and then executed via the shell, with
2458 the results of the execution returned.
2459
2460        print << `EOC`; # execute command and get results
2461     echo hi there
2462     EOC
2463
2464 =back
2465
2466 It is possible to stack multiple here-docs in a row:
2467
2468        print <<"foo", <<"bar"; # you can stack them
2469     I said foo.
2470     foo
2471     I said bar.
2472     bar
2473
2474        myfunc(<< "THIS", 23, <<'THAT');
2475     Here's a line
2476     or two.
2477     THIS
2478     and here's another.
2479     THAT
2480
2481 Just don't forget that you have to put a semicolon on the end
2482 to finish the statement, as Perl doesn't know you're not going to
2483 try to do this:
2484
2485        print <<ABC
2486     179231
2487     ABC
2488        + 20;
2489
2490 If you want to remove the line terminator from your here-docs,
2491 use C<chomp()>.
2492
2493     chomp($string = <<'END');
2494     This is a string.
2495     END
2496
2497 If you want your here-docs to be indented with the rest of the code,
2498 you'll need to remove leading whitespace from each line manually:
2499
2500     ($quote = <<'FINIS') =~ s/^\s+//gm;
2501        The Road goes ever on and on,
2502        down from the door where it began.
2503     FINIS
2504
2505 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2506 the quoted material must still come on the line following the
2507 C<<< <<FOO >>> marker, which means it may be inside the delimited
2508 construct:
2509
2510     s/this/<<E . 'that'
2511     the other
2512     E
2513      . 'more '/eg;
2514
2515 It works this way as of Perl 5.18.  Historically, it was inconsistent, and
2516 you would have to write
2517
2518     s/this/<<E . 'that'
2519      . 'more '/eg;
2520     the other
2521     E
2522
2523 outside of string evals.
2524
2525 Additionally, quoting rules for the end-of-string identifier are
2526 unrelated to Perl's quoting rules. C<q()>, C<qq()>, and the like are not
2527 supported in place of C<''> and C<"">, and the only interpolation is for
2528 backslashing the quoting character:
2529
2530     print << "abc\"def";
2531     testing...
2532     abc"def
2533
2534 Finally, quoted strings cannot span multiple lines.  The general rule is
2535 that the identifier must be a string literal.  Stick with that, and you
2536 should be safe.
2537
2538 =back
2539
2540 =head2 Gory details of parsing quoted constructs
2541 X<quote, gory details>
2542
2543 When presented with something that might have several different
2544 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2545 principle to pick the most probable interpretation.  This strategy
2546 is so successful that Perl programmers often do not suspect the
2547 ambivalence of what they write.  But from time to time, Perl's
2548 notions differ substantially from what the author honestly meant.
2549
2550 This section hopes to clarify how Perl handles quoted constructs.
2551 Although the most common reason to learn this is to unravel labyrinthine
2552 regular expressions, because the initial steps of parsing are the
2553 same for all quoting operators, they are all discussed together.
2554
2555 The most important Perl parsing rule is the first one discussed
2556 below: when processing a quoted construct, Perl first finds the end
2557 of that construct, then interprets its contents.  If you understand
2558 this rule, you may skip the rest of this section on the first
2559 reading.  The other rules are likely to contradict the user's
2560 expectations much less frequently than this first one.
2561
2562 Some passes discussed below are performed concurrently, but because
2563 their results are the same, we consider them individually.  For different
2564 quoting constructs, Perl performs different numbers of passes, from
2565 one to four, but these passes are always performed in the same order.
2566
2567 =over 4
2568
2569 =item Finding the end
2570
2571 The first pass is finding the end of the quoted construct, where
2572 the information about the delimiters is used in parsing.
2573 During this search, text between the starting and ending delimiters
2574 is copied to a safe location. The text copied gets delimiter-independent.
2575
2576 If the construct is a here-doc, the ending delimiter is a line
2577 that has a terminating string as the content. Therefore C<<<EOF> is
2578 terminated by C<EOF> immediately followed by C<"\n"> and starting
2579 from the first column of the terminating line.
2580 When searching for the terminating line of a here-doc, nothing
2581 is skipped. In other words, lines after the here-doc syntax
2582 are compared with the terminating string line by line.
2583
2584 For the constructs except here-docs, single characters are used as starting
2585 and ending delimiters. If the starting delimiter is an opening punctuation
2586 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2587 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2588 If the starting delimiter is an unpaired character like C</> or a closing
2589 punctuation, the ending delimiter is same as the starting delimiter.
2590 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2591 C<qq[]> and C<qq]]> constructs.
2592
2593 When searching for single-character delimiters, escaped delimiters
2594 and C<\\> are skipped.  For example, while searching for terminating C</>,
2595 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2596 bracketing, nested pairs are also skipped.  For example, while searching
2597 for closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2598 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2599 However, when backslashes are used as the delimiters (like C<qq\\> and
2600 C<tr\\\>), nothing is skipped.
2601 During the search for the end, backslashes that escape delimiters or
2602 other backslashes are removed (exactly speaking, they are not copied to the
2603 safe location).
2604
2605 For constructs with three-part delimiters (C<s///>, C<y///>, and
2606 C<tr///>), the search is repeated once more.
2607 If the first delimiter is not an opening punctuation, three delimiters must
2608 be same such as C<s!!!> and C<tr)))>, in which case the second delimiter
2609 terminates the left part and starts the right part at once.
2610 If the left part is delimited by bracketing punctuation (that is C<()>,
2611 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2612 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2613 and comments are allowed between both parts, though the comment must follow
2614 at least one whitespace character; otherwise a character expected as the 
2615 start of the comment may be regarded as the starting delimiter of the right part.
2616
2617 During this search no attention is paid to the semantics of the construct.
2618 Thus:
2619
2620     "$hash{"$foo/$bar"}"
2621
2622 or:
2623
2624     m/
2625       bar       # NOT a comment, this slash / terminated m//!
2626      /x
2627
2628 do not form legal quoted expressions.   The quoted part ends on the
2629 first C<"> and C</>, and the rest happens to be a syntax error.
2630 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2631 the example above is not C<m//x>, but rather C<m//> with no C</x>
2632 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2633
2634 Also no attention is paid to C<\c\> (multichar control char syntax) during
2635 this search. Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2636 of C<\/>, and the following C</> is not recognized as a delimiter.
2637 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2638
2639 =item Interpolation
2640 X<interpolation>
2641
2642 The next step is interpolation in the text obtained, which is now
2643 delimiter-independent.  There are multiple cases.
2644
2645 =over 4
2646
2647 =item C<<<'EOF'>
2648
2649 No interpolation is performed.
2650 Note that the combination C<\\> is left intact, since escaped delimiters
2651 are not available for here-docs.
2652
2653 =item  C<m''>, the pattern of C<s'''>
2654
2655 No interpolation is performed at this stage.
2656 Any backslashed sequences including C<\\> are treated at the stage
2657 to L</"parsing regular expressions">.
2658
2659 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2660
2661 The only interpolation is removal of C<\> from pairs of C<\\>.
2662 Therefore C<-> in C<tr'''> and C<y'''> is treated literally
2663 as a hyphen and no character range is available.
2664 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2665
2666 =item C<tr///>, C<y///>
2667
2668 No variable interpolation occurs.  String modifying combinations for
2669 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2670 The other escape sequences such as C<\200> and C<\t> and backslashed
2671 characters such as C<\\> and C<\-> are converted to appropriate literals.
2672 The character C<-> is treated specially and therefore C<\-> is treated
2673 as a literal C<->.
2674
2675 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2676
2677 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
2678 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2679 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
2680 The other escape sequences such as C<\200> and C<\t> and backslashed
2681 characters such as C<\\> and C<\-> are replaced with appropriate
2682 expansions.
2683
2684 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2685 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2686 no C<\E> inside.  Instead, it has C<\Q>, C<\\>, and C<E>, so the
2687 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2688 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2689 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2690 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2691
2692   $str = '\t';
2693   return "\Q$str";
2694
2695 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2696
2697 Interpolated scalars and arrays are converted internally to the C<join> and
2698 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
2699
2700   $foo . " XXX '" . (join $", @arr) . "'";
2701
2702 All operations above are performed simultaneously, left to right.
2703
2704 Because the result of C<"\Q STRING \E"> has all metacharacters
2705 quoted, there is no way to insert a literal C<$> or C<@> inside a
2706 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
2707 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2708 scalar.
2709
2710 Note also that the interpolation code needs to make a decision on
2711 where the interpolated scalar ends.  For instance, whether
2712 C<< "a $b -> {c}" >> really means:
2713
2714   "a " . $b . " -> {c}";
2715
2716 or:
2717
2718   "a " . $b -> {c};
2719
2720 Most of the time, the longest possible text that does not include
2721 spaces between components and which contains matching braces or
2722 brackets.  because the outcome may be determined by voting based
2723 on heuristic estimators, the result is not strictly predictable.
2724 Fortunately, it's usually correct for ambiguous cases.
2725
2726 =item the replacement of C<s///>
2727
2728 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
2729 happens as with C<qq//> constructs.
2730
2731 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2732 the replacement text of C<s///>, in order to correct the incorrigible
2733 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2734 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
2735 (that is, the C<$^W> variable) was set.
2736
2737 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2738
2739 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
2740 and interpolation happens (almost) as with C<qq//> constructs.
2741
2742 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2743 form for the regex compiler.  (This is because, as mentioned below, the regex
2744 compilation may be done at execution time, and C<\N{...}> is a compile-time
2745 construct.)
2746
2747 However any other combinations of C<\> followed by a character
2748 are not substituted but only skipped, in order to parse them
2749 as regular expressions at the following step.
2750 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2751 treated as an array symbol (for example C<@foo>),
2752 even though the same text in C<qq//> gives interpolation of C<\c@>.
2753
2754 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
2755 back to the perl parser, in a similar way that an interpolated array
2756 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
2757
2758 Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
2759 a C<#>-comment in a C<//x>-regular expression, no processing is
2760 performed whatsoever.  This is the first step at which the presence
2761 of the C<//x> modifier is relevant.
2762
2763 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2764 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2765 voted (by several different estimators) to be either an array element
2766 or C<$var> followed by an RE alternative.  This is where the notation
2767 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2768 array element C<-9>, not as a regular expression from the variable
2769 C<$arr> followed by a digit, which would be the interpretation of
2770 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2771 the result is not predictable.
2772
2773 The lack of processing of C<\\> creates specific restrictions on
2774 the post-processed text.  If the delimiter is C</>, one cannot get
2775 the combination C<\/> into the result of this step.  C</> will
2776 finish the regular expression, C<\/> will be stripped to C</> on
2777 the previous step, and C<\\/> will be left as is.  Because C</> is
2778 equivalent to C<\/> inside a regular expression, this does not
2779 matter unless the delimiter happens to be character special to the
2780 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2781 alphanumeric char, as in:
2782
2783   m m ^ a \s* b mmx;
2784
2785 In the RE above, which is intentionally obfuscated for illustration, the
2786 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2787 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one
2788 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2789 non-whitespace choices.
2790
2791 =back
2792
2793 This step is the last one for all constructs except regular expressions,
2794 which are processed further.
2795
2796 =item parsing regular expressions
2797 X<regexp, parse>
2798
2799 Previous steps were performed during the compilation of Perl code,
2800 but this one happens at run time, although it may be optimized to
2801 be calculated at compile time if appropriate.  After preprocessing
2802 described above, and possibly after evaluation if concatenation,
2803 joining, casing translation, or metaquoting are involved, the
2804 resulting I<string> is passed to the RE engine for compilation.
2805
2806 Whatever happens in the RE engine might be better discussed in L<perlre>,
2807 but for the sake of continuity, we shall do so here.
2808
2809 This is another step where the presence of the C<//x> modifier is
2810 relevant.  The RE engine scans the string from left to right and
2811 converts it to a finite automaton.
2812
2813 Backslashed characters are either replaced with corresponding
2814 literal strings (as with C<\{>), or else they generate special nodes
2815 in the finite automaton (as with C<\b>).  Characters special to the
2816 RE engine (such as C<|>) generate corresponding nodes or groups of
2817 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2818 converted to literal strings to match, or else is ignored (as is
2819 whitespace and C<#>-style comments if C<//x> is present).
2820
2821 Parsing of the bracketed character class construct, C<[...]>, is
2822 rather different than the rule used for the rest of the pattern.
2823 The terminator of this construct is found using the same rules as
2824 for finding the terminator of a C<{}>-delimited construct, the only
2825 exception being that C<]> immediately following C<[> is treated as
2826 though preceded by a backslash.
2827
2828 The terminator of runtime C<(?{...})> is found by temporarily switching
2829 control to the perl parser, which should stop at the point where the
2830 logically balancing terminating C<}> is found.
2831
2832 It is possible to inspect both the string given to RE engine and the
2833 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2834 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
2835 switch documented in L<perlrun/"Command Switches">.
2836
2837 =item Optimization of regular expressions
2838 X<regexp, optimization>
2839
2840 This step is listed for completeness only.  Since it does not change
2841 semantics, details of this step are not documented and are subject
2842 to change without notice.  This step is performed over the finite
2843 automaton that was generated during the previous pass.
2844
2845 It is at this stage that C<split()> silently optimizes C</^/> to
2846 mean C</^/m>.
2847
2848 =back
2849
2850 =head2 I/O Operators
2851 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2852 X<< <> >> X<@ARGV>
2853
2854 There are several I/O operators you should know about.
2855
2856 A string enclosed by backticks (grave accents) first undergoes
2857 double-quote interpolation.  It is then interpreted as an external
2858 command, and the output of that command is the value of the
2859 backtick string, like in a shell.  In scalar context, a single string
2860 consisting of all output is returned.  In list context, a list of
2861 values is returned, one per line of output.  (You can set C<$/> to use
2862 a different line terminator.)  The command is executed each time the
2863 pseudo-literal is evaluated.  The status value of the command is
2864 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2865 Unlike in B<csh>, no translation is done on the return data--newlines
2866 remain newlines.  Unlike in any of the shells, single quotes do not
2867 hide variable names in the command from interpretation.  To pass a
2868 literal dollar-sign through to the shell you need to hide it with a
2869 backslash.  The generalized form of backticks is C<qx//>.  (Because
2870 backticks always undergo shell expansion as well, see L<perlsec> for
2871 security concerns.)
2872 X<qx> X<`> X<``> X<backtick> X<glob>
2873
2874 In scalar context, evaluating a filehandle in angle brackets yields
2875 the next line from that file (the newline, if any, included), or
2876 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2877 (sometimes known as file-slurp mode) and the file is empty, it
2878 returns C<''> the first time, followed by C<undef> subsequently.
2879
2880 Ordinarily you must assign the returned value to a variable, but
2881 there is one situation where an automatic assignment happens.  If
2882 and only if the input symbol is the only thing inside the conditional
2883 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2884 the value is automatically assigned to the global variable $_,
2885 destroying whatever was there previously.  (This may seem like an
2886 odd thing to you, but you'll use the construct in almost every Perl
2887 script you write.)  The $_ variable is not implicitly localized.
2888 You'll have to put a C<local $_;> before the loop if you want that
2889 to happen.
2890
2891 The following lines are equivalent:
2892
2893     while (defined($_ = <STDIN>)) { print; }
2894     while ($_ = <STDIN>) { print; }
2895     while (<STDIN>) { print; }
2896     for (;<STDIN>;) { print; }
2897     print while defined($_ = <STDIN>);
2898     print while ($_ = <STDIN>);
2899     print while <STDIN>;
2900
2901 This also behaves similarly, but assigns to a lexical variable 
2902 instead of to C<$_>:
2903
2904     while (my $line = <STDIN>) { print $line }
2905
2906 In these loop constructs, the assigned value (whether assignment
2907 is automatic or explicit) is then tested to see whether it is
2908 defined.  The defined test avoids problems where the line has a string
2909 value that would be treated as false by Perl; for example a "" or
2910 a "0" with no trailing newline.  If you really mean for such values
2911 to terminate the loop, they should be tested for explicitly:
2912
2913     while (($_ = <STDIN>) ne '0') { ... }
2914     while (<STDIN>) { last unless $_; ... }
2915
2916 In other boolean contexts, C<< <FILEHANDLE> >> without an
2917 explicit C<defined> test or comparison elicits a warning if the
2918 C<use warnings> pragma or the B<-w>
2919 command-line switch (the C<$^W> variable) is in effect.
2920
2921 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2922 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2923 in packages, where they would be interpreted as local identifiers
2924 rather than global.)  Additional filehandles may be created with
2925 the open() function, amongst others.  See L<perlopentut> and
2926 L<perlfunc/open> for details on this.
2927 X<stdin> X<stdout> X<sterr>
2928
2929 If a <FILEHANDLE> is used in a context that is looking for
2930 a list, a list comprising all input lines is returned, one line per
2931 list element.  It's easy to grow to a rather large data space this
2932 way, so use with care.
2933
2934 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2935 See L<perlfunc/readline>.
2936
2937 The null filehandle <> is special: it can be used to emulate the
2938 behavior of B<sed> and B<awk>, and any other Unix filter program
2939 that takes a list of filenames, doing the same to each line
2940 of input from all of them.  Input from <> comes either from
2941 standard input, or from each file listed on the command line.  Here's
2942 how it works: the first time <> is evaluated, the @ARGV array is
2943 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2944 gives you standard input.  The @ARGV array is then processed as a list
2945 of filenames.  The loop
2946
2947     while (<>) {
2948         ...                     # code for each line
2949     }
2950
2951 is equivalent to the following Perl-like pseudo code:
2952
2953     unshift(@ARGV, '-') unless @ARGV;
2954     while ($ARGV = shift) {
2955         open(ARGV, $ARGV);
2956         while (<ARGV>) {
2957             ...         # code for each line
2958         }
2959     }
2960
2961 except that it isn't so cumbersome to say, and will actually work.
2962 It really does shift the @ARGV array and put the current filename
2963 into the $ARGV variable.  It also uses filehandle I<ARGV>
2964 internally. <> is just a synonym for <ARGV>, which
2965 is magical.  (The pseudo code above doesn't work because it treats
2966 <ARGV> as non-magical.)
2967
2968 Since the null filehandle uses the two argument form of L<perlfunc/open>
2969 it interprets special characters, so if you have a script like this:
2970
2971     while (<>) {
2972         print;
2973     }
2974
2975 and call it with C<perl dangerous.pl 'rm -rfv *|'>, it actually opens a
2976 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
2977 If you want all items in C<@ARGV> to be interpreted as file names, you
2978 can use the module C<ARGV::readonly> from CPAN.
2979
2980 You can modify @ARGV before the first <> as long as the array ends up
2981 containing the list of filenames you really want.  Line numbers (C<$.>)
2982 continue as though the input were one big happy file.  See the example
2983 in L<perlfunc/eof> for how to reset line numbers on each file.
2984
2985 If you want to set @ARGV to your own list of files, go right ahead.
2986 This sets @ARGV to all plain text files if no @ARGV was given:
2987
2988     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2989
2990 You can even set them to pipe commands.  For example, this automatically
2991 filters compressed arguments through B<gzip>:
2992
2993     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2994
2995 If you want to pass switches into your script, you can use one of the
2996 Getopts modules or put a loop on the front like this:
2997
2998     while ($_ = $ARGV[0], /^-/) {
2999         shift;
3000         last if /^--$/;
3001         if (/^-D(.*)/) { $debug = $1 }
3002         if (/^-v/)     { $verbose++  }
3003         # ...           # other switches
3004     }
3005
3006     while (<>) {
3007         # ...           # code for each line
3008     }
3009
3010 The <> symbol will return C<undef> for end-of-file only once.
3011 If you call it again after this, it will assume you are processing another
3012 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
3013
3014 If what the angle brackets contain is a simple scalar variable (for example,
3015 <$foo>), then that variable contains the name of the
3016 filehandle to input from, or its typeglob, or a reference to the
3017 same.  For example:
3018
3019     $fh = \*STDIN;
3020     $line = <$fh>;
3021
3022 If what's within the angle brackets is neither a filehandle nor a simple
3023 scalar variable containing a filehandle name, typeglob, or typeglob
3024 reference, it is interpreted as a filename pattern to be globbed, and
3025 either a list of filenames or the next filename in the list is returned,
3026 depending on context.  This distinction is determined on syntactic
3027 grounds alone.  That means C<< <$x> >> is always a readline() from
3028 an indirect handle, but C<< <$hash{key}> >> is always a glob().
3029 That's because $x is a simple scalar variable, but C<$hash{key}> is
3030 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
3031 is treated as C<glob("$x ")>, not C<readline($x)>.
3032
3033 One level of double-quote interpretation is done first, but you can't
3034 say C<< <$foo> >> because that's an indirect filehandle as explained
3035 in the previous paragraph.  (In older versions of Perl, programmers
3036 would insert curly brackets to force interpretation as a filename glob:
3037 C<< <${foo}> >>.  These days, it's considered cleaner to call the
3038 internal function directly as C<glob($foo)>, which is probably the right
3039 way to have done it in the first place.)  For example:
3040
3041     while (<*.c>) {
3042         chmod 0644, $_;
3043     }
3044
3045 is roughly equivalent to:
3046
3047     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
3048     while (<FOO>) {
3049         chomp;
3050         chmod 0644, $_;
3051     }
3052
3053 except that the globbing is actually done internally using the standard
3054 C<File::Glob> extension.  Of course, the shortest way to do the above is:
3055
3056     chmod 0644, <*.c>;
3057
3058 A (file)glob evaluates its (embedded) argument only when it is
3059 starting a new list.  All values must be read before it will start
3060 over.  In list context, this isn't important because you automatically
3061 get them all anyway.  However, in scalar context the operator returns
3062 the next value each time it's called, or C<undef> when the list has
3063 run out.  As with filehandle reads, an automatic C<defined> is
3064 generated when the glob occurs in the test part of a C<while>,
3065 because legal glob returns (for example,
3066 a file called F<0>) would otherwise
3067 terminate the loop.  Again, C<undef> is returned only once.  So if
3068 you're expecting a single value from a glob, it is much better to
3069 say
3070
3071     ($file) = <blurch*>;
3072
3073 than
3074
3075     $file = <blurch*>;
3076
3077 because the latter will alternate between returning a filename and
3078 returning false.
3079
3080 If you're trying to do variable interpolation, it's definitely better
3081 to use the glob() function, because the older notation can cause people
3082 to become confused with the indirect filehandle notation.
3083
3084     @files = glob("$dir/*.[ch]");
3085     @files = glob($files[$i]);
3086
3087 =head2 Constant Folding
3088 X<constant folding> X<folding>
3089
3090 Like C, Perl does a certain amount of expression evaluation at
3091 compile time whenever it determines that all arguments to an
3092 operator are static and have no side effects.  In particular, string
3093 concatenation happens at compile time between literals that don't do
3094 variable substitution.  Backslash interpolation also happens at
3095 compile time.  You can say
3096
3097       'Now is the time for all'
3098     . "\n" 
3099     .  'good men to come to.'
3100
3101 and this all reduces to one string internally.  Likewise, if
3102 you say
3103
3104     foreach $file (@filenames) {
3105         if (-s $file > 5 + 100 * 2**16) {  }
3106     }
3107
3108 the compiler precomputes the number which that expression
3109 represents so that the interpreter won't have to.
3110
3111 =head2 No-ops
3112 X<no-op> X<nop>
3113
3114 Perl doesn't officially have a no-op operator, but the bare constants
3115 C<0> and C<1> are special-cased not to produce a warning in void
3116 context, so you can for example safely do
3117
3118     1 while foo();
3119
3120 =head2 Bitwise String Operators
3121 X<operator, bitwise, string>
3122
3123 Bitstrings of any size may be manipulated by the bitwise operators
3124 (C<~ | & ^>).
3125
3126 If the operands to a binary bitwise op are strings of different
3127 sizes, B<|> and B<^> ops act as though the shorter operand had
3128 additional zero bits on the right, while the B<&> op acts as though
3129 the longer operand were truncated to the length of the shorter.
3130 The granularity for such extension or truncation is one or more
3131 bytes.
3132
3133     # ASCII-based examples
3134     print "j p \n" ^ " a h";            # prints "JAPH\n"
3135     print "JA" | "  ph\n";              # prints "japh\n"
3136     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3137     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3138
3139 If you are intending to manipulate bitstrings, be certain that
3140 you're supplying bitstrings: If an operand is a number, that will imply
3141 a B<numeric> bitwise operation.  You may explicitly show which type of
3142 operation you intend by using C<""> or C<0+>, as in the examples below.
3143
3144     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3145     $foo = '150' |  105;        # yields 255
3146     $foo =  150  | '105';       # yields 255
3147     $foo = '150' | '105';       # yields string '155' (under ASCII)
3148
3149     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3150     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3151
3152 See L<perlfunc/vec> for information on how to manipulate individual bits
3153 in a bit vector.
3154
3155 =head2 Integer Arithmetic
3156 X<integer>
3157
3158 By default, Perl assumes that it must do most of its arithmetic in
3159 floating point.  But by saying
3160
3161     use integer;
3162
3163 you may tell the compiler to use integer operations
3164 (see L<integer> for a detailed explanation) from here to the end of
3165 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3166
3167     no integer;
3168
3169 which lasts until the end of that BLOCK.  Note that this doesn't
3170 mean everything is an integer, merely that Perl will use integer
3171 operations for arithmetic, comparison, and bitwise operators.  For
3172 example, even under C<use integer>, if you take the C<sqrt(2)>, you'll
3173 still get C<1.4142135623731> or so.
3174
3175 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
3176 and ">>") always produce integral results.  (But see also
3177 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
3178 them.  By default, their results are interpreted as unsigned integers, but
3179 if C<use integer> is in effect, their results are interpreted
3180 as signed integers.  For example, C<~0> usually evaluates to a large
3181 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
3182 machines.
3183
3184 =head2 Floating-point Arithmetic
3185
3186 X<floating-point> X<floating point> X<float> X<real>
3187
3188 While C<use integer> provides integer-only arithmetic, there is no
3189 analogous mechanism to provide automatic rounding or truncation to a
3190 certain number of decimal places.  For rounding to a certain number
3191 of digits, sprintf() or printf() is usually the easiest route.
3192 See L<perlfaq4>.
3193
3194 Floating-point numbers are only approximations to what a mathematician
3195 would call real numbers.  There are infinitely more reals than floats,
3196 so some corners must be cut.  For example:
3197
3198     printf "%.20g\n", 123456789123456789;
3199     #        produces 123456789123456784
3200
3201 Testing for exact floating-point equality or inequality is not a
3202 good idea.  Here's a (relatively expensive) work-around to compare
3203 whether two floating-point numbers are equal to a particular number of
3204 decimal places.  See Knuth, volume II, for a more robust treatment of
3205 this topic.
3206
3207     sub fp_equal {
3208         my ($X, $Y, $POINTS) = @_;
3209         my ($tX, $tY);
3210         $tX = sprintf("%.${POINTS}g", $X);
3211         $tY = sprintf("%.${POINTS}g", $Y);
3212         return $tX eq $tY;
3213     }
3214
3215 The POSIX module (part of the standard perl distribution) implements
3216 ceil(), floor(), and other mathematical and trigonometric functions.
3217 The Math::Complex module (part of the standard perl distribution)
3218 defines mathematical functions that work on both the reals and the
3219 imaginary numbers.  Math::Complex not as efficient as POSIX, but
3220 POSIX can't work with complex numbers.
3221
3222 Rounding in financial applications can have serious implications, and
3223 the rounding method used should be specified precisely.  In these
3224 cases, it probably pays not to trust whichever system rounding is
3225 being used by Perl, but to instead implement the rounding function you
3226 need yourself.
3227
3228 =head2 Bigger Numbers
3229 X<number, arbitrary precision>
3230
3231 The standard C<Math::BigInt>, C<Math::BigRat>, and C<Math::BigFloat> modules,
3232 along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide
3233 variable-precision arithmetic and overloaded operators, although
3234 they're currently pretty slow. At the cost of some space and
3235 considerable speed, they avoid the normal pitfalls associated with
3236 limited-precision representations.
3237
3238         use 5.010;
3239         use bigint;  # easy interface to Math::BigInt
3240         $x = 123456789123456789;
3241         say $x * $x;
3242     +15241578780673678515622620750190521
3243
3244 Or with rationals:
3245
3246         use 5.010;
3247         use bigrat;
3248         $a = 3/22;
3249         $b = 4/6;
3250         say "a/b is ", $a/$b;
3251         say "a*b is ", $a*$b;
3252     a/b is 9/44
3253     a*b is 1/11
3254
3255 Several modules let you calculate with (bound only by memory and CPU time)
3256 unlimited or fixed precision. There are also some non-standard modules that
3257 provide faster implementations via external C libraries.
3258
3259 Here is a short, but incomplete summary:
3260
3261   Math::String           treat string sequences like numbers
3262   Math::FixedPrecision   calculate with a fixed precision
3263   Math::Currency         for currency calculations
3264   Bit::Vector            manipulate bit vectors fast (uses C)
3265   Math::BigIntFast       Bit::Vector wrapper for big numbers
3266   Math::Pari             provides access to the Pari C library
3267   Math::Cephes           uses the external Cephes C library (no
3268                          big numbers)
3269   Math::Cephes::Fraction fractions via the Cephes library
3270   Math::GMP              another one using an external C library
3271   Math::GMPz             an alternative interface to libgmp's big ints
3272   Math::GMPq             an interface to libgmp's fraction numbers
3273   Math::GMPf             an interface to libgmp's floating point numbers
3274
3275 Choose wisely.
3276
3277 =cut