This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
24db2956ae076a490e1e5606696f2100ffae19ea
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 Predefined Names
8
9 The following names have special meaning to Perl.  Most 
10 punctuation names have reasonable mnemonics, or analogs in the
11 shells.  Nevertheless, if you wish to use long variable names,
12 you need only say
13
14     use English;
15
16 at the top of your program. This aliases all the short names to the long
17 names in the current package. Some even have medium names, generally
18 borrowed from B<awk>. In general, it's best to use the
19
20     use English '-no_match_vars';
21
22 invocation if you don't need $PREMATCH, $MATCH, or $POSTMATCH, as it avoids
23 a certain performance hit with the use of regular expressions. See
24 L<English>.
25
26 Variables that depend on the currently selected filehandle may be set by
27 calling an appropriate object method on the IO::Handle object, although
28 this is less efficient than using the regular built-in variables. (Summary
29 lines below for this contain the word HANDLE.) First you must say
30
31     use IO::Handle;
32
33 after which you may use either
34
35     method HANDLE EXPR
36
37 or more safely,
38
39     HANDLE->method(EXPR)
40
41 Each method returns the old value of the IO::Handle attribute.
42 The methods each take an optional EXPR, which, if supplied, specifies the
43 new value for the IO::Handle attribute in question.  If not supplied,
44 most methods do nothing to the current value--except for
45 autoflush(), which will assume a 1 for you, just to be different.
46
47 Because loading in the IO::Handle class is an expensive operation, you should
48 learn how to use the regular built-in variables.
49
50 A few of these variables are considered "read-only".  This means that if
51 you try to assign to this variable, either directly or indirectly through
52 a reference, you'll raise a run-time exception.
53
54 You should be very careful when modifying the default values of most
55 special variables described in this document. In most cases you want
56 to localize these variables before changing them, since if you don't,
57 the change may affect other modules which rely on the default values
58 of the special variables that you have changed. This is one of the
59 correct ways to read the whole file at once:
60
61     open my $fh, "foo" or die $!;
62     local $/; # enable localized slurp mode
63     my $content = <$fh>;
64     close $fh;
65
66 But the following code is quite bad:
67
68     open my $fh, "foo" or die $!;
69     undef $/; # enable slurp mode
70     my $content = <$fh>;
71     close $fh;
72
73 since some other module, may want to read data from some file in the
74 default "line mode", so if the code we have just presented has been
75 executed, the global value of C<$/> is now changed for any other code
76 running inside the same Perl interpreter.
77
78 Usually when a variable is localized you want to make sure that this
79 change affects the shortest scope possible. So unless you are already
80 inside some short C<{}> block, you should create one yourself. For
81 example:
82
83     my $content = '';
84     open my $fh, "foo" or die $!;
85     {
86         local $/;
87         $content = <$fh>;
88     }
89     close $fh;
90
91 Here is an example of how your own code can go broken:
92
93     for (1..5){
94         nasty_break();
95         print "$_ ";
96     }
97     sub nasty_break {
98         $_ = 5;
99         # do something with $_
100     }
101
102 You probably expect this code to print:
103
104     1 2 3 4 5
105
106 but instead you get:
107
108     5 5 5 5 5
109
110 Why? Because nasty_break() modifies C<$_> without localizing it
111 first. The fix is to add local():
112
113         local $_ = 5;
114
115 It's easy to notice the problem in such a short example, but in more
116 complicated code you are looking for trouble if you don't localize
117 changes to the special variables.
118
119 The following list is ordered by scalar variables first, then the
120 arrays, then the hashes.
121
122 =over 8
123
124 =item $ARG
125
126 =item $_
127
128 The default input and pattern-searching space.  The following pairs are
129 equivalent:
130
131     while (<>) {...}    # equivalent only in while!
132     while (defined($_ = <>)) {...}
133
134     /^Subject:/
135     $_ =~ /^Subject:/
136
137     tr/a-z/A-Z/
138     $_ =~ tr/a-z/A-Z/
139
140     chomp
141     chomp($_)
142
143 Here are the places where Perl will assume $_ even if you
144 don't use it:
145
146 =over 3
147
148 =item *
149
150 Various unary functions, including functions like ord() and int(), as well
151 as the all file tests (C<-f>, C<-d>) except for C<-t>, which defaults to
152 STDIN.
153
154 =item *
155
156 Various list functions like print() and unlink().
157
158 =item *
159
160 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
161 without an C<=~> operator.
162
163 =item *
164
165 The default iterator variable in a C<foreach> loop if no other
166 variable is supplied.
167
168 =item *
169
170 The implicit iterator variable in the grep() and map() functions.
171
172 =item *
173
174 The default place to put an input record when a C<< <FH> >>
175 operation's result is tested by itself as the sole criterion of a C<while>
176 test.  Outside a C<while> test, this will not happen.
177
178 =back
179
180 As C<$_> is a global variable, this may lead in some cases to unwanted
181 side-effects.  As of perl 5.9.1, you can now use a lexical version of
182 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
183 declaring C<our $> restores the global C<$_> in the current scope.
184
185 (Mnemonic: underline is understood in certain operations.)
186
187 =back
188
189 =over 8
190
191 =item $a
192
193 =item $b
194
195 Special package variables when using sort(), see L<perlfunc/sort>.
196 Because of this specialness $a and $b don't need to be declared
197 (using use vars, or our()) even when using the C<strict 'vars'> pragma.
198 Don't lexicalize them with C<my $a> or C<my $b> if you want to be
199 able to use them in the sort() comparison block or function.
200
201 =back
202
203 =over 8
204
205 =item $<I<digits>>
206
207 Contains the subpattern from the corresponding set of capturing
208 parentheses from the last pattern match, not counting patterns
209 matched in nested blocks that have been exited already.  (Mnemonic:
210 like \digits.)  These variables are all read-only and dynamically
211 scoped to the current BLOCK.
212
213 =item $MATCH
214
215 =item $&
216
217 The string matched by the last successful pattern match (not counting
218 any matches hidden within a BLOCK or eval() enclosed by the current
219 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only
220 and dynamically scoped to the current BLOCK.
221
222 The use of this variable anywhere in a program imposes a considerable
223 performance penalty on all regular expression matches.  See L</BUGS>.
224
225 =item $PREMATCH
226
227 =item $`
228
229 The string preceding whatever was matched by the last successful
230 pattern match (not counting any matches hidden within a BLOCK or eval
231 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
232 string.)  This variable is read-only.
233
234 The use of this variable anywhere in a program imposes a considerable
235 performance penalty on all regular expression matches.  See L</BUGS>.
236
237 =item $POSTMATCH
238
239 =item $'
240
241 The string following whatever was matched by the last successful
242 pattern match (not counting any matches hidden within a BLOCK or eval()
243 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
244 string.)  Example:
245
246     local $_ = 'abcdefghi';
247     /def/;
248     print "$`:$&:$'\n";         # prints abc:def:ghi
249
250 This variable is read-only and dynamically scoped to the current BLOCK.
251
252 The use of this variable anywhere in a program imposes a considerable
253 performance penalty on all regular expression matches.  See L</BUGS>.
254
255 =item $LAST_PAREN_MATCH
256
257 =item $+
258
259 The text matched by the last bracket of the last successful search pattern.
260 This is useful if you don't know which one of a set of alternative patterns
261 matched. For example:
262
263     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
264
265 (Mnemonic: be positive and forward looking.)
266 This variable is read-only and dynamically scoped to the current BLOCK.
267
268 =item $^N
269
270 The text matched by the used group most-recently closed (i.e. the group
271 with the rightmost closing parenthesis) of the last successful search
272 pattern.  (Mnemonic: the (possibly) Nested parenthesis that most
273 recently closed.)
274
275 This is primarily used inside C<(?{...})> blocks for examining text
276 recently matched. For example, to effectively capture text to a variable
277 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
278
279      (?:(...)(?{ $var = $^N }))
280
281 By setting and then using C<$var> in this way relieves you from having to
282 worry about exactly which numbered set of parentheses they are.
283
284 This variable is dynamically scoped to the current BLOCK.
285
286 =item @LAST_MATCH_END
287
288 =item @+
289
290 This array holds the offsets of the ends of the last successful
291 submatches in the currently active dynamic scope.  C<$+[0]> is
292 the offset into the string of the end of the entire match.  This
293 is the same value as what the C<pos> function returns when called
294 on the variable that was matched against.  The I<n>th element
295 of this array holds the offset of the I<n>th submatch, so
296 C<$+[1]> is the offset past where $1 ends, C<$+[2]> the offset
297 past where $2 ends, and so on.  You can use C<$#+> to determine
298 how many subgroups were in the last successful match.  See the
299 examples given for the C<@-> variable.
300
301 =item HANDLE->input_line_number(EXPR)
302
303 =item $INPUT_LINE_NUMBER
304
305 =item $NR
306
307 =item $.
308
309 Current line number for the last filehandle accessed. 
310
311 Each filehandle in Perl counts the number of lines that have been read
312 from it.  (Depending on the value of C<$/>, Perl's idea of what
313 constitutes a line may not match yours.)  When a line is read from a
314 filehandle (via readline() or C<< <> >>), or when tell() or seek() is
315 called on it, C<$.> becomes an alias to the line counter for that
316 filehandle.
317
318 You can adjust the counter by assigning to C<$.>, but this will not
319 actually move the seek pointer.  I<Localizing C<$.> will not localize
320 the filehandle's line count>.  Instead, it will localize perl's notion
321 of which filehandle C<$.> is currently aliased to.
322
323 C<$.> is reset when the filehandle is closed, but B<not> when an open
324 filehandle is reopened without an intervening close().  For more
325 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
326 an explicit close, line numbers increase across ARGV files (but see
327 examples in L<perlfunc/eof>).
328
329 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
330 line counter for a given filehandle without having to worry about
331 which handle you last accessed.
332
333 (Mnemonic: many programs use "." to mean the current line number.)
334
335 =item IO::Handle->input_record_separator(EXPR)
336
337 =item $INPUT_RECORD_SEPARATOR
338
339 =item $RS
340
341 =item $/
342
343 The input record separator, newline by default.  This 
344 influences Perl's idea of what a "line" is.  Works like B<awk>'s RS
345 variable, including treating empty lines as a terminator if set to
346 the null string.  (An empty line cannot contain any spaces
347 or tabs.)  You may set it to a multi-character string to match a
348 multi-character terminator, or to C<undef> to read through the end
349 of file.  Setting it to C<"\n\n"> means something slightly
350 different than setting to C<"">, if the file contains consecutive
351 empty lines.  Setting to C<""> will treat two or more consecutive
352 empty lines as a single empty line.  Setting to C<"\n\n"> will
353 blindly assume that the next input character belongs to the next
354 paragraph, even if it's a newline.  (Mnemonic: / delimits
355 line boundaries when quoting poetry.)
356
357     local $/;           # enable "slurp" mode
358     local $_ = <FH>;    # whole file now here
359     s/\n[ \t]+/ /g;
360
361 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to be
362 better for something. :-)
363
364 Setting C<$/> to a reference to an integer, scalar containing an integer, or
365 scalar that's convertible to an integer will attempt to read records
366 instead of lines, with the maximum record size being the referenced
367 integer.  So this:
368
369     local $/ = \32768; # or \"32768", or \$var_containing_32768
370     open my $fh, $myfile or die $!;
371     local $_ = <$fh>;
372
373 will read a record of no more than 32768 bytes from FILE.  If you're
374 not reading from a record-oriented file (or your OS doesn't have
375 record-oriented files), then you'll likely get a full chunk of data
376 with every read.  If a record is larger than the record size you've
377 set, you'll get the record back in pieces.
378
379 On VMS, record reads are done with the equivalent of C<sysread>,
380 so it's best not to mix record and non-record reads on the same
381 file.  (This is unlikely to be a problem, because any file you'd
382 want to read in record mode is probably unusable in line mode.)
383 Non-VMS systems do normal I/O, so it's safe to mix record and
384 non-record reads of a file.
385
386 See also L<perlport/"Newlines">.  Also see C<$.>.
387
388 =item HANDLE->autoflush(EXPR)
389
390 =item $OUTPUT_AUTOFLUSH
391
392 =item $|
393
394 If set to nonzero, forces a flush right away and after every write
395 or print on the currently selected output channel.  Default is 0
396 (regardless of whether the channel is really buffered by the
397 system or not; C<$|> tells you only whether you've asked Perl
398 explicitly to flush after each write).  STDOUT will
399 typically be line buffered if output is to the terminal and block
400 buffered otherwise.  Setting this variable is useful primarily when
401 you are outputting to a pipe or socket, such as when you are running
402 a Perl program under B<rsh> and want to see the output as it's
403 happening.  This has no effect on input buffering.  See L<perlfunc/getc>
404 for that.  (Mnemonic: when you want your pipes to be piping hot.)
405
406 =item IO::Handle->output_field_separator EXPR
407
408 =item $OUTPUT_FIELD_SEPARATOR
409
410 =item $OFS
411
412 =item $,
413
414 The output field separator for the print operator.  If defined, this
415 value is printed between each of print's arguments.  Default is C<undef>.
416 (Mnemonic: what is printed when there is a "," in your print statement.)
417
418 =item IO::Handle->output_record_separator EXPR
419
420 =item $OUTPUT_RECORD_SEPARATOR
421
422 =item $ORS
423
424 =item $\
425
426 The output record separator for the print operator.  If defined, this
427 value is printed after the last of print's arguments.  Default is C<undef>.
428 (Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
429 Also, it's just like C<$/>, but it's what you get "back" from Perl.)
430
431 =item $LIST_SEPARATOR
432
433 =item $"
434
435 This is like C<$,> except that it applies to array and slice values
436 interpolated into a double-quoted string (or similar interpreted
437 string).  Default is a space.  (Mnemonic: obvious, I think.)
438
439 =item $SUBSCRIPT_SEPARATOR
440
441 =item $SUBSEP
442
443 =item $;
444
445 The subscript separator for multidimensional array emulation.  If you
446 refer to a hash element as
447
448     $foo{$a,$b,$c}
449
450 it really means
451
452     $foo{join($;, $a, $b, $c)}
453
454 But don't put
455
456     @foo{$a,$b,$c}      # a slice--note the @
457
458 which means
459
460     ($foo{$a},$foo{$b},$foo{$c})
461
462 Default is "\034", the same as SUBSEP in B<awk>.  If your
463 keys contain binary data there might not be any safe value for C<$;>.
464 (Mnemonic: comma (the syntactic subscript separator) is a
465 semi-semicolon.  Yeah, I know, it's pretty lame, but C<$,> is already
466 taken for something more important.)
467
468 Consider using "real" multidimensional arrays as described
469 in L<perllol>.
470
471 =item HANDLE->format_page_number(EXPR)
472
473 =item $FORMAT_PAGE_NUMBER
474
475 =item $%
476
477 The current page number of the currently selected output channel.
478 Used with formats.
479 (Mnemonic: % is page number in B<nroff>.)
480
481 =item HANDLE->format_lines_per_page(EXPR)
482
483 =item $FORMAT_LINES_PER_PAGE
484
485 =item $=
486
487 The current page length (printable lines) of the currently selected
488 output channel.  Default is 60.  
489 Used with formats.
490 (Mnemonic: = has horizontal lines.)
491
492 =item HANDLE->format_lines_left(EXPR)
493
494 =item $FORMAT_LINES_LEFT
495
496 =item $-
497
498 The number of lines left on the page of the currently selected output
499 channel.  
500 Used with formats.
501 (Mnemonic: lines_on_page - lines_printed.)
502
503 =item @LAST_MATCH_START
504
505 =item @-
506
507 $-[0] is the offset of the start of the last successful match.
508 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
509 I<n>-th subpattern, or undef if the subpattern did not match.
510
511 Thus after a match against $_, $& coincides with C<substr $_, $-[0],
512 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
513 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
514 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the last
515 matched subgroup in the last successful match.  Contrast with
516 C<$#+>, the number of subgroups in the regular expression.  Compare
517 with C<@+>.
518
519 This array holds the offsets of the beginnings of the last
520 successful submatches in the currently active dynamic scope.
521 C<$-[0]> is the offset into the string of the beginning of the
522 entire match.  The I<n>th element of this array holds the offset
523 of the I<n>th submatch, so C<$-[1]> is the offset where $1
524 begins, C<$-[2]> the offset where $2 begins, and so on.
525
526 After a match against some variable $var:
527
528 =over 5
529
530 =item C<$`> is the same as C<substr($var, 0, $-[0])>
531
532 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
533
534 =item C<$'> is the same as C<substr($var, $+[0])>
535
536 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>  
537
538 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
539
540 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
541
542 =back
543
544 =item HANDLE->format_name(EXPR)
545
546 =item $FORMAT_NAME
547
548 =item $~
549
550 The name of the current report format for the currently selected output
551 channel.  Default is the name of the filehandle.  (Mnemonic: brother to
552 C<$^>.)
553
554 =item HANDLE->format_top_name(EXPR)
555
556 =item $FORMAT_TOP_NAME
557
558 =item $^
559
560 The name of the current top-of-page format for the currently selected
561 output channel.  Default is the name of the filehandle with _TOP
562 appended.  (Mnemonic: points to top of page.)
563
564 =item IO::Handle->format_line_break_characters EXPR
565
566 =item $FORMAT_LINE_BREAK_CHARACTERS
567
568 =item $:
569
570 The current set of characters after which a string may be broken to
571 fill continuation fields (starting with ^) in a format.  Default is
572 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
573 poetry is a part of a line.)
574
575 =item IO::Handle->format_formfeed EXPR
576
577 =item $FORMAT_FORMFEED
578
579 =item $^L
580
581 What formats output as a form feed.  Default is \f.
582
583 =item $ACCUMULATOR
584
585 =item $^A
586
587 The current value of the write() accumulator for format() lines.  A format
588 contains formline() calls that put their result into C<$^A>.  After
589 calling its format, write() prints out the contents of C<$^A> and empties.
590 So you never really see the contents of C<$^A> unless you call
591 formline() yourself and then look at it.  See L<perlform> and
592 L<perlfunc/formline()>.
593
594 =item $CHILD_ERROR
595
596 =item $?
597
598 The status returned by the last pipe close, backtick (C<``>) command,
599 successful call to wait() or waitpid(), or from the system()
600 operator.  This is just the 16-bit status word returned by the
601 traditional Unix wait() system call (or else is made up to look like it).  Thus, the
602 exit value of the subprocess is really (C<<< $? >> 8 >>>), and
603 C<$? & 127> gives which signal, if any, the process died from, and
604 C<$? & 128> reports whether there was a core dump.  (Mnemonic:
605 similar to B<sh> and B<ksh>.)
606
607 Additionally, if the C<h_errno> variable is supported in C, its value
608 is returned via $? if any C<gethost*()> function fails.
609
610 If you have installed a signal handler for C<SIGCHLD>, the
611 value of C<$?> will usually be wrong outside that handler.
612
613 Inside an C<END> subroutine C<$?> contains the value that is going to be
614 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
615 change the exit status of your program.  For example:
616
617     END {
618         $? = 1 if $? == 255;  # die would make it 255
619     } 
620
621 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
622 actual VMS exit status, instead of the default emulation of POSIX
623 status; see L<perlvms/$?> for details.
624
625 Also see L<Error Indicators>.
626
627 =item ${^CHILD_ERROR_NATIVE}
628
629 The native status returned by the last pipe close, backtick (C<``>)
630 command, successful call to wait() or waitpid(), or from the system()
631 operator.  On POSIX-like systems this value can be decoded with the
632 WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED, WSTOPSIG
633 and WIFCONTINUED functions provided by the L<POSIX> module.
634
635 Under VMS this reflects the actual VMS exit status; i.e. it is the same
636 as $? when the pragma C<use vmsish 'status'> is in effect.
637
638 =item ${^ENCODING}
639
640 The I<object reference> to the Encode object that is used to convert
641 the source code to Unicode.  Thanks to this variable your perl script
642 does not have to be written in UTF-8.  Default is I<undef>.  The direct
643 manipulation of this variable is highly discouraged.  See L<encoding>
644 for more details.
645
646 =item $OS_ERROR
647
648 =item $ERRNO
649
650 =item $!
651
652 If used numerically, yields the current value of the C C<errno>
653 variable, or in other words, if a system or library call fails, it
654 sets this variable.  This means that the value of C<$!> is meaningful
655 only I<immediately> after a B<failure>:
656
657     if (open(FH, $filename)) {
658         # Here $! is meaningless.
659         ...
660     } else {
661         # ONLY here is $! meaningful.
662         ...
663         # Already here $! might be meaningless.
664     }
665     # Since here we might have either success or failure,
666     # here $! is meaningless.
667
668 In the above I<meaningless> stands for anything: zero, non-zero,
669 C<undef>.  A successful system or library call does B<not> set
670 the variable to zero.
671
672 If used as a string, yields the corresponding system error string.
673 You can assign a number to C<$!> to set I<errno> if, for instance,
674 you want C<"$!"> to return the string for error I<n>, or you want
675 to set the exit value for the die() operator.  (Mnemonic: What just
676 went bang?)
677
678 Also see L<Error Indicators>.
679
680 =item %!
681
682 Each element of C<%!> has a true value only if C<$!> is set to that
683 value.  For example, C<$!{ENOENT}> is true if and only if the current
684 value of C<$!> is C<ENOENT>; that is, if the most recent error was
685 "No such file or directory" (or its moral equivalent: not all operating
686 systems give that exact error, and certainly not all languages).
687 To check if a particular key is meaningful on your system, use
688 C<exists $!{the_key}>; for a list of legal keys, use C<keys %!>.
689 See L<Errno> for more information, and also see above for the
690 validity of C<$!>.
691
692 =item $EXTENDED_OS_ERROR
693
694 =item $^E
695
696 Error information specific to the current operating system.  At
697 the moment, this differs from C<$!> under only VMS, OS/2, and Win32
698 (and for MacPerl).  On all other platforms, C<$^E> is always just
699 the same as C<$!>.
700
701 Under VMS, C<$^E> provides the VMS status value from the last
702 system error.  This is more specific information about the last
703 system error than that provided by C<$!>.  This is particularly
704 important when C<$!> is set to B<EVMSERR>.
705
706 Under OS/2, C<$^E> is set to the error code of the last call to
707 OS/2 API either via CRT, or directly from perl.
708
709 Under Win32, C<$^E> always returns the last error information
710 reported by the Win32 call C<GetLastError()> which describes
711 the last error from within the Win32 API.  Most Win32-specific
712 code will report errors via C<$^E>.  ANSI C and Unix-like calls
713 set C<errno> and so most portable Perl code will report errors
714 via C<$!>. 
715
716 Caveats mentioned in the description of C<$!> generally apply to
717 C<$^E>, also.  (Mnemonic: Extra error explanation.)
718
719 Also see L<Error Indicators>.
720
721 =item $EVAL_ERROR
722
723 =item $@
724
725 The Perl syntax error message from the last eval() operator.
726 If $@ is the null string, the last eval() parsed and executed
727 correctly (although the operations you invoked may have failed in the
728 normal fashion).  (Mnemonic: Where was the syntax error "at"?)
729
730 Warning messages are not collected in this variable.  You can,
731 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
732 as described below.
733
734 Also see L<Error Indicators>.
735
736 =item $PROCESS_ID
737
738 =item $PID
739
740 =item $$
741
742 The process number of the Perl running this script.  You should
743 consider this variable read-only, although it will be altered
744 across fork() calls.  (Mnemonic: same as shells.)
745
746 Note for Linux users: on Linux, the C functions C<getpid()> and
747 C<getppid()> return different values from different threads. In order to
748 be portable, this behavior is not reflected by C<$$>, whose value remains
749 consistent across threads. If you want to call the underlying C<getpid()>,
750 you may use the CPAN module C<Linux::Pid>.
751
752 =item $REAL_USER_ID
753
754 =item $UID
755
756 =item $<
757
758 The real uid of this process.  (Mnemonic: it's the uid you came I<from>,
759 if you're running setuid.)  You can change both the real uid and
760 the effective uid at the same time by using POSIX::setuid().  Since
761 changes to $< require a system call, check $! after a change attempt to 
762 detect any possible errors.
763
764 =item $EFFECTIVE_USER_ID
765
766 =item $EUID
767
768 =item $>
769
770 The effective uid of this process.  Example:
771
772     $< = $>;            # set real to effective uid
773     ($<,$>) = ($>,$<);  # swap real and effective uid
774
775 You can change both the effective uid and the real uid at the same
776 time by using POSIX::setuid().  Changes to $> require a check to $!
777 to detect any possible errors after an attempted change. 
778
779 (Mnemonic: it's the uid you went I<to>, if you're running setuid.)
780 C<< $< >> and C<< $> >> can be swapped only on machines
781 supporting setreuid().
782
783 =item $REAL_GROUP_ID
784
785 =item $GID
786
787 =item $(
788
789 The real gid of this process.  If you are on a machine that supports
790 membership in multiple groups simultaneously, gives a space separated
791 list of groups you are in.  The first number is the one returned by
792 getgid(), and the subsequent ones by getgroups(), one of which may be
793 the same as the first number.
794
795 However, a value assigned to C<$(> must be a single number used to
796 set the real gid.  So the value given by C<$(> should I<not> be assigned
797 back to C<$(> without being forced numeric, such as by adding zero.
798
799 You can change both the real gid and the effective gid at the same
800 time by using POSIX::setgid().  Changes to $( require a check to $!
801 to detect any possible errors after an attempted change.
802
803 (Mnemonic: parentheses are used to I<group> things.  The real gid is the
804 group you I<left>, if you're running setgid.)
805
806 =item $EFFECTIVE_GROUP_ID
807
808 =item $EGID
809
810 =item $)
811
812 The effective gid of this process.  If you are on a machine that
813 supports membership in multiple groups simultaneously, gives a space
814 separated list of groups you are in.  The first number is the one
815 returned by getegid(), and the subsequent ones by getgroups(), one of
816 which may be the same as the first number.
817
818 Similarly, a value assigned to C<$)> must also be a space-separated
819 list of numbers.  The first number sets the effective gid, and
820 the rest (if any) are passed to setgroups().  To get the effect of an
821 empty list for setgroups(), just repeat the new effective gid; that is,
822 to force an effective gid of 5 and an effectively empty setgroups()
823 list, say C< $) = "5 5" >.
824
825 You can change both the effective gid and the real gid at the same
826 time by using POSIX::setgid() (use only a single numeric argument).
827 Changes to $) require a check to $! to detect any possible errors
828 after an attempted change.
829
830 (Mnemonic: parentheses are used to I<group> things.  The effective gid
831 is the group that's I<right> for you, if you're running setgid.)
832
833 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
834 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
835 and C<$)> can be swapped only on machines supporting setregid().
836
837 =item $PROGRAM_NAME
838
839 =item $0
840
841 Contains the name of the program being executed.
842
843 On some (read: not all) operating systems assigning to C<$0> modifies
844 the argument area that the C<ps> program sees.  On some platforms you
845 may have to use special C<ps> options or a different C<ps> to see the
846 changes.  Modifying the $0 is more useful as a way of indicating the
847 current program state than it is for hiding the program you're
848 running.  (Mnemonic: same as B<sh> and B<ksh>.)
849
850 Note that there are platform specific limitations on the maximum
851 length of C<$0>.  In the most extreme case it may be limited to the
852 space occupied by the original C<$0>.
853
854 In some platforms there may be arbitrary amount of padding, for
855 example space characters, after the modified name as shown by C<ps>.
856 In some platforms this padding may extend all the way to the original
857 length of the argument area, no matter what you do (this is the case
858 for example with Linux 2.2).
859
860 Note for BSD users: setting C<$0> does not completely remove "perl"
861 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
862 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
863 and the " (perl)" suffix are shown depends on your exact BSD variant
864 and version).  This is an operating system feature, Perl cannot help it.
865
866 In multithreaded scripts Perl coordinates the threads so that any
867 thread may modify its copy of the C<$0> and the change becomes visible
868 to ps(1) (assuming the operating system plays along).  Note that
869 the view of C<$0> the other threads have will not change since they
870 have their own copies of it.
871
872 =item $[
873
874 The index of the first element in an array, and of the first character
875 in a substring.  Default is 0, but you could theoretically set it
876 to 1 to make Perl behave more like B<awk> (or Fortran) when
877 subscripting and when evaluating the index() and substr() functions.
878 (Mnemonic: [ begins subscripts.)
879
880 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
881 directive, and cannot influence the behavior of any other file.
882 (That's why you can only assign compile-time constants to it.)
883 Its use is highly discouraged.
884
885 Note that, unlike other compile-time directives (such as L<strict>),
886 assignment to C<$[> can be seen from outer lexical scopes in the same file.
887 However, you can use local() on it to strictly bind its value to a
888 lexical block.
889
890 =item $]
891
892 The version + patchlevel / 1000 of the Perl interpreter.  This variable
893 can be used to determine whether the Perl interpreter executing a
894 script is in the right range of versions.  (Mnemonic: Is this version
895 of perl in the right bracket?)  Example:
896
897     warn "No checksumming!\n" if $] < 3.019;
898
899 See also the documentation of C<use VERSION> and C<require VERSION>
900 for a convenient way to fail if the running Perl interpreter is too old.
901
902 The floating point representation can sometimes lead to inaccurate
903 numeric comparisons.  See C<$^V> for a more modern representation of
904 the Perl version that allows accurate string comparisons.
905
906 =item $COMPILING
907
908 =item $^C
909
910 The current value of the flag associated with the B<-c> switch.
911 Mainly of use with B<-MO=...> to allow code to alter its behavior
912 when being compiled, such as for example to AUTOLOAD at compile
913 time rather than normal, deferred loading.  See L<perlcc>.  Setting
914 C<$^C = 1> is similar to calling C<B::minus_c>.
915
916 =item $DEBUGGING
917
918 =item $^D
919
920 The current value of the debugging flags.  (Mnemonic: value of B<-D>
921 switch.) May be read or set. Like its command-line equivalent, you can use
922 numeric or symbolic values, eg C<$^D = 10> or C<$^D = "st">.
923
924 =item ${^RE_DEBUG_FLAGS}
925
926 The current value of the regex debugging flags. Set to 0 for no debug output
927 even when the re 'debug' module is loaded. See L<re> for details.
928
929 =item ${^RE_TRIE_MAXBUF}
930
931 Controls how certain regex optimisations are applied and how much memory they
932 utilize. This value by default is 65536 which corresponds to a 512kB temporary
933 cache. Set this to a higher value to trade memory for speed when matching
934 large alternations. Set it to a lower value if you want the optimisations to
935 be as conservative of memory as possible but still occur, and set it to a
936 negative value to prevent the optimisation and conserve the most memory.
937 Under normal situations this variable should be of no interest to you.
938
939 =item $SYSTEM_FD_MAX
940
941 =item $^F
942
943 The maximum system file descriptor, ordinarily 2.  System file
944 descriptors are passed to exec()ed processes, while higher file
945 descriptors are not.  Also, during an open(), system file descriptors are
946 preserved even if the open() fails.  (Ordinary file descriptors are
947 closed before the open() is attempted.)  The close-on-exec
948 status of a file descriptor will be decided according to the value of
949 C<$^F> when the corresponding file, pipe, or socket was opened, not the
950 time of the exec().
951
952 =item $^H
953
954 WARNING: This variable is strictly for internal use only.  Its availability,
955 behavior, and contents are subject to change without notice.
956
957 This variable contains compile-time hints for the Perl interpreter.  At the
958 end of compilation of a BLOCK the value of this variable is restored to the
959 value when the interpreter started to compile the BLOCK.
960
961 When perl begins to parse any block construct that provides a lexical scope
962 (e.g., eval body, required file, subroutine body, loop body, or conditional
963 block), the existing value of $^H is saved, but its value is left unchanged.
964 When the compilation of the block is completed, it regains the saved value.
965 Between the points where its value is saved and restored, code that
966 executes within BEGIN blocks is free to change the value of $^H.
967
968 This behavior provides the semantic of lexical scoping, and is used in,
969 for instance, the C<use strict> pragma.
970
971 The contents should be an integer; different bits of it are used for
972 different pragmatic flags.  Here's an example:
973
974     sub add_100 { $^H |= 0x100 }
975
976     sub foo {
977         BEGIN { add_100() }
978         bar->baz($boon);
979     }
980
981 Consider what happens during execution of the BEGIN block.  At this point
982 the BEGIN block has already been compiled, but the body of foo() is still
983 being compiled.  The new value of $^H will therefore be visible only while
984 the body of foo() is being compiled.
985
986 Substitution of the above BEGIN block with:
987
988     BEGIN { require strict; strict->import('vars') }
989
990 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
991 version of the same lexical pragma:
992
993     BEGIN { require strict; strict->import('vars') if $condition }
994
995 =item %^H
996
997 WARNING: This variable is strictly for internal use only.  Its availability,
998 behavior, and contents are subject to change without notice.
999
1000 The %^H hash provides the same scoping semantic as $^H.  This makes it
1001 useful for implementation of lexically scoped pragmas.
1002
1003 =item $INPLACE_EDIT
1004
1005 =item $^I
1006
1007 The current value of the inplace-edit extension.  Use C<undef> to disable
1008 inplace editing.  (Mnemonic: value of B<-i> switch.)
1009
1010 =item $^M
1011
1012 By default, running out of memory is an untrappable, fatal error.
1013 However, if suitably built, Perl can use the contents of C<$^M>
1014 as an emergency memory pool after die()ing.  Suppose that your Perl
1015 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
1016 Then
1017
1018     $^M = 'a' x (1 << 16);
1019
1020 would allocate a 64K buffer for use in an emergency.  See the
1021 F<INSTALL> file in the Perl distribution for information on how to
1022 add custom C compilation flags when compiling perl.  To discourage casual
1023 use of this advanced feature, there is no L<English|English> long name for
1024 this variable.
1025
1026 =item $OSNAME
1027
1028 =item $^O
1029
1030 The name of the operating system under which this copy of Perl was
1031 built, as determined during the configuration process.  The value
1032 is identical to C<$Config{'osname'}>.  See also L<Config> and the 
1033 B<-V> command-line switch documented in L<perlrun>.
1034
1035 In Windows platforms, $^O is not very helpful: since it is always
1036 C<MSWin32>, it doesn't tell the difference between
1037 95/98/ME/NT/2000/XP/CE/.NET.  Use Win32::GetOSName() or
1038 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
1039 between the variants.
1040
1041 =item ${^OPEN}
1042
1043 An internal variable used by PerlIO.  A string in two parts, separated
1044 by a C<\0> byte, the first part describes the input layers, the second
1045 part describes the output layers.
1046
1047 =item $PERLDB
1048
1049 =item $^P
1050
1051 The internal variable for debugging support.  The meanings of the
1052 various bits are subject to change, but currently indicate:
1053
1054 =over 6
1055
1056 =item 0x01
1057
1058 Debug subroutine enter/exit.
1059
1060 =item 0x02
1061
1062 Line-by-line debugging.
1063
1064 =item 0x04
1065
1066 Switch off optimizations.
1067
1068 =item 0x08
1069
1070 Preserve more data for future interactive inspections.
1071
1072 =item 0x10
1073
1074 Keep info about source lines on which a subroutine is defined.
1075
1076 =item 0x20
1077
1078 Start with single-step on.
1079
1080 =item 0x40
1081
1082 Use subroutine address instead of name when reporting.
1083
1084 =item 0x80
1085
1086 Report C<goto &subroutine> as well.
1087
1088 =item 0x100
1089
1090 Provide informative "file" names for evals based on the place they were compiled.
1091
1092 =item 0x200
1093
1094 Provide informative names to anonymous subroutines based on the place they
1095 were compiled.
1096
1097 =item 0x400
1098
1099 Debug assertion subroutines enter/exit.
1100
1101 =back
1102
1103 Some bits may be relevant at compile-time only, some at
1104 run-time only.  This is a new mechanism and the details may change.
1105
1106 =item $LAST_REGEXP_CODE_RESULT
1107
1108 =item $^R
1109
1110 The result of evaluation of the last successful C<(?{ code })>
1111 regular expression assertion (see L<perlre>).  May be written to.
1112
1113 =item $EXCEPTIONS_BEING_CAUGHT
1114
1115 =item $^S
1116
1117 Current state of the interpreter.
1118
1119     $^S         State
1120     ---------   -------------------
1121     undef       Parsing module/eval
1122     true (1)    Executing an eval
1123     false (0)   Otherwise
1124
1125 The first state may happen in $SIG{__DIE__} and $SIG{__WARN__} handlers.
1126
1127 =item $BASETIME
1128
1129 =item $^T
1130
1131 The time at which the program began running, in seconds since the
1132 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
1133 and B<-C> filetests are based on this value.
1134
1135 =item ${^TAINT}
1136
1137 Reflects if taint mode is on or off.  1 for on (the program was run with
1138 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
1139 B<-t> or B<-TU>).  This variable is read-only.
1140
1141 =item ${^UNICODE}
1142
1143 Reflects certain Unicode settings of Perl.  See L<perlrun>
1144 documentation for the C<-C> switch for more information about
1145 the possible values. This variable is set during Perl startup
1146 and is thereafter read-only.
1147
1148 =item ${^UTF8CACHE}
1149
1150 This variable controls the state of the internal UTF-8 offset caching code.
1151 1 for on (the default), 0 for off, -1 to debug the caching code by checking
1152 all its results against linear scans, and panicking on any discrepancy.
1153
1154 =item ${^UTF8LOCALE}
1155
1156 This variable indicates whether an UTF-8 locale was detected by perl at
1157 startup. This information is used by perl when it's in
1158 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
1159 switch); see L<perlrun> for more info on this.
1160
1161 =item $PERL_VERSION
1162
1163 =item $^V
1164
1165 The revision, version, and subversion of the Perl interpreter, represented
1166 as a string composed of characters with those ordinals.  Thus in Perl v5.6.0
1167 it equals C<chr(5) . chr(6) . chr(0)> and will return true for
1168 C<$^V eq v5.6.0>.  Note that the characters in this string value can
1169 potentially be in Unicode range.
1170
1171 This can be used to determine whether the Perl interpreter executing a
1172 script is in the right range of versions.  (Mnemonic: use ^V for Version
1173 Control.)  Example:
1174
1175     warn "No \"our\" declarations!\n" if $^V and $^V lt v5.6.0;
1176
1177 To convert C<$^V> into its string representation use sprintf()'s
1178 C<"%vd"> conversion:
1179
1180     printf "version is v%vd\n", $^V;  # Perl's version
1181
1182 See the documentation of C<use VERSION> and C<require VERSION>
1183 for a convenient way to fail if the running Perl interpreter is too old.
1184
1185 See also C<$]> for an older representation of the Perl version.
1186
1187 =item $WARNING
1188
1189 =item $^W
1190
1191 The current value of the warning switch, initially true if B<-w>
1192 was used, false otherwise, but directly modifiable.  (Mnemonic:
1193 related to the B<-w> switch.)  See also L<warnings>.
1194
1195 =item ${^WARNING_BITS}
1196
1197 The current set of warning checks enabled by the C<use warnings> pragma.
1198 See the documentation of C<warnings> for more details.
1199
1200 =item $EXECUTABLE_NAME
1201
1202 =item $^X
1203
1204 The name used to execute the current copy of Perl, from C's
1205 C<argv[0]> or (where supported) F</proc/self/exe>.
1206
1207 Depending on the host operating system, the value of $^X may be
1208 a relative or absolute pathname of the perl program file, or may
1209 be the string used to invoke perl but not the pathname of the
1210 perl program file.  Also, most operating systems permit invoking
1211 programs that are not in the PATH environment variable, so there
1212 is no guarantee that the value of $^X is in PATH.  For VMS, the
1213 value may or may not include a version number.
1214
1215 You usually can use the value of $^X to re-invoke an independent
1216 copy of the same perl that is currently running, e.g.,
1217
1218   @first_run = `$^X -le "print int rand 100 for 1..100"`;
1219
1220 But recall that not all operating systems support forking or
1221 capturing of the output of commands, so this complex statement
1222 may not be portable.
1223
1224 It is not safe to use the value of $^X as a path name of a file,
1225 as some operating systems that have a mandatory suffix on
1226 executable files do not require use of the suffix when invoking
1227 a command.  To convert the value of $^X to a path name, use the
1228 following statements:
1229
1230   # Build up a set of file names (not command names).
1231   use Config;
1232   $this_perl = $^X;
1233   if ($^O ne 'VMS')
1234      {$this_perl .= $Config{_exe}
1235           unless $this_perl =~ m/$Config{_exe}$/i;}
1236
1237 Because many operating systems permit anyone with read access to
1238 the Perl program file to make a copy of it, patch the copy, and
1239 then execute the copy, the security-conscious Perl programmer
1240 should take care to invoke the installed copy of perl, not the
1241 copy referenced by $^X.  The following statements accomplish
1242 this goal, and produce a pathname that can be invoked as a
1243 command or referenced as a file.
1244
1245   use Config;
1246   $secure_perl_path = $Config{perlpath};
1247   if ($^O ne 'VMS')
1248      {$secure_perl_path .= $Config{_exe}
1249           unless $secure_perl_path =~ m/$Config{_exe}$/i;}
1250
1251 =item ARGV
1252
1253 The special filehandle that iterates over command-line filenames in
1254 C<@ARGV>. Usually written as the null filehandle in the angle operator
1255 C<< <> >>. Note that currently C<ARGV> only has its magical effect
1256 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1257 corresponding to the last file opened by C<< <> >>. In particular,
1258 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1259 may not cause your function to automatically read the contents of all the
1260 files in C<@ARGV>.
1261
1262 =item $ARGV
1263
1264 contains the name of the current file when reading from <>.
1265
1266 =item @ARGV
1267
1268 The array @ARGV contains the command-line arguments intended for
1269 the script.  C<$#ARGV> is generally the number of arguments minus
1270 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1271 command name itself.  See C<$0> for the command name.
1272
1273 =item ARGVOUT
1274
1275 The special filehandle that points to the currently open output file
1276 when doing edit-in-place processing with B<-i>.  Useful when you have
1277 to do a lot of inserting and don't want to keep modifying $_.  See
1278 L<perlrun> for the B<-i> switch.
1279
1280 =item @F
1281
1282 The array @F contains the fields of each line read in when autosplit
1283 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
1284 is package-specific, and must be declared or given a full package name
1285 if not in package main when running under C<strict 'vars'>.
1286
1287 =item @INC
1288
1289 The array @INC contains the list of places that the C<do EXPR>,
1290 C<require>, or C<use> constructs look for their library files.  It
1291 initially consists of the arguments to any B<-I> command-line
1292 switches, followed by the default Perl library, probably
1293 F</usr/local/lib/perl>, followed by ".", to represent the current
1294 directory.  ("." will not be appended if taint checks are enabled, either by
1295 C<-T> or by C<-t>.)  If you need to modify this at runtime, you should use
1296 the C<use lib> pragma to get the machine-dependent library properly
1297 loaded also:
1298
1299     use lib '/mypath/libdir/';
1300     use SomeMod;
1301
1302 You can also insert hooks into the file inclusion system by putting Perl
1303 code directly into @INC.  Those hooks may be subroutine references, array
1304 references or blessed objects.  See L<perlfunc/require> for details.
1305
1306 =item @_
1307
1308 Within a subroutine the array @_ contains the parameters passed to that
1309 subroutine.  See L<perlsub>.
1310
1311 =item %INC
1312
1313 The hash %INC contains entries for each filename included via the
1314 C<do>, C<require>, or C<use> operators.  The key is the filename
1315 you specified (with module names converted to pathnames), and the
1316 value is the location of the file found.  The C<require>
1317 operator uses this hash to determine whether a particular file has
1318 already been included.
1319
1320 If the file was loaded via a hook (e.g. a subroutine reference, see
1321 L<perlfunc/require> for a description of these hooks), this hook is
1322 by default inserted into %INC in place of a filename.  Note, however,
1323 that the hook may have set the %INC entry by itself to provide some more
1324 specific info.
1325
1326 =item %ENV
1327
1328 =item $ENV{expr}
1329
1330 The hash %ENV contains your current environment.  Setting a
1331 value in C<ENV> changes the environment for any child processes
1332 you subsequently fork() off.
1333
1334 =item %SIG
1335
1336 =item $SIG{expr}
1337
1338 The hash %SIG contains signal handlers for signals.  For example:
1339
1340     sub handler {       # 1st argument is signal name
1341         my($sig) = @_;
1342         print "Caught a SIG$sig--shutting down\n";
1343         close(LOG);
1344         exit(0);
1345     }
1346
1347     $SIG{'INT'}  = \&handler;
1348     $SIG{'QUIT'} = \&handler;
1349     ...
1350     $SIG{'INT'}  = 'DEFAULT';   # restore default action
1351     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
1352
1353 Using a value of C<'IGNORE'> usually has the effect of ignoring the
1354 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
1355 this special case.
1356
1357 Here are some other examples:
1358
1359     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
1360     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
1361     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
1362     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
1363
1364 Be sure not to use a bareword as the name of a signal handler,
1365 lest you inadvertently call it. 
1366
1367 If your system has the sigaction() function then signal handlers are
1368 installed using it.  This means you get reliable signal handling.
1369
1370 The default delivery policy of signals changed in Perl 5.8.0 from 
1371 immediate (also known as "unsafe") to deferred, also known as 
1372 "safe signals".  See L<perlipc> for more information.
1373
1374 Certain internal hooks can be also set using the %SIG hash.  The
1375 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
1376 about to be printed.  The warning message is passed as the first
1377 argument.  The presence of a __WARN__ hook causes the ordinary printing
1378 of warnings to STDERR to be suppressed.  You can use this to save warnings
1379 in a variable, or turn warnings into fatal errors, like this:
1380
1381     local $SIG{__WARN__} = sub { die $_[0] };
1382     eval $proggie;
1383
1384 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
1385 is about to be thrown.  The error message is passed as the first
1386 argument.  When a __DIE__ hook routine returns, the exception
1387 processing continues as it would have in the absence of the hook,
1388 unless the hook routine itself exits via a C<goto>, a loop exit, or a die().
1389 The C<__DIE__> handler is explicitly disabled during the call, so that you
1390 can die from a C<__DIE__> handler.  Similarly for C<__WARN__>.
1391
1392 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
1393 even inside an eval().  Do not use this to rewrite a pending exception
1394 in C<$@>, or as a bizarre substitute for overriding CORE::GLOBAL::die().
1395 This strange action at a distance may be fixed in a future release
1396 so that C<$SIG{__DIE__}> is only called if your program is about
1397 to exit, as was the original intent.  Any other use is deprecated.
1398
1399 C<__DIE__>/C<__WARN__> handlers are very special in one respect:
1400 they may be called to report (probable) errors found by the parser.
1401 In such a case the parser may be in inconsistent state, so any
1402 attempt to evaluate Perl code from such a handler will probably
1403 result in a segfault.  This means that warnings or errors that
1404 result from parsing Perl should be used with extreme caution, like
1405 this:
1406
1407     require Carp if defined $^S;
1408     Carp::confess("Something wrong") if defined &Carp::confess;
1409     die "Something wrong, but could not load Carp to give backtrace...
1410          To see backtrace try starting Perl with -MCarp switch";
1411
1412 Here the first line will load Carp I<unless> it is the parser who
1413 called the handler.  The second line will print backtrace and die if
1414 Carp was available.  The third line will be executed only if Carp was
1415 not available.
1416
1417 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
1418 L<warnings> for additional information.
1419
1420 =back
1421
1422 =head2 Error Indicators
1423
1424 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1425 about different types of error conditions that may appear during
1426 execution of a Perl program.  The variables are shown ordered by
1427 the "distance" between the subsystem which reported the error and
1428 the Perl process.  They correspond to errors detected by the Perl
1429 interpreter, C library, operating system, or an external program,
1430 respectively.
1431
1432 To illustrate the differences between these variables, consider the 
1433 following Perl expression, which uses a single-quoted string:
1434
1435     eval q{
1436         open my $pipe, "/cdrom/install |" or die $!;
1437         my @res = <$pipe>;
1438         close $pipe or die "bad pipe: $?, $!";
1439     };
1440
1441 After execution of this statement all 4 variables may have been set.  
1442
1443 C<$@> is set if the string to be C<eval>-ed did not compile (this
1444 may happen if C<open> or C<close> were imported with bad prototypes),
1445 or if Perl code executed during evaluation die()d .  In these cases
1446 the value of $@ is the compile error, or the argument to C<die>
1447 (which will interpolate C<$!> and C<$?>).  (See also L<Fatal>,
1448 though.)
1449
1450 When the eval() expression above is executed, open(), C<< <PIPE> >>,
1451 and C<close> are translated to calls in the C run-time library and
1452 thence to the operating system kernel.  C<$!> is set to the C library's
1453 C<errno> if one of these calls fails. 
1454
1455 Under a few operating systems, C<$^E> may contain a more verbose
1456 error indicator, such as in this case, "CDROM tray not closed."
1457 Systems that do not support extended error messages leave C<$^E>
1458 the same as C<$!>.
1459
1460 Finally, C<$?> may be set to non-0 value if the external program
1461 F</cdrom/install> fails.  The upper eight bits reflect specific
1462 error conditions encountered by the program (the program's exit()
1463 value).   The lower eight bits reflect mode of failure, like signal
1464 death and core dump information  See wait(2) for details.  In
1465 contrast to C<$!> and C<$^E>, which are set only if error condition
1466 is detected, the variable C<$?> is set on each C<wait> or pipe
1467 C<close>, overwriting the old value.  This is more like C<$@>, which
1468 on every eval() is always set on failure and cleared on success.
1469
1470 For more details, see the individual descriptions at C<$@>, C<$!>, C<$^E>,
1471 and C<$?>.
1472
1473 =head2 Technical Note on the Syntax of Variable Names
1474
1475 Variable names in Perl can have several formats.  Usually, they
1476 must begin with a letter or underscore, in which case they can be
1477 arbitrarily long (up to an internal limit of 251 characters) and
1478 may contain letters, digits, underscores, or the special sequence
1479 C<::> or C<'>.  In this case, the part before the last C<::> or
1480 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
1481
1482 Perl variable names may also be a sequence of digits or a single
1483 punctuation or control character.  These names are all reserved for
1484 special uses by Perl; for example, the all-digits names are used
1485 to hold data captured by backreferences after a regular expression
1486 match.  Perl has a special syntax for the single-control-character
1487 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
1488 character.  For example, the notation C<$^W> (dollar-sign caret
1489 C<W>) is the scalar variable whose name is the single character
1490 control-C<W>.  This is better than typing a literal control-C<W>
1491 into your program.
1492
1493 Finally, new in Perl 5.6, Perl variable names may be alphanumeric
1494 strings that begin with control characters (or better yet, a caret).
1495 These variables must be written in the form C<${^Foo}>; the braces
1496 are not optional.  C<${^Foo}> denotes the scalar variable whose
1497 name is a control-C<F> followed by two C<o>'s.  These variables are
1498 reserved for future special uses by Perl, except for the ones that
1499 begin with C<^_> (control-underscore or caret-underscore).  No
1500 control-character name that begins with C<^_> will acquire a special
1501 meaning in any future version of Perl; such names may therefore be
1502 used safely in programs.  C<$^_> itself, however, I<is> reserved.
1503
1504 Perl identifiers that begin with digits, control characters, or
1505 punctuation characters are exempt from the effects of the C<package>
1506 declaration and are always forced to be in package C<main>; they are
1507 also exempt from C<strict 'vars'> errors.  A few other names are also
1508 exempt in these ways:
1509
1510         ENV             STDIN
1511         INC             STDOUT
1512         ARGV            STDERR
1513         ARGVOUT         _
1514         SIG
1515
1516 In particular, the new special C<${^_XYZ}> variables are always taken
1517 to be in package C<main>, regardless of any C<package> declarations
1518 presently in scope.  
1519
1520 =head1 BUGS
1521
1522 Due to an unfortunate accident of Perl's implementation, C<use
1523 English> imposes a considerable performance penalty on all regular
1524 expression matches in a program, regardless of whether they occur
1525 in the scope of C<use English>.  For that reason, saying C<use
1526 English> in libraries is strongly discouraged.  See the
1527 Devel::SawAmpersand module documentation from CPAN
1528 ( http://www.cpan.org/modules/by-module/Devel/ )
1529 for more information.
1530
1531 Having to even think about the C<$^S> variable in your exception
1532 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
1533 invites grievous and difficult to track down errors.  Avoid it
1534 and use an C<END{}> or CORE::GLOBAL::die override instead.