lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34)>.
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 use Cwd ();
 516
 517 my $_initial_cwd;
 518
 519 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 520
 521 BEGIN {
 522     require feature;
 523     $^V =~ /^v(\d+\.\d+)/;
 524     feature->import(":$1");
 525     $_initial_cwd = Cwd::getcwd();
 526 }
 527
 528 # Debugger for Perl 5.00x; perl5db.pl patch level:
 529 use vars qw($VERSION $header);
 530
 531 # bump to X.XX in blead, only use X.XX_XX in maint
 532 $VERSION = '1.53';
 533
 534 $header = "perl5db.pl version $VERSION";
 535
 536 =head1 DEBUGGER ROUTINES
 537
 538 =head2 C<DB::eval()>
 539
 540 This function replaces straight C<eval()> inside the debugger; it simplifies
 541 the process of evaluating code in the user's context.
 542
 543 The code to be evaluated is passed via the package global variable
 544 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 545
 546 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 547 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 548 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 549 user's current package, grabbed when C<DB::DB> got control.  This causes the
 550 proper context to be used when the eval is actually done.  Afterward, we
 551 restore C<$trace>, C<$single>, and C<$^D>.
 552
 553 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 554 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 555 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 556 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 557 considered sane by the debugger. If there was an C<eval()> error, we print
 558 it on the debugger's output. If C<$onetimedump> is defined, we call
 559 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 560 'methods'. Setting it to something else causes the debugger to do the eval
 561 but not print the result - handy if you want to do something else with it
 562 (the "watch expressions" code does this to get the value of the watch
 563 expression but not show it unless it matters).
 564
 565 In any case, we then return the list of output from C<eval> to the caller,
 566 and unwinding restores the former version of C<$@> in C<@saved> as well
 567 (the localization of C<$saved[0]> goes away at the end of this scope).
 568
 569 =head3 Parameters and variables influencing execution of DB::eval()
 570
 571 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 572 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 573 The variables listed below influence C<DB::eval()>'s execution directly.
 574
 575 =over 4
 576
 577 =item C<$evalarg> - the thing to actually be eval'ed
 578
 579 =item C<$trace> - Current state of execution tracing
 580
 581 =item C<$single> - Current state of single-stepping
 582
 583 =item C<$onetimeDump> - what is to be displayed after the evaluation
 584
 585 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 586
 587 =back
 588
 589 The following variables are altered by C<DB::eval()> during its execution. They
 590 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 591
 592 =over 4
 593
 594 =item C<@res> - used to capture output from actual C<eval>.
 595
 596 =item C<$otrace> - saved value of C<$trace>.
 597
 598 =item C<$osingle> - saved value of C<$single>.
 599
 600 =item C<$od> - saved value of C<$^D>.
 601
 602 =item C<$saved[0]> - saved value of C<$@>.
 603
 604 =item $\ - for output of C<$@> if there is an evaluation error.
 605
 606 =back
 607
 608 =head3 The problem of lexicals
 609
 610 The context of C<DB::eval()> presents us with some problems. Obviously,
 611 we want to be 'sandboxed' away from the debugger's internals when we do
 612 the eval, but we need some way to control how punctuation variables and
 613 debugger globals are used.
 614
 615 We can't use local, because the code inside C<DB::eval> can see localized
 616 variables; and we can't use C<my> either for the same reason. The code
 617 in this routine compromises and uses C<my>.
 618
 619 After this routine is over, we don't have user code executing in the debugger's
 620 context, so we can use C<my> freely.
 621
 622 =cut
 623
 624 ############################################## Begin lexical danger zone
 625
 626 # 'my' variables used here could leak into (that is, be visible in)
 627 # the context that the code being evaluated is executing in. This means that
 628 # the code could modify the debugger's variables.
 629 #
 630 # Fiddling with the debugger's context could be Bad. We insulate things as
 631 # much as we can.
 632
 633 use vars qw(
 634     @args
 635     %break_on_load
 636     $CommandSet
 637     $CreateTTY
 638     $DBGR
 639     @dbline
 640     $dbline
 641     %dbline
 642     $dieLevel
 643     $filename
 644     $histfile
 645     $histsize
 646     $IN
 647     $inhibit_exit
 648     @ini_INC
 649     $ini_warn
 650     $maxtrace
 651     $od
 652     @options
 653     $osingle
 654     $otrace
 655     $pager
 656     $post
 657     %postponed
 658     $prc
 659     $pre
 660     $pretype
 661     $psh
 662     @RememberOnROptions
 663     $remoteport
 664     @res
 665     $rl
 666     @saved
 667     $signalLevel
 668     $sub
 669     $term
 670     $usercontext
 671     $warnLevel
 672 );
 673
 674 our (
 675     @cmdfhs,
 676     $evalarg,
 677     $frame,
 678     $hist,
 679     $ImmediateStop,
 680     $line,
 681     $onetimeDump,
 682     $onetimedumpDepth,
 683     %option,
 684     $OUT,
 685     $packname,
 686     $signal,
 687     $single,
 688     $start,
 689     %sub,
 690     $subname,
 691     $trace,
 692     $window,
 693 );
 694
 695 # Used to save @ARGV and extract any debugger-related flags.
 696 use vars qw(@ARGS);
 697
 698 # Used to prevent multiple entries to diesignal()
 699 # (if for instance diesignal() itself dies)
 700 use vars qw($panic);
 701
 702 # Used to prevent the debugger from running nonstop
 703 # after a restart
 704 our ($second_time);
 705
 706 sub _calc_usercontext {
 707     my ($package) = @_;
 708
 709     # Cancel strict completely for the evaluated code, so the code
 710     # the user evaluates won't be affected by it. (Shlomi Fish)
 711     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 712     . "package $package;";    # this won't let them modify, alas
 713 }
 714
 715 sub eval {
 716
 717     # 'my' would make it visible from user code
 718     #    but so does local! --tchrist
 719     # Remember: this localizes @DB::res, not @main::res.
 720     local @res;
 721     {
 722
 723         # Try to keep the user code from messing  with us. Save these so that
 724         # even if the eval'ed code changes them, we can put them back again.
 725         # Needed because the user could refer directly to the debugger's
 726         # package globals (and any 'my' variables in this containing scope)
 727         # inside the eval(), and we want to try to stay safe.
 728         local $otrace  = $trace;
 729         local $osingle = $single;
 730         local $od      = $^D;
 731
 732         # Untaint the incoming eval() argument.
 733         { ($evalarg) = $evalarg =~ /(.*)/s; }
 734
 735         # $usercontext built in DB::DB near the comment
 736         # "set up the context for DB::eval ..."
 737         # Evaluate and save any results.
 738         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 739
 740         # Restore those old values.
 741         $trace  = $otrace;
 742         $single = $osingle;
 743         $^D     = $od;
 744     }
 745
 746     # Save the current value of $@, and preserve it in the debugger's copy
 747     # of the saved precious globals.
 748     my $at = $@;
 749
 750     # Since we're only saving $@, we only have to localize the array element
 751     # that it will be stored in.
 752     local $saved[0];    # Preserve the old value of $@
 753     eval { &DB::save };
 754
 755     # Now see whether we need to report an error back to the user.
 756     if ($at) {
 757         local $\ = '';
 758         print $OUT $at;
 759     }
 760
 761     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 762     # are package globals.
 763     elsif ($onetimeDump) {
 764         if ( $onetimeDump eq 'dump' ) {
 765             local $option{dumpDepth} = $onetimedumpDepth
 766               if defined $onetimedumpDepth;
 767             dumpit( $OUT, \@res );
 768         }
 769         elsif ( $onetimeDump eq 'methods' ) {
 770             methods( $res[0] );
 771         }
 772     } ## end elsif ($onetimeDump)
 773     @res;
 774 } ## end sub eval
 775
 776 ############################################## End lexical danger zone
 777
 778 # After this point it is safe to introduce lexicals.
 779 # The code being debugged will be executing in its own context, and
 780 # can't see the inside of the debugger.
 781 #
 782 # However, one should not overdo it: leave as much control from outside as
 783 # possible. If you make something a lexical, it's not going to be addressable
 784 # from outside the debugger even if you know its name.
 785
 786 # This file is automatically included if you do perl -d.
 787 # It's probably not useful to include this yourself.
 788 #
 789 # Before venturing further into these twisty passages, it is
 790 # wise to read the perldebguts man page or risk the ire of dragons.
 791 #
 792 # (It should be noted that perldebguts will tell you a lot about
 793 # the underlying mechanics of how the debugger interfaces into the
 794 # Perl interpreter, but not a lot about the debugger itself. The new
 795 # comments in this code try to address this problem.)
 796
 797 # Note that no subroutine call is possible until &DB::sub is defined
 798 # (for subroutines defined outside of the package DB). In fact the same is
 799 # true if $deep is not defined.
 800
 801 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 802
 803 # modified Perl debugger, to be run from Emacs in perldb-mode
 804 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 805 # Johan Vromans -- upgrade to 4.0 pl 10
 806 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 807 ########################################################################
 808
 809 =head1 DEBUGGER INITIALIZATION
 810
 811 The debugger starts up in phases.
 812
 813 =head2 BASIC SETUP
 814
 815 First, it initializes the environment it wants to run in: turning off
 816 warnings during its own compilation, defining variables which it will need
 817 to avoid warnings later, setting itself up to not exit when the program
 818 terminates, and defaulting to printing return values for the C<r> command.
 819
 820 =cut
 821
 822 # Needed for the statement after exec():
 823 #
 824 # This BEGIN block is simply used to switch off warnings during debugger
 825 # compilation. Probably it would be better practice to fix the warnings,
 826 # but this is how it's done at the moment.
 827
 828 BEGIN {
 829     $ini_warn = $^W;
 830     $^W       = 0;
 831 }    # Switch compilation warnings off until another BEGIN.
 832
 833 local ($^W) = 0;    # Switch run-time warnings off during init.
 834
 835 =head2 THREADS SUPPORT
 836
 837 If we are running under a threaded Perl, we require threads and threads::shared
 838 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 839 threaded debugger control.  C<-dt> can also be used to set this.
 840
 841 Each new thread will be announced and the debugger prompt will always inform
 842 you of each new thread created.  It will also indicate the thread id in which
 843 we are currently running within the prompt like this:
 844
 845     [tid] DB<$i>
 846
 847 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 848 command prompt.  The prompt will show: C<[0]> when running under threads, but
 849 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 850
 851 While running under threads, when you set or delete a breakpoint (etc.), this
 852 will apply to all threads, not just the currently running one.  When you are
 853 in a currently executing thread, you will stay there until it completes.  With
 854 the current implementation it is not currently possible to hop from one thread
 855 to another.
 856
 857 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 858
 859 Note that threading support was built into the debugger as of Perl version
 860 C<5.8.6> and debugger version C<1.2.8>.
 861
 862 =cut
 863
 864 BEGIN {
 865     # ensure we can share our non-threaded variables or no-op
 866     if ($ENV{PERL5DB_THREADED}) {
 867         require threads;
 868         require threads::shared;
 869         import threads::shared qw(share);
 870         $DBGR;
 871         share(\$DBGR);
 872         lock($DBGR);
 873         print "Threads support enabled\n";
 874     } else {
 875         *lock = sub(*) {};
 876         *share = sub(\[$@%]) {};
 877     }
 878 }
 879
 880 # These variables control the execution of 'dumpvar.pl'.
 881 {
 882     package dumpvar;
 883     use vars qw(
 884     $hashDepth
 885     $arrayDepth
 886     $dumpDBFiles
 887     $dumpPackages
 888     $quoteHighBit
 889     $printUndef
 890     $globPrint
 891     $usageOnly
 892     );
 893 }
 894
 895 # used to control die() reporting in diesignal()
 896 {
 897     package Carp;
 898     use vars qw($CarpLevel);
 899 }
 900
 901 # without threads, $filename is not defined until DB::DB is called
 902 share($main::{'_<'.$filename}) if defined $filename;
 903
 904 # Command-line + PERLLIB:
 905 # Save the contents of @INC before they are modified elsewhere.
 906 @ini_INC = @INC;
 907
 908 # This was an attempt to clear out the previous values of various
 909 # trapped errors. Apparently it didn't help. XXX More info needed!
 910 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 911
 912 # We set these variables to safe values. We don't want to blindly turn
 913 # off warnings, because other packages may still want them.
 914 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 915                                    # (local $^W cannot help - other packages!).
 916
 917 # Default to not exiting when program finishes; print the return
 918 # value when the 'r' command is used to return from a subroutine.
 919 $inhibit_exit = $option{PrintRet} = 1;
 920
 921 use vars qw($trace_to_depth);
 922
 923 # Default to 1E9 so it won't be limited to a certain recursion depth.
 924 $trace_to_depth = 1E9;
 925
 926 =head1 OPTION PROCESSING
 927
 928 The debugger's options are actually spread out over the debugger itself and
 929 C<dumpvar.pl>; some of these are variables to be set, while others are
 930 subs to be called with a value. To try to make this a little easier to
 931 manage, the debugger uses a few data structures to define what options
 932 are legal and how they are to be processed.
 933
 934 First, the C<@options> array defines the I<names> of all the options that
 935 are to be accepted.
 936
 937 =cut
 938
 939 @options = qw(
 940   CommandSet   HistFile      HistSize
 941   hashDepth    arrayDepth    dumpDepth
 942   DumpDBFiles  DumpPackages  DumpReused
 943   compactDump  veryCompact   quote
 944   HighBit      undefPrint    globPrint
 945   PrintRet     UsageOnly     frame
 946   AutoTrace    TTY           noTTY
 947   ReadLine     NonStop       LineInfo
 948   maxTraceLen  recallCommand ShellBang
 949   pager        tkRunning     ornaments
 950   signalLevel  warnLevel     dieLevel
 951   inhibit_exit ImmediateStop bareStringify
 952   CreateTTY    RemotePort    windowSize
 953   DollarCaretP
 954 );
 955
 956 @RememberOnROptions = qw(DollarCaretP);
 957
 958 =pod
 959
 960 Second, C<optionVars> lists the variables that each option uses to save its
 961 state.
 962
 963 =cut
 964
 965 use vars qw(%optionVars);
 966
 967 %optionVars = (
 968     hashDepth     => \$dumpvar::hashDepth,
 969     arrayDepth    => \$dumpvar::arrayDepth,
 970     CommandSet    => \$CommandSet,
 971     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 972     DumpPackages  => \$dumpvar::dumpPackages,
 973     DumpReused    => \$dumpvar::dumpReused,
 974     HighBit       => \$dumpvar::quoteHighBit,
 975     undefPrint    => \$dumpvar::printUndef,
 976     globPrint     => \$dumpvar::globPrint,
 977     UsageOnly     => \$dumpvar::usageOnly,
 978     CreateTTY     => \$CreateTTY,
 979     bareStringify => \$dumpvar::bareStringify,
 980     frame         => \$frame,
 981     AutoTrace     => \$trace,
 982     inhibit_exit  => \$inhibit_exit,
 983     maxTraceLen   => \$maxtrace,
 984     ImmediateStop => \$ImmediateStop,
 985     RemotePort    => \$remoteport,
 986     windowSize    => \$window,
 987     HistFile      => \$histfile,
 988     HistSize      => \$histsize,
 989 );
 990
 991 =pod
 992
 993 Third, C<%optionAction> defines the subroutine to be called to process each
 994 option.
 995
 996 =cut
 997
 998 use vars qw(%optionAction);
 999
1000 %optionAction = (
1001     compactDump   => \&dumpvar::compactDump,
1002     veryCompact   => \&dumpvar::veryCompact,
1003     quote         => \&dumpvar::quote,
1004     TTY           => \&TTY,
1005     noTTY         => \&noTTY,
1006     ReadLine      => \&ReadLine,
1007     NonStop       => \&NonStop,
1008     LineInfo      => \&LineInfo,
1009     recallCommand => \&recallCommand,
1010     ShellBang     => \&shellBang,
1011     pager         => \&pager,
1012     signalLevel   => \&signalLevel,
1013     warnLevel     => \&warnLevel,
1014     dieLevel      => \&dieLevel,
1015     tkRunning     => \&tkRunning,
1016     ornaments     => \&ornaments,
1017     RemotePort    => \&RemotePort,
1018     DollarCaretP  => \&DollarCaretP,
1019 );
1020
1021 =pod
1022
1023 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1024 option is used.
1025
1026 =cut
1027
1028 # Note that this list is not complete: several options not listed here
1029 # actually require that dumpvar.pl be loaded for them to work, but are
1030 # not in the table. A subsequent patch will correct this problem; for
1031 # the moment, we're just recommenting, and we are NOT going to change
1032 # function.
1033 use vars qw(%optionRequire);
1034
1035 %optionRequire = (
1036     compactDump => 'dumpvar.pl',
1037     veryCompact => 'dumpvar.pl',
1038     quote       => 'dumpvar.pl',
1039 );
1040
1041 =pod
1042
1043 There are a number of initialization-related variables which can be set
1044 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1045 variable. These are:
1046
1047 =over 4
1048
1049 =item C<$rl> - readline control XXX needs more explanation
1050
1051 =item C<$warnLevel> - whether or not debugger takes over warning handling
1052
1053 =item C<$dieLevel> - whether or not debugger takes over die handling
1054
1055 =item C<$signalLevel> - whether or not debugger takes over signal handling
1056
1057 =item C<$pre> - preprompt actions (array reference)
1058
1059 =item C<$post> - postprompt actions (array reference)
1060
1061 =item C<$pretype>
1062
1063 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1064
1065 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1066
1067 =back
1068
1069 =cut
1070
1071 # These guys may be defined in $ENV{PERL5DB} :
1072 $rl          = 1     unless defined $rl;
1073 $warnLevel   = 1     unless defined $warnLevel;
1074 $dieLevel    = 1     unless defined $dieLevel;
1075 $signalLevel = 1     unless defined $signalLevel;
1076 $pre         = []    unless defined $pre;
1077 $post        = []    unless defined $post;
1078 $pretype     = []    unless defined $pretype;
1079 $CreateTTY   = 3     unless defined $CreateTTY;
1080 $CommandSet  = '580' unless defined $CommandSet;
1081
1082 share($rl);
1083 share($warnLevel);
1084 share($dieLevel);
1085 share($signalLevel);
1086 share($pre);
1087 share($post);
1088 share($pretype);
1089 share($rl);
1090 share($CreateTTY);
1091 share($CommandSet);
1092
1093 =pod
1094
1095 The default C<die>, C<warn>, and C<signal> handlers are set up.
1096
1097 =cut
1098
1099 warnLevel($warnLevel);
1100 dieLevel($dieLevel);
1101 signalLevel($signalLevel);
1102
1103 =pod
1104
1105 The pager to be used is needed next. We try to get it from the
1106 environment first.  If it's not defined there, we try to find it in
1107 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1108 then call the C<pager()> function to save the pager name.
1109
1110 =cut
1111
1112 # This routine makes sure $pager is set up so that '|' can use it.
1113 pager(
1114
1115     # If PAGER is defined in the environment, use it.
1116     defined $ENV{PAGER}
1117     ? $ENV{PAGER}
1118
1119       # If not, see if Config.pm defines it.
1120     : eval { require Config }
1121       && defined $Config::Config{pager}
1122     ? $Config::Config{pager}
1123
1124       # If not, fall back to 'more'.
1125     : 'more'
1126   )
1127   unless defined $pager;
1128
1129 =pod
1130
1131 We set up the command to be used to access the man pages, the command
1132 recall character (C<!> unless otherwise defined) and the shell escape
1133 character (C<!> unless otherwise defined). Yes, these do conflict, and
1134 neither works in the debugger at the moment.
1135
1136 =cut
1137
1138 setman();
1139
1140 # Set up defaults for command recall and shell escape (note:
1141 # these currently don't work in linemode debugging).
1142 recallCommand("!") unless defined $prc;
1143 shellBang("!")     unless defined $psh;
1144
1145 =pod
1146
1147 We then set up the gigantic string containing the debugger help.
1148 We also set the limit on the number of arguments we'll display during a
1149 trace.
1150
1151 =cut
1152
1153 sethelp();
1154
1155 # If we didn't get a default for the length of eval/stack trace args,
1156 # set it here.
1157 $maxtrace = 400 unless defined $maxtrace;
1158
1159 =head2 SETTING UP THE DEBUGGER GREETING
1160
1161 The debugger I<greeting> helps to inform the user how many debuggers are
1162 running, and whether the current debugger is the primary or a child.
1163
1164 If we are the primary, we just hang onto our pid so we'll have it when
1165 or if we start a child debugger. If we are a child, we'll set things up
1166 so we'll have a unique greeting and so the parent will give us our own
1167 TTY later.
1168
1169 We save the current contents of the C<PERLDB_PIDS> environment variable
1170 because we mess around with it. We'll also need to hang onto it because
1171 we'll need it if we restart.
1172
1173 Child debuggers make a label out of the current PID structure recorded in
1174 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1175 yet so the parent will give them one later via C<resetterm()>.
1176
1177 =cut
1178
1179 # Save the current contents of the environment; we're about to
1180 # much with it. We'll need this if we have to restart.
1181 use vars qw($ini_pids);
1182 $ini_pids = $ENV{PERLDB_PIDS};
1183
1184 use vars qw ($pids $term_pid);
1185
1186 if ( defined $ENV{PERLDB_PIDS} ) {
1187
1188     # We're a child. Make us a label out of the current PID structure
1189     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1190     # a term yet so the parent will give us one later via resetterm().
1191
1192     my $env_pids = $ENV{PERLDB_PIDS};
1193     $pids = "[$env_pids]";
1194
1195     # Unless we are on OpenVMS, all programs under the DCL shell run under
1196     # the same PID.
1197
1198     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1199         $term_pid         = $$;
1200     }
1201     else {
1202         $ENV{PERLDB_PIDS} .= "->$$";
1203         $term_pid = -1;
1204     }
1205
1206 } ## end if (defined $ENV{PERLDB_PIDS...
1207 else {
1208
1209     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1210     # child debugger, and mark us as the parent, so we'll know to set up
1211     # more TTY's is we have to.
1212     $ENV{PERLDB_PIDS} = "$$";
1213     $pids             = "[pid=$$]";
1214     $term_pid         = $$;
1215 }
1216
1217 use vars qw($pidprompt);
1218 $pidprompt = '';
1219
1220 # Sets up $emacs as a synonym for $slave_editor.
1221 our ($slave_editor);
1222 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1223
1224 =head2 READING THE RC FILE
1225
1226 The debugger will read a file of initialization options if supplied. If
1227 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1228
1229 =cut
1230
1231 # As noted, this test really doesn't check accurately that the debugger
1232 # is running at a terminal or not.
1233
1234 use vars qw($rcfile);
1235 {
1236     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1237     # this is the wrong metric!
1238     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1239 }
1240
1241 =pod
1242
1243 The debugger does a safety test of the file to be read. It must be owned
1244 either by the current user or root, and must only be writable by the owner.
1245
1246 =cut
1247
1248 # This wraps a safety test around "do" to read and evaluate the init file.
1249 #
1250 # This isn't really safe, because there's a race
1251 # between checking and opening.  The solution is to
1252 # open and fstat the handle, but then you have to read and
1253 # eval the contents.  But then the silly thing gets
1254 # your lexical scope, which is unfortunate at best.
1255 sub safe_do {
1256     my $file = shift;
1257
1258     # Just exactly what part of the word "CORE::" don't you understand?
1259     local $SIG{__WARN__};
1260     local $SIG{__DIE__};
1261
1262     unless ( is_safe_file($file) ) {
1263         CORE::warn <<EO_GRIPE;
1264 perldb: Must not source insecure rcfile $file.
1265         You or the superuser must be the owner, and it must not
1266         be writable by anyone but its owner.
1267 EO_GRIPE
1268         return;
1269     } ## end unless (is_safe_file($file...
1270
1271     do $file;
1272     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1273 } ## end sub safe_do
1274
1275 # This is the safety test itself.
1276 #
1277 # Verifies that owner is either real user or superuser and that no
1278 # one but owner may write to it.  This function is of limited use
1279 # when called on a path instead of upon a handle, because there are
1280 # no guarantees that filename (by dirent) whose file (by ino) is
1281 # eventually accessed is the same as the one tested.
1282 # Assumes that the file's existence is not in doubt.
1283 sub is_safe_file {
1284     my $path = shift;
1285     stat($path) || return;    # mysteriously vaporized
1286     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1287
1288     return 0 if $uid != 0 && $uid != $<;
1289     return 0 if $mode & 022;
1290     return 1;
1291 } ## end sub is_safe_file
1292
1293 # If the rcfile (whichever one we decided was the right one to read)
1294 # exists, we safely do it.
1295 if ( -f $rcfile ) {
1296     safe_do("./$rcfile");
1297 }
1298
1299 # If there isn't one here, try the user's home directory.
1300 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1301     safe_do("$ENV{HOME}/$rcfile");
1302 }
1303
1304 # Else try the login directory.
1305 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1306     safe_do("$ENV{LOGDIR}/$rcfile");
1307 }
1308
1309 # If the PERLDB_OPTS variable has options in it, parse those out next.
1310 if ( defined $ENV{PERLDB_OPTS} ) {
1311     parse_options( $ENV{PERLDB_OPTS} );
1312 }
1313
1314 =pod
1315
1316 The last thing we do during initialization is determine which subroutine is
1317 to be used to obtain a new terminal when a new debugger is started. Right now,
1318 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1319 (darwin).
1320
1321 =cut
1322
1323 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1324 # Works if you're running an xterm or xterm-like window, or you're on
1325 # OS/2, or on Mac OS X. This may need some expansion.
1326
1327 if (not defined &get_fork_TTY)       # only if no routine exists
1328 {
1329     if ( defined $remoteport ) {
1330                                                  # Expect an inetd-like server
1331         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1332     }
1333     elsif (defined $ENV{TERM}                    # If we know what kind
1334                                                  # of terminal this is,
1335         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1336         and defined $ENV{DISPLAY}                # and what display it's on,
1337       )
1338     {
1339         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1340     }
1341     elsif ( $ENV{TMUX} ) {
1342         *get_fork_TTY = \&tmux_get_fork_TTY;
1343     }
1344     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1345         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1346     }
1347     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1348             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1349             and $ENV{TERM_PROGRAM}
1350                 eq 'Apple_Terminal'              # Terminal.app
1351             )
1352     {
1353         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1354     }
1355 } ## end if (not defined &get_fork_TTY...
1356
1357 # untaint $^O, which may have been tainted by the last statement.
1358 # see bug [perl #24674]
1359 $^O =~ m/^(.*)\z/;
1360 $^O = $1;
1361
1362 # Here begin the unreadable code.  It needs fixing.
1363
1364 =head2 RESTART PROCESSING
1365
1366 This section handles the restart command. When the C<R> command is invoked, it
1367 tries to capture all of the state it can into environment variables, and
1368 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1369 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1370 the R command stuffed into the environment variables.
1371
1372   PERLDB_RESTART   - flag only, contains no restart data itself.
1373   PERLDB_HIST      - command history, if it's available
1374   PERLDB_ON_LOAD   - breakpoints set by the rc file
1375   PERLDB_POSTPONE  - subs that have been loaded/not executed,
1376                      and have actions
1377   PERLDB_VISITED   - files that had breakpoints
1378   PERLDB_FILE_...  - breakpoints for a file
1379   PERLDB_OPT       - active options
1380   PERLDB_INC       - the original @INC
1381   PERLDB_PRETYPE   - preprompt debugger actions
1382   PERLDB_PRE       - preprompt Perl code
1383   PERLDB_POST      - post-prompt Perl code
1384   PERLDB_TYPEAHEAD - typeahead captured by readline()
1385
1386 We chug through all these variables and plug the values saved in them
1387 back into the appropriate spots in the debugger.
1388
1389 =cut
1390
1391 use vars qw(%postponed_file @typeahead);
1392
1393 our (@hist, @truehist);
1394
1395 sub _restore_shared_globals_after_restart
1396 {
1397     @hist          = get_list('PERLDB_HIST');
1398     %break_on_load = get_list("PERLDB_ON_LOAD");
1399     %postponed     = get_list("PERLDB_POSTPONE");
1400
1401     share(@hist);
1402     share(@truehist);
1403     share(%break_on_load);
1404     share(%postponed);
1405 }
1406
1407 sub _restore_breakpoints_and_actions {
1408
1409     my @had_breakpoints = get_list("PERLDB_VISITED");
1410
1411     for my $file_idx ( 0 .. $#had_breakpoints ) {
1412         my $filename = $had_breakpoints[$file_idx];
1413         my %pf = get_list("PERLDB_FILE_$file_idx");
1414         $postponed_file{ $filename } = \%pf if %pf;
1415         my @lines = sort {$a <=> $b} keys(%pf);
1416         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1417         for my $line_idx (0 .. $#lines) {
1418             _set_breakpoint_enabled_status(
1419                 $filename,
1420                 $lines[$line_idx],
1421                 ($enabled_statuses[$line_idx] ? 1 : ''),
1422             );
1423         }
1424     }
1425
1426     return;
1427 }
1428
1429 sub _restore_options_after_restart
1430 {
1431     my %options_map = get_list("PERLDB_OPT");
1432
1433     while ( my ( $opt, $val ) = each %options_map ) {
1434         $val =~ s/[\\\']/\\$1/g;
1435         parse_options("$opt'$val'");
1436     }
1437
1438     return;
1439 }
1440
1441 sub _restore_globals_after_restart
1442 {
1443     # restore original @INC
1444     @INC     = get_list("PERLDB_INC");
1445     @ini_INC = @INC;
1446
1447     # return pre/postprompt actions and typeahead buffer
1448     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1449     $pre       = [ get_list("PERLDB_PRE") ];
1450     $post      = [ get_list("PERLDB_POST") ];
1451     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1452
1453     return;
1454 }
1455
1456
1457 if ( exists $ENV{PERLDB_RESTART} ) {
1458
1459     # We're restarting, so we don't need the flag that says to restart anymore.
1460     delete $ENV{PERLDB_RESTART};
1461
1462     # $restart = 1;
1463     _restore_shared_globals_after_restart();
1464
1465     _restore_breakpoints_and_actions();
1466
1467     # restore options
1468     _restore_options_after_restart();
1469
1470     _restore_globals_after_restart();
1471 } ## end if (exists $ENV{PERLDB_RESTART...
1472
1473 =head2 SETTING UP THE TERMINAL
1474
1475 Now, we'll decide how the debugger is going to interact with the user.
1476 If there's no TTY, we set the debugger to run non-stop; there's not going
1477 to be anyone there to enter commands.
1478
1479 =cut
1480
1481 use vars qw($notty $console $tty $LINEINFO);
1482 use vars qw($lineinfo $doccmd);
1483
1484 our ($runnonstop);
1485
1486 # Local autoflush to avoid rt#116769,
1487 # as calling IO::File methods causes an unresolvable loop
1488 # that results in debugger failure.
1489 sub _autoflush {
1490     my $o = select($_[0]);
1491     $|++;
1492     select($o);
1493 }
1494
1495 if ($notty) {
1496     $runnonstop = 1;
1497     share($runnonstop);
1498 }
1499
1500 =pod
1501
1502 If there is a TTY, we have to determine who it belongs to before we can
1503 proceed. If this is a slave editor or graphical debugger (denoted by
1504 the first command-line switch being '-emacs'), we shift this off and
1505 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1506
1507 =cut
1508
1509 else {
1510
1511     # Is Perl being run from a slave editor or graphical debugger?
1512     # If so, don't use readline, and set $slave_editor = 1.
1513     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1514         $rl = 0;
1515         shift(@main::ARGV);
1516     }
1517
1518     #require Term::ReadLine;
1519
1520 =pod
1521
1522 We then determine what the console should be on various systems:
1523
1524 =over 4
1525
1526 =item * Cygwin - We use C<stdin> instead of a separate device.
1527
1528 =cut
1529
1530     if ( $^O eq 'cygwin' ) {
1531
1532         # /dev/tty is binary. use stdin for textmode
1533         undef $console;
1534     }
1535
1536 =item * Windows or MSDOS - use C<con>.
1537
1538 =cut
1539
1540     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1541         $console = "con";
1542     }
1543
1544 =item * AmigaOS - use C<CONSOLE:>.
1545
1546 =cut
1547
1548     elsif ( $^O eq 'amigaos' ) {
1549         $console = "CONSOLE:";
1550     }
1551
1552 =item * VMS - use C<sys$command>.
1553
1554 =cut
1555
1556     elsif ($^O eq 'VMS') {
1557         $console = 'sys$command';
1558     }
1559
1560 # Keep this penultimate, on the grounds that it satisfies a wide variety of
1561 # Unix-like systems that would otherwise need to be identified individually.
1562
1563 =item * Unix - use F</dev/tty>.
1564
1565 =cut
1566
1567     elsif ( -e "/dev/tty" ) {
1568         $console = "/dev/tty";
1569     }
1570
1571 # Keep this last.
1572
1573     else {
1574         _db_warn("Can't figure out your console, using stdin");
1575         undef $console;
1576     }
1577
1578 =pod
1579
1580 =back
1581
1582 Several other systems don't use a specific console. We C<undef $console>
1583 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1584 with a slave editor).
1585
1586 =cut
1587
1588     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1589
1590         # /dev/tty is binary. use stdin for textmode
1591         $console = undef;
1592     }
1593
1594     if ( $^O eq 'NetWare' ) {
1595
1596         # /dev/tty is binary. use stdin for textmode
1597         $console = undef;
1598     }
1599
1600     # In OS/2, we need to use STDIN to get textmode too, even though
1601     # it pretty much looks like Unix otherwise.
1602     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1603     {    # In OS/2
1604         $console = undef;
1605     }
1606
1607 =pod
1608
1609 If there is a TTY hanging around from a parent, we use that as the console.
1610
1611 =cut
1612
1613     $console = $tty if defined $tty;
1614
1615 =head2 SOCKET HANDLING
1616
1617 The debugger is capable of opening a socket and carrying out a debugging
1618 session over the socket.
1619
1620 If C<RemotePort> was defined in the options, the debugger assumes that it
1621 should try to start a debugging session on that port. It builds the socket
1622 and then tries to connect the input and output filehandles to it.
1623
1624 =cut
1625
1626     # Handle socket stuff.
1627
1628     if ( defined $remoteport ) {
1629
1630         # If RemotePort was defined in the options, connect input and output
1631         # to the socket.
1632         $IN = $OUT = connect_remoteport();
1633     } ## end if (defined $remoteport)
1634
1635 =pod
1636
1637 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1638 this is probably a situation where multiple debuggers are running (for example,
1639 a backticked command that starts up another debugger). We create a new IN and
1640 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1641 and if we can.
1642
1643 =cut
1644
1645     # Non-socket.
1646     else {
1647
1648         # Two debuggers running (probably a system or a backtick that invokes
1649         # the debugger itself under the running one). create a new IN and OUT
1650         # filehandle, and do the necessary mojo to create a new tty if we
1651         # know how, and we can.
1652         create_IN_OUT(4) if $CreateTTY & 4;
1653         if ($console) {
1654
1655             # If we have a console, check to see if there are separate ins and
1656             # outs to open. (They are assumed identical if not.)
1657
1658             my ( $i, $o ) = split /,/, $console;
1659             $o = $i unless defined $o;
1660
1661             # read/write on in, or just read, or read on STDIN.
1662                  open( IN, '+<', $i )
1663               || open( IN, '<',  $i )
1664               || open( IN, "<&STDIN" );
1665
1666             # read/write/create/clobber out, or write/create/clobber out,
1667             # or merge with STDERR, or merge with STDOUT.
1668                  open( OUT, '+>', $o )
1669               || open( OUT, '>',  $o )
1670               || open( OUT, ">&STDERR" )
1671               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1672
1673         } ## end if ($console)
1674         elsif ( not defined $console ) {
1675
1676             # No console. Open STDIN.
1677             open( IN, "<&STDIN" );
1678
1679             # merge with STDERR, or with STDOUT.
1680             open( OUT,      ">&STDERR" )
1681               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1682             $console = 'STDIN/OUT';
1683         } ## end elsif (not defined $console)
1684
1685         # Keep copies of the filehandles so that when the pager runs, it
1686         # can close standard input without clobbering ours.
1687         if ($console or (not defined($console))) {
1688             $IN = \*IN;
1689             $OUT = \*OUT;
1690         }
1691     } ## end elsif (from if(defined $remoteport))
1692
1693     # Unbuffer DB::OUT. We need to see responses right away.
1694     _autoflush($OUT);
1695
1696     # Line info goes to debugger output unless pointed elsewhere.
1697     # Pointing elsewhere makes it possible for slave editors to
1698     # keep track of file and position. We have both a filehandle
1699     # and a I/O description to keep track of.
1700     $LINEINFO = $OUT     unless defined $LINEINFO;
1701     $lineinfo = $console unless defined $lineinfo;
1702     # share($LINEINFO); # <- unable to share globs
1703     share($lineinfo);   #
1704
1705 =pod
1706
1707 To finish initialization, we show the debugger greeting,
1708 and then call the C<afterinit()> subroutine if there is one.
1709
1710 =cut
1711
1712     # Show the debugger greeting.
1713     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1714     unless ($runnonstop) {
1715         local $\ = '';
1716         local $, = '';
1717         if ( $term_pid eq '-1' ) {
1718             print $OUT "\nDaughter DB session started...\n";
1719         }
1720         else {
1721             print $OUT "\nLoading DB routines from $header\n";
1722             print $OUT (
1723                 "Editor support ",
1724                 $slave_editor ? "enabled" : "available", ".\n"
1725             );
1726             print $OUT
1727 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1728         } ## end else [ if ($term_pid eq '-1')
1729     } ## end unless ($runnonstop)
1730 } ## end else [ if ($notty)
1731
1732 # XXX This looks like a bug to me.
1733 # Why copy to @ARGS and then futz with @args?
1734 @ARGS = @ARGV;
1735 # for (@args) {
1736     # Make sure backslashes before single quotes are stripped out, and
1737     # keep args unless they are numeric (XXX why?)
1738     # s/\'/\\\'/g;                      # removed while not justified understandably
1739     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1740 # }
1741
1742 # If there was an afterinit() sub defined, call it. It will get
1743 # executed in our scope, so it can fiddle with debugger globals.
1744 if ( defined &afterinit ) {    # May be defined in $rcfile
1745     afterinit();
1746 }
1747
1748 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1749 use vars qw($I_m_init);
1750
1751 $I_m_init = 1;
1752
1753 ############################################################ Subroutines
1754
1755 =head1 SUBROUTINES
1756
1757 =head2 DB
1758
1759 This gigantic subroutine is the heart of the debugger. Called before every
1760 statement, its job is to determine if a breakpoint has been reached, and
1761 stop if so; read commands from the user, parse them, and execute
1762 them, and then send execution off to the next statement.
1763
1764 Note that the order in which the commands are processed is very important;
1765 some commands earlier in the loop will actually alter the C<$cmd> variable
1766 to create other commands to be executed later. This is all highly I<optimized>
1767 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1768 see what's happening in any given command.
1769
1770 =cut
1771
1772 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1773
1774 use vars qw(
1775     $action
1776     $cmd
1777     $file
1778     $filename_ini
1779     $finished
1780     %had_breakpoints
1781     $level
1782     $max
1783     $package
1784     $try
1785 );
1786
1787 our (
1788     %alias,
1789     $doret,
1790     $end,
1791     $fall_off_end,
1792     $incr,
1793     $laststep,
1794     $rc,
1795     $sh,
1796     $stack_depth,
1797     @stack,
1798     @to_watch,
1799     @old_watch,
1800 );
1801
1802 sub _DB__determine_if_we_should_break
1803 {
1804     # if we have something here, see if we should break.
1805     # $stop is lexical and local to this block - $action on the other hand
1806     # is global.
1807     my $stop;
1808
1809     if ( $dbline{$line}
1810         && _is_breakpoint_enabled($filename, $line)
1811         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1812     {
1813
1814         # Stop if the stop criterion says to just stop.
1815         if ( $stop eq '1' ) {
1816             $signal |= 1;
1817         }
1818
1819         # It's a conditional stop; eval it in the user's context and
1820         # see if we should stop. If so, remove the one-time sigil.
1821         elsif ($stop) {
1822             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1823             # The &-call is here to ascertain the mutability of @_.
1824             &DB::eval;
1825             # If the breakpoint is temporary, then delete its enabled status.
1826             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1827                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1828             }
1829         }
1830     } ## end if ($dbline{$line} && ...
1831 }
1832
1833 sub _DB__is_finished {
1834     if ($finished and $level <= 1) {
1835         end_report();
1836         return 1;
1837     }
1838     else {
1839         return;
1840     }
1841 }
1842
1843 sub _DB__read_next_cmd
1844 {
1845     my ($tid) = @_;
1846
1847     # We have a terminal, or can get one ...
1848     if (!$term) {
1849         setterm();
1850     }
1851
1852     # ... and it belongs to this PID or we get one for this PID ...
1853     if ($term_pid != $$) {
1854         resetterm(1);
1855     }
1856
1857     # ... and we got a line of command input ...
1858     $cmd = DB::readline(
1859         "$pidprompt $tid DB"
1860         . ( '<' x $level )
1861         . ( $#hist + 1 )
1862         . ( '>' x $level ) . " "
1863     );
1864
1865     return defined($cmd);
1866 }
1867
1868 sub _DB__trim_command_and_return_first_component {
1869     my ($obj) = @_;
1870
1871     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1872     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1873
1874     # A single-character debugger command can be immediately followed by its
1875     # argument if they aren't both alphanumeric; otherwise require space
1876     # between commands and arguments:
1877     my ($verb, $args) = $cmd =~ m{\A(.\b|\S*)\s*(.*)}s;
1878
1879     $obj->cmd_verb($verb);
1880     $obj->cmd_args($args);
1881
1882     return;
1883 }
1884
1885 sub _DB__handle_f_command {
1886     my ($obj) = @_;
1887
1888     if ($file = $obj->cmd_args) {
1889         # help for no arguments (old-style was return from sub).
1890         if ( !$file ) {
1891             print $OUT
1892             "The old f command is now the r command.\n";    # hint
1893             print $OUT "The new f command switches filenames.\n";
1894             next CMD;
1895         } ## end if (!$file)
1896
1897         # if not in magic file list, try a close match.
1898         if ( !defined $main::{ '_<' . $file } ) {
1899             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1900                 {
1901                     $try = substr( $try, 2 );
1902                     print $OUT "Choosing $try matching '$file':\n";
1903                     $file = $try;
1904                 }
1905             } ## end if (($try) = grep(m#^_<.*$file#...
1906         } ## end if (!defined $main::{ ...
1907
1908         # If not successfully switched now, we failed.
1909         if ( !defined $main::{ '_<' . $file } ) {
1910             print $OUT "No file matching '$file' is loaded.\n";
1911             next CMD;
1912         }
1913
1914         # We switched, so switch the debugger internals around.
1915         elsif ( $file ne $filename ) {
1916             *dbline   = $main::{ '_<' . $file };
1917             $max      = $#dbline;
1918             $filename = $file;
1919             $start    = 1;
1920             $cmd      = "l";
1921         } ## end elsif ($file ne $filename)
1922
1923         # We didn't switch; say we didn't.
1924         else {
1925             print $OUT "Already in $file.\n";
1926             next CMD;
1927         }
1928     }
1929
1930     return;
1931 }
1932
1933 sub _DB__handle_dot_command {
1934     my ($obj) = @_;
1935
1936     # . command.
1937     if ($obj->_is_full('.')) {
1938         $incr = -1;    # stay at current line
1939
1940         # Reset everything to the old location.
1941         $start    = $line;
1942         $filename = $filename_ini;
1943         *dbline   = $main::{ '_<' . $filename };
1944         $max      = $#dbline;
1945
1946         # Now where are we?
1947         print_lineinfo($obj->position());
1948         next CMD;
1949     }
1950
1951     return;
1952 }
1953
1954 sub _DB__handle_y_command {
1955     my ($obj) = @_;
1956
1957     if (my ($match_level, $match_vars)
1958         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1959
1960         # See if we've got the necessary support.
1961         if (!eval {
1962             local @INC = @INC;
1963             pop @INC if $INC[-1] eq '.';
1964             require PadWalker; PadWalker->VERSION(0.08) }) {
1965             my $Err = $@;
1966             _db_warn(
1967                 $Err =~ /locate/
1968                 ? "PadWalker module not found - please install\n"
1969                 : $Err
1970             );
1971             next CMD;
1972         }
1973
1974         # Load up dumpvar if we don't have it. If we can, that is.
1975         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1976         defined &main::dumpvar
1977             or print $OUT "dumpvar.pl not available.\n"
1978             and next CMD;
1979
1980         # Got all the modules we need. Find them and print them.
1981         my @vars = split( ' ', $match_vars || '' );
1982
1983         # Find the pad.
1984         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 2 ) };
1985
1986         # Oops. Can't find it.
1987         if (my $Err = $@) {
1988             $Err =~ s/ at .*//;
1989             _db_warn($Err);
1990             next CMD;
1991         }
1992
1993         # Show the desired vars with dumplex().
1994         my $savout = select($OUT);
1995
1996         # Have dumplex dump the lexicals.
1997         foreach my $key (sort keys %$h) {
1998             dumpvar::dumplex( $key, $h->{$key},
1999                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2000                 @vars );
2001         }
2002         select($savout);
2003         next CMD;
2004     }
2005 }
2006
2007 sub _DB__handle_c_command {
2008     my ($obj) = @_;
2009
2010     my $i = $obj->cmd_args;
2011
2012     if ($i =~ m#\A[\w:]*\z#) {
2013
2014         # Hey, show's over. The debugged program finished
2015         # executing already.
2016         next CMD if _DB__is_finished();
2017
2018         # Capture the place to put a one-time break.
2019         $subname = $i;
2020
2021         #  Probably not needed, since we finish an interactive
2022         #  sub-session anyway...
2023         # local $filename = $filename;
2024         # local *dbline = *dbline; # XXX Would this work?!
2025         #
2026         # The above question wonders if localizing the alias
2027         # to the magic array works or not. Since it's commented
2028         # out, we'll just leave that to speculation for now.
2029
2030         # If the "subname" isn't all digits, we'll assume it
2031         # is a subroutine name, and try to find it.
2032         if ( $subname =~ /\D/ ) {    # subroutine name
2033             # Qualify it to the current package unless it's
2034             # already qualified.
2035             $subname = $package . "::" . $subname
2036             unless $subname =~ /::/;
2037
2038             # find_sub will return "file:line_number" corresponding
2039             # to where the subroutine is defined; we call find_sub,
2040             # break up the return value, and assign it in one
2041             # operation.
2042             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2043
2044             # Force the line number to be numeric.
2045             $i = $i + 0;
2046
2047             # If we got a line number, we found the sub.
2048             if ($i) {
2049
2050                 # Switch all the debugger's internals around so
2051                 # we're actually working with that file.
2052                 $filename = $file;
2053                 *dbline   = $main::{ '_<' . $filename };
2054
2055                 # Mark that there's a breakpoint in this file.
2056                 $had_breakpoints{$filename} |= 1;
2057
2058                 # Scan forward to the first executable line
2059                 # after the 'sub whatever' line.
2060                 $max = $#dbline;
2061                 my $_line_num = $i;
2062                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2063                 {
2064                     $_line_num++;
2065                 }
2066                 $i = $_line_num;
2067             } ## end if ($i)
2068
2069             # We didn't find a sub by that name.
2070             else {
2071                 print $OUT "Subroutine $subname not found.\n";
2072                 next CMD;
2073             }
2074         } ## end if ($subname =~ /\D/)
2075
2076         # At this point, either the subname was all digits (an
2077         # absolute line-break request) or we've scanned through
2078         # the code following the definition of the sub, looking
2079         # for an executable, which we may or may not have found.
2080         #
2081         # If $i (which we set $subname from) is non-zero, we
2082         # got a request to break at some line somewhere. On
2083         # one hand, if there wasn't any real subroutine name
2084         # involved, this will be a request to break in the current
2085         # file at the specified line, so we have to check to make
2086         # sure that the line specified really is breakable.
2087         #
2088         # On the other hand, if there was a subname supplied, the
2089         # preceding block has moved us to the proper file and
2090         # location within that file, and then scanned forward
2091         # looking for the next executable line. We have to make
2092         # sure that one was found.
2093         #
2094         # On the gripping hand, we can't do anything unless the
2095         # current value of $i points to a valid breakable line.
2096         # Check that.
2097         if ($i) {
2098
2099             # Breakable?
2100             if ( $dbline[$i] == 0 ) {
2101                 print $OUT "Line $i not breakable.\n";
2102                 next CMD;
2103             }
2104
2105             # Yes. Set up the one-time-break sigil.
2106             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2107             _enable_breakpoint_temp_enabled_status($filename, $i);
2108         } ## end if ($i)
2109
2110         # Turn off stack tracing from here up.
2111         for my $j (0 .. $stack_depth) {
2112             $stack[ $j ] &= ~1;
2113         }
2114         last CMD;
2115     }
2116
2117     return;
2118 }
2119
2120 sub _DB__handle_forward_slash_command {
2121     my ($obj) = @_;
2122
2123     # The pattern as a string.
2124     use vars qw($inpat);
2125
2126     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2127
2128         # Remove the final slash.
2129         $inpat =~ s:([^\\])/$:$1:;
2130
2131         # If the pattern isn't null ...
2132         if ( $inpat ne "" ) {
2133
2134             # Turn off warn and die processing for a bit.
2135             local $SIG{__DIE__};
2136             local $SIG{__WARN__};
2137
2138             # Create the pattern.
2139             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2140             if ( $@ ne "" ) {
2141
2142                 # Oops. Bad pattern. No biscuit.
2143                 # Print the eval error and go back for more
2144                 # commands.
2145                 print {$OUT} "$@";
2146                 next CMD;
2147             }
2148             $obj->pat($inpat);
2149         } ## end if ($inpat ne "")
2150
2151         # Set up to stop on wrap-around.
2152         $end = $start;
2153
2154         # Don't move off the current line.
2155         $incr = -1;
2156
2157         my $pat = $obj->pat;
2158
2159         # Done in eval so nothing breaks if the pattern
2160         # does something weird.
2161         eval
2162         {
2163             no strict q/vars/;
2164             for (;;) {
2165                 # Move ahead one line.
2166                 ++$start;
2167
2168                 # Wrap if we pass the last line.
2169                 if ($start > $max) {
2170                     $start = 1;
2171                 }
2172
2173                 # Stop if we have gotten back to this line again,
2174                 last if ($start == $end);
2175
2176                 # A hit! (Note, though, that we are doing
2177                 # case-insensitive matching. Maybe a qr//
2178                 # expression would be better, so the user could
2179                 # do case-sensitive matching if desired.
2180                 if ($dbline[$start] =~ m/$pat/i) {
2181                     if ($slave_editor) {
2182                         # Handle proper escaping in the slave.
2183                         print {$OUT} "\032\032$filename:$start:0\n";
2184                     }
2185                     else {
2186                         # Just print the line normally.
2187                         print {$OUT} "$start:\t",$dbline[$start],"\n";
2188                     }
2189                     # And quit since we found something.
2190                     last;
2191                 }
2192             }
2193         };
2194
2195         if ($@) {
2196             warn $@;
2197         }
2198
2199         # If we wrapped, there never was a match.
2200         if ( $start == $end ) {
2201             print {$OUT} "/$pat/: not found\n";
2202         }
2203         next CMD;
2204     }
2205
2206     return;
2207 }
2208
2209 sub _DB__handle_question_mark_command {
2210     my ($obj) = @_;
2211
2212     # ? - backward pattern search.
2213     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2214
2215         # Get the pattern, remove trailing question mark.
2216         $inpat =~ s:([^\\])\?$:$1:;
2217
2218         # If we've got one ...
2219         if ( $inpat ne "" ) {
2220
2221             # Turn off die & warn handlers.
2222             local $SIG{__DIE__};
2223             local $SIG{__WARN__};
2224             eval '$inpat =~ m' . "\a$inpat\a";
2225
2226             if ( $@ ne "" ) {
2227
2228                 # Ouch. Not good. Print the error.
2229                 print $OUT $@;
2230                 next CMD;
2231             }
2232             $obj->pat($inpat);
2233         } ## end if ($inpat ne "")
2234
2235         # Where we are now is where to stop after wraparound.
2236         $end = $start;
2237
2238         # Don't move away from this line.
2239         $incr = -1;
2240
2241         my $pat = $obj->pat;
2242         # Search inside the eval to prevent pattern badness
2243         # from killing us.
2244         eval {
2245             no strict q/vars/;
2246             for (;;) {
2247                 # Back up a line.
2248                 --$start;
2249
2250                 # Wrap if we pass the first line.
2251
2252                 $start = $max if ($start <= 0);
2253
2254                 # Quit if we get back where we started,
2255                 last if ($start == $end);
2256
2257                 # Match?
2258                 if ($dbline[$start] =~ m/$pat/i) {
2259                     if ($slave_editor) {
2260                         # Yep, follow slave editor requirements.
2261                         print $OUT "\032\032$filename:$start:0\n";
2262                     }
2263                     else {
2264                         # Yep, just print normally.
2265                         print $OUT "$start:\t",$dbline[$start],"\n";
2266                     }
2267
2268                     # Found, so done.
2269                     last;
2270                 }
2271             }
2272         };
2273
2274         # Say we failed if the loop never found anything,
2275         if ( $start == $end ) {
2276             print {$OUT} "?$pat?: not found\n";
2277         }
2278         next CMD;
2279     }
2280
2281     return;
2282 }
2283
2284 sub _DB__handle_restart_and_rerun_commands {
2285     my ($obj) = @_;
2286
2287     my $cmd_cmd = $obj->cmd_verb;
2288     my $cmd_params = $obj->cmd_args;
2289     # R - restart execution.
2290     # rerun - controlled restart execution.
2291     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2292
2293         # Change directory to the initial current working directory on
2294         # the script startup, so if the debugged program changed the
2295         # directory, then we will still be able to find the path to the
2296         # the program. (perl 5 RT #121509 ).
2297         chdir ($_initial_cwd);
2298
2299         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2300
2301         # Close all non-system fds for a clean restart.  A more
2302         # correct method would be to close all fds that were not
2303         # open when the process started, but this seems to be
2304         # hard.  See "debugger 'R'estart and open database
2305         # connections" on p5p.
2306
2307         my $max_fd = 1024; # default if POSIX can't be loaded
2308         if (eval { require POSIX }) {
2309             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2310         }
2311
2312         if (defined $max_fd) {
2313             foreach ($^F+1 .. $max_fd-1) {
2314                 next unless open FD_TO_CLOSE, "<&=$_";
2315                 close(FD_TO_CLOSE);
2316             }
2317         }
2318
2319         # And run Perl again.  We use exec() to keep the
2320         # PID stable (and that way $ini_pids is still valid).
2321         exec(@args) or print {$OUT} "exec failed: $!\n";
2322
2323         last CMD;
2324     }
2325
2326     return;
2327 }
2328
2329 sub _DB__handle_run_command_in_pager_command {
2330     my ($obj) = @_;
2331
2332     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2333         if ( $pager =~ /^\|/ ) {
2334
2335             # Default pager is into a pipe. Redirect I/O.
2336             open( SAVEOUT, ">&STDOUT" )
2337             || _db_warn("Can't save STDOUT");
2338             open( STDOUT, ">&OUT" )
2339             || _db_warn("Can't redirect STDOUT");
2340         } ## end if ($pager =~ /^\|/)
2341         else {
2342
2343             # Not into a pipe. STDOUT is safe.
2344             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2345         }
2346
2347         # Fix up environment to record we have less if so.
2348         fix_less();
2349
2350         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2351
2352             # Couldn't open pipe to pager.
2353             _db_warn("Can't pipe output to '$pager'");
2354             if ( $pager =~ /^\|/ ) {
2355
2356                 # Redirect I/O back again.
2357                 open( OUT, ">&STDOUT" )    # XXX: lost message
2358                 || _db_warn("Can't restore DB::OUT");
2359                 open( STDOUT, ">&SAVEOUT" )
2360                 || _db_warn("Can't restore STDOUT");
2361                 close(SAVEOUT);
2362             } ## end if ($pager =~ /^\|/)
2363             else {
2364
2365                 # Redirect I/O. STDOUT already safe.
2366                 open( OUT, ">&STDOUT" )    # XXX: lost message
2367                 || _db_warn("Can't restore DB::OUT");
2368             }
2369             next CMD;
2370         } ## end unless ($piped = open(OUT,...
2371
2372         # Set up broken-pipe handler if necessary.
2373         $SIG{PIPE} = \&DB::catch
2374         if $pager =~ /^\|/
2375         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2376
2377         _autoflush(\*OUT);
2378         # Save current filehandle, and put it back.
2379         $obj->selected(scalar( select(OUT) ));
2380         # Don't put it back if pager was a pipe.
2381         if ($cmd !~ /\A\|\|/)
2382         {
2383             select($obj->selected());
2384             $obj->selected("");
2385         }
2386
2387         # Trim off the pipe symbols and run the command now.
2388         $cmd =~ s#\A\|+\s*##;
2389         redo PIPE;
2390     }
2391
2392     return;
2393 }
2394
2395 sub _DB__handle_m_command {
2396     my ($obj) = @_;
2397
2398     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2399         methods($1);
2400         next CMD;
2401     }
2402
2403     # m expr - set up DB::eval to do the work
2404     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2405         $onetimeDump = 'methods';   #  method output gets used there
2406     }
2407
2408     return;
2409 }
2410
2411 sub _DB__at_end_of_every_command {
2412     my ($obj) = @_;
2413
2414     # At the end of every command:
2415     if ($obj->piped) {
2416
2417         # Unhook the pipe mechanism now.
2418         if ( $pager =~ /^\|/ ) {
2419
2420             # No error from the child.
2421             $? = 0;
2422
2423             # we cannot warn here: the handle is missing --tchrist
2424             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2425
2426             # most of the $? crud was coping with broken cshisms
2427             # $? is explicitly set to 0, so this never runs.
2428             if ($?) {
2429                 print SAVEOUT "Pager '$pager' failed: ";
2430                 if ( $? == -1 ) {
2431                     print SAVEOUT "shell returned -1\n";
2432                 }
2433                 elsif ( $? >> 8 ) {
2434                     print SAVEOUT ( $? & 127 )
2435                     ? " (SIG#" . ( $? & 127 ) . ")"
2436                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2437                 }
2438                 else {
2439                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2440                 }
2441             } ## end if ($?)
2442
2443             # Reopen filehandle for our output (if we can) and
2444             # restore STDOUT (if we can).
2445             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2446             open( STDOUT, ">&SAVEOUT" )
2447             || _db_warn("Can't restore STDOUT");
2448
2449             # Turn off pipe exception handler if necessary.
2450             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2451
2452             # Will stop ignoring SIGPIPE if done like nohup(1)
2453             # does SIGINT but Perl doesn't give us a choice.
2454         } ## end if ($pager =~ /^\|/)
2455         else {
2456
2457             # Non-piped "pager". Just restore STDOUT.
2458             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2459         }
2460
2461         # Let Readline know about the new filehandles.
2462         reset_IN_OUT( \*IN, \*OUT );
2463
2464         # Close filehandle pager was using, restore the normal one
2465         # if necessary,
2466         close(SAVEOUT);
2467
2468         if ($obj->selected() ne "") {
2469             select($obj->selected);
2470             $obj->selected("");
2471         }
2472
2473         # No pipes now.
2474         $obj->piped("");
2475     } ## end if ($piped)
2476
2477     return;
2478 }
2479
2480 sub _DB__handle_watch_expressions
2481 {
2482     my $self = shift;
2483
2484     if ( $DB::trace & 2 ) {
2485         for my $n (0 .. $#DB::to_watch) {
2486             $DB::evalarg = $DB::to_watch[$n];
2487             local $DB::onetimeDump;    # Tell DB::eval() to not output results
2488
2489             # Fix context DB::eval() wants to return an array, but
2490             # we need a scalar here.
2491             my ($val) = join( "', '", DB::eval(@_) );
2492             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
2493
2494             # Did it change?
2495             if ( $val ne $DB::old_watch[$n] ) {
2496
2497                 # Yep! Show the difference, and fake an interrupt.
2498                 $DB::signal = 1;
2499                 print {$DB::OUT} <<EOP;
2500 Watchpoint $n:\t$DB::to_watch[$n] changed:
2501     old value:\t$DB::old_watch[$n]
2502     new value:\t$val
2503 EOP
2504                 $DB::old_watch[$n] = $val;
2505             } ## end if ($val ne $old_watch...
2506         } ## end for my $n (0 ..
2507     } ## end if ($trace & 2)
2508
2509     return;
2510 }
2511
2512 # 't' is type.
2513 # 'm' is method.
2514 # 'v' is the value (i.e: method name or subroutine ref).
2515 # 's' is subroutine.
2516 my %cmd_lookup;
2517
2518 BEGIN
2519 {
2520     %cmd_lookup =
2521 (
2522     '-' => { t => 'm', v => '_handle_dash_command', },
2523     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2524     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2525     'H' => { t => 'm', v => '_handle_H_command', },
2526     'S' => { t => 'm', v => '_handle_S_command', },
2527     'T' => { t => 'm', v => '_handle_T_command', },
2528     'W' => { t => 'm', v => '_handle_W_command', },
2529     'c' => { t => 's', v => \&_DB__handle_c_command, },
2530     'f' => { t => 's', v => \&_DB__handle_f_command, },
2531     'm' => { t => 's', v => \&_DB__handle_m_command, },
2532     'n' => { t => 'm', v => '_handle_n_command', },
2533     'p' => { t => 'm', v => '_handle_p_command', },
2534     'q' => { t => 'm', v => '_handle_q_command', },
2535     'r' => { t => 'm', v => '_handle_r_command', },
2536     's' => { t => 'm', v => '_handle_s_command', },
2537     'save' => { t => 'm', v => '_handle_save_command', },
2538     'source' => { t => 'm', v => '_handle_source_command', },
2539     't' => { t => 'm', v => '_handle_t_command', },
2540     'w' => { t => 'm', v => '_handle_w_command', },
2541     'x' => { t => 'm', v => '_handle_x_command', },
2542     'y' => { t => 's', v => \&_DB__handle_y_command, },
2543     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2544         ('X', 'V')),
2545     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2546         qw(enable disable)),
2547     (map { $_ =>
2548         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2549         } qw(R rerun)),
2550     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2551         qw(a A b B e E h i l L M o O v w W)),
2552 );
2553 };
2554
2555 sub DB {
2556
2557     # lock the debugger and get the thread id for the prompt
2558     lock($DBGR);
2559     my $tid;
2560     my $position;
2561     my ($prefix, $after, $infix);
2562     my $pat;
2563     my $explicit_stop;
2564     my $piped;
2565     my $selected;
2566
2567     if ($ENV{PERL5DB_THREADED}) {
2568         $tid = eval { "[".threads->tid."]" };
2569     }
2570
2571     my $cmd_verb;
2572     my $cmd_args;
2573
2574     my $obj = DB::Obj->new(
2575         {
2576             position => \$position,
2577             prefix => \$prefix,
2578             after => \$after,
2579             explicit_stop => \$explicit_stop,
2580             infix => \$infix,
2581             cmd_args => \$cmd_args,
2582             cmd_verb => \$cmd_verb,
2583             pat => \$pat,
2584             piped => \$piped,
2585             selected => \$selected,
2586         },
2587     );
2588
2589     $obj->_DB_on_init__initialize_globals(@_);
2590
2591     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2592     # The code being debugged may have altered them.
2593     DB::save();
2594
2595     # Since DB::DB gets called after every line, we can use caller() to
2596     # figure out where we last were executing. Sneaky, eh? This works because
2597     # caller is returning all the extra information when called from the
2598     # debugger.
2599     local ( $package, $filename, $line ) = caller;
2600     $filename_ini = $filename;
2601
2602     # set up the context for DB::eval, so it can properly execute
2603     # code on behalf of the user. We add the package in so that the
2604     # code is eval'ed in the proper package (not in the debugger!).
2605     local $usercontext = _calc_usercontext($package);
2606
2607     # Create an alias to the active file magical array to simplify
2608     # the code here.
2609     local (*dbline) = $main::{ '_<' . $filename };
2610
2611     # Last line in the program.
2612     $max = $#dbline;
2613
2614     # The &-call is here to ascertain the mutability of @_.
2615     &_DB__determine_if_we_should_break;
2616
2617     # Preserve the current stop-or-not, and see if any of the W
2618     # (watch expressions) has changed.
2619     my $was_signal = $signal;
2620
2621     # If we have any watch expressions ...
2622     _DB__handle_watch_expressions($obj);
2623
2624 =head2 C<watchfunction()>
2625
2626 C<watchfunction()> is a function that can be defined by the user; it is a
2627 function which will be run on each entry to C<DB::DB>; it gets the
2628 current package, filename, and line as its parameters.
2629
2630 The watchfunction can do anything it likes; it is executing in the
2631 debugger's context, so it has access to all of the debugger's internal
2632 data structures and functions.
2633
2634 C<watchfunction()> can control the debugger's actions. Any of the following
2635 will cause the debugger to return control to the user's program after
2636 C<watchfunction()> executes:
2637
2638 =over 4
2639
2640 =item *
2641
2642 Returning a false value from the C<watchfunction()> itself.
2643
2644 =item *
2645
2646 Altering C<$single> to a false value.
2647
2648 =item *
2649
2650 Altering C<$signal> to a false value.
2651
2652 =item *
2653
2654 Turning off the C<4> bit in C<$trace> (this also disables the
2655 check for C<watchfunction()>. This can be done with
2656
2657     $trace &= ~4;
2658
2659 =back
2660
2661 =cut
2662
2663     # If there's a user-defined DB::watchfunction, call it with the
2664     # current package, filename, and line. The function executes in
2665     # the DB:: package.
2666     if ( $trace & 4 ) {    # User-installed watch
2667         return
2668           if watchfunction( $package, $filename, $line )
2669           and not $single
2670           and not $was_signal
2671           and not( $trace & ~4 );
2672     } ## end if ($trace & 4)
2673
2674     # Pick up any alteration to $signal in the watchfunction, and
2675     # turn off the signal now.
2676     $was_signal = $signal;
2677     $signal     = 0;
2678
2679 =head2 GETTING READY TO EXECUTE COMMANDS
2680
2681 The debugger decides to take control if single-step mode is on, the
2682 C<t> command was entered, or the user generated a signal. If the program
2683 has fallen off the end, we set things up so that entering further commands
2684 won't cause trouble, and we say that the program is over.
2685
2686 =cut
2687
2688     # Make sure that we always print if asked for explicitly regardless
2689     # of $trace_to_depth .
2690     $explicit_stop = ($single || $was_signal);
2691
2692     # Check to see if we should grab control ($single true,
2693     # trace set appropriately, or we got a signal).
2694     if ( $explicit_stop || ( $trace & 1 ) ) {
2695         $obj->_DB__grab_control(@_);
2696     } ## end if ($single || ($trace...
2697
2698 =pod
2699
2700 If there's an action to be executed for the line we stopped at, execute it.
2701 If there are any preprompt actions, execute those as well.
2702
2703 =cut
2704
2705     # If there's an action, do it now.
2706     if ($action) {
2707         $evalarg = $action;
2708         # The &-call is here to ascertain the mutability of @_.
2709         &DB::eval;
2710     }
2711
2712     # Are we nested another level (e.g., did we evaluate a function
2713     # that had a breakpoint in it at the debugger prompt)?
2714     if ( $single || $was_signal ) {
2715
2716         # Yes, go down a level.
2717         local $level = $level + 1;
2718
2719         # Do any pre-prompt actions.
2720         foreach $evalarg (@$pre) {
2721             # The &-call is here to ascertain the mutability of @_.
2722             &DB::eval;
2723         }
2724
2725         # Complain about too much recursion if we passed the limit.
2726         if ($single & 4) {
2727             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2728         }
2729
2730         # The line we're currently on. Set $incr to -1 to stay here
2731         # until we get a command that tells us to advance.
2732         $start = $line;
2733         $incr  = -1;      # for backward motion.
2734
2735         # Tack preprompt debugger actions ahead of any actual input.
2736         @typeahead = ( @$pretype, @typeahead );
2737
2738 =head2 WHERE ARE WE?
2739
2740 XXX Relocate this section?
2741
2742 The debugger normally shows the line corresponding to the current line of
2743 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2744 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2745
2746 C<$incr> controls by how many lines the I<current> line should move forward
2747 after a command is executed. If set to -1, this indicates that the I<current>
2748 line shouldn't change.
2749
2750 C<$start> is the I<current> line. It is used for things like knowing where to
2751 move forwards or backwards from when doing an C<L> or C<-> command.
2752
2753 C<$max> tells the debugger where the last line of the current file is. It's
2754 used to terminate loops most often.
2755
2756 =head2 THE COMMAND LOOP
2757
2758 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2759 in two parts:
2760
2761 =over 4
2762
2763 =item *
2764
2765 The outer part of the loop, starting at the C<CMD> label. This loop
2766 reads a command and then executes it.
2767
2768 =item *
2769
2770 The inner part of the loop, starting at the C<PIPE> label. This part
2771 is wholly contained inside the C<CMD> block and only executes a command.
2772 Used to handle commands running inside a pager.
2773
2774 =back
2775
2776 So why have two labels to restart the loop? Because sometimes, it's easier to
2777 have a command I<generate> another command and then re-execute the loop to do
2778 the new command. This is faster, but perhaps a bit more convoluted.
2779
2780 =cut
2781
2782         # The big command dispatch loop. It keeps running until the
2783         # user yields up control again.
2784         #
2785         # If we have a terminal for input, and we get something back
2786         # from readline(), keep on processing.
2787
2788       CMD:
2789         while (_DB__read_next_cmd($tid))
2790         {
2791
2792             share($cmd);
2793             # ... try to execute the input as debugger commands.
2794
2795             # Don't stop running.
2796             $single = 0;
2797
2798             # No signal is active.
2799             $signal = 0;
2800
2801             # Handle continued commands (ending with \):
2802             if ($cmd =~ s/\\\z/\n/) {
2803                 $cmd .= DB::readline("  cont: ");
2804                 redo CMD;
2805             }
2806
2807 =head4 The null command
2808
2809 A newline entered by itself means I<re-execute the last command>. We grab the
2810 command out of C<$laststep> (where it was recorded previously), and copy it
2811 back into C<$cmd> to be executed below. If there wasn't any previous command,
2812 we'll do nothing below (no command will match). If there was, we also save it
2813 in the command history and fall through to allow the command parsing to pick
2814 it up.
2815
2816 =cut
2817
2818             # Empty input means repeat the last command.
2819             if ($cmd eq '') {
2820                 $cmd = $laststep;
2821             }
2822             chomp($cmd);    # get rid of the annoying extra newline
2823             if (length($cmd) >= 2) {
2824                 push( @hist, $cmd );
2825             }
2826             push( @truehist, $cmd );
2827             share(@hist);
2828             share(@truehist);
2829
2830             # This is a restart point for commands that didn't arrive
2831             # via direct user input. It allows us to 'redo PIPE' to
2832             # re-execute command processing without reading a new command.
2833           PIPE: {
2834                 _DB__trim_command_and_return_first_component($obj);
2835
2836 =head3 COMMAND ALIASES
2837
2838 The debugger can create aliases for commands (these are stored in the
2839 C<%alias> hash). Before a command is executed, the command loop looks it up
2840 in the alias hash and substitutes the contents of the alias for the command,
2841 completely replacing it.
2842
2843 =cut
2844
2845                 # See if there's an alias for the command, and set it up if so.
2846                 if ( $alias{$cmd_verb} ) {
2847
2848                     # Squelch signal handling; we want to keep control here
2849                     # if something goes loco during the alias eval.
2850                     local $SIG{__DIE__};
2851                     local $SIG{__WARN__};
2852
2853                     # This is a command, so we eval it in the DEBUGGER's
2854                     # scope! Otherwise, we can't see the special debugger
2855                     # variables, or get to the debugger's subs. (Well, we
2856                     # _could_, but why make it even more complicated?)
2857                     eval "\$cmd =~ $alias{$cmd_verb}";
2858                     if ($@) {
2859                         local $\ = '';
2860                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2861                         next CMD;
2862                     }
2863                     _DB__trim_command_and_return_first_component($obj);
2864                 } ## end if ($alias{$cmd_verb})
2865
2866 =head3 MAIN-LINE COMMANDS
2867
2868 All of these commands work up to and after the program being debugged has
2869 terminated.
2870
2871 =head4 C<q> - quit
2872
2873 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2874 try to execute further, cleaning any restart-related stuff out of the
2875 environment, and executing with the last value of C<$?>.
2876
2877 =cut
2878
2879                 # All of these commands were remapped in perl 5.8.0;
2880                 # we send them off to the secondary dispatcher (see below).
2881                 $obj->_handle_special_char_cmd_wrapper_commands;
2882                 _DB__trim_command_and_return_first_component($obj);
2883
2884                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2885                     my $type = $cmd_rec->{t};
2886                     my $val = $cmd_rec->{v};
2887                     if ($type eq 'm') {
2888                         $obj->$val();
2889                     }
2890                     elsif ($type eq 's') {
2891                         $val->($obj);
2892                     }
2893                 }
2894
2895 =head4 C<t> - trace [n]
2896
2897 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2898 If level is specified, set C<$trace_to_depth>.
2899
2900 =head4 C<S> - list subroutines matching/not matching a pattern
2901
2902 Walks through C<%sub>, checking to see whether or not to print the name.
2903
2904 =head4 C<X> - list variables in current package
2905
2906 Since the C<V> command actually processes this, just change this to the
2907 appropriate C<V> command and fall through.
2908
2909 =head4 C<V> - list variables
2910
2911 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2912
2913 =head4 C<x> - evaluate and print an expression
2914
2915 Hands the expression off to C<DB::eval>, setting it up to print the value
2916 via C<dumpvar.pl> instead of just printing it directly.
2917
2918 =head4 C<m> - print methods
2919
2920 Just uses C<DB::methods> to determine what methods are available.
2921
2922 =head4 C<f> - switch files
2923
2924 Switch to a different filename.
2925
2926 =head4 C<.> - return to last-executed line.
2927
2928 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2929 and then we look up the line in the magical C<%dbline> hash.
2930
2931 =head4 C<-> - back one window
2932
2933 We change C<$start> to be one window back; if we go back past the first line,
2934 we set it to be the first line. We ser C<$incr> to put us back at the
2935 currently-executing line, and then put a C<l $start +> (list one window from
2936 C<$start>) in C<$cmd> to be executed later.
2937
2938 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2939
2940 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2941 problems, most notably that the default case of several commands destroying
2942 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2943 retain the old commands for those who were used to using them or who preferred
2944 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2945 deal with them instead of processing them in-line.
2946
2947 =head4 C<y> - List lexicals in higher scope
2948
2949 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2950 above the current one and then displays then using C<dumpvar.pl>.
2951
2952 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2953
2954 All of the commands below this point don't work after the program being
2955 debugged has ended. All of them check to see if the program has ended; this
2956 allows the commands to be relocated without worrying about a 'line of
2957 demarcation' above which commands can be entered anytime, and below which
2958 they can't.
2959
2960 =head4 C<n> - single step, but don't trace down into subs
2961
2962 Done by setting C<$single> to 2, which forces subs to execute straight through
2963 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2964 so a null command knows what to re-execute.
2965
2966 =head4 C<s> - single-step, entering subs
2967
2968 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2969 subs. Also saves C<s> as C<$lastcmd>.
2970
2971 =head4 C<c> - run continuously, setting an optional breakpoint
2972
2973 Most of the code for this command is taken up with locating the optional
2974 breakpoint, which is either a subroutine name or a line number. We set
2975 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2976 in this and all call levels above this one.
2977
2978 =head4 C<r> - return from a subroutine
2979
2980 For C<r> to work properly, the debugger has to stop execution again
2981 immediately after the return is executed. This is done by forcing
2982 single-stepping to be on in the call level above the current one. If
2983 we are printing return values when a C<r> is executed, set C<$doret>
2984 appropriately, and force us out of the command loop.
2985
2986 =head4 C<T> - stack trace
2987
2988 Just calls C<DB::print_trace>.
2989
2990 =head4 C<w> - List window around current line.
2991
2992 Just calls C<DB::cmd_w>.
2993
2994 =head4 C<W> - watch-expression processing.
2995
2996 Just calls C<DB::cmd_W>.
2997
2998 =head4 C</> - search forward for a string in the source
2999
3000 We take the argument and treat it as a pattern. If it turns out to be a
3001 bad one, we return the error we got from trying to C<eval> it and exit.
3002 If not, we create some code to do the search and C<eval> it so it can't
3003 mess us up.
3004
3005 =cut
3006
3007                 _DB__handle_forward_slash_command($obj);
3008
3009 =head4 C<?> - search backward for a string in the source
3010
3011 Same as for C</>, except the loop runs backwards.
3012
3013 =cut
3014
3015                 _DB__handle_question_mark_command($obj);
3016
3017 =head4 C<$rc> - Recall command
3018
3019 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3020 that the terminal supports history). It finds the command required, puts it
3021 into C<$cmd>, and redoes the loop to execute it.
3022
3023 =cut
3024
3025                 # $rc - recall command.
3026                 $obj->_handle_rc_recall_command;
3027
3028 =head4 C<$sh$sh> - C<system()> command
3029
3030 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
3031 C<STDOUT> from getting messed up.
3032
3033 =cut
3034
3035                 $obj->_handle_sh_command;
3036
3037 =head4 C<$rc I<pattern> $rc> - Search command history
3038
3039 Another command to manipulate C<@hist>: this one searches it with a pattern.
3040 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3041
3042 =cut
3043
3044                 $obj->_handle_rc_search_history_command;
3045
3046 =head4 C<$sh> - Invoke a shell
3047
3048 Uses C<_db_system()> to invoke a shell.
3049
3050 =cut
3051
3052 =head4 C<$sh I<command>> - Force execution of a command in a shell
3053
3054 Like the above, but the command is passed to the shell. Again, we use
3055 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
3056
3057 =head4 C<H> - display commands in history
3058
3059 Prints the contents of C<@hist> (if any).
3060
3061 =head4 C<man, doc, perldoc> - look up documentation
3062
3063 Just calls C<runman()> to print the appropriate document.
3064
3065 =cut
3066
3067                 $obj->_handle_doc_command;
3068
3069 =head4 C<p> - print
3070
3071 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3072 the bottom of the loop.
3073
3074 =head4 C<=> - define command alias
3075
3076 Manipulates C<%alias> to add or list command aliases.
3077
3078 =head4 C<source> - read commands from a file.
3079
3080 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3081 pick it up.
3082
3083 =head4 C<enable> C<disable> - enable or disable breakpoints
3084
3085 This enables or disables breakpoints.
3086
3087 =head4 C<save> - send current history to a file
3088
3089 Takes the complete history, (not the shrunken version you see with C<H>),
3090 and saves it to the given filename, so it can be replayed using C<source>.
3091
3092 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3093
3094 =head4 C<R> - restart
3095
3096 Restart the debugger session.
3097
3098 =head4 C<rerun> - rerun the current session
3099
3100 Return to any given position in the B<true>-history list
3101
3102 =head4 C<|, ||> - pipe output through the pager.
3103
3104 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3105 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3106 pipe to the pager (restoring the output filehandles if this fails). If this
3107 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3108 set C<$signal>, sending us back into the debugger.
3109
3110 We then trim off the pipe symbols and C<redo> the command loop at the
3111 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3112 reading another.
3113
3114 =cut
3115
3116                 # || - run command in the pager, with output to DB::OUT.
3117                 _DB__handle_run_command_in_pager_command($obj);
3118
3119 =head3 END OF COMMAND PARSING
3120
3121 Anything left in C<$cmd> at this point is a Perl expression that we want to
3122 evaluate. We'll always evaluate in the user's context, and fully qualify
3123 any variables we might want to address in the C<DB> package.
3124
3125 =cut
3126
3127             }    # PIPE:
3128
3129             # trace an expression
3130             $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3131
3132             # Make sure the flag that says "the debugger's running" is
3133             # still on, to make sure we get control again.
3134             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3135
3136             # Run *our* eval that executes in the caller's context.
3137             # The &-call is here to ascertain the mutability of @_.
3138             &DB::eval;
3139
3140             # Turn off the one-time-dump stuff now.
3141             if ($onetimeDump) {
3142                 $onetimeDump      = undef;
3143                 $onetimedumpDepth = undef;
3144             }
3145             elsif ( $term_pid == $$ ) {
3146                 eval { # May run under miniperl, when not available...
3147                     STDOUT->flush();
3148                     STDERR->flush();
3149                 };
3150
3151                 # XXX If this is the master pid, print a newline.
3152                 print {$OUT} "\n";
3153             }
3154         } ## end while (($term || &setterm...
3155
3156 =head3 POST-COMMAND PROCESSING
3157
3158 After each command, we check to see if the command output was piped anywhere.
3159 If so, we go through the necessary code to unhook the pipe and go back to
3160 our standard filehandles for input and output.
3161
3162 =cut
3163
3164         continue {    # CMD:
3165             _DB__at_end_of_every_command($obj);
3166         }    # CMD:
3167
3168 =head3 COMMAND LOOP TERMINATION
3169
3170 When commands have finished executing, we come here. If the user closed the
3171 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3172 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3173 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3174 The interpreter will then execute the next line and then return control to us
3175 again.
3176
3177 =cut
3178
3179         # No more commands? Quit.
3180         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3181
3182         # Evaluate post-prompt commands.
3183         foreach $evalarg (@$post) {
3184             # The &-call is here to ascertain the mutability of @_.
3185             &DB::eval;
3186         }
3187     }    # if ($single || $signal)
3188
3189     # Put the user's globals back where you found them.
3190     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3191     ();
3192 } ## end sub DB
3193
3194 # Because DB::Obj is used above,
3195 #
3196 #   my $obj = DB::Obj->new(
3197 #
3198 # The following package declaration must come before that,
3199 # or else runtime errors will occur with
3200 #
3201 #   PERLDB_OPTS="autotrace nonstop"
3202 #
3203 # ( rt#116771 )
3204 BEGIN {
3205
3206 package DB::Obj;
3207
3208 sub new {
3209     my $class = shift;
3210
3211     my $self = bless {}, $class;
3212
3213     $self->_init(@_);
3214
3215     return $self;
3216 }
3217
3218 sub _init {
3219     my ($self, $args) = @_;
3220
3221     %{$self} = (%$self, %$args);
3222
3223     return;
3224 }
3225
3226 {
3227     no strict 'refs';
3228     foreach my $slot_name (qw(
3229         after explicit_stop infix pat piped position prefix selected cmd_verb
3230         cmd_args
3231         )) {
3232         my $slot = $slot_name;
3233         *{$slot} = sub {
3234             my $self = shift;
3235
3236             if (@_) {
3237                 ${ $self->{$slot} } = shift;
3238             }
3239
3240             return ${ $self->{$slot} };
3241         };
3242
3243         *{"append_to_$slot"} = sub {
3244             my $self = shift;
3245             my $s = shift;
3246
3247             return $self->$slot($self->$slot . $s);
3248         };
3249     }
3250 }
3251
3252 sub _DB_on_init__initialize_globals
3253 {
3254     my $self = shift;
3255
3256     # Check for whether we should be running continuously or not.
3257     # _After_ the perl program is compiled, $single is set to 1:
3258     if ( $single and not $second_time++ ) {
3259
3260         # Options say run non-stop. Run until we get an interrupt.
3261         if ($runnonstop) {    # Disable until signal
3262                 # If there's any call stack in place, turn off single
3263                 # stepping into subs throughout the stack.
3264             for my $i (0 .. $stack_depth) {
3265                 $stack[ $i ] &= ~1;
3266             }
3267
3268             # And we are now no longer in single-step mode.
3269             $single = 0;
3270
3271             # If we simply returned at this point, we wouldn't get
3272             # the trace info. Fall on through.
3273             # return;
3274         } ## end if ($runnonstop)
3275
3276         elsif ($ImmediateStop) {
3277
3278             # We are supposed to stop here; XXX probably a break.
3279             $ImmediateStop = 0;    # We've processed it; turn it off
3280             $signal        = 1;    # Simulate an interrupt to force
3281                                    # us into the command loop
3282         }
3283     } ## end if ($single and not $second_time...
3284
3285     # If we're in single-step mode, or an interrupt (real or fake)
3286     # has occurred, turn off non-stop mode.
3287     $runnonstop = 0 if $single or $signal;
3288
3289     return;
3290 }
3291
3292 sub _my_print_lineinfo
3293 {
3294     my ($self, $i, $incr_pos) = @_;
3295
3296     if ($frame) {
3297         # Print it indented if tracing is on.
3298         DB::print_lineinfo( ' ' x $stack_depth,
3299             "$i:\t$DB::dbline[$i]" . $self->after );
3300     }
3301     else {
3302         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3303     }
3304 }
3305
3306 sub _curr_line {
3307     return $DB::dbline[$line];
3308 }
3309
3310 sub _is_full {
3311     my ($self, $letter) = @_;
3312
3313     return ($DB::cmd eq $letter);
3314 }
3315
3316 sub _DB__grab_control
3317 {
3318     my $self = shift;
3319
3320     # Yes, grab control.
3321     if ($slave_editor) {
3322
3323         # Tell the editor to update its position.
3324         $self->position("\032\032${DB::filename}:$line:0\n");
3325         DB::print_lineinfo($self->position());
3326     }
3327
3328 =pod
3329
3330 Special check: if we're in package C<DB::fake>, we've gone through the
3331 C<END> block at least once. We set up everything so that we can continue
3332 to enter commands and have a valid context to be in.
3333
3334 =cut
3335
3336     elsif ( $DB::package eq 'DB::fake' ) {
3337
3338         # Fallen off the end already.
3339         if (!$DB::term) {
3340             DB::setterm();
3341         }
3342
3343         DB::print_help(<<EOP);
3344 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3345 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3346 B<h q>, B<h R> or B<h o> to get additional info.
3347 EOP
3348
3349         # Set the DB::eval context appropriately.
3350         # At program termination disable any user actions.
3351         $DB::action = undef;
3352
3353         $DB::package     = 'main';
3354         $DB::usercontext = DB::_calc_usercontext($DB::package);
3355     } ## end elsif ($package eq 'DB::fake')
3356
3357 =pod
3358
3359 If the program hasn't finished executing, we scan forward to the
3360 next executable line, print that out, build the prompt from the file and line
3361 number information, and print that.
3362
3363 =cut
3364
3365     else {
3366
3367
3368         # Still somewhere in the midst of execution. Set up the
3369         #  debugger prompt.
3370         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3371                              # Perl 5 ones (sorry, we don't print Klingon
3372                              #module names)
3373
3374         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3375         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3376         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3377
3378         # Break up the prompt if it's really long.
3379         if ( length($self->prefix()) > 30 ) {
3380             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3381             $self->prefix("");
3382             $self->infix(":\t");
3383         }
3384         else {
3385             $self->infix("):\t");
3386             $self->position(
3387                 $self->prefix . $line. $self->infix
3388                 . $self->_curr_line . $self->after
3389             );
3390         }
3391
3392         # Print current line info, indenting if necessary.
3393         $self->_my_print_lineinfo($line, $self->position);
3394
3395         my $i;
3396         my $line_i = sub { return $DB::dbline[$i]; };
3397
3398         # Scan forward, stopping at either the end or the next
3399         # unbreakable line.
3400         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3401         {    #{ vi
3402
3403             # Drop out on null statements, block closers, and comments.
3404             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3405
3406             # Drop out if the user interrupted us.
3407             last if $signal;
3408
3409             # Append a newline if the line doesn't have one. Can happen
3410             # in eval'ed text, for instance.
3411             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3412
3413             # Next executable line.
3414             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3415                 . $self->after;
3416             $self->append_to_position($incr_pos);
3417             $self->_my_print_lineinfo($i, $incr_pos);
3418         } ## end for ($i = $line + 1 ; $i...
3419     } ## end else [ if ($slave_editor)
3420
3421     return;
3422 }
3423
3424 sub _handle_t_command {
3425     my $self = shift;
3426
3427     my $levels = $self->cmd_args();
3428
3429     if ((!length($levels)) or ($levels !~ /\D/)) {
3430         $trace ^= 1;
3431         local $\ = '';
3432         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3433         print {$OUT} "Trace = "
3434         . ( ( $trace & 1 )
3435             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3436             : "off" ) . "\n";
3437         next CMD;
3438     }
3439
3440     return;
3441 }
3442
3443
3444 sub _handle_S_command {
3445     my $self = shift;
3446
3447     if (my ($print_all_subs, $should_reverse, $Spatt)
3448         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3449         # $Spatt is the pattern (if any) to use.
3450         # Reverse scan?
3451         my $Srev     = defined $should_reverse;
3452         # No args - print all subs.
3453         my $Snocheck = !defined $print_all_subs;
3454
3455         # Need to make these sane here.
3456         local $\ = '';
3457         local $, = '';
3458
3459         # Search through the debugger's magical hash of subs.
3460         # If $nocheck is true, just print the sub name.
3461         # Otherwise, check it against the pattern. We then use
3462         # the XOR trick to reverse the condition as required.
3463         foreach $subname ( sort( keys %sub ) ) {
3464             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3465                 print $OUT $subname, "\n";
3466             }
3467         }
3468         next CMD;
3469     }
3470
3471     return;
3472 }
3473
3474 sub _handle_V_command_and_X_command {
3475     my $self = shift;
3476
3477     $DB::cmd =~ s/^X\b/V $DB::package/;
3478
3479     # Bare V commands get the currently-being-debugged package
3480     # added.
3481     if ($self->_is_full('V')) {
3482         $DB::cmd = "V $DB::package";
3483     }
3484
3485     # V - show variables in package.
3486     if (my ($new_packname, $new_vars_str) =
3487         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3488
3489         # Save the currently selected filehandle and
3490         # force output to debugger's filehandle (dumpvar
3491         # just does "print" for output).
3492         my $savout = select($OUT);
3493
3494         # Grab package name and variables to dump.
3495         $packname = $new_packname;
3496         my @vars     = split( ' ', $new_vars_str );
3497
3498         # If main::dumpvar isn't here, get it.
3499         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3500         if ( defined &main::dumpvar ) {
3501
3502             # We got it. Turn off subroutine entry/exit messages
3503             # for the moment, along with return values.
3504             local $frame = 0;
3505             local $doret = -2;
3506
3507             # must detect sigpipe failures  - not catching
3508             # then will cause the debugger to die.
3509             eval {
3510                 main::dumpvar(
3511                     $packname,
3512                     defined $option{dumpDepth}
3513                     ? $option{dumpDepth}
3514                     : -1,    # assume -1 unless specified
3515                     @vars
3516                 );
3517             };
3518
3519             # The die doesn't need to include the $@, because
3520             # it will automatically get propagated for us.
3521             if ($@) {
3522                 die unless $@ =~ /dumpvar print failed/;
3523             }
3524         } ## end if (defined &main::dumpvar)
3525         else {
3526
3527             # Couldn't load dumpvar.
3528             print $OUT "dumpvar.pl not available.\n";
3529         }
3530
3531         # Restore the output filehandle, and go round again.
3532         select($savout);
3533         next CMD;
3534     }
3535
3536     return;
3537 }
3538
3539 sub _handle_dash_command {
3540     my $self = shift;
3541
3542     if ($self->_is_full('-')) {
3543
3544         # back up by a window; go to 1 if back too far.
3545         $start -= $incr + $window + 1;
3546         $start = 1 if $start <= 0;
3547         $incr  = $window - 1;
3548
3549         # Generate and execute a "l +" command (handled below).
3550         $DB::cmd = 'l ' . ($start) . '+';
3551         redo CMD;
3552     }
3553     return;
3554 }
3555
3556 sub _n_or_s_commands_generic {
3557     my ($self, $new_val) = @_;
3558     # n - next
3559     next CMD if DB::_DB__is_finished();
3560
3561     # Single step, but don't enter subs.
3562     $single = $new_val;
3563
3564     # Save for empty command (repeat last).
3565     $laststep = $DB::cmd;
3566     last CMD;
3567 }
3568
3569 sub _n_or_s {
3570     my ($self, $letter, $new_val) = @_;
3571
3572     if ($self->_is_full($letter)) {
3573         $self->_n_or_s_commands_generic($new_val);
3574     }
3575     else {
3576         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3577     }
3578
3579     return;
3580 }
3581
3582 sub _handle_n_command {
3583     my $self = shift;
3584
3585     return $self->_n_or_s('n', 2);
3586 }
3587
3588 sub _handle_s_command {
3589     my $self = shift;
3590
3591     return $self->_n_or_s('s', 1);
3592 }
3593
3594 sub _handle_r_command {
3595     my $self = shift;
3596
3597     # r - return from the current subroutine.
3598     if ($self->_is_full('r')) {
3599
3600         # Can't do anything if the program's over.
3601         next CMD if DB::_DB__is_finished();
3602
3603         # Turn on stack trace.
3604         $stack[$stack_depth] |= 1;
3605
3606         # Print return value unless the stack is empty.
3607         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3608         last CMD;
3609     }
3610
3611     return;
3612 }
3613
3614 sub _handle_T_command {
3615     my $self = shift;
3616
3617     if ($self->_is_full('T')) {
3618         DB::print_trace( $OUT, 1 );    # skip DB
3619         next CMD;
3620     }
3621
3622     return;
3623 }
3624
3625 sub _handle_w_command {
3626     my $self = shift;
3627
3628     DB::cmd_w( 'w', $self->cmd_args() );
3629     next CMD;
3630
3631     return;
3632 }
3633
3634 sub _handle_W_command {
3635     my $self = shift;
3636
3637     if (my $arg = $self->cmd_args) {
3638         DB::cmd_W( 'W', $arg );
3639         next CMD;
3640     }
3641
3642     return;
3643 }
3644
3645 sub _handle_rc_recall_command {
3646     my $self = shift;
3647
3648     # $rc - recall command.
3649     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3650
3651         # No arguments, take one thing off history.
3652         pop(@hist) if length($DB::cmd) > 1;
3653
3654         # Relative (- found)?
3655         #  Y - index back from most recent (by 1 if bare minus)
3656         #  N - go to that particular command slot or the last
3657         #      thing if nothing following.
3658
3659         $self->cmd_verb(
3660             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3661         );
3662
3663         # Pick out the command desired.
3664         $DB::cmd = $hist[$self->cmd_verb];
3665
3666         # Print the command to be executed and restart the loop
3667         # with that command in the buffer.
3668         print {$OUT} $DB::cmd, "\n";
3669         redo CMD;
3670     }
3671
3672     return;
3673 }
3674
3675 sub _handle_rc_search_history_command {
3676     my $self = shift;
3677
3678     # $rc pattern $rc - find a command in the history.
3679     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3680
3681         # Create the pattern to use.
3682         my $pat = "^$arg";
3683         $self->pat($pat);
3684
3685         # Toss off last entry if length is >1 (and it always is).
3686         pop(@hist) if length($DB::cmd) > 1;
3687
3688         my $i;
3689
3690         # Look backward through the history.
3691         SEARCH_HIST:
3692         for ( $i = $#hist ; $i ; --$i ) {
3693             # Stop if we find it.
3694             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3695         }
3696
3697         if ( !$i ) {
3698
3699             # Never found it.
3700             print $OUT "No such command!\n\n";
3701             next CMD;
3702         }
3703
3704         # Found it. Put it in the buffer, print it, and process it.
3705         $DB::cmd = $hist[$i];
3706         print $OUT $DB::cmd, "\n";
3707         redo CMD;
3708     }
3709
3710     return;
3711 }
3712
3713 sub _handle_H_command {
3714     my $self = shift;
3715
3716     if ($self->cmd_args =~ m#\A\*#) {
3717         @hist = @truehist = ();
3718         print $OUT "History cleansed\n";
3719         next CMD;
3720     }
3721
3722     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3723
3724         # Anything other than negative numbers is ignored by
3725         # the (incorrect) pattern, so this test does nothing.
3726         $end = $num ? ( $#hist - $num ) : 0;
3727
3728         # Set to the minimum if less than zero.
3729         $hist = 0 if $hist < 0;
3730
3731         # Start at the end of the array.
3732         # Stay in while we're still above the ending value.
3733         # Tick back by one each time around the loop.
3734         my $i;
3735
3736         for ( $i = $#hist ; $i > $end ; $i-- ) {
3737
3738             # Print the command  unless it has no arguments.
3739             print $OUT "$i: ", $hist[$i], "\n"
3740             unless $hist[$i] =~ /^.?$/;
3741         }
3742
3743         next CMD;
3744     }
3745
3746     return;
3747 }
3748
3749 sub _handle_doc_command {
3750     my $self = shift;
3751
3752     # man, perldoc, doc - show manual pages.
3753     if (my ($man_page)
3754         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3755         DB::runman($man_page);
3756         next CMD;
3757     }
3758
3759     return;
3760 }
3761
3762 sub _handle_p_command {
3763     my $self = shift;
3764
3765     my $print_cmd = 'print {$DB::OUT} ';
3766     # p - print (no args): print $_.
3767     if ($self->_is_full('p')) {
3768         $DB::cmd = $print_cmd . '$_';
3769     }
3770     else {
3771         # p - print the given expression.
3772         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3773     }
3774
3775     return;
3776 }
3777
3778 sub _handle_equal_sign_command {
3779     my $self = shift;
3780
3781     if ($DB::cmd =~ s/\A=\s*//) {
3782         my @keys;
3783         if ( length $DB::cmd == 0 ) {
3784
3785             # No args, get current aliases.
3786             @keys = sort keys %alias;
3787         }
3788         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3789
3790             # Creating a new alias. $k is alias name, $v is
3791             # alias value.
3792
3793             # can't use $_ or kill //g state
3794             for my $x ( $k, $v ) {
3795
3796                 # Escape "alarm" characters.
3797                 $x =~ s/\a/\\a/g;
3798             }
3799
3800             # Substitute key for value, using alarm chars
3801             # as separators (which is why we escaped them in
3802             # the command).
3803             $alias{$k} = "s\a$k\a$v\a";
3804
3805             # Turn off standard warn and die behavior.
3806             local $SIG{__DIE__};
3807             local $SIG{__WARN__};
3808
3809             # Is it valid Perl?
3810             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3811
3812                 # Nope. Bad alias. Say so and get out.
3813                 print $OUT "Can't alias $k to $v: $@\n";
3814                 delete $alias{$k};
3815                 next CMD;
3816             }
3817
3818             # We'll only list the new one.
3819             @keys = ($k);
3820         } ## end elsif (my ($k, $v) = ($DB::cmd...
3821
3822         # The argument is the alias to list.
3823         else {
3824             @keys = ($DB::cmd);
3825         }
3826
3827         # List aliases.
3828         for my $k (@keys) {
3829
3830             # Messy metaquoting: Trim the substitution code off.
3831             # We use control-G as the delimiter because it's not
3832             # likely to appear in the alias.
3833             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3834
3835                 # Print the alias.
3836                 print $OUT "$k\t= $1\n";
3837             }
3838             elsif ( defined $alias{$k} ) {
3839
3840                 # Couldn't trim it off; just print the alias code.
3841                 print $OUT "$k\t$alias{$k}\n";
3842             }
3843             else {
3844
3845                 # No such, dude.
3846                 print "No alias for $k\n";
3847             }
3848         } ## end for my $k (@keys)
3849         next CMD;
3850     }
3851
3852     return;
3853 }
3854
3855 sub _handle_source_command {
3856     my $self = shift;
3857
3858     # source - read commands from a file (or pipe!) and execute.
3859     if (my $sourced_fn = $self->cmd_args) {
3860         if ( open my $fh, $sourced_fn ) {
3861
3862             # Opened OK; stick it in the list of file handles.
3863             push @cmdfhs, $fh;
3864         }
3865         else {
3866
3867             # Couldn't open it.
3868             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3869         }
3870         next CMD;
3871     }
3872
3873     return;
3874 }
3875
3876 sub _handle_enable_disable_commands {
3877     my $self = shift;
3878
3879     my $which_cmd = $self->cmd_verb;
3880     my $position = $self->cmd_args;
3881
3882     if ($position !~ /\s/) {
3883         my ($fn, $line_num);
3884         if ($position =~ m{\A\d+\z})
3885         {
3886             $fn = $DB::filename;
3887             $line_num = $position;
3888         }
3889         elsif (my ($new_fn, $new_line_num)
3890             = $position =~ m{\A(.*):(\d+)\z}) {
3891             ($fn, $line_num) = ($new_fn, $new_line_num);
3892         }
3893         else
3894         {
3895             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3896         }
3897
3898         if (defined($fn)) {
3899             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3900                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3901                     ($which_cmd eq 'enable' ? 1 : '')
3902                 );
3903             }
3904             else {
3905                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3906             }
3907         }
3908
3909         next CMD;
3910     }
3911
3912     return;
3913 }
3914
3915 sub _handle_save_command {
3916     my $self = shift;
3917
3918     if (my $new_fn = $self->cmd_args) {
3919         my $filename = $new_fn || '.perl5dbrc';    # default?
3920         if ( open my $fh, '>', $filename ) {
3921
3922             # chomp to remove extraneous newlines from source'd files
3923             chomp( my @truelist =
3924                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3925                 @truehist );
3926             print {$fh} join( "\n", @truelist );
3927             print "commands saved in $filename\n";
3928         }
3929         else {
3930             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3931         }
3932         next CMD;
3933     }
3934
3935     return;
3936 }
3937
3938 sub _n_or_s_and_arg_commands_generic {
3939     my ($self, $letter, $new_val) = @_;
3940
3941     # s - single-step. Remember the last command was 's'.
3942     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3943         $laststep = $letter;
3944     }
3945
3946     return;
3947 }
3948
3949 sub _handle_sh_command {
3950     my $self = shift;
3951
3952     # $sh$sh - run a shell command (if it's all ASCII).
3953     # Can't run shell commands with Unicode in the debugger, hmm.
3954     my $my_cmd = $DB::cmd;
3955     if ($my_cmd =~ m#\A$sh#gms) {
3956
3957         if ($my_cmd =~ m#\G\z#cgms) {
3958             # Run the user's shell. If none defined, run Bourne.
3959             # We resume execution when the shell terminates.
3960             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3961             next CMD;
3962         }
3963         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3964             # System it.
3965             DB::_db_system($1);
3966             next CMD;
3967         }
3968         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3969             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3970             next CMD;
3971         }
3972     }
3973 }
3974
3975 sub _handle_x_command {
3976     my $self = shift;
3977
3978     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3979         $onetimeDump = 'dump';    # main::dumpvar shows the output
3980
3981         # handle special  "x 3 blah" syntax XXX propagate
3982         # doc back to special variables.
3983         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3984             $onetimedumpDepth = $1;
3985         }
3986     }
3987
3988     return;
3989 }
3990
3991 sub _handle_q_command {
3992     my $self = shift;
3993
3994     if ($self->_is_full('q')) {
3995         $fall_off_end = 1;
3996         DB::clean_ENV();
3997         exit $?;
3998     }
3999
4000     return;
4001 }
4002
4003 sub _handle_cmd_wrapper_commands {
4004     my $self = shift;
4005
4006     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
4007     next CMD;
4008 }
4009
4010 sub _handle_special_char_cmd_wrapper_commands {
4011     my $self = shift;
4012
4013     # All of these commands were remapped in perl 5.8.0;
4014     # we send them off to the secondary dispatcher (see below).
4015     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
4016         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
4017         next CMD;
4018     }
4019
4020     return;
4021 }
4022
4023 } ## end DB::Obj
4024
4025 package DB;
4026
4027 # The following code may be executed now:
4028 # BEGIN {warn 4}
4029
4030 =head2 sub
4031
4032 C<sub> is called whenever a subroutine call happens in the program being
4033 debugged. The variable C<$DB::sub> contains the name of the subroutine
4034 being called.
4035
4036 The core function of this subroutine is to actually call the sub in the proper
4037 context, capturing its output. This of course causes C<DB::DB> to get called
4038 again, repeating until the subroutine ends and returns control to C<DB::sub>
4039 again. Once control returns, C<DB::sub> figures out whether or not to dump the
4040 return value, and returns its captured copy of the return value as its own
4041 return value. The value then feeds back into the program being debugged as if
4042 C<DB::sub> hadn't been there at all.
4043
4044 C<sub> does all the work of printing the subroutine entry and exit messages
4045 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
4046 and also prints the return value if needed (for the C<r> command and if
4047 the 16 bit is set in C<$frame>).
4048
4049 It also tracks the subroutine call depth by saving the current setting of
4050 C<$single> in the C<@stack> package global; if this exceeds the value in
4051 C<$deep>, C<sub> automatically turns on printing of the current depth by
4052 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
4053 of stop/don't stop on entry to subs set as it currently is set.
4054
4055 =head3 C<caller()> support
4056
4057 If C<caller()> is called from the package C<DB>, it provides some
4058 additional data, in the following order:
4059
4060 =over 4
4061
4062 =item * C<$package>
4063
4064 The package name the sub was in
4065
4066 =item * C<$filename>
4067
4068 The filename it was defined in
4069
4070 =item * C<$line>
4071
4072 The line number it was defined on
4073
4074 =item * C<$subroutine>
4075
4076 The subroutine name; C<(eval)> if an C<eval>().
4077
4078 =item * C<$hasargs>
4079
4080 1 if it has arguments, 0 if not
4081
4082 =item * C<$wantarray>
4083
4084 1 if array context, 0 if scalar context
4085
4086 =item * C<$evaltext>
4087
4088 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4089
4090 =item * C<$is_require>
4091
4092 frame was created by a C<use> or C<require> statement
4093
4094 =item * C<$hints>
4095
4096 pragma information; subject to change between versions
4097
4098 =item * C<$bitmask>
4099
4100 pragma information; subject to change between versions
4101
4102 =item * C<@DB::args>
4103
4104 arguments with which the subroutine was invoked
4105
4106 =back
4107
4108 =cut
4109
4110 use vars qw($deep);
4111
4112 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4113 # happy. -- Shlomi Fish
4114
4115 sub _indent_print_line_info {
4116     my ($offset, $str) = @_;
4117
4118     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4119
4120     return;
4121 }
4122
4123 sub _print_frame_message {
4124     my ($al) = @_;
4125
4126     if ($frame) {
4127         if ($frame & 4) {   # Extended frame entry message
4128             _indent_print_line_info(-1, "in  ");
4129
4130             # Why -1? But it works! :-(
4131             # Because print_trace will call add 1 to it and then call
4132             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4133             # in dump_trace.
4134             #
4135             # Now it's 0 because we extracted a function.
4136             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4137         }
4138         else {
4139             _indent_print_line_info(-1, "entering $sub$al\n" );
4140         }
4141     }
4142
4143     return;
4144 }
4145
4146 sub DB::sub {
4147     # lock ourselves under threads
4148     lock($DBGR);
4149
4150     # Whether or not the autoloader was running, a scalar to put the
4151     # sub's return value in (if needed), and an array to put the sub's
4152     # return value in (if needed).
4153     my ( $al, $ret, @ret ) = "";
4154     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4155         print "creating new thread\n";
4156     }
4157
4158     # If the last ten characters are '::AUTOLOAD', note we've traced
4159     # into AUTOLOAD for $sub.
4160     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4161         no strict 'refs';
4162         $al = " for $$sub" if defined $$sub;
4163     }
4164
4165     # We stack the stack pointer and then increment it to protect us
4166     # from a situation that might unwind a whole bunch of call frames
4167     # at once. Localizing the stack pointer means that it will automatically
4168     # unwind the same amount when multiple stack frames are unwound.
4169     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4170
4171     # Expand @stack.
4172     $#stack = $stack_depth;
4173
4174     # Save current single-step setting.
4175     $stack[-1] = $single;
4176
4177     # Turn off all flags except single-stepping.
4178     $single &= 1;
4179
4180     # If we've gotten really deeply recursed, turn on the flag that will
4181     # make us stop with the 'deep recursion' message.
4182     $single |= 4 if $stack_depth == $deep;
4183
4184     # If frame messages are on ...
4185
4186     _print_frame_message($al);
4187     # standard frame entry message
4188
4189     my $print_exit_msg = sub {
4190         # Check for exit trace messages...
4191         if ($frame & 2)
4192         {
4193             if ($frame & 4)    # Extended exit message
4194             {
4195                 _indent_print_line_info(0, "out ");
4196                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4197             }
4198             else
4199             {
4200                 _indent_print_line_info(0, "exited $sub$al\n" );
4201             }
4202         }
4203         return;
4204     };
4205
4206     # Determine the sub's return type, and capture appropriately.
4207     if (wantarray) {
4208
4209         # Called in array context. call sub and capture output.
4210         # DB::DB will recursively get control again if appropriate; we'll come
4211         # back here when the sub is finished.
4212         {
4213             no strict 'refs';
4214             @ret = &$sub;
4215         }
4216
4217         # Pop the single-step value back off the stack.
4218         $single |= $stack[ $stack_depth-- ];
4219
4220         $print_exit_msg->();
4221
4222         # Print the return info if we need to.
4223         if ( $doret eq $stack_depth or $frame & 16 ) {
4224
4225             # Turn off output record separator.
4226             local $\ = '';
4227             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4228
4229             # Indent if we're printing because of $frame tracing.
4230             if ($frame & 16)
4231             {
4232                 print {$fh} ' ' x $stack_depth;
4233             }
4234
4235             # Print the return value.
4236             print {$fh} "list context return from $sub:\n";
4237             dumpit( $fh, \@ret );
4238
4239             # And don't print it again.
4240             $doret = -2;
4241         } ## end if ($doret eq $stack_depth...
4242             # And we have to return the return value now.
4243         @ret;
4244     } ## end if (wantarray)
4245
4246     # Scalar context.
4247     else {
4248         if ( defined wantarray ) {
4249             no strict 'refs';
4250             # Save the value if it's wanted at all.
4251             $ret = &$sub;
4252         }
4253         else {
4254             no strict 'refs';
4255             # Void return, explicitly.
4256             &$sub;
4257             undef $ret;
4258         }
4259
4260         # Pop the single-step value off the stack.
4261         $single |= $stack[ $stack_depth-- ];
4262
4263         # If we're doing exit messages...
4264         $print_exit_msg->();
4265
4266         # If we are supposed to show the return value... same as before.
4267         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4268             local $\ = '';
4269             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4270             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4271             print $fh (
4272                 defined wantarray
4273                 ? "scalar context return from $sub: "
4274                 : "void context return from $sub\n"
4275             );
4276             dumpit( $fh, $ret ) if defined wantarray;
4277             $doret = -2;
4278         } ## end if ($doret eq $stack_depth...
4279
4280         # Return the appropriate scalar value.
4281         $ret;
4282     } ## end else [ if (wantarray)
4283 } ## end sub _sub
4284
4285 sub lsub : lvalue {
4286
4287     no strict 'refs';
4288
4289     # lock ourselves under threads
4290     lock($DBGR);
4291
4292     # Whether or not the autoloader was running, a scalar to put the
4293     # sub's return value in (if needed), and an array to put the sub's
4294     # return value in (if needed).
4295     my ( $al, $ret, @ret ) = "";
4296     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4297         print "creating new thread\n";
4298     }
4299
4300     # If the last ten characters are C'::AUTOLOAD', note we've traced
4301     # into AUTOLOAD for $sub.
4302     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4303         $al = " for $$sub";
4304     }
4305
4306     # We stack the stack pointer and then increment it to protect us
4307     # from a situation that might unwind a whole bunch of call frames
4308     # at once. Localizing the stack pointer means that it will automatically
4309     # unwind the same amount when multiple stack frames are unwound.
4310     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4311
4312     # Expand @stack.
4313     $#stack = $stack_depth;
4314
4315     # Save current single-step setting.
4316     $stack[-1] = $single;
4317
4318     # Turn off all flags except single-stepping.
4319     # Use local so the single-step value is popped back off the
4320     # stack for us.
4321     local $single = $single & 1;
4322
4323     # If we've gotten really deeply recursed, turn on the flag that will
4324     # make us stop with the 'deep recursion' message.
4325     $single |= 4 if $stack_depth == $deep;
4326
4327     # If frame messages are on ...
4328     _print_frame_message($al);
4329
4330     # call the original lvalue sub.
4331     &$sub;
4332 }
4333
4334 # Abstracting common code from multiple places elsewhere:
4335 sub depth_print_lineinfo {
4336     my $always_print = shift;
4337
4338     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4339 }
4340
4341 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4342
4343 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4344 Most of the changes were to systematize the command structure and to eliminate
4345 commands that threw away user input without checking.
4346
4347 The following sections describe the code added to make it easy to support
4348 multiple command sets with conflicting command names. This section is a start
4349 at unifying all command processing to make it simpler to develop commands.
4350
4351 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4352 number, and C<$dbline> (the current line) as arguments.
4353
4354 Support functions in this section which have multiple modes of failure C<die>
4355 on error; the rest simply return a false value.
4356
4357 The user-interface functions (all of the C<cmd_*> functions) just output
4358 error messages.
4359
4360 =head2 C<%set>
4361
4362 The C<%set> hash defines the mapping from command letter to subroutine
4363 name suffix.
4364
4365 C<%set> is a two-level hash, indexed by set name and then by command name.
4366 Note that trying to set the CommandSet to C<foobar> simply results in the
4367 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4368
4369 =cut
4370
4371 ### The API section
4372
4373 my %set = (    #
4374     'pre580' => {
4375         'a' => 'pre580_a',
4376         'A' => 'pre580_null',
4377         'b' => 'pre580_b',
4378         'B' => 'pre580_null',
4379         'd' => 'pre580_null',
4380         'D' => 'pre580_D',
4381         'h' => 'pre580_h',
4382         'M' => 'pre580_null',
4383         'O' => 'o',
4384         'o' => 'pre580_null',
4385         'v' => 'M',
4386         'w' => 'v',
4387         'W' => 'pre580_W',
4388     },
4389     'pre590' => {
4390         '<'  => 'pre590_prepost',
4391         '<<' => 'pre590_prepost',
4392         '>'  => 'pre590_prepost',
4393         '>>' => 'pre590_prepost',
4394         '{'  => 'pre590_prepost',
4395         '{{' => 'pre590_prepost',
4396     },
4397 );
4398
4399 my %breakpoints_data;
4400
4401 sub _has_breakpoint_data_ref {
4402     my ($filename, $line) = @_;
4403
4404     return (
4405         exists( $breakpoints_data{$filename} )
4406             and
4407         exists( $breakpoints_data{$filename}{$line} )
4408     );
4409 }
4410
4411 sub _get_breakpoint_data_ref {
4412     my ($filename, $line) = @_;
4413
4414     return ($breakpoints_data{$filename}{$line} ||= +{});
4415 }
4416
4417 sub _delete_breakpoint_data_ref {
4418     my ($filename, $line) = @_;
4419
4420     delete($breakpoints_data{$filename}{$line});
4421     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4422         delete($breakpoints_data{$filename});
4423     }
4424
4425     return;
4426 }
4427
4428 sub _set_breakpoint_enabled_status {
4429     my ($filename, $line, $status) = @_;
4430
4431     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4432         ($status ? 1 : '')
4433         ;
4434
4435     return;
4436 }
4437
4438 sub _enable_breakpoint_temp_enabled_status {
4439     my ($filename, $line) = @_;
4440
4441     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4442
4443     return;
4444 }
4445
4446 sub _cancel_breakpoint_temp_enabled_status {
4447     my ($filename, $line) = @_;
4448
4449     my $ref = _get_breakpoint_data_ref($filename, $line);
4450
4451     delete ($ref->{'temp_enabled'});
4452
4453     if (! %$ref) {
4454         _delete_breakpoint_data_ref($filename, $line);
4455     }
4456
4457     return;
4458 }
4459
4460 sub _is_breakpoint_enabled {
4461     my ($filename, $line) = @_;
4462
4463     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4464     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4465 }
4466
4467 =head2 C<cmd_wrapper()> (API)
4468
4469 C<cmd_wrapper()> allows the debugger to switch command sets
4470 depending on the value of the C<CommandSet> option.
4471
4472 It tries to look up the command in the C<%set> package-level I<lexical>
4473 (which means external entities can't fiddle with it) and create the name of
4474 the sub to call based on the value found in the hash (if it's there). I<All>
4475 of the commands to be handled in a set have to be added to C<%set>; if they
4476 aren't found, the 5.8.0 equivalent is called (if there is one).
4477
4478 This code uses symbolic references.
4479
4480 =cut
4481
4482 sub cmd_wrapper {
4483     my $cmd      = shift;
4484     my $line     = shift;
4485     my $dblineno = shift;
4486
4487     # Assemble the command subroutine's name by looking up the
4488     # command set and command name in %set. If we can't find it,
4489     # default to the older version of the command.
4490     my $call = 'cmd_'
4491       . ( $set{$CommandSet}{$cmd}
4492           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4493
4494     # Call the command subroutine, call it by name.
4495     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4496 } ## end sub cmd_wrapper
4497
4498 =head3 C<cmd_a> (command)
4499
4500 The C<a> command handles pre-execution actions. These are associated with a
4501 particular line, so they're stored in C<%dbline>. We default to the current
4502 line if none is specified.
4503
4504 =cut
4505
4506 sub cmd_a {
4507     my $cmd    = shift;
4508     my $line   = shift || '';    # [.|line] expr
4509     my $dbline = shift;
4510
4511     # If it's dot (here), or not all digits,  use the current line.
4512     $line =~ s/\A\./$dbline/;
4513
4514     # Should be a line number followed by an expression.
4515     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4516
4517         if (! length($lineno)) {
4518             $lineno = $dbline;
4519         }
4520
4521         # If we have an expression ...
4522         if ( length $expr ) {
4523
4524             # ... but the line isn't breakable, complain.
4525             if ( $dbline[$lineno] == 0 ) {
4526                 print $OUT
4527                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4528             }
4529             else {
4530
4531                 # It's executable. Record that the line has an action.
4532                 $had_breakpoints{$filename} |= 2;
4533
4534                 # Remove any action, temp breakpoint, etc.
4535                 $dbline{$lineno} =~ s/\0[^\0]*//;
4536
4537                 # Add the action to the line.
4538                 $dbline{$lineno} .= "\0" . action($expr);
4539
4540                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4541             }
4542         } ## end if (length $expr)
4543     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4544     else {
4545
4546         # Syntax wrong.
4547         print $OUT
4548           "Adding an action requires an optional lineno and an expression\n"
4549           ;    # hint
4550     }
4551 } ## end sub cmd_a
4552
4553 =head3 C<cmd_A> (command)
4554
4555 Delete actions. Similar to above, except the delete code is in a separate
4556 subroutine, C<delete_action>.
4557
4558 =cut
4559
4560 sub cmd_A {
4561     my $cmd    = shift;
4562     my $line   = shift || '';
4563     my $dbline = shift;
4564
4565     # Dot is this line.
4566     $line =~ s/^\./$dbline/;
4567
4568     # Call delete_action with a null param to delete them all.
4569     # The '1' forces the eval to be true. It'll be false only
4570     # if delete_action blows up for some reason, in which case
4571     # we print $@ and get out.
4572     if ( $line eq '*' ) {
4573         if (! eval { _delete_all_actions(); 1 }) {
4574             print {$OUT} $@;
4575             return;
4576         }
4577     }
4578
4579     # There's a real line  number. Pass it to delete_action.
4580     # Error trapping is as above.
4581     elsif ( $line =~ /^(\S.*)/ ) {
4582         if (! eval { delete_action($1); 1 }) {
4583             print {$OUT} $@;
4584             return;
4585         }
4586     }
4587
4588     # Swing and a miss. Bad syntax.
4589     else {
4590         print $OUT
4591           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4592     }
4593 } ## end sub cmd_A
4594
4595 =head3 C<delete_action> (API)
4596
4597 C<delete_action> accepts either a line number or C<undef>. If a line number
4598 is specified, we check for the line being executable (if it's not, it
4599 couldn't have had an  action). If it is, we just take the action off (this
4600 will get any kind of an action, including breakpoints).
4601
4602 =cut
4603
4604 sub _remove_action_from_dbline {
4605     my $i = shift;
4606
4607     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4608     delete $dbline{$i} if $dbline{$i} eq '';
4609
4610     return;
4611 }
4612
4613 sub _delete_all_actions {
4614     print {$OUT} "Deleting all actions...\n";
4615
4616     for my $file ( keys %had_breakpoints ) {
4617         local *dbline = $main::{ '_<' . $file };
4618         $max = $#dbline;
4619         my $was;
4620         for my $i (1 .. $max) {
4621             if ( defined $dbline{$i} ) {
4622                 _remove_action_from_dbline($i);
4623             }
4624         }
4625
4626         unless ( $had_breakpoints{$file} &= ~2 ) {
4627             delete $had_breakpoints{$file};
4628         }
4629     }
4630
4631     return;
4632 }
4633
4634 sub delete_action {
4635     my $i = shift;
4636
4637     if ( defined($i) ) {
4638         # Can there be one?
4639         die "Line $i has no action .\n" if $dbline[$i] == 0;
4640
4641         # Nuke whatever's there.
4642         _remove_action_from_dbline($i);
4643     }
4644     else {
4645         _delete_all_actions();
4646     }
4647 }
4648
4649 =head3 C<cmd_b> (command)
4650
4651 Set breakpoints. Since breakpoints can be set in so many places, in so many
4652 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4653 we try to parse the command type, and then shuttle it off to an appropriate
4654 subroutine to actually do the work of setting the breakpoint in the right
4655 place.
4656
4657 =cut
4658
4659 sub cmd_b {
4660     my $cmd    = shift;
4661     my $line   = shift;    # [.|line] [cond]
4662     my $dbline = shift;
4663
4664     my $default_cond = sub {
4665         my $cond = shift;
4666         return length($cond) ? $cond : '1';
4667     };
4668
4669     # Make . the current line number if it's there..
4670     $line =~ s/^\.(\s|\z)/$dbline$1/;
4671
4672     # No line number, no condition. Simple break on current line.
4673     if ( $line =~ /^\s*$/ ) {
4674         cmd_b_line( $dbline, 1 );
4675     }
4676
4677     # Break on load for a file.
4678     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4679         $file =~ s/\s+\z//;
4680         cmd_b_load($file);
4681     }
4682
4683     # b compile|postpone <some sub> [<condition>]
4684     # The interpreter actually traps this one for us; we just put the
4685     # necessary condition in the %postponed hash.
4686     elsif ( my ($action, $subname, $cond)
4687         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4688
4689         # De-Perl4-ify the name - ' separators to ::.
4690         $subname =~ s/'/::/g;
4691
4692         # Qualify it into the current package unless it's already qualified.
4693         $subname = "${package}::" . $subname unless $subname =~ /::/;
4694
4695         # Add main if it starts with ::.
4696         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4697
4698         # Save the break type for this sub.
4699         $postponed{$subname} = (($action eq 'postpone')
4700             ? ( "break +0 if " . $default_cond->($cond) )
4701             : "compile");
4702     } ## end elsif ($line =~ ...
4703     # b <filename>:<line> [<condition>]
4704     elsif (my ($filename, $line_num, $cond)
4705         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4706         cmd_b_filename_line(
4707             $filename,
4708             $line_num,
4709             (length($cond) ? $cond : '1'),
4710         );
4711     }
4712     # b <sub name> [<condition>]
4713     elsif ( my ($new_subname, $new_cond) =
4714         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4715
4716         #
4717         $subname = $new_subname;
4718         cmd_b_sub( $subname, $default_cond->($new_cond) );
4719     }
4720
4721     # b <line> [<condition>].
4722     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4723
4724         # Capture the line. If none, it's the current line.
4725         $line = $line_n || $dbline;
4726
4727         # Break on line.
4728         cmd_b_line( $line, $default_cond->($cond) );
4729     }
4730
4731     # Line didn't make sense.
4732     else {
4733         print "confused by line($line)?\n";
4734     }
4735
4736     return;
4737 } ## end sub cmd_b
4738
4739 =head3 C<break_on_load> (API)
4740
4741 We want to break when this file is loaded. Mark this file in the
4742 C<%break_on_load> hash, and note that it has a breakpoint in
4743 C<%had_breakpoints>.
4744
4745 =cut
4746
4747 sub break_on_load {
4748     my $file = shift;
4749     $break_on_load{$file} = 1;
4750     $had_breakpoints{$file} |= 1;
4751 }
4752
4753 =head3 C<report_break_on_load> (API)
4754
4755 Gives us an array of filenames that are set to break on load. Note that
4756 only files with break-on-load are in here, so simply showing the keys
4757 suffices.
4758
4759 =cut
4760
4761 sub report_break_on_load {
4762     sort keys %break_on_load;
4763 }
4764
4765 =head3 C<cmd_b_load> (command)
4766
4767 We take the file passed in and try to find it in C<%INC> (which maps modules
4768 to files they came from). We mark those files for break-on-load via
4769 C<break_on_load> and then report that it was done.
4770
4771 =cut
4772
4773 sub cmd_b_load {
4774     my $file = shift;
4775     my @files;
4776
4777     # This is a block because that way we can use a redo inside it
4778     # even without there being any looping structure at all outside it.
4779     {
4780
4781         # Save short name and full path if found.
4782         push @files, $file;
4783         push @files, $::INC{$file} if $::INC{$file};
4784
4785         # Tack on .pm and do it again unless there was a '.' in the name
4786         # already.
4787         $file .= '.pm', redo unless $file =~ /\./;
4788     }
4789
4790     # Do the real work here.
4791     break_on_load($_) for @files;
4792
4793     # All the files that have break-on-load breakpoints.
4794     @files = report_break_on_load;
4795
4796     # Normalize for the purposes of our printing this.
4797     local $\ = '';
4798     local $" = ' ';
4799     print $OUT "Will stop on load of '@files'.\n";
4800 } ## end sub cmd_b_load
4801
4802 =head3 C<$filename_error> (API package global)
4803
4804 Several of the functions we need to implement in the API need to work both
4805 on the current file and on other files. We don't want to duplicate code, so
4806 C<$filename_error> is used to contain the name of the file that's being
4807 worked on (if it's not the current one).
4808
4809 We can now build functions in pairs: the basic function works on the current
4810 file, and uses C<$filename_error> as part of its error message. Since this is
4811 initialized to C<"">, no filename will appear when we are working on the
4812 current file.
4813
4814 The second function is a wrapper which does the following:
4815
4816 =over 4
4817
4818 =item *
4819
4820 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4821
4822 =item *
4823
4824 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4825
4826 =item *
4827
4828 Calls the first function.
4829
4830 The first function works on the I<current> file (i.e., the one we changed to),
4831 and prints C<$filename_error> in the error message (the name of the other file)
4832 if it needs to. When the functions return, C<*dbline> is restored to point
4833 to the actual current file (the one we're executing in) and
4834 C<$filename_error> is restored to C<"">. This restores everything to
4835 the way it was before the second function was called at all.
4836
4837 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4838 details.
4839
4840 =back
4841
4842 =cut
4843
4844 use vars qw($filename_error);
4845 $filename_error = '';
4846
4847 =head3 breakable_line(from, to) (API)
4848
4849 The subroutine decides whether or not a line in the current file is breakable.
4850 It walks through C<@dbline> within the range of lines specified, looking for
4851 the first line that is breakable.
4852
4853 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4854 first line I<after> C<$to> that's breakable, if there is one.
4855
4856 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4857 first line I<before> C<$to> that's breakable, if there is one.
4858
4859 =cut
4860
4861 sub breakable_line {
4862
4863     my ( $from, $to ) = @_;
4864
4865     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4866     my $i = $from;
4867
4868     # If there are at least 2 arguments, we're trying to search a range.
4869     if ( @_ >= 2 ) {
4870
4871         # $delta is positive for a forward search, negative for a backward one.