This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
A pod nit.
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2
3 perlre - Perl regular expressions
4
5 =head1 DESCRIPTION
6
7 This page describes the syntax of regular expressions in Perl.  For a
8 description of how to I<use> regular expressions in matching
9 operations, plus various examples of the same, see discussions
10 of C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like Operators">.
11
12 Matching operations can have various modifiers.  Modifiers
13 that relate to the interpretation of the regular expression inside
14 are listed below.  Modifiers that alter the way a regular expression
15 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and 
16 L<perlop/"Gory details of parsing quoted constructs">.
17
18 =over 4
19
20 =item i
21
22 Do case-insensitive pattern matching.
23
24 If C<use locale> is in effect, the case map is taken from the current
25 locale.  See L<perllocale>.
26
27 =item m
28
29 Treat string as multiple lines.  That is, change "^" and "$" from matching
30 the start or end of the string to matching the start or end of any
31 line anywhere within the string.
32
33 =item s
34
35 Treat string as single line.  That is, change "." to match any character
36 whatsoever, even a newline, which normally it would not match.
37
38 The C</s> and C</m> modifiers both override the C<$*> setting.  That
39 is, no matter what C<$*> contains, C</s> without C</m> will force
40 "^" to match only at the beginning of the string and "$" to match
41 only at the end (or just before a newline at the end) of the string.
42 Together, as /ms, they let the "." match any character whatsoever,
43 while yet allowing "^" and "$" to match, respectively, just after
44 and just before newlines within the string.
45
46 =item x
47
48 Extend your pattern's legibility by permitting whitespace and comments.
49
50 =back
51
52 These are usually written as "the C</x> modifier", even though the delimiter
53 in question might not really be a slash.  Any of these
54 modifiers may also be embedded within the regular expression itself using
55 the C<(?...)> construct.  See below.
56
57 The C</x> modifier itself needs a little more explanation.  It tells
58 the regular expression parser to ignore whitespace that is neither
59 backslashed nor within a character class.  You can use this to break up
60 your regular expression into (slightly) more readable parts.  The C<#>
61 character is also treated as a metacharacter introducing a comment,
62 just as in ordinary Perl code.  This also means that if you want real
63 whitespace or C<#> characters in the pattern (outside a character
64 class, where they are unaffected by C</x>), that you'll either have to 
65 escape them or encode them using octal or hex escapes.  Taken together,
66 these features go a long way towards making Perl's regular expressions
67 more readable.  Note that you have to be careful not to include the
68 pattern delimiter in the comment--perl has no way of knowing you did
69 not intend to close the pattern early.  See the C-comment deletion code
70 in L<perlop>.
71
72 =head2 Regular Expressions
73
74 The patterns used in Perl pattern matching derive from supplied in
75 the Version 8 regex routines.  (The routines are derived
76 (distantly) from Henry Spencer's freely redistributable reimplementation
77 of the V8 routines.)  See L<Version 8 Regular Expressions> for
78 details.
79
80 In particular the following metacharacters have their standard I<egrep>-ish
81 meanings:
82
83     \   Quote the next metacharacter
84     ^   Match the beginning of the line
85     .   Match any character (except newline)
86     $   Match the end of the line (or before newline at the end)
87     |   Alternation
88     ()  Grouping
89     []  Character class
90
91 By default, the "^" character is guaranteed to match only the
92 beginning of the string, the "$" character only the end (or before the
93 newline at the end), and Perl does certain optimizations with the
94 assumption that the string contains only one line.  Embedded newlines
95 will not be matched by "^" or "$".  You may, however, wish to treat a
96 string as a multi-line buffer, such that the "^" will match after any
97 newline within the string, and "$" will match before any newline.  At the
98 cost of a little more overhead, you can do this by using the /m modifier
99 on the pattern match operator.  (Older programs did this by setting C<$*>,
100 but this practice is now deprecated.)
101
102 To simplify multi-line substitutions, the "." character never matches a
103 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
104 the string is a single line--even if it isn't.  The C</s> modifier also
105 overrides the setting of C<$*>, in case you have some (badly behaved) older
106 code that sets it in another module.
107
108 The following standard quantifiers are recognized:
109
110     *      Match 0 or more times
111     +      Match 1 or more times
112     ?      Match 1 or 0 times
113     {n}    Match exactly n times
114     {n,}   Match at least n times
115     {n,m}  Match at least n but not more than m times
116
117 (If a curly bracket occurs in any other context, it is treated
118 as a regular character.)  The "*" modifier is equivalent to C<{0,}>, the "+"
119 modifier to C<{1,}>, and the "?" modifier to C<{0,1}>.  n and m are limited
120 to integral values less than a preset limit defined when perl is built.
121 This is usually 32766 on the most common platforms.  The actual limit can
122 be seen in the error message generated by code such as this:
123
124     $_ **= $_ , / {$_} / for 2 .. 42;
125
126 By default, a quantified subpattern is "greedy", that is, it will match as
127 many times as possible (given a particular starting location) while still
128 allowing the rest of the pattern to match.  If you want it to match the
129 minimum number of times possible, follow the quantifier with a "?".  Note
130 that the meanings don't change, just the "greediness":
131
132     *?     Match 0 or more times
133     +?     Match 1 or more times
134     ??     Match 0 or 1 time
135     {n}?   Match exactly n times
136     {n,}?  Match at least n times
137     {n,m}? Match at least n but not more than m times
138
139 Because patterns are processed as double quoted strings, the following
140 also work:
141
142     \t          tab                   (HT, TAB)
143     \n          newline               (LF, NL)
144     \r          return                (CR)
145     \f          form feed             (FF)
146     \a          alarm (bell)          (BEL)
147     \e          escape (think troff)  (ESC)
148     \033        octal char (think of a PDP-11)
149     \x1B        hex char
150     \x{263a}    wide hex char         (Unicode SMILEY)
151     \c[         control char
152     \N{name}    named char
153     \l          lowercase next char (think vi)
154     \u          uppercase next char (think vi)
155     \L          lowercase till \E (think vi)
156     \U          uppercase till \E (think vi)
157     \E          end case modification (think vi)
158     \Q          quote (disable) pattern metacharacters till \E
159
160 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
161 and C<\U> is taken from the current locale.  See L<perllocale>.  For
162 documentation of C<\N{name}>, see L<charnames>.
163
164 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
165 An unescaped C<$> or C<@> interpolates the corresponding variable,
166 while escaping will cause the literal string C<\$> to be matched.
167 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
168
169 In addition, Perl defines the following:
170
171     \w  Match a "word" character (alphanumeric plus "_")
172     \W  Match a non-"word" character
173     \s  Match a whitespace character
174     \S  Match a non-whitespace character
175     \d  Match a digit character
176     \D  Match a non-digit character
177     \pP Match P, named property.  Use \p{Prop} for longer names.
178     \PP Match non-P
179     \X  Match eXtended Unicode "combining character sequence",
180         equivalent to C<(?:\PM\pM*)>
181     \C  Match a single C char (octet) even under utf8.
182
183 A C<\w> matches a single alphanumeric character or C<_>, not a whole word.
184 Use C<\w+> to match a string of Perl-identifier characters (which isn't 
185 the same as matching an English word).  If C<use locale> is in effect, the
186 list of alphabetic characters generated by C<\w> is taken from the
187 current locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
188 C<\d>, and C<\D> within character classes, but if you try to use them
189 as endpoints of a range, that's not a range, the "-" is understood literally.
190 See L<utf8> for details about C<\pP>, C<\PP>, and C<\X>.
191
192 The POSIX character class syntax
193
194     [:class:]
195
196 is also available.  The available classes and their backslash
197 equivalents (if available) are as follows:
198
199     alpha
200     alnum
201     ascii
202     blank               [1]
203     cntrl
204     digit       \d
205     graph
206     lower
207     print
208     punct
209     space       \s      [2]
210     upper
211     word        \w      [3]
212     xdigit
213
214   [1] A GNU extension equivalent to C<[ \t]>, `all horizontal whitespace'.
215   [2] Not I<exactly equivalent> to C<\s> since the C<[[:space:]]> includes
216       also the (very rare) `vertical tabulator', "\ck", chr(11).
217   [3] A Perl extension. 
218
219 For example use C<[:upper:]> to match all the uppercase characters.
220 Note that the C<[]> are part of the C<[::]> construct, not part of the
221 whole character class.  For example:
222
223     [01[:alpha:]%]
224
225 matches zero, one, any alphabetic character, and the percentage sign.
226
227 If the C<utf8> pragma is used, the following equivalences to Unicode
228 \p{} constructs hold:
229
230     alpha       IsAlpha
231     alnum       IsAlnum
232     ascii       IsASCII
233     blank       IsSpace
234     cntrl       IsCntrl
235     digit       IsDigit
236     graph       IsGraph
237     lower       IsLower
238     print       IsPrint
239     punct       IsPunct
240     space       IsSpace
241     upper       IsUpper
242     word        IsWord
243     xdigit      IsXDigit
244
245 For example C<[:lower:]> and C<\p{IsLower}> are equivalent.
246
247 If the C<utf8> pragma is not used but the C<locale> pragma is, the
248 classes correlate with the usual isalpha(3) interface (except for
249 `word' and `blank').
250
251 The assumedly non-obviously named classes are:
252
253 =over 4
254
255 =item cntrl
256
257 Any control character.  Usually characters that don't produce output as
258 such but instead control the terminal somehow: for example newline and
259 backspace are control characters.  All characters with ord() less than
260 32 are most often classified as control characters (assuming ASCII,
261 the ISO Latin character sets, and Unicode).
262
263 =item graph
264
265 Any alphanumeric or punctuation (special) character.
266
267 =item print
268
269 Any alphanumeric or punctuation (special) character or space.
270
271 =item punct
272
273 Any punctuation (special) character.
274
275 =item xdigit
276
277 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
278 work just fine) it is included for completeness.
279
280 =back
281
282 You can negate the [::] character classes by prefixing the class name
283 with a '^'. This is a Perl extension.  For example:
284
285     POSIX       trad. Perl  utf8 Perl
286
287     [:^digit:]      \D      \P{IsDigit}
288     [:^space:]      \S      \P{IsSpace}
289     [:^word:]       \W      \P{IsWord}
290
291 The POSIX character classes [.cc.] and [=cc=] are recognized but
292 B<not> supported and trying to use them will cause an error.
293
294 Perl defines the following zero-width assertions:
295
296     \b  Match a word boundary
297     \B  Match a non-(word boundary)
298     \A  Match only at beginning of string
299     \Z  Match only at end of string, or before newline at the end
300     \z  Match only at end of string
301     \G  Match only at pos() (e.g. at the end-of-match position
302         of prior m//g)
303
304 A word boundary (C<\b>) is a spot between two characters
305 that has a C<\w> on one side of it and a C<\W> on the other side
306 of it (in either order), counting the imaginary characters off the
307 beginning and end of the string as matching a C<\W>.  (Within
308 character classes C<\b> represents backspace rather than a word
309 boundary, just as it normally does in any double-quoted string.)
310 The C<\A> and C<\Z> are just like "^" and "$", except that they
311 won't match multiple times when the C</m> modifier is used, while
312 "^" and "$" will match at every internal line boundary.  To match
313 the actual end of the string and not ignore an optional trailing
314 newline, use C<\z>.
315
316 The C<\G> assertion can be used to chain global matches (using
317 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
318 It is also useful when writing C<lex>-like scanners, when you have
319 several patterns that you want to match against consequent substrings
320 of your string, see the previous reference.  The actual location
321 where C<\G> will match can also be influenced by using C<pos()> as
322 an lvalue.  See L<perlfunc/pos>.
323
324 The bracketing construct C<( ... )> creates capture buffers.  To
325 refer to the digit'th buffer use \<digit> within the
326 match.  Outside the match use "$" instead of "\".  (The
327 \<digit> notation works in certain circumstances outside 
328 the match.  See the warning below about \1 vs $1 for details.)
329 Referring back to another part of the match is called a
330 I<backreference>.
331
332 There is no limit to the number of captured substrings that you may
333 use.  However Perl also uses \10, \11, etc. as aliases for \010,
334 \011, etc.  (Recall that 0 means octal, so \011 is the 9'th ASCII
335 character, a tab.)  Perl resolves this ambiguity by interpreting
336 \10 as a backreference only if at least 10 left parentheses have
337 opened before it.  Likewise \11 is a backreference only if at least
338 11 left parentheses have opened before it.  And so on.  \1 through
339 \9 are always interpreted as backreferences."
340
341 Examples:
342
343     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
344
345      if (/(.)\1/) {                 # find first doubled char
346          print "'$1' is the first doubled character\n";
347      }
348
349     if (/Time: (..):(..):(..)/) {   # parse out values
350         $hours = $1;
351         $minutes = $2;
352         $seconds = $3;
353     }
354
355 Several special variables also refer back to portions of the previous
356 match.  C<$+> returns whatever the last bracket match matched.
357 C<$&> returns the entire matched string.  (At one point C<$0> did
358 also, but now it returns the name of the program.)  C<$`> returns
359 everything before the matched string.  And C<$'> returns everything
360 after the matched string.
361
362 The numbered variables ($1, $2, $3, etc.) and the related punctuation
363 set (C<$+>, C<$&>, C<$`>, and C<$'>) are all dynamically scoped
364 until the end of the enclosing block or until the next successful
365 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
366
367 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
368 C<$'> anywhere in the program, it has to provide them for every
369 pattern match.  This may substantially slow your program.  Perl
370 uses the same mechanism to produce $1, $2, etc, so you also pay a
371 price for each pattern that contains capturing parentheses.  (To
372 avoid this cost while retaining the grouping behaviour, use the
373 extended regular expression C<(?: ... )> instead.)  But if you never
374 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
375 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
376 if you can, but if you can't (and some algorithms really appreciate
377 them), once you've used them once, use them at will, because you've
378 already paid the price.  As of 5.005, C<$&> is not so costly as the
379 other two.
380
381 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
382 C<\w>, C<\n>.  Unlike some other regular expression languages, there
383 are no backslashed symbols that aren't alphanumeric.  So anything
384 that looks like \\, \(, \), \<, \>, \{, or \} is always
385 interpreted as a literal character, not a metacharacter.  This was
386 once used in a common idiom to disable or quote the special meanings
387 of regular expression metacharacters in a string that you want to
388 use for a pattern. Simply quote all non-"word" characters:
389
390     $pattern =~ s/(\W)/\\$1/g;
391
392 (If C<use locale> is set, then this depends on the current locale.)
393 Today it is more common to use the quotemeta() function or the C<\Q>
394 metaquoting escape sequence to disable all metacharacters' special
395 meanings like this:
396
397     /$unquoted\Q$quoted\E$unquoted/
398
399 Beware that if you put literal backslashes (those not inside
400 interpolated variables) between C<\Q> and C<\E>, double-quotish
401 backslash interpolation may lead to confusing results.  If you
402 I<need> to use literal backslashes within C<\Q...\E>,
403 consult L<perlop/"Gory details of parsing quoted constructs">.
404
405 =head2 Extended Patterns
406
407 Perl also defines a consistent extension syntax for features not
408 found in standard tools like B<awk> and B<lex>.  The syntax is a
409 pair of parentheses with a question mark as the first thing within
410 the parentheses.  The character after the question mark indicates
411 the extension.
412
413 The stability of these extensions varies widely.  Some have been
414 part of the core language for many years.  Others are experimental
415 and may change without warning or be completely removed.  Check
416 the documentation on an individual feature to verify its current
417 status.
418
419 A question mark was chosen for this and for the minimal-matching
420 construct because 1) question marks are rare in older regular
421 expressions, and 2) whenever you see one, you should stop and
422 "question" exactly what is going on.  That's psychology...
423
424 =over 10
425
426 =item C<(?#text)>
427
428 A comment.  The text is ignored.  If the C</x> modifier enables
429 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
430 the comment as soon as it sees a C<)>, so there is no way to put a literal
431 C<)> in the comment.
432
433 =item C<(?imsx-imsx)>
434
435 One or more embedded pattern-match modifiers.  This is particularly
436 useful for dynamic patterns, such as those read in from a configuration
437 file, read in as an argument, are specified in a table somewhere,
438 etc.  Consider the case that some of which want to be case sensitive
439 and some do not.  The case insensitive ones need to include merely
440 C<(?i)> at the front of the pattern.  For example:
441
442     $pattern = "foobar";
443     if ( /$pattern/i ) { } 
444
445     # more flexible:
446
447     $pattern = "(?i)foobar";
448     if ( /$pattern/ ) { } 
449
450 Letters after a C<-> turn those modifiers off.  These modifiers are
451 localized inside an enclosing group (if any).  For example,
452
453     ( (?i) blah ) \s+ \1
454
455 will match a repeated (I<including the case>!) word C<blah> in any
456 case, assuming C<x> modifier, and no C<i> modifier outside this
457 group.
458
459 =item C<(?:pattern)>
460
461 =item C<(?imsx-imsx:pattern)>
462
463 This is for clustering, not capturing; it groups subexpressions like
464 "()", but doesn't make backreferences as "()" does.  So
465
466     @fields = split(/\b(?:a|b|c)\b/)
467
468 is like
469
470     @fields = split(/\b(a|b|c)\b/)
471
472 but doesn't spit out extra fields.  It's also cheaper not to capture
473 characters if you don't need to.
474
475 Any letters between C<?> and C<:> act as flags modifiers as with
476 C<(?imsx-imsx)>.  For example, 
477
478     /(?s-i:more.*than).*million/i
479
480 is equivalent to the more verbose
481
482     /(?:(?s-i)more.*than).*million/i
483
484 =item C<(?=pattern)>
485
486 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
487 matches a word followed by a tab, without including the tab in C<$&>.
488
489 =item C<(?!pattern)>
490
491 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
492 matches any occurrence of "foo" that isn't followed by "bar".  Note
493 however that look-ahead and look-behind are NOT the same thing.  You cannot
494 use this for look-behind.
495
496 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
497 will not do what you want.  That's because the C<(?!foo)> is just saying that
498 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
499 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
500 say "like" because there's the case of your "bar" not having three characters
501 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
502 Sometimes it's still easier just to say:
503
504     if (/bar/ && $` !~ /foo$/)
505
506 For look-behind see below.
507
508 =item C<(?<=pattern)>
509
510 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
511 matches a word that follows a tab, without including the tab in C<$&>.
512 Works only for fixed-width look-behind.
513
514 =item C<(?<!pattern)>
515
516 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
517 matches any occurrence of "foo" that does not follow "bar".  Works
518 only for fixed-width look-behind.
519
520 =item C<(?{ code })>
521
522 B<WARNING>: This extended regular expression feature is considered
523 highly experimental, and may be changed or deleted without notice.
524
525 This zero-width assertion evaluate any embedded Perl code.  It
526 always succeeds, and its C<code> is not interpolated.  Currently,
527 the rules to determine where the C<code> ends are somewhat convoluted.
528
529 The C<code> is properly scoped in the following sense: If the assertion
530 is backtracked (compare L<"Backtracking">), all changes introduced after
531 C<local>ization are undone, so that
532
533   $_ = 'a' x 8;
534   m< 
535      (?{ $cnt = 0 })                    # Initialize $cnt.
536      (
537        a 
538        (?{
539            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
540        })
541      )*  
542      aaaa
543      (?{ $res = $cnt })                 # On success copy to non-localized
544                                         # location.
545    >x;
546
547 will set C<$res = 4>.  Note that after the match, $cnt returns to the globally
548 introduced value, because the scopes that restrict C<local> operators
549 are unwound.
550
551 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
552 switch.  If I<not> used in this way, the result of evaluation of
553 C<code> is put into the special variable C<$^R>.  This happens
554 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
555 inside the same regular expression.
556
557 The assignment to C<$^R> above is properly localized, so the old
558 value of C<$^R> is restored if the assertion is backtracked; compare
559 L<"Backtracking">.
560
561 For reasons of security, this construct is forbidden if the regular
562 expression involves run-time interpolation of variables, unless the
563 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
564 variables contain results of C<qr//> operator (see
565 L<perlop/"qr/STRING/imosx">).  
566
567 This restriction is because of the wide-spread and remarkably convenient
568 custom of using run-time determined strings as patterns.  For example:
569
570     $re = <>;
571     chomp $re;
572     $string =~ /$re/;
573
574 Before Perl knew how to execute interpolated code within a pattern,
575 this operation was completely safe from a security point of view,
576 although it could raise an exception from an illegal pattern.  If
577 you turn on the C<use re 'eval'>, though, it is no longer secure,
578 so you should only do so if you are also using taint checking.
579 Better yet, use the carefully constrained evaluation within a Safe
580 module.  See L<perlsec> for details about both these mechanisms.
581
582 =item C<(??{ code })>
583
584 B<WARNING>: This extended regular expression feature is considered
585 highly experimental, and may be changed or deleted without notice.
586 A simplified version of the syntax may be introduced for commonly
587 used idioms.
588
589 This is a "postponed" regular subexpression.  The C<code> is evaluated
590 at run time, at the moment this subexpression may match.  The result
591 of evaluation is considered as a regular expression and matched as
592 if it were inserted instead of this construct.
593
594 The C<code> is not interpolated.  As before, the rules to determine
595 where the C<code> ends are currently somewhat convoluted.
596
597 The following pattern matches a parenthesized group:
598
599   $re = qr{
600              \(
601              (?:
602                 (?> [^()]+ )    # Non-parens without backtracking
603               |
604                 (??{ $re })     # Group with matching parens
605              )*
606              \)
607           }x;
608
609 =item C<< (?>pattern) >>
610
611 B<WARNING>: This extended regular expression feature is considered
612 highly experimental, and may be changed or deleted without notice.
613
614 An "independent" subexpression, one which matches the substring
615 that a I<standalone> C<pattern> would match if anchored at the given
616 position, and it matches I<nothing other than this substring>.  This
617 construct is useful for optimizations of what would otherwise be
618 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
619 It may also be useful in places where the "grab all you can, and do not
620 give anything back" semantic is desirable.
621
622 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
623 (anchored at the beginning of string, as above) will match I<all>
624 characters C<a> at the beginning of string, leaving no C<a> for
625 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
626 since the match of the subgroup C<a*> is influenced by the following
627 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
628 C<a*ab> will match fewer characters than a standalone C<a*>, since
629 this makes the tail match.
630
631 An effect similar to C<< (?>pattern) >> may be achieved by writing
632 C<(?=(pattern))\1>.  This matches the same substring as a standalone
633 C<a+>, and the following C<\1> eats the matched string; it therefore
634 makes a zero-length assertion into an analogue of C<< (?>...) >>.
635 (The difference between these two constructs is that the second one
636 uses a capturing group, thus shifting ordinals of backreferences
637 in the rest of a regular expression.)
638
639 Consider this pattern:
640
641     m{ \(
642           ( 
643             [^()]+              # x+
644           | 
645             \( [^()]* \)
646           )+
647        \) 
648      }x
649
650 That will efficiently match a nonempty group with matching parentheses
651 two levels deep or less.  However, if there is no such group, it
652 will take virtually forever on a long string.  That's because there
653 are so many different ways to split a long string into several
654 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
655 to a subpattern of the above pattern.  Consider how the pattern
656 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
657 seconds, but that each extra letter doubles this time.  This
658 exponential performance will make it appear that your program has
659 hung.  However, a tiny change to this pattern
660
661     m{ \( 
662           ( 
663             (?> [^()]+ )        # change x+ above to (?> x+ )
664           | 
665             \( [^()]* \)
666           )+
667        \) 
668      }x
669
670 which uses C<< (?>...) >> matches exactly when the one above does (verifying
671 this yourself would be a productive exercise), but finishes in a fourth
672 the time when used on a similar string with 1000000 C<a>s.  Be aware,
673 however, that this pattern currently triggers a warning message under
674 the C<use warnings> pragma or B<-w> switch saying it
675 C<"matches the null string many times">):
676
677 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
678 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
679 This was only 4 times slower on a string with 1000000 C<a>s.
680
681 The "grab all you can, and do not give anything back" semantic is desirable
682 in many situations where on the first sight a simple C<()*> looks like
683 the correct solution.  Suppose we parse text with comments being delimited
684 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
685 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
686 the comment delimiter, because it may "give up" some whitespace if
687 the remainder of the pattern can be made to match that way.  The correct
688 answer is either one of these:
689
690     (?>#[ \t]*)
691     #[ \t]*(?![ \t])
692
693 For example, to grab non-empty comments into $1, one should use either
694 one of these:
695
696     / (?> \# [ \t]* ) (        .+ ) /x;
697     /     \# [ \t]*   ( [^ \t] .* ) /x;
698
699 Which one you pick depends on which of these expressions better reflects
700 the above specification of comments.
701
702 =item C<(?(condition)yes-pattern|no-pattern)>
703
704 =item C<(?(condition)yes-pattern)>
705
706 B<WARNING>: This extended regular expression feature is considered
707 highly experimental, and may be changed or deleted without notice.
708
709 Conditional expression.  C<(condition)> should be either an integer in
710 parentheses (which is valid if the corresponding pair of parentheses
711 matched), or look-ahead/look-behind/evaluate zero-width assertion.
712
713 For example:
714
715     m{ ( \( )? 
716        [^()]+ 
717        (?(1) \) ) 
718      }x
719
720 matches a chunk of non-parentheses, possibly included in parentheses
721 themselves.
722
723 =back
724
725 =head2 Backtracking
726
727 NOTE: This section presents an abstract approximation of regular
728 expression behavior.  For a more rigorous (and complicated) view of
729 the rules involved in selecting a match among possible alternatives,
730 see L<Combining pieces together>.
731
732 A fundamental feature of regular expression matching involves the
733 notion called I<backtracking>, which is currently used (when needed)
734 by all regular expression quantifiers, namely C<*>, C<*?>, C<+>,
735 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
736 internally, but the general principle outlined here is valid.
737
738 For a regular expression to match, the I<entire> regular expression must
739 match, not just part of it.  So if the beginning of a pattern containing a
740 quantifier succeeds in a way that causes later parts in the pattern to
741 fail, the matching engine backs up and recalculates the beginning
742 part--that's why it's called backtracking.
743
744 Here is an example of backtracking:  Let's say you want to find the
745 word following "foo" in the string "Food is on the foo table.":
746
747     $_ = "Food is on the foo table.";
748     if ( /\b(foo)\s+(\w+)/i ) {
749         print "$2 follows $1.\n";
750     }
751
752 When the match runs, the first part of the regular expression (C<\b(foo)>)
753 finds a possible match right at the beginning of the string, and loads up
754 $1 with "Foo".  However, as soon as the matching engine sees that there's
755 no whitespace following the "Foo" that it had saved in $1, it realizes its
756 mistake and starts over again one character after where it had the
757 tentative match.  This time it goes all the way until the next occurrence
758 of "foo". The complete regular expression matches this time, and you get
759 the expected output of "table follows foo."
760
761 Sometimes minimal matching can help a lot.  Imagine you'd like to match
762 everything between "foo" and "bar".  Initially, you write something
763 like this:
764
765     $_ =  "The food is under the bar in the barn.";
766     if ( /foo(.*)bar/ ) {
767         print "got <$1>\n";
768     }
769
770 Which perhaps unexpectedly yields:
771
772   got <d is under the bar in the >
773
774 That's because C<.*> was greedy, so you get everything between the
775 I<first> "foo" and the I<last> "bar".  Here it's more effective
776 to use minimal matching to make sure you get the text between a "foo"
777 and the first "bar" thereafter.
778
779     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
780   got <d is under the >
781
782 Here's another example: let's say you'd like to match a number at the end
783 of a string, and you also want to keep the preceding part the match.
784 So you write this:
785
786     $_ = "I have 2 numbers: 53147";
787     if ( /(.*)(\d*)/ ) {                                # Wrong!
788         print "Beginning is <$1>, number is <$2>.\n";
789     }
790
791 That won't work at all, because C<.*> was greedy and gobbled up the
792 whole string. As C<\d*> can match on an empty string the complete
793 regular expression matched successfully.
794
795     Beginning is <I have 2 numbers: 53147>, number is <>.
796
797 Here are some variants, most of which don't work:
798
799     $_ = "I have 2 numbers: 53147";
800     @pats = qw{
801         (.*)(\d*)
802         (.*)(\d+)
803         (.*?)(\d*)
804         (.*?)(\d+)
805         (.*)(\d+)$
806         (.*?)(\d+)$
807         (.*)\b(\d+)$
808         (.*\D)(\d+)$
809     };
810
811     for $pat (@pats) {
812         printf "%-12s ", $pat;
813         if ( /$pat/ ) {
814             print "<$1> <$2>\n";
815         } else {
816             print "FAIL\n";
817         }
818     }
819
820 That will print out:
821
822     (.*)(\d*)    <I have 2 numbers: 53147> <>
823     (.*)(\d+)    <I have 2 numbers: 5314> <7>
824     (.*?)(\d*)   <> <>
825     (.*?)(\d+)   <I have > <2>
826     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
827     (.*?)(\d+)$  <I have 2 numbers: > <53147>
828     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
829     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
830
831 As you see, this can be a bit tricky.  It's important to realize that a
832 regular expression is merely a set of assertions that gives a definition
833 of success.  There may be 0, 1, or several different ways that the
834 definition might succeed against a particular string.  And if there are
835 multiple ways it might succeed, you need to understand backtracking to
836 know which variety of success you will achieve.
837
838 When using look-ahead assertions and negations, this can all get even
839 tricker.  Imagine you'd like to find a sequence of non-digits not
840 followed by "123".  You might try to write that as
841
842     $_ = "ABC123";
843     if ( /^\D*(?!123)/ ) {              # Wrong!
844         print "Yup, no 123 in $_\n";
845     }
846
847 But that isn't going to match; at least, not the way you're hoping.  It
848 claims that there is no 123 in the string.  Here's a clearer picture of
849 why it that pattern matches, contrary to popular expectations:
850
851     $x = 'ABC123' ;
852     $y = 'ABC445' ;
853
854     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/ ;
855     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/ ;
856
857     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/ ;
858     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/ ;
859
860 This prints
861
862     2: got ABC
863     3: got AB
864     4: got ABC
865
866 You might have expected test 3 to fail because it seems to a more
867 general purpose version of test 1.  The important difference between
868 them is that test 3 contains a quantifier (C<\D*>) and so can use
869 backtracking, whereas test 1 will not.  What's happening is
870 that you've asked "Is it true that at the start of $x, following 0 or more
871 non-digits, you have something that's not 123?"  If the pattern matcher had
872 let C<\D*> expand to "ABC", this would have caused the whole pattern to
873 fail.
874
875 The search engine will initially match C<\D*> with "ABC".  Then it will
876 try to match C<(?!123> with "123", which fails.  But because
877 a quantifier (C<\D*>) has been used in the regular expression, the
878 search engine can backtrack and retry the match differently
879 in the hope of matching the complete regular expression.
880
881 The pattern really, I<really> wants to succeed, so it uses the
882 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
883 time.  Now there's indeed something following "AB" that is not
884 "123".  It's "C123", which suffices.
885
886 We can deal with this by using both an assertion and a negation.
887 We'll say that the first part in $1 must be followed both by a digit
888 and by something that's not "123".  Remember that the look-aheads
889 are zero-width expressions--they only look, but don't consume any
890 of the string in their match.  So rewriting this way produces what
891 you'd expect; that is, case 5 will fail, but case 6 succeeds:
892
893     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/ ;
894     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/ ;
895
896     6: got ABC
897
898 In other words, the two zero-width assertions next to each other work as though
899 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
900 matches only if you're at the beginning of the line AND the end of the
901 line simultaneously.  The deeper underlying truth is that juxtaposition in
902 regular expressions always means AND, except when you write an explicit OR
903 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
904 although the attempted matches are made at different positions because "a"
905 is not a zero-width assertion, but a one-width assertion.
906
907 B<WARNING>: particularly complicated regular expressions can take
908 exponential time to solve because of the immense number of possible
909 ways they can use backtracking to try match.  For example, without
910 internal optimizations done by the regular expression engine, this will
911 take a painfully long time to run:
912
913     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5}){0,5}[c]/
914
915 And if you used C<*>'s instead of limiting it to 0 through 5 matches,
916 then it would take forever--or until you ran out of stack space.
917
918 A powerful tool for optimizing such beasts is what is known as an
919 "independent group",
920 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
921 zero-length look-ahead/look-behind assertions will not backtrack to make
922 the tail match, since they are in "logical" context: only 
923 whether they match is considered relevant.  For an example
924 where side-effects of look-ahead I<might> have influenced the
925 following match, see L<C<< (?>pattern) >>>.
926
927 =head2 Version 8 Regular Expressions
928
929 In case you're not familiar with the "regular" Version 8 regex
930 routines, here are the pattern-matching rules not described above.
931
932 Any single character matches itself, unless it is a I<metacharacter>
933 with a special meaning described here or above.  You can cause
934 characters that normally function as metacharacters to be interpreted
935 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
936 character; "\\" matches a "\").  A series of characters matches that
937 series of characters in the target string, so the pattern C<blurfl>
938 would match "blurfl" in the target string.
939
940 You can specify a character class, by enclosing a list of characters
941 in C<[]>, which will match any one character from the list.  If the
942 first character after the "[" is "^", the class matches any character not
943 in the list.  Within a list, the "-" character specifies a
944 range, so that C<a-z> represents all characters between "a" and "z",
945 inclusive.  If you want either "-" or "]" itself to be a member of a
946 class, put it at the start of the list (possibly after a "^"), or
947 escape it with a backslash.  "-" is also taken literally when it is
948 at the end of the list, just before the closing "]".  (The
949 following all specify the same class of three characters: C<[-az]>,
950 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
951 specifies a class containing twenty-six characters.)
952 Also, if you try to use the character classes C<\w>, C<\W>, C<\s>,
953 C<\S>, C<\d>, or C<\D> as endpoints of a range, that's not a range,
954 the "-" is understood literally.
955
956 Note also that the whole range idea is rather unportable between
957 character sets--and even within character sets they may cause results
958 you probably didn't expect.  A sound principle is to use only ranges
959 that begin from and end at either alphabets of equal case ([a-e],
960 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
961 spell out the character sets in full.
962
963 Characters may be specified using a metacharacter syntax much like that
964 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
965 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
966 of octal digits, matches the character whose ASCII value is I<nnn>.
967 Similarly, \xI<nn>, where I<nn> are hexadecimal digits, matches the
968 character whose ASCII value is I<nn>. The expression \cI<x> matches the
969 ASCII character control-I<x>.  Finally, the "." metacharacter matches any
970 character except "\n" (unless you use C</s>).
971
972 You can specify a series of alternatives for a pattern using "|" to
973 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
974 or "foe" in the target string (as would C<f(e|i|o)e>).  The
975 first alternative includes everything from the last pattern delimiter
976 ("(", "[", or the beginning of the pattern) up to the first "|", and
977 the last alternative contains everything from the last "|" to the next
978 pattern delimiter.  That's why it's common practice to include
979 alternatives in parentheses: to minimize confusion about where they
980 start and end.
981
982 Alternatives are tried from left to right, so the first
983 alternative found for which the entire expression matches, is the one that
984 is chosen. This means that alternatives are not necessarily greedy. For
985 example: when matching C<foo|foot> against "barefoot", only the "foo"
986 part will match, as that is the first alternative tried, and it successfully
987 matches the target string. (This might not seem important, but it is
988 important when you are capturing matched text using parentheses.)
989
990 Also remember that "|" is interpreted as a literal within square brackets,
991 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
992
993 Within a pattern, you may designate subpatterns for later reference
994 by enclosing them in parentheses, and you may refer back to the
995 I<n>th subpattern later in the pattern using the metacharacter
996 \I<n>.  Subpatterns are numbered based on the left to right order
997 of their opening parenthesis.  A backreference matches whatever
998 actually matched the subpattern in the string being examined, not
999 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1000 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1001 1 matched "0x", even though the rule C<0|0x> could potentially match
1002 the leading 0 in the second number.
1003
1004 =head2 Warning on \1 vs $1
1005
1006 Some people get too used to writing things like:
1007
1008     $pattern =~ s/(\W)/\\\1/g;
1009
1010 This is grandfathered for the RHS of a substitute to avoid shocking the
1011 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1012 PerlThink, the righthand side of a C<s///> is a double-quoted string.  C<\1> in
1013 the usual double-quoted string means a control-A.  The customary Unix
1014 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1015 of doing that, you get yourself into trouble if you then add an C</e>
1016 modifier.
1017
1018     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1019
1020 Or if you try to do
1021
1022     s/(\d+)/\1000/;
1023
1024 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1025 C<${1}000>.  The operation of interpolation should not be confused
1026 with the operation of matching a backreference.  Certainly they mean two
1027 different things on the I<left> side of the C<s///>.
1028
1029 =head2 Repeated patterns matching zero-length substring
1030
1031 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1032
1033 Regular expressions provide a terse and powerful programming language.  As
1034 with most other power tools, power comes together with the ability
1035 to wreak havoc.
1036
1037 A common abuse of this power stems from the ability to make infinite
1038 loops using regular expressions, with something as innocuous as:
1039
1040     'foo' =~ m{ ( o? )* }x;
1041
1042 The C<o?> can match at the beginning of C<'foo'>, and since the position
1043 in the string is not moved by the match, C<o?> would match again and again
1044 because of the C<*> modifier.  Another common way to create a similar cycle
1045 is with the looping modifier C<//g>:
1046
1047     @matches = ( 'foo' =~ m{ o? }xg );
1048
1049 or
1050
1051     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1052
1053 or the loop implied by split().
1054
1055 However, long experience has shown that many programming tasks may
1056 be significantly simplified by using repeated subexpressions that
1057 may match zero-length substrings.  Here's a simple example being:
1058
1059     @chars = split //, $string;           # // is not magic in split
1060     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1061
1062 Thus Perl allows such constructs, by I<forcefully breaking
1063 the infinite loop>.  The rules for this are different for lower-level
1064 loops given by the greedy modifiers C<*+{}>, and for higher-level
1065 ones like the C</g> modifier or split() operator.
1066
1067 The lower-level loops are I<interrupted> (that is, the loop is
1068 broken) when Perl detects that a repeated expression matched a
1069 zero-length substring.   Thus
1070
1071    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1072
1073 is made equivalent to 
1074
1075    m{   (?: NON_ZERO_LENGTH )* 
1076       | 
1077         (?: ZERO_LENGTH )? 
1078     }x;
1079
1080 The higher level-loops preserve an additional state between iterations:
1081 whether the last match was zero-length.  To break the loop, the following 
1082 match after a zero-length match is prohibited to have a length of zero.
1083 This prohibition interacts with backtracking (see L<"Backtracking">), 
1084 and so the I<second best> match is chosen if the I<best> match is of
1085 zero length.
1086
1087 For example:
1088
1089     $_ = 'bar';
1090     s/\w??/<$&>/g;
1091
1092 results in C<"<><b><><a><><r><>">.  At each position of the string the best
1093 match given by non-greedy C<??> is the zero-length match, and the I<second 
1094 best> match is what is matched by C<\w>.  Thus zero-length matches
1095 alternate with one-character-long matches.
1096
1097 Similarly, for repeated C<m/()/g> the second-best match is the match at the 
1098 position one notch further in the string.
1099
1100 The additional state of being I<matched with zero-length> is associated with
1101 the matched string, and is reset by each assignment to pos().
1102 Zero-length matches at the end of the previous match are ignored
1103 during C<split>.
1104
1105 =head2 Combining pieces together
1106
1107 Each of the elementary pieces of regular expressions which were described
1108 before (such as C<ab> or C<\Z>) could match at most one substring
1109 at the given position of the input string.  However, in a typical regular
1110 expression these elementary pieces are combined into more complicated
1111 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1112 (in these examples C<S> and C<T> are regular subexpressions).
1113
1114 Such combinations can include alternatives, leading to a problem of choice:
1115 if we match a regular expression C<a|ab> against C<"abc">, will it match
1116 substring C<"a"> or C<"ab">?  One way to describe which substring is
1117 actually matched is the concept of backtracking (see L<"Backtracking">).
1118 However, this description is too low-level and makes you think
1119 in terms of a particular implementation.
1120
1121 Another description starts with notions of "better"/"worse".  All the
1122 substrings which may be matched by the given regular expression can be
1123 sorted from the "best" match to the "worst" match, and it is the "best"
1124 match which is chosen.  This substitutes the question of "what is chosen?"
1125 by the question of "which matches are better, and which are worse?".
1126
1127 Again, for elementary pieces there is no such question, since at most
1128 one match at a given position is possible.  This section describes the
1129 notion of better/worse for combining operators.  In the description
1130 below C<S> and C<T> are regular subexpressions.
1131
1132 =over
1133
1134 =item C<ST>
1135
1136 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1137 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1138 which can be matched by C<T>. 
1139
1140 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1141 match than C<A'B'>.
1142
1143 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1144 C<B> is better match for C<T> than C<B'>.
1145
1146 =item C<S|T>
1147
1148 When C<S> can match, it is a better match than when only C<T> can match.
1149
1150 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
1151 two matches for C<T>.
1152
1153 =item C<S{REPEAT_COUNT}>
1154
1155 Matches as C<SSS...S> (repeated as many times as necessary).
1156
1157 =item C<S{min,max}>
1158
1159 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
1160
1161 =item C<S{min,max}?>
1162
1163 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
1164
1165 =item C<S?>, C<S*>, C<S+>
1166
1167 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
1168
1169 =item C<S??>, C<S*?>, C<S+?>
1170
1171 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
1172
1173 =item C<< (?>S) >>
1174
1175 Matches the best match for C<S> and only that.
1176
1177 =item C<(?=S)>, C<(?<=S)>
1178
1179 Only the best match for C<S> is considered.  (This is important only if
1180 C<S> has capturing parentheses, and backreferences are used somewhere
1181 else in the whole regular expression.)
1182
1183 =item C<(?!S)>, C<(?<!S)>
1184
1185 For this grouping operator there is no need to describe the ordering, since
1186 only whether or not C<S> can match is important.
1187
1188 =item C<(??{ EXPR })>
1189
1190 The ordering is the same as for the regular expression which is
1191 the result of EXPR.
1192
1193 =item C<(?(condition)yes-pattern|no-pattern)>
1194
1195 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
1196 already determined.  The ordering of the matches is the same as for the
1197 chosen subexpression.
1198
1199 =back
1200
1201 The above recipes describe the ordering of matches I<at a given position>.
1202 One more rule is needed to understand how a match is determined for the
1203 whole regular expression: a match at an earlier position is always better
1204 than a match at a later position.
1205
1206 =head2 Creating custom RE engines
1207
1208 Overloaded constants (see L<overload>) provide a simple way to extend
1209 the functionality of the RE engine.
1210
1211 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
1212 matches at boundary between white-space characters and non-whitespace
1213 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
1214 at these positions, so we want to have each C<\Y|> in the place of the
1215 more complicated version.  We can create a module C<customre> to do
1216 this:
1217
1218     package customre;
1219     use overload;
1220
1221     sub import {
1222       shift;
1223       die "No argument to customre::import allowed" if @_;
1224       overload::constant 'qr' => \&convert;
1225     }
1226
1227     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
1228
1229     my %rules = ( '\\' => '\\', 
1230                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
1231     sub convert {
1232       my $re = shift;
1233       $re =~ s{ 
1234                 \\ ( \\ | Y . )
1235               }
1236               { $rules{$1} or invalid($re,$1) }sgex; 
1237       return $re;
1238     }
1239
1240 Now C<use customre> enables the new escape in constant regular
1241 expressions, i.e., those without any runtime variable interpolations.
1242 As documented in L<overload>, this conversion will work only over
1243 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
1244 part of this regular expression needs to be converted explicitly
1245 (but only if the special meaning of C<\Y|> should be enabled inside $re):
1246
1247     use customre;
1248     $re = <>;
1249     chomp $re;
1250     $re = customre::convert $re;
1251     /\Y|$re\Y|/;
1252
1253 =head1 BUGS
1254
1255 This document varies from difficult to understand to completely
1256 and utterly opaque.  The wandering prose riddled with jargon is
1257 hard to fathom in several places.
1258
1259 This document needs a rewrite that separates the tutorial content
1260 from the reference content.
1261
1262 =head1 SEE ALSO
1263
1264 L<perlop/"Regexp Quote-Like Operators">.
1265
1266 L<perlop/"Gory details of parsing quoted constructs">.
1267
1268 L<perlfaq6>.
1269
1270 L<perlfunc/pos>.
1271
1272 L<perllocale>.
1273
1274 I<Mastering Regular Expressions> by Jeffrey Friedl, published
1275 by O'Reilly and Associates.