lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.39_04';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     @cmdfhs
 631     $CommandSet
 632     $CreateTTY
 633     $DBGR
 634     @dbline
 635     $dbline
 636     %dbline
 637     $dieLevel
 638     $evalarg
 639     $filename
 640     $frame
 641     $hist
 642     $histfile
 643     $histsize
 644     $ImmediateStop
 645     $IN
 646     $inhibit_exit
 647     @ini_INC
 648     $ini_warn
 649     $line
 650     $maxtrace
 651     $od
 652     $onetimeDump
 653     $onetimedumpDepth
 654     %option
 655     @options
 656     $osingle
 657     $otrace
 658     $OUT
 659     $packname
 660     $pager
 661     $post
 662     %postponed
 663     $prc
 664     $pre
 665     $pretype
 666     $psh
 667     @RememberOnROptions
 668     $remoteport
 669     @res
 670     $rl
 671     @saved
 672     $signal
 673     $signalLevel
 674     $single
 675     $start
 676     $sub
 677     %sub
 678     $subname
 679     $term
 680     $trace
 681     $usercontext
 682     $warnLevel
 683     $window
 684 );
 685
 686 # Used to save @ARGV and extract any debugger-related flags.
 687 use vars qw(@ARGS);
 688
 689 # Used to prevent multiple entries to diesignal()
 690 # (if for instance diesignal() itself dies)
 691 use vars qw($panic);
 692
 693 # Used to prevent the debugger from running nonstop
 694 # after a restart
 695 use vars qw($second_time);
 696
 697 sub _calc_usercontext {
 698     my ($package) = @_;
 699
 700     # Cancel strict completely for the evaluated code, so the code
 701     # the user evaluates won't be affected by it. (Shlomi Fish)
 702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
 703     . "package $package;";    # this won't let them modify, alas
 704 }
 705
 706 sub eval {
 707
 708     # 'my' would make it visible from user code
 709     #    but so does local! --tchrist
 710     # Remember: this localizes @DB::res, not @main::res.
 711     local @res;
 712     {
 713
 714         # Try to keep the user code from messing  with us. Save these so that
 715         # even if the eval'ed code changes them, we can put them back again.
 716         # Needed because the user could refer directly to the debugger's
 717         # package globals (and any 'my' variables in this containing scope)
 718         # inside the eval(), and we want to try to stay safe.
 719         local $otrace  = $trace;
 720         local $osingle = $single;
 721         local $od      = $^D;
 722
 723         # Untaint the incoming eval() argument.
 724         { ($evalarg) = $evalarg =~ /(.*)/s; }
 725
 726         # $usercontext built in DB::DB near the comment
 727         # "set up the context for DB::eval ..."
 728         # Evaluate and save any results.
 729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 730
 731         # Restore those old values.
 732         $trace  = $otrace;
 733         $single = $osingle;
 734         $^D     = $od;
 735     }
 736
 737     # Save the current value of $@, and preserve it in the debugger's copy
 738     # of the saved precious globals.
 739     my $at = $@;
 740
 741     # Since we're only saving $@, we only have to localize the array element
 742     # that it will be stored in.
 743     local $saved[0];    # Preserve the old value of $@
 744     eval { &DB::save };
 745
 746     # Now see whether we need to report an error back to the user.
 747     if ($at) {
 748         local $\ = '';
 749         print $OUT $at;
 750     }
 751
 752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 753     # are package globals.
 754     elsif ($onetimeDump) {
 755         if ( $onetimeDump eq 'dump' ) {
 756             local $option{dumpDepth} = $onetimedumpDepth
 757               if defined $onetimedumpDepth;
 758             dumpit( $OUT, \@res );
 759         }
 760         elsif ( $onetimeDump eq 'methods' ) {
 761             methods( $res[0] );
 762         }
 763     } ## end elsif ($onetimeDump)
 764     @res;
 765 } ## end sub eval
 766
 767 ############################################## End lexical danger zone
 768
 769 # After this point it is safe to introduce lexicals.
 770 # The code being debugged will be executing in its own context, and
 771 # can't see the inside of the debugger.
 772 #
 773 # However, one should not overdo it: leave as much control from outside as
 774 # possible. If you make something a lexical, it's not going to be addressable
 775 # from outside the debugger even if you know its name.
 776
 777 # This file is automatically included if you do perl -d.
 778 # It's probably not useful to include this yourself.
 779 #
 780 # Before venturing further into these twisty passages, it is
 781 # wise to read the perldebguts man page or risk the ire of dragons.
 782 #
 783 # (It should be noted that perldebguts will tell you a lot about
 784 # the underlying mechanics of how the debugger interfaces into the
 785 # Perl interpreter, but not a lot about the debugger itself. The new
 786 # comments in this code try to address this problem.)
 787
 788 # Note that no subroutine call is possible until &DB::sub is defined
 789 # (for subroutines defined outside of the package DB). In fact the same is
 790 # true if $deep is not defined.
 791
 792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 793
 794 # modified Perl debugger, to be run from Emacs in perldb-mode
 795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 796 # Johan Vromans -- upgrade to 4.0 pl 10
 797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 798 ########################################################################
 799
 800 =head1 DEBUGGER INITIALIZATION
 801
 802 The debugger starts up in phases.
 803
 804 =head2 BASIC SETUP
 805
 806 First, it initializes the environment it wants to run in: turning off
 807 warnings during its own compilation, defining variables which it will need
 808 to avoid warnings later, setting itself up to not exit when the program
 809 terminates, and defaulting to printing return values for the C<r> command.
 810
 811 =cut
 812
 813 # Needed for the statement after exec():
 814 #
 815 # This BEGIN block is simply used to switch off warnings during debugger
 816 # compilation. Probably it would be better practice to fix the warnings,
 817 # but this is how it's done at the moment.
 818
 819 BEGIN {
 820     $ini_warn = $^W;
 821     $^W       = 0;
 822 }    # Switch compilation warnings off until another BEGIN.
 823
 824 local ($^W) = 0;    # Switch run-time warnings off during init.
 825
 826 =head2 THREADS SUPPORT
 827
 828 If we are running under a threaded Perl, we require threads and threads::shared
 829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 830 threaded debugger control.  C<-dt> can also be used to set this.
 831
 832 Each new thread will be announced and the debugger prompt will always inform
 833 you of each new thread created.  It will also indicate the thread id in which
 834 we are currently running within the prompt like this:
 835
 836         [tid] DB<$i>
 837
 838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 839 command prompt.  The prompt will show: C<[0]> when running under threads, but
 840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 841
 842 While running under threads, when you set or delete a breakpoint (etc.), this
 843 will apply to all threads, not just the currently running one.  When you are
 844 in a currently executing thread, you will stay there until it completes.  With
 845 the current implementation it is not currently possible to hop from one thread
 846 to another.
 847
 848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 849
 850 Note that threading support was built into the debugger as of Perl version
 851 C<5.8.6> and debugger version C<1.2.8>.
 852
 853 =cut
 854
 855 BEGIN {
 856   # ensure we can share our non-threaded variables or no-op
 857   if ($ENV{PERL5DB_THREADED}) {
 858         require threads;
 859         require threads::shared;
 860         import threads::shared qw(share);
 861         $DBGR;
 862         share(\$DBGR);
 863         lock($DBGR);
 864         print "Threads support enabled\n";
 865   } else {
 866         *lock  = sub(*) {};
 867         *share = sub(*) {};
 868   }
 869 }
 870
 871 # These variables control the execution of 'dumpvar.pl'.
 872 {
 873     package dumpvar;
 874     use vars qw(
 875     $hashDepth
 876     $arrayDepth
 877     $dumpDBFiles
 878     $dumpPackages
 879     $quoteHighBit
 880     $printUndef
 881     $globPrint
 882     $usageOnly
 883     );
 884 }
 885
 886 # used to control die() reporting in diesignal()
 887 {
 888     package Carp;
 889     use vars qw($CarpLevel);
 890 }
 891
 892 # without threads, $filename is not defined until DB::DB is called
 893 foreach my $k (keys (%INC)) {
 894         share(\$main::{'_<'.$filename}) if defined $filename;
 895 };
 896
 897 # Command-line + PERLLIB:
 898 # Save the contents of @INC before they are modified elsewhere.
 899 @ini_INC = @INC;
 900
 901 # This was an attempt to clear out the previous values of various
 902 # trapped errors. Apparently it didn't help. XXX More info needed!
 903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 904
 905 # We set these variables to safe values. We don't want to blindly turn
 906 # off warnings, because other packages may still want them.
 907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 908                                    # (local $^W cannot help - other packages!).
 909
 910 # Default to not exiting when program finishes; print the return
 911 # value when the 'r' command is used to return from a subroutine.
 912 $inhibit_exit = $option{PrintRet} = 1;
 913
 914 use vars qw($trace_to_depth);
 915
 916 # Default to 1E9 so it won't be limited to a certain recursion depth.
 917 $trace_to_depth = 1E9;
 918
 919 =head1 OPTION PROCESSING
 920
 921 The debugger's options are actually spread out over the debugger itself and
 922 C<dumpvar.pl>; some of these are variables to be set, while others are
 923 subs to be called with a value. To try to make this a little easier to
 924 manage, the debugger uses a few data structures to define what options
 925 are legal and how they are to be processed.
 926
 927 First, the C<@options> array defines the I<names> of all the options that
 928 are to be accepted.
 929
 930 =cut
 931
 932 @options = qw(
 933   CommandSet   HistFile      HistSize
 934   hashDepth    arrayDepth    dumpDepth
 935   DumpDBFiles  DumpPackages  DumpReused
 936   compactDump  veryCompact   quote
 937   HighBit      undefPrint    globPrint
 938   PrintRet     UsageOnly     frame
 939   AutoTrace    TTY           noTTY
 940   ReadLine     NonStop       LineInfo
 941   maxTraceLen  recallCommand ShellBang
 942   pager        tkRunning     ornaments
 943   signalLevel  warnLevel     dieLevel
 944   inhibit_exit ImmediateStop bareStringify
 945   CreateTTY    RemotePort    windowSize
 946   DollarCaretP
 947 );
 948
 949 @RememberOnROptions = qw(DollarCaretP);
 950
 951 =pod
 952
 953 Second, C<optionVars> lists the variables that each option uses to save its
 954 state.
 955
 956 =cut
 957
 958 use vars qw(%optionVars);
 959
 960 %optionVars = (
 961     hashDepth     => \$dumpvar::hashDepth,
 962     arrayDepth    => \$dumpvar::arrayDepth,
 963     CommandSet    => \$CommandSet,
 964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 965     DumpPackages  => \$dumpvar::dumpPackages,
 966     DumpReused    => \$dumpvar::dumpReused,
 967     HighBit       => \$dumpvar::quoteHighBit,
 968     undefPrint    => \$dumpvar::printUndef,
 969     globPrint     => \$dumpvar::globPrint,
 970     UsageOnly     => \$dumpvar::usageOnly,
 971     CreateTTY     => \$CreateTTY,
 972     bareStringify => \$dumpvar::bareStringify,
 973     frame         => \$frame,
 974     AutoTrace     => \$trace,
 975     inhibit_exit  => \$inhibit_exit,
 976     maxTraceLen   => \$maxtrace,
 977     ImmediateStop => \$ImmediateStop,
 978     RemotePort    => \$remoteport,
 979     windowSize    => \$window,
 980     HistFile      => \$histfile,
 981     HistSize      => \$histsize,
 982 );
 983
 984 =pod
 985
 986 Third, C<%optionAction> defines the subroutine to be called to process each
 987 option.
 988
 989 =cut
 990
 991 use vars qw(%optionAction);
 992
 993 %optionAction = (
 994     compactDump   => \&dumpvar::compactDump,
 995     veryCompact   => \&dumpvar::veryCompact,
 996     quote         => \&dumpvar::quote,
 997     TTY           => \&TTY,
 998     noTTY         => \&noTTY,
 999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 use vars qw($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(@hist @truehist %postponed_file @typeahead);
1381
1382 sub _restore_shared_globals_after_restart
1383 {
1384     @hist          = get_list('PERLDB_HIST');
1385     %break_on_load = get_list("PERLDB_ON_LOAD");
1386     %postponed     = get_list("PERLDB_POSTPONE");
1387
1388     share(@hist);
1389     share(@truehist);
1390     share(%break_on_load);
1391     share(%postponed);
1392 }
1393
1394 sub _restore_breakpoints_and_actions {
1395
1396     my @had_breakpoints = get_list("PERLDB_VISITED");
1397
1398     for my $file_idx ( 0 .. $#had_breakpoints ) {
1399         my $filename = $had_breakpoints[$file_idx];
1400         my %pf = get_list("PERLDB_FILE_$file_idx");
1401         $postponed_file{ $filename } = \%pf if %pf;
1402         my @lines = sort {$a <=> $b} keys(%pf);
1403         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1404         for my $line_idx (0 .. $#lines) {
1405             _set_breakpoint_enabled_status(
1406                 $filename,
1407                 $lines[$line_idx],
1408                 ($enabled_statuses[$line_idx] ? 1 : ''),
1409             );
1410         }
1411     }
1412
1413     return;
1414 }
1415
1416 sub _restore_options_after_restart
1417 {
1418     my %options_map = get_list("PERLDB_OPT");
1419
1420     while ( my ( $opt, $val ) = each %options_map ) {
1421         $val =~ s/[\\\']/\\$1/g;
1422         parse_options("$opt'$val'");
1423     }
1424
1425     return;
1426 }
1427
1428 sub _restore_globals_after_restart
1429 {
1430     # restore original @INC
1431     @INC     = get_list("PERLDB_INC");
1432     @ini_INC = @INC;
1433
1434     # return pre/postprompt actions and typeahead buffer
1435     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1436     $pre       = [ get_list("PERLDB_PRE") ];
1437     $post      = [ get_list("PERLDB_POST") ];
1438     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1439
1440     return;
1441 }
1442
1443
1444 if ( exists $ENV{PERLDB_RESTART} ) {
1445
1446     # We're restarting, so we don't need the flag that says to restart anymore.
1447     delete $ENV{PERLDB_RESTART};
1448
1449     # $restart = 1;
1450     _restore_shared_globals_after_restart();
1451
1452     _restore_breakpoints_and_actions();
1453
1454     # restore options
1455     _restore_options_after_restart();
1456
1457     _restore_globals_after_restart();
1458 } ## end if (exists $ENV{PERLDB_RESTART...
1459
1460 =head2 SETTING UP THE TERMINAL
1461
1462 Now, we'll decide how the debugger is going to interact with the user.
1463 If there's no TTY, we set the debugger to run non-stop; there's not going
1464 to be anyone there to enter commands.
1465
1466 =cut
1467
1468 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1469 use vars qw($lineinfo $doccmd);
1470
1471 if ($notty) {
1472     $runnonstop = 1;
1473         share($runnonstop);
1474 }
1475
1476 =pod
1477
1478 If there is a TTY, we have to determine who it belongs to before we can
1479 proceed. If this is a slave editor or graphical debugger (denoted by
1480 the first command-line switch being '-emacs'), we shift this off and
1481 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1482
1483 =cut
1484
1485 else {
1486
1487     # Is Perl being run from a slave editor or graphical debugger?
1488     # If so, don't use readline, and set $slave_editor = 1.
1489     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1490         $rl = 0;
1491         shift(@main::ARGV);
1492     }
1493
1494     #require Term::ReadLine;
1495
1496 =pod
1497
1498 We then determine what the console should be on various systems:
1499
1500 =over 4
1501
1502 =item * Cygwin - We use C<stdin> instead of a separate device.
1503
1504 =cut
1505
1506     if ( $^O eq 'cygwin' ) {
1507
1508         # /dev/tty is binary. use stdin for textmode
1509         undef $console;
1510     }
1511
1512 =item * Unix - use C</dev/tty>.
1513
1514 =cut
1515
1516     elsif ( -e "/dev/tty" ) {
1517         $console = "/dev/tty";
1518     }
1519
1520 =item * Windows or MSDOS - use C<con>.
1521
1522 =cut
1523
1524     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1525         $console = "con";
1526     }
1527
1528 =item * VMS - use C<sys$command>.
1529
1530 =cut
1531
1532     else {
1533
1534         # everything else is ...
1535         $console = "sys\$command";
1536     }
1537
1538 =pod
1539
1540 =back
1541
1542 Several other systems don't use a specific console. We C<undef $console>
1543 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1544 with a slave editor, Epoc).
1545
1546 =cut
1547
1548     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1549
1550         # /dev/tty is binary. use stdin for textmode
1551         $console = undef;
1552     }
1553
1554     if ( $^O eq 'NetWare' ) {
1555
1556         # /dev/tty is binary. use stdin for textmode
1557         $console = undef;
1558     }
1559
1560     # In OS/2, we need to use STDIN to get textmode too, even though
1561     # it pretty much looks like Unix otherwise.
1562     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1563     {    # In OS/2
1564         $console = undef;
1565     }
1566
1567     # EPOC also falls into the 'got to use STDIN' camp.
1568     if ( $^O eq 'epoc' ) {
1569         $console = undef;
1570     }
1571
1572 =pod
1573
1574 If there is a TTY hanging around from a parent, we use that as the console.
1575
1576 =cut
1577
1578     $console = $tty if defined $tty;
1579
1580 =head2 SOCKET HANDLING
1581
1582 The debugger is capable of opening a socket and carrying out a debugging
1583 session over the socket.
1584
1585 If C<RemotePort> was defined in the options, the debugger assumes that it
1586 should try to start a debugging session on that port. It builds the socket
1587 and then tries to connect the input and output filehandles to it.
1588
1589 =cut
1590
1591     # Handle socket stuff.
1592
1593     if ( defined $remoteport ) {
1594
1595         # If RemotePort was defined in the options, connect input and output
1596         # to the socket.
1597         $IN = $OUT = connect_remoteport();
1598     } ## end if (defined $remoteport)
1599
1600 =pod
1601
1602 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1603 this is probably a situation where multiple debuggers are running (for example,
1604 a backticked command that starts up another debugger). We create a new IN and
1605 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1606 and if we can.
1607
1608 =cut
1609
1610     # Non-socket.
1611     else {
1612
1613         # Two debuggers running (probably a system or a backtick that invokes
1614         # the debugger itself under the running one). create a new IN and OUT
1615         # filehandle, and do the necessary mojo to create a new tty if we
1616         # know how, and we can.
1617         create_IN_OUT(4) if $CreateTTY & 4;
1618         if ($console) {
1619
1620             # If we have a console, check to see if there are separate ins and
1621             # outs to open. (They are assumed identical if not.)
1622
1623             my ( $i, $o ) = split /,/, $console;
1624             $o = $i unless defined $o;
1625
1626             # read/write on in, or just read, or read on STDIN.
1627             open( IN,      "+<$i" )
1628               || open( IN, "<$i" )
1629               || open( IN, "<&STDIN" );
1630
1631             # read/write/create/clobber out, or write/create/clobber out,
1632             # or merge with STDERR, or merge with STDOUT.
1633                  open( OUT, "+>$o" )
1634               || open( OUT, ">$o" )
1635               || open( OUT, ">&STDERR" )
1636               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1637
1638         } ## end if ($console)
1639         elsif ( not defined $console ) {
1640
1641             # No console. Open STDIN.
1642             open( IN, "<&STDIN" );
1643
1644             # merge with STDERR, or with STDOUT.
1645             open( OUT,      ">&STDERR" )
1646               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1647             $console = 'STDIN/OUT';
1648         } ## end elsif (not defined $console)
1649
1650         # Keep copies of the filehandles so that when the pager runs, it
1651         # can close standard input without clobbering ours.
1652         if ($console or (not defined($console))) {
1653             $IN = \*IN;
1654             $OUT = \*OUT;
1655         }
1656     } ## end elsif (from if(defined $remoteport))
1657
1658     # Unbuffer DB::OUT. We need to see responses right away.
1659     $OUT->autoflush(1);
1660
1661     # Line info goes to debugger output unless pointed elsewhere.
1662     # Pointing elsewhere makes it possible for slave editors to
1663     # keep track of file and position. We have both a filehandle
1664     # and a I/O description to keep track of.
1665     $LINEINFO = $OUT     unless defined $LINEINFO;
1666     $lineinfo = $console unless defined $lineinfo;
1667         # share($LINEINFO); # <- unable to share globs
1668         share($lineinfo);   #
1669
1670 =pod
1671
1672 To finish initialization, we show the debugger greeting,
1673 and then call the C<afterinit()> subroutine if there is one.
1674
1675 =cut
1676
1677     # Show the debugger greeting.
1678     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1679     unless ($runnonstop) {
1680         local $\ = '';
1681         local $, = '';
1682         if ( $term_pid eq '-1' ) {
1683             print $OUT "\nDaughter DB session started...\n";
1684         }
1685         else {
1686             print $OUT "\nLoading DB routines from $header\n";
1687             print $OUT (
1688                 "Editor support ",
1689                 $slave_editor ? "enabled" : "available", ".\n"
1690             );
1691             print $OUT
1692 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1693         } ## end else [ if ($term_pid eq '-1')
1694     } ## end unless ($runnonstop)
1695 } ## end else [ if ($notty)
1696
1697 # XXX This looks like a bug to me.
1698 # Why copy to @ARGS and then futz with @args?
1699 @ARGS = @ARGV;
1700 # for (@args) {
1701     # Make sure backslashes before single quotes are stripped out, and
1702     # keep args unless they are numeric (XXX why?)
1703     # s/\'/\\\'/g;                      # removed while not justified understandably
1704     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1705 # }
1706
1707 # If there was an afterinit() sub defined, call it. It will get
1708 # executed in our scope, so it can fiddle with debugger globals.
1709 if ( defined &afterinit ) {    # May be defined in $rcfile
1710     afterinit();
1711 }
1712
1713 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1714 use vars qw($I_m_init);
1715
1716 $I_m_init = 1;
1717
1718 ############################################################ Subroutines
1719
1720 =head1 SUBROUTINES
1721
1722 =head2 DB
1723
1724 This gigantic subroutine is the heart of the debugger. Called before every
1725 statement, its job is to determine if a breakpoint has been reached, and
1726 stop if so; read commands from the user, parse them, and execute
1727 them, and then send execution off to the next statement.
1728
1729 Note that the order in which the commands are processed is very important;
1730 some commands earlier in the loop will actually alter the C<$cmd> variable
1731 to create other commands to be executed later. This is all highly I<optimized>
1732 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1733 see what's happening in any given command.
1734
1735 =cut
1736
1737 use vars qw(
1738     $action
1739     %alias
1740     $cmd
1741     $doret
1742     $fall_off_end
1743     $file
1744     $filename_ini
1745     $finished
1746     %had_breakpoints
1747     $incr
1748     $laststep
1749     $level
1750     $max
1751     @old_watch
1752     $package
1753     $rc
1754     $sh
1755     @stack
1756     $stack_depth
1757     @to_watch
1758     $try
1759     $end
1760 );
1761
1762 sub _DB_on_init__initialize_globals
1763 {
1764     # Check for whether we should be running continuously or not.
1765     # _After_ the perl program is compiled, $single is set to 1:
1766     if ( $single and not $second_time++ ) {
1767
1768         # Options say run non-stop. Run until we get an interrupt.
1769         if ($runnonstop) {    # Disable until signal
1770                 # If there's any call stack in place, turn off single
1771                 # stepping into subs throughout the stack.
1772             for my $i (0 .. $stack_depth) {
1773                 $stack[ $i ] &= ~1;
1774             }
1775
1776             # And we are now no longer in single-step mode.
1777             $single = 0;
1778
1779             # If we simply returned at this point, we wouldn't get
1780             # the trace info. Fall on through.
1781             # return;
1782         } ## end if ($runnonstop)
1783
1784         elsif ($ImmediateStop) {
1785
1786             # We are supposed to stop here; XXX probably a break.
1787             $ImmediateStop = 0;    # We've processed it; turn it off
1788             $signal        = 1;    # Simulate an interrupt to force
1789                                    # us into the command loop
1790         }
1791     } ## end if ($single and not $second_time...
1792
1793     # If we're in single-step mode, or an interrupt (real or fake)
1794     # has occurred, turn off non-stop mode.
1795     $runnonstop = 0 if $single or $signal;
1796
1797     return;
1798 }
1799
1800 sub DB {
1801
1802     # lock the debugger and get the thread id for the prompt
1803     lock($DBGR);
1804     my $tid;
1805     my $position;
1806     my ($prefix, $after, $infix);
1807     my $pat;
1808
1809     if ($ENV{PERL5DB_THREADED}) {
1810         $tid = eval { "[".threads->tid."]" };
1811     }
1812
1813     _DB_on_init__initialize_globals();
1814
1815     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1816     # The code being debugged may have altered them.
1817     &save;
1818
1819     # Since DB::DB gets called after every line, we can use caller() to
1820     # figure out where we last were executing. Sneaky, eh? This works because
1821     # caller is returning all the extra information when called from the
1822     # debugger.
1823     local ( $package, $filename, $line ) = caller;
1824     $filename_ini = $filename;
1825
1826     # set up the context for DB::eval, so it can properly execute
1827     # code on behalf of the user. We add the package in so that the
1828     # code is eval'ed in the proper package (not in the debugger!).
1829     local $usercontext = _calc_usercontext($package);
1830
1831     # Create an alias to the active file magical array to simplify
1832     # the code here.
1833     local (*dbline) = $main::{ '_<' . $filename };
1834
1835     # Last line in the program.
1836     $max = $#dbline;
1837
1838     # if we have something here, see if we should break.
1839     {
1840         # $stop is lexical and local to this block - $action on the other hand
1841         # is global.
1842         my $stop;
1843
1844         if ( $dbline{$line}
1845             && _is_breakpoint_enabled($filename, $line)
1846             && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1847         {
1848
1849             # Stop if the stop criterion says to just stop.
1850             if ( $stop eq '1' ) {
1851                 $signal |= 1;
1852             }
1853
1854             # It's a conditional stop; eval it in the user's context and
1855             # see if we should stop. If so, remove the one-time sigil.
1856             elsif ($stop) {
1857                 $evalarg = "\$DB::signal |= 1 if do {$stop}";
1858                 &eval;
1859                 # If the breakpoint is temporary, then delete its enabled status.
1860                 if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1861                     _cancel_breakpoint_temp_enabled_status($filename, $line);
1862                 }
1863             }
1864         } ## end if ($dbline{$line} && ...
1865     }
1866
1867     # Preserve the current stop-or-not, and see if any of the W
1868     # (watch expressions) has changed.
1869     my $was_signal = $signal;
1870
1871     # If we have any watch expressions ...
1872     if ( $trace & 2 ) {
1873         for my $n (0 .. $#to_watch) {
1874             $evalarg = $to_watch[$n];
1875             local $onetimeDump;    # Tell DB::eval() to not output results
1876
1877             # Fix context DB::eval() wants to return an array, but
1878             # we need a scalar here.
1879             my ($val) = join( "', '", &eval );
1880             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1881
1882             # Did it change?
1883             if ( $val ne $old_watch[$n] ) {
1884
1885                 # Yep! Show the difference, and fake an interrupt.
1886                 $signal = 1;
1887                 print $OUT <<EOP;
1888 Watchpoint $n:\t$to_watch[$n] changed:
1889     old value:\t$old_watch[$n]
1890     new value:\t$val
1891 EOP
1892                 $old_watch[$n] = $val;
1893             } ## end if ($val ne $old_watch...
1894         } ## end for my $n (0 ..
1895     } ## end if ($trace & 2)
1896
1897 =head2 C<watchfunction()>
1898
1899 C<watchfunction()> is a function that can be defined by the user; it is a
1900 function which will be run on each entry to C<DB::DB>; it gets the
1901 current package, filename, and line as its parameters.
1902
1903 The watchfunction can do anything it likes; it is executing in the
1904 debugger's context, so it has access to all of the debugger's internal
1905 data structures and functions.
1906
1907 C<watchfunction()> can control the debugger's actions. Any of the following
1908 will cause the debugger to return control to the user's program after
1909 C<watchfunction()> executes:
1910
1911 =over 4
1912
1913 =item *
1914
1915 Returning a false value from the C<watchfunction()> itself.
1916
1917 =item *
1918
1919 Altering C<$single> to a false value.
1920
1921 =item *
1922
1923 Altering C<$signal> to a false value.
1924
1925 =item *
1926
1927 Turning off the C<4> bit in C<$trace> (this also disables the
1928 check for C<watchfunction()>. This can be done with
1929
1930     $trace &= ~4;
1931
1932 =back
1933
1934 =cut
1935
1936     # If there's a user-defined DB::watchfunction, call it with the
1937     # current package, filename, and line. The function executes in
1938     # the DB:: package.
1939     if ( $trace & 4 ) {    # User-installed watch
1940         return
1941           if watchfunction( $package, $filename, $line )
1942           and not $single
1943           and not $was_signal
1944           and not( $trace & ~4 );
1945     } ## end if ($trace & 4)
1946
1947     # Pick up any alteration to $signal in the watchfunction, and
1948     # turn off the signal now.
1949     $was_signal = $signal;
1950     $signal     = 0;
1951
1952 =head2 GETTING READY TO EXECUTE COMMANDS
1953
1954 The debugger decides to take control if single-step mode is on, the
1955 C<t> command was entered, or the user generated a signal. If the program
1956 has fallen off the end, we set things up so that entering further commands
1957 won't cause trouble, and we say that the program is over.
1958
1959 =cut
1960
1961     # Make sure that we always print if asked for explicitly regardless
1962     # of $trace_to_depth .
1963     my $explicit_stop = ($single || $was_signal);
1964
1965     # Check to see if we should grab control ($single true,
1966     # trace set appropriately, or we got a signal).
1967     if ( $explicit_stop || ( $trace & 1 ) ) {
1968
1969         # Yes, grab control.
1970         if ($slave_editor) {
1971
1972             # Tell the editor to update its position.
1973             $position = "\032\032$filename:$line:0\n";
1974             print_lineinfo($position);
1975         }
1976
1977 =pod
1978
1979 Special check: if we're in package C<DB::fake>, we've gone through the
1980 C<END> block at least once. We set up everything so that we can continue
1981 to enter commands and have a valid context to be in.
1982
1983 =cut
1984
1985         elsif ( $package eq 'DB::fake' ) {
1986
1987             # Fallen off the end already.
1988             $term || &setterm;
1989             print_help(<<EOP);
1990 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1991   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1992   B<h q>, B<h R> or B<h o> to get additional info.
1993 EOP
1994
1995             # Set the DB::eval context appropriately.
1996             $package     = 'main';
1997             $usercontext = _calc_usercontext($package);
1998         } ## end elsif ($package eq 'DB::fake')
1999
2000 =pod
2001
2002 If the program hasn't finished executing, we scan forward to the
2003 next executable line, print that out, build the prompt from the file and line
2004 number information, and print that.
2005
2006 =cut
2007
2008         else {
2009
2010
2011             # Still somewhere in the midst of execution. Set up the
2012             #  debugger prompt.
2013             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2014                                  # Perl 5 ones (sorry, we don't print Klingon
2015                                  #module names)
2016
2017             $prefix = $sub =~ /::/ ? "" : ($package . '::');
2018             $prefix .= "$sub($filename:";
2019             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2020
2021             # Break up the prompt if it's really long.
2022             if ( length($prefix) > 30 ) {
2023                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2024                 $prefix   = "";
2025                 $infix    = ":\t";
2026             }
2027             else {
2028                 $infix    = "):\t";
2029                 $position = "$prefix$line$infix$dbline[$line]$after";
2030             }
2031
2032             # Print current line info, indenting if necessary.
2033             if ($frame) {
2034                 print_lineinfo( ' ' x $stack_depth,
2035                     "$line:\t$dbline[$line]$after" );
2036             }
2037             else {
2038                 depth_print_lineinfo($explicit_stop, $position);
2039             }
2040
2041             # Scan forward, stopping at either the end or the next
2042             # unbreakable line.
2043             for ( my $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2044             {    #{ vi
2045
2046                 # Drop out on null statements, block closers, and comments.
2047                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2048
2049                 # Drop out if the user interrupted us.
2050                 last if $signal;
2051
2052                 # Append a newline if the line doesn't have one. Can happen
2053                 # in eval'ed text, for instance.
2054                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2055
2056                 # Next executable line.
2057                 my $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2058                 $position .= $incr_pos;
2059                 if ($frame) {
2060
2061                     # Print it indented if tracing is on.
2062                     print_lineinfo( ' ' x $stack_depth,
2063                         "$i:\t$dbline[$i]$after" );
2064                 }
2065                 else {
2066                     depth_print_lineinfo($explicit_stop, $incr_pos);
2067                 }
2068             } ## end for ($i = $line + 1 ; $i...
2069         } ## end else [ if ($slave_editor)
2070     } ## end if ($single || ($trace...
2071
2072 =pod
2073
2074 If there's an action to be executed for the line we stopped at, execute it.
2075 If there are any preprompt actions, execute those as well.
2076
2077 =cut
2078
2079     # If there's an action, do it now.
2080     $evalarg = $action, &eval if $action;
2081
2082     # Are we nested another level (e.g., did we evaluate a function
2083     # that had a breakpoint in it at the debugger prompt)?
2084     if ( $single || $was_signal ) {
2085
2086         # Yes, go down a level.
2087         local $level = $level + 1;
2088
2089         # Do any pre-prompt actions.
2090         foreach $evalarg (@$pre) {
2091             &eval;
2092         }
2093
2094         # Complain about too much recursion if we passed the limit.
2095         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2096           if $single & 4;
2097
2098         # The line we're currently on. Set $incr to -1 to stay here
2099         # until we get a command that tells us to advance.
2100         $start = $line;
2101         $incr  = -1;      # for backward motion.
2102
2103         # Tack preprompt debugger actions ahead of any actual input.
2104         @typeahead = ( @$pretype, @typeahead );
2105
2106 =head2 WHERE ARE WE?
2107
2108 XXX Relocate this section?
2109
2110 The debugger normally shows the line corresponding to the current line of
2111 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2112 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2113
2114 C<$incr> controls by how many lines the I<current> line should move forward
2115 after a command is executed. If set to -1, this indicates that the I<current>
2116 line shouldn't change.
2117
2118 C<$start> is the I<current> line. It is used for things like knowing where to
2119 move forwards or backwards from when doing an C<L> or C<-> command.
2120
2121 C<$max> tells the debugger where the last line of the current file is. It's
2122 used to terminate loops most often.
2123
2124 =head2 THE COMMAND LOOP
2125
2126 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2127 in two parts:
2128
2129 =over 4
2130
2131 =item *
2132
2133 The outer part of the loop, starting at the C<CMD> label. This loop
2134 reads a command and then executes it.
2135
2136 =item *
2137
2138 The inner part of the loop, starting at the C<PIPE> label. This part
2139 is wholly contained inside the C<CMD> block and only executes a command.
2140 Used to handle commands running inside a pager.
2141
2142 =back
2143
2144 So why have two labels to restart the loop? Because sometimes, it's easier to
2145 have a command I<generate> another command and then re-execute the loop to do
2146 the new command. This is faster, but perhaps a bit more convoluted.
2147
2148 =cut
2149
2150         # The big command dispatch loop. It keeps running until the
2151         # user yields up control again.
2152         #
2153         # If we have a terminal for input, and we get something back
2154         # from readline(), keep on processing.
2155         my $piped;
2156         my $selected;
2157
2158       CMD:
2159         while (
2160
2161             # We have a terminal, or can get one ...
2162             ( $term || &setterm ),
2163
2164             # ... and it belogs to this PID or we get one for this PID ...
2165             ( $term_pid == $$ or resetterm(1) ),
2166
2167             # ... and we got a line of command input ...
2168             defined(
2169                 $cmd = &readline(
2170                         "$pidprompt $tid DB"
2171                       . ( '<' x $level )
2172                       . ( $#hist + 1 )
2173                       . ( '>' x $level ) . " "
2174                 )
2175             )
2176           )
2177         {
2178
2179                         share($cmd);
2180             # ... try to execute the input as debugger commands.
2181
2182             # Don't stop running.
2183             $single = 0;
2184
2185             # No signal is active.
2186             $signal = 0;
2187
2188             # Handle continued commands (ending with \):
2189             if ($cmd =~ s/\\\z/\n/) {
2190                 $cmd .= &readline("  cont: ");
2191                 redo CMD;
2192             }
2193
2194 =head4 The null command
2195
2196 A newline entered by itself means I<re-execute the last command>. We grab the
2197 command out of C<$laststep> (where it was recorded previously), and copy it
2198 back into C<$cmd> to be executed below. If there wasn't any previous command,
2199 we'll do nothing below (no command will match). If there was, we also save it
2200 in the command history and fall through to allow the command parsing to pick
2201 it up.
2202
2203 =cut
2204
2205             # Empty input means repeat the last command.
2206             $cmd =~ /^$/ && ( $cmd = $laststep );
2207             chomp($cmd);    # get rid of the annoying extra newline
2208             push( @hist, $cmd ) if length($cmd) > 1;
2209             push( @truehist, $cmd );
2210                         share(@hist);
2211                         share(@truehist);
2212
2213             # This is a restart point for commands that didn't arrive
2214             # via direct user input. It allows us to 'redo PIPE' to
2215             # re-execute command processing without reading a new command.
2216           PIPE: {
2217                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2218                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2219                 my ($i) = split( /\s+/, $cmd );
2220
2221 =head3 COMMAND ALIASES
2222
2223 The debugger can create aliases for commands (these are stored in the
2224 C<%alias> hash). Before a command is executed, the command loop looks it up
2225 in the alias hash and substitutes the contents of the alias for the command,
2226 completely replacing it.
2227
2228 =cut
2229
2230                 # See if there's an alias for the command, and set it up if so.
2231                 if ( $alias{$i} ) {
2232
2233                     # Squelch signal handling; we want to keep control here
2234                     # if something goes loco during the alias eval.
2235                     local $SIG{__DIE__};
2236                     local $SIG{__WARN__};
2237
2238                     # This is a command, so we eval it in the DEBUGGER's
2239                     # scope! Otherwise, we can't see the special debugger
2240                     # variables, or get to the debugger's subs. (Well, we
2241                     # _could_, but why make it even more complicated?)
2242                     eval "\$cmd =~ $alias{$i}";
2243                     if ($@) {
2244                         local $\ = '';
2245                         print $OUT "Couldn't evaluate '$i' alias: $@";
2246                         next CMD;
2247                     }
2248                 } ## end if ($alias{$i})
2249
2250 =head3 MAIN-LINE COMMANDS
2251
2252 All of these commands work up to and after the program being debugged has
2253 terminated.
2254
2255 =head4 C<q> - quit
2256
2257 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2258 try to execute further, cleaning any restart-related stuff out of the
2259 environment, and executing with the last value of C<$?>.
2260
2261 =cut
2262
2263                 if ($cmd eq 'q') {
2264                     $fall_off_end = 1;
2265                     clean_ENV();
2266                     exit $?;
2267                 }
2268
2269 =head4 C<t> - trace [n]
2270
2271 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2272 If level is specified, set C<$trace_to_depth>.
2273
2274 =cut
2275
2276                 if (my ($levels) = $cmd =~ /\At(?:\s+(\d+))?\z/) {
2277                     $trace ^= 1;
2278                     local $\ = '';
2279                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2280                     print $OUT "Trace = "
2281                       . ( ( $trace & 1 )
2282                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2283                       : "off" ) . "\n";
2284                     next CMD;
2285                 }
2286
2287 =head4 C<S> - list subroutines matching/not matching a pattern
2288
2289 Walks through C<%sub>, checking to see whether or not to print the name.
2290
2291 =cut
2292
2293                 if (my ($print_all_subs, $should_reverse, $Spatt)
2294                     = $cmd =~ /\AS(\s+(!)?(.+))?\z/) {
2295                     # $Spatt is the pattern (if any) to use.
2296                     # Reverse scan?
2297                     my $Srev     = defined $should_reverse;
2298                     # No args - print all subs.
2299                     my $Snocheck = !defined $print_all_subs;
2300
2301                     # Need to make these sane here.
2302                     local $\ = '';
2303                     local $, = '';
2304
2305                     # Search through the debugger's magical hash of subs.
2306                     # If $nocheck is true, just print the sub name.
2307                     # Otherwise, check it against the pattern. We then use
2308                     # the XOR trick to reverse the condition as required.
2309                     foreach $subname ( sort( keys %sub ) ) {
2310                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2311                             print $OUT $subname, "\n";
2312                         }
2313                     }
2314                     next CMD;
2315                 }
2316
2317 =head4 C<X> - list variables in current package
2318
2319 Since the C<V> command actually processes this, just change this to the
2320 appropriate C<V> command and fall through.
2321
2322 =cut
2323
2324                 $cmd =~ s/^X\b/V $package/;
2325
2326 =head4 C<V> - list variables
2327
2328 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2329
2330 =cut
2331
2332                 # Bare V commands get the currently-being-debugged package
2333                 # added.
2334                 if ($cmd eq "V") {
2335                     $cmd = "V $package";
2336                 }
2337
2338                 # V - show variables in package.
2339                 if (my ($new_packname, $new_vars_str) =
2340                     $cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
2341
2342                     # Save the currently selected filehandle and
2343                     # force output to debugger's filehandle (dumpvar
2344                     # just does "print" for output).
2345                     my $savout = select($OUT);
2346
2347                     # Grab package name and variables to dump.
2348                     $packname = $new_packname;
2349                     my @vars     = split( ' ', $new_vars_str );
2350
2351                     # If main::dumpvar isn't here, get it.
2352                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2353                     if ( defined &main::dumpvar ) {
2354
2355                         # We got it. Turn off subroutine entry/exit messages
2356                         # for the moment, along with return values.
2357                         local $frame = 0;
2358                         local $doret = -2;
2359
2360                         # must detect sigpipe failures  - not catching
2361                         # then will cause the debugger to die.
2362                         eval {
2363                             &main::dumpvar(
2364                                 $packname,
2365                                 defined $option{dumpDepth}
2366                                 ? $option{dumpDepth}
2367                                 : -1,    # assume -1 unless specified
2368                                 @vars
2369                             );
2370                         };
2371
2372                         # The die doesn't need to include the $@, because
2373                         # it will automatically get propagated for us.
2374                         if ($@) {
2375                             die unless $@ =~ /dumpvar print failed/;
2376                         }
2377                     } ## end if (defined &main::dumpvar)
2378                     else {
2379
2380                         # Couldn't load dumpvar.
2381                         print $OUT "dumpvar.pl not available.\n";
2382                     }
2383
2384                     # Restore the output filehandle, and go round again.
2385                     select($savout);
2386                     next CMD;
2387                 }
2388
2389 =head4 C<x> - evaluate and print an expression
2390
2391 Hands the expression off to C<DB::eval>, setting it up to print the value
2392 via C<dumpvar.pl> instead of just printing it directly.
2393
2394 =cut
2395
2396                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2397                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2398
2399                     # handle special  "x 3 blah" syntax XXX propagate
2400                     # doc back to special variables.
2401                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2402                         $onetimedumpDepth = $1;
2403                     }
2404                 }
2405
2406 =head4 C<m> - print methods
2407
2408 Just uses C<DB::methods> to determine what methods are available.
2409
2410 =cut
2411
2412                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2413                     methods($1);
2414                     next CMD;
2415                 }
2416
2417                 # m expr - set up DB::eval to do the work
2418                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2419                     $onetimeDump = 'methods';   #  method output gets used there
2420                 }
2421
2422 =head4 C<f> - switch files
2423
2424 =cut
2425
2426                 if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
2427                     $file =~ s/\s+$//;
2428
2429                     # help for no arguments (old-style was return from sub).
2430                     if ( !$file ) {
2431                         print $OUT
2432                           "The old f command is now the r command.\n";    # hint
2433                         print $OUT "The new f command switches filenames.\n";
2434                         next CMD;
2435                     } ## end if (!$file)
2436
2437                     # if not in magic file list, try a close match.
2438                     if ( !defined $main::{ '_<' . $file } ) {
2439                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2440                             {
2441                                 $try = substr( $try, 2 );
2442                                 print $OUT "Choosing $try matching '$file':\n";
2443                                 $file = $try;
2444                             }
2445                         } ## end if (($try) = grep(m#^_<.*$file#...
2446                     } ## end if (!defined $main::{ ...
2447
2448                     # If not successfully switched now, we failed.
2449                     if ( !defined $main::{ '_<' . $file } ) {
2450                         print $OUT "No file matching '$file' is loaded.\n";
2451                         next CMD;
2452                     }
2453
2454                     # We switched, so switch the debugger internals around.
2455                     elsif ( $file ne $filename ) {
2456                         *dbline   = $main::{ '_<' . $file };
2457                         $max      = $#dbline;
2458                         $filename = $file;
2459                         $start    = 1;
2460                         $cmd      = "l";
2461                     } ## end elsif ($file ne $filename)
2462
2463                     # We didn't switch; say we didn't.
2464                     else {
2465                         print $OUT "Already in $file.\n";
2466                         next CMD;
2467                     }
2468                 }
2469
2470 =head4 C<.> - return to last-executed line.
2471
2472 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2473 and then we look up the line in the magical C<%dbline> hash.
2474
2475 =cut
2476
2477                 # . command.
2478                 if ($cmd eq '.') {
2479                     $incr = -1;    # stay at current line
2480
2481                     # Reset everything to the old location.
2482                     $start    = $line;
2483                     $filename = $filename_ini;
2484                     *dbline   = $main::{ '_<' . $filename };
2485                     $max      = $#dbline;
2486
2487                     # Now where are we?
2488                     print_lineinfo($position);
2489                     next CMD;
2490                 }
2491
2492 =head4 C<-> - back one window
2493
2494 We change C<$start> to be one window back; if we go back past the first line,
2495 we set it to be the first line. We ser C<$incr> to put us back at the
2496 currently-executing line, and then put a C<l $start +> (list one window from
2497 C<$start>) in C<$cmd> to be executed later.
2498
2499 =cut
2500
2501                 # - - back a window.
2502                 if ($cmd eq '-') {
2503
2504                     # back up by a window; go to 1 if back too far.
2505                     $start -= $incr + $window + 1;
2506                     $start = 1 if $start <= 0;
2507                     $incr  = $window - 1;
2508
2509                     # Generate and execute a "l +" command (handled below).
2510                     $cmd = 'l ' . ($start) . '+';
2511                 }
2512
2513 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2514
2515 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2516 problems, most notably that the default case of several commands destroying
2517 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2518 retain the old commands for those who were used to using them or who preferred
2519 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2520 deal with them instead of processing them in-line.
2521
2522 =cut
2523
2524                 # All of these commands were remapped in perl 5.8.0;
2525                 # we send them off to the secondary dispatcher (see below).
2526                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2527                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2528                     next CMD;
2529                 }
2530
2531 =head4 C<y> - List lexicals in higher scope
2532
2533 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2534 above the current one and then displays then using C<dumpvar.pl>.
2535
2536 =cut
2537
2538                 if (my ($match_level, $match_vars)
2539                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2540
2541                     # See if we've got the necessary support.
2542                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2543                       or &warn(
2544                         $@ =~ /locate/
2545                         ? "PadWalker module not found - please install\n"
2546                         : $@
2547                       )
2548                       and next CMD;
2549
2550                     # Load up dumpvar if we don't have it. If we can, that is.
2551                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2552                     defined &main::dumpvar
2553                       or print $OUT "dumpvar.pl not available.\n"
2554                       and next CMD;
2555
2556                     # Got all the modules we need. Find them and print them.
2557                     my @vars = split( ' ', $match_vars || '' );
2558
2559                     # Find the pad.
2560                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2561
2562                     # Oops. Can't find it.
2563                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2564
2565                     # Show the desired vars with dumplex().
2566                     my $savout = select($OUT);
2567
2568                     # Have dumplex dump the lexicals.
2569                     dumpvar::dumplex( $_, $h->{$_},
2570                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2571                         @vars )
2572                       for sort keys %$h;
2573                     select($savout);
2574                     next CMD;
2575                 }
2576
2577 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2578
2579 All of the commands below this point don't work after the program being
2580 debugged has ended. All of them check to see if the program has ended; this
2581 allows the commands to be relocated without worrying about a 'line of
2582 demarcation' above which commands can be entered anytime, and below which
2583 they can't.
2584
2585 =head4 C<n> - single step, but don't trace down into subs
2586
2587 Done by setting C<$single> to 2, which forces subs to execute straight through
2588 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2589 so a null command knows what to re-execute.
2590
2591 =cut
2592
2593                 # n - next
2594                 if ($cmd eq 'n') {
2595                     end_report(), next CMD if $finished and $level <= 1;
2596
2597                     # Single step, but don't enter subs.
2598                     $single = 2;
2599
2600                     # Save for empty command (repeat last).
2601                     $laststep = $cmd;
2602                     last CMD;
2603                 }
2604
2605 =head4 C<s> - single-step, entering subs
2606
2607 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2608 subs. Also saves C<s> as C<$lastcmd>.
2609
2610 =cut
2611
2612                 # s - single step.
2613                 if ($cmd eq 's') {
2614
2615                     # Get out and restart the command loop if program
2616                     # has finished.
2617                     end_report(), next CMD if $finished and $level <= 1;
2618
2619                     # Single step should enter subs.
2620                     $single = 1;
2621
2622                     # Save for empty command (repeat last).
2623                     $laststep = $cmd;
2624                     last CMD;
2625                 }
2626
2627 =head4 C<c> - run continuously, setting an optional breakpoint
2628
2629 Most of the code for this command is taken up with locating the optional
2630 breakpoint, which is either a subroutine name or a line number. We set
2631 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2632 in this and all call levels above this one.
2633
2634 =cut
2635
2636                 # c - start continuous execution.
2637                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2638
2639                     # Hey, show's over. The debugged program finished
2640                     # executing already.
2641                     end_report(), next CMD if $finished and $level <= 1;
2642
2643                     # Capture the place to put a one-time break.
2644                     $subname = $i;
2645
2646                     #  Probably not needed, since we finish an interactive
2647                     #  sub-session anyway...
2648                     # local $filename = $filename;
2649                     # local *dbline = *dbline; # XXX Would this work?!
2650                     #
2651                     # The above question wonders if localizing the alias
2652                     # to the magic array works or not. Since it's commented
2653                     # out, we'll just leave that to speculation for now.
2654
2655                     # If the "subname" isn't all digits, we'll assume it
2656                     # is a subroutine name, and try to find it.
2657                     if ( $subname =~ /\D/ ) {    # subroutine name
2658                             # Qualify it to the current package unless it's
2659                             # already qualified.
2660                         $subname = $package . "::" . $subname
2661                           unless $subname =~ /::/;
2662
2663                         # find_sub will return "file:line_number" corresponding
2664                         # to where the subroutine is defined; we call find_sub,
2665                         # break up the return value, and assign it in one
2666                         # operation.
2667                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2668
2669                         # Force the line number to be numeric.
2670                         $i += 0;
2671
2672                         # If we got a line number, we found the sub.
2673                         if ($i) {
2674
2675                             # Switch all the debugger's internals around so
2676                             # we're actually working with that file.
2677                             $filename = $file;
2678                             *dbline   = $main::{ '_<' . $filename };
2679
2680                             # Mark that there's a breakpoint in this file.
2681                             $had_breakpoints{$filename} |= 1;
2682
2683                             # Scan forward to the first executable line
2684                             # after the 'sub whatever' line.
2685                             $max = $#dbline;
2686                             ++$i while $dbline[$i] == 0 && $i < $max;
2687                         } ## end if ($i)
2688
2689                         # We didn't find a sub by that name.
2690                         else {
2691                             print $OUT "Subroutine $subname not found.\n";
2692                             next CMD;
2693                         }
2694                     } ## end if ($subname =~ /\D/)
2695
2696                     # At this point, either the subname was all digits (an
2697                     # absolute line-break request) or we've scanned through
2698                     # the code following the definition of the sub, looking
2699                     # for an executable, which we may or may not have found.
2700                     #
2701                     # If $i (which we set $subname from) is non-zero, we
2702                     # got a request to break at some line somewhere. On
2703                     # one hand, if there wasn't any real subroutine name
2704                     # involved, this will be a request to break in the current
2705                     # file at the specified line, so we have to check to make
2706                     # sure that the line specified really is breakable.
2707                     #
2708                     # On the other hand, if there was a subname supplied, the
2709                     # preceding block has moved us to the proper file and
2710                     # location within that file, and then scanned forward
2711                     # looking for the next executable line. We have to make
2712                     # sure that one was found.
2713                     #
2714                     # On the gripping hand, we can't do anything unless the
2715                     # current value of $i points to a valid breakable line.
2716                     # Check that.
2717                     if ($i) {
2718
2719                         # Breakable?
2720                         if ( $dbline[$i] == 0 ) {
2721                             print $OUT "Line $i not breakable.\n";
2722                             next CMD;
2723                         }
2724
2725                         # Yes. Set up the one-time-break sigil.
2726                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2727                         _enable_breakpoint_temp_enabled_status($filename, $i);
2728                     } ## end if ($i)
2729
2730                     # Turn off stack tracing from here up.
2731                     for my $i (0 .. $stack_depth) {
2732                         $stack[ $i ] &= ~1;
2733                     }
2734                     last CMD;
2735                 }
2736
2737 =head4 C<r> - return from a subroutine
2738
2739 For C<r> to work properly, the debugger has to stop execution again
2740 immediately after the return is executed. This is done by forcing
2741 single-stepping to be on in the call level above the current one. If
2742 we are printing return values when a C<r> is executed, set C<$doret>
2743 appropriately, and force us out of the command loop.
2744
2745 =cut
2746
2747                 # r - return from the current subroutine.
2748                 if ($cmd eq 'r') {
2749
2750                     # Can't do anything if the program's over.
2751                     end_report(), next CMD if $finished and $level <= 1;
2752
2753                     # Turn on stack trace.
2754                     $stack[$stack_depth] |= 1;
2755
2756                     # Print return value unless the stack is empty.
2757                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2758                     last CMD;
2759                 }
2760
2761 =head4 C<T> - stack trace
2762
2763 Just calls C<DB::print_trace>.
2764
2765 =cut
2766
2767                 if ($cmd eq 'T') {
2768                     print_trace( $OUT, 1 );    # skip DB
2769                     next CMD;
2770                 }
2771
2772 =head4 C<w> - List window around current line.
2773
2774 Just calls C<DB::cmd_w>.
2775
2776 =cut
2777
2778                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2779                     &cmd_w( 'w', $arg );
2780                     next CMD;
2781                 }
2782
2783 =head4 C<W> - watch-expression processing.
2784
2785 Just calls C<DB::cmd_W>.
2786
2787 =cut
2788
2789                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2790                     &cmd_W( 'W', $arg );
2791                     next CMD;
2792                 }
2793
2794 =head4 C</> - search forward for a string in the source
2795
2796 We take the argument and treat it as a pattern. If it turns out to be a
2797 bad one, we return the error we got from trying to C<eval> it and exit.
2798 If not, we create some code to do the search and C<eval> it so it can't
2799 mess us up.
2800
2801 =cut
2802
2803                 # The pattern as a string.
2804                 use vars qw($inpat);
2805
2806                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2807
2808                     # Remove the final slash.
2809                     $inpat =~ s:([^\\])/$:$1:;
2810
2811                     # If the pattern isn't null ...
2812                     if ( $inpat ne "" ) {
2813
2814                         # Turn of warn and die procesing for a bit.
2815                         local $SIG{__DIE__};
2816                         local $SIG{__WARN__};
2817
2818                         # Create the pattern.
2819                         eval '$inpat =~ m' . "\a$inpat\a";
2820                         if ( $@ ne "" ) {
2821
2822                             # Oops. Bad pattern. No biscuit.
2823                             # Print the eval error and go back for more
2824                             # commands.
2825                             print $OUT "$@";
2826                             next CMD;
2827                         }
2828                         $pat = $inpat;
2829                     } ## end if ($inpat ne "")
2830
2831                     # Set up to stop on wrap-around.
2832                     $end = $start;
2833
2834                     # Don't move off the current line.
2835                     $incr = -1;
2836
2837                     # Done in eval so nothing breaks if the pattern
2838                     # does something weird.
2839                     eval '
2840                         for (;;) {
2841                             # Move ahead one line.
2842                             ++$start;
2843
2844                             # Wrap if we pass the last line.
2845                             $start = 1 if ($start > $max);
2846
2847                             # Stop if we have gotten back to this line again,
2848                             last if ($start == $end);
2849
2850                             # A hit! (Note, though, that we are doing
2851                             # case-insensitive matching. Maybe a qr//
2852                             # expression would be better, so the user could
2853                             # do case-sensitive matching if desired.
2854                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2855                                 if ($slave_editor) {
2856                                     # Handle proper escaping in the slave.
2857                                     print $OUT "\032\032$filename:$start:0\n";
2858                                 }
2859                                 else {
2860                                     # Just print the line normally.
2861                                     print $OUT "$start:\t",$dbline[$start],"\n";
2862                                 }
2863                                 # And quit since we found something.
2864                                 last;
2865                             }
2866                          } ';
2867
2868                     # If we wrapped, there never was a match.
2869                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2870                     next CMD;
2871                 }
2872
2873 =head4 C<?> - search backward for a string in the source
2874
2875 Same as for C</>, except the loop runs backwards.
2876
2877 =cut
2878
2879                 # ? - backward pattern search.
2880                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2881
2882                     # Get the pattern, remove trailing question mark.
2883                     $inpat =~ s:([^\\])\?$:$1:;
2884
2885                     # If we've got one ...
2886                     if ( $inpat ne "" ) {
2887
2888                         # Turn off die & warn handlers.
2889                         local $SIG{__DIE__};
2890                         local $SIG{__WARN__};
2891                         eval '$inpat =~ m' . "\a$inpat\a";
2892
2893                         if ( $@ ne "" ) {
2894
2895                             # Ouch. Not good. Print the error.
2896                             print $OUT $@;
2897                             next CMD;
2898                         }
2899                         $pat = $inpat;
2900                     } ## end if ($inpat ne "")
2901
2902                     # Where we are now is where to stop after wraparound.
2903                     $end = $start;
2904
2905                     # Don't move away from this line.
2906                     $incr = -1;
2907
2908                     # Search inside the eval to prevent pattern badness
2909                     # from killing us.
2910                     eval '
2911                         for (;;) {
2912                             # Back up a line.
2913                             --$start;
2914
2915                             # Wrap if we pass the first line.
2916
2917                             $start = $max if ($start <= 0);
2918
2919                             # Quit if we get back where we started,
2920                             last if ($start == $end);
2921
2922                             # Match?
2923                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2924                                 if ($slave_editor) {
2925                                     # Yep, follow slave editor requirements.
2926                                     print $OUT "\032\032$filename:$start:0\n";
2927                                 }
2928                                 else {
2929                                     # Yep, just print normally.
2930                                     print $OUT "$start:\t",$dbline[$start],"\n";
2931                                 }
2932
2933                                 # Found, so done.
2934                                 last;
2935                             }
2936                         } ';
2937
2938                     # Say we failed if the loop never found anything,
2939                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2940                     next CMD;
2941                 }
2942
2943 =head4 C<$rc> - Recall command
2944
2945 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2946 that the terminal supports history). It find the the command required, puts it
2947 into C<$cmd>, and redoes the loop to execute it.
2948
2949 =cut
2950
2951                 # $rc - recall command.
2952                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2953
2954                     # No arguments, take one thing off history.
2955                     pop(@hist) if length($cmd) > 1;
2956
2957                     # Relative (- found)?
2958                     #  Y - index back from most recent (by 1 if bare minus)
2959                     #  N - go to that particular command slot or the last
2960                     #      thing if nothing following.
2961                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2962
2963                     # Pick out the command desired.
2964                     $cmd = $hist[$i];
2965
2966                     # Print the command to be executed and restart the loop
2967                     # with that command in the buffer.
2968                     print $OUT $cmd, "\n";
2969                     redo CMD;
2970                 }
2971
2972 =head4 C<$sh$sh> - C<system()> command
2973
2974 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2975 C<STDOUT> from getting messed up.
2976
2977 =cut
2978
2979                 # $sh$sh - run a shell command (if it's all ASCII).
2980                 # Can't run shell commands with Unicode in the debugger, hmm.
2981                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2982
2983                     # System it.
2984                     &system($arg);
2985                     next CMD;
2986                 }
2987
2988 =head4 C<$rc I<pattern> $rc> - Search command history
2989
2990 Another command to manipulate C<@hist>: this one searches it with a pattern.
2991 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2992
2993 =cut
2994
2995                 # $rc pattern $rc - find a command in the history.
2996                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2997
2998                     # Create the pattern to use.
2999                     $pat = "^$arg";
3000
3001                     # Toss off last entry if length is >1 (and it always is).
3002                     pop(@hist) if length($cmd) > 1;
3003
3004                     # Look backward through the history.
3005                     for ( $i = $#hist ; $i ; --$i ) {
3006                         # Stop if we find it.
3007                         last if $hist[$i] =~ /$pat/;
3008                     }
3009
3010                     if ( !$i ) {
3011
3012                         # Never found it.
3013                         print $OUT "No such command!\n\n";
3014                         next CMD;
3015                     }
3016
3017                     # Found it. Put it in the buffer, print it, and process it.
3018                     $cmd = $hist[$i];
3019                     print $OUT $cmd, "\n";
3020                     redo CMD;
3021                 }
3022
3023 =head4 C<$sh> - Invoke a shell
3024
3025 Uses C<DB::system> to invoke a shell.
3026
3027 =cut
3028
3029                 # $sh - start a shell.
3030                 if ($cmd =~ /\A$sh\z/) {
3031
3032                     # Run the user's shell. If none defined, run Bourne.
3033                     # We resume execution when the shell terminates.
3034                     &system( $ENV{SHELL} || "/bin/sh" );
3035                     next CMD;
3036                 }
3037
3038 =head4 C<$sh I<command>> - Force execution of a command in a shell
3039
3040 Like the above, but the command is passed to the shell. Again, we use
3041 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3042
3043 =cut
3044
3045                 # $sh command - start a shell and run a command in it.
3046                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
3047
3048                     # XXX: using csh or tcsh destroys sigint retvals!
3049                     #&system($1);  # use this instead
3050
3051                     # use the user's shell, or Bourne if none defined.
3052                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
3053                     next CMD;
3054                 }
3055
3056 =head4 C<H> - display commands in history
3057
3058 Prints the contents of C<@hist> (if any).
3059
3060 =cut
3061
3062                 if ($cmd =~ /\AH\b\s*\*/) {
3063                     @hist = @truehist = ();
3064                     print $OUT "History cleansed\n";
3065                     next CMD;
3066                 }
3067
3068                 if (my ($num)
3069                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
3070
3071                     # Anything other than negative numbers is ignored by
3072                     # the (incorrect) pattern, so this test does nothing.
3073                     $end = $num ? ( $#hist - $num ) : 0;
3074
3075                     # Set to the minimum if less than zero.
3076                     $hist = 0 if $hist < 0;
3077
3078                     # Start at the end of the array.
3079                     # Stay in while we're still above the ending value.
3080                     # Tick back by one each time around the loop.
3081                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3082
3083                         # Print the command  unless it has no arguments.
3084                         print $OUT "$i: ", $hist[$i], "\n"
3085                           unless $hist[$i] =~ /^.?$/;
3086                     }
3087                     next CMD;
3088                 }
3089
3090 =head4 C<man, doc, perldoc> - look up documentation
3091
3092 Just calls C<runman()> to print the appropriate document.
3093
3094 =cut
3095
3096                 # man, perldoc, doc - show manual pages.
3097                 if (my ($man_page)
3098                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3099                     runman($man_page);
3100                     next CMD;
3101                 }
3102
3103 =head4 C<p> - print
3104
3105 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3106 the bottom of the loop.
3107
3108 =cut
3109
3110                 my $print_cmd = 'print {$DB::OUT} ';
3111                 # p - print (no args): print $_.
3112                 if ($cmd eq 'p') {
3113                     $cmd = $print_cmd . '$_';
3114                 }
3115
3116                 # p - print the given expression.
3117                 $cmd =~ s/\Ap\b/$print_cmd /;
3118
3119 =head4 C<=> - define command alias
3120
3121 Manipulates C<%alias> to add or list command aliases.
3122
3123 =cut
3124
3125                 # = - set up a command alias.
3126                 if ($cmd =~ s/\A=\s*//) {
3127                     my @keys;
3128                     if ( length $cmd == 0 ) {
3129
3130                         # No args, get current aliases.
3131                         @keys = sort keys %alias;
3132                     }
3133                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3134
3135                         # Creating a new alias. $k is alias name, $v is
3136                         # alias value.
3137
3138                         # can't use $_ or kill //g state
3139                         for my $x ( $k, $v ) {
3140
3141                             # Escape "alarm" characters.
3142                             $x =~ s/\a/\\a/g;
3143                         }
3144
3145                         # Substitute key for value, using alarm chars
3146                         # as separators (which is why we escaped them in
3147                         # the command).
3148                         $alias{$k} = "s\a$k\a$v\a";
3149
3150                         # Turn off standard warn and die behavior.
3151                         local $SIG{__DIE__};
3152                         local $SIG{__WARN__};
3153
3154                         # Is it valid Perl?
3155                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3156
3157                             # Nope. Bad alias. Say so and get out.
3158                             print $OUT "Can't alias $k to $v: $@\n";
3159                             delete $alias{$k};
3160                             next CMD;
3161                         }
3162
3163                         # We'll only list the new one.
3164                         @keys = ($k);
3165                     } ## end elsif (my ($k, $v) = ($cmd...
3166
3167                     # The argument is the alias to list.
3168                     else {
3169                         @keys = ($cmd);
3170                     }
3171
3172                     # List aliases.
3173                     for my $k (@keys) {
3174
3175                         # Messy metaquoting: Trim the substitution code off.
3176                         # We use control-G as the delimiter because it's not
3177                         # likely to appear in the alias.
3178                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3179
3180                             # Print the alias.
3181                             print $OUT "$k\t= $1\n";
3182                         }
3183                         elsif ( defined $alias{$k} ) {
3184
3185                             # Couldn't trim it off; just print the alias code.
3186                             print $OUT "$k\t$alias{$k}\n";
3187                         }
3188                         else {
3189
3190                             # No such, dude.
3191                             print "No alias for $k\n";
3192                         }
3193                     } ## end for my $k (@keys)
3194                     next CMD;
3195                 }
3196
3197 =head4 C<source> - read commands from a file.
3198
3199 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3200 pick it up.
3201
3202 =cut
3203
3204                 # source - read commands from a file (or pipe!) and execute.
3205                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3206                     if ( open my $fh, $sourced_fn ) {
3207
3208                         # Opened OK; stick it in the list of file handles.
3209                         push @cmdfhs, $fh;
3210                     }
3211                     else {
3212
3213                         # Couldn't open it.
3214                         &warn("Can't execute '$sourced_fn': $!\n");
3215                     }
3216                     next CMD;
3217                 }
3218
3219                 if (my ($which_cmd, $position)
3220                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3221
3222                     my ($fn, $line_num);
3223                     if ($position =~ m{\A\d+\z})
3224                     {
3225                         $fn = $filename;
3226                         $line_num = $position;
3227                     }
3228                     elsif (my ($new_fn, $new_line_num)
3229                         = $position =~ m{\A(.*):(\d+)\z}) {
3230                         ($fn, $line_num) = ($new_fn, $new_line_num);
3231                     }
3232                     else
3233                     {
3234                         &warn("Wrong spec for enable/disable argument.\n");
3235                     }
3236
3237                     if (defined($fn)) {
3238                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3239                             _set_breakpoint_enabled_status($fn, $line_num,
3240                                 ($which_cmd eq 'enable' ? 1 : '')
3241                             );
3242                         }
3243                         else {
3244                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3245                         }
3246                     }
3247
3248                     next CMD;
3249                 }
3250
3251 =head4 C<save> - send current history to a file
3252
3253 Takes the complete history, (not the shrunken version you see with C<H>),
3254 and saves it to the given filename, so it can be replayed using C<source>.
3255
3256 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3257
3258 =cut
3259
3260                 # save source - write commands to a file for later use
3261                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3262                     my $filename = $new_fn || '.perl5dbrc';    # default?
3263                     if ( open my $fh, '>', $filename ) {
3264
3265                        # chomp to remove extraneous newlines from source'd files
3266                         chomp( my @truelist =
3267                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3268                               @truehist );
3269                         print $fh join( "\n", @truelist );
3270                         print "commands saved in $file\n";
3271                     }
3272                     else {
3273                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3274                     }
3275                     next CMD;
3276                 }
3277
3278 =head4 C<R> - restart
3279
3280 Restart the debugger session.
3281
3282 =head4 C<rerun> - rerun the current session
3283
3284 Return to any given position in the B<true>-history list
3285
3286 =cut
3287
3288                 # R - restart execution.
3289                 # rerun - controlled restart execution.
3290                 if (my ($cmd_cmd, $cmd_params) =
3291                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3292                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3293
3294                     # Close all non-system fds for a clean restart.  A more
3295                     # correct method would be to close all fds that were not
3296                     # open when the process started, but this seems to be
3297                     # hard.  See "debugger 'R'estart and open database
3298                     # connections" on p5p.
3299
3300                     my $max_fd = 1024; # default if POSIX can't be loaded
3301                     if (eval { require POSIX }) {
3302                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3303                     }
3304
3305                     if (defined $max_fd) {
3306                         foreach ($^F+1 .. $max_fd-1) {
3307                             next unless open FD_TO_CLOSE, "<&=$_";
3308                             close(FD_TO_CLOSE);
3309                         }
3310                     }
3311
3312                     # And run Perl again.  We use exec() to keep the
3313                     # PID stable (and that way $ini_pids is still valid).
3314                     exec(@args) || print $OUT "exec failed: $!\n";
3315
3316                     last CMD;
3317                 }
3318
3319 =head4 C<|, ||> - pipe output through the pager.
3320
3321 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3322 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3323 pipe to the pager (restoring the output filehandles if this fails). If this
3324 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3325 set C<$signal>, sending us back into the debugger.
3326
3327 We then trim off the pipe symbols and C<redo> the command loop at the
3328 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3329 reading another.
3330
3331 =cut
3332
3333                 # || - run command in the pager, with output to DB::OUT.
3334                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3335                     if ( $pager =~ /^\|/ ) {
3336
3337                         # Default pager is into a pipe. Redirect I/O.
3338                         open( SAVEOUT, ">&STDOUT" )
3339                           || &warn("Can't save STDOUT");
3340                         open( STDOUT, ">&OUT" )
3341                           || &warn("Can't redirect STDOUT");
3342                     } ## end if ($pager =~ /^\|/)
3343                     else {
3344
3345                         # Not into a pipe. STDOUT is safe.
3346                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3347                     }
3348
3349                     # Fix up environment to record we have less if so.
3350                     fix_less();
3351
3352                     unless ( $piped = open( OUT, $pager ) ) {
3353
3354                         # Couldn't open pipe to pager.
3355                         &warn("Can't pipe output to '$pager'");
3356                         if ( $pager =~ /^\|/ ) {
3357
3358                             # Redirect I/O back again.
3359                             open( OUT, ">&STDOUT" )    # XXX: lost message
3360                               || &warn("Can't restore DB::OUT");
3361                             open( STDOUT, ">&SAVEOUT" )
3362                               || &warn("Can't restore STDOUT");
3363                             close(SAVEOUT);
3364                         } ## end if ($pager =~ /^\|/)
3365                         else {
3366
3367                             # Redirect I/O. STDOUT already safe.
3368                             open( OUT, ">&STDOUT" )    # XXX: lost message
3369                               || &warn("Can't restore DB::OUT");
3370                         }
3371                         next CMD;
3372                     } ## end unless ($piped = open(OUT,...
3373
3374                     # Set up broken-pipe handler if necessary.
3375                     $SIG{PIPE} = \&DB::catch
3376                       if $pager =~ /^\|/
3377                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3378
3379                     OUT->autoflush(1);
3380                     # Save current filehandle, and put it back.
3381                     $selected = select(OUT);
3382                     # Don't put it back if pager was a pipe.
3383                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3384
3385                     # Trim off the pipe symbols and run the command now.
3386                     $cmd =~ s#\A\|+\s*##;
3387                     redo PIPE;
3388                 }
3389
3390 =head3 END OF COMMAND PARSING
3391
3392 Anything left in C<$cmd> at this point is a Perl expression that we want to
3393 evaluate. We'll always evaluate in the user's context, and fully qualify
3394 any variables we might want to address in the C<DB> package.
3395
3396 =cut
3397
3398                 # t - turn trace on.
3399                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3400                     my $trace_arg = $1;
3401                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3402                 }
3403
3404                 # s - single-step. Remember the last command was 's'.
3405                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3406                     $laststep = 's';
3407                 }
3408
3409                 # n - single-step, but not into subs. Remember last command
3410                 # was 'n'.
3411                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3412                     $laststep = 'n';
3413                 }
3414
3415             }    # PIPE:
3416
3417             # Make sure the flag that says "the debugger's running" is
3418             # still on, to make sure we get control again.
3419             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3420
3421             # Run *our* eval that executes in the caller's context.
3422             &eval;
3423
3424             # Turn off the one-time-dump stuff now.
3425             if ($onetimeDump) {
3426                 $onetimeDump      = undef;
3427                 $onetimedumpDepth = undef;
3428             }
3429             elsif ( $term_pid == $$ ) {
3430                 eval {          # May run under miniperl, when not available...
3431                     STDOUT->flush();
3432                     STDERR->flush();
3433                 };
3434
3435                 # XXX If this is the master pid, print a newline.
3436                 print $OUT "\n";
3437             }
3438         } ## end while (($term || &setterm...
3439
3440 =head3 POST-COMMAND PROCESSING
3441
3442 After each command, we check to see if the command output was piped anywhere.
3443 If so, we go through the necessary code to unhook the pipe and go back to
3444 our standard filehandles for input and output.
3445
3446 =cut
3447
3448         continue {    # CMD:
3449
3450             # At the end of every command:
3451             if ($piped) {
3452
3453                 # Unhook the pipe mechanism now.
3454                 if ( $pager =~ /^\|/ ) {
3455
3456                     # No error from the child.
3457                     $? = 0;
3458
3459                     # we cannot warn here: the handle is missing --tchrist
3460                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3461
3462                     # most of the $? crud was coping with broken cshisms
3463                     # $? is explicitly set to 0, so this never runs.
3464                     if ($?) {
3465                         print SAVEOUT "Pager '$pager' failed: ";
3466                         if ( $? == -1 ) {
3467                             print SAVEOUT "shell returned -1\n";
3468                         }
3469                         elsif ( $? >> 8 ) {
3470                             print SAVEOUT ( $? & 127 )
3471                               ? " (SIG#" . ( $? & 127 ) . ")"
3472                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3473                         }
3474                         else {
3475                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3476                         }
3477                     } ## end if ($?)
3478
3479                     # Reopen filehandle for our output (if we can) and
3480                     # restore STDOUT (if we can).
3481                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3482                     open( STDOUT, ">&SAVEOUT" )
3483                       || &warn("Can't restore STDOUT");
3484
3485                     # Turn off pipe exception handler if necessary.
3486                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3487
3488                     # Will stop ignoring SIGPIPE if done like nohup(1)
3489                     # does SIGINT but Perl doesn't give us a choice.
3490                 } ## end if ($pager =~ /^\|/)
3491                 else {
3492
3493                     # Non-piped "pager". Just restore STDOUT.
3494                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3495                 }
3496
3497                 # Close filehandle pager was using, restore the normal one
3498                 # if necessary,
3499                 close(SAVEOUT);
3500                 select($selected), $selected = "" unless $selected eq "";
3501
3502                 # No pipes now.
3503                 $piped = "";
3504             } ## end if ($piped)
3505         }    # CMD:
3506
3507 =head3 COMMAND LOOP TERMINATION
3508
3509 When commands have finished executing, we come here. If the user closed the
3510 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3511 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3512 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3513 The interpreter will then execute the next line and then return control to us
3514 again.
3515
3516 =cut
3517
3518         # No more commands? Quit.
3519         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3520
3521         # Evaluate post-prompt commands.
3522         foreach $evalarg (@$post) {
3523             &eval;
3524         }
3525     }    # if ($single || $signal)
3526
3527     # Put the user's globals back where you found them.
3528     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3529     ();
3530 } ## end sub DB
3531
3532 # The following code may be executed now:
3533 # BEGIN {warn 4}
3534
3535 =head2 sub
3536
3537 C<sub> is called whenever a subroutine call happens in the program being
3538 debugged. The variable C<$DB::sub> contains the name of the subroutine
3539 being called.
3540
3541 The core function of this subroutine is to actually call the sub in the proper
3542 context, capturing its output. This of course causes C<DB::DB> to get called
3543 again, repeating until the subroutine ends and returns control to C<DB::sub>
3544 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3545 return value, and returns its captured copy of the return value as its own
3546 return value. The value then feeds back into the program being debugged as if
3547 C<DB::sub> hadn't been there at all.
3548
3549 C<sub> does all the work of printing the subroutine entry and exit messages
3550 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3551 and also prints the return value if needed (for the C<r> command and if
3552 the 16 bit is set in C<$frame>).
3553
3554 It also tracks the subroutine call depth by saving the current setting of
3555 C<$single> in the C<@stack> package global; if this exceeds the value in
3556 C<$deep>, C<sub> automatically turns on printing of the current depth by
3557 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3558 of stop/don't stop on entry to subs set as it currently is set.
3559
3560 =head3 C<caller()> support
3561
3562 If C<caller()> is called from the package C<DB>, it provides some
3563 additional data, in the following order:
3564
3565 =over 4
3566
3567 =item * C<$package>
3568
3569 The package name the sub was in
3570
3571 =item * C<$filename>
3572
3573 The filename it was defined in
3574
3575 =item * C<$line>
3576
3577 The line number it was defined on
3578
3579 =item * C<$subroutine>
3580
3581 The subroutine name; C<(eval)> if an C<eval>().
3582
3583 =item * C<$hasargs>
3584
3585 1 if it has arguments, 0 if not
3586
3587 =item * C<$wantarray>
3588
3589 1 if array context, 0 if scalar context
3590
3591 =item * C<$evaltext>
3592
3593 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3594
3595 =item * C<$is_require>
3596
3597 frame was created by a C<use> or C<require> statement
3598
3599 =item * C<$hints>
3600
3601 pragma information; subject to change between versions
3602
3603 =item * C<$bitmask>
3604
3605 pragma information; subject to change between versions
3606
3607 =item * C<@DB::args>
3608
3609 arguments with which the subroutine was invoked
3610
3611 =back
3612
3613 =cut
3614
3615 use vars qw($deep);
3616
3617 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3618 # happy. -- Shlomi Fish
3619 sub DB::sub {
3620         # Do not use a regex in this subroutine -> results in corrupted memory
3621         # See: [perl #66110]
3622
3623         # lock ourselves under threads
3624         lock($DBGR);
3625
3626     # Whether or not the autoloader was running, a scalar to put the
3627     # sub's return value in (if needed), and an array to put the sub's
3628     # return value in (if needed).
3629     my ( $al, $ret, @ret ) = "";
3630         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3631                 print "creating new thread\n";
3632         }
3633
3634     # If the last ten characters are '::AUTOLOAD', note we've traced
3635     # into AUTOLOAD for $sub.
3636     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3637         no strict 'refs';
3638         $al = " for $$sub" if defined $$sub;
3639     }
3640
3641     # We stack the stack pointer and then increment it to protect us
3642     # from a situation that might unwind a whole bunch of call frames
3643     # at once. Localizing the stack pointer means that it will automatically
3644     # unwind the same amount when multiple stack frames are unwound.
3645     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3646
3647     # Expand @stack.
3648     $#stack = $stack_depth;
3649
3650     # Save current single-step setting.
3651     $stack[-1] = $single;
3652
3653     # Turn off all flags except single-stepping.
3654     $single &= 1;
3655
3656     # If we've gotten really deeply recursed, turn on the flag that will
3657     # make us stop with the 'deep recursion' message.
3658     $single |= 4 if $stack_depth == $deep;
3659
3660     # If frame messages are on ...
3661     (
3662         $frame & 4    # Extended frame entry message
3663         ? (
3664             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3665
3666             # Why -1? But it works! :-(
3667             # Because print_trace will call add 1 to it and then call
3668             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3669             # in dump_trace.
3670             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3671           )
3672         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3673
3674           # standard frame entry message
3675       )
3676       if $frame;
3677
3678     # Determine the sub's return type, and capture appropriately.
3679     if (wantarray) {
3680
3681         # Called in array context. call sub and capture output.
3682         # DB::DB will recursively get control again if appropriate; we'll come
3683         # back here when the sub is finished.
3684         {
3685             no strict 'refs';
3686             @ret = &$sub;
3687         }
3688
3689         # Pop the single-step value back off the stack.
3690         $single |= $stack[ $stack_depth-- ];
3691
3692         # Check for exit trace messages...
3693         (
3694             $frame & 4    # Extended exit message
3695             ? (
3696                 print_lineinfo( ' ' x $stack_depth, "out " ),
3697                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3698               )
3699             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3700
3701               # Standard exit message
3702           )
3703           if $frame & 2;
3704
3705         # Print the return info if we need to.
3706         if ( $doret eq $stack_depth or $frame & 16 ) {
3707
3708             # Turn off output record separator.
3709             local $\ = '';
3710             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3711
3712             # Indent if we're printing because of $frame tracing.
3713             print $fh ' ' x $stack_depth if $frame & 16;
3714
3715             # Print the return value.
3716             print $fh "list context return from $sub:\n";
3717             dumpit( $fh, \@ret );
3718
3719             # And don't print it again.
3720             $doret = -2;
3721         } ## end if ($doret eq $stack_depth...
3722             # And we have to return the return value now.
3723         @ret;
3724     } ## end if (wantarray)
3725
3726     # Scalar context.
3727     else {
3728         if ( defined wantarray ) {
3729         no strict 'refs';
3730             # Save the value if it's wanted at all.
3731             $ret = &$sub;
3732         }
3733         else {
3734         no strict 'refs';
3735             # Void return, explicitly.
3736             &$sub;
3737             undef $ret;
3738         }
3739
3740         # Pop the single-step value off the stack.
3741         $single |= $stack[ $stack_depth-- ];
3742
3743         # If we're doing exit messages...
3744         (
3745             $frame & 4    # Extended messages
3746             ? (
3747                 print_lineinfo( ' ' x $stack_depth, "out " ),
3748                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3749               )
3750             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3751
3752               # Standard messages
3753           )
3754           if $frame & 2;
3755
3756         # If we are supposed to show the return value... same as before.
3757         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3758             local $\ = '';
3759             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3760             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3761             print $fh (
3762                 defined wantarray
3763                 ? "scalar context return from $sub: "
3764                 : "void context return from $sub\n"
3765             );
3766             dumpit( $fh, $ret ) if defined wantarray;
3767             $doret = -2;
3768         } ## end if ($doret eq $stack_depth...
3769
3770         # Return the appropriate scalar value.
3771         $ret;
3772     } ## end else [ if (wantarray)
3773 } ## end sub _sub
3774
3775 sub lsub : lvalue {
3776
3777     no strict 'refs';
3778
3779         # lock ourselves under threads
3780         lock($DBGR);
3781
3782     # Whether or not the autoloader was running, a scalar to put the
3783     # sub's return value in (if needed), and an array to put the sub's
3784     # return value in (if needed).
3785     my ( $al, $ret, @ret ) = "";
3786         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3787                 print "creating new thread\n";
3788         }
3789
3790     # If the last ten characters are C'::AUTOLOAD', note we've traced
3791     # into AUTOLOAD for $sub.
3792     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3793         $al = " for $$sub";
3794     }
3795
3796     # We stack the stack pointer and then increment it to protect us
3797     # from a situation that might unwind a whole bunch of call frames
3798     # at once. Localizing the stack pointer means that it will automatically
3799     # unwind the same amount when multiple stack frames are unwound.
3800     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3801
3802     # Expand @stack.
3803     $#stack = $stack_depth;
3804
3805     # Save current single-step setting.
3806     $stack[-1] = $single;
3807
3808     # Turn off all flags except single-stepping.
3809     $single &= 1;
3810
3811     # If we've gotten really deeply recursed, turn on the flag that will
3812     # make us stop with the 'deep recursion' message.
3813     $single |= 4 if $stack_depth == $deep;
3814
3815     # If frame messages are on ...
3816     (
3817         $frame & 4    # Extended frame entry message
3818         ? (
3819             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3820
3821             # Why -1? But it works! :-(
3822             # Because print_trace will call add 1 to it and then call
3823             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3824             # in dump_trace.
3825             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3826           )
3827         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3828
3829           # standard frame entry message
3830       )
3831       if $frame;
3832
3833     # Pop the single-step value back off the stack.
3834     $single |= $stack[ $stack_depth-- ];
3835
3836     # call the original lvalue sub.
3837     &$sub;
3838 }
3839
3840 # Abstracting common code from multiple places elsewhere:
3841 sub depth_print_lineinfo {
3842     my $always_print = shift;
3843
3844     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3845 }
3846
3847 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3848
3849 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3850 Most of the changes were to systematize the command structure and to eliminate
3851 commands that threw away user input without checking.
3852
3853 The following sections describe the code added to make it easy to support
3854 multiple command sets with conflicting command names. This section is a start
3855 at unifying all command processing to make it simpler to develop commands.
3856
3857 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3858 number, and C<$dbline> (the current line) as arguments.
3859
3860 Support functions in this section which have multiple modes of failure C<die>
3861 on error; the rest simply return a false value.
3862
3863 The user-interface functions (all of the C<cmd_*> functions) just output
3864 error messages.
3865
3866 =head2 C<%set>
3867
3868 The C<%set> hash defines the mapping from command letter to subroutine
3869 name suffix.
3870
3871 C<%set> is a two-level hash, indexed by set name and then by command name.
3872 Note that trying to set the CommandSet to C<foobar> simply results in the
3873 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3874
3875 =cut
3876
3877 ### The API section
3878
3879 my %set = (    #
3880     'pre580' => {
3881         'a' => 'pre580_a',
3882         'A' => 'pre580_null',
3883         'b' => 'pre580_b',
3884         'B' => 'pre580_null',
3885         'd' => 'pre580_null',
3886         'D' => 'pre580_D',
3887         'h' => 'pre580_h',
3888         'M' => 'pre580_null',
3889         'O' => 'o',
3890         'o' => 'pre580_null',
3891         'v' => 'M',
3892         'w' => 'v',
3893         'W' => 'pre580_W',
3894     },
3895     'pre590' => {
3896         '<'  => 'pre590_prepost',
3897         '<<' => 'pre590_prepost',
3898         '>'  => 'pre590_prepost',
3899         '>>' => 'pre590_prepost',
3900         '{'  => 'pre590_prepost',
3901         '{{' => 'pre590_prepost',
3902     },
3903 );
3904
3905 my %breakpoints_data;
3906
3907 sub _has_breakpoint_data_ref {
3908     my ($filename, $line) = @_;
3909
3910     return (
3911         exists( $breakpoints_data{$filename} )
3912             and
3913         exists( $breakpoints_data{$filename}{$line} )
3914     );
3915 }
3916
3917 sub _get_breakpoint_data_ref {
3918     my ($filename, $line) = @_;
3919
3920     return ($breakpoints_data{$filename}{$line} ||= +{});
3921 }
3922
3923 sub _delete_breakpoint_data_ref {
3924     my ($filename, $line) = @_;
3925
3926     delete($breakpoints_data{$filename}{$line});
3927     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3928         delete($breakpoints_data{$filename});
3929     }
3930
3931     return;
3932 }
3933
3934 sub _set_breakpoint_enabled_status {
3935     my ($filename, $line, $status) = @_;
3936
3937     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3938         ($status ? 1 : '')
3939         ;
3940
3941     return;
3942 }
3943
3944 sub _enable_breakpoint_temp_enabled_status {
3945     my ($filename, $line) = @_;
3946
3947     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3948
3949     return;
3950 }
3951
3952 sub _cancel_breakpoint_temp_enabled_status {
3953     my ($filename, $line) = @_;
3954
3955     my $ref = _get_breakpoint_data_ref($filename, $line);
3956
3957     delete ($ref->{'temp_enabled'});
3958
3959     if (! %$ref) {
3960         _delete_breakpoint_data_ref($filename, $line);
3961     }
3962
3963     return;
3964 }
3965
3966 sub _is_breakpoint_enabled {
3967     my ($filename, $line) = @_;
3968
3969     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3970     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3971 }
3972
3973 =head2 C<cmd_wrapper()> (API)
3974
3975 C<cmd_wrapper()> allows the debugger to switch command sets
3976 depending on the value of the C<CommandSet> option.
3977
3978 It tries to look up the command in the C<%set> package-level I<lexical>
3979 (which means external entities can't fiddle with it) and create the name of
3980 the sub to call based on the value found in the hash (if it's there). I<All>
3981 of the commands to be handled in a set have to be added to C<%set>; if they
3982 aren't found, the 5.8.0 equivalent is called (if there is one).
3983
3984 This code uses symbolic references.
3985
3986 =cut
3987
3988 sub cmd_wrapper {
3989     my $cmd      = shift;
3990     my $line     = shift;
3991     my $dblineno = shift;
3992
3993     # Assemble the command subroutine's name by looking up the
3994     # command set and command name in %set. If we can't find it,
3995     # default to the older version of the command.
3996     my $call = 'cmd_'
3997       . ( $set{$CommandSet}{$cmd}
3998           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3999
4000     # Call the command subroutine, call it by name.
4001     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4002 } ## end sub cmd_wrapper
4003
4004 =head3 C<cmd_a> (command)
4005
4006 The C<a> command handles pre-execution actions. These are associated with a
4007 particular line, so they're stored in C<%dbline>. We default to the current
4008 line if none is specified.
4009
4010 =cut
4011
4012 sub cmd_a {
4013     my $cmd    = shift;
4014     my $line   = shift || '';    # [.|line] expr
4015     my $dbline = shift;
4016
4017     # If it's dot (here), or not all digits,  use the current line.
4018     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
4019
4020     # Should be a line number followed by an expression.
4021     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4022         my ( $lineno, $expr ) = ( $1, $2 );
4023
4024         # If we have an expression ...
4025         if ( length $expr ) {
4026
4027             # ... but the line isn't breakable, complain.
4028             if ( $dbline[$lineno] == 0 ) {
4029                 print $OUT
4030                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4031             }
4032             else {
4033
4034                 # It's executable. Record that the line has an action.
4035                 $had_breakpoints{$filename} |= 2;
4036
4037                 # Remove any action, temp breakpoint, etc.
4038                 $dbline{$lineno} =~ s/\0[^\0]*//;
4039
4040                 # Add the action to the line.
4041                 $dbline{$lineno} .= "\0" . action($expr);
4042
4043                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4044             }
4045         } ## end if (length $expr)
4046     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4047     else {
4048
4049         # Syntax wrong.
4050         print $OUT
4051           "Adding an action requires an optional lineno and an expression\n"
4052           ;    # hint
4053     }
4054 } ## end sub cmd_a
4055
4056 =head3 C<cmd_A> (command)
4057
4058 Delete actions. Similar to above, except the delete code is in a separate
4059 subroutine, C<delete_action>.
4060
4061 =cut
4062
4063 sub cmd_A {
4064     my $cmd    = shift;
4065     my $line   = shift || '';
4066     my $dbline = shift;
4067
4068     # Dot is this line.
4069     $line =~ s/^\./$dbline/;
4070
4071     # Call delete_action with a null param to delete them all.
4072     # The '1' forces the eval to be true. It'll be false only
4073     # if delete_action blows up for some reason, in which case
4074     # we print $@ and get out.
4075     if ( $line eq '*' ) {
4076         eval { &delete_action(); 1 } or print $OUT $@ and return;
4077     }
4078
4079     # There's a real line  number. Pass it to delete_action.
4080     # Error trapping is as above.
4081     elsif ( $line =~ /^(\S.*)/ ) {
4082         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4083     }
4084
4085     # Swing and a miss. Bad syntax.
4086     else {
4087         print $OUT
4088           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4089     }
4090 } ## end sub cmd_A
4091
4092 =head3 C<delete_action> (API)
4093
4094 C<delete_action> accepts either a line number or C<undef>. If a line number
4095 is specified, we check for the line being executable (if it's not, it
4096 couldn't have had an  action). If it is, we just take the action off (this
4097 will get any kind of an action, including breakpoints).
4098
4099 =cut
4100
4101 sub delete_action {
4102     my $i = shift;
4103     if ( defined($i) ) {
4104
4105         # Can there be one?
4106         die "Line $i has no action .\n" if $dbline[$i] == 0;
4107
4108         # Nuke whatever's there.
4109         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4110         delete $dbline{$i} if $dbline{$i} eq '';
4111     }
4112     else {
4113         print $OUT "Deleting all actions...\n";
4114         for my $file ( keys %had_breakpoints ) {
4115             local *dbline = $main::{ '_<' . $file };
4116             $max = $#dbline;
4117             my $was;
4118             for $i (1 .. $max) {
4119                 if ( defined $dbline{$i} ) {
4120                     $dbline{$i} =~ s/\0[^\0]*//;
4121                     delete $dbline{$i} if $dbline{$i} eq '';
4122                 }
4123                 unless ( $had_breakpoints{$file} &= ~2 ) {
4124                     delete $had_breakpoints{$file};
4125                 }
4126             } ## end for ($i = 1 .. $max)
4127         } ## end for my $file (keys %had_breakpoints)
4128     } ## end else [ if (defined($i))
4129 } ## end sub delete_action
4130
4131 =head3 C<cmd_b> (command)
4132
4133 Set breakpoints. Since breakpoints can be set in so many places, in so many
4134 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4135 we try to parse the command type, and then shuttle it off to an appropriate
4136 subroutine to actually do the work of setting the breakpoint in the right
4137 place.
4138
4139 =cut
4140
4141 sub cmd_b {
4142     my $cmd    = shift;
4143     my $line   = shift;    # [.|line] [cond]
4144     my $dbline = shift;
4145
4146     # Make . the current line number if it's there..
4147     $line =~ s/^\.(\s|\z)/$dbline$1/;
4148
4149     # No line number, no condition. Simple break on current line.
4150     if ( $line =~ /^\s*$/ ) {
4151         &cmd_b_line( $dbline, 1 );
4152     }
4153
4154     # Break on load for a file.
4155     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4156         my $file = $1;
4157         $file =~ s/\s+$//;
4158         &cmd_b_load($file);
4159     }
4160
4161     # b compile|postpone <some sub> [<condition>]
4162     # The interpreter actually traps this one for us; we just put the
4163     # necessary condition in the %postponed hash.
4164     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4165
4166         # Capture the condition if there is one. Make it true if none.
4167         my $cond = length $3 ? $3 : '1';
4168
4169         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4170         # if it was 'compile'.
4171         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4172
4173         # De-Perl4-ify the name - ' separators to ::.
4174         $subname =~ s/\'/::/g;
4175
4176         # Qualify it into the current package unless it's already qualified.
4177         $subname = "${package}::" . $subname unless $subname =~ /::/;
4178
4179         # Add main if it starts with ::.
4180         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4181
4182         # Save the break type for this sub.
4183         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4184     } ## end elsif ($line =~ ...
4185     # b <filename>:<line> [<condition>]
4186     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4187         my ($filename, $line_num, $cond) = ($1, $2, $3);
4188         cmd_b_filename_line(
4189             $filename,
4190             $line_num,
4191             (length($cond) ? $cond : '1'),
4192         );
4193     }
4194     # b <sub name> [<condition>]
4195     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4196
4197         #
4198         $subname = $1;
4199         my $cond = length $2 ? $2 : '1';
4200         &cmd_b_sub( $subname, $cond );
4201     }
4202
4203     # b <line> [<condition>].
4204     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4205
4206         # Capture the line. If none, it's the current line.
4207         $line = $1 || $dbline;
4208
4209         # If there's no condition, make it '1'.
4210         my $cond = length $2 ? $2 : '1';
4211
4212         # Break on line.
4213         &cmd_b_line( $line, $cond );
4214     }
4215
4216     # Line didn't make sense.
4217     else {
4218         print "confused by line($line)?\n";
4219     }
4220 } ## end sub cmd_b
4221
4222 =head3 C<break_on_load> (API)
4223
4224 We want to break when this file is loaded. Mark this file in the
4225 C<%break_on_load> hash, and note that it has a breakpoint in
4226 C<%had_breakpoints>.
4227
4228 =cut
4229
4230 sub break_on_load {
4231     my $file = shift;
4232     $break_on_load{$file} = 1;
4233     $had_breakpoints{$file} |= 1;
4234 }
4235
4236 =head3 C<report_break_on_load> (API)
4237
4238 Gives us an array of filenames that are set to break on load. Note that
4239 only files with break-on-load are in here, so simply showing the keys
4240 suffices.
4241
4242 =cut
4243
4244 sub report_break_on_load {
4245     sort keys %break_on_load;
4246 }
4247
4248 =head3 C<cmd_b_load> (command)
4249
4250 We take the file passed in and try to find it in C<%INC> (which maps modules
4251 to files they came from). We mark those files for break-on-load via
4252 C<break_on_load> and then report that it was done.
4253
4254 =cut
4255
4256 sub cmd_b_load {
4257     my $file = shift;
4258     my @files;
4259
4260     # This is a block because that way we can use a redo inside it
4261     # even without there being any looping structure at all outside it.
4262     {
4263
4264         # Save short name and full path if found.
4265         push @files, $file;
4266         push @files, $::INC{$file} if $::INC{$file};
4267
4268         # Tack on .pm and do it again unless there was a '.' in the name
4269         # already.
4270         $file .= '.pm', redo unless $file =~ /\./;
4271     }
4272
4273     # Do the real work here.
4274     break_on_load($_) for @files;
4275
4276     # All the files that have break-on-load breakpoints.
4277     @files = report_break_on_load;
4278
4279     # Normalize for the purposes of our printing this.
4280     local $\ = '';
4281     local $" = ' ';
4282     print $OUT "Will stop on load of '@files'.\n";
4283 } ## end sub cmd_b_load
4284
4285 =head3 C<$filename_error> (API package global)
4286
4287 Several of the functions we need to implement in the API need to work both
4288 on the current file and on other files. We don't want to duplicate code, so
4289 C<$filename_error> is used to contain the name of the file that's being
4290 worked on (if it's not the current one).
4291
4292 We can now build functions in pairs: the basic function works on the current
4293 file, and uses C<$filename_error> as part of its error message. Since this is
4294 initialized to C<"">, no filename will appear when we are working on the
4295 current file.
4296
4297 The second function is a wrapper which does the following:
4298
4299 =over 4
4300
4301 =item *
4302
4303 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4304
4305 =item *
4306
4307 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4308
4309 =item *
4310
4311 Calls the first function.
4312
4313 The first function works on the I<current> file (i.e., the one we changed to),
4314 and prints C<$filename_error> in the error message (the name of the other file)
4315 if it needs to. When the functions return, C<*dbline> is restored to point
4316 to the actual current file (the one we're executing in) and
4317 C<$filename_error> is restored to C<"">. This restores everything to
4318 the way it was before the second function was called at all.
4319
4320 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4321 details.
4322
4323 =back
4324
4325 =cut
4326
4327 use vars qw($filename_error);
4328 $filename_error = '';
4329
4330 =head3 breakable_line(from, to) (API)
4331
4332 The subroutine decides whether or not a line in the current file is breakable.
4333 It walks through C<@dbline> within the range of lines specified, looking for
4334 the first line that is breakable.
4335
4336 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4337 first line I<after> C<$to> that's breakable, if there is one.
4338
4339 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4340 first line I<before> C<$to> that's breakable, if there is one.
4341
4342 =cut
4343
4344 sub breakable_line {
4345
4346     my ( $from, $to ) = @_;
4347
4348     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4349     my $i = $from;
4350
4351     # If there are at least 2 arguments, we're trying to search a range.
4352     if ( @_ >= 2 ) {
4353
4354         # $delta is positive for a forward search, negative for a backward one.
4355         my $delta = $from < $to ? +1 : -1;
4356
4357         # Keep us from running off the ends of the file.
4358         my $limit = $delta > 0 ? $#dbline : 1;
4359
4360         # Clever test. If you're a mathematician, it's obvious why this
4361         # test works. If not:
4362         # If $delta is positive (going forward), $limit will be $#dbline.
4363         #    If $to is less than $limit, ($limit - $to) will be positive, times
4364         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4365         #    as the stopping point.
4366         #
4367         #    If $to is greater than $limit, ($limit - $to) is negative,
4368         #    times $delta of 1 (positive), so the result is < 0 and we should
4369         #    use $limit ($#dbline) as the stopping point.
4370         #
4371         # If $delta is negative (going backward), $limit will be 1.
4372         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4373         #    (negative) so the result is > 0, and we use $to as the stopping
4374         #    point.
4375         #
4376         #    If $to is less than zero, ($limit - $to) will be positive,
4377         #    times $delta of -1 (negative), so the result is not > 0, and
4378         #    we use $limit (1) as the stopping point.
4379         #
4380         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4381         #    (negative), still giving zero; the result is not > 0, and
4382         #    we use $limit (1) as the stopping point.
4383         #
4384         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4385         #    (negative), giving a positive (>0) value, so we'll set $limit to
4386         #    $to.
4387
4388         $limit = $to if ( $limit - $to ) * $delta > 0;
4389
4390         # The real search loop.
4391         # $i starts at $from (the point we want to start searching from).
4392         # We move through @dbline in the appropriate direction (determined
4393         # by $delta: either -1 (back) or +1 (ahead).
4394         # We stay in as long as we haven't hit an executable line
4395         # ($dbline[$i] == 0 means not executable) and we haven't reached
4396         # the limit yet (test similar to the above).
4397         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4398
4399     } ## end if (@_ >= 2)
4400
4401     # If $i points to a line that is executable, return that.
4402     return $i unless $dbline[$i] == 0;
4403
4404     # Format the message and print it: no breakable lines in range.
4405     my ( $pl, $upto ) = ( '', '' );
4406     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4407
4408     # If there's a filename in filename_error, we'll see it.
4409     # If not, not.
4410     die "Line$pl $from$upto$filename_error not breakable\n";
4411 } ## end sub breakable_line
4412
4413 =head3 breakable_line_in_filename(file, from, to) (API)
4414
4415 Like C<breakable_line>, but look in another file.
4416
4417 =cut
4418
4419 sub breakable_line_in_filename {
4420
4421     # Capture the file name.
4422     my ($f) = shift;
4423
4424     # Swap the magic line array over there temporarily.
4425     local *dbline = $main::{ '_<' . $f };
4426
4427     # If there's an error, it's in this other file.
4428     local $filename_error = " of '$f'";
4429
4430     # Find the breakable line.
4431     breakable_line(@_);
4432
4433     # *dbline and $filename_error get restored when this block ends.
4434
4435 } ## end sub breakable_line_in_filename
4436
4437 =head3 break_on_line(lineno, [condition]) (API)
4438
4439 Adds a breakpoint with the specified condition (or 1 if no condition was
4440 specified) to the specified line. Dies if it can't.
4441
4442 =cut
4443
4444 sub break_on_line {
4445     my ( $i, $cond ) = @_;
4446
4447     # Always true if no condition supplied.
4448     $cond = 1 unless @_ >= 2;
4449
4450     my $inii  = $i;
4451     my $after = '';
4452     my $pl    = '';
4453
4454     # Woops, not a breakable line. $filename_error allows us to say
4455     # if it was in a different file.
4456     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4457
4458     # Mark this file as having breakpoints in it.
4459     $had_breakpoints{$filename} |= 1;
4460
4461     # If there is an action or condition here already ...
4462     if ( $dbline{$i} ) {
4463
4464         # ... swap this condition for the existing one.
4465         $dbline{$i} =~ s/^[^\0]*/$cond/;
4466     }
4467     else {
4468
4469         # Nothing here - just add the condition.
4470         $dbline{$i} = $cond;
4471
4472         _set_breakpoint_enabled_status($filename, $i, 1);
4473     }
4474 } ## end sub break_on_line
4475
4476 =head3 cmd_b_line(line, [condition]) (command)
4477
4478 Wrapper for C<break_on_line>. Prints the failure message if it
4479 doesn't work.
4480
4481 =cut
4482
4483 sub cmd_b_line {
4484     if (not eval { break_on_line(@_); 1 }) {
4485         local $\ = '';
4486         print $OUT $@ and return;
4487     }
4488
4489     return;
4490 } ## end sub cmd_b_line
4491
4492 =head3 cmd_b_filename_line(line, [condition]) (command)
4493
4494 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4495 doesn't work.
4496
4497 =cut
4498
4499 sub cmd_b_filename_line {
4500     if (not eval { break_on_filename_line(@_); 1 }) {
4501         local $\ = '';
4502         print $OUT $@ and return;
4503     }
4504
4505     return;
4506 }
4507
4508 =head3 break_on_filename_line(file, line, [condition]) (API)
4509
4510 Switches to the file specified and then calls C<break_on_line> to set
4511 the breakpoint.
4512
4513 =cut
4514
4515 sub break_on_filename_line {
4516     my ( $f, $i, $cond ) = @_;
4517
4518     # Always true if condition left off.
4519     $cond = 1 unless @_ >= 3;
4520
4521     # Switch the magical hash temporarily.
4522     local *dbline = $main::{ '_<' . $f };
4523
4524     # Localize the variables that break_on_line uses to make its message.
4525     local $filename_error = " of '$f'";
4526     local $filename       = $f;
4527
4528     # Add the breakpoint.
4529     break_on_line( $i, $cond );
4530 } ## end sub break_on_filename_line
4531
4532 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4533
4534 Switch to another file, search the range of lines specified for an
4535 executable one, and put a breakpoint on the first one you find.
4536
4537 =cut
4538
4539 sub break_on_filename_line_range {
4540     my ( $f, $from, $to, $cond ) = @_;
4541
4542     # Find a breakable line if there is one.
4543     my $i = breakable_line_in_filename( $f, $from, $to );
4544