This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
26efa3fbb2dc68fd82ee12964aeaa047f9133c48
[perl5.git] / pod / perlfaq8.pod
1 =head1 NAME
2
3 perlfaq8 - System Interaction ($Revision: 1.39 $, $Date: 1999/05/23 18:37:57 $)
4
5 =head1 DESCRIPTION
6
7 This section of the Perl FAQ covers questions involving operating
8 system interaction.  This involves interprocess communication (IPC),
9 control over the user-interface (keyboard, screen and pointing
10 devices), and most anything else not related to data manipulation.
11
12 Read the FAQs and documentation specific to the port of perl to your
13 operating system (eg, L<perlvms>, L<perlplan9>, ...).  These should
14 contain more detailed information on the vagaries of your perl.
15
16 =head2 How do I find out which operating system I'm running under?
17
18 The $^O variable ($OSNAME if you use English) contains an indication of
19 the name of the operating system (not its release number) that your perl
20 binary was built for.
21
22 =head2 How come exec() doesn't return?
23
24 Because that's what it does: it replaces your currently running
25 program with a different one.  If you want to keep going (as is
26 probably the case if you're asking this question) use system()
27 instead.
28
29 =head2 How do I do fancy stuff with the keyboard/screen/mouse?
30
31 How you access/control keyboards, screens, and pointing devices
32 ("mice") is system-dependent.  Try the following modules:
33
34 =over 4
35
36 =item Keyboard
37
38     Term::Cap                   Standard perl distribution
39     Term::ReadKey               CPAN
40     Term::ReadLine::Gnu         CPAN
41     Term::ReadLine::Perl        CPAN
42     Term::Screen                CPAN
43
44 =item Screen
45
46     Term::Cap                   Standard perl distribution
47     Curses                      CPAN
48     Term::ANSIColor             CPAN
49
50 =item Mouse
51
52     Tk                          CPAN
53
54 =back
55
56 Some of these specific cases are shown below.
57
58 =head2 How do I print something out in color?
59
60 In general, you don't, because you don't know whether
61 the recipient has a color-aware display device.  If you
62 know that they have an ANSI terminal that understands
63 color, you can use the Term::ANSIColor module from CPAN:
64
65     use Term::ANSIColor;
66     print color("red"), "Stop!\n", color("reset");
67     print color("green"), "Go!\n", color("reset");
68
69 Or like this:
70
71     use Term::ANSIColor qw(:constants);
72     print RED, "Stop!\n", RESET;
73     print GREEN, "Go!\n", RESET;
74
75 =head2 How do I read just one key without waiting for a return key?
76
77 Controlling input buffering is a remarkably system-dependent matter.
78 On many systems, you can just use the B<stty> command as shown in
79 L<perlfunc/getc>, but as you see, that's already getting you into
80 portability snags.  
81
82     open(TTY, "+</dev/tty") or die "no tty: $!";
83     system "stty  cbreak </dev/tty >/dev/tty 2>&1";
84     $key = getc(TTY);           # perhaps this works
85     # OR ELSE
86     sysread(TTY, $key, 1);      # probably this does
87     system "stty -cbreak </dev/tty >/dev/tty 2>&1";
88
89 The Term::ReadKey module from CPAN offers an easy-to-use interface that
90 should be more efficient than shelling out to B<stty> for each key.
91 It even includes limited support for Windows.
92
93     use Term::ReadKey;
94     ReadMode('cbreak');
95     $key = ReadKey(0);
96     ReadMode('normal');
97
98 However, that requires that you have a working C compiler and can use it
99 to build and install a CPAN module.  Here's a solution using
100 the standard POSIX module, which is already on your systems (assuming
101 your system supports POSIX).
102
103     use HotKey;
104     $key = readkey();
105
106 And here's the HotKey module, which hides the somewhat mystifying calls
107 to manipulate the POSIX termios structures.
108
109     # HotKey.pm
110     package HotKey;
111
112     @ISA = qw(Exporter);
113     @EXPORT = qw(cbreak cooked readkey);
114
115     use strict;
116     use POSIX qw(:termios_h);
117     my ($term, $oterm, $echo, $noecho, $fd_stdin);
118
119     $fd_stdin = fileno(STDIN);
120     $term     = POSIX::Termios->new();
121     $term->getattr($fd_stdin);
122     $oterm     = $term->getlflag();
123
124     $echo     = ECHO | ECHOK | ICANON;
125     $noecho   = $oterm & ~$echo;
126
127     sub cbreak {
128         $term->setlflag($noecho);  # ok, so i don't want echo either
129         $term->setcc(VTIME, 1);
130         $term->setattr($fd_stdin, TCSANOW);
131     }
132
133     sub cooked {
134         $term->setlflag($oterm);
135         $term->setcc(VTIME, 0);
136         $term->setattr($fd_stdin, TCSANOW);
137     }
138
139     sub readkey {
140         my $key = '';
141         cbreak();
142         sysread(STDIN, $key, 1);
143         cooked();
144         return $key;
145     }
146
147     END { cooked() }
148
149     1;
150
151 =head2 How do I check whether input is ready on the keyboard?
152
153 The easiest way to do this is to read a key in nonblocking mode with the
154 Term::ReadKey module from CPAN, passing it an argument of -1 to indicate
155 not to block:
156
157     use Term::ReadKey;
158
159     ReadMode('cbreak');
160
161     if (defined ($char = ReadKey(-1)) ) {
162         # input was waiting and it was $char
163     } else {
164         # no input was waiting
165     }
166
167     ReadMode('normal');                  # restore normal tty settings
168
169 =head2 How do I clear the screen?
170
171 If you only have do so infrequently, use C<system>:
172
173     system("clear");
174
175 If you have to do this a lot, save the clear string
176 so you can print it 100 times without calling a program
177 100 times:
178
179     $clear_string = `clear`;
180     print $clear_string;
181
182 If you're planning on doing other screen manipulations, like cursor
183 positions, etc, you might wish to use Term::Cap module:
184
185     use Term::Cap;
186     $terminal = Term::Cap->Tgetent( {OSPEED => 9600} );
187     $clear_string = $terminal->Tputs('cl');
188
189 =head2 How do I get the screen size?
190
191 If you have Term::ReadKey module installed from CPAN, 
192 you can use it to fetch the width and height in characters
193 and in pixels:
194
195     use Term::ReadKey;
196     ($wchar, $hchar, $wpixels, $hpixels) = GetTerminalSize();
197
198 This is more portable than the raw C<ioctl>, but not as 
199 illustrative:
200
201     require 'sys/ioctl.ph';
202     die "no TIOCGWINSZ " unless defined &TIOCGWINSZ;
203     open(TTY, "+</dev/tty")                     or die "No tty: $!";
204     unless (ioctl(TTY, &TIOCGWINSZ, $winsize='')) {
205         die sprintf "$0: ioctl TIOCGWINSZ (%08x: $!)\n", &TIOCGWINSZ;
206     }
207     ($row, $col, $xpixel, $ypixel) = unpack('S4', $winsize);
208     print "(row,col) = ($row,$col)";
209     print "  (xpixel,ypixel) = ($xpixel,$ypixel)" if $xpixel || $ypixel;
210     print "\n";
211
212 =head2 How do I ask the user for a password?
213
214 (This question has nothing to do with the web.  See a different
215 FAQ for that.)
216
217 There's an example of this in L<perlfunc/crypt>).  First, you put
218 the terminal into "no echo" mode, then just read the password
219 normally.  You may do this with an old-style ioctl() function, POSIX
220 terminal control (see L<POSIX>, and Chapter 7 of the Camel), or a call
221 to the B<stty> program, with varying degrees of portability.
222
223 You can also do this for most systems using the Term::ReadKey module
224 from CPAN, which is easier to use and in theory more portable.
225
226     use Term::ReadKey;
227
228     ReadMode('noecho');
229     $password = ReadLine(0);
230
231 =head2 How do I read and write the serial port?
232
233 This depends on which operating system your program is running on.  In
234 the case of Unix, the serial ports will be accessible through files in
235 /dev; on other systems, the devices names will doubtless differ.
236 Several problem areas common to all device interaction are the
237 following
238
239 =over 4
240
241 =item lockfiles
242
243 Your system may use lockfiles to control multiple access.  Make sure
244 you follow the correct protocol.  Unpredictable behaviour can result
245 from multiple processes reading from one device.
246
247 =item open mode
248
249 If you expect to use both read and write operations on the device,
250 you'll have to open it for update (see L<perlfunc/"open"> for
251 details).  You may wish to open it without running the risk of
252 blocking by using sysopen() and C<O_RDWR|O_NDELAY|O_NOCTTY> from the
253 Fcntl module (part of the standard perl distribution).  See
254 L<perlfunc/"sysopen"> for more on this approach.
255
256 =item end of line
257
258 Some devices will be expecting a "\r" at the end of each line rather
259 than a "\n".  In some ports of perl, "\r" and "\n" are different from
260 their usual (Unix) ASCII values of "\012" and "\015".  You may have to
261 give the numeric values you want directly, using octal ("\015"), hex
262 ("0x0D"), or as a control-character specification ("\cM").
263
264     print DEV "atv1\012";       # wrong, for some devices
265     print DEV "atv1\015";       # right, for some devices
266
267 Even though with normal text files, a "\n" will do the trick, there is
268 still no unified scheme for terminating a line that is portable
269 between Unix, DOS/Win, and Macintosh, except to terminate I<ALL> line
270 ends with "\015\012", and strip what you don't need from the output.
271 This applies especially to socket I/O and autoflushing, discussed
272 next.
273
274 =item flushing output
275
276 If you expect characters to get to your device when you print() them,
277 you'll want to autoflush that filehandle.  You can use select()
278 and the C<$|> variable to control autoflushing (see L<perlvar/$|>
279 and L<perlfunc/select>):
280
281     $oldh = select(DEV);
282     $| = 1;
283     select($oldh);
284
285 You'll also see code that does this without a temporary variable, as in
286
287     select((select(DEV), $| = 1)[0]);
288
289 Or if you don't mind pulling in a few thousand lines
290 of code just because you're afraid of a little $| variable:
291
292     use IO::Handle;
293     DEV->autoflush(1);
294
295 As mentioned in the previous item, this still doesn't work when using
296 socket I/O between Unix and Macintosh.  You'll need to hardcode your
297 line terminators, in that case.
298
299 =item non-blocking input
300
301 If you are doing a blocking read() or sysread(), you'll have to
302 arrange for an alarm handler to provide a timeout (see
303 L<perlfunc/alarm>).  If you have a non-blocking open, you'll likely
304 have a non-blocking read, which means you may have to use a 4-arg
305 select() to determine whether I/O is ready on that device (see
306 L<perlfunc/"select">.
307
308 =back
309
310 While trying to read from his caller-id box, the notorious Jamie Zawinski
311 <jwz@netscape.com>, after much gnashing of teeth and fighting with sysread,
312 sysopen, POSIX's tcgetattr business, and various other functions that
313 go bump in the night, finally came up with this:
314
315     sub open_modem {
316         use IPC::Open2;
317         my $stty = `/bin/stty -g`;
318         open2( \*MODEM_IN, \*MODEM_OUT, "cu -l$modem_device -s2400 2>&1");
319         # starting cu hoses /dev/tty's stty settings, even when it has
320         # been opened on a pipe...
321         system("/bin/stty $stty");
322         $_ = <MODEM_IN>;
323         chop;
324         if ( !m/^Connected/ ) {
325             print STDERR "$0: cu printed `$_' instead of `Connected'\n";
326         }
327     }
328
329 =head2 How do I decode encrypted password files?
330
331 You spend lots and lots of money on dedicated hardware, but this is
332 bound to get you talked about.
333
334 Seriously, you can't if they are Unix password files - the Unix
335 password system employs one-way encryption.  It's more like hashing than
336 encryption.  The best you can check is whether something else hashes to
337 the same string.  You can't turn a hash back into the original string.
338 Programs like Crack
339 can forcibly (and intelligently) try to guess passwords, but don't
340 (can't) guarantee quick success.
341
342 If you're worried about users selecting bad passwords, you should
343 proactively check when they try to change their password (by modifying
344 passwd(1), for example).
345
346 =head2 How do I start a process in the background?
347
348 You could use
349
350     system("cmd &")
351
352 or you could use fork as documented in L<perlfunc/"fork">, with
353 further examples in L<perlipc>.  Some things to be aware of, if you're
354 on a Unix-like system:
355
356 =over 4
357
358 =item STDIN, STDOUT, and STDERR are shared
359
360 Both the main process and the backgrounded one (the "child" process)
361 share the same STDIN, STDOUT and STDERR filehandles.  If both try to
362 access them at once, strange things can happen.  You may want to close
363 or reopen these for the child.  You can get around this with
364 C<open>ing a pipe (see L<perlfunc/"open">) but on some systems this
365 means that the child process cannot outlive the parent.
366
367 =item Signals
368
369 You'll have to catch the SIGCHLD signal, and possibly SIGPIPE too.
370 SIGCHLD is sent when the backgrounded process finishes.  SIGPIPE is
371 sent when you write to a filehandle whose child process has closed (an
372 untrapped SIGPIPE can cause your program to silently die).  This is
373 not an issue with C<system("cmd&")>.
374
375 =item Zombies
376
377 You have to be prepared to "reap" the child process when it finishes
378
379     $SIG{CHLD} = sub { wait };
380
381 See L<perlipc/"Signals"> for other examples of code to do this.
382 Zombies are not an issue with C<system("prog &")>.
383
384 =back
385
386 =head2 How do I trap control characters/signals?
387
388 You don't actually "trap" a control character.  Instead, that character
389 generates a signal which is sent to your terminal's currently
390 foregrounded process group, which you then trap in your process.
391 Signals are documented in L<perlipc/"Signals"> and chapter 6 of the Camel.
392
393 Be warned that very few C libraries are re-entrant.  Therefore, if you
394 attempt to print() in a handler that got invoked during another stdio
395 operation your internal structures will likely be in an
396 inconsistent state, and your program will dump core.  You can
397 sometimes avoid this by using syswrite() instead of print().
398
399 Unless you're exceedingly careful, the only safe things to do inside a
400 signal handler are: set a variable and exit.  And in the first case,
401 you should only set a variable in such a way that malloc() is not
402 called (eg, by setting a variable that already has a value).
403
404 For example:
405
406     $Interrupted = 0;   # to ensure it has a value
407     $SIG{INT} = sub {
408         $Interrupted++;
409         syswrite(STDERR, "ouch\n", 5);
410     }
411
412 However, because syscalls restart by default, you'll find that if
413 you're in a "slow" call, such as E<lt>FHE<gt>, read(), connect(), or
414 wait(), that the only way to terminate them is by "longjumping" out;
415 that is, by raising an exception.  See the time-out handler for a
416 blocking flock() in L<perlipc/"Signals"> or chapter 6 of the Camel.
417
418 =head2 How do I modify the shadow password file on a Unix system?
419
420 If perl was installed correctly, and your shadow library was written
421 properly, the getpw*() functions described in L<perlfunc> should in
422 theory provide (read-only) access to entries in the shadow password
423 file.  To change the file, make a new shadow password file (the format
424 varies from system to system - see L<passwd(5)> for specifics) and use
425 pwd_mkdb(8) to install it (see L<pwd_mkdb(8)> for more details).
426
427 =head2 How do I set the time and date?
428
429 Assuming you're running under sufficient permissions, you should be
430 able to set the system-wide date and time by running the date(1)
431 program.  (There is no way to set the time and date on a per-process
432 basis.)  This mechanism will work for Unix, MS-DOS, Windows, and NT;
433 the VMS equivalent is C<set time>.
434
435 However, if all you want to do is change your timezone, you can
436 probably get away with setting an environment variable:
437
438     $ENV{TZ} = "MST7MDT";                  # unixish
439     $ENV{'SYS$TIMEZONE_DIFFERENTIAL'}="-5" # vms
440     system "trn comp.lang.perl.misc";
441
442 =head2 How can I sleep() or alarm() for under a second?
443
444 If you want finer granularity than the 1 second that the sleep()
445 function provides, the easiest way is to use the select() function as
446 documented in L<perlfunc/"select">.  If your system has itimers and
447 syscall() support, you can check out the old example in
448 http://www.perl.com/CPAN/doc/misc/ancient/tutorial/eg/itimers.pl .
449
450 =head2 How can I measure time under a second?
451
452 In general, you may not be able to.  The Time::HiRes module (available
453 from CPAN) provides this functionality for some systems.
454
455 If your system supports both the syscall() function in Perl as well as
456 a system call like gettimeofday(2), then you may be able to do
457 something like this:
458
459     require 'sys/syscall.ph';
460
461     $TIMEVAL_T = "LL";
462
463     $done = $start = pack($TIMEVAL_T, ());
464
465     syscall(&SYS_gettimeofday, $start, 0) != -1
466                or die "gettimeofday: $!";
467
468        ##########################
469        # DO YOUR OPERATION HERE #
470        ##########################
471
472     syscall( &SYS_gettimeofday, $done, 0) != -1
473            or die "gettimeofday: $!";
474
475     @start = unpack($TIMEVAL_T, $start);
476     @done  = unpack($TIMEVAL_T, $done);
477
478     # fix microseconds
479     for ($done[1], $start[1]) { $_ /= 1_000_000 }
480
481     $delta_time = sprintf "%.4f", ($done[0]  + $done[1]  )
482                                             -
483                                  ($start[0] + $start[1] );
484
485 =head2 How can I do an atexit() or setjmp()/longjmp()? (Exception handling)
486
487 Release 5 of Perl added the END block, which can be used to simulate
488 atexit().  Each package's END block is called when the program or
489 thread ends (see L<perlmod> manpage for more details).  
490
491 For example, you can use this to make sure your filter program
492 managed to finish its output without filling up the disk:
493
494     END {
495         close(STDOUT) || die "stdout close failed: $!";
496     } 
497
498 The END block isn't called when untrapped signals kill the program, though, so if
499 you use END blocks you should also use
500
501         use sigtrap qw(die normal-signals);
502
503 Perl's exception-handling mechanism is its eval() operator.  You can
504 use eval() as setjmp and die() as longjmp.  For details of this, see
505 the section on signals, especially the time-out handler for a blocking
506 flock() in L<perlipc/"Signals"> and chapter 6 of the Camel.
507
508 If exception handling is all you're interested in, try the
509 exceptions.pl library (part of the standard perl distribution).
510
511 If you want the atexit() syntax (and an rmexit() as well), try the
512 AtExit module available from CPAN.
513
514 =head2 Why doesn't my sockets program work under System V (Solaris)? What does the error message "Protocol not supported" mean?
515
516 Some Sys-V based systems, notably Solaris 2.X, redefined some of the
517 standard socket constants.  Since these were constant across all
518 architectures, they were often hardwired into perl code.  The proper
519 way to deal with this is to "use Socket" to get the correct values.
520
521 Note that even though SunOS and Solaris are binary compatible, these
522 values are different.  Go figure.
523
524 =head2 How can I call my system's unique C functions from Perl?
525
526 In most cases, you write an external module to do it - see the answer
527 to "Where can I learn about linking C with Perl? [h2xs, xsubpp]".
528 However, if the function is a system call, and your system supports
529 syscall(), you can use the syscall function (documented in
530 L<perlfunc>).
531
532 Remember to check the modules that came with your distribution, and
533 CPAN as well - someone may already have written a module to do it.
534
535 =head2 Where do I get the include files to do ioctl() or syscall()?
536
537 Historically, these would be generated by the h2ph tool, part of the
538 standard perl distribution.  This program converts cpp(1) directives
539 in C header files to files containing subroutine definitions, like
540 &SYS_getitimer, which you can use as arguments to your functions.
541 It doesn't work perfectly, but it usually gets most of the job done.
542 Simple files like F<errno.h>, F<syscall.h>, and F<socket.h> were fine,
543 but the hard ones like F<ioctl.h> nearly always need to hand-edited.
544 Here's how to install the *.ph files:
545
546     1.  become super-user
547     2.  cd /usr/include
548     3.  h2ph *.h */*.h
549
550 If your system supports dynamic loading, for reasons of portability and
551 sanity you probably ought to use h2xs (also part of the standard perl
552 distribution).  This tool converts C header files to Perl extensions.
553 See L<perlxstut> for how to get started with h2xs.
554
555 If your system doesn't support dynamic loading, you still probably
556 ought to use h2xs.  See L<perlxstut> and L<ExtUtils::MakeMaker> for
557 more information (in brief, just use B<make perl> instead of a plain
558 B<make> to rebuild perl with a new static extension).
559
560 =head2 Why do setuid perl scripts complain about kernel problems?
561
562 Some operating systems have bugs in the kernel that make setuid
563 scripts inherently insecure.  Perl gives you a number of options
564 (described in L<perlsec>) to work around such systems.
565
566 =head2 How can I open a pipe both to and from a command?
567
568 The IPC::Open2 module (part of the standard perl distribution) is an
569 easy-to-use approach that internally uses pipe(), fork(), and exec() to do
570 the job.  Make sure you read the deadlock warnings in its documentation,
571 though (see L<IPC::Open2>).  See L<perlipc/"Bidirectional Communication
572 with Another Process"> and L<perlipc/"Bidirectional Communication with
573 Yourself">
574
575 You may also use the IPC::Open3 module (part of the standard perl
576 distribution), but be warned that it has a different order of
577 arguments from IPC::Open2 (see L<IPC::Open3>).
578
579 =head2 Why can't I get the output of a command with system()?
580
581 You're confusing the purpose of system() and backticks (``).  system()
582 runs a command and returns exit status information (as a 16 bit value:
583 the low 7 bits are the signal the process died from, if any, and
584 the high 8 bits are the actual exit value).  Backticks (``) run a
585 command and return what it sent to STDOUT.
586
587     $exit_status   = system("mail-users");
588     $output_string = `ls`;
589
590 =head2 How can I capture STDERR from an external command?
591
592 There are three basic ways of running external commands:
593
594     system $cmd;                # using system()
595     $output = `$cmd`;           # using backticks (``)
596     open (PIPE, "cmd |");       # using open()
597
598 With system(), both STDOUT and STDERR will go the same place as the
599 script's versions of these, unless the command redirects them.
600 Backticks and open() read B<only> the STDOUT of your command.
601
602 With any of these, you can change file descriptors before the call:
603
604     open(STDOUT, ">logfile");
605     system("ls");
606
607 or you can use Bourne shell file-descriptor redirection:
608
609     $output = `$cmd 2>some_file`;
610     open (PIPE, "cmd 2>some_file |");
611
612 You can also use file-descriptor redirection to make STDERR a
613 duplicate of STDOUT:
614
615     $output = `$cmd 2>&1`;
616     open (PIPE, "cmd 2>&1 |");
617
618 Note that you I<cannot> simply open STDERR to be a dup of STDOUT
619 in your Perl program and avoid calling the shell to do the redirection.
620 This doesn't work:
621
622     open(STDERR, ">&STDOUT");
623     $alloutput = `cmd args`;  # stderr still escapes
624
625 This fails because the open() makes STDERR go to where STDOUT was
626 going at the time of the open().  The backticks then make STDOUT go to
627 a string, but don't change STDERR (which still goes to the old
628 STDOUT).
629
630 Note that you I<must> use Bourne shell (sh(1)) redirection syntax in
631 backticks, not csh(1)!  Details on why Perl's system() and backtick
632 and pipe opens all use the Bourne shell are in
633 http://www.perl.com/CPAN/doc/FMTEYEWTK/versus/csh.whynot .
634 To capture a command's STDERR and STDOUT together:
635
636     $output = `cmd 2>&1`;                       # either with backticks
637     $pid = open(PH, "cmd 2>&1 |");              # or with an open pipe
638     while (<PH>) { }                            #    plus a read
639
640 To capture a command's STDOUT but discard its STDERR:
641
642     $output = `cmd 2>/dev/null`;                # either with backticks
643     $pid = open(PH, "cmd 2>/dev/null |");       # or with an open pipe
644     while (<PH>) { }                            #    plus a read
645
646 To capture a command's STDERR but discard its STDOUT:
647
648     $output = `cmd 2>&1 1>/dev/null`;           # either with backticks
649     $pid = open(PH, "cmd 2>&1 1>/dev/null |");  # or with an open pipe
650     while (<PH>) { }                            #    plus a read
651
652 To exchange a command's STDOUT and STDERR in order to capture the STDERR
653 but leave its STDOUT to come out our old STDERR:
654
655     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;        # either with backticks
656     $pid = open(PH, "cmd 3>&1 1>&2 2>&3 3>&-|");# or with an open pipe
657     while (<PH>) { }                            #    plus a read
658
659 To read both a command's STDOUT and its STDERR separately, it's easiest
660 and safest to redirect them separately to files, and then read from those
661 files when the program is done:
662
663     system("program args 1>/tmp/program.stdout 2>/tmp/program.stderr");
664
665 Ordering is important in all these examples.  That's because the shell
666 processes file descriptor redirections in strictly left to right order.
667
668     system("prog args 1>tmpfile 2>&1");
669     system("prog args 2>&1 1>tmpfile");
670
671 The first command sends both standard out and standard error to the
672 temporary file.  The second command sends only the old standard output
673 there, and the old standard error shows up on the old standard out.
674
675 =head2 Why doesn't open() return an error when a pipe open fails?
676
677 Because the pipe open takes place in two steps: first Perl calls
678 fork() to start a new process, then this new process calls exec() to
679 run the program you really wanted to open.  The first step reports
680 success or failure to your process, so open() can only tell you
681 whether the fork() succeeded or not.
682
683 To find out if the exec() step succeeded, you have to catch SIGCHLD
684 and wait() to get the exit status.  You should also catch SIGPIPE if
685 you're writing to the child--you may not have found out the exec()
686 failed by the time you write.  This is documented in L<perlipc>.
687
688 In some cases, even this won't work.  If the second argument to a
689 piped open() contains shell metacharacters, perl fork()s, then exec()s
690 a shell to decode the metacharacters and eventually run the desired
691 program.  Now when you call wait(), you only learn whether or not the
692 I<shell> could be successfully started.  Best to avoid shell
693 metacharacters.
694
695 On systems that follow the spawn() paradigm, open() I<might> do what
696 you expect--unless perl uses a shell to start your command. In this
697 case the fork()/exec() description still applies.
698
699 =head2 What's wrong with using backticks in a void context?
700
701 Strictly speaking, nothing.  Stylistically speaking, it's not a good
702 way to write maintainable code because backticks have a (potentially
703 humongous) return value, and you're ignoring it.  It's may also not be very
704 efficient, because you have to read in all the lines of output, allocate
705 memory for them, and then throw it away.  Too often people are lulled
706 to writing:
707
708     `cp file file.bak`;
709
710 And now they think "Hey, I'll just always use backticks to run programs."
711 Bad idea: backticks are for capturing a program's output; the system()
712 function is for running programs.
713
714 Consider this line:
715
716     `cat /etc/termcap`;
717
718 You haven't assigned the output anywhere, so it just wastes memory
719 (for a little while).  Plus you forgot to check C<$?> to see whether
720 the program even ran correctly.  Even if you wrote
721
722     print `cat /etc/termcap`;
723
724 In most cases, this could and probably should be written as
725
726     system("cat /etc/termcap") == 0
727         or die "cat program failed!";
728
729 Which will get the output quickly (as it is generated, instead of only
730 at the end) and also check the return value.
731
732 system() also provides direct control over whether shell wildcard
733 processing may take place, whereas backticks do not.
734
735 =head2 How can I call backticks without shell processing?
736
737 This is a bit tricky.  Instead of writing
738
739     @ok = `grep @opts '$search_string' @filenames`;
740
741 You have to do this:
742
743     my @ok = ();
744     if (open(GREP, "-|")) {
745         while (<GREP>) {
746             chomp;
747             push(@ok, $_);
748         }
749         close GREP;
750     } else {
751         exec 'grep', @opts, $search_string, @filenames;
752     }
753
754 Just as with system(), no shell escapes happen when you exec() a list.
755 Further examples of this can be found in L<perlipc/"Safe Pipe Opens">.
756
757 Note that if you're stuck on Microsoft, no solution to this vexing issue
758 is even possible.  Even if Perl were to emulate fork(), you'd still
759 be hosed, because Microsoft gives no argc/argv-style API.  Their API
760 always reparses from a single string, which is fundamentally wrong,
761 but you're not likely to get the Gods of Redmond to acknowledge this
762 and fix it for you.
763
764 =head2 Why can't my script read from STDIN after I gave it EOF (^D on Unix, ^Z on MS-DOS)?
765
766 Because some stdio's set error and eof flags that need clearing.  The
767 POSIX module defines clearerr() that you can use.  That is the
768 technically correct way to do it.  Here are some less reliable
769 workarounds:
770
771 =over 4
772
773 =item 1
774
775 Try keeping around the seekpointer and go there, like this:
776
777     $where = tell(LOG);
778     seek(LOG, $where, 0);
779
780 =item 2
781
782 If that doesn't work, try seeking to a different part of the file and
783 then back.
784
785 =item 3
786
787 If that doesn't work, try seeking to a different part of
788 the file, reading something, and then seeking back.
789
790 =item 4
791
792 If that doesn't work, give up on your stdio package and use sysread.
793
794 =back
795
796 =head2 How can I convert my shell script to perl?
797
798 Learn Perl and rewrite it.  Seriously, there's no simple converter.
799 Things that are awkward to do in the shell are easy to do in Perl, and
800 this very awkwardness is what would make a shell->perl converter
801 nigh-on impossible to write.  By rewriting it, you'll think about what
802 you're really trying to do, and hopefully will escape the shell's
803 pipeline datastream paradigm, which while convenient for some matters,
804 causes many inefficiencies.
805
806 =head2 Can I use perl to run a telnet or ftp session?
807
808 Try the Net::FTP, TCP::Client, and Net::Telnet modules (available from
809 CPAN).  http://www.perl.com/CPAN/scripts/netstuff/telnet.emul.shar
810 will also help for emulating the telnet protocol, but Net::Telnet is
811 quite probably easier to use..
812
813 If all you want to do is pretend to be telnet but don't need
814 the initial telnet handshaking, then the standard dual-process
815 approach will suffice:
816
817     use IO::Socket;             # new in 5.004
818     $handle = IO::Socket::INET->new('www.perl.com:80')
819             || die "can't connect to port 80 on www.perl.com: $!";
820     $handle->autoflush(1);
821     if (fork()) {               # XXX: undef means failure
822         select($handle);
823         print while <STDIN>;    # everything from stdin to socket
824     } else {
825         print while <$handle>;  # everything from socket to stdout
826     }
827     close $handle;
828     exit;
829
830 =head2 How can I write expect in Perl?
831
832 Once upon a time, there was a library called chat2.pl (part of the
833 standard perl distribution), which never really got finished.  If you
834 find it somewhere, I<don't use it>.  These days, your best bet is to
835 look at the Expect module available from CPAN, which also requires two
836 other modules from CPAN, IO::Pty and IO::Stty.
837
838 =head2 Is there a way to hide perl's command line from programs such as "ps"?
839
840 First of all note that if you're doing this for security reasons (to
841 avoid people seeing passwords, for example) then you should rewrite
842 your program so that critical information is never given as an
843 argument.  Hiding the arguments won't make your program completely
844 secure.
845
846 To actually alter the visible command line, you can assign to the
847 variable $0 as documented in L<perlvar>.  This won't work on all
848 operating systems, though.  Daemon programs like sendmail place their
849 state there, as in:
850
851     $0 = "orcus [accepting connections]";
852
853 =head2 I {changed directory, modified my environment} in a perl script.  How come the change disappeared when I exited the script?  How do I get my changes to be visible?
854
855 =over 4
856
857 =item Unix
858
859 In the strictest sense, it can't be done -- the script executes as a
860 different process from the shell it was started from.  Changes to a
861 process are not reflected in its parent, only in its own children
862 created after the change.  There is shell magic that may allow you to
863 fake it by eval()ing the script's output in your shell; check out the
864 comp.unix.questions FAQ for details.  
865
866 =back
867
868 =head2 How do I close a process's filehandle without waiting for it to complete?
869
870 Assuming your system supports such things, just send an appropriate signal
871 to the process (see L<perlfunc/"kill">.  It's common to first send a TERM
872 signal, wait a little bit, and then send a KILL signal to finish it off.
873
874 =head2 How do I fork a daemon process?
875
876 If by daemon process you mean one that's detached (disassociated from
877 its tty), then the following process is reported to work on most
878 Unixish systems.  Non-Unix users should check their Your_OS::Process
879 module for other solutions.
880
881 =over 4
882
883 =item *
884
885 Open /dev/tty and use the TIOCNOTTY ioctl on it.  See L<tty(4)>
886 for details.  Or better yet, you can just use the POSIX::setsid()
887 function, so you don't have to worry about process groups.
888
889 =item *
890
891 Change directory to /
892
893 =item *
894
895 Reopen STDIN, STDOUT, and STDERR so they're not connected to the old
896 tty.
897
898 =item *
899
900 Background yourself like this:
901
902     fork && exit;
903
904 =back
905
906 The Proc::Daemon module, available from CPAN, provides a function to
907 perform these actions for you.
908
909 =head2 How do I make my program run with sh and csh?
910
911 See the F<eg/nih> script (part of the perl source distribution).
912
913 =head2 How do I find out if I'm running interactively or not?
914
915 Good question.  Sometimes C<-t STDIN> and C<-t STDOUT> can give clues,
916 sometimes not.
917
918     if (-t STDIN && -t STDOUT) {
919         print "Now what? ";
920     }
921
922 On POSIX systems, you can test whether your own process group matches
923 the current process group of your controlling terminal as follows:
924
925     use POSIX qw/getpgrp tcgetpgrp/;
926     open(TTY, "/dev/tty") or die $!;
927     $tpgrp = tcgetpgrp(fileno(*TTY));
928     $pgrp = getpgrp();
929     if ($tpgrp == $pgrp) {
930         print "foreground\n";
931     } else {
932         print "background\n";
933     }
934
935 =head2 How do I timeout a slow event?
936
937 Use the alarm() function, probably in conjunction with a signal
938 handler, as documented L<perlipc/"Signals"> and chapter 6 of the
939 Camel.  You may instead use the more flexible Sys::AlarmCall module
940 available from CPAN.
941
942 =head2 How do I set CPU limits?
943
944 Use the BSD::Resource module from CPAN.
945
946 =head2 How do I avoid zombies on a Unix system?
947
948 Use the reaper code from L<perlipc/"Signals"> to call wait() when a
949 SIGCHLD is received, or else use the double-fork technique described
950 in L<perlfunc/fork>.
951
952 =head2 How do I use an SQL database?
953
954 There are a number of excellent interfaces to SQL databases.  See the
955 DBD::* modules available from
956 http://www.perl.com/CPAN/modules/dbperl/DBD .
957 A lot of information on this can be found at 
958 http://www.hermetica.com/technologia/perl/DBI/index.html .
959
960 =head2 How do I make a system() exit on control-C?
961
962 You can't.  You need to imitate the system() call (see L<perlipc> for
963 sample code) and then have a signal handler for the INT signal that
964 passes the signal on to the subprocess.  Or you can check for it:
965
966     $rc = system($cmd);
967     if ($rc & 127) { die "signal death" } 
968
969 =head2 How do I open a file without blocking?
970
971 If you're lucky enough to be using a system that supports
972 non-blocking reads (most Unixish systems do), you need only to use the
973 O_NDELAY or O_NONBLOCK flag from the Fcntl module in conjunction with
974 sysopen():
975
976     use Fcntl;
977     sysopen(FH, "/tmp/somefile", O_WRONLY|O_NDELAY|O_CREAT, 0644)
978         or die "can't open /tmp/somefile: $!":
979
980    
981
982
983 =head2 How do I install a module from CPAN?
984
985 The easiest way is to have a module also named CPAN do it for you.
986 This module comes with perl version 5.004 and later.  To manually install
987 the CPAN module, or any well-behaved CPAN module for that matter, follow
988 these steps:
989
990 =over 4
991
992 =item 1
993
994 Unpack the source into a temporary area.
995
996 =item 2
997
998     perl Makefile.PL
999
1000 =item 3
1001
1002     make
1003
1004 =item 4
1005
1006     make test
1007
1008 =item 5
1009
1010     make install
1011
1012 =back
1013
1014 If your version of perl is compiled without dynamic loading, then you
1015 just need to replace step 3 (B<make>) with B<make perl> and you will
1016 get a new F<perl> binary with your extension linked in.
1017
1018 See L<ExtUtils::MakeMaker> for more details on building extensions.
1019 See also the next question.
1020
1021 =head2 What's the difference between require and use?
1022
1023 Perl offers several different ways to include code from one file into
1024 another.  Here are the deltas between the various inclusion constructs:
1025
1026     1)  do $file is like eval `cat $file`, except the former:
1027         1.1: searches @INC and updates %INC.
1028         1.2: bequeaths an *unrelated* lexical scope on the eval'ed code.
1029
1030     2)  require $file is like do $file, except the former:
1031         2.1: checks for redundant loading, skipping already loaded files.
1032         2.2: raises an exception on failure to find, compile, or execute $file.
1033
1034     3)  require Module is like require "Module.pm", except the former:
1035         3.1: translates each "::" into your system's directory separator.
1036         3.2: primes the parser to disambiguate class Module as an indirect object.
1037
1038     4)  use Module is like require Module, except the former:
1039         4.1: loads the module at compile time, not run-time.
1040         4.2: imports symbols and semantics from that package to the current one.
1041
1042 In general, you usually want C<use> and a proper Perl module.
1043
1044 =head2 How do I keep my own module/library directory?
1045
1046 When you build modules, use the PREFIX option when generating
1047 Makefiles:
1048
1049     perl Makefile.PL PREFIX=/u/mydir/perl
1050
1051 then either set the PERL5LIB environment variable before you run
1052 scripts that use the modules/libraries (see L<perlrun>) or say
1053
1054     use lib '/u/mydir/perl';
1055
1056 This is almost the same as:
1057
1058     BEGIN {
1059         unshift(@INC, '/u/mydir/perl');
1060     }
1061
1062 except that the lib module checks for machine-dependent subdirectories.
1063 See Perl's L<lib> for more information.
1064
1065 =head2 How do I add the directory my program lives in to the module/library search path?
1066
1067     use FindBin;
1068     use lib "$FindBin::Bin";
1069     use your_own_modules;
1070
1071 =head2 How do I add a directory to my include path at runtime?
1072
1073 Here are the suggested ways of modifying your include path:
1074
1075     the PERLLIB environment variable
1076     the PERL5LIB environment variable
1077     the perl -Idir command line flag
1078     the use lib pragma, as in
1079         use lib "$ENV{HOME}/myown_perllib";
1080
1081 The latter is particularly useful because it knows about machine
1082 dependent architectures.  The lib.pm pragmatic module was first
1083 included with the 5.002 release of Perl.
1084
1085 =head2 What is socket.ph and where do I get it?
1086
1087 It's a perl4-style file defining values for system networking
1088 constants.  Sometimes it is built using h2ph when Perl is installed,
1089 but other times it is not.  Modern programs C<use Socket;> instead.
1090
1091 =head1 AUTHOR AND COPYRIGHT
1092
1093 Copyright (c) 1997-1999 Tom Christiansen and Nathan Torkington.
1094 All rights reserved.
1095
1096 When included as part of the Standard Version of Perl, or as part of
1097 its complete documentation whether printed or otherwise, this work
1098 may be distributed only under the terms of Perl's Artistic License.
1099 Any distribution of this file or derivatives thereof I<outside>
1100 of that package require that special arrangements be made with
1101 copyright holder.
1102
1103 Irrespective of its distribution, all code examples in this file
1104 are hereby placed into the public domain.  You are permitted and
1105 encouraged to use this code in your own programs for fun
1106 or for profit as you see fit.  A simple comment in the code giving
1107 credit would be courteous but is not required.