This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Extract _handle_W_command .
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_05';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     @cmdfhs
631     $CommandSet
632     $CreateTTY
633     $DBGR
634     @dbline
635     $dbline
636     %dbline
637     $dieLevel
638     $filename
639     $hist
640     $histfile
641     $histsize
642     $IN
643     $inhibit_exit
644     @ini_INC
645     $ini_warn
646     $maxtrace
647     $od
648     $onetimedumpDepth
649     @options
650     $osingle
651     $otrace
652     $pager
653     $post
654     %postponed
655     $prc
656     $pre
657     $pretype
658     $psh
659     @RememberOnROptions
660     $remoteport
661     @res
662     $rl
663     @saved
664     $signalLevel
665     $sub
666     $term
667     $usercontext
668     $warnLevel
669 );
670
671 our (
672     $evalarg,
673     $frame,
674     $ImmediateStop,
675     $line,
676     $onetimeDump,
677     %option,
678     $OUT,
679     $packname,
680     $signal,
681     $single,
682     $start,
683     %sub,
684     $subname,
685     $trace,
686     $window,
687 );
688
689 # Used to save @ARGV and extract any debugger-related flags.
690 use vars qw(@ARGS);
691
692 # Used to prevent multiple entries to diesignal()
693 # (if for instance diesignal() itself dies)
694 use vars qw($panic);
695
696 # Used to prevent the debugger from running nonstop
697 # after a restart
698 our ($second_time);
699
700 sub _calc_usercontext {
701     my ($package) = @_;
702
703     # Cancel strict completely for the evaluated code, so the code
704     # the user evaluates won't be affected by it. (Shlomi Fish)
705     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
706     . "package $package;";    # this won't let them modify, alas
707 }
708
709 sub eval {
710
711     # 'my' would make it visible from user code
712     #    but so does local! --tchrist
713     # Remember: this localizes @DB::res, not @main::res.
714     local @res;
715     {
716
717         # Try to keep the user code from messing  with us. Save these so that
718         # even if the eval'ed code changes them, we can put them back again.
719         # Needed because the user could refer directly to the debugger's
720         # package globals (and any 'my' variables in this containing scope)
721         # inside the eval(), and we want to try to stay safe.
722         local $otrace  = $trace;
723         local $osingle = $single;
724         local $od      = $^D;
725
726         # Untaint the incoming eval() argument.
727         { ($evalarg) = $evalarg =~ /(.*)/s; }
728
729         # $usercontext built in DB::DB near the comment
730         # "set up the context for DB::eval ..."
731         # Evaluate and save any results.
732         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
733
734         # Restore those old values.
735         $trace  = $otrace;
736         $single = $osingle;
737         $^D     = $od;
738     }
739
740     # Save the current value of $@, and preserve it in the debugger's copy
741     # of the saved precious globals.
742     my $at = $@;
743
744     # Since we're only saving $@, we only have to localize the array element
745     # that it will be stored in.
746     local $saved[0];    # Preserve the old value of $@
747     eval { DB::save() };
748
749     # Now see whether we need to report an error back to the user.
750     if ($at) {
751         local $\ = '';
752         print $OUT $at;
753     }
754
755     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
756     # are package globals.
757     elsif ($onetimeDump) {
758         if ( $onetimeDump eq 'dump' ) {
759             local $option{dumpDepth} = $onetimedumpDepth
760               if defined $onetimedumpDepth;
761             dumpit( $OUT, \@res );
762         }
763         elsif ( $onetimeDump eq 'methods' ) {
764             methods( $res[0] );
765         }
766     } ## end elsif ($onetimeDump)
767     @res;
768 } ## end sub eval
769
770 ############################################## End lexical danger zone
771
772 # After this point it is safe to introduce lexicals.
773 # The code being debugged will be executing in its own context, and
774 # can't see the inside of the debugger.
775 #
776 # However, one should not overdo it: leave as much control from outside as
777 # possible. If you make something a lexical, it's not going to be addressable
778 # from outside the debugger even if you know its name.
779
780 # This file is automatically included if you do perl -d.
781 # It's probably not useful to include this yourself.
782 #
783 # Before venturing further into these twisty passages, it is
784 # wise to read the perldebguts man page or risk the ire of dragons.
785 #
786 # (It should be noted that perldebguts will tell you a lot about
787 # the underlying mechanics of how the debugger interfaces into the
788 # Perl interpreter, but not a lot about the debugger itself. The new
789 # comments in this code try to address this problem.)
790
791 # Note that no subroutine call is possible until &DB::sub is defined
792 # (for subroutines defined outside of the package DB). In fact the same is
793 # true if $deep is not defined.
794
795 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
796
797 # modified Perl debugger, to be run from Emacs in perldb-mode
798 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
799 # Johan Vromans -- upgrade to 4.0 pl 10
800 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
801 ########################################################################
802
803 =head1 DEBUGGER INITIALIZATION
804
805 The debugger starts up in phases.
806
807 =head2 BASIC SETUP
808
809 First, it initializes the environment it wants to run in: turning off
810 warnings during its own compilation, defining variables which it will need
811 to avoid warnings later, setting itself up to not exit when the program
812 terminates, and defaulting to printing return values for the C<r> command.
813
814 =cut
815
816 # Needed for the statement after exec():
817 #
818 # This BEGIN block is simply used to switch off warnings during debugger
819 # compilation. Probably it would be better practice to fix the warnings,
820 # but this is how it's done at the moment.
821
822 BEGIN {
823     $ini_warn = $^W;
824     $^W       = 0;
825 }    # Switch compilation warnings off until another BEGIN.
826
827 local ($^W) = 0;    # Switch run-time warnings off during init.
828
829 =head2 THREADS SUPPORT
830
831 If we are running under a threaded Perl, we require threads and threads::shared
832 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
833 threaded debugger control.  C<-dt> can also be used to set this.
834
835 Each new thread will be announced and the debugger prompt will always inform
836 you of each new thread created.  It will also indicate the thread id in which
837 we are currently running within the prompt like this:
838
839     [tid] DB<$i>
840
841 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
842 command prompt.  The prompt will show: C<[0]> when running under threads, but
843 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
844
845 While running under threads, when you set or delete a breakpoint (etc.), this
846 will apply to all threads, not just the currently running one.  When you are
847 in a currently executing thread, you will stay there until it completes.  With
848 the current implementation it is not currently possible to hop from one thread
849 to another.
850
851 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
852
853 Note that threading support was built into the debugger as of Perl version
854 C<5.8.6> and debugger version C<1.2.8>.
855
856 =cut
857
858 BEGIN {
859     # ensure we can share our non-threaded variables or no-op
860     if ($ENV{PERL5DB_THREADED}) {
861         require threads;
862         require threads::shared;
863         import threads::shared qw(share);
864         $DBGR;
865         share(\$DBGR);
866         lock($DBGR);
867         print "Threads support enabled\n";
868     } else {
869         *lock  = sub(*) {};
870         *share = sub(*) {};
871     }
872 }
873
874 # These variables control the execution of 'dumpvar.pl'.
875 {
876     package dumpvar;
877     use vars qw(
878     $hashDepth
879     $arrayDepth
880     $dumpDBFiles
881     $dumpPackages
882     $quoteHighBit
883     $printUndef
884     $globPrint
885     $usageOnly
886     );
887 }
888
889 # used to control die() reporting in diesignal()
890 {
891     package Carp;
892     use vars qw($CarpLevel);
893 }
894
895 # without threads, $filename is not defined until DB::DB is called
896 foreach my $k (keys (%INC)) {
897     share(\$main::{'_<'.$filename}) if defined $filename;
898 };
899
900 # Command-line + PERLLIB:
901 # Save the contents of @INC before they are modified elsewhere.
902 @ini_INC = @INC;
903
904 # This was an attempt to clear out the previous values of various
905 # trapped errors. Apparently it didn't help. XXX More info needed!
906 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
907
908 # We set these variables to safe values. We don't want to blindly turn
909 # off warnings, because other packages may still want them.
910 $trace = $signal = $single = 0;    # Uninitialized warning suppression
911                                    # (local $^W cannot help - other packages!).
912
913 # Default to not exiting when program finishes; print the return
914 # value when the 'r' command is used to return from a subroutine.
915 $inhibit_exit = $option{PrintRet} = 1;
916
917 use vars qw($trace_to_depth);
918
919 # Default to 1E9 so it won't be limited to a certain recursion depth.
920 $trace_to_depth = 1E9;
921
922 =head1 OPTION PROCESSING
923
924 The debugger's options are actually spread out over the debugger itself and
925 C<dumpvar.pl>; some of these are variables to be set, while others are
926 subs to be called with a value. To try to make this a little easier to
927 manage, the debugger uses a few data structures to define what options
928 are legal and how they are to be processed.
929
930 First, the C<@options> array defines the I<names> of all the options that
931 are to be accepted.
932
933 =cut
934
935 @options = qw(
936   CommandSet   HistFile      HistSize
937   hashDepth    arrayDepth    dumpDepth
938   DumpDBFiles  DumpPackages  DumpReused
939   compactDump  veryCompact   quote
940   HighBit      undefPrint    globPrint
941   PrintRet     UsageOnly     frame
942   AutoTrace    TTY           noTTY
943   ReadLine     NonStop       LineInfo
944   maxTraceLen  recallCommand ShellBang
945   pager        tkRunning     ornaments
946   signalLevel  warnLevel     dieLevel
947   inhibit_exit ImmediateStop bareStringify
948   CreateTTY    RemotePort    windowSize
949   DollarCaretP
950 );
951
952 @RememberOnROptions = qw(DollarCaretP);
953
954 =pod
955
956 Second, C<optionVars> lists the variables that each option uses to save its
957 state.
958
959 =cut
960
961 use vars qw(%optionVars);
962
963 %optionVars = (
964     hashDepth     => \$dumpvar::hashDepth,
965     arrayDepth    => \$dumpvar::arrayDepth,
966     CommandSet    => \$CommandSet,
967     DumpDBFiles   => \$dumpvar::dumpDBFiles,
968     DumpPackages  => \$dumpvar::dumpPackages,
969     DumpReused    => \$dumpvar::dumpReused,
970     HighBit       => \$dumpvar::quoteHighBit,
971     undefPrint    => \$dumpvar::printUndef,
972     globPrint     => \$dumpvar::globPrint,
973     UsageOnly     => \$dumpvar::usageOnly,
974     CreateTTY     => \$CreateTTY,
975     bareStringify => \$dumpvar::bareStringify,
976     frame         => \$frame,
977     AutoTrace     => \$trace,
978     inhibit_exit  => \$inhibit_exit,
979     maxTraceLen   => \$maxtrace,
980     ImmediateStop => \$ImmediateStop,
981     RemotePort    => \$remoteport,
982     windowSize    => \$window,
983     HistFile      => \$histfile,
984     HistSize      => \$histsize,
985 );
986
987 =pod
988
989 Third, C<%optionAction> defines the subroutine to be called to process each
990 option.
991
992 =cut
993
994 use vars qw(%optionAction);
995
996 %optionAction = (
997     compactDump   => \&dumpvar::compactDump,
998     veryCompact   => \&dumpvar::veryCompact,
999     quote         => \&dumpvar::quote,
1000     TTY           => \&TTY,
1001     noTTY         => \&noTTY,
1002     ReadLine      => \&ReadLine,
1003     NonStop       => \&NonStop,
1004     LineInfo      => \&LineInfo,
1005     recallCommand => \&recallCommand,
1006     ShellBang     => \&shellBang,
1007     pager         => \&pager,
1008     signalLevel   => \&signalLevel,
1009     warnLevel     => \&warnLevel,
1010     dieLevel      => \&dieLevel,
1011     tkRunning     => \&tkRunning,
1012     ornaments     => \&ornaments,
1013     RemotePort    => \&RemotePort,
1014     DollarCaretP  => \&DollarCaretP,
1015 );
1016
1017 =pod
1018
1019 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1020 option is used.
1021
1022 =cut
1023
1024 # Note that this list is not complete: several options not listed here
1025 # actually require that dumpvar.pl be loaded for them to work, but are
1026 # not in the table. A subsequent patch will correct this problem; for
1027 # the moment, we're just recommenting, and we are NOT going to change
1028 # function.
1029 use vars qw(%optionRequire);
1030
1031 %optionRequire = (
1032     compactDump => 'dumpvar.pl',
1033     veryCompact => 'dumpvar.pl',
1034     quote       => 'dumpvar.pl',
1035 );
1036
1037 =pod
1038
1039 There are a number of initialization-related variables which can be set
1040 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1041 variable. These are:
1042
1043 =over 4
1044
1045 =item C<$rl> - readline control XXX needs more explanation
1046
1047 =item C<$warnLevel> - whether or not debugger takes over warning handling
1048
1049 =item C<$dieLevel> - whether or not debugger takes over die handling
1050
1051 =item C<$signalLevel> - whether or not debugger takes over signal handling
1052
1053 =item C<$pre> - preprompt actions (array reference)
1054
1055 =item C<$post> - postprompt actions (array reference)
1056
1057 =item C<$pretype>
1058
1059 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1060
1061 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1062
1063 =back
1064
1065 =cut
1066
1067 # These guys may be defined in $ENV{PERL5DB} :
1068 $rl          = 1     unless defined $rl;
1069 $warnLevel   = 1     unless defined $warnLevel;
1070 $dieLevel    = 1     unless defined $dieLevel;
1071 $signalLevel = 1     unless defined $signalLevel;
1072 $pre         = []    unless defined $pre;
1073 $post        = []    unless defined $post;
1074 $pretype     = []    unless defined $pretype;
1075 $CreateTTY   = 3     unless defined $CreateTTY;
1076 $CommandSet  = '580' unless defined $CommandSet;
1077
1078 share($rl);
1079 share($warnLevel);
1080 share($dieLevel);
1081 share($signalLevel);
1082 share($pre);
1083 share($post);
1084 share($pretype);
1085 share($rl);
1086 share($CreateTTY);
1087 share($CommandSet);
1088
1089 =pod
1090
1091 The default C<die>, C<warn>, and C<signal> handlers are set up.
1092
1093 =cut
1094
1095 warnLevel($warnLevel);
1096 dieLevel($dieLevel);
1097 signalLevel($signalLevel);
1098
1099 =pod
1100
1101 The pager to be used is needed next. We try to get it from the
1102 environment first.  If it's not defined there, we try to find it in
1103 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1104 then call the C<pager()> function to save the pager name.
1105
1106 =cut
1107
1108 # This routine makes sure $pager is set up so that '|' can use it.
1109 pager(
1110
1111     # If PAGER is defined in the environment, use it.
1112     defined $ENV{PAGER}
1113     ? $ENV{PAGER}
1114
1115       # If not, see if Config.pm defines it.
1116     : eval { require Config }
1117       && defined $Config::Config{pager}
1118     ? $Config::Config{pager}
1119
1120       # If not, fall back to 'more'.
1121     : 'more'
1122   )
1123   unless defined $pager;
1124
1125 =pod
1126
1127 We set up the command to be used to access the man pages, the command
1128 recall character (C<!> unless otherwise defined) and the shell escape
1129 character (C<!> unless otherwise defined). Yes, these do conflict, and
1130 neither works in the debugger at the moment.
1131
1132 =cut
1133
1134 setman();
1135
1136 # Set up defaults for command recall and shell escape (note:
1137 # these currently don't work in linemode debugging).
1138 recallCommand("!") unless defined $prc;
1139 shellBang("!")     unless defined $psh;
1140
1141 =pod
1142
1143 We then set up the gigantic string containing the debugger help.
1144 We also set the limit on the number of arguments we'll display during a
1145 trace.
1146
1147 =cut
1148
1149 sethelp();
1150
1151 # If we didn't get a default for the length of eval/stack trace args,
1152 # set it here.
1153 $maxtrace = 400 unless defined $maxtrace;
1154
1155 =head2 SETTING UP THE DEBUGGER GREETING
1156
1157 The debugger I<greeting> helps to inform the user how many debuggers are
1158 running, and whether the current debugger is the primary or a child.
1159
1160 If we are the primary, we just hang onto our pid so we'll have it when
1161 or if we start a child debugger. If we are a child, we'll set things up
1162 so we'll have a unique greeting and so the parent will give us our own
1163 TTY later.
1164
1165 We save the current contents of the C<PERLDB_PIDS> environment variable
1166 because we mess around with it. We'll also need to hang onto it because
1167 we'll need it if we restart.
1168
1169 Child debuggers make a label out of the current PID structure recorded in
1170 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1171 yet so the parent will give them one later via C<resetterm()>.
1172
1173 =cut
1174
1175 # Save the current contents of the environment; we're about to
1176 # much with it. We'll need this if we have to restart.
1177 use vars qw($ini_pids);
1178 $ini_pids = $ENV{PERLDB_PIDS};
1179
1180 use vars qw ($pids $term_pid);
1181
1182 if ( defined $ENV{PERLDB_PIDS} ) {
1183
1184     # We're a child. Make us a label out of the current PID structure
1185     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1186     # a term yet so the parent will give us one later via resetterm().
1187
1188     my $env_pids = $ENV{PERLDB_PIDS};
1189     $pids = "[$env_pids]";
1190
1191     # Unless we are on OpenVMS, all programs under the DCL shell run under
1192     # the same PID.
1193
1194     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1195         $term_pid         = $$;
1196     }
1197     else {
1198         $ENV{PERLDB_PIDS} .= "->$$";
1199         $term_pid = -1;
1200     }
1201
1202 } ## end if (defined $ENV{PERLDB_PIDS...
1203 else {
1204
1205     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1206     # child debugger, and mark us as the parent, so we'll know to set up
1207     # more TTY's is we have to.
1208     $ENV{PERLDB_PIDS} = "$$";
1209     $pids             = "[pid=$$]";
1210     $term_pid         = $$;
1211 }
1212
1213 use vars qw($pidprompt);
1214 $pidprompt = '';
1215
1216 # Sets up $emacs as a synonym for $slave_editor.
1217 our ($slave_editor);
1218 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1219
1220 =head2 READING THE RC FILE
1221
1222 The debugger will read a file of initialization options if supplied. If
1223 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1224
1225 =cut
1226
1227 # As noted, this test really doesn't check accurately that the debugger
1228 # is running at a terminal or not.
1229
1230 use vars qw($rcfile);
1231 {
1232     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1233     # this is the wrong metric!
1234     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1235 }
1236
1237 =pod
1238
1239 The debugger does a safety test of the file to be read. It must be owned
1240 either by the current user or root, and must only be writable by the owner.
1241
1242 =cut
1243
1244 # This wraps a safety test around "do" to read and evaluate the init file.
1245 #
1246 # This isn't really safe, because there's a race
1247 # between checking and opening.  The solution is to
1248 # open and fstat the handle, but then you have to read and
1249 # eval the contents.  But then the silly thing gets
1250 # your lexical scope, which is unfortunate at best.
1251 sub safe_do {
1252     my $file = shift;
1253
1254     # Just exactly what part of the word "CORE::" don't you understand?
1255     local $SIG{__WARN__};
1256     local $SIG{__DIE__};
1257
1258     unless ( is_safe_file($file) ) {
1259         CORE::warn <<EO_GRIPE;
1260 perldb: Must not source insecure rcfile $file.
1261         You or the superuser must be the owner, and it must not
1262         be writable by anyone but its owner.
1263 EO_GRIPE
1264         return;
1265     } ## end unless (is_safe_file($file...
1266
1267     do $file;
1268     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1269 } ## end sub safe_do
1270
1271 # This is the safety test itself.
1272 #
1273 # Verifies that owner is either real user or superuser and that no
1274 # one but owner may write to it.  This function is of limited use
1275 # when called on a path instead of upon a handle, because there are
1276 # no guarantees that filename (by dirent) whose file (by ino) is
1277 # eventually accessed is the same as the one tested.
1278 # Assumes that the file's existence is not in doubt.
1279 sub is_safe_file {
1280     my $path = shift;
1281     stat($path) || return;    # mysteriously vaporized
1282     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1283
1284     return 0 if $uid != 0 && $uid != $<;
1285     return 0 if $mode & 022;
1286     return 1;
1287 } ## end sub is_safe_file
1288
1289 # If the rcfile (whichever one we decided was the right one to read)
1290 # exists, we safely do it.
1291 if ( -f $rcfile ) {
1292     safe_do("./$rcfile");
1293 }
1294
1295 # If there isn't one here, try the user's home directory.
1296 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1297     safe_do("$ENV{HOME}/$rcfile");
1298 }
1299
1300 # Else try the login directory.
1301 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1302     safe_do("$ENV{LOGDIR}/$rcfile");
1303 }
1304
1305 # If the PERLDB_OPTS variable has options in it, parse those out next.
1306 if ( defined $ENV{PERLDB_OPTS} ) {
1307     parse_options( $ENV{PERLDB_OPTS} );
1308 }
1309
1310 =pod
1311
1312 The last thing we do during initialization is determine which subroutine is
1313 to be used to obtain a new terminal when a new debugger is started. Right now,
1314 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1315 (darwin).
1316
1317 =cut
1318
1319 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1320 # Works if you're running an xterm or xterm-like window, or you're on
1321 # OS/2, or on Mac OS X. This may need some expansion.
1322
1323 if (not defined &get_fork_TTY)       # only if no routine exists
1324 {
1325     if ( defined $remoteport ) {
1326                                                  # Expect an inetd-like server
1327         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1328     }
1329     elsif (defined $ENV{TERM}                    # If we know what kind
1330                                                  # of terminal this is,
1331         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1332         and defined $ENV{DISPLAY}                # and what display it's on,
1333       )
1334     {
1335         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1336     }
1337     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1338         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1339     }
1340     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1341             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1342             and $ENV{TERM_PROGRAM}
1343                 eq 'Apple_Terminal'              # Terminal.app
1344             )
1345     {
1346         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1347     }
1348 } ## end if (not defined &get_fork_TTY...
1349
1350 # untaint $^O, which may have been tainted by the last statement.
1351 # see bug [perl #24674]
1352 $^O =~ m/^(.*)\z/;
1353 $^O = $1;
1354
1355 # Here begin the unreadable code.  It needs fixing.
1356
1357 =head2 RESTART PROCESSING
1358
1359 This section handles the restart command. When the C<R> command is invoked, it
1360 tries to capture all of the state it can into environment variables, and
1361 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1362 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1363 the R command stuffed into the environment variables.
1364
1365   PERLDB_RESTART   - flag only, contains no restart data itself.
1366   PERLDB_HIST      - command history, if it's available
1367   PERLDB_ON_LOAD   - breakpoints set by the rc file
1368   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1369   PERLDB_VISITED   - files that had breakpoints
1370   PERLDB_FILE_...  - breakpoints for a file
1371   PERLDB_OPT       - active options
1372   PERLDB_INC       - the original @INC
1373   PERLDB_PRETYPE   - preprompt debugger actions
1374   PERLDB_PRE       - preprompt Perl code
1375   PERLDB_POST      - post-prompt Perl code
1376   PERLDB_TYPEAHEAD - typeahead captured by readline()
1377
1378 We chug through all these variables and plug the values saved in them
1379 back into the appropriate spots in the debugger.
1380
1381 =cut
1382
1383 use vars qw(@hist @truehist %postponed_file @typeahead);
1384
1385 sub _restore_shared_globals_after_restart
1386 {
1387     @hist          = get_list('PERLDB_HIST');
1388     %break_on_load = get_list("PERLDB_ON_LOAD");
1389     %postponed     = get_list("PERLDB_POSTPONE");
1390
1391     share(@hist);
1392     share(@truehist);
1393     share(%break_on_load);
1394     share(%postponed);
1395 }
1396
1397 sub _restore_breakpoints_and_actions {
1398
1399     my @had_breakpoints = get_list("PERLDB_VISITED");
1400
1401     for my $file_idx ( 0 .. $#had_breakpoints ) {
1402         my $filename = $had_breakpoints[$file_idx];
1403         my %pf = get_list("PERLDB_FILE_$file_idx");
1404         $postponed_file{ $filename } = \%pf if %pf;
1405         my @lines = sort {$a <=> $b} keys(%pf);
1406         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1407         for my $line_idx (0 .. $#lines) {
1408             _set_breakpoint_enabled_status(
1409                 $filename,
1410                 $lines[$line_idx],
1411                 ($enabled_statuses[$line_idx] ? 1 : ''),
1412             );
1413         }
1414     }
1415
1416     return;
1417 }
1418
1419 sub _restore_options_after_restart
1420 {
1421     my %options_map = get_list("PERLDB_OPT");
1422
1423     while ( my ( $opt, $val ) = each %options_map ) {
1424         $val =~ s/[\\\']/\\$1/g;
1425         parse_options("$opt'$val'");
1426     }
1427
1428     return;
1429 }
1430
1431 sub _restore_globals_after_restart
1432 {
1433     # restore original @INC
1434     @INC     = get_list("PERLDB_INC");
1435     @ini_INC = @INC;
1436
1437     # return pre/postprompt actions and typeahead buffer
1438     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1439     $pre       = [ get_list("PERLDB_PRE") ];
1440     $post      = [ get_list("PERLDB_POST") ];
1441     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1442
1443     return;
1444 }
1445
1446
1447 if ( exists $ENV{PERLDB_RESTART} ) {
1448
1449     # We're restarting, so we don't need the flag that says to restart anymore.
1450     delete $ENV{PERLDB_RESTART};
1451
1452     # $restart = 1;
1453     _restore_shared_globals_after_restart();
1454
1455     _restore_breakpoints_and_actions();
1456
1457     # restore options
1458     _restore_options_after_restart();
1459
1460     _restore_globals_after_restart();
1461 } ## end if (exists $ENV{PERLDB_RESTART...
1462
1463 =head2 SETTING UP THE TERMINAL
1464
1465 Now, we'll decide how the debugger is going to interact with the user.
1466 If there's no TTY, we set the debugger to run non-stop; there's not going
1467 to be anyone there to enter commands.
1468
1469 =cut
1470
1471 use vars qw($notty $console $tty $LINEINFO);
1472 use vars qw($lineinfo $doccmd);
1473
1474 our ($runnonstop);
1475
1476 if ($notty) {
1477     $runnonstop = 1;
1478     share($runnonstop);
1479 }
1480
1481 =pod
1482
1483 If there is a TTY, we have to determine who it belongs to before we can
1484 proceed. If this is a slave editor or graphical debugger (denoted by
1485 the first command-line switch being '-emacs'), we shift this off and
1486 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1487
1488 =cut
1489
1490 else {
1491
1492     # Is Perl being run from a slave editor or graphical debugger?
1493     # If so, don't use readline, and set $slave_editor = 1.
1494     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1495         $rl = 0;
1496         shift(@main::ARGV);
1497     }
1498
1499     #require Term::ReadLine;
1500
1501 =pod
1502
1503 We then determine what the console should be on various systems:
1504
1505 =over 4
1506
1507 =item * Cygwin - We use C<stdin> instead of a separate device.
1508
1509 =cut
1510
1511     if ( $^O eq 'cygwin' ) {
1512
1513         # /dev/tty is binary. use stdin for textmode
1514         undef $console;
1515     }
1516
1517 =item * Unix - use C</dev/tty>.
1518
1519 =cut
1520
1521     elsif ( -e "/dev/tty" ) {
1522         $console = "/dev/tty";
1523     }
1524
1525 =item * Windows or MSDOS - use C<con>.
1526
1527 =cut
1528
1529     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1530         $console = "con";
1531     }
1532
1533 =item * VMS - use C<sys$command>.
1534
1535 =cut
1536
1537     else {
1538
1539         # everything else is ...
1540         $console = "sys\$command";
1541     }
1542
1543 =pod
1544
1545 =back
1546
1547 Several other systems don't use a specific console. We C<undef $console>
1548 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1549 with a slave editor, Epoc).
1550
1551 =cut
1552
1553     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1554
1555         # /dev/tty is binary. use stdin for textmode
1556         $console = undef;
1557     }
1558
1559     if ( $^O eq 'NetWare' ) {
1560
1561         # /dev/tty is binary. use stdin for textmode
1562         $console = undef;
1563     }
1564
1565     # In OS/2, we need to use STDIN to get textmode too, even though
1566     # it pretty much looks like Unix otherwise.
1567     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1568     {    # In OS/2
1569         $console = undef;
1570     }
1571
1572     # EPOC also falls into the 'got to use STDIN' camp.
1573     if ( $^O eq 'epoc' ) {
1574         $console = undef;
1575     }
1576
1577 =pod
1578
1579 If there is a TTY hanging around from a parent, we use that as the console.
1580
1581 =cut
1582
1583     $console = $tty if defined $tty;
1584
1585 =head2 SOCKET HANDLING
1586
1587 The debugger is capable of opening a socket and carrying out a debugging
1588 session over the socket.
1589
1590 If C<RemotePort> was defined in the options, the debugger assumes that it
1591 should try to start a debugging session on that port. It builds the socket
1592 and then tries to connect the input and output filehandles to it.
1593
1594 =cut
1595
1596     # Handle socket stuff.
1597
1598     if ( defined $remoteport ) {
1599
1600         # If RemotePort was defined in the options, connect input and output
1601         # to the socket.
1602         $IN = $OUT = connect_remoteport();
1603     } ## end if (defined $remoteport)
1604
1605 =pod
1606
1607 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1608 this is probably a situation where multiple debuggers are running (for example,
1609 a backticked command that starts up another debugger). We create a new IN and
1610 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1611 and if we can.
1612
1613 =cut
1614
1615     # Non-socket.
1616     else {
1617
1618         # Two debuggers running (probably a system or a backtick that invokes
1619         # the debugger itself under the running one). create a new IN and OUT
1620         # filehandle, and do the necessary mojo to create a new tty if we
1621         # know how, and we can.
1622         create_IN_OUT(4) if $CreateTTY & 4;
1623         if ($console) {
1624
1625             # If we have a console, check to see if there are separate ins and
1626             # outs to open. (They are assumed identical if not.)
1627
1628             my ( $i, $o ) = split /,/, $console;
1629             $o = $i unless defined $o;
1630
1631             # read/write on in, or just read, or read on STDIN.
1632             open( IN,      "+<$i" )
1633               || open( IN, "<$i" )
1634               || open( IN, "<&STDIN" );
1635
1636             # read/write/create/clobber out, or write/create/clobber out,
1637             # or merge with STDERR, or merge with STDOUT.
1638                  open( OUT, "+>$o" )
1639               || open( OUT, ">$o" )
1640               || open( OUT, ">&STDERR" )
1641               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1642
1643         } ## end if ($console)
1644         elsif ( not defined $console ) {
1645
1646             # No console. Open STDIN.
1647             open( IN, "<&STDIN" );
1648
1649             # merge with STDERR, or with STDOUT.
1650             open( OUT,      ">&STDERR" )
1651               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1652             $console = 'STDIN/OUT';
1653         } ## end elsif (not defined $console)
1654
1655         # Keep copies of the filehandles so that when the pager runs, it
1656         # can close standard input without clobbering ours.
1657         if ($console or (not defined($console))) {
1658             $IN = \*IN;
1659             $OUT = \*OUT;
1660         }
1661     } ## end elsif (from if(defined $remoteport))
1662
1663     # Unbuffer DB::OUT. We need to see responses right away.
1664     $OUT->autoflush(1);
1665
1666     # Line info goes to debugger output unless pointed elsewhere.
1667     # Pointing elsewhere makes it possible for slave editors to
1668     # keep track of file and position. We have both a filehandle
1669     # and a I/O description to keep track of.
1670     $LINEINFO = $OUT     unless defined $LINEINFO;
1671     $lineinfo = $console unless defined $lineinfo;
1672     # share($LINEINFO); # <- unable to share globs
1673     share($lineinfo);   #
1674
1675 =pod
1676
1677 To finish initialization, we show the debugger greeting,
1678 and then call the C<afterinit()> subroutine if there is one.
1679
1680 =cut
1681
1682     # Show the debugger greeting.
1683     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1684     unless ($runnonstop) {
1685         local $\ = '';
1686         local $, = '';
1687         if ( $term_pid eq '-1' ) {
1688             print $OUT "\nDaughter DB session started...\n";
1689         }
1690         else {
1691             print $OUT "\nLoading DB routines from $header\n";
1692             print $OUT (
1693                 "Editor support ",
1694                 $slave_editor ? "enabled" : "available", ".\n"
1695             );
1696             print $OUT
1697 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1698         } ## end else [ if ($term_pid eq '-1')
1699     } ## end unless ($runnonstop)
1700 } ## end else [ if ($notty)
1701
1702 # XXX This looks like a bug to me.
1703 # Why copy to @ARGS and then futz with @args?
1704 @ARGS = @ARGV;
1705 # for (@args) {
1706     # Make sure backslashes before single quotes are stripped out, and
1707     # keep args unless they are numeric (XXX why?)
1708     # s/\'/\\\'/g;                      # removed while not justified understandably
1709     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1710 # }
1711
1712 # If there was an afterinit() sub defined, call it. It will get
1713 # executed in our scope, so it can fiddle with debugger globals.
1714 if ( defined &afterinit ) {    # May be defined in $rcfile
1715     afterinit();
1716 }
1717
1718 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1719 use vars qw($I_m_init);
1720
1721 $I_m_init = 1;
1722
1723 ############################################################ Subroutines
1724
1725 =head1 SUBROUTINES
1726
1727 =head2 DB
1728
1729 This gigantic subroutine is the heart of the debugger. Called before every
1730 statement, its job is to determine if a breakpoint has been reached, and
1731 stop if so; read commands from the user, parse them, and execute
1732 them, and then send execution off to the next statement.
1733
1734 Note that the order in which the commands are processed is very important;
1735 some commands earlier in the loop will actually alter the C<$cmd> variable
1736 to create other commands to be executed later. This is all highly I<optimized>
1737 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1738 see what's happening in any given command.
1739
1740 =cut
1741
1742 use vars qw(
1743     $action
1744     %alias
1745     $cmd
1746     $fall_off_end
1747     $file
1748     $filename_ini
1749     $finished
1750     %had_breakpoints
1751     $level
1752     $max
1753     $package
1754     $rc
1755     $sh
1756     $try
1757     $end
1758 );
1759
1760 our (
1761     $doret,
1762     $incr,
1763     $laststep,
1764     $stack_depth,
1765     @stack,
1766     @to_watch,
1767     @old_watch,
1768 );
1769
1770 sub _DB__determine_if_we_should_break
1771 {
1772     # if we have something here, see if we should break.
1773     # $stop is lexical and local to this block - $action on the other hand
1774     # is global.
1775     my $stop;
1776
1777     if ( $dbline{$line}
1778         && _is_breakpoint_enabled($filename, $line)
1779         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1780     {
1781
1782         # Stop if the stop criterion says to just stop.
1783         if ( $stop eq '1' ) {
1784             $signal |= 1;
1785         }
1786
1787         # It's a conditional stop; eval it in the user's context and
1788         # see if we should stop. If so, remove the one-time sigil.
1789         elsif ($stop) {
1790             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1791             &eval;
1792             # If the breakpoint is temporary, then delete its enabled status.
1793             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1794                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1795             }
1796         }
1797     } ## end if ($dbline{$line} && ...
1798 }
1799
1800 sub _DB__is_finished {
1801     if ($finished and $level <= 1) {
1802         end_report();
1803         return 1;
1804     }
1805     else {
1806         return;
1807     }
1808 }
1809
1810 sub _DB__read_next_cmd
1811 {
1812     my ($tid) = @_;
1813
1814     # We have a terminal, or can get one ...
1815     if (!$term) {
1816         setterm();
1817     }
1818
1819     # ... and it belogs to this PID or we get one for this PID ...
1820     if ($term_pid != $$) {
1821         resetterm(1);
1822     }
1823
1824     # ... and we got a line of command input ...
1825     $cmd = DB::readline(
1826         "$pidprompt $tid DB"
1827         . ( '<' x $level )
1828         . ( $#hist + 1 )
1829         . ( '>' x $level ) . " "
1830     );
1831
1832     return defined($cmd);
1833 }
1834
1835 sub _DB__trim_command_and_return_first_component {
1836     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1837     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1838
1839     $cmd =~ m{\A(\S*)};
1840     return $1;
1841 }
1842
1843 sub _DB__handle_f_command {
1844     if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
1845         $file =~ s/\s+$//;
1846
1847         # help for no arguments (old-style was return from sub).
1848         if ( !$file ) {
1849             print $OUT
1850             "The old f command is now the r command.\n";    # hint
1851             print $OUT "The new f command switches filenames.\n";
1852             next CMD;
1853         } ## end if (!$file)
1854
1855         # if not in magic file list, try a close match.
1856         if ( !defined $main::{ '_<' . $file } ) {
1857             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1858                 {
1859                     $try = substr( $try, 2 );
1860                     print $OUT "Choosing $try matching '$file':\n";
1861                     $file = $try;
1862                 }
1863             } ## end if (($try) = grep(m#^_<.*$file#...
1864         } ## end if (!defined $main::{ ...
1865
1866         # If not successfully switched now, we failed.
1867         if ( !defined $main::{ '_<' . $file } ) {
1868             print $OUT "No file matching '$file' is loaded.\n";
1869             next CMD;
1870         }
1871
1872         # We switched, so switch the debugger internals around.
1873         elsif ( $file ne $filename ) {
1874             *dbline   = $main::{ '_<' . $file };
1875             $max      = $#dbline;
1876             $filename = $file;
1877             $start    = 1;
1878             $cmd      = "l";
1879         } ## end elsif ($file ne $filename)
1880
1881         # We didn't switch; say we didn't.
1882         else {
1883             print $OUT "Already in $file.\n";
1884             next CMD;
1885         }
1886     }
1887
1888     return;
1889 }
1890
1891 sub _DB__handle_dot_command {
1892     my ($obj) = @_;
1893
1894     # . command.
1895     if ($cmd eq '.') {
1896         $incr = -1;    # stay at current line
1897
1898         # Reset everything to the old location.
1899         $start    = $line;
1900         $filename = $filename_ini;
1901         *dbline   = $main::{ '_<' . $filename };
1902         $max      = $#dbline;
1903
1904         # Now where are we?
1905         print_lineinfo($obj->position());
1906         next CMD;
1907     }
1908
1909     return;
1910 }
1911
1912 sub _DB__handle_y_command {
1913     my ($obj) = @_;
1914
1915     if (my ($match_level, $match_vars)
1916         = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
1917
1918         # See if we've got the necessary support.
1919         eval { require PadWalker; PadWalker->VERSION(0.08) }
1920             or &warn(
1921             $@ =~ /locate/
1922             ? "PadWalker module not found - please install\n"
1923             : $@
1924         )
1925             and next CMD;
1926
1927         # Load up dumpvar if we don't have it. If we can, that is.
1928         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1929         defined &main::dumpvar
1930             or print $OUT "dumpvar.pl not available.\n"
1931             and next CMD;
1932
1933         # Got all the modules we need. Find them and print them.
1934         my @vars = split( ' ', $match_vars || '' );
1935
1936         # Find the pad.
1937         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
1938
1939         # Oops. Can't find it.
1940         $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
1941
1942         # Show the desired vars with dumplex().
1943         my $savout = select($OUT);
1944
1945         # Have dumplex dump the lexicals.
1946         dumpvar::dumplex( $_, $h->{$_},
1947             defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1948             @vars )
1949         for sort keys %$h;
1950         select($savout);
1951         next CMD;
1952     }
1953 }
1954
1955 sub _DB__handle_c_command {
1956     my ($obj) = @_;
1957
1958     if (my ($new_i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
1959
1960         $obj->i_cmd($new_i);
1961
1962         # Hey, show's over. The debugged program finished
1963         # executing already.
1964         next CMD if _DB__is_finished();
1965
1966         # Capture the place to put a one-time break.
1967         $subname = $obj->i_cmd;
1968
1969         #  Probably not needed, since we finish an interactive
1970         #  sub-session anyway...
1971         # local $filename = $filename;
1972         # local *dbline = *dbline; # XXX Would this work?!
1973         #
1974         # The above question wonders if localizing the alias
1975         # to the magic array works or not. Since it's commented
1976         # out, we'll just leave that to speculation for now.
1977
1978         # If the "subname" isn't all digits, we'll assume it
1979         # is a subroutine name, and try to find it.
1980         if ( $subname =~ /\D/ ) {    # subroutine name
1981             # Qualify it to the current package unless it's
1982             # already qualified.
1983             $subname = $package . "::" . $subname
1984             unless $subname =~ /::/;
1985
1986             # find_sub will return "file:line_number" corresponding
1987             # to where the subroutine is defined; we call find_sub,
1988             # break up the return value, and assign it in one
1989             # operation.
1990             ( $file, $new_i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
1991
1992             # Force the line number to be numeric.
1993             $obj->i_cmd($new_i + 0);
1994
1995             # If we got a line number, we found the sub.
1996             if ($obj->i_cmd) {
1997
1998                 # Switch all the debugger's internals around so
1999                 # we're actually working with that file.
2000                 $filename = $file;
2001                 *dbline   = $main::{ '_<' . $filename };
2002
2003                 # Mark that there's a breakpoint in this file.
2004                 $had_breakpoints{$filename} |= 1;
2005
2006                 # Scan forward to the first executable line
2007                 # after the 'sub whatever' line.
2008                 $max = $#dbline;
2009                 my $ii = $obj->i_cmd;
2010                 ++$ii while $dbline[$ii] == 0 && $ii < $max;
2011                 $obj->i_cmd($ii);
2012             } ## end if ($i)
2013
2014             # We didn't find a sub by that name.
2015             else {
2016                 print $OUT "Subroutine $subname not found.\n";
2017                 next CMD;
2018             }
2019         } ## end if ($subname =~ /\D/)
2020
2021         # At this point, either the subname was all digits (an
2022         # absolute line-break request) or we've scanned through
2023         # the code following the definition of the sub, looking
2024         # for an executable, which we may or may not have found.
2025         #
2026         # If $i (which we set $subname from) is non-zero, we
2027         # got a request to break at some line somewhere. On
2028         # one hand, if there wasn't any real subroutine name
2029         # involved, this will be a request to break in the current
2030         # file at the specified line, so we have to check to make
2031         # sure that the line specified really is breakable.
2032         #
2033         # On the other hand, if there was a subname supplied, the
2034         # preceding block has moved us to the proper file and
2035         # location within that file, and then scanned forward
2036         # looking for the next executable line. We have to make
2037         # sure that one was found.
2038         #
2039         # On the gripping hand, we can't do anything unless the
2040         # current value of $i points to a valid breakable line.
2041         # Check that.
2042         if ($obj->i_cmd) {
2043
2044             # Breakable?
2045             if ( $dbline[$obj->i_cmd] == 0 ) {
2046                 print $OUT "Line " . $obj->i_cmd . " not breakable.\n";
2047                 next CMD;
2048             }
2049
2050             # Yes. Set up the one-time-break sigil.
2051             $dbline{$obj->i_cmd} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2052             _enable_breakpoint_temp_enabled_status($filename, $obj->i_cmd);
2053         } ## end if ($i)
2054
2055         # Turn off stack tracing from here up.
2056         for my $i (0 .. $stack_depth) {
2057             $stack[ $i ] &= ~1;
2058         }
2059         last CMD;
2060     }
2061
2062     return;
2063 }
2064
2065 sub DB {
2066
2067     # lock the debugger and get the thread id for the prompt
2068     lock($DBGR);
2069     my $tid;
2070     my $position;
2071     my ($prefix, $after, $infix);
2072     my $pat;
2073     my $explicit_stop;
2074
2075     if ($ENV{PERL5DB_THREADED}) {
2076         $tid = eval { "[".threads->tid."]" };
2077     }
2078
2079     my $i;
2080
2081     my $obj = DB::Obj->new(
2082         {
2083             position => \$position,
2084             prefix => \$prefix,
2085             after => \$after,
2086             explicit_stop => \$explicit_stop,
2087             infix => \$infix,
2088             i_cmd => \$i,
2089         },
2090     );
2091
2092     $obj->_DB_on_init__initialize_globals(@_);
2093
2094     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2095     # The code being debugged may have altered them.
2096     &save;
2097
2098     # Since DB::DB gets called after every line, we can use caller() to
2099     # figure out where we last were executing. Sneaky, eh? This works because
2100     # caller is returning all the extra information when called from the
2101     # debugger.
2102     local ( $package, $filename, $line ) = caller;
2103     $filename_ini = $filename;
2104
2105     # set up the context for DB::eval, so it can properly execute
2106     # code on behalf of the user. We add the package in so that the
2107     # code is eval'ed in the proper package (not in the debugger!).
2108     local $usercontext = _calc_usercontext($package);
2109
2110     # Create an alias to the active file magical array to simplify
2111     # the code here.
2112     local (*dbline) = $main::{ '_<' . $filename };
2113
2114     # Last line in the program.
2115     $max = $#dbline;
2116
2117     _DB__determine_if_we_should_break(@_);
2118
2119     # Preserve the current stop-or-not, and see if any of the W
2120     # (watch expressions) has changed.
2121     my $was_signal = $signal;
2122
2123     # If we have any watch expressions ...
2124     $obj->_DB__handle_watch_expressions(@_);
2125
2126 =head2 C<watchfunction()>
2127
2128 C<watchfunction()> is a function that can be defined by the user; it is a
2129 function which will be run on each entry to C<DB::DB>; it gets the
2130 current package, filename, and line as its parameters.
2131
2132 The watchfunction can do anything it likes; it is executing in the
2133 debugger's context, so it has access to all of the debugger's internal
2134 data structures and functions.
2135
2136 C<watchfunction()> can control the debugger's actions. Any of the following
2137 will cause the debugger to return control to the user's program after
2138 C<watchfunction()> executes:
2139
2140 =over 4
2141
2142 =item *
2143
2144 Returning a false value from the C<watchfunction()> itself.
2145
2146 =item *
2147
2148 Altering C<$single> to a false value.
2149
2150 =item *
2151
2152 Altering C<$signal> to a false value.
2153
2154 =item *
2155
2156 Turning off the C<4> bit in C<$trace> (this also disables the
2157 check for C<watchfunction()>. This can be done with
2158
2159     $trace &= ~4;
2160
2161 =back
2162
2163 =cut
2164
2165     # If there's a user-defined DB::watchfunction, call it with the
2166     # current package, filename, and line. The function executes in
2167     # the DB:: package.
2168     if ( $trace & 4 ) {    # User-installed watch
2169         return
2170           if watchfunction( $package, $filename, $line )
2171           and not $single
2172           and not $was_signal
2173           and not( $trace & ~4 );
2174     } ## end if ($trace & 4)
2175
2176     # Pick up any alteration to $signal in the watchfunction, and
2177     # turn off the signal now.
2178     $was_signal = $signal;
2179     $signal     = 0;
2180
2181 =head2 GETTING READY TO EXECUTE COMMANDS
2182
2183 The debugger decides to take control if single-step mode is on, the
2184 C<t> command was entered, or the user generated a signal. If the program
2185 has fallen off the end, we set things up so that entering further commands
2186 won't cause trouble, and we say that the program is over.
2187
2188 =cut
2189
2190     # Make sure that we always print if asked for explicitly regardless
2191     # of $trace_to_depth .
2192     $explicit_stop = ($single || $was_signal);
2193
2194     # Check to see if we should grab control ($single true,
2195     # trace set appropriately, or we got a signal).
2196     if ( $explicit_stop || ( $trace & 1 ) ) {
2197         $obj->_DB__grab_control(@_);
2198     } ## end if ($single || ($trace...
2199
2200 =pod
2201
2202 If there's an action to be executed for the line we stopped at, execute it.
2203 If there are any preprompt actions, execute those as well.
2204
2205 =cut
2206
2207     # If there's an action, do it now.
2208     if ($action) {
2209         $evalarg = $action;
2210         DB::eval();
2211     }
2212
2213     # Are we nested another level (e.g., did we evaluate a function
2214     # that had a breakpoint in it at the debugger prompt)?
2215     if ( $single || $was_signal ) {
2216
2217         # Yes, go down a level.
2218         local $level = $level + 1;
2219
2220         # Do any pre-prompt actions.
2221         foreach $evalarg (@$pre) {
2222             DB::eval();
2223         }
2224
2225         # Complain about too much recursion if we passed the limit.
2226         if ($single & 4) {
2227             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2228         }
2229
2230         # The line we're currently on. Set $incr to -1 to stay here
2231         # until we get a command that tells us to advance.
2232         $start = $line;
2233         $incr  = -1;      # for backward motion.
2234
2235         # Tack preprompt debugger actions ahead of any actual input.
2236         @typeahead = ( @$pretype, @typeahead );
2237
2238 =head2 WHERE ARE WE?
2239
2240 XXX Relocate this section?
2241
2242 The debugger normally shows the line corresponding to the current line of
2243 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2244 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2245
2246 C<$incr> controls by how many lines the I<current> line should move forward
2247 after a command is executed. If set to -1, this indicates that the I<current>
2248 line shouldn't change.
2249
2250 C<$start> is the I<current> line. It is used for things like knowing where to
2251 move forwards or backwards from when doing an C<L> or C<-> command.
2252
2253 C<$max> tells the debugger where the last line of the current file is. It's
2254 used to terminate loops most often.
2255
2256 =head2 THE COMMAND LOOP
2257
2258 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2259 in two parts:
2260
2261 =over 4
2262
2263 =item *
2264
2265 The outer part of the loop, starting at the C<CMD> label. This loop
2266 reads a command and then executes it.
2267
2268 =item *
2269
2270 The inner part of the loop, starting at the C<PIPE> label. This part
2271 is wholly contained inside the C<CMD> block and only executes a command.
2272 Used to handle commands running inside a pager.
2273
2274 =back
2275
2276 So why have two labels to restart the loop? Because sometimes, it's easier to
2277 have a command I<generate> another command and then re-execute the loop to do
2278 the new command. This is faster, but perhaps a bit more convoluted.
2279
2280 =cut
2281
2282         # The big command dispatch loop. It keeps running until the
2283         # user yields up control again.
2284         #
2285         # If we have a terminal for input, and we get something back
2286         # from readline(), keep on processing.
2287         my $piped;
2288         my $selected;
2289
2290       CMD:
2291         while (_DB__read_next_cmd($tid))
2292         {
2293
2294             share($cmd);
2295             # ... try to execute the input as debugger commands.
2296
2297             # Don't stop running.
2298             $single = 0;
2299
2300             # No signal is active.
2301             $signal = 0;
2302
2303             # Handle continued commands (ending with \):
2304             if ($cmd =~ s/\\\z/\n/) {
2305                 $cmd .= DB::readline("  cont: ");
2306                 redo CMD;
2307             }
2308
2309 =head4 The null command
2310
2311 A newline entered by itself means I<re-execute the last command>. We grab the
2312 command out of C<$laststep> (where it was recorded previously), and copy it
2313 back into C<$cmd> to be executed below. If there wasn't any previous command,
2314 we'll do nothing below (no command will match). If there was, we also save it
2315 in the command history and fall through to allow the command parsing to pick
2316 it up.
2317
2318 =cut
2319
2320             # Empty input means repeat the last command.
2321             if ($cmd eq '') {
2322                 $cmd = $laststep;
2323             }
2324             chomp($cmd);    # get rid of the annoying extra newline
2325             if (length($cmd) >= 2) {
2326                 push( @hist, $cmd );
2327             }
2328             push( @truehist, $cmd );
2329             share(@hist);
2330             share(@truehist);
2331
2332             # This is a restart point for commands that didn't arrive
2333             # via direct user input. It allows us to 'redo PIPE' to
2334             # re-execute command processing without reading a new command.
2335           PIPE: {
2336                 $i = _DB__trim_command_and_return_first_component();
2337
2338 =head3 COMMAND ALIASES
2339
2340 The debugger can create aliases for commands (these are stored in the
2341 C<%alias> hash). Before a command is executed, the command loop looks it up
2342 in the alias hash and substitutes the contents of the alias for the command,
2343 completely replacing it.
2344
2345 =cut
2346
2347                 # See if there's an alias for the command, and set it up if so.
2348                 if ( $alias{$i} ) {
2349
2350                     # Squelch signal handling; we want to keep control here
2351                     # if something goes loco during the alias eval.
2352                     local $SIG{__DIE__};
2353                     local $SIG{__WARN__};
2354
2355                     # This is a command, so we eval it in the DEBUGGER's
2356                     # scope! Otherwise, we can't see the special debugger
2357                     # variables, or get to the debugger's subs. (Well, we
2358                     # _could_, but why make it even more complicated?)
2359                     eval "\$cmd =~ $alias{$i}";
2360                     if ($@) {
2361                         local $\ = '';
2362                         print $OUT "Couldn't evaluate '$i' alias: $@";
2363                         next CMD;
2364                     }
2365                 } ## end if ($alias{$i})
2366
2367 =head3 MAIN-LINE COMMANDS
2368
2369 All of these commands work up to and after the program being debugged has
2370 terminated.
2371
2372 =head4 C<q> - quit
2373
2374 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2375 try to execute further, cleaning any restart-related stuff out of the
2376 environment, and executing with the last value of C<$?>.
2377
2378 =cut
2379
2380                 if ($cmd eq 'q') {
2381                     $fall_off_end = 1;
2382                     clean_ENV();
2383                     exit $?;
2384                 }
2385
2386 =head4 C<t> - trace [n]
2387
2388 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2389 If level is specified, set C<$trace_to_depth>.
2390
2391 =cut
2392
2393                 $obj->_handle_t_command;
2394
2395 =head4 C<S> - list subroutines matching/not matching a pattern
2396
2397 Walks through C<%sub>, checking to see whether or not to print the name.
2398
2399 =cut
2400
2401                 $obj->_handle_S_command;
2402
2403 =head4 C<X> - list variables in current package
2404
2405 Since the C<V> command actually processes this, just change this to the
2406 appropriate C<V> command and fall through.
2407
2408 =head4 C<V> - list variables
2409
2410 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2411
2412 =cut
2413
2414                 $obj->_handle_V_command_and_X_command;
2415
2416 =head4 C<x> - evaluate and print an expression
2417
2418 Hands the expression off to C<DB::eval>, setting it up to print the value
2419 via C<dumpvar.pl> instead of just printing it directly.
2420
2421 =cut
2422
2423                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2424                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2425
2426                     # handle special  "x 3 blah" syntax XXX propagate
2427                     # doc back to special variables.
2428                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2429                         $onetimedumpDepth = $1;
2430                     }
2431                 }
2432
2433 =head4 C<m> - print methods
2434
2435 Just uses C<DB::methods> to determine what methods are available.
2436
2437 =cut
2438
2439                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2440                     methods($1);
2441                     next CMD;
2442                 }
2443
2444                 # m expr - set up DB::eval to do the work
2445                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2446                     $onetimeDump = 'methods';   #  method output gets used there
2447                 }
2448
2449 =head4 C<f> - switch files
2450
2451 =cut
2452
2453                 _DB__handle_f_command();
2454
2455 =head4 C<.> - return to last-executed line.
2456
2457 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2458 and then we look up the line in the magical C<%dbline> hash.
2459
2460 =cut
2461
2462         _DB__handle_dot_command($obj);
2463
2464 =head4 C<-> - back one window
2465
2466 We change C<$start> to be one window back; if we go back past the first line,
2467 we set it to be the first line. We ser C<$incr> to put us back at the
2468 currently-executing line, and then put a C<l $start +> (list one window from
2469 C<$start>) in C<$cmd> to be executed later.
2470
2471 =cut
2472
2473                 # - - back a window.
2474                 $obj->_handle_dash_command;
2475
2476 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2477
2478 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2479 problems, most notably that the default case of several commands destroying
2480 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2481 retain the old commands for those who were used to using them or who preferred
2482 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2483 deal with them instead of processing them in-line.
2484
2485 =cut
2486
2487                 # All of these commands were remapped in perl 5.8.0;
2488                 # we send them off to the secondary dispatcher (see below).
2489                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2490                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2491                     next CMD;
2492                 }
2493
2494 =head4 C<y> - List lexicals in higher scope
2495
2496 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2497 above the current one and then displays then using C<dumpvar.pl>.
2498
2499 =cut
2500
2501                 _DB__handle_y_command($obj);
2502
2503 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2504
2505 All of the commands below this point don't work after the program being
2506 debugged has ended. All of them check to see if the program has ended; this
2507 allows the commands to be relocated without worrying about a 'line of
2508 demarcation' above which commands can be entered anytime, and below which
2509 they can't.
2510
2511 =head4 C<n> - single step, but don't trace down into subs
2512
2513 Done by setting C<$single> to 2, which forces subs to execute straight through
2514 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2515 so a null command knows what to re-execute.
2516
2517 =cut
2518
2519                 # n - next
2520                 $obj->_handle_n_command;
2521
2522 =head4 C<s> - single-step, entering subs
2523
2524 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2525 subs. Also saves C<s> as C<$lastcmd>.
2526
2527 =cut
2528
2529                 $obj->_handle_s_command;
2530
2531 =head4 C<c> - run continuously, setting an optional breakpoint
2532
2533 Most of the code for this command is taken up with locating the optional
2534 breakpoint, which is either a subroutine name or a line number. We set
2535 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2536 in this and all call levels above this one.
2537
2538 =cut
2539
2540                 # c - start continuous execution.
2541                 _DB__handle_c_command($obj);
2542
2543 =head4 C<r> - return from a subroutine
2544
2545 For C<r> to work properly, the debugger has to stop execution again
2546 immediately after the return is executed. This is done by forcing
2547 single-stepping to be on in the call level above the current one. If
2548 we are printing return values when a C<r> is executed, set C<$doret>
2549 appropriately, and force us out of the command loop.
2550
2551 =cut
2552
2553                 # r - return from the current subroutine.
2554                 $obj->_handle_r_command;
2555
2556 =head4 C<T> - stack trace
2557
2558 Just calls C<DB::print_trace>.
2559
2560 =cut
2561
2562                 $obj->_handle_T_command;
2563
2564 =head4 C<w> - List window around current line.
2565
2566 Just calls C<DB::cmd_w>.
2567
2568 =cut
2569
2570                 $obj->_handle_w_command;
2571
2572 =head4 C<W> - watch-expression processing.
2573
2574 Just calls C<DB::cmd_W>.
2575
2576 =cut
2577
2578                 $obj->_handle_W_command;
2579
2580 =head4 C</> - search forward for a string in the source
2581
2582 We take the argument and treat it as a pattern. If it turns out to be a
2583 bad one, we return the error we got from trying to C<eval> it and exit.
2584 If not, we create some code to do the search and C<eval> it so it can't
2585 mess us up.
2586
2587 =cut
2588
2589                 # The pattern as a string.
2590                 use vars qw($inpat);
2591
2592                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2593
2594                     # Remove the final slash.
2595                     $inpat =~ s:([^\\])/$:$1:;
2596
2597                     # If the pattern isn't null ...
2598                     if ( $inpat ne "" ) {
2599
2600                         # Turn of warn and die procesing for a bit.
2601                         local $SIG{__DIE__};
2602                         local $SIG{__WARN__};
2603
2604                         # Create the pattern.
2605                         eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2606                         if ( $@ ne "" ) {
2607
2608                             # Oops. Bad pattern. No biscuit.
2609                             # Print the eval error and go back for more
2610                             # commands.
2611                             print $OUT "$@";
2612                             next CMD;
2613                         }
2614                         $pat = $inpat;
2615                     } ## end if ($inpat ne "")
2616
2617                     # Set up to stop on wrap-around.
2618                     $end = $start;
2619
2620                     # Don't move off the current line.
2621                     $incr = -1;
2622
2623                     # Done in eval so nothing breaks if the pattern
2624                     # does something weird.
2625                     eval '
2626                         no strict q/vars/;
2627                         for (;;) {
2628                             # Move ahead one line.
2629                             ++$start;
2630
2631                             # Wrap if we pass the last line.
2632                             $start = 1 if ($start > $max);
2633
2634                             # Stop if we have gotten back to this line again,
2635                             last if ($start == $end);
2636
2637                             # A hit! (Note, though, that we are doing
2638                             # case-insensitive matching. Maybe a qr//
2639                             # expression would be better, so the user could
2640                             # do case-sensitive matching if desired.
2641                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2642                                 if ($slave_editor) {
2643                                     # Handle proper escaping in the slave.
2644                                     print $OUT "\032\032$filename:$start:0\n";
2645                                 }
2646                                 else {
2647                                     # Just print the line normally.
2648                                     print $OUT "$start:\t",$dbline[$start],"\n";
2649                                 }
2650                                 # And quit since we found something.
2651                                 last;
2652                             }
2653                          } ';
2654
2655                     # If we wrapped, there never was a match.
2656                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2657                     next CMD;
2658                 }
2659
2660 =head4 C<?> - search backward for a string in the source
2661
2662 Same as for C</>, except the loop runs backwards.
2663
2664 =cut
2665
2666                 # ? - backward pattern search.
2667                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2668
2669                     # Get the pattern, remove trailing question mark.
2670                     $inpat =~ s:([^\\])\?$:$1:;
2671
2672                     # If we've got one ...
2673                     if ( $inpat ne "" ) {
2674
2675                         # Turn off die & warn handlers.
2676                         local $SIG{__DIE__};
2677                         local $SIG{__WARN__};
2678                         eval '$inpat =~ m' . "\a$inpat\a";
2679
2680                         if ( $@ ne "" ) {
2681
2682                             # Ouch. Not good. Print the error.
2683                             print $OUT $@;
2684                             next CMD;
2685                         }
2686                         $pat = $inpat;
2687                     } ## end if ($inpat ne "")
2688
2689                     # Where we are now is where to stop after wraparound.
2690                     $end = $start;
2691
2692                     # Don't move away from this line.
2693                     $incr = -1;
2694
2695                     # Search inside the eval to prevent pattern badness
2696                     # from killing us.
2697                     eval '
2698                         no strict q/vars/;
2699                         for (;;) {
2700                             # Back up a line.
2701                             --$start;
2702
2703                             # Wrap if we pass the first line.
2704
2705                             $start = $max if ($start <= 0);
2706
2707                             # Quit if we get back where we started,
2708                             last if ($start == $end);
2709
2710                             # Match?
2711                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2712                                 if ($slave_editor) {
2713                                     # Yep, follow slave editor requirements.
2714                                     print $OUT "\032\032$filename:$start:0\n";
2715                                 }
2716                                 else {
2717                                     # Yep, just print normally.
2718                                     print $OUT "$start:\t",$dbline[$start],"\n";
2719                                 }
2720
2721                                 # Found, so done.
2722                                 last;
2723                             }
2724                         } ';
2725
2726                     # Say we failed if the loop never found anything,
2727                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2728                     next CMD;
2729                 }
2730
2731 =head4 C<$rc> - Recall command
2732
2733 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2734 that the terminal supports history). It find the the command required, puts it
2735 into C<$cmd>, and redoes the loop to execute it.
2736
2737 =cut
2738
2739                 # $rc - recall command.
2740                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2741
2742                     # No arguments, take one thing off history.
2743                     pop(@hist) if length($cmd) > 1;
2744
2745                     # Relative (- found)?
2746                     #  Y - index back from most recent (by 1 if bare minus)
2747                     #  N - go to that particular command slot or the last
2748                     #      thing if nothing following.
2749                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2750
2751                     # Pick out the command desired.
2752                     $cmd = $hist[$i];
2753
2754                     # Print the command to be executed and restart the loop
2755                     # with that command in the buffer.
2756                     print $OUT $cmd, "\n";
2757                     redo CMD;
2758                 }
2759
2760 =head4 C<$sh$sh> - C<system()> command
2761
2762 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2763 C<STDOUT> from getting messed up.
2764
2765 =cut
2766
2767                 # $sh$sh - run a shell command (if it's all ASCII).
2768                 # Can't run shell commands with Unicode in the debugger, hmm.
2769                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2770
2771                     # System it.
2772                     &system($arg);
2773                     next CMD;
2774                 }
2775
2776 =head4 C<$rc I<pattern> $rc> - Search command history
2777
2778 Another command to manipulate C<@hist>: this one searches it with a pattern.
2779 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2780
2781 =cut
2782
2783                 # $rc pattern $rc - find a command in the history.
2784                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2785
2786                     # Create the pattern to use.
2787                     $pat = "^$arg";
2788
2789                     # Toss off last entry if length is >1 (and it always is).
2790                     pop(@hist) if length($cmd) > 1;
2791
2792                     # Look backward through the history.
2793                     for ( $i = $#hist ; $i ; --$i ) {
2794                         # Stop if we find it.
2795                         last if $hist[$i] =~ /$pat/;
2796                     }
2797
2798                     if ( !$i ) {
2799
2800                         # Never found it.
2801                         print $OUT "No such command!\n\n";
2802                         next CMD;
2803                     }
2804
2805                     # Found it. Put it in the buffer, print it, and process it.
2806                     $cmd = $hist[$i];
2807                     print $OUT $cmd, "\n";
2808                     redo CMD;
2809                 }
2810
2811 =head4 C<$sh> - Invoke a shell
2812
2813 Uses C<DB::system> to invoke a shell.
2814
2815 =cut
2816
2817                 # $sh - start a shell.
2818                 if ($cmd =~ /\A$sh\z/) {
2819
2820                     # Run the user's shell. If none defined, run Bourne.
2821                     # We resume execution when the shell terminates.
2822                     &system( $ENV{SHELL} || "/bin/sh" );
2823                     next CMD;
2824                 }
2825
2826 =head4 C<$sh I<command>> - Force execution of a command in a shell
2827
2828 Like the above, but the command is passed to the shell. Again, we use
2829 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2830
2831 =cut
2832
2833                 # $sh command - start a shell and run a command in it.
2834                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
2835
2836                     # XXX: using csh or tcsh destroys sigint retvals!
2837                     #&system($1);  # use this instead
2838
2839                     # use the user's shell, or Bourne if none defined.
2840                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
2841                     next CMD;
2842                 }
2843
2844 =head4 C<H> - display commands in history
2845
2846 Prints the contents of C<@hist> (if any).
2847
2848 =cut
2849
2850                 if ($cmd =~ /\AH\b\s*\*/) {
2851                     @hist = @truehist = ();
2852                     print $OUT "History cleansed\n";
2853                     next CMD;
2854                 }
2855
2856                 if (my ($num)
2857                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
2858
2859                     # Anything other than negative numbers is ignored by
2860                     # the (incorrect) pattern, so this test does nothing.
2861                     $end = $num ? ( $#hist - $num ) : 0;
2862
2863                     # Set to the minimum if less than zero.
2864                     $hist = 0 if $hist < 0;
2865
2866                     # Start at the end of the array.
2867                     # Stay in while we're still above the ending value.
2868                     # Tick back by one each time around the loop.
2869                     for ( $i = $#hist ; $i > $end ; $i-- ) {
2870
2871                         # Print the command  unless it has no arguments.
2872                         print $OUT "$i: ", $hist[$i], "\n"
2873                           unless $hist[$i] =~ /^.?$/;
2874                     }
2875                     next CMD;
2876                 }
2877
2878 =head4 C<man, doc, perldoc> - look up documentation
2879
2880 Just calls C<runman()> to print the appropriate document.
2881
2882 =cut
2883
2884                 # man, perldoc, doc - show manual pages.
2885                 if (my ($man_page)
2886                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
2887                     runman($man_page);
2888                     next CMD;
2889                 }
2890
2891 =head4 C<p> - print
2892
2893 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2894 the bottom of the loop.
2895
2896 =cut
2897
2898                 my $print_cmd = 'print {$DB::OUT} ';
2899                 # p - print (no args): print $_.
2900                 if ($cmd eq 'p') {
2901                     $cmd = $print_cmd . '$_';
2902                 }
2903
2904                 # p - print the given expression.
2905                 $cmd =~ s/\Ap\b/$print_cmd /;
2906
2907 =head4 C<=> - define command alias
2908
2909 Manipulates C<%alias> to add or list command aliases.
2910
2911 =cut
2912
2913                 # = - set up a command alias.
2914                 if ($cmd =~ s/\A=\s*//) {
2915                     my @keys;
2916                     if ( length $cmd == 0 ) {
2917
2918                         # No args, get current aliases.
2919                         @keys = sort keys %alias;
2920                     }
2921                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
2922
2923                         # Creating a new alias. $k is alias name, $v is
2924                         # alias value.
2925
2926                         # can't use $_ or kill //g state
2927                         for my $x ( $k, $v ) {
2928
2929                             # Escape "alarm" characters.
2930                             $x =~ s/\a/\\a/g;
2931                         }
2932
2933                         # Substitute key for value, using alarm chars
2934                         # as separators (which is why we escaped them in
2935                         # the command).
2936                         $alias{$k} = "s\a$k\a$v\a";
2937
2938                         # Turn off standard warn and die behavior.
2939                         local $SIG{__DIE__};
2940                         local $SIG{__WARN__};
2941
2942                         # Is it valid Perl?
2943                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
2944
2945                             # Nope. Bad alias. Say so and get out.
2946                             print $OUT "Can't alias $k to $v: $@\n";
2947                             delete $alias{$k};
2948                             next CMD;
2949                         }
2950
2951                         # We'll only list the new one.
2952                         @keys = ($k);
2953                     } ## end elsif (my ($k, $v) = ($cmd...
2954
2955                     # The argument is the alias to list.
2956                     else {
2957                         @keys = ($cmd);
2958                     }
2959
2960                     # List aliases.
2961                     for my $k (@keys) {
2962
2963                         # Messy metaquoting: Trim the substitution code off.
2964                         # We use control-G as the delimiter because it's not
2965                         # likely to appear in the alias.
2966                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
2967
2968                             # Print the alias.
2969                             print $OUT "$k\t= $1\n";
2970                         }
2971                         elsif ( defined $alias{$k} ) {
2972
2973                             # Couldn't trim it off; just print the alias code.
2974                             print $OUT "$k\t$alias{$k}\n";
2975                         }
2976                         else {
2977
2978                             # No such, dude.
2979                             print "No alias for $k\n";
2980                         }
2981                     } ## end for my $k (@keys)
2982                     next CMD;
2983                 }
2984
2985 =head4 C<source> - read commands from a file.
2986
2987 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
2988 pick it up.
2989
2990 =cut
2991
2992                 # source - read commands from a file (or pipe!) and execute.
2993                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
2994                     if ( open my $fh, $sourced_fn ) {
2995
2996                         # Opened OK; stick it in the list of file handles.
2997                         push @cmdfhs, $fh;
2998                     }
2999                     else {
3000
3001                         # Couldn't open it.
3002                         &warn("Can't execute '$sourced_fn': $!\n");
3003                     }
3004                     next CMD;
3005                 }
3006
3007                 if (my ($which_cmd, $position)
3008                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3009
3010                     my ($fn, $line_num);
3011                     if ($position =~ m{\A\d+\z})
3012                     {
3013                         $fn = $filename;
3014                         $line_num = $position;
3015                     }
3016                     elsif (my ($new_fn, $new_line_num)
3017                         = $position =~ m{\A(.*):(\d+)\z}) {
3018                         ($fn, $line_num) = ($new_fn, $new_line_num);
3019                     }
3020                     else
3021                     {
3022                         &warn("Wrong spec for enable/disable argument.\n");
3023                     }
3024
3025                     if (defined($fn)) {
3026                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3027                             _set_breakpoint_enabled_status($fn, $line_num,
3028                                 ($which_cmd eq 'enable' ? 1 : '')
3029                             );
3030                         }
3031                         else {
3032                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3033                         }
3034                     }
3035
3036                     next CMD;
3037                 }
3038
3039 =head4 C<save> - send current history to a file
3040
3041 Takes the complete history, (not the shrunken version you see with C<H>),
3042 and saves it to the given filename, so it can be replayed using C<source>.
3043
3044 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3045
3046 =cut
3047
3048                 # save source - write commands to a file for later use
3049                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3050                     my $filename = $new_fn || '.perl5dbrc';    # default?
3051                     if ( open my $fh, '>', $filename ) {
3052
3053                        # chomp to remove extraneous newlines from source'd files
3054                         chomp( my @truelist =
3055                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3056                               @truehist );
3057                         print $fh join( "\n", @truelist );
3058                         print "commands saved in $file\n";
3059                     }
3060                     else {
3061                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3062                     }
3063                     next CMD;
3064                 }
3065
3066 =head4 C<R> - restart
3067
3068 Restart the debugger session.
3069
3070 =head4 C<rerun> - rerun the current session
3071
3072 Return to any given position in the B<true>-history list
3073
3074 =cut
3075
3076                 # R - restart execution.
3077                 # rerun - controlled restart execution.
3078                 if (my ($cmd_cmd, $cmd_params) =
3079                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3080                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3081
3082                     # Close all non-system fds for a clean restart.  A more
3083                     # correct method would be to close all fds that were not
3084                     # open when the process started, but this seems to be
3085                     # hard.  See "debugger 'R'estart and open database
3086                     # connections" on p5p.
3087
3088                     my $max_fd = 1024; # default if POSIX can't be loaded
3089                     if (eval { require POSIX }) {
3090                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3091                     }
3092
3093                     if (defined $max_fd) {
3094                         foreach ($^F+1 .. $max_fd-1) {
3095                             next unless open FD_TO_CLOSE, "<&=$_";
3096                             close(FD_TO_CLOSE);
3097                         }
3098                     }
3099
3100                     # And run Perl again.  We use exec() to keep the
3101                     # PID stable (and that way $ini_pids is still valid).
3102                     exec(@args) || print $OUT "exec failed: $!\n";
3103
3104                     last CMD;
3105                 }
3106
3107 =head4 C<|, ||> - pipe output through the pager.
3108
3109 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3110 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3111 pipe to the pager (restoring the output filehandles if this fails). If this
3112 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3113 set C<$signal>, sending us back into the debugger.
3114
3115 We then trim off the pipe symbols and C<redo> the command loop at the
3116 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3117 reading another.
3118
3119 =cut
3120
3121                 # || - run command in the pager, with output to DB::OUT.
3122                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3123                     if ( $pager =~ /^\|/ ) {
3124
3125                         # Default pager is into a pipe. Redirect I/O.
3126                         open( SAVEOUT, ">&STDOUT" )
3127                           || &warn("Can't save STDOUT");
3128                         open( STDOUT, ">&OUT" )
3129                           || &warn("Can't redirect STDOUT");
3130                     } ## end if ($pager =~ /^\|/)
3131                     else {
3132
3133                         # Not into a pipe. STDOUT is safe.
3134                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3135                     }
3136
3137                     # Fix up environment to record we have less if so.
3138                     fix_less();
3139
3140                     unless ( $piped = open( OUT, $pager ) ) {
3141
3142                         # Couldn't open pipe to pager.
3143                         &warn("Can't pipe output to '$pager'");
3144                         if ( $pager =~ /^\|/ ) {
3145
3146                             # Redirect I/O back again.
3147                             open( OUT, ">&STDOUT" )    # XXX: lost message
3148                               || &warn("Can't restore DB::OUT");
3149                             open( STDOUT, ">&SAVEOUT" )
3150                               || &warn("Can't restore STDOUT");
3151                             close(SAVEOUT);
3152                         } ## end if ($pager =~ /^\|/)
3153                         else {
3154
3155                             # Redirect I/O. STDOUT already safe.
3156                             open( OUT, ">&STDOUT" )    # XXX: lost message
3157                               || &warn("Can't restore DB::OUT");
3158                         }
3159                         next CMD;
3160                     } ## end unless ($piped = open(OUT,...
3161
3162                     # Set up broken-pipe handler if necessary.
3163                     $SIG{PIPE} = \&DB::catch
3164                       if $pager =~ /^\|/
3165                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3166
3167                     OUT->autoflush(1);
3168                     # Save current filehandle, and put it back.
3169                     $selected = select(OUT);
3170                     # Don't put it back if pager was a pipe.
3171                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3172
3173                     # Trim off the pipe symbols and run the command now.
3174                     $cmd =~ s#\A\|+\s*##;
3175                     redo PIPE;
3176                 }
3177
3178 =head3 END OF COMMAND PARSING
3179
3180 Anything left in C<$cmd> at this point is a Perl expression that we want to
3181 evaluate. We'll always evaluate in the user's context, and fully qualify
3182 any variables we might want to address in the C<DB> package.
3183
3184 =cut
3185
3186                 # t - turn trace on.
3187                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3188                     my $trace_arg = $1;
3189                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3190                 }
3191
3192                 # s - single-step. Remember the last command was 's'.
3193                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3194                     $laststep = 's';
3195                 }
3196
3197                 # n - single-step, but not into subs. Remember last command
3198                 # was 'n'.
3199                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3200                     $laststep = 'n';
3201                 }
3202
3203             }    # PIPE:
3204
3205             # Make sure the flag that says "the debugger's running" is
3206             # still on, to make sure we get control again.
3207             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3208
3209             # Run *our* eval that executes in the caller's context.
3210             DB::eval();
3211
3212             # Turn off the one-time-dump stuff now.
3213             if ($onetimeDump) {
3214                 $onetimeDump      = undef;
3215                 $onetimedumpDepth = undef;
3216             }
3217             elsif ( $term_pid == $$ ) {
3218                 eval { # May run under miniperl, when not available...
3219                     STDOUT->flush();
3220                     STDERR->flush();
3221                 };
3222
3223                 # XXX If this is the master pid, print a newline.
3224                 print {$OUT} "\n";
3225             }
3226         } ## end while (($term || &setterm...
3227
3228 =head3 POST-COMMAND PROCESSING
3229
3230 After each command, we check to see if the command output was piped anywhere.
3231 If so, we go through the necessary code to unhook the pipe and go back to
3232 our standard filehandles for input and output.
3233
3234 =cut
3235
3236         continue {    # CMD:
3237
3238             # At the end of every command:
3239             if ($piped) {
3240
3241                 # Unhook the pipe mechanism now.
3242                 if ( $pager =~ /^\|/ ) {
3243
3244                     # No error from the child.
3245                     $? = 0;
3246
3247                     # we cannot warn here: the handle is missing --tchrist
3248                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3249
3250                     # most of the $? crud was coping with broken cshisms
3251                     # $? is explicitly set to 0, so this never runs.
3252                     if ($?) {
3253                         print SAVEOUT "Pager '$pager' failed: ";
3254                         if ( $? == -1 ) {
3255                             print SAVEOUT "shell returned -1\n";
3256                         }
3257                         elsif ( $? >> 8 ) {
3258                             print SAVEOUT ( $? & 127 )
3259                               ? " (SIG#" . ( $? & 127 ) . ")"
3260                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3261                         }
3262                         else {
3263                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3264                         }
3265                     } ## end if ($?)
3266
3267                     # Reopen filehandle for our output (if we can) and
3268                     # restore STDOUT (if we can).
3269                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3270                     open( STDOUT, ">&SAVEOUT" )
3271                       || &warn("Can't restore STDOUT");
3272
3273                     # Turn off pipe exception handler if necessary.
3274                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3275
3276                     # Will stop ignoring SIGPIPE if done like nohup(1)
3277                     # does SIGINT but Perl doesn't give us a choice.
3278                 } ## end if ($pager =~ /^\|/)
3279                 else {
3280
3281                     # Non-piped "pager". Just restore STDOUT.
3282                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3283                 }
3284
3285                 # Close filehandle pager was using, restore the normal one
3286                 # if necessary,
3287                 close(SAVEOUT);
3288                 select($selected), $selected = "" unless $selected eq "";
3289
3290                 # No pipes now.
3291                 $piped = "";
3292             } ## end if ($piped)
3293         }    # CMD:
3294
3295 =head3 COMMAND LOOP TERMINATION
3296
3297 When commands have finished executing, we come here. If the user closed the
3298 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3299 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3300 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3301 The interpreter will then execute the next line and then return control to us
3302 again.
3303
3304 =cut
3305
3306         # No more commands? Quit.
3307         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3308
3309         # Evaluate post-prompt commands.
3310         foreach $evalarg (@$post) {
3311             DB::eval();
3312         }
3313     }    # if ($single || $signal)
3314
3315     # Put the user's globals back where you found them.
3316     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3317     ();
3318 } ## end sub DB
3319
3320 package DB::Obj;
3321
3322 sub new {
3323     my $class = shift;
3324
3325     my $self = bless {}, $class;
3326
3327     $self->_init(@_);
3328
3329     return $self;
3330 }
3331
3332 sub _init {
3333     my ($self, $args) = @_;
3334
3335     %{$self} = (%$self, %$args);
3336
3337     return;
3338 }
3339
3340 {
3341     no strict 'refs';
3342     foreach my $slot_name (qw(after explicit_stop infix position prefix i_cmd)) {
3343         my $slot = $slot_name;
3344         *{$slot} = sub {
3345             my $self = shift;
3346
3347             if (@_) {
3348                 ${ $self->{$slot} } = shift;
3349             }
3350
3351             return ${ $self->{$slot} };
3352         };
3353
3354         *{"append_to_$slot"} = sub {
3355             my $self = shift;
3356             my $s = shift;
3357
3358             return $self->$slot($self->$slot . $s);
3359         };
3360     }
3361 }
3362
3363 sub _DB_on_init__initialize_globals
3364 {
3365     my $self = shift;
3366
3367     # Check for whether we should be running continuously or not.
3368     # _After_ the perl program is compiled, $single is set to 1:
3369     if ( $single and not $second_time++ ) {
3370
3371         # Options say run non-stop. Run until we get an interrupt.
3372         if ($runnonstop) {    # Disable until signal
3373                 # If there's any call stack in place, turn off single
3374                 # stepping into subs throughout the stack.
3375             for my $i (0 .. $stack_depth) {
3376                 $stack[ $i ] &= ~1;
3377             }
3378
3379             # And we are now no longer in single-step mode.
3380             $single = 0;
3381
3382             # If we simply returned at this point, we wouldn't get
3383             # the trace info. Fall on through.
3384             # return;
3385         } ## end if ($runnonstop)
3386
3387         elsif ($ImmediateStop) {
3388
3389             # We are supposed to stop here; XXX probably a break.
3390             $ImmediateStop = 0;    # We've processed it; turn it off
3391             $signal        = 1;    # Simulate an interrupt to force
3392                                    # us into the command loop
3393         }
3394     } ## end if ($single and not $second_time...
3395
3396     # If we're in single-step mode, or an interrupt (real or fake)
3397     # has occurred, turn off non-stop mode.
3398     $runnonstop = 0 if $single or $signal;
3399
3400     return;
3401 }
3402
3403 sub _DB__handle_watch_expressions
3404 {
3405     my $self = shift;
3406
3407     if ( $trace & 2 ) {
3408         for my $n (0 .. $#to_watch) {
3409             $evalarg = $to_watch[$n];
3410             local $onetimeDump;    # Tell DB::eval() to not output results
3411
3412             # Fix context DB::eval() wants to return an array, but
3413             # we need a scalar here.
3414             my ($val) = join( "', '", DB::eval() );
3415             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3416
3417             # Did it change?
3418             if ( $val ne $old_watch[$n] ) {
3419
3420                 # Yep! Show the difference, and fake an interrupt.
3421                 $signal = 1;
3422                 print {$OUT} <<EOP;
3423 Watchpoint $n:\t$to_watch[$n] changed:
3424     old value:\t$old_watch[$n]
3425     new value:\t$val
3426 EOP
3427                 $old_watch[$n] = $val;
3428             } ## end if ($val ne $old_watch...
3429         } ## end for my $n (0 ..
3430     } ## end if ($trace & 2)
3431
3432     return;
3433 }
3434
3435 sub _my_print_lineinfo
3436 {
3437     my ($self, $i, $incr_pos) = @_;
3438
3439     if ($frame) {
3440         # Print it indented if tracing is on.
3441         DB::print_lineinfo( ' ' x $stack_depth,
3442             "$i:\t$DB::dbline[$i]" . $self->after );
3443     }
3444     else {
3445         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3446     }
3447 }
3448
3449 sub _curr_line {
3450     return $DB::dbline[$line];
3451 }
3452
3453 sub _DB__grab_control
3454 {
3455     my $self = shift;
3456
3457     # Yes, grab control.
3458     if ($slave_editor) {
3459
3460         # Tell the editor to update its position.
3461         $self->position("\032\032${DB::filename}:$line:0\n");
3462         DB::print_lineinfo($self->position());
3463     }
3464
3465 =pod
3466
3467 Special check: if we're in package C<DB::fake>, we've gone through the
3468 C<END> block at least once. We set up everything so that we can continue
3469 to enter commands and have a valid context to be in.
3470
3471 =cut
3472
3473     elsif ( $DB::package eq 'DB::fake' ) {
3474
3475         # Fallen off the end already.
3476         if (!$DB::term) {
3477             DB::setterm();
3478         }
3479
3480         DB::print_help(<<EOP);
3481 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3482 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3483 B<h q>, B<h R> or B<h o> to get additional info.
3484 EOP
3485
3486         # Set the DB::eval context appropriately.
3487         $DB::package     = 'main';
3488         $DB::usercontext = DB::_calc_usercontext($DB::package);
3489     } ## end elsif ($package eq 'DB::fake')
3490
3491 =pod
3492
3493 If the program hasn't finished executing, we scan forward to the
3494 next executable line, print that out, build the prompt from the file and line
3495 number information, and print that.
3496
3497 =cut
3498
3499     else {
3500
3501
3502         # Still somewhere in the midst of execution. Set up the
3503         #  debugger prompt.
3504         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3505                              # Perl 5 ones (sorry, we don't print Klingon
3506                              #module names)
3507
3508         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3509         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3510         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3511
3512         # Break up the prompt if it's really long.
3513         if ( length($self->prefix()) > 30 ) {
3514             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3515             $self->prefix("");
3516             $self->infix(":\t");
3517         }
3518         else {
3519             $self->infix("):\t");
3520             $self->position(
3521                 $self->prefix . $line. $self->infix
3522                 . $self->_curr_line . $self->after
3523             );
3524         }
3525
3526         # Print current line info, indenting if necessary.
3527         $self->_my_print_lineinfo($line, $self->position);
3528
3529         my $i;
3530         my $line_i = sub { return $DB::dbline[$i]; };
3531
3532         # Scan forward, stopping at either the end or the next
3533         # unbreakable line.
3534         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3535         {    #{ vi
3536
3537             # Drop out on null statements, block closers, and comments.
3538             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3539
3540             # Drop out if the user interrupted us.
3541             last if $signal;
3542
3543             # Append a newline if the line doesn't have one. Can happen
3544             # in eval'ed text, for instance.
3545             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3546
3547             # Next executable line.
3548             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3549                 . $self->after;
3550             $self->append_to_position($incr_pos);
3551             $self->_my_print_lineinfo($i, $incr_pos);
3552         } ## end for ($i = $line + 1 ; $i...
3553     } ## end else [ if ($slave_editor)
3554
3555     return;
3556 }
3557
3558 sub _handle_t_command {
3559     if (my ($levels) = $DB::cmd =~ /\At(?:\s+(\d+))?\z/) {
3560         $trace ^= 1;
3561         local $\ = '';
3562         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3563         print {$OUT} "Trace = "
3564         . ( ( $trace & 1 )
3565             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3566             : "off" ) . "\n";
3567         next CMD;
3568     }
3569
3570     return;
3571 }
3572
3573
3574 sub _handle_S_command {
3575     if (my ($print_all_subs, $should_reverse, $Spatt)
3576         = $DB::cmd =~ /\AS(\s+(!)?(.+))?\z/) {
3577         # $Spatt is the pattern (if any) to use.
3578         # Reverse scan?
3579         my $Srev     = defined $should_reverse;
3580         # No args - print all subs.
3581         my $Snocheck = !defined $print_all_subs;
3582
3583         # Need to make these sane here.
3584         local $\ = '';
3585         local $, = '';
3586
3587         # Search through the debugger's magical hash of subs.
3588         # If $nocheck is true, just print the sub name.
3589         # Otherwise, check it against the pattern. We then use
3590         # the XOR trick to reverse the condition as required.
3591         foreach $subname ( sort( keys %sub ) ) {
3592             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3593                 print $OUT $subname, "\n";
3594             }
3595         }
3596         next CMD;
3597     }
3598
3599     return;
3600 }
3601
3602 sub _handle_V_command_and_X_command {
3603
3604     $DB::cmd =~ s/^X\b/V $DB::package/;
3605
3606     # Bare V commands get the currently-being-debugged package
3607     # added.
3608     if ($DB::cmd eq "V") {
3609         $DB::cmd = "V $DB::package";
3610     }
3611
3612     # V - show variables in package.
3613     if (my ($new_packname, $new_vars_str) =
3614         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3615
3616         # Save the currently selected filehandle and
3617         # force output to debugger's filehandle (dumpvar
3618         # just does "print" for output).
3619         my $savout = select($OUT);
3620
3621         # Grab package name and variables to dump.
3622         $packname = $new_packname;
3623         my @vars     = split( ' ', $new_vars_str );
3624
3625         # If main::dumpvar isn't here, get it.
3626         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3627         if ( defined &main::dumpvar ) {
3628
3629             # We got it. Turn off subroutine entry/exit messages
3630             # for the moment, along with return values.
3631             local $frame = 0;
3632             local $doret = -2;
3633
3634             # must detect sigpipe failures  - not catching
3635             # then will cause the debugger to die.
3636             eval {
3637                 &main::dumpvar(
3638                     $packname,
3639                     defined $option{dumpDepth}
3640                     ? $option{dumpDepth}
3641                     : -1,    # assume -1 unless specified
3642                     @vars
3643                 );
3644             };
3645
3646             # The die doesn't need to include the $@, because
3647             # it will automatically get propagated for us.
3648             if ($@) {
3649                 die unless $@ =~ /dumpvar print failed/;
3650             }
3651         } ## end if (defined &main::dumpvar)
3652         else {
3653
3654             # Couldn't load dumpvar.
3655             print $OUT "dumpvar.pl not available.\n";
3656         }
3657
3658         # Restore the output filehandle, and go round again.
3659         select($savout);
3660         next CMD;
3661     }
3662
3663     return;
3664 }
3665
3666 sub _handle_dash_command {
3667
3668     if ($DB::cmd eq '-') {
3669
3670         # back up by a window; go to 1 if back too far.
3671         $start -= $incr + $window + 1;
3672         $start = 1 if $start <= 0;
3673         $incr  = $window - 1;
3674
3675         # Generate and execute a "l +" command (handled below).
3676         $DB::cmd = 'l ' . ($start) . '+';
3677     }
3678     return;
3679 }
3680
3681 sub _n_or_s_commands_generic {
3682     my ($self, $new_val) = @_;
3683     # n - next
3684     next CMD if DB::_DB__is_finished();
3685
3686     # Single step, but don't enter subs.
3687     $single = $new_val;
3688
3689     # Save for empty command (repeat last).
3690     $laststep = $DB::cmd;
3691     last CMD;
3692 }
3693
3694 sub _n_or_s {
3695     my ($self, $letter, $new_val) = @_;
3696
3697     if ($DB::cmd eq $letter) {
3698         $self->_n_or_s_commands_generic($new_val);
3699     }
3700
3701     return;
3702 }
3703
3704 sub _handle_n_command {
3705     my $self = shift;
3706
3707     return $self->_n_or_s('n', 2);
3708 }
3709
3710 sub _handle_s_command {
3711     my $self = shift;
3712
3713     return $self->_n_or_s('s', 1);
3714 }
3715
3716 sub _handle_r_command {
3717     my $self = shift;
3718     # r - return from the current subroutine.
3719     if ($DB::cmd eq 'r') {
3720
3721         # Can't do anything if the program's over.
3722         next CMD if DB::_DB__is_finished();
3723
3724         # Turn on stack trace.
3725         $stack[$stack_depth] |= 1;
3726
3727         # Print return value unless the stack is empty.
3728         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3729         last CMD;
3730     }
3731
3732     return;
3733 }
3734
3735 sub _handle_T_command {
3736     if ($DB::cmd eq 'T') {
3737         DB::print_trace( $OUT, 1 );    # skip DB
3738         next CMD;
3739     }
3740
3741     return;
3742 }
3743
3744 sub _handle_w_command {
3745     if (my ($arg) = $DB::cmd =~ /\Aw\b\s*(.*)/s) {
3746         DB::cmd_w( 'w', $arg );
3747         next CMD;
3748     }
3749
3750     return;
3751 }
3752
3753 sub _handle_W_command {
3754     if (my ($arg) = $DB::cmd =~ /\AW\b\s*(.*)/s) {
3755         DB::cmd_W( 'W', $arg );
3756         next CMD;
3757     }
3758
3759     return;
3760 }
3761
3762 package DB;
3763
3764 # The following code may be executed now:
3765 # BEGIN {warn 4}
3766
3767 =head2 sub
3768
3769 C<sub> is called whenever a subroutine call happens in the program being
3770 debugged. The variable C<$DB::sub> contains the name of the subroutine
3771 being called.
3772
3773 The core function of this subroutine is to actually call the sub in the proper
3774 context, capturing its output. This of course causes C<DB::DB> to get called
3775 again, repeating until the subroutine ends and returns control to C<DB::sub>
3776 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3777 return value, and returns its captured copy of the return value as its own
3778 return value. The value then feeds back into the program being debugged as if
3779 C<DB::sub> hadn't been there at all.
3780
3781 C<sub> does all the work of printing the subroutine entry and exit messages
3782 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3783 and also prints the return value if needed (for the C<r> command and if
3784 the 16 bit is set in C<$frame>).
3785
3786 It also tracks the subroutine call depth by saving the current setting of
3787 C<$single> in the C<@stack> package global; if this exceeds the value in
3788 C<$deep>, C<sub> automatically turns on printing of the current depth by
3789 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3790 of stop/don't stop on entry to subs set as it currently is set.
3791
3792 =head3 C<caller()> support
3793
3794 If C<caller()> is called from the package C<DB>, it provides some
3795 additional data, in the following order:
3796
3797 =over 4
3798
3799 =item * C<$package>
3800
3801 The package name the sub was in
3802
3803 =item * C<$filename>
3804
3805 The filename it was defined in
3806
3807 =item * C<$line>
3808
3809 The line number it was defined on
3810
3811 =item * C<$subroutine>
3812
3813 The subroutine name; C<(eval)> if an C<eval>().
3814
3815 =item * C<$hasargs>
3816
3817 1 if it has arguments, 0 if not
3818
3819 =item * C<$wantarray>
3820
3821 1 if array context, 0 if scalar context
3822
3823 =item * C<$evaltext>
3824
3825 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3826
3827 =item * C<$is_require>
3828
3829 frame was created by a C<use> or C<require> statement
3830
3831 =item * C<$hints>
3832
3833 pragma information; subject to change between versions
3834
3835 =item * C<$bitmask>
3836
3837 pragma information; subject to change between versions
3838
3839 =item * C<@DB::args>
3840
3841 arguments with which the subroutine was invoked
3842
3843 =back
3844
3845 =cut
3846
3847 use vars qw($deep);
3848
3849 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3850 # happy. -- Shlomi Fish
3851 sub DB::sub {
3852     # Do not use a regex in this subroutine -> results in corrupted memory
3853     # See: [perl #66110]
3854
3855     # lock ourselves under threads
3856     lock($DBGR);
3857
3858     # Whether or not the autoloader was running, a scalar to put the
3859     # sub's return value in (if needed), and an array to put the sub's
3860     # return value in (if needed).
3861     my ( $al, $ret, @ret ) = "";
3862     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3863         print "creating new thread\n";
3864     }
3865
3866     # If the last ten characters are '::AUTOLOAD', note we've traced
3867     # into AUTOLOAD for $sub.
3868     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3869         no strict 'refs';
3870         $al = " for $$sub" if defined $$sub;
3871     }
3872
3873     # We stack the stack pointer and then increment it to protect us
3874     # from a situation that might unwind a whole bunch of call frames
3875     # at once. Localizing the stack pointer means that it will automatically
3876     # unwind the same amount when multiple stack frames are unwound.
3877     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3878
3879     # Expand @stack.
3880     $#stack = $stack_depth;
3881
3882     # Save current single-step setting.
3883     $stack[-1] = $single;
3884
3885     # Turn off all flags except single-stepping.
3886     $single &= 1;
3887
3888     # If we've gotten really deeply recursed, turn on the flag that will
3889     # make us stop with the 'deep recursion' message.
3890     $single |= 4 if $stack_depth == $deep;
3891
3892     # If frame messages are on ...
3893     (
3894         $frame & 4    # Extended frame entry message
3895         ? (
3896             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3897
3898             # Why -1? But it works! :-(
3899             # Because print_trace will call add 1 to it and then call
3900             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3901             # in dump_trace.
3902             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3903           )
3904         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3905
3906           # standard frame entry message
3907       )
3908       if $frame;
3909
3910     # Determine the sub's return type, and capture appropriately.
3911     if (wantarray) {
3912
3913         # Called in array context. call sub and capture output.
3914         # DB::DB will recursively get control again if appropriate; we'll come
3915         # back here when the sub is finished.
3916         {
3917             no strict 'refs';
3918             @ret = &$sub;
3919         }
3920
3921         # Pop the single-step value back off the stack.
3922         $single |= $stack[ $stack_depth-- ];
3923
3924         # Check for exit trace messages...
3925         (
3926             $frame & 4    # Extended exit message
3927             ? (
3928                 print_lineinfo( ' ' x $stack_depth, "out " ),
3929                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3930               )
3931             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3932
3933               # Standard exit message
3934           )
3935           if $frame & 2;
3936
3937         # Print the return info if we need to.
3938         if ( $doret eq $stack_depth or $frame & 16 ) {
3939
3940             # Turn off output record separator.
3941             local $\ = '';
3942             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3943
3944             # Indent if we're printing because of $frame tracing.
3945             print $fh ' ' x $stack_depth if $frame & 16;
3946
3947             # Print the return value.
3948             print $fh "list context return from $sub:\n";
3949             dumpit( $fh, \@ret );
3950
3951             # And don't print it again.
3952             $doret = -2;
3953         } ## end if ($doret eq $stack_depth...
3954             # And we have to return the return value now.
3955         @ret;
3956     } ## end if (wantarray)
3957
3958     # Scalar context.
3959     else {
3960         if ( defined wantarray ) {
3961             no strict 'refs';
3962             # Save the value if it's wanted at all.
3963             $ret = &$sub;
3964         }
3965         else {
3966             no strict 'refs';
3967             # Void return, explicitly.
3968             &$sub;
3969             undef $ret;
3970         }
3971
3972         # Pop the single-step value off the stack.
3973         $single |= $stack[ $stack_depth-- ];
3974
3975         # If we're doing exit messages...
3976         (
3977             $frame & 4    # Extended messages
3978             ? (
3979                 print_lineinfo( ' ' x $stack_depth, "out " ),
3980                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3981               )
3982             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3983
3984               # Standard messages
3985           )
3986           if $frame & 2;
3987
3988         # If we are supposed to show the return value... same as before.
3989         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3990             local $\ = '';
3991             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3992             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3993             print $fh (
3994                 defined wantarray
3995                 ? "scalar context return from $sub: "
3996                 : "void context return from $sub\n"
3997             );
3998             dumpit( $fh, $ret ) if defined wantarray;
3999             $doret = -2;
4000         } ## end if ($doret eq $stack_depth...
4001
4002         # Return the appropriate scalar value.
4003         $ret;
4004     } ## end else [ if (wantarray)
4005 } ## end sub _sub
4006
4007 sub lsub : lvalue {
4008
4009     no strict 'refs';
4010
4011     # lock ourselves under threads
4012     lock($DBGR);
4013
4014     # Whether or not the autoloader was running, a scalar to put the
4015     # sub's return value in (if needed), and an array to put the sub's
4016     # return value in (if needed).
4017     my ( $al, $ret, @ret ) = "";
4018     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4019         print "creating new thread\n";
4020     }
4021
4022     # If the last ten characters are C'::AUTOLOAD', note we've traced
4023     # into AUTOLOAD for $sub.
4024     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4025         $al = " for $$sub";
4026     }
4027
4028     # We stack the stack pointer and then increment it to protect us
4029     # from a situation that might unwind a whole bunch of call frames
4030     # at once. Localizing the stack pointer means that it will automatically
4031     # unwind the same amount when multiple stack frames are unwound.
4032     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4033
4034     # Expand @stack.
4035     $#stack = $stack_depth;
4036
4037     # Save current single-step setting.
4038     $stack[-1] = $single;
4039
4040     # Turn off all flags except single-stepping.
4041     $single &= 1;
4042
4043     # If we've gotten really deeply recursed, turn on the flag that will
4044     # make us stop with the 'deep recursion' message.
4045     $single |= 4 if $stack_depth == $deep;
4046
4047     # If frame messages are on ...
4048     (
4049         $frame & 4    # Extended frame entry message
4050         ? (
4051             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
4052
4053             # Why -1? But it works! :-(
4054             # Because print_trace will call add 1 to it and then call
4055             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4056             # in dump_trace.
4057             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4058           )
4059         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
4060
4061           # standard frame entry message
4062       )
4063       if $frame;
4064
4065     # Pop the single-step value back off the stack.
4066     $single |= $stack[ $stack_depth-- ];
4067
4068     # call the original lvalue sub.
4069     &$sub;
4070 }
4071
4072 # Abstracting common code from multiple places elsewhere:
4073 sub depth_print_lineinfo {
4074     my $always_print = shift;
4075
4076     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4077 }
4078
4079 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4080
4081 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4082 Most of the changes were to systematize the command structure and to eliminate
4083 commands that threw away user input without checking.
4084
4085 The following sections describe the code added to make it easy to support
4086 multiple command sets with conflicting command names. This section is a start
4087 at unifying all command processing to make it simpler to develop commands.
4088
4089 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4090 number, and C<$dbline> (the current line) as arguments.
4091
4092 Support functions in this section which have multiple modes of failure C<die>
4093 on error; the rest simply return a false value.
4094
4095 The user-interface functions (all of the C<cmd_*> functions) just output
4096 error messages.
4097
4098 =head2 C<%set>
4099
4100 The C<%set> hash defines the mapping from command letter to subroutine
4101 name suffix.
4102
4103 C<%set> is a two-level hash, indexed by set name and then by command name.
4104 Note that trying to set the CommandSet to C<foobar> simply results in the
4105 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4106
4107 =cut
4108
4109 ### The API section
4110
4111 my %set = (    #
4112     'pre580' => {
4113         'a' => 'pre580_a',
4114         'A' => 'pre580_null',
4115         'b' => 'pre580_b',
4116         'B' => 'pre580_null',
4117         'd' => 'pre580_null',
4118         'D' => 'pre580_D',
4119         'h' => 'pre580_h',
4120         'M' => 'pre580_null',
4121         'O' => 'o',
4122         'o' => 'pre580_null',
4123         'v' => 'M',
4124         'w' => 'v',
4125         'W' => 'pre580_W',
4126     },
4127     'pre590' => {
4128         '<'  => 'pre590_prepost',
4129         '<<' => 'pre590_prepost',
4130         '>'  => 'pre590_prepost',
4131         '>>' => 'pre590_prepost',
4132         '{'  => 'pre590_prepost',
4133         '{{' => 'pre590_prepost',
4134     },
4135 );
4136
4137 my %breakpoints_data;
4138
4139 sub _has_breakpoint_data_ref {
4140     my ($filename, $line) = @_;
4141
4142     return (
4143         exists( $breakpoints_data{$filename} )
4144             and
4145         exists( $breakpoints_data{$filename}{$line} )
4146     );
4147 }
4148
4149 sub _get_breakpoint_data_ref {
4150     my ($filename, $line) = @_;
4151
4152     return ($breakpoints_data{$filename}{$line} ||= +{});
4153 }
4154
4155 sub _delete_breakpoint_data_ref {
4156     my ($filename, $line) = @_;
4157
4158     delete($breakpoints_data{$filename}{$line});
4159     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4160         delete($breakpoints_data{$filename});
4161     }
4162
4163     return;
4164 }
4165
4166 sub _set_breakpoint_enabled_status {
4167     my ($filename, $line, $status) = @_;
4168
4169     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4170         ($status ? 1 : '')
4171         ;
4172
4173     return;
4174 }
4175
4176 sub _enable_breakpoint_temp_enabled_status {
4177     my ($filename, $line) = @_;
4178
4179     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4180
4181     return;
4182 }
4183
4184 sub _cancel_breakpoint_temp_enabled_status {
4185     my ($filename, $line) = @_;
4186
4187     my $ref = _get_breakpoint_data_ref($filename, $line);
4188
4189     delete ($ref->{'temp_enabled'});
4190
4191     if (! %$ref) {
4192         _delete_breakpoint_data_ref($filename, $line);
4193     }
4194
4195     return;
4196 }
4197
4198 sub _is_breakpoint_enabled {
4199     my ($filename, $line) = @_;
4200
4201     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4202     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4203 }
4204
4205 =head2 C<cmd_wrapper()> (API)
4206
4207 C<cmd_wrapper()> allows the debugger to switch command sets
4208 depending on the value of the C<CommandSet> option.
4209
4210 It tries to look up the command in the C<%set> package-level I<lexical>
4211 (which means external entities can't fiddle with it) and create the name of
4212 the sub to call based on the value found in the hash (if it's there). I<All>
4213 of the commands to be handled in a set have to be added to C<%set>; if they
4214 aren't found, the 5.8.0 equivalent is called (if there is one).
4215
4216 This code uses symbolic references.
4217
4218 =cut
4219
4220 sub cmd_wrapper {
4221     my $cmd      = shift;
4222     my $line     = shift;
4223     my $dblineno = shift;
4224
4225     # Assemble the command subroutine's name by looking up the
4226     # command set and command name in %set. If we can't find it,
4227     # default to the older version of the command.
4228     my $call = 'cmd_'
4229       . ( $set{$CommandSet}{$cmd}
4230           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4231
4232     # Call the command subroutine, call it by name.
4233     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4234 } ## end sub cmd_wrapper
4235
4236 =head3 C<cmd_a> (command)
4237
4238 The C<a> command handles pre-execution actions. These are associated with a
4239 particular line, so they're stored in C<%dbline>. We default to the current
4240 line if none is specified.
4241
4242 =cut
4243
4244 sub cmd_a {
4245     my $cmd    = shift;
4246     my $line   = shift || '';    # [.|line] expr
4247     my $dbline = shift;
4248
4249     # If it's dot (here), or not all digits,  use the current line.
4250     $line =~ s/\A\./$dbline/;
4251
4252     # Should be a line number followed by an expression.
4253     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4254
4255         if (! length($lineno)) {
4256             $lineno = $dbline;
4257         }
4258
4259         # If we have an expression ...
4260         if ( length $expr ) {
4261
4262             # ... but the line isn't breakable, complain.
4263             if ( $dbline[$lineno] == 0 ) {
4264                 print $OUT
4265                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4266             }
4267             else {
4268
4269                 # It's executable. Record that the line has an action.
4270                 $had_breakpoints{$filename} |= 2;
4271
4272                 # Remove any action, temp breakpoint, etc.
4273                 $dbline{$lineno} =~ s/\0[^\0]*//;
4274
4275                 # Add the action to the line.
4276                 $dbline{$lineno} .= "\0" . action($expr);
4277
4278                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4279             }
4280         } ## end if (length $expr)
4281     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4282     else {
4283
4284         # Syntax wrong.
4285         print $OUT
4286           "Adding an action requires an optional lineno and an expression\n"
4287           ;    # hint
4288     }
4289 } ## end sub cmd_a
4290
4291 =head3 C<cmd_A> (command)
4292
4293 Delete actions. Similar to above, except the delete code is in a separate
4294 subroutine, C<delete_action>.
4295
4296 =cut
4297
4298 sub cmd_A {
4299     my $cmd    = shift;
4300     my $line   = shift || '';
4301     my $dbline = shift;
4302
4303     # Dot is this line.
4304     $line =~ s/^\./$dbline/;
4305
4306     # Call delete_action with a null param to delete them all.
4307     # The '1' forces the eval to be true. It'll be false only
4308     # if delete_action blows up for some reason, in which case
4309     # we print $@ and get out.
4310     if ( $line eq '*' ) {
4311         if (! eval { _delete_all_actions(); 1 }) {
4312             print {$OUT} $@;
4313             return;
4314         }
4315     }
4316
4317     # There's a real line  number. Pass it to delete_action.
4318     # Error trapping is as above.
4319     elsif ( $line =~ /^(\S.*)/ ) {
4320         if (! eval { delete_action($1); 1 }) {
4321             print {$OUT} $@;
4322             return;
4323         }
4324     }
4325
4326     # Swing and a miss. Bad syntax.
4327     else {
4328         print $OUT
4329           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4330     }
4331 } ## end sub cmd_A
4332
4333 =head3 C<delete_action> (API)
4334
4335 C<delete_action> accepts either a line number or C<undef>. If a line number
4336 is specified, we check for the line being executable (if it's not, it
4337 couldn't have had an  action). If it is, we just take the action off (this
4338 will get any kind of an action, including breakpoints).
4339
4340 =cut
4341
4342 sub _remove_action_from_dbline {
4343     my $i = shift;
4344
4345     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4346     delete $dbline{$i} if $dbline{$i} eq '';
4347
4348     return;
4349 }
4350
4351 sub _delete_all_actions {
4352     print {$OUT} "Deleting all actions...\n";
4353
4354     for my $file ( keys %had_breakpoints ) {
4355         local *dbline = $main::{ '_<' . $file };
4356         $max = $#dbline;
4357         my $was;
4358         for my $i (1 .. $max) {
4359             if ( defined $dbline{$i} ) {
4360                 _remove_action_from_dbline($i);
4361             }
4362         }
4363
4364         unless ( $had_breakpoints{$file} &= ~2 ) {
4365             delete $had_breakpoints{$file};
4366         }
4367     }
4368
4369     return;
4370 }
4371
4372 sub delete_action {
4373     my $i = shift;
4374
4375     if ( defined($i) ) {
4376         # Can there be one?
4377         die "Line $i has no action .\n" if $dbline[$i] == 0;
4378
4379         # Nuke whatever's there.
4380         _remove_action_from_dbline($i);
4381     }
4382     else {
4383         _delete_all_actions();
4384     }
4385 }
4386
4387 =head3 C<cmd_b> (command)
4388
4389 Set breakpoints. Since breakpoints can be set in so many places, in so many
4390 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4391 we try to parse the command type, and then shuttle it off to an appropriate
4392 subroutine to actually do the work of setting the breakpoint in the right
4393 place.
4394
4395 =cut
4396
4397 sub cmd_b {
4398     my $cmd    = shift;
4399     my $line   = shift;    # [.|line] [cond]
4400     my $dbline = shift;
4401
4402     my $default_cond = sub {
4403         my $cond = shift;
4404         return length($cond) ? $cond : '1';
4405     };
4406
4407     # Make . the current line number if it's there..
4408     $line =~ s/^\.(\s|\z)/$dbline$1/;
4409
4410     # No line number, no condition. Simple break on current line.
4411     if ( $line =~ /^\s*$/ ) {
4412         cmd_b_line( $dbline, 1 );
4413     }
4414
4415     # Break on load for a file.
4416     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4417         $file =~ s/\s+\z//;
4418         cmd_b_load($file);
4419     }
4420
4421     # b compile|postpone <some sub> [<condition>]
4422     # The interpreter actually traps this one for us; we just put the
4423     # necessary condition in the %postponed hash.
4424     elsif ( my ($action, $subname, $cond)
4425         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4426
4427         # De-Perl4-ify the name - ' separators to ::.
4428         $subname =~ s/'/::/g;
4429
4430         # Qualify it into the current package unless it's already qualified.
4431         $subname = "${package}::" . $subname unless $subname =~ /::/;
4432
4433         # Add main if it starts with ::.
4434         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4435
4436         # Save the break type for this sub.
4437         $postponed{$subname} = (($action eq 'postpone')
4438             ? ( "break +0 if " . $default_cond->($cond) )
4439             : "compile");
4440     } ## end elsif ($line =~ ...
4441     # b <filename>:<line> [<condition>]
4442     elsif (my ($filename, $line_num, $cond)
4443         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4444         cmd_b_filename_line(
4445             $filename,
4446             $line_num,
4447             (length($cond) ? $cond : '1'),
4448         );
4449     }
4450     # b <sub name> [<condition>]
4451     elsif ( my ($new_subname, $new_cond) =
4452         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4453
4454         #
4455         $subname = $new_subname;
4456         cmd_b_sub( $subname, $default_cond->($new_cond) );
4457     }
4458
4459     # b <line> [<condition>].
4460     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4461
4462         # Capture the line. If none, it's the current line.
4463         $line = $line_n || $dbline;
4464
4465         # Break on line.
4466         cmd_b_line( $line, $default_cond->($cond) );
4467     }
4468
4469     # Line didn't make sense.
4470     else {
4471         print "confused by line($line)?\n";
4472     }
4473
4474     return;
4475 } ## end sub cmd_b
4476
4477 =head3 C<break_on_load> (API)
4478
4479 We want to break when this file is loaded. Mark this file in the
4480 C<%break_on_load> hash, and note that it has a breakpoint in
4481 C<%had_breakpoints>.
4482
4483 =cut
4484
4485 sub break_on_load {
4486     my $file = shift;
4487     $break_on_load{$file} = 1;
4488     $had_breakpoints{$file} |= 1;
4489 }
4490
4491 =head3 C<report_break_on_load> (API)
4492
4493 Gives us an array of filenames that are set to break on load. Note that
4494 only files with break-on-load are in here, so simply showing the keys
4495 suffices.
4496
4497 =cut
4498
4499 sub report_break_on_load {
4500     sort keys %break_on_load;
4501 }
4502
4503 =head3 C<cmd_b_load> (command)
4504
4505 We take the file passed in and try to find it in C<%INC> (which maps modules
4506 to files they came from). We mark those files for break-on-load via
4507 C<break_on_load> and then report that it was done.
4508
4509 =cut
4510
4511 sub cmd_b_load {
4512     my $file = shift;
4513     my @files;
4514
4515     # This is a block because that way we can use a redo inside it
4516     # even without there being any looping structure at all outside it.
4517     {
4518
4519         # Save short name and full path if found.
4520         push @files, $file;
4521         push @files, $::INC{$file} if $::INC{$file};
4522
4523         # Tack on .pm and do it again unless there was a '.' in the name
4524         # already.
4525         $file .= '.pm', redo unless $file =~ /\./;
4526     }
4527
4528     # Do the real work here.
4529     break_on_load($_) for @files;
4530
4531     # All the files that have break-on-load breakpoints.
4532     @files = report_break_on_load;
4533
4534     # Normalize for the purposes of our printing this.
4535     local $\ = '';
4536     local $" = ' ';
4537     print $OUT "Will stop on load of '@files'.\n";
4538 } ## end sub cmd_b_load
4539
4540 =head3 C<$filename_error> (API package global)
4541
4542 Several of the functions we need to implement in the API need to work both
4543 on the current file and on other files. We don't want to duplicate code, so
4544 C<$filename_error> is used to contain the name of the file that's being
4545 worked on (if it's not the current one).
4546
4547 We can now build functions in pairs: the basic function works on the current
4548 file, and uses C<$filename_error> as part of its error message. Since this is
4549 initialized to C<"">, no filename will appear when we are working on the
4550 current file.
4551
4552 The second function is a wrapper which does the following:
4553
4554 =over 4
4555
4556 =item *
4557
4558 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4559
4560 =item *
4561
4562 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4563
4564 =item *
4565
4566 Calls the first function.
4567
4568 The first function works on the I<current> file (i.e., the one we changed to),
4569 and prints C<$filename_error> in the error message (the name of the other file)
4570 if it needs to. When the functions return, C<*dbline> is restored to point
4571 to the actual current file (the one we're executing in) and
4572 C<$filename_error> is restored to C<"">. This restores everything to
4573 the way it was before the second function was called at all.
4574
4575 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4576 details.
4577
4578 =back
4579
4580 =cut
4581
4582 use vars qw($filename_error);
4583 $filename_error = '';
4584
4585 =head3 breakable_line(from, to) (API)
4586
4587 The subroutine decides whether or not a line in the current file is breakable.
4588 It walks through C<@dbline> within the range of lines specified, looking for
4589 the first line that is breakable.
4590
4591 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4592 first line I<after> C<$to> that's breakable, if there is one.
4593
4594 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4595 first line I<before> C<$to> that's breakable, if there is one.
4596
4597 =cut
4598
4599 sub breakable_line {
4600
4601     my ( $from, $to ) = @_;
4602
4603     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4604     my $i = $from;
4605
4606     # If there are at least 2 arguments, we're trying to search a range.
4607     if ( @_ >= 2 ) {
4608
4609         # $delta is positive for a forward search, negative for a backward one.
4610         my $delta = $from < $to ? +1 : -1;
4611
4612         # Keep us from running off the ends of the file.
4613         my $limit = $delta > 0 ? $#dbline : 1;
4614
4615         # Clever test. If you're a mathematician, it's obvious why this
4616         # test works. If not:
4617         # If $delta is positive (going forward), $limit will be $#dbline.
4618         #    If $to is less than $limit, ($limit - $to) will be positive, times
4619         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4620         #    as the stopping point.
4621         #
4622         #    If $to is greater than $limit, ($limit - $to) is negative,
4623         #    times $delta of 1 (positive), so the result is < 0 and we should
4624         #    use $limit ($#dbline) as the stopping point.
4625         #
4626         # If $delta is negative (going backward), $limit will be 1.
4627         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4628         #    (negative) so the result is > 0, and we use $to as the stopping
4629         #    point.
4630         #
4631         #    If $to is less than zero, ($limit - $to) will be positive,
4632         #    times $delta of -1 (negative), so the result is not > 0, and
4633         #    we use $limit (1) as the stopping point.
4634         #
4635         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4636         #    (negative), still giving zero; the result is not > 0, and
4637         #    we use $limit (1) as the stopping point.
4638         #
4639         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4640         #    (negative), giving a positive (>0) value, so we'll set $limit to
4641         #    $to.
4642
4643         $limit = $to if ( $limit - $to ) * $delta > 0;
4644
4645         # The real search loop.
4646         # $i starts at $from (the point we want to start searching from).
4647         # We move through @dbline in the appropriate direction (determined
4648         # by $delta: either -1 (back) or +1 (ahead).
4649         # We stay in as long as we haven't hit an executable line
4650         # ($dbline[$i] == 0 means not executable) and we haven't reached
4651         # the limit yet (test similar to the above).
4652         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4653
4654     } ## end if (@_ >= 2)
4655
4656     # If $i points to a line that is executable, return that.
4657     return $i unless $dbline[$i] == 0;
4658
4659     # Format the message and print it: no breakable lines in range.
4660     my ( $pl, $upto ) = ( '', '' );
4661     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4662
4663     # If there's a filename in filename_error, we'll see it.
4664     # If not, not.
4665     die "Line$pl $from$upto$filename_error not breakable\n";
4666 } ## end sub breakable_line
4667
4668 =head3 breakable_line_in_filename(file, from, to) (API)
4669
4670 Like C<breakable_line>, but look in another file.
4671
4672 =cut
4673
4674 sub breakable_line_in_filename {
4675
4676     # Capture the file name.
4677     my ($f) = shift;
4678
4679     # Swap the magic line array over there temporarily.
4680     local *dbline = $main::{ '_<' . $f };
4681
4682     # If there's an error, it's in this other file.
4683     local $filename_error = " of '$f'";
4684
4685     # Find the breakable line.
4686     breakable_line(@_);
4687
4688     # *dbline and $filename_error get restored when this block ends.
4689
4690 } ## end sub breakable_line_in_filename
4691
4692 =head3 break_on_line(lineno, [condition]) (API)
4693