This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlop.pod: Reword escapes that have ordinals
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 =head2 Operator Precedence and Associativity
9 X<operator, precedence> X<precedence> X<associativity>
10
11 Operator precedence and associativity work in Perl more or less like
12 they do in mathematics.
13
14 I<Operator precedence> means some operators are evaluated before
15 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
16 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
17 22> and not C<6 * 5 == 30>.
18
19 I<Operator associativity> defines what happens if a sequence of the
20 same operators is used one after another: whether the evaluator will
21 evaluate the left operations first or the right.  For example, in C<8
22 - 4 - 2>, subtraction is left associative so Perl evaluates the
23 expression left to right.  C<8 - 4> is evaluated first making the
24 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
25
26 Perl operators have the following associativity and precedence,
27 listed from highest precedence to lowest.  Operators borrowed from
28 C keep the same precedence relationship with each other, even where
29 C's precedence is slightly screwy.  (This makes learning Perl easier
30 for C folks.)  With very few exceptions, these all operate on scalar
31 values only, not array values.
32
33     left        terms and list operators (leftward)
34     left        ->
35     nonassoc    ++ --
36     right       **
37     right       ! ~ \ and unary + and -
38     left        =~ !~
39     left        * / % x
40     left        + - .
41     left        << >>
42     nonassoc    named unary operators
43     nonassoc    < > <= >= lt gt le ge
44     nonassoc    == != <=> eq ne cmp ~~
45     left        &
46     left        | ^
47     left        &&
48     left        || //
49     nonassoc    ..  ...
50     right       ?:
51     right       = += -= *= etc.
52     left        , =>
53     nonassoc    list operators (rightward)
54     right       not
55     left        and
56     left        or xor
57
58 In the following sections, these operators are covered in precedence order.
59
60 Many operators can be overloaded for objects.  See L<overload>.
61
62 =head2 Terms and List Operators (Leftward)
63 X<list operator> X<operator, list> X<term>
64
65 A TERM has the highest precedence in Perl.  They include variables,
66 quote and quote-like operators, any expression in parentheses,
67 and any function whose arguments are parenthesized.  Actually, there
68 aren't really functions in this sense, just list operators and unary
69 operators behaving as functions because you put parentheses around
70 the arguments.  These are all documented in L<perlfunc>.
71
72 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
73 is followed by a left parenthesis as the next token, the operator and
74 arguments within parentheses are taken to be of highest precedence,
75 just like a normal function call.
76
77 In the absence of parentheses, the precedence of list operators such as
78 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
79 whether you are looking at the left side or the right side of the operator.
80 For example, in
81
82     @ary = (1, 3, sort 4, 2);
83     print @ary;         # prints 1324
84
85 the commas on the right of the sort are evaluated before the sort,
86 but the commas on the left are evaluated after.  In other words,
87 list operators tend to gobble up all arguments that follow, and
88 then act like a simple TERM with regard to the preceding expression.
89 Be careful with parentheses:
90
91     # These evaluate exit before doing the print:
92     print($foo, exit);  # Obviously not what you want.
93     print $foo, exit;   # Nor is this.
94
95     # These do the print before evaluating exit:
96     (print $foo), exit; # This is what you want.
97     print($foo), exit;  # Or this.
98     print ($foo), exit; # Or even this.
99
100 Also note that
101
102     print ($foo & 255) + 1, "\n";
103
104 probably doesn't do what you expect at first glance.  The parentheses
105 enclose the argument list for C<print> which is evaluated (printing
106 the result of C<$foo & 255>).  Then one is added to the return value
107 of C<print> (usually 1).  The result is something like this:
108
109     1 + 1, "\n";    # Obviously not what you meant.
110
111 To do what you meant properly, you must write:
112
113     print(($foo & 255) + 1, "\n");
114
115 See L<Named Unary Operators> for more discussion of this.
116
117 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
118 well as subroutine and method calls, and the anonymous
119 constructors C<[]> and C<{}>.
120
121 See also L<Quote and Quote-like Operators> toward the end of this section,
122 as well as L</"I/O Operators">.
123
124 =head2 The Arrow Operator
125 X<arrow> X<dereference> X<< -> >>
126
127 "C<< -> >>" is an infix dereference operator, just as it is in C
128 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
129 C<(...)> subscript, then the left side must be either a hard or
130 symbolic reference to an array, a hash, or a subroutine respectively.
131 (Or technically speaking, a location capable of holding a hard
132 reference, if it's an array or hash reference being used for
133 assignment.)  See L<perlreftut> and L<perlref>.
134
135 Otherwise, the right side is a method name or a simple scalar
136 variable containing either the method name or a subroutine reference,
137 and the left side must be either an object (a blessed reference)
138 or a class name (that is, a package name).  See L<perlobj>.
139
140 =head2 Auto-increment and Auto-decrement
141 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
142
143 "++" and "--" work as in C.  That is, if placed before a variable,
144 they increment or decrement the variable by one before returning the
145 value, and if placed after, increment or decrement after returning the
146 value.
147
148     $i = 0;  $j = 0;
149     print $i++;  # prints 0
150     print ++$j;  # prints 1
151
152 Note that just as in C, Perl doesn't define B<when> the variable is
153 incremented or decremented. You just know it will be done sometime
154 before or after the value is returned. This also means that modifying
155 a variable twice in the same statement will lead to undefined behaviour.
156 Avoid statements like:
157
158     $i = $i ++;
159     print ++ $i + $i ++;
160
161 Perl will not guarantee what the result of the above statements is.
162
163 The auto-increment operator has a little extra builtin magic to it.  If
164 you increment a variable that is numeric, or that has ever been used in
165 a numeric context, you get a normal increment.  If, however, the
166 variable has been used in only string contexts since it was set, and
167 has a value that is not the empty string and matches the pattern
168 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
169 character within its range, with carry:
170
171     print ++($foo = '99');      # prints '100'
172     print ++($foo = 'a0');      # prints 'a1'
173     print ++($foo = 'Az');      # prints 'Ba'
174     print ++($foo = 'zz');      # prints 'aaa'
175
176 C<undef> is always treated as numeric, and in particular is changed
177 to C<0> before incrementing (so that a post-increment of an undef value
178 will return C<0> rather than C<undef>).
179
180 The auto-decrement operator is not magical.
181
182 =head2 Exponentiation
183 X<**> X<exponentiation> X<power>
184
185 Binary "**" is the exponentiation operator.  It binds even more
186 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
187 implemented using C's pow(3) function, which actually works on doubles
188 internally.)
189
190 =head2 Symbolic Unary Operators
191 X<unary operator> X<operator, unary>
192
193 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
194 precedence version of this.
195 X<!>
196
197 Unary "-" performs arithmetic negation if the operand is numeric.  If
198 the operand is an identifier, a string consisting of a minus sign
199 concatenated with the identifier is returned.  Otherwise, if the string
200 starts with a plus or minus, a string starting with the opposite sign
201 is returned.  One effect of these rules is that -bareword is equivalent
202 to the string "-bareword".  If, however, the string begins with a
203 non-alphabetic character (excluding "+" or "-"), Perl will attempt to convert
204 the string to a numeric and the arithmetic negation is performed. If the
205 string cannot be cleanly converted to a numeric, Perl will give the warning
206 B<Argument "the string" isn't numeric in negation (-) at ...>.
207 X<-> X<negation, arithmetic>
208
209 Unary "~" performs bitwise negation, i.e., 1's complement.  For
210 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
211 L<Bitwise String Operators>.)  Note that the width of the result is
212 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
213 bits wide on a 64-bit platform, so if you are expecting a certain bit
214 width, remember to use the & operator to mask off the excess bits.
215 X<~> X<negation, binary>
216
217 Unary "+" has no effect whatsoever, even on strings.  It is useful
218 syntactically for separating a function name from a parenthesized expression
219 that would otherwise be interpreted as the complete list of function
220 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
221 X<+>
222
223 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
224 and L<perlref>.  Do not confuse this behavior with the behavior of
225 backslash within a string, although both forms do convey the notion
226 of protecting the next thing from interpolation.
227 X<\> X<reference> X<backslash>
228
229 =head2 Binding Operators
230 X<binding> X<operator, binding> X<=~> X<!~>
231
232 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
233 search or modify the string $_ by default.  This operator makes that kind
234 of operation work on some other string.  The right argument is a search
235 pattern, substitution, or transliteration.  The left argument is what is
236 supposed to be searched, substituted, or transliterated instead of the default
237 $_.  When used in scalar context, the return value generally indicates the
238 success of the operation.  The exception is substitution with the C</r>
239 (non-destructive) option, which causes the return value to be the result of
240 the substition.  Behavior in list context depends on the particular operator.
241 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
242 examples using these operators.
243
244 If the right argument is an expression rather than a search pattern,
245 substitution, or transliteration, it is interpreted as a search pattern at run
246 time. Note that this means that its contents will be interpolated twice, so
247
248   '\\' =~ q'\\';
249
250 is not ok, as the regex engine will end up trying to compile the
251 pattern C<\>, which it will consider a syntax error.
252
253 Binary "!~" is just like "=~" except the return value is negated in
254 the logical sense.
255
256 Binary "!~" with a non-destructive substitution (s///r) is a syntax error.
257
258 =head2 Multiplicative Operators
259 X<operator, multiplicative>
260
261 Binary "*" multiplies two numbers.
262 X<*>
263
264 Binary "/" divides two numbers.
265 X</> X<slash>
266
267 Binary "%" is the modulo operator, which computes the division
268 remainder of its first argument with respect to its second argument.
269 Given integer
270 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
271 C<$a> minus the largest multiple of C<$b> less than or equal to
272 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
273 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
274 result will be less than or equal to zero).  If the operands
275 C<$a> and C<$b> are floating point values and the absolute value of
276 C<$b> (that is C<abs($b)>) is less than C<(UV_MAX + 1)>, only
277 the integer portion of C<$a> and C<$b> will be used in the operation
278 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
279 If the absolute value of the right operand (C<abs($b)>) is greater than
280 or equal to C<(UV_MAX + 1)>, "%" computes the floating-point remainder
281 C<$r> in the equation C<($r = $a - $i*$b)> where C<$i> is a certain
282 integer that makes C<$r> have the same sign as the right operand
283 C<$b> (B<not> as the left operand C<$a> like C function C<fmod()>)
284 and the absolute value less than that of C<$b>.
285 Note that when C<use integer> is in scope, "%" gives you direct access
286 to the modulo operator as implemented by your C compiler.  This
287 operator is not as well defined for negative operands, but it will
288 execute faster.
289 X<%> X<remainder> X<modulo> X<mod>
290
291 Binary "x" is the repetition operator.  In scalar context or if the left
292 operand is not enclosed in parentheses, it returns a string consisting
293 of the left operand repeated the number of times specified by the right
294 operand.  In list context, if the left operand is enclosed in
295 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
296 If the right operand is zero or negative, it returns an empty string
297 or an empty list, depending on the context.
298 X<x>
299
300     print '-' x 80;             # print row of dashes
301
302     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
303
304     @ones = (1) x 80;           # a list of 80 1's
305     @ones = (5) x @ones;        # set all elements to 5
306
307
308 =head2 Additive Operators
309 X<operator, additive>
310
311 Binary "+" returns the sum of two numbers.
312 X<+>
313
314 Binary "-" returns the difference of two numbers.
315 X<->
316
317 Binary "." concatenates two strings.
318 X<string, concatenation> X<concatenation>
319 X<cat> X<concat> X<concatenate> X<.>
320
321 =head2 Shift Operators
322 X<shift operator> X<operator, shift> X<<< << >>>
323 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
324 X<shl> X<shr> X<shift, right> X<shift, left>
325
326 Binary "<<" returns the value of its left argument shifted left by the
327 number of bits specified by the right argument.  Arguments should be
328 integers.  (See also L<Integer Arithmetic>.)
329
330 Binary ">>" returns the value of its left argument shifted right by
331 the number of bits specified by the right argument.  Arguments should
332 be integers.  (See also L<Integer Arithmetic>.)
333
334 Note that both "<<" and ">>" in Perl are implemented directly using
335 "<<" and ">>" in C.  If C<use integer> (see L<Integer Arithmetic>) is
336 in force then signed C integers are used, else unsigned C integers are
337 used.  Either way, the implementation isn't going to generate results
338 larger than the size of the integer type Perl was built with (32 bits
339 or 64 bits).
340
341 The result of overflowing the range of the integers is undefined
342 because it is undefined also in C.  In other words, using 32-bit
343 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
344 of bits is also undefined.
345
346 =head2 Named Unary Operators
347 X<operator, named unary>
348
349 The various named unary operators are treated as functions with one
350 argument, with optional parentheses.
351
352 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
353 is followed by a left parenthesis as the next token, the operator and
354 arguments within parentheses are taken to be of highest precedence,
355 just like a normal function call.  For example,
356 because named unary operators are higher precedence than ||:
357
358     chdir $foo    || die;       # (chdir $foo) || die
359     chdir($foo)   || die;       # (chdir $foo) || die
360     chdir ($foo)  || die;       # (chdir $foo) || die
361     chdir +($foo) || die;       # (chdir $foo) || die
362
363 but, because * is higher precedence than named operators:
364
365     chdir $foo * 20;    # chdir ($foo * 20)
366     chdir($foo) * 20;   # (chdir $foo) * 20
367     chdir ($foo) * 20;  # (chdir $foo) * 20
368     chdir +($foo) * 20; # chdir ($foo * 20)
369
370     rand 10 * 20;       # rand (10 * 20)
371     rand(10) * 20;      # (rand 10) * 20
372     rand (10) * 20;     # (rand 10) * 20
373     rand +(10) * 20;    # rand (10 * 20)
374
375 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
376 treated like named unary operators, but they don't follow this functional
377 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
378 equivalent to C<-f "$file.bak">.
379 X<-X> X<filetest> X<operator, filetest>
380
381 See also L<"Terms and List Operators (Leftward)">.
382
383 =head2 Relational Operators
384 X<relational operator> X<operator, relational>
385
386 Binary "<" returns true if the left argument is numerically less than
387 the right argument.
388 X<< < >>
389
390 Binary ">" returns true if the left argument is numerically greater
391 than the right argument.
392 X<< > >>
393
394 Binary "<=" returns true if the left argument is numerically less than
395 or equal to the right argument.
396 X<< <= >>
397
398 Binary ">=" returns true if the left argument is numerically greater
399 than or equal to the right argument.
400 X<< >= >>
401
402 Binary "lt" returns true if the left argument is stringwise less than
403 the right argument.
404 X<< lt >>
405
406 Binary "gt" returns true if the left argument is stringwise greater
407 than the right argument.
408 X<< gt >>
409
410 Binary "le" returns true if the left argument is stringwise less than
411 or equal to the right argument.
412 X<< le >>
413
414 Binary "ge" returns true if the left argument is stringwise greater
415 than or equal to the right argument.
416 X<< ge >>
417
418 =head2 Equality Operators
419 X<equality> X<equal> X<equals> X<operator, equality>
420
421 Binary "==" returns true if the left argument is numerically equal to
422 the right argument.
423 X<==>
424
425 Binary "!=" returns true if the left argument is numerically not equal
426 to the right argument.
427 X<!=>
428
429 Binary "<=>" returns -1, 0, or 1 depending on whether the left
430 argument is numerically less than, equal to, or greater than the right
431 argument.  If your platform supports NaNs (not-a-numbers) as numeric
432 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
433 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
434 returns true, as does NaN != anything else. If your platform doesn't
435 support NaNs then NaN is just a string with numeric value 0.
436 X<< <=> >> X<spaceship>
437
438     perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
439     perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
440
441 Binary "eq" returns true if the left argument is stringwise equal to
442 the right argument.
443 X<eq>
444
445 Binary "ne" returns true if the left argument is stringwise not equal
446 to the right argument.
447 X<ne>
448
449 Binary "cmp" returns -1, 0, or 1 depending on whether the left
450 argument is stringwise less than, equal to, or greater than the right
451 argument.
452 X<cmp>
453
454 Binary "~~" does a smart match between its arguments. Smart matching
455 is described in L<perlsyn/"Smart matching in detail">.
456 X<~~>
457
458 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
459 by the current locale if C<use locale> is in effect.  See L<perllocale>.
460
461 =head2 Bitwise And
462 X<operator, bitwise, and> X<bitwise and> X<&>
463
464 Binary "&" returns its operands ANDed together bit by bit.
465 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
466
467 Note that "&" has lower priority than relational operators, so for example
468 the brackets are essential in a test like
469
470         print "Even\n" if ($x & 1) == 0;
471
472 =head2 Bitwise Or and Exclusive Or
473 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
474 X<bitwise xor> X<^>
475
476 Binary "|" returns its operands ORed together bit by bit.
477 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
478
479 Binary "^" returns its operands XORed together bit by bit.
480 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
481
482 Note that "|" and "^" have lower priority than relational operators, so
483 for example the brackets are essential in a test like
484
485         print "false\n" if (8 | 2) != 10;
486
487 =head2 C-style Logical And
488 X<&&> X<logical and> X<operator, logical, and>
489
490 Binary "&&" performs a short-circuit logical AND operation.  That is,
491 if the left operand is false, the right operand is not even evaluated.
492 Scalar or list context propagates down to the right operand if it
493 is evaluated.
494
495 =head2 C-style Logical Or
496 X<||> X<operator, logical, or>
497
498 Binary "||" performs a short-circuit logical OR operation.  That is,
499 if the left operand is true, the right operand is not even evaluated.
500 Scalar or list context propagates down to the right operand if it
501 is evaluated.
502
503 =head2 C-style Logical Defined-Or
504 X<//> X<operator, logical, defined-or>
505
506 Although it has no direct equivalent in C, Perl's C<//> operator is related
507 to its C-style or.  In fact, it's exactly the same as C<||>, except that it
508 tests the left hand side's definedness instead of its truth.  Thus, C<$a // $b>
509 is similar to C<defined($a) || $b> (except that it returns the value of C<$a>
510 rather than the value of C<defined($a)>) and is exactly equivalent to
511 C<defined($a) ? $a : $b>.  This is very useful for providing default values
512 for variables.  If you actually want to test if at least one of C<$a> and
513 C<$b> is defined, use C<defined($a // $b)>.
514
515 The C<||>, C<//> and C<&&> operators return the last value evaluated
516 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
517 portable way to find out the home directory might be:
518
519     $home = $ENV{'HOME'} // $ENV{'LOGDIR'} //
520         (getpwuid($<))[7] // die "You're homeless!\n";
521
522 In particular, this means that you shouldn't use this
523 for selecting between two aggregates for assignment:
524
525     @a = @b || @c;              # this is wrong
526     @a = scalar(@b) || @c;      # really meant this
527     @a = @b ? @b : @c;          # this works fine, though
528
529 As more readable alternatives to C<&&> and C<||> when used for
530 control flow, Perl provides the C<and> and C<or> operators (see below).
531 The short-circuit behavior is identical.  The precedence of "and"
532 and "or" is much lower, however, so that you can safely use them after a
533 list operator without the need for parentheses:
534
535     unlink "alpha", "beta", "gamma"
536             or gripe(), next LINE;
537
538 With the C-style operators that would have been written like this:
539
540     unlink("alpha", "beta", "gamma")
541             || (gripe(), next LINE);
542
543 Using "or" for assignment is unlikely to do what you want; see below.
544
545 =head2 Range Operators
546 X<operator, range> X<range> X<..> X<...>
547
548 Binary ".." is the range operator, which is really two different
549 operators depending on the context.  In list context, it returns a
550 list of values counting (up by ones) from the left value to the right
551 value.  If the left value is greater than the right value then it
552 returns the empty list.  The range operator is useful for writing
553 C<foreach (1..10)> loops and for doing slice operations on arrays. In
554 the current implementation, no temporary array is created when the
555 range operator is used as the expression in C<foreach> loops, but older
556 versions of Perl might burn a lot of memory when you write something
557 like this:
558
559     for (1 .. 1_000_000) {
560         # code
561     }
562
563 The range operator also works on strings, using the magical
564 auto-increment, see below.
565
566 In scalar context, ".." returns a boolean value.  The operator is
567 bistable, like a flip-flop, and emulates the line-range (comma)
568 operator of B<sed>, B<awk>, and various editors. Each ".." operator
569 maintains its own boolean state, even across calls to a subroutine
570 that contains it. It is false as long as its left operand is false.
571 Once the left operand is true, the range operator stays true until the
572 right operand is true, I<AFTER> which the range operator becomes false
573 again.  It doesn't become false till the next time the range operator
574 is evaluated.  It can test the right operand and become false on the
575 same evaluation it became true (as in B<awk>), but it still returns
576 true once. If you don't want it to test the right operand until the
577 next evaluation, as in B<sed>, just use three dots ("...") instead of
578 two.  In all other regards, "..." behaves just like ".." does.
579
580 The right operand is not evaluated while the operator is in the
581 "false" state, and the left operand is not evaluated while the
582 operator is in the "true" state.  The precedence is a little lower
583 than || and &&.  The value returned is either the empty string for
584 false, or a sequence number (beginning with 1) for true.  The sequence
585 number is reset for each range encountered.  The final sequence number
586 in a range has the string "E0" appended to it, which doesn't affect
587 its numeric value, but gives you something to search for if you want
588 to exclude the endpoint.  You can exclude the beginning point by
589 waiting for the sequence number to be greater than 1.
590
591 If either operand of scalar ".." is a constant expression,
592 that operand is considered true if it is equal (C<==>) to the current
593 input line number (the C<$.> variable).
594
595 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
596 but that is only an issue if you use a floating point expression; when
597 implicitly using C<$.> as described in the previous paragraph, the
598 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
599 is set to a floating point value and you are not reading from a file.
600 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
601 you want in scalar context because each of the operands are evaluated
602 using their integer representation.
603
604 Examples:
605
606 As a scalar operator:
607
608     if (101 .. 200) { print; } # print 2nd hundred lines, short for
609                                #  if ($. == 101 .. $. == 200) { print; }
610
611     next LINE if (1 .. /^$/);  # skip header lines, short for
612                                #   next LINE if ($. == 1 .. /^$/);
613                                # (typically in a loop labeled LINE)
614
615     s/^/> / if (/^$/ .. eof());  # quote body
616
617     # parse mail messages
618     while (<>) {
619         $in_header =   1  .. /^$/;
620         $in_body   = /^$/ .. eof;
621         if ($in_header) {
622             # do something
623         } else { # in body
624             # do something else
625         }
626     } continue {
627         close ARGV if eof;             # reset $. each file
628     }
629
630 Here's a simple example to illustrate the difference between
631 the two range operators:
632
633     @lines = ("   - Foo",
634               "01 - Bar",
635               "1  - Baz",
636               "   - Quux");
637
638     foreach (@lines) {
639         if (/0/ .. /1/) {
640             print "$_\n";
641         }
642     }
643
644 This program will print only the line containing "Bar". If
645 the range operator is changed to C<...>, it will also print the
646 "Baz" line.
647
648 And now some examples as a list operator:
649
650     for (101 .. 200) { print; } # print $_ 100 times
651     @foo = @foo[0 .. $#foo];    # an expensive no-op
652     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
653
654 The range operator (in list context) makes use of the magical
655 auto-increment algorithm if the operands are strings.  You
656 can say
657
658     @alphabet = ('A' .. 'Z');
659
660 to get all normal letters of the English alphabet, or
661
662     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
663
664 to get a hexadecimal digit, or
665
666     @z2 = ('01' .. '31');  print $z2[$mday];
667
668 to get dates with leading zeros.
669
670 If the final value specified is not in the sequence that the magical
671 increment would produce, the sequence goes until the next value would
672 be longer than the final value specified.
673
674 If the initial value specified isn't part of a magical increment
675 sequence (that is, a non-empty string matching "/^[a-zA-Z]*[0-9]*\z/"),
676 only the initial value will be returned.  So the following will only
677 return an alpha:
678
679     use charnames 'greek';
680     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
681
682 To get lower-case greek letters, use this instead:
683
684     my @greek_small =  map { chr } ( ord("\N{alpha}") ..
685                                                      ord("\N{omega}") );
686
687 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
688 return two elements in list context.
689
690     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
691
692 =head2 Conditional Operator
693 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
694
695 Ternary "?:" is the conditional operator, just as in C.  It works much
696 like an if-then-else.  If the argument before the ? is true, the
697 argument before the : is returned, otherwise the argument after the :
698 is returned.  For example:
699
700     printf "I have %d dog%s.\n", $n,
701             ($n == 1) ? '' : "s";
702
703 Scalar or list context propagates downward into the 2nd
704 or 3rd argument, whichever is selected.
705
706     $a = $ok ? $b : $c;  # get a scalar
707     @a = $ok ? @b : @c;  # get an array
708     $a = $ok ? @b : @c;  # oops, that's just a count!
709
710 The operator may be assigned to if both the 2nd and 3rd arguments are
711 legal lvalues (meaning that you can assign to them):
712
713     ($a_or_b ? $a : $b) = $c;
714
715 Because this operator produces an assignable result, using assignments
716 without parentheses will get you in trouble.  For example, this:
717
718     $a % 2 ? $a += 10 : $a += 2
719
720 Really means this:
721
722     (($a % 2) ? ($a += 10) : $a) += 2
723
724 Rather than this:
725
726     ($a % 2) ? ($a += 10) : ($a += 2)
727
728 That should probably be written more simply as:
729
730     $a += ($a % 2) ? 10 : 2;
731
732 =head2 Assignment Operators
733 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
734 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
735 X<%=> X<^=> X<x=>
736
737 "=" is the ordinary assignment operator.
738
739 Assignment operators work as in C.  That is,
740
741     $a += 2;
742
743 is equivalent to
744
745     $a = $a + 2;
746
747 although without duplicating any side effects that dereferencing the lvalue
748 might trigger, such as from tie().  Other assignment operators work similarly.
749 The following are recognized:
750
751     **=    +=    *=    &=    <<=    &&=
752            -=    /=    |=    >>=    ||=
753            .=    %=    ^=           //=
754                  x=
755
756 Although these are grouped by family, they all have the precedence
757 of assignment.
758
759 Unlike in C, the scalar assignment operator produces a valid lvalue.
760 Modifying an assignment is equivalent to doing the assignment and
761 then modifying the variable that was assigned to.  This is useful
762 for modifying a copy of something, like this:
763
764     ($tmp = $global) =~ tr [A-Z] [a-z];
765
766 Likewise,
767
768     ($a += 2) *= 3;
769
770 is equivalent to
771
772     $a += 2;
773     $a *= 3;
774
775 Similarly, a list assignment in list context produces the list of
776 lvalues assigned to, and a list assignment in scalar context returns
777 the number of elements produced by the expression on the right hand
778 side of the assignment.
779
780 =head2 Comma Operator
781 X<comma> X<operator, comma> X<,>
782
783 Binary "," is the comma operator.  In scalar context it evaluates
784 its left argument, throws that value away, then evaluates its right
785 argument and returns that value.  This is just like C's comma operator.
786
787 In list context, it's just the list argument separator, and inserts
788 both its arguments into the list.  These arguments are also evaluated
789 from left to right.
790
791 The C<< => >> operator is a synonym for the comma except that it causes
792 its left operand to be interpreted as a string if it begins with a letter
793 or underscore and is composed only of letters, digits and underscores.
794 This includes operands that might otherwise be interpreted as operators,
795 constants, single number v-strings or function calls. If in doubt about
796 this behaviour, the left operand can be quoted explicitly.
797
798 Otherwise, the C<< => >> operator behaves exactly as the comma operator
799 or list argument separator, according to context.
800
801 For example:
802
803     use constant FOO => "something";
804
805     my %h = ( FOO => 23 );
806
807 is equivalent to:
808
809     my %h = ("FOO", 23);
810
811 It is I<NOT>:
812
813     my %h = ("something", 23);
814
815 The C<< => >> operator is helpful in documenting the correspondence
816 between keys and values in hashes, and other paired elements in lists.
817
818         %hash = ( $key => $value );
819         login( $username => $password );
820
821 =head2 Yada Yada Operator
822 X<...> X<... operator> X<yada yada operator>
823
824 The yada yada operator (noted C<...>) is a placeholder for code. Perl
825 parses it without error, but when you try to execute a yada yada, it
826 throws an exception with the text C<Unimplemented>:
827
828         sub unimplemented { ... }
829         
830         eval { unimplemented() };
831         if( $@ eq 'Unimplemented' ) {
832           print "I found the yada yada!\n";
833           }
834
835 You can only use the yada yada to stand in for a complete statement.
836 These examples of the yada yada work:
837
838         { ... }
839         
840         sub foo { ... }
841         
842         ...;
843         
844         eval { ... };
845         
846         sub foo {
847                         my( $self ) = shift;
848                         
849                         ...;
850                         }
851                         
852         do { my $n; ...; print 'Hurrah!' };
853
854 The yada yada cannot stand in for an expression that is part of a
855 larger statement since the C<...> is also the three-dot version of the
856 range operator (see L<Range Operators>). These examples of the yada
857 yada are still syntax errors:
858
859         print ...;
860         
861         open my($fh), '>', '/dev/passwd' or ...;
862         
863         if( $condition && ... ) { print "Hello\n" };
864
865 There are some cases where Perl can't immediately tell the difference
866 between an expression and a statement. For instance, the syntax for a
867 block and an anonymous hash reference constructor look the same unless
868 there's something in the braces that give Perl a hint. The yada yada
869 is a syntax error if Perl doesn't guess that the C<{ ... }> is a
870 block. In that case, it doesn't think the C<...> is the yada yada
871 because it's expecting an expression instead of a statement:
872
873         my @transformed = map { ... } @input;  # syntax error
874
875 You can use a C<;> inside your block to denote that the C<{ ... }> is
876 a block and not a hash reference constructor. Now the yada yada works:
877
878         my @transformed = map {; ... } @input; # ; disambiguates
879
880         my @transformed = map { ...; } @input; # ; disambiguates
881
882 =head2 List Operators (Rightward)
883 X<operator, list, rightward> X<list operator>
884
885 On the right side of a list operator, it has very low precedence,
886 such that it controls all comma-separated expressions found there.
887 The only operators with lower precedence are the logical operators
888 "and", "or", and "not", which may be used to evaluate calls to list
889 operators without the need for extra parentheses:
890
891     open HANDLE, "filename"
892         or die "Can't open: $!\n";
893
894 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
895
896 =head2 Logical Not
897 X<operator, logical, not> X<not>
898
899 Unary "not" returns the logical negation of the expression to its right.
900 It's the equivalent of "!" except for the very low precedence.
901
902 =head2 Logical And
903 X<operator, logical, and> X<and>
904
905 Binary "and" returns the logical conjunction of the two surrounding
906 expressions.  It's equivalent to && except for the very low
907 precedence.  This means that it short-circuits: i.e., the right
908 expression is evaluated only if the left expression is true.
909
910 =head2 Logical or, Defined or, and Exclusive Or
911 X<operator, logical, or> X<operator, logical, xor>
912 X<operator, logical, defined or> X<operator, logical, exclusive or>
913 X<or> X<xor>
914
915 Binary "or" returns the logical disjunction of the two surrounding
916 expressions.  It's equivalent to || except for the very low precedence.
917 This makes it useful for control flow
918
919     print FH $data              or die "Can't write to FH: $!";
920
921 This means that it short-circuits: i.e., the right expression is evaluated
922 only if the left expression is false.  Due to its precedence, you should
923 probably avoid using this for assignment, only for control flow.
924
925     $a = $b or $c;              # bug: this is wrong
926     ($a = $b) or $c;            # really means this
927     $a = $b || $c;              # better written this way
928
929 However, when it's a list-context assignment and you're trying to use
930 "||" for control flow, you probably need "or" so that the assignment
931 takes higher precedence.
932
933     @info = stat($file) || die;     # oops, scalar sense of stat!
934     @info = stat($file) or die;     # better, now @info gets its due
935
936 Then again, you could always use parentheses.
937
938 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
939 It cannot short circuit, of course.
940
941 =head2 C Operators Missing From Perl
942 X<operator, missing from perl> X<&> X<*>
943 X<typecasting> X<(TYPE)>
944
945 Here is what C has that Perl doesn't:
946
947 =over 8
948
949 =item unary &
950
951 Address-of operator.  (But see the "\" operator for taking a reference.)
952
953 =item unary *
954
955 Dereference-address operator. (Perl's prefix dereferencing
956 operators are typed: $, @, %, and &.)
957
958 =item (TYPE)
959
960 Type-casting operator.
961
962 =back
963
964 =head2 Quote and Quote-like Operators
965 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
966 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
967 X<escape sequence> X<escape>
968
969
970 While we usually think of quotes as literal values, in Perl they
971 function as operators, providing various kinds of interpolating and
972 pattern matching capabilities.  Perl provides customary quote characters
973 for these behaviors, but also provides a way for you to choose your
974 quote character for any of them.  In the following table, a C<{}> represents
975 any pair of delimiters you choose.
976
977     Customary  Generic        Meaning        Interpolates
978         ''       q{}          Literal             no
979         ""      qq{}          Literal             yes
980         ``      qx{}          Command             yes*
981                 qw{}         Word list            no
982         //       m{}       Pattern match          yes*
983                 qr{}          Pattern             yes*
984                  s{}{}      Substitution          yes*
985                 tr{}{}    Transliteration         no (but see below)
986         <<EOF                 here-doc            yes*
987
988         * unless the delimiter is ''.
989
990 Non-bracketing delimiters use the same character fore and aft, but the four
991 sorts of brackets (round, angle, square, curly) will all nest, which means
992 that
993
994         q{foo{bar}baz}
995
996 is the same as
997
998         'foo{bar}baz'
999
1000 Note, however, that this does not always work for quoting Perl code:
1001
1002         $s = q{ if($a eq "}") ... }; # WRONG
1003
1004 is a syntax error. The C<Text::Balanced> module (from CPAN, and
1005 starting from Perl 5.8 part of the standard distribution) is able
1006 to do this properly.
1007
1008 There can be whitespace between the operator and the quoting
1009 characters, except when C<#> is being used as the quoting character.
1010 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
1011 operator C<q> followed by a comment.  Its argument will be taken
1012 from the next line.  This allows you to write:
1013
1014     s {foo}  # Replace foo
1015       {bar}  # with bar.
1016
1017 The following escape sequences are available in constructs that interpolate
1018 and in transliterations.
1019 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1020 X<\o{}>
1021
1022     Sequence     Note  Description
1023     \t                  tab               (HT, TAB)
1024     \n                  newline           (NL)
1025     \r                  return            (CR)
1026     \f                  form feed         (FF)
1027     \b                  backspace         (BS)
1028     \a                  alarm (bell)      (BEL)
1029     \e                  escape            (ESC)
1030     \x{263a}     [1,8]  hex char          (example: SMILEY)
1031     \x1b         [2,8]  restricted range hex char (example: ESC)
1032     \N{name}     [3]    named Unicode character
1033     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1034     \c[          [5]    control char      (example: chr(27))
1035     \o{23072}    [6,8]  octal char        (example: SMILEY)
1036     \033         [7,8]  restricted range octal char  (example: ESC)
1037
1038 =over 4
1039
1040 =item [1]
1041
1042 The result is the character specified by the hexadecimal number between
1043 the braces.  See L</[8]> below for details on which character.
1044
1045 Only hexadecimal digits are valid between the braces. If an invalid
1046 character is encountered, a warning will be issued and the invalid
1047 character and all subsequent characters (valid or invalid) within the
1048 braces will be discarded.
1049
1050 If there are no valid digits between the braces, the generated character is
1051 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1052 will not cause a warning.
1053
1054 =item [2]
1055
1056 The result is the character specified by the hexadecimal number in the range
1057 0x00 to 0xFF.  See L</[8]> below for details on which character.
1058
1059 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1060 by fewer than two valid digits, any valid digits will be zero-padded.  This
1061 means that C<\x7> will be interpreted as C<\x07> and C<\x> alone will be
1062 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1063 two valid digits will result in a warning.  Note that while the warning
1064 says the illegal character is ignored, it is only ignored as part of the
1065 escape and will still be used as the subsequent character in the string.
1066 For example:
1067
1068   Original    Result    Warns?
1069   "\x7"       "\x07"    no
1070   "\x"        "\x00"    no
1071   "\x7q"      "\x07q"   yes
1072   "\xq"       "\x00q"   yes
1073
1074 =item [3]
1075
1076 The result is the Unicode character given by I<name>.
1077 See L<charnames>.
1078
1079 =item [4]
1080
1081 C<\N{U+I<hexadecimal number>}> means the Unicode character whose Unicode code
1082 point is I<hexadecimal number>.
1083
1084 =item [5]
1085
1086 The character following C<\c> is mapped to some other character as shown in the
1087 table:
1088
1089  Sequence   Value
1090    \c@      chr(0)
1091    \cA      chr(1)
1092    \ca      chr(1)
1093    \cB      chr(2)
1094    \cb      chr(2)
1095    ...
1096    \cZ      chr(26)
1097    \cz      chr(26)
1098    \c[      chr(27)
1099    \c]      chr(29)
1100    \c^      chr(30)
1101    \c?      chr(127)
1102
1103 Also, C<\c\I<X>> yields C< chr(28) . "I<X>"> for any I<X>, but cannot come at the
1104 end of a string, because the backslash would be parsed as escaping the end
1105 quote.
1106
1107 On ASCII platforms, the resulting characters from the list above are the
1108 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1109 L<perlebcdic/OPERATOR DIFFERENCES> for the complete list of what these
1110 sequences mean on both ASCII and EBCDIC platforms.
1111
1112 Use of any other character following the "c" besides those listed above is
1113 discouraged, and may become deprecated or forbidden.  What happens for those
1114 other characters currently though, is that the value is derived by inverting
1115 the 7th bit (0x40).
1116
1117 To get platform independent controls, you can use C<\N{...}>.
1118
1119 =item [6]
1120
1121 The result is the character specified by the octal number between the braces.
1122 See L</[8]> below for details on which character.
1123
1124 If a character that isn't an octal digit is encountered, a warning is raised,
1125 and the value is based on the octal digits before it, discarding it and all
1126 following characters up to the closing brace.  It is a fatal error if there are
1127 no octal digits at all.
1128
1129 =item [7]
1130
1131 The result is the character specified by the three digit octal number in the
1132 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1133 L</[8]> below for details on which character.
1134
1135 Some contexts allow 2 or even 1 digit, but any usage without exactly
1136 three digits, the first being a zero, may give unintended results.  (For
1137 example, see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1138 use C<\o{}> instead which avoids all these problems.  Otherwise, it is best to
1139 use this construct only for ordinals C<\077> and below, remembering to pad to
1140 the left with zeros to make three digits.  For larger ordinals, either use
1141 C<\o{}> , or convert to someething else, such as to hex and use C<\x{}>
1142 instead.
1143
1144 A backslash followed by a non-octal digit in a bracketed character class
1145 (C<[\8]> or C<[\9]>) will be interpreted as a NULL character and the digit.
1146
1147 Having fewer than 3 digits may lead to a misleading warning message that says
1148 that what follows is ignored.  For example, C<"\128"> in the ASCII character set
1149 is equivalent to the two characters C<"\n8">, but the warning C<Illegal octal
1150 digit '8' ignored> will be thrown.  To avoid this warning, make sure to pad
1151 your octal number with C<0>s: C<"\0128">.
1152
1153 =item [8]
1154
1155 Several of the constructs above specify a character by a number.  That number
1156 gives the character's position in the character set encoding (indexed from 0).
1157 This is called synonymously its ordinal, code position, or code point).  Perl
1158 works on platforms that have a native encoding currently of either ASCII/Latin1
1159 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1160 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1161 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1162 it as as a Unicode code point and the result is the corresponding Unicode
1163 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1164 decimal, which is less than 256, so the number is interpreted in the native
1165 character set encoding.  In ASCII the character in the 80th position (indexed
1166 from 0) is the letter "P", and in EBCDIC it is the ampersand symbol "&".
1167 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1168 as a Unicode code point no matter what the native encoding is.  The name of the
1169 character in the 100th position (indexed by 0) in Unicode is
1170 C<LATIN CAPITAL LETTER A WITH MACRON>.
1171
1172 There are a couple of exceptions to the above rule.  C<\N{U+I<hex number>}> is
1173 always interpreted as a Unicode code point, so that C<\N{U+0050}> is "P" even
1174 on EBCDIC platforms.  And if L<C<S<use encoding>>|encoding> is in effect, the
1175 number is considered to be in that encoding, and is translated from that into
1176 the platform's native encoding if there is a corresponding native character;
1177 otherwise to Unicode.
1178
1179 =back
1180
1181 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1182 the vertical tab (VT - ASCII 11), but you may use C<\ck> or C<\x0b>.  (C<\v>
1183 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1184
1185 The following escape sequences are available in constructs that interpolate,
1186 but not in transliterations.
1187 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
1188
1189     \l          lowercase next char
1190     \u          uppercase next char
1191     \L          lowercase till \E
1192     \U          uppercase till \E
1193     \E          end case modification
1194     \Q          quote non-word characters till \E
1195
1196 If C<use locale> is in effect, the case map used by C<\l>, C<\L>,
1197 C<\u> and C<\U> is taken from the current locale.  See L<perllocale>.
1198 If Unicode (for example, C<\N{}> or wide hex characters of 0x100 or
1199 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u> and
1200 C<\U> is as defined by Unicode.
1201
1202 All systems use the virtual C<"\n"> to represent a line terminator,
1203 called a "newline".  There is no such thing as an unvarying, physical
1204 newline character.  It is only an illusion that the operating system,
1205 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1206 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1207 on a Mac, these are reversed, and on systems without line terminator,
1208 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
1209 you mean a "newline" for your system, but use the literal ASCII when you
1210 need an exact character.  For example, most networking protocols expect
1211 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1212 and although they often accept just C<"\012">, they seldom tolerate just
1213 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1214 you may be burned some day.
1215 X<newline> X<line terminator> X<eol> X<end of line>
1216 X<\n> X<\r> X<\r\n>
1217
1218 For constructs that do interpolate, variables beginning with "C<$>"
1219 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1220 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1221 But method calls such as C<< $obj->meth >> are not.
1222
1223 Interpolating an array or slice interpolates the elements in order,
1224 separated by the value of C<$">, so is equivalent to interpolating
1225 C<join $", @array>.    "Punctuation" arrays such as C<@*> are only
1226 interpolated if the name is enclosed in braces C<@{*}>, but special
1227 arrays C<@_>, C<@+>, and C<@-> are interpolated, even without braces.
1228
1229 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
1230 An unescaped C<$> or C<@> interpolates the corresponding variable,
1231 while escaping will cause the literal string C<\$> to be inserted.
1232 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
1233
1234 Patterns are subject to an additional level of interpretation as a
1235 regular expression.  This is done as a second pass, after variables are
1236 interpolated, so that regular expressions may be incorporated into the
1237 pattern from the variables.  If this is not what you want, use C<\Q> to
1238 interpolate a variable literally.
1239
1240 Apart from the behavior described above, Perl does not expand
1241 multiple levels of interpolation.  In particular, contrary to the
1242 expectations of shell programmers, back-quotes do I<NOT> interpolate
1243 within double quotes, nor do single quotes impede evaluation of
1244 variables when used within double quotes.
1245
1246 =head2 Regexp Quote-Like Operators
1247 X<operator, regexp>
1248
1249 Here are the quote-like operators that apply to pattern
1250 matching and related activities.
1251
1252 =over 8
1253
1254 =item qr/STRING/msixpo
1255 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1256
1257 This operator quotes (and possibly compiles) its I<STRING> as a regular
1258 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1259 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1260 is done.  Returns a Perl value which may be used instead of the
1261 corresponding C</STRING/msixpo> expression. The returned value is a
1262 normalized version of the original pattern. It magically differs from
1263 a string containing the same characters: C<ref(qr/x/)> returns "Regexp",
1264 even though dereferencing the result returns undef.
1265
1266 For example,
1267
1268     $rex = qr/my.STRING/is;
1269     print $rex;                 # prints (?si-xm:my.STRING)
1270     s/$rex/foo/;
1271
1272 is equivalent to
1273
1274     s/my.STRING/foo/is;
1275
1276 The result may be used as a subpattern in a match:
1277
1278     $re = qr/$pattern/;
1279     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
1280     $string =~ $re;             # or used standalone
1281     $string =~ /$re/;           # or this way
1282
1283 Since Perl may compile the pattern at the moment of execution of qr()
1284 operator, using qr() may have speed advantages in some situations,
1285 notably if the result of qr() is used standalone:
1286
1287     sub match {
1288         my $patterns = shift;
1289         my @compiled = map qr/$_/i, @$patterns;
1290         grep {
1291             my $success = 0;
1292             foreach my $pat (@compiled) {
1293                 $success = 1, last if /$pat/;
1294             }
1295             $success;
1296         } @_;
1297     }
1298
1299 Precompilation of the pattern into an internal representation at
1300 the moment of qr() avoids a need to recompile the pattern every
1301 time a match C</$pat/> is attempted.  (Perl has many other internal
1302 optimizations, but none would be triggered in the above example if
1303 we did not use qr() operator.)
1304
1305 Options are:
1306
1307     m   Treat string as multiple lines.
1308     s   Treat string as single line. (Make . match a newline)
1309     i   Do case-insensitive pattern matching.
1310     x   Use extended regular expressions.
1311     p   When matching preserve a copy of the matched string so
1312         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be defined.
1313     o   Compile pattern only once.
1314
1315 If a precompiled pattern is embedded in a larger pattern then the effect
1316 of 'msixp' will be propagated appropriately.  The effect of the 'o'
1317 modifier has is not propagated, being restricted to those patterns
1318 explicitly using it.
1319
1320 See L<perlre> for additional information on valid syntax for STRING, and
1321 for a detailed look at the semantics of regular expressions.
1322
1323 =item m/PATTERN/msixpogc
1324 X<m> X<operator, match>
1325 X<regexp, options> X<regexp> X<regex, options> X<regex>
1326 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1327
1328 =item /PATTERN/msixpogc
1329
1330 Searches a string for a pattern match, and in scalar context returns
1331 true if it succeeds, false if it fails.  If no string is specified
1332 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1333 string specified with C<=~> need not be an lvalue--it may be the
1334 result of an expression evaluation, but remember the C<=~> binds
1335 rather tightly.)  See also L<perlre>.  See L<perllocale> for
1336 discussion of additional considerations that apply when C<use locale>
1337 is in effect.
1338
1339 Options are as described in C<qr//>; in addition, the following match
1340 process modifiers are available:
1341
1342  g  Match globally, i.e., find all occurrences.
1343  c  Do not reset search position on a failed match when /g is in effect.
1344
1345 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1346 you can use any pair of non-whitespace characters
1347 as delimiters.  This is particularly useful for matching path names
1348 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1349 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
1350 If "'" is the delimiter, no interpolation is performed on the PATTERN.
1351 When using a character valid in an identifier, whitespace is required
1352 after the C<m>.
1353
1354 PATTERN may contain variables, which will be interpolated (and the
1355 pattern recompiled) every time the pattern search is evaluated, except
1356 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1357 C<$|> are not interpolated because they look like end-of-string tests.)
1358 If you want such a pattern to be compiled only once, add a C</o> after
1359 the trailing delimiter.  This avoids expensive run-time recompilations,
1360 and is useful when the value you are interpolating won't change over
1361 the life of the script.  However, mentioning C</o> constitutes a promise
1362 that you won't change the variables in the pattern.  If you change them,
1363 Perl won't even notice.  See also L<"qr/STRING/msixpo">.
1364
1365 =item The empty pattern //
1366
1367 If the PATTERN evaluates to the empty string, the last
1368 I<successfully> matched regular expression is used instead. In this
1369 case, only the C<g> and C<c> flags on the empty pattern is honoured -
1370 the other flags are taken from the original pattern. If no match has
1371 previously succeeded, this will (silently) act instead as a genuine
1372 empty pattern (which will always match).
1373
1374 Note that it's possible to confuse Perl into thinking C<//> (the empty
1375 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1376 good about this, but some pathological cases might trigger this, such as
1377 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //>
1378 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl
1379 will assume you meant defined-or.  If you meant the empty regex, just
1380 use parentheses or spaces to disambiguate, or even prefix the empty
1381 regex with an C<m> (so C<//> becomes C<m//>).
1382
1383 =item Matching in list context
1384
1385 If the C</g> option is not used, C<m//> in list context returns a
1386 list consisting of the subexpressions matched by the parentheses in the
1387 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
1388 also set, and that this differs from Perl 4's behavior.)  When there are
1389 no parentheses in the pattern, the return value is the list C<(1)> for
1390 success.  With or without parentheses, an empty list is returned upon
1391 failure.
1392
1393 Examples:
1394
1395     open(TTY, '/dev/tty');
1396     <TTY> =~ /^y/i && foo();    # do foo if desired
1397
1398     if (/Version: *([0-9.]*)/) { $version = $1; }
1399
1400     next if m#^/usr/spool/uucp#;
1401
1402     # poor man's grep
1403     $arg = shift;
1404     while (<>) {
1405         print if /$arg/o;       # compile only once
1406     }
1407
1408     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1409
1410 This last example splits $foo into the first two words and the
1411 remainder of the line, and assigns those three fields to $F1, $F2, and
1412 $Etc.  The conditional is true if any variables were assigned, i.e., if
1413 the pattern matched.
1414
1415 The C</g> modifier specifies global pattern matching--that is,
1416 matching as many times as possible within the string.  How it behaves
1417 depends on the context.  In list context, it returns a list of the
1418 substrings matched by any capturing parentheses in the regular
1419 expression.  If there are no parentheses, it returns a list of all
1420 the matched strings, as if there were parentheses around the whole
1421 pattern.
1422
1423 In scalar context, each execution of C<m//g> finds the next match,
1424 returning true if it matches, and false if there is no further match.
1425 The position after the last match can be read or set using the pos()
1426 function; see L<perlfunc/pos>.   A failed match normally resets the
1427 search position to the beginning of the string, but you can avoid that
1428 by adding the C</c> modifier (e.g. C<m//gc>).  Modifying the target
1429 string also resets the search position.
1430
1431 =item \G assertion
1432
1433 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1434 zero-width assertion that matches the exact position where the previous
1435 C<m//g>, if any, left off.  Without the C</g> modifier, the C<\G> assertion
1436 still anchors at pos(), but the match is of course only attempted once.
1437 Using C<\G> without C</g> on a target string that has not previously had a
1438 C</g> match applied to it is the same as using the C<\A> assertion to match
1439 the beginning of the string.  Note also that, currently, C<\G> is only
1440 properly supported when anchored at the very beginning of the pattern.
1441
1442 Examples:
1443
1444     # list context
1445     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1446
1447     # scalar context
1448     $/ = "";
1449     while (defined($paragraph = <>)) {
1450         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
1451             $sentences++;
1452         }
1453     }
1454     print "$sentences\n";
1455
1456     # using m//gc with \G
1457     $_ = "ppooqppqq";
1458     while ($i++ < 2) {
1459         print "1: '";
1460         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1461         print "2: '";
1462         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1463         print "3: '";
1464         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1465     }
1466     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1467
1468 The last example should print:
1469
1470     1: 'oo', pos=4
1471     2: 'q', pos=5
1472     3: 'pp', pos=7
1473     1: '', pos=7
1474     2: 'q', pos=8
1475     3: '', pos=8
1476     Final: 'q', pos=8
1477
1478 Notice that the final match matched C<q> instead of C<p>, which a match
1479 without the C<\G> anchor would have done. Also note that the final match
1480 did not update C<pos>. C<pos> is only updated on a C</g> match. If the
1481 final match did indeed match C<p>, it's a good bet that you're running an
1482 older (pre-5.6.0) Perl.
1483
1484 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1485 combine several regexps like this to process a string part-by-part,
1486 doing different actions depending on which regexp matched.  Each
1487 regexp tries to match where the previous one leaves off.
1488
1489  $_ = <<'EOL';
1490     $url = URI::URL->new( "http://example.com/" ); die if $url eq "xXx";
1491  EOL
1492  LOOP:
1493     {
1494      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1495      print(" lowercase"),    redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
1496      print(" UPPERCASE"),    redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
1497      print(" Capitalized"),  redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
1498      print(" MiXeD"),        redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
1499      print(" alphanumeric"), redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
1500      print(" line-noise"),   redo LOOP if /\G[^A-Za-z0-9]+/gc;
1501      print ". That's all!\n";
1502     }
1503
1504 Here is the output (split into several lines):
1505
1506  line-noise lowercase line-noise lowercase UPPERCASE line-noise
1507  UPPERCASE line-noise lowercase line-noise lowercase line-noise
1508  lowercase lowercase line-noise lowercase lowercase line-noise
1509  MiXeD line-noise. That's all!
1510
1511 =item ?PATTERN?
1512 X<?>
1513
1514 This is just like the C</pattern/> search, except that it matches only
1515 once between calls to the reset() operator.  This is a useful
1516 optimization when you want to see only the first occurrence of
1517 something in each file of a set of files, for instance.  Only C<??>
1518 patterns local to the current package are reset.
1519
1520     while (<>) {
1521         if (?^$?) {
1522                             # blank line between header and body
1523         }
1524     } continue {
1525         reset if eof;       # clear ?? status for next file
1526     }
1527
1528 This usage is vaguely deprecated, which means it just might possibly
1529 be removed in some distant future version of Perl, perhaps somewhere
1530 around the year 2168.
1531
1532 =item s/PATTERN/REPLACEMENT/msixpogcer
1533 X<substitute> X<substitution> X<replace> X<regexp, replace>
1534 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
1535
1536 Searches a string for a pattern, and if found, replaces that pattern
1537 with the replacement text and returns the number of substitutions
1538 made.  Otherwise it returns false (specifically, the empty string).
1539
1540 If the C</r> (non-destructive) option is used then it will perform the
1541 substitution on a copy of the string and return the copy whether or not a
1542 substitution occurred. The original string will always remain unchanged in
1543 this case. The copy will always be a plain string, even if the input is an
1544 object or a tied variable.
1545
1546 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1547 variable is searched and modified.  (The string specified with C<=~> must
1548 be scalar variable, an array element, a hash element, or an assignment
1549 to one of those, i.e., an lvalue.)
1550
1551 If the delimiter chosen is a single quote, no interpolation is
1552 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1553 PATTERN contains a $ that looks like a variable rather than an
1554 end-of-string test, the variable will be interpolated into the pattern
1555 at run-time.  If you want the pattern compiled only once the first time
1556 the variable is interpolated, use the C</o> option.  If the pattern
1557 evaluates to the empty string, the last successfully executed regular
1558 expression is used instead.  See L<perlre> for further explanation on these.
1559 See L<perllocale> for discussion of additional considerations that apply
1560 when C<use locale> is in effect.
1561
1562 Options are as with m// with the addition of the following replacement
1563 specific options:
1564
1565     e   Evaluate the right side as an expression.
1566     ee  Evaluate the right side as a string then eval the result.
1567     r   Return substitution and leave the original string untouched.
1568
1569 Any non-whitespace delimiter may replace the slashes.  Add space after
1570 the C<s> when using a character allowed in identifiers.  If single quotes
1571 are used, no interpretation is done on the replacement string (the C</e>
1572 modifier overrides this, however).  Unlike Perl 4, Perl 5 treats backticks
1573 as normal delimiters; the replacement text is not evaluated as a command.
1574 If the PATTERN is delimited by bracketing quotes, the REPLACEMENT has
1575 its own pair of quotes, which may or may not be bracketing quotes, e.g.,
1576 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
1577 replacement portion to be treated as a full-fledged Perl expression
1578 and evaluated right then and there.  It is, however, syntax checked at
1579 compile-time. A second C<e> modifier will cause the replacement portion
1580 to be C<eval>ed before being run as a Perl expression.
1581
1582 Examples:
1583
1584     s/\bgreen\b/mauve/g;                # don't change wintergreen
1585
1586     $path =~ s|/usr/bin|/usr/local/bin|;
1587
1588     s/Login: $foo/Login: $bar/; # run-time pattern
1589
1590     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1591     ($foo = "$bar") =~ s/this/that/;    # convert to string, copy, then change
1592     $foo = $bar =~ s/this/that/r;       # Same as above using /r
1593     $foo = $bar =~ s/this/that/r
1594                 =~ s/that/the other/r;  # Chained substitutes using /r
1595     @foo = map { s/this/that/r } @bar   # /r is very useful in maps
1596
1597     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1598
1599     $_ = 'abc123xyz';
1600     s/\d+/$&*2/e;               # yields 'abc246xyz'
1601     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1602     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1603
1604     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1605     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1606     s/^=(\w+)/pod($1)/ge;       # use function call
1607
1608     $_ = 'abc123xyz';
1609     $a = s/abc/def/r;           # $a is 'def123xyz' and
1610                                 # $_ remains 'abc123xyz'.
1611
1612     # expand variables in $_, but dynamics only, using
1613     # symbolic dereferencing
1614     s/\$(\w+)/${$1}/g;
1615
1616     # Add one to the value of any numbers in the string
1617     s/(\d+)/1 + $1/eg;
1618
1619     # This will expand any embedded scalar variable
1620     # (including lexicals) in $_ : First $1 is interpolated
1621     # to the variable name, and then evaluated
1622     s/(\$\w+)/$1/eeg;
1623
1624     # Delete (most) C comments.
1625     $program =~ s {
1626         /\*     # Match the opening delimiter.
1627         .*?     # Match a minimal number of characters.
1628         \*/     # Match the closing delimiter.
1629     } []gsx;
1630
1631     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_, expensively
1632
1633     for ($variable) {           # trim whitespace in $variable, cheap
1634         s/^\s+//;
1635         s/\s+$//;
1636     }
1637
1638     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1639
1640 Note the use of $ instead of \ in the last example.  Unlike
1641 B<sed>, we use the \<I<digit>> form in only the left hand side.
1642 Anywhere else it's $<I<digit>>.
1643
1644 Occasionally, you can't use just a C</g> to get all the changes
1645 to occur that you might want.  Here are two common cases:
1646
1647     # put commas in the right places in an integer
1648     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
1649
1650     # expand tabs to 8-column spacing
1651     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1652
1653 =back
1654
1655 =head2 Quote-Like Operators
1656 X<operator, quote-like>
1657
1658 =over 4
1659
1660 =item q/STRING/
1661 X<q> X<quote, single> X<'> X<''>
1662
1663 =item 'STRING'
1664
1665 A single-quoted, literal string.  A backslash represents a backslash
1666 unless followed by the delimiter or another backslash, in which case
1667 the delimiter or backslash is interpolated.
1668
1669     $foo = q!I said, "You said, 'She said it.'"!;
1670     $bar = q('This is it.');
1671     $baz = '\n';                # a two-character string
1672
1673 =item qq/STRING/
1674 X<qq> X<quote, double> X<"> X<"">
1675
1676 =item "STRING"
1677
1678 A double-quoted, interpolated string.
1679
1680     $_ .= qq
1681      (*** The previous line contains the naughty word "$1".\n)
1682                 if /\b(tcl|java|python)\b/i;      # :-)
1683     $baz = "\n";                # a one-character string
1684
1685 =item qx/STRING/
1686 X<qx> X<`> X<``> X<backtick>
1687
1688 =item `STRING`
1689
1690 A string which is (possibly) interpolated and then executed as a
1691 system command with C</bin/sh> or its equivalent.  Shell wildcards,
1692 pipes, and redirections will be honored.  The collected standard
1693 output of the command is returned; standard error is unaffected.  In
1694 scalar context, it comes back as a single (potentially multi-line)
1695 string, or undef if the command failed.  In list context, returns a
1696 list of lines (however you've defined lines with $/ or
1697 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
1698
1699 Because backticks do not affect standard error, use shell file descriptor
1700 syntax (assuming the shell supports this) if you care to address this.
1701 To capture a command's STDERR and STDOUT together:
1702
1703     $output = `cmd 2>&1`;
1704
1705 To capture a command's STDOUT but discard its STDERR:
1706
1707     $output = `cmd 2>/dev/null`;
1708
1709 To capture a command's STDERR but discard its STDOUT (ordering is
1710 important here):
1711
1712     $output = `cmd 2>&1 1>/dev/null`;
1713
1714 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1715 but leave its STDOUT to come out the old STDERR:
1716
1717     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1718
1719 To read both a command's STDOUT and its STDERR separately, it's easiest
1720 to redirect them separately to files, and then read from those files
1721 when the program is done:
1722
1723     system("program args 1>program.stdout 2>program.stderr");
1724
1725 The STDIN filehandle used by the command is inherited from Perl's STDIN.
1726 For example:
1727
1728     open BLAM, "blam" || die "Can't open: $!";
1729     open STDIN, "<&BLAM";
1730     print `sort`;
1731
1732 will print the sorted contents of the file "blam".
1733
1734 Using single-quote as a delimiter protects the command from Perl's
1735 double-quote interpolation, passing it on to the shell instead:
1736
1737     $perl_info  = qx(ps $$);            # that's Perl's $$
1738     $shell_info = qx'ps $$';            # that's the new shell's $$
1739
1740 How that string gets evaluated is entirely subject to the command
1741 interpreter on your system.  On most platforms, you will have to protect
1742 shell metacharacters if you want them treated literally.  This is in
1743 practice difficult to do, as it's unclear how to escape which characters.
1744 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1745 to emulate backticks safely.
1746
1747 On some platforms (notably DOS-like ones), the shell may not be
1748 capable of dealing with multiline commands, so putting newlines in
1749 the string may not get you what you want.  You may be able to evaluate
1750 multiple commands in a single line by separating them with the command
1751 separator character, if your shell supports that (e.g. C<;> on many Unix
1752 shells; C<&> on the Windows NT C<cmd> shell).
1753
1754 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1755 output before starting the child process, but this may not be supported
1756 on some platforms (see L<perlport>).  To be safe, you may need to set
1757 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1758 C<IO::Handle> on any open handles.
1759
1760 Beware that some command shells may place restrictions on the length
1761 of the command line.  You must ensure your strings don't exceed this
1762 limit after any necessary interpolations.  See the platform-specific
1763 release notes for more details about your particular environment.
1764
1765 Using this operator can lead to programs that are difficult to port,
1766 because the shell commands called vary between systems, and may in
1767 fact not be present at all.  As one example, the C<type> command under
1768 the POSIX shell is very different from the C<type> command under DOS.
1769 That doesn't mean you should go out of your way to avoid backticks
1770 when they're the right way to get something done.  Perl was made to be
1771 a glue language, and one of the things it glues together is commands.
1772 Just understand what you're getting yourself into.
1773
1774 See L</"I/O Operators"> for more discussion.
1775
1776 =item qw/STRING/
1777 X<qw> X<quote, list> X<quote, words>
1778
1779 Evaluates to a list of the words extracted out of STRING, using embedded
1780 whitespace as the word delimiters.  It can be understood as being roughly
1781 equivalent to:
1782
1783     split(' ', q/STRING/);
1784
1785 the differences being that it generates a real list at compile time, and
1786 in scalar context it returns the last element in the list.  So
1787 this expression:
1788
1789     qw(foo bar baz)
1790
1791 is semantically equivalent to the list:
1792
1793     'foo', 'bar', 'baz'
1794
1795 Some frequently seen examples:
1796
1797     use POSIX qw( setlocale localeconv )
1798     @EXPORT = qw( foo bar baz );
1799
1800 A common mistake is to try to separate the words with comma or to
1801 put comments into a multi-line C<qw>-string.  For this reason, the
1802 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
1803 produces warnings if the STRING contains the "," or the "#" character.
1804
1805
1806 =item tr/SEARCHLIST/REPLACEMENTLIST/cds
1807 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
1808
1809 =item y/SEARCHLIST/REPLACEMENTLIST/cds
1810
1811 Transliterates all occurrences of the characters found in the search list
1812 with the corresponding character in the replacement list.  It returns
1813 the number of characters replaced or deleted.  If no string is
1814 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1815 string specified with =~ must be a scalar variable, an array element, a
1816 hash element, or an assignment to one of those, i.e., an lvalue.)
1817
1818 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
1819 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1820 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1821 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1822 its own pair of quotes, which may or may not be bracketing quotes,
1823 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1824
1825 Note that C<tr> does B<not> do regular expression character classes
1826 such as C<\d> or C<[:lower:]>.  The C<tr> operator is not equivalent to
1827 the tr(1) utility.  If you want to map strings between lower/upper
1828 cases, see L<perlfunc/lc> and L<perlfunc/uc>, and in general consider
1829 using the C<s> operator if you need regular expressions.
1830
1831 Note also that the whole range idea is rather unportable between
1832 character sets--and even within character sets they may cause results
1833 you probably didn't expect.  A sound principle is to use only ranges
1834 that begin from and end at either alphabets of equal case (a-e, A-E),
1835 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1836 character sets in full.
1837
1838 Options:
1839
1840     c   Complement the SEARCHLIST.
1841     d   Delete found but unreplaced characters.
1842     s   Squash duplicate replaced characters.
1843
1844 If the C</c> modifier is specified, the SEARCHLIST character set
1845 is complemented.  If the C</d> modifier is specified, any characters
1846 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1847 (Note that this is slightly more flexible than the behavior of some
1848 B<tr> programs, which delete anything they find in the SEARCHLIST,
1849 period.) If the C</s> modifier is specified, sequences of characters
1850 that were transliterated to the same character are squashed down
1851 to a single instance of the character.
1852
1853 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1854 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1855 than the SEARCHLIST, the final character is replicated till it is long
1856 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1857 This latter is useful for counting characters in a class or for
1858 squashing character sequences in a class.
1859
1860 Examples:
1861
1862     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1863
1864     $cnt = tr/*/*/;             # count the stars in $_
1865
1866     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1867
1868     $cnt = tr/0-9//;            # count the digits in $_
1869
1870     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1871
1872     ($HOST = $host) =~ tr/a-z/A-Z/;
1873
1874     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1875
1876     tr [\200-\377]
1877        [\000-\177];             # delete 8th bit
1878
1879 If multiple transliterations are given for a character, only the
1880 first one is used:
1881
1882     tr/AAA/XYZ/
1883
1884 will transliterate any A to X.
1885
1886 Because the transliteration table is built at compile time, neither
1887 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1888 interpolation.  That means that if you want to use variables, you
1889 must use an eval():
1890
1891     eval "tr/$oldlist/$newlist/";
1892     die $@ if $@;
1893
1894     eval "tr/$oldlist/$newlist/, 1" or die $@;
1895
1896 =item <<EOF
1897 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
1898
1899 A line-oriented form of quoting is based on the shell "here-document"
1900 syntax.  Following a C<< << >> you specify a string to terminate
1901 the quoted material, and all lines following the current line down to
1902 the terminating string are the value of the item.
1903
1904 The terminating string may be either an identifier (a word), or some
1905 quoted text.  An unquoted identifier works like double quotes.
1906 There may not be a space between the C<< << >> and the identifier,
1907 unless the identifier is explicitly quoted.  (If you put a space it
1908 will be treated as a null identifier, which is valid, and matches the
1909 first empty line.)  The terminating string must appear by itself
1910 (unquoted and with no surrounding whitespace) on the terminating line.
1911
1912 If the terminating string is quoted, the type of quotes used determine
1913 the treatment of the text.
1914
1915 =over 4
1916
1917 =item Double Quotes
1918
1919 Double quotes indicate that the text will be interpolated using exactly
1920 the same rules as normal double quoted strings.
1921
1922        print <<EOF;
1923     The price is $Price.
1924     EOF
1925
1926        print << "EOF"; # same as above
1927     The price is $Price.
1928     EOF
1929
1930
1931 =item Single Quotes
1932
1933 Single quotes indicate the text is to be treated literally with no
1934 interpolation of its content. This is similar to single quoted
1935 strings except that backslashes have no special meaning, with C<\\>
1936 being treated as two backslashes and not one as they would in every
1937 other quoting construct.
1938
1939 This is the only form of quoting in perl where there is no need
1940 to worry about escaping content, something that code generators
1941 can and do make good use of.
1942
1943 =item Backticks
1944
1945 The content of the here doc is treated just as it would be if the
1946 string were embedded in backticks. Thus the content is interpolated
1947 as though it were double quoted and then executed via the shell, with
1948 the results of the execution returned.
1949
1950        print << `EOC`; # execute command and get results
1951     echo hi there
1952     EOC
1953
1954 =back
1955
1956 It is possible to stack multiple here-docs in a row:
1957
1958        print <<"foo", <<"bar"; # you can stack them
1959     I said foo.
1960     foo
1961     I said bar.
1962     bar
1963
1964        myfunc(<< "THIS", 23, <<'THAT');
1965     Here's a line
1966     or two.
1967     THIS
1968     and here's another.
1969     THAT
1970
1971 Just don't forget that you have to put a semicolon on the end
1972 to finish the statement, as Perl doesn't know you're not going to
1973 try to do this:
1974
1975        print <<ABC
1976     179231
1977     ABC
1978        + 20;
1979
1980 If you want to remove the line terminator from your here-docs,
1981 use C<chomp()>.
1982
1983     chomp($string = <<'END');
1984     This is a string.
1985     END
1986
1987 If you want your here-docs to be indented with the rest of the code,
1988 you'll need to remove leading whitespace from each line manually:
1989
1990     ($quote = <<'FINIS') =~ s/^\s+//gm;
1991        The Road goes ever on and on,
1992        down from the door where it began.
1993     FINIS
1994
1995 If you use a here-doc within a delimited construct, such as in C<s///eg>,
1996 the quoted material must come on the lines following the final delimiter.
1997 So instead of
1998
1999     s/this/<<E . 'that'
2000     the other
2001     E
2002      . 'more '/eg;
2003
2004 you have to write
2005
2006     s/this/<<E . 'that'
2007      . 'more '/eg;
2008     the other
2009     E
2010
2011 If the terminating identifier is on the last line of the program, you
2012 must be sure there is a newline after it; otherwise, Perl will give the
2013 warning B<Can't find string terminator "END" anywhere before EOF...>.
2014
2015 Additionally, the quoting rules for the end of string identifier are not
2016 related to Perl's quoting rules. C<q()>, C<qq()>, and the like are not
2017 supported in place of C<''> and C<"">, and the only interpolation is for
2018 backslashing the quoting character:
2019
2020     print << "abc\"def";
2021     testing...
2022     abc"def
2023
2024 Finally, quoted strings cannot span multiple lines.  The general rule is
2025 that the identifier must be a string literal.  Stick with that, and you
2026 should be safe.
2027
2028 =back
2029
2030 =head2 Gory details of parsing quoted constructs
2031 X<quote, gory details>
2032
2033 When presented with something that might have several different
2034 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2035 principle to pick the most probable interpretation.  This strategy
2036 is so successful that Perl programmers often do not suspect the
2037 ambivalence of what they write.  But from time to time, Perl's
2038 notions differ substantially from what the author honestly meant.
2039
2040 This section hopes to clarify how Perl handles quoted constructs.
2041 Although the most common reason to learn this is to unravel labyrinthine
2042 regular expressions, because the initial steps of parsing are the
2043 same for all quoting operators, they are all discussed together.
2044
2045 The most important Perl parsing rule is the first one discussed
2046 below: when processing a quoted construct, Perl first finds the end
2047 of that construct, then interprets its contents.  If you understand
2048 this rule, you may skip the rest of this section on the first
2049 reading.  The other rules are likely to contradict the user's
2050 expectations much less frequently than this first one.
2051
2052 Some passes discussed below are performed concurrently, but because
2053 their results are the same, we consider them individually.  For different
2054 quoting constructs, Perl performs different numbers of passes, from
2055 one to four, but these passes are always performed in the same order.
2056
2057 =over 4
2058
2059 =item Finding the end
2060
2061 The first pass is finding the end of the quoted construct, where
2062 the information about the delimiters is used in parsing.
2063 During this search, text between the starting and ending delimiters
2064 is copied to a safe location. The text copied gets delimiter-independent.
2065
2066 If the construct is a here-doc, the ending delimiter is a line
2067 that has a terminating string as the content. Therefore C<<<EOF> is
2068 terminated by C<EOF> immediately followed by C<"\n"> and starting
2069 from the first column of the terminating line.
2070 When searching for the terminating line of a here-doc, nothing
2071 is skipped. In other words, lines after the here-doc syntax
2072 are compared with the terminating string line by line.
2073
2074 For the constructs except here-docs, single characters are used as starting
2075 and ending delimiters. If the starting delimiter is an opening punctuation
2076 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2077 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2078 If the starting delimiter is an unpaired character like C</> or a closing
2079 punctuation, the ending delimiter is same as the starting delimiter.
2080 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2081 C<qq[]> and C<qq]]> constructs.
2082
2083 When searching for single-character delimiters, escaped delimiters
2084 and C<\\> are skipped. For example, while searching for terminating C</>,
2085 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2086 bracketing, nested pairs are also skipped.  For example, while searching
2087 for closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2088 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2089 However, when backslashes are used as the delimiters (like C<qq\\> and
2090 C<tr\\\>), nothing is skipped.
2091 During the search for the end, backslashes that escape delimiters
2092 are removed (exactly speaking, they are not copied to the safe location).
2093
2094 For constructs with three-part delimiters (C<s///>, C<y///>, and
2095 C<tr///>), the search is repeated once more.
2096 If the first delimiter is not an opening punctuation, three delimiters must
2097 be same such as C<s!!!> and C<tr)))>, in which case the second delimiter
2098 terminates the left part and starts the right part at once.
2099 If the left part is delimited by bracketing punctuations (that is C<()>,
2100 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2101 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespaces
2102 and comments are allowed between both parts, though the comment must follow
2103 at least one whitespace; otherwise a character expected as the start of
2104 the comment may be regarded as the starting delimiter of the right part.
2105
2106 During this search no attention is paid to the semantics of the construct.
2107 Thus:
2108
2109     "$hash{"$foo/$bar"}"
2110
2111 or:
2112
2113     m/
2114       bar       # NOT a comment, this slash / terminated m//!
2115      /x
2116
2117 do not form legal quoted expressions.   The quoted part ends on the
2118 first C<"> and C</>, and the rest happens to be a syntax error.
2119 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2120 the example above is not C<m//x>, but rather C<m//> with no C</x>
2121 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2122
2123 Also no attention is paid to C<\c\> (multichar control char syntax) during
2124 this search. Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2125 of C<\/>, and the following C</> is not recognized as a delimiter.
2126 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2127
2128 =item Interpolation
2129 X<interpolation>
2130
2131 The next step is interpolation in the text obtained, which is now
2132 delimiter-independent.  There are multiple cases.
2133
2134 =over 4
2135
2136 =item C<<<'EOF'>
2137
2138 No interpolation is performed.
2139 Note that the combination C<\\> is left intact, since escaped delimiters
2140 are not available for here-docs.
2141
2142 =item  C<m''>, the pattern of C<s'''>
2143
2144 No interpolation is performed at this stage.
2145 Any backslashed sequences including C<\\> are treated at the stage
2146 to L</"parsing regular expressions">.
2147
2148 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2149
2150 The only interpolation is removal of C<\> from pairs of C<\\>.
2151 Therefore C<-> in C<tr'''> and C<y'''> is treated literally
2152 as a hyphen and no character range is available.
2153 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2154
2155 =item C<tr///>, C<y///>
2156
2157 No variable interpolation occurs.  String modifying combinations for
2158 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2159 The other escape sequences such as C<\200> and C<\t> and backslashed
2160 characters such as C<\\> and C<\-> are converted to appropriate literals.
2161 The character C<-> is treated specially and therefore C<\-> is treated
2162 as a literal C<->.
2163
2164 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2165
2166 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
2167 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2168 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
2169 The other escape sequences such as C<\200> and C<\t> and backslashed
2170 characters such as C<\\> and C<\-> are replaced with appropriate
2171 expansions.
2172
2173 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2174 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2175 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
2176 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2177 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2178 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2179 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2180
2181   $str = '\t';
2182   return "\Q$str";
2183
2184 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2185
2186 Interpolated scalars and arrays are converted internally to the C<join> and
2187 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
2188
2189   $foo . " XXX '" . (join $", @arr) . "'";
2190
2191 All operations above are performed simultaneously, left to right.
2192
2193 Because the result of C<"\Q STRING \E"> has all metacharacters
2194 quoted, there is no way to insert a literal C<$> or C<@> inside a
2195 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
2196 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2197 scalar.
2198
2199 Note also that the interpolation code needs to make a decision on
2200 where the interpolated scalar ends.  For instance, whether
2201 C<< "a $b -> {c}" >> really means:
2202
2203   "a " . $b . " -> {c}";
2204
2205 or:
2206
2207   "a " . $b -> {c};
2208
2209 Most of the time, the longest possible text that does not include
2210 spaces between components and which contains matching braces or
2211 brackets.  because the outcome may be determined by voting based
2212 on heuristic estimators, the result is not strictly predictable.
2213 Fortunately, it's usually correct for ambiguous cases.
2214
2215 =item the replacement of C<s///>
2216
2217 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
2218 happens as with C<qq//> constructs.
2219
2220 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2221 the replacement text of C<s///>, in order to correct the incorrigible
2222 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2223 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
2224 (that is, the C<$^W> variable) was set.
2225
2226 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2227
2228 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\E>,
2229 and interpolation happens (almost) as with C<qq//> constructs.
2230
2231 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2232 form for the regex compiler.  (This is because, as mentioned below, the regex
2233 compilation may be done at execution time, and C<\N{...}> is a compile-time
2234 construct.)
2235
2236 However any other combinations of C<\> followed by a character
2237 are not substituted but only skipped, in order to parse them
2238 as regular expressions at the following step.
2239 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2240 treated as an array symbol (for example C<@foo>),
2241 even though the same text in C<qq//> gives interpolation of C<\c@>.
2242
2243 Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
2244 a C<#>-comment in a C<//x>-regular expression, no processing is
2245 performed whatsoever.  This is the first step at which the presence
2246 of the C<//x> modifier is relevant.
2247
2248 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2249 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2250 voted (by several different estimators) to be either an array element
2251 or C<$var> followed by an RE alternative.  This is where the notation
2252 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2253 array element C<-9>, not as a regular expression from the variable
2254 C<$arr> followed by a digit, which would be the interpretation of
2255 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2256 the result is not predictable.
2257
2258 The lack of processing of C<\\> creates specific restrictions on
2259 the post-processed text.  If the delimiter is C</>, one cannot get
2260 the combination C<\/> into the result of this step.  C</> will
2261 finish the regular expression, C<\/> will be stripped to C</> on
2262 the previous step, and C<\\/> will be left as is.  Because C</> is
2263 equivalent to C<\/> inside a regular expression, this does not
2264 matter unless the delimiter happens to be character special to the
2265 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2266 alphanumeric char, as in:
2267
2268   m m ^ a \s* b mmx;
2269
2270 In the RE above, which is intentionally obfuscated for illustration, the
2271 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2272 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one
2273 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2274 non-whitespace choices.
2275
2276 =back
2277
2278 This step is the last one for all constructs except regular expressions,
2279 which are processed further.
2280
2281 =item parsing regular expressions
2282 X<regexp, parse>
2283
2284 Previous steps were performed during the compilation of Perl code,
2285 but this one happens at run time, although it may be optimized to
2286 be calculated at compile time if appropriate.  After preprocessing
2287 described above, and possibly after evaluation if concatenation,
2288 joining, casing translation, or metaquoting are involved, the
2289 resulting I<string> is passed to the RE engine for compilation.
2290
2291 Whatever happens in the RE engine might be better discussed in L<perlre>,
2292 but for the sake of continuity, we shall do so here.
2293
2294 This is another step where the presence of the C<//x> modifier is
2295 relevant.  The RE engine scans the string from left to right and
2296 converts it to a finite automaton.
2297
2298 Backslashed characters are either replaced with corresponding
2299 literal strings (as with C<\{>), or else they generate special nodes
2300 in the finite automaton (as with C<\b>).  Characters special to the
2301 RE engine (such as C<|>) generate corresponding nodes or groups of
2302 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2303 converted to literal strings to match, or else is ignored (as is
2304 whitespace and C<#>-style comments if C<//x> is present).
2305
2306 Parsing of the bracketed character class construct, C<[...]>, is
2307 rather different than the rule used for the rest of the pattern.
2308 The terminator of this construct is found using the same rules as
2309 for finding the terminator of a C<{}>-delimited construct, the only
2310 exception being that C<]> immediately following C<[> is treated as
2311 though preceded by a backslash.  Similarly, the terminator of
2312 C<(?{...})> is found using the same rules as for finding the
2313 terminator of a C<{}>-delimited construct.
2314
2315 It is possible to inspect both the string given to RE engine and the
2316 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2317 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
2318 switch documented in L<perlrun/"Command Switches">.
2319
2320 =item Optimization of regular expressions
2321 X<regexp, optimization>
2322
2323 This step is listed for completeness only.  Since it does not change
2324 semantics, details of this step are not documented and are subject
2325 to change without notice.  This step is performed over the finite
2326 automaton that was generated during the previous pass.
2327
2328 It is at this stage that C<split()> silently optimizes C</^/> to
2329 mean C</^/m>.
2330
2331 =back
2332
2333 =head2 I/O Operators
2334 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2335 X<< <> >> X<@ARGV>
2336
2337 There are several I/O operators you should know about.
2338
2339 A string enclosed by backticks (grave accents) first undergoes
2340 double-quote interpolation.  It is then interpreted as an external
2341 command, and the output of that command is the value of the
2342 backtick string, like in a shell.  In scalar context, a single string
2343 consisting of all output is returned.  In list context, a list of
2344 values is returned, one per line of output.  (You can set C<$/> to use
2345 a different line terminator.)  The command is executed each time the
2346 pseudo-literal is evaluated.  The status value of the command is
2347 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2348 Unlike in B<csh>, no translation is done on the return data--newlines
2349 remain newlines.  Unlike in any of the shells, single quotes do not
2350 hide variable names in the command from interpretation.  To pass a
2351 literal dollar-sign through to the shell you need to hide it with a
2352 backslash.  The generalized form of backticks is C<qx//>.  (Because
2353 backticks always undergo shell expansion as well, see L<perlsec> for
2354 security concerns.)
2355 X<qx> X<`> X<``> X<backtick> X<glob>
2356
2357 In scalar context, evaluating a filehandle in angle brackets yields
2358 the next line from that file (the newline, if any, included), or
2359 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2360 (sometimes known as file-slurp mode) and the file is empty, it
2361 returns C<''> the first time, followed by C<undef> subsequently.
2362
2363 Ordinarily you must assign the returned value to a variable, but
2364 there is one situation where an automatic assignment happens.  If
2365 and only if the input symbol is the only thing inside the conditional
2366 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2367 the value is automatically assigned to the global variable $_,
2368 destroying whatever was there previously.  (This may seem like an
2369 odd thing to you, but you'll use the construct in almost every Perl
2370 script you write.)  The $_ variable is not implicitly localized.
2371 You'll have to put a C<local $_;> before the loop if you want that
2372 to happen.
2373
2374 The following lines are equivalent:
2375
2376     while (defined($_ = <STDIN>)) { print; }
2377     while ($_ = <STDIN>) { print; }
2378     while (<STDIN>) { print; }
2379     for (;<STDIN>;) { print; }
2380     print while defined($_ = <STDIN>);
2381     print while ($_ = <STDIN>);
2382     print while <STDIN>;
2383
2384 This also behaves similarly, but avoids $_ :
2385
2386     while (my $line = <STDIN>) { print $line }
2387
2388 In these loop constructs, the assigned value (whether assignment
2389 is automatic or explicit) is then tested to see whether it is
2390 defined.  The defined test avoids problems where line has a string
2391 value that would be treated as false by Perl, for example a "" or
2392 a "0" with no trailing newline.  If you really mean for such values
2393 to terminate the loop, they should be tested for explicitly:
2394
2395     while (($_ = <STDIN>) ne '0') { ... }
2396     while (<STDIN>) { last unless $_; ... }
2397
2398 In other boolean contexts, C<< <filehandle> >> without an
2399 explicit C<defined> test or comparison elicits a warning if the
2400 C<use warnings> pragma or the B<-w>
2401 command-line switch (the C<$^W> variable) is in effect.
2402
2403 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2404 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2405 in packages, where they would be interpreted as local identifiers
2406 rather than global.)  Additional filehandles may be created with
2407 the open() function, amongst others.  See L<perlopentut> and
2408 L<perlfunc/open> for details on this.
2409 X<stdin> X<stdout> X<sterr>
2410
2411 If a <FILEHANDLE> is used in a context that is looking for
2412 a list, a list comprising all input lines is returned, one line per
2413 list element.  It's easy to grow to a rather large data space this
2414 way, so use with care.
2415
2416 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2417 See L<perlfunc/readline>.
2418
2419 The null filehandle <> is special: it can be used to emulate the
2420 behavior of B<sed> and B<awk>.  Input from <> comes either from
2421 standard input, or from each file listed on the command line.  Here's
2422 how it works: the first time <> is evaluated, the @ARGV array is
2423 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2424 gives you standard input.  The @ARGV array is then processed as a list
2425 of filenames.  The loop
2426
2427     while (<>) {
2428         ...                     # code for each line
2429     }
2430
2431 is equivalent to the following Perl-like pseudo code:
2432
2433     unshift(@ARGV, '-') unless @ARGV;
2434     while ($ARGV = shift) {
2435         open(ARGV, $ARGV);
2436         while (<ARGV>) {
2437             ...         # code for each line
2438         }
2439     }
2440
2441 except that it isn't so cumbersome to say, and will actually work.
2442 It really does shift the @ARGV array and put the current filename
2443 into the $ARGV variable.  It also uses filehandle I<ARGV>
2444 internally. <> is just a synonym for <ARGV>, which
2445 is magical.  (The pseudo code above doesn't work because it treats
2446 <ARGV> as non-magical.)
2447
2448 Since the null filehandle uses the two argument form of L<perlfunc/open>
2449 it interprets special characters, so if you have a script like this:
2450
2451     while (<>) {
2452         print;
2453     }
2454
2455 and call it with C<perl dangerous.pl 'rm -rfv *|'>, it actually opens a
2456 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
2457 If you want all items in C<@ARGV> to be interpreted as file names, you
2458 can use the module C<ARGV::readonly> from CPAN.
2459
2460 You can modify @ARGV before the first <> as long as the array ends up
2461 containing the list of filenames you really want.  Line numbers (C<$.>)
2462 continue as though the input were one big happy file.  See the example
2463 in L<perlfunc/eof> for how to reset line numbers on each file.
2464
2465 If you want to set @ARGV to your own list of files, go right ahead.
2466 This sets @ARGV to all plain text files if no @ARGV was given:
2467
2468     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2469
2470 You can even set them to pipe commands.  For example, this automatically
2471 filters compressed arguments through B<gzip>:
2472
2473     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2474
2475 If you want to pass switches into your script, you can use one of the
2476 Getopts modules or put a loop on the front like this:
2477
2478     while ($_ = $ARGV[0], /^-/) {
2479         shift;
2480         last if /^--$/;
2481         if (/^-D(.*)/) { $debug = $1 }
2482         if (/^-v/)     { $verbose++  }
2483         # ...           # other switches
2484     }
2485
2486     while (<>) {
2487         # ...           # code for each line
2488     }
2489
2490 The <> symbol will return C<undef> for end-of-file only once.
2491 If you call it again after this, it will assume you are processing another
2492 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
2493
2494 If what the angle brackets contain is a simple scalar variable (e.g.,
2495 <$foo>), then that variable contains the name of the
2496 filehandle to input from, or its typeglob, or a reference to the
2497 same.  For example:
2498
2499     $fh = \*STDIN;
2500     $line = <$fh>;
2501
2502 If what's within the angle brackets is neither a filehandle nor a simple
2503 scalar variable containing a filehandle name, typeglob, or typeglob
2504 reference, it is interpreted as a filename pattern to be globbed, and
2505 either a list of filenames or the next filename in the list is returned,
2506 depending on context.  This distinction is determined on syntactic
2507 grounds alone.  That means C<< <$x> >> is always a readline() from
2508 an indirect handle, but C<< <$hash{key}> >> is always a glob().
2509 That's because $x is a simple scalar variable, but C<$hash{key}> is
2510 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
2511 is treated as C<glob("$x ")>, not C<readline($x)>.
2512
2513 One level of double-quote interpretation is done first, but you can't
2514 say C<< <$foo> >> because that's an indirect filehandle as explained
2515 in the previous paragraph.  (In older versions of Perl, programmers
2516 would insert curly brackets to force interpretation as a filename glob:
2517 C<< <${foo}> >>.  These days, it's considered cleaner to call the
2518 internal function directly as C<glob($foo)>, which is probably the right
2519 way to have done it in the first place.)  For example:
2520
2521     while (<*.c>) {
2522         chmod 0644, $_;
2523     }
2524
2525 is roughly equivalent to:
2526
2527     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
2528     while (<FOO>) {
2529         chomp;
2530         chmod 0644, $_;
2531     }
2532
2533 except that the globbing is actually done internally using the standard
2534 C<File::Glob> extension.  Of course, the shortest way to do the above is:
2535
2536     chmod 0644, <*.c>;
2537
2538 A (file)glob evaluates its (embedded) argument only when it is
2539 starting a new list.  All values must be read before it will start
2540 over.  In list context, this isn't important because you automatically
2541 get them all anyway.  However, in scalar context the operator returns
2542 the next value each time it's called, or C<undef> when the list has
2543 run out.  As with filehandle reads, an automatic C<defined> is
2544 generated when the glob occurs in the test part of a C<while>,
2545 because legal glob returns (e.g. a file called F<0>) would otherwise
2546 terminate the loop.  Again, C<undef> is returned only once.  So if
2547 you're expecting a single value from a glob, it is much better to
2548 say
2549
2550     ($file) = <blurch*>;
2551
2552 than
2553
2554     $file = <blurch*>;
2555
2556 because the latter will alternate between returning a filename and
2557 returning false.
2558
2559 If you're trying to do variable interpolation, it's definitely better
2560 to use the glob() function, because the older notation can cause people
2561 to become confused with the indirect filehandle notation.
2562
2563     @files = glob("$dir/*.[ch]");
2564     @files = glob($files[$i]);
2565
2566 =head2 Constant Folding
2567 X<constant folding> X<folding>
2568
2569 Like C, Perl does a certain amount of expression evaluation at
2570 compile time whenever it determines that all arguments to an
2571 operator are static and have no side effects.  In particular, string
2572 concatenation happens at compile time between literals that don't do
2573 variable substitution.  Backslash interpolation also happens at
2574 compile time.  You can say
2575
2576     'Now is the time for all' . "\n" .
2577         'good men to come to.'
2578
2579 and this all reduces to one string internally.  Likewise, if
2580 you say
2581
2582     foreach $file (@filenames) {
2583         if (-s $file > 5 + 100 * 2**16) {  }
2584     }
2585
2586 the compiler will precompute the number which that expression
2587 represents so that the interpreter won't have to.
2588
2589 =head2 No-ops
2590 X<no-op> X<nop>
2591
2592 Perl doesn't officially have a no-op operator, but the bare constants
2593 C<0> and C<1> are special-cased to not produce a warning in a void
2594 context, so you can for example safely do
2595
2596     1 while foo();
2597
2598 =head2 Bitwise String Operators
2599 X<operator, bitwise, string>
2600
2601 Bitstrings of any size may be manipulated by the bitwise operators
2602 (C<~ | & ^>).
2603
2604 If the operands to a binary bitwise op are strings of different
2605 sizes, B<|> and B<^> ops act as though the shorter operand had
2606 additional zero bits on the right, while the B<&> op acts as though
2607 the longer operand were truncated to the length of the shorter.
2608 The granularity for such extension or truncation is one or more
2609 bytes.
2610
2611     # ASCII-based examples
2612     print "j p \n" ^ " a h";            # prints "JAPH\n"
2613     print "JA" | "  ph\n";              # prints "japh\n"
2614     print "japh\nJunk" & '_____';       # prints "JAPH\n";
2615     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
2616
2617 If you are intending to manipulate bitstrings, be certain that
2618 you're supplying bitstrings: If an operand is a number, that will imply
2619 a B<numeric> bitwise operation.  You may explicitly show which type of
2620 operation you intend by using C<""> or C<0+>, as in the examples below.
2621
2622     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
2623     $foo = '150' |  105;        # yields 255
2624     $foo =  150  | '105';       # yields 255
2625     $foo = '150' | '105';       # yields string '155' (under ASCII)
2626
2627     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
2628     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
2629
2630 See L<perlfunc/vec> for information on how to manipulate individual bits
2631 in a bit vector.
2632
2633 =head2 Integer Arithmetic
2634 X<integer>
2635
2636 By default, Perl assumes that it must do most of its arithmetic in
2637 floating point.  But by saying
2638
2639     use integer;
2640
2641 you may tell the compiler that it's okay to use integer operations
2642 (if it feels like it) from here to the end of the enclosing BLOCK.
2643 An inner BLOCK may countermand this by saying
2644
2645     no integer;
2646
2647 which lasts until the end of that BLOCK.  Note that this doesn't
2648 mean everything is only an integer, merely that Perl may use integer
2649 operations if it is so inclined.  For example, even under C<use
2650 integer>, if you take the C<sqrt(2)>, you'll still get C<1.4142135623731>
2651 or so.
2652
2653 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
2654 and ">>") always produce integral results.  (But see also
2655 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
2656 them.  By default, their results are interpreted as unsigned integers, but
2657 if C<use integer> is in effect, their results are interpreted
2658 as signed integers.  For example, C<~0> usually evaluates to a large
2659 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
2660 machines.
2661
2662 =head2 Floating-point Arithmetic
2663 X<floating-point> X<floating point> X<float> X<real>
2664
2665 While C<use integer> provides integer-only arithmetic, there is no
2666 analogous mechanism to provide automatic rounding or truncation to a
2667 certain number of decimal places.  For rounding to a certain number
2668 of digits, sprintf() or printf() is usually the easiest route.
2669 See L<perlfaq4>.
2670
2671 Floating-point numbers are only approximations to what a mathematician
2672 would call real numbers.  There are infinitely more reals than floats,
2673 so some corners must be cut.  For example:
2674
2675     printf "%.20g\n", 123456789123456789;
2676     #        produces 123456789123456784
2677
2678 Testing for exact floating-point equality or inequality is not a
2679 good idea.  Here's a (relatively expensive) work-around to compare
2680 whether two floating-point numbers are equal to a particular number of
2681 decimal places.  See Knuth, volume II, for a more robust treatment of
2682 this topic.
2683
2684     sub fp_equal {
2685         my ($X, $Y, $POINTS) = @_;
2686         my ($tX, $tY);
2687         $tX = sprintf("%.${POINTS}g", $X);
2688         $tY = sprintf("%.${POINTS}g", $Y);
2689         return $tX eq $tY;
2690     }
2691
2692 The POSIX module (part of the standard perl distribution) implements
2693 ceil(), floor(), and other mathematical and trigonometric functions.
2694 The Math::Complex module (part of the standard perl distribution)
2695 defines mathematical functions that work on both the reals and the
2696 imaginary numbers.  Math::Complex not as efficient as POSIX, but
2697 POSIX can't work with complex numbers.
2698
2699 Rounding in financial applications can have serious implications, and
2700 the rounding method used should be specified precisely.  In these
2701 cases, it probably pays not to trust whichever system rounding is
2702 being used by Perl, but to instead implement the rounding function you
2703 need yourself.
2704
2705 =head2 Bigger Numbers
2706 X<number, arbitrary precision>
2707
2708 The standard Math::BigInt and Math::BigFloat modules provide
2709 variable-precision arithmetic and overloaded operators, although
2710 they're currently pretty slow. At the cost of some space and
2711 considerable speed, they avoid the normal pitfalls associated with
2712 limited-precision representations.
2713
2714     use Math::BigInt;
2715     $x = Math::BigInt->new('123456789123456789');
2716     print $x * $x;
2717
2718     # prints +15241578780673678515622620750190521
2719
2720 There are several modules that let you calculate with (bound only by
2721 memory and cpu-time) unlimited or fixed precision. There are also
2722 some non-standard modules that provide faster implementations via
2723 external C libraries.
2724
2725 Here is a short, but incomplete summary:
2726
2727   Math::Fraction         big, unlimited fractions like 9973 / 12967
2728   Math::String           treat string sequences like numbers
2729   Math::FixedPrecision   calculate with a fixed precision
2730   Math::Currency         for currency calculations
2731   Bit::Vector            manipulate bit vectors fast (uses C)
2732   Math::BigIntFast       Bit::Vector wrapper for big numbers
2733   Math::Pari             provides access to the Pari C library
2734   Math::BigInteger       uses an external C library
2735   Math::Cephes           uses external Cephes C library (no big numbers)
2736   Math::Cephes::Fraction fractions via the Cephes library
2737   Math::GMP              another one using an external C library
2738
2739 Choose wisely.
2740
2741 =cut