t/op/chdir.t

   1 #!./perl -w
   2
   3 BEGIN {
   4     # We're not going to chdir() into 't' because we don't know if
   5     # chdir() works!  Instead, we'll hedge our bets and put both
   6     # possibilities into @INC.
   7     @INC = qw(t . lib ../lib);
   8 }
   9
  10 use Config;
  11 require "test.pl";
  12 plan(tests => 31);
  13
  14 my $IsVMS   = $^O eq 'VMS';
  15 my $IsMacOS = $^O eq 'MacOS';
  16
  17 # Might be a little early in the testing process to start using these,
  18 # but I can't think of a way to write this test without them.
  19 use File::Spec::Functions qw(:DEFAULT splitdir rel2abs splitpath);
  20
  21 # Can't use Cwd::abs_path() because it has different ideas about
  22 # path separators than File::Spec.
  23 sub abs_path {
  24     my $d = rel2abs(curdir);
  25
  26     $d = uc($d) if $IsVMS;
  27     $d = lc($d) if $^O =~ /^uwin/;
  28     $d;
  29 }
  30
  31 my $Cwd = abs_path;
  32
  33 # Let's get to a known position
  34 SKIP: {
  35     my ($vol,$dir) = splitpath(abs_path,1);
  36     my $test_dir = $IsVMS ? 'T' : 't';
  37     skip("Already in t/", 2) if (splitdir($dir))[-1] eq $test_dir;
  38
  39     ok( chdir($test_dir),     'chdir($test_dir)');
  40     is( abs_path, catdir($Cwd, $test_dir),    '  abs_path() agrees' );
  41 }
  42
  43 $Cwd = abs_path;
  44
  45 # The environment variables chdir() pays attention to.
  46 my @magic_envs = qw(HOME LOGDIR SYS$LOGIN);
  47
  48 sub check_env {
  49     my($key) = @_;
  50
  51     # Make sure $ENV{'SYS$LOGIN'} is only honored on VMS.
  52     if( $key eq 'SYS$LOGIN' && !$IsVMS && !$IsMacOS ) {
  53         ok( !chdir(),         "chdir() on $^O ignores only \$ENV{$key} set" );
  54         is( abs_path, $Cwd,   '  abs_path() did not change' );
  55         pass( "  no need to test SYS\$LOGIN on $^O" ) for 1..7;
  56     }
  57     else {
  58         ok( chdir(),              "chdir() w/ only \$ENV{$key} set" );
  59         is( abs_path, $ENV{$key}, '  abs_path() agrees' );
  60         chdir($Cwd);
  61         is( abs_path, $Cwd,       '  and back again' );
  62
  63         my $warning = '';
  64         local $SIG{__WARN__} = sub { $warning .= join '', @_ };
  65
  66
  67         # Check the deprecated chdir(undef) feature.
  68 #line 64
  69         ok( chdir(undef),           "chdir(undef) w/ only \$ENV{$key} set" );
  70         is( abs_path, $ENV{$key},   '  abs_path() agrees' );
  71         is( $warning,  <<WARNING,   '  got uninit & deprecation warning' );
  72 Use of uninitialized value in chdir at $0 line 64.
  73 Use of chdir('') or chdir(undef) as chdir() is deprecated at $0 line 64.
  74 WARNING
  75
  76         chdir($Cwd);
  77
  78         # Ditto chdir('').
  79         $warning = '';
  80 #line 76
  81         ok( chdir(''),              "chdir('') w/ only \$ENV{$key} set" );
  82         is( abs_path, $ENV{$key},   '  abs_path() agrees' );
  83         is( $warning,  <<WARNING,   '  got deprecation warning' );
  84 Use of chdir('') or chdir(undef) as chdir() is deprecated at $0 line 76.
  85 WARNING
  86
  87         chdir($Cwd);
  88     }
  89 }
  90
  91 my %Saved_Env = ();
  92 sub clean_env {
  93     foreach my $env (@magic_envs) {
  94         $Saved_Env{$env} = $ENV{$env};
  95
  96         # Can't actually delete SYS$ stuff on VMS.
  97         next if $IsVMS && $env eq 'SYS$LOGIN';
  98         next if $IsVMS && $env eq 'HOME' && !$Config{'d_setenv'};
  99
 100         unless ($IsMacOS) { # ENV on MacOS is "special" :-)
 101             # On VMS, %ENV is many layered.
 102             delete $ENV{$env} while exists $ENV{$env};
 103         }
 104     }
 105
 106     # The following means we won't really be testing for non-existence,
 107     # but in Perl we can only delete from the process table, not the job
 108     # table.
 109     $ENV{'SYS$LOGIN'} = '' if $IsVMS;
 110 }
 111
 112 END {
 113     no warnings 'uninitialized';
 114
 115     # Restore the environment for VMS (and doesn't hurt for anyone else)
 116     @ENV{@magic_envs} = @Saved_Env{@magic_envs};
 117 }
 118
 119
 120 foreach my $key (@magic_envs) {
 121     # We're going to be using undefs a lot here.
 122     no warnings 'uninitialized';
 123
 124     clean_env;
 125     $ENV{$key} = catdir $Cwd, ($IsVMS ? 'OP' : 'op');
 126
 127     check_env($key);
 128 }
 129
 130 {
 131     clean_env;
 132     if (($IsVMS || $IsMacOS) && !$Config{'d_setenv'}) {
 133         pass("Can't reset HOME, so chdir() test meaningless");
 134     } else {
 135         ok( !chdir(),                   'chdir() w/o any ENV set' );
 136     }
 137     is( abs_path, $Cwd,             '  abs_path() agrees' );
 138 }