This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Extract _DB__handle_f_command.
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_05';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     @cmdfhs
631     $CommandSet
632     $CreateTTY
633     $DBGR
634     @dbline
635     $dbline
636     %dbline
637     $dieLevel
638     $filename
639     $hist
640     $histfile
641     $histsize
642     $IN
643     $inhibit_exit
644     @ini_INC
645     $ini_warn
646     $maxtrace
647     $od
648     $onetimedumpDepth
649     @options
650     $osingle
651     $otrace
652     $pager
653     $post
654     %postponed
655     $prc
656     $pre
657     $pretype
658     $psh
659     @RememberOnROptions
660     $remoteport
661     @res
662     $rl
663     @saved
664     $signalLevel
665     $start
666     $sub
667     $term
668     $usercontext
669     $warnLevel
670     $window
671 );
672
673 our (
674     $evalarg,
675     $frame,
676     $ImmediateStop,
677     $line,
678     $onetimeDump,
679     %option,
680     $OUT,
681     $packname,
682     $signal,
683     $single,
684     %sub,
685     $subname,
686     $trace,
687 );
688
689 # Used to save @ARGV and extract any debugger-related flags.
690 use vars qw(@ARGS);
691
692 # Used to prevent multiple entries to diesignal()
693 # (if for instance diesignal() itself dies)
694 use vars qw($panic);
695
696 # Used to prevent the debugger from running nonstop
697 # after a restart
698 our ($second_time);
699
700 sub _calc_usercontext {
701     my ($package) = @_;
702
703     # Cancel strict completely for the evaluated code, so the code
704     # the user evaluates won't be affected by it. (Shlomi Fish)
705     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
706     . "package $package;";    # this won't let them modify, alas
707 }
708
709 sub eval {
710
711     # 'my' would make it visible from user code
712     #    but so does local! --tchrist
713     # Remember: this localizes @DB::res, not @main::res.
714     local @res;
715     {
716
717         # Try to keep the user code from messing  with us. Save these so that
718         # even if the eval'ed code changes them, we can put them back again.
719         # Needed because the user could refer directly to the debugger's
720         # package globals (and any 'my' variables in this containing scope)
721         # inside the eval(), and we want to try to stay safe.
722         local $otrace  = $trace;
723         local $osingle = $single;
724         local $od      = $^D;
725
726         # Untaint the incoming eval() argument.
727         { ($evalarg) = $evalarg =~ /(.*)/s; }
728
729         # $usercontext built in DB::DB near the comment
730         # "set up the context for DB::eval ..."
731         # Evaluate and save any results.
732         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
733
734         # Restore those old values.
735         $trace  = $otrace;
736         $single = $osingle;
737         $^D     = $od;
738     }
739
740     # Save the current value of $@, and preserve it in the debugger's copy
741     # of the saved precious globals.
742     my $at = $@;
743
744     # Since we're only saving $@, we only have to localize the array element
745     # that it will be stored in.
746     local $saved[0];    # Preserve the old value of $@
747     eval { DB::save() };
748
749     # Now see whether we need to report an error back to the user.
750     if ($at) {
751         local $\ = '';
752         print $OUT $at;
753     }
754
755     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
756     # are package globals.
757     elsif ($onetimeDump) {
758         if ( $onetimeDump eq 'dump' ) {
759             local $option{dumpDepth} = $onetimedumpDepth
760               if defined $onetimedumpDepth;
761             dumpit( $OUT, \@res );
762         }
763         elsif ( $onetimeDump eq 'methods' ) {
764             methods( $res[0] );
765         }
766     } ## end elsif ($onetimeDump)
767     @res;
768 } ## end sub eval
769
770 ############################################## End lexical danger zone
771
772 # After this point it is safe to introduce lexicals.
773 # The code being debugged will be executing in its own context, and
774 # can't see the inside of the debugger.
775 #
776 # However, one should not overdo it: leave as much control from outside as
777 # possible. If you make something a lexical, it's not going to be addressable
778 # from outside the debugger even if you know its name.
779
780 # This file is automatically included if you do perl -d.
781 # It's probably not useful to include this yourself.
782 #
783 # Before venturing further into these twisty passages, it is
784 # wise to read the perldebguts man page or risk the ire of dragons.
785 #
786 # (It should be noted that perldebguts will tell you a lot about
787 # the underlying mechanics of how the debugger interfaces into the
788 # Perl interpreter, but not a lot about the debugger itself. The new
789 # comments in this code try to address this problem.)
790
791 # Note that no subroutine call is possible until &DB::sub is defined
792 # (for subroutines defined outside of the package DB). In fact the same is
793 # true if $deep is not defined.
794
795 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
796
797 # modified Perl debugger, to be run from Emacs in perldb-mode
798 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
799 # Johan Vromans -- upgrade to 4.0 pl 10
800 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
801 ########################################################################
802
803 =head1 DEBUGGER INITIALIZATION
804
805 The debugger starts up in phases.
806
807 =head2 BASIC SETUP
808
809 First, it initializes the environment it wants to run in: turning off
810 warnings during its own compilation, defining variables which it will need
811 to avoid warnings later, setting itself up to not exit when the program
812 terminates, and defaulting to printing return values for the C<r> command.
813
814 =cut
815
816 # Needed for the statement after exec():
817 #
818 # This BEGIN block is simply used to switch off warnings during debugger
819 # compilation. Probably it would be better practice to fix the warnings,
820 # but this is how it's done at the moment.
821
822 BEGIN {
823     $ini_warn = $^W;
824     $^W       = 0;
825 }    # Switch compilation warnings off until another BEGIN.
826
827 local ($^W) = 0;    # Switch run-time warnings off during init.
828
829 =head2 THREADS SUPPORT
830
831 If we are running under a threaded Perl, we require threads and threads::shared
832 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
833 threaded debugger control.  C<-dt> can also be used to set this.
834
835 Each new thread will be announced and the debugger prompt will always inform
836 you of each new thread created.  It will also indicate the thread id in which
837 we are currently running within the prompt like this:
838
839     [tid] DB<$i>
840
841 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
842 command prompt.  The prompt will show: C<[0]> when running under threads, but
843 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
844
845 While running under threads, when you set or delete a breakpoint (etc.), this
846 will apply to all threads, not just the currently running one.  When you are
847 in a currently executing thread, you will stay there until it completes.  With
848 the current implementation it is not currently possible to hop from one thread
849 to another.
850
851 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
852
853 Note that threading support was built into the debugger as of Perl version
854 C<5.8.6> and debugger version C<1.2.8>.
855
856 =cut
857
858 BEGIN {
859     # ensure we can share our non-threaded variables or no-op
860     if ($ENV{PERL5DB_THREADED}) {
861         require threads;
862         require threads::shared;
863         import threads::shared qw(share);
864         $DBGR;
865         share(\$DBGR);
866         lock($DBGR);
867         print "Threads support enabled\n";
868     } else {
869         *lock  = sub(*) {};
870         *share = sub(*) {};
871     }
872 }
873
874 # These variables control the execution of 'dumpvar.pl'.
875 {
876     package dumpvar;
877     use vars qw(
878     $hashDepth
879     $arrayDepth
880     $dumpDBFiles
881     $dumpPackages
882     $quoteHighBit
883     $printUndef
884     $globPrint
885     $usageOnly
886     );
887 }
888
889 # used to control die() reporting in diesignal()
890 {
891     package Carp;
892     use vars qw($CarpLevel);
893 }
894
895 # without threads, $filename is not defined until DB::DB is called
896 foreach my $k (keys (%INC)) {
897     share(\$main::{'_<'.$filename}) if defined $filename;
898 };
899
900 # Command-line + PERLLIB:
901 # Save the contents of @INC before they are modified elsewhere.
902 @ini_INC = @INC;
903
904 # This was an attempt to clear out the previous values of various
905 # trapped errors. Apparently it didn't help. XXX More info needed!
906 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
907
908 # We set these variables to safe values. We don't want to blindly turn
909 # off warnings, because other packages may still want them.
910 $trace = $signal = $single = 0;    # Uninitialized warning suppression
911                                    # (local $^W cannot help - other packages!).
912
913 # Default to not exiting when program finishes; print the return
914 # value when the 'r' command is used to return from a subroutine.
915 $inhibit_exit = $option{PrintRet} = 1;
916
917 use vars qw($trace_to_depth);
918
919 # Default to 1E9 so it won't be limited to a certain recursion depth.
920 $trace_to_depth = 1E9;
921
922 =head1 OPTION PROCESSING
923
924 The debugger's options are actually spread out over the debugger itself and
925 C<dumpvar.pl>; some of these are variables to be set, while others are
926 subs to be called with a value. To try to make this a little easier to
927 manage, the debugger uses a few data structures to define what options
928 are legal and how they are to be processed.
929
930 First, the C<@options> array defines the I<names> of all the options that
931 are to be accepted.
932
933 =cut
934
935 @options = qw(
936   CommandSet   HistFile      HistSize
937   hashDepth    arrayDepth    dumpDepth
938   DumpDBFiles  DumpPackages  DumpReused
939   compactDump  veryCompact   quote
940   HighBit      undefPrint    globPrint
941   PrintRet     UsageOnly     frame
942   AutoTrace    TTY           noTTY
943   ReadLine     NonStop       LineInfo
944   maxTraceLen  recallCommand ShellBang
945   pager        tkRunning     ornaments
946   signalLevel  warnLevel     dieLevel
947   inhibit_exit ImmediateStop bareStringify
948   CreateTTY    RemotePort    windowSize
949   DollarCaretP
950 );
951
952 @RememberOnROptions = qw(DollarCaretP);
953
954 =pod
955
956 Second, C<optionVars> lists the variables that each option uses to save its
957 state.
958
959 =cut
960
961 use vars qw(%optionVars);
962
963 %optionVars = (
964     hashDepth     => \$dumpvar::hashDepth,
965     arrayDepth    => \$dumpvar::arrayDepth,
966     CommandSet    => \$CommandSet,
967     DumpDBFiles   => \$dumpvar::dumpDBFiles,
968     DumpPackages  => \$dumpvar::dumpPackages,
969     DumpReused    => \$dumpvar::dumpReused,
970     HighBit       => \$dumpvar::quoteHighBit,
971     undefPrint    => \$dumpvar::printUndef,
972     globPrint     => \$dumpvar::globPrint,
973     UsageOnly     => \$dumpvar::usageOnly,
974     CreateTTY     => \$CreateTTY,
975     bareStringify => \$dumpvar::bareStringify,
976     frame         => \$frame,
977     AutoTrace     => \$trace,
978     inhibit_exit  => \$inhibit_exit,
979     maxTraceLen   => \$maxtrace,
980     ImmediateStop => \$ImmediateStop,
981     RemotePort    => \$remoteport,
982     windowSize    => \$window,
983     HistFile      => \$histfile,
984     HistSize      => \$histsize,
985 );
986
987 =pod
988
989 Third, C<%optionAction> defines the subroutine to be called to process each
990 option.
991
992 =cut
993
994 use vars qw(%optionAction);
995
996 %optionAction = (
997     compactDump   => \&dumpvar::compactDump,
998     veryCompact   => \&dumpvar::veryCompact,
999     quote         => \&dumpvar::quote,
1000     TTY           => \&TTY,
1001     noTTY         => \&noTTY,
1002     ReadLine      => \&ReadLine,
1003     NonStop       => \&NonStop,
1004     LineInfo      => \&LineInfo,
1005     recallCommand => \&recallCommand,
1006     ShellBang     => \&shellBang,
1007     pager         => \&pager,
1008     signalLevel   => \&signalLevel,
1009     warnLevel     => \&warnLevel,
1010     dieLevel      => \&dieLevel,
1011     tkRunning     => \&tkRunning,
1012     ornaments     => \&ornaments,
1013     RemotePort    => \&RemotePort,
1014     DollarCaretP  => \&DollarCaretP,
1015 );
1016
1017 =pod
1018
1019 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1020 option is used.
1021
1022 =cut
1023
1024 # Note that this list is not complete: several options not listed here
1025 # actually require that dumpvar.pl be loaded for them to work, but are
1026 # not in the table. A subsequent patch will correct this problem; for
1027 # the moment, we're just recommenting, and we are NOT going to change
1028 # function.
1029 use vars qw(%optionRequire);
1030
1031 %optionRequire = (
1032     compactDump => 'dumpvar.pl',
1033     veryCompact => 'dumpvar.pl',
1034     quote       => 'dumpvar.pl',
1035 );
1036
1037 =pod
1038
1039 There are a number of initialization-related variables which can be set
1040 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1041 variable. These are:
1042
1043 =over 4
1044
1045 =item C<$rl> - readline control XXX needs more explanation
1046
1047 =item C<$warnLevel> - whether or not debugger takes over warning handling
1048
1049 =item C<$dieLevel> - whether or not debugger takes over die handling
1050
1051 =item C<$signalLevel> - whether or not debugger takes over signal handling
1052
1053 =item C<$pre> - preprompt actions (array reference)
1054
1055 =item C<$post> - postprompt actions (array reference)
1056
1057 =item C<$pretype>
1058
1059 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1060
1061 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1062
1063 =back
1064
1065 =cut
1066
1067 # These guys may be defined in $ENV{PERL5DB} :
1068 $rl          = 1     unless defined $rl;
1069 $warnLevel   = 1     unless defined $warnLevel;
1070 $dieLevel    = 1     unless defined $dieLevel;
1071 $signalLevel = 1     unless defined $signalLevel;
1072 $pre         = []    unless defined $pre;
1073 $post        = []    unless defined $post;
1074 $pretype     = []    unless defined $pretype;
1075 $CreateTTY   = 3     unless defined $CreateTTY;
1076 $CommandSet  = '580' unless defined $CommandSet;
1077
1078 share($rl);
1079 share($warnLevel);
1080 share($dieLevel);
1081 share($signalLevel);
1082 share($pre);
1083 share($post);
1084 share($pretype);
1085 share($rl);
1086 share($CreateTTY);
1087 share($CommandSet);
1088
1089 =pod
1090
1091 The default C<die>, C<warn>, and C<signal> handlers are set up.
1092
1093 =cut
1094
1095 warnLevel($warnLevel);
1096 dieLevel($dieLevel);
1097 signalLevel($signalLevel);
1098
1099 =pod
1100
1101 The pager to be used is needed next. We try to get it from the
1102 environment first.  If it's not defined there, we try to find it in
1103 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1104 then call the C<pager()> function to save the pager name.
1105
1106 =cut
1107
1108 # This routine makes sure $pager is set up so that '|' can use it.
1109 pager(
1110
1111     # If PAGER is defined in the environment, use it.
1112     defined $ENV{PAGER}
1113     ? $ENV{PAGER}
1114
1115       # If not, see if Config.pm defines it.
1116     : eval { require Config }
1117       && defined $Config::Config{pager}
1118     ? $Config::Config{pager}
1119
1120       # If not, fall back to 'more'.
1121     : 'more'
1122   )
1123   unless defined $pager;
1124
1125 =pod
1126
1127 We set up the command to be used to access the man pages, the command
1128 recall character (C<!> unless otherwise defined) and the shell escape
1129 character (C<!> unless otherwise defined). Yes, these do conflict, and
1130 neither works in the debugger at the moment.
1131
1132 =cut
1133
1134 setman();
1135
1136 # Set up defaults for command recall and shell escape (note:
1137 # these currently don't work in linemode debugging).
1138 recallCommand("!") unless defined $prc;
1139 shellBang("!")     unless defined $psh;
1140
1141 =pod
1142
1143 We then set up the gigantic string containing the debugger help.
1144 We also set the limit on the number of arguments we'll display during a
1145 trace.
1146
1147 =cut
1148
1149 sethelp();
1150
1151 # If we didn't get a default for the length of eval/stack trace args,
1152 # set it here.
1153 $maxtrace = 400 unless defined $maxtrace;
1154
1155 =head2 SETTING UP THE DEBUGGER GREETING
1156
1157 The debugger I<greeting> helps to inform the user how many debuggers are
1158 running, and whether the current debugger is the primary or a child.
1159
1160 If we are the primary, we just hang onto our pid so we'll have it when
1161 or if we start a child debugger. If we are a child, we'll set things up
1162 so we'll have a unique greeting and so the parent will give us our own
1163 TTY later.
1164
1165 We save the current contents of the C<PERLDB_PIDS> environment variable
1166 because we mess around with it. We'll also need to hang onto it because
1167 we'll need it if we restart.
1168
1169 Child debuggers make a label out of the current PID structure recorded in
1170 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1171 yet so the parent will give them one later via C<resetterm()>.
1172
1173 =cut
1174
1175 # Save the current contents of the environment; we're about to
1176 # much with it. We'll need this if we have to restart.
1177 use vars qw($ini_pids);
1178 $ini_pids = $ENV{PERLDB_PIDS};
1179
1180 use vars qw ($pids $term_pid);
1181
1182 if ( defined $ENV{PERLDB_PIDS} ) {
1183
1184     # We're a child. Make us a label out of the current PID structure
1185     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1186     # a term yet so the parent will give us one later via resetterm().
1187
1188     my $env_pids = $ENV{PERLDB_PIDS};
1189     $pids = "[$env_pids]";
1190
1191     # Unless we are on OpenVMS, all programs under the DCL shell run under
1192     # the same PID.
1193
1194     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1195         $term_pid         = $$;
1196     }
1197     else {
1198         $ENV{PERLDB_PIDS} .= "->$$";
1199         $term_pid = -1;
1200     }
1201
1202 } ## end if (defined $ENV{PERLDB_PIDS...
1203 else {
1204
1205     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1206     # child debugger, and mark us as the parent, so we'll know to set up
1207     # more TTY's is we have to.
1208     $ENV{PERLDB_PIDS} = "$$";
1209     $pids             = "[pid=$$]";
1210     $term_pid         = $$;
1211 }
1212
1213 use vars qw($pidprompt);
1214 $pidprompt = '';
1215
1216 # Sets up $emacs as a synonym for $slave_editor.
1217 our ($slave_editor);
1218 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1219
1220 =head2 READING THE RC FILE
1221
1222 The debugger will read a file of initialization options if supplied. If
1223 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1224
1225 =cut
1226
1227 # As noted, this test really doesn't check accurately that the debugger
1228 # is running at a terminal or not.
1229
1230 use vars qw($rcfile);
1231 {
1232     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1233     # this is the wrong metric!
1234     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1235 }
1236
1237 =pod
1238
1239 The debugger does a safety test of the file to be read. It must be owned
1240 either by the current user or root, and must only be writable by the owner.
1241
1242 =cut
1243
1244 # This wraps a safety test around "do" to read and evaluate the init file.
1245 #
1246 # This isn't really safe, because there's a race
1247 # between checking and opening.  The solution is to
1248 # open and fstat the handle, but then you have to read and
1249 # eval the contents.  But then the silly thing gets
1250 # your lexical scope, which is unfortunate at best.
1251 sub safe_do {
1252     my $file = shift;
1253
1254     # Just exactly what part of the word "CORE::" don't you understand?
1255     local $SIG{__WARN__};
1256     local $SIG{__DIE__};
1257
1258     unless ( is_safe_file($file) ) {
1259         CORE::warn <<EO_GRIPE;
1260 perldb: Must not source insecure rcfile $file.
1261         You or the superuser must be the owner, and it must not
1262         be writable by anyone but its owner.
1263 EO_GRIPE
1264         return;
1265     } ## end unless (is_safe_file($file...
1266
1267     do $file;
1268     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1269 } ## end sub safe_do
1270
1271 # This is the safety test itself.
1272 #
1273 # Verifies that owner is either real user or superuser and that no
1274 # one but owner may write to it.  This function is of limited use
1275 # when called on a path instead of upon a handle, because there are
1276 # no guarantees that filename (by dirent) whose file (by ino) is
1277 # eventually accessed is the same as the one tested.
1278 # Assumes that the file's existence is not in doubt.
1279 sub is_safe_file {
1280     my $path = shift;
1281     stat($path) || return;    # mysteriously vaporized
1282     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1283
1284     return 0 if $uid != 0 && $uid != $<;
1285     return 0 if $mode & 022;
1286     return 1;
1287 } ## end sub is_safe_file
1288
1289 # If the rcfile (whichever one we decided was the right one to read)
1290 # exists, we safely do it.
1291 if ( -f $rcfile ) {
1292     safe_do("./$rcfile");
1293 }
1294
1295 # If there isn't one here, try the user's home directory.
1296 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1297     safe_do("$ENV{HOME}/$rcfile");
1298 }
1299
1300 # Else try the login directory.
1301 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1302     safe_do("$ENV{LOGDIR}/$rcfile");
1303 }
1304
1305 # If the PERLDB_OPTS variable has options in it, parse those out next.
1306 if ( defined $ENV{PERLDB_OPTS} ) {
1307     parse_options( $ENV{PERLDB_OPTS} );
1308 }
1309
1310 =pod
1311
1312 The last thing we do during initialization is determine which subroutine is
1313 to be used to obtain a new terminal when a new debugger is started. Right now,
1314 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1315 (darwin).
1316
1317 =cut
1318
1319 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1320 # Works if you're running an xterm or xterm-like window, or you're on
1321 # OS/2, or on Mac OS X. This may need some expansion.
1322
1323 if (not defined &get_fork_TTY)       # only if no routine exists
1324 {
1325     if ( defined $remoteport ) {
1326                                                  # Expect an inetd-like server
1327         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1328     }
1329     elsif (defined $ENV{TERM}                    # If we know what kind
1330                                                  # of terminal this is,
1331         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1332         and defined $ENV{DISPLAY}                # and what display it's on,
1333       )
1334     {
1335         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1336     }
1337     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1338         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1339     }
1340     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1341             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1342             and $ENV{TERM_PROGRAM}
1343                 eq 'Apple_Terminal'              # Terminal.app
1344             )
1345     {
1346         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1347     }
1348 } ## end if (not defined &get_fork_TTY...
1349
1350 # untaint $^O, which may have been tainted by the last statement.
1351 # see bug [perl #24674]
1352 $^O =~ m/^(.*)\z/;
1353 $^O = $1;
1354
1355 # Here begin the unreadable code.  It needs fixing.
1356
1357 =head2 RESTART PROCESSING
1358
1359 This section handles the restart command. When the C<R> command is invoked, it
1360 tries to capture all of the state it can into environment variables, and
1361 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1362 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1363 the R command stuffed into the environment variables.
1364
1365   PERLDB_RESTART   - flag only, contains no restart data itself.
1366   PERLDB_HIST      - command history, if it's available
1367   PERLDB_ON_LOAD   - breakpoints set by the rc file
1368   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1369   PERLDB_VISITED   - files that had breakpoints
1370   PERLDB_FILE_...  - breakpoints for a file
1371   PERLDB_OPT       - active options
1372   PERLDB_INC       - the original @INC
1373   PERLDB_PRETYPE   - preprompt debugger actions
1374   PERLDB_PRE       - preprompt Perl code
1375   PERLDB_POST      - post-prompt Perl code
1376   PERLDB_TYPEAHEAD - typeahead captured by readline()
1377
1378 We chug through all these variables and plug the values saved in them
1379 back into the appropriate spots in the debugger.
1380
1381 =cut
1382
1383 use vars qw(@hist @truehist %postponed_file @typeahead);
1384
1385 sub _restore_shared_globals_after_restart
1386 {
1387     @hist          = get_list('PERLDB_HIST');
1388     %break_on_load = get_list("PERLDB_ON_LOAD");
1389     %postponed     = get_list("PERLDB_POSTPONE");
1390
1391     share(@hist);
1392     share(@truehist);
1393     share(%break_on_load);
1394     share(%postponed);
1395 }
1396
1397 sub _restore_breakpoints_and_actions {
1398
1399     my @had_breakpoints = get_list("PERLDB_VISITED");
1400
1401     for my $file_idx ( 0 .. $#had_breakpoints ) {
1402         my $filename = $had_breakpoints[$file_idx];
1403         my %pf = get_list("PERLDB_FILE_$file_idx");
1404         $postponed_file{ $filename } = \%pf if %pf;
1405         my @lines = sort {$a <=> $b} keys(%pf);
1406         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1407         for my $line_idx (0 .. $#lines) {
1408             _set_breakpoint_enabled_status(
1409                 $filename,
1410                 $lines[$line_idx],
1411                 ($enabled_statuses[$line_idx] ? 1 : ''),
1412             );
1413         }
1414     }
1415
1416     return;
1417 }
1418
1419 sub _restore_options_after_restart
1420 {
1421     my %options_map = get_list("PERLDB_OPT");
1422
1423     while ( my ( $opt, $val ) = each %options_map ) {
1424         $val =~ s/[\\\']/\\$1/g;
1425         parse_options("$opt'$val'");
1426     }
1427
1428     return;
1429 }
1430
1431 sub _restore_globals_after_restart
1432 {
1433     # restore original @INC
1434     @INC     = get_list("PERLDB_INC");
1435     @ini_INC = @INC;
1436
1437     # return pre/postprompt actions and typeahead buffer
1438     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1439     $pre       = [ get_list("PERLDB_PRE") ];
1440     $post      = [ get_list("PERLDB_POST") ];
1441     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1442
1443     return;
1444 }
1445
1446
1447 if ( exists $ENV{PERLDB_RESTART} ) {
1448
1449     # We're restarting, so we don't need the flag that says to restart anymore.
1450     delete $ENV{PERLDB_RESTART};
1451
1452     # $restart = 1;
1453     _restore_shared_globals_after_restart();
1454
1455     _restore_breakpoints_and_actions();
1456
1457     # restore options
1458     _restore_options_after_restart();
1459
1460     _restore_globals_after_restart();
1461 } ## end if (exists $ENV{PERLDB_RESTART...
1462
1463 =head2 SETTING UP THE TERMINAL
1464
1465 Now, we'll decide how the debugger is going to interact with the user.
1466 If there's no TTY, we set the debugger to run non-stop; there's not going
1467 to be anyone there to enter commands.
1468
1469 =cut
1470
1471 use vars qw($notty $console $tty $LINEINFO);
1472 use vars qw($lineinfo $doccmd);
1473
1474 our ($runnonstop);
1475
1476 if ($notty) {
1477     $runnonstop = 1;
1478     share($runnonstop);
1479 }
1480
1481 =pod
1482
1483 If there is a TTY, we have to determine who it belongs to before we can
1484 proceed. If this is a slave editor or graphical debugger (denoted by
1485 the first command-line switch being '-emacs'), we shift this off and
1486 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1487
1488 =cut
1489
1490 else {
1491
1492     # Is Perl being run from a slave editor or graphical debugger?
1493     # If so, don't use readline, and set $slave_editor = 1.
1494     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1495         $rl = 0;
1496         shift(@main::ARGV);
1497     }
1498
1499     #require Term::ReadLine;
1500
1501 =pod
1502
1503 We then determine what the console should be on various systems:
1504
1505 =over 4
1506
1507 =item * Cygwin - We use C<stdin> instead of a separate device.
1508
1509 =cut
1510
1511     if ( $^O eq 'cygwin' ) {
1512
1513         # /dev/tty is binary. use stdin for textmode
1514         undef $console;
1515     }
1516
1517 =item * Unix - use C</dev/tty>.
1518
1519 =cut
1520
1521     elsif ( -e "/dev/tty" ) {
1522         $console = "/dev/tty";
1523     }
1524
1525 =item * Windows or MSDOS - use C<con>.
1526
1527 =cut
1528
1529     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1530         $console = "con";
1531     }
1532
1533 =item * VMS - use C<sys$command>.
1534
1535 =cut
1536
1537     else {
1538
1539         # everything else is ...
1540         $console = "sys\$command";
1541     }
1542
1543 =pod
1544
1545 =back
1546
1547 Several other systems don't use a specific console. We C<undef $console>
1548 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1549 with a slave editor, Epoc).
1550
1551 =cut
1552
1553     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1554
1555         # /dev/tty is binary. use stdin for textmode
1556         $console = undef;
1557     }
1558
1559     if ( $^O eq 'NetWare' ) {
1560
1561         # /dev/tty is binary. use stdin for textmode
1562         $console = undef;
1563     }
1564
1565     # In OS/2, we need to use STDIN to get textmode too, even though
1566     # it pretty much looks like Unix otherwise.
1567     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1568     {    # In OS/2
1569         $console = undef;
1570     }
1571
1572     # EPOC also falls into the 'got to use STDIN' camp.
1573     if ( $^O eq 'epoc' ) {
1574         $console = undef;
1575     }
1576
1577 =pod
1578
1579 If there is a TTY hanging around from a parent, we use that as the console.
1580
1581 =cut
1582
1583     $console = $tty if defined $tty;
1584
1585 =head2 SOCKET HANDLING
1586
1587 The debugger is capable of opening a socket and carrying out a debugging
1588 session over the socket.
1589
1590 If C<RemotePort> was defined in the options, the debugger assumes that it
1591 should try to start a debugging session on that port. It builds the socket
1592 and then tries to connect the input and output filehandles to it.
1593
1594 =cut
1595
1596     # Handle socket stuff.
1597
1598     if ( defined $remoteport ) {
1599
1600         # If RemotePort was defined in the options, connect input and output
1601         # to the socket.
1602         $IN = $OUT = connect_remoteport();
1603     } ## end if (defined $remoteport)
1604
1605 =pod
1606
1607 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1608 this is probably a situation where multiple debuggers are running (for example,
1609 a backticked command that starts up another debugger). We create a new IN and
1610 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1611 and if we can.
1612
1613 =cut
1614
1615     # Non-socket.
1616     else {
1617
1618         # Two debuggers running (probably a system or a backtick that invokes
1619         # the debugger itself under the running one). create a new IN and OUT
1620         # filehandle, and do the necessary mojo to create a new tty if we
1621         # know how, and we can.
1622         create_IN_OUT(4) if $CreateTTY & 4;
1623         if ($console) {
1624
1625             # If we have a console, check to see if there are separate ins and
1626             # outs to open. (They are assumed identical if not.)
1627
1628             my ( $i, $o ) = split /,/, $console;
1629             $o = $i unless defined $o;
1630
1631             # read/write on in, or just read, or read on STDIN.
1632             open( IN,      "+<$i" )
1633               || open( IN, "<$i" )
1634               || open( IN, "<&STDIN" );
1635
1636             # read/write/create/clobber out, or write/create/clobber out,
1637             # or merge with STDERR, or merge with STDOUT.
1638                  open( OUT, "+>$o" )
1639               || open( OUT, ">$o" )
1640               || open( OUT, ">&STDERR" )
1641               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1642
1643         } ## end if ($console)
1644         elsif ( not defined $console ) {
1645
1646             # No console. Open STDIN.
1647             open( IN, "<&STDIN" );
1648
1649             # merge with STDERR, or with STDOUT.
1650             open( OUT,      ">&STDERR" )
1651               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1652             $console = 'STDIN/OUT';
1653         } ## end elsif (not defined $console)
1654
1655         # Keep copies of the filehandles so that when the pager runs, it
1656         # can close standard input without clobbering ours.
1657         if ($console or (not defined($console))) {
1658             $IN = \*IN;
1659             $OUT = \*OUT;
1660         }
1661     } ## end elsif (from if(defined $remoteport))
1662
1663     # Unbuffer DB::OUT. We need to see responses right away.
1664     $OUT->autoflush(1);
1665
1666     # Line info goes to debugger output unless pointed elsewhere.
1667     # Pointing elsewhere makes it possible for slave editors to
1668     # keep track of file and position. We have both a filehandle
1669     # and a I/O description to keep track of.
1670     $LINEINFO = $OUT     unless defined $LINEINFO;
1671     $lineinfo = $console unless defined $lineinfo;
1672     # share($LINEINFO); # <- unable to share globs
1673     share($lineinfo);   #
1674
1675 =pod
1676
1677 To finish initialization, we show the debugger greeting,
1678 and then call the C<afterinit()> subroutine if there is one.
1679
1680 =cut
1681
1682     # Show the debugger greeting.
1683     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1684     unless ($runnonstop) {
1685         local $\ = '';
1686         local $, = '';
1687         if ( $term_pid eq '-1' ) {
1688             print $OUT "\nDaughter DB session started...\n";
1689         }
1690         else {
1691             print $OUT "\nLoading DB routines from $header\n";
1692             print $OUT (
1693                 "Editor support ",
1694                 $slave_editor ? "enabled" : "available", ".\n"
1695             );
1696             print $OUT
1697 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1698         } ## end else [ if ($term_pid eq '-1')
1699     } ## end unless ($runnonstop)
1700 } ## end else [ if ($notty)
1701
1702 # XXX This looks like a bug to me.
1703 # Why copy to @ARGS and then futz with @args?
1704 @ARGS = @ARGV;
1705 # for (@args) {
1706     # Make sure backslashes before single quotes are stripped out, and
1707     # keep args unless they are numeric (XXX why?)
1708     # s/\'/\\\'/g;                      # removed while not justified understandably
1709     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1710 # }
1711
1712 # If there was an afterinit() sub defined, call it. It will get
1713 # executed in our scope, so it can fiddle with debugger globals.
1714 if ( defined &afterinit ) {    # May be defined in $rcfile
1715     afterinit();
1716 }
1717
1718 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1719 use vars qw($I_m_init);
1720
1721 $I_m_init = 1;
1722
1723 ############################################################ Subroutines
1724
1725 =head1 SUBROUTINES
1726
1727 =head2 DB
1728
1729 This gigantic subroutine is the heart of the debugger. Called before every
1730 statement, its job is to determine if a breakpoint has been reached, and
1731 stop if so; read commands from the user, parse them, and execute
1732 them, and then send execution off to the next statement.
1733
1734 Note that the order in which the commands are processed is very important;
1735 some commands earlier in the loop will actually alter the C<$cmd> variable
1736 to create other commands to be executed later. This is all highly I<optimized>
1737 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1738 see what's happening in any given command.
1739
1740 =cut
1741
1742 use vars qw(
1743     $action
1744     %alias
1745     $cmd
1746     $fall_off_end
1747     $file
1748     $filename_ini
1749     $finished
1750     %had_breakpoints
1751     $incr
1752     $laststep
1753     $level
1754     $max
1755     $package
1756     $rc
1757     $sh
1758     $try
1759     $end
1760 );
1761
1762 our (
1763     $doret,
1764     $stack_depth,
1765     @stack,
1766     @to_watch,
1767     @old_watch,
1768 );
1769
1770 sub _DB__determine_if_we_should_break
1771 {
1772     # if we have something here, see if we should break.
1773     # $stop is lexical and local to this block - $action on the other hand
1774     # is global.
1775     my $stop;
1776
1777     if ( $dbline{$line}
1778         && _is_breakpoint_enabled($filename, $line)
1779         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1780     {
1781
1782         # Stop if the stop criterion says to just stop.
1783         if ( $stop eq '1' ) {
1784             $signal |= 1;
1785         }
1786
1787         # It's a conditional stop; eval it in the user's context and
1788         # see if we should stop. If so, remove the one-time sigil.
1789         elsif ($stop) {
1790             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1791             &eval;
1792             # If the breakpoint is temporary, then delete its enabled status.
1793             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1794                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1795             }
1796         }
1797     } ## end if ($dbline{$line} && ...
1798 }
1799
1800 sub _DB__is_finished {
1801     if ($finished and $level <= 1) {
1802         end_report();
1803         return 1;
1804     }
1805     else {
1806         return;
1807     }
1808 }
1809
1810 sub _DB__read_next_cmd
1811 {
1812     my ($tid) = @_;
1813
1814     # We have a terminal, or can get one ...
1815     if (!$term) {
1816         setterm();
1817     }
1818
1819     # ... and it belogs to this PID or we get one for this PID ...
1820     if ($term_pid != $$) {
1821         resetterm(1);
1822     }
1823
1824     # ... and we got a line of command input ...
1825     $cmd = DB::readline(
1826         "$pidprompt $tid DB"
1827         . ( '<' x $level )
1828         . ( $#hist + 1 )
1829         . ( '>' x $level ) . " "
1830     );
1831
1832     return defined($cmd);
1833 }
1834
1835 sub _DB__trim_command_and_return_first_component {
1836     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1837     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1838
1839     $cmd =~ m{\A(\S*)};
1840     return $1;
1841 }
1842
1843 sub _DB__handle_f_command {
1844     if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
1845         $file =~ s/\s+$//;
1846
1847         # help for no arguments (old-style was return from sub).
1848         if ( !$file ) {
1849             print $OUT
1850             "The old f command is now the r command.\n";    # hint
1851             print $OUT "The new f command switches filenames.\n";
1852             next CMD;
1853         } ## end if (!$file)
1854
1855         # if not in magic file list, try a close match.
1856         if ( !defined $main::{ '_<' . $file } ) {
1857             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1858                 {
1859                     $try = substr( $try, 2 );
1860                     print $OUT "Choosing $try matching '$file':\n";
1861                     $file = $try;
1862                 }
1863             } ## end if (($try) = grep(m#^_<.*$file#...
1864         } ## end if (!defined $main::{ ...
1865
1866         # If not successfully switched now, we failed.
1867         if ( !defined $main::{ '_<' . $file } ) {
1868             print $OUT "No file matching '$file' is loaded.\n";
1869             next CMD;
1870         }
1871
1872         # We switched, so switch the debugger internals around.
1873         elsif ( $file ne $filename ) {
1874             *dbline   = $main::{ '_<' . $file };
1875             $max      = $#dbline;
1876             $filename = $file;
1877             $start    = 1;
1878             $cmd      = "l";
1879         } ## end elsif ($file ne $filename)
1880
1881         # We didn't switch; say we didn't.
1882         else {
1883             print $OUT "Already in $file.\n";
1884             next CMD;
1885         }
1886     }
1887
1888     return;
1889 }
1890
1891 sub DB {
1892
1893     # lock the debugger and get the thread id for the prompt
1894     lock($DBGR);
1895     my $tid;
1896     my $position;
1897     my ($prefix, $after, $infix);
1898     my $pat;
1899     my $explicit_stop;
1900
1901     if ($ENV{PERL5DB_THREADED}) {
1902         $tid = eval { "[".threads->tid."]" };
1903     }
1904
1905     my $obj = DB::Obj->new(
1906         {
1907             position => \$position,
1908             prefix => \$prefix,
1909             after => \$after,
1910             explicit_stop => \$explicit_stop,
1911             infix => \$infix,
1912         },
1913     );
1914
1915     $obj->_DB_on_init__initialize_globals(@_);
1916
1917     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1918     # The code being debugged may have altered them.
1919     &save;
1920
1921     # Since DB::DB gets called after every line, we can use caller() to
1922     # figure out where we last were executing. Sneaky, eh? This works because
1923     # caller is returning all the extra information when called from the
1924     # debugger.
1925     local ( $package, $filename, $line ) = caller;
1926     $filename_ini = $filename;
1927
1928     # set up the context for DB::eval, so it can properly execute
1929     # code on behalf of the user. We add the package in so that the
1930     # code is eval'ed in the proper package (not in the debugger!).
1931     local $usercontext = _calc_usercontext($package);
1932
1933     # Create an alias to the active file magical array to simplify
1934     # the code here.
1935     local (*dbline) = $main::{ '_<' . $filename };
1936
1937     # Last line in the program.
1938     $max = $#dbline;
1939
1940     _DB__determine_if_we_should_break(@_);
1941
1942     # Preserve the current stop-or-not, and see if any of the W
1943     # (watch expressions) has changed.
1944     my $was_signal = $signal;
1945
1946     # If we have any watch expressions ...
1947     $obj->_DB__handle_watch_expressions(@_);
1948
1949 =head2 C<watchfunction()>
1950
1951 C<watchfunction()> is a function that can be defined by the user; it is a
1952 function which will be run on each entry to C<DB::DB>; it gets the
1953 current package, filename, and line as its parameters.
1954
1955 The watchfunction can do anything it likes; it is executing in the
1956 debugger's context, so it has access to all of the debugger's internal
1957 data structures and functions.
1958
1959 C<watchfunction()> can control the debugger's actions. Any of the following
1960 will cause the debugger to return control to the user's program after
1961 C<watchfunction()> executes:
1962
1963 =over 4
1964
1965 =item *
1966
1967 Returning a false value from the C<watchfunction()> itself.
1968
1969 =item *
1970
1971 Altering C<$single> to a false value.
1972
1973 =item *
1974
1975 Altering C<$signal> to a false value.
1976
1977 =item *
1978
1979 Turning off the C<4> bit in C<$trace> (this also disables the
1980 check for C<watchfunction()>. This can be done with
1981
1982     $trace &= ~4;
1983
1984 =back
1985
1986 =cut
1987
1988     # If there's a user-defined DB::watchfunction, call it with the
1989     # current package, filename, and line. The function executes in
1990     # the DB:: package.
1991     if ( $trace & 4 ) {    # User-installed watch
1992         return
1993           if watchfunction( $package, $filename, $line )
1994           and not $single
1995           and not $was_signal
1996           and not( $trace & ~4 );
1997     } ## end if ($trace & 4)
1998
1999     # Pick up any alteration to $signal in the watchfunction, and
2000     # turn off the signal now.
2001     $was_signal = $signal;
2002     $signal     = 0;
2003
2004 =head2 GETTING READY TO EXECUTE COMMANDS
2005
2006 The debugger decides to take control if single-step mode is on, the
2007 C<t> command was entered, or the user generated a signal. If the program
2008 has fallen off the end, we set things up so that entering further commands
2009 won't cause trouble, and we say that the program is over.
2010
2011 =cut
2012
2013     # Make sure that we always print if asked for explicitly regardless
2014     # of $trace_to_depth .
2015     $explicit_stop = ($single || $was_signal);
2016
2017     # Check to see if we should grab control ($single true,
2018     # trace set appropriately, or we got a signal).
2019     if ( $explicit_stop || ( $trace & 1 ) ) {
2020         $obj->_DB__grab_control(@_);
2021     } ## end if ($single || ($trace...
2022
2023 =pod
2024
2025 If there's an action to be executed for the line we stopped at, execute it.
2026 If there are any preprompt actions, execute those as well.
2027
2028 =cut
2029
2030     # If there's an action, do it now.
2031     if ($action) {
2032         $evalarg = $action;
2033         DB::eval();
2034     }
2035
2036     # Are we nested another level (e.g., did we evaluate a function
2037     # that had a breakpoint in it at the debugger prompt)?
2038     if ( $single || $was_signal ) {
2039
2040         # Yes, go down a level.
2041         local $level = $level + 1;
2042
2043         # Do any pre-prompt actions.
2044         foreach $evalarg (@$pre) {
2045             DB::eval();
2046         }
2047
2048         # Complain about too much recursion if we passed the limit.
2049         if ($single & 4) {
2050             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2051         }
2052
2053         # The line we're currently on. Set $incr to -1 to stay here
2054         # until we get a command that tells us to advance.
2055         $start = $line;
2056         $incr  = -1;      # for backward motion.
2057
2058         # Tack preprompt debugger actions ahead of any actual input.
2059         @typeahead = ( @$pretype, @typeahead );
2060
2061 =head2 WHERE ARE WE?
2062
2063 XXX Relocate this section?
2064
2065 The debugger normally shows the line corresponding to the current line of
2066 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2067 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2068
2069 C<$incr> controls by how many lines the I<current> line should move forward
2070 after a command is executed. If set to -1, this indicates that the I<current>
2071 line shouldn't change.
2072
2073 C<$start> is the I<current> line. It is used for things like knowing where to
2074 move forwards or backwards from when doing an C<L> or C<-> command.
2075
2076 C<$max> tells the debugger where the last line of the current file is. It's
2077 used to terminate loops most often.
2078
2079 =head2 THE COMMAND LOOP
2080
2081 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2082 in two parts:
2083
2084 =over 4
2085
2086 =item *
2087
2088 The outer part of the loop, starting at the C<CMD> label. This loop
2089 reads a command and then executes it.
2090
2091 =item *
2092
2093 The inner part of the loop, starting at the C<PIPE> label. This part
2094 is wholly contained inside the C<CMD> block and only executes a command.
2095 Used to handle commands running inside a pager.
2096
2097 =back
2098
2099 So why have two labels to restart the loop? Because sometimes, it's easier to
2100 have a command I<generate> another command and then re-execute the loop to do
2101 the new command. This is faster, but perhaps a bit more convoluted.
2102
2103 =cut
2104
2105         # The big command dispatch loop. It keeps running until the
2106         # user yields up control again.
2107         #
2108         # If we have a terminal for input, and we get something back
2109         # from readline(), keep on processing.
2110         my $piped;
2111         my $selected;
2112
2113       CMD:
2114         while (_DB__read_next_cmd($tid))
2115         {
2116
2117             share($cmd);
2118             # ... try to execute the input as debugger commands.
2119
2120             # Don't stop running.
2121             $single = 0;
2122
2123             # No signal is active.
2124             $signal = 0;
2125
2126             # Handle continued commands (ending with \):
2127             if ($cmd =~ s/\\\z/\n/) {
2128                 $cmd .= DB::readline("  cont: ");
2129                 redo CMD;
2130             }
2131
2132 =head4 The null command
2133
2134 A newline entered by itself means I<re-execute the last command>. We grab the
2135 command out of C<$laststep> (where it was recorded previously), and copy it
2136 back into C<$cmd> to be executed below. If there wasn't any previous command,
2137 we'll do nothing below (no command will match). If there was, we also save it
2138 in the command history and fall through to allow the command parsing to pick
2139 it up.
2140
2141 =cut
2142
2143             # Empty input means repeat the last command.
2144             if ($cmd eq '') {
2145                 $cmd = $laststep;
2146             }
2147             chomp($cmd);    # get rid of the annoying extra newline
2148             if (length($cmd) >= 2) {
2149                 push( @hist, $cmd );
2150             }
2151             push( @truehist, $cmd );
2152             share(@hist);
2153             share(@truehist);
2154
2155             # This is a restart point for commands that didn't arrive
2156             # via direct user input. It allows us to 'redo PIPE' to
2157             # re-execute command processing without reading a new command.
2158           PIPE: {
2159                 my $i = _DB__trim_command_and_return_first_component();
2160
2161 =head3 COMMAND ALIASES
2162
2163 The debugger can create aliases for commands (these are stored in the
2164 C<%alias> hash). Before a command is executed, the command loop looks it up
2165 in the alias hash and substitutes the contents of the alias for the command,
2166 completely replacing it.
2167
2168 =cut
2169
2170                 # See if there's an alias for the command, and set it up if so.
2171                 if ( $alias{$i} ) {
2172
2173                     # Squelch signal handling; we want to keep control here
2174                     # if something goes loco during the alias eval.
2175                     local $SIG{__DIE__};
2176                     local $SIG{__WARN__};
2177
2178                     # This is a command, so we eval it in the DEBUGGER's
2179                     # scope! Otherwise, we can't see the special debugger
2180                     # variables, or get to the debugger's subs. (Well, we
2181                     # _could_, but why make it even more complicated?)
2182                     eval "\$cmd =~ $alias{$i}";
2183                     if ($@) {
2184                         local $\ = '';
2185                         print $OUT "Couldn't evaluate '$i' alias: $@";
2186                         next CMD;
2187                     }
2188                 } ## end if ($alias{$i})
2189
2190 =head3 MAIN-LINE COMMANDS
2191
2192 All of these commands work up to and after the program being debugged has
2193 terminated.
2194
2195 =head4 C<q> - quit
2196
2197 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2198 try to execute further, cleaning any restart-related stuff out of the
2199 environment, and executing with the last value of C<$?>.
2200
2201 =cut
2202
2203                 if ($cmd eq 'q') {
2204                     $fall_off_end = 1;
2205                     clean_ENV();
2206                     exit $?;
2207                 }
2208
2209 =head4 C<t> - trace [n]
2210
2211 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2212 If level is specified, set C<$trace_to_depth>.
2213
2214 =cut
2215
2216                 $obj->_handle_t_command;
2217
2218 =head4 C<S> - list subroutines matching/not matching a pattern
2219
2220 Walks through C<%sub>, checking to see whether or not to print the name.
2221
2222 =cut
2223
2224                 $obj->_handle_S_command;
2225
2226 =head4 C<X> - list variables in current package
2227
2228 Since the C<V> command actually processes this, just change this to the
2229 appropriate C<V> command and fall through.
2230
2231 =head4 C<V> - list variables
2232
2233 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2234
2235 =cut
2236
2237                 $obj->_handle_V_command_and_X_command;
2238
2239 =head4 C<x> - evaluate and print an expression
2240
2241 Hands the expression off to C<DB::eval>, setting it up to print the value
2242 via C<dumpvar.pl> instead of just printing it directly.
2243
2244 =cut
2245
2246                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2247                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2248
2249                     # handle special  "x 3 blah" syntax XXX propagate
2250                     # doc back to special variables.
2251                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2252                         $onetimedumpDepth = $1;
2253                     }
2254                 }
2255
2256 =head4 C<m> - print methods
2257
2258 Just uses C<DB::methods> to determine what methods are available.
2259
2260 =cut
2261
2262                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2263                     methods($1);
2264                     next CMD;
2265                 }
2266
2267                 # m expr - set up DB::eval to do the work
2268                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2269                     $onetimeDump = 'methods';   #  method output gets used there
2270                 }
2271
2272 =head4 C<f> - switch files
2273
2274 =cut
2275
2276                 _DB__handle_f_command();
2277
2278 =head4 C<.> - return to last-executed line.
2279
2280 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2281 and then we look up the line in the magical C<%dbline> hash.
2282
2283 =cut
2284
2285                 # . command.
2286                 if ($cmd eq '.') {
2287                     $incr = -1;    # stay at current line
2288
2289                     # Reset everything to the old location.
2290                     $start    = $line;
2291                     $filename = $filename_ini;
2292                     *dbline   = $main::{ '_<' . $filename };
2293                     $max      = $#dbline;
2294
2295                     # Now where are we?
2296                     print_lineinfo($position);
2297                     next CMD;
2298                 }
2299
2300 =head4 C<-> - back one window
2301
2302 We change C<$start> to be one window back; if we go back past the first line,
2303 we set it to be the first line. We ser C<$incr> to put us back at the
2304 currently-executing line, and then put a C<l $start +> (list one window from
2305 C<$start>) in C<$cmd> to be executed later.
2306
2307 =cut
2308
2309                 # - - back a window.
2310                 if ($cmd eq '-') {
2311
2312                     # back up by a window; go to 1 if back too far.
2313                     $start -= $incr + $window + 1;
2314                     $start = 1 if $start <= 0;
2315                     $incr  = $window - 1;
2316
2317                     # Generate and execute a "l +" command (handled below).
2318                     $cmd = 'l ' . ($start) . '+';
2319                 }
2320
2321 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2322
2323 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2324 problems, most notably that the default case of several commands destroying
2325 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2326 retain the old commands for those who were used to using them or who preferred
2327 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2328 deal with them instead of processing them in-line.
2329
2330 =cut
2331
2332                 # All of these commands were remapped in perl 5.8.0;
2333                 # we send them off to the secondary dispatcher (see below).
2334                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2335                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2336                     next CMD;
2337                 }
2338
2339 =head4 C<y> - List lexicals in higher scope
2340
2341 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2342 above the current one and then displays then using C<dumpvar.pl>.
2343
2344 =cut
2345
2346                 if (my ($match_level, $match_vars)
2347                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2348
2349                     # See if we've got the necessary support.
2350                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2351                       or &warn(
2352                         $@ =~ /locate/
2353                         ? "PadWalker module not found - please install\n"
2354                         : $@
2355                       )
2356                       and next CMD;
2357
2358                     # Load up dumpvar if we don't have it. If we can, that is.
2359                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2360                     defined &main::dumpvar
2361                       or print $OUT "dumpvar.pl not available.\n"
2362                       and next CMD;
2363
2364                     # Got all the modules we need. Find them and print them.
2365                     my @vars = split( ' ', $match_vars || '' );
2366
2367                     # Find the pad.
2368                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2369
2370                     # Oops. Can't find it.
2371                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2372
2373                     # Show the desired vars with dumplex().
2374                     my $savout = select($OUT);
2375
2376                     # Have dumplex dump the lexicals.
2377                     dumpvar::dumplex( $_, $h->{$_},
2378                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2379                         @vars )
2380                       for sort keys %$h;
2381                     select($savout);
2382                     next CMD;
2383                 }
2384
2385 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2386
2387 All of the commands below this point don't work after the program being
2388 debugged has ended. All of them check to see if the program has ended; this
2389 allows the commands to be relocated without worrying about a 'line of
2390 demarcation' above which commands can be entered anytime, and below which
2391 they can't.
2392
2393 =head4 C<n> - single step, but don't trace down into subs
2394
2395 Done by setting C<$single> to 2, which forces subs to execute straight through
2396 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2397 so a null command knows what to re-execute.
2398
2399 =cut
2400
2401                 # n - next
2402                 if ($cmd eq 'n') {
2403                     next CMD if _DB__is_finished();
2404
2405                     # Single step, but don't enter subs.
2406                     $single = 2;
2407
2408                     # Save for empty command (repeat last).
2409                     $laststep = $cmd;
2410                     last CMD;
2411                 }
2412
2413 =head4 C<s> - single-step, entering subs
2414
2415 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2416 subs. Also saves C<s> as C<$lastcmd>.
2417
2418 =cut
2419
2420                 # s - single step.
2421                 if ($cmd eq 's') {
2422
2423                     # Get out and restart the command loop if program
2424                     # has finished.
2425                     next CMD if _DB__is_finished();
2426
2427                     # Single step should enter subs.
2428                     $single = 1;
2429
2430                     # Save for empty command (repeat last).
2431                     $laststep = $cmd;
2432                     last CMD;
2433                 }
2434
2435 =head4 C<c> - run continuously, setting an optional breakpoint
2436
2437 Most of the code for this command is taken up with locating the optional
2438 breakpoint, which is either a subroutine name or a line number. We set
2439 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2440 in this and all call levels above this one.
2441
2442 =cut
2443
2444                 # c - start continuous execution.
2445                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2446
2447                     # Hey, show's over. The debugged program finished
2448                     # executing already.
2449                     next CMD if _DB__is_finished();
2450
2451                     # Capture the place to put a one-time break.
2452                     $subname = $i;
2453
2454                     #  Probably not needed, since we finish an interactive
2455                     #  sub-session anyway...
2456                     # local $filename = $filename;
2457                     # local *dbline = *dbline; # XXX Would this work?!
2458                     #
2459                     # The above question wonders if localizing the alias
2460                     # to the magic array works or not. Since it's commented
2461                     # out, we'll just leave that to speculation for now.
2462
2463                     # If the "subname" isn't all digits, we'll assume it
2464                     # is a subroutine name, and try to find it.
2465                     if ( $subname =~ /\D/ ) {    # subroutine name
2466                             # Qualify it to the current package unless it's
2467                             # already qualified.
2468                         $subname = $package . "::" . $subname
2469                           unless $subname =~ /::/;
2470
2471                         # find_sub will return "file:line_number" corresponding
2472                         # to where the subroutine is defined; we call find_sub,
2473                         # break up the return value, and assign it in one
2474                         # operation.
2475                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2476
2477                         # Force the line number to be numeric.
2478                         $i += 0;
2479
2480                         # If we got a line number, we found the sub.
2481                         if ($i) {
2482
2483                             # Switch all the debugger's internals around so
2484                             # we're actually working with that file.
2485                             $filename = $file;
2486                             *dbline   = $main::{ '_<' . $filename };
2487
2488                             # Mark that there's a breakpoint in this file.
2489                             $had_breakpoints{$filename} |= 1;
2490
2491                             # Scan forward to the first executable line
2492                             # after the 'sub whatever' line.
2493                             $max = $#dbline;
2494                             ++$i while $dbline[$i] == 0 && $i < $max;
2495                         } ## end if ($i)
2496
2497                         # We didn't find a sub by that name.
2498                         else {
2499                             print $OUT "Subroutine $subname not found.\n";
2500                             next CMD;
2501                         }
2502                     } ## end if ($subname =~ /\D/)
2503
2504                     # At this point, either the subname was all digits (an
2505                     # absolute line-break request) or we've scanned through
2506                     # the code following the definition of the sub, looking
2507                     # for an executable, which we may or may not have found.
2508                     #
2509                     # If $i (which we set $subname from) is non-zero, we
2510                     # got a request to break at some line somewhere. On
2511                     # one hand, if there wasn't any real subroutine name
2512                     # involved, this will be a request to break in the current
2513                     # file at the specified line, so we have to check to make
2514                     # sure that the line specified really is breakable.
2515                     #
2516                     # On the other hand, if there was a subname supplied, the
2517                     # preceding block has moved us to the proper file and
2518                     # location within that file, and then scanned forward
2519                     # looking for the next executable line. We have to make
2520                     # sure that one was found.
2521                     #
2522                     # On the gripping hand, we can't do anything unless the
2523                     # current value of $i points to a valid breakable line.
2524                     # Check that.
2525                     if ($i) {
2526
2527                         # Breakable?
2528                         if ( $dbline[$i] == 0 ) {
2529                             print $OUT "Line $i not breakable.\n";
2530                             next CMD;
2531                         }
2532
2533                         # Yes. Set up the one-time-break sigil.
2534                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2535                         _enable_breakpoint_temp_enabled_status($filename, $i);
2536                     } ## end if ($i)
2537
2538                     # Turn off stack tracing from here up.
2539                     for my $i (0 .. $stack_depth) {
2540                         $stack[ $i ] &= ~1;
2541                     }
2542                     last CMD;
2543                 }
2544
2545 =head4 C<r> - return from a subroutine
2546
2547 For C<r> to work properly, the debugger has to stop execution again
2548 immediately after the return is executed. This is done by forcing
2549 single-stepping to be on in the call level above the current one. If
2550 we are printing return values when a C<r> is executed, set C<$doret>
2551 appropriately, and force us out of the command loop.
2552
2553 =cut
2554
2555                 # r - return from the current subroutine.
2556                 if ($cmd eq 'r') {
2557
2558                     # Can't do anything if the program's over.
2559                     next CMD if _DB__is_finished();
2560
2561                     # Turn on stack trace.
2562                     $stack[$stack_depth] |= 1;
2563
2564                     # Print return value unless the stack is empty.
2565                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2566                     last CMD;
2567                 }
2568
2569 =head4 C<T> - stack trace
2570
2571 Just calls C<DB::print_trace>.
2572
2573 =cut
2574
2575                 if ($cmd eq 'T') {
2576                     print_trace( $OUT, 1 );    # skip DB
2577                     next CMD;
2578                 }
2579
2580 =head4 C<w> - List window around current line.
2581
2582 Just calls C<DB::cmd_w>.
2583
2584 =cut
2585
2586                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2587                     &cmd_w( 'w', $arg );
2588                     next CMD;
2589                 }
2590
2591 =head4 C<W> - watch-expression processing.
2592
2593 Just calls C<DB::cmd_W>.
2594
2595 =cut
2596
2597                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2598                     &cmd_W( 'W', $arg );
2599                     next CMD;
2600                 }
2601
2602 =head4 C</> - search forward for a string in the source
2603
2604 We take the argument and treat it as a pattern. If it turns out to be a
2605 bad one, we return the error we got from trying to C<eval> it and exit.
2606 If not, we create some code to do the search and C<eval> it so it can't
2607 mess us up.
2608
2609 =cut
2610
2611                 # The pattern as a string.
2612                 use vars qw($inpat);
2613
2614                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2615
2616                     # Remove the final slash.
2617                     $inpat =~ s:([^\\])/$:$1:;
2618
2619                     # If the pattern isn't null ...
2620                     if ( $inpat ne "" ) {
2621
2622                         # Turn of warn and die procesing for a bit.
2623                         local $SIG{__DIE__};
2624                         local $SIG{__WARN__};
2625
2626                         # Create the pattern.
2627                         eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2628                         if ( $@ ne "" ) {
2629
2630                             # Oops. Bad pattern. No biscuit.
2631                             # Print the eval error and go back for more
2632                             # commands.
2633                             print $OUT "$@";
2634                             next CMD;
2635                         }
2636                         $pat = $inpat;
2637                     } ## end if ($inpat ne "")
2638
2639                     # Set up to stop on wrap-around.
2640                     $end = $start;
2641
2642                     # Don't move off the current line.
2643                     $incr = -1;
2644
2645                     # Done in eval so nothing breaks if the pattern
2646                     # does something weird.
2647                     eval '
2648                         no strict q/vars/;
2649                         for (;;) {
2650                             # Move ahead one line.
2651                             ++$start;
2652
2653                             # Wrap if we pass the last line.
2654                             $start = 1 if ($start > $max);
2655
2656                             # Stop if we have gotten back to this line again,
2657                             last if ($start == $end);
2658
2659                             # A hit! (Note, though, that we are doing
2660                             # case-insensitive matching. Maybe a qr//
2661                             # expression would be better, so the user could
2662                             # do case-sensitive matching if desired.
2663                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2664                                 if ($slave_editor) {
2665                                     # Handle proper escaping in the slave.
2666                                     print $OUT "\032\032$filename:$start:0\n";
2667                                 }
2668                                 else {
2669                                     # Just print the line normally.
2670                                     print $OUT "$start:\t",$dbline[$start],"\n";
2671                                 }
2672                                 # And quit since we found something.
2673                                 last;
2674                             }
2675                          } ';
2676
2677                     # If we wrapped, there never was a match.
2678                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2679                     next CMD;
2680                 }
2681
2682 =head4 C<?> - search backward for a string in the source
2683
2684 Same as for C</>, except the loop runs backwards.
2685
2686 =cut
2687
2688                 # ? - backward pattern search.
2689                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2690
2691                     # Get the pattern, remove trailing question mark.
2692                     $inpat =~ s:([^\\])\?$:$1:;
2693
2694                     # If we've got one ...
2695                     if ( $inpat ne "" ) {
2696
2697                         # Turn off die & warn handlers.
2698                         local $SIG{__DIE__};
2699                         local $SIG{__WARN__};
2700                         eval '$inpat =~ m' . "\a$inpat\a";
2701
2702                         if ( $@ ne "" ) {
2703
2704                             # Ouch. Not good. Print the error.
2705                             print $OUT $@;
2706                             next CMD;
2707                         }
2708                         $pat = $inpat;
2709                     } ## end if ($inpat ne "")
2710
2711                     # Where we are now is where to stop after wraparound.
2712                     $end = $start;
2713
2714                     # Don't move away from this line.
2715                     $incr = -1;
2716
2717                     # Search inside the eval to prevent pattern badness
2718                     # from killing us.
2719                     eval '
2720                         no strict q/vars/;
2721                         for (;;) {
2722                             # Back up a line.
2723                             --$start;
2724
2725                             # Wrap if we pass the first line.
2726
2727                             $start = $max if ($start <= 0);
2728
2729                             # Quit if we get back where we started,
2730                             last if ($start == $end);
2731
2732                             # Match?
2733                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2734                                 if ($slave_editor) {
2735                                     # Yep, follow slave editor requirements.
2736                                     print $OUT "\032\032$filename:$start:0\n";
2737                                 }
2738                                 else {
2739                                     # Yep, just print normally.
2740                                     print $OUT "$start:\t",$dbline[$start],"\n";
2741                                 }
2742
2743                                 # Found, so done.
2744                                 last;
2745                             }
2746                         } ';
2747
2748                     # Say we failed if the loop never found anything,
2749                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2750                     next CMD;
2751                 }
2752
2753 =head4 C<$rc> - Recall command
2754
2755 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2756 that the terminal supports history). It find the the command required, puts it
2757 into C<$cmd>, and redoes the loop to execute it.
2758
2759 =cut
2760
2761                 # $rc - recall command.
2762                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2763
2764                     # No arguments, take one thing off history.
2765                     pop(@hist) if length($cmd) > 1;
2766
2767                     # Relative (- found)?
2768                     #  Y - index back from most recent (by 1 if bare minus)
2769                     #  N - go to that particular command slot or the last
2770                     #      thing if nothing following.
2771                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2772
2773                     # Pick out the command desired.
2774                     $cmd = $hist[$i];
2775
2776                     # Print the command to be executed and restart the loop
2777                     # with that command in the buffer.
2778                     print $OUT $cmd, "\n";
2779                     redo CMD;
2780                 }
2781
2782 =head4 C<$sh$sh> - C<system()> command
2783
2784 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2785 C<STDOUT> from getting messed up.
2786
2787 =cut
2788
2789                 # $sh$sh - run a shell command (if it's all ASCII).
2790                 # Can't run shell commands with Unicode in the debugger, hmm.
2791                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2792
2793                     # System it.
2794                     &system($arg);
2795                     next CMD;
2796                 }
2797
2798 =head4 C<$rc I<pattern> $rc> - Search command history
2799
2800 Another command to manipulate C<@hist>: this one searches it with a pattern.
2801 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2802
2803 =cut
2804
2805                 # $rc pattern $rc - find a command in the history.
2806                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2807
2808                     # Create the pattern to use.
2809                     $pat = "^$arg";
2810
2811                     # Toss off last entry if length is >1 (and it always is).
2812                     pop(@hist) if length($cmd) > 1;
2813
2814                     # Look backward through the history.
2815                     for ( $i = $#hist ; $i ; --$i ) {
2816                         # Stop if we find it.
2817                         last if $hist[$i] =~ /$pat/;
2818                     }
2819
2820                     if ( !$i ) {
2821
2822                         # Never found it.
2823                         print $OUT "No such command!\n\n";
2824                         next CMD;
2825                     }
2826
2827                     # Found it. Put it in the buffer, print it, and process it.
2828                     $cmd = $hist[$i];
2829                     print $OUT $cmd, "\n";
2830                     redo CMD;
2831                 }
2832
2833 =head4 C<$sh> - Invoke a shell
2834
2835 Uses C<DB::system> to invoke a shell.
2836
2837 =cut
2838
2839                 # $sh - start a shell.
2840                 if ($cmd =~ /\A$sh\z/) {
2841
2842                     # Run the user's shell. If none defined, run Bourne.
2843                     # We resume execution when the shell terminates.
2844                     &system( $ENV{SHELL} || "/bin/sh" );
2845                     next CMD;
2846                 }
2847
2848 =head4 C<$sh I<command>> - Force execution of a command in a shell
2849
2850 Like the above, but the command is passed to the shell. Again, we use
2851 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2852
2853 =cut
2854
2855                 # $sh command - start a shell and run a command in it.
2856                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
2857
2858                     # XXX: using csh or tcsh destroys sigint retvals!
2859                     #&system($1);  # use this instead
2860
2861                     # use the user's shell, or Bourne if none defined.
2862                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
2863                     next CMD;
2864                 }
2865
2866 =head4 C<H> - display commands in history
2867
2868 Prints the contents of C<@hist> (if any).
2869
2870 =cut
2871
2872                 if ($cmd =~ /\AH\b\s*\*/) {
2873                     @hist = @truehist = ();
2874                     print $OUT "History cleansed\n";
2875                     next CMD;
2876                 }
2877
2878                 if (my ($num)
2879                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
2880
2881                     # Anything other than negative numbers is ignored by
2882                     # the (incorrect) pattern, so this test does nothing.
2883                     $end = $num ? ( $#hist - $num ) : 0;
2884
2885                     # Set to the minimum if less than zero.
2886                     $hist = 0 if $hist < 0;
2887
2888                     # Start at the end of the array.
2889                     # Stay in while we're still above the ending value.
2890                     # Tick back by one each time around the loop.
2891                     for ( $i = $#hist ; $i > $end ; $i-- ) {
2892
2893                         # Print the command  unless it has no arguments.
2894                         print $OUT "$i: ", $hist[$i], "\n"
2895                           unless $hist[$i] =~ /^.?$/;
2896                     }
2897                     next CMD;
2898                 }
2899
2900 =head4 C<man, doc, perldoc> - look up documentation
2901
2902 Just calls C<runman()> to print the appropriate document.
2903
2904 =cut
2905
2906                 # man, perldoc, doc - show manual pages.
2907                 if (my ($man_page)
2908                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
2909                     runman($man_page);
2910                     next CMD;
2911                 }
2912
2913 =head4 C<p> - print
2914
2915 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2916 the bottom of the loop.
2917
2918 =cut
2919
2920                 my $print_cmd = 'print {$DB::OUT} ';
2921                 # p - print (no args): print $_.
2922                 if ($cmd eq 'p') {
2923                     $cmd = $print_cmd . '$_';
2924                 }
2925
2926                 # p - print the given expression.
2927                 $cmd =~ s/\Ap\b/$print_cmd /;
2928
2929 =head4 C<=> - define command alias
2930
2931 Manipulates C<%alias> to add or list command aliases.
2932
2933 =cut
2934
2935                 # = - set up a command alias.
2936                 if ($cmd =~ s/\A=\s*//) {
2937                     my @keys;
2938                     if ( length $cmd == 0 ) {
2939
2940                         # No args, get current aliases.
2941                         @keys = sort keys %alias;
2942                     }
2943                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
2944
2945                         # Creating a new alias. $k is alias name, $v is
2946                         # alias value.
2947
2948                         # can't use $_ or kill //g state
2949                         for my $x ( $k, $v ) {
2950
2951                             # Escape "alarm" characters.
2952                             $x =~ s/\a/\\a/g;
2953                         }
2954
2955                         # Substitute key for value, using alarm chars
2956                         # as separators (which is why we escaped them in
2957                         # the command).
2958                         $alias{$k} = "s\a$k\a$v\a";
2959
2960                         # Turn off standard warn and die behavior.
2961                         local $SIG{__DIE__};
2962                         local $SIG{__WARN__};
2963
2964                         # Is it valid Perl?
2965                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
2966
2967                             # Nope. Bad alias. Say so and get out.
2968                             print $OUT "Can't alias $k to $v: $@\n";
2969                             delete $alias{$k};
2970                             next CMD;
2971                         }
2972
2973                         # We'll only list the new one.
2974                         @keys = ($k);
2975                     } ## end elsif (my ($k, $v) = ($cmd...
2976
2977                     # The argument is the alias to list.
2978                     else {
2979                         @keys = ($cmd);
2980                     }
2981
2982                     # List aliases.
2983                     for my $k (@keys) {
2984
2985                         # Messy metaquoting: Trim the substitution code off.
2986                         # We use control-G as the delimiter because it's not
2987                         # likely to appear in the alias.
2988                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
2989
2990                             # Print the alias.
2991                             print $OUT "$k\t= $1\n";
2992                         }
2993                         elsif ( defined $alias{$k} ) {
2994
2995                             # Couldn't trim it off; just print the alias code.
2996                             print $OUT "$k\t$alias{$k}\n";
2997                         }
2998                         else {
2999
3000                             # No such, dude.
3001                             print "No alias for $k\n";
3002                         }
3003                     } ## end for my $k (@keys)
3004                     next CMD;
3005                 }
3006
3007 =head4 C<source> - read commands from a file.
3008
3009 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3010 pick it up.
3011
3012 =cut
3013
3014                 # source - read commands from a file (or pipe!) and execute.
3015                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3016                     if ( open my $fh, $sourced_fn ) {
3017
3018                         # Opened OK; stick it in the list of file handles.
3019                         push @cmdfhs, $fh;
3020                     }
3021                     else {
3022
3023                         # Couldn't open it.
3024                         &warn("Can't execute '$sourced_fn': $!\n");
3025                     }
3026                     next CMD;
3027                 }
3028
3029                 if (my ($which_cmd, $position)
3030                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3031
3032                     my ($fn, $line_num);
3033                     if ($position =~ m{\A\d+\z})
3034                     {
3035                         $fn = $filename;
3036                         $line_num = $position;
3037                     }
3038                     elsif (my ($new_fn, $new_line_num)
3039                         = $position =~ m{\A(.*):(\d+)\z}) {
3040                         ($fn, $line_num) = ($new_fn, $new_line_num);
3041                     }
3042                     else
3043                     {
3044                         &warn("Wrong spec for enable/disable argument.\n");
3045                     }
3046
3047                     if (defined($fn)) {
3048                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3049                             _set_breakpoint_enabled_status($fn, $line_num,
3050                                 ($which_cmd eq 'enable' ? 1 : '')
3051                             );
3052                         }
3053                         else {
3054                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3055                         }
3056                     }
3057
3058                     next CMD;
3059                 }
3060
3061 =head4 C<save> - send current history to a file
3062
3063 Takes the complete history, (not the shrunken version you see with C<H>),
3064 and saves it to the given filename, so it can be replayed using C<source>.
3065
3066 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3067
3068 =cut
3069
3070                 # save source - write commands to a file for later use
3071                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3072                     my $filename = $new_fn || '.perl5dbrc';    # default?
3073                     if ( open my $fh, '>', $filename ) {
3074
3075                        # chomp to remove extraneous newlines from source'd files
3076                         chomp( my @truelist =
3077                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3078                               @truehist );
3079                         print $fh join( "\n", @truelist );
3080                         print "commands saved in $file\n";
3081                     }
3082                     else {
3083                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3084                     }
3085                     next CMD;
3086                 }
3087
3088 =head4 C<R> - restart
3089
3090 Restart the debugger session.
3091
3092 =head4 C<rerun> - rerun the current session
3093
3094 Return to any given position in the B<true>-history list
3095
3096 =cut
3097
3098                 # R - restart execution.
3099                 # rerun - controlled restart execution.
3100                 if (my ($cmd_cmd, $cmd_params) =
3101                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3102                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3103
3104                     # Close all non-system fds for a clean restart.  A more
3105                     # correct method would be to close all fds that were not
3106                     # open when the process started, but this seems to be
3107                     # hard.  See "debugger 'R'estart and open database
3108                     # connections" on p5p.
3109
3110                     my $max_fd = 1024; # default if POSIX can't be loaded
3111                     if (eval { require POSIX }) {
3112                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3113                     }
3114
3115                     if (defined $max_fd) {
3116                         foreach ($^F+1 .. $max_fd-1) {
3117                             next unless open FD_TO_CLOSE, "<&=$_";
3118                             close(FD_TO_CLOSE);
3119                         }
3120                     }
3121
3122                     # And run Perl again.  We use exec() to keep the
3123                     # PID stable (and that way $ini_pids is still valid).
3124                     exec(@args) || print $OUT "exec failed: $!\n";
3125
3126                     last CMD;
3127                 }
3128
3129 =head4 C<|, ||> - pipe output through the pager.
3130
3131 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3132 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3133 pipe to the pager (restoring the output filehandles if this fails). If this
3134 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3135 set C<$signal>, sending us back into the debugger.
3136
3137 We then trim off the pipe symbols and C<redo> the command loop at the
3138 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3139 reading another.
3140
3141 =cut
3142
3143                 # || - run command in the pager, with output to DB::OUT.
3144                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3145                     if ( $pager =~ /^\|/ ) {
3146
3147                         # Default pager is into a pipe. Redirect I/O.
3148                         open( SAVEOUT, ">&STDOUT" )
3149                           || &warn("Can't save STDOUT");
3150                         open( STDOUT, ">&OUT" )
3151                           || &warn("Can't redirect STDOUT");
3152                     } ## end if ($pager =~ /^\|/)
3153                     else {
3154
3155                         # Not into a pipe. STDOUT is safe.
3156                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3157                     }
3158
3159                     # Fix up environment to record we have less if so.
3160                     fix_less();
3161
3162                     unless ( $piped = open( OUT, $pager ) ) {
3163
3164                         # Couldn't open pipe to pager.
3165                         &warn("Can't pipe output to '$pager'");
3166                         if ( $pager =~ /^\|/ ) {
3167
3168                             # Redirect I/O back again.
3169                             open( OUT, ">&STDOUT" )    # XXX: lost message
3170                               || &warn("Can't restore DB::OUT");
3171                             open( STDOUT, ">&SAVEOUT" )
3172                               || &warn("Can't restore STDOUT");
3173                             close(SAVEOUT);
3174                         } ## end if ($pager =~ /^\|/)
3175                         else {
3176
3177                             # Redirect I/O. STDOUT already safe.
3178                             open( OUT, ">&STDOUT" )    # XXX: lost message
3179                               || &warn("Can't restore DB::OUT");
3180                         }
3181                         next CMD;
3182                     } ## end unless ($piped = open(OUT,...
3183
3184                     # Set up broken-pipe handler if necessary.
3185                     $SIG{PIPE} = \&DB::catch
3186                       if $pager =~ /^\|/
3187                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3188
3189                     OUT->autoflush(1);
3190                     # Save current filehandle, and put it back.
3191                     $selected = select(OUT);
3192                     # Don't put it back if pager was a pipe.
3193                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3194
3195                     # Trim off the pipe symbols and run the command now.
3196                     $cmd =~ s#\A\|+\s*##;
3197                     redo PIPE;
3198                 }
3199
3200 =head3 END OF COMMAND PARSING
3201
3202 Anything left in C<$cmd> at this point is a Perl expression that we want to
3203 evaluate. We'll always evaluate in the user's context, and fully qualify
3204 any variables we might want to address in the C<DB> package.
3205
3206 =cut
3207
3208                 # t - turn trace on.
3209                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3210                     my $trace_arg = $1;
3211                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3212                 }
3213
3214                 # s - single-step. Remember the last command was 's'.
3215                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3216                     $laststep = 's';
3217                 }
3218
3219                 # n - single-step, but not into subs. Remember last command
3220                 # was 'n'.
3221                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3222                     $laststep = 'n';
3223                 }
3224
3225             }    # PIPE:
3226
3227             # Make sure the flag that says "the debugger's running" is
3228             # still on, to make sure we get control again.
3229             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3230
3231             # Run *our* eval that executes in the caller's context.
3232             DB::eval();
3233
3234             # Turn off the one-time-dump stuff now.
3235             if ($onetimeDump) {
3236                 $onetimeDump      = undef;
3237                 $onetimedumpDepth = undef;
3238             }
3239             elsif ( $term_pid == $$ ) {
3240                 eval { # May run under miniperl, when not available...
3241                     STDOUT->flush();
3242                     STDERR->flush();
3243                 };
3244
3245                 # XXX If this is the master pid, print a newline.
3246                 print {$OUT} "\n";
3247             }
3248         } ## end while (($term || &setterm...
3249
3250 =head3 POST-COMMAND PROCESSING
3251
3252 After each command, we check to see if the command output was piped anywhere.
3253 If so, we go through the necessary code to unhook the pipe and go back to
3254 our standard filehandles for input and output.
3255
3256 =cut
3257
3258         continue {    # CMD:
3259
3260             # At the end of every command:
3261             if ($piped) {
3262
3263                 # Unhook the pipe mechanism now.
3264                 if ( $pager =~ /^\|/ ) {
3265
3266                     # No error from the child.
3267                     $? = 0;
3268
3269                     # we cannot warn here: the handle is missing --tchrist
3270                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3271
3272                     # most of the $? crud was coping with broken cshisms
3273                     # $? is explicitly set to 0, so this never runs.
3274                     if ($?) {
3275                         print SAVEOUT "Pager '$pager' failed: ";
3276                         if ( $? == -1 ) {
3277                             print SAVEOUT "shell returned -1\n";
3278                         }
3279                         elsif ( $? >> 8 ) {
3280                             print SAVEOUT ( $? & 127 )
3281                               ? " (SIG#" . ( $? & 127 ) . ")"
3282                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3283                         }
3284                         else {
3285                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3286                         }
3287                     } ## end if ($?)
3288
3289                     # Reopen filehandle for our output (if we can) and
3290                     # restore STDOUT (if we can).
3291                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3292                     open( STDOUT, ">&SAVEOUT" )
3293                       || &warn("Can't restore STDOUT");
3294
3295                     # Turn off pipe exception handler if necessary.
3296                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3297
3298                     # Will stop ignoring SIGPIPE if done like nohup(1)
3299                     # does SIGINT but Perl doesn't give us a choice.
3300                 } ## end if ($pager =~ /^\|/)
3301                 else {
3302
3303                     # Non-piped "pager". Just restore STDOUT.
3304                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3305                 }
3306
3307                 # Close filehandle pager was using, restore the normal one
3308                 # if necessary,
3309                 close(SAVEOUT);
3310                 select($selected), $selected = "" unless $selected eq "";
3311
3312                 # No pipes now.
3313                 $piped = "";
3314             } ## end if ($piped)
3315         }    # CMD:
3316
3317 =head3 COMMAND LOOP TERMINATION
3318
3319 When commands have finished executing, we come here. If the user closed the
3320 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3321 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3322 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3323 The interpreter will then execute the next line and then return control to us
3324 again.
3325
3326 =cut
3327
3328         # No more commands? Quit.
3329         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3330
3331         # Evaluate post-prompt commands.
3332         foreach $evalarg (@$post) {
3333             DB::eval();
3334         }
3335     }    # if ($single || $signal)
3336
3337     # Put the user's globals back where you found them.
3338     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3339     ();
3340 } ## end sub DB
3341
3342 package DB::Obj;
3343
3344 sub new {
3345     my $class = shift;
3346
3347     my $self = bless {}, $class;
3348
3349     $self->_init(@_);
3350
3351     return $self;
3352 }
3353
3354 sub _init {
3355     my ($self, $args) = @_;
3356
3357     %{$self} = (%$self, %$args);
3358
3359     return;
3360 }
3361
3362 {
3363     no strict 'refs';
3364     foreach my $slot_name (qw(after explicit_stop infix position prefix)) {
3365         my $slot = $slot_name;
3366         *{$slot} = sub {
3367             my $self = shift;
3368
3369             if (@_) {
3370                 ${ $self->{$slot} } = shift;
3371             }
3372
3373             return ${ $self->{$slot} };
3374         };
3375
3376         *{"append_to_$slot"} = sub {
3377             my $self = shift;
3378             my $s = shift;
3379
3380             return $self->$slot($self->$slot . $s);
3381         };
3382     }
3383 }
3384
3385 sub _DB_on_init__initialize_globals
3386 {
3387     my $self = shift;
3388
3389     # Check for whether we should be running continuously or not.
3390     # _After_ the perl program is compiled, $single is set to 1:
3391     if ( $single and not $second_time++ ) {
3392
3393         # Options say run non-stop. Run until we get an interrupt.
3394         if ($runnonstop) {    # Disable until signal
3395                 # If there's any call stack in place, turn off single
3396                 # stepping into subs throughout the stack.
3397             for my $i (0 .. $stack_depth) {
3398                 $stack[ $i ] &= ~1;
3399             }
3400
3401             # And we are now no longer in single-step mode.
3402             $single = 0;
3403
3404             # If we simply returned at this point, we wouldn't get
3405             # the trace info. Fall on through.
3406             # return;
3407         } ## end if ($runnonstop)
3408
3409         elsif ($ImmediateStop) {
3410
3411             # We are supposed to stop here; XXX probably a break.
3412             $ImmediateStop = 0;    # We've processed it; turn it off
3413             $signal        = 1;    # Simulate an interrupt to force
3414                                    # us into the command loop
3415         }
3416     } ## end if ($single and not $second_time...
3417
3418     # If we're in single-step mode, or an interrupt (real or fake)
3419     # has occurred, turn off non-stop mode.
3420     $runnonstop = 0 if $single or $signal;
3421
3422     return;
3423 }
3424
3425 sub _DB__handle_watch_expressions
3426 {
3427     my $self = shift;
3428
3429     if ( $trace & 2 ) {
3430         for my $n (0 .. $#to_watch) {
3431             $evalarg = $to_watch[$n];
3432             local $onetimeDump;    # Tell DB::eval() to not output results
3433
3434             # Fix context DB::eval() wants to return an array, but
3435             # we need a scalar here.
3436             my ($val) = join( "', '", DB::eval() );
3437             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3438
3439             # Did it change?
3440             if ( $val ne $old_watch[$n] ) {
3441
3442                 # Yep! Show the difference, and fake an interrupt.
3443                 $signal = 1;
3444                 print {$OUT} <<EOP;
3445 Watchpoint $n:\t$to_watch[$n] changed:
3446     old value:\t$old_watch[$n]
3447     new value:\t$val
3448 EOP
3449                 $old_watch[$n] = $val;
3450             } ## end if ($val ne $old_watch...
3451         } ## end for my $n (0 ..
3452     } ## end if ($trace & 2)
3453
3454     return;
3455 }
3456
3457 sub _my_print_lineinfo
3458 {
3459     my ($self, $i, $incr_pos) = @_;
3460
3461     if ($frame) {
3462         # Print it indented if tracing is on.
3463         DB::print_lineinfo( ' ' x $stack_depth,
3464             "$i:\t$DB::dbline[$i]" . $self->after );
3465     }
3466     else {
3467         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3468     }
3469 }
3470
3471 sub _curr_line {
3472     return $DB::dbline[$line];
3473 }
3474
3475 sub _DB__grab_control
3476 {
3477     my $self = shift;
3478
3479     # Yes, grab control.
3480     if ($slave_editor) {
3481
3482         # Tell the editor to update its position.
3483         $self->position("\032\032${DB::filename}:$line:0\n");
3484         DB::print_lineinfo($self->position());
3485     }
3486
3487 =pod
3488
3489 Special check: if we're in package C<DB::fake>, we've gone through the
3490 C<END> block at least once. We set up everything so that we can continue
3491 to enter commands and have a valid context to be in.
3492
3493 =cut
3494
3495     elsif ( $DB::package eq 'DB::fake' ) {
3496
3497         # Fallen off the end already.
3498         if (!$DB::term) {
3499             DB::setterm();
3500         }
3501
3502         DB::print_help(<<EOP);
3503 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3504 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3505 B<h q>, B<h R> or B<h o> to get additional info.
3506 EOP
3507
3508         # Set the DB::eval context appropriately.
3509         $DB::package     = 'main';
3510         $DB::usercontext = DB::_calc_usercontext($DB::package);
3511     } ## end elsif ($package eq 'DB::fake')
3512
3513 =pod
3514
3515 If the program hasn't finished executing, we scan forward to the
3516 next executable line, print that out, build the prompt from the file and line
3517 number information, and print that.
3518
3519 =cut
3520
3521     else {
3522
3523
3524         # Still somewhere in the midst of execution. Set up the
3525         #  debugger prompt.
3526         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3527                              # Perl 5 ones (sorry, we don't print Klingon
3528                              #module names)
3529
3530         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3531         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3532         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3533
3534         # Break up the prompt if it's really long.
3535         if ( length($self->prefix()) > 30 ) {
3536             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3537             $self->prefix("");
3538             $self->infix(":\t");
3539         }
3540         else {
3541             $self->infix("):\t");
3542             $self->position(
3543                 $self->prefix . $line. $self->infix
3544                 . $self->_curr_line . $self->after
3545             );
3546         }
3547
3548         # Print current line info, indenting if necessary.
3549         $self->_my_print_lineinfo($line, $self->position);
3550
3551         my $i;
3552         my $line_i = sub { return $DB::dbline[$i]; };
3553
3554         # Scan forward, stopping at either the end or the next
3555         # unbreakable line.
3556         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3557         {    #{ vi
3558
3559             # Drop out on null statements, block closers, and comments.
3560             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3561
3562             # Drop out if the user interrupted us.
3563             last if $signal;
3564
3565             # Append a newline if the line doesn't have one. Can happen
3566             # in eval'ed text, for instance.
3567             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3568
3569             # Next executable line.
3570             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3571                 . $self->after;
3572             $self->append_to_position($incr_pos);
3573             $self->_my_print_lineinfo($i, $incr_pos);
3574         } ## end for ($i = $line + 1 ; $i...
3575     } ## end else [ if ($slave_editor)
3576
3577     return;
3578 }
3579
3580 sub _handle_t_command {
3581     if (my ($levels) = $DB::cmd =~ /\At(?:\s+(\d+))?\z/) {
3582         $trace ^= 1;
3583         local $\ = '';
3584         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3585         print {$OUT} "Trace = "
3586         . ( ( $trace & 1 )
3587             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3588             : "off" ) . "\n";
3589         next CMD;
3590     }
3591
3592     return;
3593 }
3594
3595
3596 sub _handle_S_command {
3597     if (my ($print_all_subs, $should_reverse, $Spatt)
3598         = $DB::cmd =~ /\AS(\s+(!)?(.+))?\z/) {
3599         # $Spatt is the pattern (if any) to use.
3600         # Reverse scan?
3601         my $Srev     = defined $should_reverse;
3602         # No args - print all subs.
3603         my $Snocheck = !defined $print_all_subs;
3604
3605         # Need to make these sane here.
3606         local $\ = '';
3607         local $, = '';
3608
3609         # Search through the debugger's magical hash of subs.
3610         # If $nocheck is true, just print the sub name.
3611         # Otherwise, check it against the pattern. We then use
3612         # the XOR trick to reverse the condition as required.
3613         foreach $subname ( sort( keys %sub ) ) {
3614             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3615                 print $OUT $subname, "\n";
3616             }
3617         }
3618         next CMD;
3619     }
3620
3621     return;
3622 }
3623
3624 sub _handle_V_command_and_X_command {
3625
3626     $DB::cmd =~ s/^X\b/V $DB::package/;
3627
3628     # Bare V commands get the currently-being-debugged package
3629     # added.
3630     if ($DB::cmd eq "V") {
3631         $DB::cmd = "V $DB::package";
3632     }
3633
3634     # V - show variables in package.
3635     if (my ($new_packname, $new_vars_str) =
3636         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3637
3638         # Save the currently selected filehandle and
3639         # force output to debugger's filehandle (dumpvar
3640         # just does "print" for output).
3641         my $savout = select($OUT);
3642
3643         # Grab package name and variables to dump.
3644         $packname = $new_packname;
3645         my @vars     = split( ' ', $new_vars_str );
3646
3647         # If main::dumpvar isn't here, get it.
3648         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3649         if ( defined &main::dumpvar ) {
3650
3651             # We got it. Turn off subroutine entry/exit messages
3652             # for the moment, along with return values.
3653             local $frame = 0;
3654             local $doret = -2;
3655
3656             # must detect sigpipe failures  - not catching
3657             # then will cause the debugger to die.
3658             eval {
3659                 &main::dumpvar(
3660                     $packname,
3661                     defined $option{dumpDepth}
3662                     ? $option{dumpDepth}
3663                     : -1,    # assume -1 unless specified
3664                     @vars
3665                 );
3666             };
3667
3668             # The die doesn't need to include the $@, because
3669             # it will automatically get propagated for us.
3670             if ($@) {
3671                 die unless $@ =~ /dumpvar print failed/;
3672             }
3673         } ## end if (defined &main::dumpvar)
3674         else {
3675
3676             # Couldn't load dumpvar.
3677             print $OUT "dumpvar.pl not available.\n";
3678         }
3679
3680         # Restore the output filehandle, and go round again.
3681         select($savout);
3682         next CMD;
3683     }
3684
3685     return;
3686 }
3687
3688 package DB;
3689
3690 # The following code may be executed now:
3691 # BEGIN {warn 4}
3692
3693 =head2 sub
3694
3695 C<sub> is called whenever a subroutine call happens in the program being
3696 debugged. The variable C<$DB::sub> contains the name of the subroutine
3697 being called.
3698
3699 The core function of this subroutine is to actually call the sub in the proper
3700 context, capturing its output. This of course causes C<DB::DB> to get called
3701 again, repeating until the subroutine ends and returns control to C<DB::sub>
3702 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3703 return value, and returns its captured copy of the return value as its own
3704 return value. The value then feeds back into the program being debugged as if
3705 C<DB::sub> hadn't been there at all.
3706
3707 C<sub> does all the work of printing the subroutine entry and exit messages
3708 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3709 and also prints the return value if needed (for the C<r> command and if
3710 the 16 bit is set in C<$frame>).
3711
3712 It also tracks the subroutine call depth by saving the current setting of
3713 C<$single> in the C<@stack> package global; if this exceeds the value in
3714 C<$deep>, C<sub> automatically turns on printing of the current depth by
3715 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3716 of stop/don't stop on entry to subs set as it currently is set.
3717
3718 =head3 C<caller()> support
3719
3720 If C<caller()> is called from the package C<DB>, it provides some
3721 additional data, in the following order:
3722
3723 =over 4
3724
3725 =item * C<$package>
3726
3727 The package name the sub was in
3728
3729 =item * C<$filename>
3730
3731 The filename it was defined in
3732
3733 =item * C<$line>
3734
3735 The line number it was defined on
3736
3737 =item * C<$subroutine>
3738
3739 The subroutine name; C<(eval)> if an C<eval>().
3740
3741 =item * C<$hasargs>
3742
3743 1 if it has arguments, 0 if not
3744
3745 =item * C<$wantarray>
3746
3747 1 if array context, 0 if scalar context
3748
3749 =item * C<$evaltext>
3750
3751 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3752
3753 =item * C<$is_require>
3754
3755 frame was created by a C<use> or C<require> statement
3756
3757 =item * C<$hints>
3758
3759 pragma information; subject to change between versions
3760
3761 =item * C<$bitmask>
3762
3763 pragma information; subject to change between versions
3764
3765 =item * C<@DB::args>
3766
3767 arguments with which the subroutine was invoked
3768
3769 =back
3770
3771 =cut
3772
3773 use vars qw($deep);
3774
3775 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3776 # happy. -- Shlomi Fish
3777 sub DB::sub {
3778     # Do not use a regex in this subroutine -> results in corrupted memory
3779     # See: [perl #66110]
3780
3781     # lock ourselves under threads
3782     lock($DBGR);
3783
3784     # Whether or not the autoloader was running, a scalar to put the
3785     # sub's return value in (if needed), and an array to put the sub's
3786     # return value in (if needed).
3787     my ( $al, $ret, @ret ) = "";
3788     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3789         print "creating new thread\n";
3790     }
3791
3792     # If the last ten characters are '::AUTOLOAD', note we've traced
3793     # into AUTOLOAD for $sub.
3794     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3795         no strict 'refs';
3796         $al = " for $$sub" if defined $$sub;
3797     }
3798
3799     # We stack the stack pointer and then increment it to protect us
3800     # from a situation that might unwind a whole bunch of call frames
3801     # at once. Localizing the stack pointer means that it will automatically
3802     # unwind the same amount when multiple stack frames are unwound.
3803     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3804
3805     # Expand @stack.
3806     $#stack = $stack_depth;
3807
3808     # Save current single-step setting.
3809     $stack[-1] = $single;
3810
3811     # Turn off all flags except single-stepping.
3812     $single &= 1;
3813
3814     # If we've gotten really deeply recursed, turn on the flag that will
3815     # make us stop with the 'deep recursion' message.
3816     $single |= 4 if $stack_depth == $deep;
3817
3818     # If frame messages are on ...
3819     (
3820         $frame & 4    # Extended frame entry message
3821         ? (
3822             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3823
3824             # Why -1? But it works! :-(
3825             # Because print_trace will call add 1 to it and then call
3826             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3827             # in dump_trace.
3828             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3829           )
3830         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3831
3832           # standard frame entry message
3833       )
3834       if $frame;
3835
3836     # Determine the sub's return type, and capture appropriately.
3837     if (wantarray) {
3838
3839         # Called in array context. call sub and capture output.
3840         # DB::DB will recursively get control again if appropriate; we'll come
3841         # back here when the sub is finished.
3842         {
3843             no strict 'refs';
3844             @ret = &$sub;
3845         }
3846
3847         # Pop the single-step value back off the stack.
3848         $single |= $stack[ $stack_depth-- ];
3849
3850         # Check for exit trace messages...
3851         (
3852             $frame & 4    # Extended exit message
3853             ? (
3854                 print_lineinfo( ' ' x $stack_depth, "out " ),
3855                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3856               )
3857             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3858
3859               # Standard exit message
3860           )
3861           if $frame & 2;
3862
3863         # Print the return info if we need to.
3864         if ( $doret eq $stack_depth or $frame & 16 ) {
3865
3866             # Turn off output record separator.
3867             local $\ = '';
3868             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3869
3870             # Indent if we're printing because of $frame tracing.
3871             print $fh ' ' x $stack_depth if $frame & 16;
3872
3873             # Print the return value.
3874             print $fh "list context return from $sub:\n";
3875             dumpit( $fh, \@ret );
3876
3877             # And don't print it again.
3878             $doret = -2;
3879         } ## end if ($doret eq $stack_depth...
3880             # And we have to return the return value now.
3881         @ret;
3882     } ## end if (wantarray)
3883
3884     # Scalar context.
3885     else {
3886         if ( defined wantarray ) {
3887             no strict 'refs';
3888             # Save the value if it's wanted at all.
3889             $ret = &$sub;
3890         }
3891         else {
3892             no strict 'refs';
3893             # Void return, explicitly.
3894             &$sub;
3895             undef $ret;
3896         }
3897
3898         # Pop the single-step value off the stack.
3899         $single |= $stack[ $stack_depth-- ];
3900
3901         # If we're doing exit messages...
3902         (
3903             $frame & 4    # Extended messages
3904             ? (
3905                 print_lineinfo( ' ' x $stack_depth, "out " ),
3906                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3907               )
3908             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3909
3910               # Standard messages
3911           )
3912           if $frame & 2;
3913
3914         # If we are supposed to show the return value... same as before.
3915         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3916             local $\ = '';
3917             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3918             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3919             print $fh (
3920                 defined wantarray
3921                 ? "scalar context return from $sub: "
3922                 : "void context return from $sub\n"
3923             );
3924             dumpit( $fh, $ret ) if defined wantarray;
3925             $doret = -2;
3926         } ## end if ($doret eq $stack_depth...
3927
3928         # Return the appropriate scalar value.
3929         $ret;
3930     } ## end else [ if (wantarray)
3931 } ## end sub _sub
3932
3933 sub lsub : lvalue {
3934
3935     no strict 'refs';
3936
3937     # lock ourselves under threads
3938     lock($DBGR);
3939
3940     # Whether or not the autoloader was running, a scalar to put the
3941     # sub's return value in (if needed), and an array to put the sub's
3942     # return value in (if needed).
3943     my ( $al, $ret, @ret ) = "";
3944     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3945         print "creating new thread\n";
3946     }
3947
3948     # If the last ten characters are C'::AUTOLOAD', note we've traced
3949     # into AUTOLOAD for $sub.
3950     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3951         $al = " for $$sub";
3952     }
3953
3954     # We stack the stack pointer and then increment it to protect us
3955     # from a situation that might unwind a whole bunch of call frames
3956     # at once. Localizing the stack pointer means that it will automatically
3957     # unwind the same amount when multiple stack frames are unwound.
3958     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3959
3960     # Expand @stack.
3961     $#stack = $stack_depth;
3962
3963     # Save current single-step setting.
3964     $stack[-1] = $single;
3965
3966     # Turn off all flags except single-stepping.
3967     $single &= 1;
3968
3969     # If we've gotten really deeply recursed, turn on the flag that will
3970     # make us stop with the 'deep recursion' message.
3971     $single |= 4 if $stack_depth == $deep;
3972
3973     # If frame messages are on ...
3974     (
3975         $frame & 4    # Extended frame entry message
3976         ? (
3977             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3978
3979             # Why -1? But it works! :-(
3980             # Because print_trace will call add 1 to it and then call
3981             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3982             # in dump_trace.
3983             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3984           )
3985         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3986
3987           # standard frame entry message
3988       )
3989       if $frame;
3990
3991     # Pop the single-step value back off the stack.
3992     $single |= $stack[ $stack_depth-- ];
3993
3994     # call the original lvalue sub.
3995     &$sub;
3996 }
3997
3998 # Abstracting common code from multiple places elsewhere:
3999 sub depth_print_lineinfo {
4000     my $always_print = shift;
4001
4002     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4003 }
4004
4005 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4006
4007 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4008 Most of the changes were to systematize the command structure and to eliminate
4009 commands that threw away user input without checking.
4010
4011 The following sections describe the code added to make it easy to support
4012 multiple command sets with conflicting command names. This section is a start
4013 at unifying all command processing to make it simpler to develop commands.
4014
4015 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4016 number, and C<$dbline> (the current line) as arguments.
4017
4018 Support functions in this section which have multiple modes of failure C<die>
4019 on error; the rest simply return a false value.
4020
4021 The user-interface functions (all of the C<cmd_*> functions) just output
4022 error messages.
4023
4024 =head2 C<%set>
4025
4026 The C<%set> hash defines the mapping from command letter to subroutine
4027 name suffix.
4028
4029 C<%set> is a two-level hash, indexed by set name and then by command name.
4030 Note that trying to set the CommandSet to C<foobar> simply results in the
4031 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4032
4033 =cut
4034
4035 ### The API section
4036
4037 my %set = (    #
4038     'pre580' => {
4039         'a' => 'pre580_a',
4040         'A' => 'pre580_null',
4041         'b' => 'pre580_b',
4042         'B' => 'pre580_null',
4043         'd' => 'pre580_null',
4044         'D' => 'pre580_D',
4045         'h' => 'pre580_h',
4046         'M' => 'pre580_null',
4047         'O' => 'o',
4048         'o' => 'pre580_null',
4049         'v' => 'M',
4050         'w' => 'v',
4051         'W' => 'pre580_W',
4052     },
4053     'pre590' => {
4054         '<'  => 'pre590_prepost',
4055         '<<' => 'pre590_prepost',
4056         '>'  => 'pre590_prepost',
4057         '>>' => 'pre590_prepost',
4058         '{'  => 'pre590_prepost',
4059         '{{' => 'pre590_prepost',
4060     },
4061 );
4062
4063 my %breakpoints_data;
4064
4065 sub _has_breakpoint_data_ref {
4066     my ($filename, $line) = @_;
4067
4068     return (
4069         exists( $breakpoints_data{$filename} )
4070             and
4071         exists( $breakpoints_data{$filename}{$line} )
4072     );
4073 }
4074
4075 sub _get_breakpoint_data_ref {
4076     my ($filename, $line) = @_;
4077
4078     return ($breakpoints_data{$filename}{$line} ||= +{});
4079 }
4080
4081 sub _delete_breakpoint_data_ref {
4082     my ($filename, $line) = @_;
4083
4084     delete($breakpoints_data{$filename}{$line});
4085     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4086         delete($breakpoints_data{$filename});
4087     }
4088
4089     return;
4090 }
4091
4092 sub _set_breakpoint_enabled_status {
4093     my ($filename, $line, $status) = @_;
4094
4095     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4096         ($status ? 1 : '')
4097         ;
4098
4099     return;
4100 }
4101
4102 sub _enable_breakpoint_temp_enabled_status {
4103     my ($filename, $line) = @_;
4104
4105     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4106
4107     return;
4108 }
4109
4110 sub _cancel_breakpoint_temp_enabled_status {
4111     my ($filename, $line) = @_;
4112
4113     my $ref = _get_breakpoint_data_ref($filename, $line);
4114
4115     delete ($ref->{'temp_enabled'});
4116
4117     if (! %$ref) {
4118         _delete_breakpoint_data_ref($filename, $line);
4119     }
4120
4121     return;
4122 }
4123
4124 sub _is_breakpoint_enabled {
4125     my ($filename, $line) = @_;
4126
4127     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4128     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4129 }
4130
4131 =head2 C<cmd_wrapper()> (API)
4132
4133 C<cmd_wrapper()> allows the debugger to switch command sets
4134 depending on the value of the C<CommandSet> option.
4135
4136 It tries to look up the command in the C<%set> package-level I<lexical>
4137 (which means external entities can't fiddle with it) and create the name of
4138 the sub to call based on the value found in the hash (if it's there). I<All>
4139 of the commands to be handled in a set have to be added to C<%set>; if they
4140 aren't found, the 5.8.0 equivalent is called (if there is one).
4141
4142 This code uses symbolic references.
4143
4144 =cut
4145
4146 sub cmd_wrapper {
4147     my $cmd      = shift;
4148     my $line     = shift;
4149     my $dblineno = shift;
4150
4151     # Assemble the command subroutine's name by looking up the
4152     # command set and command name in %set. If we can't find it,
4153     # default to the older version of the command.
4154     my $call = 'cmd_'
4155       . ( $set{$CommandSet}{$cmd}
4156           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4157
4158     # Call the command subroutine, call it by name.
4159     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4160 } ## end sub cmd_wrapper
4161
4162 =head3 C<cmd_a> (command)
4163
4164 The C<a> command handles pre-execution actions. These are associated with a
4165 particular line, so they're stored in C<%dbline>. We default to the current
4166 line if none is specified.
4167
4168 =cut
4169
4170 sub cmd_a {
4171     my $cmd    = shift;
4172     my $line   = shift || '';    # [.|line] expr
4173     my $dbline = shift;
4174
4175     # If it's dot (here), or not all digits,  use the current line.
4176     $line =~ s/\A\./$dbline/;
4177
4178     # Should be a line number followed by an expression.
4179     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4180
4181         if (! length($lineno)) {
4182             $lineno = $dbline;
4183         }
4184
4185         # If we have an expression ...
4186         if ( length $expr ) {
4187
4188             # ... but the line isn't breakable, complain.
4189             if ( $dbline[$lineno] == 0 ) {
4190                 print $OUT
4191                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4192             }
4193             else {
4194
4195                 # It's executable. Record that the line has an action.
4196                 $had_breakpoints{$filename} |= 2;
4197
4198                 # Remove any action, temp breakpoint, etc.
4199                 $dbline{$lineno} =~ s/\0[^\0]*//;
4200
4201                 # Add the action to the line.
4202                 $dbline{$lineno} .= "\0" . action($expr);
4203
4204                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4205             }
4206         } ## end if (length $expr)
4207     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4208     else {
4209
4210         # Syntax wrong.
4211         print $OUT
4212           "Adding an action requires an optional lineno and an expression\n"
4213           ;    # hint
4214     }
4215 } ## end sub cmd_a
4216
4217 =head3 C<cmd_A> (command)
4218
4219 Delete actions. Similar to above, except the delete code is in a separate
4220 subroutine, C<delete_action>.
4221
4222 =cut
4223
4224 sub cmd_A {
4225     my $cmd    = shift;
4226     my $line   = shift || '';
4227     my $dbline = shift;
4228
4229     # Dot is this line.
4230     $line =~ s/^\./$dbline/;
4231
4232     # Call delete_action with a null param to delete them all.
4233     # The '1' forces the eval to be true. It'll be false only
4234     # if delete_action blows up for some reason, in which case
4235     # we print $@ and get out.
4236     if ( $line eq '*' ) {
4237         if (! eval { _delete_all_actions(); 1 }) {
4238             print {$OUT} $@;
4239             return;
4240         }
4241     }
4242
4243     # There's a real line  number. Pass it to delete_action.
4244     # Error trapping is as above.
4245     elsif ( $line =~ /^(\S.*)/ ) {
4246         if (! eval { delete_action($1); 1 }) {
4247             print {$OUT} $@;
4248             return;
4249         }
4250     }
4251
4252     # Swing and a miss. Bad syntax.
4253     else {
4254         print $OUT
4255           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4256     }
4257 } ## end sub cmd_A
4258
4259 =head3 C<delete_action> (API)
4260
4261 C<delete_action> accepts either a line number or C<undef>. If a line number
4262 is specified, we check for the line being executable (if it's not, it
4263 couldn't have had an  action). If it is, we just take the action off (this
4264 will get any kind of an action, including breakpoints).
4265
4266 =cut
4267
4268 sub _remove_action_from_dbline {
4269     my $i = shift;
4270
4271     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4272     delete $dbline{$i} if $dbline{$i} eq '';
4273
4274     return;
4275 }
4276
4277 sub _delete_all_actions {
4278     print {$OUT} "Deleting all actions...\n";
4279
4280     for my $file ( keys %had_breakpoints ) {
4281         local *dbline = $main::{ '_<' . $file };
4282         $max = $#dbline;
4283         my $was;
4284         for my $i (1 .. $max) {
4285             if ( defined $dbline{$i} ) {
4286                 _remove_action_from_dbline($i);
4287             }
4288         }
4289
4290         unless ( $had_breakpoints{$file} &= ~2 ) {
4291             delete $had_breakpoints{$file};
4292         }
4293     }
4294
4295     return;
4296 }
4297
4298 sub delete_action {
4299     my $i = shift;
4300
4301     if ( defined($i) ) {
4302         # Can there be one?
4303         die "Line $i has no action .\n" if $dbline[$i] == 0;
4304
4305         # Nuke whatever's there.
4306         _remove_action_from_dbline($i);
4307     }
4308     else {
4309         _delete_all_actions();
4310     }
4311 }
4312
4313 =head3 C<cmd_b> (command)
4314
4315 Set breakpoints. Since breakpoints can be set in so many places, in so many
4316 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4317 we try to parse the command type, and then shuttle it off to an appropriate
4318 subroutine to actually do the work of setting the breakpoint in the right
4319 place.
4320
4321 =cut
4322
4323 sub cmd_b {
4324     my $cmd    = shift;
4325     my $line   = shift;    # [.|line] [cond]
4326     my $dbline = shift;
4327
4328     my $default_cond = sub {
4329         my $cond = shift;
4330         return length($cond) ? $cond : '1';
4331     };
4332
4333     # Make . the current line number if it's there..
4334     $line =~ s/^\.(\s|\z)/$dbline$1/;
4335
4336     # No line number, no condition. Simple break on current line.
4337     if ( $line =~ /^\s*$/ ) {
4338         cmd_b_line( $dbline, 1 );
4339     }
4340
4341     # Break on load for a file.
4342     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4343         $file =~ s/\s+\z//;
4344         cmd_b_load($file);
4345     }
4346
4347     # b compile|postpone <some sub> [<condition>]
4348     # The interpreter actually traps this one for us; we just put the
4349     # necessary condition in the %postponed hash.
4350     elsif ( my ($action, $subname, $cond)
4351         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4352
4353         # De-Perl4-ify the name - ' separators to ::.
4354         $subname =~ s/'/::/g;
4355
4356         # Qualify it into the current package unless it's already qualified.
4357         $subname = "${package}::" . $subname unless $subname =~ /::/;
4358
4359         # Add main if it starts with ::.
4360         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4361
4362         # Save the break type for this sub.
4363         $postponed{$subname} = (($action eq 'postpone')
4364             ? ( "break +0 if " . $default_cond->($cond) )
4365             : "compile");
4366     } ## end elsif ($line =~ ...
4367     # b <filename>:<line> [<condition>]
4368     elsif (my ($filename, $line_num, $cond)
4369         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4370         cmd_b_filename_line(
4371             $filename,
4372             $line_num,
4373             (length($cond) ? $cond : '1'),
4374         );
4375     }
4376     # b <sub name> [<condition>]
4377     elsif ( my ($new_subname, $new_cond) =
4378         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4379
4380         #
4381         $subname = $new_subname;
4382         cmd_b_sub( $subname, $default_cond->($new_cond) );
4383     }
4384
4385     # b <line> [<condition>].
4386     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4387
4388         # Capture the line. If none, it's the current line.
4389         $line = $line_n || $dbline;
4390
4391         # Break on line.
4392         cmd_b_line( $line, $default_cond->($cond) );
4393     }
4394
4395     # Line didn't make sense.
4396     else {
4397         print "confused by line($line)?\n";
4398     }
4399
4400     return;
4401 } ## end sub cmd_b
4402
4403 =head3 C<break_on_load> (API)
4404
4405 We want to break when this file is loaded. Mark this file in the
4406 C<%break_on_load> hash, and note that it has a breakpoint in
4407 C<%had_breakpoints>.
4408
4409 =cut
4410
4411 sub break_on_load {
4412     my $file = shift;
4413     $break_on_load{$file} = 1;
4414     $had_breakpoints{$file} |= 1;
4415 }
4416
4417 =head3 C<report_break_on_load> (API)
4418
4419 Gives us an array of filenames that are set to break on load. Note that
4420 only files with break-on-load are in here, so simply showing the keys
4421 suffices.
4422
4423 =cut
4424
4425 sub report_break_on_load {
4426     sort keys %break_on_load;
4427 }
4428
4429 =head3 C<cmd_b_load> (command)
4430
4431 We take the file passed in and try to find it in C<%INC> (which maps modules
4432 to files they came from). We mark those files for break-on-load via
4433 C<break_on_load> and then report that it was done.
4434
4435 =cut
4436
4437 sub cmd_b_load {
4438     my $file = shift;
4439     my @files;
4440
4441     # This is a block because that way we can use a redo inside it
4442     # even without there being any looping structure at all outside it.
4443     {
4444
4445         # Save short name and full path if found.
4446         push @files, $file;
4447         push @files, $::INC{$file} if $::INC{$file};
4448
4449         # Tack on .pm and do it again unless there was a '.' in the name
4450         # already.
4451         $file .= '.pm', redo unless $file =~ /\./;
4452     }
4453
4454     # Do the real work here.
4455     break_on_load($_) for @files;
4456
4457     # All the files that have break-on-load breakpoints.
4458     @files = report_break_on_load;
4459
4460     # Normalize for the purposes of our printing this.
4461     local $\ = '';
4462     local $" = ' ';
4463     print $OUT "Will stop on load of '@files'.\n";
4464 } ## end sub cmd_b_load
4465
4466 =head3 C<$filename_error> (API package global)
4467
4468 Several of the functions we need to implement in the API need to work both
4469 on the current file and on other files. We don't want to duplicate code, so
4470 C<$filename_error> is used to contain the name of the file that's being
4471 worked on (if it's not the current one).
4472
4473 We can now build functions in pairs: the basic function works on the current
4474 file, and uses C<$filename_error> as part of its error message. Since this is
4475 initialized to C<"">, no filename will appear when we are working on the
4476 current file.
4477
4478 The second function is a wrapper which does the following:
4479
4480 =over 4
4481
4482 =item *
4483
4484 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4485
4486 =item *
4487
4488 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4489
4490 =item *
4491
4492 Calls the first function.
4493
4494 The first function works on the I<current> file (i.e., the one we changed to),
4495 and prints C<$filename_error> in the error message (the name of the other file)
4496 if it needs to. When the functions return, C<*dbline> is restored to point
4497 to the actual current file (the one we're executing in) and
4498 C<$filename_error> is restored to C<"">. This restores everything to
4499 the way it was before the second function was called at all.
4500
4501 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4502 details.
4503
4504 =back
4505
4506 =cut
4507
4508 use vars qw($filename_error);
4509 $filename_error = '';
4510
4511 =head3 breakable_line(from, to) (API)
4512
4513 The subroutine decides whether or not a line in the current file is breakable.
4514 It walks through C<@dbline> within the range of lines specified, looking for
4515 the first line that is breakable.
4516
4517 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4518 first line I<after> C<$to> that's breakable, if there is one.
4519
4520 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4521 first line I<before> C<$to> that's breakable, if there is one.
4522
4523 =cut
4524
4525 sub breakable_line {
4526
4527     my ( $from, $to ) = @_;
4528
4529     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4530     my $i = $from;
4531
4532     # If there are at least 2 arguments, we're trying to search a range.
4533     if ( @_ >= 2 ) {
4534
4535         # $delta is positive for a forward search, negative for a backward one.
4536         my $delta = $from < $to ? +1 : -1;
4537
4538         # Keep us from running off the ends of the file.
4539         my $limit = $delta > 0 ? $#dbline : 1;
4540
4541         # Clever test. If you're a mathematician, it's obvious why this
4542         # test works. If not:
4543         # If $delta is positive (going forward), $limit will be $#dbline.
4544         #    If $to is less than $limit, ($limit - $to) will be positive, times
4545         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4546         #    as the stopping point.
4547         #
4548         #    If $to is greater than $limit, ($limit - $to) is negative,
4549         #    times $delta of 1 (positive), so the result is < 0 and we should
4550         #    use $limit ($#dbline) as the stopping point.
4551         #
4552         # If $delta is negative (going backward), $limit will be 1.
4553         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4554         #    (negative) so the result is > 0, and we use $to as the stopping
4555         #    point.
4556         #
4557         #    If $to is less than zero, ($limit - $to) will be positive,
4558         #    times $delta of -1 (negative), so the result is not > 0, and
4559         #    we use $limit (1) as the stopping point.
4560         #
4561         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4562         #    (negative), still giving zero; the result is not > 0, and
4563         #    we use $limit (1) as the stopping point.
4564         #
4565         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4566         #    (negative), giving a positive (>0) value, so we'll set $limit to
4567         #    $to.
4568
4569         $limit = $to if ( $limit - $to ) * $delta > 0;
4570
4571         # The real search loop.
4572         # $i starts at $from (the point we want to start searching from).
4573         # We move through @dbline in the appropriate direction (determined
4574         # by $delta: either -1 (back) or +1 (ahead).
4575         # We stay in as long as we haven't hit an executable line
4576         # ($dbline[$i] == 0 means not executable) and we haven't reached
4577         # the limit yet (test similar to the above).
4578         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4579
4580     } ## end if (@_ >= 2)
4581
4582     # If $i points to a line that is executable, return that.
4583     return $i unless $dbline[$i] == 0;
4584
4585     # Format the message and print it: no breakable lines in range.
4586     my ( $pl, $upto ) = ( '', '' );
4587     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4588
4589     # If there's a filename in filename_error, we'll see it.
4590     # If not, not.
4591     die "Line$pl $from$upto$filename_error not breakable\n";
4592 } ## end sub breakable_line
4593
4594 =head3 breakable_line_in_filename(file, from, to) (API)
4595
4596 Like C<breakable_line>, but look in another file.
4597
4598 =cut
4599
4600 sub breakable_line_in_filename {
4601
4602     # Capture the file name.
4603     my ($f) = shift;
4604
4605     # Swap the magic line array over there temporarily.
4606     local *dbline = $main::{ '_<' . $f };
4607
4608     # If there's an error, it's in this other file.
4609     local $filename_error = " of '$f'";
4610
4611     # Find the breakable line.
4612     breakable_line(@_);
4613
4614     # *dbline and $filename_error get restored when this block ends.
4615
4616 } ## end sub breakable_line_in_filename
4617
4618 =head3 break_on_line(lineno, [condition]) (API)
4619
4620 Adds a breakpoint with the specified condition (or 1 if no condition was
4621 specified) to the specified line. Dies if it can't.
4622
4623 =cut