This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
27cb45ab9d4aebdc87e9d8eabf81224a9d08d7c9
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # There was an attempt when this was first rewritten to make it 5.8
8 # compatible, but that has now been abandoned, and newer constructs are used
9 # as convenient.
10
11 my $start_time;
12 BEGIN { # Get the time the script started running; do it at compilation to
13         # get it as close as possible
14     $start_time= time;
15 }
16
17 require 5.010_001;
18 use strict;
19 use warnings;
20 use Carp;
21 use Config;
22 use File::Find;
23 use File::Path;
24 use File::Spec;
25 use Text::Tabs;
26 use re "/aa";
27 use feature 'state';
28
29 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
30 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
31
32 sub NON_ASCII_PLATFORM { ord("A") != 65 }
33
34 ##########################################################################
35 #
36 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
37 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
38 # a pod file and .t files, depending on option parameters.
39 #
40 # The structure of this file is:
41 #   First these introductory comments; then
42 #   code needed for everywhere, such as debugging stuff; then
43 #   code to handle input parameters; then
44 #   data structures likely to be of external interest (some of which depend on
45 #       the input parameters, so follows them; then
46 #   more data structures and subroutine and package (class) definitions; then
47 #   the small actual loop to process the input files and finish up; then
48 #   a __DATA__ section, for the .t tests
49 #
50 # This program works on all releases of Unicode so far.  The outputs have been
51 # scrutinized most intently for release 5.1.  The others have been checked for
52 # somewhat more than just sanity.  It can handle all non-provisional Unicode
53 # character properties in those releases.
54 #
55 # This program is mostly about Unicode character (or code point) properties.
56 # A property describes some attribute or quality of a code point, like if it
57 # is lowercase or not, its name, what version of Unicode it was first defined
58 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
59 # possibilities by making all properties into mappings from each code point
60 # into some corresponding value.  In the case of it being lowercase or not,
61 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
62 # property maps each Unicode code point to a single value, called a "property
63 # value".  (Some more recently defined properties, map a code point to a set
64 # of values.)
65 #
66 # When using a property in a regular expression, what is desired isn't the
67 # mapping of the code point to its property's value, but the reverse (or the
68 # mathematical "inverse relation"): starting with the property value, "Does a
69 # code point map to it?"  These are written in a "compound" form:
70 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
71 # files containing the lists of code points that map to each such regular
72 # expression property value, one file per list
73 #
74 # There is also a single form shortcut that Perl adds for many of the commonly
75 # used properties.  This happens for all binary properties, plus script,
76 # general_category, and block properties.
77 #
78 # Thus the outputs of this program are files.  There are map files, mostly in
79 # the 'To' directory; and there are list files for use in regular expression
80 # matching, all in subdirectories of the 'lib' directory, with each
81 # subdirectory being named for the property that the lists in it are for.
82 # Bookkeeping, test, and documentation files are also generated.
83
84 my $matches_directory = 'lib';   # Where match (\p{}) files go.
85 my $map_directory = 'To';        # Where map files go.
86
87 # DATA STRUCTURES
88 #
89 # The major data structures of this program are Property, of course, but also
90 # Table.  There are two kinds of tables, very similar to each other.
91 # "Match_Table" is the data structure giving the list of code points that have
92 # a particular property value, mentioned above.  There is also a "Map_Table"
93 # data structure which gives the property's mapping from code point to value.
94 # There are two structures because the match tables need to be combined in
95 # various ways, such as constructing unions, intersections, complements, etc.,
96 # and the map ones don't.  And there would be problems, perhaps subtle, if
97 # a map table were inadvertently operated on in some of those ways.
98 # The use of separate classes with operations defined on one but not the other
99 # prevents accidentally confusing the two.
100 #
101 # At the heart of each table's data structure is a "Range_List", which is just
102 # an ordered list of "Ranges", plus ancillary information, and methods to
103 # operate on them.  A Range is a compact way to store property information.
104 # Each range has a starting code point, an ending code point, and a value that
105 # is meant to apply to all the code points between the two end points,
106 # inclusive.  For a map table, this value is the property value for those
107 # code points.  Two such ranges could be written like this:
108 #   0x41 .. 0x5A, 'Upper',
109 #   0x61 .. 0x7A, 'Lower'
110 #
111 # Each range also has a type used as a convenience to classify the values.
112 # Most ranges in this program will be Type 0, or normal, but there are some
113 # ranges that have a non-zero type.  These are used only in map tables, and
114 # are for mappings that don't fit into the normal scheme of things.  Mappings
115 # that require a hash entry to communicate with utf8.c are one example;
116 # another example is mappings for charnames.pm to use which indicate a name
117 # that is algorithmically determinable from its code point (and the reverse).
118 # These are used to significantly compact these tables, instead of listing
119 # each one of the tens of thousands individually.
120 #
121 # In a match table, the value of a range is irrelevant (and hence the type as
122 # well, which will always be 0), and arbitrarily set to the null string.
123 # Using the example above, there would be two match tables for those two
124 # entries, one named Upper would contain the 0x41..0x5A range, and the other
125 # named Lower would contain 0x61..0x7A.
126 #
127 # Actually, there are two types of range lists, "Range_Map" is the one
128 # associated with map tables, and "Range_List" with match tables.
129 # Again, this is so that methods can be defined on one and not the others so
130 # as to prevent operating on them in incorrect ways.
131 #
132 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
133 # in the perl core.  All tables could in theory be written, but some are
134 # suppressed because there is no current practical use for them.  It is easy
135 # to change which get written by changing various lists that are near the top
136 # of the actual code in this file.  The table data structures contain enough
137 # ancillary information to allow them to be treated as separate entities for
138 # writing, such as the path to each one's file.  There is a heading in each
139 # map table that gives the format of its entries, and what the map is for all
140 # the code points missing from it.  (This allows tables to be more compact.)
141 #
142 # The Property data structure contains one or more tables.  All properties
143 # contain a map table (except the $perl property which is a
144 # pseudo-property containing only match tables), and any properties that
145 # are usable in regular expression matches also contain various matching
146 # tables, one for each value the property can have.  A binary property can
147 # have two values, True and False (or Y and N, which are preferred by Unicode
148 # terminology).  Thus each of these properties will have a map table that
149 # takes every code point and maps it to Y or N (but having ranges cuts the
150 # number of entries in that table way down), and two match tables, one
151 # which has a list of all the code points that map to Y, and one for all the
152 # code points that map to N.  (For each binary property, a third table is also
153 # generated for the pseudo Perl property.  It contains the identical code
154 # points as the Y table, but can be written in regular expressions, not in the
155 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
156 # properties are binary, but some properties have several possible values,
157 # some have many, and properties like Name have a different value for every
158 # named code point.  Those will not, unless the controlling lists are changed,
159 # have their match tables written out.  But all the ones which can be used in
160 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
161 # a property would have either its map table or its match tables written but
162 # not both.  Again, what gets written is controlled by lists which can easily
163 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
164 # tables needed to reconstruct the Unicode db are now written out, while
165 # suppressing the Unicode .txt files that contain the data.  Our tables are
166 # much more compact than the .txt files, so a significant space savings was
167 # achieved.  Also, tables are not written out that are trivially derivable
168 # from tables that do get written.  So, there typically is no file containing
169 # the code points not matched by a binary property (the table for \P{} versus
170 # lowercase \p{}), since you just need to invert the True table to get the
171 # False table.
172
173 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
174 # how many match tables there are and the content of the maps.  This 'Type' is
175 # different than a range 'Type', so don't get confused by the two concepts
176 # having the same name.
177 #
178 # For information about the Unicode properties, see Unicode's UAX44 document:
179
180 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
181
182 # As stated earlier, this program will work on any release of Unicode so far.
183 # Most obvious problems in earlier data have NOT been corrected except when
184 # necessary to make Perl or this program work reasonably, and to keep out
185 # potential security issues.  For example, no folding information was given in
186 # early releases, so this program substitutes lower case instead, just so that
187 # a regular expression with the /i option will do something that actually
188 # gives the right results in many cases.  There are also a couple other
189 # corrections for version 1.1.5, commented at the point they are made.  As an
190 # example of corrections that weren't made (but could be) is this statement
191 # from DerivedAge.txt: "The supplementary private use code points and the
192 # non-character code points were assigned in version 2.0, but not specifically
193 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
194 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
195 # further down in these introductory comments.
196 #
197 # This program works on all non-provisional properties as of the current
198 # Unicode release, though the files for some are suppressed for various
199 # reasons.  You can change which are output by changing lists in this program.
200 #
201 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
202 # loose matchings rules (from Unicode TR18):
203 #
204 #    The recommended names for UCD properties and property values are in
205 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
206 #    [PropValue]. There are both abbreviated names and longer, more
207 #    descriptive names. It is strongly recommended that both names be
208 #    recognized, and that loose matching of property names be used,
209 #    whereby the case distinctions, whitespace, hyphens, and underbar
210 #    are ignored.
211 #
212 # The program still allows Fuzzy to override its determination of if loose
213 # matching should be used, but it isn't currently used, as it is no longer
214 # needed; the calculations it makes are good enough.
215 #
216 # SUMMARY OF HOW IT WORKS:
217 #
218 #   Process arguments
219 #
220 #   A list is constructed containing each input file that is to be processed
221 #
222 #   Each file on the list is processed in a loop, using the associated handler
223 #   code for each:
224 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
225 #            first.  These files name the properties and property values.
226 #            Objects are created of all the property and property value names
227 #            that the rest of the input should expect, including all synonyms.
228 #        The other input files give mappings from properties to property
229 #           values.  That is, they list code points and say what the mapping
230 #           is under the given property.  Some files give the mappings for
231 #           just one property; and some for many.  This program goes through
232 #           each file and populates the properties and their map tables from
233 #           them.  Some properties are listed in more than one file, and
234 #           Unicode has set up a precedence as to which has priority if there
235 #           is a conflict.  Thus the order of processing matters, and this
236 #           program handles the conflict possibility by processing the
237 #           overriding input files last, so that if necessary they replace
238 #           earlier values.
239 #        After this is all done, the program creates the property mappings not
240 #            furnished by Unicode, but derivable from what it does give.
241 #        The tables of code points that match each property value in each
242 #            property that is accessible by regular expressions are created.
243 #        The Perl-defined properties are created and populated.  Many of these
244 #            require data determined from the earlier steps
245 #        Any Perl-defined synonyms are created, and name clashes between Perl
246 #            and Unicode are reconciled and warned about.
247 #        All the properties are written to files
248 #        Any other files are written, and final warnings issued.
249 #
250 # For clarity, a number of operators have been overloaded to work on tables:
251 #   ~ means invert (take all characters not in the set).  The more
252 #       conventional '!' is not used because of the possibility of confusing
253 #       it with the actual boolean operation.
254 #   + means union
255 #   - means subtraction
256 #   & means intersection
257 # The precedence of these is the order listed.  Parentheses should be
258 # copiously used.  These are not a general scheme.  The operations aren't
259 # defined for a number of things, deliberately, to avoid getting into trouble.
260 # Operations are done on references and affect the underlying structures, so
261 # that the copy constructors for them have been overloaded to not return a new
262 # clone, but the input object itself.
263 #
264 # The bool operator is deliberately not overloaded to avoid confusion with
265 # "should it mean if the object merely exists, or also is non-empty?".
266 #
267 # WHY CERTAIN DESIGN DECISIONS WERE MADE
268 #
269 # This program needs to be able to run under miniperl.  Therefore, it uses a
270 # minimum of other modules, and hence implements some things itself that could
271 # be gotten from CPAN
272 #
273 # This program uses inputs published by the Unicode Consortium.  These can
274 # change incompatibly between releases without the Perl maintainers realizing
275 # it.  Therefore this program is now designed to try to flag these.  It looks
276 # at the directories where the inputs are, and flags any unrecognized files.
277 # It keeps track of all the properties in the files it handles, and flags any
278 # that it doesn't know how to handle.  It also flags any input lines that
279 # don't match the expected syntax, among other checks.
280 #
281 # It is also designed so if a new input file matches one of the known
282 # templates, one hopefully just needs to add it to a list to have it
283 # processed.
284 #
285 # As mentioned earlier, some properties are given in more than one file.  In
286 # particular, the files in the extracted directory are supposedly just
287 # reformattings of the others.  But they contain information not easily
288 # derivable from the other files, including results for Unihan (which isn't
289 # usually available to this program) and for unassigned code points.  They
290 # also have historically had errors or been incomplete.  In an attempt to
291 # create the best possible data, this program thus processes them first to
292 # glean information missing from the other files; then processes those other
293 # files to override any errors in the extracted ones.  Much of the design was
294 # driven by this need to store things and then possibly override them.
295 #
296 # It tries to keep fatal errors to a minimum, to generate something usable for
297 # testing purposes.  It always looks for files that could be inputs, and will
298 # warn about any that it doesn't know how to handle (the -q option suppresses
299 # the warning).
300 #
301 # Why is there more than one type of range?
302 #   This simplified things.  There are some very specialized code points that
303 #   have to be handled specially for output, such as Hangul syllable names.
304 #   By creating a range type (done late in the development process), it
305 #   allowed this to be stored with the range, and overridden by other input.
306 #   Originally these were stored in another data structure, and it became a
307 #   mess trying to decide if a second file that was for the same property was
308 #   overriding the earlier one or not.
309 #
310 # Why are there two kinds of tables, match and map?
311 #   (And there is a base class shared by the two as well.)  As stated above,
312 #   they actually are for different things.  Development proceeded much more
313 #   smoothly when I (khw) realized the distinction.  Map tables are used to
314 #   give the property value for every code point (actually every code point
315 #   that doesn't map to a default value).  Match tables are used for regular
316 #   expression matches, and are essentially the inverse mapping.  Separating
317 #   the two allows more specialized methods, and error checks so that one
318 #   can't just take the intersection of two map tables, for example, as that
319 #   is nonsensical.
320 #
321 # What about 'fate' and 'status'.  The concept of a table's fate was created
322 #   late when it became clear that something more was needed.  The difference
323 #   between this and 'status' is unclean, and could be improved if someone
324 #   wanted to spend the effort.
325 #
326 # DEBUGGING
327 #
328 # This program is written so it will run under miniperl.  Occasionally changes
329 # will cause an error where the backtrace doesn't work well under miniperl.
330 # To diagnose the problem, you can instead run it under regular perl, if you
331 # have one compiled.
332 #
333 # There is a good trace facility.  To enable it, first sub DEBUG must be set
334 # to return true.  Then a line like
335 #
336 # local $to_trace = 1 if main::DEBUG;
337 #
338 # can be added to enable tracing in its lexical scope (plus dynamic) or until
339 # you insert another line:
340 #
341 # local $to_trace = 0 if main::DEBUG;
342 #
343 # To actually trace, use a line like "trace $a, @b, %c, ...;
344 #
345 # Some of the more complex subroutines already have trace statements in them.
346 # Permanent trace statements should be like:
347 #
348 # trace ... if main::DEBUG && $to_trace;
349 #
350 # If there is just one or a few files that you're debugging, you can easily
351 # cause most everything else to be skipped.  Change the line
352 #
353 # my $debug_skip = 0;
354 #
355 # to 1, and every file whose object is in @input_file_objects and doesn't have
356 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
357 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
358 #
359 # To compare the output tables, it may be useful to specify the -annotate
360 # flag.  (As of this writing, this can't be done on a clean workspace, due to
361 # requirements in Text::Tabs used in this option; so first run mktables
362 # without this option.)  This option adds comment lines to each table, one for
363 # each non-algorithmically named character giving, currently its code point,
364 # name, and graphic representation if printable (and you have a font that
365 # knows about it).  This makes it easier to see what the particular code
366 # points are in each output table.  Non-named code points are annotated with a
367 # description of their status, and contiguous ones with the same description
368 # will be output as a range rather than individually.  Algorithmically named
369 # characters are also output as ranges, except when there are just a few
370 # contiguous ones.
371 #
372 # FUTURE ISSUES
373 #
374 # The program would break if Unicode were to change its names so that
375 # interior white space, underscores, or dashes differences were significant
376 # within property and property value names.
377 #
378 # It might be easier to use the xml versions of the UCD if this program ever
379 # would need heavy revision, and the ability to handle old versions was not
380 # required.
381 #
382 # There is the potential for name collisions, in that Perl has chosen names
383 # that Unicode could decide it also likes.  There have been such collisions in
384 # the past, with mostly Perl deciding to adopt the Unicode definition of the
385 # name.  However in the 5.2 Unicode beta testing, there were a number of such
386 # collisions, which were withdrawn before the final release, because of Perl's
387 # and other's protests.  These all involved new properties which began with
388 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
389 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
390 # Unicode document, so they are unlikely to be used by Unicode for another
391 # purpose.  However, they might try something beginning with 'In', or use any
392 # of the other Perl-defined properties.  This program will warn you of name
393 # collisions, and refuse to generate tables with them, but manual intervention
394 # will be required in this event.  One scheme that could be implemented, if
395 # necessary, would be to have this program generate another file, or add a
396 # field to mktables.lst that gives the date of first definition of a property.
397 # Each new release of Unicode would use that file as a basis for the next
398 # iteration.  And the Perl synonym addition code could sort based on the age
399 # of the property, so older properties get priority, and newer ones that clash
400 # would be refused; hence existing code would not be impacted, and some other
401 # synonym would have to be used for the new property.  This is ugly, and
402 # manual intervention would certainly be easier to do in the short run; lets
403 # hope it never comes to this.
404 #
405 # A NOTE ON UNIHAN
406 #
407 # This program can generate tables from the Unihan database.  But that db
408 # isn't normally available, so it is marked as optional.  Prior to version
409 # 5.2, this database was in a single file, Unihan.txt.  In 5.2 the database
410 # was split into 8 different files, all beginning with the letters 'Unihan'.
411 # If you plunk those files down into the directory mktables ($0) is in, this
412 # program will read them and automatically create tables for the properties
413 # from it that are listed in PropertyAliases.txt and PropValueAliases.txt,
414 # plus any you add to the @cjk_properties array and the @cjk_property_values
415 # array, being sure to add necessary '# @missings' lines to the latter.  For
416 # Unicode versions earlier than 5.2, most of the Unihan properties are not
417 # listed at all in PropertyAliases nor PropValueAliases.  This program assumes
418 # for these early releases that you want the properties that are specified in
419 # the 5.2 release.
420 #
421 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
422 # and filter_unihan_line() are the functions where this is done.  This program
423 # already does some adjusting to make the lines look more like the rest of the
424 # Unicode DB;  You can see what that is in filter_unihan_line()
425 #
426 # There is a bug in the 3.2 data file in which some values for the
427 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
428 # could be added to correct these; or for a particular installation, the
429 # Unihan.txt file could be edited to fix them.
430 #
431 # HOW TO ADD A FILE TO BE PROCESSED
432 #
433 # A new file from Unicode needs to have an object constructed for it in
434 # @input_file_objects, probably at the end or at the end of the extracted
435 # ones.  The program should warn you if its name will clash with others on
436 # restrictive file systems, like DOS.  If so, figure out a better name, and
437 # add lines to the README.perl file giving that.  If the file is a character
438 # property, it should be in the format that Unicode has implicitly
439 # standardized for such files for the more recently introduced ones.
440 # If so, the Input_file constructor for @input_file_objects can just be the
441 # file name and release it first appeared in.  If not, then it should be
442 # possible to construct an each_line_handler() to massage the line into the
443 # standardized form.
444 #
445 # For non-character properties, more code will be needed.  You can look at
446 # the existing entries for clues.
447 #
448 # UNICODE VERSIONS NOTES
449 #
450 # The Unicode UCD has had a number of errors in it over the versions.  And
451 # these remain, by policy, in the standard for that version.  Therefore it is
452 # risky to correct them, because code may be expecting the error.  So this
453 # program doesn't generally make changes, unless the error breaks the Perl
454 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
455 # for U+1105, which causes real problems for the algorithms for Jamo
456 # calculations, so it is changed here.
457 #
458 # But it isn't so clear cut as to what to do about concepts that are
459 # introduced in a later release; should they extend back to earlier releases
460 # where the concept just didn't exist?  It was easier to do this than to not,
461 # so that's what was done.  For example, the default value for code points not
462 # in the files for various properties was probably undefined until changed by
463 # some version.  No_Block for blocks is such an example.  This program will
464 # assign No_Block even in Unicode versions that didn't have it.  This has the
465 # benefit that code being written doesn't have to special case earlier
466 # versions; and the detriment that it doesn't match the Standard precisely for
467 # the affected versions.
468 #
469 # Here are some observations about some of the issues in early versions:
470 #
471 # Prior to version 3.0, there were 3 character decompositions.  These are not
472 # handled by Unicode::Normalize, nor will it compile when presented a version
473 # that has them.  However, you can trivially get it to compile by simply
474 # ignoring those decompositions, by changing the croak to a carp.  At the time
475 # of this writing, the line (in cpan/Unicode-Normalize/Normalize.pm or
476 # cpan/Unicode-Normalize/mkheader) reads
477 #
478 #   croak("Weird Canonical Decomposition of U+$h");
479 #
480 # Simply comment it out.  It will compile, but will not know about any three
481 # character decompositions.
482
483 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
484 # that the reason is that the CJK block starting at 4E00 was removed from
485 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
486 # single property name \p{alpha}) has the correct values.  But the compound
487 # form is simply not generated until 3.1, as it can be argued that prior to
488 # this release, this was not an official property.  The comments for
489 # filter_old_style_proplist() give more details.
490 #
491 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
492 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
493 # reason is that 3.2 introduced U+205F=medium math space, which was not
494 # classed as white space, but Perl figured out that it should have been. 4.0
495 # reclassified it correctly.
496 #
497 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
498 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
499 # became 202, and ATBL was left with no code points, as all the ones that
500 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
501 # name for the class, it would not have been affected, but if it used the
502 # mnemonic, it would have been.
503 #
504 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that, code
505 # points which eventually came to have this script property value, instead
506 # mapped to "Unknown".  But in the next release all these code points were
507 # moved to \p{sc=common} instead.
508
509 # The tests furnished  by Unicode for testing WordBreak and SentenceBreak
510 # generate errors in 5.0 and earlier.
511 #
512 # The default for missing code points for BidiClass is complicated.  Starting
513 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
514 # tries to do the best it can for earlier releases.  It is done in
515 # process_PropertyAliases()
516 #
517 # In version 2.1.2, the entry in UnicodeData.txt:
518 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
519 # should instead be
520 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
521 # Without this change, there are casing problems for this character.
522 #
523 # Search for $string_compare_versions to see how to compare changes to
524 # properties between Unicode versions
525 #
526 ##############################################################################
527
528 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
529                         # and errors
530 my $MAX_LINE_WIDTH = 78;
531
532 # Debugging aid to skip most files so as to not be distracted by them when
533 # concentrating on the ones being debugged.  Add
534 # non_skip => 1,
535 # to the constructor for those files you want processed when you set this.
536 # Files with a first version number of 0 are special: they are always
537 # processed regardless of the state of this flag.  Generally, Jamo.txt and
538 # UnicodeData.txt must not be skipped if you want this program to not die
539 # before normal completion.
540 my $debug_skip = 0;
541
542
543 # Normally these are suppressed.
544 my $write_Unicode_deprecated_tables = 0;
545
546 # Set to 1 to enable tracing.
547 our $to_trace = 0;
548
549 { # Closure for trace: debugging aid
550     my $print_caller = 1;        # ? Include calling subroutine name
551     my $main_with_colon = 'main::';
552     my $main_colon_length = length($main_with_colon);
553
554     sub trace {
555         return unless $to_trace;        # Do nothing if global flag not set
556
557         my @input = @_;
558
559         local $DB::trace = 0;
560         $DB::trace = 0;          # Quiet 'used only once' message
561
562         my $line_number;
563
564         # Loop looking up the stack to get the first non-trace caller
565         my $caller_line;
566         my $caller_name;
567         my $i = 0;
568         do {
569             $line_number = $caller_line;
570             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
571             $caller = $main_with_colon unless defined $caller;
572
573             $caller_name = $caller;
574
575             # get rid of pkg
576             $caller_name =~ s/.*:://;
577             if (substr($caller_name, 0, $main_colon_length)
578                 eq $main_with_colon)
579             {
580                 $caller_name = substr($caller_name, $main_colon_length);
581             }
582
583         } until ($caller_name ne 'trace');
584
585         # If the stack was empty, we were called from the top level
586         $caller_name = 'main' if ($caller_name eq ""
587                                     || $caller_name eq 'trace');
588
589         my $output = "";
590         #print STDERR __LINE__, ": ", join ", ", @input, "\n";
591         foreach my $string (@input) {
592             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
593                 $output .= simple_dumper($string);
594             }
595             else {
596                 $string = "$string" if ref $string;
597                 $string = $UNDEF unless defined $string;
598                 chomp $string;
599                 $string = '""' if $string eq "";
600                 $output .= " " if $output ne ""
601                                 && $string ne ""
602                                 && substr($output, -1, 1) ne " "
603                                 && substr($string, 0, 1) ne " ";
604                 $output .= $string;
605             }
606         }
607
608         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
609         print STDERR "$caller_name: " if $print_caller;
610         print STDERR $output, "\n";
611         return;
612     }
613 }
614
615 # This is for a rarely used development feature that allows you to compare two
616 # versions of the Unicode standard without having to deal with changes caused
617 # by the code points introduced in the later version.  You probably also want
618 # to use the -annotate option when using this.  Change the 0 to a string
619 # containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only code
620 # points introduced in that release and earlier will be used; later ones are
621 # thrown away.  You use the version number of the earliest one you want to
622 # compare; then run this program on directory structures containing each
623 # release, and compare the outputs.  These outputs will therefore include only
624 # the code points common to both releases, and you can see the changes caused
625 # just by the underlying release semantic changes.  For versions earlier than
626 # 3.2, you must copy a version of DAge.txt into the directory.
627 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
628 my $compare_versions = DEBUG
629                        && $string_compare_versions
630                        && pack "C*", split /\./, $string_compare_versions;
631
632 sub uniques {
633     # Returns non-duplicated input values.  From "Perl Best Practices:
634     # Encapsulated Cleverness".  p. 455 in first edition.
635
636     my %seen;
637     # Arguably this breaks encapsulation, if the goal is to permit multiple
638     # distinct objects to stringify to the same value, and be interchangeable.
639     # However, for this program, no two objects stringify identically, and all
640     # lists passed to this function are either objects or strings. So this
641     # doesn't affect correctness, but it does give a couple of percent speedup.
642     no overloading;
643     return grep { ! $seen{$_}++ } @_;
644 }
645
646 $0 = File::Spec->canonpath($0);
647
648 my $make_test_script = 0;      # ? Should we output a test script
649 my $make_norm_test_script = 0; # ? Should we output a normalization test script
650 my $write_unchanged_files = 0; # ? Should we update the output files even if
651                                #    we don't think they have changed
652 my $use_directory = "";        # ? Should we chdir somewhere.
653 my $pod_directory;             # input directory to store the pod file.
654 my $pod_file = 'perluniprops';
655 my $t_path;                     # Path to the .t test file
656 my $file_list = 'mktables.lst'; # File to store input and output file names.
657                                # This is used to speed up the build, by not
658                                # executing the main body of the program if
659                                # nothing on the list has changed since the
660                                # previous build
661 my $make_list = 1;             # ? Should we write $file_list.  Set to always
662                                # make a list so that when the pumpking is
663                                # preparing a release, s/he won't have to do
664                                # special things
665 my $glob_list = 0;             # ? Should we try to include unknown .txt files
666                                # in the input.
667 my $output_range_counts = $debugging_build;   # ? Should we include the number
668                                               # of code points in ranges in
669                                               # the output
670 my $annotate = 0;              # ? Should character names be in the output
671
672 # Verbosity levels; 0 is quiet
673 my $NORMAL_VERBOSITY = 1;
674 my $PROGRESS = 2;
675 my $VERBOSE = 3;
676
677 my $verbosity = $NORMAL_VERBOSITY;
678
679 # Stored in mktables.lst so that if this program is called with different
680 # options, will regenerate even if the files otherwise look like they're
681 # up-to-date.
682 my $command_line_arguments = join " ", @ARGV;
683
684 # Process arguments
685 while (@ARGV) {
686     my $arg = shift @ARGV;
687     if ($arg eq '-v') {
688         $verbosity = $VERBOSE;
689     }
690     elsif ($arg eq '-p') {
691         $verbosity = $PROGRESS;
692         $| = 1;     # Flush buffers as we go.
693     }
694     elsif ($arg eq '-q') {
695         $verbosity = 0;
696     }
697     elsif ($arg eq '-w') {
698         $write_unchanged_files = 1; # update the files even if havent changed
699     }
700     elsif ($arg eq '-check') {
701         my $this = shift @ARGV;
702         my $ok = shift @ARGV;
703         if ($this ne $ok) {
704             print "Skipping as check params are not the same.\n";
705             exit(0);
706         }
707     }
708     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
709         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
710     }
711     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
712     {
713         $make_test_script = 1;
714     }
715     elsif ($arg eq '-makenormtest')
716     {
717         $make_norm_test_script = 1;
718     }
719     elsif ($arg eq '-makelist') {
720         $make_list = 1;
721     }
722     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
723         -d $use_directory or croak "Unknown directory '$use_directory'";
724     }
725     elsif ($arg eq '-L') {
726
727         # Existence not tested until have chdir'd
728         $file_list = shift;
729     }
730     elsif ($arg eq '-globlist') {
731         $glob_list = 1;
732     }
733     elsif ($arg eq '-c') {
734         $output_range_counts = ! $output_range_counts
735     }
736     elsif ($arg eq '-annotate') {
737         $annotate = 1;
738         $debugging_build = 1;
739         $output_range_counts = 1;
740     }
741     else {
742         my $with_c = 'with';
743         $with_c .= 'out' if $output_range_counts;   # Complements the state
744         croak <<END;
745 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
746           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
747           [-check A B ]
748   -c          : Output comments $with_c number of code points in ranges
749   -q          : Quiet Mode: Only output serious warnings.
750   -p          : Set verbosity level to normal plus show progress.
751   -v          : Set Verbosity level high:  Show progress and non-serious
752                 warnings
753   -w          : Write files regardless
754   -C dir      : Change to this directory before proceeding. All relative paths
755                 except those specified by the -P and -T options will be done
756                 with respect to this directory.
757   -P dir      : Output $pod_file file to directory 'dir'.
758   -T path     : Create a test script as 'path'; overrides -maketest
759   -L filelist : Use alternate 'filelist' instead of standard one
760   -globlist   : Take as input all non-Test *.txt files in current and sub
761                 directories
762   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
763                 overrides -T
764   -makelist   : Rewrite the file list $file_list based on current setup
765   -annotate   : Output an annotation for each character in the table files;
766                 useful for debugging mktables, looking at diffs; but is slow
767                 and memory intensive
768   -check A B  : Executes $0 only if A and B are the same
769 END
770     }
771 }
772
773 # Stores the most-recently changed file.  If none have changed, can skip the
774 # build
775 my $most_recent = (stat $0)[9];   # Do this before the chdir!
776
777 # Change directories now, because need to read 'version' early.
778 if ($use_directory) {
779     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
780         $pod_directory = File::Spec->rel2abs($pod_directory);
781     }
782     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
783         $t_path = File::Spec->rel2abs($t_path);
784     }
785     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
786     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
787         $pod_directory = File::Spec->abs2rel($pod_directory);
788     }
789     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
790         $t_path = File::Spec->abs2rel($t_path);
791     }
792 }
793
794 # Get Unicode version into regular and v-string.  This is done now because
795 # various tables below get populated based on it.  These tables are populated
796 # here to be near the top of the file, and so easily seeable by those needing
797 # to modify things.
798 open my $VERSION, "<", "version"
799                     or croak "$0: can't open required file 'version': $!\n";
800 my $string_version = <$VERSION>;
801 close $VERSION;
802 chomp $string_version;
803 my $v_version = pack "C*", split /\./, $string_version;        # v string
804
805 # The following are the complete names of properties with property values that
806 # are known to not match any code points in some versions of Unicode, but that
807 # may change in the future so they should be matchable, hence an empty file is
808 # generated for them.
809 my @tables_that_may_be_empty;
810 push @tables_that_may_be_empty, 'Joining_Type=Left_Joining'
811                                                     if $v_version lt v6.3.0;
812 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
813 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
814 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
815                                                     if $v_version ge v4.1.0;
816 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
817                                                     if $v_version ge v6.0.0;
818 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
819                                                     if $v_version ge v6.1.0;
820 push @tables_that_may_be_empty, 'Canonical_Combining_Class=CCC133'
821                                                     if $v_version ge v6.2.0;
822
823 # The lists below are hashes, so the key is the item in the list, and the
824 # value is the reason why it is in the list.  This makes generation of
825 # documentation easier.
826
827 my %why_suppressed;  # No file generated for these.
828
829 # Files aren't generated for empty extraneous properties.  This is arguable.
830 # Extraneous properties generally come about because a property is no longer
831 # used in a newer version of Unicode.  If we generated a file without code
832 # points, programs that used to work on that property will still execute
833 # without errors.  It just won't ever match (or will always match, with \P{}).
834 # This means that the logic is now likely wrong.  I (khw) think its better to
835 # find this out by getting an error message.  Just move them to the table
836 # above to change this behavior
837 my %why_suppress_if_empty_warn_if_not = (
838
839    # It is the only property that has ever officially been removed from the
840    # Standard.  The database never contained any code points for it.
841    'Special_Case_Condition' => 'Obsolete',
842
843    # Apparently never official, but there were code points in some versions of
844    # old-style PropList.txt
845    'Non_Break' => 'Obsolete',
846 );
847
848 # These would normally go in the warn table just above, but they were changed
849 # a long time before this program was written, so warnings about them are
850 # moot.
851 if ($v_version gt v3.2.0) {
852     push @tables_that_may_be_empty,
853                                 'Canonical_Combining_Class=Attached_Below_Left'
854 }
855
856 # Enum values for to_output_map() method in the Map_Table package. (0 is don't
857 # output)
858 my $EXTERNAL_MAP = 1;
859 my $INTERNAL_MAP = 2;
860 my $OUTPUT_ADJUSTED = 3;
861
862 # To override computed values for writing the map tables for these properties.
863 # The default for enum map tables is to write them out, so that the Unicode
864 # .txt files can be removed, but all the data to compute any property value
865 # for any code point is available in a more compact form.
866 my %global_to_output_map = (
867     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
868     # get stuck supporting it if things change.  Since it is a STRING
869     # property, it normally would be listed in the pod, but INTERNAL_MAP
870     # suppresses that.
871     Unicode_1_Name => $INTERNAL_MAP,
872
873     Present_In => 0,                # Suppress, as easily computed from Age
874     Block => (NON_ASCII_PLATFORM) ? 1 : 0,  # Suppress, as Blocks.txt is
875                                             # retained, but needed for
876                                             # non-ASCII
877
878     # Suppress, as mapping can be found instead from the
879     # Perl_Decomposition_Mapping file
880     Decomposition_Type => 0,
881 );
882
883 # There are several types of obsolete properties defined by Unicode.  These
884 # must be hand-edited for every new Unicode release.
885 my %why_deprecated;  # Generates a deprecated warning message if used.
886 my %why_stabilized;  # Documentation only
887 my %why_obsolete;    # Documentation only
888
889 {   # Closure
890     my $simple = 'Perl uses the more complete version';
891     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
892
893     my $other_properties = 'other properties';
894     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
895     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
896
897     %why_deprecated = (
898         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
899         'Jamo_Short_Name' => $contributory,
900         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
901         'Other_Alphabetic' => $contributory,
902         'Other_Default_Ignorable_Code_Point' => $contributory,
903         'Other_Grapheme_Extend' => $contributory,
904         'Other_ID_Continue' => $contributory,
905         'Other_ID_Start' => $contributory,
906         'Other_Lowercase' => $contributory,
907         'Other_Math' => $contributory,
908         'Other_Uppercase' => $contributory,
909         'Expands_On_NFC' => $why_no_expand,
910         'Expands_On_NFD' => $why_no_expand,
911         'Expands_On_NFKC' => $why_no_expand,
912         'Expands_On_NFKD' => $why_no_expand,
913     );
914
915     %why_suppressed = (
916         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
917         # contains the same information, but without the algorithmically
918         # determinable Hangul syllables'.  This file is not published, so it's
919         # existence is not noted in the comment.
920         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or prop_invmap() or charprop() in Unicode::UCD::',
921
922         # Don't suppress ISO_Comment, as otherwise special handling is needed
923         # to differentiate between it and gc=c, which can be written as 'isc',
924         # which is the same characters as ISO_Comment's short name.
925
926         'Name' => "Accessible via \\N{...} or 'use charnames;' or charprop() or prop_invmap() in Unicode::UCD::",
927
928         'Simple_Case_Folding' => "$simple.  Can access this through casefold(), charprop(), or prop_invmap() in Unicode::UCD",
929         'Simple_Lowercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
930         'Simple_Titlecase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
931         'Simple_Uppercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
932
933         FC_NFKC_Closure => 'Deprecated by Unicode, and supplanted in usage by NFKC_Casefold; otherwise not useful',
934     );
935
936     foreach my $property (
937
938             # The following are suppressed because they were made contributory
939             # or deprecated by Unicode before Perl ever thought about
940             # supporting them.
941             'Jamo_Short_Name',
942             'Grapheme_Link',
943             'Expands_On_NFC',
944             'Expands_On_NFD',
945             'Expands_On_NFKC',
946             'Expands_On_NFKD',
947
948             # The following are suppressed because they have been marked
949             # as deprecated for a sufficient amount of time
950             'Other_Alphabetic',
951             'Other_Default_Ignorable_Code_Point',
952             'Other_Grapheme_Extend',
953             'Other_ID_Continue',
954             'Other_ID_Start',
955             'Other_Lowercase',
956             'Other_Math',
957             'Other_Uppercase',
958     ) {
959         $why_suppressed{$property} = $why_deprecated{$property};
960     }
961
962     # Customize the message for all the 'Other_' properties
963     foreach my $property (keys %why_deprecated) {
964         next if (my $main_property = $property) !~ s/^Other_//;
965         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
966     }
967 }
968
969 if ($write_Unicode_deprecated_tables) {
970     foreach my $property (keys %why_suppressed) {
971         delete $why_suppressed{$property} if $property =~
972                                                     / ^ Other | Grapheme /x;
973     }
974 }
975
976 if ($v_version ge 4.0.0) {
977     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
978     if ($v_version ge 6.0.0) {
979         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
980     }
981 }
982 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
983     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
984     if ($v_version ge 6.0.0) {
985         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
986     }
987 }
988
989 # Probably obsolete forever
990 if ($v_version ge v4.1.0) {
991     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
992 }
993 if ($v_version ge v6.0.0) {
994     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana" (or both)';
995     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
996 }
997
998 # This program can create files for enumerated-like properties, such as
999 # 'Numeric_Type'.  This file would be the same format as for a string
1000 # property, with a mapping from code point to its value, so you could look up,
1001 # for example, the script a code point is in.  But no one so far wants this
1002 # mapping, or they have found another way to get it since this is a new
1003 # feature.  So no file is generated except if it is in this list.
1004 my @output_mapped_properties = split "\n", <<END;
1005 END
1006
1007 # If you want more Unihan properties than the default, you need to add them to
1008 # these arrays.  Depending on the property type, @missing lines might have to
1009 # be added to the second array.  A sample entry would be (including the '#'):
1010 # @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1011 my @cjk_properties = split "\n", <<'END';
1012 END
1013 my @cjk_property_values = split "\n", <<'END';
1014 END
1015
1016 # The input files don't list every code point.  Those not listed are to be
1017 # defaulted to some value.  Below are hard-coded what those values are for
1018 # non-binary properties as of 5.1.  Starting in 5.0, there are
1019 # machine-parsable comment lines in the files that give the defaults; so this
1020 # list shouldn't have to be extended.  The claim is that all missing entries
1021 # for binary properties will default to 'N'.  Unicode tried to change that in
1022 # 5.2, but the beta period produced enough protest that they backed off.
1023 #
1024 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1025 # be in the form that it expects.  The others may be synonyms.
1026 my $CODE_POINT = '<code point>';
1027 my %default_mapping = (
1028     Age => "Unassigned",
1029     # Bidi_Class => Complicated; set in code
1030     Bidi_Mirroring_Glyph => "",
1031     Block => 'No_Block',
1032     Canonical_Combining_Class => 0,
1033     Case_Folding => $CODE_POINT,
1034     Decomposition_Mapping => $CODE_POINT,
1035     Decomposition_Type => 'None',
1036     East_Asian_Width => "Neutral",
1037     FC_NFKC_Closure => $CODE_POINT,
1038     General_Category => ($v_version le 6.3.0) ? 'Cn' : 'Unassigned',
1039     Grapheme_Cluster_Break => 'Other',
1040     Hangul_Syllable_Type => 'NA',
1041     ISO_Comment => "",
1042     Jamo_Short_Name => "",
1043     Joining_Group => "No_Joining_Group",
1044     # Joining_Type => Complicated; set in code
1045     kIICore => 'N',   #                       Is converted to binary
1046     #Line_Break => Complicated; set in code
1047     Lowercase_Mapping => $CODE_POINT,
1048     Name => "",
1049     Name_Alias => "",
1050     NFC_QC => 'Yes',
1051     NFD_QC => 'Yes',
1052     NFKC_QC => 'Yes',
1053     NFKD_QC => 'Yes',
1054     Numeric_Type => 'None',
1055     Numeric_Value => 'NaN',
1056     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1057     Sentence_Break => 'Other',
1058     Simple_Case_Folding => $CODE_POINT,
1059     Simple_Lowercase_Mapping => $CODE_POINT,
1060     Simple_Titlecase_Mapping => $CODE_POINT,
1061     Simple_Uppercase_Mapping => $CODE_POINT,
1062     Titlecase_Mapping => $CODE_POINT,
1063     Unicode_1_Name => "",
1064     Unicode_Radical_Stroke => "",
1065     Uppercase_Mapping => $CODE_POINT,
1066     Word_Break => 'Other',
1067 );
1068
1069 ### End of externally interesting definitions, except for @input_file_objects
1070
1071 my $HEADER=<<"EOF";
1072 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1073 # This file is machine-generated by $0 from the Unicode
1074 # database, Version $string_version.  Any changes made here will be lost!
1075 EOF
1076
1077 my $INTERNAL_ONLY_HEADER = <<"EOF";
1078
1079 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1080 # This file is for internal use by core Perl only.  The format and even the
1081 # name or existence of this file are subject to change without notice.  Don't
1082 # use it directly.  Use Unicode::UCD to access the Unicode character data
1083 # base.
1084 EOF
1085
1086 my $DEVELOPMENT_ONLY=<<"EOF";
1087 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1088 # This file contains information artificially constrained to code points
1089 # present in Unicode release $string_compare_versions.
1090 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1091 # not be used for production.
1092
1093 EOF
1094
1095 my $MAX_UNICODE_CODEPOINT_STRING = ($v_version ge v2.0.0)
1096                                    ? "10FFFF"
1097                                    : "FFFF";
1098 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1099 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1100
1101 # We work with above-Unicode code points, up to UV_MAX.   But when you get
1102 # that high, above IV_MAX, some operations don't work, and you can easily get
1103 # overflow.  Therefore for internal use, we use a much smaller number,
1104 # translating it to UV_MAX only for output.  The exact number is immaterial
1105 # (all Unicode code points are treated exactly the same), but the algorithm
1106 # requires it to be at least 2 * $MAX_UNICODE_CODEPOINTS + 1;
1107 my $MAX_WORKING_CODEPOINTS= $MAX_UNICODE_CODEPOINT * 8;
1108 my $MAX_WORKING_CODEPOINT = $MAX_WORKING_CODEPOINTS - 1;
1109 my $MAX_WORKING_CODEPOINT_STRING = sprintf("%X", $MAX_WORKING_CODEPOINT);
1110
1111 my $MAX_PLATFORM_CODEPOINT = ~0;
1112
1113 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1114 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1115 # to decrease backtracking.  The first regex allows the code point to be at
1116 # the end of a word, but to work properly, the word shouldn't end with a valid
1117 # hex character.  The second one won't match a code point at the end of a
1118 # word, and doesn't have the run-on issue
1119 my $run_on_code_point_re =
1120             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1121 my $code_point_re = qr/\b$run_on_code_point_re/;
1122
1123 # This matches the beginning of the line in the Unicode db files that give the
1124 # defaults for code points not listed (i.e., missing) in the file.  The code
1125 # depends on this ending with a semi-colon, so it can assume it is a valid
1126 # field when the line is split() by semi-colons
1127 my $missing_defaults_prefix = qr/^#\s+\@missing:\s+0000\.\.10FFFF\s*;/;
1128
1129 # Property types.  Unicode has more types, but these are sufficient for our
1130 # purposes.
1131 my $UNKNOWN = -1;   # initialized to illegal value
1132 my $NON_STRING = 1; # Either binary or enum
1133 my $BINARY = 2;
1134 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1135                        # tables, additional true and false tables are
1136                        # generated so that false is anything matching the
1137                        # default value, and true is everything else.
1138 my $ENUM = 4;       # Include catalog
1139 my $STRING = 5;     # Anything else: string or misc
1140
1141 # Some input files have lines that give default values for code points not
1142 # contained in the file.  Sometimes these should be ignored.
1143 my $NO_DEFAULTS = 0;        # Must evaluate to false
1144 my $NOT_IGNORED = 1;
1145 my $IGNORED = 2;
1146
1147 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1148 # and will appear in the main body of the tables in the output files, but
1149 # there are other types of ranges as well, listed below, that are specially
1150 # handled.   There are pseudo-types as well that will never be stored as a
1151 # type, but will affect the calculation of the type.
1152
1153 # 0 is for normal, non-specials
1154 my $MULTI_CP = 1;           # Sequence of more than code point
1155 my $HANGUL_SYLLABLE = 2;
1156 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1157 my $NULL = 4;               # The map is to the null string; utf8.c can't
1158                             # handle these, nor is there an accepted syntax
1159                             # for them in \p{} constructs
1160 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1161                              # otherwise be $MULTI_CP type are instead type 0
1162
1163 # process_generic_property_file() can accept certain overrides in its input.
1164 # Each of these must begin AND end with $CMD_DELIM.
1165 my $CMD_DELIM = "\a";
1166 my $REPLACE_CMD = 'replace';    # Override the Replace
1167 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1168
1169 my $NO = 0;
1170 my $YES = 1;
1171
1172 # Values for the Replace argument to add_range.
1173 # $NO                      # Don't replace; add only the code points not
1174                            # already present.
1175 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1176                            # the comments at the subroutine definition.
1177 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1178 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1179                            # already there
1180 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1181                            # already there
1182 my $CROAK = 6;             # Die with an error if is already there
1183
1184 # Flags to give property statuses.  The phrases are to remind maintainers that
1185 # if the flag is changed, the indefinite article referring to it in the
1186 # documentation may need to be as well.
1187 my $NORMAL = "";
1188 my $DEPRECATED = 'D';
1189 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1190 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1191 my $DISCOURAGED = 'X';
1192 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1193 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1194 my $STRICTER = 'T';
1195 my $a_bold_stricter = "a 'B<$STRICTER>'";
1196 my $A_bold_stricter = "A 'B<$STRICTER>'";
1197 my $STABILIZED = 'S';
1198 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1199 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1200 my $OBSOLETE = 'O';
1201 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1202 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1203
1204 # Aliases can also have an extra status:
1205 my $INTERNAL_ALIAS = 'P';
1206
1207 my %status_past_participles = (
1208     $DISCOURAGED => 'discouraged',
1209     $STABILIZED => 'stabilized',
1210     $OBSOLETE => 'obsolete',
1211     $DEPRECATED => 'deprecated',
1212     $INTERNAL_ALIAS => 'reserved for Perl core internal use only',
1213 );
1214
1215 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1216 # externally documented.
1217 my $ORDINARY = 0;       # The normal fate.
1218 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1219                         # but there is a file written that can be used to
1220                         # reconstruct this table
1221 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1222                         # for Perl's internal use only
1223 my $LEGACY_ONLY = 3;    # Like $INTERNAL_ONLY, but not actually used by Perl.
1224                         # Is for backwards compatibility for applications that
1225                         # read the file directly, so it's format is
1226                         # unchangeable.
1227 my $SUPPRESSED = 4;     # The file for this table is not written out, and as a
1228                         # result, we don't bother to do many computations on
1229                         # it.
1230 my $PLACEHOLDER = 5;    # Like $SUPPRESSED, but we go through all the
1231                         # computations anyway, as the values are needed for
1232                         # things to work.  This happens when we have Perl
1233                         # extensions that depend on Unicode tables that
1234                         # wouldn't normally be in a given Unicode version.
1235
1236 # The format of the values of the tables:
1237 my $EMPTY_FORMAT = "";
1238 my $BINARY_FORMAT = 'b';
1239 my $DECIMAL_FORMAT = 'd';
1240 my $FLOAT_FORMAT = 'f';
1241 my $INTEGER_FORMAT = 'i';
1242 my $HEX_FORMAT = 'x';
1243 my $RATIONAL_FORMAT = 'r';
1244 my $STRING_FORMAT = 's';
1245 my $ADJUST_FORMAT = 'a';
1246 my $HEX_ADJUST_FORMAT = 'ax';
1247 my $DECOMP_STRING_FORMAT = 'c';
1248 my $STRING_WHITE_SPACE_LIST = 'sw';
1249
1250 my %map_table_formats = (
1251     $BINARY_FORMAT => 'binary',
1252     $DECIMAL_FORMAT => 'single decimal digit',
1253     $FLOAT_FORMAT => 'floating point number',
1254     $INTEGER_FORMAT => 'integer',
1255     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1256     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1257     $STRING_FORMAT => 'string',
1258     $ADJUST_FORMAT => 'some entries need adjustment',
1259     $HEX_ADJUST_FORMAT => 'mapped value in hex; some entries need adjustment',
1260     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1261     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1262 );
1263
1264 # Unicode didn't put such derived files in a separate directory at first.
1265 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1266 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1267 my $AUXILIARY = 'auxiliary';
1268
1269 # Hashes and arrays that will eventually go into Heavy.pl for the use of
1270 # utf8_heavy.pl and into UCD.pl for the use of UCD.pm
1271 my %loose_to_file_of;       # loosely maps table names to their respective
1272                             # files
1273 my %stricter_to_file_of;    # same; but for stricter mapping.
1274 my %loose_property_to_file_of; # Maps a loose property name to its map file
1275 my %strict_property_to_file_of; # Same, but strict
1276 my @inline_definitions = "V0"; # Each element gives a definition of a unique
1277                             # inversion list.  When a definition is inlined,
1278                             # its value in the hash it's in (one of the two
1279                             # defined just above) will include an index into
1280                             # this array.  The 0th element is initialized to
1281                             # the definition for a zero length inversion list
1282 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1283                             # in the hash %utf8::SwashInfo
1284 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1285                              # their rational equivalent
1286 my %loose_property_name_of; # Loosely maps (non_string) property names to
1287                             # standard form
1288 my %strict_property_name_of; # Strictly maps (non_string) property names to
1289                             # standard form
1290 my %string_property_loose_to_name; # Same, for string properties.
1291 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1292                             # the property name in standard loose form, and
1293                             # 'value' is the default value for that property,
1294                             # also in standard loose form.
1295 my %loose_to_standard_value; # loosely maps table names to the canonical
1296                             # alias for them
1297 my %ambiguous_names;        # keys are alias names (in standard form) that
1298                             # have more than one possible meaning.
1299 my %combination_property;   # keys are alias names (in standard form) that
1300                             # have both a map table, and a binary one that
1301                             # yields true for all non-null maps.
1302 my %prop_aliases;           # Keys are standard property name; values are each
1303                             # one's aliases
1304 my %prop_value_aliases;     # Keys of top level are standard property name;
1305                             # values are keys to another hash,  Each one is
1306                             # one of the property's values, in standard form.
1307                             # The values are that prop-val's aliases.
1308 my %skipped_files;          # List of files that we skip
1309 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1310
1311 # Most properties are immune to caseless matching, otherwise you would get
1312 # nonsensical results, as properties are a function of a code point, not
1313 # everything that is caselessly equivalent to that code point.  For example,
1314 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1315 # be true because 's' and 'S' are equivalent caselessly.  However,
1316 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1317 # extend that concept to those very few properties that are like this.  Each
1318 # such property will match the full range caselessly.  They are hard-coded in
1319 # the program; it's not worth trying to make it general as it's extremely
1320 # unlikely that they will ever change.
1321 my %caseless_equivalent_to;
1322
1323 # These constants names and values were taken from the Unicode standard,
1324 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1325 # syllables.  The '_string' versions are so generated tables can retain the
1326 # hex format, which is the more familiar value
1327 my $SBase_string = "0xAC00";
1328 my $SBase = CORE::hex $SBase_string;
1329 my $LBase_string = "0x1100";
1330 my $LBase = CORE::hex $LBase_string;
1331 my $VBase_string = "0x1161";
1332 my $VBase = CORE::hex $VBase_string;
1333 my $TBase_string = "0x11A7";
1334 my $TBase = CORE::hex $TBase_string;
1335 my $SCount = 11172;
1336 my $LCount = 19;
1337 my $VCount = 21;
1338 my $TCount = 28;
1339 my $NCount = $VCount * $TCount;
1340
1341 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1342 # with the above published constants.
1343 my %Jamo;
1344 my %Jamo_L;     # Leading consonants
1345 my %Jamo_V;     # Vowels
1346 my %Jamo_T;     # Trailing consonants
1347
1348 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1349 # The key is the base name of the code point, and the value is an
1350 # array giving all the ranges that use this base name.  Each range
1351 # is actually a hash giving the 'low' and 'high' values of it.
1352 my %names_ending_in_code_point;
1353 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1354                                         # removed from the names
1355 # Inverse mapping.  The list of ranges that have these kinds of
1356 # names.  Each element contains the low, high, and base names in an
1357 # anonymous hash.
1358 my @code_points_ending_in_code_point;
1359
1360 # To hold Unicode's normalization test suite
1361 my @normalization_tests;
1362
1363 # Boolean: does this Unicode version have the hangul syllables, and are we
1364 # writing out a table for them?
1365 my $has_hangul_syllables = 0;
1366
1367 # Does this Unicode version have code points whose names end in their
1368 # respective code points, and are we writing out a table for them?  0 for no;
1369 # otherwise points to first property that a table is needed for them, so that
1370 # if multiple tables are needed, we don't create duplicates
1371 my $needing_code_points_ending_in_code_point = 0;
1372
1373 my @backslash_X_tests;     # List of tests read in for testing \X
1374 my @SB_tests;              # List of tests read in for testing \b{sb}
1375 my @WB_tests;              # List of tests read in for testing \b{wb}
1376 my @unhandled_properties;  # Will contain a list of properties found in
1377                            # the input that we didn't process.
1378 my @match_properties;      # Properties that have match tables, to be
1379                            # listed in the pod
1380 my @map_properties;        # Properties that get map files written
1381 my @named_sequences;       # NamedSequences.txt contents.
1382 my %potential_files;       # Generated list of all .txt files in the directory
1383                            # structure so we can warn if something is being
1384                            # ignored.
1385 my @missing_early_files;   # Generated list of absent files that we need to
1386                            # proceed in compiling this early Unicode version
1387 my @files_actually_output; # List of files we generated.
1388 my @more_Names;            # Some code point names are compound; this is used
1389                            # to store the extra components of them.
1390 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1391                            # the minimum before we consider it equivalent to a
1392                            # candidate rational
1393 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1394
1395 # These store references to certain commonly used property objects
1396 my $ccc;
1397 my $gc;
1398 my $perl;
1399 my $block;
1400 my $perl_charname;
1401 my $print;
1402 my $All;
1403 my $Assigned;   # All assigned characters in this Unicode release
1404 my $script;
1405
1406 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1407 my $has_In_conflicts = 0;
1408 my $has_Is_conflicts = 0;
1409
1410 sub internal_file_to_platform ($) {
1411     # Convert our file paths which have '/' separators to those of the
1412     # platform.
1413
1414     my $file = shift;
1415     return undef unless defined $file;
1416
1417     return File::Spec->join(split '/', $file);
1418 }
1419
1420 sub file_exists ($) {   # platform independent '-e'.  This program internally
1421                         # uses slash as a path separator.
1422     my $file = shift;
1423     return 0 if ! defined $file;
1424     return -e internal_file_to_platform($file);
1425 }
1426
1427 sub objaddr($) {
1428     # Returns the address of the blessed input object.
1429     # It doesn't check for blessedness because that would do a string eval
1430     # every call, and the program is structured so that this is never called
1431     # for a non-blessed object.
1432
1433     no overloading; # If overloaded, numifying below won't work.
1434
1435     # Numifying a ref gives its address.
1436     return pack 'J', $_[0];
1437 }
1438
1439 # These are used only if $annotate is true.
1440 # The entire range of Unicode characters is examined to populate these
1441 # after all the input has been processed.  But most can be skipped, as they
1442 # have the same descriptive phrases, such as being unassigned
1443 my @viacode;            # Contains the 1 million character names
1444 my @printable;          # boolean: And are those characters printable?
1445 my @annotate_char_type; # Contains a type of those characters, specifically
1446                         # for the purposes of annotation.
1447 my $annotate_ranges;    # A map of ranges of code points that have the same
1448                         # name for the purposes of annotation.  They map to the
1449                         # upper edge of the range, so that the end point can
1450                         # be immediately found.  This is used to skip ahead to
1451                         # the end of a range, and avoid processing each
1452                         # individual code point in it.
1453 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1454                                    # characters, but excluding those which are
1455                                    # also noncharacter code points
1456
1457 # The annotation types are an extension of the regular range types, though
1458 # some of the latter are folded into one.  Make the new types negative to
1459 # avoid conflicting with the regular types
1460 my $SURROGATE_TYPE = -1;
1461 my $UNASSIGNED_TYPE = -2;
1462 my $PRIVATE_USE_TYPE = -3;
1463 my $NONCHARACTER_TYPE = -4;
1464 my $CONTROL_TYPE = -5;
1465 my $ABOVE_UNICODE_TYPE = -6;
1466 my $UNKNOWN_TYPE = -7;  # Used only if there is a bug in this program
1467
1468 sub populate_char_info ($) {
1469     # Used only with the $annotate option.  Populates the arrays with the
1470     # input code point's info that are needed for outputting more detailed
1471     # comments.  If calling context wants a return, it is the end point of
1472     # any contiguous range of characters that share essentially the same info
1473
1474     my $i = shift;
1475     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1476
1477     $viacode[$i] = $perl_charname->value_of($i) || "";
1478
1479     # A character is generally printable if Unicode says it is,
1480     # but below we make sure that most Unicode general category 'C' types
1481     # aren't.
1482     $printable[$i] = $print->contains($i);
1483
1484     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1485
1486     # Only these two regular types are treated specially for annotations
1487     # purposes
1488     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1489                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1490
1491     # Give a generic name to all code points that don't have a real name.
1492     # We output ranges, if applicable, for these.  Also calculate the end
1493     # point of the range.
1494     my $end;
1495     if (! $viacode[$i]) {
1496         my $nonchar;
1497         if ($i > $MAX_UNICODE_CODEPOINT) {
1498             $viacode[$i] = 'Above-Unicode';
1499             $annotate_char_type[$i] = $ABOVE_UNICODE_TYPE;
1500             $printable[$i] = 0;
1501             $end = $MAX_WORKING_CODEPOINT;
1502         }
1503         elsif ($gc-> table('Private_use')->contains($i)) {
1504             $viacode[$i] = 'Private Use';
1505             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1506             $printable[$i] = 0;
1507             $end = $gc->table('Private_Use')->containing_range($i)->end;
1508         }
1509         elsif ((defined ($nonchar =
1510                             Property::property_ref('Noncharacter_Code_Point'))
1511                && $nonchar->table('Y')->contains($i)))
1512         {
1513             $viacode[$i] = 'Noncharacter';
1514             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1515             $printable[$i] = 0;
1516             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1517                                                     containing_range($i)->end;
1518         }
1519         elsif ($gc-> table('Control')->contains($i)) {
1520             $viacode[$i] = property_ref('Name_Alias')->value_of($i) || 'Control';
1521             $annotate_char_type[$i] = $CONTROL_TYPE;
1522             $printable[$i] = 0;
1523         }
1524         elsif ($gc-> table('Unassigned')->contains($i)) {
1525             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1526             $printable[$i] = 0;
1527             if (defined $block) { # No blocks in earliest releases
1528                 $viacode[$i] = 'Unassigned';
1529                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1530             }
1531             else {
1532                 $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1533
1534                 # Because we name the unassigned by the blocks they are in, it
1535                 # can't go past the end of that block, and it also can't go
1536                 # past the unassigned range it is in.  The special table makes
1537                 # sure that the non-characters, which are unassigned, are
1538                 # separated out.
1539                 $end = min($block->containing_range($i)->end,
1540                            $unassigned_sans_noncharacters->
1541                                                     containing_range($i)->end);
1542             }
1543         }
1544         elsif ($perl->table('_Perl_Surrogate')->contains($i)) {
1545             $viacode[$i] = 'Surrogate';
1546             $annotate_char_type[$i] = $SURROGATE_TYPE;
1547             $printable[$i] = 0;
1548             $end = $gc->table('Surrogate')->containing_range($i)->end;
1549         }
1550         else {
1551             Carp::my_carp_bug("Can't figure out how to annotate "
1552                               . sprintf("U+%04X", $i)
1553                               . ".  Proceeding anyway.");
1554             $viacode[$i] = 'UNKNOWN';
1555             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1556             $printable[$i] = 0;
1557         }
1558     }
1559
1560     # Here, has a name, but if it's one in which the code point number is
1561     # appended to the name, do that.
1562     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1563         $viacode[$i] .= sprintf("-%04X", $i);
1564         $end = $perl_charname->containing_range($i)->end;
1565     }
1566
1567     # And here, has a name, but if it's a hangul syllable one, replace it with
1568     # the correct name from the Unicode algorithm
1569     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1570         use integer;
1571         my $SIndex = $i - $SBase;
1572         my $L = $LBase + $SIndex / $NCount;
1573         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1574         my $T = $TBase + $SIndex % $TCount;
1575         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1576         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1577         $end = $perl_charname->containing_range($i)->end;
1578     }
1579
1580     return if ! defined wantarray;
1581     return $i if ! defined $end;    # If not a range, return the input
1582
1583     # Save this whole range so can find the end point quickly
1584     $annotate_ranges->add_map($i, $end, $end);
1585
1586     return $end;
1587 }
1588
1589 # Commented code below should work on Perl 5.8.
1590 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1591 ## the native perl version of it (which is what would operate under miniperl)
1592 ## is extremely slow, as it does a string eval every call.
1593 #my $has_fast_scalar_util = $^X !~ /miniperl/
1594 #                            && defined eval "require Scalar::Util";
1595 #
1596 #sub objaddr($) {
1597 #    # Returns the address of the blessed input object.  Uses the XS version if
1598 #    # available.  It doesn't check for blessedness because that would do a
1599 #    # string eval every call, and the program is structured so that this is
1600 #    # never called for a non-blessed object.
1601 #
1602 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1603 #
1604 #    # Check at least that is a ref.
1605 #    my $pkg = ref($_[0]) or return undef;
1606 #
1607 #    # Change to a fake package to defeat any overloaded stringify
1608 #    bless $_[0], 'main::Fake';
1609 #
1610 #    # Numifying a ref gives its address.
1611 #    my $addr = pack 'J', $_[0];
1612 #
1613 #    # Return to original class
1614 #    bless $_[0], $pkg;
1615 #    return $addr;
1616 #}
1617
1618 sub max ($$) {
1619     my $a = shift;
1620     my $b = shift;
1621     return $a if $a >= $b;
1622     return $b;
1623 }
1624
1625 sub min ($$) {
1626     my $a = shift;
1627     my $b = shift;
1628     return $a if $a <= $b;
1629     return $b;
1630 }
1631
1632 sub clarify_number ($) {
1633     # This returns the input number with underscores inserted every 3 digits
1634     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1635     # checked.
1636
1637     my $number = shift;
1638     my $pos = length($number) - 3;
1639     return $number if $pos <= 1;
1640     while ($pos > 0) {
1641         substr($number, $pos, 0) = '_';
1642         $pos -= 3;
1643     }
1644     return $number;
1645 }
1646
1647 sub clarify_code_point_count ($) {
1648     # This is like clarify_number(), but the input is assumed to be a count of
1649     # code points, rather than a generic number.
1650
1651     my $append = "";
1652
1653     my $number = shift;
1654     if ($number > $MAX_UNICODE_CODEPOINTS) {
1655         $number -= ($MAX_WORKING_CODEPOINTS - $MAX_UNICODE_CODEPOINTS);
1656         return "All above-Unicode code points" if $number == 0;
1657         $append = " + all above-Unicode code points";
1658     }
1659     return clarify_number($number) . $append;
1660 }
1661
1662 package Carp;
1663
1664 # These routines give a uniform treatment of messages in this program.  They
1665 # are placed in the Carp package to cause the stack trace to not include them,
1666 # although an alternative would be to use another package and set @CARP_NOT
1667 # for it.
1668
1669 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1670
1671 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1672 # and overload trying to load Scalar:Util under miniperl.  See
1673 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1674 undef $overload::VERSION;
1675
1676 sub my_carp {
1677     my $message = shift || "";
1678     my $nofold = shift || 0;
1679
1680     if ($message) {
1681         $message = main::join_lines($message);
1682         $message =~ s/^$0: *//;     # Remove initial program name
1683         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1684         $message = "\n$0: $message;";
1685
1686         # Fold the message with program name, semi-colon end punctuation
1687         # (which looks good with the message that carp appends to it), and a
1688         # hanging indent for continuation lines.
1689         $message = main::simple_fold($message, "", 4) unless $nofold;
1690         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1691                                     # appends is to the same line
1692     }
1693
1694     return $message if defined wantarray;   # If a caller just wants the msg
1695
1696     carp $message;
1697     return;
1698 }
1699
1700 sub my_carp_bug {
1701     # This is called when it is clear that the problem is caused by a bug in
1702     # this program.
1703
1704     my $message = shift;
1705     $message =~ s/^$0: *//;
1706     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1707     carp $message;
1708     return;
1709 }
1710
1711 sub carp_too_few_args {
1712     if (@_ != 2) {
1713         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1714         return;
1715     }
1716
1717     my $args_ref = shift;
1718     my $count = shift;
1719
1720     my_carp_bug("Need at least $count arguments to "
1721         . (caller 1)[3]
1722         . ".  Instead got: '"
1723         . join ', ', @$args_ref
1724         . "'.  No action taken.");
1725     return;
1726 }
1727
1728 sub carp_extra_args {
1729     my $args_ref = shift;
1730     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1731
1732     unless (ref $args_ref) {
1733         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1734         return;
1735     }
1736     my ($package, $file, $line) = caller;
1737     my $subroutine = (caller 1)[3];
1738
1739     my $list;
1740     if (ref $args_ref eq 'HASH') {
1741         foreach my $key (keys %$args_ref) {
1742             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1743         }
1744         $list = join ', ', each %{$args_ref};
1745     }
1746     elsif (ref $args_ref eq 'ARRAY') {
1747         foreach my $arg (@$args_ref) {
1748             $arg = $UNDEF unless defined $arg;
1749         }
1750         $list = join ', ', @$args_ref;
1751     }
1752     else {
1753         my_carp_bug("Can't cope with ref "
1754                 . ref($args_ref)
1755                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1756         return;
1757     }
1758
1759     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1760     return;
1761 }
1762
1763 package main;
1764
1765 { # Closure
1766
1767     # This program uses the inside-out method for objects, as recommended in
1768     # "Perl Best Practices".  (This is the best solution still, since this has
1769     # to run under miniperl.)  This closure aids in generating those.  There
1770     # are two routines.  setup_package() is called once per package to set
1771     # things up, and then set_access() is called for each hash representing a
1772     # field in the object.  These routines arrange for the object to be
1773     # properly destroyed when no longer used, and for standard accessor
1774     # functions to be generated.  If you need more complex accessors, just
1775     # write your own and leave those accesses out of the call to set_access().
1776     # More details below.
1777
1778     my %constructor_fields; # fields that are to be used in constructors; see
1779                             # below
1780
1781     # The values of this hash will be the package names as keys to other
1782     # hashes containing the name of each field in the package as keys, and
1783     # references to their respective hashes as values.
1784     my %package_fields;
1785
1786     sub setup_package {
1787         # Sets up the package, creating standard DESTROY and dump methods
1788         # (unless already defined).  The dump method is used in debugging by
1789         # simple_dumper().
1790         # The optional parameters are:
1791         #   a)  a reference to a hash, that gets populated by later
1792         #       set_access() calls with one of the accesses being
1793         #       'constructor'.  The caller can then refer to this, but it is
1794         #       not otherwise used by these two routines.
1795         #   b)  a reference to a callback routine to call during destruction
1796         #       of the object, before any fields are actually destroyed
1797
1798         my %args = @_;
1799         my $constructor_ref = delete $args{'Constructor_Fields'};
1800         my $destroy_callback = delete $args{'Destroy_Callback'};
1801         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1802
1803         my %fields;
1804         my $package = (caller)[0];
1805
1806         $package_fields{$package} = \%fields;
1807         $constructor_fields{$package} = $constructor_ref;
1808
1809         unless ($package->can('DESTROY')) {
1810             my $destroy_name = "${package}::DESTROY";
1811             no strict "refs";
1812
1813             # Use typeglob to give the anonymous subroutine the name we want
1814             *$destroy_name = sub {
1815                 my $self = shift;
1816                 my $addr = do { no overloading; pack 'J', $self; };
1817
1818                 $self->$destroy_callback if $destroy_callback;
1819                 foreach my $field (keys %{$package_fields{$package}}) {
1820                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1821                     delete $package_fields{$package}{$field}{$addr};
1822                 }
1823                 return;
1824             }
1825         }
1826
1827         unless ($package->can('dump')) {
1828             my $dump_name = "${package}::dump";
1829             no strict "refs";
1830             *$dump_name = sub {
1831                 my $self = shift;
1832                 return dump_inside_out($self, $package_fields{$package}, @_);
1833             }
1834         }
1835         return;
1836     }
1837
1838     sub set_access {
1839         # Arrange for the input field to be garbage collected when no longer
1840         # needed.  Also, creates standard accessor functions for the field
1841         # based on the optional parameters-- none if none of these parameters:
1842         #   'addable'    creates an 'add_NAME()' accessor function.
1843         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1844         #                function.
1845         #   'settable'   creates a 'set_NAME()' accessor function.
1846         #   'constructor' doesn't create an accessor function, but adds the
1847         #                field to the hash that was previously passed to
1848         #                setup_package();
1849         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1850         # 'add' etc. all mean 'addable'.
1851         # The read accessor function will work on both array and scalar
1852         # values.  If another accessor in the parameter list is 'a', the read
1853         # access assumes an array.  You can also force it to be array access
1854         # by specifying 'readable_array' instead of 'readable'
1855         #
1856         # A sort-of 'protected' access can be set-up by preceding the addable,
1857         # readable or settable with some initial portion of 'protected_' (but,
1858         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1859         # "protection" is only by convention.  All that happens is that the
1860         # accessor functions' names begin with an underscore.  So instead of
1861         # calling set_foo, the call is _set_foo.  (Real protection could be
1862         # accomplished by having a new subroutine, end_package, called at the
1863         # end of each package, and then storing the __LINE__ ranges and
1864         # checking them on every accessor.  But that is way overkill.)
1865
1866         # We create anonymous subroutines as the accessors and then use
1867         # typeglobs to assign them to the proper package and name
1868
1869         my $name = shift;   # Name of the field
1870         my $field = shift;  # Reference to the inside-out hash containing the
1871                             # field
1872
1873         my $package = (caller)[0];
1874
1875         if (! exists $package_fields{$package}) {
1876             croak "$0: Must call 'setup_package' before 'set_access'";
1877         }
1878
1879         # Stash the field so DESTROY can get it.
1880         $package_fields{$package}{$name} = $field;
1881
1882         # Remaining arguments are the accessors.  For each...
1883         foreach my $access (@_) {
1884             my $access = lc $access;
1885
1886             my $protected = "";
1887
1888             # Match the input as far as it goes.
1889             if ($access =~ /^(p[^_]*)_/) {
1890                 $protected = $1;
1891                 if (substr('protected_', 0, length $protected)
1892                     eq $protected)
1893                 {
1894
1895                     # Add 1 for the underscore not included in $protected
1896                     $access = substr($access, length($protected) + 1);
1897                     $protected = '_';
1898                 }
1899                 else {
1900                     $protected = "";
1901                 }
1902             }
1903
1904             if (substr('addable', 0, length $access) eq $access) {
1905                 my $subname = "${package}::${protected}add_$name";
1906                 no strict "refs";
1907
1908                 # add_ accessor.  Don't add if already there, which we
1909                 # determine using 'eq' for scalars and '==' otherwise.
1910                 *$subname = sub {
1911                     use strict "refs";
1912                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1913                     my $self = shift;
1914                     my $value = shift;
1915                     my $addr = do { no overloading; pack 'J', $self; };
1916                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1917                     if (ref $value) {
1918                         return if grep { $value == $_ } @{$field->{$addr}};
1919                     }
1920                     else {
1921                         return if grep { $value eq $_ } @{$field->{$addr}};
1922                     }
1923                     push @{$field->{$addr}}, $value;
1924                     return;
1925                 }
1926             }
1927             elsif (substr('constructor', 0, length $access) eq $access) {
1928                 if ($protected) {
1929                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1930                 }
1931                 else {
1932                     $constructor_fields{$package}{$name} = $field;
1933                 }
1934             }
1935             elsif (substr('readable_array', 0, length $access) eq $access) {
1936
1937                 # Here has read access.  If one of the other parameters for
1938                 # access is array, or this one specifies array (by being more
1939                 # than just 'readable_'), then create a subroutine that
1940                 # assumes the data is an array.  Otherwise just a scalar
1941                 my $subname = "${package}::${protected}$name";
1942                 if (grep { /^a/i } @_
1943                     or length($access) > length('readable_'))
1944                 {
1945                     no strict "refs";
1946                     *$subname = sub {
1947                         use strict "refs";
1948                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1949                         my $addr = do { no overloading; pack 'J', $_[0]; };
1950                         if (ref $field->{$addr} ne 'ARRAY') {
1951                             my $type = ref $field->{$addr};
1952                             $type = 'scalar' unless $type;
1953                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1954                             return;
1955                         }
1956                         return scalar @{$field->{$addr}} unless wantarray;
1957
1958                         # Make a copy; had problems with caller modifying the
1959                         # original otherwise
1960                         my @return = @{$field->{$addr}};
1961                         return @return;
1962                     }
1963                 }
1964                 else {
1965
1966                     # Here not an array value, a simpler function.
1967                     no strict "refs";
1968                     *$subname = sub {
1969                         use strict "refs";
1970                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1971                         no overloading;
1972                         return $field->{pack 'J', $_[0]};
1973                     }
1974                 }
1975             }
1976             elsif (substr('settable', 0, length $access) eq $access) {
1977                 my $subname = "${package}::${protected}set_$name";
1978                 no strict "refs";
1979                 *$subname = sub {
1980                     use strict "refs";
1981                     if (main::DEBUG) {
1982                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1983                         Carp::carp_extra_args(\@_) if @_ > 2;
1984                     }
1985                     # $self is $_[0]; $value is $_[1]
1986                     no overloading;
1987                     $field->{pack 'J', $_[0]} = $_[1];
1988                     return;
1989                 }
1990             }
1991             else {
1992                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1993             }
1994         }
1995         return;
1996     }
1997 }
1998
1999 package Input_file;
2000
2001 # All input files use this object, which stores various attributes about them,
2002 # and provides for convenient, uniform handling.  The run method wraps the
2003 # processing.  It handles all the bookkeeping of opening, reading, and closing
2004 # the file, returning only significant input lines.
2005 #
2006 # Each object gets a handler which processes the body of the file, and is
2007 # called by run().  All character property files must use the generic,
2008 # default handler, which has code scrubbed to handle things you might not
2009 # expect, including automatic EBCDIC handling.  For files that don't deal with
2010 # mapping code points to a property value, such as test files,
2011 # PropertyAliases, PropValueAliases, and named sequences, you can override the
2012 # handler to be a custom one.  Such a handler should basically be a
2013 # while(next_line()) {...} loop.
2014 #
2015 # You can also set up handlers to
2016 #   0) call during object construction time, after everything else is done
2017 #   1) call before the first line is read, for pre processing
2018 #   2) call to adjust each line of the input before the main handler gets
2019 #      them.  This can be automatically generated, if appropriately simple
2020 #      enough, by specifiying a Properties parameter in the constructor.
2021 #   3) call upon EOF before the main handler exits its loop
2022 #   4) call at the end, for post processing
2023 #
2024 # $_ is used to store the input line, and is to be filtered by the
2025 # each_line_handler()s.  So, if the format of the line is not in the desired
2026 # format for the main handler, these are used to do that adjusting.  They can
2027 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2028 # so the $_ output of one is used as the input to the next.  The eof handler
2029 # is also stackable, but none of the others are, but could easily be changed
2030 # to be so.
2031 #
2032 # Some properties are used by the Perl core but aren't defined until later
2033 # Unicode releases.  The perl interpreter would have problems working when
2034 # compiled with an earlier Unicode version that doesn't have them, so we need
2035 # to define them somehow for those releases.  The 'Early' constructor
2036 # parameter can be used to automatically handle this.  It is essentially
2037 # ignored if the Unicode version being compiled has a data file for this
2038 # property.  Either code to execute or a file to read can be specified.
2039 # Details are at the %early definition.
2040 #
2041 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2042 # which insert the parameters as lines to be processed before the next input
2043 # file line is read.  This allows the EOF handler(s) to flush buffers, for
2044 # example.  The difference between the two routines is that the lines inserted
2045 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2046 # called it from such a handler, you would get infinite recursion without some
2047 # mechanism to prevent that.)  Lines inserted by insert_adjusted_lines() go
2048 # directly to the main handler without any adjustments.  If the
2049 # post-processing handler calls any of these, there will be no effect.  Some
2050 # error checking for these conditions could be added, but it hasn't been done.
2051 #
2052 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2053 # to prevent further processing of the line.  This routine will output the
2054 # message as a warning once, and then keep a count of the lines that have the
2055 # same message, and output that count at the end of the file's processing.
2056 # This keeps the number of messages down to a manageable amount.
2057 #
2058 # get_missings() should be called to retrieve any @missing input lines.
2059 # Messages will be raised if this isn't done if the options aren't to ignore
2060 # missings.
2061
2062 sub trace { return main::trace(@_); }
2063
2064 { # Closure
2065     # Keep track of fields that are to be put into the constructor.
2066     my %constructor_fields;
2067
2068     main::setup_package(Constructor_Fields => \%constructor_fields);
2069
2070     my %file; # Input file name, required
2071     main::set_access('file', \%file, qw{ c r });
2072
2073     my %first_released; # Unicode version file was first released in, required
2074     main::set_access('first_released', \%first_released, qw{ c r });
2075
2076     my %handler;    # Subroutine to process the input file, defaults to
2077                     # 'process_generic_property_file'
2078     main::set_access('handler', \%handler, qw{ c });
2079
2080     my %property;
2081     # name of property this file is for.  defaults to none, meaning not
2082     # applicable, or is otherwise determinable, for example, from each line.
2083     main::set_access('property', \%property, qw{ c r });
2084
2085     my %optional;
2086     # This is either an unsigned number, or a list of property names.  In the
2087     # former case, if it is non-zero, it means the file is optional, so if the
2088     # file is absent, no warning about that is output.  In the latter case, it
2089     # is a list of properties that the file (exclusively) defines.  If the
2090     # file is present, tables for those properties will be produced; if
2091     # absent, none will, even if they are listed elsewhere (namely
2092     # PropertyAliases.txt and PropValueAliases.txt) as being in this release,
2093     # and no warnings will be raised about them not being available.  (And no
2094     # warning about the file itself will be raised.)
2095     main::set_access('optional', \%optional, qw{ c readable_array } );
2096
2097     my %non_skip;
2098     # This is used for debugging, to skip processing of all but a few input
2099     # files.  Add 'non_skip => 1' to the constructor for those files you want
2100     # processed when you set the $debug_skip global.
2101     main::set_access('non_skip', \%non_skip, 'c');
2102
2103     my %skip;
2104     # This is used to skip processing of this input file (semi-) permanently.
2105     # The value should be the reason the file is being skipped.  It is used
2106     # for files that we aren't planning to process anytime soon, but want to
2107     # allow to be in the directory and be checked for their names not
2108     # conflicting with any other files on a DOS 8.3 name filesystem, but to
2109     # not otherwise be processed, and to not raise a warning about not being
2110     # handled.  In the constructor call, any value that evaluates to a numeric
2111     # 0 or undef means don't skip.  Any other value is a string giving the
2112     # reason it is being skippped, and this will appear in generated pod.
2113     # However, an empty string reason will suppress the pod entry.
2114     # Internally, calls that evaluate to numeric 0 are changed into undef to
2115     # distinguish them from an empty string call.
2116     main::set_access('skip', \%skip, 'c', 'r');
2117
2118     my %each_line_handler;
2119     # list of subroutines to look at and filter each non-comment line in the
2120     # file.  defaults to none.  The subroutines are called in order, each is
2121     # to adjust $_ for the next one, and the final one adjusts it for
2122     # 'handler'
2123     main::set_access('each_line_handler', \%each_line_handler, 'c');
2124
2125     my %properties; # Optional ordered list of the properties that occur in each
2126     # meaningful line of the input file.  If present, an appropriate
2127     # each_line_handler() is automatically generated and pushed onto the stack
2128     # of such handlers.  This is useful when a file contains multiple
2129     # proerties per line, but no other special considerations are necessary.
2130     # The special value "<ignored>" means to discard the corresponding input
2131     # field.
2132     # Any @missing lines in the file should also match this syntax; no such
2133     # files exist as of 6.3.  But if it happens in a future release, the code
2134     # could be expanded to properly parse them.
2135     main::set_access('properties', \%properties, qw{ c r });
2136
2137     my %has_missings_defaults;
2138     # ? Are there lines in the file giving default values for code points
2139     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2140     # the norm, but IGNORED means it has such lines, but the handler doesn't
2141     # use them.  Having these three states allows us to catch changes to the
2142     # UCD that this program should track.  XXX This could be expanded to
2143     # specify the syntax for such lines, like %properties above.
2144     main::set_access('has_missings_defaults',
2145                                         \%has_missings_defaults, qw{ c r });
2146
2147     my %construction_time_handler;
2148     # Subroutine to call at the end of the new method.  If undef, no such
2149     # handler is called.
2150     main::set_access('construction_time_handler',
2151                                         \%construction_time_handler, qw{ c });
2152
2153     my %pre_handler;
2154     # Subroutine to call before doing anything else in the file.  If undef, no
2155     # such handler is called.
2156     main::set_access('pre_handler', \%pre_handler, qw{ c });
2157
2158     my %eof_handler;
2159     # Subroutines to call upon getting an EOF on the input file, but before
2160     # that is returned to the main handler.  This is to allow buffers to be
2161     # flushed.  The handler is expected to call insert_lines() or
2162     # insert_adjusted() with the buffered material
2163     main::set_access('eof_handler', \%eof_handler, qw{ c });
2164
2165     my %post_handler;
2166     # Subroutine to call after all the lines of the file are read in and
2167     # processed.  If undef, no such handler is called.  Note that this cannot
2168     # add lines to be processed; instead use eof_handler
2169     main::set_access('post_handler', \%post_handler, qw{ c });
2170
2171     my %progress_message;
2172     # Message to print to display progress in lieu of the standard one
2173     main::set_access('progress_message', \%progress_message, qw{ c });
2174
2175     my %handle;
2176     # cache open file handle, internal.  Is undef if file hasn't been
2177     # processed at all, empty if has;
2178     main::set_access('handle', \%handle);
2179
2180     my %added_lines;
2181     # cache of lines added virtually to the file, internal
2182     main::set_access('added_lines', \%added_lines);
2183
2184     my %remapped_lines;
2185     # cache of lines added virtually to the file, internal
2186     main::set_access('remapped_lines', \%remapped_lines);
2187
2188     my %errors;
2189     # cache of errors found, internal
2190     main::set_access('errors', \%errors);
2191
2192     my %missings;
2193     # storage of '@missing' defaults lines
2194     main::set_access('missings', \%missings);
2195
2196     my %early;
2197     # Used for properties that must be defined (for Perl's purposes) on
2198     # versions of Unicode earlier than Unicode itself defines them.  The
2199     # parameter is an array (it would be better to be a hash, but not worth
2200     # bothering about due to its rare use).
2201     #
2202     # The first element is either a code reference to call when in a release
2203     # earlier than the Unicode file is available in, or it is an alternate
2204     # file to use instead of the non-existent one.  This file must have been
2205     # plunked down in the same directory as mktables.  Should you be compiling
2206     # on a release that needs such a file, mktables will abort the
2207     # compilation, and tell you where to get the necessary file(s), and what
2208     # name(s) to use to store them as.
2209     # In the case of specifying an alternate file, the array must contain two
2210     # further elements:
2211     #
2212     # [1] is the name of the property that will be generated by this file.
2213     # The class automatically takes the input file and excludes any code
2214     # points in it that were not assigned in the Unicode version being
2215     # compiled.  It then uses this result to define the property in the given
2216     # version.  Since the property doesn't actually exist in the Unicode
2217     # version being compiled, this should be a name accessible only by core
2218     # perl.  If it is the same name as the regular property, the constructor
2219     # will mark the output table as a $PLACEHOLDER so that it doesn't actually
2220     # get output, and so will be unusable by non-core code.  Otherwise it gets
2221     # marked as $INTERNAL_ONLY.
2222     #
2223     # [2] is a property value to assign (only when compiling Unicode 1.1.5) to
2224     # the Hangul syllables in that release (which were ripped out in version
2225     # 2) for the given property .  (Hence it is ignored except when compiling
2226     # version 1.  You only get one value that applies to all of them, which
2227     # may not be the actual reality, but probably nobody cares anyway for
2228     # these obsolete characters.)
2229     #
2230     # Not all files can be handled in the above way, and so the code ref
2231     # alternative is available.  It can do whatever it needs to.  The other
2232     # array elements are optional in this case, and the code is free to use or
2233     # ignore them if they are present.
2234     #
2235     # Internally, the constructor unshifts a 0 or 1 onto this array to
2236     # indicate if an early alternative is actually being used or not.  This
2237     # makes for easier testing later on.
2238     main::set_access('early', \%early, 'c');
2239
2240     my %required_even_in_debug_skip;
2241     # debug_skip is used to speed up compilation during debugging by skipping
2242     # processing files that are not needed for the task at hand.  However,
2243     # some files pretty much can never be skipped, and this is used to specify
2244     # that this is one of them.  In order to skip this file, the call to the
2245     # constructor must be edited to comment out this parameter.
2246     main::set_access('required_even_in_debug_skip',
2247                      \%required_even_in_debug_skip, 'c');
2248
2249     my %withdrawn;
2250     # Some files get removed from the Unicode DB.  This is a version object
2251     # giving the first release without this file.
2252     main::set_access('withdrawn', \%withdrawn, 'c');
2253
2254     my %in_this_release;
2255     # Calculated value from %first_released and %withdrawn.  Are we compiling
2256     # a Unicode release which includes this file?
2257     main::set_access('in_this_release', \%in_this_release);
2258
2259     sub _next_line;
2260     sub _next_line_with_remapped_range;
2261
2262     sub new {
2263         my $class = shift;
2264
2265         my $self = bless \do{ my $anonymous_scalar }, $class;
2266         my $addr = do { no overloading; pack 'J', $self; };
2267
2268         # Set defaults
2269         $handler{$addr} = \&main::process_generic_property_file;
2270         $non_skip{$addr} = 0;
2271         $skip{$addr} = undef;
2272         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2273         $handle{$addr} = undef;
2274         $added_lines{$addr} = [ ];
2275         $remapped_lines{$addr} = [ ];
2276         $each_line_handler{$addr} = [ ];
2277         $eof_handler{$addr} = [ ];
2278         $errors{$addr} = { };
2279         $missings{$addr} = [ ];
2280         $early{$addr} = [ ];
2281         $optional{$addr} = [ ];
2282
2283         # Two positional parameters.
2284         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2285         $file{$addr} = main::internal_file_to_platform(shift);
2286         $first_released{$addr} = shift;
2287
2288         # The rest of the arguments are key => value pairs
2289         # %constructor_fields has been set up earlier to list all possible
2290         # ones.  Either set or push, depending on how the default has been set
2291         # up just above.
2292         my %args = @_;
2293         foreach my $key (keys %args) {
2294             my $argument = $args{$key};
2295
2296             # Note that the fields are the lower case of the constructor keys
2297             my $hash = $constructor_fields{lc $key};
2298             if (! defined $hash) {
2299                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2300                 next;
2301             }
2302             if (ref $hash->{$addr} eq 'ARRAY') {
2303                 if (ref $argument eq 'ARRAY') {
2304                     foreach my $argument (@{$argument}) {
2305                         next if ! defined $argument;
2306                         push @{$hash->{$addr}}, $argument;
2307                     }
2308                 }
2309                 else {
2310                     push @{$hash->{$addr}}, $argument if defined $argument;
2311                 }
2312             }
2313             else {
2314                 $hash->{$addr} = $argument;
2315             }
2316             delete $args{$key};
2317         };
2318
2319         $non_skip{$addr} = 1 if $required_even_in_debug_skip{$addr};
2320
2321         # Convert 0 (meaning don't skip) to undef
2322         undef $skip{$addr} unless $skip{$addr};
2323
2324         # Handle the case where this file is optional
2325         my $pod_message_for_non_existent_optional = "";
2326         if ($optional{$addr}->@*) {
2327
2328             # First element is the pod message
2329             $pod_message_for_non_existent_optional
2330                                                 = shift $optional{$addr}->@*;
2331             # Convert a 0 'Optional' argument to an empty list to make later
2332             # code more concise.
2333             if (   $optional{$addr}->@*
2334                 && $optional{$addr}->@* == 1
2335                 && $optional{$addr}[0] ne ""
2336                 && $optional{$addr}[0] !~ /\D/
2337                 && $optional{$addr}[0] == 0)
2338             {
2339                 $optional{$addr} = [ ];
2340             }
2341             else {  # But if the only element doesn't evaluate to 0, make sure
2342                     # that this file is indeed considered optional below.
2343                 unshift $optional{$addr}->@*, 1;
2344             }
2345         }
2346
2347         my $progress;
2348         my $function_instead_of_file = 0;
2349
2350         # If we are compiling a Unicode release earlier than the file became
2351         # available, the constructor may have supplied a substitute
2352         if ($first_released{$addr} gt $v_version && $early{$addr}->@*) {
2353
2354             # Yes, we have a substitute, that we will use; mark it so
2355             unshift $early{$addr}->@*, 1;
2356
2357             # See the definition of %early for what the array elements mean.
2358             # If we have a property this defines, create a table and default
2359             # map for it now (at essentially compile time), so that it will be
2360             # available for the whole of run time.  (We will want to add this
2361             # name as an alias when we are using the official property name;
2362             # but this must be deferred until run(), because at construction
2363             # time the official names have yet to be defined.)
2364             if ($early{$addr}[2]) {
2365                 my $fate = ($property{$addr}
2366                             && $property{$addr} eq $early{$addr}[2])
2367                           ? $PLACEHOLDER
2368                           : $INTERNAL_ONLY;
2369                 my $prop_object = Property->new($early{$addr}[2],
2370                                                 Fate => $fate,
2371                                                 Perl_Extension => 1,
2372                                                 );
2373
2374                 # Use the default mapping for the regular property for this
2375                 # substitute one.
2376                 if (    defined $property{$addr}
2377                     &&  defined $default_mapping{$property{$addr}})
2378                 {
2379                     $prop_object
2380                         ->set_default_map($default_mapping{$property{$addr}});
2381                 }
2382             }
2383
2384             if (ref $early{$addr}[1] eq 'CODE') {
2385                 $function_instead_of_file = 1;
2386
2387                 # If the first element of the array is a code ref, the others
2388                 # are optional.
2389                 $handler{$addr} = $early{$addr}[1];
2390                 $property{$addr} = $early{$addr}[2]
2391                                                 if defined $early{$addr}[2];
2392                 $progress = "substitute $file{$addr}";
2393
2394                 undef $file{$addr};
2395             }
2396             else {  # Specifying a substitute file
2397
2398                 if (! main::file_exists($early{$addr}[1])) {
2399
2400                     # If we don't see the substitute file, generate an error
2401                     # message giving the needed things, and add it to the list
2402                     # of such to output before actual processing happens
2403                     # (hence the user finds out all of them in one run).
2404                     # Instead of creating a general method for NameAliases,
2405                     # hard-code it here, as there is unlikely to ever be a
2406                     # second one which needs special handling.
2407                     my $string_version = ($file{$addr} eq "NameAliases.txt")
2408                                     ? 'at least 6.1 (the later, the better)'
2409                                     : sprintf "%vd", $first_released{$addr};
2410                     push @missing_early_files, <<END;
2411 '$file{$addr}' version $string_version should be copied to '$early{$addr}[1]'.
2412 END
2413                     ;
2414                     return;
2415                 }
2416                 $progress = $early{$addr}[1];
2417                 $progress .= ", substituting for $file{$addr}" if $file{$addr};
2418                 $file{$addr} = $early{$addr}[1];
2419                 $property{$addr} = $early{$addr}[2];
2420
2421                 # Ignore code points not in the version being compiled
2422                 push $each_line_handler{$addr}->@*, \&_exclude_unassigned;
2423
2424                 if (   $v_version lt v2.0        # Hanguls in this release ...
2425                     && defined $early{$addr}[3]) # ... need special treatment
2426                 {
2427                     push $eof_handler{$addr}->@*, \&_fixup_obsolete_hanguls;
2428                 }
2429             }
2430
2431             # And this substitute is valid for all releases.
2432             $first_released{$addr} = v0;
2433         }
2434         else {  # Normal behavior
2435             $progress = $file{$addr};
2436             unshift $early{$addr}->@*, 0; # No substitute
2437         }
2438
2439         my $file = $file{$addr};
2440         $progress_message{$addr} = "Processing $progress"
2441                                             unless $progress_message{$addr};
2442
2443         # A file should be there if it is within the window of versions for
2444         # which Unicode supplies it
2445         if ($withdrawn{$addr} && $withdrawn{$addr} le $v_version) {
2446             $in_this_release{$addr} = 0;
2447             $skip{$addr} = "";
2448         }
2449         else {
2450             $in_this_release{$addr} = $first_released{$addr} le $v_version;
2451
2452             # Check that the file for this object (possibly using a substitute
2453             # for early releases) exists or we have a function alternative
2454             if (   ! $function_instead_of_file
2455                 && ! main::file_exists($file))
2456             {
2457                 # Here there is nothing available for this release.  This is
2458                 # fine if we aren't expecting anything in this release.
2459                 if (! $in_this_release{$addr}) {
2460                     $skip{$addr} = "";  # Don't remark since we expected
2461                                         # nothing and got nothing
2462                 }
2463                 elsif ($optional{$addr}->@*) {
2464
2465                     # Here the file is optional in this release; Use the
2466                     # passed in text to document this case in the pod.
2467                     $skip{$addr} = $pod_message_for_non_existent_optional;
2468                 }
2469                 elsif (   $in_this_release{$addr}
2470                        && ! defined $skip{$addr}
2471                        && defined $file)
2472                 { # Doesn't exist but should.
2473                     $skip{$addr} = "'$file' not found.  Possibly Big problems";
2474                     Carp::my_carp($skip{$addr});
2475                 }
2476             }
2477             elsif ($debug_skip && ! defined $skip{$addr} && ! $non_skip{$addr})
2478             {
2479
2480                 # The file exists; if not skipped for another reason, and we are
2481                 # skipping most everything during debugging builds, use that as
2482                 # the skip reason.
2483                 $skip{$addr} = '$debug_skip is on'
2484             }
2485         }
2486
2487         if (   ! $debug_skip
2488             && $non_skip{$addr}
2489             && ! $required_even_in_debug_skip{$addr}
2490             && $verbosity)
2491         {
2492             print "Warning: " . __PACKAGE__ . " constructor for $file has useless 'non_skip' in it\n";
2493         }
2494
2495         # Here, we have figured out if we will be skipping this file or not.
2496         # If so, we add any single property it defines to any passed in
2497         # optional property list.  These will be dealt with at run time.
2498         if (defined $skip{$addr}) {
2499             if ($property{$addr}) {
2500                 push $optional{$addr}->@*, $property{$addr};
2501             }
2502         } # Otherwise, are going to process the file.
2503         elsif ($property{$addr}) {
2504
2505             # If the file has a property defined in the constructor for it, it
2506             # means that the property is not listed in the file's entries.  So
2507             # add a handler (to the list of line handlers) to insert the
2508             # property name into the lines, to provide a uniform interface to
2509             # the final processing subroutine.
2510             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2511         }
2512         elsif ($properties{$addr}) {
2513
2514             # Similarly, there may be more than one property represented on
2515             # each line, with no clue but the constructor input what those
2516             # might be.  Add a handler for each line in the input so that it
2517             # creates a separate input line for each property in those input
2518             # lines, thus making them suitable to handle generically.
2519
2520             push @{$each_line_handler{$addr}},
2521                  sub {
2522                     my $file = shift;
2523                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2524
2525                     my @fields = split /\s*;\s*/, $_, -1;
2526
2527                     if (@fields - 1 > @{$properties{$addr}}) {
2528                         $file->carp_bad_line('Extra fields');
2529                         $_ = "";
2530                         return;
2531                     }
2532                     my $range = shift @fields;  # 0th element is always the
2533                                                 # range
2534
2535                     # The next fields in the input line correspond
2536                     # respectively to the stored properties.
2537                     for my $i (0 ..  @{$properties{$addr}} - 1) {
2538                         my $property_name = $properties{$addr}[$i];
2539                         next if $property_name eq '<ignored>';
2540                         $file->insert_adjusted_lines(
2541                               "$range; $property_name; $fields[$i]");
2542                     }
2543                     $_ = "";
2544
2545                     return;
2546                 };
2547         }
2548
2549         {   # On non-ascii platforms, we use a special pre-handler
2550             no strict;
2551             no warnings 'once';
2552             *next_line = (main::NON_ASCII_PLATFORM)
2553                          ? *_next_line_with_remapped_range
2554                          : *_next_line;
2555         }
2556
2557         &{$construction_time_handler{$addr}}($self)
2558                                         if $construction_time_handler{$addr};
2559
2560         return $self;
2561     }
2562
2563
2564     use overload
2565         fallback => 0,
2566         qw("") => "_operator_stringify",
2567         "." => \&main::_operator_dot,
2568         ".=" => \&main::_operator_dot_equal,
2569     ;
2570
2571     sub _operator_stringify {
2572         my $self = shift;
2573
2574         return __PACKAGE__ . " object for " . $self->file;
2575     }
2576
2577     sub run {
2578         # Process the input object $self.  This opens and closes the file and
2579         # calls all the handlers for it.  Currently,  this can only be called
2580         # once per file, as it destroy's the EOF handlers
2581
2582         # flag to make sure extracted files are processed early
2583         state $seen_non_extracted_non_age = 0;
2584
2585         my $self = shift;
2586         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2587
2588         my $addr = do { no overloading; pack 'J', $self; };
2589
2590         my $file = $file{$addr};
2591
2592         if (! $file) {
2593             $handle{$addr} = 'pretend_is_open';
2594         }
2595         else {
2596             if ($seen_non_extracted_non_age) {
2597                 if ($file =~ /$EXTRACTED/i) # Some platforms may change the
2598                                             # case of the file's name
2599                 {
2600                     Carp::my_carp_bug(main::join_lines(<<END
2601 $file should be processed just after the 'Prop...Alias' files, and before
2602 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2603 have subtle problems
2604 END
2605                     ));
2606                 }
2607             }
2608             elsif ($EXTRACTED_DIR
2609
2610                     # We only do this check for generic property files
2611                     && $handler{$addr} == \&main::process_generic_property_file
2612
2613                     && $file !~ /$EXTRACTED/i
2614                     && lc($file) ne 'dage.txt')
2615             {
2616                 # We don't set this (by the 'if' above) if we have no
2617                 # extracted directory, so if running on an early version,
2618                 # this test won't work.  Not worth worrying about.
2619                 $seen_non_extracted_non_age = 1;
2620             }
2621
2622             # Mark the file as having being processed, and warn if it
2623             # isn't a file we are expecting.  As we process the files,
2624             # they are deleted from the hash, so any that remain at the
2625             # end of the program are files that we didn't process.
2626             my $fkey = File::Spec->rel2abs($file);
2627             my $exists = delete $potential_files{lc($fkey)};
2628
2629             Carp::my_carp("Was not expecting '$file'.")
2630                                     if $exists && ! $in_this_release{$addr};
2631
2632             # If there is special handling for compiling Unicode releases
2633             # earlier than the first one in which Unicode defines this
2634             # property ...
2635             if ($early{$addr}->@* > 1) {
2636
2637                 # Mark as processed any substitute file that would be used in
2638                 # such a release
2639                 $fkey = File::Spec->rel2abs($early{$addr}[1]);
2640                 delete $potential_files{lc($fkey)};
2641
2642                 # As commented in the constructor code, when using the
2643                 # official property, we still have to allow the publicly
2644                 # inaccessible early name so that the core code which uses it
2645                 # will work regardless.
2646                 if (! $early{$addr}[0] && $early{$addr}->@* > 2) {
2647                     my $early_property_name = $early{$addr}[2];
2648                     if ($property{$addr} ne $early_property_name) {
2649                         main::property_ref($property{$addr})
2650                                             ->add_alias($early_property_name);
2651                     }
2652                 }
2653             }
2654
2655             # We may be skipping this file ...
2656             if (defined $skip{$addr}) {
2657
2658                 # If the file isn't supposed to be in this release, there is
2659                 # nothing to do
2660                 if ($in_this_release{$addr}) {
2661
2662                     # But otherwise, we may print a message
2663                     if ($debug_skip) {
2664                         print STDERR "Skipping input file '$file'",
2665                                      " because '$skip{$addr}'\n";
2666                     }
2667
2668                     # And add it to the list of skipped files, which is later
2669                     # used to make the pod
2670                     $skipped_files{$file} = $skip{$addr};
2671
2672                     # The 'optional' list contains properties that are also to
2673                     # be skipped along with the file.  (There may also be
2674                     # digits which are just placeholders to make sure it isn't
2675                     # an empty list
2676                     foreach my $property ($optional{$addr}->@*) {
2677                         next unless $property =~ /\D/;
2678                         my $prop_object = main::property_ref($property);
2679                         next unless defined $prop_object;
2680                         $prop_object->set_fate($SUPPRESSED, $skip{$addr});
2681                     }
2682                 }
2683
2684                 return;
2685             }
2686
2687             # Here, we are going to process the file.  Open it, converting the
2688             # slashes used in this program into the proper form for the OS
2689             my $file_handle;
2690             if (not open $file_handle, "<", $file) {
2691                 Carp::my_carp("Can't open $file.  Skipping: $!");
2692                 return;
2693             }
2694             $handle{$addr} = $file_handle; # Cache the open file handle
2695
2696             # If possible, make sure that the file is the correct version.
2697             # (This data isn't available on early Unicode releases or in
2698             # UnicodeData.txt.)  We don't do this check if we are using a
2699             # substitute file instead of the official one (though the code
2700             # could be extended to do so).
2701             if ($in_this_release{$addr}
2702                 && ! $early{$addr}[0]
2703                 && lc($file) ne 'unicodedata.txt')
2704             {
2705                 if ($file !~ /^Unihan/i) {
2706
2707                     # The non-Unihan files started getting version numbers in
2708                     # 3.2, but some files in 4.0 are unchanged from 3.2, and
2709                     # marked as 3.2.  4.0.1 is the first version where there
2710                     # are no files marked as being from less than 4.0, though
2711                     # some are marked as 4.0.  In versions after that, the
2712                     # numbers are correct.
2713                     if ($v_version ge v4.0.1) {
2714                         $_ = <$file_handle>;    # The version number is in the
2715                                                 # very first line
2716                         if ($_ !~ / - $string_version \. /x) {
2717                             chomp;
2718                             $_ =~ s/^#\s*//;
2719
2720                             # 4.0.1 had some valid files that weren't updated.
2721                             if (! ($v_version eq v4.0.1 && $_ =~ /4\.0\.0/)) {
2722                                 die Carp::my_carp("File '$file' is version "
2723                                                 . "'$_'.  It should be "
2724                                                 . "version $string_version");
2725                             }
2726                         }
2727                     }
2728                 }
2729                 elsif ($v_version ge v6.0.0) { # Unihan
2730
2731                     # Unihan files didn't get accurate version numbers until
2732                     # 6.0.  The version is somewhere in the first comment
2733                     # block
2734                     while (<$file_handle>) {
2735                         if ($_ !~ /^#/) {
2736                             Carp::my_carp_bug("Could not find the expected "
2737                                             . "version info in file '$file'");
2738                             last;
2739                         }
2740                         chomp;
2741                         $_ =~ s/^#\s*//;
2742                         next if $_ !~ / version: /x;
2743                         last if $_ =~ /$string_version/;
2744                         die Carp::my_carp("File '$file' is version "
2745                                         . "'$_'.  It should be "
2746                                         . "version $string_version");
2747                     }
2748                 }
2749             }
2750         }
2751
2752         print "$progress_message{$addr}\n" if $verbosity >= $PROGRESS;
2753
2754         # Call any special handler for before the file.
2755         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2756
2757         # Then the main handler
2758         &{$handler{$addr}}($self);
2759
2760         # Then any special post-file handler.
2761         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2762
2763         # If any errors have been accumulated, output the counts (as the first
2764         # error message in each class was output when it was encountered).
2765         if ($errors{$addr}) {
2766             my $total = 0;
2767             my $types = 0;
2768             foreach my $error (keys %{$errors{$addr}}) {
2769                 $total += $errors{$addr}->{$error};
2770                 delete $errors{$addr}->{$error};
2771                 $types++;
2772             }
2773             if ($total > 1) {
2774                 my $message
2775                         = "A total of $total lines had errors in $file.  ";
2776
2777                 $message .= ($types == 1)
2778                             ? '(Only the first one was displayed.)'
2779                             : '(Only the first of each type was displayed.)';
2780                 Carp::my_carp($message);
2781             }
2782         }
2783
2784         if (@{$missings{$addr}}) {
2785             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2786         }
2787
2788         # If a real file handle, close it.
2789         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2790                                                         ref $handle{$addr};
2791         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2792                                # the file, as opposed to undef
2793         return;
2794     }
2795
2796     sub _next_line {
2797         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2798         # if such a line exists.  'logical' means that any lines that have
2799         # been added via insert_lines() will be returned in $_ before the file
2800         # is read again.
2801
2802         my $self = shift;
2803         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2804
2805         my $addr = do { no overloading; pack 'J', $self; };
2806
2807         # Here the file is open (or if the handle is not a ref, is an open
2808         # 'virtual' file).  Get the next line; any inserted lines get priority
2809         # over the file itself.
2810         my $adjusted;
2811
2812         LINE:
2813         while (1) { # Loop until find non-comment, non-empty line
2814             #local $to_trace = 1 if main::DEBUG;
2815             my $inserted_ref = shift @{$added_lines{$addr}};
2816             if (defined $inserted_ref) {
2817                 ($adjusted, $_) = @{$inserted_ref};
2818                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2819                 return 1 if $adjusted;
2820             }
2821             else {
2822                 last if ! ref $handle{$addr}; # Don't read unless is real file
2823                 last if ! defined ($_ = readline $handle{$addr});
2824             }
2825             chomp;
2826             trace $_ if main::DEBUG && $to_trace;
2827
2828             # See if this line is the comment line that defines what property
2829             # value that code points that are not listed in the file should
2830             # have.  The format or existence of these lines is not guaranteed
2831             # by Unicode since they are comments, but the documentation says
2832             # that this was added for machine-readability, so probably won't
2833             # change.  This works starting in Unicode Version 5.0.  They look
2834             # like:
2835             #
2836             # @missing: 0000..10FFFF; Not_Reordered
2837             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2838             # @missing: 0000..10FFFF; ; NaN
2839             #
2840             # Save the line for a later get_missings() call.
2841             if (/$missing_defaults_prefix/) {
2842                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2843                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2844                 }
2845                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2846                     my @defaults = split /\s* ; \s*/x, $_;
2847
2848                     # The first field is the @missing, which ends in a
2849                     # semi-colon, so can safely shift.
2850                     shift @defaults;
2851
2852                     # Some of these lines may have empty field placeholders
2853                     # which get in the way.  An example is:
2854                     # @missing: 0000..10FFFF; ; NaN
2855                     # Remove them.  Process starting from the top so the
2856                     # splice doesn't affect things still to be looked at.
2857                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2858                         next if $defaults[$i] ne "";
2859                         splice @defaults, $i, 1;
2860                     }
2861
2862                     # What's left should be just the property (maybe) and the
2863                     # default.  Having only one element means it doesn't have
2864                     # the property.
2865                     my $default;
2866                     my $property;
2867                     if (@defaults >= 1) {
2868                         if (@defaults == 1) {
2869                             $default = $defaults[0];
2870                         }
2871                         else {
2872                             $property = $defaults[0];
2873                             $default = $defaults[1];
2874                         }
2875                     }
2876
2877                     if (@defaults < 1
2878                         || @defaults > 2
2879                         || ($default =~ /^</
2880                             && $default !~ /^<code *point>$/i
2881                             && $default !~ /^<none>$/i
2882                             && $default !~ /^<script>$/i))
2883                     {
2884                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2885                     }
2886                     else {
2887
2888                         # If the property is missing from the line, it should
2889                         # be the one for the whole file
2890                         $property = $property{$addr} if ! defined $property;
2891
2892                         # Change <none> to the null string, which is what it
2893                         # really means.  If the default is the code point
2894                         # itself, set it to <code point>, which is what
2895                         # Unicode uses (but sometimes they've forgotten the
2896                         # space)
2897                         if ($default =~ /^<none>$/i) {
2898                             $default = "";
2899                         }
2900                         elsif ($default =~ /^<code *point>$/i) {
2901                             $default = $CODE_POINT;
2902                         }
2903                         elsif ($default =~ /^<script>$/i) {
2904
2905                             # Special case this one.  Currently is from
2906                             # ScriptExtensions.txt, and means for all unlisted
2907                             # code points, use their Script property values.
2908                             # For the code points not listed in that file, the
2909                             # default value is 'Unknown'.
2910                             $default = "Unknown";
2911                         }
2912
2913                         # Store them as a sub-arrays with both components.
2914                         push @{$missings{$addr}}, [ $default, $property ];
2915                     }
2916                 }
2917
2918                 # There is nothing for the caller to process on this comment
2919                 # line.
2920                 next;
2921             }
2922
2923             # Remove comments and trailing space, and skip this line if the
2924             # result is empty
2925             s/#.*//;
2926             s/\s+$//;
2927             next if /^$/;
2928
2929             # Call any handlers for this line, and skip further processing of
2930             # the line if the handler sets the line to null.
2931             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2932                 &{$sub_ref}($self);
2933                 next LINE if /^$/;
2934             }
2935
2936             # Here the line is ok.  return success.
2937             return 1;
2938         } # End of looping through lines.
2939
2940         # If there are EOF handlers, call each (only once) and if it generates
2941         # more lines to process go back in the loop to handle them.
2942         while ($eof_handler{$addr}->@*) {
2943             &{$eof_handler{$addr}[0]}($self);
2944             shift $eof_handler{$addr}->@*;   # Currently only get one shot at it.
2945             goto LINE if $added_lines{$addr};
2946         }
2947
2948         # Return failure -- no more lines.
2949         return 0;
2950
2951     }
2952
2953     sub _next_line_with_remapped_range {
2954         my $self = shift;
2955         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2956
2957         # like _next_line(), but for use on non-ASCII platforms.  It sets $_
2958         # to be the next logical input line, if any.  Returns non-zero if such
2959         # a line exists.  'logical' means that any lines that have been added
2960         # via insert_lines() will be returned in $_ before the file is read
2961         # again.
2962         #
2963         # The difference from _next_line() is that this remaps the Unicode
2964         # code points in the input to those of the native platform.  Each
2965         # input line contains a single code point, or a single contiguous
2966         # range of them  This routine splits each range into its individual
2967         # code points and caches them.  It returns the cached values,
2968         # translated into their native equivalents, one at a time, for each
2969         # call, before reading the next line.  Since native values can only be
2970         # a single byte wide, no translation is needed for code points above
2971         # 0xFF, and ranges that are entirely above that number are not split.
2972         # If an input line contains the range 254-1000, it would be split into
2973         # three elements: 254, 255, and 256-1000.  (The downstream table
2974         # insertion code will sort and coalesce the individual code points
2975         # into appropriate ranges.)
2976
2977         my $addr = do { no overloading; pack 'J', $self; };
2978
2979         while (1) {
2980
2981             # Look in cache before reading the next line.  Return any cached
2982             # value, translated
2983             my $inserted = shift @{$remapped_lines{$addr}};
2984             if (defined $inserted) {
2985                 trace $inserted if main::DEBUG && $to_trace;
2986                 $_ = $inserted =~ s/^ ( \d+ ) /sprintf("%04X", utf8::unicode_to_native($1))/xer;
2987                 trace $_ if main::DEBUG && $to_trace;
2988                 return 1;
2989             }
2990
2991             # Get the next line.
2992             return 0 unless _next_line($self);
2993
2994             # If there is a special handler for it, return the line,
2995             # untranslated.  This should happen only for files that are
2996             # special, not being code-point related, such as property names.
2997             return 1 if $handler{$addr}
2998                                     != \&main::process_generic_property_file;
2999
3000             my ($range, $property_name, $map, @remainder)
3001                 = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
3002
3003             if (@remainder
3004                 || ! defined $property_name
3005                 || $range !~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
3006             {
3007                 Carp::my_carp_bug("Unrecognized input line '$_'.  Ignored");
3008             }
3009
3010             my $low = hex $1;
3011             my $high = (defined $2) ? hex $2 : $low;
3012
3013             # If the input maps the range to another code point, remap the
3014             # target if it is between 0 and 255.
3015             my $tail;
3016             if (defined $map) {
3017                 $map =~ s/\b 00 ( [0-9A-F]{2} ) \b/sprintf("%04X", utf8::unicode_to_native(hex $1))/gxe;
3018                 $tail = "$property_name; $map";
3019                 $_ = "$range; $tail";
3020             }
3021             else {
3022                 $tail = $property_name;
3023             }
3024
3025             # If entire range is above 255, just return it, unchanged (except
3026             # any mapped-to code point, already changed above)
3027             return 1 if $low > 255;
3028
3029             # Cache an entry for every code point < 255.  For those in the
3030             # range above 255, return a dummy entry for just that portion of
3031             # the range.  Note that this will be out-of-order, but that is not
3032             # a problem.
3033             foreach my $code_point ($low .. $high) {
3034                 if ($code_point > 255) {
3035                     $_ = sprintf "%04X..%04X; $tail", $code_point, $high;
3036                     return 1;
3037                 }
3038                 push @{$remapped_lines{$addr}}, "$code_point; $tail";
3039             }
3040         } # End of looping through lines.
3041
3042         # NOTREACHED
3043     }
3044
3045 #   Not currently used, not fully tested.
3046 #    sub peek {
3047 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
3048 #        # record.  Not callable from an each_line_handler(), nor does it call
3049 #        # an each_line_handler() on the line.
3050 #
3051 #        my $self = shift;
3052 #        my $addr = do { no overloading; pack 'J', $self; };
3053 #
3054 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
3055 #            my ($adjusted, $line) = @{$inserted_ref};
3056 #            next if $adjusted;
3057 #
3058 #            # Remove comments and trailing space, and return a non-empty
3059 #            # resulting line
3060 #            $line =~ s/#.*//;
3061 #            $line =~ s/\s+$//;
3062 #            return $line if $line ne "";
3063 #        }
3064 #
3065 #        return if ! ref $handle{$addr}; # Don't read unless is real file
3066 #        while (1) { # Loop until find non-comment, non-empty line
3067 #            local $to_trace = 1 if main::DEBUG;
3068 #            trace $_ if main::DEBUG && $to_trace;
3069 #            return if ! defined (my $line = readline $handle{$addr});
3070 #            chomp $line;
3071 #            push @{$added_lines{$addr}}, [ 0, $line ];
3072 #
3073 #            $line =~ s/#.*//;
3074 #            $line =~ s/\s+$//;
3075 #            return $line if $line ne "";
3076 #        }
3077 #
3078 #        return;
3079 #    }
3080
3081
3082     sub insert_lines {
3083         # Lines can be inserted so that it looks like they were in the input
3084         # file at the place it was when this routine is called.  See also
3085         # insert_adjusted_lines().  Lines inserted via this routine go through
3086         # any each_line_handler()
3087
3088         my $self = shift;
3089
3090         # Each inserted line is an array, with the first element being 0 to
3091         # indicate that this line hasn't been adjusted, and needs to be
3092         # processed.
3093         no overloading;
3094         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
3095         return;
3096     }
3097
3098     sub insert_adjusted_lines {
3099         # Lines can be inserted so that it looks like they were in the input
3100         # file at the place it was when this routine is called.  See also
3101         # insert_lines().  Lines inserted via this routine are already fully
3102         # adjusted, ready to be processed; each_line_handler()s handlers will
3103         # not be called.  This means this is not a completely general
3104         # facility, as only the last each_line_handler on the stack should
3105         # call this.  It could be made more general, by passing to each of the
3106         # line_handlers their position on the stack, which they would pass on
3107         # to this routine, and that would replace the boolean first element in
3108         # the anonymous array pushed here, so that the next_line routine could
3109         # use that to call only those handlers whose index is after it on the
3110         # stack.  But this is overkill for what is needed now.
3111
3112         my $self = shift;
3113         trace $_[0] if main::DEBUG && $to_trace;
3114
3115         # Each inserted line is an array, with the first element being 1 to
3116         # indicate that this line has been adjusted
3117         no overloading;
3118         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
3119         return;
3120     }
3121
3122     sub get_missings {
3123         # Returns the stored up @missings lines' values, and clears the list.
3124         # The values are in an array, consisting of the default in the first
3125         # element, and the property in the 2nd.  However, since these lines
3126         # can be stacked up, the return is an array of all these arrays.
3127
3128         my $self = shift;
3129         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3130
3131         my $addr = do { no overloading; pack 'J', $self; };
3132
3133         # If not accepting a list return, just return the first one.
3134         return shift @{$missings{$addr}} unless wantarray;
3135
3136         my @return = @{$missings{$addr}};
3137         undef @{$missings{$addr}};
3138         return @return;
3139     }
3140
3141     sub _exclude_unassigned {
3142
3143         # Takes the range in $_ and excludes code points that aren't assigned
3144         # in this release
3145
3146         state $skip_inserted_count = 0;
3147
3148         # Ignore recursive calls.
3149         if ($skip_inserted_count) {
3150             $skip_inserted_count--;
3151             return;
3152         }
3153
3154         # Find what code points are assigned in this release
3155         main::calculate_Assigned() if ! defined $Assigned;
3156
3157         my $self = shift;
3158         my $addr = do { no overloading; pack 'J', $self; };
3159         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3160
3161         my ($range, @remainder)
3162             = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
3163
3164         # Examine the range.
3165         if ($range =~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
3166         {
3167             my $low = hex $1;
3168             my $high = (defined $2) ? hex $2 : $low;
3169
3170             # Split the range into subranges of just those code points in it
3171             # that are assigned.
3172             my @ranges = (Range_List->new(Initialize
3173                               => Range->new($low, $high)) & $Assigned)->ranges;
3174
3175             # Do nothing if nothing in the original range is assigned in this
3176             # release; handle normally if everything is in this release.
3177             if (! @ranges) {
3178                 $_ = "";
3179             }
3180             elsif (@ranges != 1) {
3181
3182                 # Here, some code points in the original range aren't in this
3183                 # release; @ranges gives the ones that are.  Create fake input
3184                 # lines for each of the ranges, and set things up so that when
3185                 # this routine is called on that fake input, it will do
3186                 # nothing.
3187                 $skip_inserted_count = @ranges;
3188                 my $remainder = join ";", @remainder;
3189                 for my $range (@ranges) {
3190                     $self->insert_lines(sprintf("%04X..%04X;%s",
3191                                     $range->start, $range->end, $remainder));
3192                 }
3193                 $_ = "";    # The original range is now defunct.
3194             }
3195         }
3196
3197         return;
3198     }
3199
3200     sub _fixup_obsolete_hanguls {
3201
3202         # This is called only when compiling Unicode version 1.  All Unicode
3203         # data for subsequent releases assumes that the code points that were
3204         # Hangul syllables in this release only are something else, so if
3205         # using such data, we have to override it
3206
3207         my $self = shift;
3208         my $addr = do { no overloading; pack 'J', $self; };
3209         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3210
3211         my $object = main::property_ref($property{$addr});
3212         $object->add_map(0x3400, 0x4DFF,
3213                          $early{$addr}[3],  # Passed-in value for these
3214                          Replace => $UNCONDITIONALLY);
3215     }
3216
3217     sub _insert_property_into_line {
3218         # Add a property field to $_, if this file requires it.
3219
3220         my $self = shift;
3221         my $addr = do { no overloading; pack 'J', $self; };
3222         my $property = $property{$addr};
3223         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3224
3225         $_ =~ s/(;|$)/; $property$1/;
3226         return;
3227     }
3228
3229     sub carp_bad_line {
3230         # Output consistent error messages, using either a generic one, or the
3231         # one given by the optional parameter.  To avoid gazillions of the
3232         # same message in case the syntax of a  file is way off, this routine
3233         # only outputs the first instance of each message, incrementing a
3234         # count so the totals can be output at the end of the file.
3235
3236         my $self = shift;
3237         my $message = shift;
3238         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3239
3240         my $addr = do { no overloading; pack 'J', $self; };
3241
3242         $message = 'Unexpected line' unless $message;
3243
3244         # No trailing punctuation so as to fit with our addenda.
3245         $message =~ s/[.:;,]$//;
3246
3247         # If haven't seen this exact message before, output it now.  Otherwise
3248         # increment the count of how many times it has occurred
3249         unless ($errors{$addr}->{$message}) {
3250             Carp::my_carp("$message in '$_' in "
3251                             . $file{$addr}
3252                             . " at line $..  Skipping this line;");
3253             $errors{$addr}->{$message} = 1;
3254         }
3255         else {
3256             $errors{$addr}->{$message}++;
3257         }
3258
3259         # Clear the line to prevent any further (meaningful) processing of it.
3260         $_ = "";
3261
3262         return;
3263     }
3264 } # End closure
3265
3266 package Multi_Default;
3267
3268 # Certain properties in early versions of Unicode had more than one possible
3269 # default for code points missing from the files.  In these cases, one
3270 # default applies to everything left over after all the others are applied,
3271 # and for each of the others, there is a description of which class of code
3272 # points applies to it.  This object helps implement this by storing the
3273 # defaults, and for all but that final default, an eval string that generates
3274 # the class that it applies to.
3275
3276
3277 {   # Closure
3278
3279     main::setup_package();
3280
3281     my %class_defaults;
3282     # The defaults structure for the classes
3283     main::set_access('class_defaults', \%class_defaults);
3284
3285     my %other_default;
3286     # The default that applies to everything left over.
3287     main::set_access('other_default', \%other_default, 'r');
3288
3289
3290     sub new {
3291         # The constructor is called with default => eval pairs, terminated by
3292         # the left-over default. e.g.
3293         # Multi_Default->new(
3294         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
3295         #               -  0x200D',
3296         #        'R' => 'some other expression that evaluates to code points',
3297         #        .
3298         #        .
3299         #        .
3300         #        'U'));
3301         # It is best to leave the final value be the one that matches the
3302         # above-Unicode code points.
3303
3304         my $class = shift;
3305
3306         my $self = bless \do{my $anonymous_scalar}, $class;
3307         my $addr = do { no overloading; pack 'J', $self; };
3308
3309         while (@_ > 1) {
3310             my $default = shift;
3311             my $eval = shift;
3312             $class_defaults{$addr}->{$default} = $eval;
3313         }
3314
3315         $other_default{$addr} = shift;
3316
3317         return $self;
3318     }
3319
3320     sub get_next_defaults {
3321         # Iterates and returns the next class of defaults.
3322         my $self = shift;
3323         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3324
3325         my $addr = do { no overloading; pack 'J', $self; };
3326
3327         return each %{$class_defaults{$addr}};
3328     }
3329 }
3330
3331 package Alias;
3332
3333 # An alias is one of the names that a table goes by.  This class defines them
3334 # including some attributes.  Everything is currently setup in the
3335 # constructor.
3336
3337
3338 {   # Closure
3339
3340     main::setup_package();
3341
3342     my %name;
3343     main::set_access('name', \%name, 'r');
3344
3345     my %loose_match;
3346     # Should this name match loosely or not.
3347     main::set_access('loose_match', \%loose_match, 'r');
3348
3349     my %make_re_pod_entry;
3350     # Some aliases should not get their own entries in the re section of the
3351     # pod, because they are covered by a wild-card, and some we want to
3352     # discourage use of.  Binary
3353     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
3354
3355     my %ucd;
3356     # Is this documented to be accessible via Unicode::UCD
3357     main::set_access('ucd', \%ucd, 'r', 's');
3358
3359     my %status;
3360     # Aliases have a status, like deprecated, or even suppressed (which means
3361     # they don't appear in documentation).  Enum
3362     main::set_access('status', \%status, 'r');
3363
3364     my %ok_as_filename;
3365     # Similarly, some aliases should not be considered as usable ones for
3366     # external use, such as file names, or we don't want documentation to
3367     # recommend them.  Boolean
3368     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
3369
3370     sub new {
3371         my $class = shift;
3372
3373         my $self = bless \do { my $anonymous_scalar }, $class;
3374         my $addr = do { no overloading; pack 'J', $self; };
3375
3376         $name{$addr} = shift;
3377         $loose_match{$addr} = shift;
3378         $make_re_pod_entry{$addr} = shift;
3379         $ok_as_filename{$addr} = shift;
3380         $status{$addr} = shift;
3381         $ucd{$addr} = shift;
3382
3383         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3384
3385         # Null names are never ok externally
3386         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
3387
3388         return $self;
3389     }
3390 }
3391
3392 package Range;
3393
3394 # A range is the basic unit for storing code points, and is described in the
3395 # comments at the beginning of the program.  Each range has a starting code
3396 # point; an ending code point (not less than the starting one); a value
3397 # that applies to every code point in between the two end-points, inclusive;
3398 # and an enum type that applies to the value.  The type is for the user's
3399 # convenience, and has no meaning here, except that a non-zero type is
3400 # considered to not obey the normal Unicode rules for having standard forms.
3401 #
3402 # The same structure is used for both map and match tables, even though in the
3403 # latter, the value (and hence type) is irrelevant and could be used as a
3404 # comment.  In map tables, the value is what all the code points in the range
3405 # map to.  Type 0 values have the standardized version of the value stored as
3406 # well, so as to not have to recalculate it a lot.
3407
3408 sub trace { return main::trace(@_); }
3409
3410 {   # Closure
3411
3412     main::setup_package();
3413
3414     my %start;
3415     main::set_access('start', \%start, 'r', 's');
3416
3417     my %end;
3418     main::set_access('end', \%end, 'r', 's');
3419
3420     my %value;
3421     main::set_access('value', \%value, 'r');
3422
3423     my %type;
3424     main::set_access('type', \%type, 'r');
3425
3426     my %standard_form;
3427     # The value in internal standard form.  Defined only if the type is 0.
3428     main::set_access('standard_form', \%standard_form);
3429
3430     # Note that if these fields change, the dump() method should as well
3431
3432     sub new {
3433         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
3434         my $class = shift;
3435
3436         my $self = bless \do { my $anonymous_scalar }, $class;
3437         my $addr = do { no overloading; pack 'J', $self; };
3438
3439         $start{$addr} = shift;
3440         $end{$addr} = shift;
3441
3442         my %args = @_;
3443
3444         my $value = delete $args{'Value'};  # Can be 0
3445         $value = "" unless defined $value;
3446         $value{$addr} = $value;
3447
3448         $type{$addr} = delete $args{'Type'} || 0;
3449
3450         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3451
3452         return $self;
3453     }
3454
3455     use overload
3456         fallback => 0,
3457         qw("") => "_operator_stringify",
3458         "." => \&main::_operator_dot,
3459         ".=" => \&main::_operator_dot_equal,
3460     ;
3461
3462     sub _operator_stringify {
3463         my $self = shift;
3464         my $addr = do { no overloading; pack 'J', $self; };
3465
3466         # Output it like '0041..0065 (value)'
3467         my $return = sprintf("%04X", $start{$addr})
3468                         .  '..'
3469                         . sprintf("%04X", $end{$addr});
3470         my $value = $value{$addr};
3471         my $type = $type{$addr};
3472         $return .= ' (';
3473         $return .= "$value";
3474         $return .= ", Type=$type" if $type != 0;
3475         $return .= ')';
3476
3477         return $return;
3478     }
3479
3480     sub standard_form {
3481         # Calculate the standard form only if needed, and cache the result.
3482         # The standard form is the value itself if the type is special.
3483         # This represents a considerable CPU and memory saving - at the time
3484         # of writing there are 368676 non-special objects, but the standard
3485         # form is only requested for 22047 of them - ie about 6%.
3486
3487         my $self = shift;
3488         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3489
3490         my $addr = do { no overloading; pack 'J', $self; };
3491
3492         return $standard_form{$addr} if defined $standard_form{$addr};
3493
3494         my $value = $value{$addr};
3495         return $value if $type{$addr};
3496         return $standard_form{$addr} = main::standardize($value);
3497     }
3498
3499     sub dump {
3500         # Human, not machine readable.  For machine readable, comment out this
3501         # entire routine and let the standard one take effect.
3502         my $self = shift;
3503         my $indent = shift;
3504         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3505
3506         my $addr = do { no overloading; pack 'J', $self; };
3507
3508         my $return = $indent
3509                     . sprintf("%04X", $start{$addr})
3510                     . '..'
3511                     . sprintf("%04X", $end{$addr})
3512                     . " '$value{$addr}';";
3513         if (! defined $standard_form{$addr}) {
3514             $return .= "(type=$type{$addr})";
3515         }
3516         elsif ($standard_form{$addr} ne $value{$addr}) {
3517             $return .= "(standard '$standard_form{$addr}')";
3518         }
3519         return $return;
3520     }
3521 } # End closure
3522
3523 package _Range_List_Base;
3524
3525 # Base class for range lists.  A range list is simply an ordered list of
3526 # ranges, so that the ranges with the lowest starting numbers are first in it.
3527 #
3528 # When a new range is added that is adjacent to an existing range that has the
3529 # same value and type, it merges with it to form a larger range.
3530 #
3531 # Ranges generally do not overlap, except that there can be multiple entries
3532 # of single code point ranges.  This is because of NameAliases.txt.
3533 #
3534 # In this program, there is a standard value such that if two different
3535 # values, have the same standard value, they are considered equivalent.  This
3536 # value was chosen so that it gives correct results on Unicode data
3537
3538 # There are a number of methods to manipulate range lists, and some operators
3539 # are overloaded to handle them.
3540
3541 sub trace { return main::trace(@_); }
3542
3543 { # Closure
3544
3545     our $addr;
3546
3547     # Max is initialized to a negative value that isn't adjacent to 0, for
3548     # simpler tests
3549     my $max_init = -2;
3550
3551     main::setup_package();
3552
3553     my %ranges;
3554     # The list of ranges
3555     main::set_access('ranges', \%ranges, 'readable_array');
3556
3557     my %max;
3558     # The highest code point in the list.  This was originally a method, but
3559     # actual measurements said it was used a lot.
3560     main::set_access('max', \%max, 'r');
3561
3562     my %each_range_iterator;
3563     # Iterator position for each_range()
3564     main::set_access('each_range_iterator', \%each_range_iterator);
3565
3566     my %owner_name_of;
3567     # Name of parent this is attached to, if any.  Solely for better error
3568     # messages.
3569     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3570
3571     my %_search_ranges_cache;
3572     # A cache of the previous result from _search_ranges(), for better
3573     # performance
3574     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3575
3576     sub new {
3577         my $class = shift;
3578         my %args = @_;
3579
3580         # Optional initialization data for the range list.
3581         my $initialize = delete $args{'Initialize'};
3582
3583         my $self;
3584
3585         # Use _union() to initialize.  _union() returns an object of this
3586         # class, which means that it will call this constructor recursively.
3587         # But it won't have this $initialize parameter so that it won't
3588         # infinitely loop on this.
3589         return _union($class, $initialize, %args) if defined $initialize;
3590
3591         $self = bless \do { my $anonymous_scalar }, $class;
3592         my $addr = do { no overloading; pack 'J', $self; };
3593
3594         # Optional parent object, only for debug info.
3595         $owner_name_of{$addr} = delete $args{'Owner'};
3596         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3597
3598         # Stringify, in case it is an object.
3599         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3600
3601         # This is used only for error messages, and so a colon is added
3602         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3603
3604         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3605
3606         $max{$addr} = $max_init;
3607
3608         $_search_ranges_cache{$addr} = 0;
3609         $ranges{$addr} = [];
3610
3611         return $self;
3612     }
3613
3614     use overload
3615         fallback => 0,
3616         qw("") => "_operator_stringify",
3617         "." => \&main::_operator_dot,
3618         ".=" => \&main::_operator_dot_equal,
3619     ;
3620
3621     sub _operator_stringify {
3622         my $self = shift;
3623         my $addr = do { no overloading; pack 'J', $self; };
3624
3625         return "Range_List attached to '$owner_name_of{$addr}'"
3626                                                 if $owner_name_of{$addr};
3627         return "anonymous Range_List " . \$self;
3628     }
3629
3630     sub _union {
3631         # Returns the union of the input code points.  It can be called as
3632         # either a constructor or a method.  If called as a method, the result
3633         # will be a new() instance of the calling object, containing the union
3634         # of that object with the other parameter's code points;  if called as
3635         # a constructor, the first parameter gives the class that the new object
3636         # should be, and the second parameter gives the code points to go into
3637         # it.
3638         # In either case, there are two parameters looked at by this routine;
3639         # any additional parameters are passed to the new() constructor.
3640         #
3641         # The code points can come in the form of some object that contains
3642         # ranges, and has a conventionally named method to access them; or
3643         # they can be an array of individual code points (as integers); or
3644         # just a single code point.
3645         #
3646         # If they are ranges, this routine doesn't make any effort to preserve
3647         # the range values and types of one input over the other.  Therefore
3648         # this base class should not allow _union to be called from other than
3649         # initialization code, so as to prevent two tables from being added
3650         # together where the range values matter.  The general form of this
3651         # routine therefore belongs in a derived class, but it was moved here
3652         # to avoid duplication of code.  The failure to overload this in this
3653         # class keeps it safe.
3654         #
3655         # It does make the effort during initialization to accept tables with
3656         # multiple values for the same code point, and to preserve the order
3657         # of these.  If there is only one input range or range set, it doesn't
3658         # sort (as it should already be sorted to the desired order), and will
3659         # accept multiple values per code point.  Otherwise it will merge
3660         # multiple values into a single one.
3661
3662         my $self;
3663         my @args;   # Arguments to pass to the constructor
3664
3665         my $class = shift;
3666
3667         # If a method call, will start the union with the object itself, and
3668         # the class of the new object will be the same as self.
3669         if (ref $class) {
3670             $self = $class;
3671             $class = ref $self;
3672             push @args, $self;
3673         }
3674
3675         # Add the other required parameter.
3676         push @args, shift;
3677         # Rest of parameters are passed on to the constructor
3678
3679         # Accumulate all records from both lists.
3680         my @records;
3681         my $input_count = 0;
3682         for my $arg (@args) {
3683             #local $to_trace = 0 if main::DEBUG;
3684             trace "argument = $arg" if main::DEBUG && $to_trace;
3685             if (! defined $arg) {
3686                 my $message = "";
3687                 if (defined $self) {
3688                     no overloading;
3689                     $message .= $owner_name_of{pack 'J', $self};
3690                 }
3691                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3692                 return;
3693             }
3694
3695             $arg = [ $arg ] if ! ref $arg;
3696             my $type = ref $arg;
3697             if ($type eq 'ARRAY') {
3698                 foreach my $element (@$arg) {
3699                     push @records, Range->new($element, $element);
3700                     $input_count++;
3701                 }
3702             }
3703             elsif ($arg->isa('Range')) {
3704                 push @records, $arg;
3705                 $input_count++;
3706             }
3707             elsif ($arg->can('ranges')) {
3708                 push @records, $arg->ranges;
3709                 $input_count++;
3710             }
3711             else {
3712                 my $message = "";
3713                 if (defined $self) {
3714                     no overloading;
3715                     $message .= $owner_name_of{pack 'J', $self};
3716                 }
3717                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3718                 return;
3719             }
3720         }
3721
3722         # Sort with the range containing the lowest ordinal first, but if
3723         # two ranges start at the same code point, sort with the bigger range
3724         # of the two first, because it takes fewer cycles.
3725         if ($input_count > 1) {
3726             @records = sort { ($a->start <=> $b->start)
3727                                       or
3728                                     # if b is shorter than a, b->end will be
3729                                     # less than a->end, and we want to select
3730                                     # a, so want to return -1
3731                                     ($b->end <=> $a->end)
3732                                    } @records;
3733         }
3734
3735         my $new = $class->new(@_);
3736
3737         # Fold in records so long as they add new information.
3738         for my $set (@records) {
3739             my $start = $set->start;
3740             my $end   = $set->end;
3741             my $value = $set->value;
3742             my $type  = $set->type;
3743             if ($start > $new->max) {
3744                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3745             }
3746             elsif ($end > $new->max) {
3747                 $new->_add_delete('+', $new->max +1, $end, $value,
3748                                                                 Type => $type);
3749             }
3750             elsif ($input_count == 1) {
3751                 # Here, overlaps existing range, but is from a single input,
3752                 # so preserve the multiple values from that input.
3753                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3754                                                 Replace => $MULTIPLE_AFTER);
3755             }
3756         }
3757
3758         return $new;
3759     }
3760
3761     sub range_count {        # Return the number of ranges in the range list
3762         my $self = shift;
3763         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3764
3765         no overloading;
3766         return scalar @{$ranges{pack 'J', $self}};
3767     }
3768
3769     sub min {
3770         # Returns the minimum code point currently in the range list, or if
3771         # the range list is empty, 2 beyond the max possible.  This is a
3772         # method because used so rarely, that not worth saving between calls,
3773         # and having to worry about changing it as ranges are added and
3774         # deleted.
3775
3776         my $self = shift;
3777         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3778
3779         my $addr = do { no overloading; pack 'J', $self; };
3780
3781         # If the range list is empty, return a large value that isn't adjacent
3782         # to any that could be in the range list, for simpler tests
3783         return $MAX_WORKING_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3784         return $ranges{$addr}->[0]->start;
3785     }
3786
3787     sub contains {
3788         # Boolean: Is argument in the range list?  If so returns $i such that:
3789         #   range[$i]->end < $codepoint <= range[$i+1]->end
3790         # which is one beyond what you want; this is so that the 0th range
3791         # doesn't return false
3792         my $self = shift;
3793         my $codepoint = shift;
3794         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3795
3796         my $i = $self->_search_ranges($codepoint);
3797         return 0 unless defined $i;
3798
3799         # The search returns $i, such that
3800         #   range[$i-1]->end < $codepoint <= range[$i]->end
3801         # So is in the table if and only iff it is at least the start position
3802         # of range $i.
3803         no overloading;
3804         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3805         return $i + 1;
3806     }
3807
3808     sub containing_range {
3809         # Returns the range object that contains the code point, undef if none
3810
3811         my $self = shift;
3812         my $codepoint = shift;
3813         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3814
3815         my $i = $self->contains($codepoint);
3816         return unless $i;
3817
3818         # contains() returns 1 beyond where we should look
3819         no overloading;
3820         return $ranges{pack 'J', $self}->[$i-1];
3821     }
3822
3823     sub value_of {
3824         # Returns the value associated with the code point, undef if none
3825
3826         my $self = shift;
3827         my $codepoint = shift;
3828         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3829
3830         my $range = $self->containing_range($codepoint);
3831         return unless defined $range;
3832
3833         return $range->value;
3834     }
3835
3836     sub type_of {
3837         # Returns the type of the range containing the code point, undef if
3838         # the code point is not in the table
3839
3840         my $self = shift;
3841         my $codepoint = shift;
3842         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3843
3844         my $range = $self->containing_range($codepoint);
3845         return unless defined $range;
3846
3847         return $range->type;
3848     }
3849
3850     sub _search_ranges {
3851         # Find the range in the list which contains a code point, or where it
3852         # should go if were to add it.  That is, it returns $i, such that:
3853         #   range[$i-1]->end < $codepoint <= range[$i]->end
3854         # Returns undef if no such $i is possible (e.g. at end of table), or
3855         # if there is an error.
3856
3857         my $self = shift;
3858         my $code_point = shift;
3859         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3860
3861         my $addr = do { no overloading; pack 'J', $self; };
3862
3863         return if $code_point > $max{$addr};
3864         my $r = $ranges{$addr};                # The current list of ranges
3865         my $range_list_size = scalar @$r;
3866         my $i;
3867
3868         use integer;        # want integer division
3869
3870         # Use the cached result as the starting guess for this one, because,
3871         # an experiment on 5.1 showed that 90% of the time the cache was the
3872         # same as the result on the next call (and 7% it was one less).
3873         $i = $_search_ranges_cache{$addr};
3874         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3875                                             # from an intervening deletion
3876         #local $to_trace = 1 if main::DEBUG;
3877         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3878         return $i if $code_point <= $r->[$i]->end
3879                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3880
3881         # Here the cache doesn't yield the correct $i.  Try adding 1.
3882         if ($i < $range_list_size - 1
3883             && $r->[$i]->end < $code_point &&
3884             $code_point <= $r->[$i+1]->end)
3885         {
3886             $i++;
3887             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3888             $_search_ranges_cache{$addr} = $i;
3889             return $i;
3890         }
3891
3892         # Here, adding 1 also didn't work.  We do a binary search to
3893         # find the correct position, starting with current $i
3894         my $lower = 0;
3895         my $upper = $range_list_size - 1;
3896         while (1) {
3897             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3898
3899             if ($code_point <= $r->[$i]->end) {
3900
3901                 # Here we have met the upper constraint.  We can quit if we
3902                 # also meet the lower one.
3903                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3904
3905                 $upper = $i;        # Still too high.
3906
3907             }
3908             else {
3909
3910                 # Here, $r[$i]->end < $code_point, so look higher up.
3911                 $lower = $i;
3912             }
3913
3914             # Split search domain in half to try again.
3915             my $temp = ($upper + $lower) / 2;
3916
3917             # No point in continuing unless $i changes for next time
3918             # in the loop.
3919             if ($temp == $i) {
3920
3921                 # We can't reach the highest element because of the averaging.
3922                 # So if one below the upper edge, force it there and try one
3923                 # more time.
3924                 if ($i == $range_list_size - 2) {
3925
3926                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3927                     $i = $range_list_size - 1;
3928
3929                     # Change $lower as well so if fails next time through,
3930                     # taking the average will yield the same $i, and we will
3931                     # quit with the error message just below.
3932                     $lower = $i;
3933                     next;
3934                 }
3935                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3936                 return;
3937             }
3938             $i = $temp;
3939         } # End of while loop
3940
3941         if (main::DEBUG && $to_trace) {
3942             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3943             trace "i=  [ $i ]", $r->[$i];
3944             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3945         }
3946
3947         # Here we have found the offset.  Cache it as a starting point for the
3948         # next call.
3949         $_search_ranges_cache{$addr} = $i;
3950         return $i;
3951     }
3952
3953     sub _add_delete {
3954         # Add, replace or delete ranges to or from a list.  The $type
3955         # parameter gives which:
3956         #   '+' => insert or replace a range, returning a list of any changed
3957         #          ranges.
3958         #   '-' => delete a range, returning a list of any deleted ranges.
3959         #
3960         # The next three parameters give respectively the start, end, and
3961         # value associated with the range.  'value' should be null unless the
3962         # operation is '+';
3963         #
3964         # The range list is kept sorted so that the range with the lowest
3965         # starting position is first in the list, and generally, adjacent
3966         # ranges with the same values are merged into a single larger one (see
3967         # exceptions below).
3968         #
3969         # There are more parameters; all are key => value pairs:
3970         #   Type    gives the type of the value.  It is only valid for '+'.
3971         #           All ranges have types; if this parameter is omitted, 0 is
3972         #           assumed.  Ranges with type 0 are assumed to obey the
3973         #           Unicode rules for casing, etc; ranges with other types are
3974         #           not.  Otherwise, the type is arbitrary, for the caller's
3975         #           convenience, and looked at only by this routine to keep
3976         #           adjacent ranges of different types from being merged into
3977         #           a single larger range, and when Replace =>
3978         #           $IF_NOT_EQUIVALENT is specified (see just below).
3979         #   Replace  determines what to do if the range list already contains
3980         #            ranges which coincide with all or portions of the input
3981         #            range.  It is only valid for '+':
3982         #       => $NO            means that the new value is not to replace
3983         #                         any existing ones, but any empty gaps of the
3984         #                         range list coinciding with the input range
3985         #                         will be filled in with the new value.
3986         #       => $UNCONDITIONALLY  means to replace the existing values with
3987         #                         this one unconditionally.  However, if the
3988         #                         new and old values are identical, the
3989         #                         replacement is skipped to save cycles
3990         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3991         #          (the default)  with this one if they are not equivalent.
3992         #                         Ranges are equivalent if their types are the
3993         #                         same, and they are the same string; or if
3994         #                         both are type 0 ranges, if their Unicode
3995         #                         standard forms are identical.  In this last
3996         #                         case, the routine chooses the more "modern"
3997         #                         one to use.  This is because some of the
3998         #                         older files are formatted with values that
3999         #                         are, for example, ALL CAPs, whereas the
4000         #                         derived files have a more modern style,
4001         #                         which looks better.  By looking for this
4002         #                         style when the pre-existing and replacement
4003         #