This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
22f71ab211f94b18db479e4620137b707b1223cd
[perl5.git] / pod / perlrecharclass.pod
1 =head1 NAME
2 X<character class>
3
4 perlrecharclass - Perl Regular Expression Character Classes
5
6 =head1 DESCRIPTION
7
8 The top level documentation about Perl regular expressions
9 is found in L<perlre>.
10
11 This manual page discusses the syntax and use of character
12 classes in Perl regular expressions.
13
14 A character class is a way of denoting a set of characters
15 in such a way that one character of the set is matched.
16 It's important to remember that: matching a character class
17 consumes exactly one character in the source string. (The source
18 string is the string the regular expression is matched against.)
19
20 There are three types of character classes in Perl regular
21 expressions: the dot, backslash sequences, and the form enclosed in square
22 brackets.  Keep in mind, though, that often the term "character class" is used
23 to mean just the bracketed form.  Certainly, most Perl documentation does that.
24
25 =head2 The dot
26
27 The dot (or period), C<.> is probably the most used, and certainly
28 the most well-known character class. By default, a dot matches any
29 character, except for the newline. That default can be changed to
30 add matching the newline by using the I<single line> modifier: either
31 for the entire regular expression with the C</s> modifier, or
32 locally with C<(?s)>.  (The C<L</\N>> backslash sequence, described
33 below, matches any character except newline without regard to the
34 I<single line> modifier.)
35
36 Here are some examples:
37
38  "a"  =~  /./       # Match
39  "."  =~  /./       # Match
40  ""   =~  /./       # No match (dot has to match a character)
41  "\n" =~  /./       # No match (dot does not match a newline)
42  "\n" =~  /./s      # Match (global 'single line' modifier)
43  "\n" =~  /(?s:.)/  # Match (local 'single line' modifier)
44  "ab" =~  /^.$/     # No match (dot matches one character)
45
46 =head2 Backslash sequences
47 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\p> X<\P>
48 X<\N> X<\v> X<\V> X<\h> X<\H>
49 X<word> X<whitespace>
50
51 A backslash sequence is a sequence of characters, the first one of which is a
52 backslash.  Perl ascribes special meaning to many such sequences, and some of
53 these are character classes.  That is, they match a single character each,
54 provided that the character belongs to the specific set of characters defined
55 by the sequence.
56
57 Here's a list of the backslash sequences that are character classes.  They
58 are discussed in more detail below.  (For the backslash sequences that aren't
59 character classes, see L<perlrebackslash>.)
60
61  \d             Match a decimal digit character.
62  \D             Match a non-decimal-digit character.
63  \w             Match a "word" character.
64  \W             Match a non-"word" character.
65  \s             Match a whitespace character.
66  \S             Match a non-whitespace character.
67  \h             Match a horizontal whitespace character.
68  \H             Match a character that isn't horizontal whitespace.
69  \v             Match a vertical whitespace character.
70  \V             Match a character that isn't vertical whitespace.
71  \N             Match a character that isn't a newline.
72  \pP, \p{Prop}  Match a character that has the given Unicode property.
73  \PP, \P{Prop}  Match a character that doesn't have the Unicode property
74
75 =head3 \N
76
77 C<\N>, available starting in v5.12, like the dot, matches any
78 character that is not a newline. The difference is that C<\N> is not influenced
79 by the I<single line> regular expression modifier (see L</The dot> above).  Note
80 that the form C<\N{...}> may mean something completely different.  When the
81 C<{...}> is a L<quantifier|perlre/Quantifiers>, it means to match a non-newline
82 character that many times.  For example, C<\N{3}> means to match 3
83 non-newlines; C<\N{5,}> means to match 5 or more non-newlines.  But if C<{...}>
84 is not a legal quantifier, it is presumed to be a named character.  See
85 L<charnames> for those.  For example, none of C<\N{COLON}>, C<\N{4F}>, and
86 C<\N{F4}> contain legal quantifiers, so Perl will try to find characters whose
87 names are respectively C<COLON>, C<4F>, and C<F4>.
88
89 =head3 Digits
90
91 C<\d> matches a single character considered to be a decimal I<digit>.
92 If the C</a> regular expression modifier is in effect, it matches [0-9].
93 Otherwise, it
94 matches anything that is matched by C<\p{Digit}>, which includes [0-9].
95 (An unlikely possible exception is that under locale matching rules, the
96 current locale might not have C<[0-9]> matched by C<\d>, and/or might match
97 other characters whose code point is less than 256.  The only such locale
98 definitions that are legal would be to match C<[0-9]> plus another set of
99 10 consecutive digit characters;  anything else would be in violation of
100 the C language standard, but Perl doesn't currently assume anything in
101 regard to this.)
102
103 What this means is that unless the C</a> modifier is in effect C<\d> not
104 only matches the digits '0' - '9', but also Arabic, Devanagari, and
105 digits from other languages.  This may cause some confusion, and some
106 security issues.
107
108 Some digits that C<\d> matches look like some of the [0-9] ones, but
109 have different values.  For example, BENGALI DIGIT FOUR (U+09EA) looks
110 very much like an ASCII DIGIT EIGHT (U+0038).  An application that
111 is expecting only the ASCII digits might be misled, or if the match is
112 C<\d+>, the matched string might contain a mixture of digits from
113 different writing systems that look like they signify a number different
114 than they actually do.  L<Unicode::UCD/num()> can
115 be used to safely
116 calculate the value, returning C<undef> if the input string contains
117 such a mixture.
118
119 What C<\p{Digit}> means (and hence C<\d> except under the C</a>
120 modifier) is C<\p{General_Category=Decimal_Number}>, or synonymously,
121 C<\p{General_Category=Digit}>.  Starting with Unicode version 4.1, this
122 is the same set of characters matched by C<\p{Numeric_Type=Decimal}>.
123 But Unicode also has a different property with a similar name,
124 C<\p{Numeric_Type=Digit}>, which matches a completely different set of
125 characters.  These characters are things such as C<CIRCLED DIGIT ONE>
126 or subscripts, or are from writing systems that lack all ten digits.
127
128 The design intent is for C<\d> to exactly match the set of characters
129 that can safely be used with "normal" big-endian positional decimal
130 syntax, where, for example 123 means one 'hundred', plus two 'tens',
131 plus three 'ones'.  This positional notation does not necessarily apply
132 to characters that match the other type of "digit",
133 C<\p{Numeric_Type=Digit}>, and so C<\d> doesn't match them.
134
135 The Tamil digits (U+0BE6 - U+0BEF) can also legally be
136 used in old-style Tamil numbers in which they would appear no more than
137 one in a row, separated by characters that mean "times 10", "times 100",
138 etc.  (See L<http://www.unicode.org/notes/tn21>.)
139
140 Any character not matched by C<\d> is matched by C<\D>.
141
142 =head3 Word characters
143
144 A C<\w> matches a single alphanumeric character (an alphabetic character, or a
145 decimal digit); or a connecting punctuation character, such as an
146 underscore ("_"); or a "mark" character (like some sort of accent) that
147 attaches to one of those.  It does not match a whole word.  To match a
148 whole word, use C<\w+>.  This isn't the same thing as matching an
149 English word, but in the ASCII range it is the same as a string of
150 Perl-identifier characters.
151
152 =over
153
154 =item If the C</a> modifier is in effect ...
155
156 C<\w> matches the 63 characters [a-zA-Z0-9_].
157
158 =item otherwise ...
159
160 =over
161
162 =item For code points above 255 ...
163
164 C<\w> matches the same as C<\p{Word}> matches in this range.  That is,
165 it matches Thai letters, Greek letters, etc.  This includes connector
166 punctuation (like the underscore) which connect two words together, or
167 diacritics, such as a C<COMBINING TILDE> and the modifier letters, which
168 are generally used to add auxiliary markings to letters.
169
170 =item For code points below 256 ...
171
172 =over
173
174 =item if locale rules are in effect ...
175
176 C<\w> matches the platform's native underscore character plus whatever
177 the locale considers to be alphanumeric.
178
179 =item if Unicode rules are in effect ...
180
181 C<\w> matches exactly what C<\p{Word}> matches.
182
183 =item otherwise ...
184
185 C<\w> matches [a-zA-Z0-9_].
186
187 =back
188
189 =back
190
191 =back
192
193 Which rules apply are determined as described in L<perlre/Which character set modifier is in effect?>.
194
195 There are a number of security issues with the full Unicode list of word
196 characters.  See L<http://unicode.org/reports/tr36>.
197
198 Also, for a somewhat finer-grained set of characters that are in programming
199 language identifiers beyond the ASCII range, you may wish to instead use the
200 more customized L</Unicode Properties>, C<\p{ID_Start}>,
201 C<\p{ID_Continue}>, C<\p{XID_Start}>, and C<\p{XID_Continue}>.  See
202 L<http://unicode.org/reports/tr31>.
203
204 Any character not matched by C<\w> is matched by C<\W>.
205
206 =head3 Whitespace
207
208 C<\s> matches any single character considered whitespace.
209
210 =over
211
212 =item If the C</a> modifier is in effect ...
213
214 In all Perl versions, C<\s> matches the 5 characters [\t\n\f\r ]; that
215 is, the horizontal tab,
216 the newline, the form feed, the carriage return, and the space.
217 Starting in Perl v5.18, it also matches the vertical tab, C<\cK>.
218 See note C<[1]> below for a discussion of this.
219
220 =item otherwise ...
221
222 =over
223
224 =item For code points above 255 ...
225
226 C<\s> matches exactly the code points above 255 shown with an "s" column
227 in the table below.
228
229 =item For code points below 256 ...
230
231 =over
232
233 =item if locale rules are in effect ...
234
235 C<\s> matches whatever the locale considers to be whitespace.
236
237 =item if Unicode rules are in effect ...
238
239 C<\s> matches exactly the characters shown with an "s" column in the
240 table below.
241
242 =item otherwise ...
243
244 C<\s> matches [\t\n\f\r ] and, starting in Perl
245 v5.18, the vertical tab, C<\cK>.
246 (See note C<[1]> below for a discussion of this.)
247 Note that this list doesn't include the non-breaking space.
248
249 =back
250
251 =back
252
253 =back
254
255 Which rules apply are determined as described in L<perlre/Which character set modifier is in effect?>.
256
257 Any character not matched by C<\s> is matched by C<\S>.
258
259 C<\h> matches any character considered horizontal whitespace;
260 this includes the platform's space and tab characters and several others
261 listed in the table below.  C<\H> matches any character
262 not considered horizontal whitespace.  They use the platform's native
263 character set, and do not consider any locale that may otherwise be in
264 use.
265
266 C<\v> matches any character considered vertical whitespace;
267 this includes the platform's carriage return and line feed characters (newline)
268 plus several other characters, all listed in the table below.
269 C<\V> matches any character not considered vertical whitespace.
270 They use the platform's native character set, and do not consider any
271 locale that may otherwise be in use.
272
273 C<\R> matches anything that can be considered a newline under Unicode
274 rules. It can match a multi-character sequence. It cannot be used inside
275 a bracketed character class; use C<\v> instead (vertical whitespace).
276 It uses the platform's
277 native character set, and does not consider any locale that may
278 otherwise be in use.
279 Details are discussed in L<perlrebackslash>.
280
281 Note that unlike C<\s> (and C<\d> and C<\w>), C<\h> and C<\v> always match
282 the same characters, without regard to other factors, such as the active
283 locale or whether the source string is in UTF-8 format.
284
285 One might think that C<\s> is equivalent to C<[\h\v]>. This is indeed true
286 starting in Perl v5.18, but prior to that, the sole difference was that the
287 vertical tab (C<"\cK">) was not matched by C<\s>.
288
289 The following table is a complete listing of characters matched by
290 C<\s>, C<\h> and C<\v> as of Unicode 6.3.
291
292 The first column gives the Unicode code point of the character (in hex format),
293 the second column gives the (Unicode) name. The third column indicates
294 by which class(es) the character is matched (assuming no locale is in
295 effect that changes the C<\s> matching).
296
297  0x0009        CHARACTER TABULATION   h s
298  0x000a              LINE FEED (LF)    vs
299  0x000b             LINE TABULATION    vs  [1]
300  0x000c              FORM FEED (FF)    vs
301  0x000d        CARRIAGE RETURN (CR)    vs
302  0x0020                       SPACE   h s
303  0x0085             NEXT LINE (NEL)    vs  [2]
304  0x00a0              NO-BREAK SPACE   h s  [2]
305  0x1680            OGHAM SPACE MARK   h s
306  0x2000                     EN QUAD   h s
307  0x2001                     EM QUAD   h s
308  0x2002                    EN SPACE   h s
309  0x2003                    EM SPACE   h s
310  0x2004          THREE-PER-EM SPACE   h s
311  0x2005           FOUR-PER-EM SPACE   h s
312  0x2006            SIX-PER-EM SPACE   h s
313  0x2007                FIGURE SPACE   h s
314  0x2008           PUNCTUATION SPACE   h s
315  0x2009                  THIN SPACE   h s
316  0x200a                  HAIR SPACE   h s
317  0x2028              LINE SEPARATOR    vs
318  0x2029         PARAGRAPH SEPARATOR    vs
319  0x202f       NARROW NO-BREAK SPACE   h s
320  0x205f   MEDIUM MATHEMATICAL SPACE   h s
321  0x3000           IDEOGRAPHIC SPACE   h s
322
323 =over 4
324
325 =item [1]
326
327 Prior to Perl v5.18, C<\s> did not match the vertical tab.
328 C<[^\S\cK]> (obscurely) matches what C<\s> traditionally did.
329
330 =item [2]
331
332 NEXT LINE and NO-BREAK SPACE may or may not match C<\s> depending
333 on the rules in effect.  See
334 L<the beginning of this section|/Whitespace>.
335
336 =back
337
338 =head3 Unicode Properties
339
340 C<\pP> and C<\p{Prop}> are character classes to match characters that fit given
341 Unicode properties.  One letter property names can be used in the C<\pP> form,
342 with the property name following the C<\p>, otherwise, braces are required.
343 When using braces, there is a single form, which is just the property name
344 enclosed in the braces, and a compound form which looks like C<\p{name=value}>,
345 which means to match if the property "name" for the character has that particular
346 "value".
347 For instance, a match for a number can be written as C</\pN/> or as
348 C</\p{Number}/>, or as C</\p{Number=True}/>.
349 Lowercase letters are matched by the property I<Lowercase_Letter> which
350 has the short form I<Ll>. They need the braces, so are written as C</\p{Ll}/> or
351 C</\p{Lowercase_Letter}/>, or C</\p{General_Category=Lowercase_Letter}/>
352 (the underscores are optional).
353 C</\pLl/> is valid, but means something different.
354 It matches a two character string: a letter (Unicode property C<\pL>),
355 followed by a lowercase C<l>.
356
357 If locale rules are not in effect, the use of
358 a Unicode property will force the regular expression into using Unicode
359 rules, if it isn't already.
360
361 Note that almost all properties are immune to case-insensitive matching.
362 That is, adding a C</i> regular expression modifier does not change what
363 they match.  There are two sets that are affected.  The first set is
364 C<Uppercase_Letter>,
365 C<Lowercase_Letter>,
366 and C<Titlecase_Letter>,
367 all of which match C<Cased_Letter> under C</i> matching.
368 The second set is
369 C<Uppercase>,
370 C<Lowercase>,
371 and C<Titlecase>,
372 all of which match C<Cased> under C</i> matching.
373 (The difference between these sets is that some things, such as Roman
374 numerals, come in both upper and lower case, so they are C<Cased>, but
375 aren't considered to be letters, so they aren't C<Cased_Letter>s. They're
376 actually C<Letter_Number>s.)
377 This set also includes its subsets C<PosixUpper> and C<PosixLower>, both
378 of which under C</i> match C<PosixAlpha>.
379
380 For more details on Unicode properties, see L<perlunicode/Unicode
381 Character Properties>; for a
382 complete list of possible properties, see
383 L<perluniprops/Properties accessible through \p{} and \P{}>,
384 which notes all forms that have C</i> differences.
385 It is also possible to define your own properties. This is discussed in
386 L<perlunicode/User-Defined Character Properties>.
387
388 Unicode properties are defined (surprise!) only on Unicode code points.
389 Starting in v5.20, when matching against C<\p> and C<\P>, Perl treats
390 non-Unicode code points (those above the legal Unicode maximum of
391 0x10FFFF) as if they were typical unassigned Unicode code points.
392
393 Prior to v5.20, Perl raised a warning and made all matches fail on
394 non-Unicode code points.  This could be somewhat surprising:
395
396  chr(0x110000) =~ \p{ASCII_Hex_Digit=True}     # Fails on Perls < v5.20.
397  chr(0x110000) =~ \p{ASCII_Hex_Digit=False}    # Also fails on Perls
398                                                # < v5.20
399
400 Even though these two matches might be thought of as complements, until
401 v5.20 they were so only on Unicode code points.
402
403 =head4 Examples
404
405  "a"  =~  /\w/      # Match, "a" is a 'word' character.
406  "7"  =~  /\w/      # Match, "7" is a 'word' character as well.
407  "a"  =~  /\d/      # No match, "a" isn't a digit.
408  "7"  =~  /\d/      # Match, "7" is a digit.
409  " "  =~  /\s/      # Match, a space is whitespace.
410  "a"  =~  /\D/      # Match, "a" is a non-digit.
411  "7"  =~  /\D/      # No match, "7" is not a non-digit.
412  " "  =~  /\S/      # No match, a space is not non-whitespace.
413
414  " "  =~  /\h/      # Match, space is horizontal whitespace.
415  " "  =~  /\v/      # No match, space is not vertical whitespace.
416  "\r" =~  /\v/      # Match, a return is vertical whitespace.
417
418  "a"  =~  /\pL/     # Match, "a" is a letter.
419  "a"  =~  /\p{Lu}/  # No match, /\p{Lu}/ matches upper case letters.
420
421  "\x{0e0b}" =~ /\p{Thai}/  # Match, \x{0e0b} is the character
422                            # 'THAI CHARACTER SO SO', and that's in
423                            # Thai Unicode class.
424  "a"  =~  /\P{Lao}/ # Match, as "a" is not a Laotian character.
425
426 It is worth emphasizing that C<\d>, C<\w>, etc, match single characters, not
427 complete numbers or words. To match a number (that consists of digits),
428 use C<\d+>; to match a word, use C<\w+>.  But be aware of the security
429 considerations in doing so, as mentioned above.
430
431 =head2 Bracketed Character Classes
432
433 The third form of character class you can use in Perl regular expressions
434 is the bracketed character class.  In its simplest form, it lists the characters
435 that may be matched, surrounded by square brackets, like this: C<[aeiou]>.
436 This matches one of C<a>, C<e>, C<i>, C<o> or C<u>.  Like the other
437 character classes, exactly one character is matched.* To match
438 a longer string consisting of characters mentioned in the character
439 class, follow the character class with a L<quantifier|perlre/Quantifiers>.  For
440 instance, C<[aeiou]+> matches one or more lowercase English vowels.
441
442 Repeating a character in a character class has no
443 effect; it's considered to be in the set only once.
444
445 Examples:
446
447  "e"  =~  /[aeiou]/        # Match, as "e" is listed in the class.
448  "p"  =~  /[aeiou]/        # No match, "p" is not listed in the class.
449  "ae" =~  /^[aeiou]$/      # No match, a character class only matches
450                            # a single character.
451  "ae" =~  /^[aeiou]+$/     # Match, due to the quantifier.
452
453  -------
454
455 * There are two exceptions to a bracketed character class matching a
456 single character only.  Each requires special handling by Perl to make
457 things work:
458
459 =over
460
461 =item *
462
463 When the class is to match caselessly under C</i> matching rules, and a
464 character that is explicitly mentioned inside the class matches a
465 multiple-character sequence caselessly under Unicode rules, the class
466 will also match that sequence.  For example, Unicode says that the
467 letter C<LATIN SMALL LETTER SHARP S> should match the sequence C<ss>
468 under C</i> rules.  Thus,
469
470  'ss' =~ /\A\N{LATIN SMALL LETTER SHARP S}\z/i             # Matches
471  'ss' =~ /\A[aeioust\N{LATIN SMALL LETTER SHARP S}]\z/i    # Matches
472
473 For this to happen, the class must not be inverted (see L</Negation>)
474 and the character must be explicitly specified, and not be part of a
475 multi-character range (not even as one of its endpoints).  (L</Character
476 Ranges> will be explained shortly.) Therefore,
477
478  'ss' =~ /\A[\0-\x{ff}]\z/ui       # Doesn't match
479  'ss' =~ /\A[\0-\N{LATIN SMALL LETTER SHARP S}]\z/ui   # No match
480  'ss' =~ /\A[\xDF-\xDF]\z/ui   # Matches on ASCII platforms, since
481                                # \xDF is LATIN SMALL LETTER SHARP S,
482                                # and the range is just a single
483                                # element
484
485 Note that it isn't a good idea to specify these types of ranges anyway.
486
487 =item *
488
489 Some names known to C<\N{...}> refer to a sequence of multiple characters,
490 instead of the usual single character.  When one of these is included in
491 the class, the entire sequence is matched.  For example,
492
493   "\N{TAMIL LETTER KA}\N{TAMIL VOWEL SIGN AU}"
494                               =~ / ^ [\N{TAMIL SYLLABLE KAU}]  $ /x;
495
496 matches, because C<\N{TAMIL SYLLABLE KAU}> is a named sequence
497 consisting of the two characters matched against.  Like the other
498 instance where a bracketed class can match multiple characters, and for
499 similar reasons, the class must not be inverted, and the named sequence
500 may not appear in a range, even one where it is both endpoints.  If
501 these happen, it is a fatal error if the character class is within an
502 extended L<C<(?[...])>|/Extended Bracketed Character Classes>
503 class; and only the first code point is used (with
504 a C<regexp>-type warning raised) otherwise.
505
506 =back
507
508 =head3 Special Characters Inside a Bracketed Character Class
509
510 Most characters that are meta characters in regular expressions (that
511 is, characters that carry a special meaning like C<.>, C<*>, or C<(>) lose
512 their special meaning and can be used inside a character class without
513 the need to escape them. For instance, C<[()]> matches either an opening
514 parenthesis, or a closing parenthesis, and the parens inside the character
515 class don't group or capture.  Be aware that, unless the pattern is
516 evaluated in single-quotish context, variable interpolation will take
517 place before the bracketed class is parsed:
518
519  $, = "\t| ";
520  $a =~ m'[$,]';        # single-quotish: matches '$' or ','
521  $a =~ q{[$,]}'        # same
522  $a =~ m/[$,]/;        # double-quotish: matches "\t", "|", or " "
523
524 Characters that may carry a special meaning inside a character class are:
525 C<\>, C<^>, C<->, C<[> and C<]>, and are discussed below. They can be
526 escaped with a backslash, although this is sometimes not needed, in which
527 case the backslash may be omitted.
528
529 The sequence C<\b> is special inside a bracketed character class. While
530 outside the character class, C<\b> is an assertion indicating a point
531 that does not have either two word characters or two non-word characters
532 on either side, inside a bracketed character class, C<\b> matches a
533 backspace character.
534
535 The sequences
536 C<\a>,
537 C<\c>,
538 C<\e>,
539 C<\f>,
540 C<\n>,
541 C<\N{I<NAME>}>,
542 C<\N{U+I<hex char>}>,
543 C<\r>,
544 C<\t>,
545 and
546 C<\x>
547 are also special and have the same meanings as they do outside a
548 bracketed character class.
549
550 Also, a backslash followed by two or three octal digits is considered an octal
551 number.
552
553 A C<[> is not special inside a character class, unless it's the start of a
554 POSIX character class (see L</POSIX Character Classes> below). It normally does
555 not need escaping.
556
557 A C<]> is normally either the end of a POSIX character class (see
558 L</POSIX Character Classes> below), or it signals the end of the bracketed
559 character class.  If you want to include a C<]> in the set of characters, you
560 must generally escape it.
561
562 However, if the C<]> is the I<first> (or the second if the first
563 character is a caret) character of a bracketed character class, it
564 does not denote the end of the class (as you cannot have an empty class)
565 and is considered part of the set of characters that can be matched without
566 escaping.
567
568 Examples:
569
570  "+"   =~ /[+?*]/     #  Match, "+" in a character class is not special.
571  "\cH" =~ /[\b]/      #  Match, \b inside in a character class
572                       #  is equivalent to a backspace.
573  "]"   =~ /[][]/      #  Match, as the character class contains
574                       #  both [ and ].
575  "[]"  =~ /[[]]/      #  Match, the pattern contains a character class
576                       #  containing just [, and the character class is
577                       #  followed by a ].
578
579 =head3 Bracketed Character Classes and the C</xx> pattern modifier
580
581 Normally SPACE and TAB characters have no special meaning inside a
582 bracketed character class; they are just added to the list of characters
583 matched by the class.  But if the L<C</xx>|perlre/E<sol>x and E<sol>xx>
584 pattern modifier is in effect, they are generally ignored and can be
585 added to improve readability.  They can't be added in the middle of a
586 single construct:
587
588  / [ \x{10 FFFF} ] /xx  # WRONG!
589
590 The SPACE in the middle of the hex constant is illegal.
591
592 To specify a literal SPACE character, you can escape it with a
593 backslash, like:
594
595  /[ a e i o u \  ]/xx
596
597 This matches the English vowels plus the SPACE character.
598
599 For clarity, you should already have been using C<\t> to specify a
600 literal tab, and C<\t> is unaffected by C</xx>.
601
602 =head3 Character Ranges
603
604 It is not uncommon to want to match a range of characters. Luckily, instead
605 of listing all characters in the range, one may use the hyphen (C<->).
606 If inside a bracketed character class you have two characters separated
607 by a hyphen, it's treated as if all characters between the two were in
608 the class. For instance, C<[0-9]> matches any ASCII digit, and C<[a-m]>
609 matches any lowercase letter from the first half of the ASCII alphabet.
610
611 Note that the two characters on either side of the hyphen are not
612 necessarily both letters or both digits. Any character is possible,
613 although not advisable.  C<['-?]> contains a range of characters, but
614 most people will not know which characters that means.  Furthermore,
615 such ranges may lead to portability problems if the code has to run on
616 a platform that uses a different character set, such as EBCDIC.
617
618 If a hyphen in a character class cannot syntactically be part of a range, for
619 instance because it is the first or the last character of the character class,
620 or if it immediately follows a range, the hyphen isn't special, and so is
621 considered a character to be matched literally.  If you want a hyphen in
622 your set of characters to be matched and its position in the class is such
623 that it could be considered part of a range, you must escape that hyphen
624 with a backslash.
625
626 Examples:
627
628  [a-z]       #  Matches a character that is a lower case ASCII letter.
629  [a-fz]      #  Matches any letter between 'a' and 'f' (inclusive) or
630              #  the letter 'z'.
631  [-z]        #  Matches either a hyphen ('-') or the letter 'z'.
632  [a-f-m]     #  Matches any letter between 'a' and 'f' (inclusive), the
633              #  hyphen ('-'), or the letter 'm'.
634  ['-?]       #  Matches any of the characters  '()*+,-./0123456789:;<=>?
635              #  (But not on an EBCDIC platform).
636  [\N{APOSTROPHE}-\N{QUESTION MARK}]
637              #  Matches any of the characters  '()*+,-./0123456789:;<=>?
638              #  even on an EBCDIC platform.
639  [\N{U+27}-\N{U+3F}] # Same. (U+27 is "'", and U+3F is "?")
640
641 As the final two examples above show, you can achieve portablity to
642 non-ASCII platforms by using the C<\N{...}> form for the range
643 endpoints.  These indicate that the specified range is to be interpreted
644 using Unicode values, so C<[\N{U+27}-\N{U+3F}]> means to match
645 C<\N{U+27}>, C<\N{U+28}>, C<\N{U+29}>, ..., C<\N{U+3D}>, C<\N{U+3E}>,
646 and C<\N{U+3F}>, whatever the native code point versions for those are.
647 These are called "Unicode" ranges.  If either end is of the C<\N{...}>
648 form, the range is considered Unicode.  A C<regexp> warning is raised
649 under C<S<"use re 'strict'">> if the other endpoint is specified
650 non-portably:
651
652  [\N{U+00}-\x09]    # Warning under re 'strict'; \x09 is non-portable
653  [\N{U+00}-\t]      # No warning;
654
655 Both of the above match the characters C<\N{U+00}> C<\N{U+01}>, ...
656 C<\N{U+08}>, C<\N{U+09}>, but the C<\x09> looks like it could be a
657 mistake so the warning is raised (under C<re 'strict'>) for it.
658
659 Perl also guarantees that the ranges C<A-Z>, C<a-z>, C<0-9>, and any
660 subranges of these match what an English-only speaker would expect them
661 to match on any platform.  That is, C<[A-Z]> matches the 26 ASCII
662 uppercase letters;
663 C<[a-z]> matches the 26 lowercase letters; and C<[0-9]> matches the 10
664 digits.  Subranges, like C<[h-k]>, match correspondingly, in this case
665 just the four letters C<"h">, C<"i">, C<"j">, and C<"k">.  This is the
666 natural behavior on ASCII platforms where the code points (ordinal
667 values) for C<"h"> through C<"k"> are consecutive integers (0x68 through
668 0x6B).  But special handling to achieve this may be needed on platforms
669 with a non-ASCII native character set.  For example, on EBCDIC
670 platforms, the code point for C<"h"> is 0x88, C<"i"> is 0x89, C<"j"> is
671 0x91, and C<"k"> is 0x92.   Perl specially treats C<[h-k]> to exclude the
672 seven code points in the gap: 0x8A through 0x90.  This special handling is
673 only invoked when the range is a subrange of one of the ASCII uppercase,
674 lowercase, and digit ranges, AND each end of the range is expressed
675 either as a literal, like C<"A">, or as a named character (C<\N{...}>,
676 including the C<\N{U+...> form).
677
678 EBCDIC Examples:
679
680  [i-j]               #  Matches either "i" or "j"
681  [i-\N{LATIN SMALL LETTER J}]  # Same
682  [i-\N{U+6A}]        #  Same
683  [\N{U+69}-\N{U+6A}] #  Same
684  [\x{89}-\x{91}]     #  Matches 0x89 ("i"), 0x8A .. 0x90, 0x91 ("j")
685  [i-\x{91}]          #  Same
686  [\x{89}-j]          #  Same
687  [i-J]               #  Matches, 0x89 ("i") .. 0xC1 ("J"); special
688                      #  handling doesn't apply because range is mixed
689                      #  case
690
691 =head3 Negation
692
693 It is also possible to instead list the characters you do not want to
694 match. You can do so by using a caret (C<^>) as the first character in the
695 character class. For instance, C<[^a-z]> matches any character that is not a
696 lowercase ASCII letter, which therefore includes more than a million
697 Unicode code points.  The class is said to be "negated" or "inverted".
698
699 This syntax make the caret a special character inside a bracketed character
700 class, but only if it is the first character of the class. So if you want
701 the caret as one of the characters to match, either escape the caret or
702 else don't list it first.
703
704 In inverted bracketed character classes, Perl ignores the Unicode rules
705 that normally say that named sequence, and certain characters should
706 match a sequence of multiple characters use under caseless C</i>
707 matching.  Following those rules could lead to highly confusing
708 situations:
709
710  "ss" =~ /^[^\xDF]+$/ui;   # Matches!
711
712 This should match any sequences of characters that aren't C<\xDF> nor
713 what C<\xDF> matches under C</i>.  C<"s"> isn't C<\xDF>, but Unicode
714 says that C<"ss"> is what C<\xDF> matches under C</i>.  So which one
715 "wins"? Do you fail the match because the string has C<ss> or accept it
716 because it has an C<s> followed by another C<s>?  Perl has chosen the
717 latter.  (See note in L</Bracketed Character Classes> above.)
718
719 Examples:
720
721  "e"  =~  /[^aeiou]/   #  No match, the 'e' is listed.
722  "x"  =~  /[^aeiou]/   #  Match, as 'x' isn't a lowercase vowel.
723  "^"  =~  /[^^]/       #  No match, matches anything that isn't a caret.
724  "^"  =~  /[x^]/       #  Match, caret is not special here.
725
726 =head3 Backslash Sequences
727
728 You can put any backslash sequence character class (with the exception of
729 C<\N> and C<\R>) inside a bracketed character class, and it will act just
730 as if you had put all characters matched by the backslash sequence inside the
731 character class. For instance, C<[a-f\d]> matches any decimal digit, or any
732 of the lowercase letters between 'a' and 'f' inclusive.
733
734 C<\N> within a bracketed character class must be of the forms C<\N{I<name>}>
735 or C<\N{U+I<hex char>}>, and NOT be the form that matches non-newlines,
736 for the same reason that a dot C<.> inside a bracketed character class loses
737 its special meaning: it matches nearly anything, which generally isn't what you
738 want to happen.
739
740
741 Examples:
742
743  /[\p{Thai}\d]/     # Matches a character that is either a Thai
744                     # character, or a digit.
745  /[^\p{Arabic}()]/  # Matches a character that is neither an Arabic
746                     # character, nor a parenthesis.
747
748 Backslash sequence character classes cannot form one of the endpoints
749 of a range.  Thus, you can't say:
750
751  /[\p{Thai}-\d]/     # Wrong!
752
753 =head3 POSIX Character Classes
754 X<character class> X<\p> X<\p{}>
755 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
756 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
757
758 POSIX character classes have the form C<[:class:]>, where I<class> is the
759 name, and the C<[:> and C<:]> delimiters. POSIX character classes only appear
760 I<inside> bracketed character classes, and are a convenient and descriptive
761 way of listing a group of characters.
762
763 Be careful about the syntax,
764
765  # Correct:
766  $string =~ /[[:alpha:]]/
767
768  # Incorrect (will warn):
769  $string =~ /[:alpha:]/
770
771 The latter pattern would be a character class consisting of a colon,
772 and the letters C<a>, C<l>, C<p> and C<h>.
773
774 POSIX character classes can be part of a larger bracketed character class.
775 For example,
776
777  [01[:alpha:]%]
778
779 is valid and matches '0', '1', any alphabetic character, and the percent sign.
780
781 Perl recognizes the following POSIX character classes:
782
783  alpha  Any alphabetical character ("[A-Za-z]").
784  alnum  Any alphanumeric character ("[A-Za-z0-9]").
785  ascii  Any character in the ASCII character set.
786  blank  A GNU extension, equal to a space or a horizontal tab ("\t").
787  cntrl  Any control character.  See Note [2] below.
788  digit  Any decimal digit ("[0-9]"), equivalent to "\d".
789  graph  Any printable character, excluding a space.  See Note [3] below.
790  lower  Any lowercase character ("[a-z]").
791  print  Any printable character, including a space.  See Note [4] below.
792  punct  Any graphical character excluding "word" characters.  Note [5].
793  space  Any whitespace character. "\s" including the vertical tab
794         ("\cK").
795  upper  Any uppercase character ("[A-Z]").
796  word   A Perl extension ("[A-Za-z0-9_]"), equivalent to "\w".
797  xdigit Any hexadecimal digit ("[0-9a-fA-F]").
798
799 Like the L<Unicode properties|/Unicode Properties>, most of the POSIX
800 properties match the same regardless of whether case-insensitive (C</i>)
801 matching is in effect or not.  The two exceptions are C<[:upper:]> and
802 C<[:lower:]>.  Under C</i>, they each match the union of C<[:upper:]> and
803 C<[:lower:]>.
804
805 Most POSIX character classes have two Unicode-style C<\p> property
806 counterparts.  (They are not official Unicode properties, but Perl extensions
807 derived from official Unicode properties.)  The table below shows the relation
808 between POSIX character classes and these counterparts.
809
810 One counterpart, in the column labelled "ASCII-range Unicode" in
811 the table, matches only characters in the ASCII character set.
812
813 The other counterpart, in the column labelled "Full-range Unicode", matches any
814 appropriate characters in the full Unicode character set.  For example,
815 C<\p{Alpha}> matches not just the ASCII alphabetic characters, but any
816 character in the entire Unicode character set considered alphabetic.
817 An entry in the column labelled "backslash sequence" is a (short)
818 equivalent.
819
820  [[:...:]]      ASCII-range          Full-range  backslash  Note
821                  Unicode              Unicode     sequence
822  -----------------------------------------------------
823    alpha      \p{PosixAlpha}       \p{XPosixAlpha}
824    alnum      \p{PosixAlnum}       \p{XPosixAlnum}
825    ascii      \p{ASCII}
826    blank      \p{PosixBlank}       \p{XPosixBlank}  \h      [1]
827                                    or \p{HorizSpace}        [1]
828    cntrl      \p{PosixCntrl}       \p{XPosixCntrl}          [2]
829    digit      \p{PosixDigit}       \p{XPosixDigit}  \d
830    graph      \p{PosixGraph}       \p{XPosixGraph}          [3]
831    lower      \p{PosixLower}       \p{XPosixLower}
832    print      \p{PosixPrint}       \p{XPosixPrint}          [4]
833    punct      \p{PosixPunct}       \p{XPosixPunct}          [5]
834               \p{PerlSpace}        \p{XPerlSpace}   \s      [6]
835    space      \p{PosixSpace}       \p{XPosixSpace}          [6]
836    upper      \p{PosixUpper}       \p{XPosixUpper}
837    word       \p{PosixWord}        \p{XPosixWord}   \w
838    xdigit     \p{PosixXDigit}      \p{XPosixXDigit}
839
840 =over 4
841
842 =item [1]
843
844 C<\p{Blank}> and C<\p{HorizSpace}> are synonyms.
845
846 =item [2]
847
848 Control characters don't produce output as such, but instead usually control
849 the terminal somehow: for example, newline and backspace are control characters.
850 On ASCII platforms, in the ASCII range, characters whose code points are
851 between 0 and 31 inclusive, plus 127 (C<DEL>) are control characters; on
852 EBCDIC platforms, their counterparts are control characters.
853
854 =item [3]
855
856 Any character that is I<graphical>, that is, visible. This class consists
857 of all alphanumeric characters and all punctuation characters.
858
859 =item [4]
860
861 All printable characters, which is the set of all graphical characters
862 plus those whitespace characters which are not also controls.
863
864 =item [5]
865
866 C<\p{PosixPunct}> and C<[[:punct:]]> in the ASCII range match all
867 non-controls, non-alphanumeric, non-space characters:
868 C<[-!"#$%&'()*+,./:;<=E<gt>?@[\\\]^_`{|}~]> (although if a locale is in effect,
869 it could alter the behavior of C<[[:punct:]]>).
870
871 The similarly named property, C<\p{Punct}>, matches a somewhat different
872 set in the ASCII range, namely
873 C<[-!"#%&'()*,./:;?@[\\\]_{}]>.  That is, it is missing the nine
874 characters C<[$+E<lt>=E<gt>^`|~]>.
875 This is because Unicode splits what POSIX considers to be punctuation into two
876 categories, Punctuation and Symbols.
877
878 C<\p{XPosixPunct}> and (under Unicode rules) C<[[:punct:]]>, match what
879 C<\p{PosixPunct}> matches in the ASCII range, plus what C<\p{Punct}>
880 matches.  This is different than strictly matching according to
881 C<\p{Punct}>.  Another way to say it is that
882 if Unicode rules are in effect, C<[[:punct:]]> matches all characters
883 that Unicode considers punctuation, plus all ASCII-range characters that
884 Unicode considers symbols.
885
886 =item [6]
887
888 C<\p{XPerlSpace}> and C<\p{Space}> match identically starting with Perl
889 v5.18.  In earlier versions, these differ only in that in non-locale
890 matching, C<\p{XPerlSpace}> did not match the vertical tab, C<\cK>.
891 Same for the two ASCII-only range forms.
892
893 =back
894
895 There are various other synonyms that can be used besides the names
896 listed in the table.  For example, C<\p{XPosixAlpha}> can be written as
897 C<\p{Alpha}>.  All are listed in
898 L<perluniprops/Properties accessible through \p{} and \P{}>.
899
900 Both the C<\p> counterparts always assume Unicode rules are in effect.
901 On ASCII platforms, this means they assume that the code points from 128
902 to 255 are Latin-1, and that means that using them under locale rules is
903 unwise unless the locale is guaranteed to be Latin-1 or UTF-8.  In contrast, the
904 POSIX character classes are useful under locale rules.  They are
905 affected by the actual rules in effect, as follows:
906
907 =over
908
909 =item If the C</a> modifier, is in effect ...
910
911 Each of the POSIX classes matches exactly the same as their ASCII-range
912 counterparts.
913
914 =item otherwise ...
915
916 =over
917
918 =item For code points above 255 ...
919
920 The POSIX class matches the same as its Full-range counterpart.
921
922 =item For code points below 256 ...
923
924 =over
925
926 =item if locale rules are in effect ...
927
928 The POSIX class matches according to the locale, except:
929
930 =over
931
932 =item C<word>
933
934 also includes the platform's native underscore character, no matter what
935 the locale is.
936
937 =item C<ascii>
938
939 on platforms that don't have the POSIX C<ascii> extension, this matches
940 just the platform's native ASCII-range characters.
941
942 =item C<blank>
943
944 on platforms that don't have the POSIX C<blank> extension, this matches
945 just the platform's native tab and space characters.
946
947 =back
948
949 =item if Unicode rules are in effect ...
950
951 The POSIX class matches the same as the Full-range counterpart.
952
953 =item otherwise ...
954
955 The POSIX class matches the same as the ASCII range counterpart.
956
957 =back
958
959 =back
960
961 =back
962
963 Which rules apply are determined as described in
964 L<perlre/Which character set modifier is in effect?>.
965
966 It is proposed to change this behavior in a future release of Perl so that
967 whether or not Unicode rules are in effect would not change the
968 behavior:  Outside of locale, the POSIX classes
969 would behave like their ASCII-range counterparts.  If you wish to
970 comment on this proposal, send email to C<perl5-porters@perl.org>.
971
972 =head4 Negation of POSIX character classes
973 X<character class, negation>
974
975 A Perl extension to the POSIX character class is the ability to
976 negate it. This is done by prefixing the class name with a caret (C<^>).
977 Some examples:
978
979      POSIX         ASCII-range     Full-range  backslash
980                     Unicode         Unicode    sequence
981  -----------------------------------------------------
982  [[:^digit:]]   \P{PosixDigit}  \P{XPosixDigit}   \D
983  [[:^space:]]   \P{PosixSpace}  \P{XPosixSpace}
984                 \P{PerlSpace}   \P{XPerlSpace}    \S
985  [[:^word:]]    \P{PerlWord}    \P{XPosixWord}    \W
986
987 The backslash sequence can mean either ASCII- or Full-range Unicode,
988 depending on various factors as described in L<perlre/Which character set modifier is in effect?>.
989
990 =head4 [= =] and [. .]
991
992 Perl recognizes the POSIX character classes C<[=class=]> and
993 C<[.class.]>, but does not (yet?) support them.  Any attempt to use
994 either construct raises an exception.
995
996 =head4 Examples
997
998  /[[:digit:]]/            # Matches a character that is a digit.
999  /[01[:lower:]]/          # Matches a character that is either a
1000                           # lowercase letter, or '0' or '1'.
1001  /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
1002                           # except the letters 'a' to 'f' and 'A' to
1003                           # 'F'.  This is because the main character
1004                           # class is composed of two POSIX character
1005                           # classes that are ORed together, one that
1006                           # matches any digit, and the other that
1007                           # matches anything that isn't a hex digit.
1008                           # The OR adds the digits, leaving only the
1009                           # letters 'a' to 'f' and 'A' to 'F' excluded.
1010
1011 =head3 Extended Bracketed Character Classes
1012 X<character class>
1013 X<set operations>
1014
1015 This is a fancy bracketed character class that can be used for more
1016 readable and less error-prone classes, and to perform set operations,
1017 such as intersection. An example is
1018
1019  /(?[ \p{Thai} & \p{Digit} ])/
1020
1021 This will match all the digit characters that are in the Thai script.
1022
1023 This is an experimental feature available starting in 5.18, and is
1024 subject to change as we gain field experience with it.  Any attempt to
1025 use it will raise a warning, unless disabled via
1026
1027  no warnings "experimental::regex_sets";
1028
1029 Comments on this feature are welcome; send email to
1030 C<perl5-porters@perl.org>.
1031
1032 The rules used by L<C<use re 'strict>|re/'strict' mode> apply to this
1033 construct.
1034
1035 We can extend the example above:
1036
1037  /(?[ ( \p{Thai} + \p{Lao} ) & \p{Digit} ])/
1038
1039 This matches digits that are in either the Thai or Laotian scripts.
1040
1041 Notice the white space in these examples.  This construct always has
1042 the C<E<sol>xx> modifier turned on within it.
1043
1044 The available binary operators are:
1045
1046  &    intersection
1047  +    union
1048  |    another name for '+', hence means union
1049  -    subtraction (the result matches the set consisting of those
1050       code points matched by the first operand, excluding any that
1051       are also matched by the second operand)
1052  ^    symmetric difference (the union minus the intersection).  This
1053       is like an exclusive or, in that the result is the set of code
1054       points that are matched by either, but not both, of the
1055       operands.
1056
1057 There is one unary operator:
1058
1059  !    complement
1060
1061 All the binary operators left associate; C<"&"> is higher precedence
1062 than the others, which all have equal precedence.  The unary operator
1063 right associates, and has highest precedence.  Thus this follows the
1064 normal Perl precedence rules for logical operators.  Use parentheses to
1065 override the default precedence and associativity.
1066
1067 The main restriction is that everything is a metacharacter.  Thus,
1068 you cannot refer to single characters by doing something like this:
1069
1070  /(?[ a + b ])/ # Syntax error!
1071
1072 The easiest way to specify an individual typable character is to enclose
1073 it in brackets:
1074
1075  /(?[ [a] + [b] ])/
1076
1077 (This is the same thing as C<[ab]>.)  You could also have said the
1078 equivalent:
1079
1080  /(?[[ a b ]])/
1081
1082 (You can, of course, specify single characters by using, C<\x{...}>,
1083 C<\N{...}>, etc.)
1084
1085 This last example shows the use of this construct to specify an ordinary
1086 bracketed character class without additional set operations.  Note the
1087 white space within it.  This is allowed because C<E<sol>xx> is
1088 automatically turned on within this construct.
1089
1090 All the other escapes accepted by normal bracketed character classes are
1091 accepted here as well.
1092
1093 Because this construct compiles under
1094 L<C<use re 'strict>|re/'strict' mode>,  unrecognized escapes that
1095 generate warnings in normal classes are fatal errors here, as well as
1096 all other warnings from these class elements, as well as some
1097 practices that don't currently warn outside C<re 'strict'>.  For example
1098 you cannot say
1099
1100  /(?[ [ \xF ] ])/     # Syntax error!
1101
1102 You have to have two hex digits after a braceless C<\x> (use a leading
1103 zero to make two).  These restrictions are to lower the incidence of
1104 typos causing the class to not match what you thought it would.
1105
1106 If a regular bracketed character class contains a C<\p{}> or C<\P{}> and
1107 is matched against a non-Unicode code point, a warning may be
1108 raised, as the result is not Unicode-defined.  No such warning will come
1109 when using this extended form.
1110
1111 The final difference between regular bracketed character classes and
1112 these, is that it is not possible to get these to match a
1113 multi-character fold.  Thus,
1114
1115  /(?[ [\xDF] ])/iu
1116
1117 does not match the string C<ss>.
1118
1119 You don't have to enclose POSIX class names inside double brackets,
1120 hence both of the following work:
1121
1122  /(?[ [:word:] - [:lower:] ])/
1123  /(?[ [[:word:]] - [[:lower:]] ])/
1124
1125 Any contained POSIX character classes, including things like C<\w> and C<\D>
1126 respect the C<E<sol>a> (and C<E<sol>aa>) modifiers.
1127
1128 C<< (?[ ]) >> is a regex-compile-time construct.  Any attempt to use
1129 something which isn't knowable at the time the containing regular
1130 expression is compiled is a fatal error.  In practice, this means
1131 just three limitations:
1132
1133 =over 4
1134
1135 =item 1
1136
1137 When compiled within the scope of C<use locale> (or the C<E<sol>l> regex
1138 modifier), this construct assumes that the execution-time locale will be
1139 a UTF-8 one, and the generated pattern always uses Unicode rules.  What
1140 gets matched or not thus isn't dependent on the actual runtime locale, so
1141 tainting is not enabled.  But a C<locale> category warning is raised
1142 if the runtime locale turns out to not be UTF-8.
1143
1144 =item 2
1145
1146 Any
1147 L<user-defined property|perlunicode/"User-Defined Character Properties">
1148 used must be already defined by the time the regular expression is
1149 compiled (but note that this construct can be used instead of such
1150 properties).
1151
1152 =item 3
1153
1154 A regular expression that otherwise would compile
1155 using C<E<sol>d> rules, and which uses this construct will instead
1156 use C<E<sol>u>.  Thus this construct tells Perl that you don't want
1157 C<E<sol>d> rules for the entire regular expression containing it.
1158
1159 =back
1160
1161 Note that skipping white space applies only to the interior of this
1162 construct.  There must not be any space between any of the characters
1163 that form the initial C<(?[>.  Nor may there be space between the
1164 closing C<])> characters.
1165
1166 Just as in all regular expressions, the pattern can be built up by
1167 including variables that are interpolated at regex compilation time.
1168 Care must be taken to ensure that you are getting what you expect.  For
1169 example:
1170
1171  my $thai_or_lao = '\p{Thai} + \p{Lao}';
1172  ...
1173  qr/(?[ \p{Digit} & $thai_or_lao ])/;
1174
1175 compiles to
1176
1177  qr/(?[ \p{Digit} & \p{Thai} + \p{Lao} ])/;
1178
1179 But this does not have the effect that someone reading the code would
1180 likely expect, as the intersection applies just to C<\p{Thai}>,
1181 excluding the Laotian.  Pitfalls like this can be avoided by
1182 parenthesizing the component pieces:
1183
1184  my $thai_or_lao = '( \p{Thai} + \p{Lao} )';
1185
1186 But any modifiers will still apply to all the components:
1187
1188  my $lower = '\p{Lower} + \p{Digit}';
1189  qr/(?[ \p{Greek} & $lower ])/i;
1190
1191 matches upper case things.  You can avoid surprises by making the
1192 components into instances of this construct by compiling them:
1193
1194  my $thai_or_lao = qr/(?[ \p{Thai} + \p{Lao} ])/;
1195  my $lower = qr/(?[ \p{Lower} + \p{Digit} ])/;
1196
1197 When these are embedded in another pattern, what they match does not
1198 change, regardless of parenthesization or what modifiers are in effect
1199 in that outer pattern.
1200
1201 Due to the way that Perl parses things, your parentheses and brackets
1202 may need to be balanced, even including comments.  If you run into any
1203 examples, please send them to C<perlbug@perl.org>, so that we can have a
1204 concrete example for this man page.
1205
1206 We may change it so that things that remain legal uses in normal bracketed
1207 character classes might become illegal within this experimental
1208 construct.  One proposal, for example, is to forbid adjacent uses of the
1209 same character, as in C<(?[ [aa] ])>.  The motivation for such a change
1210 is that this usage is likely a typo, as the second "a" adds nothing.