This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Tidy t/io/layers.t
[perl5.git] / t / io / layers.t
1 #!./perl
2
3 my $PERLIO;
4
5 BEGIN {
6     chdir 't' if -d 't';
7     @INC = '../lib';
8     require './test.pl';
9     skip_all('not perlio') unless (find PerlIO::Layer 'perlio');
10     # FIXME - more of these could be tested without Encode or full perl
11     skip_all_if_miniperl("no dynamic loading on miniperl, no Encode");
12     require Config; Config->import;
13     skip_all('Encode was not built')
14         unless ($Config::Config{extensions} =~ /\bEncode\b/);
15
16     # Makes testing easier.
17     $ENV{PERLIO} = 'stdio' if exists $ENV{PERLIO} && $ENV{PERLIO} eq '';
18     if (exists $ENV{PERLIO} && $ENV{PERLIO} !~ /^(stdio|perlio|mmap)$/) {
19         # We are not prepared for anything else.
20         print "1..0 # PERLIO='$ENV{PERLIO}' unknown\n";
21         exit 0;
22     }
23     $PERLIO = exists $ENV{PERLIO} ? $ENV{PERLIO} : "(undef)";
24 }
25
26
27 my $DOSISH    = $^O =~ /^(?:MSWin32|os2|dos|NetWare)$/ ? 1 : 0;
28    $DOSISH    = 1 if !$DOSISH and $^O =~ /^uwin/;
29 my $NONSTDIO  = exists $ENV{PERLIO} && $ENV{PERLIO} ne 'stdio'     ? 1 : 0;
30 my $FASTSTDIO = $Config{d_faststdio} && $Config{usefaststdio}      ? 1 : 0;
31 my $UTF8_STDIN;
32 if (${^UNICODE} & 1) {
33     if (${^UNICODE} & 64) {
34         # Conditional on the locale
35         $UTF8_STDIN = ${^UTF8LOCALE};
36     } else {
37         # Unconditional
38         $UTF8_STDIN = 1;
39     }
40 } else {
41     $UTF8_STDIN = 0;
42 }
43 my $NTEST = 55 - (($DOSISH || !$FASTSTDIO) ? 7 : 0) - ($DOSISH ? 7 : 0)
44     + $UTF8_STDIN;
45
46 sub PerlIO::F_UTF8 () { 0x00008000 } # from perliol.h
47
48 plan tests => $NTEST;
49
50 print <<__EOH__;
51 # PERLIO        = $PERLIO
52 # DOSISH        = $DOSISH
53 # NONSTDIO      = $NONSTDIO
54 # FASTSTDIO     = $FASTSTDIO
55 # UNICODE       = ${^UNICODE}
56 # UTF8LOCALE    = ${^UTF8LOCALE}
57 # UTF8_STDIN = $UTF8_STDIN
58 __EOH__
59
60 {
61     sub check {
62         my ($result, $expected, $id) = @_;
63         # An interesting dance follows where we try to make the following
64         # IO layer stack setups to compare equal:
65         #
66         # PERLIO     UNIX-like                   DOS-like
67         #
68         # unset / "" unix perlio / stdio [1]     unix crlf
69         # stdio      unix perlio / stdio [1]     stdio
70         # perlio     unix perlio                 unix perlio
71         # mmap       unix mmap                   unix mmap
72         #
73         # [1] "stdio" if Configure found out how to do "fast stdio" (depends
74         # on the stdio implementation) and in Perl 5.8, otherwise "unix perlio"
75         #
76         if ($NONSTDIO) {
77             # Get rid of "unix".
78             shift @$result if $result->[0] eq "unix";
79             # Change expectations.
80             if ($FASTSTDIO) {
81                 $expected->[0] = $ENV{PERLIO};
82             } else {
83                 $expected->[0] = $ENV{PERLIO} if $expected->[0] eq "stdio";
84             }
85         } elsif (!$FASTSTDIO && !$DOSISH) {
86             splice(@$result, 0, 2, "stdio")
87                 if @$result >= 2 &&
88                    $result->[0] eq "unix" &&
89                    $result->[1] eq "perlio";
90         } elsif ($DOSISH) {
91             splice(@$result, 0, 2, "stdio")
92                 if @$result >= 2 &&
93                    $result->[0] eq "unix" &&
94                    $result->[1] eq "crlf";
95         }
96         if ($DOSISH && grep { $_ eq 'crlf' } @$expected) {
97             # 5 tests potentially skipped because
98             # DOSISH systems already have a CRLF layer
99             # which will make new ones not stick.
100             splice @$expected, 1, 1 if $expected->[1] eq 'crlf';
101         }
102         my $n = scalar @$expected;
103         is(scalar @$result, $n, "$id - layers == $n");
104         for (my $i = 0; $i < $n; $i++) {
105             my $j = $expected->[$i];
106             if (ref $j eq 'CODE') {
107                 ok($j->($result->[$i]), "$id - $i is ok");
108             } else {
109                 is($result->[$i], $j,
110                    sprintf("$id - $i is %s",
111                            defined $j ? $j : "undef"));
112             }
113         }
114     }
115
116     check([ PerlIO::get_layers(STDIN) ],
117           $UTF8_STDIN ? [ "stdio", "utf8" ] : [ "stdio" ],
118           "STDIN");
119
120     my $afile = tempfile();
121     open(F, ">:crlf", $afile);
122
123     check([ PerlIO::get_layers(F) ],
124           [ qw(stdio crlf) ],
125           "open :crlf");
126
127     binmode(F, ":crlf");
128
129     check([ PerlIO::get_layers(F) ],
130           [ qw(stdio crlf) ],
131           "binmode :crlf");
132
133     binmode(F, ":encoding(cp1047)"); 
134
135     check([ PerlIO::get_layers(F) ],
136           [ qw[stdio crlf encoding(cp1047) utf8] ],
137           ":encoding(cp1047)");
138
139     binmode(F, ":crlf");
140
141     check([ PerlIO::get_layers(F) ],
142           [ qw[stdio crlf encoding(cp1047) utf8 crlf utf8] ],
143           ":encoding(cp1047):crlf");
144     
145     binmode(F, ":pop:pop");
146
147     check([ PerlIO::get_layers(F) ],
148           [ qw(stdio crlf) ],
149           ":pop");
150
151     binmode(F, ":raw");
152
153     check([ PerlIO::get_layers(F) ],
154           [ "stdio" ],
155           ":raw");
156
157     binmode(F, ":utf8");
158
159     check([ PerlIO::get_layers(F) ],
160           [ qw(stdio utf8) ],
161           ":utf8");
162
163     binmode(F, ":bytes");
164
165     check([ PerlIO::get_layers(F) ],
166           [ "stdio" ],
167           ":bytes");
168
169     binmode(F, ":encoding(utf8)");
170
171     check([ PerlIO::get_layers(F) ],
172             [ qw[stdio encoding(utf8) utf8] ],
173             ":encoding(utf8)");
174
175     binmode(F, ":raw :crlf");
176
177     check([ PerlIO::get_layers(F) ],
178           [ qw(stdio crlf) ],
179           ":raw:crlf");
180
181     binmode(F, ":raw :encoding(latin1)"); # "latin1" will be canonized
182
183     # 7 tests potentially skipped.
184     unless ($DOSISH || !$FASTSTDIO) {
185         my @results = PerlIO::get_layers(F, details => 1);
186
187         # Get rid of the args and the flags.
188         splice(@results, 1, 2) if $NONSTDIO;
189
190         check([ @results ],
191               [ "stdio",    undef,        sub { $_[0] > 0 },
192                 "encoding", "iso-8859-1", sub { $_[0] & PerlIO::F_UTF8() } ],
193               ":raw:encoding(latin1)");
194     }
195
196     binmode(F);
197
198     check([ PerlIO::get_layers(F) ],
199           [ "stdio" ],
200           "binmode");
201
202     # RT78844
203     {
204         local $@ = "foo";
205         binmode(F, ":encoding(utf8)");
206         is( $@, "foo", '$@ not clobbered by binmode and :encoding');
207     }
208
209     close F;
210
211     {
212         use open(IN => ":crlf", OUT => ":encoding(cp1252)");
213
214         open F, '<', $afile;
215         open G, '>', $afile;
216
217         check([ PerlIO::get_layers(F, input  => 1) ],
218               [ qw(stdio crlf) ],
219               "use open IN");
220         
221         check([ PerlIO::get_layers(G, output => 1) ],
222               [ qw[stdio encoding(cp1252) utf8] ],
223               "use open OUT");
224
225         close F;
226         close G;
227     }
228
229     # Check that PL_sigwarn's reference count is correct, and that 
230     # &PerlIO::Layer::NoWarnings isn't prematurely freed.
231     fresh_perl_like (<<"EOT", qr/^CODE/);
232 open(UTF, "<:raw:encoding(utf8)", '$afile') or die \$!;
233 print ref *PerlIO::Layer::NoWarnings{CODE};
234 EOT
235 }