This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
2ed8ffd3f61a7195e5c0323366bb04480d0025fa
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # There was an attempt when this was first rewritten to make it 5.8
8 # compatible, but that has now been abandoned, and newer constructs are used
9 # as convenient.
10
11 # NOTE: this script can run quite slowly in older/slower systems.
12 # It can also consume a lot of memory (128 MB or more), you may need
13 # to raise your process resource limits (e.g. in bash, "ulimit -a"
14 # to inspect, and "ulimit -d ..." or "ulimit -m ..." to set)
15
16 my $start_time;
17 BEGIN { # Get the time the script started running; do it at compilation to
18         # get it as close as possible
19     $start_time= time;
20 }
21
22 require 5.010_001;
23 use strict;
24 use warnings;
25 use Carp;
26 use Config;
27 use File::Find;
28 use File::Path;
29 use File::Spec;
30 use Text::Tabs;
31 use re "/aa";
32 use feature 'state';
33
34 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
35 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
36
37 sub NON_ASCII_PLATFORM { ord("A") != 65 }
38
39 # When a new version of Unicode is published, unfortunately the algorithms for
40 # dealing with various bounds, like \b{gcb}, \b{lb} may have to be updated
41 # manually.  The changes may or may not be backward compatible with older
42 # releases.  The code is in regen/mk_invlist.pl and regexec.c.  Make the
43 # changes, then come back here and set the variable below to what version the
44 # code is expecting.  If a newer version of Unicode is being compiled than
45 # expected, a warning will be generated.  If an older version is being
46 # compiled, any bounds tests that fail in the generated test file (-maketest
47 # option) will be marked as TODO.
48 my $version_of_mk_invlist_bounds = v12.1.0;
49
50 ##########################################################################
51 #
52 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
53 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
54 # a pod file and .t files, depending on option parameters.
55 #
56 # The structure of this file is:
57 #   First these introductory comments; then
58 #   code needed for everywhere, such as debugging stuff; then
59 #   code to handle input parameters; then
60 #   data structures likely to be of external interest (some of which depend on
61 #       the input parameters, so follows them; then
62 #   more data structures and subroutine and package (class) definitions; then
63 #   the small actual loop to process the input files and finish up; then
64 #   a __DATA__ section, for the .t tests
65 #
66 # This program works on all releases of Unicode so far.  The outputs have been
67 # scrutinized most intently for release 5.1.  The others have been checked for
68 # somewhat more than just sanity.  It can handle all non-provisional Unicode
69 # character properties in those releases.
70 #
71 # This program is mostly about Unicode character (or code point) properties.
72 # A property describes some attribute or quality of a code point, like if it
73 # is lowercase or not, its name, what version of Unicode it was first defined
74 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
75 # possibilities by making all properties into mappings from each code point
76 # into some corresponding value.  In the case of it being lowercase or not,
77 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
78 # property maps each Unicode code point to a single value, called a "property
79 # value".  (Some more recently defined properties, map a code point to a set
80 # of values.)
81 #
82 # When using a property in a regular expression, what is desired isn't the
83 # mapping of the code point to its property's value, but the reverse (or the
84 # mathematical "inverse relation"): starting with the property value, "Does a
85 # code point map to it?"  These are written in a "compound" form:
86 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
87 # files containing the lists of code points that map to each such regular
88 # expression property value, one file per list
89 #
90 # There is also a single form shortcut that Perl adds for many of the commonly
91 # used properties.  This happens for all binary properties, plus script,
92 # general_category, and block properties.
93 #
94 # Thus the outputs of this program are files.  There are map files, mostly in
95 # the 'To' directory; and there are list files for use in regular expression
96 # matching, all in subdirectories of the 'lib' directory, with each
97 # subdirectory being named for the property that the lists in it are for.
98 # Bookkeeping, test, and documentation files are also generated.
99
100 my $matches_directory = 'lib';   # Where match (\p{}) files go.
101 my $map_directory = 'To';        # Where map files go.
102
103 # DATA STRUCTURES
104 #
105 # The major data structures of this program are Property, of course, but also
106 # Table.  There are two kinds of tables, very similar to each other.
107 # "Match_Table" is the data structure giving the list of code points that have
108 # a particular property value, mentioned above.  There is also a "Map_Table"
109 # data structure which gives the property's mapping from code point to value.
110 # There are two structures because the match tables need to be combined in
111 # various ways, such as constructing unions, intersections, complements, etc.,
112 # and the map ones don't.  And there would be problems, perhaps subtle, if
113 # a map table were inadvertently operated on in some of those ways.
114 # The use of separate classes with operations defined on one but not the other
115 # prevents accidentally confusing the two.
116 #
117 # At the heart of each table's data structure is a "Range_List", which is just
118 # an ordered list of "Ranges", plus ancillary information, and methods to
119 # operate on them.  A Range is a compact way to store property information.
120 # Each range has a starting code point, an ending code point, and a value that
121 # is meant to apply to all the code points between the two end points,
122 # inclusive.  For a map table, this value is the property value for those
123 # code points.  Two such ranges could be written like this:
124 #   0x41 .. 0x5A, 'Upper',
125 #   0x61 .. 0x7A, 'Lower'
126 #
127 # Each range also has a type used as a convenience to classify the values.
128 # Most ranges in this program will be Type 0, or normal, but there are some
129 # ranges that have a non-zero type.  These are used only in map tables, and
130 # are for mappings that don't fit into the normal scheme of things.  Mappings
131 # that require a hash entry to communicate with utf8.c are one example;
132 # another example is mappings for charnames.pm to use which indicate a name
133 # that is algorithmically determinable from its code point (and the reverse).
134 # These are used to significantly compact these tables, instead of listing
135 # each one of the tens of thousands individually.
136 #
137 # In a match table, the value of a range is irrelevant (and hence the type as
138 # well, which will always be 0), and arbitrarily set to the empty string.
139 # Using the example above, there would be two match tables for those two
140 # entries, one named Upper would contain the 0x41..0x5A range, and the other
141 # named Lower would contain 0x61..0x7A.
142 #
143 # Actually, there are two types of range lists, "Range_Map" is the one
144 # associated with map tables, and "Range_List" with match tables.
145 # Again, this is so that methods can be defined on one and not the others so
146 # as to prevent operating on them in incorrect ways.
147 #
148 # Eventually, most tables are written out to files to be read by Unicode::UCD.
149 # All tables could in theory be written, but some are suppressed because there
150 # is no current practical use for them.  It is easy to change which get
151 # written by changing various lists that are near the top of the actual code
152 # in this file.  The table data structures contain enough ancillary
153 # information to allow them to be treated as separate entities for writing,
154 # such as the path to each one's file.  There is a heading in each map table
155 # that gives the format of its entries, and what the map is for all the code
156 # points missing from it.  (This allows tables to be more compact.)
157 #
158 # The Property data structure contains one or more tables.  All properties
159 # contain a map table (except the $perl property which is a
160 # pseudo-property containing only match tables), and any properties that
161 # are usable in regular expression matches also contain various matching
162 # tables, one for each value the property can have.  A binary property can
163 # have two values, True and False (or Y and N, which are preferred by Unicode
164 # terminology).  Thus each of these properties will have a map table that
165 # takes every code point and maps it to Y or N (but having ranges cuts the
166 # number of entries in that table way down), and two match tables, one
167 # which has a list of all the code points that map to Y, and one for all the
168 # code points that map to N.  (For each binary property, a third table is also
169 # generated for the pseudo Perl property.  It contains the identical code
170 # points as the Y table, but can be written in regular expressions, not in the
171 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
172 # properties are binary, but some properties have several possible values,
173 # some have many, and properties like Name have a different value for every
174 # named code point.  Those will not, unless the controlling lists are changed,
175 # have their match tables written out.  But all the ones which can be used in
176 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
177 # a property would have either its map table or its match tables written but
178 # not both.  Again, what gets written is controlled by lists which can easily
179 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
180 # tables needed to reconstruct the Unicode db are now written out, while
181 # suppressing the Unicode .txt files that contain the data.  Our tables are
182 # much more compact than the .txt files, so a significant space savings was
183 # achieved.  Also, tables are not written out that are trivially derivable
184 # from tables that do get written.  So, there typically is no file containing
185 # the code points not matched by a binary property (the table for \P{} versus
186 # lowercase \p{}), since you just need to invert the True table to get the
187 # False table.
188
189 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
190 # how many match tables there are and the content of the maps.  This 'Type' is
191 # different than a range 'Type', so don't get confused by the two concepts
192 # having the same name.
193 #
194 # For information about the Unicode properties, see Unicode's UAX44 document:
195
196 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
197
198 # As stated earlier, this program will work on any release of Unicode so far.
199 # Most obvious problems in earlier data have NOT been corrected except when
200 # necessary to make Perl or this program work reasonably, and to keep out
201 # potential security issues.  For example, no folding information was given in
202 # early releases, so this program substitutes lower case instead, just so that
203 # a regular expression with the /i option will do something that actually
204 # gives the right results in many cases.  There are also a couple other
205 # corrections for version 1.1.5, commented at the point they are made.  As an
206 # example of corrections that weren't made (but could be) is this statement
207 # from DerivedAge.txt: "The supplementary private use code points and the
208 # non-character code points were assigned in version 2.0, but not specifically
209 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
210 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
211 # further down in these introductory comments.
212 #
213 # This program works on all non-provisional properties as of the current
214 # Unicode release, though the files for some are suppressed for various
215 # reasons.  You can change which are output by changing lists in this program.
216 #
217 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
218 # loose matchings rules (from Unicode TR18):
219 #
220 #    The recommended names for UCD properties and property values are in
221 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
222 #    [PropValue]. There are both abbreviated names and longer, more
223 #    descriptive names. It is strongly recommended that both names be
224 #    recognized, and that loose matching of property names be used,
225 #    whereby the case distinctions, whitespace, hyphens, and underbar
226 #    are ignored.
227 #
228 # The program still allows Fuzzy to override its determination of if loose
229 # matching should be used, but it isn't currently used, as it is no longer
230 # needed; the calculations it makes are good enough.
231 #
232 # SUMMARY OF HOW IT WORKS:
233 #
234 #   Process arguments
235 #
236 #   A list is constructed containing each input file that is to be processed
237 #
238 #   Each file on the list is processed in a loop, using the associated handler
239 #   code for each:
240 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
241 #            first.  These files name the properties and property values.
242 #            Objects are created of all the property and property value names
243 #            that the rest of the input should expect, including all synonyms.
244 #        The other input files give mappings from properties to property
245 #           values.  That is, they list code points and say what the mapping
246 #           is under the given property.  Some files give the mappings for
247 #           just one property; and some for many.  This program goes through
248 #           each file and populates the properties and their map tables from
249 #           them.  Some properties are listed in more than one file, and
250 #           Unicode has set up a precedence as to which has priority if there
251 #           is a conflict.  Thus the order of processing matters, and this
252 #           program handles the conflict possibility by processing the
253 #           overriding input files last, so that if necessary they replace
254 #           earlier values.
255 #        After this is all done, the program creates the property mappings not
256 #            furnished by Unicode, but derivable from what it does give.
257 #        The tables of code points that match each property value in each
258 #            property that is accessible by regular expressions are created.
259 #        The Perl-defined properties are created and populated.  Many of these
260 #            require data determined from the earlier steps
261 #        Any Perl-defined synonyms are created, and name clashes between Perl
262 #            and Unicode are reconciled and warned about.
263 #        All the properties are written to files
264 #        Any other files are written, and final warnings issued.
265 #
266 # For clarity, a number of operators have been overloaded to work on tables:
267 #   ~ means invert (take all characters not in the set).  The more
268 #       conventional '!' is not used because of the possibility of confusing
269 #       it with the actual boolean operation.
270 #   + means union
271 #   - means subtraction
272 #   & means intersection
273 # The precedence of these is the order listed.  Parentheses should be
274 # copiously used.  These are not a general scheme.  The operations aren't
275 # defined for a number of things, deliberately, to avoid getting into trouble.
276 # Operations are done on references and affect the underlying structures, so
277 # that the copy constructors for them have been overloaded to not return a new
278 # clone, but the input object itself.
279 #
280 # The bool operator is deliberately not overloaded to avoid confusion with
281 # "should it mean if the object merely exists, or also is non-empty?".
282 #
283 # WHY CERTAIN DESIGN DECISIONS WERE MADE
284 #
285 # This program needs to be able to run under miniperl.  Therefore, it uses a
286 # minimum of other modules, and hence implements some things itself that could
287 # be gotten from CPAN
288 #
289 # This program uses inputs published by the Unicode Consortium.  These can
290 # change incompatibly between releases without the Perl maintainers realizing
291 # it.  Therefore this program is now designed to try to flag these.  It looks
292 # at the directories where the inputs are, and flags any unrecognized files.
293 # It keeps track of all the properties in the files it handles, and flags any
294 # that it doesn't know how to handle.  It also flags any input lines that
295 # don't match the expected syntax, among other checks.
296 #
297 # It is also designed so if a new input file matches one of the known
298 # templates, one hopefully just needs to add it to a list to have it
299 # processed.
300 #
301 # As mentioned earlier, some properties are given in more than one file.  In
302 # particular, the files in the extracted directory are supposedly just
303 # reformattings of the others.  But they contain information not easily
304 # derivable from the other files, including results for Unihan (which isn't
305 # usually available to this program) and for unassigned code points.  They
306 # also have historically had errors or been incomplete.  In an attempt to
307 # create the best possible data, this program thus processes them first to
308 # glean information missing from the other files; then processes those other
309 # files to override any errors in the extracted ones.  Much of the design was
310 # driven by this need to store things and then possibly override them.
311 #
312 # It tries to keep fatal errors to a minimum, to generate something usable for
313 # testing purposes.  It always looks for files that could be inputs, and will
314 # warn about any that it doesn't know how to handle (the -q option suppresses
315 # the warning).
316 #
317 # Why is there more than one type of range?
318 #   This simplified things.  There are some very specialized code points that
319 #   have to be handled specially for output, such as Hangul syllable names.
320 #   By creating a range type (done late in the development process), it
321 #   allowed this to be stored with the range, and overridden by other input.
322 #   Originally these were stored in another data structure, and it became a
323 #   mess trying to decide if a second file that was for the same property was
324 #   overriding the earlier one or not.
325 #
326 # Why are there two kinds of tables, match and map?
327 #   (And there is a base class shared by the two as well.)  As stated above,
328 #   they actually are for different things.  Development proceeded much more
329 #   smoothly when I (khw) realized the distinction.  Map tables are used to
330 #   give the property value for every code point (actually every code point
331 #   that doesn't map to a default value).  Match tables are used for regular
332 #   expression matches, and are essentially the inverse mapping.  Separating
333 #   the two allows more specialized methods, and error checks so that one
334 #   can't just take the intersection of two map tables, for example, as that
335 #   is nonsensical.
336 #
337 # What about 'fate' and 'status'.  The concept of a table's fate was created
338 #   late when it became clear that something more was needed.  The difference
339 #   between this and 'status' is unclean, and could be improved if someone
340 #   wanted to spend the effort.
341 #
342 # DEBUGGING
343 #
344 # This program is written so it will run under miniperl.  Occasionally changes
345 # will cause an error where the backtrace doesn't work well under miniperl.
346 # To diagnose the problem, you can instead run it under regular perl, if you
347 # have one compiled.
348 #
349 # There is a good trace facility.  To enable it, first sub DEBUG must be set
350 # to return true.  Then a line like
351 #
352 # local $to_trace = 1 if main::DEBUG;
353 #
354 # can be added to enable tracing in its lexical scope (plus dynamic) or until
355 # you insert another line:
356 #
357 # local $to_trace = 0 if main::DEBUG;
358 #
359 # To actually trace, use a line like "trace $a, @b, %c, ...;
360 #
361 # Some of the more complex subroutines already have trace statements in them.
362 # Permanent trace statements should be like:
363 #
364 # trace ... if main::DEBUG && $to_trace;
365 #
366 # main::stack_trace() will display what its name implies
367 #
368 # If there is just one or a few files that you're debugging, you can easily
369 # cause most everything else to be skipped.  Change the line
370 #
371 # my $debug_skip = 0;
372 #
373 # to 1, and every file whose object is in @input_file_objects and doesn't have
374 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
375 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
376 #
377 # To compare the output tables, it may be useful to specify the -annotate
378 # flag.  (As of this writing, this can't be done on a clean workspace, due to
379 # requirements in Text::Tabs used in this option; so first run mktables
380 # without this option.)  This option adds comment lines to each table, one for
381 # each non-algorithmically named character giving, currently its code point,
382 # name, and graphic representation if printable (and you have a font that
383 # knows about it).  This makes it easier to see what the particular code
384 # points are in each output table.  Non-named code points are annotated with a
385 # description of their status, and contiguous ones with the same description
386 # will be output as a range rather than individually.  Algorithmically named
387 # characters are also output as ranges, except when there are just a few
388 # contiguous ones.
389 #
390 # FUTURE ISSUES
391 #
392 # The program would break if Unicode were to change its names so that
393 # interior white space, underscores, or dashes differences were significant
394 # within property and property value names.
395 #
396 # It might be easier to use the xml versions of the UCD if this program ever
397 # would need heavy revision, and the ability to handle old versions was not
398 # required.
399 #
400 # There is the potential for name collisions, in that Perl has chosen names
401 # that Unicode could decide it also likes.  There have been such collisions in
402 # the past, with mostly Perl deciding to adopt the Unicode definition of the
403 # name.  However in the 5.2 Unicode beta testing, there were a number of such
404 # collisions, which were withdrawn before the final release, because of Perl's
405 # and other's protests.  These all involved new properties which began with
406 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
407 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
408 # Unicode document, so they are unlikely to be used by Unicode for another
409 # purpose.  However, they might try something beginning with 'In', or use any
410 # of the other Perl-defined properties.  This program will warn you of name
411 # collisions, and refuse to generate tables with them, but manual intervention
412 # will be required in this event.  One scheme that could be implemented, if
413 # necessary, would be to have this program generate another file, or add a
414 # field to mktables.lst that gives the date of first definition of a property.
415 # Each new release of Unicode would use that file as a basis for the next
416 # iteration.  And the Perl synonym addition code could sort based on the age
417 # of the property, so older properties get priority, and newer ones that clash
418 # would be refused; hence existing code would not be impacted, and some other
419 # synonym would have to be used for the new property.  This is ugly, and
420 # manual intervention would certainly be easier to do in the short run; lets
421 # hope it never comes to this.
422 #
423 # A NOTE ON UNIHAN
424 #
425 # This program can generate tables from the Unihan database.  But that DB
426 # isn't normally available, so it is marked as optional.  Prior to version
427 # 5.2, this database was in a single file, Unihan.txt.  In 5.2 the database
428 # was split into 8 different files, all beginning with the letters 'Unihan'.
429 # If you plunk those files down into the directory mktables ($0) is in, this
430 # program will read them and automatically create tables for the properties
431 # from it that are listed in PropertyAliases.txt and PropValueAliases.txt,
432 # plus any you add to the @cjk_properties array and the @cjk_property_values
433 # array, being sure to add necessary '# @missings' lines to the latter.  For
434 # Unicode versions earlier than 5.2, most of the Unihan properties are not
435 # listed at all in PropertyAliases nor PropValueAliases.  This program assumes
436 # for these early releases that you want the properties that are specified in
437 # the 5.2 release.
438 #
439 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
440 # and filter_unihan_line() are the functions where this is done.  This program
441 # already does some adjusting to make the lines look more like the rest of the
442 # Unicode DB;  You can see what that is in filter_unihan_line()
443 #
444 # There is a bug in the 3.2 data file in which some values for the
445 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
446 # could be added to correct these; or for a particular installation, the
447 # Unihan.txt file could be edited to fix them.
448 #
449 # HOW TO ADD A FILE TO BE PROCESSED
450 #
451 # A new file from Unicode needs to have an object constructed for it in
452 # @input_file_objects, probably at the end or at the end of the extracted
453 # ones.  The program should warn you if its name will clash with others on
454 # restrictive file systems, like DOS.  If so, figure out a better name, and
455 # add lines to the README.perl file giving that.  If the file is a character
456 # property, it should be in the format that Unicode has implicitly
457 # standardized for such files for the more recently introduced ones.
458 # If so, the Input_file constructor for @input_file_objects can just be the
459 # file name and release it first appeared in.  If not, then it should be
460 # possible to construct an each_line_handler() to massage the line into the
461 # standardized form.
462 #
463 # For non-character properties, more code will be needed.  You can look at
464 # the existing entries for clues.
465 #
466 # UNICODE VERSIONS NOTES
467 #
468 # The Unicode UCD has had a number of errors in it over the versions.  And
469 # these remain, by policy, in the standard for that version.  Therefore it is
470 # risky to correct them, because code may be expecting the error.  So this
471 # program doesn't generally make changes, unless the error breaks the Perl
472 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
473 # for U+1105, which causes real problems for the algorithms for Jamo
474 # calculations, so it is changed here.
475 #
476 # But it isn't so clear cut as to what to do about concepts that are
477 # introduced in a later release; should they extend back to earlier releases
478 # where the concept just didn't exist?  It was easier to do this than to not,
479 # so that's what was done.  For example, the default value for code points not
480 # in the files for various properties was probably undefined until changed by
481 # some version.  No_Block for blocks is such an example.  This program will
482 # assign No_Block even in Unicode versions that didn't have it.  This has the
483 # benefit that code being written doesn't have to special case earlier
484 # versions; and the detriment that it doesn't match the Standard precisely for
485 # the affected versions.
486 #
487 # Here are some observations about some of the issues in early versions:
488 #
489 # Prior to version 3.0, there were 3 character decompositions.  These are not
490 # handled by Unicode::Normalize, nor will it compile when presented a version
491 # that has them.  However, you can trivially get it to compile by simply
492 # ignoring those decompositions, by changing the croak to a carp.  At the time
493 # of this writing, the line (in dist/Unicode-Normalize/Normalize.pm or
494 # dist/Unicode-Normalize/mkheader) reads
495 #
496 #   croak("Weird Canonical Decomposition of U+$h");
497 #
498 # Simply comment it out.  It will compile, but will not know about any three
499 # character decompositions.
500
501 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
502 # that the reason is that the CJK block starting at 4E00 was removed from
503 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
504 # single property name \p{alpha}) has the correct values.  But the compound
505 # form is simply not generated until 3.1, as it can be argued that prior to
506 # this release, this was not an official property.  The comments for
507 # filter_old_style_proplist() give more details.
508 #
509 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
510 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
511 # reason is that 3.2 introduced U+205F=medium math space, which was not
512 # classed as white space, but Perl figured out that it should have been. 4.0
513 # reclassified it correctly.
514 #
515 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
516 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
517 # became 202, and ATBL was left with no code points, as all the ones that
518 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
519 # name for the class, it would not have been affected, but if it used the
520 # mnemonic, it would have been.
521 #
522 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that, code
523 # points which eventually came to have this script property value, instead
524 # mapped to "Unknown".  But in the next release all these code points were
525 # moved to \p{sc=common} instead.
526
527 # The tests furnished  by Unicode for testing WordBreak and SentenceBreak
528 # generate errors in 5.0 and earlier.
529 #
530 # The default for missing code points for BidiClass is complicated.  Starting
531 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
532 # tries to do the best it can for earlier releases.  It is done in
533 # process_PropertyAliases()
534 #
535 # In version 2.1.2, the entry in UnicodeData.txt:
536 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
537 # should instead be
538 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
539 # Without this change, there are casing problems for this character.
540 #
541 # Search for $string_compare_versions to see how to compare changes to
542 # properties between Unicode versions
543 #
544 ##############################################################################
545
546 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
547                         # and errors
548 my $MAX_LINE_WIDTH = 78;
549
550 # Debugging aid to skip most files so as to not be distracted by them when
551 # concentrating on the ones being debugged.  Add
552 # non_skip => 1,
553 # to the constructor for those files you want processed when you set this.
554 # Files with a first version number of 0 are special: they are always
555 # processed regardless of the state of this flag.  Generally, Jamo.txt and
556 # UnicodeData.txt must not be skipped if you want this program to not die
557 # before normal completion.
558 my $debug_skip = 0;
559
560
561 # Normally these are suppressed.
562 my $write_Unicode_deprecated_tables = 0;
563
564 # Set to 1 to enable tracing.
565 our $to_trace = 0;
566
567 { # Closure for trace: debugging aid
568     my $print_caller = 1;        # ? Include calling subroutine name
569     my $main_with_colon = 'main::';
570     my $main_colon_length = length($main_with_colon);
571
572     sub trace {
573         return unless $to_trace;        # Do nothing if global flag not set
574
575         my @input = @_;
576
577         local $DB::trace = 0;
578         $DB::trace = 0;          # Quiet 'used only once' message
579
580         my $line_number;
581
582         # Loop looking up the stack to get the first non-trace caller
583         my $caller_line;
584         my $caller_name;
585         my $i = 0;
586         do {
587             $line_number = $caller_line;
588             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
589             $caller = $main_with_colon unless defined $caller;
590
591             $caller_name = $caller;
592
593             # get rid of pkg
594             $caller_name =~ s/.*:://;
595             if (substr($caller_name, 0, $main_colon_length)
596                 eq $main_with_colon)
597             {
598                 $caller_name = substr($caller_name, $main_colon_length);
599             }
600
601         } until ($caller_name ne 'trace');
602
603         # If the stack was empty, we were called from the top level
604         $caller_name = 'main' if ($caller_name eq ""
605                                     || $caller_name eq 'trace');
606
607         my $output = "";
608         #print STDERR __LINE__, ": ", join ", ", @input, "\n";
609         foreach my $string (@input) {
610             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
611                 $output .= simple_dumper($string);
612             }
613             else {
614                 $string = "$string" if ref $string;
615                 $string = $UNDEF unless defined $string;
616                 chomp $string;
617                 $string = '""' if $string eq "";
618                 $output .= " " if $output ne ""
619                                 && $string ne ""
620                                 && substr($output, -1, 1) ne " "
621                                 && substr($string, 0, 1) ne " ";
622                 $output .= $string;
623             }
624         }
625
626         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
627         print STDERR "$caller_name: " if $print_caller;
628         print STDERR $output, "\n";
629         return;
630     }
631 }
632
633 sub stack_trace() {
634     local $to_trace = 1 if main::DEBUG;
635     my $line = (caller(0))[2];
636     my $i = 1;
637
638     # Accumulate the stack trace
639     while (1) {
640         my ($pkg, $file, $caller_line, $caller) = caller $i++;
641
642         last unless defined $caller;
643
644         trace "called from $caller() at line $line";
645         $line = $caller_line;
646     }
647 }
648
649 # This is for a rarely used development feature that allows you to compare two
650 # versions of the Unicode standard without having to deal with changes caused
651 # by the code points introduced in the later version.  You probably also want
652 # to use the -annotate option when using this.  Run this program on a unicore
653 # containing the starting release you want to compare.  Save that output
654 # structure.  Then, switching to a unicore with the ending release, change the
655 # "" in the $string_compare_versions definition just below to a string
656 # containing a SINGLE dotted Unicode release number (e.g. "2.1") corresponding
657 # to the starting release.  This program will then compile, but throw away all
658 # code points introduced after the starting release.  Finally use a diff tool
659 # to compare the two directory structures.  They include only the code points
660 # common to both releases, and you can see the changes caused just by the
661 # underlying release semantic changes.  For versions earlier than 3.2, you
662 # must copy a version of DAge.txt into the directory.
663 my $string_compare_versions = DEBUG && "";
664 my $compare_versions = DEBUG
665                        && $string_compare_versions
666                        && pack "C*", split /\./, $string_compare_versions;
667
668 sub uniques {
669     # Returns non-duplicated input values.  From "Perl Best Practices:
670     # Encapsulated Cleverness".  p. 455 in first edition.
671
672     my %seen;
673     # Arguably this breaks encapsulation, if the goal is to permit multiple
674     # distinct objects to stringify to the same value, and be interchangeable.
675     # However, for this program, no two objects stringify identically, and all
676     # lists passed to this function are either objects or strings. So this
677     # doesn't affect correctness, but it does give a couple of percent speedup.
678     no overloading;
679     return grep { ! $seen{$_}++ } @_;
680 }
681
682 $0 = File::Spec->canonpath($0);
683
684 my $make_test_script = 0;      # ? Should we output a test script
685 my $make_norm_test_script = 0; # ? Should we output a normalization test script
686 my $write_unchanged_files = 0; # ? Should we update the output files even if
687                                #    we don't think they have changed
688 my $use_directory = "";        # ? Should we chdir somewhere.
689 my $pod_directory;             # input directory to store the pod file.
690 my $pod_file = 'perluniprops';
691 my $t_path;                     # Path to the .t test file
692 my $file_list = 'mktables.lst'; # File to store input and output file names.
693                                # This is used to speed up the build, by not
694                                # executing the main body of the program if
695                                # nothing on the list has changed since the
696                                # previous build
697 my $make_list = 1;             # ? Should we write $file_list.  Set to always
698                                # make a list so that when the pumpking is
699                                # preparing a release, s/he won't have to do
700                                # special things
701 my $glob_list = 0;             # ? Should we try to include unknown .txt files
702                                # in the input.
703 my $output_range_counts = $debugging_build;   # ? Should we include the number
704                                               # of code points in ranges in
705                                               # the output
706 my $annotate = 0;              # ? Should character names be in the output
707
708 # Verbosity levels; 0 is quiet
709 my $NORMAL_VERBOSITY = 1;
710 my $PROGRESS = 2;
711 my $VERBOSE = 3;
712
713 my $verbosity = $NORMAL_VERBOSITY;
714
715 # Stored in mktables.lst so that if this program is called with different
716 # options, will regenerate even if the files otherwise look like they're
717 # up-to-date.
718 my $command_line_arguments = join " ", @ARGV;
719
720 # Process arguments
721 while (@ARGV) {
722     my $arg = shift @ARGV;
723     if ($arg eq '-v') {
724         $verbosity = $VERBOSE;
725     }
726     elsif ($arg eq '-p') {
727         $verbosity = $PROGRESS;
728         $| = 1;     # Flush buffers as we go.
729     }
730     elsif ($arg eq '-q') {
731         $verbosity = 0;
732     }
733     elsif ($arg eq '-w') {
734         # update the files even if they haven't changed
735         $write_unchanged_files = 1;
736     }
737     elsif ($arg eq '-check') {
738         my $this = shift @ARGV;
739         my $ok = shift @ARGV;
740         if ($this ne $ok) {
741             print "Skipping as check params are not the same.\n";
742             exit(0);
743         }
744     }
745     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
746         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
747     }
748     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
749     {
750         $make_test_script = 1;
751     }
752     elsif ($arg eq '-makenormtest')
753     {
754         $make_norm_test_script = 1;
755     }
756     elsif ($arg eq '-makelist') {
757         $make_list = 1;
758     }
759     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
760         -d $use_directory or croak "Unknown directory '$use_directory'";
761     }
762     elsif ($arg eq '-L') {
763
764         # Existence not tested until have chdir'd
765         $file_list = shift;
766     }
767     elsif ($arg eq '-globlist') {
768         $glob_list = 1;
769     }
770     elsif ($arg eq '-c') {
771         $output_range_counts = ! $output_range_counts
772     }
773     elsif ($arg eq '-annotate') {
774         $annotate = 1;
775         $debugging_build = 1;
776         $output_range_counts = 1;
777     }
778     else {
779         my $with_c = 'with';
780         $with_c .= 'out' if $output_range_counts;   # Complements the state
781         croak <<END;
782 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
783           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
784           [-check A B ]
785   -c          : Output comments $with_c number of code points in ranges
786   -q          : Quiet Mode: Only output serious warnings.
787   -p          : Set verbosity level to normal plus show progress.
788   -v          : Set Verbosity level high:  Show progress and non-serious
789                 warnings
790   -w          : Write files regardless
791   -C dir      : Change to this directory before proceeding. All relative paths
792                 except those specified by the -P and -T options will be done
793                 with respect to this directory.
794   -P dir      : Output $pod_file file to directory 'dir'.
795   -T path     : Create a test script as 'path'; overrides -maketest
796   -L filelist : Use alternate 'filelist' instead of standard one
797   -globlist   : Take as input all non-Test *.txt files in current and sub
798                 directories
799   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
800                 overrides -T
801   -makelist   : Rewrite the file list $file_list based on current setup
802   -annotate   : Output an annotation for each character in the table files;
803                 useful for debugging mktables, looking at diffs; but is slow
804                 and memory intensive
805   -check A B  : Executes $0 only if A and B are the same
806 END
807     }
808 }
809
810 # Stores the most-recently changed file.  If none have changed, can skip the
811 # build
812 my $most_recent = (stat $0)[9];   # Do this before the chdir!
813
814 # Change directories now, because need to read 'version' early.
815 if ($use_directory) {
816     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
817         $pod_directory = File::Spec->rel2abs($pod_directory);
818     }
819     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
820         $t_path = File::Spec->rel2abs($t_path);
821     }
822     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
823     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
824         $pod_directory = File::Spec->abs2rel($pod_directory);
825     }
826     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
827         $t_path = File::Spec->abs2rel($t_path);
828     }
829 }
830
831 # Get Unicode version into regular and v-string.  This is done now because
832 # various tables below get populated based on it.  These tables are populated
833 # here to be near the top of the file, and so easily seeable by those needing
834 # to modify things.
835 open my $VERSION, "<", "version"
836                     or croak "$0: can't open required file 'version': $!\n";
837 my $string_version = <$VERSION>;
838 close $VERSION;
839 chomp $string_version;
840 my $v_version = pack "C*", split /\./, $string_version;        # v string
841
842 my $unicode_version = ($compare_versions)
843                       ? (  "$string_compare_versions (using "
844                          . "$string_version rules)")
845                       : $string_version;
846
847 # The following are the complete names of properties with property values that
848 # are known to not match any code points in some versions of Unicode, but that
849 # may change in the future so they should be matchable, hence an empty file is
850 # generated for them.
851 my @tables_that_may_be_empty;
852 push @tables_that_may_be_empty, 'Joining_Type=Left_Joining'
853                                                     if $v_version lt v6.3.0;
854 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
855 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
856 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
857                                                     if $v_version ge v4.1.0;
858 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
859                                                     if $v_version ge v6.0.0;
860 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
861                                                     if $v_version ge v6.1.0;
862 push @tables_that_may_be_empty, 'Canonical_Combining_Class=CCC133'
863                                                     if $v_version ge v6.2.0;
864
865 # The lists below are hashes, so the key is the item in the list, and the
866 # value is the reason why it is in the list.  This makes generation of
867 # documentation easier.
868
869 my %why_suppressed;  # No file generated for these.
870
871 # Files aren't generated for empty extraneous properties.  This is arguable.
872 # Extraneous properties generally come about because a property is no longer
873 # used in a newer version of Unicode.  If we generated a file without code
874 # points, programs that used to work on that property will still execute
875 # without errors.  It just won't ever match (or will always match, with \P{}).
876 # This means that the logic is now likely wrong.  I (khw) think its better to
877 # find this out by getting an error message.  Just move them to the table
878 # above to change this behavior
879 my %why_suppress_if_empty_warn_if_not = (
880
881    # It is the only property that has ever officially been removed from the
882    # Standard.  The database never contained any code points for it.
883    'Special_Case_Condition' => 'Obsolete',
884
885    # Apparently never official, but there were code points in some versions of
886    # old-style PropList.txt
887    'Non_Break' => 'Obsolete',
888 );
889
890 # These would normally go in the warn table just above, but they were changed
891 # a long time before this program was written, so warnings about them are
892 # moot.
893 if ($v_version gt v3.2.0) {
894     push @tables_that_may_be_empty,
895                                 'Canonical_Combining_Class=Attached_Below_Left'
896 }
897
898 # Obsoleted
899 if ($v_version ge v11.0.0) {
900     push @tables_that_may_be_empty, qw(
901                                        Grapheme_Cluster_Break=E_Base
902                                        Grapheme_Cluster_Break=E_Base_GAZ
903                                        Grapheme_Cluster_Break=E_Modifier
904                                        Grapheme_Cluster_Break=Glue_After_Zwj
905                                        Word_Break=E_Base
906                                        Word_Break=E_Base_GAZ
907                                        Word_Break=E_Modifier
908                                        Word_Break=Glue_After_Zwj);
909 }
910
911 # Enum values for to_output_map() method in the Map_Table package. (0 is don't
912 # output)
913 my $EXTERNAL_MAP = 1;
914 my $INTERNAL_MAP = 2;
915 my $OUTPUT_ADJUSTED = 3;
916
917 # To override computed values for writing the map tables for these properties.
918 # The default for enum map tables is to write them out, so that the Unicode
919 # .txt files can be removed, but all the data to compute any property value
920 # for any code point is available in a more compact form.
921 my %global_to_output_map = (
922     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
923     # get stuck supporting it if things change.  Since it is a STRING
924     # property, it normally would be listed in the pod, but INTERNAL_MAP
925     # suppresses that.
926     Unicode_1_Name => $INTERNAL_MAP,
927
928     Present_In => 0,                # Suppress, as easily computed from Age
929     Block => (NON_ASCII_PLATFORM) ? 1 : 0,  # Suppress, as Blocks.txt is
930                                             # retained, but needed for
931                                             # non-ASCII
932
933     # Suppress, as mapping can be found instead from the
934     # Perl_Decomposition_Mapping file
935     Decomposition_Type => 0,
936 );
937
938 # There are several types of obsolete properties defined by Unicode.  These
939 # must be hand-edited for every new Unicode release.
940 my %why_deprecated;  # Generates a deprecated warning message if used.
941 my %why_stabilized;  # Documentation only
942 my %why_obsolete;    # Documentation only
943
944 {   # Closure
945     my $simple = 'Perl uses the more complete version';
946     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
947
948     my $other_properties = 'other properties';
949     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
950     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
951
952     %why_deprecated = (
953         'Grapheme_Link' => 'Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
954         'Jamo_Short_Name' => $contributory,
955         'Line_Break=Surrogate' => 'Surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
956         'Other_Alphabetic' => $contributory,
957         'Other_Default_Ignorable_Code_Point' => $contributory,
958         'Other_Grapheme_Extend' => $contributory,
959         'Other_ID_Continue' => $contributory,
960         'Other_ID_Start' => $contributory,
961         'Other_Lowercase' => $contributory,
962         'Other_Math' => $contributory,
963         'Other_Uppercase' => $contributory,
964         'Expands_On_NFC' => $why_no_expand,
965         'Expands_On_NFD' => $why_no_expand,
966         'Expands_On_NFKC' => $why_no_expand,
967         'Expands_On_NFKD' => $why_no_expand,
968     );
969
970     %why_suppressed = (
971         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
972         # contains the same information, but without the algorithmically
973         # determinable Hangul syllables'.  This file is not published, so it's
974         # existence is not noted in the comment.
975         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or prop_invmap() or charprop() in Unicode::UCD::',
976
977         # Don't suppress ISO_Comment, as otherwise special handling is needed
978         # to differentiate between it and gc=c, which can be written as 'isc',
979         # which is the same characters as ISO_Comment's short name.
980
981         'Name' => "Accessible via \\N{...} or 'use charnames;' or charprop() or prop_invmap() in Unicode::UCD::",
982
983         'Simple_Case_Folding' => "$simple.  Can access this through casefold(), charprop(), or prop_invmap() in Unicode::UCD",
984         'Simple_Lowercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
985         'Simple_Titlecase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
986         'Simple_Uppercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
987
988         FC_NFKC_Closure => 'Deprecated by Unicode, and supplanted in usage by NFKC_Casefold; otherwise not useful',
989     );
990
991     foreach my $property (
992
993             # The following are suppressed because they were made contributory
994             # or deprecated by Unicode before Perl ever thought about
995             # supporting them.
996             'Jamo_Short_Name',
997             'Grapheme_Link',
998             'Expands_On_NFC',
999             'Expands_On_NFD',
1000             'Expands_On_NFKC',
1001             'Expands_On_NFKD',
1002
1003             # The following are suppressed because they have been marked
1004             # as deprecated for a sufficient amount of time
1005             'Other_Alphabetic',
1006             'Other_Default_Ignorable_Code_Point',
1007             'Other_Grapheme_Extend',
1008             'Other_ID_Continue',
1009             'Other_ID_Start',
1010             'Other_Lowercase',
1011             'Other_Math',
1012             'Other_Uppercase',
1013     ) {
1014         $why_suppressed{$property} = $why_deprecated{$property};
1015     }
1016
1017     # Customize the message for all the 'Other_' properties
1018     foreach my $property (keys %why_deprecated) {
1019         next if (my $main_property = $property) !~ s/^Other_//;
1020         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
1021     }
1022 }
1023
1024 if ($write_Unicode_deprecated_tables) {
1025     foreach my $property (keys %why_suppressed) {
1026         delete $why_suppressed{$property} if $property =~
1027                                                     / ^ Other | Grapheme /x;
1028     }
1029 }
1030
1031 if ($v_version ge 4.0.0) {
1032     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
1033     if ($v_version ge 6.0.0) {
1034         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
1035     }
1036 }
1037 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
1038     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
1039     if ($v_version ge 6.0.0) {
1040         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
1041     }
1042 }
1043
1044 # Probably obsolete forever
1045 if ($v_version ge v4.1.0) {
1046     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
1047 }
1048 if ($v_version ge v6.0.0) {
1049     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana" (or both)';
1050     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
1051 }
1052
1053 # This program can create files for enumerated-like properties, such as
1054 # 'Numeric_Type'.  This file would be the same format as for a string
1055 # property, with a mapping from code point to its value, so you could look up,
1056 # for example, the script a code point is in.  But no one so far wants this
1057 # mapping, or they have found another way to get it since this is a new
1058 # feature.  So no file is generated except if it is in this list.
1059 my @output_mapped_properties = split "\n", <<END;
1060 END
1061
1062 # If you want more Unihan properties than the default, you need to add them to
1063 # these arrays.  Depending on the property type, @missing lines might have to
1064 # be added to the second array.  A sample entry would be (including the '#'):
1065 # @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1066 my @cjk_properties = split "\n", <<'END';
1067 END
1068 my @cjk_property_values = split "\n", <<'END';
1069 END
1070
1071 # The input files don't list every code point.  Those not listed are to be
1072 # defaulted to some value.  Below are hard-coded what those values are for
1073 # non-binary properties as of 5.1.  Starting in 5.0, there are
1074 # machine-parsable comment lines in the files that give the defaults; so this
1075 # list shouldn't have to be extended.  The claim is that all missing entries
1076 # for binary properties will default to 'N'.  Unicode tried to change that in
1077 # 5.2, but the beta period produced enough protest that they backed off.
1078 #
1079 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1080 # be in the form that it expects.  The others may be synonyms.
1081 my $CODE_POINT = '<code point>';
1082 my %default_mapping = (
1083     Age => "Unassigned",
1084     # Bidi_Class => Complicated; set in code
1085     Bidi_Mirroring_Glyph => "",
1086     Block => 'No_Block',
1087     Canonical_Combining_Class => 0,
1088     Case_Folding => $CODE_POINT,
1089     Decomposition_Mapping => $CODE_POINT,
1090     Decomposition_Type => 'None',
1091     East_Asian_Width => "Neutral",
1092     FC_NFKC_Closure => $CODE_POINT,
1093     General_Category => ($v_version le 6.3.0) ? 'Cn' : 'Unassigned',
1094     Grapheme_Cluster_Break => 'Other',
1095     Hangul_Syllable_Type => 'NA',
1096     ISO_Comment => "",
1097     Jamo_Short_Name => "",
1098     Joining_Group => "No_Joining_Group",
1099     # Joining_Type => Complicated; set in code
1100     kIICore => 'N',   #                       Is converted to binary
1101     #Line_Break => Complicated; set in code
1102     Lowercase_Mapping => $CODE_POINT,
1103     Name => "",
1104     Name_Alias => "",
1105     NFC_QC => 'Yes',
1106     NFD_QC => 'Yes',
1107     NFKC_QC => 'Yes',
1108     NFKD_QC => 'Yes',
1109     Numeric_Type => 'None',
1110     Numeric_Value => 'NaN',
1111     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1112     Sentence_Break => 'Other',
1113     Simple_Case_Folding => $CODE_POINT,
1114     Simple_Lowercase_Mapping => $CODE_POINT,
1115     Simple_Titlecase_Mapping => $CODE_POINT,
1116     Simple_Uppercase_Mapping => $CODE_POINT,
1117     Titlecase_Mapping => $CODE_POINT,
1118     Unicode_1_Name => "",
1119     Unicode_Radical_Stroke => "",
1120     Uppercase_Mapping => $CODE_POINT,
1121     Word_Break => 'Other',
1122 );
1123
1124 ### End of externally interesting definitions, except for @input_file_objects
1125
1126 my $HEADER=<<"EOF";
1127 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1128 # This file is machine-generated by $0 from the Unicode
1129 # database, Version $unicode_version.  Any changes made here will be lost!
1130 EOF
1131
1132 my $INTERNAL_ONLY_HEADER = <<"EOF";
1133
1134 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1135 # This file is for internal use by core Perl only.  The format and even the
1136 # name or existence of this file are subject to change without notice.  Don't
1137 # use it directly.  Use Unicode::UCD to access the Unicode character data
1138 # base.
1139 EOF
1140
1141 my $DEVELOPMENT_ONLY=<<"EOF";
1142 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1143 # This file contains information artificially constrained to code points
1144 # present in Unicode release $string_compare_versions.
1145 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1146 # not be used for production.
1147
1148 EOF
1149
1150 my $MAX_UNICODE_CODEPOINT_STRING = ($v_version ge v2.0.0)
1151                                    ? "10FFFF"
1152                                    : "FFFF";
1153 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1154 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1155
1156 # We work with above-Unicode code points, up to IV_MAX, but we may want to use
1157 # sentinels above that number.  Therefore for internal use, we use a much
1158 # smaller number, translating it to IV_MAX only for output.  The exact number
1159 # is immaterial (all above-Unicode code points are treated exactly the same),
1160 # but the algorithm requires it to be at least
1161 # 2 * $MAX_UNICODE_CODEPOINTS + 1
1162 my $MAX_WORKING_CODEPOINTS= $MAX_UNICODE_CODEPOINT * 8;
1163 my $MAX_WORKING_CODEPOINT = $MAX_WORKING_CODEPOINTS - 1;
1164 my $MAX_WORKING_CODEPOINT_STRING = sprintf("%X", $MAX_WORKING_CODEPOINT);
1165
1166 my $MAX_PLATFORM_CODEPOINT = ~0 >> 1;
1167
1168 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1169 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1170 # to decrease backtracking.  The first regex allows the code point to be at
1171 # the end of a word, but to work properly, the word shouldn't end with a valid
1172 # hex character.  The second one won't match a code point at the end of a
1173 # word, and doesn't have the run-on issue
1174 my $run_on_code_point_re =
1175             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1176 my $code_point_re = qr/\b$run_on_code_point_re/;
1177
1178 # This matches the beginning of the line in the Unicode DB files that give the
1179 # defaults for code points not listed (i.e., missing) in the file.  The code
1180 # depends on this ending with a semi-colon, so it can assume it is a valid
1181 # field when the line is split() by semi-colons
1182 my $missing_defaults_prefix = qr/^#\s+\@missing:\s+0000\.\.10FFFF\s*;/;
1183
1184 # Property types.  Unicode has more types, but these are sufficient for our
1185 # purposes.
1186 my $UNKNOWN = -1;   # initialized to illegal value
1187 my $NON_STRING = 1; # Either binary or enum
1188 my $BINARY = 2;
1189 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1190                        # tables, additional true and false tables are
1191                        # generated so that false is anything matching the
1192                        # default value, and true is everything else.
1193 my $ENUM = 4;       # Include catalog
1194 my $STRING = 5;     # Anything else: string or misc
1195
1196 # Some input files have lines that give default values for code points not
1197 # contained in the file.  Sometimes these should be ignored.
1198 my $NO_DEFAULTS = 0;        # Must evaluate to false
1199 my $NOT_IGNORED = 1;
1200 my $IGNORED = 2;
1201
1202 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1203 # and will appear in the main body of the tables in the output files, but
1204 # there are other types of ranges as well, listed below, that are specially
1205 # handled.   There are pseudo-types as well that will never be stored as a
1206 # type, but will affect the calculation of the type.
1207
1208 # 0 is for normal, non-specials
1209 my $MULTI_CP = 1;           # Sequence of more than code point
1210 my $HANGUL_SYLLABLE = 2;
1211 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1212 my $NULL = 4;               # The map is to the null string; utf8.c can't
1213                             # handle these, nor is there an accepted syntax
1214                             # for them in \p{} constructs
1215 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1216                              # otherwise be $MULTI_CP type are instead type 0
1217
1218 # process_generic_property_file() can accept certain overrides in its input.
1219 # Each of these must begin AND end with $CMD_DELIM.
1220 my $CMD_DELIM = "\a";
1221 my $REPLACE_CMD = 'replace';    # Override the Replace
1222 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1223
1224 my $NO = 0;
1225 my $YES = 1;
1226
1227 # Values for the Replace argument to add_range.
1228 # $NO                      # Don't replace; add only the code points not
1229                            # already present.
1230 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1231                            # the comments at the subroutine definition.
1232 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1233 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1234                            # already there
1235 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1236                            # already there
1237 my $CROAK = 6;             # Die with an error if is already there
1238
1239 # Flags to give property statuses.  The phrases are to remind maintainers that
1240 # if the flag is changed, the indefinite article referring to it in the
1241 # documentation may need to be as well.
1242 my $NORMAL = "";
1243 my $DEPRECATED = 'D';
1244 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1245 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1246 my $DISCOURAGED = 'X';
1247 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1248 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1249 my $STRICTER = 'T';
1250 my $a_bold_stricter = "a 'B<$STRICTER>'";
1251 my $A_bold_stricter = "A 'B<$STRICTER>'";
1252 my $STABILIZED = 'S';
1253 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1254 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1255 my $OBSOLETE = 'O';
1256 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1257 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1258
1259 # Aliases can also have an extra status:
1260 my $INTERNAL_ALIAS = 'P';
1261
1262 my %status_past_participles = (
1263     $DISCOURAGED => 'discouraged',
1264     $STABILIZED => 'stabilized',
1265     $OBSOLETE => 'obsolete',
1266     $DEPRECATED => 'deprecated',
1267     $INTERNAL_ALIAS => 'reserved for Perl core internal use only',
1268 );
1269
1270 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1271 # externally documented.
1272 my $ORDINARY = 0;       # The normal fate.
1273 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1274                         # but there is a file written that can be used to
1275                         # reconstruct this table
1276 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1277                         # for Perl's internal use only
1278 my $LEGACY_ONLY = 3;    # Like $INTERNAL_ONLY, but not actually used by Perl.
1279                         # Is for backwards compatibility for applications that
1280                         # read the file directly, so it's format is
1281                         # unchangeable.
1282 my $SUPPRESSED = 4;     # The file for this table is not written out, and as a
1283                         # result, we don't bother to do many computations on
1284                         # it.
1285 my $PLACEHOLDER = 5;    # Like $SUPPRESSED, but we go through all the
1286                         # computations anyway, as the values are needed for
1287                         # things to work.  This happens when we have Perl
1288                         # extensions that depend on Unicode tables that
1289                         # wouldn't normally be in a given Unicode version.
1290
1291 # The format of the values of the tables:
1292 my $EMPTY_FORMAT = "";
1293 my $BINARY_FORMAT = 'b';
1294 my $DECIMAL_FORMAT = 'd';
1295 my $FLOAT_FORMAT = 'f';
1296 my $INTEGER_FORMAT = 'i';
1297 my $HEX_FORMAT = 'x';
1298 my $RATIONAL_FORMAT = 'r';
1299 my $STRING_FORMAT = 's';
1300 my $ADJUST_FORMAT = 'a';
1301 my $HEX_ADJUST_FORMAT = 'ax';
1302 my $DECOMP_STRING_FORMAT = 'c';
1303 my $STRING_WHITE_SPACE_LIST = 'sw';
1304
1305 my %map_table_formats = (
1306     $BINARY_FORMAT => 'binary',
1307     $DECIMAL_FORMAT => 'single decimal digit',
1308     $FLOAT_FORMAT => 'floating point number',
1309     $INTEGER_FORMAT => 'integer',
1310     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1311     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1312     $STRING_FORMAT => 'string',
1313     $ADJUST_FORMAT => 'some entries need adjustment',
1314     $HEX_ADJUST_FORMAT => 'mapped value in hex; some entries need adjustment',
1315     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1316     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1317 );
1318
1319 # Unicode didn't put such derived files in a separate directory at first.
1320 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1321 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1322 my $AUXILIARY = 'auxiliary';
1323
1324 # Hashes and arrays that will eventually go into UCD.pl for the use of UCD.pm
1325 my %loose_to_file_of;       # loosely maps table names to their respective
1326                             # files
1327 my %stricter_to_file_of;    # same; but for stricter mapping.
1328 my %loose_property_to_file_of; # Maps a loose property name to its map file
1329 my %strict_property_to_file_of; # Same, but strict
1330 my @inline_definitions = "V0"; # Each element gives a definition of a unique
1331                             # inversion list.  When a definition is inlined,
1332                             # its value in the hash it's in (one of the two
1333                             # defined just above) will include an index into
1334                             # this array.  The 0th element is initialized to
1335                             # the definition for a zero length inversion list
1336 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1337                             # in the hash %Unicode::UCD::SwashInfo
1338 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1339                              # their rational equivalent
1340 my %loose_property_name_of; # Loosely maps (non_string) property names to
1341                             # standard form
1342 my %strict_property_name_of; # Strictly maps (non_string) property names to
1343                             # standard form
1344 my %string_property_loose_to_name; # Same, for string properties.
1345 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1346                             # the property name in standard loose form, and
1347                             # 'value' is the default value for that property,
1348                             # also in standard loose form.
1349 my %loose_to_standard_value; # loosely maps table names to the canonical
1350                             # alias for them
1351 my %ambiguous_names;        # keys are alias names (in standard form) that
1352                             # have more than one possible meaning.
1353 my %combination_property;   # keys are alias names (in standard form) that
1354                             # have both a map table, and a binary one that
1355                             # yields true for all non-null maps.
1356 my %prop_aliases;           # Keys are standard property name; values are each
1357                             # one's aliases
1358 my %prop_value_aliases;     # Keys of top level are standard property name;
1359                             # values are keys to another hash,  Each one is
1360                             # one of the property's values, in standard form.
1361                             # The values are that prop-val's aliases.
1362 my %skipped_files;          # List of files that we skip
1363 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1364
1365 # Most properties are immune to caseless matching, otherwise you would get
1366 # nonsensical results, as properties are a function of a code point, not
1367 # everything that is caselessly equivalent to that code point.  For example,
1368 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1369 # be true because 's' and 'S' are equivalent caselessly.  However,
1370 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1371 # extend that concept to those very few properties that are like this.  Each
1372 # such property will match the full range caselessly.  They are hard-coded in
1373 # the program; it's not worth trying to make it general as it's extremely
1374 # unlikely that they will ever change.
1375 my %caseless_equivalent_to;
1376
1377 # This is the range of characters that were in Release 1 of Unicode, and
1378 # removed in Release 2 (replaced with the current Hangul syllables starting at
1379 # U+AC00).  The range was reused starting in Release 3 for other purposes.
1380 my $FIRST_REMOVED_HANGUL_SYLLABLE = 0x3400;
1381 my $FINAL_REMOVED_HANGUL_SYLLABLE = 0x4DFF;
1382
1383 # These constants names and values were taken from the Unicode standard,
1384 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1385 # syllables.  The '_string' versions are so generated tables can retain the
1386 # hex format, which is the more familiar value
1387 my $SBase_string = "0xAC00";
1388 my $SBase = CORE::hex $SBase_string;
1389 my $LBase_string = "0x1100";
1390 my $LBase = CORE::hex $LBase_string;
1391 my $VBase_string = "0x1161";
1392 my $VBase = CORE::hex $VBase_string;
1393 my $TBase_string = "0x11A7";
1394 my $TBase = CORE::hex $TBase_string;
1395 my $SCount = 11172;
1396 my $LCount = 19;
1397 my $VCount = 21;
1398 my $TCount = 28;
1399 my $NCount = $VCount * $TCount;
1400
1401 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1402 # with the above published constants.
1403 my %Jamo;
1404 my %Jamo_L;     # Leading consonants
1405 my %Jamo_V;     # Vowels
1406 my %Jamo_T;     # Trailing consonants
1407
1408 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1409 # The key is the base name of the code point, and the value is an
1410 # array giving all the ranges that use this base name.  Each range
1411 # is actually a hash giving the 'low' and 'high' values of it.
1412 my %names_ending_in_code_point;
1413 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1414                                         # removed from the names
1415 # Inverse mapping.  The list of ranges that have these kinds of
1416 # names.  Each element contains the low, high, and base names in an
1417 # anonymous hash.
1418 my @code_points_ending_in_code_point;
1419
1420 # To hold Unicode's normalization test suite
1421 my @normalization_tests;
1422
1423 # Boolean: does this Unicode version have the hangul syllables, and are we
1424 # writing out a table for them?
1425 my $has_hangul_syllables = 0;
1426
1427 # Does this Unicode version have code points whose names end in their
1428 # respective code points, and are we writing out a table for them?  0 for no;
1429 # otherwise points to first property that a table is needed for them, so that
1430 # if multiple tables are needed, we don't create duplicates
1431 my $needing_code_points_ending_in_code_point = 0;
1432
1433 my @backslash_X_tests;     # List of tests read in for testing \X
1434 my @LB_tests;              # List of tests read in for testing \b{lb}
1435 my @SB_tests;              # List of tests read in for testing \b{sb}
1436 my @WB_tests;              # List of tests read in for testing \b{wb}
1437 my @unhandled_properties;  # Will contain a list of properties found in
1438                            # the input that we didn't process.
1439 my @match_properties;      # Properties that have match tables, to be
1440                            # listed in the pod
1441 my @map_properties;        # Properties that get map files written
1442 my @named_sequences;       # NamedSequences.txt contents.
1443 my %potential_files;       # Generated list of all .txt files in the directory
1444                            # structure so we can warn if something is being
1445                            # ignored.
1446 my @missing_early_files;   # Generated list of absent files that we need to
1447                            # proceed in compiling this early Unicode version
1448 my @files_actually_output; # List of files we generated.
1449 my @more_Names;            # Some code point names are compound; this is used
1450                            # to store the extra components of them.
1451 my $E_FLOAT_PRECISION = 2; # The minimum number of digits after the decimal
1452                            # point of a normalized floating point number
1453                            # needed to match before we consider it equivalent
1454                            # to a candidate rational
1455
1456 # These store references to certain commonly used property objects
1457 my $age;
1458 my $ccc;
1459 my $gc;
1460 my $perl;
1461 my $block;
1462 my $perl_charname;
1463 my $print;
1464 my $All;
1465 my $Assigned;   # All assigned characters in this Unicode release
1466 my $DI;         # Default_Ignorable_Code_Point property
1467 my $NChar;      # Noncharacter_Code_Point property
1468 my $script;
1469 my $scx;        # Script_Extensions property
1470
1471 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1472 my $has_In_conflicts = 0;
1473 my $has_Is_conflicts = 0;
1474
1475 sub internal_file_to_platform ($) {
1476     # Convert our file paths which have '/' separators to those of the
1477     # platform.
1478
1479     my $file = shift;
1480     return undef unless defined $file;
1481
1482     return File::Spec->join(split '/', $file);
1483 }
1484
1485 sub file_exists ($) {   # platform independent '-e'.  This program internally
1486                         # uses slash as a path separator.
1487     my $file = shift;
1488     return 0 if ! defined $file;
1489     return -e internal_file_to_platform($file);
1490 }
1491
1492 sub objaddr($) {
1493     # Returns the address of the blessed input object.
1494     # It doesn't check for blessedness because that would do a string eval
1495     # every call, and the program is structured so that this is never called
1496     # for a non-blessed object.
1497
1498     no overloading; # If overloaded, numifying below won't work.
1499
1500     # Numifying a ref gives its address.
1501     return pack 'J', $_[0];
1502 }
1503
1504 # These are used only if $annotate is true.
1505 # The entire range of Unicode characters is examined to populate these
1506 # after all the input has been processed.  But most can be skipped, as they
1507 # have the same descriptive phrases, such as being unassigned
1508 my @viacode;            # Contains the 1 million character names
1509 my @age;                # And their ages ("" if none)
1510 my @printable;          # boolean: And are those characters printable?
1511 my @annotate_char_type; # Contains a type of those characters, specifically
1512                         # for the purposes of annotation.
1513 my $annotate_ranges;    # A map of ranges of code points that have the same
1514                         # name for the purposes of annotation.  They map to the
1515                         # upper edge of the range, so that the end point can
1516                         # be immediately found.  This is used to skip ahead to
1517                         # the end of a range, and avoid processing each
1518                         # individual code point in it.
1519 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1520                                    # characters, but excluding those which are
1521                                    # also noncharacter code points
1522
1523 # The annotation types are an extension of the regular range types, though
1524 # some of the latter are folded into one.  Make the new types negative to
1525 # avoid conflicting with the regular types
1526 my $SURROGATE_TYPE = -1;
1527 my $UNASSIGNED_TYPE = -2;
1528 my $PRIVATE_USE_TYPE = -3;
1529 my $NONCHARACTER_TYPE = -4;
1530 my $CONTROL_TYPE = -5;
1531 my $ABOVE_UNICODE_TYPE = -6;
1532 my $UNKNOWN_TYPE = -7;  # Used only if there is a bug in this program
1533
1534 sub populate_char_info ($) {
1535     # Used only with the $annotate option.  Populates the arrays with the
1536     # input code point's info that are needed for outputting more detailed
1537     # comments.  If calling context wants a return, it is the end point of
1538     # any contiguous range of characters that share essentially the same info
1539
1540     my $i = shift;
1541     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1542
1543     $viacode[$i] = $perl_charname->value_of($i) || "";
1544     $age[$i] = (defined $age)
1545                ? (($age->value_of($i) =~ / ^ \d+ \. \d+ $ /x)
1546                   ? $age->value_of($i)
1547                   : "")
1548                : "";
1549
1550     # A character is generally printable if Unicode says it is,
1551     # but below we make sure that most Unicode general category 'C' types
1552     # aren't.
1553     $printable[$i] = $print->contains($i);
1554
1555     # But the characters in this range were removed in v2.0 and replaced by
1556     # different ones later.  Modern fonts will be for the replacement
1557     # characters, so suppress printing them.
1558     if (($v_version lt v2.0
1559          || ($compare_versions && $compare_versions lt v2.0))
1560         && (   $i >= $FIRST_REMOVED_HANGUL_SYLLABLE
1561             && $i <= $FINAL_REMOVED_HANGUL_SYLLABLE))
1562     {
1563         $printable[$i] = 0;
1564     }
1565
1566     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1567
1568     # Only these two regular types are treated specially for annotations
1569     # purposes
1570     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1571                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1572
1573     # Give a generic name to all code points that don't have a real name.
1574     # We output ranges, if applicable, for these.  Also calculate the end
1575     # point of the range.
1576     my $end;
1577     if (! $viacode[$i]) {
1578         if ($i > $MAX_UNICODE_CODEPOINT) {
1579             $viacode[$i] = 'Above-Unicode';
1580             $annotate_char_type[$i] = $ABOVE_UNICODE_TYPE;
1581             $printable[$i] = 0;
1582             $end = $MAX_WORKING_CODEPOINT;
1583         }
1584         elsif ($gc-> table('Private_use')->contains($i)) {
1585             $viacode[$i] = 'Private Use';
1586             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1587             $printable[$i] = 0;
1588             $end = $gc->table('Private_Use')->containing_range($i)->end;
1589         }
1590         elsif ($NChar->contains($i)) {
1591             $viacode[$i] = 'Noncharacter';
1592             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1593             $printable[$i] = 0;
1594             $end = $NChar->containing_range($i)->end;
1595         }
1596         elsif ($gc-> table('Control')->contains($i)) {
1597             my $name_ref = property_ref('Name_Alias');
1598             $name_ref = property_ref('Unicode_1_Name') if ! defined $name_ref;
1599             $viacode[$i] = (defined $name_ref)
1600                            ? $name_ref->value_of($i)
1601                            : 'Control';
1602             $annotate_char_type[$i] = $CONTROL_TYPE;
1603             $printable[$i] = 0;
1604         }
1605         elsif ($gc-> table('Unassigned')->contains($i)) {
1606             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1607             $printable[$i] = 0;
1608             $viacode[$i] = 'Unassigned';
1609
1610             if (defined $block) { # No blocks in earliest releases
1611                 $viacode[$i] .= ', block=' . $block-> value_of($i);
1612                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1613
1614                 # Because we name the unassigned by the blocks they are in, it
1615                 # can't go past the end of that block, and it also can't go
1616                 # past the unassigned range it is in.  The special table makes
1617                 # sure that the non-characters, which are unassigned, are
1618                 # separated out.
1619                 $end = min($block->containing_range($i)->end,
1620                            $unassigned_sans_noncharacters->
1621                                                     containing_range($i)->end);
1622             }
1623             else {
1624                 $end = $i + 1;
1625                 while ($unassigned_sans_noncharacters->contains($end)) {
1626                     $end++;
1627                 }
1628                 $end--;
1629             }
1630         }
1631         elsif ($perl->table('_Perl_Surrogate')->contains($i)) {
1632             $viacode[$i] = 'Surrogate';
1633             $annotate_char_type[$i] = $SURROGATE_TYPE;
1634             $printable[$i] = 0;
1635             $end = $gc->table('Surrogate')->containing_range($i)->end;
1636         }
1637         else {
1638             Carp::my_carp_bug("Can't figure out how to annotate "
1639                               . sprintf("U+%04X", $i)
1640                               . ".  Proceeding anyway.");
1641             $viacode[$i] = 'UNKNOWN';
1642             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1643             $printable[$i] = 0;
1644         }
1645     }
1646
1647     # Here, has a name, but if it's one in which the code point number is
1648     # appended to the name, do that.
1649     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1650         $viacode[$i] .= sprintf("-%04X", $i);
1651
1652         my $limit = $perl_charname->containing_range($i)->end;
1653         if (defined $age) {
1654             # Do all these as groups of the same age, instead of individually,
1655             # because their names are so meaningless, and there are typically
1656             # large quantities of them.
1657             $end = $i + 1;
1658             while ($end <= $limit && $age->value_of($end) == $age[$i]) {
1659                 $end++;
1660             }
1661             $end--;
1662         }
1663         else {
1664             $end = $limit;
1665         }
1666     }
1667
1668     # And here, has a name, but if it's a hangul syllable one, replace it with
1669     # the correct name from the Unicode algorithm
1670     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1671         use integer;
1672         my $SIndex = $i - $SBase;
1673         my $L = $LBase + $SIndex / $NCount;
1674         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1675         my $T = $TBase + $SIndex % $TCount;
1676         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1677         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1678         $end = $perl_charname->containing_range($i)->end;
1679     }
1680
1681     return if ! defined wantarray;
1682     return $i if ! defined $end;    # If not a range, return the input
1683
1684     # Save this whole range so can find the end point quickly
1685     $annotate_ranges->add_map($i, $end, $end);
1686
1687     return $end;
1688 }
1689
1690 # Commented code below should work on Perl 5.8.
1691 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1692 ## the native perl version of it (which is what would operate under miniperl)
1693 ## is extremely slow, as it does a string eval every call.
1694 #my $has_fast_scalar_util = $^X !~ /miniperl/
1695 #                            && defined eval "require Scalar::Util";
1696 #
1697 #sub objaddr($) {
1698 #    # Returns the address of the blessed input object.  Uses the XS version if
1699 #    # available.  It doesn't check for blessedness because that would do a
1700 #    # string eval every call, and the program is structured so that this is
1701 #    # never called for a non-blessed object.
1702 #
1703 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1704 #
1705 #    # Check at least that is a ref.
1706 #    my $pkg = ref($_[0]) or return undef;
1707 #
1708 #    # Change to a fake package to defeat any overloaded stringify
1709 #    bless $_[0], 'main::Fake';
1710 #
1711 #    # Numifying a ref gives its address.
1712 #    my $addr = pack 'J', $_[0];
1713 #
1714 #    # Return to original class
1715 #    bless $_[0], $pkg;
1716 #    return $addr;
1717 #}
1718
1719 sub max ($$) {
1720     my $a = shift;
1721     my $b = shift;
1722     return $a if $a >= $b;
1723     return $b;
1724 }
1725
1726 sub min ($$) {
1727     my $a = shift;
1728     my $b = shift;
1729     return $a if $a <= $b;
1730     return $b;
1731 }
1732
1733 sub clarify_number ($) {
1734     # This returns the input number with underscores inserted every 3 digits
1735     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1736     # checked.
1737
1738     my $number = shift;
1739     my $pos = length($number) - 3;
1740     return $number if $pos <= 1;
1741     while ($pos > 0) {
1742         substr($number, $pos, 0) = '_';
1743         $pos -= 3;
1744     }
1745     return $number;
1746 }
1747
1748 sub clarify_code_point_count ($) {
1749     # This is like clarify_number(), but the input is assumed to be a count of
1750     # code points, rather than a generic number.
1751
1752     my $append = "";
1753
1754     my $number = shift;
1755     if ($number > $MAX_UNICODE_CODEPOINTS) {
1756         $number -= ($MAX_WORKING_CODEPOINTS - $MAX_UNICODE_CODEPOINTS);
1757         return "All above-Unicode code points" if $number == 0;
1758         $append = " + all above-Unicode code points";
1759     }
1760     return clarify_number($number) . $append;
1761 }
1762
1763 package Carp;
1764
1765 # These routines give a uniform treatment of messages in this program.  They
1766 # are placed in the Carp package to cause the stack trace to not include them,
1767 # although an alternative would be to use another package and set @CARP_NOT
1768 # for it.
1769
1770 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1771
1772 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1773 # and overload trying to load Scalar:Util under miniperl.  See
1774 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1775 undef $overload::VERSION;
1776
1777 sub my_carp {
1778     my $message = shift || "";
1779     my $nofold = shift || 0;
1780
1781     if ($message) {
1782         $message = main::join_lines($message);
1783         $message =~ s/^$0: *//;     # Remove initial program name
1784         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1785         $message = "\n$0: $message;";
1786
1787         # Fold the message with program name, semi-colon end punctuation
1788         # (which looks good with the message that carp appends to it), and a
1789         # hanging indent for continuation lines.
1790         $message = main::simple_fold($message, "", 4) unless $nofold;
1791         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1792                                     # appends is to the same line
1793     }
1794
1795     return $message if defined wantarray;   # If a caller just wants the msg
1796
1797     carp $message;
1798     return;
1799 }
1800
1801 sub my_carp_bug {
1802     # This is called when it is clear that the problem is caused by a bug in
1803     # this program.
1804
1805     my $message = shift;
1806     $message =~ s/^$0: *//;
1807     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1808     carp $message;
1809     return;
1810 }
1811
1812 sub carp_too_few_args {
1813     if (@_ != 2) {
1814         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1815         return;
1816     }
1817
1818     my $args_ref = shift;
1819     my $count = shift;
1820
1821     my_carp_bug("Need at least $count arguments to "
1822         . (caller 1)[3]
1823         . ".  Instead got: '"
1824         . join ', ', @$args_ref
1825         . "'.  No action taken.");
1826     return;
1827 }
1828
1829 sub carp_extra_args {
1830     my $args_ref = shift;
1831     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1832
1833     unless (ref $args_ref) {
1834         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1835         return;
1836     }
1837     my ($package, $file, $line) = caller;
1838     my $subroutine = (caller 1)[3];
1839
1840     my $list;
1841     if (ref $args_ref eq 'HASH') {
1842         foreach my $key (keys %$args_ref) {
1843             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1844         }
1845         $list = join ', ', each %{$args_ref};
1846     }
1847     elsif (ref $args_ref eq 'ARRAY') {
1848         foreach my $arg (@$args_ref) {
1849             $arg = $UNDEF unless defined $arg;
1850         }
1851         $list = join ', ', @$args_ref;
1852     }
1853     else {
1854         my_carp_bug("Can't cope with ref "
1855                 . ref($args_ref)
1856                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1857         return;
1858     }
1859
1860     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1861     return;
1862 }
1863
1864 package main;
1865
1866 { # Closure
1867
1868     # This program uses the inside-out method for objects, as recommended in
1869     # "Perl Best Practices".  (This is the best solution still, since this has
1870     # to run under miniperl.)  This closure aids in generating those.  There
1871     # are two routines.  setup_package() is called once per package to set
1872     # things up, and then set_access() is called for each hash representing a
1873     # field in the object.  These routines arrange for the object to be
1874     # properly destroyed when no longer used, and for standard accessor
1875     # functions to be generated.  If you need more complex accessors, just
1876     # write your own and leave those accesses out of the call to set_access().
1877     # More details below.
1878
1879     my %constructor_fields; # fields that are to be used in constructors; see
1880                             # below
1881
1882     # The values of this hash will be the package names as keys to other
1883     # hashes containing the name of each field in the package as keys, and
1884     # references to their respective hashes as values.
1885     my %package_fields;
1886
1887     sub setup_package {
1888         # Sets up the package, creating standard DESTROY and dump methods
1889         # (unless already defined).  The dump method is used in debugging by
1890         # simple_dumper().
1891         # The optional parameters are:
1892         #   a)  a reference to a hash, that gets populated by later
1893         #       set_access() calls with one of the accesses being
1894         #       'constructor'.  The caller can then refer to this, but it is
1895         #       not otherwise used by these two routines.
1896         #   b)  a reference to a callback routine to call during destruction
1897         #       of the object, before any fields are actually destroyed
1898
1899         my %args = @_;
1900         my $constructor_ref = delete $args{'Constructor_Fields'};
1901         my $destroy_callback = delete $args{'Destroy_Callback'};
1902         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1903
1904         my %fields;
1905         my $package = (caller)[0];
1906
1907         $package_fields{$package} = \%fields;
1908         $constructor_fields{$package} = $constructor_ref;
1909
1910         unless ($package->can('DESTROY')) {
1911             my $destroy_name = "${package}::DESTROY";
1912             no strict "refs";
1913
1914             # Use typeglob to give the anonymous subroutine the name we want
1915             *$destroy_name = sub {
1916                 my $self = shift;
1917                 my $addr = do { no overloading; pack 'J', $self; };
1918
1919                 $self->$destroy_callback if $destroy_callback;
1920                 foreach my $field (keys %{$package_fields{$package}}) {
1921                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1922                     delete $package_fields{$package}{$field}{$addr};
1923                 }
1924                 return;
1925             }
1926         }
1927
1928         unless ($package->can('dump')) {
1929             my $dump_name = "${package}::dump";
1930             no strict "refs";
1931             *$dump_name = sub {
1932                 my $self = shift;
1933                 return dump_inside_out($self, $package_fields{$package}, @_);
1934             }
1935         }
1936         return;
1937     }
1938
1939     sub set_access {
1940         # Arrange for the input field to be garbage collected when no longer
1941         # needed.  Also, creates standard accessor functions for the field
1942         # based on the optional parameters-- none if none of these parameters:
1943         #   'addable'    creates an 'add_NAME()' accessor function.
1944         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1945         #                function.
1946         #   'settable'   creates a 'set_NAME()' accessor function.
1947         #   'constructor' doesn't create an accessor function, but adds the
1948         #                field to the hash that was previously passed to
1949         #                setup_package();
1950         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1951         # 'add' etc. all mean 'addable'.
1952         # The read accessor function will work on both array and scalar
1953         # values.  If another accessor in the parameter list is 'a', the read
1954         # access assumes an array.  You can also force it to be array access
1955         # by specifying 'readable_array' instead of 'readable'
1956         #
1957         # A sort-of 'protected' access can be set-up by preceding the addable,
1958         # readable or settable with some initial portion of 'protected_' (but,
1959         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1960         # "protection" is only by convention.  All that happens is that the
1961         # accessor functions' names begin with an underscore.  So instead of
1962         # calling set_foo, the call is _set_foo.  (Real protection could be
1963         # accomplished by having a new subroutine, end_package, called at the
1964         # end of each package, and then storing the __LINE__ ranges and
1965         # checking them on every accessor.  But that is way overkill.)
1966
1967         # We create anonymous subroutines as the accessors and then use
1968         # typeglobs to assign them to the proper package and name
1969
1970         my $name = shift;   # Name of the field
1971         my $field = shift;  # Reference to the inside-out hash containing the
1972                             # field
1973
1974         my $package = (caller)[0];
1975
1976         if (! exists $package_fields{$package}) {
1977             croak "$0: Must call 'setup_package' before 'set_access'";
1978         }
1979
1980         # Stash the field so DESTROY can get it.
1981         $package_fields{$package}{$name} = $field;
1982
1983         # Remaining arguments are the accessors.  For each...
1984         foreach my $access (@_) {
1985             my $access = lc $access;
1986
1987             my $protected = "";
1988
1989             # Match the input as far as it goes.
1990             if ($access =~ /^(p[^_]*)_/) {
1991                 $protected = $1;
1992                 if (substr('protected_', 0, length $protected)
1993                     eq $protected)
1994                 {
1995
1996                     # Add 1 for the underscore not included in $protected
1997                     $access = substr($access, length($protected) + 1);
1998                     $protected = '_';
1999                 }
2000                 else {
2001                     $protected = "";
2002                 }
2003             }
2004
2005             if (substr('addable', 0, length $access) eq $access) {
2006                 my $subname = "${package}::${protected}add_$name";
2007                 no strict "refs";
2008
2009                 # add_ accessor.  Don't add if already there, which we
2010                 # determine using 'eq' for scalars and '==' otherwise.
2011                 *$subname = sub {
2012                     use strict "refs";
2013                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2014                     my $self = shift;
2015                     my $value = shift;
2016                     my $addr = do { no overloading; pack 'J', $self; };
2017                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2018                     if (ref $value) {
2019                         return if grep { $value == $_ } @{$field->{$addr}};
2020                     }
2021                     else {
2022                         return if grep { $value eq $_ } @{$field->{$addr}};
2023                     }
2024                     push @{$field->{$addr}}, $value;
2025                     return;
2026                 }
2027             }
2028             elsif (substr('constructor', 0, length $access) eq $access) {
2029                 if ($protected) {
2030                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
2031                 }
2032                 else {
2033                     $constructor_fields{$package}{$name} = $field;
2034                 }
2035             }
2036             elsif (substr('readable_array', 0, length $access) eq $access) {
2037
2038                 # Here has read access.  If one of the other parameters for
2039                 # access is array, or this one specifies array (by being more
2040                 # than just 'readable_'), then create a subroutine that
2041                 # assumes the data is an array.  Otherwise just a scalar
2042                 my $subname = "${package}::${protected}$name";
2043                 if (grep { /^a/i } @_
2044                     or length($access) > length('readable_'))
2045                 {
2046                     no strict "refs";
2047                     *$subname = sub {
2048                         use strict "refs";
2049                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2050                         my $addr = do { no overloading; pack 'J', $_[0]; };
2051                         if (ref $field->{$addr} ne 'ARRAY') {
2052                             my $type = ref $field->{$addr};
2053                             $type = 'scalar' unless $type;
2054                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
2055                             return;
2056                         }
2057                         return scalar @{$field->{$addr}} unless wantarray;
2058
2059                         # Make a copy; had problems with caller modifying the
2060                         # original otherwise
2061                         my @return = @{$field->{$addr}};
2062                         return @return;
2063                     }
2064                 }
2065                 else {
2066
2067                     # Here not an array value, a simpler function.
2068                     no strict "refs";
2069                     *$subname = sub {
2070                         use strict "refs";
2071                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2072                         no overloading;
2073                         return $field->{pack 'J', $_[0]};
2074                     }
2075                 }
2076             }
2077             elsif (substr('settable', 0, length $access) eq $access) {
2078                 my $subname = "${package}::${protected}set_$name";
2079                 no strict "refs";
2080                 *$subname = sub {
2081                     use strict "refs";
2082                     if (main::DEBUG) {
2083                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
2084                         Carp::carp_extra_args(\@_) if @_ > 2;
2085                     }
2086                     # $self is $_[0]; $value is $_[1]
2087                     no overloading;
2088                     $field->{pack 'J', $_[0]} = $_[1];
2089                     return;
2090                 }
2091             }
2092             else {
2093                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
2094             }
2095         }
2096         return;
2097     }
2098 }
2099
2100 package Input_file;
2101
2102 # All input files use this object, which stores various attributes about them,
2103 # and provides for convenient, uniform handling.  The run method wraps the
2104 # processing.  It handles all the bookkeeping of opening, reading, and closing
2105 # the file, returning only significant input lines.
2106 #
2107 # Each object gets a handler which processes the body of the file, and is
2108 # called by run().  All character property files must use the generic,
2109 # default handler, which has code scrubbed to handle things you might not
2110 # expect, including automatic EBCDIC handling.  For files that don't deal with
2111 # mapping code points to a property value, such as test files,
2112 # PropertyAliases, PropValueAliases, and named sequences, you can override the
2113 # handler to be a custom one.  Such a handler should basically be a
2114 # while(next_line()) {...} loop.
2115 #
2116 # You can also set up handlers to
2117 #   0) call during object construction time, after everything else is done
2118 #   1) call before the first line is read, for pre processing
2119 #   2) call to adjust each line of the input before the main handler gets
2120 #      them.  This can be automatically generated, if appropriately simple
2121 #      enough, by specifying a Properties parameter in the constructor.
2122 #   3) call upon EOF before the main handler exits its loop
2123 #   4) call at the end, for post processing
2124 #
2125 # $_ is used to store the input line, and is to be filtered by the
2126 # each_line_handler()s.  So, if the format of the line is not in the desired
2127 # format for the main handler, these are used to do that adjusting.  They can
2128 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2129 # so the $_ output of one is used as the input to the next.  The EOF handler
2130 # is also stackable, but none of the others are, but could easily be changed
2131 # to be so.
2132 #
2133 # Some properties are used by the Perl core but aren't defined until later
2134 # Unicode releases.  The perl interpreter would have problems working when
2135 # compiled with an earlier Unicode version that doesn't have them, so we need
2136 # to define them somehow for those releases.  The 'Early' constructor
2137 # parameter can be used to automatically handle this.  It is essentially
2138 # ignored if the Unicode version being compiled has a data file for this
2139 # property.  Either code to execute or a file to read can be specified.
2140 # Details are at the %early definition.
2141 #
2142 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2143 # which insert the parameters as lines to be processed before the next input
2144 # file line is read.  This allows the EOF handler(s) to flush buffers, for
2145 # example.  The difference between the two routines is that the lines inserted
2146 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2147 # called it from such a handler, you would get infinite recursion without some
2148 # mechanism to prevent that.)  Lines inserted by insert_adjusted_lines() go
2149 # directly to the main handler without any adjustments.  If the
2150 # post-processing handler calls any of these, there will be no effect.  Some
2151 # error checking for these conditions could be added, but it hasn't been done.
2152 #
2153 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2154 # to prevent further processing of the line.  This routine will output the
2155 # message as a warning once, and then keep a count of the lines that have the
2156 # same message, and output that count at the end of the file's processing.
2157 # This keeps the number of messages down to a manageable amount.
2158 #
2159 # get_missings() should be called to retrieve any @missing input lines.
2160 # Messages will be raised if this isn't done if the options aren't to ignore
2161 # missings.
2162
2163 sub trace { return main::trace(@_); }
2164
2165 { # Closure
2166     # Keep track of fields that are to be put into the constructor.
2167     my %constructor_fields;
2168
2169     main::setup_package(Constructor_Fields => \%constructor_fields);
2170
2171     my %file; # Input file name, required
2172     main::set_access('file', \%file, qw{ c r });
2173
2174     my %first_released; # Unicode version file was first released in, required
2175     main::set_access('first_released', \%first_released, qw{ c r });
2176
2177     my %handler;    # Subroutine to process the input file, defaults to
2178                     # 'process_generic_property_file'
2179     main::set_access('handler', \%handler, qw{ c });
2180
2181     my %property;
2182     # name of property this file is for.  defaults to none, meaning not
2183     # applicable, or is otherwise determinable, for example, from each line.
2184     main::set_access('property', \%property, qw{ c r });
2185
2186     my %optional;
2187     # This is either an unsigned number, or a list of property names.  In the
2188     # former case, if it is non-zero, it means the file is optional, so if the
2189     # file is absent, no warning about that is output.  In the latter case, it
2190     # is a list of properties that the file (exclusively) defines.  If the
2191     # file is present, tables for those properties will be produced; if
2192     # absent, none will, even if they are listed elsewhere (namely
2193     # PropertyAliases.txt and PropValueAliases.txt) as being in this release,
2194     # and no warnings will be raised about them not being available.  (And no
2195     # warning about the file itself will be raised.)
2196     main::set_access('optional', \%optional, qw{ c readable_array } );
2197
2198     my %non_skip;
2199     # This is used for debugging, to skip processing of all but a few input
2200     # files.  Add 'non_skip => 1' to the constructor for those files you want
2201     # processed when you set the $debug_skip global.
2202     main::set_access('non_skip', \%non_skip, 'c');
2203
2204     my %skip;
2205     # This is used to skip processing of this input file (semi-) permanently.
2206     # The value should be the reason the file is being skipped.  It is used
2207     # for files that we aren't planning to process anytime soon, but want to
2208     # allow to be in the directory and be checked for their names not
2209     # conflicting with any other files on a DOS 8.3 name filesystem, but to
2210     # not otherwise be processed, and to not raise a warning about not being
2211     # handled.  In the constructor call, any value that evaluates to a numeric
2212     # 0 or undef means don't skip.  Any other value is a string giving the
2213     # reason it is being skipped, and this will appear in generated pod.
2214     # However, an empty string reason will suppress the pod entry.
2215     # Internally, calls that evaluate to numeric 0 are changed into undef to
2216     # distinguish them from an empty string call.
2217     main::set_access('skip', \%skip, 'c', 'r');
2218
2219     my %each_line_handler;
2220     # list of subroutines to look at and filter each non-comment line in the
2221     # file.  defaults to none.  The subroutines are called in order, each is
2222     # to adjust $_ for the next one, and the final one adjusts it for
2223     # 'handler'
2224     main::set_access('each_line_handler', \%each_line_handler, 'c');
2225
2226     my %retain_trailing_comments;
2227     # This is used to not discard the comments that end data lines.  This
2228     # would be used only for files with non-typical syntax, and most code here
2229     # assumes that comments have been stripped, so special handlers would have
2230     # to be written.  It is assumed that the code will use these in
2231     # single-quoted contexts, and so any "'" marks in the comment will be
2232     # prefixed by a backslash.
2233     main::set_access('retain_trailing_comments', \%retain_trailing_comments, 'c');
2234
2235     my %properties; # Optional ordered list of the properties that occur in each
2236     # meaningful line of the input file.  If present, an appropriate
2237     # each_line_handler() is automatically generated and pushed onto the stack
2238     # of such handlers.  This is useful when a file contains multiple
2239     # properties per line, but no other special considerations are necessary.
2240     # The special value "<ignored>" means to discard the corresponding input
2241     # field.
2242     # Any @missing lines in the file should also match this syntax; no such
2243     # files exist as of 6.3.  But if it happens in a future release, the code
2244     # could be expanded to properly parse them.
2245     main::set_access('properties', \%properties, qw{ c r });
2246
2247     my %has_missings_defaults;
2248     # ? Are there lines in the file giving default values for code points
2249     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2250     # the norm, but IGNORED means it has such lines, but the handler doesn't
2251     # use them.  Having these three states allows us to catch changes to the
2252     # UCD that this program should track.  XXX This could be expanded to
2253     # specify the syntax for such lines, like %properties above.
2254     main::set_access('has_missings_defaults',
2255                                         \%has_missings_defaults, qw{ c r });
2256
2257     my %construction_time_handler;
2258     # Subroutine to call at the end of the new method.  If undef, no such
2259     # handler is called.
2260     main::set_access('construction_time_handler',
2261                                         \%construction_time_handler, qw{ c });
2262
2263     my %pre_handler;
2264     # Subroutine to call before doing anything else in the file.  If undef, no
2265     # such handler is called.
2266     main::set_access('pre_handler', \%pre_handler, qw{ c });
2267
2268     my %eof_handler;
2269     # Subroutines to call upon getting an EOF on the input file, but before
2270     # that is returned to the main handler.  This is to allow buffers to be
2271     # flushed.  The handler is expected to call insert_lines() or
2272     # insert_adjusted() with the buffered material
2273     main::set_access('eof_handler', \%eof_handler, qw{ c });
2274
2275     my %post_handler;
2276     # Subroutine to call after all the lines of the file are read in and
2277     # processed.  If undef, no such handler is called.  Note that this cannot
2278     # add lines to be processed; instead use eof_handler
2279     main::set_access('post_handler', \%post_handler, qw{ c });
2280
2281     my %progress_message;
2282     # Message to print to display progress in lieu of the standard one
2283     main::set_access('progress_message', \%progress_message, qw{ c });
2284
2285     my %handle;
2286     # cache open file handle, internal.  Is undef if file hasn't been
2287     # processed at all, empty if has;
2288     main::set_access('handle', \%handle);
2289
2290     my %added_lines;
2291     # cache of lines added virtually to the file, internal
2292     main::set_access('added_lines', \%added_lines);
2293
2294     my %remapped_lines;
2295     # cache of lines added virtually to the file, internal
2296     main::set_access('remapped_lines', \%remapped_lines);
2297
2298     my %errors;
2299     # cache of errors found, internal
2300     main::set_access('errors', \%errors);
2301
2302     my %missings;
2303     # storage of '@missing' defaults lines
2304     main::set_access('missings', \%missings);
2305
2306     my %early;
2307     # Used for properties that must be defined (for Perl's purposes) on
2308     # versions of Unicode earlier than Unicode itself defines them.  The
2309     # parameter is an array (it would be better to be a hash, but not worth
2310     # bothering about due to its rare use).
2311     #
2312     # The first element is either a code reference to call when in a release
2313     # earlier than the Unicode file is available in, or it is an alternate
2314     # file to use instead of the non-existent one.  This file must have been
2315     # plunked down in the same directory as mktables.  Should you be compiling
2316     # on a release that needs such a file, mktables will abort the
2317     # compilation, and tell you where to get the necessary file(s), and what
2318     # name(s) to use to store them as.
2319     # In the case of specifying an alternate file, the array must contain two
2320     # further elements:
2321     #
2322     # [1] is the name of the property that will be generated by this file.
2323     # The class automatically takes the input file and excludes any code
2324     # points in it that were not assigned in the Unicode version being
2325     # compiled.  It then uses this result to define the property in the given
2326     # version.  Since the property doesn't actually exist in the Unicode
2327     # version being compiled, this should be a name accessible only by core
2328     # perl.  If it is the same name as the regular property, the constructor
2329     # will mark the output table as a $PLACEHOLDER so that it doesn't actually
2330     # get output, and so will be unusable by non-core code.  Otherwise it gets
2331     # marked as $INTERNAL_ONLY.
2332     #
2333     # [2] is a property value to assign (only when compiling Unicode 1.1.5) to
2334     # the Hangul syllables in that release (which were ripped out in version
2335     # 2) for the given property .  (Hence it is ignored except when compiling
2336     # version 1.  You only get one value that applies to all of them, which
2337     # may not be the actual reality, but probably nobody cares anyway for
2338     # these obsolete characters.)
2339     #
2340     # [3] if present is the default value for the property to assign for code
2341     # points not given in the input.  If not present, the default from the
2342     # normal property is used
2343     #
2344     # [-1] If there is an extra final element that is the string 'ONLY_EARLY'.
2345     # it means to not add the name in [1] as an alias to the property name
2346     # used for these.  Normally, when compiling Unicode versions that don't
2347     # invoke the early handling, the name is added as a synonym.
2348     #
2349     # Not all files can be handled in the above way, and so the code ref
2350     # alternative is available.  It can do whatever it needs to.  The other
2351     # array elements are optional in this case, and the code is free to use or
2352     # ignore them if they are present.
2353     #
2354     # Internally, the constructor unshifts a 0 or 1 onto this array to
2355     # indicate if an early alternative is actually being used or not.  This
2356     # makes for easier testing later on.
2357     main::set_access('early', \%early, 'c');
2358
2359     my %only_early;
2360     main::set_access('only_early', \%only_early, 'c');
2361
2362     my %required_even_in_debug_skip;
2363     # debug_skip is used to speed up compilation during debugging by skipping
2364     # processing files that are not needed for the task at hand.  However,
2365     # some files pretty much can never be skipped, and this is used to specify
2366     # that this is one of them.  In order to skip this file, the call to the
2367     # constructor must be edited to comment out this parameter.
2368     main::set_access('required_even_in_debug_skip',
2369                      \%required_even_in_debug_skip, 'c');
2370
2371     my %withdrawn;
2372     # Some files get removed from the Unicode DB.  This is a version object
2373     # giving the first release without this file.
2374     main::set_access('withdrawn', \%withdrawn, 'c');
2375
2376     my %in_this_release;
2377     # Calculated value from %first_released and %withdrawn.  Are we compiling
2378     # a Unicode release which includes this file?
2379     main::set_access('in_this_release', \%in_this_release);
2380
2381     sub _next_line;
2382     sub _next_line_with_remapped_range;
2383
2384     sub new {
2385         my $class = shift;
2386
2387         my $self = bless \do{ my $anonymous_scalar }, $class;
2388         my $addr = do { no overloading; pack 'J', $self; };
2389
2390         # Set defaults
2391         $handler{$addr} = \&main::process_generic_property_file;
2392         $retain_trailing_comments{$addr} = 0;
2393         $non_skip{$addr} = 0;
2394         $skip{$addr} = undef;
2395         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2396         $handle{$addr} = undef;
2397         $added_lines{$addr} = [ ];
2398         $remapped_lines{$addr} = [ ];
2399         $each_line_handler{$addr} = [ ];
2400         $eof_handler{$addr} = [ ];
2401         $errors{$addr} = { };
2402         $missings{$addr} = [ ];
2403         $early{$addr} = [ ];
2404         $optional{$addr} = [ ];
2405
2406         # Two positional parameters.
2407         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2408         $file{$addr} = main::internal_file_to_platform(shift);
2409         $first_released{$addr} = shift;
2410
2411         # The rest of the arguments are key => value pairs
2412         # %constructor_fields has been set up earlier to list all possible
2413         # ones.  Either set or push, depending on how the default has been set
2414         # up just above.
2415         my %args = @_;
2416         foreach my $key (keys %args) {
2417             my $argument = $args{$key};
2418
2419             # Note that the fields are the lower case of the constructor keys
2420             my $hash = $constructor_fields{lc $key};
2421             if (! defined $hash) {
2422                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2423                 next;
2424             }
2425             if (ref $hash->{$addr} eq 'ARRAY') {
2426                 if (ref $argument eq 'ARRAY') {
2427                     foreach my $argument (@{$argument}) {
2428                         next if ! defined $argument;
2429                         push @{$hash->{$addr}}, $argument;
2430                     }
2431                 }
2432                 else {
2433                     push @{$hash->{$addr}}, $argument if defined $argument;
2434                 }
2435             }
2436             else {
2437                 $hash->{$addr} = $argument;
2438             }
2439             delete $args{$key};
2440         };
2441
2442         $non_skip{$addr} = 1 if $required_even_in_debug_skip{$addr};
2443
2444         # Convert 0 (meaning don't skip) to undef
2445         undef $skip{$addr} unless $skip{$addr};
2446
2447         # Handle the case where this file is optional
2448         my $pod_message_for_non_existent_optional = "";
2449         if ($optional{$addr}->@*) {
2450
2451             # First element is the pod message
2452             $pod_message_for_non_existent_optional
2453                                                 = shift $optional{$addr}->@*;
2454             # Convert a 0 'Optional' argument to an empty list to make later
2455             # code more concise.
2456             if (   $optional{$addr}->@*
2457                 && $optional{$addr}->@* == 1
2458                 && $optional{$addr}[0] ne ""
2459                 && $optional{$addr}[0] !~ /\D/
2460                 && $optional{$addr}[0] == 0)
2461             {
2462                 $optional{$addr} = [ ];
2463             }
2464             else {  # But if the only element doesn't evaluate to 0, make sure
2465                     # that this file is indeed considered optional below.
2466                 unshift $optional{$addr}->@*, 1;
2467             }
2468         }
2469
2470         my $progress;
2471         my $function_instead_of_file = 0;
2472
2473         if ($early{$addr}->@* && $early{$addr}[-1] eq 'ONLY_EARLY') {
2474             $only_early{$addr} = 1;
2475             pop $early{$addr}->@*;
2476         }
2477
2478         # If we are compiling a Unicode release earlier than the file became
2479         # available, the constructor may have supplied a substitute
2480         if ($first_released{$addr} gt $v_version && $early{$addr}->@*) {
2481
2482             # Yes, we have a substitute, that we will use; mark it so
2483             unshift $early{$addr}->@*, 1;
2484
2485             # See the definition of %early for what the array elements mean.
2486             # Note that we have just unshifted onto the array, so the numbers
2487             # below are +1 of those in the %early description.
2488             # If we have a property this defines, create a table and default
2489             # map for it now (at essentially compile time), so that it will be
2490             # available for the whole of run time.  (We will want to add this
2491             # name as an alias when we are using the official property name;
2492             # but this must be deferred until run(), because at construction
2493             # time the official names have yet to be defined.)
2494             if ($early{$addr}[2]) {
2495                 my $fate = ($property{$addr}
2496                             && $property{$addr} eq $early{$addr}[2])
2497                           ? $PLACEHOLDER
2498                           : $INTERNAL_ONLY;
2499                 my $prop_object = Property->new($early{$addr}[2],
2500                                                 Fate => $fate,
2501                                                 Perl_Extension => 1,
2502                                                 );
2503
2504                 # If not specified by the constructor, use the default mapping
2505                 # for the regular property for this substitute one.
2506                 if ($early{$addr}[4]) {
2507                     $prop_object->set_default_map($early{$addr}[4]);
2508                 }
2509                 elsif (    defined $property{$addr}
2510                        &&  defined $default_mapping{$property{$addr}})
2511                 {
2512                     $prop_object
2513                         ->set_default_map($default_mapping{$property{$addr}});
2514                 }
2515             }
2516
2517             if (ref $early{$addr}[1] eq 'CODE') {
2518                 $function_instead_of_file = 1;
2519
2520                 # If the first element of the array is a code ref, the others
2521                 # are optional.
2522                 $handler{$addr} = $early{$addr}[1];
2523                 $property{$addr} = $early{$addr}[2]
2524                                                 if defined $early{$addr}[2];
2525                 $progress = "substitute $file{$addr}";
2526
2527                 undef $file{$addr};
2528             }
2529             else {  # Specifying a substitute file
2530
2531                 if (! main::file_exists($early{$addr}[1])) {
2532
2533                     # If we don't see the substitute file, generate an error
2534                     # message giving the needed things, and add it to the list
2535                     # of such to output before actual processing happens
2536                     # (hence the user finds out all of them in one run).
2537                     # Instead of creating a general method for NameAliases,
2538                     # hard-code it here, as there is unlikely to ever be a
2539                     # second one which needs special handling.
2540                     my $string_version = ($file{$addr} eq "NameAliases.txt")
2541                                     ? 'at least 6.1 (the later, the better)'
2542                                     : sprintf "%vd", $first_released{$addr};
2543                     push @missing_early_files, <<END;
2544 '$file{$addr}' version $string_version should be copied to '$early{$addr}[1]'.
2545 END
2546                     ;
2547                     return;
2548                 }
2549                 $progress = $early{$addr}[1];
2550                 $progress .= ", substituting for $file{$addr}" if $file{$addr};
2551                 $file{$addr} = $early{$addr}[1];
2552                 $property{$addr} = $early{$addr}[2];
2553
2554                 # Ignore code points not in the version being compiled
2555                 push $each_line_handler{$addr}->@*, \&_exclude_unassigned;
2556
2557                 if (   $v_version lt v2.0        # Hanguls in this release ...
2558                     && defined $early{$addr}[3]) # ... need special treatment
2559                 {
2560                     push $eof_handler{$addr}->@*, \&_fixup_obsolete_hanguls;
2561                 }
2562             }
2563
2564             # And this substitute is valid for all releases.
2565             $first_released{$addr} = v0;
2566         }
2567         else {  # Normal behavior
2568             $progress = $file{$addr};
2569             unshift $early{$addr}->@*, 0; # No substitute
2570         }
2571
2572         my $file = $file{$addr};
2573         $progress_message{$addr} = "Processing $progress"
2574                                             unless $progress_message{$addr};
2575
2576         # A file should be there if it is within the window of versions for
2577         # which Unicode supplies it
2578         if ($withdrawn{$addr} && $withdrawn{$addr} le $v_version) {
2579             $in_this_release{$addr} = 0;
2580             $skip{$addr} = "";
2581         }
2582         else {
2583             $in_this_release{$addr} = $first_released{$addr} le $v_version;
2584
2585             # Check that the file for this object (possibly using a substitute
2586             # for early releases) exists or we have a function alternative
2587             if (   ! $function_instead_of_file
2588                 && ! main::file_exists($file))
2589             {
2590                 # Here there is nothing available for this release.  This is
2591                 # fine if we aren't expecting anything in this release.
2592                 if (! $in_this_release{$addr}) {
2593                     $skip{$addr} = "";  # Don't remark since we expected
2594                                         # nothing and got nothing
2595                 }
2596                 elsif ($optional{$addr}->@*) {
2597
2598                     # Here the file is optional in this release; Use the
2599                     # passed in text to document this case in the pod.
2600                     $skip{$addr} = $pod_message_for_non_existent_optional;
2601                 }
2602                 elsif (   $in_this_release{$addr}
2603                        && ! defined $skip{$addr}
2604                        && defined $file)
2605                 { # Doesn't exist but should.
2606                     $skip{$addr} = "'$file' not found.  Possibly Big problems";
2607                     Carp::my_carp($skip{$addr});
2608                 }
2609             }
2610             elsif ($debug_skip && ! defined $skip{$addr} && ! $non_skip{$addr})
2611             {
2612
2613                 # The file exists; if not skipped for another reason, and we are
2614                 # skipping most everything during debugging builds, use that as
2615                 # the skip reason.
2616                 $skip{$addr} = '$debug_skip is on'
2617             }
2618         }
2619
2620         if (   ! $debug_skip
2621             && $non_skip{$addr}
2622             && ! $required_even_in_debug_skip{$addr}
2623             && $verbosity)
2624         {
2625             print "Warning: " . __PACKAGE__ . " constructor for $file has useless 'non_skip' in it\n";
2626         }
2627
2628         # Here, we have figured out if we will be skipping this file or not.
2629         # If so, we add any single property it defines to any passed in
2630         # optional property list.  These will be dealt with at run time.
2631         if (defined $skip{$addr}) {
2632             if ($property{$addr}) {
2633                 push $optional{$addr}->@*, $property{$addr};
2634             }
2635         } # Otherwise, are going to process the file.
2636         elsif ($property{$addr}) {
2637
2638             # If the file has a property defined in the constructor for it, it
2639             # means that the property is not listed in the file's entries.  So
2640             # add a handler (to the list of line handlers) to insert the
2641             # property name into the lines, to provide a uniform interface to
2642             # the final processing subroutine.
2643             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2644         }
2645         elsif ($properties{$addr}) {
2646
2647             # Similarly, there may be more than one property represented on
2648             # each line, with no clue but the constructor input what those
2649             # might be.  Add a handler for each line in the input so that it
2650             # creates a separate input line for each property in those input
2651             # lines, thus making them suitable to handle generically.
2652
2653             push @{$each_line_handler{$addr}},
2654                  sub {
2655                     my $file = shift;
2656                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2657
2658                     my @fields = split /\s*;\s*/, $_, -1;
2659
2660                     if (@fields - 1 > @{$properties{$addr}}) {
2661                         $file->carp_bad_line('Extra fields');
2662                         $_ = "";
2663                         return;
2664                     }
2665                     my $range = shift @fields;  # 0th element is always the
2666                                                 # range
2667
2668                     # The next fields in the input line correspond
2669                     # respectively to the stored properties.
2670                     for my $i (0 ..  @{$properties{$addr}} - 1) {
2671                         my $property_name = $properties{$addr}[$i];
2672                         next if $property_name eq '<ignored>';
2673                         $file->insert_adjusted_lines(
2674                               "$range; $property_name; $fields[$i]");
2675                     }
2676                     $_ = "";
2677
2678                     return;
2679                 };
2680         }
2681
2682         {   # On non-ascii platforms, we use a special pre-handler
2683             no strict;
2684             no warnings 'once';
2685             *next_line = (main::NON_ASCII_PLATFORM)
2686                          ? *_next_line_with_remapped_range
2687                          : *_next_line;
2688         }
2689
2690         &{$construction_time_handler{$addr}}($self)
2691                                         if $construction_time_handler{$addr};
2692
2693         return $self;
2694     }
2695
2696
2697     use overload
2698         fallback => 0,
2699         qw("") => "_operator_stringify",
2700         "." => \&main::_operator_dot,
2701         ".=" => \&main::_operator_dot_equal,
2702     ;
2703
2704     sub _operator_stringify {
2705         my $self = shift;
2706
2707         return __PACKAGE__ . " object for " . $self->file;
2708     }
2709
2710     sub run {
2711         # Process the input object $self.  This opens and closes the file and
2712         # calls all the handlers for it.  Currently,  this can only be called
2713         # once per file, as it destroy's the EOF handlers
2714
2715         # flag to make sure extracted files are processed early
2716         state $seen_non_extracted = 0;
2717
2718         my $self = shift;
2719         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2720
2721         my $addr = do { no overloading; pack 'J', $self; };
2722
2723         my $file = $file{$addr};
2724
2725         if (! $file) {
2726             $handle{$addr} = 'pretend_is_open';
2727         }
2728         else {
2729             if ($seen_non_extracted) {
2730                 if ($file =~ /$EXTRACTED/i) # Some platforms may change the
2731                                             # case of the file's name
2732                 {
2733                     Carp::my_carp_bug(main::join_lines(<<END
2734 $file should be processed just after the 'Prop...Alias' files, and before
2735 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2736 have subtle problems
2737 END
2738                     ));
2739                 }
2740             }
2741             elsif ($EXTRACTED_DIR
2742
2743                     # We only do this check for generic property files
2744                     && $handler{$addr} == \&main::process_generic_property_file
2745
2746                     && $file !~ /$EXTRACTED/i)
2747             {
2748                 # We don't set this (by the 'if' above) if we have no
2749                 # extracted directory, so if running on an early version,
2750                 # this test won't work.  Not worth worrying about.
2751                 $seen_non_extracted = 1;
2752             }
2753
2754             # Mark the file as having being processed, and warn if it
2755             # isn't a file we are expecting.  As we process the files,
2756             # they are deleted from the hash, so any that remain at the
2757             # end of the program are files that we didn't process.
2758             my $fkey = File::Spec->rel2abs($file);
2759             my $exists = delete $potential_files{lc($fkey)};
2760
2761             Carp::my_carp("Was not expecting '$file'.")
2762                                     if $exists && ! $in_this_release{$addr};
2763
2764             # If there is special handling for compiling Unicode releases
2765             # earlier than the first one in which Unicode defines this
2766             # property ...
2767             if ($early{$addr}->@* > 1) {
2768
2769                 # Mark as processed any substitute file that would be used in
2770                 # such a release
2771                 $fkey = File::Spec->rel2abs($early{$addr}[1]);
2772                 delete $potential_files{lc($fkey)};
2773
2774                 # As commented in the constructor code, when using the
2775                 # official property, we still have to allow the publicly
2776                 # inaccessible early name so that the core code which uses it
2777                 # will work regardless.
2778                 if (   ! $only_early{$addr}
2779                     && ! $early{$addr}[0]
2780                     && $early{$addr}->@* > 2)
2781                 {
2782                     my $early_property_name = $early{$addr}[2];
2783                     if ($property{$addr} ne $early_property_name) {
2784                         main::property_ref($property{$addr})
2785                                             ->add_alias($early_property_name);
2786                     }
2787                 }
2788             }
2789
2790             # We may be skipping this file ...
2791             if (defined $skip{$addr}) {
2792
2793                 # If the file isn't supposed to be in this release, there is
2794                 # nothing to do
2795                 if ($in_this_release{$addr}) {
2796
2797                     # But otherwise, we may print a message
2798                     if ($debug_skip) {
2799                         print STDERR "Skipping input file '$file'",
2800                                      " because '$skip{$addr}'\n";
2801                     }
2802
2803                     # And add it to the list of skipped files, which is later
2804                     # used to make the pod
2805                     $skipped_files{$file} = $skip{$addr};
2806
2807                     # The 'optional' list contains properties that are also to
2808                     # be skipped along with the file.  (There may also be
2809                     # digits which are just placeholders to make sure it isn't
2810                     # an empty list
2811                     foreach my $property ($optional{$addr}->@*) {
2812                         next unless $property =~ /\D/;
2813                         my $prop_object = main::property_ref($property);
2814                         next unless defined $prop_object;
2815                         $prop_object->set_fate($SUPPRESSED, $skip{$addr});
2816                     }
2817                 }
2818
2819                 return;
2820             }
2821
2822             # Here, we are going to process the file.  Open it, converting the
2823             # slashes used in this program into the proper form for the OS
2824             my $file_handle;
2825             if (not open $file_handle, "<", $file) {
2826                 Carp::my_carp("Can't open $file.  Skipping: $!");
2827                 return;
2828             }
2829             $handle{$addr} = $file_handle; # Cache the open file handle
2830
2831             # If possible, make sure that the file is the correct version.
2832             # (This data isn't available on early Unicode releases or in
2833             # UnicodeData.txt.)  We don't do this check if we are using a
2834             # substitute file instead of the official one (though the code
2835             # could be extended to do so).
2836             if ($in_this_release{$addr}
2837                 && ! $early{$addr}[0]
2838                 && lc($file) ne 'unicodedata.txt')
2839             {
2840                 if ($file !~ /^Unihan/i) {
2841
2842                     # The non-Unihan files started getting version numbers in
2843                     # 3.2, but some files in 4.0 are unchanged from 3.2, and
2844                     # marked as 3.2.  4.0.1 is the first version where there
2845                     # are no files marked as being from less than 4.0, though
2846                     # some are marked as 4.0.  In versions after that, the
2847                     # numbers are correct.
2848                     if ($v_version ge v4.0.1) {
2849                         $_ = <$file_handle>;    # The version number is in the
2850                                                 # very first line
2851                         if ($_ !~ / - $string_version \. /x) {
2852                             chomp;
2853                             $_ =~ s/^#\s*//;
2854
2855                             # 4.0.1 had some valid files that weren't updated.
2856                             if (! ($v_version eq v4.0.1 && $_ =~ /4\.0\.0/)) {
2857                                 die Carp::my_carp("File '$file' is version "
2858                                                 . "'$_'.  It should be "
2859                                                 . "version $string_version");
2860                             }
2861                         }
2862                     }
2863                 }
2864                 elsif ($v_version ge v6.0.0) { # Unihan
2865
2866                     # Unihan files didn't get accurate version numbers until
2867                     # 6.0.  The version is somewhere in the first comment
2868                     # block
2869                     while (<$file_handle>) {
2870                         if ($_ !~ /^#/) {
2871                             Carp::my_carp_bug("Could not find the expected "
2872                                             . "version info in file '$file'");
2873                             last;
2874                         }
2875                         chomp;
2876                         $_ =~ s/^#\s*//;
2877                         next if $_ !~ / version: /x;
2878                         last if $_ =~ /$string_version/;
2879                         die Carp::my_carp("File '$file' is version "
2880                                         . "'$_'.  It should be "
2881                                         . "version $string_version");
2882                     }
2883                 }
2884             }
2885         }
2886
2887         print "$progress_message{$addr}\n" if $verbosity >= $PROGRESS;
2888
2889         # Call any special handler for before the file.
2890         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2891
2892         # Then the main handler
2893         &{$handler{$addr}}($self);
2894
2895         # Then any special post-file handler.
2896         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2897
2898         # If any errors have been accumulated, output the counts (as the first
2899         # error message in each class was output when it was encountered).
2900         if ($errors{$addr}) {
2901             my $total = 0;
2902             my $types = 0;
2903             foreach my $error (keys %{$errors{$addr}}) {
2904                 $total += $errors{$addr}->{$error};
2905                 delete $errors{$addr}->{$error};
2906                 $types++;
2907             }
2908             if ($total > 1) {
2909                 my $message
2910                         = "A total of $total lines had errors in $file.  ";
2911
2912                 $message .= ($types == 1)
2913                             ? '(Only the first one was displayed.)'
2914                             : '(Only the first of each type was displayed.)';
2915                 Carp::my_carp($message);
2916             }
2917         }
2918
2919         if (@{$missings{$addr}}) {
2920             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2921         }
2922
2923         # If a real file handle, close it.
2924         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2925                                                         ref $handle{$addr};
2926         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2927                                # the file, as opposed to undef
2928         return;
2929     }
2930
2931     sub _next_line {
2932         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2933         # if such a line exists.  'logical' means that any lines that have
2934         # been added via insert_lines() will be returned in $_ before the file
2935         # is read again.
2936
2937         my $self = shift;
2938         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2939
2940         my $addr = do { no overloading; pack 'J', $self; };
2941
2942         # Here the file is open (or if the handle is not a ref, is an open
2943         # 'virtual' file).  Get the next line; any inserted lines get priority
2944         # over the file itself.
2945         my $adjusted;
2946
2947         LINE:
2948         while (1) { # Loop until find non-comment, non-empty line
2949             #local $to_trace = 1 if main::DEBUG;
2950             my $inserted_ref = shift @{$added_lines{$addr}};
2951             if (defined $inserted_ref) {
2952                 ($adjusted, $_) = @{$inserted_ref};
2953                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2954                 return 1 if $adjusted;
2955             }
2956             else {
2957                 last if ! ref $handle{$addr}; # Don't read unless is real file
2958                 last if ! defined ($_ = readline $handle{$addr});
2959             }
2960             chomp;
2961             trace $_ if main::DEBUG && $to_trace;
2962
2963             # See if this line is the comment line that defines what property
2964             # value that code points that are not listed in the file should
2965             # have.  The format or existence of these lines is not guaranteed
2966             # by Unicode since they are comments, but the documentation says
2967             # that this was added for machine-readability, so probably won't
2968             # change.  This works starting in Unicode Version 5.0.  They look
2969             # like:
2970             #
2971             # @missing: 0000..10FFFF; Not_Reordered
2972             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2973             # @missing: 0000..10FFFF; ; NaN
2974             #
2975             # Save the line for a later get_missings() call.
2976             if (/$missing_defaults_prefix/) {
2977                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2978                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2979                 }
2980                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2981                     my @defaults = split /\s* ; \s*/x, $_;
2982
2983                     # The first field is the @missing, which ends in a
2984                     # semi-colon, so can safely shift.
2985                     shift @defaults;
2986
2987                     # Some of these lines may have empty field placeholders
2988                     # which get in the way.  An example is:
2989                     # @missing: 0000..10FFFF; ; NaN
2990                     # Remove them.  Process starting from the top so the
2991                     # splice doesn't affect things still to be looked at.
2992                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2993                         next if $defaults[$i] ne "";
2994                         splice @defaults, $i, 1;
2995                     }
2996
2997                     # What's left should be just the property (maybe) and the
2998                     # default.  Having only one element means it doesn't have
2999                     # the property.
3000                     my $default;
3001                     my $property;
3002                     if (@defaults >= 1) {
3003                         if (@defaults == 1) {
3004                             $default = $defaults[0];
3005                         }
3006                         else {
3007                             $property = $defaults[0];
3008                             $default = $defaults[1];
3009                         }
3010                     }
3011
3012                     if (@defaults < 1
3013                         || @defaults > 2
3014                         || ($default =~ /^</
3015                             && $default !~ /^<code *point>$/i
3016                             && $default !~ /^<none>$/i
3017                             && $default !~ /^<script>$/i))
3018                     {
3019                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
3020                     }
3021                     else {
3022
3023                         # If the property is missing from the line, it should
3024                         # be the one for the whole file
3025                         $property = $property{$addr} if ! defined $property;
3026
3027                         # Change <none> to the null string, which is what it
3028                         # really means.  If the default is the code point
3029                         # itself, set it to <code point>, which is what
3030                         # Unicode uses (but sometimes they've forgotten the
3031                         # space)
3032                         if ($default =~ /^<none>$/i) {
3033                             $default = "";
3034                         }
3035                         elsif ($default =~ /^<code *point>$/i) {
3036                             $default = $CODE_POINT;
3037                         }
3038                         elsif ($default =~ /^<script>$/i) {
3039
3040                             # Special case this one.  Currently is from
3041                             # ScriptExtensions.txt, and means for all unlisted
3042                             # code points, use their Script property values.
3043                             # For the code points not listed in that file, the
3044                             # default value is 'Unknown'.
3045                             $default = "Unknown";
3046                         }
3047
3048                         # Store them as a sub-arrays with both components.
3049                         push @{$missings{$addr}}, [ $default, $property ];
3050                     }
3051                 }
3052
3053                 # There is nothing for the caller to process on this comment
3054                 # line.
3055                 next;
3056             }
3057
3058             # Unless to keep, remove comments.  If to keep, ignore
3059             # comment-only lines
3060             if ($retain_trailing_comments{$addr}) {
3061                 next if / ^ \s* \# /x;
3062
3063                 # But escape any single quotes (done in both the comment and
3064                 # non-comment portion; this could be a bug someday, but not
3065                 # likely)
3066                 s/'/\\'/g;
3067             }
3068             else {
3069                 s/#.*//;
3070             }
3071
3072             # Remove trailing space, and skip this line if the result is empty
3073             s/\s+$//;
3074             next if /^$/;
3075
3076             # Call any handlers for this line, and skip further processing of
3077             # the line if the handler sets the line to null.
3078             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
3079                 &{$sub_ref}($self);
3080                 next LINE if /^$/;
3081             }
3082
3083             # Here the line is ok.  return success.
3084             return 1;
3085         } # End of looping through lines.
3086
3087         # If there are EOF handlers, call each (only once) and if it generates
3088         # more lines to process go back in the loop to handle them.
3089         while ($eof_handler{$addr}->@*) {
3090             &{$eof_handler{$addr}[0]}($self);
3091             shift $eof_handler{$addr}->@*;   # Currently only get one shot at it.
3092             goto LINE if $added_lines{$addr};
3093         }
3094
3095         # Return failure -- no more lines.
3096         return 0;
3097
3098     }
3099
3100     sub _next_line_with_remapped_range {
3101         my $self = shift;
3102         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3103
3104         # like _next_line(), but for use on non-ASCII platforms.  It sets $_
3105         # to be the next logical input line, if any.  Returns non-zero if such
3106         # a line exists.  'logical' means that any lines that have been added
3107         # via insert_lines() will be returned in $_ before the file is read
3108         # again.
3109         #
3110         # The difference from _next_line() is that this remaps the Unicode
3111         # code points in the input to those of the native platform.  Each
3112         # input line contains a single code point, or a single contiguous
3113         # range of them  This routine splits each range into its individual
3114         # code points and caches them.  It returns the cached values,
3115         # translated into their native equivalents, one at a time, for each
3116         # call, before reading the next line.  Since native values can only be
3117         # a single byte wide, no translation is needed for code points above
3118         # 0xFF, and ranges that are entirely above that number are not split.
3119         # If an input line contains the range 254-1000, it would be split into
3120         # three elements: 254, 255, and 256-1000.  (The downstream table
3121         # insertion code will sort and coalesce the individual code points
3122         # into appropriate ranges.)
3123
3124         my $addr = do { no overloading; pack 'J', $self; };
3125
3126         while (1) {
3127
3128             # Look in cache before reading the next line.  Return any cached
3129             # value, translated
3130             my $inserted = shift @{$remapped_lines{$addr}};
3131             if (defined $inserted) {
3132                 trace $inserted if main::DEBUG && $to_trace;
3133                 $_ = $inserted =~ s/^ ( \d+ ) /sprintf("%04X", utf8::unicode_to_native($1))/xer;
3134                 trace $_ if main::DEBUG && $to_trace;
3135                 return 1;
3136             }
3137
3138             # Get the next line.
3139             return 0 unless _next_line($self);
3140
3141             # If there is a special handler for it, return the line,
3142             # untranslated.  This should happen only for files that are
3143             # special, not being code-point related, such as property names.
3144             return 1 if $handler{$addr}
3145                                     != \&main::process_generic_property_file;
3146
3147             my ($range, $property_name, $map, @remainder)
3148                 = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
3149
3150             if (@remainder
3151                 || ! defined $property_name
3152                 || $range !~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
3153             {
3154                 Carp::my_carp_bug("Unrecognized input line '$_'.  Ignored");
3155             }
3156
3157             my $low = hex $1;
3158             my $high = (defined $2) ? hex $2 : $low;
3159
3160             # If the input maps the range to another code point, remap the
3161             # target if it is between 0 and 255.
3162             my $tail;
3163             if (defined $map) {
3164                 $map =~ s/\b 00 ( [0-9A-F]{2} ) \b/sprintf("%04X", utf8::unicode_to_native(hex $1))/gxe;
3165                 $tail = "$property_name; $map";
3166                 $_ = "$range; $tail";
3167             }
3168             else {
3169                 $tail = $property_name;
3170             }
3171
3172             # If entire range is above 255, just return it, unchanged (except
3173             # any mapped-to code point, already changed above)
3174             return 1 if $low > 255;
3175
3176             # Cache an entry for every code point < 255.  For those in the
3177             # range above 255, return a dummy entry for just that portion of
3178             # the range.  Note that this will be out-of-order, but that is not
3179             # a problem.
3180             foreach my $code_point ($low .. $high) {
3181                 if ($code_point > 255) {
3182                     $_ = sprintf "%04X..%04X; $tail", $code_point, $high;
3183                     return 1;
3184                 }
3185                 push @{$remapped_lines{$addr}}, "$code_point; $tail";
3186             }
3187         } # End of looping through lines.
3188
3189         # NOTREACHED
3190     }
3191
3192 #   Not currently used, not fully tested.
3193 #    sub peek {
3194 #        # Non-destructive lookahead one non-adjusted, non-comment, non-blank
3195 #        # record.  Not callable from an each_line_handler(), nor does it call
3196 #        # an each_line_handler() on the line.
3197 #
3198 #        my $self = shift;
3199 #        my $addr = do { no overloading; pack 'J', $self; };
3200 #
3201 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
3202 #            my ($adjusted, $line) = @{$inserted_ref};
3203 #            next if $adjusted;
3204 #
3205 #            # Remove comments and trailing space, and return a non-empty
3206 #            # resulting line
3207 #            $line =~ s/#.*//;
3208 #            $line =~ s/\s+$//;
3209 #            return $line if $line ne "";
3210 #        }
3211 #
3212 #        return if ! ref $handle{$addr}; # Don't read unless is real file
3213 #        while (1) { # Loop until find non-comment, non-empty line
3214 #            local $to_trace = 1 if main::DEBUG;
3215 #            trace $_ if main::DEBUG && $to_trace;
3216 #            return if ! defined (my $line = readline $handle{$addr});
3217 #            chomp $line;
3218 #            push @{$added_lines{$addr}}, [ 0, $line ];
3219 #
3220 #            $line =~ s/#.*//;
3221 #            $line =~ s/\s+$//;
3222 #            return $line if $line ne "";
3223 #        }
3224 #
3225 #        return;
3226 #    }
3227
3228
3229     sub insert_lines {
3230         # Lines can be inserted so that it looks like they were in the input
3231         # file at the place it was when this routine is called.  See also
3232         # insert_adjusted_lines().  Lines inserted via this routine go through
3233         # any each_line_handler()
3234
3235         my $self = shift;
3236
3237         # Each inserted line is an array, with the first element being 0 to
3238         # indicate that this line hasn't been adjusted, and needs to be
3239         # processed.
3240         no overloading;
3241         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
3242         return;
3243     }
3244
3245     sub insert_adjusted_lines {
3246         # Lines can be inserted so that it looks like they were in the input
3247         # file at the place it was when this routine is called.  See also
3248         # insert_lines().  Lines inserted via this routine are already fully
3249         # adjusted, ready to be processed; each_line_handler()s handlers will
3250         # not be called.  This means this is not a completely general
3251         # facility, as only the last each_line_handler on the stack should
3252         # call this.  It could be made more general, by passing to each of the
3253         # line_handlers their position on the stack, which they would pass on
3254         # to this routine, and that would replace the boolean first element in
3255         # the anonymous array pushed here, so that the next_line routine could
3256         # use that to call only those handlers whose index is after it on the
3257         # stack.  But this is overkill for what is needed now.
3258
3259         my $self = shift;
3260         trace $_[0] if main::DEBUG && $to_trace;
3261
3262         # Each inserted line is an array, with the first element being 1 to
3263         # indicate that this line has been adjusted
3264         no overloading;
3265         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
3266         return;
3267     }
3268
3269     sub get_missings {
3270         # Returns the stored up @missings lines' values, and clears the list.
3271         # The values are in an array, consisting of the default in the first
3272         # element, and the property in the 2nd.  However, since these lines
3273         # can be stacked up, the return is an array of all these arrays.
3274
3275         my $self = shift;
3276         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3277
3278         my $addr = do { no overloading; pack 'J', $self; };
3279
3280         # If not accepting a list return, just return the first one.
3281         return shift @{$missings{$addr}} unless wantarray;
3282
3283         my @return = @{$missings{$addr}};
3284         undef @{$missings{$addr}};
3285         return @return;
3286     }
3287
3288     sub _exclude_unassigned {
3289
3290         # Takes the range in $_ and excludes code points that aren't assigned
3291         # in this release
3292
3293         state $skip_inserted_count = 0;
3294
3295         # Ignore recursive calls.
3296         if ($skip_inserted_count) {
3297             $skip_inserted_count--;
3298             return;
3299         }
3300
3301         # Find what code points are assigned in this release
3302         main::calculate_Assigned() if ! defined $Assigned;
3303
3304         my $self = shift;
3305         my $addr = do { no overloading; pack 'J', $self; };
3306         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3307
3308         my ($range, @remainder)
3309             = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
3310
3311         # Examine the range.
3312         if ($range =~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
3313         {
3314             my $low = hex $1;
3315             my $high = (defined $2) ? hex $2 : $low;
3316
3317             # Split the range into subranges of just those code points in it
3318             # that are assigned.
3319             my @ranges = (Range_List->new(Initialize
3320                               => Range->new($low, $high)) & $Assigned)->ranges;
3321
3322             # Do nothing if nothing in the original range is assigned in this
3323             # release; handle normally if everything is in this release.
3324             if (! @ranges) {
3325                 $_ = "";
3326             }
3327             elsif (@ranges != 1) {
3328
3329                 # Here, some code points in the original range aren't in this
3330                 # release; @ranges gives the ones that are.  Create fake input
3331                 # lines for each of the ranges, and set things up so that when
3332                 # this routine is called on that fake input, it will do
3333                 # nothing.
3334                 $skip_inserted_count = @ranges;
3335                 my $remainder = join ";", @remainder;
3336                 for my $range (@ranges) {
3337                     $self->insert_lines(sprintf("%04X..%04X;%s",
3338                                     $range->start, $range->end, $remainder));
3339                 }
3340                 $_ = "";    # The original range is now defunct.
3341             }
3342         }
3343
3344         return;
3345     }
3346
3347     sub _fixup_obsolete_hanguls {
3348
3349         # This is called only when compiling Unicode version 1.  All Unicode
3350         # data for subsequent releases assumes that the code points that were
3351         # Hangul syllables in this release only are something else, so if
3352         # using such data, we have to override it
3353
3354         my $self = shift;
3355         my $addr = do { no overloading; pack 'J', $self; };
3356         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3357
3358         my $object = main::property_ref($property{$addr});
3359         $object->add_map($FIRST_REMOVED_HANGUL_SYLLABLE,
3360                          $FINAL_REMOVED_HANGUL_SYLLABLE,
3361                          $early{$addr}[3],  # Passed-in value for these
3362                          Replace => $UNCONDITIONALLY);
3363     }
3364
3365     sub _insert_property_into_line {
3366         # Add a property field to $_, if this file requires it.
3367
3368         my $self = shift;
3369         my $addr = do { no overloading; pack 'J', $self; };
3370         my $property = $property{$addr};
3371         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3372
3373         $_ =~ s/(;|$)/; $property$1/;
3374         return;
3375     }
3376
3377     sub carp_bad_line {
3378         # Output consistent error messages, using either a generic one, or the
3379         # one given by the optional parameter.  To avoid gazillions of the
3380         # same message in case the syntax of a  file is way off, this routine
3381         # only outputs the first instance of each message, incrementing a
3382         # count so the totals can be output at the end of the file.
3383
3384         my $self = shift;
3385         my $message = shift;
3386         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3387
3388         my $addr = do { no overloading; pack 'J', $self; };
3389
3390         $message = 'Unexpected line' unless $message;
3391
3392         # No trailing punctuation so as to fit with our addenda.
3393         $message =~ s/[.:;,]$//;
3394
3395         # If haven't seen this exact message before, output it now.  Otherwise
3396         # increment the count of how many times it has occurred
3397         unless ($errors{$addr}->{$message}) {
3398             Carp::my_carp("$message in '$_' in "
3399                             . $file{$addr}
3400                             . " at line $..  Skipping this line;");
3401             $errors{$addr}->{$message} = 1;
3402         }
3403         else {
3404             $errors{$addr}->{$message}++;
3405         }
3406
3407         # Clear the line to prevent any further (meaningful) processing of it.
3408         $_ = "";
3409
3410         return;
3411     }
3412 } # End closure
3413
3414 package Multi_Default;
3415
3416 # Certain properties in early versions of Unicode had more than one possible
3417 # default for code points missing from the files.  In these cases, one
3418 # default applies to everything left over after all the others are applied,
3419 # and for each of the others, there is a description of which class of code
3420 # points applies to it.  This object helps implement this by storing the
3421 # defaults, and for all but that final default, an eval string that generates
3422 # the class that it applies to.
3423
3424
3425 {   # Closure
3426
3427     main::setup_package();
3428
3429     my %class_defaults;
3430     # The defaults structure for the classes
3431     main::set_access('class_defaults', \%class_defaults);
3432
3433     my %other_default;
3434     # The default that applies to everything left over.
3435     main::set_access('other_default', \%other_default, 'r');
3436
3437
3438     sub new {
3439         # The constructor is called with default => eval pairs, terminated by
3440         # the left-over default. e.g.
3441         # Multi_Default->new(
3442         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
3443         #               -  0x200D',
3444         #        'R' => 'some other expression that evaluates to code points',
3445         #        .
3446         #        .
3447         #        .
3448         #        'U'));
3449         # It is best to leave the final value be the one that matches the
3450         # above-Unicode code points.
3451
3452         my $class = shift;
3453
3454         my $self = bless \do{my $anonymous_scalar}, $class;
3455         my $addr = do { no overloading; pack 'J', $self; };
3456
3457         while (@_ > 1) {
3458             my $default = shift;
3459             my $eval = shift;
3460             $class_defaults{$addr}->{$default} = $eval;
3461         }
3462
3463         $other_default{$addr} = shift;
3464
3465         return $self;
3466     }
3467
3468     sub get_next_defaults {
3469         # Iterates and returns the next class of defaults.
3470         my $self = shift;
3471         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3472
3473         my $addr = do { no overloading; pack 'J', $self; };
3474
3475         return each %{$class_defaults{$addr}};
3476     }
3477 }
3478
3479 package Alias;
3480
3481 # An alias is one of the names that a table goes by.  This class defines them
3482 # including some attributes.  Everything is currently setup in the
3483 # constructor.
3484
3485
3486 {   # Closure
3487
3488     main::setup_package();
3489
3490     my %name;
3491     main::set_access('name', \%name, 'r');
3492
3493     my %loose_match;
3494     # Should this name match loosely or not.
3495     main::set_access('loose_match', \%loose_match, 'r');
3496
3497     my %make_re_pod_entry;
3498     # Some aliases should not get their own entries in the re section of the
3499     # pod, because they are covered by a wild-card, and some we want to
3500     # discourage use of.  Binary
3501     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
3502
3503     my %ucd;
3504     # Is this documented to be accessible via Unicode::UCD
3505     main::set_access('ucd', \%ucd, 'r', 's');
3506
3507     my %status;
3508     # Aliases have a status, like deprecated, or even suppressed (which means
3509     # they don't appear in documentation).  Enum
3510     main::set_access('status', \%status, 'r');
3511
3512     my %ok_as_filename;
3513     # Similarly, some aliases should not be considered as usable ones for
3514     # external use, such as file names, or we don't want documentation to
3515     # recommend them.  Boolean
3516     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
3517
3518     sub new {
3519         my $class = shift;
3520
3521         my $self = bless \do { my $anonymous_scalar }, $class;
3522         my $addr = do { no overloading; pack 'J', $self; };
3523
3524         $name{$addr} = shift;
3525         $loose_match{$addr} = shift;
3526         $make_re_pod_entry{$addr} = shift;
3527         $ok_as_filename{$addr} = shift;
3528         $status{$addr} = shift;
3529         $ucd{$addr} = shift;
3530
3531         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3532
3533         # Null names are never ok externally
3534         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
3535
3536         return $self;
3537     }
3538 }
3539
3540 package Range;
3541
3542 # A range is the basic unit for storing code points, and is described in the
3543 # comments at the beginning of the program.  Each range has a starting code
3544 # point; an ending code point (not less than the starting one); a value
3545 # that applies to every code point in between the two end-points, inclusive;
3546 # and an enum type that applies to the value.  The type is for the user's
3547 # convenience, and has no meaning here, except that a non-zero type is
3548 # considered to not obey the normal Unicode rules for having standard forms.
3549 #
3550 # The same structure is used for both map and match tables, even though in the
3551 # latter, the value (and hence type) is irrelevant and could be used as a
3552 # comment.  In map tables, the value is what all the code points in the range
3553 # map to.  Type 0 values have the standardized version of the value stored as
3554 # well, so as to not have to recalculate it a lot.
3555
3556 sub trace { return main::trace(@_); }
3557
3558 {   # Closure
3559
3560     main::setup_package();
3561
3562     my %start;
3563     main::set_access('start', \%start, 'r', 's');
3564
3565     my %end;
3566     main::set_access('end', \%end, 'r', 's');
3567
3568     my %value;
3569     main::set_access('value', \%value, 'r', 's');
3570
3571     my %type;
3572     main::set_access('type', \%type, 'r');
3573
3574     my %standard_form;
3575     # The value in internal standard form.  Defined only if the type is 0.
3576     main::set_access('standard_form', \%standard_form);
3577
3578     # Note that if these fields change, the dump() method should as well
3579
3580     sub new {
3581         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
3582         my $class = shift;
3583
3584         my $self = bless \do { my $anonymous_scalar }, $class;
3585         my $addr = do { no overloading; pack 'J', $self; };
3586
3587         $start{$addr} = shift;
3588         $end{$addr} = shift;
3589
3590         my %args = @_;
3591
3592         my $value = delete $args{'Value'};  # Can be 0
3593         $value = "" unless defined $value;
3594         $value{$addr} = $value;
3595
3596         $type{$addr} = delete $args{'Type'} || 0;
3597
3598         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3599
3600         return $self;
3601     }
3602
3603     use overload
3604         fallback => 0,
3605         qw("") => "_operator_stringify",
3606         "." => \&main::_operator_dot,
3607         ".=" => \&main::_operator_dot_equal,
3608     ;
3609
3610     sub _operator_stringify {
3611         my $self = shift;
3612         my $addr = do { no overloading; pack 'J', $self; };
3613
3614         # Output it like '0041..0065 (value)'
3615         my $return = sprintf("%04X", $start{$addr})
3616                         .  '..'
3617                         . sprintf("%04X", $end{$addr});
3618         my $value = $value{$addr};
3619         my $type = $type{$addr};
3620         $return .= ' (';
3621         $return .= "$value";
3622         $return .= ", Type=$type" if $type != 0;
3623         $return .= ')';
3624
3625         return $return;
3626     }
3627
3628     sub standard_form {
3629         # Calculate the standard form only if needed, and cache the result.
3630         # The standard form is the value itself if the type is special.
3631         # This represents a considerable CPU and memory saving - at the time
3632         # of writing there are 368676 non-special objects, but the standard
3633         # form is only requested for 22047 of them - ie about 6%.
3634
3635         my $self = shift;
3636         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3637
3638         my $addr = do { no overloading; pack 'J', $self; };
3639
3640         return $standard_form{$addr} if defined $standard_form{$addr};
3641
3642         my $value = $value{$addr};
3643         return $value if $type{$addr};
3644         return $standard_form{$addr} = main::standardize($value);
3645     }
3646
3647     sub dump {
3648         # Human, not machine readable.  For machine readable, comment out this
3649         # entire routine and let the standard one take effect.
3650         my $self = shift;
3651         my $indent = shift;
3652         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3653
3654         my $addr = do { no overloading; pack 'J', $self; };
3655
3656         my $return = $indent
3657                     . sprintf("%04X", $start{$addr})
3658                     . '..'
3659                     . sprintf("%04X", $end{$addr})
3660                     . " '$value{$addr}';";
3661         if (! defined $standard_form{$addr}) {
3662             $return .= "(type=$type{$addr})";
3663         }
3664         elsif ($standard_form{$addr} ne $value{$addr}) {
3665             $return .= "(standard '$standard_form{$addr}')";
3666         }
3667         return $return;
3668     }
3669 } # End closure
3670
3671 package _Range_List_Base;
3672
3673 # Base class for range lists.  A range list is simply an ordered list of
3674 # ranges, so that the ranges with the lowest starting numbers are first in it.
3675 #
3676 # When a new range is added that is adjacent to an existing range that has the
3677 # same value and type, it merges with it to form a larger range.
3678 #
3679 # Ranges generally do not overlap, except that there can be multiple entries
3680 # of single code point ranges.  This is because of NameAliases.txt.
3681 #
3682 # In this program, there is a standard value such that if two different
3683 # values, have the same standard value, they are considered equivalent.  This
3684 # value was chosen so that it gives correct results on Unicode data
3685
3686 # There are a number of methods to manipulate range lists, and some operators
3687 # are overloaded to handle them.
3688
3689 sub trace { return main::trace(@_); }
3690
3691 { # Closure
3692
3693     our $addr;
3694
3695     # Max is initialized to a negative value that isn't adjacent to 0, for
3696     # simpler tests
3697     my $max_init = -2;
3698
3699     main::setup_package();
3700
3701     my %ranges;
3702     # The list of ranges
3703     main::set_access('ranges', \%ranges, 'readable_array');
3704
3705     my %max;
3706     # The highest code point in the list.  This was originally a method, but
3707     # actual measurements said it was used a lot.
3708     main::set_access('max', \%max, 'r');
3709
3710     my %each_range_iterator;
3711     # Iterator position for each_range()
3712     main::set_access('each_range_iterator', \%each_range_iterator);
3713
3714     my %owner_name_of;
3715     # Name of parent this is attached to, if any.  Solely for better error
3716     # messages.
3717     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3718
3719     my %_search_ranges_cache;
3720     # A cache of the previous result from _search_ranges(), for better
3721     # performance
3722     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3723
3724     sub new {
3725         my $class = shift;
3726         my %args = @_;
3727
3728         # Optional initialization data for the range list.
3729         my $initialize = delete $args{'Initialize'};
3730
3731         my $self;
3732
3733         # Use _union() to initialize.  _union() returns an object of this
3734         # class, which means that it will call this constructor recursively.
3735         # But it won't have this $initialize parameter so that it won't
3736         # infinitely loop on this.
3737         return _union($class, $initialize, %args) if defined $initialize;
3738
3739         $self = bless \do { my $anonymous_scalar }, $class;
3740         my $addr = do { no overloading; pack 'J', $self; };
3741
3742         # Optional parent object, only for debug info.
3743         $owner_name_of{$addr} = delete $args{'Owner'};
3744         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3745
3746         # Stringify, in case it is an object.
3747         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3748
3749         # This is used only for error messages, and so a colon is added
3750         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3751
3752         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3753
3754         $max{$addr} = $max_init;
3755
3756         $_search_ranges_cache{$addr} = 0;
3757         $ranges{$addr} = [];
3758
3759         return $self;
3760     }
3761
3762     use overload
3763         fallback => 0,
3764         qw("") => "_operator_stringify",
3765         "." => \&main::_operator_dot,
3766         ".=" => \&main::_operator_dot_equal,
3767     ;
3768
3769     sub _operator_stringify {
3770         my $self = shift;
3771         my $addr = do { no overloading; pack 'J', $self; };
3772
3773         return "Range_List attached to '$owner_name_of{$addr}'"
3774                                                 if $owner_name_of{$addr};
3775         return "anonymous Range_List " . \$self;
3776     }
3777
3778     sub _union {
3779         # Returns the union of the input code points.  It can be called as
3780         # either a constructor or a method.  If called as a method, the result
3781         # will be a new() instance of the calling object, containing the union
3782         # of that object with the other parameter's code points;  if called as
3783         # a constructor, the first parameter gives the class that the new object
3784         # should be, and the second parameter gives the code points to go into
3785         # it.
3786         # In either case, there are two parameters looked at by this routine;
3787         # any additional parameters are passed to the new() constructor.
3788         #
3789         # The code points can come in the form of some object that contains
3790         # ranges, and has a conventionally named method to access them; or
3791         # they can be an array of individual code points (as integers); or
3792         # just a single code point.
3793         #
3794         # If they are ranges, this routine doesn't make any effort to preserve
3795         # the range values and types of one input over the other.  Therefore
3796         # this base class should not allow _union to be called from other than
3797         # initialization code, so as to prevent two tables from being added
3798         # together where the range values matter.  The general form of this
3799         # routine therefore belongs in a derived class, but it was moved here
3800         # to avoid duplication of code.  The failure to overload this in this
3801         # class keeps it safe.
3802         #
3803         # It does make the effort during initialization to accept tables with
3804         # multiple values for the same code point, and to preserve the order
3805         # of these.  If there is only one input range or range set, it doesn't
3806         # sort (as it should already be sorted to the desired order), and will
3807         # accept multiple values per code point.  Otherwise it will merge
3808         # multiple values into a single one.
3809
3810         my $self;
3811         my @args;   # Arguments to pass to the constructor
3812
3813         my $class = shift;
3814
3815         # If a method call, will start the union with the object itself, and
3816         # the class of the new object will be the same as self.
3817         if (ref $class) {
3818             $self = $class;
3819             $class = ref $self;
3820             push @args, $self;
3821         }
3822
3823         # Add the other required parameter.
3824         push @args, shift;
3825         # Rest of parameters are passed on to the constructor
3826
3827         # Accumulate all records from both lists.
3828         my @records;
3829         my $input_count = 0;
3830         for my $arg (@args) {
3831             #local $to_trace = 0 if main::DEBUG;
3832             trace "argument = $arg" if main::DEBUG && $to_trace;
3833             if (! defined $arg) {
3834                 my $message = "";
3835                 if (defined $self) {
3836                     no overloading;
3837                     $message .= $owner_name_of{pack 'J', $self};
3838                 }
3839                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3840                 return;
3841             }
3842
3843             $arg = [ $arg ] if ! ref $arg;
3844             my $type = ref $arg;
3845             if ($type eq 'ARRAY') {
3846                 foreach my $element (@$arg) {
3847                     push @records, Range->new($element, $element);
3848                     $input_count++;
3849                 }
3850             }
3851             elsif ($arg->isa('Range')) {
3852                 push @records, $arg;
3853                 $input_count++;
3854             }
3855             elsif ($arg->can('ranges')) {
3856                 push @records, $arg->ranges;
3857                 $input_count++;
3858             }
3859             else {
3860                 my $message = "";
3861                 if (defined $self) {
3862                     no overloading;
3863                     $message .= $owner_name_of{pack 'J', $self};
3864                 }
3865                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3866                 return;
3867             }
3868         }
3869
3870         # Sort with the range containing the lowest ordinal first, but if
3871         # two ranges start at the same code point, sort with the bigger range
3872         # of the two first, because it takes fewer cycles.
3873         if ($input_count > 1) {
3874             @records = sort { ($a->start <=> $b->start)
3875                                       or
3876                                     # if b is shorter than a, b->end will be
3877                                     # less than a->end, and we want to select
3878                                     # a, so want to return -1
3879                                     ($b->end <=> $a->end)
3880                                    } @records;
3881         }
3882
3883         my $new = $class->new(@_);
3884
3885         # Fold in records so long as they add new information.
3886         for my $set (@records) {
3887             my $start = $set->start;
3888             my $end   = $set->end;
3889             my $value = $set->value;
3890             my $type  = $set->type;
3891             if ($start > $new->max) {
3892                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3893             }
3894             elsif ($end > $new->max) {
3895                 $new->_add_delete('+', $new->max +1, $end, $value,
3896                                                                 Type => $type);
3897             }
3898             elsif ($input_count == 1) {
3899                 # Here, overlaps existing range, but is from a single input,
3900                 # so preserve the multiple values from that input.
3901                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3902                                                 Replace => $MULTIPLE_AFTER);
3903             }
3904         }
3905
3906         return $new;
3907     }
3908
3909     sub range_count {        # Return the number of ranges in the range list
3910         my $self = shift;
3911         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3912
3913         no overloading;
3914         return scalar @{$ranges{pack 'J', $self}};
3915     }
3916
3917     sub min {
3918         # Returns the minimum code point currently in the range list, or if
3919         # the range list is empty, 2 beyond the max possible.  This is a
3920         # method because used so rarely, that not worth saving between calls,
3921         # and having to worry about changing it as ranges are added and
3922         # deleted.
3923
3924         my $self = shift;
3925         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3926
3927         my $addr = do { no overloading; pack 'J', $self; };
3928
3929         # If the range list is empty, return a large value that isn't adjacent
3930         # to any that could be in the range list, for simpler tests
3931         return $MAX_WORKING_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3932         return $ranges{$addr}->[0]->start;
3933     }
3934
3935     sub contains {
3936         # Boolean: Is argument in the range list?  If so returns $i such that:
3937         #   range[$i]->end < $codepoint <= range[$i+1]->end
3938         # which is one beyond what you want; this is so that the 0th range
3939         # doesn't return false
3940         my $self = shift;
3941         my $codepoint = shift;
3942         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3943
3944         my $i = $self->_search_ranges($codepoint);
3945         return 0 unless defined $i;
3946
3947         # The search returns $i, such that
3948         #   range[$i-1]->end < $codepoint <= range[$i]->end
3949         # So is in the table if and only iff it is at least the start position
3950         # of range $i.
3951         no overloading;
3952         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3953         return $i + 1;
3954     }
3955
3956     sub containing_range {
3957         # Returns the range object that contains the code point, undef if none
3958
3959         my $self = shift;
3960         my $codepoint = shift;
3961         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3962
3963         my $i = $self->contains($codepoint);
3964         return unless $i;
3965
3966         # contains() returns 1 beyond where we should look
3967         no overloading;
3968         return $ranges{pack 'J', $self}->[$i-1];
3969     }
3970
3971     sub value_of {
3972         # Returns the value associated with the code point, undef if none
3973
3974         my $self = shift;
3975         my $codepoint = shift;
3976         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3977
3978         my $range = $self->containing_range($codepoint);
3979         return unless defined $range;
3980
3981         return $range->value;
3982     }
3983
3984     sub type_of {
3985         # Returns the type of the range containing the code point, undef if
3986         # the code point is not in the table
3987
3988         my $self = shift;
3989         my $codepoint = shift;
3990         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3991
3992         my $range = $self->containing_range($codepoint);
3993         return unless defined $range;
3994
3995         return $range->type;
3996     }
3997
3998     sub _search_ranges {
3999         # Find the range in the list which contains a code point, or where it
4000         # should go if were to add it.  That is, it returns $i, such that:
4001         #   range[$i-1]->end < $codepoint <= range[$i]->end
4002         # Returns undef if no such $i is possible (e.g. at end of table), or
4003         # if there is an error.
4004
4005         my $self = shift;
4006         my $code_point = shift;
4007         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
4008
4009         my $addr = do { no overloading; pack 'J', $self; };
4010
4011         return if $code_point > $max{$addr};
4012         my $r = $ranges{$addr};                # The current list of ranges
4013         my $range_list_size = scalar @$r;
4014         my $i;
4015
4016         use integer;        # want integer division
4017
4018         # Use the cached result as the starting guess for this one, because,
4019         # an experiment on 5.1 showed that 90% of the time the cache was the
4020         # same as the result on the next call (and 7% it was one less).
4021         $i = $_search_ranges_cache{$addr};
4022         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
4023                                             # from an intervening deletion
4024         #local $to_trace = 1 if main::DEBUG;
4025         trace "previous \$i is