ext/B/B/Concise.pm

   1 package B::Concise;
   2 # Copyright (C) 2000-2003 Stephen McCamant. All rights reserved.
   3 # This program is free software; you can redistribute and/or modify it
   4 # under the same terms as Perl itself.
   5
   6 # Note: we need to keep track of how many use declarations/BEGIN
   7 # blocks this module uses, so we can avoid printing them when user
   8 # asks for the BEGIN blocks in her program. Update the comments and
   9 # the count in concise_specials if you add or delete one. The
  10 # -MO=Concise counts as use #1.
  11
  12 use strict; # use #2
  13 use warnings; # uses #3 and #4, since warnings uses Carp
  14
  15 use Exporter (); # use #5
  16
  17 our $VERSION   = "0.996";
  18 our @ISA       = qw(Exporter);
  19 our @EXPORT_OK = qw( set_style set_style_standard add_callback
  20                      concise_subref concise_cv concise_main
  21                      add_style walk_output compile reset_sequence );
  22 our %EXPORT_TAGS =
  23     ( io        => [qw( walk_output compile reset_sequence )],
  24       style     => [qw( add_style set_style_standard )],
  25       cb        => [qw( add_callback )],
  26       mech      => [qw( concise_subref concise_cv concise_main )],  );
  27
  28 # use #6
  29 use B qw(class ppname main_start main_root main_cv cstring svref_2object
  30          SVf_IOK SVf_NOK SVf_POK SVf_IVisUV SVf_FAKE OPf_KIDS OPf_SPECIAL
  31          CVf_ANON PAD_FAKELEX_ANON PAD_FAKELEX_MULTI SVf_ROK);
  32
  33 my %style =
  34   ("terse" =>
  35    ["(?(#label =>\n)?)(*(    )*)#class (#addr) #name (?([#targ])?) "
  36     . "#svclass~(?((#svaddr))?)~#svval~(?(label \"#coplabel\")?)\n",
  37     "(*(    )*)goto #class (#addr)\n",
  38     "#class pp_#name"],
  39    "concise" =>
  40    ["#hyphseq2 (*(   (x( ;)x))*)<#classsym> #exname#arg(?([#targarglife])?)"
  41     . "~#flags(?(/#private)?)(?(:#hints)?)(x(;~->#next)x)\n"
  42     , "  (*(    )*)     goto #seq\n",
  43     "(?(<#seq>)?)#exname#arg(?([#targarglife])?)"],
  44    "linenoise" =>
  45    ["(x(;(*( )*))x)#noise#arg(?([#targarg])?)(x( ;\n)x)",
  46     "gt_#seq ",
  47     "(?(#seq)?)#noise#arg(?([#targarg])?)"],
  48    "debug" =>
  49    ["#class (#addr)\n\top_next\t\t#nextaddr\n\t(?(op_other\t#otheraddr\n\t)?)"
  50     . "op_sibling\t#sibaddr\n\t"
  51     . "op_ppaddr\tPL_ppaddr[OP_#NAME]\n\top_type\t\t#typenum\n"
  52     . "\top_flags\t#flagval\n\top_private\t#privval\t#hintsval\n"
  53     . "(?(\top_first\t#firstaddr\n)?)(?(\top_last\t\t#lastaddr\n)?)"
  54     . "(?(\top_sv\t\t#svaddr\n)?)",
  55     "    GOTO #addr\n",
  56     "#addr"],
  57    "env" => [$ENV{B_CONCISE_FORMAT}, $ENV{B_CONCISE_GOTO_FORMAT},
  58              $ENV{B_CONCISE_TREE_FORMAT}],
  59   );
  60
  61 # Renderings, ie how Concise prints, is controlled by these vars
  62 # primary:
  63 our $stylename;         # selects current style from %style
  64 my $order = "basic";    # how optree is walked & printed: basic, exec, tree
  65
  66 # rendering mechanics:
  67 # these 'formats' are the line-rendering templates
  68 # they're updated from %style when $stylename changes
  69 my ($format, $gotofmt, $treefmt);
  70
  71 # lesser players:
  72 my $base = 36;          # how <sequence#> is displayed
  73 my $big_endian = 1;     # more <sequence#> display
  74 my $tree_style = 0;     # tree-order details
  75 my $banner = 1;         # print banner before optree is traversed
  76 my $do_main = 0;        # force printing of main routine
  77 my $show_src;           # show source code
  78
  79 # another factor: can affect all styles!
  80 our @callbacks;         # allow external management
  81
  82 set_style_standard("concise");
  83
  84 my $curcv;
  85 my $cop_seq_base;
  86
  87 sub set_style {
  88     ($format, $gotofmt, $treefmt) = @_;
  89     #warn "set_style: deprecated, use set_style_standard instead\n"; # someday
  90     die "expecting 3 style-format args\n" unless @_ == 3;
  91 }
  92
  93 sub add_style {
  94     my ($newstyle,@args) = @_;
  95     die "style '$newstyle' already exists, choose a new name\n"
  96         if exists $style{$newstyle};
  97     die "expecting 3 style-format args\n" unless @args == 3;
  98     $style{$newstyle} = [@args];
  99     $stylename = $newstyle; # update rendering state
 100 }
 101
 102 sub set_style_standard {
 103     ($stylename) = @_; # update rendering state
 104     die "err: style '$stylename' unknown\n" unless exists $style{$stylename};
 105     set_style(@{$style{$stylename}});
 106 }
 107
 108 sub add_callback {
 109     push @callbacks, @_;
 110 }
 111
 112 # output handle, used with all Concise-output printing
 113 our $walkHandle;        # public for your convenience
 114 BEGIN { $walkHandle = \*STDOUT }
 115
 116 sub walk_output { # updates $walkHandle
 117     my $handle = shift;
 118     return $walkHandle unless $handle; # allow use as accessor
 119
 120     if (ref $handle eq 'SCALAR') {
 121         require Config;
 122         die "no perlio in this build, can't call walk_output (\\\$scalar)\n"
 123             unless $Config::Config{useperlio};
 124         # in 5.8+, open(FILEHANDLE,MODE,REFERENCE) writes to string
 125         open my $tmp, '>', $handle;     # but cant re-set existing STDOUT
 126         $walkHandle = $tmp;             # so use my $tmp as intermediate var
 127         return $walkHandle;
 128     }
 129     my $iotype = ref $handle;
 130     die "expecting argument/object that can print\n"
 131         unless $iotype eq 'GLOB' or $iotype and $handle->can('print');
 132     $walkHandle = $handle;
 133 }
 134
 135 sub concise_subref {
 136     my($order, $coderef, $name) = @_;
 137     my $codeobj = svref_2object($coderef);
 138
 139     return concise_stashref(@_)
 140         unless ref($codeobj) =~ '^B::(?:CV|FM)\z';
 141     concise_cv_obj($order, $codeobj, $name);
 142 }
 143
 144 sub concise_stashref {
 145     my($order, $h) = @_;
 146     local *s;
 147     foreach my $k (sort keys %$h) {
 148         next unless defined $h->{$k};
 149         *s = $h->{$k};
 150         my $coderef = *s{CODE} or next;
 151         reset_sequence();
 152         print "FUNC: ", *s, "\n";
 153         my $codeobj = svref_2object($coderef);
 154         next unless ref $codeobj eq 'B::CV';
 155         eval { concise_cv_obj($order, $codeobj, $k) };
 156         warn "err $@ on $codeobj" if $@;
 157     }
 158 }
 159
 160 # This should have been called concise_subref, but it was exported
 161 # under this name in versions before 0.56
 162 *concise_cv = \&concise_subref;
 163
 164 sub concise_cv_obj {
 165     my ($order, $cv, $name) = @_;
 166     # name is either a string, or a CODE ref (copy of $cv arg??)
 167
 168     $curcv = $cv;
 169
 170     if (ref($cv->XSUBANY) =~ /B::(\w+)/) {
 171         print $walkHandle "$name is a constant sub, optimized to a $1\n";
 172         return;
 173     }
 174     if ($cv->XSUB) {
 175         print $walkHandle "$name is XS code\n";
 176         return;
 177     }
 178     if (class($cv->START) eq "NULL") {
 179         no strict 'refs';
 180         if (ref $name eq 'CODE') {
 181             print $walkHandle "coderef $name has no START\n";
 182         }
 183         elsif (exists &$name) {
 184             print $walkHandle "$name exists in stash, but has no START\n";
 185         }
 186         else {
 187             print $walkHandle "$name not in symbol table\n";
 188         }
 189         return;
 190     }
 191     sequence($cv->START);
 192     if ($order eq "exec") {
 193         walk_exec($cv->START);
 194     }
 195     elsif ($order eq "basic") {
 196         # walk_topdown($cv->ROOT, sub { $_[0]->concise($_[1]) }, 0);
 197         my $root = $cv->ROOT;
 198         unless (ref $root eq 'B::NULL') {
 199             walk_topdown($root, sub { $_[0]->concise($_[1]) }, 0);
 200         } else {
 201             print $walkHandle "B::NULL encountered doing ROOT on $cv. avoiding disaster\n";
 202         }
 203     } else {
 204         print $walkHandle tree($cv->ROOT, 0);
 205     }
 206 }
 207
 208 sub concise_main {
 209     my($order) = @_;
 210     sequence(main_start);
 211     $curcv = main_cv;
 212     if ($order eq "exec") {
 213         return if class(main_start) eq "NULL";
 214         walk_exec(main_start);
 215     } elsif ($order eq "tree") {
 216         return if class(main_root) eq "NULL";
 217         print $walkHandle tree(main_root, 0);
 218     } elsif ($order eq "basic") {
 219         return if class(main_root) eq "NULL";
 220         walk_topdown(main_root,
 221                      sub { $_[0]->concise($_[1]) }, 0);
 222     }
 223 }
 224
 225 sub concise_specials {
 226     my($name, $order, @cv_s) = @_;
 227     my $i = 1;
 228     if ($name eq "BEGIN") {
 229         splice(@cv_s, 0, 8); # skip 7 BEGIN blocks in this file. NOW 8 ??
 230     } elsif ($name eq "CHECK") {
 231         pop @cv_s; # skip the CHECK block that calls us
 232     }
 233     for my $cv (@cv_s) {
 234         print $walkHandle "$name $i:\n";
 235         $i++;
 236         concise_cv_obj($order, $cv, $name);
 237     }
 238 }
 239
 240 my $start_sym = "\e(0"; # "\cN" sometimes also works
 241 my $end_sym   = "\e(B"; # "\cO" respectively
 242
 243 my @tree_decorations =
 244   (["  ", "--", "+-", "|-", "| ", "`-", "-", 1],
 245    [" ", "-", "+", "+", "|", "`", "", 0],
 246    ["  ", map("$start_sym$_$end_sym", "qq", "wq", "tq", "x ", "mq", "q"), 1],
 247    [" ", map("$start_sym$_$end_sym", "q", "w", "t", "x", "m"), "", 0],
 248   );
 249
 250 my @render_packs; # collect -stash=<packages>
 251
 252 sub compileOpts {
 253     # set rendering state from options and args
 254     my (@options,@args);
 255     if (@_) {
 256         @options = grep(/^-/, @_);
 257         @args = grep(!/^-/, @_);
 258     }
 259     for my $o (@options) {
 260         # mode/order
 261         if ($o eq "-basic") {
 262             $order = "basic";
 263         } elsif ($o eq "-exec") {
 264             $order = "exec";
 265         } elsif ($o eq "-tree") {
 266             $order = "tree";
 267         }
 268         # tree-specific
 269         elsif ($o eq "-compact") {
 270             $tree_style |= 1;
 271         } elsif ($o eq "-loose") {
 272             $tree_style &= ~1;
 273         } elsif ($o eq "-vt") {
 274             $tree_style |= 2;
 275         } elsif ($o eq "-ascii") {
 276             $tree_style &= ~2;
 277         }
 278         # sequence numbering
 279         elsif ($o =~ /^-base(\d+)$/) {
 280             $base = $1;
 281         } elsif ($o eq "-bigendian") {
 282             $big_endian = 1;
 283         } elsif ($o eq "-littleendian") {
 284             $big_endian = 0;
 285         }
 286         # miscellaneous, presentation
 287         elsif ($o eq "-nobanner") {
 288             $banner = 0;
 289         } elsif ($o eq "-banner") {
 290             $banner = 1;
 291         }
 292         elsif ($o eq "-main") {
 293             $do_main = 1;
 294         } elsif ($o eq "-nomain") {
 295             $do_main = 0;
 296         } elsif ($o eq "-src") {
 297             $show_src = 1;
 298         }
 299         elsif ($o =~ /^-stash=(.*)/) {
 300             my $pkg = $1;
 301             no strict 'refs';
 302             if (! %{$pkg.'::'}) {
 303                 eval "require $pkg";
 304             } else {
 305                 require Config;
 306                 if (!$Config::Config{usedl}
 307                     && keys %{$pkg.'::'} == 1
 308                     && $pkg->can('bootstrap')) {
 309                     # It is something that we're statically linked to, but hasn't
 310                     # yet been used.
 311                     eval "require $pkg";
 312                 }
 313             }
 314             push @render_packs, $pkg;
 315         }
 316         # line-style options
 317         elsif (exists $style{substr($o, 1)}) {
 318             $stylename = substr($o, 1);
 319             set_style_standard($stylename);
 320         } else {
 321             warn "Option $o unrecognized";
 322         }
 323     }
 324     return (@args);
 325 }
 326
 327 sub compile {
 328     my (@args) = compileOpts(@_);
 329     return sub {
 330         my @newargs = compileOpts(@_); # accept new rendering options
 331         warn "disregarding non-options: @newargs\n" if @newargs;
 332
 333         for my $objname (@args) {
 334             next unless $objname; # skip null args to avoid noisy responses
 335
 336             if ($objname eq "BEGIN") {
 337                 concise_specials("BEGIN", $order,
 338                                  B::begin_av->isa("B::AV") ?
 339                                  B::begin_av->ARRAY : ());
 340             } elsif ($objname eq "INIT") {
 341                 concise_specials("INIT", $order,
 342                                  B::init_av->isa("B::AV") ?
 343                                  B::init_av->ARRAY : ());
 344             } elsif ($objname eq "CHECK") {
 345                 concise_specials("CHECK", $order,
 346                                  B::check_av->isa("B::AV") ?
 347                                  B::check_av->ARRAY : ());
 348             } elsif ($objname eq "UNITCHECK") {
 349                 concise_specials("UNITCHECK", $order,
 350                                  B::unitcheck_av->isa("B::AV") ?
 351                                  B::unitcheck_av->ARRAY : ());
 352             } elsif ($objname eq "END") {
 353                 concise_specials("END", $order,
 354                                  B::end_av->isa("B::AV") ?
 355                                  B::end_av->ARRAY : ());
 356             }
 357             else {
 358                 # convert function names to subrefs
 359                 if (ref $objname) {
 360                     print $walkHandle "B::Concise::compile($objname)\n"
 361                         if $banner;
 362                     concise_subref($order, ($objname)x2);
 363                     next;
 364                 } else {
 365                     $objname = "main::" . $objname unless $objname =~ /::/;
 366                     no strict 'refs';
 367                     my $glob = \*$objname;
 368                     unless (*$glob{CODE} || *$glob{FORMAT}) {
 369                         print $walkHandle "$objname:\n" if $banner;
 370                         print $walkHandle "err: unknown function ($objname)\n";
 371                         return;
 372                     }
 373                     if (my $objref = *$glob{CODE}) {
 374                         print $walkHandle "$objname:\n" if $banner;
 375                         concise_subref($order, $objref, $objname);
 376                     }
 377                     if (my $objref = *$glob{FORMAT}) {
 378                         print $walkHandle "$objname (FORMAT):\n"
 379                             if $banner;
 380                         concise_subref($order, $objref, $objname);
 381                     }
 382                 }
 383             }
 384         }
 385         for my $pkg (@render_packs) {
 386             no strict 'refs';
 387             concise_stashref($order, \%{$pkg.'::'});
 388         }
 389
 390         if (!@args or $do_main or @render_packs) {
 391             print $walkHandle "main program:\n" if $do_main;
 392             concise_main($order);
 393         }
 394         return @args;   # something
 395     }
 396 }
 397
 398 my %labels;
 399 my $lastnext;   # remembers op-chain, used to insert gotos
 400
 401 my %opclass = ('OP' => "0", 'UNOP' => "1", 'BINOP' => "2", 'LOGOP' => "|",
 402                'LISTOP' => "@", 'PMOP' => "/", 'SVOP' => "\$", 'GVOP' => "*",
 403                'PVOP' => '"', 'LOOP' => "{", 'COP' => ";", 'PADOP' => "#",
 404                'METHOP' => '.', UNOP_AUX => '+');
 405
 406 no warnings 'qw'; # "Possible attempt to put comments..."; use #7
 407 my @linenoise =
 408   qw'#  () sc (  @? 1  $* gv *{ m$ m@ m% m? p/ *$ $  $# & a& pt \\ s\\ rf bl
 409      `  *? <> ?? ?/ r/ c/ // qr s/ /c y/ =  @= C  sC Cp sp df un BM po +1 +I
 410      -1 -I 1+ I+ 1- I- ** *  i* /  i/ %$ i% x  +  i+ -  i- .  "  << >> <  i<
 411      >  i> <= i, >= i. == i= != i! <? i? s< s> s, s. s= s! s? b& b^ b| -0 -i
 412      !  ~  a2 si cs rd sr e^ lg sq in %x %o ab le ss ve ix ri sf FL od ch cy
 413      uf lf uc lc qm @  [f [  @[ eh vl ky dl ex %  ${ @{ uk pk st jn )  )[ a@
 414      a% sl +] -] [- [+ so rv GS GW MS MW .. f. .f && || ^^ ?: &= |= -> s{ s}
 415      v} ca wa di rs ;; ;  ;d }{ {  }  {} f{ it {l l} rt }l }n }r dm }g }e ^o
 416      ^c ^| ^# um bm t~ u~ ~d DB db ^s se ^g ^r {w }w pf pr ^O ^K ^R ^W ^d ^v
 417      ^e ^t ^k t. fc ic fl .s .p .b .c .l .a .h g1 s1 g2 s2 ?. l? -R -W -X -r
 418      -w -x -e -o -O -z -s -M -A -C -S -c -b -f -d -p -l -u -g -k -t -T -B cd
 419      co cr u. cm ut r. l@ s@ r@ mD uD oD rD tD sD wD cD f$ w$ p$ sh e$ k$ g3
 420      g4 s4 g5 s5 T@ C@ L@ G@ A@ S@ Hg Hc Hr Hw Mg Mc Ms Mr Sg Sc So rq do {e
 421      e} {t t} g6 G6 6e g7 G7 7e g8 G8 8e g9 G9 9e 6s 7s 8s 9s 6E 7E 8E 9E Pn
 422      Pu GP SP EP Gn Gg GG SG EG g0 c$ lk t$ ;s n> // /= CO';
 423
 424 my $chars = "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ";
 425
 426 sub op_flags { # common flags (see BASOP.op_flags in op.h)
 427     my($x) = @_;
 428     my(@v);
 429     push @v, "v" if ($x & 3) == 1;
 430     push @v, "s" if ($x & 3) == 2;
 431     push @v, "l" if ($x & 3) == 3;
 432     push @v, "K" if $x & 4;
 433     push @v, "P" if $x & 8;
 434     push @v, "R" if $x & 16;
 435     push @v, "M" if $x & 32;
 436     push @v, "S" if $x & 64;
 437     push @v, "*" if $x & 128;
 438     return join("", @v);
 439 }
 440
 441 sub base_n {
 442     my $x = shift;
 443     return "-" . base_n(-$x) if $x < 0;
 444     my $str = "";
 445     do { $str .= substr($chars, $x % $base, 1) } while $x = int($x / $base);
 446     $str = reverse $str if $big_endian;
 447     return $str;
 448 }
 449
 450 my %sequence_num;
 451 my $seq_max = 1;
 452
 453 sub reset_sequence {
 454     # reset the sequence
 455     %sequence_num = ();
 456     $seq_max = 1;
 457     $lastnext = 0;
 458 }
 459
 460 sub seq {
 461     my($op) = @_;
 462     return "-" if not exists $sequence_num{$$op};
 463     return base_n($sequence_num{$$op});
 464 }
 465
 466 sub walk_topdown {
 467     my($op, $sub, $level) = @_;
 468     $sub->($op, $level);
 469     if ($op->flags & OPf_KIDS) {
 470         for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
 471             walk_topdown($kid, $sub, $level + 1);
 472         }
 473     }
 474     if (class($op) eq "PMOP") {
 475         my $maybe_root = $op->code_list;
 476         if ( ref($maybe_root) and $maybe_root->isa("B::OP")
 477          and not $op->flags & OPf_KIDS) {
 478             walk_topdown($maybe_root, $sub, $level + 1);
 479         }
 480         $maybe_root = $op->pmreplroot;
 481         if (ref($maybe_root) and $maybe_root->isa("B::OP")) {
 482             # It really is the root of the replacement, not something
 483             # else stored here for lack of space elsewhere
 484             walk_topdown($maybe_root, $sub, $level + 1);
 485         }
 486     }
 487 }
 488
 489 sub walklines {
 490     my($ar, $level) = @_;
 491     for my $l (@$ar) {
 492         if (ref($l) eq "ARRAY") {
 493             walklines($l, $level + 1);
 494         } else {
 495             $l->concise($level);
 496         }
 497     }
 498 }
 499
 500 sub walk_exec {
 501     my($top, $level) = @_;
 502     my %opsseen;
 503     my @lines;
 504     my @todo = ([$top, \@lines]);
 505     while (@todo and my($op, $targ) = @{shift @todo}) {
 506         for (; $$op; $op = $op->next) {
 507             last if $opsseen{$$op}++;
 508             push @$targ, $op;
 509             my $name = $op->name;
 510             if (class($op) eq "LOGOP") {
 511                 my $ar = [];
 512                 push @$targ, $ar;
 513                 push @todo, [$op->other, $ar];
 514             } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
 515                 my $ar = [];
 516                 push @$targ, $ar;
 517                 push @todo, [$op->pmreplstart, $ar];
 518             } elsif ($name =~ /^enter(loop|iter)$/) {
 519                 $labels{${$op->nextop}} = "NEXT";
 520                 $labels{${$op->lastop}} = "LAST";
 521                 $labels{${$op->redoop}} = "REDO";
 522             }
 523         }
 524     }
 525     walklines(\@lines, 0);
 526 }
 527
 528 # The structure of this routine is purposely modeled after op.c's peep()
 529 sub sequence {
 530     my($op) = @_;
 531     my $oldop = 0;
 532     return if class($op) eq "NULL" or exists $sequence_num{$$op};
 533     for (; $$op; $op = $op->next) {
 534         last if exists $sequence_num{$$op};
 535         my $name = $op->name;
 536         $sequence_num{$$op} = $seq_max++;
 537         if (class($op) eq "LOGOP") {
 538             sequence($op->other);
 539         } elsif (class($op) eq "LOOP") {
 540             sequence($op->redoop);
 541             sequence( $op->nextop);
 542             sequence($op->lastop);
 543         } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
 544             sequence($op->pmreplstart);
 545         }
 546         $oldop = $op;
 547     }
 548 }
 549
 550 sub fmt_line {    # generate text-line for op.
 551     my($hr, $op, $text, $level) = @_;
 552
 553     $_->($hr, $op, \$text, \$level, $stylename) for @callbacks;
 554
 555     return '' if $hr->{SKIP};   # suppress line if a callback said so
 556     return '' if $hr->{goto} and $hr->{goto} eq '-';    # no goto nowhere
 557
 558     # spec: (?(text1#varText2)?)
 559     $text =~ s/\(\?\(([^\#]*?)\#(\w+)([^\#]*?)\)\?\)/
 560         $hr->{$2} ? $1.$hr->{$2}.$3 : ""/eg;
 561
 562     # spec: (x(exec_text;basic_text)x)
 563     $text =~ s/\(x\((.*?);(.*?)\)x\)/$order eq "exec" ? $1 : $2/egs;
 564
 565     # spec: (*(text)*)
 566     $text =~ s/\(\*\(([^;]*?)\)\*\)/$1 x $level/egs;
 567
 568     # spec: (*(text1;text2)*)
 569     $text =~ s/\(\*\((.*?);(.*?)\)\*\)/$1 x ($level - 1) . $2 x ($level>0)/egs;
 570
 571     # convert #Var to tag=>val form: Var\t#var
 572     $text =~ s/\#([A-Z][a-z]+)(\d+)?/\t\u$1\t\L#$1$2/gs;
 573
 574     # spec: #varN
 575     $text =~ s/\#([a-zA-Z]+)(\d+)/sprintf("%-$2s", $hr->{$1})/eg;
 576
 577     $text =~ s/\#([a-zA-Z]+)/$hr->{$1}/eg;      # populate #var's
 578     $text =~ s/[ \t]*~+[ \t]*/ /g;              # squeeze tildes
 579
 580     $text = "# $hr->{src}\n$text" if $show_src and $hr->{src};
 581
 582     chomp $text;
 583     return "$text\n" if $text ne "" and $order ne "tree";
 584     return $text; # suppress empty lines
 585 }
 586
 587
 588
 589 # use require rather than use here to avoid disturbing tests that dump
 590 # BEGIN blocks
 591 require B::Op_private;
 592
 593
 594
 595 our %hints; # used to display each COP's op_hints values
 596
 597 # strict refs, subs, vars
 598 @hints{2,512,1024,32,64,128} = ('$', '&', '*', 'x$', 'x&', 'x*');
 599 # integers, locale, bytes
 600 @hints{1,4,8,16} = ('i', 'l', 'b');
 601 # block scope, localise %^H, $^OPEN (in), $^OPEN (out)
 602 @hints{256,131072,262144,524288} = ('{','%','<','>');
 603 # overload new integer, float, binary, string, re
 604 @hints{4096,8192,16384,32768,65536} = ('I', 'F', 'B', 'S', 'R');
 605 # taint and eval
 606 @hints{1048576,2097152} = ('T', 'E');
 607 # filetest access, UTF-8
 608 @hints{4194304,8388608} = ('X', 'U');
 609
 610 sub _flags {
 611     my($hash, $x) = @_;
 612     my @s;
 613     for my $flag (sort {$b <=> $a} keys %$hash) {
 614         if ($hash->{$flag} and $x & $flag and $x >= $flag) {
 615             $x -= $flag;
 616             push @s, $hash->{$flag};
 617         }
 618     }
 619     push @s, $x if $x;
 620     return join(",", @s);
 621 }
 622
 623 # return a string like 'LVINTRO,1' for the op $name with op_private
 624 # value $x
 625
 626 sub private_flags {
 627     my($name, $x) = @_;
 628     my $entry = $B::Op_private::bits{$name};
 629     return $x ? "$x" : '' unless $entry;
 630
 631     my @flags;
 632     my $bit;
 633     for ($bit = 7; $bit >= 0; $bit--) {
 634         next unless exists $entry->{$bit};
 635         my $e = $entry->{$bit};
 636         if (ref($e) eq 'HASH') {
 637             # bit field
 638
 639             my ($bitmin, $bitmax, $bitmask, $enum, $label) =
 640                     @{$e}{qw(bitmin bitmax bitmask enum label)};
 641             $bit = $bitmin;
 642             next if defined $label && $label eq '-'; # display as raw number
 643
 644             my $val = $x & $bitmask;
 645             $x &= ~$bitmask;
 646             $val >>= $bitmin;
 647
 648             if (defined $enum) {
 649                 # try to convert numeric $val into symbolic
 650                 my @enum = @$enum;
 651                 while (@enum) {
 652                     my $ix    = shift @enum;
 653                     my $name  = shift @enum;
 654                     my $label = shift @enum;
 655                     if ($val == $ix) {
 656                         $val = $label;
 657                         last;
 658                     }
 659                 }
 660             }
 661             next if $val eq '0'; # don't display anonymous zero values
 662             push @flags, defined $label ? "$label=$val" : $val;
 663
 664         }
 665         else {
 666             # flag bit
 667             my $label = $B::Op_private::labels{$e};
 668             next if defined $label && $label eq '-'; # display as raw number
 669             if ($x & (1<<$bit)) {
 670                 $x -= (1<<$bit);
 671                 push @flags, $label;
 672             }
 673         }
 674     }
 675
 676     push @flags, $x if $x; # display unknown bits numerically
 677     return join ",", @flags;
 678 }
 679
 680 sub hints_flags {
 681     my($x) = @_;
 682     _flags(\%hints, $x);
 683 }
 684
 685 sub concise_sv {
 686     my($sv, $hr, $preferpv) = @_;
 687     $hr->{svclass} = class($sv);
 688     $hr->{svclass} = "UV"
 689       if $hr->{svclass} eq "IV" and $sv->FLAGS & SVf_IVisUV;
 690     Carp::cluck("bad concise_sv: $sv") unless $sv and $$sv;
 691     $hr->{svaddr} = sprintf("%#x", $$sv);
 692     if ($hr->{svclass} eq "GV" && $sv->isGV_with_GP()) {
 693         my $gv = $sv;
 694         my $stash = $gv->STASH;
 695         if (class($stash) eq "SPECIAL") {
 696             $stash = "<none>";
 697         }
 698         else {
 699             $stash = $stash->NAME;
 700         }
 701         if ($stash eq "main") {
 702             $stash = "";
 703         } else {
 704             $stash = $stash . "::";
 705         }
 706         $hr->{svval} = "*$stash" . $gv->SAFENAME;
 707         return "*$stash" . $gv->SAFENAME;
 708     } else {
 709         if ($] >= 5.011) {
 710             while (class($sv) eq "IV" && $sv->FLAGS & SVf_ROK) {
 711                 $hr->{svval} .= "\\";
 712                 $sv = $sv->RV;
 713             }
 714         } else {
 715             while (class($sv) eq "RV") {
 716                 $hr->{svval} .= "\\";
 717                 $sv = $sv->RV;
 718             }
 719         }
 720         if (class($sv) eq "SPECIAL") {
 721             $hr->{svval} .= ["Null", "sv_undef", "sv_yes", "sv_no"]->[$$sv];
 722         } elsif ($preferpv
 723               && ($sv->FLAGS & SVf_POK || class($sv) eq "REGEXP")) {
 724             $hr->{svval} .= cstring($sv->PV);
 725         } elsif ($sv->FLAGS & SVf_NOK) {
 726             $hr->{svval} .= $sv->NV;
 727         } elsif ($sv->FLAGS & SVf_IOK) {
 728             $hr->{svval} .= $sv->int_value;
 729         } elsif ($sv->FLAGS & SVf_POK || class($sv) eq "REGEXP") {
 730             $hr->{svval} .= cstring($sv->PV);
 731         } elsif (class($sv) eq "HV") {
 732             $hr->{svval} .= 'HASH';
 733         }
 734
 735         $hr->{svval} = 'undef' unless defined $hr->{svval};
 736         my $out = $hr->{svclass};
 737         return $out .= " $hr->{svval}" ;
 738     }
 739 }
 740
 741 my %srclines;
 742
 743 sub fill_srclines {
 744     my $fullnm = shift;
 745     if ($fullnm eq '-e') {
 746         $srclines{$fullnm} = [ $fullnm, "-src not supported for -e" ];
 747         return;
 748     }
 749     open (my $fh, '<', $fullnm)
 750         or warn "# $fullnm: $!, (chdirs not supported by this feature yet)\n"
 751         and return;
 752     my @l = <$fh>;
 753     chomp @l;
 754     unshift @l, $fullnm; # like @{_<$fullnm} in debug, array starts at 1
 755     $srclines{$fullnm} = \@l;
 756 }
 757
 758 sub concise_op {
 759     my ($op, $level, $format) = @_;
 760     my %h;
 761     $h{exname} = $h{name} = $op->name;
 762     $h{NAME} = uc $h{name};
 763     $h{class} = class($op);
 764     $h{extarg} = $h{targ} = $op->targ;
 765     $h{extarg} = "" unless $h{extarg};
 766     $h{privval} = $op->private;
 767     # for null ops, targ holds the old type
 768     my $origname = $h{name} eq "null" && $h{targ}
 769       ? substr(ppname($h{targ}), 3)
 770       : $h{name};
 771     $h{private} = private_flags($origname, $op->private);
 772     if ($op->folded) {
 773       $h{private} &&= "$h{private},";
 774       $h{private} .= "FOLD";
 775     }
 776
 777     if ($h{name} ne $origname) { # a null op
 778         $h{exname} = "ex-$origname";
 779         $h{extarg} = "";
 780     } elsif ($h{private} =~ /\bREFC\b/) {
 781         # targ holds a reference count
 782         my $refs = "ref" . ($h{targ} != 1 ? "s" : "");
 783         $h{targarglife} = $h{targarg} = "$h{targ} $refs";
 784     } elsif ($h{targ}) {
 785         my $count = $h{name} eq 'padrange'
 786             ? ($op->private & $B::Op_private::defines{'OPpPADRANGE_COUNTMASK'})
 787             : 1;
 788         my (@targarg, @targarglife);
 789         for my $i (0..$count-1) {
 790             my ($targarg, $targarglife);
 791             my $padname = (($curcv->PADLIST->ARRAY)[0]->ARRAY)[$h{targ}+$i];
 792             if (defined $padname and class($padname) ne "SPECIAL" and
 793                 $padname->LEN)
 794             {
 795                 $targarg  = $padname->PVX;
 796                 if ($padname->FLAGS & SVf_FAKE) {
 797                     # These changes relate to the jumbo closure fix.
 798                     # See changes 19939 and 20005
 799                     my $fake = '';
 800                     $fake .= 'a'
 801                         if $padname->PARENT_FAKELEX_FLAGS & PAD_FAKELEX_ANON;
 802                     $fake .= 'm'
 803                         if $padname->PARENT_FAKELEX_FLAGS & PAD_FAKELEX_MULTI;
 804                     $fake .= ':' . $padname->PARENT_PAD_INDEX
 805                         if $curcv->CvFLAGS & CVf_ANON;
 806                     $targarglife = "$targarg:FAKE:$fake";
 807                 }
 808                 else {
 809                     my $intro = $padname->COP_SEQ_RANGE_LOW - $cop_seq_base;
 810                     my $finish = int($padname->COP_SEQ_RANGE_HIGH) - $cop_seq_base;
 811                     $finish = "end" if $finish == 999999999 - $cop_seq_base;
 812                     $targarglife = "$targarg:$intro,$finish";
 813                 }
 814             } else {
 815                 $targarglife = $targarg = "t" . ($h{targ}+$i);
 816             }
 817             push @targarg,     $targarg;
 818             push @targarglife, $targarglife;
 819         }
 820         $h{targarg}     = join '; ', @targarg;
 821         $h{targarglife} = join '; ', @targarglife;
 822     }
 823     $h{arg} = "";
 824     $h{svclass} = $h{svaddr} = $h{svval} = "";
 825     if ($h{class} eq "PMOP") {
 826         my $extra = '';
 827         my $precomp = $op->precomp;
 828         if (defined $precomp) {
 829             $precomp = cstring($precomp); # Escape literal control sequences
 830             $precomp = "/$precomp/";
 831         } else {
 832             $precomp = "";
 833         }
 834         if ($op->name eq 'subst') {
 835             if (class($op->pmreplstart) ne "NULL") {
 836                 undef $lastnext;
 837                 $extra = " replstart->" . seq($op->pmreplstart);
 838             }
 839         }
 840         elsif ($op->name eq 'pushre') {
 841             # with C<@stash_array = split(/pat/, str);>,
 842             #  *stash_array is stored in /pat/'s pmreplroot.
 843             my $gv = $op->pmreplroot;
 844             if (!ref($gv)) {
 845                 # threaded: the value is actually a pad offset for where
 846                 # the GV is kept (op_pmtargetoff)
 847                 if ($gv) {
 848                     $gv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$gv]->NAME;
 849                 }
 850             }
 851             else {
 852                 # unthreaded: its a GV (if it exists)
 853                 $gv = (ref($gv) eq "B::GV") ? $gv->NAME : undef;
 854             }
 855             $extra = " => \@$gv" if $gv;
 856         }
 857         $h{arg} = "($precomp$extra)";
 858     } elsif ($h{class} eq "PVOP" and $h{name} !~ '^transr?\z') {
 859         $h{arg} = '("' . $op->pv . '")';
 860         $h{svval} = '"' . $op->pv . '"';
 861     } elsif ($h{class} eq "COP") {
 862         my $label = $op->label;
 863         $h{coplabel} = $label;
 864         $label = $label ? "$label: " : "";
 865         my $loc = $op->file;
 866         my $pathnm = $loc;
 867         $loc =~ s[.*/][];
 868         my $ln = $op->line;
 869         $loc .= ":$ln";
 870         my($stash, $cseq) = ($op->stash->NAME, $op->cop_seq - $cop_seq_base);
 871         $h{arg} = "($label$stash $cseq $loc)";
 872         if ($show_src) {
 873             fill_srclines($pathnm) unless exists $srclines{$pathnm};
 874             # Would love to retain Jim's use of // but this code needs to be
 875             # portable to 5.8.x
 876             my $line = $srclines{$pathnm}[$ln];
 877             $line = "-src unavailable under -e" unless defined $line;
 878             $h{src} = "$ln: $line";
 879         }
 880     } elsif ($h{class} eq "LOOP") {
 881         $h{arg} = "(next->" . seq($op->nextop) . " last->" . seq($op->lastop)
 882           . " redo->" . seq($op->redoop) . ")";
 883     } elsif ($h{class} eq "LOGOP") {
 884         undef $lastnext;
 885         $h{arg} = "(other->" . seq($op->other) . ")";
 886         $h{otheraddr} = sprintf("%#x", $ {$op->other});
 887     }
 888     elsif ($h{class} eq "SVOP" or $h{class} eq "PADOP") {
 889         unless ($h{name} eq 'aelemfast' and $op->flags & OPf_SPECIAL) {
 890             my $idx = ($h{class} eq "SVOP") ? $op->targ : $op->padix;
 891             if ($h{class} eq "PADOP" or !${$op->sv}) {
 892                 my $sv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$idx];
 893                 $h{arg} = "[" . concise_sv($sv, \%h, 0) . "]";
 894                 $h{targarglife} = $h{targarg} = "";
 895             } else {
 896                 $h{arg} = "(" . concise_sv($op->sv, \%h, 0) . ")";
 897             }
 898         }
 899     }
 900     elsif ($h{class} eq "METHOP") {
 901         my $prefix = '';
 902         if ($h{name} eq 'method_redir' or $h{name} eq 'method_redir_super') {
 903             my $rclass_sv = $op->rclass;
 904             $rclass_sv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$rclass_sv]
 905                 unless ref $rclass_sv;
 906             $prefix .= 'PACKAGE "'.$rclass_sv->PV.'", ';
 907         }
 908         if ($h{name} ne "method") {
 909             if (${$op->meth_sv}) {
 910                 $h{arg} = "($prefix" . concise_sv($op->meth_sv, \%h, 1) . ")";
 911             } else {
 912                 my $sv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$op->targ];
 913                 $h{arg} = "[$prefix" . concise_sv($sv, \%h, 1) . "]";
 914                 $h{targarglife} = $h{targarg} = "";
 915             }
 916         }
 917     }
 918     elsif ($h{class} eq "UNOP_AUX") {
 919         $h{arg} = "(" . $op->string($curcv) . ")";
 920     }
 921
 922     $h{seq} = $h{hyphseq} = seq($op);
 923     $h{seq} = "" if $h{seq} eq "-";
 924     $h{opt} = $op->opt;
 925     $h{label} = $labels{$$op};
 926     $h{next} = $op->next;
 927     $h{next} = (class($h{next}) eq "NULL") ? "(end)" : seq($h{next});
 928     $h{nextaddr} = sprintf("%#x", $ {$op->next});
 929     $h{sibaddr} = sprintf("%#x", $ {$op->sibling});
 930     $h{firstaddr} = sprintf("%#x", $ {$op->first}) if $op->can("first");
 931     $h{lastaddr} = sprintf("%#x", $ {$op->last}) if $op->can("last");
 932
 933     $h{classsym} = $opclass{$h{class}};
 934     $h{flagval} = $op->flags;
 935     $h{flags} = op_flags($op->flags);
 936     if ($op->can("hints")) {
 937       $h{hintsval} = $op->hints;
 938       $h{hints} = hints_flags($h{hintsval});
 939     } else {
 940       $h{hintsval} = $h{hints} = '';
 941     }
 942     $h{addr} = sprintf("%#x", $$op);
 943     $h{typenum} = $op->type;
 944     $h{noise} = $linenoise[$op->type];
 945
 946     return fmt_line(\%h, $op, $format, $level);
 947 }
 948
 949 sub B::OP::concise {
 950     my($op, $level) = @_;
 951     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
 952         # insert a 'goto' line
 953         my $synth = {"seq" => seq($lastnext), "class" => class($lastnext),
 954                      "addr" => sprintf("%#x", $$lastnext),
 955                      "goto" => seq($lastnext), # simplify goto '-' removal
 956              };
 957         print $walkHandle fmt_line($synth, $op, $gotofmt, $level+1);
 958     }
 959     $lastnext = $op->next;
 960     print $walkHandle concise_op($op, $level, $format);
 961 }
 962
 963 # B::OP::terse (see Terse.pm) now just calls this
 964 sub b_terse {
 965     my($op, $level) = @_;
 966
 967     # This isn't necessarily right, but there's no easy way to get
 968     # from an OP to the right CV. This is a limitation of the
 969     # ->terse() interface style, and there isn't much to do about
 970     # it. In particular, we can die in concise_op if the main pad
 971     # isn't long enough, or has the wrong kind of entries, compared to
 972     # the pad a sub was compiled with. The fix for that would be to
 973     # make a backwards compatible "terse" format that never even
 974     # looked at the pad, just like the old B::Terse. I don't think
 975     # that's worth the effort, though.
 976     $curcv = main_cv unless $curcv;
 977
 978     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
 979         # insert a 'goto'
 980         my $h = {"seq" => seq($lastnext), "class" => class($lastnext),
 981                  "addr" => sprintf("%#x", $$lastnext)};
 982         print # $walkHandle
 983             fmt_line($h, $op, $style{"terse"}[1], $level+1);
 984     }
 985     $lastnext = $op->next;
 986     print # $walkHandle
 987         concise_op($op, $level, $style{"terse"}[0]);
 988 }
 989
 990 sub tree {
 991     my $op = shift;
 992     my $level = shift;
 993     my $style = $tree_decorations[$tree_style];
 994     my($space, $single, $kids, $kid, $nokid, $last, $lead, $size) = @$style;
 995     my $name = concise_op($op, $level, $treefmt);
 996     if (not $op->flags & OPf_KIDS) {
 997         return $name . "\n";
 998     }
 999     my @lines;
1000     for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
1001         push @lines, tree($kid, $level+1);
1002     }
1003     my $i;
1004     for ($i = $#lines; substr($lines[$i], 0, 1) eq " "; $i--) {
1005         $lines[$i] = $space . $lines[$i];
1006     }
1007     if ($i > 0) {
1008         $lines[$i] = $last . $lines[$i];
1009         while ($i-- > 1) {
1010             if (substr($lines[$i], 0, 1) eq " ") {
1011                 $lines[$i] = $nokid . $lines[$i];
1012             } else {
1013                 $lines[$i] = $kid . $lines[$i];
1014             }
1015         }
1016         $lines[$i] = $kids . $lines[$i];
1017     } else {
1018         $lines[0] = $single . $lines[0];
1019     }
1020     return("$name$lead" . shift @lines,
1021            map(" " x (length($name)+$size) . $_, @lines));
1022 }
1023
1024 # *** Warning: fragile kludge ahead ***
1025 # Because the B::* modules run in the same interpreter as the code
1026 # they're compiling, their presence tends to distort the view we have of
1027 # the code we're looking at. In particular, perl gives sequence numbers
1028 # to COPs. If the program we're looking at were run on its own, this
1029 # would start at 1. Because all of B::Concise and all the modules it
1030 # uses are compiled first, though, by the time we get to the user's
1031 # program the sequence number is already pretty high, which could be
1032 # distracting if you're trying to tell OPs apart. Therefore we'd like to
1033 # subtract an offset from all the sequence numbers we display, to
1034 # restore the simpler view of the world. The trick is to know what that
1035 # offset will be, when we're still compiling B::Concise!  If we
1036 # hardcoded a value, it would have to change every time B::Concise or
1037 # other modules we use do. To help a little, what we do here is compile
1038 # a little code at the end of the module, and compute the base sequence
1039 # number for the user's program as being a small offset later, so all we
1040 # have to worry about are changes in the offset.
1041
1042 # [For 5.8.x and earlier perl is generating sequence numbers for all ops,
1043 #  and using them to reference labels]
1044
1045
1046 # When you say "perl -MO=Concise -e '$a'", the output should look like:
1047
1048 # 4  <@> leave[t1] vKP/REFC ->(end)
1049 # 1     <0> enter ->2
1050  #^ smallest OP sequence number should be 1
1051 # 2     <;> nextstate(main 1 -e:1) v ->3
1052  #                         ^ smallest COP sequence number should be 1
1053 # -     <1> ex-rv2sv vK/1 ->4
1054 # 3        <$> gvsv(*a) s ->4
1055
1056 # If the second of the marked numbers there isn't 1, it means you need
1057 # to update the corresponding magic number in the next line.
1058 # Remember, this needs to stay the last things in the module.
1059
1060 my $cop_seq_mnum = 16;
1061 $cop_seq_base = svref_2object(eval 'sub{0;}')->START->cop_seq + $cop_seq_mnum;
1062
1063 1;
1064
1065 __END__
1066
1067 =head1 NAME
1068
1069 B::Concise - Walk Perl syntax tree, printing concise info about ops
1070
1071 =head1 SYNOPSIS
1072
1073     perl -MO=Concise[,OPTIONS] foo.pl
1074
1075     use B::Concise qw(set_style add_callback);
1076
1077 =head1 DESCRIPTION
1078
1079 This compiler backend prints the internal OPs of a Perl program's syntax
1080 tree in one of several space-efficient text formats suitable for debugging
1081 the inner workings of perl or other compiler backends. It can print OPs in
1082 the order they appear in the OP tree, in the order they will execute, or
1083 in a text approximation to their tree structure, and the format of the
1084 information displayed is customizable. Its function is similar to that of
1085 perl's B<-Dx> debugging flag or the B<B::Terse> module, but it is more
1086 sophisticated and flexible.
1087
1088 =head1 EXAMPLE
1089
1090 Here's two outputs (or 'renderings'), using the -exec and -basic
1091 (i.e. default) formatting conventions on the same code snippet.
1092
1093     % perl -MO=Concise,-exec -e '$a = $b + 42'
1094     1  <0> enter
1095     2  <;> nextstate(main 1 -e:1) v
1096     3  <#> gvsv[*b] s
1097     4  <$> const[IV 42] s
1098  *  5  <2> add[t3] sK/2
1099     6  <#> gvsv[*a] s
1100     7  <2> sassign vKS/2
1101     8  <@> leave[1 ref] vKP/REFC
1102
1103 In this -exec rendering, each opcode is executed in the order shown.
1104 The add opcode, marked with '*', is discussed in more detail.
1105
1106 The 1st column is the op's sequence number, starting at 1, and is
1107 displayed in base 36 by default.  Here they're purely linear; the
1108 sequences are very helpful when looking at code with loops and
1109 branches.
1110
1111 The symbol between angle brackets indicates the op's type, for
1112 example; <2> is a BINOP, <@> a LISTOP, and <#> is a PADOP, which is
1113 used in threaded perls. (see L</"OP class abbreviations">).
1114
1115 The opname, as in B<'add[t1]'>, may be followed by op-specific
1116 information in parentheses or brackets (ex B<'[t1]'>).
1117
1118 The op-flags (ex B<'sK/2'>) are described in (L</"OP flags
1119 abbreviations">).
1120
1121     % perl -MO=Concise -e '$a = $b + 42'
1122     8  <@> leave[1 ref] vKP/REFC ->(end)
1123     1     <0> enter ->2
1124     2     <;> nextstate(main 1 -e:1) v ->3
1125     7     <2> sassign vKS/2 ->8
1126  *  5        <2> add[t1] sK/2 ->6
1127     -           <1> ex-rv2sv sK/1 ->4
1128     3              <$> gvsv(*b) s ->4
1129     4           <$> const(IV 42) s ->5
1130     -        <1> ex-rv2sv sKRM*/1 ->7
1131     6           <$> gvsv(*a) s ->7
1132
1133 The default rendering is top-down, so they're not in execution order.
1134 This form reflects the way the stack is used to parse and evaluate
1135 expressions; the add operates on the two terms below it in the tree.
1136
1137 Nullops appear as C<ex-opname>, where I<opname> is an op that has been
1138 optimized away by perl.  They're displayed with a sequence-number of
1139 '-', because they are not executed (they don't appear in previous
1140 example), they're printed here because they reflect the parse.
1141
1142 The arrow points to the sequence number of the next op; they're not
1143 displayed in -exec mode, for obvious reasons.
1144
1145 Note that because this rendering was done on a non-threaded perl, the
1146 PADOPs in the previous examples are now SVOPs, and some (but not all)
1147 of the square brackets have been replaced by round ones.  This is a
1148 subtle feature to provide some visual distinction between renderings
1149 on threaded and un-threaded perls.
1150
1151
1152 =head1 OPTIONS
1153
1154 Arguments that don't start with a hyphen are taken to be the names of
1155 subroutines or formats to render; if no
1156 such functions are specified, the main
1157 body of the program (outside any subroutines, and not including use'd
1158 or require'd files) is rendered.  Passing C<BEGIN>, C<UNITCHECK>,
1159 C<CHECK>, C<INIT>, or C<END> will cause all of the corresponding
1160 special blocks to be printed.  Arguments must follow options.
1161
1162 Options affect how things are rendered (ie printed).  They're presented
1163 here by their visual effect, 1st being strongest.  They're grouped
1164 according to how they interrelate; within each group the options are
1165 mutually exclusive (unless otherwise stated).
1166
1167 =head2 Options for Opcode Ordering
1168
1169 These options control the 'vertical display' of opcodes.  The display
1170 'order' is also called 'mode' elsewhere in this document.
1171
1172 =over 4
1173
1174 =item B<-basic>
1175
1176 Print OPs in the order they appear in the OP tree (a preorder
1177 traversal, starting at the root). The indentation of each OP shows its
1178 level in the tree, and the '->' at the end of the line indicates the
1179 next opcode in execution order.  This mode is the default, so the flag
1180 is included simply for completeness.
1181
1182 =item B<-exec>
1183
1184 Print OPs in the order they would normally execute (for the majority
1185 of constructs this is a postorder traversal of the tree, ending at the
1186 root). In most cases the OP that usually follows a given OP will
1187 appear directly below it; alternate paths are shown by indentation. In
1188 cases like loops when control jumps out of a linear path, a 'goto'
1189 line is generated.
1190
1191 =item B<-tree>
1192
1193 Print OPs in a text approximation of a tree, with the root of the tree
1194 at the left and 'left-to-right' order of children transformed into
1195 'top-to-bottom'. Because this mode grows both to the right and down,
1196 it isn't suitable for large programs (unless you have a very wide
1197 terminal).
1198
1199 =back
1200
1201 =head2 Options for Line-Style
1202
1203 These options select the line-style (or just style) used to render
1204 each opcode, and dictates what info is actually printed into each line.
1205
1206 =over 4
1207
1208 =item B<-concise>
1209
1210 Use the author's favorite set of formatting conventions. This is the
1211 default, of course.
1212
1213 =item B<-terse>
1214
1215 Use formatting conventions that emulate the output of B<B::Terse>. The
1216 basic mode is almost indistinguishable from the real B<B::Terse>, and the
1217 exec mode looks very similar, but is in a more logical order and lacks
1218 curly brackets. B<B::Terse> doesn't have a tree mode, so the tree mode
1219 is only vaguely reminiscent of B<B::Terse>.
1220
1221 =item B<-linenoise>
1222
1223 Use formatting conventions in which the name of each OP, rather than being
1224 written out in full, is represented by a one- or two-character abbreviation.
1225 This is mainly a joke.
1226
1227 =item B<-debug>
1228
1229 Use formatting conventions reminiscent of B<B::Debug>; these aren't
1230 very concise at all.
1231
1232 =item B<-env>
1233
1234 Use formatting conventions read from the environment variables
1235 C<B_CONCISE_FORMAT>, C<B_CONCISE_GOTO_FORMAT>, and C<B_CONCISE_TREE_FORMAT>.
1236
1237 =back
1238
1239 =head2 Options for tree-specific formatting
1240
1241 =over 4
1242
1243 =item B<-compact>
1244
1245 Use a tree format in which the minimum amount of space is used for the
1246 lines connecting nodes (one character in most cases). This squeezes out
1247 a few precious columns of screen real estate.
1248
1249 =item B<-loose>
1250
1251 Use a tree format that uses longer edges to separate OP nodes. This format
1252 tends to look better than the compact one, especially in ASCII, and is
1253 the default.
1254
1255 =item B<-vt>
1256
1257 Use tree connecting characters drawn from the VT100 line-drawing set.
1258 This looks better if your terminal supports it.
1259
1260 =item B<-ascii>
1261
1262 Draw the tree with standard ASCII characters like C<+> and C<|>. These don't
1263 look as clean as the VT100 characters, but they'll work with almost any
1264 terminal (or the horizontal scrolling mode of less(1)) and are suitable
1265 for text documentation or email. This is the default.
1266
1267 =back
1268
1269 These are pairwise exclusive, i.e. compact or loose, vt or ascii.
1270
1271 =head2 Options controlling sequence numbering
1272
1273 =over 4
1274
1275 =item B<-base>I<n>
1276
1277 Print OP sequence numbers in base I<n>. If I<n> is greater than 10, the
1278 digit for 11 will be 'a', and so on. If I<n> is greater than 36, the digit
1279 for 37 will be 'A', and so on until 62. Values greater than 62 are not
1280 currently supported. The default is 36.
1281
1282 =item B<-bigendian>
1283
1284 Print sequence numbers with the most significant digit first. This is the
1285 usual convention for Arabic numerals, and the default.
1286
1287 =item B<-littleendian>
1288
1289 Print sequence numbers with the least significant digit first.  This is
1290 obviously mutually exclusive with bigendian.
1291
1292 =back
1293
1294 =head2 Other options
1295
1296 =over 4
1297
1298 =item B<-src>
1299
1300 With this option, the rendering of each statement (starting with the
1301 nextstate OP) will be preceded by the 1st line of source code that
1302 generates it.  For example:
1303
1304     1  <0> enter
1305     # 1: my $i;
1306     2  <;> nextstate(main 1 junk.pl:1) v:{
1307     3  <0> padsv[$i:1,10] vM/LVINTRO
1308     # 3: for $i (0..9) {
1309     4  <;> nextstate(main 3 junk.pl:3) v:{
1310     5  <0> pushmark s
1311     6  <$> const[IV 0] s
1312     7  <$> const[IV 9] s
1313     8  <{> enteriter(next->j last->m redo->9)[$i:1,10] lKS
1314     k  <0> iter s
1315     l  <|> and(other->9) vK/1
1316     # 4:     print "line ";
1317     9      <;> nextstate(main 2 junk.pl:4) v
1318     a      <0> pushmark s
1319     b      <$> const[PV "line "] s
1320     c      <@> print vK
1321     # 5:     print "$i\n";
1322     ...
1323
1324 =item B<-stash="somepackage">
1325
1326 With this, "somepackage" will be required, then the stash is
1327 inspected, and each function is rendered.
1328
1329 =back
1330
1331 The following options are pairwise exclusive.
1332
1333 =over 4
1334
1335 =item B<-main>
1336
1337 Include the main program in the output, even if subroutines were also
1338 specified.  This rendering is normally suppressed when a subroutine
1339 name or reference is given.
1340
1341 =item B<-nomain>
1342
1343 This restores the default behavior after you've changed it with '-main'
1344 (it's not normally needed).  If no subroutine name/ref is given, main is
1345 rendered, regardless of this flag.
1346
1347 =item B<-nobanner>
1348
1349 Renderings usually include a banner line identifying the function name
1350 or stringified subref.  This suppresses the printing of the banner.
1351
1352 TBC: Remove the stringified coderef; while it provides a 'cookie' for
1353 each function rendered, the cookies used should be 1,2,3.. not a
1354 random hex-address.  It also complicates string comparison of two
1355 different trees.
1356
1357 =item B<-banner>
1358
1359 restores default banner behavior.
1360
1361 =item B<-banneris> => subref
1362
1363 TBC: a hookpoint (and an option to set it) for a user-supplied
1364 function to produce a banner appropriate for users needs.  It's not
1365 ideal, because the rendering-state variables, which are a natural
1366 candidate for use in concise.t, are unavailable to the user.
1367
1368 =back
1369
1370 =head2 Option Stickiness
1371
1372 If you invoke Concise more than once in a program, you should know that
1373 the options are 'sticky'.  This means that the options you provide in
1374 the first call will be remembered for the 2nd call, unless you
1375 re-specify or change them.
1376
1377 =head1 ABBREVIATIONS
1378
1379 The concise style uses symbols to convey maximum info with minimal
1380 clutter (like hex addresses).  With just a little practice, you can
1381 start to see the flowers, not just the branches, in the trees.
1382
1383 =head2 OP class abbreviations
1384
1385 These symbols appear before the op-name, and indicate the
1386 B:: namespace that represents the ops in your Perl code.
1387
1388     0      OP (aka BASEOP)  An OP with no children
1389     1      UNOP             An OP with one child
1390     +      UNOP_AUX         A UNOP with auxillary fields
1391     2      BINOP            An OP with two children
1392     |      LOGOP            A control branch OP
1393     @      LISTOP           An OP that could have lots of children
1394     /      PMOP             An OP with a regular expression
1395     $      SVOP             An OP with an SV
1396     "      PVOP             An OP with a string
1397     {      LOOP             An OP that holds pointers for a loop
1398     ;      COP              An OP that marks the start of a statement
1399     #      PADOP            An OP with a GV on the pad
1400     .      METHOP           An OP with method call info
1401
1402 =head2 OP flags abbreviations
1403
1404 OP flags are either public or private.  The public flags alter the
1405 behavior of each opcode in consistent ways, and are represented by 0
1406 or more single characters.
1407
1408     v      OPf_WANT_VOID    Want nothing (void context)
1409     s      OPf_WANT_SCALAR  Want single value (scalar context)
1410     l      OPf_WANT_LIST    Want list of any length (list context)
1411                             Want is unknown
1412     K      OPf_KIDS         There is a firstborn child.
1413     P      OPf_PARENS       This operator was parenthesized.
1414                              (Or block needs explicit scope entry.)
1415     R      OPf_REF          Certified reference.
1416                              (Return container, not containee).
1417     M      OPf_MOD          Will modify (lvalue).
1418     S      OPf_STACKED      Some arg is arriving on the stack.
1419     *      OPf_SPECIAL      Do something weird for this op (see op.h)
1420
1421 Private flags, if any are set for an opcode, are displayed after a '/'
1422
1423     8  <@> leave[1 ref] vKP/REFC ->(end)
1424     7     <2> sassign vKS/2 ->8
1425
1426 They're opcode specific, and occur less often than the public ones, so
1427 they're represented by short mnemonics instead of single-chars; see
1428 B::Op_private and F<regen/op_private> for more details.
1429
1430 =head1 FORMATTING SPECIFICATIONS
1431
1432 For each line-style ('concise', 'terse', 'linenoise', etc.) there are
1433 3 format-specs which control how OPs are rendered.
1434
1435 The first is the 'default' format, which is used in both basic and exec
1436 modes to print all opcodes.  The 2nd, goto-format, is used in exec
1437 mode when branches are encountered.  They're not real opcodes, and are
1438 inserted to look like a closing curly brace.  The tree-format is tree
1439 specific.
1440
1441 When a line is rendered, the correct format-spec is copied and scanned
1442 for the following items; data is substituted in, and other
1443 manipulations like basic indenting are done, for each opcode rendered.
1444
1445 There are 3 kinds of items that may be populated; special patterns,
1446 #vars, and literal text, which is copied verbatim.  (Yes, it's a set
1447 of s///g steps.)
1448
1449 =head2 Special Patterns
1450
1451 These items are the primitives used to perform indenting, and to
1452 select text from amongst alternatives.
1453
1454 =over 4
1455
1456 =item B<(x(>I<exec_text>B<;>I<basic_text>B<)x)>
1457
1458 Generates I<exec_text> in exec mode, or I<basic_text> in basic mode.
1459
1460 =item B<(*(>I<text>B<)*)>
1461
1462 Generates one copy of I<text> for each indentation level.
1463
1464 =item B<(*(>I<text1>B<;>I<text2>B<)*)>
1465
1466 Generates one fewer copies of I<text1> than the indentation level, followed
1467 by one copy of I<text2> if the indentation level is more than 0.
1468
1469 =item B<(?(>I<text1>B<#>I<var>I<Text2>B<)?)>
1470
1471 If the value of I<var> is true (not empty or zero), generates the
1472 value of I<var> surrounded by I<text1> and I<Text2>, otherwise
1473 nothing.
1474
1475 =item B<~>
1476
1477 Any number of tildes and surrounding whitespace will be collapsed to
1478 a single space.
1479
1480 =back
1481
1482 =head2 # Variables
1483
1484 These #vars represent opcode properties that you may want as part of
1485 your rendering.  The '#' is intended as a private sigil; a #var's
1486 value is interpolated into the style-line, much like "read $this".
1487
1488 These vars take 3 forms:
1489
1490 =over 4
1491
1492 =item B<#>I<var>
1493
1494 A property named 'var' is assumed to exist for the opcodes, and is
1495 interpolated into the rendering.
1496
1497 =item B<#>I<var>I<N>
1498
1499 Generates the value of I<var>, left justified to fill I<N> spaces.
1500 Note that this means while you can have properties 'foo' and 'foo2',
1501 you cannot render 'foo2', but you could with 'foo2a'.  You would be
1502 wise not to rely on this behavior going forward ;-)
1503
1504 =item B<#>I<Var>
1505
1506 This ucfirst form of #var generates a tag-value form of itself for
1507 display; it converts '#Var' into a 'Var => #var' style, which is then
1508 handled as described above.  (Imp-note: #Vars cannot be used for
1509 conditional-fills, because the => #var transform is done after the check
1510 for #Var's value).
1511
1512 =back
1513
1514 The following variables are 'defined' by B::Concise; when they are
1515 used in a style, their respective values are plugged into the
1516 rendering of each opcode.
1517
1518 Only some of these are used by the standard styles, the others are
1519 provided for you to delve into optree mechanics, should you wish to
1520 add a new style (see L</add_style> below) that uses them.  You can
1521 also add new ones using L</add_callback>.
1522
1523 =over 4
1524
1525 =item B<#addr>
1526
1527 The address of the OP, in hexadecimal.
1528
1529 =item B<#arg>
1530
1531 The OP-specific information of the OP (such as the SV for an SVOP, the
1532 non-local exit pointers for a LOOP, etc.) enclosed in parentheses.
1533
1534 =item B<#class>
1535
1536 The B-determined class of the OP, in all caps.
1537
1538 =item B<#classsym>
1539
1540 A single symbol abbreviating the class of the OP.
1541
1542 =item B<#coplabel>
1543
1544 The label of the statement or block the OP is the start of, if any.
1545
1546 =item B<#exname>
1547
1548 The name of the OP, or 'ex-foo' if the OP is a null that used to be a foo.
1549
1550 =item B<#extarg>
1551
1552 The target of the OP, or nothing for a nulled OP.
1553
1554 =item B<#firstaddr>
1555
1556 The address of the OP's first child, in hexadecimal.
1557
1558 =item B<#flags>
1559
1560 The OP's flags, abbreviated as a series of symbols.
1561
1562 =item B<#flagval>
1563
1564 The numeric value of the OP's flags.
1565
1566 =item B<#hints>
1567
1568 The COP's hint flags, rendered with abbreviated names if possible. An empty
1569 string if this is not a COP. Here are the symbols used:
1570
1571     $ strict refs
1572     & strict subs
1573     * strict vars
1574    x$ explicit use/no strict refs
1575    x& explicit use/no strict subs
1576    x* explicit use/no strict vars
1577     i integers
1578     l locale
1579     b bytes
1580     { block scope
1581     % localise %^H
1582     < open in
1583     > open out
1584     I overload int
1585     F overload float
1586     B overload binary
1587     S overload string
1588     R overload re
1589     T taint
1590     E eval
1591     X filetest access
1592     U utf-8
1593
1594 =item B<#hintsval>
1595
1596 The numeric value of the COP's hint flags, or an empty string if this is not
1597 a COP.
1598
1599 =item B<#hyphseq>
1600
1601 The sequence number of the OP, or a hyphen if it doesn't have one.
1602
1603 =item B<#label>
1604
1605 'NEXT', 'LAST', or 'REDO' if the OP is a target of one of those in exec
1606 mode, or empty otherwise.
1607
1608 =item B<#lastaddr>
1609
1610 The address of the OP's last child, in hexadecimal.
1611
1612 =item B<#name>
1613
1614 The OP's name.
1615
1616 =item B<#NAME>
1617
1618 The OP's name, in all caps.
1619
1620 =item B<#next>
1621
1622 The sequence number of the OP's next OP.
1623
1624 =item B<#nextaddr>
1625
1626 The address of the OP's next OP, in hexadecimal.
1627
1628 =item B<#noise>
1629
1630 A one- or two-character abbreviation for the OP's name.
1631
1632 =item B<#private>
1633
1634 The OP's private flags, rendered with abbreviated names if possible.
1635
1636 =item B<#privval>
1637
1638 The numeric value of the OP's private flags.
1639
1640 =item B<#seq>
1641
1642 The sequence number of the OP. Note that this is a sequence number
1643 generated by B::Concise.
1644
1645 =item B<#seqnum>
1646
1647 5.8.x and earlier only. 5.9 and later do not provide this.
1648
1649 The real sequence number of the OP, as a regular number and not adjusted
1650 to be relative to the start of the real program. (This will generally be
1651 a fairly large number because all of B<B::Concise> is compiled before
1652 your program is).
1653
1654 =item B<#opt>
1655
1656 Whether or not the op has been optimized by the peephole optimizer.
1657
1658 Only available in 5.9 and later.
1659
1660 =item B<#sibaddr>
1661
1662 The address of the OP's next youngest sibling, in hexadecimal.
1663
1664 =item B<#svaddr>
1665
1666 The address of the OP's SV, if it has an SV, in hexadecimal.
1667
1668 =item B<#svclass>
1669
1670 The class of the OP's SV, if it has one, in all caps (e.g., 'IV').
1671
1672 =item B<#svval>
1673
1674 The value of the OP's SV, if it has one, in a short human-readable format.
1675
1676 =item B<#targ>
1677
1678 The numeric value of the OP's targ.
1679
1680 =item B<#targarg>
1681
1682 The name of the variable the OP's targ refers to, if any, otherwise the
1683 letter t followed by the OP's targ in decimal.
1684
1685 =item B<#targarglife>
1686
1687 Same as B<#targarg>, but followed by the COP sequence numbers that delimit
1688 the variable's lifetime (or 'end' for a variable in an open scope) for a
1689 variable.
1690
1691 =item B<#typenum>
1692
1693 The numeric value of the OP's type, in decimal.
1694
1695 =back
1696
1697 =head1 One-Liner Command tips
1698
1699 =over 4
1700
1701 =item perl -MO=Concise,bar foo.pl
1702
1703 Renders only bar() from foo.pl.  To see main, drop the ',bar'.  To see
1704 both, add ',-main'
1705
1706 =item perl -MDigest::MD5=md5 -MO=Concise,md5 -e1
1707
1708 Identifies md5 as an XS function.  The export is needed so that BC can
1709 find it in main.
1710
1711 =item perl -MPOSIX -MO=Concise,_POSIX_ARG_MAX -e1
1712
1713 Identifies _POSIX_ARG_MAX as a constant sub, optimized to an IV.
1714 Although POSIX isn't entirely consistent across platforms, this is
1715 likely to be present in virtually all of them.
1716
1717 =item perl -MPOSIX -MO=Concise,a -e 'print _POSIX_SAVED_IDS'
1718
1719 This renders a print statement, which includes a call to the function.
1720 It's identical to rendering a file with a use call and that single
1721 statement, except for the filename which appears in the nextstate ops.
1722
1723 =item perl -MPOSIX -MO=Concise,a -e 'sub a{_POSIX_SAVED_IDS}'
1724
1725 This is B<very> similar to previous, only the first two ops differ.  This
1726 subroutine rendering is more representative, insofar as a single main
1727 program will have many subs.
1728
1729 =item perl -MB::Concise -e 'B::Concise::compile("-exec","-src", \%B::Concise::)->()'
1730
1731 This renders all functions in the B::Concise package with the source
1732 lines.  It eschews the O framework so that the stashref can be passed
1733 directly to B::Concise::compile().  See -stash option for a more
1734 convenient way to render a package.
1735
1736 =back
1737
1738 =head1 Using B::Concise outside of the O framework
1739
1740 The common (and original) usage of B::Concise was for command-line
1741 renderings of simple code, as given in EXAMPLE.  But you can also use
1742 B<B::Concise> from your code, and call compile() directly, and
1743 repeatedly.  By doing so, you can avoid the compile-time only
1744 operation of O.pm, and even use the debugger to step through
1745 B::Concise::compile() itself.
1746
1747 Once you're doing this, you may alter Concise output by adding new
1748 rendering styles, and by optionally adding callback routines which
1749 populate new variables, if such were referenced from those (just
1750 added) styles.
1751
1752 =head2 Example: Altering Concise Renderings
1753
1754     use B::Concise qw(set_style add_callback);
1755     add_style($yourStyleName => $defaultfmt, $gotofmt, $treefmt);
1756     add_callback
1757       ( sub {
1758             my ($h, $op, $format, $level, $stylename) = @_;
1759             $h->{variable} = some_func($op);
1760         });
1761     $walker = B::Concise::compile(@options,@subnames,@subrefs);
1762     $walker->();
1763
1764 =head2 set_style()
1765
1766 B<set_style> accepts 3 arguments, and updates the three format-specs
1767 comprising a line-style (basic-exec, goto, tree).  It has one minor
1768 drawback though; it doesn't register the style under a new name.  This
1769 can become an issue if you render more than once and switch styles.
1770 Thus you may prefer to use add_style() and/or set_style_standard()
1771 instead.
1772
1773 =head2 set_style_standard($name)
1774
1775 This restores one of the standard line-styles: C<terse>, C<concise>,
1776 C<linenoise>, C<debug>, C<env>, into effect.  It also accepts style
1777 names previously defined with add_style().
1778
1779 =head2 add_style ()
1780
1781 This subroutine accepts a new style name and three style arguments as
1782 above, and creates, registers, and selects the newly named style.  It is
1783 an error to re-add a style; call set_style_standard() to switch between
1784 several styles.
1785
1786 =head2 add_callback ()
1787
1788 If your newly minted styles refer to any new #variables, you'll need
1789 to define a callback subroutine that will populate (or modify) those
1790 variables.  They are then available for use in the style you've
1791 chosen.
1792
1793 The callbacks are called for each opcode visited by Concise, in the
1794 same order as they are added.  Each subroutine is passed five
1795 parameters.
1796
1797   1. A hashref, containing the variable names and values which are
1798      populated into the report-line for the op
1799   2. the op, as a B<B::OP> object
1800   3. a reference to the format string
1801   4. the formatting (indent) level
1802   5. the selected stylename
1803
1804 To define your own variables, simply add them to the hash, or change
1805 existing values if you need to.  The level and format are passed in as
1806 references to scalars, but it is unlikely that they will need to be
1807 changed or even used.
1808
1809 =head2 Running B::Concise::compile()
1810
1811 B<compile> accepts options as described above in L</OPTIONS>, and
1812 arguments, which are either coderefs, or subroutine names.
1813
1814 It constructs and returns a $treewalker coderef, which when invoked,
1815 traverses, or walks, and renders the optrees of the given arguments to
1816 STDOUT.  You can reuse this, and can change the rendering style used
1817 each time; thereafter the coderef renders in the new style.
1818
1819 B<walk_output> lets you change the print destination from STDOUT to
1820 another open filehandle, or into a string passed as a ref (unless
1821 you've built perl with -Uuseperlio).
1822
1823   my $walker = B::Concise::compile('-terse','aFuncName', \&aSubRef); # 1
1824   walk_output(\my $buf);
1825   $walker->();                          # 1 renders -terse
1826   set_style_standard('concise');        # 2
1827   $walker->();                          # 2 renders -concise
1828   $walker->(@new);                      # 3 renders whatever
1829   print "3 different renderings: terse, concise, and @new: $buf\n";
1830
1831 When $walker is called, it traverses the subroutines supplied when it
1832 was created, and renders them using the current style.  You can change
1833 the style afterwards in several different ways:
1834
1835   1. call C<compile>, altering style or mode/order
1836   2. call C<set_style_standard>
1837   3. call $walker, passing @new options
1838
1839 Passing new options to the $walker is the easiest way to change
1840 amongst any pre-defined styles (the ones you add are automatically
1841 recognized as options), and is the only way to alter rendering order
1842 without calling compile again.  Note however that rendering state is
1843 still shared amongst multiple $walker objects, so they must still be
1844 used in a coordinated manner.
1845
1846 =head2 B::Concise::reset_sequence()
1847
1848 This function (not exported) lets you reset the sequence numbers (note
1849 that they're numbered arbitrarily, their goal being to be human
1850 readable).  Its purpose is mostly to support testing, i.e. to compare
1851 the concise output from two identical anonymous subroutines (but
1852 different instances).  Without the reset, B::Concise, seeing that
1853 they're separate optrees, generates different sequence numbers in
1854 the output.
1855
1856 =head2 Errors
1857
1858 Errors in rendering (non-existent function-name, non-existent coderef)
1859 are written to the STDOUT, or wherever you've set it via
1860 walk_output().
1861
1862 Errors using the various *style* calls, and bad args to walk_output(),
1863 result in die().  Use an eval if you wish to catch these errors and
1864 continue processing.
1865
1866 =head1 AUTHOR
1867
1868 Stephen McCamant, E<lt>smcc@CSUA.Berkeley.EDUE<gt>.
1869
1870 =cut