This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Move ExtUtils-Command to cpan/
[perl5.git] / dist / ExtUtils-Manifest / t / Manifest.t
1 #!/usr/bin/perl -w
2
3 BEGIN {
4     if( $ENV{PERL_CORE} ) {
5         chdir 't' if -d 't';
6         unshift @INC, '../lib';
7     }
8     else {
9         unshift @INC, 't/lib';
10     }
11 }
12 chdir 't';
13
14 use strict;
15
16 use Test::More tests => 96;
17 use Cwd;
18
19 use File::Spec;
20 use File::Path;
21 use File::Find;
22 use Config;
23
24 my $Is_VMS = $^O eq 'VMS';
25 my $Is_VMS_noefs = $Is_VMS;
26 if ($Is_VMS) {
27     my $vms_efs = 0;
28     if (eval 'require VMS::Feature') {
29         $vms_efs = VMS::Feature::current("efs_charset");
30     } else {
31         my $efs_charset = $ENV{'DECC$EFS_CHARSET'} || '';
32         $vms_efs = $efs_charset =~ /^[ET1]/i;
33     }
34     $Is_VMS_noefs = 0 if $vms_efs;
35 }
36
37
38 # We're going to be chdir'ing and modules are sometimes loaded on the
39 # fly in this test, so we need an absolute @INC.
40 @INC = map { File::Spec->rel2abs($_) } @INC;
41
42 # keep track of everything added so it can all be deleted
43 my %Files;
44 sub add_file {
45     my ($file, $data) = @_;
46     $data ||= 'foo';
47     $file =~ s/ /^_/g if $Is_VMS_noefs; # escape spaces
48     1 while unlink $file;  # or else we'll get multiple versions on VMS
49     open( T, '> '.$file) or return;
50     print T $data;
51     close T;
52     return 0 unless -e $file;  # exists under the name we gave it ?
53     ++$Files{$file};
54 }
55
56 sub read_manifest {
57     open( M, 'MANIFEST' ) or return;
58     chomp( my @files = <M> );
59     close M;
60     return @files;
61 }
62
63 sub catch_warning {
64     my $warn = '';
65     local $SIG{__WARN__} = sub { $warn .= $_[0] };
66     return join('', $_[0]->() ), $warn;
67 }
68
69 sub remove_dir {
70     ok( rmdir( $_ ), "remove $_ directory" ) for @_;
71 }
72
73 # use module, import functions
74 BEGIN {
75     use_ok( 'ExtUtils::Manifest',
76             qw( mkmanifest manicheck filecheck fullcheck
77                 maniread manicopy skipcheck maniadd maniskip) );
78 }
79
80 my $cwd = Cwd::getcwd();
81
82 # Just in case any old files were lying around.
83 rmtree('mantest');
84
85 ok( mkdir( 'mantest', 0777 ), 'make mantest directory' );
86 ok( chdir( 'mantest' ), 'chdir() to mantest' );
87 ok( add_file('foo'), 'add a temporary file' );
88
89 # This ensures the -x check for manicopy means something
90 # Some platforms don't have chmod or an executable bit, in which case
91 # this call will do nothing or fail, but on the platforms where chmod()
92 # works, we test the executable bit is copied
93 chmod( 0744, 'foo') if $Config{'chmod'};
94
95 # there shouldn't be a MANIFEST there
96 my ($res, $warn) = catch_warning( \&mkmanifest );
97 # Canonize the order.
98 $warn = join("", map { "$_|" }
99                  sort { lc($a) cmp lc($b) } split /\r?\n/, $warn);
100 is( $warn, "Added to MANIFEST: foo|Added to MANIFEST: MANIFEST|",
101     "mkmanifest() displayed its additions" );
102
103 # and now you see it
104 ok( -e 'MANIFEST', 'create MANIFEST file' );
105
106 my @list = read_manifest();
107 is( @list, 2, 'check files in MANIFEST' );
108 ok( ! ExtUtils::Manifest::filecheck(), 'no additional files in directory' );
109
110 # after adding bar, the MANIFEST is out of date
111 ok( add_file( 'bar' ), 'add another file' );
112 ok( ! manicheck(), 'MANIFEST now out of sync' );
113
114 # it reports that bar has been added and throws a warning
115 ($res, $warn) = catch_warning( \&filecheck );
116
117 like( $warn, qr/^Not in MANIFEST: bar/, 'warning that bar has been added' );
118 is( $res, 'bar', 'bar reported as new' );
119
120 # now quiet the warning that bar was added and test again
121 ($res, $warn) = do { local $ExtUtils::Manifest::Quiet = 1;
122                      catch_warning( \&skipcheck )
123                 };
124 is( $warn, '', 'disabled warnings' );
125
126 # add a skip file with a rule to skip itself (and the nonexistent glob '*baz*')
127 add_file( 'MANIFEST.SKIP', "baz\n.SKIP" );
128
129 # this'll skip the new file
130 ($res, $warn) = catch_warning( \&skipcheck );
131 like( $warn, qr/^Skipping MANIFEST\.SKIP/i, 'got skipping warning' );
132
133 my @skipped;
134 catch_warning( sub {
135         @skipped = skipcheck()
136 });
137
138 is( join( ' ', @skipped ), 'MANIFEST.SKIP', 'listed skipped files' );
139
140 {
141         local $ExtUtils::Manifest::Quiet = 1;
142         is( join(' ', filecheck() ), 'bar', 'listing skipped with filecheck()' );
143 }
144
145 # add a subdirectory and a file there that should be found
146 ok( mkdir( 'moretest', 0777 ), 'created moretest directory' );
147 add_file( File::Spec->catfile('moretest', 'quux'), 'quux' );
148 ok( exists( ExtUtils::Manifest::manifind()->{'moretest/quux'} ),
149                                         "manifind found moretest/quux" );
150
151 # only MANIFEST and foo are in the manifest
152 $_ = 'foo';
153 my $files = maniread();
154 is( keys %$files, 2, 'two files found' );
155 is( join(' ', sort { lc($a) cmp lc($b) } keys %$files), 'foo MANIFEST',
156                                         'both files found' );
157 is( $_, 'foo', q{maniread() doesn't clobber $_} );
158
159 ok( mkdir( 'copy', 0777 ), 'made copy directory' );
160
161 # Check that manicopy copies files.
162 manicopy( $files, 'copy', 'cp' );
163 my @copies = ();
164 find( sub { push @copies, $_ if -f }, 'copy' );
165 @copies = map { s/\.$//; $_ } @copies if $Is_VMS;  # VMS likes to put dots on
166                                                    # the end of files.
167 # Have to compare insensitively for non-case preserving VMS
168 is_deeply( [sort map { lc } @copies], [sort map { lc } keys %$files] );
169
170 # cp would leave files readonly, so check permissions.
171 foreach my $orig (@copies) {
172     my $copy = "copy/$orig";
173     ok( -r $copy,               "$copy: must be readable" );
174     is( -w $copy, -w $orig,     "       writable if original was" );
175     is( -x $copy, -x $orig,     "       executable if original was" );
176 }
177 rmtree('copy');
178
179
180 # poison the manifest, and add a comment that should be reported
181 add_file( 'MANIFEST', 'none #none' );
182 is( ExtUtils::Manifest::maniread()->{none}, '#none',
183                                         'maniread found comment' );
184
185 ok( mkdir( 'copy', 0777 ), 'made copy directory' );
186 $files = maniread();
187 eval { (undef, $warn) = catch_warning( sub {
188                 manicopy( $files, 'copy', 'cp' ) })
189 };
190
191 # a newline comes through, so get rid of it
192 chomp($warn);
193 # the copy should have given a warning
194 like($warn, qr/^none not found/, 'carped about none' );
195 ($res, $warn) = catch_warning( \&skipcheck );
196 like($warn, qr/^Skipping MANIFEST.SKIP/i, 'warned about MANIFEST.SKIP' );
197
198 # tell ExtUtils::Manifest to use a different file
199 {
200         local $ExtUtils::Manifest::MANIFEST = 'albatross';
201         ($res, $warn) = catch_warning( \&mkmanifest );
202         like( $warn, qr/Added to albatross: /, 'using a new manifest file' );
203
204         # add the new file to the list of files to be deleted
205         $Files{'albatross'}++;
206 }
207
208
209 # Make sure MANIFEST.SKIP is using complete relative paths
210 add_file( 'MANIFEST.SKIP' => "^moretest/q\n" );
211
212 # This'll skip moretest/quux
213 ($res, $warn) = catch_warning( \&skipcheck );
214 like( $warn, qr{^Skipping moretest/quux$}i, 'got skipping warning again' );
215
216
217 # There was a bug where entries in MANIFEST would be blotted out
218 # by MANIFEST.SKIP rules.
219 add_file( 'MANIFEST.SKIP' => 'foo' );
220 add_file( 'MANIFEST'      => "foobar\n"   );
221 add_file( 'foobar'        => '123' );
222 ($res, $warn) = catch_warning( \&manicheck );
223 is( $res,  '',      'MANIFEST overrides MANIFEST.SKIP' );
224 is( $warn, '',   'MANIFEST overrides MANIFEST.SKIP, no warnings' );
225
226 $files = maniread;
227 ok( !$files->{wibble},     'MANIFEST in good state' );
228 maniadd({ wibble => undef });
229 maniadd({ yarrow => "hock" });
230 $files = maniread;
231 is( $files->{wibble}, '',    'maniadd() with undef comment' );
232 is( $files->{yarrow}, 'hock','          with comment' );
233 is( $files->{foobar}, '',    '          preserved old entries' );
234
235 {
236     # EOL normalization in maniadd()
237
238     # move manifest away:
239     rename "MANIFEST", "MANIFEST.bak" or die "Could not rename MANIFEST to MANIFEST.bak: $!";
240     my $prev_maniaddresult;
241     my @eol = ("\012","\015","\015\012");
242     # for all line-endings:
243     for my $i (0..$#eol) {
244         my $eol = $eol[$i];
245         #   cp the backup of the manifest to MANIFEST, line-endings adjusted
246         my $content = do { local $/; open my $fh, "MANIFEST.bak" or die; <$fh> };
247     SPLITTER: for my $eol2 (@eol) {
248             if ( index($content, $eol2) > -1 ) {
249                 my @lines = split /$eol2/, $content;
250                 pop @lines while $lines[-1] eq "";
251                 open my $fh, ">", "MANIFEST" or die "Could not open >MANIFEST: $!";
252                 print $fh map { "$_$eol" } @lines;
253                 close $fh or die "Could not close: $!";
254                 last SPLITTER;
255             }
256         }
257         #   try maniadd
258         maniadd({eoltest => "end of line normalization test"});
259         #   slurp result and compare to previous result
260         my $maniaddresult = do { local $/; open my $fh, "MANIFEST" or die; <$fh> };
261         if ($prev_maniaddresult) {
262             if ( $maniaddresult eq $prev_maniaddresult ) {
263                 pass "normalization success with i=$i";
264             } else {
265                 require Data::Dumper;
266                 no warnings "once";
267                 local $Data::Dumper::Useqq = 1;
268                 local $Data::Dumper::Terse = 1;
269                 is Data::Dumper::Dumper($maniaddresult), Data::Dumper::Dumper($prev_maniaddresult), "eol normalization failed with i=$i";
270             }
271         }
272         $prev_maniaddresult = $maniaddresult;
273     }
274     # move backup over MANIFEST
275     rename "MANIFEST.bak", "MANIFEST" or die "Could not rename MANIFEST.bak to MANIFEST: $!";
276 }
277
278 my %funky_files;
279 # test including a filename with a space
280 SKIP: {
281     add_file( 'foo bar' => "space" )
282         or skip "couldn't create spaced test file", 2;
283     local $ExtUtils::Manifest::MANIFEST = "albatross";
284     maniadd({ 'foo bar' => "contains space"});
285     is( maniread()->{'foo bar'}, "contains space",
286         'spaced manifest filename' );
287     add_file( 'albatross.bak', '' );
288     ($res, $warn) = catch_warning( \&mkmanifest );
289     like( $warn, qr/\A(Added to.*\n)+\z/m,
290           'no warnings about funky filename' );
291     $funky_files{'space'} = 'foo bar';
292 }
293
294 # test including a filename with a space and a quote
295 SKIP: {
296     add_file( 'foo\' baz\'quux' => "quote" )
297         or skip "couldn't create quoted test file", 1;
298     local $ExtUtils::Manifest::MANIFEST = "albatross";
299     maniadd({ 'foo\' baz\'quux' => "contains quote"});
300     is( maniread()->{'foo\' baz\'quux'}, "contains quote",
301         'quoted manifest filename' );
302     $funky_files{'space_quote'} = 'foo\' baz\'quux';
303 }
304
305 # test including a filename with a space and a backslash
306 SKIP: {
307     add_file( 'foo bar\\baz' => "backslash" )
308         or skip "couldn't create backslash test file", 1;
309     local $ExtUtils::Manifest::MANIFEST = "albatross";
310     maniadd({ 'foo bar\\baz' => "contains backslash"});
311     is( maniread()->{'foo bar\\baz'}, "contains backslash",
312         'backslashed manifest filename' );
313     $funky_files{'space_backslash'} = 'foo bar\\baz';
314 }
315
316 # test including a filename with a space, quote, and a backslash
317 SKIP: {
318     add_file( 'foo bar\\baz\'quux' => "backslash/quote" )
319         or skip "couldn't create backslash/quote test file", 1;
320     local $ExtUtils::Manifest::MANIFEST = "albatross";
321     maniadd({ 'foo bar\\baz\'quux' => "backslash and quote"});
322     is( maniread()->{'foo bar\\baz\'quux'}, "backslash and quote",
323         'backslashed and quoted manifest filename' );
324     $funky_files{'space_quote_backslash'} = 'foo bar\\baz\'quux';
325 }
326
327 my @funky_keys = qw(space space_quote space_backslash space_quote_backslash);
328 # test including an external manifest.skip file in MANIFEST.SKIP
329 {
330     maniadd({ foo => undef , albatross => undef,
331               'mymanifest.skip' => undef, 'mydefault.skip' => undef});
332     for (@funky_keys) {
333         maniadd( {$funky_files{$_} => $_} ) if defined $funky_files{$_};
334     }
335
336     add_file('mymanifest.skip' => "^foo\n");
337     add_file('mydefault.skip'  => "^my\n");
338     local $ExtUtils::Manifest::DEFAULT_MSKIP =
339          File::Spec->catfile($cwd, qw(mantest mydefault.skip));
340     my $skip = File::Spec->catfile($cwd, qw(mantest mymanifest.skip));
341     add_file('MANIFEST.SKIP' =>
342              "albatross\n#!include $skip\n#!include_default");
343     my ($res, $warn) = catch_warning( \&skipcheck );
344     for (qw(albatross foo foobar mymanifest.skip mydefault.skip)) {
345         like( $warn, qr/Skipping \b$_\b/,
346               "Skipping $_" );
347     }
348     for my $funky_key (@funky_keys) {
349         SKIP: {
350             my $funky_file = $funky_files{$funky_key};
351             skip "'$funky_key' not created", 1 unless $funky_file;
352             like( $warn, qr/Skipping \b\Q$funky_file\E\b/,
353               "Skipping $funky_file");
354         }
355     }
356     ($res, $warn) = catch_warning( \&mkmanifest );
357     for (qw(albatross foo foobar mymanifest.skip mydefault.skip)) {
358         like( $warn, qr/Removed from MANIFEST: \b$_\b/,
359               "Removed $_ from MANIFEST" );
360     }
361     for my $funky_key (@funky_keys) {
362         SKIP: {
363             my $funky_file = $funky_files{$funky_key};
364             skip "'$funky_key' not created", 1 unless $funky_file;
365             like( $warn, qr/Removed from MANIFEST: \b\Q$funky_file\E\b/,
366               "Removed $funky_file from MANIFEST");
367         }
368     }
369     my $files = maniread;
370     ok( ! exists $files->{albatross}, 'albatross excluded via MANIFEST.SKIP' );
371     ok( exists $files->{yarrow},      'yarrow included in MANIFEST' );
372     ok( exists $files->{bar},         'bar included in MANIFEST' );
373     ok( ! exists $files->{foobar},    'foobar excluded via mymanifest.skip' );
374     ok( ! exists $files->{foo},       'foo excluded via mymanifest.skip' );
375     ok( ! exists $files->{'mymanifest.skip'},
376         'mymanifest.skip excluded via mydefault.skip' );
377     ok( ! exists $files->{'mydefault.skip'},
378         'mydefault.skip excluded via mydefault.skip' );
379
380     # test exclusion of funky files
381     for my $funky_key (@funky_keys) {
382         SKIP: {
383             my $funky_file = $funky_files{$funky_key};
384             skip "'$funky_key' not created", 1 unless $funky_file;
385             ok( ! exists $files->{$funky_file},
386                   "'$funky_file' excluded via mymanifest.skip" );
387         }
388     }
389
390     # tests for maniskip
391     my $skipchk = maniskip();
392     is ( $skipchk->('albatross'), 1,
393         'albatross excluded via MANIFEST.SKIP' );
394     is( $skipchk->('yarrow'), '',
395         'yarrow included in MANIFEST' );
396     is( $skipchk->('bar'), '',
397         'bar included in MANIFEST' );
398     $skipchk = maniskip('mymanifest.skip');
399     is( $skipchk->('foobar'), 1,
400         'foobar excluded via mymanifest.skip' );
401     is( $skipchk->('foo'), 1,
402         'foo excluded via mymanifest.skip' );
403     is( $skipchk->('mymanifest.skip'), '',
404         'mymanifest.skip included via mydefault.skip' );
405     is( $skipchk->('mydefault.skip'), '',
406         'mydefault.skip included via mydefault.skip' );
407     $skipchk = maniskip('mydefault.skip');
408     is( $skipchk->('foobar'), '',
409         'foobar included via mydefault.skip' );
410     is( $skipchk->('foo'), '',
411         'foo included via mydefault.skip' );
412     is( $skipchk->('mymanifest.skip'), 1,
413         'mymanifest.skip excluded via mydefault.skip' );
414     is( $skipchk->('mydefault.skip'), 1,
415         'mydefault.skip excluded via mydefault.skip' );
416
417     my $extsep = $Is_VMS_noefs ? '_' : '.';
418     $Files{"$_.bak"}++ for ('MANIFEST', "MANIFEST${extsep}SKIP");
419 }
420
421 add_file('MANIFEST'   => 'Makefile.PL');
422 maniadd({ foo  => 'bar' });
423 $files = maniread;
424 # VMS downcases the MANIFEST.  We normalize it here to match.
425 %$files = map { (lc $_ => $files->{$_}) } keys %$files;
426 my %expect = ( 'makefile.pl' => '',
427                'foo'    => 'bar'
428              );
429 is_deeply( $files, \%expect, 'maniadd() vs MANIFEST without trailing newline');
430
431 #add_file('MANIFEST'   => 'Makefile.PL');
432 #maniadd({ foo => 'bar' });
433
434 SKIP: {
435     chmod( 0400, 'MANIFEST' );
436     skip "Can't make MANIFEST read-only", 2 if -w 'MANIFEST';
437
438     eval {
439         maniadd({ 'foo' => 'bar' });
440     };
441     is( $@, '',  "maniadd() won't open MANIFEST if it doesn't need to" );
442
443     eval {
444         maniadd({ 'grrrwoof' => 'yippie' });
445     };
446     like( $@, qr/^\Qmaniadd() could not open MANIFEST:\E/,
447                  "maniadd() dies if it can't open the MANIFEST" );
448
449     chmod( 0600, 'MANIFEST' );
450 }
451
452
453 END {
454         is( unlink( keys %Files ), keys %Files, 'remove all added files' );
455         for my $file ( keys %Files ) { 1 while unlink $file; } # all versions
456         remove_dir( 'moretest', 'copy' );
457
458         # now get rid of the parent directory
459         ok( chdir( $cwd ), 'return to parent directory' );
460         remove_dir( 'mantest' );
461 }