This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
In FindExt, use File::Find instead of shelling out to a dir command.
[perl5.git] / win32 / FindExt.pm
1 package FindExt;
2
3 our $VERSION = '1.02';
4
5 use strict;
6 use warnings;
7
8 my $no = join('|',qw(GDBM_File ODBM_File NDBM_File DB_File
9                      VMS VMS-DCLsym VMS-Stdio Sys-Syslog IPC-SysV I18N-Langinfo));
10 $no = qr/^(?:$no)$/i;
11
12 sub apply_config {
13     my ($config) = @_;
14     my @no;
15
16     push @no, 'Sys-Syslog' if $^O eq 'MSWin32';
17
18     # duplicates logic from Configure (mostly)
19     push @no, "DB_File" unless $config->{i_db};
20     push @no, "GDBM_File" unless $config->{i_gdbm};
21     push @no, "I18N-Langinfo" unless $config->{i_langinfo} && $config->{i_nl_langinfo};
22     push @no, "IPC-SysV" unless $config->{d_msg} || $config->{d_sem} || $config->{d_shm};
23     push @no, "NDBM_File" unless $config->{d_ndbm};
24     push @no, "ODBM_File"
25       unless ($config->{i_dbm} || $config->{i_rpcsvcdbm}) && !$config->{d_cplusplus};
26     push @no, "VMS.*" unless $^O eq "VMS";
27     push @no, "Win32.*" unless $^O eq "MSWin32" || $^O eq "cygwin";
28
29     $no = join('|', @no);
30     $no = qr/^(?:$no)$/i;
31 }
32
33 my %ext;
34 my %static;
35
36 sub set_static_extensions {
37     # adjust results of scan_ext, and also save
38     # statics in case scan_ext hasn't been called yet.
39     # if '*' is passed then all XS extensions are static
40     # (with possible exclusions)
41     %static = ();
42     my @list = @_;
43     if (@_ and $_[0] eq '*') {
44         my %excl = map {$_=>1} map {m/^!(.*)$/} @_[1 .. $#_];
45         @list = grep {!exists $excl{$_}} keys %ext;
46     }
47     for (@list) {
48         $static{$_} = 1;
49         $ext{$_} = 'static' if $ext{$_} && $ext{$_} eq 'dynamic';
50     }
51
52     # Encode is a special case.  If we are building Encode as a static
53     # extension, we need to explicitly list its subextensions as well.
54     # For other nested extensions, this is handled automatically by
55     # the appropriate Makefile.PL.
56     if ($ext{Encode} && $ext{Encode} eq 'static') {
57         require File::Find;
58         File::Find::find({
59                           no_chdir => 1,
60                           wanted => sub {
61                               return unless m!\b(Encode/.+)/Makefile\.PL!;
62                               $static{$1} = 1;
63                               $ext{$1} = 'static';
64                           },
65                          }, "../cpan/Encode");
66     }
67 }
68
69 sub scan_ext
70 {
71     my $dir  = shift;
72     find_ext("$dir/");
73     extensions();
74 }
75
76 sub _ext_eq {
77     my $key = shift;
78     sub {
79         sort grep $ext{$_} eq $key, keys %ext;
80     }
81 }
82
83 *dynamic_ext = _ext_eq('dynamic');
84 *static_ext = _ext_eq('static');
85 *nonxs_ext = _ext_eq('nonxs');
86
87 sub _ext_ne {
88     my $key = shift;
89     sub {
90         sort grep $ext{$_} ne $key, keys %ext;
91     }
92 }
93
94 *extensions = _ext_ne('known');
95 # faithfully copy Configure in not including nonxs extensions for the nonce
96 *known_extensions = _ext_ne('nonxs');
97
98 sub is_static
99 {
100  return $ext{$_[0]} eq 'static'
101 }
102
103 sub has_xs_or_c {
104     my $dir = shift;
105     opendir my $dh, $dir or die "opendir $dir: $!";
106     while (defined (my $item = readdir $dh)) {
107         return 1 if $item =~ /\.xs$/;
108         return 1 if $item =~ /\.c$/;
109     }
110     return 0;
111 }
112
113 # Function to find available extensions, ignoring DynaLoader
114 sub find_ext
115 {
116     my $ext_dir = shift;
117     opendir my $dh, "$ext_dir";
118     while (defined (my $item = readdir $dh)) {
119         next if $item =~ /^\.\.?$/;
120         next if $item eq "DynaLoader";
121         next unless -d "$ext_dir$item";
122         my $this_ext = $item;
123         my $leaf = $item;
124
125         $this_ext =~ s!-!/!g;
126         $leaf =~ s/.*-//;
127
128         # Temporary hack to cope with smokers that are not clearing directories:
129         next if $ext{$this_ext};
130
131         if (has_xs_or_c("$ext_dir$item")) {
132             $ext{$this_ext} = $static{$this_ext} ? 'static' : 'dynamic';
133         } else {
134             $ext{$this_ext} = 'nonxs';
135         }
136         $ext{$this_ext} = 'known' if $ext{$this_ext} && $item =~ $no;
137     }
138 }
139
140 1;
141 # Local variables:
142 # cperl-indent-level: 4
143 # indent-tabs-mode: nil
144 # End:
145 #
146 # ex: set ts=8 sts=4 sw=4 et: