This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
216f83cd206c22b8baca72b165ca4a6c8d3ad930
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2
3 perlop - Perl operators and precedence
4
5 =head1 SYNOPSIS
6
7 Perl operators have the following associativity and precedence,
8 listed from highest precedence to lowest.  Note that all operators
9 borrowed from C keep the same precedence relationship with each other,
10 even where C's precedence is slightly screwy.  (This makes learning
11 Perl easier for C folks.)  With very few exceptions, these all
12 operate on scalar values only, not array values.
13
14     left        terms and list operators (leftward)
15     left        ->
16     nonassoc    ++ --
17     right       **
18     right       ! ~ \ and unary + and -
19     left        =~ !~
20     left        * / % x
21     left        + - .
22     left        << >>
23     nonassoc    named unary operators
24     nonassoc    < > <= >= lt gt le ge
25     nonassoc    == != <=> eq ne cmp
26     left        &
27     left        | ^
28     left        &&
29     left        ||
30     nonassoc    ..  ...
31     right       ?:
32     right       = += -= *= etc.
33     left        , =>
34     nonassoc    list operators (rightward)
35     right       not
36     left        and
37     left        or xor
38
39 In the following sections, these operators are covered in precedence order.
40
41 Many operators can be overloaded for objects.  See L<overload>.
42
43 =head1 DESCRIPTION
44
45 =head2 Terms and List Operators (Leftward)
46
47 A TERM has the highest precedence in Perl.  They includes variables,
48 quote and quote-like operators, any expression in parentheses,
49 and any function whose arguments are parenthesized.  Actually, there
50 aren't really functions in this sense, just list operators and unary
51 operators behaving as functions because you put parentheses around
52 the arguments.  These are all documented in L<perlfunc>.
53
54 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
55 is followed by a left parenthesis as the next token, the operator and
56 arguments within parentheses are taken to be of highest precedence,
57 just like a normal function call.
58
59 In the absence of parentheses, the precedence of list operators such as
60 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
61 whether you are looking at the left side or the right side of the operator.
62 For example, in
63
64     @ary = (1, 3, sort 4, 2);
65     print @ary;         # prints 1324
66
67 the commas on the right of the sort are evaluated before the sort, but
68 the commas on the left are evaluated after.  In other words, list
69 operators tend to gobble up all the arguments that follow them, and
70 then act like a simple TERM with regard to the preceding expression.
71 Note that you have to be careful with parentheses:
72
73     # These evaluate exit before doing the print:
74     print($foo, exit);  # Obviously not what you want.
75     print $foo, exit;   # Nor is this.
76
77     # These do the print before evaluating exit:
78     (print $foo), exit; # This is what you want.
79     print($foo), exit;  # Or this.
80     print ($foo), exit; # Or even this.
81
82 Also note that
83
84     print ($foo & 255) + 1, "\n";
85
86 probably doesn't do what you expect at first glance.  See
87 L<Named Unary Operators> for more discussion of this.
88
89 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
90 well as subroutine and method calls, and the anonymous
91 constructors C<[]> and C<{}>.
92
93 See also L<Quote and Quote-like Operators> toward the end of this section,
94 as well as L<"I/O Operators">.
95
96 =head2 The Arrow Operator
97
98 Just as in C and C++, "C<-E<gt>>" is an infix dereference operator.  If the
99 right side is either a C<[...]> or C<{...}> subscript, then the left side
100 must be either a hard or symbolic reference to an array or hash (or
101 a location capable of holding a hard reference, if it's an lvalue (assignable)).
102 See L<perlref>.
103
104 Otherwise, the right side is a method name or a simple scalar variable
105 containing the method name, and the left side must either be an object
106 (a blessed reference) or a class name (that is, a package name).
107 See L<perlobj>.
108
109 =head2 Auto-increment and Auto-decrement
110
111 "++" and "--" work as in C.  That is, if placed before a variable, they
112 increment or decrement the variable before returning the value, and if
113 placed after, increment or decrement the variable after returning the value.
114
115 The auto-increment operator has a little extra builtin magic to it.  If
116 you increment a variable that is numeric, or that has ever been used in
117 a numeric context, you get a normal increment.  If, however, the
118 variable has been used in only string contexts since it was set, and
119 has a value that is not the empty string and matches the pattern
120 C</^[a-zA-Z]*[0-9]*$/>, the increment is done as a string, preserving each
121 character within its range, with carry:
122
123     print ++($foo = '99');      # prints '100'
124     print ++($foo = 'a0');      # prints 'a1'
125     print ++($foo = 'Az');      # prints 'Ba'
126     print ++($foo = 'zz');      # prints 'aaa'
127
128 The auto-decrement operator is not magical.
129
130 =head2 Exponentiation
131
132 Binary "**" is the exponentiation operator.  Note that it binds even more
133 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
134 implemented using C's pow(3) function, which actually works on doubles
135 internally.)
136
137 =head2 Symbolic Unary Operators
138
139 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
140 precedence version of this.
141
142 Unary "-" performs arithmetic negation if the operand is numeric.  If
143 the operand is an identifier, a string consisting of a minus sign
144 concatenated with the identifier is returned.  Otherwise, if the string
145 starts with a plus or minus, a string starting with the opposite sign
146 is returned.  One effect of these rules is that C<-bareword> is equivalent
147 to C<"-bareword">.
148
149 Unary "~" performs bitwise negation, i.e., 1's complement.  For example,
150 C<0666 &~ 027> is 0640.  (See also L<Integer Arithmetic> and L<Bitwise
151 String Operators>.)
152
153 Unary "+" has no effect whatsoever, even on strings.  It is useful
154 syntactically for separating a function name from a parenthesized expression
155 that would otherwise be interpreted as the complete list of function
156 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
157
158 Unary "\" creates a reference to whatever follows it.  See L<perlref>.
159 Do not confuse this behavior with the behavior of backslash within a
160 string, although both forms do convey the notion of protecting the next
161 thing from interpretation.
162
163 =head2 Binding Operators
164
165 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
166 search or modify the string $_ by default.  This operator makes that kind
167 of operation work on some other string.  The right argument is a search
168 pattern, substitution, or transliteration.  The left argument is what is
169 supposed to be searched, substituted, or transliterated instead of the default
170 $_.  The return value indicates the success of the operation.  (If the
171 right argument is an expression rather than a search pattern,
172 substitution, or transliteration, it is interpreted as a search pattern at run
173 time.  This can be is less efficient than an explicit search, because the
174 pattern must be compiled every time the expression is evaluated.
175
176 Binary "!~" is just like "=~" except the return value is negated in
177 the logical sense.
178
179 =head2 Multiplicative Operators
180
181 Binary "*" multiplies two numbers.
182
183 Binary "/" divides two numbers.
184
185 Binary "%" computes the modulus of two numbers.  Given integer
186 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
187 C<$a> minus the largest multiple of C<$b> that is not greater than
188 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
189 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
190 result will be less than or equal to zero).  If C<use integer> is
191 in effect, the native hardware will be used instead of this rule,
192 which may be construed a bug that will be fixed at some point.
193
194 Note than when C<use integer> is in scope, "%" give you direct access
195 to the modulus operator as implemented by your C compiler.  This
196 operator is not as well defined for negative operands, but it will
197 execute faster.
198
199 Binary "x" is the repetition operator.  In scalar context, it
200 returns a string consisting of the left operand repeated the number of
201 times specified by the right operand.  In list context, if the left
202 operand is a list in parentheses, it repeats the list.
203
204     print '-' x 80;             # print row of dashes
205
206     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
207
208     @ones = (1) x 80;           # a list of 80 1's
209     @ones = (5) x @ones;        # set all elements to 5
210
211
212 =head2 Additive Operators
213
214 Binary "+" returns the sum of two numbers.
215
216 Binary "-" returns the difference of two numbers.
217
218 Binary "." concatenates two strings.
219
220 =head2 Shift Operators
221
222 Binary "<<" returns the value of its left argument shifted left by the
223 number of bits specified by the right argument.  Arguments should be
224 integers.  (See also L<Integer Arithmetic>.)
225
226 Binary ">>" returns the value of its left argument shifted right by
227 the number of bits specified by the right argument.  Arguments should
228 be integers.  (See also L<Integer Arithmetic>.)
229
230 =head2 Named Unary Operators
231
232 The various named unary operators are treated as functions with one
233 argument, with optional parentheses.  These include the filetest
234 operators, like C<-f>, C<-M>, etc.  See L<perlfunc>.
235
236 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
237 is followed by a left parenthesis as the next token, the operator and
238 arguments within parentheses are taken to be of highest precedence,
239 just like a normal function call.  Examples:
240
241     chdir $foo    || die;       # (chdir $foo) || die
242     chdir($foo)   || die;       # (chdir $foo) || die
243     chdir ($foo)  || die;       # (chdir $foo) || die
244     chdir +($foo) || die;       # (chdir $foo) || die
245
246 but, because * is higher precedence than ||:
247
248     chdir $foo * 20;    # chdir ($foo * 20)
249     chdir($foo) * 20;   # (chdir $foo) * 20
250     chdir ($foo) * 20;  # (chdir $foo) * 20
251     chdir +($foo) * 20; # chdir ($foo * 20)
252
253     rand 10 * 20;       # rand (10 * 20)
254     rand(10) * 20;      # (rand 10) * 20
255     rand (10) * 20;     # (rand 10) * 20
256     rand +(10) * 20;    # rand (10 * 20)
257
258 See also L<"Terms and List Operators (Leftward)">.
259
260 =head2 Relational Operators
261
262 Binary "E<lt>" returns true if the left argument is numerically less than
263 the right argument.
264
265 Binary "E<gt>" returns true if the left argument is numerically greater
266 than the right argument.
267
268 Binary "E<lt>=" returns true if the left argument is numerically less than
269 or equal to the right argument.
270
271 Binary "E<gt>=" returns true if the left argument is numerically greater
272 than or equal to the right argument.
273
274 Binary "lt" returns true if the left argument is stringwise less than
275 the right argument.
276
277 Binary "gt" returns true if the left argument is stringwise greater
278 than the right argument.
279
280 Binary "le" returns true if the left argument is stringwise less than
281 or equal to the right argument.
282
283 Binary "ge" returns true if the left argument is stringwise greater
284 than or equal to the right argument.
285
286 =head2 Equality Operators
287
288 Binary "==" returns true if the left argument is numerically equal to
289 the right argument.
290
291 Binary "!=" returns true if the left argument is numerically not equal
292 to the right argument.
293
294 Binary "E<lt>=E<gt>" returns -1, 0, or 1 depending on whether the left
295 argument is numerically less than, equal to, or greater than the right
296 argument.
297
298 Binary "eq" returns true if the left argument is stringwise equal to
299 the right argument.
300
301 Binary "ne" returns true if the left argument is stringwise not equal
302 to the right argument.
303
304 Binary "cmp" returns -1, 0, or 1 depending on whether the left argument is stringwise
305 less than, equal to, or greater than the right argument.
306
307 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
308 by the current locale if C<use locale> is in effect.  See L<perllocale>.
309
310 =head2 Bitwise And
311
312 Binary "&" returns its operators ANDed together bit by bit.
313 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
314
315 =head2 Bitwise Or and Exclusive Or
316
317 Binary "|" returns its operators ORed together bit by bit.
318 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
319
320 Binary "^" returns its operators XORed together bit by bit.
321 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
322
323 =head2 C-style Logical And
324
325 Binary "&&" performs a short-circuit logical AND operation.  That is,
326 if the left operand is false, the right operand is not even evaluated.
327 Scalar or list context propagates down to the right operand if it
328 is evaluated.
329
330 =head2 C-style Logical Or
331
332 Binary "||" performs a short-circuit logical OR operation.  That is,
333 if the left operand is true, the right operand is not even evaluated.
334 Scalar or list context propagates down to the right operand if it
335 is evaluated.
336
337 The C<||> and C<&&> operators differ from C's in that, rather than returning
338 0 or 1, they return the last value evaluated.  Thus, a reasonably portable
339 way to find out the home directory (assuming it's not "0") might be:
340
341     $home = $ENV{'HOME'} || $ENV{'LOGDIR'} ||
342         (getpwuid($<))[7] || die "You're homeless!\n";
343
344 In particular, this means that you shouldn't use this
345 for selecting between two aggregates for assignment:
346
347     @a = @b || @c;              # this is wrong
348     @a = scalar(@b) || @c;      # really meant this
349     @a = @b ? @b : @c;          # this works fine, though
350
351 As more readable alternatives to C<&&> and C<||> when used for
352 control flow, Perl provides C<and> and C<or> operators (see below).
353 The short-circuit behavior is identical.  The precedence of "and" and
354 "or" is much lower, however, so that you can safely use them after a
355 list operator without the need for parentheses:
356
357     unlink "alpha", "beta", "gamma"
358             or gripe(), next LINE;
359
360 With the C-style operators that would have been written like this:
361
362     unlink("alpha", "beta", "gamma")
363             || (gripe(), next LINE);
364
365 Use "or" for assignment is unlikely to do what you want; see below.
366
367 =head2 Range Operators
368
369 Binary ".." is the range operator, which is really two different
370 operators depending on the context.  In list context, it returns an
371 array of values counting (by ones) from the left value to the right
372 value.  This is useful for writing C<foreach (1..10)> loops and for
373 doing slice operations on arrays.  In the current implementation, no
374 temporary array is created when the range operator is used as the
375 expression in C<foreach> loops, but older versions of Perl might burn
376 a lot of memory when you write something like this:
377
378     for (1 .. 1_000_000) {
379         # code
380     }
381
382 In scalar context, ".." returns a boolean value.  The operator is
383 bistable, like a flip-flop, and emulates the line-range (comma) operator
384 of B<sed>, B<awk>, and various editors.  Each ".." operator maintains its
385 own boolean state.  It is false as long as its left operand is false.
386 Once the left operand is true, the range operator stays true until the
387 right operand is true, I<AFTER> which the range operator becomes false
388 again.  (It doesn't become false till the next time the range operator is
389 evaluated.  It can test the right operand and become false on the same
390 evaluation it became true (as in B<awk>), but it still returns true once.
391 If you don't want it to test the right operand till the next evaluation
392 (as in B<sed>), use three dots ("...") instead of two.)  The right
393 operand is not evaluated while the operator is in the "false" state, and
394 the left operand is not evaluated while the operator is in the "true"
395 state.  The precedence is a little lower than || and &&.  The value
396 returned is either the empty string for false, or a sequence number
397 (beginning with 1) for true.  The sequence number is reset for each range
398 encountered.  The final sequence number in a range has the string "E0"
399 appended to it, which doesn't affect its numeric value, but gives you
400 something to search for if you want to exclude the endpoint.  You can
401 exclude the beginning point by waiting for the sequence number to be
402 greater than 1.  If either operand of scalar ".." is a numeric literal,
403 that operand is implicitly compared to the C<$.> variable, the current
404 line number.  Examples:
405
406 As a scalar operator:
407
408     if (101 .. 200) { print; }  # print 2nd hundred lines
409     next line if (1 .. /^$/);   # skip header lines
410     s/^/> / if (/^$/ .. eof()); # quote body
411
412     # parse mail messages
413     while (<>) {
414         $in_header =   1  .. /^$/;
415         $in_body   = /^$/ .. eof();
416         # do something based on those
417     } continue {
418         close ARGV if eof;              # reset $. each file
419     }
420
421 As a list operator:
422
423     for (101 .. 200) { print; } # print $_ 100 times
424     @foo = @foo[0 .. $#foo];    # an expensive no-op
425     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
426
427 The range operator (in list context) makes use of the magical
428 auto-increment algorithm if the operands are strings.  You
429 can say
430
431     @alphabet = ('A' .. 'Z');
432
433 to get all the letters of the alphabet, or
434
435     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
436
437 to get a hexadecimal digit, or
438
439     @z2 = ('01' .. '31');  print $z2[$mday];
440
441 to get dates with leading zeros.  If the final value specified is not
442 in the sequence that the magical increment would produce, the sequence
443 goes until the next value would be longer than the final value
444 specified.
445
446 =head2 Conditional Operator
447
448 Ternary "?:" is the conditional operator, just as in C.  It works much
449 like an if-then-else.  If the argument before the ? is true, the
450 argument before the : is returned, otherwise the argument after the :
451 is returned.  For example:
452
453     printf "I have %d dog%s.\n", $n,
454             ($n == 1) ? '' : "s";
455
456 Scalar or list context propagates downward into the 2nd
457 or 3rd argument, whichever is selected.
458
459     $a = $ok ? $b : $c;  # get a scalar
460     @a = $ok ? @b : @c;  # get an array
461     $a = $ok ? @b : @c;  # oops, that's just a count!
462
463 The operator may be assigned to if both the 2nd and 3rd arguments are
464 legal lvalues (meaning that you can assign to them):
465
466     ($a_or_b ? $a : $b) = $c;
467
468 This is not necessarily guaranteed to contribute to the readability of your program.
469
470 Because this operator produces an assignable result, using assignments
471 without parentheses will get you in trouble.  For example, this:
472
473     $a % 2 ? $a += 10 : $a += 2
474
475 Really means this:
476
477     (($a % 2) ? ($a += 10) : $a) += 2
478
479 Rather than this:
480
481     ($a % 2) ? ($a += 10) : ($a += 2)
482
483 =head2 Assignment Operators
484
485 "=" is the ordinary assignment operator.
486
487 Assignment operators work as in C.  That is,
488
489     $a += 2;
490
491 is equivalent to
492
493     $a = $a + 2;
494
495 although without duplicating any side effects that dereferencing the lvalue
496 might trigger, such as from tie().  Other assignment operators work similarly.
497 The following are recognized:
498
499     **=    +=    *=    &=    <<=    &&=
500            -=    /=    |=    >>=    ||=
501            .=    %=    ^=
502                  x=
503
504 Note that while these are grouped by family, they all have the precedence
505 of assignment.
506
507 Unlike in C, the assignment operator produces a valid lvalue.  Modifying
508 an assignment is equivalent to doing the assignment and then modifying
509 the variable that was assigned to.  This is useful for modifying
510 a copy of something, like this:
511
512     ($tmp = $global) =~ tr [A-Z] [a-z];
513
514 Likewise,
515
516     ($a += 2) *= 3;
517
518 is equivalent to
519
520     $a += 2;
521     $a *= 3;
522
523 =head2 Comma Operator
524
525 Binary "," is the comma operator.  In scalar context it evaluates
526 its left argument, throws that value away, then evaluates its right
527 argument and returns that value.  This is just like C's comma operator.
528
529 In list context, it's just the list argument separator, and inserts
530 both its arguments into the list.
531
532 The =E<gt> digraph is mostly just a synonym for the comma operator.  It's useful for
533 documenting arguments that come in pairs.  As of release 5.001, it also forces
534 any word to the left of it to be interpreted as a string.
535
536 =head2 List Operators (Rightward)
537
538 On the right side of a list operator, it has very low precedence,
539 such that it controls all comma-separated expressions found there.
540 The only operators with lower precedence are the logical operators
541 "and", "or", and "not", which may be used to evaluate calls to list
542 operators without the need for extra parentheses:
543
544     open HANDLE, "filename"
545         or die "Can't open: $!\n";
546
547 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
548
549 =head2 Logical Not
550
551 Unary "not" returns the logical negation of the expression to its right.
552 It's the equivalent of "!" except for the very low precedence.
553
554 =head2 Logical And
555
556 Binary "and" returns the logical conjunction of the two surrounding
557 expressions.  It's equivalent to && except for the very low
558 precedence.  This means that it short-circuits: i.e., the right
559 expression is evaluated only if the left expression is true.
560
561 =head2 Logical or and Exclusive Or
562
563 Binary "or" returns the logical disjunction of the two surrounding
564 expressions.  It's equivalent to || except for the very low precedence.
565 This makes it useful for control flow
566
567     print FH $data              or die "Can't write to FH: $!";
568
569 This means that it short-circuits: i.e., the right expression is evaluated
570 only if the left expression is false.  Due to its precedence, you should
571 probably avoid using this for assignment, only for control flow.
572
573     $a = $b or $c;              # bug: this is wrong
574     ($a = $b) or $c;            # really means this
575     $a = $b || $c;              # better written this way
576
577 However, when it's a list context assignment and you're trying to use
578 "||" for control flow, you probably need "or" so that the assignment
579 takes higher precedence.
580
581     @info = stat($file) || die;     # oops, scalar sense of stat!
582     @info = stat($file) or die;     # better, now @info gets its due
583
584 Then again, you could always use parentheses.
585
586 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
587 It cannot short circuit, of course.
588
589 =head2 C Operators Missing From Perl
590
591 Here is what C has that Perl doesn't:
592
593 =over 8
594
595 =item unary &
596
597 Address-of operator.  (But see the "\" operator for taking a reference.)
598
599 =item unary *
600
601 Dereference-address operator. (Perl's prefix dereferencing
602 operators are typed: $, @, %, and &.)
603
604 =item (TYPE)
605
606 Type casting operator.
607
608 =back
609
610 =head2 Quote and Quote-like Operators
611
612 While we usually think of quotes as literal values, in Perl they
613 function as operators, providing various kinds of interpolating and
614 pattern matching capabilities.  Perl provides customary quote characters
615 for these behaviors, but also provides a way for you to choose your
616 quote character for any of them.  In the following table, a C<{}> represents
617 any pair of delimiters you choose.  Non-bracketing delimiters use
618 the same character fore and aft, but the 4 sorts of brackets
619 (round, angle, square, curly) will all nest.
620
621     Customary  Generic        Meaning        Interpolates
622         ''       q{}          Literal             no
623         ""      qq{}          Literal             yes
624         ``      qx{}          Command             yes (unless '' is delimiter)
625                 qw{}         Word list            no
626         //       m{}       Pattern match          yes
627                  s{}{}      Substitution          yes
628                 tr{}{}    Transliteration         no (but see below)
629
630 Note that there can be whitespace between the operator and the quoting
631 characters, except when C<#> is being used as the quoting character.
632 C<q#foo#> is parsed as being the string C<foo>, while C<q #foo#> is the
633 operator C<q> followed by a comment. Its argument will be taken from the
634 next line. This allows you to write:
635
636     s {foo}  # Replace foo
637       {bar}  # with bar.
638
639 For constructs that do interpolation, variables beginning with "C<$>"
640 or "C<@>" are interpolated, as are the following sequences. Within
641 a transliteration, the first ten of these sequences may be used.
642
643     \t          tab             (HT, TAB)
644     \n          newline         (NL)
645     \r          return          (CR)
646     \f          form feed       (FF)
647     \b          backspace       (BS)
648     \a          alarm (bell)    (BEL)
649     \e          escape          (ESC)
650     \033        octal char
651     \x1b        hex char
652     \c[         control char
653
654     \l          lowercase next char
655     \u          uppercase next char
656     \L          lowercase till \E
657     \U          uppercase till \E
658     \E          end case modification
659     \Q          quote non-word characters till \E
660
661 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
662 and C<\U> is taken from the current locale.  See L<perllocale>.
663
664 All systems use the virtual C<"\n"> to represent a line terminator,
665 called a "newline".  There is no such thing as an unvarying, physical
666 newline character.  It is an illusion that the operating system,
667 device drivers, C libraries, and Perl all conspire to preserve.  Not all
668 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
669 on a Mac, these are reversed, and on systems without line terminator,
670 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
671 you mean a "newline" for your system, but use the literal ASCII when you
672 need an exact character.  For example, most networking protocols expect
673 and prefer a CR+LF (C<"\012\015"> or C<"\cJ\cM">) for line terminators,
674 and although they often accept just C<"\012">, they seldom tolerate just
675 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
676 you may be burned some day.
677
678 You cannot include a literal C<$> or C<@> within a C<\Q> sequence. 
679 An unescaped C<$> or C<@> interpolates the corresponding variable, 
680 while escaping will cause the literal string C<\$> to be inserted.
681 You'll need to write something like C<m/\Quser\E\@\Qhost/>. 
682
683 Patterns are subject to an additional level of interpretation as a
684 regular expression.  This is done as a second pass, after variables are
685 interpolated, so that regular expressions may be incorporated into the
686 pattern from the variables.  If this is not what you want, use C<\Q> to
687 interpolate a variable literally.
688
689 Apart from the above, there are no multiple levels of interpolation.  In
690 particular, contrary to the expectations of shell programmers, back-quotes
691 do I<NOT> interpolate within double quotes, nor do single quotes impede
692 evaluation of variables when used within double quotes.
693
694 =head2 Regexp Quote-Like Operators
695
696 Here are the quote-like operators that apply to pattern
697 matching and related activities.
698
699 Most of this section is related to use of regular expressions from Perl.
700 Such a use may be considered from two points of view: Perl handles a
701 a string and a "pattern" to RE (regular expression) engine to match, 
702 RE engine finds (or does not find) the match, and Perl uses the findings 
703 of RE engine for its operation, possibly asking the engine for other matches.
704
705 RE engine has no idea what Perl is going to do with what it finds, 
706 similarly, the rest of Perl has no idea what a particular regular expression 
707 means to RE engine.  This creates a clean separation, and in this section
708 we discuss matching from Perl point of view only.  The other point of
709 view may be found in L<perlre>.
710
711 =over 8
712
713 =item ?PATTERN?
714
715 This is just like the C</pattern/> search, except that it matches only
716 once between calls to the reset() operator.  This is a useful
717 optimization when you want to see only the first occurrence of
718 something in each file of a set of files, for instance.  Only C<??>
719 patterns local to the current package are reset.
720
721     while (<>) {
722         if (?^$?) {
723                             # blank line between header and body
724         }
725     } continue {
726         reset if eof;       # clear ?? status for next file
727     }
728
729 This usage is vaguely deprecated, and may be removed in some future
730 version of Perl.
731
732 =item m/PATTERN/cgimosx
733
734 =item /PATTERN/cgimosx
735
736 Searches a string for a pattern match, and in scalar context returns
737 true (1) or false ('').  If no string is specified via the C<=~> or
738 C<!~> operator, the $_ string is searched.  (The string specified with
739 C<=~> need not be an lvalue--it may be the result of an expression
740 evaluation, but remember the C<=~> binds rather tightly.)  See also
741 L<perlre>.
742 See L<perllocale> for discussion of additional considerations that apply
743 when C<use locale> is in effect.
744
745 Options are:
746
747     c   Do not reset search position on a failed match when /g is in effect.
748     g   Match globally, i.e., find all occurrences.
749     i   Do case-insensitive pattern matching.
750     m   Treat string as multiple lines.
751     o   Compile pattern only once.
752     s   Treat string as single line.
753     x   Use extended regular expressions.
754
755 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
756 you can use any pair of non-alphanumeric, non-whitespace characters 
757 as delimiters (if single quotes are used, no interpretation is done
758 on the replacement string. Unlike Perl 4, Perl 5 treats backticks as normal
759 delimiters; the replacement text is not evaluated as a command).
760 This is particularly useful for matching Unix path names
761 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
762 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
763
764 PATTERN may contain variables, which will be interpolated (and the
765 pattern recompiled) every time the pattern search is evaluated.  (Note
766 that C<$)> and C<$|> might not be interpolated because they look like
767 end-of-string tests.)  If you want such a pattern to be compiled only
768 once, add a C</o> after the trailing delimiter.  This avoids expensive
769 run-time recompilations, and is useful when the value you are
770 interpolating won't change over the life of the script.  However, mentioning
771 C</o> constitutes a promise that you won't change the variables in the pattern.
772 If you change them, Perl won't even notice.
773
774 If the PATTERN evaluates to the empty string, the last
775 I<successfully> matched regular expression is used instead.
776
777 If the C</g> option is not used, C<m//> in a list context returns a
778 list consisting of the subexpressions matched by the parentheses in the
779 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here
780 C<$1> etc. are also set, and
781 that this differs from Perl 4's behavior.)  If there are no parentheses,
782 the return value is the list C<(1)> for success or C<('')> upon failure.
783 With parentheses, C<()> is returned upon failure.
784
785 Examples:
786
787     open(TTY, '/dev/tty');
788     <TTY> =~ /^y/i && foo();    # do foo if desired
789
790     if (/Version: *([0-9.]*)/) { $version = $1; }
791
792     next if m#^/usr/spool/uucp#;
793
794     # poor man's grep
795     $arg = shift;
796     while (<>) {
797         print if /$arg/o;       # compile only once
798     }
799
800     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
801
802 This last example splits $foo into the first two words and the
803 remainder of the line, and assigns those three fields to $F1, $F2, and
804 $Etc.  The conditional is true if any variables were assigned, i.e., if
805 the pattern matched.
806
807 The C</g> modifier specifies global pattern matching--that is, matching
808 as many times as possible within the string.  How it behaves depends on
809 the context.  In list context, it returns a list of all the
810 substrings matched by all the parentheses in the regular expression.
811 If there are no parentheses, it returns a list of all the matched
812 strings, as if there were parentheses around the whole pattern.
813
814 In scalar context, C<m//g> iterates through the string, returning TRUE
815 each time it matches, and FALSE when it eventually runs out of matches.
816 (In other words, it remembers where it left off last time and restarts
817 the search at that point.  You can actually find the current match
818 position of a string or set it using the pos() function; see
819 L<perlfunc/pos>.)  A failed match normally resets the search position to
820 the beginning of the string, but you can avoid that by adding the C</c>
821 modifier (e.g. C<m//gc>).  Modifying the target string also resets the
822 search position.
823
824 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
825 zero-width assertion that matches the exact position where the previous
826 C<m//g>, if any, left off.  The C<\G> assertion is not supported without
827 the C</g> modifier; currently, without C</g>, C<\G> behaves just like
828 C<\A>, but that's accidental and may change in the future.
829
830 Examples:
831
832     # list context
833     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
834
835     # scalar context
836     $/ = ""; $* = 1;  # $* deprecated in modern perls
837     while (defined($paragraph = <>)) {
838         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
839             $sentences++;
840         }
841     }
842     print "$sentences\n";
843
844     # using m//gc with \G
845     $_ = "ppooqppqq";
846     while ($i++ < 2) {
847         print "1: '";
848         print $1 while /(o)/gc; print "', pos=", pos, "\n";
849         print "2: '";
850         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
851         print "3: '";
852         print $1 while /(p)/gc; print "', pos=", pos, "\n";
853     }
854
855 The last example should print:
856
857     1: 'oo', pos=4
858     2: 'q', pos=5
859     3: 'pp', pos=7
860     1: '', pos=7
861     2: 'q', pos=8
862     3: '', pos=8
863
864 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
865 combine several regexps like this to process a string part-by-part,
866 doing different actions depending on which regexp matched.  Each
867 regexp tries to match where the previous one leaves off.
868
869  $_ = <<'EOL';
870       $url = new URI::URL "http://www/";   die if $url eq "xXx";
871  EOL
872  LOOP:
873     {
874       print(" digits"),         redo LOOP if /\G\d+\b[,.;]?\s*/gc;
875       print(" lowercase"),      redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
876       print(" UPPERCASE"),      redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
877       print(" Capitalized"),    redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
878       print(" MiXeD"),          redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
879       print(" alphanumeric"),   redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
880       print(" line-noise"),     redo LOOP if /\G[^A-Za-z0-9]+/gc;
881       print ". That's all!\n";
882     }
883
884 Here is the output (split into several lines):
885
886  line-noise lowercase line-noise lowercase UPPERCASE line-noise
887  UPPERCASE line-noise lowercase line-noise lowercase line-noise
888  lowercase lowercase line-noise lowercase lowercase line-noise
889  MiXeD line-noise. That's all!
890
891 =item q/STRING/
892
893 =item C<'STRING'>
894
895 A single-quoted, literal string. A backslash represents a backslash
896 unless followed by the delimiter or another backslash, in which case
897 the delimiter or backslash is interpolated.
898
899     $foo = q!I said, "You said, 'She said it.'"!;
900     $bar = q('This is it.');
901     $baz = '\n';                # a two-character string
902
903 =item qq/STRING/
904
905 =item "STRING"
906
907 A double-quoted, interpolated string.
908
909     $_ .= qq
910      (*** The previous line contains the naughty word "$1".\n)
911                 if /(tcl|rexx|python)/;      # :-)
912     $baz = "\n";                # a one-character string
913
914 =item qx/STRING/
915
916 =item `STRING`
917
918 A string which is (possibly) interpolated and then executed as a system
919 command with C</bin/sh> or its equivalent.  Shell wildcards, pipes,
920 and redirections will be honored.  The collected standard output of the
921 command is returned; standard error is unaffected.  In scalar context,
922 it comes back as a single (potentially multi-line) string.  In list
923 context, returns a list of lines (however you've defined lines with $/
924 or $INPUT_RECORD_SEPARATOR).
925
926 Because backticks do not affect standard error, use shell file descriptor
927 syntax (assuming the shell supports this) if you care to address this.
928 To capture a command's STDERR and STDOUT together:
929
930     $output = `cmd 2>&1`;
931
932 To capture a command's STDOUT but discard its STDERR:
933
934     $output = `cmd 2>/dev/null`;
935
936 To capture a command's STDERR but discard its STDOUT (ordering is
937 important here):
938
939     $output = `cmd 2>&1 1>/dev/null`;
940
941 To exchange a command's STDOUT and STDERR in order to capture the STDERR
942 but leave its STDOUT to come out the old STDERR:
943
944     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
945
946 To read both a command's STDOUT and its STDERR separately, it's easiest
947 and safest to redirect them separately to files, and then read from those
948 files when the program is done:
949
950     system("program args 1>/tmp/program.stdout 2>/tmp/program.stderr");
951
952 Using single-quote as a delimiter protects the command from Perl's
953 double-quote interpolation, passing it on to the shell instead:
954
955     $perl_info  = qx(ps $$);            # that's Perl's $$
956     $shell_info = qx'ps $$';            # that's the new shell's $$
957
958 Note that how the string gets evaluated is entirely subject to the command
959 interpreter on your system.  On most platforms, you will have to protect
960 shell metacharacters if you want them treated literally.  This is in
961 practice difficult to do, as it's unclear how to escape which characters.
962 See L<perlsec> for a clean and safe example of a manual fork() and exec()
963 to emulate backticks safely.
964
965 On some platforms (notably DOS-like ones), the shell may not be
966 capable of dealing with multiline commands, so putting newlines in
967 the string may not get you what you want.  You may be able to evaluate
968 multiple commands in a single line by separating them with the command
969 separator character, if your shell supports that (e.g. C<;> on many Unix
970 shells; C<&> on the Windows NT C<cmd> shell).
971
972 Beware that some command shells may place restrictions on the length
973 of the command line.  You must ensure your strings don't exceed this
974 limit after any necessary interpolations.  See the platform-specific
975 release notes for more details about your particular environment.
976
977 Using this operator can lead to programs that are difficult to port,
978 because the shell commands called vary between systems, and may in
979 fact not be present at all.  As one example, the C<type> command under
980 the POSIX shell is very different from the C<type> command under DOS.
981 That doesn't mean you should go out of your way to avoid backticks
982 when they're the right way to get something done.  Perl was made to be
983 a glue language, and one of the things it glues together is commands.
984 Just understand what you're getting yourself into.
985
986 See L<"I/O Operators"> for more discussion.
987
988 =item qw/STRING/
989
990 Returns a list of the words extracted out of STRING, using embedded
991 whitespace as the word delimiters.  It is exactly equivalent to
992
993     split(' ', q/STRING/);
994
995 This equivalency means that if used in scalar context, you'll get split's
996 (unfortunate) scalar context behavior, complete with mysterious warnings.
997
998 Some frequently seen examples:
999
1000     use POSIX qw( setlocale localeconv )
1001     @EXPORT = qw( foo bar baz );
1002
1003 A common mistake is to try to separate the words with comma or to put
1004 comments into a multi-line C<qw>-string.  For this reason the C<-w>
1005 switch produce warnings if the STRING contains the "," or the "#"
1006 character.
1007
1008 =item s/PATTERN/REPLACEMENT/egimosx
1009
1010 Searches a string for a pattern, and if found, replaces that pattern
1011 with the replacement text and returns the number of substitutions
1012 made.  Otherwise it returns false (specifically, the empty string).
1013
1014 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1015 variable is searched and modified.  (The string specified with C<=~> must
1016 be scalar variable, an array element, a hash element, or an assignment
1017 to one of those, i.e., an lvalue.)
1018
1019 If the delimiter chosen is single quote, no variable interpolation is
1020 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1021 PATTERN contains a $ that looks like a variable rather than an
1022 end-of-string test, the variable will be interpolated into the pattern
1023 at run-time.  If you want the pattern compiled only once the first time
1024 the variable is interpolated, use the C</o> option.  If the pattern
1025 evaluates to the empty string, the last successfully executed regular
1026 expression is used instead.  See L<perlre> for further explanation on these.
1027 See L<perllocale> for discussion of additional considerations that apply
1028 when C<use locale> is in effect.
1029
1030 Options are:
1031
1032     e   Evaluate the right side as an expression.
1033     g   Replace globally, i.e., all occurrences.
1034     i   Do case-insensitive pattern matching.
1035     m   Treat string as multiple lines.
1036     o   Compile pattern only once.
1037     s   Treat string as single line.
1038     x   Use extended regular expressions.
1039
1040 Any non-alphanumeric, non-whitespace delimiter may replace the
1041 slashes.  If single quotes are used, no interpretation is done on the
1042 replacement string (the C</e> modifier overrides this, however).  Unlike
1043 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
1044 text is not evaluated as a command.  If the
1045 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
1046 pair of quotes, which may or may not be bracketing quotes, e.g.,
1047 C<s(foo)(bar)> or C<sE<lt>fooE<gt>/bar/>.  A C</e> will cause the
1048 replacement portion to be interpreted as a full-fledged Perl expression
1049 and eval()ed right then and there.  It is, however, syntax checked at
1050 compile-time.
1051
1052 Examples:
1053
1054     s/\bgreen\b/mauve/g;                # don't change wintergreen
1055
1056     $path =~ s|/usr/bin|/usr/local/bin|;
1057
1058     s/Login: $foo/Login: $bar/; # run-time pattern
1059
1060     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1061
1062     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1063
1064     $_ = 'abc123xyz';
1065     s/\d+/$&*2/e;               # yields 'abc246xyz'
1066     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1067     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1068
1069     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1070     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1071     s/^=(\w+)/&pod($1)/ge;      # use function call
1072
1073     # expand variables in $_, but dynamics only, using
1074     # symbolic dereferencing
1075     s/\$(\w+)/${$1}/g;
1076
1077     # /e's can even nest;  this will expand
1078     # any embedded scalar variable (including lexicals) in $_
1079     s/(\$\w+)/$1/eeg;
1080
1081     # Delete (most) C comments.
1082     $program =~ s {
1083         /\*     # Match the opening delimiter.
1084         .*?     # Match a minimal number of characters.
1085         \*/     # Match the closing delimiter.
1086     } []gsx;
1087
1088     s/^\s*(.*?)\s*$/$1/;        # trim white space in $_, expensively
1089
1090     for ($variable) {           # trim white space in $variable, cheap
1091         s/^\s+//;
1092         s/\s+$//;
1093     }
1094
1095     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1096
1097 Note the use of $ instead of \ in the last example.  Unlike
1098 B<sed>, we use the \E<lt>I<digit>E<gt> form in only the left hand side.
1099 Anywhere else it's $E<lt>I<digit>E<gt>.
1100
1101 Occasionally, you can't use just a C</g> to get all the changes
1102 to occur.  Here are two common cases:
1103
1104     # put commas in the right places in an integer
1105     1 while s/(.*\d)(\d\d\d)/$1,$2/g;      # perl4
1106     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;  # perl5
1107
1108     # expand tabs to 8-column spacing
1109     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1110
1111
1112 =item tr/SEARCHLIST/REPLACEMENTLIST/cds
1113
1114 =item y/SEARCHLIST/REPLACEMENTLIST/cds
1115
1116 Transliterates all occurrences of the characters found in the search list
1117 with the corresponding character in the replacement list.  It returns
1118 the number of characters replaced or deleted.  If no string is
1119 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1120 string specified with =~ must be a scalar variable, an array element, a
1121 hash element, or an assignment to one of those, i.e., an lvalue.)
1122 A character range may be specified with a hyphen, so C<tr/A-J/0-9/> 
1123 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1124 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1125 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1126 its own pair of quotes, which may or may not be bracketing quotes,
1127 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1128
1129 Options:
1130
1131     c   Complement the SEARCHLIST.
1132     d   Delete found but unreplaced characters.
1133     s   Squash duplicate replaced characters.
1134
1135 If the C</c> modifier is specified, the SEARCHLIST character set is
1136 complemented.  If the C</d> modifier is specified, any characters specified
1137 by SEARCHLIST not found in REPLACEMENTLIST are deleted.  (Note
1138 that this is slightly more flexible than the behavior of some B<tr>
1139 programs, which delete anything they find in the SEARCHLIST, period.)
1140 If the C</s> modifier is specified, sequences of characters that were
1141 transliterated to the same character are squashed down to a single instance of the
1142 character.
1143
1144 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1145 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1146 than the SEARCHLIST, the final character is replicated till it is long
1147 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1148 This latter is useful for counting characters in a class or for
1149 squashing character sequences in a class.
1150
1151 Examples:
1152
1153     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1154
1155     $cnt = tr/*/*/;             # count the stars in $_
1156
1157     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1158
1159     $cnt = tr/0-9//;            # count the digits in $_
1160
1161     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1162
1163     ($HOST = $host) =~ tr/a-z/A-Z/;
1164
1165     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1166
1167     tr [\200-\377]
1168        [\000-\177];             # delete 8th bit
1169
1170 If multiple transliterations are given for a character, only the first one is used:
1171
1172     tr/AAA/XYZ/
1173
1174 will transliterate any A to X.
1175
1176 Note that because the transliteration table is built at compile time, neither
1177 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1178 interpolation.  That means that if you want to use variables, you must use
1179 an eval():
1180
1181     eval "tr/$oldlist/$newlist/";
1182     die $@ if $@;
1183
1184     eval "tr/$oldlist/$newlist/, 1" or die $@;
1185
1186 =back
1187
1188 =head2 Gory details of parsing quoted constructs
1189
1190 When presented with something which may have several different 
1191 interpretations, Perl uses the principle B<DWIM> (expanded to Do What I Mean 
1192 - not what I wrote) to pick up the most probable interpretation of the 
1193 source.  This strategy is so successful that Perl users usually do not
1194 suspect ambivalence of what they write.  However, time to time Perl's ideas
1195 differ from what the author meant.  
1196
1197 The target of this section is to clarify the Perl's way of interpreting
1198 quoted constructs.  The most frequent reason one may have to want to know the 
1199 details discussed in this section is hairy regular expressions.  However, the 
1200 first steps of parsing are the same for all Perl quoting operators, so here
1201 they are discussed together.
1202
1203 Some of the passes discussed below are performed concurrently, but as 
1204 far as results are the same, we consider them one-by-one.  For different
1205 quoting constructs Perl performs different number of passes, from
1206 one to five, but they are always performed in the same order.
1207
1208 =over
1209
1210 =item Finding the end
1211
1212 First pass is finding the end of the quoted construct, be it multichar ender
1213 C<"\nEOF\n"> of C<<<EOF> construct, C</> which terminates C<qq/> construct,
1214 C<E<]>> which terminates C<qq[> construct, or C<E<gt>> which terminates a
1215 fileglob started with C<<>.
1216
1217 When searching for multichar construct no skipping is performed.  When 
1218 searching for one-char non-matching delimiter, such as C</>, combinations
1219 C<\\> and C<\/> are skipped.  When searching for one-char matching delimiter,
1220 such as C<]>, combinations C<\\>, C<\]> and C<\[> are skipped, and 
1221 nested C<[>, C<]> are skipped as well.
1222
1223 For 3-parts constructs C<s///> etc. the search is repeated once more.
1224
1225 During this search no attension is paid to the semantic of the construct, thus
1226
1227     "$hash{"$foo/$bar"}"
1228
1229 or
1230
1231     m/ 
1232       bar       #  This is not a comment, this slash / terminated m//!
1233      /x
1234
1235 do not form legal quoted expressions.  Note that since the slash which 
1236 terminated C<m//> was followed by a C<SPACE>, this is not C<m//x>, 
1237 thus C<#> was interpreted as a literal C<#>.
1238
1239 =item Removal of backslashes before delimiters
1240
1241 During the second pass the text between the starting delimiter and 
1242 the ending delimiter is copied to a safe location, and the C<\> is 
1243 removed from combinations consisting of C<\> and delimiter(s) (both starting
1244 and ending delimiter if they differ).
1245
1246 The removal does not happen for multi-char delimiters.
1247
1248 Note that the combination C<\\> is left as it was!
1249
1250 Starting from this step no information about the delimiter(s) is used in the
1251 parsing.
1252
1253 =item Interpolation
1254
1255 Next step is interpolation in the obtained delimiter-independent text.
1256 There are many different cases.
1257
1258 =over
1259
1260 =item C<<<'EOF'>, C<m''>, C<s'''>, C<tr///>, C<y///>
1261
1262 No interpolation is performed.
1263
1264 =item C<''>, C<q//>
1265
1266 The only interpolation is removal of C<\> from pairs C<\\>.
1267
1268 =item C<"">, C<``>, C<qq//>, C<qx//>, C<<file*globE<gt>>
1269
1270 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are converted
1271 to corresponding Perl constructs, thus C<"$foo\Qbaz$bar"> is converted to 
1272
1273    $foo . (quotemeta("baz" . $bar));
1274
1275 Other combinations of C<\> with following chars are substituted with
1276 appropriate expansions.  
1277
1278 Interpolated scalars and arrays are converted to C<join> and C<.> Perl 
1279 constructs, thus C<"'@arr'"> becomes
1280
1281   "'" . (join $", @arr) . "'";
1282
1283 Since all three above steps are performed simultaneously left-to-right,
1284 the is no way to insert a literal C<$> or C<@> inside C<\Q\E> pair: it
1285 cannot be protected by C<\>, since any C<\> (except in C<\E>) is 
1286 interpreted as a literal inside C<\Q\E>, and any $ is 
1287 interpreted as starting an interpolated scalar.
1288
1289 Note also that the interpolating code needs to make decision where the 
1290 interpolated scalar ends, say, whether C<"a $b -> {c}"> means 
1291
1292   "a " . $b . " -> {c}";
1293
1294 or 
1295
1296   "a " . $b -> {c};
1297
1298 Most the time the decision is to take the longest possible text which does
1299 not include spaces between components and contains matching braces/brackets.
1300
1301 =item C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>, 
1302
1303 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> and interpolation happens 
1304 (almost) as with qq// constructs, but I<the substitution of C<\> followed by
1305 other chars is not performed>!  Moreover, inside C<(?{BLOCK})> no processing
1306 is performed at all.
1307
1308 Interpolation has several quirks: $|, $( and $) are not interpolated, and
1309 constructs C<$var[SOMETHING]> are I<voted> (by several different estimators) 
1310 to be an array element or $var followed by a RE alternative.  This is
1311 the place where the notation C<${arr[$bar]}> comes handy: C</${arr[0-9]}/>
1312 is interpreted as an array element -9, not as a regular expression from
1313 variable $arr followed by a digit, which is the interpretation of 
1314 C</$arr[0-9]/>.
1315
1316 Note that absense of processing of C<\\> creates specific restrictions on the
1317 post-processed text: if the delimeter is C</>, one cannot get the combination
1318 C<\/> into the result of this step: C</> will finish the regular expression,
1319 C<\/> will be stripped to C</> on the previous step, and C<\\/> will be left
1320 as is.  Since C</> is equivalent to C<\/> inside a regular expression, this
1321 does not matter unless the delimiter is special character for RE engine, as 
1322 in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>.
1323
1324 =back
1325
1326 This step is the last one for all the constructs except regular expressions,
1327 which are processed further.
1328
1329 =item Interpolation of regular expressions
1330
1331 All the previous steps were performed during the compilation of Perl code,
1332 this one happens in run time (though it may be optimized to be calculated
1333 at compile time if appropriate).  After all the preprocessing performed 
1334 above (and possibly after evaluation if catenation, joining, up/down-casing 
1335 and quotemeta()ing are involved) the resulting I<string> is passed to RE
1336 engine for compilation.
1337
1338 Whatever happens in the RE engine is better be discussed in L<perlre>,
1339 but for the sake of continuity let us do it here.
1340
1341 This is the first step where presense of the C<//x> switch is relevant.
1342 RE engine scans the string left-to-right, and converts it to a finite 
1343 automaton.  
1344
1345 Backslashed chars are either substituted by corresponding literal 
1346 strings, or generate special nodes of the finite automaton.  Characters
1347 which are special to RE engine generate corresponding nodes.  C<(?#...)>
1348 comments are ignored.  All the rest is either converted to literal strings
1349 to match, or is ignored (as is whitespace and C<#>-style comments if
1350 C<//x> is present).
1351
1352 Note that the parsing of the construct C<[...]> is performed using 
1353 absolutely different rules than the rest of the regular expression.  
1354 Similarly, the C<(?{...})> is only checked for matching braces.
1355
1356 =item Optimization of regular expressions
1357
1358 This step is listed for compeleteness only.  Since it does not change
1359 semantics, details of this step are not documented and are subject
1360 to change.
1361
1362 =back
1363
1364 =head2 I/O Operators
1365
1366 There are several I/O operators you should know about.
1367 A string enclosed by backticks (grave accents) first undergoes
1368 variable substitution just like a double quoted string.  It is then
1369 interpreted as a command, and the output of that command is the value
1370 of the pseudo-literal, like in a shell.  In scalar context, a single
1371 string consisting of all the output is returned.  In list context,
1372 a list of values is returned, one for each line of output.  (You can
1373 set C<$/> to use a different line terminator.)  The command is executed
1374 each time the pseudo-literal is evaluated.  The status value of the
1375 command is returned in C<$?> (see L<perlvar> for the interpretation
1376 of C<$?>).  Unlike in B<csh>, no translation is done on the return
1377 data--newlines remain newlines.  Unlike in any of the shells, single
1378 quotes do not hide variable names in the command from interpretation.
1379 To pass a $ through to the shell you need to hide it with a backslash.
1380 The generalized form of backticks is C<qx//>.  (Because backticks
1381 always undergo shell expansion as well, see L<perlsec> for
1382 security concerns.)
1383
1384 Evaluating a filehandle in angle brackets yields the next line from
1385 that file (newline, if any, included), or C<undef> at end of file.
1386 Ordinarily you must assign that value to a variable, but there is one
1387 situation where an automatic assignment happens.  I<If and ONLY if> the
1388 input symbol is the only thing inside the conditional of a C<while> or
1389 C<for(;;)> loop, the value is automatically assigned to the variable
1390 C<$_>.  In these loop constructs, the assigned value (whether assignment
1391 is automatic or explicit) is then tested to see if it is defined.
1392 The defined test avoids problems where line has a string value
1393 that would be treated as false by perl e.g. "" or "0" with no trailing
1394 newline. (This may seem like an odd thing to you, but you'll use the 
1395 construct in almost every Perl script you write.) Anyway, the following 
1396 lines are equivalent to each other:
1397
1398     while (defined($_ = <STDIN>)) { print; }
1399     while ($_ = <STDIN>) { print; }
1400     while (<STDIN>) { print; }
1401     for (;<STDIN>;) { print; }
1402     print while defined($_ = <STDIN>);
1403     print while ($_ = <STDIN>);
1404     print while <STDIN>;
1405
1406 and this also behaves similarly, but avoids the use of $_ :
1407
1408     while (my $line = <STDIN>) { print $line }    
1409
1410 If you really mean such values to terminate the loop they should be 
1411 tested for explicitly:
1412
1413     while (($_ = <STDIN>) ne '0') { ... }
1414     while (<STDIN>) { last unless $_; ... }
1415
1416 In other boolean contexts, C<E<lt>I<filehandle>E<gt>> without explicit C<defined>
1417 test or comparison will solicit a warning if C<-w> is in effect.
1418
1419 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
1420 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except in
1421 packages, where they would be interpreted as local identifiers rather
1422 than global.)  Additional filehandles may be created with the open()
1423 function.  See L<perlfunc/open()> for details on this.
1424
1425 If a E<lt>FILEHANDLEE<gt> is used in a context that is looking for a list, a
1426 list consisting of all the input lines is returned, one line per list
1427 element.  It's easy to make a I<LARGE> data space this way, so use with
1428 care.
1429
1430 The null filehandle E<lt>E<gt> is special and can be used to emulate the
1431 behavior of B<sed> and B<awk>.  Input from E<lt>E<gt> comes either from
1432 standard input, or from each file listed on the command line.  Here's
1433 how it works: the first time E<lt>E<gt> is evaluated, the @ARGV array is
1434 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
1435 gives you standard input.  The @ARGV array is then processed as a list
1436 of filenames.  The loop
1437
1438     while (<>) {
1439         ...                     # code for each line
1440     }
1441
1442 is equivalent to the following Perl-like pseudo code:
1443
1444     unshift(@ARGV, '-') unless @ARGV;
1445     while ($ARGV = shift) {
1446         open(ARGV, $ARGV);
1447         while (<ARGV>) {
1448             ...         # code for each line
1449         }
1450     }
1451
1452 except that it isn't so cumbersome to say, and will actually work.  It
1453 really does shift array @ARGV and put the current filename into variable
1454 $ARGV.  It also uses filehandle I<ARGV> internally--E<lt>E<gt> is just a
1455 synonym for E<lt>ARGVE<gt>, which is magical.  (The pseudo code above
1456 doesn't work because it treats E<lt>ARGVE<gt> as non-magical.)
1457
1458 You can modify @ARGV before the first E<lt>E<gt> as long as the array ends up
1459 containing the list of filenames you really want.  Line numbers (C<$.>)
1460 continue as if the input were one big happy file.  (But see example
1461 under C<eof> for how to reset line numbers on each file.)
1462
1463 If you want to set @ARGV to your own list of files, go right ahead.  
1464 This sets @ARGV to all plain text files if no @ARGV was given:
1465
1466     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
1467
1468 You can even set them to pipe commands.  For example, this automatically
1469 filters compressed arguments through B<gzip>:
1470
1471     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
1472
1473 If you want to pass switches into your script, you can use one of the
1474 Getopts modules or put a loop on the front like this:
1475
1476     while ($_ = $ARGV[0], /^-/) {
1477         shift;
1478         last if /^--$/;
1479         if (/^-D(.*)/) { $debug = $1 }
1480         if (/^-v/)     { $verbose++  }
1481         # ...           # other switches
1482     }
1483
1484     while (<>) {
1485         # ...           # code for each line
1486     }
1487
1488 The E<lt>E<gt> symbol will return C<undef> for end-of-file only once.  
1489 If you call it again after this it will assume you are processing another 
1490 @ARGV list, and if you haven't set @ARGV, will input from STDIN.
1491
1492 If the string inside the angle brackets is a reference to a scalar
1493 variable (e.g., E<lt>$fooE<gt>), then that variable contains the name of the
1494 filehandle to input from, or its typeglob, or a reference to the same.  For example:
1495
1496     $fh = \*STDIN;
1497     $line = <$fh>;
1498
1499 If what's within the angle brackets is neither a filehandle nor a simple
1500 scalar variable containing a filehandle name, typeglob, or typeglob
1501 reference, it is interpreted as a filename pattern to be globbed, and
1502 either a list of filenames or the next filename in the list is returned,
1503 depending on context.   This distinction is determined on syntactic
1504 grounds alone.  That means C<E<lt>$xE<gt>> is always a readline from
1505 an indirect handle, but C<E<lt>$hash{key}E<gt>> is always a glob.
1506 That's because $x is a simple scalar variable, but C<$hash{key}> is
1507 not--it's a hash element.
1508
1509 One level of double-quote interpretation is done first, but you can't
1510 say C<E<lt>$fooE<gt>> because that's an indirect filehandle as explained
1511 in the previous paragraph.  (In older versions of Perl, programmers
1512 would insert curly brackets to force interpretation as a filename glob:
1513 C<E<lt>${foo}E<gt>>.  These days, it's considered cleaner to call the
1514 internal function directly as C<glob($foo)>, which is probably the right
1515 way to have done it in the first place.)  Example:
1516
1517     while (<*.c>) {
1518         chmod 0644, $_;
1519     }
1520
1521 is equivalent to
1522
1523     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
1524     while (<FOO>) {
1525         chop;
1526         chmod 0644, $_;
1527     }
1528
1529 In fact, it's currently implemented that way.  (Which means it will not
1530 work on filenames with spaces in them unless you have csh(1) on your
1531 machine.)  Of course, the shortest way to do the above is:
1532
1533     chmod 0644, <*.c>;
1534
1535 Because globbing invokes a shell, it's often faster to call readdir() yourself
1536 and do your own grep() on the filenames.  Furthermore, due to its current
1537 implementation of using a shell, the glob() routine may get "Arg list too
1538 long" errors (unless you've installed tcsh(1L) as F</bin/csh>).
1539
1540 A glob evaluates its (embedded) argument only when it is starting a new
1541 list.  All values must be read before it will start over.  In a list
1542 context this isn't important, because you automatically get them all
1543 anyway.  In scalar context, however, the operator returns the next value
1544 each time it is called, or a C<undef> value if you've just run out. As
1545 for filehandles an automatic C<defined> is generated when the glob
1546 occurs in the test part of a C<while> or C<for> - because legal glob returns
1547 (e.g. a file called F<0>) would otherwise terminate the loop.
1548 Again, C<undef> is returned only once.  So if you're expecting a single value 
1549 from a glob, it is much better to say
1550
1551     ($file) = <blurch*>;
1552
1553 than
1554
1555     $file = <blurch*>;
1556
1557 because the latter will alternate between returning a filename and
1558 returning FALSE.
1559
1560 It you're trying to do variable interpolation, it's definitely better
1561 to use the glob() function, because the older notation can cause people
1562 to become confused with the indirect filehandle notation.
1563
1564     @files = glob("$dir/*.[ch]");
1565     @files = glob($files[$i]);
1566
1567 =head2 Constant Folding
1568
1569 Like C, Perl does a certain amount of expression evaluation at
1570 compile time, whenever it determines that all arguments to an
1571 operator are static and have no side effects.  In particular, string
1572 concatenation happens at compile time between literals that don't do
1573 variable substitution.  Backslash interpretation also happens at
1574 compile time.  You can say
1575
1576     'Now is the time for all' . "\n" .
1577         'good men to come to.'
1578
1579 and this all reduces to one string internally.  Likewise, if
1580 you say
1581
1582     foreach $file (@filenames) {
1583         if (-s $file > 5 + 100 * 2**16) {  }
1584     }
1585
1586 the compiler will precompute the number that
1587 expression represents so that the interpreter
1588 won't have to.
1589
1590 =head2 Bitwise String Operators
1591
1592 Bitstrings of any size may be manipulated by the bitwise operators
1593 (C<~ | & ^>).
1594
1595 If the operands to a binary bitwise op are strings of different sizes,
1596 B<or> and B<xor> ops will act as if the shorter operand had additional
1597 zero bits on the right, while the B<and> op will act as if the longer
1598 operand were truncated to the length of the shorter.
1599
1600     # ASCII-based examples 
1601     print "j p \n" ^ " a h";            # prints "JAPH\n"
1602     print "JA" | "  ph\n";              # prints "japh\n"
1603     print "japh\nJunk" & '_____';       # prints "JAPH\n";
1604     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
1605
1606 If you are intending to manipulate bitstrings, you should be certain that
1607 you're supplying bitstrings: If an operand is a number, that will imply
1608 a B<numeric> bitwise operation. You may explicitly show which type of
1609 operation you intend by using C<""> or C<0+>, as in the examples below.
1610
1611     $foo =  150  |  105 ;       # yields 255  (0x96 | 0x69 is 0xFF)
1612     $foo = '150' |  105 ;       # yields 255
1613     $foo =  150  | '105';       # yields 255
1614     $foo = '150' | '105';       # yields string '155' (under ASCII)
1615
1616     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
1617     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
1618
1619 =head2 Integer Arithmetic
1620
1621 By default Perl assumes that it must do most of its arithmetic in
1622 floating point.  But by saying
1623
1624     use integer;
1625
1626 you may tell the compiler that it's okay to use integer operations
1627 from here to the end of the enclosing BLOCK.  An inner BLOCK may
1628 countermand this by saying
1629
1630     no integer;
1631
1632 which lasts until the end of that BLOCK.
1633
1634 The bitwise operators ("&", "|", "^", "~", "<<", and ">>") always
1635 produce integral results.  (But see also L<Bitwise String Operators>.)
1636 However, C<use integer> still has meaning
1637 for them.  By default, their results are interpreted as unsigned
1638 integers.  However, if C<use integer> is in effect, their results are
1639 interpreted as signed integers.  For example, C<~0> usually evaluates
1640 to a large integral value.  However, C<use integer; ~0> is -1 on twos-complement machines.
1641
1642 =head2 Floating-point Arithmetic
1643
1644 While C<use integer> provides integer-only arithmetic, there is no
1645 similar ways to provide rounding or truncation at a certain number of
1646 decimal places.  For rounding to a certain number of digits, sprintf()
1647 or printf() is usually the easiest route.
1648
1649 Floating-point numbers are only approximations to what a mathematician
1650 would call real numbers.  There are infinitely more reals than floats,
1651 so some corners must be cut.  For example:
1652
1653     printf "%.20g\n", 123456789123456789;
1654     #        produces 123456789123456784
1655
1656 Testing for exact equality of floating-point equality or inequality is
1657 not a good idea.  Here's a (relatively expensive) work-around to compare
1658 whether two floating-point numbers are equal to a particular number of
1659 decimal places.  See Knuth, volume II, for a more robust treatment of
1660 this topic.
1661
1662     sub fp_equal {
1663         my ($X, $Y, $POINTS) = @_;
1664         my ($tX, $tY);
1665         $tX = sprintf("%.${POINTS}g", $X);
1666         $tY = sprintf("%.${POINTS}g", $Y);
1667         return $tX eq $tY;
1668     }
1669
1670 The POSIX module (part of the standard perl distribution) implements
1671 ceil(), floor(), and a number of other mathematical and trigonometric
1672 functions.  The Math::Complex module (part of the standard perl
1673 distribution) defines a number of mathematical functions that can also
1674 work on real numbers.  Math::Complex not as efficient as POSIX, but
1675 POSIX can't work with complex numbers.
1676
1677 Rounding in financial applications can have serious implications, and
1678 the rounding method used should be specified precisely.  In these
1679 cases, it probably pays not to trust whichever system rounding is
1680 being used by Perl, but to instead implement the rounding function you
1681 need yourself.
1682
1683 =head2 Bigger Numbers
1684
1685 The standard Math::BigInt and Math::BigFloat modules provide
1686 variable precision arithmetic and overloaded operators.
1687 At the cost of some space and considerable speed, they
1688 avoid the normal pitfalls associated with limited-precision
1689 representations.
1690
1691     use Math::BigInt;
1692     $x = Math::BigInt->new('123456789123456789');
1693     print $x * $x;
1694
1695     # prints +15241578780673678515622620750190521