This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Updates to perlfunc.pod
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar and list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one list argument.)  For instance, splice() has three scalar
19 arguments followed by a list.
20
21 In the syntax descriptions that follow, list operators that expect a
22 list (and provide list context for the elements of the list) are shown
23 with LIST as an argument.  Such a list may consist of any combination
24 of scalar arguments or list values; the list values will be included
25 in the list as if each individual element were interpolated at that
26 point in the list, forming a longer single-dimensional list value.
27 Elements of the LIST should be separated by commas.
28
29 Any function in the list below may be used either with or without
30 parentheses around its arguments.  (The syntax descriptions omit the
31 parentheses.)  If you use the parentheses, the simple (but occasionally
32 surprising) rule is this: It I<LOOKS> like a function, therefore it I<IS> a
33 function, and precedence doesn't matter.  Otherwise it's a list
34 operator or unary operator, and precedence does matter.  And whitespace
35 between the function and left parenthesis doesn't count--so you need to
36 be careful sometimes:
37
38     print 1+2+3;        # Prints 6.
39     print(1+2) + 3;     # Prints 3.
40     print (1+2)+3;      # Also prints 3!
41     print +(1+2)+3;     # Prints 6.
42     print ((1+2)+3);    # Prints 6.
43
44 If you run Perl with the B<-w> switch it can warn you about this.  For
45 example, the third line above produces:
46
47     print (...) interpreted as function at - line 1.
48     Useless use of integer addition in void context at - line 1.
49
50 For functions that can be used in either a scalar or list context,
51 non-abortive failure is generally indicated in a scalar context by
52 returning the undefined value, and in a list context by returning the
53 null list.
54
55 Remember the following rule:
56
57 =over 8
58
59 =item  I<THERE IS NO GENERAL RULE FOR CONVERTING A LIST INTO A SCALAR!>
60
61 =back
62
63 Each operator and function decides which sort of value it would be most
64 appropriate to return in a scalar context.  Some operators return the
65 length of the list that would have been returned in a list context.  Some
66 operators return the first value in the list.  Some operators return the
67 last value in the list.  Some operators return a count of successful
68 operations.  In general, they do what you want, unless you want
69 consistency.
70
71 =head2 Perl Functions by Category
72
73 Here are Perl's functions (including things that look like
74 functions, like some of the keywords and named operators)
75 arranged by category.  Some functions appear in more
76 than one place.
77
78 =over
79
80 =item Functions for SCALARs or strings
81
82 chomp, chop, chr, crypt, hex, index, lc, lcfirst, length,
83 oct, ord, pack, q/STRING/, qq/STRING/, reverse, rindex,
84 sprintf, substr, tr///, uc, ucfirst, y///
85
86 =item Regular expressions and pattern matching
87
88 m//, pos, quotemeta, s///, split, study
89
90 =item Numeric functions
91
92 abs, atan2, cos, exp, hex, int, log, oct, rand, sin, sqrt,
93 srand
94
95 =item Functions for real @ARRAYs
96
97 pop, push, shift, splice, unshift
98
99 =item Functions for list data
100
101 grep, join, map, qw/STRING/, reverse, sort, unpack
102
103 =item Functions for real %HASHes
104
105 delete, each, exists, keys, values
106
107 =item Input and output functions
108
109 binmode, close, closedir, dbmclose, dbmopen, die, eof,
110 fileno, flock, format, getc, print, printf, read, readdir,
111 rewinddir, seek, seekdir, select, syscall, sysread,
112 syswrite, tell, telldir, truncate, warn, write
113
114 =item Functions for fixed length data or records
115
116 pack, read, syscall, sysread, syswrite, unpack, vec
117
118 =item Functions for filehandles, files, or directories
119
120 I<-X>, chdir, chmod, chown, chroot, fcntl, glob, ioctl, link,
121 lstat, mkdir, open, opendir, readlink, rename, rmdir,
122 stat, symlink, umask, unlink, utime
123
124 =item Keywords related to the control flow of your perl program
125
126 caller, continue, die, do, dump, eval, exit, goto, last,
127 next, redo, return, sub, wantarray
128
129 =item Keywords related to scoping 
130
131 caller, import, local, my, package, use
132
133 =item Miscellaneous functions
134
135 defined, dump, eval, formline, local, my, reset, scalar,
136 undef, wantarray
137
138 =item Functions for processes and process groups
139
140 alarm, exec, fork, getpgrp, getppid, getpriority, kill,
141 pipe, qx/STRING/, setpgrp, setpriority, sleep, system,
142 times, wait, waitpid
143
144 =item Keywords related to perl modules
145
146 do, import, no, package, require, use
147
148 =item Keywords related to classes and object-orientedness
149
150 bless, dbmclose, dbmopen, package, ref, tie, tied, untie, use
151
152 =item Low-level socket functions
153
154 accept, bind, connect, getpeername, getsockname,
155 getsockopt, listen, recv, send, setsockopt, shutdown,
156 socket, socketpair
157
158 =item System V interprocess communication functions
159
160 msgctl, msgget, msgrcv, msgsnd, semctl, semget, semop,
161 shmctl, shmget, shmread, shmwrite
162
163 =item Fetching user and group info
164
165 endgrent, endhostent, endnetent, endpwent, getgrent,
166 getgrgid, getgrnam, getlogin, getpwent, getpwnam,
167 getpwuid, setgrent, setpwent
168
169 =item Fetching network info
170
171 endprotoent, endservent, gethostbyaddr, gethostbyname,
172 gethostent, getnetbyaddr, getnetbyname, getnetent,
173 getprotobyname, getprotobynumber, getprotoent,
174 getservbyname, getservbyport, getservent, sethostent,
175 setnetent, setprotoent, setservent
176
177 =item Time-related functions
178
179 gmtime, localtime, time, times
180
181 =item Functions new in perl5
182
183 abs, bless, chomp, chr, exists, formline, glob, import, lc,
184 lcfirst, map, my, no, prototype, qx, qw, readline, readpipe,
185 ref, sub*, sysopen, tie, tied, uc, ucfirst, untie, use
186
187 * - C<sub> was a keyword in perl4, but in perl5 it is an
188 operator which can be used in expressions.
189
190 =item Functions obsoleted in perl5
191
192 dbmclose, dbmopen
193
194 =back
195
196 =head2 Alphabetical Listing of Perl Functions
197
198 =over 8
199
200 =item -X FILEHANDLE
201
202 =item -X EXPR
203
204 =item -X
205
206 A file test, where X is one of the letters listed below.  This unary
207 operator takes one argument, either a filename or a filehandle, and
208 tests the associated file to see if something is true about it.  If the
209 argument is omitted, tests $_, except for C<-t>, which tests STDIN.
210 Unless otherwise documented, it returns C<1> for TRUE and C<''> for FALSE, or
211 the undefined value if the file doesn't exist.  Despite the funny
212 names, precedence is the same as any other named unary operator, and
213 the argument may be parenthesized like any other unary operator.  The
214 operator may be any of:
215
216     -r  File is readable by effective uid/gid.
217     -w  File is writable by effective uid/gid.
218     -x  File is executable by effective uid/gid.
219     -o  File is owned by effective uid.
220
221     -R  File is readable by real uid/gid.
222     -W  File is writable by real uid/gid.
223     -X  File is executable by real uid/gid.
224     -O  File is owned by real uid.
225
226     -e  File exists.
227     -z  File has zero size.
228     -s  File has non-zero size (returns size).
229
230     -f  File is a plain file.
231     -d  File is a directory.
232     -l  File is a symbolic link.
233     -p  File is a named pipe (FIFO).
234     -S  File is a socket.
235     -b  File is a block special file.
236     -c  File is a character special file.
237     -t  Filehandle is opened to a tty.
238
239     -u  File has setuid bit set.
240     -g  File has setgid bit set.
241     -k  File has sticky bit set.
242
243     -T  File is a text file.
244     -B  File is a binary file (opposite of -T).
245
246     -M  Age of file in days when script started.
247     -A  Same for access time.
248     -C  Same for inode change time.
249
250 The interpretation of the file permission operators C<-r>, C<-R>, C<-w>,
251 C<-W>, C<-x>, and C<-X> is based solely on the mode of the file and the
252 uids and gids of the user.  There may be other reasons you can't actually
253 read, write or execute the file.  Also note that, for the superuser,
254 C<-r>, C<-R>, C<-w>, and C<-W> always return 1, and C<-x> and C<-X> return
255 1 if any execute bit is set in the mode.  Scripts run by the superuser may
256 thus need to do a stat() to determine the actual mode of the
257 file, or temporarily set the uid to something else.
258
259 Example:
260
261     while (<>) {
262         chop;
263         next unless -f $_;      # ignore specials
264         ...
265     }
266
267 Note that C<-s/a/b/> does not do a negated substitution.  Saying
268 C<-exp($foo)> still works as expected, however--only single letters
269 following a minus are interpreted as file tests.
270
271 The C<-T> and C<-B> switches work as follows.  The first block or so of the
272 file is examined for odd characters such as strange control codes or
273 characters with the high bit set.  If too many odd characters (E<gt>30%)
274 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
275 containing null in the first block is considered a binary file.  If C<-T>
276 or C<-B> is used on a filehandle, the current stdio buffer is examined
277 rather than the first block.  Both C<-T> and C<-B> return TRUE on a null
278 file, or a file at EOF when testing a filehandle.  Because you have to 
279 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
280 against the file first, as in C<next unless -f $file && -T $file>.
281
282 If any of the file tests (or either the stat() or lstat() operators) are given
283 the special filehandle consisting of a solitary underline, then the stat
284 structure of the previous file test (or stat operator) is used, saving
285 a system call.  (This doesn't work with C<-t>, and you need to remember
286 that lstat() and C<-l> will leave values in the stat structure for the
287 symbolic link, not the real file.)  Example:
288
289     print "Can do.\n" if -r $a || -w _ || -x _;
290
291     stat($filename);
292     print "Readable\n" if -r _;
293     print "Writable\n" if -w _;
294     print "Executable\n" if -x _;
295     print "Setuid\n" if -u _;
296     print "Setgid\n" if -g _;
297     print "Sticky\n" if -k _;
298     print "Text\n" if -T _;
299     print "Binary\n" if -B _;
300
301 =item abs VALUE
302
303 =item abs 
304
305 Returns the absolute value of its argument.
306 If VALUE is omitted, uses $_.
307
308 =item accept NEWSOCKET,GENERICSOCKET
309
310 Accepts an incoming socket connect, just as the accept(2) system call
311 does.  Returns the packed address if it succeeded, FALSE otherwise.
312 See example in L<perlipc/"Sockets: Client/Server Communication">.
313
314 =item alarm SECONDS
315
316 =item alarm 
317
318 Arranges to have a SIGALRM delivered to this process after the
319 specified number of seconds have elapsed.  If SECONDS is not specified,
320 the value stored in $_ is used. (On some machines,
321 unfortunately, the elapsed time may be up to one second less than you
322 specified because of how seconds are counted.)  Only one timer may be
323 counting at once.  Each call disables the previous timer, and an
324 argument of 0 may be supplied to cancel the previous timer without
325 starting a new one.  The returned value is the amount of time remaining
326 on the previous timer.
327
328 For delays of finer granularity than one second, you may use Perl's
329 syscall() interface to access setitimer(2) if your system supports it, 
330 or else see L</select()> below.  It is not advised to intermix alarm() 
331 and sleep() calls.
332
333 If you want to use alarm() to time out a system call you need to use an
334 eval/die pair.  You can't rely on the alarm causing the system call to
335 fail with $! set to EINTR because Perl sets up signal handlers to
336 restart system calls on some systems.  Using eval/die always works.
337
338     eval {
339         local $SIG{ALRM} = sub { die "alarm\n" };       # NB \n required
340         alarm $timeout;
341         $nread = sysread SOCKET, $buffer, $size;
342         alarm 0;
343     };
344     die if $@ && $@ ne "alarm\n";       # propagate errors
345     if ($@) {
346         # timed out
347     }
348     else {
349         # didn't
350     }
351
352 =item atan2 Y,X
353
354 Returns the arctangent of Y/X in the range -PI to PI.
355
356 For the tangent operation, you may use the POSIX::tan()
357 function, or use the familiar relation:
358
359     sub tan { sin($_[0]) / cos($_[0])  }
360
361 =item bind SOCKET,NAME
362
363 Binds a network address to a socket, just as the bind system call
364 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
365 packed address of the appropriate type for the socket.  See the examples in
366 L<perlipc/"Sockets: Client/Server Communication">.
367
368 =item binmode FILEHANDLE
369
370 Arranges for the file to be read or written in "binary" mode in operating
371 systems that distinguish between binary and text files.  Files that are
372 not in binary mode have CR LF sequences translated to LF on input and LF
373 translated to CR LF on output.  Binmode has no effect under Unix; in DOS
374 and similarly archaic systems, it may be imperative--otherwise your
375 DOS-damaged C library may mangle your file.  The key distinction between
376 systems that need binmode and those that don't is their text file
377 formats.  Systems like Unix and Plan9 that delimit lines with a single
378 character, and that encode that character in C as '\n', do not need
379 C<binmode>.  The rest need it.  If FILEHANDLE is an expression, the value
380 is taken as the name of the filehandle.
381
382 =item bless REF,CLASSNAME
383
384 =item bless REF
385
386 This function tells the thingy referenced by REF that it is now
387 an object in the CLASSNAME package--or the current package if no CLASSNAME
388 is specified, which is often the case.  It returns the reference for
389 convenience, because a bless() is often the last thing in a constructor.
390 Always use the two-argument version if the function doing the blessing
391 might be inherited by a derived class.  See L<perlobj> for more about the
392 blessing (and blessings) of objects.
393
394 =item caller EXPR
395
396 =item caller
397
398 Returns the context of the current subroutine call.  In a scalar context,
399 returns the caller's package name if there is a caller, that is, if
400 we're in a subroutine or eval() or require(), and the undefined value
401 otherwise.  In a list context, returns
402
403     ($package, $filename, $line) = caller;
404
405 With EXPR, it returns some extra information that the debugger uses to
406 print a stack trace.  The value of EXPR indicates how many call frames
407 to go back before the current one.
408
409     ($package, $filename, $line, $subroutine, 
410      $hasargs, $wantarray, $evaltext, $is_require) = caller($i);
411
412 Here $subroutine may be C<"(eval)"> if the frame is not a subroutine
413 call, but C<L<eval>>.  In such a case additional elements $evaltext and
414 $is_require are set: $is_require is true if the frame is created by
415 C<L<require>> or C<L<use>> statement, $evaltext contains the text of
416 C<L<eval EXPR>> statement.  In particular, for C<L<eval BLOCK>>
417 statement $filename is C<"(eval)">, but $evaltext is undefined. (Note
418 also that C<L<use>> statement creates a C<L<require>> frame inside
419 an C<L<eval EXPR>>) frame.
420
421 Furthermore, when called from within the DB package, caller returns more
422 detailed information: it sets the list variable @DB::args to be the
423 arguments with which that subroutine was invoked.
424
425 =item chdir EXPR
426
427 Changes the working directory to EXPR, if possible.  If EXPR is
428 omitted, changes to home directory.  Returns TRUE upon success, FALSE
429 otherwise.  See example under die().
430
431 =item chmod LIST
432
433 Changes the permissions of a list of files.  The first element of the
434 list must be the numerical mode, which should probably be an octal
435 number, and which definitely should I<not> a string of octal digits:
436 C<0644> is okay, C<'0644'> is not.  Returns the number of files
437 successfully changed.  See also L<oct>, if all you have is a string.
438
439     $cnt = chmod 0755, 'foo', 'bar';
440     chmod 0755, @executables;
441     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to --w----r-T
442     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
443     $mode = 0644;   chmod $mode, 'foo';      # this is best
444
445 =item chomp VARIABLE
446
447 =item chomp LIST
448
449 =item chomp
450
451 This is a slightly safer version of chop (see below).  It removes any
452 line ending that corresponds to the current value of C<$/> (also known as
453 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
454 number of characters removed from all its arguments.  It's often used to
455 remove the newline from the end of an input record when you're worried
456 that the final record may be missing its newline.  When in paragraph mode
457 (C<$/ = "">), it removes all trailing newlines from the string.  If
458 VARIABLE is omitted, it chomps $_.  Example:
459
460     while (<>) {
461         chomp;  # avoid \n on last field
462         @array = split(/:/);
463         ...
464     }
465
466 You can actually chomp anything that's an lvalue, including an assignment:
467
468     chomp($cwd = `pwd`);
469     chomp($answer = <STDIN>);
470
471 If you chomp a list, each element is chomped, and the total number of
472 characters removed is returned.
473
474 =item chop VARIABLE
475
476 =item chop LIST
477
478 =item chop
479
480 Chops off the last character of a string and returns the character
481 chopped.  It's used primarily to remove the newline from the end of an
482 input record, but is much more efficient than C<s/\n//> because it neither
483 scans nor copies the string.  If VARIABLE is omitted, chops $_.
484 Example:
485
486     while (<>) {
487         chop;   # avoid \n on last field
488         @array = split(/:/);
489         ...
490     }
491
492 You can actually chop anything that's an lvalue, including an assignment:
493
494     chop($cwd = `pwd`);
495     chop($answer = <STDIN>);
496
497 If you chop a list, each element is chopped.  Only the value of the
498 last chop is returned.
499
500 Note that chop returns the last character.  To return all but the last
501 character, use C<substr($string, 0, -1)>.
502
503 =item chown LIST
504
505 Changes the owner (and group) of a list of files.  The first two
506 elements of the list must be the I<NUMERICAL> uid and gid, in that order.
507 Returns the number of files successfully changed.
508
509     $cnt = chown $uid, $gid, 'foo', 'bar';
510     chown $uid, $gid, @filenames;
511
512 Here's an example that looks up non-numeric uids in the passwd file:
513
514     print "User: ";
515     chop($user = <STDIN>);
516     print "Files: "
517     chop($pattern = <STDIN>);
518
519     ($login,$pass,$uid,$gid) = getpwnam($user)
520         or die "$user not in passwd file";
521
522     @ary = <${pattern}>;        # expand filenames
523     chown $uid, $gid, @ary;
524
525 On most systems, you are not allowed to change the ownership of the 
526 file unless you're the superuser, although you should be able to change
527 the group to any of your secondary groups.  On insecure systems, these
528 restrictions may be relaxed, but this is not a portable assumption.
529
530 =item chr NUMBER
531
532 =item chr 
533
534 Returns the character represented by that NUMBER in the character set.
535 For example, C<chr(65)> is "A" in ASCII.  For the reverse, use L<ord>.
536
537 If NUMBER is omitted, uses $_.
538
539 =item chroot FILENAME
540
541 =item chroot 
542
543 This function works as the system call by the same name: it makes the
544 named directory the new root directory for all further pathnames that
545 begin with a "/" by your process and all of its children.  (It doesn't
546 change your current working directory, which is unaffected.)  For security
547 reasons, this call is restricted to the superuser.  If FILENAME is
548 omitted, does chroot to $_.
549
550 =item close FILEHANDLE
551
552 Closes the file or pipe associated with the file handle, returning TRUE
553 only if stdio successfully flushes buffers and closes the system file
554 descriptor.  You don't have to close FILEHANDLE if you are immediately
555 going to do another open() on it, because open() will close it for you.  (See
556 open().)  However, an explicit close on an input file resets the line
557 counter ($.), while the implicit close done by open() does not.  Also,
558 closing a pipe will wait for the process executing on the pipe to
559 complete, in case you want to look at the output of the pipe
560 afterwards.  Closing a pipe explicitly also puts the status value of
561 the command into C<$?>.  Example:
562
563     open(OUTPUT, '|sort >foo'); # pipe to sort
564     ...                         # print stuff to output
565     close OUTPUT;               # wait for sort to finish
566     open(INPUT, 'foo');         # get sort's results
567
568 FILEHANDLE may be an expression whose value gives the real filehandle name.
569
570 =item closedir DIRHANDLE
571
572 Closes a directory opened by opendir().
573
574 =item connect SOCKET,NAME
575
576 Attempts to connect to a remote socket, just as the connect system call
577 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
578 packed address of the appropriate type for the socket.  See the examples in
579 L<perlipc/"Sockets: Client/Server Communication">.
580
581 =item continue BLOCK
582
583 Actually a flow control statement rather than a function.  If there is a
584 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
585 C<foreach>), it is always executed just before the conditional is about to
586 be evaluated again, just like the third part of a C<for> loop in C.  Thus
587 it can be used to increment a loop variable, even when the loop has been
588 continued via the C<next> statement (which is similar to the C C<continue>
589 statement).
590
591 =item cos EXPR
592
593 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted
594 takes cosine of $_.
595
596 For the inverse cosine operation, you may use the POSIX::acos()
597 function, or use this relation:
598
599     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
600
601 =item crypt PLAINTEXT,SALT
602
603 Encrypts a string exactly like the crypt(3) function in the C library
604 (assuming that you actually have a version there that has not been
605 extirpated as a potential munition).  This can prove useful for checking
606 the password file for lousy passwords, amongst other things.  Only the
607 guys wearing white hats should do this.
608
609 Note that there is no corresponding decrypt, so this fucntion isn't
610 all that useful for cryptography. (For that, see your nearby CPAN mirror.)
611
612 Here's an example that makes sure that whoever runs this program knows
613 their own password:
614
615     $pwd = (getpwuid($<))[1];
616     $salt = substr($pwd, 0, 2);
617
618     system "stty -echo";
619     print "Password: ";
620     chop($word = <STDIN>);
621     print "\n";
622     system "stty echo";
623
624     if (crypt($word, $salt) ne $pwd) {
625         die "Sorry...\n";
626     } else {
627         print "ok\n";
628     } 
629
630 Of course, typing in your own password to whomever asks you 
631 for it is unwise.
632
633 =item dbmclose HASH
634
635 [This function has been superseded by the untie() function.]
636
637 Breaks the binding between a DBM file and a hash.
638
639 =item dbmopen HASH,DBNAME,MODE
640
641 [This function has been superseded by the tie() function.]
642
643 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(), or Berkeley DB file to a
644 hash.  HASH is the name of the hash.  (Unlike normal open, the first
645 argument is I<NOT> a filehandle, even though it looks like one).  DBNAME
646 is the name of the database (without the F<.dir> or F<.pag> extension if
647 any).  If the database does not exist, it is created with protection
648 specified by MODE (as modified by the umask()).  If your system supports
649 only the older DBM functions, you may perform only one dbmopen() in your
650 program.  In older versions of Perl, if your system had neither DBM nor
651 ndbm, calling dbmopen() produced a fatal error; it now falls back to
652 sdbm(3).
653
654 If you don't have write access to the DBM file, you can only read hash
655 variables, not set them.  If you want to test whether you can write,
656 either use file tests or try setting a dummy hash entry inside an eval(),
657 which will trap the error.
658
659 Note that functions such as keys() and values() may return huge array
660 values when used on large DBM files.  You may prefer to use the each()
661 function to iterate over large DBM files.  Example:
662
663     # print out history file offsets
664     dbmopen(%HIST,'/usr/lib/news/history',0666);
665     while (($key,$val) = each %HIST) {
666         print $key, ' = ', unpack('L',$val), "\n";
667     }
668     dbmclose(%HIST);
669
670 See also L<AnyDBM_File> for a more general description of the pros and
671 cons of the various dbm approaches, as well as L<DB_File> for a particularly
672 rich implementation.
673
674 =item defined EXPR
675
676 =item defined 
677
678 Returns a Boolean value telling whether EXPR has a value other than
679 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
680 checked.
681
682 Many operations return C<undef> to indicate failure, end of file,
683 system error, uninitialized variable, and other exceptional
684 conditions.  This function allows you to distinguish C<undef> from
685 other values.  (A simple Boolean test will not distinguish among
686 C<undef>, zero, the empty string, and "0", which are all equally
687 false.)  Note that since C<undef> is a valid scalar, its presence
688 doesn't I<necessarily> indicate an exceptional condition: pop()
689 returns C<undef> when its argument is an empty array, I<or> when the
690 element to return happens to be C<undef>.
691
692 You may also use defined() to check whether a subroutine exists.  On
693 the other hand, use of defined() upon aggregates (hashes and arrays)
694 is not guaranteed to produce intuitive results, and should probably be
695 avoided.
696
697 When used on a hash element, it tells you whether the value is defined,
698 not whether the key exists in the hash.  Use L<exists> for the latter
699 purpose.
700
701 Examples:
702
703     print if defined $switch{'D'};
704     print "$val\n" while defined($val = pop(@ary));
705     die "Can't readlink $sym: $!"
706         unless defined($value = readlink $sym);
707     eval '@foo = ()' if defined(@foo);
708     die "No XYZ package defined" unless defined %_XYZ;
709     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
710     $debugging = 0 unless defined $debugging;
711
712 Note:  Many folks tend to overuse defined(), and then are surprised to
713 discover that the number 0 and "" (the zero-length string) are, in fact,
714 defined values.  For example, if you say
715
716     "ab" =~ /a(.*)b/;
717
718 the pattern match succeeds, and $1 is defined, despite the fact that it
719 matched "nothing".  But it didn't really match nothing--rather, it
720 matched something that happened to be 0 characters long.  This is all
721 very above-board and honest.  When a function returns an undefined value,
722 it's an admission that it couldn't give you an honest answer.  So you
723 should use defined() only when you're questioning the integrity of what
724 you're trying to do.  At other times, a simple comparison to 0 or "" is
725 what you want.
726
727 Currently, using defined() on an entire array or hash reports whether
728 memory for that aggregate has ever been allocated.  So an array you set
729 to the empty list appears undefined initially, and one that once was full
730 and that you then set to the empty list still appears defined.  You
731 should instead use a simple test for size:
732
733     if (@an_array) { print "has array elements\n" }
734     if (%a_hash)   { print "has hash members\n"   }
735
736 Using undef() on these, however, does clear their memory and then report
737 them as not defined anymore, but you shoudln't do that unless you don't
738 plan to use them again, because it saves time when you load them up
739 again to have memory already ready to be filled.
740
741 This counter-intuitive behaviour of defined() on aggregates may be
742 changed, fixed, or broken in a future release of Perl.
743
744 See also L<undef>, L<exists>, L<ref>.
745
746 =item delete EXPR
747
748 Deletes the specified key(s) and their associated values from a hash.
749 For each key, returns the deleted value associated with that key, or
750 the undefined value if there was no such key.  Deleting from C<$ENV{}>
751 modifies the environment.  Deleting from a hash tied to a DBM file
752 deletes the entry from the DBM file.  (But deleting from a tie()d hash
753 doesn't necessarily return anything.)
754
755 The following deletes all the values of a hash:
756
757     foreach $key (keys %HASH) {
758         delete $HASH{$key};
759     }
760
761 And so does this:
762
763     delete @HASH{keys %HASH}
764
765 (But both of these are slower than the undef() command.)  Note that the
766 EXPR can be arbitrarily complicated as long as the final operation is a
767 hash element lookup or hash slice:
768
769     delete $ref->[$x][$y]{$key};
770     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
771
772 =item die LIST
773
774 Outside of an eval(), prints the value of LIST to C<STDERR> and exits with
775 the current value of C<$!> (errno).  If C<$!> is 0, exits with the value of
776 C<($? E<gt>E<gt> 8)> (back-tick `command` status).  If C<($? E<gt>E<gt> 8)>
777 is 0, exits with 255.  Inside an eval(), the error message is stuffed into
778 C<$@>, and the eval() is terminated with the undefined value; this makes
779 die() the way to raise an exception.
780
781 Equivalent examples:
782
783     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
784     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n" 
785
786 If the value of EXPR does not end in a newline, the current script line
787 number and input line number (if any) are also printed, and a newline
788 is supplied.  Hint: sometimes appending ", stopped" to your message
789 will cause it to make better sense when the string "at foo line 123" is
790 appended.  Suppose you are running script "canasta".
791
792     die "/etc/games is no good";
793     die "/etc/games is no good, stopped";
794
795 produce, respectively
796
797     /etc/games is no good at canasta line 123.
798     /etc/games is no good, stopped at canasta line 123.
799
800 See also exit() and warn().
801
802 You can arrange for a callback to be called just before the die() does
803 its deed, by setting the C<$SIG{__DIE__}> hook.  The associated handler
804 will be called with the error text and can change the error message, if
805 it sees fit, by calling die() again.  See L<perlvar> for details on
806 setting C<%SIG> entries, and eval() for some examples.
807
808 =item do BLOCK
809
810 Not really a function.  Returns the value of the last command in the
811 sequence of commands indicated by BLOCK.  When modified by a loop
812 modifier, executes the BLOCK once before testing the loop condition.
813 (On other statements the loop modifiers test the conditional first.)
814
815 =item do SUBROUTINE(LIST)
816
817 A deprecated form of subroutine call.  See L<perlsub>.
818
819 =item do EXPR
820
821 Uses the value of EXPR as a filename and executes the contents of the
822 file as a Perl script.  Its primary use is to include subroutines
823 from a Perl subroutine library.
824
825     do 'stat.pl';
826
827 is just like
828
829     eval `cat stat.pl`;
830
831 except that it's more efficient, more concise, keeps track of the
832 current filename for error messages, and searches all the B<-I>
833 libraries if the file isn't in the current directory (see also the @INC
834 array in L<perlvar/Predefined Names>).  It's the same, however, in that it does
835 re-parse the file every time you call it, so you probably don't want to
836 do this inside a loop.
837
838 Note that inclusion of library modules is better done with the
839 use() and require() operators, which also do error checking
840 and raise an exception if there's a problem.
841
842 =item dump LABEL
843
844 This causes an immediate core dump.  Primarily this is so that you can
845 use the B<undump> program to turn your core dump into an executable binary
846 after having initialized all your variables at the beginning of the
847 program.  When the new binary is executed it will begin by executing a
848 C<goto LABEL> (with all the restrictions that C<goto> suffers).  Think of
849 it as a goto with an intervening core dump and reincarnation.  If LABEL
850 is omitted, restarts the program from the top.  WARNING: any files
851 opened at the time of the dump will NOT be open any more when the
852 program is reincarnated, with possible resulting confusion on the part
853 of Perl.  See also B<-u> option in L<perlrun>.
854
855 Example:
856
857     #!/usr/bin/perl
858     require 'getopt.pl';
859     require 'stat.pl';
860     %days = (
861         'Sun' => 1,
862         'Mon' => 2,
863         'Tue' => 3,
864         'Wed' => 4,
865         'Thu' => 5,
866         'Fri' => 6,
867         'Sat' => 7,
868     );
869
870     dump QUICKSTART if $ARGV[0] eq '-d';
871
872     QUICKSTART:
873     Getopt('f');
874
875 =item each HASH
876
877 When called in a list context, returns a 2-element array consisting of the
878 key and value for the next element of a hash, so that you can iterate over
879 it.  When called in a scalar context, returns the key for only the next
880 element in the hash.  (Note: Keys may be "0" or "", which are logically
881 false; you may wish to avoid constructs like C<while ($k = each %foo) {}>
882 for this reason.)
883
884 Entries are returned in an apparently random order.  When the hash is
885 entirely read, a null array is returned in list context (which when
886 assigned produces a FALSE (0) value), and C<undef> is returned in a
887 scalar context.  The next call to each() after that will start iterating
888 again.  There is a single iterator for each hash, shared by all each(),
889 keys(), and values() function calls in the program; it can be reset by
890 reading all the elements from the hash, or by evaluating C<keys HASH> or
891 C<values HASH>.  If you add or delete elements of a hash while you're
892 iterating over it, you may get entries skipped or duplicated, so don't.
893
894 The following prints out your environment like the printenv(1) program,
895 only in a different order:
896
897     while (($key,$value) = each %ENV) {
898         print "$key=$value\n";
899     }
900
901 See also keys() and values().
902
903 =item eof FILEHANDLE
904
905 =item eof ()
906
907 =item eof
908
909 Returns 1 if the next read on FILEHANDLE will return end of file, or if
910 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
911 gives the real filehandle name.  (Note that this function actually
912 reads a character and then ungetc()s it, so it is not very useful in an
913 interactive context.)  Do not read from a terminal file (or call
914 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  Filetypes such
915 as terminals may lose the end-of-file condition if you do.
916
917 An C<eof> without an argument uses the last file read as argument.
918 Empty parentheses () may be used to indicate the pseudo file formed of
919 the files listed on the command line, i.e., C<eof()> is reasonable to
920 use inside a C<while (E<lt>E<gt>)> loop to detect the end of only the
921 last file.  Use C<eof(ARGV)> or eof without the parentheses to test
922 I<EACH> file in a while (E<lt>E<gt>) loop.  Examples:
923
924     # reset line numbering on each input file
925     while (<>) {
926         print "$.\t$_";
927         close(ARGV) if (eof);   # Not eof().
928     }
929
930     # insert dashes just before last line of last file
931     while (<>) {
932         if (eof()) {
933             print "--------------\n";
934             close(ARGV);        # close or break; is needed if we
935                                 # are reading from the terminal
936         }
937         print;
938     }
939
940 Practical hint: you almost never need to use C<eof> in Perl, because the
941 input operators return undef when they run out of data.  
942
943 =item eval EXPR
944
945 =item eval BLOCK
946
947 EXPR is parsed and executed as if it were a little Perl program.  It
948 is executed in the context of the current Perl program, so that any
949 variable settings or subroutine and format definitions remain afterwards.
950 The value returned is the value of the last expression evaluated, or a
951 return statement may be used, just as with subroutines.  The last
952 expression is evaluated in scalar or array context, depending on the
953 context of the eval.
954
955 If there is a syntax error or runtime error, or a die() statement is
956 executed, an undefined value is returned by eval(), and C<$@> is set to the
957 error message.  If there was no error, C<$@> is guaranteed to be a null
958 string.  If EXPR is omitted, evaluates C<$_>.  The final semicolon, if
959 any, may be omitted from the expression.  Beware that using eval()
960 neither silences perl from printing warnings to STDERR, nor does it
961 stuff the text of warning messages into C<$@>.  To do either of those,
962 you have to use the C<$SIG{__WARN__}> facility.  See warn() and L<perlvar>.
963
964 Note that, because eval() traps otherwise-fatal errors, it is useful for
965 determining whether a particular feature (such as socket() or symlink())
966 is implemented.  It is also Perl's exception trapping mechanism, where
967 the die operator is used to raise exceptions.
968
969 If the code to be executed doesn't vary, you may use the eval-BLOCK
970 form to trap run-time errors without incurring the penalty of
971 recompiling each time.  The error, if any, is still returned in C<$@>.
972 Examples:
973
974     # make divide-by-zero non-fatal
975     eval { $answer = $a / $b; }; warn $@ if $@;
976
977     # same thing, but less efficient
978     eval '$answer = $a / $b'; warn $@ if $@;
979
980     # a compile-time error
981     eval { $answer = };
982
983     # a run-time error
984     eval '$answer =';   # sets $@
985
986 When using the eval{} form as an exception trap in libraries, you may
987 wish not to trigger any C<__DIE__> hooks that user code may have
988 installed.  You can use the C<local $SIG{__DIE__}> construct for this
989 purpose, as shown in this example:
990
991     # a very private exception trap for divide-by-zero
992     eval { local $SIG{'__DIE__'}; $answer = $a / $b; }; warn $@ if $@;
993
994 This is especially significant, given that C<__DIE__> hooks can call
995 die() again, which has the effect of changing their error messages:
996
997     # __DIE__ hooks may modify error messages
998     {
999        local $SIG{'__DIE__'} = sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1000        eval { die "foo foofs here" };
1001        print $@ if $@;                # prints "bar barfs here"
1002     }
1003
1004 With an eval(), you should be especially careful to remember what's 
1005 being looked at when:
1006
1007     eval $x;            # CASE 1
1008     eval "$x";          # CASE 2
1009
1010     eval '$x';          # CASE 3
1011     eval { $x };        # CASE 4
1012
1013     eval "\$$x++"       # CASE 5
1014     $$x++;              # CASE 6
1015
1016 Cases 1 and 2 above behave identically: they run the code contained in
1017 the variable $x.  (Although case 2 has misleading double quotes making
1018 the reader wonder what else might be happening (nothing is).)  Cases 3
1019 and 4 likewise behave in the same way: they run the code '$x', which
1020 does nothing but return the value of C<$x>.  (Case 4 is preferred for
1021 purely visual reasons, but it also has the advantage of compiling at
1022 compile-time instead of at run-time.)  Case 5 is a place where
1023 normally you I<WOULD> like to use double quotes, except that in that
1024 particular situation, you can just use symbolic references instead, as
1025 in case 6.
1026
1027 =item exec LIST
1028
1029 The exec() function executes a system command I<AND NEVER RETURNS>,
1030 unless the command does not exist and is executed directly instead of
1031 via C</bin/sh -c> (see below).  Use system() instead of exec() if you
1032 want it to return.
1033
1034 If there is more than one argument in LIST, or if LIST is an array with
1035 more than one value, calls execvp(3) with the arguments in LIST.  If
1036 there is only one scalar argument, the argument is checked for shell
1037 metacharacters.  If there are any, the entire argument is passed to
1038 C</bin/sh -c> for parsing.  If there are none, the argument is split
1039 into words and passed directly to execvp(), which is more efficient.
1040 Note: exec() and system() do not flush your output buffer, so you may
1041 need to set C<$|> to avoid lost output.  Examples:
1042
1043     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1044     exec "sort $outfile | uniq";
1045
1046 If you don't really want to execute the first argument, but want to lie
1047 to the program you are executing about its own name, you can specify
1048 the program you actually want to run as an "indirect object" (without a
1049 comma) in front of the LIST.  (This always forces interpretation of the
1050 LIST as a multi-valued list, even if there is only a single scalar in
1051 the list.)  Example:
1052
1053     $shell = '/bin/csh';
1054     exec $shell '-sh';          # pretend it's a login shell
1055
1056 or, more directly,
1057
1058     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1059
1060 =item exists EXPR
1061
1062 Returns TRUE if the specified hash key exists in its hash array, even
1063 if the corresponding value is undefined.
1064
1065     print "Exists\n" if exists $array{$key};
1066     print "Defined\n" if defined $array{$key};
1067     print "True\n" if $array{$key};
1068
1069 A hash element can be TRUE only if it's defined, and defined if
1070 it exists, but the reverse doesn't necessarily hold true.
1071
1072 Note that the EXPR can be arbitrarily complicated as long as the final
1073 operation is a hash key lookup:
1074
1075     if (exists $ref->[$x][$y]{$key}) { ... }
1076
1077 =item exit EXPR
1078
1079 Evaluates EXPR and exits immediately with that value.  (Actually, it
1080 calls any defined C<END> routines first, but the C<END> routines may not
1081 abort the exit.  Likewise any object destructors that need to be called
1082 are called before exit.)  Example:
1083
1084     $ans = <STDIN>;
1085     exit 0 if $ans =~ /^[Xx]/;
1086
1087 See also die().  If EXPR is omitted, exits with 0 status.  The only
1088 univerally portable values for EXPR are 0 for success and 1 for error;
1089 all other values are subject to unpredictable interpretation depending
1090 on the environment in which the Perl program is running.
1091
1092 You shouldn't use exit() to abort a subroutine if there's any chance that
1093 someone might want to trap whatever error happened.  Use die() instead,
1094 which can be trapped by an eval().
1095
1096 =item exp EXPR
1097
1098 =item exp 
1099
1100 Returns I<e> (the natural logarithm base) to the power of EXPR.  
1101 If EXPR is omitted, gives C<exp($_)>.
1102
1103 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1104
1105 Implements the fcntl(2) function.  You'll probably have to say
1106
1107     use Fcntl;
1108
1109 first to get the correct function definitions.  Argument processing and
1110 value return works just like ioctl() below.  Note that fcntl() will produce
1111 a fatal error if used on a machine that doesn't implement fcntl(2).
1112 For example:
1113
1114     use Fcntl;
1115     fcntl($filehandle, F_GETLK, $packed_return_buffer);
1116
1117 =item fileno FILEHANDLE
1118
1119 Returns the file descriptor for a filehandle.  This is useful for
1120 constructing bitmaps for select().  If FILEHANDLE is an expression, the
1121 value is taken as the name of the filehandle.
1122
1123 =item flock FILEHANDLE,OPERATION
1124
1125 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns TRUE for
1126 success, FALSE on failure.  Will produce a fatal error if used on a
1127 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1128 flock() is Perl's portable file locking interface, although it will lock
1129 only entire files, not records.
1130
1131 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1132 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1133 you can use the symbolic names if you pull them in with an explicit
1134 request to the Fcntl module.  The names can be requested as a group with
1135 the :flock tag (or they can be requested individually, of course).
1136 LOCK_SH requests a shared lock, LOCK_EX requests an exclusive lock, and
1137 LOCK_UN releases a previously requested lock.  If LOCK_NB is added to
1138 LOCK_SH or LOCK_EX then flock() will return immediately rather than
1139 blocking waiting for the lock (check the return status to see if you got
1140 it).
1141
1142 Note that the emulation built with lockf(3) doesn't provide shared
1143 locks, and it requires that FILEHANDLE be open with write intent.  These
1144 are the semantics that lockf(3) implements.  Most (all?) systems
1145 implement lockf(3) in terms of fcntl(2) locking, though, so the
1146 differing semantics shouldn't bite too many people.
1147
1148 Note also that some versions of flock() cannot lock things over the
1149 network; you would need to use the more system-specific fcntl() for
1150 that.  If you like you can force Perl to ignore your system's flock(2)
1151 function, and so provide its own fcntl(2)-based emulation, by passing
1152 the switch C<-Ud_flock> to the F<Configure> program when you configure
1153 perl.
1154
1155 Here's a mailbox appender for BSD systems.
1156
1157     use Fcntl ':flock'; # import LOCK_* constants
1158
1159     sub lock {
1160         flock(MBOX,LOCK_EX);
1161         # and, in case someone appended
1162         # while we were waiting...
1163         seek(MBOX, 0, 2);
1164     }
1165
1166     sub unlock {
1167         flock(MBOX,LOCK_UN);
1168     }
1169
1170     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1171             or die "Can't open mailbox: $!";
1172
1173     lock();
1174     print MBOX $msg,"\n\n";
1175     unlock();
1176
1177 See also L<DB_File> for other flock() examples.
1178
1179 =item fork
1180
1181 Does a fork(2) system call.  Returns the child pid to the parent process
1182 and 0 to the child process, or C<undef> if the fork is unsuccessful.
1183 Note: unflushed buffers remain unflushed in both processes, which means
1184 you may need to set C<$|> ($AUTOFLUSH in English) or call the autoflush()
1185 method of IO::Handle to avoid duplicate output.
1186
1187 If you fork() without ever waiting on your children, you will accumulate
1188 zombies:
1189
1190     $SIG{CHLD} = sub { wait };
1191
1192 There's also the double-fork trick (error checking on 
1193 fork() returns omitted);
1194
1195     unless ($pid = fork) {
1196         unless (fork) {
1197             exec "what you really wanna do";
1198             die "no exec";
1199             # ... or ...
1200             ## (some_perl_code_here)
1201             exit 0;
1202         }
1203         exit 0;
1204     }
1205     waitpid($pid,0);
1206
1207 See also L<perlipc> for more examples of forking and reaping
1208 moribund children.
1209
1210 Note that if your forked child inherits system file descriptors like
1211 STDIN and STDOUT that are actually connected by a pipe or socket, even
1212 if you exit, the remote server (such as, say, httpd or rsh) won't think
1213 you're done.  You should reopen those to /dev/null if it's any issue.
1214
1215 =item format
1216
1217 Declare a picture format with use by the write() function.  For
1218 example:
1219
1220     format Something = 
1221         Test: @<<<<<<<< @||||| @>>>>>
1222               $str,     $%,    '$' . int($num)
1223     .
1224
1225     $str = "widget";
1226     $num = $cost/$quantity;
1227     $~ = 'Something';
1228     write;
1229
1230 See L<perlform> for many details and examples.
1231
1232
1233 =item formline PICTURE, LIST
1234
1235 This is an internal function used by C<format>s, though you may call it
1236 too.  It formats (see L<perlform>) a list of values according to the
1237 contents of PICTURE, placing the output into the format output
1238 accumulator, C<$^A> (or $ACCUMULATOR in English).
1239 Eventually, when a write() is done, the contents of
1240 C<$^A> are written to some filehandle, but you could also read C<$^A>
1241 yourself and then set C<$^A> back to "".  Note that a format typically
1242 does one formline() per line of form, but the formline() function itself
1243 doesn't care how many newlines are embedded in the PICTURE.  This means
1244 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1245 You may therefore need to use multiple formlines to implement a single
1246 record format, just like the format compiler.
1247
1248 Be careful if you put double quotes around the picture, because an "C<@>"
1249 character may be taken to mean the beginning of an array name.
1250 formline() always returns TRUE.  See L<perlform> for other examples.
1251
1252 =item getc FILEHANDLE
1253
1254 =item getc
1255
1256 Returns the next character from the input file attached to FILEHANDLE,
1257 or a null string at end of file.  If FILEHANDLE is omitted, reads from STDIN.
1258 This is not particularly efficient.  It cannot be used to get unbuffered
1259 single-characters, however.  For that, try something more like:
1260
1261     if ($BSD_STYLE) {
1262         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1263     }
1264     else {
1265         system "stty", '-icanon', 'eol', "\001"; 
1266     }
1267
1268     $key = getc(STDIN);
1269
1270     if ($BSD_STYLE) {
1271         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1272     }
1273     else {
1274         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1275     }
1276     print "\n";
1277
1278 Determination of whether $BSD_STYLE should be set 
1279 is left as an exercise to the reader.  
1280
1281 The POSIX::getattr() function can do this more portably on systems
1282 alleging POSIX compliance.
1283 See also the C<Term::ReadKey> module from your nearest CPAN site;
1284 details on CPAN can be found on L<perlmod/CPAN>.  
1285
1286 =item getlogin
1287
1288 Returns the current login from F</etc/utmp>, if any.  If null, use
1289 getpwuid().  
1290
1291     $login = getlogin || getpwuid($<) || "Kilroy";
1292
1293 Do not consider getlogin() for authentication: it is not as
1294 secure as getpwuid().
1295
1296 =item getpeername SOCKET
1297
1298 Returns the packed sockaddr address of other end of the SOCKET connection.
1299
1300     use Socket;
1301     $hersockaddr    = getpeername(SOCK);
1302     ($port, $iaddr) = unpack_sockaddr_in($hersockaddr);
1303     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1304     $herstraddr     = inet_ntoa($iaddr);
1305
1306 =item getpgrp PID
1307
1308 Returns the current process group for the specified PID.  Use
1309 a PID of 0 to get the current process group for the
1310 current process.  Will raise an exception if used on a machine that
1311 doesn't implement getpgrp(2).  If PID is omitted, returns process
1312 group of current process.  Note that the POSIX version of getpgrp()
1313 does not accept a PID argument, so only PID==0 is truly portable.
1314
1315 =item getppid
1316
1317 Returns the process id of the parent process.
1318
1319 =item getpriority WHICH,WHO
1320
1321 Returns the current priority for a process, a process group, or a user.
1322 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1323 machine that doesn't implement getpriority(2).
1324
1325 =item getpwnam NAME
1326
1327 =item getgrnam NAME
1328
1329 =item gethostbyname NAME
1330
1331 =item getnetbyname NAME
1332
1333 =item getprotobyname NAME
1334
1335 =item getpwuid UID
1336
1337 =item getgrgid GID
1338
1339 =item getservbyname NAME,PROTO
1340
1341 =item gethostbyaddr ADDR,ADDRTYPE
1342
1343 =item getnetbyaddr ADDR,ADDRTYPE
1344
1345 =item getprotobynumber NUMBER
1346
1347 =item getservbyport PORT,PROTO
1348
1349 =item getpwent
1350
1351 =item getgrent
1352
1353 =item gethostent
1354
1355 =item getnetent
1356
1357 =item getprotoent
1358
1359 =item getservent
1360
1361 =item setpwent
1362
1363 =item setgrent
1364
1365 =item sethostent STAYOPEN
1366
1367 =item setnetent STAYOPEN
1368
1369 =item setprotoent STAYOPEN
1370
1371 =item setservent STAYOPEN
1372
1373 =item endpwent
1374
1375 =item endgrent
1376
1377 =item endhostent
1378
1379 =item endnetent
1380
1381 =item endprotoent
1382
1383 =item endservent
1384
1385 These routines perform the same functions as their counterparts in the
1386 system library.  Within a list context, the return values from the
1387 various get routines are as follows:
1388
1389     ($name,$passwd,$uid,$gid,
1390        $quota,$comment,$gcos,$dir,$shell) = getpw*
1391     ($name,$passwd,$gid,$members) = getgr*
1392     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1393     ($name,$aliases,$addrtype,$net) = getnet*
1394     ($name,$aliases,$proto) = getproto*
1395     ($name,$aliases,$port,$proto) = getserv*
1396
1397 (If the entry doesn't exist you get a null list.)
1398
1399 Within a scalar context, you get the name, unless the function was a
1400 lookup by name, in which case you get the other thing, whatever it is.
1401 (If the entry doesn't exist you get the undefined value.)  For example:
1402
1403     $uid = getpwnam
1404     $name = getpwuid
1405     $name = getpwent
1406     $gid = getgrnam
1407     $name = getgrgid
1408     $name = getgrent
1409     etc.
1410
1411 The $members value returned by I<getgr*()> is a space separated list of
1412 the login names of the members of the group.
1413
1414 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1415 C, it will be returned to you via C<$?> if the function call fails.  The
1416 @addrs value returned by a successful call is a list of the raw
1417 addresses returned by the corresponding system library call.  In the
1418 Internet domain, each address is four bytes long and you can unpack it
1419 by saying something like:
1420
1421     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1422
1423 =item getsockname SOCKET
1424
1425 Returns the packed sockaddr address of this end of the SOCKET connection.
1426
1427     use Socket;
1428     $mysockaddr = getsockname(SOCK);
1429     ($port, $myaddr) = unpack_sockaddr_in($mysockaddr);
1430
1431 =item getsockopt SOCKET,LEVEL,OPTNAME
1432
1433 Returns the socket option requested, or undefined if there is an error.
1434
1435 =item glob EXPR
1436
1437 =item glob
1438
1439 Returns the value of EXPR with filename expansions such as a shell
1440 would do.  This is the internal function implementing the <*.c>
1441 operator, except it's easier to use.  If EXPR is omitted, $_ is used.
1442
1443 =item gmtime EXPR
1444
1445 Converts a time as returned by the time function to a 9-element array
1446 with the time localized for the standard Greenwich time zone.  
1447 Typically used as follows:
1448
1449
1450     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1451                                             gmtime(time);
1452
1453 All array elements are numeric, and come straight out of a struct tm.
1454 In particular this means that $mon has the range 0..11 and $wday has
1455 the range 0..6.  Also, $year is the number of years since 1900, I<not>
1456 simply the last two digits of the year.
1457
1458 If EXPR is omitted, does C<gmtime(time())>.
1459
1460 In a scalar context, prints out the ctime(3) value:
1461
1462     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1463
1464 Also see the F<timegm.pl> library, and the strftime(3) function available
1465 via the POSIX module.
1466
1467 =item goto LABEL
1468
1469 =item goto EXPR
1470
1471 =item goto &NAME
1472
1473 The goto-LABEL form finds the statement labeled with LABEL and resumes
1474 execution there.  It may not be used to go into any construct that
1475 requires initialization, such as a subroutine or a foreach loop.  It
1476 also can't be used to go into a construct that is optimized away,
1477 or to get out of a block or subroutine given to sort().
1478 It can be used to go almost anywhere else within the dynamic scope,
1479 including out of subroutines, but it's usually better to use some other
1480 construct such as last or die.  The author of Perl has never felt the
1481 need to use this form of goto (in Perl, that is--C is another matter).
1482
1483 The goto-EXPR form expects a label name, whose scope will be resolved
1484 dynamically.  This allows for computed gotos per FORTRAN, but isn't
1485 necessarily recommended if you're optimizing for maintainability:
1486
1487     goto ("FOO", "BAR", "GLARCH")[$i];
1488
1489 The goto-&NAME form is highly magical, and substitutes a call to the
1490 named subroutine for the currently running subroutine.  This is used by
1491 AUTOLOAD subroutines that wish to load another subroutine and then
1492 pretend that the other subroutine had been called in the first place
1493 (except that any modifications to @_ in the current subroutine are
1494 propagated to the other subroutine.)  After the goto, not even caller()
1495 will be able to tell that this routine was called first.
1496
1497 =item grep BLOCK LIST
1498
1499 =item grep EXPR,LIST
1500
1501 This is similar in spirit to, but not the same as, L<grep(1)>
1502 and its relatives.  In particular, it is not limited to using
1503 regular expressions.
1504
1505 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1506 $_ to each element) and returns the list value consisting of those
1507 elements for which the expression evaluated to TRUE.  In a scalar
1508 context, returns the number of times the expression was TRUE.
1509
1510     @foo = grep(!/^#/, @bar);    # weed out comments
1511
1512 or equivalently,
1513
1514     @foo = grep {!/^#/} @bar;    # weed out comments
1515
1516 Note that, because $_ is a reference into the list value, it can be used
1517 to modify the elements of the array.  While this is useful and
1518 supported, it can cause bizarre results if the LIST is not a named
1519 array.  Similarly, grep returns aliases into the original list,
1520 much like the way that L<foreach>'s index variable aliases the list
1521 elements.  That is, modifying an element of a list returned by grep
1522 actually modifies the element in the original list.
1523
1524 =item hex EXPR
1525
1526 =item hex 
1527
1528 Interprets EXPR as a hex string and returns the corresponding 
1529 value.  (To convert strings that might start with either 0 or 0x
1530 see L<oct>.)  If EXPR is omitted, uses $_.
1531
1532     print hex '0xAf'; # prints '175'
1533     print hex 'aF';   # same
1534
1535 =item import
1536
1537 There is no built-in import() function.  It is merely an ordinary
1538 method (subroutine) defined (or inherited) by modules that wish to export
1539 names to another module.  The use() function calls the import() method
1540 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
1541
1542 =item index STR,SUBSTR,POSITION
1543
1544 =item index STR,SUBSTR
1545
1546 Returns the position of the first occurrence of SUBSTR in STR at or after
1547 POSITION.  If POSITION is omitted, starts searching from the beginning of
1548 the string.  The return value is based at 0 (or whatever you've set the C<$[>
1549 variable to--but don't do that).  If the substring is not found, returns
1550 one less than the base, ordinarily -1.
1551
1552 =item int EXPR
1553
1554 =item int 
1555
1556 Returns the integer portion of EXPR.  If EXPR is omitted, uses $_.
1557
1558 =item ioctl FILEHANDLE,FUNCTION,SCALAR
1559
1560 Implements the ioctl(2) function.  You'll probably have to say
1561
1562     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
1563
1564 first to get the correct function definitions.  If F<ioctl.ph> doesn't
1565 exist or doesn't have the correct definitions you'll have to roll your
1566 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
1567 (There is a Perl script called B<h2ph> that comes with the Perl kit which
1568 may help you in this, but it's non-trivial.)  SCALAR will be read and/or
1569 written depending on the FUNCTION--a pointer to the string value of SCALAR
1570 will be passed as the third argument of the actual ioctl call.  (If SCALAR
1571 has no string value but does have a numeric value, that value will be
1572 passed rather than a pointer to the string value.  To guarantee this to be
1573 TRUE, add a 0 to the scalar before using it.)  The pack() and unpack()
1574 functions are useful for manipulating the values of structures used by
1575 ioctl().  The following example sets the erase character to DEL.
1576
1577     require 'ioctl.ph';
1578     $getp = &TIOCGETP;
1579     die "NO TIOCGETP" if $@ || !$getp;
1580     $sgttyb_t = "ccccs";                # 4 chars and a short
1581     if (ioctl(STDIN,$getp,$sgttyb)) {
1582         @ary = unpack($sgttyb_t,$sgttyb);
1583         $ary[2] = 127;
1584         $sgttyb = pack($sgttyb_t,@ary);
1585         ioctl(STDIN,&TIOCSETP,$sgttyb)
1586             || die "Can't ioctl: $!";
1587     }
1588
1589 The return value of ioctl (and fcntl) is as follows:
1590
1591         if OS returns:          then Perl returns:
1592             -1                    undefined value
1593              0                  string "0 but true"
1594         anything else               that number
1595
1596 Thus Perl returns TRUE on success and FALSE on failure, yet you can
1597 still easily determine the actual value returned by the operating
1598 system:
1599
1600     ($retval = ioctl(...)) || ($retval = -1);
1601     printf "System returned %d\n", $retval;
1602
1603 =item join EXPR,LIST
1604
1605 Joins the separate strings of LIST or ARRAY into a single string with
1606 fields separated by the value of EXPR, and returns the string.
1607 Example:
1608
1609     $_ = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
1610
1611 See L<perlfunc/split>.
1612
1613 =item keys HASH
1614
1615 Returns a normal array consisting of all the keys of the named hash.  (In
1616 a scalar context, returns the number of keys.)  The keys are returned in
1617 an apparently random order, but it is the same order as either the
1618 values() or each() function produces (given that the hash has not been
1619 modified).  As a side effect, it resets HASH's iterator.
1620
1621 Here is yet another way to print your environment:
1622
1623     @keys = keys %ENV;
1624     @values = values %ENV;
1625     while ($#keys >= 0) {
1626         print pop(@keys), '=', pop(@values), "\n";
1627     }
1628
1629 or how about sorted by key:
1630
1631     foreach $key (sort(keys %ENV)) {
1632         print $key, '=', $ENV{$key}, "\n";
1633     }
1634
1635 To sort an array by value, you'll need to use a C<sort{}> function.
1636 Here's a descending numeric sort of a hash by its values:
1637
1638     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash)) {
1639         printf "%4d %s\n", $hash{$key}, $key;
1640     }
1641
1642 As an lvalue C<keys> allows you to increase the number of hash buckets
1643 allocated for the given hash.  This can gain you a measure of efficiency if
1644 you know the hash is going to get big.  (This is similar to pre-extending
1645 an array by assigning a larger number to $#array.)  If you say
1646
1647     keys %hash = 200;
1648
1649 then C<%hash> will have at least 200 buckets allocated for it.  These
1650 buckets will be retained even if you do C<%hash = ()>, use C<undef
1651 %hash> if you want to free the storage while C<%hash> is still in scope.
1652 You can't shrink the number of buckets allocated for the hash using
1653 C<keys> in this way (but you needn't worry about doing this by accident,
1654 as trying has no effect).
1655
1656 =item kill LIST
1657
1658 Sends a signal to a list of processes.  The first element of 
1659 the list must be the signal to send.  Returns the number of 
1660 processes successfully signaled.
1661
1662     $cnt = kill 1, $child1, $child2;
1663     kill 9, @goners;
1664
1665 Unlike in the shell, in Perl if the I<SIGNAL> is negative, it kills
1666 process groups instead of processes.  (On System V, a negative I<PROCESS>
1667 number will also kill process groups, but that's not portable.)  That
1668 means you usually want to use positive not negative signals.  You may also
1669 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
1670
1671 =item last LABEL
1672
1673 =item last
1674
1675 The C<last> command is like the C<break> statement in C (as used in
1676 loops); it immediately exits the loop in question.  If the LABEL is
1677 omitted, the command refers to the innermost enclosing loop.  The
1678 C<continue> block, if any, is not executed:
1679
1680     LINE: while (<STDIN>) {
1681         last LINE if /^$/;      # exit when done with header
1682         ...
1683     }
1684
1685 =item lc EXPR
1686
1687 =item lc 
1688
1689 Returns an lowercased version of EXPR.  This is the internal function
1690 implementing the \L escape in double-quoted strings.  
1691 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
1692
1693 If EXPR is omitted, uses $_.
1694
1695 =item lcfirst EXPR
1696
1697 =item lcfirst 
1698
1699 Returns the value of EXPR with the first character lowercased.  This is
1700 the internal function implementing the \l escape in double-quoted strings.
1701 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
1702
1703 If EXPR is omitted, uses $_.
1704
1705 =item length EXPR
1706
1707 =item length 
1708
1709 Returns the length in characters of the value of EXPR.  If EXPR is
1710 omitted, returns length of $_.
1711
1712 =item link OLDFILE,NEWFILE
1713
1714 Creates a new filename linked to the old filename.  Returns 1 for
1715 success, 0 otherwise.
1716
1717 =item listen SOCKET,QUEUESIZE
1718
1719 Does the same thing that the listen system call does.  Returns TRUE if
1720 it succeeded, FALSE otherwise.  See example in L<perlipc/"Sockets: Client/Server Communication">.
1721
1722 =item local EXPR
1723
1724 A local modifies the listed variables to be local to the enclosing block,
1725 subroutine, C<eval{}>, or C<do>.  If more than one value is listed, the
1726 list must be placed in parentheses.  See L<perlsub/"Temporary Values via
1727 local()"> for details.
1728
1729 But you really probably want to be using my() instead, because local() isn't
1730 what most people think of as "local").  See L<perlsub/"Private Variables
1731 via my()"> for details.
1732
1733 =item localtime EXPR
1734
1735 Converts a time as returned by the time function to a 9-element array
1736 with the time analyzed for the local time zone.  Typically used as
1737 follows:
1738
1739     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1740                                                 localtime(time);
1741
1742 All array elements are numeric, and come straight out of a struct tm.
1743 In particular this means that $mon has the range 0..11 and $wday has
1744 the range 0..6 and $year is year-1900, that is, $year is 123 in year
1745 2023.  If EXPR is omitted, uses the current time ("localtime(time)").
1746
1747 In a scalar context, returns the ctime(3) value:
1748
1749     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1750
1751 Also see the Time::Local module, and the strftime(3) function available
1752 via the POSIX module.
1753
1754 =item log EXPR
1755
1756 =item log 
1757
1758 Returns logarithm (base I<e>) of EXPR.  If EXPR is omitted, returns log
1759 of $_.
1760
1761 =item lstat FILEHANDLE
1762
1763 =item lstat EXPR
1764
1765 =item lstat 
1766
1767 Does the same thing as the stat() function, but stats a symbolic link
1768 instead of the file the symbolic link points to.  If symbolic links are
1769 unimplemented on your system, a normal stat() is done.
1770
1771 If EXPR is omitted, stats $_.
1772
1773 =item m//
1774
1775 The match operator.  See L<perlop>.
1776
1777 =item map BLOCK LIST
1778
1779 =item map EXPR,LIST
1780
1781 Evaluates the BLOCK or EXPR for each element of LIST (locally setting $_ to each
1782 element) and returns the list value composed of the results of each such
1783 evaluation.  Evaluates BLOCK or EXPR in a list context, so each element of LIST
1784 may produce zero, one, or more elements in the returned value.
1785
1786     @chars = map(chr, @nums);
1787
1788 translates a list of numbers to the corresponding characters.  And
1789
1790     %hash = map { getkey($_) => $_ } @array;
1791
1792 is just a funny way to write
1793
1794     %hash = ();
1795     foreach $_ (@array) {
1796         $hash{getkey($_)} = $_;
1797     }
1798
1799 =item mkdir FILENAME,MODE
1800
1801 Creates the directory specified by FILENAME, with permissions specified
1802 by MODE (as modified by umask).  If it succeeds it returns 1, otherwise
1803 it returns 0 and sets C<$!> (errno).
1804
1805 =item msgctl ID,CMD,ARG
1806
1807 Calls the System V IPC function msgctl(2).  If CMD is &IPC_STAT, then ARG
1808 must be a variable which will hold the returned msqid_ds structure.
1809 Returns like ioctl: the undefined value for error, "0 but true" for
1810 zero, or the actual return value otherwise.
1811
1812 =item msgget KEY,FLAGS
1813
1814 Calls the System V IPC function msgget(2).  Returns the message queue id,
1815 or the undefined value if there is an error.
1816
1817 =item msgsnd ID,MSG,FLAGS
1818
1819 Calls the System V IPC function msgsnd to send the message MSG to the
1820 message queue ID.  MSG must begin with the long integer message type,
1821 which may be created with C<pack("l", $type)>.  Returns TRUE if
1822 successful, or FALSE if there is an error.
1823
1824 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
1825
1826 Calls the System V IPC function msgrcv to receive a message from
1827 message queue ID into variable VAR with a maximum message size of
1828 SIZE.  Note that if a message is received, the message type will be the
1829 first thing in VAR, and the maximum length of VAR is SIZE plus the size
1830 of the message type.  Returns TRUE if successful, or FALSE if there is
1831 an error.
1832
1833 =item my EXPR
1834
1835 A "my" declares the listed variables to be local (lexically) to the
1836 enclosing block, subroutine, C<eval>, or C<do/require/use>'d file.  If
1837 more than one value is listed, the list must be placed in parentheses.  See
1838 L<perlsub/"Private Variables via my()"> for details.
1839
1840 =item next LABEL
1841
1842 =item next
1843
1844 The C<next> command is like the C<continue> statement in C; it starts
1845 the next iteration of the loop:
1846
1847     LINE: while (<STDIN>) {
1848         next LINE if /^#/;      # discard comments
1849         ...
1850     }
1851
1852 Note that if there were a C<continue> block on the above, it would get
1853 executed even on discarded lines.  If the LABEL is omitted, the command
1854 refers to the innermost enclosing loop.
1855
1856 =item no Module LIST
1857
1858 See the "use" function, which "no" is the opposite of.
1859
1860 =item oct EXPR
1861
1862 =item oct 
1863
1864 Interprets EXPR as an octal string and returns the corresponding
1865 value.  (If EXPR happens to start off with 0x, interprets it as
1866 a hex string instead.)  The following will handle decimal, octal, and
1867 hex in the standard Perl or C notation:
1868
1869     $val = oct($val) if $val =~ /^0/;
1870
1871 If EXPR is omitted, uses $_.  This function is commonly used when
1872 a string such as "644" needs to be converted into a file mode, for
1873 example. (Although perl will automatically convert strings into
1874 numbers as needed, this automatic conversion assumes base 10.)
1875
1876 =item open FILEHANDLE,EXPR
1877
1878 =item open FILEHANDLE
1879
1880 Opens the file whose filename is given by EXPR, and associates it with
1881 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
1882 name of the real filehandle wanted.  If EXPR is omitted, the scalar
1883 variable of the same name as the FILEHANDLE contains the filename.
1884 (Note that lexical variables--those declared with C<my>--will not work
1885 for this purpose; so if you're using C<my>, specify EXPR in your call
1886 to open.)
1887
1888 If the filename begins with '<' or nothing, the file is opened for input.
1889 If the filename begins with '>', the file is truncated and opened for
1890 output.  If the filename begins with '>>', the file is opened for
1891 appending.  You can put a '+' in front of the '>' or '<' to indicate that
1892 you want both read and write access to the file; thus '+<' is almost
1893 always preferred for read/write updates--the '+>' mode would clobber the
1894 file first.  The prefix and the filename may be separated with spaces.
1895 These various prefixes correspond to the fopen(3) modes of 'r', 'r+', 'w',
1896 'w+', 'a', and 'a+'.
1897
1898 If the filename begins with "|", the filename is interpreted as a command
1899 to which output is to be piped, and if the filename ends with a "|", the
1900 filename is interpreted See L<perlipc/"Using open() for IPC"> for more
1901 examples of this.  as command which pipes input to us.  (You may not have
1902 a raw open() to a command that pipes both in I<and> out, but see
1903 L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
1904 for alternatives.)
1905
1906 Opening '-' opens STDIN and opening 'E<gt>-' opens STDOUT.  Open returns
1907 non-zero upon success, the undefined value otherwise.  If the open
1908 involved a pipe, the return value happens to be the pid of the
1909 subprocess.  
1910
1911 If you're unfortunate enough to be running Perl on a system that
1912 distinguishes between text files and binary files (modern operating
1913 systems don't care), then you should check out L</binmode> for tips for
1914 dealing with this.  The key distinction between systems that need binmode
1915 and those that don't is their text file formats.  Systems like Unix and
1916 Plan9 that delimit lines with a single character, and that encode that
1917 character in C as '\n', do not need C<binmode>.  The rest need it.
1918
1919 Examples:
1920
1921     $ARTICLE = 100;
1922     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
1923     while (<ARTICLE>) {...
1924
1925     open(LOG, '>>/usr/spool/news/twitlog'); # (log is reserved)
1926
1927     open(DBASE, '+<dbase.mine');            # open for update
1928
1929     open(ARTICLE, "caesar <$article |");    # decrypt article
1930
1931     open(EXTRACT, "|sort >/tmp/Tmp$$");     # $$ is our process id
1932
1933     # process argument list of files along with any includes
1934
1935     foreach $file (@ARGV) {
1936         process($file, 'fh00');
1937     }
1938
1939     sub process {
1940         local($filename, $input) = @_;
1941         $input++;               # this is a string increment
1942         unless (open($input, $filename)) {
1943             print STDERR "Can't open $filename: $!\n";
1944             return;
1945         }
1946
1947         while (<$input>) {              # note use of indirection
1948             if (/^#include "(.*)"/) {
1949                 process($1, $input);
1950                 next;
1951             }
1952             ...         # whatever
1953         }
1954     }
1955
1956 You may also, in the Bourne shell tradition, specify an EXPR beginning
1957 with "E<gt>&", in which case the rest of the string is interpreted as the
1958 name of a filehandle (or file descriptor, if numeric) which is to be
1959 duped and opened.  You may use & after E<gt>, E<gt>E<gt>, E<lt>, +E<gt>,
1960 +E<gt>E<gt>, and +E<lt>.  The
1961 mode you specify should match the mode of the original filehandle.
1962 (Duping a filehandle does not take into account any existing contents of
1963 stdio buffers.)
1964 Here is a script that saves, redirects, and restores STDOUT and
1965 STDERR:
1966
1967     #!/usr/bin/perl
1968     open(SAVEOUT, ">&STDOUT");
1969     open(SAVEERR, ">&STDERR");
1970
1971     open(STDOUT, ">foo.out") || die "Can't redirect stdout";
1972     open(STDERR, ">&STDOUT") || die "Can't dup stdout";
1973
1974     select(STDERR); $| = 1;     # make unbuffered
1975     select(STDOUT); $| = 1;     # make unbuffered
1976
1977     print STDOUT "stdout 1\n";  # this works for
1978     print STDERR "stderr 1\n";  # subprocesses too
1979
1980     close(STDOUT);
1981     close(STDERR);
1982
1983     open(STDOUT, ">&SAVEOUT");
1984     open(STDERR, ">&SAVEERR");
1985
1986     print STDOUT "stdout 2\n";
1987     print STDERR "stderr 2\n";
1988
1989
1990 If you specify "E<lt>&=N", where N is a number, then Perl will do an
1991 equivalent of C's fdopen() of that file descriptor; this is more
1992 parsimonious of file descriptors.  For example:
1993
1994     open(FILEHANDLE, "<&=$fd")
1995
1996 If you open a pipe on the command "-", i.e., either "|-" or "-|", then
1997 there is an implicit fork done, and the return value of open is the pid
1998 of the child within the parent process, and 0 within the child
1999 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2000 The filehandle behaves normally for the parent, but i/o to that
2001 filehandle is piped from/to the STDOUT/STDIN of the child process.
2002 In the child process the filehandle isn't opened--i/o happens from/to
2003 the new STDOUT or STDIN.  Typically this is used like the normal
2004 piped open when you want to exercise more control over just how the
2005 pipe command gets executed, such as when you are running setuid, and
2006 don't want to have to scan shell commands for metacharacters.  
2007 The following pairs are more or less equivalent:
2008
2009     open(FOO, "|tr '[a-z]' '[A-Z]'");
2010     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
2011
2012     open(FOO, "cat -n '$file'|");
2013     open(FOO, "-|") || exec 'cat', '-n', $file;
2014
2015 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2016
2017 Explicitly closing any piped filehandle causes the parent process to
2018 wait for the child to finish, and returns the status value in C<$?>.
2019 Note: on any operation which may do a fork, unflushed buffers remain
2020 unflushed in both processes, which means you may need to set C<$|> to
2021 avoid duplicate output.
2022
2023 Using the constructor from the IO::Handle package (or one of its
2024 subclasses, such as IO::File or IO::Socket),
2025 you can generate anonymous filehandles which have the scope of whatever
2026 variables hold references to them, and automatically close whenever
2027 and however you leave that scope:
2028
2029     use IO::File;
2030     ...
2031     sub read_myfile_munged {
2032         my $ALL = shift;
2033         my $handle = new IO::File;
2034         open($handle, "myfile") or die "myfile: $!";
2035         $first = <$handle>
2036             or return ();     # Automatically closed here.
2037         mung $first or die "mung failed";       # Or here.
2038         return $first, <$handle> if $ALL;       # Or here.
2039         $first;                                 # Or here.
2040     }
2041
2042 The filename that is passed to open will have leading and trailing
2043 whitespace deleted.  To open a file with arbitrary weird
2044 characters in it, it's necessary to protect any leading and trailing
2045 whitespace thusly:
2046
2047     $file =~ s#^(\s)#./$1#;
2048     open(FOO, "< $file\0");
2049
2050 If you want a "real" C open() (see L<open(2)> on your system), then
2051 you should use the sysopen() function.  This is another way to
2052 protect your filenames from interpretation.  For example:
2053
2054     use IO::Handle;
2055     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL, 0700)
2056         or die "sysopen $path: $!";
2057     HANDLE->autoflush(1);
2058     HANDLE->print("stuff $$\n");
2059     seek(HANDLE, 0, 0);
2060     print "File contains: ", <HANDLE>;
2061
2062 See L</seek()> for some details about mixing reading and writing.
2063
2064 =item opendir DIRHANDLE,EXPR
2065
2066 Opens a directory named EXPR for processing by readdir(), telldir(),
2067 seekdir(), rewinddir(), and closedir().  Returns TRUE if successful.
2068 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2069
2070 =item ord EXPR
2071
2072 =item ord 
2073
2074 Returns the numeric ascii value of the first character of EXPR.  If
2075 EXPR is omitted, uses $_.  For the reverse, see L<chr>.
2076
2077 =item pack TEMPLATE,LIST
2078
2079 Takes an array or list of values and packs it into a binary structure,
2080 returning the string containing the structure.  The TEMPLATE is a
2081 sequence of characters that give the order and type of values, as
2082 follows:
2083
2084     A   An ascii string, will be space padded.
2085     a   An ascii string, will be null padded.
2086     b   A bit string (ascending bit order, like vec()).
2087     B   A bit string (descending bit order).
2088     h   A hex string (low nybble first).
2089     H   A hex string (high nybble first).
2090
2091     c   A signed char value.
2092     C   An unsigned char value.
2093     s   A signed short value.
2094     S   An unsigned short value.
2095     i   A signed integer value.
2096     I   An unsigned integer value.
2097     l   A signed long value.
2098     L   An unsigned long value.
2099
2100     n   A short in "network" order.
2101     N   A long in "network" order.
2102     v   A short in "VAX" (little-endian) order.
2103     V   A long in "VAX" (little-endian) order.
2104
2105     f   A single-precision float in the native format.
2106     d   A double-precision float in the native format.
2107
2108     p   A pointer to a null-terminated string.
2109     P   A pointer to a structure (fixed-length string).
2110
2111     u   A uuencoded string.
2112
2113     w A BER compressed integer.  Bytes give an unsigned integer base
2114       128, most significant digit first, with as few digits as
2115       possible, and with the bit 8 of each byte except the last set
2116       to "1."
2117
2118     x   A null byte.
2119     X   Back up a byte.
2120     @   Null fill to absolute position.
2121
2122 Each letter may optionally be followed by a number which gives a repeat
2123 count.  With all types except "a", "A", "b", "B", "h", "H", and "P" the
2124 pack function will gobble up that many values from the LIST.  A * for the
2125 repeat count means to use however many items are left.  The "a" and "A"
2126 types gobble just one value, but pack it as a string of length count,
2127 padding with nulls or spaces as necessary.  (When unpacking, "A" strips
2128 trailing spaces and nulls, but "a" does not.)  Likewise, the "b" and "B"
2129 fields pack a string that many bits long.  The "h" and "H" fields pack a
2130 string that many nybbles long.  The "P" packs a pointer to a structure of
2131 the size indicated by the length.  Real numbers (floats and doubles) are
2132 in the native machine format only; due to the multiplicity of floating
2133 formats around, and the lack of a standard "network" representation, no
2134 facility for interchange has been made.  This means that packed floating
2135 point data written on one machine may not be readable on another - even if
2136 both use IEEE floating point arithmetic (as the endian-ness of the memory
2137 representation is not part of the IEEE spec).  Note that Perl uses doubles
2138 internally for all numeric calculation, and converting from double into
2139 float and thence back to double again will lose precision (i.e.,
2140 C<unpack("f", pack("f", $foo)>) will not in general equal $foo).
2141
2142 Examples:
2143
2144     $foo = pack("cccc",65,66,67,68);
2145     # foo eq "ABCD"
2146     $foo = pack("c4",65,66,67,68);
2147     # same thing
2148
2149     $foo = pack("ccxxcc",65,66,67,68);
2150     # foo eq "AB\0\0CD"
2151
2152     $foo = pack("s2",1,2);
2153     # "\1\0\2\0" on little-endian
2154     # "\0\1\0\2" on big-endian
2155
2156     $foo = pack("a4","abcd","x","y","z");
2157     # "abcd"
2158
2159     $foo = pack("aaaa","abcd","x","y","z");
2160     # "axyz"
2161
2162     $foo = pack("a14","abcdefg");
2163     # "abcdefg\0\0\0\0\0\0\0"
2164
2165     $foo = pack("i9pl", gmtime);
2166     # a real struct tm (on my system anyway)
2167
2168     sub bintodec {
2169         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
2170     }
2171
2172 The same template may generally also be used in the unpack function.
2173
2174 =item package NAMESPACE
2175
2176 Declares the compilation unit as being in the given namespace.  The scope
2177 of the package declaration is from the declaration itself through the end of
2178 the enclosing block (the same scope as the local() operator).  All further
2179 unqualified dynamic identifiers will be in this namespace.  A package
2180 statement affects only dynamic variables--including those you've used
2181 local() on--but I<not> lexical variables created with my().  Typically it
2182 would be the first declaration in a file to be included by the C<require>
2183 or C<use> operator.  You can switch into a package in more than one place;
2184 it influences merely which symbol table is used by the compiler for the
2185 rest of that block.  You can refer to variables and filehandles in other
2186 packages by prefixing the identifier with the package name and a double
2187 colon:  C<$Package::Variable>.  If the package name is null, the C<main>
2188 package as assumed.  That is, C<$::sail> is equivalent to C<$main::sail>.
2189
2190 See L<perlmod/"Packages"> for more information about packages, modules,
2191 and classes.  See L<perlsub> for other scoping issues.
2192
2193 =item pipe READHANDLE,WRITEHANDLE
2194
2195 Opens a pair of connected pipes like the corresponding system call.
2196 Note that if you set up a loop of piped processes, deadlock can occur
2197 unless you are very careful.  In addition, note that Perl's pipes use
2198 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
2199 after each command, depending on the application.
2200
2201 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
2202 for examples of such things.
2203
2204 =item pop ARRAY
2205
2206 =item pop 
2207
2208 Pops and returns the last value of the array, shortening the array by
2209 1.  Has a similar effect to
2210
2211     $tmp = $ARRAY[$#ARRAY--];
2212
2213 If there are no elements in the array, returns the undefined value.
2214 If ARRAY is omitted, pops the
2215 @ARGV array in the main program, and the @_ array in subroutines, just
2216 like shift().
2217
2218 =item pos SCALAR
2219
2220 =item pos 
2221
2222 Returns the offset of where the last C<m//g> search left off for the variable
2223 is in question ($_ is used when the variable is not specified).  May be
2224 modified to change that offset.  Such modification will also influence
2225 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
2226 L<perlop>.
2227
2228 =item print FILEHANDLE LIST
2229
2230 =item print LIST
2231
2232 =item print
2233
2234 Prints a string or a comma-separated list of strings.  Returns TRUE
2235 if successful.  FILEHANDLE may be a scalar variable name, in which case
2236 the variable contains the name of or a reference to the filehandle, thus introducing one
2237 level of indirection.  (NOTE: If FILEHANDLE is a variable and the next
2238 token is a term, it may be misinterpreted as an operator unless you
2239 interpose a + or put parentheses around the arguments.)  If FILEHANDLE is
2240 omitted, prints by default to standard output (or to the last selected
2241 output channel--see L</select>).  If LIST is also omitted, prints $_ to
2242 STDOUT.  To set the default output channel to something other than
2243 STDOUT use the select operation.  Note that, because print takes a
2244 LIST, anything in the LIST is evaluated in a list context, and any
2245 subroutine that you call will have one or more of its expressions
2246 evaluated in a list context.  Also be careful not to follow the print
2247 keyword with a left parenthesis unless you want the corresponding right
2248 parenthesis to terminate the arguments to the print--interpose a + or
2249 put parentheses around all the arguments.
2250
2251 Note that if you're storing FILEHANDLES in an array or other expression,
2252 you will have to use a block returning its value instead:
2253
2254     print { $files[$i] } "stuff\n";
2255     print { $OK ? STDOUT : STDERR } "stuff\n";
2256
2257 =item printf FILEHANDLE FORMAT, LIST
2258
2259 =item printf FORMAT, LIST
2260
2261 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>.  The first argument
2262 of the list will be interpreted as the printf format.  If C<use locale> is
2263 in effect, the character used for the decimal point in formatted real numbers
2264 is affected by the LC_NUMERIC locale.  See L<perllocale>.
2265
2266 Don't fall into the trap of using a printf() when a simple
2267 print() would do.  The print() is more efficient, and less
2268 error prone.
2269
2270 =item prototype FUNCTION
2271
2272 Returns the prototype of a function as a string (or C<undef> if the
2273 function has no prototype).  FUNCTION is a reference to, or the name of,
2274 the function whose prototype you want to retrieve.
2275
2276 =item push ARRAY,LIST
2277
2278 Treats ARRAY as a stack, and pushes the values of LIST
2279 onto the end of ARRAY.  The length of ARRAY increases by the length of
2280 LIST.  Has the same effect as
2281
2282     for $value (LIST) {
2283         $ARRAY[++$#ARRAY] = $value;
2284     }
2285
2286 but is more efficient.  Returns the new number of elements in the array.
2287
2288 =item q/STRING/
2289
2290 =item qq/STRING/
2291
2292 =item qx/STRING/
2293
2294 =item qw/STRING/
2295
2296 Generalized quotes.  See L<perlop>.
2297
2298 =item quotemeta EXPR
2299
2300 =item quotemeta 
2301
2302 Returns the value of EXPR with with all non-alphanumeric
2303 characters backslashed.  (That is, all characters not matching
2304 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
2305 returned string, regardless of any locale settings.)
2306 This is the internal function implementing
2307 the \Q escape in double-quoted strings.
2308
2309 If EXPR is omitted, uses $_.
2310
2311 =item rand EXPR
2312
2313 =item rand
2314
2315 Returns a random fractional number between 0 and the value of EXPR.
2316 (EXPR should be positive.)  If EXPR is omitted, returns a value between 
2317 0 and 1.  Automatically calls srand() unless srand() has already been
2318 called.  See also srand().
2319
2320 (Note: If your rand function consistently returns numbers that are too
2321 large or too small, then your version of Perl was probably compiled
2322 with the wrong number of RANDBITS.)
2323
2324 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
2325
2326 =item read FILEHANDLE,SCALAR,LENGTH
2327
2328 Attempts to read LENGTH bytes of data into variable SCALAR from the
2329 specified FILEHANDLE.  Returns the number of bytes actually read, or
2330 undef if there was an error.  SCALAR will be grown or shrunk to the
2331 length actually read.  An OFFSET may be specified to place the read
2332 data at some other place than the beginning of the string.  This call
2333 is actually implemented in terms of stdio's fread call.  To get a true
2334 read system call, see sysread().
2335
2336 =item readdir DIRHANDLE
2337
2338 Returns the next directory entry for a directory opened by opendir().
2339 If used in a list context, returns all the rest of the entries in the
2340 directory.  If there are no more entries, returns an undefined value in
2341 a scalar context or a null list in a list context.
2342
2343 If you're planning to filetest the return values out of a readdir(), you'd
2344 better prepend the directory in question.  Otherwise, because we didn't
2345 chdir() there, it would have been testing the wrong file.
2346
2347     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
2348     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
2349     closedir DIR;
2350
2351 =item readlink EXPR
2352
2353 =item readlink 
2354
2355 Returns the value of a symbolic link, if symbolic links are
2356 implemented.  If not, gives a fatal error.  If there is some system
2357 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
2358 omitted, uses $_.
2359
2360 =item recv SOCKET,SCALAR,LEN,FLAGS
2361
2362 Receives a message on a socket.  Attempts to receive LENGTH bytes of
2363 data into variable SCALAR from the specified SOCKET filehandle.
2364 Actually does a C recvfrom(), so that it can returns the address of the
2365 sender.  Returns the undefined value if there's an error.  SCALAR will
2366 be grown or shrunk to the length actually read.  Takes the same flags
2367 as the system call of the same name.  
2368 See L<perlipc/"UDP: Message Passing"> for examples.
2369
2370 =item redo LABEL
2371
2372 =item redo
2373
2374 The C<redo> command restarts the loop block without evaluating the
2375 conditional again.  The C<continue> block, if any, is not executed.  If
2376 the LABEL is omitted, the command refers to the innermost enclosing
2377 loop.  This command is normally used by programs that want to lie to
2378 themselves about what was just input:
2379
2380     # a simpleminded Pascal comment stripper
2381     # (warning: assumes no { or } in strings)
2382     LINE: while (<STDIN>) {
2383         while (s|({.*}.*){.*}|$1 |) {}
2384         s|{.*}| |;
2385         if (s|{.*| |) {
2386             $front = $_;
2387             while (<STDIN>) {
2388                 if (/}/) {      # end of comment?
2389                     s|^|$front{|;
2390                     redo LINE;
2391                 }
2392             }
2393         }
2394         print;
2395     }
2396
2397 =item ref EXPR
2398
2399 =item ref 
2400
2401 Returns a TRUE value if EXPR is a reference, FALSE otherwise.  If EXPR
2402 is not specified, $_ will be used.  The value returned depends on the
2403 type of thing the reference is a reference to.
2404 Builtin types include:
2405
2406     REF
2407     SCALAR
2408     ARRAY
2409     HASH
2410     CODE
2411     GLOB
2412
2413 If the referenced object has been blessed into a package, then that package 
2414 name is returned instead.  You can think of ref() as a typeof() operator.
2415
2416     if (ref($r) eq "HASH") {
2417         print "r is a reference to a hash.\n";
2418     } 
2419     if (!ref ($r) {
2420         print "r is not a reference at all.\n";
2421     } 
2422
2423 See also L<perlref>.
2424
2425 =item rename OLDNAME,NEWNAME
2426
2427 Changes the name of a file.  Returns 1 for success, 0 otherwise.  Will
2428 not work across file system boundaries.
2429
2430 =item require EXPR
2431
2432 =item require
2433
2434 Demands some semantics specified by EXPR, or by $_ if EXPR is not
2435 supplied.  If EXPR is numeric, demands that the current version of Perl
2436 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
2437
2438 Otherwise, demands that a library file be included if it hasn't already
2439 been included.  The file is included via the do-FILE mechanism, which is
2440 essentially just a variety of eval().  Has semantics similar to the following
2441 subroutine:
2442
2443     sub require {
2444         local($filename) = @_;
2445         return 1 if $INC{$filename};
2446         local($realfilename,$result);
2447         ITER: {
2448             foreach $prefix (@INC) {
2449                 $realfilename = "$prefix/$filename";
2450                 if (-f $realfilename) {
2451                     $result = do $realfilename;
2452                     last ITER;
2453                 }
2454             }
2455             die "Can't find $filename in \@INC";
2456         }
2457         die $@ if $@;
2458         die "$filename did not return true value" unless $result;
2459         $INC{$filename} = $realfilename;
2460         $result;
2461     }
2462
2463 Note that the file will not be included twice under the same specified
2464 name.  The file must return TRUE as the last statement to indicate
2465 successful execution of any initialization code, so it's customary to
2466 end such a file with "1;" unless you're sure it'll return TRUE
2467 otherwise.  But it's better just to put the "C<1;>", in case you add more
2468 statements.
2469
2470 If EXPR is a bare word, the require assumes a "F<.pm>" extension and
2471 replaces "F<::>" with "F</>" in the filename for you,
2472 to make it easy to load standard modules.  This form of loading of 
2473 modules does not risk altering your namespace.
2474
2475 For a yet-more-powerful import facility, see L</use> and 
2476 L<perlmod>.
2477
2478 =item reset EXPR
2479
2480 =item reset
2481
2482 Generally used in a C<continue> block at the end of a loop to clear
2483 variables and reset ?? searches so that they work again.  The
2484 expression is interpreted as a list of single characters (hyphens
2485 allowed for ranges).  All variables and arrays beginning with one of
2486 those letters are reset to their pristine state.  If the expression is
2487 omitted, one-match searches (?pattern?) are reset to match again.  Resets
2488 only variables or searches in the current package.  Always returns
2489 1.  Examples:
2490
2491     reset 'X';          # reset all X variables
2492     reset 'a-z';        # reset lower case variables
2493     reset;              # just reset ?? searches
2494
2495 Resetting "A-Z" is not recommended because you'll wipe out your
2496 ARGV and ENV arrays.  Resets only package variables--lexical variables
2497 are unaffected, but they clean themselves up on scope exit anyway,
2498 so you'll probably want to use them instead.  See L</my>.
2499
2500 =item return LIST
2501
2502 Returns from a subroutine or eval with the value specified.  (Note that
2503 in the absence of a return a subroutine or eval() will automatically
2504 return the value of the last expression evaluated.)
2505
2506 =item reverse LIST
2507
2508 In a list context, returns a list value consisting of the elements
2509 of LIST in the opposite order.  In a scalar context, concatenates the
2510 elements of LIST, and returns a string value consisting of those bytes,
2511 but in the opposite order.
2512
2513     print reverse <>;           # line tac, last line first
2514
2515     undef $/;                   # for efficiency of <>
2516     print scalar reverse <>;    # byte tac, last line tsrif
2517
2518 This operator is also handy for inverting a hash, although there are some
2519 caveats.  If a value is duplicated in the original hash, only one of those
2520 can be represented as a key in the inverted hash.  Also, this has to
2521 unwind one hash and build a whole new one, which may take some time
2522 on a large hash.
2523
2524     %by_name = reverse %by_address;     # Invert the hash
2525
2526 =item rewinddir DIRHANDLE
2527
2528 Sets the current position to the beginning of the directory for the
2529 readdir() routine on DIRHANDLE.
2530
2531 =item rindex STR,SUBSTR,POSITION
2532
2533 =item rindex STR,SUBSTR
2534
2535 Works just like index except that it returns the position of the LAST
2536 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
2537 last occurrence at or before that position.
2538
2539 =item rmdir FILENAME
2540
2541 =item rmdir 
2542
2543 Deletes the directory specified by FILENAME if it is empty.  If it
2544 succeeds it returns 1, otherwise it returns 0 and sets C<$!> (errno).  If
2545 FILENAME is omitted, uses $_.
2546
2547 =item s///
2548
2549 The substitution operator.  See L<perlop>.
2550
2551 =item scalar EXPR
2552
2553 Forces EXPR to be interpreted in a scalar context and returns the value
2554 of EXPR.  
2555
2556     @counts = ( scalar @a, scalar @b, scalar @c );
2557
2558 There is no equivalent operator to force an expression to 
2559 be interpolated in a list context because it's in practice never
2560 needed.  If you really wanted to do so, however, you could use
2561 the construction C<@{[ (some expression) ]}>, but usually a simple
2562 C<(some expression)> suffices.
2563
2564 =item seek FILEHANDLE,POSITION,WHENCE
2565
2566 Randomly positions the file pointer for FILEHANDLE, just like the fseek()
2567 call of stdio.  FILEHANDLE may be an expression whose value gives the name
2568 of the filehandle.  The values for WHENCE are 0 to set the file pointer to
2569 POSITION, 1 to set the it to current plus POSITION, and 2 to set it to EOF
2570 plus offset.  You may use the values SEEK_SET, SEEK_CUR, and SEEK_END for
2571 this from POSIX module.  Returns 1 upon success, 0 otherwise.
2572
2573 On some systems you have to do a seek whenever you switch between reading
2574 and writing.  Amongst other things, this may have the effect of calling
2575 stdio's clearerr(3).  A "whence" of 1 (SEEK_CUR) is useful for not moving
2576 the file pointer:
2577
2578     seek(TEST,0,1);
2579
2580 This is also useful for applications emulating C<tail -f>.  Once you hit
2581 EOF on your read, and then sleep for a while, you might have to stick in a
2582 seek() to reset things.  First the simple trick listed above to clear the
2583 filepointer.  The seek() doesn't change the current position, but it
2584 I<does> clear the end-of-file condition on the handle, so that the next
2585 C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
2586
2587 If that doesn't work (some stdios are particularly cantankerous), then
2588 you may need something more like this:
2589
2590     for (;;) {
2591         for ($curpos = tell(FILE); $_ = <FILE>; $curpos = tell(FILE)) {
2592             # search for some stuff and put it into files
2593         }
2594         sleep($for_a_while);
2595         seek(FILE, $curpos, 0);
2596     }
2597
2598 =item seekdir DIRHANDLE,POS
2599
2600 Sets the current position for the readdir() routine on DIRHANDLE.  POS
2601 must be a value returned by telldir().  Has the same caveats about
2602 possible directory compaction as the corresponding system library
2603 routine.
2604
2605 =item select FILEHANDLE
2606
2607 =item select
2608
2609 Returns the currently selected filehandle.  Sets the current default
2610 filehandle for output, if FILEHANDLE is supplied.  This has two
2611 effects: first, a C<write> or a C<print> without a filehandle will
2612 default to this FILEHANDLE.  Second, references to variables related to
2613 output will refer to this output channel.  For example, if you have to
2614 set the top of form format for more than one output channel, you might
2615 do the following:
2616
2617     select(REPORT1);
2618     $^ = 'report1_top';
2619     select(REPORT2);
2620     $^ = 'report2_top';
2621
2622 FILEHANDLE may be an expression whose value gives the name of the
2623 actual filehandle.  Thus:
2624
2625     $oldfh = select(STDERR); $| = 1; select($oldfh);
2626
2627 Some programmers may prefer to think of filehandles as objects with
2628 methods, preferring to write the last example as:
2629
2630     use IO::Handle;
2631     STDERR->autoflush(1);
2632
2633 =item select RBITS,WBITS,EBITS,TIMEOUT
2634
2635 This calls the select(2) system call with the bit masks specified, which
2636 can be constructed using fileno() and vec(), along these lines:
2637
2638     $rin = $win = $ein = '';
2639     vec($rin,fileno(STDIN),1) = 1;
2640     vec($win,fileno(STDOUT),1) = 1;
2641     $ein = $rin | $win;
2642
2643 If you want to select on many filehandles you might wish to write a
2644 subroutine:
2645
2646     sub fhbits {
2647         local(@fhlist) = split(' ',$_[0]);
2648         local($bits);
2649         for (@fhlist) {
2650             vec($bits,fileno($_),1) = 1;
2651         }
2652         $bits;
2653     }
2654     $rin = fhbits('STDIN TTY SOCK');
2655
2656 The usual idiom is:
2657
2658     ($nfound,$timeleft) =
2659       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
2660
2661 or to block until something becomes ready just do this 
2662
2663     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
2664
2665 Most systems do not bother to return anything useful in $timeleft, so
2666 calling select() in a scalar context just returns $nfound.
2667
2668 Any of the bit masks can also be undef.  The timeout, if specified, is
2669 in seconds, which may be fractional.  Note: not all implementations are
2670 capable of returning the $timeleft.  If not, they always return
2671 $timeleft equal to the supplied $timeout.
2672
2673 You can effect a sleep of 250 milliseconds this way:
2674
2675     select(undef, undef, undef, 0.25);
2676
2677 B<WARNING>: Do not attempt to mix buffered I/O (like read() or E<lt>FHE<gt>)
2678 with select().  You have to use sysread() instead.
2679
2680 =item semctl ID,SEMNUM,CMD,ARG
2681
2682 Calls the System V IPC function semctl.  If CMD is &IPC_STAT or
2683 &GETALL, then ARG must be a variable which will hold the returned
2684 semid_ds structure or semaphore value array.  Returns like ioctl: the
2685 undefined value for error, "0 but true" for zero, or the actual return
2686 value otherwise.
2687
2688 =item semget KEY,NSEMS,FLAGS
2689
2690 Calls the System V IPC function semget.  Returns the semaphore id, or
2691 the undefined value if there is an error.
2692
2693 =item semop KEY,OPSTRING
2694
2695 Calls the System V IPC function semop to perform semaphore operations
2696 such as signaling and waiting.  OPSTRING must be a packed array of
2697 semop structures.  Each semop structure can be generated with
2698 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
2699 operations is implied by the length of OPSTRING.  Returns TRUE if
2700 successful, or FALSE if there is an error.  As an example, the
2701 following code waits on semaphore $semnum of semaphore id $semid:
2702
2703     $semop = pack("sss", $semnum, -1, 0);
2704     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
2705
2706 To signal the semaphore, replace "-1" with "1".
2707
2708 =item send SOCKET,MSG,FLAGS,TO
2709
2710 =item send SOCKET,MSG,FLAGS
2711
2712 Sends a message on a socket.  Takes the same flags as the system call
2713 of the same name.  On unconnected sockets you must specify a
2714 destination to send TO, in which case it does a C sendto().  Returns
2715 the number of characters sent, or the undefined value if there is an
2716 error.
2717 See L<perlipc/"UDP: Message Passing"> for examples.
2718
2719 =item setpgrp PID,PGRP
2720
2721 Sets the current process group for the specified PID, 0 for the current
2722 process.  Will produce a fatal error if used on a machine that doesn't
2723 implement setpgrp(2).  If the arguments are omitted, it defaults to
2724 0,0.  Note that the POSIX version of setpgrp() does not accept any
2725 arguments, so only setpgrp 0,0 is portable.
2726
2727 =item setpriority WHICH,WHO,PRIORITY
2728
2729 Sets the current priority for a process, a process group, or a user.
2730 (See setpriority(2).)  Will produce a fatal error if used on a machine
2731 that doesn't implement setpriority(2).
2732
2733 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
2734
2735 Sets the socket option requested.  Returns undefined if there is an
2736 error.  OPTVAL may be specified as undef if you don't want to pass an
2737 argument.
2738
2739 =item shift ARRAY
2740
2741 =item shift
2742
2743 Shifts the first value of the array off and returns it, shortening the
2744 array by 1 and moving everything down.  If there are no elements in the
2745 array, returns the undefined value.  If ARRAY is omitted, shifts the
2746 @ARGV array in the main program, and the @_ array in subroutines.
2747 (This is determined lexically.)  See also unshift(), push(), and pop().
2748 Shift() and unshift() do the same thing to the left end of an array
2749 that pop() and push() do to the right end.
2750
2751 =item shmctl ID,CMD,ARG
2752
2753 Calls the System V IPC function shmctl.  If CMD is &IPC_STAT, then ARG
2754 must be a variable which will hold the returned shmid_ds structure.
2755 Returns like ioctl: the undefined value for error, "0 but true" for
2756 zero, or the actual return value otherwise.
2757
2758 =item shmget KEY,SIZE,FLAGS
2759
2760 Calls the System V IPC function shmget.  Returns the shared memory
2761 segment id, or the undefined value if there is an error.
2762
2763 =item shmread ID,VAR,POS,SIZE
2764
2765 =item shmwrite ID,STRING,POS,SIZE
2766
2767 Reads or writes the System V shared memory segment ID starting at
2768 position POS for size SIZE by attaching to it, copying in/out, and
2769 detaching from it.  When reading, VAR must be a variable which will
2770 hold the data read.  When writing, if STRING is too long, only SIZE
2771 bytes are used; if STRING is too short, nulls are written to fill out
2772 SIZE bytes.  Return TRUE if successful, or FALSE if there is an error.
2773
2774 =item shutdown SOCKET,HOW
2775
2776 Shuts down a socket connection in the manner indicated by HOW, which
2777 has the same interpretation as in the system call of the same name.
2778
2779 =item sin EXPR
2780
2781 =item sin 
2782
2783 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
2784 returns sine of $_.
2785
2786 For the inverse sine operation, you may use the POSIX::sin()
2787 function, or use this relation:
2788
2789     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
2790
2791 =item sleep EXPR
2792
2793 =item sleep
2794
2795 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
2796 May be interrupted by sending the process a SIGALRM.  Returns the
2797 number of seconds actually slept.  You probably cannot mix alarm() and
2798 sleep() calls, because sleep() is often implemented using alarm().
2799
2800 On some older systems, it may sleep up to a full second less than what
2801 you requested, depending on how it counts seconds.  Most modern systems
2802 always sleep the full amount.
2803
2804 For delays of finer granularity than one second, you may use Perl's
2805 syscall() interface to access setitimer(2) if your system supports it, 
2806 or else see L</select()> below.  
2807
2808 See also the POSIX module's sigpause() function.
2809
2810 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
2811
2812 Opens a socket of the specified kind and attaches it to filehandle
2813 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for the
2814 system call of the same name.  You should "use Socket;" first to get
2815 the proper definitions imported.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
2816
2817 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
2818
2819 Creates an unnamed pair of sockets in the specified domain, of the
2820 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
2821 for the system call of the same name.  If unimplemented, yields a fatal
2822 error.  Returns TRUE if successful.
2823
2824 =item sort SUBNAME LIST
2825
2826 =item sort BLOCK LIST
2827
2828 =item sort LIST
2829
2830 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
2831 is omitted, sorts in standard string comparison order.  If SUBNAME is
2832 specified, it gives the name of a subroutine that returns an integer
2833 less than, equal to, or greater than 0, depending on how the elements
2834 of the array are to be ordered.  (The C<E<lt>=E<gt>> and C<cmp>
2835 operators are extremely useful in such routines.)  SUBNAME may be a
2836 scalar variable name, in which case the value provides the name of the
2837 subroutine to use.  In place of a SUBNAME, you can provide a BLOCK as
2838 an anonymous, in-line sort subroutine.
2839
2840 In the interests of efficiency the normal calling code for subroutines is
2841 bypassed, with the following effects: the subroutine may not be a
2842 recursive subroutine, and the two elements to be compared are passed into
2843 the subroutine not via @_ but as the package global variables $a and
2844 $b (see example below).  They are passed by reference, so don't
2845 modify $a and $b.  And don't try to declare them as lexicals either.
2846
2847 You also cannot exit out of the sort block or subroutine using any of the
2848 loop control operators described in L<perlsyn> or with goto().
2849
2850 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
2851 current collation locale.  See L<perllocale>.
2852
2853 Examples:
2854
2855     # sort lexically
2856     @articles = sort @files;
2857
2858     # same thing, but with explicit sort routine
2859     @articles = sort {$a cmp $b} @files;
2860
2861     # now case-insensitively
2862     @articles = sort { uc($a) cmp uc($b)} @files;
2863
2864     # same thing in reversed order
2865     @articles = sort {$b cmp $a} @files;
2866
2867     # sort numerically ascending
2868     @articles = sort {$a <=> $b} @files;
2869
2870     # sort numerically descending
2871     @articles = sort {$b <=> $a} @files;
2872
2873     # sort using explicit subroutine name
2874     sub byage {
2875         $age{$a} <=> $age{$b};  # presuming numeric
2876     }
2877     @sortedclass = sort byage @class;
2878
2879     # this sorts the %age hash by value instead of key
2880     # using an in-line function
2881     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
2882
2883     sub backwards { $b cmp $a; }
2884     @harry = ('dog','cat','x','Cain','Abel');
2885     @george = ('gone','chased','yz','Punished','Axed');
2886     print sort @harry;
2887             # prints AbelCaincatdogx
2888     print sort backwards @harry;
2889             # prints xdogcatCainAbel
2890     print sort @george, 'to', @harry;
2891             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
2892
2893     # inefficiently sort by descending numeric compare using 
2894     # the first integer after the first = sign, or the 
2895     # whole record case-insensitively otherwise
2896
2897     @new = sort {
2898         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
2899                             ||
2900                     uc($a)  cmp  uc($b)
2901     } @old;
2902
2903     # same thing, but much more efficiently;
2904     # we'll build auxiliary indices instead
2905     # for speed
2906     @nums = @caps = ();
2907     for (@old) { 
2908         push @nums, /=(\d+)/;
2909         push @caps, uc($_);
2910     } 
2911
2912     @new = @old[ sort {
2913                         $nums[$b] <=> $nums[$a]
2914                                  ||
2915                         $caps[$a] cmp $caps[$b]
2916                        } 0..$#old
2917                ];
2918
2919     # same thing using a Schwartzian Transform (no temps)
2920     @new = map { $_->[0] }
2921         sort { $b->[1] <=> $a->[1]
2922                         ||
2923                $a->[2] cmp $b->[2]
2924         } map { [$_, /=(\d+)/, uc($_)] } @old;
2925
2926 If you're using strict, you I<MUST NOT> declare $a
2927 and $b as lexicals.  They are package globals.  That means
2928 if you're in the C<main> package, it's
2929
2930     @articles = sort {$main::b <=> $main::a} @files;
2931
2932 or just
2933
2934     @articles = sort {$::b <=> $::a} @files;
2935
2936 but if you're in the C<FooPack> package, it's
2937
2938     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
2939
2940 The comparison function is required to behave.  If it returns
2941 inconsistent results (sometimes saying $x[1] is less than $x[2] and
2942 sometimes saying the opposite, for example) the Perl interpreter will
2943 probably crash and dump core.  This is entirely due to and dependent
2944 upon your system's qsort(3) library routine; this routine often avoids
2945 sanity checks in the interest of speed.
2946
2947 =item splice ARRAY,OFFSET,LENGTH,LIST
2948
2949 =item splice ARRAY,OFFSET,LENGTH
2950
2951 =item splice ARRAY,OFFSET
2952
2953 Removes the elements designated by OFFSET and LENGTH from an array, and
2954 replaces them with the elements of LIST, if any.  Returns the elements
2955 removed from the array.  The array grows or shrinks as necessary.  If
2956 LENGTH is omitted, removes everything from OFFSET onward.  The
2957 following equivalences hold (assuming C<$[ == 0>):
2958
2959     push(@a,$x,$y)      splice(@a,$#a+1,0,$x,$y)
2960     pop(@a)             splice(@a,-1)
2961     shift(@a)           splice(@a,0,1)
2962     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
2963     $a[$x] = $y         splice(@a,$x,1,$y);
2964
2965 Example, assuming array lengths are passed before arrays:
2966
2967     sub aeq {   # compare two list values
2968         local(@a) = splice(@_,0,shift);
2969         local(@b) = splice(@_,0,shift);
2970         return 0 unless @a == @b;       # same len?
2971         while (@a) {
2972             return 0 if pop(@a) ne pop(@b);
2973         }
2974         return 1;
2975     }
2976     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
2977
2978 =item split /PATTERN/,EXPR,LIMIT
2979
2980 =item split /PATTERN/,EXPR
2981
2982 =item split /PATTERN/
2983
2984 =item split
2985
2986 Splits a string into an array of strings, and returns it.
2987
2988 If not in a list context, returns the number of fields found and splits into
2989 the @_ array.  (In a list context, you can force the split into @_ by
2990 using C<??> as the pattern delimiters, but it still returns the array
2991 value.)  The use of implicit split to @_ is deprecated, however.
2992
2993 If EXPR is omitted, splits the $_ string.  If PATTERN is also omitted,
2994 splits on whitespace (after skipping any leading whitespace).  Anything
2995 matching PATTERN is taken to be a delimiter separating the fields.  (Note
2996 that the delimiter may be longer than one character.)  If LIMIT is
2997 specified and is not negative, splits into no more than that many fields
2998 (though it may split into fewer).  If LIMIT is unspecified, trailing null
2999 fields are stripped (which potential users of pop() would do well to
3000 remember).  If LIMIT is negative, it is treated as if an arbitrarily large
3001 LIMIT had been specified.
3002
3003 A pattern matching the null string (not to be confused with
3004 a null pattern C<//>, which is just one member of the set of patterns
3005 matching a null string) will split the value of EXPR into separate
3006 characters at each point it matches that way.  For example:
3007
3008     print join(':', split(/ */, 'hi there'));
3009
3010 produces the output 'h:i:t:h:e:r:e'.
3011
3012 The LIMIT parameter can be used to split a line partially
3013
3014     ($login, $passwd, $remainder) = split(/:/, $_, 3);
3015
3016 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
3017 one larger than the number of variables in the list, to avoid
3018 unnecessary work.  For the list above LIMIT would have been 4 by
3019 default.  In time critical applications it behooves you not to split
3020 into more fields than you really need.
3021
3022 If the PATTERN contains parentheses, additional array elements are
3023 created from each matching substring in the delimiter.
3024
3025     split(/([,-])/, "1-10,20", 3);
3026
3027 produces the list value
3028
3029     (1, '-', 10, ',', 20)
3030
3031 If you had the entire header of a normal Unix email message in $header, 
3032 you could split it up into fields and their values this way:
3033
3034     $header =~ s/\n\s+/ /g;  # fix continuation lines
3035     %hdrs   =  (UNIX_FROM => split /^(.*?):\s*/m, $header);
3036
3037 The pattern C</PATTERN/> may be replaced with an expression to specify
3038 patterns that vary at runtime.  (To do runtime compilation only once,
3039 use C</$variable/o>.)
3040
3041 As a special case, specifying a PATTERN of space (C<' '>) will split on
3042 white space just as split with no arguments does.  Thus, split(' ') can
3043 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
3044 will give you as many null initial fields as there are leading spaces.
3045 A split on /\s+/ is like a split(' ') except that any leading
3046 whitespace produces a null first field.  A split with no arguments
3047 really does a C<split(' ', $_)> internally.
3048
3049 Example:
3050
3051     open(passwd, '/etc/passwd');
3052     while (<passwd>) {
3053         ($login, $passwd, $uid, $gid, $gcos, 
3054             $home, $shell) = split(/:/);
3055         ...
3056     }
3057
3058 (Note that $shell above will still have a newline on it.  See L</chop>, 
3059 L</chomp>, and L</join>.)
3060
3061 =item sprintf FORMAT, LIST
3062
3063 Returns a string formatted by the usual printf conventions of the C
3064 language.  See L<sprintf(3)> or L<printf(3)> on your system for details.
3065 (The * character for an indirectly specified length is not
3066 supported, but you can get the same effect by interpolating a variable
3067 into the pattern.)  If C<use locale> is
3068 in effect, the character used for the decimal point in formatted real numbers
3069 is affected by the LC_NUMERIC locale.  See L<perllocale>.
3070 Some C libraries' implementations of sprintf() can
3071 dump core when fed ludicrous arguments.
3072
3073 =item sqrt EXPR
3074
3075 =item sqrt 
3076
3077 Return the square root of EXPR.  If EXPR is omitted, returns square
3078 root of $_.
3079
3080 =item srand EXPR
3081
3082 =item srand
3083
3084 Sets the random number seed for the C<rand> operator.  If EXPR is
3085 omitted, uses a semi-random value based on the current time and process
3086 ID, among other things.  In versions of Perl prior to 5.004 the default
3087 seed was just the current time().  This isn't a particularly good seed,
3088 so many old programs supply their own seed value (often C<time ^ $$> or
3089 C<time ^ ($$ + ($$ << 15))>), but that isn't necessary any more.
3090
3091 In fact, it's usually not necessary to call srand() at all, because if
3092 it is not called explicitly, it is called implicitly at the first use of
3093 the C<rand> operator.  However, this was not the case in version of Perl
3094 before 5.004, so if your script will run under older Perl versions, it
3095 should call srand().
3096
3097 Note that you need something much more random than the default seed for
3098 cryptographic purposes.  Checksumming the compressed output of one or more
3099 rapidly changing operating system status programs is the usual method.  For
3100 example:
3101
3102     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
3103
3104 If you're particularly concerned with this, see the Math::TrulyRandom
3105 module in CPAN.
3106
3107 Do I<not> call srand() multiple times in your program unless you know
3108 exactly what you're doing and why you're doing it.  The point of the
3109 function is to "seed" the rand() function so that rand() can produce
3110 a different sequence each time you run your program.  Just do it once at the
3111 top of your program, or you I<won't> get random numbers out of rand()!
3112
3113 Frequently called programs (like CGI scripts) that simply use 
3114
3115     time ^ $$
3116
3117 for a seed can fall prey to the mathematical property that 
3118
3119     a^b == (a+1)^(b+1)
3120
3121 one-third of the time.  So don't do that.
3122
3123 =item stat FILEHANDLE
3124
3125 =item stat EXPR
3126
3127 =item stat 
3128
3129 Returns a 13-element array giving the status info for a file, either the
3130 file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted, it
3131 stats $_.  Returns a null list if the stat fails.  Typically used as
3132 follows:
3133
3134
3135     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
3136        $atime,$mtime,$ctime,$blksize,$blocks)
3137            = stat($filename);
3138
3139 Not all fields are supported on all filesystem types.  Here are the 
3140 meaning of the fields:
3141
3142   dev       device number of filesystem 
3143   ino       inode number 
3144   mode      file mode  (type and permissions)
3145   nlink     number of (hard) links to the file 
3146   uid       numeric user ID of file's owner 
3147   gid       numeric group ID of file's owner 
3148   rdev      the device identifier (special files only)
3149   size      total size of file, in bytes 
3150   atime     last access time since the epoch
3151   mtime     last modify time since the epoch
3152   ctime     inode change time (NOT creation time!) since the epoch
3153   blksize   preferred block size for file system I/O
3154   blocks    actual number of blocks allocated
3155
3156 (The epoch was at 00:00 January 1, 1970 GMT.)
3157
3158 If stat is passed the special filehandle consisting of an underline, no
3159 stat is done, but the current contents of the stat structure from the
3160 last stat or filetest are returned.  Example:
3161
3162     if (-x $file && (($d) = stat(_)) && $d < 0) {
3163         print "$file is executable NFS file\n";
3164     }
3165
3166 (This works on machines only for which the device number is negative under NFS.)
3167
3168 =item study SCALAR
3169
3170 =item study
3171
3172 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
3173 doing many pattern matches on the string before it is next modified.
3174 This may or may not save time, depending on the nature and number of
3175 patterns you are searching on, and on the distribution of character
3176 frequencies in the string to be searched--you probably want to compare
3177 run times with and without it to see which runs faster.  Those loops
3178 which scan for many short constant strings (including the constant
3179 parts of more complex patterns) will benefit most.  You may have only
3180 one study active at a time--if you study a different scalar the first
3181 is "unstudied".  (The way study works is this: a linked list of every
3182 character in the string to be searched is made, so we know, for
3183 example, where all the 'k' characters are.  From each search string,
3184 the rarest character is selected, based on some static frequency tables
3185 constructed from some C programs and English text.  Only those places
3186 that contain this "rarest" character are examined.)
3187
3188 For example, here is a loop which inserts index producing entries
3189 before any line containing a certain pattern:
3190
3191     while (<>) {
3192         study;
3193         print ".IX foo\n" if /\bfoo\b/;
3194         print ".IX bar\n" if /\bbar\b/;
3195         print ".IX blurfl\n" if /\bblurfl\b/;
3196         ...
3197         print;
3198     }
3199
3200 In searching for /\bfoo\b/, only those locations in $_ that contain "f"
3201 will be looked at, because "f" is rarer than "o".  In general, this is
3202 a big win except in pathological cases.  The only question is whether
3203 it saves you more time than it took to build the linked list in the
3204 first place.
3205
3206 Note that if you have to look for strings that you don't know till
3207 runtime, you can build an entire loop as a string and eval that to
3208 avoid recompiling all your patterns all the time.  Together with
3209 undefining $/ to input entire files as one record, this can be very
3210 fast, often faster than specialized programs like fgrep(1).  The following
3211 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
3212 out the names of those files that contain a match:
3213
3214     $search = 'while (<>) { study;';
3215     foreach $word (@words) {
3216         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
3217     }
3218     $search .= "}";
3219     @ARGV = @files;
3220     undef $/;
3221     eval $search;               # this screams
3222     $/ = "\n";          # put back to normal input delimiter
3223     foreach $file (sort keys(%seen)) {
3224         print $file, "\n";
3225     }
3226
3227 =item sub BLOCK
3228
3229 =item sub NAME
3230
3231 =item sub NAME BLOCK
3232
3233 This is subroutine definition, not a real function I<per se>.  With just a
3234 NAME (and possibly prototypes), it's just a forward declaration.  Without
3235 a NAME, it's an anonymous function declaration, and does actually return a
3236 value: the CODE ref of the closure you just created.  See L<perlsub> and
3237 L<perlref> for details.
3238
3239 =item substr EXPR,OFFSET,LEN
3240
3241 =item substr EXPR,OFFSET
3242
3243 Extracts a substring out of EXPR and returns it.  First character is at
3244 offset 0, or whatever you've set C<$[> to (but don't do that).
3245 If OFFSET is negative, starts
3246 that far from the end of the string.  If LEN is omitted, returns
3247 everything to the end of the string.  If LEN is negative, leaves that
3248 many characters off the end of the string.
3249
3250 You can use the substr() function
3251 as an lvalue, in which case EXPR must be an lvalue.  If you assign
3252 something shorter than LEN, the string will shrink, and if you assign
3253 something longer than LEN, the string will grow to accommodate it.  To
3254 keep the string the same length you may need to pad or chop your value
3255 using sprintf().
3256
3257 =item symlink OLDFILE,NEWFILE
3258
3259 Creates a new filename symbolically linked to the old filename.
3260 Returns 1 for success, 0 otherwise.  On systems that don't support
3261 symbolic links, produces a fatal error at run time.  To check for that,
3262 use eval:
3263
3264     $symlink_exists = (eval 'symlink("","");', $@ eq '');
3265
3266 =item syscall LIST
3267
3268 Calls the system call specified as the first element of the list,
3269 passing the remaining elements as arguments to the system call.  If
3270 unimplemented, produces a fatal error.  The arguments are interpreted
3271 as follows: if a given argument is numeric, the argument is passed as
3272 an int.  If not, the pointer to the string value is passed.  You are
3273 responsible to make sure a string is pre-extended long enough to
3274 receive any result that might be written into a string.  If your
3275 integer arguments are not literals and have never been interpreted in a
3276 numeric context, you may need to add 0 to them to force them to look
3277 like numbers.
3278
3279     require 'syscall.ph';               # may need to run h2ph
3280     syscall(&SYS_write, fileno(STDOUT), "hi there\n", 9);
3281
3282 Note that Perl supports passing of up to only 14 arguments to your system call,
3283 which in practice should usually suffice.
3284
3285 =item sysopen FILEHANDLE,FILENAME,MODE
3286
3287 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
3288
3289 Opens the file whose filename is given by FILENAME, and associates it
3290 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
3291 the name of the real filehandle wanted.  This function calls the
3292 underlying operating system's C<open> function with the parameters
3293 FILENAME, MODE, PERMS.
3294
3295 The possible values and flag bits of the MODE parameter are
3296 system-dependent; they are available via the standard module C<Fcntl>.
3297 However, for historical reasons, some values are universal: zero means
3298 read-only, one means write-only, and two means read/write.
3299
3300 If the file named by FILENAME does not exist and the C<open> call
3301 creates it (typically because MODE includes the O_CREAT flag), then
3302 the value of PERMS specifies the permissions of the newly created
3303 file.  If PERMS is omitted, the default value is 0666, which allows
3304 read and write for all.  This default is reasonable: see C<umask>.
3305
3306 The IO::File module provides a more object-oriented approach, if you're
3307 into that kind of thing.
3308
3309 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
3310
3311 =item sysread FILEHANDLE,SCALAR,LENGTH
3312
3313 Attempts to read LENGTH bytes of data into variable SCALAR from the
3314 specified FILEHANDLE, using the system call read(2).  It bypasses
3315 stdio, so mixing this with other kinds of reads may cause confusion.
3316 Returns the number of bytes actually read, or undef if there was an
3317 error.  SCALAR will be grown or shrunk so that the last byte actually
3318 read is the last byte of the scalar after the read.
3319
3320 An OFFSET may be specified to place the read data at some place in the
3321 string other than the beginning.  A negative OFFSET specifies
3322 placement at that many bytes counting backwards from the end of the
3323 string.  A positive OFFSET greater than the length of SCALAR results
3324 in the string being padded to the required size with "\0" bytes before
3325 the result of the read is appended.
3326
3327 =item system LIST
3328
3329 Does exactly the same thing as "exec LIST" except that a fork is done
3330 first, and the parent process waits for the child process to complete.
3331 Note that argument processing varies depending on the number of
3332 arguments.  The return value is the exit status of the program as
3333 returned by the wait() call.  To get the actual exit value divide by
3334 256.  See also L</exec>.  This is I<NOT> what you want to use to capture 
3335 the output from a command, for that you should use merely back-ticks or
3336 qx//, as described in L<perlop/"`STRING`">.
3337
3338 Because system() and back-ticks block SIGINT and SIGQUIT, killing the
3339 program they're running doesn't actually interrupt your program.
3340
3341     @args = ("command", "arg1", "arg2");
3342     system(@args) == 0 
3343          or die "system @args failed: $?" 
3344
3345 Here's a more elaborate example of analysing the return value from
3346 system() on a UNIX system to check for all possibilities, including for
3347 signals and coredumps.
3348
3349     $rc = 0xffff & system @args;
3350     printf "system(%s) returned %#04x: ", "@args", $rc;
3351     if ($rc == 0) {
3352         print "ran with normal exit\n";
3353     } 
3354     elsif ($rc == 0xff00) {
3355         print "command failed: $!\n";
3356     } 
3357     elsif ($rc > 0x80) {
3358         $rc >>= 8;
3359         print "ran with non-zero exit status $rc\n";
3360     } 
3361     else {
3362         print "ran with ";
3363         if ($rc &   0x80) {
3364             $rc &= ~0x80;
3365             print "coredump from ";
3366         } 
3367         print "signal $rc\n"
3368     } 
3369     $ok = ($rc != 0);
3370
3371 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
3372
3373 =item syswrite FILEHANDLE,SCALAR,LENGTH
3374
3375 Attempts to write LENGTH bytes of data from variable SCALAR to the
3376 specified FILEHANDLE, using the system call write(2).  It bypasses
3377 stdio, so mixing this with prints may cause confusion.  Returns the
3378 number of bytes actually written, or undef if there was an error.
3379 If the length is greater than the available data, only as much data as
3380 is available will be written.
3381
3382 An OFFSET may be specified to write the data from some part of the
3383 string other than the beginning.  A negative OFFSET specifies writing
3384 from that many bytes counting backwards from the end of the string.
3385
3386 =item tell FILEHANDLE
3387
3388 =item tell
3389
3390 Returns the current file position for FILEHANDLE.  FILEHANDLE may be an
3391 expression whose value gives the name of the actual filehandle.  If
3392 FILEHANDLE is omitted, assumes the file last read.
3393
3394 =item telldir DIRHANDLE
3395
3396 Returns the current position of the readdir() routines on DIRHANDLE.
3397 Value may be given to seekdir() to access a particular location in a
3398 directory.  Has the same caveats about possible directory compaction as
3399 the corresponding system library routine.
3400
3401 =item tie VARIABLE,CLASSNAME,LIST
3402
3403 This function binds a variable to a package class that will provide the
3404 implementation for the variable.  VARIABLE is the name of the variable
3405 to be enchanted.  CLASSNAME is the name of a class implementing objects
3406 of correct type.  Any additional arguments are passed to the "new"
3407 method of the class (meaning TIESCALAR, TIEARRAY, or TIEHASH).
3408 Typically these are arguments such as might be passed to the dbm_open()
3409 function of C.  The object returned by the "new" method is also
3410 returned by the tie() function, which would be useful if you want to
3411 access other methods in CLASSNAME.
3412
3413 Note that functions such as keys() and values() may return huge array
3414 values when used on large objects, like DBM files.  You may prefer to
3415 use the each() function to iterate over such.  Example:
3416
3417     # print out history file offsets
3418     use NDBM_File;
3419     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
3420     while (($key,$val) = each %HIST) {
3421         print $key, ' = ', unpack('L',$val), "\n";
3422     }
3423     untie(%HIST);
3424
3425 A class implementing a hash should have the following methods:
3426
3427     TIEHASH classname, LIST
3428     DESTROY this
3429     FETCH this, key
3430     STORE this, key, value
3431     DELETE this, key
3432     EXISTS this, key
3433     FIRSTKEY this
3434     NEXTKEY this, lastkey
3435
3436 A class implementing an ordinary array should have the following methods:
3437
3438     TIEARRAY classname, LIST
3439     DESTROY this
3440     FETCH this, key
3441     STORE this, key, value
3442     [others TBD]
3443
3444 A class implementing a scalar should have the following methods:
3445
3446     TIESCALAR classname, LIST
3447     DESTROY this
3448     FETCH this, 
3449     STORE this, value
3450
3451 Unlike dbmopen(), the tie() function will not use or require a module
3452 for you--you need to do that explicitly yourself.  See L<DB_File>
3453 or the F<Config> module for interesting tie() implementations.
3454
3455 =item tied VARIABLE
3456
3457 Returns a reference to the object underlying VARIABLE (the same value
3458 that was originally returned by the tie() call which bound the variable
3459 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
3460 package.
3461
3462 =item time
3463
3464 Returns the number of non-leap seconds since whatever time the system
3465 considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS,
3466 and 00:00:00 UTC, January 1, 1970 for most other systems).
3467 Suitable for feeding to gmtime() and localtime().
3468
3469 =item times
3470
3471 Returns a four-element array giving the user and system times, in
3472 seconds, for this process and the children of this process.
3473
3474     ($user,$system,$cuser,$csystem) = times;
3475
3476 =item tr///
3477
3478 The translation operator.  See L<perlop>.
3479
3480 =item truncate FILEHANDLE,LENGTH
3481
3482 =item truncate EXPR,LENGTH
3483
3484 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
3485 specified length.  Produces a fatal error if truncate isn't implemented
3486 on your system.
3487
3488 =item uc EXPR
3489
3490 =item uc 
3491
3492 Returns an uppercased version of EXPR.  This is the internal function
3493 implementing the \U escape in double-quoted strings.
3494 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
3495
3496 If EXPR is omitted, uses $_.
3497
3498 =item ucfirst EXPR
3499
3500 =item ucfirst 
3501
3502 Returns the value of EXPR with the first character uppercased.  This is
3503 the internal function implementing the \u escape in double-quoted strings.
3504 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
3505
3506 If EXPR is omitted, uses $_.
3507
3508 =item umask EXPR
3509
3510 =item umask
3511
3512 Sets the umask for the process to EXPR and returns the previous value.
3513 If EXPR is omitted, merely returns the current umask.  Remember that a
3514 umask is a number, usually given in octal; it is I<not> a string of octal
3515 digits.  See also L<oct>, if all you have is a string.
3516
3517 =item undef EXPR
3518
3519 =item undef
3520
3521 Undefines the value of EXPR, which must be an lvalue.  Use on only a
3522 scalar value, an entire array or hash, or a subroutine name (using
3523 "&").  (Using undef() will probably not do what you expect on most
3524 predefined variables or DBM list values, so don't do that.)  Always
3525 returns the undefined value.  You can omit the EXPR, in which case
3526 nothing is undefined, but you still get an undefined value that you
3527 could, for instance, return from a subroutine, assign to a variable or
3528 pass as a parameter.  Examples:
3529
3530     undef $foo;
3531     undef $bar{'blurfl'};             # Compare to: delete $bar{'blurfl'};
3532     undef @ary;
3533     undef %hash;
3534     undef &mysub;
3535     return (wantarray ? () : undef) if $they_blew_it;
3536     select undef, undef, undef, 0.25;
3537     ($a, $b, undef, $c) = &foo;       # Ignore third value returned
3538
3539 =item unlink LIST
3540
3541 =item unlink 
3542
3543 Deletes a list of files.  Returns the number of files successfully
3544 deleted.
3545
3546     $cnt = unlink 'a', 'b', 'c';
3547     unlink @goners;
3548     unlink <*.bak>;
3549
3550 Note: unlink will not delete directories unless you are superuser and
3551 the B<-U> flag is supplied to Perl.  Even if these conditions are
3552 met, be warned that unlinking a directory can inflict damage on your
3553 filesystem.  Use rmdir instead.
3554
3555 If LIST is omitted, uses $_.
3556
3557 =item unpack TEMPLATE,EXPR
3558
3559 Unpack does the reverse of pack: it takes a string representing a
3560 structure and expands it out into a list value, returning the array
3561 value.  (In a scalar context, it returns merely the first value
3562 produced.)  The TEMPLATE has the same format as in the pack function.
3563 Here's a subroutine that does substring:
3564
3565     sub substr {
3566         local($what,$where,$howmuch) = @_;
3567         unpack("x$where a$howmuch", $what);
3568     }
3569
3570 and then there's
3571
3572     sub ordinal { unpack("c",$_[0]); } # same as ord()
3573
3574 In addition, you may prefix a field with a %E<lt>numberE<gt> to indicate that
3575 you want a E<lt>numberE<gt>-bit checksum of the items instead of the items
3576 themselves.  Default is a 16-bit checksum.  For example, the following
3577 computes the same number as the System V sum program:
3578
3579     while (<>) {
3580         $checksum += unpack("%16C*", $_);
3581     }
3582     $checksum %= 65536;
3583
3584 The following efficiently counts the number of set bits in a bit vector:
3585
3586     $setbits = unpack("%32b*", $selectmask);
3587
3588 =item untie VARIABLE
3589
3590 Breaks the binding between a variable and a package.  (See tie().)
3591
3592 =item unshift ARRAY,LIST
3593
3594 Does the opposite of a C<shift>.  Or the opposite of a C<push>,
3595 depending on how you look at it.  Prepends list to the front of the
3596 array, and returns the new number of elements in the array.
3597
3598     unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/;
3599
3600 Note the LIST is prepended whole, not one element at a time, so the
3601 prepended elements stay in the same order.  Use reverse to do the
3602 reverse.
3603
3604 =item use Module LIST
3605
3606 =item use Module
3607
3608 =item use Module VERSION LIST
3609
3610 =item use VERSION
3611
3612 Imports some semantics into the current package from the named module,
3613 generally by aliasing certain subroutine or variable names into your
3614 package.  It is exactly equivalent to
3615
3616     BEGIN { require Module; import Module LIST; }
3617
3618 except that Module I<must> be a bare word.
3619
3620 If the first argument to C<use> is a number, it is treated as a version
3621 number instead of a module name.  If the version of the Perl interpreter
3622 is less than VERSION, then an error message is printed and Perl exits
3623 immediately.  This is often useful if you need to check the current
3624 Perl version before C<use>ing library modules which have changed in
3625 incompatible ways from older versions of Perl.  (We try not to do
3626 this more than we have to.)
3627
3628 The BEGIN forces the require and import to happen at compile time.  The
3629 require makes sure the module is loaded into memory if it hasn't been
3630 yet.  The import is not a builtin--it's just an ordinary static method
3631 call into the "Module" package to tell the module to import the list of
3632 features back into the current package.  The module can implement its
3633 import method any way it likes, though most modules just choose to
3634 derive their import method via inheritance from the Exporter class that
3635 is defined in the Exporter module.  See L<Exporter>.  If no import
3636 method can be found then the error is currently silently ignored.  This
3637 may change to a fatal error in a future version.
3638
3639 If you don't want your namespace altered, explicitly supply an empty list:
3640
3641     use Module ();
3642
3643 That is exactly equivalent to
3644
3645     BEGIN { require Module; }
3646
3647 If the VERSION argument is present between Module and LIST, then the
3648 C<use> will call the VERSION method in class Module with the given
3649 version as an argument.  The default VERSION method, inherited from
3650 the Universal class, croaks if the given version is larger than the
3651 value of the variable $Module::VERSION.  (Note that there is not a
3652 comma after VERSION!)
3653
3654 Because this is a wide-open interface, pragmas (compiler directives)
3655 are also implemented this way.  Currently implemented pragmas are:
3656
3657     use integer;
3658     use diagnostics;
3659     use sigtrap qw(SEGV BUS);
3660     use strict  qw(subs vars refs);
3661     use subs    qw(afunc blurfl);
3662
3663 These pseudo-modules import semantics into the current block scope, unlike
3664 ordinary modules, which import symbols into the current package (which are
3665 effective through the end of the file).
3666
3667 There's a corresponding "no" command that unimports meanings imported
3668 by use, i.e., it calls C<unimport Module LIST> instead of C<import>.
3669
3670     no integer;
3671     no strict 'refs';
3672
3673 If no unimport method can be found the call fails with a fatal error.
3674
3675 See L<perlmod> for a list of standard modules and pragmas.
3676
3677 =item utime LIST
3678
3679 Changes the access and modification times on each file of a list of
3680 files.  The first two elements of the list must be the NUMERICAL access
3681 and modification times, in that order.  Returns the number of files
3682 successfully changed.  The inode modification time of each file is set
3683 to the current time.  Example of a "touch" command:
3684
3685     #!/usr/bin/perl
3686     $now = time;
3687     utime $now, $now, @ARGV;
3688
3689 =item values HASH
3690
3691 Returns a normal array consisting of all the values of the named hash.
3692 (In a scalar context, returns the number of values.)  The values are
3693 returned in an apparently random order, but it is the same order as either
3694 the keys() or each() function would produce on the same hash.  As a side
3695 effect, it resets HASH's iterator.  See also keys(), each(), and sort().
3696
3697 =item vec EXPR,OFFSET,BITS
3698
3699 Treats the string in EXPR as a vector of unsigned integers, and
3700 returns the value of the bit field specified by OFFSET.  BITS specifies
3701 the number of bits that are reserved for each entry in the bit
3702 vector.  This must be a power of two from 1 to 32. vec() may also be
3703 assigned to, in which case parentheses are needed to give the expression
3704 the correct precedence as in
3705
3706     vec($image, $max_x * $x + $y, 8) = 3;
3707
3708 Vectors created with vec() can also be manipulated with the logical
3709 operators |, &, and ^, which will assume a bit vector operation is
3710 desired when both operands are strings.
3711
3712 To transform a bit vector into a string or array of 0's and 1's, use these:
3713
3714     $bits = unpack("b*", $vector);
3715     @bits = split(//, unpack("b*", $vector));
3716
3717 If you know the exact length in bits, it can be used in place of the *.
3718
3719 =item wait
3720
3721 Waits for a child process to terminate and returns the pid of the
3722 deceased process, or -1 if there are no child processes.  The status is
3723 returned in C<$?>.
3724
3725 =item waitpid PID,FLAGS
3726
3727 Waits for a particular child process to terminate and returns the pid
3728 of the deceased process, or -1 if there is no such child process.  The
3729 status is returned in C<$?>.  If you say
3730
3731     use POSIX ":sys_wait_h";
3732     ...
3733     waitpid(-1,&WNOHANG);
3734
3735 then you can do a non-blocking wait for any process.  Non-blocking wait
3736 is available on machines supporting either the waitpid(2) or
3737 wait4(2) system calls.  However, waiting for a particular pid with
3738 FLAGS of 0 is implemented everywhere.  (Perl emulates the system call
3739 by remembering the status values of processes that have exited but have
3740 not been harvested by the Perl script yet.)
3741
3742 =item wantarray
3743
3744 Returns TRUE if the context of the currently executing subroutine is
3745 looking for a list value.  Returns FALSE if the context is looking
3746 for a scalar.
3747
3748     return wantarray ? () : undef;
3749
3750 =item warn LIST
3751
3752 Produces a message on STDERR just like die(), but doesn't exit or throw
3753 an exception.
3754
3755 No message is printed if there is a C<$SIG{__WARN__}> handler
3756 installed.  It is the handler's responsibility to deal with the message
3757 as it sees fit (like, for instance, converting it into a die()).  Most
3758 handlers must therefore make arrangements to actually display the
3759 warnings that they are not prepared to deal with, by calling warn()
3760 again in the handler.  Note that this is quite safe and will not
3761 produce an endless loop, since C<__WARN__> hooks are not called from
3762 inside one.
3763
3764 You will find this behavior is slightly different from that of
3765 C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can
3766 instead call die() again to change it).
3767
3768 Using a C<__WARN__> handler provides a powerful way to silence all
3769 warnings (even the so-called mandatory ones).  An example:
3770
3771     # wipe out *all* compile-time warnings
3772     BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
3773     my $foo = 10;
3774     my $foo = 20;          # no warning about duplicate my $foo,
3775                            # but hey, you asked for it!
3776     # no compile-time or run-time warnings before here
3777     $DOWARN = 1;
3778
3779     # run-time warnings enabled after here
3780     warn "\$foo is alive and $foo!";     # does show up
3781
3782 See L<perlvar> for details on setting C<%SIG> entries, and for more
3783 examples.
3784
3785 =item write FILEHANDLE
3786
3787 =item write EXPR
3788
3789 =item write
3790
3791 Writes a formatted record (possibly multi-line) to the specified file,
3792 using the format associated with that file.  By default the format for
3793 a file is the one having the same name is the filehandle, but the
3794 format for the current output channel (see the select() function) may be set
3795 explicitly by assigning the name of the format to the C<$~> variable.
3796
3797 Top of form processing is handled automatically:  if there is
3798 insufficient room on the current page for the formatted record, the
3799 page is advanced by writing a form feed, a special top-of-page format
3800 is used to format the new page header, and then the record is written.
3801 By default the top-of-page format is the name of the filehandle with
3802 "_TOP" appended, but it may be dynamically set to the format of your
3803 choice by assigning the name to the C<$^> variable while the filehandle is
3804 selected.  The number of lines remaining on the current page is in
3805 variable C<$->, which can be set to 0 to force a new page.
3806
3807 If FILEHANDLE is unspecified, output goes to the current default output
3808 channel, which starts out as STDOUT but may be changed by the
3809 C<select> operator.  If the FILEHANDLE is an EXPR, then the expression
3810 is evaluated and the resulting string is used to look up the name of
3811 the FILEHANDLE at run time.  For more on formats, see L<perlform>.
3812
3813 Note that write is I<NOT> the opposite of read.  Unfortunately.
3814
3815 =item y///
3816
3817 The translation operator.  See L<perlop>.
3818
3819 =back