pod/perluniintro.pod

   1 =head1 NAME
   2
   3 perluniintro - Perl Unicode introduction
   4
   5 =head1 DESCRIPTION
   6
   7 This document gives a general idea of Unicode and how to use Unicode
   8 in Perl.  See L</Further Resources> for references to more in-depth
   9 treatments of Unicode.
  10
  11 =head2 Unicode
  12
  13 Unicode is a character set standard which plans to codify all of the
  14 writing systems of the world, plus many other symbols.
  15
  16 Unicode and ISO/IEC 10646 are coordinated standards that unify
  17 almost all other modern character set standards,
  18 covering more than 80 writing systems and hundreds of languages,
  19 including all commercially-important modern languages.  All characters
  20 in the largest Chinese, Japanese, and Korean dictionaries are also
  21 encoded. The standards will eventually cover almost all characters in
  22 more than 250 writing systems and thousands of languages.
  23 Unicode 1.0 was released in October 1991, and 6.0 in October 2010.
  24
  25 A Unicode I<character> is an abstract entity.  It is not bound to any
  26 particular integer width, especially not to the C language C<char>.
  27 Unicode is language-neutral and display-neutral: it does not encode the
  28 language of the text, and it does not generally define fonts or other graphical
  29 layout details.  Unicode operates on characters and on text built from
  30 those characters.
  31
  32 Unicode defines characters like C<LATIN CAPITAL LETTER A> or C<GREEK
  33 SMALL LETTER ALPHA> and unique numbers for the characters, in this
  34 case 0x0041 and 0x03B1, respectively.  These unique numbers are called
  35 I<code points>.  A code point is essentially the position of the
  36 character within the set of all possible Unicode characters, and thus in
  37 Perl, the term I<ordinal> is often used interchangeably with it.
  38
  39 The Unicode standard prefers using hexadecimal notation for the code
  40 points.  If numbers like C<0x0041> are unfamiliar to you, take a peek
  41 at a later section, L</"Hexadecimal Notation">.  The Unicode standard
  42 uses the notation C<U+0041 LATIN CAPITAL LETTER A>, to give the
  43 hexadecimal code point and the normative name of the character.
  44
  45 Unicode also defines various I<properties> for the characters, like
  46 "uppercase" or "lowercase", "decimal digit", or "punctuation";
  47 these properties are independent of the names of the characters.
  48 Furthermore, various operations on the characters like uppercasing,
  49 lowercasing, and collating (sorting) are defined.
  50
  51 A Unicode I<logical> "character" can actually consist of more than one internal
  52 I<actual> "character" or code point.  For Western languages, this is adequately
  53 modelled by a I<base character> (like C<LATIN CAPITAL LETTER A>) followed
  54 by one or more I<modifiers> (like C<COMBINING ACUTE ACCENT>).  This sequence of
  55 base character and modifiers is called a I<combining character
  56 sequence>.  Some non-western languages require more complicated
  57 models, so Unicode created the I<grapheme cluster> concept, which was
  58 later further refined into the I<extended grapheme cluster>.  For
  59 example, a Korean Hangul syllable is considered a single logical
  60 character, but most often consists of three actual
  61 Unicode characters: a leading consonant followed by an interior vowel followed
  62 by a trailing consonant.
  63
  64 Whether to call these extended grapheme clusters "characters" depends on your
  65 point of view. If you are a programmer, you probably would tend towards seeing
  66 each element in the sequences as one unit, or "character".  However from
  67 the user's point of view, the whole sequence could be seen as one
  68 "character" since that's probably what it looks like in the context of the
  69 user's language.  In this document, we take the programmer's point of
  70 view: one "character" is one Unicode code point.
  71
  72 For some combinations of base character and modifiers, there are
  73 I<precomposed> characters.  There is a single character equivalent, for
  74 example, for the sequence C<LATIN CAPITAL LETTER A> followed by
  75 C<COMBINING ACUTE ACCENT>.  It is called  C<LATIN CAPITAL LETTER A WITH
  76 ACUTE>.  These precomposed characters are, however, only available for
  77 some combinations, and are mainly meant to support round-trip
  78 conversions between Unicode and legacy standards (like ISO 8859).  Using
  79 sequences, as Unicode does, allows for needing fewer basic building blocks
  80 (code points) to express many more potential grapheme clusters.  To
  81 support conversion between equivalent forms, various I<normalization
  82 forms> are also defined.  Thus, C<LATIN CAPITAL LETTER A WITH ACUTE> is
  83 in I<Normalization Form Composed>, (abbreviated NFC), and the sequence
  84 C<LATIN CAPITAL LETTER A> followed by C<COMBINING ACUTE ACCENT>
  85 represents the same character in I<Normalization Form Decomposed> (NFD).
  86
  87 Because of backward compatibility with legacy encodings, the "a unique
  88 number for every character" idea breaks down a bit: instead, there is
  89 "at least one number for every character".  The same character could
  90 be represented differently in several legacy encodings.  The
  91 converse is not true: some code points do not have an assigned
  92 character.  Firstly, there are unallocated code points within
  93 otherwise used blocks.  Secondly, there are special Unicode control
  94 characters that do not represent true characters.
  95
  96 When Unicode was first conceived, it was thought that all the world's
  97 characters could be represented using a 16-bit word; that is a maximum of
  98 C<0x10000> (or 65,536) characters would be needed, from C<0x0000> to
  99 C<0xFFFF>.  This soon proved to be wrong, and since Unicode 2.0 (July
 100 1996), Unicode has been defined all the way up to 21 bits (C<0x10FFFF>),
 101 and Unicode 3.1 (March 2001) defined the first characters above C<0xFFFF>.
 102 The first C<0x10000> characters are called the I<Plane 0>, or the
 103 I<Basic Multilingual Plane> (BMP).  With Unicode 3.1, 17 (yes,
 104 seventeen) planes in all were defined--but they are nowhere near full of
 105 defined characters, yet.
 106
 107 When a new language is being encoded, Unicode generally will choose a
 108 C<block> of consecutive unallocated code points for its characters.  So
 109 far, the number of code points in these blocks has always been evenly
 110 divisible by 16.  Extras in a block, not currently needed, are left
 111 unallocated, for future growth.  But there have been occasions when
 112 a later release needed more code points than the available extras, and a
 113 new block had to allocated somewhere else, not contiguous to the initial
 114 one, to handle the overflow.  Thus, it became apparent early on that
 115 "block" wasn't an adequate organizing principle, and so the C<Script>
 116 property was created.  (Later an improved script property was added as
 117 well, the C<Script_Extensions> property.)  Those code points that are in
 118 overflow blocks can still
 119 have the same script as the original ones.  The script concept fits more
 120 closely with natural language: there is C<Latin> script, C<Greek>
 121 script, and so on; and there are several artificial scripts, like
 122 C<Common> for characters that are used in multiple scripts, such as
 123 mathematical symbols.  Scripts usually span varied parts of several
 124 blocks.  For more information about scripts, see L<perlunicode/Scripts>.
 125 The division into blocks exists, but it is almost completely
 126 accidental--an artifact of how the characters have been and still are
 127 allocated.  (Note that this paragraph has oversimplified things for the
 128 sake of this being an introduction.  Unicode doesn't really encode
 129 languages, but the writing systems for them--their scripts; and one
 130 script can be used by many languages.  Unicode also encodes things that
 131 aren't really about languages, such as symbols like C<BAGGAGE CLAIM>.)
 132
 133 The Unicode code points are just abstract numbers.  To input and
 134 output these abstract numbers, the numbers must be I<encoded> or
 135 I<serialised> somehow.  Unicode defines several I<character encoding
 136 forms>, of which I<UTF-8> is the most popular.  UTF-8 is a
 137 variable length encoding that encodes Unicode characters as 1 to 4
 138 bytes.  Other encodings
 139 include UTF-16 and UTF-32 and their big- and little-endian variants
 140 (UTF-8 is byte-order independent).  The ISO/IEC 10646 defines the UCS-2
 141 and UCS-4 encoding forms.
 142
 143 For more information about encodings--for instance, to learn what
 144 I<surrogates> and I<byte order marks> (BOMs) are--see L<perlunicode>.
 145
 146 =head2 Perl's Unicode Support
 147
 148 Starting from Perl v5.6.0, Perl has had the capacity to handle Unicode
 149 natively.  Perl v5.8.0, however, is the first recommended release for
 150 serious Unicode work.  The maintenance release 5.6.1 fixed many of the
 151 problems of the initial Unicode implementation, but for example
 152 regular expressions still do not work with Unicode in 5.6.1.
 153 Perl v5.14.0 is the first release where Unicode support is
 154 (almost) seamlessly integrable without some gotchas. (There are two
 155 exceptions. Firstly, some differences in L<quotemeta|perlfunc/quotemeta>
 156 were fixed starting in Perl 5.16.0. Secondly, some differences in
 157 L<the range operator|perlop/Range Operators> were fixed starting in
 158 Perl 5.26.0.)
 159
 160 To enable this
 161 seamless support, you should C<use feature 'unicode_strings'> (which is
 162 automatically selected if you C<use 5.012> or higher).  See L<feature>.
 163 (5.14 also fixes a number of bugs and departures from the Unicode
 164 standard.)
 165
 166 Before Perl v5.8.0, the use of C<use utf8> was used to declare
 167 that operations in the current block or file would be Unicode-aware.
 168 This model was found to be wrong, or at least clumsy: the "Unicodeness"
 169 is now carried with the data, instead of being attached to the
 170 operations.
 171 Starting with Perl v5.8.0, only one case remains where an explicit C<use
 172 utf8> is needed: if your Perl script itself is encoded in UTF-8, you can
 173 use UTF-8 in your identifier names, and in string and regular expression
 174 literals, by saying C<use utf8>.  This is not the default because
 175 scripts with legacy 8-bit data in them would break.  See L<utf8>.
 176
 177 =head2 Perl's Unicode Model
 178
 179 Perl supports both pre-5.6 strings of eight-bit native bytes, and
 180 strings of Unicode characters.  The general principle is that Perl tries
 181 to keep its data as eight-bit bytes for as long as possible, but as soon
 182 as Unicodeness cannot be avoided, the data is transparently upgraded
 183 to Unicode.  Prior to Perl v5.14.0, the upgrade was not completely
 184 transparent (see L<perlunicode/The "Unicode Bug">), and for backwards
 185 compatibility, full transparency is not gained unless C<use feature
 186 'unicode_strings'> (see L<feature>) or C<use 5.012> (or higher) is
 187 selected.
 188
 189 Internally, Perl currently uses either whatever the native eight-bit
 190 character set of the platform (for example Latin-1) is, defaulting to
 191 UTF-8, to encode Unicode strings. Specifically, if all code points in
 192 the string are C<0xFF> or less, Perl uses the native eight-bit
 193 character set.  Otherwise, it uses UTF-8.
 194
 195 A user of Perl does not normally need to know nor care how Perl
 196 happens to encode its internal strings, but it becomes relevant when
 197 outputting Unicode strings to a stream without a PerlIO layer (one with
 198 the "default" encoding).  In such a case, the raw bytes used internally
 199 (the native character set or UTF-8, as appropriate for each string)
 200 will be used, and a "Wide character" warning will be issued if those
 201 strings contain a character beyond 0x00FF.
 202
 203 For example,
 204
 205       perl -e 'print "\x{DF}\n", "\x{0100}\x{DF}\n"'
 206
 207 produces a fairly useless mixture of native bytes and UTF-8, as well
 208 as a warning:
 209
 210      Wide character in print at ...
 211
 212 To output UTF-8, use the C<:encoding> or C<:utf8> output layer.  Prepending
 213
 214       binmode(STDOUT, ":utf8");
 215
 216 to this sample program ensures that the output is completely UTF-8,
 217 and removes the program's warning.
 218
 219 You can enable automatic UTF-8-ification of your standard file
 220 handles, default C<open()> layer, and C<@ARGV> by using either
 221 the C<-C> command line switch or the C<PERL_UNICODE> environment
 222 variable, see L<perlrun> for the documentation of the C<-C> switch.
 223
 224 Note that this means that Perl expects other software to work the same
 225 way:
 226 if Perl has been led to believe that STDIN should be UTF-8, but then
 227 STDIN coming in from another command is not UTF-8, Perl will likely
 228 complain about the malformed UTF-8.
 229
 230 All features that combine Unicode and I/O also require using the new
 231 PerlIO feature.  Almost all Perl 5.8 platforms do use PerlIO, though:
 232 you can see whether yours is by running "perl -V" and looking for
 233 C<useperlio=define>.
 234
 235 =head2 Unicode and EBCDIC
 236
 237 Perl 5.8.0 added support for Unicode on EBCDIC platforms.  This support
 238 was allowed to lapse in later releases, but was revived in 5.22.
 239 Unicode support is somewhat more complex to implement since additional
 240 conversions are needed.  See L<perlebcdic> for more information.
 241
 242 On EBCDIC platforms, the internal Unicode encoding form is UTF-EBCDIC
 243 instead of UTF-8.  The difference is that as UTF-8 is "ASCII-safe" in
 244 that ASCII characters encode to UTF-8 as-is, while UTF-EBCDIC is
 245 "EBCDIC-safe", in that all the basic characters (which includes all
 246 those that have ASCII equivalents (like C<"A">, C<"0">, C<"%">, I<etc.>)
 247 are the same in both EBCDIC and UTF-EBCDIC.  Often, documentation
 248 will use the term "UTF-8" to mean UTF-EBCDIC as well.  This is the case
 249 in this document.
 250
 251 =head2 Creating Unicode
 252
 253 This section applies fully to Perls starting with v5.22.  Various
 254 caveats for earlier releases are in the L</Earlier releases caveats>
 255 subsection below.
 256
 257 To create Unicode characters in literals,
 258 use the C<\N{...}> notation in double-quoted strings:
 259
 260  my $smiley_from_name = "\N{WHITE SMILING FACE}";
 261  my $smiley_from_code_point = "\N{U+263a}";
 262
 263 Similarly, they can be used in regular expression literals
 264
 265  $smiley =~ /\N{WHITE SMILING FACE}/;
 266  $smiley =~ /\N{U+263a}/;
 267
 268 At run-time you can use:
 269
 270  use charnames ();
 271  my $hebrew_alef_from_name
 272                       = charnames::string_vianame("HEBREW LETTER ALEF");
 273  my $hebrew_alef_from_code_point = charnames::string_vianame("U+05D0");
 274
 275 Naturally, C<ord()> will do the reverse: it turns a character into
 276 a code point.
 277
 278 There are other runtime options as well.  You can use C<pack()>:
 279
 280  my $hebrew_alef_from_code_point = pack("U", 0x05d0);
 281
 282 Or you can use C<chr()>, though it is less convenient in the general
 283 case:
 284
 285  $hebrew_alef_from_code_point = chr(utf8::unicode_to_native(0x05d0));
 286  utf8::upgrade($hebrew_alef_from_code_point);
 287
 288 The C<utf8::unicode_to_native()> and C<utf8::upgrade()> aren't needed if
 289 the argument is above 0xFF, so the above could have been written as
 290
 291  $hebrew_alef_from_code_point = chr(0x05d0);
 292
 293 since 0x5d0 is above 255.
 294
 295 C<\x{}> and C<\o{}> can also be used to specify code points at compile
 296 time in double-quotish strings, but, for backward compatibility with
 297 older Perls, the same rules apply as with C<chr()> for code points less
 298 than 256.
 299
 300 C<utf8::unicode_to_native()> is used so that the Perl code is portable
 301 to EBCDIC platforms.  You can omit it if you're I<really> sure no one
 302 will ever want to use your code on a non-ASCII platform.  Starting in
 303 Perl v5.22, calls to it on ASCII platforms are optimized out, so there's
 304 no performance penalty at all in adding it.  Or you can simply use the
 305 other constructs that don't require it.
 306
 307 See L</"Further Resources"> for how to find all these names and numeric
 308 codes.
 309
 310 =head3 Earlier releases caveats
 311
 312 On EBCDIC platforms, prior to v5.22, using C<\N{U+...}> doesn't work
 313 properly.
 314
 315 Prior to v5.16, using C<\N{...}> with a character name (as opposed to a
 316 C<U+...> code point) required a S<C<use charnames :full>>.
 317
 318 Prior to v5.14, there were some bugs in C<\N{...}> with a character name
 319 (as opposed to a C<U+...> code point).
 320
 321 C<charnames::string_vianame()> was introduced in v5.14.  Prior to that,
 322 C<charnames::vianame()> should work, but only if the argument is of the
 323 form C<"U+...">.  Your best bet there for runtime Unicode by character
 324 name is probably:
 325
 326  use charnames ();
 327  my $hebrew_alef_from_name
 328                   = pack("U", charnames::vianame("HEBREW LETTER ALEF"));
 329
 330 =head2 Handling Unicode
 331
 332 Handling Unicode is for the most part transparent: just use the
 333 strings as usual.  Functions like C<index()>, C<length()>, and
 334 C<substr()> will work on the Unicode characters; regular expressions
 335 will work on the Unicode characters (see L<perlunicode> and L<perlretut>).
 336
 337 Note that Perl considers grapheme clusters to be separate characters, so for
 338 example
 339
 340  print length("\N{LATIN CAPITAL LETTER A}\N{COMBINING ACUTE ACCENT}"),
 341        "\n";
 342
 343 will print 2, not 1.  The only exception is that regular expressions
 344 have C<\X> for matching an extended grapheme cluster.  (Thus C<\X> in a
 345 regular expression would match the entire sequence of both the example
 346 characters.)
 347
 348 Life is not quite so transparent, however, when working with legacy
 349 encodings, I/O, and certain special cases:
 350
 351 =head2 Legacy Encodings
 352
 353 When you combine legacy data and Unicode, the legacy data needs
 354 to be upgraded to Unicode.  Normally the legacy data is assumed to be
 355 ISO 8859-1 (or EBCDIC, if applicable).
 356
 357 The C<Encode> module knows about many encodings and has interfaces
 358 for doing conversions between those encodings:
 359
 360     use Encode 'decode';
 361     $data = decode("iso-8859-3", $data); # convert from legacy
 362
 363 =head2 Unicode I/O
 364
 365 Normally, writing out Unicode data
 366
 367     print FH $some_string_with_unicode, "\n";
 368
 369 produces raw bytes that Perl happens to use to internally encode the
 370 Unicode string.  Perl's internal encoding depends on the system as
 371 well as what characters happen to be in the string at the time. If
 372 any of the characters are at code points C<0x100> or above, you will get
 373 a warning.  To ensure that the output is explicitly rendered in the
 374 encoding you desire--and to avoid the warning--open the stream with
 375 the desired encoding. Some examples:
 376
 377     open FH, ">:utf8", "file";
 378
 379     open FH, ">:encoding(ucs2)",      "file";
 380     open FH, ">:encoding(UTF-8)",     "file";
 381     open FH, ">:encoding(shift_jis)", "file";
 382
 383 and on already open streams, use C<binmode()>:
 384
 385     binmode(STDOUT, ":utf8");
 386
 387     binmode(STDOUT, ":encoding(ucs2)");
 388     binmode(STDOUT, ":encoding(UTF-8)");
 389     binmode(STDOUT, ":encoding(shift_jis)");
 390
 391 The matching of encoding names is loose: case does not matter, and
 392 many encodings have several aliases.  Note that the C<:utf8> layer
 393 must always be specified exactly like that; it is I<not> subject to
 394 the loose matching of encoding names. Also note that currently C<:utf8> is unsafe for
 395 input, because it accepts the data without validating that it is indeed valid
 396 UTF-8; you should instead use C<:encoding(utf-8)> (with or without a
 397 hyphen).
 398
 399 See L<PerlIO> for the C<:utf8> layer, L<PerlIO::encoding> and
 400 L<Encode::PerlIO> for the C<:encoding()> layer, and
 401 L<Encode::Supported> for many encodings supported by the C<Encode>
 402 module.
 403
 404 Reading in a file that you know happens to be encoded in one of the
 405 Unicode or legacy encodings does not magically turn the data into
 406 Unicode in Perl's eyes.  To do that, specify the appropriate
 407 layer when opening files
 408
 409     open(my $fh,'<:encoding(UTF-8)', 'anything');
 410     my $line_of_unicode = <$fh>;
 411
 412     open(my $fh,'<:encoding(Big5)', 'anything');
 413     my $line_of_unicode = <$fh>;
 414
 415 The I/O layers can also be specified more flexibly with
 416 the C<open> pragma.  See L<open>, or look at the following example.
 417
 418     use open ':encoding(UTF-8)'; # input/output default encoding will be
 419                                  # UTF-8
 420     open X, ">file";
 421     print X chr(0x100), "\n";
 422     close X;
 423     open Y, "<file";
 424     printf "%#x\n", ord(<Y>); # this should print 0x100
 425     close Y;
 426
 427 With the C<open> pragma you can use the C<:locale> layer
 428
 429     BEGIN { $ENV{LC_ALL} = $ENV{LANG} = 'ru_RU.KOI8-R' }
 430     # the :locale will probe the locale environment variables like
 431     # LC_ALL
 432     use open OUT => ':locale'; # russki parusski
 433     open(O, ">koi8");
 434     print O chr(0x430); # Unicode CYRILLIC SMALL LETTER A = KOI8-R 0xc1
 435     close O;
 436     open(I, "<koi8");
 437     printf "%#x\n", ord(<I>), "\n"; # this should print 0xc1
 438     close I;
 439
 440 These methods install a transparent filter on the I/O stream that
 441 converts data from the specified encoding when it is read in from the
 442 stream.  The result is always Unicode.
 443
 444 The L<open> pragma affects all the C<open()> calls after the pragma by
 445 setting default layers.  If you want to affect only certain
 446 streams, use explicit layers directly in the C<open()> call.
 447
 448 You can switch encodings on an already opened stream by using
 449 C<binmode()>; see L<perlfunc/binmode>.
 450
 451 The C<:locale> does not currently work with
 452 C<open()> and C<binmode()>, only with the C<open> pragma.  The
 453 C<:utf8> and C<:encoding(...)> methods do work with all of C<open()>,
 454 C<binmode()>, and the C<open> pragma.
 455
 456 Similarly, you may use these I/O layers on output streams to
 457 automatically convert Unicode to the specified encoding when it is
 458 written to the stream. For example, the following snippet copies the
 459 contents of the file "text.jis" (encoded as ISO-2022-JP, aka JIS) to
 460 the file "text.utf8", encoded as UTF-8:
 461
 462     open(my $nihongo, '<:encoding(iso-2022-jp)', 'text.jis');
 463     open(my $unicode, '>:utf8',                  'text.utf8');
 464     while (<$nihongo>) { print $unicode $_ }
 465
 466 The naming of encodings, both by the C<open()> and by the C<open>
 467 pragma allows for flexible names: C<koi8-r> and C<KOI8R> will both be
 468 understood.
 469
 470 Common encodings recognized by ISO, MIME, IANA, and various other
 471 standardisation organisations are recognised; for a more detailed
 472 list see L<Encode::Supported>.
 473
 474 C<read()> reads characters and returns the number of characters.
 475 C<seek()> and C<tell()> operate on byte counts, as do C<sysread()>
 476 and C<sysseek()>.
 477
 478 Notice that because of the default behaviour of not doing any
 479 conversion upon input if there is no default layer,
 480 it is easy to mistakenly write code that keeps on expanding a file
 481 by repeatedly encoding the data:
 482
 483     # BAD CODE WARNING
 484     open F, "file";
 485     local $/; ## read in the whole file of 8-bit characters
 486     $t = <F>;
 487     close F;
 488     open F, ">:encoding(UTF-8)", "file";
 489     print F $t; ## convert to UTF-8 on output
 490     close F;
 491
 492 If you run this code twice, the contents of the F<file> will be twice
 493 UTF-8 encoded.  A C<use open ':encoding(UTF-8)'> would have avoided the
 494 bug, or explicitly opening also the F<file> for input as UTF-8.
 495
 496 B<NOTE>: the C<:utf8> and C<:encoding> features work only if your
 497 Perl has been built with L<PerlIO>, which is the default
 498 on most systems.
 499
 500 =head2 Displaying Unicode As Text
 501
 502 Sometimes you might want to display Perl scalars containing Unicode as
 503 simple ASCII (or EBCDIC) text.  The following subroutine converts
 504 its argument so that Unicode characters with code points greater than
 505 255 are displayed as C<\x{...}>, control characters (like C<\n>) are
 506 displayed as C<\x..>, and the rest of the characters as themselves:
 507
 508  sub nice_string {
 509         join("",
 510         map { $_ > 255                    # if wide character...
 511               ? sprintf("\\x{%04X}", $_)  # \x{...}
 512               : chr($_) =~ /[[:cntrl:]]/  # else if control character...
 513                 ? sprintf("\\x%02X", $_)  # \x..
 514                 : quotemeta(chr($_))      # else quoted or as themselves
 515         } unpack("W*", $_[0]));           # unpack Unicode characters
 516    }
 517
 518 For example,
 519
 520    nice_string("foo\x{100}bar\n")
 521
 522 returns the string
 523
 524    'foo\x{0100}bar\x0A'
 525
 526 which is ready to be printed.
 527
 528 (C<\\x{}> is used here instead of C<\\N{}>, since it's most likely that
 529 you want to see what the native values are.)
 530
 531 =head2 Special Cases
 532
 533 =over 4
 534
 535 =item *
 536
 537 Bit Complement Operator ~ And vec()
 538
 539 The bit complement operator C<~> may produce surprising results if
 540 used on strings containing characters with ordinal values above
 541 255. In such a case, the results are consistent with the internal
 542 encoding of the characters, but not with much else. So don't do
 543 that. Similarly for C<vec()>: you will be operating on the
 544 internally-encoded bit patterns of the Unicode characters, not on
 545 the code point values, which is very probably not what you want.
 546
 547 =item *
 548
 549 Peeking At Perl's Internal Encoding
 550
 551 Normal users of Perl should never care how Perl encodes any particular
 552 Unicode string (because the normal ways to get at the contents of a
 553 string with Unicode--via input and output--should always be via
 554 explicitly-defined I/O layers). But if you must, there are two
 555 ways of looking behind the scenes.
 556
 557 One way of peeking inside the internal encoding of Unicode characters
 558 is to use C<unpack("C*", ...> to get the bytes of whatever the string
 559 encoding happens to be, or C<unpack("U0..", ...)> to get the bytes of the
 560 UTF-8 encoding:
 561
 562     # this prints  c4 80  for the UTF-8 bytes 0xc4 0x80
 563     print join(" ", unpack("U0(H2)*", pack("U", 0x100))), "\n";
 564
 565 Yet another way would be to use the Devel::Peek module:
 566
 567     perl -MDevel::Peek -e 'Dump(chr(0x100))'
 568
 569 That shows the C<UTF8> flag in FLAGS and both the UTF-8 bytes
 570 and Unicode characters in C<PV>.  See also later in this document
 571 the discussion about the C<utf8::is_utf8()> function.
 572
 573 =back
 574
 575 =head2 Advanced Topics
 576
 577 =over 4
 578
 579 =item *
 580
 581 String Equivalence
 582
 583 The question of string equivalence turns somewhat complicated
 584 in Unicode: what do you mean by "equal"?
 585
 586 (Is C<LATIN CAPITAL LETTER A WITH ACUTE> equal to
 587 C<LATIN CAPITAL LETTER A>?)
 588
 589 The short answer is that by default Perl compares equivalence (C<eq>,
 590 C<ne>) based only on code points of the characters.  In the above
 591 case, the answer is no (because 0x00C1 != 0x0041).  But sometimes, any
 592 CAPITAL LETTER A's should be considered equal, or even A's of any case.
 593
 594 The long answer is that you need to consider character normalization
 595 and casing issues: see L<Unicode::Normalize>, Unicode Technical Report #15,
 596 L<Unicode Normalization Forms|http://www.unicode.org/unicode/reports/tr15> and
 597 sections on case mapping in the L<Unicode Standard|http://www.unicode.org>.
 598
 599 As of Perl 5.8.0, the "Full" case-folding of I<Case
 600 Mappings/SpecialCasing> is implemented, but bugs remain in C<qr//i> with them,
 601 mostly fixed by 5.14, and essentially entirely by 5.18.
 602
 603 =item *
 604
 605 String Collation
 606
 607 People like to see their strings nicely sorted--or as Unicode
 608 parlance goes, collated.  But again, what do you mean by collate?
 609
 610 (Does C<LATIN CAPITAL LETTER A WITH ACUTE> come before or after
 611 C<LATIN CAPITAL LETTER A WITH GRAVE>?)
 612
 613 The short answer is that by default, Perl compares strings (C<lt>,
 614 C<le>, C<cmp>, C<ge>, C<gt>) based only on the code points of the
 615 characters.  In the above case, the answer is "after", since
 616 C<0x00C1> > C<0x00C0>.
 617
 618 The long answer is that "it depends", and a good answer cannot be
 619 given without knowing (at the very least) the language context.
 620 See L<Unicode::Collate>, and I<Unicode Collation Algorithm>
 621 L<http://www.unicode.org/unicode/reports/tr10/>
 622
 623 =back
 624
 625 =head2 Miscellaneous
 626
 627 =over 4
 628
 629 =item *
 630
 631 Character Ranges and Classes
 632
 633 Character ranges in regular expression bracketed character classes ( e.g.,
 634 C</[a-z]/>) and in the C<tr///> (also known as C<y///>) operator are not
 635 magically Unicode-aware.  What this means is that C<[A-Za-z]> will not
 636 magically start to mean "all alphabetic letters" (not that it does mean that
 637 even for 8-bit characters; for those, if you are using locales (L<perllocale>),
 638 use C</[[:alpha:]]/>; and if not, use the 8-bit-aware property C<\p{alpha}>).
 639
 640 All the properties that begin with C<\p> (and its inverse C<\P>) are actually
 641 character classes that are Unicode-aware.  There are dozens of them, see
 642 L<perluniprops>.
 643
 644 Starting in v5.22, you can use Unicode code points as the end points of
 645 regular expression pattern character ranges, and the range will include
 646 all Unicode code points that lie between those end points, inclusive.
 647
 648  qr/ [ \N{U+03} - \N{U+20} ] /xx
 649
 650 includes the code points
 651 C<\N{U+03}>, C<\N{U+04}>, ..., C<\N{U+20}>.
 652
 653 This also works for ranges in C<tr///> starting in Perl v5.24.
 654
 655 =item *
 656
 657 String-To-Number Conversions
 658
 659 Unicode does define several other decimal--and numeric--characters
 660 besides the familiar 0 to 9, such as the Arabic and Indic digits.
 661 Perl does not support string-to-number conversion for digits other
 662 than ASCII C<0> to C<9> (and ASCII C<a> to C<f> for hexadecimal).
 663 To get safe conversions from any Unicode string, use
 664 L<Unicode::UCD/num()>.
 665
 666 =back
 667
 668 =head2 Questions With Answers
 669
 670 =over 4
 671
 672 =item *
 673
 674 Will My Old Scripts Break?
 675
 676 Very probably not.  Unless you are generating Unicode characters
 677 somehow, old behaviour should be preserved.  About the only behaviour
 678 that has changed and which could start generating Unicode is the old
 679 behaviour of C<chr()> where supplying an argument more than 255
 680 produced a character modulo 255.  C<chr(300)>, for example, was equal
 681 to C<chr(45)> or "-" (in ASCII), now it is LATIN CAPITAL LETTER I WITH
 682 BREVE.
 683
 684 =item *
 685
 686 How Do I Make My Scripts Work With Unicode?
 687
 688 Very little work should be needed since nothing changes until you
 689 generate Unicode data.  The most important thing is getting input as
 690 Unicode; for that, see the earlier I/O discussion.
 691 To get full seamless Unicode support, add
 692 C<use feature 'unicode_strings'> (or C<use 5.012> or higher) to your
 693 script.
 694
 695 =item *
 696
 697 How Do I Know Whether My String Is In Unicode?
 698
 699 You shouldn't have to care.  But you may if your Perl is before 5.14.0
 700 or you haven't specified C<use feature 'unicode_strings'> or C<use
 701 5.012> (or higher) because otherwise the rules for the code points
 702 in the range 128 to 255 are different depending on
 703 whether the string they are contained within is in Unicode or not.
 704 (See L<perlunicode/When Unicode Does Not Happen>.)
 705
 706 To determine if a string is in Unicode, use:
 707
 708     print utf8::is_utf8($string) ? 1 : 0, "\n";
 709
 710 But note that this doesn't mean that any of the characters in the
 711 string are necessary UTF-8 encoded, or that any of the characters have
 712 code points greater than 0xFF (255) or even 0x80 (128), or that the
 713 string has any characters at all.  All the C<is_utf8()> does is to
 714 return the value of the internal "utf8ness" flag attached to the
 715 C<$string>.  If the flag is off, the bytes in the scalar are interpreted
 716 as a single byte encoding.  If the flag is on, the bytes in the scalar
 717 are interpreted as the (variable-length, potentially multi-byte) UTF-8 encoded
 718 code points of the characters.  Bytes added to a UTF-8 encoded string are
 719 automatically upgraded to UTF-8.  If mixed non-UTF-8 and UTF-8 scalars
 720 are merged (double-quoted interpolation, explicit concatenation, or
 721 printf/sprintf parameter substitution), the result will be UTF-8 encoded
 722 as if copies of the byte strings were upgraded to UTF-8: for example,
 723
 724     $a = "ab\x80c";
 725     $b = "\x{100}";
 726     print "$a = $b\n";
 727
 728 the output string will be UTF-8-encoded C<ab\x80c = \x{100}\n>, but
 729 C<$a> will stay byte-encoded.
 730
 731 Sometimes you might really need to know the byte length of a string
 732 instead of the character length. For that use the C<bytes> pragma
 733 and the C<length()> function:
 734
 735     my $unicode = chr(0x100);
 736     print length($unicode), "\n"; # will print 1
 737     use bytes;
 738     print length($unicode), "\n"; # will print 2
 739                                   # (the 0xC4 0x80 of the UTF-8)
 740     no bytes;
 741
 742 =item *
 743
 744 How Do I Find Out What Encoding a File Has?
 745
 746 You might try L<Encode::Guess>, but it has a number of limitations.
 747
 748 =item *
 749
 750 How Do I Detect Data That's Not Valid In a Particular Encoding?
 751
 752 Use the C<Encode> package to try converting it.
 753 For example,
 754
 755     use Encode 'decode';
 756
 757     if (eval { decode('UTF-8', $string, Encode::FB_CROAK); 1 }) {
 758         # $string is valid UTF-8
 759     } else {
 760         # $string is not valid UTF-8
 761     }
 762
 763 Or use C<unpack> to try decoding it:
 764
 765     use warnings;
 766     @chars = unpack("C0U*", $string_of_bytes_that_I_think_is_utf8);
 767
 768 If invalid, a C<Malformed UTF-8 character> warning is produced. The "C0" means
 769 "process the string character per character".  Without that, the
 770 C<unpack("U*", ...)> would work in C<U0> mode (the default if the format
 771 string starts with C<U>) and it would return the bytes making up the UTF-8
 772 encoding of the target string, something that will always work.
 773
 774 =item *
 775
 776 How Do I Convert Binary Data Into a Particular Encoding, Or Vice Versa?
 777
 778 This probably isn't as useful as you might think.
 779 Normally, you shouldn't need to.
 780
 781 In one sense, what you are asking doesn't make much sense: encodings
 782 are for characters, and binary data are not "characters", so converting
 783 "data" into some encoding isn't meaningful unless you know in what
 784 character set and encoding the binary data is in, in which case it's
 785 not just binary data, now is it?
 786
 787 If you have a raw sequence of bytes that you know should be
 788 interpreted via a particular encoding, you can use C<Encode>:
 789
 790     use Encode 'from_to';
 791     from_to($data, "iso-8859-1", "utf-8"); # from latin-1 to utf-8
 792
 793 The call to C<from_to()> changes the bytes in C<$data>, but nothing
 794 material about the nature of the string has changed as far as Perl is
 795 concerned.  Both before and after the call, the string C<$data>
 796 contains just a bunch of 8-bit bytes. As far as Perl is concerned,
 797 the encoding of the string remains as "system-native 8-bit bytes".
 798
 799 You might relate this to a fictional 'Translate' module:
 800
 801    use Translate;
 802    my $phrase = "Yes";
 803    Translate::from_to($phrase, 'english', 'deutsch');
 804    ## phrase now contains "Ja"
 805
 806 The contents of the string changes, but not the nature of the string.
 807 Perl doesn't know any more after the call than before that the
 808 contents of the string indicates the affirmative.
 809
 810 Back to converting data.  If you have (or want) data in your system's
 811 native 8-bit encoding (e.g. Latin-1, EBCDIC, etc.), you can use
 812 pack/unpack to convert to/from Unicode.
 813
 814     $native_string  = pack("W*", unpack("U*", $Unicode_string));
 815     $Unicode_string = pack("U*", unpack("W*", $native_string));
 816
 817 If you have a sequence of bytes you B<know> is valid UTF-8,
 818 but Perl doesn't know it yet, you can make Perl a believer, too:
 819
 820     $Unicode = $bytes;
 821     utf8::decode($Unicode);
 822
 823 or:
 824
 825     $Unicode = pack("U0a*", $bytes);
 826
 827 You can find the bytes that make up a UTF-8 sequence with
 828
 829     @bytes = unpack("C*", $Unicode_string)
 830
 831 and you can create well-formed Unicode with
 832
 833     $Unicode_string = pack("U*", 0xff, ...)
 834
 835 =item *
 836
 837 How Do I Display Unicode?  How Do I Input Unicode?
 838
 839 See L<http://www.alanwood.net/unicode/> and
 840 L<http://www.cl.cam.ac.uk/~mgk25/unicode.html>
 841
 842 =item *
 843
 844 How Does Unicode Work With Traditional Locales?
 845
 846 If your locale is a UTF-8 locale, starting in Perl v5.20, Perl works
 847 well for all categories except C<LC_COLLATE> dealing with sorting and
 848 the C<cmp> operator.
 849
 850 For other locales, starting in Perl 5.16, you can specify
 851
 852     use locale ':not_characters';
 853
 854 to get Perl to work well with them.  The catch is that you
 855 have to translate from the locale character set to/from Unicode
 856 yourself.  See L</Unicode IE<sol>O> above for how to
 857
 858     use open ':locale';
 859
 860 to accomplish this, but full details are in L<perllocale/Unicode and
 861 UTF-8>, including gotchas that happen if you don't specify
 862 C<:not_characters>.
 863
 864 =back
 865
 866 =head2 Hexadecimal Notation
 867
 868 The Unicode standard prefers using hexadecimal notation because
 869 that more clearly shows the division of Unicode into blocks of 256 characters.
 870 Hexadecimal is also simply shorter than decimal.  You can use decimal
 871 notation, too, but learning to use hexadecimal just makes life easier
 872 with the Unicode standard.  The C<U+HHHH> notation uses hexadecimal,
 873 for example.
 874
 875 The C<0x> prefix means a hexadecimal number, the digits are 0-9 I<and>
 876 a-f (or A-F, case doesn't matter).  Each hexadecimal digit represents
 877 four bits, or half a byte.  C<print 0x..., "\n"> will show a
 878 hexadecimal number in decimal, and C<printf "%x\n", $decimal> will
 879 show a decimal number in hexadecimal.  If you have just the
 880 "hex digits" of a hexadecimal number, you can use the C<hex()> function.
 881
 882     print 0x0009, "\n";    # 9
 883     print 0x000a, "\n";    # 10
 884     print 0x000f, "\n";    # 15
 885     print 0x0010, "\n";    # 16
 886     print 0x0011, "\n";    # 17
 887     print 0x0100, "\n";    # 256
 888
 889     print 0x0041, "\n";    # 65
 890
 891     printf "%x\n",  65;    # 41
 892     printf "%#x\n", 65;    # 0x41
 893
 894     print hex("41"), "\n"; # 65
 895
 896 =head2 Further Resources
 897
 898 =over 4
 899
 900 =item *
 901
 902 Unicode Consortium
 903
 904 L<http://www.unicode.org/>
 905
 906 =item *
 907
 908 Unicode FAQ
 909
 910 L<http://www.unicode.org/unicode/faq/>
 911
 912 =item *
 913
 914 Unicode Glossary
 915
 916 L<http://www.unicode.org/glossary/>
 917
 918 =item *
 919
 920 Unicode Recommended Reading List
 921
 922 The Unicode Consortium has a list of articles and books, some of which
 923 give a much more in depth treatment of Unicode:
 924 L<http://unicode.org/resources/readinglist.html>
 925
 926 =item *
 927
 928 Unicode Useful Resources
 929
 930 L<http://www.unicode.org/unicode/onlinedat/resources.html>
 931
 932 =item *
 933
 934 Unicode and Multilingual Support in HTML, Fonts, Web Browsers and Other Applications
 935
 936 L<http://www.alanwood.net/unicode/>
 937
 938 =item *
 939
 940 UTF-8 and Unicode FAQ for Unix/Linux
 941
 942 L<http://www.cl.cam.ac.uk/~mgk25/unicode.html>
 943
 944 =item *
 945
 946 Legacy Character Sets
 947
 948 L<http://www.czyborra.com/>
 949 L<http://www.eki.ee/letter/>
 950
 951 =item *
 952
 953 You can explore various information from the Unicode data files using
 954 the C<Unicode::UCD> module.
 955
 956 =back
 957
 958 =head1 UNICODE IN OLDER PERLS
 959
 960 If you cannot upgrade your Perl to 5.8.0 or later, you can still
 961 do some Unicode processing by using the modules C<Unicode::String>,
 962 C<Unicode::Map8>, and C<Unicode::Map>, available from CPAN.
 963 If you have the GNU recode installed, you can also use the
 964 Perl front-end C<Convert::Recode> for character conversions.
 965
 966 The following are fast conversions from ISO 8859-1 (Latin-1) bytes
 967 to UTF-8 bytes and back, the code works even with older Perl 5 versions.
 968
 969     # ISO 8859-1 to UTF-8
 970     s/([\x80-\xFF])/chr(0xC0|ord($1)>>6).chr(0x80|ord($1)&0x3F)/eg;
 971
 972     # UTF-8 to ISO 8859-1
 973     s/([\xC2\xC3])([\x80-\xBF])/chr(ord($1)<<6&0xC0|ord($2)&0x3F)/eg;
 974
 975 =head1 SEE ALSO
 976
 977 L<perlunitut>, L<perlunicode>, L<Encode>, L<open>, L<utf8>, L<bytes>,
 978 L<perlretut>, L<perlrun>, L<Unicode::Collate>, L<Unicode::Normalize>,
 979 L<Unicode::UCD>
 980
 981 =head1 ACKNOWLEDGMENTS
 982
 983 Thanks to the kind readers of the perl5-porters@perl.org,
 984 perl-unicode@perl.org, linux-utf8@nl.linux.org, and unicore@unicode.org
 985 mailing lists for their valuable feedback.
 986
 987 =head1 AUTHOR, COPYRIGHT, AND LICENSE
 988
 989 Copyright 2001-2011 Jarkko Hietaniemi E<lt>jhi@iki.fiE<gt>.
 990 Now maintained by Perl 5 Porters.
 991
 992 This document may be distributed under the same terms as Perl itself.