This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
2f9a85c8f6bb83e36a32497ea36ac04aab0b98b8
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, the scalar arguments will
18 be first, and the list argument will follow.  (Note that there can ever
19 be only one such list argument.)  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for the elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use the parentheses, the simple (but occasionally
34 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  And whitespace
37 between the function and left parenthesis doesn't count--so you need to
38 be careful sometimes:
39
40     print 1+2+4;        # Prints 7.
41     print(1+2) + 4;     # Prints 3.
42     print (1+2)+4;      # Also prints 3!
43     print +(1+2)+4;     # Prints 7.
44     print ((1+2)+4);    # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in a scalar context by
59 returning the undefined value, and in a list context by returning the
60 null list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value it would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls
82 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 =head2 Perl Functions by Category
90 X<function>
91
92 Here are Perl's functions (including things that look like
93 functions, like some keywords and named operators)
94 arranged by category.  Some functions appear in more
95 than one place.
96
97 =over 4
98
99 =item Functions for SCALARs or strings
100 X<scalar> X<string> X<character>
101
102 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
103 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
104 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
105
106 =item Regular expressions and pattern matching
107 X<regular expression> X<regex> X<regexp>
108
109 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
110
111 =item Numeric functions
112 X<numeric> X<number> X<trigonometric> X<trigonometry>
113
114 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
115 C<sin>, C<sqrt>, C<srand>
116
117 =item Functions for real @ARRAYs
118 X<array>
119
120 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
121
122 =item Functions for list data
123 X<list>
124
125 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
126
127 =item Functions for real %HASHes
128 X<hash>
129
130 C<delete>, C<each>, C<exists>, C<keys>, C<values>
131
132 =item Input and output functions
133 X<I/O> X<input> X<output> X<dbm>
134
135 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
136 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
137 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
138 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
139 C<warn>, C<write>
140
141 =item Functions for fixed length data or records
142
143 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
144
145 =item Functions for filehandles, files, or directories
146 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
147
148 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
149 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
150 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
151 C<umask>, C<unlink>, C<utime>
152
153 =item Keywords related to the control flow of your Perl program
154 X<control flow>
155
156 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
157 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
158
159 =item Keywords related to switch
160
161 C<break>, C<continue>, C<given>, C<when>, C<default>
162
163 (These are only available if you enable the "switch" feature.
164 See L<feature> and L<perlsyn/"Switch statements">.)
165
166 =item Keywords related to scoping
167
168 C<caller>, C<import>, C<local>, C<my>, C<our>, C<state>, C<package>,
169 C<use>
170
171 (C<state> is only available if the "state" feature is enabled. See
172 L<feature>.)
173
174 =item Miscellaneous functions
175
176 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
177 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
178
179 =item Functions for processes and process groups
180 X<process> X<pid> X<process id>
181
182 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
183 C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
184 C<times>, C<wait>, C<waitpid>
185
186 =item Keywords related to perl modules
187 X<module>
188
189 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
190
191 =item Keywords related to classes and object-orientation
192 X<object> X<class> X<package>
193
194 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
195 C<untie>, C<use>
196
197 =item Low-level socket functions
198 X<socket> X<sock>
199
200 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
201 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
202 C<socket>, C<socketpair>
203
204 =item System V interprocess communication functions
205 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
206
207 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
208 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
209
210 =item Fetching user and group info
211 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
212
213 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
214 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
215 C<getpwuid>, C<setgrent>, C<setpwent>
216
217 =item Fetching network info
218 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
219
220 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
221 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
222 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
223 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
224 C<setnetent>, C<setprotoent>, C<setservent>
225
226 =item Time-related functions
227 X<time> X<date>
228
229 C<gmtime>, C<localtime>, C<time>, C<times>
230
231 =item Functions new in perl5
232 X<perl5>
233
234 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
235 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
236 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
237 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
238 C<ucfirst>, C<untie>, C<use>, C<when>
239
240 * - C<sub> was a keyword in perl4, but in perl5 it is an
241 operator, which can be used in expressions.
242
243 =item Functions obsoleted in perl5
244
245 C<dbmclose>, C<dbmopen>
246
247 =back
248
249 =head2 Portability
250 X<portability> X<Unix> X<portable>
251
252 Perl was born in Unix and can therefore access all common Unix
253 system calls.  In non-Unix environments, the functionality of some
254 Unix system calls may not be available, or details of the available
255 functionality may differ slightly.  The Perl functions affected
256 by this are:
257
258 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
259 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
260 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
261 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
262 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
263 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
264 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
265 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
266 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
267 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
268 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
269 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
270 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
271 C<shmwrite>, C<socket>, C<socketpair>,
272 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
273 C<times>, C<truncate>, C<umask>, C<unlink>,
274 C<utime>, C<wait>, C<waitpid>
275
276 For more information about the portability of these functions, see
277 L<perlport> and other available platform-specific documentation.
278
279 =head2 Alphabetical Listing of Perl Functions
280
281 =over 8
282
283 =item -X FILEHANDLE
284 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
285 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
286
287 =item -X EXPR
288
289 =item -X DIRHANDLE
290
291 =item -X
292
293 A file test, where X is one of the letters listed below.  This unary
294 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
295 and tests the associated file to see if something is true about it.  If the
296 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
297 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
298 the undefined value if the file doesn't exist.  Despite the funny
299 names, precedence is the same as any other named unary operator.  The
300 operator may be any of:
301
302     -r  File is readable by effective uid/gid.
303     -w  File is writable by effective uid/gid.
304     -x  File is executable by effective uid/gid.
305     -o  File is owned by effective uid.
306
307     -R  File is readable by real uid/gid.
308     -W  File is writable by real uid/gid.
309     -X  File is executable by real uid/gid.
310     -O  File is owned by real uid.
311
312     -e  File exists.
313     -z  File has zero size (is empty).
314     -s  File has nonzero size (returns size in bytes).
315
316     -f  File is a plain file.
317     -d  File is a directory.
318     -l  File is a symbolic link.
319     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
320     -S  File is a socket.
321     -b  File is a block special file.
322     -c  File is a character special file.
323     -t  Filehandle is opened to a tty.
324
325     -u  File has setuid bit set.
326     -g  File has setgid bit set.
327     -k  File has sticky bit set.
328
329     -T  File is an ASCII text file (heuristic guess).
330     -B  File is a "binary" file (opposite of -T).
331
332     -M  Script start time minus file modification time, in days.
333     -A  Same for access time.
334     -C  Same for inode change time (Unix, may differ for other platforms)
335
336 Example:
337
338     while (<>) {
339         chomp;
340         next unless -f $_;      # ignore specials
341         #...
342     }
343
344 The interpretation of the file permission operators C<-r>, C<-R>,
345 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
346 of the file and the uids and gids of the user.  There may be other
347 reasons you can't actually read, write, or execute the file: for
348 example network filesystem access controls, ACLs (access control lists),
349 read-only filesystems, and unrecognized executable formats.  Note
350 that the use of these six specific operators to verify if some operation
351 is possible is usually a mistake, because it may be open to race
352 conditions.
353
354 Also note that, for the superuser on the local filesystems, the C<-r>,
355 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
356 if any execute bit is set in the mode.  Scripts run by the superuser
357 may thus need to do a stat() to determine the actual mode of the file,
358 or temporarily set their effective uid to something else.
359
360 If you are using ACLs, there is a pragma called C<filetest> that may
361 produce more accurate results than the bare stat() mode bits.
362 When under the C<use filetest 'access'> the above-mentioned filetests
363 will test whether the permission can (not) be granted using the
364 access() family of system calls.  Also note that the C<-x> and C<-X> may
365 under this pragma return true even if there are no execute permission
366 bits set (nor any extra execute permission ACLs).  This strangeness is
367 due to the underlying system calls' definitions. Note also that, due to
368 the implementation of C<use filetest 'access'>, the C<_> special
369 filehandle won't cache the results of the file tests when this pragma is
370 in effect.  Read the documentation for the C<filetest> pragma for more
371 information.
372
373 Note that C<-s/a/b/> does not do a negated substitution.  Saying
374 C<-exp($foo)> still works as expected, however--only single letters
375 following a minus are interpreted as file tests.
376
377 The C<-T> and C<-B> switches work as follows.  The first block or so of the
378 file is examined for odd characters such as strange control codes or
379 characters with the high bit set.  If too many strange characters (>30%)
380 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
381 containing null in the first block is considered a binary file.  If C<-T>
382 or C<-B> is used on a filehandle, the current IO buffer is examined
383 rather than the first block.  Both C<-T> and C<-B> return true on a null
384 file, or a file at EOF when testing a filehandle.  Because you have to
385 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
386 against the file first, as in C<next unless -f $file && -T $file>.
387
388 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
389 the special filehandle consisting of a solitary underline, then the stat
390 structure of the previous file test (or stat operator) is used, saving
391 a system call.  (This doesn't work with C<-t>, and you need to remember
392 that lstat() and C<-l> will leave values in the stat structure for the
393 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
394 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
395 Example:
396
397     print "Can do.\n" if -r $a || -w _ || -x _;
398
399     stat($filename);
400     print "Readable\n" if -r _;
401     print "Writable\n" if -w _;
402     print "Executable\n" if -x _;
403     print "Setuid\n" if -u _;
404     print "Setgid\n" if -g _;
405     print "Sticky\n" if -k _;
406     print "Text\n" if -T _;
407     print "Binary\n" if -B _;
408
409 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
410 test operators, in a way that C<-f -w -x $file> is equivalent to
411 C<-x $file && -w _ && -f _>. (This is only syntax fancy: if you use
412 the return value of C<-f $file> as an argument to another filetest
413 operator, no special magic will happen.)
414
415 =item abs VALUE
416 X<abs> X<absolute>
417
418 =item abs
419
420 Returns the absolute value of its argument.
421 If VALUE is omitted, uses C<$_>.
422
423 =item accept NEWSOCKET,GENERICSOCKET
424 X<accept>
425
426 Accepts an incoming socket connect, just as the accept(2) system call
427 does.  Returns the packed address if it succeeded, false otherwise.
428 See the example in L<perlipc/"Sockets: Client/Server Communication">.
429
430 On systems that support a close-on-exec flag on files, the flag will
431 be set for the newly opened file descriptor, as determined by the
432 value of $^F.  See L<perlvar/$^F>.
433
434 =item alarm SECONDS
435 X<alarm>
436 X<SIGALRM>
437 X<timer>
438
439 =item alarm
440
441 Arranges to have a SIGALRM delivered to this process after the
442 specified number of wallclock seconds has elapsed.  If SECONDS is not
443 specified, the value stored in C<$_> is used. (On some machines,
444 unfortunately, the elapsed time may be up to one second less or more
445 than you specified because of how seconds are counted, and process
446 scheduling may delay the delivery of the signal even further.)
447
448 Only one timer may be counting at once.  Each call disables the
449 previous timer, and an argument of C<0> may be supplied to cancel the
450 previous timer without starting a new one.  The returned value is the
451 amount of time remaining on the previous timer.
452
453 For delays of finer granularity than one second, the Time::HiRes module
454 (from CPAN, and starting from Perl 5.8 part of the standard
455 distribution) provides ualarm().  You may also use Perl's four-argument
456 version of select() leaving the first three arguments undefined, or you
457 might be able to use the C<syscall> interface to access setitimer(2) if
458 your system supports it. See L<perlfaq8> for details.
459
460 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
461 (C<sleep> may be internally implemented in your system with C<alarm>)
462
463 If you want to use C<alarm> to time out a system call you need to use an
464 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
465 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
466 restart system calls on some systems.  Using C<eval>/C<die> always works,
467 modulo the caveats given in L<perlipc/"Signals">.
468
469     eval {
470         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
471         alarm $timeout;
472         $nread = sysread SOCKET, $buffer, $size;
473         alarm 0;
474     };
475     if ($@) {
476         die unless $@ eq "alarm\n";   # propagate unexpected errors
477         # timed out
478     }
479     else {
480         # didn't
481     }
482
483 For more information see L<perlipc>.
484
485 =item atan2 Y,X
486 X<atan2> X<arctangent> X<tan> X<tangent>
487
488 Returns the arctangent of Y/X in the range -PI to PI.
489
490 For the tangent operation, you may use the C<Math::Trig::tan>
491 function, or use the familiar relation:
492
493     sub tan { sin($_[0]) / cos($_[0])  }
494
495 The return value for C<atan2(0,0)> is implementation-defined; consult
496 your atan2(3) manpage for more information.
497
498 =item bind SOCKET,NAME
499 X<bind>
500
501 Binds a network address to a socket, just as the bind system call
502 does.  Returns true if it succeeded, false otherwise.  NAME should be a
503 packed address of the appropriate type for the socket.  See the examples in
504 L<perlipc/"Sockets: Client/Server Communication">.
505
506 =item binmode FILEHANDLE, LAYER
507 X<binmode> X<binary> X<text> X<DOS> X<Windows>
508
509 =item binmode FILEHANDLE
510
511 Arranges for FILEHANDLE to be read or written in "binary" or "text"
512 mode on systems where the run-time libraries distinguish between
513 binary and text files.  If FILEHANDLE is an expression, the value is
514 taken as the name of the filehandle.  Returns true on success,
515 otherwise it returns C<undef> and sets C<$!> (errno).
516
517 On some systems (in general, DOS and Windows-based systems) binmode()
518 is necessary when you're not working with a text file.  For the sake
519 of portability it is a good idea to always use it when appropriate,
520 and to never use it when it isn't appropriate.  Also, people can
521 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
522
523 In other words: regardless of platform, use binmode() on binary data,
524 like for example images.
525
526 If LAYER is present it is a single string, but may contain multiple
527 directives. The directives alter the behaviour of the file handle.
528 When LAYER is present using binmode on text file makes sense.
529
530 If LAYER is omitted or specified as C<:raw> the filehandle is made
531 suitable for passing binary data. This includes turning off possible CRLF
532 translation and marking it as bytes (as opposed to Unicode characters).
533 Note that, despite what may be implied in I<"Programming Perl"> (the
534 Camel) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>
535 -- other layers which would affect the binary nature of the stream are
536 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
537 PERLIO environment variable.
538
539 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
540 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
541 establish default I/O layers.  See L<open>.
542
543 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
544 in "Programming Perl, 3rd Edition".  However, since the publishing of this
545 book, by many known as "Camel III", the consensus of the naming of this
546 functionality has moved from "discipline" to "layer".  All documentation
547 of this version of Perl therefore refers to "layers" rather than to
548 "disciplines".  Now back to the regularly scheduled documentation...>
549
550 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(utf8)>.
551 C<:utf8> just marks the data as UTF-8 without further checking,
552 while C<:encoding(utf8)> checks the data for actually being valid
553 UTF-8. More details can be found in L<PerlIO::encoding>.
554
555 In general, binmode() should be called after open() but before any I/O
556 is done on the filehandle.  Calling binmode() will normally flush any
557 pending buffered output data (and perhaps pending input data) on the
558 handle.  An exception to this is the C<:encoding> layer that
559 changes the default character encoding of the handle, see L<open>.
560 The C<:encoding> layer sometimes needs to be called in
561 mid-stream, and it doesn't flush the stream.  The C<:encoding>
562 also implicitly pushes on top of itself the C<:utf8> layer because
563 internally Perl will operate on UTF-8 encoded Unicode characters.
564
565 The operating system, device drivers, C libraries, and Perl run-time
566 system all work together to let the programmer treat a single
567 character (C<\n>) as the line terminator, irrespective of the external
568 representation.  On many operating systems, the native text file
569 representation matches the internal representation, but on some
570 platforms the external representation of C<\n> is made up of more than
571 one character.
572
573 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
574 character to end each line in the external representation of text (even
575 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
576 on Unix and most VMS files). In other systems like OS/2, DOS and the
577 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
578 but what's stored in text files are the two characters C<\cM\cJ>.  That
579 means that, if you don't use binmode() on these systems, C<\cM\cJ>
580 sequences on disk will be converted to C<\n> on input, and any C<\n> in
581 your program will be converted back to C<\cM\cJ> on output.  This is what
582 you want for text files, but it can be disastrous for binary files.
583
584 Another consequence of using binmode() (on some systems) is that
585 special end-of-file markers will be seen as part of the data stream.
586 For systems from the Microsoft family this means that if your binary
587 data contains C<\cZ>, the I/O subsystem will regard it as the end of
588 the file, unless you use binmode().
589
590 binmode() is not only important for readline() and print() operations,
591 but also when using read(), seek(), sysread(), syswrite() and tell()
592 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
593 in L<perlvar> for how to manually set your input and output
594 line-termination sequences.
595
596 =item bless REF,CLASSNAME
597 X<bless>
598
599 =item bless REF
600
601 This function tells the thingy referenced by REF that it is now an object
602 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
603 is used.  Because a C<bless> is often the last thing in a constructor,
604 it returns the reference for convenience.  Always use the two-argument
605 version if a derived class might inherit the function doing the blessing.
606 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
607 of objects.
608
609 Consider always blessing objects in CLASSNAMEs that are mixed case.
610 Namespaces with all lowercase names are considered reserved for
611 Perl pragmata.  Builtin types have all uppercase names. To prevent
612 confusion, you may wish to avoid such package names as well.  Make sure
613 that CLASSNAME is a true value.
614
615 See L<perlmod/"Perl Modules">.
616
617 =item break
618
619 Break out of a C<given()> block.
620
621 This keyword is enabled by the "switch" feature: see L<feature>
622 for more information.
623
624 =item caller EXPR
625 X<caller> X<call stack> X<stack> X<stack trace>
626
627 =item caller
628
629 Returns the context of the current subroutine call.  In scalar context,
630 returns the caller's package name if there is a caller, that is, if
631 we're in a subroutine or C<eval> or C<require>, and the undefined value
632 otherwise.  In list context, returns
633
634     # 0         1          2
635     ($package, $filename, $line) = caller;
636
637 With EXPR, it returns some extra information that the debugger uses to
638 print a stack trace.  The value of EXPR indicates how many call frames
639 to go back before the current one.
640
641     #  0         1          2      3            4
642     ($package, $filename, $line, $subroutine, $hasargs,
643
644     #  5          6          7            8       9         10
645     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
646      = caller($i);
647
648 Here $subroutine may be C<(eval)> if the frame is not a subroutine
649 call, but an C<eval>.  In such a case additional elements $evaltext and
650 C<$is_require> are set: C<$is_require> is true if the frame is created by a
651 C<require> or C<use> statement, $evaltext contains the text of the
652 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
653 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
654 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
655 frame.)  $subroutine may also be C<(unknown)> if this particular
656 subroutine happens to have been deleted from the symbol table.
657 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
658 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
659 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
660 between versions of Perl, and are not meant for external use.
661
662 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
663 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
664 of this hash, as they are the actual values stored in the optree.
665
666 Furthermore, when called from within the DB package, caller returns more
667 detailed information: it sets the list variable C<@DB::args> to be the
668 arguments with which the subroutine was invoked.
669
670 Be aware that the optimizer might have optimized call frames away before
671 C<caller> had a chance to get the information.  That means that C<caller(N)>
672 might not return information about the call frame you expect it do, for
673 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
674 previous time C<caller> was called.
675
676 =item chdir EXPR
677 X<chdir>
678 X<cd>
679 X<directory, change>
680
681 =item chdir FILEHANDLE
682
683 =item chdir DIRHANDLE
684
685 =item chdir
686
687 Changes the working directory to EXPR, if possible. If EXPR is omitted,
688 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
689 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
690 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
691 neither is set, C<chdir> does nothing. It returns true upon success,
692 false otherwise. See the example under C<die>.
693
694 On systems that support fchdir, you might pass a file handle or
695 directory handle as argument.  On systems that don't support fchdir,
696 passing handles produces a fatal error at run time.
697
698 =item chmod LIST
699 X<chmod> X<permission> X<mode>
700
701 Changes the permissions of a list of files.  The first element of the
702 list must be the numerical mode, which should probably be an octal
703 number, and which definitely should I<not> be a string of octal digits:
704 C<0644> is okay, C<'0644'> is not.  Returns the number of files
705 successfully changed.  See also L</oct>, if all you have is a string.
706
707     $cnt = chmod 0755, 'foo', 'bar';
708     chmod 0755, @executables;
709     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
710                                              # --w----r-T
711     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
712     $mode = 0644;   chmod $mode, 'foo';      # this is best
713
714 On systems that support fchmod, you might pass file handles among the
715 files.  On systems that don't support fchmod, passing file handles
716 produces a fatal error at run time.   The file handles must be passed
717 as globs or references to be recognized.  Barewords are considered
718 file names.
719
720     open(my $fh, "<", "foo");
721     my $perm = (stat $fh)[2] & 07777;
722     chmod($perm | 0600, $fh);
723
724 You can also import the symbolic C<S_I*> constants from the Fcntl
725 module:
726
727     use Fcntl ':mode';
728
729     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
730     # This is identical to the chmod 0755 of the above example.
731
732 =item chomp VARIABLE
733 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
734
735 =item chomp( LIST )
736
737 =item chomp
738
739 This safer version of L</chop> removes any trailing string
740 that corresponds to the current value of C<$/> (also known as
741 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
742 number of characters removed from all its arguments.  It's often used to
743 remove the newline from the end of an input record when you're worried
744 that the final record may be missing its newline.  When in paragraph
745 mode (C<$/ = "">), it removes all trailing newlines from the string.
746 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
747 a reference to an integer or the like, see L<perlvar>) chomp() won't
748 remove anything.
749 If VARIABLE is omitted, it chomps C<$_>.  Example:
750
751     while (<>) {
752         chomp;  # avoid \n on last field
753         @array = split(/:/);
754         # ...
755     }
756
757 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
758
759 You can actually chomp anything that's an lvalue, including an assignment:
760
761     chomp($cwd = `pwd`);
762     chomp($answer = <STDIN>);
763
764 If you chomp a list, each element is chomped, and the total number of
765 characters removed is returned.
766
767 Note that parentheses are necessary when you're chomping anything
768 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
769 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
770 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
771 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
772 as C<chomp($a, $b)>.
773
774 =item chop VARIABLE
775 X<chop>
776
777 =item chop( LIST )
778
779 =item chop
780
781 Chops off the last character of a string and returns the character
782 chopped.  It is much more efficient than C<s/.$//s> because it neither
783 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
784 If VARIABLE is a hash, it chops the hash's values, but not its keys.
785
786 You can actually chop anything that's an lvalue, including an assignment.
787
788 If you chop a list, each element is chopped.  Only the value of the
789 last C<chop> is returned.
790
791 Note that C<chop> returns the last character.  To return all but the last
792 character, use C<substr($string, 0, -1)>.
793
794 See also L</chomp>.
795
796 =item chown LIST
797 X<chown> X<owner> X<user> X<group>
798
799 Changes the owner (and group) of a list of files.  The first two
800 elements of the list must be the I<numeric> uid and gid, in that
801 order.  A value of -1 in either position is interpreted by most
802 systems to leave that value unchanged.  Returns the number of files
803 successfully changed.
804
805     $cnt = chown $uid, $gid, 'foo', 'bar';
806     chown $uid, $gid, @filenames;
807
808 On systems that support fchown, you might pass file handles among the
809 files.  On systems that don't support fchown, passing file handles
810 produces a fatal error at run time.  The file handles must be passed
811 as globs or references to be recognized.  Barewords are considered
812 file names.
813
814 Here's an example that looks up nonnumeric uids in the passwd file:
815
816     print "User: ";
817     chomp($user = <STDIN>);
818     print "Files: ";
819     chomp($pattern = <STDIN>);
820
821     ($login,$pass,$uid,$gid) = getpwnam($user)
822         or die "$user not in passwd file";
823
824     @ary = glob($pattern);      # expand filenames
825     chown $uid, $gid, @ary;
826
827 On most systems, you are not allowed to change the ownership of the
828 file unless you're the superuser, although you should be able to change
829 the group to any of your secondary groups.  On insecure systems, these
830 restrictions may be relaxed, but this is not a portable assumption.
831 On POSIX systems, you can detect this condition this way:
832
833     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
834     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
835
836 =item chr NUMBER
837 X<chr> X<character> X<ASCII> X<Unicode>
838
839 =item chr
840
841 Returns the character represented by that NUMBER in the character set.
842 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
843 chr(0x263a) is a Unicode smiley face.  
844
845 Negative values give the Unicode replacement character (chr(0xfffd)),
846 except under the L<bytes> pragma, where low eight bits of the value
847 (truncated to an integer) are used.
848
849 If NUMBER is omitted, uses C<$_>.
850
851 For the reverse, use L</ord>.
852
853 Note that characters from 128 to 255 (inclusive) are by default
854 internally not encoded as UTF-8 for backward compatibility reasons.
855
856 See L<perlunicode> for more about Unicode.
857
858 =item chroot FILENAME
859 X<chroot> X<root>
860
861 =item chroot
862
863 This function works like the system call by the same name: it makes the
864 named directory the new root directory for all further pathnames that
865 begin with a C</> by your process and all its children.  (It doesn't
866 change your current working directory, which is unaffected.)  For security
867 reasons, this call is restricted to the superuser.  If FILENAME is
868 omitted, does a C<chroot> to C<$_>.
869
870 =item close FILEHANDLE
871 X<close>
872
873 =item close
874
875 Closes the file or pipe associated with the file handle, flushes the IO
876 buffers, and closes the system file descriptor.  Returns true if those
877 operations have succeeded and if no error was reported by any PerlIO
878 layer.  Closes the currently selected filehandle if the argument is
879 omitted.
880
881 You don't have to close FILEHANDLE if you are immediately going to do
882 another C<open> on it, because C<open> will close it for you.  (See
883 C<open>.)  However, an explicit C<close> on an input file resets the line
884 counter (C<$.>), while the implicit close done by C<open> does not.
885
886 If the file handle came from a piped open, C<close> will additionally
887 return false if one of the other system calls involved fails, or if the
888 program exits with non-zero status.  (If the only problem was that the
889 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
890 also waits for the process executing on the pipe to complete, in case you
891 want to look at the output of the pipe afterwards, and
892 implicitly puts the exit status value of that command into C<$?> and
893 C<${^CHILD_ERROR_NATIVE}>.
894
895 Prematurely closing the read end of a pipe (i.e. before the process
896 writing to it at the other end has closed it) will result in a
897 SIGPIPE being delivered to the writer.  If the other end can't
898 handle that, be sure to read all the data before closing the pipe.
899
900 Example:
901
902     open(OUTPUT, '|sort >foo')  # pipe to sort
903         or die "Can't start sort: $!";
904     #...                        # print stuff to output
905     close OUTPUT                # wait for sort to finish
906         or warn $! ? "Error closing sort pipe: $!"
907                    : "Exit status $? from sort";
908     open(INPUT, 'foo')          # get sort's results
909         or die "Can't open 'foo' for input: $!";
910
911 FILEHANDLE may be an expression whose value can be used as an indirect
912 filehandle, usually the real filehandle name.
913
914 =item closedir DIRHANDLE
915 X<closedir>
916
917 Closes a directory opened by C<opendir> and returns the success of that
918 system call.
919
920 =item connect SOCKET,NAME
921 X<connect>
922
923 Attempts to connect to a remote socket, just as the connect system call
924 does.  Returns true if it succeeded, false otherwise.  NAME should be a
925 packed address of the appropriate type for the socket.  See the examples in
926 L<perlipc/"Sockets: Client/Server Communication">.
927
928 =item continue BLOCK
929 X<continue>
930
931 =item continue
932
933 C<continue> is actually a flow control statement rather than a function.  If
934 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
935 C<foreach>), it is always executed just before the conditional is about to
936 be evaluated again, just like the third part of a C<for> loop in C.  Thus
937 it can be used to increment a loop variable, even when the loop has been
938 continued via the C<next> statement (which is similar to the C C<continue>
939 statement).
940
941 C<last>, C<next>, or C<redo> may appear within a C<continue>
942 block.  C<last> and C<redo> will behave as if they had been executed within
943 the main block.  So will C<next>, but since it will execute a C<continue>
944 block, it may be more entertaining.
945
946     while (EXPR) {
947         ### redo always comes here
948         do_something;
949     } continue {
950         ### next always comes here
951         do_something_else;
952         # then back the top to re-check EXPR
953     }
954     ### last always comes here
955
956 Omitting the C<continue> section is semantically equivalent to using an
957 empty one, logically enough.  In that case, C<next> goes directly back
958 to check the condition at the top of the loop.
959
960 If the "switch" feature is enabled, C<continue> is also a
961 function that will break out of the current C<when> or C<default>
962 block, and fall through to the next case. See L<feature> and
963 L<perlsyn/"Switch statements"> for more information.
964
965
966 =item cos EXPR
967 X<cos> X<cosine> X<acos> X<arccosine>
968
969 =item cos
970
971 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
972 takes cosine of C<$_>.
973
974 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
975 function, or use this relation:
976
977     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
978
979 =item crypt PLAINTEXT,SALT
980 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
981 X<decrypt> X<cryptography> X<passwd> X<encrypt>
982
983 Creates a digest string exactly like the crypt(3) function in the C
984 library (assuming that you actually have a version there that has not
985 been extirpated as a potential munitions).
986
987 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
988 into a short string, called a digest, which is returned.  The same
989 PLAINTEXT and SALT will always return the same string, but there is no
990 (known) way to get the original PLAINTEXT from the hash.  Small
991 changes in the PLAINTEXT or SALT will result in large changes in the
992 digest.
993
994 There is no decrypt function.  This function isn't all that useful for
995 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
996 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
997 primarily used to check if two pieces of text are the same without
998 having to transmit or store the text itself.  An example is checking
999 if a correct password is given.  The digest of the password is stored,
1000 not the password itself.  The user types in a password that is
1001 crypt()'d with the same salt as the stored digest.  If the two digests
1002 match the password is correct.
1003
1004 When verifying an existing digest string you should use the digest as
1005 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1006 to create the digest is visible as part of the digest.  This ensures
1007 crypt() will hash the new string with the same salt as the digest.
1008 This allows your code to work with the standard L<crypt|/crypt> and
1009 with more exotic implementations.  In other words, do not assume
1010 anything about the returned string itself, or how many bytes in the
1011 digest matter.
1012
1013 Traditionally the result is a string of 13 bytes: two first bytes of
1014 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1015 the first eight bytes of the digest string mattered, but alternative
1016 hashing schemes (like MD5), higher level security schemes (like C2),
1017 and implementations on non-UNIX platforms may produce different
1018 strings.
1019
1020 When choosing a new salt create a random two character string whose
1021 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1022 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1023 characters is just a recommendation; the characters allowed in
1024 the salt depend solely on your system's crypt library, and Perl can't
1025 restrict what salts C<crypt()> accepts.
1026
1027 Here's an example that makes sure that whoever runs this program knows
1028 their password:
1029
1030     $pwd = (getpwuid($<))[1];
1031
1032     system "stty -echo";
1033     print "Password: ";
1034     chomp($word = <STDIN>);
1035     print "\n";
1036     system "stty echo";
1037
1038     if (crypt($word, $pwd) ne $pwd) {
1039         die "Sorry...\n";
1040     } else {
1041         print "ok\n";
1042     }
1043
1044 Of course, typing in your own password to whoever asks you
1045 for it is unwise.
1046
1047 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1048 of data, not least of all because you can't get the information
1049 back.  Look at the L<Digest> module for more robust algorithms.
1050
1051 If using crypt() on a Unicode string (which I<potentially> has
1052 characters with codepoints above 255), Perl tries to make sense
1053 of the situation by trying to downgrade (a copy of the string)
1054 the string back to an eight-bit byte string before calling crypt()
1055 (on that copy).  If that works, good.  If not, crypt() dies with
1056 C<Wide character in crypt>.
1057
1058 =item dbmclose HASH
1059 X<dbmclose>
1060
1061 [This function has been largely superseded by the C<untie> function.]
1062
1063 Breaks the binding between a DBM file and a hash.
1064
1065 =item dbmopen HASH,DBNAME,MASK
1066 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1067
1068 [This function has been largely superseded by the C<tie> function.]
1069
1070 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1071 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1072 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1073 is the name of the database (without the F<.dir> or F<.pag> extension if
1074 any).  If the database does not exist, it is created with protection
1075 specified by MASK (as modified by the C<umask>).  If your system supports
1076 only the older DBM functions, you may perform only one C<dbmopen> in your
1077 program.  In older versions of Perl, if your system had neither DBM nor
1078 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1079 sdbm(3).
1080
1081 If you don't have write access to the DBM file, you can only read hash
1082 variables, not set them.  If you want to test whether you can write,
1083 either use file tests or try setting a dummy hash entry inside an C<eval>,
1084 which will trap the error.
1085
1086 Note that functions such as C<keys> and C<values> may return huge lists
1087 when used on large DBM files.  You may prefer to use the C<each>
1088 function to iterate over large DBM files.  Example:
1089
1090     # print out history file offsets
1091     dbmopen(%HIST,'/usr/lib/news/history',0666);
1092     while (($key,$val) = each %HIST) {
1093         print $key, ' = ', unpack('L',$val), "\n";
1094     }
1095     dbmclose(%HIST);
1096
1097 See also L<AnyDBM_File> for a more general description of the pros and
1098 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1099 rich implementation.
1100
1101 You can control which DBM library you use by loading that library
1102 before you call dbmopen():
1103
1104     use DB_File;
1105     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1106         or die "Can't open netscape history file: $!";
1107
1108 =item defined EXPR
1109 X<defined> X<undef> X<undefined>
1110
1111 =item defined
1112
1113 Returns a Boolean value telling whether EXPR has a value other than
1114 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
1115 checked.
1116
1117 Many operations return C<undef> to indicate failure, end of file,
1118 system error, uninitialized variable, and other exceptional
1119 conditions.  This function allows you to distinguish C<undef> from
1120 other values.  (A simple Boolean test will not distinguish among
1121 C<undef>, zero, the empty string, and C<"0">, which are all equally
1122 false.)  Note that since C<undef> is a valid scalar, its presence
1123 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1124 returns C<undef> when its argument is an empty array, I<or> when the
1125 element to return happens to be C<undef>.
1126
1127 You may also use C<defined(&func)> to check whether subroutine C<&func>
1128 has ever been defined.  The return value is unaffected by any forward
1129 declarations of C<&func>.  Note that a subroutine which is not defined
1130 may still be callable: its package may have an C<AUTOLOAD> method that
1131 makes it spring into existence the first time that it is called -- see
1132 L<perlsub>.
1133
1134 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1135 used to report whether memory for that aggregate has ever been
1136 allocated.  This behavior may disappear in future versions of Perl.
1137 You should instead use a simple test for size:
1138
1139     if (@an_array) { print "has array elements\n" }
1140     if (%a_hash)   { print "has hash members\n"   }
1141
1142 When used on a hash element, it tells you whether the value is defined,
1143 not whether the key exists in the hash.  Use L</exists> for the latter
1144 purpose.
1145
1146 Examples:
1147
1148     print if defined $switch{'D'};
1149     print "$val\n" while defined($val = pop(@ary));
1150     die "Can't readlink $sym: $!"
1151         unless defined($value = readlink $sym);
1152     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1153     $debugging = 0 unless defined $debugging;
1154
1155 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1156 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1157 defined values.  For example, if you say
1158
1159     "ab" =~ /a(.*)b/;
1160
1161 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1162 matched "nothing".  It didn't really fail to match anything.  Rather, it
1163 matched something that happened to be zero characters long.  This is all
1164 very above-board and honest.  When a function returns an undefined value,
1165 it's an admission that it couldn't give you an honest answer.  So you
1166 should use C<defined> only when you're questioning the integrity of what
1167 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1168 what you want.
1169
1170 See also L</undef>, L</exists>, L</ref>.
1171
1172 =item delete EXPR
1173 X<delete>
1174
1175 Given an expression that specifies a hash element, array element, hash slice,
1176 or array slice, deletes the specified element(s) from the hash or array.
1177 In the case of an array, if the array elements happen to be at the end,
1178 the size of the array will shrink to the highest element that tests
1179 true for exists() (or 0 if no such element exists).
1180
1181 Returns a list with the same number of elements as the number of elements
1182 for which deletion was attempted.  Each element of that list consists of
1183 either the value of the element deleted, or the undefined value.  In scalar
1184 context, this means that you get the value of the last element deleted (or
1185 the undefined value if that element did not exist).
1186
1187     %hash = (foo => 11, bar => 22, baz => 33);
1188     $scalar = delete $hash{foo};             # $scalar is 11
1189     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1190     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1191
1192 Deleting from C<%ENV> modifies the environment.  Deleting from
1193 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1194 from a C<tie>d hash or array may not necessarily return anything.
1195
1196 Deleting an array element effectively returns that position of the array
1197 to its initial, uninitialized state.  Subsequently testing for the same
1198 element with exists() will return false.  Also, deleting array elements
1199 in the middle of an array will not shift the index of the elements
1200 after them down.  Use splice() for that.  See L</exists>.
1201
1202 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1203
1204     foreach $key (keys %HASH) {
1205         delete $HASH{$key};
1206     }
1207
1208     foreach $index (0 .. $#ARRAY) {
1209         delete $ARRAY[$index];
1210     }
1211
1212 And so do these:
1213
1214     delete @HASH{keys %HASH};
1215
1216     delete @ARRAY[0 .. $#ARRAY];
1217
1218 But both of these are slower than just assigning the empty list
1219 or undefining %HASH or @ARRAY:
1220
1221     %HASH = ();         # completely empty %HASH
1222     undef %HASH;        # forget %HASH ever existed
1223
1224     @ARRAY = ();        # completely empty @ARRAY
1225     undef @ARRAY;       # forget @ARRAY ever existed
1226
1227 Note that the EXPR can be arbitrarily complicated as long as the final
1228 operation is a hash element, array element,  hash slice, or array slice
1229 lookup:
1230
1231     delete $ref->[$x][$y]{$key};
1232     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1233
1234     delete $ref->[$x][$y][$index];
1235     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1236
1237 =item die LIST
1238 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1239
1240 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1241 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1242 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1243 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1244 an C<eval(),> the error message is stuffed into C<$@> and the
1245 C<eval> is terminated with the undefined value.  This makes
1246 C<die> the way to raise an exception.
1247
1248 Equivalent examples:
1249
1250     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1251     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1252
1253 If the last element of LIST does not end in a newline, the current
1254 script line number and input line number (if any) are also printed,
1255 and a newline is supplied.  Note that the "input line number" (also
1256 known as "chunk") is subject to whatever notion of "line" happens to
1257 be currently in effect, and is also available as the special variable
1258 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1259
1260 Hint: sometimes appending C<", stopped"> to your message will cause it
1261 to make better sense when the string C<"at foo line 123"> is appended.
1262 Suppose you are running script "canasta".
1263
1264     die "/etc/games is no good";
1265     die "/etc/games is no good, stopped";
1266
1267 produce, respectively
1268
1269     /etc/games is no good at canasta line 123.
1270     /etc/games is no good, stopped at canasta line 123.
1271
1272 See also exit(), warn(), and the Carp module.
1273
1274 If LIST is empty and C<$@> already contains a value (typically from a
1275 previous eval) that value is reused after appending C<"\t...propagated">.
1276 This is useful for propagating exceptions:
1277
1278     eval { ... };
1279     die unless $@ =~ /Expected exception/;
1280
1281 If LIST is empty and C<$@> contains an object reference that has a
1282 C<PROPAGATE> method, that method will be called with additional file
1283 and line number parameters.  The return value replaces the value in
1284 C<$@>.  i.e. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1285 were called.
1286
1287 If C<$@> is empty then the string C<"Died"> is used.
1288
1289 die() can also be called with a reference argument.  If this happens to be
1290 trapped within an eval(), $@ contains the reference.  This behavior permits
1291 a more elaborate exception handling implementation using objects that
1292 maintain arbitrary state about the nature of the exception.  Such a scheme
1293 is sometimes preferable to matching particular string values of $@ using
1294 regular expressions.  Because $@ is a global variable, and eval() may be
1295 used within object implementations, care must be taken that analyzing the
1296 error object doesn't replace the reference in the global variable.  The
1297 easiest solution is to make a local copy of the reference before doing
1298 other manipulations.  Here's an example:
1299
1300     use Scalar::Util 'blessed';
1301
1302     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1303     if (my $ev_err = $@) {
1304         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1305             # handle Some::Module::Exception
1306         }
1307         else {
1308             # handle all other possible exceptions
1309         }
1310     }
1311
1312 Because perl will stringify uncaught exception messages before displaying
1313 them, you may want to overload stringification operations on such custom
1314 exception objects.  See L<overload> for details about that.
1315
1316 You can arrange for a callback to be run just before the C<die>
1317 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1318 handler will be called with the error text and can change the error
1319 message, if it sees fit, by calling C<die> again.  See
1320 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1321 L<"eval BLOCK"> for some examples.  Although this feature was 
1322 to be run only right before your program was to exit, this is not
1323 currently the case--the C<$SIG{__DIE__}> hook is currently called
1324 even inside eval()ed blocks/strings!  If one wants the hook to do
1325 nothing in such situations, put
1326
1327         die @_ if $^S;
1328
1329 as the first line of the handler (see L<perlvar/$^S>).  Because
1330 this promotes strange action at a distance, this counterintuitive
1331 behavior may be fixed in a future release.
1332
1333 =item do BLOCK
1334 X<do> X<block>
1335
1336 Not really a function.  Returns the value of the last command in the
1337 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1338 C<until> loop modifier, executes the BLOCK once before testing the loop
1339 condition. (On other statements the loop modifiers test the conditional
1340 first.)
1341
1342 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1343 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1344 See L<perlsyn> for alternative strategies.
1345
1346 =item do SUBROUTINE(LIST)
1347 X<do>
1348
1349 This form of subroutine call is deprecated.  See L<perlsub>.
1350
1351 =item do EXPR
1352 X<do>
1353
1354 Uses the value of EXPR as a filename and executes the contents of the
1355 file as a Perl script.
1356
1357     do 'stat.pl';
1358
1359 is just like
1360
1361     eval `cat stat.pl`;
1362
1363 except that it's more efficient and concise, keeps track of the current
1364 filename for error messages, searches the @INC directories, and updates
1365 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1366 variables.  It also differs in that code evaluated with C<do FILENAME>
1367 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1368 same, however, in that it does reparse the file every time you call it,
1369 so you probably don't want to do this inside a loop.
1370
1371 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1372 error.  If C<do> can read the file but cannot compile it, it
1373 returns undef and sets an error message in C<$@>.   If the file is
1374 successfully compiled, C<do> returns the value of the last expression
1375 evaluated.
1376
1377 Note that inclusion of library modules is better done with the
1378 C<use> and C<require> operators, which also do automatic error checking
1379 and raise an exception if there's a problem.
1380
1381 You might like to use C<do> to read in a program configuration
1382 file.  Manual error checking can be done this way:
1383
1384     # read in config files: system first, then user
1385     for $file ("/share/prog/defaults.rc",
1386                "$ENV{HOME}/.someprogrc")
1387    {
1388         unless ($return = do $file) {
1389             warn "couldn't parse $file: $@" if $@;
1390             warn "couldn't do $file: $!"    unless defined $return;
1391             warn "couldn't run $file"       unless $return;
1392         }
1393     }
1394
1395 =item dump LABEL
1396 X<dump> X<core> X<undump>
1397
1398 =item dump
1399
1400 This function causes an immediate core dump.  See also the B<-u>
1401 command-line switch in L<perlrun>, which does the same thing.
1402 Primarily this is so that you can use the B<undump> program (not
1403 supplied) to turn your core dump into an executable binary after
1404 having initialized all your variables at the beginning of the
1405 program.  When the new binary is executed it will begin by executing
1406 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1407 Think of it as a goto with an intervening core dump and reincarnation.
1408 If C<LABEL> is omitted, restarts the program from the top.
1409
1410 B<WARNING>: Any files opened at the time of the dump will I<not>
1411 be open any more when the program is reincarnated, with possible
1412 resulting confusion on the part of Perl.
1413
1414 This function is now largely obsolete, mostly because it's very hard to
1415 convert a core file into an executable. That's why you should now invoke
1416 it as C<CORE::dump()>, if you don't want to be warned against a possible
1417 typo.
1418
1419 =item each HASH
1420 X<each> X<hash, iterator>
1421
1422 =item each ARRAY
1423 X<array, iterator>
1424
1425 When called in list context, returns a 2-element list consisting of the
1426 key and value for the next element of a hash, or the index and value for
1427 the next element of an array, so that you can iterate over it.  When called
1428 in scalar context, returns only the key for the next element in the hash
1429 (or the index for an array).
1430
1431 Hash entries are returned in an apparently random order.  The actual random
1432 order is subject to change in future versions of perl, but it is
1433 guaranteed to be in the same order as either the C<keys> or C<values>
1434 function would produce on the same (unmodified) hash.  Since Perl
1435 5.8.2 the ordering can be different even between different runs of Perl
1436 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1437
1438 When the hash or array is entirely read, a null array is returned in list
1439 context (which when assigned produces a false (C<0>) value), and C<undef> in
1440 scalar context.  The next call to C<each> after that will start iterating
1441 again.  There is a single iterator for each hash or array, shared by all
1442 C<each>, C<keys>, and C<values> function calls in the program; it can be
1443 reset by reading all the elements from the hash or array, or by evaluating
1444 C<keys HASH>, C<values HASH>, C<keys ARRAY>, or C<values ARRAY>.  If you add
1445 or delete elements of a hash while you're
1446 iterating over it, you may get entries skipped or duplicated, so
1447 don't.  Exception: It is always safe to delete the item most recently
1448 returned by C<each()>, which means that the following code will work:
1449
1450         while (($key, $value) = each %hash) {
1451           print $key, "\n";
1452           delete $hash{$key};   # This is safe
1453         }
1454
1455 The following prints out your environment like the printenv(1) program,
1456 only in a different order:
1457
1458     while (($key,$value) = each %ENV) {
1459         print "$key=$value\n";
1460     }
1461
1462 See also C<keys>, C<values> and C<sort>.
1463
1464 =item eof FILEHANDLE
1465 X<eof>
1466 X<end of file>
1467 X<end-of-file>
1468
1469 =item eof ()
1470
1471 =item eof
1472
1473 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1474 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1475 gives the real filehandle.  (Note that this function actually
1476 reads a character and then C<ungetc>s it, so isn't very useful in an
1477 interactive context.)  Do not read from a terminal file (or call
1478 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1479 as terminals may lose the end-of-file condition if you do.
1480
1481 An C<eof> without an argument uses the last file read.  Using C<eof()>
1482 with empty parentheses is very different.  It refers to the pseudo file
1483 formed from the files listed on the command line and accessed via the
1484 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1485 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1486 used will cause C<@ARGV> to be examined to determine if input is
1487 available.   Similarly, an C<eof()> after C<< <> >> has returned
1488 end-of-file will assume you are processing another C<@ARGV> list,
1489 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1490 see L<perlop/"I/O Operators">.
1491
1492 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1493 detect the end of each file, C<eof()> will only detect the end of the
1494 last file.  Examples:
1495
1496     # reset line numbering on each input file
1497     while (<>) {
1498         next if /^\s*#/;        # skip comments
1499         print "$.\t$_";
1500     } continue {
1501         close ARGV  if eof;     # Not eof()!
1502     }
1503
1504     # insert dashes just before last line of last file
1505     while (<>) {
1506         if (eof()) {            # check for end of last file
1507             print "--------------\n";
1508         }
1509         print;
1510         last if eof();          # needed if we're reading from a terminal
1511     }
1512
1513 Practical hint: you almost never need to use C<eof> in Perl, because the
1514 input operators typically return C<undef> when they run out of data, or if
1515 there was an error.
1516
1517 =item eval EXPR
1518 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1519 X<error, handling> X<exception, handling>
1520
1521 =item eval BLOCK
1522
1523 =item eval
1524
1525 In the first form, the return value of EXPR is parsed and executed as if it
1526 were a little Perl program.  The value of the expression (which is itself
1527 determined within scalar context) is first parsed, and if there weren't any
1528 errors, executed in the lexical context of the current Perl program, so
1529 that any variable settings or subroutine and format definitions remain
1530 afterwards.  Note that the value is parsed every time the C<eval> executes.
1531 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1532 delay parsing and subsequent execution of the text of EXPR until run time.
1533
1534 In the second form, the code within the BLOCK is parsed only once--at the
1535 same time the code surrounding the C<eval> itself was parsed--and executed
1536 within the context of the current Perl program.  This form is typically
1537 used to trap exceptions more efficiently than the first (see below), while
1538 also providing the benefit of checking the code within BLOCK at compile
1539 time.
1540
1541 The final semicolon, if any, may be omitted from the value of EXPR or within
1542 the BLOCK.
1543
1544 In both forms, the value returned is the value of the last expression
1545 evaluated inside the mini-program; a return statement may be also used, just
1546 as with subroutines.  The expression providing the return value is evaluated
1547 in void, scalar, or list context, depending on the context of the C<eval> 
1548 itself.  See L</wantarray> for more on how the evaluation context can be 
1549 determined.
1550
1551 If there is a syntax error or runtime error, or a C<die> statement is
1552 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1553 error message.  If there was no error, C<$@> is guaranteed to be a null
1554 string.  Beware that using C<eval> neither silences perl from printing
1555 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1556 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1557 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1558 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1559
1560 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1561 determining whether a particular feature (such as C<socket> or C<symlink>)
1562 is implemented.  It is also Perl's exception trapping mechanism, where
1563 the die operator is used to raise exceptions.
1564
1565 If you want to trap errors when loading an XS module, some problems with
1566 the binary interface (such as Perl version skew) may be fatal even with
1567 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set. See L<perlrun>.
1568
1569 If the code to be executed doesn't vary, you may use the eval-BLOCK
1570 form to trap run-time errors without incurring the penalty of
1571 recompiling each time.  The error, if any, is still returned in C<$@>.
1572 Examples:
1573
1574     # make divide-by-zero nonfatal
1575     eval { $answer = $a / $b; }; warn $@ if $@;
1576
1577     # same thing, but less efficient
1578     eval '$answer = $a / $b'; warn $@ if $@;
1579
1580     # a compile-time error
1581     eval { $answer = };                 # WRONG
1582
1583     # a run-time error
1584     eval '$answer =';   # sets $@
1585
1586 Using the C<eval{}> form as an exception trap in libraries does have some
1587 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1588 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1589 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1590 as shown in this example:
1591
1592     # a very private exception trap for divide-by-zero
1593     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1594     warn $@ if $@;
1595
1596 This is especially significant, given that C<__DIE__> hooks can call
1597 C<die> again, which has the effect of changing their error messages:
1598
1599     # __DIE__ hooks may modify error messages
1600     {
1601        local $SIG{'__DIE__'} =
1602               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1603        eval { die "foo lives here" };
1604        print $@ if $@;                # prints "bar lives here"
1605     }
1606
1607 Because this promotes action at a distance, this counterintuitive behavior
1608 may be fixed in a future release.
1609
1610 With an C<eval>, you should be especially careful to remember what's
1611 being looked at when:
1612
1613     eval $x;            # CASE 1
1614     eval "$x";          # CASE 2
1615
1616     eval '$x';          # CASE 3
1617     eval { $x };        # CASE 4
1618
1619     eval "\$$x++";      # CASE 5
1620     $$x++;              # CASE 6
1621
1622 Cases 1 and 2 above behave identically: they run the code contained in
1623 the variable $x.  (Although case 2 has misleading double quotes making
1624 the reader wonder what else might be happening (nothing is).)  Cases 3
1625 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1626 does nothing but return the value of $x.  (Case 4 is preferred for
1627 purely visual reasons, but it also has the advantage of compiling at
1628 compile-time instead of at run-time.)  Case 5 is a place where
1629 normally you I<would> like to use double quotes, except that in this
1630 particular situation, you can just use symbolic references instead, as
1631 in case 6.
1632
1633 The assignment to C<$@> occurs before restoration of localised variables,
1634 which means a temporary is required if you want to mask some but not all
1635 errors:
1636
1637     # alter $@ on nefarious repugnancy only
1638     {
1639        my $e;
1640        {
1641           local $@; # protect existing $@
1642           eval { test_repugnancy() };
1643           # $@ =~ /nefarious/ and die $@; # DOES NOT WORK
1644           $@ =~ /nefarious/ and $e = $@;
1645        }
1646        die $e if defined $e
1647     }
1648
1649 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1650 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1651
1652 Note that as a very special case, an C<eval ''> executed within the C<DB>
1653 package doesn't see the usual surrounding lexical scope, but rather the
1654 scope of the first non-DB piece of code that called it. You don't normally
1655 need to worry about this unless you are writing a Perl debugger.
1656
1657 =item exec LIST
1658 X<exec> X<execute>
1659
1660 =item exec PROGRAM LIST
1661
1662 The C<exec> function executes a system command I<and never returns>--
1663 use C<system> instead of C<exec> if you want it to return.  It fails and
1664 returns false only if the command does not exist I<and> it is executed
1665 directly instead of via your system's command shell (see below).
1666
1667 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1668 warns you if there is a following statement which isn't C<die>, C<warn>,
1669 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1670 I<really> want to follow an C<exec> with some other statement, you
1671 can use one of these styles to avoid the warning:
1672
1673     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1674     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1675
1676 If there is more than one argument in LIST, or if LIST is an array
1677 with more than one value, calls execvp(3) with the arguments in LIST.
1678 If there is only one scalar argument or an array with one element in it,
1679 the argument is checked for shell metacharacters, and if there are any,
1680 the entire argument is passed to the system's command shell for parsing
1681 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1682 If there are no shell metacharacters in the argument, it is split into
1683 words and passed directly to C<execvp>, which is more efficient.
1684 Examples:
1685
1686     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1687     exec "sort $outfile | uniq";
1688
1689 If you don't really want to execute the first argument, but want to lie
1690 to the program you are executing about its own name, you can specify
1691 the program you actually want to run as an "indirect object" (without a
1692 comma) in front of the LIST.  (This always forces interpretation of the
1693 LIST as a multivalued list, even if there is only a single scalar in
1694 the list.)  Example:
1695
1696     $shell = '/bin/csh';
1697     exec $shell '-sh';          # pretend it's a login shell
1698
1699 or, more directly,
1700
1701     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1702
1703 When the arguments get executed via the system shell, results will
1704 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1705 for details.
1706
1707 Using an indirect object with C<exec> or C<system> is also more
1708 secure.  This usage (which also works fine with system()) forces
1709 interpretation of the arguments as a multivalued list, even if the
1710 list had just one argument.  That way you're safe from the shell
1711 expanding wildcards or splitting up words with whitespace in them.
1712
1713     @args = ( "echo surprise" );
1714
1715     exec @args;               # subject to shell escapes
1716                                 # if @args == 1
1717     exec { $args[0] } @args;  # safe even with one-arg list
1718
1719 The first version, the one without the indirect object, ran the I<echo>
1720 program, passing it C<"surprise"> an argument.  The second version
1721 didn't--it tried to run a program literally called I<"echo surprise">,
1722 didn't find it, and set C<$?> to a non-zero value indicating failure.
1723
1724 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1725 output before the exec, but this may not be supported on some platforms
1726 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1727 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1728 open handles in order to avoid lost output.
1729
1730 Note that C<exec> will not call your C<END> blocks, nor will it call
1731 any C<DESTROY> methods in your objects.
1732
1733 =item exists EXPR
1734 X<exists> X<autovivification>
1735
1736 Given an expression that specifies a hash element or array element,
1737 returns true if the specified element in the hash or array has ever
1738 been initialized, even if the corresponding value is undefined.
1739
1740     print "Exists\n"    if exists $hash{$key};
1741     print "Defined\n"   if defined $hash{$key};
1742     print "True\n"      if $hash{$key};
1743
1744     print "Exists\n"    if exists $array[$index];
1745     print "Defined\n"   if defined $array[$index];
1746     print "True\n"      if $array[$index];
1747
1748 A hash or array element can be true only if it's defined, and defined if
1749 it exists, but the reverse doesn't necessarily hold true.
1750
1751 Given an expression that specifies the name of a subroutine,
1752 returns true if the specified subroutine has ever been declared, even
1753 if it is undefined.  Mentioning a subroutine name for exists or defined
1754 does not count as declaring it.  Note that a subroutine which does not
1755 exist may still be callable: its package may have an C<AUTOLOAD>
1756 method that makes it spring into existence the first time that it is
1757 called -- see L<perlsub>.
1758
1759     print "Exists\n"    if exists &subroutine;
1760     print "Defined\n"   if defined &subroutine;
1761
1762 Note that the EXPR can be arbitrarily complicated as long as the final
1763 operation is a hash or array key lookup or subroutine name:
1764
1765     if (exists $ref->{A}->{B}->{$key})  { }
1766     if (exists $hash{A}{B}{$key})       { }
1767
1768     if (exists $ref->{A}->{B}->[$ix])   { }
1769     if (exists $hash{A}{B}[$ix])        { }
1770
1771     if (exists &{$ref->{A}{B}{$key}})   { }
1772
1773 Although the deepest nested array or hash will not spring into existence
1774 just because its existence was tested, any intervening ones will.
1775 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1776 into existence due to the existence test for the $key element above.
1777 This happens anywhere the arrow operator is used, including even:
1778
1779     undef $ref;
1780     if (exists $ref->{"Some key"})      { }
1781     print $ref;             # prints HASH(0x80d3d5c)
1782
1783 This surprising autovivification in what does not at first--or even
1784 second--glance appear to be an lvalue context may be fixed in a future
1785 release.
1786
1787 Use of a subroutine call, rather than a subroutine name, as an argument
1788 to exists() is an error.
1789
1790     exists &sub;        # OK
1791     exists &sub();      # Error
1792
1793 =item exit EXPR
1794 X<exit> X<terminate> X<abort>
1795
1796 =item exit
1797
1798 Evaluates EXPR and exits immediately with that value.    Example:
1799
1800     $ans = <STDIN>;
1801     exit 0 if $ans =~ /^[Xx]/;
1802
1803 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1804 universally recognized values for EXPR are C<0> for success and C<1>
1805 for error; other values are subject to interpretation depending on the
1806 environment in which the Perl program is running.  For example, exiting
1807 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1808 the mailer to return the item undelivered, but that's not true everywhere.
1809
1810 Don't use C<exit> to abort a subroutine if there's any chance that
1811 someone might want to trap whatever error happened.  Use C<die> instead,
1812 which can be trapped by an C<eval>.
1813
1814 The exit() function does not always exit immediately.  It calls any
1815 defined C<END> routines first, but these C<END> routines may not
1816 themselves abort the exit.  Likewise any object destructors that need to
1817 be called are called before the real exit.  If this is a problem, you
1818 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1819 See L<perlmod> for details.
1820
1821 =item exp EXPR
1822 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1823
1824 =item exp
1825
1826 Returns I<e> (the natural logarithm base) to the power of EXPR.
1827 If EXPR is omitted, gives C<exp($_)>.
1828
1829 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1830 X<fcntl>
1831
1832 Implements the fcntl(2) function.  You'll probably have to say
1833
1834     use Fcntl;
1835
1836 first to get the correct constant definitions.  Argument processing and
1837 value return works just like C<ioctl> below.
1838 For example:
1839
1840     use Fcntl;
1841     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1842         or die "can't fcntl F_GETFL: $!";
1843
1844 You don't have to check for C<defined> on the return from C<fcntl>.
1845 Like C<ioctl>, it maps a C<0> return from the system call into
1846 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1847 in numeric context.  It is also exempt from the normal B<-w> warnings
1848 on improper numeric conversions.
1849
1850 Note that C<fcntl> will produce a fatal error if used on a machine that
1851 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1852 manpage to learn what functions are available on your system.
1853
1854 Here's an example of setting a filehandle named C<REMOTE> to be
1855 non-blocking at the system level.  You'll have to negotiate C<$|>
1856 on your own, though.
1857
1858     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1859
1860     $flags = fcntl(REMOTE, F_GETFL, 0)
1861                 or die "Can't get flags for the socket: $!\n";
1862
1863     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1864                 or die "Can't set flags for the socket: $!\n";
1865
1866 =item fileno FILEHANDLE
1867 X<fileno>
1868
1869 Returns the file descriptor for a filehandle, or undefined if the
1870 filehandle is not open.  This is mainly useful for constructing
1871 bitmaps for C<select> and low-level POSIX tty-handling operations.
1872 If FILEHANDLE is an expression, the value is taken as an indirect
1873 filehandle, generally its name.
1874
1875 You can use this to find out whether two handles refer to the
1876 same underlying descriptor:
1877
1878     if (fileno(THIS) == fileno(THAT)) {
1879         print "THIS and THAT are dups\n";
1880     }
1881
1882 (Filehandles connected to memory objects via new features of C<open> may
1883 return undefined even though they are open.)
1884
1885
1886 =item flock FILEHANDLE,OPERATION
1887 X<flock> X<lock> X<locking>
1888
1889 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1890 for success, false on failure.  Produces a fatal error if used on a
1891 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1892 C<flock> is Perl's portable file locking interface, although it locks
1893 only entire files, not records.
1894
1895 Two potentially non-obvious but traditional C<flock> semantics are
1896 that it waits indefinitely until the lock is granted, and that its locks
1897 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1898 fewer guarantees.  This means that programs that do not also use C<flock>
1899 may modify files locked with C<flock>.  See L<perlport>, 
1900 your port's specific documentation, or your system-specific local manpages
1901 for details.  It's best to assume traditional behavior if you're writing
1902 portable programs.  (But if you're not, you should as always feel perfectly
1903 free to write for your own system's idiosyncrasies (sometimes called
1904 "features").  Slavish adherence to portability concerns shouldn't get
1905 in the way of your getting your job done.)
1906
1907 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1908 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1909 you can use the symbolic names if you import them from the Fcntl module,
1910 either individually, or as a group using the ':flock' tag.  LOCK_SH
1911 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1912 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1913 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1914 waiting for the lock (check the return status to see if you got it).
1915
1916 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1917 before locking or unlocking it.
1918
1919 Note that the emulation built with lockf(3) doesn't provide shared
1920 locks, and it requires that FILEHANDLE be open with write intent.  These
1921 are the semantics that lockf(3) implements.  Most if not all systems
1922 implement lockf(3) in terms of fcntl(2) locking, though, so the
1923 differing semantics shouldn't bite too many people.
1924
1925 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1926 be open with read intent to use LOCK_SH and requires that it be open
1927 with write intent to use LOCK_EX.
1928
1929 Note also that some versions of C<flock> cannot lock things over the
1930 network; you would need to use the more system-specific C<fcntl> for
1931 that.  If you like you can force Perl to ignore your system's flock(2)
1932 function, and so provide its own fcntl(2)-based emulation, by passing
1933 the switch C<-Ud_flock> to the F<Configure> program when you configure
1934 perl.
1935
1936 Here's a mailbox appender for BSD systems.
1937
1938     use Fcntl ':flock'; # import LOCK_* constants
1939
1940     sub lock {
1941         flock(MBOX,LOCK_EX);
1942         # and, in case someone appended
1943         # while we were waiting...
1944         seek(MBOX, 0, 2);
1945     }
1946
1947     sub unlock {
1948         flock(MBOX,LOCK_UN);
1949     }
1950
1951     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
1952             or die "Can't open mailbox: $!";
1953
1954     lock();
1955     print $mbox $msg,"\n\n";
1956     unlock();
1957
1958 On systems that support a real flock(), locks are inherited across fork()
1959 calls, whereas those that must resort to the more capricious fcntl()
1960 function lose the locks, making it harder to write servers.
1961
1962 See also L<DB_File> for other flock() examples.
1963
1964 =item fork
1965 X<fork> X<child> X<parent>
1966
1967 Does a fork(2) system call to create a new process running the
1968 same program at the same point.  It returns the child pid to the
1969 parent process, C<0> to the child process, or C<undef> if the fork is
1970 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1971 are shared, while everything else is copied.  On most systems supporting
1972 fork(), great care has gone into making it extremely efficient (for
1973 example, using copy-on-write technology on data pages), making it the
1974 dominant paradigm for multitasking over the last few decades.
1975
1976 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1977 output before forking the child process, but this may not be supported
1978 on some platforms (see L<perlport>).  To be safe, you may need to set
1979 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1980 C<IO::Handle> on any open handles in order to avoid duplicate output.
1981
1982 If you C<fork> without ever waiting on your children, you will
1983 accumulate zombies.  On some systems, you can avoid this by setting
1984 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1985 forking and reaping moribund children.
1986
1987 Note that if your forked child inherits system file descriptors like
1988 STDIN and STDOUT that are actually connected by a pipe or socket, even
1989 if you exit, then the remote server (such as, say, a CGI script or a
1990 backgrounded job launched from a remote shell) won't think you're done.
1991 You should reopen those to F</dev/null> if it's any issue.
1992
1993 =item format
1994 X<format>
1995
1996 Declare a picture format for use by the C<write> function.  For
1997 example:
1998
1999     format Something =
2000         Test: @<<<<<<<< @||||| @>>>>>
2001               $str,     $%,    '$' . int($num)
2002     .
2003
2004     $str = "widget";
2005     $num = $cost/$quantity;
2006     $~ = 'Something';
2007     write;
2008
2009 See L<perlform> for many details and examples.
2010
2011 =item formline PICTURE,LIST
2012 X<formline>
2013
2014 This is an internal function used by C<format>s, though you may call it,
2015 too.  It formats (see L<perlform>) a list of values according to the
2016 contents of PICTURE, placing the output into the format output
2017 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2018 Eventually, when a C<write> is done, the contents of
2019 C<$^A> are written to some filehandle.  You could also read C<$^A>
2020 and then set C<$^A> back to C<"">.  Note that a format typically
2021 does one C<formline> per line of form, but the C<formline> function itself
2022 doesn't care how many newlines are embedded in the PICTURE.  This means
2023 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
2024 You may therefore need to use multiple formlines to implement a single
2025 record format, just like the format compiler.
2026
2027 Be careful if you put double quotes around the picture, because an C<@>
2028 character may be taken to mean the beginning of an array name.
2029 C<formline> always returns true.  See L<perlform> for other examples.
2030
2031 =item getc FILEHANDLE
2032 X<getc> X<getchar> X<character> X<file, read>
2033
2034 =item getc
2035
2036 Returns the next character from the input file attached to FILEHANDLE,
2037 or the undefined value at end of file, or if there was an error (in
2038 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2039 STDIN.  This is not particularly efficient.  However, it cannot be
2040 used by itself to fetch single characters without waiting for the user
2041 to hit enter.  For that, try something more like:
2042
2043     if ($BSD_STYLE) {
2044         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2045     }
2046     else {
2047         system "stty", '-icanon', 'eol', "\001";
2048     }
2049
2050     $key = getc(STDIN);
2051
2052     if ($BSD_STYLE) {
2053         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2054     }
2055     else {
2056         system "stty", 'icanon', 'eol', '^@'; # ASCII null
2057     }
2058     print "\n";
2059
2060 Determination of whether $BSD_STYLE should be set
2061 is left as an exercise to the reader.
2062
2063 The C<POSIX::getattr> function can do this more portably on
2064 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2065 module from your nearest CPAN site; details on CPAN can be found on
2066 L<perlmodlib/CPAN>.
2067
2068 =item getlogin
2069 X<getlogin> X<login>
2070
2071 This implements the C library function of the same name, which on most
2072 systems returns the current login from F</etc/utmp>, if any.  If null,
2073 use C<getpwuid>.
2074
2075     $login = getlogin || getpwuid($<) || "Kilroy";
2076
2077 Do not consider C<getlogin> for authentication: it is not as
2078 secure as C<getpwuid>.
2079
2080 =item getpeername SOCKET
2081 X<getpeername> X<peer>
2082
2083 Returns the packed sockaddr address of other end of the SOCKET connection.
2084
2085     use Socket;
2086     $hersockaddr    = getpeername(SOCK);
2087     ($port, $iaddr) = sockaddr_in($hersockaddr);
2088     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2089     $herstraddr     = inet_ntoa($iaddr);
2090
2091 =item getpgrp PID
2092 X<getpgrp> X<group>
2093
2094 Returns the current process group for the specified PID.  Use
2095 a PID of C<0> to get the current process group for the
2096 current process.  Will raise an exception if used on a machine that
2097 doesn't implement getpgrp(2).  If PID is omitted, returns process
2098 group of current process.  Note that the POSIX version of C<getpgrp>
2099 does not accept a PID argument, so only C<PID==0> is truly portable.
2100
2101 =item getppid
2102 X<getppid> X<parent> X<pid>
2103
2104 Returns the process id of the parent process.
2105
2106 Note for Linux users: on Linux, the C functions C<getpid()> and
2107 C<getppid()> return different values from different threads. In order to
2108 be portable, this behavior is not reflected by the perl-level function
2109 C<getppid()>, that returns a consistent value across threads. If you want
2110 to call the underlying C<getppid()>, you may use the CPAN module
2111 C<Linux::Pid>.
2112
2113 =item getpriority WHICH,WHO
2114 X<getpriority> X<priority> X<nice>
2115
2116 Returns the current priority for a process, a process group, or a user.
2117 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2118 machine that doesn't implement getpriority(2).
2119
2120 =item getpwnam NAME
2121 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2122 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2123 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2124 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2125 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2126 X<endnetent> X<endprotoent> X<endservent> 
2127
2128 =item getgrnam NAME
2129
2130 =item gethostbyname NAME
2131
2132 =item getnetbyname NAME
2133
2134 =item getprotobyname NAME
2135
2136 =item getpwuid UID
2137
2138 =item getgrgid GID
2139
2140 =item getservbyname NAME,PROTO
2141
2142 =item gethostbyaddr ADDR,ADDRTYPE
2143
2144 =item getnetbyaddr ADDR,ADDRTYPE
2145
2146 =item getprotobynumber NUMBER
2147
2148 =item getservbyport PORT,PROTO
2149
2150 =item getpwent
2151
2152 =item getgrent
2153
2154 =item gethostent
2155
2156 =item getnetent
2157
2158 =item getprotoent
2159
2160 =item getservent
2161
2162 =item setpwent
2163
2164 =item setgrent
2165
2166 =item sethostent STAYOPEN
2167
2168 =item setnetent STAYOPEN
2169
2170 =item setprotoent STAYOPEN
2171
2172 =item setservent STAYOPEN
2173
2174 =item endpwent
2175
2176 =item endgrent
2177
2178 =item endhostent
2179
2180 =item endnetent
2181
2182 =item endprotoent
2183
2184 =item endservent
2185
2186 These routines perform the same functions as their counterparts in the
2187 system library.  In list context, the return values from the
2188 various get routines are as follows:
2189
2190     ($name,$passwd,$uid,$gid,
2191        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2192     ($name,$passwd,$gid,$members) = getgr*
2193     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2194     ($name,$aliases,$addrtype,$net) = getnet*
2195     ($name,$aliases,$proto) = getproto*
2196     ($name,$aliases,$port,$proto) = getserv*
2197
2198 (If the entry doesn't exist you get a null list.)
2199
2200 The exact meaning of the $gcos field varies but it usually contains
2201 the real name of the user (as opposed to the login name) and other
2202 information pertaining to the user.  Beware, however, that in many
2203 system users are able to change this information and therefore it
2204 cannot be trusted and therefore the $gcos is tainted (see
2205 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2206 login shell, are also tainted, because of the same reason.
2207
2208 In scalar context, you get the name, unless the function was a
2209 lookup by name, in which case you get the other thing, whatever it is.
2210 (If the entry doesn't exist you get the undefined value.)  For example:
2211
2212     $uid   = getpwnam($name);
2213     $name  = getpwuid($num);
2214     $name  = getpwent();
2215     $gid   = getgrnam($name);
2216     $name  = getgrgid($num);
2217     $name  = getgrent();
2218     #etc.
2219
2220 In I<getpw*()> the fields $quota, $comment, and $expire are special
2221 cases in the sense that in many systems they are unsupported.  If the
2222 $quota is unsupported, it is an empty scalar.  If it is supported, it
2223 usually encodes the disk quota.  If the $comment field is unsupported,
2224 it is an empty scalar.  If it is supported it usually encodes some
2225 administrative comment about the user.  In some systems the $quota
2226 field may be $change or $age, fields that have to do with password
2227 aging.  In some systems the $comment field may be $class.  The $expire
2228 field, if present, encodes the expiration period of the account or the
2229 password.  For the availability and the exact meaning of these fields
2230 in your system, please consult your getpwnam(3) documentation and your
2231 F<pwd.h> file.  You can also find out from within Perl what your
2232 $quota and $comment fields mean and whether you have the $expire field
2233 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2234 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2235 files are only supported if your vendor has implemented them in the
2236 intuitive fashion that calling the regular C library routines gets the
2237 shadow versions if you're running under privilege or if there exists
2238 the shadow(3) functions as found in System V (this includes Solaris
2239 and Linux.)  Those systems that implement a proprietary shadow password
2240 facility are unlikely to be supported.
2241
2242 The $members value returned by I<getgr*()> is a space separated list of
2243 the login names of the members of the group.
2244
2245 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2246 C, it will be returned to you via C<$?> if the function call fails.  The
2247 C<@addrs> value returned by a successful call is a list of the raw
2248 addresses returned by the corresponding system library call.  In the
2249 Internet domain, each address is four bytes long and you can unpack it
2250 by saying something like:
2251
2252     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2253
2254 The Socket library makes this slightly easier:
2255
2256     use Socket;
2257     $iaddr = inet_aton("127.1"); # or whatever address
2258     $name  = gethostbyaddr($iaddr, AF_INET);
2259
2260     # or going the other way
2261     $straddr = inet_ntoa($iaddr);
2262
2263 In the opposite way, to resolve a hostname to the IP address
2264 you can write this:
2265
2266     use Socket;
2267     $packed_ip = gethostbyname("www.perl.org");
2268     if (defined $packed_ip) {
2269         $ip_address = inet_ntoa($packed_ip);
2270     }
2271
2272 Make sure <gethostbyname()> is called in SCALAR context and that
2273 its return value is checked for definedness.
2274
2275 If you get tired of remembering which element of the return list
2276 contains which return value, by-name interfaces are provided
2277 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2278 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2279 and C<User::grent>.  These override the normal built-ins, supplying
2280 versions that return objects with the appropriate names
2281 for each field.  For example:
2282
2283    use File::stat;
2284    use User::pwent;
2285    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2286
2287 Even though it looks like they're the same method calls (uid),
2288 they aren't, because a C<File::stat> object is different from
2289 a C<User::pwent> object.
2290
2291 =item getsockname SOCKET
2292 X<getsockname>
2293
2294 Returns the packed sockaddr address of this end of the SOCKET connection,
2295 in case you don't know the address because you have several different
2296 IPs that the connection might have come in on.
2297
2298     use Socket;
2299     $mysockaddr = getsockname(SOCK);
2300     ($port, $myaddr) = sockaddr_in($mysockaddr);
2301     printf "Connect to %s [%s]\n",
2302        scalar gethostbyaddr($myaddr, AF_INET),
2303        inet_ntoa($myaddr);
2304
2305 =item getsockopt SOCKET,LEVEL,OPTNAME
2306 X<getsockopt>
2307
2308 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2309 Options may exist at multiple protocol levels depending on the socket
2310 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2311 C<Socket> module) will exist. To query options at another level the
2312 protocol number of the appropriate protocol controlling the option
2313 should be supplied. For example, to indicate that an option is to be
2314 interpreted by the TCP protocol, LEVEL should be set to the protocol
2315 number of TCP, which you can get using getprotobyname.
2316
2317 The call returns a packed string representing the requested socket option,
2318 or C<undef> if there is an error (the error reason will be in $!). What
2319 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2320 your system documentation for details. A very common case however is that
2321 the option is an integer, in which case the result will be a packed
2322 integer which you can decode using unpack with the C<i> (or C<I>) format.
2323
2324 An example testing if Nagle's algorithm is turned on on a socket:
2325
2326     use Socket qw(:all);
2327
2328     defined(my $tcp = getprotobyname("tcp"))
2329         or die "Could not determine the protocol number for tcp";
2330     # my $tcp = IPPROTO_TCP; # Alternative
2331     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2332         or die "Could not query TCP_NODELAY socket option: $!";
2333     my $nodelay = unpack("I", $packed);
2334     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2335
2336
2337 =item glob EXPR
2338 X<glob> X<wildcard> X<filename, expansion> X<expand>
2339
2340 =item glob
2341
2342 In list context, returns a (possibly empty) list of filename expansions on
2343 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2344 scalar context, glob iterates through such filename expansions, returning
2345 undef when the list is exhausted. This is the internal function
2346 implementing the C<< <*.c> >> operator, but you can use it directly. If
2347 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2348 more detail in L<perlop/"I/O Operators">.
2349
2350 Note that C<glob> will split its arguments on whitespace, treating
2351 each segment as separate pattern.  As such, C<glob('*.c *.h')> would
2352 match all files with a F<.c> or F<.h> extension.  The expression
2353 C<glob('.* *')> would match all files in the current working directory.
2354
2355 Beginning with v5.6.0, this operator is implemented using the standard
2356 C<File::Glob> extension.  See L<File::Glob> for details, including
2357 C<bsd_glob> which does not treat whitespace as a pattern separator.
2358
2359 =item gmtime EXPR
2360 X<gmtime> X<UTC> X<Greenwich>
2361
2362 =item gmtime
2363
2364 Works just like L<localtime> but the returned values are
2365 localized for the standard Greenwich time zone.
2366
2367 Note: when called in list context, $isdst, the last value
2368 returned by gmtime is always C<0>.  There is no
2369 Daylight Saving Time in GMT.
2370
2371 See L<perlport/gmtime> for portability concerns.
2372
2373 =item goto LABEL
2374 X<goto> X<jump> X<jmp>
2375
2376 =item goto EXPR
2377
2378 =item goto &NAME
2379
2380 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2381 execution there.  It may not be used to go into any construct that
2382 requires initialization, such as a subroutine or a C<foreach> loop.  It
2383 also can't be used to go into a construct that is optimized away,
2384 or to get out of a block or subroutine given to C<sort>.
2385 It can be used to go almost anywhere else within the dynamic scope,
2386 including out of subroutines, but it's usually better to use some other
2387 construct such as C<last> or C<die>.  The author of Perl has never felt the
2388 need to use this form of C<goto> (in Perl, that is--C is another matter).
2389 (The difference being that C does not offer named loops combined with
2390 loop control.  Perl does, and this replaces most structured uses of C<goto>
2391 in other languages.)
2392
2393 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2394 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2395 necessarily recommended if you're optimizing for maintainability:
2396
2397     goto ("FOO", "BAR", "GLARCH")[$i];
2398
2399 The C<goto-&NAME> form is quite different from the other forms of
2400 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2401 doesn't have the stigma associated with other gotos.  Instead, it
2402 exits the current subroutine (losing any changes set by local()) and
2403 immediately calls in its place the named subroutine using the current
2404 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2405 load another subroutine and then pretend that the other subroutine had
2406 been called in the first place (except that any modifications to C<@_>
2407 in the current subroutine are propagated to the other subroutine.)
2408 After the C<goto>, not even C<caller> will be able to tell that this
2409 routine was called first.
2410
2411 NAME needn't be the name of a subroutine; it can be a scalar variable
2412 containing a code reference, or a block that evaluates to a code
2413 reference.
2414
2415 =item grep BLOCK LIST
2416 X<grep>
2417
2418 =item grep EXPR,LIST
2419
2420 This is similar in spirit to, but not the same as, grep(1) and its
2421 relatives.  In particular, it is not limited to using regular expressions.
2422
2423 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2424 C<$_> to each element) and returns the list value consisting of those
2425 elements for which the expression evaluated to true.  In scalar
2426 context, returns the number of times the expression was true.
2427
2428     @foo = grep(!/^#/, @bar);    # weed out comments
2429
2430 or equivalently,
2431
2432     @foo = grep {!/^#/} @bar;    # weed out comments
2433
2434 Note that C<$_> is an alias to the list value, so it can be used to
2435 modify the elements of the LIST.  While this is useful and supported,
2436 it can cause bizarre results if the elements of LIST are not variables.
2437 Similarly, grep returns aliases into the original list, much as a for
2438 loop's index variable aliases the list elements.  That is, modifying an
2439 element of a list returned by grep (for example, in a C<foreach>, C<map>
2440 or another C<grep>) actually modifies the element in the original list.
2441 This is usually something to be avoided when writing clear code.
2442
2443 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2444 been declared with C<my $_>) then, in addition to being locally aliased to
2445 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2446 can't be seen from the outside, avoiding any potential side-effects.
2447
2448 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2449
2450 =item hex EXPR
2451 X<hex> X<hexadecimal>
2452
2453 =item hex
2454
2455 Interprets EXPR as a hex string and returns the corresponding value.
2456 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2457 L</oct>.)  If EXPR is omitted, uses C<$_>.
2458
2459     print hex '0xAf'; # prints '175'
2460     print hex 'aF';   # same
2461
2462 Hex strings may only represent integers.  Strings that would cause
2463 integer overflow trigger a warning.  Leading whitespace is not stripped,
2464 unlike oct(). To present something as hex, look into L</printf>,
2465 L</sprintf>, or L</unpack>.
2466
2467 =item import LIST
2468 X<import>
2469
2470 There is no builtin C<import> function.  It is just an ordinary
2471 method (subroutine) defined (or inherited) by modules that wish to export
2472 names to another module.  The C<use> function calls the C<import> method
2473 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2474
2475 =item index STR,SUBSTR,POSITION
2476 X<index> X<indexOf> X<InStr>
2477
2478 =item index STR,SUBSTR
2479
2480 The index function searches for one string within another, but without
2481 the wildcard-like behavior of a full regular-expression pattern match.
2482 It returns the position of the first occurrence of SUBSTR in STR at
2483 or after POSITION.  If POSITION is omitted, starts searching from the
2484 beginning of the string.  POSITION before the beginning of the string
2485 or after its end is treated as if it were the beginning or the end,
2486 respectively.  POSITION and the return value are based at C<0> (or whatever
2487 you've set the C<$[> variable to--but don't do that).  If the substring
2488 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2489
2490 =item int EXPR
2491 X<int> X<integer> X<truncate> X<trunc> X<floor>
2492
2493 =item int
2494
2495 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2496 You should not use this function for rounding: one because it truncates
2497 towards C<0>, and two because machine representations of floating point
2498 numbers can sometimes produce counterintuitive results.  For example,
2499 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2500 because it's really more like -268.99999999999994315658 instead.  Usually,
2501 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2502 functions will serve you better than will int().
2503
2504 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2505 X<ioctl>
2506
2507 Implements the ioctl(2) function.  You'll probably first have to say
2508
2509     require "sys/ioctl.ph";     # probably in $Config{archlib}/sys/ioctl.ph
2510
2511 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2512 exist or doesn't have the correct definitions you'll have to roll your
2513 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2514 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2515 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2516 written depending on the FUNCTION--a pointer to the string value of SCALAR
2517 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2518 has no string value but does have a numeric value, that value will be
2519 passed rather than a pointer to the string value.  To guarantee this to be
2520 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2521 functions may be needed to manipulate the values of structures used by
2522 C<ioctl>.
2523
2524 The return value of C<ioctl> (and C<fcntl>) is as follows:
2525
2526         if OS returns:          then Perl returns:
2527             -1                    undefined value
2528              0                  string "0 but true"
2529         anything else               that number
2530
2531 Thus Perl returns true on success and false on failure, yet you can
2532 still easily determine the actual value returned by the operating
2533 system:
2534
2535     $retval = ioctl(...) || -1;
2536     printf "System returned %d\n", $retval;
2537
2538 The special string C<"0 but true"> is exempt from B<-w> complaints
2539 about improper numeric conversions.
2540
2541 =item join EXPR,LIST
2542 X<join>
2543
2544 Joins the separate strings of LIST into a single string with fields
2545 separated by the value of EXPR, and returns that new string.  Example:
2546
2547     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2548
2549 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2550 first argument.  Compare L</split>.
2551
2552 =item keys HASH
2553 X<keys> X<key>
2554
2555 =item keys ARRAY
2556
2557 Returns a list consisting of all the keys of the named hash, or the indices
2558 of an array. (In scalar context, returns the number of keys or indices.)
2559
2560 The keys of a hash are returned in an apparently random order.  The actual
2561 random order is subject to change in future versions of perl, but it
2562 is guaranteed to be the same order as either the C<values> or C<each>
2563 function produces (given that the hash has not been modified).  Since
2564 Perl 5.8.1 the ordering is different even between different runs of
2565 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2566 Attacks">).
2567
2568 As a side effect, calling keys() resets the HASH or ARRAY's internal iterator
2569 (see L</each>).  In particular, calling keys() in void context resets
2570 the iterator with no other overhead.
2571
2572 Here is yet another way to print your environment:
2573
2574     @keys = keys %ENV;
2575     @values = values %ENV;
2576     while (@keys) {
2577         print pop(@keys), '=', pop(@values), "\n";
2578     }
2579
2580 or how about sorted by key:
2581
2582     foreach $key (sort(keys %ENV)) {
2583         print $key, '=', $ENV{$key}, "\n";
2584     }
2585
2586 The returned values are copies of the original keys in the hash, so
2587 modifying them will not affect the original hash.  Compare L</values>.
2588
2589 To sort a hash by value, you'll need to use a C<sort> function.
2590 Here's a descending numeric sort of a hash by its values:
2591
2592     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2593         printf "%4d %s\n", $hash{$key}, $key;
2594     }
2595
2596 As an lvalue C<keys> allows you to increase the number of hash buckets
2597 allocated for the given hash.  This can gain you a measure of efficiency if
2598 you know the hash is going to get big.  (This is similar to pre-extending
2599 an array by assigning a larger number to $#array.)  If you say
2600
2601     keys %hash = 200;
2602
2603 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2604 in fact, since it rounds up to the next power of two.  These
2605 buckets will be retained even if you do C<%hash = ()>, use C<undef
2606 %hash> if you want to free the storage while C<%hash> is still in scope.
2607 You can't shrink the number of buckets allocated for the hash using
2608 C<keys> in this way (but you needn't worry about doing this by accident,
2609 as trying has no effect). C<keys @array> in an lvalue context is a syntax
2610 error.
2611
2612 See also C<each>, C<values> and C<sort>.
2613
2614 =item kill SIGNAL, LIST
2615 X<kill> X<signal>
2616
2617 Sends a signal to a list of processes.  Returns the number of
2618 processes successfully signaled (which is not necessarily the
2619 same as the number actually killed).
2620
2621     $cnt = kill 1, $child1, $child2;
2622     kill 9, @goners;
2623
2624 If SIGNAL is zero, no signal is sent to the process, but the kill(2)
2625 system call will check whether it's possible to send a signal to it (that
2626 means, to be brief, that the process is owned by the same user, or we are
2627 the super-user).  This is a useful way to check that a child process is
2628 alive (even if only as a zombie) and hasn't changed its UID.  See
2629 L<perlport> for notes on the portability of this construct.
2630
2631 Unlike in the shell, if SIGNAL is negative, it kills
2632 process groups instead of processes.  (On System V, a negative I<PROCESS>
2633 number will also kill process groups, but that's not portable.)  That
2634 means you usually want to use positive not negative signals.  You may also
2635 use a signal name in quotes.
2636
2637 See L<perlipc/"Signals"> for more details.
2638
2639 =item last LABEL
2640 X<last> X<break>
2641
2642 =item last
2643
2644 The C<last> command is like the C<break> statement in C (as used in
2645 loops); it immediately exits the loop in question.  If the LABEL is
2646 omitted, the command refers to the innermost enclosing loop.  The
2647 C<continue> block, if any, is not executed:
2648
2649     LINE: while (<STDIN>) {
2650         last LINE if /^$/;      # exit when done with header
2651         #...
2652     }
2653
2654 C<last> cannot be used to exit a block which returns a value such as
2655 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2656 a grep() or map() operation.
2657
2658 Note that a block by itself is semantically identical to a loop
2659 that executes once.  Thus C<last> can be used to effect an early
2660 exit out of such a block.
2661
2662 See also L</continue> for an illustration of how C<last>, C<next>, and
2663 C<redo> work.
2664
2665 =item lc EXPR
2666 X<lc> X<lowercase>
2667
2668 =item lc
2669
2670 Returns a lowercased version of EXPR.  This is the internal function
2671 implementing the C<\L> escape in double-quoted strings.  Respects
2672 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2673 and L<perlunicode> for more details about locale and Unicode support.
2674
2675 If EXPR is omitted, uses C<$_>.
2676
2677 =item lcfirst EXPR
2678 X<lcfirst> X<lowercase>
2679
2680 =item lcfirst
2681
2682 Returns the value of EXPR with the first character lowercased.  This
2683 is the internal function implementing the C<\l> escape in
2684 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2685 locale> in force.  See L<perllocale> and L<perlunicode> for more
2686 details about locale and Unicode support.
2687
2688 If EXPR is omitted, uses C<$_>.
2689
2690 =item length EXPR
2691 X<length> X<size>
2692
2693 =item length
2694
2695 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2696 omitted, returns length of C<$_>.  If EXPR is undefined, returns C<undef>.
2697 Note that this cannot be used on an entire array or hash to find out how
2698 many elements these have. For that, use C<scalar @array> and C<scalar keys
2699 %hash> respectively.
2700
2701 Note the I<characters>: if the EXPR is in Unicode, you will get the
2702 number of characters, not the number of bytes.  To get the length
2703 of the internal string in bytes, use C<bytes::length(EXPR)>, see
2704 L<bytes>.  Note that the internal encoding is variable, and the number
2705 of bytes usually meaningless.  To get the number of bytes that the
2706 string would have when encoded as UTF-8, use
2707 C<length(Encoding::encode_utf8(EXPR))>.
2708
2709 =item link OLDFILE,NEWFILE
2710 X<link>
2711
2712 Creates a new filename linked to the old filename.  Returns true for
2713 success, false otherwise.
2714
2715 =item listen SOCKET,QUEUESIZE
2716 X<listen>
2717
2718 Does the same thing that the listen system call does.  Returns true if
2719 it succeeded, false otherwise.  See the example in
2720 L<perlipc/"Sockets: Client/Server Communication">.
2721
2722 =item local EXPR
2723 X<local>
2724
2725 You really probably want to be using C<my> instead, because C<local> isn't
2726 what most people think of as "local".  See
2727 L<perlsub/"Private Variables via my()"> for details.
2728
2729 A local modifies the listed variables to be local to the enclosing
2730 block, file, or eval.  If more than one value is listed, the list must
2731 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2732 for details, including issues with tied arrays and hashes.
2733
2734 =item localtime EXPR
2735 X<localtime> X<ctime>
2736
2737 =item localtime
2738
2739 Converts a time as returned by the time function to a 9-element list
2740 with the time analyzed for the local time zone.  Typically used as
2741 follows:
2742
2743     #  0    1    2     3     4    5     6     7     8
2744     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2745                                                 localtime(time);
2746
2747 All list elements are numeric, and come straight out of the C `struct
2748 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2749 of the specified time.
2750
2751 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2752 the range C<0..11> with 0 indicating January and 11 indicating December.
2753 This makes it easy to get a month name from a list:
2754
2755     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2756     print "$abbr[$mon] $mday";
2757     # $mon=9, $mday=18 gives "Oct 18"
2758
2759 C<$year> is the number of years since 1900, not just the last two digits
2760 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2761 to get a complete 4-digit year is simply:
2762
2763     $year += 1900;
2764
2765 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
2766 to do that, would you?
2767
2768 To get the last two digits of the year (e.g., '01' in 2001) do:
2769
2770     $year = sprintf("%02d", $year % 100);
2771
2772 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2773 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2774 (or C<0..365> in leap years.)
2775
2776 C<$isdst> is true if the specified time occurs during Daylight Saving
2777 Time, false otherwise.
2778
2779 If EXPR is omitted, C<localtime()> uses the current time (as returned
2780 by time(3)).
2781
2782 In scalar context, C<localtime()> returns the ctime(3) value:
2783
2784     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2785
2786 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2787 instead of local time use the L</gmtime> builtin. See also the
2788 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2789 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2790 and mktime(3) functions.
2791
2792 To get somewhat similar but locale dependent date strings, set up your
2793 locale environment variables appropriately (please see L<perllocale>) and
2794 try for example:
2795
2796     use POSIX qw(strftime);
2797     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2798     # or for GMT formatted appropriately for your locale:
2799     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2800
2801 Note that the C<%a> and C<%b>, the short forms of the day of the week
2802 and the month of the year, may not necessarily be three characters wide.
2803
2804 See L<perlport/localtime> for portability concerns.
2805
2806 The L<Time::gmtime> and L<Time::localtime> modules provides a convenient,
2807 by-name access mechanism to the gmtime() and localtime() functions,
2808 respectively.
2809
2810 For a comprehensive date and time representation look at the
2811 L<DateTime> module on CPAN.
2812
2813 =item lock THING
2814 X<lock>
2815
2816 This function places an advisory lock on a shared variable, or referenced
2817 object contained in I<THING> until the lock goes out of scope.
2818
2819 lock() is a "weak keyword" : this means that if you've defined a function
2820 by this name (before any calls to it), that function will be called
2821 instead. (However, if you've said C<use threads>, lock() is always a
2822 keyword.) See L<threads>.
2823
2824 =item log EXPR
2825 X<log> X<logarithm> X<e> X<ln> X<base>
2826
2827 =item log
2828
2829 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2830 returns log of C<$_>.  To get the log of another base, use basic algebra:
2831 The base-N log of a number is equal to the natural log of that number
2832 divided by the natural log of N.  For example:
2833
2834     sub log10 {
2835         my $n = shift;
2836         return log($n)/log(10);
2837     }
2838
2839 See also L</exp> for the inverse operation.
2840
2841 =item lstat EXPR
2842 X<lstat>
2843
2844 =item lstat
2845
2846 Does the same thing as the C<stat> function (including setting the
2847 special C<_> filehandle) but stats a symbolic link instead of the file
2848 the symbolic link points to.  If symbolic links are unimplemented on
2849 your system, a normal C<stat> is done.  For much more detailed
2850 information, please see the documentation for C<stat>.
2851
2852 If EXPR is omitted, stats C<$_>.
2853
2854 =item m//
2855
2856 The match operator.  See L<perlop>.
2857
2858 =item map BLOCK LIST
2859 X<map>
2860
2861 =item map EXPR,LIST
2862
2863 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2864 C<$_> to each element) and returns the list value composed of the
2865 results of each such evaluation.  In scalar context, returns the
2866 total number of elements so generated.  Evaluates BLOCK or EXPR in
2867 list context, so each element of LIST may produce zero, one, or
2868 more elements in the returned value.
2869
2870     @chars = map(chr, @nums);
2871
2872 translates a list of numbers to the corresponding characters.  And
2873
2874     %hash = map { get_a_key_for($_) => $_ } @array;
2875
2876 is just a funny way to write
2877
2878     %hash = ();
2879     foreach (@array) {
2880         $hash{get_a_key_for($_)} = $_;
2881     }
2882
2883 Note that C<$_> is an alias to the list value, so it can be used to
2884 modify the elements of the LIST.  While this is useful and supported,
2885 it can cause bizarre results if the elements of LIST are not variables.
2886 Using a regular C<foreach> loop for this purpose would be clearer in
2887 most cases.  See also L</grep> for an array composed of those items of
2888 the original list for which the BLOCK or EXPR evaluates to true.
2889
2890 If C<$_> is lexical in the scope where the C<map> appears (because it has
2891 been declared with C<my $_>), then, in addition to being locally aliased to
2892 the list elements, C<$_> keeps being lexical inside the block; that is, it
2893 can't be seen from the outside, avoiding any potential side-effects.
2894
2895 C<{> starts both hash references and blocks, so C<map { ...> could be either
2896 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2897 ahead for the closing C<}> it has to take a guess at which its dealing with
2898 based what it finds just after the C<{>. Usually it gets it right, but if it
2899 doesn't it won't realize something is wrong until it gets to the C<}> and
2900 encounters the missing (or unexpected) comma. The syntax error will be
2901 reported close to the C<}> but you'll need to change something near the C<{>
2902 such as using a unary C<+> to give perl some help:
2903
2904     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2905     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2906     %hash = map { ("\L$_", 1) } @array  # this also works
2907     %hash = map {  lc($_), 1  } @array  # as does this.
2908     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2909
2910     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2911
2912 or to force an anon hash constructor use C<+{>:
2913
2914    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2915
2916 and you get list of anonymous hashes each with only 1 entry.
2917
2918 =item mkdir FILENAME,MASK
2919 X<mkdir> X<md> X<directory, create>
2920
2921 =item mkdir FILENAME
2922
2923 =item mkdir
2924
2925 Creates the directory specified by FILENAME, with permissions
2926 specified by MASK (as modified by C<umask>).  If it succeeds it
2927 returns true, otherwise it returns false and sets C<$!> (errno).
2928 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2929 to C<$_>.
2930
2931 In general, it is better to create directories with permissive MASK,
2932 and let the user modify that with their C<umask>, than it is to supply
2933 a restrictive MASK and give the user no way to be more permissive.
2934 The exceptions to this rule are when the file or directory should be
2935 kept private (mail files, for instance).  The perlfunc(1) entry on
2936 C<umask> discusses the choice of MASK in more detail.
2937
2938 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2939 number of trailing slashes.  Some operating and filesystems do not get
2940 this right, so Perl automatically removes all trailing slashes to keep
2941 everyone happy.
2942
2943 In order to recursively create a directory structure look at
2944 the C<mkpath> function of the L<File::Path> module.
2945
2946 =item msgctl ID,CMD,ARG
2947 X<msgctl>
2948
2949 Calls the System V IPC function msgctl(2).  You'll probably have to say
2950
2951     use IPC::SysV;
2952
2953 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2954 then ARG must be a variable that will hold the returned C<msqid_ds>
2955 structure.  Returns like C<ioctl>: the undefined value for error,
2956 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2957 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2958
2959 =item msgget KEY,FLAGS
2960 X<msgget>
2961
2962 Calls the System V IPC function msgget(2).  Returns the message queue
2963 id, or the undefined value if there is an error.  See also
2964 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2965
2966 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2967 X<msgrcv>
2968
2969 Calls the System V IPC function msgrcv to receive a message from
2970 message queue ID into variable VAR with a maximum message size of
2971 SIZE.  Note that when a message is received, the message type as a
2972 native long integer will be the first thing in VAR, followed by the
2973 actual message.  This packing may be opened with C<unpack("l! a*")>.
2974 Taints the variable.  Returns true if successful, or false if there is
2975 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2976 C<IPC::SysV::Msg> documentation.
2977
2978 =item msgsnd ID,MSG,FLAGS
2979 X<msgsnd>
2980
2981 Calls the System V IPC function msgsnd to send the message MSG to the
2982 message queue ID.  MSG must begin with the native long integer message
2983 type, and be followed by the length of the actual message, and finally
2984 the message itself.  This kind of packing can be achieved with
2985 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2986 or false if there is an error.  See also C<IPC::SysV>
2987 and C<IPC::SysV::Msg> documentation.
2988
2989 =item my EXPR
2990 X<my>
2991
2992 =item my TYPE EXPR
2993
2994 =item my EXPR : ATTRS
2995
2996 =item my TYPE EXPR : ATTRS
2997
2998 A C<my> declares the listed variables to be local (lexically) to the
2999 enclosing block, file, or C<eval>.  If more than one value is listed,
3000 the list must be placed in parentheses.
3001
3002 The exact semantics and interface of TYPE and ATTRS are still
3003 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3004 and attributes are handled using the C<attributes> pragma, or starting
3005 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3006 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3007 L<attributes>, and L<Attribute::Handlers>.
3008
3009 =item next LABEL
3010 X<next> X<continue>
3011
3012 =item next
3013
3014 The C<next> command is like the C<continue> statement in C; it starts
3015 the next iteration of the loop:
3016
3017     LINE: while (<STDIN>) {
3018         next LINE if /^#/;      # discard comments
3019         #...
3020     }
3021
3022 Note that if there were a C<continue> block on the above, it would get
3023 executed even on discarded lines.  If the LABEL is omitted, the command
3024 refers to the innermost enclosing loop.
3025
3026 C<next> cannot be used to exit a block which returns a value such as
3027 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3028 a grep() or map() operation.
3029
3030 Note that a block by itself is semantically identical to a loop
3031 that executes once.  Thus C<next> will exit such a block early.
3032
3033 See also L</continue> for an illustration of how C<last>, C<next>, and
3034 C<redo> work.
3035
3036 =item no Module VERSION LIST
3037 X<no>
3038
3039 =item no Module VERSION
3040
3041 =item no Module LIST
3042
3043 =item no Module
3044
3045 =item no VERSION
3046
3047 See the C<use> function, of which C<no> is the opposite.
3048
3049 =item oct EXPR
3050 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3051
3052 =item oct
3053
3054 Interprets EXPR as an octal string and returns the corresponding
3055 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3056 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3057 binary string.  Leading whitespace is ignored in all three cases.)
3058 The following will handle decimal, binary, octal, and hex in the standard
3059 Perl or C notation:
3060
3061     $val = oct($val) if $val =~ /^0/;
3062
3063 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3064 in octal), use sprintf() or printf():
3065
3066     $perms = (stat("filename"))[2] & 07777;
3067     $oct_perms = sprintf "%lo", $perms;
3068
3069 The oct() function is commonly used when a string such as C<644> needs
3070 to be converted into a file mode, for example. (Although perl will
3071 automatically convert strings into numbers as needed, this automatic
3072 conversion assumes base 10.)
3073
3074 =item open FILEHANDLE,EXPR
3075 X<open> X<pipe> X<file, open> X<fopen>
3076
3077 =item open FILEHANDLE,MODE,EXPR
3078
3079 =item open FILEHANDLE,MODE,EXPR,LIST
3080
3081 =item open FILEHANDLE,MODE,REFERENCE
3082
3083 =item open FILEHANDLE
3084
3085 Opens the file whose filename is given by EXPR, and associates it with
3086 FILEHANDLE.
3087
3088 Simple examples to open a file for reading:
3089
3090     open(my $fh, '<', "input.txt") or die $!;
3091
3092 and for writing:
3093
3094     open(my $fh, '>', "output.txt") or die $!;
3095
3096 (The following is a comprehensive reference to open(): for a gentler
3097 introduction you may consider L<perlopentut>.)
3098
3099 If FILEHANDLE is an undefined scalar variable (or array or hash element)
3100 the variable is assigned a reference to a new anonymous filehandle,
3101 otherwise if FILEHANDLE is an expression, its value is used as the name of
3102 the real filehandle wanted.  (This is considered a symbolic reference, so
3103 C<use strict 'refs'> should I<not> be in effect.)
3104
3105 If EXPR is omitted, the scalar variable of the same name as the
3106 FILEHANDLE contains the filename.  (Note that lexical variables--those
3107 declared with C<my>--will not work for this purpose; so if you're
3108 using C<my>, specify EXPR in your call to open.)
3109
3110 If three or more arguments are specified then the mode of opening and
3111 the file name are separate. If MODE is C<< '<' >> or nothing, the file
3112 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
3113 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
3114 the file is opened for appending, again being created if necessary.
3115
3116 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
3117 indicate that you want both read and write access to the file; thus
3118 C<< '+<' >> is almost always preferred for read/write updates--the C<<
3119 '+>' >> mode would clobber the file first.  You can't usually use
3120 either read-write mode for updating textfiles, since they have
3121 variable length records.  See the B<-i> switch in L<perlrun> for a
3122 better approach.  The file is created with permissions of C<0666>
3123 modified by the process' C<umask> value.
3124
3125 These various prefixes correspond to the fopen(3) modes of C<'r'>,
3126 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
3127
3128 In the 2-arguments (and 1-argument) form of the call the mode and
3129 filename should be concatenated (in this order), possibly separated by
3130 spaces.  It is possible to omit the mode in these forms if the mode is
3131 C<< '<' >>.
3132
3133 If the filename begins with C<'|'>, the filename is interpreted as a
3134 command to which output is to be piped, and if the filename ends with a
3135 C<'|'>, the filename is interpreted as a command which pipes output to
3136 us.  See L<perlipc/"Using open() for IPC">
3137 for more examples of this.  (You are not allowed to C<open> to a command
3138 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
3139 and L<perlipc/"Bidirectional Communication with Another Process">
3140 for alternatives.)
3141
3142 For three or more arguments if MODE is C<'|-'>, the filename is
3143 interpreted as a command to which output is to be piped, and if MODE
3144 is C<'-|'>, the filename is interpreted as a command which pipes
3145 output to us.  In the 2-arguments (and 1-argument) form one should
3146 replace dash (C<'-'>) with the command.
3147 See L<perlipc/"Using open() for IPC"> for more examples of this.
3148 (You are not allowed to C<open> to a command that pipes both in I<and>
3149 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3150 L<perlipc/"Bidirectional Communication"> for alternatives.)
3151
3152 In the three-or-more argument form of pipe opens, if LIST is specified
3153 (extra arguments after the command name) then LIST becomes arguments
3154 to the command invoked if the platform supports it.  The meaning of
3155 C<open> with more than three arguments for non-pipe modes is not yet
3156 specified. Experimental "layers" may give extra LIST arguments
3157 meaning.
3158
3159 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
3160 and opening C<< '>-' >> opens STDOUT.
3161
3162 You may use the three-argument form of open to specify IO "layers"
3163 (sometimes also referred to as "disciplines") to be applied to the handle
3164 that affect how the input and output are processed (see L<open> and
3165 L<PerlIO> for more details). For example
3166
3167   open(my $fh, "<:encoding(UTF-8)", "file")
3168
3169 will open the UTF-8 encoded file containing Unicode characters,
3170 see L<perluniintro>. Note that if layers are specified in the
3171 three-arg form then default layers stored in ${^OPEN} (see L<perlvar>;
3172 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3173
3174 Open returns nonzero upon success, the undefined value otherwise.  If
3175 the C<open> involved a pipe, the return value happens to be the pid of
3176 the subprocess.
3177
3178 If you're running Perl on a system that distinguishes between text
3179 files and binary files, then you should check out L</binmode> for tips
3180 for dealing with this.  The key distinction between systems that need
3181 C<binmode> and those that don't is their text file formats.  Systems
3182 like Unix, Mac OS, and Plan 9, which delimit lines with a single
3183 character, and which encode that character in C as C<"\n">, do not
3184 need C<binmode>.  The rest need it.
3185
3186 When opening a file, it's usually a bad idea to continue normal execution
3187 if the request failed, so C<open> is frequently used in connection with
3188 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3189 where you want to make a nicely formatted error message (but there are
3190 modules that can help with that problem)) you should always check
3191 the return value from opening a file.  The infrequent exception is when
3192 working with an unopened filehandle is actually what you want to do.
3193
3194 As a special case the 3-arg form with a read/write mode and the third
3195 argument being C<undef>:
3196
3197     open(my $tmp, "+>", undef) or die ...
3198
3199 opens a filehandle to an anonymous temporary file.  Also using "+<"
3200 works for symmetry, but you really should consider writing something
3201 to the temporary file first.  You will need to seek() to do the
3202 reading.
3203
3204 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
3205 changed this (i.e. Configure -Uuseperlio), you can open file handles to
3206 "in memory" files held in Perl scalars via:
3207
3208     open($fh, '>', \$variable) || ..
3209
3210 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
3211 file, you have to close it first:
3212
3213     close STDOUT;
3214     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3215
3216 Examples:
3217
3218     $ARTICLE = 100;
3219     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3220     while (<ARTICLE>) {...
3221
3222     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
3223     # if the open fails, output is discarded
3224
3225     open(my $dbase, '+<', 'dbase.mine')         # open for update
3226         or die "Can't open 'dbase.mine' for update: $!";
3227
3228     open(my $dbase, '+<dbase.mine')                     # ditto
3229         or die "Can't open 'dbase.mine' for update: $!";
3230
3231     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
3232         or die "Can't start caesar: $!";
3233
3234     open(ARTICLE, "caesar <$article |")         # ditto
3235         or die "Can't start caesar: $!";
3236
3237     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
3238         or die "Can't start sort: $!";
3239
3240     # in memory files
3241     open(MEMORY,'>', \$var)
3242         or die "Can't open memory file: $!";
3243     print MEMORY "foo!\n";                      # output will end up in $var
3244
3245     # process argument list of files along with any includes
3246
3247     foreach $file (@ARGV) {
3248         process($file, 'fh00');
3249     }
3250
3251     sub process {
3252         my($filename, $input) = @_;
3253         $input++;               # this is a string increment
3254         unless (open($input, $filename)) {
3255             print STDERR "Can't open $filename: $!\n";
3256             return;
3257         }
3258
3259         local $_;
3260         while (<$input>) {              # note use of indirection
3261             if (/^#include "(.*)"/) {
3262                 process($1, $input);
3263                 next;
3264             }
3265             #...                # whatever
3266         }
3267     }
3268
3269 See L<perliol> for detailed info on PerlIO.
3270
3271 You may also, in the Bourne shell tradition, specify an EXPR beginning
3272 with C<< '>&' >>, in which case the rest of the string is interpreted
3273 as the name of a filehandle (or file descriptor, if numeric) to be
3274 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3275 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3276 The mode you specify should match the mode of the original filehandle.
3277 (Duping a filehandle does not take into account any existing contents
3278 of IO buffers.) If you use the 3-arg form then you can pass either a
3279 number, the name of a filehandle or the normal "reference to a glob".
3280
3281 Here is a script that saves, redirects, and restores C<STDOUT> and
3282 C<STDERR> using various methods:
3283
3284     #!/usr/bin/perl
3285     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3286     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3287
3288     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3289     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3290
3291     select STDERR; $| = 1;      # make unbuffered
3292     select STDOUT; $| = 1;      # make unbuffered
3293
3294     print STDOUT "stdout 1\n";  # this works for
3295     print STDERR "stderr 1\n";  # subprocesses too
3296
3297     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3298     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3299
3300     print STDOUT "stdout 2\n";
3301     print STDERR "stderr 2\n";
3302
3303 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3304 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3305 that file descriptor (and not call L<dup(2)>); this is more
3306 parsimonious of file descriptors.  For example:
3307
3308     # open for input, reusing the fileno of $fd
3309     open(FILEHANDLE, "<&=$fd")
3310
3311 or
3312
3313     open(FILEHANDLE, "<&=", $fd)
3314
3315 or
3316
3317     # open for append, using the fileno of OLDFH
3318     open(FH, ">>&=", OLDFH)
3319
3320 or
3321
3322     open(FH, ">>&=OLDFH")
3323
3324 Being parsimonious on filehandles is also useful (besides being
3325 parsimonious) for example when something is dependent on file
3326 descriptors, like for example locking using flock().  If you do just
3327 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3328 descriptor as B, and therefore flock(A) will not flock(B), and vice
3329 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3330 the same file descriptor.
3331
3332 Note that if you are using Perls older than 5.8.0, Perl will be using
3333 the standard C libraries' fdopen() to implement the "=" functionality.
3334 On many UNIX systems fdopen() fails when file descriptors exceed a
3335 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3336 most often the default.
3337
3338 You can see whether Perl has been compiled with PerlIO or not by
3339 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3340 is C<define>, you have PerlIO, otherwise you don't.
3341
3342 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3343 with 2-arguments (or 1-argument) form of open(), then
3344 there is an implicit fork done, and the return value of open is the pid
3345 of the child within the parent process, and C<0> within the child
3346 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3347 The filehandle behaves normally for the parent, but i/o to that
3348 filehandle is piped from/to the STDOUT/STDIN of the child process.
3349 In the child process the filehandle isn't opened--i/o happens from/to
3350 the new STDOUT or STDIN.  Typically this is used like the normal
3351 piped open when you want to exercise more control over just how the
3352 pipe command gets executed, such as when you are running setuid, and
3353 don't want to have to scan shell commands for metacharacters.
3354 The following triples are more or less equivalent:
3355
3356     open(FOO, "|tr '[a-z]' '[A-Z]'");
3357     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3358     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3359     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3360
3361     open(FOO, "cat -n '$file'|");
3362     open(FOO, '-|', "cat -n '$file'");
3363     open(FOO, '-|') || exec 'cat', '-n', $file;
3364     open(FOO, '-|', "cat", '-n', $file);
3365
3366 The last example in each block shows the pipe as "list form", which is
3367 not yet supported on all platforms.  A good rule of thumb is that if
3368 your platform has true C<fork()> (in other words, if your platform is
3369 UNIX) you can use the list form.
3370
3371 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3372
3373 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3374 output before any operation that may do a fork, but this may not be
3375 supported on some platforms (see L<perlport>).  To be safe, you may need
3376 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3377 of C<IO::Handle> on any open handles.
3378
3379 On systems that support a close-on-exec flag on files, the flag will
3380 be set for the newly opened file descriptor as determined by the value
3381 of $^F.  See L<perlvar/$^F>.
3382
3383 Closing any piped filehandle causes the parent process to wait for the
3384 child to finish, and returns the status value in C<$?> and
3385 C<${^CHILD_ERROR_NATIVE}>.
3386
3387 The filename passed to 2-argument (or 1-argument) form of open() will
3388 have leading and trailing whitespace deleted, and the normal
3389 redirection characters honored.  This property, known as "magic open",
3390 can often be used to good effect.  A user could specify a filename of
3391 F<"rsh cat file |">, or you could change certain filenames as needed:
3392
3393     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3394     open(FH, $filename) or die "Can't open $filename: $!";
3395
3396 Use 3-argument form to open a file with arbitrary weird characters in it,
3397
3398     open(FOO, '<', $file);
3399
3400 otherwise it's necessary to protect any leading and trailing whitespace:
3401
3402     $file =~ s#^(\s)#./$1#;
3403     open(FOO, "< $file\0");
3404
3405 (this may not work on some bizarre filesystems).  One should
3406 conscientiously choose between the I<magic> and 3-arguments form
3407 of open():
3408
3409     open IN, $ARGV[0];
3410
3411 will allow the user to specify an argument of the form C<"rsh cat file |">,
3412 but will not work on a filename which happens to have a trailing space, while
3413
3414     open IN, '<', $ARGV[0];
3415
3416 will have exactly the opposite restrictions.
3417
3418 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3419 should use the C<sysopen> function, which involves no such magic (but
3420 may use subtly different filemodes than Perl open(), which is mapped
3421 to C fopen()).  This is
3422 another way to protect your filenames from interpretation.  For example:
3423
3424     use IO::Handle;
3425     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3426         or die "sysopen $path: $!";
3427     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3428     print HANDLE "stuff $$\n";
3429     seek(HANDLE, 0, 0);
3430     print "File contains: ", <HANDLE>;
3431
3432 Using the constructor from the C<IO::Handle> package (or one of its
3433 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3434 filehandles that have the scope of whatever variables hold references to
3435 them, and automatically close whenever and however you leave that scope:
3436
3437     use IO::File;
3438     #...
3439     sub read_myfile_munged {
3440         my $ALL = shift;
3441         my $handle = IO::File->new;
3442         open($handle, "myfile") or die "myfile: $!";
3443         $first = <$handle>
3444             or return ();     # Automatically closed here.
3445         mung $first or die "mung failed";       # Or here.
3446         return $first, <$handle> if $ALL;       # Or here.
3447         $first;                                 # Or here.
3448     }
3449
3450 See L</seek> for some details about mixing reading and writing.
3451
3452 =item opendir DIRHANDLE,EXPR
3453 X<opendir>
3454
3455 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3456 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3457 DIRHANDLE may be an expression whose value can be used as an indirect
3458 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3459 scalar variable (or array or hash element), the variable is assigned a
3460 reference to a new anonymous dirhandle.
3461 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3462
3463 See example at C<readdir>.
3464
3465 =item ord EXPR
3466 X<ord> X<encoding>
3467
3468 =item ord
3469
3470 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3471 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3472 uses C<$_>.
3473
3474 For the reverse, see L</chr>.
3475 See L<perlunicode> for more about Unicode.
3476
3477 =item our EXPR
3478 X<our> X<global>
3479
3480 =item our TYPE EXPR
3481
3482 =item our EXPR : ATTRS
3483
3484 =item our TYPE EXPR : ATTRS
3485
3486 C<our> associates a simple name with a package variable in the current
3487 package for use within the current scope.  When C<use strict 'vars'> is in
3488 effect, C<our> lets you use declared global variables without qualifying
3489 them with package names, within the lexical scope of the C<our> declaration.
3490 In this way C<our> differs from C<use vars>, which is package scoped.
3491
3492 Unlike C<my>, which both allocates storage for a variable and associates
3493 a simple name with that storage for use within the current scope, C<our>
3494 associates a simple name with a package variable in the current package,
3495 for use within the current scope.  In other words, C<our> has the same
3496 scoping rules as C<my>, but does not necessarily create a
3497 variable.
3498
3499 If more than one value is listed, the list must be placed
3500 in parentheses.
3501
3502     our $foo;
3503     our($bar, $baz);
3504
3505 An C<our> declaration declares a global variable that will be visible
3506 across its entire lexical scope, even across package boundaries.  The
3507 package in which the variable is entered is determined at the point
3508 of the declaration, not at the point of use.  This means the following
3509 behavior holds:
3510
3511     package Foo;
3512     our $bar;           # declares $Foo::bar for rest of lexical scope
3513     $bar = 20;
3514
3515     package Bar;
3516     print $bar;         # prints 20, as it refers to $Foo::bar
3517
3518 Multiple C<our> declarations with the same name in the same lexical
3519 scope are allowed if they are in different packages.  If they happen
3520 to be in the same package, Perl will emit warnings if you have asked
3521 for them, just like multiple C<my> declarations.  Unlike a second
3522 C<my> declaration, which will bind the name to a fresh variable, a
3523 second C<our> declaration in the same package, in the same scope, is
3524 merely redundant.
3525
3526     use warnings;
3527     package Foo;
3528     our $bar;           # declares $Foo::bar for rest of lexical scope
3529     $bar = 20;
3530
3531     package Bar;
3532     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3533     print $bar;         # prints 30
3534
3535     our $bar;           # emits warning but has no other effect
3536     print $bar;         # still prints 30
3537
3538 An C<our> declaration may also have a list of attributes associated
3539 with it.
3540
3541 The exact semantics and interface of TYPE and ATTRS are still
3542 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3543 and attributes are handled using the C<attributes> pragma, or starting
3544 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3545 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3546 L<attributes>, and L<Attribute::Handlers>.
3547
3548 =item pack TEMPLATE,LIST
3549 X<pack>
3550
3551 Takes a LIST of values and converts it into a string using the rules
3552 given by the TEMPLATE.  The resulting string is the concatenation of
3553 the converted values.  Typically, each converted value looks
3554 like its machine-level representation.  For example, on 32-bit machines
3555 an integer may be represented by a sequence of 4 bytes that will be 
3556 converted to a sequence of 4 characters.
3557
3558 The TEMPLATE is a sequence of characters that give the order and type
3559 of values, as follows:
3560
3561     a   A string with arbitrary binary data, will be null padded.
3562     A   A text (ASCII) string, will be space padded.
3563     Z   A null terminated (ASCIZ) string, will be null padded.
3564
3565     b   A bit string (ascending bit order inside each byte, like vec()).
3566     B   A bit string (descending bit order inside each byte).
3567     h   A hex string (low nybble first).
3568     H   A hex string (high nybble first).
3569
3570     c   A signed char (8-bit) value.
3571     C   An unsigned char (octet) value.
3572     W   An unsigned char value (can be greater than 255).
3573
3574     s   A signed short (16-bit) value.
3575     S   An unsigned short value.
3576
3577     l   A signed long (32-bit) value.
3578     L   An unsigned long value.
3579
3580     q   A signed quad (64-bit) value.
3581     Q   An unsigned quad value.
3582           (Quads are available only if your system supports 64-bit
3583            integer values _and_ if Perl has been compiled to support those.
3584            Causes a fatal error otherwise.)
3585
3586     i   A signed integer value.
3587     I   A unsigned integer value.
3588           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3589            size depends on what a local C compiler calls 'int'.)
3590
3591     n   An unsigned short (16-bit) in "network" (big-endian) order.
3592     N   An unsigned long (32-bit) in "network" (big-endian) order.
3593     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3594     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3595
3596     j   A Perl internal signed integer value (IV).
3597     J   A Perl internal unsigned integer value (UV).
3598
3599     f   A single-precision float in the native format.
3600     d   A double-precision float in the native format.
3601
3602     F   A Perl internal floating point value (NV) in the native format
3603     D   A long double-precision float in the native format.
3604           (Long doubles are available only if your system supports long
3605            double values _and_ if Perl has been compiled to support those.
3606            Causes a fatal error otherwise.)
3607
3608     p   A pointer to a null-terminated string.
3609     P   A pointer to a structure (fixed-length string).
3610
3611     u   A uuencoded string.
3612     U   A Unicode character number.  Encodes to a character in character mode
3613         and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in byte mode.
3614
3615     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3616         details).  Its bytes represent an unsigned integer in base 128,
3617         most significant digit first, with as few digits as possible.  Bit
3618         eight (the high bit) is set on each byte except the last.
3619
3620     x   A null byte.
3621     X   Back up a byte.
3622     @   Null fill or truncate to absolute position, counted from the
3623         start of the innermost ()-group.
3624     .   Null fill or truncate to absolute position specified by value.
3625     (   Start of a ()-group.
3626
3627 One or more of the modifiers below may optionally follow some letters in the
3628 TEMPLATE (the second column lists the letters for which the modifier is
3629 valid):
3630
3631     !   sSlLiI     Forces native (short, long, int) sizes instead
3632                    of fixed (16-/32-bit) sizes.
3633
3634         xX         Make x and X act as alignment commands.
3635
3636         nNvV       Treat integers as signed instead of unsigned.
3637
3638         @.         Specify position as byte offset in the internal
3639                    representation of the packed string. Efficient but
3640                    dangerous.
3641
3642     >   sSiIlLqQ   Force big-endian byte-order on the type.
3643         jJfFdDpP   (The "big end" touches the construct.)
3644
3645     <   sSiIlLqQ   Force little-endian byte-order on the type.
3646         jJfFdDpP   (The "little end" touches the construct.)
3647
3648 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3649 in which case they force a certain byte-order on all components of
3650 that group, including subgroups.
3651
3652 The following rules apply:
3653
3654 =over 8
3655
3656 =item *
3657
3658 Each letter may optionally be followed by a number giving a repeat
3659 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3660 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3661 that many values from the LIST.  A C<*> for the repeat count means to
3662 use however many items are left, except for C<@>, C<x>, C<X>, where it
3663 is equivalent to C<0>, for <.> where it means relative to string start
3664 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3665 A numeric repeat count may optionally be enclosed in brackets, as in
3666 C<pack 'C[80]', @arr>.
3667
3668 One can replace the numeric repeat count by a template enclosed in brackets;
3669 then the packed length of this template in bytes is used as a count.
3670 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3671 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3672 If the template in brackets contains alignment commands (such as C<x![d]>),
3673 its packed length is calculated as if the start of the template has the maximal
3674 possible alignment.
3675
3676 When used with C<Z>, C<*> results in the addition of a trailing null
3677 byte (so the packed result will be one longer than the byte C<length>
3678 of the item).
3679
3680 When used with C<@>, the repeat count represents an offset from the start
3681 of the innermost () group.
3682
3683 When used with C<.>, the repeat count is used to determine the starting
3684 position from where the value offset is calculated. If the repeat count
3685 is 0, it's relative to the current position. If the repeat count is C<*>,
3686 the offset is relative to the start of the packed string. And if its an
3687 integer C<n> the offset is relative to the start of the n-th innermost
3688 () group (or the start of the string if C<n> is bigger then the group
3689 level).
3690
3691 The repeat count for C<u> is interpreted as the maximal number of bytes
3692 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3693 count should not be more than 65.
3694
3695 =item *
3696
3697 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3698 string of length count, padding with nulls or spaces as necessary.  When
3699 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3700 after the first null, and C<a> returns data verbatim.
3701
3702 If the value-to-pack is too long, it is truncated.  If too long and an
3703 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3704 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3705 count is 0).
3706
3707 =item *
3708
3709 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3710 Each character of the input field of pack() generates 1 bit of the result.
3711 Each result bit is based on the least-significant bit of the corresponding
3712 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3713 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3714
3715 Starting from the beginning of the input string of pack(), each 8-tuple
3716 of characters is converted to 1 character of output.  With format C<b>
3717 the first character of the 8-tuple determines the least-significant bit of a
3718 character, and with format C<B> it determines the most-significant bit of
3719 a character.
3720
3721 If the length of the input string is not exactly divisible by 8, the
3722 remainder is packed as if the input string were padded by null characters
3723 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3724
3725 If the input string of pack() is longer than needed, extra characters are 
3726 ignored. A C<*> for the repeat count of pack() means to use all the 
3727 characters of the input field.  On unpack()ing the bits are converted to a 
3728 string of C<"0">s and C<"1">s.
3729
3730 =item *
3731
3732 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3733 representable as hexadecimal digits, 0-9a-f) long.
3734
3735 Each character of the input field of pack() generates 4 bits of the result.
3736 For non-alphabetical characters the result is based on the 4 least-significant
3737 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3738 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3739 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3740 is compatible with the usual hexadecimal digits, so that C<"a"> and
3741 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3742 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3743
3744 Starting from the beginning of the input string of pack(), each pair
3745 of characters is converted to 1 character of output.  With format C<h> the
3746 first character of the pair determines the least-significant nybble of the
3747 output character, and with format C<H> it determines the most-significant
3748 nybble.
3749
3750 If the length of the input string is not even, it behaves as if padded
3751 by a null character at the end.  Similarly, during unpack()ing the "extra"
3752 nybbles are ignored.
3753
3754 If the input string of pack() is longer than needed, extra characters are
3755 ignored.
3756 A C<*> for the repeat count of pack() means to use all the characters of
3757 the input field.  On unpack()ing the nybbles are converted to a string
3758 of hexadecimal digits.
3759
3760 =item *
3761
3762 The C<p> type packs a pointer to a null-terminated string.  You are
3763 responsible for ensuring the string is not a temporary value (which can
3764 potentially get deallocated before you get around to using the packed result).
3765 The C<P> type packs a pointer to a structure of the size indicated by the
3766 length.  A NULL pointer is created if the corresponding value for C<p> or
3767 C<P> is C<undef>, similarly for unpack().
3768
3769 If your system has a strange pointer size (i.e. a pointer is neither as
3770 big as an int nor as big as a long), it may not be possible to pack or
3771 unpack pointers in big- or little-endian byte order.  Attempting to do
3772 so will result in a fatal error.
3773
3774 =item *
3775
3776 The C</> template character allows packing and unpacking of a sequence of
3777 items where the packed structure contains a packed item count followed by 
3778 the packed items themselves.
3779
3780 For C<pack> you write I<length-item>C</>I<sequence-item> and the
3781 I<length-item> describes how the length value is packed. The ones likely
3782 to be of most use are integer-packing ones like C<n> (for Java strings),
3783 C<w> (for ASN.1 or SNMP) and C<N> (for Sun XDR).
3784
3785 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3786 the minimum of that and the number of available items is used as argument
3787 for the I<length-item>. If it has no repeat count or uses a '*', the number
3788 of available items is used.
3789
3790 For C<unpack> an internal stack of integer arguments unpacked so far is
3791 used. You write C</>I<sequence-item> and the repeat count is obtained by
3792 popping off the last element from the stack. The I<sequence-item> must not
3793 have a repeat count.
3794
3795 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3796 the I<length-item> is a string length, not a number of strings. If there is
3797 an explicit repeat count for pack, the packed string will be adjusted to that
3798 given length.
3799
3800     unpack 'W/a', "\04Gurusamy";            gives ('Guru')
3801     unpack 'a3/A A*', '007 Bond  J ';       gives (' Bond', 'J')
3802     unpack 'a3 x2 /A A*', '007: Bond, J.';  gives ('Bond, J', '.')
3803     pack 'n/a* w/a','hello,','world';       gives "\000\006hello,\005world"
3804     pack 'a/W2', ord('a') .. ord('z');      gives '2ab'
3805
3806 The I<length-item> is not returned explicitly from C<unpack>.
3807
3808 Adding a count to the I<length-item> letter is unlikely to do anything
3809 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3810 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3811 which Perl does not regard as legal in numeric strings.
3812
3813 =item *
3814
3815 The integer types C<s>, C<S>, C<l>, and C<L> may be
3816 followed by a C<!> modifier to signify native shorts or
3817 longs--as you can see from above for example a bare C<l> does mean
3818 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3819 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3820 see whether using C<!> makes any difference by
3821
3822         print length(pack("s")), " ", length(pack("s!")), "\n";
3823         print length(pack("l")), " ", length(pack("l!")), "\n";
3824
3825 C<i!> and C<I!> also work but only because of completeness;
3826 they are identical to C<i> and C<I>.
3827
3828 The actual sizes (in bytes) of native shorts, ints, longs, and long
3829 longs on the platform where Perl was built are also available via
3830 L<Config>:
3831
3832        use Config;
3833        print $Config{shortsize},    "\n";
3834        print $Config{intsize},      "\n";
3835        print $Config{longsize},     "\n";
3836        print $Config{longlongsize}, "\n";
3837
3838 (The C<$Config{longlongsize}> will be undefined if your system does
3839 not support long longs.)
3840
3841 =item *
3842
3843 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3844 are inherently non-portable between processors and operating systems
3845 because they obey the native byteorder and endianness.  For example a
3846 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3847 (arranged in and handled by the CPU registers) into bytes as
3848
3849         0x12 0x34 0x56 0x78     # big-endian
3850         0x78 0x56 0x34 0x12     # little-endian
3851
3852 Basically, the Intel and VAX CPUs are little-endian, while everybody
3853 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3854 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3855 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3856 mode.
3857
3858 The names `big-endian' and `little-endian' are comic references to
3859 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3860 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3861 the egg-eating habits of the Lilliputians.
3862
3863 Some systems may have even weirder byte orders such as
3864
3865         0x56 0x78 0x12 0x34
3866         0x34 0x12 0x78 0x56
3867
3868 You can see your system's preference with
3869
3870         print join(" ", map { sprintf "%#02x", $_ }
3871                             unpack("W*",pack("L",0x12345678))), "\n";
3872
3873 The byteorder on the platform where Perl was built is also available
3874 via L<Config>:
3875
3876         use Config;
3877         print $Config{byteorder}, "\n";
3878
3879 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3880 and C<'87654321'> are big-endian.
3881
3882 If you want portable packed integers you can either use the formats
3883 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3884 modifiers.  These modifiers are only available as of perl 5.9.2.
3885 See also L<perlport>.
3886
3887 =item *
3888
3889 All integer and floating point formats as well as C<p> and C<P> and
3890 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3891 to force big- or little- endian byte-order, respectively.
3892 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3893 signed integers, 64-bit integers and floating point values.  However,
3894 there are some things to keep in mind.
3895
3896 Exchanging signed integers between different platforms only works
3897 if all platforms store them in the same format.  Most platforms store
3898 signed integers in two's complement, so usually this is not an issue.
3899
3900 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3901 formats on big- or little-endian machines.  Otherwise, attempting to
3902 do so will result in a fatal error.
3903
3904 Forcing big- or little-endian byte-order on floating point values for
3905 data exchange can only work if all platforms are using the same
3906 binary representation (e.g. IEEE floating point format).  Even if all
3907 platforms are using IEEE, there may be subtle differences.  Being able
3908 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3909 but also very dangerous if you don't know exactly what you're doing.
3910 It is definitely not a general way to portably store floating point
3911 values.
3912
3913 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3914 all types inside the group that accept the byte-order modifiers,
3915 including all subgroups.  It will silently be ignored for all other
3916 types.  You are not allowed to override the byte-order within a group
3917 that already has a byte-order modifier suffix.
3918
3919 =item *
3920
3921 Real numbers (floats and doubles) are in the native machine format only;
3922 due to the multiplicity of floating formats around, and the lack of a
3923 standard "network" representation, no facility for interchange has been
3924 made.  This means that packed floating point data written on one machine
3925 may not be readable on another - even if both use IEEE floating point
3926 arithmetic (as the endian-ness of the memory representation is not part
3927 of the IEEE spec).  See also L<perlport>.
3928
3929 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3930 modifiers to force big- or little-endian byte-order on floating point values.
3931
3932 Note that Perl uses doubles (or long doubles, if configured) internally for
3933 all numeric calculation, and converting from double into float and thence back
3934 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3935 will not in general equal $foo).
3936
3937 =item *
3938
3939 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3940 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3941 where the packed string is processed in its UTF-8-encoded Unicode form on
3942 a byte by byte basis. Character mode is the default unless the format string 
3943 starts with an C<U>. You can switch mode at any moment with an explicit 
3944 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3945 or until the end of the ()-group in which it was entered.
3946
3947 =item *
3948
3949 You must yourself do any alignment or padding by inserting for example
3950 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3951 could know where the characters are going to or coming from.  Therefore
3952 C<pack> (and C<unpack>) handle their output and input as flat
3953 sequences of characters.
3954
3955 =item *
3956
3957 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3958 take a repeat count, both as postfix, and for unpack() also via the C</>
3959 template character. Within each repetition of a group, positioning with
3960 C<@> starts again at 0. Therefore, the result of
3961
3962     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3963
3964 is the string "\0a\0\0bc".
3965
3966 =item *
3967
3968 C<x> and C<X> accept C<!> modifier.  In this case they act as
3969 alignment commands: they jump forward/back to the closest position
3970 aligned at a multiple of C<count> characters. For example, to pack() or
3971 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3972 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3973 aligned on the double's size.
3974
3975 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3976 both result in no-ops.
3977
3978 =item *
3979
3980 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3981 will represent signed 16-/32-bit integers in big-/little-endian order.
3982 This is only portable if all platforms sharing the packed data use the
3983 same binary representation for signed integers (e.g. all platforms are
3984 using two's complement representation).
3985
3986 =item *
3987
3988 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3989 White space may be used to separate pack codes from each other, but
3990 modifiers and a repeat count must follow immediately.
3991
3992 =item *
3993
3994 If TEMPLATE requires more arguments to pack() than actually given, pack()
3995 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
3996 to pack() than actually given, extra arguments are ignored.
3997
3998 =back
3999
4000 Examples:
4001
4002     $foo = pack("WWWW",65,66,67,68);
4003     # foo eq "ABCD"
4004     $foo = pack("W4",65,66,67,68);
4005     # same thing
4006     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4007     # same thing with Unicode circled letters.
4008     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4009     # same thing with Unicode circled letters. You don't get the UTF-8
4010     # bytes because the U at the start of the format caused a switch to
4011     # U0-mode, so the UTF-8 bytes get joined into characters
4012     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4013     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4014     # This is the UTF-8 encoding of the string in the previous example
4015
4016     $foo = pack("ccxxcc",65,66,67,68);
4017     # foo eq "AB\0\0CD"
4018
4019     # note: the above examples featuring "W" and "c" are true
4020     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4021     # and UTF-8.  In EBCDIC the first example would be
4022     # $foo = pack("WWWW",193,194,195,196);
4023
4024     $foo = pack("s2",1,2);
4025     # "\1\0\2\0" on little-endian
4026     # "\0\1\0\2" on big-endian
4027
4028     $foo = pack("a4","abcd","x","y","z");
4029     # "abcd"
4030
4031     $foo = pack("aaaa","abcd","x","y","z");
4032     # "axyz"
4033
4034     $foo = pack("a14","abcdefg");
4035     # "abcdefg\0\0\0\0\0\0\0"
4036
4037     $foo = pack("i9pl", gmtime);
4038     # a real struct tm (on my system anyway)
4039
4040     $utmp_template = "Z8 Z8 Z16 L";
4041     $utmp = pack($utmp_template, @utmp1);
4042     # a struct utmp (BSDish)
4043
4044     @utmp2 = unpack($utmp_template, $utmp);
4045     # "@utmp1" eq "@utmp2"
4046
4047     sub bintodec {
4048         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4049     }
4050
4051     $foo = pack('sx2l', 12, 34);
4052     # short 12, two zero bytes padding, long 34
4053     $bar = pack('s@4l', 12, 34);
4054     # short 12, zero fill to position 4, long 34
4055     # $foo eq $bar
4056     $baz = pack('s.l', 12, 4, 34);
4057     # short 12, zero fill to position 4, long 34
4058
4059     $foo = pack('nN', 42, 4711);
4060     # pack big-endian 16- and 32-bit unsigned integers
4061     $foo = pack('S>L>', 42, 4711);
4062     # exactly the same
4063     $foo = pack('s<l<', -42, 4711);
4064     # pack little-endian 16- and 32-bit signed integers
4065     $foo = pack('(sl)<', -42, 4711);
4066     # exactly the same
4067
4068 The same template may generally also be used in unpack().
4069
4070 =item package NAMESPACE
4071 X<package> X<module> X<namespace>
4072
4073 =item package
4074
4075 Declares the compilation unit as being in the given namespace.  The scope
4076 of the package declaration is from the declaration itself through the end
4077 of the enclosing block, file, or eval (the same as the C<my> operator).
4078 All further unqualified dynamic identifiers will be in this namespace.
4079 A package statement affects only dynamic variables--including those
4080 you've used C<local> on--but I<not> lexical variables, which are created
4081 with C<my>.  Typically it would be the first declaration in a file to
4082 be included by the C<require> or C<use> operator.  You can switch into a
4083 package in more than one place; it merely influences which symbol table
4084 is used by the compiler for the rest of that block.  You can refer to
4085 variables and filehandles in other packages by prefixing the identifier
4086 with the package name and a double colon:  C<$Package::Variable>.
4087 If the package name is null, the C<main> package as assumed.  That is,
4088 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
4089 still seen in older code).
4090
4091 See L<perlmod/"Packages"> for more information about packages, modules,
4092 and classes.  See L<perlsub> for other scoping issues.
4093
4094 =item pipe READHANDLE,WRITEHANDLE
4095 X<pipe>
4096
4097 Opens a pair of connected pipes like the corresponding system call.
4098 Note that if you set up a loop of piped processes, deadlock can occur
4099 unless you are very careful.  In addition, note that Perl's pipes use
4100 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4101 after each command, depending on the application.
4102
4103 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
4104 for examples of such things.
4105
4106 On systems that support a close-on-exec flag on files, the flag will be set
4107 for the newly opened file descriptors as determined by the value of $^F.
4108 See L<perlvar/$^F>.
4109
4110 =item pop ARRAY
4111 X<pop> X<stack>
4112
4113 =item pop
4114
4115 Pops and returns the last value of the array, shortening the array by
4116 one element.
4117
4118 If there are no elements in the array, returns the undefined value
4119 (although this may happen at other times as well).  If ARRAY is
4120 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
4121 array in subroutines, just like C<shift>.
4122
4123 =item pos SCALAR
4124 X<pos> X<match, position>
4125
4126 =item pos
4127
4128 Returns the offset of where the last C<m//g> search left off for the variable
4129 in question (C<$_> is used when the variable is not specified).  Note that
4130 0 is a valid match offset.  C<undef> indicates that the search position
4131 is reset (usually due to match failure, but can also be because no match has
4132 yet been performed on the scalar). C<pos> directly accesses the location used
4133 by the regexp engine to store the offset, so assigning to C<pos> will change
4134 that offset, and so will also influence the C<\G> zero-width assertion in
4135 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
4136 the return from C<pos> won't change either in this case.  See L<perlre> and
4137 L<perlop>.
4138
4139 =item print FILEHANDLE LIST
4140 X<print>
4141
4142 =item print LIST
4143
4144 =item print
4145
4146 Prints a string or a list of strings.  Returns true if successful.
4147 FILEHANDLE may be a scalar variable name, in which case the variable
4148 contains the name of or a reference to the filehandle, thus introducing
4149 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
4150 the next token is a term, it may be misinterpreted as an operator
4151 unless you interpose a C<+> or put parentheses around the arguments.)
4152 If FILEHANDLE is omitted, prints by default to standard output (or
4153 to the last selected output channel--see L</select>).  If LIST is
4154 also omitted, prints C<$_> to the currently selected output channel.
4155 To set the default output channel to something other than STDOUT
4156 use the select operation.  The current value of C<$,> (if any) is
4157 printed between each LIST item.  The current value of C<$\> (if
4158 any) is printed after the entire LIST has been printed.  Because
4159 print takes a LIST, anything in the LIST is evaluated in list
4160 context, and any subroutine that you call will have one or more of
4161 its expressions evaluated in list context.  Also be careful not to
4162 follow the print keyword with a left parenthesis unless you want
4163 the corresponding right parenthesis to terminate the arguments to
4164 the print--interpose a C<+> or put parentheses around all the
4165 arguments.
4166
4167 Note that if you're storing FILEHANDLEs in an array, or if you're using
4168 any other expression more complex than a scalar variable to retrieve it,
4169 you will have to use a block returning the filehandle value instead:
4170
4171     print { $files[$i] } "stuff\n";
4172     print { $OK ? STDOUT : STDERR } "stuff\n";
4173
4174 =item printf FILEHANDLE FORMAT, LIST
4175 X<printf>
4176
4177 =item printf FORMAT, LIST
4178
4179 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4180 (the output record separator) is not appended.  The first argument
4181 of the list will be interpreted as the C<printf> format. See C<sprintf>
4182 for an explanation of the format argument.  If C<use locale> is in effect,
4183 and POSIX::setlocale() has been called, the character used for the decimal
4184 separator in formatted floating point numbers is affected by the LC_NUMERIC
4185 locale.  See L<perllocale> and L<POSIX>.
4186
4187 Don't fall into the trap of using a C<printf> when a simple
4188 C<print> would do.  The C<print> is more efficient and less
4189 error prone.
4190
4191 =item prototype FUNCTION
4192 X<prototype>
4193
4194 Returns the prototype of a function as a string (or C<undef> if the
4195 function has no prototype).  FUNCTION is a reference to, or the name of,
4196 the function whose prototype you want to retrieve.
4197
4198 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4199 name for Perl builtin.  If the builtin is not I<overridable> (such as
4200 C<qw//>) or if its arguments cannot be adequately expressed by a prototype
4201 (such as C<system>), prototype() returns C<undef>, because the builtin
4202 does not really behave like a Perl function.  Otherwise, the string
4203 describing the equivalent prototype is returned.
4204
4205 =item push ARRAY,LIST
4206 X<push> X<stack>
4207
4208 Treats ARRAY as a stack, and pushes the values of LIST
4209 onto the end of ARRAY.  The length of ARRAY increases by the length of
4210 LIST.  Has the same effect as
4211
4212     for $value (LIST) {
4213         $ARRAY[++$#ARRAY] = $value;
4214     }
4215
4216 but is more efficient.  Returns the number of elements in the array following
4217 the completed C<push>.
4218
4219 =item q/STRING/
4220
4221 =item qq/STRING/
4222
4223 =item qx/STRING/
4224
4225 =item qw/STRING/
4226
4227 Generalized quotes.  See L<perlop/"Quote-Like Operators">.
4228
4229 =item qr/STRING/
4230
4231 Regexp-like quote.  See L<perlop/"Regexp Quote-Like Operators">.
4232
4233 =item quotemeta EXPR
4234 X<quotemeta> X<metacharacter>
4235
4236 =item quotemeta
4237
4238 Returns the value of EXPR with all non-"word"
4239 characters backslashed.  (That is, all characters not matching
4240 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4241 returned string, regardless of any locale settings.)
4242 This is the internal function implementing
4243 the C<\Q> escape in double-quoted strings.
4244
4245 If EXPR is omitted, uses C<$_>.
4246
4247 =item rand EXPR
4248 X<rand> X<random>
4249
4250 =item rand
4251
4252 Returns a random fractional number greater than or equal to C<0> and less
4253 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4254 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4255 also special-cased as C<1> - this has not been documented before perl 5.8.0
4256 and is subject to change in future versions of perl.  Automatically calls
4257 C<srand> unless C<srand> has already been called.  See also C<srand>.
4258
4259 Apply C<int()> to the value returned by C<rand()> if you want random
4260 integers instead of random fractional numbers.  For example,
4261
4262     int(rand(10))
4263
4264 returns a random integer between C<0> and C<9>, inclusive.
4265
4266 (Note: If your rand function consistently returns numbers that are too
4267 large or too small, then your version of Perl was probably compiled
4268 with the wrong number of RANDBITS.)
4269
4270 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4271 X<read> X<file, read>
4272
4273 =item read FILEHANDLE,SCALAR,LENGTH
4274
4275 Attempts to read LENGTH I<characters> of data into variable SCALAR
4276 from the specified FILEHANDLE.  Returns the number of characters
4277 actually read, C<0> at end of file, or undef if there was an error (in
4278 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4279 so that the last character actually read is the last character of the
4280 scalar after the read.
4281
4282 An OFFSET may be specified to place the read data at some place in the
4283 string other than the beginning.  A negative OFFSET specifies
4284 placement at that many characters counting backwards from the end of
4285 the string.  A positive OFFSET greater than the length of SCALAR
4286 results in the string being padded to the required size with C<"\0">
4287 bytes before the result of the read is appended.
4288
4289 The call is actually implemented in terms of either Perl's or system's
4290 fread() call.  To get a true read(2) system call, see C<sysread>.
4291
4292 Note the I<characters>: depending on the status of the filehandle,
4293 either (8-bit) bytes or characters are read.  By default all
4294 filehandles operate on bytes, but for example if the filehandle has
4295 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4296 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4297 characters, not bytes.  Similarly for the C<:encoding> pragma:
4298 in that case pretty much any characters can be read.
4299
4300 =item readdir DIRHANDLE
4301 X<readdir>
4302
4303 Returns the next directory entry for a directory opened by C<opendir>.
4304 If used in list context, returns all the rest of the entries in the
4305 directory.  If there are no more entries, returns an undefined value in
4306 scalar context or a null list in list context.
4307
4308 If you're planning to filetest the return values out of a C<readdir>, you'd
4309 better prepend the directory in question.  Otherwise, because we didn't
4310 C<chdir> there, it would have been testing the wrong file.
4311
4312     opendir(my $dh, $some_dir) || die "can't opendir $some_dir: $!";
4313     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir($dh);
4314     closedir $dh;
4315
4316 =item readline EXPR
4317
4318 =item readline
4319 X<readline> X<gets> X<fgets>
4320
4321 Reads from the filehandle whose typeglob is contained in EXPR (or from
4322 *ARGV if EXPR is not provided).  In scalar context, each call reads and
4323 returns the next line, until end-of-file is reached, whereupon the
4324 subsequent call returns undef.  In list context, reads until end-of-file
4325 is reached and returns a list of lines.  Note that the notion of "line"
4326 used here is however you may have defined it with C<$/> or
4327 C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4328
4329 When C<$/> is set to C<undef>, when readline() is in scalar
4330 context (i.e. file slurp mode), and when an empty file is read, it
4331 returns C<''> the first time, followed by C<undef> subsequently.
4332
4333 This is the internal function implementing the C<< <EXPR> >>
4334 operator, but you can use it directly.  The C<< <EXPR> >>
4335 operator is discussed in more detail in L<perlop/"I/O Operators">.
4336
4337     $line = <STDIN>;
4338     $line = readline(*STDIN);           # same thing
4339
4340 If readline encounters an operating system error, C<$!> will be set with the
4341 corresponding error message.  It can be helpful to check C<$!> when you are
4342 reading from filehandles you don't trust, such as a tty or a socket.  The
4343 following example uses the operator form of C<readline>, and takes the necessary
4344 steps to ensure that C<readline> was successful.
4345
4346     for (;;) {
4347         undef $!;
4348         unless (defined( $line = <> )) {
4349             die $! if $!;
4350             last; # reached EOF
4351         }
4352         # ...
4353     }
4354
4355 =item readlink EXPR
4356 X<readlink>
4357
4358 =item readlink
4359
4360 Returns the value of a symbolic link, if symbolic links are
4361 implemented.  If not, gives a fatal error.  If there is some system
4362 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4363 omitted, uses C<$_>.
4364
4365 =item readpipe EXPR
4366
4367 =item readpipe
4368 X<readpipe>
4369
4370 EXPR is executed as a system command.
4371 The collected standard output of the command is returned.
4372 In scalar context, it comes back as a single (potentially
4373 multi-line) string.  In list context, returns a list of lines
4374 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4375 This is the internal function implementing the C<qx/EXPR/>
4376 operator, but you can use it directly.  The C<qx/EXPR/>
4377 operator is discussed in more detail in L<perlop/"I/O Operators">.
4378 If EXPR is omitted, uses C<$_>.
4379
4380 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4381 X<recv>
4382
4383 Receives a message on a socket.  Attempts to receive LENGTH characters
4384 of data into variable SCALAR from the specified SOCKET filehandle.
4385 SCALAR will be grown or shrunk to the length actually read.  Takes the
4386 same flags as the system call of the same name.  Returns the address
4387 of the sender if SOCKET's protocol supports this; returns an empty
4388 string otherwise.  If there's an error, returns the undefined value.
4389 This call is actually implemented in terms of recvfrom(2) system call.
4390 See L<perlipc/"UDP: Message Passing"> for examples.
4391
4392 Note the I<characters>: depending on the status of the socket, either
4393 (8-bit) bytes or characters are received.  By default all sockets
4394 operate on bytes, but for example if the socket has been changed using
4395 binmode() to operate with the C<:encoding(utf8)> I/O layer (see the
4396 C<open> pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4397 characters, not bytes.  Similarly for the C<:encoding> pragma: in that
4398 case pretty much any characters can be read.
4399
4400 =item redo LABEL
4401 X<redo>
4402
4403 =item redo
4404
4405 The C<redo> command restarts the loop block without evaluating the
4406 conditional again.  The C<continue> block, if any, is not executed.  If
4407 the LABEL is omitted, the command refers to the innermost enclosing
4408 loop.  Programs that want to lie to themselves about what was just input 
4409 normally use this command:
4410
4411     # a simpleminded Pascal comment stripper
4412     # (warning: assumes no { or } in strings)
4413     LINE: while (<STDIN>) {
4414         while (s|({.*}.*){.*}|$1 |) {}
4415         s|{.*}| |;
4416         if (s|{.*| |) {
4417             $front = $_;
4418             while (<STDIN>) {
4419                 if (/}/) {      # end of comment?
4420                     s|^|$front\{|;
4421                     redo LINE;
4422                 }
4423             }
4424         }
4425         print;
4426     }
4427
4428 C<redo> cannot be used to retry a block which returns a value such as
4429 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4430 a grep() or map() operation.
4431
4432 Note that a block by itself is semantically identical to a loop
4433 that executes once.  Thus C<redo> inside such a block will effectively
4434 turn it into a looping construct.
4435
4436 See also L</continue> for an illustration of how C<last>, C<next>, and
4437 C<redo> work.
4438
4439 =item ref EXPR
4440 X<ref> X<reference>
4441
4442 =item ref
4443
4444 Returns a non-empty string if EXPR is a reference, the empty
4445 string otherwise. If EXPR
4446 is not specified, C<$_> will be used.  The value returned depends on the
4447 type of thing the reference is a reference to.
4448 Builtin types include:
4449
4450     SCALAR
4451     ARRAY
4452     HASH
4453     CODE
4454     REF
4455     GLOB
4456     LVALUE
4457     FORMAT
4458     IO
4459     VSTRING
4460     Regexp
4461
4462 If the referenced object has been blessed into a package, then that package
4463 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4464
4465     if (ref($r) eq "HASH") {
4466         print "r is a reference to a hash.\n";
4467     }
4468     unless (ref($r)) {
4469         print "r is not a reference at all.\n";
4470     }
4471
4472 The return value C<LVALUE> indicates a reference to an lvalue that is not
4473 a variable. You get this from taking the reference of function calls like
4474 C<pos()> or C<substr()>. C<VSTRING> is returned if the reference points
4475 to a L<version string|perldata/"Version Strings">.
4476
4477 The result C<Regexp> indicates that the argument is a regular expression
4478 resulting from C<qr//>.
4479
4480 See also L<perlref>.
4481
4482 =item rename OLDNAME,NEWNAME
4483 X<rename> X<move> X<mv> X<ren>
4484
4485 Changes the name of a file; an existing file NEWNAME will be
4486 clobbered.  Returns true for success, false otherwise.
4487
4488 Behavior of this function varies wildly depending on your system
4489 implementation.  For example, it will usually not work across file system
4490 boundaries, even though the system I<mv> command sometimes compensates
4491 for this.  Other restrictions include whether it works on directories,
4492 open files, or pre-existing files.  Check L<perlport> and either the
4493 rename(2) manpage or equivalent system documentation for details.
4494
4495 For a platform independent C<move> function look at the L<File::Copy>
4496 module.
4497
4498 =item require VERSION
4499 X<require>
4500
4501 =item require EXPR
4502
4503 =item require
4504
4505 Demands a version of Perl specified by VERSION, or demands some semantics
4506 specified by EXPR or by C<$_> if EXPR is not supplied.
4507
4508 VERSION may be either a numeric argument such as 5.006, which will be
4509 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4510 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4511 VERSION is greater than the version of the current Perl interpreter.
4512 Compare with L</use>, which can do a similar check at compile time.
4513
4514 Specifying VERSION as a literal of the form v5.6.1 should generally be
4515 avoided, because it leads to misleading error messages under earlier
4516 versions of Perl that do not support this syntax.  The equivalent numeric
4517 version should be used instead.
4518
4519     require v5.6.1;     # run time version check
4520     require 5.6.1;      # ditto
4521     require 5.006_001;  # ditto; preferred for backwards compatibility
4522
4523 Otherwise, C<require> demands that a library file be included if it
4524 hasn't already been included.  The file is included via the do-FILE
4525 mechanism, which is essentially just a variety of C<eval> with the
4526 caveat that lexical variables in the invoking script will be invisible
4527 to the included code.  Has semantics similar to the following subroutine:
4528
4529     sub require {
4530        my ($filename) = @_;
4531        if (exists $INC{$filename}) {
4532            return 1 if $INC{$filename};
4533            die "Compilation failed in require";
4534        }
4535        my ($realfilename,$result);
4536        ITER: {
4537            foreach $prefix (@INC) {
4538                $realfilename = "$prefix/$filename";
4539                if (-f $realfilename) {
4540                    $INC{$filename} = $realfilename;
4541                    $result = do $realfilename;
4542                    last ITER;
4543                }
4544            }
4545            die "Can't find $filename in \@INC";
4546        }
4547        if ($@) {
4548            $INC{$filename} = undef;
4549            die $@;
4550        } elsif (!$result) {
4551            delete $INC{$filename};
4552            die "$filename did not return true value";
4553        } else {
4554            return $result;
4555        }
4556     }
4557
4558 Note that the file will not be included twice under the same specified
4559 name.
4560
4561 The file must return true as the last statement to indicate
4562 successful execution of any initialization code, so it's customary to
4563 end such a file with C<1;> unless you're sure it'll return true
4564 otherwise.  But it's better just to put the C<1;>, in case you add more
4565 statements.
4566
4567 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4568 replaces "F<::>" with "F</>" in the filename for you,
4569 to make it easy to load standard modules.  This form of loading of
4570 modules does not risk altering your namespace.
4571
4572 In other words, if you try this:
4573
4574         require Foo::Bar;    # a splendid bareword
4575
4576 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4577 directories specified in the C<@INC> array.
4578
4579 But if you try this:
4580
4581         $class = 'Foo::Bar';
4582         require $class;      # $class is not a bareword
4583     #or
4584         require "Foo::Bar";  # not a bareword because of the ""
4585
4586 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4587 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4588
4589         eval "require $class";
4590
4591 Now that you understand how C<require> looks for files in the case of a
4592 bareword argument, there is a little extra functionality going on behind
4593 the scenes.  Before C<require> looks for a "F<.pm>" extension, it will
4594 first look for a similar filename with a "F<.pmc>" extension. If this file
4595 is found, it will be loaded in place of any file ending in a "F<.pm>"
4596 extension.
4597
4598 You can also insert hooks into the import facility, by putting directly
4599 Perl code into the @INC array.  There are three forms of hooks: subroutine
4600 references, array references and blessed objects.
4601
4602 Subroutine references are the simplest case.  When the inclusion system
4603 walks through @INC and encounters a subroutine, this subroutine gets
4604 called with two parameters, the first being a reference to itself, and the
4605 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4606 subroutine should return nothing, or a list of up to three values in the
4607 following order:
4608
4609 =over
4610
4611 =item 1
4612
4613 A filehandle, from which the file will be read.  
4614
4615 =item 2
4616
4617 A reference to a subroutine. If there is no filehandle (previous item),
4618 then this subroutine is expected to generate one line of source code per
4619 call, writing the line into C<$_> and returning 1, then returning 0 at
4620 "end of file". If there is a filehandle, then the subroutine will be
4621 called to act a simple source filter, with the line as read in C<$_>.
4622 Again, return 1 for each valid line, and 0&n