lib/utf8.pm

   1 package utf8;
   2
   3 $utf8::hint_bits = 0x00800000;
   4
   5 our $VERSION = '1.08';
   6
   7 sub import {
   8     $^H |= $utf8::hint_bits;
   9     $enc{caller()} = $_[1] if $_[1];
  10 }
  11
  12 sub unimport {
  13     $^H &= ~$utf8::hint_bits;
  14 }
  15
  16 sub AUTOLOAD {
  17     require "utf8_heavy.pl";
  18     goto &$AUTOLOAD if defined &$AUTOLOAD;
  19     require Carp;
  20     Carp::croak("Undefined subroutine $AUTOLOAD called");
  21 }
  22
  23 1;
  24 __END__
  25
  26 =head1 NAME
  27
  28 utf8 - Perl pragma to enable/disable UTF-8 (or UTF-EBCDIC) in source code
  29
  30 =head1 SYNOPSIS
  31
  32     use utf8;
  33     no utf8;
  34
  35     # Convert the internal representation of a Perl scalar to/from UTF-8.
  36
  37     $num_octets = utf8::upgrade($string);
  38     $success    = utf8::downgrade($string[, FAIL_OK]);
  39
  40     # Change each character of a Perl scalar to/from a series of
  41     # characters that represent the UTF-8 bytes of each original character.
  42
  43     utf8::encode($string);  # "\x{100}"  becomes "\xc4\x80"
  44     utf8::decode($string);  # "\xc4\x80" becomes "\x{100}"
  45
  46     $flag = utf8::is_utf8(STRING); # since Perl 5.8.1
  47     $flag = utf8::valid(STRING);
  48
  49 =head1 DESCRIPTION
  50
  51 The C<use utf8> pragma tells the Perl parser to allow UTF-8 in the
  52 program text in the current lexical scope (allow UTF-EBCDIC on EBCDIC based
  53 platforms).  The C<no utf8> pragma tells Perl to switch back to treating
  54 the source text as literal bytes in the current lexical scope.
  55
  56 B<Do not use this pragma for anything else than telling Perl that your
  57 script is written in UTF-8.> The utility functions described below are
  58 directly usable without C<use utf8;>.
  59
  60 Because it is not possible to reliably tell UTF-8 from native 8 bit
  61 encodings, you need either a Byte Order Mark at the beginning of your
  62 source code, or C<use utf8;>, to instruct perl.
  63
  64 When UTF-8 becomes the standard source format, this pragma will
  65 effectively become a no-op.  For convenience in what follows the term
  66 I<UTF-X> is used to refer to UTF-8 on ASCII and ISO Latin based
  67 platforms and UTF-EBCDIC on EBCDIC based platforms.
  68
  69 See also the effects of the C<-C> switch and its cousin, the
  70 C<$ENV{PERL_UNICODE}>, in L<perlrun>.
  71
  72 Enabling the C<utf8> pragma has the following effect:
  73
  74 =over 4
  75
  76 =item *
  77
  78 Bytes in the source text that have their high-bit set will be treated
  79 as being part of a literal UTF-X sequence.  This includes most
  80 literals such as identifier names, string constants, and constant
  81 regular expression patterns.
  82
  83 On EBCDIC platforms characters in the Latin 1 character set are
  84 treated as being part of a literal UTF-EBCDIC character.
  85
  86 =back
  87
  88 Note that if you have bytes with the eighth bit on in your script
  89 (for example embedded Latin-1 in your string literals), C<use utf8>
  90 will be unhappy since the bytes are most probably not well-formed
  91 UTF-X.  If you want to have such bytes under C<use utf8>, you can disable
  92 this pragma until the end the block (or file, if at top level) by
  93 C<no utf8;>.
  94
  95 =head2 Utility functions
  96
  97 The following functions are defined in the C<utf8::> package by the
  98 Perl core.  You do not need to say C<use utf8> to use these and in fact
  99 you should not say that  unless you really want to have UTF-8 source code.
 100
 101 =over 4
 102
 103 =item * $num_octets = utf8::upgrade($string)
 104
 105 Converts in-place the internal representation of the string from an octet
 106 sequence in the native encoding (Latin-1 or EBCDIC) to I<UTF-X>. The
 107 logical character sequence itself is unchanged.  If I<$string> is already
 108 stored as I<UTF-X>, then this is a no-op. Returns the
 109 number of octets necessary to represent the string as I<UTF-X>.  Can be
 110 used to make sure that the UTF-8 flag is on, so that C<\w> or C<lc()>
 111 work as Unicode on strings containing characters in the range 0x80-0xFF
 112 (on ASCII and derivatives).
 113
 114 B<Note that this function does not handle arbitrary encodings.>
 115 Therefore Encode is recommended for the general purposes; see also
 116 L<Encode>.
 117
 118 =item * $success = utf8::downgrade($string[, FAIL_OK])
 119
 120 Converts in-place the internal representation of the string from
 121 I<UTF-X> to the equivalent octet sequence in the native encoding (Latin-1
 122 or EBCDIC). The logical character sequence itself is unchanged. If
 123 I<$string> is already stored as native 8 bit, then this is a no-op.  Can
 124 be used to
 125 make sure that the UTF-8 flag is off, e.g. when you want to make sure
 126 that the substr() or length() function works with the usually faster
 127 byte algorithm.
 128
 129 Fails if the original I<UTF-X> sequence cannot be represented in the
 130 native 8 bit encoding. On failure dies or, if the value of C<FAIL_OK> is
 131 true, returns false.
 132
 133 Returns true on success.
 134
 135 B<Note that this function does not handle arbitrary encodings.>
 136 Therefore Encode is recommended for the general purposes; see also
 137 L<Encode>.
 138
 139 =item * utf8::encode($string)
 140
 141 Converts in-place the character sequence to the corresponding octet
 142 sequence in I<UTF-X>. That is, every (possibly wide) character gets
 143 replaced with a sequence of one or more characters that represent the
 144 individual I<UTF-X> bytes of the character.  The UTF8 flag is turned off.
 145 Returns nothing.
 146
 147     my $a = "\x{100}"; # $a contains one character, with ord 0x100
 148     utf8::encode($a);  # $a contains two characters, with ords 0xc4 and 0x80
 149
 150 B<Note that this function does not handle arbitrary encodings.>
 151 Therefore Encode is recommended for the general purposes; see also
 152 L<Encode>.
 153
 154 =item * $success = utf8::decode($string)
 155
 156 Attempts to convert in-place the octet sequence in I<UTF-X> to the
 157 corresponding character sequence. That is, it replaces each sequence of
 158 characters in the string whose ords represent a valid UTF-X byte
 159 sequence, with the corresponding single character.  The UTF-8 flag is
 160 turned on only if the source string contains multiple-byte I<UTF-X>
 161 characters.  If I<$string> is invalid as I<UTF-X>, returns false;
 162 otherwise returns true.
 163
 164     my $a = "\xc4\x80"; # $a contains two characters, with ords 0xc4 and 0x80
 165     utf8::decode($a);   # $a contains one character, with ord 0x100
 166
 167 B<Note that this function does not handle arbitrary encodings.>
 168 Therefore Encode is recommended for the general purposes; see also
 169 L<Encode>.
 170
 171 =item * $flag = utf8::is_utf8(STRING)
 172
 173 (Since Perl 5.8.1)  Test whether STRING is in UTF-8 internally.
 174 Functionally the same as Encode::is_utf8().
 175
 176 =item * $flag = utf8::valid(STRING)
 177
 178 [INTERNAL] Test whether STRING is in a consistent state regarding
 179 UTF-8.  Will return true is well-formed UTF-8 and has the UTF-8 flag
 180 on B<or> if string is held as bytes (both these states are 'consistent').
 181 Main reason for this routine is to allow Perl's testsuite to check
 182 that operations have left strings in a consistent state.  You most
 183 probably want to use utf8::is_utf8() instead.
 184
 185 =back
 186
 187 C<utf8::encode> is like C<utf8::upgrade>, but the UTF8 flag is
 188 cleared.  See L<perlunicode> for more on the UTF8 flag and the C API
 189 functions C<sv_utf8_upgrade>, C<sv_utf8_downgrade>, C<sv_utf8_encode>,
 190 and C<sv_utf8_decode>, which are wrapped by the Perl functions
 191 C<utf8::upgrade>, C<utf8::downgrade>, C<utf8::encode> and
 192 C<utf8::decode>.  Also, the functions utf8::is_utf8, utf8::valid,
 193 utf8::encode, utf8::decode, utf8::upgrade, and utf8::downgrade are
 194 actually internal, and thus always available, without a C<require utf8>
 195 statement.
 196
 197 =head1 BUGS
 198
 199 One can have Unicode in identifier names, but not in package/class or
 200 subroutine names.  While some limited functionality towards this does
 201 exist as of Perl 5.8.0, that is more accidental than designed; use of
 202 Unicode for the said purposes is unsupported.
 203
 204 One reason of this unfinishedness is its (currently) inherent
 205 unportability: since both package names and subroutine names may need
 206 to be mapped to file and directory names, the Unicode capability of
 207 the filesystem becomes important-- and there unfortunately aren't
 208 portable answers.
 209
 210 =head1 SEE ALSO
 211
 212 L<perlunitut>, L<perluniintro>, L<perlrun>, L<bytes>, L<perlunicode>
 213
 214 =cut