This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Take advantage of the fact that we can use indent as a stdin/stdout
[perl5.git] / Porting / expand-macro.pl
1 #!perl -w
2 use strict;
3
4 use Getopt::Std;
5
6 use vars qw($trysource $tryout $sentinel);
7 $trysource = "try.c";
8 $tryout = "try.i";
9
10 getopts('fF:ekvI:', \my %opt) or usage();
11
12 sub usage {
13     die<<EO_HELP;
14 @_;
15 usage: $0 [options] <macro-name> [headers]
16 options:
17     -f          use 'indent' to format output
18     -F  <tool>  use <tool> to format output  (instead of -f)
19     -e          erase try.[ic] instead of failing when theyre present (errdetect)
20     -k          keep them after generating (for handy inspection)
21     -v          verbose
22     -I <indent-opts>    passed into indent
23 EO_HELP
24 }
25
26 my $macro = shift;
27 usage "missing <macro-name>" unless defined $macro;
28
29 $sentinel = "$macro expands to";
30
31 usage "-f and -F <tool> are exclusive\n" if $opt{f} and $opt{F};
32
33 foreach($trysource, $tryout) {
34     unlink $_ if $opt{e};
35     die "You already have a $_" if -e $_;
36 }
37
38 if (!@ARGV) {
39     open my $fh, '<', 'MANIFEST' or die "Can't open MANIFEST: $!";
40     while (<$fh>) {
41         push @ARGV, $1 if m!^([^/]+\.h)\t!;
42     }
43 }
44
45 my $args = '';
46
47 my $found_macro;
48 while (<>) {
49     next unless /^#\s*define\s+$macro\b/;
50     my ($def_args) = /^#\s*define\s+$macro\(([^)]*)\)/;
51     if (defined $def_args) {
52         my @args = split ',', $def_args;
53         print "# macro: $macro args: @args in $_\n" if $opt{v};
54         my $argname = "A0";
55         $args = '(' . join (', ', map {$argname++} 1..@args) . ')';
56     }
57     $found_macro++;
58     last;
59 }
60 die "$macro not found\n" unless $found_macro;
61
62 open my $out, '>', $trysource or die "Can't open $trysource: $!";
63
64 print $out <<"EOF";
65 #include "EXTERN.h"
66 #include "perl.h"
67 #line 3 "$sentinel"
68 $macro$args
69 EOF
70
71 close $out or die "Can't close $trysource: $!";
72
73 print "doing: make $tryout\n" if $opt{v};
74 system "make $tryout" and die;
75
76 # if user wants 'indent' formatting ..
77 my $out_fh;
78
79 if ($opt{f} || $opt{F}) {
80     # a: indent is a well behaved filter when given 0 arguments, reading from
81     #    stdin and writing to stdout
82     # b: all our braces should be balanced, indented back to column 0, in the
83     #    headers, hence everything before our #line directive can be ignored
84     #
85     # We can take advantage of this to reduce the work to indent.
86
87     my $indent_command = $opt{f} ? 'indent' : $opt{F};
88
89     if (defined $opt{I}) {
90         $indent_command .= " $opt{I}";
91     }
92     open $out_fh, '|-', $indent_command or die $?;
93 } else {
94     $out_fh = \*STDOUT;
95 }
96
97 open my $fh, '<', $tryout or die "Can't open $tryout: $!";
98
99 while (<$fh>) {
100     print $out_fh $_ if /$sentinel/o .. 1;
101 }
102
103 unless ($opt{k}) {
104     foreach($trysource, $tryout) {
105         die "Can't unlink $_" unless unlink $_;
106     }
107 }