autodoc.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Unconditionally regenerate:
   4 #
   5 #    pod/perlintern.pod
   6 #    pod/perlapi.pod
   7 #
   8 # from information stored in
   9 #
  10 #    embed.fnc
  11 #    plus all the .c and .h files listed in MANIFEST
  12 #
  13 # Has an optional arg, which is the directory to chdir to before reading
  14 # MANIFEST and *.[ch].
  15 #
  16 # This script is invoked as part of 'make all'
  17 #
  18 # '=head1' are the only headings looked for.  If the first non-blank line after
  19 # the heading begins with a word character, it is considered to be the first
  20 # line of documentation that applies to the heading itself.  That is, it is
  21 # output immediately after the heading, before the first function, and not
  22 # indented. The next input line that is a pod directive terminates this
  23 # heading-level documentation.
  24
  25 # The meanings of the flags fields in embed.fnc and the source code is
  26 # documented at the top of embed.fnc.
  27
  28 use strict;
  29
  30 if (@ARGV) {
  31     my $workdir = shift;
  32     chdir $workdir
  33         or die "Couldn't chdir to '$workdir': $!";
  34 }
  35 require './regen/regen_lib.pl';
  36 require './regen/embed_lib.pl';
  37
  38 #
  39 # See database of global and static function prototypes in embed.fnc
  40 # This is used to generate prototype headers under various configurations,
  41 # export symbols lists for different platforms, and macros to provide an
  42 # implicit interpreter context argument.
  43 #
  44
  45 my %docs;
  46 my %funcflags;
  47 my %macro = (
  48              ax => 1,
  49              items => 1,
  50              ix => 1,
  51              svtype => 1,
  52             );
  53 my %missing;
  54
  55 my $curheader = "Unknown section";
  56
  57 sub autodoc ($$) { # parse a file and extract documentation info
  58     my($fh,$file) = @_;
  59     my($in, $doc, $line, $header_doc);
  60
  61     # Count lines easier
  62     my $get_next_line = sub { $line++; return <$fh> };
  63
  64 FUNC:
  65     while (defined($in = $get_next_line->())) {
  66         if ($in =~ /^#\s*define\s+([A-Za-z_][A-Za-z_0-9]+)\(/ &&
  67             ($file ne 'embed.h' || $file ne 'proto.h')) {
  68             $macro{$1} = $file;
  69             next FUNC;
  70         }
  71         if ($in=~ /^=head1 (.*)/) {
  72             $curheader = $1;
  73
  74             # If the next non-space line begins with a word char, then it is
  75             # the start of heading-ldevel documentation.
  76             if (defined($doc = $get_next_line->())) {
  77                 # Skip over empty lines
  78                 while ($doc =~ /^\s+$/) {
  79                     if (! defined($doc = $get_next_line->())) {
  80                         next FUNC;
  81                     }
  82                 }
  83
  84                 if ($doc !~ /^\w/) {
  85                     $in = $doc;
  86                     redo FUNC;
  87                 }
  88                 $header_doc = $doc;
  89
  90                 # Continue getting the heading-level documentation until read
  91                 # in any pod directive (or as a fail-safe, find a closing
  92                 # comment to this pod in a C language file
  93 HDR_DOC:
  94                 while (defined($doc = $get_next_line->())) {
  95                     if ($doc =~ /^=\w/) {
  96                         $in = $doc;
  97                         redo FUNC;
  98                     }
  99
 100                     if ($doc =~ m:^\s*\*/$:) {
 101                         warn "=cut missing? $file:$line:$doc";;
 102                         last HDR_DOC;
 103                     }
 104                     $header_doc .= $doc;
 105                 }
 106             }
 107             next FUNC;
 108         }
 109         if ($in =~ /^=for\s+apidoc\s+(.*?)\s*\n/) {
 110             my $proto_in_file = $1;
 111             my $proto = $proto_in_file;
 112             $proto = "||$proto" unless $proto =~ /\|/;
 113             my($flags, $ret, $name, @args) = split /\s*\|\s*/, $proto;
 114             $name or die <<EOS;
 115 Bad apidoc at $file line $.:
 116   $in
 117 Expected:
 118   =for apidoc flags|returntype|name|arg|arg|...
 119   =for apidoc flags|returntype|name
 120   =for apidoc name
 121 EOS
 122             warn ("'$name' not \\w+ in '$proto_in_file' in $file")
 123                         if $flags !~ /N/ && $name !~ / ^ [_[:alpha:]] \w* $ /x;
 124             my $docs = "";
 125 DOC:
 126             while (defined($doc = $get_next_line->())) {
 127
 128                 # Other pod commands are considered part of the current
 129                 # function's docs, so can have lists, etc.
 130                 last DOC if $doc =~ /^=(cut|for\s+apidoc|head)/;
 131                 if ($doc =~ m:^\*/$:) {
 132                     warn "=cut missing? $file:$line:$doc";;
 133                     last DOC;
 134                 }
 135                 $docs .= $doc;
 136             }
 137             $docs = "\n$docs" if $docs and $docs !~ /^\n/;
 138
 139             # If the entry is also in embed.fnc, it should be defined
 140             # completely there, but not here
 141             my $embed_docref = delete $funcflags{$name};
 142             if ($embed_docref and %$embed_docref) {
 143                 warn "embed.fnc entry overrides redundant information in"
 144                    . " '$proto_in_file' in $file" if $flags || $ret || @args;
 145                 $flags = $embed_docref->{'flags'};
 146                 $ret = $embed_docref->{'retval'};
 147                 @args = @{$embed_docref->{args}};
 148             } else {
 149                 $missing{$name} = $file;
 150             }
 151
 152             my $inline_where = $flags =~ /A/ ? 'api' : 'guts';
 153
 154             if (exists $docs{$inline_where}{$curheader}{$name}) {
 155                 warn "$0: duplicate API entry for '$name' in $inline_where/$curheader\n";
 156                 next;
 157             }
 158             $docs{$inline_where}{$curheader}{$name}
 159                 = [$flags, $docs, $ret, $file, @args];
 160
 161             # Create a special entry with an empty-string name for the
 162             # heading-level documentation.
 163             if (defined $header_doc) {
 164                 $docs{$inline_where}{$curheader}{""} = $header_doc;
 165                 undef $header_doc;
 166             }
 167
 168             if (defined $doc) {
 169                 if ($doc =~ /^=(?:for|head)/) {
 170                     $in = $doc;
 171                     redo FUNC;
 172                 }
 173             } else {
 174                 warn "$file:$line:$in";
 175             }
 176         }
 177     }
 178 }
 179
 180 sub docout ($$$) { # output the docs for one function
 181     my($fh, $name, $docref) = @_;
 182     my($flags, $docs, $ret, $file, @args) = @$docref;
 183     $name =~ s/\s*$//;
 184
 185     if ($flags =~ /D/) {
 186         $docs = "\n\nDEPRECATED!  It is planned to remove this function from a
 187 future release of Perl.  Do not use it for new code; remove it from
 188 existing code.\n\n$docs";
 189     }
 190     else {
 191         $docs = "\n\nNOTE: this function is experimental and may change or be
 192 removed without notice.\n\n$docs" if $flags =~ /x/;
 193     }
 194
 195     # Is Perl_, but no #define foo # Perl_foo
 196     my $p = $flags =~ /p/ && $flags =~ /o/ && $flags !~ /M/;
 197
 198     $docs .= "NOTE: the perl_ form of this function is deprecated.\n\n"
 199          if $flags =~ /O/;
 200     if ($p) {
 201         $docs .= "NOTE: this function must be explicitly called as Perl_$name";
 202         $docs .= " with an aTHX_ parameter" if $flags !~ /T/;
 203         $docs .= ".\n\n"
 204     }
 205
 206     print $fh "=item $name\nX<$name>\n$docs";
 207
 208     if ($flags =~ /U/) { # no usage
 209         warn("U and s flags are incompatible") if $flags =~ /s/;
 210         # nothing
 211     } else {
 212         if ($flags =~ /n/) { # no args
 213             warn("n flag without m") unless $flags =~ /m/;
 214             warn("n flag but apparently has args") if @args;
 215             print $fh "\t$ret\t$name";
 216         } else { # full usage
 217             my $n            = "Perl_"x$p . $name;
 218             my $large_ret    = length $ret > 7;
 219             my $indent_size  = 7+8 # nroff: 7 under =head + 8 under =item
 220                             +8+($large_ret ? 1 + length $ret : 8)
 221                             +length($n) + 1;
 222             my $indent;
 223             print $fh "\t$ret" . ($large_ret ? ' ' : "\t") . "$n(";
 224             my $long_args;
 225             for (@args) {
 226                 if ($indent_size + 2 + length > 79) {
 227                     $long_args=1;
 228                     $indent_size -= length($n) - 3;
 229                     last;
 230                 }
 231             }
 232             my $args = '';
 233             if ($p && $flags !~ /T/) {
 234                 $args = @args ? "pTHX_ " : "pTHX";
 235                 if ($long_args) { print $fh $args; $args = '' }
 236             }
 237             $long_args and print $fh "\n";
 238             my $first = !$long_args;
 239             while () {
 240                 if (!@args or
 241                     length $args
 242                     && $indent_size + 3 + length($args[0]) + length $args > 79
 243                 ) {
 244                     print $fh
 245                     $first ? '' : (
 246                         $indent //=
 247                         "\t".($large_ret ? " " x (1+length $ret) : "\t")
 248                         ." "x($long_args ? 4 : 1 + length $n)
 249                     ),
 250                     $args, (","x($args ne 'pTHX_ ') . "\n")x!!@args;
 251                     $args = $first = '';
 252                 }
 253                 @args or last;
 254                 $args .= ", "x!!(length $args && $args ne 'pTHX_ ')
 255                     . shift @args;
 256             }
 257             if ($long_args) { print $fh "\n", substr $indent, 0, -4 }
 258             print $fh ")";
 259         }
 260         print $fh ";" if $flags =~ /s/; # semicolon "dTHR;"
 261         print $fh "\n\n";
 262     }
 263     print $fh "=for hackers\nFound in file $file\n\n";
 264 }
 265
 266 sub sort_helper {
 267     # Do a case-insensitive dictionary sort, with only alphabetics
 268     # significant, falling back to using everything for determinancy
 269     return (uc($a =~ s/[[:^alpha:]]//r) cmp uc($b =~ s/[[:^alpha:]]//r))
 270            || uc($a) cmp uc($b)
 271            || $a cmp $b;
 272 }
 273
 274 sub output {
 275     my ($podname, $header, $dochash, $missing, $footer) = @_;
 276     #
 277     # strip leading '|' from each line which had been used to hide
 278     # pod from pod checkers.
 279     s/^\|//gm for $header, $footer;
 280
 281     my $fh = open_new("pod/$podname.pod", undef,
 282                       {by => "$0 extracting documentation",
 283                        from => 'the C source files'}, 1);
 284
 285     print $fh $header;
 286
 287     my $key;
 288     for $key (sort sort_helper keys %$dochash) {
 289         my $section = $dochash->{$key};
 290         print $fh "\n=head1 $key\n\n";
 291
 292         # Output any heading-level documentation and delete so won't get in
 293         # the way later
 294         if (exists $section->{""}) {
 295             print $fh $section->{""} . "\n";
 296             delete $section->{""};
 297         }
 298         print $fh "=over 8\n\n";
 299
 300         for my $key (sort sort_helper keys %$section) {
 301             docout($fh, $key, $section->{$key});
 302         }
 303         print $fh "\n=back\n";
 304     }
 305
 306     if (@$missing) {
 307         print $fh "\n=head1 Undocumented functions\n\n";
 308     print $fh $podname eq 'perlapi' ? <<'_EOB_' : <<'_EOB_';
 309 The following functions have been flagged as part of the public API,
 310 but are currently undocumented.  Use them at your own risk, as the
 311 interfaces are subject to change.  Functions that are not listed in this
 312 document are not intended for public use, and should NOT be used under any
 313 circumstances.
 314
 315 If you feel you need to use one of these functions, first send email to
 316 L<perl5-porters@perl.org|mailto:perl5-porters@perl.org>.  It may be
 317 that there is a good reason for the function not being documented, and it
 318 should be removed from this list; or it may just be that no one has gotten
 319 around to documenting it.  In the latter case, you will be asked to submit a
 320 patch to document the function.  Once your patch is accepted, it will indicate
 321 that the interface is stable (unless it is explicitly marked otherwise) and
 322 usable by you.
 323 _EOB_
 324 The following functions are currently undocumented.  If you use one of
 325 them, you may wish to consider creating and submitting documentation for
 326 it.
 327 _EOB_
 328     print $fh "\n=over\n\n";
 329
 330     for my $missing (sort @$missing) {
 331         print $fh "=item $missing\nX<$missing>\n\n";
 332     }
 333     print $fh "=back\n\n";
 334 }
 335     print $fh $footer, "=cut\n";
 336
 337     read_only_bottom_close_and_rename($fh);
 338 }
 339
 340 foreach (@{(setup_embed())[0]}) {
 341     next if @$_ < 2;
 342     my ($flags, $retval, $func, @args) = @$_;
 343     s/\b(?:NN|NULLOK)\b\s+//g for @args;
 344
 345     $funcflags{$func} = {
 346                          flags => $flags,
 347                          retval => $retval,
 348                          args => \@args,
 349                         };
 350 }
 351
 352 # glob() picks up docs from extra .c or .h files that may be in unclean
 353 # development trees.
 354 open my $fh, '<', 'MANIFEST'
 355     or die "Can't open MANIFEST: $!";
 356 while (my $line = <$fh>) {
 357     next unless my ($file) = $line =~ /^(\S+\.[ch])\t/;
 358
 359     open F, '<', $file or die "Cannot open $file for docs: $!\n";
 360     $curheader = "Functions in file $file\n";
 361     autodoc(\*F,$file);
 362     close F or die "Error closing $file: $!\n";
 363 }
 364 close $fh or die "Error whilst reading MANIFEST: $!";
 365
 366 for (sort keys %funcflags) {
 367     next unless $funcflags{$_}{flags} =~ /d/;
 368     warn "no docs for $_\n"
 369 }
 370
 371 foreach (sort keys %missing) {
 372     next if $macro{$_};
 373     # Heuristics for known not-a-function macros:
 374     next if /^[A-Z]/;
 375     next if /^dj?[A-Z]/;
 376
 377     warn "Function '$_', documented in $missing{$_}, not listed in embed.fnc";
 378 }
 379
 380 # walk table providing an array of components in each line to
 381 # subroutine, printing the result
 382
 383 # List of funcs in the public API that aren't also marked as experimental nor
 384 # deprecated.
 385 my @missing_api = grep $funcflags{$_}{flags} =~ /A/ && $funcflags{$_}{flags} !~ /[xD]/ && !$docs{api}{$_}, keys %funcflags;
 386 output('perlapi', <<'_EOB_', $docs{api}, \@missing_api, <<'_EOE_');
 387 |=encoding UTF-8
 388 |
 389 |=head1 NAME
 390 |
 391 |perlapi - autogenerated documentation for the perl public API
 392 |
 393 |=head1 DESCRIPTION
 394 |X<Perl API> X<API> X<api>
 395 |
 396 |This file contains the documentation of the perl public API generated by
 397 |F<embed.pl>, specifically a listing of functions, macros, flags, and variables
 398 |that may be used by extension writers.  L<At the end|/Undocumented functions>
 399 |is a list of functions which have yet to be documented.  The interfaces of
 400 |those are subject to change without notice.  Anything not listed here is
 401 |not part of the public API, and should not be used by extension writers at
 402 |all.  For these reasons, blindly using functions listed in proto.h is to be
 403 |avoided when writing extensions.
 404 |
 405 |In Perl, unlike C, a string of characters may generally contain embedded
 406 |C<NUL> characters.  Sometimes in the documentation a Perl string is referred
 407 |to as a "buffer" to distinguish it from a C string, but sometimes they are
 408 |both just referred to as strings.
 409 |
 410 |Note that all Perl API global variables must be referenced with the C<PL_>
 411 |prefix.  Again, those not listed here are not to be used by extension writers,
 412 |and can be changed or removed without notice; same with macros.
 413 |Some macros are provided for compatibility with the older,
 414 |unadorned names, but this support may be disabled in a future release.
 415 |
 416 |Perl was originally written to handle US-ASCII only (that is characters
 417 |whose ordinal numbers are in the range 0 - 127).
 418 |And documentation and comments may still use the term ASCII, when
 419 |sometimes in fact the entire range from 0 - 255 is meant.
 420 |
 421 |The non-ASCII characters below 256 can have various meanings, depending on
 422 |various things.  (See, most notably, L<perllocale>.)  But usually the whole
 423 |range can be referred to as ISO-8859-1.  Often, the term "Latin-1" (or
 424 |"Latin1") is used as an equivalent for ISO-8859-1.  But some people treat
 425 |"Latin1" as referring just to the characters in the range 128 through 255, or
 426 |somethimes from 160 through 255.
 427 |This documentation uses "Latin1" and "Latin-1" to refer to all 256 characters.
 428 |
 429 |Note that Perl can be compiled and run under either ASCII or EBCDIC (See
 430 |L<perlebcdic>).  Most of the documentation (and even comments in the code)
 431 |ignore the EBCDIC possibility.
 432 |For almost all purposes the differences are transparent.
 433 |As an example, under EBCDIC,
 434 |instead of UTF-8, UTF-EBCDIC is used to encode Unicode strings, and so
 435 |whenever this documentation refers to C<utf8>
 436 |(and variants of that name, including in function names),
 437 |it also (essentially transparently) means C<UTF-EBCDIC>.
 438 |But the ordinals of characters differ between ASCII, EBCDIC, and
 439 |the UTF- encodings, and a string encoded in UTF-EBCDIC may occupy a different
 440 |number of bytes than in UTF-8.
 441 |
 442 |The listing below is alphabetical, case insensitive.
 443 |
 444 _EOB_
 445 |
 446 |=head1 AUTHORS
 447 |
 448 |Until May 1997, this document was maintained by Jeff Okamoto
 449 |<okamoto@corp.hp.com>.  It is now maintained as part of Perl itself.
 450 |
 451 |With lots of help and suggestions from Dean Roehrich, Malcolm Beattie,
 452 |Andreas Koenig, Paul Hudson, Ilya Zakharevich, Paul Marquess, Neil
 453 |Bowers, Matthew Green, Tim Bunce, Spider Boardman, Ulrich Pfeifer,
 454 |Stephen McCamant, and Gurusamy Sarathy.
 455 |
 456 |API Listing originally by Dean Roehrich <roehrich@cray.com>.
 457 |
 458 |Updated to be autogenerated from comments in the source by Benjamin Stuhl.
 459 |
 460 |=head1 SEE ALSO
 461 |
 462 |L<perlguts>, L<perlxs>, L<perlxstut>, L<perlintern>
 463 |
 464 _EOE_
 465
 466 # List of non-static internal functions
 467 my @missing_guts =
 468  grep $funcflags{$_}{flags} !~ /[AS]/ && !$docs{guts}{$_}, keys %funcflags;
 469
 470 output('perlintern', <<'END', $docs{guts}, \@missing_guts, <<'END');
 471 |=head1 NAME
 472 |
 473 |perlintern - autogenerated documentation of purely B<internal>
 474 |Perl functions
 475 |
 476 |=head1 DESCRIPTION
 477 |X<internal Perl functions> X<interpreter functions>
 478 |
 479 |This file is the autogenerated documentation of functions in the
 480 |Perl interpreter that are documented using Perl's internal documentation
 481 |format but are not marked as part of the Perl API.  In other words,
 482 |B<they are not for use in extensions>!
 483 |
 484 END
 485 |
 486 |=head1 AUTHORS
 487 |
 488 |The autodocumentation system was originally added to the Perl core by
 489 |Benjamin Stuhl.  Documentation is by whoever was kind enough to
 490 |document their functions.
 491 |
 492 |=head1 SEE ALSO
 493 |
 494 |L<perlguts>, L<perlapi>
 495 |
 496 END