This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: [PATCH] Documentation patch for overload
[perl5.git] / lib / overload.pm
1 package overload;
2
3 our $VERSION = '1.04';
4
5 $overload::hint_bits = 0x20000; # HINT_LOCALIZE_HH
6
7 sub nil {}
8
9 sub OVERLOAD {
10   $package = shift;
11   my %arg = @_;
12   my ($sub, $fb);
13   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
14   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
15   for (keys %arg) {
16     if ($_ eq 'fallback') {
17       $fb = $arg{$_};
18     } else {
19       $sub = $arg{$_};
20       if (not ref $sub and $sub !~ /::/) {
21         $ {$package . "::(" . $_} = $sub;
22         $sub = \&nil;
23       }
24       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
25       *{$package . "::(" . $_} = \&{ $sub };
26     }
27   }
28   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
29 }
30
31 sub import {
32   $package = (caller())[0];
33   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
34   shift;
35   $package->overload::OVERLOAD(@_);
36 }
37
38 sub unimport {
39   $package = (caller())[0];
40   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
41   shift;
42   for (@_) {
43     if ($_ eq 'fallback') {
44       undef $ {$package . "::()"};
45     } else {
46       delete $ {$package . "::"}{"(" . $_};
47     }
48   }
49 }
50
51 sub Overloaded {
52   my $package = shift;
53   $package = ref $package if ref $package;
54   $package->can('()');
55 }
56
57 sub ov_method {
58   my $globref = shift;
59   return undef unless $globref;
60   my $sub = \&{*$globref};
61   return $sub if $sub ne \&nil;
62   return shift->can($ {*$globref});
63 }
64
65 sub OverloadedStringify {
66   my $package = shift;
67   $package = ref $package if ref $package;
68   #$package->can('(""')
69   ov_method mycan($package, '(""'), $package
70     or ov_method mycan($package, '(0+'), $package
71     or ov_method mycan($package, '(bool'), $package
72     or ov_method mycan($package, '(nomethod'), $package;
73 }
74
75 sub Method {
76   my $package = shift;
77   $package = ref $package if ref $package;
78   #my $meth = $package->can('(' . shift);
79   ov_method mycan($package, '(' . shift), $package;
80   #return $meth if $meth ne \&nil;
81   #return $ {*{$meth}};
82 }
83
84 sub AddrRef {
85   my $package = ref $_[0];
86   return "$_[0]" unless $package;
87
88         require Scalar::Util;
89         my $class = Scalar::Util::blessed($_[0]);
90         my $class_prefix = defined($class) ? "$class=" : "";
91         my $type = Scalar::Util::reftype($_[0]);
92         my $addr = Scalar::Util::refaddr($_[0]);
93         return sprintf("$class_prefix$type(0x%x)", $addr);
94 }
95
96 *StrVal = *AddrRef;
97
98 sub mycan {                             # Real can would leave stubs.
99   my ($package, $meth) = @_;
100   return \*{$package . "::$meth"} if defined &{$package . "::$meth"};
101   my $p;
102   foreach $p (@{$package . "::ISA"}) {
103     my $out = mycan($p, $meth);
104     return $out if $out;
105   }
106   return undef;
107 }
108
109 %constants = (
110               'integer'   =>  0x1000, # HINT_NEW_INTEGER
111               'float'     =>  0x2000, # HINT_NEW_FLOAT
112               'binary'    =>  0x4000, # HINT_NEW_BINARY
113               'q'         =>  0x8000, # HINT_NEW_STRING
114               'qr'        => 0x10000, # HINT_NEW_RE
115              );
116
117 %ops = ( with_assign      => "+ - * / % ** << >> x .",
118          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
119          num_comparison   => "< <= >  >= == !=",
120          '3way_comparison'=> "<=> cmp",
121          str_comparison   => "lt le gt ge eq ne",
122          binary           => "& | ^",
123          unary            => "neg ! ~",
124          mutators         => '++ --',
125          func             => "atan2 cos sin exp abs log sqrt int",
126          conversion       => 'bool "" 0+',
127          iterators        => '<>',
128          dereferencing    => '${} @{} %{} &{} *{}',
129          special          => 'nomethod fallback =');
130
131 use warnings::register;
132 sub constant {
133   # Arguments: what, sub
134   while (@_) {
135     if (@_ == 1) {
136         warnings::warnif ("Odd number of arguments for overload::constant");
137         last;
138     }
139     elsif (!exists $constants {$_ [0]}) {
140         warnings::warnif ("`$_[0]' is not an overloadable type");
141     }
142     elsif (!ref $_ [1] || "$_[1]" !~ /CODE\(0x[\da-f]+\)$/) {
143         # Can't use C<ref $_[1] eq "CODE"> above as code references can be
144         # blessed, and C<ref> would return the package the ref is blessed into.
145         if (warnings::enabled) {
146             $_ [1] = "undef" unless defined $_ [1];
147             warnings::warn ("`$_[1]' is not a code reference");
148         }
149     }
150     else {
151         $^H{$_[0]} = $_[1];
152         $^H |= $constants{$_[0]} | $overload::hint_bits;
153     }
154     shift, shift;
155   }
156 }
157
158 sub remove_constant {
159   # Arguments: what, sub
160   while (@_) {
161     delete $^H{$_[0]};
162     $^H &= ~ $constants{$_[0]};
163     shift, shift;
164   }
165 }
166
167 1;
168
169 __END__
170
171 =head1 NAME
172
173 overload - Package for overloading Perl operations
174
175 =head1 SYNOPSIS
176
177     package SomeThing;
178
179     use overload
180         '+' => \&myadd,
181         '-' => \&mysub;
182         # etc
183     ...
184
185     package main;
186     $a = new SomeThing 57;
187     $b=5+$a;
188     ...
189     if (overload::Overloaded $b) {...}
190     ...
191     $strval = overload::StrVal $b;
192
193 =head1 DESCRIPTION
194
195 =head2 Declaration of overloaded functions
196
197 The compilation directive
198
199     package Number;
200     use overload
201         "+" => \&add,
202         "*=" => "muas";
203
204 declares function Number::add() for addition, and method muas() in
205 the "class" C<Number> (or one of its base classes)
206 for the assignment form C<*=> of multiplication.
207
208 Arguments of this directive come in (key, value) pairs.  Legal values
209 are values legal inside a C<&{ ... }> call, so the name of a
210 subroutine, a reference to a subroutine, or an anonymous subroutine
211 will all work.  Note that values specified as strings are
212 interpreted as methods, not subroutines.  Legal keys are listed below.
213
214 The subroutine C<add> will be called to execute C<$a+$b> if $a
215 is a reference to an object blessed into the package C<Number>, or if $a is
216 not an object from a package with defined mathemagic addition, but $b is a
217 reference to a C<Number>.  It can also be called in other situations, like
218 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
219 methods refer to methods triggered by an overloaded mathematical
220 operator.)
221
222 Since overloading respects inheritance via the @ISA hierarchy, the
223 above declaration would also trigger overloading of C<+> and C<*=> in
224 all the packages which inherit from C<Number>.
225
226 =head2 Calling Conventions for Binary Operations
227
228 The functions specified in the C<use overload ...> directive are called
229 with three (in one particular case with four, see L<Last Resort>)
230 arguments.  If the corresponding operation is binary, then the first
231 two arguments are the two arguments of the operation.  However, due to
232 general object calling conventions, the first argument should always be
233 an object in the package, so in the situation of C<7+$a>, the
234 order of the arguments is interchanged.  It probably does not matter
235 when implementing the addition method, but whether the arguments
236 are reversed is vital to the subtraction method.  The method can
237 query this information by examining the third argument, which can take
238 three different values:
239
240 =over 7
241
242 =item FALSE
243
244 the order of arguments is as in the current operation.
245
246 =item TRUE
247
248 the arguments are reversed.
249
250 =item C<undef>
251
252 the current operation is an assignment variant (as in
253 C<$a+=7>), but the usual function is called instead.  This additional
254 information can be used to generate some optimizations.  Compare
255 L<Calling Conventions for Mutators>.
256
257 =back
258
259 =head2 Calling Conventions for Unary Operations
260
261 Unary operation are considered binary operations with the second
262 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
263 is called with arguments C<($a,undef,'')> when $a++ is executed.
264
265 =head2 Calling Conventions for Mutators
266
267 Two types of mutators have different calling conventions:
268
269 =over
270
271 =item C<++> and C<-->
272
273 The routines which implement these operators are expected to actually
274 I<mutate> their arguments.  So, assuming that $obj is a reference to a
275 number,
276
277   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
278
279 is an appropriate implementation of overloaded C<++>.  Note that
280
281   sub incr { ++$ {$_[0]} ; shift }
282
283 is OK if used with preincrement and with postincrement. (In the case
284 of postincrement a copying will be performed, see L<Copy Constructor>.)
285
286 =item C<x=> and other assignment versions
287
288 There is nothing special about these methods.  They may change the
289 value of their arguments, and may leave it as is.  The result is going
290 to be assigned to the value in the left-hand-side if different from
291 this value.
292
293 This allows for the same method to be used as overloaded C<+=> and
294 C<+>.  Note that this is I<allowed>, but not recommended, since by the
295 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
296 if C<+=> is not overloaded.
297
298 =back
299
300 B<Warning.>  Due to the presence of assignment versions of operations,
301 routines which may be called in assignment context may create
302 self-referential structures.  Currently Perl will not free self-referential
303 structures until cycles are C<explicitly> broken.  You may get problems
304 when traversing your structures too.
305
306 Say,
307
308   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
309
310 is asking for trouble, since for code C<$obj += $foo> the subroutine
311 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj,
312 \$foo]>.  If using such a subroutine is an important optimization, one
313 can overload C<+=> explicitly by a non-"optimized" version, or switch
314 to non-optimized version if C<not defined $_[2]> (see
315 L<Calling Conventions for Binary Operations>).
316
317 Even if no I<explicit> assignment-variants of operators are present in
318 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
319 C<',' . $obj . ','> may be both optimized to
320
321   my $tmp = ',' . $obj;    $tmp .= ',';
322
323 =head2 Overloadable Operations
324
325 The following symbols can be specified in C<use overload> directive:
326
327 =over 5
328
329 =item * I<Arithmetic operations>
330
331     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
332     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
333
334 For these operations a substituted non-assignment variant can be called if
335 the assignment variant is not available.  Methods for operations C<+>,
336 C<->, C<+=>, and C<-=> can be called to automatically generate
337 increment and decrement methods.  The operation C<-> can be used to
338 autogenerate missing methods for unary minus or C<abs>.
339
340 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
341 L<"Calling Conventions for Binary Operations">) for details of these
342 substitutions.
343
344 =item * I<Comparison operations>
345
346     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
347     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
348
349 If the corresponding "spaceship" variant is available, it can be
350 used to substitute for the missing operation.  During C<sort>ing
351 arrays, C<cmp> is used to compare values subject to C<use overload>.
352
353 =item * I<Bit operations>
354
355     "&", "^", "|", "neg", "!", "~",
356
357 C<neg> stands for unary minus.  If the method for C<neg> is not
358 specified, it can be autogenerated using the method for
359 subtraction. If the method for C<!> is not specified, it can be
360 autogenerated using the methods for C<bool>, or C<"">, or C<0+>.
361
362 =item * I<Increment and decrement>
363
364     "++", "--",
365
366 If undefined, addition and subtraction methods can be
367 used instead.  These operations are called both in prefix and
368 postfix form.
369
370 =item * I<Transcendental functions>
371
372     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt", "int"
373
374 If C<abs> is unavailable, it can be autogenerated using methods
375 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
376
377 Note that traditionally the Perl function L<int> rounds to 0, thus for
378 floating-point-like types one should follow the same semantic.  If
379 C<int> is unavailable, it can be autogenerated using the overloading of
380 C<0+>.
381
382 =item * I<Boolean, string and numeric conversion>
383
384     'bool', '""', '0+',
385
386 If one or two of these operations are not overloaded, the remaining ones can
387 be used instead.  C<bool> is used in the flow control operators
388 (like C<while>) and for the ternary C<?:> operation.  These functions can
389 return any arbitrary Perl value.  If the corresponding operation for this value
390 is overloaded too, that operation will be called again with this value.
391
392 As a special case if the overload returns the object itself then it will
393 be used directly. An overloaded conversion returning the object is
394 probably a bug, because you're likely to get something that looks like
395 C<YourPackage=HASH(0x8172b34)>.
396
397 =item * I<Iteration>
398
399     "<>"
400
401 If not overloaded, the argument will be converted to a filehandle or
402 glob (which may require a stringification).  The same overloading
403 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
404 I<globbing> syntax C<E<lt>${var}E<gt>>.
405
406 B<BUGS> Even in list context, the iterator is currently called only
407 once and with scalar context.
408
409 =item * I<Dereferencing>
410
411     '${}', '@{}', '%{}', '&{}', '*{}'.
412
413 If not overloaded, the argument will be dereferenced I<as is>, thus
414 should be of correct type.  These functions should return a reference
415 of correct type, or another object with overloaded dereferencing.
416
417 As a special case if the overload returns the object itself then it
418 will be used directly (provided it is the correct type).
419
420 The dereference operators must be specified explicitly they will not be passed to
421 "nomethod".
422
423 =item * I<Special>
424
425     "nomethod", "fallback", "=", "~~",
426
427 see L<SPECIAL SYMBOLS FOR C<use overload>>.
428
429 =back
430
431 See L<"Fallback"> for an explanation of when a missing method can be
432 autogenerated.
433
434 A computer-readable form of the above table is available in the hash
435 %overload::ops, with values being space-separated lists of names:
436
437  with_assign      => '+ - * / % ** << >> x .',
438  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
439  num_comparison   => '< <= > >= == !=',
440  '3way_comparison'=> '<=> cmp',
441  str_comparison   => 'lt le gt ge eq ne',
442  binary           => '& | ^',
443  unary            => 'neg ! ~',
444  mutators         => '++ --',
445  func             => 'atan2 cos sin exp abs log sqrt',
446  conversion       => 'bool "" 0+',
447  iterators        => '<>',
448  dereferencing    => '${} @{} %{} &{} *{}',
449  special          => 'nomethod fallback ='
450
451 =head2 Inheritance and overloading
452
453 Inheritance interacts with overloading in two ways.
454
455 =over
456
457 =item Strings as values of C<use overload> directive
458
459 If C<value> in
460
461   use overload key => value;
462
463 is a string, it is interpreted as a method name.
464
465 =item Overloading of an operation is inherited by derived classes
466
467 Any class derived from an overloaded class is also overloaded.  The
468 set of overloaded methods is the union of overloaded methods of all
469 the ancestors. If some method is overloaded in several ancestor, then
470 which description will be used is decided by the usual inheritance
471 rules:
472
473 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
474 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
475 then the subroutine C<D::plus_sub> will be called to implement
476 operation C<+> for an object in package C<A>.
477
478 =back
479
480 Note that since the value of the C<fallback> key is not a subroutine,
481 its inheritance is not governed by the above rules.  In the current
482 implementation, the value of C<fallback> in the first overloaded
483 ancestor is used, but this is accidental and subject to change.
484
485 =head1 SPECIAL SYMBOLS FOR C<use overload>
486
487 Three keys are recognized by Perl that are not covered by the above
488 description.
489
490 =head2 Last Resort
491
492 C<"nomethod"> should be followed by a reference to a function of four
493 parameters.  If defined, it is called when the overloading mechanism
494 cannot find a method for some operation.  The first three arguments of
495 this function coincide with the arguments for the corresponding method if
496 it were found, the fourth argument is the symbol
497 corresponding to the missing method.  If several methods are tried,
498 the last one is used.  Say, C<1-$a> can be equivalent to
499
500         &nomethodMethod($a,1,1,"-")
501
502 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
503 C<use overload> directive.
504
505 The C<"nomethod"> mechanism is I<not> used for the dereference operators
506 ( ${} @{} %{} &{} *{} ).
507
508
509 If some operation cannot be resolved, and there is no function
510 assigned to C<"nomethod">, then an exception will be raised via die()--
511 unless C<"fallback"> was specified as a key in C<use overload> directive.
512
513
514 =head2 Fallback
515
516 The key C<"fallback"> governs what to do if a method for a particular
517 operation is not found.  Three different cases are possible depending on
518 the value of C<"fallback">:
519
520 =head2 Smart Match
521
522 The key C<"~~"> allows you to override the smart matching used by
523 the switch construct. See L<feature>.
524
525 =over 16
526
527 =item * C<undef>
528
529 Perl tries to use a
530 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
531 then tries to calls C<"nomethod"> value; if missing, an exception
532 will be raised.
533
534 =item * TRUE
535
536 The same as for the C<undef> value, but no exception is raised.  Instead,
537 it silently reverts to what it would have done were there no C<use overload>
538 present.
539
540 =item * defined, but FALSE
541
542 No autogeneration is tried.  Perl tries to call
543 C<"nomethod"> value, and if this is missing, raises an exception.
544
545 =back
546
547 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
548 yet, see L<"Inheritance and overloading">.
549
550 =head2 Copy Constructor
551
552 The value for C<"="> is a reference to a function with three
553 arguments, i.e., it looks like the other values in C<use
554 overload>. However, it does not overload the Perl assignment
555 operator. This would go against Camel hair.
556
557 This operation is called in the situations when a mutator is applied
558 to a reference that shares its object with some other reference, such
559 as
560
561         $a=$b;
562         ++$a;
563
564 To make this change $a and not change $b, a copy of C<$$a> is made,
565 and $a is assigned a reference to this new object.  This operation is
566 done during execution of the C<++$a>, and not during the assignment,
567 (so before the increment C<$$a> coincides with C<$$b>).  This is only
568 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
569 C<nomethod>).  Note that if this operation is expressed via C<'+'>
570 a nonmutator, i.e., as in
571
572         $a=$b;
573         $a=$a+1;
574
575 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
576 appear as lvalue when the above code is executed.
577
578 If the copy constructor is required during the execution of some mutator,
579 but a method for C<'='> was not specified, it can be autogenerated as a
580 string copy if the object is a plain scalar.
581
582 =over 5
583
584 =item B<Example>
585
586 The actually executed code for
587
588         $a=$b;
589         Something else which does not modify $a or $b....
590         ++$a;
591
592 may be
593
594         $a=$b;
595         Something else which does not modify $a or $b....
596         $a = $a->clone(undef,"");
597         $a->incr(undef,"");
598
599 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
600 C<'='> was overloaded with C<\&clone>.
601
602 =back
603
604 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
605 C<$b = $a; ++$a>.
606
607 =head1 MAGIC AUTOGENERATION
608
609 If a method for an operation is not found, and the value for  C<"fallback"> is
610 TRUE or undefined, Perl tries to autogenerate a substitute method for
611 the missing operation based on the defined operations.  Autogenerated method
612 substitutions are possible for the following operations:
613
614 =over 16
615
616 =item I<Assignment forms of arithmetic operations>
617
618 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
619 is not defined.
620
621 =item I<Conversion operations>
622
623 String, numeric, and boolean conversion are calculated in terms of one
624 another if not all of them are defined.
625
626 =item I<Increment and decrement>
627
628 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
629 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
630
631 =item C<abs($a)>
632
633 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
634
635 =item I<Unary minus>
636
637 can be expressed in terms of subtraction.
638
639 =item I<Negation>
640
641 C<!> and C<not> can be expressed in terms of boolean conversion, or
642 string or numerical conversion.
643
644 =item I<Concatenation>
645
646 can be expressed in terms of string conversion.
647
648 =item I<Comparison operations>
649
650 can be expressed in terms of its "spaceship" counterpart: either
651 C<E<lt>=E<gt>> or C<cmp>:
652
653     <, >, <=, >=, ==, !=        in terms of <=>
654     lt, gt, le, ge, eq, ne      in terms of cmp
655
656 =item I<Iterator>
657
658     <>                          in terms of builtin operations
659
660 =item I<Dereferencing>
661
662     ${} @{} %{} &{} *{}         in terms of builtin operations
663
664 =item I<Copy operator>
665
666 can be expressed in terms of an assignment to the dereferenced value, if this
667 value is a scalar and not a reference.
668
669 =back
670
671 =head1 Minimal set of overloaded operations
672
673 Since some operations can be automatically generated from others, there is
674 a minimal set of operations that need to be overloaded in order to have
675 the complete set of overloaded operations at one's disposal.
676 Of course, the autogenerated operations may not do exactly what the user
677 expects. See L<MAGIC AUTOGENERATION> above. The minimal set is:
678
679     + - * / % ** << >> x
680     <=> cmp
681     & | ^ ~
682     atan2 cos sin exp log sqrt int
683
684 Additionally, you need to define at least one of string, boolean or
685 numeric conversions because any one can be used to emulate the others.
686 The string conversion can also be used to emulate concatenation.
687
688 =head1 Losing overloading
689
690 The restriction for the comparison operation is that even if, for example,
691 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
692 function will produce only a standard logical value based on the
693 numerical value of the result of `C<cmp>'.  In particular, a working
694 numeric conversion is needed in this case (possibly expressed in terms of
695 other conversions).
696
697 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
698 if the string conversion substitution is applied.
699
700 When you chop() a mathemagical object it is promoted to a string and its
701 mathemagical properties are lost.  The same can happen with other
702 operations as well.
703
704 =head1 Run-time Overloading
705
706 Since all C<use> directives are executed at compile-time, the only way to
707 change overloading during run-time is to
708
709     eval 'use overload "+" => \&addmethod';
710
711 You can also use
712
713     eval 'no overload "+", "--", "<="';
714
715 though the use of these constructs during run-time is questionable.
716
717 =head1 Public functions
718
719 Package C<overload.pm> provides the following public functions:
720
721 =over 5
722
723 =item overload::StrVal(arg)
724
725 Gives string value of C<arg> as in absence of stringify overloading. If you
726 are using this to get the address of a reference (useful for checking if two
727 references point to the same thing) then you may be better off using
728 C<Scalar::Util::refaddr()>, which is faster.
729
730 =item overload::Overloaded(arg)
731
732 Returns true if C<arg> is subject to overloading of some operations.
733
734 =item overload::Method(obj,op)
735
736 Returns C<undef> or a reference to the method that implements C<op>.
737
738 =back
739
740 =head1 Overloading constants
741
742 For some applications, the Perl parser mangles constants too much.
743 It is possible to hook into this process via C<overload::constant()>
744 and C<overload::remove_constant()> functions.
745
746 These functions take a hash as an argument.  The recognized keys of this hash
747 are:
748
749 =over 8
750
751 =item integer
752
753 to overload integer constants,
754
755 =item float
756
757 to overload floating point constants,
758
759 =item binary
760
761 to overload octal and hexadecimal constants,
762
763 =item q
764
765 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
766 strings and here-documents,
767
768 =item qr
769
770 to overload constant pieces of regular expressions.
771
772 =back
773
774 The corresponding values are references to functions which take three arguments:
775 the first one is the I<initial> string form of the constant, the second one
776 is how Perl interprets this constant, the third one is how the constant is used.
777 Note that the initial string form does not
778 contain string delimiters, and has backslashes in backslash-delimiter
779 combinations stripped (thus the value of delimiter is not relevant for
780 processing of this string).  The return value of this function is how this
781 constant is going to be interpreted by Perl.  The third argument is undefined
782 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
783 context (comes from strings, regular expressions, and single-quote HERE
784 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
785 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
786
787 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
788 it is expected that overloaded constant strings are equipped with reasonable
789 overloaded catenation operator, otherwise absurd results will result.
790 Similarly, negative numbers are considered as negations of positive constants.
791
792 Note that it is probably meaningless to call the functions overload::constant()
793 and overload::remove_constant() from anywhere but import() and unimport() methods.
794 From these methods they may be called as
795
796         sub import {
797           shift;
798           return unless @_;
799           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
800           overload::constant integer => sub {Math::BigInt->new(shift)};
801         }
802
803 =head1 IMPLEMENTATION
804
805 What follows is subject to change RSN.
806
807 The table of methods for all operations is cached in magic for the
808 symbol table hash for the package.  The cache is invalidated during
809 processing of C<use overload>, C<no overload>, new function
810 definitions, and changes in @ISA. However, this invalidation remains
811 unprocessed until the next C<bless>ing into the package. Hence if you
812 want to change overloading structure dynamically, you'll need an
813 additional (fake) C<bless>ing to update the table.
814
815 (Every SVish thing has a magic queue, and magic is an entry in that
816 queue.  This is how a single variable may participate in multiple
817 forms of magic simultaneously.  For instance, environment variables
818 regularly have two forms at once: their %ENV magic and their taint
819 magic. However, the magic which implements overloading is applied to
820 the stashes, which are rarely used directly, thus should not slow down
821 Perl.)
822
823 If an object belongs to a package using overload, it carries a special
824 flag.  Thus the only speed penalty during arithmetic operations without
825 overloading is the checking of this flag.
826
827 In fact, if C<use overload> is not present, there is almost no overhead
828 for overloadable operations, so most programs should not suffer
829 measurable performance penalties.  A considerable effort was made to
830 minimize the overhead when overload is used in some package, but the
831 arguments in question do not belong to packages using overload.  When
832 in doubt, test your speed with C<use overload> and without it.  So far
833 there have been no reports of substantial speed degradation if Perl is
834 compiled with optimization turned on.
835
836 There is no size penalty for data if overload is not used. The only
837 size penalty if overload is used in some package is that I<all> the
838 packages acquire a magic during the next C<bless>ing into the
839 package. This magic is three-words-long for packages without
840 overloading, and carries the cache table if the package is overloaded.
841
842 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is
843 carried out before any operation that can imply an assignment to the
844 object $a (or $b) refers to, like C<$a++>.  You can override this
845 behavior by defining your own copy constructor (see L<"Copy Constructor">).
846
847 It is expected that arguments to methods that are not explicitly supposed
848 to be changed are constant (but this is not enforced).
849
850 =head1 Metaphor clash
851
852 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
853 If it I<looks> counter intuitive to you, you are subject to a metaphor
854 clash.
855
856 Here is a Perl object metaphor:
857
858 I<  object is a reference to blessed data>
859
860 and an arithmetic metaphor:
861
862 I<  object is a thing by itself>.
863
864 The I<main> problem of overloading C<=> is the fact that these metaphors
865 imply different actions on the assignment C<$a = $b> if $a and $b are
866 objects.  Perl-think implies that $a becomes a reference to whatever
867 $b was referencing.  Arithmetic-think implies that the value of "object"
868 $a is changed to become the value of the object $b, preserving the fact
869 that $a and $b are separate entities.
870
871 The difference is not relevant in the absence of mutators.  After
872 a Perl-way assignment an operation which mutates the data referenced by $a
873 would change the data referenced by $b too.  Effectively, after
874 C<$a = $b> values of $a and $b become I<indistinguishable>.
875
876 On the other hand, anyone who has used algebraic notation knows the
877 expressive power of the arithmetic metaphor.  Overloading works hard
878 to enable this metaphor while preserving the Perlian way as far as
879 possible.  Since it is not possible to freely mix two contradicting
880 metaphors, overloading allows the arithmetic way to write things I<as
881 far as all the mutators are called via overloaded access only>.  The
882 way it is done is described in L<Copy Constructor>.
883
884 If some mutator methods are directly applied to the overloaded values,
885 one may need to I<explicitly unlink> other values which references the
886 same value:
887
888     $a = new Data 23;
889     ...
890     $b = $a;            # $b is "linked" to $a
891     ...
892     $a = $a->clone;     # Unlink $b from $a
893     $a->increment_by(4);
894
895 Note that overloaded access makes this transparent:
896
897     $a = new Data 23;
898     $b = $a;            # $b is "linked" to $a
899     $a += 4;            # would unlink $b automagically
900
901 However, it would not make
902
903     $a = new Data 23;
904     $a = 4;             # Now $a is a plain 4, not 'Data'
905
906 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
907 to an object do whatever you want.  It is just not the overload, but
908 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
909 which returns the object itself, and STORE() method which changes the
910 value of the object, one can reproduce the arithmetic metaphor in its
911 completeness, at least for variables which were tie()d from the start.
912
913 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
914
915 =head1 Cookbook
916
917 Please add examples to what follows!
918
919 =head2 Two-face scalars
920
921 Put this in F<two_face.pm> in your Perl library directory:
922
923   package two_face;             # Scalars with separate string and
924                                 # numeric values.
925   sub new { my $p = shift; bless [@_], $p }
926   use overload '""' => \&str, '0+' => \&num, fallback => 1;
927   sub num {shift->[1]}
928   sub str {shift->[0]}
929
930 Use it as follows:
931
932   require two_face;
933   my $seven = new two_face ("vii", 7);
934   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
935   print "seven contains `i'\n" if $seven =~ /i/;
936
937 (The second line creates a scalar which has both a string value, and a
938 numeric value.)  This prints:
939
940   seven=vii, seven=7, eight=8
941   seven contains `i'
942
943 =head2 Two-face references
944
945 Suppose you want to create an object which is accessible as both an
946 array reference and a hash reference.
947
948   package two_refs;
949   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
950   sub new {
951     my $p = shift;
952     bless \ [@_], $p;
953   }
954   sub gethash {
955     my %h;
956     my $self = shift;
957     tie %h, ref $self, $self;
958     \%h;
959   }
960
961   sub TIEHASH { my $p = shift; bless \ shift, $p }
962   my %fields;
963   my $i = 0;
964   $fields{$_} = $i++ foreach qw{zero one two three};
965   sub STORE {
966     my $self = ${shift()};
967     my $key = $fields{shift()};
968     defined $key or die "Out of band access";
969     $$self->[$key] = shift;
970   }
971   sub FETCH {
972     my $self = ${shift()};
973     my $key = $fields{shift()};
974     defined $key or die "Out of band access";
975     $$self->[$key];
976   }
977
978 Now one can access an object using both the array and hash syntax:
979
980   my $bar = new two_refs 3,4,5,6;
981   $bar->[2] = 11;
982   $bar->{two} == 11 or die 'bad hash fetch';
983
984 Note several important features of this example.  First of all, the
985 I<actual> type of $bar is a scalar reference, and we do not overload
986 the scalar dereference.  Thus we can get the I<actual> non-overloaded
987 contents of $bar by just using C<$$bar> (what we do in functions which
988 overload dereference).  Similarly, the object returned by the
989 TIEHASH() method is a scalar reference.
990
991 Second, we create a new tied hash each time the hash syntax is used.
992 This allows us not to worry about a possibility of a reference loop,
993 which would lead to a memory leak.
994
995 Both these problems can be cured.  Say, if we want to overload hash
996 dereference on a reference to an object which is I<implemented> as a
997 hash itself, the only problem one has to circumvent is how to access
998 this I<actual> hash (as opposed to the I<virtual> hash exhibited by the
999 overloaded dereference operator).  Here is one possible fetching routine:
1000
1001   sub access_hash {
1002     my ($self, $key) = (shift, shift);
1003     my $class = ref $self;
1004     bless $self, 'overload::dummy'; # Disable overloading of %{}
1005     my $out = $self->{$key};
1006     bless $self, $class;        # Restore overloading
1007     $out;
1008   }
1009
1010 To remove creation of the tied hash on each access, one may an extra
1011 level of indirection which allows a non-circular structure of references:
1012
1013   package two_refs1;
1014   use overload '%{}' => sub { ${shift()}->[1] },
1015                '@{}' => sub { ${shift()}->[0] };
1016   sub new {
1017     my $p = shift;
1018     my $a = [@_];
1019     my %h;
1020     tie %h, $p, $a;
1021     bless \ [$a, \%h], $p;
1022   }
1023   sub gethash {
1024     my %h;
1025     my $self = shift;
1026     tie %h, ref $self, $self;
1027     \%h;
1028   }
1029
1030   sub TIEHASH { my $p = shift; bless \ shift, $p }
1031   my %fields;
1032   my $i = 0;
1033   $fields{$_} = $i++ foreach qw{zero one two three};
1034   sub STORE {
1035     my $a = ${shift()};
1036     my $key = $fields{shift()};
1037     defined $key or die "Out of band access";
1038     $a->[$key] = shift;
1039   }
1040   sub FETCH {
1041     my $a = ${shift()};
1042     my $key = $fields{shift()};
1043     defined $key or die "Out of band access";
1044     $a->[$key];
1045   }
1046
1047 Now if $baz is overloaded like this, then C<$baz> is a reference to a
1048 reference to the intermediate array, which keeps a reference to an
1049 actual array, and the access hash.  The tie()ing object for the access
1050 hash is a reference to a reference to the actual array, so
1051
1052 =over
1053
1054 =item *
1055
1056 There are no loops of references.
1057
1058 =item *
1059
1060 Both "objects" which are blessed into the class C<two_refs1> are
1061 references to a reference to an array, thus references to a I<scalar>.
1062 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1063 overloaded operations.
1064
1065 =back
1066
1067 =head2 Symbolic calculator
1068
1069 Put this in F<symbolic.pm> in your Perl library directory:
1070
1071   package symbolic;             # Primitive symbolic calculator
1072   use overload nomethod => \&wrap;
1073
1074   sub new { shift; bless ['n', @_] }
1075   sub wrap {
1076     my ($obj, $other, $inv, $meth) = @_;
1077     ($obj, $other) = ($other, $obj) if $inv;
1078     bless [$meth, $obj, $other];
1079   }
1080
1081 This module is very unusual as overloaded modules go: it does not
1082 provide any usual overloaded operators, instead it provides the L<Last
1083 Resort> operator C<nomethod>.  In this example the corresponding
1084 subroutine returns an object which encapsulates operations done over
1085 the objects: C<new symbolic 3> contains C<['n', 3]>, C<2 + new
1086 symbolic 3> contains C<['+', 2, ['n', 3]]>.
1087
1088 Here is an example of the script which "calculates" the side of
1089 circumscribed octagon using the above package:
1090
1091   require symbolic;
1092   my $iter = 1;                 # 2**($iter+2) = 8
1093   my $side = new symbolic 1;
1094   my $cnt = $iter;
1095
1096   while ($cnt--) {
1097     $side = (sqrt(1 + $side**2) - 1)/$side;
1098   }
1099   print "OK\n";
1100
1101 The value of $side is
1102
1103   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1104                        undef], 1], ['n', 1]]
1105
1106 Note that while we obtained this value using a nice little script,
1107 there is no simple way to I<use> this value.  In fact this value may
1108 be inspected in debugger (see L<perldebug>), but ony if
1109 C<bareStringify> B<O>ption is set, and not via C<p> command.
1110
1111 If one attempts to print this value, then the overloaded operator
1112 C<""> will be called, which will call C<nomethod> operator.  The
1113 result of this operator will be stringified again, but this result is
1114 again of type C<symbolic>, which will lead to an infinite loop.
1115
1116 Add a pretty-printer method to the module F<symbolic.pm>:
1117
1118   sub pretty {
1119     my ($meth, $a, $b) = @{+shift};
1120     $a = 'u' unless defined $a;
1121     $b = 'u' unless defined $b;
1122     $a = $a->pretty if ref $a;
1123     $b = $b->pretty if ref $b;
1124     "[$meth $a $b]";
1125   }
1126
1127 Now one can finish the script by
1128
1129   print "side = ", $side->pretty, "\n";
1130
1131 The method C<pretty> is doing object-to-string conversion, so it
1132 is natural to overload the operator C<""> using this method.  However,
1133 inside such a method it is not necessary to pretty-print the
1134 I<components> $a and $b of an object.  In the above subroutine
1135 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1136 and $b.  If these components use overloading, the catenation operator
1137 will look for an overloaded operator C<.>; if not present, it will
1138 look for an overloaded operator C<"">.  Thus it is enough to use
1139
1140   use overload nomethod => \&wrap, '""' => \&str;
1141   sub str {
1142     my ($meth, $a, $b) = @{+shift};
1143     $a = 'u' unless defined $a;
1144     $b = 'u' unless defined $b;
1145     "[$meth $a $b]";
1146   }
1147
1148 Now one can change the last line of the script to
1149
1150   print "side = $side\n";
1151
1152 which outputs
1153
1154   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1155
1156 and one can inspect the value in debugger using all the possible
1157 methods.
1158
1159 Something is still amiss: consider the loop variable $cnt of the
1160 script.  It was a number, not an object.  We cannot make this value of
1161 type C<symbolic>, since then the loop will not terminate.
1162
1163 Indeed, to terminate the cycle, the $cnt should become false.
1164 However, the operator C<bool> for checking falsity is overloaded (this
1165 time via overloaded C<"">), and returns a long string, thus any object
1166 of type C<symbolic> is true.  To overcome this, we need a way to
1167 compare an object to 0.  In fact, it is easier to write a numeric
1168 conversion routine.
1169
1170 Here is the text of F<symbolic.pm> with such a routine added (and
1171 slightly modified str()):
1172
1173   package symbolic;             # Primitive symbolic calculator
1174   use overload
1175     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1176
1177   sub new { shift; bless ['n', @_] }
1178   sub wrap {
1179     my ($obj, $other, $inv, $meth) = @_;
1180     ($obj, $other) = ($other, $obj) if $inv;
1181     bless [$meth, $obj, $other];
1182   }
1183   sub str {
1184     my ($meth, $a, $b) = @{+shift};
1185     $a = 'u' unless defined $a;
1186     if (defined $b) {
1187       "[$meth $a $b]";
1188     } else {
1189       "[$meth $a]";
1190     }
1191   }
1192   my %subr = ( n => sub {$_[0]},
1193                sqrt => sub {sqrt $_[0]},
1194                '-' => sub {shift() - shift()},
1195                '+' => sub {shift() + shift()},
1196                '/' => sub {shift() / shift()},
1197                '*' => sub {shift() * shift()},
1198                '**' => sub {shift() ** shift()},
1199              );
1200   sub num {
1201     my ($meth, $a, $b) = @{+shift};
1202     my $subr = $subr{$meth}
1203       or die "Do not know how to ($meth) in symbolic";
1204     $a = $a->num if ref $a eq __PACKAGE__;
1205     $b = $b->num if ref $b eq __PACKAGE__;
1206     $subr->($a,$b);
1207   }
1208
1209 All the work of numeric conversion is done in %subr and num().  Of
1210 course, %subr is not complete, it contains only operators used in the
1211 example below.  Here is the extra-credit question: why do we need an
1212 explicit recursion in num()?  (Answer is at the end of this section.)
1213
1214 Use this module like this:
1215
1216   require symbolic;
1217   my $iter = new symbolic 2;    # 16-gon
1218   my $side = new symbolic 1;
1219   my $cnt = $iter;
1220
1221   while ($cnt) {
1222     $cnt = $cnt - 1;            # Mutator `--' not implemented
1223     $side = (sqrt(1 + $side**2) - 1)/$side;
1224   }
1225   printf "%s=%f\n", $side, $side;
1226   printf "pi=%f\n", $side*(2**($iter+2));
1227
1228 It prints (without so many line breaks)
1229
1230   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1231                           [n 1]] 2]]] 1]
1232      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1233   pi=3.182598
1234
1235 The above module is very primitive.  It does not implement
1236 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1237 (not required without mutators!), and implements only those arithmetic
1238 operations which are used in the example.
1239
1240 To implement most arithmetic operations is easy; one should just use
1241 the tables of operations, and change the code which fills %subr to
1242
1243   my %subr = ( 'n' => sub {$_[0]} );
1244   foreach my $op (split " ", $overload::ops{with_assign}) {
1245     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1246   }
1247   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1248   foreach my $op (split " ", "@overload::ops{ @bins }") {
1249     $subr{$op} = eval "sub {shift() $op shift()}";
1250   }
1251   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1252     print "defining `$op'\n";
1253     $subr{$op} = eval "sub {$op shift()}";
1254   }
1255
1256 Due to L<Calling Conventions for Mutators>, we do not need anything
1257 special to make C<+=> and friends work, except filling C<+=> entry of
1258 %subr, and defining a copy constructor (needed since Perl has no
1259 way to know that the implementation of C<'+='> does not mutate
1260 the argument, compare L<Copy Constructor>).
1261
1262 To implement a copy constructor, add C<< '=' => \&cpy >> to C<use overload>
1263 line, and code (this code assumes that mutators change things one level
1264 deep only, so recursive copying is not needed):
1265
1266   sub cpy {
1267     my $self = shift;
1268     bless [@$self], ref $self;
1269   }
1270
1271 To make C<++> and C<--> work, we need to implement actual mutators,
1272 either directly, or in C<nomethod>.  We continue to do things inside
1273 C<nomethod>, thus add
1274
1275     if ($meth eq '++' or $meth eq '--') {
1276       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1277       return $obj;
1278     }
1279
1280 after the first line of wrap().  This is not a most effective
1281 implementation, one may consider
1282
1283   sub inc { $_[0] = bless ['++', shift, 1]; }
1284
1285 instead.
1286
1287 As a final remark, note that one can fill %subr by
1288
1289   my %subr = ( 'n' => sub {$_[0]} );
1290   foreach my $op (split " ", $overload::ops{with_assign}) {
1291     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1292   }
1293   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1294   foreach my $op (split " ", "@overload::ops{ @bins }") {
1295     $subr{$op} = eval "sub {shift() $op shift()}";
1296   }
1297   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1298     $subr{$op} = eval "sub {$op shift()}";
1299   }
1300   $subr{'++'} = $subr{'+'};
1301   $subr{'--'} = $subr{'-'};
1302
1303 This finishes implementation of a primitive symbolic calculator in
1304 50 lines of Perl code.  Since the numeric values of subexpressions
1305 are not cached, the calculator is very slow.
1306
1307 Here is the answer for the exercise: In the case of str(), we need no
1308 explicit recursion since the overloaded C<.>-operator will fall back
1309 to an existing overloaded operator C<"">.  Overloaded arithmetic
1310 operators I<do not> fall back to numeric conversion if C<fallback> is
1311 not explicitly requested.  Thus without an explicit recursion num()
1312 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1313 the argument of num().
1314
1315 If you wonder why defaults for conversion are different for str() and
1316 num(), note how easy it was to write the symbolic calculator.  This
1317 simplicity is due to an appropriate choice of defaults.  One extra
1318 note: due to the explicit recursion num() is more fragile than sym():
1319 we need to explicitly check for the type of $a and $b.  If components
1320 $a and $b happen to be of some related type, this may lead to problems.
1321
1322 =head2 I<Really> symbolic calculator
1323
1324 One may wonder why we call the above calculator symbolic.  The reason
1325 is that the actual calculation of the value of expression is postponed
1326 until the value is I<used>.
1327
1328 To see it in action, add a method
1329
1330   sub STORE {
1331     my $obj = shift;
1332     $#$obj = 1;
1333     @$obj->[0,1] = ('=', shift);
1334   }
1335
1336 to the package C<symbolic>.  After this change one can do
1337
1338   my $a = new symbolic 3;
1339   my $b = new symbolic 4;
1340   my $c = sqrt($a**2 + $b**2);
1341
1342 and the numeric value of $c becomes 5.  However, after calling
1343
1344   $a->STORE(12);  $b->STORE(5);
1345
1346 the numeric value of $c becomes 13.  There is no doubt now that the module
1347 symbolic provides a I<symbolic> calculator indeed.
1348
1349 To hide the rough edges under the hood, provide a tie()d interface to the
1350 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1351
1352   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1353   sub FETCH { shift }
1354   sub nop {  }          # Around a bug
1355
1356 (the bug is described in L<"BUGS">).  One can use this new interface as
1357
1358   tie $a, 'symbolic', 3;
1359   tie $b, 'symbolic', 4;
1360   $a->nop;  $b->nop;    # Around a bug
1361
1362   my $c = sqrt($a**2 + $b**2);
1363
1364 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1365 of $c becomes 13.  To insulate the user of the module add a method
1366
1367   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1368
1369 Now
1370
1371   my ($a, $b);
1372   symbolic->vars($a, $b);
1373   my $c = sqrt($a**2 + $b**2);
1374
1375   $a = 3; $b = 4;
1376   printf "c5  %s=%f\n", $c, $c;
1377
1378   $a = 12; $b = 5;
1379   printf "c13  %s=%f\n", $c, $c;
1380
1381 shows that the numeric value of $c follows changes to the values of $a
1382 and $b.
1383
1384 =head1 AUTHOR
1385
1386 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1387
1388 =head1 DIAGNOSTICS
1389
1390 When Perl is run with the B<-Do> switch or its equivalent, overloading
1391 induces diagnostic messages.
1392
1393 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1394 deduce which operations are overloaded (and which ancestor triggers
1395 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1396 is shown by debugger. The method C<()> corresponds to the C<fallback>
1397 key (in fact a presence of this method shows that this package has
1398 overloading enabled, and it is what is used by the C<Overloaded>
1399 function of module C<overload>).
1400
1401 The module might issue the following warnings:
1402
1403 =over 4
1404
1405 =item Odd number of arguments for overload::constant
1406
1407 (W) The call to overload::constant contained an odd number of arguments.
1408 The arguments should come in pairs.
1409
1410 =item `%s' is not an overloadable type
1411
1412 (W) You tried to overload a constant type the overload package is unaware of.
1413
1414 =item `%s' is not a code reference
1415
1416 (W) The second (fourth, sixth, ...) argument of overload::constant needs
1417 to be a code reference. Either an anonymous subroutine, or a reference
1418 to a subroutine.
1419
1420 =back
1421
1422 =head1 BUGS
1423
1424 Because it is used for overloading, the per-package hash %OVERLOAD now
1425 has a special meaning in Perl. The symbol table is filled with names
1426 looking like line-noise.
1427
1428 For the purpose of inheritance every overloaded package behaves as if
1429 C<fallback> is present (possibly undefined). This may create
1430 interesting effects if some package is not overloaded, but inherits
1431 from two overloaded packages.
1432
1433 Relation between overloading and tie()ing is broken.  Overloading is
1434 triggered or not basing on the I<previous> class of tie()d value.
1435
1436 This happens because the presence of overloading is checked too early,
1437 before any tie()d access is attempted.  If the FETCH()ed class of the
1438 tie()d value does not change, a simple workaround is to access the value
1439 immediately after tie()ing, so that after this call the I<previous> class
1440 coincides with the current one.
1441
1442 B<Needed:> a way to fix this without a speed penalty.
1443
1444 Barewords are not covered by overloaded string constants.
1445
1446 This document is confusing.  There are grammos and misleading language
1447 used in places.  It would seem a total rewrite is needed.
1448
1449 =cut
1450