This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
\N is no longer experimental
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of line only at the left and right ends of the string to
35 matching them anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If locale matching rules are in effect, the case map is taken from the
55 current
56 locale for code points less than 255, and from Unicode rules for larger
57 code points.  However, matches that would cross the Unicode
58 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
59 L<perllocale>.
60
61 There are a number of Unicode characters that match multiple characters
62 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
63 should match the sequence C<fi>.  Perl is not
64 currently able to do this when the multiple characters are in the pattern and
65 are split between groupings, or when one or more are quantified.  Thus
66
67  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
68  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
69  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
70
71  # The below doesn't match, and it isn't clear what $1 and $2 would
72  # be even if it did!!
73  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
74
75 Perl doesn't match multiple characters in a bracketed
76 character class unless the character that maps to them is explicitly
77 mentioned, and it doesn't match them at all if the character class is
78 inverted, which otherwise could be highly confusing.  See
79 L<perlrecharclass/Bracketed Character Classes>, and
80 L<perlrecharclass/Negation>.
81
82 =item x
83 X</x>
84
85 Extend your pattern's legibility by permitting whitespace and comments.
86 Details in L</"/x">
87
88 =item p
89 X</p> X<regex, preserve> X<regexp, preserve>
90
91 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
92 ${^POSTMATCH} are available for use after matching.
93
94 In Perl 5.18 and higher this is ignored.  ${^PREMATCH}, ${^MATCH}, and
95 ${^POSTMATCH} will be available after the match regardless of the modifier.
96
97 =item g and c
98 X</g> X</c>
99
100 Global matching, and keep the Current position after failed matching.
101 Unlike i, m, s and x, these two flags affect the way the regex is used
102 rather than the regex itself. See
103 L<perlretut/"Using regular expressions in Perl"> for further explanation
104 of the g and c modifiers.
105
106 =item a, d, l and u
107 X</a> X</d> X</l> X</u>
108
109 These modifiers, all new in 5.14, affect which character-set semantics
110 (Unicode, etc.) are used, as described below in
111 L</Character set modifiers>.
112
113 =back
114
115 Regular expression modifiers are usually written in documentation
116 as e.g., "the C</x> modifier", even though the delimiter
117 in question might not really be a slash.  The modifiers C</imsxadlup>
118 may also be embedded within the regular expression itself using
119 the C<(?...)> construct, see L</Extended Patterns> below.
120
121 =head3 /x
122
123 C</x> tells
124 the regular expression parser to ignore most whitespace that is neither
125 backslashed nor within a character class.  You can use this to break up
126 your regular expression into (slightly) more readable parts.  The C<#>
127 character is also treated as a metacharacter introducing a comment,
128 just as in ordinary Perl code.  This also means that if you want real
129 whitespace or C<#> characters in the pattern (outside a character
130 class, where they are unaffected by C</x>), then you'll either have to
131 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
132 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
133 making Perl's regular expressions more readable.  Note that you have to
134 be careful not to include the pattern delimiter in the comment--perl has
135 no way of knowing you did not intend to close the pattern early.  See
136 the C-comment deletion code in L<perlop>.  Also note that anything inside
137 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
138 space interpretation within a single multi-character construct.  For
139 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
140 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
141 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
142 but can between the C<(> and C<?>.  Within any delimiters for such a
143 construct, allowed spaces are not affected by C</x>, and depend on the
144 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
145 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
146 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
147 L<perluniprops/Properties accessible through \p{} and \P{}>.
148 X</x>
149
150 =head3 Character set modifiers
151
152 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
153 the character set modifiers; they affect the character set semantics
154 used for the regular expression.
155
156 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
157 to you, and so you need not worry about them very much.  They exist for
158 Perl's internal use, so that complex regular expression data structures
159 can be automatically serialized and later exactly reconstituted,
160 including all their nuances.  But, since Perl can't keep a secret, and
161 there may be rare instances where they are useful, they are documented
162 here.
163
164 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
165 allow code that is to work mostly on ASCII data to not have to concern
166 itself with Unicode.
167
168 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
169 effect at the time of the execution of the pattern match.
170
171 C</u> sets the character set to B<U>nicode.
172
173 C</a> also sets the character set to Unicode, BUT adds several
174 restrictions for B<A>SCII-safe matching.
175
176 C</d> is the old, problematic, pre-5.14 B<D>efault character set
177 behavior.  Its only use is to force that old behavior.
178
179 At any given time, exactly one of these modifiers is in effect.  Their
180 existence allows Perl to keep the originally compiled behavior of a
181 regular expression, regardless of what rules are in effect when it is
182 actually executed.  And if it is interpolated into a larger regex, the
183 original's rules continue to apply to it, and only it.
184
185 The C</l> and C</u> modifiers are automatically selected for
186 regular expressions compiled within the scope of various pragmas,
187 and we recommend that in general, you use those pragmas instead of
188 specifying these modifiers explicitly.  For one thing, the modifiers
189 affect only pattern matching, and do not extend to even any replacement
190 done, whereas using the pragmas give consistent results for all
191 appropriate operations within their scopes.  For example,
192
193  s/foo/\Ubar/il
194
195 will match "foo" using the locale's rules for case-insensitive matching,
196 but the C</l> does not affect how the C<\U> operates.  Most likely you
197 want both of them to use locale rules.  To do this, instead compile the
198 regular expression within the scope of C<use locale>.  This both
199 implicitly adds the C</l> and applies locale rules to the C<\U>.   The
200 lesson is to C<use locale> and not C</l> explicitly.
201
202 Similarly, it would be better to use C<use feature 'unicode_strings'>
203 instead of,
204
205  s/foo/\Lbar/iu
206
207 to get Unicode rules, as the C<\L> in the former (but not necessarily
208 the latter) would also use Unicode rules.
209
210 More detail on each of the modifiers follows.  Most likely you don't
211 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
212 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
213
214 =head4 /l
215
216 means to use the current locale's rules (see L<perllocale>) when pattern
217 matching.  For example, C<\w> will match the "word" characters of that
218 locale, and C<"/i"> case-insensitive matching will match according to
219 the locale's case folding rules.  The locale used will be the one in
220 effect at the time of execution of the pattern match.  This may not be
221 the same as the compilation-time locale, and can differ from one match
222 to another if there is an intervening call of the
223 L<setlocale() function|perllocale/The setlocale function>.
224
225 Perl only supports single-byte locales.  This means that code points
226 above 255 are treated as Unicode no matter what locale is in effect.
227 Under Unicode rules, there are a few case-insensitive matches that cross
228 the 255/256 boundary.  These are disallowed under C</l>.  For example,
229 0xFF (on ASCII platforms) does not caselessly match the character at
230 0x178, C<LATIN CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be
231 C<LATIN SMALL LETTER Y WITH DIAERESIS> in the current locale, and Perl
232 has no way of knowing if that character even exists in the locale, much
233 less what code point it is.
234
235 This modifier may be specified to be the default by C<use locale>, but
236 see L</Which character set modifier is in effect?>.
237 X</l>
238
239 =head4 /u
240
241 means to use Unicode rules when pattern matching.  On ASCII platforms,
242 this means that the code points between 128 and 255 take on their
243 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
244 (Otherwise Perl considers their meanings to be undefined.)  Thus,
245 under this modifier, the ASCII platform effectively becomes a Unicode
246 platform; and hence, for example, C<\w> will match any of the more than
247 100_000 word characters in Unicode.
248
249 Unlike most locales, which are specific to a language and country pair,
250 Unicode classifies all the characters that are letters I<somewhere> in
251 the world as
252 C<\w>.  For example, your locale might not think that C<LATIN SMALL
253 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
254 Unicode does.  Similarly, all the characters that are decimal digits
255 somewhere in the world will match C<\d>; this is hundreds, not 10,
256 possible matches.  And some of those digits look like some of the 10
257 ASCII digits, but mean a different number, so a human could easily think
258 a number is a different quantity than it really is.  For example,
259 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
260 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
261 that are a mixture from different writing systems, creating a security
262 issue.  L<Unicode::UCD/num()> can be used to sort
263 this out.  Or the C</a> modifier can be used to force C<\d> to match
264 just the ASCII 0 through 9.
265
266 Also, under this modifier, case-insensitive matching works on the full
267 set of Unicode
268 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
269 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
270 if you're not prepared, might make it look like a hexadecimal constant,
271 presenting another potential security issue.  See
272 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
273 security issues.
274
275 On the EBCDIC platforms that Perl handles, the native character set is
276 equivalent to Latin-1.  Thus this modifier changes behavior only when
277 the C<"/i"> modifier is also specified, and it turns out it affects only
278 two characters, giving them full Unicode semantics: the C<MICRO SIGN>
279 will match the Greek capital and small letters C<MU>, otherwise not; and
280 the C<LATIN CAPITAL LETTER SHARP S> will match any of C<SS>, C<Ss>,
281 C<sS>, and C<ss>, otherwise not.
282
283 This modifier may be specified to be the default by C<use feature
284 'unicode_strings>, C<use locale ':not_characters'>, or
285 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
286 but see L</Which character set modifier is in effect?>.
287 X</u>
288
289 =head4 /d
290
291 This modifier means to use the "Default" native rules of the platform
292 except when there is cause to use Unicode rules instead, as follows:
293
294 =over 4
295
296 =item 1
297
298 the target string is encoded in UTF-8; or
299
300 =item 2
301
302 the pattern is encoded in UTF-8; or
303
304 =item 3
305
306 the pattern explicitly mentions a code point that is above 255 (say by
307 C<\x{100}>); or
308
309 =item 4
310
311 the pattern uses a Unicode name (C<\N{...}>);  or
312
313 =item 5
314
315 the pattern uses a Unicode property (C<\p{...}>); or
316
317 =item 6
318
319 the pattern uses L</C<(?[ ])>>
320
321 =back
322
323 Another mnemonic for this modifier is "Depends", as the rules actually
324 used depend on various things, and as a result you can get unexpected
325 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
326 become rather infamous, leading to yet another (printable) name for this
327 modifier, "Dodgy".
328
329 On ASCII platforms, the native rules are ASCII, and on EBCDIC platforms
330 (at least the ones that Perl handles), they are Latin-1.
331
332 Here are some examples of how that works on an ASCII platform:
333
334  $str =  "\xDF";      # $str is not in UTF-8 format.
335  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
336  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
337  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
338  chop $str;
339  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
340
341 This modifier is automatically selected by default when none of the
342 others are, so yet another name for it is "Default".
343
344 Because of the unexpected behaviors associated with this modifier, you
345 probably should only use it to maintain weird backward compatibilities.
346
347 =head4 /a (and /aa)
348
349 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
350 unlike the others, may be doubled-up to increase its effect.
351
352 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
353 the Posix character classes to match only in the ASCII range.  They thus
354 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
355 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
356 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, experimentally,
357 the vertical tab; C<\w> means the 63 characters
358 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
359 C<[[:print:]]> match only the appropriate ASCII-range characters.
360
361 This modifier is useful for people who only incidentally use Unicode,
362 and who do not wish to be burdened with its complexities and security
363 concerns.
364
365 With C</a>, one can write C<\d> with confidence that it will only match
366 ASCII characters, and should the need arise to match beyond ASCII, you
367 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
368 similar C<\p{...}> constructs that can match beyond ASCII both white
369 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
370 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
371 doesn't mean you can't use Unicode, it means that to get Unicode
372 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
373 signals Unicode.
374
375 As you would expect, this modifier causes, for example, C<\D> to mean
376 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
377 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
378 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
379 for C<\B>).
380
381 Otherwise, C</a> behaves like the C</u> modifier, in that
382 case-insensitive matching uses Unicode semantics; for example, "k" will
383 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
384 points in the Latin1 range, above ASCII will have Unicode rules when it
385 comes to case-insensitive matching.
386
387 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
388 specify the "a" twice, for example C</aai> or C</aia>.  (The first
389 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
390 adds the C</i> restrictions.)  But, note that code points outside the
391 ASCII range will use Unicode rules for C</i> matching, so the modifier
392 doesn't really restrict things to just ASCII; it just forbids the
393 intermixing of ASCII and non-ASCII.
394
395 To summarize, this modifier provides protection for applications that
396 don't wish to be exposed to all of Unicode.  Specifying it twice
397 gives added protection.
398
399 This modifier may be specified to be the default by C<use re '/a'>
400 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
401 the C</u> modifier explictly if there are a few regular expressions
402 where you do want full Unicode rules (but even here, it's best if
403 everything were under feature C<"unicode_strings">, along with the
404 C<use re '/aa'>).  Also see L</Which character set modifier is in
405 effect?>.
406 X</a>
407 X</aa>
408
409 =head4 Which character set modifier is in effect?
410
411 Which of these modifiers is in effect at any given point in a regular
412 expression depends on a fairly complex set of interactions.  These have
413 been designed so that in general you don't have to worry about it, but
414 this section gives the gory details.  As
415 explained below in L</Extended Patterns> it is possible to explicitly
416 specify modifiers that apply only to portions of a regular expression.
417 The innermost always has priority over any outer ones, and one applying
418 to the whole expression has priority over any of the default settings that are
419 described in the remainder of this section.
420
421 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
422 default modifiers (including these) for regular expressions compiled
423 within its scope.  This pragma has precedence over the other pragmas
424 listed below that also change the defaults.
425
426 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
427 and C<L<use feature 'unicode_strings|feature>>, or
428 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
429 C</u> when not in the same scope as either C<L<use locale|perllocale>>
430 or C<L<use bytes|bytes>>.
431 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
432 sets the default to C</u>, overriding any plain C<use locale>.)
433 Unlike the mechanisms mentioned above, these
434 affect operations besides regular expressions pattern matching, and so
435 give more consistent results with other operators, including using
436 C<\U>, C<\l>, etc. in substitution replacements.
437
438 If none of the above apply, for backwards compatibility reasons, the
439 C</d> modifier is the one in effect by default.  As this can lead to
440 unexpected results, it is best to specify which other rule set should be
441 used.
442
443 =head4 Character set modifier behavior prior to Perl 5.14
444
445 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
446 for regexes compiled within the scope of C<use locale>, and C</d> was
447 implied otherwise.  However, interpolating a regex into a larger regex
448 would ignore the original compilation in favor of whatever was in effect
449 at the time of the second compilation.  There were a number of
450 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
451 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
452 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
453
454 =head2 Regular Expressions
455
456 =head3 Metacharacters
457
458 The patterns used in Perl pattern matching evolved from those supplied in
459 the Version 8 regex routines.  (The routines are derived
460 (distantly) from Henry Spencer's freely redistributable reimplementation
461 of the V8 routines.)  See L<Version 8 Regular Expressions> for
462 details.
463
464 In particular the following metacharacters have their standard I<egrep>-ish
465 meanings:
466 X<metacharacter>
467 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
468
469
470     \        Quote the next metacharacter
471     ^        Match the beginning of the line
472     .        Match any character (except newline)
473     $        Match the end of the line (or before newline at the end)
474     |        Alternation
475     ()       Grouping
476     []       Bracketed Character class
477
478 By default, the "^" character is guaranteed to match only the
479 beginning of the string, the "$" character only the end (or before the
480 newline at the end), and Perl does certain optimizations with the
481 assumption that the string contains only one line.  Embedded newlines
482 will not be matched by "^" or "$".  You may, however, wish to treat a
483 string as a multi-line buffer, such that the "^" will match after any
484 newline within the string (except if the newline is the last character in
485 the string), and "$" will match before any newline.  At the
486 cost of a little more overhead, you can do this by using the /m modifier
487 on the pattern match operator.  (Older programs did this by setting C<$*>,
488 but this option was removed in perl 5.10.)
489 X<^> X<$> X</m>
490
491 To simplify multi-line substitutions, the "." character never matches a
492 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
493 the string is a single line--even if it isn't.
494 X<.> X</s>
495
496 =head3 Quantifiers
497
498 The following standard quantifiers are recognized:
499 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
500
501     *           Match 0 or more times
502     +           Match 1 or more times
503     ?           Match 1 or 0 times
504     {n}         Match exactly n times
505     {n,}        Match at least n times
506     {n,m}       Match at least n but not more than m times
507
508 (If a curly bracket occurs in any other context and does not form part of
509 a backslashed sequence like C<\x{...}>, it is treated as a regular
510 character.  In particular, the lower quantifier bound is not optional,
511 and a typo in a quantifier silently causes it to be treated as the
512 literal characters.  For example,
513
514     /o{4,3}/
515
516 looks like a quantifier that matches 0 times, since 4 is greater than 3,
517 but it really means to match the sequence of six characters
518 S<C<"o { 4 , 3 }">>.  It is planned to eventually require literal uses
519 of curly brackets to be escaped, say by preceding them with a backslash
520 or enclosing them within square brackets, (C<"\{"> or C<"[{]">).  This
521 change will allow for future syntax extensions (like making the lower
522 bound of a quantifier optional), and better error checking.  In the
523 meantime, you should get in the habit of escaping all instances where
524 you mean a literal "{".)
525
526 The "*" quantifier is equivalent to C<{0,}>, the "+"
527 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
528 to non-negative integral values less than a preset limit defined when perl is built.
529 This is usually 32766 on the most common platforms.  The actual limit can
530 be seen in the error message generated by code such as this:
531
532     $_ **= $_ , / {$_} / for 2 .. 42;
533
534 By default, a quantified subpattern is "greedy", that is, it will match as
535 many times as possible (given a particular starting location) while still
536 allowing the rest of the pattern to match.  If you want it to match the
537 minimum number of times possible, follow the quantifier with a "?".  Note
538 that the meanings don't change, just the "greediness":
539 X<metacharacter> X<greedy> X<greediness>
540 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
541
542     *?        Match 0 or more times, not greedily
543     +?        Match 1 or more times, not greedily
544     ??        Match 0 or 1 time, not greedily
545     {n}?      Match exactly n times, not greedily (redundant)
546     {n,}?     Match at least n times, not greedily
547     {n,m}?    Match at least n but not more than m times, not greedily
548
549 By default, when a quantified subpattern does not allow the rest of the
550 overall pattern to match, Perl will backtrack. However, this behaviour is
551 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
552 as well.
553
554  *+     Match 0 or more times and give nothing back
555  ++     Match 1 or more times and give nothing back
556  ?+     Match 0 or 1 time and give nothing back
557  {n}+   Match exactly n times and give nothing back (redundant)
558  {n,}+  Match at least n times and give nothing back
559  {n,m}+ Match at least n but not more than m times and give nothing back
560
561 For instance,
562
563    'aaaa' =~ /a++a/
564
565 will never match, as the C<a++> will gobble up all the C<a>'s in the
566 string and won't leave any for the remaining part of the pattern. This
567 feature can be extremely useful to give perl hints about where it
568 shouldn't backtrack. For instance, the typical "match a double-quoted
569 string" problem can be most efficiently performed when written as:
570
571    /"(?:[^"\\]++|\\.)*+"/
572
573 as we know that if the final quote does not match, backtracking will not
574 help. See the independent subexpression
575 L</C<< (?>pattern) >>> for more details;
576 possessive quantifiers are just syntactic sugar for that construct. For
577 instance the above example could also be written as follows:
578
579    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
580
581 =head3 Escape sequences
582
583 Because patterns are processed as double-quoted strings, the following
584 also work:
585
586  \t          tab                   (HT, TAB)
587  \n          newline               (LF, NL)
588  \r          return                (CR)
589  \f          form feed             (FF)
590  \a          alarm (bell)          (BEL)
591  \e          escape (think troff)  (ESC)
592  \cK         control char          (example: VT)
593  \x{}, \x00  character whose ordinal is the given hexadecimal number
594  \N{name}    named Unicode character or character sequence
595  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
596  \o{}, \000  character whose ordinal is the given octal number
597  \l          lowercase next char (think vi)
598  \u          uppercase next char (think vi)
599  \L          lowercase till \E (think vi)
600  \U          uppercase till \E (think vi)
601  \Q          quote (disable) pattern metacharacters till \E
602  \E          end either case modification or quoted section, think vi
603
604 Details are in L<perlop/Quote and Quote-like Operators>.
605
606 =head3 Character Classes and other Special Escapes
607
608 In addition, Perl defines the following:
609 X<\g> X<\k> X<\K> X<backreference>
610
611  Sequence   Note    Description
612   [...]     [1]  Match a character according to the rules of the
613                    bracketed character class defined by the "...".
614                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
615   [[:...:]] [2]  Match a character according to the rules of the POSIX
616                    character class "..." within the outer bracketed
617                    character class.  Example: [[:upper:]] matches any
618                    uppercase character.
619   (?[...])  [8]  Extended bracketed character class
620   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
621                    other connector punctuation chars plus Unicode
622                    marks)
623   \W        [3]  Match a non-"word" character
624   \s        [3]  Match a whitespace character
625   \S        [3]  Match a non-whitespace character
626   \d        [3]  Match a decimal digit character
627   \D        [3]  Match a non-digit character
628   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
629   \PP       [3]  Match non-P
630   \X        [4]  Match Unicode "eXtended grapheme cluster"
631   \C             Match a single C-language char (octet) even if that is
632                    part of a larger UTF-8 character.  Thus it breaks up
633                    characters into their UTF-8 bytes, so you may end up
634                    with malformed pieces of UTF-8.  Unsupported in
635                    lookbehind.
636   \1        [5]  Backreference to a specific capture group or buffer.
637                    '1' may actually be any positive integer.
638   \g1       [5]  Backreference to a specific or previous group,
639   \g{-1}    [5]  The number may be negative indicating a relative
640                    previous group and may optionally be wrapped in
641                    curly brackets for safer parsing.
642   \g{name}  [5]  Named backreference
643   \k<name>  [5]  Named backreference
644   \K        [6]  Keep the stuff left of the \K, don't include it in $&
645   \N        [7]  Any character but \n.  Not affected by /s modifier
646   \v        [3]  Vertical whitespace
647   \V        [3]  Not vertical whitespace
648   \h        [3]  Horizontal whitespace
649   \H        [3]  Not horizontal whitespace
650   \R        [4]  Linebreak
651
652 =over 4
653
654 =item [1]
655
656 See L<perlrecharclass/Bracketed Character Classes> for details.
657
658 =item [2]
659
660 See L<perlrecharclass/POSIX Character Classes> for details.
661
662 =item [3]
663
664 See L<perlrecharclass/Backslash sequences> for details.
665
666 =item [4]
667
668 See L<perlrebackslash/Misc> for details.
669
670 =item [5]
671
672 See L</Capture groups> below for details.
673
674 =item [6]
675
676 See L</Extended Patterns> below for details.
677
678 =item [7]
679
680 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
681 character or character sequence whose name is C<NAME>; and similarly
682 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
683 code point is I<hex>.  Otherwise it matches any character but C<\n>.
684
685 =item [8]
686
687 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
688
689 =back
690
691 =head3 Assertions
692
693 Perl defines the following zero-width assertions:
694 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
695 X<regexp, zero-width assertion>
696 X<regular expression, zero-width assertion>
697 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
698
699     \b  Match a word boundary
700     \B  Match except at a word boundary
701     \A  Match only at beginning of string
702     \Z  Match only at end of string, or before newline at the end
703     \z  Match only at end of string
704     \G  Match only at pos() (e.g. at the end-of-match position
705         of prior m//g)
706
707 A word boundary (C<\b>) is a spot between two characters
708 that has a C<\w> on one side of it and a C<\W> on the other side
709 of it (in either order), counting the imaginary characters off the
710 beginning and end of the string as matching a C<\W>.  (Within
711 character classes C<\b> represents backspace rather than a word
712 boundary, just as it normally does in any double-quoted string.)
713 The C<\A> and C<\Z> are just like "^" and "$", except that they
714 won't match multiple times when the C</m> modifier is used, while
715 "^" and "$" will match at every internal line boundary.  To match
716 the actual end of the string and not ignore an optional trailing
717 newline, use C<\z>.
718 X<\b> X<\A> X<\Z> X<\z> X</m>
719
720 The C<\G> assertion can be used to chain global matches (using
721 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
722 It is also useful when writing C<lex>-like scanners, when you have
723 several patterns that you want to match against consequent substrings
724 of your string; see the previous reference.  The actual location
725 where C<\G> will match can also be influenced by using C<pos()> as
726 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
727 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
728 is modified somewhat, in that contents to the left of C<\G> are
729 not counted when determining the length of the match. Thus the following
730 will not match forever:
731 X<\G>
732
733      my $string = 'ABC';
734      pos($string) = 1;
735      while ($string =~ /(.\G)/g) {
736          print $1;
737      }
738
739 It will print 'A' and then terminate, as it considers the match to
740 be zero-width, and thus will not match at the same position twice in a
741 row.
742
743 It is worth noting that C<\G> improperly used can result in an infinite
744 loop. Take care when using patterns that include C<\G> in an alternation.
745
746 =head3 Capture groups
747
748 The bracketing construct C<( ... )> creates capture groups (also referred to as
749 capture buffers). To refer to the current contents of a group later on, within
750 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
751 for the second, and so on.
752 This is called a I<backreference>.
753 X<regex, capture buffer> X<regexp, capture buffer>
754 X<regex, capture group> X<regexp, capture group>
755 X<regular expression, capture buffer> X<backreference>
756 X<regular expression, capture group> X<backreference>
757 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
758 X<named capture buffer> X<regular expression, named capture buffer>
759 X<named capture group> X<regular expression, named capture group>
760 X<%+> X<$+{name}> X<< \k<name> >>
761 There is no limit to the number of captured substrings that you may use.
762 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
763 a group did not match, the associated backreference won't match either. (This
764 can happen if the group is optional, or in a different branch of an
765 alternation.)
766 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
767 this form, described below.
768
769 You can also refer to capture groups relatively, by using a negative number, so
770 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
771 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
772 example:
773
774         /
775          (Y)            # group 1
776          (              # group 2
777             (X)         # group 3
778             \g{-1}      # backref to group 3
779             \g{-3}      # backref to group 1
780          )
781         /x
782
783 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
784 interpolate regexes into larger regexes and not have to worry about the
785 capture groups being renumbered.
786
787 You can dispense with numbers altogether and create named capture groups.
788 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
789 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
790 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
791 I<name> must not begin with a number, nor contain hyphens.
792 When different groups within the same pattern have the same name, any reference
793 to that name assumes the leftmost defined group.  Named groups count in
794 absolute and relative numbering, and so can also be referred to by those
795 numbers.
796 (It's possible to do things with named capture groups that would otherwise
797 require C<(??{})>.)
798
799 Capture group contents are dynamically scoped and available to you outside the
800 pattern until the end of the enclosing block or until the next successful
801 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
802 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
803 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
804
805 Braces are required in referring to named capture groups, but are optional for
806 absolute or relative numbered ones.  Braces are safer when creating a regex by
807 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
808 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
809 is probably not what you intended.
810
811 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
812 there were no named nor relative numbered capture groups.  Absolute numbered
813 groups were referred to using C<\1>,
814 C<\2>, etc., and this notation is still
815 accepted (and likely always will be).  But it leads to some ambiguities if
816 there are more than 9 capture groups, as C<\10> could mean either the tenth
817 capture group, or the character whose ordinal in octal is 010 (a backspace in
818 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
819 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
820 a backreference only if at least 11 left parentheses have opened before it.
821 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
822 There are several examples below that illustrate these perils.  You can avoid
823 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
824 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
825 digits padded with leading zeros, since a leading zero implies an octal
826 constant.
827
828 The C<\I<digit>> notation also works in certain circumstances outside
829 the pattern.  See L</Warning on \1 Instead of $1> below for details.
830
831 Examples:
832
833     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
834
835     /(.)\g1/                        # find first doubled char
836          and print "'$1' is the first doubled character\n";
837
838     /(?<char>.)\k<char>/            # ... a different way
839          and print "'$+{char}' is the first doubled character\n";
840
841     /(?'char'.)\g1/                 # ... mix and match
842          and print "'$1' is the first doubled character\n";
843
844     if (/Time: (..):(..):(..)/) {   # parse out values
845         $hours = $1;
846         $minutes = $2;
847         $seconds = $3;
848     }
849
850     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
851     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
852     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
853     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
854
855     $a = '(.)\1';        # Creates problems when concatenated.
856     $b = '(.)\g{1}';     # Avoids the problems.
857     "aa" =~ /${a}/;      # True
858     "aa" =~ /${b}/;      # True
859     "aa0" =~ /${a}0/;    # False!
860     "aa0" =~ /${b}0/;    # True
861     "aa\x08" =~ /${a}0/;  # True!
862     "aa\x08" =~ /${b}0/;  # False
863
864 Several special variables also refer back to portions of the previous
865 match.  C<$+> returns whatever the last bracket match matched.
866 C<$&> returns the entire matched string.  (At one point C<$0> did
867 also, but now it returns the name of the program.)  C<$`> returns
868 everything before the matched string.  C<$'> returns everything
869 after the matched string. And C<$^N> contains whatever was matched by
870 the most-recently closed group (submatch). C<$^N> can be used in
871 extended patterns (see below), for example to assign a submatch to a
872 variable.
873 X<$+> X<$^N> X<$&> X<$`> X<$'>
874
875 These special variables, like the C<%+> hash and the numbered match variables
876 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
877 until the end of the enclosing block or until the next successful
878 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
879 X<$+> X<$^N> X<$&> X<$`> X<$'>
880 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
881
882 B<NOTE>: Failed matches in Perl do not reset the match variables,
883 which makes it easier to write code that tests for a series of more
884 specific cases and remembers the best match.
885
886 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
887 beware that once Perl sees that you need one of C<$&>, C<$`>, or
888 C<$'> anywhere in the program, it has to provide them for every
889 pattern match.  This may substantially slow your program.  (In Perl 5.18 a
890 more efficient mechanism is used, eliminating any slowdown.)  Perl
891 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
892 price for each pattern that contains capturing parentheses.  (To
893 avoid this cost while retaining the grouping behaviour, use the
894 extended regular expression C<(?: ... )> instead.)  But if you never
895 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
896 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
897 if you can, but if you can't (and some algorithms really appreciate
898 them), once you've used them once, use them at will, because you've
899 already paid the price. 
900 X<$&> X<$`> X<$'>
901
902 As a workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
903 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
904 and C<$'>, B<except> that they are only guaranteed to be defined after a
905 successful match that was executed with the C</p> (preserve) modifier.
906 The use of these variables incurs no global performance penalty, unlike
907 their punctuation char equivalents, however at the trade-off that you
908 have to tell perl when you want to use them.  As of Perl 5.18, these three
909 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
910 X</p> X<p modifier>
911
912 =head2 Quoting metacharacters
913
914 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
915 C<\w>, C<\n>.  Unlike some other regular expression languages, there
916 are no backslashed symbols that aren't alphanumeric.  So anything
917 that looks like \\, \(, \), \[, \], \{, or \} is always
918 interpreted as a literal character, not a metacharacter.  This was
919 once used in a common idiom to disable or quote the special meanings
920 of regular expression metacharacters in a string that you want to
921 use for a pattern. Simply quote all non-"word" characters:
922
923     $pattern =~ s/(\W)/\\$1/g;
924
925 (If C<use locale> is set, then this depends on the current locale.)
926 Today it is more common to use the quotemeta() function or the C<\Q>
927 metaquoting escape sequence to disable all metacharacters' special
928 meanings like this:
929
930     /$unquoted\Q$quoted\E$unquoted/
931
932 Beware that if you put literal backslashes (those not inside
933 interpolated variables) between C<\Q> and C<\E>, double-quotish
934 backslash interpolation may lead to confusing results.  If you
935 I<need> to use literal backslashes within C<\Q...\E>,
936 consult L<perlop/"Gory details of parsing quoted constructs">.
937
938 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
939
940 =head2 Extended Patterns
941
942 Perl also defines a consistent extension syntax for features not
943 found in standard tools like B<awk> and
944 B<lex>.  The syntax for most of these is a
945 pair of parentheses with a question mark as the first thing within
946 the parentheses.  The character after the question mark indicates
947 the extension.
948
949 The stability of these extensions varies widely.  Some have been
950 part of the core language for many years.  Others are experimental
951 and may change without warning or be completely removed.  Check
952 the documentation on an individual feature to verify its current
953 status.
954
955 A question mark was chosen for this and for the minimal-matching
956 construct because 1) question marks are rare in older regular
957 expressions, and 2) whenever you see one, you should stop and
958 "question" exactly what is going on.  That's psychology....
959
960 =over 4
961
962 =item C<(?#text)>
963 X<(?#)>
964
965 A comment.  The text is ignored.  If the C</x> modifier enables
966 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
967 the comment as soon as it sees a C<)>, so there is no way to put a literal
968 C<)> in the comment.
969
970 =item C<(?adlupimsx-imsx)>
971
972 =item C<(?^alupimsx)>
973 X<(?)> X<(?^)>
974
975 One or more embedded pattern-match modifiers, to be turned on (or
976 turned off, if preceded by C<->) for the remainder of the pattern or
977 the remainder of the enclosing pattern group (if any).
978
979 This is particularly useful for dynamic patterns, such as those read in from a
980 configuration file, taken from an argument, or specified in a table
981 somewhere.  Consider the case where some patterns want to be
982 case-sensitive and some do not:  The case-insensitive ones merely need to
983 include C<(?i)> at the front of the pattern.  For example:
984
985     $pattern = "foobar";
986     if ( /$pattern/i ) { }
987
988     # more flexible:
989
990     $pattern = "(?i)foobar";
991     if ( /$pattern/ ) { }
992
993 These modifiers are restored at the end of the enclosing group. For example,
994
995     ( (?i) blah ) \s+ \g1
996
997 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
998 repetition of the previous word, assuming the C</x> modifier, and no C</i>
999 modifier outside this group.
1000
1001 These modifiers do not carry over into named subpatterns called in the
1002 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1003 change the case-sensitivity of the "NAME" pattern.
1004
1005 Any of these modifiers can be set to apply globally to all regular
1006 expressions compiled within the scope of a C<use re>.  See
1007 L<re/"'/flags' mode">.
1008
1009 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1010 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
1011 C<"d">) may follow the caret to override it.
1012 But a minus sign is not legal with it.
1013
1014 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
1015 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
1016 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1017 others, and a maximum of one (or two C<a>'s) may appear in the
1018 construct.  Thus, for
1019 example, C<(?-p)> will warn when compiled under C<use warnings>;
1020 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1021
1022 Note also that the C<p> modifier is special in that its presence
1023 anywhere in a pattern has a global effect.
1024
1025 =item C<(?:pattern)>
1026 X<(?:)>
1027
1028 =item C<(?adluimsx-imsx:pattern)>
1029
1030 =item C<(?^aluimsx:pattern)>
1031 X<(?^:)>
1032
1033 This is for clustering, not capturing; it groups subexpressions like
1034 "()", but doesn't make backreferences as "()" does.  So
1035
1036     @fields = split(/\b(?:a|b|c)\b/)
1037
1038 is like
1039
1040     @fields = split(/\b(a|b|c)\b/)
1041
1042 but doesn't spit out extra fields.  It's also cheaper not to capture
1043 characters if you don't need to.
1044
1045 Any letters between C<?> and C<:> act as flags modifiers as with
1046 C<(?adluimsx-imsx)>.  For example,
1047
1048     /(?s-i:more.*than).*million/i
1049
1050 is equivalent to the more verbose
1051
1052     /(?:(?s-i)more.*than).*million/i
1053
1054 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1055 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1056 flags (except C<"d">) may follow the caret, so
1057
1058     (?^x:foo)
1059
1060 is equivalent to
1061
1062     (?x-ims:foo)
1063
1064 The caret tells Perl that this cluster doesn't inherit the flags of any
1065 surrounding pattern, but uses the system defaults (C<d-imsx>),
1066 modified by any flags specified.
1067
1068 The caret allows for simpler stringification of compiled regular
1069 expressions.  These look like
1070
1071     (?^:pattern)
1072
1073 with any non-default flags appearing between the caret and the colon.
1074 A test that looks at such stringification thus doesn't need to have the
1075 system default flags hard-coded in it, just the caret.  If new flags are
1076 added to Perl, the meaning of the caret's expansion will change to include
1077 the default for those flags, so the test will still work, unchanged.
1078
1079 Specifying a negative flag after the caret is an error, as the flag is
1080 redundant.
1081
1082 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1083 to match at the beginning.
1084
1085 =item C<(?|pattern)>
1086 X<(?|)> X<Branch reset>
1087
1088 This is the "branch reset" pattern, which has the special property
1089 that the capture groups are numbered from the same starting point
1090 in each alternation branch. It is available starting from perl 5.10.0.
1091
1092 Capture groups are numbered from left to right, but inside this
1093 construct the numbering is restarted for each branch.
1094
1095 The numbering within each branch will be as normal, and any groups
1096 following this construct will be numbered as though the construct
1097 contained only one branch, that being the one with the most capture
1098 groups in it.
1099
1100 This construct is useful when you want to capture one of a
1101 number of alternative matches.
1102
1103 Consider the following pattern.  The numbers underneath show in
1104 which group the captured content will be stored.
1105
1106
1107     # before  ---------------branch-reset----------- after        
1108     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1109     # 1            2         2  3        2     3     4  
1110
1111 Be careful when using the branch reset pattern in combination with 
1112 named captures. Named captures are implemented as being aliases to 
1113 numbered groups holding the captures, and that interferes with the
1114 implementation of the branch reset pattern. If you are using named
1115 captures in a branch reset pattern, it's best to use the same names,
1116 in the same order, in each of the alternations:
1117
1118    /(?|  (?<a> x ) (?<b> y )
1119       |  (?<a> z ) (?<b> w )) /x
1120
1121 Not doing so may lead to surprises:
1122
1123   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1124   say $+ {a};   # Prints '12'
1125   say $+ {b};   # *Also* prints '12'.
1126
1127 The problem here is that both the group named C<< a >> and the group
1128 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1129
1130 =item Look-Around Assertions
1131 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1132
1133 Look-around assertions are zero-width patterns which match a specific
1134 pattern without including it in C<$&>. Positive assertions match when
1135 their subpattern matches, negative assertions match when their subpattern
1136 fails. Look-behind matches text up to the current match position,
1137 look-ahead matches text following the current match position.
1138
1139 =over 4
1140
1141 =item C<(?=pattern)>
1142 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1143
1144 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1145 matches a word followed by a tab, without including the tab in C<$&>.
1146
1147 =item C<(?!pattern)>
1148 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1149
1150 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1151 matches any occurrence of "foo" that isn't followed by "bar".  Note
1152 however that look-ahead and look-behind are NOT the same thing.  You cannot
1153 use this for look-behind.
1154
1155 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1156 will not do what you want.  That's because the C<(?!foo)> is just saying that
1157 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1158 match.  Use look-behind instead (see below).
1159
1160 =item C<(?<=pattern)> C<\K>
1161 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1162
1163 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1164 matches a word that follows a tab, without including the tab in C<$&>.
1165 Works only for fixed-width look-behind.
1166
1167 There is a special form of this construct, called C<\K>, which causes the
1168 regex engine to "keep" everything it had matched prior to the C<\K> and
1169 not include it in C<$&>. This effectively provides variable-length
1170 look-behind. The use of C<\K> inside of another look-around assertion
1171 is allowed, but the behaviour is currently not well defined.
1172
1173 For various reasons C<\K> may be significantly more efficient than the
1174 equivalent C<< (?<=...) >> construct, and it is especially useful in
1175 situations where you want to efficiently remove something following
1176 something else in a string. For instance
1177
1178   s/(foo)bar/$1/g;
1179
1180 can be rewritten as the much more efficient
1181
1182   s/foo\Kbar//g;
1183
1184 =item C<(?<!pattern)>
1185 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1186
1187 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1188 matches any occurrence of "foo" that does not follow "bar".  Works
1189 only for fixed-width look-behind.
1190
1191 =back
1192
1193 =item C<(?'NAME'pattern)>
1194
1195 =item C<< (?<NAME>pattern) >>
1196 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1197
1198 A named capture group. Identical in every respect to normal capturing
1199 parentheses C<()> but for the additional fact that the group
1200 can be referred to by name in various regular expression
1201 constructs (like C<\g{NAME}>) and can be accessed by name
1202 after a successful match via C<%+> or C<%->. See L<perlvar>
1203 for more details on the C<%+> and C<%-> hashes.
1204
1205 If multiple distinct capture groups have the same name then the
1206 $+{NAME} will refer to the leftmost defined group in the match.
1207
1208 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1209
1210 B<NOTE:> While the notation of this construct is the same as the similar
1211 function in .NET regexes, the behavior is not. In Perl the groups are
1212 numbered sequentially regardless of being named or not. Thus in the
1213 pattern
1214
1215   /(x)(?<foo>y)(z)/
1216
1217 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1218 the opposite which is what a .NET regex hacker might expect.
1219
1220 Currently NAME is restricted to simple identifiers only.
1221 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1222 its Unicode extension (see L<utf8>),
1223 though it isn't extended by the locale (see L<perllocale>).
1224
1225 B<NOTE:> In order to make things easier for programmers with experience
1226 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1227 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1228 support the use of single quotes as a delimiter for the name.
1229
1230 =item C<< \k<NAME> >>
1231
1232 =item C<< \k'NAME' >>
1233
1234 Named backreference. Similar to numeric backreferences, except that
1235 the group is designated by name and not number. If multiple groups
1236 have the same name then it refers to the leftmost defined group in
1237 the current match.
1238
1239 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1240 earlier in the pattern.
1241
1242 Both forms are equivalent.
1243
1244 B<NOTE:> In order to make things easier for programmers with experience
1245 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1246 may be used instead of C<< \k<NAME> >>.
1247
1248 =item C<(?{ code })>
1249 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1250
1251 B<WARNING>: This extended regular expression feature is considered
1252 experimental, and may be changed without notice. Code executed that
1253 has side effects may not perform identically from version to version
1254 due to the effect of future optimisations in the regex engine. The
1255 implementation of this feature was radically overhauled for the 5.18.0
1256 release, and its behaviour in earlier versions of perl was much buggier,
1257 especially in relation to parsing, lexical vars, scoping, recursion and
1258 reentrancy.
1259
1260 This zero-width assertion executes any embedded Perl code.  It always
1261 succeeds, and its return value is set as C<$^R>.
1262
1263 In literal patterns, the code is parsed at the same time as the
1264 surrounding code. While within the pattern, control is passed temporarily
1265 back to the perl parser, until the logically-balancing closing brace is
1266 encountered. This is similar to the way that an array index expression in
1267 a literal string is handled, for example
1268
1269     "abc$array[ 1 + f('[') + g()]def"
1270
1271 In particular, braces do not need to be balanced:
1272
1273     s/abc(?{ f('{'); })/def/
1274
1275 Even in a pattern that is interpolated and compiled at run-time, literal
1276 code blocks will be compiled once, at perl compile time; the following
1277 prints "ABCD":
1278
1279     print "D";
1280     my $qr = qr/(?{ BEGIN { print "A" } })/;
1281     my $foo = "foo";
1282     /$foo$qr(?{ BEGIN { print "B" } })/;
1283     BEGIN { print "C" }
1284
1285 In patterns where the text of the code is derived from run-time
1286 information rather than appearing literally in a source code /pattern/,
1287 the code is compiled at the same time that the pattern is compiled, and
1288 for reasons of security, C<use re 'eval'> must be in scope. This is to
1289 stop user-supplied patterns containing code snippets from being
1290 executable.
1291
1292 In situations where you need to enable this with C<use re 'eval'>, you should
1293 also have taint checking enabled.  Better yet, use the carefully
1294 constrained evaluation within a Safe compartment.  See L<perlsec> for
1295 details about both these mechanisms.
1296
1297 From the viewpoint of parsing, lexical variable scope and closures,
1298
1299     /AAA(?{ BBB })CCC/
1300
1301 behaves approximately like
1302
1303     /AAA/ && do { BBB } && /CCC/
1304
1305 Similarly,
1306
1307     qr/AAA(?{ BBB })CCC/
1308
1309 behaves approximately like
1310
1311     sub { /AAA/ && do { BBB } && /CCC/ }
1312
1313 In particular:
1314
1315     { my $i = 1; $r = qr/(?{ print $i })/ }
1316     my $i = 2;
1317     /$r/; # prints "1"
1318
1319 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1320 expression is matching against. You can also use C<pos()> to know what is
1321 the current position of matching within this string.
1322
1323 The code block introduces a new scope from the perspective of lexical
1324 variable declarations, but B<not> from the perspective of C<local> and
1325 similar localizing behaviours. So later code blocks within the same
1326 pattern will still see the values which were localized in earlier blocks.
1327 These accumulated localizations are undone either at the end of a
1328 successful match, or if the assertion is backtracked (compare
1329 L<"Backtracking">). For example,
1330
1331   $_ = 'a' x 8;
1332   m<
1333      (?{ $cnt = 0 })               # Initialize $cnt.
1334      (
1335        a
1336        (?{
1337            local $cnt = $cnt + 1;  # Update $cnt,
1338                                    # backtracking-safe.
1339        })
1340      )*
1341      aaaa
1342      (?{ $res = $cnt })            # On success copy to
1343                                    # non-localized location.
1344    >x;
1345
1346 will initially increment C<$cnt> up to 8; then during backtracking, its
1347 value will be unwound back to 4, which is the value assigned to C<$res>.
1348 At the end of the regex execution, $cnt will be wound back to its initial
1349 value of 0.
1350
1351 This assertion may be used as the condition in a
1352
1353     (?(condition)yes-pattern|no-pattern)
1354
1355 switch.  If I<not> used in this way, the result of evaluation of C<code>
1356 is put into the special variable C<$^R>.  This happens immediately, so
1357 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1358 regular expression.
1359
1360 The assignment to C<$^R> above is properly localized, so the old
1361 value of C<$^R> is restored if the assertion is backtracked; compare
1362 L<"Backtracking">.
1363
1364 Note that the special variable C<$^N>  is particularly useful with code
1365 blocks to capture the results of submatches in variables without having to
1366 keep track of the number of nested parentheses. For example:
1367
1368   $_ = "The brown fox jumps over the lazy dog";
1369   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1370   print "color = $color, animal = $animal\n";
1371
1372
1373 =item C<(??{ code })>
1374 X<(??{})>
1375 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1376
1377 B<WARNING>: This extended regular expression feature is considered
1378 experimental, and may be changed without notice. Code executed that
1379 has side effects may not perform identically from version to version
1380 due to the effect of future optimisations in the regex engine.
1381
1382 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1383 same way as a C<(?{ code })> code block as described above, except that
1384 its return value, rather than being assigned to C<$^R>, is treated as a
1385 pattern, compiled if it's a string (or used as-is if its a qr// object),
1386 then matched as if it were inserted instead of this construct.
1387
1388 During the matching of this sub-pattern, it has its own set of
1389 captures which are valid during the sub-match, but are discarded once
1390 control returns to the main pattern. For example, the following matches,
1391 with the inner pattern capturing "B" and matching "BB", while the outer
1392 pattern captures "A";
1393
1394     my $inner = '(.)\1';
1395     "ABBA" =~ /^(.)(??{ $inner })\1/;
1396     print $1; # prints "A";
1397
1398 Note that this means that  there is no way for the inner pattern to refer
1399 to a capture group defined outside.  (The code block itself can use C<$1>,
1400 etc., to refer to the enclosing pattern's capture groups.)  Thus, although
1401
1402     ('a' x 100)=~/(??{'(.)' x 100})/
1403
1404 I<will> match, it will I<not> set $1 on exit.
1405
1406 The following pattern matches a parenthesized group:
1407
1408  $re = qr{
1409             \(
1410             (?:
1411                (?> [^()]+ )  # Non-parens without backtracking
1412              |
1413                (??{ $re })   # Group with matching parens
1414             )*
1415             \)
1416          }x;
1417
1418 See also C<(?PARNO)> for a different, more efficient way to accomplish
1419 the same task.
1420
1421 Executing a postponed regular expression 50 times without consuming any
1422 input string will result in a fatal error.  The maximum depth is compiled
1423 into perl, so changing it requires a custom build.
1424
1425 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1426 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1427 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1428 X<regex, relative recursion>
1429
1430 Similar to C<(??{ code })> except that it does not involve executing any
1431 code or potentially compiling a returned pattern string; instead it treats
1432 the part of the current pattern contained within a specified capture group
1433 as an independent pattern that must match at the current position.
1434 Capture groups contained by the pattern will have the value as determined
1435 by the outermost recursion.
1436
1437 PARNO is a sequence of digits (not starting with 0) whose value reflects
1438 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1439 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1440 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1441 to be relative, with negative numbers indicating preceding capture groups
1442 and positive ones following. Thus C<(?-1)> refers to the most recently
1443 declared group, and C<(?+1)> indicates the next group to be declared.
1444 Note that the counting for relative recursion differs from that of
1445 relative backreferences, in that with recursion unclosed groups B<are>
1446 included.
1447
1448 The following pattern matches a function foo() which may contain
1449 balanced parentheses as the argument.
1450
1451   $re = qr{ (                   # paren group 1 (full function)
1452               foo
1453               (                 # paren group 2 (parens)
1454                 \(
1455                   (             # paren group 3 (contents of parens)
1456                   (?:
1457                    (?> [^()]+ ) # Non-parens without backtracking
1458                   |
1459                    (?2)         # Recurse to start of paren group 2
1460                   )*
1461                   )
1462                 \)
1463               )
1464             )
1465           }x;
1466
1467 If the pattern was used as follows
1468
1469     'foo(bar(baz)+baz(bop))'=~/$re/
1470         and print "\$1 = $1\n",
1471                   "\$2 = $2\n",
1472                   "\$3 = $3\n";
1473
1474 the output produced should be the following:
1475
1476     $1 = foo(bar(baz)+baz(bop))
1477     $2 = (bar(baz)+baz(bop))
1478     $3 = bar(baz)+baz(bop)
1479
1480 If there is no corresponding capture group defined, then it is a
1481 fatal error.  Recursing deeper than 50 times without consuming any input
1482 string will also result in a fatal error.  The maximum depth is compiled
1483 into perl, so changing it requires a custom build.
1484
1485 The following shows how using negative indexing can make it
1486 easier to embed recursive patterns inside of a C<qr//> construct
1487 for later use:
1488
1489     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1490     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1491        # do something here...
1492     }
1493
1494 B<Note> that this pattern does not behave the same way as the equivalent
1495 PCRE or Python construct of the same form. In Perl you can backtrack into
1496 a recursed group, in PCRE and Python the recursed into group is treated
1497 as atomic. Also, modifiers are resolved at compile time, so constructs
1498 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1499 be processed.
1500
1501 =item C<(?&NAME)>
1502 X<(?&NAME)>
1503
1504 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1505 parenthesis to recurse to is determined by name. If multiple parentheses have
1506 the same name, then it recurses to the leftmost.
1507
1508 It is an error to refer to a name that is not declared somewhere in the
1509 pattern.
1510
1511 B<NOTE:> In order to make things easier for programmers with experience
1512 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1513 may be used instead of C<< (?&NAME) >>.
1514
1515 =item C<(?(condition)yes-pattern|no-pattern)>
1516 X<(?()>
1517
1518 =item C<(?(condition)yes-pattern)>
1519
1520 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1521 a true value, matches C<no-pattern> otherwise. A missing pattern always
1522 matches.
1523
1524 C<(condition)> should be one of: 1) an integer in
1525 parentheses (which is valid if the corresponding pair of parentheses
1526 matched); 2) a look-ahead/look-behind/evaluate zero-width assertion; 3) a
1527 name in angle brackets or single quotes (which is valid if a group
1528 with the given name matched); or 4) the special symbol (R) (true when
1529 evaluated inside of recursion or eval). Additionally the R may be
1530 followed by a number, (which will be true when evaluated when recursing
1531 inside of the appropriate group), or by C<&NAME>, in which case it will
1532 be true only when evaluated during recursion in the named group.
1533
1534 Here's a summary of the possible predicates:
1535
1536 =over 4
1537
1538 =item (1) (2) ...
1539
1540 Checks if the numbered capturing group has matched something.
1541
1542 =item (<NAME>) ('NAME')
1543
1544 Checks if a group with the given name has matched something.
1545
1546 =item (?=...) (?!...) (?<=...) (?<!...)
1547
1548 Checks whether the pattern matches (or does not match, for the '!'
1549 variants).
1550
1551 =item (?{ CODE })
1552
1553 Treats the return value of the code block as the condition.
1554
1555 =item (R)
1556
1557 Checks if the expression has been evaluated inside of recursion.
1558
1559 =item (R1) (R2) ...
1560
1561 Checks if the expression has been evaluated while executing directly
1562 inside of the n-th capture group. This check is the regex equivalent of
1563
1564   if ((caller(0))[3] eq 'subname') { ... }
1565
1566 In other words, it does not check the full recursion stack.
1567
1568 =item (R&NAME)
1569
1570 Similar to C<(R1)>, this predicate checks to see if we're executing
1571 directly inside of the leftmost group with a given name (this is the same
1572 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1573 stack, but only the name of the innermost active recursion.
1574
1575 =item (DEFINE)
1576
1577 In this case, the yes-pattern is never directly executed, and no
1578 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1579 See below for details.
1580
1581 =back
1582
1583 For example:
1584
1585     m{ ( \( )?
1586        [^()]+
1587        (?(1) \) )
1588      }x
1589
1590 matches a chunk of non-parentheses, possibly included in parentheses
1591 themselves.
1592
1593 A special form is the C<(DEFINE)> predicate, which never executes its
1594 yes-pattern directly, and does not allow a no-pattern. This allows one to
1595 define subpatterns which will be executed only by the recursion mechanism.
1596 This way, you can define a set of regular expression rules that can be
1597 bundled into any pattern you choose.
1598
1599 It is recommended that for this usage you put the DEFINE block at the
1600 end of the pattern, and that you name any subpatterns defined within it.
1601
1602 Also, it's worth noting that patterns defined this way probably will
1603 not be as efficient, as the optimiser is not very clever about
1604 handling them.
1605
1606 An example of how this might be used is as follows:
1607
1608   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1609    (?(DEFINE)
1610      (?<NAME_PAT>....)
1611      (?<ADRESS_PAT>....)
1612    )/x
1613
1614 Note that capture groups matched inside of recursion are not accessible
1615 after the recursion returns, so the extra layer of capturing groups is
1616 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1617 C<$+{NAME}> would be.
1618
1619 Finally, keep in mind that subpatterns created inside a DEFINE block
1620 count towards the absolute and relative number of captures, so this:
1621
1622     my @captures = "a" =~ /(.)                  # First capture
1623                            (?(DEFINE)
1624                                (?<EXAMPLE> 1 )  # Second capture
1625                            )/x;
1626     say scalar @captures;
1627
1628 Will output 2, not 1. This is particularly important if you intend to
1629 compile the definitions with the C<qr//> operator, and later
1630 interpolate them in another pattern.
1631
1632 =item C<< (?>pattern) >>
1633 X<backtrack> X<backtracking> X<atomic> X<possessive>
1634
1635 An "independent" subexpression, one which matches the substring
1636 that a I<standalone> C<pattern> would match if anchored at the given
1637 position, and it matches I<nothing other than this substring>.  This
1638 construct is useful for optimizations of what would otherwise be
1639 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1640 It may also be useful in places where the "grab all you can, and do not
1641 give anything back" semantic is desirable.
1642
1643 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1644 (anchored at the beginning of string, as above) will match I<all>
1645 characters C<a> at the beginning of string, leaving no C<a> for
1646 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1647 since the match of the subgroup C<a*> is influenced by the following
1648 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1649 C<a*ab> will match fewer characters than a standalone C<a*>, since
1650 this makes the tail match.
1651
1652 C<< (?>pattern) >> does not disable backtracking altogether once it has
1653 matched. It is still possible to backtrack past the construct, but not
1654 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1655
1656 An effect similar to C<< (?>pattern) >> may be achieved by writing
1657 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1658 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1659 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1660 (The difference between these two constructs is that the second one
1661 uses a capturing group, thus shifting ordinals of backreferences
1662 in the rest of a regular expression.)
1663
1664 Consider this pattern:
1665
1666     m{ \(
1667           (
1668             [^()]+           # x+
1669           |
1670             \( [^()]* \)
1671           )+
1672        \)
1673      }x
1674
1675 That will efficiently match a nonempty group with matching parentheses
1676 two levels deep or less.  However, if there is no such group, it
1677 will take virtually forever on a long string.  That's because there
1678 are so many different ways to split a long string into several
1679 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1680 to a subpattern of the above pattern.  Consider how the pattern
1681 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1682 seconds, but that each extra letter doubles this time.  This
1683 exponential performance will make it appear that your program has
1684 hung.  However, a tiny change to this pattern
1685
1686     m{ \(
1687           (
1688             (?> [^()]+ )        # change x+ above to (?> x+ )
1689           |
1690             \( [^()]* \)
1691           )+
1692        \)
1693      }x
1694
1695 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1696 this yourself would be a productive exercise), but finishes in a fourth
1697 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1698 however, that, when this construct is followed by a
1699 quantifier, it currently triggers a warning message under
1700 the C<use warnings> pragma or B<-w> switch saying it
1701 C<"matches null string many times in regex">.
1702
1703 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1704 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1705 This was only 4 times slower on a string with 1000000 C<a>s.
1706
1707 The "grab all you can, and do not give anything back" semantic is desirable
1708 in many situations where on the first sight a simple C<()*> looks like
1709 the correct solution.  Suppose we parse text with comments being delimited
1710 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1711 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1712 the comment delimiter, because it may "give up" some whitespace if
1713 the remainder of the pattern can be made to match that way.  The correct
1714 answer is either one of these:
1715
1716     (?>#[ \t]*)
1717     #[ \t]*(?![ \t])
1718
1719 For example, to grab non-empty comments into $1, one should use either
1720 one of these:
1721
1722     / (?> \# [ \t]* ) (        .+ ) /x;
1723     /     \# [ \t]*   ( [^ \t] .* ) /x;
1724
1725 Which one you pick depends on which of these expressions better reflects
1726 the above specification of comments.
1727
1728 In some literature this construct is called "atomic matching" or
1729 "possessive matching".
1730
1731 Possessive quantifiers are equivalent to putting the item they are applied
1732 to inside of one of these constructs. The following equivalences apply:
1733
1734     Quantifier Form     Bracketing Form
1735     ---------------     ---------------
1736     PAT*+               (?>PAT*)
1737     PAT++               (?>PAT+)
1738     PAT?+               (?>PAT?)
1739     PAT{min,max}+       (?>PAT{min,max})
1740
1741 =item C<(?[ ])>
1742
1743 See L<perlrecharclass/Extended Bracketed Character Classes>.
1744
1745 =back
1746
1747 =head2 Special Backtracking Control Verbs
1748
1749 B<WARNING:> These patterns are experimental and subject to change or
1750 removal in a future version of Perl. Their usage in production code should
1751 be noted to avoid problems during upgrades.
1752
1753 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1754 otherwise stated the ARG argument is optional; in some cases, it is
1755 forbidden.
1756
1757 Any pattern containing a special backtracking verb that allows an argument
1758 has the special behaviour that when executed it sets the current package's
1759 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1760 rules apply:
1761
1762 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1763 verb pattern, if the verb was involved in the failure of the match. If the
1764 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1765 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1766 none. Also, the C<$REGMARK> variable will be set to FALSE.
1767
1768 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1769 the C<$REGMARK> variable will be set to the name of the last
1770 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1771 C<(*MARK:NAME)> verb below for more details.
1772
1773 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1774 and most other regex-related variables. They are not local to a scope, nor
1775 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1776 Use C<local> to localize changes to them to a specific scope if necessary.
1777
1778 If a pattern does not contain a special backtracking verb that allows an
1779 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1780
1781 =over 3
1782
1783 =item Verbs that take an argument
1784
1785 =over 4
1786
1787 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1788 X<(*PRUNE)> X<(*PRUNE:NAME)>
1789
1790 This zero-width pattern prunes the backtracking tree at the current point
1791 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1792 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1793 A may backtrack as necessary to match. Once it is reached, matching
1794 continues in B, which may also backtrack as necessary; however, should B
1795 not match, then no further backtracking will take place, and the pattern
1796 will fail outright at the current starting position.
1797
1798 The following example counts all the possible matching strings in a
1799 pattern (without actually matching any of them).
1800
1801     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1802     print "Count=$count\n";
1803
1804 which produces:
1805
1806     aaab
1807     aaa
1808     aa
1809     a
1810     aab
1811     aa
1812     a
1813     ab
1814     a
1815     Count=9
1816
1817 If we add a C<(*PRUNE)> before the count like the following
1818
1819     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1820     print "Count=$count\n";
1821
1822 we prevent backtracking and find the count of the longest matching string
1823 at each matching starting point like so:
1824
1825     aaab
1826     aab
1827     ab
1828     Count=3
1829
1830 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1831
1832 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1833 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1834 replaced with a C<< (?>pattern) >> with no functional difference; however,
1835 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1836 C<< (?>pattern) >> alone.
1837
1838 =item C<(*SKIP)> C<(*SKIP:NAME)>
1839 X<(*SKIP)>
1840
1841 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1842 failure it also signifies that whatever text that was matched leading up
1843 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1844 of this pattern. This effectively means that the regex engine "skips" forward
1845 to this position on failure and tries to match again, (assuming that
1846 there is sufficient room to match).
1847
1848 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1849 C<(*MARK:NAME)> was encountered while matching, then it is that position
1850 which is used as the "skip point". If no C<(*MARK)> of that name was
1851 encountered, then the C<(*SKIP)> operator has no effect. When used
1852 without a name the "skip point" is where the match point was when
1853 executing the (*SKIP) pattern.
1854
1855 Compare the following to the examples in C<(*PRUNE)>; note the string
1856 is twice as long:
1857
1858  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1859  print "Count=$count\n";
1860
1861 outputs
1862
1863     aaab
1864     aaab
1865     Count=2
1866
1867 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1868 executed, the next starting point will be where the cursor was when the
1869 C<(*SKIP)> was executed.
1870
1871 =item C<(*MARK:NAME)> C<(*:NAME)>
1872 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1873
1874 This zero-width pattern can be used to mark the point reached in a string
1875 when a certain part of the pattern has been successfully matched. This
1876 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1877 forward to that point if backtracked into on failure. Any number of
1878 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1879
1880 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1881 can be used to "label" a pattern branch, so that after matching, the
1882 program can determine which branches of the pattern were involved in the
1883 match.
1884
1885 When a match is successful, the C<$REGMARK> variable will be set to the
1886 name of the most recently executed C<(*MARK:NAME)> that was involved
1887 in the match.
1888
1889 This can be used to determine which branch of a pattern was matched
1890 without using a separate capture group for each branch, which in turn
1891 can result in a performance improvement, as perl cannot optimize
1892 C</(?:(x)|(y)|(z))/> as efficiently as something like
1893 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1894
1895 When a match has failed, and unless another verb has been involved in
1896 failing the match and has provided its own name to use, the C<$REGERROR>
1897 variable will be set to the name of the most recently executed
1898 C<(*MARK:NAME)>.
1899
1900 See L</(*SKIP)> for more details.
1901
1902 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1903
1904 =item C<(*THEN)> C<(*THEN:NAME)>
1905
1906 This is similar to the "cut group" operator C<::> from Perl 6.  Like
1907 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1908 failure, it causes the regex engine to try the next alternation in the
1909 innermost enclosing group (capturing or otherwise) that has alternations.
1910 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
1911 count as an alternation, as far as C<(*THEN)> is concerned.
1912
1913 Its name comes from the observation that this operation combined with the
1914 alternation operator (C<|>) can be used to create what is essentially a
1915 pattern-based if/then/else block:
1916
1917   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1918
1919 Note that if this operator is used and NOT inside of an alternation then
1920 it acts exactly like the C<(*PRUNE)> operator.
1921
1922   / A (*PRUNE) B /
1923
1924 is the same as
1925
1926   / A (*THEN) B /
1927
1928 but
1929
1930   / ( A (*THEN) B | C ) /
1931
1932 is not the same as
1933
1934   / ( A (*PRUNE) B | C ) /
1935
1936 as after matching the A but failing on the B the C<(*THEN)> verb will
1937 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1938
1939 =back
1940
1941 =item Verbs without an argument
1942
1943 =over 4
1944
1945 =item C<(*COMMIT)>
1946 X<(*COMMIT)>
1947
1948 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1949 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1950 into on failure it causes the match to fail outright. No further attempts
1951 to find a valid match by advancing the start pointer will occur again.
1952 For example,
1953
1954  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1955  print "Count=$count\n";
1956
1957 outputs
1958
1959     aaab
1960     Count=1
1961
1962 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1963 does not match, the regex engine will not try any further matching on the
1964 rest of the string.
1965
1966 =item C<(*FAIL)> C<(*F)>
1967 X<(*FAIL)> X<(*F)>
1968
1969 This pattern matches nothing and always fails. It can be used to force the
1970 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1971 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1972
1973 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1974
1975 =item C<(*ACCEPT)>
1976 X<(*ACCEPT)>
1977
1978 B<WARNING:> This feature is highly experimental. It is not recommended
1979 for production code.
1980
1981 This pattern matches nothing and causes the end of successful matching at
1982 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1983 whether there is actually more to match in the string. When inside of a
1984 nested pattern, such as recursion, or in a subpattern dynamically generated
1985 via C<(??{})>, only the innermost pattern is ended immediately.
1986
1987 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1988 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1989 For instance:
1990
1991   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1992
1993 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1994 be set. If another branch in the inner parentheses was matched, such as in the
1995 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1996
1997 =back
1998
1999 =back
2000
2001 =head2 Backtracking
2002 X<backtrack> X<backtracking>
2003
2004 NOTE: This section presents an abstract approximation of regular
2005 expression behavior.  For a more rigorous (and complicated) view of
2006 the rules involved in selecting a match among possible alternatives,
2007 see L<Combining RE Pieces>.
2008
2009 A fundamental feature of regular expression matching involves the
2010 notion called I<backtracking>, which is currently used (when needed)
2011 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
2012 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2013 internally, but the general principle outlined here is valid.
2014
2015 For a regular expression to match, the I<entire> regular expression must
2016 match, not just part of it.  So if the beginning of a pattern containing a
2017 quantifier succeeds in a way that causes later parts in the pattern to
2018 fail, the matching engine backs up and recalculates the beginning
2019 part--that's why it's called backtracking.
2020
2021 Here is an example of backtracking:  Let's say you want to find the
2022 word following "foo" in the string "Food is on the foo table.":
2023
2024     $_ = "Food is on the foo table.";
2025     if ( /\b(foo)\s+(\w+)/i ) {
2026         print "$2 follows $1.\n";
2027     }
2028
2029 When the match runs, the first part of the regular expression (C<\b(foo)>)
2030 finds a possible match right at the beginning of the string, and loads up
2031 $1 with "Foo".  However, as soon as the matching engine sees that there's
2032 no whitespace following the "Foo" that it had saved in $1, it realizes its
2033 mistake and starts over again one character after where it had the
2034 tentative match.  This time it goes all the way until the next occurrence
2035 of "foo". The complete regular expression matches this time, and you get
2036 the expected output of "table follows foo."
2037
2038 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2039 everything between "foo" and "bar".  Initially, you write something
2040 like this:
2041
2042     $_ =  "The food is under the bar in the barn.";
2043     if ( /foo(.*)bar/ ) {
2044         print "got <$1>\n";
2045     }
2046
2047 Which perhaps unexpectedly yields:
2048
2049   got <d is under the bar in the >
2050
2051 That's because C<.*> was greedy, so you get everything between the
2052 I<first> "foo" and the I<last> "bar".  Here it's more effective
2053 to use minimal matching to make sure you get the text between a "foo"
2054 and the first "bar" thereafter.
2055
2056     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2057   got <d is under the >
2058
2059 Here's another example. Let's say you'd like to match a number at the end
2060 of a string, and you also want to keep the preceding part of the match.
2061 So you write this:
2062
2063     $_ = "I have 2 numbers: 53147";
2064     if ( /(.*)(\d*)/ ) {                                # Wrong!
2065         print "Beginning is <$1>, number is <$2>.\n";
2066     }
2067
2068 That won't work at all, because C<.*> was greedy and gobbled up the
2069 whole string. As C<\d*> can match on an empty string the complete
2070 regular expression matched successfully.
2071
2072     Beginning is <I have 2 numbers: 53147>, number is <>.
2073
2074 Here are some variants, most of which don't work:
2075
2076     $_ = "I have 2 numbers: 53147";
2077     @pats = qw{
2078         (.*)(\d*)
2079         (.*)(\d+)
2080         (.*?)(\d*)
2081         (.*?)(\d+)
2082         (.*)(\d+)$
2083         (.*?)(\d+)$
2084         (.*)\b(\d+)$
2085         (.*\D)(\d+)$
2086     };
2087
2088     for $pat (@pats) {
2089         printf "%-12s ", $pat;
2090         if ( /$pat/ ) {
2091             print "<$1> <$2>\n";
2092         } else {
2093             print "FAIL\n";
2094         }
2095     }
2096
2097 That will print out:
2098
2099     (.*)(\d*)    <I have 2 numbers: 53147> <>
2100     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2101     (.*?)(\d*)   <> <>
2102     (.*?)(\d+)   <I have > <2>
2103     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2104     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2105     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2106     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2107
2108 As you see, this can be a bit tricky.  It's important to realize that a
2109 regular expression is merely a set of assertions that gives a definition
2110 of success.  There may be 0, 1, or several different ways that the
2111 definition might succeed against a particular string.  And if there are
2112 multiple ways it might succeed, you need to understand backtracking to
2113 know which variety of success you will achieve.
2114
2115 When using look-ahead assertions and negations, this can all get even
2116 trickier.  Imagine you'd like to find a sequence of non-digits not
2117 followed by "123".  You might try to write that as
2118
2119     $_ = "ABC123";
2120     if ( /^\D*(?!123)/ ) {                # Wrong!
2121         print "Yup, no 123 in $_\n";
2122     }
2123
2124 But that isn't going to match; at least, not the way you're hoping.  It
2125 claims that there is no 123 in the string.  Here's a clearer picture of
2126 why that pattern matches, contrary to popular expectations:
2127
2128     $x = 'ABC123';
2129     $y = 'ABC445';
2130
2131     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2132     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2133
2134     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2135     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2136
2137 This prints
2138
2139     2: got ABC
2140     3: got AB
2141     4: got ABC
2142
2143 You might have expected test 3 to fail because it seems to a more
2144 general purpose version of test 1.  The important difference between
2145 them is that test 3 contains a quantifier (C<\D*>) and so can use
2146 backtracking, whereas test 1 will not.  What's happening is
2147 that you've asked "Is it true that at the start of $x, following 0 or more
2148 non-digits, you have something that's not 123?"  If the pattern matcher had
2149 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2150 fail.
2151
2152 The search engine will initially match C<\D*> with "ABC".  Then it will
2153 try to match C<(?!123)> with "123", which fails.  But because
2154 a quantifier (C<\D*>) has been used in the regular expression, the
2155 search engine can backtrack and retry the match differently
2156 in the hope of matching the complete regular expression.
2157
2158 The pattern really, I<really> wants to succeed, so it uses the
2159 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2160 time.  Now there's indeed something following "AB" that is not
2161 "123".  It's "C123", which suffices.
2162
2163 We can deal with this by using both an assertion and a negation.
2164 We'll say that the first part in $1 must be followed both by a digit
2165 and by something that's not "123".  Remember that the look-aheads
2166 are zero-width expressions--they only look, but don't consume any
2167 of the string in their match.  So rewriting this way produces what
2168 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2169
2170     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2171     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2172
2173     6: got ABC
2174
2175 In other words, the two zero-width assertions next to each other work as though
2176 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2177 matches only if you're at the beginning of the line AND the end of the
2178 line simultaneously.  The deeper underlying truth is that juxtaposition in
2179 regular expressions always means AND, except when you write an explicit OR
2180 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2181 although the attempted matches are made at different positions because "a"
2182 is not a zero-width assertion, but a one-width assertion.
2183
2184 B<WARNING>: Particularly complicated regular expressions can take
2185 exponential time to solve because of the immense number of possible
2186 ways they can use backtracking to try for a match.  For example, without
2187 internal optimizations done by the regular expression engine, this will
2188 take a painfully long time to run:
2189
2190     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2191
2192 And if you used C<*>'s in the internal groups instead of limiting them
2193 to 0 through 5 matches, then it would take forever--or until you ran
2194 out of stack space.  Moreover, these internal optimizations are not
2195 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2196 on the external group, no current optimization is applicable, and the
2197 match takes a long time to finish.
2198
2199 A powerful tool for optimizing such beasts is what is known as an
2200 "independent group",
2201 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2202 zero-length look-ahead/look-behind assertions will not backtrack to make
2203 the tail match, since they are in "logical" context: only
2204 whether they match is considered relevant.  For an example
2205 where side-effects of look-ahead I<might> have influenced the
2206 following match, see L</C<< (?>pattern) >>>.
2207
2208 =head2 Version 8 Regular Expressions
2209 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2210
2211 In case you're not familiar with the "regular" Version 8 regex
2212 routines, here are the pattern-matching rules not described above.
2213
2214 Any single character matches itself, unless it is a I<metacharacter>
2215 with a special meaning described here or above.  You can cause
2216 characters that normally function as metacharacters to be interpreted
2217 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2218 character; "\\" matches a "\"). This escape mechanism is also required
2219 for the character used as the pattern delimiter.
2220
2221 A series of characters matches that series of characters in the target
2222 string, so the pattern C<blurfl> would match "blurfl" in the target
2223 string.
2224
2225 You can specify a character class, by enclosing a list of characters
2226 in C<[]>, which will match any character from the list.  If the
2227 first character after the "[" is "^", the class matches any character not
2228 in the list.  Within a list, the "-" character specifies a
2229 range, so that C<a-z> represents all characters between "a" and "z",
2230 inclusive.  If you want either "-" or "]" itself to be a member of a
2231 class, put it at the start of the list (possibly after a "^"), or
2232 escape it with a backslash.  "-" is also taken literally when it is
2233 at the end of the list, just before the closing "]".  (The
2234 following all specify the same class of three characters: C<[-az]>,
2235 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2236 specifies a class containing twenty-six characters, even on EBCDIC-based
2237 character sets.)  Also, if you try to use the character
2238 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2239 a range, the "-" is understood literally.
2240
2241 Note also that the whole range idea is rather unportable between
2242 character sets--and even within character sets they may cause results
2243 you probably didn't expect.  A sound principle is to use only ranges
2244 that begin from and end at either alphabetics of equal case ([a-e],
2245 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
2246 spell out the character sets in full.
2247
2248 Characters may be specified using a metacharacter syntax much like that
2249 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2250 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2251 of three octal digits, matches the character whose coded character set value
2252 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2253 matches the character whose ordinal is I<nn>. The expression \cI<x>
2254 matches the character control-I<x>.  Finally, the "." metacharacter
2255 matches any character except "\n" (unless you use C</s>).
2256
2257 You can specify a series of alternatives for a pattern using "|" to
2258 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2259 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2260 first alternative includes everything from the last pattern delimiter
2261 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2262 the last alternative contains everything from the last "|" to the next
2263 closing pattern delimiter.  That's why it's common practice to include
2264 alternatives in parentheses: to minimize confusion about where they
2265 start and end.
2266
2267 Alternatives are tried from left to right, so the first
2268 alternative found for which the entire expression matches, is the one that
2269 is chosen. This means that alternatives are not necessarily greedy. For
2270 example: when matching C<foo|foot> against "barefoot", only the "foo"
2271 part will match, as that is the first alternative tried, and it successfully
2272 matches the target string. (This might not seem important, but it is
2273 important when you are capturing matched text using parentheses.)
2274
2275 Also remember that "|" is interpreted as a literal within square brackets,
2276 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2277
2278 Within a pattern, you may designate subpatterns for later reference
2279 by enclosing them in parentheses, and you may refer back to the
2280 I<n>th subpattern later in the pattern using the metacharacter
2281 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2282 of their opening parenthesis.  A backreference matches whatever
2283 actually matched the subpattern in the string being examined, not
2284 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2285 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2286 1 matched "0x", even though the rule C<0|0x> could potentially match
2287 the leading 0 in the second number.
2288
2289 =head2 Warning on \1 Instead of $1
2290
2291 Some people get too used to writing things like:
2292
2293     $pattern =~ s/(\W)/\\\1/g;
2294
2295 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2296 shocking the
2297 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2298 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2299 the usual double-quoted string means a control-A.  The customary Unix
2300 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2301 of doing that, you get yourself into trouble if you then add an C</e>
2302 modifier.
2303
2304     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2305
2306 Or if you try to do
2307
2308     s/(\d+)/\1000/;
2309
2310 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2311 C<${1}000>.  The operation of interpolation should not be confused
2312 with the operation of matching a backreference.  Certainly they mean two
2313 different things on the I<left> side of the C<s///>.
2314
2315 =head2 Repeated Patterns Matching a Zero-length Substring
2316
2317 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2318
2319 Regular expressions provide a terse and powerful programming language.  As
2320 with most other power tools, power comes together with the ability
2321 to wreak havoc.
2322
2323 A common abuse of this power stems from the ability to make infinite
2324 loops using regular expressions, with something as innocuous as:
2325
2326     'foo' =~ m{ ( o? )* }x;
2327
2328 The C<o?> matches at the beginning of C<'foo'>, and since the position
2329 in the string is not moved by the match, C<o?> would match again and again
2330 because of the C<*> quantifier.  Another common way to create a similar cycle
2331 is with the looping modifier C<//g>:
2332
2333     @matches = ( 'foo' =~ m{ o? }xg );
2334
2335 or
2336
2337     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2338
2339 or the loop implied by split().
2340
2341 However, long experience has shown that many programming tasks may
2342 be significantly simplified by using repeated subexpressions that
2343 may match zero-length substrings.  Here's a simple example being:
2344
2345     @chars = split //, $string;           # // is not magic in split
2346     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2347
2348 Thus Perl allows such constructs, by I<forcefully breaking
2349 the infinite loop>.  The rules for this are different for lower-level
2350 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2351 ones like the C</g> modifier or split() operator.
2352
2353 The lower-level loops are I<interrupted> (that is, the loop is
2354 broken) when Perl detects that a repeated expression matched a
2355 zero-length substring.   Thus
2356
2357    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2358
2359 is made equivalent to
2360
2361    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2362
2363 For example, this program
2364
2365    #!perl -l
2366    "aaaaab" =~ /
2367      (?:
2368         a                 # non-zero
2369         |                 # or
2370        (?{print "hello"}) # print hello whenever this
2371                           #    branch is tried
2372        (?=(b))            # zero-width assertion
2373      )*  # any number of times
2374     /x;
2375    print $&;
2376    print $1;
2377
2378 prints
2379
2380    hello
2381    aaaaa
2382    b
2383
2384 Notice that "hello" is only printed once, as when Perl sees that the sixth
2385 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2386 the C<*>.
2387
2388 The higher-level loops preserve an additional state between iterations:
2389 whether the last match was zero-length.  To break the loop, the following
2390 match after a zero-length match is prohibited to have a length of zero.
2391 This prohibition interacts with backtracking (see L<"Backtracking">),
2392 and so the I<second best> match is chosen if the I<best> match is of
2393 zero length.
2394
2395 For example:
2396
2397     $_ = 'bar';
2398     s/\w??/<$&>/g;
2399
2400 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2401 match given by non-greedy C<??> is the zero-length match, and the I<second
2402 best> match is what is matched by C<\w>.  Thus zero-length matches
2403 alternate with one-character-long matches.
2404
2405 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2406 position one notch further in the string.
2407
2408 The additional state of being I<matched with zero-length> is associated with
2409 the matched string, and is reset by each assignment to pos().
2410 Zero-length matches at the end of the previous match are ignored
2411 during C<split>.
2412
2413 =head2 Combining RE Pieces
2414
2415 Each of the elementary pieces of regular expressions which were described
2416 before (such as C<ab> or C<\Z>) could match at most one substring
2417 at the given position of the input string.  However, in a typical regular
2418 expression these elementary pieces are combined into more complicated
2419 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2420 (in these examples C<S> and C<T> are regular subexpressions).
2421
2422 Such combinations can include alternatives, leading to a problem of choice:
2423 if we match a regular expression C<a|ab> against C<"abc">, will it match
2424 substring C<"a"> or C<"ab">?  One way to describe which substring is
2425 actually matched is the concept of backtracking (see L<"Backtracking">).
2426 However, this description is too low-level and makes you think
2427 in terms of a particular implementation.
2428
2429 Another description starts with notions of "better"/"worse".  All the
2430 substrings which may be matched by the given regular expression can be
2431 sorted from the "best" match to the "worst" match, and it is the "best"
2432 match which is chosen.  This substitutes the question of "what is chosen?"
2433 by the question of "which matches are better, and which are worse?".
2434
2435 Again, for elementary pieces there is no such question, since at most
2436 one match at a given position is possible.  This section describes the
2437 notion of better/worse for combining operators.  In the description
2438 below C<S> and C<T> are regular subexpressions.
2439
2440 =over 4
2441
2442 =item C<ST>
2443
2444 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2445 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2446 which can be matched by C<T>.
2447
2448 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2449 match than C<A'B'>.
2450
2451 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2452 C<B> is a better match for C<T> than C<B'>.
2453
2454 =item C<S|T>
2455
2456 When C<S> can match, it is a better match than when only C<T> can match.
2457
2458 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2459 two matches for C<T>.
2460
2461 =item C<S{REPEAT_COUNT}>
2462
2463 Matches as C<SSS...S> (repeated as many times as necessary).
2464
2465 =item C<S{min,max}>
2466
2467 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2468
2469 =item C<S{min,max}?>
2470
2471 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2472
2473 =item C<S?>, C<S*>, C<S+>
2474
2475 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2476
2477 =item C<S??>, C<S*?>, C<S+?>
2478
2479 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2480
2481 =item C<< (?>S) >>
2482
2483 Matches the best match for C<S> and only that.
2484
2485 =item C<(?=S)>, C<(?<=S)>
2486
2487 Only the best match for C<S> is considered.  (This is important only if
2488 C<S> has capturing parentheses, and backreferences are used somewhere
2489 else in the whole regular expression.)
2490
2491 =item C<(?!S)>, C<(?<!S)>
2492
2493 For this grouping operator there is no need to describe the ordering, since
2494 only whether or not C<S> can match is important.
2495
2496 =item C<(??{ EXPR })>, C<(?PARNO)>
2497
2498 The ordering is the same as for the regular expression which is
2499 the result of EXPR, or the pattern contained by capture group PARNO.
2500
2501 =item C<(?(condition)yes-pattern|no-pattern)>
2502
2503 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2504 already determined.  The ordering of the matches is the same as for the
2505 chosen subexpression.
2506
2507 =back
2508
2509 The above recipes describe the ordering of matches I<at a given position>.
2510 One more rule is needed to understand how a match is determined for the
2511 whole regular expression: a match at an earlier position is always better
2512 than a match at a later position.
2513
2514 =head2 Creating Custom RE Engines
2515
2516 As of Perl 5.10.0, one can create custom regular expression engines.  This
2517 is not for the faint of heart, as they have to plug in at the C level.  See
2518 L<perlreapi> for more details.
2519
2520 As an alternative, overloaded constants (see L<overload>) provide a simple
2521 way to extend the functionality of the RE engine, by substituting one
2522 pattern for another.
2523
2524 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2525 matches at a boundary between whitespace characters and non-whitespace
2526 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2527 at these positions, so we want to have each C<\Y|> in the place of the
2528 more complicated version.  We can create a module C<customre> to do
2529 this:
2530
2531     package customre;
2532     use overload;
2533
2534     sub import {
2535       shift;
2536       die "No argument to customre::import allowed" if @_;
2537       overload::constant 'qr' => \&convert;
2538     }
2539
2540     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2541
2542     # We must also take care of not escaping the legitimate \\Y|
2543     # sequence, hence the presence of '\\' in the conversion rules.
2544     my %rules = ( '\\' => '\\\\',
2545                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2546     sub convert {
2547       my $re = shift;
2548       $re =~ s{
2549                 \\ ( \\ | Y . )
2550               }
2551               { $rules{$1} or invalid($re,$1) }sgex;
2552       return $re;
2553     }
2554
2555 Now C<use customre> enables the new escape in constant regular
2556 expressions, i.e., those without any runtime variable interpolations.
2557 As documented in L<overload>, this conversion will work only over
2558 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2559 part of this regular expression needs to be converted explicitly
2560 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2561
2562     use customre;
2563     $re = <>;
2564     chomp $re;
2565     $re = customre::convert $re;
2566     /\Y|$re\Y|/;
2567
2568 =head2 PCRE/Python Support
2569
2570 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2571 to the regex syntax. While Perl programmers are encouraged to use the
2572 Perl-specific syntax, the following are also accepted:
2573
2574 =over 4
2575
2576 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2577
2578 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2579
2580 =item C<< (?P=NAME) >>
2581
2582 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2583
2584 =item C<< (?P>NAME) >>
2585
2586 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2587
2588 =back
2589
2590 =head1 BUGS
2591
2592 Many regular expression constructs don't work on EBCDIC platforms.
2593
2594 There are a number of issues with regard to case-insensitive matching
2595 in Unicode rules.  See C<i> under L</Modifiers> above.
2596
2597 This document varies from difficult to understand to completely
2598 and utterly opaque.  The wandering prose riddled with jargon is
2599 hard to fathom in several places.
2600
2601 This document needs a rewrite that separates the tutorial content
2602 from the reference content.
2603
2604 =head1 SEE ALSO
2605
2606 L<perlrequick>.
2607
2608 L<perlretut>.
2609
2610 L<perlop/"Regexp Quote-Like Operators">.
2611
2612 L<perlop/"Gory details of parsing quoted constructs">.
2613
2614 L<perlfaq6>.
2615
2616 L<perlfunc/pos>.
2617
2618 L<perllocale>.
2619
2620 L<perlebcdic>.
2621
2622 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2623 by O'Reilly and Associates.