This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
2e603cabc4b5efab157d8df6a19ace84d48e0e54
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 =for Pod::Functions =String
111
112 C<chomp>, C<chop>, C<chr>, C<crypt>, C<fc>, C<hex>, C<index>, C<lc>,
113 C<lcfirst>, C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
114 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
115
116 C<fc> is available only if the C<"fc"> feature is enabled or if it is
117 prefixed with C<CORE::>.  The C<"fc"> feature is enabled automatically
118 with a C<use v5.16> (or higher) declaration in the current scope.
119
120
121 =item Regular expressions and pattern matching
122 X<regular expression> X<regex> X<regexp>
123
124 =for Pod::Functions =Regexp
125
126 C<m//>, C<pos>, C<qr//>, C<quotemeta>, C<s///>, C<split>, C<study>
127
128 =item Numeric functions
129 X<numeric> X<number> X<trigonometric> X<trigonometry>
130
131 =for Pod::Functions =Math
132
133 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
134 C<sin>, C<sqrt>, C<srand>
135
136 =item Functions for real @ARRAYs
137 X<array>
138
139 =for Pod::Functions =ARRAY
140
141 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
142
143 =item Functions for list data
144 X<list>
145
146 =for Pod::Functions =LIST
147
148 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
149
150 =item Functions for real %HASHes
151 X<hash>
152
153 =for Pod::Functions =HASH
154
155 C<delete>, C<each>, C<exists>, C<keys>, C<values>
156
157 =item Input and output functions
158 X<I/O> X<input> X<output> X<dbm>
159
160 =for Pod::Functions =I/O
161
162 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
163 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
164 C<readdir>, C<readline> C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>,
165 C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>,
166 C<truncate>, C<warn>, C<write>
167
168 C<say> is available only if the C<"say"> feature is enabled or if it is
169 prefixed with C<CORE::>.  The C<"say"> feature is enabled automatically
170 with a C<use v5.10> (or higher) declaration in the current scope.
171
172 =item Functions for fixed-length data or records
173
174 =for Pod::Functions =Binary
175
176 C<pack>, C<read>, C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<unpack>,
177 C<vec>
178
179 =item Functions for filehandles, files, or directories
180 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
181
182 =for Pod::Functions =File
183
184 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
185 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
186 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
187 C<umask>, C<unlink>, C<utime>
188
189 =item Keywords related to the control flow of your Perl program
190 X<control flow>
191
192 =for Pod::Functions =Flow
193
194 C<break>, C<caller>, C<continue>, C<die>, C<do>,
195 C<dump>, C<eval>, C<evalbytes> C<exit>,
196 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
197 C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
198
199 C<break> is available only if you enable the experimental C<"switch">
200 feature or use the C<CORE::> prefix. The C<"switch"> feature also enables
201 the C<default>, C<given> and C<when> statements, which are documented in
202 L<perlsyn/"Switch Statements">. The C<"switch"> feature is enabled
203 automatically with a C<use v5.10> (or higher) declaration in the current
204 scope. In Perl v5.14 and earlier, C<continue> required the C<"switch">
205 feature, like the other keywords.
206
207 C<evalbytes> is only available with the C<"evalbytes"> feature (see
208 L<feature>) or if prefixed with C<CORE::>.  C<__SUB__> is only available
209 with the C<"current_sub"> feature or if prefixed with C<CORE::>. Both
210 the C<"evalbytes"> and C<"current_sub"> features are enabled automatically
211 with a C<use v5.16> (or higher) declaration in the current scope.
212
213 =item Keywords related to scoping
214
215 =for Pod::Functions =Namespace
216
217 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
218
219 C<state> is available only if the C<"state"> feature is enabled or if it is
220 prefixed with C<CORE::>.  The C<"state"> feature is enabled automatically
221 with a C<use v5.10> (or higher) declaration in the current scope.
222
223 =item Miscellaneous functions
224
225 =for Pod::Functions =Misc
226
227 C<defined>, C<formline>, C<lock>, C<prototype>, C<reset>, C<scalar>, C<undef>
228
229 =item Functions for processes and process groups
230 X<process> X<pid> X<process id>
231
232 =for Pod::Functions =Process
233
234 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
235 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
236 C<setpriority>, C<sleep>, C<system>,
237 C<times>, C<wait>, C<waitpid>
238
239 =item Keywords related to Perl modules
240 X<module>
241
242 =for Pod::Functions =Modules
243
244 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
245
246 =item Keywords related to classes and object-orientation
247 X<object> X<class> X<package>
248
249 =for Pod::Functions =Objects
250
251 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
252 C<untie>, C<use>
253
254 =item Low-level socket functions
255 X<socket> X<sock>
256
257 =for Pod::Functions =Socket
258
259 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
260 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
261 C<socket>, C<socketpair>
262
263 =item System V interprocess communication functions
264 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
265
266 =for Pod::Functions =SysV
267
268 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
269 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
270
271 =item Fetching user and group info
272 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
273
274 =for Pod::Functions =User
275
276 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
277 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
278 C<getpwuid>, C<setgrent>, C<setpwent>
279
280 =item Fetching network info
281 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
282
283 =for Pod::Functions =Network
284
285 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
286 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
287 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
288 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
289 C<setnetent>, C<setprotoent>, C<setservent>
290
291 =item Time-related functions
292 X<time> X<date>
293
294 =for Pod::Functions =Time
295
296 C<gmtime>, C<localtime>, C<time>, C<times>
297
298 =item Non-function keywords
299
300 =for Pod::Functions =!Non-functions
301
302 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
303 C<default>, C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>,
304 C<eq>, C<for>, C<foreach>, C<ge>, C<given>, C<gt>, C<if>, C<INIT>, C<le>,
305 C<lt>, C<ne>, C<not>, C<or>, C<UNITCHECK>, C<unless>, C<until>, C<when>,
306 C<while>, C<x>, C<xor>
307
308 =back
309
310 =head2 Portability
311 X<portability> X<Unix> X<portable>
312
313 Perl was born in Unix and can therefore access all common Unix
314 system calls.  In non-Unix environments, the functionality of some
315 Unix system calls may not be available or details of the available
316 functionality may differ slightly.  The Perl functions affected
317 by this are:
318
319 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
320 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
321 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
322 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
323 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
324 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
325 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
326 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
327 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
328 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
329 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
330 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
331 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
332 C<shmwrite>, C<socket>, C<socketpair>,
333 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
334 C<times>, C<truncate>, C<umask>, C<unlink>,
335 C<utime>, C<wait>, C<waitpid>
336
337 For more information about the portability of these functions, see
338 L<perlport> and other available platform-specific documentation.
339
340 =head2 Alphabetical Listing of Perl Functions
341
342 =over 
343
344 =item -X FILEHANDLE
345 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
346 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
347
348 =item -X EXPR
349
350 =item -X DIRHANDLE
351
352 =item -X
353
354 =for Pod::Functions a file test (-r, -x, etc)
355
356 A file test, where X is one of the letters listed below.  This unary
357 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
358 and tests the associated file to see if something is true about it.  If the
359 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
360 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
361 the undefined value if the file doesn't exist.  Despite the funny
362 names, precedence is the same as any other named unary operator.  The
363 operator may be any of:
364
365     -r  File is readable by effective uid/gid.
366     -w  File is writable by effective uid/gid.
367     -x  File is executable by effective uid/gid.
368     -o  File is owned by effective uid.
369
370     -R  File is readable by real uid/gid.
371     -W  File is writable by real uid/gid.
372     -X  File is executable by real uid/gid.
373     -O  File is owned by real uid.
374
375     -e  File exists.
376     -z  File has zero size (is empty).
377     -s  File has nonzero size (returns size in bytes).
378
379     -f  File is a plain file.
380     -d  File is a directory.
381     -l  File is a symbolic link.
382     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
383     -S  File is a socket.
384     -b  File is a block special file.
385     -c  File is a character special file.
386     -t  Filehandle is opened to a tty.
387
388     -u  File has setuid bit set.
389     -g  File has setgid bit set.
390     -k  File has sticky bit set.
391
392     -T  File is an ASCII text file (heuristic guess).
393     -B  File is a "binary" file (opposite of -T).
394
395     -M  Script start time minus file modification time, in days.
396     -A  Same for access time.
397     -C  Same for inode change time (Unix, may differ for other
398         platforms)
399
400 Example:
401
402     while (<>) {
403         chomp;
404         next unless -f $_;  # ignore specials
405         #...
406     }
407
408 Note that C<-s/a/b/> does not do a negated substitution.  Saying
409 C<-exp($foo)> still works as expected, however: only single letters
410 following a minus are interpreted as file tests.
411
412 These operators are exempt from the "looks like a function rule" described
413 above.  That is, an opening parenthesis after the operator does not affect
414 how much of the following code constitutes the argument.  Put the opening
415 parentheses before the operator to separate it from code that follows (this
416 applies only to operators with higher precedence than unary operators, of
417 course):
418
419     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
420     (-s $file) + 1024  # correct
421
422 The interpretation of the file permission operators C<-r>, C<-R>,
423 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
424 of the file and the uids and gids of the user.  There may be other
425 reasons you can't actually read, write, or execute the file: for
426 example network filesystem access controls, ACLs (access control lists),
427 read-only filesystems, and unrecognized executable formats.  Note
428 that the use of these six specific operators to verify if some operation
429 is possible is usually a mistake, because it may be open to race
430 conditions.
431
432 Also note that, for the superuser on the local filesystems, the C<-r>,
433 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
434 if any execute bit is set in the mode.  Scripts run by the superuser
435 may thus need to do a stat() to determine the actual mode of the file,
436 or temporarily set their effective uid to something else.
437
438 If you are using ACLs, there is a pragma called C<filetest> that may
439 produce more accurate results than the bare stat() mode bits.
440 When under C<use filetest 'access'> the above-mentioned filetests
441 test whether the permission can(not) be granted using the
442 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
443 under this pragma return true even if there are no execute permission
444 bits set (nor any extra execute permission ACLs).  This strangeness is
445 due to the underlying system calls' definitions.  Note also that, due to
446 the implementation of C<use filetest 'access'>, the C<_> special
447 filehandle won't cache the results of the file tests when this pragma is
448 in effect.  Read the documentation for the C<filetest> pragma for more
449 information.
450
451 The C<-T> and C<-B> switches work as follows.  The first block or so of the
452 file is examined for odd characters such as strange control codes or
453 characters with the high bit set.  If too many strange characters (>30%)
454 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
455 containing a zero byte in the first block is considered a binary file.  If C<-T>
456 or C<-B> is used on a filehandle, the current IO buffer is examined
457 rather than the first block.  Both C<-T> and C<-B> return true on an empty
458 file, or a file at EOF when testing a filehandle.  Because you have to
459 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
460 against the file first, as in C<next unless -f $file && -T $file>.
461
462 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
463 the special filehandle consisting of a solitary underline, then the stat
464 structure of the previous file test (or stat operator) is used, saving
465 a system call.  (This doesn't work with C<-t>, and you need to remember
466 that lstat() and C<-l> leave values in the stat structure for the
467 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
468 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
469 Example:
470
471     print "Can do.\n" if -r $a || -w _ || -x _;
472
473     stat($filename);
474     print "Readable\n" if -r _;
475     print "Writable\n" if -w _;
476     print "Executable\n" if -x _;
477     print "Setuid\n" if -u _;
478     print "Setgid\n" if -g _;
479     print "Sticky\n" if -k _;
480     print "Text\n" if -T _;
481     print "Binary\n" if -B _;
482
483 As of Perl 5.10.0, as a form of purely syntactic sugar, you can stack file
484 test operators, in a way that C<-f -w -x $file> is equivalent to
485 C<-x $file && -w _ && -f _>.  (This is only fancy syntax: if you use
486 the return value of C<-f $file> as an argument to another filetest
487 operator, no special magic will happen.)
488
489 Portability issues: L<perlport/-X>.
490
491 To avoid confusing would-be users of your code with mysterious
492 syntax errors, put something like this at the top of your script:
493
494     use 5.010;  # so filetest ops can stack
495
496 =item abs VALUE
497 X<abs> X<absolute>
498
499 =item abs
500
501 =for Pod::Functions absolute value function
502
503 Returns the absolute value of its argument.
504 If VALUE is omitted, uses C<$_>.
505
506 =item accept NEWSOCKET,GENERICSOCKET
507 X<accept>
508
509 =for Pod::Functions accept an incoming socket connect
510
511 Accepts an incoming socket connect, just as accept(2) 
512 does.  Returns the packed address if it succeeded, false otherwise.
513 See the example in L<perlipc/"Sockets: Client/Server Communication">.
514
515 On systems that support a close-on-exec flag on files, the flag will
516 be set for the newly opened file descriptor, as determined by the
517 value of $^F.  See L<perlvar/$^F>.
518
519 =item alarm SECONDS
520 X<alarm>
521 X<SIGALRM>
522 X<timer>
523
524 =item alarm
525
526 =for Pod::Functions schedule a SIGALRM
527
528 Arranges to have a SIGALRM delivered to this process after the
529 specified number of wallclock seconds has elapsed.  If SECONDS is not
530 specified, the value stored in C<$_> is used.  (On some machines,
531 unfortunately, the elapsed time may be up to one second less or more
532 than you specified because of how seconds are counted, and process
533 scheduling may delay the delivery of the signal even further.)
534
535 Only one timer may be counting at once.  Each call disables the
536 previous timer, and an argument of C<0> may be supplied to cancel the
537 previous timer without starting a new one.  The returned value is the
538 amount of time remaining on the previous timer.
539
540 For delays of finer granularity than one second, the Time::HiRes module
541 (from CPAN, and starting from Perl 5.8 part of the standard
542 distribution) provides ualarm().  You may also use Perl's four-argument
543 version of select() leaving the first three arguments undefined, or you
544 might be able to use the C<syscall> interface to access setitimer(2) if
545 your system supports it.  See L<perlfaq8> for details.
546
547 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
548 C<sleep> may be internally implemented on your system with C<alarm>.
549
550 If you want to use C<alarm> to time out a system call you need to use an
551 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
552 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
553 restart system calls on some systems.  Using C<eval>/C<die> always works,
554 modulo the caveats given in L<perlipc/"Signals">.
555
556     eval {
557         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
558         alarm $timeout;
559         $nread = sysread SOCKET, $buffer, $size;
560         alarm 0;
561     };
562     if ($@) {
563         die unless $@ eq "alarm\n";   # propagate unexpected errors
564         # timed out
565     }
566     else {
567         # didn't
568     }
569
570 For more information see L<perlipc>.
571
572 Portability issues: L<perlport/alarm>.
573
574 =item atan2 Y,X
575 X<atan2> X<arctangent> X<tan> X<tangent>
576
577 =for Pod::Functions arctangent of Y/X in the range -PI to PI
578
579 Returns the arctangent of Y/X in the range -PI to PI.
580
581 For the tangent operation, you may use the C<Math::Trig::tan>
582 function, or use the familiar relation:
583
584     sub tan { sin($_[0]) / cos($_[0])  }
585
586 The return value for C<atan2(0,0)> is implementation-defined; consult
587 your atan2(3) manpage for more information.
588
589 Portability issues: L<perlport/atan2>.
590
591 =item bind SOCKET,NAME
592 X<bind>
593
594 =for Pod::Functions binds an address to a socket
595
596 Binds a network address to a socket, just as bind(2)
597 does.  Returns true if it succeeded, false otherwise.  NAME should be a
598 packed address of the appropriate type for the socket.  See the examples in
599 L<perlipc/"Sockets: Client/Server Communication">.
600
601 =item binmode FILEHANDLE, LAYER
602 X<binmode> X<binary> X<text> X<DOS> X<Windows>
603
604 =item binmode FILEHANDLE
605
606 =for Pod::Functions prepare binary files for I/O
607
608 Arranges for FILEHANDLE to be read or written in "binary" or "text"
609 mode on systems where the run-time libraries distinguish between
610 binary and text files.  If FILEHANDLE is an expression, the value is
611 taken as the name of the filehandle.  Returns true on success,
612 otherwise it returns C<undef> and sets C<$!> (errno).
613
614 On some systems (in general, DOS- and Windows-based systems) binmode()
615 is necessary when you're not working with a text file.  For the sake
616 of portability it is a good idea always to use it when appropriate,
617 and never to use it when it isn't appropriate.  Also, people can
618 set their I/O to be by default UTF8-encoded Unicode, not bytes.
619
620 In other words: regardless of platform, use binmode() on binary data,
621 like images, for example.
622
623 If LAYER is present it is a single string, but may contain multiple
624 directives.  The directives alter the behaviour of the filehandle.
625 When LAYER is present, using binmode on a text file makes sense.
626
627 If LAYER is omitted or specified as C<:raw> the filehandle is made
628 suitable for passing binary data.  This includes turning off possible CRLF
629 translation and marking it as bytes (as opposed to Unicode characters).
630 Note that, despite what may be implied in I<"Programming Perl"> (the
631 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
632 Other layers that would affect the binary nature of the stream are
633 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
634 PERLIO environment variable.
635
636 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
637 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
638 establish default I/O layers.  See L<open>.
639
640 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
641 in "Programming Perl, 3rd Edition".  However, since the publishing of this
642 book, by many known as "Camel III", the consensus of the naming of this
643 functionality has moved from "discipline" to "layer".  All documentation
644 of this version of Perl therefore refers to "layers" rather than to
645 "disciplines".  Now back to the regularly scheduled documentation...>
646
647 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
648 C<:utf8> just marks the data as UTF-8 without further checking,
649 while C<:encoding(UTF-8)> checks the data for actually being valid
650 UTF-8.  More details can be found in L<PerlIO::encoding>.
651
652 In general, binmode() should be called after open() but before any I/O
653 is done on the filehandle.  Calling binmode() normally flushes any
654 pending buffered output data (and perhaps pending input data) on the
655 handle.  An exception to this is the C<:encoding> layer that
656 changes the default character encoding of the handle; see L</open>.
657 The C<:encoding> layer sometimes needs to be called in
658 mid-stream, and it doesn't flush the stream.  The C<:encoding>
659 also implicitly pushes on top of itself the C<:utf8> layer because
660 internally Perl operates on UTF8-encoded Unicode characters.
661
662 The operating system, device drivers, C libraries, and Perl run-time
663 system all conspire to let the programmer treat a single
664 character (C<\n>) as the line terminator, irrespective of external
665 representation.  On many operating systems, the native text file
666 representation matches the internal representation, but on some
667 platforms the external representation of C<\n> is made up of more than
668 one character.
669
670 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
671 a single character to end each line in the external representation of text
672 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
673 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
674 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
675 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
676 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
677 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
678 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
679 output.  This is what you want for text files, but it can be disastrous for
680 binary files.
681
682 Another consequence of using binmode() (on some systems) is that
683 special end-of-file markers will be seen as part of the data stream.
684 For systems from the Microsoft family this means that, if your binary
685 data contain C<\cZ>, the I/O subsystem will regard it as the end of
686 the file, unless you use binmode().
687
688 binmode() is important not only for readline() and print() operations,
689 but also when using read(), seek(), sysread(), syswrite() and tell()
690 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
691 in L<perlvar> for how to manually set your input and output
692 line-termination sequences.
693
694 Portability issues: L<perlport/binmode>.
695
696 =item bless REF,CLASSNAME
697 X<bless>
698
699 =item bless REF
700
701 =for Pod::Functions create an object
702
703 This function tells the thingy referenced by REF that it is now an object
704 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
705 is used.  Because a C<bless> is often the last thing in a constructor,
706 it returns the reference for convenience.  Always use the two-argument
707 version if a derived class might inherit the function doing the blessing.
708 See L<perlobj> for more about the blessing (and blessings) of objects.
709
710 Consider always blessing objects in CLASSNAMEs that are mixed case.
711 Namespaces with all lowercase names are considered reserved for
712 Perl pragmata.  Builtin types have all uppercase names.  To prevent
713 confusion, you may wish to avoid such package names as well.  Make sure
714 that CLASSNAME is a true value.
715
716 See L<perlmod/"Perl Modules">.
717
718 =item break
719
720 =for Pod::Functions +switch break out of a C<given> block
721
722 Break out of a C<given()> block.
723
724 This keyword is enabled by the C<"switch"> feature; see L<feature> for
725 more information on C<"switch">.  You can also access it by prefixing it
726 with C<CORE::>.  Alternatively, include a C<use v5.10> or later to the
727 current scope.
728
729 =item caller EXPR
730 X<caller> X<call stack> X<stack> X<stack trace>
731
732 =item caller
733
734 =for Pod::Functions get context of the current subroutine call
735
736 Returns the context of the current subroutine call.  In scalar context,
737 returns the caller's package name if there I<is> a caller (that is, if
738 we're in a subroutine or C<eval> or C<require>) and the undefined value
739 otherwise.  In list context, returns
740
741     # 0         1          2
742     ($package, $filename, $line) = caller;
743
744 With EXPR, it returns some extra information that the debugger uses to
745 print a stack trace.  The value of EXPR indicates how many call frames
746 to go back before the current one.
747
748     #  0         1          2      3            4
749     ($package, $filename, $line, $subroutine, $hasargs,
750
751     #  5          6          7            8       9         10
752     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
753      = caller($i);
754
755 Here $subroutine may be C<(eval)> if the frame is not a subroutine
756 call, but an C<eval>.  In such a case additional elements $evaltext and
757 C<$is_require> are set: C<$is_require> is true if the frame is created by a
758 C<require> or C<use> statement, $evaltext contains the text of the
759 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
760 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
761 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
762 frame.)  $subroutine may also be C<(unknown)> if this particular
763 subroutine happens to have been deleted from the symbol table.
764 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
765 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
766 compiled with.  C<$hints> corresponds to C<$^H>, and C<$bitmask>
767 corresponds to C<${^WARNING_BITS}>.  The
768 C<$hints> and C<$bitmask> values are subject
769 to change between versions of Perl, and are not meant for external use.
770
771 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
772 caller was compiled, or C<undef> if C<%^H> was empty.  Do not modify the values
773 of this hash, as they are the actual values stored in the optree.
774
775 Furthermore, when called from within the DB package in
776 list context, and with an argument, caller returns more
777 detailed information: it sets the list variable C<@DB::args> to be the
778 arguments with which the subroutine was invoked.
779
780 Be aware that the optimizer might have optimized call frames away before
781 C<caller> had a chance to get the information.  That means that C<caller(N)>
782 might not return information about the call frame you expect it to, for
783 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
784 previous time C<caller> was called.
785
786 Be aware that setting C<@DB::args> is I<best effort>, intended for
787 debugging or generating backtraces, and should not be relied upon.  In
788 particular, as C<@_> contains aliases to the caller's arguments, Perl does
789 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
790 subroutine makes to C<@_> or its contents, not the original values at call
791 time.  C<@DB::args>, like C<@_>, does not hold explicit references to its
792 elements, so under certain cases its elements may have become freed and
793 reallocated for other variables or temporary values.  Finally, a side effect
794 of the current implementation is that the effects of C<shift @_> can
795 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
796 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
797 elements), so C<@DB::args> is actually a hybrid of the current state and
798 initial state of C<@_>.  Buyer beware.
799
800 =item chdir EXPR
801 X<chdir>
802 X<cd>
803 X<directory, change>
804
805 =item chdir FILEHANDLE
806
807 =item chdir DIRHANDLE
808
809 =item chdir
810
811 =for Pod::Functions change your current working directory
812
813 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
814 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
815 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
816 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.)  If
817 neither is set, C<chdir> does nothing.  It returns true on success,
818 false otherwise.  See the example under C<die>.
819
820 On systems that support fchdir(2), you may pass a filehandle or
821 directory handle as the argument.  On systems that don't support fchdir(2),
822 passing handles raises an exception.
823
824 =item chmod LIST
825 X<chmod> X<permission> X<mode>
826
827 =for Pod::Functions changes the permissions on a list of files
828
829 Changes the permissions of a list of files.  The first element of the
830 list must be the numeric mode, which should probably be an octal
831 number, and which definitely should I<not> be a string of octal digits:
832 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
833 successfully changed.  See also L</oct> if all you have is a string.
834
835     $cnt = chmod 0755, "foo", "bar";
836     chmod 0755, @executables;
837     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
838                                              # --w----r-T
839     $mode = "0644"; chmod oct($mode), "foo"; # this is better
840     $mode = 0644;   chmod $mode, "foo";      # this is best
841
842 On systems that support fchmod(2), you may pass filehandles among the
843 files.  On systems that don't support fchmod(2), passing filehandles raises
844 an exception.  Filehandles must be passed as globs or glob references to be
845 recognized; barewords are considered filenames.
846
847     open(my $fh, "<", "foo");
848     my $perm = (stat $fh)[2] & 07777;
849     chmod($perm | 0600, $fh);
850
851 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
852 module:
853
854     use Fcntl qw( :mode );
855     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
856     # Identical to the chmod 0755 of the example above.
857
858 Portability issues: L<perlport/chmod>.
859
860 =item chomp VARIABLE
861 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
862
863 =item chomp( LIST )
864
865 =item chomp
866
867 =for Pod::Functions remove a trailing record separator from a string
868
869 This safer version of L</chop> removes any trailing string
870 that corresponds to the current value of C<$/> (also known as
871 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
872 number of characters removed from all its arguments.  It's often used to
873 remove the newline from the end of an input record when you're worried
874 that the final record may be missing its newline.  When in paragraph
875 mode (C<$/ = "">), it removes all trailing newlines from the string.
876 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
877 a reference to an integer or the like; see L<perlvar>) chomp() won't
878 remove anything.
879 If VARIABLE is omitted, it chomps C<$_>.  Example:
880
881     while (<>) {
882         chomp;  # avoid \n on last field
883         @array = split(/:/);
884         # ...
885     }
886
887 If VARIABLE is a hash, it chomps the hash's values, but not its keys,
888 resetting the C<each> iterator in the process.
889
890 You can actually chomp anything that's an lvalue, including an assignment:
891
892     chomp($cwd = `pwd`);
893     chomp($answer = <STDIN>);
894
895 If you chomp a list, each element is chomped, and the total number of
896 characters removed is returned.
897
898 Note that parentheses are necessary when you're chomping anything
899 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
900 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
901 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
902 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
903 as C<chomp($a, $b)>.
904
905 =item chop VARIABLE
906 X<chop>
907
908 =item chop( LIST )
909
910 =item chop
911
912 =for Pod::Functions remove the last character from a string
913
914 Chops off the last character of a string and returns the character
915 chopped.  It is much more efficient than C<s/.$//s> because it neither
916 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
917 If VARIABLE is a hash, it chops the hash's values, but not its keys,
918 resetting the C<each> iterator in the process.
919
920 You can actually chop anything that's an lvalue, including an assignment.
921
922 If you chop a list, each element is chopped.  Only the value of the
923 last C<chop> is returned.
924
925 Note that C<chop> returns the last character.  To return all but the last
926 character, use C<substr($string, 0, -1)>.
927
928 See also L</chomp>.
929
930 =item chown LIST
931 X<chown> X<owner> X<user> X<group>
932
933 =for Pod::Functions change the ownership on a list of files
934
935 Changes the owner (and group) of a list of files.  The first two
936 elements of the list must be the I<numeric> uid and gid, in that
937 order.  A value of -1 in either position is interpreted by most
938 systems to leave that value unchanged.  Returns the number of files
939 successfully changed.
940
941     $cnt = chown $uid, $gid, 'foo', 'bar';
942     chown $uid, $gid, @filenames;
943
944 On systems that support fchown(2), you may pass filehandles among the
945 files.  On systems that don't support fchown(2), passing filehandles raises
946 an exception.  Filehandles must be passed as globs or glob references to be
947 recognized; barewords are considered filenames.
948
949 Here's an example that looks up nonnumeric uids in the passwd file:
950
951     print "User: ";
952     chomp($user = <STDIN>);
953     print "Files: ";
954     chomp($pattern = <STDIN>);
955
956     ($login,$pass,$uid,$gid) = getpwnam($user)
957         or die "$user not in passwd file";
958
959     @ary = glob($pattern);  # expand filenames
960     chown $uid, $gid, @ary;
961
962 On most systems, you are not allowed to change the ownership of the
963 file unless you're the superuser, although you should be able to change
964 the group to any of your secondary groups.  On insecure systems, these
965 restrictions may be relaxed, but this is not a portable assumption.
966 On POSIX systems, you can detect this condition this way:
967
968     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
969     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
970
971 Portability issues: L<perlport/chmod>.
972
973 =item chr NUMBER
974 X<chr> X<character> X<ASCII> X<Unicode>
975
976 =item chr
977
978 =for Pod::Functions get character this number represents
979
980 Returns the character represented by that NUMBER in the character set.
981 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
982 chr(0x263a) is a Unicode smiley face.  
983
984 Negative values give the Unicode replacement character (chr(0xfffd)),
985 except under the L<bytes> pragma, where the low eight bits of the value
986 (truncated to an integer) are used.
987
988 If NUMBER is omitted, uses C<$_>.
989
990 For the reverse, use L</ord>.
991
992 Note that characters from 128 to 255 (inclusive) are by default
993 internally not encoded as UTF-8 for backward compatibility reasons.
994
995 See L<perlunicode> for more about Unicode.
996
997 =item chroot FILENAME
998 X<chroot> X<root>
999
1000 =item chroot
1001
1002 =for Pod::Functions make directory new root for path lookups
1003
1004 This function works like the system call by the same name: it makes the
1005 named directory the new root directory for all further pathnames that
1006 begin with a C</> by your process and all its children.  (It doesn't
1007 change your current working directory, which is unaffected.)  For security
1008 reasons, this call is restricted to the superuser.  If FILENAME is
1009 omitted, does a C<chroot> to C<$_>.
1010
1011 Portability issues: L<perlport/chroot>.
1012
1013 =item close FILEHANDLE
1014 X<close>
1015
1016 =item close
1017
1018 =for Pod::Functions close file (or pipe or socket) handle
1019
1020 Closes the file or pipe associated with the filehandle, flushes the IO
1021 buffers, and closes the system file descriptor.  Returns true if those
1022 operations succeed and if no error was reported by any PerlIO
1023 layer.  Closes the currently selected filehandle if the argument is
1024 omitted.
1025
1026 You don't have to close FILEHANDLE if you are immediately going to do
1027 another C<open> on it, because C<open> closes it for you.  (See
1028 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
1029 counter (C<$.>), while the implicit close done by C<open> does not.
1030
1031 If the filehandle came from a piped open, C<close> returns false if one of
1032 the other syscalls involved fails or if its program exits with non-zero
1033 status.  If the only problem was that the program exited non-zero, C<$!>
1034 will be set to C<0>.  Closing a pipe also waits for the process executing
1035 on the pipe to exit--in case you wish to look at the output of the pipe
1036 afterwards--and implicitly puts the exit status value of that command into
1037 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
1038
1039 If there are multiple threads running, C<close> on a filehandle from a
1040 piped open returns true without waiting for the child process to terminate,
1041 if the filehandle is still open in another thread.
1042
1043 Closing the read end of a pipe before the process writing to it at the
1044 other end is done writing results in the writer receiving a SIGPIPE.  If
1045 the other end can't handle that, be sure to read all the data before
1046 closing the pipe.
1047
1048 Example:
1049
1050     open(OUTPUT, '|sort >foo')  # pipe to sort
1051         or die "Can't start sort: $!";
1052     #...                        # print stuff to output
1053     close OUTPUT                # wait for sort to finish
1054         or warn $! ? "Error closing sort pipe: $!"
1055                    : "Exit status $? from sort";
1056     open(INPUT, 'foo')          # get sort's results
1057         or die "Can't open 'foo' for input: $!";
1058
1059 FILEHANDLE may be an expression whose value can be used as an indirect
1060 filehandle, usually the real filehandle name or an autovivified handle.
1061
1062 =item closedir DIRHANDLE
1063 X<closedir>
1064
1065 =for Pod::Functions close directory handle
1066
1067 Closes a directory opened by C<opendir> and returns the success of that
1068 system call.
1069
1070 =item connect SOCKET,NAME
1071 X<connect>
1072
1073 =for Pod::Functions connect to a remote socket
1074
1075 Attempts to connect to a remote socket, just like connect(2).
1076 Returns true if it succeeded, false otherwise.  NAME should be a
1077 packed address of the appropriate type for the socket.  See the examples in
1078 L<perlipc/"Sockets: Client/Server Communication">.
1079
1080 =item continue BLOCK
1081 X<continue>
1082
1083 =item continue
1084
1085 =for Pod::Functions optional trailing block in a while or foreach
1086
1087 When followed by a BLOCK, C<continue> is actually a
1088 flow control statement rather than a function.  If
1089 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
1090 C<foreach>), it is always executed just before the conditional is about to
1091 be evaluated again, just like the third part of a C<for> loop in C.  Thus
1092 it can be used to increment a loop variable, even when the loop has been
1093 continued via the C<next> statement (which is similar to the C C<continue>
1094 statement).
1095
1096 C<last>, C<next>, or C<redo> may appear within a C<continue>
1097 block; C<last> and C<redo> behave as if they had been executed within
1098 the main block.  So will C<next>, but since it will execute a C<continue>
1099 block, it may be more entertaining.
1100
1101     while (EXPR) {
1102         ### redo always comes here
1103         do_something;
1104     } continue {
1105         ### next always comes here
1106         do_something_else;
1107         # then back the top to re-check EXPR
1108     }
1109     ### last always comes here
1110
1111 Omitting the C<continue> section is equivalent to using an
1112 empty one, logically enough, so C<next> goes directly back
1113 to check the condition at the top of the loop.
1114
1115 When there is no BLOCK, C<continue> is a function that
1116 falls through the current C<when> or C<default> block instead of iterating
1117 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1118 In Perl 5.14 and earlier, this form of C<continue> was
1119 only available when the C<"switch"> feature was enabled.
1120 See L<feature> and L<perlsyn/"Switch Statements"> for more
1121 information.
1122
1123 =item cos EXPR
1124 X<cos> X<cosine> X<acos> X<arccosine>
1125
1126 =item cos
1127
1128 =for Pod::Functions cosine function
1129
1130 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1131 takes the cosine of C<$_>.
1132
1133 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1134 function, or use this relation:
1135
1136     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1137
1138 =item crypt PLAINTEXT,SALT
1139 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1140 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1141
1142 =for Pod::Functions one-way passwd-style encryption
1143
1144 Creates a digest string exactly like the crypt(3) function in the C
1145 library (assuming that you actually have a version there that has not
1146 been extirpated as a potential munition).
1147
1148 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1149 into a short string, called a digest, which is returned.  The same
1150 PLAINTEXT and SALT will always return the same string, but there is no
1151 (known) way to get the original PLAINTEXT from the hash.  Small
1152 changes in the PLAINTEXT or SALT will result in large changes in the
1153 digest.
1154
1155 There is no decrypt function.  This function isn't all that useful for
1156 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1157 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1158 primarily used to check if two pieces of text are the same without
1159 having to transmit or store the text itself.  An example is checking
1160 if a correct password is given.  The digest of the password is stored,
1161 not the password itself.  The user types in a password that is
1162 crypt()'d with the same salt as the stored digest.  If the two digests
1163 match, the password is correct.
1164
1165 When verifying an existing digest string you should use the digest as
1166 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1167 to create the digest is visible as part of the digest.  This ensures
1168 crypt() will hash the new string with the same salt as the digest.
1169 This allows your code to work with the standard L<crypt|/crypt> and
1170 with more exotic implementations.  In other words, assume
1171 nothing about the returned string itself nor about how many bytes 
1172 of SALT may matter.
1173
1174 Traditionally the result is a string of 13 bytes: two first bytes of
1175 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1176 the first eight bytes of PLAINTEXT mattered.  But alternative
1177 hashing schemes (like MD5), higher level security schemes (like C2),
1178 and implementations on non-Unix platforms may produce different
1179 strings.
1180
1181 When choosing a new salt create a random two character string whose
1182 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1183 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1184 characters is just a recommendation; the characters allowed in
1185 the salt depend solely on your system's crypt library, and Perl can't
1186 restrict what salts C<crypt()> accepts.
1187
1188 Here's an example that makes sure that whoever runs this program knows
1189 their password:
1190
1191     $pwd = (getpwuid($<))[1];
1192
1193     system "stty -echo";
1194     print "Password: ";
1195     chomp($word = <STDIN>);
1196     print "\n";
1197     system "stty echo";
1198
1199     if (crypt($word, $pwd) ne $pwd) {
1200         die "Sorry...\n";
1201     } else {
1202         print "ok\n";
1203     }
1204
1205 Of course, typing in your own password to whoever asks you
1206 for it is unwise.
1207
1208 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1209 of data, not least of all because you can't get the information
1210 back.  Look at the L<Digest> module for more robust algorithms.
1211
1212 If using crypt() on a Unicode string (which I<potentially> has
1213 characters with codepoints above 255), Perl tries to make sense
1214 of the situation by trying to downgrade (a copy of)
1215 the string back to an eight-bit byte string before calling crypt()
1216 (on that copy).  If that works, good.  If not, crypt() dies with
1217 C<Wide character in crypt>.
1218
1219 Portability issues: L<perlport/crypt>.
1220
1221 =item dbmclose HASH
1222 X<dbmclose>
1223
1224 =for Pod::Functions breaks binding on a tied dbm file
1225
1226 [This function has been largely superseded by the C<untie> function.]
1227
1228 Breaks the binding between a DBM file and a hash.
1229
1230 Portability issues: L<perlport/dbmclose>.
1231
1232 =item dbmopen HASH,DBNAME,MASK
1233 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1234
1235 =for Pod::Functions create binding on a tied dbm file
1236
1237 [This function has been largely superseded by the
1238 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1239
1240 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1241 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1242 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1243 is the name of the database (without the F<.dir> or F<.pag> extension if
1244 any).  If the database does not exist, it is created with protection
1245 specified by MASK (as modified by the C<umask>).  To prevent creation of
1246 the database if it doesn't exist, you may specify a MODE
1247 of 0, and the function will return a false value if it
1248 can't find an existing database.  If your system supports
1249 only the older DBM functions, you may make only one C<dbmopen> call in your
1250 program.  In older versions of Perl, if your system had neither DBM nor
1251 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1252 sdbm(3).
1253
1254 If you don't have write access to the DBM file, you can only read hash
1255 variables, not set them.  If you want to test whether you can write,
1256 either use file tests or try setting a dummy hash entry inside an C<eval> 
1257 to trap the error.
1258
1259 Note that functions such as C<keys> and C<values> may return huge lists
1260 when used on large DBM files.  You may prefer to use the C<each>
1261 function to iterate over large DBM files.  Example:
1262
1263     # print out history file offsets
1264     dbmopen(%HIST,'/usr/lib/news/history',0666);
1265     while (($key,$val) = each %HIST) {
1266         print $key, ' = ', unpack('L',$val), "\n";
1267     }
1268     dbmclose(%HIST);
1269
1270 See also L<AnyDBM_File> for a more general description of the pros and
1271 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1272 rich implementation.
1273
1274 You can control which DBM library you use by loading that library
1275 before you call dbmopen():
1276
1277     use DB_File;
1278     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1279         or die "Can't open netscape history file: $!";
1280
1281 Portability issues: L<perlport/dbmopen>.
1282
1283 =item defined EXPR
1284 X<defined> X<undef> X<undefined>
1285
1286 =item defined
1287
1288 =for Pod::Functions test whether a value, variable, or function is defined
1289
1290 Returns a Boolean value telling whether EXPR has a value other than
1291 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1292 checked.
1293
1294 Many operations return C<undef> to indicate failure, end of file,
1295 system error, uninitialized variable, and other exceptional
1296 conditions.  This function allows you to distinguish C<undef> from
1297 other values.  (A simple Boolean test will not distinguish among
1298 C<undef>, zero, the empty string, and C<"0">, which are all equally
1299 false.)  Note that since C<undef> is a valid scalar, its presence
1300 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1301 returns C<undef> when its argument is an empty array, I<or> when the
1302 element to return happens to be C<undef>.
1303
1304 You may also use C<defined(&func)> to check whether subroutine C<&func>
1305 has ever been defined.  The return value is unaffected by any forward
1306 declarations of C<&func>.  A subroutine that is not defined
1307 may still be callable: its package may have an C<AUTOLOAD> method that
1308 makes it spring into existence the first time that it is called; see
1309 L<perlsub>.
1310
1311 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1312 used to report whether memory for that aggregate had ever been
1313 allocated.  This behavior may disappear in future versions of Perl.
1314 You should instead use a simple test for size:
1315
1316     if (@an_array) { print "has array elements\n" }
1317     if (%a_hash)   { print "has hash members\n"   }
1318
1319 When used on a hash element, it tells you whether the value is defined,
1320 not whether the key exists in the hash.  Use L</exists> for the latter
1321 purpose.
1322
1323 Examples:
1324
1325     print if defined $switch{D};
1326     print "$val\n" while defined($val = pop(@ary));
1327     die "Can't readlink $sym: $!"
1328         unless defined($value = readlink $sym);
1329     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1330     $debugging = 0 unless defined $debugging;
1331
1332 Note:  Many folks tend to overuse C<defined> and are then surprised to
1333 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1334 defined values.  For example, if you say
1335
1336     "ab" =~ /a(.*)b/;
1337
1338 The pattern match succeeds and C<$1> is defined, although it
1339 matched "nothing".  It didn't really fail to match anything.  Rather, it
1340 matched something that happened to be zero characters long.  This is all
1341 very above-board and honest.  When a function returns an undefined value,
1342 it's an admission that it couldn't give you an honest answer.  So you
1343 should use C<defined> only when questioning the integrity of what
1344 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1345 what you want.
1346
1347 See also L</undef>, L</exists>, L</ref>.
1348
1349 =item delete EXPR
1350 X<delete>
1351
1352 =for Pod::Functions deletes a value from a hash
1353
1354 Given an expression that specifies an element or slice of a hash, C<delete>
1355 deletes the specified elements from that hash so that exists() on that element
1356 no longer returns true.  Setting a hash element to the undefined value does
1357 not remove its key, but deleting it does; see L</exists>.
1358
1359 In list context, returns the value or values deleted, or the last such
1360 element in scalar context.  The return list's length always matches that of
1361 the argument list: deleting non-existent elements returns the undefined value
1362 in their corresponding positions.
1363
1364 delete() may also be used on arrays and array slices, but its behavior is less
1365 straightforward.  Although exists() will return false for deleted entries,
1366 deleting array elements never changes indices of existing values; use shift()
1367 or splice() for that.  However, if all deleted elements fall at the end of an
1368 array, the array's size shrinks to the position of the highest element that
1369 still tests true for exists(), or to 0 if none do.
1370
1371 B<WARNING:> Calling delete on array values is deprecated and likely to
1372 be removed in a future version of Perl.
1373
1374 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1375 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1376 or array may not necessarily return anything; it depends on the implementation
1377 of the C<tied> package's DELETE method, which may do whatever it pleases.
1378
1379 The C<delete local EXPR> construct localizes the deletion to the current
1380 block at run time.  Until the block exits, elements locally deleted
1381 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1382 of composite types">.
1383
1384     %hash = (foo => 11, bar => 22, baz => 33);
1385     $scalar = delete $hash{foo};         # $scalar is 11
1386     $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
1387     @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)
1388
1389 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1390
1391     foreach $key (keys %HASH) {
1392         delete $HASH{$key};
1393     }
1394
1395     foreach $index (0 .. $#ARRAY) {
1396         delete $ARRAY[$index];
1397     }
1398
1399 And so do these:
1400
1401     delete @HASH{keys %HASH};
1402
1403     delete @ARRAY[0 .. $#ARRAY];
1404
1405 But both are slower than assigning the empty list
1406 or undefining %HASH or @ARRAY, which is the customary 
1407 way to empty out an aggregate:
1408
1409     %HASH = ();     # completely empty %HASH
1410     undef %HASH;    # forget %HASH ever existed
1411
1412     @ARRAY = ();    # completely empty @ARRAY
1413     undef @ARRAY;   # forget @ARRAY ever existed
1414
1415 The EXPR can be arbitrarily complicated provided its
1416 final operation is an element or slice of an aggregate:
1417
1418     delete $ref->[$x][$y]{$key};
1419     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1420
1421     delete $ref->[$x][$y][$index];
1422     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1423
1424 =item die LIST
1425 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1426
1427 =for Pod::Functions raise an exception or bail out
1428
1429 C<die> raises an exception.  Inside an C<eval> the error message is stuffed
1430 into C<$@> and the C<eval> is terminated with the undefined value.
1431 If the exception is outside of all enclosing C<eval>s, then the uncaught
1432 exception prints LIST to C<STDERR> and exits with a non-zero value.  If you
1433 need to exit the process with a specific exit code, see L</exit>.
1434
1435 Equivalent examples:
1436
1437     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1438     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1439
1440 If the last element of LIST does not end in a newline, the current
1441 script line number and input line number (if any) are also printed,
1442 and a newline is supplied.  Note that the "input line number" (also
1443 known as "chunk") is subject to whatever notion of "line" happens to
1444 be currently in effect, and is also available as the special variable
1445 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1446
1447 Hint: sometimes appending C<", stopped"> to your message will cause it
1448 to make better sense when the string C<"at foo line 123"> is appended.
1449 Suppose you are running script "canasta".
1450
1451     die "/etc/games is no good";
1452     die "/etc/games is no good, stopped";
1453
1454 produce, respectively
1455
1456     /etc/games is no good at canasta line 123.
1457     /etc/games is no good, stopped at canasta line 123.
1458
1459 If the output is empty and C<$@> already contains a value (typically from a
1460 previous eval) that value is reused after appending C<"\t...propagated">.
1461 This is useful for propagating exceptions:
1462
1463     eval { ... };
1464     die unless $@ =~ /Expected exception/;
1465
1466 If the output is empty and C<$@> contains an object reference that has a
1467 C<PROPAGATE> method, that method will be called with additional file
1468 and line number parameters.  The return value replaces the value in
1469 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1470 were called.
1471
1472 If C<$@> is empty then the string C<"Died"> is used.
1473
1474 If an uncaught exception results in interpreter exit, the exit code is
1475 determined from the values of C<$!> and C<$?> with this pseudocode:
1476
1477     exit $! if $!;              # errno
1478     exit $? >> 8 if $? >> 8;    # child exit status
1479     exit 255;                   # last resort
1480
1481 The intent is to squeeze as much possible information about the likely cause
1482 into the limited space of the system exit
1483 code.  However, as C<$!> is the value
1484 of C's C<errno>, which can be set by any system call, this means that the value
1485 of the exit code used by C<die> can be non-predictable, so should not be relied
1486 upon, other than to be non-zero.
1487
1488 You can also call C<die> with a reference argument, and if this is trapped
1489 within an C<eval>, C<$@> contains that reference.  This permits more
1490 elaborate exception handling using objects that maintain arbitrary state
1491 about the exception.  Such a scheme is sometimes preferable to matching
1492 particular string values of C<$@> with regular expressions.  Because C<$@> 
1493 is a global variable and C<eval> may be used within object implementations,
1494 be careful that analyzing the error object doesn't replace the reference in
1495 the global variable.  It's easiest to make a local copy of the reference
1496 before any manipulations.  Here's an example:
1497
1498     use Scalar::Util "blessed";
1499
1500     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1501     if (my $ev_err = $@) {
1502         if (blessed($ev_err)
1503             && $ev_err->isa("Some::Module::Exception")) {
1504             # handle Some::Module::Exception
1505         }
1506         else {
1507             # handle all other possible exceptions
1508         }
1509     }
1510
1511 Because Perl stringifies uncaught exception messages before display,
1512 you'll probably want to overload stringification operations on
1513 exception objects.  See L<overload> for details about that.
1514
1515 You can arrange for a callback to be run just before the C<die>
1516 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1517 handler is called with the error text and can change the error
1518 message, if it sees fit, by calling C<die> again.  See
1519 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1520 L<"eval BLOCK"> for some examples.  Although this feature was 
1521 to be run only right before your program was to exit, this is not
1522 currently so: the C<$SIG{__DIE__}> hook is currently called
1523 even inside eval()ed blocks/strings!  If one wants the hook to do
1524 nothing in such situations, put
1525
1526     die @_ if $^S;
1527
1528 as the first line of the handler (see L<perlvar/$^S>).  Because
1529 this promotes strange action at a distance, this counterintuitive
1530 behavior may be fixed in a future release.
1531
1532 See also exit(), warn(), and the Carp module.
1533
1534 =item do BLOCK
1535 X<do> X<block>
1536
1537 =for Pod::Functions turn a BLOCK into a TERM
1538
1539 Not really a function.  Returns the value of the last command in the
1540 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1541 C<until> loop modifier, executes the BLOCK once before testing the loop
1542 condition.  (On other statements the loop modifiers test the conditional
1543 first.)
1544
1545 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1546 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1547 See L<perlsyn> for alternative strategies.
1548
1549 =item do SUBROUTINE(LIST)
1550 X<do>
1551
1552 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword
1553 or scalar variable.
1554
1555 =item do EXPR
1556 X<do>
1557
1558 Uses the value of EXPR as a filename and executes the contents of the
1559 file as a Perl script.
1560
1561     do 'stat.pl';
1562
1563 is largely like
1564
1565     eval `cat stat.pl`;
1566
1567 except that it's more concise, runs no external processes, keeps track of
1568 the current
1569 filename for error messages, searches the C<@INC> directories, and updates
1570 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1571 these variables.  It also differs in that code evaluated with C<do FILENAME>
1572 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1573 same, however, in that it does reparse the file every time you call it,
1574 so you probably don't want to do this inside a loop.
1575
1576 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1577 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1578 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1579 could fail in a way that also sets C<$!>.  If the file is successfully
1580 compiled, C<do> returns the value of the last expression evaluated.
1581
1582 Inclusion of library modules is better done with the
1583 C<use> and C<require> operators, which also do automatic error checking
1584 and raise an exception if there's a problem.
1585
1586 You might like to use C<do> to read in a program configuration
1587 file.  Manual error checking can be done this way:
1588
1589     # read in config files: system first, then user
1590     for $file ("/share/prog/defaults.rc",
1591                "$ENV{HOME}/.someprogrc")
1592     {
1593         unless ($return = do $file) {
1594             warn "couldn't parse $file: $@" if $@;
1595             warn "couldn't do $file: $!"    unless defined $return;
1596             warn "couldn't run $file"       unless $return;
1597         }
1598     }
1599
1600 =item dump LABEL
1601 X<dump> X<core> X<undump>
1602
1603 =item dump EXPR
1604
1605 =item dump
1606
1607 =for Pod::Functions create an immediate core dump
1608
1609 This function causes an immediate core dump.  See also the B<-u>
1610 command-line switch in L<perlrun>, which does the same thing.
1611 Primarily this is so that you can use the B<undump> program (not
1612 supplied) to turn your core dump into an executable binary after
1613 having initialized all your variables at the beginning of the
1614 program.  When the new binary is executed it will begin by executing
1615 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1616 Think of it as a goto with an intervening core dump and reincarnation.
1617 If C<LABEL> is omitted, restarts the program from the top.  The
1618 C<dump EXPR> form, available starting in Perl 5.18.0, allows a name to be
1619 computed at run time, being otherwise identical to C<dump LABEL>.
1620
1621 B<WARNING>: Any files opened at the time of the dump will I<not>
1622 be open any more when the program is reincarnated, with possible
1623 resulting confusion by Perl.
1624
1625 This function is now largely obsolete, mostly because it's very hard to
1626 convert a core file into an executable.  That's why you should now invoke
1627 it as C<CORE::dump()>, if you don't want to be warned against a possible
1628 typo.
1629
1630 Unlike most named operators, this has the same precedence as assignment.
1631 It is also exempt from the looks-like-a-function rule, so
1632 C<dump ("foo")."bar"> will cause "bar" to be part of the argument to
1633 C<dump>.
1634
1635 Portability issues: L<perlport/dump>.
1636
1637 =item each HASH
1638 X<each> X<hash, iterator>
1639
1640 =item each ARRAY
1641 X<array, iterator>
1642
1643 =item each EXPR
1644
1645 =for Pod::Functions retrieve the next key/value pair from a hash
1646
1647 When called on a hash in list context, returns a 2-element list
1648 consisting of the key and value for the next element of a hash.  In Perl
1649 5.12 and later only, it will also return the index and value for the next
1650 element of an array so that you can iterate over it; older Perls consider
1651 this a syntax error.  When called in scalar context, returns only the key
1652 (not the value) in a hash, or the index in an array.
1653
1654 Hash entries are returned in an apparently random order.  The actual random
1655 order is specific to a given hash; the exact same series of operations
1656 on two hashes may result in a different order for each hash. Any insertion
1657 into the hash may change the order, as will any deletion, with the exception
1658 that the most recent key returned by C<each> or C<keys> may be deleted
1659 without changing the order. So long as a given hash is unmodified you may
1660 rely on C<keys>, C<values> and C<each> to repeatedly return the same order
1661 as each other. See L<perlsec/"Algorithmic Complexity Attacks"> for
1662 details on why hash order is randomized. Aside from the guarantees
1663 provided here the exact details of Perl's hash algorithm and the hash
1664 traversal order are subject to change in any release of Perl.
1665
1666 After C<each> has returned all entries from the hash or array, the next
1667 call to C<each> returns the empty list in list context and C<undef> in
1668 scalar context; the next call following I<that> one restarts iteration.
1669 Each hash or array has its own internal iterator, accessed by C<each>,
1670 C<keys>, and C<values>.  The iterator is implicitly reset when C<each> has
1671 reached the end as just described; it can be explicitly reset by calling
1672 C<keys> or C<values> on the hash or array.  If you add or delete a hash's
1673 elements while iterating over it, entries may be skipped or duplicated--so
1674 don't do that.  Exception: In the current implementation, it is always safe
1675 to delete the item most recently returned by C<each()>, so the following
1676 code works properly:
1677
1678         while (($key, $value) = each %hash) {
1679           print $key, "\n";
1680           delete $hash{$key};   # This is safe
1681         }
1682
1683 This prints out your environment like the printenv(1) program,
1684 but in a different order:
1685
1686     while (($key,$value) = each %ENV) {
1687         print "$key=$value\n";
1688     }
1689
1690 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1691 reference to an unblessed hash or array.  The argument will be dereferenced
1692 automatically.  This aspect of C<each> is considered highly experimental.
1693 The exact behaviour may change in a future version of Perl.
1694
1695     while (($key,$value) = each $hashref) { ... }
1696
1697 As of Perl 5.18 you can use a bare C<each> in a C<while> loop,
1698 which will set C<$_> on every iteration.
1699
1700     while(each %ENV) {
1701         print "$_=$ENV{$_}\n";
1702     }
1703
1704 To avoid confusing would-be users of your code who are running earlier
1705 versions of Perl with mysterious syntax errors, put this sort of thing at
1706 the top of your file to signal that your code will work I<only> on Perls of
1707 a recent vintage:
1708
1709     use 5.012;  # so keys/values/each work on arrays
1710     use 5.014;  # so keys/values/each work on scalars (experimental)
1711     use 5.018;  # so each assigns to $_ in a lone while test
1712
1713 See also C<keys>, C<values>, and C<sort>.
1714
1715 =item eof FILEHANDLE
1716 X<eof>
1717 X<end of file>
1718 X<end-of-file>
1719
1720 =item eof ()
1721
1722 =item eof
1723
1724 =for Pod::Functions test a filehandle for its end
1725
1726 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1727 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1728 gives the real filehandle.  (Note that this function actually
1729 reads a character and then C<ungetc>s it, so isn't useful in an
1730 interactive context.)  Do not read from a terminal file (or call
1731 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1732 as terminals may lose the end-of-file condition if you do.
1733
1734 An C<eof> without an argument uses the last file read.  Using C<eof()>
1735 with empty parentheses is different.  It refers to the pseudo file
1736 formed from the files listed on the command line and accessed via the
1737 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1738 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1739 used will cause C<@ARGV> to be examined to determine if input is
1740 available.   Similarly, an C<eof()> after C<< <> >> has returned
1741 end-of-file will assume you are processing another C<@ARGV> list,
1742 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1743 see L<perlop/"I/O Operators">.
1744
1745 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1746 detect the end of each file, whereas C<eof()> will detect the end 
1747 of the very last file only.  Examples:
1748
1749     # reset line numbering on each input file
1750     while (<>) {
1751         next if /^\s*#/;  # skip comments
1752         print "$.\t$_";
1753     } continue {
1754         close ARGV if eof;  # Not eof()!
1755     }
1756
1757     # insert dashes just before last line of last file
1758     while (<>) {
1759         if (eof()) {  # check for end of last file
1760             print "--------------\n";
1761         }
1762         print;
1763         last if eof();     # needed if we're reading from a terminal
1764     }
1765
1766 Practical hint: you almost never need to use C<eof> in Perl, because the
1767 input operators typically return C<undef> when they run out of data or 
1768 encounter an error.
1769
1770 =item eval EXPR
1771 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1772 X<error, handling> X<exception, handling>
1773
1774 =item eval BLOCK
1775
1776 =item eval
1777
1778 =for Pod::Functions catch exceptions or compile and run code
1779
1780 In the first form, the return value of EXPR is parsed and executed as if it
1781 were a little Perl program.  The value of the expression (which is itself
1782 determined within scalar context) is first parsed, and if there were no
1783 errors, executed as a block within the lexical context of the current Perl
1784 program.  This means, that in particular, any outer lexical variables are
1785 visible to it, and any package variable settings or subroutine and format
1786 definitions remain afterwards.
1787
1788 Note that the value is parsed every time the C<eval> executes.
1789 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1790 delay parsing and subsequent execution of the text of EXPR until run time.
1791
1792 If the C<unicode_eval> feature is enabled (which is the default under a
1793 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1794 characters, so C<use utf8> declarations have no effect, and source filters
1795 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1796 will sometimes be treated as characters and sometimes as bytes, depending
1797 on the internal encoding, and source filters activated within the C<eval>
1798 exhibit the erratic, but historical, behaviour of affecting some outer file
1799 scope that is still compiling.  See also the L</evalbytes> keyword, which
1800 always treats its input as a byte stream and works properly with source
1801 filters, and the L<feature> pragma.
1802
1803 In the second form, the code within the BLOCK is parsed only once--at the
1804 same time the code surrounding the C<eval> itself was parsed--and executed
1805 within the context of the current Perl program.  This form is typically
1806 used to trap exceptions more efficiently than the first (see below), while
1807 also providing the benefit of checking the code within BLOCK at compile
1808 time.
1809
1810 The final semicolon, if any, may be omitted from the value of EXPR or within
1811 the BLOCK.
1812
1813 In both forms, the value returned is the value of the last expression
1814 evaluated inside the mini-program; a return statement may be also used, just
1815 as with subroutines.  The expression providing the return value is evaluated
1816 in void, scalar, or list context, depending on the context of the C<eval> 
1817 itself.  See L</wantarray> for more on how the evaluation context can be 
1818 determined.
1819
1820 If there is a syntax error or runtime error, or a C<die> statement is
1821 executed, C<eval> returns C<undef> in scalar context
1822 or an empty list in list context, and C<$@> is set to the error
1823 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1824 in list context for syntax errors, but not for runtime errors.)
1825 If there was no error, C<$@> is set to the empty string.  A
1826 control flow operator like C<last> or C<goto> can bypass the setting of
1827 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1828 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1829 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1830 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1831 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1832
1833 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1834 determining whether a particular feature (such as C<socket> or C<symlink>)
1835 is implemented.  It is also Perl's exception-trapping mechanism, where
1836 the die operator is used to raise exceptions.
1837
1838 If you want to trap errors when loading an XS module, some problems with
1839 the binary interface (such as Perl version skew) may be fatal even with
1840 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1841
1842 If the code to be executed doesn't vary, you may use the eval-BLOCK
1843 form to trap run-time errors without incurring the penalty of
1844 recompiling each time.  The error, if any, is still returned in C<$@>.
1845 Examples:
1846
1847     # make divide-by-zero nonfatal
1848     eval { $answer = $a / $b; }; warn $@ if $@;
1849
1850     # same thing, but less efficient
1851     eval '$answer = $a / $b'; warn $@ if $@;
1852
1853     # a compile-time error
1854     eval { $answer = }; # WRONG
1855
1856     # a run-time error
1857     eval '$answer =';   # sets $@
1858
1859 Using the C<eval{}> form as an exception trap in libraries does have some
1860 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1861 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1862 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1863 as this example shows:
1864
1865     # a private exception trap for divide-by-zero
1866     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1867     warn $@ if $@;
1868
1869 This is especially significant, given that C<__DIE__> hooks can call
1870 C<die> again, which has the effect of changing their error messages:
1871
1872     # __DIE__ hooks may modify error messages
1873     {
1874        local $SIG{'__DIE__'} =
1875               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1876        eval { die "foo lives here" };
1877        print $@ if $@;                # prints "bar lives here"
1878     }
1879
1880 Because this promotes action at a distance, this counterintuitive behavior
1881 may be fixed in a future release.
1882
1883 With an C<eval>, you should be especially careful to remember what's
1884 being looked at when:
1885
1886     eval $x;        # CASE 1
1887     eval "$x";      # CASE 2
1888
1889     eval '$x';      # CASE 3
1890     eval { $x };    # CASE 4
1891
1892     eval "\$$x++";  # CASE 5
1893     $$x++;          # CASE 6
1894
1895 Cases 1 and 2 above behave identically: they run the code contained in
1896 the variable $x.  (Although case 2 has misleading double quotes making
1897 the reader wonder what else might be happening (nothing is).)  Cases 3
1898 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1899 does nothing but return the value of $x.  (Case 4 is preferred for
1900 purely visual reasons, but it also has the advantage of compiling at
1901 compile-time instead of at run-time.)  Case 5 is a place where
1902 normally you I<would> like to use double quotes, except that in this
1903 particular situation, you can just use symbolic references instead, as
1904 in case 6.
1905
1906 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1907 of localized variables, which means that for your code to run on older
1908 versions, a temporary is required if you want to mask some but not all
1909 errors:
1910
1911     # alter $@ on nefarious repugnancy only
1912     {
1913        my $e;
1914        {
1915          local $@; # protect existing $@
1916          eval { test_repugnancy() };
1917          # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1918          $@ =~ /nefarious/ and $e = $@;
1919        }
1920        die $e if defined $e
1921     }
1922
1923 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1924 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1925
1926 An C<eval ''> executed within a subroutine defined
1927 in the C<DB> package doesn't see the usual
1928 surrounding lexical scope, but rather the scope of the first non-DB piece
1929 of code that called it.  You don't normally need to worry about this unless
1930 you are writing a Perl debugger.
1931
1932 =item evalbytes EXPR
1933 X<evalbytes>
1934
1935 =item evalbytes
1936
1937 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
1938
1939 This function is like L</eval> with a string argument, except it always
1940 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1941 string containing characters whose ordinal value exceeds 255 results in an
1942 error.  Source filters activated within the evaluated code apply to the
1943 code itself.
1944
1945 This function is only available under the C<evalbytes> feature, a
1946 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1947 L<feature> for more information.
1948
1949 =item exec LIST
1950 X<exec> X<execute>
1951
1952 =item exec PROGRAM LIST
1953
1954 =for Pod::Functions abandon this program to run another
1955
1956 The C<exec> function executes a system command I<and never returns>;
1957 use C<system> instead of C<exec> if you want it to return.  It fails and
1958 returns false only if the command does not exist I<and> it is executed
1959 directly instead of via your system's command shell (see below).
1960
1961 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1962 warns you if C<exec> is called in void context and if there is a following
1963 statement that isn't C<die>, C<warn>, or C<exit> (if C<-w> is set--but
1964 you always do that, right?).  If you I<really> want to follow an C<exec>
1965 with some other statement, you can use one of these styles to avoid the warning:
1966
1967     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1968     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1969
1970 If there is more than one argument in LIST, or if LIST is an array
1971 with more than one value, calls execvp(3) with the arguments in LIST.
1972 If there is only one scalar argument or an array with one element in it,
1973 the argument is checked for shell metacharacters, and if there are any,
1974 the entire argument is passed to the system's command shell for parsing
1975 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1976 If there are no shell metacharacters in the argument, it is split into
1977 words and passed directly to C<execvp>, which is more efficient.
1978 Examples:
1979
1980     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1981     exec "sort $outfile | uniq";
1982
1983 If you don't really want to execute the first argument, but want to lie
1984 to the program you are executing about its own name, you can specify
1985 the program you actually want to run as an "indirect object" (without a
1986 comma) in front of the LIST.  (This always forces interpretation of the
1987 LIST as a multivalued list, even if there is only a single scalar in
1988 the list.)  Example:
1989
1990     $shell = '/bin/csh';
1991     exec $shell '-sh';    # pretend it's a login shell
1992
1993 or, more directly,
1994
1995     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1996
1997 When the arguments get executed via the system shell, results are
1998 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1999 for details.
2000
2001 Using an indirect object with C<exec> or C<system> is also more
2002 secure.  This usage (which also works fine with system()) forces
2003 interpretation of the arguments as a multivalued list, even if the
2004 list had just one argument.  That way you're safe from the shell
2005 expanding wildcards or splitting up words with whitespace in them.
2006
2007     @args = ( "echo surprise" );
2008
2009     exec @args;               # subject to shell escapes
2010                                 # if @args == 1
2011     exec { $args[0] } @args;  # safe even with one-arg list
2012
2013 The first version, the one without the indirect object, ran the I<echo>
2014 program, passing it C<"surprise"> an argument.  The second version didn't;
2015 it tried to run a program named I<"echo surprise">, didn't find it, and set
2016 C<$?> to a non-zero value indicating failure.
2017
2018 Perl attempts to flush all files opened for output before the exec,
2019 but this may not be supported on some platforms (see L<perlport>).
2020 To be safe, you may need to set C<$|> ($AUTOFLUSH in English) or
2021 call the C<autoflush()> method of C<IO::Handle> on any open handles
2022 to avoid lost output.
2023
2024 Note that C<exec> will not call your C<END> blocks, nor will it invoke
2025 C<DESTROY> methods on your objects.
2026
2027 Portability issues: L<perlport/exec>.
2028
2029 =item exists EXPR
2030 X<exists> X<autovivification>
2031
2032 =for Pod::Functions test whether a hash key is present
2033
2034 Given an expression that specifies an element of a hash, returns true if the
2035 specified element in the hash has ever been initialized, even if the
2036 corresponding value is undefined.
2037
2038     print "Exists\n"    if exists $hash{$key};
2039     print "Defined\n"   if defined $hash{$key};
2040     print "True\n"      if $hash{$key};
2041
2042 exists may also be called on array elements, but its behavior is much less
2043 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
2044 that calling exists on array values is deprecated and likely to be removed in
2045 a future version of Perl.
2046
2047     print "Exists\n"    if exists $array[$index];
2048     print "Defined\n"   if defined $array[$index];
2049     print "True\n"      if $array[$index];
2050
2051 A hash or array element can be true only if it's defined and defined only if
2052 it exists, but the reverse doesn't necessarily hold true.
2053
2054 Given an expression that specifies the name of a subroutine,
2055 returns true if the specified subroutine has ever been declared, even
2056 if it is undefined.  Mentioning a subroutine name for exists or defined
2057 does not count as declaring it.  Note that a subroutine that does not
2058 exist may still be callable: its package may have an C<AUTOLOAD>
2059 method that makes it spring into existence the first time that it is
2060 called; see L<perlsub>.
2061
2062     print "Exists\n"  if exists &subroutine;
2063     print "Defined\n" if defined &subroutine;
2064
2065 Note that the EXPR can be arbitrarily complicated as long as the final
2066 operation is a hash or array key lookup or subroutine name:
2067
2068     if (exists $ref->{A}->{B}->{$key})  { }
2069     if (exists $hash{A}{B}{$key})       { }
2070
2071     if (exists $ref->{A}->{B}->[$ix])   { }
2072     if (exists $hash{A}{B}[$ix])        { }
2073
2074     if (exists &{$ref->{A}{B}{$key}})   { }
2075
2076 Although the most deeply nested array or hash element will not spring into
2077 existence just because its existence was tested, any intervening ones will.
2078 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2079 into existence due to the existence test for the $key element above.
2080 This happens anywhere the arrow operator is used, including even here:
2081
2082     undef $ref;
2083     if (exists $ref->{"Some key"})    { }
2084     print $ref;  # prints HASH(0x80d3d5c)
2085
2086 This surprising autovivification in what does not at first--or even
2087 second--glance appear to be an lvalue context may be fixed in a future
2088 release.
2089
2090 Use of a subroutine call, rather than a subroutine name, as an argument
2091 to exists() is an error.
2092
2093     exists &sub;    # OK
2094     exists &sub();  # Error
2095
2096 =item exit EXPR
2097 X<exit> X<terminate> X<abort>
2098
2099 =item exit
2100
2101 =for Pod::Functions terminate this program
2102
2103 Evaluates EXPR and exits immediately with that value.    Example:
2104
2105     $ans = <STDIN>;
2106     exit 0 if $ans =~ /^[Xx]/;
2107
2108 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
2109 universally recognized values for EXPR are C<0> for success and C<1>
2110 for error; other values are subject to interpretation depending on the
2111 environment in which the Perl program is running.  For example, exiting
2112 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2113 the mailer to return the item undelivered, but that's not true everywhere.
2114
2115 Don't use C<exit> to abort a subroutine if there's any chance that
2116 someone might want to trap whatever error happened.  Use C<die> instead,
2117 which can be trapped by an C<eval>.
2118
2119 The exit() function does not always exit immediately.  It calls any
2120 defined C<END> routines first, but these C<END> routines may not
2121 themselves abort the exit.  Likewise any object destructors that need to
2122 be called are called before the real exit.  C<END> routines and destructors
2123 can change the exit status by modifying C<$?>.  If this is a problem, you
2124 can call C<POSIX::_exit($status)> to avoid END and destructor processing.
2125 See L<perlmod> for details.
2126
2127 Portability issues: L<perlport/exit>.
2128
2129 =item exp EXPR
2130 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2131
2132 =item exp
2133
2134 =for Pod::Functions raise I<e> to a power
2135
2136 Returns I<e> (the natural logarithm base) to the power of EXPR.
2137 If EXPR is omitted, gives C<exp($_)>.
2138
2139 =item fc EXPR
2140 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2141
2142 =item fc
2143
2144 =for Pod::Functions +fc return casefolded version of a string
2145
2146 Returns the casefolded version of EXPR.  This is the internal function
2147 implementing the C<\F> escape in double-quoted strings.
2148
2149 Casefolding is the process of mapping strings to a form where case
2150 differences are erased; comparing two strings in their casefolded
2151 form is effectively a way of asking if two strings are equal,
2152 regardless of case.
2153
2154 Roughly, if you ever found yourself writing this
2155
2156     lc($this) eq lc($that)    # Wrong!
2157         # or
2158     uc($this) eq uc($that)    # Also wrong!
2159         # or
2160     $this =~ /^\Q$that\E\z/i  # Right!
2161
2162 Now you can write
2163
2164     fc($this) eq fc($that)
2165
2166 And get the correct results.
2167
2168 Perl only implements the full form of casefolding,
2169 but you can access the simple folds using L<Unicode::UCD/casefold()> and
2170 L<Unicode::UCD/prop_invmap()>.
2171 For further information on casefolding, refer to
2172 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2173 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2174 available at L<http://www.unicode.org/versions/latest/>, as well as the
2175 Case Charts available at L<http://www.unicode.org/charts/case/>.
2176
2177 If EXPR is omitted, uses C<$_>.
2178
2179 This function behaves the same way under various pragma, such as within
2180 S<C<"use feature 'unicode_strings">>, as L</lc> does, with the single
2181 exception of C<fc> of LATIN CAPITAL LETTER SHARP S (U+1E9E) within the
2182 scope of S<C<use locale>>.  The foldcase of this character would
2183 normally be C<"ss">, but as explained in the L</lc> section, case
2184 changes that cross the 255/256 boundary are problematic under locales,
2185 and are hence prohibited.  Therefore, this function under locale returns
2186 instead the string C<"\x{17F}\x{17F}">, which is the LATIN SMALL LETTER
2187 LONG S.  Since that character itself folds to C<"s">, the string of two
2188 of them together should be equivalent to a single U+1E9E when foldcased.
2189
2190 While the Unicode Standard defines two additional forms of casefolding,
2191 one for Turkic languages and one that never maps one character into multiple
2192 characters, these are not provided by the Perl core; However, the CPAN module
2193 C<Unicode::Casing> may be used to provide an implementation.
2194
2195 This keyword is available only when the C<"fc"> feature is enabled,
2196 or when prefixed with C<CORE::>; See L<feature>. Alternately,
2197 include a C<use v5.16> or later to the current scope.
2198
2199 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2200 X<fcntl>
2201
2202 =for Pod::Functions file control system call
2203
2204 Implements the fcntl(2) function.  You'll probably have to say
2205
2206     use Fcntl;
2207
2208 first to get the correct constant definitions.  Argument processing and
2209 value returned work just like C<ioctl> below.
2210 For example:
2211
2212     use Fcntl;
2213     fcntl($filehandle, F_GETFL, $packed_return_buffer)
2214         or die "can't fcntl F_GETFL: $!";
2215
2216 You don't have to check for C<defined> on the return from C<fcntl>.
2217 Like C<ioctl>, it maps a C<0> return from the system call into
2218 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
2219 in numeric context.  It is also exempt from the normal B<-w> warnings
2220 on improper numeric conversions.
2221
2222 Note that C<fcntl> raises an exception if used on a machine that
2223 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2224 manpage to learn what functions are available on your system.
2225
2226 Here's an example of setting a filehandle named C<REMOTE> to be
2227 non-blocking at the system level.  You'll have to negotiate C<$|>
2228 on your own, though.
2229
2230     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2231
2232     $flags = fcntl(REMOTE, F_GETFL, 0)
2233                 or die "Can't get flags for the socket: $!\n";
2234
2235     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2236                 or die "Can't set flags for the socket: $!\n";
2237
2238 Portability issues: L<perlport/fcntl>.
2239
2240 =item __FILE__
2241 X<__FILE__>
2242
2243 =for Pod::Functions the name of the current source file
2244
2245 A special token that returns the name of the file in which it occurs.
2246
2247 =item fileno FILEHANDLE
2248 X<fileno>
2249
2250 =for Pod::Functions return file descriptor from filehandle
2251
2252 Returns the file descriptor for a filehandle, or undefined if the
2253 filehandle is not open.  If there is no real file descriptor at the OS
2254 level, as can happen with filehandles connected to memory objects via
2255 C<open> with a reference for the third argument, -1 is returned.
2256
2257 This is mainly useful for constructing
2258 bitmaps for C<select> and low-level POSIX tty-handling operations.
2259 If FILEHANDLE is an expression, the value is taken as an indirect
2260 filehandle, generally its name.
2261
2262 You can use this to find out whether two handles refer to the
2263 same underlying descriptor:
2264
2265     if (fileno(THIS) != -1 && fileno(THIS) == fileno(THAT)) {
2266         print "THIS and THAT are dups\n";
2267     } elsif (fileno(THIS) != -1 && fileno(THAT) != -1) {
2268         print "THIS and THAT have different underlying file descriptors\n";
2269     } else {
2270         print "At least one of THIS and THAT does not have a real file descriptor\n";
2271     }
2272
2273 =item flock FILEHANDLE,OPERATION
2274 X<flock> X<lock> X<locking>
2275
2276 =for Pod::Functions lock an entire file with an advisory lock
2277
2278 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2279 for success, false on failure.  Produces a fatal error if used on a
2280 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2281 C<flock> is Perl's portable file-locking interface, although it locks
2282 entire files only, not records.
2283
2284 Two potentially non-obvious but traditional C<flock> semantics are
2285 that it waits indefinitely until the lock is granted, and that its locks
2286 are B<merely advisory>.  Such discretionary locks are more flexible, but
2287 offer fewer guarantees.  This means that programs that do not also use
2288 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2289 your port's specific documentation, and your system-specific local manpages
2290 for details.  It's best to assume traditional behavior if you're writing
2291 portable programs.  (But if you're not, you should as always feel perfectly
2292 free to write for your own system's idiosyncrasies (sometimes called
2293 "features").  Slavish adherence to portability concerns shouldn't get
2294 in the way of your getting your job done.)
2295
2296 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2297 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2298 you can use the symbolic names if you import them from the L<Fcntl> module,
2299 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2300 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2301 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2302 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2303 waiting for the lock; check the return status to see if you got it.
2304
2305 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2306 before locking or unlocking it.
2307
2308 Note that the emulation built with lockf(3) doesn't provide shared
2309 locks, and it requires that FILEHANDLE be open with write intent.  These
2310 are the semantics that lockf(3) implements.  Most if not all systems
2311 implement lockf(3) in terms of fcntl(2) locking, though, so the
2312 differing semantics shouldn't bite too many people.
2313
2314 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2315 be open with read intent to use LOCK_SH and requires that it be open
2316 with write intent to use LOCK_EX.
2317
2318 Note also that some versions of C<flock> cannot lock things over the
2319 network; you would need to use the more system-specific C<fcntl> for
2320 that.  If you like you can force Perl to ignore your system's flock(2)
2321 function, and so provide its own fcntl(2)-based emulation, by passing
2322 the switch C<-Ud_flock> to the F<Configure> program when you configure
2323 and build a new Perl.
2324
2325 Here's a mailbox appender for BSD systems.
2326
2327     # import LOCK_* and SEEK_END constants
2328     use Fcntl qw(:flock SEEK_END);
2329
2330     sub lock {
2331         my ($fh) = @_;
2332         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2333
2334         # and, in case someone appended while we were waiting...
2335         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2336     }
2337
2338     sub unlock {
2339         my ($fh) = @_;
2340         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2341     }
2342
2343     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2344         or die "Can't open mailbox: $!";
2345
2346     lock($mbox);
2347     print $mbox $msg,"\n\n";
2348     unlock($mbox);
2349
2350 On systems that support a real flock(2), locks are inherited across fork()
2351 calls, whereas those that must resort to the more capricious fcntl(2)
2352 function lose their locks, making it seriously harder to write servers.
2353
2354 See also L<DB_File> for other flock() examples.
2355
2356 Portability issues: L<perlport/flock>.
2357
2358 =item fork
2359 X<fork> X<child> X<parent>
2360
2361 =for Pod::Functions create a new process just like this one
2362
2363 Does a fork(2) system call to create a new process running the
2364 same program at the same point.  It returns the child pid to the
2365 parent process, C<0> to the child process, or C<undef> if the fork is
2366 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2367 are shared, while everything else is copied.  On most systems supporting
2368 fork(), great care has gone into making it extremely efficient (for
2369 example, using copy-on-write technology on data pages), making it the
2370 dominant paradigm for multitasking over the last few decades.
2371
2372 Perl attempts to flush all files opened for
2373 output before forking the child process, but this may not be supported
2374 on some platforms (see L<perlport>).  To be safe, you may need to set
2375 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2376 C<IO::Handle> on any open handles to avoid duplicate output.
2377
2378 If you C<fork> without ever waiting on your children, you will
2379 accumulate zombies.  On some systems, you can avoid this by setting
2380 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2381 forking and reaping moribund children.
2382
2383 Note that if your forked child inherits system file descriptors like
2384 STDIN and STDOUT that are actually connected by a pipe or socket, even
2385 if you exit, then the remote server (such as, say, a CGI script or a
2386 backgrounded job launched from a remote shell) won't think you're done.
2387 You should reopen those to F</dev/null> if it's any issue.
2388
2389 On some platforms such as Windows, where the fork() system call is not available,
2390 Perl can be built to emulate fork() in the Perl interpreter.
2391 The emulation is designed, at the level of the Perl program,
2392 to be as compatible as possible with the "Unix" fork().
2393 However it has limitations that have to be considered in code intended to be portable.
2394 See L<perlfork> for more details.
2395
2396 Portability issues: L<perlport/fork>.
2397
2398 =item format
2399 X<format>
2400
2401 =for Pod::Functions declare a picture format with use by the write() function
2402
2403 Declare a picture format for use by the C<write> function.  For
2404 example:
2405
2406     format Something =
2407         Test: @<<<<<<<< @||||| @>>>>>
2408               $str,     $%,    '$' . int($num)
2409     .
2410
2411     $str = "widget";
2412     $num = $cost/$quantity;
2413     $~ = 'Something';
2414     write;
2415
2416 See L<perlform> for many details and examples.
2417
2418 =item formline PICTURE,LIST
2419 X<formline>
2420
2421 =for Pod::Functions internal function used for formats
2422
2423 This is an internal function used by C<format>s, though you may call it,
2424 too.  It formats (see L<perlform>) a list of values according to the
2425 contents of PICTURE, placing the output into the format output
2426 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2427 Eventually, when a C<write> is done, the contents of
2428 C<$^A> are written to some filehandle.  You could also read C<$^A>
2429 and then set C<$^A> back to C<"">.  Note that a format typically
2430 does one C<formline> per line of form, but the C<formline> function itself
2431 doesn't care how many newlines are embedded in the PICTURE.  This means
2432 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2433 You may therefore need to use multiple formlines to implement a single
2434 record format, just like the C<format> compiler.
2435
2436 Be careful if you put double quotes around the picture, because an C<@>
2437 character may be taken to mean the beginning of an array name.
2438 C<formline> always returns true.  See L<perlform> for other examples.
2439
2440 If you are trying to use this instead of C<write> to capture the output,
2441 you may find it easier to open a filehandle to a scalar
2442 (C<< open $fh, ">", \$output >>) and write to that instead.
2443
2444 =item getc FILEHANDLE
2445 X<getc> X<getchar> X<character> X<file, read>
2446
2447 =item getc
2448
2449 =for Pod::Functions get the next character from the filehandle
2450
2451 Returns the next character from the input file attached to FILEHANDLE,
2452 or the undefined value at end of file or if there was an error (in
2453 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2454 STDIN.  This is not particularly efficient.  However, it cannot be
2455 used by itself to fetch single characters without waiting for the user
2456 to hit enter.  For that, try something more like:
2457
2458     if ($BSD_STYLE) {
2459         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2460     }
2461     else {
2462         system "stty", '-icanon', 'eol', "\001";
2463     }
2464
2465     $key = getc(STDIN);
2466
2467     if ($BSD_STYLE) {
2468         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2469     }
2470     else {
2471         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2472     }
2473     print "\n";
2474
2475 Determination of whether $BSD_STYLE should be set
2476 is left as an exercise to the reader.
2477
2478 The C<POSIX::getattr> function can do this more portably on
2479 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2480 module from your nearest L<CPAN|http://www.cpan.org> site.
2481
2482 =item getlogin
2483 X<getlogin> X<login>
2484
2485 =for Pod::Functions return who logged in at this tty
2486
2487 This implements the C library function of the same name, which on most
2488 systems returns the current login from F</etc/utmp>, if any.  If it
2489 returns the empty string, use C<getpwuid>.
2490
2491     $login = getlogin || getpwuid($<) || "Kilroy";
2492
2493 Do not consider C<getlogin> for authentication: it is not as
2494 secure as C<getpwuid>.
2495
2496 Portability issues: L<perlport/getlogin>.
2497
2498 =item getpeername SOCKET
2499 X<getpeername> X<peer>
2500
2501 =for Pod::Functions find the other end of a socket connection
2502
2503 Returns the packed sockaddr address of the other end of the SOCKET
2504 connection.
2505
2506     use Socket;
2507     $hersockaddr    = getpeername(SOCK);
2508     ($port, $iaddr) = sockaddr_in($hersockaddr);
2509     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2510     $herstraddr     = inet_ntoa($iaddr);
2511
2512 =item getpgrp PID
2513 X<getpgrp> X<group>
2514
2515 =for Pod::Functions get process group
2516
2517 Returns the current process group for the specified PID.  Use
2518 a PID of C<0> to get the current process group for the
2519 current process.  Will raise an exception if used on a machine that
2520 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2521 group of the current process.  Note that the POSIX version of C<getpgrp>
2522 does not accept a PID argument, so only C<PID==0> is truly portable.
2523
2524 Portability issues: L<perlport/getpgrp>.
2525
2526 =item getppid
2527 X<getppid> X<parent> X<pid>
2528
2529 =for Pod::Functions get parent process ID
2530
2531 Returns the process id of the parent process.
2532
2533 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
2534 around non-POSIX thread semantics the minority of Linux systems (and
2535 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
2536 has since been removed. See the documentation for L<$$|perlvar/$$> for
2537 details.
2538
2539 Portability issues: L<perlport/getppid>.
2540
2541 =item getpriority WHICH,WHO
2542 X<getpriority> X<priority> X<nice>
2543
2544 =for Pod::Functions get current nice value
2545
2546 Returns the current priority for a process, a process group, or a user.
2547 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2548 machine that doesn't implement getpriority(2).
2549
2550 Portability issues: L<perlport/getpriority>.
2551
2552 =item getpwnam NAME
2553 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2554 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2555 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2556 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2557 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2558 X<endnetent> X<endprotoent> X<endservent> 
2559
2560 =for Pod::Functions get passwd record given user login name
2561
2562 =item getgrnam NAME
2563
2564 =for Pod::Functions get group record given group name
2565
2566 =item gethostbyname NAME
2567
2568 =for Pod::Functions get host record given name
2569
2570 =item getnetbyname NAME
2571
2572 =for Pod::Functions get networks record given name
2573
2574 =item getprotobyname NAME
2575
2576 =for Pod::Functions get protocol record given name
2577
2578 =item getpwuid UID
2579
2580 =for Pod::Functions get passwd record given user ID
2581
2582 =item getgrgid GID
2583
2584 =for Pod::Functions get group record given group user ID
2585
2586 =item getservbyname NAME,PROTO
2587
2588 =for Pod::Functions get services record given its name
2589
2590 =item gethostbyaddr ADDR,ADDRTYPE
2591
2592 =for Pod::Functions get host record given its address
2593
2594 =item getnetbyaddr ADDR,ADDRTYPE
2595
2596 =for Pod::Functions get network record given its address
2597
2598 =item getprotobynumber NUMBER
2599
2600 =for Pod::Functions get protocol record numeric protocol
2601
2602 =item getservbyport PORT,PROTO
2603
2604 =for Pod::Functions get services record given numeric port
2605
2606 =item getpwent
2607
2608 =for Pod::Functions get next passwd record
2609
2610 =item getgrent
2611
2612 =for Pod::Functions get next group record
2613
2614 =item gethostent
2615
2616 =for Pod::Functions get next hosts record
2617
2618 =item getnetent
2619
2620 =for Pod::Functions get next networks record
2621
2622 =item getprotoent
2623
2624 =for Pod::Functions get next protocols record
2625
2626 =item getservent
2627
2628 =for Pod::Functions get next services record
2629
2630 =item setpwent
2631
2632 =for Pod::Functions prepare passwd file for use
2633
2634 =item setgrent
2635
2636 =for Pod::Functions prepare group file for use
2637
2638 =item sethostent STAYOPEN
2639
2640 =for Pod::Functions prepare hosts file for use
2641
2642 =item setnetent STAYOPEN
2643
2644 =for Pod::Functions prepare networks file for use
2645
2646 =item setprotoent STAYOPEN
2647
2648 =for Pod::Functions prepare protocols file for use
2649
2650 =item setservent STAYOPEN
2651
2652 =for Pod::Functions prepare services file for use
2653
2654 =item endpwent
2655
2656 =for Pod::Functions be done using passwd file
2657
2658 =item endgrent
2659
2660 =for Pod::Functions be done using group file
2661
2662 =item endhostent
2663
2664 =for Pod::Functions be done using hosts file
2665
2666 =item endnetent
2667
2668 =for Pod::Functions be done using networks file
2669
2670 =item endprotoent
2671
2672 =for Pod::Functions be done using protocols file
2673
2674 =item endservent
2675
2676 =for Pod::Functions be done using services file
2677
2678 These routines are the same as their counterparts in the
2679 system C library.  In list context, the return values from the
2680 various get routines are as follows:
2681
2682     ($name,$passwd,$uid,$gid,
2683        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2684     ($name,$passwd,$gid,$members) = getgr*
2685     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2686     ($name,$aliases,$addrtype,$net) = getnet*
2687     ($name,$aliases,$proto) = getproto*
2688     ($name,$aliases,$port,$proto) = getserv*
2689
2690 (If the entry doesn't exist you get an empty list.)
2691
2692 The exact meaning of the $gcos field varies but it usually contains
2693 the real name of the user (as opposed to the login name) and other
2694 information pertaining to the user.  Beware, however, that in many
2695 system users are able to change this information and therefore it
2696 cannot be trusted and therefore the $gcos is tainted (see
2697 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2698 login shell, are also tainted, for the same reason.
2699
2700 In scalar context, you get the name, unless the function was a
2701 lookup by name, in which case you get the other thing, whatever it is.
2702 (If the entry doesn't exist you get the undefined value.)  For example:
2703
2704     $uid   = getpwnam($name);
2705     $name  = getpwuid($num);
2706     $name  = getpwent();
2707     $gid   = getgrnam($name);
2708     $name  = getgrgid($num);
2709     $name  = getgrent();
2710     #etc.
2711
2712 In I<getpw*()> the fields $quota, $comment, and $expire are special
2713 in that they are unsupported on many systems.  If the
2714 $quota is unsupported, it is an empty scalar.  If it is supported, it
2715 usually encodes the disk quota.  If the $comment field is unsupported,
2716 it is an empty scalar.  If it is supported it usually encodes some
2717 administrative comment about the user.  In some systems the $quota
2718 field may be $change or $age, fields that have to do with password
2719 aging.  In some systems the $comment field may be $class.  The $expire
2720 field, if present, encodes the expiration period of the account or the
2721 password.  For the availability and the exact meaning of these fields
2722 in your system, please consult getpwnam(3) and your system's 
2723 F<pwd.h> file.  You can also find out from within Perl what your
2724 $quota and $comment fields mean and whether you have the $expire field
2725 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2726 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2727 files are supported only if your vendor has implemented them in the
2728 intuitive fashion that calling the regular C library routines gets the
2729 shadow versions if you're running under privilege or if there exists
2730 the shadow(3) functions as found in System V (this includes Solaris
2731 and Linux).  Those systems that implement a proprietary shadow password
2732 facility are unlikely to be supported.
2733
2734 The $members value returned by I<getgr*()> is a space-separated list of
2735 the login names of the members of the group.
2736
2737 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2738 C, it will be returned to you via C<$?> if the function call fails.  The
2739 C<@addrs> value returned by a successful call is a list of raw
2740 addresses returned by the corresponding library call.  In the
2741 Internet domain, each address is four bytes long; you can unpack it
2742 by saying something like:
2743
2744     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2745
2746 The Socket library makes this slightly easier:
2747
2748     use Socket;
2749     $iaddr = inet_aton("127.1"); # or whatever address
2750     $name  = gethostbyaddr($iaddr, AF_INET);
2751
2752     # or going the other way
2753     $straddr = inet_ntoa($iaddr);
2754
2755 In the opposite way, to resolve a hostname to the IP address
2756 you can write this:
2757
2758     use Socket;
2759     $packed_ip = gethostbyname("www.perl.org");
2760     if (defined $packed_ip) {
2761         $ip_address = inet_ntoa($packed_ip);
2762     }
2763
2764 Make sure C<gethostbyname()> is called in SCALAR context and that
2765 its return value is checked for definedness.
2766
2767 The C<getprotobynumber> function, even though it only takes one argument,
2768 has the precedence of a list operator, so beware:
2769
2770     getprotobynumber $number eq 'icmp'   # WRONG
2771     getprotobynumber($number eq 'icmp')  # actually means this
2772     getprotobynumber($number) eq 'icmp'  # better this way
2773
2774 If you get tired of remembering which element of the return list
2775 contains which return value, by-name interfaces are provided
2776 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2777 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2778 and C<User::grent>.  These override the normal built-ins, supplying
2779 versions that return objects with the appropriate names
2780 for each field.  For example:
2781
2782    use File::stat;
2783    use User::pwent;
2784    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2785
2786 Even though it looks as though they're the same method calls (uid),
2787 they aren't, because a C<File::stat> object is different from
2788 a C<User::pwent> object.
2789
2790 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2791
2792 =item getsockname SOCKET
2793 X<getsockname>
2794
2795 =for Pod::Functions retrieve the sockaddr for a given socket
2796
2797 Returns the packed sockaddr address of this end of the SOCKET connection,
2798 in case you don't know the address because you have several different
2799 IPs that the connection might have come in on.
2800
2801     use Socket;
2802     $mysockaddr = getsockname(SOCK);
2803     ($port, $myaddr) = sockaddr_in($mysockaddr);
2804     printf "Connect to %s [%s]\n",
2805        scalar gethostbyaddr($myaddr, AF_INET),
2806        inet_ntoa($myaddr);
2807
2808 =item getsockopt SOCKET,LEVEL,OPTNAME
2809 X<getsockopt>
2810
2811 =for Pod::Functions get socket options on a given socket
2812
2813 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2814 Options may exist at multiple protocol levels depending on the socket
2815 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2816 C<Socket> module) will exist.  To query options at another level the
2817 protocol number of the appropriate protocol controlling the option
2818 should be supplied.  For example, to indicate that an option is to be
2819 interpreted by the TCP protocol, LEVEL should be set to the protocol
2820 number of TCP, which you can get using C<getprotobyname>.
2821
2822 The function returns a packed string representing the requested socket
2823 option, or C<undef> on error, with the reason for the error placed in
2824 C<$!>.  Just what is in the packed string depends on LEVEL and OPTNAME;
2825 consult getsockopt(2) for details.  A common case is that the option is an
2826 integer, in which case the result is a packed integer, which you can decode
2827 using C<unpack> with the C<i> (or C<I>) format.
2828
2829 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2830
2831     use Socket qw(:all);
2832
2833     defined(my $tcp = getprotobyname("tcp"))
2834         or die "Could not determine the protocol number for tcp";
2835     # my $tcp = IPPROTO_TCP; # Alternative
2836     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2837         or die "getsockopt TCP_NODELAY: $!";
2838     my $nodelay = unpack("I", $packed);
2839     print "Nagle's algorithm is turned ",
2840            $nodelay ? "off\n" : "on\n";
2841
2842 Portability issues: L<perlport/getsockopt>.
2843
2844 =item glob EXPR
2845 X<glob> X<wildcard> X<filename, expansion> X<expand>
2846
2847 =item glob
2848
2849 =for Pod::Functions expand filenames using wildcards
2850
2851 In list context, returns a (possibly empty) list of filename expansions on
2852 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
2853 scalar context, glob iterates through such filename expansions, returning
2854 undef when the list is exhausted.  This is the internal function
2855 implementing the C<< <*.c> >> operator, but you can use it directly.  If
2856 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2857 more detail in L<perlop/"I/O Operators">.
2858
2859 Note that C<glob> splits its arguments on whitespace and treats
2860 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2861 matches all files with a F<.c> or F<.h> extension.  The expression
2862 C<glob(".* *")> matches all files in the current working directory.
2863 If you want to glob filenames that might contain whitespace, you'll
2864 have to use extra quotes around the spacey filename to protect it.
2865 For example, to glob filenames that have an C<e> followed by a space
2866 followed by an C<f>, use either of:
2867
2868     @spacies = <"*e f*">;
2869     @spacies = glob '"*e f*"';
2870     @spacies = glob q("*e f*");
2871
2872 If you had to get a variable through, you could do this:
2873
2874     @spacies = glob "'*${var}e f*'";
2875     @spacies = glob qq("*${var}e f*");
2876
2877 If non-empty braces are the only wildcard characters used in the
2878 C<glob>, no filenames are matched, but potentially many strings
2879 are returned.  For example, this produces nine strings, one for
2880 each pairing of fruits and colors:
2881
2882     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2883
2884 This operator is implemented using the standard
2885 C<File::Glob> extension.  See L<File::Glob> for details, including
2886 C<bsd_glob> which does not treat whitespace as a pattern separator.
2887
2888 Portability issues: L<perlport/glob>.
2889
2890 =item gmtime EXPR
2891 X<gmtime> X<UTC> X<Greenwich>
2892
2893 =item gmtime
2894
2895 =for Pod::Functions convert UNIX time into record or string using Greenwich time
2896
2897 Works just like L</localtime> but the returned values are
2898 localized for the standard Greenwich time zone.
2899
2900 Note: When called in list context, $isdst, the last value
2901 returned by gmtime, is always C<0>.  There is no
2902 Daylight Saving Time in GMT.
2903
2904 Portability issues: L<perlport/gmtime>.
2905
2906 =item goto LABEL
2907 X<goto> X<jump> X<jmp>
2908
2909 =item goto EXPR
2910
2911 =item goto &NAME
2912
2913 =for Pod::Functions create spaghetti code
2914
2915 The C<goto-LABEL> form finds the statement labeled with LABEL and
2916 resumes execution there.  It can't be used to get out of a block or
2917 subroutine given to C<sort>.  It can be used to go almost anywhere
2918 else within the dynamic scope, including out of subroutines, but it's
2919 usually better to use some other construct such as C<last> or C<die>.
2920 The author of Perl has never felt the need to use this form of C<goto>
2921 (in Perl, that is; C is another matter).  (The difference is that C
2922 does not offer named loops combined with loop control.  Perl does, and
2923 this replaces most structured uses of C<goto> in other languages.)
2924
2925 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2926 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2927 necessarily recommended if you're optimizing for maintainability:
2928
2929     goto ("FOO", "BAR", "GLARCH")[$i];
2930
2931 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2932 function" rule.  A pair of parentheses following it does not (necessarily)
2933 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2934 Also, unlike most named operators, this has the same precedence as
2935 assignment.
2936
2937 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2938 deprecated and will issue a warning.  Even then, it may not be used to
2939 go into any construct that requires initialization, such as a
2940 subroutine or a C<foreach> loop.  It also can't be used to go into a
2941 construct that is optimized away.
2942
2943 The C<goto-&NAME> form is quite different from the other forms of
2944 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2945 doesn't have the stigma associated with other gotos.  Instead, it
2946 exits the current subroutine (losing any changes set by local()) and
2947 immediately calls in its place the named subroutine using the current
2948 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2949 load another subroutine and then pretend that the other subroutine had
2950 been called in the first place (except that any modifications to C<@_>
2951 in the current subroutine are propagated to the other subroutine.)
2952 After the C<goto>, not even C<caller> will be able to tell that this
2953 routine was called first.
2954
2955 NAME needn't be the name of a subroutine; it can be a scalar variable
2956 containing a code reference or a block that evaluates to a code
2957 reference.
2958
2959 =item grep BLOCK LIST
2960 X<grep>
2961
2962 =item grep EXPR,LIST
2963
2964 =for Pod::Functions locate elements in a list test true against a given criterion
2965
2966 This is similar in spirit to, but not the same as, grep(1) and its
2967 relatives.  In particular, it is not limited to using regular expressions.
2968
2969 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2970 C<$_> to each element) and returns the list value consisting of those
2971 elements for which the expression evaluated to true.  In scalar
2972 context, returns the number of times the expression was true.
2973
2974     @foo = grep(!/^#/, @bar);    # weed out comments
2975
2976 or equivalently,
2977
2978     @foo = grep {!/^#/} @bar;    # weed out comments
2979
2980 Note that C<$_> is an alias to the list value, so it can be used to
2981 modify the elements of the LIST.  While this is useful and supported,
2982 it can cause bizarre results if the elements of LIST are not variables.
2983 Similarly, grep returns aliases into the original list, much as a for
2984 loop's index variable aliases the list elements.  That is, modifying an
2985 element of a list returned by grep (for example, in a C<foreach>, C<map>
2986 or another C<grep>) actually modifies the element in the original list.
2987 This is usually something to be avoided when writing clear code.
2988
2989 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2990 been declared with the deprecated C<my $_> construct)
2991 then, in addition to being locally aliased to
2992 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2993 can't be seen from the outside, avoiding any potential side-effects.
2994
2995 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2996
2997 =item hex EXPR
2998 X<hex> X<hexadecimal>
2999
3000 =item hex
3001
3002 =for Pod::Functions convert a string to a hexadecimal number
3003
3004 Interprets EXPR as a hex string and returns the corresponding value.
3005 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
3006 L</oct>.)  If EXPR is omitted, uses C<$_>.
3007
3008     print hex '0xAf'; # prints '175'
3009     print hex 'aF';   # same
3010
3011 Hex strings may only represent integers.  Strings that would cause
3012 integer overflow trigger a warning.  Leading whitespace is not stripped,
3013 unlike oct().  To present something as hex, look into L</printf>,
3014 L</sprintf>, and L</unpack>.
3015
3016 =item import LIST
3017 X<import>
3018
3019 =for Pod::Functions patch a module's namespace into your own
3020
3021 There is no builtin C<import> function.  It is just an ordinary
3022 method (subroutine) defined (or inherited) by modules that wish to export
3023 names to another module.  The C<use> function calls the C<import> method
3024 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
3025
3026 =item index STR,SUBSTR,POSITION
3027 X<index> X<indexOf> X<InStr>
3028
3029 =item index STR,SUBSTR
3030
3031 =for Pod::Functions find a substring within a string
3032
3033 The index function searches for one string within another, but without
3034 the wildcard-like behavior of a full regular-expression pattern match.
3035 It returns the position of the first occurrence of SUBSTR in STR at
3036 or after POSITION.  If POSITION is omitted, starts searching from the
3037 beginning of the string.  POSITION before the beginning of the string
3038 or after its end is treated as if it were the beginning or the end,
3039 respectively.  POSITION and the return value are based at zero.
3040 If the substring is not found, C<index> returns -1.
3041
3042 =item int EXPR
3043 X<int> X<integer> X<truncate> X<trunc> X<floor>
3044
3045 =item int
3046
3047 =for Pod::Functions get the integer portion of a number
3048
3049 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
3050 You should not use this function for rounding: one because it truncates
3051 towards C<0>, and two because machine representations of floating-point
3052 numbers can sometimes produce counterintuitive results.  For example,
3053 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3054 because it's really more like -268.99999999999994315658 instead.  Usually,
3055 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
3056 functions will serve you better than will int().
3057
3058 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3059 X<ioctl>
3060
3061 =for Pod::Functions system-dependent device control system call
3062
3063 Implements the ioctl(2) function.  You'll probably first have to say
3064
3065     require "sys/ioctl.ph";  # probably in
3066                              # $Config{archlib}/sys/ioctl.ph
3067
3068 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3069 exist or doesn't have the correct definitions you'll have to roll your
3070 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3071 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3072 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3073 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3074 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
3075 has no string value but does have a numeric value, that value will be
3076 passed rather than a pointer to the string value.  To guarantee this to be
3077 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
3078 functions may be needed to manipulate the values of structures used by
3079 C<ioctl>.
3080
3081 The return value of C<ioctl> (and C<fcntl>) is as follows:
3082
3083     if OS returns:      then Perl returns:
3084         -1               undefined value
3085          0              string "0 but true"
3086     anything else           that number
3087
3088 Thus Perl returns true on success and false on failure, yet you can
3089 still easily determine the actual value returned by the operating
3090 system:
3091
3092     $retval = ioctl(...) || -1;
3093     printf "System returned %d\n", $retval;
3094
3095 The special string C<"0 but true"> is exempt from B<-w> complaints
3096 about improper numeric conversions.
3097
3098 Portability issues: L<perlport/ioctl>.
3099
3100 =item join EXPR,LIST
3101 X<join>
3102
3103 =for Pod::Functions join a list into a string using a separator
3104
3105 Joins the separate strings of LIST into a single string with fields
3106 separated by the value of EXPR, and returns that new string.  Example:
3107
3108     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3109
3110 Beware that unlike C<split>, C<join> doesn't take a pattern as its
3111 first argument.  Compare L</split>.
3112
3113 =item keys HASH
3114 X<keys> X<key>
3115
3116 =item keys ARRAY
3117
3118 =item keys EXPR
3119
3120 =for Pod::Functions retrieve list of indices from a hash
3121
3122 Called in list context, returns a list consisting of all the keys of the
3123 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3124 releases prior to 5.12 will produce a syntax error if you try to use an
3125 array argument.  In scalar context, returns the number of keys or indices.
3126
3127 Hash entries are returned in an apparently random order.  The actual random
3128 order is specific to a given hash; the exact same series of operations
3129 on two hashes may result in a different order for each hash. Any insertion
3130 into the hash may change the order, as will any deletion, with the exception
3131 that the most recent key returned by C<each> or C<keys> may be deleted
3132 without changing the order. So long as a given hash is unmodified you may
3133 rely on C<keys>, C<values> and C<each> to repeatedly return the same order
3134 as each other. See L<perlsec/"Algorithmic Complexity Attacks"> for
3135 details on why hash order is randomized. Aside from the guarantees
3136 provided here the exact details of Perl's hash algorithm and the hash
3137 traversal order are subject to change in any release of Perl.
3138
3139 As a side effect, calling keys() resets the internal iterator of the HASH or
3140 ARRAY (see L</each>).  In particular, calling keys() in void context resets
3141 the iterator with no other overhead.
3142
3143 Here is yet another way to print your environment:
3144
3145     @keys = keys %ENV;
3146     @values = values %ENV;
3147     while (@keys) {
3148         print pop(@keys), '=', pop(@values), "\n";
3149     }
3150
3151 or how about sorted by key:
3152
3153     foreach $key (sort(keys %ENV)) {
3154         print $key, '=', $ENV{$key}, "\n";
3155     }
3156
3157 The returned values are copies of the original keys in the hash, so
3158 modifying them will not affect the original hash.  Compare L</values>.
3159
3160 To sort a hash by value, you'll need to use a C<sort> function.
3161 Here's a descending numeric sort of a hash by its values:
3162
3163     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3164         printf "%4d %s\n", $hash{$key}, $key;
3165     }
3166
3167 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
3168 allocated for the given hash.  This can gain you a measure of efficiency if
3169 you know the hash is going to get big.  (This is similar to pre-extending
3170 an array by assigning a larger number to $#array.)  If you say
3171
3172     keys %hash = 200;
3173
3174 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3175 in fact, since it rounds up to the next power of two.  These
3176 buckets will be retained even if you do C<%hash = ()>, use C<undef
3177 %hash> if you want to free the storage while C<%hash> is still in scope.
3178 You can't shrink the number of buckets allocated for the hash using
3179 C<keys> in this way (but you needn't worry about doing this by accident,
3180 as trying has no effect).  C<keys @array> in an lvalue context is a syntax
3181 error.
3182
3183 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
3184 a reference to an unblessed hash or array.  The argument will be
3185 dereferenced automatically.  This aspect of C<keys> is considered highly
3186 experimental.  The exact behaviour may change in a future version of Perl.
3187
3188     for (keys $hashref) { ... }
3189     for (keys $obj->get_arrayref) { ... }
3190
3191 To avoid confusing would-be users of your code who are running earlier
3192 versions of Perl with mysterious syntax errors, put this sort of thing at
3193 the top of your file to signal that your code will work I<only> on Perls of
3194 a recent vintage:
3195
3196     use 5.012;  # so keys/values/each work on arrays
3197     use 5.014;  # so keys/values/each work on scalars (experimental)
3198
3199 See also C<each>, C<values>, and C<sort>.
3200
3201 =item kill SIGNAL, LIST
3202
3203 =item kill SIGNAL
3204 X<kill> X<signal>
3205
3206 =for Pod::Functions send a signal to a process or process group
3207
3208 Sends a signal to a list of processes.  Returns the number of
3209 processes successfully signaled (which is not necessarily the
3210 same as the number actually killed).
3211
3212     $cnt = kill 'HUP', $child1, $child2;
3213     kill 'KILL', @goners;
3214
3215 SIGNAL may be either a signal name (a string) or a signal number.  A signal
3216 name may start with a C<SIG> prefix, thus C<FOO> and C<SIGFOO> refer to the
3217 same signal.  The string form of SIGNAL is recommended for portability because
3218 the same signal may have different numbers in different operating systems.
3219
3220 A list of signal names supported by the current platform can be found in
3221 C<$Config{sig_name}>, which is provided by the C<Config> module. See L<Config>
3222 for more details.
3223
3224 A negative signal name is the same as a negative signal number, killing process
3225 groups instead of processes.  For example, C<kill '-KILL', $pgrp> and
3226 C<kill -9, $pgrp> will send C<SIGKILL> to the entire process group specified. That
3227 means you usually want to use positive not negative signals.
3228
3229 If SIGNAL is either the number 0 or the string C<ZERO> (or C<SIGZZERO>),
3230 no signal is sent to
3231 the process, but C<kill> checks whether it's I<possible> to send a signal to it
3232 (that means, to be brief, that the process is owned by the same user, or we are
3233 the super-user).  This is useful to check that a child process is still
3234 alive (even if only as a zombie) and hasn't changed its UID.  See
3235 L<perlport> for notes on the portability of this construct.
3236
3237 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3238 the operating system.  For example, on POSIX-conforming systems, zero will
3239 signal the current process group, -1 will signal all processes, and any
3240 other negative PROCESS number will act as a negative signal number and
3241 kill the entire process group specified.
3242
3243 If both the SIGNAL and the PROCESS are negative, the results are undefined.
3244 A warning may be produced in a future version.
3245
3246 See L<perlipc/"Signals"> for more details.
3247
3248 On some platforms such as Windows where the fork() system call is not available.
3249 Perl can be built to emulate fork() at the interpreter level.
3250 This emulation has limitations related to kill that have to be considered,
3251 for code running on Windows and in code intended to be portable.
3252
3253 See L<perlfork> for more details.
3254
3255 If there is no I<LIST> of processes, no signal is sent, and the return
3256 value is 0.  This form is sometimes used, however, because it causes
3257 tainting checks to be run.  But see
3258 L<perlsec/Laundering and Detecting Tainted Data>.
3259
3260 Portability issues: L<perlport/kill>.
3261
3262 =item last LABEL
3263 X<last> X<break>
3264
3265 =item last EXPR
3266
3267 =item last
3268
3269 =for Pod::Functions exit a block prematurely
3270
3271 The C<last> command is like the C<break> statement in C (as used in
3272 loops); it immediately exits the loop in question.  If the LABEL is
3273 omitted, the command refers to the innermost enclosing
3274 loop.  The C<last EXPR> form, available starting in Perl
3275 5.18.0, allows a label name to be computed at run time,
3276 and is otherwise identical to C<last LABEL>.  The
3277 C<continue> block, if any, is not executed:
3278
3279     LINE: while (<STDIN>) {
3280         last LINE if /^$/;  # exit when done with header
3281         #...
3282     }
3283
3284 C<last> cannot be used to exit a block that returns a value such as
3285 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3286 a grep() or map() operation.
3287
3288 Note that a block by itself is semantically identical to a loop
3289 that executes once.  Thus C<last> can be used to effect an early
3290 exit out of such a block.
3291
3292 See also L</continue> for an illustration of how C<last>, C<next>, and
3293 C<redo> work.
3294
3295 Unlike most named operators, this has the same precedence as assignment.
3296 It is also exempt from the looks-like-a-function rule, so
3297 C<last ("foo")."bar"> will cause "bar" to be part of the argument to
3298 C<last>.
3299
3300 =item lc EXPR
3301 X<lc> X<lowercase>
3302
3303 =item lc
3304
3305 =for Pod::Functions return lower-case version of a string
3306
3307 Returns a lowercased version of EXPR.  This is the internal function
3308 implementing the C<\L> escape in double-quoted strings.
3309
3310 If EXPR is omitted, uses C<$_>.
3311
3312 What gets returned depends on several factors:
3313
3314 =over
3315
3316 =item If C<use bytes> is in effect:
3317
3318 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
3319 respectively.
3320
3321 =item Otherwise, if C<use locale> (but not C<use locale ':not_characters'>) is in effect:
3322
3323 Respects current LC_CTYPE locale for code points < 256; and uses Unicode
3324 semantics for the remaining code points (this last can only happen if
3325 the UTF8 flag is also set).  See L<perllocale>.
3326
3327 A deficiency in this is that case changes that cross the 255/256
3328 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3329 LETTER SHARP S (U+1E9E) in Unicode semantics is U+00DF (on ASCII
3330 platforms).   But under C<use locale>, the lower case of U+1E9E is
3331 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3332 current locale, and Perl has no way of knowing if that character even
3333 exists in the locale, much less what code point it is.  Perl returns
3334 the input character unchanged, for all instances (and there aren't
3335 many) where the 255/256 boundary would otherwise be crossed.
3336
3337 =item Otherwise, If EXPR has the UTF8 flag set:
3338
3339 Unicode semantics are used for the case change.
3340
3341 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'> is in effect:
3342
3343 Unicode semantics are used for the case change.
3344
3345 =item Otherwise:
3346
3347 ASCII semantics are used for the case change.  The lowercase of any character
3348 outside the ASCII range is the character itself.
3349
3350 =back
3351
3352 =item lcfirst EXPR
3353 X<lcfirst> X<lowercase>
3354
3355 =item lcfirst
3356
3357 =for Pod::Functions return a string with just the next letter in lower case
3358
3359 Returns the value of EXPR with the first character lowercased.  This
3360 is the internal function implementing the C<\l> escape in
3361 double-quoted strings.
3362
3363 If EXPR is omitted, uses C<$_>.
3364
3365 This function behaves the same way under various pragmata, such as in a locale,
3366 as L</lc> does.
3367
3368 =item length EXPR
3369 X<length> X<size>
3370
3371 =item length
3372
3373 =for Pod::Functions return the number of characters in a string
3374
3375 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3376 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3377 C<undef>.
3378
3379 This function cannot be used on an entire array or hash to find out how
3380 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3381 %hash>, respectively.
3382
3383 Like all Perl character operations, length() normally deals in logical
3384 characters, not physical bytes.  For how many bytes a string encoded as
3385 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3386 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3387
3388 =item __LINE__
3389 X<__LINE__>
3390
3391 =for Pod::Functions the current source line number
3392
3393 A special token that compiles to the current line number.
3394
3395 =item link OLDFILE,NEWFILE
3396 X<link>
3397
3398 =for Pod::Functions create a hard link in the filesystem
3399
3400 Creates a new filename linked to the old filename.  Returns true for
3401 success, false otherwise.
3402
3403 Portability issues: L<perlport/link>.
3404
3405 =item listen SOCKET,QUEUESIZE
3406 X<listen>
3407
3408 =for Pod::Functions register your socket as a server
3409
3410 Does the same thing that the listen(2) system call does.  Returns true if
3411 it succeeded, false otherwise.  See the example in
3412 L<perlipc/"Sockets: Client/Server Communication">.
3413
3414 =item local EXPR
3415 X<local>
3416
3417 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
3418
3419 You really probably want to be using C<my> instead, because C<local> isn't
3420 what most people think of as "local".  See
3421 L<perlsub/"Private Variables via my()"> for details.
3422
3423 A local modifies the listed variables to be local to the enclosing
3424 block, file, or eval.  If more than one value is listed, the list must
3425 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3426 for details, including issues with tied arrays and hashes.
3427
3428 The C<delete local EXPR> construct can also be used to localize the deletion
3429 of array/hash elements to the current block.
3430 See L<perlsub/"Localized deletion of elements of composite types">.
3431
3432 =item localtime EXPR
3433 X<localtime> X<ctime>
3434
3435 =item localtime
3436
3437 =for Pod::Functions convert UNIX time into record or string using local time
3438
3439 Converts a time as returned by the time function to a 9-element list
3440 with the time analyzed for the local time zone.  Typically used as
3441 follows:
3442
3443     #  0    1    2     3     4    5     6     7     8
3444     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3445                                                 localtime(time);
3446
3447 All list elements are numeric and come straight out of the C `struct
3448 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3449 of the specified time.
3450
3451 C<$mday> is the day of the month and C<$mon> the month in
3452 the range C<0..11>, with 0 indicating January and 11 indicating December.
3453 This makes it easy to get a month name from a list:
3454
3455     my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
3456     print "$abbr[$mon] $mday";
3457     # $mon=9, $mday=18 gives "Oct 18"
3458
3459 C<$year> contains the number of years since 1900.  To get a 4-digit
3460 year write:
3461
3462     $year += 1900;
3463
3464 To get the last two digits of the year (e.g., "01" in 2001) do:
3465
3466     $year = sprintf("%02d", $year % 100);
3467
3468 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3469 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3470 (or C<0..365> in leap years.)
3471
3472 C<$isdst> is true if the specified time occurs during Daylight Saving
3473 Time, false otherwise.
3474
3475 If EXPR is omitted, C<localtime()> uses the current time (as returned
3476 by time(3)).
3477
3478 In scalar context, C<localtime()> returns the ctime(3) value:
3479
3480     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3481
3482 The format of this scalar value is B<not> locale-dependent
3483 but built into Perl.  For GMT instead of local
3484 time use the L</gmtime> builtin.  See also the
3485 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3486 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3487 and mktime(3) functions.
3488
3489 To get somewhat similar but locale-dependent date strings, set up your
3490 locale environment variables appropriately (please see L<perllocale>) and
3491 try for example:
3492
3493     use POSIX qw(strftime);
3494     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3495     # or for GMT formatted appropriately for your locale:
3496     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3497
3498 Note that the C<%a> and C<%b>, the short forms of the day of the week
3499 and the month of the year, may not necessarily be three characters wide.
3500
3501 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3502 by-name access mechanism to the gmtime() and localtime() functions,
3503 respectively.
3504
3505 For a comprehensive date and time representation look at the
3506 L<DateTime> module on CPAN.
3507
3508 Portability issues: L<perlport/localtime>.
3509
3510 =item lock THING
3511 X<lock>
3512
3513 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
3514
3515 This function places an advisory lock on a shared variable or referenced
3516 object contained in I<THING> until the lock goes out of scope.
3517
3518 The value returned is the scalar itself, if the argument is a scalar, or a
3519 reference, if the argument is a hash, array or subroutine.
3520
3521 lock() is a "weak keyword" : this means that if you've defined a function
3522 by this name (before any calls to it), that function will be called
3523 instead.  If you are not under C<use threads::shared> this does nothing.
3524 See L<threads::shared>.
3525
3526 =item log EXPR
3527 X<log> X<logarithm> X<e> X<ln> X<base>
3528
3529 =item log
3530
3531 =for Pod::Functions retrieve the natural logarithm for a number
3532
3533 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3534 returns the log of C<$_>.  To get the
3535 log of another base, use basic algebra:
3536 The base-N log of a number is equal to the natural log of that number
3537 divided by the natural log of N.  For example:
3538
3539     sub log10 {
3540         my $n = shift;
3541         return log($n)/log(10);
3542     }
3543
3544 See also L</exp> for the inverse operation.
3545
3546 =item lstat FILEHANDLE
3547 X<lstat>
3548
3549 =item lstat EXPR
3550
3551 =item lstat DIRHANDLE
3552
3553 =item lstat
3554
3555 =for Pod::Functions stat a symbolic link
3556
3557 Does the same thing as the C<stat> function (including setting the
3558 special C<_> filehandle) but stats a symbolic link instead of the file
3559 the symbolic link points to.  If symbolic links are unimplemented on
3560 your system, a normal C<stat> is done.  For much more detailed
3561 information, please see the documentation for C<stat>.
3562
3563 If EXPR is omitted, stats C<$_>.
3564
3565 Portability issues: L<perlport/lstat>.
3566
3567 =item m//
3568
3569 =for Pod::Functions match a string with a regular expression pattern
3570
3571 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3572
3573 =item map BLOCK LIST
3574 X<map>
3575
3576 =item map EXPR,LIST
3577
3578 =for Pod::Functions apply a change to a list to get back a new list with the changes
3579
3580 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3581 C<$_> to each element) and returns the list value composed of the
3582 results of each such evaluation.  In scalar context, returns the
3583 total number of elements so generated.  Evaluates BLOCK or EXPR in
3584 list context, so each element of LIST may produce zero, one, or
3585 more elements in the returned value.
3586
3587     @chars = map(chr, @numbers);
3588
3589 translates a list of numbers to the corresponding characters.
3590
3591     my @squares = map { $_ * $_ } @numbers;
3592
3593 translates a list of numbers to their squared values.
3594
3595     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3596
3597 shows that number of returned elements can differ from the number of
3598 input elements.  To omit an element, return an empty list ().
3599 This could also be achieved by writing
3600
3601     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3602
3603 which makes the intention more clear.
3604
3605 Map always returns a list, which can be
3606 assigned to a hash such that the elements
3607 become key/value pairs.  See L<perldata> for more details.
3608
3609     %hash = map { get_a_key_for($_) => $_ } @array;
3610
3611 is just a funny way to write
3612
3613     %hash = ();
3614     foreach (@array) {
3615         $hash{get_a_key_for($_)} = $_;
3616     }
3617
3618 Note that C<$_> is an alias to the list value, so it can be used to
3619 modify the elements of the LIST.  While this is useful and supported,
3620 it can cause bizarre results if the elements of LIST are not variables.
3621 Using a regular C<foreach> loop for this purpose would be clearer in
3622 most cases.  See also L</grep> for an array composed of those items of
3623 the original list for which the BLOCK or EXPR evaluates to true.
3624
3625 If C<$_> is lexical in the scope where the C<map> appears (because it has
3626 been declared with the deprecated C<my $_> construct),
3627 then, in addition to being locally aliased to
3628 the list elements, C<$_> keeps being lexical inside the block; that is, it
3629 can't be seen from the outside, avoiding any potential side-effects.
3630
3631 C<{> starts both hash references and blocks, so C<map { ...> could be either
3632 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
3633 ahead for the closing C<}> it has to take a guess at which it's dealing with
3634 based on what it finds just after the
3635 C<{>.  Usually it gets it right, but if it
3636 doesn't it won't realize something is wrong until it gets to the C<}> and
3637 encounters the missing (or unexpected) comma.  The syntax error will be
3638 reported close to the C<}>, but you'll need to change something near the C<{>
3639 such as using a unary C<+> to give Perl some help:
3640
3641     %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
3642     %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
3643     %hash = map { ("\L$_" => 1) } @array # this also works
3644     %hash = map {  lc($_) => 1  } @array # as does this.
3645     %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
3646
3647     %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)
3648
3649 or to force an anon hash constructor use C<+{>:
3650
3651     @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
3652                                            # comma at end
3653
3654 to get a list of anonymous hashes each with only one entry apiece.
3655
3656 =item mkdir FILENAME,MASK
3657 X<mkdir> X<md> X<directory, create>
3658
3659 =item mkdir FILENAME
3660
3661 =item mkdir
3662
3663 =for Pod::Functions create a directory
3664
3665 Creates the directory specified by FILENAME, with permissions
3666 specified by MASK (as modified by C<umask>).  If it succeeds it
3667 returns true; otherwise it returns false and sets C<$!> (errno).
3668 MASK defaults to 0777 if omitted, and FILENAME defaults
3669 to C<$_> if omitted.
3670
3671 In general, it is better to create directories with a permissive MASK
3672 and let the user modify that with their C<umask> than it is to supply
3673 a restrictive MASK and give the user no way to be more permissive.
3674 The exceptions to this rule are when the file or directory should be
3675 kept private (mail files, for instance).  The perlfunc(1) entry on
3676 C<umask> discusses the choice of MASK in more detail.
3677
3678 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3679 number of trailing slashes.  Some operating and filesystems do not get
3680 this right, so Perl automatically removes all trailing slashes to keep
3681 everyone happy.
3682
3683 To recursively create a directory structure, look at
3684 the C<mkpath> function of the L<File::Path> module.
3685
3686 =item msgctl ID,CMD,ARG
3687 X<msgctl>
3688
3689 =for Pod::Functions SysV IPC message control operations
3690
3691 Calls the System V IPC function msgctl(2).  You'll probably have to say
3692
3693     use IPC::SysV;
3694
3695 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3696 then ARG must be a variable that will hold the returned C<msqid_ds>
3697 structure.  Returns like C<ioctl>: the undefined value for error,
3698 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3699 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3700 C<IPC::Semaphore>.
3701
3702 Portability issues: L<perlport/msgctl>.
3703
3704 =item msgget KEY,FLAGS
3705 X<msgget>
3706
3707 =for Pod::Functions get SysV IPC message queue
3708
3709 Calls the System V IPC function msgget(2).  Returns the message queue
3710 id, or C<undef> on error.  See also
3711 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3712 C<IPC::Msg>.
3713
3714 Portability issues: L<perlport/msgget>.
3715
3716 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3717 X<msgrcv>
3718
3719 =for Pod::Functions receive a SysV IPC message from a message queue
3720
3721 Calls the System V IPC function msgrcv to receive a message from
3722 message queue ID into variable VAR with a maximum message size of
3723 SIZE.  Note that when a message is received, the message type as a
3724 native long integer will be the first thing in VAR, followed by the
3725 actual message.  This packing may be opened with C<unpack("l! a*")>.
3726 Taints the variable.  Returns true if successful, false 
3727 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3728 C<IPC::SysV> and C<IPC::SysV::Msg>.
3729
3730 Portability issues: L<perlport/msgrcv>.
3731
3732 =item msgsnd ID,MSG,FLAGS
3733 X<msgsnd>
3734
3735 =for Pod::Functions send a SysV IPC message to a message queue
3736
3737 Calls the System V IPC function msgsnd to send the message MSG to the
3738 message queue ID.  MSG must begin with the native long integer message
3739 type, be followed by the length of the actual message, and then finally
3740 the message itself.  This kind of packing can be achieved with
3741 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3742 false on error.  See also the C<IPC::SysV>
3743 and C<IPC::SysV::Msg> documentation.
3744
3745 Portability issues: L<perlport/msgsnd>.
3746
3747 =item my EXPR
3748 X<my>
3749
3750 =item my TYPE EXPR
3751
3752 =item my EXPR : ATTRS
3753
3754 =item my TYPE EXPR : ATTRS
3755
3756 =for Pod::Functions declare and assign a local variable (lexical scoping)
3757
3758 A C<my> declares the listed variables to be local (lexically) to the
3759 enclosing block, file, or C<eval>.  If more than one value is listed,
3760 the list must be placed in parentheses.
3761
3762 The exact semantics and interface of TYPE and ATTRS are still
3763 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3764 and attributes are handled using the C<attributes> pragma, or starting
3765 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3766 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3767 L<attributes>, and L<Attribute::Handlers>.
3768
3769 =item next LABEL
3770 X<next> X<continue>
3771
3772 =item next EXPR
3773
3774 =item next
3775
3776 =for Pod::Functions iterate a block prematurely
3777
3778 The C<next> command is like the C<continue> statement in C; it starts
3779 the next iteration of the loop:
3780
3781     LINE: while (<STDIN>) {
3782         next LINE if /^#/;  # discard comments
3783         #...
3784     }
3785
3786 Note that if there were a C<continue> block on the above, it would get
3787 executed even on discarded lines.  If LABEL is omitted, the command
3788 refers to the innermost enclosing loop.  The C<next EXPR> form, available
3789 as of Perl 5.18.0, allows a label name to be computed at run time, being
3790 otherwise identical to C<next LABEL>.
3791
3792 C<next> cannot be used to exit a block which returns a value such as
3793 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3794 a grep() or map() operation.
3795
3796 Note that a block by itself is semantically identical to a loop
3797 that executes once.  Thus C<next> will exit such a block early.
3798
3799 See also L</continue> for an illustration of how C<last>, C<next>, and
3800 C<redo> work.
3801
3802 Unlike most named operators, this has the same precedence as assignment.
3803 It is also exempt from the looks-like-a-function rule, so
3804 C<next ("foo")."bar"> will cause "bar" to be part of the argument to
3805 C<next>.
3806
3807 =item no MODULE VERSION LIST
3808 X<no declarations>
3809 X<unimporting>
3810
3811 =item no MODULE VERSION
3812
3813 =item no MODULE LIST
3814
3815 =item no MODULE
3816
3817 =item no VERSION
3818
3819 =for Pod::Functions unimport some module symbols or semantics at compile time
3820
3821 See the C<use> function, of which C<no> is the opposite.
3822
3823 =item oct EXPR
3824 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3825
3826 =item oct
3827
3828 =for Pod::Functions convert a string to an octal number
3829
3830 Interprets EXPR as an octal string and returns the corresponding
3831 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3832 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3833 binary string.  Leading whitespace is ignored in all three cases.)
3834 The following will handle decimal, binary, octal, and hex in standard
3835 Perl notation:
3836
3837     $val = oct($val) if $val =~ /^0/;
3838
3839 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3840 in octal), use sprintf() or printf():
3841
3842     $dec_perms = (stat("filename"))[2] & 07777;
3843     $oct_perm_str = sprintf "%o", $perms;
3844
3845 The oct() function is commonly used when a string such as C<644> needs
3846 to be converted into a file mode, for example.  Although Perl 
3847 automatically converts strings into numbers as needed, this automatic
3848 conversion assumes base 10.
3849
3850 Leading white space is ignored without warning, as too are any trailing 
3851 non-digits, such as a decimal point (C<oct> only handles non-negative
3852 integers, not negative integers or floating point).
3853
3854 =item open FILEHANDLE,EXPR
3855 X<open> X<pipe> X<file, open> X<fopen>
3856
3857 =item open FILEHANDLE,MODE,EXPR
3858
3859 =item open FILEHANDLE,MODE,EXPR,LIST
3860
3861 =item open FILEHANDLE,MODE,REFERENCE
3862
3863 =item open FILEHANDLE
3864
3865 =for Pod::Functions open a file, pipe, or descriptor
3866
3867 Opens the file whose filename is given by EXPR, and associates it with
3868 FILEHANDLE.
3869
3870 Simple examples to open a file for reading:
3871
3872     open(my $fh, "<", "input.txt") 
3873         or die "cannot open < input.txt: $!";
3874
3875 and for writing:
3876
3877     open(my $fh, ">", "output.txt") 
3878         or die "cannot open > output.txt: $!";
3879
3880 (The following is a comprehensive reference to open(): for a gentler
3881 introduction you may consider L<perlopentut>.)
3882
3883 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3884 new filehandle is autovivified, meaning that the variable is assigned a
3885 reference to a newly allocated anonymous filehandle.  Otherwise if
3886 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3887 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3888 in effect.)
3889
3890 If EXPR is omitted, the global (package) scalar variable of the same
3891 name as the FILEHANDLE contains the filename.  (Note that lexical 
3892 variables--those declared with C<my> or C<state>--will not work for this
3893 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3894 call to open.)
3895
3896 If three (or more) arguments are specified, the open mode (including
3897 optional encoding) in the second argument are distinct from the filename in
3898 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3899 If MODE is C<< > >>, the file is opened for output, with existing files
3900 first being truncated ("clobbered") and nonexisting files newly created.
3901 If MODE is C<<< >> >>>, the file is opened for appending, again being
3902 created if necessary.
3903
3904 You can put a C<+> in front of the C<< > >> or C<< < >> to
3905 indicate that you want both read and write access to the file; thus
3906 C<< +< >> is almost always preferred for read/write updates--the 
3907 C<< +> >> mode would clobber the file first.  You can't usually use
3908 either read-write mode for updating textfiles, since they have
3909 variable-length records.  See the B<-i> switch in L<perlrun> for a
3910 better approach.  The file is created with permissions of C<0666>
3911 modified by the process's C<umask> value.
3912
3913 These various prefixes correspond to the fopen(3) modes of C<r>,
3914 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3915
3916 In the one- and two-argument forms of the call, the mode and filename
3917 should be concatenated (in that order), preferably separated by white
3918 space.  You can--but shouldn't--omit the mode in these forms when that mode
3919 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3920 the filename argument is a known literal.
3921
3922 For three or more arguments if MODE is C<|->, the filename is
3923 interpreted as a command to which output is to be piped, and if MODE
3924 is C<-|>, the filename is interpreted as a command that pipes
3925 output to us.  In the two-argument (and one-argument) form, one should
3926 replace dash (C<->) with the command.
3927 See L<perlipc/"Using open() for IPC"> for more examples of this.
3928 (You are not allowed to C<open> to a command that pipes both in I<and>
3929 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3930 L<perlipc/"Bidirectional Communication with Another Process"> for
3931 alternatives.)
3932
3933 In the form of pipe opens taking three or more arguments, if LIST is specified
3934 (extra arguments after the command name) then LIST becomes arguments
3935 to the command invoked if the platform supports it.  The meaning of
3936 C<open> with more than three arguments for non-pipe modes is not yet
3937 defined, but experimental "layers" may give extra LIST arguments
3938 meaning.
3939
3940 In the two-argument (and one-argument) form, opening C<< <- >> 
3941 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3942
3943 You may (and usually should) use the three-argument form of open to specify
3944 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3945 that affect how the input and output are processed (see L<open> and
3946 L<PerlIO> for more details).  For example:
3947
3948   open(my $fh, "<:encoding(UTF-8)", "filename")
3949     || die "can't open UTF-8 encoded filename: $!";
3950
3951 opens the UTF8-encoded file containing Unicode characters;
3952 see L<perluniintro>.  Note that if layers are specified in the
3953 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3954 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3955 Those layers will also be ignored if you specifying a colon with no name
3956 following it.  In that case the default layer for the operating system
3957 (:raw on Unix, :crlf on Windows) is used.
3958
3959 Open returns nonzero on success, the undefined value otherwise.  If
3960 the C<open> involved a pipe, the return value happens to be the pid of
3961 the subprocess.
3962
3963 If you're running Perl on a system that distinguishes between text
3964 files and binary files, then you should check out L</binmode> for tips
3965 for dealing with this.  The key distinction between systems that need
3966 C<binmode> and those that don't is their text file formats.  Systems
3967 like Unix, Mac OS, and Plan 9, that end lines with a single
3968 character and encode that character in C as C<"\n"> do not
3969 need C<binmode>.  The rest need it.
3970
3971 When opening a file, it's seldom a good idea to continue 
3972 if the request failed, so C<open> is frequently used with
3973 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3974 where you want to format a suitable error message (but there are
3975 modules that can help with that problem)) always check
3976 the return value from opening a file.  
3977
3978 As a special case the three-argument form with a read/write mode and the third
3979 argument being C<undef>:
3980
3981     open(my $tmp, "+>", undef) or die ...
3982
3983 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3984 works for symmetry, but you really should consider writing something
3985 to the temporary file first.  You will need to seek() to do the
3986 reading.
3987
3988 Perl is built using PerlIO by default; Unless you've
3989 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3990 open filehandles directly to Perl scalars via:
3991
3992     open($fh, ">", \$variable) || ..
3993
3994 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3995
3996     close STDOUT;
3997     open(STDOUT, ">", \$variable)
3998         or die "Can't open STDOUT: $!";
3999
4000 General examples:
4001
4002     $ARTICLE = 100;
4003     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
4004     while (<ARTICLE>) {...
4005
4006     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
4007     # if the open fails, output is discarded
4008
4009     open(my $dbase, "+<", "dbase.mine")      # open for update
4010         or die "Can't open 'dbase.mine' for update: $!";
4011
4012     open(my $dbase, "+<dbase.mine")          # ditto
4013         or die "Can't open 'dbase.mine' for update: $!";
4014
4015     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
4016         or die "Can't start caesar: $!";
4017
4018     open(ARTICLE, "caesar <$article |")      # ditto
4019         or die "Can't start caesar: $!";
4020
4021     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
4022         or die "Can't start sort: $!";
4023
4024     # in-memory files
4025     open(MEMORY, ">", \$var)
4026         or die "Can't open memory file: $!";
4027     print MEMORY "foo!\n";              # output will appear in $var
4028
4029     # process argument list of files along with any includes
4030
4031     foreach $file (@ARGV) {
4032         process($file, "fh00");
4033     }
4034
4035     sub process {
4036         my($filename, $input) = @_;
4037         $input++;    # this is a string increment
4038         unless (open($input, "<", $filename)) {
4039             print STDERR "Can't open $filename: $!\n";
4040             return;
4041         }
4042
4043         local $_;
4044         while (<$input>) {    # note use of indirection
4045             if (/^#include "(.*)"/) {
4046                 process($1, $input);
4047                 next;
4048             }
4049             #...          # whatever
4050         }
4051     }
4052
4053 See L<perliol> for detailed info on PerlIO.
4054
4055 You may also, in the Bourne shell tradition, specify an EXPR beginning
4056 with C<< >& >>, in which case the rest of the string is interpreted
4057 as the name of a filehandle (or file descriptor, if numeric) to be
4058 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
4059 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
4060 The mode you specify should match the mode of the original filehandle.
4061 (Duping a filehandle does not take into account any existing contents
4062 of IO buffers.)  If you use the three-argument
4063 form, then you can pass either a
4064 number, the name of a filehandle, or the normal "reference to a glob".
4065
4066 Here is a script that saves, redirects, and restores C<STDOUT> and
4067 C<STDERR> using various methods:
4068
4069     #!/usr/bin/perl
4070     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4071     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
4072
4073     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
4074     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4075
4076     select STDERR; $| = 1;  # make unbuffered
4077     select STDOUT; $| = 1;  # make unbuffered
4078
4079     print STDOUT "stdout 1\n";  # this works for
4080     print STDERR "stderr 1\n";  # subprocesses too
4081
4082     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
4083     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
4084
4085     print STDOUT "stdout 2\n";
4086     print STDERR "stderr 2\n";
4087
4088 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
4089 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
4090 that file descriptor (and not call C<dup(2)>); this is more
4091 parsimonious of file descriptors.  For example:
4092
4093     # open for input, reusing the fileno of $fd
4094     open(FILEHANDLE, "<&=$fd")
4095
4096 or
4097
4098     open(FILEHANDLE, "<&=", $fd)
4099
4100 or
4101
4102     # open for append, using the fileno of OLDFH
4103     open(FH, ">>&=", OLDFH)
4104
4105 or
4106
4107     open(FH, ">>&=OLDFH")
4108
4109 Being parsimonious on filehandles is also useful (besides being
4110 parsimonious) for example when something is dependent on file
4111 descriptors, like for example locking using flock().  If you do just
4112 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
4113 descriptor as B, and therefore flock(A) will not flock(B) nor vice
4114 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
4115 the same underlying system file descriptor.
4116
4117 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
4118 fdopen() to implement the C<=> functionality.  On many Unix systems,
4119 fdopen() fails when file descriptors exceed a certain value, typically 255.
4120 For Perls 5.8.0 and later, PerlIO is (most often) the default.
4121
4122 You can see whether your Perl was built with PerlIO by running C<perl -V>
4123 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
4124 have PerlIO; otherwise you don't.
4125
4126 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
4127 with the one- or two-argument forms of C<open>), 
4128 an implicit C<fork> is done, so C<open> returns twice: in the parent
4129 process it returns the pid
4130 of the child process, and in the child process it returns (a defined) C<0>.
4131 Use C<defined($pid)> or C<//> to determine whether the open was successful.
4132
4133 For example, use either
4134
4135     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
4136
4137 or
4138
4139     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
4140
4141 followed by 
4142
4143     if ($child_pid) {
4144         # am the parent:
4145         # either write TO_KID or else read FROM_KID
4146         ...
4147        waitpid $child_pid, 0;
4148     } else {
4149         # am the child; use STDIN/STDOUT normally
4150         ...
4151         exit;
4152     } 
4153
4154 The filehandle behaves normally for the parent, but I/O to that
4155 filehandle is piped from/to the STDOUT/STDIN of the child process.
4156 In the child process, the filehandle isn't opened--I/O happens from/to
4157 the new STDOUT/STDIN.  Typically this is used like the normal
4158 piped open when you want to exercise more control over just how the
4159 pipe command gets executed, such as when running setuid and
4160 you don't want to have to scan shell commands for metacharacters.
4161
4162 The following blocks are more or less equivalent:
4163
4164     open(FOO, "|tr '[a-z]' '[A-Z]'");
4165     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
4166     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
4167     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
4168
4169     open(FOO, "cat -n '$file'|");
4170     open(FOO, "-|", "cat -n '$file'");
4171     open(FOO, "-|") || exec "cat", "-n", $file;
4172     open(FOO, "-|", "cat", "-n", $file);
4173
4174 The last two examples in each block show the pipe as "list form", which is
4175 not yet supported on all platforms.  A good rule of thumb is that if
4176 your platform has a real C<fork()> (in other words, if your platform is
4177 Unix, including Linux and MacOS X), you can use the list form.  You would 
4178 want to use the list form of the pipe so you can pass literal arguments
4179 to the command without risk of the shell interpreting any shell metacharacters
4180 in them.  However, this also bars you from opening pipes to commands
4181 that intentionally contain shell metacharacters, such as:
4182
4183     open(FOO, "|cat -n | expand -4 | lpr")
4184         // die "Can't open pipeline to lpr: $!";
4185
4186 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
4187
4188 Perl will attempt to flush all files opened for
4189 output before any operation that may do a fork, but this may not be
4190 supported on some platforms (see L<perlport>).  To be safe, you may need
4191 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
4192 of C<IO::Handle> on any open handles.
4193
4194 On systems that support a close-on-exec flag on files, the flag will
4195 be set for the newly opened file descriptor as determined by the value
4196 of C<$^F>.  See L<perlvar/$^F>.
4197
4198 Closing any piped filehandle causes the parent process to wait for the
4199 child to finish, then returns the status value in C<$?> and
4200 C<${^CHILD_ERROR_NATIVE}>.
4201
4202 The filename passed to the one- and two-argument forms of open() will
4203 have leading and trailing whitespace deleted and normal
4204 redirection characters honored.  This property, known as "magic open",
4205 can often be used to good effect.  A user could specify a filename of
4206 F<"rsh cat file |">, or you could change certain filenames as needed:
4207
4208     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
4209     open(FH, $filename) or die "Can't open $filename: $!";
4210
4211 Use the three-argument form to open a file with arbitrary weird characters in it,
4212
4213     open(FOO, "<", $file)
4214         || die "can't open < $file: $!";
4215
4216 otherwise it's necessary to protect any leading and trailing whitespace:
4217
4218     $file =~ s#^(\s)#./$1#;
4219     open(FOO, "< $file\0")
4220         || die "open failed: $!";
4221
4222 (this may not work on some bizarre filesystems).  One should
4223 conscientiously choose between the I<magic> and I<three-argument> form
4224 of open():
4225
4226     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
4227
4228 will allow the user to specify an argument of the form C<"rsh cat file |">,
4229 but will not work on a filename that happens to have a trailing space, while
4230
4231     open(IN, "<", $ARGV[0])
4232         || die "can't open < $ARGV[0]: $!";
4233
4234 will have exactly the opposite restrictions.
4235
4236 If you want a "real" C C<open> (see L<open(2)> on your system), then you
4237 should use the C<sysopen> function, which involves no such magic (but may
4238 use subtly different filemodes than Perl open(), which is mapped to C
4239 fopen()).  This is another way to protect your filenames from
4240 interpretation.  For example:
4241
4242     use IO::Handle;
4243     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
4244         or die "sysopen $path: $!";
4245     $oldfh = select(HANDLE); $| = 1; select($oldfh);
4246     print HANDLE "stuff $$\n";
4247     seek(HANDLE, 0, 0);
4248     print "File contains: ", <HANDLE>;
4249
4250 Using the constructor from the C<IO::Handle> package (or one of its
4251 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
4252 filehandles that have the scope of the variables used to hold them, then
4253 automatically (but silently) close once their reference counts become
4254 zero, typically at scope exit:
4255
4256     use IO::File;
4257     #...
4258     sub read_myfile_munged {
4259         my $ALL = shift;
4260         # or just leave it undef to autoviv
4261         my $handle = IO::File->new;
4262         open($handle, "<", "myfile") or die "myfile: $!";
4263         $first = <$handle>
4264             or return ();     # Automatically closed here.
4265         mung($first) or die "mung failed";  # Or here.
4266         return (first, <$handle>) if $ALL;  # Or here.
4267         return $first;                      # Or here.
4268     }
4269
4270 B<WARNING:> The previous example has a bug because the automatic
4271 close that happens when the refcount on C<handle> reaches zero does not
4272 properly detect and report failures.  I<Always> close the handle
4273 yourself and inspect the return value.
4274
4275     close($handle) 
4276         || warn "close failed: $!";
4277
4278 See L</seek> for some details about mixing reading and writing.
4279
4280 Portability issues: L<perlport/open>.
4281
4282 =item opendir DIRHANDLE,EXPR
4283 X<opendir>
4284
4285 =for Pod::Functions open a directory
4286
4287 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
4288 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
4289 DIRHANDLE may be an expression whose value can be used as an indirect
4290 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
4291 scalar variable (or array or hash element), the variable is assigned a
4292 reference to a new anonymous dirhandle; that is, it's autovivified.
4293 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
4294
4295 See the example at C<readdir>.
4296
4297 =item ord EXPR
4298 X<ord> X<encoding>
4299
4300 =item ord
4301
4302 =for Pod::Functions find a character's numeric representation
4303
4304 Returns the numeric value of the first character of EXPR.
4305 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
4306 (Note I<character>, not byte.)
4307
4308 For the reverse, see L</chr>.
4309 See L<perlunicode> for more about Unicode.
4310
4311 =item our EXPR
4312 X<our> X<global>
4313
4314 =item our TYPE EXPR
4315
4316 =item our EXPR : ATTRS
4317
4318 =item our TYPE EXPR : ATTRS
4319
4320 =for Pod::Functions +5.6.0 declare and assign a package variable (lexical scoping)
4321
4322 C<our> makes a lexical alias to a package variable of the same name in the current
4323 package for use within the current lexical scope.
4324
4325 C<our> has the same scoping rules as C<my> or C<state>, but C<our> only
4326 declares an alias, whereas C<my> or C<state> both declare a variable name and
4327 allocate storage for that name within the current scope.
4328
4329 This means that when C<use strict 'vars'> is in effect, C<our> lets you use
4330 a package variable without qualifying it with the package name, but only within
4331 the lexical scope of the C<our> declaration.  In this way, C<our> differs from
4332 C<use vars>, which allows use of an unqualified name I<only> within the
4333 affected package, but across scopes.
4334
4335 If more than one value is listed, the list must be placed
4336 in parentheses.
4337
4338     our $foo;
4339     our($bar, $baz);
4340
4341 An C<our> declaration declares an alias for a package variable that will be visible
4342 across its entire lexical scope, even across package boundaries.  The
4343 package in which the variable is entered is determined at the point
4344 of the declaration, not at the point of use.  This means the following
4345 behavior holds:
4346
4347     package Foo;
4348     our $bar;      # declares $Foo::bar for rest of lexical scope
4349     $bar = 20;
4350
4351     package Bar;
4352     print $bar;    # prints 20, as it refers to $Foo::bar
4353
4354 Multiple C<our> declarations with the same name in the same lexical
4355 scope are allowed if they are in different packages.  If they happen
4356 to be in the same package, Perl will emit warnings if you have asked
4357 for them, just like multiple C<my> declarations.  Unlike a second
4358 C<my> declaration, which will bind the name to a fresh variable, a
4359 second C<our> declaration in the same package, in the same scope, is
4360 merely redundant.
4361
4362     use warnings;
4363     package Foo;
4364     our $bar;      # declares $Foo::bar for rest of lexical scope
4365     $bar = 20;
4366
4367     package Bar;
4368     our $bar = 30; # declares $Bar::bar for rest of lexical scope
4369     print $bar;    # prints 30
4370
4371     our $bar;      # emits warning but has no other effect
4372     print $bar;    # still prints 30
4373
4374 An C<our> declaration may also have a list of attributes associated
4375 with it.
4376
4377 The exact semantics and interface of TYPE and ATTRS are still
4378 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
4379 and attributes are handled using the C<attributes> pragma, or, starting
4380 from Perl 5.8.0, also via the C<Attribute::Handlers> module.  See
4381 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
4382 L<attributes>, and L<Attribute::Handlers>.
4383
4384 =item pack TEMPLATE,LIST
4385 X<pack>
4386
4387 =for Pod::Functions convert a list into a binary representation
4388
4389 Takes a LIST of values and converts it into a string using the rules
4390 given by the TEMPLATE.  The resulting string is the concatenation of
4391 the converted values.  Typically, each converted value looks
4392 like its machine-level representation.  For example, on 32-bit machines
4393 an integer may be represented by a sequence of 4 bytes, which  will in
4394 Perl be presented as a string that's 4 characters long. 
4395
4396 See L<perlpacktut> for an introduction to this function.
4397
4398 The TEMPLATE is a sequence of characters that give the order and type
4399 of values, as follows:
4400
4401     a  A string with arbitrary binary data, will be null padded.
4402     A  A text (ASCII) string, will be space padded.
4403     Z  A null-terminated (ASCIZ) string, will be null padded.
4404
4405     b  A bit string (ascending bit order inside each byte,
4406        like vec()).
4407     B  A bit string (descending bit order inside each byte).
4408     h  A hex string (low nybble first).
4409     H  A hex string (high nybble first).
4410
4411     c  A signed char (8-bit) value.
4412     C  An unsigned char (octet) value.
4413     W  An unsigned char value (can be greater than 255).
4414
4415     s  A signed short (16-bit) value.
4416     S  An unsigned short value.
4417
4418     l  A signed long (32-bit) value.
4419     L  An unsigned long value.
4420
4421     q  A signed quad (64-bit) value.
4422     Q  An unsigned quad value.
4423          (Quads are available only if your system supports 64-bit
4424           integer values _and_ if Perl has been compiled to support
4425           those.  Raises an exception otherwise.)
4426
4427     i  A signed integer value.
4428     I  A unsigned integer value.
4429          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4430           size depends on what a local C compiler calls 'int'.)
4431
4432     n  An unsigned short (16-bit) in "network" (big-endian) order.
4433     N  An unsigned long (32-bit) in "network" (big-endian) order.
4434     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4435     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4436
4437     j  A Perl internal signed integer value (IV).
4438     J  A Perl internal unsigned integer value (UV).
4439
4440     f  A single-precision float in native format.
4441     d  A double-precision float in native format.
4442
4443     F  A Perl internal floating-point value (NV) in native format
4444     D  A float of long-double precision in native format.
4445          (Long doubles are available only if your system supports
4446           long double values _and_ if Perl has been compiled to
4447           support those.  Raises an exception otherwise.)
4448
4449     p  A pointer to a null-terminated string.
4450     P  A pointer to a structure (fixed-length string).
4451
4452     u  A uuencoded string.
4453     U  A Unicode character number.  Encodes to a character in char-
4454        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4455        byte mode.
4456
4457     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4458        for details).  Its bytes represent an unsigned integer in
4459        base 128, most significant digit first, with as few digits
4460        as possible.  Bit eight (the high bit) is set on each byte
4461        except the last.
4462
4463     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4464     X  Back up a byte.
4465     @  Null-fill or truncate to absolute position, counted from the
4466        start of the innermost ()-group.
4467     .  Null-fill or truncate to absolute position specified by
4468        the value.
4469     (  Start of a ()-group.
4470
4471 One or more modifiers below may optionally follow certain letters in the
4472 TEMPLATE (the second column lists letters for which the modifier is valid):
4473
4474     !   sSlLiI     Forces native (short, long, int) sizes instead
4475                    of fixed (16-/32-bit) sizes.
4476
4477         xX         Make x and X act as alignment commands.
4478
4479         nNvV       Treat integers as signed instead of unsigned.
4480
4481         @.         Specify position as byte offset in the internal
4482                    representation of the packed string.  Efficient
4483                    but dangerous.
4484
4485     >   sSiIlLqQ   Force big-endian byte-order on the type.
4486         jJfFdDpP   (The "big end" touches the construct.)
4487
4488     <   sSiIlLqQ   Force little-endian byte-order on the type.
4489         jJfFdDpP   (The "little end" touches the construct.)
4490
4491 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4492 to force a particular byte-order on all components in that group, 
4493 including all its subgroups.
4494
4495 =begin comment
4496
4497 Larry recalls that the hex and bit string formats (H, h, B, b) were added to
4498 pack for processing data from NASA's Magellan probe. Magellan was in an
4499 elliptical orbit, using the antenna for the radar mapping when close to
4500 Venus and for communicating data back to Earth for the rest of the orbit.
4501 There were two transmission units, but one of these failed, and then the
4502 other developed a fault whereby it would randomly flip the sense of all the
4503 bits. It was easy to automatically detect complete records with the correct
4504 sense, and complete records with all the bits flipped. However, this didn't
4505 recover the records where the sense flipped midway. A colleague of Larry's
4506 was able to pretty much eyeball where the records flipped, so they wrote an
4507 editor named kybble (a pun on the dog food Kibbles 'n Bits) to enable him to
4508 manually correct the records and recover the data. For this purpose pack
4509 gained the hex and bit string format specifiers.
4510
4511 git shows that they were added to perl 3.0 in patch #44 (Jan 1991, commit
4512 27e2fb84680b9cc1), but the patch description makes no mention of their
4513 addition, let alone the story behind them.
4514
4515 =end comment
4516
4517 The following rules apply:
4518
4519 =over 
4520
4521 =item *
4522
4523 Each letter may optionally be followed by a number indicating the repeat
4524 count.  A numeric repeat count may optionally be enclosed in brackets, as
4525 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4526 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4527 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4528 something else, described below.  Supplying a C<*> for the repeat count
4529 instead of a number means to use however many items are left, except for:
4530
4531 =over 
4532
4533 =item * 
4534
4535 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4536
4537 =item * 
4538
4539 <.>, where it means relative to the start of the string.
4540
4541 =item * 
4542
4543 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4544
4545 =back 
4546
4547 One can replace a numeric repeat count with a template letter enclosed in
4548 brackets to use the packed byte length of the bracketed template for the
4549 repeat count.
4550
4551 For example, the template C<x[L]> skips as many bytes as in a packed long,
4552 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4553 variable-expanded) unpacks.  If the template in brackets contains alignment
4554 commands (such as C<x![d]>), its packed length is calculated as if the
4555 start of the template had the maximal possible alignment.
4556
4557 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4558 trailing null byte, so the resulting string is always one byte longer than
4559 the byte length of the item itself.
4560
4561 When used with C<@>, the repeat count represents an offset from the start
4562 of the innermost C<()> group.
4563
4564 When used with C<.>, the repeat count determines the starting position to
4565 calculate the value offset as follows:
4566
4567 =over 
4568
4569 =item *
4570
4571 If the repeat count is C<0>, it's relative to the current position.
4572
4573 =item *
4574
4575 If the repeat count is C<*>, the offset is relative to the start of the
4576 packed string.
4577
4578 =item *
4579
4580 And if it's an integer I<n>, the offset is relative to the start of the
4581 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4582 bigger then the group level.
4583
4584 =back
4585
4586 The repeat count for C<u> is interpreted as the maximal number of bytes
4587 to encode per line of output, with 0, 1 and 2 replaced by 45.  The repeat 
4588 count should not be more than 65.
4589
4590 =item *
4591
4592 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4593 string of length count, padding with nulls or spaces as needed.  When
4594 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4595 after the first null, and C<a> returns data with no stripping at all.
4596
4597 If the value to pack is too long, the result is truncated.  If it's too
4598 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4599 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4600 when the count is 0.
4601
4602 =item *
4603
4604 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4605 Each such format generates 1 bit of the result.  These are typically followed
4606 by a repeat count like C<B8> or C<B64>.
4607
4608 Each result bit is based on the least-significant bit of the corresponding
4609 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4610 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4611
4612 Starting from the beginning of the input string, each 8-tuple
4613 of characters is converted to 1 character of output.  With format C<b>,
4614 the first character of the 8-tuple determines the least-significant bit of a
4615 character; with format C<B>, it determines the most-significant bit of
4616 a character.
4617
4618 If the length of the input string is not evenly divisible by 8, the
4619 remainder is packed as if the input string were padded by null characters
4620 at the end.  Similarly during unpacking, "extra" bits are ignored.
4621
4622 If the input string is longer than needed, remaining characters are ignored.
4623
4624 A C<*> for the repeat count uses all characters of the input field.  
4625 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4626
4627 =item *
4628
4629 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4630 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4631
4632 For each such format, pack() generates 4 bits of result.
4633 With non-alphabetical characters, the result is based on the 4 least-significant
4634 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4635 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4636 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4637 is compatible with the usual hexadecimal digits, so that C<"a"> and
4638 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4639 characters with this format.
4640
4641 Starting from the beginning of the template to pack(), each pair
4642 of characters is converted to 1 character of output.  With format C<h>, the
4643 first character of the pair determines the least-significant nybble of the
4644 output character; with format C<H>, it determines the most-significant
4645 nybble.
4646
4647 If the length of the input string is not even, it behaves as if padded by
4648 a null character at the end.  Similarly, "extra" nybbles are ignored during
4649 unpacking.
4650
4651 If the input string is longer than needed, extra characters are ignored.
4652
4653 A C<*> for the repeat count uses all characters of the input field.  For
4654 unpack(), nybbles are converted to a string of hexadecimal digits.
4655
4656 =item *
4657
4658 The C<p> format packs a pointer to a null-terminated string.  You are
4659 responsible for ensuring that the string is not a temporary value, as that
4660 could potentially get deallocated before you got around to using the packed
4661 result.  The C<P> format packs a pointer to a structure of the size indicated
4662 by the length.  A null pointer is created if the corresponding value for
4663 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4664 unpacks into C<undef>.
4665
4666 If your system has a strange pointer size--meaning a pointer is neither as
4667 big as an int nor as big as a long--it may not be possible to pack or
4668 unpack pointers in big- or little-endian byte order.  Attempting to do
4669 so raises an exception.
4670
4671 =item *
4672
4673 The C</> template character allows packing and unpacking of a sequence of
4674 items where the packed structure contains a packed item count followed by
4675 the packed items themselves.  This is useful when the structure you're
4676 unpacking has encoded the sizes or repeat counts for some of its fields
4677 within the structure itself as separate fields.
4678
4679 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
<