t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     require './test.pl';        # for which_perl() etc
   6     set_up_inc('../lib');
   7 }
   8
   9 use strict;
  10 use warnings;
  11 use Config;
  12
  13 my ($Null, $Curdir);
  14 if(eval {require File::Spec; 1}) {
  15     $Null = File::Spec->devnull;
  16     $Curdir = File::Spec->curdir;
  17 } else {
  18     die $@ unless is_miniperl();
  19     $Curdir = '.';
  20     diag("miniperl failed to load File::Spec, error is:\n$@");
  21     diag("\ncontinuing, assuming '.' for current directory. Some tests will be skipped.");
  22 }
  23
  24 if ($^O eq 'MSWin32') {
  25     # under minitest, buildcustomize sets this to 1, which means
  26     # nlinks isn't populated properly, allow nlinks tests to pass
  27     ${^WIN32_SLOPPY_STAT} = 0;
  28 }
  29
  30 plan tests => 110;
  31
  32 my $Perl = which_perl();
  33
  34 $ENV{LC_ALL}   = 'C';           # Forge English error messages.
  35 $ENV{LANGUAGE} = 'C';           # Ditto in GNU.
  36
  37 my $Is_Amiga   = $^O eq 'amigaos';
  38 my $Is_Cygwin  = $^O eq 'cygwin';
  39 my $Is_Darwin  = $^O eq 'darwin';
  40 my $Is_Dos     = $^O eq 'dos';
  41 my $Is_MSWin32 = $^O eq 'MSWin32';
  42 my $Is_NetWare = $^O eq 'NetWare';
  43 my $Is_OS2     = $^O eq 'os2';
  44 my $Is_Solaris = $^O eq 'solaris';
  45 my $Is_VMS     = $^O eq 'VMS';
  46 my $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
  47 my $Is_Android = $^O =~ /android/;
  48 my $Is_Dfly    = $^O eq 'dragonfly';
  49
  50 my $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare;
  51
  52 my $ufs_no_ctime = ($Is_Dfly || $Is_Darwin) && (() = `df -t ufs . 2>/dev/null`) == 2;
  53
  54 my $Is_linux_container = is_linux_container();
  55
  56 if ($Is_Cygwin && !is_miniperl) {
  57   require Win32;
  58   Win32->import;
  59 }
  60
  61 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  62    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  63
  64 my $tmpfile = tempfile();
  65 my $tmpfile_link = tempfile();
  66
  67 chmod 0666, $tmpfile;
  68 unlink_all $tmpfile;
  69 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  70 close FOO;
  71
  72 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  73
  74 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  75
  76 # The clock on a network filesystem might be different from the
  77 # system clock.
  78 my $Filesystem_Time_Offset = abs($mtime - time);
  79
  80 #nlink should if link support configured in Perl.
  81 SKIP: {
  82     skip "No link count - Hard link support not built in.", 1
  83         unless $Config{d_link};
  84
  85     is($nlink, 1, 'nlink on regular file');
  86 }
  87
  88 SKIP: {
  89   skip "mtime and ctime not reliable", 2
  90     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_Darwin;
  91
  92   ok( $mtime,           'mtime' );
  93   is( $mtime, $ctime,   'mtime == ctime' );
  94 }
  95
  96
  97 # Cygwin seems to have a 3 second granularity on its timestamps.
  98 my $funky_FAT_timestamps = $Is_Cygwin;
  99 sleep 3 if $funky_FAT_timestamps;
 100
 101 print FOO "Now is the time for all good men to come to.\n";
 102 close(FOO);
 103
 104 sleep 2;
 105
 106 my $has_link = 1;
 107 my $inaccurate_atime = 0;
 108 if (defined &Win32::IsWinNT && Win32::IsWinNT()) {
 109     if (Win32::FsType() ne 'NTFS') {
 110         $has_link            = 0;
 111         $inaccurate_atime    = 1;
 112     }
 113 }
 114
 115 SKIP: {
 116     skip "No link on this filesystem", 6 unless $has_link;
 117     unlink $tmpfile_link;
 118     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
 119     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
 120
 121     is( $@, '',         'link() implemented' );
 122     ok( $lnk_result,    'linked tmp testfile' );
 123     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
 124
 125     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
 126
 127     SKIP: {
 128         skip "No link count", 1 if $Config{dont_use_nlink};
 129         skip "Cygwin9X fakes hard links by copying", 1
 130           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
 131
 132         is($nlink, 2,     'Link count on hard linked file' );
 133     }
 134
 135     SKIP: {
 136         skip_if_miniperl("File::Spec not built for minitest", 2);
 137         my $cwd = File::Spec->rel2abs($Curdir);
 138         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
 139                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
 140                                         $mtime && $mtime == $ctime;
 141         skip "AFS has different mtime/ctime link semantics", 2
 142                                      if $cwd =~ m#$Config{'afsroot'}/#;
 143         skip "AmigaOS has different mtime/ctime link semantics", 2
 144                                      if $Is_Amiga;
 145         # Win32 could pass $mtime test but as FAT and NTFS have
 146         # no ctime concept $ctime is ALWAYS == $mtime
 147         # expect netware to be the same ...
 148         skip "No ctime concept on this OS", 2
 149                                      if $Is_MSWin32 || $ufs_no_ctime;
 150
 151         if( !ok($mtime, 'hard link mtime') ||
 152             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 153             print STDERR <<DIAG;
 154 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 155 # has this problem.  Building on the ClearCase VOBS filesystem may also
 156 # cause this failure.
 157 #
 158 # Some UFS implementations don't have a ctime concept, and thus are
 159 # expected to fail this test.
 160 DIAG
 161         }
 162     }
 163
 164 }
 165
 166 # truncate and touch $tmpfile.
 167 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 168 ok(-z \*F,     '-z on empty filehandle');
 169 ok(! -s \*F,   '   and -s');
 170 close F;
 171
 172 ok(-z $tmpfile,     '-z on empty file');
 173 ok(! -s $tmpfile,   '   and -s');
 174
 175 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 176 print F "hi\n";
 177 close F;
 178
 179 open(F, "<$tmpfile") || DIE("Can't open temp test file: $!");
 180 ok(!-z *F,     '-z on empty filehandle');
 181 ok( -s *F,   '   and -s');
 182 close F;
 183
 184 ok(! -z $tmpfile,   '-z on non-empty file');
 185 ok(-s $tmpfile,     '   and -s');
 186
 187
 188 # Strip all access rights from the file.
 189 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 190
 191 SKIP: {
 192     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 193
 194     SKIP: {
 195         # Going to try to switch away from root.  Might not work.
 196         my $olduid = $>;
 197         eval { $> = 1; };
 198         skip "Can't test if an admin user in miniperl", 2,
 199           if $Is_Cygwin && is_miniperl();
 200         skip "Can't test -r or -w meaningfully if you're superuser", 2
 201           if ($> == 0);
 202
 203         SKIP: {
 204             skip "Can't test -r meaningfully?", 1 if $Is_Dos;
 205             ok(!-r $tmpfile,    "   -r");
 206         }
 207
 208         ok(!-w $tmpfile,    "   -w");
 209
 210         # switch uid back (may not be implemented)
 211         eval { $> = $olduid; };
 212     }
 213
 214     ok(! -x $tmpfile,   '   -x');
 215 }
 216
 217
 218
 219 ok(chmod(0700,$tmpfile),    'chmod 0700');
 220 ok(-r $tmpfile,     '   -r');
 221 ok(-w $tmpfile,     '   -w');
 222
 223 SKIP: {
 224     skip "-x simply determines if a file ends in an executable suffix", 1
 225       if $Is_Dosish;
 226
 227     ok(-x $tmpfile,     '   -x');
 228 }
 229
 230 ok(  -f $tmpfile,   '   -f');
 231 ok(! -d $tmpfile,   '   !-d');
 232
 233 # Is this portable?
 234 ok(  -d '.',          '-d cwd' );
 235 ok(! -f '.',          '!-f cwd' );
 236
 237
 238 SKIP: {
 239     unlink($tmpfile_link);
 240     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 241     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 242
 243     is( $@, '',     'symlink() implemented' );
 244     ok( $symlink_rslt,      'symlink() ok' );
 245     ok(-l $tmpfile_link,    '-l');
 246 }
 247
 248 ok(-o $tmpfile,     '-o');
 249
 250 ok(-e $tmpfile,     '-e');
 251
 252 unlink($tmpfile_link);
 253 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 254
 255 SKIP: {
 256     skip "No character, socket or block special files", 6
 257       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 258     skip "/dev isn't available to test against", 6
 259       unless -d '/dev' && -r '/dev' && -x '/dev';
 260     skip "Skipping: unexpected ls output in MP-RAS", 6
 261       if $Is_MPRAS;
 262
 263     # VMS problem:  If GNV or other UNIX like tool is installed, then
 264     # sometimes Perl will find /bin/ls, and will try to run it.
 265     # But since Perl on VMS does not know to run it under Bash, it will
 266     # try to run the DCL verb LS.  And if the VMS product Language
 267     # Sensitive Editor is installed, or some other LS verb, that will
 268     # be run instead.  So do not do this until we can teach Perl
 269     # when to use BASH on VMS.
 270     skip "ls command not available to Perl in OpenVMS right now.", 6
 271       if $Is_VMS;
 272
 273     delete $ENV{CLICOLOR_FORCE};
 274     my $LS  = $Config{d_readlink} && !$Is_Android ? "ls -lL" : "ls -l";
 275     my $CMD = "$LS /dev 2>/dev/null";
 276     my $DEV = qx($CMD);
 277
 278     skip "$CMD failed", 6 if $DEV eq '';
 279
 280     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 281
 282     skip "opendir failed: $!", 6 if @DEV == 0;
 283
 284     # /dev/stdout might be either character special or a named pipe,
 285     # or a symlink, or a socket, depending on which OS and how are
 286     # you running the test, so let's censor that one away.
 287     # Similar remarks hold for stderr.
 288     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 289     @DEV =  grep { $_ ne 'stdout' } @DEV;
 290     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
 291     @DEV =  grep { $_ ne 'stderr' } @DEV;
 292
 293     # /dev/printer is also naughty: in IRIX it shows up as
 294     # Srwx-----, not srwx------.
 295     $DEV =~ s{^.+?\sprinter$}{}m;
 296     @DEV =  grep { $_ ne 'printer' } @DEV;
 297
 298     # If running as root, we will see .files in the ls result,
 299     # and readdir() will see them always.  Potential for conflict,
 300     # so let's weed them out.
 301     $DEV =~ s{^.+?\s\..+?$}{}m;
 302     @DEV =  grep { ! m{^\..+$} } @DEV;
 303
 304     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
 305     if ($^O eq 'irix') {
 306         $DEV =~ s{^S(.+?)}{s$1}mg;
 307     }
 308
 309     my $try = sub {
 310         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 311         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 312         my $c1 = scalar @c1;
 313         my $c2 = scalar @c2;
 314         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 315     };
 316
 317 {
 318     $try->('b', '-b');
 319     $try->('c', '-c');
 320     $try->('s', '-S');
 321 }
 322
 323 ok(! -b $Curdir,    '!-b cwd');
 324 ok(! -c $Curdir,    '!-c cwd');
 325 ok(! -S $Curdir,    '!-S cwd');
 326
 327 }
 328
 329 SKIP: {
 330     my($cnt, $uid);
 331     $cnt = $uid = 0;
 332
 333     # Find a set of directories that's very likely to have setuid files
 334     # but not likely to be *all* setuid files.
 335     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 336     skip "Can't find a setuid file to test with", 3 unless @bin;
 337
 338     for my $bin (@bin) {
 339         opendir BIN, $bin or die "Can't opendir $bin: $!";
 340         while (defined($_ = readdir BIN)) {
 341             $_ = "$bin/$_";
 342             $cnt++;
 343             $uid++ if -u;
 344             last if $uid && $uid < $cnt;
 345         }
 346     }
 347     closedir BIN;
 348
 349     skip "No setuid programs", 3 if $uid == 0;
 350
 351     isnt($cnt, 0,    'found some programs');
 352     isnt($uid, 0,    '  found some setuid programs');
 353     ok($uid < $cnt,  "    they're not all setuid");
 354 }
 355
 356
 357 # To assist in automated testing when a controlling terminal (/dev/tty)
 358 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 359 # can be set to skip the tests that need a tty.
 360 SKIP: {
 361     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 362     skip "Skipping TTY tests on linux containers", 4 if $Is_linux_container;
 363
 364     my $TTY = "/dev/tty";
 365
 366     SKIP: {
 367         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 368         skip "No TTY to test -t with", 2 unless -e $TTY;
 369
 370         open(TTY, $TTY) ||
 371           warn "Can't open $TTY--run t/TEST outside of make.\n";
 372         ok(-t TTY,  '-t');
 373         ok(-c TTY,  'tty is -c');
 374         close(TTY);
 375     }
 376     ok(! -t TTY,    '!-t on closed TTY filehandle');
 377
 378     {
 379         local our $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 380         ok(-t,          '-t on STDIN');
 381     }
 382 }
 383
 384 SKIP: {
 385     skip "No null device to test with", 1 unless -e $Null;
 386     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 387
 388     open(NULL, $Null) or DIE("Can't open $Null: $!");
 389     ok(! -t NULL,   'null device is not a TTY');
 390     close(NULL);
 391 }
 392
 393
 394 # These aren't strictly "stat" calls, but so what?
 395 my $statfile = './op/stat.t';
 396 ok(  -T $statfile,    '-T');
 397 ok(! -B $statfile,    '!-B');
 398 ok(-B $Perl,      '-B');
 399 ok(! -T $Perl,    '!-T');
 400
 401 open(FOO,$statfile);
 402 SKIP: {
 403     eval { -T FOO; };
 404     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 405
 406     is( $@, '',     '-T on filehandle causes no errors' );
 407
 408     ok(-T FOO,      '   -T');
 409     ok(! -B FOO,    '   !-B');
 410
 411     $_ = <FOO>;
 412     like($_, qr/perl/, 'after readline');
 413     ok(-T FOO,      '   still -T');
 414     ok(! -B FOO,    '   still -B');
 415     close(FOO);
 416
 417     open(FOO,$statfile);
 418     $_ = <FOO>;
 419     like($_, qr/perl/,      'reopened and after readline');
 420     ok(-T FOO,      '   still -T');
 421     ok(! -B FOO,    '   still !-B');
 422
 423     ok(seek(FOO,0,0),   'after seek');
 424     ok(-T FOO,          '   still -T');
 425     ok(! -B FOO,        '   still !-B');
 426
 427     # It's documented this way in perlfunc *shrug*
 428     () = <FOO>;
 429     ok(eof FOO,         'at EOF');
 430     ok(-T FOO,          '   still -T');
 431     ok(-B FOO,          '   now -B');
 432 }
 433 close(FOO);
 434
 435
 436 SKIP: {
 437     skip "No null device to test with", 2 unless -e $Null;
 438
 439     ok(-T $Null,  'null device is -T');
 440     ok(-B $Null,  '    and -B');
 441 }
 442
 443
 444 # and now, a few parsing tests:
 445 $_ = $tmpfile;
 446 ok(-f,      'bare -f   uses $_');
 447 ok(-f(),    '     -f() "');
 448
 449 unlink $tmpfile or print "# unlink failed: $!\n";
 450
 451 # bug id 20011101.069 (#7861)
 452 my @r = \stat($Curdir);
 453 is(scalar @r, 13,   'stat returns full 13 elements');
 454
 455 stat $0;
 456 eval { lstat _ };
 457 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 458     'lstat _ croaks after stat' );
 459 eval { lstat *_ };
 460 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 461     'lstat *_ croaks after stat' );
 462 eval { lstat \*_ };
 463 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 464     'lstat \*_ croaks after stat' );
 465 eval { -l _ };
 466 like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 467     '-l _ croaks after stat' );
 468
 469 lstat $0;
 470 eval { lstat _ };
 471 is( "$@", "", "lstat _ ok after lstat" );
 472 eval { -l _ };
 473 is( "$@", "", "-l _ ok after lstat" );
 474
 475 eval { lstat "test.pl" };
 476 {
 477     open my $fh, "test.pl";
 478     stat *$fh{IO};
 479     eval { lstat _ }
 480 }
 481 like $@, qr/^The stat preceding lstat\(\) wasn't an lstat at /,
 482 'stat $ioref resets stat type';
 483
 484 {
 485     open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
 486     my @statbuf = stat FOO;
 487     stat "test.pl";
 488     no warnings 'io';
 489     my @lstatbuf = lstat *FOO{IO};
 490     is "@lstatbuf", "@statbuf", 'lstat $ioref reverts to regular fstat';
 491     close(FOO);
 492     unlink $tmpfile or print "# unlink failed: $!\n";
 493 }
 494
 495 SKIP: {
 496     skip "No lstat", 2 unless $Config{d_lstat};
 497
 498     # bug id 20020124.004 (#8334)
 499     # If we have d_lstat, we should have symlink()
 500     my $linkname = 'stat-' . rand =~ y/.//dr;
 501     my $target = $Perl;
 502     $target =~ s/;\d+\z// if $Is_VMS; # symlinks don't like version numbers
 503     symlink $target, $linkname or die "# Can't symlink $0: $!";
 504     lstat $linkname;
 505     -T _;
 506     eval { lstat _ };
 507     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 508         'lstat croaks after -T _' );
 509     eval { -l _ };
 510     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 511         '-l _ croaks after -T _' );
 512     unlink $linkname or print "# unlink $linkname failed: $!\n";
 513 }
 514
 515 SKIP: {
 516     skip "Too much clock skew between system and filesystem", 5
 517         if ($Filesystem_Time_Offset > 5);
 518     print "# Zzz...\n";
 519     sleep($Filesystem_Time_Offset+1);
 520     my $f = 'tstamp.tmp';
 521     unlink $f;
 522     ok (open(S, "> $f"), 'can create tmp file');
 523     close S or die;
 524     my @a = stat $f;
 525     print "# time=$^T, stat=(@a)\n";
 526     my @b = (-M _, -A _, -C _);
 527     print "# -MAC=(@b)\n";
 528     ok( (-M _) < 0, 'negative -M works');
 529   SKIP:
 530     {
 531         skip "Access timestamps inaccurate", 1 if $inaccurate_atime;
 532         ok( (-A _) < 0, 'negative -A works');
 533     }
 534     ok( (-C _) < 0, 'negative -C works');
 535     ok(unlink($f), 'unlink tmp file');
 536 }
 537
 538 # [perl #4253]
 539 {
 540     ok(open(F, ">", $tmpfile), 'can create temp file');
 541     close F;
 542     chmod 0077, $tmpfile;
 543     my @a = stat($tmpfile);
 544     my $s1 = -s _;
 545     -T _;
 546     my $s2 = -s _;
 547     is($s1, $s2, q(-T _ doesn't break the statbuffer));
 548     SKIP: {
 549         my $root_uid = $Is_Cygwin ? 18 : 0;
 550         skip "No lstat", 1 unless $Config{d_lstat};
 551         skip "uid=0", 1 if $< == $root_uid or $> == $root_uid;
 552         skip "Can't check if admin user in miniperl", 1
 553           if $^O =~ /^(cygwin|MSWin32|msys)$/ && is_miniperl();
 554         skip "Readable by group/other means readable by me on $^O", 1 if $^O eq 'VMS'
 555           or ($^O =~ /^(cygwin|MSWin32|msys)$/ and Win32::IsAdminUser());
 556         lstat($tmpfile);
 557         -T _;
 558         ok(eval { lstat _ },
 559            q(-T _ doesn't break lstat for unreadable file));
 560     }
 561     unlink $tmpfile;
 562 }
 563
 564 SKIP: {
 565     skip "No dirfd()", 4 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 566     ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 567     ok(stat(DIR), "stat() on dirhandle works");
 568     ok(-d -r _ , "chained -x's on dirhandle");
 569     ok(-d DIR, "-d on a dirhandle works");
 570     closedir DIR or die $!;
 571 }
 572
 573 {
 574     # RT #8244: *FILE{IO} does not behave like *FILE for stat() and -X() operators
 575     ok(open(F, ">", $tmpfile), 'can create temp file');
 576     my @thwap = stat *F{IO};
 577     ok(@thwap, "stat(*F{IO}) works");
 578     ok( -f *F{IO} , "single file tests work with *F{IO}");
 579     close F;
 580     unlink $tmpfile;
 581
 582     #PVIO's hold dirhandle information, so let's test them too.
 583
 584     SKIP: {
 585         skip "No dirfd()", 4 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 586         ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 587         ok(stat(*DIR{IO}), "stat() on *DIR{IO} works");
 588         ok(-d _ , "The special file handle _ is set correctly");
 589         ok(-d -r *DIR{IO} , "chained -x's on *DIR{IO}");
 590         closedir DIR or die $!;
 591     }
 592 }
 593
 594 # [perl #71002]
 595 {
 596     my $w;
 597     local $SIG{__WARN__} = sub { warn shift; ++$w };
 598     stat 'prepeinamehyparcheiarcheiometoonomaavto';
 599     stat _;
 600     is $w, undef, 'no unopened warning from stat _';
 601 }
 602
 603 {
 604     # [perl #123816]
 605     # Inappropriate stacking of l?stat with filetests should either work or
 606     # give a syntax error, they shouldn't crash.
 607     eval { stat -t };
 608     ok(1, 'can "stat -t" without crashing');
 609         eval { lstat -t };
 610     ok(1, 'can "lstat -t" without crashing');
 611 }
 612
 613 # [perl #126064] stat stat stack busting
 614 is join("-", 1,2,3,(stat stat stat),4,5,6), "1-2-3-4-5-6",
 615   'stat inside stat gets scalar context';
 616
 617 # [perl #126162] stat an array should not work
 618 # skip if -e '2'.
 619 SKIP:
 620 {
 621     skip "There is a file named '2', which invalidates this test", 2 if -e '2';
 622
 623     my $Errno_loaded = eval { require Errno };
 624     my @statarg = ($statfile, $statfile);
 625     no warnings 'syntax';
 626     ok !stat(@statarg),
 627     'stat on an array of valid paths should warn and should not return any data';
 628     my $error = 0+$!;
 629     skip "Errno not available", 1
 630       unless $Errno_loaded;
 631     is $error, &Errno::ENOENT,
 632       'stat on an array of valid paths should return ENOENT';
 633 }
 634
 635 # [perl #131895] stat() doesn't fail on filenames containing \0 / NUL
 636 {
 637     no warnings 'syscalls';
 638     ok !stat("TEST\0-"), 'stat on filename with \0';
 639 }
 640 SKIP: {
 641     my $link = "stat_t_$$\_TEST.symlink";
 642     my $can_symlink = eval { symlink "TEST", $link };
 643     skip "cannot symlink", 1 unless $can_symlink;
 644     no warnings 'syscalls';
 645     ok !lstat("$link\0-"), 'lstat on filename with \0';
 646     unlink $link;
 647 }
 648
 649 END {
 650     chmod 0666, $tmpfile;
 651     unlink_all $tmpfile;
 652 }