installperl

   1 #!./perl -w
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '../lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8
   9     # This needs to be at BEGIN time, before any use of Config
  10     require './install_lib.pl';
  11 }
  12
  13 use strict;
  14 use vars qw($Is_VMS $Is_W32 $Is_OS2 $Is_Cygwin $Is_Darwin $Is_NetWare
  15             %opts $packlist);
  16 my ($dostrip, $versiononly, $force,
  17     $otherperls, $archname, $nwinstall, $nopods);
  18 # Not sure how easy it would be to refactor to remove the need for local $depth
  19 # below
  20 use vars qw /$depth/;
  21
  22 BEGIN {
  23     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  24 }
  25
  26 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  27
  28 use File::Find;
  29 use File::Compare;
  30 use File::Copy ();
  31 use File::Path ();
  32 use ExtUtils::Packlist;
  33 use Cwd;
  34
  35 if ($Is_NetWare) {
  36     $Is_W32 = 0;
  37     $scr_ext = '.pl';
  38 }
  39
  40 # override the ones in the rest of the script
  41 sub mkpath {
  42     File::Path::mkpath(@_) unless $opts{notify};
  43 }
  44
  45 my $mainperldir = "/usr/bin";
  46 my $exe_ext = $Config{exe_ext};
  47
  48 # Allow "make install PERLNAME=something_besides_perl":
  49 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  50
  51 # This is the base used for versioned names, like "perl5.6.0".
  52 # It's separate because a common use of $PERLNAME is to install
  53 # perl as "perl5", if that's used as base for versioned files you
  54 # get "perl55.6.0".
  55 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  56                     ? $ENV{PERLNAME_VERBASE}
  57                     : $perl;
  58 my $dbg = '';
  59 my $ndbg = '';
  60 if ( $Is_VMS ) {
  61     if ( defined $Config{usevmsdebug} ) {
  62         if ( $Config{usevmsdebug} eq 'define' ) {
  63             $dbg = 'dbg';
  64             $ndbg = 'ndbg';
  65         }
  66     }
  67 }
  68
  69 $otherperls = 1;
  70 # Consider refactoring this to use Getopt::Long once Getopt::Long's planned
  71 # feature is implemented, to distinguish + and - options.
  72 while (@ARGV) {
  73     $opts{notify} = 1 if $ARGV[0] eq '-n';
  74     $dostrip = 1 if $ARGV[0] eq '-s';
  75     $versiononly = 1 if $ARGV[0] eq '-v';
  76     $versiononly = 0 if $ARGV[0] eq '+v';
  77     $opts{silent} = 1 if $ARGV[0] eq '-S';
  78     $otherperls = 0 if $ARGV[0] eq '-o';
  79     $force = 1 if $ARGV[0] eq '-f';
  80     $opts{verbose} = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  81     $archname = 1 if $ARGV[0] eq '-A';
  82     $nwinstall = 1 if $ARGV[0] eq '-netware';
  83     $nopods = 1 if $ARGV[0] eq '-p';
  84     $opts{destdir} = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
  85     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  86         print <<"EOT";
  87 Usage $0: [switches]
  88   -n        Don't actually run any commands; just print them.
  89   -s        Run strip on installed binaries.
  90   -v        Only install perl as a binary with the version number in the name.
  91             (Override whatever config.sh says)
  92   +v        Install perl as "perl" and as a binary with the version number in
  93             the name.  (Override whatever config.sh says)
  94   -S        Silent mode.
  95   -f        Force installation (don't check if same version is there)
  96   -o        Skip checking for other copies of perl in your PATH.
  97   -V        Verbose mode.
  98   -A        Also install perl with the architecture's name in the perl binary's
  99             name.
 100   -p        Don't install the pod files. [This will break use diagnostics;]
 101   -netware  Install correctly on a Netware server.
 102   -destdir  Prefix installation directories by this string.
 103 EOT
 104         exit;
 105     }
 106     shift;
 107 }
 108
 109 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 110 my (@scripts, @tolink);
 111 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 112 while (<SCRIPTS>) {
 113     next if /^#/;
 114     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
 115     next if /a2p/; # a2p is binary, to be installed separately
 116     chomp;
 117     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 118         push @scripts, $1;
 119         push @tolink, [$1, $2];
 120     } else {
 121         push @scripts, $_;
 122     }
 123 }
 124 close SCRIPTS;
 125
 126 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 127
 128 my @pods = $nopods ? () : (<pod/*.pod>, 'x2p/a2p.pod');
 129
 130 # Specify here any .pm files that are actually architecture-dependent.
 131 # (Those included with XS extensions under ext/ are automatically
 132 # added later.)
 133 # Now that the default privlib has the full perl version number included,
 134 # we no longer have to play the trick of sticking version-specific .pm
 135 # files under the archlib directory.
 136 my %archpms = (
 137     Config => 1,
 138     lib => 1,
 139     Cwd => 1,
 140 );
 141
 142 if ($^O eq 'dos') {
 143     push(@scripts,'djgpp/fixpmain');
 144     $archpms{config} = $archpms{filehand} = 1;
 145 }
 146
 147 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 148     push(@scripts, map("$_.exe", @scripts));
 149 }
 150
 151 find(sub {
 152     if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 153         my($path, $modname) = ($1,$2);
 154
 155         # strip to optional "/lib", or remove trailing component
 156         $path =~ s{.*/lib\b}{} or $path =~ s{/[^/]*$}{};
 157
 158         # strip any leading /
 159         $path =~ s{^/}{};
 160
 161         # reconstitute canonical module name
 162         $modname = "$path/$modname" if length $path;
 163
 164         # remember it
 165         $archpms{$modname} = 1;
 166     }
 167 }, 'ext');
 168
 169 # print "[$_]\n" for sort keys %archpms;
 170
 171 my $ver = $Config{version};
 172 my $release = substr($],0,3);   # Not used currently.
 173 my $patchlevel = substr($],3,2);
 174 die "Patchlevel of perl ($patchlevel)",
 175     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 176         if $patchlevel != $Config{'PERL_VERSION'};
 177
 178 # Fetch some frequently-used items from %Config
 179 my $installbin = "$opts{destdir}$Config{installbin}";
 180 my $installscript = "$opts{destdir}$Config{installscript}";
 181 my $installprivlib = "$opts{destdir}$Config{installprivlib}";
 182 my $installarchlib = "$opts{destdir}$Config{installarchlib}";
 183 my $installsitelib = "$opts{destdir}$Config{installsitelib}";
 184 my $installsitearch = "$opts{destdir}$Config{installsitearch}";
 185 my $installman1dir = "$opts{destdir}$Config{installman1dir}";
 186 my $man1ext = $Config{man1ext};
 187 my $libperl = $Config{libperl};
 188 # Shared library and dynamic loading suffixes.
 189 my $so = $Config{so};
 190 my $dlext = $Config{dlext};
 191 my $dlsrc = $Config{dlsrc};
 192 if ($^O eq 'os390') {
 193     my $pwd;
 194     chomp($pwd=`pwd`);
 195     my $archlibexp = $Config{archlibexp};
 196     my $usedl = $Config{usedl};
 197     if ($usedl eq 'define') {
 198         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 199     }
 200 }
 201
 202 if ($nwinstall) {
 203     # This is required only if we are installing on a NetWare server
 204     $installscript = $Config{installnwscripts};
 205     $installprivlib = $Config{installnwlib};
 206     $installarchlib = $Config{installnwlib};
 207     $installsitelib = $Config{installnwlib};
 208 }
 209
 210 my $d_dosuid = $Config{d_dosuid};
 211 my $binexp = $Config{binexp};
 212
 213 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 214     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 215               \$installarchlib, \$installsitelib, \$installsitearch,
 216               \$installman1dir ) {
 217         $$_ = unixify($$_);  $$_ =~ s:/$::;
 218     }
 219 }
 220
 221 # Do some quick sanity checks.
 222
 223 if (!$opts{notify} && $d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 224
 225    $installbin          || die "No installbin directory in config.sh\n";
 226 -d $installbin          || mkpath($installbin, $opts{verbose}, 0777);
 227 -d $installbin          || $opts{notify} || die "$installbin is not a directory\n";
 228 -w $installbin          || $opts{notify} || die "$installbin is not writable by you\n"
 229         unless $installbin =~ m#^/afs/# || $opts{notify};
 230
 231 if (!$Is_NetWare) {
 232 if (!$Is_VMS) {
 233 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 234 }
 235 else {
 236 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
 237     if ($dbg) {
 238         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
 239     }
 240 }
 241 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 242
 243 -f 't/rantests'         || $Is_W32
 244                         || warn "WARNING: You've never run 'make test' or",
 245                                 " some tests failed! (Installing anyway.)\n";
 246 } #if (!$Is_NetWare)
 247
 248 # This will be used to store the packlist
 249 $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 250
 251 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 252     my $perldll;
 253
 254     if ($Is_Cygwin) {
 255         $perldll = $libperl;
 256     } else {
 257         $perldll = 'perl5'.$Config{patchlevel}.'.'.$dlext;
 258     }
 259
 260     if ($dlsrc ne "dl_none.xs") {
 261         -f $perldll || die "No perl DLL built\n";
 262     }
 263
 264     # Install the DLL
 265     safe_unlink("$installbin/$perldll");
 266     copy("$perldll", "$installbin/$perldll");
 267     chmod(0755, "$installbin/$perldll");
 268     $packlist->{"$installbin/$perldll"} = { type => 'file' };
 269 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 270
 271 # First we install the version-numbered executables.
 272
 273 if ($Is_VMS) {
 274     safe_unlink("$installbin/perl_setup.com");
 275     copy("perl_setup.com", "$installbin/perl_setup.com");
 276     chmod(0755, "$installbin/perl_setup.com");
 277     safe_unlink("$installbin/$dbg$perl$exe_ext");
 278     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
 279     chmod(0755, "$installbin/$dbg$perl$exe_ext");
 280     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
 281     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
 282     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
 283     if ($ndbg) {
 284         safe_unlink("$installbin/$ndbg$perl$exe_ext");
 285         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
 286         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
 287         safe_unlink("$installbin/${dbg}a2p$exe_ext");
 288         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
 289         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
 290     }
 291 }
 292 elsif ($^O eq 'mpeix') {
 293     # MPE lacks hard links and requires that executables with special
 294     # capabilities reside in the MPE namespace.
 295     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 296     # Install the primary executable into the MPE namespace as perlpath.
 297     copy("perl$exe_ext", $Config{perlpath});
 298     chmod(0755, $Config{perlpath});
 299     # Create a backup copy with the version number.
 300     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 301 }
 302 elsif ($^O ne 'dos') {
 303     if (!$Is_NetWare) {
 304         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 305         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 306         strip("$installbin/$perl_verbase$ver$exe_ext");
 307         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 308     }
 309     else {
 310         # If installing onto a NetWare server
 311         if ($nwinstall) {
 312             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 313             mkpath($Config{installnwsystem}, 1, 0777);
 314             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 315             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 316             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 317             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 318             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 319             mkpath($Config{installnwlcgi}, 1, 0777);
 320             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 321         }
 322     } #if (!$Is_NetWare)
 323 }
 324 else {
 325     safe_unlink("$installbin/$perl.exe");
 326     copy("perl.exe", "$installbin/$perl.exe");
 327 }
 328
 329 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 330 if ($d_dosuid) {
 331     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 332     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 333 }
 334
 335 # Install library files.
 336
 337 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 338 my $vershort = ($Is_Cygwin and !$Config{usedevel}) ? substr($ver,0,-2) : $ver;
 339
 340 mkpath($installprivlib, $opts{verbose}, 0777);
 341 mkpath($installarchlib, $opts{verbose}, 0777);
 342 mkpath($installsitelib, $opts{verbose}, 0777) if ($installsitelib);
 343 mkpath($installsitearch, $opts{verbose}, 0777) if ($installsitearch);
 344
 345 if (chdir "lib") {
 346     $do_installarchlib = ! samepath($installarchlib, '.');
 347     $do_installprivlib = ! samepath($installprivlib, '.');
 348     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$vershort/);
 349
 350     if ($do_installarchlib || $do_installprivlib) {
 351         find(\&installlib, '.');
 352     }
 353     chdir ".." || die "Can't cd back to source directory: $!\n";
 354 }
 355 else {
 356     warn "Can't cd to lib to install lib files: $!\n";
 357 }
 358
 359 # Install header files and libraries.
 360 mkpath("$installarchlib/CORE", $opts{verbose}, 0777);
 361 my @corefiles;
 362 if ($Is_VMS) {  # We did core file selection during build
 363     my $coredir = "lib/$Config{archname}/$ver/CORE";
 364     $coredir =~ tr/./_/;
 365     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 366 }
 367 elsif ($Is_Cygwin) { # On Cygwin symlink it to CORE to make Makefile happy
 368     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 369     my $coredll = "$installarchlib/CORE/$libperl";
 370     safe_unlink($coredll);
 371     ( $Config{'d_link'} eq 'define' &&
 372       eval {
 373           CORE::link("$installbin/$libperl", $coredll);
 374           $packlist->{$coredll} = { from => "$installbin/$libperl",
 375                                     type => 'link' };
 376       }
 377     ) ||
 378     eval {
 379         symlink("$installbin/$libperl", $coredll);
 380         $packlist->{$coredll} = { from => "$installbin/$libperl",
 381                                   type => 'link' };
 382     } ||
 383     ( copy("$installbin/$libperl", $coredll) &&
 384       push(@corefiles, $coredll)
 385     )
 386 } else {
 387     # [als] hard-coded 'libperl' name... not good!
 388     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
 389
 390     # AIX needs perl.exp installed as well.
 391     push(@corefiles,'perl.exp') if $^O eq 'aix';
 392     if ($^O eq 'mpeix') {
 393         # MPE needs mpeixish.h installed as well.
 394         mkpath("$installarchlib/CORE/mpeix", $opts{verbose}, 0777);
 395         push(@corefiles,'mpeix/mpeixish.h');
 396     }
 397     # If they have built sperl.o...
 398     push(@corefiles,'sperl.o') if -f 'sperl.o';
 399 }
 400 foreach my $file (@corefiles) {
 401     # HP-UX (at least) needs to maintain execute permissions
 402     # on dynamically-loadable libraries. So we do it for all.
 403     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 404         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 405             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 406             chmod(0555, "$installarchlib/CORE/$file");
 407         } else {
 408             chmod(0444, "$installarchlib/CORE/$file");
 409         }
 410     }
 411 }
 412
 413 # Install main perl executables
 414 # Make links to ordinary names if installbin directory isn't current directory.
 415
 416 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 417     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 418     if ($^O eq 'mpeix') {
 419         # MPE doesn't support hard links, so use a symlink.
 420         # We don't want another cloned copy.
 421         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 422     } elsif ($^O eq 'vos') {
 423         # VOS doesn't support hard links, so use a symlink.
 424         symlink("$installbin/$perl_verbase$ver$exe_ext",
 425                 "$installbin/$perl$exe_ext");
 426     } else {
 427         link("$installbin/$perl_verbase$ver$exe_ext",
 428                 "$installbin/$perl$exe_ext");
 429     }
 430     link("$installbin/$perl_verbase$ver$exe_ext",
 431             "$installbin/suid$perl$exe_ext")
 432       if $d_dosuid;
 433 }
 434
 435 # For development purposes it can be very useful to have multiple perls
 436 # build for different "architectures" (eg threading or not) simultaneously.
 437 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 438     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 439     safe_unlink("$installbin/$archperl");
 440     if ($^O eq 'mpeix') {
 441         # MPE doesn't support hard links, so use a symlink.
 442         # We don't want another cloned copy.
 443         symlink($Config{perlpath}, "$installbin/$archperl");
 444     } elsif ($^O eq 'vos') {
 445         # VOS doesn't support hard links, so use a symlink.
 446         symlink("$installbin/$perl_verbase$ver$exe_ext",
 447                 "$installbin/$archperl");
 448     } else {
 449         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 450     }
 451 }
 452
 453 # Offer to install perl in a "standard" location
 454
 455 my $mainperl_is_instperl = 0;
 456
 457 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 458     !$versiononly && !$opts{notify} && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 459         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 460     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 461     my($instperl)       = "$installbin/$perl$exe_ext";
 462     my($expinstperl)    = "$binexp/$perl$exe_ext";
 463
 464     # First make sure $usrbinperl is not already the same as the perl we
 465     # just installed.
 466     if (-x $usrbinperl) {
 467         # Try to be clever about mainperl being a symbolic link
 468         # to binexp/perl if binexp and installbin are different.
 469         $mainperl_is_instperl =
 470             samepath($usrbinperl, $instperl) ||
 471             samepath($usrbinperl, $expinstperl) ||
 472              (($binexp ne $installbin) &&
 473               (-l $usrbinperl) &&
 474               ((readlink $usrbinperl) eq $expinstperl));
 475     }
 476     if (! $mainperl_is_instperl) {
 477         unlink($usrbinperl);
 478         ( $Config{'d_link'} eq 'define' &&
 479           eval { CORE::link $instperl, $usrbinperl } )  ||
 480         eval { symlink $expinstperl, $usrbinperl }      ||
 481         copy($instperl, $usrbinperl);
 482
 483         $mainperl_is_instperl = 1;
 484     }
 485 }
 486
 487 # Make links to ordinary names if installbin directory isn't current directory.
 488 if (!$Is_NetWare && $dbg eq '') {
 489     if (! samepath($installbin, 'x2p')) {
 490         my $base = 'a2p';
 491         $base .= $ver if $versiononly;
 492         safe_unlink("$installbin/$base$exe_ext");
 493         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 494         strip("$installbin/$base$exe_ext");
 495         chmod(0755, "$installbin/$base$exe_ext");
 496     }
 497 }
 498
 499 # cppstdin is just a script, but it is architecture-dependent, so
 500 # it can't safely be shared.  Place it in $installbin.
 501 # Note that Configure doesn't build cppstin if it isn't needed, so
 502 # we skip this if cppstdin doesn't exist.
 503 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 504     safe_unlink("$installbin/cppstdin");
 505     copy("cppstdin", "$installbin/cppstdin");
 506     chmod(0755, "$installbin/cppstdin");
 507 }
 508
 509 sub script_alias {
 510     my ($installscript, $orig, $alias, $scr_ext) = @_;
 511
 512     safe_unlink("$installscript/$alias$scr_ext");
 513     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 514         copy("$installscript/$orig$scr_ext",
 515              "$installscript/$alias$scr_ext");
 516     } elsif ($^O eq 'vos') {
 517         symlink("$installscript/$orig$scr_ext",
 518                 "$installscript/$alias$scr_ext");
 519     } else {
 520         link("$installscript/$orig$scr_ext",
 521              "$installscript/$alias$scr_ext");
 522     }
 523 }
 524
 525 # Install scripts.
 526 mkpath($installscript, $opts{verbose}, 0777);
 527 if ($versiononly) {
 528     for (@scripts) {
 529         (my $base = $_) =~ s#.*/##;
 530         $base .= $ver;
 531         copy($_,    "$installscript/$base");
 532         chmod(0755, "$installscript/$base");
 533     }
 534
 535     for (@tolink) {
 536         my ($from, $to) = map { "$_$ver" } @$_;
 537         (my $frbase = $from) =~ s#.*/##;
 538         (my $tobase = $to) =~ s#.*/##;
 539         script_alias($installscript, $frbase, $tobase, $scr_ext);
 540     }
 541 } else {
 542     for (@scripts) {
 543         (my $base = $_) =~ s#.*/##;
 544         copy($_, "$installscript/$base");
 545         chmod(0755, "$installscript/$base");
 546     }
 547
 548     for (@tolink) {
 549         my ($from, $to) = @$_;
 550         (my $frbase = $from) =~ s#.*/##;
 551         (my $tobase = $to) =~ s#.*/##;
 552         script_alias($installscript, $frbase, $tobase, $scr_ext);
 553     }
 554 }
 555
 556 # Install pod pages.  Where? I guess in $installprivlib/pod
 557 # ($installprivlib/pods for cygwin).
 558
 559 my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
 560 if ( !$versiononly || ($installprivlib =~ m/\Q$vershort/)) {
 561     mkpath("${installprivlib}/$pod", $opts{verbose}, 0777);
 562
 563     # If Perl 5.003's perldiag.pod is there, rename it.
 564     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 565         read POD, $_, 4000;
 566         close POD;
 567         # Some of Perl 5.003's diagnostic messages ended with periods.
 568         if (/^=.*\.$/m) {
 569             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 570                                "${installprivlib}/$pod/perldiag-5.003.pod");
 571             print "  rename $from $to";
 572             rename($from, $to)
 573                 or warn "Couldn't rename $from to $to: $!\n"
 574                 unless $opts{notify};
 575         }
 576     }
 577
 578     for (@pods) {
 579         # $_ is a name like  pod/perl.pod
 580         (my $base = $_) =~ s#.*/##;
 581         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 582     }
 583
 584 }
 585
 586 # Check to make sure there aren't other perls around in installer's
 587 # path.  This is probably UNIX-specific.  Check all absolute directories
 588 # in the path except for where public executables are supposed to live.
 589 # Also skip $mainperl if the user opted to have it be a link to the
 590 # installed perl.
 591
 592 if (!$versiononly && $otherperls) {
 593     my ($path, @path);
 594     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 595     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 596     @path = split(/$dirsep/, $path);
 597     if ($Is_VMS) {
 598         my $i = 0;
 599         while (exists $ENV{'DCL$PATH' . $i}) {
 600             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 601             push(@path,$dir);
 602         }
 603     }
 604     my @otherperls;
 605     my %otherperls;
 606     for (@path) {
 607         next unless m,^/,;
 608         # Use &samepath here because some systems have other dirs linked
 609         # to $mainperldir (like SunOS)
 610         next if samepath($_, $binexp);
 611         next if samepath($_, cwd());
 612         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 613         my $otherperl = "$_/$perl$exe_ext";
 614         next if $otherperls{$otherperl}++;
 615         push(@otherperls, $otherperl)
 616             if (-x $otherperl && ! -d $otherperl);
 617     }
 618     if (@otherperls) {
 619         warn "\nWarning: $perl appears in your path in the following " .
 620             "locations beyond where\nwe just installed it:\n";
 621         for (@otherperls) {
 622             warn "    ", $_, "\n";
 623         }
 624         warn "\n";
 625     }
 626
 627 }
 628
 629 $packlist->write() unless $opts{notify};
 630 print "  Installation complete\n" if $opts{verbose};
 631
 632 exit 0;
 633
 634 ###############################################################################
 635
 636 # If these are needed elsewhere, move them into install_lib.pl rather than
 637 # copying them.
 638
 639 sub yn {
 640     my($prompt) = @_;
 641     my($answer);
 642     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 643     print STDERR $prompt;
 644     chop($answer = <STDIN>);
 645     $answer = $default if $answer =~ m/^\s*$/;
 646     ($answer =~ m/^[yY]/);
 647 }
 648
 649 sub safe_unlink {
 650     return if $opts{notify} or $Is_VMS;
 651     my @names = @_;
 652     foreach my $name (@names) {
 653         next unless -e $name;
 654         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 655         print "  unlink $name\n" if $opts{verbose};
 656         next if CORE::unlink($name);
 657         warn "Couldn't unlink $name: $!\n";
 658         if ($! =~ /busy/i) {
 659             print "  mv $name $name.old\n" if $opts{verbose};
 660             safe_rename($name, "$name.old")
 661                 or warn "Couldn't rename $name: $!\n";
 662         }
 663     }
 664 }
 665
 666 sub safe_rename {
 667     my($from,$to) = @_;
 668     if (-f $to and not unlink($to)) {
 669         my($i);
 670         for ($i = 1; $i < 50; $i++) {
 671             last if rename($to, "$to.$i");
 672         }
 673         warn("Cannot rename to `$to.$i': $!"), return 0
 674            if $i >= 50; # Give up!
 675     }
 676     link($from,$to) || return 0;
 677     unlink($from);
 678 }
 679
 680 sub copy {
 681     my($from,$to) = @_;
 682
 683     my $xto = $to;
 684     $xto =~ s/^\Q$opts{destdir}\E// if $opts{destdir};
 685     print $opts{verbose} ? "  cp $from $xto\n" : "  $xto\n"
 686         unless $opts{silent};
 687     print "  creating new version of $xto\n"
 688         if $Is_VMS and -e $to and !$opts{silent};
 689     unless ($opts{notify} or File::Copy::copy($from, $to)) {
 690         # Might have been that F::C::c can't overwrite the target
 691         warn "Couldn't copy $from to $to: $!\n"
 692             unless -f $to and (chmod(0666, $to), unlink $to)
 693                    and File::Copy::copy($from, $to);
 694     }
 695     $packlist->{$xto} = { type => 'file' };
 696 }
 697
 698 sub installlib {
 699     my $dir = $File::Find::dir;
 700     $dir =~ s#^\.(?![^/])/?##;
 701     local($depth) = $dir ? "lib/$dir" : "lib";
 702
 703     my $name = $_;
 704
 705     # Ignore version control directories.
 706     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
 707         $File::Find::prune = 1;
 708         return;
 709     }
 710
 711     # ignore patch backups, RCS files, emacs backup & temp files and the
 712     # .exists files, .PL files, and test files.
 713     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$|^dbm_filter_util.pl$} ||
 714               $dir  =~ m{/t(?:/|$)};
 715     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
 716     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
 717     # the corelist script from lib/Module/CoreList/bin and ptar* in
 718     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
 719     # (they're installed later with other utils)
 720     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|cpan2dist|cpanp|cpanp-run-perl|ptardiff|config_data)\z/;
 721     # ignore the Makefiles
 722     return if $name =~ /^makefile$/i;
 723     # ignore the test extensions
 724     return if $dir =~ m{\bXS/(?:APItest|Typemap)\b};
 725     return if $name =~ m{\b(?:APItest|Typemap)\.pm$};
 726     # ignore the demo files
 727     return if $dir =~ /\b(?:demos?|eg)\b/;
 728
 729     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
 730     # Changes.e2x and README.e2x are needed by enc2xs.
 731     return if $name =~ m{^(?:README(?:\.\w+)?)$} && $name ne 'README.e2x';
 732     return if $name =~ m{^(?:MANIFEST|META\.yml)$};
 733     return if $name =~ m{^(?:INSTALL|TODO|BUGS|CREDITS)$}i;
 734     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
 735     return if $name =~ m{^(?:SIGNATURE|PAUSE200\d\.pub)$}; # CPAN files
 736     return if $name =~ m{^(?:NOTES|PATCHING)$}; # ExtUtils files
 737
 738     # if using a shared perl library then ignore:
 739     # - static library files [of statically linked extensions];
 740     # - import library files and export library files (only present on Win32
 741     #   anyway?) and empty bootstrap files [of dynamically linked extensions].
 742     return if $Config{useshrplib} eq 'true' and
 743              ($name =~ /$Config{_a}$/ or $name =~ /\.exp$/ or ($name =~ /\.bs$/ and -z $name));
 744
 745     $name = "$dir/$name" if $dir ne '';
 746
 747     my $installlib = $installprivlib;
 748     if ($dir =~ /^auto/ ||
 749           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 750           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
 751           $name eq 'Config_heavy.pl'
 752        ) {
 753         $installlib = $installarchlib;
 754         return unless $do_installarchlib;
 755     } else {
 756         return unless $do_installprivlib;
 757     }
 758
 759     if (-f $_) {
 760         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$])) {
 761             $installlib = $installprivlib;
 762             #We're installing *.al and *.ix files into $installprivlib,
 763             #but we have to delete old *.al and *.ix files from the 5.000
 764             #distribution:
 765             #This might not work because $archname might have changed.
 766             unlink("$installarchlib/$name");
 767         }
 768         my $xname = "$installlib/$name";
 769         $xname =~ s/^\Q$opts{destdir}\E// if $opts{destdir};
 770         $packlist->{$xname} = { type => 'file' };
 771         if ($force || compare($_, "$installlib/$name") || $opts{notify}) {
 772             unlink("$installlib/$name");
 773             mkpath("$installlib/$dir", $opts{verbose}, 0777);
 774             # HP-UX (at least) needs to maintain execute permissions
 775             # on dynamically-loaded libraries.
 776             if ($Is_NetWare && !$nwinstall) {
 777                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 778                 # if copied will give problems when building new extensions.
 779                 # Has to be copied if we are installing on a NetWare server and hence
 780                 # the check !$nwinstall
 781                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 782                     copy_if_diff($_, "$installlib/$name")
 783                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 784                                   "$installlib/$name");
 785                 }
 786            } else {
 787                 if (copy_if_diff($_, "$installlib/$name")) {
 788                     if ($name =~ /\.(so|$dlext)$/o) {
 789                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 790                         chmod(0555, "$installlib/$name");
 791                     } else {
 792                         strip("-S", "$installlib/$name")
 793                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 794                         chmod(0444, "$installlib/$name");
 795                     }
 796                 }
 797             } #if ($Is_NetWare)
 798         }
 799     }
 800 }
 801
 802 # Copy $from to $to, only if $from is different than $to.
 803 # Also preserve modification times for .a libraries.
 804 # On some systems, if you do
 805 #   ranlib libperl.a
 806 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 807 # and then try to link against the installed libperl.a, you might
 808 # get an error message to the effect that the symbol table is older
 809 # than the library.
 810 # Return true if copying occurred.
 811
 812 sub copy_if_diff {
 813     my($from,$to)=@_;
 814     return 1 if (($^O eq 'VMS') && (-d $from));
 815     my $xto = $to;
 816     $xto =~ s/^\Q$opts{destdir}\E// if $opts{destdir};
 817     my $perlpodbadsymlink;
 818     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 819         -l $from &&
 820         ! -e $from) {
 821         # Some Linux implementations have problems traversing over
 822         # multiple symlinks (when going over NFS?) and fail to read
 823         # the symlink target.  Combine this with the fact that some
 824         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 825         # and you end up with those pods not getting installed.
 826         $perlpodbadsymlink = 1;
 827     }
 828     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 829     $packlist->{$xto} = { type => 'file' };
 830     if ($force || compare($from, $to) || $opts{notify}) {
 831         safe_unlink($to);   # In case we don't have write permissions.
 832         if ($opts{notify}) {
 833             $from = $depth . "/" . $from if $depth;
 834         }
 835         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 836             $from = "README.$1";
 837         }
 838         copy($from, $to);
 839         # Restore timestamps if it's a .a library or for OS/2.
 840         if (!$opts{notify} && ($Is_OS2 || $to =~ /\.a$/)) {
 841             my ($atime, $mtime) = (stat $from)[8,9];
 842             utime $atime, $mtime, $to;
 843         }
 844         1;
 845     }
 846 }
 847
 848 sub strip
 849 {
 850     my(@args) = @_;
 851
 852     return unless $dostrip;
 853
 854     my @opts;
 855     while (@args && $args[0] =~ /^(-\w+)$/) {
 856         push @opts, shift @args;
 857     }
 858
 859     foreach my $file (@args) {
 860         if (-f $file) {
 861             if ($opts{verbose}) {
 862                 print "  strip " . join(' ', @opts);
 863                 print " " if (@opts);
 864                 print "$file\n";
 865             }
 866             system("strip", @opts, $file);
 867         } else {
 868             print "# file '$file' skipped\n" if $opts{verbose};
 869         }
 870     }
 871 }