This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Upgrade File::Path to 2.08 (and add taint.t test)
[perl5.git] / cpan / File-Path / t / Path.t
1 # Path.t -- tests for module File::Path
2
3 use strict;
4
5 use Test::More tests => 129;
6 use Config;
7
8 BEGIN {
9     use_ok('Cwd');
10     use_ok('File::Path', qw(rmtree mkpath make_path remove_tree));
11     use_ok('File::Spec::Functions');
12 }
13
14 eval "use Test::Output";
15 my $has_Test_Output = $@ ? 0 : 1;
16
17 my $Is_VMS = $^O eq 'VMS';
18
19 # first check for stupid permissions second for full, so we clean up
20 # behind ourselves
21 for my $perm (0111,0777) {
22     my $path = catdir(curdir(), "mhx", "bar");
23     mkpath($path);
24     chmod $perm, "mhx", $path;
25
26     my $oct = sprintf('0%o', $perm);
27     ok(-d "mhx", "mkdir parent dir $oct");
28     ok(-d $path, "mkdir child dir $oct");
29
30     rmtree("mhx");
31     ok(! -e "mhx", "mhx does not exist $oct");
32 }
33
34 # find a place to work
35 my ($error, $list, $file, $message);
36 my $tmp_base = catdir(
37     curdir(),
38     sprintf( 'test-%x-%x-%x', time, $$, rand(99999) ),
39 );
40
41 # invent some names
42 my @dir = (
43     catdir($tmp_base, qw(a b)),
44     catdir($tmp_base, qw(a c)),
45     catdir($tmp_base, qw(z b)),
46     catdir($tmp_base, qw(z c)),
47 );
48
49 # create them
50 my @created = mkpath([@dir]);
51
52 is(scalar(@created), 7, "created list of directories");
53
54 # pray for no race conditions blowing them out from under us
55 @created = mkpath([$tmp_base]);
56 is(scalar(@created), 0, "skipped making existing directory")
57     or diag("unexpectedly recreated @created");
58
59 # create a file
60 my $file_name = catfile( $tmp_base, 'a', 'delete.me' );
61 my $file_count = 0;
62 if (open OUT, "> $file_name") {
63     print OUT "this file may be deleted\n";
64     close OUT;
65     ++$file_count;
66 }
67 else {
68     diag( "Failed to create file $file_name: $!" );
69 }
70
71 SKIP: {
72     skip "cannot remove a file we failed to create", 1
73         unless $file_count == 1;
74     my $count = rmtree($file_name);
75     is($count, 1, "rmtree'ed a file");
76 }
77
78 @created = mkpath('');
79 is(scalar(@created), 0, "Can't create a directory named ''");
80
81 my $dir;
82 my $dir2;
83
84 sub gisle {
85     # background info: @_ = 1; !shift # gives '' not 0
86     # Message-Id: <3C820CE6-4400-4E91-AF43-A3D19B356E68@activestate.com>
87     # http://www.nntp.perl.org/group/perl.perl5.porters/2008/05/msg136625.html
88     mkpath(shift, !shift, 0755);
89 }
90
91 sub count {
92     opendir D, shift or return -1;
93     my $count = () = readdir D;
94     closedir D or return -1;
95     return $count;
96 }
97
98 {
99     mkdir 'solo', 0755;
100     chdir 'solo';
101     open my $f, '>', 'foo.dat';
102     close $f;
103     my $before = count(curdir());
104     cmp_ok($before, '>', 0, "baseline $before");
105
106     gisle('1st', 1);
107     is(count(curdir()), $before + 1, "first after $before");
108
109     $before = count(curdir());
110     gisle('2nd', 1);
111     is(count(curdir()), $before + 1, "second after $before");
112
113     chdir updir();
114     rmtree 'solo';
115 }
116
117 {
118     mkdir 'solo', 0755;
119     chdir 'solo';
120     open my $f, '>', 'foo.dat';
121     close $f;
122     my $before = count(curdir());
123     cmp_ok($before, '>', 0, "ARGV $before");
124     {
125         local @ARGV = (1);
126         mkpath('3rd', !shift, 0755);
127     }
128     is(count(curdir()), $before + 1, "third after $before");
129
130     $before = count(curdir());
131     {
132         local @ARGV = (1);
133         mkpath('4th', !shift, 0755);
134     }
135     is(count(curdir()), $before + 1, "fourth after $before");
136
137     chdir updir();
138     rmtree 'solo';
139 }
140
141 SKIP: {
142     # tests for rmtree() of ancestor directory
143     my $nr_tests = 6;
144     my $cwd = getcwd() or skip "failed to getcwd: $!", $nr_tests;
145     my $dir  = catdir($cwd, 'remove');
146     my $dir2 = catdir($cwd, 'remove', 'this', 'dir');
147
148     skip "failed to mkpath '$dir2': $!", $nr_tests
149         unless mkpath($dir2, {verbose => 0});
150     skip "failed to chdir dir '$dir2': $!", $nr_tests
151         unless chdir($dir2);
152
153     rmtree($dir, {error => \$error});
154     my $nr_err = @$error;
155     is($nr_err, 1, "ancestor error");
156
157     if ($nr_err) {
158         my ($file, $message) = each %{$error->[0]};
159         is($file, $dir, "ancestor named");
160         my $ortho_dir = $^O eq 'MSWin32' ? File::Path::_slash_lc($dir2) : $dir2;
161         $^O eq 'MSWin32' and $message
162             =~ s/\A(cannot remove path when cwd is )(.*)\Z/$1 . File::Path::_slash_lc($2)/e;
163         is($message, "cannot remove path when cwd is $ortho_dir", "ancestor reason");
164         ok(-d $dir2, "child not removed");
165         ok(-d $dir, "ancestor not removed");
166     }
167     else {
168         fail( "ancestor 1");
169         fail( "ancestor 2");
170         fail( "ancestor 3");
171         fail( "ancestor 4");
172     }
173     chdir $cwd;
174     rmtree($dir);
175     ok(!(-d $dir), "ancestor now removed");
176 };
177
178 my $count = rmtree({error => \$error});
179 is( $count, 0, 'rmtree of nothing, count of zero' );
180 is( scalar(@$error), 0, 'no diagnostic captured' );
181
182 @created = mkpath($tmp_base, 0);
183 is(scalar(@created), 0, "skipped making existing directories (old style 1)")
184     or diag("unexpectedly recreated @created");
185
186 $dir = catdir($tmp_base,'C');
187 # mkpath returns unix syntax filespecs on VMS
188 $dir = VMS::Filespec::unixify($dir) if $Is_VMS;
189 @created = make_path($tmp_base, $dir);
190 is(scalar(@created), 1, "created directory (new style 1)");
191 is($created[0], $dir, "created directory (new style 1) cross-check");
192
193 @created = mkpath($tmp_base, 0, 0700);
194 is(scalar(@created), 0, "skipped making existing directories (old style 2)")
195     or diag("unexpectedly recreated @created");
196
197 $dir2 = catdir($tmp_base,'D');
198 # mkpath returns unix syntax filespecs on VMS
199 $dir2 = VMS::Filespec::unixify($dir2) if $Is_VMS;
200 @created = make_path($tmp_base, $dir, $dir2);
201 is(scalar(@created), 1, "created directory (new style 2)");
202 is($created[0], $dir2, "created directory (new style 2) cross-check");
203
204 $count = rmtree($dir, 0);
205 is($count, 1, "removed directory unsafe mode");
206
207 $count = rmtree($dir2, 0, 1);
208 my $removed = $Is_VMS ? 0 : 1;
209 is($count, $removed, "removed directory safe mode");
210
211 # mkdir foo ./E/../Y
212 # Y should exist
213 # existence of E is neither here nor there
214 $dir = catdir($tmp_base, 'E', updir(), 'Y');
215 @created =mkpath($dir);
216 cmp_ok(scalar(@created), '>=', 1, "made one or more dirs because of ..");
217 cmp_ok(scalar(@created), '<=', 2, "made less than two dirs because of ..");
218 ok( -d catdir($tmp_base, 'Y'), "directory after parent" );
219
220 @created = make_path(catdir(curdir(), $tmp_base));
221 is(scalar(@created), 0, "nothing created")
222     or diag(@created);
223
224 $dir  = catdir($tmp_base, 'a');
225 $dir2 = catdir($tmp_base, 'z');
226
227 rmtree( $dir, $dir2,
228     {
229         error     => \$error,
230         result    => \$list,
231         keep_root => 1,
232     }
233 );
234
235 is(scalar(@$error), 0, "no errors unlinking a and z");
236 is(scalar(@$list),  4, "list contains 4 elements")
237     or diag("@$list");
238
239 ok(-d $dir,  "dir a still exists");
240 ok(-d $dir2, "dir z still exists");
241
242 $dir = catdir($tmp_base,'F');
243 # mkpath returns unix syntax filespecs on VMS
244 $dir = VMS::Filespec::unixify($dir) if $Is_VMS;
245
246 @created = mkpath($dir, undef, 0770);
247 is(scalar(@created), 1, "created directory (old style 2 verbose undef)");
248 is($created[0], $dir, "created directory (old style 2 verbose undef) cross-check");
249 is(rmtree($dir, undef, 0), 1, "removed directory 2 verbose undef");
250
251 @created = mkpath($dir, undef);
252 is(scalar(@created), 1, "created directory (old style 2a verbose undef)");
253 is($created[0], $dir, "created directory (old style 2a verbose undef) cross-check");
254 is(rmtree($dir, undef), 1, "removed directory 2a verbose undef");
255
256 @created = mkpath($dir, 0, undef);
257 is(scalar(@created), 1, "created directory (old style 3 mode undef)");
258 is($created[0], $dir, "created directory (old style 3 mode undef) cross-check");
259 is(rmtree($dir, 0, undef), 1, "removed directory 3 verbose undef");
260
261 $dir = catdir($tmp_base,'G');
262 $dir = VMS::Filespec::unixify($dir) if $Is_VMS;
263
264 @created = mkpath($dir, undef, 0200);
265 is(scalar(@created), 1, "created write-only dir");
266 is($created[0], $dir, "created write-only directory cross-check");
267 is(rmtree($dir), 1, "removed write-only dir");
268
269 # borderline new-style heuristics
270 if (chdir $tmp_base) {
271     pass("chdir to temp dir");
272 }
273 else {
274     fail("chdir to temp dir: $!");
275 }
276
277 $dir   = catdir('a', 'd1');
278 $dir2  = catdir('a', 'd2');
279
280 @created = make_path( $dir, 0, $dir2 );
281 is(scalar @created, 3, 'new-style 3 dirs created');
282
283 $count = remove_tree( $dir, 0, $dir2, );
284 is($count, 3, 'new-style 3 dirs removed');
285
286 @created = make_path( $dir, $dir2, 1 );
287 is(scalar @created, 3, 'new-style 3 dirs created (redux)');
288
289 $count = remove_tree( $dir, $dir2, 1 );
290 is($count, 3, 'new-style 3 dirs removed (redux)');
291
292 @created = make_path( $dir, $dir2 );
293 is(scalar @created, 2, 'new-style 2 dirs created');
294
295 $count = remove_tree( $dir, $dir2 );
296 is($count, 2, 'new-style 2 dirs removed');
297
298 if (chdir updir()) {
299     pass("chdir parent");
300 }
301 else {
302     fail("chdir parent: $!");
303 }
304
305 SKIP: {
306     skip "This is not a MSWin32 platform", 1
307         unless $^O eq 'MSWin32';
308
309     my $UNC_path_taint = $ENV{PERL_FILE_PATH_UNC_TESTDIR};
310     skip "PERL_FILE_PATH_UNC_TESTDIR environment variable not set", 1
311         unless defined($UNC_path_taint);
312
313     my ($UNC_path) = ($UNC_path_taint =~ m{^([/\\]{2}\w+[/\\]\w+[/\\]\w+)$});
314     
315     skip "PERL_FILE_PATH_UNC_TESTDIR environment variable does not point to a directory", 1
316         unless -d $UNC_path;
317     
318     my $removed = rmtree($UNC_path);
319     cmp_ok($removed, '>', 0, "removed $removed entries from $UNC_path");
320 }
321
322 SKIP: {
323     # test bug http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=487319
324     skip "Don't need Force_Writeable semantics on $^O", 4
325         if grep {$^O eq $_} qw(amigaos dos epoc MSWin32 MacOS os2);
326     skip "Symlinks not available", 4 unless $Config{d_symlink};
327     $dir  = 'bug487319';
328     $dir2 = 'bug487319-symlink';
329     @created = make_path($dir, {mask => 0700});
330     is(scalar @created, 1, 'bug 487319 setup');
331     symlink($dir, $dir2);
332     ok(-e $dir2, "debian bug 487319 setup symlink") or diag($dir2);
333
334     chmod 0500, $dir;
335     my $mask_initial = (stat $dir)[2];
336     remove_tree($dir2);
337
338     my $mask = (stat $dir)[2];
339     is( $mask, $mask_initial, 'mask of symlink target dir unchanged (debian bug 487319)');
340
341     # now try a file
342     my $file = catfile($dir, 'file');
343     open my $out, '>', $file;
344     close $out;
345
346     chmod 0500, $file;
347     $mask_initial = (stat $file)[2];
348
349     my $file2 = catfile($dir, 'symlink');
350     symlink($file, $file2);
351     remove_tree($file2);
352
353     $mask = (stat $file)[2];
354     is( $mask, $mask_initial, 'mask of symlink target file unchanged (debian bug 487319)');
355
356     remove_tree($dir);
357 }
358
359 # see what happens if a file exists where we want a directory
360 SKIP: {
361     my $entry = catdir($tmp_base, "file");
362     skip "Cannot create $entry", 4 unless open OUT, "> $entry";
363     print OUT "test file, safe to delete\n", scalar(localtime), "\n";
364     close OUT;
365     ok(-e $entry, "file exists in place of directory");
366
367     mkpath( $entry, {error => \$error} );
368     is( scalar(@$error), 1, "caught error condition" );
369     ($file, $message) = each %{$error->[0]};
370     is( $entry, $file, "and the message is: $message");
371
372     eval {@created = mkpath($entry, 0, 0700)};
373     $error = $@;
374     chomp $error; # just to remove silly # in TAP output
375     cmp_ok( $error, 'ne', "", "no directory created (old-style) err=$error" )
376         or diag(@created);
377 }
378
379 my $extra =  catdir(curdir(), qw(EXTRA 1 a));
380
381 SKIP: {
382     skip "extra scenarios not set up, see eg/setup-extra-tests", 14
383         unless -e $extra;
384     skip "Symlinks not available", 14 unless $Config{d_symlink};
385
386     my ($list, $err);
387     $dir = catdir( 'EXTRA', '1' );
388     rmtree( $dir, {result => \$list, error => \$err} );
389     is(scalar(@$list), 2, "extra dir $dir removed");
390     is(scalar(@$err), 1, "one error encountered");
391
392     $dir = catdir( 'EXTRA', '3', 'N' );
393     rmtree( $dir, {result => \$list, error => \$err} );
394     is( @$list, 1, q{remove a symlinked dir} );
395     is( @$err,  0, q{with no errors} );
396
397     $dir = catdir('EXTRA', '3', 'S');
398     rmtree($dir, {error => \$error});
399     is( scalar(@$error), 1, 'one error for an unreadable dir' );
400     eval { ($file, $message) = each %{$error->[0]}};
401     is( $file, $dir, 'unreadable dir reported in error' )
402         or diag($message);
403
404     $dir = catdir('EXTRA', '3', 'T');
405     rmtree($dir, {error => \$error});
406     is( scalar(@$error), 1, 'one error for an unreadable dir T' );
407     eval { ($file, $message) = each %{$error->[0]}};
408     is( $file, $dir, 'unreadable dir reported in error T' );
409
410     $dir = catdir( 'EXTRA', '4' );
411     rmtree($dir,  {result => \$list, error => \$err} );
412     is( scalar(@$list), 0, q{don't follow a symlinked dir} );
413     is( scalar(@$err),  2, q{two errors when removing a symlink in r/o dir} );
414     eval { ($file, $message) = each %{$err->[0]} };
415     is( $file, $dir, 'symlink reported in error' );
416
417     $dir  = catdir('EXTRA', '3', 'U');
418     $dir2 = catdir('EXTRA', '3', 'V');
419     rmtree($dir, $dir2, {verbose => 0, error => \$err, result => \$list});
420     is( scalar(@$list),  1, q{deleted 1 out of 2 directories} );
421     is( scalar(@$error), 1, q{left behind 1 out of 2 directories} );
422     eval { ($file, $message) = each %{$err->[0]} };
423     is( $file, $dir, 'first dir reported in error' );
424 }
425
426 {
427     $dir = catdir($tmp_base, 'ZZ');
428     @created = mkpath($dir);
429     is(scalar(@created), 1, "create a ZZ directory");
430
431     local @ARGV = ($dir);
432     rmtree( [grep -e $_, @ARGV], 0, 0 );
433     ok(!-e $dir, "blow it away via \@ARGV");
434 }
435
436 SKIP: {
437     my $skip_count = 8; # DRY
438     skip "getpwent() not implemented on $^O", $skip_count
439         unless $Config{d_getpwent};
440     skip "getgrent() not implemented on $^O", $skip_count
441         unless $Config{d_getgrent};
442     skip 'not running as root', $skip_count
443         unless $< == 0;
444
445     my $dir_stem = $dir = catdir($tmp_base, 'owned-by');
446
447     # find the highest uid ('nobody' or similar)
448     my $max_uid   = 0;
449     my $max_user = undef;
450     while (my @u = getpwent()) {
451         if ($max_uid < $u[2]) {
452             $max_uid  = $u[2];
453             $max_user = $u[0];
454         }
455     }
456     skip 'getpwent() appears to be insane', $skip_count
457         unless $max_uid > 0;
458
459     # find the highest gid ('nogroup' or similar)
460     my $max_gid   = 0;
461     my $max_group = undef;
462     while (my @g = getgrent()) {
463         if ($max_gid < $g[2]) {
464             $max_gid = $g[2];
465             $max_group = $g[0];
466         }
467     }
468     skip 'getgrent() appears to be insane', $skip_count
469         unless $max_gid > 0;
470
471     $dir = catdir($dir_stem, 'aaa');
472     @created = make_path($dir, {owner => $max_user});
473     is(scalar(@created), 2, "created a directory owned by $max_user...");
474     my $dir_uid = (stat $created[0])[4];
475     is($dir_uid, $max_uid, "... owned by $max_uid");
476
477     $dir = catdir($dir_stem, 'aab');
478     @created = make_path($dir, {group => $max_group});
479     is(scalar(@created), 1, "created a directory owned by group $max_group...");
480     my $dir_gid = (stat $created[0])[5];
481     is($dir_gid, $max_gid, "... owned by group $max_gid");
482
483     $dir = catdir($dir_stem, 'aac');
484     @created = make_path($dir, {user => $max_user, group => $max_group});
485     is(scalar(@created), 1, "created a directory owned by $max_user:$max_group...");
486     ($dir_uid, $dir_gid) = (stat $created[0])[4,5];
487     is($dir_uid, $max_uid, "... owned by $max_uid");
488     is($dir_gid, $max_gid, "... owned by group $max_gid");
489
490     SKIP: {
491         skip 'Test::Output not available', 1
492                unless $has_Test_Output;
493
494         # invent a user and group that don't exist
495         do { ++$max_user  } while (getpwnam($max_user));
496         do { ++$max_group } while (getgrnam($max_group));
497
498         $dir = catdir($dir_stem, 'aad');
499         stderr_like(
500             sub {make_path($dir, {user => $max_user, group => $max_group})},
501             qr{\Aunable to map $max_user to a uid, ownership not changed: .* at \S+ line \d+
502 unable to map $max_group to a gid, group ownership not changed: .* at \S+ line \d+\b},
503             "created a directory not owned by $max_user:$max_group..."
504         );
505     }
506 }
507
508 SKIP: {
509     skip 'Test::Output not available', 14
510         unless $has_Test_Output;
511
512     SKIP: {
513         $dir = catdir('EXTRA', '3');
514         skip "extra scenarios not set up, see eg/setup-extra-tests", 3
515             unless -e $dir;
516
517         $dir = catdir('EXTRA', '3', 'U');
518         stderr_like( 
519             sub {rmtree($dir, {verbose => 0})},
520             qr{\Acannot make child directory read-write-exec for [^:]+: .* at \S+ line \d+},
521             q(rmtree can't chdir into root dir)
522         );
523
524         $dir = catdir('EXTRA', '3');
525         stderr_like( 
526             sub {rmtree($dir, {})},
527             qr{\Acannot make child directory read-write-exec for [^:]+: .* at (\S+) line (\d+)
528 cannot make child directory read-write-exec for [^:]+: .* at \1 line \2
529 cannot make child directory read-write-exec for [^:]+: .* at \1 line \2
530 cannot remove directory for [^:]+: .* at \1 line \2},
531             'rmtree with file owned by root'
532         );
533
534         stderr_like( 
535             sub {rmtree('EXTRA', {})},
536             qr{\Acannot remove directory for [^:]+: .* at (\S+) line (\d+)
537 cannot remove directory for [^:]+: .* at \1 line \2
538 cannot make child directory read-write-exec for [^:]+: .* at \1 line \2
539 cannot make child directory read-write-exec for [^:]+: .* at \1 line \2
540 cannot make child directory read-write-exec for [^:]+: .* at \1 line \2
541 cannot remove directory for [^:]+: .* at \1 line \2
542 cannot unlink file for [^:]+: .* at \1 line \2
543 cannot restore permissions to \d+ for [^:]+: .* at \1 line \2
544 cannot make child directory read-write-exec for [^:]+: .* at \1 line \2
545 cannot remove directory for [^:]+: .* at \1 line \2},
546             'rmtree with insufficient privileges'
547         );
548     }
549
550     my $base = catdir($tmp_base,'output');
551     $dir  = catdir($base,'A');
552     $dir2 = catdir($base,'B');
553
554     stderr_like(
555         sub { rmtree( undef, 1 ) },
556         qr/\ANo root path\(s\) specified\b/,
557         "rmtree of nothing carps sensibly"
558     );
559
560     stderr_like(
561         sub { rmtree( '', 1 ) },
562         qr/\ANo root path\(s\) specified\b/,
563         "rmtree of empty dir carps sensibly"
564     );
565
566     stderr_is( sub { make_path() }, '', "make_path no args does not carp" );
567     stderr_is( sub { remove_tree() }, '', "remove_tree no args does not carp" );
568
569     stdout_is(
570         sub {@created = mkpath($dir, 1)},
571         "mkdir $base\nmkdir $dir\n",
572         'mkpath verbose (old style 1)'
573     );
574
575     stdout_is(
576         sub {@created = mkpath([$dir2], 1)},
577         "mkdir $dir2\n",
578         'mkpath verbose (old style 2)'
579     );
580
581     stdout_is(
582         sub {$count = rmtree([$dir, $dir2], 1, 1)},
583         "rmdir $dir\nrmdir $dir2\n",
584         'rmtree verbose (old style)'
585     );
586
587     stdout_is(
588         sub {@created = mkpath($dir, {verbose => 1, mask => 0750})},
589         "mkdir $dir\n",
590         'mkpath verbose (new style 1)'
591     );
592
593     stdout_is(
594         sub {@created = mkpath($dir2, 1, 0771)},
595         "mkdir $dir2\n",
596         'mkpath verbose (new style 2)'
597     );
598
599     SKIP: {
600         $file = catdir($dir2, "file");
601         skip "Cannot create $file", 2 unless open OUT, "> $file";
602         print OUT "test file, safe to delete\n", scalar(localtime), "\n";
603         close OUT;
604
605         ok(-e $file, "file created in directory");
606
607         stdout_is(
608             sub {$count = rmtree($dir, $dir2, {verbose => 1, safe => 1})},
609             "rmdir $dir\nunlink $file\nrmdir $dir2\n",
610             'rmtree safe verbose (new style)'
611         );
612     }
613 }
614
615 SKIP: {
616     skip "extra scenarios not set up, see eg/setup-extra-tests", 11
617         unless -d catdir(qw(EXTRA 1));
618
619     rmtree 'EXTRA', {safe => 0, error => \$error};
620     is( scalar(@$error), 10, 'seven deadly sins' ); # well there used to be 7
621
622     rmtree 'EXTRA', {safe => 1, error => \$error};
623     is( scalar(@$error), 9, 'safe is better' );
624     for (@$error) {
625         ($file, $message) = each %$_;
626         if ($file =~  /[123]\z/) {
627             is(index($message, 'cannot remove directory: '), 0, "failed to remove $file with rmdir")
628                 or diag($message);
629         }
630         else {
631             like($message, qr(\Acannot (?:restore permissions to \d+|chdir to child|unlink file): ), "failed to remove $file with unlink")
632                 or diag($message)
633         }
634     }
635 }
636
637 SKIP: {
638     my $nr_tests = 6;
639     my $cwd = getcwd() or skip "failed to getcwd: $!", $nr_tests;
640     rmtree($tmp_base, {result => \$list} );
641     is(ref($list), 'ARRAY', "received a final list of results");
642     ok( !(-d $tmp_base), "test base directory gone" );
643     
644     my $p = getcwd();
645     my $x = "x$$";
646     my $xx = $x . "x";
647     
648     # setup
649     ok(mkpath($xx), "make $xx");
650     ok(chdir($xx), "... and chdir $xx");
651     END {
652          ok(chdir($p), "... now chdir $p");
653          ok(rmtree($xx), "... and finally rmtree $xx");
654     }
655     
656     # create and delete directory
657     my $px = catdir($p, $x);
658     ok(mkpath($px), 'create and delete directory 2.07');
659     ok(rmtree($px), '.. rmtree fails in File-Path-2.07');
660 }