This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Documentation fixes for EGID/GID confusion
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 Predefined Names
8
9 The following names have special meaning to Perl.  Most 
10 punctuation names have reasonable mnemonics, or analogs in the
11 shells.  Nevertheless, if you wish to use long variable names,
12 you need only say
13
14     use English;
15
16 at the top of your program. This aliases all the short names to the long
17 names in the current package. Some even have medium names, generally
18 borrowed from B<awk>. In general, it's best to use the
19
20     use English '-no_match_vars';
21
22 invocation if you don't need $PREMATCH, $MATCH, or $POSTMATCH, as it avoids
23 a certain performance hit with the use of regular expressions. See
24 L<English>.
25
26 Variables that depend on the currently selected filehandle may be set by
27 calling an appropriate object method on the IO::Handle object, although
28 this is less efficient than using the regular built-in variables. (Summary
29 lines below for this contain the word HANDLE.) First you must say
30
31     use IO::Handle;
32
33 after which you may use either
34
35     method HANDLE EXPR
36
37 or more safely,
38
39     HANDLE->method(EXPR)
40
41 Each method returns the old value of the IO::Handle attribute.
42 The methods each take an optional EXPR, which, if supplied, specifies the
43 new value for the IO::Handle attribute in question.  If not supplied,
44 most methods do nothing to the current value--except for
45 autoflush(), which will assume a 1 for you, just to be different.
46
47 Because loading in the IO::Handle class is an expensive operation, you should
48 learn how to use the regular built-in variables.
49
50 A few of these variables are considered "read-only".  This means that if
51 you try to assign to this variable, either directly or indirectly through
52 a reference, you'll raise a run-time exception.
53
54 You should be very careful when modifying the default values of most
55 special variables described in this document. In most cases you want
56 to localize these variables before changing them, since if you don't,
57 the change may affect other modules which rely on the default values
58 of the special variables that you have changed. This is one of the
59 correct ways to read the whole file at once:
60
61     open my $fh, "foo" or die $!;
62     local $/; # enable localized slurp mode
63     my $content = <$fh>;
64     close $fh;
65
66 But the following code is quite bad:
67
68     open my $fh, "foo" or die $!;
69     undef $/; # enable slurp mode
70     my $content = <$fh>;
71     close $fh;
72
73 since some other module, may want to read data from some file in the
74 default "line mode", so if the code we have just presented has been
75 executed, the global value of C<$/> is now changed for any other code
76 running inside the same Perl interpreter.
77
78 Usually when a variable is localized you want to make sure that this
79 change affects the shortest scope possible. So unless you are already
80 inside some short C<{}> block, you should create one yourself. For
81 example:
82
83     my $content = '';
84     open my $fh, "foo" or die $!;
85     {
86         local $/;
87         $content = <$fh>;
88     }
89     close $fh;
90
91 Here is an example of how your own code can go broken:
92
93     for (1..5){
94         nasty_break();
95         print "$_ ";
96     }
97     sub nasty_break {
98         $_ = 5;
99         # do something with $_
100     }
101
102 You probably expect this code to print:
103
104     1 2 3 4 5
105
106 but instead you get:
107
108     5 5 5 5 5
109
110 Why? Because nasty_break() modifies C<$_> without localizing it
111 first. The fix is to add local():
112
113         local $_ = 5;
114
115 It's easy to notice the problem in such a short example, but in more
116 complicated code you are looking for trouble if you don't localize
117 changes to the special variables.
118
119 The following list is ordered by scalar variables first, then the
120 arrays, then the hashes.
121
122 =over 8
123
124 =item $ARG
125
126 =item $_
127 X<$_> X<$ARG>
128
129 The default input and pattern-searching space.  The following pairs are
130 equivalent:
131
132     while (<>) {...}    # equivalent only in while!
133     while (defined($_ = <>)) {...}
134
135     /^Subject:/
136     $_ =~ /^Subject:/
137
138     tr/a-z/A-Z/
139     $_ =~ tr/a-z/A-Z/
140
141     chomp
142     chomp($_)
143
144 Here are the places where Perl will assume $_ even if you
145 don't use it:
146
147 =over 3
148
149 =item *
150
151 Various unary functions, including functions like ord() and int(), as well
152 as the all file tests (C<-f>, C<-d>) except for C<-t>, which defaults to
153 STDIN.
154
155 =item *
156
157 Various list functions like print() and unlink().
158
159 =item *
160
161 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
162 without an C<=~> operator.
163
164 =item *
165
166 The default iterator variable in a C<foreach> loop if no other
167 variable is supplied.
168
169 =item *
170
171 The implicit iterator variable in the grep() and map() functions.
172
173 =item *
174
175 The default place to put an input record when a C<< <FH> >>
176 operation's result is tested by itself as the sole criterion of a C<while>
177 test.  Outside a C<while> test, this will not happen.
178
179 =back
180
181 As C<$_> is a global variable, this may lead in some cases to unwanted
182 side-effects.  As of perl 5.9.1, you can now use a lexical version of
183 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
184 declaring C<our $> restores the global C<$_> in the current scope.
185
186 (Mnemonic: underline is understood in certain operations.)
187
188 =back
189
190 =over 8
191
192 =item $a
193
194 =item $b
195 X<$a> X<$b>
196
197 Special package variables when using sort(), see L<perlfunc/sort>.
198 Because of this specialness $a and $b don't need to be declared
199 (using use vars, or our()) even when using the C<strict 'vars'> pragma.
200 Don't lexicalize them with C<my $a> or C<my $b> if you want to be
201 able to use them in the sort() comparison block or function.
202
203 =back
204
205 =over 8
206
207 =item $<I<digits>>
208 X<$1> X<$2> X<$3>
209
210 Contains the subpattern from the corresponding set of capturing
211 parentheses from the last pattern match, not counting patterns
212 matched in nested blocks that have been exited already.  (Mnemonic:
213 like \digits.)  These variables are all read-only and dynamically
214 scoped to the current BLOCK.
215
216 =item $MATCH
217
218 =item $&
219 X<$&> X<$MATCH>
220
221 The string matched by the last successful pattern match (not counting
222 any matches hidden within a BLOCK or eval() enclosed by the current
223 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only
224 and dynamically scoped to the current BLOCK.
225
226 The use of this variable anywhere in a program imposes a considerable
227 performance penalty on all regular expression matches.  See L</BUGS>.
228
229 See L</@-> for a replacement.
230
231 =item ${^MATCH}
232 X<${^MATCH}>
233
234 This is similar to C<$&> (C<$POSTMATCH>) except that it does not incur the
235 performance penalty associated with that variable, and is only guaranteed
236 to return a defined value when the pattern was compiled or executed with
237 the C</p> modifier.
238
239 =item $PREMATCH
240
241 =item $`
242 X<$`> X<$PREMATCH>
243
244 The string preceding whatever was matched by the last successful
245 pattern match (not counting any matches hidden within a BLOCK or eval
246 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
247 string.)  This variable is read-only.
248
249 The use of this variable anywhere in a program imposes a considerable
250 performance penalty on all regular expression matches.  See L</BUGS>.
251
252 See L</@-> for a replacement.
253
254 =item ${^PREMATCH}
255 X<${^PREMATCH}>
256
257 This is similar to C<$`> ($PREMATCH) except that it does not incur the
258 performance penalty associated with that variable, and is only guaranteed
259 to return a defined value when the pattern was compiled or executed with
260 the C</p> modifier.
261
262 =item $POSTMATCH
263
264 =item $'
265 X<$'> X<$POSTMATCH>
266
267 The string following whatever was matched by the last successful
268 pattern match (not counting any matches hidden within a BLOCK or eval()
269 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
270 string.)  Example:
271
272     local $_ = 'abcdefghi';
273     /def/;
274     print "$`:$&:$'\n";         # prints abc:def:ghi
275
276 This variable is read-only and dynamically scoped to the current BLOCK.
277
278 The use of this variable anywhere in a program imposes a considerable
279 performance penalty on all regular expression matches.  See L</BUGS>.
280
281 See L</@-> for a replacement.
282
283 =item ${^POSTMATCH}
284 X<${^POSTMATCH}>
285
286 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
287 performance penalty associated with that variable, and is only guaranteed
288 to return a defined value when the pattern was compiled or executed with
289 the C</p> modifier.
290
291 =item $LAST_PAREN_MATCH
292
293 =item $+
294 X<$+> X<$LAST_PAREN_MATCH>
295
296 The text matched by the last bracket of the last successful search pattern.
297 This is useful if you don't know which one of a set of alternative patterns
298 matched. For example:
299
300     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
301
302 (Mnemonic: be positive and forward looking.)
303 This variable is read-only and dynamically scoped to the current BLOCK.
304
305 =item $^N
306 X<$^N>
307
308 The text matched by the used group most-recently closed (i.e. the group
309 with the rightmost closing parenthesis) of the last successful search
310 pattern.  (Mnemonic: the (possibly) Nested parenthesis that most
311 recently closed.)
312
313 This is primarily used inside C<(?{...})> blocks for examining text
314 recently matched. For example, to effectively capture text to a variable
315 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
316
317      (?:(...)(?{ $var = $^N }))
318
319 By setting and then using C<$var> in this way relieves you from having to
320 worry about exactly which numbered set of parentheses they are.
321
322 This variable is dynamically scoped to the current BLOCK.
323
324 =item @LAST_MATCH_END
325
326 =item @+
327 X<@+> X<@LAST_MATCH_END>
328
329 This array holds the offsets of the ends of the last successful
330 submatches in the currently active dynamic scope.  C<$+[0]> is
331 the offset into the string of the end of the entire match.  This
332 is the same value as what the C<pos> function returns when called
333 on the variable that was matched against.  The I<n>th element
334 of this array holds the offset of the I<n>th submatch, so
335 C<$+[1]> is the offset past where $1 ends, C<$+[2]> the offset
336 past where $2 ends, and so on.  You can use C<$#+> to determine
337 how many subgroups were in the last successful match.  See the
338 examples given for the C<@-> variable.
339
340 =item %+
341 X<%+>
342
343 Similar to C<@+>, the C<%+> hash allows access to the named capture
344 buffers, should they exist, in the last successful match in the
345 currently active dynamic scope.
346
347 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
348
349   'foo' =~ /(?<foo>foo)/;
350
351 The keys of the C<%+> hash list only the names of buffers that have
352 captured (and that are thus associated to defined values).
353
354 The underlying behaviour of C<%+> is provided by the
355 L<Tie::Hash::NamedCapture> module.
356
357 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
358 associated with the last successful regular expression. Therefore mixing
359 iterative access to them via C<each> may have unpredictable results.
360 Likewise, if the last successful match changes, then the results may be
361 surprising.
362
363 =item HANDLE->input_line_number(EXPR)
364
365 =item $INPUT_LINE_NUMBER
366
367 =item $NR
368
369 =item $.
370 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
371
372 Current line number for the last filehandle accessed.
373
374 Each filehandle in Perl counts the number of lines that have been read
375 from it.  (Depending on the value of C<$/>, Perl's idea of what
376 constitutes a line may not match yours.)  When a line is read from a
377 filehandle (via readline() or C<< <> >>), or when tell() or seek() is
378 called on it, C<$.> becomes an alias to the line counter for that
379 filehandle.
380
381 You can adjust the counter by assigning to C<$.>, but this will not
382 actually move the seek pointer.  I<Localizing C<$.> will not localize
383 the filehandle's line count>.  Instead, it will localize perl's notion
384 of which filehandle C<$.> is currently aliased to.
385
386 C<$.> is reset when the filehandle is closed, but B<not> when an open
387 filehandle is reopened without an intervening close().  For more
388 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
389 an explicit close, line numbers increase across ARGV files (but see
390 examples in L<perlfunc/eof>).
391
392 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
393 line counter for a given filehandle without having to worry about
394 which handle you last accessed.
395
396 (Mnemonic: many programs use "." to mean the current line number.)
397
398 =item IO::Handle->input_record_separator(EXPR)
399
400 =item $INPUT_RECORD_SEPARATOR
401
402 =item $RS
403
404 =item $/
405 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
406
407 The input record separator, newline by default.  This 
408 influences Perl's idea of what a "line" is.  Works like B<awk>'s RS
409 variable, including treating empty lines as a terminator if set to
410 the null string.  (An empty line cannot contain any spaces
411 or tabs.)  You may set it to a multi-character string to match a
412 multi-character terminator, or to C<undef> to read through the end
413 of file.  Setting it to C<"\n\n"> means something slightly
414 different than setting to C<"">, if the file contains consecutive
415 empty lines.  Setting to C<""> will treat two or more consecutive
416 empty lines as a single empty line.  Setting to C<"\n\n"> will
417 blindly assume that the next input character belongs to the next
418 paragraph, even if it's a newline.  (Mnemonic: / delimits
419 line boundaries when quoting poetry.)
420
421     local $/;           # enable "slurp" mode
422     local $_ = <FH>;    # whole file now here
423     s/\n[ \t]+/ /g;
424
425 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to be
426 better for something. :-)
427
428 Setting C<$/> to a reference to an integer, scalar containing an integer, or
429 scalar that's convertible to an integer will attempt to read records
430 instead of lines, with the maximum record size being the referenced
431 integer.  So this:
432
433     local $/ = \32768; # or \"32768", or \$var_containing_32768
434     open my $fh, $myfile or die $!;
435     local $_ = <$fh>;
436
437 will read a record of no more than 32768 bytes from FILE.  If you're
438 not reading from a record-oriented file (or your OS doesn't have
439 record-oriented files), then you'll likely get a full chunk of data
440 with every read.  If a record is larger than the record size you've
441 set, you'll get the record back in pieces.  Trying to set the record
442 size to zero or less will cause reading in the (rest of the) whole file.
443
444 On VMS, record reads are done with the equivalent of C<sysread>,
445 so it's best not to mix record and non-record reads on the same
446 file.  (This is unlikely to be a problem, because any file you'd
447 want to read in record mode is probably unusable in line mode.)
448 Non-VMS systems do normal I/O, so it's safe to mix record and
449 non-record reads of a file.
450
451 See also L<perlport/"Newlines">.  Also see C<$.>.
452
453 =item HANDLE->autoflush(EXPR)
454
455 =item $OUTPUT_AUTOFLUSH
456
457 =item $|
458 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
459
460 If set to nonzero, forces a flush right away and after every write
461 or print on the currently selected output channel.  Default is 0
462 (regardless of whether the channel is really buffered by the
463 system or not; C<$|> tells you only whether you've asked Perl
464 explicitly to flush after each write).  STDOUT will
465 typically be line buffered if output is to the terminal and block
466 buffered otherwise.  Setting this variable is useful primarily when
467 you are outputting to a pipe or socket, such as when you are running
468 a Perl program under B<rsh> and want to see the output as it's
469 happening.  This has no effect on input buffering.  See L<perlfunc/getc>
470 for that.  (Mnemonic: when you want your pipes to be piping hot.)
471
472 =item IO::Handle->output_field_separator EXPR
473
474 =item $OUTPUT_FIELD_SEPARATOR
475
476 =item $OFS
477
478 =item $,
479 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
480
481 The output field separator for the print operator.  If defined, this
482 value is printed between each of print's arguments.  Default is C<undef>.
483 (Mnemonic: what is printed when there is a "," in your print statement.)
484
485 =item IO::Handle->output_record_separator EXPR
486
487 =item $OUTPUT_RECORD_SEPARATOR
488
489 =item $ORS
490
491 =item $\
492 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
493
494 The output record separator for the print operator.  If defined, this
495 value is printed after the last of print's arguments.  Default is C<undef>.
496 (Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
497 Also, it's just like C<$/>, but it's what you get "back" from Perl.)
498
499 =item $LIST_SEPARATOR
500
501 =item $"
502 X<$"> X<$LIST_SEPARATOR>
503
504 This is like C<$,> except that it applies to array and slice values
505 interpolated into a double-quoted string (or similar interpreted
506 string).  Default is a space.  (Mnemonic: obvious, I think.)
507
508 =item $SUBSCRIPT_SEPARATOR
509
510 =item $SUBSEP
511
512 =item $;
513 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
514
515 The subscript separator for multidimensional array emulation.  If you
516 refer to a hash element as
517
518     $foo{$a,$b,$c}
519
520 it really means
521
522     $foo{join($;, $a, $b, $c)}
523
524 But don't put
525
526     @foo{$a,$b,$c}      # a slice--note the @
527
528 which means
529
530     ($foo{$a},$foo{$b},$foo{$c})
531
532 Default is "\034", the same as SUBSEP in B<awk>.  If your
533 keys contain binary data there might not be any safe value for C<$;>.
534 (Mnemonic: comma (the syntactic subscript separator) is a
535 semi-semicolon.  Yeah, I know, it's pretty lame, but C<$,> is already
536 taken for something more important.)
537
538 Consider using "real" multidimensional arrays as described
539 in L<perllol>.
540
541 =item HANDLE->format_page_number(EXPR)
542
543 =item $FORMAT_PAGE_NUMBER
544
545 =item $%
546 X<$%> X<$FORMAT_PAGE_NUMBER>
547
548 The current page number of the currently selected output channel.
549 Used with formats.
550 (Mnemonic: % is page number in B<nroff>.)
551
552 =item HANDLE->format_lines_per_page(EXPR)
553
554 =item $FORMAT_LINES_PER_PAGE
555
556 =item $=
557 X<$=> X<$FORMAT_LINES_PER_PAGE>
558
559 The current page length (printable lines) of the currently selected
560 output channel.  Default is 60.  
561 Used with formats.
562 (Mnemonic: = has horizontal lines.)
563
564 =item HANDLE->format_lines_left(EXPR)
565
566 =item $FORMAT_LINES_LEFT
567
568 =item $-
569 X<$-> X<$FORMAT_LINES_LEFT>
570
571 The number of lines left on the page of the currently selected output
572 channel.  
573 Used with formats.
574 (Mnemonic: lines_on_page - lines_printed.)
575
576 =item @LAST_MATCH_START
577
578 =item @-
579 X<@-> X<@LAST_MATCH_START>
580
581 $-[0] is the offset of the start of the last successful match.
582 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
583 I<n>-th subpattern, or undef if the subpattern did not match.
584
585 Thus after a match against $_, $& coincides with C<substr $_, $-[0],
586 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
587 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
588 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the last
589 matched subgroup in the last successful match.  Contrast with
590 C<$#+>, the number of subgroups in the regular expression.  Compare
591 with C<@+>.
592
593 This array holds the offsets of the beginnings of the last
594 successful submatches in the currently active dynamic scope.
595 C<$-[0]> is the offset into the string of the beginning of the
596 entire match.  The I<n>th element of this array holds the offset
597 of the I<n>th submatch, so C<$-[1]> is the offset where $1
598 begins, C<$-[2]> the offset where $2 begins, and so on.
599
600 After a match against some variable $var:
601
602 =over 5
603
604 =item C<$`> is the same as C<substr($var, 0, $-[0])>
605
606 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
607
608 =item C<$'> is the same as C<substr($var, $+[0])>
609
610 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>  
611
612 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
613
614 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
615
616 =back
617
618 =item %-
619 X<%->
620
621 Similar to C<%+>, this variable allows access to the named capture buffers
622 in the last successful match in the currently active dynamic scope. To
623 each capture buffer name found in the regular expression, it associates a
624 reference to an array containing the list of values captured by all
625 buffers with that name (should there be several of them), in the order
626 where they appear.
627
628 Here's an example:
629
630     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
631         foreach my $bufname (sort keys %-) {
632             my $ary = $-{$bufname};
633             foreach my $idx (0..$#$ary) {
634                 print "\$-{$bufname}[$idx] : ",
635                       (defined($ary->[$idx]) ? "'$ary->[$idx]'" : "undef"),
636                       "\n";
637             }
638         }
639     }
640
641 would print out:
642
643     $-{A}[0] : '1'
644     $-{A}[1] : '3'
645     $-{B}[0] : '2'
646     $-{B}[1] : '4'
647
648 The keys of the C<%-> hash correspond to all buffer names found in
649 the regular expression.
650
651 The behaviour of C<%-> is implemented via the
652 L<Tie::Hash::NamedCapture> module.
653
654 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
655 associated with the last successful regular expression. Therefore mixing
656 iterative access to them via C<each> may have unpredictable results.
657 Likewise, if the last successful match changes, then the results may be
658 surprising.
659
660 =item HANDLE->format_name(EXPR)
661
662 =item $FORMAT_NAME
663
664 =item $~
665 X<$~> X<$FORMAT_NAME>
666
667 The name of the current report format for the currently selected output
668 channel.  Default is the name of the filehandle.  (Mnemonic: brother to
669 C<$^>.)
670
671 =item HANDLE->format_top_name(EXPR)
672
673 =item $FORMAT_TOP_NAME
674
675 =item $^
676 X<$^> X<$FORMAT_TOP_NAME>
677
678 The name of the current top-of-page format for the currently selected
679 output channel.  Default is the name of the filehandle with _TOP
680 appended.  (Mnemonic: points to top of page.)
681
682 =item IO::Handle->format_line_break_characters EXPR
683
684 =item $FORMAT_LINE_BREAK_CHARACTERS
685
686 =item $:
687 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
688
689 The current set of characters after which a string may be broken to
690 fill continuation fields (starting with ^) in a format.  Default is
691 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
692 poetry is a part of a line.)
693
694 =item IO::Handle->format_formfeed EXPR
695
696 =item $FORMAT_FORMFEED
697
698 =item $^L
699 X<$^L> X<$FORMAT_FORMFEED>
700
701 What formats output as a form feed.  Default is \f.
702
703 =item $ACCUMULATOR
704
705 =item $^A
706 X<$^A> X<$ACCUMULATOR>
707
708 The current value of the write() accumulator for format() lines.  A format
709 contains formline() calls that put their result into C<$^A>.  After
710 calling its format, write() prints out the contents of C<$^A> and empties.
711 So you never really see the contents of C<$^A> unless you call
712 formline() yourself and then look at it.  See L<perlform> and
713 L<perlfunc/formline()>.
714
715 =item $CHILD_ERROR
716
717 =item $?
718 X<$?> X<$CHILD_ERROR>
719
720 The status returned by the last pipe close, backtick (C<``>) command,
721 successful call to wait() or waitpid(), or from the system()
722 operator.  This is just the 16-bit status word returned by the
723 traditional Unix wait() system call (or else is made up to look like it).  Thus, the
724 exit value of the subprocess is really (C<<< $? >> 8 >>>), and
725 C<$? & 127> gives which signal, if any, the process died from, and
726 C<$? & 128> reports whether there was a core dump.  (Mnemonic:
727 similar to B<sh> and B<ksh>.)
728
729 Additionally, if the C<h_errno> variable is supported in C, its value
730 is returned via $? if any C<gethost*()> function fails.
731
732 If you have installed a signal handler for C<SIGCHLD>, the
733 value of C<$?> will usually be wrong outside that handler.
734
735 Inside an C<END> subroutine C<$?> contains the value that is going to be
736 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
737 change the exit status of your program.  For example:
738
739     END {
740         $? = 1 if $? == 255;  # die would make it 255
741     } 
742
743 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
744 actual VMS exit status, instead of the default emulation of POSIX
745 status; see L<perlvms/$?> for details.
746
747 Also see L<Error Indicators>.
748
749 =item ${^CHILD_ERROR_NATIVE}
750 X<$^CHILD_ERROR_NATIVE>
751
752 The native status returned by the last pipe close, backtick (C<``>)
753 command, successful call to wait() or waitpid(), or from the system()
754 operator.  On POSIX-like systems this value can be decoded with the
755 WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED, WSTOPSIG
756 and WIFCONTINUED functions provided by the L<POSIX> module.
757
758 Under VMS this reflects the actual VMS exit status; i.e. it is the same
759 as $? when the pragma C<use vmsish 'status'> is in effect.
760
761 =item ${^ENCODING}
762 X<$^ENCODING>
763
764 The I<object reference> to the Encode object that is used to convert
765 the source code to Unicode.  Thanks to this variable your perl script
766 does not have to be written in UTF-8.  Default is I<undef>.  The direct
767 manipulation of this variable is highly discouraged.  See L<encoding>
768 for more details.
769
770 =item $OS_ERROR
771
772 =item $ERRNO
773
774 =item $!
775 X<$!> X<$ERRNO> X<$OS_ERROR>
776
777 If used numerically, yields the current value of the C C<errno>
778 variable, or in other words, if a system or library call fails, it
779 sets this variable.  This means that the value of C<$!> is meaningful
780 only I<immediately> after a B<failure>:
781
782     if (open(FH, $filename)) {
783         # Here $! is meaningless.
784         ...
785     } else {
786         # ONLY here is $! meaningful.
787         ...
788         # Already here $! might be meaningless.
789     }
790     # Since here we might have either success or failure,
791     # here $! is meaningless.
792
793 In the above I<meaningless> stands for anything: zero, non-zero,
794 C<undef>.  A successful system or library call does B<not> set
795 the variable to zero.
796
797 If used as a string, yields the corresponding system error string.
798 You can assign a number to C<$!> to set I<errno> if, for instance,
799 you want C<"$!"> to return the string for error I<n>, or you want
800 to set the exit value for the die() operator.  (Mnemonic: What just
801 went bang?)
802
803 Also see L<Error Indicators>.
804
805 =item %!
806 X<%!>
807
808 Each element of C<%!> has a true value only if C<$!> is set to that
809 value.  For example, C<$!{ENOENT}> is true if and only if the current
810 value of C<$!> is C<ENOENT>; that is, if the most recent error was
811 "No such file or directory" (or its moral equivalent: not all operating
812 systems give that exact error, and certainly not all languages).
813 To check if a particular key is meaningful on your system, use
814 C<exists $!{the_key}>; for a list of legal keys, use C<keys %!>.
815 See L<Errno> for more information, and also see above for the
816 validity of C<$!>.
817
818 =item $EXTENDED_OS_ERROR
819
820 =item $^E
821 X<$^E> X<$EXTENDED_OS_ERROR>
822
823 Error information specific to the current operating system.  At
824 the moment, this differs from C<$!> under only VMS, OS/2, and Win32
825 (and for MacPerl).  On all other platforms, C<$^E> is always just
826 the same as C<$!>.
827
828 Under VMS, C<$^E> provides the VMS status value from the last
829 system error.  This is more specific information about the last
830 system error than that provided by C<$!>.  This is particularly
831 important when C<$!> is set to B<EVMSERR>.
832
833 Under OS/2, C<$^E> is set to the error code of the last call to
834 OS/2 API either via CRT, or directly from perl.
835
836 Under Win32, C<$^E> always returns the last error information
837 reported by the Win32 call C<GetLastError()> which describes
838 the last error from within the Win32 API.  Most Win32-specific
839 code will report errors via C<$^E>.  ANSI C and Unix-like calls
840 set C<errno> and so most portable Perl code will report errors
841 via C<$!>. 
842
843 Caveats mentioned in the description of C<$!> generally apply to
844 C<$^E>, also.  (Mnemonic: Extra error explanation.)
845
846 Also see L<Error Indicators>.
847
848 =item $EVAL_ERROR
849
850 =item $@
851 X<$@> X<$EVAL_ERROR>
852
853 The Perl syntax error message from the last eval() operator.
854 If $@ is the null string, the last eval() parsed and executed
855 correctly (although the operations you invoked may have failed in the
856 normal fashion).  (Mnemonic: Where was the syntax error "at"?)
857
858 Warning messages are not collected in this variable.  You can,
859 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
860 as described below.
861
862 Also see L<Error Indicators>.
863
864 =item $PROCESS_ID
865
866 =item $PID
867
868 =item $$
869 X<$$> X<$PID> X<$PROCESS_ID>
870
871 The process number of the Perl running this script.  You should
872 consider this variable read-only, although it will be altered
873 across fork() calls.  (Mnemonic: same as shells.)
874
875 Note for Linux users: on Linux, the C functions C<getpid()> and
876 C<getppid()> return different values from different threads. In order to
877 be portable, this behavior is not reflected by C<$$>, whose value remains
878 consistent across threads. If you want to call the underlying C<getpid()>,
879 you may use the CPAN module C<Linux::Pid>.
880
881 =item $REAL_USER_ID
882
883 =item $UID
884
885 =item $<
886 X<< $< >> X<$UID> X<$REAL_USER_ID>
887
888 The real uid of this process.  (Mnemonic: it's the uid you came I<from>,
889 if you're running setuid.)  You can change both the real uid and
890 the effective uid at the same time by using POSIX::setuid().  Since
891 changes to $< require a system call, check $! after a change attempt to 
892 detect any possible errors.
893
894 =item $EFFECTIVE_USER_ID
895
896 =item $EUID
897
898 =item $>
899 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
900
901 The effective uid of this process.  Example:
902
903     $< = $>;            # set real to effective uid
904     ($<,$>) = ($>,$<);  # swap real and effective uid
905
906 You can change both the effective uid and the real uid at the same
907 time by using POSIX::setuid().  Changes to $> require a check to $!
908 to detect any possible errors after an attempted change. 
909
910 (Mnemonic: it's the uid you went I<to>, if you're running setuid.)
911 C<< $< >> and C<< $> >> can be swapped only on machines
912 supporting setreuid().
913
914 =item $REAL_GROUP_ID
915
916 =item $GID
917
918 =item $(
919 X<$(> X<$GID> X<$REAL_GROUP_ID>
920
921 The real gid of this process.  If you are on a machine that supports
922 membership in multiple groups simultaneously, gives a space separated
923 list of groups you are in.  The first number is the one returned by
924 getgid(), and the subsequent ones by getgroups(), one of which may be
925 the same as the first number.
926
927 However, a value assigned to C<$(> must be a single number used to
928 set the real gid.  So the value given by C<$(> should I<not> be assigned
929 back to C<$(> without being forced numeric, such as by adding zero. Note
930 that this is different to the effective gid (C<$)>) which does take a
931 list.
932
933 You can change both the real gid and the effective gid at the same
934 time by using POSIX::setgid().  Changes to $( require a check to $!
935 to detect any possible errors after an attempted change.
936
937 (Mnemonic: parentheses are used to I<group> things.  The real gid is the
938 group you I<left>, if you're running setgid.)
939
940 =item $EFFECTIVE_GROUP_ID
941
942 =item $EGID
943
944 =item $)
945 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
946
947 The effective gid of this process.  If you are on a machine that
948 supports membership in multiple groups simultaneously, gives a space
949 separated list of groups you are in.  The first number is the one
950 returned by getegid(), and the subsequent ones by getgroups(), one of
951 which may be the same as the first number.
952
953 Similarly, a value assigned to C<$)> must also be a space-separated
954 list of numbers.  The first number sets the effective gid, and
955 the rest (if any) are passed to setgroups().  To get the effect of an
956 empty list for setgroups(), just repeat the new effective gid; that is,
957 to force an effective gid of 5 and an effectively empty setgroups()
958 list, say C< $) = "5 5" >.
959
960 You can change both the effective gid and the real gid at the same
961 time by using POSIX::setgid() (use only a single numeric argument).
962 Changes to $) require a check to $! to detect any possible errors
963 after an attempted change.
964
965 (Mnemonic: parentheses are used to I<group> things.  The effective gid
966 is the group that's I<right> for you, if you're running setgid.)
967
968 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
969 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
970 and C<$)> can be swapped only on machines supporting setregid().
971
972 =item $PROGRAM_NAME
973
974 =item $0
975 X<$0> X<$PROGRAM_NAME>
976
977 Contains the name of the program being executed.
978
979 On some (read: not all) operating systems assigning to C<$0> modifies
980 the argument area that the C<ps> program sees.  On some platforms you
981 may have to use special C<ps> options or a different C<ps> to see the
982 changes.  Modifying the $0 is more useful as a way of indicating the
983 current program state than it is for hiding the program you're
984 running.  (Mnemonic: same as B<sh> and B<ksh>.)
985
986 Note that there are platform specific limitations on the maximum
987 length of C<$0>.  In the most extreme case it may be limited to the
988 space occupied by the original C<$0>.
989
990 In some platforms there may be arbitrary amount of padding, for
991 example space characters, after the modified name as shown by C<ps>.
992 In some platforms this padding may extend all the way to the original
993 length of the argument area, no matter what you do (this is the case
994 for example with Linux 2.2).
995
996 Note for BSD users: setting C<$0> does not completely remove "perl"
997 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
998 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
999 and the " (perl)" suffix are shown depends on your exact BSD variant
1000 and version).  This is an operating system feature, Perl cannot help it.
1001
1002 In multithreaded scripts Perl coordinates the threads so that any
1003 thread may modify its copy of the C<$0> and the change becomes visible
1004 to ps(1) (assuming the operating system plays along).  Note that
1005 the view of C<$0> the other threads have will not change since they
1006 have their own copies of it.
1007
1008 =item $[
1009 X<$[>
1010
1011 The index of the first element in an array, and of the first character
1012 in a substring.  Default is 0, but you could theoretically set it
1013 to 1 to make Perl behave more like B<awk> (or Fortran) when
1014 subscripting and when evaluating the index() and substr() functions.
1015 (Mnemonic: [ begins subscripts.)
1016
1017 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
1018 directive, and cannot influence the behavior of any other file.
1019 (That's why you can only assign compile-time constants to it.)
1020 Its use is highly discouraged.
1021
1022 Note that, unlike other compile-time directives (such as L<strict>),
1023 assignment to C<$[> can be seen from outer lexical scopes in the same file.
1024 However, you can use local() on it to strictly bind its value to a
1025 lexical block.
1026
1027 =item $]
1028 X<$]>
1029
1030 The version + patchlevel / 1000 of the Perl interpreter.  This variable
1031 can be used to determine whether the Perl interpreter executing a
1032 script is in the right range of versions.  (Mnemonic: Is this version
1033 of perl in the right bracket?)  Example:
1034
1035     warn "No checksumming!\n" if $] < 3.019;
1036
1037 See also the documentation of C<use VERSION> and C<require VERSION>
1038 for a convenient way to fail if the running Perl interpreter is too old.
1039
1040 The floating point representation can sometimes lead to inaccurate
1041 numeric comparisons.  See C<$^V> for a more modern representation of
1042 the Perl version that allows accurate string comparisons.
1043
1044 =item $COMPILING
1045
1046 =item $^C
1047 X<$^C> X<$COMPILING>
1048
1049 The current value of the flag associated with the B<-c> switch.
1050 Mainly of use with B<-MO=...> to allow code to alter its behavior
1051 when being compiled, such as for example to AUTOLOAD at compile
1052 time rather than normal, deferred loading.  Setting
1053 C<$^C = 1> is similar to calling C<B::minus_c>.
1054
1055 =item $DEBUGGING
1056
1057 =item $^D
1058 X<$^D> X<$DEBUGGING>
1059
1060 The current value of the debugging flags.  (Mnemonic: value of B<-D>
1061 switch.) May be read or set. Like its command-line equivalent, you can use
1062 numeric or symbolic values, eg C<$^D = 10> or C<$^D = "st">.
1063
1064 =item ${^RE_DEBUG_FLAGS}
1065
1066 The current value of the regex debugging flags. Set to 0 for no debug output
1067 even when the re 'debug' module is loaded. See L<re> for details.
1068
1069 =item ${^RE_TRIE_MAXBUF}
1070
1071 Controls how certain regex optimisations are applied and how much memory they
1072 utilize. This value by default is 65536 which corresponds to a 512kB temporary
1073 cache. Set this to a higher value to trade memory for speed when matching
1074 large alternations. Set it to a lower value if you want the optimisations to
1075 be as conservative of memory as possible but still occur, and set it to a
1076 negative value to prevent the optimisation and conserve the most memory.
1077 Under normal situations this variable should be of no interest to you.
1078
1079 =item $SYSTEM_FD_MAX
1080
1081 =item $^F
1082 X<$^F> X<$SYSTEM_FD_MAX>
1083
1084 The maximum system file descriptor, ordinarily 2.  System file
1085 descriptors are passed to exec()ed processes, while higher file
1086 descriptors are not.  Also, during an open(), system file descriptors are
1087 preserved even if the open() fails.  (Ordinary file descriptors are
1088 closed before the open() is attempted.)  The close-on-exec
1089 status of a file descriptor will be decided according to the value of
1090 C<$^F> when the corresponding file, pipe, or socket was opened, not the
1091 time of the exec().
1092
1093 =item $^H
1094
1095 WARNING: This variable is strictly for internal use only.  Its availability,
1096 behavior, and contents are subject to change without notice.
1097
1098 This variable contains compile-time hints for the Perl interpreter.  At the
1099 end of compilation of a BLOCK the value of this variable is restored to the
1100 value when the interpreter started to compile the BLOCK.
1101
1102 When perl begins to parse any block construct that provides a lexical scope
1103 (e.g., eval body, required file, subroutine body, loop body, or conditional
1104 block), the existing value of $^H is saved, but its value is left unchanged.
1105 When the compilation of the block is completed, it regains the saved value.
1106 Between the points where its value is saved and restored, code that
1107 executes within BEGIN blocks is free to change the value of $^H.
1108
1109 This behavior provides the semantic of lexical scoping, and is used in,
1110 for instance, the C<use strict> pragma.
1111
1112 The contents should be an integer; different bits of it are used for
1113 different pragmatic flags.  Here's an example:
1114
1115     sub add_100 { $^H |= 0x100 }
1116
1117     sub foo {
1118         BEGIN { add_100() }
1119         bar->baz($boon);
1120     }
1121
1122 Consider what happens during execution of the BEGIN block.  At this point
1123 the BEGIN block has already been compiled, but the body of foo() is still
1124 being compiled.  The new value of $^H will therefore be visible only while
1125 the body of foo() is being compiled.
1126
1127 Substitution of the above BEGIN block with:
1128
1129     BEGIN { require strict; strict->import('vars') }
1130
1131 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
1132 version of the same lexical pragma:
1133
1134     BEGIN { require strict; strict->import('vars') if $condition }
1135
1136 =item %^H
1137
1138 The %^H hash provides the same scoping semantic as $^H.  This makes it
1139 useful for implementation of lexically scoped pragmas. See L<perlpragma>.
1140
1141 =item $INPLACE_EDIT
1142
1143 =item $^I
1144 X<$^I> X<$INPLACE_EDIT>
1145
1146 The current value of the inplace-edit extension.  Use C<undef> to disable
1147 inplace editing.  (Mnemonic: value of B<-i> switch.)
1148
1149 =item $^M
1150 X<$^M>
1151
1152 By default, running out of memory is an untrappable, fatal error.
1153 However, if suitably built, Perl can use the contents of C<$^M>
1154 as an emergency memory pool after die()ing.  Suppose that your Perl
1155 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
1156 Then
1157
1158     $^M = 'a' x (1 << 16);
1159
1160 would allocate a 64K buffer for use in an emergency.  See the
1161 F<INSTALL> file in the Perl distribution for information on how to
1162 add custom C compilation flags when compiling perl.  To discourage casual
1163 use of this advanced feature, there is no L<English|English> long name for
1164 this variable.
1165
1166 =item $OSNAME
1167
1168 =item $^O
1169 X<$^O> X<$OSNAME>
1170
1171 The name of the operating system under which this copy of Perl was
1172 built, as determined during the configuration process.  The value
1173 is identical to C<$Config{'osname'}>.  See also L<Config> and the 
1174 B<-V> command-line switch documented in L<perlrun>.
1175
1176 In Windows platforms, $^O is not very helpful: since it is always
1177 C<MSWin32>, it doesn't tell the difference between
1178 95/98/ME/NT/2000/XP/CE/.NET.  Use Win32::GetOSName() or
1179 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
1180 between the variants.
1181
1182 =item ${^OPEN}
1183
1184 An internal variable used by PerlIO.  A string in two parts, separated
1185 by a C<\0> byte, the first part describes the input layers, the second
1186 part describes the output layers.
1187
1188 =item $PERLDB
1189
1190 =item $^P
1191 X<$^P> X<$PERLDB>
1192
1193 The internal variable for debugging support.  The meanings of the
1194 various bits are subject to change, but currently indicate:
1195
1196 =over 6
1197
1198 =item 0x01
1199
1200 Debug subroutine enter/exit.
1201
1202 =item 0x02
1203
1204 Line-by-line debugging.
1205
1206 =item 0x04
1207
1208 Switch off optimizations.
1209
1210 =item 0x08
1211
1212 Preserve more data for future interactive inspections.
1213
1214 =item 0x10
1215
1216 Keep info about source lines on which a subroutine is defined.
1217
1218 =item 0x20
1219
1220 Start with single-step on.
1221
1222 =item 0x40
1223
1224 Use subroutine address instead of name when reporting.
1225
1226 =item 0x80
1227
1228 Report C<goto &subroutine> as well.
1229
1230 =item 0x100
1231
1232 Provide informative "file" names for evals based on the place they were compiled.
1233
1234 =item 0x200
1235
1236 Provide informative names to anonymous subroutines based on the place they
1237 were compiled.
1238
1239 =item 0x400
1240
1241 Debug assertion subroutines enter/exit.
1242
1243 =back
1244
1245 Some bits may be relevant at compile-time only, some at
1246 run-time only.  This is a new mechanism and the details may change.
1247
1248 =item $LAST_REGEXP_CODE_RESULT
1249
1250 =item $^R
1251 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1252
1253 The result of evaluation of the last successful C<(?{ code })>
1254 regular expression assertion (see L<perlre>).  May be written to.
1255
1256 =item $EXCEPTIONS_BEING_CAUGHT
1257
1258 =item $^S
1259 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1260
1261 Current state of the interpreter.
1262
1263     $^S         State
1264     ---------   -------------------
1265     undef       Parsing module/eval
1266     true (1)    Executing an eval
1267     false (0)   Otherwise
1268
1269 The first state may happen in $SIG{__DIE__} and $SIG{__WARN__} handlers.
1270
1271 =item $BASETIME
1272
1273 =item $^T
1274 X<$^T> X<$BASETIME>
1275
1276 The time at which the program began running, in seconds since the
1277 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
1278 and B<-C> filetests are based on this value.
1279
1280 =item ${^TAINT}
1281
1282 Reflects if taint mode is on or off.  1 for on (the program was run with
1283 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
1284 B<-t> or B<-TU>).  This variable is read-only.
1285
1286 =item ${^UNICODE}
1287
1288 Reflects certain Unicode settings of Perl.  See L<perlrun>
1289 documentation for the C<-C> switch for more information about
1290 the possible values. This variable is set during Perl startup
1291 and is thereafter read-only.
1292
1293 =item ${^UTF8CACHE}
1294
1295 This variable controls the state of the internal UTF-8 offset caching code.
1296 1 for on (the default), 0 for off, -1 to debug the caching code by checking
1297 all its results against linear scans, and panicking on any discrepancy.
1298
1299 =item ${^UTF8LOCALE}
1300
1301 This variable indicates whether an UTF-8 locale was detected by perl at
1302 startup. This information is used by perl when it's in
1303 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
1304 switch); see L<perlrun> for more info on this.
1305
1306 =item $PERL_VERSION
1307
1308 =item $^V
1309 X<$^V> X<$PERL_VERSION>
1310
1311 The revision, version, and subversion of the Perl interpreter, represented
1312 as a string composed of characters with those ordinals.  Thus in Perl v5.6.0
1313 it equals C<chr(5) . chr(6) . chr(0)> and will return true for
1314 C<$^V eq v5.6.0>.  Note that the characters in this string value can
1315 potentially be greater than 255.
1316
1317 This variable first appeared in perl 5.6.0; earlier versions of perl will
1318 see an undefined value.
1319
1320 This can be used to determine whether the Perl interpreter executing a
1321 script is in the right range of versions.  (Mnemonic: use ^V for Version
1322 Control.)  Example:
1323
1324     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
1325
1326 To convert C<$^V> into its string representation use sprintf()'s
1327 C<"%vd"> conversion:
1328
1329     printf "version is v%vd\n", $^V;  # Perl's version
1330
1331 See the documentation of C<use VERSION> and C<require VERSION>
1332 for a convenient way to fail if the running Perl interpreter is too old.
1333
1334 See also C<$]> for an older representation of the Perl version.
1335
1336 =item $WARNING
1337
1338 =item $^W
1339 X<$^W> X<$WARNING>
1340
1341 The current value of the warning switch, initially true if B<-w>
1342 was used, false otherwise, but directly modifiable.  (Mnemonic:
1343 related to the B<-w> switch.)  See also L<warnings>.
1344
1345 =item ${^WARNING_BITS}
1346
1347 The current set of warning checks enabled by the C<use warnings> pragma.
1348 See the documentation of C<warnings> for more details.
1349
1350 =item ${^WIN32_SLOPPY_STAT}
1351
1352 If this variable is set to a true value, then stat() on Windows will
1353 not try to open the file. This means that the link count cannot be
1354 determined and file attributes may be out of date if additional
1355 hardlinks to the file exist. On the other hand, not opening the file
1356 is considerably faster, especially for files on network drives.
1357
1358 This variable could be set in the F<sitecustomize.pl> file to
1359 configure the local Perl installation to use "sloppy" stat() by
1360 default.  See L<perlrun> for more information about site
1361 customization.
1362
1363 =item $EXECUTABLE_NAME
1364
1365 =item $^X
1366 X<$^X> X<$EXECUTABLE_NAME>
1367
1368 The name used to execute the current copy of Perl, from C's
1369 C<argv[0]> or (where supported) F</proc/self/exe>.
1370
1371 Depending on the host operating system, the value of $^X may be
1372 a relative or absolute pathname of the perl program file, or may
1373 be the string used to invoke perl but not the pathname of the
1374 perl program file.  Also, most operating systems permit invoking
1375 programs that are not in the PATH environment variable, so there
1376 is no guarantee that the value of $^X is in PATH.  For VMS, the
1377 value may or may not include a version number.
1378
1379 You usually can use the value of $^X to re-invoke an independent
1380 copy of the same perl that is currently running, e.g.,
1381
1382   @first_run = `$^X -le "print int rand 100 for 1..100"`;
1383
1384 But recall that not all operating systems support forking or
1385 capturing of the output of commands, so this complex statement
1386 may not be portable.
1387
1388 It is not safe to use the value of $^X as a path name of a file,
1389 as some operating systems that have a mandatory suffix on
1390 executable files do not require use of the suffix when invoking
1391 a command.  To convert the value of $^X to a path name, use the
1392 following statements:
1393
1394   # Build up a set of file names (not command names).
1395   use Config;
1396   $this_perl = $^X;
1397   if ($^O ne 'VMS')
1398      {$this_perl .= $Config{_exe}
1399           unless $this_perl =~ m/$Config{_exe}$/i;}
1400
1401 Because many operating systems permit anyone with read access to
1402 the Perl program file to make a copy of it, patch the copy, and
1403 then execute the copy, the security-conscious Perl programmer
1404 should take care to invoke the installed copy of perl, not the
1405 copy referenced by $^X.  The following statements accomplish
1406 this goal, and produce a pathname that can be invoked as a
1407 command or referenced as a file.
1408
1409   use Config;
1410   $secure_perl_path = $Config{perlpath};
1411   if ($^O ne 'VMS')
1412      {$secure_perl_path .= $Config{_exe}
1413           unless $secure_perl_path =~ m/$Config{_exe}$/i;}
1414
1415 =item ARGV
1416 X<ARGV>
1417
1418 The special filehandle that iterates over command-line filenames in
1419 C<@ARGV>. Usually written as the null filehandle in the angle operator
1420 C<< <> >>. Note that currently C<ARGV> only has its magical effect
1421 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1422 corresponding to the last file opened by C<< <> >>. In particular,
1423 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1424 may not cause your function to automatically read the contents of all the
1425 files in C<@ARGV>.
1426
1427 =item $ARGV
1428 X<$ARGV>
1429
1430 contains the name of the current file when reading from <>.
1431
1432 =item @ARGV
1433 X<@ARGV>
1434
1435 The array @ARGV contains the command-line arguments intended for
1436 the script.  C<$#ARGV> is generally the number of arguments minus
1437 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1438 command name itself.  See C<$0> for the command name.
1439
1440 =item ARGVOUT
1441 X<ARGVOUT>
1442
1443 The special filehandle that points to the currently open output file
1444 when doing edit-in-place processing with B<-i>.  Useful when you have
1445 to do a lot of inserting and don't want to keep modifying $_.  See
1446 L<perlrun> for the B<-i> switch.
1447
1448 =item @F
1449 X<@F>
1450
1451 The array @F contains the fields of each line read in when autosplit
1452 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
1453 is package-specific, and must be declared or given a full package name
1454 if not in package main when running under C<strict 'vars'>.
1455
1456 =item @INC
1457 X<@INC>
1458
1459 The array @INC contains the list of places that the C<do EXPR>,
1460 C<require>, or C<use> constructs look for their library files.  It
1461 initially consists of the arguments to any B<-I> command-line
1462 switches, followed by the default Perl library, probably
1463 F</usr/local/lib/perl>, followed by ".", to represent the current
1464 directory.  ("." will not be appended if taint checks are enabled, either by
1465 C<-T> or by C<-t>.)  If you need to modify this at runtime, you should use
1466 the C<use lib> pragma to get the machine-dependent library properly
1467 loaded also:
1468
1469     use lib '/mypath/libdir/';
1470     use SomeMod;
1471
1472 You can also insert hooks into the file inclusion system by putting Perl
1473 code directly into @INC.  Those hooks may be subroutine references, array
1474 references or blessed objects.  See L<perlfunc/require> for details.
1475
1476 =item @ARG
1477
1478 =item @_
1479 X<@_> X<@ARG>
1480
1481 Within a subroutine the array @_ contains the parameters passed to that
1482 subroutine.  See L<perlsub>.
1483
1484 =item %INC
1485 X<%INC>
1486
1487 The hash %INC contains entries for each filename included via the
1488 C<do>, C<require>, or C<use> operators.  The key is the filename
1489 you specified (with module names converted to pathnames), and the
1490 value is the location of the file found.  The C<require>
1491 operator uses this hash to determine whether a particular file has
1492 already been included.
1493
1494 If the file was loaded via a hook (e.g. a subroutine reference, see
1495 L<perlfunc/require> for a description of these hooks), this hook is
1496 by default inserted into %INC in place of a filename.  Note, however,
1497 that the hook may have set the %INC entry by itself to provide some more
1498 specific info.
1499
1500 =item %ENV
1501
1502 =item $ENV{expr}
1503 X<%ENV>
1504
1505 The hash %ENV contains your current environment.  Setting a
1506 value in C<ENV> changes the environment for any child processes
1507 you subsequently fork() off.
1508
1509 =item %SIG
1510
1511 =item $SIG{expr}
1512 X<%SIG>
1513
1514 The hash C<%SIG> contains signal handlers for signals.  For example:
1515
1516     sub handler {       # 1st argument is signal name
1517         my($sig) = @_;
1518         print "Caught a SIG$sig--shutting down\n";
1519         close(LOG);
1520         exit(0);
1521     }
1522
1523     $SIG{'INT'}  = \&handler;
1524     $SIG{'QUIT'} = \&handler;
1525     ...
1526     $SIG{'INT'}  = 'DEFAULT';   # restore default action
1527     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
1528
1529 Using a value of C<'IGNORE'> usually has the effect of ignoring the
1530 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
1531 this special case.
1532
1533 Here are some other examples:
1534
1535     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
1536     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
1537     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
1538     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
1539
1540 Be sure not to use a bareword as the name of a signal handler,
1541 lest you inadvertently call it. 
1542
1543 If your system has the sigaction() function then signal handlers are
1544 installed using it.  This means you get reliable signal handling.
1545
1546 The default delivery policy of signals changed in Perl 5.8.0 from 
1547 immediate (also known as "unsafe") to deferred, also known as 
1548 "safe signals".  See L<perlipc> for more information.
1549
1550 Certain internal hooks can be also set using the %SIG hash.  The
1551 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
1552 about to be printed.  The warning message is passed as the first
1553 argument.  The presence of a C<__WARN__> hook causes the ordinary printing
1554 of warnings to C<STDERR> to be suppressed.  You can use this to save warnings
1555 in a variable, or turn warnings into fatal errors, like this:
1556
1557     local $SIG{__WARN__} = sub { die $_[0] };
1558     eval $proggie;
1559
1560 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
1561 disable warnings using the empty subroutine:
1562
1563     local $SIG{__WARN__} = sub {};
1564
1565 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
1566 is about to be thrown.  The error message is passed as the first
1567 argument.  When a C<__DIE__> hook routine returns, the exception
1568 processing continues as it would have in the absence of the hook,
1569 unless the hook routine itself exits via a C<goto>, a loop exit, or a C<die()>.
1570 The C<__DIE__> handler is explicitly disabled during the call, so that you
1571 can die from a C<__DIE__> handler.  Similarly for C<__WARN__>.
1572
1573 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
1574 even inside an eval().  Do not use this to rewrite a pending exception
1575 in C<$@>, or as a bizarre substitute for overriding C<CORE::GLOBAL::die()>.
1576 This strange action at a distance may be fixed in a future release
1577 so that C<$SIG{__DIE__}> is only called if your program is about
1578 to exit, as was the original intent.  Any other use is deprecated.
1579
1580 C<__DIE__>/C<__WARN__> handlers are very special in one respect:
1581 they may be called to report (probable) errors found by the parser.
1582 In such a case the parser may be in inconsistent state, so any
1583 attempt to evaluate Perl code from such a handler will probably
1584 result in a segfault.  This means that warnings or errors that
1585 result from parsing Perl should be used with extreme caution, like
1586 this:
1587
1588     require Carp if defined $^S;
1589     Carp::confess("Something wrong") if defined &Carp::confess;
1590     die "Something wrong, but could not load Carp to give backtrace...
1591          To see backtrace try starting Perl with -MCarp switch";
1592
1593 Here the first line will load Carp I<unless> it is the parser who
1594 called the handler.  The second line will print backtrace and die if
1595 Carp was available.  The third line will be executed only if Carp was
1596 not available.
1597
1598 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
1599 L<warnings> for additional information.
1600
1601 =back
1602
1603 =head2 Error Indicators
1604 X<error> X<exception>
1605
1606 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1607 about different types of error conditions that may appear during
1608 execution of a Perl program.  The variables are shown ordered by
1609 the "distance" between the subsystem which reported the error and
1610 the Perl process.  They correspond to errors detected by the Perl
1611 interpreter, C library, operating system, or an external program,
1612 respectively.
1613
1614 To illustrate the differences between these variables, consider the 
1615 following Perl expression, which uses a single-quoted string:
1616
1617     eval q{
1618         open my $pipe, "/cdrom/install |" or die $!;
1619         my @res = <$pipe>;
1620         close $pipe or die "bad pipe: $?, $!";
1621     };
1622
1623 After execution of this statement all 4 variables may have been set.  
1624
1625 C<$@> is set if the string to be C<eval>-ed did not compile (this
1626 may happen if C<open> or C<close> were imported with bad prototypes),
1627 or if Perl code executed during evaluation die()d .  In these cases
1628 the value of $@ is the compile error, or the argument to C<die>
1629 (which will interpolate C<$!> and C<$?>).  (See also L<Fatal>,
1630 though.)
1631
1632 When the eval() expression above is executed, open(), C<< <PIPE> >>,
1633 and C<close> are translated to calls in the C run-time library and
1634 thence to the operating system kernel.  C<$!> is set to the C library's
1635 C<errno> if one of these calls fails. 
1636
1637 Under a few operating systems, C<$^E> may contain a more verbose
1638 error indicator, such as in this case, "CDROM tray not closed."
1639 Systems that do not support extended error messages leave C<$^E>
1640 the same as C<$!>.
1641
1642 Finally, C<$?> may be set to non-0 value if the external program
1643 F</cdrom/install> fails.  The upper eight bits reflect specific
1644 error conditions encountered by the program (the program's exit()
1645 value).   The lower eight bits reflect mode of failure, like signal
1646 death and core dump information  See wait(2) for details.  In
1647 contrast to C<$!> and C<$^E>, which are set only if error condition
1648 is detected, the variable C<$?> is set on each C<wait> or pipe
1649 C<close>, overwriting the old value.  This is more like C<$@>, which
1650 on every eval() is always set on failure and cleared on success.
1651
1652 For more details, see the individual descriptions at C<$@>, C<$!>, C<$^E>,
1653 and C<$?>.
1654
1655 =head2 Technical Note on the Syntax of Variable Names
1656
1657 Variable names in Perl can have several formats.  Usually, they
1658 must begin with a letter or underscore, in which case they can be
1659 arbitrarily long (up to an internal limit of 251 characters) and
1660 may contain letters, digits, underscores, or the special sequence
1661 C<::> or C<'>.  In this case, the part before the last C<::> or
1662 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
1663
1664 Perl variable names may also be a sequence of digits or a single
1665 punctuation or control character.  These names are all reserved for
1666 special uses by Perl; for example, the all-digits names are used
1667 to hold data captured by backreferences after a regular expression
1668 match.  Perl has a special syntax for the single-control-character
1669 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
1670 character.  For example, the notation C<$^W> (dollar-sign caret
1671 C<W>) is the scalar variable whose name is the single character
1672 control-C<W>.  This is better than typing a literal control-C<W>
1673 into your program.
1674
1675 Finally, new in Perl 5.6, Perl variable names may be alphanumeric
1676 strings that begin with control characters (or better yet, a caret).
1677 These variables must be written in the form C<${^Foo}>; the braces
1678 are not optional.  C<${^Foo}> denotes the scalar variable whose
1679 name is a control-C<F> followed by two C<o>'s.  These variables are
1680 reserved for future special uses by Perl, except for the ones that
1681 begin with C<^_> (control-underscore or caret-underscore).  No
1682 control-character name that begins with C<^_> will acquire a special
1683 meaning in any future version of Perl; such names may therefore be
1684 used safely in programs.  C<$^_> itself, however, I<is> reserved.
1685
1686 Perl identifiers that begin with digits, control characters, or
1687 punctuation characters are exempt from the effects of the C<package>
1688 declaration and are always forced to be in package C<main>; they are
1689 also exempt from C<strict 'vars'> errors.  A few other names are also
1690 exempt in these ways:
1691
1692         ENV             STDIN
1693         INC             STDOUT
1694         ARGV            STDERR
1695         ARGVOUT         _
1696         SIG
1697
1698 In particular, the new special C<${^_XYZ}> variables are always taken
1699 to be in package C<main>, regardless of any C<package> declarations
1700 presently in scope.  
1701
1702 =head1 BUGS
1703
1704 Due to an unfortunate accident of Perl's implementation, C<use
1705 English> imposes a considerable performance penalty on all regular
1706 expression matches in a program, regardless of whether they occur
1707 in the scope of C<use English>.  For that reason, saying C<use
1708 English> in libraries is strongly discouraged.  See the
1709 Devel::SawAmpersand module documentation from CPAN
1710 ( http://www.cpan.org/modules/by-module/Devel/ )
1711 for more information. Writing C<use English '-no_match_vars';>
1712 avoids the performance penalty.
1713
1714 Having to even think about the C<$^S> variable in your exception
1715 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
1716 invites grievous and difficult to track down errors.  Avoid it
1717 and use an C<END{}> or CORE::GLOBAL::die override instead.