This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
235177b63ae25daf64de6031627bb5ff08d3e1e9
[perl5.git] / pod / perldata.pod
1 =head1 NAME
2
3 perldata - Perl data types
4
5 =head1 DESCRIPTION
6
7 =head2 Variable names
8 X<variable, name> X<variable name> X<data type> X<type>
9
10 Perl has three built-in data types: scalars, arrays of scalars, and
11 associative arrays of scalars, known as "hashes".  A scalar is a 
12 single string (of any size, limited only by the available memory),
13 number, or a reference to something (which will be discussed
14 in L<perlref>).  Normal arrays are ordered lists of scalars indexed
15 by number, starting with 0.  Hashes are unordered collections of scalar 
16 values indexed by their associated string key.
17
18 Values are usually referred to by name, or through a named reference.
19 The first character of the name tells you to what sort of data
20 structure it refers.  The rest of the name tells you the particular
21 value to which it refers.  Usually this name is a single I<identifier>,
22 that is, a string beginning with a letter or underscore, and
23 containing letters, underscores, and digits.  In some cases, it may
24 be a chain of identifiers, separated by C<::> (or by the slightly
25 archaic C<'>); all but the last are interpreted as names of packages,
26 to locate the namespace in which to look up the final identifier
27 (see L<perlmod/Packages> for details).  For a more in-depth discussion
28 on identifiers, see L<Identifier parsing>.  It's possible to
29 substitute for a simple identifier, an expression that produces a reference
30 to the value at runtime.   This is described in more detail below
31 and in L<perlref>.
32 X<identifier>
33
34 Perl also has its own built-in variables whose names don't follow
35 these rules.  They have strange names so they don't accidentally
36 collide with one of your normal variables.  Strings that match
37 parenthesized parts of a regular expression are saved under names
38 containing only digits after the C<$> (see L<perlop> and L<perlre>).
39 In addition, several special variables that provide windows into
40 the inner working of Perl have names containing punctuation characters
41 and control characters.  These are documented in L<perlvar>.
42 X<variable, built-in>
43
44 Scalar values are always named with '$', even when referring to a
45 scalar that is part of an array or a hash.  The '$' symbol works
46 semantically like the English word "the" in that it indicates a
47 single value is expected.
48 X<scalar>
49
50     $days               # the simple scalar value "days"
51     $days[28]           # the 29th element of array @days
52     $days{'Feb'}        # the 'Feb' value from hash %days
53     $#days              # the last index of array @days
54
55 Entire arrays (and slices of arrays and hashes) are denoted by '@',
56 which works much as the word "these" or "those" does in English,
57 in that it indicates multiple values are expected.
58 X<array>
59
60     @days               # ($days[0], $days[1],... $days[n])
61     @days[3,4,5]        # same as ($days[3],$days[4],$days[5])
62     @days{'a','c'}      # same as ($days{'a'},$days{'c'})
63
64 Entire hashes are denoted by '%':
65 X<hash>
66
67     %days               # (key1, val1, key2, val2 ...)
68
69 In addition, subroutines are named with an initial '&', though this
70 is optional when unambiguous, just as the word "do" is often redundant
71 in English.  Symbol table entries can be named with an initial '*',
72 but you don't really care about that yet (if ever :-).
73
74 Every variable type has its own namespace, as do several
75 non-variable identifiers.  This means that you can, without fear
76 of conflict, use the same name for a scalar variable, an array, or
77 a hash--or, for that matter, for a filehandle, a directory handle, a
78 subroutine name, a format name, or a label.  This means that $foo
79 and @foo are two different variables.  It also means that C<$foo[1]>
80 is a part of @foo, not a part of $foo.  This may seem a bit weird,
81 but that's okay, because it is weird.
82 X<namespace>
83
84 Because variable references always start with '$', '@', or '%', the
85 "reserved" words aren't in fact reserved with respect to variable
86 names.  They I<are> reserved with respect to labels and filehandles,
87 however, which don't have an initial special character.  You can't
88 have a filehandle named "log", for instance.  Hint: you could say
89 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>.  Using
90 uppercase filehandles also improves readability and protects you
91 from conflict with future reserved words.  Case I<is> significant--"FOO",
92 "Foo", and "foo" are all different names.  Names that start with a
93 letter or underscore may also contain digits and underscores.
94 X<identifier, case sensitivity>
95 X<case>
96
97 It is possible to replace such an alphanumeric name with an expression
98 that returns a reference to the appropriate type.  For a description
99 of this, see L<perlref>.
100
101 Names that start with a digit may contain only more digits.  Names
102 that do not start with a letter, underscore, digit or a caret (i.e.
103 a control character) are limited to one character, e.g.,  C<$%> or
104 C<$$>.  (Most of these one character names have a predefined
105 significance to Perl.  For instance, C<$$> is the current process
106 id.)
107
108 =head2 Identifier parsing
109 X<identifiers>
110
111 Up until Perl 5.18, the actual rules of what a valid identifier
112 was were a bit fuzzy.  However, in general, anything defined here should
113 work on previous versions of Perl, while the opposite -- edge cases
114 that work in previous versions, but aren't defined here -- probably
115 won't work on newer versions.
116 As an important side note, please note that the following only applies
117 to bareword identifiers as found in Perl source code, not identifiers
118 introduced through symbolic references, which have much fewer
119 restrictions.
120 If working under the effect of the C<use utf8;> pragma, the following
121 rules apply:
122
123     / (?[ ( \p{Word} & \p{XID_Start} ) + [_] ])
124       (?[ ( \p{Word} & \p{XID_Continue} ) ]) *    /x
125
126 That is, a "start" character followed by any number of "continue"
127 characters.  Perl requires every character in an identifier to also
128 match C<\w> (this prevents some problematic cases); and Perl
129 additionally accepts identfier names beginning with an underscore.
130
131 If not under C<use utf8>, the source is treated as ASCII + 128 extra
132 controls, and identifiers should match
133
134     / (?aa) (?!\d) \w+ /x
135
136 That is, any word character in the ASCII range, as long as the first
137 character is not a digit.
138
139 There are two package separators in Perl: A double colon (C<::>) and a single
140 quote (C<'>).  Normal identifiers can start or end with a double colon, and
141 can contain several parts delimited by double colons.
142 Single quotes have similar rules, but with the exception that they are not
143 legal at the end of an identifier: That is, C<$'foo> and C<$foo'bar> are
144 legal, but C<$foo'bar'> are not.
145
146
147 Finally, if the identifier is preceded by a sigil --
148 More so, normal identifiers can start or end with any number
149 of double colons (::), and can contain several parts delimited
150 by double colons.
151 And additionally, if the identifier is preceded by a sigil --
152 that is, if the identifier is part of a variable name -- it
153 may optionally be enclosed in braces.
154
155 While you can mix double colons with singles quotes, the quotes must come
156 after the colons: C<$::::'foo> and C<$foo::'bar> are legal, but C<$::'::foo>
157 and C<$foo'::bar> are not.
158
159 Put together, a grammar to match a basic identifier becomes
160
161  /
162   (?(DEFINE)
163       (?<variable>
164           (?&sigil)
165           (?:
166                   (?&normal_identifier)
167               |   \{ \s* (?&normal_identifier) \s* \}
168           )
169       )
170       (?<normal_identifier>
171           (?: :: )* '?
172            (?&basic_identifier)
173            (?: (?= (?: :: )+ '? | (?: :: )* ' ) (?&normal_identifier) )?
174           (?: :: )*
175       )
176       (?<basic_identifier>
177         # is use utf8 on?
178           (?(?{ (caller(0))[8] & $utf8::hint_bits })
179               (?&Perl_XIDS) (?&Perl_XIDC)*
180             | (?aa) (?!\d) \w+
181           )
182       )
183       (?<sigil> [&*\$\@\%])
184       (?<Perl_XIDS> (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) )
185       (?<Perl_XIDC> (?[ \p{Word} & \p{XID_Continue} ]) )
186   )
187  /x
188
189 Meanwhile, special identifiers don't follow the above rules; For the most
190 part, all of the identifiers in this category have a special meaning given
191 by Perl.  Because they have special parsing rules, these generally can't be
192 fully-qualified.  They come in four forms:
193
194 =over
195
196 =item A sigil, followed solely by digits matching \p{POSIX_Digit}, like C<$0>,
197 C<$1>, or C<$10000>.
198
199 =item A sigil, followed by either a caret and a single POSIX uppercase letter,
200 like C<$^V> or C<$^W>, or a sigil followed by a literal control character
201 matching the C<\p{POSIX_Cntrl}> property. Due to a historical oddity, if not
202 running under C<use utf8>, the 128 extra controls in the C<[0x80-0xff]> range
203 may also be used in length one variables.
204
205 =item Similar to the above, a sigil, followed by bareword text in brackets,
206 where the first character is either a caret followed by an uppercase letter,
207 or a literal control, like C<${^GLOBAL_PHASE}> or C<${\7LOBAL_PHASE}>.
208
209 =item A sigil followed by a single character matching the C<\p{POSIX_Punct}>
210 property, like C<$!> or C<%+>.
211
212 =back
213
214 =head2 Context
215 X<context> X<scalar context> X<list context>
216
217 The interpretation of operations and values in Perl sometimes depends
218 on the requirements of the context around the operation or value.
219 There are two major contexts: list and scalar.  Certain operations
220 return list values in contexts wanting a list, and scalar values
221 otherwise.  If this is true of an operation it will be mentioned in
222 the documentation for that operation.  In other words, Perl overloads
223 certain operations based on whether the expected return value is
224 singular or plural.  Some words in English work this way, like "fish"
225 and "sheep".
226
227 In a reciprocal fashion, an operation provides either a scalar or a
228 list context to each of its arguments.  For example, if you say
229
230     int( <STDIN> )
231
232 the integer operation provides scalar context for the <>
233 operator, which responds by reading one line from STDIN and passing it
234 back to the integer operation, which will then find the integer value
235 of that line and return that.  If, on the other hand, you say
236
237     sort( <STDIN> )
238
239 then the sort operation provides list context for <>, which
240 will proceed to read every line available up to the end of file, and
241 pass that list of lines back to the sort routine, which will then
242 sort those lines and return them as a list to whatever the context
243 of the sort was.
244
245 Assignment is a little bit special in that it uses its left argument
246 to determine the context for the right argument.  Assignment to a
247 scalar evaluates the right-hand side in scalar context, while
248 assignment to an array or hash evaluates the righthand side in list
249 context.  Assignment to a list (or slice, which is just a list
250 anyway) also evaluates the right-hand side in list context.
251
252 When you use the C<use warnings> pragma or Perl's B<-w> command-line 
253 option, you may see warnings
254 about useless uses of constants or functions in "void context".
255 Void context just means the value has been discarded, such as a
256 statement containing only C<"fred";> or C<getpwuid(0);>.  It still
257 counts as scalar context for functions that care whether or not
258 they're being called in list context.
259
260 User-defined subroutines may choose to care whether they are being
261 called in a void, scalar, or list context.  Most subroutines do not
262 need to bother, though.  That's because both scalars and lists are
263 automatically interpolated into lists.  See L<perlfunc/wantarray>
264 for how you would dynamically discern your function's calling
265 context.
266
267 =head2 Scalar values
268 X<scalar> X<number> X<string> X<reference>
269
270 All data in Perl is a scalar, an array of scalars, or a hash of
271 scalars.  A scalar may contain one single value in any of three
272 different flavors: a number, a string, or a reference.  In general,
273 conversion from one form to another is transparent.  Although a
274 scalar may not directly hold multiple values, it may contain a
275 reference to an array or hash which in turn contains multiple values.
276
277 Scalars aren't necessarily one thing or another.  There's no place
278 to declare a scalar variable to be of type "string", type "number",
279 type "reference", or anything else.  Because of the automatic
280 conversion of scalars, operations that return scalars don't need
281 to care (and in fact, cannot care) whether their caller is looking
282 for a string, a number, or a reference.  Perl is a contextually
283 polymorphic language whose scalars can be strings, numbers, or
284 references (which includes objects).  Although strings and numbers
285 are considered pretty much the same thing for nearly all purposes,
286 references are strongly-typed, uncastable pointers with builtin
287 reference-counting and destructor invocation.
288
289 A scalar value is interpreted as FALSE in the Boolean sense
290 if it is undefined, the null string or the number 0 (or its
291 string equivalent, "0"), and TRUE if it is anything else.  The
292 Boolean context is just a special kind of scalar context where no 
293 conversion to a string or a number is ever performed.
294 X<boolean> X<bool> X<true> X<false> X<truth>
295
296 There are actually two varieties of null strings (sometimes referred
297 to as "empty" strings), a defined one and an undefined one.  The
298 defined version is just a string of length zero, such as C<"">.
299 The undefined version is the value that indicates that there is
300 no real value for something, such as when there was an error, or
301 at end of file, or when you refer to an uninitialized variable or
302 element of an array or hash.  Although in early versions of Perl,
303 an undefined scalar could become defined when first used in a
304 place expecting a defined value, this no longer happens except for
305 rare cases of autovivification as explained in L<perlref>.  You can
306 use the defined() operator to determine whether a scalar value is
307 defined (this has no meaning on arrays or hashes), and the undef()
308 operator to produce an undefined value.
309 X<defined> X<undefined> X<undef> X<null> X<string, null>
310
311 To find out whether a given string is a valid non-zero number, it's
312 sometimes enough to test it against both numeric 0 and also lexical
313 "0" (although this will cause noises if warnings are on).  That's 
314 because strings that aren't numbers count as 0, just as they do in B<awk>:
315
316     if ($str == 0 && $str ne "0")  {
317         warn "That doesn't look like a number";
318     }
319
320 That method may be best because otherwise you won't treat IEEE
321 notations like C<NaN> or C<Infinity> properly.  At other times, you
322 might prefer to determine whether string data can be used numerically
323 by calling the POSIX::strtod() function or by inspecting your string
324 with a regular expression (as documented in L<perlre>).
325
326     warn "has nondigits"        if     /\D/;
327     warn "not a natural number" unless /^\d+$/;             # rejects -3
328     warn "not an integer"       unless /^-?\d+$/;           # rejects +3
329     warn "not an integer"       unless /^[+-]?\d+$/;
330     warn "not a decimal number" unless /^-?\d+\.?\d*$/;     # rejects .2
331     warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
332     warn "not a C float"
333         unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
334
335 The length of an array is a scalar value.  You may find the length
336 of array @days by evaluating C<$#days>, as in B<csh>.  However, this
337 isn't the length of the array; it's the subscript of the last element,
338 which is a different value since there is ordinarily a 0th element.
339 Assigning to C<$#days> actually changes the length of the array.
340 Shortening an array this way destroys intervening values.  Lengthening
341 an array that was previously shortened does not recover values
342 that were in those elements.
343 X<$#> X<array, length>
344
345 You can also gain some minuscule measure of efficiency by pre-extending
346 an array that is going to get big.  You can also extend an array
347 by assigning to an element that is off the end of the array.  You
348 can truncate an array down to nothing by assigning the null list
349 () to it.  The following are equivalent:
350
351     @whatever = ();
352     $#whatever = -1;
353
354 If you evaluate an array in scalar context, it returns the length
355 of the array.  (Note that this is not true of lists, which return
356 the last value, like the C comma operator, nor of built-in functions,
357 which return whatever they feel like returning.)  The following is
358 always true:
359 X<array, length>
360
361     scalar(@whatever) == $#whatever + 1;
362
363 Some programmers choose to use an explicit conversion so as to 
364 leave nothing to doubt:
365
366     $element_count = scalar(@whatever);
367
368 If you evaluate a hash in scalar context, it returns false if the
369 hash is empty.  If there are any key/value pairs, it returns true;
370 more precisely, the value returned is a string consisting of the
371 number of used buckets and the number of allocated buckets, separated
372 by a slash.  This is pretty much useful only to find out whether
373 Perl's internal hashing algorithm is performing poorly on your data
374 set.  For example, you stick 10,000 things in a hash, but evaluating
375 %HASH in scalar context reveals C<"1/16">, which means only one out
376 of sixteen buckets has been touched, and presumably contains all
377 10,000 of your items.  This isn't supposed to happen.  If a tied hash
378 is evaluated in scalar context, the C<SCALAR> method is called (with a
379 fallback to C<FIRSTKEY>).
380 X<hash, scalar context> X<hash, bucket> X<bucket>
381
382 You can preallocate space for a hash by assigning to the keys() function.
383 This rounds up the allocated buckets to the next power of two:
384
385     keys(%users) = 1000;                # allocate 1024 buckets
386
387 =head2 Scalar value constructors
388 X<scalar, literal> X<scalar, constant>
389
390 Numeric literals are specified in any of the following floating point or
391 integer formats:
392
393     12345
394     12345.67
395     .23E-10             # a very small number
396     3.14_15_92          # a very important number
397     4_294_967_296       # underscore for legibility
398     0xff                # hex
399     0xdead_beef         # more hex   
400     0377                # octal (only numbers, begins with 0)
401     0b011011            # binary
402
403 You are allowed to use underscores (underbars) in numeric literals
404 between digits for legibility (but not multiple underscores in a row:
405 C<23__500> is not legal; C<23_500> is).
406 You could, for example, group binary
407 digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
408 or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
409 X<number, literal>
410
411 String literals are usually delimited by either single or double
412 quotes.  They work much like quotes in the standard Unix shells:
413 double-quoted string literals are subject to backslash and variable
414 substitution; single-quoted strings are not (except for C<\'> and
415 C<\\>).  The usual C-style backslash rules apply for making
416 characters such as newline, tab, etc., as well as some more exotic
417 forms.  See L<perlop/"Quote and Quote-like Operators"> for a list.
418 X<string, literal>
419
420 Hexadecimal, octal, or binary, representations in string literals
421 (e.g. '0xff') are not automatically converted to their integer
422 representation.  The hex() and oct() functions make these conversions
423 for you.  See L<perlfunc/hex> and L<perlfunc/oct> for more details.
424
425 You can also embed newlines directly in your strings, i.e., they can end
426 on a different line than they begin.  This is nice, but if you forget
427 your trailing quote, the error will not be reported until Perl finds
428 another line containing the quote character, which may be much further
429 on in the script.  Variable substitution inside strings is limited to
430 scalar variables, arrays, and array or hash slices.  (In other words,
431 names beginning with $ or @, followed by an optional bracketed
432 expression as a subscript.)  The following code segment prints out "The
433 price is $Z<>100."
434 X<interpolation>
435
436     $Price = '$100';    # not interpolated
437     print "The price is $Price.\n";     # interpolated
438
439 There is no double interpolation in Perl, so the C<$100> is left as is.
440
441 By default floating point numbers substituted inside strings use the
442 dot (".")  as the decimal separator.  If C<use locale> is in effect,
443 and POSIX::setlocale() has been called, the character used for the
444 decimal separator is affected by the LC_NUMERIC locale.
445 See L<perllocale> and L<POSIX>.
446
447 As in some shells, you can enclose the variable name in braces to
448 disambiguate it from following alphanumerics (and underscores).
449 You must also do
450 this when interpolating a variable into a string to separate the
451 variable name from a following double-colon or an apostrophe, since
452 these would be otherwise treated as a package separator:
453 X<interpolation>
454
455     $who = "Larry";
456     print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
457     print "We use ${who}speak when ${who}'s here.\n";
458
459 Without the braces, Perl would have looked for a $whospeak, a
460 C<$who::0>, and a C<$who's> variable.  The last two would be the
461 $0 and the $s variables in the (presumably) non-existent package
462 C<who>.
463
464 In fact, a simple identifier within such curlies is forced to be
465 a string, and likewise within a hash subscript. Neither need
466 quoting.  Our earlier example, C<$days{'Feb'}> can be written as
467 C<$days{Feb}> and the quotes will be assumed automatically.  But
468 anything more complicated in the subscript will be interpreted as an
469 expression.  This means for example that C<$version{2.0}++> is
470 equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>.
471
472 =head3 Version Strings
473 X<version string> X<vstring> X<v-string>
474
475 A literal of the form C<v1.20.300.4000> is parsed as a string composed
476 of characters with the specified ordinals.  This form, known as
477 v-strings, provides an alternative, more readable way to construct
478 strings, rather than use the somewhat less readable interpolation form
479 C<"\x{1}\x{14}\x{12c}\x{fa0}">.  This is useful for representing
480 Unicode strings, and for comparing version "numbers" using the string
481 comparison operators, C<cmp>, C<gt>, C<lt> etc.  If there are two or
482 more dots in the literal, the leading C<v> may be omitted.
483
484     print v9786;              # prints SMILEY, "\x{263a}"
485     print v102.111.111;       # prints "foo"
486     print 102.111.111;        # same
487
488 Such literals are accepted by both C<require> and C<use> for
489 doing a version check.  Note that using the v-strings for IPv4
490 addresses is not portable unless you also use the
491 inet_aton()/inet_ntoa() routines of the Socket package.
492
493 Note that since Perl 5.8.1 the single-number v-strings (like C<v65>)
494 are not v-strings before the C<< => >> operator (which is usually used
495 to separate a hash key from a hash value); instead they are interpreted
496 as literal strings ('v65').  They were v-strings from Perl 5.6.0 to
497 Perl 5.8.0, but that caused more confusion and breakage than good.
498 Multi-number v-strings like C<v65.66> and C<65.66.67> continue to
499 be v-strings always.
500
501 =head3 Special Literals
502 X<special literal> X<__END__> X<__DATA__> X<END> X<DATA>
503 X<end> X<data> X<^D> X<^Z>
504
505 The special literals __FILE__, __LINE__, and __PACKAGE__
506 represent the current filename, line number, and package name at that
507 point in your program.  __SUB__ gives a reference to the current
508 subroutine.  They may be used only as separate tokens; they
509 will not be interpolated into strings.  If there is no current package
510 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
511 value.  (But the empty C<package;> is no longer supported, as of version
512 5.10.)  Outside of a subroutine, __SUB__ is the undefined value.  __SUB__
513 is only available in 5.16 or higher, and only with a C<use v5.16> or
514 C<use feature "current_sub"> declaration.
515 X<__FILE__> X<__LINE__> X<__PACKAGE__> X<__SUB__>
516 X<line> X<file> X<package>
517
518 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
519 may be used to indicate the logical end of the script before the actual
520 end of file.  Any following text is ignored.
521
522 Text after __DATA__ may be read via the filehandle C<PACKNAME::DATA>,
523 where C<PACKNAME> is the package that was current when the __DATA__
524 token was encountered.  The filehandle is left open pointing to the
525 line after __DATA__.  The program should C<close DATA> when it is done
526 reading from it.  (Leaving it open leaks filehandles if the module is
527 reloaded for any reason, so it's a safer practice to close it.)  For
528 compatibility with older scripts written before __DATA__ was
529 introduced, __END__ behaves like __DATA__ in the top level script (but
530 not in files loaded with C<require> or C<do>) and leaves the remaining
531 contents of the file accessible via C<main::DATA>.
532
533 See L<SelfLoader> for more description of __DATA__, and
534 an example of its use.  Note that you cannot read from the DATA
535 filehandle in a BEGIN block: the BEGIN block is executed as soon
536 as it is seen (during compilation), at which point the corresponding
537 __DATA__ (or __END__) token has not yet been seen.
538
539 =head3 Barewords
540 X<bareword>
541
542 A word that has no other interpretation in the grammar will
543 be treated as if it were a quoted string.  These are known as
544 "barewords".  As with filehandles and labels, a bareword that consists
545 entirely of lowercase letters risks conflict with future reserved
546 words, and if you use the C<use warnings> pragma or the B<-w> switch, 
547 Perl will warn you about any such words.  Perl limits barewords (like
548 identifiers) to about 250 characters.  Future versions of Perl are likely
549 to eliminate these arbitrary limitations.
550
551 Some people may wish to outlaw barewords entirely.  If you
552 say
553
554     use strict 'subs';
555
556 then any bareword that would NOT be interpreted as a subroutine call
557 produces a compile-time error instead.  The restriction lasts to the
558 end of the enclosing block.  An inner block may countermand this
559 by saying C<no strict 'subs'>.
560
561 =head3 Array Interpolation
562 X<array, interpolation> X<interpolation, array> X<$">
563
564 Arrays and slices are interpolated into double-quoted strings
565 by joining the elements with the delimiter specified in the C<$">
566 variable (C<$LIST_SEPARATOR> if "use English;" is specified), 
567 space by default.  The following are equivalent:
568
569     $temp = join($", @ARGV);
570     system "echo $temp";
571
572     system "echo @ARGV";
573
574 Within search patterns (which also undergo double-quotish substitution)
575 there is an unfortunate ambiguity:  Is C</$foo[bar]/> to be interpreted as
576 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
577 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
578 @foo)?  If @foo doesn't otherwise exist, then it's obviously a
579 character class.  If @foo exists, Perl takes a good guess about C<[bar]>,
580 and is almost always right.  If it does guess wrong, or if you're just
581 plain paranoid, you can force the correct interpretation with curly
582 braces as above.
583
584 If you're looking for the information on how to use here-documents,
585 which used to be here, that's been moved to
586 L<perlop/Quote and Quote-like Operators>.
587
588 =head2 List value constructors
589 X<list>
590
591 List values are denoted by separating individual values by commas
592 (and enclosing the list in parentheses where precedence requires it):
593
594     (LIST)
595
596 In a context not requiring a list value, the value of what appears
597 to be a list literal is simply the value of the final element, as
598 with the C comma operator.  For example,
599
600     @foo = ('cc', '-E', $bar);
601
602 assigns the entire list value to array @foo, but
603
604     $foo = ('cc', '-E', $bar);
605
606 assigns the value of variable $bar to the scalar variable $foo.
607 Note that the value of an actual array in scalar context is the
608 length of the array; the following assigns the value 3 to $foo:
609
610     @foo = ('cc', '-E', $bar);
611     $foo = @foo;                # $foo gets 3
612
613 You may have an optional comma before the closing parenthesis of a
614 list literal, so that you can say:
615
616     @foo = (
617         1,
618         2,
619         3,
620     );
621
622 To use a here-document to assign an array, one line per element,
623 you might use an approach like this:
624
625     @sauces = <<End_Lines =~ m/(\S.*\S)/g;
626         normal tomato
627         spicy tomato
628         green chile
629         pesto
630         white wine
631     End_Lines
632
633 LISTs do automatic interpolation of sublists.  That is, when a LIST is
634 evaluated, each element of the list is evaluated in list context, and
635 the resulting list value is interpolated into LIST just as if each
636 individual element were a member of LIST.  Thus arrays and hashes lose their
637 identity in a LIST--the list
638
639     (@foo,@bar,&SomeSub,%glarch)
640
641 contains all the elements of @foo followed by all the elements of @bar,
642 followed by all the elements returned by the subroutine named SomeSub 
643 called in list context, followed by the key/value pairs of %glarch.
644 To make a list reference that does I<NOT> interpolate, see L<perlref>.
645
646 The null list is represented by ().  Interpolating it in a list
647 has no effect.  Thus ((),(),()) is equivalent to ().  Similarly,
648 interpolating an array with no elements is the same as if no
649 array had been interpolated at that point.
650
651 This interpolation combines with the facts that the opening
652 and closing parentheses are optional (except when necessary for
653 precedence) and lists may end with an optional comma to mean that
654 multiple commas within lists are legal syntax.  The list C<1,,3> is a
655 concatenation of two lists, C<1,> and C<3>, the first of which ends
656 with that optional comma.  C<1,,3> is C<(1,),(3)> is C<1,3> (And
657 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.)  Not that
658 we'd advise you to use this obfuscation.
659
660 A list value may also be subscripted like a normal array.  You must
661 put the list in parentheses to avoid ambiguity.  For example:
662
663     # Stat returns list value.
664     $time = (stat($file))[8];
665
666     # SYNTAX ERROR HERE.
667     $time = stat($file)[8];  # OOPS, FORGOT PARENTHESES
668
669     # Find a hex digit.
670     $hexdigit = ('a','b','c','d','e','f')[$digit-10];
671
672     # A "reverse comma operator".
673     return (pop(@foo),pop(@foo))[0];
674
675 Lists may be assigned to only when each element of the list
676 is itself legal to assign to:
677
678     ($a, $b, $c) = (1, 2, 3);
679
680     ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
681
682 An exception to this is that you may assign to C<undef> in a list.
683 This is useful for throwing away some of the return values of a
684 function:
685
686     ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
687
688 List assignment in scalar context returns the number of elements
689 produced by the expression on the right side of the assignment:
690
691     $x = (($foo,$bar) = (3,2,1));       # set $x to 3, not 2
692     $x = (($foo,$bar) = f());           # set $x to f()'s return count
693
694 This is handy when you want to do a list assignment in a Boolean
695 context, because most list functions return a null list when finished,
696 which when assigned produces a 0, which is interpreted as FALSE.
697
698 It's also the source of a useful idiom for executing a function or
699 performing an operation in list context and then counting the number of
700 return values, by assigning to an empty list and then using that
701 assignment in scalar context.  For example, this code:
702
703     $count = () = $string =~ /\d+/g;
704
705 will place into $count the number of digit groups found in $string.
706 This happens because the pattern match is in list context (since it
707 is being assigned to the empty list), and will therefore return a list
708 of all matching parts of the string.  The list assignment in scalar
709 context will translate that into the number of elements (here, the
710 number of times the pattern matched) and assign that to $count.  Note
711 that simply using
712
713     $count = $string =~ /\d+/g;
714
715 would not have worked, since a pattern match in scalar context will
716 only return true or false, rather than a count of matches.
717
718 The final element of a list assignment may be an array or a hash:
719
720     ($a, $b, @rest) = split;
721     my($a, $b, %rest) = @_;
722
723 You can actually put an array or hash anywhere in the list, but the first one
724 in the list will soak up all the values, and anything after it will become
725 undefined.  This may be useful in a my() or local().
726
727 A hash can be initialized using a literal list holding pairs of
728 items to be interpreted as a key and a value:
729
730     # same as map assignment above
731     %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
732
733 While literal lists and named arrays are often interchangeable, that's
734 not the case for hashes.  Just because you can subscript a list value like
735 a normal array does not mean that you can subscript a list value as a
736 hash.  Likewise, hashes included as parts of other lists (including
737 parameters lists and return lists from functions) always flatten out into
738 key/value pairs.  That's why it's good to use references sometimes.
739
740 It is often more readable to use the C<< => >> operator between key/value
741 pairs.  The C<< => >> operator is mostly just a more visually distinctive
742 synonym for a comma, but it also arranges for its left-hand operand to be
743 interpreted as a string if it's a bareword that would be a legal simple
744 identifier.  C<< => >> doesn't quote compound identifiers, that contain
745 double colons.  This makes it nice for initializing hashes:
746
747     %map = (
748                  red   => 0x00f,
749                  blue  => 0x0f0,
750                  green => 0xf00,
751    );
752
753 or for initializing hash references to be used as records:
754
755     $rec = {
756                 witch => 'Mable the Merciless',
757                 cat   => 'Fluffy the Ferocious',
758                 date  => '10/31/1776',
759     };
760
761 or for using call-by-named-parameter to complicated functions:
762
763    $field = $query->radio_group(
764                name      => 'group_name',
765                values    => ['eenie','meenie','minie'],
766                default   => 'meenie',
767                linebreak => 'true',
768                labels    => \%labels
769    );
770
771 Note that just because a hash is initialized in that order doesn't
772 mean that it comes out in that order.  See L<perlfunc/sort> for examples
773 of how to arrange for an output ordering.
774
775 If a key appears more than once in the initializer list of a hash, the last
776 occurrence wins:
777
778     %circle = (
779                   center => [5, 10],
780                   center => [27, 9],
781                   radius => 100,
782                   color => [0xDF, 0xFF, 0x00],
783                   radius => 54,
784     );
785
786     # same as
787     %circle = (
788                   center => [27, 9],
789                   color => [0xDF, 0xFF, 0x00],
790                   radius => 54,
791     );
792
793 This can be used to provide overridable configuration defaults:
794
795     # values in %args take priority over %config_defaults
796     %config = (%config_defaults, %args);
797
798 =head2 Subscripts
799
800 An array can be accessed one scalar at a
801 time by specifying a dollar sign (C<$>), then the
802 name of the array (without the leading C<@>), then the subscript inside
803 square brackets.  For example:
804
805     @myarray = (5, 50, 500, 5000);
806     print "The Third Element is", $myarray[2], "\n";
807
808 The array indices start with 0.  A negative subscript retrieves its 
809 value from the end.  In our example, C<$myarray[-1]> would have been 
810 5000, and C<$myarray[-2]> would have been 500.
811
812 Hash subscripts are similar, only instead of square brackets curly brackets
813 are used.  For example:
814
815     %scientists = 
816     (
817         "Newton" => "Isaac",
818         "Einstein" => "Albert",
819         "Darwin" => "Charles",
820         "Feynman" => "Richard",
821     );
822
823     print "Darwin's First Name is ", $scientists{"Darwin"}, "\n";
824
825 You can also subscript a list to get a single element from it:
826
827     $dir = (getpwnam("daemon"))[7];
828
829 =head2 Multi-dimensional array emulation
830
831 Multidimensional arrays may be emulated by subscripting a hash with a
832 list.  The elements of the list are joined with the subscript separator
833 (see L<perlvar/$;>).
834
835     $foo{$a,$b,$c}
836
837 is equivalent to
838
839     $foo{join($;, $a, $b, $c)}
840
841 The default subscript separator is "\034", the same as SUBSEP in B<awk>.
842
843 =head2 Slices
844 X<slice> X<array, slice> X<hash, slice>
845
846 A slice accesses several elements of a list, an array, or a hash
847 simultaneously using a list of subscripts.  It's more convenient
848 than writing out the individual elements as a list of separate
849 scalar values.
850
851     ($him, $her)   = @folks[0,-1];              # array slice
852     @them          = @folks[0 .. 3];            # array slice
853     ($who, $home)  = @ENV{"USER", "HOME"};      # hash slice
854     ($uid, $dir)   = (getpwnam("daemon"))[2,7]; # list slice
855
856 Since you can assign to a list of variables, you can also assign to
857 an array or hash slice.
858
859     @days[3..5]    = qw/Wed Thu Fri/;
860     @colors{'red','blue','green'} 
861                    = (0xff0000, 0x0000ff, 0x00ff00);
862     @folks[0, -1]  = @folks[-1, 0];
863
864 The previous assignments are exactly equivalent to
865
866     ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
867     ($colors{'red'}, $colors{'blue'}, $colors{'green'})
868                    = (0xff0000, 0x0000ff, 0x00ff00);
869     ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
870
871 Since changing a slice changes the original array or hash that it's
872 slicing, a C<foreach> construct will alter some--or even all--of the
873 values of the array or hash.
874
875     foreach (@array[ 4 .. 10 ]) { s/peter/paul/ } 
876
877     foreach (@hash{qw[key1 key2]}) {
878         s/^\s+//;           # trim leading whitespace
879         s/\s+$//;           # trim trailing whitespace
880         s/(\w+)/\u\L$1/g;   # "titlecase" words
881     }
882
883 A slice of an empty list is still an empty list.  Thus:
884
885     @a = ()[1,0];           # @a has no elements
886     @b = (@a)[0,1];         # @b has no elements
887
888 But:
889
890     @a = (1)[1,0];          # @a has two elements
891     @b = (1,undef)[1,0,2];  # @b has three elements
892
893 More generally, a slice yields the empty list if it indexes only
894 beyond the end of a list:
895
896     @a = (1)[  1,2];        # @a has no elements
897     @b = (1)[0,1,2];        # @b has three elements
898
899 This makes it easy to write loops that terminate when a null list
900 is returned:
901
902     while ( ($home, $user) = (getpwent)[7,0]) {
903         printf "%-8s %s\n", $user, $home;
904     }
905
906 As noted earlier in this document, the scalar sense of list assignment
907 is the number of elements on the right-hand side of the assignment.
908 The null list contains no elements, so when the password file is
909 exhausted, the result is 0, not 2.
910
911 Slices in scalar context return the last item of the slice.
912
913     @a = qw/first second third/;
914     %h = (first => 'A', second => 'B');
915     $t = @a[0, 1];                  # $t is now 'second'
916     $u = @h{'first', 'second'};     # $u is now 'B'
917
918 If you're confused about why you use an '@' there on a hash slice
919 instead of a '%', think of it like this.  The type of bracket (square
920 or curly) governs whether it's an array or a hash being looked at.
921 On the other hand, the leading symbol ('$' or '@') on the array or
922 hash indicates whether you are getting back a singular value (a
923 scalar) or a plural one (a list).
924
925 =head2 Typeglobs and Filehandles
926 X<typeglob> X<filehandle> X<*>
927
928 Perl uses an internal type called a I<typeglob> to hold an entire
929 symbol table entry.  The type prefix of a typeglob is a C<*>, because
930 it represents all types.  This used to be the preferred way to
931 pass arrays and hashes by reference into a function, but now that
932 we have real references, this is seldom needed.  
933
934 The main use of typeglobs in modern Perl is create symbol table aliases.
935 This assignment:
936
937     *this = *that;
938
939 makes $this an alias for $that, @this an alias for @that, %this an alias
940 for %that, &this an alias for &that, etc.  Much safer is to use a reference.
941 This:
942
943     local *Here::blue = \$There::green;
944
945 temporarily makes $Here::blue an alias for $There::green, but doesn't
946 make @Here::blue an alias for @There::green, or %Here::blue an alias for
947 %There::green, etc.  See L<perlmod/"Symbol Tables"> for more examples
948 of this.  Strange though this may seem, this is the basis for the whole
949 module import/export system.
950
951 Another use for typeglobs is to pass filehandles into a function or
952 to create new filehandles.  If you need to use a typeglob to save away
953 a filehandle, do it this way:
954
955     $fh = *STDOUT;
956
957 or perhaps as a real reference, like this:
958
959     $fh = \*STDOUT;
960
961 See L<perlsub> for examples of using these as indirect filehandles
962 in functions.
963
964 Typeglobs are also a way to create a local filehandle using the local()
965 operator.  These last until their block is exited, but may be passed back.
966 For example:
967
968     sub newopen {
969         my $path = shift;
970         local  *FH;  # not my!
971         open   (FH, $path)          or  return undef;
972         return *FH;
973     }
974     $fh = newopen('/etc/passwd');
975
976 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
977 for filehandle manipulations, although they're still needed to pass brand
978 new file and directory handles into or out of functions.  That's because
979 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
980 In other words, C<*FH> must be used to create new symbol table entries;
981 C<*foo{THING}> cannot.  When in doubt, use C<*FH>.
982
983 All functions that are capable of creating filehandles (open(),
984 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
985 automatically create an anonymous filehandle if the handle passed to
986 them is an uninitialized scalar variable.  This allows the constructs
987 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
988 create filehandles that will conveniently be closed automatically when
989 the scope ends, provided there are no other references to them.  This
990 largely eliminates the need for typeglobs when opening filehandles
991 that must be passed around, as in the following example:
992
993     sub myopen {
994         open my $fh, "@_"
995              or die "Can't open '@_': $!";
996         return $fh;
997     }
998
999     {
1000         my $f = myopen("</etc/motd");
1001         print <$f>;
1002         # $f implicitly closed here
1003     }
1004
1005 Note that if an initialized scalar variable is used instead the
1006 result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent
1007 to C<open( *{'zzz'}, ...)>.
1008 C<use strict 'refs'> forbids such practice.
1009
1010 Another way to create anonymous filehandles is with the Symbol
1011 module or with the IO::Handle module and its ilk.  These modules
1012 have the advantage of not hiding different types of the same name
1013 during the local().  See the bottom of L<perlfunc/open> for an
1014 example.
1015
1016 =head1 SEE ALSO
1017
1018 See L<perlvar> for a description of Perl's built-in variables and
1019 a discussion of legal variable names.  See L<perlref>, L<perlsub>,
1020 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
1021 the C<*foo{THING}> syntax.