This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
21bf1d2cdbaccaaeab2e5ba684b41ae159ea23f2
[perl5.git] / t / test.pl
1 #
2 # t/test.pl - most of Test::More functionality without the fuss, plus
3 # has mappings native_to_latin1 and latin1_to_native so that fewer tests
4 # on non ASCII-ish platforms need to be skipped
5
6
7 # NOTE:
8 #
9 # Increment ($x++) has a certain amount of cleverness for things like
10 #
11 #   $x = 'zz';
12 #   $x++; # $x eq 'aaa';
13 #
14 # stands more chance of breaking than just a simple
15 #
16 #   $x = $x + 1
17 #
18 # In this file, we use the latter "Baby Perl" approach, and increment
19 # will be worked over by t/op/inc.t
20
21 $Level = 1;
22 my $test = 1;
23 my $planned;
24 my $noplan;
25 my $Perl;       # Safer version of $^X set by which_perl()
26
27 # This defines ASCII/UTF-8 vs EBCDIC/UTF-EBCDIC
28 $::IS_ASCII  = ord 'A' ==  65;
29 $::IS_EBCDIC = ord 'A' == 193;
30
31 $TODO = 0;
32 $NO_ENDING = 0;
33 $Tests_Are_Passing = 1;
34
35 # Use this instead of print to avoid interference while testing globals.
36 sub _print {
37     local($\, $", $,) = (undef, ' ', '');
38     print STDOUT @_;
39 }
40
41 sub _print_stderr {
42     local($\, $", $,) = (undef, ' ', '');
43     print STDERR @_;
44 }
45
46 sub plan {
47     my $n;
48     if (@_ == 1) {
49         $n = shift;
50         if ($n eq 'no_plan') {
51           undef $n;
52           $noplan = 1;
53         }
54     } else {
55         my %plan = @_;
56         $n = $plan{tests};
57     }
58     _print "1..$n\n" unless $noplan;
59     $planned = $n;
60 }
61
62
63 # Set the plan at the end.  See Test::More::done_testing.
64 sub done_testing {
65     my $n = $test - 1;
66     $n = shift if @_;
67
68     _print "1..$n\n";
69     $planned = $n;
70 }
71
72
73 END {
74     my $ran = $test - 1;
75     if (!$NO_ENDING) {
76         if (defined $planned && $planned != $ran) {
77             _print_stderr
78                 "# Looks like you planned $planned tests but ran $ran.\n";
79         } elsif ($noplan) {
80             _print "1..$ran\n";
81         }
82     }
83 }
84
85 sub _diag {
86     return unless @_;
87     my @mess = _comment(@_);
88     $TODO ? _print(@mess) : _print_stderr(@mess);
89 }
90
91 # Use this instead of "print STDERR" when outputting failure diagnostic
92 # messages
93 sub diag {
94     _diag(@_);
95 }
96
97 # Use this instead of "print" when outputting informational messages
98 sub note {
99     return unless @_;
100     _print( _comment(@_) );
101 }
102
103 sub is_miniperl {
104     return !defined &DynaLoader::boot_DynaLoader;
105 }
106
107 sub _comment {
108     return map { /^#/ ? "$_\n" : "# $_\n" }
109            map { split /\n/ } @_;
110 }
111
112 sub skip_all {
113     if (@_) {
114         _print "1..0 # Skip @_\n";
115     } else {
116         _print "1..0\n";
117     }
118     exit(0);
119 }
120
121 sub skip_all_if_miniperl {
122     skip_all(@_) if is_miniperl();
123 }
124
125 sub skip_all_without_dynamic_extension {
126     my $extension = shift;
127     skip_all("no dynamic loading on miniperl, no $extension") if is_miniperl();
128     unless (eval {require Config; 1}) {
129         warn "test.pl had problems loading Config: $@";
130         return;
131     }
132     return if ($Config::Config{extensions} =~ /\b$extension\b/);
133     skip_all("$extension was not built");
134 }
135
136 sub skip_all_without_perlio {
137     skip_all('no PerlIO') unless PerlIO::Layer->find('perlio');
138 }
139
140 sub skip_all_without_config {
141     unless (eval {require Config; 1}) {
142         warn "test.pl had problems loading Config: $@";
143         return;
144     }
145     foreach (@_) {
146         next if $Config::Config{$_};
147         my $key = $_; # Need to copy, before trying to modify.
148         $key =~ s/^use//;
149         $key =~ s/^d_//;
150         skip_all("no $key");
151     }
152 }
153
154 sub _ok {
155     my ($pass, $where, $name, @mess) = @_;
156     # Do not try to microoptimize by factoring out the "not ".
157     # VMS will avenge.
158     my $out;
159     if ($name) {
160         # escape out '#' or it will interfere with '# skip' and such
161         $name =~ s/#/\\#/g;
162         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
163     } else {
164         $out = $pass ? "ok $test" : "not ok $test";
165     }
166
167     if ($TODO) {
168         $out = $out . " # TODO $TODO";
169     } else {
170         $Tests_Are_Passing = 0 unless $pass;
171     }
172
173     _print "$out\n";
174
175     if ($pass) {
176         note @mess; # Ensure that the message is properly escaped.
177     }
178     else {
179         _diag "# Failed $where\n";
180         _diag @mess;
181     }
182
183     $test = $test + 1; # don't use ++
184
185     return $pass;
186 }
187
188 sub _where {
189     my @caller = caller($Level);
190     return "at $caller[1] line $caller[2]";
191 }
192
193 # DON'T use this for matches. Use like() instead.
194 sub ok ($@) {
195     my ($pass, $name, @mess) = @_;
196     _ok($pass, _where(), $name, @mess);
197 }
198
199 sub _q {
200     my $x = shift;
201     return 'undef' unless defined $x;
202     my $q = $x;
203     $q =~ s/\\/\\\\/g;
204     $q =~ s/'/\\'/g;
205     return "'$q'";
206 }
207
208 sub _qq {
209     my $x = shift;
210     return defined $x ? '"' . display ($x) . '"' : 'undef';
211 };
212
213 # keys are the codes \n etc map to, values are 2 char strings such as \n
214 my %backslash_escape;
215 foreach my $x (split //, 'nrtfa\\\'"') {
216     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
217 }
218 # A way to display scalars containing control characters and Unicode.
219 # Trying to avoid setting $_, or relying on local $_ to work.
220 sub display {
221     my @result;
222     foreach my $x (@_) {
223         if (defined $x and not ref $x) {
224             my $y = '';
225             foreach my $c (unpack("U*", $x)) {
226                 if ($c > 255) {
227                     $y = $y . sprintf "\\x{%x}", $c;
228                 } elsif ($backslash_escape{$c}) {
229                     $y = $y . $backslash_escape{$c};
230                 } else {
231                     my $z = chr $c; # Maybe we can get away with a literal...
232                     if ($z =~ /[[:^print:]]/) {
233
234                         # Use octal for characters traditionally expressed as
235                         # such: the low controls
236                         if ($c <= 037) {
237                             $z = sprintf "\\%03o", $c;
238                         } else {
239                             $z = sprintf "\\x{%x}", $c;
240                         }
241                     }
242                     $y = $y . $z;
243                 }
244             }
245             $x = $y;
246         }
247         return $x unless wantarray;
248         push @result, $x;
249     }
250     return @result;
251 }
252
253 sub is ($$@) {
254     my ($got, $expected, $name, @mess) = @_;
255
256     my $pass;
257     if( !defined $got || !defined $expected ) {
258         # undef only matches undef
259         $pass = !defined $got && !defined $expected;
260     }
261     else {
262         $pass = $got eq $expected;
263     }
264
265     unless ($pass) {
266         unshift(@mess, "#      got "._qq($got)."\n",
267                        "# expected "._qq($expected)."\n");
268     }
269     _ok($pass, _where(), $name, @mess);
270 }
271
272 sub isnt ($$@) {
273     my ($got, $isnt, $name, @mess) = @_;
274
275     my $pass;
276     if( !defined $got || !defined $isnt ) {
277         # undef only matches undef
278         $pass = defined $got || defined $isnt;
279     }
280     else {
281         $pass = $got ne $isnt;
282     }
283
284     unless( $pass ) {
285         unshift(@mess, "# it should not be "._qq($got)."\n",
286                        "# but it is.\n");
287     }
288     _ok($pass, _where(), $name, @mess);
289 }
290
291 sub cmp_ok ($$$@) {
292     my($got, $type, $expected, $name, @mess) = @_;
293
294     my $pass;
295     {
296         local $^W = 0;
297         local($@,$!);   # don't interfere with $@
298                         # eval() sometimes resets $!
299         $pass = eval "\$got $type \$expected";
300     }
301     unless ($pass) {
302         # It seems Irix long doubles can have 2147483648 and 2147483648
303         # that stringify to the same thing but are actually numerically
304         # different. Display the numbers if $type isn't a string operator,
305         # and the numbers are stringwise the same.
306         # (all string operators have alphabetic names, so tr/a-z// is true)
307         # This will also show numbers for some unneeded cases, but will
308         # definitely be helpful for things such as == and <= that fail
309         if ($got eq $expected and $type !~ tr/a-z//) {
310             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
311         }
312         unshift(@mess, "#      got "._qq($got)."\n",
313                        "# expected $type "._qq($expected)."\n");
314     }
315     _ok($pass, _where(), $name, @mess);
316 }
317
318 # Check that $got is within $range of $expected
319 # if $range is 0, then check it's exact
320 # else if $expected is 0, then $range is an absolute value
321 # otherwise $range is a fractional error.
322 # Here $range must be numeric, >= 0
323 # Non numeric ranges might be a useful future extension. (eg %)
324 sub within ($$$@) {
325     my ($got, $expected, $range, $name, @mess) = @_;
326     my $pass;
327     if (!defined $got or !defined $expected or !defined $range) {
328         # This is a fail, but doesn't need extra diagnostics
329     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
330         # This is a fail
331         unshift @mess, "# got, expected and range must be numeric\n";
332     } elsif ($range < 0) {
333         # This is also a fail
334         unshift @mess, "# range must not be negative\n";
335     } elsif ($range == 0) {
336         # Within 0 is ==
337         $pass = $got == $expected;
338     } elsif ($expected == 0) {
339         # If expected is 0, treat range as absolute
340         $pass = ($got <= $range) && ($got >= - $range);
341     } else {
342         my $diff = $got - $expected;
343         $pass = abs ($diff / $expected) < $range;
344     }
345     unless ($pass) {
346         if ($got eq $expected) {
347             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
348         }
349         unshift@mess, "#      got "._qq($got)."\n",
350                       "# expected "._qq($expected)." (within "._qq($range).")\n";
351     }
352     _ok($pass, _where(), $name, @mess);
353 }
354
355 # Note: this isn't quite as fancy as Test::More::like().
356
357 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
358 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
359
360 sub like_yn ($$$@) {
361     my ($flip, undef, $expected, $name, @mess) = @_;
362     my $pass;
363     $pass = $_[1] =~ /$expected/ if !$flip;
364     $pass = $_[1] !~ /$expected/ if $flip;
365     unless ($pass) {
366         unshift(@mess, "#      got '$_[1]'\n",
367                 $flip
368                 ? "# expected !~ /$expected/\n" : "# expected /$expected/\n");
369     }
370     local $Level = $Level + 1;
371     _ok($pass, _where(), $name, @mess);
372 }
373
374 sub pass {
375     _ok(1, '', @_);
376 }
377
378 sub fail {
379     _ok(0, _where(), @_);
380 }
381
382 sub curr_test {
383     $test = shift if @_;
384     return $test;
385 }
386
387 sub next_test {
388   my $retval = $test;
389   $test = $test + 1; # don't use ++
390   $retval;
391 }
392
393 # Note: can't pass multipart messages since we try to
394 # be compatible with Test::More::skip().
395 sub skip {
396     my $why = shift;
397     my $n    = @_ ? shift : 1;
398     for (1..$n) {
399         _print "ok $test # skip $why\n";
400         $test = $test + 1;
401     }
402     local $^W = 0;
403     last SKIP;
404 }
405
406 sub skip_if_miniperl {
407     skip(@_) if is_miniperl();
408 }
409
410 sub todo_skip {
411     my $why = shift;
412     my $n   = @_ ? shift : 1;
413
414     for (1..$n) {
415         _print "not ok $test # TODO & SKIP $why\n";
416         $test = $test + 1;
417     }
418     local $^W = 0;
419     last TODO;
420 }
421
422 sub eq_array {
423     my ($ra, $rb) = @_;
424     return 0 unless $#$ra == $#$rb;
425     for my $i (0..$#$ra) {
426         next     if !defined $ra->[$i] && !defined $rb->[$i];
427         return 0 if !defined $ra->[$i];
428         return 0 if !defined $rb->[$i];
429         return 0 unless $ra->[$i] eq $rb->[$i];
430     }
431     return 1;
432 }
433
434 sub eq_hash {
435   my ($orig, $suspect) = @_;
436   my $fail;
437   while (my ($key, $value) = each %$suspect) {
438     # Force a hash recompute if this perl's internals can cache the hash key.
439     $key = "" . $key;
440     if (exists $orig->{$key}) {
441       if ($orig->{$key} ne $value) {
442         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
443                      " now ", _qq($value), "\n";
444         $fail = 1;
445       }
446     } else {
447       _print "# key ", _qq($key), " is ", _qq($value),
448                    ", not in original.\n";
449       $fail = 1;
450     }
451   }
452   foreach (keys %$orig) {
453     # Force a hash recompute if this perl's internals can cache the hash key.
454     $_ = "" . $_;
455     next if (exists $suspect->{$_});
456     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
457     $fail = 1;
458   }
459   !$fail;
460 }
461
462 # We only provide a subset of the Test::More functionality.
463 sub require_ok ($) {
464     my ($require) = @_;
465     if ($require =~ tr/[A-Za-z0-9:.]//c) {
466         fail("Invalid character in \"$require\", passed to require_ok");
467     } else {
468         eval <<REQUIRE_OK;
469 require $require;
470 REQUIRE_OK
471         is($@, '', _where(), "require $require");
472     }
473 }
474
475 sub use_ok ($) {
476     my ($use) = @_;
477     if ($use =~ tr/[A-Za-z0-9:.]//c) {
478         fail("Invalid character in \"$use\", passed to use");
479     } else {
480         eval <<USE_OK;
481 use $use;
482 USE_OK
483         is($@, '', _where(), "use $use");
484     }
485 }
486
487 # runperl - Runs a separate perl interpreter.
488 # Arguments :
489 #   switches => [ command-line switches ]
490 #   nolib    => 1 # don't use -I../lib (included by default)
491 #   non_portable => Don't warn if a one liner contains quotes
492 #   prog     => one-liner (avoid quotes)
493 #   progs    => [ multi-liner (avoid quotes) ]
494 #   progfile => perl script
495 #   stdin    => string to feed the stdin
496 #   stderr   => redirect stderr to stdout
497 #   args     => [ command-line arguments to the perl program ]
498 #   verbose  => print the command line
499
500 my $is_mswin    = $^O eq 'MSWin32';
501 my $is_netware  = $^O eq 'NetWare';
502 my $is_vms      = $^O eq 'VMS';
503 my $is_cygwin   = $^O eq 'cygwin';
504
505 sub _quote_args {
506     my ($runperl, $args) = @_;
507
508     foreach (@$args) {
509         # In VMS protect with doublequotes because otherwise
510         # DCL will lowercase -- unless already doublequoted.
511        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
512        $runperl = $runperl . ' ' . $_;
513     }
514     return $runperl;
515 }
516
517 sub _create_runperl { # Create the string to qx in runperl().
518     my %args = @_;
519     my $runperl = which_perl();
520     if ($runperl =~ m/\s/) {
521         $runperl = qq{"$runperl"};
522     }
523     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
524     if ($ENV{PERL_RUNPERL_DEBUG}) {
525         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
526     }
527     unless ($args{nolib}) {
528         $runperl = $runperl . ' "-I../lib"'; # doublequotes because of VMS
529     }
530     if ($args{switches}) {
531         local $Level = 2;
532         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
533             unless ref $args{switches} eq "ARRAY";
534         $runperl = _quote_args($runperl, $args{switches});
535     }
536     if (defined $args{prog}) {
537         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
538             if defined $args{progs};
539         $args{progs} = [$args{prog}]
540     }
541     if (defined $args{progs}) {
542         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
543             unless ref $args{progs} eq "ARRAY";
544         foreach my $prog (@{$args{progs}}) {
545             if ($prog =~ tr/'"// && !$args{non_portable}) {
546                 warn "quotes in prog >>$prog<< are not portable";
547             }
548             if ($is_mswin || $is_netware || $is_vms) {
549                 $runperl = $runperl . qq ( -e "$prog" );
550             }
551             else {
552                 $runperl = $runperl . qq ( -e '$prog' );
553             }
554         }
555     } elsif (defined $args{progfile}) {
556         $runperl = $runperl . qq( "$args{progfile}");
557     } else {
558         # You probably didn't want to be sucking in from the upstream stdin
559         die "test.pl:runperl(): none of prog, progs, progfile, args, "
560             . " switches or stdin specified"
561             unless defined $args{args} or defined $args{switches}
562                 or defined $args{stdin};
563     }
564     if (defined $args{stdin}) {
565         # so we don't try to put literal newlines and crs onto the
566         # command line.
567         $args{stdin} =~ s/\n/\\n/g;
568         $args{stdin} =~ s/\r/\\r/g;
569
570         if ($is_mswin || $is_netware || $is_vms) {
571             $runperl = qq{$Perl -e "print qq(} .
572                 $args{stdin} . q{)" | } . $runperl;
573         }
574         else {
575             $runperl = qq{$Perl -e 'print qq(} .
576                 $args{stdin} . q{)' | } . $runperl;
577         }
578     }
579     if (defined $args{args}) {
580         $runperl = _quote_args($runperl, $args{args});
581     }
582     $runperl = $runperl . ' 2>&1' if $args{stderr};
583     if ($args{verbose}) {
584         my $runperldisplay = $runperl;
585         $runperldisplay =~ s/\n/\n\#/g;
586         _print_stderr "# $runperldisplay\n";
587     }
588     return $runperl;
589 }
590
591 sub runperl {
592     die "test.pl:runperl() does not take a hashref"
593         if ref $_[0] and ref $_[0] eq 'HASH';
594     my $runperl = &_create_runperl;
595     my $result;
596
597     my $tainted = ${^TAINT};
598     my %args = @_;
599     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
600
601     if ($tainted) {
602         # We will assume that if you're running under -T, you really mean to
603         # run a fresh perl, so we'll brute force launder everything for you
604         my $sep;
605
606         if (! eval {require Config; 1}) {
607             warn "test.pl had problems loading Config: $@";
608             $sep = ':';
609         } else {
610             $sep = $Config::Config{path_sep};
611         }
612
613         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
614         local @ENV{@keys} = ();
615         # Untaint, plus take out . and empty string:
616         local $ENV{'DCL$PATH'} = $1 if $is_vms && exists($ENV{'DCL$PATH'}) && ($ENV{'DCL$PATH'} =~ /(.*)/s);
617         $ENV{PATH} =~ /(.*)/s;
618         local $ENV{PATH} =
619             join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
620                 ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
621                     split quotemeta ($sep), $1;
622         if ($is_cygwin) {   # Must have /bin under Cygwin
623             if (length $ENV{PATH}) {
624                 $ENV{PATH} = $ENV{PATH} . $sep;
625             }
626             $ENV{PATH} = $ENV{PATH} . '/bin';
627         }
628         $runperl =~ /(.*)/s;
629         $runperl = $1;
630
631         $result = `$runperl`;
632     } else {
633         $result = `$runperl`;
634     }
635     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
636     return $result;
637 }
638
639 # Nice alias
640 *run_perl = *run_perl = \&runperl; # shut up "used only once" warning
641
642 sub DIE {
643     _print_stderr "# @_\n";
644     exit 1;
645 }
646
647 # A somewhat safer version of the sometimes wrong $^X.
648 sub which_perl {
649     unless (defined $Perl) {
650         $Perl = $^X;
651
652         # VMS should have 'perl' aliased properly
653         return $Perl if $is_vms;
654
655         my $exe;
656         if (! eval {require Config; 1}) {
657             warn "test.pl had problems loading Config: $@";
658             $exe = '';
659         } else {
660             $exe = $Config::Config{_exe};
661         }
662        $exe = '' unless defined $exe;
663
664         # This doesn't absolutize the path: beware of future chdirs().
665         # We could do File::Spec->abs2rel() but that does getcwd()s,
666         # which is a bit heavyweight to do here.
667
668         if ($Perl =~ /^perl\Q$exe\E$/i) {
669             my $perl = "perl$exe";
670             if (! eval {require File::Spec; 1}) {
671                 warn "test.pl had problems loading File::Spec: $@";
672                 $Perl = "./$perl";
673             } else {
674                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
675             }
676         }
677
678         # Build up the name of the executable file from the name of
679         # the command.
680
681         if ($Perl !~ /\Q$exe\E$/i) {
682             $Perl = $Perl . $exe;
683         }
684
685         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
686
687         # For subcommands to use.
688         $ENV{PERLEXE} = $Perl;
689     }
690     return $Perl;
691 }
692
693 sub unlink_all {
694     my $count = 0;
695     foreach my $file (@_) {
696         1 while unlink $file;
697         if( -f $file ){
698             _print_stderr "# Couldn't unlink '$file': $!\n";
699         }else{
700             ++$count;
701         }
702     }
703     $count;
704 }
705
706 my %tmpfiles;
707 END { unlink_all keys %tmpfiles }
708
709 # A regexp that matches the tempfile names
710 $::tempfile_regexp = 'tmp\d+[A-Z][A-Z]?';
711
712 # Avoid ++, avoid ranges, avoid split //
713 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
714 sub tempfile {
715     my $count = 0;
716     do {
717         my $temp = $count;
718         my $try = "tmp$$";
719         do {
720             $try = $try . $letters[$temp % 26];
721             $temp = int ($temp / 26);
722         } while $temp;
723         # Need to note all the file names we allocated, as a second request may
724         # come before the first is created.
725         if (!-e $try && !$tmpfiles{$try}) {
726             # We have a winner
727             $tmpfiles{$try} = 1;
728             return $try;
729         }
730         $count = $count + 1;
731     } while $count < 26 * 26;
732     die "Can't find temporary file name starting 'tmp$$'";
733 }
734
735 # This is the temporary file for _fresh_perl
736 my $tmpfile = tempfile();
737
738 sub _fresh_perl {
739     my($prog, $action, $expect, $runperl_args, $name) = @_;
740
741     # Given the choice of the mis-parsable {}
742     # (we want an anon hash, but a borked lexer might think that it's a block)
743     # or relying on taking a reference to a lexical
744     # (\ might be mis-parsed, and the reference counting on the pad may go
745     #  awry)
746     # it feels like the least-worse thing is to assume that auto-vivification
747     # works. At least, this is only going to be a run-time failure, so won't
748     # affect tests using this file but not this function.
749     $runperl_args->{progfile} = $tmpfile;
750     $runperl_args->{stderr} = 1;
751
752     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
753
754     # VMS adjustments
755     if( $is_vms ) {
756         $prog =~ s#/dev/null#NL:#;
757
758         # VMS file locking
759         $prog =~ s{if \(-e _ and -f _ and -r _\)}
760                   {if (-e _ and -f _)}
761     }
762
763     print TEST $prog;
764     close TEST or die "Cannot close $tmpfile: $!";
765
766     my $results = runperl(%$runperl_args);
767     my $status = $?;
768
769     # Clean up the results into something a bit more predictable.
770     $results  =~ s/\n+$//;
771     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
772     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
773
774     # bison says 'parse error' instead of 'syntax error',
775     # various yaccs may or may not capitalize 'syntax'.
776     $results =~ s/^(syntax|parse) error/syntax error/mig;
777
778     if ($is_vms) {
779         # some tests will trigger VMS messages that won't be expected
780         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
781
782         # pipes double these sometimes
783         $results =~ s/\n\n/\n/g;
784     }
785
786     # Use the first line of the program as a name if none was given
787     unless( $name ) {
788         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
789         $name = $name . '...' if length $first_line > length $name;
790     }
791
792     # Historically this was implemented using a closure, but then that means
793     # that the tests for closures avoid using this code. Given that there
794     # are exactly two callers, doing exactly two things, the simpler approach
795     # feels like a better trade off.
796     my $pass;
797     if ($action eq 'eq') {
798         $pass = is($results, $expect, $name);
799     } elsif ($action eq '=~') {
800         $pass = like($results, $expect, $name);
801     } else {
802         die "_fresh_perl can't process action '$action'";
803     }
804         
805     unless ($pass) {
806         _diag "# PROG: \n$prog\n";
807         _diag "# STATUS: $status\n";
808     }
809
810     return $pass;
811 }
812
813 #
814 # fresh_perl_is
815 #
816 # Combination of run_perl() and is().
817 #
818
819 sub fresh_perl_is {
820     my($prog, $expected, $runperl_args, $name) = @_;
821
822     # _fresh_perl() is going to clip the trailing newlines off the result.
823     # This will make it so the test author doesn't have to know that.
824     $expected =~ s/\n+$//;
825
826     local $Level = 2;
827     _fresh_perl($prog, 'eq', $expected, $runperl_args, $name);
828 }
829
830 #
831 # fresh_perl_like
832 #
833 # Combination of run_perl() and like().
834 #
835
836 sub fresh_perl_like {
837     my($prog, $expected, $runperl_args, $name) = @_;
838     local $Level = 2;
839     _fresh_perl($prog, '=~', $expected, $runperl_args, $name);
840 }
841
842 # Many tests use the same format in __DATA__ or external files to specify a
843 # sequence of (fresh) tests to run, extra files they may temporarily need, and
844 # what the expected output is. So have excatly one copy of the code to run that
845
846 sub run_multiple_progs {
847     my $up = shift;
848     my @prgs;
849     if ($up) {
850         # The tests in lib run in a temporary subdirectory of t, and always
851         # pass in a list of "programs" to run
852         @prgs = @_;
853     } else {
854         # The tests below t run in t and pass in a file handle.
855         my $fh = shift;
856         local $/;
857         @prgs = split "\n########\n", <$fh>;
858     }
859
860     my $tmpfile = tempfile();
861
862     for (@prgs){
863         unless (/\n/) {
864             print "# From $_\n";
865             next;
866         }
867         my $switch = "";
868         my @temps ;
869         my @temp_path;
870         if (s/^(\s*-\w+)//) {
871             $switch = $1;
872         }
873         my ($prog, $expected) = split(/\nEXPECT(?:\n|$)/, $_, 2);
874
875         my %reason;
876         foreach my $what (qw(skip todo)) {
877             $prog =~ s/^#\s*\U$what\E\s*(.*)\n//m and $reason{$what} = $1;
878             # If the SKIP reason starts ? then it's taken as a code snippet to
879             # evaluate. This provides the flexibility to have conditional SKIPs
880             if ($reason{$what} && $reason{$what} =~ s/^\?//) {
881                 my $temp = eval $reason{$what};
882                 if ($@) {
883                     die "# In \U$what\E code reason:\n# $reason{$what}\n$@";
884                 }
885                 $reason{$what} = $temp;
886             }
887         }
888
889         if ($prog =~ /--FILE--/) {
890             my @files = split(/\n--FILE--\s*([^\s\n]*)\s*\n/, $prog) ;
891             shift @files ;
892             die "Internal error: test $_ didn't split into pairs, got " .
893                 scalar(@files) . "[" . join("%%%%", @files) ."]\n"
894                     if @files % 2;
895             while (@files > 2) {
896                 my $filename = shift @files;
897                 my $code = shift @files;
898                 push @temps, $filename;
899                 if ($filename =~ m#(.*)/# && $filename !~ m#^\.\./#) {
900                     require File::Path;
901                     File::Path::mkpath($1);
902                     push(@temp_path, $1);
903                 }
904                 open my $fh, '>', $filename or die "Cannot open $filename: $!\n";
905                 print $fh $code;
906                 close $fh or die "Cannot close $filename: $!\n";
907             }
908             shift @files;
909             $prog = shift @files;
910         }
911
912         open my $fh, '>', $tmpfile or die "Cannot open >$tmpfile: $!";
913         print $fh q{
914         BEGIN {
915             open STDERR, '>&', STDOUT
916               or die "Can't dup STDOUT->STDERR: $!;";
917         }
918         };
919         print $fh "\n#line 1\n";  # So the line numbers don't get messed up.
920         print $fh $prog,"\n";
921         close $fh or die "Cannot close $tmpfile: $!";
922         my $results = runperl( stderr => 1, progfile => $tmpfile, $up
923                                ? (switches => ["-I$up/lib", $switch], nolib => 1)
924                                : (switches => [$switch])
925                                 );
926         my $status = $?;
927         $results =~ s/\n+$//;
928         # allow expected output to be written as if $prog is on STDIN
929         $results =~ s/$::tempfile_regexp/-/g;
930         if ($^O eq 'VMS') {
931             # some tests will trigger VMS messages that won't be expected
932             $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
933
934             # pipes double these sometimes
935             $results =~ s/\n\n/\n/g;
936         }
937         # bison says 'parse error' instead of 'syntax error',
938         # various yaccs may or may not capitalize 'syntax'.
939         $results =~ s/^(syntax|parse) error/syntax error/mig;
940         # allow all tests to run when there are leaks
941         $results =~ s/Scalars leaked: \d+\n//g;
942
943         $expected =~ s/\n+$//;
944         my $prefix = ($results =~ s#^PREFIX(\n|$)##) ;
945         # any special options? (OPTIONS foo bar zap)
946         my $option_regex = 0;
947         my $option_random = 0;
948         if ($expected =~ s/^OPTIONS? (.+)\n//) {
949             foreach my $option (split(' ', $1)) {
950                 if ($option eq 'regex') { # allow regular expressions
951                     $option_regex = 1;
952                 }
953                 elsif ($option eq 'random') { # all lines match, but in any order
954                     $option_random = 1;
955                 }
956                 else {
957                     die "$0: Unknown OPTION '$option'\n";
958                 }
959             }
960         }
961         die "$0: can't have OPTION regex and random\n"
962             if $option_regex + $option_random > 1;
963         my $ok = 0;
964         if ($results =~ s/^SKIPPED\n//) {
965             print "$results\n" ;
966             $ok = 1;
967         }
968         elsif ($option_random) {
969             my @got = sort split "\n", $results;
970             my @expected = sort split "\n", $expected;
971
972             $ok = "@got" eq "@expected";
973         }
974         elsif ($option_regex) {
975             $ok = $results =~ /^$expected/;
976         }
977         elsif ($prefix) {
978             $ok = $results =~ /^\Q$expected/;
979         }
980         else {
981             $ok = $results eq $expected;
982         }
983
984         local $::TODO = $reason{todo};
985
986         unless ($ok) {
987             my $err_line = "PROG: $switch\n$prog\n" .
988                            "EXPECTED:\n$expected\n" .
989                            "GOT:\n$results\n";
990             if ($::TODO) {
991                 $err_line =~ s/^/# /mg;
992                 print $err_line;  # Harness can't filter it out from STDERR.
993             }
994             else {
995                 print STDERR $err_line;
996             }
997         }
998
999         ok($ok);
1000
1001         foreach (@temps) {
1002             unlink $_ if $_;
1003         }
1004         foreach (@temp_path) {
1005             File::Path::rmtree $_ if -d $_;
1006         }
1007     }
1008 }
1009
1010 sub can_ok ($@) {
1011     my($proto, @methods) = @_;
1012     my $class = ref $proto || $proto;
1013
1014     unless( @methods ) {
1015         return _ok( 0, _where(), "$class->can(...)" );
1016     }
1017
1018     my @nok = ();
1019     foreach my $method (@methods) {
1020         local($!, $@);  # don't interfere with caller's $@
1021                         # eval sometimes resets $!
1022         eval { $proto->can($method) } || push @nok, $method;
1023     }
1024
1025     my $name;
1026     $name = @methods == 1 ? "$class->can('$methods[0]')"
1027                           : "$class->can(...)";
1028
1029     _ok( !@nok, _where(), $name );
1030 }
1031
1032
1033 # Call $class->new( @$args ); and run the result through isa_ok.
1034 # See Test::More::new_ok
1035 sub new_ok {
1036     my($class, $args, $obj_name) = @_;
1037     $args ||= [];
1038     $object_name = "The object" unless defined $obj_name;
1039
1040     local $Level = $Level + 1;
1041
1042     my $obj;
1043     my $ok = eval { $obj = $class->new(@$args); 1 };
1044     my $error = $@;
1045
1046     if($ok) {
1047         isa_ok($obj, $class, $object_name);
1048     }
1049     else {
1050         ok( 0, "new() died" );
1051         diag("Error was:  $@");
1052     }
1053
1054     return $obj;
1055
1056 }
1057
1058
1059 sub isa_ok ($$;$) {
1060     my($object, $class, $obj_name) = @_;
1061
1062     my $diag;
1063     $obj_name = 'The object' unless defined $obj_name;
1064     my $name = "$obj_name isa $class";
1065     if( !defined $object ) {
1066         $diag = "$obj_name isn't defined";
1067     }
1068     elsif( !ref $object ) {
1069         $diag = "$obj_name isn't a reference";
1070     }
1071     else {
1072         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
1073         local($@, $!);  # eval sometimes resets $!
1074         my $rslt = eval { $object->isa($class) };
1075         if( $@ ) {
1076             if( $@ =~ /^Can't call method "isa" on unblessed reference/ ) {
1077                 if( !UNIVERSAL::isa($object, $class) ) {
1078                     my $ref = ref $object;
1079                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
1080                 }
1081             } else {
1082                 die <<WHOA;
1083 WHOA! I tried to call ->isa on your object and got some weird error.
1084 This should never happen.  Please contact the author immediately.
1085 Here's the error.
1086 $@
1087 WHOA
1088             }
1089         }
1090         elsif( !$rslt ) {
1091             my $ref = ref $object;
1092             $diag = "$obj_name isn't a '$class' it's a '$ref'";
1093         }
1094     }
1095
1096     _ok( !$diag, _where(), $name );
1097 }
1098
1099 sub capture_warnings {
1100     my $code = shift;
1101
1102     my @w;
1103     local $SIG {__WARN__} = sub {push @w, join "", @_};
1104     &$code;
1105     return @w;
1106 }
1107
1108 # This will generate a variable number of tests.
1109 # Use done_testing() instead of a fixed plan.
1110 sub warnings_like {
1111     my ($code, $expect, $name) = @_;
1112     local $Level = $Level + 1;
1113
1114     my @w = capture_warnings($code);
1115
1116     cmp_ok(scalar @w, '==', scalar @$expect, $name);
1117     foreach my $e (@$expect) {
1118         if (ref $e) {
1119             like(shift @w, $e, $name);
1120         } else {
1121             is(shift @w, $e, $name);
1122         }
1123     }
1124     if (@w) {
1125         diag("Saw these additional warnings:");
1126         diag($_) foreach @w;
1127     }
1128 }
1129
1130 sub _fail_excess_warnings {
1131     my($expect, $got, $name) = @_;
1132     local $Level = $Level + 1;
1133     # This will fail, and produce diagnostics
1134     is($expect, scalar @$got, $name);
1135     diag("Saw these warnings:");
1136     diag($_) foreach @$got;
1137 }
1138
1139 sub warning_is {
1140     my ($code, $expect, $name) = @_;
1141     die sprintf "Expect must be a string or undef, not a %s reference", ref $expect
1142         if ref $expect;
1143     local $Level = $Level + 1;
1144     my @w = capture_warnings($code);
1145     if (@w > 1) {
1146         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1147     } else {
1148         is($w[0], $expect, $name);
1149     }
1150 }
1151
1152 sub warning_like {
1153     my ($code, $expect, $name) = @_;
1154     die sprintf "Expect must be a regexp object"
1155         unless ref $expect eq 'Regexp';
1156     local $Level = $Level + 1;
1157     my @w = capture_warnings($code);
1158     if (@w > 1) {
1159         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1160     } else {
1161         like($w[0], $expect, $name);
1162     }
1163 }
1164
1165 # Set a watchdog to timeout the entire test file
1166 # NOTE:  If the test file uses 'threads', then call the watchdog() function
1167 #        _AFTER_ the 'threads' module is loaded.
1168 sub watchdog ($;$)
1169 {
1170     my $timeout = shift;
1171     my $method  = shift || "";
1172     my $timeout_msg = 'Test process timed out - terminating';
1173
1174     # Valgrind slows perl way down so give it more time before dying.
1175     $timeout *= 10 if $ENV{PERL_VALGRIND};
1176
1177     my $pid_to_kill = $$;   # PID for this process
1178
1179     if ($method eq "alarm") {
1180         goto WATCHDOG_VIA_ALARM;
1181     }
1182
1183     # shut up use only once warning
1184     my $threads_on = $threads::threads && $threads::threads;
1185
1186     # Don't use a watchdog process if 'threads' is loaded -
1187     #   use a watchdog thread instead
1188     if (!$threads_on) {
1189
1190         # On Windows and VMS, try launching a watchdog process
1191         #   using system(1, ...) (see perlport.pod)
1192         if ($is_mswin || $is_vms) {
1193             # On Windows, try to get the 'real' PID
1194             if ($is_mswin) {
1195                 eval { require Win32; };
1196                 if (defined(&Win32::GetCurrentProcessId)) {
1197                     $pid_to_kill = Win32::GetCurrentProcessId();
1198                 }
1199             }
1200
1201             # If we still have a fake PID, we can't use this method at all
1202             return if ($pid_to_kill <= 0);
1203
1204             # Launch watchdog process
1205             my $watchdog;
1206             eval {
1207                 local $SIG{'__WARN__'} = sub {
1208                     _diag("Watchdog warning: $_[0]");
1209                 };
1210                 my $sig = $is_vms ? 'TERM' : 'KILL';
1211                 my $cmd = _create_runperl( prog =>  "sleep($timeout);" .
1212                                                     "warn qq/# $timeout_msg" . '\n/;' .
1213                                                     "kill($sig, $pid_to_kill);");
1214                 $watchdog = system(1, $cmd);
1215             };
1216             if ($@ || ($watchdog <= 0)) {
1217                 _diag('Failed to start watchdog');
1218                 _diag($@) if $@;
1219                 undef($watchdog);
1220                 return;
1221             }
1222
1223             # Add END block to parent to terminate and
1224             #   clean up watchdog process
1225             eval "END { local \$! = 0; local \$? = 0;
1226                         wait() if kill('KILL', $watchdog); };";
1227             return;
1228         }
1229
1230         # Try using fork() to generate a watchdog process
1231         my $watchdog;
1232         eval { $watchdog = fork() };
1233         if (defined($watchdog)) {
1234             if ($watchdog) {   # Parent process
1235                 # Add END block to parent to terminate and
1236                 #   clean up watchdog process
1237                 eval "END { local \$! = 0; local \$? = 0;
1238                             wait() if kill('KILL', $watchdog); };";
1239                 return;
1240             }
1241
1242             ### Watchdog process code
1243
1244             # Load POSIX if available
1245             eval { require POSIX; };
1246
1247             # Execute the timeout
1248             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
1249             sleep(2);
1250
1251             # Kill test process if still running
1252             if (kill(0, $pid_to_kill)) {
1253                 _diag($timeout_msg);
1254                 kill('KILL', $pid_to_kill);
1255             }
1256
1257             # Don't execute END block (added at beginning of this file)
1258             $NO_ENDING = 1;
1259
1260             # Terminate ourself (i.e., the watchdog)
1261             POSIX::_exit(1) if (defined(&POSIX::_exit));
1262             exit(1);
1263         }
1264
1265         # fork() failed - fall through and try using a thread
1266     }
1267
1268     # Use a watchdog thread because either 'threads' is loaded,
1269     #   or fork() failed
1270     if (eval {require threads; 1}) {
1271         'threads'->create(sub {
1272                 # Load POSIX if available
1273                 eval { require POSIX; };
1274
1275                 # Execute the timeout
1276                 my $time_left = $timeout;
1277                 do {
1278                     $time_left = $time_left - sleep($time_left);
1279                 } while ($time_left > 0);
1280
1281                 # Kill the parent (and ourself)
1282                 select(STDERR); $| = 1;
1283                 _diag($timeout_msg);
1284                 POSIX::_exit(1) if (defined(&POSIX::_exit));
1285                 my $sig = $is_vms ? 'TERM' : 'KILL';
1286                 kill($sig, $pid_to_kill);
1287             })->detach();
1288         return;
1289     }
1290
1291     # If everything above fails, then just use an alarm timeout
1292 WATCHDOG_VIA_ALARM:
1293     if (eval { alarm($timeout); 1; }) {
1294         # Load POSIX if available
1295         eval { require POSIX; };
1296
1297         # Alarm handler will do the actual 'killing'
1298         $SIG{'ALRM'} = sub {
1299             select(STDERR); $| = 1;
1300             _diag($timeout_msg);
1301             POSIX::_exit(1) if (defined(&POSIX::_exit));
1302             my $sig = $is_vms ? 'TERM' : 'KILL';
1303             kill($sig, $pid_to_kill);
1304         };
1305     }
1306 }
1307
1308 my $cp_0037 =   # EBCDIC code page 0037
1309     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x25\x0B\x0C\x0D\x0E\x0F' .
1310     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1311     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1312     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1313     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1314     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBA\xE0\xBB\xB0\x6D' .
1315     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1316     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1317     '\x20\x21\x22\x23\x24\x15\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1318     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1319     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBD\xB4\x9A\x8A\x5F\xCA\xAF\xBC' .
1320     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1321     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1322     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xAD\xAE\x59' .
1323     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1324     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1325
1326 my $cp_1047 =   # EBCDIC code page 1047
1327     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1328     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1329     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1330     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1331     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1332     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xAD\xE0\xBD\x5F\x6D' .
1333     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1334     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1335     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1336     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1337     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBB\xB4\x9A\x8A\xB0\xCA\xAF\xBC' .
1338     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1339     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1340     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xBA\xAE\x59' .
1341     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1342     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1343
1344 my $cp_bc = # EBCDIC code page POSiX-BC
1345     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1346     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1347     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1348     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1349     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1350     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBB\xBC\xBD\x6A\x6D' .
1351     '\x4A\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1352     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xFB\x4F\xFD\xFF\x07' .
1353     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1354     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\x5F' .
1355     '\x41\xAA\xB0\xB1\x9F\xB2\xD0\xB5\x79\xB4\x9A\x8A\xBA\xCA\xAF\xA1' .
1356     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1357     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1358     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xE0\xFE\xDD\xFC\xAD\xAE\x59' .
1359     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1360     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xC0\xDE\xDB\xDC\x8D\x8E\xDF';
1361
1362 my $straight =  # Avoid ranges
1363     '\x00\x01\x02\x03\x04\x05\x06\x07\x08\x09\x0A\x0B\x0C\x0D\x0E\x0F' .
1364     '\x10\x11\x12\x13\x14\x15\x16\x17\x18\x19\x1A\x1B\x1C\x1D\x1E\x1F' .
1365     '\x20\x21\x22\x23\x24\x25\x26\x27\x28\x29\x2A\x2B\x2C\x2D\x2E\x2F' .
1366     '\x30\x31\x32\x33\x34\x35\x36\x37\x38\x39\x3A\x3B\x3C\x3D\x3E\x3F' .
1367     '\x40\x41\x42\x43\x44\x45\x46\x47\x48\x49\x4A\x4B\x4C\x4D\x4E\x4F' .
1368     '\x50\x51\x52\x53\x54\x55\x56\x57\x58\x59\x5A\x5B\x5C\x5D\x5E\x5F' .
1369     '\x60\x61\x62\x63\x64\x65\x66\x67\x68\x69\x6A\x6B\x6C\x6D\x6E\x6F' .
1370     '\x70\x71\x72\x73\x74\x75\x76\x77\x78\x79\x7A\x7B\x7C\x7D\x7E\x7F' .
1371     '\x80\x81\x82\x83\x84\x85\x86\x87\x88\x89\x8A\x8B\x8C\x8D\x8E\x8F' .
1372     '\x90\x91\x92\x93\x94\x95\x96\x97\x98\x99\x9A\x9B\x9C\x9D\x9E\x9F' .
1373     '\xA0\xA1\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xAA\xAB\xAC\xAD\xAE\xAF' .
1374     '\xB0\xB1\xB2\xB3\xB4\xB5\xB6\xB7\xB8\xB9\xBA\xBB\xBC\xBD\xBE\xBF' .
1375     '\xC0\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xCA\xCB\xCC\xCD\xCE\xCF' .
1376     '\xD0\xD1\xD2\xD3\xD4\xD5\xD6\xD7\xD8\xD9\xDA\xDB\xDC\xDD\xDE\xDF' .
1377     '\xE0\xE1\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xEA\xEB\xEC\xED\xEE\xEF' .
1378     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\xFA\xFB\xFC\xFD\xFE\xFF';
1379
1380 # The following 2 functions allow tests to work on both EBCDIC and
1381 # ASCII-ish platforms.  They convert string scalars between the native
1382 # character set and the set of 256 characters which is usually called
1383 # Latin1.
1384 #
1385 # These routines don't work on UTF-EBCDIC and UTF-8.
1386
1387 sub native_to_latin1($) {
1388     my $string = shift;
1389
1390     return $string if ord('^') == 94;   # ASCII, Latin1
1391     my $cp;
1392     if (ord('^') == 95) {    # EBCDIC 1047
1393         $cp = \$cp_1047;
1394     }
1395     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1396         $cp = \$cp_bc;
1397     }
1398     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1399         $cp = \$cp_0037;
1400     }
1401     else {
1402         die "Unknown native character set";
1403     }
1404
1405     eval '$string =~ tr/' . $$cp . '/' . $straight . '/';
1406     return $string;
1407 }
1408
1409 sub latin1_to_native($) {
1410     my $string = shift;
1411
1412     return $string if ord('^') == 94;   # ASCII, Latin1
1413     my $cp;
1414     if (ord('^') == 95) {    # EBCDIC 1047
1415         $cp = \$cp_1047;
1416     }
1417     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1418         $cp = \$cp_bc;
1419     }
1420     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1421         $cp = \$cp_0037;
1422     }
1423     else {
1424         die "Unknown native character set";
1425     }
1426
1427     eval '$string =~ tr/' . $straight . '/' . $$cp . '/';
1428     return $string;
1429 }
1430
1431 sub ord_latin1_to_native {
1432     # given an input code point, return the platform's native
1433     # equivalent value.  Anything above latin1 is itself.
1434
1435     my $ord = shift;
1436     return $ord if $ord > 255;
1437     return ord latin1_to_native(chr $ord);
1438 }
1439
1440 sub ord_native_to_latin1 {
1441     # given an input platform code point, return the latin1 equivalent value.
1442     # Anything above latin1 is itself.
1443
1444     my $ord = shift;
1445     return $ord if $ord > 255;
1446     return ord native_to_latin1(chr $ord);
1447 }
1448
1449 1;