This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Make Porting/expand-macro.pl use $Config{make} instead of hardcoded `make`
[perl5.git] / Porting / expand-macro.pl
1 #!perl -w
2 use strict;
3
4 use Pod::Usage;
5 use Getopt::Std;
6 use Config;
7 $Getopt::Std::STANDARD_HELP_VERSION = 1;
8
9 my $trysource = "try.c";
10 my $tryout = "try.i";
11
12 getopts('fF:ekvI:X', \my %opt) or pod2usage();
13
14 my($expr, @headers) = @ARGV ? splice @ARGV : "-";
15
16 pod2usage "-f and -F <tool> are exclusive\n" if $opt{f} and $opt{F};
17
18 foreach($trysource, $tryout) {
19     unlink $_ if $opt{e};
20     die "You already have a $_" if -e $_;
21 }
22
23 if ($expr eq '-') {
24     warn "reading from stdin...\n";
25     $expr = do { local $/; <> };
26 }
27
28 my($macro, $args) = $expr =~ /^\s*(\w+)((?:\s*\(.*\))?)\s*;?\s*$/s
29     or pod2usage "$expr doesn't look like a macro-name or macro-expression to me";
30
31 if (!(@ARGV = @headers)) {
32     open my $fh, '<', 'MANIFEST' or die "Can't open MANIFEST: $!";
33     while (<$fh>) {
34         push @ARGV, $1 if m!^([^/]+\.h)\t!;
35     }
36     push @ARGV, 'config.h' if -f 'config.h';
37 }
38
39 my $header;
40 while (<>) {
41     next unless /^#\s*define\s+$macro\b/;
42     my ($def_args) = /^#\s*define\s+$macro\(([^)]*)\)/;
43     if (defined $def_args && !$args) {
44         my @args = split ',', $def_args;
45         print "# macro: $macro args: @args in $_\n" if $opt{v};
46         my $argname = "A0";
47         $args = '(' . join (', ', map {$argname++} 1..@args) . ')';
48     }
49     $header = $ARGV;
50     last;
51 }
52 die "$macro not found\n" unless defined $header;
53
54 open my $out, '>', $trysource or die "Can't open $trysource: $!";
55
56 my $sentinel = "$macro expands to";
57
58 my %done_header;
59
60 sub do_header {
61     my $header = shift;
62     return if $done_header{$header}++;
63     print $out qq{#include "$header"\n};
64 }
65
66 print $out <<'EOF' if $opt{X};
67 /* Need to do this like this, as cflags.sh sets it for us come what may.  */
68 #undef PERL_CORE
69
70 EOF
71
72 do_header('EXTERN.h');
73 do_header('perl.h');
74 do_header($header);
75 do_header('XSUB.h') if $opt{X};
76
77 print $out <<"EOF";
78 #line 4 "$sentinel"
79 $macro$args
80 EOF
81
82 close $out or die "Can't close $trysource: $!";
83
84 print "doing: $Config{make} $tryout\n" if $opt{v};
85 my $cmd = "$Config{make} $tryout";
86 system( $cmd ) == 0
87     or die "Couldn't launch [$cmd]: $! / $?";
88
89 # if user wants 'indent' formatting ..
90 my $out_fh;
91
92 if ($opt{f} || $opt{F}) {
93     # a: indent is a well behaved filter when given 0 arguments, reading from
94     #    stdin and writing to stdout
95     # b: all our braces should be balanced, indented back to column 0, in the
96     #    headers, hence everything before our #line directive can be ignored
97     #
98     # We can take advantage of this to reduce the work to indent.
99
100     my $indent_command = $opt{f} ? 'indent' : $opt{F};
101
102     if (defined $opt{I}) {
103         $indent_command .= " $opt{I}";
104     }
105     open $out_fh, '|-', $indent_command or die $?;
106 } else {
107     $out_fh = \*STDOUT;
108 }
109
110 open my $fh, '<', $tryout or die "Can't open $tryout: $!";
111
112 while (<$fh>) {
113     print $out_fh $_ if /$sentinel/o .. 1;
114 }
115
116 unless ($opt{k}) {
117     foreach($trysource, $tryout) {
118         die "Can't unlink $_" unless unlink $_;
119     }
120 }
121
122 __END__
123
124 =head1 NAME
125
126 expand-macro.pl - expand C macros using the C preprocessor
127
128 =head1 SYNOPSIS
129
130   expand-macro.pl [options] [ < macro-name | macro-expression | - > [headers] ]
131
132   options:
133     -f          use 'indent' to format output
134     -F  <tool>  use <tool> to format output  (instead of -f)
135     -e          erase try.[ic] instead of failing when they're present (errdetect)
136     -k          keep them after generating (for handy inspection)
137     -v          verbose
138     -I <indent-opts>    passed into indent
139     -X          include "XSUB.h" (and undefine PERL_CORE)
140
141 =cut